BEEX TITLE 'EDIT UTILITY DATA SET FINAL PROCESSING ROUTINE -IKJEBEEX'   00600020
IKJEBEEX CSECT                                                          01200020
*********************************************************************** 01800020
*                                                                     * 03600020
*STATUS -- VERSION NO. 01, OS/360 RELEASE 20                          * 04200020
*                                                                     * 04800020
*FUNCTION -- PERFORMS THE FINAL PROCESSING ON THE UTILITY DATA SET    * 05400020
*   BY PERFORMING THE FOLLOWING OPERATIONS -                          * 06000020
*       -RELEASE THE CORE FOR THE BUFFERS                             * 06600020
*       -CLOSES THE UTILITY DATA SET                                  * 07200020
*       -UNALLOCATES THE UTILITY DATA SET                             * 07800020
*       -DELETES THE ACCESS ROUTINE LOAD MODULE (IKJEBEAA)            * 08400020
*       -RELEASES THE WORKAREA CORE                                   * 09000020
*                                                                     * 09600020
*ENTRY POINTS -- AT IKJEBEEX VIA A LINK OR LOAD-CALL                  * 10200020
*                                                                     * 10800020
*INPUT -- REGISTER 1 CONTAINS THE ADDRESS OF THE EDIT COMMUNICATIONS  * 11400020
*           AREA, IKJEBECA.                                           * 12000020
*         REGISTER 0 CONTAINS THE ADDRESS OF THE UTILITY WORKAREA,    * 12600020
*           UTILWORK.                                                 * 13200020
*                                                                     * 13800020
*OUTPUT --    THE OPERATIONS DESCRIBED UNDER 'FUNCTION' ABOVE WILL    * 14400020
*   HAVE BEEN PERFORMED.                                              * 15000020
*                                                                     * 15600020
*EXTERNAL REFERENCES --                                               * 16200020
*       IKJDAIR              -UNALLOCATES THE DATA SET                * 16800020
*       MACROS USED                                                   * 17400020
*         FREEMAIN           -RELEASE BUFFER AND WORKAREA CORE        * 18000020
*         DELETE             -DELETES ACCESSING LOAD MODULE (IKJEBEAA)* 18600020
*         CLOSE              -CLOSES UTILITY DATA SET                 * 19200020
*                                                                     * 19800020
*EXITS,NORMAL -- RETURNS ON REGISTER 14, ALL REGISTERS INTACT.        * 20400020
*                                                                     * 21000020
*EXITS,ERROR --  NONE                                                 * 21600020
*                                                                     * 22200020
*TABLES/WORK AREAS -- DEPENDENT ON THE UTILITY WORKAREA FOR-          * 22800020
*       -ADDRESS OF BUFFERS TO RELEASE                                * 23400020
*       -DCB TO CLOSE                                                 * 24000020
*   DEPENDENT ON THE EDIT COMMUNICATIONS AREA (IKJEBECA) FOR-         * 24600020
*       -INVOKING IKJDAIR TO UNALLOCATE THE DATA SET                  * 25200020
*       -INVOKING IKJEBEMS FOR WRITING OUT MESSAGES                   * 25800020
*                                                                     * 26400020
*ATTRIBUTES --  REFERESHABLE,ENABLED,NON-PRIVILEGED                   * 27000020
*                                                                     * 27600020
*NOTES -- REGISTER CONVENTIONS AS DESCRIBED BELOW.                    * 28500020
*                                                                     * 29400020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 29600020
*                                                                     * 29800020
*********************************************************************** 30000020
         SPACE 2                                                        30600020
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS                              31200020
PARMREG0 EQU   0                       PARM POINTER                     31800020
PARMREG1 EQU   1                       PARM POINTER                     32400020
WORK2    EQU   2                       WORK REGISTER                    33000020
WORK3    EQU   3                       WORK REGISTER                    33600020
COMMREG  EQU   9                       COMMUNICATIONS AREA ADDRESSING   34200020
BASEREG  EQU   11                      BASE REGISTER                    34800020
DATAREG  EQU   12                      UTILITY WORK AREA ADDRESSING     35400020
SAVEREG  EQU   13                      SAVE AREA ADDRESSING             36000020
RETREG   EQU   14                      RETURN REGISTER                  36600020
RETCDREG EQU   15                      RETURN CODE                      37200020
         SPACE 3                                                        37800020
*   DEFINITIONS                                                         38400020
SPONE    EQU   1                       SUBPOOL NUMBER                   39000020
X0       EQU   0                       OFFSET OF ZERO                   39600020
X2       EQU   2                       OFFSET OF TWO                    39630020
X8       EQU   8                       OFFSET OF EIGHT                  39660020
X26      EQU   26                      USED IN CLEARING MESSAGE AREA    39690020
X28      EQU   28                      OFFSET OF TWENTY-EIGHT           39700020
X240     EQU   240                     USED TO ADDRESS TRANSLATE TABLE  39720020
ONE      EQU   1                       CONSTANT OF 1                    39750020
THREE    EQU   3                       CONSTANT OF 3                    39780020
FOUR     EQU   4                       CONSTANT OF 4                    39810020
FIVE     EQU   5                       CONSTANT OF 5                    39840020
SIX      EQU   6                       CONSTANT OF 8                    39870020
EIGHT    EQU   8                       CONSTANT OF 8                    39900020
MGCOREB  EQU   40                      OFFSET TO MESSAGE BLOCK          39930020
MGCOREBO EQU   MGCOREB+6               OFFSET TO 2ND LEVEL OFFSET       39960020
MGCOREBL EQU   MGCOREB+5               OFFSET TO LENGTH FIELD           39990020
MGCOREBM EQU   MGCOREB+8               OFFSET TO 2ND LEVEL TEXT         40020020
MGCORB2  EQU   MGCOREB+16              OFFSET TO NEXT MESSAGE BLOCK     40050020
MGCORB2O EQU   MGCORB2+6               OFFSET TO 2ND 2ND LEVEL OFFSET   40080020
MGCORB2L EQU   MGCORB2+5               OFFSET TO 2ND 2ND LEVEL LENGTH   40110020
MGCORB2M EQU   MGCORB2+8               OFFSET TO 2ND 2ND LEVEL TEXT     40140020
         SPACE 3                                                        40200020
*   MESSAGE REFERENCES                                                  40800020
         SPACE 2                                                        41200020
         IKJEBEMI (313,424)                                             41600020
         EJECT                                                          42000020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          42600020
         IKJEBESV  (14,12),T,*             SAVE THE REGISTERS           43200020
         SPACE                                                          43800020
         USING IKJEBECA,COMMREG                                         44400020
         LR    DATAREG,PARMREG0        UTILITY WORK AREA ADDRESS        45000020
         USING UTILWORK,DATAREG                                         45600020
         LA    WORK3,TEMPAREA          TEMPORARY WORKAREA FOR THIS      46200020
         USING EXWORK,WORK3              ROUTINE                        46800020
         XC    EXWORK(EXEND-EXWORK),EXWORK  CLEAR WORK AREA             47400020
         SPACE 2                                                        48000020
*   CLOSE THE DCB HERE                                                  51600020
         MVC   EXCLOSE(CLOSEEND-CLOSE),CLOSE  LIST FORM OF CLOSE MACRO  52200020
         LA    WORK2,UTILDCB           ADDRESS OF DCB                   52800020
         LA    PARMREG1,EXCLOSE        ADDRESS OF LIST FORM             53400020
         CLOSE ((WORK2)),MF=(E,(1))        CLOSE THE DCB                54000020
         EJECT                                                          54600020
*   CHECK IF EDIT END IS IN PROCESS                                     55600020
         TM    CAMAWKA+X28,MAENDPRC    IS END IN PROCESS                56600020
         BZ    EXDAIR                  NO,GO INVOKE DAIR                57600020
*                                      YES,LET TMP DISPOSE OF UTIL DS   58600020
         SPACE 2                                                        61800020
*   DELETE THE ACCESSING ROUTINES HERE                                  62400020
EX1      EQU   *                                                        63000020
         DELETE EP=IKJEBEAA            DELETE THE ACCESS METHOD         63600020
         SPACE 2                                                        64200020
*   FREE THE WORKAREA AND BUFFER CORE                                   64800020
         LR    PARMREG1,DATAREG        WORKAREA ADDRESS                 65400020
         LA    PARMREG1,X0(PARMREG1)   INSURE HIGH ORDER BYTE CLEAR     66000020
         FREEMAIN R,LV=CORESIZE,A=(1),SP=SPONE                          66600020
         SPACE 2                                                        67200020
*   RETURN TO CALLING ROUTINE HERE                                      67800020
         IKJEBERT (14,12),T                                             68400020
         EJECT                                                          68500020
*   UNALLOCATE THE DATA SET HERE                                        68600020
EXDAIR   EQU   *                                                        68700020
         MVC   DAPB18(DAIRSIZE),DAIRCODE DAIR LIST TO WORKAREA          68720020
         MVC   DA18DDN(L'DCBDDNAM),DCBDDNAM DDNAME TO LIST              68740020
         LA    PARMREG1,DAPB18         DAIR PARM LIST ADDRESS           68760020
         ST    PARMREG1,CATMPLST+DAPLDAPB-DAPL TO PARM LIST             68780020
         L     PARMREG1,CAPTTMP        ADDRESS OF CPPL LIST             68800020
         USING CPPL,PARMREG1                                            68820020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'CPPLPSCB),CPPLPSCB PSCB ADDRESS 68840020
         DROP  PARMREG1                                                 68860020
         LA    PARMREG1,CATMPLST       TOTAL PARM LIST ADDRESS          68880020
         LINK  EP=IKJDAIR              UNALLOCATE THE DATA SET          68900020
         LTR   RETCDREG,RETCDREG       WAS UNALLOCATION SUCCESSFUL      68920020
         BZ    EX1                     YES, GO DELETE ACCESSING RTNS    68940020
*                                      NO, ISSUE MESSAGE                68960020
         SPACE 2                                                        68980020
*********************************************************************** 69010020
*   SYSTEM ERROR IN ATTEMPTING TO UNALLOCATE DATA SET                   69020020
EXSYSER  EQU   *                                                        69030020
         CH    RETCDREG,RC12           WAS THERE A DYNAMIC ALLOC ERROR  69040020
         BE    EXUNLCER                YES, GO GIVE MESSAGE             69050020
         XC    CASRWKA+MGCOREB(X26),CASRWKA+MGCOREB  CLEAR MESSAGE AREA 69060020
         MVC   CASRWKA(MLSYSERE-MLSYSER),MLSYSER  MOVE MESSAGE BLOCK    69070020
         LA    WORK2,CASRWKA+MGCOREB   GET ADDRESS OF 2ND LEVEL         69080020
         ST    WORK2,CASRWKA+EIGHT     INITIALIZE AREA                  69090020
         LA    WORK2,CASRWKA+MGCORB2   GET ADDRESS OF 2ND 2ND LEVEL     69100020
         ST    WORK2,CASRWKA+MGCOREB   POINT TO NEXT INSERTION          69110020
         MVI   CASRWKA+MGCOREBL,L'IKJDAIR+FOUR  SET LENGTH FIELD        69120020
         LA    WORK2,M3131IN1          GET RELATIVE OFFSET              69130020
         STH   WORK2,CASRWKA+MGCOREBO  STORE IN MESSAGE BLOCK           69140020
         MVC   CASRWKA+MGCOREBM(L'IKJDAIR),IKJDAIR  TEXT INTO BLOCK     69150020
         LA    WORK2,M3131IN2          GET 2ND RELATIVE OFFSET          69160020
         STH   WORK2,CASRWKA+MGCORB2O  STORE IN MESSAGE BLOCK           69170020
         SRL   RETCDREG,ONE            SET UP FOR INSERTION PICK UP     69180020
         LH    WORK2,CODETAB-X2(RETCDREG) GET CODE IN REG               69190020
         STH   WORK2,CASRWKA+MGCORB2M  STORE 2ND INSERTION              69200020
         MVI   CASRWKA+MGCORB2L,SIX    MOVE LENGTH INTO BLOCK           69210020
         SPACE 2                                                        69220020
MSG      EQU   *                                                        69230020
         IKJEBEML ,,,,MF=(E,CASRWKA)   PUT OUT MESSAGE                  69240020
         B     EX1                     GO DELETE ACCESSING ROUTINES     69250020
         SPACE 2                                                        69260020
*********************************************************************** 69270020
*   NOT ABLE TO UNALLOCATE DATA SET                                     69280020
EXUNLCER EQU   *                                                        69290020
         MVC   CASRWKA(MLUNALCE-MLUNALC),MLUNALC  MOVE 1ST LEVEL        69300020
         XC    CASRWKA+MGCOREB(X8),CASRWKA+MGCOREB  CLEAR MESSAGE AREA  69310020
         LA    WORK2,CASRWKA+MGCOREB   ADDRESS OF SECOND LEVEL AREA     69320020
         ST    WORK2,CASRWKA+EIGHT     POINT TO 2ND LEVEL BLOCK         69330020
         LA    WORK2,M4241IN1          GET RELATIVE POINTER             69340020
         STH   WORK2,CASRWKA+MGCOREBO  PUT IN 2ND LEVEL BLOCK           69350020
         MVI   CASRWKA+MGCOREBL,EIGHT  SET UP LENGTH                    69360020
         SPACE                                                          69370020
*        CONVERT RETURN CODE TO HEX CHARACTERS USING TRANSLATE TABLE.   69380020
         UNPK  CASRWKA+MGCOREBM(FIVE),EXWORK+DA18DARC-DAPB18(THREE)     69390020
         TR    CASRWKA+MGCOREBM(FOUR),TRANTAB-X240                      69400020
         B     MSG                     GO PUT OUT MESSAGE               69410020
         EJECT                                                          69420020
         DROP  BASEREG,COMMREG,DATAREG,WORK3                            69600020
         SPACE 2                                                        70200020
*   IKJEBEEX CONSTANT AREA                                              70300020
RC12     DC    H'12'                   DAIR RETURN CODE 12 - DYNAMIC    70400020
*                                      ALLOCATION ERROR                 70500020
CODETAB  DS    0H                                                       70600020
         DC    C'04081216202428'       MSG INSERTION TABLE              70700020
TRANTAB  DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  70800020
IKJDAIR  DC    C'DAIR'                 MESSAGE INSERTION                70900020
         SPACE 2                                                        71000020
*   CLOSE - LIST FORM                                                   71100020
CLOSE    CLOSE  0,MF=L                                                  71400020
CLOSEEND EQU   *                                                        72000020
         SPACE                                                          72600020
*********************************************************************** 72650020
*   SYSTEM ERROR MESSAGE, LIST FORM                                     72700020
MLSYSER  IKJEBEML M313,M3131,,,MF=L                                     72750020
MLSYSERE EQU   *                                                        72800020
         SPACE 2                                                        72850020
*********************************************************************** 72900020
*   MESSAGE - DATA SET NOT UNALLOCATED - LIST FORM                      72950020
MLUNALC  IKJEBEML M424,M4241,,,MF=L                                     73000020
MLUNALCE EQU   *                                                        73050020
         SPACE 2                                                        73100020
*   PARAMETER LIST FOR DAIR --- UTILITY DATA SET UNALLOCATION           73200020
         DS    0D                                                       73800020
DAIRCODE DC    H'24'                   ENTRY CODE                       74400020
FLAGS    DC    H'0'                    RETURN SETTINGS                  75000020
DARC     DC    H'0'                    ERROR CODE---DYNAMIC ALLOCATION  75600020
CTRC     DC    H'0'                    ERROR CODE---CATALOG             76200020
DSNAMPTR DC    F'0'                    POINTER TO DSNAME                76800020
DDNAME   DC    8C' '                   DDNAME                           77400020
MEMBER   DC    8C' '                   MEMBER NAME                      78000020
SYSCLS   DC    H'0'                    SYSOUT CLASS                     78600020
DISP2    DC    X'04'                   DISPOSITION---DELETE             79200020
CONTROL  DC    X'00'                   DAIR CONTROL                     79800020
DAIRSIZE EQU   *-DAIRCODE              LENGTH OF PARM LIST              80400020
         SPACE 2                                                        81000020
*   DESCRIPTION OF USE OF THE SUBROUTINE WORK AREA IN 'TEMPAREA'        81600020
*********************************************************************** 82200020
         IKJDAP18                                                       82800020
EXWORK   EQU   DAPB18                                                   83400020
EXCLOSE  CLOSE 0,MF=L                  LIST FORM OF CLOSE               84000020
EXEND    EQU   *                       END OF WORK AREA                 84600020
*********************************************************************** 85200020
         IKJCPPL                                                        85800020
*********************************************************************** 86400020
          IKJDAPL                                                       87000020
*********************************************************************** 87600020
         EJECT                                                          88200020
         IKJEBEUW                                                       88800020
         EJECT                                                          89400020
         IKJEBECA                                                       90000020
*********************************************************************** 90600020
         END                                                            91200020
