BEFC     TITLE 'EDIT SERVICE ROUTINE-FINAL COPY-IKJEBEFC'               00200020
*********************************************************************** 00400020
*                                                                     * 00600020
*                                                                     * 01000020
*STATUS-  VERSION NO. 01. OS/360 RELEASE NO. 20                       * 01200020
*                                                                     * 01400020
*FUNCTION/OPERATION-  IKJEBEFC IS AN EDIT SERVICE ROUTINE WHICH IS    * 01600020
*   USED TO COPY THE UTILITY DATA SET BEING EDITED INTO A QSAM DATA   * 01800020
*   SET. THIS ROUTINE WILL READ THE RECORDS FROM THE UTILITY DATA SET,* 02000020
*   CHANGE THE RECORD FORMAT FROM WHAT EXISTS ON THE UTILITY DATA SET * 02200020
*   TO A FORMAT REQUIRED FOR THE QSAM DATA SET, AND WRITE THE RECORDS * 02400020
*   INTO THE QSAM DATA SET.                                           * 02600020
*                                                                     * 02800020
*ENTRY POINTS- IKJEBEFC IS THE MAIN AND ONLY ENTRY POINT.             * 03000020
*                                                                     * 03200020
*INPUT-  REGISTER 1 CONTAINS A POINTER TO EDIT'S COMMUNICATION AREA.  * 03400020
*                                                                     * 03800020
*OUTPUT-  A FORMATTED QSAM DATA SET IS WRITTEN.                       * 04200020
*         REGISTERS AS DESCRIBED UNDER EXITS BELOW.                   * 04600020
*                                                                     * 05200020
*EXTERNAL REFERENCES-                                                 * 05400020
*        IKJEBEUT        -PERFORMS READING OF RECORDS FROM UTILITY    * 05600020
*                         DATA SET                                    * 05800020
*        IKJEBEEX        -UTILITY DATA SET ACCESS TERMINATION         * 06000020
*        MACROS USED -                                                * 06200020
*          IKJEBESV      -SAVE CALLER'S REGISTERS AND ESTABLISH       * 06400020
*                         ADDRESSABILITY                              * 06600020
*          IKJEBERT      -RELOAD CALLER'S REGISTERS AND RETURN CONTROL* 06800020
*                         TO CALLER                                   * 07000020
*          IKJEBESH      -LINKAGE TO EDIT MODULES                     * 07200020
*          IKJEBEML      -STANDARD MESSAGE TO TERMINAL USER           * 07400020
*          IKJEBECA      -LAYOUT AND DESCRIPTION OF COMMUNICATION AREA* 07600020
*          FREEPOOL      -RELEASE BUFFER ACQUIRED BY OPEN MACRO TO    * 07800020
*                        -SYSTEM                                      * 08000020
*          OPEN          -OPEN QSAM DATA SET                          * 08200020
*          CLOSE         -CLOSE QSAM DATA SET                         * 08400020
*          DCBD          -LAYOUT OF DCB FOR QSAM DATA SET             * 08600020
*                                                                     * 08800020
*EXITS,NORMAL-  A RETURN CODE IN REGISTER 15 AS FOLLOWS-              * 08900020
*                                                                     * 09000020
*           RETURN CODE = 0  THE UTILITY DATA SET WAS COPIED          * 09100020
*             SUCCESSFULLY.                                           * 09200020
*                                                                     * 09300020
*           RETURN CODE = 4  THE UTILITY DATA SET CONTAINS NO LOGICAL * 09400020
*             RECORDS                                                 * 09500020
*                                                                     * 09600020
*EXITS,ERROR-   A RETURN CODE IN REGISTER 15 AS FOLLOWS-              * 09700020
*                                                                     * 09800020
*           RETURN CODE = 8  I/O ERROR ON QSAM DATA SET               * 09900020
*                                                                     * 10000020
*           RETURN CODE = 12  I/O ERROR ON UTILITY DATA SET           * 10100020
*                                                                     * 10200020
*TABLES/WORK AREAS - THE EDIT SERVICE ROUTINE WORK AREA OF FIFTY      * 10300020
*   FULLWORDS AND A BUFFER POOL OF 98 FULLWORDS IN THE COMMUNICATION  * 10600020
*   AREA ARE USED                                                     * 10800020
*                                                                     * 11000020
*ATTRIBUTES - REFRESHABLE, ENABLED, NON-PRIVILEGED                    * 11200020
*                                                                     * 11400020
*NOTES - THIS ROUTINE IS CHARACTER CODE INDEPENDENT                   * 11460020
*                                                                     * 11520020
*********************************************************************** 11600020
IKJEBEFC CSECT                                                          11800020
*                                                                       11850000
*A259000-265000,750500-751500                                    A45002 11900000
*D260000-266000                                                  A45002 11950000
*C413500,415000                                                   M5134 11960021
*D411000-412000                                                   M5134 11970021
         SPACE 2                                                        12000020
*********************************************************************** 12200020
*    EQUATES OF SYMBOLIC REGISTERS                                      12400020
*********************************************************************** 12600020
PARMREG0 EQU   0                       PARAMETER POINTER                12800020
PARMREG1 EQU   1                       PARAMETER POINTER                13000020
TESTREG  EQU   2                       WORK REGISTER                    13200020
BINREG   EQU   3                       WORK REGISTER                    13400020
ADDREG   EQU   4                       WORK REGISTER                    13600020
DCBREG   EQU   5                       WORK REGISTER                    13800020
WORKREG  EQU   6                       WORK REGISTER                    14000020
UTREG    EQU   8                       PARAMETERS FOR IKJEBEUT POINTER  14200020
COMMREG  EQU   9                       COMMUNICATION AREA ADDRESSING    14400020
TEMPREG  EQU   10                      WORK REGISTER                    14600020
BASEREG  EQU   11                      BASE REGISTER                    14800020
DATAREG  EQU   12                      WORK REGISTER                    15000020
SAVEREG  EQU   13                      SAVE AREA POINTER                15200020
RETREG   EQU   14                      RETURN REGISTER                  15400020
RETCDREG EQU   15                      RETURN CODE                      15600020
         SPACE 2                                                        15800020
*********************************************************************** 16000020
*    EQUATES OF SYMBOLIC CONSTANTS                                      16200020
*********************************************************************** 16400020
FC0      EQU   0                       CONSTANT OF 0                    16600020
FC1      EQU   1                       CONSTANT OF 1                    16800020
FC2      EQU   2                       CONSTANT OF 2                    17000020
FC3      EQU   3                       CONSTANT OD 3                    17200020
FC4      EQU   4                       CONSTANT OF 4                    17400020
FC6      EQU   6                       CONSTANT OF 6                    17600020
FC8      EQU   8                       CONSTANT OF 8                    17800020
FC10     EQU   10                      CONSTANT OF 10                   18000020
FC12     EQU   12                      CONSTANT OF 12                   18200020
FC16     EQU   16                      CONSTANT OF 16                   18400020
FC20     EQU   20                      CONSTANT OF 20                   18600020
FC29     EQU   29                      CONSTANT OF 29                   18800020
FC50     EQU   50                      CONSTANT OF 50                   19000020
FC78     EQU   78                      CONSTANT OF 78                   19200020
DCBOPEN  EQU   X'10'                   OPEN TEST FLAG                   19400020
FIXED    EQU   X'80'                   FIXED RECORD FORMAT TEST FLAG    19600020
VAR      EQU   X'40'                   VARIABLE RECORD FORMAT TEST FLAG 19800020
FIXEDBL  EQU   X'90'                   FIXED BLOCKED REC. FORMAT BIT    20000020
VARBL    EQU   X'50'                   VARIABLE BLOCKED REC. FORMAT BIT 20200020
RECFSBIT EQU   B'00001000'             STANDARD BLOCKS OR SPANNED       20260020
*                                      RECORDS BIT IN DCBRECFM.         20320020
END      EQU   X'80'                   END OF PARAMETER LIST CODE       20400020
FIRST    EQU   X'04'                   READ 1ST RECORD CODE             20600020
AFTER    EQU   X'02'                   READ NEXT RECORD FLAG            20800020
EXIST    EQU   X'C0'                   RECORD FORMAT TEST FLAG          21000020
ALL      EQU   X'FF'                   USED TO SET SWITCHES             21200020
MESS1    EQU   X'80'                   MESSAGE1 TEST SWITCH             21400020
         SPACE 2                                                        21600020
*********************************************************************** 21800020
*    MESSAGE REFERENCES                                                 22000020
*********************************************************************** 22200020
         IKJEBEMI (309)                                                 22400020
         EJECT                                                          22600020
*********************************************************************** 22800020
*    STANDARD ENTRY LINKAGE AND ESTABLISHMENT OF ADDRESSABILITY BOTH    23000020
*    IN THIS ROUTINE AND IN THE COMMUNICATION AREA                      23200020
*********************************************************************** 23400020
         IKJEBESV (14,12),T,*          SAVE CALLER'S REGISTERS AND      23600020
*                                      ESTABLISH ADDRESSABILITY         23800020
         LR    COMMREG,PARMREG1        LET COMMREG PT. TO COMMUNICATION 24000020
*                                      AREA                             24200020
         USING IKJEBECA,COMMREG        ADDRESSABILITY IN COMMUNICATION  24400020
*                                      AREA                             24600020
         MVI   SW,FC0                  TURN SWITCHES OFF                24700020
         SPACE 2                                                        24800020
*********************************************************************** 25000020
*    MOVE DCB WHICH HAS BEEN INITIALIZED WITH DSORG, MACRF, A SYNAD     25200020
*    EXIT ADDRESS AND AN OPEN EXIT ADDRESS FOR QSAM DATA SET TO         25400020
*    THE COMMUNICATION AREA AND ESTABLISH ITS ADDRESSABILITY HERE       25600020
*********************************************************************** 25800020
         TM    CACFLAG4,CAABEND     CHECK IF ABEND IN PROGRESS   A45002 26000000
         BO    FCAEDCB              IF ABEND, DON'T DESTROY THE  A45002 26100000
*                                   EXISTING DCB                 A45002 26200000
         LA    DCBREG,COFCDCB       NORMAL DCB ADDRESS           A45002 26300000
         B     MOVEDCB              BRANCH TO MOVE DCB           A45002 26400000
FCAEDCB  LA    DCBREG,CAAEDCB       ABEND DCB ADDRESS            A45002 26500000
MOVEDCB  MVC   FC0(FCDCBL,DCBREG),FCDCB MOVE DCB TO AREA         A45002 26600000
         USING IHADCB,DCBREG           ADDRESSABILITY IN DCB DSECT      26800020
         SPACE 2                                                        27000020
*********************************************************************** 27200020
*    DETERMINE WHETHER FINAL COPY IS TO BE PERFORMED ON EDIT OR SAVE    27400020
*    DATA SET                                                           27600020
*********************************************************************** 27800020
         TM    CAEDFLAG,CAEDFNCP       TEST WHETHER FINAL COPY IS TO    28000020
*                                      BE PERFORMED ON EDIT DATA SET    28200020
         BO    EDITDATA                IF YES,BRANCH TO MOVE EDIT DATA  28300020
*                                      SET DDNAME TO DCB              * 28400020
         SPACE 2                                                        28600020
*********************************************************************** 28800020
*    INITIALIZE DCB WITH THE APPROPRIATE DDNAME FROM COMMUNICATION      29000020
*    AREA HERE                                                          29200020
*********************************************************************** 29400020
         MVC   DCBDDNAM(FC8),CASADDN   MOVE SAVE DATA SET DDNAME FROM   29600020
*                                      COMM. AREA TO DCB                29800020
         B     NEXT                    BRANCH AROUND MOVE FOR EDIT DATA 29900020
*                                      SET DDNAME                     * 30000020
EDITDATA MVC   DCBDDNAM(FC8),CAEDDDN   MOVE EDIT DATA SET DDNAME FROM   30200020
*                                      COMM. AREA TO DCB                30400020
         SPACE 2                                                        30600020
*********************************************************************** 30800020
*    EDIT OR SAVE DATA IS OPENED AND TESTED IF OPEN IS SUCCESSFUL       31000020
*********************************************************************** 31200020
NEXT     MVC   COOPENPL(FCOPENL),FCOPEN                                 31400020
         OPEN  ((DCBREG),(OUTPUT)),MF=(E,COOPENPL)  EXECUTE FORM OF     31600020
*                                      OPEN MACRO                       31800020
         TM    DCBOFLGS,DCBOPEN        CHECK IF DATA SET OPENED         32000020
         BNO   MESSAGE1                BRANCH ON NOT OPEN TO MESSAGE1   32200020
         SPACE 2                                                        32400020
*********************************************************************** 32600020
*    IKJEBEUT IS CALLED THROUGH IKJEBESH MACRO TO READ FIRST RECORD OF  32800020
*    UTILITY DATA SET                                                   33000020
*********************************************************************** 33200020
         MVC   COWORD1(FC4),CAPTCDCB   PUT ADDR OF CURRENT UTILITY DCB  33400020
*                                      IN THE 3 LOW ORDER BYTES OF      33600020
*                                      1ST PARAM WORD                   33800020
         MVI   COWORD1,FIRST           PUT X'04' IN HIGH ORDER BYTE OF  34000020
*                                      1ST PARAM WORD                   34200020
         XC    COWORD2(FC4),COWORD2       2ND PARAM WORD DOES NOT       34400020
*                                         CONTAIN ANY POINTER           34600020
         LA    TESTREG,PUTAD                                            34800020
         ST    TESTREG,COWORD3         PUT POINTER TO BUFFER POOL       35000020
*                                      WHERE THE RECORD IS TO BE PLACED 35200020
*                                      IN 3 LOW ORDER BYTES OF 3RD      35400020
*                                      PARAM WORD                       35600020
         MVI   COWORD3,END             PUT END OF PARAMETER LIST CODE   35800020
*                                      IN HIGH ORDER BYTE OF 3RD PARAM  36000020
*                                      WORD                             36200020
         LA    UTREG,COWORD1              LET UTREG PT. TO PARMLIST     36400020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(UTREG)),MF=(E,A) 36600020
         LTR   RETCDREG,RETCDREG       TEST RETURN CODE FROM IKJEBEUT   36800020
         BZ    CONT1                   BRANCH IF ZERO TO CONT1          37000020
         C     RETCDREG,FCDC4          TEST WHETHER R.C.=4              37200020
         BE    EMPTY                   BRANCH TO SET R.C.=4             37400020
IOERR    LA    TEMPREG,FC12            SET R.C.=12 IN TEMPREG           37600020
         SPACE 2                                                        37800020
*********************************************************************** 38000020
*    TERMINATION PROCESSING                                             38200020
*********************************************************************** 38400020
CLOSED   MVC   COOPENPL(FCCLOSEL),FCCLOSE                               38600020
         CLOSE ((DCBREG)),MF=(E,COOPENPL)  EXECUTE FORM OF CLOSE MACRO  38800020
         FREEPOOL IHADCB               RELEASE BUFFER ACQUIRED TO       39000020
*                                      SYSTEM                           39200020
EXIT     LR    RETCDREG,TEMPREG        PUT RET. CODE IN REG. 15         39400020
LINKAGE  IKJEBERT (14,12),T,RC=(15)    RELOAD CALLER'S REGISTERS        39600020
*                                      EXCEPT REG 15 AND RETURN CONTROL 39800020
*                                      TO CALLER                        40000020
         SPACE 2                                                        40200020
*********************************************************************** 40400020
*    OPEN EXIT ROUTINE                                                  40600020
*********************************************************************** 40800020
OPENEXIT EQU   *                                                        41000020
         TM    CASAFLAG,CASAFNCP+CASADSOR IS FINAL COPY TO BE DONE      41002020
*                                      INTO A SAVE PDS                  41002420
         BO    PDS                     YES, GO TO CONDITIONALLY SET     41002520
*                                      DCB ATTRIBUTES                   41002620
         TM    CAEDFLAG,CAEDFNCP+CAEDDSOR IF NO,IS FINAL TO BE DONE     41002820
*                                      INTO THE EDIT DATA SET,A PDS     41003220
         BO    PDS                     YES, GO TO CONDITIONALLY SET     41003720
*                                      DCB ATTRIBUTES                   41003820
*                                      NO, DATA SET IS SEQUENTIAL, AND  41003920
*                                      ATTRIBUTES MUST BE OVERLAYED     41007620
         BAL   WORKREG,MERGE           GO SET RECFM                     41008020
         BAL   WORKREG,DCBEX1          GO SET BLOCKSIZE                 41010020
         B     DCBEX2                  GO SET LRECL                     41012020
PDS      EQU   *                                                        41014020
         TM    DCBRECFM,FIXED+VAR      IS RECFM ALREADY SET TO          41015220
*                                      FIXED OR VARIABLE -              41018920
         BM    PDS10                   YES, GO CHECK BLKSIZE            41022620
         BAL   WORKREG,MERGE           NO, GO SET RECFM                 41026020
PDS10    EQU   *                                                        41026120
         OC    DCBBLKSI(FC2),DCBBLKSI  IS BLOCKSIZE ALREADY SET         41026220
         BNZ   PDS20                   YES, GO CHECK LRECL              41026320
         BAL   WORKREG,DCBEX1          NO, GO SET BLKSIZE               41028320
PDS20    EQU   *                                                        41028720
         OC    DCBLRECL(FC2),DCBLRECL  IS LRECL ALREADY SET             41029120
         BZ    DCBEX2                  NO, GO SET LRECL                 41029520
         BR    RETREG                  YES, RETURN TO OPEN              41029920
MERGE    EQU   *                                                        41084020
         TM    CACFLAG2,CARECFM        IS EDIT RECFM FIXED              41250020
         BO    FIX1                    YES, GO SET RECFM TO FB          41300020
         MVI   DCBRECFM,VARBL          NO, SET RECFM TO VB        M5134 41350021
         BR    WORKREG                 RETURN                           41400020
FIX1     EQU   *                                                        41450020
         MVI   DCBRECFM,FIXEDBL        SET RECFM TO FB            M5134 41500021
         BR    WORKREG                 RETURN                           41550020
DCBEX1   MVC   DCBBLKSI(FC2),CABLKS    MOVE BLKSIZE FROM COMM. AREA TO  44200020
*                                      DCB                              44400020
         BR    WORKREG                 RETURN TO CALLING POINT IN OPEN  44600020
*                                      EXIT                             44650020
DCBEX2   LH    TESTREG,CALRECL         GET EDIT LRECL                   44800020
         TM    CACFLAG2,CARECFM        IS EDIT RECFM FIXED              44860020
         BNO   VARY                    NO, GO SET LRECL                 44920020
         S     TESTREG,FCDC4           YES, SUBTRACT LENGTH OF CONTROL  45000020
*                                      WORD (LL00) FROM EDIT LRECL      45200020
VARY     EQU   *                                                        45250020
         STH   TESTREG,DCBLRECL        SET LRECL IN DCB                 45400020
         BR    RETREG                  RETURN TO OPEN                   45600020
         EJECT                                                          45650020
*********************************************************************** 47600020
*    MSG1- 'DATA SET (EDIT OR SAVE DSNAME) NOT USABLE+.  OPEN ERROR'    47800020
*    IS ISSUED HERE                                                     48000020
*********************************************************************** 48200020
MESSAGE1 OI    SW,MESS1                TURN MESSAGE1 SWITCH ON          48400020
M13      TM    CAEDFLAG,CAEDFNCP       TEST WHETHER IT IS EDIT DATA SET 48600020
*                                      OR SAVE DATA SET                 48800020
         BO    EDSN1                   EDIT DATA SET THEN GO TO EDSN1   49000020
         SR    TESTREG,TESTREG         CLEAR TESTREG                    49200020
         ST    TESTREG,CADSNPT2        SET CADSNPT2 TO ZERO             49400020
         LA    TESTREG,M309IN1                                          49600020
         STH   TESTREG,CADSNOF2        SET OFFSET VALUE IN CADSNOF2     49800020
         TM    SW,MESS1                TEST WHETHER MESSAGE1 IS ISSUED  50000020
         BO    COMBINE2                BRANCH IF ON TO COMBINE2         50200020
         B     COMBINE3                BRANCH TO COMBINE3 IF MESSAGE2   50400020
*                                      IS ISSUED                        50600020
EDSN1    SR    TESTREG,TESTREG         CLEAR TESTREG                    50800020
         ST    TESTREG,CADSNPTR        SET CADSNPTR TO ZERO             51000020
         LA    TESTREG,M309IN1                                          51200020
         STH   TESTREG,CADSNOFF        SET OFFSET VALUE IN CADSNOFF     51400020
         TM    SW,MESS1                TEST WHETHER MESSAGE1 IS ISSUED  51600020
         BO    COMBINE4                BRANCH TO COMBINE4 IF MESSAGE1   51800020
*                                      IS ISSUED                        52000020
         B     COMBINE3                BRANCH TO COMBINE3 IF MESSAGE3   52200020
*                                      IS ISSUED                        52400020
COMBINE2 MVC   B(FC12),INLIST1                                          52600020
ISSUE1   IKJEBEML M309,M3093,CADSNPT2,MF=(E,B)                          52800020
COMBINE6 NI    SW,ALL-MESS1            TURN MESSAGE1 SWITCH OFF         53000020
         LA    TEMPREG,FC8             SET RETURN CODE TO 8             53200020
         B     EXIT                    BRANCH TO RETURN TO CALLING      53400020
*                                      ROUTINE                          53600020
COMBINE4 MVC   B(FC12),INLIST1                                          53800020
ISSUE2   IKJEBEML M309,M3093,CADSNPTR,MF=(E,B)                          54000020
         B     COMBINE6                BRANCH UNCOND. TO COMBINE6       54200020
         SPACE 2                                                        54400020
*********************************************************************** 54600020
*    EACH LINE IS FORMATTED FOR OUTPUT TO THE QSAM DATA SET AND         54800020
*    WRITTEN OUT                                                        55000020
*********************************************************************** 55200020
CONT1    TM    DCBRECFM,FIXED          TEST WHETHER QSAM DATA SET IS    55400020
*                                      FIXED OR VARIABLE                55600020
         BO    FX                      BRANCH AROUND IF FIXED           55800020
VR       LA    ADDREG,PUTAD            FORMAT REC. FOR QSAM VAR.        56000020
*                                      DATA SET                         56200020
         A     ADDREG,FCDC4            PUT ADDR FOR PUT MACRO IN ADDREG 56400020
ACTION   MVC   COKEYA(FC4),PUTAD       PUT KEY OF LAST LINE REFERENCED  56600020
*                                      IN COKEYA                        56800020
WRITE    PUT   IHADCB,FC0(ADDREG)      PUT RECORD INTO QSAM DATA SET    57000020
         SPACE 2                                                        57200020
*********************************************************************** 57400020
*    CALL IKJEBEUT RTN. THROUGH IKJEBESH TO READ NEXT                   57600020
*    RECORD OF UTILITY DATA SET                                         57800020
*********************************************************************** 58000020
         MVI   COWORD1,AFTER           PUT X'02' IN HIGH ORDER BYTE     58200020
*                                      OF 1ST PARAM. WORD               58400020
         LA    TESTREG,COKEYA          PUT POINTER TO KEY OF LAST       58600020
*                                      LINE REFERENCED IN 2ND PARAM     58800020
*                                      WORD                             59000020
         ST    TESTREG,COWORD2                                          59200020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(UTREG)),MF=(E,A) 59400020
         LTR   RETCDREG,RETCDREG       CHECK R.C. FROM IKJEBEUT         59600020
         BZ    ACTION                  IF R.C.=0 GO TO ACTION           59800020
         C     RETCDREG,FCDC4                                           60000020
         BE    CLSE                    IF R.C.=4 GO TO CLSE             60200020
         B     IOERR                   IF R.C.=8 GO TO IOERR            60400020
CLSE     SR    TEMPREG,TEMPREG                                          60600020
         B     CLOSED                  GO TO TERMINATION PROCESSING     60800020
EMPTY    LA    TEMPREG,FC4             SET RET. CODE TO 4               61000020
         B     CLOSED                  GO TO TERMINATION PROCESSING     61200020
FX       LA    ADDREG,PUTAD            FORMAT RECORD FOR QSAM FIXED     61400020
*                                      DATA SET                         61600020
         A     ADDREG,FCDC8            PUT ADDR FOR PUT MACRO IN ADDREG 61800020
         B     ACTION                  GO TO SET KEY AND WRITE          62000020
         SPACE 2                                                        62200020
*********************************************************************** 62400020
*    SYNAD EXIT ROUTINE                                                 62600020
*********************************************************************** 62800020
FCSYNAD  SYNADAF ACSMETH=QSAM          DIAGNOSE I/O ERROR               63000020
         LA    TESTREG,M3092IN1                                         63200020
         STH   TESTREG,OFFSET2         PUT OFFSET VALUE IN OFFSET2      63400020
         B     M13                     BRANCH UNCOND. TO M13            63600020
COMBINE3 XC    COBUILD2(FC4),COBUILD2  PUT 0 IN PTR FIELD OF COBUILD2   63800020
         MVC   COBUILD2+FC4(FC2),FCDC82  PUT (LENGTH OF SYNADAF         64000020
*                                      MESSAGE) +4 IN 5TH & 6TH BYTES   64200020
*                                      COBUILD2                         64400020
         MVC   COBUILD2+FC6(FC2),OFFSET2  PUT OFFSET IN 7TH & 8TH BYTES 64600020
*                                      OF COBUILD2                      64800020
         MVC   COBUILD2+FC8(FC78),FC50(PARMREG1)  PUT SYNAD MESSAGE     65000020
*                                      IN COBUILD2                      65200020
         SPACE 2                                                        65400020
*********************************************************************** 65600020
*    SYNADRLS MACRO IS ISSUED TO RELEASE THE BUFFER TO THE SYSTEM       65800020
*********************************************************************** 66000020
         SYNADRLS                                                       66200020
         TM    CAEDFLAG,CAEDFNCP       TEST WHETHER FINAL COPY IS TO    66400020
*                                      BE PERFORMED ON EDIT DATA SET    66600020
*                                      OR SAVE DATA SET                 66800020
         BO    EDSN2                   EDIT DATA SET THEN GO TO EDSN2   67000020
*********************************************************************** 67200020
*    MSG2- 'DATA SET (SAVE DSNAME) NOT USABLE+.  I/O SYNAD ERROR        67400020
*    (SYNADINFO)' IS ISSUED HERE                                        67600020
*********************************************************************** 67800020
         MVC   B(FC12),INLIST3                                          68000020
ISSUE3   IKJEBEML M309,M3092,CADSNPT2,COBUILD2,MF=(E,B)                 68200020
COMBINE7 LA    TEMPREG,FC8             SET R.C.=8                       68400020
         B     CLOSED                  BRANCH TO CLOSE QSAM DATA SET    68600020
EDSN2    EQU   *                                                        68800020
         SPACE 2                                                        69000020
*********************************************************************** 69200020
*    MESSAGE3- 'DATA SET (EDIT DSNAME) NOT USABLE+.  I/O SYNAD ERROR    69400020
*    (SYNADINFO) ' IS ISSUED HERE                                       69600020
*********************************************************************** 69800020
         MVC   B(FC12),INLIST3                                          70000020
ISSUE4   IKJEBEML M309,M3092,CADSNPTR,COBUILD2,MF=(E,B)                 70200020
         B     COMBINE7                BRANCH UNCOND. TO COMBINE7       70400020
         SPACE 3                                                        70600020
*********************************************************************** 70800020
*    CONSTANT AREA FOR IKJEBEFC                                         71000020
*********************************************************************** 71200020
FCDC4    DC    F'4'                    FULWORD OF 4                     71400020
FCDC8    DC    F'8'                    FULLWORD OF 8                    71600020
FCEXLST  DC    X'85'                   HEX 85                           71800020
         DC    AL3(OPENEXIT)           ADDR OF OPEN EXIT ROUTINE        72000020
FCDC82   DC    H'82'                   HALFWORD OF 82                   72200020
INLIST1  IKJEBEML M309,M3091,,MF=L                                      72400020
INLIST3  IKJEBEML M309,M3092,,,MF=L                                     72600020
FCDCB    DCB   DSORG=PS,MACRF=PM,SYNAD=FCSYNAD,EXLST=FCEXLST            72800020
FCDCBEND EQU   *                                                        73000020
FCDCBL   EQU   FCDCBEND-FCDCB                                           73200020
FCOPEN   OPEN  (,(OUTPUT)),MF=L        LIST FORM OF OPEN MACRO          73400020
OPENEND  EQU   *                                                        73600020
FCOPENL  EQU   OPENEND-FCOPEN                                           73800020
FCCLOSE  CLOSE (,),MF=L                                                 74000020
CLOSEND  EQU   *                                                        74200020
FCCLOSEL EQU   CLOSEND-FCCLOSE                                          74400020
         DCBD  DSORG=PS,DEVD=DA                                         74600020
         SPACE 2                                                        74800020
         IKJEBECA                                                       75000020
CAAEDCB  EQU   CAATNWKA+140         UNUSED PART OF ATTENTION     A45002 75050000
*                                   WORK AREA USED FOR DCB AFTER A45002 75100000
*                                   AN ABEND                     A45002 75150000
         ORG   CASRWKA                 ORG FOR CA'S SERVICE WORK AREA   75200020
COOPENPL DS    F                       ******************************** 75400020
COWORD1  DS    F                       *     SERVICE                  * 75600020
COWORD2  DS    F                       *      ROUTINE                 * 75800020
COWORD3  DS    F                       *       WORK                   * 76000020
A        DS    5F                      *        AREA                  * 76200020
COKEYA   DS    F                       *         FOR ECA              * 76400020
COBUILD2 DS    22F                     ******************************** 76600020
OFFSET2  DS    H                       1ST INSERTION FOR 2ND 2ND-       76800020
*                                      LEVEL OF MSG2 AND MSG3           77000020
SW       DS    X                       MESSAGE1 SWITCH                  77200020
         ORG   CATEMPBF                *  ORG  FOR THE TEMPORARY      * 77400020
PUTAD    DS    66F                     *  BUFFER POOL                 * 77600020
COFCDCB  DS    24F                     *  AVAILABLE                   * 77800020
B        DS    10F                     *  FROM ECA                    * 78000020
         END                                                            78200020
