BEHE     TITLE 'EDIT SUBCOMMAND - HELP/PROFILE - IKJEBEHE'              00500020
         SPACE 2                                                        01000020
*********************************************************************** 01500020
*                                                                     * 02000020
*                                                                     * 03500020
* STATUS --                                                           * 04000020
*    VERSION NO. 01, OS/360, RELEASE NO. 20.7                    A42956 04500020
*                                                                     * 05000020
* FUNCTION --                                                         * 05500020
*    THIS ROUTINE IS USED TO INVOKE, UNDER THE EDIT COMMAND      A42956 05700020
*    PROCESSOR, SYSTEM COMMAND PROCESSORS WHICH REQUIRE NO       A42956 05900020
*    SPECIAL EDIT INFORMATION.  THAT IS, THE INPUT COMMAND       A42956 06100020
*    BUFFER, ADDRESSED BY FIELD CAPTIBFR IN THE EDIT             A42956 06300020
*    COMMUNICATIONS AREA, CONTAINS AN EDIT SUBCOMMAND NAME       A42956 06500020
*    WHICH IS ALSO A VALID SYSTEM COMMAND NAME, AND THE          A42956 06700020
*    OPERANDS REQUIRED BY THAT COMMAND PROCESSOR.  IKJEBEHE      A42956 06900020
*    ENSURES THAT THE THIRD AND FOURTH BYTES OF THE COMMAND      A42956 07100020
*    BUFFER ARE ZERO, THAT IS, THAT THE BUFFER BEGINS WITH       A42956 07300020
*    LL00, SO THAT THE BUFFER CAN BE SCANNED.  IKJEBEHE THEN     A42956 07500020
*    PASSES CONTROL TO THE COMMAND INVOKER ROUTINE, IKJEBECI,    A42956 07700020
*    WHICH ATTACHES THE SYSTEM COMMAND, PASSING THE BUFFER AS    A42956 07900020
*    A PARAMETER.  UPON COMPLETION OF THE SYSTEM COMMAND         A42956 08100020
*    PROCESSOR, IKJEBECI RETURNS CONTROL TO IKJEBEMA.            A42956 08300020
*                                                                A42956 08500020
*    SYSTEM COMMANDS INVOKED -                                   A42956 08700020
*                                                                A42956 08900020
*    HELP   -   PROVIDES LIST OF EDIT SUBCOMMANDS, INFORMATION   A42956 09100020
*               ON THE FUNCTION, SYNTAX, AND OPERANDS OF EDIT    A42956 09300020
*               SUBCOMMANDS.                                     A42956 09500020
*                                                                A42956 09700020
*    PROFILE -  ALLOWS TERMINAL USER TO MODIFY USER PROFILE      A42956 09900020
*               TABLE ENTRIES.                                   A42956 10100020
*                                                                     * 10500020
* ENTRY POINTS --                                                     * 11000020
*         IKJEBEHE  -  THE MAIN AND ONLY ENTRY POINT                  * 11500020
*                                                                     * 12000020
* INPUT --                                                            * 12500020
*    REGISTER 1 CONTAINS A POINTER TO THE EDIT COMMUNICATIONS AREA.   * 13000020
*    THE WORD 'CAPTIBFR' OF THE COMMUNICATIONS AREA CONTAINS A POINTER* 13500020
*    TO THE INPUT BUFFER.                                        A42956 14200020
*                                                                     * 15000020
* OUTPUT --                                                           * 15500020
*    A TWO WORD PARAMETER LIST PASSED TO THE COMMAND INVOKER ROUTINE. * 16000020
*    THE FIRST WORD CONTAINS A POINTER TO THE EDIT COMMUNICATIONS     * 16500020
*    AREA, AND THE SECOND CONTAINS A POINTER TO A BUFFER. THE FIRST   * 17000020
*    HALFWORD OF THIS BUFFER CONTAINS THE LENGTH OF THE BUFFER, AND   * 17500020
*    THE SECOND HALFWORD CONTAINS ZERO. THE REMAINDER OF THE BUFFER   * 18000020
*    CONTAINS THE SUBCOMMAND AS ENTERED AT THE TERMINAL.         A42956 18500020
*                                                                     * 19000020
* EXTERNAL REFERENCES --                                              * 19500020
*         IKJEBECI  -  THE COMMAND INVOKER ROUTINE                    * 20000020
*         EDIT COMMUNICATION AREA, BUILT BY THE INITIALIZATION        * 20500020
*           ROUTINE, IKJEBEIN.                                        * 21000020
*                                                                     * 21500020
* EXITS,NORMAL --                                                     * 22000020
*    THIS ROUTINE EXITS TO THE COMMAND INVOKER ROUTINE, IKJEBECI, VIA * 22500020
*    XCTL. UPON EXIT REGISTER 1 CONTAINS A POINTER TO THE PARAMETER   * 23000020
*    LIST DESCRIBED UNDER 'OUTPUT'.                                   * 23500020
*                                                                     * 24000020
* EXITS,ERROR -- N/A                                                  * 24500020
*                                                                     * 25000020
* TABLES/WORK AREAS -- N/A                                            * 25500020
*                                                                     * 26000020
* ATTRIBUTES --                                                       * 26500020
*    REFRESHABLE,ENABLED,NON-PRIVILEGED                               * 27000020
*                                                                     * 27200020
* CHARACTER CODE DEPENDENCY --                                        * 27500020
*    NONE                                                             * 28000020
*                                                                     * 28200020
* NOTES --                                                            * 28500020
*    USE OF THE IKJEBESV MACRO FOR STANDSRD ENTRY LINKAGE REQUIRES    * 29000020
*    THAT A BASE REGISTER BE DEFINED WITH THE SYMBOLIC NAME 'BASEREG',* 29500020
*    AND THAT ANOTHER REGISTER BE DEFINED WITH THE SYMBOLIC NAME      * 30000020
*    'COMMREG', FOR USE IN ADDRESSING THE EDIT COMMUNICATIONS AREA.   * 30500020
*                                                                     * 31000020
*    THIS ROUTINE IS DESCRIBED IN PROGRAM LOGIC MANUAL           A42956 31100020
*    GY28-6773, TSO COMMAND PROCESSOR PROGRAM LOGIC MANUAL,      A42956 31200020
*    VOLUME 3, EDIT.                                             A42956 31300020
*                                                                     * 31400020
*********************************************************************** 31500020
         SPACE 2                                                        32000020
IKJEBEHE CSECT                                                          32500020
*A057000-101000,142000,311000-313000                                    32600020
*C045000,185000,730000                                                  32700020
*D060000-100000,140000-145000                                           32800020
         SPACE 2                                                        33000020
*********************************************************************** 33500020
*                                                                     * 34000020
*    EQUATES OF SYMBOLIC REGISTERS                                      34500020
*                                                                     * 35000020
*********************************************************************** 35500020
PARMREG1 EQU   1                       PARAMETER POINTER                36000020
ADDRREG  EQU   5                       ADDRESSING REGISTER              36500020
WORKREG  EQU   6                       WORK REGISTER                    37000020
COMMREG  EQU   9                       COMMUNICATION AREA ADDRESSING    37500020
BASEREG  EQU   11                      BASE REGISTER                    38000020
SAVEREG  EQU   13                      SAVE AREA REGISTER               38500020
RETREG   EQU   14                      RETURN TO CALLER                 39000020
RETCDREG EQU   15                      RETURN CODE                      39500020
         SPACE 2                                                        40000020
*********************************************************************** 40500020
*                                                                     * 41000020
*    EQUATES OF SYMBOLIC CONSTANTS                                      41500020
*                                                                     * 42000020
*********************************************************************** 42500020
         SPACE                                                          43000020
D2       EQU   2                       DISPLACEMENT OF 2 (DECIMAL).     43500020
D4       EQU   4                       DISPLACEMENT OF 4 (DECIMAL).     44000020
D12      EQU   12                      DISPLACEMENT OF 12 (DECIMAL).    44500020
         EJECT                                                          45000020
*********************************************************************** 45500020
*                                                                     * 46000020
*    STANDARD ENTRY LINKAGE AND ESTABLISHMENT OF ADDRESSABILITY BOTH    46500020
*    IN THIS ROUTINE AND IN THE COMMUNICATION AREA                      47000020
*                                                                     * 47500020
*********************************************************************** 48000020
         SPACE                                                          48500020
*    SAVE CALLER'S REGISTERS AND ESTABLISH ADDRESSABILITY               49000020
         IKJEBESV (14,12),T,*                                           49500020
         SPACE                                                          50000020
         USING IKJEBECA,COMMREG        ADDRESSABILITY IN COMMUNICATION  50500020
*                                      AREA                             51000020
         SPACE 2                                                        51500020
*********************************************************************** 52000020
*                                                                     * 52500020
*    SET UP PARAMETER LIST FOR IKJEBECI                               * 53000020
*                                                                     * 53500020
*********************************************************************** 54000020
         LA    PARMREG1,COWORD1        LET PARMREG1 POINT TO PARMLIST   54500020
         ST    COMMREG,COWORD1         LET 1ST PARAM WORD POINT TO      55000020
*                                      COMM. AREA                       55500020
         L     ADDRREG,CAPTIBFR        ADDRESS OF INPUT COMMAND BUFFER  56000020
*                                      INTO ADDRREG                     56500020
         ST    ADDRREG,COWORD2         SECOND WORD OF PARAMETER LIST    57000020
*                                      POINTS TO INPUT COMMAND BUFFER   57500020
         SPACE 2                                                        58000020
*********************************************************************** 58500020
*                                                                     * 59000020
*    SET SECOND HALFWORD OF INPUT COMMAND BUFFER TO ZERO              * 59500020
*                                                                     * 60000020
*********************************************************************** 60500020
         SPACE                                                          61000020
         SR    WORKREG,WORKREG         SET WORKREG TO ZERO              61500020
         STH   WORKREG,D2(ADDRREG)     SET SECOND HALFWORD OF BUFFER    62000020
*                                      TO ZERO                          62500020
         SPACE 2                                                        63000020
*********************************************************************** 63500020
*                                                                     * 64000020
*    TRANSFER CONTROL TO THE COMMAND INVOKER ROUTINE                  * 64500020
*                                                                     * 65000020
*********************************************************************** 65500020
         ST    SAVEREG,CANXTSVA        SET POINTER TO NEXT AVAILABLE    66000020
*                                      SAVE AREA TO POINT TO SAVE AREA  66500020
*                                      USED BY THIS ROUTINE.            67000020
         L     SAVEREG,D4(SAVEREG)     SAVEREG POINTS TO PREVIOUS SAVE  67500020
*                                      AREA                             68000020
         L     RETREG,D12(SAVEREG)     RETURN ADDRESS INTO RETREG       68500020
         SPACE                                                          69000020
         MVC   COXCTL(XCTLL),HEXCTL    MOVE LIST FOR XCTL INTO EDIT     69500020
*                                      COMMUNICATION AREA               70000020
         SPACE                                                          70500020
         XCTL  (2,12),MF=(E,(1)),SF=(E,COXCTL)                          71000020
         SPACE 3                                                        71500020
*********************************************************************** 72000020
*                                                                     * 72500020
*                       CONSTANT AREA                            A42956 73000020
*                                                                     * 73500020
*********************************************************************** 74000020
HEXCTL   XCTL  EP=IKJEBECI,SF=L                                         74500020
XCTLEND  EQU   *                                                        75000020
XCTLL    EQU   XCTLEND-HEXCTL                                           75500020
         SPACE 2                                                        76000020
         IKJEBECA                                                       76500020
         SPACE 2                                                        77000020
         SPACE                                                          77500020
*********************************************************************** 78000020
*                                                                     * 78500020
*    COWORD1 AND COWORD2 ARE TO ADDRESS THE FIRST TWO WORDS OF THE    * 79000020
*    SUBCOMMAND WORK AREA OF THE EDIT COMMUNICATIONS AREA             * 79500020
*                                                                     * 80000020
*********************************************************************** 80500020
         SPACE                                                          81000020
         ORG   CASCWKA                 SET LOCATION COUNTER TO OFFSET   81500020
*                                      OF SUBCOMMAND WORD AREA          82000020
COWORD1  DS    F                       FIRST WORD OF PARAMETER LIST     82500020
COWORD2  DS    F                       SECOND WORD OF PARAMETER LIST    83000020
COXCTL   DS    20F                     AREA FOR THE LIST FORM OF XCTL   83500020
         END                                                            84000020
