BEDO     TITLE 'EDIT SUBCOMMAND - DOWN - IKJEBEDO'                      00200020
IKJEBEDO CSECT                                                          00400020
*A420500,436000-445500,476000-477000,478100-479200,482000-499600 A45119 00430021
*A702500-703500,770100-771500                                    A45119 00460021
*C420000,606000                                                  A45119 00490021
*D436000-444000,476000,482000-502000,516000-518000,522000-572000 A45119 00520021
*D626000,712000-724000,772000                                    A45119 00550021
*********************************************************************** 00600020
* STATUS-  VERSION NO. 01, OS/360 RELEASE NO. 20                      * 00800020
*                                                                     * 01000020
* FUNCTION-  IKJEBEDO IS AN EDIT SUBCOMMAND WHICH IS USED TO CAUSE THE* 01040020
*    CURRENT LINE POINTER '*' TO BE MOVED TOWARD THE END OF THE DATA  * 01080020
*    SET.  IF THE DOWN SUBCOMMAND CAUSES THE CURRENT LINE POINTER '*' * 01120020
*    TO POINT TO THE LAST LINE OF THE SET, OR IF THIS SUBCOMMAND IS   * 01160020
*    ISSUED WITH THE '*' VALUE ALREADY POINTING AT THE LAST LINE OF   * 01200020
*    THE DATA SET, THE USER WILL BE NOTIFIED.  IF DURING THE PROCESS  * 01240020
*    OF READING THE UTILITY DATA SET, AN ATTENTION IS ISSUED BY THE   * 01280020
*    TERMINAL USER, CONTROL WILL BE RETURNED TO THE CONTROLLER        * 01320020
*    IMMEDIATELY WITH A RETURN CODE OF ZERO IN REGISTER 15.           * 01360020
*                                                                     * 03000020
* ENTRY POINTS-  IKJEBEDO, MAIN ENTRY POINT                           * 03060020
*                                                                     * 03120020
* INPUT-  REGISTER 1 CONTAINS A POINTER TO EDIT'S COMMUNICATION AREA. * 03210020
*    A PART OF OR THE WHOLE UTILITY DATA SET IS READ AS REQUIRED.     * 03300020
*                                                                     * 03600020
* OUTPUT-  A RETURN CODE IN REGISTER 15. POSSIBLE RETURN CODES ARE-   * 03700020
*    0 - OPERATION WAS SUCCESSFUL.                                    * 03800020
*    8 - STACK NEEDS FLUSHING                                         * 03850020
*    12 - I/O ERROR.                                                  * 03900020
*                                                                     * 04400020
* EXTERNAL REFERENCES-                                                * 04410020
*         IKJPARS      -SCANS OPERAND                                 * 04420020
*         IKJEBEUT     -READS UTILITY DATA SET                        * 04430020
*         IKJEBEMS     -MESSAGES TO USER AND LINE VERIFICATION        * 04440020
*    EDIT MACROS USED-                                                * 04450020
*         IKJEBESV     -STANDARD ENTRY LINKAGE AND ADDRESSABILITY     * 04460020
*         IKJEBERT     -STANDARD EXIT LINKAGE                         * 04470020
*         IKJEBECA     -LAYOUT AND DESCRIPTION OF COMMUNICATION AREA  * 04480020
*         IKJEBEML     -STANDARD MESSAGE TO TERMINAL USER             * 04490020
*         IKJEBEMG     -MESSAGE INSERITON                             * 04500020
*         IKJEBESH     -PROVIDES LINKAGE TO EDIT SERVICE ROUTINES     * 04510020
*    SYSTEM MACROS USED-                                              * 04520020
*         LINK         -CALLS IKJPARS                                 * 04530020
*         IKJPARM      -GENERATE PCL CSECT                            * 04540020
*         IKJIDENT     -GENERATE COUNT FIELD IN PCL                   * 04550020
*         IKJENDP      -CLOSE PCL CSECT                               * 04560020
*         IKJRLSA      -RELEASE PCL CORE                              * 04570020
*         IKJPPL       -PARSE PARAMETER LIST                          * 04580020
*         SAVE         -SAVE PARSE'S REGISTERS                        * 04590020
*         RETURN       -RETURN TO PARSE                               * 04600020
*                                                                     * 07700020
* EXITS,NORMAL-  STANDARD EXIT TO THE CONTROLLER WITH RETURN CODE = 0 * 07800020
*    IN REGISTER 15                                                   * 07900020
*                                                                     * 08200020
* EXITS,ERROR-  STANDARD EXIT TO THE CONTROLLER WITH RETURN CODE = 12 * 08300020
*    OR 8 IN REGISTER 15.                                             * 08800020
* TABLES/WORK AREAS-  THE EDIT SUBCOMMAND WORK AREA IN THE            * 08900020
*    COMMUNICATIONS AREA IS USED                                      * 09000020
*                                                                     * 09400020
* ATTRIBUTES-  REFRESHABLE, ENABLED, NON-PRIVILEGED                   * 09600020
*                                                                     * 09800020
* CHARACTER CODE DEPENDENCY-  THIS SUBCOMMAND IS CHARACTER CODE       * 09900020
*    DEPENDENT AND HAS TO BE REASSEMBLED WHEN CHARACTER CODE CHANGES  * 10000020
*                                                                     * 10260020
* NOTES-  STANDARD LINKAGE CONVENTIONS USED                           * 10330020
*********************************************************************** 10400020
         SPACE 2                                                        10600020
*********************************************************************** 10800020
*    EQUATES OF SYMBOLIC REGISTERS                                      11000020
*********************************************************************** 11200020
PARMREG0 EQU   0                       PARAMETER POINTER                11400020
PARMREG1 EQU   1                       PARAMETER POINTER                11600020
TESTREG  EQU   2                       WORK REGISTER                    11800020
BINREG   EQU   3                       WORK REGISTER                    12000020
ADDREG   EQU   4                       WORK REGISTER                    12200020
DCBREG   EQU   5                       WORK REGISTER                    12400020
WORKREG  EQU   6                       WORK REGISTER                    12600020
PDLREG   EQU   7                       POINTER TO PDL                   12800020
UTREG    EQU   8                       PARAMETERS FOR IKJEBEUT POINTER  13000020
COMMREG  EQU   9                       COMMUNICATION AREA ADDRESSING    13200020
TEMPREG  EQU   10                      WORK REGISTER                    13400020
BASEREG  EQU   11                      BASE REGISTER                    13600020
DATAREG  EQU   12                      WORK REGISTER                    13800020
SAVEREG  EQU   13                      SAVE AREA REGISTER               14000020
RETREG   EQU   14                      RETURN TO CALLER                 14200020
RETCDREG EQU   15                      RETURN CODE                      14400020
         SPACE 2                                                        14600020
*********************************************************************** 14800020
*    EQUATES OF SYMBOLIC CONSTANTS                                      15000020
*********************************************************************** 15200020
DN0      EQU   0                       CONSTANT OF 0                    15400020
DN1      EQU   1                       CONSTANT OF 1                    15600020
DN3      EQU   3                       CONSTANT OF 3                    15800020
DN4      EQU   4                       CONSTANT OF 4                    16000020
DN8      EQU   8                       CONSTANT OF 8                    16200020
DN12     EQU   12                      CONSTANT OF 12                   16400020
DN16     EQU   16                      CONSTANT OF 16                   16600020
END      EQU   X'80'                   END OF PARAMETER LIST CODE       16800020
LAST     EQU   X'05'                   READ LAST RECORD CODE            17000020
NEXT     EQU   X'02'                   READ NEXT RECORD CODE            17200020
SW1      EQU   X'80'                                                    17400020
ALL      EQU   X'FF'                                                    17600020
         SPACE 2                                                        17800020
*********************************************************************** 18000020
*    MESSAGE REFERENCES                                                 18200020
*********************************************************************** 18400020
         IKJEBEMI (312,313,500,501)                                     18600020
         EJECT                                                          18800020
*********************************************************************** 19000020
*    STANDARD ENTRY LINKAGE AND ESTABLISHMENT OF ADDRESSABILITY BOTH    19200020
*    IN THIS ROUTINE AND IN THE COMMUNICATION AREA                      19400020
*********************************************************************** 19600020
         IKJEBESV (14,12),T,*          SAVE CALLER'S REGISTERS AND      19800020
*                                      ESTABLISH ADDRESSABILITY         20000020
         USING IKJEBECA,COMMREG        ADDRESSABILITY IN COMMUNICATION  20200020
*                                      AREA                             20400020
         MVI   SW,DN0                  CLEAR SWITCH                     20500020
         SPACE 2                                                        20600020
*********************************************************************** 20800020
*    OPERAND TEST                                                       21000020
*********************************************************************** 21200020
         TM    CAPTIBFR,CAOPERND       TEST WHETHER THERE ARE OPERANDS  21400020
         BNO   DEFAULT                 NO OPERAND, THEN GO TO DEFAULT   21600020
         SPACE 2                                                        21800020
*********************************************************************** 22000020
*    CALL IKJPARSE TO SCAN OPERAND                                      22200020
*********************************************************************** 22400020
OPERAND  LA    PARMREG1,CATMPLST       LET REG. 1 PT. TO TMP SERVICE    22600020
*                                      RTN. PARAMETER LIST              22800020
         MVC   CATMPLST+PPLPCL-PPL(DN4),ADDNPCL  PUT POINTER TO PCL IN  23000020
*                                                PPLPCL                 23200020
         LA    TESTREG,CAPTPRSD                                         23400020
         ST    TESTREG,CATMPLST+PPLANS-PPL  PUT POINTER TO ANS. PLACE   23600020
*                                           IN PPLANS                   23800020
         MVC   CATMPLST+PPLCBUF-PPL(DN4),CAPTIBFR  PUT ADDRESS OF       24000020
*                                      INPUT BUFFER IN PPLCBUF          24200020
         ST    COMMREG,CATMPLST+PPLUWA-PPL  PUT POINTER TO COMM. AREA   24400020
*                                           IN PPLVWA                   24600020
         LINK  EP=IKJPARS                                               24800020
         SPACE 2                                                        25000020
*********************************************************************** 25200020
*    CHECK RETURN CODES FROM PARSE SERVICE ROUTINE AND ESTABLISH        25400020
*    ADDRESSABILITY IN PDL DSECT                                        25600020
*********************************************************************** 25800020
         L     PDLREG,CAPTPRSD         PUT PTR. TO PDL IN PDLREG        26000020
         USING DNPDL,PDLREG            ESTABLISH ADDRESSABILITY IN      26200020
*                                      PDL DSECT                        26400020
         LTR   RETCDREG,RETCDREG       CHECK RET. CODE FROM PARSE       26600020
         BZ    CONV                    IF SUCCESSFUL COMPLETION THEN GO 26800020
*                                      TO CONV                          27000020
         C     RETCDREG,DNDC4          TEST WHETHER R.C.=4              27200020
         BE    FLUSH                   R.C.=4 THEN GO TO FLUSH          27400020
         C     RETCDREG,DNDC8          TEST WHETHER R.C.=8              27600020
         BE    NORMAL                  R.C.=8 THEN GO TO NORMAL         27800020
         C     RETCDREG,DNDC12         TEST WHETHER R.C.=12             28000020
         BE    MSG5                    R.C.=12 THEN GO TO ISSUE MSG5    28200020
         C     RETCDREG,DNDC16         TEST WHETHER R.C.=16             28400020
         BE    MESSAGE3                R.C.=16 THEN GO TO ISSUE MSG3    28600020
         SPACE 2                                                        28800020
*********************************************************************** 29000020
*    CONVERSION OF OPERAND 'COUNT' TO BINARY                            29200020
*********************************************************************** 29400020
CONV     L     TESTREG,COUNT           LET TESTREG CONTAIN ADDRESS      29600020
*                                      OF OPERAND                       29800020
         LH    ADDREG,COUNT+DN4        PUT LENGTH OF OPERAND IN 2       30000020
*                                      LOW ORDER BYTES OF ADDREG        30200020
         BCTR  ADDREG,PARMREG0         LENGTH OF OPERAND - 1            30400020
         EX    ADDREG,PACKED           CONVERT OPERAND FROM ZONED       30600020
*                                      DECIMAL TO PACKED DECIMAL        30800020
         CVB   BINREG,COPACKED         CONVERT OPERAND FROM PACKED      31000020
*                                      DECIMAL TO BINARY                31200020
         SPACE 2                                                        31400020
*********************************************************************** 31600020
*    CALL IKJEBEUT THROUGH IKJEBESH TO READ LAST RECORD OF UTILITY      31800020
*    DATA SET                                                           32000020
*********************************************************************** 32200020
READLAST MVC   COWORD1(DN4),CAPTCDCB   PUT ADDRESS OF UTILITY DCB IN 3  32400020
*                                      LOW ORDER BYTES OF 1ST PARAM.    32600020
*                                      WORD                             32800020
         MVI   COWORD1,LAST            PUT READ LAST RECORD CODE IN     33000020
*                                      HIGH ORDER BYTE OF 1ST PARAM     33200020
*                                      WORD                             33400020
         XC    COWORD2(DN4),COWORD2    NO POINTER IS PUT IN 2ND         33600020
*                                      PARAM. WORD                      33800020
         LA    TESTREG,CATEMPBF+DN12   PUT ADDRESS OF BUFFER POOL IN    34000020
*                                      3RD PARAM WORD                   34200020
         ST    TESTREG,COWORD3                                          34400020
         MVI   COWORD3,END             PUT END OF PARAMETER CODE IN     34600020
*                                      HIGH ORDER BYTE OF 3RD PARAM     34800020
*                                      WORD                             35000020
         LA    UTREG,COWORD1           LET UTREG POINT TO PARMLIST      35200020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(UTREG)),MF=(E,A) 35400020
         SPACE 2                                                        35600020
*********************************************************************** 35800020
*    CHECK RETURN CODE FROM IKJEBEUT AFTER READING LAST RECORD          36000020
*********************************************************************** 36200020
         LTR   RETCDREG,RETCDREG       TEST RETURN CODE FROM IKJEBEUT   36400020
*                                      AFTER READING LAST RECORD        36600020
         BZ    CONT1                   BRANCH IF ZERO TO CONT1          36800020
         C     RETCDREG,DNDC4          TEST WHETHER R.C.=4              37000020
         BE    EMPTY                   BRANCH IF EQUAL TO EMPTY         37200020
IOERR    LA    RETCDREG,DN12           OTHERWISE, SET R.C. TO 12        37400020
         SPACE 2                                                        37600020
*********************************************************************** 37800020
*    STANDARD EXIT LINKAGE TO CONTROLLER                                38000020
*********************************************************************** 38200020
EXIT     TM    CAPRSPDL,CAFREEDL       TEST WHETHER PARSE PDL REQUIRES  38300020
*                                      FREEMAIN                         38400020
         BNZ   RET                     PDL NOT EXIST THEN RETURN TO     38600020
*                                      CONTROLLER                       38800020
         IKJRLSA CAPRSPDL              RELEASE PARSE PDL CORE           38900020
         OI    CAPRSPDL,CAFREEDL       TURN ON THE BIT TO INDICATE PDL  39000020
*                                      WAS FREED                        39100020
RET      EQU   *                                                        39200020
         IKJEBERT (14,12),T,RC=(15)                                     39400020
         SPACE 2                                                        39600020
*********************************************************************** 39800020
*    IF NO OPERAND IS SPECIFIED IN THE SUBCOMMAND, THEN IT IS DEFAULTED 40000020
*    TO 1                                                               40200020
*********************************************************************** 40400020
DEFAULT  LA    BINREG,DN1              PUT 1 IN BINREG                  40600020
         B     READLAST                BRANCH TO READ LAST RECORD OF    40800020
*                                      DATA SET                         41000020
         SPACE 2                                                        41200020
*********************************************************************** 41400020
*    DATA SET IS EMPTY                                                  41600020
*********************************************************************** 41800020
EMPTY    EQU   *                                                 A45119 42000021
         XC    B(DN12),B               ZERO PARAMETER LIST AREA  A45119 42050021
         IKJEBEML M501,MF=(E,B)        ISSUE MESSAGE1- 'NO LINES IN     42200020
*                                      DATA SET'                        42400020
         XC    CACURNUM(DN4),CACURNUM  SET CURRENT LINE NUMBER TO ZERO  42600020
NORMAL   SR    RETCDREG,RETCDREG       SET RETURN CODE TO ZERO          42800020
         B     EXIT                    STANDARD EXIT LINKAGE TO         43000020
*                                      CONTROLLER                       43200020
FLUSH    LA    RETCDREG,DN8            INDICATE STACK NEEDS FLUSHING    43250020
         B     EXIT                    BRANCH TO MAKE EXIT              43300020
         SPACE 2                                                        43400020
**************************************************************** A45119 43600021
*                                                                A45119 43650021
*    DATA SET IS NOT EMPTY.                                      A45119 43700021
*                                                                A45119 43750021
*    CHECK IF CURRENT LINE (*) IS LAST LINE IN DATA SET.         A45119 43800021
*    IF SO, INFORM USER THAT END OF DATA HAS BEEN REACHED AND    A45119 43850021
*    TERMINATE SUBCOMMAND.  IF NOT, SAVE THE KEY OF THE LAST     A45119 43900021
*    LINE AND READ RECORD FOLLOWING THE CURRENT LINE.            A45119 43950021
*                                                                A45119 44000021
**************************************************************** A45119 44050021
         SPACE 2                                                        44100021
CONT1    EQU   *                                                 A45119 44150021
         L     TESTREG,CATEMPBF+DN12   OBTAIN KEY OF LAST LINE   A45119 44200021
         C     TESTREG,CACURNUM        CHECK IF '*' IS LAST LINE A45119 44250021
         BE    DO000020                IF SO, BR TO INFORM USER  A45119 44300021
         ST    TESTREG,DOLASTLN        IF NOT, SAVE KEY OF LAST  A45119 44350021
*                                      LINE IN DATA SET          A45119 44400021
         L     TESTREG,CACURNUM        OBTAIN CURRENT LINE KEY   A45119 44450021
         ST    TESTREG,COKEYA          SPECIFY AS KEY FOR        A45119 44500021
*                                      IKJEBEUT                  A45119 44550021
*                                      IS LOCATED IN SUBCMD. WORKAREA   44600020
         LR    WORKREG,BINREG          PUT OPERAND 'COUNT' IN BINREG    44800020
READ     MVI   COWORD1,NEXT            PUT READ NEXT RECORD CODE IN     45000020
*                                      HIGH ORDER BYTE OF 1ST           45200020
*                                      PARAM WORD                       45400020
         LA    TESTREG,COKEYA          LET 2ND PARAM. WORD POINT TO     45600020
         ST    TESTREG,COWORD2         COKEYA                           45800020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(UTREG)),MF=(E,A) 46000020
         SPACE 2                                                        46200020
*********************************************************************** 46400020
*    CHECK RETURN CODE FROM IKJEBEUT AFTER READING NEXT RECORD          46600020
*********************************************************************** 46800020
         LTR   RETCDREG,RETCDREG       TEST RET. CODE FROM IKJEBEUT     47000020
         BZ    CONT2                   BRANCH IF ZERO TO CONT2          47200020
         C     RETCDREG,DNDC4          TEST WHETHER R.C.=4              47400020
         BE    DO000010                IF END-OF-DATA, BRANCH TO A45119 47600021
*                                      ISSUE APPROPRIATE MESSAGE A45119 47700021
         B     IOERR                   R,C,=8 THEN GO TO IOERR          47800020
CONT2    EQU   *                                                 A45119 47810021
         BCT   WORKREG,LOOP            DECREMENT COUNT BY ONE    A45119 47820021
*                                      AND BR IF RESULT GT ZERO  A45119 47830021
         L     TESTREG,DOLASTLN        OBTAIN KEY OF LAST LINE   A45119 47840021
         C     TESTREG,CATEMPBF+DN12   IS LINE JUST READ THE     A45119 47850021
*                                      LAST LINE                 A45119 47860021
         BE    DO000040                IF SO, BRANCH TO INFORM   A45119 47870021
*                                      USER LAST LINE REACHED    A45119 47880021
         OI    CACFLAG1,CALNTOVF       OTHERWISE, INDICATE A     A45119 47890021
*                                      LINE TO VERIFY            A45119 47900021
         B     SET                     BR TO SET * VALUE AND     A45119 47910021
*                                      RETURN CONTROL            A45119 47920021
         SPACE 2                                                        48000020
**************************************************************** A45119 48200021
*                                                                A45119 48240021
*    END-OF-DATA HAS BEEN REACHED.  ISSUE IKJ52500I IN ITS       A45119 48280021
*    APPROPRIATE FORM.                                           A45119 48320021
*                                                                A45119 48360021
**************************************************************** A45119 48400021
         SPACE 2                                                        48440021
DO000010 EQU   *                       ENTER HERE WHEN EOD       A45119 48480021
*                                      REACHED ON READ NEXT      A45119 48520021
*                                      OPERATION.                A45119 48560021
         TM    CACFLAG1,CAVRFYSW       CHECK IF VERIFY IN EFFECT A45119 48600021
         BO    DO000030                IF SO, ISSUE MESSAGE WITH A45119 48640021
*                                      TWO INSERTIONS            A45119 48680021
DO000020 EQU   *                       ENTER HERE TO PROCESS     A45119 48720021
*                                      'TERMINATION' INSERTION   A45119 48760021
*                                      ONLY FOR IKJ525001.       A45119 48800021
         LA    TESTREG,DOEODTRM        OBTAIN ADDRESS OF         A45119 48840021
*                                      INSERTION LIST            A45119 48880021
         B     DO000070                BR TO SEND MSG TO USER    A45119 48920021
DO000030 EQU   *                       PROCESS TWO INSERTIONS -  A45119 48960021
         MVC   DOMSINS1(DOEODTLN),DOEODTRM MOVE FIRST INSERTION  A45119 49000021
*                                      TO WORK AREA              A45119 49040021
         LA    TESTREG,DOEODVFY        OBTAIN ADDR OF INSERT 2   A45119 49080021
         ST    TESTREG,DOMSINS1        CHAIN INSERTIONS          A45119 49120021
         LA    TESTREG,DOMSINS1        OBTAIN ADDRESS OF         A45119 49160021
*                                      CHAIN OF INSERTIONS       A45119 49200021
         B     DO000060                BRANCH TO SEND MESSAGE    A45119 49240021
DO000040 EQU   *                       ENTER HERE IF LINE TO     A45119 49280021
*                                      BE DESIGNATED AS CURRENT  A45119 49320021
*                                      IS THE LAST LINE.         A45119 49360021
         TM    CACFLAG1,CAVRFYSW       CHECK IF VERIFY IN EFFECT A45119 49400021
         BO    DO000050                IF SO, BRANCH TO PROCESS  A45119 49440021
*                                      REQUIRED INSERTION.       A45119 49480021
         SR    TESTREG,TESTREG         SPECIFY NO INSERTIONS.    A45119 49520021
         B     DO000070                BRANCH TO SEND MESSAGE.   A45119 49560021
DO000050 EQU   *                       INCLUDE 'VERIFY' INSERT   A45119 49600021
*                                      IN MSG IKJ52500I.         A45119 49640021
         LA    TESTREG,DOEODVFY        OBTAIN ADDRESS OF         A45119 49680021
*                                      INSERTION LIST            A45119 49720021
DO000060 EQU   *                                                 A45119 49760021
         OI    CACFLAG1,CALNTOVF       INDICATE LINE TO BE       A45119 49800021
*                                      VERIFIED                  A45119 49840021
DO000070 EQU   *                       ISSUE MSG IKJ52500I.      A45119 49880021
         XC    B(DN12),B               ZERO IKJEBEMS PARM LIST   A45119 49920021
         IKJEBEML M500,,(TESTREG),,MF=(E,B) INVOKE IKJEBEMS      A45119 49960021
         SPACE 2                                                        50400020
*********************************************************************** 50600020
*    '*' VALUE IS SET TO LAST LINE READ                                 50800020
*********************************************************************** 51000020
SET      MVC   CACURNUM(DN4),CATEMPBF+DN12  SET '*' VALUE TO KEY OF     51200020
*                                      LAST LINE READ                   51400020
         SPACE 2                                                        52000020
         B     NORMAL                  BRANCH TO NORMAL RETURN TO       57400020
*                                      CONTROLLER                       57600020
LOOP     TM    CAATTN,CAATTNIS         TEST WHETHER ATTN IS ISSUED BY   57800020
*                                      TERMINAL USER                    58000020
         BO    NORMAL                  IF ATTN IS ISSUED THEN BRANCH    58200020
*                                      TO SET R.C. TO ZERO AND RET.     58400020
*                                      TO CONTROLLER                    58600020
NO       MVC   COKEYA(DN4),CATEMPBF+DN12  IF ATTN IS NOT ISSUED THEN    58800020
*                                      SET VALUE OF COKEYA TO KEY OF    59000020
*                                      LAST LINE READ                   59200020
         B     READ                    BRANCH TO READ THE NEXT RECORD   59400020
         SPACE 2                                                        59600020
*********************************************************************** 59800020
*    MESSAGE3- 'NOT ENOUGH MAIN STORAGE TO EXECUTE DOWN' IS             60000020
*    ISSUED HERE                                                        60200020
*********************************************************************** 60400020
MESSAGE3 EQU   *                                                 A45119 60600021
         IKJEBEML M312,,SUBCMD,,MF=(E,B)                                60800020
         B     FLUSH                   BRANCH TO SET R.C. TO 8 AND      61000020
*                                      RETURN TO CONTROLLER             61200020
MSG5     EQU   *                                                        61400020
         SPACE 2                                                        61600020
*********************************************************************** 61800020
*    MSG5- 'COMMAND SYSTEM ERROR+  IKJPARS ERROR CODE 12' IS            62000020
*    ISSUED HERE                                                        62200020
*********************************************************************** 62400020
         IKJEBEML M313,M3131,,INS12,MF=(E,B)                            62800020
         B     FLUSH                   BRANCH TO SET R.C. TO 8 AND      63000020
*                                      RETURN TO CONTROLLER             63200020
         SPACE 2                                                        63400020
*********************************************************************** 63600020
*    VALIDITY CHECKING ROUTINE FOR DOWN OPERAND                         63800020
*********************************************************************** 64000020
DVALID   SAVE  (14,12),T,*             SAVE PARSE'S REGISTERS           64200020
         BALR  TEMPREG,DN0             SET UP ADDRESSABILITY            64400020
         USING *,TEMPREG               ADDRESSABILITY IN VALIDITY       64600020
*                                      CHECKING ROUTINE                 64800020
         L     TESTREG,DN0(PARMREG1)   PUT POINTER TO COUNT IN TESTREG  65000020
         L     BINREG,DN0(TESTREG)     PUT COUNT IN BINREG              65200020
         LH    UTREG,DN4(TESTREG)      PUT LENGTH OF COUNT IN 2 LOW     65400020
*                                      ORDER BYTES OF UTREG             65600020
         BCTR  UTREG,PARMREG0          LENGTH OF COUNT - 1              65800020
         EX    UTREG,COMPARE           TEST WHETHER COUNT=0             66000020
         BE    EXIT1                   EQUAL TO ZERO THEN GO TO EXIT1   66200020
         SR    RETCDREG,RETCDREG       PUT R.C.=0 IN REG. 15            66400020
EXIT2    RETURN (14,12),T,RC=(15)      RETURN TO PARSE                  66600020
EXIT1    LA    RETCDREG,DN4            PUT R.C.=4 IN REG. 15            66800020
         B     EXIT2                   BRANCH TO RET. TO PARSE          67000020
         SPACE 3                                                        67200020
*********************************************************************** 67400020
*    CONSTANT AREA FOR IKJEBEDO                                         67600020
*********************************************************************** 67800020
DNDC4    DC    F'4'                    FULL WORD OF 4                   68000020
DNDC8    DC    F'8'                    FULL WORD OF 8                   68200020
DNDC12   DC    F'12'                   FULL WORD OF 12                  68400020
DNDC16   DC    F'16'                   FULL WORD OF 16                  68600020
ADDNPCL  DC    A(IKJEBDO0)             ADCON OF PCL                     68800020
ZERO     DC    8C'0'                   8 BYTES OF EBCDIC ZERO           69000020
PACKED   PACK  COPACKED(DN8),DN0(DN0,TESTREG)                           69200020
COMPARE  CLC   DN0(DN0,BINREG),ZERO                                     69400020
         SPACE 2                                                        69600020
*********************************************************************** 69800020
*    MESSAGE INSERTION MACRO - IKJEBEMG IS ISSUED HERE                  70000020
*********************************************************************** 70200020
DOEODTRM IKJEBEMG ,M500IN1,'DOWN TERMINATED AT '                 A45119 70250021
DOEODTLN EQU   *-DOEODTRM              LENGTH OF INSERT LIST     A45119 70300021
DOEODVFY IKJEBEMG ,M500IN2,', LAST LINE IS:'                     A45119 70350021
SUBCMD   IKJEBEMG ,M312IN1,'DOWN'                                       70400020
INS12    IKJEBEMG CODE12,M3131IN1,'IKJPARS'                             70600020
CODE12   IKJEBEMG 0,M3131IN2,'12'                                       70800020
         SPACE 2                                                        71000020
         SPACE 2                                                        72600020
*********************************************************************** 72800020
*    MACROS OF PARSE                                                    73000020
*********************************************************************** 73200020
IKJEBDO0 IKJPARM DSECT=DNPDL                                            73400020
COUNT    IKJIDENT 'DOWN OPERAND',MAXLNTH=8,FIRST=NUMERIC,OTHER=NUMERIC,*73600020
               PROMPT='DOWN OPERAND',VALIDCK=DVALID                     73800020
         IKJENDP                                                        74000020
         SPACE 2                                                        74200020
         IKJPPL                                                         74400020
         SPACE 2                                                        74600020
         IKJEBECA                                                       74800020
         ORG   CASCWKA                 EDIT SUBCOMMAND WORK AREA        75000020
COPACKED DS    D                       DOUBLE WORD FOR PACKED           75200020
*                                      DECIMAL OF 'COUNT'               75400020
COWORD1  DS    F                       1ST PARAM WORD FOR UT            75600020
COWORD2  DS    F                       2ND PARAM WORD FOR UT            75800020
COWORD3  DS    F                       3RD PARAM WORD FOR UT            76000020
COKEYA   DS    F                       CURRENT REFERNCED VALUE FOR UT   76200020
A        DS    5F                      5 FULLWORDS FOR IKJEBESH MACRO   76600020
B        DS    10F                     10 FULL WORDS FOR IKJEBEML MACRO 76800020
SW       DS    X                       SWITCH FOR DET. WHETHER ONE      77000020
*                                      MORE LINE SHOULD BE READ  A45119 77010021
DOLASTLN DS    F                       SAVE AREA FOR KEY OF LAST A45119 77020021
*                                      LINE IN UTILITY DATA SET  A45119 77030021
DOMSINS1 DS    0F                      DYNAMIC INSERTION AREA    A45119 77050021
         DS    XL(DOEODTLN)            LENGTH RESERVED IS FOR    A45119 77100021
*                                      INSERTION 1, IKJ52500I    A45119 77150021
         END                                                            77400020
