BEIA     TITLE 'IKJEBEIA - INITIALIZATION MESSAGES - EDIT CP TSO/360'   00070020
*********************************************************************** 00140020
*                                                                     * 00210020
* STATUS -- VERSION NO.01, OS/360 RELEASE NO. 20                      * 00490020
*                                                                     * 00560020
* FUNCTION -- THIS ROUTINE IS INVOKED VIA LINK WHENEVER EDIT          * 00630020
*    INITIALIZATION REQUIRES TERMINAL OUTPUT OF AN INFORMATIONAL      * 00700020
*    MESSAGE.  SPECIFIC MESSAGES ARE SELECTED BY USING AN             * 00770020
*    OFFSET SUPPLIED IN THE PARAMETER LIST AS AN INDEX TO A           * 00840020
*    BRANCH TABLE.  IN THIS WAY, A PARTICULAR MESSAGE SUBROUTINE      * 00910020
*    IS GIVEN CONTROL TO FORMAT THE MESSAGE FOR IKJEBEMS, THE         * 00980020
*    EDIT MESSAGE SELECTION ROUTINE.  IKJEBEMS IS INVOKED             * 01050020
*    THROUGH THE IKJEBESH MACRO FOR TERMINAL OUTPUT OF THE            * 01120020
*    MESSAGE VIA THE PUTLINE SERVICE ROUTINE.                         * 01190020
*                                                                     * 01260020
* ENTRY POINTS --                                                     * 01330020
*         IKJEBEIA - VIA LINK MACRO FROM THE EDIT INITIALIZATION      * 01380020
*         PROGRAM (IKJEBEIN) FOR OUTPUT OF TERMINAL MESSAGES          * 01390020
*         REQUIRED DURING INITIALIZATION OF THE EDIT COMMAND.         * 01400020
*                                                                     * 01450020
* INPUT --                                                            * 01460020
*    REGISTER ONE (1) CONTAINS A POINTER TO A SIX-WORD PARAMETER LIST * 01470020
*    FOR THIS ROUTINE --                                              * 01520020
*    WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA                  * 01530020
*    WORD 2 - MESSAGE INDEX FOR ADDRESSING APPROPRIATE SUBROUTINE     * 01540020
*    WORD 3 - RELATIVE NUMBER OF SECOND-LEVEL MESSAGE (OPTIONAL)      * 01590020
*    WORD 4 - FIRST-LEVEL INSERTION INFORMATION (OPTIONAL)            * 01600020
*    WORD 5 - SECOND-LEVEL INSERTION INFORMATION (OPTIONAL)           * 01610020
*    WORD 6 - ADDRESS OF 100 FULLWORD WORK AREA FOR THIS ROUTINE      * 01660020
*                                                                     * 01670020
* OUTPUT --                                                           * 01680020
*    REGISTER FIFTEEN (15) CONTAINS THE PUTLINE RETURN CODE           * 01730020
*    RETURNED BY IKJEBEMS.                                            * 01740020
*                                                                     * 01750020
* EXTERNAL REFERENCES --                                              * 01800020
*         IKJEBEMS - EDIT MESSAGE SELECTION ROUTINE, INVOKED VIA      * 01810020
*         IKJEBESH MACRO FOR TERMINAL OUTPUT OF INFORMATIONAL         * 01820020
*         MESSAGES.                                                   * 01870020
*                                                                     * 02310020
*    MACROS USED --                                                   * 02380020
*                                                                     * 02450020
*         IKJCPPL  - DEFINES COMMAND PROCESSOR PARAMETER LIST.        * 02470020
*         IKJEBEMG - BUILDING MESSAGE INSERTION LISTS.                * 02490020
*         IKJEBEMI - SYMBOLIC EQUATES FOR RELATIVE MESSAGE            * 02520020
*                    NUMBERS AND INSERTION OFFSETS.                   * 02590020
*         IKJEBERT - RETURN LINKAGE FOR EDIT COMMAND PROCESSOR.       * 02660020
*         IKJEBESH - LINKAGE TO EDIT SERVICE ROUTINES.                * 02730020
*         IKJEBESV - ENTRY LINKAGE FOR EDIT COMMAND PROCESSOR.        * 02800020
*         IKJPSCB  - DEFINES PROTECTED STEP CONTROL BLOCK.            * 02830020
*                                                                     * 02870020
* EXITS, NORMAL --                                                    * 02940020
*    THIS ROUTINE UNCONDITIONALLY RETURNS TO THE CALLING ROUTINE      * 02990020
*    BY BRANCHING ON REGISTER FOURTEEN (14).                          * 03000020
*                                                                     * 03150020
* EXITS, ERROR -- NONE.                                               * 03220020
*                                                                     * 03290020
* TABLES/WORK AREAS --                                                * 03360020
*                                                                     * 03430020
*    THE EDIT COMMUNICATION AREA CONTAINS BUFFERS, WORK AREAS,        * 03500020
*    AND CONTROL INFORMATION FOR THE EDIT COMMAND PROCESSOR.          * 03570020
*    ITS ADDRESS IS PASSED AS A PARAMETER TO THIS ROUTINE.            * 03640020
*                                                                     * 04130020
* ATTRIBUTES --                                                       * 04200020
*    REFRESHABLE, ENABLED, NON-PRIVILEGED.                            * 04250020
*                                                                     * 04260020
* CHARACTER CODE DEPENDENCY --                                        * 04270020
*    THIS ROUTINE ASSUMES THAT THE HIGH ORDER ZONE OF A SIGNED,       * 04320020
*    UNPACKED DECIMAL DIGIT WILL CONTAIN NO BITS UNCOMMON TO THE HIGH * 04330020
*    ORDER ZONE OF ANY CHARACTER DIGIT.                               * 04340020
*                                                                     * 04390020
* NOTES -- NONE.                                                      * 04400020
*                                                                     * 04410020
*********************************************************************** 04830020
         EJECT                                                          04900020
IKJEBEIA CSECT                                                          04970020
*A114600,138400-138584,686500-687322,837000                      A45714 05020021
*C765100,786800                                                  A45714 05030021
*********************************************************************** 05040020
*                                                                     * 05110020
*   GENERAL PURPOSE REGISTER EQUATES FOR THIS ROUTINE.                * 05180020
*                                                                     * 05250020
*********************************************************************** 05320020
PARMREG0 EQU   0              PARAMETER REGISTER.                       05390020
PARMREG1 EQU   1              PARAMETER REGISTER.                       05460020
LENREG   EQU   2              REGISTER USED TO CONTAIN LENGTH FOR       05530020
*                                  CURRENT OPERATION.                   05600020
LEV1REG  EQU   2              RELATIVE NUMBER OF FIRST LEVEL            05670020
*                                  MESSAGE.                             05740020
COUNTREG EQU   3              LOOP CONTROL COUNTER.                     05810020
LEV2REG  EQU   3              RELATIVE NUMBER OF SECOND LEVEL           05880020
*                                  MESSAGE.                             05950020
INS1REG  EQU   4              ADDRESS OF INSERTION LIST FOR FIRST       06160020
*                                  LEVEL MESSAGE.                       06230020
DSNAMREG EQU   5              ADDRESS OF DATA SET NAME.                 06300020
INS2REG  EQU   5              ADDRESS OF INSERTION LIST FOR             06370020
*                                  SECOND LEVEL MESSAGE.                06440020
PLISTREG EQU   6              POINTER TO INPUT PARAMETER LIST FOR       06510020
*                                  A SUBROUTINE.                        06580020
TMPREG   EQU   6              ADDRESS OF TMP PARAMETER LIST.            06650020
DSORGREG EQU   7              ADDRESSABILITY TO DSORG FIELD             06720020
*                                  OF FORMAT 1 DSCB.                    06790020
INLENREG EQU   7              COUNTER OF NUMBER OF BYTES IN AN          06860020
*                                  INSERTION RECORD.                    06930020
PASSREG  EQU   8              ADDRESS OF PSCB.                          07000020
SRRTNREG EQU   8              REGISTER USED TO LINK TO INTERNAL         07070020
*                                  SUBROUTINES.                         07140020
COMMREG  EQU   9              BASE REGISTER USED TO ADDRESS THE         07210020
*                                  COMMUNICATION AREA.                  07280020
BASEREG  EQU   11             BASE REGISTER FOR THIS CSECT              07350020
DATAREG  EQU   12             WORK AREA ADDRESSABILITY.                 07420020
SAVEREG  EQU   13             ADDRESS OF SAVE AREA.                     07490020
RETREG   EQU   14             ADDRESS OF RETURN POINT IN CALLING        07560020
*                                  MODULE.                              07630020
EPLOCREG EQU   15             ENTRY POINT ADDRESS OF MODULE TO BE       07700020
*                                  INVOKED.                             07770020
RETCDREG EQU   15             CONDITION CODE RETURNED TO CALLING        07840020
*                                  ROUTINE.                             07910020
         EJECT                                                          07980020
         IKJEBESV (14,12),,*,COMMREG=(9)                                08050020
         USING IKJEBECA,COMMREG ADDRESSABILITY TO THE                   08120020
*                                  COMMUNICATION AREA.                  08190020
         L     DATAREG,D20(,PARMREG1) ADDRESS OF WORK AREA.             08260020
         USING IAWORKA,DATAREG ESTABLISH ADDRESSABILITY TO WORK         08330020
*                                  AREA.                                08400020
         LR    PLISTREG,PARMREG1 SAVE ADDRESS OF INPUT PARAMETER        08470020
*                                  LIST.                                08540020
         L     PARMREG1,D4(,PLISTREG) OBTAIN RELATIVE MESSAGE           08610020
*                                  NUMBER TO BE PROCESSED.              08680020
         EJECT                                                          08730020
*********************************************************************** 08740020
*                                                                       08742020
*    BELOW IS A BRANCH TABLE FOR SELECTING EXECUTABLE CODE FOR          08744020
*    PARTICULAR MESSAGES, BASED ON THE SECOND WORD OF THE PARAMETER     08746020
*    LIST (MESSAGE INDEX).  THE TABLE IS STRICTLY POSITION              08748020
*    DEPENDENT.                                                         08748420
*                                                                       08748820
*********************************************************************** 08749220
         SPACE 2                                                        08749620
IA001001 EQU   *                                                        08750020
         B     IA001001+X4(PARMREG1) ERROR PROCESSING BRANCH            08820020
*                                  TABLE.                               08890020
         B     IA002010       01 - NO MAIN STORAGE AVAILABLE.           08960020
         B     IA003010       02 - COMMAND SYSTEM ERROR.                09030020
         B     IA004010       03 - DATA SET NOT PARTITIONED.            09100020
         B     IA005010       04 - INVALID DSORG ENCOUNTERED.           09170020
         B     IA006010       05 - INVALID RECFM ENCOUNTERED.           09240020
         B     IA007010       06 - INVALID LRECL FOR OLD DATA SET       09310020
         B     IA008010       07 - DSNAME NOT IN CATALOG.               09380020
         B     IA009010       08 - LINE VALUE ENTERED ON COMMAND        09450020
*                                  (OR LRECL FIELD IN DSCB) IS          09500020
*                                  INVALID.                             09510020
         B     IA010010       09 - BLOCK VALUE ENTERED INCORRECT.       09520020
         B     IA011010       10 - SYNTAX CHECKING NOT ALLOWED.         09590020
         B     IA012010       11 - DATA SET MUST BE NUMBERED.           09660020
         B     IA013010       12 - PLI SOURCE MARGIN ERROR.             09730020
         B     IA014010       13 - INVALID NUM OPERAND SUBFIELDS.       09800020
         B     IA015010       14 - CAPS REQUIRED.                       09870020
         B     IA016010       15 - UNALLOCATION ERROR OR DDNAME         09940020
*                                  NOT FOUND IN TIOT.                   10010020
         B     IA017010       16 - LINE/BLOCK OPERAND INVALID.          10080020
         B     IA018010       17 - LINE LE 8 FOR NUM DATA SETS.         10150020
         B     IA019010       18 - MEMBER NOT FOUND.                    10220020
         B     IA021010       19 - OLD DATA SET HAS RECFM=V WHERE       10290020
*                                  F IS REQUIRED.                       10360020
         B     IA022010       20 - DSNAME ALREADY IN USE.               10430020
         B     IA023010       21 - DATA SET NOT USABLE.                 10500020
         B     IA024010       22 - TOO MANY DATA SETS ALLOCATED.        10570020
         B     IA025010       23 - REQUIRED VOLUME NOT MOUNTED.         10640020
         B     IA026010       24 - DSNAME NOT ON VOLUME.                10710020
         B     IA027010       25 - ALLOCATION SYSTEM ERROR.             10780020
         B     IA028010       26 - DEVICE NOT DIRECT ACCESS.            10850020
         B     IA029010       27 - INVALID DSNAME.                      10920020
         B     IA030010       28 - DSNAME WILL CREATE INVALID           10990020
*                                  CATALOG STRUCTURE.                   11060020
         B     IA031010       29 - DSNAME NOT QUALIFIED.                11130020
         B     IA032010       30 - DSNAME NOT RESOLVED.                 11200020
         B     IA033010       31 - GOFORT(FREE) SPECIFIED FOR RECORD    11270020
*                                  F DATA SET.                          11320020
         B     IA034010       32 - INVALID UNIT OR NO UNIT              11340020
*                                  AVAILABLE.                           11410020
         B     IA035010       33 - MISSING DATA SET TYPE.        A45714 11460021
         EJECT                                                          11480020
*********************************************************************** 11530020
*                                                                       11540020
*    MESSAGE ID -- IKJ52312I                                            11542020
*                                                                       11544020
*    CONDITION(S) --                                                    11546020
*                                                                       11548020
*         NOT ENOUGH MAIN STORAGE IS AVAILABLE TO EXECUTE THE EDIT      11548420
*         COMMAND.                                                      11548820
*                                                                       11549220
*    PARAMETER FORMAT --                                                11549620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               11549720
*         WORD 2 - MESSAGE INDEX = 00                                   11549820
*         WORD 3 - NOT USED                                             11549920
*         WORD 4 - NOT USED                                             11573220
*         WORD 5 - NOT USED                                             11583220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    11593220
*                                                                       11595220
*********************************************************************** 11595620
IA002010 EQU   *                                                        11596720
         LA    LEV1REG,M312   RELATIVE MESSAGE TO BE PUT TO THE         11620020
*                                  TERMINAL.                            11690020
         LA    INS1REG,IAINS001 ADDRESS OF INSERTION RECORD FOR         11760020
*                                  FIRST LEVEL MESSAGE.                 11830020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        11900020
         SR    INS2REG,INS2REG     OR INSERTIONS ARE REQUIRED.          11970020
         B     IA020001        BRANCH TO CALL IKJEBEMS.                 12040020
         EJECT                                                          12110020
*********************************************************************** 12160020
*                                                                       12170020
*    MESSAGE ID -- IKJ52313I                                            12172020
*                                                                       12174020
*    CONDITION(S) --                                                    12176020
*                                                                       12178020
*         AN ERROR HAS OCCURRED IN A SERVICE ROUTINE OR SYSTEM          12178420
*         ROUTINE.                                                      12178820
*                                                                       12179220
*    PARAMETER FORMAT --                                                12179620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               12179720
*         WORD 2 - MESSAGE INDEX = 04                                   12179820
*         WORD 3 - NOT USED                                             12179920
*         WORD 4 - NOT USED                                             12203220
*         WORD 5 - INSERTION INDICATOR FOR SECOND-LEVEL MESSAGE         12213220
*              BYTE 1 - INDICATES SERVICE ROUTINE                       12223220
*              BYTES 2-4 - RETURN CODE (BINARY)                         12225220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    12225620
*                                                                       12226020
*********************************************************************** 12226420
IA003010 EQU   *                                                        12226720
         LA    LEV1REG,M313   RELATIVE MESSAGE TO BE PUT TO THE         12250020
*                                  TERMINAL.                            12320020
         SR    INS1REG,INS1REG SHOW NO INSERTION REQUIRED IN            12390020
*                                  FIRST LEVEL MESSAGE.                 12460020
         CLI   D16(PLISTREG),IANORTN CHECK IF SERVICE ROUTINE           12530020
*                                  INSERTION PREVIOUSLY DEFINED.        12600020
         BE    IA003040       IF SO, BRANCH TO PUT MESSAGE.             12670020
         CLI   D16(PLISTREG),IASVCOBT DETERMINE IF SERVICE              12740020
*                                  ROUTINE IS OBTAIN SVC.               12810020
         BNE   IA003014       IF NOT SVC OBTAIN, BRANCH TO CHECK        12880020
*                                  IF DEVTYPE.                          12950020
         MVC   INMSGIN1(IAINS005-IAINS004),IAINS004 MOVE SERVICE        13020020
*                                  ROUTINE NAME TO INSERTION.           13090020
         B     IA003030       BRANCH TO CONVERT RETURN CODE.            13160020
IA003014 EQU   *                                                        13230020
         CLI   D16(PLISTREG),IADEVTYP DETERMINE IF SERVICE              13300020
*                                  ROUTINE IS DEVTYPE SVC.              13370020
         BNE   IA003015       IF NOT DEVTYPE, BRANCH TO DETERMINE       13440020
*                                  IF IKJDAIR.                          13510020
         MVC   INMSGIN1(IAINS014-IAINS013),IAINS013 MOVE SERVICE        13580020
*                                  ROUTINE NAME TO INSERTION.           13650020
         B     IA003030       BRANCH TO CONVERT RETURN CODE.            13720020
IA003015 EQU   *                                                        13790020
         CLI   D16(PLISTREG),IAPUTGET CHECK IF SERVICE ROUTINE   A45714 13840021
*                                  IS IKJPTGT.                   A45714 13850021
         BNE   IA003018       IF NO, BRANCH TO CHECK IF DAIR.    A45714 13852021
         MVC   INMSGIN1(IAINS015-IAINS014),IAINS014 MOVE SERVICE A45714 13854021
*                                  ROUTINE NAME TO INSERTION     A45714 13856021
         B     IA003030       BRANCH TO CONVERT RETURN CODE.     A45714 13858021
IA003018 EQU   *                                                 A45714 13858421
         CLI   D16(PLISTREG),IADAIR DETERMINE IF SERVICE ROUTINE        13860020
*                                  IS IKJDAIR.                          13930020
         BNE   IA003020       IF NOT IKJDAIR, BRANCH TO CHECK           14000020
*                                  IF DEFAULT.                          14070020
         MVC   INMSGIN1(IAINS011-IAINS010),IAINS010 MOVE SERVICE        14140020
*                                  ROUTINE NAME TO INSERTION.           14210020
         B     IA003030       BRANCH TO CONVERT RETURN CODE.            14280020
IA003020 EQU   *                                                        14350020
         CLI   D16(PLISTREG),IADFAULT DETERMINE IF SERVICE              14420020
*                                  ROUTINE IS DEFAULT.                  14490020
         BNE   IA003022       IF NOT DEFAULT, BRANCH TO CHECK           14560020
*                                  IF DELETE SVC.                       14630020
         MVC   INMSGIN1(IAINS009-IAINS008),IAINS008 MOVE SERVICE        14700020
*                                  ROUTINE NAME TO INSERTION.           14770020
         B     IA003030       BRANCH TO CALL IKJEBEMS.                  14840020
IA003022 EQU   *                                                        14910020
         CLI   D16(PLISTREG),IASVCDEL DETERMINE IF SERVICE              14980020
*                                  ROUTINE IS DELETE SVC.               15050020
         BNE   IA003024       IF NOT DELETE SVC, ASSUME THAT            15120020
*                                  SERVICE ROUTINE IS PARSE.            15190020
         MVC   INMSGIN1(IAINS010-IAINS009),IAINS009 MOVE SERVICE        15260020
*                                  ROUTINE NAME TO INSERTION.           15330020
         B     IA003030       BRANCH TO CALL IKJEBEMS.                  15400020
IA003024 EQU   *                                                        15470020
         MVC   INMSGIN1(IAINS012-IAINS011),IAINS011 MOVE SERVICE        15540020
*                                  ROUTINE NAME TO INSERTION.           15610020
IA003030 EQU   *                                                        15680020
         MVI   D16(PLISTREG),IAZEROES ZERO SERVICE ROUTINE NUMBER       15750020
         L     PARMREG1,D16(,PLISTREG) OBTAIN RETURN CODE FOR           15820020
*                                  CONVERSION.                          15890020
         BAL   EPLOCREG,IA003035 INSURE REGISTER NEGATIVE FOR           15960020
*                                  PROCESSING 2-DIGIT RETURN            16030020
*                                  CODE.                                16100020
IA003035 EQU   *                                                        16170020
         LA    LEV2REG,INMSGIN2 ADDRESS OF AREA FOR CONVERSION.         16240020
         BAL   SRRTNREG,IA100003 BRANCH TO CONVERT RETURN CODE TO       16310020
*                                  PRINTABLE DECIMAL.                   16380020
         ST    LEV2REG,INPTIN1 CHAIN FIRST AND SECOND INSERTION         16450020
*                                  RECORDS.                             16520020
         LA    INS2REG,INMSGIN1 ADDRESS OF INSERTION CHAIN FOR          16590020
*                                  SECOND LEVEL MESSAGE.                16660020
         LA    LEV2REG,M3131IN2 OBTAIN OFFSET TO SECOND INSERTION       16730020
         STH   LEV2REG,INOFFIN2    AND SAVE IN PARAMETER LIST.          16800020
         B     IA003050       BRANCH TO COMPLETE PARAMETER LIST.        16870020
IA003040 EQU   *                                                        16940020
         L     INS2REG,D16(,PLISTREG) ADDRESS OF PREFORMATTED           17010020
*                                  INSERTION LIST.                      17080020
IA003050 EQU   *                                                        17150020
         LA    LEV2REG,M3131  RELATIVE SECOND LEVEL MESSAGE TO BE       17220020
*                                  PUT TO THE USER.                     17290020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  17360020
         EJECT                                                          17430020
*********************************************************************** 17480020
*                                                                       17490020
*    MESSAGE ID -- IKJ52311I                                            17492020
*                                                                       17494020
*    CONDITION(S) --                                                    17496020
*                                                                       17498020
*         A MEMBER NAME HAS BEEN SPECIFIED FOR A SEQUENTIAL DATA SET.   17498420
*                                                                       17498820
*    PARAMETER FORMAT --                                                17499220
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               17499620
*         WORD 2 - MESSAGE INDEX = 08                                   17499720
*         WORD 3 - NOT USED                                             17499820
*         WORD 4 - LENGTH OF MEMBER NAME                                17499920
*         WORD 5 - NOT USED                                             17523220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    17533220
*                                                                       17543220
*********************************************************************** 17545220
IA004010 EQU   *                                                        17546720
         LA    LEV1REG,M311   RELATIVE MESSAGE TO BE PUT TO THE         17570020
*                                  TERMINAL.                            17640020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LIST FOR           17710020
*                                  FIRST LEVEL MESSAGE.                 17780020
         L     INS2REG,D12(,PLISTREG) OBTAIN LENGTH OF MEMBER           17850020
         BCTR  INS2REG,D0          NAME, REDUCE BY 1, AND MOVE TO       17920020
         EX    INS2REG,IAMVC006    INSERTION RECORD.                    17990020
         LA    INS2REG,D5(,INS2REG) COMPUTE LENGTH OF INSERTION         18060020
         STH   INS2REG,INLNIN1     AND SAVE IN PARAMETER LIST.          18130020
         LA    INS2REG,M311IN1 OBTAIN OFFSET TO MEMBER INSERTION        18200020
         STH   INS2REG,INOFFIN1    AND SAVE IN PARAMETER LIST.          18270020
         LA    INS2REG,CADSNPTR OBTAIN ADDRESS OF DSNAME AND SAVE       18340020
         ST    INS2REG,INPTIN1     IN PARAMETER LIST.                   18410020
         LA    INS2REG,M311IN2 OBTAIN OFFSET TO DSNAME INSERTION        18480020
         STH   INS2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          18550020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE OR          18620020
         SR    INS2REG,INS2REG     INSERTION REQUIRED.                  18690020
         ST    INS2REG,CADSNPTR SHOW ONLY TWO INSERTIONS REQUIRED       18760020
*                                  IN THIS MESSAGE.                     18830020
         B     IA020001        BRANCH TO CALL IKJEBEMS.                 18900020
         EJECT                                                          18970020
*********************************************************************** 19020020
*                                                                       19030020
*    MESSAGE ID -- IKJ52330I                                            19032020
*                                                                       19034020
*    CONDITION(S) --                                                    19036020
*                                                                       19038020
*         THE DATA SET ORGANIZATION SPECIFIED IN THE FORMAT 1 DSCB IS   19038420
*         NOT ACCEPTABLE FOR THE EDIT COMMAND.                          19038820
*                                                                       19039220
*    PARAMETER FORMAT --                                                19039620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               19039720
*         WORD 2 - MESSAGE INDEX = 12                                   19039820
*         WORD 3 - NOT USED                                             19039920
*         WORD 4 - ADDRESS OF DSORG FIELD IN FORMAT 1 DSCB              19063220
*         WORD 5 - NOT USED                                             19073220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    19083220
*                                                                       19085220
*********************************************************************** 19085620
IA005010 EQU   *                                                        19086720
         L     DSORGREG,D12(,PLISTREG) ADDRESS OF DSORG FIELD.          19110020
         CLI   X0(DSORGREG),DS1ORGIS CHECK IF INDEXED SEQUENTIAL        19180020
*                                  ORGAINZATION.                        19250020
         BNE   IA005020       IF NOT INDEXED SEQUENTIAL, BRANCH         19320020
*                                  TO CHECK IF DIRECT.                  19390020
         MVC   INMSGIN1(IAINS004-IAINS003),IAINS003 MOVE FIRST          19460020
*                                  INSERTION RECORD TO PARAMETER        19530020
*                                  LIST.                                19600020
         B     IA005040       BRANCH TO SET UP DATA SET NAME.           19670020
IA005020 EQU   *                                                        19740020
         CLI   D0(DSORGREG),DS1ORGDA CHECK IF DIRECT ORGANIZATION.      19810020
         BNE   IA005030       IF NOT DIRECT, BRANCH TO PUT              19880020
*                                  UNKNOWN DSORG INSERTION.             19950020
         MVC   INMSGIN1(IAINS003-IAINS002),IAINS002 MOVE FIRST          20020020
*                                  INSERTION RECORD TO PARAMETER        20090020
*                                  LIST.                                20160020
         B     IA005040       BRANCH TO SET UP DATA SET NAME.           20230020
IA005030 EQU   *                                                        20300020
         MVC   INMSGIN1(IAINS013-IAINS012),IAINS012 MOVE FIRST          20370020
*                                  INSERTION RECORD TO PARAMETER        20440020
*                                  LIST.                                20510020
IA005040 EQU   *                                                        20580020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION PARAMETER          20650020
*                                  LIST FOR FIRST LEVEL MESSAGE.        20720020
         LA    LEV1REG,CADSNPTR ADDRESS OF DSNAME INSERTION TO          20790020
         ST    LEV1REG,INPTIN1     PARAMETER LIST.                      20860020
         LA    LEV1REG,M330IN2 OBTAIN OFFSET IN MESSAGE TO DSNAME       20930020
         STH   LEV1REG,CADSNOFF    INSERTION AND SAVE.                  21000020
         LA    LEV1REG,M330   RELATIVE MESSAGE TO BE PUT TO THE         21070020
*                                  TERMINAL.                            21140020
         LA    LEV2REG,M3301  RELATIVE SECOND LEVEL MESSAGE             21210020
*                                  NUMBER.                              21280020
         SR    INS2REG,INS2REG SHOW NO INSERTIONS REQUIRED IN           21350020
*                                  SECOND LEVEL MESSAGE.                21420020
         ST    INS2REG,CADSNPTR SHOW NO MORE THAN TWO INSERTIONS        21490020
*                                  ARE REQUIRED IN MESSAGE.             21560020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  21630020
         EJECT                                                          21700020
*********************************************************************** 21750020
*                                                                       21760020
*    MESSAGE ID -- IKJ52331I                                            21762020
*                                                                       21764020
*    CONDITION(S) --                                                    21766020
*                                                                       21768020
*         THE EDIT DATA SET HAS A RECORD FORMAT OTHER THAN F, V, FB,    21768420
*         OR VB.                                                        21768820
*                                                                       21769220
*    PARAMETER FORMAT --                                                21769620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               21769720
*         WORD 2 - MESSAGE INDEX = 16                                   21769820
*         WORD 3 - NOT USED                                             21769920
*         WORD 4 - ADDRESS OF RECFM FIELD IN FORMAT 1 DSCB              21793220
*         WORD 5 - NOT USED                                             21803220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    21813220
*                                                                       21815220
*********************************************************************** 21815620
IA006010 EQU   *                                                        21816720
         L     INS1REG,D12(,PLISTREG) ADDRESS RECFM BYTE.               21840020
         LA    INS2REG,D1     COUNT OF CHARACTERS = 1.                  21910020
         TM    D0(INS1REG),DS1FMUDF CHECK FOR UNDEFINED LRECL.          21980020
         BNO   IA006015       IF VARIABLE OR FIXED, BRANCH TO           22050020
*                                  PROCESS.                             22120020
         MVI   ININS1,IAFMU   MOVE 'U' TO INSERTION.                    22190020
         TM    D0(INS1REG),DS1FMOVF CHECK FOR TRACK OVERFLOW.           22260020
         BZ    IA006040       IF NO TRACK OVERFLOW, BRANCH              22330020
*                                  TO CHECK FOR CONTROL                 22400020
*                                  CHARACTERS.                          22470020
         MVI   ININS1+D1,IAFMT MOVE 'T' TO INSERTION.                   22540020
         LA    INS2REG,D2     COUNT OF CHARACTERS = 2.                  22610020
         B     IA006040       BRANCH TO CHECK FOR CONTROL               22680020
*                                  CHARACTERS.                          22750020
IA006015 EQU   *                                                        22820020
         TM    D0(INS1REG),DS1FMFX CHECK FOR FIXED FORMAT.              22890020
         BZ    IA006020       IF NOT FIXED, BRANCH TO MOVE 'V'          22960020
*                                  TO INSERTION.                        23030020
         MVI   ININS1,IAFMF   MOVE 'F' TO INSERTION.                    23100020
         B     IA006030       BRANCH TO CONTINUE.                       23170020
IA006020 EQU   *                                                        23240020
         MVI   ININS1,IAFMV   MOVE 'V' TO INSERTION.                    23310020
IA006030 EQU   *                                                        23380020
         IC    LEV1REG,D0(,INS1REG) ACQUIRE RECFM FIELD FROM DSCB.      23450020
         N     LEV1REG,IAFMMASK INSURE ALL BITS ZERO EXCEPT             23520020
*                                  B,S, AND T BITS.                     23590020
         BZ    IA006040       IF NONE OF THE 3 BITS ARE 1,              23660020
*                                  BRANCH TO CHECK CONTROL              23730020
*                                  CHARACTERS.                          23800020
         SRL   LEV1REG,D1     SHIFT RESULT FOR INDEXING.                23870020
         SR    LEV2REG,LEV2REG ZERO REGISTER.                           23940020
         IC    LEV2REG,IAFMTAB(LEV1REG) ACQUIRE LENGTH FOR MOVE.        24010020
         LA    LEV1REG,IAFMTAB+D1(LEV1REG) ADDRESS OF DATA TO           24080020
*                                  BE MOVED.                            24150020
         EX    LEV2REG,IAMVC012 MOVE DATA TO INSERTION RECORD.          24220020
         LA    INS2REG,D1(LEV2REG,INS2REG) UPDATE INSERTION             24290020
*                                  LENGTH.                              24360020
IA006040 EQU   *                                                        24430020
         LA    LEV2REG,ININS1(INS2REG) COMPUTE ADDRESS FOR              24500020
*                                  NEXT INSERTION CHARACTER.            24570020
         TM    D0(INS1REG),DS1FMA+DS1FMM CHECK FOR CONTROL              24640020
*                                  CHARACTER FORMAT.                    24710020
         BZ    IA006070       IF NO CONTROL CHARACTERS,                 24780020
*                                  BRANCH TO FINISH PARAMETERS.         24850020
         TM    D0(INS1REG),DS1FMA CHECK FOR ASA CONTROL.                24920020
         BZ    IA006050       IF NOT, ASSUME MACHINE CONTROL.           24990020
         MVI   D0(LEV2REG),IAFMA IF SO, MOVE 'A' TO INSERTION.          25060020
         B     IA006060       BRANCH TO UPDATE INSERTION LENGTH.        25130020
IA006050 EQU   *                                                        25200020
         MVI   D0(LEV2REG),IAFMM MOVE 'M' TO INSERTION.                 25270020
IA006060 EQU   *                                                        25340020
         LA    INS2REG,D1(,INS2REG) UPDATE INSERTION LENGTH.            25410020
IA006070 EQU   *                                                        25480020
         LA    INS2REG,D4(,INS2REG) ADD 4 TO INSERTION LENGTH           25550020
*                                  FOR CONTROL WORD.                    25620020
         STH   INS2REG,INLNIN1 STORE LENGTH IN INSERTION LIST.          25690020
         LA    INS2REG,M331IN1 OBTAIN OFFSET FOR INSERTION.             25760020
         STH   INS2REG,INOFFIN1 STORE OFFSET INTO LIST.                 25830020
         SR    INS2REG,INS2REG SPECIFY NO LEVEL-2 INSERTIONS.           25900020
         LR    LEV2REG,INS2REG SPECIFY NO LEVEL-2 MESSAGE.              25970020
         ST    LEV2REG,INPTIN1 SPECIFY ONE FIRST-LEVEL INSERTION.       26040020
         LA    INS1REG,INPTIN1 ADDRESS OF FIRST-LEVEL INSERTION.        26110020
         LA    LEV1REG,M331   RELATIVE FIRST-LEVEL MESSAGE.             26180020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  26250020
         EJECT                                                          26320020
*********************************************************************** 26370020
*                                                                       26380020
*    MESSAGE ID -- IKJ52336I                                            26390020
*                                                                       26440020
*    CONDITION(S) --                                                    26450020
*                                                                       26452020
*         THE LOGICAL RECORD LENGTH OF THE DATA SET SPECIFIED IS        26454020
*         INVALID FOR THE DATA SET TYPE SPECIFIED.                      26456020
*                                                                       26458020
*    PARAMETER FORMAT --                                                26458420
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               26458820
*         WORD 2 - MESSAGE INDEX = 20                                   26459220
*         WORD 3 - NOT USED                                             26459620
*         WORD 4 - FULLWORD BINARY LOGICAL RECORD LENGTH                26459720
*         WORD 5 - NOT USED                                             26459820
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    26459920
*                                                                       26483220
*********************************************************************** 26493220
IA007010 EQU   *                                                        26506720
         L     PARMREG1,D12(,PLISTREG) OBTAIN LRECL FOR MESSAGE.        26530020
         LA    LEV2REG,INMSGIN1 ADDRESS OF INSERTION RECORD.            26600020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT LRECL TO             26670020
*                                  EBCDIC AND SUPPRESS LEADING          26740020
*                                  ZEROES.                              26810020
         LA    INS1REG,M336IN1 OBTAIN OFFSET TO INSERTION TEXT          26880020
         STH   INS1REG,INOFFIN1    AND SAVE IN PARAMETER LIST.          26950020
         MVC   INMSGIN2(IAINS008-IAINS007),IAINS007 CREATE SECOND       27020020
         MVC   ININS2(L'CADSTYPE),CADSTYPE INSERTION RECORD (DATA       27090020
*                                  SET TYPE) FOR MESSAGE.               27160020
         LA    INS1REG,M336IN2 OBTAIN OFFSET TO INSERTION TEXT          27230020
         STH   INS1REG,INOFFIN2    AND SAVE IN PARAMETER LIST.          27300020
         LA    INS1REG,INMSGIN2 OBTAIN ADDRESS OF SECOND                27370020
         ST    INS1REG,INPTIN1     INSERTION RECORD AND SAVE IN         27440020
*                                  PARAMETER LIST.                      27510020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            27580020
*                                  BLANKS FROM DATA SET TYPE.           27650020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LIST.              27720020
         LA    LEV1REG,M336   RELATIVE MESSAGE TO BE PUT TO THE         27790020
*                                  TERMINAL.                            27860020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL OR             27930020
         SR    INS2REG,INS2REG     INSERTION IS REQUIRED.               28000020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  28070020
         EJECT                                                          28140020
*********************************************************************** 28190020
*                                                                       28200020
*    MESSAGE ID -- IKJ52307I                                            28202020
*                                                                       28204020
*    CONDITION(S) --                                                    28206020
*                                                                       28208020
*         THE DATA SET NAME SPECIFIED COULD NOT BE FOUND IN THE         28208420
*         CATALOG AND 'OLD' WAS SPECIFIED ON THE EDIT COMMAND.          28208820
*                                                                       28209220
*    PARAMETER FORMAT --                                                28209620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               28209720
*         WORD 2 - MESSAGE INDEX = 24                                   28209820
*         WORD 3 - NOT USED                                             28209920
*         WORD 4 - NOT USED                                             28233220
*         WORD 5 - NOT USED                                             28243220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    28253220
*                                                                       28255220
*********************************************************************** 28255620
IA008010 EQU   *                                                        28256720
         LA    INS1REG,CADSNPTR ADDRESS OF INSERTION PARAMETER          28280020
*                                  LIST.                                28350020
         LA    LEV1REG,M307IN1 OBTAIN OFFSET IN FIRST LEVEL             28420020
         STH   LEV1REG,CADSNOFF    MESSAGE FOR DATA SET NAME            28490020
*                                  INSERTION AND SAVE IN                28560020
*                                  PARAMETER LIST.                      28630020
         LA    LEV1REG,M307   RELATIVE MESSAGE TO BE PUT TO THE         28700020
*                                  TERMINAL.                            28770020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE             28840020
*                                  IS REQUIRED.                         28910020
         SR    INS2REG,INS2REG SHOW NO INSERTIONS REQUIRED IN           28980020
*                                  SECOND LEVEL MESSAGE.                29050020
         ST    LEV2REG,CADSNPTR SHOW ONLY ONE INSERTION IN THIS         29120020
*                                  MESSAGE.                             29190020
         B     IA020001        BRANCH TO CALL IKJEBEMS.                 29260020
         EJECT                                                          29330020
*********************************************************************** 29380020
*                                                                       29390020
*    MESSAGE ID -- IKJ52335I                                            29392020
*                                                                       29394020
*    CONDITION(S) --                                                    29396020
*                                                                       29398020
*        A. THE LINE VALUE SPECIFIED FOR A NEW DATA SET IS -            29398420
*           (1) OTHER THAN 80 WHEN 80 IS REQUIRED    OR-                29398820
*           (2) GREATER THAN THE MAXIMUM LRECL FOR THE DATA SET TYPE    29399220
*           SPECIFIED.                                                  29399620
*                                                                       29399720
*        B. THE LRECL OF AN OLD DATA SET IS ZERO.                       29399820
*                                                                       29405620
*    PARAMETER FORMAT --                                                29411620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               29417420
*         WORD 2 - MESSAGE INDEX=28                                     29419420
*         WORD 3 - SECOND-LEVEL RELATIVE MESSAGE NUMBER                 29433220
*         WORD 4 - FULLWORD BINARY VALUE OF QUANTITY TO BE USED AS      29443220
*                  LINE VALUE                                           29443620
*         WORD 5 - NOT USED                                             29445220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    29445620
*                                                                       29446020
*********************************************************************** 29446420
IA009010 EQU   *                                                        29446720
         MVC   ININS1(L'CADSTYPE),CADSTYPE BUILD DATA SET TYPE          29470020
         MVC   ININS3(L'CADSTYPE),CADSTYPE INSERTIONS FOR FIRST         29540020
*                                  AND SECOND LEVEL MESSAGES.           29610020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION RECORD.            29680020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            29750020
*                                  BLANKS.                              29820020
         LA    INS1REG,M335IN1 OBTAIN OFFSET TO INSERTION AND           29890020
         STH   INS1REG,INOFFIN1    SAVE IN PARAMETER LIST.              29960020
         LA    INS1REG,INMSGIN3 ADDRESS OF INSERTION RECORD.            30030020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            30100020
*                                  BLANKS.                              30170020
         L     PARMREG1,D12(,PLISTREG) LRECL TO BE USED BY EDIT.        30240020
         LA    LEV2REG,INMSGIN2 ADDRESS OF INSERTION RECORD.            30310020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT LRECL TO             30380020
*                                  EBCDIC AND SUPPRESS LEADING          30450020
*                                  ZEROES.                              30520020
         ST    LEV2REG,INPTIN1 CHAIN LINE VALUE TO DATA SET TYPE.       30590020
         LA    LEV2REG,M335IN2 OBTAIN OFFSET TO INSERTION AND           30660020
         STH   LEV2REG,INOFFIN2    SAVE IN PARAMETER LIST.              30730020
         CLI   D11(PLISTREG),M3353 DETERMINE IF LRECL IN DSCB IS ZERO.  30780020
         BE    IA009040       IF SO, BRANCH TO COMPLETE MESSAGE         30790020
*                                  PARAMETERS.                          30792020
         TM    CADSATTR,CALRECLX CHECK IF LRECL MUST BE 80              30800020
         BO    IA009020       IF 80 REQUIRED, BRANCH TO COMPLETE        30870020
*                                  MESSAGE.                             30940020
         LH    PARMREG1,CAFLRLMX MAXIMUM LRECL PERMITTED FOR DATA       31010020
*                                  SET TYPE.                            31080020
         LA    LEV2REG,INMSGIN4 ADDRESS OF INSERTION RECORD.            31150020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT LRECL TO             31220020
*                                  EBCDIC AND SUPPRESS LEADING          31290020
*                                  ZEROES.                              31360020
         ST    LEV2REG,INPTIN3     INSERTION AND SAVE.                  31430020
         LA    LEV2REG,M3352IN1 OBTAIN OFFSET TO DATA SET TYPE          31500020
         STH   LEV2REG,INOFFIN3    INSERTION AND SAVE.                  31570020
         LA    LEV2REG,M3352IN2 OBTAIN OFFSET TO INSERTION AND          31640020
         STH   LEV2REG,INOFFIN4    SAVE IN PARAMETER LIST.              31710020
         LA    LEV2REG,M3352  RELATIVE SECOND LEVEL MESSAGE.            31780020
         B     IA009030       BRANCH TO COMPLETE PARAMETER LIST.        31850020
IA009020 EQU   *                                                        31920020
         LA    LEV2REG,M3351IN1 OBTAIN OFFSET TO DATA SET TYPE          31990020
         STH   LEV2REG,INOFFIN3    INSERTION AND SAVE.                  32060020
         LA    LEV2REG,M3351  RELATIVE SECOND LEVEL MESSAGE.            32130020
IA009030 EQU   *                                                        32200020
         LA    LEV1REG,M335   RELATIVE MESSAGE TO BE PUT TO THE         32270020
*                                  TERMINAL.                            32340020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LISTS FOR          32410020
         LA    INS2REG,INMSGIN3    FIRST AND SECOND LEVEL MESSAGE       32480020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  32550020
IA009040 EQU   *                                                        32600020
         LA    LEV1REG,M335   RELATIVE MESSAGE TO BE PUT TO THE         32610020
*                                  TERMINAL.                            32612020
         LA    LEV2REG,M3353  SECOND-LEVEL RELATIVE MESSAGE NUMBER.     32614020
         LA    INS1REG,INMSGIN1 ADDRESS OF FIRST-LEVEL INSERTIONS.      32616020
         SR    INS2REG,INS2REG SPECIFY NO SECOND-LEVEL INSERTIONS.      32618020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  32618420
         EJECT                                                          32620020
*********************************************************************** 32670020
*                                                                       32680020
*    MESSAGE ID -- IKJ52333I                                            32682020
*                                                                       32684020
*    CONDITION(S) --                                                    32686020
*                                                                       32688020
*         THE BLOCK VALUE ENTERED FOR A NEW DATA SET IS INVALID.        32688420
*                                                                       32688820
*    PARAMETER FORMAT --                                                32689220
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               32689620
*         WORD 2 - MESSAGE INDEX = 32                                   32689720
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 32689820
*         WORD 4 - FULLWORD BINARY BLOCK SIZE                           32689920
*         WORD 5 - NOT USED                                             32713220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    32723220
*                                                                       32733220
*********************************************************************** 32735220
IA010010 EQU   *                                                        32736720
         L     PARMREG1,D12(,PLISTREG) OBTAIN BLOCK VALUE FOR           32760020
*                                  MESSAGE.                             32830020
         LA    LEV2REG,INMSGIN1 ADDRESS OF INSERTION RECORD.            32900020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT TO EBCDIC            32970020
*                                  AND SUPPRESS LEADING ZEROES.         33040020
         LR    INS1REG,LEV2REG ADDRESS OF INSERTION RECORD.             33110020
         LA    LEV2REG,M333IN1 OBTAIN OFFSET TO INSERTION AND           33180020
         STH   LEV2REG,INOFFIN1    DEFAULT BLKSIZE INSERTION            33250020
         LA    LEV1REG,M333   RELATIVE FIRST LEVEL MESSAGE TO BE        33320020
*                                  PUT TO THE TERMINAL.                 33390020
         L     LEV2REG,D8(,PLISTREG) RELATIVE SECOND LEVEL              33460020
*                                  MESSAGE NUMBER.                      33530020
         SR    INS2REG,INS2REG SHOW NO INSERTION REQUIRED IN            33600020
*                                  SECOND LEVEL MESSAGE.                33670020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  33740020
         EJECT                                                          33810020
*********************************************************************** 33860020
*                                                                       33870020
*    MESSAGE ID -- IKJ52363I                                            33872020
*    MESSAGE ID -- IKJ52364I                                            33874020
*                                                                       33876020
*    CONDITION(S) --                                                    33878020
*                                                                       33878420
*         (1) 'SCAN' HAS BEEN SPECIFIED FOR A DATA SET TYPE HAVING      33878820
*             NO ASSOCIATED LANGUAGE PROCESSOR     OR                   33879220
*                                                                       33879620
*         (2) 'SCAN' HAS BEEN SPECIFIED BUT THE ASSOCIATED LANGUAGE     33879720
*             PROCESSOR IS NOT IN THE SYSTEM                            33879820
*                                                                       33879920
*    PARAMETER FORMAT --                                                33903220
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               33913220
*         WORD 2 - MESSAGE INDEX = 36                                   33923220
*         WORD 3 - NOT USED                                             33925220
*         WORD 4 - NOT USED                                             33925620
*         WORD 5 - NOT USED                                             33926020
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    33926420
*                                                                       33926520
*********************************************************************** 33926620
IA011010 EQU   *                                                        33926720
         MVC   INPTIN2(IAINS008-IAINS007),IAINS007 CREATE DATA          33950020
         MVC   ININS2(L'CADSTYPE),CADSTYPE SET TYPE INSERTION           34020020
*                                  RECORD FOR MESSAGE.                  34090020
         LA    INS1REG,M363IN2 OBTAIN OFFSET TO DATA SET TYPE.          34160020
         STH   INS1REG,INOFFIN2    AND PLACE IN PARAMETER LIST.         34230020
         LA    INS1REG,INMSGIN2 ADDRESS OF INSERTION RECORD FOR         34300020
*                                  FIRST LEVEL MESSAGE.                 34370020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            34440020
*                                  BLANKS FROM DATA SET TYPE.           34510020
         MVC   INMSGIN1(IAINS006-IAINS005),IAINS005 MOVE                34580020
*                                  INSERTION TO WORK AREA.              34650020
         ST    INS1REG,INPTIN1 CHAIN INSERTION RECORDS.                 34720020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION CHAIN.             34790020
         TM    CADSATTR,CASCAN CHECK IF SYNTAX CHECKING ALLOWED.        34860020
         BO    IA011020       IF ALLOWED, BRANCH TO COMPLETE            34930020
*                                  MESSAGE.                             35000020
         LA    LEV1REG,M363   RELATIVE MESSAGE TO BE PUT TO THE         35070020
*                                  TERMINAL.                            35140020
         B     IA011030       BRANCH TO CALL IKJEBEMS.                  35210020
IA011020 EQU   *                                                        35280020
         LA    LEV1REG,M364   RELATIVE MESSAGE TO BE PUT TO THE         35350020
*                                  TERMINAL.                            35420020
         LA    LEV2REG,M3641  RELATIVE SECOND LEVEL MESSAGE.            35490020
         LA    INS2REG,M364IN2 OBTAIN OFFSET TO DATA SET TYPE           35560020
         STH   INS2REG,INOFFIN2    AND PLACE IN PARAMETER LIST.         35630020
         B     IA011040       BRANCH TO CALL IKJEBEMS.                  35700020
IA011030 EQU   *                                                        35770020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        35840020
IA011040 EQU   *                                                        35910020
         SR    INS2REG,INS2REG     OR INSERTION REQUIRED.               35980020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  36050020
         EJECT                                                          36120020
*********************************************************************** 36170020
*                                                                       36180020
*    MESSAGE ID -- IKJ52362I                                            36182020
*                                                                       36184020
*    CONDITION(S) --                                                    36186020
*                                                                       36188020
*         'NONUM' HAS BEEN SPECIFIED FOR A DATA SET TYPE THAT           36188420
*         REQUIRES THE DATA SET TO BE LINE NUMBERED.                    36188820
*                                                                       36189220
*    PARAMETER FORMAT --                                                36189620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               36189720
*         WORD 2 - MESSAGE INDEX = 40                                   36189820
*         WORD 3 - NOT USED                                             36189920
*         WORD 4 - NOT USED                                             36213220
*         WORD 5 - NOT USED                                             36223220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    36233220
*                                                                       36235220
*********************************************************************** 36235620
IA012010 EQU   *                                                        36236720
         MVC   INPTIN1(IAINS008-IAINS007),IAINS007 CREATE DATA          36260020
         MVC   ININS1(L'CADSTYPE),CADSTYPE SET TYPE INSERTION           36330020
*                                  RECORD FOR MESSAGE.                  36400020
         LA    LEV1REG,M362   RELATIVE MESSAGE TO BE PUT TO THE         36470020
*                                  TERMINAL.                            36540020
         LA    INS1REG,M362IN1 OBTAIN OFFSET FOR DATA SET TYPE          36610020
         STH   INS1REG,INOFFIN1    AND PLACE IN PARAMETER LIST.         36680020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION RECORD FOR         36750020
*                                  FIRST LEVEL MESSAGE.                 36820020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            36890020
*                                  BLANKS FROM DATA SET TYPE.           36960020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        37030020
         SR    INS2REG,INS2REG     OR INSERTION REQUIRED.               37100020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  37170020
         EJECT                                                          37240020
*********************************************************************** 37290020
*                                                                       37300020
*    MESSAGE ID -- IKJ52365I                                            37302020
*                                                                       37304020
*    CONDITION(S) --                                                    37306020
*                                                                       37308020
*         THE SOURCE MARGINS SPECIFIED FOR A PLI OR PLIF DATA SET       37308420
*         ARE INVALID.                                                  37308820
*                                                                       37309220
*    PARAMETER FORMAT --                                                37309620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               37309720
*         WORD 2 - MESSAGE INDEX = 44                                   37309820
*         WORD 3 - NOT USED                                             37309920
*         WORD 4 - MARGIN INSERTIONS                                    37333220
*              FIRST HALFWORD - LEFT MARGIN (DECIMAL)                   37343220
*              SECOND HALFWORD - RIGHT MARGIN (DECIMAL)                 37353220
*         WORD 5 - NOT USED                                             37355220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    37355620
*                                                                       37356020
*********************************************************************** 37356420
IA013010 EQU   *                                                        37356720
         LH    PARMREG1,D12(,PLISTREG) OBTAIN START POSITION FOR        37380020
*                                  MESSAGE.                             37450020
         LA    LEV2REG,INMSGIN1 ADDRESS OF INSERTION RECORD.            37520020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT TO EBCDIC            37590020
*                                  AND SUPPRESS LEADING ZEROES.         37660020
         LA    LEV2REG,M365IN1 OBTAIN OFFSET TO INSERTION AND           37730020
         STH   LEV2REG,INOFFIN1    SAVE IN PARAMETER LIST.              37800020
         LH    PARMREG1,D14(,PLISTREG) OBTAIN LENGTH FOR MESSAGE.       37870020
         LTR   PARMREG1,PARMREG1 CHECK IF LENGTH ENTERED.               37940020
         BZ    IA013020       IF NOT ENTERED, BRANCH TO COMPLETE        38010020
*                                  PARAMETER LIST.                      38080020
         LA    LEV2REG,INMSGIN2 ADDRESS OF INSERTION RECORD.            38150020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT TO EBCDIC.           38220020
*                                  AND SUPPRESS LEADING ZEROES.         38290020
         ST    LEV2REG,INPTIN1 CHAIN INSERTION RECORDS.                 38360020
         LA    LEV2REG,M365IN2 OBTAIN OFFSET TO INSERTION AND           38430020
         STH   LEV2REG,INOFFIN2    SAVE IN PARAMETER LIST.              38500020
IA013020 EQU   *                                                        38570020
         LA    LEV1REG,M365   RELATIVE MESSAGE TO BE PUT TO THE         38640020
*                                  TERMINAL.                            38710020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LIST FOR           38780020
*                                  FIRST LEVEL MESSAGE.                 38850020
         LA    LEV2REG,M3651  RELATIVE SECOND LEVEL MESSAGE.            38920020
         SR    INS2REG,INS2REG SHOW NO INSERTION REQUIRED IN            38990020
*                                  SECOND LEVEL MESSAGE.                39060020
         B     IA020001       BRANCH TO PUT MESSAGE.                    39130020
         EJECT                                                          39200020
*********************************************************************** 39250020
*                                                                       39260020
*    MESSAGE ID -- IKJ52360I                                            39262020
*                                                                       39264020
*    CONDITION(S) --                                                    39266020
*                                                                       39268020
*         INVALID SUBFIELD OPERANDS APPEAR ON THE 'NUM' OPERAND         39268420
*         OF THE COMMAND.                                               39268820
*                                                                       39269220
*    PARAMETER FORMAT --                                                39269620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               39269720
*         WORD 2 - MESSAGE INDEX = 48                                   39269820
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 39269920
*         WORD 4 - NOT USED                                             39293220
*         WORD 5 - NOT USED                                             39303220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    39313220
*                                                                       39315220
*********************************************************************** 39315620
IA014010 EQU   *                                                        39316720
         SR    PARMREG1,PARMREG1 OBTAIN START POSITION FOR              39340020
         IC    PARMREG1,CALINE     MESSAGE.                             39410020
         LA    LEV2REG,INMSGIN1 ADDRESS OF INSERTION RECORD.            39480020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT TO EBCDIC            39550020
*                                  AND SUPPRESS LEADING ZEROES.         39620020
         LA    LEV2REG,M360IN1 OBTAIN OFFSET TO INSERTION AND           39690020
         STH   LEV2REG,INOFFIN1    SAVE IN PARAMETER LIST.              39760020
         SR    PARMREG1,PARMREG1 OBTAIN LINE NUMBER LENGTH FOR          39830020
         IC    PARMREG1,CALENGTH   MESSAGE.                             39900020
         LA    LEV2REG,INMSGIN2 ADDRESS OF INSERTION RECORD.            39970020
         BAL   SRRTNREG,IA100000 BRANCH TO CONVERT TO EBCDIC.           40040020
*                                  AND SUPPRESS LEADING ZEROES.         40110020
         ST    LEV2REG,INPTIN1 CHAIN INSERTION RECORDS.                 40180020
         LA    LEV2REG,M360IN2 OBTAIN OFFSET TO INSERTION AND           40250020
         STH   LEV2REG,INOFFIN2    SAVE IN PARAMETER LIST.              40320020
         LA    LEV1REG,M360   RELATIVE MESSAGE TO BE PUT TO THE         40460020
*                                  TERMINAL.                            40530020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LIST FOR           40600020
*                                  FIRST LEVEL MESSAGE.                 40670020
         L     LEV2REG,D8(,PLISTREG) RELATIVE SECOND LEVEL NUMBER       40740020
         SR    INS2REG,INS2REG SHOW NO INSERTION REQUIRED IN            40810020
*                                  SECOND LEVEL MESSAGE.                40880020
         B     IA020001       BRANCH TO PUT MESSAGE.                    40950020
         EJECT                                                          41020020
*********************************************************************** 41070020
*                                                                       41080020
*    MESSAGE ID -- IKJ52361I                                            41082020
*                                                                       41084020
*    CONDITION(S) --                                                    41086020
*                                                                       41088020
*         'CAPS' ARE REQUIRED FOR THE DATA SET TYPE BEING EDITED        41088420
*         BUT THE 'ASIS' KEYWORD HAS BEEN ENTERED ON THE COMMAND.       41088820
*                                                                       41089220
*    PARAMETER FORMAT --                                                41089620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               41089720
*         WORD 2 - MESSAGE INDEX = 52                                   41089820
*         WORD 3 - NOT USED                                             41089920
*         WORD 4 - NOT USED                                             41113220
*         WORD 5 - NOT USED                                             41123220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    41133220
*                                                                       41135220
*********************************************************************** 41135620
IA015010 EQU   *                                                        41136720
         MVC   INPTIN1(IAINS008-IAINS007),IAINS007 CREATE DATA          41160020
         MVC   ININS1(L'CADSTYPE),CADSTYPE SET TYPE INSERTION           41230020
*                                  RECORD FOR MESSAGE.                  41300020
         LA    LEV1REG,M361   RELATIVE MESSAGE TO BE PUT TO THE         41370020
*                                  TERMINAL.                            41440020
         LA    INS1REG,M361IN1 OBTAIN OFFSET FOR DATA SET TYPE.         41510020
         STH   INS1REG,INOFFIN1    AND PLACE IN PARAMETER LIST.         41580020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION RECORD FOR         41650020
*                                  FIRST LEVEL MESSAGE.                 41720020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            41790020
*                                  BLANKS FROM DATA SET TYPE.           41860020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        41930020
         SR    INS2REG,INS2REG     OR INSERTION REQUIRED.               42000020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  42070020
         EJECT                                                          42140020
*********************************************************************** 42190020
*                                                                       42200020
*    MESSAGE ID -- IKJ52424I                                            42202020
*                                                                       42204020
*    CONDITION(S) --                                                    42206020
*                                                                       42208020
*         ONE OF THE FOLLOWING HAS OCCURRED -                           42208420
*           (1) THE DDNAME RETURNED BY IKJDAIR COULD NOT BE LOCATED     42208820
*               IN THE TIOT.                                            42209220
*           (2) A CATALOG OR DYNAMIC ALLOCATION ERROR OCCURRED          42209620
*               WHEN IKJDAIR WAS INVOKED TO UNALLOCATE A PDS.           42209720
*                                                                       42209820
*    PARAMETER FORMAT --                                                42209920
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               42233220
*         WORD 2 - MESSAGE INDEX = 56                                   42243220
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 42253220
*         WORD 4 - NOT USED                                             42255220
*         WORD 5 - RIGHT-JUSTIFIED DARC OR CTRC FIELD                   42255620
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    42256020
*                                                                       42256420
*********************************************************************** 42256520
IA016010 EQU   *                                                        42256720
         CLI   D11(PLISTREG),M4245 CHECK IF DDNAME NOT FOUND IN         42280020
*                                  TIOT.                                42350020
         BNE   IA016020       IF NOT, BRANCH TO PROCESS FOR             42420020
*                                  UNALLOCATION ERROR.                  42490020
         MVC   INMSGIN1(D8),IAINS015 MOVE INSERTION CONTROL             42560020
*                                  INFORMATION.                         42630020
         MVC   ININS1(D8),CAEDDDN MOVE DDNAME TO INSERTION              42700020
*                                  RECORD.                              42770020
         LA    INS1REG,INMSGIN1 ADDRESS INSERTION LIST.                 42840020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            42910020
*                                  BLANKS.                              42980020
         B     IA016060       BRANCH TO COMPLETE PARAMETERS.            43050020
IA016020 EQU   *                                                        43120020
         SR    INS2REG,INS2REG SPECIFY DARC OR CTRC AS LAST             43190020
         ST    INS2REG,INPTIN2     SECOND-LEVEL INSERTION.              43260020
         LA    INS2REG,D16(,PLISTREG) ADDRESS DARC OR CTRC FIELD.       43330020
         LA    LEV2REG,INMSGIN2 ADDRESS SECOND INSERTION LIST.          43400020
         BAL   SRRTNREG,IA100010 BRANCH TO FORMAT INSERTION.            43470020
         CLI   D11(PLISTREG),M4242 CHECK IF DYNAMIC ALLOCATION          43540020
*                                  ERROR.                               43610020
         BNE   IA016030       IF NOT, BRANCH TO PROCESS CATALOG         43680020
*                                  ERROR INSERTION.                     43750020
         LA    INS2REG,M4242IN2 SET OFFSET FOR DARC INSERTION.          43820020
         LA    INS1REG,M4242IN1 SET OFFSET FOR DSNAME INSERTION.        43890020
         B     IA016040       BRANCH TO CONTINUE PROCESSING.            43960020
IA016030 EQU   *                                                        44030020
         LA    INS1REG,M4244IN1 SET OFFSET FOR DSNAME INSERTION.        44100020
         LA    INS2REG,M4244IN2 SET OFFSET FOR CTRC INSERTION.          44170020
IA016040 EQU   *                                                        44240020
         STH   INS2REG,INOFFIN2 STORE OFFSET FOR SECOND INSERTION.      44310020
         STH   INS1REG,CADSNOFF STORE OFFSET FOR DSNAME INSERTION.      44380020
         LA    INS2REG,INMSGIN2                                         44450020
         ST    INS2REG,CADSNPTR CHAIN INSERTION LISTS.                  44520020
         MVC   INMSGIN1(D8),CADSNPTR MOVE CONTROL PORTION OF            44590020
*                                  INSERTION RECORD.                    44660020
         CLI   CADSNREC,INSNGLQT IS INSERTION FULLY QUALIFIED.          44730020
         BNE   IA016050       IF NOT, BRANCH TO APPEND USERID           44800020
*                                  AND ENCLOSE IN QUOTES.               44870020
         MVC   ININS1(D56),CADSNREC MOVE DATA SET NAME, ASSUMING        44940020
*                                  MAXIMUM LENGTH.                      45010020
         B     IA016060       BRANCH TO COMPLETE MESSAGE                45080020
*                                  PARAMETERS.                          45150020
IA016050 EQU   *                                                        45220020
         L     PASSREG,CAPTTMP ADDRESS COMMAND PARAMETER LIST.          45290020
         L     PASSREG,CPPLPSCB-CPPL(,PASSREG) ADDRESS PSCB.            45360020
         SR    INS1REG,INS1REG                                          45430020
         IC    INS1REG,PSCBUSRL-PSCB(,PASSREG) GET USERID LENGTH.       45500020
         MVI   ININS1,INSNGLQT APPEND QUOTE TO INSERTION RECORD.        45570020
         EX    INS1REG,IAMVC011  MOVE USERID TO INSERTION RECORD.       45640020
         LA    DSNAMREG,ININS1(INS1REG) COMPUTE ADDRESS FOR MOVE        45710020
*                                  OF DSNAME.                           45780020
         MVI   D1(DSNAMREG),INPERIOD MOVE PERIOD AFTER USERID.          45850020
         MVC   D2(D56,DSNAMREG),CADSNREC MOVE DSNAME.                   45920020
         LA    INS1REG,D3(,INS1REG) COMPUTE INCREMENT TO DSNAME         45990020
*                                  LENGTH.                              46060020
         AH    INS1REG,CADSNLEN ADD LENGTH OF UNFORMATTED DSNAME.       46130020
         STH   INS1REG,INLNIN1 UPDATE LENGTH IN INSERTION RECORD.       46200020
         LA    INS1REG,ININS1-D5(INS1REG) COMPUTE POSITION OF           46270020
*                                  FINAL QUOTE.                         46340020
         MVI   D0(INS1REG),INSNGLQT MOVE FINAL QUOTE.                   46410020
IA016060 EQU   *                                                        46480020
         LA    LEV1REG,M424   SET RELATIVE FIRST-LEVEL NUMBER.          46550020
         L     LEV2REG,D8(,PLISTREG) SET SECOND-LEVEL NUMBER.           46620020
         SR    INS1REG,INS1REG SPECIFY NO FIRST-LEVEL INSERTIONS.       46690020
         LA    INS2REG,INMSGIN1 ADDRESS FIRST LEVEL-2 INSERTION.        46760020
         B     IA020001       BRANCH TO CALL IKJEBEMS TO PUT            46830020
*                                  MESSAGE TO TERMINAL.                 46900020
         EJECT                                                          46970020
*********************************************************************** 47020020
*                                                                       47030020
*    MESSAGE ID -- IKJ52334I                                            47032020
*                                                                       47034020
*    CONDITION(S) --                                                    47036020
*                                                                       47038020
*         'LINE' AND/OR 'BLOCK' OPERANDS HAVE BEEN SPECIFIED FOR        47038420
*         AN OLD DATA SET WHICH IS NOT EMPTY.                           47038820
*                                                                       47039220
*    PARAMETER FORMAT --                                                47039620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               47039720
*         WORD 2 - MESSAGE INDEX = 60                                   47039820
*         WORD 3 - NOT USED                                             47039920
*         WORD 4 - ADDRESS OF FORMATTED INSERTION LIST                  47063220
*         WORD 5 - NOT USED                                             47073220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    47083220
*                                                                       47085220
*********************************************************************** 47085620
IA017010 EQU   *                                                        47086720
         LA    LEV1REG,M334   RELATIVE MESSAGE TO BE PUT TO THE         47110020
*                                  TERMINAL.                            47180020
         L     INS1REG,D12(,PLISTREG) ADDRESS OF INSERTION FOR          47250020
*                                  MESSAGE.                             47320020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE OR          47390020
         SR    INS2REG,INS2REG     INSERTION REQUIRED.                  47460020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  47530020
         EJECT                                                          47600020
*********************************************************************** 47650020
*                                                                       47660020
*    MESSAGE ID -- IKJ52342I                                            47662020
*                                                                       47664020
*    CONDITION(S) --                                                    47666020
*                                                                       47668020
*         THE LINE VALUE SPECIFIED OR LRECL ENCOUNTERED IS TOO SMALL    47668420
*         TO PERMIT LINE NUMBERING.                                     47668820
*                                                                       47669220
*    PARAMETER FORMAT --                                                47669620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               47669720
*         WORD 2 - MESSAGE INDEX = 64                                   47669820
*         WORD 3 - NOT USED                                             47669920
*         WORD 4 - NOT USED                                             47693220
*         WORD 5 - NOT USED                                             47703220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    47713220
*                                                                       47715220
*********************************************************************** 47715620
IA018010 EQU   *                                                        47716720
         LA    LEV1REG,M342   RELATIVE MESSAGE TO BE PUT TO THE         47740020
*                                  TERMINAL.                            47810020
         LA    LEV2REG,M3421  RELATIVE SECOND LEVEL MESSAGE             47880020
*                                  NUMBER.                              47950020
         SR    INS1REG,INS1REG SHOW NO INSERTION REQUIRED IN            48020020
         SR    INS2REG,INS2REG     EITHER MESSAGE.                      48090020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  48160020
         EJECT                                                          48230020
*********************************************************************** 48280020
*                                                                       48290020
*    MESSAGE ID -- IKJ52308I                                            48292020
*                                                                       48294020
*    CONDITION(S) --                                                    48296020
*                                                                       48298020
*         THE MEMBER SPECIFIED ON THE COMMAND DOES NOT EXIST AND        48298420
*         THE USER SPECIFIED 'OLD'.                                     48298820
*                                                                       48299220
*    PARAMETER FORMAT --                                                48299620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               48299720
*         WORD 2 - MESSAGE INDEX = 68                                   48299820
*         WORD 3 - NOT USED                                             48299920
*         WORD 4 - LENGTH OF MEMBER NAME FOR INSERTION                  48323220
*         WORD 5 - NOT USED                                             48333220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    48343220
*                                                                       48345220
*********************************************************************** 48345620
IA019010 EQU   *                                                        48346720
         LA    LEV1REG,M308   RELATIVE MESSAGE TO BE PUT TO THE         48370020
*                                  TERMINAL.                            48440020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION LIST FOR           48510020
*                                  FIRST LEVEL MESSAGE.                 48580020
         L     INS2REG,D12(,PLISTREG) OBTAIN LENGTH OF MEMBER           48650020
         BCTR  INS2REG,D0          NAME, REDUCE BY 1, AND MOVE TO       48720020
         EX    INS2REG,IAMVC006    INSERTION RECORD.                    48790020
         LA    INS2REG,D5(,INS2REG) COMPUTE LENGTH OF INSERTION         48860020
         STH   INS2REG,INLNIN1     AND SAVE IN PARAMETER LIST.          48930020
         LA    INS2REG,M308IN1 OBTAIN OFFSET TO MEMBER INSERTION        49000020
         STH   INS2REG,INOFFIN1    AND SAVE IN PARAMETER LIST.          49070020
         CLC   CAEDMEMB(D8),IAMEMNAM CHECK FOR MEMBER NAME OF           49120020
*                                  'TEMPNAME'.                          49130020
         BE    IA019050       IF 'TEMPNAME' DEFAULTED, BYPASS           49132020
*                                  STRIPPING MEMBER FROM DSNAME         49134020
*                                  INSERTION.                           49136020
         LA    INS2REG,CADSNPTR+D3 ADDRESS LAST CHARACTER OF            49140020
         AH    INS2REG,CADSNLEN    INSERTION RECORD FOR DSNAME.         49210020
         LA    COUNTREG,D10(,D0) SET COUNTER TO 1 LESS THAN             49280020
*                                  MAXIMUM NUMBER OF CHARACTERS         49350020
*                                  TO BE REMOVED FROM INSERTION.        49420020
IA019020 EQU   *                                                        49490020
         CLI   D0(INS2REG),INLFTPRN IS CHARACTER A LEFT                 49560020
*                                  PARENTHESIS.                         49630020
         BE    IA019030       IF SO, BRANCH TO PROCESS.                 49700020
         BCTR  INS2REG,D0     IF NOT, ADDRESS NEXT BYTE TO LEFT.        49770020
         BCT   COUNTREG,IA019020 REPEAT LOOP 10 TIMES.                  49840020
         B     IA019050       IF NO MEMBER FOUND, BRANCH                49890020
*                                  TO USE DSNAME INSERTION AS           49900020
*                                  IT EXISTS.                           49902020
IA019030 EQU   *                                                        49910020
         LA    INS2REG,D11(,D0) COMPUTE NUMBER OF CHARACTERS TO         49980020
         SR    COUNTREG,INS2REG    BE REMOVED. (RESULT IS NEG.)         50050020
         AH    COUNTREG,CADSNLEN COMPUTE NEW LENGTH FOR INSERTION.      50120020
         CLI   CADSNREC,INSNGLQT IS INSERTION TO BE ENCLOSED IN         50190020
*                                  QUOTES.                              50260020
         BNE   IA019040       IF NOT,BRANCH TO SET UP REMAINING         50330020
*                                  PARAMETERS.                          50400020
         LA    INS2REG,CADSNLEN(COUNTREG) ADDRESS BYTE FOLOWING         50470020
*                                  INSERTION RECORD.                    50540020
         MVI   D0(INS2REG),INSNGLQT MOVE SINGLE QUOTE TO END OF         50610020
*                                  DSNAME.                              50680020
         LA    COUNTREG,D1(,COUNTREG) INCREMENT INSERTION LENGTH        50750020
*                                  BY ONE.                              50820020
IA019040 EQU   *                                                        50890020
         STH   COUNTREG,CADSNLEN UPDATE INSERTION LENGTH.               50960020
IA019050 EQU   *                                                        51010020
         LA    INS2REG,CADSNPTR OBTAIN ADDRESS OF DSNAME AND SAVE       51030020
         ST    INS2REG,INPTIN1     IN PARAMETER LIST.                   51100020
         LA    INS2REG,M308IN2 OBTAIN OFFSET TO DSNAME INSERTION        51170020
         STH   INS2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          51240020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE OR          51310020
         SR    INS2REG,INS2REG     INSERTION REQUIRED.                  51380020
         ST    INS2REG,CADSNPTR SHOW ONLY TWO INSERTIONS REQUIRED       51450020
*                                  IN THIS MESSAGE.                     51520020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  51590020
         EJECT                                                          51660020
*********************************************************************** 51710020
*                                                                       51720020
*    MESSAGE ID -- IKJ52332I                                            51722020
*                                                                       51724020
*    CONDITION(S) --                                                    51726020
*                                                                       51728020
*         THE EDIT DATA SET HAS RECORD FORMAT OF V OR VB.  EDIT         51728420
*         ACCEPTS ONLY FIXED-LENGTH RECORDS FOR THE DATA SET TYPE       51728820
*         SPECIFIED.                                                    51729220
*                                                                       51729620
*    PARAMETER FORMAT --                                                51729720
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               51729820
*         WORD 2 - MESSAGE INDEX = 72                                   51729920
*         WORD 3 - NOT USED                                             51753220
*         WORD 4 - NOT USED                                             51763220
*         WORD 5 - NOT USED                                             51773220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    51775220
*                                                                       51775620
*********************************************************************** 51776020
IA021010 EQU   *                                                        51776720
         LA    LEV1REG,M332   RELATIVE MESSAGE TO BE PUT TO THE         51800020
*                                  TERMINAL.                            51870020
         MVC   INPTIN1(IAINS008-IAINS007),IAINS007 BUILD BASIC          51940020
*                                  INSERTION RECORD FOR DATA SET        52010020
*                                  TYPE.                                52080020
         LA    INS1REG,M332IN1 OBTAIN OFFSET TO INSERTION AND           52150020
         STH   INS1REG,INOFFIN1    SAVE IN PARAMETER LIST.              52220020
         MVC   ININS1(L'CADSTYPE),CADSTYPE MOVE DATA SET TYPE TO        52290020
*                                  INSERTION RECORD.                    52360020
         LA    INS1REG,INMSGIN1 ADDRESS OF INSERTION CHAIN FOR          52430020
*                                  FIRST LEVEL MESSAGE.                 52500020
         BAL   SRRTNREG,IA110010 BRANCH TO SUPPRESS TRAILING            52570020
*                                  BLANKS.                              52640020
         SR    LEV2REG,LEV2REG SHOW NO SECOND LEVEL MESSAGE OR          52710020
         SR    INS2REG,INS2REG     INSERTION REQUIRED.                  52780020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  52850020
         EJECT                                                          52920020
*********************************************************************** 52970020
*                                                                       52980020
*    MESSAGE ID -- IKJ52306I                                            52982020
*                                                                       52984020
*    CONDITION(S) --                                                    52986020
*                                                                       52988020
*         THE DATA SET SPECIFIED ON THE COMMAND IS ALLOCATED            52988420
*         TO ANOTHER USER OR JOB.                                       52988820
*                                                                       52989220
*    PARAMETER FORMAT --                                                52989620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               52989720
*         WORD 2 - MESSAGE INDEX = 76                                   52989820
*         WORD 3 - NOT USED                                             52989920
*         WORD 4 - NOT USED                                             53013220
*         WORD 5 - NOT USED                                             53023220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    53033220
*                                                                       53035220
*********************************************************************** 53035620
IA022010 EQU   *                                                        53036720
         LA    LEV1REG,M306   RELATIVE MESSAGE TO BE PUT TO THE         53060020
*                                  TERMINAL.                            53130020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        53200020
*                                  RECORD.                              53270020
         LA    LEV2REG,M306IN1 OBTAIN OFFSET TO DSNAME INSERTION        53340020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          53410020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       53480020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              53550020
         LA    LEV2REG,M3061  RELATIVE SECOND LEVEL MESSAGE             53620020
*                                  NUMBER.                              53690020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  53760020
         EJECT                                                          53830020
*********************************************************************** 53880020
*                                                                       53890020
*    MESSAGE ID -- IKJ52309I                                            53892020
*                                                                       53894020
*    CONDITION(S) --                                                    53896020
*                                                                       53898020
*         THE DCB FOR A PARTITIONED DATA SET COULD NOT BE OPENED.       53898420
*                                                                       53898820
*    PARAMETER FORMAT --                                                53899220
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               53899620
*         WORD 2 - MESSAGE INDEX = 80                                   53899720
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 53899820
*         WORD 4 - NOT USED                                             53899920
*         WORD 5 - NOT USED                                             53923220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    53933220
*                                                                       53943220
*********************************************************************** 53945220
IA023010 EQU   *                                                        53946720
         LA    LEV1REG,M309   RELATIVE MESSAGE TO BE PUT TO THE         54040020
*                                  TERMINAL.                            54110020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        54180020
*                                  RECORD.                              54250020
         LA    LEV2REG,M309IN1 OBTAIN OFFSET TO DSNAME INSERTION        54320020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          54390020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       54460020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              54530020
         L     LEV2REG,D8(,PLISTREG) OBTAIN RELATIVE SECOND LEVEL       54600020
         SR    INS2REG,INS2REG     NUMBER AND SHOW NO INSERTIONS.       54670020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  54740020
         EJECT                                                          54810020
*********************************************************************** 54860020
*                                                                       54870020
*    MESSAGE ID -- IKJ52301I                                            54872020
*                                                                       54874020
*    CONDITION(S) --                                                    54876020
*                                                                       54878020
*         THE DATA SET SPECIFIED ON THE EDIT COMMAND CANNOT BE          54878420
*         ALLOCATED BECAUSE THE TIOT IS FILLED.                         54878820
*                                                                       54879220
*    PARAMETER FORMAT --                                                54879620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               54879720
*         WORD 2 - MESSAGE INDEX = 84                                   54879820
*         WORD 3 - NOT USED                                             54879920
*         WORD 4 - NOT USED                                             54903220
*         WORD 5 - NOT USED                                             54913220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    54923220
*                                                                       54925220
*********************************************************************** 54925620
IA024010 EQU   *                                                        54926720
         LA    LEV1REG,M301   RELATIVE MESSAGE TO BE PUT TO THE         54950020
*                                  TERMINAL.                            55020020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        55090020
*                                  RECORD.                              55160020
         LA    LEV2REG,M301IN1 OBTAIN OFFSET TO DSNAME INSERTION        55230020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          55300020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       55370020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              55440020
         LA    LEV2REG,M3011  RELATIVE SECOND LEVEL MESSAGE             55510020
*                                  NUMBER.                              55580020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  55650020
         EJECT                                                          55720020
*********************************************************************** 55770020
*                                                                       55780020
*    MESSAGE ID -- IKJ52303I                                            55782020
*                                                                       55784020
*    CONDITION(S) --                                                    55786020
*                                                                       55788020
*         A REQUIRED VOLUME OR CONTROL VOLUME IS NOT MOUNTED ON         55788420
*         THE SYSTEM.                                                   55788820
*                                                                       55789220
*    PARAMETER FORMAT --                                                55789620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               55789720
*         WORD 2 - MESSAGE INDEX = 88                                   55789820
*         WORD 3 - NOT USED                                             55789920
*         WORD 4 - NOT USED                                             55813220
*         WORD 5 - NOT USED                                             55823220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    55833220
*                                                                       55835220
*********************************************************************** 55835620
IA025010 EQU   *                                                        55836720
         LA    LEV1REG,M303   RELATIVE MESSAGE TO BE PUT TO THE         55860020
*                                  TERMINAL.                            55930020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        56000020
*                                  RECORD.                              56070020
         LA    LEV2REG,M303IN1 OBTAIN OFFSET TO DSNAME INSERTION        56140020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          56210020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       56280020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              56350020
         LA    LEV2REG,M3031  RELATIVE SECOND LEVEL MESSAGE             56420020
*                                  NUMBER.                              56490020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  56560020
         EJECT                                                          56630020
*********************************************************************** 56680020
*                                                                       56690020
*    MESSAGE ID -- IKJ52302I                                            56692020
*                                                                       56694020
*    CONDITION(S) --                                                    56696020
*                                                                       56698020
*         THE EDIT DATA SET DOES NOT RESIDE ON THE VOLUME SPECIFIED     56698420
*         IN THE CATALOG.                                               56698820
*                                                                       56699220
*    PARAMETER FORMAT --                                                56699620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               56699720
*         WORD 2 - MESSAGE INDEX = 92                                   56699820
*         WORD 3 - NOT USED                                             56699920
*         WORD 4 - NOT USED                                             56723220
*         WORD 5 - NOT USED                                             56733220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    56743220
*                                                                       56745220
*********************************************************************** 56745620
IA026010 EQU   *                                                        56746720
         LA    LEV1REG,M302   RELATIVE MESSAGE TO BE PUT TO THE         56770020
*                                  TERMINAL.                            56840020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        56910020
*                                  RECORD.                              56980020
         LA    LEV2REG,M302IN1 OBTAIN OFFSET TO DSNAME INSERTION        57050020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          57120020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       57190020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              57260020
         LA    LEV2REG,M3021  RELATIVE SECOND LEVEL MESSAGE             57330020
*                                  NUMBER.                              57400020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  57470020
         EJECT                                                          57540020
*********************************************************************** 57590020
*                                                                       57600020
*    MESSAGE ID -- IKJ52304I                                            57602020
*                                                                       57604020
*    CONDITION(S) --                                                    57606020
*                                                                       57608020
*         A CATALOG MANAGEMENT ERROR, DYNAMIC ALLOCATION ERROR,         57608420
*         OR CATALOG I/O ERROR HAS OCCURRED.                            57608820
*                                                                       57609220
*    PARAMETER FORMAT --                                                57609620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               57609720
*         WORD 2 - MESSAGE INDEX = 96                                   57609820
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 57609920
*         WORD 4 - NOT USED                                             57633220
*         WORD 5 - RIGHT-JUSTIFIED DARC OR CTRC FIELD                   57643220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    57653220
*                                                                       57655220
*********************************************************************** 57655620
IA027010 EQU   *                                                        57656720
         LA    LEV1REG,M304   RELATIVE MESSAGE TO BE PUT TO THE         57680020
*                                  TERMINAL.                            57750020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        57820020
*                                  RECORD.                              57890020
         LA    LEV2REG,M304IN1 OBTAIN OFFSET TO DSNAME INSERTION        57960020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          58030020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       58100020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              58170020
         CLI   D11(PLISTREG),M3043 CHECK FOR CATALOG I/O ERROR.         58240020
         BE    IA027030       IF SO, BRANCH TO FINISH PARAMETERS.       58310020
         LA    INS2REG,D16(,PLISTREG) OBTAIN RETURN CODE FOR            58380020
*                                  CONVERSION.                          58450020
         LA    LEV2REG,INMSGIN1 ADDRESS OF AREA FOR CONVERSION.         58520020
         BAL   SRRTNREG,IA100010 BRANCH TO CONVERT RETURN CODE TO       58590020
*                                  PRINTABLE HEXADECIMAL.               58660020
         LR    INS2REG,LEV2REG ADDRESS OF INSERTION LIST FOR            58730020
*                                  SECOND LEVEL MESSAGE.                58800020
         SR    LEV2REG,LEV2REG INDICATE ONLY 1 INSERTION IN             58870020
         ST    LEV2REG,INPTIN1     SECOND LEVEL MESSAGE.                58940020
         CLI   D11(PLISTREG),M3041 DETERMINE IF FIRST SECOND            59010020
*                                  LEVEL MESSAGE REQUESTED.             59080020
         BNE   IA027020       IF NOT, BRANCH TO SET OFFSET FOR          59150020
*                                  SECOND SECOND LEVEL MESSAGE.         59220020
         LA    LEV2REG,M3041IN1 OBTAIN OFFSET TO INSERTION AND          59290020
         STH   LEV2REG,INOFFIN1    SAVE IN PARAMETER LIST.              59360020
         B     IA027030       BRANCH TO SET UP SECOND LEVEL             59430020
*                                  MESSAGE.                             59500020
IA027020 EQU   *                                                        59570020
         LA    LEV2REG,M3042IN1 OBTAIN OFFSET TO INSERTION AND          59640020
         STH   LEV2REG,INOFFIN1    SAVE IN PARAMETER LIST.              59710020
IA027030 EQU   *                                                        59780020
         L     LEV2REG,D8(,PLISTREG) RELATIVE SECOND LEVEL              59850020
*                                  MESSAGE NUMBER.                      59920020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  59990020
         EJECT                                                          60060020
*********************************************************************** 60110020
*                                                                       60120020
*    MESSAGE ID -- IKJ52317I                                            60122020
*                                                                       60124020
*    CONDITION(S) --                                                    60126020
*                                                                       60128020
*         THE DATA SET SPECIFIED ON THE COMMAND DOES NOT RESIDE         60128420
*         ON A DIRECT ACCESS VOLUME.                                    60128820
*                                                                       60129220
*    PARAMETER FORMAT --                                                60129620
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               60129720
*         WORD 2 - MESSAGE INDEX = 100                                  60129820
*         WORD 3 - NOT USED                                             60129920
*         WORD 4 - NOT USED                                             60153220
*         WORD 5 - NOT USED                                             60163220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    60173220
*                                                                       60175220
*********************************************************************** 60175620
IA028010 EQU   *                                                        60176720
         LA    LEV1REG,M317   RELATIVE MESSAGE TO BE PUT TO THE         60200020
*                                  TERMINAL.                            60270020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST LEVEL INSERTION        60340020
*                                  RECORD.                              60410020
         LA    LEV2REG,M317IN1 OBTAIN OFFSET TO DSNAME INSERTION        60480020
         STH   LEV2REG,CADSNOFF    AND SAVE IN PARAMETER LIST.          60550020
         SR    INS2REG,INS2REG INDICATE ONLY 1 INSERTION REQUIRED       60620020
         ST    INS2REG,CADSNPTR    IN FIRST LEVEL MESSAGE.              60690020
         LR    LEV2REG,INS2REG INDICATE NO SECOND-LEVEL MESSAGE.        60760020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  60830020
         EJECT                                                          60880020
*********************************************************************** 60890020
*                                                                       60892020
*    MESSAGE ID -- IKJ52310I                                            60894020
*                                                                       60896020
*    CONDITION(S) --                                                    60898020
*                                                                       60898420
*         WHEN FULLY QUALIFIED, THE PARTIALLY QUALIFIED DATA SET        60898820
*         NAME ENTERED ON THE EDIT COMMAND EXCEEDS 44 CHARACTERS.       60899220
*                                                                       60899620
*    PARAMETER FORMAT --                                                60899720
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               60899820
*         WORD 2 - MESSAGE INDEX = 104                                  60899920
*         WORD 3 - NOT USED                                             60923220
*         WORD 4 - NOT USED                                             60933220
*         WORD 5 - NOT USED                                             60943220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    60945220
*                                                                       60945620
*********************************************************************** 60946020
IA029010 EQU   *                                                        60946720
         LA    DSNAMREG,INDSNREC ADDRESS TEXT FIELD OF DSNAME           60970020
*                                  INSERTION RECORD.                    61040020
         MVI   D0(DSNAMREG),INSNGLQT MOVE SINGLE QUOTE TO FIRST         61110020
*                                  CHARACTER POSITION.                  61180020
         L     TMPREG,CAPTTMP ADDRESS COMMAND PARAMETER LIST.           61250020
         L     PASSREG,CPPLPSCB-CPPL(,TMPREG) ADDRESS PROTECTED         61320020
*                                  STEP CONTROL BLOCK.                  61390020
         SR    LENREG,LENREG  ZERO LENGTH.                              61460020
         IC    LENREG,PSCBUSRL-PSCB(,PASSREG) SET LENGTH OF             61530020
*                                  USERID.                              61600020
         LR    COUNTREG,LENREG ESTABLISH LENGTH COUNTER FOR             61670020
*                                  INSERTION.                           61740020
         BCTR  LENREG,D0      ADJUST USERID LENGTH FOR MVC.             61810020
         EX    LENREG,IAMVC007 MOVE USERID TO INSERTION RECORD.         61880020
         LA    DSNAMREG,D2(DSNAMREG,LENREG) UPDATE FIELD ADDRESS.       61950020
         MVI   D0(DSNAMREG),INPERIOD MOVE '.' TO INSERTION              62020020
*                                  RECORD.                              62090020
         LH    LENREG,CAEDDSNL SET USER-SUPPLIED NAME LENGTH.           62160020
         AR    COUNTREG,LENREG UPDATE LENGTH COUNTER.                   62230020
         BCTR  LENREG,D0      ADJUST USER-SUPPLIED NAME LENGTH.         62300020
         EX    LENREG,IAMVC008 MOVE USER-SUPPLIED NAME.                 62370020
         LA    DSNAMREG,D2(DSNAMREG,LENREG) UPDATE FIELD ADDRESS.       62440020
         MVI   D0(DSNAMREG),INPERIOD MOVE '.' TO INSERTION RECORD.      62510020
         LA    RETREG,CADSQUAL+D7 COMPARES BEGIN AT LAST                62580020
*                                  CHARACTER IN QUALIFIER FIELD.        62650020
         LA    EPLOCREG,D7    SET LOOP COUNTER.                         62720020
IA029020 EQU   *                                                        62790020
         CLI   D0(RETREG),CHRBLANK IS CHARACTER A BLANK -               62860020
         BNE   IA029030       IF NOT, BRANCH TO MOVE QUALIFIER.         62930020
         BCTR  RETREG,D0      ADDRESS NEXT BYTE TO LEFT.                63000020
         BCT   EPLOCREG,IA029020 REPEAT LOOP SEVEN TIMES.               63070020
IA029030 EQU   *                                                        63140020
         EX    EPLOCREG,IAMVC009 MOVE QUALIFIER TO INSERTION            63210020
*                                  RECORD.                              63280020
         LA    DSNAMREG,D2(EPLOCREG,DSNAMREG) UPDATE FIELD              63350020
*                                  ADDRESS.                             63420020
         MVI   D0(DSNAMREG),INSNGLQT MOVE SINGLE QUOTE TO               63490020
*                                  INSERTION RECORD.                    63560020
         LA    COUNTREG,D9(EPLOCREG,COUNTREG) UPDATE LENGTH COUNT       63630020
*                                  FOR INSERTION RECORD.                63700020
         STH   COUNTREG,INDSNLEN SET INSERTION LENGTH.                  63770020
         LA    LENREG,M310IN1 SET INSERTION OFFSET.                     63840020
         STH   LENREG,INDSNOFF                                          63910020
         LA    LEV1REG,M310   SET FIRST-LEVEL RELATIVE MESSAGE.         63980020
         SR    LEV2REG,LEV2REG SPECIFY NO SECOND-LEVEL MESSAGE.         64050020
         ST    LEV2REG,INDSNPTR SPECIFY ONE FIRST-LEVEL                 64120020
*                                  INSERTION ONLY.                      64190020
         LA    INS1REG,INDSNPTR SET FIRST-LEVEL INSERTION CHAIN         64260020
*                                  ADDRESS.                             64330020
         LR    INS2REG,LEV2REG SPECIFY NO SECOND-LEVEL INSERTIONS.      64400020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  64470020
         EJECT                                                          64520020
*********************************************************************** 64530020
*                                                                       64532020
*    MESSAGE ID -- IKJ52316I                                            64534020
*                                                                       64536020
*    CONDITION(S) --                                                    64538020
*                                                                       64538420
*         WHEN FULLY QUALIFIED, THE PARTIALLY QUALIFIED DATA SET        64538820
*         NAME ENTERED ON THE EDIT COMMAND IS INCOMPATIBLE WITH         64539220
*         AN EXISTING INDEX STRUCTURE IN THE CATALOG.                   64539620
*                                                                       64539720
*    PARAMETER FORMAT --                                                64539820
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               64539920
*         WORD 2 - MESSAGE INDEX = 108                                  64563220
*         WORD 3 - NOT USED                                             64573220
*         WORD 4 - NOT USED                                             64583220
*         WORD 5 - NOT USED                                             64585220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    64585620
*                                                                       64586020
*********************************************************************** 64586420
IA030010 EQU   *                                                        64586720
         BAL   SRRTNREG,IA100050 PROCESS DSNAME INSERTION.              64610020
         LA    DSNAMREG,M316IN1 SET OFFSET FOR INSERTION.               64680020
         STH   DSNAMREG,INDSNOFF                                        64750020
         LA    LEV1REG,M316   SPECIFY RELATIVE FIRST-LEVEL NO.          64820020
         LA    LEV2REG,M3161  SPECIFY RELATIVE SECOND-LEVEL NO.         64890020
         LA    INS1REG,INDSNPTR ADDRESS LEVEL-1 INSERTION.              64960020
         SR    INS2REG,INS2REG SPECIFY NO LEVEL TWO INSERTIONS.         65030020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  65100020
         EJECT                                                          65150020
*********************************************************************** 65160020
*                                                                       65162020
*    MESSAGE ID -- IKJ52314I                                            65164020
*                                                                       65166020
*    CONDITION(S) --                                                    65168020
*                                                                       65168420
*         THE EDIT DATA SET RESIDES ON MULTIPLE VOLUMES.  MULTIPLE      65168820
*         VOLUME DATA SETS ARE NOT SUPPORTED BY THE EDIT COMMAND.       65169220
*                                                                       65169620
*    PARAMETER FORMAT --                                                65169720
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               65169820
*         WORD 2 - MESSAGE INDEX = 112                                  65169920
*         WORD 3 - NOT USED                                             65193220
*         WORD 4 - NOT USED                                             65203220
*         WORD 5 - NOT USED                                             65213220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    65215220
*                                                                       65215620
*********************************************************************** 65216020
IA031010 EQU   *                                                        65216720
         LA    LEV1REG,M314   RELATIVE MESSAGE TO BE PUT TO THE         65240020
*                                  TERMINAL.                            65310020
         LA    INS1REG,M314IN1 OBTAIN OFFSET FOR DSNAME INSERTION.      65380020
         STH   INS1REG,CADSNOFF STORE IN INSERTION LIST.                65450020
         SR    LEV2REG,LEV2REG SPECIFY NO LEVEL-2 MESSAGE.              65520020
         ST    LEV2REG,CADSNPTR SPECIFY ONE INSERTION ONLY.             65590020
         LR    INS2REG,LEV2REG SPECIFY NO LEVEL-2 INSERTIONS.           65660020
         LA    INS1REG,CADSNPTR ADDRESS LEVEL-1 INSERTION.              65730020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  65800020
         EJECT                                                          65850020
*********************************************************************** 65860020
*                                                                       65862020
*    MESSAGE ID -- IKJ52315I                                            65864020
*                                                                       65866020
*    CONDITION(S) --                                                    65868020
*                                                                       65868420
*         THE DEFAULT SERVICE ROUTINE (IKJDFLT) HAS BEEN UNABLE TO      65868820
*         QUALIFY A DATA SET NAME DUE TO A SYSTEM ERROR.                65869220
*                                                                       65869620
*    PARAMETER FORMAT --                                                65869720
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               65869820
*         WORD 2 - MESSAGE INDEX = 116                                  65869920
*         WORD 3 - NOT USED                                             65893220
*         WORD 4 - NOT USED                                             65903220
*         WORD 5 - FULLWORD BINARY RETURN CODE FOR INSERTION            65913220
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    65915220
*                                                                       65915620
*********************************************************************** 65916020
IA032010 EQU   *                                                        65916720
         BAL   SRRTNREG,IA100050 PROCESS DSNAME INSERTION.              65940020
         LA    DSNAMREG,M315IN1 SET OFFSET IN INSERTION LIST.           66010020
         STH   DSNAMREG,INDSNOFF                                        66080020
         L     PARMREG1,D16(,PLISTREG) OBTAIN RETURN CODE               66150020
*                                  FOR CONVERSION.                      66220020
         BAL   EPLOCREG,IA032020 INSURE REGISTER NEGATIVE               66290020
*                                  FOR PROCESSING AS TWO-DIGIT          66360020
*                                  RETURN CODE.                         66430020
IA032020 EQU   *                                                        66500020
         LA    LEV2REG,INMSGIN2 ADDRESS OF AREA FOR CONVERSION.         66570020
         BAL   SRRTNREG,IA100003 BRANCH TO CONVERT RETURN CODE TO       66640020
*                                  PRINTABLE DECIMAL.                   66710020
         LR    INS2REG,LEV2REG SPECIFY LEVEL-2 INSERTION ADDRESS.       66780020
         LA    INS1REG,M3151IN1 SET OFFSET FOR CODE INSERTION.          66850020
         STH   INS1REG,INOFFIN2                                         66920020
         LA    LEV1REG,M315   SPECIFY RELATIVE FIRST-LEVEL NO.          66990020
         LA    LEV2REG,M3151  SPECIFY RELATIVE SECOND-LEVEL NO.         67060020
         LA    INS1REG,INDSNPTR ADDRESS LEVEL-ONE INSERTION.            67130020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  67200020
         EJECT                                                          67250020
*********************************************************************** 67260020
*                                                                       67262020
*    MESSAGE ID -- IKJ52343I                                            67264020
*                                                                       67266020
*    CONDITIONS --                                                      67268020
*                                                                       67268120
*    GOFORT(FREE) WAS SPECIFIED OR DEFAULTED AND --                     67268220
*         (1) LINE OPERAND WAS SPECIFIED FOR A NEW DATA SET OR          67268320
*         (2) RECORD FORMAT IS FIXED FOR AN OLD DATA SET                67280220
*    PARAMETER FORMAT --                                                67290220
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               67292220
*         WORD 2 - MESSAGE INDEX = 120                                  67292320
*         WORD 3 - NOT USED                                             67296320
*         WORD 4 - NOT USED                                             67298320
*         WORD 5 - NOT USED                                             67298720
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    67299120
*                                                                       67300320
*********************************************************************** 67304320
         SPACE 2                                                        67316220
IA033010 EQU   *                                                        67328120
         TM    CAEDFLAG,CAEDDISP DETERMINE IF DATA SET IS NEW.          67338120
         BZ    IA033020       IF SO, BRANCH TO SET UP SECOND-LEVEL      67338520
*                                  MESSAGE FOR NEW DATA SET.            67338920
         LA    LEV2REG,M3431  OTHERWISE, SET UP SECOND-LEVEL            67339320
*                                  MESSAGE FOR OLD DATA SET.            67339720
         B     IA033030            BRANCH TO COMPLETE PARAMETERS.       67339820
IA033020 EQU   *                                                        67339920
         LA    LEV2REG,M3432  SET UP SECOND-LEVEL MESSAGE FOR           67340020
*                                  NEW DATA SET.                        67390020
IA033030 EQU   *                                                        67392020
         LA    LEV1REG,M343   SPECIFY RELATIVE FIRST-LEVEL NUMBER.      67394020
         SR    INS1REG,INS1REG SPECIFY NO FIRST-LEVEL INSERTIONS.       67396020
         LR    INS2REG,INS1REG SPECIFY NO SECOND-LEVEL INSERTIONS.      67398020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  67398420
         EJECT                                                          67400020
*********************************************************************** 67410020
*                                                                       67460020
*    MESSAGE ID -- IKJ52318I                                            67470020
*                                                                       67480020
*    CONDITION(S) --                                                    67530020
*                                                                       67540020
*         ONE OF THE FOLLOWING HAS OCCURRED -                           67550020
*           (1) THE USER HAS AN INVALID UNIT NAME IN THE USER           67600020
*               ATTRIBUTE DATA SET (UADS).                              67610020
*           (2) NO UNIT IS AVAILABLE FOR DYNAMIC ALLOCATION.            67620020
*                                                                       67670020
* PARAMETER FORMAT --                                                   67680020
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA               67690020
*         WORD 2 - MESSAGE INDEX = 124                                  67740020
*         WORD 3 - RELATIVE SECOND-LEVEL MESSAGE NUMBER                 67750020
*         WORD 4 - NOT USED                                             67760020
*         WORD 5 - NOT USED                                             67810020
*         WORD 6 - ADDRESS OF THE IKJEBEIA WORK AREA                    67820020
*                                                                       67830020
*********************************************************************** 67880020
IA034010 EQU   *                                                        67900020
         L     LEV2REG,D8(,PLISTREG) RELATIVE SECOND-LEVEL              67970020
*                                  MESSAGE NUMBER.                      68040020
         LA    INS1REG,M318IN1 OBTAIN OFFSET FOR DSNAME.                68110020
         STH   INS1REG,CADSNOFF STORE IN INSERTION LIST.                68180020
         SR    INS2REG,INS2REG SPECIFY NO SECOND-LEVEL INSERTION.       68250020
         ST    INS2REG,CADSNPTR SPECIFY ONE FIRST-LEVEL INSERTION.      68320020
         LA    INS1REG,CADSNPTR ADDRESS OF FIRST-LEVEL INSERTION.       68390020
         LA    LEV1REG,M318   RELATIVE ERROR TO BE PUT TO THE           68460020
*                                  TERMINAL.                            68530020
         B     IA020001       BRANCH TO CALL IKJEBEMS.                  68600020
         EJECT                                                          68650021
**************************************************************** A45714 68660021
*                                                                A45714 68662021
*    MESSAGE ID -- IKJ52568I                                     A45714 68664021
*                                                                A45714 68666021
*    CONDITION(S) --                                             A45714 68668021
*                                                                A45714 68668421
*         DATA SET TYPE WAS NOT ENTERED ON THE EDIT COMMAND AND  A45714 68668821
*         THE USER HAS INVOKED EDIT WITHIN A PROCEDURE.  EDIT    A45714 68669221
*         IS UNABLE TO PROMPT THE USER FOR DATA SET TYPE.        A45714 68669621
*                                                                A45714 68669721
* PARAMETER FORMAT --                                            A45714 68669921
*         WORD 1 - ADDRESS OF THE EDIT COMMUNICATION AREA        A45714 68670021
*         WORD 2 - MESSAGE INDEX = 128                           A45714 68693221
*         WORDS 3-6 - NOT USED                                   A45714 68703221
*                                                                A45714 68713221
**************************************************************** A45714 68715221
IA035010 EQU   *                                                 A45714 68715621
         LA    LEV1REG,M568   RELATIVE ERROR TO BE PUT TO TERM.  A45714 68716021
         SR    LEV2REG,LEV2REG NO SECOND LEVEL MESSAGE.          A45714 68716421
         SR    INS1REG,INS1REG NO FIRST LEVEL INSERTIONS.        A45714 68716521
         SR    INS2REG,INS2REG NO SECOND LEVEL INSERTIONS.       A45714 68716621
         B     IA020001       BRANCH TO CALL IKJEBEMS.           A45714 68724421
         EJECT                                                          68732221
*********************************************************************** 68740020
*                                                                     * 68810020
*   INVOKE IKJEBEMS TO PUT THE MESSAGE TO THE TERMINAL USER.  UPON    * 68880020
*   RETURN FROM IKJEBEMS, RETURN TO THE CALLING ROUTINE.  REGISTER 15 * 68950020
*   ON EXIT FROM THIS ROUTINE WILL CONTAIN THE RETURN CODE PASSED     * 69020020
*   BACK BY IKJEBEMS.                                                 * 69090020
*                                                                     * 69160020
*********************************************************************** 69230020
IA020001 EQU   *                                                        69300020
         IKJEBEML (LEV1REG),(LEV2REG),(INS1REG),(INS2REG),             X69370020
               MF=(E,IAPRMLST) CALL IKJEBEMS.                           69440020
         SPACE 2                                                        69490020
IA020002 EQU   *                                                        69500020
         IKJEBERT (14,12),,RC=(15) RESTORE REGISTERS AND RETURN.        69510020
         EJECT                                                          69580020
*********************************************************************** 69630020
*                                                                       69640020
*    THE FOLLOWING SECTION IS EXECUTED FOR DECIMAL AND HEXADECIMAL      69642020
*    CONVERSIONS AND FORMATTING OF NUMERIC MESSAGE INSERTIONS.          69644020
*                                                                       69646020
*********************************************************************** 69648020
         SPACE 2                                                        69648420
IA100000 EQU   *                                                        69650020
         SR    EPLOCREG,EPLOCREG SPECIFY THAT INSERTION IS NOT A        69720020
*                                  RETURN CODE                          69790020
IA100003 EQU   *                                                        69860020
         CVD   PARMREG1,INDECBIN CONVERT DATA TO PACKED DECIMAL         69930020
         UNPK  D16(D10,LEV2REG),INDECBIN+D4(D5) AND TO EBCDIC.          70000020
         LTR   EPLOCREG,EPLOCREG DETERMINE IF INSERTION IS TO BE        70070020
*                                  PROCESSED AS 2-DIGIT CODE.           70140020
         BM    IA100005       IF SO, BRANCH TO PROCESS.                 70210020
         LTR   PARMREG1,PARMREG1 CHECK FOR NUMERIC INSERTION            70260020
*                                  EQUAL TO ZERO.                       70270020
         BNZ   IA100004       IF NOT ZERO, BRANCH TO PROCESS            70272020
*                                  LEADING ZEROES.                      70274020
         MVI   D8(LEV2REG),IACHRZRO MOVE CHARACTER ZERO TO              70276020
*                                  INSERTION LIST.                      70278020
         LA    INLENREG,D5    LENGTH OF INSERTION IS FIVE BYTES.        70278420
         B     IA100045       BRANCH TO COMPLETE INSERTION.             70278820
IA100004 EQU   *                                                        70279220
         LA    INS2REG,D16(,LEV2REG) ADDRESS OF CONVERTED DATA.         70280020
         LA    INLENREG,D8(,D0) SET COUNTER EQUAL TO DATA LENGTH.       70350020
         B     IA100020       BRANCH TO SUPPRESS LEADING ZEROES.        70420020
IA100005 EQU   *                                                        70490020
         LA    INS2REG,D22(,LEV2REG) ADDRESS OF CONVERTED DATA.         70560020
         LA    INLENREG,D1(,D0) TWO CHARACTER DIGITS TO BE MOVED.       70630020
         B     IA100040       BRANCH TO MOVE RC TO INSERTION.           70700020
IA100010 EQU   *                                                        70770020
         UNPK  D16(D9,LEV2REG),D0(D5,INS2REG) CONVERT DATA TO           70840020
         TR    D16(D8,LEV2REG),IATRNSTB-IACHRZRO PRINTABLE EBCDIC       70910020
         LA    INS2REG,D20(,LEV2REG) ADDRESS OF CONVERTED DATA.         70980020
         LA    INLENREG,D3(,D0) SET DATA LENGTH FOR MVC.                71050020
         B     IA100040       BRANCH TO MOVE 4-CHARACTER FIELD          71120020
*                                  TO INSERTION RECORD.                 71190020
IA100020 EQU   *                                                        71260020
         CLI   D0(INS2REG),IACHRZRO CHECK IF CHARACTER IS A ZERO.       71330020
         BNE   IA100030       IF NOT, BRANCH TO COMPLETE                71400020
*                                  INSERTION RECORD.                    71470020
         LA    INS2REG,D1(,INS2REG) UPDATE POINTER TO NEXT BYTE.        71540020
         BCT   INLENREG,IA100020   REDUCE COUNTER BY 1 AND BRANCH       71610020
*                             TO CHECK NEXT BYTE.                       71680020
IA100030 EQU   *                                                        71750020
         BCTR  INLENREG,D0    REDUCE COUNT BY ONE FOR MVC.              72030020
IA100040 EQU   *                                                        72100020
         EX    INLENREG,IAMVC005 MOVE DATA INTO INSERTION RECORD.       72170020
         LA    INLENREG,D5(,INLENREG) COMPUTE LENGTH OF INSERTION       72240020
*                                  RECORD.                              72310020
IA100045 EQU   *                                                        72360020
         XC    D0(D8,LEV2REG),D0(LEV2REG) ZERO CONTROL PORTION OF       72380020
*                             INSERTION RECORD.                         72450020
         STH   INLENREG,D4(,LEV2REG) SAVE LENGTH OF INSERTION           72520020
*                                  RECORD.                              72590020
         BR    SRRTNREG       RETURN TO CALLER.                         72660020
         EJECT                                                          72710020
*********************************************************************** 72720020
*                                                                       72722020
*    THE FOLLOWING SUBROUTINE IS EXECUTED TO PROCESS A PARTIALLY        72724020
*    QUALIFIED DATA SET NAME AS A MESSAGE INSERTION.                    72726020
*                                                                       72728020
*********************************************************************** 72728420
         SPACE 2                                                        72728820
IA100050 EQU   *                                                        72730020
         LA    DSNAMREG,CAEDDSN+D1 ADDRESS SECOND CHARACTER OF          72800020
*                                  DATA SET NAME.                       72870020
         LA    COUNTREG,D2    MINUMUM NUMBER OF CHARACTERS TO           72940020
*                                  BE STRIPPED IS TWO.                  73010020
IA100060 EQU   *                                                        73080020
         CLI   D0(DSNAMREG),INPERIOD CHECK FOR PERIOD FOLLOWING         73150020
*                                  USERID -                             73220020
         BE    IA100070       IF PERIOD ENCOUNTERED, BRANCH             73290020
*                             TO MOVE INSERTION TEXT.                   73360020
         LA    COUNTREG,D1(,COUNTREG) BUMP COUNT BY ONE.                73430020
         LA    DSNAMREG,D1(,DSNAMREG) ADDRESS NEXT CHARACTER            73500020
*                                  OF DSNAME.                           73570020
         B     IA100060       REPEAT LOOP UNTIL PERIOD FOUND.           73640020
IA100070 EQU   *                                                        73710020
         LH    LENREG,CAEDDSNL GET DSNAME LENGTH.                       73780020
         SR    LENREG,COUNTREG DETERMINE INSERTION TEXT LENGTH.         73850020
         BCTR  LENREG,D0      DECREMENT BY 1 FOR MVC.                   73920020
         EX    LENREG,IAMVC010 MOVE INSERTION TEXT TO INSERTION         73990020
*                                  RECORD.                              74060020
         LA    LENREG,D5(,LENREG) COMPUTE LENGTH FOR INSERTION          74130020
*                                  RECORD.                              74200020
         STH   LENREG,INDSNLEN SET LENGTH IN INSERTION RECORD.          74270020
         SR    LENREG,LENREG  SET INSERTION CHAIN WORD TO ZERO.         74340020
         ST    LENREG,INDSNPTR (THIS IS LAST MESSAGE INSERTION.)        74410020
         BR    SRRTNREG       RETURN TO MAINLINE ROUTINE.               74480020
         SPACE 5                                                        74550020
         EJECT                                                          74600020
*********************************************************************** 74610020
*    THE FOLLOWING SUBROUTINE IS EXECUTED TO STRIP TRAILING BLANKS      74612020
*    FROM MESSAGE INSERTIONS.                                           74614020
*                                                                       74616020
*                                                                       74618020
*********************************************************************** 74618420
         SPACE 2                                                        74618820
IA110010 EQU   *                                                        74620020
         LA    RETREG,D8(,D0) LOOP CONTROL COUNTER.                     74690020
         LA    EPLOCREG,D15(,INS1REG) ADDRESS OF LAST CHARACTER         74760020
*                                  IN DATA SET TYPE.                    74830020
IA110020 EQU   *                                                        74900020
         CLI   D0(EPLOCREG),IACHBLNK CHECK FOR BLANK.                   74970020
         BNE   IA110030       IF NOT A BLANK, ALL TRAILING BLANKS       75040020
*                                  HAVE BEEN SUPPRESSED.                75110020
         BCTR  EPLOCREG,D0    BACK POINTER UP ONE CHARACTER.            75180020
         BCT   RETREG,IA110020 REDUCE COUNTER BY ONE AND BRANCH         75250020
*                                  TO CHECK NEXT BYTE.                  75320020
IA110030 EQU   *                                                        75390020
         XC    D0(D4,INS1REG),D0(INS1REG) ZERO CONTROL FIELDS.          75460020
         LA    RETREG,D4(,RETREG) COMPUTE LENGTH OF INSERTION           75530020
         STH   RETREG,D4(,INS1REG) RECORD AND SAVE.                     75600020
         BR    SRRTNREG       RETURN TO CALLER.                         75670020
         EJECT                                                          75740020
*********************************************************************** 75810020
*                                                                     * 75880020
*   EQUATES USED BY THIS ROUTINE TO REFERENCE (1) RELATIVE FIRST      * 75950020
*   LEVEL MESSAGES, (2) RELATIVE SECOND LEVEL MESSAGES WITHIN FIRST   * 76020020
*   LEVEL MESSAGES, AND (3) OFFSETS TO INSERTIONS IN BOTH FIRST AND   * 76090020
*   SECOND LEVEL MESSAGES.                                            * 76160020
*                                                                     * 76230020
*********************************************************************** 76300020
         IKJEBEMI (301,302,303,304,305,306,307,308,309,310,311,312,    X76370020
               313,314,315,316,317,318,330,331,332,333,334,335,336,    X76440020
               342,343,360,361,362,363,364,365,424,568)          A45714 76510021
         EJECT                                                          76580020
*********************************************************************** 76650020
*                                                                     * 76720020
*   INSERTION RECORDS USED IN FIRST AND SECOND LEVEL MESSAGES.        * 76790020
*                                                                     * 76860020
*********************************************************************** 76930020
IAINS001 IKJEBEMG 0,M312IN1,'EDIT' COMMAND NAME FOR INSERTION IN       X77000020
                                   MESSAGE IKJ52382I.                   77070020
IAINS002 IKJEBEMG 0,M330IN1,'DIRECT' DSORG INSERTION IN MESSAGE        X77140020
                                   MESSAGE IKJ52502I.                   77210020
IAINS003 IKJEBEMG 0,M330IN1,'INDEXED SEQUENTIAL' DSORG INSERTION       X77280020
                                   IN MESSAGE IKJ52502I.                77350020
IAINS004 IKJEBEMG 0,M3131IN1,'OBTAIN SVC' SERVICE ROUTINE NAME         X77420020
                                   INSERTION.                           77490020
IAINS005 IKJEBEMG 0,M363IN1,'SCAN' INSERTION IN MESSAGE                X77560020
                                   IKJ52430I.                           77630020
IAINS006 EQU   *                                                        77700020
IAINS007 IKJEBEMG 0,M335IN1,'        ' DATA SET TYPE INSERTION         X77770020
                                   IN MESSAGE IKJ52430I.                77840020
IAINS008 IKJEBEMG 0,M3131IN1,'DEFAULT' SERVICE ROUTINE NAME            X77910020
                                   INSERTION.                           77980020
IAINS009 IKJEBEMG 0,M3131IN1,'DELETE SVC' SERVICE ROUTINE NAME         X78050020
                                   INSERTION.                           78120020
IAINS010 IKJEBEMG 0,M3131IN1,'DAIR' SERVICE ROUTINE NAME               X78190020
                                   INSERTION                            78260020
IAINS011 IKJEBEMG 0,M3131IN1,'PARSE' SERVICE ROUTINE NAME              X78330020
                                   INSERTION                            78400020
IAINS012 IKJEBEMG 0,M330IN1,'UNKNOWN' DSORG INSERTION.                  78470020
IAINS013 IKJEBEMG 0,M3131IN1,'DEVTYPE' SERVICE ROUTINE                 X78540020
                                   INSERTION.                           78610020
IAINS014 IKJEBEMG 0,M3131IN1,'PUTGET' SERVICE RTN INSERTION.     A45714 78680021
IAINS015 IKJEBEMG 0,M4245IN1,' ' DDNAME INSERTION IN MESSAGE           X78750020
                                   IKJ52424I.                           78820020
IATRNSTB DC    CL16'0123456789ABCDEF' TRANSLATE TABLE FOR               78890020
*                                  CONVERSION TO HEXADECIMAL.           78960020
IAMEMNAM DC    C'TEMPNAME'    CHARACTER CONSTANT USED TO DETERMINE      79010020
*                                  IF A MEMBER NAME WAS                 79020020
*                                  ENTERED ON THE EDIT COMMAND.         79022020
         EJECT                                                          79030020
*********************************************************************** 79100020
*                                                                     * 79170020
*   OTHER EQUATES, INSTRUCTIONS EXECUTED OUT OF SEQUENCE AND DATA     * 79240020
*   AREAS.                                                            * 79310020
*                                                                     * 79380020
*********************************************************************** 79450020
DS1ORGDA EQU   B'00100000'    DSCB DSORG = DIRECT.                      79520020
DS1ORGIS EQU   B'10000000'    DSCB DSORG = INDEXED SEQUENTIAL.          79590020
IAFMA    EQU   C'A'           ASA CONTROL FORMAT.                       79660020
IAFMF    EQU   C'F'           FIXED FORMAT.                             79730020
IAFMM    EQU   C'M'           MACHINE CONTROL FORMAT.                   79800020
IAFMT    EQU   C'T'           TRACK OVERFLOW FORMAT.                    79870020
IAFMU    EQU   C'U'           UNDEFINED FORMAT.                         79940020
IAFMV    EQU   C'V'           VARIABLE FORMAT.                          80010020
DS1FMFX  EQU   B'10000000'    DSCB RECFM = FIXED.                       80080020
DS1FMUDF EQU   B'11000000'    DSCB RECFM = UNDEFINED.                   80150020
DS1FMOVF EQU   B'00100000'    DSCB RECFM = TRACK OVERFLOW.              80220020
DS1FMA   EQU   B'00000100'    DSCB RECFM = ASA CONTROL CHARACTER.       80290020
DS1FMM   EQU   B'00000010'    DSCB RECFM = MACHINE CONTROL.             80360020
*                                  CHARACTER.                           80430020
X0       EQU   0              OFFSET ZERO.                              80500020
X4       EQU   4              OFFSET 4.                                 80570020
D0       EQU   0              OFFSET ZERO (DECIMAL).                    80780020
D1       EQU   1              OFFSET 1 (DECIMAL).                       80850020
D2       EQU   2              OFFSET 2 (DECIMAL).                       80920020
D3       EQU   3              OFFSET 3 (DECIMAL).                       80990020
D4       EQU   4              OFFSET 4 (DECIMAL).                       81060020
D5       EQU   5              OFFSET 5 (DECIMAL).                       81130020
D7       EQU   7              OFFSET 7 (DECIMAL).                       81200020
D8       EQU   8              OFFSET 8 (DECIMAL).                       81270020
D9       EQU   9              OFFSET 9 (DECIMAL).                       81340020
D10      EQU   10             OFFSET 10 (DECIMAL).                      81410020
D11      EQU   11             OFFSET 11 (DECIMAL).                      81480020
D12      EQU   12             OFFSET 12 (DECIMAL).                      81550020
D14      EQU   14             OFFSET 14 (DECIMAL).                      81620020
D15      EQU   15             OFFSET 15 (DECIMAL).                      81690020
D16      EQU   16             OFFSET 16 (DECIMAL).                      81760020
D20      EQU   20             OFFSET 20 (DECIMAL).                      81830020
D22      EQU   22             OFFSET 22 (DECIMAL).                      81900020
D56      EQU   56             OFFSET 56 (DECIMAL).                      81970020
IACHRZRO EQU   C'0'           CHARACTER ZERO.                           82040020
CHRBLANK EQU   C' '           CHARACTER BLANK.                          82110020
IACHBLNK EQU   C' '           CHARACTER BLANK.                          82180020
INSNGLQT EQU   C''''          SINGLE QUOTE.                             82250020
INPERIOD EQU   C'.'           PERIOD.                                   82320020
INLFTPRN EQU   C'('           LEFT PARENTHESIS.                         82390020
IAZEROES EQU   X'00'          USED TO ZERO A BYTE.                      82530020
IANORTN  EQU   X'00'          USED TO DETERMINE WHETHER THIS            82600020
*                                  ROUTINE MUST BUILD INSERTION         82670020
*                                  FOR COMMAND SYSTEM ERROR             82740020
*                                  MESSAGE.                             82810020
IADAIR   EQU   X'02'          INDICATOR FOR IKJDAIR SERVICE             83160020
*                                  ROUTINE.                             83230020
IADEVTYP EQU   X'03'          INDICATOR FOR DEVTYPE SERVICE             83300020
*                                  ROUTINE.                             83370020
IASVCOBT EQU   X'04'          INDICATOR FOR OBTAIN SVC.                 83440020
IADFAULT EQU   X'05'          INDICATOR FOR DEFAULT SERVICE             83510020
*                                  ROUTINE.                             83580020
IASVCDEL EQU   X'06'          INDICATOR FOR DELETE SVC.                 83650020
IAPUTGET EQU   X'07'          INDICATOR FOR PUTGET SERVICE RTN.  A45714 83700021
         SPACE 2                                                        83720020
IAMVC005 MVC   D8(*-*,LEV2REG),D0(INS2REG) MOVE NUMERIC DATA TO         84350020
*                                  INSERTION RECORD.                    84420020
IAMVC006 MVC   ININS1(*-*),CAEDMEMB MOVE MEMBER NAME TO INSERTION       84490020
*                                  RECORD.                              84560020
IAMVC007 MVC   D1(*-*,DSNAMREG),PSCBUSER-PSCB(PASSREG) MOVE             84630020
*                                  USERID TO INSERTION RECORD.          84700020
IAMVC008 MVC   D1(*-*,DSNAMREG),CAEDDSN MOVE USER-SUPPLIED NAME         84770020
*                                  TO INSERTION RECORD.                 84840020
IAMVC009 MVC   D1(*-*,DSNAMREG),CADSQUAL MOVE QUALIFIER TO              84910020
*                                  INSERTION RECORD.                    84980020
IAMVC010 MVC   INDSNREC(*-*),D1(DSNAMREG) MOVE DSNAME INSERTION         85050020
*                                  TEXT TO INSERTION RECORD.            85120020
IAMVC011 MVC   ININS1+D1(*-*),PSCBUSER-PSCB(PASSREG) MOVE USERID.       85190020
IAMVC012 MVC   ININS1+D1(*-*),D0(LEV1REG) MOVE RECFM INSERTION          85260020
*                                  DATA.                                85330020
         SPACE 2                                                        85400020
IAFMTAB  DS    0F             RECFM TRANSLATION TABLE.                  85470020
IAFMMASK DC    XL4'38'        MASK FOR ISOLATING B,S, AND T BITS        85540020
*                                  OF DS1RECFM FIELD.                   85610020
         DC    AL1(0),CL3'S'  STANDARD.                                 85680020
         DC    AL1(0),CL3'B'  BLOCKED.                                  85750020
         DC    AL1(1),CL3'BS' BLOCKED, STANDARD.                        85820020
         DC    AL1(0),CL3'T'  TRACK OVERFLOW.                           85890020
         DC    AL1(1),CL3'ST' STANDARD,TRACK OVERFLOW.                  85960020
         DC    AL1(1),CL3'BT' BLOCKED, TRACK OVERFLOW.                  86030020
         DC    AL1(2),C'BST'  BLOCKED, STANDARD, TRACK OVERFLOW.        86100020
         EJECT                                                          86170020
*********************************************************************** 86240020
*                                                                       86310020
*    WORK AREA MAP                                                      86380020
*                                                                       86450020
*********************************************************************** 86520020
IAWORKA  DSECT                WORK AREA FOR THIS ROUTINE.               86590020
         SPACE 2                                                        86660020
INDECBIN DS    D              DOUBLE WORD USED FOR CONVERT TO           86730020
*                                  BINARY OPERATIONS.                   86800020
IAPRMLST DS    7F             REMOTE PROGRAM PARAMETER LIST.            86870020
INMSGIN1 DS    0F             INSERTION RECORD FOR IKJEBEMS.            86940020
INPTIN1  DS    F              POINTER TO NEXT INSERTION.                87010020
INLNIN1  DS    H              LENGTH OF INSERTION RECORD.               87080020
INOFFIN1 DS    H              OFFSET IN MESSAGE TO INSERTION.           87150020
ININS1   DS    CL80           INSERTION TEXT.                           87220020
         SPACE 2                                                        87290020
INMSGIN2 DS    0F             INSERTION RECORD FOR IKJEBEMS.            87360020
INPTIN2  DS    F              POINTER TO NEXT INSERTION.                87430020
INLNIN2  DS    H              LENGTH OF INSERTION RECORD.               87500020
INOFFIN2 DS    H              OFFSET IN MESSAGE TO INSERTION.           87570020
ININS2   DS    CL80           INSERTION TEXT.                           87640020
         SPACE 2                                                        87710020
INMSGIN3 DS    0F             INSERTION RECORD FOR IKJEBEMS.            87780020
INPTIN3  DS    F              POINTER TO NEXT INSERTION.                87850020
INLNIN3  DS    H              LENGTH OF INSERTION RECORD.               87920020
INOFFIN3 DS    H              OFFSET IN MESSAGE TO INSERTION.           87990020
ININS3   DS    CL80           INSERTION TEXT.                           88060020
         SPACE 2                                                        88130020
INMSGIN4 DS    0F             INSERTION RECORD FOR IKJEBEMS.            88200020
INPTIN4  DS    F              POINTER TO NEXT INSERTION.                88270020
INLNIN4  DS    H              LENGTH OF INSERTION RECORD.               88340020
INOFFIN4 DS    H              OFFSET IN MESSAGE TO INSERTION.           88410020
ININS4   DS    CL80           INSERTION TEXT.                           88480020
         SPACE 2                                                        88550020
INDSNINS DS    0F             THIS AREA IS USED FOR DSNAME              88620020
*                                  INSERTIONS IN DIAGNOSTIC             88690020
*                                  MESSAGES CONCERNED WITH              88760020
*                                  PARTIALLY QUALIFIED DSNAMES.         88830020
INDSNPTR DS    F              ADDRESS OF NEXT INSERTION RECORD.         88900020
INDSNLEN DS    H              LENGTH OF INSERTION RECORD.               88970020
INDSNOFF DS    H              OFFSET OF INSERTION INTO BASIC            89040020
*                                  MESSAGE.                             89110020
INDSNREC DS    CL63           INSERTION TEXT.                           89180020
         EJECT                                                          89250020
         IKJEBECA                                                       89320020
         EJECT                                                          89390020
         IKJCPPL                                                        89600020
         EJECT                                                          89670020
         IKJPSCB                                                        89740020
   END                                                                  89810020
