 TITLE 'TSO ''EDIT'' COMMAND - ''LIST'' SUBCOMMAND - IKJEBELT'          00100020
IKJEBELT CSECT                                                          00200020
*********************************************************************** 00300020
*                                                                     * 00400020
*STATUS  --  VERSION NO. 01, O/S 360 RELEASE NO. 20                   * 00500020
*                                                                     * 00600020
*FUNCTION  --  THIS EDIT SUBCOMMAND PROCESSOR IS A PROBLEM-PROGRAM,   * 00700020
*   INVOKED BY THE MASTER CONTROLLER (IKJEBEMA).                      * 00900020
*                                                                     * 01100020
*   THIS ROUTINE'S FUNCTION IS TO DISPLAY PART OR ALL OF THE EDIT     * 01200020
*   DATA SET AT THE TERMINAL. THE 'NUM' & 'SNUM' KEYWORDS CAUSE LINE  * 01250020
*   NUMBERS TO BE DISPLAYED TO THE LEFT OF THE TEXT WITH 3 OR LESS    * 01300020
*   LEADING ZEROES SUPPRESSED OR TO BE SUPPRESSED, RESPECTIVELY. THESE* 01350020
*   KEYWORDS ARE INEFFECTUAL IF THE DATA SET IS NOT LINE-NUMBERED.    * 01600020
*                                                                     * 01700020
*   FORMS OF THE SUBCOMMAND & CONSEQUENT ACTIONS FOLLOW.              * 01800020
*                                                                     * 01900020
*   'LIST'       - ENTIRE DATA SET IS DISPLAYED.                      * 01930020
*   'LIST N'     - THE LINE NUMBERED 'N' IS DISPLAYED.                * 01960020
*   'LIST N1 N2' - LINES 'N1' THRU 'N2' ARE DISPLAYED.                * 01990020
*   'LIST *'     - CURRENT LINE IS DISPLAYED.                         * 02020020
*   'LIST * N'   - N LINES ARE DISPLAYED, STARTING WITH THE CURRENT   * 02050020
*                  ONE.                                               * 02500020
*                                                                     * 02800020
*ENTRY POINTS  --                                                     * 02900020
*       IKJEBELT - BY A 'CALL' MACRO INSTRUCTION FROM THE MASTER      * 02950020
*   CONTROLLER(IKJEBEMA), TO LIST ONE OR MORE LINES OF THE DATA SET   * 03000020
*   BEING EDITED, AS DESCRIBED IN 'FUNCTION --'.                      * 03050020
*                                                                     * 03300020
*INPUT  --  REGISTER 1 CONTAINS A POINTER TO EDIT'S COMMUNICATION     * 03400020
*   AREA, DEFINED IN THE IKJEBECA MACRO.  THIS AREA CONTAINS A        * 03460020
*   POINTER TO THE BUFFER CONTAINING THE 'LIST' SUBCOMMAND, & A       * 03520020
*   SWITCH TO TELL WHETHER THIS ROUTINE WAS CALLED BY A SUBCOMMAND.   * 03700020
*                                                                     * 03800020
*OUTPUT  --  RETURN CODES POSSIBLE IN REGISTER 15 ARE                 * 03900020
*   00 - SUCCESSFUL OPERATION (I.E., NO I/O ERROR)                    * 04000020
*   08 - THIS RETURN CODE SIGNIFIES THAT THE INPUT STACK MUST BE      * 04010020
*        CLEARED (AND DELETED IF INPUT SOURCE IS AN IN-CORE PROCEDURE)* 04020020
*        BECAUSE THIS MODULE WAS UNABLE TO COMPLETE ITS FUNCTION DUE  * 04030020
*        TO COMMAND SYSTEM ERROR, INSUFFICIENT CORE STORAGE, INVALID  * 04040020
*        LINE RANGE, MEANINGLESS LINE NUMBER, OR LINE NOT FOUND.      * 04050020
*   12 - PERMANENT I/O ERROR ON UTILITY DATA SET                      * 04100020
*                                                                     * 04200020
*EXTERNAL REFERENCES  --                                              * 04300020
*       IKJPARS  - CHECKS SYNTAX OF SUBCOMMAND                        * 04400020
*       IKJEBEMS - SELECTS & SENDS MESSAGES TO USER                   * 04600020
*       IKJEBEUT - ACCESSES UTILITY DATA SET                          * 04700020
*       MACROS USED                                                   * 04800020
*         LINK     - PASSES CONTROL TO IKJPARS                        * 04900020
*         PUTLINE  - BUILDS PARM LIST & CALLS RTN TO DISPLAY A  LINE  * 05000020
*         IKJPARM  - ) CONSTRUCTS                                     * 05100020
*         IKJIDENT - )  PARAMETER                                     * 05200020
*         IKJKEYWD - )   CONTROL &                                    * 05300020
*         IKJNAME  - )    DESCRIPTOR                                  * 05400020
*         IKJENDP  - )     LISTS (PCL,PDL)                            * 05500020
*         IKJEBESH - INVOKES IKJEBEUT SERVICE ROUTINE.                * 05550020
*         IKJRLSA  - FREES STORAGE FOR PARM DESCRIPTOR LIST (PDL)     * 05600020
*         IKJEBECA - DEFINES DUMMY SECTION FOR EDIT COMM AREA         * 05700020
*         IKJEBESV - GENERATES ENTRY LINKAGE ) CHAINED                * 05800020
*         IKJEBERT - GENERATES EXIT LINKAGE  )  SAVE AREAS            * 05900020
*                                                                     * 06000020
*EXITS,NORMAL  --  VIA A BRANCH TO THE CALLER, WITH RETURN CODE AS    * 06100020
*   DESCRIBED IN 'OUTPUT  --'. AN EXPLANATION IS PROVIDED WHEN NO     * 06200020
*   LINES ARE DISPLAYED.                                              * 06300020
*                                                                     * 06400020
*EXITS,ERROR  --  NONE.                                               * 06500020
*                                                                     * 06600020
*TABLES/WORK AREAS --                                                 * 06700020
*   CASCWKA IN EDIT'S COMMUNICATION AREA IS USED AS A WORK AREA.      * 06900020
*   CABFRPL IN EDIT'S COMMUNICATION AREA IS USED TO FORMAT THE LINE   * 07000020
*   TO BE LISTED.                                                     * 07100020
*                                                                     * 07200020
*ATTRIBUTES  --  REFRESHABLE, ENABLED, NON-PRIVILEGED.                * 07300020
*NOTES  --  THERE IS CHARACTER-CODE INDEPENDENCE.                     * 07400020
*                                                                     * 07500020
*********************************************************************** 07600020
 EJECT                                                                  07700020
*********************************************************************** 07800020
*                                                                     * 07900020
*                             ENTRY CODE                              * 08000020
*                                                                     * 08100020
*********************************************************************** 08200020
 SPACE                                                                  08300020
         IKJEBESV (14,12),,*                                            08400020
 SPACE                                                                  08500020
*********************************************************************** 08600020
*                                                                     * 08700020
*                             PROCESSING                              * 08800020
*                                                                     * 08900020
*********************************************************************** 09000020
 SPACE                                                                  09100020
* SET RETURN CODE TO ZERO FOR TIME BEING.                               09200020
* INITIALIZE PARM LISTS FOR IKJEBESR & IKJEBEUT.  SET REG FOR RET CODE  09300020
*  COMPARISON.  IND LIST NOT BY LINE NO.  IND PARSE NOT CALLED.         09400020
*  INDICATE 'NUM' SPECIFIED.  PICK UP LINE NO. LNG & OFFSET             09500020
 SPACE                                                                  09600020
         LR    COMMREG,PARMREG1         KEEP PT EDIT COMM AREA          09700020
         LA    COMMREG,O(COMMREG)                                       09800020
         USING IKJEBECA,COMMREG         ESTABLISH ADDRESSABILITY        09900020
         XC    LTKODE(WD),LTKODE        RET CODE ZERO                   10000020
         MVI   LTINRCD,BLANK            BLANK-OUT INPUT AREA            10100020
         MVC   LTINRCD+BYTE(MAXL),LTINRCD                               10200020
         MVC   LTPAD(DUBLWD),LTINRCD                                    10300020
         ST    COMMREG,LTCA@            PT COMMAREA INTO IKJEBESR       10400020
         ST    COMMREG,LTCOMA@           & IKJEBEUT PARM LISTS          10500020
         LA    WRKREG,UT                                                10600020
         ST    WRKREG,LTMODNM@          PT TO IKJEBEUT                  10700020
         LA    WRKREG,LTCOMA@                                           10800020
         ST    WRKREG,LTPLST@@          PT UT PLIST                     10900020
         LA    WRKREG,LTUTCODE                                          11000020
         ST    WRKREG,LTPLST@           PT 3-WD PLIST IN UT PLIST       11100020
         MVI   LTPLST@,LASTPARM                                         11200020
         MVC   LTDCB@-BYTE(WD),CAPTCDCB PT UTIL DCB                     11300020
         LA    WRKREG,LTKEY                                             11400020
         ST    WRKREG,LTKEY@            PT KEY                          11500020
         LA    WRKREG,LTINAREA                                          11600020
         ST    WRKREG,LTREAD@           PT INPUT AREA                   11700020
         MVI   LTREAD@,LASTPARM                                         11800020
HERE     BAL   LINUM1,HERE+WD           IND LIST NOT BY LINE NO.        11900020
*                                        (ILC IN PSW=10,SO LINUM1       12000020
*                                         IS MADE NEGATIVE)             12100020
         MVI   NUMSNUM,ZEROMASK         IND 'NUM' SPEC                  12300020
         SR    LINUMLEN,LINUMLEN                                        12400020
         LR    LINUMOFF,LINUMLEN                                        12500020
         IC    LINUMLEN,CALENGTH        GET LINE NO. LNG                12600020
         IC    LINUMOFF,CALINE          GET LINE NO. OFFSET             12700020
 EJECT                                                                  12800020
*********************************************************************** 12900020
*                                                                     * 13000020
* IF NOT, SEE IF ANY OPERANDS WERE PRESENT.                           * 13200020
*         IF NOT, SET COUNT GREATER THAN 999999999                    * 13260020
*         (SO ENTIRE DATA SET WILL BE LISTED), AND READ 1ST RECORD.   * 13320020
*         IF PRESENT, CALL PARSE.                                     * 13500020
*                                                                     * 13600020
*********************************************************************** 13700020
 SPACE                                                                  13800020
         TM    CAPTIBFR,ANYOPNDS        NO, ANY OPERANDS                14100020
         BO    PARSE                       YES,CALL PARSE               14200020
*                                          NO,LIST ENTIRE DATASET       14300020
LISTALL  BALR  CTR,O                    SET BIT 1 OF COUNTER TO         14400020
*                                        1 (ILC IN PSW=01) TO           14500020
*                                        MAKE CTR GRTR THAN 99999999    14600020
         LA    PARMREG1,LTSHPLST        SET PT TO PARM LIST             14800020
         MVI   LTUTCODE,READ1ST         IND 'RD 1ST RCD'                14900020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),LTUTCODE),       C15000020
               MF=(E,(1))                                               15100020
         CH    RETCDREG,COD4            CHECK IKJEBEUT RET CODE         15200020
         BH    IOERR1                   I/O ERR-TERMINATE               15300020
        BE    EMPTY                     RCD NOT LOC-ISSUE DIAGNOSTIC    15400020
         B     NUMB                     SUCCESS-FMT RCD FOR OUTPT       15500020
IOERR1   MVC   LTKODE(WD),RC12          SET RET CODE 12                 15600020
         B     EXEUNT                   BRANCH TO CLEANUP               15700020
IOERR2   MVC   LTKODE(WD),RC12          SET RET CODE 12                 15800020
         B     CLEANUP                  BRANCH TO CLEANUP               15900020
 SPACE                                                                  16000020
* CALL PARSING ROUTINE                                                  16100020
 SPACE                                                                  16200020
PARSE    L     WRKREG,LISTPCL#                                          16300020
         ST    WRKREG,CATMPLST+PPLPCL-PPL PT TO PCL                     16400020
         LA    WRKREG,CAPTPRSD                                          16500020
         ST    WRKREG,CATMPLST+PPLANS-PPL PT TO ANSWER PLACE            16600020
         MVC   CATMPLST+PPLCBUF-PPL(WD),CAPTIBFR PT TO COMMAND BUFFER   16700020
         LA    PARMREG1,CATMPLST        SET PT PARM LIST                16800020
         LINK  EP=IKJPARS               CALL PARSE                      16900020
* BRANCH ACCORDING TO RETURN CODE                                       17000020
         B     PARSEBT(CODEREG)         PARSE BR TABLE                  17100020
PARSEBT  B     SUCCESS        00(SUCCESS)         -GET ANSWER           17200020
         B     INCMPLT1       04(UNABLE TO PROMPT)-GO INDICATE          17260020
*                             FUNCTION NOT COMPLETED.                   17320020
         B     EXEUNT         08(ATTN)            -EXIT                 17400020
         B     SRERROR        12(INVALID PARMS)   -ISSUE ERR MSG        17500020
         B     NOROOM         16(NO SPACE)        -ISSUE ERR MSG        17600020
SUCCESS  L     PDLBASE,CAPTPRSD         PICK UP PT TO PDL.              17700020
         USING LISTPDL,PDLBASE          ESTABLISH ADDRESSABILITY        17800020
 EJECT                                                                  17900020
*********************************************************************** 18000020
*                                                                     * 18100020
* IF 'SNUM' WAS SPECIFIED, INDICATE THIS FACT.                        * 18160020
* IF NO LINENUM OR '*' WAS SPECIFIED, PROCEED AS IF THERE WERE NO     * 18220020
* OPERANDS.                                                           * 18400020
* IF 1ST OPERAND IS A LINE NO., SEE IF THE D.S. IS LINE-NUMBERED.     * 18500020
*                               IF NOT, ISSUE AN ERROR MSG.           * 18600020
*                               IF SO, SEE IF THERE IS A 2ND OPERAND. * 18700020
*                                     IF SO, CHECK FOR A VALID RANGE. * 18800020
*                                     IF NOT, SET LINENUM2=LINENUM1.  * 18900020
*                               SET THE KEY TO LINENUM1 & READ W/ IT. * 19000020
* IF THE 1ST OPERAND IS AN ASTERISK, SEE IF THERE IS A 2ND OPERAND.   * 19060020
*  IF NOT, SET THE COUNT TO 1.                                        * 19120020
*  SET THE KEY TO THE CURRENT LINE REFERENCE POINTER, & READ W/ KEY.  * 19300020
*                                                                     * 19400020
*********************************************************************** 19500020
 SPACE                                                                  19600020
         TM    OP3,SNUM                 WAS 'SNUM' SPEC                 19700020
         BZ    LINORAST                 NO,SEE IF LINUM OR * SPEC       19800020
         MVI   NUMSNUM,SNUM             YES,IND SO & CONT               19900020
LINORAST TM    OP1SPEC,ANYOPNDS         LINUM OR * SPEC AT ALL          20000020
         BZ    LISTALL                  NO,LIST ENTIRE D.S.             20100020
         L     WRKREG,LINE1             YES,GET PT 1ST OPERAND          20200020
         CLI   O(WRKREG),STAR           IS IS A NO.                     20300020
         BE    ANY2ND                   NO,SEE IF ANY 2ND OPERAND       20400020
         TM    CACFLAG1,CANONUM         YES,IS D.S. LINE-NUMBERED       20500020
         BO    DSNOTNUM                     NO, ISSUE  'DS NOT NUMD'    20600020
         LH    L,OP1L                       YES,GET LNG LINENUM1        20700020
         BCTR  L,O                     MINUS ONE FOR EX                 20800020
         EX    L,LNORCTPK               CHG  LINENUM1 TO PKD DEC        20900020
         CVB   LINUM1,LTPAKARA          CONV IT TO BINARY (THIS         21000020
*                                        ALSO INDICATES THAT THE        21100020
*                                        LIST IS BY LINE NO.)           21200020
         TM    OP2SPEC,ANYOPNDS         ANY 2ND OPERAND                 21300020
         BZ    LIST1LIN                 NO,SET RANGE TO 1 LINE          21400020
         LA    RETREG,CMP1AND2          GET PT LINENO. CMP,WHICH        21500020
*                                        FOLLOWS THE FOLLOWING          21600020
*                                        ROUTINE                        21700020
 EJECT                                                                  21800020
*********************************************************************** 21900020
*                                                                     * 22000020
* THIS CLOSED SUBROUTINE PICKS UP THE 2ND OPERAND, CHANGES IT TO      * 22100020
* PACKED-DECIMAL, & CONVERTS IT TO BINARY.  IT IS USED WHETHER        * 22200020
* THE 2ND OPERAND IS A LINE NO. OR A COUNT.                           * 22300020
*                                                                     * 22400020
*********************************************************************** 22500020
 SPACE                                                                  22600020
GETOPND2 L     WRKREG,LINORCNT          GET PT 2ND OPERAND              22700020
         LH    L,OP2L                   GET ITS LENGTH                  22800020
         BCTR  L,O                      MINUS ONE FOR EX                22900020
         EX    L,LNORCTPK               PACK IT                         23000020
         CVB   (LINUM2+CTR)/TWO,LTPAKARA CONVERT PKD DEC TO BINARY      23100020
         BR    RETREG                   RETURN TO NEXT SEQ INST         23200020
 SPACE                                                                  23300020
* CHECK FOR VALID RANGE (LINENUM1 LESS THAN OR EQUAL TO LINENUM2)       23400020
 SPACE                                                                  23500020
CMP1AND2 CR    LINUM1,LINUM2            LINUM1 GTR THAN LINUM2          23600020
         BH    L1GTL2                   YES, ISSUE 'INVALID RANGE'      23700020
         B     SETKEY1                  NO,SET KEY FOR READ             23800020
LIST1LIN LR    LINUM2,LINUM1            SET LINENUM2=LINENUM1           23900020
SETKEY1  ST    LINUM1,LTKEY             KEY=LINENUM1 FOR READ           24000020
         B     READWKEY                 PREPARE FOR READ                24100020
ANY2ND   TM OP2SPEC,ANYOPNDS            ANY 2ND OPERAND                 24200020
         BZ    SETCNT1                  NO,SET CTR FOR 1 LINE           24300020
         BAL   RETREG,GETOPND2          YES,BRING COUNT INTO REG        24400020
         B     KEYSTAR                  SET KEY FOR READ                24500020
SETCNT1  LA    CTR,ONE                  SET COUNT TO 1                  24600020
KEYSTAR  MVC   LTKEY(WD),CACURNUM       SET KEY TO CURR LINE NO.        24700020
READWKEY MVI   LTUTCODE,READCURR        IND 'READ CURR REF RCD'         24800020
         LTR   LINUM1,LINUM1            WAS '*' SPECIFIED -             24810020
         BNM   LTNOTAST                 IF NO,GOTO READ CURR RCD.       24820020
         L     WRKREG,CACURNUM          IF YES,IS '*' SET               24830020
         LTR   WRKREG,WRKREG                   TO ZERO -                24840020
         BNZ   LTNOTAST                 IF NO,GOTO READ CURR RCD.       24850020
         MVI   LTUTCODE,READ1ST         IF YES,IND 'READ BEGNG'.        24860020
LTNOTAST EQU   *                                                        24870020
         LA    PARMREG1,LTSHPLST        SET PT PARM LIST                24900020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),LTUTCODE),       C25000020
               MF=(E,(1))                                               25100020
         CH    RETCDREG,COD4            CHECK UT RET CODE               25200020
         BH    IOERR2                   I/O ERR-TERMINATE               25400020
         BE    SELECT                   RCD NOT LOC-SELECT ERR MSG      25500020
NUMB     MVI   LTUTCODE,READNEXT        SUCCESS-IND 'READ NEXT' FOR     25600020
*                                       FUTURE CALLS OF IKJEBEUT        25700020
 SPACE                                                                  25800020
* MOVE THE PUTLINE PARM BLOCK INTO WORKAREA & PUT ITS ADDRESS           25900020
*  INTO THE GENREAL SERVICE ROUTINE PARM LIST.                          26000020
*                                                                       26100020
         MVC   LTPUTBLK(BLKL),PARMBLOK                                  26200020
         LA    WRKREG,LTPUTBLK                                          26300020
         ST    WRKREG,CATMPLST+IOPLIOPB-IOPL                            26400020
 EJECT                                                                  26500020
*********************************************************************** 26600020
*                                                                     * 26700020
* THE FOLLOWING CODE IS EXECUTED FOR EVERY DATA SET LINE LISTED AT    * 26800020
* THE TERMINAL.                                                       * 26900020
*                                                                     * 27000020
* IF THE D.S. IS NOT LINE-NUMBERED, CALL PUTLINE.                     * 27100020
* IF IT IS, SEE WHETHER 'SNUM' WAS SPECIFIED -                        * 27200020
*           IF IT WAS, EITHER BLANK-OUT THE NO. AT THE END OF THE     * 27300020
*                      RCD(FOR FIXED-LNG RCD) OR LEFT-JUSTIFY THE     * 27400020
*                      DATA PORTION OF RCD(FOR VARIABLE-LNG RCD)      * 27500020
*                      & CALL PUTLINE.                                * 27600020
*           IF IT WASN'T, SEPARATE NO. & DATA BY 1 BLANK (AFTER       * 27700020
*                      HAVING MOVED THE NO. TO THE BEGNG OF THE       * 27800020
*                      RCD, IN THE CASE OF FIXED RCD LNG), BLANK-     * 27900020
*                      OUT UP TO 3 LEADING ZEROES, & CALL PUTLINE.    * 28000020
*                                                                     * 28100020
*********************************************************************** 28200020
 SPACE                                                                  28300020
PUTLOOP  TM    CACFLAG1,CANONUM         IS D.S. LINE-NUMBERED           28400020
         BO    CLATTER                  NO,BRANCH TO LIST LINE          28500020
         CLI   NUMSNUM,SNUM             YES, WAS  'SNUM' SPEC           28600020
         BNE   NUMSPEC                     NO,FMT RCD FOR OUTPUT        28700020
         TM    CACFLAG2,CARECFM            YES,TEST RCD FMT             28800020
         BZ    SLIDE                    VAR,BRANCH TO L-JUST DATA       28900020
         CLI   CALINE,ONE               FIXED & NO. BEGINS IN COL       28930020
         BE    SLIDE                     1, TREAT LIKE VARIABLE         28960020
         LA    WRKREG,LTINRCD-BYTE(LINUMOFF) FIXED,GET ADDR OF NO.      29000020
         MVC   O(DUBLWD,WRKREG),LTPAD   BLANK-OUT LINE NO.              29200020
         B     CLATTER                  BRANCH TO LIST LINE             29400020
SLIDE    LA    WRKREG,LTINRCD(LINUMLEN) GET ADDR OF DATA                29500020
         MVC   LTOUTRCD(MAXL+ONE),O(WRKREG) LEFT-JUSTIFY IT             29600020
         LH    L,LTLL                   SUBTRACT LNG OF LINE NO.        29620020
         SR    L,LINUMLEN                FROM LNG OF RECORD             29640020
         STH   L,LTLL                                                   29660020
         B     CLATTER                  BRANCH TO LIST LINE             29700020
NUMSPEC  LH    L,LTLL                   ADD 1 TO LNG FOR BLANK TO       29800020
         LA    L,BYTE(L)                      BE INSERTED               29900020
         STH   L,LTLL                                                   30000020
         TM    CACFLAG2,CARECFM         TEST RCD FMT                    30100020
         BZ    CLEAVE                   VAR,INSERT BLANK BETWEEN        30200020
*                                           NO. & DATA                  30300020
         CLI   CALINE,ONE               FIXED & NO. BEGINS IN COL       30330020
         BE    CLEAVE                    1, TREAT LIKE VARIABLE         30360020
         MVC   LTTEMP(MAXL+ONE),LTINRCD FIXED,SAVE RCD TEMPORARILY      30400020
         LA    WRKREG,LTTEMP-BYTE(LINUMOFF) GET ADDR OF NO.             30500020
         MVC   LTOUTRCD(DUBLWD),O(WRKREG) MOVE IT TO BEGNG              30600020
         MVC   O(DUBLWD,WRKREG),LTPAD   BLANK-OUT AFTER-IMAGE.          30800020
         LA    WRKREG,LTOUTRCD(LINUMLEN)                                31000020
         MVI   O(WRKREG),BLANK          INSERT BLANK AFTER NO.          31100020
         MVC   BYTE(MAXL+ONE,WRKREG),LTTEMP DATA FOLLOWS THE BLANK      31200020
         B     SUPPRESS                 BRANCH TO SUPPRESS LEADING Z    31300020
CLEAVE   LA    WRKREG,LTINRCD(LINUMLEN)      GET ADDR OF DATA           31400020
         MVC   LTTEMP(MAXL),O(WRKREG)   SHIFT IT RIGHT 1 BYTE           31500020
         MVC   BYTE(MAXL,WRKREG),LTTEMP                                 31600020
         MVI   O(WRKREG),BLANK          INSERT A BLANK                  31700020
 SPACE                                                                  31800020
* THE FOLLOWING CODE SETS UP TO (& INCLUDING) 3 LEADING-ZEROES TO BLNK  31900020
 SPACE                                                                  32000020
SUPPRESS LA    WRKREG,LTOUTRCD          START AT BEGNG OF LINENO.       32100020
         LA    INCRMENT,ONE             INCR BY 1                       32200020
         LA    COMPRAND,HAFWD(WRKREG)   STOP AT 3RD DIGIT               32300020
LOOP     CLI   O(WRKREG),NOUGHT         IS DIGIT A ZERO                 32400020
         BNE   LEFTWARD                      NO,BRANCH TO SHIFT LEFT    32500020
         BXLE  WRKREG,INCRMENT,LOOP     BUMP INDEX & BRANCH             32600020
LEFTWARD MVC   LTOUTRCD(MAXL+TWO),O(WRKREG) L-JUSTIFY OUTPUT RCD.       32700020
 SPACE                                                                  32800020
* COMPLETE PUTLINE PARM BLOCK & CALL PUTLINE TO LIST LINE AT TERMINAL   32900020
 SPACE                                                                  33000020
CLATTER  PUTLINE ,OUTPUT=(LTPUTOUT,DATA),MF=(E,CATMPLST)                33100020
         B     LTPUTLBT(RETCDREG)       BRANCH ON RET CODE.             33140020
LTPUTLBT EQU   *                                                        33180020
         B     LTPUTLOK                 0 - BRANCH TO CONTINUE.         33220020
         B     CLEANUP                  4 - ATTN,GOTO FREE PDL.         33260020
         B     LTPUTERR                 8 - GOTO ISSUE ERR MSG.         33300020
         B     LTPUTERR                 12- GOTO ISSUE ERR MSG.         33340020
         B     NOROOM                   16 -GOTO ISSUE ERR MSG.         33380020
LTPUTLOK EQU   *                                                        33420020
         MVI   LTINRCD,BLANK            0-BLANK OUT INPUT AREA          33500020
         MVC   LTINRCD+BYTE(MAXL),LTINRCD                               33600020
         MVC   LTPAD(DUBLWD),LTINRCD                                    33700020
 EJECT                                                                  33800020
*********************************************************************** 33900020
*                                                                     * 34000020
* UPDATE THE CURRENT LINE REFERENCE POINTER ('*')                     * 34100020
* IF AN ATTENTION BUTTON WAS PUSHED, FREE PDL CORE IF NEC & EXIT.     * 34200020
* IF THE LISTING IS BY LINE NO., EITHER CALL UT TO READ-NEXT (IF MORE * 34300020
*        LINES ARE TO BE LISTED) OR FREE PDL CORE IF NEC & EXIT(IF    * 34400020
*        THE LAST LINE IN THE RANGE WAS LISTED).                      * 34500020
* OTHERWISE DECREMENT THE COUNT BY 1 AND EITHER READ NEXT (IF LINES   * 34600020
*        REMAIN TO BE LISTED) OR FREE PDL CORE IF NEC & EXIT (IF THE  * 34700020
*        COUNT HAS BECOME ZERO).                                      * 34800020
*                                                                     * 34900020
*********************************************************************** 35000020
 SPACE                                                                  35100020
         MVC   CACURNUM(WD),LTKEE       UPDATE * FR KEY OF RCD          35200020
         TM    CAATTN,POSTED            HAS ATTN ECB BEEN POSTED        35300020
         BO    CLEANUP                  YES,FREE PDL IF NEC &EXIT       35400020
         LTR   LINUM1,LINUM1            NO, IS LIST BY LINE NO.         35500020
         BNM   ENDQUEST                   YES,SEE IF LIST IS DONE       35600020
         BCTR  CTR,O                      NO,DECR CTR                   35700020
         LTR   CTR,CTR                  IS CTR ZERO                     35800020
         BNP   CLEANUP                  YES,FREE PDL IF NEC &EXIT       35900020
         B     NEWKEY                   NO,SET KEY FOR NEXT READ        36000020
ENDQUEST C     LINUM2,CACURNUM          HAS LAST LINE BEEN LISTED       36100020
         BNH   CLEANUP                  YES,FREE PDL IF NEC &EXIT       36200020
NEWKEY   MVC   LTKEY(WD),CACURNUM       NO,SET KEY=CURR LINE NO.        36300020
         LA    PARMREG1,LTSHPLST        SET PT TO PLIST                 36500020
         MVI   LTINRCD,BLANK            BLANK-OUT INPUT AREA            36700020
         MVC   LTINRCD+BYTE(MAXL),LTINRCD                               36800020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),LTUTCODE),       C36860020
               MF=(E,(1))                                               36920020
         CH    RETCDREG,COD4            CHECK IKJEBEUT RET CODE         37010020
         BH    IOERR2                   I/O ERR-FREE PDL,EXIT           37100020
         BE    EOD                      RCD NOT LOC-ISSUE 'EOD'         37200020
 EJECT                                                                  37300020
*********************************************************************** 37400020
*                                                                     * 37500020
* IF THE LIST IS BY LINE NO., SEE WHETHER THE LINE JUST READ IS       * 37600020
*        WITHIN RANGE.  IF SO, LIST THE LINE.                         * 37700020
*                       IF NOT, FREE PDL CORE IF NEC & EXIT.          * 37800020
* IF THE LIST IS BY COUNT, LIST THE LINE JUST READ                    * 37900020
*                                                                     * 38000020
*********************************************************************** 38100020
 SPACE                                                                  38200020
         LTR   LINUM1,LINUM1            IS LIST BY LINE NO.             38300020
         BM    PUTLOOP                  NO,FMT RCD & LIST IT            38400020
         C     LINUM2,LTINAREA          YES,IS LINE WITHIN RANGE        38500020
         BNL   PUTLOOP                     YES,FMT RCD & LIST IT        38600020
CLEANUP EQU *                                                           38700020
         TM    CAPRSPDL,CAFREEDL        IS THERE A PDL TO BE FREED      38800020
         BNZ   EXEUNT                   IF NO, GO TO EXIT.              38900020
         IKJRLSA CAPTPRSD               IF YES, FREE PDL CORE.          39000020
         OI    CAPRSPDL,CAFREEDL        IND PDL FREED.                  39100020
 EJECT                                                                  39200020
*********************************************************************** 39300020
*                                                                     * 39400020
*                                 EXIT                                * 39500020
*                                                                     * 39600020
*********************************************************************** 39700020
 SPACE                                                                  39800020
EXEUNT EQU *                                                            39900020
         L     RETCDREG,LTKODE          SET RET CODE                    40000020
         IKJEBERT (14,12),RC=(15)                                       40100020
 SPACE                                                                  40200020
*********************************************************************** 40300020
*                                                                     * 40400020
* THE FOLLOWING CODE IS BRANCHED-TO WHENEVER A MESSAGE MUST BE ISSUED * 40500020
*                                                                     * 40600020
*********************************************************************** 40700020
 SPACE                                                                  40800020
EMPTY    LA    WRKREG,LEMPTY                                            41100020
         B     MOVE3WDS                 BR TO SET PARMLIST              41200020
NOROOM   MVC   LEVEL1(WD+WD+WD),LNOROOM SET UP LEV1 PARMLIST            41230020
         LA    WRKREG,LTIN1            CHAIN                            41260020
         ST    WRKREG,L1INPT           PARMLISTS                        41290020
         MVC   LTIN1(LTMG3L),LTMG3     SET UP INSERTION PLIST           41320020
         BAL   RETREG,INCMPLT2          GO IND FUNCTION INCOMPLETE      41330020
         B     ZYXWVUTS                BR TO PUT MSG                    41350020
EOD      LA    WRKREG,LEOD                                              41500020
         B     MOVE3WDS                 BR TO SET PARMLIST              41510020
DSNOTNUM EQU   *                                                        41515020
         BAL   RETREG,INCMPLT2          GO IND FUNCTION INCOMPLETE      41520020
         LA    WRKREG,LDSNOTNU          PTR TO PARMLIST                 41525020
         B     MOVE3WDS                 BR TO MOVE TO MS PARMLIST       41530020
LTPUTERR EQU   *                                                        41532020
         MVC   LEVEL1(WD+WD+WD),LTM313  INITLZ LEVEL 1 PARM LIST.       41534020
         MVC   LTIN1(LTMGPUTL),LTMGPUT  INITLZ 1ST 2ND-LEVEL INS.       41536020
         B     SRERRORX                 GOTO FINISH MESSAGE.            41538020
SRERROR  MVC   LEVEL1(WD+WD+WD),LTM313  SET UP LEV1 PARMLIST            41540020
         MVC   LTIN1(LTMG1L),LTMG1      SET UP 1ST LEV2 INSERT PLIST    41550020
SRERRORX EQU   *                                                        41555020
         BAL   RETREG,INCMPLT2          GO IND FUNCTION INCOMPLETE      41557020
         MVC   LTIN2(LTMG2L),LTMG2      SET UP 2ND LEV2 INSERT PLIST    41560020
         SRL   RETCDREG,ONE             SHIFT R15 FOR INDEXING          41570020
         LH    WRKREG,LTCDTAB(RETCDREG) PICK UP PRINTABLE CHARACTERS    41580020
         STH   WRKREG,INST2             STORE IN INSERTION              41590020
         LA    WRKREG,LTIN1             CHAIN POINTERS                  41600020
         ST    WRKREG,L2INPT            TO INSERTION1                   41610020
         LA    WRKREG,LTIN2             AND INSERTION2                  41620020
         ST    WRKREG,LTIN1             PARMLISTS                       41630020
         B     ZYXWVUTS                 BR TO PUT ERROR MSG             41640020
L1GTL2   EQU   *                                                        41680020
         BAL   RETREG,INCMPLT2          GO IND FUNCTION INCOMPLETE      41720020
         LA    WRKREG,LL1GTL2           PT TO PARMLIST.                 41760020
MOVE3WDS MVC   LT10AREA(WD+WD+WD),O(WRKREG) 3WD LIST INTO 10WD AREA     41800020
ZYXWVUTS EQU   *                                                        41830020
         IKJEBEML ,,,,MF=(E,LT10AREA)   LINK TO IKJEBEMS TO PUT MSG     41860020
         B     CLEANUP                  BR TO RLSE PDL CORE             41960020
SELECT   LTR   LINUM1,LINUM1            LIST BY LINE NO.                42060020
         BNM   NOLINE                   YES,ISSUE'LINE NOT FOUND'.      42120020
         CLI   LTUTCODE,READ1ST         NO,WAS '*' NON-ZERO -           42180020
         BE    EMPTY                    IF NO,ISSUE 'D.S. EMPTY'.       42240020
*                                       YES, ISSUE 'LINE NOT FOUND'     42300020
NOLINE   L     LINUM1,LINE1             GET ADDR LINE NO.               42400020
         LH    L,OP1L                   GET LNG LINE NO.                42600020
         BCTR  L,O                      MINUS ONE FOR EX                42620020
         EX    L,LTMVC                  MOVE LINE NUMBER TO INSERTION   42640020
         LA    L,WD+ONE(L)              RESTORE LENGTH AND ADD OFFSET   42660020
         STH   L,LTL                    STORE IN LENGTH FIELD OF PLIST  42760020
         LA    WRKREG,M504IN1                                           42900020
         STH   WRKREG,LTLINOFF          SET OFFSET TO LINE NO.          43000020
         XC    LTIN1(FOUR),LTIN1        ZERO PTR TO NEXT INSERTION      43010020
         MVC   LEVEL1(WD+WD+WD),LNOLINE SET UP 1ST LEVEL                43020020
         LA    WRKREG,LTIN1             CHAIN PARMLISTS                 43030020
         ST    WRKREG,L1INPT            FOR INSERTIONS                  43040020
         BAL   RETREG,INCMPLT2          GO IND FUNCTION INCOMPLETE      43045020
         B     ZYXWVUTS                 BR TO PUT ERROR MSG             43050020
 SPACE                                                                  43150020
* THE FOLLOWING SETS A RET CODE INDICATING FUNCTION NOT COMPLETED.      43250020
 SPACE                                                                  43350020
INCMPLT1 EQU   *                                                        43450020
         LA    RETREG,EXEUNT            GET NEXT BRANCH POINT.          43550020
INCMPLT2 EQU   *                                                        43650020
         LA    WRKREG,RCNOTCOM          GET RET CODE.                   43750020
         ST    WRKREG,LTKODE            SAVE IT,                        43850020
         BR    RETREG                   EXIT OR ISSUE MESSAGE.          43950020
 EJECT                                                                  45000020
*********************************************************************** 45100020
*                                                                     * 45200020
*              OBJECTS OF EXECUTE INSTRUCTIONS                        * 45300020
*                                                                     * 45400020
*********************************************************************** 45500020
 SPACE                                                                  45600020
LNORCTPK PACK  LTPAKARA(DUBLWD),O(O,WRKREG)  CHANGE LINENUM1,           45700020
*                                       LINENUM2, OR COUNT FROM         45800020
*                                       ZONED TO PACKED DECIMAL         45900020
LTMVC    MVC   INST1(O),O(LINUM1)       MOVE LINE NUMBER TO INSERTION   46150020
 SPACE                                                                  46200020
*********************************************************************** 46300020
*                                                                     * 46400020
*                             CONSTANTS                               * 46500020
*                                                                     * 46600020
*********************************************************************** 46700020
*                                                                       46800020
RC12     DC    F'12'                    I/O ERROR RET CODE              46900020
UT       DC    C'IKJEBEUT'              NAME OF UTIL D.S. INTER-        47000020
*                                        FACE RTN                       47100020
COD4     DC    H'4'                     FOR TESTING RET CODES           47200020
LTCDTAB  DS    0H                                                       47220020
         DC    C'  040812'              TABLE OF PRINTABLE              47240020
         DC    C'16'                    CHARACTERS                      47260020
LISTPCL# DC    V(IKJEBLT1)              ADDR OF PCL                     47330020
 SPACE                                                                  47400020
* MESSAGE INSERTION RECORD                                              47500020
 SPACE                                                                  47600020
         DS    0F                                                       47610020
LTMG1    EQU   *                                                        47620020
         IKJEBEMG 0,M3131IN1,'PARSE'                                    47630020
LTMG1L   EQU   *-LTMG1                                                  47640020
LTMGPUT  IKJEBEMG 0,M3131IN1,'PUTLINE'                                  47643020
LTMGPUTL EQU   *-LTMGPUT                LNG OF INSERTION.               47646020
         DS    0F                                                       47650020
LTMG2    EQU   *                                                        47660020
         IKJEBEMG 0,M3131IN2,'00'                                       47670020
LTMG2L   EQU   *-LTMG2                                                  47680020
         DS    0F                                                       47690020
LTMG3    EQU   *                                                        47700020
         IKJEBEMG 0,M312IN1,'LIST'                                      47710020
LTMG3L   EQU   *-LTMG3                                                  47720020
 SPACE                                                                  47800020
* IKJEBEMS PARM LISTS                                                   47900020
 SPACE                                                                  48000020
LTM313   IKJEBEML M313,M3131,0,0,MF=L                                   48100020
LNOROOM  IKJEBEML M312,0,0,0,MF=L                                       48200020
LEMPTY   IKJEBEML M501,,,,MF=L                                          48300020
LEOD     IKJEBEML M500,,,,MF=L                                          48400020
LNOLINE  IKJEBEML M504,,,,MF=L                                          48500020
LL1GTL2  IKJEBEML M503,,,,MF=L                                          48600020
LDSNOTNU IKJEBEML M502,,,,MF=L                                          48700020
 SPACE                                                                  48800020
* PUTLINE PARAMETER BLOCK                                               48900020
 SPACE                                                                  49000020
PARMBLOK PUTLINE OUTPUT=(0,DATA),MF=L                                   49100020
 EJECT                                                                  49200020
*********************************************************************** 49300020
*                                                                     * 49400020
* MACROS TO GENERATE PARSE PARAMETER CONTROL LIST (PCL) & PROVIDE     * 49500020
*  SYMBOLIC REFERENCE FOR PARAMETER DESCRIPTOR LIST (PDL)             * 49600020
*                                                                     * 49700020
*********************************************************************** 49800020
 SPACE                                                                  49900020
IKJEBLT1 IKJPARM DSECT=LISTPDL                                          50000020
LINE1    IKJIDENT 'LINE NUMBER',ASIS,ASTERISK,MAXLNTH=8,               C50100020
               FIRST=NUMERIC,OTHER=NUMERIC                              50200020
LINORCNT IKJIDENT 'LINE NUMBER OR COUNT',ASIS,MAXLNTH=8,               C50300020
               FIRST=NUMERIC,OTHER=NUMERIC                              50400020
NUM      IKJKEYWD DEFAULT='NUM'                                         50500020
         IKJNAME 'NUM'                                                  50600020
         IKJNAME 'SNUM'                                                 50700020
         IKJENDP                                                        50800020
LISTPDL  DSECT                                                          50900020
OP1L     EQU   LINE1+4                  LNG OF 1ST OPERAND              51000020
OP2L     EQU   LINORCNT+4               LNG OF 2ND OPERAND              51100020
OP1SPEC  EQU   LINE1+6                  )FLAGS- BIT 0 IS OFF IF         51200020
OP2SPEC  EQU   LINORCNT+6               ) OPERAND IS OMITTED            51300020
OP3      EQU   LISTPDL+25               3RD OPERAND CODE                51400020
IKJEBELT CSECT                          RESUME LIST CONTROL SECT        51500020
 EJECT                                                                  51600020
*********************************************************************** 51700020
*                                                                     * 51800020
*                       COMMUNICATION AREA                            * 51900020
*                                                                     * 52000020
*********************************************************************** 52100020
 SPACE                                                                  52200020
         IKJEBECA                                                       52300020
 SPACE                                                                  52400020
*********************************************************************** 52500020
* STRUCTURE OF CASCWKA AS USED BY IKJEBELT                            * 52600020
*********************************************************************** 52700020
 SPACE                                                                  52800020
         ORG   CASCWKA   WORK AREA                                      52900020
LTSHPLST DS    0F -      SERVICE RTN HANDLER PARM LIST                  53000020
LTCA@    DS    F -       ADDR COMM AREA                                 53100020
LTMODNM@ DS    F -       PT MODULE NAME IN EBCDIC                       53200020
LTPLST@@ DS    F -       PT TO PT TO SERVICE RTN PARM LIST              53300020
 SPACE                                                                  53400020
* IKJEBEUT PARM LIST                                                    53500020
 SPACE                                                                  53600020
LTCOMA@  DS    F -       ADDR COMM AREA                                 53700020
LTPLST@  DS    F -       PT TO 1-3 WD PARM LIST                         53800020
LTUTCODE DS    X -       OPTION CODE                                    53900020
LTDCB@   DS    AL3 -     PT UTILITY DCB                                 54000020
LTKEY@   DS    F -       PT 4-BYTE BINARY KEY                           54100020
LTREAD@  DS    F -       PT AREA FOR READ                               54200020
LTKEY    DS    F -       KEY TO REPLACE CURR REF                        54300020
 SPACE                                                                  54400020
 SPACE                                                                  54800020
* AREA FOR PACKING LINE NO.                                             54900020
 SPACE                                                                  55000020
LTPAKARA DS    D         PACK AREA.                                     55100020
 SPACE                                                                  55200020
LTANSPLC DS    F -       PARSE ANSWER PLACE                             55300020
 SPACE                                                                  55400020
* PARAMETERS FOR IKJEBEMS                                               55500020
 SPACE                                                                  55600020
         ORG   CASCWKA+60               START MSG AREA                  55700020
LT10AREA DS    10F -     WORK AREA (PLIST IN 1ST 3 WORDS)               55800020
LEVEL1   EQU   LT10AREA                 LEVEL1 PARMLIST                 55900020
L1INPT   EQU   LEVEL1+4                 PTR TO INSERTION1 PARMLIST      56000020
L2INPT   EQU   LEVEL1+8                 PTR TO INSERTION2 PARMLIST      56100020
LTIN1    EQU   LEVEL1+12                INSERTION1 PARMLIST             56200020
LTL      EQU   LTIN1+4                  LENGTH OF INSERTION1 PARMLIST   56300020
LTLINOFF EQU   LTL+2                    OFFSET TO INSERTION PT IN MSG   56400020
INST1    EQU   LTLINOFF+2               INSERTION1                      56500020
LTIN2    EQU   INST1+8                  INSERTION2 PARMLIST             56560020
INST2    EQU   LTIN2+8                  INSERTION2                      56620020
 SPACE                                                                  56700020
* 1 BYTE-X'00' IF 'NUM' SPEC, X'02' IF 'SNUM' SPEC                      56800020
 SPACE                                                                  56900020
NUMSNUM  DS    X -                                                      57000020
         ORG   CASCWKA+196 ALIGN TO END OF WORKAREA                     57100020
LTKODE   DS    F -        RETURN CODE SAVE AREA                         57200020
 SPACE                                                                  57220020
* PUTLINE PARAMETER BLOCK -                                             57240020
 SPACE                                                                  57260020
LTPUTBLK DS    5F                       P.P.B.                          57280020
 SPACE                                                                  57300020
*********************************************************************** 57400020
* STRUCTURE OF BUFFER POOL AS USED BY IKJEBELT                        * 57500020
*********************************************************************** 57600020
 SPACE                                                                  57700020
         ORG   CABFRPL   WORK AREA                                      57800020
LTKEE    DS    0F -      4-BYTE BINARY KEY                              57900020
LTINAREA DS    259C -    AREA INTO WHICH IKJEBEUT READS                 58000020
         ORG   CABFRPL+4 WORK AREA                                      58100020
LTLL     DS    0H -      LNG OF RCD                                     58200020
LTPUTOUT DS    256C -    OUTPUT LINE                                    58300020
         ORG   CABFRPL+8 WORK AREA                                      58400020
LTOUTRCD DS    0X -      OUTPUT LINE                                    58500020
LTINRCD  DS    255C                     INPUT RECORD.                   58600020
LTPAD    DS    8C -      TRAILING BLANKS                                58700020
         ORG   CABFRPL+271              WORK AREA.                      58800020
LTTEMP   DS    251C -    TEMPORARY WORK AREA                            58900020
 SPACE                                                                  59000020
*********************************************************************** 59100020
* DSECT FOR PARSE PARM LIST                                           * 59200020
*********************************************************************** 59300020
 SPACE                                                                  59400020
         IKJPPL                                                         59500020
 SPACE                                                                  59600020
*********************************************************************** 59700020
* DSECT FOR PUTLINE PARM LIST                                         * 59800020
*********************************************************************** 59900020
 SPACE                                                                  60000020
         IKJIOPL                                                        60100020
IKJEBELT CSECT                          RESUME 'LIST' CONTROL SECTION   60200020
 EJECT                                                                  60300020
*********************************************************************** 60400020
*                                                                     * 60500020
*                             EQUATES                                 * 60600020
*                                                                     * 60700020
*********************************************************************** 60800020
 SPACE                                                                  60900020
* REGISTERS                                                             61000020
 SPACE                                                                  61100020
PARMREG0 EQU   0    FOR PASSING PARMS                                   61200020
R1       EQU   1                                                        61300020
PARMREG1 EQU   1    FOR PASSING PARMS                                   61400020
LINUMLEN EQU   3    LNG OF LINE NO.                                     61500020
LINUMOFF EQU   4    OFFSET OF LINE NO.                                  61600020
WRKREG   EQU   5                                                        61700020
L        EQU   6    FOR LENGTHS                                         61800020
LINUM1   EQU   7    FOR 1ST OPERAND OF SUBCOMMAND                       61900020
LINUM2   EQU   8    FOR 2ND OPERAND                                     62000020
CTR      EQU   8    OF SUBCOMMAND                                       62100020
COMMREG  EQU   9    BASE REG FOR COMM AREA                              62200020
PDLBASE  EQU   10   BASE REG FOR PARM DESCRIPTOR LIST                   62300020
BASEREG  EQU   11   GENERAL BASE REG                                    62400020
DATAREG  EQU   12                                                       62500020
SAVEREG  EQU   13   PT REG SAVE AREA                                    62600020
RETREG   EQU   14   ADDR RET PT IN RTN                                  62700020
INCRMENT EQU   14   INCREMENT IN 'BXLE' INSTRUCTION                     62760020
COMPRAND EQU   15   COMPARAND IN 'BXLE' INSTRUCTION                     62820020
CODEREG  EQU   15   RETURN CODE                                         63000020
RETCDREG EQU   15   RETURN CODE                                         63100020
CALDRTN@ EQU   15   ADDR CALLED RTN                                     63200020
 SPACE                                                                  63300020
* CONSTANTS                                                             63400020
 SPACE                                                                  63500020
RCNOTCOM EQU   8    RET CODE TO IND FUNCTION NOT COMPLETED.             63550020
O        EQU   0                                                        63600020
ONE      EQU   1                                                        63700020
BYTE     EQU   1                                                        63800020
TWO      EQU   2                                                        63900020
HAFWD    EQU   2                                                        64000020
LEEDNG0S EQU   3    MAX NO. OF LEADING ZEROES TO BE SUPPRESSED          64100020
FOUR     EQU   4                                                        64200020
WD       EQU   4                                                        64300020
DUBLWD   EQU   8                                                        64400020
NUML     EQU   9    LINE NO. = 8 BYTES (+1 BLANK)                       64500020
BLKL     EQU   20   LNG OF PUTLINE PARM BLOCK                           64600020
LO4TOHI4 EQU   28   FOR SHIFTING 4 BITS FR LO TO HI-ORDER IN REG        64700020
WHOLEDSN EQU   68                                                       64800020
MAXL     EQU   254                      MAX DATA LNG = 255 BYTES        64860020
*                                       (259 MINUS 4-BYTE HEADER).      64920020
NOUGHT   EQU   C'0'                                                     65000020
BLANK    EQU   C' '                                                     65100020
STAR     EQU   C'*'                                                     65200020
 SPACE                                                                  65300020
* MASKS                                                                 65400020
 SPACE                                                                  65500020
VERIFY   EQU   X'80'     TO FIND IF CALLED FOR VERIFY                   65600020
LASTPARM EQU   X'80'     TO IND LAST PARM IN LIST FOR IKJEBESR          65700020
ANYOPNDS EQU   X'80'     TO FIND IF ANY OPERANDS ON SUBCMD              65800020
READ1ST  EQU   X'04'     IKJEBEUT CODE FOR 'RD 1ST RCD'                 65900020
READCURR EQU   X'00'     IKJEBEUT CODE FOR 'RD CURR RECD'               66000020
SNUM     EQU   X'02'     TO FIND IF 'SNUM' SPEC                         66100020
READNEXT EQU   X'02'     IKJEBEUT CODE FOR 'READ NEXT RCD'              66200020
POSTED   EQU   X'40'     TO FIND IF ATTN ECB POSTED                     66300020
ZEROMASK EQU   X'00'     TO SET SINGLE BYTES TO ZERO                    66400020
 SPACE                                                                  66500020
* MESSAGE NUMBERS & INSERTION OFFSETS                                   66600020
 SPACE                                                                  66700020
         IKJEBEMI (312,313,500,501,502,503,504) MSG EQUATE MACRO        66800020
         END   IKJEBELT                                                 66900020
