BECO     TITLE 'EDIT SERVICE ROUTINE-INITIAL COPY-IKJEBECO'             00100020
*********************************************************************** 00200020
*                                                                     * 00400020
*STATUS-  VERSION NO. 01, OS/360 RELEASE NO. 20                       * 00500020
*                                                                     * 00600020
*FUNCTION/OPERATION-  IKJEBECO IS AN EDIT SERVICE ROUTINE WHICH IS    * 00700020
*   USED WHENEVER IT IS NECESSARY TO CREATE AN UTILITY DATA SET FROM  * 00800020
*   AN OLD EXISTING DATA SET WHICH MAY BE ACCESSED BY THE QUEUED      * 00900020
*   SEQUENTIAL ACCESS METHOD.  THIS ROUTINE WILL READ THE EXISTING    * 01000020
*   DATA SET SEQUENTIALLY, CHANGE THE RECORD FORMAT FROM WHAT EXISTS  * 01100020
*   ON THE OLD DATA SET TO AN EQUIVALENT RECORD FORMAT FOR THE        * 01200020
*   UTILITY DATA SET AS DESCRIBED IN THE UTILITY DATA SET STRUCTURE,  * 01300020
*   AND WRITE THE RECORDS INTO THE UTILITY DATA SET USING EITHER THE  * 01400020
*   SEQUENCE NUMBER AS THE KEY (IF THE DATA SET IS NUMBERED) OR A     * 01500020
*   GENERATED NUMBER AS THE KEY (IF THE DATA SET IS NOT NUMBERED).    * 01600020
*                                                                     * 01700020
*ENTRY POINTS-  IKJEBECO IS THE MAIN AND ONLY ENTRY POINT             * 01800020
*                                                                     * 01900020
*INPUT-  REGISTER 1 CONTAINS A POINTER TO EDIT'S COMMUNICATION AREA   * 02000020
*   WHICH HAS BEEN INITIALIZED WITH DDNAME, THE FULLY QUALIFIED       * 02100020
*   DSNAME, AND THE LOGICAL RECORD LENGTH OF THE DATA SET TO BE       * 02200020
*   COPIED.                                                           * 02300020
*                                                                     * 02500020
*OUTPUT-  A FORMATTED UTILITY DATA SET IS WRITTEN.                    * 02900020
*         REGISTERS AS DESCRIBED UNDER EXITS BELOW.                   * 03300020
*                                                                     * 03700020
*EXTERNAL REFERENCES-                                                 * 03800020
*        IKJEBEUI      -UTILITY DATA SET ACCESS INITIALIZATION        * 03900020
*        IKJEBEUT      -PERFORMS WRITING OF RECORDS ON UTILITY DATA   * 04000020
*                       SET                                           * 04100020
*        IKJEBEEX      -UTILITY DATA SET ACCESS TERMINATION           * 04200020
*        MACROS USED -                                                * 04300020
*           IKJEBESV   -SAVE CALLER'S REGISTERS AND ESTABLISH         * 04400020
*                       ADDRESSABILITY                                * 04500020
*           IKJEBERT   -RELOAD CALLER'S REGISTERS AND RETURN CONTROL  * 04600020
*                       TO CALLER                                     * 04700020
*           IKJEBESH   -LINKAGE TO EDIT MODULES                       * 04800020
*           IKJEBEML   -STANDARD MESSAGE TO TERMINAL USER             * 04900020
*           IKJEBECA   -LAYOUT AND DESCRIPTION OF COMMUNICATION AREA  * 05000020
*           FREEPOOL   -RELEASE BUFFER ACQUIRED BY OPEN MACRO TO      * 05100020
*                       SYSTEM                                        * 05200020
*           OPEN       -OPEN QSAM DATA SET                            * 05300020
*           CLOSE      -CLOSE QSAM DATA SET                           * 05400020
*           DCBD       -LAYOUT OF DCB FOR QSAM DATA SET               * 05500020
*                                                                     * 05600020
*EXITS,NORMAL-  A RETURN CODE IN REGISTER 15 AS FOLLOWS-              * 05640020
*                                                                     * 05680020
*           RETURN CODE = 0  THE EXISTING DATA SET WAS COPIED         * 05720020
*             SUCCESSFULLY.                                           * 05760020
*                                                                     * 05800020
*           RETURN CODE = 4  THE EXISTING DATA SET CONTAINS NO LOGICAL* 05840020
*             RECORDS.                                                * 05880020
*                                                                     * 05920020
*EXITS,ERROR-  RETURN CODE = 8 IN REGISTER 15 . POSSIBLE REASONS ARE- * 05960020
*           DATA SET CONTAINS INVALID LINE NUMBERS                    * 06000020
*           UNABLE TO OPEN EXISTING DATA SET                          * 06040020
*           UNABLE TO INITIALIZE EDIT ACCESS METHOD                   * 06080020
*           PERMANENT I/O ERROR                                       * 06120020
*                                                                     * 06160020
*TABLES/WORK AREAS -  THE EDIT SERVICE ROUTINE WORK AREA OF FIFTY     * 06200020
*   FULLWORDS AND A BUFFER POOL OF 98 FULLWORDS IN THE COMMUNICATION  * 06300020
*   AREA ARE USED                                                     * 06400020
*                                                                     * 06500020
*ATTRIBUTES - REFRESHABLE, ENABLED, NON-PRIVILEGED                    * 06600020
*                                                                     * 06700020
*NOTES- THIS ROUTINE DEPENDS ON THE CHARACTER CODE REPRESENTATIONS OF * 06720020
*       THE DIGITS 0 THROUGH 9 HAVING CONSECUTIVE BINARY VALUES IN    * 06740020
*       COLLATING SEQUENCE.  SEE THE SUBROUTINE  COCVBIN .            * 06760020
*                                                                     * 06780020
*********************************************************************** 06800020
IKJEBECO CSECT                                                          06900020
*A108090-108900,342070-345920,349050-349850,396700-398100,506500 A45155 06920021
*A507200-507800,546060-546900                                    A45155 06930021
*C329000-330000,333000                                           A45155 06940021
*D343000-346280,397000-398000,546200-546800                      A45155 06950021
*A137600,262500,441500-441700,500004-501904,504500,506600        A50471 06960021
*A507900-507960,514500-514780,536100-536500,538500-538700        A50471 06970021
*A542500-543000,546100-546120,546904-546928                      A50471 06980021
*C123000,262000,515000                                           A50471 06990021
*D111000,537000,545000                                           A50471 06992021
*A536050                                                          M4276 06994021
*D542500                                                          M4276 06996021
         SPACE 1                                                        07000020
*********************************************************************** 07100020
*    EQUATES OF SYMBOLIC REGISTERS                                      07200020
*********************************************************************** 07300020
PARMREG0 EQU   0                       PARAMETER POINTER                07400020
PARMREG1 EQU   1                       PARAMETER POINTER                07500020
TESTREG  EQU   2                       WORK REGISTER                    07600020
BINREG   EQU   3                       WORK REGISTER                    07700020
ADDREG   EQU   4                       WORK REGISTER                    07800020
DCBREG   EQU   5                       WORK REGISTER                    07900020
WORKREG  EQU   6                       WORK REGISTER                    08000020
EXREG    EQU   7                       WORK REGISTER                    08100020
UTREG    EQU   8                       WORK REGISTER                    08200020
COMMREG  EQU   9                       COMMUNICATION AREA ADDRESSING    08300020
TEMPREG  EQU   10                      WORK REGISTER                    08400020
BASEREG  EQU   11                      BASE REGISTER                    08500020
DATAREG  EQU   12                      WORK REGISTER                    08600020
SAVEREG  EQU   13                      SAVE AREA POINTER                08700020
RETREG   EQU   14                      RETURN REGISTER                  08800020
RETCDREG EQU   15                      RETURN CODE                      08900020
         SPACE 2                                                        09000020
*********************************************************************** 09100020
*    EQUATES OF SYMBOLIC CONSTANTS                                      09200020
*********************************************************************** 09300020
INTCY0   EQU   0                       CONSTANT OF 0                    09400020
INTCY1   EQU   1                       CONSTANT OF 1                    09500020
INTCY2   EQU   2                       CONSTANT OF 2                    09600020
INTCY3   EQU   3                       CONSTANT OF 3                    09700020
INTCY4   EQU   4                       CONSTANT OF 4                    09800020
INTCY5   EQU   5                       CONSTANT OF 5                    09850020
INTCY6   EQU   6                       CONSTANT OF 6                    09900020
INTCY8   EQU   8                       CONSTANT OF 8                    10000020
INTCY10  EQU   10                      CONSTANT OF 10                   10100020
INTCY12  EQU   12                      CONSTANT OF 12                   10200020
INTCY16  EQU   16                      CONSTANT OF 16                   10300020
INTCY20  EQU   20                      CONSTANT OF 20                   10400020
INTCY29  EQU   29                      CONSTANT OF 29                   10500020
INTCY50  EQU   50                      CONSTANT OF 50                   10600020
INTCY78  EQU   78                      CONSTANT OF 78                   10700020
INTCY100 EQU   100                     CONSTANT OF 100                  10800020
D0       EQU   0                       DISPLACEMENT OF 0         A45155 10809021
D3       EQU   3                       DISPLACEMENT OF 3         A45155 10818021
D7       EQU   7                       DISPLACEMENT OF 7         A45155 10827021
D8       EQU   8                       DISPLACEMENT OF 8         A45155 10836021
L0       EQU   0                       LENGTH OF 0               A45155 10845021
L1       EQU   1                       LENGTH OF 1               A45155 10854021
L4       EQU   4                       LENGTH OF 4               A45155 10863021
L5       EQU   5                       LENGTH OF 5               A45155 10872021
L8       EQU   8                       LENGTH OF 8               A45155 10881021
L9       EQU   9                       LENGTH OF 9               A45155 10890021
DCBOPEN  EQU   X'10'                   OPEN TEST FLAG                   10900020
VAR      EQU   X'40'                   VARIABLE RECORD FORMAT TEST FLAG 11000020
FIXED    EQU   X'80'                   FIXED RECORD FORMAT TEST FLAG    11200020
END      EQU   X'80'                   END OF PARAMETER LIST CODE       11300020
LAST     EQU   X'20'                   WRITE RECORD ON UTILITY DATA     11400020
*                                      SET CODE                         11500020
ALL      EQU   X'FF'                   USED TO SET SWITCHES             11580020
CHAR0    EQU   C'0'                    USED TO VERIFY LINE NUMBERS      11660020
CHAR9    EQU   C'9'                    USED TO VERIFY LINE NUMBERS      11740020
BLANK    EQU   C' '                    USED IN SCANNING MESSAGE TEXT    11820020
         SPACE 2                                                        11900020
*********************************************************************** 12000020
*    MESSAGE REFERENCES                                                 12100020
*********************************************************************** 12200020
         IKJEBEMI (309,337,338,344)                              A50471 12300021
MESS1    EQU   X'80'                   MESSAGE1 TEST SWITCH             12400020
MESS5    EQU   X'40'                   MESSAGE5 TEST SWITCH             12500020
MESS6    EQU   X'20'                   MESSAGE6 TEST SWITCH             12600020
         EJECT                                                          12700020
*********************************************************************** 12800020
*    STANDARD ENTRY LINKAGE AND ESTABLISHMENT OF ADDRESSABILITY BOTH    12900020
*    IN THIS ROUTINE AND IN THE COMMUNICATION AREA                      13000020
*********************************************************************** 13100020
         IKJEBESV (14,12),T,*          SAVE CALLER'S REGISTERS AND      13200020
*                                      ESTABLISH ADDRESSABILITY         13300020
         LR    COMMREG,PARMREG1        LET COMMREG PT TO COMMUNICATION  13400020
*                                      AREA                             13500020
         USING IKJEBECA,COMMREG        ADDRESSABILITY IN COMMUNICATION  13600020
*                                      AREA                             13700020
         MVI   SW,INTCY0               TURN SWITCHES OFF                13750020
         MVI   CORDFLAG,INTCY0         TURN CONTROL BITS OFF     A50471 13760021
         SPACE 2                                                        13800020
*********************************************************************** 13900020
*    MOVE DCB WHICH HAS BEEN INITIALIZED WITH DSORG, MACRF, A SYNAD     14000020
*    EXIT ADDRESS AND AN EOD EXIT ADDRESS FOR EXISTING DATA SET TO      14100020
*    THE COMMUNICATION AREA AND ESTABLISH ITS ADDRESSABILITY HERE       14200020
*********************************************************************** 14300020
         MVC   COINDCB(INDCBL),INDCB   MOVE DCB FOR EXISTING DATA SET   14400020
*                                      TO COMM. AREA                    14500020
         LA    DCBREG,COINDCB          LET DCBREG POINT TO DCB IN COMM. 14600020
*                                      AREA                             14700020
         USING IHADCB,DCBREG           ADDRESSABILITY IN DCB DSECT      14800020
         SPACE 2                                                        14900020
*********************************************************************** 15000020
*    DETERMINE WHETHER INITIAL COPY IS TO BE PERFORMED ON EDIT OR SAVE  15100020
*    DATA SET HERE                                                      15200020
*********************************************************************** 15300020
         TM    CAEDFLAG,CAEDINCP       TEST WHETHER INIT. COPY IS TO    15400020
*                                      BE PERFORMED ON EDIT DATA SET    15500020
         BO    EDITDATA                BRANCH IF YES TO EDITDATA        15600020
         SPACE 2                                                        15700020
*********************************************************************** 15800020
*    INITIALIZE DCB WITH THE APPROPRIATE DDNAME FROM THE COMMUNICATION  15900020
*    AREA HERE                                                          16000020
*********************************************************************** 16100020
         MVC   DCBDDNAM(INTCY8),CASADDN  MOVE SAVE DATA SET DDNAME FROM 16200020
*                                      COMM. AREA TO DCB                16300020
         SPACE 2                                                        16400020
*********************************************************************** 16500020
*    EDIT OR SAVE DATA SET IS OPENED AND TESTED IF OPEN IS SUCCESSFUL   16600020
*    HERE                                                               16700020
*********************************************************************** 16800020
NEXT     MVC   COOPENPL(INOPENL),INOPEN                                 16900020
         OPEN  ((DCBREG),(INPUT)),MF=(E,COOPENPL) EXECUTE FORM OF OPEN  17000020
*                                                 MACRO                 17100020
         TM    DCBOFLGS,DCBOPEN        CHECK IF DCB OPENED              17200020
         BNO   MESSAGE1                BRANCH IF NOT OPEN TO ISSUE      17300020
*                                      MESSAGE1                         17400020
         OI    CORDFLAG,READFLAG       TURN ON 1ST READ FLAG IN         17500020
*                                      WORKAREA OF COMM. AREA           17600020
         SPACE 2                                                        17700020
*********************************************************************** 17800020
*    IKJEBEUI IS CALLED TO ALLOCATE THE UTILITY DATA SET AND            17900020
*    INITIALIZE THE EDIT ACCESS METHOD                                  18000020
*********************************************************************** 18100020
         LR    PARMREG1,COMMREG        LET PARMREG1 POINT TO COMM. AREA 18200020
         LINK  EP=IKJEBEUI                                              18300020
         LTR   RETCDREG,RETCDREG       TEST RETURN CODE FROM IKJEBEUI   18400020
         BZ    SUCCESS                 BRANCH IF ZERO TO SUCCESS        18500020
UNSUC    LA    TEMPREG,INTCY8          SET RETURN CODE TO 8 IN TEMPREG  18600020
         SPACE 2                                                        18700020
*********************************************************************** 18800020
*    TERMINATION PROCESSING                                             18900020
*********************************************************************** 19000020
CLOSED   MVC   COOPENPL(INCLOSEL),INCLOSE                               19100020
         CLOSE ((DCBREG)),MF=(E,COOPENPL)  EXECUTE FORM OF CLOSEMACRO   19200020
         FREEPOOL IHADCB                                                19300020
EXIT     LR    RETCDREG,TEMPREG        PUT RET. CODE IN REG 15          19400020
         IKJEBERT (14,12),T,RC=(15)    RELOAD ALL REGISTERS EXCEPT      19500020
*                                      REGISTER 15 AND RETURN           19600020
*                                      CONTROL TO CALLER                19700020
EDITDATA MVC   DCBDDNAM(INTCY8),CAEDDDN  MOVE EDIT DATA SET NAME FROM   19800020
*                                      COMM. AREA TO DCB                19900020
         B     NEXT                    BRANCH TO OPEN EDIT DATA SET     20000020
         SPACE 2                                                        20100020
*********************************************************************** 20200020
*    MSG1- 'DATA SET (EDIT OR SAVE DSNAME) NOT USABLE+.  OPEN ERROR'    20300020
*    IS ISSUED HERE                                                     20400020
*********************************************************************** 20500020
MESSAGE1 OI    SW,MESS1                TURN MESSAGE1 SWITCH ON          20600020
M135     TM    CAEDFLAG,CAEDINCP       TEST WHETHER IT IS EDIT DATA SET 20700020
*                                      OR SAVE DATA SET                 20800020
         BO    EDSN1                   EDIT DATA SET THEN GO TO EDSN1   20900020
         SR    TESTREG,TESTREG         CLEAR TESTREG                    21000020
         ST    TESTREG,CADSNPT2        SET CADSNPT2 TO ZERO             21100020
         LA    TESTREG,M309IN1                                          21200020
         STH   TESTREG,CADSNOF2        SET OFFSET VALUE IN CADSNOF2     21300020
         TM    SW,MESS1                TEST WHETHER MESSAGE1 IS ISSUED  21400020
         BO    COMBINE2                BRANCH IF ON TO COMBINE2         21500020
         TM    SW,MESS5                TEST WHETHER MESSAGE5 IS TO BE   21600020
*                                      ISSUED                           21700020
         BO    COMBINE5                BRANCH TO COMBINE5 IF MESSAGE5   21800020
*                                      IS TO BE ISSUED                  21900020
         B     COMBINE3                BRANCH TO COMBINE3 IF MESSAGE4   22000020
*                                      IS ISSUED                        22100020
EDSN1    SR    TESTREG,TESTREG         CLEAR TESTREG                    22200020
         ST    TESTREG,CADSNPTR        SET CADSNPTR TO ZERO             22300020
         LA    TESTREG,M309IN1                                          22400020
         STH   TESTREG,CADSNOFF        SET OFFSET VALUE IN CADSNOFF     22500020
         TM    SW,MESS1                TEST WHETHER MESSAGE1 IS ISSUED  22600020
         BO    COMBINE4                BRANCH TO COMBINE4 IF MESSAGE1   22700020
*                                      IS ISSUED                        22800020
         TM    SW,MESS6                TEST WHETHER MESSAGE6 IS TO BE   22900020
*                                      ISSUED                           23000020
         BO    COMBINE8                BRANCH TO COMBINE8 IF MESSAGE6   23100020
*                                      IS TO BE ISSUED                  23200020
         B     COMBINE3                BRANCH TO COMBINE3 IF MESSAGE3   23300020
*                                      IS ISSUED                        23400020
COMBINE2 MVC   B(INTCY12),INLIST1                                       23500020
ISSUE1   IKJEBEML M309,M3093,CADSNPT2,MF=(E,B)                          23600020
COMBINE6 NI    SW,ALL-MESS1            TURN MESSAGE1 SWITCH OFF         23700020
         LA    TEMPREG,INTCY8          SET RETURN CODE TO 8             23800020
         B     EXIT                    BRANCH TO RETURN TO CALLING      23900020
*                                      ROUTINE                          24000020
COMBINE4 MVC   B(INTCY12),INLIST1                                       24100020
ISSUE2   IKJEBEML M309,M3093,CADSNPTR,MF=(E,B)                          24200020
         B     COMBINE6                BRANCH UNCOND. TO COMBINE6       24300020
         SPACE 2                                                        24400020
*********************************************************************** 24500020
*    THE EXISTING DATA SET IS PROCESSED HERE                            24600020
*********************************************************************** 24700020
SUCCESS  ST    PARMREG0,CAPTCDCB       SAVE POINTER TO UTILDCB IN COMM. 24800020
*                                      AREA                             24900020
         TM    DCBRECFM,FIXED          TEST WHETHER RECFM OF EXISTING   25000020
*                                      DATA SET IS FIXED OR NOT         25100020
         BNO   VARIABLE                BRANCH ON NOT FIXED TO VARIABLE  25200020
FIX      MVC   GETAD+INTCY4(INTCY2),CALRECL  THE LENGTH FIELD IS        25300020
*                                      SET TO THE VALUE OF LOG.REC.LENG 25400020
         XC    GETAD+INTCY6(INTCY2),GETAD+INTCY6  PUT ZERO INTO 7TH     25500020
*                                      AND 8TH BYTES IN BUFFER          25600020
         LA    ADDREG,GETAD+INTCY8     PUT STARTING ADDRESS FOR         25700020
*                                      GET MACRO IN ADDREG              25800020
         B     READ                    BRANCH UNCOND. TO READ           25900020
VARIABLE LA    ADDREG,GETAD+INTCY4     PUT STARTING ADDRESS FOR         26000020
*                                      GET MACRO IN ADDREG              26100020
READ     GET   IHADCB                                            A50471 26200021
         BAL   WORKREG,MOVETRNC        CALL MOVE/TRUNCATE RTN    A50471 26250021
STEP     TM    CORDFLAG,READFLAG       TEST WHETHER 1ST READ FLAG IS ON 26300020
         BNO   OFF                     BRANCH IF NOT ON TO OFF          26400020
ON       TM    CACFLAG1,CANONUM         TEST WHETHER DATA SET IS LINE-  26500020
*                                      NUMBERED                         26600020
         BO    STEP2                   NOT LINE-NUMBERED,GO TO STEP2    26700020
         SPACE 2                                                        26800020
*********************************************************************** 26900020
*    1ST READ FLAG IS ON AND DATA SET IS LINE-NUMBERED                  27000020
*********************************************************************** 27100020
STEP1    SR    TESTREG,TESTREG         CLEAR TESTREG                    27200020
         IC    TESTREG,CALINE          PUT LINE NUMBER OFFSET FOR       27300020
*                                      FIXED RECFM IN TESTREG           27400020
         TM    DCBRECFM,FIXED          TEST WHETHER DATA SET IS FIXED   27500020
*                                      OR VARIABLE                      27600020
         BO    PRECONV                 BRANCH IF RECFM IS FIXED TO      27700020
*                                      PRECONV                          27800020
VAR1     LA    TESTREG,INTCY4(TESTREG)  ADD 4 TO LINE NUMBER OFFSET     27900020
*                                       FOR VARIABLE RECFM              28000020
PRECONV  BCTR  TESTREG,PARMREG0         LINE NUMBER OFFSET - 1          28100020
         LA    TESTREG,INTCY0(TESTREG,ADDREG)                           28200020
         ST    TESTREG,TRULINE         PUT STARTING ADDRESS OF          28300020
*                                      LINE NO. IN TRULINE              28400020
         LA    RETCDREG,COCVBIN        PUT ENTRY ADDRESS OF BINARY      28500020
*                                      CONVERSION RTN. IN RETCDREG      28600020
         BALR  RETREG,RETCDREG         TRANSFER CONTROL TO BIN. CONV.   28700020
*                                      RTN.                             28800020
SEQNUM   ST    BINREG,CASTNUM          STORE CONVERTED SEQ. NO. IN      28900020
*                                      STARTING LINE NUMBER IN COMM.    29000020
*                                      AREA                             29100020
         ST    BINREG,CACURNUM         STORE CONVERTED SEQ. NO. IN      29200020
*                                      CURRENT LINE NO. IN COMM. AREA   29300020
TURNOFF  NI    CORDFLAG,ALL-READFLAG   TURN 1ST READFLAG OFF            29400020
         B     KEY                     BRANCH UNCOND. TO PLACE LINE     29500020
*                                      NO. IN OUTPUT BUFFER AS KEY      29600020
         SPACE 2                                                        29700020
*********************************************************************** 29800020
*    CONVERSION ROUTINE OF SEQ. NUMBER FROM DECIMAL TO BINARY           29900020
*********************************************************************** 30000020
COCVBIN  L     TESTREG,TRULINE         PUT STARTING ADDRESS OF LINE     30100020
*                                      NUMBER IN TESTREG                30200020
         SR    WORKREG,WORKREG         CLEAR WORKREG                    30300020
         IC    WORKREG,CALENGTH        PUT LENGTH OF LINE NUMBER IN     30400020
*                                      WORKREG                          30500020
         LR    EXREG,TESTREG                                            30600020
         LR    UTREG,WORKREG           UTREG CONT. LENG. OF SEQ. NO.    30700020
LOOP     CLI   INTCY0(EXREG),CHAR0     CHECK WHETHER LINE NO. IS        30800020
*                                      DEC. NUMERIC                     30900020
         BL    TEST1ST                 NOT DEC. NUMERIC THEN BRANCH TO  31000020
*                                      TEST1ST                          31100020
         CLI   INTCY0(EXREG),CHAR9     CHECK WHETHER LINE NUMBER        31200020
*                                      IS DEC. NUMERIC                  31300020
         BH    TEST1ST                 NOT DEC. NUMERIC THEN BRANCH TO  31400020
*                                      TEST1ST                          31500020
         LA    EXREG,INTCY1(EXREG)     INCREMENT ADDRESS OF LINE NO.    31600020
*                                      BY 1                             31700020
         BCT   WORKREG,LOOP            VERIFY ANY REMAINING DIGITS      31800020
CONV1    BCTR  UTREG,PARMREG0          LENGTH OF LINE NUMBER - 1        32000020
         EX    UTREG,PACKED                                             32100020
         CVB   BINREG,COPACKED         CONVERT LINE NO. TO BINARY       32200020
         BR    RETREG                  RETURN TO INITIAL COPY ROUTINE   32300020
TEST1ST  TM    CORDFLAG,READFLAG       TEST WHETHER 1ST READFLAG        32400020
*                                      IS ON                            32500020
         BO    TESTLAN                 IF ON BRANCH TO TEST FOR THOSE   32600020
*                                      LANGUAGES THAT MUST BE LINE-     32700020
*                                      NUMBERED                         32800020
         B     MSG2B                   IF NOT FIRST RECORD,      A45155 32900021
*                                      BRANCH TO ISSUE MESSAGE   A45155 33000021
TESTLAN  TM    CADSATTR,CALNNUM        TEST WHETHER ATTR. OF DATA SET   33100020
*                                      IS THAT IT MUST BE LINE-NUMBERED 33200020
         BO    MSG2A                   IF SO, BRANCH TO SEND MSG A45155 33300021
         OI    CACFLAG1,CANONUM        TURN NOT LINE-NUMBERED FLAG ON   33400020
         TM    CAEDFLAG,CAEDINCP       TEST WHETHER IT IS EDIT DATA SET 33500020
*                                      OR SAVE DATA SET                 33600020
         BO    EDSN3                   EDIT DATA SET THEN GO TO EDSN3   33700020
         OI    SW,MESS5                TURN MESSAGE5 SWITCH ON          33800020
         B     M135                    BRANCH UNCOND. TO M135           33900020
EDSN3    OI    SW,MESS6                TURN MESSAGE6 SWITCH ON          34000020
         B     M135                    BRANCH UNCOND. TO M135           34100020
         SPACE 2                                                        34200020
**************************************************************** A45155 34300021
*    THE FOLLOWING SECTION PREPARES THE FIRST-LEVEL MESSAGE FOR  A45155 34305021
*    THE CASE IN WHICH THE FIRST LINE OF THE DATA SET CONTAINS   A45155 34310021
*    AN INVALID LINE NUMBER.                                     A45155 34315021
**************************************************************** A45155 34320021
MSG2A    EQU   *                                                 A45155 34325021
         LA    ADDREG,M337A            SET MESSAGE NUMBER        A45155 34330021
         BAL   RETREG,MSG2INS1         BRANCH TO PROCESS INS.    A45155 34335021
         SR    WORKREG,WORKREG                                   A45155 34340021
         ST    WORKREG,INS1PTR         SPECIFY ONE INSERTION.    A45155 34345021
         B     MSG2LEV2                BRANCH TO PROCESS SECOND  A45155 34350021
*                                      LEVEL MESSAGE             A45155 34355021
         SPACE                                                          34360021
**************************************************************** A45155 34365021
*    THE FOLLOWING SECTION PREPARES THE FIRST-LEVEL MESSAGE FOR  A45155 34370021
*    THE CASE IN WHICH AN INVALID LINE NUMBER (NOT IN THE FIRST  A45155 34375021
*    LINE) IS ENCOUNTERED.                                       A45155 34380021
**************************************************************** A45155 34385021
MSG2B    EQU   *                                                 A45155 34390021
         LA    ADDREG,M337B            SET MESSAGE NUMBER        A45155 34395021
         BAL   RETREG,MSG2INS1         BRANCH TO PROCESS FIRST   A45155 34400021
*                                      INSERTION (INVALID NO.)   A45155 34405021
         LA    WORKREG,INS2PTR         OBTAIN ADDRESS FOR        A45155 34410021
*                                      SECOND INSERTION          A45155 34415021
         ST    WORKREG,INS1PTR         CHAIN INSERTIONS          A45155 34420021
         SR    WORKREG,WORKREG                                   A45155 34425021
         ST    WORKREG,INS2PTR         SPECIFY 2 INSERTIONS ONLY A45155 34430021
*                                                                A45155 34435021
* PREPARE SECOND INSERTION (PRECEDING LINE NUMBER).              A45155 34440021
*                                                                A45155 34445021
         LA    WORKREG,M337IN2         OBTAIN OFFSET FOR INS.    A45155 34450021
         STH   WORKREG,INS2OFF         STORE OFFSET IN LIST      A45155 34455021
         IC    WORKREG,CALENGTH        OBTAIN LINE NO. LENGTH    A45155 34460021
         LA    WORKREG,L4(,WORKREG)    COMPUTE INSERTION LENGTH  A45155 34465021
         STH   WORKREG,INS2LEN         SET LENGTH IN LIST        A45155 34470021
         L     UTREG,CACURNUM          OBTAIN PREVIOUS LINE NO.  A45155 34475021
         CVD   UTREG,COPACKED          CONVERT IT TO DECIMAL     A45155 34480021
         UNPK  INS2TXT(L9),COPACKED+D3(L5) UNPACK RESULT         A45155 34485021
         MVZ   INS2TXT+D8(L1),INS2TXT+D7 INSURE CORRECTNESS OF   A45155 34490021
*                                      LAST DIGIT                A45155 34495021
         LA    EXREG,L8                MAXIMUM LENGTH FOR MOVE   A45155 34500021
*                                      IS EIGHT CHARACTERS       A45155 34505021
         SH    WORKREG,H13             SUBTRACT CONSTANT FROM    A45155 34510021
*                                      INSERTION LENGTH FOR      A45155 34515021
*                                      COMPUTING LENGTH FOR MOVE A45155 34520021
         AR    EXREG,WORKREG           ADD 8 TO ABOVE RESULT -   A45155 34525021
*                                      THIS IS LENGTH FOR MOVE   A45155 34530021
*                                      TO LEFT-JUSTIFY LINE NO.  A45155 34535021
         LPR   WORKREG,WORKREG         CHANGE SIGN TO POSITIVE   A45155 34540021
         LA    WORKREG,INS2TXT(WORKREG) COMPUTE START POINT FOR  A45155 34545021
*                                      MOVE                      A45155 34550021
         EX    EXREG,MOVEINS2          MOVE INSERTION 2 TO       A45155 34555021
*                                      LEFT-JUSTIFY              A45155 34560021
MSG2LEV2 EQU   *                                                 A45155 34565021
         LA    WORKREG,INS1PTR         SET POINTER TO FIRST      A45155 34570021
*                                      FIRST-LEVEL INSERTION     A45155 34575021
         TM    CADSATTR,CALNNUM        DETERMINE IF DATA SET TYPE MUST  34635020
*                                      BE LINE NUMBERED                 34642020
         BO    DSTYPE                  YES,BRANCH AROUND                34649020
         SR    EXREG,EXREG             SET REG TO 0,NO SECOND LEVEL     34656020
*                                      INSERTION                        34663020
         LA    UTREG,M3371             PUT ADDR OF 2ND LEVEL MSG NO. IN 34670020
*                                      UTREG                            34677020
         B     MSG                     BRANCH AROUND                    34684020
DSTYPE   EQU   *                                                        34691020
         MVC   MSGTEXT(L'MSGTEXT),CADSTYPE   GET DSTYPE FROM COMM. AREA 34698020
*                                            AND MOVE TO MSGTEXT        34705020
         LA    EXREG,MSGTEXT+L'MSGTEXT-INTCY1 SET EXREG TO POINT TO END 34712020
*                                             OF MSGTEXT                34719020
LOOPIT   EQU   *                                                        34726020
         CLI   INTCY0(EXREG),BLANK     CHECK FOR BLANK IN MSGTEXT TO    34733020
*                                      GET LENGTH                       34740020
         BNE   OUTER                   IF NOT BLANK BRANCH AROUND       34747020
         BCT   EXREG,LOOPIT            GO CHECK NEXT BYTE FOR BLANK     34754020
OUTER    EQU   *                                                        34761020
         LA    UTREG,MSGTEXT           PUT ADDR OF MSGTEXT IN UTREG     34768020
         SR    EXREG,UTREG             GET LENGTH OF DSTYPE NAME        34775020
         LA    EXREG,INTCY5(,EXREG)    ADD LENGTH OF KEY(FOUR)TO LENGTH 34782020
*                                      OF DSTYPE NAME                   34789020
         STH   EXREG,MSGLEN            STORE LENGTH OF DSTYPE NAME AND  34796020
*                                      KEY INTO MSGLEN                  34803020
         LA    EXREG,M3372IN1          PUT ADDR OF INSERTION FOR 2ND    34810020
*                                      LEVEL MSG IN EXREG               34817020
         STH   EXREG,MSGOFF            STORE ADDR IN MSG OFFSET         34824020
         XC    MSGPTR(L'MSGPTR),MSGPTR SET MSGPTR TO ZERO,NO 2ND 2ND    34831020
*                                      LEVEL MSG                        34838020
         LA    EXREG,MSGPTR            PUT ADDR OF 2ND LEVEL INSERTION  34845020
*                                      LIST IN EXREG                    34852020
         LA    UTREG,M3372             PUT ADDR OF RELATIVE 2ND LEVEL   34859020
*                                      NUMBER IN UTREG                  34866020
MSG      EQU   *                                                        34873020
         IKJEBEML   (ADDREG),(UTREG),(WORKREG),(EXREG),MF=(E,B)         34880020
         B     EX                      BRANCH UNCOND. TO EX             34900020
         SPACE                                                          34905021
**************************************************************** A45155 34910021
*    THE FOLLOWING SECTION IS A SUBROUTINE FOR PROCESSING THE    A45155 34915021
*    FIRST FIRST-LEVEL INSERTION FOR MESSAGE IKJ52337I           A45155 34920021
**************************************************************** A45155 34925021
MSG2INS1 EQU   *                                                 A45155 34930021
         SR    EXREG,EXREG             CLEAR REGISTER FOR IC     A45155 34935021
         IC    EXREG,CALENGTH          OBTAIN LINE NO. LENGTH    A45155 34940021
         BCTR  EXREG,0                 ADJUST LENGTH FOR MVC     A45155 34945021
         EX    EXREG,MOVEINS1          MOVE LINE NO. TO          A45155 34950021
*                                      INSERTION LIST AREA       A45155 34955021
         LA    EXREG,L5(,EXREG)        COMPUTE INSERTION LENGTH  A45155 34960021
         STH   EXREG,INS1LEN           STORE LENGTH IN LIST      A45155 34965021
         LA    EXREG,M337IN1           OBTAIN INSERTION OFFSET   A45155 34970021
         STH   EXREG,INS1OFF           STORE OFFSET IN LIST      A45155 34975021
         BR    RETREG                  RETURN                    A45155 34980021
         SPACE                                                          34985021
COMBINE5 EQU   *                                                        35000020
         SPACE 2                                                        35100020
*********************************************************************** 35200020
*    MSG5- 'DATA SET (SAVE DSNAME) NOT LINE NUMBERED,USING NONUM' IS    35300020
*    ISSUED HERE                                                        35400020
*********************************************************************** 35500020
         MVC   B(INTCY12),INLIST5                                       35600020
         IKJEBEML M338,,CADSNPT2,MF=(E,B)                               35700020
         NI    SW,ALL-MESS5            TURN MESSAGE5 SWITCH OFF         35800020
         B     STEP2                   BRANCH UNCOND. TO STEP2          35900020
COMBINE8 EQU   *                                                        36000020
         SPACE 2                                                        36100020
*********************************************************************** 36200020
*    MSG6- 'DATA SET (EDIT DSNAME) NOT LINE NUMBERED, USING NONUM' IS   36300020
*    ISSUED HERE                                                        36400020
*********************************************************************** 36500020
         MVC   B(INTCY12),INLIST5                                       36600020
         IKJEBEML M338,,CADSNPTR,MF=(E,B)                               36700020
         NI    SW,ALL-MESS6            TURN MESSAGE6 SWITCH OFF         36800020
         SPACE 2                                                        36900020
*********************************************************************** 37000020
*    1ST READ FLAG IS ON AND DATA SET IS NOT LINE-NUMBERED              37100020
*********************************************************************** 37200020
STEP2    LA    WORKREG,INTCY100        PUT 100 IN WORKREG               37300020
         ST    WORKREG,CASTNUM         GENERATE STARTING LINE NUMBER IN 37400020
*                                      COMM. AREA                       37500020
         ST    WORKREG,CACURNUM        STORE GENERATED LINE NO. IN      37600020
*                                      CURRENT LINE NO. IN COMM. AREA   37700020
         ST    WORKREG,CAINCRE         STORE GENEARATED INCREMENT IN    37800020
*                                      LINE NUMBER INCREMENT IN COMM.   37900020
*                                      AREA                             38000020
         B     TURNOFF                 BRANCH TO TURN OFF 1ST READFLAG  38100020
OFF      TM    CACFLAG1,CANONUM         TEST WHETHER DATA SET IS LINE   38200020
*                                      NUMBERED                         38300020
         BO    STEP4                   BRANCH IF NOT LINE NUMBERED TO   38400020
*                                      STEP4                            38500020
         SPACE 2                                                        38600020
*********************************************************************** 38700020
*    1ST READ FLAG IS OFF AND DATA SET IS LINE-NUMBERED                 38800020
*********************************************************************** 38900020
STEP3    LA    RETCDREG,COCVBIN        BRANCH IF LINE NUMBERED TO       39000020
*                                      CONVERSION RTN.                  39100020
         BALR  RETREG,RETCDREG         TRANSFER CONTROL TO BINARY       39200020
*                                      CONVERSION RTN.                  39300020
         C     BINREG,CACURNUM         TEST WHETHER CURRENT SEQ. NO. IS 39400020
*                                      NOT GREATER THAN THE PREV. SEQ.  39500020
*                                      NO.                              39600020
         BNH   MSG2B                   BRANCH IF NOT GREATER TO  A45155 39700021
*                                      INFORM USER OF INVALID    A45155 39760021
*                                      LINE NUMBER               A45155 39820021
UPDATE   ST    BINREG,CACURNUM         BRANCH IF GREATER THAN TO UPDATE 39900020
*                                      CURRENT LINE NO. IN COMM. AREA   40000020
         B     KEY                     BRANCH UNCOND. TO PLACE LINE     40100020
*                                      NO. IN OUTPUT BUFFER AS KEY      40200020
         SPACE 2                                                        40300020
*********************************************************************** 40400020
*    1ST READ FLAG IS OFF AND DATA SET IS NOT LINE-NUMBERED             40500020
*********************************************************************** 40600020
STEP4    L     WORKREG,CACURNUM        PUT CURRENT LINE NO. IN WORKREG  40700020
         A     WORKREG,CAINCRE         ADD INCREMENT TO WORKREG         40800020
         ST    WORKREG,CACURNUM        UPDATE CURRENT LINE NO. IN COMM. 40900020
*                                      AREA                             41000020
KEY      MVC   GETAD(INTCY4),CACURNUM  PLACE LINE NO. IN OUTPUT         41100020
*                                      BUFFER AS KEY                    41200020
         SPACE 2                                                        41300020
*********************************************************************** 41400020
*    IKJEBEUT IS CALLED THROUGH IKJEBESH TO WRITE RECORD ON UTILITY     41500020
*    DATA SET                                                           41600020
*********************************************************************** 41700020
         MVC   COWORD1(INTCY4),CAPTCDCB  PUT ADDRESS OF CURRENT         41800020
*                                      UTILITY DCB IN COWORD1           41900020
         MVI   COWORD1,LAST            PUT X'20' IN HIGH ORDER BYTE OF  42000020
*                                      1ST PARAM. WORD                  42100020
         LA    TESTREG,GETAD                                            42200020
         ST    TESTREG,COWORD2         PUT STARTING ADDRESS OF RECORD   42300020
*                                      IN UTILITY DATA SET IN 2ND       42400020
*                                      PARAM. WORD                      42500020
         MVI   COWORD2,END             PUT X'80' IN HIGH ORDER BYTE OF  42600020
*                                      2ND PARAM. WORD                  42700020
         LA    UTREG,COWORD1           LET UTREG PT. TO PARMLIST        42800020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(UTREG)),MF=(E,A) 42900020
         LTR   RETCDREG,RETCDREG       TEST RETURN CODE FROM IKJEBEUT   43000020
         BNZ   EX                      BRANCH IF NOT ZERO TO EX         43100020
SET      B     READ                    BRANCH IF ZERO TO READ NEXT REC. 43200020
         SPACE 2                                                        43300020
*********************************************************************** 43400020
*    END OF FILE PROCESSING                                             43500020
*********************************************************************** 43600020
INEOF    TM    CORDFLAG,READFLAG       TEST WHETHER 1ST READ FLAG IS ON 43700020
         BO    OUT                     BRANCH IF ON TO OUT              43800020
         SR    TEMPREG,TEMPREG         SET RET. CODE TO ZERO IN TEMPREG 43900020
         NI    CACFLAG2,ALL-CADSMODS   TURN DATA SET MODIFIED           44000020
*                                      SWITCH OFF                       44100020
         TM    CORDFLAG,TRNCFLAG       CHECK FOR TRUNCATED RCDS  A50471 44150021
         BZ    CLOSED                  IF NONE, BRANCH TO CLOSE  A50471 44160021
         BAL   WORKREG,ISSUE5          OTHERWISE, SEND ERROR MSG A50471 44170021
         B     CLOSED                  BRANCH UNCOND. TO CLOSE EXISTING 44200020
*                                      DATA SET                         44300020
OUT      LA    TEMPREG,INTCY4          SET RETURN CODE TO 4 (EXISTING   44400020
*                                      DATA SET IS EMPTY)               44500020
         B     CLOSED                  BRANCH UNCOND. TO CLOSE EXISTING 44600020
*                                      DATA SET                         44700020
         SPACE 2                                                        44800020
*********************************************************************** 44900020
*    SYNCHRONOUS ERROR (SYNAD) PROCESSING                               45000020
*********************************************************************** 45100020
INSYNAD  SYNADAF  ACSMETH=QSAM         DIAGNOSE I/O ERROR               45200020
         LA    TESTREG,M3092IN1                                         45300020
         STH   TESTREG,OFFSET2         PUT OFFSET VALUE IN OFFSET2      45400020
         B     M135                    BRANCH UNCOND. TO M135           45500020
COMBINE3 XC    COBUILD2(INTCY4),COBUILD2  PUT 0 IN PTR FIELD OF         45600020
*                                         COBUILD2                      45700020
         MVC   COBUILD2+INTCY4(INTCY2),INDC82 PUT (LENGTH OF SYNADAF    45800020
*                                             MESSAGE) +4 IN 5TH &      45900020
*                                             6TH BYTES OF COBUILD2     46000020
         MVC   COBUILD2+INTCY6(INTCY2),OFFSET2 PUT OFFSET IN 7TH &      46100020
*                                              8TH BYTES OF COBUILD2    46200020
         MVC   COBUILD2+INTCY8(INTCY78),INTCY50(PARMREG1)  PUT SYNADAF  46300020
*                                                       MESSAGE IN      46400020
*                                                       COBUILD2        46500020
         SPACE 2                                                        46600020
*********************************************************************** 46700020
*    SYNADRLS MACRO IS ISSUED TO RELEASE THE BUFFER TO THE SYSTEM       46800020
*********************************************************************** 46900020
         SYNADRLS                                                       47000020
         TM    CAEDFLAG,CAEDINCP       TEST WHETHER INITIAL COPY IS TO  47100020
*                                      BE PERFORMED ON EDIT DATA SET    47200020
*                                      OR SAVE DATA SET                 47300020
         BO    EDSN2                   EDIT DATA SET THEN GO TO EDSN2   47400020
         SPACE 2                                                        47500020
*********************************************************************** 47600020
*    MSG4- 'DATA SET (SAVE DSNAME) NOT USABLE+.  I/O SYNAD ERROR        47700020
*    (SYNADINFO)' IS ISSUED HERE                                        47800020
*********************************************************************** 47900020
         MVC   B(INTCY12),INLIST3                                       48000020
ISSUE3   IKJEBEML M309,M3092,CADSNPT2,MF=(E,B)                          48100020
         B     EX                      BRANCH UNCOND. TO EX             48200020
EDSN2    EQU   *                                                        48300020
         SPACE 2                                                        48400020
*********************************************************************** 48500020
*    MESSAGE3- 'DATA SET (EDIT DSNAME) NOT USABLE+.  I/O SYNAD ERROR    48600020
*    (SYNADINFO)' IS ISSUED HERE                                        48700020
*********************************************************************** 48800020
         MVC   B(INTCY12),INLIST3                                       48900020
ISSUE4   IKJEBEML M309,M3092,CADSNPTR,COBUILD2,MF=(E,B)                 49000020
         SPACE 2                                                        49100020
*********************************************************************** 49200020
*    IKJEBEEX IS CALLED TO TERMINATE THE EDIT ACCESS METHOD             49300020
*********************************************************************** 49400020
EX       L     PARMREG0,CAPTCDCB       PUT ADDRESS OF CURRENT UTILDCB   49500020
*                                      IN PARMREG0                      49600020
         LR    PARMREG1,COMMREG        LET PARMREG1 POINT TO COMM.      49700020
*                                      AREA                             49800020
         LINK  EP=IKJEBEEX                                              49900020
         B     UNSUC                   BRANCH UNCOND. TO UNSUC.         50000020
         EJECT                                                          50000121
**************************************************************** A50471 50000421
*                                                                A50471 50000521
* SUBROUTINE BELOW MOVES INPUT RECORDS OBTAINED BY GET-LOCATE    A50471 50000621
* LOGIC.  THIS IS ITS ONLY FUNCTION WHEN RECFM IS F OR FB.  WITH A50471 50000721
* VARIABLE RECORDS, A POSSIBILITY EXISTS FOR THE RECORD LL TO    A50471 50000821
* EXCEED CALRECL. IN THIS CIRCUMSTANCE, THE RECORD IS TRUNCATED  A50471 50001121
* (LL= CALRECL), AND A SWITCH IS SET TO INDICATE THAT RECORD(S)  A50471 50001521
* HAVE BEEN TRUNCATED. A COUNT OF TRUNCATED RECORDS (TRNCOUNT)   A50471 50001921
* IS MAINTAINED IN THE WORK AREA FOR THE INITIAL COPY ROUTINE.   A50471 50003021
*                                                                A50471 50003121
**************************************************************** A50471 50003421
MOVETRNC EQU   *                                                 A50471 50003521
         LH    TESTREG,DCBLRECL          OBTAIN RECORD LL        A50471 50003621
         CH    TESTREG,CALRECL           COMPARE TO CALRECL      A50471 50003921
         SPACE                                                          50004021
*  NOTE -- RECORD LL CAN EXCEED CALRECL ONLY FOR VARIABLE        A50471 50004521
*  RECORDS WHOSE LL EXCEEDS LRECL IN THE FORMAT 1 DSCB.          A50471 50004621
         SPACE                                                          50004721
         BH    MVTRTRNC                  BRANCH TO TRUNCATE IF   A50471 50005321
*                                        LL > DATA SET LRECL     A50471 50005521
         BCT   TESTREG,MVTRMOVE          DECREMENT LENGTH FOR    A50471 50005721
*                                        MOVE AND BRANCH TO EXEC A50471 50005921
MVTRTRNC EQU   *                                                 A50471 50006121
         LH    TESTREG,CALRECL           OBTAIN TRUNCATION LEN.  A50471 50009221
         TM    CORDFLAG,TRNCFLAG         TEST FOR PREVIOUS TRNC. A50471 50014421
         BZ    MVTR1ST                   IF NONE PREVIOUSLY, SET A50471 50017621
*                                        SWITCH AND INIT. COUNT  A50471 50020821
         LH    BINREG,TRNCOUNT           OBTAIN COUNT OF TRNC'S  A50471 50024021
         LA    BINREG,INTCY1(,BINREG)    INCREMENT COUNT         A50471 50027221
         B     MVTRUPDT                  BRANCH TO TRUNCATE REC. A50471 50030421
MVTR1ST  EQU   *                                                 A50471 50033621
         LA    BINREG,INTCY1             INITIAL COUNT IS 1      A50471 50036821
         OI    CORDFLAG,TRNCFLAG         INDICATE REC. TRUNCATED A50471 50040021
MVTRUPDT EQU   *                                                 A50471 50043221
         STH   BINREG,TRNCOUNT           SAVE TRUNCATION COUNT   A50471 50046421
         MVC   INTCY0(INTCY2,PARMREG1),CALRECL TRUNCATE RECORD   A50471 50049621
         BCTR  TESTREG,PARMREG0          DECREMENT LEN FOR MVC   A50471 50056021
MVTRMOVE EQU   *                                                 A50471 50059221
         EX    TESTREG,MVTRMVC           MOVE RECORD - INPUT BFR A50471 50061221
         BR    WORKREG                   RETURN TO CALLER        A50471 50062421
         EJECT                                                          50065621
**************************************************************** A50471 50068821
* THE FOLLOWING SUBROUTINE FORMATS THE INFORMATIONAL MESSAGE FOR A50471 50072021
* TRUNCATED VARIABLE RECORDS AND REQUESTS MESSAGE OUTPUT VIA THE A50471 50075221
* MESSAGE SELECTION ROUTINE (IKJEBEMS).                          A50471 50078421
**************************************************************** A50471 50081621
         SPACE                                                          50084821
ISSUE5   EQU   *                                                        50088021
         LH    BINREG,TRNCOUNT         OBTAIN COUNT OF TRUNCATED A50471 50091221
*                                      LINES                     A50471 50094421
         CH    BINREG,INDC1            CHECK FOR COUNT = ONE     A50471 50097621
         BH    ISSUE510                IF NOT, BR TO PROCESS 3   A50471 50100821
*                                      INSERTIONS                A50471 50104021
         LA    ADDREG,SINGTRNC         OBTAIN ADDRESS OF SINGLE  A50471 50107221
*                                      INSERTION OTHERWISE       A50471 50110421
         B     ISSUE520                BRANCH TO PUT MESSAGE     A50471 50113621
ISSUE510 EQU   *                                                        50116821
         MVC   MS5INS2(TRINSLEN),MULTTRNC MOVE 2ND AND 3RD       A50471 50120021
*                                      INSERTIONS TO WORK AREA   A50471 50123221
         LA    ADDREG,MS5INS3          CHAIN 3RD INSERTION       A50471 50126421
         ST    ADDREG,MS5INS2          TO 2ND INSERTION LIST     A50471 50129621
         CVD   BINREG,COPACKED         CONVERT COUNT TO DECIMAL  A50471 50132821
         MVC   EDITMASK,EDITPTRN       MOVE EDIT PATTERN TO      A50471 50136021
*                                      WORK AREA                 A50471 50139221
         EDMK  EDITMASK,COPACKED+INTCY3 SUPPRESS LEADING ZEROES  A50471 50142421
         LA    BINREG,EDITMASK+INTCY10 ADDRESS OF BYTE THAT      A50471 50145621
*                                      FOLLOWS MASK              A50471 50148821
         SR    BINREG,PARMREG1         COMPUTE LENGTH OF TEXT    A50471 50152021
         BCTR  BINREG,PARMREG0         DECREMENT LENGTH FOR MVC  A50471 50155221
         EX    BINREG,ISSUE5MV         MOVE INSERTION TEXT       A50471 50158421
         LA    BINREG,INTCY5(,BINREG)  COMPUTE INSERTION LENGTH  A50471 50161621
         STH   BINREG,MS5LEN1          SET LENGTH IN LIST        A50471 50164821
         LA    BINREG,M344IN1          OBTAIN OFFSET FOR INS. 1  A50471 50168021
         STH   BINREG,MS5OFF1          SET OFFSET IN LIST        A50471 50171221
         LA    ADDREG,MS5INS2          CHAIN 2ND INSERTION LIST  A50471 50174421
         ST    ADDREG,MS5INS1          TO FIRST INSERTION LIST   A50471 50177621
         LA    ADDREG,MS5INS1          ADDRESS OF INSERTION      A50471 50180821
*                                      CHAIN                     A50471 50184021
ISSUE520 IKJEBEML M344,0,(ADDREG),0,MF=(E,B) PUT MESSAGE         A50471 50187221
         BR    WORKREG                 RETURN TO CALLER          A50471 50190421
         EJECT                                                          50193621
*********************************************************************** 50200020
*    CONSTANT AREA FOR IKJEBECO                                         50300020
*********************************************************************** 50400020
INDC1    DC    H'1'                    CONSTANT FOR COMPARES     A50471 50450021
INDC4    DC    F'4'                    FULLWORD OF 4                    50500020
INDC82   DC    H'82'                   HALFWORD OF 82                   50600020
H13      DC    H'13'                   HALFWORD CONSTANT 13      A45155 50650021
EDITPTRN DC    X'40202020202020202020' PATTERN FOR EDMK OP.      A50471 50660021
PACKED   PACK  COPACKED(INTCY8),INTCY0(INTCY0,TESTREG)                  50700020
MOVEINS1 MVC   INS1TXT(L0),D0(TESTREG) MOVE INSERTION TEXT FOR   A45155 50720021
*                                      INVALID LINE NUMBER       A45155 50740021
MOVEINS2 MVC   INS2TXT(L0),D0(WORKREG) MOVE PRECEDING LINE       A45155 50760021
*                                      NUMBER TO INSERTION       A45155 50780021
ISSUE5MV MVC   MS5TXT1(INTCY0),INTCY0(PARMREG1) MOVE INSERTION   A50471 50790021
*                                      FOR MSG. IKJ52344I        A50471 50792021
MVTRMVC  MVC   INTCY0(INTCY0,ADDREG),INTCY0(PARMREG1) MOVE       A50471 50794021
*                                      RECORD TO INPUT BUFFER    A50471 50796021
         SPACE 2                                                        50800020
*    LIST FORMS OF IKJEBEML MACRO                                       50900020
INLIST1  IKJEBEML M309,M3091,,MF=L                                      51000020
INLIST3  IKJEBEML M309,M3092,,,MF=L                                     51200020
INLIST5  IKJEBEML M338,,,MF=L                                           51300020
         SPACE 2                                                        51400020
*    IKJEBEMG MACROS FOR LOCAL INSERTION LISTS                   A50471 51450021
*    NOTE -- THESE MACROS MUST BE MAINTAINED IN EXISTING ORDER   A50471 51460021
         SPACE                                                          51462021
MULTTRNC IKJEBEMG 0,M344IN2,'S'        IKJ52344I - 2ND INSERTION A50471 51470021
MULTTRN2 IKJEBEMG 0,M344IN3,'S'        IKJ52344I - 3RD INSERTION A50471 51472021
TRINSLEN EQU   *-MULTTRNC              LENGTH OF COMBINED LISTS  A50471 51474021
         SPACE                                                          51476021
SINGTRNC IKJEBEMG 0,M344IN1,'1'        IKJ52344I - 1ST INSERTION A50471 51478021
         SPACE 2                                                        51478421
INDCB    DCB   DSORG=PS,MACRF=GL,SYNAD=INSYNAD,EODAD=INEOF       A50471 51500021
INDCBEND EQU   *                                                        51600020
INDCBL   EQU   INDCBEND-INDCB                                           51700020
INOPEN   OPEN  (,(INPUT)),MF=L         LIST FORM OF OPEN MACRO          51800020
OPENEND  EQU   *                                                        51900020
INOPENL  EQU   OPENEND-INOPEN                                           52000020
INCLOSE  CLOSE (,),MF=L                LIST FORM OF CLOSE MACRO         52100020
CLOSEND  EQU   *                                                        52200020
INCLOSEL EQU   CLOSEND-INCLOSE                                          52300020
         DCBD  DSORG=PS,DEVD=DA                                         52400020
         IKJEBECA                                                       52500020
         ORG   CASRWKA                 EDIT SERVICE ROUTINE             52600020
*                                      WORK AREA                        52700020
COOPENPL DS    F                       FULLWORD FOR EXEC FORM OF        52800020
*                                      OPEN MACRO                       52900020
COWORD1  DS    F                       1ST PARAM WORD FOR UT            53000020
COWORD2  DS    F                       2ND PARAM WORD FOR UT            53100020
A        DS    5F                      5 FULLWORDS FOR SH MACRO         53200020
COPACKED DS    D                       DOUBLE WORD FOR CONVERTING       53300020
*                                      ZONED DEC. INTO PACKED DEC.      53400020
TRULINE  DS    F                       LOCATION FOR STARTING ADDRESS    53500020
*                                      OF LINE NO.                      53600020
COINDCB  DS    24F                     STORAGE FOR DCB            M4276 53605021
TRNCOUNT DS    H                       COUNT OF TRUNCATED LINES  A50471 53610021
EDITMASK DS    CL10                    MASK FOR EDMK INSTRUCTION A50471 53650021
CORDFLAG DS    X                       1ST TIME READ SWITCH             53800020
READFLAG EQU   X'80'                   1ST TIME READ (1-YES)     A50471 53850021
TRNCFLAG EQU   X'40'                   VARIABLE RECORDS          A50471 53860021
*                                      TRUNCATED (1-YES)         A50471 53870021
SW       DS    X                       SWITCH                           53900020
OFFSET2  DS    H                       1ST INSERTION FOR 2ND 2ND-       54000020
*                                      LEVEL MESSAGE OF MSG3            54100020
         ORG   CATEMPBF                TEMPORARY BUFFER POOL            54200020
GETAD    DS    66F                     STORAGE FOR LOGICAL REC.  A50471 54300021
*                                      MACRO                            54400020
B        DS    10F                     10 FULLWORDS FOR ML MACRO        54600020
INSWKA   DS    22F                     INSERTION WORK AREA       A50471 54610021
         ORG   INSWKA                  GENERAL ORGANIZATION      A50471 54610121
COBUILD2 DS    22F                     INSERT. BFR FOR ML MACRO  A50471 54610421
         ORG   INSWKA                  ORGANIZATION FOR IKJ52337 A50471 54612021
MSGPTR   DS    F                       POINTER TO NEXT INSERTION A45155 54620021
MSGLEN   DS    H                       LENGTH OF INSERTION       A45155 54625021
MSGOFF   DS    H                       OFFSET OF INSERTION IN    A45155 54630021
*                                      BASIC MESSAGE             A45155 54635021
MSGTEXT  DS    CL8                     TEXT OF INSERTION         A45155 54640021
INS1PTR  DS    F                       POINTER TO NEXT INSERTION A45155 54645021
INS1LEN  DS    H                       LENGTH OF INSERTION       A45155 54650021
INS1OFF  DS    H                       OFFSET OF INSERTION IN    A45155 54655021
*                                      BASIC MESSAGE             A45155 54660021
INS1TXT  DS    12C                     TEXT OF INSERTION         A45155 54665021
INS2PTR  DS    F                       POINTER TO NEXT INSERTION A45155 54670021
INS2LEN  DS    H                       LENGTH OF INSERTION       A45155 54675021
INS2OFF  DS    H                       OFFSET OF INSERTION IN    A45155 54680021
*                                      BASIC MESSAGE             A45155 54685021
INS2TXT  DS    12C                     TEXT OF INSERTION         A45155 54690021
         ORG   INSWKA                  ORGANIZATION FOR IKJ52344 A50471 54690421
MS5INS1  DS    F                       CHAIN WORD - INSERTION 1  A50471 54690821
MS5LEN1  DS    H                       LENGTH - INSERTION 1      A50471 54691221
MS5OFF1  DS    H                       OFFSET - INSERTION 1      A50471 54691621
MS5TXT1  DS    8C                      TEXT - INSERTION 1        A50471 54691721
         DS    0F                      ALIGNMENT ONLY            A50471 54691821
MS5INS2  DS    9C                      INSERTION LIST 2          A50471 54691921
         DS    0F                      ALIGNMENT ONLY            A50471 54692021
MS5INS3  DS    9C                      INSERTION LIST 3          A50471 54692421
         ORG   ,                       END OF WORK AREA ORG.     A50471 54692821
         END                                                            54700020
