BEEN     TITLE 'TSO EDIT - IKJEBEEN - END SUBCOMMAND PROCESSOR'         00100020
IKJEBEEN CSECT                                                          00200020
*                                                                       00202021
*A271984,273960                                                  A45718 00210021
*D272000,273000                                                  A45718 00220021
*C258580,422000-423000                                           A50474 00222021
*D258900-258920                                                  A50474 00224021
*A283500-285500,293100-292500                                    A50473 00230021
*D284000-288000                                                  A50473 00280021
*A367500,531500                                                   M5133 00280521
*C371000                                                          M5133 00281021
*D368000-370000                                                   M5133 00281521
         ENTRY IKJEBEEN                                                 00300020
         ENTRY IKJEBEXT                                                 00400020
         EJECT                                                          00500020
*********************************************************************** 00600020
*                                                                     * 00700020
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 00800020
*                                                                     * 00900020
* FUNCTION --                                                         * 01000020
*                                                                     * 01100020
*    THE END SUBCOMMAND PROCESSOR (IKJEBEEN) PERFORMS ALL             * 01200020
*    CLEAN-UP FUNCTIONS REQUIRED FOR NORMAL OR ABNORMAL               * 01300020
*    TERMINATION OF THE EDIT COMMAND PROCESSOR.                       * 01400020
*                                                                     * 01500020
*    1. IKJEBEEN WILL DETERMINE IF THE USER HAS SAVED HIS DATA        * 01600020
*    SET SINCE THE LAST MODIFICATION.  IF THE DATA SET HAS NOT        * 01700020
*    BEEN SAVED, THE USER WILL BE PROMPTED TO ENTER A 'SAVE' OR       * 01800020
*    'END' SUBCOMMAND. (THIS PROMPTING SEQUENCE WILL BE BYPASSED IF   * 01900020
*    THE CURRENT SOURCE OF INPUT IS AN IN-CORE PROCEDURE.)            * 01960020
*                                                                     * 02000020
*    2. AFTER THE USER HAS ENTERED A SUBCOMMAND, IKJSCAN IS           * 02100020
*    INVOKED TO SCAN THE INPUT BUFFER.  WHEN A 'SAVE' SUBCOMMAND      * 02200020
*    IS INPUT, IKJEBESA IS INVOKED TO PERFORM THE SAVE OPERATION.     * 02300020
*    UPON RETURN FROM IKJEBESA, IKJSCAN IS INVOKED AGAIN TO SCAN      * 02400020
*    THE INPUT BUFFER.  IF A SUBCOMMAND OTHER THAN 'END' IS           * 02500020
*    ENTERED, CONTROL IS RETURNED TO IKJEBEMA.                        * 02600020
*                                                                     * 02700020
*    3. WHEN AN 'END' SUBCOMMAND IS ENTERED IN 1. OR 2. ABOVE,        * 02800020
*    OR WHEN EDIT IS TERMINATING ABNORMALLY, IKJEBEEX IS INVOKED      * 02900020
*    TO DELETE THE EDIT ACCESS METHOD AND TO UNALLOCATE THE           * 03000020
*    UTILITY DATA SET.  WHEN SYNTAX CHECKING IS IN USE, OR WHEN       * 03100020
*    THE DATA SET TYPE IS BASIC OR IPLI, IKJEBESC IS INVOKED TO       * 03200020
*    PERFORM FINAL PROCESSING FOR THE SYNTAX CHECKER OR LANGUAGE      * 03300020
*    PREPROCESSOR.  THE ATTENTION EXIT AND THE ABNORMAL END EXIT      * 03400020
*    ARE CANCELLED AND THE PERMANENTLY RESIDENT SERVICE ROUTINES,     * 03500020
*    IKJEBEMS AND IKJEBELE, ARE DELETED.  CONTROL IS THEN             * 03600020
*    RETURNED TO IKJEBEMA.                                            * 03700020
*                                                                     * 03800020
*    THE CONTROL SECTION IKJEBEN0 CONTAINS THE PROMPT MESSAGE         * 03900020
*    USED TO PROMPT THE USER FOR AN 'END' OR 'SAVE' SUBCOMMAND.       * 04000020
*                                                                     * 04100020
* ENTRY POINTS --                                                     * 04200020
*         IKJEBEEN -- POINT OF ENTRY FOR 'END' SUBCOMMAND             * 04300020
*              PROCESSING.  CONTROL IS RECEIVED FROM IKJEBEMA         * 04400020
*              WITH AN 'END' SUBCOMMAND IN THE CURRENT INPUT          * 04500020
*              BUFFER.                                                * 04600020
*                                                                     * 04700020
*         IKJEBEXT -- POINT OF ENTRY FOR ABNORMAL TERMINATION         * 04800020
*              OF EDIT.                                               * 04900020
*                                                                     * 05000020
* INPUT --                                                            * 05100020
*    REGISTER 1 (ONE) CONTAINS THE ADDRESS OF THE EDIT COMMUNI-       * 05200020
*    CATION AREA IN ALL CASES.                                        * 05300020
*                                                                     * 05400020
* OUTPUT --                                                           * 05500020
*    A RETURN CODE IN REGISTER 15 (FIFTEEN).  RETURN CODES ARE --     * 05600020
*                                                                     * 05700020
*    00 - NORMAL RETURN TO IKJEBEMA, A SUBCOMMAND OTHER THAN          * 05800020
*    'SAVE' OR 'END' WAS ENCOUNTERED.  THE OFFSET FIELD IN THE        * 05900020
*    CURRENT INPUT BUFFER IS ZEROED AND THE 'NEXT SUBCOMMAND BUFFER'  * 06000021
*    (CAPTNBFR) IS SET TO THE ADDRESS OF THE BUFFER                   * 06100021
*    CONTAINING THE SUBCOMMAND TO BE PROCESSED NEXT.                  * 06200021
*                                                                     * 06300020
*    12 - ABNORMAL RETURN TO IKJEBEMA, TERMINATION PROCESSING         * 06400020
*    COMPLETE.  THIS RETURN CODE WITH BIT 2, BYTE 28 OF CAMAWKA       * 06500020
*    SET TO 1 (MAENDPRC = 1) INDICATES THAT END PROCESSING IS         * 06600020
*    COMPLETE.                                                        * 06700020
*                                                                     * 06800020
* EXTERNAL REFERENCES --                                              * 06900020
*         IKJEBEMS -- EDIT MESSAGE SELECTION ROUTINE.                 * 07000020
*         IKJPTGT  -- PUTGET SERVICE ROUTINE.                         * 07100020
*         IKJEBESA -- SAVE SUBCOMMAND.                                * 07200020
*         IKJEBEEX -- UTILITY ACCESS METHOD CLEAN-UP ROUTINE.         * 07300020
*         IKJEBESC -- SCAN SUBCOMMAND.                                * 07400020
*         IKJSCAN  -- COMMAND SCAN SERVICE ROUTINE.                   * 07500020
*                                                                     * 07600020
*    MACROS USED --                                                   * 07700020
*         DELETE   -- FREE SERVICE ROUTINES.                          * 07800020
*         FREEMAIN -- RETURN GOTTEN CORE TO SYSTEM.                   * 07900020
*         LINK     -- INVOKE IKJSCAN SERVICE ROUTINE.                 * 08000020
*         PUTGET   -- INVOKE PUTGET SERVICE ROUTINE.                  * 08100020
*         SAVE     -- SAVE ENTRY REGISTERS.                           * 08200020
*         STAE     -- CANCEL ABNORMAL END EXIT.                       * 08300020
*         STAX     -- CANCEL ATTENTION EXIT.                          * 08400020
*         IKJCSOA  -- MAP COMMAND SCAN OUTPUT AREA.                   * 08500020
*         IKJPGPB  -- MAP PUTGET PARAMETER BLOCK                      * 08600020
*         IKJEBECA -- DEFINE EDIT COMMUNICATION AREA.                 * 08700020
*         IKJEBEMG -- DEFINE INSERTION FOR EDIT MESSAGE.              * 08800020
*         IKJEBEMI -- DEFINE SYMBOLIC REFERENCES FOR MESSAGES.        * 08900020
*         IKJEBEML -- INVOKE EDIT MESSAGE SELECTION ROUTINE.          * 09000020
*         IKJEBERT -- RETURN TO CALLING ROUTINE.                      * 09100020
*         IKJEBESH -- INVOKE 'SCAN' OR 'SAVE' SUBCOMMAND.             * 09200020
*                                                                     * 09300020
* EXITS, NORMAL --                                                    * 09400020
*    CONTROL IS RETURNED TO IKJEBEMA IN ALL CASES WITH A RETURN       * 09500020
*    CODE IS REGISTER 15 (FIFTEEN) AS OUTLINED IN OUTPUT ABOVE.       * 09600020
*                                                                     * 09700020
* EXITS, ERROR --                                                     * 09800020
*    DOES NOT APPLY.                                                  * 09900020
*                                                                     * 10000020
* TABLES/WORK AREAS --                                                * 10100020
*    THE EDIT COMMUNICATION AREA (IKJEBECA) CONTAINS ALL POINTERS     * 10200020
*    AND OTHER AREAS REFERENCED BY THIS SUBCOMMAND.                   * 10300020
*                                                                     * 10400020
* ATTRIBUTES --                                                       * 10500020
*    RE-ENTRANT, READ-ONLY, REFRESHABLE, NON-PRIVILEGED, ENABLED.     * 10600020
*                                                                     * 10700020
* CHARACTER CODE DEPENDENCY --                                        * 10800020
*    THIS MODULE IS DEPENDENT UPON THE EBCDIC REPRESENTATION          * 10900020
*    OF PACKED DECIMAL DIGITS USED IN THE CONVERSION OF RETURN        * 11000020
*    CODES TO PRINTABLE EBCDIC.                                       * 11100020
*                                                                     * 11200020
* NOTES --                                                            * 11300020
*    THIS SUBCOMMAND PROCESSOR USES THE MAIN CONTROLLER WORK AREA     * 11400020
*    (CAMAWKA) IN THE COMMUNICATION AREA.  THE COMMUNICATION OF       * 11500020
*    END PROCESSING BETWEEN THIS MODULE AND IKJEBEMA IS DEPENDENT     * 11600020
*    UPON BIT 2, BYTE 28 OF CAMAWKA.  CARE MUST BE EXERCISED IN       * 11700020
*    MODIFYING CAMAWKA IN EITHER THIS MODULE OR IKJEBEMA.             * 11800020
*                                                                     * 11900020
*    BIT 2, BYTE 28 OF 'CAMAWKA' ('MAENDPRC') IS USED IN THE          * 11950020
*    FOLLOWING WAY --                                                 * 11960020
*                                                                     * 11970020
*    UPON ENTRY TO THIS ROUTINE --                                    * 11980020
*    'MAENDPRC' IS SET TO ZERO IF A SUBCOMMAND BUFFER FOR 'END'       * 11990020
*    EXISTS AND ITS ADDRESS IS IN THE EDIT COMMUNICATION AREA.        * 11992020
*    'MAENDPRC' IS SET TO ONE IF NO SUBCOMMAND BUFFER EXISTS FOR THIS * 11994020
*    ROUTINE.                                                         * 11996020
*                                                                     * 11998020
*    UPON EXIT FROM THIS ROUTINE --                                   * 11998420
*    'MAENDPRC' IS SET TO ONE IF THE RETURN CODE FROM THIS ROUTINE IS * 11998820
*    12.  ( END PROCESSING IS COMPLETE.)                              * 11999220
*    'MAENDPRC' IS SET TO ZERO IF THE RETURN CODE FROM THIS ROUTINE   * 11999620
*    IS ZERO. ( A SUBCOMMAND OTHER THAN 'END' HAS BEEN ENTERED IN     * 11999720
*    RESPONSE TO THE 'ENTER SAVE OR END' OR 'SAVED' MODE MESSAGE.)    * 11999820
*                                                                     * 11999920
*********************************************************************** 12000020
         EJECT                                                          12100020
*********************************************************************** 12200020
*                                                                     * 12300020
*   GENERAL REGISTER EQUATES USED IN THIS ROUTINE.                    * 12400020
*                                                                     * 12500020
*********************************************************************** 12600020
PARMREG0 EQU   0              PARAMETER REGISTER 0 (ZERO).              12700020
PARMREG1 EQU   1              PARAMETER REGISTER 1.                     12800020
FLAGREG  EQU   2              FLAG WORD FOR IKJSCAN.                    12900020
LEV1REG  EQU   2              FIRST LEVEL MESSAGE NUMBER.               13000020
SCLENREG EQU   2              LENGTH OF SUBCOMMAND.                     13100020
LEV2REG  EQU   3              SECOND LEVEL MESSAGE NUMBER.              13200020
OAREAREG EQU   3              OUTPUT AREA FOR IKJSCAN.                  13300020
SCPTREG  EQU   3              ADDRESS OF SUBCOMMAND NAME.               13400020
INS1REG  EQU   4              ADDRESS OF FIRST LEVEL INSERTION.         13500020
INS2REG  EQU   5              ADDRESS OF SECOND LEVEL INSERTION.        13600020
BFRREG   EQU   6              ADDRESS OF SUBCOMMAND BUFFER.             13700020
PTGTREG  EQU   7              ADDRESS OF PUTGET PARM BLOCK.             13800020
BRNCHREG EQU   8              RETURN ADDRESS AFTER SUBROUTINE           13900020
*                                  PROCESSING.                          14000020
COMMREG  EQU   9              COMMUNICATION AREA POINTER.               14100020
BASEREG  EQU   11             BASE REGISTER.                            14200020
DATAREG  EQU   12             POINTER TO DATA.                          14300020
SAVEREG  EQU   13             SAVE AREA POINTER.                        14400020
RETREG   EQU   14             ADDRESS OF RETURN POINT.                  14500020
EPLOCREG EQU   15             ENTRY POINT REGISTER.                     14600020
RETCDREG EQU   15             RETURN CODE REGISTER.                     14700020
SCKNMREG EQU   2              FLOATING POINT REGISTER 2 - NAME OF       14800020
*                                  SYNTAX CHECKER.                      14900020
         EJECT                                                          15000020
         SAVE  (14,12),,*     SAVE ENTRY REGISTERS.                     15100020
EN001010 EQU   *                                                        15200020
         BALR  BASEREG,X0     ESTABLISH ADDRESSABILITY FOR THIS         15300020
         USING *,BASEREG           ROUTINE.                             15400020
         LR    COMMREG,PARMREG1 SAVE ADDRESS OF COMMUNICATION           15500020
*                                  AREA.                                15600020
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         15700020
*                                  COMMUNICATION AREA.                  15800020
         L     EPLOCREG,CANXTSVA ADDRESS OF NEXT AVAILABLE SAVE         15900020
*                                  AREA.                                16000020
         ST    SAVEREG,X4(EPLOCREG) CROSS CHAIN PREVIOUS AND            16100020
         ST    EPLOCREG,X8(,SAVEREG) CURRENT SAVE AREAS.                16200020
         LR    SAVEREG,EPLOCREG INITIALIZE SAVE AREA POINTER.           16300020
         LA    EPLOCREG,X72(,EPLOCREG) COMPUTE ADDRESS OF NEXT          16400020
         ST    EPLOCREG,CANXTSVA   SAVE AREA AND SAVE.                  16500020
         SPACE 5                                                        16600020
*********************************************************************** 16700020
*                                                                     * 16800020
*   WHEN AN END SUBCOMMAND IS ENTERED, DETERMINE IF CURRENT INPUT     * 16900020
*   BUFFER MUST BE FREED.  WHEN BUFFER MUST BE FREED, ISSUE THE       * 17000020
*   FREEMAIN MACRO INSTRUCTION SPECIFYING THE LAST INPUT BUFFER       * 17100020
*   ADDRESS.  OTHERWISE, CHECK IF THE DATA SET HAS BEEN MODIFIED      * 17200020
*   SINCE THE LAST SAVE.  IF DATA SET HAS BEEN SAVED, PROCEED WITH    * 17300020
*   TERMINATION PROCESSING.  IF DATA SET HAS NOT BEEN SAVED, PROMPT   * 17400020
*   USER TO DETERMINE IF A SAVE IS DESIRED.                           * 17500020
*                                                                     * 17600020
*********************************************************************** 17700020
         OI    ENCFLAGS,MAENDPRC SHOW END PROCESSING ATTEMPTED.         17800020
         TM    CACFLAG4,CAPTGTBF CHECK IF BUFFER MUST BE FREED.         17900020
         BZ    EN001030       IF NOT, BRANCH TO CHECK IF DATA SET       18000020
*                                  HAS BEEN MODIFIED SINCE LAST         18100020
*                                  SAVE.                                18200020
         BAL   BRNCHREG,EN005090 BRANCH TO FREE BUFFER.                 18300020
         SPACE 2                                                        18400020
EN001030 EQU   *                                                        18500020
         TM    CACFLAG4,CAINPROC DETERMINE IF CURRENT SOURCE OF         18550020
*                                  INPUT IS AN IN-CORE PROCEDURE.       18560020
         BO    EN004050       IF SO, BRANCH TO TERMINATE.               18570020
         TM    CACFLAG2,CADSMODS DETERMINE IF DATA SET HAS BEEN         18600020
*                                  MODIFIED SINCE LAST SAVE.            18700020
         BZ    EN004050       IF DATA SET HAS NOT BEEN MODIFIED,        18800020
*                                  BRANCH TO TERMINATE.                 18900020
         XC    ENMSPLST(X12),ENMSPLST ZERO PARAMETER LIST AND           19000020
         IKJEBEML M555,,,,MF=(E,ENMSPLST) CALL IKJEBEMS.                19100020
         B     EN001050(RETCDREG) RETURN CODE BRANCH TABLE.             19200020
EN001050 EQU   *                                                        19300020
         B     EN002030       00 - NORMAL RETURN.                       19400020
         B     EN003090       04 - ATTENTION OCCURRED.                  19500020
         B     EN001090       08 - NOWAIT, NO LINE OUTPUT.              19600020
         B     EN001090       12 - INVALID PARAMETERS.                  19700020
         B     EN006010       16 - NO CORE AVAILABLE.                   19800020
         SPACE 5                                                        19900020
EN001090 EQU   *                                                        20000020
         LA    INS1REG,ENMLPUTL INDICATE PUTLINE FAILURE.               20100020
EN002010 EQU   *                                                        20200020
         LR    INS2REG,RETCDREG SAVE RETURN CODE FOR MESSAGE.           20300020
         B     EN006020       BRANCH TO PUT MESSAGE.                    20400020
         SPACE 5                                                        20500020
EN002030 EQU   *                                                        20600020
         LA    PTGTREG,ENPGPB ADDRESS OF PUTGET PARAMETER BLOCK.        20700020
         MVC   X0(ENSAVLN,PTGTREG),ENSAVE MOVE PARAMETER BLOCK TO       20800020
*                                  WORK AREA.                           20900020
EN002035 EQU   *                                                        20950020
         PUTGET PARM=(PTGTREG),MF=(E,CATMPLST) PUT PROMPT MESSAGE       21000020
         B     EN002050(RETCDREG) RETURN CODE BRANCH TABLE.             21100020
EN002050 EQU   *                                                        21200020
         B     EN002085       00 - NORMAL RETURN FROM TERMINAL.         21300020
         B     EN002090       04 - INPUT NOT FROM TERMINAL.             21400020
         B     EN003090       08 - ATTENTION OCCURRED.                  21500020
         B     EN002080       12 - SECOND-LEVEL MESSAGE PRESENT.        21600020
         B     EN002070       16 - NOWAIT SPECIFIED FOR OUTPUT.         21700020
         B     EN002070       20 - NOWAIT SPECIFIED FOR INPUT.          21800020
         B     EN002070       24 - INVALID PARAMETERS.                  21900020
         B     EN006010       28 - NO CORE AVAILABLE.                   22000020
         SPACE 5                                                        22100020
EN002070 EQU   *                                                        22200020
         LA    INS1REG,ENMLPTGT INDICATE PUTGET FAILURE.                22300020
         B     EN002010       BRANCH TO GET RETURN CODE.                22400020
         SPACE 5                                                        22450020
EN002080 EQU   *                                                        22460020
         L     DATAREG,CAPTECT ADDRESS OF ECT.                          22470020
         OI    (ECTMSGF-ECT)(DATAREG),ENLEV2MS INDICATE FLUSH OF        22480020
*                                  SECOND-LEVEL MESSAGES.               22490020
         B     EN002035       BRANCH TO RE-ISSUE PUTGET.                22492020
         EJECT                                                          22500020
*********************************************************************** 22600020
*                                                                     * 22700020
*   ONCE A LINE OF INPUT IS AVAILABLE FROM THE TERMINAL, INVOKE       * 22800020
*   IKJSCAN TO SCAN THE INPUT BUFFER.  IF THE SUBCOMMAND ENTERED      * 22900020
*   IS NOT A SAVE SUBCOMMAND, RETURN TO MAINLINE PROCESSING.  IF      * 23000020
*   A SAVE SUBCOMMAND IS ENTERED, INVOKE IKJEBESA.                    * 23100020
*                                                                     * 23200020
*********************************************************************** 23300020
EN002085 EQU   *                                                        23350020
         NI    CACFLAG4,X'FF'-CAINPROC INSURE THAT CURRENT INPUT        23360020
*                                  SOURCE INDICATION IS TERMINAL.       23370020
         B     EN002095       BRANCH TO CONTINUE PROCESSING.            23380020
EN002090 EQU   *                                                        23400020
         OI    CACFLAG4,CAINPROC INDICATE THAT IN-CORE PROCEDURE        23450020
*                                  IS CURRENT INPUT SOURCE.             23460020
EN002095 EQU   *                                                        23470020
         L     BFRREG,(PGPBIBUF-PGPB)(,PTGTREG) ADDRESS OF INPUT        23500020
*                                  BUFFER.                              23600020
         ST    BFRREG,CAPTIBFR SAVE ADDRESS OF INPUT BUFFER IN          23700020
*                                  THE COMMUNICATION AREA.              23800020
         OI    CACFLAG4,CAPTGTBF INDICATE PUTGET GOT BUFFER.            23900020
         BAL   BRNCHREG,EN005030 BRANCH TO LINK TO IKJSCAN.             24000020
         CH    SCLENREG,ENCON001 CHECK FOR LENGTH = 1.                  24100020
         BE    EN003010       IF = 1, BRANCH TO CHECK FOR 'S'.          24200020
         CH    SCLENREG,ENCON002 CHECK FOR LENGTH = 4.                  24300020
         BNE   EN003060       IF NOT = 4, BRANCH TO CHECK FOR           24400020
*                                  AN 'END' SUBCOMMAND.                 24500020
EN003010 EQU   *                                                        24600020
         BCTR  SCLENREG,X0    REDUCE LENGTH BY 1 FOR COMPARE.           24700020
         EX    SCLENREG,ENCLC001 CHECK FOR 'SAVE' OR 'S'.               24800020
         BNE   EN003070       IF NEITHER, BRANCH TO RETURN TO           24900020
*                                  MAINLINE.                            25000020
         IKJEBESH (COMMREG),IKJEBESA,PARAM=((COMMREG)),                X25100020
               MF=(E,ENLINKSF) INVOKE SAVE SUBCOMMAND.                  25200020
         B     EN003030(RETCDREG) RETURN CODE BRANCH TABLE.             25300020
EN003030 EQU   *                                                        25400020
         B     EN003050       00 - NORMAL RETURN.                       25500020
         B     EN003050       04 - NOT USED BY SAVE.                    25600020
         B     EN003040       08 - UNSUCCESSFUL SAVE OPERATION.         25700020
         B     EN004050       12 - I/O ERROR ON UTILITY DATA SET.       25800020
         EJECT                                                          25850020
*********************************************************************** 25852020
*                                                                     * 25854020
*   UPON RETURN FROM SAVE WITH A RETURN CODE OF EIGHT(8), THE         * 25856020
*   USER IS GIVEN ANOTHER CHANCE TO SAVE IF ABEND IN PROGRESS.   A50474 25858021
*                                                                     * 25858820
*********************************************************************** 25859220
EN003040 EQU   *                                                        25860020
         TM    CACFLAG4,CAABEND   CHECK IF ABEND IN PROCESS             25870020
         BZ    EN004000       IF NO ABEND, RETURN TO IKJEBEMA           25880020
         TM    CACFLAG4,CAPTGTBF  CHECK IF BUFFER TO BE FREED           25894020
         BZ    EN002030       IF NO, REPROMPT USER FOR 'SAVE'           25896020
*                             OR 'END' BEFORE TERMINATING EDIT          25896420
         BAL   BRNCHREG,EN005090  FREE SUBCOMMAND BUFFER                25898020
         B     EN002030       REPROMPT USER FOR 'SAVE' OR 'END'         25898420
         EJECT                                                          25900020
*********************************************************************** 26000020
*                                                                     * 26100020
*   UPON RETURN FROM SAVE, INVOKE IKJSCAN TO SCAN INPUT BUFFER        * 26200020
*   FOR AN END SUBCOMMAND.  IF AN END SUBCOMMAND IS PRESENT,          * 26300020
*   CONTINUE WITH END PROCESSING.  IF NOT AN END SUBCOMMAND,          * 26400020
*   RETURN TO MAINLINE PROCESSING.                                    * 26500020
*                                                                     * 26600020
*********************************************************************** 26700020
EN003050 EQU   *                                                        26800020
         TM    CACFLAG4,CAABEND CHECK IF ABEND IN PROGRESS.             26900020
         BO    EN004050       IF AN ABEND, DO NOT PROCESS               27000020
*                                  REMAINING BUFFER.                    27100020
         TM    CACFLAG4,CAPTGTBF CHECK IF BUFFER OBTAINED        A45718 27198421
*                                  THROUGH PUTGET.               A45718 27200021
         BZ    EN003055       IF NOT, BRANCH AROUND FREEMAIN.    A45718 27250021
         BAL   BRNCHREG,EN005090 BRANCH TO FREE BUFFER.          A45718 27360021
EN003055 EQU   *                                                 A45718 27370021
         LA    PTGTREG,ENPGPB OBTAIN ADDRESS OF PGPB.            A45718 27380021
         MVC   X0(ENSAVLN,PTGTREG),ENSAVE SET PARMS IN PGPB.     A45718 27392021
         XC    ENPGPB+X4(X4),ENPGPB+X4 INDICATE NO PUT.          A45718 27394021
         B     EN002035       BRANCH TO INVOKE PUTGET.           A45718 27396021
EN003060 EQU   *                                                        27400020
         CH    SCLENREG,ENCON003 CHECK FOR LENGTH = 3.                  27500020
         BNE   EN003070       IF NOT = 3, BRANCH TO RETURN.             27600020
         BCTR  SCLENREG,X0    REDUCE LENGTH BY 1 FOR COMPARE.           27700020
         EX    SCLENREG,ENCLC002 CHECK FOR 'END' SUBCOMMAND.            27800020
         BE    EN004050       IF 'END', BRANCH TO COMPLETE              27900020
*                                  PROCESSING.                          28000020
         SPACE 5                                                        28100020
*********************************************************************** 28200020
*                                                                     * 28300020
*    WHEN A SUBCOMMAND OTHER THAN SAVE OR END IS ENTERED         A50473 28350021
*    AT THE TERMINAL, RESET THE BUFFER OFFSET BEFORE RETURNING   A50473 28400021
*    TO IKJEBEMA WITH RETURN CODE ZERO.  IF AN ABEND IS IN       A50473 28450021
*    PROGRESS, CONTINUE TERMINATION PROCESSING.                  A50473 28500021
*                                                                A50473 28550021
*********************************************************************** 28900020
EN003070 EQU   *                                                        29000020
         XC    X2(X2,BFRREG),X2(BFRREG) FOR A BUFFER WHICH HAS          29100020
*                                  BEEN PROCESSED, RESET OFFSET         29200020
*                                  TO ZERO.                             29300020
         ST    BFRREG,CAPTNBFR UPDATE 'NEXT' BFR PTR.            A50473 29310021
         NI    CACFLAG4,X'FF'-CAPTGTBF INDICATE NO BFR TO FREE.  A50473 29320021
         XC    CAPTIBFR(X4),CAPTIBFR CLEAR CURRENT BFR PTR.      A50473 29350021
EN003090 EQU   *                                                        29400020
         TM    CACFLAG4,CAABEND CHECK IF AN ABEND IN PROGRESS.          29500020
         BO    EN004050       IF SO, BRANCH TO COMPLETE 'END'.          29600020
         SR    RETCDREG,RETCDREG SET ZERO RETURN CODE.                  29700020
EN004000 EQU   *                                                        29710020
         NI    ENCFLAGS,X'FF'-MAENDPRC INDICATE THAT END PROCESSING     29750020
*                                   IS NOT COMPLETE.                    29760020
         EJECT                                                          29900020
*********************************************************************** 30000020
*                                                                     * 30100020
*   EXIT -- RETURN TO MAINLINE (IKJEBEMA) WITH THE RETURN CODE        * 30200020
*   SET ELSEWHERE.  RETURN CODES ARE 0 (ZERO) - RESUME NORMAL         * 30300020
*   PROCESSING - AND 12 - TERMINATE EDIT.                             * 30400020
*                                                                     * 30500020
*********************************************************************** 30600020
EN004010 EQU   *                                                        30700020
         IKJEBERT (14,12),,RC=(15) RETURN TO IKJEBEMA.                  30800020
         EJECT                                                          30900020
*********************************************************************** 31000020
*                                                                     * 31100020
*   ENTRY POINT -- IKJEBEXT                                           * 31200020
*                                                                     * 31300020
*   CONTROL IS PASSED TO THIS LOCATION WHEN THE MAIN CONTROLLER       * 31400020
*   DISCOVERS A TERMINAL ERROR CONDITION.                             * 31500020
*                                                                     * 31600020
*********************************************************************** 31700020
IKJEBEXT SAVE  (14,12)        SAVE ENTRY REGISTERS.                     31800020
EN004030 EQU   *                                                        31900020
         BALR  BASEREG,X0     ESTABLISH ADDRESSABILITY FOR THIS         32000020
         LA    RETCDREG,EN004030-EN001010 ROUTINE BASED ON MAIN         32100020
         SR    BASEREG,RETCDREG    ENTRY POINT.                         32200020
         LR    COMMREG,PARMREG1 SAVE ADDRESS OF COMMUNICATION           32300020
*                                  AREA.                                32400020
         L     EPLOCREG,CANXTSVA ADDRESS OF NEXT AVAILABLE SAVE         32500020
*                                  AREA.                                32600020
         ST    SAVEREG,X4(EPLOCREG) CROSS CHAIN PREVIOUS AND            32700020
         ST    EPLOCREG,X8(,SAVEREG) CURRENT SAVE AREAS.                32800020
         LR    SAVEREG,EPLOCREG INITIALIZE SAVE AREA POINTER.           32900020
         LA    EPLOCREG,X72(,EPLOCREG) COMPUTE ADDRESS OF NEXT          33000020
         ST    EPLOCREG,CANXTSVA   SAVE AREA AND SAVE.                  33100020
         SPACE 5                                                        33200020
*********************************************************************** 33300020
*                                                                     * 33400020
*   END PROCESSING.                                                   * 33500020
*                                                                     * 33600020
*   (1) INVOKE IKJEBEEX TO DELETE THE EDIT ACCESS METHOD AND TO       * 33700020
*   UNALLOCATE THE UTILITY DATA SET.  (2) INVOKE THE SCAN             * 33800020
*   SUBCOMMAND PROCESSOR FOR FINAL ENTRY TO SYNTAX CHECKER IF         * 33900020
*   THE DATA SET TYPE IS BASIC OR IPLI OR IF THE SCAN SWITCH IS       * 34000020
*   ON.  (3) CANCEL THE ABNORMAL END EXIT AND THE ATTENTION EXIT.     * 34100020
*   (4) DELETE THE PERMANENTLY RESIDENT SERVICE ROUTINES --           * 34200020
*   IKJEBEUT, IKJEBEMS, AND IKJEBELE.                                 * 34300020
*                                                                     * 34400020
*********************************************************************** 34500020
EN004050 EQU   *                                                        34600020
         TM    CACFLAG4,CAPTGTBF CHECK IF BUFFER MUST BE FREED.         34700020
         BZ    EN004070       IF NOT, BRANCH TO CHECK IF SYNTAX         34800020
*                                  CHECKING IN USE.                     34900020
         BAL   BRNCHREG,EN005090 BRANCH TO FREE BUFFER.                 35000020
EN004070 EQU   *                                                        35100020
         L     PARMREG0,CAPTCDCB ADDRESS OF CURRENT UTILITY DCB.        35200020
         LR    PARMREG1,COMMREG ADDRESS OF COMMUNICATION AREA.          35300020
         LINK  EP=IKJEBEEX    LINK TO IKJEBEEX                         X35400020
                                   TO DELETE THE UTILITY ACCESS        X35500020
                                   METHOD AND WORK AREA.                35600020
* --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- * 35700020
         CLI   CADSCODE,CABASIC TEST FOR BASIC DATA SET TYPE.           35800020
         BE    EN004090       IF BASIC, BRANCH TO TERMINATE             35900020
*                                  PREPROCESSOR.                        36000020
         CLI   CADSCODE,CAIPLI TEST FOR IPLI DATA SET TYPE.             36100020
         BE    EN004090       IF IPLI, BRANCH TO TERMINATE              36200020
*                                  PREPROCESSOR.                        36300020
         TM    CACFLAG1,CASCANSW TEST IF SYNTAX CHECKING IS IN US       36400020
         BZ    EN005010       IF NOT, BRANCH TO CANCEL STAX AND         36500020
*                                  STAE EXITS.                          36600020
EN004090 EQU   *                                                        36700020
         TM    CASYNAME,ALLBITS CHECK IF SYN CHECKER IN SYSTEM    M5133 36750021
         BNM   EN005010       IF NOT IN SYSTEM, BR TO CANCEL      M5133 37100021
*                                  STAX AND STAE EXITS.                 37200020
         MVC   CABFRPL(SCNOFEND-SCNOFMSG),SCNOFMSG MOVE SCAN            37300020
*                                  OFF MESSAGE TO GOTTEN CORE.          37400020
         LA    PARMREG1,CABFRPL OBTAIN ADDRESS OF SCAN OFF              37500020
*                                  MESSAGE.                             37600020
         OI    CACFLAG1,CAENDSC INDICATE TO SCAN THAT FINAL CALL        37700020
*                                  IS FROM THE CONTROLLER.              37800020
         ST    PARMREG1,CAPTIBFR PLACE ADDRESS OF DUMMY                 37900020
*                                  SUBCOMMAND IN COMMUNICATION          38000020
*                                  AREA FOR IKJEBESC.                   38100020
         MVI   CAPTIBFR,CAOPERND INDICATE THAT OPERANDS ARE             38200020
*                                  PRESENT ON SUBCOMMAND.               38300020
         IKJEBESH (COMMREG),IKJEBESC,PARAM=((COMMREG)),                X38400020
               MF=(E,ENLINKSF) TERMINATE SYNTAX CHECKER.                38500020
* --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- * 38600020
EN005010 EQU   *                                                        38700020
         STAX  ,MF=(E,CASTAXPL) CANCEL ATTENTION EXIT.                  38800020
         STAE  0,,MF=(E,CASTAEPL) CANCEL ABNORMAL END EXIT.             38900020
* --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- * 39000020
         DELETE EP=IKJEBELE   DELETE LINE EDIT ROUTINE.                 39100020
         DELETE EP=IKJEBEMS   DELETE MESSAGE SELECTION ROUTINE.         39200020
         LA    RETCDREG,X12(,X0) SET RETURN CODE = 12 AND BRANCH        39300020
         B     EN004010            TO EXIT.                             39400020
         EJECT                                                          39500020
*********************************************************************** 39600020
*                                                                     * 39700020
*   THIS SUBROUTINE INVOKES IKJSCAN AND INTERROGATES ITS RETURN       * 39800020
*   CODES.  IT RETURNS THE SUBCOMMAND ADDRESS AND LENGTH TO THE       * 39900020
*   CALLER.                                                           * 40000020
*                                                                     * 40100020
*********************************************************************** 40200020
EN005030 EQU   *                                                        40300020
         LA    FLAGREG,ENSCNFLG ADDRESS OF FLAG WORD.                   40400020
         XC    ENSCNFLG(L'ENSCNFLG),ENSCNFLG ZERO FLAG WORD.            40500020
         OI    ENSCNFLG,ENNOSCHK INDICATE NO SYNTAX CHECKING.           40600020
         LA    OAREAREG,ENSCNOA ADDRESS OF IKJSCAN OUTPUT AREA.         40700020
         XC    ENLINKSF(X8),ENLINKSF ZERO LINK PARAMETER AREA.          40800020
         LINK  EP=IKJSCAN,PARAM=(,,,(FLAGREG),(OAREAREG),(BFRREG)),    X40900020
               MF=(E,CATMPLST),SF=(E,ENLINKSF) INVOKE IKJSCAN.          41000020
         LTR   RETCDREG,RETCDREG CHECK IF IKJSCAN WAS SUCCESSFUL.       41100020
         BZ    EN005050       IF SO, BRANCH TO GET ADDRESS AND          41200020
*                                  LENGTH OF SUBCOMMAND.                41300020
         LA    INS1REG,ENMLSCAN INDICATE SCAN FAILURE.                  41400020
         B     EN002010       BRANCH TO GET RETURN CODE.                41500020
EN005050 EQU   *                                                        41600020
         CLI   ENSCNOA+(CSOAFLG-CSOA),CSOAVNP CHECK IF VALID            41700020
*                                  WITH NO PARAMETERS.                  41800020
         BE    EN005070       IF SO, BRANCH TO SET OPERAND FLAG.        41900020
         CLI   ENSCNOA+(CSOAFLG-CSOA),CSOAVWP CHECK IF VALID            42000020
*                                  WITH PARAMETERS.                     42100020
         BNE   EN002030       IF NEITHER, BRANCH TO RE-ISSUE     A50474 42200021
*                                  PUTGET (WITH MSG.).           A50474 42300021
         MVI   CAPTIBFR,CAOPERND INDICATE THAT OPERANDS ARE             42400020
*                                  PRESENT ON SUBCOMMAND.               42500020
EN005070 EQU   *                                                        42600020
         LH    SCLENREG,ENSCNOA+(CSOALNM-CSOA) SET UP LENGTH AND        42700020
         L     SCPTREG,ENSCNOA+(CSOACNM-CSOA) ADDRESS RETURNED BY       42800020
*                                  IKJSCAN.                             42900020
         BR    BRNCHREG       RETURN TO CALLER.                         43000020
         EJECT                                                          43100020
*********************************************************************** 43200020
*                                                                     * 43300020
*   THIS SUBROUTINE IS USED TO FREE THE LAST USED SUBCOMMAND          * 43400020
*   BUFFER.                                                           * 43500020
*                                                                     * 43600020
*********************************************************************** 43700020
EN005090 EQU   *                                                        43800020
         L     BFRREG,CAPTIBFR ADDRESS OF BUFFER TO BE FREED.           43900020
         LH    BFRREG,X0(,BFRREG) LENGTH OF BUFFER.                     44000020
         NI    CAPTIBFR,X255-CAOPERND SET OPERAND FLAG TO ZERO.         44100020
         FREEMAIN E,LV=(BFRREG),A=CAPTIBFR,SP=SUBPOOL1,                X44200020
               MF=(E,ENFREMNL) FREE INPUT BUFFER.                       44300020
         NI    CACFLAG4,X255-CAPTGTBF INDICATE THAT BUFFER WAS          44400020
*                                  FREED.                               44500020
         BR    BRNCHREG       RETURN TO CALLER.                         44600020
         SPACE 5                                                        44700020
*********************************************************************** 44800020
*                                                                     * 44900020
*   THIS SUB-SECTION COMPLETES MESSAGE PROCESSING FOR THE END         * 45000020
*   SUBCOMMAND PROCESSOR.  SINCE ALL MESSAGES ARE OF A TERMINAL       * 45100020
*   NATURE, TERMINATION PROCESSING CONTINUES AFTER THE MESSAGE        * 45200020
*   IS PUT.                                                           * 45300020
*                                                                     * 45400020
*********************************************************************** 45500020
EN006010 EQU   *                                                        45600020
         LA    LEV1REG,M312   RELATIVE MESSAGE TO BE PUT.               45700020
         LA    INS1REG,ENINS001 ADDRESS OF FIRST LEVEL INSERTION        45800020
*                                  LIST.                                45900020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE OR          46000020
         SR    INS2REG,INS2REG     INSERTION.                           46100020
         B     EN006030       BRANCH TO PUT MESSAGE.                    46200020
EN006020 EQU   *                                                        46300020
         LA    LEV1REG,M313   RELATIVE MESSAGE TO BE PUT.               46400020
         LA    INS1REG,ENMLTABL(INS1REG) INDEX TO SERVICE ROUTINE       46500020
*                                  NAME INSERTION.                      46600020
         MVC   ENLNIN1(X12),X0(INS1REG) MOVE ROUTINE NAME TO            46700020
*                                  INSERTION RECORD.                    46800020
         LA    INS1REG,ENPTIN2 ADDRESS OF SECOND INSERTION RECORD       46900020
         MVC   X0(X8,INS1REG),ENCON004 INITIALIZE POINTER, LENGTH       47000020
*                                  AND OFFSET.                          47100020
         CVD   INS2REG,X8(,INS1REG) CONVERT RETURN CODE TO              47200020
*                                  DECIMAL.                             47300020
         OI    X15(INS1REG),ENMLZONE CHANGE ZONE ON LAST BYTE.          47400020
         UNPK  X9(X3,INS1REG),X14(X2,INS1REG) CONVERT TO EBCDIC         47500020
         MVC   X8(X2,INS1REG),X10(INS1REG) AND MOVE TO INSERTION.       47600020
         ST    INS1REG,ENPTIN1 CHAIN INSERTION RECORDS.                 47700020
         LA    LEV2REG,M3131  SET UP SECOND LEVEL MESSAGE NUMBER,       47800020
         LA    INS2REG,ENMSGIN1    ADDRESS OF INSERTION LIST, AND       47900020
         SR    INS1REG,INS1REG     SHOW NO FIRST LEVEL INSERTION.       48000020
EN006030 EQU   *                                                        48100020
         IKJEBEML (LEV1REG),(LEV2REG),(INS1REG),(INS2REG),             X48200020
               MF=(E,ENMSPLST) BRANCH TO PUT MESSAGE.                   48300020
         B     EN004050       BRANCH TO CONTINUE TERMINATION            48400020
*                                  PROCESSING.                          48500020
         EJECT                                                          48600020
*********************************************************************** 48700020
*                                                                     * 48800020
*   EQUATES, CONSTANTS, AND DATA AREAS USED BY THE END SUBCOMMAND     * 48900020
*   PROCESSOR.                                                        * 49000020
*                                                                     * 49100020
*********************************************************************** 49200020
ENMLTABL DS    0F                                                       49300020
ENMLPUTL EQU   0*12           OFFSET TO PUTLINE ENTRY.                  49400020
ENNAME01 EQU   *                                                        49500020
         DC    AL2(ENNAME02-*) INSERTION LENGTH.                        49600020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      49700020
         DC    C'PUTLINE'     SERVICE ROUTINE NAME.                     49800020
ENNAME02 EQU   *                                                        49900020
         DC    (12-(ENNAME02-ENNAME01))C' ' FILL CHARACTERS.            50000020
ENMLPTGT EQU   1*12           OFFSET TO PUTGET ENTRY.                   50100020
ENNAME03 EQU   *                                                        50200020
         DC    AL2(ENNAME04-*) INSERTION LENGTH.                        50300020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      50400020
         DC    C'PUTGET'      SERVICE ROUTINE NAME.                     50500020
ENNAME04 EQU   *                                                        50600020
         DC    (12-(ENNAME04-ENNAME03))C' ' FILL CHARACTERS.            50700020
ENMLSCAN EQU   2*12           OFFSET TO SCAN ENTRY.                     50800020
ENNAME05 EQU   *                                                        50900020
         DC    AL2(ENNAME06-*) INSERTION LENGTH.                        51000020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      51100020
         DC    C'SCAN'        SERVICE ROUTINE NAME.                     51200020
ENNAME06 EQU   *                                                        51300020
         DC    (12-(ENNAME06-ENNAME05))C' ' FILL CHARACTERS.            51400020
ENCON001 DC    H'1'           LENGTH 1.                                 51500020
ENCON002 DC    H'4'           LENGTH 4.                                 51600020
ENCON003 DC    H'3'           LENGTH 3.                                 51700020
ENCON004 DC    A(0),H'6',AL2(M3131IN2) POINTER, LENGTH AND OFFSET       51800020
*                                  FOR INSERTION RECORD.                51900020
ENCON005 DC    CL4'SAVE'      SAVE SUBCOMMAND NAME.                     52000020
ENCON006 DC    CL3'END'       END SUBCOMMAND NAME.                      52100020
ENCLC001 CLC   X0(*-*,SCPTREG),ENCON005 CHECK FOR SAVE.                 52200020
ENCLC002 CLC   X0(*-*,SCPTREG),ENCON006 CHECK FOR END.                  52300020
ENINS001 IKJEBEMG 0,M312IN1,'EDIT' COMMAND NAME INSERTION.              52400020
SCNOFMSG DC    AL2(SCNOFEND-*),AL2(0),CL3'OFF' SCAN OFF MESSAGE.        52500020
SCNOFEND EQU   *              SCAN OFF MESSAGE END.                     52600020
ENSAVE   PUTGET OUTPUT=(IKJEBMSG,SINGLE,MODE),TERMGET=(EDIT,WAIT),     X52700020
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),MF=L                  52800020
ENSAVLN  EQU   *-ENSAVE       LENGTH OF PARAMETER BLOCK.                52900020
ENMLZONE EQU   X'0F'          EBCDIC NUMERIC ZONE BITS.                 53000020
ENLEV2MS EQU   X'80'          BIT SETTING FOR 'ECTMSGF' BYTE OF         53050020
*                                  ECT TO INDICATE THAT EXISTING        53060020
*                                  SECOND-LEVEL MESSAGES ARE TO         53070020
*                                  DELETED.                             53080020
ENNOSCHK EQU   X'80'          NO SYNTAX CHECKING REQUIRED FLAG.         53100020
ALLBITS  EQU   X'FF'          MASK OF BINARY 1'S FOR TM OPCODE    M5133 53150021
SUBPOOL1 EQU   1              SUBPOOL VALUE.                            53200020
X0       EQU   0              OFFSET 0.                                 53300020
X2       EQU   2              OFFSET 2.                                 53400020
X3       EQU   3              OFFSET 3.                                 53500020
X4       EQU   4              OFFSET 4.                                 53600020
X8       EQU   8              OFFSET 8.                                 53700020
X9       EQU   9              OFFSET 9.                                 53800020
X10      EQU   10             OFFSET 10.                                53900020
X12      EQU   12             OFFSET 12.                                54000020
X14      EQU   14             OFFSET 14.                                54100020
X15      EQU   15             OFFSET 15.                                54200020
X28      EQU   28             OFFSET 28.                                54300020
X72      EQU   72             OFFSET 72.                                54400020
X255     EQU   255            OFFSET 255.                               54500020
         IKJEBEMI (312,313,555) MESSAGE EQUATES.                        54600020
         EJECT                                                          54700020
         IKJEBECA                                                       54800020
         SPACE 5                                                        54900020
*********************************************************************** 55000020
*                                                                     * 55100020
*   DEFINE END SUBCOMMAND PROCESSOR WORKAREA.                         * 55200020
*                                                                     * 55300020
*********************************************************************** 55400020
         ORG   CAMAWKA        DEFINE WORK AREA FOR END SUBCOMMAND       55500020
ENLINKSF DS    2F             PARAMETER LIST FOR SUBCOMMAND.            55600020
ENSCNFLG DS    F              FLAG WORD FOR IKJSCAN.                    55700020
ENSCNOA  DS    2F             IKJSCAN OUTPUT AREA.                      55800020
         ORG   CAMAWKA        RE-USE WORKAREA.                          55900020
ENMSPLST DS    5F             PARAMETER LIST FOR MESSAGE ROUTINE.       56000020
         ORG   CAMAWKA        RE-USE WORK AREA.                         56100020
ENFREMNL DS    3F             PARAMETER LIST FOR FREEMAIN.              56200020
         ORG   CAMAWKA        RE-USE WORK AREA.                         56300020
ENPGPB   DS    4F             PUTGET PARAMETER BLOCK.                   56400020
         ORG   CAMAWKA+X28    ORIGIN TO LAST WORD OF CAMAWKA.           56500020
ENCFLAGS EQU   MACFLAGS       CONTROL FLAGS, BYTE 1.                    56600020
*                             BITS 0, 1 RESERVED.                       56700020
*                             BIT 2, END PROCESSING COMPLETE.           56800020
*                                  0 = NOT COMPLETE.                    56850020
*                                  1 = COMPLETE.                        56860020
*                             BITS 3-7 RESERVED.                        56900020
         SPACE 2                                                        57000020
         ORG   CATEMPBF       DEFINE INSERTION RECORD FORMAT.           57100020
ENMSGIN1 DS    0F             INSERTION RECORD FOR IKJEBEMS.            57200020
ENPTIN1  DS    A              POINTER TO NEXT INSERTION.                57300020
ENLNIN1  DS    H              LENGTH OF INSERTION RECORD.               57400020
ENOFFIN1 DS    H              OFFSET IN MESSAGE TO INSERTION.           57500020
ENINS1   DS    CL80           INSERTION TEXT.                           57600020
ENMSGIN2 DS    0F             INSERTION RECORD FOR IKJEBEMS.            57700020
ENPTIN2  DS    A              POINTER TO NEXT INSERTION.                57800020
ENLNIN2  DS    H              LENGTH OF INSERTION RECORD.               57900020
ENOFFIN2 DS    H              OFFSET IN MESSAGE TO INSERTION.           58000020
ENINS2   DS    CL80           INSERTION TEXT.                           58100020
         EJECT                                                          58200020
         IKJCSOA                                                        58300020
         EJECT                                                          58400020
         IKJPGPB                                                        58500020
         IKJECT                                                         58550020
         TITLE 'TSO EDIT - IKJEBEN0 - MESSAGE CSECT FOR END SUBCOMMAND' 58600020
IKJEBEN0 CSECT                                                          58700020
         ENTRY IKJEBMSG                                                 58800020
IKJEBMSG DC    A(1)           NO. OF INSERTIONS TO BE MADE.             58900020
         DC    A(ENMSG531)    ADDRESS OF MESSAGE.                       59000020
ENMSG531 DC    AL2(ENMSGEND-ENMSG531) MESSAGE LENGTH.                   59100020
         DC    H'0'           CURRENT OFFSET FIELD.                     59200020
         DC    C' ENTER SAVE OR END-' PROMPT MESSAGE.                   59300020
ENMSGEND EQU   *                                                        59400020
         END                                                            59500020
