BEFI     TITLE 'TSO EDIT COMMAND  FIND SUBCOMMAND  IKJEBEFI'            00200020
IKJEBEFI CSECT                                                          00400020
         SPACE                                                          00410021
*A180600-181200,319250,518240-519562,612600-613200               A45363 00420021
*A718000,738600,748200-749000                                    A45363 00430021
*C666000                                                         A45363 00432021
*D163200-163500,334000-344000,350000-386000,518240-519800,672000 A45363 00440021
*D718000-720000,732000,772400-773200                             A45363 00442021
*A684800-687600                                                  A45110 00444021
*D346000-348500                                                  A45110 00446021
*C693000,703000                                                  S21004 00450021
*D556000-564000,568300-568900,571000-573700                      A42955 00500021
         SPACE                                                          00550021
*********************************************************************** 00600021
*                                                                     * 00800020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 01000020
*                                                                     * 01200020
*FUNCTION -- THIS EDIT SUBCOMMAND CONTROLS LOCATION OF A SPECIFIED    * 01400020
*   TEXT IN THE DATA SET. FOR TEXT DATA SETS THE SEARCH STRING        * 01600020
*   MAY OVERLAP TO THE NEXT RECORD.                                   * 01800020
*                                                                     * 02000020
*ENTRY POINT -- IKJEBEFI                                              * 02200020
*                                                                     * 02400020
*INPUT -- REGISTER 1 CONTAINS A POINTER TO THE EDIT COMMUNICATION     * 02600020
*   AREA,DEFINED IN THE IKJEBECA MACRO.                               * 02800020
*                                                                     * 03000020
*OUTPUT --REGISTER 15 CONTAINS A RETURN CODE                          * 03200020
*   00 - SUCCESSFUL COMPLETION                                        * 03400020
*   08 - INCOMPLETE PROCESSING, FLUSH STACK                           * 03450020
*   0C - I/O ERROR                                                    * 03600020
*                                                                     * 03800020
*EXTERNAL REFERENCES --                                               * 04000020
*        IKJEBEUT -- READS UTILITY DATA SET                           * 04100020
*        IKJEBESE -- FINDS STRING AT ANY OFFSET IN RECORD             * 04200020
*        IKJEBEMS -- MESSAGE SELECTION INTERFACE                      * 04300020
*        IKJPARS  -- PARSES SUBCOMMAND OPERANDS                       * 04400020
*                                                                     * 04500020
*   MACROS USED --                                                    * 04600020
*        IKJEBESV -- ENTRY LINKAGE                                    * 04700020
*        IKJEBERT -- EXIT LINKAGE                                     * 04800020
*        IKJEBESH -- CALLS SERVICE ROUTINES                           * 04900020
*        IKJEBECA -- DEFINES COMMUNICATION AREA DSECT                 * 05000020
*        IKJEBEMI -- EQU'S FOR MESSAGE SELECTION                      * 05100020
*        IKJPPL   -- DEFINES DSECT FOR IKJPARS PARAMETERS             * 05200020
*                                                                     * 06400020
*EXITS, NORMAL -- RETURN TO CALLER, WITH RETURN CODE.                 * 06600020
*                                                                     * 06800020
*EXITS, ERROR -- NONE.                                                * 07000020
*                                                                     * 07200020
*TABLES/WORK AREAS -- THE CASCWKA FIELD OF THE EDIT COMMUNICATION     * 07400020
*   AREA IS USED FOR WORK AREAS.                                      * 07600020
*   THE CAFINDIS BIT OF THE EDIT COMMAREA IS TURNED ON UPON EXIT      * 07630020
*   THE CAFIBFR AREA OF THE EDIT COMMAREA WILL CONTAIN THE            * 07660020
*   TOTAL LENGTH OF THE FIND STRING PLUS 4 IN THE FIRST 2 BYTES       * 07690020
*   FOLLOWED BY THE SEARCH OFFSET, OR ZERO IF NONE, FOLLOWED BY THE   * 07720020
*   SEARCH STRING.                                                    * 07750020
*                                                                     * 07800020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED.                  * 08000020
*                                                                     * 08060020
*NOTES -- THERE IS CHARACTER-CODE INDEPENDENCE                        * 08120020
*********************************************************************** 08200020
         EJECT                                                          08700020
*  REGISTER AND SPECIAL EQUATES                                         09000020
PARMREG0 EQU   0                   PARAMETER REGISTER                   09400020
PARMREG1 EQU   1                   PARAMETER REGISTER                   09600020
WRA      EQU   2                   GENERAL REGISTER                     09800020
WRB      EQU   3                   GENERAL REGISTER                     10000020
WRC      EQU   4                   GENERAL REGISTER                     10200020
WRD      EQU   5                   GENERAL REGISTER                     10400020
WRE      EQU   6                   GENERAL REGISTER                     10600020
WRF      EQU   7                   GENERAL REGISTER                     10800020
WRG      EQU   8                   GENERAL REGISTER                     11000020
COMMREG  EQU   9                   BASE REG FOR COMMAREA DSECT          11200020
BASEREG  EQU   11                  BASE REG FOR PROGRAM CSECT           11400020
DATAREG  EQU   12                  RESERVED REGISTER                    11600020
SAVEREG  EQU   13                  SAVE AREA POINTER                    11800020
RETREG   EQU   14                  RETURN ADDR REG                      12000020
RETCDREG EQU   15                  RETURN CODE REG                      12200020
DELIMOP  EQU   X'80'               DELIM STRING OPERAND                 12400020
WORKREGA EQU   2                   GENERAL REGISTER                     12600020
PARSREG  EQU   10                  BASE REG FOR PARSE DSECT             12800020
CUREAD   EQU   X'00'               OPERAND FOR CURRENT READ             13000020
FIRSTRD  EQU   X'04'               OPERAND FOR FIRST READ               13200020
NEXTRD   EQU   X'02'               OPERAND FOR NEXT READ                13400020
EOPARM   EQU   X'80'               OPERAND FOR END OF PARM LIST         13600020
L0       EQU   0                   LENGTH                               13800020
L4       EQU   4                   LENGTH                               14000020
L5       EQU   5                   LENGTH                               14200020
L12      EQU   12                  LENGTH                               14400020
RET4     EQU   4                   RETURN CODE FOR EOD                  14600020
RET12    EQU   12                  RETURN CODE FOR I/O ERROR            14800020
L20      EQU   20                  LENGTH                               15060020
L255     EQU   255                 LENGTH                               15120020
L6       EQU   6                   LENGTH                               15200020
L2       EQU   2                   LENGTH                               15400020
L3       EQU   3                   LENGTH                               15600020
L1       EQU   1                   LENGTH                               15800020
OFF1     EQU   1                   OFFSET                               16000020
RET8     EQU   8                   RETURN CODE FOR STRING NOT FOUND     16100020
*                                  AND FLUSH STACK                      16150020
L8       EQU   8                   LENGTH                               16250020
L7       EQU   7                   LENGTH                               16300020
         IKJEBEMI  (0,312,313,501,506)                                  16450020
         EJECT                                                          16470020
*  ENTRY LINKAGE                                                        16490020
         IKJEBESV (14,12),,*                                            16510020
         USING IKJEBECA,COMMREG                                         16530020
         EJECT                                                          16550020
         SPACE                                                          16600020
*  TEST FOR OPERANDS                                                    16800020
         TM    CAPTIBFR,CAOPERND   ANY OPERANDS                         17000020
         BZ    NOOPS               IF NOT, BRANCH                       17200020
         LA    PARMREG1,CATMPLST   PREPARE PARSE PARMLIST               17400020
         USING PPL,PARMREG1                                             17600020
         L     WORKREGA,PRSADA     VCON FOR PARSE PCL                   17800020
PARSENT  ST    WORKREGA,PPLPCL     ADDR OF PCL                          18000020
         SR    WORKREGA,WORKREGA   INITIALIZE COUNT FIELD IN     A45363 18060021
         STH   WORKREGA,CAFIBFR+L2   FIND BUFFER TO ZERO         A45363 18120021
         LA    WORKREGA,CAPTPRSD   PTR TO PDL WILL GO IN                18200020
         ST    WORKREGA,PPLANS     ANSWER PLACE ADDR RCV                18400020
         L     WORKREGA,CAPTIBFR   PTR TO COMMAND BUFFER                18600020
         ST    WRA,PPLCBUF         ADDR OF SUBCOMMAND                   18800020
         ST    COMMREG,PPLUWA      PTR TO CAMMAREA IN USER WKAREA       19000020
         DROP  PARMREG1                                                 19200020
         LINK  EP=IKJPARS                                               19400020
         B     RETCHECK(RETCDREG)   CHECK PARSE RETURN CODE             19500020
         SPACE                                                          19600020
*  CHECK PARSE RETURN CODE                                              19700020
RETCHECK EQU   *                                                        19800020
         B     ASTRTST             RC 0 CONTINUE                        19900020
         B     OUT8                RC 4 CANT PROMPT, EXIT               20000020
         B     OUT                 RC 8 ATTN ISSUED, EXIT               20100020
         B     CMDERR              RC 12 CMD SYS ERR MSG                20200020
         B     NOSPAC              RC 16 NO CORE AVAIL MSG              20300020
         EJECT                                                          20330020
*  NO OPERANDS ON SUBCOMMAND                                            20360020
         SPACE                                                          20400020
NOOPS    TM    CACFLAG4,CAFINDIS   WAS FIND PREVIOUSLY CALLED           21000020
         BNZ   NNFIND1             YES, GO READ RECORD                  21200021
*  SET UP 'PROMPT' PARSE PCL                                            21400020
         LA    PARMREG1,CATMPLST   ADDR OF TMP PARMLIST                 21600020
         L     WRA,PRSADB          ADDR OF PCL FOR PROMPT               21800020
         B     PARSENT             GO TO ENTER PARSE                    22000020
         EJECT                                                          22100020
         SPACE                                                          22200020
*  CHECK FOR *=0                                                        22400020
ASTRTST  L     WRA,CACURNUM        GET CURRENT LINE NUMBER              22600020
         LTR   WRA,WRA             IS IT ZERO                           22800020
         BNZ   READCUR             IF NOT, BRANCH                       23000020
         SPACE                                                          23060020
*  READ FIRST RECORD                                                    23120020
         L     WRA,CAPTCDCB        ADDR OF CURRENT DCB                  23200020
         ST    WRA,BEUTABA         STORE IN PARM LIST                   23400020
         MVI   BEUTABA,FIRSTRD     CODE FOR FIRST READ                  23600020
         LA    WRA,BEUTABA         ADDR OF PARM LIST                    23800020
         SR    WRB,WRB             ZERO REG                             24000020
         ST    WRB,BEUTABB         ZERO UT PARM FOR RCD KEY             24200020
         LA    WRB,CABFRPL         ADDR OF BUFFERPOOL                   24400020
         ST    WRB,BEUTABC         PTR FOR RCD READ MOVE MODE           24600020
         OI    BEUTABC,EOPARM      END OF PARMLIST INDICATOR            24800020
         IKJEBESH   (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),        X25000020
               MF=(E,SHAREA)                                            25200020
         LTR   RETCDREG,RETCDREG   TEST RETURN CODE                     25400020
         BZ    LESTRNG             IF ZERO, BRANCH                      25600020
TESTAS   LA    WRA,RET4               CODE FOR EOD                      25800020
         CR    WRA,RETCDREG        COMPARE WITH RC                      26000020
         BNE   IOER                BRANCH IF IO ERROR OCCURRED          26200020
         MVC   AREAM(LEND-LBEG),LBEG  MOVE LFORM OF ML MACRO            26400020
LABEL    IKJEBEML   M501,,,,MF=(E,AREAM)   WRITE EMPTY DS.MSG           26600020
         B     OUT                 AND  EXIT                            26800020
IOER     LA    RETCDREG,RET12      SET IO ERROR RETCODE                 27000020
         B     OUTA                 AND EXIT                            27200020
         EJECT                                                          27260020
*  READ CURRENT RECORD                                                  27320020
READCUR  L     WRA,CAPTCDCB        ADDR OF CURRENT DCB                  27400020
         ST    WRA,BEUTABA         STORE IN PARM LIST                   27600020
         LA    WRA,CABFRPL         ADDR OF BUFFERPOOL                   27800020
         ST    WRA,BEUTABC         UT PTR TO STGE FOR RCD READ          28000020
         MVI   BEUTABA,CUREAD      CODE FOR CURRENT READ                28200020
         LA    WRB,CACURNUM        CURRENT LINE NUMBER                  28400020
         LA    WRA,BEUTABA         ADDR OF PARM LIST                    28600020
         ST    WRB,BEUTABB         UT PTR TO KEY TO READ ON             28800020
         OI    BEUTABC,EOPARM      END OF PARMLIST INDICATOR            29000020
         IKJEBESH   (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),        X29200020
               MF=(E,SHAREA)                                            29400020
         LTR   RETCDREG,RETCDREG   TEST RC                              29600020
         BZ    LESTRNG             IF SUCCESSFUL GO TO LINEDIT STRING   29800020
TESTIO   LA    WRA,RET4            RETCODE FOR EOD                      30000020
         CR    WRA,RETCDREG        COMPARE                              30200020
         BE    NOTFOUND            IF EOD, BRANCH                       30400020
         B     IOER                ELSE, I/O ERROR OCCURRED, BRANCH     30600020
         EJECT                                                          30660020
*  EXAMINE PARSE PDL                                                    30720020
LESTRNG  L     PARSREG,CAPTPRSD    ADDRESS OF PARSE PDL                 30800020
         USING IKJPARMD,PARSREG    ADDRESSABILITY FOR PARSE DSECT       31000020
         SR    WRA,WRA                                                  31100020
         TM    CACFLAG1,CANONUM    IS DS NUMBERED                       31200020
         BNZ   NUMORNOT            IF NOT DONT CONSIDER SEQ FIELD       31300020
         IC    WRA,CALENGTH        SEQ FIELD LENGTH                     31500020
NUMORNOT LA    WRA,L4(WRA)         CONTROL WORD LENGTH                  31600020
         LH    WRB,CALRECL         TOTAL LENTH OF CW,SEQ,DATA           31700020
         SR    WRB,WRA             MAX VALID LENGTH FOR STRING          31800020
         LH    WRA,STRNGB+L4       LENGTH OF STRING                     31900020
         LTR   WRA,WRA             IS IT A NULL STRING                  31910020
         BZ    NOTFOUND            IF SO, TREAT AS NOT FOUND            31920020
FI000100 EQU   *                                                 A45363 31925021
         CLI   CADSCODE,CATEXT     IS DSTYPE TEXT                       31930020
         BE    NOLNCMP             IF SO THEN LENGTH OF TEXT MAY BE     31940020
*                                  GT LINESIZE SINCE SEARCH ACROSS BDYS 31950020
         CR    WRA,WRB             COMPARE                              32000020
         BH    NOTFOUND            IF LENGTH GT MAX, BRANCH             32200020
NOLNCMP  EQU   *                   BRANCH FOR TEXT DSTYPE               32300020
         BCTR  WRA,PARMREG0        DECREMENT FOR EX MVC                 32400020
         L     WRB,STRNGB          ADDR OF STRING                       32600020
         EX    WRA,MOVB            MOVE STRING                          32800020
         LA    WRA,L5(WRA)          INCREMENT LENGTH FOR LL00           33000020
         STH   WRA,CAFIBFR         STORE IN FIND BUFFER                 33200020
         OI    CACFLAG4,CAFINDIS   TURN ON FIND ISSUED BIT              33250020
         EJECT                                                          38660020
*  LINE-EDIT THE SEARCH STRING                                          38720020
LEDIT    LA    WRA,CAFIBFR         ADDR OF BUFFER                       38800020
         ST    WRA,LEAREA          STORE IN PARM LIST                   39000020
         MVI   LEAREA,DELIMOP      OPERAND FOR DELIM STRING             39200020
         ST    COMMREG,LEAREA+L4    PTR TO COMM AREA                    39400020
         LA    WRA,LEAREA                                               39600020
         IKJEBESH (COMMREG),IKJEBELE,PARAM=((WRA)),MF=(E,SHAREA)        39800020
NNFIND   LH    WRA,CAFIBFR+L2       COUNT SPECIFIED                     40000020
         LTR   WRA,WRA             IS IT NOT SPECIFIED                  40200020
         BZ    STRSERCH            IF NOT SPECIFIED  BRANCH             40400020
         EJECT                                                          40500020
*  THIS ROUTINE PLACES PTR TO BEGINNING OF DATA PORTION OF              40600020
*  RECORD IN WRB, AND PTR TO ONE BYTE PAST END OF DATA PORTION          40800020
*  IN WRC.                                                              41000020
SRCHIT   LA    WRB,CABFRPL         ADDR OF LINE                         41200020
         LH    WRC,L4(WRB)          LENGTH IN REGC                      41400020
         LA    WRB,L4(WRB)         INCREMENT TO POINT AT LL00           41600020
         AR    WRC,WRB             ADD TO POINT NEAR END                41800020
         TM    CACFLAG1,CANONUM    IS NONUM SPECIFIED                   42000020
         BZ    NUMBRD              IF NOT, BRANCH AS IF FIXED           42200020
         LA    WRB,L4(WRB)          INCREMENT PTR                       42400020
         B     OUTPT               EXIT FROM RTN                        42600020
NUMBRD   EQU   *                   IF LINE NUMBERED                     42800020
         SR    WRA,WRA             ZERO REG AND                         43000020
         IC    WRA,CALINE          INSERT OFFSET OF LINE NUMBER         43200020
         LA    WRD,OFF1            ONE                                  43400020
         CR    WRA,WRD             IS OFFSET OF LINE NUM ONE            43600020
         BNE   LCALDCD             IF NOT BRANCH                        43800020
         IC    WRA,CALENGTH        GET LENGTH OF LINE NUM               44000020
         AR    WRB,WRA             INCREMENT PTR PAST LINE NUMBER       44200020
         LA    WRB,L4(WRB)         INCREMENT BY 4 FOR LL00              44400020
         B     OUTPT               EXIT RTN                             44600020
LCALDCD  EQU   *                   IF OFFSET GT ONE                     44800020
         LR    WRC,WRB             SAVE PTR TO LL00                     45000020
         AR    WRC,WRA             INCREMENT BY LINE NUM OFFSET         45200020
         LA    WRC,L3(WRC)         INCREMENT ENDPTR FOR LL00            45400020
         LA    WRB,L4(WRB)         INCREMENT DATA PTR FOR LL00          45600020
OUTPT    EQU   *                   EXIT FROM ROUTINE                    45660020
         EJECT                                                          45720020
*  WRB CONTAINS BEGINNING POINTER                                       45780020
*  WRC CONTAINS END POINTER                                             45840020
         LH    WRD,CAFIBFR+L2      COUNT ORIGIN ONE                     45900020
         BCTR  WRD,PARMREG0        DECREMENT FOR 0 BASE                 46000020
         AR    WRD,WRB             POINT TO BYTE TO BEGIN SEARCH        46200020
         LR    WRA,WRD             REGA HAS PTR TO SEARCH POINT         46400020
         LH    WRD,CAFIBFR         LENGTH OF FIND STRING TO             46600020
         LA    WRE,L4                                                   46800020
         BCTR  WRD,PARMREG0        DECREMENT FOR EX                     47000020
         SR    WRD,WRE             DECREMENT FOR LENGTH OF STRING       47200020
         LR    WRE,WRD                                                  47400020
         AR    WRE,WRA             WILL SEARCH GO OVER END OF DATA      47600020
         CR    WRE,WRC             COMPARE                              47800020
         BNL   RDNXT               IF OVERFLOW, BRANCH                  48000020
         EX    WRD,COMPARE         EXECUTE THE STRING COMPARE           48200020
         BE    FOUND               IF FOUND, BRANCH                     48400020
         EJECT                                                          48460020
*  READ NEXT RECORD                                                     48520020
RDNXT    L     WRA,CAPTCDCB        ADDR OF CURRENT DCB                  48600020
         ST    WRA,BEUTABA         STORE IN PARM LIST                   48800020
         MVI   BEUTABA,NEXTRD      CODE FOR NEXT READ                   49000020
         SR    WRA,WRA             ZERO REG FOR                         49200020
         ST    WRA,BEUTABB         UT PTR TO KEY FOR READ               49400020
         LA    WRA,CABFRPL         PTR TO BUFFERPOOL                    49600020
         ST    WRA,BEUTABC         UT PTR TO STGE FOR RCD READ          49800020
         OI    BEUTABC,EOPARM      END OF PARMLIST INDICATOR            50000020
         LA    WRA,BEUTABA         ADDR OF PARM LIST                    50200020
         IKJEBESH   (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),        X50400020
               MF=(E,SHAREA)                                            50600020
         LTR   RETCDREG,RETCDREG   TEST RETURN CODE                     50800020
         BNZ   TESTIOT             IF NOT ZERO, BRANCH                  51000020
         TM    CAATTN,CAATTNIS     WAS ATTN ISSUED                      51200020
         BZ    SRCHIT              IF NOT, BRANCH                       51400020
         SR    RETCDREG,RETCDREG   ZERO RETCODE                         51600020
         B     OUT                 EXIT                                 51800020
         EJECT                                                          51803020
         SPACE                                                          51806020
*  VALIDITY CHECK EXIT                                                  51812020
CHKVAL   EQU   *                                                        51818020
         IKJEBESV  (14,12),,,COMMREG=L4(,PARMREG1),CODEREG=NO    A45363 51824021
         BALR  WRC,PARMREG0        ESTABLISH ADDRESSABILITY      A45363 51830021
         USING *,WRC                                             A45363 51836021
         SPACE                                                          51842021
*  CONVERT COUNT TO BINARY, REPROMPT IF ZERO                     A45363 51848021
         SPACE                                                          51854021
         L     WRA,L0(,PARMREG1)   ADDR OF PDE                   A45363 51860021
         LH    WRB,L4(,WRA)        LENGTH OF COUNT IN EBCDIC     A45363 51866021
         BCTR  WRB,PARMREG0        DECREMENT FOR EXECUTE         A45363 51872021
         L     WRA,L0(,WRA)        ADDR OF COUNT IN EBCDIC       A45363 51878021
         EX    WRB,FIPACK          COUNT IN PACKED DECIMAL       A45363 51884021
         CVB   WRB,FIDWORD         COUNT IN BINARY               A45363 51890021
         LTR   WRB,WRB             WAS ZERO SPECIFIED            A45363 51896021
         BZ    FI000210            YES, SPECIFY NOT VALID        A45363 51902021
         STH   WRB,CAFIBFR+L2      NO, SAVE COUNT                A45363 51908021
         SR    RETCDREG,RETCDREG   SPECIFY COUNT VALID           A45363 51914021
         SPACE                                                          51920021
FI000220 EQU   *                                                 A45363 51926021
         IKJEBERT  (14,12),,RC=(15)  RETURN TO IKJPARS           A45363 51932021
         SPACE 2                                                        51938021
FI000210 EQU   *                                                 A45363 51944021
         LA    RETCDREG,RET4       SPECIFY NOT VALID, REPROMPT   A45363 51950021
         B     FI000220            RETURN TO IKJPARS             A45363 51956021
         SPACE 2                                                        51962021
         DROP  WRC                                                      51986020
         EJECT                                                          51990020
*  MESSAGE FOR NO CORE AVAILABLE                                        51994020
NOSPAC   MVC   AREAM(LEND-LBEG),LBEG  MOVE MSG PARAMS                   52000020
         IKJEBEML  M312,0,NONINS,0,MF=(E,AREAM)                         52200020
         SR    RETCDREG,RETCDREG                                        52400020
         B     OUT8                EXIT                                 52600020
         EJECT                                                          52660020
*  IKJEBEUT RETURN CODE OTHER THAN ZERO                                 52720020
TESTIOT  LA    WRB,RET4            CODE FOR EOD                         52800020
         CR    WRB,RETCDREG        COMPARE                              53000020
         BE    NOTFOUND            IF EOD, BRANCH                       53200020
         B     IOER                GO TO IO ERROR RTN                   53400020
         EJECT                                                          53430020
         SPACE                                                          53460020
*  READ ANOTHER RECORD                                                  53520020
NNFIND1  EQU   *                                                        53600020
         L     WRA,CAPTCDCB        PTR TO UTIL DCB                      53800020
         ST    WRA,BEUTABA         STORE IN IKJEBEUT PARM LIST          54000020
         MVI   BEUTABA,NEXTRD      OPERAND FOR READ NEXT                54200020
         LA    WRA,CABFRPL         ADDR OF BUFFER TO PUT RCD            54400020
         ST    WRA,BEUTABC         STORE IN PARM LIST                   54600020
         LA    WRB,CACURNUM        ADDR OF LINE NUMBER (CURRENT)        54800020
         ST    WRB,BEUTABB         STORE IN PARM LIST                   55000020
         OI    BEUTABC,EOPARM      OPERAND FOR END OF PARMLIST          55200020
         LA    WRA,BEUTABA         ADDR OF PARM BLOCK                   55400020
         L     WRB,CACURNUM        CURRENT LINE NUMBER                  55600020
         LTR   WRB,WRB             IS IT ZERO                           55800020
         BNZ   OKRD                IF * IS NOT ZERO READ CURRENT RCD    56000020
         MVI   BEUTABA,FIRSTRD     IF * IS ZERO READ FIRST RECORD       56200020
OKRD     EQU   *                                                        56400020
         IKJEBESH  (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),         X56600020
               MF=(E,SHAREA)                                            56800020
         LTR   WRB,WRB             WAS CACURNUM ZERO                    56830020
         BZ    TSTZR               IF SO TEST RC DIFFERENTLY            56860020
TESTIX   EQU   *                                                        56890020
         LTR   RETCDREG,RETCDREG   TEST IO RETURN CODE                  56920020
         BZ    NNFIND              IF OKAY, CONTINUE                    56950020
         LA    WRA,RET4            IF NEXT RCD NOT FOUND                56980020
         CR    WRA,RETCDREG        AS INDICATED BY RC 4                 57010020
         BE    NOTFOUND            GO TO NOT FOUND RTN                  57040020
         B     IOER                ELSE IO ERROR EXIT                   57070020
TSTZR    EQU   *                                                        57100020
         LTR   RETCDREG,RETCDREG   TEST IO RETURN CODE                  57130020
         BNZ   TESTAS              IF UNSUCCESSFUL, TEST FURTHER        57160020
         LA    WRA,CABFRPL         POINT TO CURRENT KEY FOR READ NEXT   57190020
         ST    WRA,BEUTABB         STORE IN PARM LIST                   57220020
         MVI   BEUTABA,NEXTRD      CODE FOR READ NEXT                   57250020
         LA    WRA,BEUTABA         POINT TO PARM LIST                   57280020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),          X57310020
               MF=(E,SHAREA)                                            57340020
         B     TESTIX              GO TO TEST RETURN CODE               57370020
         EJECT                                                          57460020
*  TEXT NOT FOUND                                                       57520020
NOTFOUND EQU   *                                                        57600020
LAA      IKJEBEML   M506,0,0,0,MF=(E,AREAM)                             57800020
         SR    RETCDREG,RETCDREG   ZERO RC                              58000020
         B     OUT8                AND EXIT                             58200020
         EJECT                                                          58205020
         SPACE                                                          58210020
*  COMMAND SYSTEM ERROR MESSAGE                                         58220020
CMDERR   EQU   *                   COMMAND  SYSTEM ERROR MSG            58250020
         IKJEBEML  M313,M3131,0,CSERIN,MF=(E,AREAM)                     58280020
         B     OUT8                EXIT                                 58320020
         EJECT                                                          58360020
*  ROUTINE TO GO TO STRING SEARCH SERVICE RTN FOR FINDING               58400020
*  STRINGS AT ANY INCREMENT OR ACROSS TWO RECORDS (FOR TEXT DATASETS)   58600020
STRSERCH EQU   *                                                        58800020
         L     WRA,CAPTCDCB        PTR TO CURRENT UTILITY DCB           59000020
         ST    WRA,DCBPTR          STORE IN PARM LIST                   59200020
         LH    WRA,CAFIBFR         LENGTH OF STRING                     59400020
         LA    WRB,L4               AND LL00                            59600020
         SR    WRA,WRB             ADJUST FOR LL00                      59800020
         ST    WRA,LNTXT           STORE IN PARM LIST                   60000020
         LA    WRA,CAFIBFR+L4       ADDR OF STRING                      60200020
         ST    WRA,TXTPTR          STORE IN PARM LIST                   60400020
         LA    WRA,CABFRPL         ADDR OF BUFFER                       60600020
         ST    WRA,BUFPTR          STORE IN PARM LIST                   60800020
         LA    WRA,SRANGE          SEARCH RANGE                         61000020
         ST    WRA,LINRNPTR        STORE IN PARM LIST                   61200020
         LA    WRA,L255            INITIALIZE SEFLAGS TO ZERO    A45363 61260021
         ST    WRA,SEFLAGCT          AND COUNT TO MAX POSSIBLE   A45363 61320021
         L     WRA,CABFRPL         RECORD KEY                           61400020
         ST    WRA,SRANGE          FIRST RCD OF SEARCH RANGE            61600020
         L     WRA,ENINPO          MAX RCD KEY                          61800020
         ST    WRA,SRANGE+L4       END OF SEARCH RANGE                  62000020
         LA    PARMREG1,DCBPTR     ADDR OF PARM LIST                    62200020
         LR    PARMREG0,COMMREG    PTR TO COMM AREA                     62400020
         L     RETCDREG,STRADR     LOAD ADDRESS OF STRING SEARCH        62600020
         BALR  RETREG,RETCDREG         AND LINK TO IKJEBESE             62800020
         TM    CAATTN,CAATTNIS     WAS ATTN ISSUED                      63000020
         BZ    TXTS                IF NOT, BRANCH                       63200020
         SR    RETCDREG,RETCDREG   ZERO RETURN CODE                     63400020
         B     OUT                 AND EXIT                             63600020
TXTS     ST    RETCDREG,SESAVE     STORE RETURN CODE                    63800020
         SR    WRA,WRA             ZERO REGISTER                        64000020
         IC    WRA,SESAVE          INSERT RC BYTE                       64200020
         LTR   WRA,WRA             TEST                                 64400020
         BZ    FOND                IF FOUND, BRANCH                     64600020
         LA    WRB,RET4                                                 64800020
         CR    WRA,WRB             TEST FOR FOUND ACROSS LINES (TEXT)   65000020
         BE    FOND                IF SO, BRANCH                        65200020
         LA    WRD,RET8               CODE FOR NOT FOUND                65400020
         CR    WRA,WRD             COMPARE                              65600020
         BE    NOTFOUND            IF NOT FOUND, BR TO PUT MSG          65800020
         B     IOER                ELSE, BR TO PUT TO ERROR MSG         66000020
         EJECT                                                          66060020
*  STRING WAS FOUND AT CORRECT OFFSET                                   66120020
FOND     EQU   *                   EXIT FOR STRING FOUND                66200020
FOUND    EQU   *                   EXIT FOR STRING FOUND                66400020
         L     WRA,CABFRPL         KEY OF RECORD                 A45363 66600021
         ST    WRA,CACURNUM        STORE IN CURRENT LINE NUM            66800020
         OI    CACFLAG1,CALNTOVF   TURN ON LINE TO BE VERIFIED SW       67000020
OUT      EQU   *                   NORMAL ENTRY TO EXIT RTN             67600020
         SR    RETCDREG,RETCDREG   ZERO RETURN CODE                     67800020
OUTA     EQU   *                   ERROR ENTRANCE TO EXIT RTN           68000020
         MVC   CATEMPBF+L12(L8),CABFRPL  MOVE VERIFY                    68200020
         MVC   CATEMPBF+L20(L255),CABFRPL+L8  LINE INTO BUFFER          68400020
         SPACE                                                          68440021
*  FREE PARSE PDL IF NECESSARY                                   A45110 68480021
         TM    CAPRSPDL,CAFREEDL   IS THERE A PARSE PDL          A45110 68520021
         BO    FI000500            NO, EXIT                      A45110 68560021
         LA    PARSREG,CAPTPRSD    ADDR OF PDL POINTER           A45110 68600021
         IKJRLSA (PARSREG)         FREE PDL                      A45110 68640021
         OI    CAPRSPDL,CAFREEDL   INDICATE PDL FREED            A45110 68680021
         SPACE                                                          68720021
FI000500 EQU   *                                                 A45110 68760021
         IKJEBERT   (14,12),,RC=(15)                                    68800020
OUT8     EQU   *                                                        68850020
         LA    RETCDREG,RET8       RETURN CODE FOR STACK FLUSH          68852020
         B     OUTA                EXIT                                 68854020
         EJECT                                                          68860020
*  PARSE PCL MACROS FOR SECOND AND SUBSEQUENT ENTRIES INTO FIND         68920020
IKJEBFI0 IKJPARM  DSECT=DUMMIE                                          69000020
DELJAA   IKJPOSIT   DELIMITER                                           69200020
STRNGA IKJPOSIT STRING,SQSTRING,ASIS                             S21004 69300021
COUNTA IKJIDENT 'COUNT',MAXLNTH=3,FIRST=NUMERIC,OTHER=NUMERIC,         X69400020
               VALIDCK=CHKVAL                                           69500020
         IKJENDP                                                        69800020
         EJECT                                                          69860020
*  PARSE PCL MACROS FOR FIRST ENTRY INTO FIND                           69920020
IKJEBFI1 IKJPARM                                                        70000020
DELIMB   IKJPOSIT   DELIMITER                                           70200020
STRNGB IKJPOSIT STRING,SQSTRING,ASIS,PROMPT='STRING'             S21004 70300021
COUNTB IKJIDENT 'COUNT',MAXLNTH=3,FIRST=NUMERIC,OTHER=NUMERIC,         X70400020
               VALIDCK=CHKVAL                                           70500020
         IKJENDP                                                        70800020
         EJECT                                                          70860020
*  CONSTANTS AND MESSAGE CONSTANTS                                      70920020
LBEG     IKJEBEML 0,,,,MF=L                                             71000020
LEND     EQU   *                                                        71200020
ENINPO   DC    F'100000000'        LARGEST RECORD NUMBER ALLOWABLE      71400020
MOVB     MVC   CAFIBFR+L4(L0),L0(WRB) MOVE FOR STRING INTO BUFFER       71600020
FIPACK   PACK  FIDWORD(L8),L0(L0,WRA)  EX TARGET INSTRUCTION     A45363 71800021
MOVBUF   MVC   CATEMPBF+L12(L0),CABFRPL     MOVE FOR VERIFY             72200020
PRSADB   DC    V(IKJEBFI1)          POINTER TO 'PROMPT' PCL             72400020
PRSADA   DC    V(IKJEBFI0)          POINTER TO NOPROMPT PCL             72600020
COMPARE  CLC   CAFIBFR+L4(L0),L0(WRA) COMPARE FOR CHAR STRING           72800020
STRADR   DC    V(IKJEBESE)         ADDR OF STRING SEARCH RTN            73000020
NONINS   IKJEBEMG  ,M312IN1,'FIND'                                      73250020
CSERIN   IKJEBEMG CSERINA,M3131IN1,'PARSE'                              73350020
CSERINA  IKJEBEMG ,M3131IN2,'12'                                        73450020
         EJECT                                                          73520020
         IKJEBECA                                                       73600020
         EJECT                                                          73660020
*  WORK AREAS                                                           73720020
         ORG   CASCWKA             SUBCOMMAND WORKAREA                  73800020
FIDWORD  DS    D                   DOUBLE WORD FOR COUNT CVB     A45363 73860021
         SPACE                                                          73920021
DCBPTR   DS    1F                  IKJEBESE PARM LIST, DCB PTR          74000020
LNTXT    DS    1F                  LENGTH OF TEXT                       74200020
TXTPTR   DS    1F                  POINTER TO TEXT                      74400020
BUFPTR   DS    1F                  POINTER TO BUFFER AREA               74600020
LINRNPTR DS    1F                  POINTER TO LINE RANGE                74800020
SEFLAGCT DS    0F                  LABEL FOR STORE               A45363 74820021
         DS    X                   RESERVED                      A45363 74840021
SEFLAGS  DS    X                   FLAGS                         A45363 74860021
SEMODSW  EQU   X'80'               LINE HAS BEEN MODIFIED FLAG   A45363 74880021
SECHARCT DS    H                   MAX NUMBER OF CHAR TO SCAN    A45363 74900021
         SPACE                                                          74920021
LEAREA   DS    2F                  LINEDIT PARMLIST                     75000020
         DS    0D                                                       75200020
CONAR    DS    1F                  CONVERSION RTN WORKAREA              75400020
CONAREA  DS    1F                  CONVERSION RTN WORKAREA              75600020
SHAREA   DS    10F                 SR HANDLER PARMLIST                  75800020
AREAM    DS    10F                 MSG SELECT PARM LIST                 76000020
BEUTABA  DS    1F                  UT PARM LIST, OPCODE AND PTR TO DCB  76200020
BEUTABB  DS    1F                  UT PARM LIST, PTR TO KEY             76400020
BEUTABC  DS    1F                  UT PARM LIST, PTR TO BUFFER          76600020
SRANGE   DS    2F                  SEARCH RANGE                         76800020
SESAVE   DS    1F                  STRING SEARCH RETCODE STGE           77000020
         ORG   ,                   RESTORE COUNTER                      77410020
         EJECT                                                          77500020
         IKJPPL                                                         77600020
         END                                                            77800020
         BE    RET                 RETURN RET4 CODE IF COUNT ZEROE      78000020
