BEDE     TITLE 'TSO EDIT COMMAND - IKJEBEDE - DELETE SUBCOMMAND'        00100020
IKJEBEDE CSECT                                                          00200020
*********************************************************************** 00300020
*                                                                     * 00400020
* D482400                                                      SA61391* 00420021
* C482240-482340                                               SA61391* 00440021
* A235500                                                      SA61391* 00460021
*                                                              SA61391* 00480021
* C482240                                                      SA69232* 00490021
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 00500020
*                                                                     * 00600020
* FUNCTION -- IKJEBEDE IS THE EDIT SUBCOMMAND 'DELETE'.  IT CAUSES ONE* 00700020
*    OR MORE LINES TO BE DELETED FROM THE EDIT UTILITY DATA SET.      * 00800020
*    IKJPARS SCANS THE OPERANDS AND PROMPTS FOR VALID SYNTAX.  A      * 00900020
*    VALIDITY CHECK ROUTINE, 'DEVALCHK', GAINS CONTROL AFTER EACH     * 01000020
*    OPERAND IS PARSED.  FOR THE FIRST OPERAND, IT SETS A SWITCH      * 01100020
*    FOR '*' OR CONVERTS THE STARTING LINE NUMBER TO BINARY.          * 01200020
*    IT CONVERTS THE SECOND OPERAND TO BINARY, AND STORES IT AS       * 01300020
*    EITHER (1) A COUNT OF LINES, OR (2) THE ENDING LINE NUMBER.      * 01400020
*    IF TWO LINE NUMBERS ARE SPECIFIED, 'DEVALCHK' SETS AN INVALID    * 01500020
*    RANGE SWITCH WHEN THEY ARE IN DESCENDING ORDER.  A TEST IS MADE  * 01600020
*    FOR A COUNT OF ZERO, AND A RETURN CODE OF FOUR (4) IS SET IF     * 01700020
*    ZERO IS SPECIFIED.  IN ALL OTHER CASES THE RETURN CODE TO IKJPARS* 01800020
*    IKJPARS IS ZERO (0).                                             * 01900020
*                                                                     * 02000020
*    WHEN IKJEBEDE REGAINS CONTROL FROM IKJPARS, IT TESTS FOR         * 02100020
*    '*'.  IF '*' IS SPECIFIED, 'COUNT' LINES BEGINNING WITH THE      * 02200020
*    CURRENT LINE '*' ARE DELETED.                                    * 02300020
*    IF '*' IS NOT SPECIFIED, THE UTILITY DATA SET MUST BE LINE       * 02400020
*    NUMBERED FOR IKJEBEDE TO CONTINUE.  IF NOT, AN INFORMATIONAL     * 02500020
*    MESSAGE IS PRINTED AT THE TERMINAL AND IKJEBEDE TERMINATES.      * 02600020
*    IF AN INVALID LINE RANGE IS SPECIFIED ON THE SUBCOMMAND,         * 02700020
*    IKJEBEDE ISSUES A DIAGNOSTIC MESSAGE AND TERMINATES.             * 02800020
*    OTHERWISE DELETION OF LINES BY LINE NUMBER IN THE UTILITY DATA   * 02900020
*    SET BEGINS.                                                      * 03000020
*                                                                     * 03100020
*    DELETION OF LINES FROM THE UTILITY DATA SET IS ACCOMPLISHED BY   * 03200020
*    INVOKING IKJEBEUT TO PERFORM VARIOUS I/O OPERATIONS ON THE       * 03300020
*    DATA SET --                                                      * 03400020
*                                                                     * 03500020
*    1.  THE FIRST RECORD IS DELETED.  IF NOT FOUND, THE USER IS      * 03600020
*    INFORMED BY TERMINAL MESSAGE AND IKJEBEDE TERMINATES.            * 03700020
*                                                                     * 03800020
*    2.  THE NEXT RECORD IS READ.                                     * 03900020
*                                                                     * 04000020
*    3.  THE RECORD JUST READ IS DELETED.  IF THE READ IS             * 04100020
*    UNSUCCESSFUL, '*' IS SET TO THE KEY OF THE PREVIOUS              * 04200020
*    RECORD.  IF NO PREVIOUS RECORD EXISTS, THE USER                  * 04300020
*    IS INFORMED BY TERMINAL MESSAGE THAT THE DATA SET                * 04400020
*    IS EMPTY.                                                        * 04500020
*                                                                     * 04600020
*    4.  2. AND 3. ABOVE ARE REPEATED UNTIL A RECORD IS NOT           * 04700020
*    FOUND OR UNTIL THE LAST RECORD SPECIFIED TO BE DELETED           * 04800020
*    HAS BEEN REMOVED FROM THE DATA SET.  WHEN THE LATTER             * 04900020
*    OCCURS, '*' IS SET TO THE PREVIOUS RECORD KEY OR TO              * 05000020
*    ZERO IF NO PREVIOUS RECORDS EXIST.  (WHEN NO PREVIOUS            * 05100020
*    RECORDS EXIST, THE USER IS INFORMED BY MESSAGE THAT THE TOP OF   * 05200020
*    THE DATA SET HAS BEEN REACHED.)                                  * 05300020
*                                                                     * 05400020
*    WHEN DELETION OF LINES FROM THE UTILITY DATA SET IS COMPLETE,    * 05500020
*    A CHECK IS MADE TO DETERMINE IF THE BASIC/IPLI LANGUAGE PROCESSOR* 05600020
*    MUST BE CALLED TO REMOVE LINES FROM THE REVERSE POLISH DATA SET  * 05700020
*    MAINTAINED FOR THOSE DATA SET TYPES.  IF THE LANGUAGE PROCESSOR  * 05800020
*    EXISTS IN THE SYSTEM, IT IS INVOKED VIA THE STANDARD SYNTAX      * 05900020
*    CHECKER INTERFACE.                                               * 06000020
*                                                                     * 06100020
*    WHEN DELETION OPERATIONS ARE COMPLETE, CONTROL IS RETURNED       * 06200020
*    TO IKJEBEMA BY BRANCHING ON REGISTER FOURTEEN (14).              * 06300020
*                                                                     * 06400020
* ENTRY POINTS --                                                     * 06500020
*         IKJEBEDE - VIA IKJEBESH MACRO ISSUED BY IKJEBEMA            * 06600020
*         WHEN THE DELETE SUBCOMMAND IS ENTERED AT THE TERMINAL.      * 06700020
*                                                                     * 06800020
* INPUT --                                                            * 06900020
*    REGISTER ONE (1) CONTAINS THE ADDRESS OF THE EDIT COMMUNICATION  * 07000020
*    AREA.                                                            * 07100020
*                                                                     * 07200020
* OUTPUT --                                                           * 07300020
*    REGISTER FIFTEEN (15) CONTAINS ONE OF THE FOLLOWING              * 07400020
*    RETURN CODES --                                                  * 07500020
*                                                                     * 07600020
*    00 - SUCCESSFUL OPERATION                                        * 07700020
*    08 - UNABLE TO COMPLETE (SEE 'NOTES' FOR DESCRIPTION)            * 07750020
*    12 - I/O ERROR IN THE UTILITY DATA SET                           * 07800020
*    16 - LANGUAGE PROCESSOR FAILURE                                  * 07900020
*                                                                     * 08000020
* EXTERNAL REFERENCES --                                              * 08100020
*                                                                     * 08200020
*         IKJEBEMS - EDIT MESSAGE SELECTION ROUTINE, INVOKED VIA      * 08300020
*                    IKJEBESH MACRO, TO CAUSE TERMINAL OUTPUT OF      * 08400020
*                    INFORMATIONAL MESSAGES                           * 08500020
*         IKJEBEUT - EDIT UTILITY INTERFACE ROUTINE, INVOKED VIA      * 08600020
*                    IKJEBESH MACRO TO PERFORM I/O OPERATIONS ON THE  * 08700020
*                    EDIT UTILITY DATA SET                            * 08800020
*         IKJPARS  - A TMP SERVICE ROUTINE, INVOKED VIA LINK TO       * 08900020
*                    SCAN OPERANDS OF THE SUBCOMMAND AND TO PROMPT    * 09000020
*                    FOR SYNTAX VALIDITY                              * 09100020
*                                                                     * 09200020
*    MACROS USED --                                                   * 09300020
*                                                                     * 09400020
*         CALL     - USED TO INVOKE THE BASIC/IPLI LANGUAGE           * 09500020
*                    PROCESSOR                                        * 09600020
*         IKJEBEMG - BUILDS LOCAL INSERTION LISTS FOR TERMINAL        * 09700020
*                    MESSAGES                                         * 09800020
*         IKJEBEMI - GENERATES RELATIVE MESSAGE NUMBERS AND INSERTION * 09900020
*                    OFFSETS                                          * 10000020
*         IKJEBEML - BUILDS MESSAGE PARAMETER LISTS                   * 10100020
*         IKJEBESH - INVOKES ANY EDIT SERVICE ROUTINE                 * 10200020
*         IKJEBESV - ENTRY LINKAGE AND ADDRESSABILITY WITHIN THE      * 10300020
*                    EDIT COMMAND PROCESSOR                           * 10400020
*         IKJPARM  - ESTABLISHES THE BEGINNING OF THE PARAMETER       * 10500020
*                    CONTROL LIST FOR IKJPARS                         * 10600020
*         IKJIDENT - ESTABLISHES PARAMETER CONTROL ENTRIES            * 10700020
*                    FOR '*', LINE NUMBERS, AND COUNT IN THE          * 10800020
*                    PARAMETER CONTROL LIST                           * 10900020
*         IKJENDP  - MARKS THE END OF THE PARAMETER CONTROL LIST      * 11000020
*         LINK     - USED TO INVOKE IKJPARS                           * 11100020
*                                                                     * 11200020
* EXITS, NORMAL --                                                    * 11300020
*    CONTROL IS RETURNED TO IKJEBEMA BY BRANCHING ON THE CONTENTS     * 11400020
*    OF REGISTER FOURTEEN (14).                                       * 11500020
*                                                                     * 11600020
* EXITS, ERROR --                                                     * 11700020
*    CONTROL IS RETURNED TO IKJEBEMA BY BRANCHING ON                  * 11800020
*    THE CONTENTS OF REGISTER FOURTEEN (14) WITH AN ERROR CODE SET IN * 11900020
*    REGISTER FIFTEEN (15).                                           * 12000020
*                                                                     * 12100020
* TABLES/WORK AREAS --                                                * 12200020
*                                                                     * 12300020
*    IKJEBECA, THE EDIT COMMUNICATION AREA CONTAINS PARAMETER LIST    * 12400020
*    STORAGE FOR SERVICE ROUTINES INVOKED BY IKJEBEDE, A WORK AREA    * 12500020
*    'CASCWKA' FOR THE USE OF ALL EDIT SUBCOMMANDS, A POINTER TO      * 12600020
*    THE CURRENT INPUT BUFFER, AND VARIOUS CONTROL INFORMATION.       * 12700020
*                                                                     * 12800020
*    THE IKJPARS PARAMETER CONTROL LIST SPECIFIES POSITIONAL          * 12900020
*    OPERANDS THAT IKJPARS IS EXPECTED TO SCAN OFF.                   * 13000020
*                                                                     * 13100020
*    THE IKJPARS PARAMETER DESCRIPTOR LIST CONTAINS POINTERS TO AND   * 13200020
*    LENGTHS OF 'PARSED' OPERANDS.  THE IKJEBEDE VALIDITY CHECK       * 13300020
*    ROUTINE, 'DEVALCHK', DETERMINES BINARY VALUES OF OPERANDS,       * 13400020
*    AND CHECKS LINE RANGES FOR VALIDITY.                             * 13500020
*                                                                     * 13600020
* ATTRIBUTES --                                                       * 13700020
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 13800020
*                                                                     * 13900020
* CHARACTER CODE DEPENDENCY --                                        * 14000020
*    THIS ROUTINE ASSUMES THAT THE HIGH ORDER ZONE OF A SIGNED,       * 14100020
*    UNPACKED DECIMAL BYTE CONTAINS NO BITS UNCOMMON TO THE HIGH      * 14200020
*    ORDER ZONE OF A CHARACTER DIGIT.                                 * 14300020
*                                                                     * 14400020
* NOTES --                                                            * 14500020
*                                                                     * 14600020
*    EXPLANATION OF ERROR CONDITIONS --                               * 14700020
*                                                                     * 15200020
*    AN INPUT/OUTPUT ERROR OCCURS WHEN IKJEBEUT IS UNABLE             * 15300020
*    TO SUCCESSFULLY READ OR DELETE AN EXISTING RECORD.               * 15400020
*                                                                     * 15500020
*    A LANGUAGE PROCESSOR FAILURE OCCURS WHEN A RETURN CODE OF        * 15600020
*    20 IS RETURNED BY THE BASIC/IPLI LANGUAGE PROCESSOR.             * 15700020
*                                                                     * 15800020
*    A SUBCOMMAND TERMINATION ERROR (RETURN CODE 08 TO IKJEBEMA)      8 15850020
*    OCCURS WHEN ANY OF THE FOLLOWING CONDITIONS HAS BEEN             * 15860020
*    ENCOUNTERED --                                                   * 15870020
*                                                                     * 15880020
*    (1) A COMMAND SYSTEM ERROR - A SERVICE ROUTINE HAS INDICATED     * 15890020
*    THAT IT CANNOT PERFORM ITS FUNCTION.                             * 15892020
*                                                                     * 15894020
*    (2) A LINE EXPECTED TO BE IN THE UTILITY DATA SET CANNOT BE      * 15896020
*    LOCATED.                                                         * 15898420
*                                                                     * 15898520
*    (3) A LINE NUMBER OPERAND HAS BEEN SPECIFIED FOR A 'NONUM'       * 15898820
*    DATA SET.                                                        * 15899220
*                                                                     * 15899320
*    (4) AN INVALID LINE NUMBER RANGE HAS BEEN SPECIFIED.             * 15899620
*                                                                     * 15907920
*    (5) A LANGUAGE PROCESSOR RETURN CODE OTHER THAN 0,4, OR 20       * 15925020
*    HAS BEEN ENCOUNTERED WHEN 'SCAN' IS NOT IN EFFECT, OR A RETURN   * 15933320
*    CODE OTHER THAN 0 OR 20 HAS BEEN ENCOUNTERED WHEN 'SCAN' IS IN   * 15941620
*    EFFECT.                                                          * 15949920
*                                                                     * 15959920
*    (6) A CONDITIONAL GETMAIN FAILED IN A SERVICE ROUTINE.           * 15969920
*                                                                     * 15979920
*    (7) IKJPARS COULD NOT PROMPT USER FOR REQUIRED POSITIONAL        * 15989920
*    OPERAND -- USER IS NOPROMPT.                                     * 15991920
*                                                                     * 15993920
*********************************************************************** 15999920
         EJECT                                                          19600020
*********************************************************************** 19700020
*                                                                       19800020
* THE FOLLOWING EQU'S ALLOW SYMBOLIC ADDRESSING OF REGISTERS            19900020
*                                                                       20000020
*********************************************************************** 20100020
PARMREG0 EQU   0                   PARAMETER REGISTER                   20200020
PARMREG1 EQU   1                   PARAMETER REGISTER                   20300020
COMMREG  EQU   9                   COMMUNICATION AREA ADDRESS           20400020
BASEREG  EQU   11                  BASE REGISTER                        20500020
DATAREG  EQU   12                  DATA ADDRESS                         20600020
SAVEREG  EQU   13                  SAVE AREA ADDRESS                    20700020
RETREG   EQU   14                  CONTAINS RETURN ADDRESS              20800020
CALLREG  EQU   15                  ENTRY POINT FOR CALLED ROUTINES      20900020
RETCDREG EQU   15                  RETURN CODE REGISTER                 21000020
REG0     EQU   0                   WORK REGISTER                        21100020
REG2     EQU   2                   WORK REGISTER                        21200020
REG3     EQU   3                   WORK REGISTER                        21300020
REG4     EQU   4                   WORK REGISTER                        21400020
REG5     EQU   5                   WORK REGISTER                        21500020
REG6     EQU   6                   WORK REGISTER                        21600020
REG7     EQU   7                   WORK REGISTER                        21700020
REG8     EQU   8                   WORK REGISTER                        21800020
REG15    EQU   15                  WORK REGISTER                        21900020
         EJECT                                                          22000020
*********************************************************************** 22100020
*                                                                       22200020
* THE FOLLOWING EQU'S ALLOW SYMBOLIC REFERENCE TO CHARACTER             22300020
* AND DECIMAL CONSTANTS                                                 22400020
*                                                                       22500020
*********************************************************************** 22600020
ASTERISK EQU   C'*'                ASTERISK REPRESENTATION              22700020
CHARBLNK EQU   C' '                CHARACTER BLANK                      22800020
CHARZERO EQU   C'0'                CHARACTER ZERO REPRESENTATION        22900020
DEATTNIS EQU   8                   MASK FOR BCR INSTRUCTION             23000020
ELEVEN   EQU   11                  DISPLACEMENT OF ELEVEN               23100020
FIVE     EQU   5                   DISPLACEMENT OF FIVE                 23200020
FOUR     EQU   4                   CONSTANT 4 FOR COMPARISONS           23250020
IOERRRC  EQU   12                  RETURN CODE FOR I/O ERROR IS 12      23300020
LENGTH0  EQU   0                   LENGTH OF ZERO                       23400020
LENGTH1  EQU   0                   LENGTH OF ONE                        23500020
LENGTH4  EQU   4                   LENGTH OF FOUR               SA61391 23550021
LENGTH5  EQU   5                   LENGTH OF FIVE                       23600020
LENGTH8  EQU   8                   LENGTH OF EIGHT                      23700020
LENGTH12 EQU   12                  LENGTH OF TWELVE                     23800020
LENGTH15 EQU   15                  LENGTH OF FIFTEEN                    23900020
LENGTH16 EQU   16                  LENGTH OF SIXTEEN                    24000020
LOW      EQU   4                   MASK FOR BCR INSTRUCTION             24100020
NEXTBYTE EQU   1                   DISPLACEMENT OF ONE                  24200020
NOBRANCH EQU   0                   SPECIFIES NO BRANCH FOR BCTR         24300020
ONE      EQU   1                   DISPLACEMENT OF ONE                  24400020
RC8       EQU   8                  RETURN CODE 08 TO IKJEBEMA           24450020
SEVEN    EQU   7                   DISPLACEMENT OF SEVEN                24500020
SIGBYTES EQU   0                   DISPLACEMENT OF ZERO                 24600020
SIXTEEN  EQU   16                  CONSTANT 16 FOR COMPARISONS          24650020
THISBYTE EQU   0                   DISPLACEMENT OF ZERO                 24700020
TWENTY   EQU   20                  CONSTANT 20 FOR COMPARISONS          24750020
WORD     EQU   4                   LENGTH OF ONE WORD                   24800020
WORD1    EQU   0                   DISPLACEMENT OF FIRST WORD           24900020
WORD2    EQU   4                   DISPLACEMENT OF SECOND WORD          25000020
WORD3    EQU   8                   DISPLACEMENT OF THIRD WORD           25100020
         SPACE 2                                                        25200020
         IKJEBEMI (312,313,501,502,503,504,505) GENERATE MESSAGE DATA   25300020
         EJECT                                                          25400020
*********************************************************************** 25500020
*                                                                       25600020
*                             PROLOG                                    25700020
*                                                                       25800020
*********************************************************************** 25900020
         SPACE 2                                                        26000020
         IKJEBESV (14,12),,,COMMREG=(1) ENTRY LINKAGE                   26100020
         USING IKJEBECA,COMMREG    ADDRESSABILITY                       26200020
         ST    REG15,DESVAREA      STORE POINTER TO NEXT SAVE AREA FOR X26300020
                                   THE VALIDITY CHECK ROUTINE           26400020
         TM    CAPTIBFR,CAOPERND   ARE ANY OPERANDS SPECIFIED           26500020
         BO    PARSEIT             YES-PARSE TO SCAN OPERANDS           26600020
         LA    REG2,ONE            INITIALIZE COUNT TO ONE              26700020
         ST    REG2,DECOUNT        IF NO OPERANDS PRESENT               26800020
         B     ASTERRTN            TREAT AS IF '*' WERE SPECIFIED       26900020
         EJECT                                                          27000020
*********************************************************************** 27100020
*IN ORDER TO INVOKE IKJPARS,A PARAMETER LIST ADDRESS IS PASSED          27200020
*IN REGISTER ONE. THE LIST INCLUDES -                                   27300020
*        WORD 1 PTR TO UPT                                              27400020
*        WORD 2 PTR TO ECT                                              27500020
*        WORD 3 PTR TO EDIT ATTENTION ECB                               27600020
*        WORD 4 PTR TO PCL                                              27700020
*        WORD 5 PTR TO ANS. PLACE(ANS. PLACE POINTS TO PDL)             27800020
*        WORD 6 PTR TO COMMAND BUFFER                                   27900020
*        WORD 7 PTR TO COMMUNICATIONS AREA(USED BY VALIDITY CHECK       28000020
*                   ROUTINE TO ADDRESS SUBCOMMAND WORK AREA.)           28100020
*BEFORE PASSING CONTROL TO IKJPARS, FLAGS ARE INITIALIZED OFF FOR       28200020
*THE VALIDITY CHECK ROUTINE                                             28300020
*********************************************************************** 28400020
         SPACE 2                                                        28500020
PARSEIT  NI    DEFLAGS,DEZEROES    INITIALIZE FLAGS FOR DEVALCHK        28600020
         L     REG2,PCLADDR        POINTER TO PARSE PCL                 28700020
         LA    REG3,CAPTPRSD       POINTER TO ANSWER PLACE              28800020
         L     REG4,CAPTIBFR       POINTER TO INPUT BUFFER              28900020
         ST    REG2,CATMPLST+PPLPCL-PPL STORE PCL ADDRESS               29000020
*                                       IN PARAMETER LIST               29100020
         ST    REG3,CATMPLST+PPLANS-PPL STORE ANSWER ADDRESS            29200020
*                                       IN PARAMETER LIST               29300020
         ST    REG4,CATMPLST+PPLCBUF-PPL STORE POINTER TO COMMAND       29400020
*                                    BUFFER IN PARAMETER LIST           29500020
         ST    COMMREG,CATMPLST+PPLUWA-PPL STORE COMMUNICATION AREA     29600020
*                                    ADDRESS IN PARAMETER LIST          29700020
* A 'LINK' MACRO IS USED TO DYNAMICALLY BUILD THE PARSE PARAMETER LIST  29800020
* AND PASS CONTROL TO IKJPARS                                           29900020
         LINK  EP=IKJPARS,DCB=0,MF=(E,CATMPLST),SF=(E,DEPARM)           30000020
         EJECT                                                          30100020
*********************************************************************** 30200020
*WHEN CONTROL IS RETURNED FROM PARSE,OPERANDS HAVE BEEN CHECKED         30300020
*FOR VALIDITY. LINE VALUES OR COUNT HAVE BEEN SET BY THE                30400020
*VALIDITY CHECK ROUTINES.  FIVE RETURN CODES ARE POSSIBLE -             30500020
*        RETURN CODE     ACTION BY IKJEBEDE                             30600020
*        0-SUCCESSFUL    CONTINUE PROCESSING SUBCOMMAND                 30700020
*        4-COMMAND       RETURN TO MAIN CONTROLLER WITH RETURN CODE     30800020
*          INCOMPLETE    08 (CAN'T COMPLETE)                            30900020
*        8-ATTN ISSUED   RETURN TO MAIN CONTROLLER                      31000020
*       12-INVALID PARMS COMMAND SYSTEM ERROR MESSAGE                   31100020
*       16-NO SPACE      'NOT ENOUGH MAIN STORAGE' MESSAGE              31200020
*********************************************************************** 31300020
         SPACE 2                                                        31400020
*THIS BRANCH TABLE IS POSITION DEPENDENT                                31500020
         B     NOCORE@(RETCDREG)   BRANCH ON RETURN CODE                31600020
         B     NORMAL              CONTINUE PROCESSING                  31700020
         B     GOBACKR8            RETURN WITH RETURN CODE 08           31800020
         B     GOBACK              RETURN                               31900020
         B     DEPRSERR            DIAGNOSE ERROR                       32000020
NOCORE   LA    REG2,DENOCORE       LOAD ADDRESS OF MESSAGE LIST         32100020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            32300020
*                                  RETURN TO IKJEBEMA WITH RC=8.        32500020
         SPACE 2                                                        32700020
         EJECT                                                          33000020
NORMAL   TM    DEFLAGS,DEASTER     IF '*' WAS SPECIFIED DELETE 'COUNT'  33100020
         BO    ASTERRTN            LINES STARTING AT THE CURRENT LINE   33200020
         TM    DEFLAGS,DEBADRNG    IS LINE RANGE VALID                  33300020
         BZ    VALIDRNG              YES - CONTINUE PROCESSING          33400020
         LA    REG2,RNGINVAL         NO  - INVALID RANGE MESSAGE        33500020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            33600020
*                                  RETURN TO IKJEBEMA (RC IS 08.)       33700020
VALIDRNG EQU   *                                                        34000020
         TM    CACFLAG1,CANONUM    IS DATA SET LINE NUMBERED            34100020
         BZ    LINERTN               YES - BRANCH TO DELETE LINES       34200020
*                                          IN THE UTILITY DATA SET      34300020
*                                    NO  - ISSUE DIAGNOSTIC MESSAGE     34400020
         LA    REG2,DEDSNONM       ADDRESS MESSAGE PARAMETERS           34500020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            34600020
*                                  RETURN TO IKJEBEMA  (RC IS 08.)      34700020
         EJECT                                                          35000020
*********************************************************************** 35100020
* FOLLOWING IS THE MAIN ROUTINE THAT DELETES LINES IN A RANGE           35200020
*(LINE NUMBER 1, LINE NUMBER 2).  A TWO-WORD PARAMETER LIST             35300020
* IS PASSED TO THE EDIT SERVICE ROUTINE IKJEBEUT TO PERFORM             35400020
* READ AND DELETE OPERATIONS ON THE UTILITY DATA SET.                   35500020
*********************************************************************** 35600020
LINERTN  L     PARMREG1,CAPTCDCB   WORD 1 POINTS TO CURRENT DCB WITH    35700020
         ST    PARMREG1,DEPTCDCB          OPERATION CODE FOR DELETE     35800020
         MVI   DEUTOPCD,DEOPCODC          CURRENT LINE IN HIGH ORDER   X35900020
                                          BYTE                          36000020
         LA    PARMREG1,DEVALUE1   WORD 2 POINTS TO BINARY VALUE OF     36100020
         ST    PARMREG1,DECURLIN          STARTING LINE NUMBER TO       36200020
         OI    DECURLIN,DELASTWD          REPLACE CURRENT LINE NUMBER  X36300020
                                          HIGH ORDER BIT=1 - LAST PARAM 36400020
         BAL   REG6,UTILITY        INVOKE SUBROUTINE TO CALL IKJEBEUT   36500020
         LH    REG8,H4             INIT FOR IKJEBEUT RC COMPARES        36600020
         CR    RETCDREG,REG8       WAS DELETE SUCCESSFUL                36700020
         BL    DELETELR              YES- A RANGE OF LINES ARE DELETED  36800020
         BH    IOERROR               I/O ERROR- RETURN RC=12           X36900020
                                     LINE NOT FOUND- PRINT 'LINE NUMBERX37000020
                                        NOT FOUND IN DATA SET' MESSAGE  37100020
         EJECT                                                          37200020
*********************************************************************** 37300020
* FALLING THROUGH THE PRECEDING CODE DENOTES THE FACT THAT THE FIRST    37400020
* LINE SPECIFIED BY THE USER DOES NOT EXIST.  THE FOLLOWING SECTION     37500020
* BUILDS THE INSERTION LIST FOR LINE NUMBER IN THE 'LINE NUMBER         37600020
* (LINE NUMBER) NOT FOUND' MESSAGE.                                     37700020
*********************************************************************** 37800020
         SPACE 2                                                        37900020
LINENF   L     REG5,DEVALUE1       CONVERT STARTING LINE VALUE TO       38000020
*                                  DECIMAL                              38100020
         CVD   REG5,DEPACK                                              38200020
         UNPK  DEFIELD1(LENGTH8),DEPACK@(LENGTH5) CHANGE DEC DIGITS     38300020
*                                  CHAR DIGITS AND PLACE IN INSERTION   38400020
*                                  FIELD                                38500020
         OI    DEFIELD1+SEVEN,CHARZERO INSURE LAST BYTE IS CHAR DIGIT   38600020
         LH    REG8,MAXZEROS       SET COUNTER FOR ZERO SUPPRESSION     38700020
         LA    REG7,DEFIELD1       ADDRESS CHARACTER FIELD              38800020
*THIS LOOP TESTS FOR LEADING ZEROES                                     38900020
LZLOOP   CLI   THISBYTE(REG7),CHARZERO   IS BYTE A CHARACTER ZERO       39000020
         BNE   LDZERO1               NO- DETERMINE COUNT OF LEAD ZEROES 39100020
         LA    REG7,NEXTBYTE(,REG7) YES- ADDRESS NEXT BYTE              39200020
         BCT   REG8,LZLOOP         REPEAT LOOP 3 TIMES                  39300020
LDZERO1  EQU   *                                                        39400020
         SH    REG8,MAXZEROS       ADJUST COUNTER TO NUMBER OF          39500020
         LPR   REG7,REG8           ZEROES ENCOUNTERED                   39600020
         BNZ   LDZERO2             IF COUNTER NON-ZERO, BRANCH TO       39700020
*                                  SUPPRESS LEADING ZEROES              39800020
         LA    REG7,LENGTH12       SET INSERTION LENGTH TO 12           39900020
         STH   REG7,DELEN1                                              40000020
         B     LDZERO3             CONTINUE PROCESSING INSERTION        40100020
LDZERO2  EQU   *                                                        40200020
         LA    REG8,DEFIELD1(REG7) ADDRESS FIRST SIGNIFICANT BYTE       40300020
         SH    REG7,MAXZEROS       COMPUTE FIELD LENGTH                 40400020
         LPR   REG7,REG7           AND ADJUST FOR MVC                   40500020
         EX    REG7,MVCLINE        MOVE LINE NUMBER TO SUPPRESS         40600020
*                                  LEADING ZEROS                        40700020
         LA    REG8,LENGTH5(,REG7) COMPUTE LENGTH OF INSERTION          40800020
         STH   REG8,DELEN1         AND STORE IN LENGTH FIELD OF INSERT  40900020
LDZERO3  EQU   *                                                        41000020
         LA    REG8,M504IN1        SET INSERTION OFFSET                 41100020
         STH   REG8,DEOFF1                                              41200020
         SR    REG8,REG8           SPECIFY ONE INSERTION ONLY           41300020
         ST    REG8,DEPTR1                                              41400020
         SPACE 2                                                        41500020
* INSERTION PROCESSING IS COMPLETE                                      41600020
         MVC   DEPARM(LENGTH12),DELNFLST MOVE PARM LIST TO WORK AREA    41700020
         LA    REG8,DEPTR1         ADDRESS INSERTION                    41800020
         ST    REG8,DEPARM+WORD2   AND STORE IN PARAMETER LIST          41900020
         LA    REG2,DEPARM         ADDRESS PARM LIST                    42000020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            42200020
*                                  RETURN TO IKJEBEMA (RC IS 08.)       42400020
         EJECT                                                          42600020
*********************************************************************** 42700020
*THE FOLLOWING CODE IS GIVEN CONTROL WHEN A LINE RANGE IS TO BE DELETED 42800020
*SINGLE LINES ARE TREATED AS A LINE RANGE,I.E. DEVALUE2=DEVALUE1        42900020
*********************************************************************** 43000020
         SPACE 2                                                        43100020
DELETELR LA    REG7,LINELOOP       SET REGISTER 7 FOR START ADDRESS     43200020
         LA    REG5,DETEMPBF       INITIALIZE THE THIRD WORD OF         43300020
         ST    REG5,DEREADBF       PARMLIST TO READ BUFFER ADDRESS      43400020
         MVI   DEREADBF,DELASTWD   PARMLIST HAS MAX LENGTH = 3 WORDS    43500020
         ST    REG5,DECURLIN       DECURLIN POINTS TO KEY FOR IKJEBEUT  43600020
         L     REG5,DEVALUE1       INITIALIZE KEY FIELD OF READ         43700020
         ST    REG5,DETEMPBF       BUFFER TO STARTING LINE NUMBER       43800020
LINELOOP EQU   *                                                        43900020
         L     REG4,DETEMPBF       SAVE KEY OF LAST LINE DELETED        44000020
         MVI   DEUTOPCD,DEOPCORN   READ THE NEXT RECORD                 44100020
         NI    DECURLIN,DEZEROES   WITH 3-WORD PARAMETER LIST           44200020
         BAL   REG6,UTILITY        BRANCH TO INVOKE IKJEBEUT            44300020
         LTR   RETCDREG,RETCDREG   WAS READ SUCCESSFUL                  44400020
         BNZ   READPRV@(RETCDREG)    NO- BRANCH TABLE DETERMINES ACTION 44500020
         CLC   DEVALUE2(WORD),DETEMPBF YES- IS THE RECORD KEY          X44600020
                                            GT THE ENDING LINE NUMBER   44700020
         BL    READPRV                  YES- SET '*' AND RETURN         44800020
         TM    CAATTN,CAATTNIS          NO- ATTENTION ISSUED            44900020
         BO    READPRV                     YES- SET * AND RETURN        45000020
         MVI   DEUTOPCD,DEOPCODC           NO- DELETE LINE BY KEY       45100020
         XI    DECURLIN,DELASTWD               WITH 2-WORD PARMLIST     45200020
         BAL   REG6,UTILITY        DELETE CURRENT LINE                  45300020
         CR    RETCDREG,REG8       WAS DELETE SUCCESSFUL                45400020
         BCR   LOW,REG7              YES- LOOP TO READ NEXT RECORD      45500020
         BE    DECSEUTL              NO- LOGIC ERROR-LINE WAS READ      45600020
*                                        SUCCESSFULLY BUT NOT FOUND     45700020
*                                        FOR DELETION                   45800020
         BH    IOERROR               NO- I/O ERROR OCCURRED             45900020
        EJECT                                                           46000020
*********************************************************************** 46100020
*THE FOLLOWING SECTION DELETES 'COUNT' LINES BEGINNING AT THE CURRENT   46200020
*LINE. THE SERVICE ROUTINE IKJEBEUT PERFORMS READS AND DELETES.         46300020
*********************************************************************** 46400020
         SPACE 2                                                        46500020
ASTERRTN TM    CAATTN,CAATTNIS     ATTN ISSUED                          46600020
         BO    GOBACK              IF SO, RETURN TO IKJEBEMA            46700020
         L     REG2,CACURNUM       SAVE THE CURRENT LINE REFERENCE      46800020
         ST    REG2,DESVAREA       FOR POSSIBLE BASIC/IPLI PROCESSING   46900020
         L     REG2,CAPTCDCB       PTR TO CURRENT DCB IN WORD 1         47000020
         ST    REG2,DEPTCDCB           OF IKJEBEUT PARMLIST             47100020
         MVI   DEUTOPCD,DEOPCODC   SPECIFY DELETE CURRENT LINE          47200020
         LA    REG2,CACURNUM       SPECIFY * AS CURRENT LINE            47300020
         ST    REG2,DECURLIN                                            47400020
ASTDELX  EQU   *                                                        47450020
         OI    DECURLIN,DELASTWD   A 2-WORD PARMLIST USED FOR DELETE    47500020
         BAL   REG6,UTILITY        DELETE CURRENT LINE                  47600020
         LH    REG8,H4             INIT FOR IKJEBEUT RC COMPARES        47700020
         CR    RETCDREG,REG8       WAS DELETE SUCCESSFUL.               47800020
         BL    ASTINIT               YES- BRANCH TO SET UP LOOP         47900020
         BH    IOERROR               I/O ERROR- RETURN RC=12            48000020
*                                  LINE NOT FOUND - CHECK FOR           48008020
*                                     KEY=ZERO.  IF KEY IS ZERO,        48016020
*                                     DELETE COUNT LINES                48024020
*                                     BEGINNING WITH THE FIRST          48032020
*                                     LINE OF THE DATA SET.             48040020
         L     REG2,CACURNUM       ACQUIRE CURRENT LINE REFERENCE.      48048020
         LTR   REG2,REG2           TEST FOR KEY OF ZERO.                48056020
         BNE   ASTNOTFD            IF NOT ZERO, BRANCH TO ISSUE         48064020
*                                       LINE NOT FOUND MESSAGE          48072020
         MVI   DEUTOPCD,DEOPCORF   SPECIFY READ FIRST OPERATION         48080020
         BAL   REG6,UTILITY        INVOKE IKJEBEUT FOR UTILITY          48088020
*                                       I/O OPERATION                   48096020
         CR    RETCDREG,REG8       TEST FOR NORMAL RETURN               48104020
         BL    ASTFIRST            BRANCH TO CONTINUE PROCESSING        48112020
*                                       IF RETURN NORMAL                48120020
         BH    IOERROR             RETURN WITH CODE 12 IF               48128020
*                                       UTILITY I/O ERROR               48136020
*                                       ENCOUNTERED                     48144020
         LA    REG2,EMPTYDS        ADDRESS 'EMPTY DATA SET'             48152020
*                                       MESSAGE PARAMETERS              48160020
         B     DEPUTRET            BRANCH TO PUT MESSAGE AND            48170020
*                                  RETURN TO IKJEBEMA                   48180020
ASTFIRST EQU   *                                                        48208020
         ST    PARMREG1,DECURLIN   SPECIFY FIRST LINE AS CURRENT        48216020
         MVC   DESVAREA(LENGTH4),0(PARMREG1)  SAVE KEY IN CASE  SA69232 48224021
*                                  BASIC OR IPLI DS TYPE        SA61391 48234021
         MVI   DEUTOPCD,DEOPCODC   SPECIFY DELETE OPERATION             48248020
         B     ASTDELX             BRANCH TO DELETE FIRST LINE          48256020
ASTNOTFD EQU   *                                                        48264020
         LA    REG2,DELNFLST       SPECIFY LINE NOT FOUND MESSAGE       48272020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            48372020
*                                  RETURN TO IKJEBEMA (RC IS 08.)       48472020
ASTINIT  L     REG7,DECOUNT        SET COUNTER FOR LOOP                 48800020
         LA    REG2,DETEMPBF       SPECIFY READ BUFFER FOR IKJEBEUT     48900020
         ST    REG2,DEREADBF                                            49000020
         BCT   REG7,ASTNXT         IF INITIAL COUNT GT 1, CONTINUE      49100020
         B     READPRV             IF NOT, SET '*' AND RETURN           49200020
ASTNXT   LA    REG5,ASTLOOP        INITIALIZE REG5 WITH LOOP ADDRESS    49300020
         ST    REG2,DECURLIN       INITIALIZE POINTER TO RECORD KEY     49400020
         L     REG2,CACURNUM       INITIALIZE KEY FIELD OF READ         49500020
         ST    REG2,DETEMPBF       BUFFER TO '*'                        49600020
         MVI   DEREADBF,DELASTWD   MAX LENGTH OF PARMLIST = 3 WORDS     49700020
ASTLOOP  EQU   *                                                        49800020
         L     REG4,DETEMPBF       SAVE KEY OF LAST LINE DELETED        49900020
         MVI   DEUTOPCD,DEOPCORN   READ NEXT RECORD WITH 3-WORD         50000020
         NI    DECURLIN,DEZEROES   PARAMETER LIST                       50100020
         BAL   REG6,UTILITY        BRANCH TO INVOKE IKJEBEUT            50200020
         LTR   RETCDREG,RETCDREG   WAS READ SUCCESSFUL                  50300020
         BNZ   READPRV@(RETCDREG)    NO- LINE NOT FOUND OR I/O ERROR    50400020
         TM    CAATTN,CAATTNIS       YES- ATTN ISSUED                   50500020
         BO    READPRV                 YES- SET * AND RETURN            50600020
ASTDELET MVI   DEUTOPCD,DEOPCODC       NO- DELETE CURRENT LINE          50700020
         XI    DECURLIN,DELASTWD   SPECIFY 2-WORD PARAMETER LIST        50800020
         BAL   REG6,UTILITY        BRANCH TO INVOKE IKJEBEUT            50900020
         LTR   RETCDREG,RETCDREG   WAS DELETE SUCCESSFUL                51000020
         BNZ   ABNRMRC@(RETCDREG)    NO- LOGIC ERROR OR I/O ERROR       51100020
         BCTR  REG7,REG5             YES- REPEAT LOOP 'COUNT' TIMES     51200020
         SPACE 2                                                        51300020
READPREV B     READPRV             RECORD NOT FOUND- SET * AND RETURN   51400020
         B     IOERROR             I/O ERROR- RETURN WITH RC=12         51500020
ABNORMRC EQU   *                                                        51600020
         B     DECSEUTL            ISSUE COMMAND SYSTEM ERROR MSG       51700020
IOERROR  LA    RETCDREG,IOERRRC    SET RETURN CODE 12 TO IKJEBEMA       51800020
         B     GOBACKRC            RETURN TO IKJEBEMA                   51900020
         EJECT                                                          52000020
*********************************************************************** 52100020
* THIS SECTION GAINS CONTROL UPON DELETION OF THE SPECIFIED             52200020
* LINE RANGE OR UPON AN ATTENTION INTERRUPT AFTER AT LEAST ONE          52300020
* 'DELETE' AND ONE 'READ NEXT'.  THE LINE PREVIOUS TO THE LAST          52400020
* LINE READ IS READ.  IF PRESENT, '*' IS SET AND BASIC/IPLI PROCESSING  52500020
* DONE PRIOR TO RETURN TO IKJEBEMA.  AN I/O ERROR RESULTS IN            52600020
* RETURN TO IKJEBEMA WITH RC=12.  IF NOT FOUND, A 'READ NEXT'           52700020
* IS PERFORMED, A DIAGNOSTIC ISSUED, '*' SET TO ZERO AND BASIC/IPLI     52800020
* PROCESSING DONE.                                                      52900020
*********************************************************************** 53000020
        SPACE 2                                                         53100020
READPRV  EQU   *                                                        53200020
         MVI   DEUTOPCD,DEOPCORP   READ PREVIOUS RECORD                 53300020
         MVI   DECURLIN,DEZEROES   INSURE 3-WORD PARAMETER LIST         53400020
         BAL   REG6,UTILITY        BRANCH TO INVOKE IKJEBEUT            53500020
         CR    RETCDREG,REG8       WAS READ SUCCESSFUL                  53600020
         BL    SETAST                YES- SET * AND RETURN              53700020
         BH    IOERROR               I/O ERROR- RC=12                   53800020
* IF NO PREVIOUS LINE EXISTS, A 'READ FIRST' IS PERFORMED               53900020
* TO DETERMINE IF THE DATA SET IS EMPTY                                 54000020
         MVI   DEUTOPCD,DEOPCORF   SPECIFY READ FIRST RECORD            54100020
         BAL   REG6,UTILITY        BRANCH TO INVOKE IKJEBEUT            54200020
         CH    RETCDREG,H4         WAS READ SUCCESSFUL                  54300020
         BH    IOERROR               I/O ERROR- RETURN WITH RC=12       54400020
         BE    DEEMTYDS              NO- 'NO LINES IN DS' DIAGNOSTIC    54500020
         LA    REG2,TOPDS            YES- 'TOP OF DATA SET' DIAGNOSTIC  54600020
         BAL   REG6,PUTMSG         BRANCH TO PUT MESSAGE                54700020
         B     SETAST0             SET CURRENT LINE PTR                 54800020
DEEMTYDS EQU   *                                                        54900020
         LA    REG2,EMPTYDS        SPECIFY PARAMETER LIST               55000020
         BAL   REG6,PUTMSG         BRANCH TO PUT MESSAGE                55100020
SETAST0  EQU   *                                                        55200020
         SR    REG2,REG2           SET '*' TO ZERO                      55300020
         ST    REG2,CACURNUM                                            55400020
         LTR   RETCDREG,RETCDREG   WAS TERMINAL OUTPUT SUCCESSFUL       55500020
         BZ    DESYNCHK              YES- BRANCH TO CHECK FOR BASIC     55600020
*                                         OR IPLI DATA SET TYPE         55700020
         BAL   REG2,DECSEPUT         NO-  DIAGNOSE PUTLINE RETURN CODE  55800020
         B     DESYNCHK            BRANCH TO CHECK BASIC/IPLI           55900020
SETAST   EQU   *                                                        56000020
         L     REG2,DETEMPBF       '*' IS KEY OF RECORD                 56100020
         ST    REG2,CACURNUM                                            56200020
         OI    CACFLAG1,CALNTOVF   SET LINE VERIFY SWITCH ON            56400020
         EJECT                                                          56600020
*********************************************************************** 56700020
*THE FOLLOWING SECTION INITIALIZES PARAMETERS FOR SYNTAX CHECKER        56800020
*THE BUFFER,IN COMMAND INTERFACE FORMAT,IS PROVIDED FROM THIS ROUTINE'S 56900020
*WORK AREA.  ALL OTHER PARAMETERS WITH THE EXCEPTION OF ENTRY CODE      57000020
*AND OPERATION CODE WERE INITIALIZED BEFORE IKJEBEDE GAINED CONTROL     57100020
*********************************************************************** 57200020
DESYNCHK EQU   *                                                        57300020
         SPACE 2                                                        57400020
         CLI   CADSCODE,CAIPLI     IS DATA SET TYPE IPLI                57500020
         BE    DESYNCK1            IF SO BRANCH TO CALL IPLI SYN CHKR   57600020
         CLI   CADSCODE,CABASIC    IS DATA SET BASIC TYPE               57700020
         BNE   GOBACK              IF NOT BRANCH TO RETURN              57800020
DESYNCK1 EQU   *                                                        57900020
         L     CALLREG,CAPTCHK     ADDRESS THE SYNTAX CHECKER           58000020
         LTR   CALLREG,CALLREG     IS THE CHECKER LOADED                58100020
         BZ    GOBACK              IF NOT BRANCH TO RETURN              58200020
         LA    PARMREG1,DESYNBFR   WORD 1 OF PARMLIST IS A PTR TO THE   58300020
         ST    PARMREG1,CASYNBFR        BUFFER                          58400020
         ST    REG4,DEVALUE2       SET KEY FOR LAST LINE IN RANGE       58500020
         TM    DEFLAGS,DEASTER     ASTERISK SPECIFIED                   58600020
         BZ    DESYNLIN            IF NOT BYPASS START VALUE INIT       58700020
         L     REG2,DESVAREA       SET THE START VALUE                  58800020
         ST    REG2,DEVALUE1                                            58900020
DESYNLIN EQU   *                                                        59000020
         MVI   CASYNCD2,DEDEL1     OPERATION IS DELETE                  59100020
         SR    PARMREG1,PARMREG1   ZERO FIRST WORD OF                   59200020
         ST    PARMREG1,DECOUNT    COMMAND INTERFACE BUFFER             59300020
         LA    PARMREG1,CASYNLST   ADDRESS PARAMETER LIST               59500020
         CALL  (15)                INVOKE SYNTAX CHECKER                59600020
         EJECT                                                          59610020
*********************************************************************** 59620020
*                                                                       59630020
*   THE FOLLOWING SECTION DIAGNOSES RETURN CODES FROM THE ITF           59640020
*   LANGUAGE PROCESSOR.  POSSIBLE CODES AND ACTION ARE INDICATED        59650020
*   BELOW --                                                            59660020
*                                                                       59670020
*   CODE   MEANING            ACTION                                    59680020
*                                                                       59690020
*    00    NORMAL RETURN      RETURN TO IKJEBEMA WITH RC=0              59700020
*                                                                       59710020
*    04    MESSAGE RETURNED   RETURN TO IKJEBEMA WITH RC=0              59720020
*                                                                       59722020
*    NOTE -- IF RETURN CODE 04 IS ENCOUNTERED, AND 'CASCANSW'           59724020
*            IS B'1', AN ERROR MESSAGE IS ISSUED, AND THE RETURN        59726020
*            CODE TO IKJEBEMA IS 08.                                    59728020
*                                                                       59730020
*    16    GETMAIN FAILURE    ISSUE ERROR MESSAGE                       59740020
*                                                                       59750020
*    20    PROCESSOR FAILURE  RETURN TO IKJEBEMA WITH RC=16             59760020
*                                                                       59770020
*    OTHER SYSTEM ERROR       ISSUE ERROR MESSAGE                       59780020
*                                                                       59790020
*********************************************************************** 59800020
         SPACE 2                                                        59810020
         LTR   RETCDREG,RETCDREG   CHECK FOR RETURN CODE ZERO           59820020
         BZ    GOBACK              IF RC=0, RETURN TO IKJEBEMA          59830020
         LA    PARMREG1,FOUR       CREATE CONSTANT OF FOUR              59840020
         CR    PARMREG1,RETCDREG   CHECK FOR RETURN CODE = 4            59850020
         BNE   DEITF001            IF RETURN CODE IS NOT 4, BRANCH      59860020
*                                  TO CHECK FOR RC=16.                  59862020
         TM    CACFLAG1,CASCANSW   IF RETURN CODE IS 4, DETER-          59864020
*                                  MINE IF 'SCAN' IS IN EFFECT.         59866020
         BO    DEITFCSE            IF SO, BRANCH TO PUT ERROR           59868020
*                                  MESSAGE.                             59868420
         B     GOBACK              OTHERWISE, RETURN NORMALLY.          59868820
DEITF001 EQU   *                                                        59869220
         LA    PARMREG1,SIXTEEN    CREATE CONSTANT OF SIXTEEN           59870020
         CR    PARMREG1,RETCDREG   CHECK FOR RETURN CODE OF 16          59880020
         BE    NOCORE              IF RC = 16, BRANCH TO ISSUE          59890020
*                                       DIAGNOSTIC MESSAGE              59900020
         LA    PARMREG1,TWENTY     CREATE CONSTANT OF TWENTY            59910020
         CR    PARMREG1,RETCDREG   CHECK FOR RETURN CODE OF 20          59920020
         BNE   DEITFCSE            IF RC IS NOT 20, BRANCH TO           59930020
*                                       ISSUE COMMAND SYSTEM ERROR      59940020
*                                       MESSAGE                         59950020
         LA    RETCDREG,SIXTEEN    IF RC = 20, SET RETURN CODE 16       59960020
         B     GOBACKRC            AND RETURN TO IKJEBEMA               59970020
DEITFCSE EQU   *                                                        59980020
         MVC   DEPARM(LENGTH12),DECSELST OTHERWISE MOVE PARAMETER       60300020
*                                        LIST TO WORK AREA              60400020
         MVC   DEPTR1(LENGTH16),DESYNAME MOVE INS LIST TO WORK AREA     60500020
         MVC   DEFIELD1(LENGTH8),CASYNAME MOVE SYNTAX CHECKER NAME      60600020
         LA    REG3,LENGTH12       SPECIFY MAX LENGTH FOR INSERTION LST 60700020
         LA    REG4,DEFIELD1+SEVEN ADDRESS LAST BYTE OF NAME FIELD      60800020
DESNLOOP EQU   *                                                        60900020
         CLI   THISBYTE(REG4),CHARBLNK IS BYTE A BLANK                  61000020
         BNE   DESYNLEN            IF NOT, EXIT FROM LOOP               61100020
         BCTR  REG4,NOBRANCH       DECREMENT ADDRESS                    61200020
         BCT   REG3,DESNLOOP       REPEAT LOOP UNTIL COMPARE FAILS      61300020
DESYNLEN EQU   *                                                        61400020
         STH   REG3,DELEN1         SET LENGTH TO REFLECT SUPPRESSION    61500020
*                                  OF TRAILING BLANKS                   61600020
         MH    RETCDREG,H3         DETERMINE OFFSET INTO RETURN         61700020
*                                  CODE INSERTION TABLE                 61800020
         LA    REG3,DERCTABL(RETCDREG) ADDRESS INSERTION LIST FOR RC    61900020
         ST    REG3,DEPTR1         CHAIN FIRST AND SECOND INSERTIONS    62000020
*                                  FOR SECOND LEVEL MESSAGE             62100020
         LA    REG2,DEPTR1         ADDRESS CHAINED INSERTIONS           62120020
*                                  FOR SECOND-LEVEL MESSAGE             62140020
         ST    REG2,DEPARM+WORD3   PLACE ADDR IN PARMLIST               62160020
         LA    REG2,DEPARM         ADDRESS IKJEBEMS PARAMETER LIST      62200020
*                                                                       62250020
*    FALL THROUGH TO PUT MESSAGE AND RETURN TO IKJEBEMA WITH            62300020
*    RETURN CODE 08.                                                    62350020
*                                                                       62400020
         EJECT                                                          62800020
*********************************************************************** 62806020
*                                                                       62812020
*    THE FOLLOWING SECTION FO CODE IS EXECUTED FOR ALL MESSAGES         62818020
*    WHICH REQUIRE TERMINATION AFTER THEY ARE ISSUED.                   62824020
*                                                                       62830020
*********************************************************************** 62836020
         SPACE 2                                                        62842020
DEPUTRE8 EQU   *                                                        62844020
         OI    DEFLAGS,DESCTERM    INDICATE RETURN TO IKJEBEMA WITH     62846020
*                                  RETURN CODE 08.                      62846420
DEPUTRET EQU   *                                                        62848020
         BAL   REG6,PUTMSG         BRANCH TO PUT ERROR MESSAGE          62854020
         LTR   RETCDREG,RETCDREG   WAS TERMINAL OUTPUT SUCCESSFUL       62860020
         BZ    GOBACK              IF SO, BRANCH TO RETURN              62866020
         BAL   REG2,DECSEPUT       IF NOT, DIAGNOSE PUTLINE CODE        62872020
         B     GOBACK              AND RETURN TO IKJEBEMA               62878020
         EJECT                                                          62884020
*********************************************************************** 62900020
* THE FOLLOWING SUBROUTINE DIAGNOSES THE PUTLINE RETURN CODE            63000020
* RETURNED FROM IKJEBEMS.  THE 'COMMAND SYSTEM ERROR' DIAGNOSTIC        63100020
* IS ISSUED FOR THE FOLLOWING RETURN CODES --                           63200020
*                                                                       63300020
*     RETURN CODE        MEANING                                        63400020
*          8             NOWAIT SPECIFIED - NO OUTPUT                   63500020
*         12             INVALID PARAMETERS                             63600020
*         16             GETMAIN FAILURE                                63700020
*                                                                       63800020
* RETURN CODE 4 (ATTN ISSUED) IS IGNORED IF IT OCCURS.                  63900020
*                                                                       64000020
*********************************************************************** 64100020
         SPACE 2                                                        64200020
DECSEPUT EQU   *                                                        64300020
         CH    RETCDREG,H4         WAS ATTN ISSUED                      64400020
         BCR   DEATTNIS,REG2       IF SO, RETURN TO MAINLINE ROUTINE    64500020
         OI    DEFLAGS,DESCTERM    INDICATE RETURN TO IKJEBEMA WITH     64550020
*                                  RETURN CODE 08.                      64560020
         MVC   DEPTR1(LENGTH15),DEPUTLIN  MOVE INSERTION LIST FOR       64600020
*                                         SERVICE ROUTINE NAME          64700020
         MH    RETCDREG,H3         DETERMINE OFFSET INTO RC TABLE       64800020
         LA    REG3,DERCTABL(RETCDREG) ADDRESS INSERTION LIST           64900020
         ST    REG3,DEPTR1         CHAIN INSERTIONS                     65000020
         MVC   DEPARM(LENGTH12),DECSELST MOVE IKJEBEMS PARM LIST        65100020
         LA    REG3,DEPTR1         ADDRESS FIRST LEVEL-2 INSERTION      65200020
         ST    REG3,DEPARM+WORD3   AND STORE IN PARAMETER LIST          65300020
         LR    REG6,REG2           SPECIFY RETURN ADDRESS               65400020
         LA    REG2,DEPARM         ADDRESS PARM LIST                    65500020
         B     PUTMSG              BRANCH TO PUT MESSAGE                65600020
         EJECT                                                          65700020
*********************************************************************** 65800020
*                                                                       65900020
* THE FOLLOWING SECTION ISSUES THE 'COMMAND SYSTEM ERROR' DIAGNOSTIC    66000020
* FOR A RC OF 4 FROM IKJEBEUT ON A 'DELETE' AFTER A RC OF 0 ON A        66100020
* 'READ NEXT'.                                                          66200020
*                                                                       66300020
*********************************************************************** 66400020
DECSEUTL EQU   *                                                        66500020
         OI    DEFLAGS,DESCTERM    INDICATE RETURN TO IKJEBEMA WITH     66550020
*                                  RETURN CODE 08.                      66560020
         MVC   DEPARM(LENGTH12),DECSELST MOVE PARM LIST TO WORK AREA    66600020
         LA    REG2,DEUTINS        ADDRESS CHAINED INSERTIONS           66700020
         ST    REG2,DEPARM+WORD3   AND STORE IN PARM LIST               66800020
         LA    REG2,DEPARM         ADDRESS PARAMETER LIST               66900020
         BAL   REG6,PUTMSG         BRANCH TO PUT MESSAGE                67000020
         LTR   RETCDREG,RETCDREG   TERMINAL OUTPUT SUCCESSFUL           67100020
         BZ    READPREV            IF SO, BRANCH TO SET '*'             67200020
         BAL   REG2,DECSEPUT       OTHERWISE DIAGNOSE PUTLINE CODE      67300020
         B     READPRV             BRANCH TO SET THE CURRENT LINE '*'   67400020
         EJECT                                                          67500020
*********************************************************************** 67600020
*                                                                       67700020
* THIS SECTION DIAGNOSES COMMAND SYSTEM ERRORS FROM IKJPARS.            67800020
*                                                                       68000020
* RETURN CODE    MEANING                                                68100020
*                                                                       68200020
*    12          INVALID PARAMETERS                                     68400020
*                                                                       68500020
*********************************************************************** 68600020
DEPRSERR EQU   *                                                        68700020
         MVC   DEPARM(LENGTH12),DECSELST MOVE PARM LIST TO WORK AREA    68800020
         MVC   DEPTR1(LENGTH15),DEPRSINS MOVE INSERTION LIST FOR        68900020
*                                        SERVICE ROUTINE NAME           69000020
         LA    REG2,DEPTR1                                              69100020
         ST    REG2,DEPARM+WORD3   CHAIN INSERTION TO PARM LIST         69200020
         MH    RETCDREG,H3         DETERMINE OFFSET INTO RC TABLE       69300020
         LA    REG2,DERCTABL(RETCDREG) ADDRESS SECOND INSERTION         69400020
         ST    REG2,DEPTR1         CHAIN INSERTION TO FIRST             69500020
         LA    REG2,DEPARM         ADDRESS IKJEBEMS PARM LIST           69600020
         B     DEPUTRE8            BRANCH TO PUT MESSAGE AND            69700020
*                                  RETURN TO IKJEBEMA (RC IS 08.)       69800020
         EJECT                                                          69900020
GOBACK   EQU   *                                                        70000020
         TM    DEFLAGS,DESCTERM    DETERMINE IF DELETE IS ENDING        70050020
*                                  WITHOUT COMPLETING REQUESTED         70060020
*                                  FUNCTION.                            70070020
         BZ    GOBACKR0            IF NOT, BRANCH TO RETURN NORMALLY.   70080020
GOBACKR8 EQU   *                                                        70082020
         LA    RETCDREG,RC8        IF SO, SET RETURN CODE 08.           70090020
         B     GOBACKRC            BRANCH TO RETURN WITH CODE 08.       70092020
GOBACKR0 EQU   *                                                        70094020
         SR    RETCDREG,RETCDREG   RC=0 TO CALLING ROUTINE              70100020
GOBACKRC EQU   *                                                        70200020
         TM    CAPRSPDL,CAFREEDL   CHECK IF PDL RETURNED.               70300020
         BNZ   SKIPRLSA            IF NOT, BYPASS FREEMAIN OF PDL.      70400020
         LA    REG2,CAPTPRSD       FREE PARSE PDL                       70500020
         IKJRLSA (REG2)                                                 70600020
         OI    CAPRSPDL,CAFREEDL   INDICATE THAT ALL PDL'S HAVE         70630020
*                                  BEEN FREED.                          70660020
SKIPRLSA EQU   *                                                        70700020
         IKJEBERT (14,12),,RC=(15) RELOAD REGISTERS AND RETURN          70800020
        EJECT                                                           70900020
*********************************************************************** 71000020
*THIS SUBROUTINE IS USED FOR ALL READ AND DELETE OPERATIONS ON THE      71100020
*UTILITY DATA SET.  REG6 CONTAINS THE RETURN ADDRESS                    71200020
*********************************************************************** 71300020
UTILITY  LA    REG2,DEUTPARM       ADDRESS OF IKJEBEUT PARMLIST         71400020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(REG2)),         X71500020
               MF=(E,DEPARM)       PERFORM REQUESTED OPERATION          71600020
         BR    REG6                RETURN TO MAIN ROUTINE               71700020
         EJECT                                                          71800020
*********************************************************************** 71900020
*THE FOLLOWING SECTION PUTS OUT ALL MESSAGES WHOSE PARAMETER LISTS      72000020
*RESIDE IN LOCAL STORAGE.  IT GAINS CONTROL THROUGH A BAL AND RETURNS   72100020
*VIA REGISTER 6.  REGISTER 2 CONTAINS THE ADDRESS OF THE PARAMETER LIST 72200020
*********************************************************************** 72300020
PUTMSG   IKJEBESH (COMMREG),IKJEBEMS,PARAM=((COMMREG),(REG2)),         X72400020
               MF=(E,DEPARM)       PRINT REQUESTED MESSAGE              72500020
         BR    REG6                RETURN TO MAINLINE ROUTINE           72600020
         EJECT                                                          72700020
*********************************************************************** 72800020
* THE FOLLOWING SUBROUTINE IS A VALIDITY CHECK EXIT FROM IKJPARS.  IT   72900020
* GAINS CONTROL AS EACH OPERAND IS PARSED AND SETS BINARY VALUES FOR    73000020
* LINE NUMBER 1, LINE NUMBER 2, AND COUNT.  IN THE CASE OF '*' IT SETS  73100020
* A FLAG BIT.  IT ALSO CHECKS FOR AN INVALID LINE RANGE AND SETS A      73200020
* SWITCH WHEN THIS OCCURS.  NORMAL RETURN IS WITH RC=0 TO IKJPARS.    * 73300020
* THE ONLY POSSIBLE INVALID OPERAND IS A ZERO COUNT.  IN THIS CASE    * 73400020
* A RETURN CODE OF 4 IS SET, AND IKJPARS WILL ISSUE A DIAGNOSTIC OR   * 73500020
* PROMPT, AS APPROPRIATE.                                             * 73600020
*********************************************************************** 73700020
         SPACE 2                                                        73800020
*********************************************************************** 73900020
*                            SPECIAL EQU'S                              74000020
*********************************************************************** 74100020
OPADDR   EQU   0                                                        74200020
LENGTH   EQU   4                                                        74300020
OPERAND  EQU   0                                                        74400020
OPNDPRES EQU   6                                                        74500020
INVALOP  EQU   4                   RC=4 FOR PARSE PROMPT/ERROR MSG      74600020
         SPACE 2                                                        74700020
DEVALCHK SAVE  (14,12),,*          ENTRY LINKAGE                        74800020
         BALR  BASEREG,REG0        ESTABLISH ADDRESSABILITY FOR MODULE  74900020
         USING *,BASEREG                                                75000020
         L     COMMREG,WORD2(,PARMREG1) GET COMMUNICATIONS AREA POINTER 75100020
         USING IKJEBECA,COMMREG    AND ESTABLISH ADDRESSABILITY         75200020
         L     REG15,DESVAREA      GET POINTER TO NEXT SAVE AREA        75300020
         ST    SAVEREG,WORD2(,REG15) CROSS CHAIN NEW AND OLD SAVE AREAS 75400020
         ST    REG15,WORD3(,SAVEREG)                                    75500020
         LR    SAVEREG,REG15       SAVE AREA ADDRESS IN REGISTER 13     75600020
         L     PARMREG1,OPADDR(,PARMREG1)  GET POINTER TO OPERAND       75700020
         LH    REG2,LENGTH(,PARMREG1) OBTAIN LENGTH OF OPERAND          75800020
         LR    REG3,PARMREG1       SAVE POINTER TO OPERAND ADDRESS      75900020
         L     PARMREG1,WORD1(,PARMREG1) LOAD OPERAND ADDRESS           76000020
         TM    DEFLAGS,DEOPND1     FIRST OPERAND TO BE CHECKED          76100020
         BO    SETVAL2             IF NOT, CHECK SECOND OPERAND         76200020
         LA    REG5,ONE            TEST FOR LENGTH=1                    76300020
         CR    REG2,REG5                                                76400020
         BNE   SETVAL1             IF LENGTH NE 1,* IS IMPOSSIBLE       76500020
         CLI   OPERAND(PARMREG1),ASTERISK IS FIRST OPERAND='*'          76600020
         BNE   SETVAL1             NO-BINARY VALUE OF LINE CALC         76700020
         OI    DEFLAGS,DEONEAST    YES-SET SWITCH TO INDICATE '*'       76800020
         ST    REG5,DECOUNT        SET COUNT TO ONE                     76900020
         B     GOBACKPS            PREPARE RETURN TO PARSE              77000020
         EJECT                                                          77100020
SETVAL2  TM    OPNDPRES(REG3),DE2OPS IS SECOND OPERAND PRESENT          77200020
         BZ    GOBACKPS            IF NOT, RETURN WITH RC=0             77300020
         BAL   REG6,PACKRTN        CONVERT OPERAND TO BINARY            77400020
         TM    DEFLAGS,DEASTER     WAS FIRST OPERAND='*'                77500020
         BO    SETCOUNT            YES-SECOND OPERAND IS 'COUNT'        77600020
         ST    REG2,DEVALUE2       NO-SECOND OPERAND IS 'LINE'          77700020
         XI    DEFLAGS,DE2OPS      HIGH ORDER BIT=0 FOR 2 OPNDS         77800020
         B     VALRANGE            CHECK LINE RANGE VALIDITY            77900020
SETCOUNT EQU   *                                                        78000020
         LTR   REG2,REG2           CHECK FOR COUNT OF ZERO              78060020
         BNZ   SETCTX              IF NOT, BRANCH TO STORE COUNT        78120020
         LA    RETCDREG,INVALOP    SET RETURN CODE FOR PROMPT/ERROR     78180020
*                                  MESSAGE                              78240020
         B     GOBCKPSX            BRANCH TO RETURN TO IKJPARS          78300020
SETCTX   EQU   *                                                        78360020
         ST    REG2,DECOUNT        STORE BINARY COUNT                   78420020
         B     GOBACKPS            RETURN TO IKJPARS WITH RC=0          78480020
VALRANGE CLC   DEVALUE1(WORD),DEVALUE2 IF OPND1 GT OPND2,INVALID RANGE  78600020
         BH    BADRANGE            OF LINES - SET FLAG AND RETURN       78700020
         BNH   GOBACKPS            IF OPND1 LT OPND2, RETURN            78800020
BADRANGE OI    DEFLAGS,DEBADRNG    SET SWITCH FOR INVALID LINE         X78900020
                                   RANGE                                79000020
         B     GOBACKPS            PREPARE RETURN TO PARSE              79100020
SETVAL1  BAL   REG6,PACKRTN        CONVERT OPERAND TO BINARY            79200020
         ST    REG2,DEVALUE1       SET LINE NUMBER                      79300020
         ST    REG2,DEVALUE2       SET ENDING LINE NUMBER IN CASE      X79400020
                                   OF ONE OPERAND SPECIFIED             79500020
         OI    DEFLAGS,DEOPND1     INDICATE 1ST OPERAND PROCESSED       79600020
         EJECT                                                          79700020
*********************************************************************** 79800020
* A NORMAL RETURN CODE OF ZERO IS ALWAYS RETURNED TO IKJPARS.           79900020
* IN THE EVENT OF AN INVALID LINE RANGE, DEVALCHK SETS A SWITCH         80000020
* TO INDICATE THIS ERROR - THE MAINLINE DELETE ROUTINE TAKES            80100020
* APPROPRIATE ACTION.                                                   80200020
*********************************************************************** 80300020
GOBACKPS SR    RETCDREG,RETCDREG   NORMAL RETURN - PARAMETER VALID      80400020
GOBCKPSX EQU   *                   BRANCH ADDR FOR RC=4                 80500020
         IKJEBERT (14,12),,RC=(15) RETURN LINKAGE TO PARSE              80600020
PACKRTN  BCTR  REG2,NOBRANCH       CONVERT OPERAND AREA TO BINARY       80700020
         EX    REG2,PACKIT         EX INSTRUCTION NECESSARY FOR PACK    80800020
         CVB   REG2,DEPACK         LENGTH IS VARIABLE 1-8 BYTES         80900020
         BR    REG6                RETURN                               81000020
PACKIT   PACK  DEPACK(LENGTH8),OPERAND(LENGTH1,PARMREG1)                81100020
         EJECT                                                          81200020
*********************************************************************** 81300020
* LOCAL STORAGE CONSTANTS AND ADDRESS CONSTANTS                         81400020
*********************************************************************** 81500020
         SPACE                                                          81600020
H3       DC    H'3'                CONSTANT                             81700020
         SPACE                                                          81800020
H4       DC    H'4'                CONSTANT                             81900020
         SPACE                                                          82000020
MAXZEROS DC    H'7'                MAX. NO. OF SUPPRESSED ZEROS         82100020
*                                  IN LINE NUMBER INSERTION             82200020
         SPACE                                                          82300020
MVCLINE  MVC   DEFIELD1(LENGTH0),SIGBYTES(REG8) SUPPRESS LEADING        82400020
*                                               ZEROES                  82500020
         SPACE                                                          82600020
PCLADDR  DC    V(IKJEBDE1)         ADDR OF IKJPARS PCL                  82700020
         SPACE 2                                                        82800020
*********************************************************************** 82900020
*THE FOLLOWING STORAGE CONTAINS ALL LOCAL MESSAGE PARAMETER LISTS AND   83000020
*INSERTION LISTS.                                                       83100020
*********************************************************************** 83200020
         SPACE                                                          83300020
DENOCORE IKJEBEML M312,,DESCNAME,,MF=L 'NOT ENOUGH STORAGE' MESSAGE     83400020
         SPACE                                                          83500020
DESCNAME IKJEBEMG ,M312IN1,'DELETE'                                     83600020
         EJECT                                                          83700020
DECSELST IKJEBEML M313,M3131,,,MF=L COMMAND SYSTEM ERROR MESSAGE        83800020
         SPACE                                                          83900020
DEPUTLIN IKJEBEMG ,M3131IN1,'PUTLINE' PUTLINE INSERTION                 84000020
         SPACE                                                          84100020
DEPRSINS IKJEBEMG ,M3131IN1,'PARSE' PARSE INSERTION                     84200020
         SPACE                                                          84300020
DESYNAME IKJEBEMG ,M3131IN1,'        ' SYNTAX CHECKER NAME INSERTION    84400020
         SPACE                                                          84500020
DEUTINS  IKJEBEMG DERC04,M3131IN1,'IKJEBEUT' IKJEBEUT INSERTION         84600020
         EJECT                                                          84700020
DERCTABL DS    0F                  TABLE OF INSERTION LISTS FOR RC'S    84800020
         SPACE 2                                                        84900020
DERC00   IKJEBEMG ,M3131IN2,'00'   RETURN CODE 0                        85000020
         SPACE 2                                                        85100020
DERC04   IKJEBEMG ,M3131IN2,'04'   RETURN CODE 4                        85200020
         SPACE 2                                                        85300020
DERC08   IKJEBEMG ,M3131IN2,'08'   RETURN CODE 8                        85400020
         SPACE 2                                                        85500020
DERC0C   IKJEBEMG ,M3131IN2,'12'   RETURN CODE 12                       85600020
         SPACE 2                                                        85700020
DERC10   IKJEBEMG ,M3131IN2,'16'   RETURN CODE 16                       85800020
         EJECT                                                          85900020
DERC14   IKJEBEMG ,M3131IN2,'20'   RETURN CODE 20                       86000020
         SPACE 2                                                        86100020
EMPTYDS  IKJEBEML M501,,,,MF=L       EMPTY DATA SET MESSAGE             86700020
         SPACE                                                          86800020
DEDSNONM IKJEBEML M502,,,,MF=L DS NOT LINE NUMBERED MESSAGE             86900020
         SPACE                                                          87000020
RNGINVAL IKJEBEML M503,,,,MF=L       INVALID RANGE MESSAGE              87100020
         SPACE                                                          87200020
DELNFLST IKJEBEML M504,,ASTERNF,,MF=L LINE NOT FOUND MESSAGE            87300020
         EJECT                                                          87400020
ASTERNF  IKJEBEMG ,M504IN1,'''*''' INSERTION FOR '*'                    87500020
         SPACE                                                          87600020
TOPDS    IKJEBEML M505,,,,MF=L       TOP OF DATA SET MESSAGE            87700020
         EJECT                                                          87800020
*********************************************************************** 87900020
* THE FOLLOWING IS THE EXPANSION OF THE PARAMETER CONTROL LIST          88000020
* THAT IS INPUT TO IKJPARS.  A CSECT IS GENERATED, SO IT IS             88100020
* NECESSARY TO INCLUDE AN EXTERNAL REFERENCE TO IT IN IKJEBEDE'S        88200020
* LOCAL STORAGE.                                                        88300020
*********************************************************************** 88400020
IKJEBDE1 IKJPARM                                                        88500020
PCE1     IKJIDENT 'LINE NUMBER OR *',ASTERISK,MAXLNTH=8,FIRST=NUMERIC, X88600020
               OTHER=NUMERIC,VALIDCK=DEVALCHK,                         X88660020
               PROMPT='SINGLE LINE NUMBER OR RESPECIFY LINE RANGE'      88720020
PCE2     IKJIDENT 'LINE NUMBER OR COUNT',MAXLNTH=8,FIRST=NUMERIC,      X88800020
               OTHER=NUMERIC,VALIDCK=DEVALCHK                           88900020
ENDPDL   IKJENDP                                                        89000020
         EJECT                                                          89100020
         IKJPPL                                                         89200020
         EJECT                                                          89300020
*********************************************************************** 89400020
*THE FOLLOWING SECTION IS THE EXPANSION OF IKJEBECA,THE EDIT            89500020
*COMMUNICATIONS AREA.  THE SUBCOMMAND WORK AREA,CASWKA IS ORGANIZED     89600020
*BELOW THE EXPANSION FOR SYMBOLIC ADDRESSING BY IKJEBEDE.               89700020
*********************************************************************** 89800020
         SPACE 2                                                        89900020
COMMAREA IKJEBECA                  GENERATES COMMUNICATIONS AREA DSECT  90000020
        EJECT                                                           90100020
*********************************************************************** 90200020
* THE FOLLOWING SECTION IS AN ORGANIZATION OF IKJEBEDE'S DYNAMIC        90300020
* WORK AREA, CASCWKA IN THE EDIT COMMUNICATIONS AREA.                   90400020
*********************************************************************** 90500020
         ORG   CASCWKA             IKJEBEDE WORK AREA ORGANIZATION      90600020
DEPACK   DS    D                   CVD INTO THIS AREA - UNPK OUT OF IT  90700020
         SPACE 2                                                        90800020
*THE FIELD BELOW MUST BE ALIGNED ON A DOUBLE-WORD BOUNDARY AND MUST BE  90900020
*CONTIGUOUS.                                                            91000020
DELINENO DS    0D                  LINE NUMBER INSERTION LIST           91100020
DEPTR1   DS    F                        PTR TO NEXT INSERTION-0 IF NONE 91200020
DELEN1   DS    H                        LENGTH OF DECIMAL NUMBER(1-8)   91300020
DEOFF1   DS    H                        OFFSET OF INSERTION             91400020
DEFIELD1 DS    D                        UNPACKED DECIMAL LINE NUMBER    91500020
         SPACE 2                                                        91600020
DEDSNAME DS    0F                  DATA SET NAME INSERTION LIST         91700020
DEPTR2   DS    F                        PTR TO NEXT INSERTION-0 IF NONE 91800020
DELEN2   DS    H                        LENGTH OF USER-ENTERED DSNAME   91900020
DEOFF2   DS    H                        OFFSET OF INSERTION             92000020
DEFIELD2 DS    44X                      DATA SET NAME(1-44 CHARACTERS)  92100020
         SPACE 2                                                        92200020
DESYNBFR DS    0F                  SYNTAX CHECKER COMMAND INTERFACE BFR 92300020
DECOUNT  DS    F                        COUNT OF LINES/WK AREA SYN CHK  92400020
DEVALUE1 DS    F                        STARTING LINE(BINARY)           92500020
DEVALUE2 DS    F                        ENDING LINE(BINARY)             92600020
*                                  SYNTAX CHECKER ENTRY CODES           92700020
DENORM1  EQU   X'80'                    ENTRY CODE FOR NORMAL ENTRY     92800020
DENORM2  EQU   X'8F'                    PRESERVES BITS 4-7              92900020
*                                  SYNTAX CHECKER OPTION CODES          93000020
DEDEL1   EQU   X'40'                    OPTION CODE FOR DELETE          93100020
DEDEL2   EQU   X'67'                    PRESERVES BITS 5-7              93200020
         SPACE 2                                                        93300020
DEPARM   DS    10F                 REMOTE PROGRAM PARAMETER LIST        93400020
         EJECT                                                          93500020
         SPACE 2                                                        93600020
DEUTPARM DS    0F                  IKJEBEUT PARAMETER LIST              93700020
DELASTWD EQU   X'80'                    (HIGH ORDER BIT=1-END PARMLIST) 93800020
DEPTCDCB DS    A                        PTR TO CURRENT DCB              93900020
         ORG   DEPTCDCB                 ORGANIZATION -                  94000020
DEUTOPCD DS    X                             BYTE 0 - OPTION CODE       94100020
DEOPCORC EQU   X'00'                              READ CURRENT LINE     94200020
DEOPCORP EQU   X'01'                              READ PREVIOUS LINE    94300020
DEOPCORN EQU   X'02'                              READ NEXT LINE        94400020
DEOPCORF EQU   X'04'                              READ FIRST LINE       94500020
DEOPCODC EQU   X'10'                              DELETE CURRENT LINE   94600020
         DS    AL3                           BYTES 1-3 - 3-BYTE POINTER 94700020
         ORG   DEPTCDCB+L'DEPTCDCB END OF DCB PTR ORGANIZATION.         94800020
DECURLIN DS    F                        REPLACEMENT FOR CURRENT LINE    94900020
DEREADBF DS    F                        READ BUFFER FOR IKJEBEUT        95000020
DESVAREA DS    A                   ADDRESS OF SAVE AREA FOR VALIDITY   X95100020
                                   CHECK ROUTINE                        95200020
         SPACE 2                                                        95300020
DEANSWER DS    F                   ADDRESS OF PARSE PDL                 95400020
         SPACE 2                                                        95500020
DEFLAGS  DS    X                   IKJEBEDE CONTROL FLAGS               95600020
DEONEAST EQU   X'C0'                     1 - FIRST OPERAND,ASTERISK     95700020
DEOPND1  EQU   X'80'                     1 - FIRST OPERAND PROCESSED    95800020
DE2OPS   EQU   X'80'                     0 - SECOND OPERAND PROCESSED   95900020
DEASTER  EQU   X'40'                     1 - ASTERISK SPECIFIED         96000020
DEBADRNG EQU   X'20'                     1 - INVALID LINE RANGE         96100020
DESCTERM EQU   X'10'                     1 - RETURN CODE TO IKJEBEMA    96150020
*                                            IS 08.                     96160020
*                                        0 - RETURN CODE TO IKJEBEMA    96170020
*                                            IS 00 (NORMAL).            96180020
DEZEROES EQU   X'00'                         INITIALIZATION VALUE       96200020
         ORG                                                            96300020
         EJECT                                                          96400020
*********************************************************************** 96500020
*                                                                       96600020
* THE FOLLOWING SECTION CONTAINS EQU'S FOR SYMBOLIC ADDRESSING          96700020
*                                                                       96800020
*********************************************************************** 96900020
         SPACE 2                                                        97000020
ABNRMRC@ EQU   ABNORMRC-4                                               97100020
DEPACK@  EQU   DEPACK+3                                                 97200020
DETEMPBF EQU   CATEMPBF+12              READ BUFFER ADDRESS             97300020
NOCORE@  EQU   NOCORE-16                                                97400020
READPRV@ EQU   READPREV-4                                               97500020
SIGBYTE1 EQU   DEFIELD1+1                                               97600020
         END                                                            97700020
