BECI     TITLE 'EDIT COMMAND - COMMAND INVOKER - IKJEBECI'              00100020
*********************************************************************** 00200020
*                                                                     * 00300020
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 00400020
*                                                                     * 00500020
* FUNCTION -- THIS ROUTINE INVOKES COMMAND PROCESSORS FOR THE EDIT    * 00550020
*    SUBCOMMANDS- FORMAT, MERGE, RUN, AND HELP. THE APPROPRIATE CP IS * 00600020
*    ATTACHED BY IKJEBECI.                                            * 00650020
*                                                                     * 00800020
* ENTRY POINTS --                                                     * 00830020
*         IKJEBECI - MAIN ENTRY POINT                                 * 00860020
*         STAIEXIT - STAI EXIT ROUTINE                                * 00890020
*         STAEEXIT - STAE EXIT ROUTINE                                * 00920020
*         STAERTRY - STAE RETRY ROUTINE                               * 00950020
*                                                                     * 01200020
* INPUT -- REGISTER 1 CONTAINS A POINTER TO A PARAMETER LIST WHICH    * 01250020
*    CONTAINS IN WORD ONE A POINTER TO THE COMMUNICATION AREA, AND IN * 01300020
*    WORD TWO A POINTER TO A COMMAND BUFFER.                          * 01350020
*                                                                     * 01600020
* OUTPUT -- RETURN CODE IN REGISTER 15.                               * 01700020
*    0 -- SUCCESSFUL COMPLETION                                       * 01800020
*    8 -- UNSUCCESSFUL COMPLETION                                     * 01802020
*                                                                     * 01804020
* EXTERNAL REFERENCES --                                              * 01810020
*         IKJEBEMS    - MESSAGES TO USER                              * 01820020
*         IKJPTGT     - READ IN-CORE COMMANDS                         * 01830020
*         IKJSTCK     - UNSTACK IN-CORE SOURCE OF INPUT               * 01840020
*         IKJDAIR     - CLEAN-UP OF DSE                               * 01850020
*         IKJSCAN     - SCAN COMMAND NAME                             * 01860020
*         MACROS USED -                                               * 01870020
*         GETMAIN     OBTAIN STACK AND LSD AREAS                      * 01880020
*         FREEMAIN    - FREE SUBPOOL 1 AND 78 CORE                    * 01890020
*         ATTACH      - ATTACH COMMAND PROCESSORS                     * 01900020
*         STAE        - ABNORMAL END EXIT                             * 01910020
*         LINK        CALL IKJSCAN                                    * 01920020
*         WAIT        WAIT ON SUBTASK COMPLETION OR ATTENTION         * 01930020
*         STATUS      - MAKE SUBTASKS NON-DISPATCHABLE                * 01940020
*         TCLEARQ     - CLEAR INPUT QUEUE                             * 01950020
*                                                                     * 03300020
* EXITS, NORMAL -- THIS PROGRAM EXITS NORMALLY WITH A RETURN CODE OF  * 03360020
*    0 IN REGISTER 15.                                                * 03420020
*                                                                     * 03600020
* EXITS, ERROR -- THIS PROGRAN EXITS WITH A RETURN CODE OF 4 IN       * 03660020
*    REGISTER 15 FOR MERGE OR GOFORT ONLY.                            * 03720020
*                                                                     * 03900020
* TABLES/WORK AREAS --                                                * 03940020
*    IKJEBECA - EDIT COMMUNICATION AREA                               * 03980020
*    ABENDTAB - TRANSLATE TABLE FOR ABEND CODE                        * 04020020
*    CIRCTAB  - PRINTABLE CHARACTER RETURN CODES                      * 04060020
*                                                                     * 04300020
* ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                  * 04400020
*                                                                     * 04500020
* CHARACTER CODE DEPENDENCY -- NONE                                   * 04530020
*                                                                     * 04560020
* NOTES -- STANDARD CONVENTIONS EXCEPT IN STAI EXIT WHRRE ADDRESS-    * 04590020
*    ABILITY BASED ON REGISTER 15, NO SAVE AREAS AVAILABLE, AND ONLY  * 04620020
*    REGISTERS 0, 1, 14, 15 PREDICTABLE.                              * 04650020
*                                                                     * 05000020
*    THIS ROUTINE IS DESCRIBED IN PLM GY28-6773                       * 05010020
*                                                                     * 05050020
*********************************************************************** 05100020
         EJECT                                                          05200020
IKJEBECI CSECT                                                          05300020
*A085500,234100-234800                                          SA56859 05303021
*C235000                                                        SA56859 05306021
*A143100-143600                                                  A42942 05350021
*D685000-687000                                                  A45716 05370021
*D142000                                                         A45112 05372021
*C363000                                                         A50463 05380021
*A489500-490000                                                  A50473 05385021
*C489000                                                         A50473 05390021
*D478000-488000                                                  A50473 05395021
*A585100,625500,745100-745998                                     M5143 05395321
*D585000-591000                                                   M5143 05395421
*********************************************************************** 05400020
*                                                                     * 05500020
*                          REGISTER EQUATES                           * 05600020
*                                                                     * 05700020
*********************************************************************** 05800020
         SPACE 2                                                        05900020
PARMREG0 EQU   0                  REGISTERS 0 AND 1 USED TO PASS        06000020
PARMREG1 EQU   1                  PARAMETERS                            06100020
WORKREG1 EQU   2                  REGISTER 2 USED AS WORK REG           06200020
WORKREG2 EQU   3                  REGISTER 3 USED AS WORK REG           06300020
DSECTREG EQU   4                  BASE REGISTER FOR MAPPING DSECTS      06400020
MSGREG   EQU   6                  BASE REGISTER FOR MESSAGE CSECT       06500020
COMMREG  EQU   9                  BASE REGISTER FOR IKJEBECA DSECT      07000020
DATAREG  EQU   12                 WORK REGISTER                         07100020
BASEREG  EQU   11                 BASE REGISTER FOR PROGRAM             07200020
SAVEREG  EQU   13                 ADDRESS OF SAVE AREA                  07300020
RETREG   EQU   14                 ADDRESS OF RETURN POINT OF CALLER     07400020
RETCDREG EQU   15                 BRANCH AND RETURN CODE REGISTER       07500020
ENTRY    EQU   15                 ADDRESS OF ENTRY POINTS               07600020
         EJECT                                                          07700020
*********************************************************************** 07800020
*                                                                     * 07900020
*                           SPECIAL EQUATES                           * 08000020
*                                                                     * 08100020
*********************************************************************** 08200020
         SPACE 2                                                        08300020
ALLBITS  EQU   X'FF'              BIT MASK                              08400020
HIORDBIT EQU   X'80'              BIT MASK                              08500020
OPERANDS EQU   X'80'              OPERANDS PRESENT IN CMD BUF   SA56859 08550021
COMPLETE EQU   X'40'              ECB COMPLETE BIT - WAIT POSTED IF ON  08600020
ZONEBITS EQU   X'0F'              EBCDIC CHARACTER ZONE BITS            08700020
CLEANDSE EQU   X'2C'              ENTRY CODE TO IKJDAIR                 08800020
RETCD8   EQU   8                  UNSUCCESSFUL RC                       08900020
BITS20   EQU   20                 SHIFT OF 20 BITS                      09000020
BITS16   EQU   16                 SHIFT OF 16 BITS                      09020020
BITS12   EQU   12                 SHIFT OF 12 BITS                      09050020
BITS4    EQU   4                  SHIFT OF 4 BITS                       09100020
OFFSET0  EQU   0                  DISPLACEMENT OF 0                     09200020
OFFSET1  EQU   1                  DISPLACEMENT OF 1                     09300020
OFFSET2  EQU   2                  DISPLACEMENT OF 2                     09400020
OFFSET3  EQU   3                  DISPLACEMENT OF 3                     09500020
OFFSET4  EQU   4                  DISPLACEMENT OF 4                     09600020
OFFSET5  EQU   5                  DISPLACEMENT OF 5                     09700020
OFFSET6  EQU   6                  DISPLACEMENT OF 6                     09760020
OFFSET7  EQU   7                  DISPLACEMENT OF 7                     09820020
OFFSET12 EQU   12                 DISPLACEMENT OF 12                    09950020
LEN1     EQU   1                  LENGTH OF 1                           10020020
LEN2     EQU   2                  LENGTH OF 2                           10100020
LEN3     EQU   3                  LENGTH OF 3                           10200020
LEN4     EQU   4                  LENGTH OF 4                           10300020
LEN6     EQU   6                  LENGTH OF 6                           10350020
LEN7     EQU   7                  LENGTH OF 7                           10400020
LEN8     EQU   8                  LENGTH OF 8                           10500020
STAICODE EQU   16                 RETURN CODE FROM STAI EXIT            10600020
STAECODE EQU   4                  RETURN CODE FROM STAE EXIT            10630020
CCX3E    EQU   X'3E'              DETACH ABEND CODE                     10660020
SP01     EQU   1                  SUBPOOL NUMBER                        10700020
SP78     EQU   78                 SUBPOOL NUMBER                        10800020
CHAR0    EQU   C'0'               EBCDIC CHARACTER ZERO                 10900020
BLANK    EQU   C' '               EBCDIC CHARACTER BLANK                11000020
CIOPCD   EQU   X'02'              OPTION CODE FOR DAIR 2C               11030020
K48      EQU   48                 BYTE LENGTH OF MSG PARMLIST           11060020
         EJECT                                                          11100020
*********************************************************************** 11200020
*                                                                     * 11300020
*                      EXECUTABLE CODE                                * 11400020
*                                                                     * 11500020
*********************************************************************** 11600020
         SPACE 2                                                        11700020
* SAVE CALLER'S REGISTERS, ESTABLISH PROGRAM ADDRESSIBILITY,            11800020
*     AND CHAIN SAVE AREA POINTERS                                      11900020
         IKJEBESV (14,12),,*,COMMREG=OFFSET0(PARMREG1)                  12000020
*                                 ESTABLISH ADDRESSIBILITY              12100020
         USING IKJEBECA,COMMREG   TO COMMUNICATION AREA DSECT           12200020
         MVC   CICMDBFR(LEN4),OFFSET4(PARMREG1) SAVE PTR TO COMMAND BUF 12300020
         XC    CIRETCD,CIRETCD    INIT RETURN CODE TO ZERO              12400020
         NI    FREEBIT,ALLBITS-HIORDBIT INIT FREEMAIN SWITCH OFF        12600020
         MVC   CMDBUFF+OFFSET1(LEN3),CICMDBFR+OFFSET1 PTR TO COMMAND    12700020
         EJECT                                                          13000020
*********************************************************************** 13100020
*                                                                     * 13200020
*        BUILD ECB LIST FOR WAIT ON ATTACH WITH STAI AND ATTENTION    * 13300020
*                                                                     * 13400020
*********************************************************************** 13500020
         SPACE 2                                                        13600020
         LA    WORKREG1,CAATTN    INIT ADDRESS OF ATTENTION             13700020
         ST    WORKREG1,CIECBATT  ECB IN ECB LIST                       13800020
         LA    WORKREG1,CINORECB  INIT ADDRESS OF NORMAL RETURN         13900020
         ST    WORKREG1,CIECBNOR  ECB IN ECB LIST                       14000020
         OI    CIECBNOR,HIORDBIT  SET BIT TO MARK END OF ECB LIST       14100020
         SPACE 2                                                        14300020
         L     DSECTREG,CAPTECT   ADDRESS OF ECT                 A42942 14350021
         USING ECT,DSECTREG       ADDRESSABILITY                 A42942 14360021
         XC    ECTRTCD,ECTRTCD    ZERO ECT RETURN CODE FIELD     A42942 14370021
         NI    ECTRCDF,ALLBITS-HIORDBIT  ZERO ABEND OCCURRED BIT A42942 14380021
         NI    SAVEBIT,ALLBITS-HIORDBIT INIT SWITCH FOR REG SAVE        14400020
         NI    ABENDBIT,ALLBITS-HIORDBIT INIT CP ABEND SWITCH OFF       14500020
         NI    STAEBIT,ALLBITS-HIORDBIT INIT STAE IN EFFECT SWITCH OFF  14550020
         XC    MSGPLIST(K48),MSGPLIST ZERO MESSAGE PARMLIST             14560020
         L     MSGREG,CIMSGADR    ADDR OF MESSAGE CSECT                 14570020
         USING IKJEBCIM,MSGREG    ESTABLISH ADDRESSABILITY              14580020
         EJECT                                                          14600020
*********************************************************************** 14602020
*                                                                     * 14604020
*        ISSUE  STAE MACRO TO INTERCEPT  X3E ABENDS CAUSED BY         * 14606020
*        DETACHING A SUBTASK THAT HAS NOT COMPLETED AND AN ATTENTION  * 14608020
*        HAS BEEN ISSUED                                              * 14610020
*                                                                     * 14612020
*********************************************************************** 14614020
         SPACE 2                                                        14616020
         MVC   STAELIST(STAELEN),STAELFM MOVE LIST FORM TO PARMLIST     14616420
         STM   COMMREG,SAVEREG,REGSAVE SAVE REGS FOR RETRY RTN          14618020
         STAE  ,CT,PARAM=(COMMREG),XCTL=NO,MF=(E,STAELIST)              14620020
         SPACE 2                                                        14622020
         B     STAERCTB(RETCDREG) CHECK RETURN CODES FROM STAE          14624020
         SPACE                                                          14626020
* STAE MACRO BRANCH TABLE                                               14628020
         SPACE                                                          14630020
STAERCTB EQU   *                                                        14632020
         B     STAESUCC           IF RC = 0, SUCCESSFUL RETURN          14634020
         B     NOCORE             IF RC = 4, NO CORE AVAILABLE          14634220
         B     STAEMVC            IF RC = 8, LOGIC ERROR                14634420
         B     STAEMVC            IF RC =12, LOGIC ERROR                14634620
         B     STAEMVC            IF RC =16, LOGIC ERROR                14634820
         SPACE                                                          14635020
STAEMVC  EQU   *                                                        14635220
         MVC   INSERT1(MSG4LEN),CIMSG4 SET UP SERVICE ROUTINE INSERT    14635420
         BAL   RETREG,FORM313A    SET UP PARMLIST                       14635620
         B     GOSEND             SEND MSG                              14635820
         SPACE                                                          14636020
NOCORE   EQU   *                                                        14636220
         BAL   RETREG,NOCORMSG    SET UP PARMLIST                       14636420
GOSEND   BAL   RETREG,SENDMSG     NOTIFY USER                           14636620
         B     MSGSENT            RETURN TO CALLER                      14676020
         SPACE 2                                                        14678020
STAESUCC EQU   *                                                        14680020
         OI    STAEBIT,HIORDBIT   INDICATE STAE EXIT IN EFFECT          14682020
         EJECT                                                          14684020
*********************************************************************** 14700020
*                                                                     * 14800020
*              DETERMINE IF COMMAND IN SYSTEM                         * 14900020
*                                                                     * 15000020
*********************************************************************** 15100020
         SPACE 2                                                        15200020
*  CALL IKJSCAN TO SCAN OFF COMMAND NAME                                15300020
         SPACE                                                          15400020
NEXTCMD  EQU   *                                                        15500020
         XC    SCANFLAG(L'SCANFLAG),SCANFLAG ZERO OUT FLAG FIELD        15700020
         LA    PARMREG1,CATMPLST                                        15800020
         USING CSPL,PARMREG1      ESTAB ADDR. TO CMD SCAN PARMLIST      15900020
         LA    DSECTREG,SCANOUT                                         16000020
         USING CSOA,DSECTREG      ESTAB ADDR. TO CMD SCAN PARMBLOCK     16100020
         LA    WORKREG1,SCANFLAG                                        16200020
         ST    WORKREG1,CSPLFLG   PTR TO FLAG FIELD                     16300020
         XC    CSOA(CSOALEN),CSOA ZERO OUT OUTPUT AREA                  16400020
         ST    DSECTREG,CSPLOA    INIT PTR TO OUTPUT AREA               16500020
         XC    CSPLCBUF(L'CSPLCBUF),CSPLCBUF ZERO BUFFER PTR FIELD      16560020
         MVC   CSPLCBUF+OFFSET1(LEN3),CMDBUFF+OFFSET1 INIT PTR TO BFR   16620020
         XC    LINKLIST(LEN8),LINKLIST ZERO OUT LFORM OF LINK           16700020
         LA    RETCDREG,LINKLIST   PTR TO LFORM                         16800020
         LINK  EP=IKJSCAN,DCB=0,MF=(E,(1)),SF=(E,(15))                  16900020
         B     CSRCTAB(RETCDREG)  BRANCH INDEXED BY RC                  17000020
         SPACE                                                          17100020
* IKJSCAN BRANCH TABLE                                                  17200020
         SPACE                                                          17300020
CSRCTAB  EQU   *                                                        17400020
         B     VALIDRC            IF RC=0, VALID COMMAND                17500020
         B     ERROR1A            IF RC=4, INVALID PARMS                17600020
         B     NOCOR              IF RC=8, NO SPACE AVAILABLE           17700020
         SPACE                                                          17800020
* VALID COMMAND NAME IN COMMAND BUFFER                                  17900020
         SPACE                                                          18000020
VALIDRC  EQU   *                                                        18100020
         TM    CSOAFLG,CSOAQM+CSOANOC+CSOABAD CHECK IF                  18200020
*                                 VALID COMMAND NAME                    18300020
         BZ    VALIDCMD           IF YES, BRANCH TO PROCESS             18400020
         B     ERROR3A            IF NO, NOT COMMAND                    18500020
         SPACE 2                                                        18600020
ERROR1A  EQU   *                                                        18700020
         MVC   INSERT1(MSG9LEN),CIMSG9 SET UP SERVICE ROUTINE INSERT    18800020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       18900020
         B     CLEANUP            RETURN TO CALLER                      19300020
         SPACE 2                                                        19400020
NOCOR    EQU   *                                                        19800020
         BAL   RETREG,NOCORMSG    SET UP PARMLIST                       20200020
         B     CLEANUP            RETURN TO CALLER                      21000020
         SPACE 2                                                        21100020
ERROR3A  EQU   *                                                        21200020
         MVC   INSERT1(MSG9LEN),CIMSG9 SET UP SERVICE ROUTINE INSERT    21230020
         MVC   INSERT2(CIFLGLEN),CIFLG SET UP FLAGS INSERTION           21260020
         SR    WORKREG1,WORKREG1                                        21300020
         IC    WORKREG1,CSOAFLG-CSOA(DSECTREG) FLAG BYTE RETURNED       21400020
         SLL   WORKREG1,BITS4                                           21500020
         ST    WORKREG1,COMPCODE                                        21600020
         OI    COMPCODE+OFFSET3,ZONEBITS   MOVE IN ZONE SIGN            21700020
         UNPK  INSRT2+OFFSET6(LEN2),COMPCODE+OFFSET2(LEN2)              21760020
         TR    INSRT2+OFFSET6(LEN2),ABENDTAB-CHAR0 TRANSLATE FLAGS      21820020
         BAL   RETREG,FORM313B    SET UP PARMLIST                       22320020
         B     CLEANUP            RETURN TO CALLER                      23200020
         EJECT                                                          23240020
*********************************************************************** 23280020
*  DO BLDL TO DETERMINE IF COMMAND IS IN SYSTEM                       * 23320020
*********************************************************************** 23360020
VALIDCMD EQU   *                                                        23400020
         L     WORKREG2,CAPTECT   LOAD PTR TO ECT               SA56859 23410021
         USING ECT,WORKREG2                                     SA56859 23420021
         TM    CSOAFLG,CSOAVWP    COMMAND CONTAIN OPERANDS?     SA56859 23430021
         BZ    NOOPANDS           IF NO, MARK AS SUCH IN ECT    SA56859 23440021
         NI    ECTSWS,ALLBITS-OPERANDS     MARK THAT OPS        SA56859 23450021
*                                 ARE PRESENT ON COMMAND        SA56859 23460021
         B     DOBLDL             BEGIN BLDL PROCESSING         SA56859 23470021
NOOPANDS OI    ECTSWS,OPERANDS    MARK NO OPERANDS PRESENT      SA56859 23480021
DOBLDL   LA    WORKREG1,OFFSET1                                 SA56859 23500021
         STH   WORKREG1,BLDLNO    NUMBER OF BLDL ENTRIES                23600020
         LA    WORKREG1,ENTRYLEN                                        23650020
         STH   WORKREG1,BLDLLEN   LENGTH OF EACH ENTRY                  23700020
         MVI   BLDLNAME,BLANK                                           23750020
         MVC   BLDLNAME+OFFSET1(LEN7),BLDLNAME BLANK OUT FIELD          25200020
         L     WORKREG1,CSOACNM   PTR TO CMD NAME                       25300020
         LH    WORKREG2,CSOALNM   LENGTH OF CMD NAME                    25400020
         BCTR  WORKREG2,PARMREG0  DECREMENT BY ONE TO EXEC MVC          25500020
         EX    WORKREG2,BLDLMOVE  MOVE COMMAND NAME                     25600020
         BLDL  0,BLDLIST          BLDL ON COMMAND NAME                  25800020
         B     BLDLRCTB(RETCDREG)  BRANCG INDEXED BY RET CODE           25900020
         SPACE 2                                                        26000020
BLDLMOVE MVC   BLDLNAME(*-*),OFFSET0(WORKREG1)                          26100020
         SPACE 2                                                        26200020
BLDLRCTB EQU   *                                                        26300020
         B     RUNTEST            IF RC = 0, SUCCESSFUL RETURN          26400020
         B     CMDNOTFD           IF RC = 4, CMD NOT FOUND              26500020
         B     BLDLIOER           IF RC = 8, IO ERROR OCCURRED          26600020
         SPACE 2                                                        26700020
CMDNOTFD EQU   *                                                        26800020
         BAL   RETREG,CMDNFD      SET UP PARMLIST                       27300020
         B     CLEANUP            BRANCH TO TERMINATE                   28100020
         SPACE 2                                                        28200020
BLDLIOER EQU   *                                                        28300020
         MVC   INSERT1(MSG7LEN),CIMSG7 SET UP SERVICE ROUTINE INSERT    28400020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       28500020
         B     CLEANUP            BRANCH TO TERMINATE                   28900020
         EJECT                                                          28940020
*********************************************************************** 28980020
*  IF CALLER IS RUN, DO GETMAIN FOR LSD AREA AND STACK THE ELEMENT    * 29020020
*********************************************************************** 29060020
RUNTEST  EQU   *                                                        29100020
         CLC   BLDLNAME(L'RUNSC),RUNSC  CHECK IF RUN CALLER             29200020
         BNE   BUILDPLT           IF NO, BRANCH TO BUILD                29300020
*                                 PARMLIST FOR ATTACH                   29400020
         XC    FREELIST(LEN8),FREELIST ZERO LIST FORM                   29500020
         LA    WORKREG1,GETPTR        ADDR OF GETMAIN AREA              29600020
         LA    PARMREG1,FREELIST      PTR TO LIST FORM                  29700020
         GETMAIN EC,LV=LSDLEN+DATALEN,A=(WORKREG1),SP=SP78,MF=(E,(1))   29800020
         LTR   RETCDREG,RETCDREG      CHECK IF GETMAIN SUCCESSFUL       29900020
         BNZ   NOCORE                 IF NO, BRANCH - PUT OUT MESSAGE   29970020
         LA    DSECTREG,CISTCKLF                                        31600020
         USING STPB,DSECTREG          ESTAB. ADDR. TO PARMBLOCK         31700020
         XC    STPB(STPBLEN),STPB     ZERO IKJSTACK PARMBLOCK           31800020
         L     WORKREG2,GETPTR        ADDR. OF LSD AREA                 31900020
         USING LSD,WORKREG2           ESTAB. ADDR. TO LSD AREA          32000020
         MVC   ENDMARK(DATALEN),EODCODE MOVE DATA INTO AREA             32100020
         LA    WORKREG1,ENDMARK       PTR TO IN-CORE DATA               32200020
         ST    WORKREG1,LSDADATA      BEGINNING OF DATA                 32300020
         ST    WORKREG1,LSDANEXT      FIRST RECORD OF DATA              32400020
         LA    WORKREG1,DATALEN       LENGTH OF DATA                    32500020
         STH   WORKREG1,LSDRCLEN      RECORD LENGTH                     32600020
         STH   WORKREG1,LSDTOTLN      TOTAL LENGTH OF DATA AREA         32700020
         XC    LSDRSVRD(L'LSDRSVRD),LSDRSVRD ZERO RESERVED AREA         32800020
         LA    PARMREG1,CATMPLST      PTR TO TMP PARMLIST               32900020
         STACK PARM=STPB,STORAGE=((WORKREG2),SOURCE),MF=(E,(1))         33000020
         LTR   RETCDREG,RETCDREG      CHECK IF STACK SUCCESSFUL         33100020
         BZ    BUILDPLT               IF YES, BRANCH-BUILD PARMLST      33200020
         MVC   INSERT1(MSG8LEN),CIMSG8 SET UP SERVICE ROUTINE INSERT    33300020
         BAL   RETREG,FORM313A        SET UP PARMLIST                   33400020
         BAL   RETREG,SENDMSG         NOTIFY USER                       33600020
         MVC   FREEAREA(L'GETPTR),GETPTR PTR TO LSD AND STACK           33700020
         LA    WORKREG1,LSDLEN+DATALEN LENGTH OF AREA TO BE FREED       33800020
         ST    WORKREG1,FREEAREA+OFFSET4                                33900020
         LA    WORKREG1,FREEAREA      PTR TO AREA TO BE FREED           34000020
         XC    FREELIST(LEN8),FREELIST ZERO LIST FORM                   34100020
         FREEMAIN V,A=(WORKREG1),SP=SP78,MF=(E,(1))                     34200020
         B     MSGSENT                RETURN TO CALLER                  34300020
         EJECT                                                          34400020
* BUILD TMP-LIKE PARAMETER LIST FOR ATTACHED COMMAND PROCESSOR          34500020
BUILDPLT MVC   CIATTACH(ATTACHLN),ATTACHLT                              34600020
         XC    CINORECB(L'CINORECB),CINORECB ZERO NORM. ECB             34700020
         LA    WORKREG1,CINORECB      MODULE NAME AND ADDRESS OF        34800020
         ST    WORKREG1,CIATHECB      ATTACH ECB                        34900020
         L     DSECTREG,CAPTTMP       ESTABLISH ADDRESSIBILITY TO CMD   35000020
         USING CPPL,DSECTREG          PROCESSOR PARAMETER LIST          35100020
         MVC   CITMPLST+CPPLCBUF-CPPL(L'CMDBUFF),CMDBUFF MOVE PTR TO    35200020
*                                     COMMAND BUFFER INTO PARMLIST      35300020
         MVC   CITMPLST+CPPLUPT-CPPL(L'CPPLUPT),CPPLUPT MOVE PTR TO     35400020
*                                     UPT INTO PARMLIST                 35500020
         MVC   CITMPLST+CPPLPSCB-CPPL(L'CPPLPSCB),CPPLPSCB MOVE PTR TO  35600020
*                                     PSCB INTO PARMLIST                35700020
         MVC   CITMPLST+CPPLECT-CPPL(L'CPPLECT),CPPLECT MOVE PTR TO     35800020
*                                     ECT INTO PARMLIST                 35900020
         LA    RETCDREG,CIATTACH                                        36000020
         LA    PARMREG1,CITMPLST                                        36100020
* ATTACH WITH STAI EXIT APPROPRIATE COMMAND PROCESSOR                   36200020
         ATTACH DE=BLDLNAME,MF=(E,(1)),SF=(E,(15)),SZERO=NO,     A50463X36300021
               STAI=(STAIEXIT,STAIPLST)                                 36400020
         SPACE                                                          36450020
         LTR   RETCDREG,RETCDREG      IS RC = 0                         36460020
         BNZ   NOCOR                  BR NO TO PUT OUT MESSAGE          36470020
         ST    PARMREG1,CITCBPTR      SAVE TCB PTR FOR DETACH           36500020
         EJECT                                                          36600020
* WAIT ON COMPLETION OF ANY ONE OF THE FOLLOWING EVENTS                 36700020
*             - NORMAL RETURN FROM THE SUB-TASK                         36800020
*             - ISSUANCE OF AN ATTENTION INTERRUPT                      36900020
         SPACE 2                                                        37000020
         WAIT  ECBLIST=CIECBLST                                         37100020
         SPACE 2                                                        37200020
         TM    CINORECB,COMPLETE      CHECK IF NORMAL RETURN            37300020
         BNO   ATTNISSU               IF NO, BRANCH-ATTENTION           37400020
         L     WORKREG1,CAPTTMP       GET TMP PARM LIST ADDR            37500020
         L     DSECTREG,CPPLECT-CPPL(WORKREG1) GET ECT ADDR             37600020
         USING ECT,DSECTREG                                             37700020
         TM    ABENDBIT,HIORDBIT      CHECK IF STAI EXIT USED           37800020
         BNZ   CPABEND                IF YES, BRANCH-ISSUE MSG          37900020
         MVC   ECTRTCD(LEN3),CINORECB+OFFSET1 SAVE CC                   38000020
         OC    CINORECB+OFFSET1(LEN3),CINORECB+OFFSET1                  38500020
         BZ    UNALLOC                IF YES, BRANCH-RC=0               38600020
         LA    WORKREG1,RETCD8                                          38700020
         ST    WORKREG1,CIRETCD       SET RETURN CODE OF 8              38800020
UNALLOC  EQU   *                                                        38900020
         DETACH CITCBPTR              DETACH SUB-TASK                   39000020
         BAL   RETREG,CALLDAIR        CALL IKJDAIR FOR DSE CLEAN UP     39100020
         LTR   RETCDREG,RETCDREG      CHECK IF SUCCESSFUL               39200020
         BNZ   UNSTK                  IF NO, RETURN TO CALLER           39300020
         L     WORKREG1,CICMDBFR                                        39400020
         CLC   OFFSET4(L'RUNSC,WORKREG1),RUNSC CHECK IF 'RUN' CALLER    39500020
         BNE   NOTRUN                 IF NO, CLEAN UP AND EXIT          39600020
         TM    FREEBIT,HIORDBIT       CHECK IF AREA TO BE FREEMAINED    39700020
         BZ    NOFRBFR                IF NO, BY-PASS FREEMAIN           39800020
         L     WORKREG1,CMDBUFF       PTR TO AREA TO BE FREED           39900020
         ST    WORKREG1,FREEAREA      MOVE INTO FREEMAIN LIST           40000020
         LH    WORKREG1,OFFSET0(WORKREG1) LENGTH OF AREA                40100020
         ST    WORKREG1,FREEAREA+OFFSET4 MOVE INTO FREEMAIN LIST        40200020
         LA    WORKREG1,FREEAREA      PTR TO FREEMAIN LIST              40300020
         XC    FREELIST(LEN8),FREELIST ZERO OUT LFORM                   40400020
         LA    PARMREG1,FREELIST      PTR TO LFORM                      40500020
         FREEMAIN V,A=(WORKREG1),SP=SP01,MF=(E,(1)) FREEMAIN BUFFER     40600020
         NI    FREEBIT,ALLBITS-HIORDBIT SET FREEMAIN SW OFF             40700020
NOFRBFR  EQU   *                                                        40800020
* ISSUE PUTGET TO READ IN-CORE COMMAND BUILT BY RUN CP                  40900020
         LA    DSECTREG,CIGETLFM  ESTABLISH ADDRESSIBILITY TO PUTGET    41000020
         USING PGPB,DSECTREG      PARAMETER BLOCK                       41100020
         XC    PGPB(PGPBLEN),PGPB ZERO OUT PARM BLOCK                   41200020
         ST    DSECTREG,CATMPLST+IOPLIOPB-IOPL SET PT TO PARM BLOCK     42400020
         LA    PARMREG1,CATMPLST                                        42500020
         PUTGET ,OUTPUT=(CAMODEMG,SINGLE,MODE),TERMGET=(EDIT,WAIT),    X42600020
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),MF=(E,(1))            42700020
         B     RETCDTAB(RETCDREG) CHECK RETURN CODES                    42800020
         SPACE                                                          42900020
*  PUTGET RETURN CODE BRANCH TABLE                                      43000020
         SPACE                                                          43100020
RETCDTAB EQU   *                                                        43200020
         B     TERMLINE           IF RC = 0, STACK FLUSHED              43300020
         B     NORMRET            IF RC = 4, SUCCESSFUL RETURN          43400020
         B     MAINEXIT           IF RC = 8, ATTENTION ISSUED           43500020
         B     SECLEV             IF RC =12, 2ND LEVEL PRESENT          43600020
         B     PTGTMVC            IF RC =16, LOGIC ERROR                43620020
         B     PTGTMVC            IF RC =20, LOGIC ERROR                43640020
         B     PTGTMVC            IF RC =24, LOGIC ERROR                43660020
         B     NOCOR              IF RC =28, NO SPACE AVAILABLE         43680020
         SPACE                                                          43700020
PTGTMVC  EQU   *                                                        43720020
         MVC   INSERT1(MSG10LEN),CIMSG10 SET UP SERVICE ROUTINE INSERT  43740020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       43760020
         B     CLEANUP            RETURN TO CALLER                      45800020
         SPACE 2                                                        45900020
         EJECT                                                          47600020
TERMLINE EQU   *                                                        47700020
         MVC   CAPTNBFR(L'CAPTNBFR),CIGETLFM+PGPBIBUF-PGPB PLACE A50473 48900021
*                                 NEW SUBCOMMAND ADDRESS IN      A50473 48950021
*                                 COMMUNICATION AREA             A50473 49000021
         B     MAINEXIT           RETURN TO CALLER                      49100020
         EJECT                                                          49200020
* DETERMINE IF SECOND LEVEL MESSAGE IS INFORMATIONAL OR DIAGNOSTIC      49300020
         SPACE 2                                                        49400020
SECLEV   EQU   *                                                        49500020
* CHECK IF SUCCESSFUL RETURN CODE FROM SUBTASK                          49600020
         OC    CINORECB+OFFSET1(LEN3),CINORECB+OFFSET1                  49700020
         BZ    CONTPRCS           IF YES, MSG INFORMATIONAL             49800020
         LA    DSECTREG,CISTCKLF                                        49900020
         USING STPB,DSECTREG      ESTAB ADDR. FOR STACK PARMBLOCK       50000020
         XC    STPB(STPBLEN),STPB ZERO OUT PARM BLOCK                   50100020
         LA    PARMREG1,CATMPLST  PTR TO STACK PARMLIST                 50200020
         USING STPL,PARMREG1      ESTAB ADDR. FOR STACK PARMLIST        50300020
         ST    DSECTREG,STPLSTPB  PTR TO PARMBLOCK IN PARMLIST          50400020
         STACK DELETE=ALL,MF=(E,(1)) ISSUE STACK MACRO                  50500020
         LTR   RETCDREG,RETCDREG  CHECK IF SUCCESSFUL RETURN            50600020
         BZ    MAINEXIT           IF YES, RETURN TO CALLER              50700020
         MVC   INSERT1(MSG8LEN),CIMSG8 SET UP SERVICE ROUTINE INSERT    50740020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       50780020
         B     GOSEND             SEND MSG                              50820020
         SPACE                                                          50860020
         SPACE 2                                                        50900020
CONTPRCS EQU   *                                                        51000020
         L     DSECTREG,CAPTTMP                                         51100020
         L     DSECTREG,CPPLECT-CPPL(DSECTREG) PTR TO ECT               51200020
         USING ECT,DSECTREG       ESTAB ADDR. TO ECT                    51300020
         OI    ECTMSGF,HIORDBIT   SET BIT TO FLUSH SEC LEVEL            51400020
         LA    WORKREG2,CIGETLFM                                        51500020
         USING PGPB,WORKREG2      ESTAB ADDR. TO PARMBLOCK              51600020
         XC    PGPB(PGPBLEN),PGPB ZERO OUT PARM BLOCK                   51700020
         ST    WORKREG2,CATMPLST+IOPLIOPB-IOPL SET PT TO PARM BLOCK     52900020
         LA    PARMREG1,CATMPLST                                        53000020
         PUTGET ,OUTPUT=(CAMODEMG,SINGLE,MODE),TERMGET=(EDIT,WAIT),    X53100020
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),MF=(E,(1))            53200020
         NI    ECTMSGF,ALLBITS-HIORDBIT SET MSG BIT OFF                 53300020
         B     RETCDTAB(RETCDREG) CHECK RETURN CODE                     53600020
         EJECT                                                          53900020
* DETERMINE APPROPRIATE COMMAND PROCESSOR TO ATTACH FOR 'RUN'           54000020
NORMRET  EQU   *                                                        54100020
         NI    CACFLAG4,ALLBITS-CAINPROC  SET PROC BIT OFF              54150020
         OI    FREEBIT,HIORDBIT   SET ON AREA TO BE FREED               54200020
         L     WORKREG1,CIGETLFM+PGPBIBUF-PGPB                          54300020
         ST    WORKREG1,CMDBUFF   PTR TO CMD TO BE PROCESSED            54400020
         CLC   OFFSET4(DATALEN,WORKREG1),EODCODE CHECK IF EOD           54500020
         BNE   NEXTCMD            IF NO, CONTINUE PROCESS               54600020
         OI    CACFLAG2,CAMODMSG  INDICATE MODE MSG TO BE PUT OUT       55600020
         B     MAINEXIT           RETURN TO CALLER                      56600020
         EJECT                                                          58300020
CLEANUP  EQU   *                                                        58400020
         BAL   RETREG,SENDMSG     NOTIFY USER                           58430020
UNSTK    EQU   *                                                        58460020
         BAL   WORKREG1,UNSTACK   DELETE THE INPUT STACK          M5143 58510021
MSGSENT  EQU   *                                                        60100020
         LA    WORKREG1,RETCD8    SET RETURN CODE = 8                   60140020
         ST    WORKREG1,CIRETCD                                         60150020
MAINEXIT EQU   *                                                        60200020
* IF CALLER IS RUN, FREEMAIN THE COMMAND BUFFER                         60250020
         TM    FREEBIT,HIORDBIT   CHECK IF BFR TO BE FREED              60300020
         BZ    NOTRUN             IF NO, BY-PASS FREEMAIN               60400020
         L     WORKREG1,CMDBUFF   PTR TO IN-CORE CMD BUFFER             60500020
         ST    WORKREG1,FREEAREA                                        60600020
         LH    WORKREG1,OFFSET0(WORKREG1) LENGTH OF BUFFER              60700020
         ST    WORKREG1,FREEAREA+OFFSET4                                60800020
         LA    WORKREG1,FREEAREA  PTR TO AREA TO BE FREED               60900020
         XC    FREELIST(LEN8),FREELIST ZERO LIST FORM                   61000020
         LA    PARMREG1,FREELIST  PTR TO LIST FORM                      61100020
         FREEMAIN V,A=(WORKREG1),SP=SP01,MF=(E,(1))                     61200020
NOTRUN   EQU   *                                                        61300020
         TM    STAEBIT,HIORDBIT   CHECK IF STAE IN EFFECT               61310020
         BZ    NOSTAE             IF NO, BY-PASS STAE CANCEL            61320020
         STAE  0,MF=(E,STAELIST)                                        61330020
         LTR   RETCDREG,RETCDREG  CHECK IF STAE CANCEL SUCCESSFUL       61340020
         BZ    NOSTAE             IF YES, CONTINUE TO EXIT              61350020
         NI    STAEBIT,ALLBITS-HIORDBIT SET STAE IN EFFECT SWITCH OFF   61360020
         B     STAERCTB(RETCDREG) CHECK FOR NONZERO RETURN CODE         61370020
         SPACE                                                          61380020
NOSTAE   EQU   *                                                        61390020
         L     RETCDREG,CIRETCD   MOVE RETURN CODE INTO REG 15          61400020
         IKJEBERT (14,12),,RC=(15)                                      61500020
         EJECT                                                          61600020
* ATTENTION ECB POSTED - ATTENTION ISSUED                               61700020
ATTNISSU EQU   *                                                        61800020
         STATUS STOP              MAKE ALL SUBTASKS NON-DISPATCH.       61900020
         XC    CINORECB(L'CINORECB),CINORECB ZERO NORM. ECB             62000020
         STATUS START             MAKE SUB-TASKS DISPATCHABLE           62100020
         DETACH CITCBPTR,STAE=YES GIVE CONTROL TO SUBTASK STAE          62200020
         BAL   RETREG,CALLDAIR    MARK SUBTASK DS AS NOT IN USE         62500020
         BAL   WORKREG1,UNSTACK   DELETE THE INPUT STACK          M5143 62550021
         B     MAINEXIT           RETURN TO CALLER                      62600020
         EJECT                                                          62700020
*********************************************************************** 62800020
*                                                                     * 62900020
*              COMMAND PROCESSOR ENDED ABNORMALLY                     * 63000020
*                                                                     * 63100020
*********************************************************************** 63200020
         SPACE 2                                                        63300020
CPABEND  EQU   *                                                        63400020
         L     WORKREG1,CAPTTMP   PTR TO TMP PARMLIST                   63430020
         L     DSECTREG,CPPLECT-CPPL(WORKREG1) PTR TO ECT               63460020
         USING ECT,DSECTREG                                             63500020
         MVC   ECTRTCD(LEN3),COMPCODE+OFFSET1                           63600020
         OI    ECTRCDF,HIORDBIT   SET ABEND FLAG ON                     63700020
         DETACH CITCBPTR                                                64400020
         BAL   RETREG,CALLDAIR    CALL IKJDAIR FOR DSE CLEAN UP         64500020
         LTR   RETCDREG,RETCDREG   CHECK IF SUCCESSFUL                  64600020
         BNZ   UNSTK              IF NO, RETURN TO CALLER               64610020
* CLEAR INPUT QUEUE                                                     64620020
         TCLEARQ INPUT                                                  64630020
         LTR   RETCDREG,RETCDREG  CHECK IF SUCCESSFUL RETURN            64640020
         BZ    ABPRCS             IF YES, BRANCH-CONTINUE PROCESSING    64690020
         MVC   INSERT1(MSG3LEN),CIMSG3 SET UP SERVICE ROUTINE INSERT    64720020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       64730020
         BAL   RETREG,SENDMSG     NOTIFY USER                           64750020
         B     ABEXIT             BRANCH TO EXIT                        64770020
         SPACE                                                          64780020
ABPRCS   EQU   *                                                        64790020
         L     WORKREG2,COMPCODE                                        65000020
         SLDL  WORKREG1,BITS20        SEPERATE SYS/USER COMP. CODE      65100020
         SRL   WORKREG2,BITS20                                          65200020
         LTR   WORKREG2,WORKREG2  CHECK IF SYSTEM ABEND OCCURRED        65600020
         BZ    SYSABEND           IF YES, BRANCH - SYSTEM ABEND         65700020
         CVD   WORKREG2,CONVERTD       CONVERT USER CODE TO DECIMAL     65854020
         UNPK  UNPACKD(LEN8),CONVERTD+OFFSET3(OFFSET5)                  65858020
         OI    UNPACKD+OFFSET7,CHAR0   SET PROPER ZONE SIGN             65862020
         MVC   INSRT2(LEN4),UNPACKD+OFFSET4 SET UP COMP CODE INSERT     65872020
         MVI   INS2LEN,LEN8       LENGTH OF INSERTION                   65882020
         MVI   INS2OFF,M4222IN1   INSERTION POINT IN MESSAGE            65892020
         MVI   LEVEL2,M4222       RELATIVE LEVEL2 MSG NUMBER            65902020
         B     SYSABMSG           BRANCH TO FORM REST OF MSG            65940020
SYSABEND SLL   WORKREG1,BITS20    CLEAR HIGH ORDER BITS                 65990020
         SRL   WORKREG1,BITS16                                          66040020
         ST    WORKREG1,COMPCODE                                        66100020
         OI    COMPCODE+OFFSET3,ZONEBITS INSERT SIGN BITS               66200020
         UNPK  COMPCODE+OFFSET1(LEN3),COMPCODE+OFFSET2(LEN2) UNPACK     66300020
         TR    COMPCODE+OFFSET1(LEN3),ABENDTAB-CHAR0 CONVERT TO EBCDIC  66400020
         MVC   INSRT2(LEN3),COMPCODE+OFFSET1 SET UP COMP CODE INSERT    66420020
         MVI   INS2LEN,LEN7       LENGTH OF INSERTION                   66440020
         MVI   INS2OFF,M4221IN1   INSERTION POINT IN MESSAGE            66460020
         MVI   LEVEL2,M4221       RELATIVE LEVEL2 MSG NUMBER            66480020
SYSABMSG EQU   *                                                        66530020
         BAL   RETREG,CMDERR      SET UP PARMLIST                       66560020
         BAL   RETREG,SENDMSG     NOTIFY USER                           67700020
         XC    ECTRTCD(LEN3),ECTRTCD ZERO CC IN ECT                     67900020
         NI    ECTRCDF,ALLBITS-HIORDBIT SET ABEND BIT OFF               68000020
ABEXIT   EQU   *                                                        68200020
         B     UNSTK              BR TO TERMINATE                       68800020
         EJECT                                                          68900020
*********************************************************************** 69000020
*                                                                     * 69100020
*              MARK ALL DSE ENTRIES OF SUB-TASK AS NOT IN USE         * 69200020
*                                                                     * 69300020
*********************************************************************** 69400020
         SPACE 2                                                        69500020
CALLDAIR EQU   *                                                        69600020
         IKJEBESV (14,12),,,CODEREG=NO,COMMREG=NO                       69700020
         SPACE                                                          69750020
         L     DSECTREG,CAPTTMP   PTR TO TMP PARMLIST                   69800020
         USING CPPL,DSECTREG                                            69900020
         L     WORKREG1,CPPLPSCB  PTR TO PSCB                           70000020
         LA    PARMREG1,CATMPLST  PTR TO DAIR PARMLIST                  70100020
         USING DAPL,PARMREG1      ESTAB ADDR. TO DAIR PARMLIST          70200020
         ST    WORKREG1,DAPLPSCB  PTR TO PSCB IN PARMLIST               70300020
         LA    DSECTREG,DAIRPARM                                        70400020
         USING DAPB2C,DSECTREG    ESTAB ADDR. TO DAIR PARMBLOCK         70500020
         ST    DSECTREG,DAPLDAPB  PTR TO PARMBLOCK IN PARMLIST          70600020
         XC    DA2CCD(LEN8),DA2CCD ZERO AREA                            70700020
         MVI   DA2CCD+OFFSET1,CLEANDSE DAIR ENTRY CODE                  70800020
         MVI   DA2CCD+OFFSET3,CIOPCD MOVE IN OPTION CODE                70850020
         LINK  EP=IKJDAIR                                               71000020
         SPACE                                                          71050020
         LTR   RETCDREG,RETCDREG   CHECK IF SUCCESSFUL                  71100020
         BZ    DAIREXIT           IF YES, RETURN TO CALLER              71200020
         MVC   INSERT1(MSG5LEN),CIMSG5 SET UP SERVICE ROUTINE INSERT    71240020
         BAL   RETREG,FORM313A    SET UP PARMLIST                       72240020
         BAL   RETREG,SENDMSG      NOTIFY USER                          74000020
         LA    RETCDREG,RETCD8     SET NONZERO RETURN CODE              74200020
         SPACE                                                          74250020
DAIREXIT EQU   *                                                        74300020
         IKJEBERT (14,12),,RC=(15) RETURN TO CALLER                     74400020
         EJECT                                                          74500020
***************************************************************   M5143 74550021
*                                                                 M5143 74560021
*    CALL IKJSTCK TO DELETE ALL ELEMENTS BUT TERMINAL FROM        M5143 74570021
*    INPUT STACK.                                                 M5143 74580021
*                                                                 M5143 74590021
***************************************************************   M5143 74592021
UNSTACK  EQU   *                                                  M5143 74594021
         LA    DSECTREG,CISTCKLF                                  M5143 74596021
         USING STPB,DSECTREG      ESTAB ADDR. FOR STACK BLOCK     M5143 74598021
         XC    STPB(STPBLEN),STPB ZERO OUT PARM BLOCK             M5143 74598421
         LA    PARMREG1,CATMPLST  PTR TO STACK PARMLIST           M5143 74598821
         USING STPL,PARMREG1      ESTAB. ADDR FOR STACK LIST      M5143 74599221
         ST    DSECTREG,STPLSTPB  PTR TO PARM BLOCK IN PARMLIST   M5143 74599621
         STACK DELETE=ALL,MF=(E,(1)) ISSUE STACK MACRO            M5143 74599721
         BR    WORKREG1           RETURN TO CALLER                M5143 74599821
         EJECT                                                          74599921
*********************************************************************** 74600020
*                                                                     * 74700020
*  CREATE PARAMETER LISTS FOR MESSAGES                                $ 74800020
*                                                                     * 74900020
*********************************************************************** 75000020
NOCORMSG EQU   *                                                        75002020
         MVC   LEVEL1(LEN2),CIM312 RELATIVE LEVEL1 MSG NUMBER           75004020
         MVI   INS1OFF,M312IN1    INSERTION POINT                       75006020
NOCORB   EQU   *                                                        75008020
         L     WORKREG1,CAPTSCMD  PTR TO SUBCOMMAND NAME                75010020
         MVC   INSRT1(LEN8),OFFSET0(WORKREG1) MOVE TO INSERT FIELD      75012020
         LH    WORKREG1,CASCMDLN  LENGTH OF SUBCOMMAND NAME             75014020
         LA    WORKREG1,LEN4(WORKREG1) ADD FOUR FOR OFFSET              75016020
         STH   WORKREG1,INS1LEN   LENGTH OF INSERTION                   75018020
         LA    WORKREG1,INSERT1   CHAIN INSERTION                       75020020
         ST    WORKREG1,INS1PTR   PARMLIST                              75022020
         BR    RETREG             RETURN TO CALLER                      75024020
         SPACE                                                          75026020
FORM313A EQU   *                                                        75028020
         MVC   INSERT2(MSGRCL),CIMSGRC SET UP RC INSERTION PARMLIST     75030020
         SRL   RETCDREG,LEN1      SHIFT RC FOR INDEXING                 75032020
         LH    WORKREG1,CIRCTAB(RETCDREG) PICK UP PRINTABLE CHARACTER   75034020
         STH   WORKREG1,INSRT2    MOVE TO INSERTION                     75036020
FORM313B EQU   *                                                        75038020
         MVC   LEVEL1(LEN4),CIM313 RELATIVE LEVEL1 MSG NUMBER           75040020
         LA    WORKREG1,INSERT2   CHAIN                                 75042020
         ST    WORKREG1,INSERT1   INSERTION                             75044020
         LA    WORKREG1,INSERT1   PARMLISTS                             75046020
         ST    WORKREG1,INS2PTR   TOGETHER                              75048020
         BR    RETREG             RETURN TO CALLER                      75050020
         SPACE                                                          75052020
CMDNFD   EQU   *                                                        75054020
         MVC   INSRT1(LEN8),BLDLNAME NAME OF INVALID COMMAND            75056020
         LH    WORKREG1,SCANOUT+CSOALNM-CSOA LENGTH OF BLDLNAME         75058020
         LA    WORKREG1,LEN4(WORKREG1) PLUS FOUR FOR OFFSET             75060020
         STH   WORKREG1,INS1LEN   LENGTH OF INSERTION                   75062020
         MVI   INS1OFF,M425IN1    INSERTION POINT                       75064020
         MVC   LEVEL1(LEN2),CIM425 RELATIVE LEVEL1 MSG NUMBER           75066020
         LA    WORKREG1,INSERT1   CHAIN                                 75068020
         ST    WORKREG1,INS1PTR   PARMLISTS                             75070020
         BR    RETREG             RETURN TO CALLER                      75072020
         SPACE                                                          75074020
CMDERR   EQU   *                                                        75076020
         MVC   LEVEL1(LEN2),CIM422 RELATIVE LEVEL1 MSG NUMBER           75078020
         LA    WORKREG1,INSERT2   CHAIN                                 75080020
         ST    WORKREG1,INS2PTR   PARMLISTS                             75082020
         MVI   INS1OFF,M422IN1    INSERTION POINT                       75084020
         B     NOCORB             BR TO PUT OUT MESSAGE                 75086020
         EJECT                                                          75088020
*********************************************************************** 75090020
*  USE IKJEBEML MACRO TO SEND MESSAGES TO USER                        * 75092020
*********************************************************************** 75094020
         SPACE 2                                                        75100020
SENDMSG  EQU   *                                                        75200020
         IKJEBESV (14,12),,,CODEREG=NO,COMMREG=NO                       75300020
         IKJEBEML ,,,,MF=(E,MSGPLIST) SEND ERROR MESSAGE TO USER        75400020
         IKJEBERT (14,12)                                               75600020
         EJECT                                                          75700020
         IKJEBECA                                                       77500020
         EJECT                                                          77600020
*********************************************************************** 77700020
*                                                                     * 77800020
*                          SUBCOMMAND WORKAREA                        * 77900020
*                                                                     * 78000020
*********************************************************************** 78100020
         SPACE 2                                                        78200020
         ORG   CASRWKA            SERVICE ROUTINE WORK AREA IN IKJEBECA 78300020
CICMDBFR DS    A                  ADDRESS OF COMMAND BUFFER             78600020
CINORECB DS    F                  ECB FOR SUBTASK NORMAL RETURN         78700020
CIECBLST DS    0F                 ECB LIST FOR WAIT                     78800020
CIECBATT DS    A                  ADDRESS OF ATTENTION ECB              78900020
CIECBNOR DS    A                  ADDRESS OF NORMAL RETURN ECB          79000020
CITCBPTR DS    A                  ADDRESS OF SUB-TASK TCB               79100020
CIGETLFM DS    4A                 IKJGETL PARM BLOCK                    79200020
CISTCKLF DS    2F                 IKJSTCK PARM BLOCK                    79400020
CITMPLST DS    4A                 DUMMY TMP PARAMETER LIST              79500020
DAIRPARM DS    2F                 IKJDAIR PARM BLOCK                    79600020
CMDBUFF  DS    A                  PTR TO CMD BUFFER TO BE PROCESSED     79700020
CIRETCD  DS    F                  SAVE AREA FOR PROGRAM RETURN CODE     79800020
LINKLIST DS    2A                 LFORM OF LINK MACRO                   79900020
SCANOUT  DS    2A                 IKJSCAN OUTPUT AREA                   80000020
SCANFLAG DS    F                  IKJSCAN FLAG FIELD                    80100020
FREEAREA DS    2F                 FREEMAIN LIST AREA                    80200020
FREELIST DS    2A                 LFORM FOR FREEMAIN MACRO              80300020
         DS    2X                 FREEMAIN CODE AND SUBPOOL NUMBER      80400020
FREEBIT  DS    BL1                FREEMAIN SWITCH- 0-NO AREA TO FREE    81700020
*                                                  1-AREA TO BE FREED   81800020
         EJECT                                                          82600020
         ORG   CATEMPBF           ADDITIONAL WORK AREA IN IKJEBECA      82700020
STAIPLST DS    0F                 STAI EXIT PARAMETER LIST              82800020
COMPCODE DS    F                  ABEND COMPLETION CODE                 82900020
SAVEBIT  DS    BL1                REGISTER SAVE SWITCH-                 83000020
*                                     1 - REGISTERS SAVED               83100020
*                                     0 - REGISTERS NOT SAVED           83200020
ABENDBIT DS    BL1                ABEND SWITCH-                         83300020
*                                     0 - CP FIELDED ABEND              83400020
*                                     1 - STAI FIELDED ABEND            83500020
         SPACE 2                                                        83600020
CIATTACH DS    0F                 LIST FORM OF ATTACH MACRO             83700020
CIMODNAM DS    A                  ADDRESS OF MODULE NAME                83800020
         DS    A                  ADDRESS OF DCB                        83900020
CIATHECB DS    A                  ADDRESS OF ATTACH ECB                 84000020
         DS    A                  GSPL OR GSPV                          84100020
         DS    A                  SHSPV OR SHSPL                        84200020
         DS    AL1                SET ROLLOUT BITS                      84300020
         DS    AL3                EXIT ROUTINE ADDRESS                  84400020
         DS    AL2                DPMOD VALUE                           84500020
         DS    AL1                LPMOD VALUE                           84600020
         DS    AL1                UNUSED                                84700020
         DS    CL8                MODULE NAME                           84800020
         DS    A                  ADDRESS OF STAI PARMLIST              84900020
         DS    A                  ADDRESS OF STAI EXIT ROUTINE          85000020
         SPACE 2                                                        85100020
GETPTR   DS    A                   PTR TO LSD AND IN-CORE AREA          85200020
         SPACE 2                                                        85500020
BLDLIST  DS    0H                            ENTRY LIST FOR BLDL        85600020
BLDLNO   DS    H                  NUMBER OF ENTRIES                     85700020
BLDLLEN  DS    H                  LENGTH OF EACH ENTRY                  85800020
BLDLNAME DS    CL8                NAME OF MODULE                        85900020
         DS    CL50               INFO FILLED IN BY BLDL                86000020
ENTRYLEN EQU   *-BLDLNAME                    LENGTH OF ENTRY            86100020
         SPACE 2                                                        86110020
STAELIST DS    5F                 LIST FORM FOR STAE MACRO              86120020
REGSAVE  DS    5F                 SAVE AREA FOR REGS 9-13               86130020
WKAREA   DS    A                  PTR TO STAE EXIT WORKAREA             86140020
CCTEMP   DS    X                  TEMP AREA FOR COMPLETION CODE         86150020
STAEBIT  DS    BL1                STAE SWITCH- 0 - STAE NOT IN EFFECT   86160020
*                                              1 - STAE IN EFFECT       86170020
         DS    0D                                                       86177020
CONVERTD DS    D                  UNPACK AND                            86184020
UNPACKD  DS    D                  CONVERT AREA                          86185020
MSGPLIST DS    12F                MESSAGE PARMLIST                      86186020
LEVEL1   EQU   MSGPLIST           RELATIVE LEVEL1 MSG NUMBER            86187020
LEVEL2   EQU   LEVEL1+3           RELATIVE LEVEL2 MSG NUMBER            86188020
INS1PTR  EQU   LEVEL1+4           PTR TO 1ST LEV1 INSERT PARMLIST       86189020
INS2PTR  EQU   LEVEL1+8           PTR TO 1ST LEV2 INSERT PARMLIST       86190020
INSERT1  EQU   LEVEL1+12          PTR TO NEXT INSERT PARMLIST           86191020
INS1LEN  EQU   INSERT1+4          LENGTH OF INSERTION                   86192020
INS1OFF  EQU   INSERT1+7          INSERTION PT IN MESSAGE               86193020
INSRT1   EQU   INSERT1+8          INSERTION1                            86194020
INSERT2  EQU   INSERT1+16         PTR TO NEXT INSERT PARMLIST           86195020
INS2LEN  EQU   INSERT2+5          LENGTH OF INSERTION                   86196020
INS2OFF  EQU   INSERT2+7          INSERTION PT IN MESSAGE               86197020
INSRT2   EQU   INSERT2+8          INSERTION2                            86198020
         EJECT                                                          86200020
         IKJIOPL                                                        86300020
         SPACE 2                                                        86400020
         IKJECT                                                         86500020
         EJECT                                                          86600020
         IKJCPPL                                                        86700020
         SPACE 2                                                        86800020
         IKJPGPB                                                        86900020
PGPBLEN  EQU   *-PGPB                                                   87000020
         EJECT                                                          87100020
         IKJCSPL                                                        87200020
         SPACE 2                                                        87300020
         IKJCSOA                                                        87400020
CSOALEN  EQU   *-CSOA                                                   87500020
         EJECT                                                          87600020
         IKJSTPL                                                        87700020
         SPACE 2                                                        87800020
         IKJSTPB                                                        87900020
STPBLEN  EQU   *-STPB                                                   88000020
         EJECT                                                          88100020
         IKJDAPL                                                        88200020
         SPACE 2                                                        88300020
         IKJDAP2C                                                       88400020
         SPACE 2                                                        88500020
         IKJLSD                                                         88600020
LSDLEN   EQU   *-LSD                                                    88700020
ENDMARK  EQU   *                                                        88800020
         EJECT                                                          88900020
         IKJEBEMI (312,313,422,425)                                     89000020
         EJECT                                                          89100020
IKJEBECI CSECT                                                          89200020
         SPACE 2                                                        89300020
*********************************************************************** 89400020
*                                                                     * 89500020
*                          PROGRAM CONSTANTS                          * 89600020
*                                                                     * 89700020
*********************************************************************** 89800020
         SPACE 2                                                        89900020
* LIST FORM OF ATTACH MACRO                                             90000020
ATTACHLT ATTACH SHSPV=SP78,SF=L     LIST FORM OF ATTACH MACRO           90100020
ATTACHLN EQU   *-ATTACHLT           LENGTH OF LIST FORM                 90200020
         SPACE 2                                                        90300020
STAELFM  STAE  STAEEXIT,,MF=L       LIST FORM OF STAE MACRO             90350020
STAELEN  EQU   *-STAELFM            LENGTH OF MACRO                     90360020
         SPACE 2                                                        90370020
* LIST OF COMMAND PROCESSORS THAT MAY BE EXECUTED UNDER EDIT            90400020
RUNSC    DC    C'RUN'             RUN SUBCOMMAND                        90700020
         SPACE 2                                                        91100020
ABENDTAB DC    C'0123456789ABCDEF' TRANSLATE TABLE FOR ABEND CODE       91200020
CIRCTAB  DC    C'  040812162024'  TABLE OF PRINTABLE CHARACTERS         91250020
         SPACE 2                                                        91300020
EODCODE  DC    X'FFFFFFFF'        END OF DATA INDICATOR                 91400020
DATALEN  EQU   *-EODCODE          LENGTH OF EOD INDICATOR               91500020
         SPACE 2                                                        91600020
CIMSGADR DC    V(IKJEBCIM)        ADDR OF MSG CSECT                     91660020
         EJECT                                                          93000020
IKJEBCIM CSECT                                                          93010020
         SPACE                                                          93020020
         DS    0F                                                       93030020
CIM312   DC    AL2(M312)          LEVEL1 MSG 312                        93040020
CIM313   DC    AL2(M313)          LEVEL1 MSG 313                        93050020
         DC    AL2(M3131)         LEVEL2 MSG 1                          93060020
CIM422   DC    AL2(M422)          LEVEL1 MSG 422                        93070020
CIM425   DC    AL2(M425)          LEVEL1 MSG 425                        93080020
         SPACE                                                          93090020
         DS    0F                                                       93100020
CIMSG3   IKJEBEMG ,M3131IN1,'TCLEARQ'                                   93330020
MSG3LEN  EQU   *-CIMSG3                                                 93340020
CIMSG4   IKJEBEMG ,M3131IN1,'STAE'                                      93360020
MSG4LEN  EQU   *-CIMSG4                                                 93390020
CIMSG5   IKJEBEMG ,M3131IN1,'DAIR'                                      93430020
MSG5LEN  EQU   *-CIMSG5                                                 93500020
CIMSG7   IKJEBEMG ,M3131IN1,'BLDL'                                      93800020
MSG7LEN  EQU   *-CIMSG7                                                 93850020
CIMSG8   IKJEBEMG ,M3131IN1,'STACK'                                     93900020
MSG8LEN  EQU   *-CIMSG8                                                 93950020
CIMSG9   IKJEBEMG ,M3131IN1,'SCAN'                                      94000020
MSG9LEN  EQU   *-CIMSG9                                                 94100020
CIMSG10  IKJEBEMG ,M3131IN1,'PUTGET'                                    94200020
MSG10LEN EQU   *-CIMSG10                                                94250020
CIFLG    IKJEBEMG ,M3131IN2,'FLAGS=  '                                  94300020
CIFLGLEN EQU   *-CIFLG                                                  94400020
CIMSGRC  IKJEBEMG ,M3131IN2,'  '                                        94440020
MSGRCL   EQU   *-CIMSGRC                                                94480020
         EJECT                                                          95000020
IKJEBECI CSECT                                                          95100020
*********************************************************************** 95200020
*                                                                     * 95300020
*                             STAI EXIT                               * 95400020
*                                                                     * 95500020
*********************************************************************** 95600020
         SPACE 2                                                        95700020
         CNOP  0,4                                                      95800020
STAIEXIT EQU   *                                                        95900020
         USING STAIEXIT,ENTRY                                           96000020
         CH    PARMREG0,CODE12    CHECK IF WORKAREA PROVIDED            96100020
         BE    NOWKA                         IF NO, BRANCH-BYPASS SAVE  96200020
         SAVE  (14,12)            SAVE REGISTERS                        96300020
         L     WORKREG1,OFFSET0(PARMREG1) PTR TO PARMLIST               96400020
         OI    SAVEBIT-STAIPLST(WORKREG1),HIORDBIT                      96500020
         MVC   COMPCODE-STAIPLST(LEN4,WORKREG1),OFFSET4(PARMREG1)       96600020
         B     SETSW              BRANCH TO SET ABEND BIT               96700020
NOWKA    ST    PARMREG1,COMPCODE-STAIPLST(WORKREG1)                     96800020
SETSW    EQU   *                                                        96900020
         OI    ABENDBIT-STAIPLST(WORKREG1),HIORDBIT                     97000020
         TM    SAVEBIT-STAIPLST(WORKREG1),HIORDBIT                      97100020
*                                 CHECK IF REGS SAVED                   97200020
         BNO   NORESTOR           IF NO,BRANCH-REGS SET                 97300020
         RETURN (14,12),,RC=STAICODE RETURN TO SYSTEM                   97400020
NORESTOR EQU   *                                                        97500020
         LA    RETCDREG,STAICODE  SET STAI RETURN CODE                  97600020
         BR    RETREG             RETURN TO SYSTEM                      97700020
CODE12   DC    H'12'              WORKAREA CODE                         97800020
         EJECT                                                          97801020
*********************************************************************** 97802020
*                                                                     * 97803020
*                             STAE EXIT                               * 97804020
*                                                                     * 97805020
*********************************************************************** 97806020
         SPACE 2                                                        97807020
         CNOP  0,4                                                      97808020
STAEEXIT EQU   *                                                        97809020
         USING STAEEXIT,ENTRY                                           97810020
         CH    PARMREG0,CD12      CHECK IF WORKAREA PROVIDED            97811020
         BE    NOWKAREA           IF NO, BRANCH- BYPASS SAVE            97812020
         SAVE  (14,12)                                                  97813020
         L     WORKREG1,OFFSET0(PARMREG1) PTR TO IKJEBECA               97814020
         DROP  COMMREG            CHANGE BASE REG FOR IKJEBECA          97815020
         USING IKJEBECA,WORKREG1                                        97816020
         ST    PARMREG1,WKAREA                                          97817020
         OI    SAVEBIT,HIORDBIT   INDICATE REGS SAVED                   97818020
         MVC   COMPCODE(LEN4),OFFSET4(PARMREG1) SAVE COMPLETION CODE    97819020
         B     CHECKCC            BRANCH TO CHECK COMPLETION CODE       97820020
NOWKAREA EQU   *                                                        97821020
         ST    PARMREG1,COMPCODE  SAVE COMPLETION CODE                  97822020
CHECKCC  NI    STAEBIT,ALLBITS-HIORDBIT INDICATE STAE CANCELED          97823020
         L     PARMREG1,COMPCODE                                        97824020
         SRL   PARMREG1,BITS12                                          97825020
         STC   PARMREG1,CCTEMP                                          97826020
         CLI   CCTEMP,CCX3E       CHECK IF ABEND IS X3E                 97827020
         BNE   NOTX3E             IF NO, BRANCH- TRUE PROGRAM ABEND     97828020
         TM    SAVEBIT,HIORDBIT   CHECK IF REGISTERS SAVED              97829020
         BNO   NOSAVE             IF NO, BRANCH-REGS SET                97830020
         RETURN (14,12),,RC=0     RETURN TO SYSTEM                      97831020
NOSAVE   EQU   *                                                        97832020
         L     PARMREG1,COMPCODE                                        97833020
         SR    RETCDREG,RETCDREG  SET RETURN CODE OF ZERO-NO RETRY      97834020
         BR    RETREG             RETURN TO SYSTEM                      97835020
         SPACE 2                                                        97836020
NOTX3E   EQU   *                                                        97837020
         TM    SAVEBIT,HIORDBIT   CHECK IF REGISTERS SAVED              97838020
         BNO   NOSAVE             IF NO, BRANCH-NOT RETRY POSSIBLE      97839020
         L     PARMREG1,WKAREA    RESTORE PTR TO WORKAREA               97840020
         L     PARMREG0,RETRYAD   PTR TO STAE RETRY                     97841020
         L     RETREG,OFFSET12(SAVEREG) RESTORE REG 14                  97842020
         RETURN (2,12),,RC=STAECODE RETURN TO SYSTEM                    97843020
         SPACE                                                          97844020
CD12     DC    H'12'              WORKAREA CODE                         97845020
RETRYAD  DC    A(STAERTRY)        PTR TO STAE RETRY                     97846020
         EJECT                                                          97847020
*********************************************************************** 97848020
*                                                                     * 97849020
*                            STAE RETRY                               * 97850020
*                                                                     * 97851020
*********************************************************************** 97852020
         SPACE 2                                                        97853020
         CNOP  0,4                                                      97854020
STAERTRY EQU   *                                                        97855020
         USING STAERTRY,ENTRY                                           97856020
         L     WORKREG1,OFFSET0(PARMREG1) PTR TO PARMLIST               97857020
         USING IKJEBECA,WORKREG1                                        97858020
         LM    COMMREG,SAVEREG,REGSAVE RESTORE PROGRAM REGS 9-13        97859020
         L     RETREG,RETURNAD    PTR TO RETURN POINT                   97860020
         BR    RETREG             RETURN TO MAIN LINE PROGRAM           97861020
RETURNAD DC    A(CPABEND)         PTR TO RETURN POINT IN MAIN PROGRAM   97862020
         END                                                            97900020
