BEMA     TITLE 'IKJEBEMA - MAIN CONTROLLER - EDIT CP TSO/360'           00080020
IKJEBEMA CSECT                                                          00160020
*A 671200,762900                                                SA62903 00165021
*A206410-206500,208800                                           A42952 00170021
*C209600                                                         A42952 00180021
*D207000-207800                                                  A42952 00190021
*A329600,596100-596800,604900-606200                             A42953 00200021
*D326400-332800,596800,605600                                    A42953 00210021
*C936800                                                         A42956 00217021
*A651600,731126-732126                                           A45002 00219021
*D730130-730132                                                  A45002 00221021
*A330600-332600                                                  A45102 00224021
*D323200-324800                                                  A45102 00231021
*A426900                                                          M2108 00234021
*C608800                                                          M2108 00237021
         ENTRY IKJEBEMA                                                 00240020
         EXTRN IKJEBEAE                                                 00320020
         EXTRN IKJEBEAT                                                 00400020
         EXTRN IKJEBEUT                                                 00480020
         EJECT                                                          00520020
*********************************************************************** 00560020
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 00610020
*                                                                     * 00660020
* FUNCTION --  THIS ROUTINE CONTROLS THE EDIT COMMAND PROCESSOR       * 00710020
*    AFTER THE INITIALIZATION PROCESS IS COMPLETE.                    * 00760020
*                                                                     * 00810020
*    INITIALLY THIS ROUTINE ISSUES THE STAX AND STAE MACRO            * 00860020
*    INSTRUCTIONS TO ESTABLISH THE ATTENTION EXIT AND THE             * 00910020
*    ABNORMAL END EXIT, RESPECTIVELY.  IF THE SCAN OPERAND WAS        * 00960020
*    SPECIFIED ON THE EDIT COMMAND OR IF THE DATA SET TYPE IS         * 01010020
*    BASIC OR IPLI, THE SCAN SUBCOMMAND (IKJEBESC) IS INVOKED TO      * 01060020
*    PERFORM INITIAL PROCESSING REQUIRED BY THE LANGUAGE              * 01110020
*    PROCESSOR (LANGPRCR).                                            * 01160020
*                                                                     * 01210020
*    AFTER ITS INITIALIZATION PROCESSING (ABOVE), IKJEBEMA            * 01260020
*    DETERMINES WHICH MODE IS TO BE ENTERED FIRST.  IF THE DATA       * 01310020
*    SET OR MEMBER IS NEW AND IS TO BE CREATED, INPUT MODE            * 01360020
*    (IKJEBEIP) IS INVOKED INITIALLY.  IF THE DATA SET OR MEMBER      * 01410020
*    IS OLD, SUBCOMMAND MODE IS ENTERED INITIALLY.                    * 01460020
*                                                                     * 01510020
*    IN SUBCOMMAND MODE, THIS ROUTINE TESTS 'CAMODMSG' TO DETERMINE   * 01560020
*    IF THE MODE MESSAGE IS TO BE ISSUED.  THE PUTGET SERVICE         * 01610020
*    ROUTINE IS INVOKED TO PUT THE MODE MESSAGE, IF NECESSARY,        * 01660020
*    AND TO GET A LINE OF INPUT (A SUBCOMMAND) FROM THE CURRENT       * 01710020
*    SOURCE.  IF THE LINE RETURNED BY PUTGET IS NULL, I.E., HAS       * 01760020
*    A LENGTH OF FOUR (4), CONTROL IS PASSED TO IKJEBEIP.             * 01810020
*    OTHERWISE, THE SCAN SERVICE ROUTINE IS CALLED TO SCAN OFF        * 01860020
*    THE SUBCOMMAND NAME.                                             * 01910020
*                                                                     * 01960020
*    WHEN A SUBCOMMAND NAME IS KNOWN, IT IS COMPARED WITH EACH        * 02010020
*    ABBREVIATION AND SUBCOMMAND NAME IN THE IBM TABLE OF             * 02060020
*    SUBCOMMANDS (IKJEBMA8).  IF NO MATCH IS FOUND, THE USER          * 02110020
*    TABLE OF SUBCOMMANDS (IKJEBMA9) IS ALSO SEARCHED.  IF A          * 02160020
*    MATCH IS FOUND, THE SUBCOMMAND PROCESSOR IS INVOKED VIA THE      * 02210020
*    IKJEBESH MACRO INSTRUCTION.  IF NO MATCH IS FOUND, AN ERROR      * 02260020
*    MESSAGE IS PUT OUT AND PROCESSING CONTINUES AS FOR SUBCOMMAND    * 02270020
*    RETURN CODE 08 (SEE BELOW).  UPON RETURN FROM A SUBCOMMAND       * 02280020
*    PROCESSOR, PROCESSING CONTINUES DEPENDING UPON THE RETURN        * 02310020
*    CODE (SEE BELOW).                                                * 02360020
*                                                                     * 02410020
*    RETURN CODE ZERO (00) -- THE ATTENTION ISSUED                    * 02460020
*    FLAG (CAATTNIS) IS CHECKED TO DETERMINE IF THE SUBCOMMAND        * 02510020
*    PROCESSOR WAS INTERRUPTED DUE TO AN ATTENTION.  IF AN            * 02560020
*    ATTENTION WAS ISSUED, CAATTNIS IS SET TO ZERO AND THE NEXT       * 02610020
*    SUBCOMMAND BUFFER TO BE PROCESSED IS POINTED TO BY CAPTIBFR      * 02660020
*    (SEE NOTES BELOW).  PROCESSING CONTINUES BY INVOKING THE         * 02710020
*    SCAN SERVICE ROUTINE AS ABOVE.  WHEN AN ATTENTION INTERRUPT      * 02760020
*    WAS NOT ISSUED, A TEST IS MADE TO DETERMINE IF A VERIFY          * 02810020
*    REQUEST IS PENDING (CALNTOVF AND CAVRFYSW BOTH SET TO ONE).      * 02860020
*    WHEN VERIFY HAS BEEN REQUESTED, THE MESSAGE SELECT ROUTINE       * 02910020
*    (IKJEBEMS) IS INVOKED TO PROCESS THE VERIFY REQUEST.             * 02960020
*    PROCESSING CONTINUES BY INVOKING THE PUTGET SERVICE ROUTINE      * 03010020
*    AS ABOVE.                                                        * 03060020
*                                                                     * 03110020
*    RETURN CODE FOUR (04) -- CONTROL IS PASSED TO IKJEBEIP.          * 03160020
*                                                                     * 03210020
*    RETURN CODE EIGHT (08) -- IF THE SOURCE OF INPUT TO EDIT IS      * 03220020
*    THE TERMINAL, A TCLEARQ IS ISSUED FOR THE INPUT AND OUTPUT       * 03230020
*    QUEUES, AND PROCESSING CONTINUES AS FOR RETURN CODE ZERO (0)     * 03240020
*    ABOVE.  IF THE SOURCE OF INPUT TO EDIT IS AN IN-CORE             * 03250020
*    PROCEDURE, EDIT IS TERMINATED (CLEARING QUEUES AND DELETING      * 03252020
*    ALL BUT THE TERMINAL FROM THE INPUT STACK).                      * 03254020
*                                                                     * 03256020
*    RETURN CODE 12 -- CONTROL IS RETURNED TO THE TMP (SEE            * 03260020
*    TERMINATION PROCESSING BELOW).                                   * 03310020
*                                                                     * 03360020
*    RETURN CODE 16 -- AN ERROR OCCURRED IN LANGPRCR.  SET            * 03410020
*    CASCRC20 AND INVOKE IKJEBESC TO ATTEMPT RECOVERY.                * 03460020
*                                                                     * 03510020
*    TERMINATION PROCESSING -- THIS ROUTINE TERMINATES THE EDIT       * 03560020
*    COMMAND PROCESSOR WHENEVER A RETURN CODE 12 IS RETURNED BY       * 03610020
*    A SUBCOMMAND PROCESSOR.  IF END SUBCOMMAND PROCESSING IS         * 03660020
*    COMPLETE (MAENDPRC IS ONE), THE COMMUNICATION AREA IS            * 03710020
*    FREEMAIN'D AND CONTROL IS RETURNED TO THE TMP WITH A RETURN      * 03760020
*    CODE OF ZERO (00).  WHEN END PROCESSING IS NOT COMPLETE, THE     * 03810020
*    END SUBCOMMAND PROCESSOR IS INVOKED TO PERFORM TERMINATION       * 03860020
*    PROCESSING.  AFTER END PROCESSING IS COMPLETE, CONTROL IS        * 03910020
*    RETURNED TO THE TMP WITH A RETURN CODE OF 12.                    * 03960020
*                                                                     * 04010020
*    STAE RETRY ROUTINE -- IKJEBEMA ALSO CONTAINS THE STAE RETRY      * 04060020
*    ROUTINE.  THIS ROUTINE GAINS CONTROL ONCE THE STAE EXIT HAS      * 04110020
*    PROCESSED SUCCESSFULLY.  THE RETRY ROUTINE RESTORES IKJEBEMA     * 04160020
*    REGISTERS, BUILDS AN END SUBCOMMAND IN CORE, AND BRANCHES        * 04210020
*    INTO THE MAINLINE CODE TO PROCESS THE SUBCOMMAND.                * 04260020
*                                                                     * 04310020
* ENTRY POINTS --                                                     * 04360020
*         IKJEBEMA -- VIA A TRANSFER OF CONTROL (XCTL) FROM THE       * 04410020
*                     INITIALIZATION ROUTINE (IKJEBEIN).              * 04460020
*                                                                     * 04510020
* INPUT --                                                            * 04560020
*    REGISTER ONE (1) CONTAINS A POINTER TO IKJEBECA, THE EDIT        * 04610020
*    COMMUNICATION AREA.                                              * 04660020
*                                                                     * 04710020
* OUTPUT --                                                           * 04760020
*    REGISTER 15 CONTAINS A RETURN CODE INDICATING WHETHER EDIT       * 04810020
*    COMPLETED SUCCESSFULLY.  RETURN CODES ARE --                     * 04860020
*    00 - SUCCESSFUL TERMINATION                                      * 04910020
*    12 - ABNORMAL TERMINATION.                                       * 04960020
*                                                                     * 05010020
* EXTERNAL REFERENCES --                                              * 05060020
*         IKJPTGT  - PUTGET SERVICE ROUTINE.                          * 05110020
*         IKJSCAN  - SCAN SERVICE ROUTINE.                            * 05160020
*         IKJSTACK - STACK SERVICE ROUTINE.                           * 05170020
*         IKJEBMA1 - MESSAGE PROCESSING ROUTINE.                      * 05210020
*         IKJEBMA2 - INPUT STACK CLEAN-UP ROUTINE.                    * 05260020
*         IKJEBMA8 - IBM SUBCOMMAND TABLE.                            * 05310020
*         IKJEBMA9 - USER SUBCOMMAND TABLE.                           * 05360020
*         IKJEBEAE - ABNORMAL END EXIT.                               * 05410020
*         IKJEBEAT - ATTENTION EXIT.                                  * 05460020
*         IKJEBEUT - ACCESS METHOD INTERFACE ROUTINE.                 * 05510020
*         IKJEBEBO - BOTTOM SUBCOMMAND PROCESSOR.                     * 05560020
*         IKJEBECH - CHANGE SUBCOMMAND PROCESSOR.                     * 05610020
*         IKJEBEDE - DELETE SUBCOMMAND PROCESSOR.                     * 05660020
*         IKJEBEDO - DOWN SUBCOMMAND PROCESSOR.                       * 05710020
*         IKJEBEEN - END SUBCOMMAND PROCESSOR.                        * 05760020
*         IKJEBEFI - FIND SUBCOMMAND PROCESSOR.                       * 05810020
*         IKJEBEFO - FORMAT SUBCOMMAND PROCESSOR.                     * 05860020
*         IKJEBEHE - HELP SUBCOMMAND PROCESSOR.                       * 05910020
*         IKJEBEIP - INPUT SUBCOMMAND PROCESSOR.                      * 05960020
*         IKJEBEIS - INSERT SUBCOMMAND PROCESSOR.                     * 06010020
*         IKJEBELI - IMPLICIT SUBCOMMAND PROCESSOR.                   * 06060020
*         IKJEBELT - LIST SUBCOMMAND PROCESSOR                        * 06110020
*         IKJEBEME - MERGE SUBCOMMAND PROCESSOR.                      * 06160020
*         IKJEBEPR - PROFILE SUBCOMMAND PROCESSOR.                    * 06210020
*         IKJEBERE - RENUM SUBCOMMAND PROCESSOR.                      * 06260020
*         IKJEBERU - RUN SUBCOMMAND PROCESSOR.                        * 06310020
*         IKJEBESA - SAVE SUBCOMMAND PROCESSOR.                       * 06360020
*         IKJEBESC - SCAN SUBCOMMAND PROCESSOR.                       * 06410020
*         IKJEBETA - TABSET SUBCOMMAND PROCESSOR.                     * 06460020
*         IKJEBETO - TOP SUBCOMMAND PROCESSOR.                        * 06510020
*         IKJEBEUP - UP SUBCOMMAND PROCESSOR.                         * 06560020
*         IKJEBEVE - VERIFY SUBCOMMAND PROCESSOR.                     * 06610020
*                                                                     * 06660020
*    MACROS USED --                                                   * 06710020
*                                                                     * 06760020
*         SAVE     - ENTRY LINKAGE.                                   * 06810020
*         STAX     - ESTABLISH ATTENTION EXIT.                        * 06860020
*         STAE     - ESTABLISH ABNORMAL END EXIT.                     * 06910020
*         LOAD     - OBTAIN LANGPRCR.                                 * 06960020
*         IKJEBESH - INVOKE EDIT ROUTINES.                            * 07010020
*         DELETE   - DELETE LANGPRCR FROM CORE.                       * 07060020
*         CALL     - BRANCH TO INTERNAL ROUTINE.                      * 07110020
*         PUTGET   - PUT MODE MESSAGE, GET SUBCOMMAND.                * 07160020
*         LINK     - INVOKE SERVICE FUNCTIONS.                        * 07210020
*         FREEMAIN - FREE COMMUNICATION AREA.                         * 07260020
*         RETURN   - RETURN CONTROL TO TMP.                           * 07310020
*         TCLEARQ  - ISSUED TO CLEAR INPUT OR OUTPUT QUEUES.          * 07320020
*         STACK    - ISSUED TO INVOKE STACK SERVICE ROUTINE.          * 07330020
*         IKJEBESV - EDIT ENTRY LINKAGE.                              * 07360020
*         IKJEBEML - INVOKE MESSAGE SELECT ROUTINE.                   * 07410020
*         IKJEBERT - EDIT EXIT LINKAGE.                               * 07460020
*         IKJEBEMG - BUILD INSERTION RECORD FOR MESSAGE.              * 07510020
*         IKJEBECA - MAPS EDIT COMMUNICATION AREA.                    * 07560020
*         IKJEBEMI - DEFINES SYMBOLIC NAMES FOR MESSAGES.             * 07610020
*         IKJCPPL  - MAPS COMMAND PROCESSOR PARAMETER LIST.           * 07660020
*         IKJECT   - MAPS ENVIRONMENT CONTROL TABLE.                  * 07710020
*         IKJCSOA  - MAPS SCAN OUTPUT AREA.                           * 07760020
*         IKJPGPB  - MAPS PUTGET PARAMETER BLOCK.                     * 07810020
*         IKJEBEST - BUILDS IBM AND USER SUBCOMMAND TABLES.           * 07860020
*                                                                     * 07910020
* * EXITS,NORMAL --                                                   * 07960020
*    RETURN TO THE TMP WITH A RETURN CODE ZERO (0) IN REGISTER 15     * 08010020
*                                                                     * 08060020
* EXITS,ERROR --                                                      * 08110020
*    RETURN TO THE TMP WITH A RETURN CODE 12 IN REGISTER 15.          * 08160020
*                                                                     * 08210020
* TABLES/WORK AREAS --                                                * 08260020
*    DATA AREAS DEFINED BY THIS MODULE --                             * 08310020
*    CAMAWKA -- IN IKJEBECA -- MAIN CONTROLLER WORK AREA.             * 08360020
*    CABFRPL -- IN IKJEBECA -- AUXILIARY BUFFER SPACE.                * 08410020
*    CASVAREA -- IN IKJEBECA -- MODULE SAVE AREA.                     * 08460020
*                                                                     * 08510020
*    DATA AREAS UPDATED BY THIS MODULE --                             * 08560020
*    IN IKJEBECA -- CAATTNIS, CAIMSC, CAINITSC, CALNTOVF, CAINPROC,   * 08610020
*    CAMODMSG, CAOPERND, CAPTGTBF, CASCRC20, CATPUTVF, CANXTSVA,      * 08660020
*    CAPTCHK, CAPTIBFR, CAPTLE, CAPTRTRY, CAPTSCMD, CASCMDLN,         * 08710020
*    CASTAEPL, CASTAXPL, CASRPLST, CAPTUT, CAPTAE, CAPTAT.            * 08760020
*                                                                     * 08810020
*    IN ECT -- ECTMSGF, ECTSCMD.                                      * 08860020
*                                                                     * 08910020
* ATTRIBUTES --                                                       * 08960020
*    READ ONLY, NON-PRIVILEGED, REFRESHABLE, RE-ENTRANT.              * 09010020
*                                                                     * 09060020
* CHARACTER CODE DEPENDENCY --                                        * 09110020
*    THIS MODULE IS DEPENDENT UPON THE EBCDIC COLLATING SEQUENCE      * 09160020
*    TO ISOLATE THE IMPLICIT SUBCOMMAND.                              * 09210020
*                                                                     * 09260020
* NOTES --                                                            * 09310020
*    (1) THE FOLLOWING CONVENTION IS USED BETWEEN A SUBCOMMAND        * 09360020
*    PROCESSOR AND IKJEBEMA TO INDICATE THAT THE NEXT SUBCOMMAND      * 09410020
*    IS ALREADY IN CORE --                                            * 09460020
*                                                                     * 09510020
*    CAATTNIS = 1 AND CAPTIBFR = THE ADDRESS OF THE NEW               * 09560020
*    SUBCOMMAND.                                                      * 09610020
*                                                                     * 09660020
*    (2) THE END SUBCOMMAND PROCESSOR USES THE MAIN CONTROLLER        * 09710020
*    WORK AREA (CAMAWKA) IN THE COMMUNICATION AREA.  THE              * 09760020
*    COMMUNICATION OF END PROCESSING BETWEEN THE END SUBCOMMAND       * 09810020
*    PROCESSOR AND IKJEBEMA IS DEPENDENT UPON BIT 2, BYTE 28 OF       * 09860020
*    CAMAWKA.  CARE MUST BE EXERCISED IN MODIFYING CAMAWKA IN         * 09910020
*    EITHER THIS MODULE OR IKJEBEEN.                                  * 09960020
*                                                                     * 10560020
*    (3) THIS MODULE IS DESCRIBED IN PROGRAM LOGIC MANUAL GY28-6773,  * 10580021
*    TSO COMMAND PROCESSOR PROGRAM LOGIC MANUAL, VOLUME 3, EDIT.      * 10600021
*                                                                     * 10620021
*********************************************************************** 10640020
         EJECT                                                          10720020
*********************************************************************** 10800020
*                                                                     * 10880020
*   GENERAL PURPOSE REGISTER EQUATES FOR THIS ROUTINE.                * 10960020
*                                                                     * 11040020
*********************************************************************** 11120020
PARMREG0 EQU   0                                                        11200020
PARMREG1 EQU   1              ADDRESS OF EDIT COMMUNICATION AREA.       11280020
COMMREG  EQU   9              BASE REGISTER USED TO REFERENCE           11360020
*                                  THE COMMUNICATION AREA               11440020
BASEREG  EQU   11             BASE REGISTER FOR THIS CSECT.             11520020
DATAREG  EQU   12             ADDRESS OF PARAMETER LIST PASSED          11600020
*                                  BY IMP.                              11680020
SAVEREG  EQU   13             ADDRESS OF ROUTINE SAVE AREA.             11760020
RETREG   EQU   14             ADDRESS OF RETURN POINT IN CALLING        11840020
*                                  MODULE.                              11920020
RETCDREG EQU   15             RETURN CODE RETURNED TO CALLING           12000020
*                                  ROUTINE.                             12080020
ATOBFREG EQU   2              ADDRESS OF ATTENTION EXIT OUTPUT          12160020
*                                  BUFFER.                              12240020
ATIBFREG EQU   4              ADDRESS OF ATTENTION EXIT INPUT           12320020
*                                  BUFFER.                              12400020
ATOSZREG EQU   3              SIZE OF OUTPUT BUFFER FOR ATTENTION       12480020
*                                  EXIT ROUTINE.                        12560020
ATISZREG EQU   5              SIZE OF INPUT BUFFER FOR ATTENTION        12640020
*                                  EXIT ROUTINE.                        12720020
EPLOCREG EQU   15             ADDRESS OF MODULE TO BE GIVEN             12800020
*                                  CONTROL.                             12880020
SCKNMREG EQU   2              SYNTAX CHECKER MODULE NAME.  (THIS        12960020
*                                  IS FLOATING POINT REGISTER 2).       13040020
TMPCDREG EQU   7              TEMPORARY RETURN CODE, REGISTER           13120020
*                                  USED TO TEST RETURN CODE FROM        13200020
*                                  SUBCOMMANDS                          13280020
IBFPTREG EQU   8              POINTER TO TERMINAL INPUT BUFFER.         13360020
UPTREG   EQU   2              ADDRESS OF UPT.                           13440020
PSCBREG  EQU   3              ADDRESS OF PSCB.                          13520020
ECTREG   EQU   4              ADDRESS OF ECT.                           13600020
MODEREG  EQU   4              ADDRESS OF EDIT MODE MESSAGE.             13680020
PTGTREG  EQU   5              ADDRESS OF PARAMETER LIST FOR             13760020
*                                  PUTGET SERVICE ROUTINE.              13840020
ECBREG   EQU   3              ADDRESS OF ATTENTION ECB.                 13920020
BRNCHREG EQU   3              BRANCH REGISTER USED FOR BRANCH           14000020
*                                  TABLE FOLLOWING RETURN FROM          14080020
*                                  IKJSCAN.  THIS MUST BE AN ODD        14160020
*                                  REGISTER.                            14240020
PTSCMREG EQU   2              POINTER TO SUBCOMMAND NAME.               14320020
SCLENREG EQU   3              LENGTH OF SUBCOMMAND AS RETURNED BY       14400020
*                                  IKJSCAN.                             14480020
TBLPTREG EQU   4              POINTER TO TABLE OF SUBCOMMANDS           14560020
*                                  (CURRENT ENTRY).                     14640020
TBLENREG EQU   5              LENGTH OF ENTRY IN SUBCOMMAND             14720020
*                                  TABLE.                               14800020
SCMDREG  EQU   6              ADDRESS OF SUBCOMMAND NAME FOR            14880020
*                                  IKJEBESR.                            14960020
LEV1REG  EQU   2              RELATIVE NUMBER OF FIRST LEVEL            15040020
*                                  MESSAGE.                             15120020
LEV2REG  EQU   3              RELATIVE NUMBER OF SECOND LEVEL           15200020
*                                  MESSAGE.                             15280020
INS1REG  EQU   4              ADDRESS OF INSERTION LIST FOR FIRST       15360020
*                                  LEVEL MESSAGE.                       15440020
INS2REG  EQU   5              ADDRESS OF INSERTION LIST FOR             15520020
*                                  SECOND LEVEL MESSAGE.                15600020
STAEREG  EQU   2              ADDRESS OF STAE EXIT ROUTINE.             15680020
SRRTNREG EQU   8              BRANCH REGISTER FOR RETURN FROM           15760020
*                                  SUBCOMMAND.                          15840020
R2       EQU   2              GENERAL REGISTER 2.                       15920020
R5       EQU   5              GENERAL REGISTER 5.                       16000020
         EJECT                                                          16080020
*********************************************************************** 16160020
*                                                                     * 16240020
*   PROLOG                                                            * 16320020
*                                                                     * 16400020
*********************************************************************** 16480020
         SAVE  (14,12),,*     SAVE ENTRY REGISTERS.                     16560020
         BALR  BASEREG,X0     ESTABLISH A BASE REGISTER AND             16640020
         USING *,BASEREG           ADDRESSABILITY FOR THIS CSECT.       16720020
MA000010 EQU   *                                                        16800020
         LR    COMMREG,PARMREG1 INITIALIZE ADDRESS OF AND               16880020
         USING IKJEBECA,COMMREG    ADDRESSABILITY TO EDITS              16960020
*                                  COMMUNICATION AREA.                  17040020
         LA    DATAREG,CASVAREA ADDRESS OF FIRST SAVE AREA IN           17120020
*                                  COMMUNICATION AREA.                  17200020
         ST    SAVEREG,X4(,DATAREG) CROSS CHAIN SAVE AREAS AND          17280020
         ST    DATAREG,X8(,SAVEREG) LOAD SAVEREG WITH FIRST SAVE        17360020
         LR    SAVEREG,DATAREG     AREA IN COMMUNICATION AREA.          17440020
         LA    DATAREG,X72(,DATAREG) COMPUTE ADDRESS OF NEXT SAVE       17520020
         ST    DATAREG,CANXTSVA AREA AND SAVE IN THE                    17600020
*                                  COMMUNICATION AREA.                  17680020
         SPACE 5                                                        17760020
*********************************************************************** 17840020
*                                                                     * 17920020
*   LOAD REMAINING PERMANENTLY RESIDENT SERVICE ROUTINES.             * 18000020
*   (IKJEBEAE, IKJEBEAT, IKJEBELE)                                    * 18080020
*                                                                     * 18160020
*********************************************************************** 18240020
         LOAD  EP=IKJEBELE    LOAD LINE EDIT ROUTINE.                   18320020
         ST    PARMREG0,CAPTLE SAVE ADDRESS IN THE                      18400020
*                                  COMMUNICATION AREA.                  18480020
         MVC   CAPTUT(L'MAPTUT),MAPTUT SET UP ADDRESS OF IKJEBEUT       18560020
         EJECT                                                          18640020
MASTAX   EQU   *                                                        18720020
*********************************************************************** 18800020
*                                                                     * 18880020
*   ESTABLISH AN ATTENTION INTERRUPT EXIT FOR THE EDIT COMMAND        * 18960020
*   PROCESSING PROGRAM.  THE MACRO SPECIFIES THE ATTENTION EXIT       * 19040020
*   BUFFER, AND THE EXIT MESSAGE CONTAINED IN THIS CSECT.  THE USER   * 19120020
*   ADDRESS SPECIFIED IS THAT OF EDITS COMMUNICATION AREA.  THIS IS   * 19200020
*   THE ONLY ATTENTION EXIT TO BE ESTABLISHED FOR THIS COMMAND        * 19280020
*   PROCESSOR.                                                        * 19360020
*                                                                     * 19440020
*********************************************************************** 19520020
         L     EPLOCREG,MAPTAT OBTAIN ENTRY POINT ADDRESS OF            19600020
*                                  IKJEBEAT (ATTENTION EXIT).           19680020
         LA    ATOBFREG,CAMODETX+X1 ADDRESS OF EDIT MESSAGE TO BE       20240020
*                                  ISSUED ON ENTRY TO ATTENTION         20320020
*                                  EXIT.                                20400020
         LH    ATOSZREG,CAMODELN LENGTH OF EDIT MODE MESSAGE.           20480020
         LA    PARMREG1,X5(,X0) REDUCE LENGTH BY 5 FOR INSERTION.       20560020
         SR    ATOSZREG,PARMREG1   HEADER WORD.                         20640020
         LA    ATIBFREG,CATEMPBF SPECIFY VALID ADDRESS FOR INPUT A42952 20641021
*                                  BUFFER - NO DATA TRANSFER     A42952 20642021
*                                  TO THIS BUFFER WILL BE        A42952 20643021
*                                  MADE DURING ATTN PROCESSING,  A42952 20644021
*                                  HOWEVER.                      A42952 20645021
         SR    ATISZREG,ATISZREG INPUT BUFFER LENGTH OF ZERO     A42952 20646021
*                                  SPECIFIES NO DATA TRANSFER,   A42952 20647021
*                                  WHICH ALLOWS IKJEBEAT TO      A42952 20648021
*                                  OBTAIN A LOGICAL LINE FROM    A42952 20649021
*                                  THE TERMINAL                  A42952 20650021
         MVC   CASTAXPL(MASTAXLN),MASTAXLF MOVE LIST-FORM               20660020
*                                  PARAMETERS TO DYNAMIC AREA.          20680020
         STAX  (EPLOCREG),OBUF=((ATOBFREG),(ATOSZREG)),                X20800020
               IBUF=((ATIBFREG),(ATISZREG)),USADDR=(COMMREG),    A42952X20880021
               REPLACE=YES,MF=(E,CASTAXPL)  ESTABLISH ATTN EXIT  A42952 20960021
*                                                                       21040020
*   UPON RETURN FROM STAX, TEST RETURN CODE IN REGISTER 15 FOR          21120020
*   SUCCESSFUL COMPLETION .  WHEN NO ATTENTION EXIT WAS CREATED,        21200020
*   PUT MESSAGE TO TERMINAL AND RETURN TO TMP.                          21280020
*                                                                       21360020
         LTR   RETCDREG,RETCDREG TEST FOR RETURN CODE ZERO.             21440020
         BZ    MASTAE         IF ZERO, BRANCH TO ESTABLISH              21520020
*                                  ABNORMAL END EXIT.                   21600020
         LA    INS1REG,M1MLSTAX INDEX TO INSERTION FOR COMMAND          21680020
*                                  SYSTEM ERROR MESSAGE.                21760020
         B     MATERMED       BRANCH TO TERMINATE EDIT.                 21840020
         EJECT                                                          21920020
MASTAE   EQU   *                                                        22000020
*********************************************************************** 22080020
*                                                                     * 22160020
*   ESTABLISH AN ABNORMAL END EXIT FOR THE EDIT COMMAND PROCESSING    * 22240020
*   PROGRAM.  INITIALIZE THE ADDRESS OF THE STAE RETRY ROUTINE IN     * 22320020
*   THE COMMUNICATION AREA.  IF UNABLE TO ESTABLISH AN ABNORMAL       * 22400020
*   END EXIT, RETURN TO THE TMP.                                      * 22480020
*                                                                     * 22560020
*********************************************************************** 22640020
         LA    EPLOCREG,MAAERTRY OBTAIN ADDRESS OF STAE RETRY           22720020
         ST    EPLOCREG,CAPTRTRY   ROUTINE AND SAVE IN THE              22800020
*                                  COMMUNICATION AREA.                  22880020
         L     STAEREG,MAPTAE ADDRESS OF STAE EXIT ROUTINE.             22960020
         MVC   CASTAEPL(MASTAELN),MASTAELF MOVE LIST-FORM               22980020
*                                  PARAMETERS TO DYNAMIC AREA.          23000020
         STAE  (STAEREG),CT,PARAM=(COMMREG),XCTL=YES,                  X23040020
               MF=(E,CASTAEPL)     ESTABLISH STAE EXIT.                 23120020
*                                                                       23200020
*   UPON RETURN FROM STAE, TEST RETURN CODE IN REGISTER 15 FOR          23280020
*   SUCCESSFUL COMPLETION.  WHEN NO ABNORMAL END EXIT WAS CREATED,      23360020
*   PUT MESSAGE TO THE TERMINAL AND RETURN TO THE TMP.                  23440020
*                                                                       23520020
         LTR   RETCDREG,RETCDREG TEST FOR RETURN CODE ZERO.             23600020
         BZ    MAPREPRC       IF ZERO, BRANCH TO CHECK IF A             23680020
*                                  PREPROCESSOR IS NECESSARY.           23760020
         LA    INS1REG,M1MLSTAE INDEX TO INSERTION FOR COMMAND          23840020
*                                  SYSTEM ERROR MESSAGE.                23920020
         B     MATERMED       BRANCH TO TERMINATE EDIT.                 24000020
         EJECT                                                          24080020
MAPREPRC EQU   *                                                        24160020
*********************************************************************** 24240020
*                                                                     * 24320020
*   DETERMINE IF A PREPROCESSOR (FOR BASIC OR IPLI) OR A SYNTAX       * 24400020
*   CHECKER (FOR PLI, FORT, OR GOFORT) IS REQUIRED.                   * 24480020
*                                                                     * 24560020
*   1. TEST FOR DATA SET TYPE BASIC OR IPLI.  IF EITHER, CHECK IF     * 24640020
*      PREPROCESSOR IS AVAILABLE.  IF PREPROCESSOR IS AVAILABLE. LOAD * 24720020
*      PREPROCESSOR AND INVOKE SCAN SUBCOMMAND TO INITIALIZE          * 24800020
*      INTERFACE.  IF PREPROCESSOR NOT AVAILABLE, INVOKE MESSAGE      * 24880020
*      SELECTION ROUTINE TO INFORM USER.                              * 24960020
*                                                                     * 25040020
*   2. WHEN DATA SET TYPE IS NOT BASIC OR IPLI, TEST SCAN FLAG TO     * 25120020
*      DETERMINE IF SYNTAX CHECKING TO BE USED.  WHEN THE SCAN FLAG   * 25200020
*      IS OFF, CONTINUE PROCESSING.  WHEN THE SCAN FLAG IS ON, CHECK  * 25280020
*      IF SYNTAX CHECKER IS AVAILABLE.  IF SYNTAX ECHECKER IS         * 25360020
*      AVAILABLE, LOAD SYNTAX CHECKER AND INVOKE SCAN SUBCOMMAND TO   * 25440020
*      INITIALIZE INTERFACE.  IF SYNTAX CHECKER IS NOT AVAILABLE.     * 25520020
*      INVOKE MESSAGE SELECTION ROUTINE TO INFORM USER.               * 25600020
*                                                                     * 25680020
*********************************************************************** 25760020
         OI    CACFLAG2,CAMODMSG INDICATE THAT MODE MESSAGE TO BE       25840020
*                                  ISSUED.                              25920020
         CLI   CADSCODE,CABASIC CHECK IF DATA SET TYPE IS BASIC.        26000020
         BE    MA001010       BRANCH TO LOAD SYNTAX CHECKER.            26080020
         CLI   CADSCODE,CAIPLI CHECK IF DATA SET TYPE IS LEARNERS       26160020
*                                  LANGUAGE.                            26240020
         BE    MA001010       BRANCH TO LOAD SYNTAX CHECKER.            26320020
         TM    CACFLAG2,CASCANON CHECK IF SYNTAX CHECKING TO BE         26400020
*                                  INVOKED.                             26480020
         BZ    MADSSTAT       IF NOT, BRANCH TO CHECK DATA SET          26560020
*                                  STATUS (NEW OR OLD).                 26640020
MA001010 EQU   *                                                        26720020
         LD    SCKNMREG,CASYNAME OBTAIN NAME OF SYNTAX CHECKER          26800020
         LTDR  SCKNMREG,SCKNMREG   AND DETERMINE IF MODULE IS IN        26880020
*                                  SYSTEM.                              26960020
         BZ    MADSSTAT       IF SYNTAX CHECKER NOT PRESENT,            27040020
*                                  BRANCH TO CHECK DATA SET             27120020
*                                  STATUS.                              27200020
MA001020 EQU   *                                                        27280020
         LA    PARMREG0,CASYNAME ADDRESS OF MODULE NAME FOR             27360020
*                                  SYNTAX CHECKER/PREPROCESSOR.         27440020
         LOAD  EPLOC=(0)      LOAD SYNTAX CHECKER/PREPROCESSOR.         27520020
         ST    PARMREG0,CAPTCHK SAVE ENTRY POINT ADDRESS FOR            27600020
*                                  SYNTAX CHECKER.                      27680020
         EJECT                                                          27760020
*********************************************************************** 27840020
*                                                                     * 27920020
*   INVOKE SCAN SUBCOMMAND (IKJEBESC) TO INITIALIZE SYNTAX            * 28000020
*   CHECKER INTERFACE.                                                * 28080020
*                                                                     * 28160020
*   BUILD SCAN ''ON'' COMMAND IN TERMINAL INPUT BUFFER AND TURN ON    * 28240020
*   FLAG TO INDICATE THAT SCAN IS BEING CALLED BY IKJEBEMA.           * 28320020
*                                                                     * 28400020
*********************************************************************** 28480020
         LA    BRNCHREG,MADSSTAT SET BRANCH ADDRESS FOR                 28646020
*                                  SUCCESSFUL RETURN FROM SCAN.         28652020
*                                  SCAN CAN BE CALLED AT MOST           28658020
*                                  THREE TIMES -- 1. TO PERFORM         28664020
*                                  INITIAL ENTRY, 2. TO ATTEMPT         28670020
*                                  RECOVERY, AND 3. TO CLEAN-UP         28676020
*                                  IF RECOVERY IS NOT POSSIBLE.         28682020
*                                  THIS ADDRESS MUST REMAIN FOR         28688020
*                                  ALL THREE SITUATIONS SO THAT         28694020
*                                  THE INITIAL MODE MAY BE              28700020
*                                  DETERMINED.                          28706020
MASCANON EQU   *                                                        28720020
         OI    CACFLAG1,CAINITSC INDICATE TO SCAN THAT INITIAL          28770020
*                                  CALL IS FROM THE CONTROLLER.         28772020
         MVC   CABFRPL(SCNONEND-SCNONMSG),SCNONMSG MOVE SCAN            28780020
*                                  ON MESSAGE TO GOTTEN CORE.           28880020
         LA    PARMREG1,CABFRPL OBTAIN ADDRESS OF SCAN ON               28960020
*                                  MESSAGE                              29040020
         ST    PARMREG1,CAPTIBFR PLACE ADDRESS OF DUMMY                 29120020
*                                  SUBCOMMAND IN COMMUNICATION          29200020
*                                  AREA FOR IKJEBESC.                   29280020
         MVI   CAPTIBFR,CAOPERND INDICATE THAT OPERANDS ARE             29360020
*                                  PRESENT ON SUBCOMMAND.               29440020
         IKJEBESH (COMMREG),IKJEBESC,PARAM=((COMMREG)),                X29520020
               MF=(E,MASRPLST) INVOKE IKJEBESC FOR INITIAL ENTRY.       29600020
         LTR   RETCDREG,RETCDREG TEST RETURN CODE FROM IKJEBESC.        29840020
         BNZ   MASCERR        IF NOT ZERO, BRANCH TO DIAGNOSE ERROR.    29842020
         NI    CACFLAG1,X255-CAINITSC TURN OFF INITIAL CALL FLAG        29850020
*                                  FOR IKJEBESC.                        29860020
         BR   BRNCHREG        BRANCH TO EXECUTE INITIAL MODE            29880020
*                                  DETERMINATION (IF SCAN WAS           29920020
*                                  CALLED FOR INITIAL ENTRY) OR         29960020
*                                  TO CHECK FOR AN ATTENTION (IF        30000020
*                                  SCAN WAS CALLED FOR RECOVERY).       30040020
MASCERR  EQU   *                                                        30050020
         LA    TMPCDREG,RCODE12 CREATE CONSTANT FOR RETURN CODE         30080020
*                                  TEST.                                30160020
         CR    TMPCDREG,RETCDREG TEST FOR RETURN CODE 12.               30240020
         BE    MAEXIT         IF RETURN CODE IS 12, BRANCH TO           30320020
*                                  TERMINATE EDIT.                      30400020
         B     MASYNR20       FOR RETURN CODE = 16, BRANCH TO           30480020
*                                  ATTEMPT SYNTAX CHECKER               30560020
*                                  RECOVERY.                            30640020
         EJECT                                                          30720020
MADSSTAT EQU   *                                                        30800020
*********************************************************************** 30880020
*                                                                     * 30960020
*   DETERMINE STATUS OF EDIT DATA SET.                                * 31040020
*                                                                     * 31120020
*   TEST NEW/OLD DATA SET FLAG.  IF DATA SET IS NEW, INVOKE INPUT     * 31200020
*   MODE TO PROCESS INPUT DATA FROM TERMINAL.   IF DATA SET IS OLD,   * 31280020
*   BRANCH TO OBTAIN SUBCOMMAND FROM TERMINAL.                        * 31360020
*                                                                     * 31440020
*********************************************************************** 31520020
         TM    CAEDFLAG,CAEDMEM+CAEDDISP CHECK IF MEMBER EXISTS         31600020
*                                  AND IF DATA SET IS OLD.              31680020
         BO    MAGETSUB       IF BOTH OLD, BRANCH TO GET                31760020
*                                  SUBCOMMAND.                          31840020
         BZ    MAINPUT        IF BOTH NEW, BRANCH TO INVOKE INPUT       31920020
         TM    CAEDFLAG,CAEDDSOR CHECK IF A SEQUENTIAL DATA SET.        32000020
         BZ    MAGETSUB       IF SEQUENTIAL, BRANCH TO GET              32080020
*                                  SUBCOMMAND.                          32160020
MAINPUT  EQU   *                                                        32240020
         TM    CAATTN,CAATTNIS CHECK IF ATTENTION WAS ISSUED.           32560020
         BO    MA002056       YES, GO PROCESS ATTN BUFFER        A42953 32960021
         OI    CACFLAG3,CAIMSC INDICATE TO INPUT MODE THAT CALL  A45102 33060021
*                                  WAS RESULT OF NULL LINE OR    A45102 33160021
*                                  NEW DATA SET                  A45102 33260021
MA001075 EQU   *                                                        33360020
         BAL   BRNCHREG,MAFREEBF BRANCH TO FREE INPUT BUFFER.           33440020
MA001077 EQU   *                                                        33520020
*                                                                       33600020
*   INITIALIZE VALUES SO THAT INPUT SUBCOMMAND NAME CAN BE MOVED        33680020
*   INTO THE ENVIRONMENT CONTROL TABLE (ECT).                           33760020
*                                                                       33840020
         L     SCMDREG,MAEBEIP ADDRESS OF INPUT MODE ENTRY IN           33920020
*                                  SUBCOMMAND NAME TABLE.               34000020
         LA    TBLENREG,L'MACONS2-X1(,X0) LENGTH AND ADDRESS OF         34080020
         LA    PTSCMREG,MACONS2    NAME FOR MOVE TO ECT.                34160020
         B     MA002055       BRANCH TO INVOKE INPUT SUBCOMMAND.        34240020
         EJECT                                                          34320020
MAGETSUB EQU   *                                                        34400020
*********************************************************************** 34480020
*                                                                     * 34560020
*   OBTAIN SUBCOMMAND FROM TERMINAL USER                              * 34640020
*                                                                     * 34720020
*   AT END OF SUBCOMMAND PROCESSING OR AT COMPLETION OF INPUT MODE    * 34800020
*   PROCESSING, INVOKE THE PUTGET SERVICE ROUTINE TO PUT THE ''EDIT'' * 34880020
*   MODE MESSAGE AND TO OBTAIN THE NEXT SUBCOMMAND.  PROCESSING UPON  * 34960020
*   RETURN FROM GETLINE DEPENDS UPON RETURN CODE RECEIVED.            * 35040020
*                                                                     * 35120020
*********************************************************************** 35200020
         LA    PTGTREG,MAPGPB ADDRESS OF PUTGET WORK AREA.              35280020
         MVC   MAPGPB(PTGTPLEN),PTGTPLST MOVE PARAMETER BLOCK           35360020
*                                  FOR PUTGET TO WORK AREA.             35440020
         SR    MODEREG,MODEREG SHOW NO MODE MESSAGE.                    35520020
         TM    CACFLAG2,CAMODMSG CHECK IF MODE MESSAGE TO BE            35600020
*                                  ISSUED.                              35680020
         BZ    MANOMODE       IF NOT, BRANCH TO GET LINE.               35760020
         NI    CACFLAG2,X255-CAMODMSG INDICATE MODE MESSAGE             35840020
*                                  ISSUED.                              35920020
         LA    MODEREG,CAMODEMG ADDRESS OF MODE MESSAGE.                36000020
MANOMODE EQU   *                                                        36080020
         PUTGET PARM=(PTGTREG),OUTPUT=((MODEREG),SINGLE,MODE),         X36160020
               MF=(E,CATMPLST) GET SUBCOMMAND.                          36240020
*                                                                       36320020
*   RETURN CODE BRANCH TABLE UPON RETURN FROM PUTGET.  THIS BRANCH      36400020
*   TABLE ASSUMES THAT RETURN CODES ARE 0, 4, 8, 12, 16, 20, 24,        36480020
*   OR 28.                                                              36560020
*                                                                       36640020
MAPTBRTB EQU   *                                                        36720020
         B     MAPTBRTB+X4(RETCDREG) BRANCH TO APPROPRIATE              36800020
*                                  PROCESSING AFTER PUTGET.             36880020
         B     MASCANTM       RC = 00 -- BRANCH TO CALL IKJSCAN.        36960020
*                                  INDICATE TERMINAL AS SOURCE          37010020
*                                  OF INPUT TO EDIT.                    37020020
         B     MASCANPR       RC = 04 -- BRANCH TO CALL IKJSCAN.        37040020
*                                  INDICATE IN-CORE PROCEDURE           37090020
*                                  AS SOURCE OF INPUT TO EDIT.          37100020
         B     MACKATTN       RC = 08 -- BRANCH TO PROCESS AS           37120020
*                                  ATTENTION AFTER SUBCOMMAND.          37200020
         B     MADLTMSG       RC = 12 -- BRANCH TO SET ECTSMSG          37280020
         B     MAPTGTER       RC = 16 )                                 37360020
         B     MAPTGTER       RC = 20 ) BRANCH TO PUT MESSAGE           37440020
         B     MAPTGTER       RC = 24 ) AND TO TERMINATE.               37520020
*                             RC = 28)                                  37600020
         SPACE 5                                                        37680020
MANOCORE EQU   *                                                        37760020
*********************************************************************** 37840020
*                                                                     * 37920020
*   WHEN NO MAIN STORAGE IS AVAILABLE, BRANCH TO PUT MESSAGE AND      * 38000020
*   TO TERMINATE EDIT.                                                * 38080020
*                                                                     * 38160020
*********************************************************************** 38240020
         LA    LEV1REG,M1ERROR1 RELATIVE ERROR TO BE PROCESSED.         38320020
         B     MACALMSG       BRANCH TO PUT MESSAGE.                    38400020
         SPACE 5                                                        38480020
MAPTGTER EQU   *                                                        38560020
*********************************************************************** 38640020
*                                                                     * 38720020
*   FOR A RETURN CODE WHICH IS NOT MEANINGFUL TO IKJEBEMA, ISSUE      * 38800020
*   COMMAND SYSTEM ERROR MESSAGE AND TERMINATE.                       * 38880020
*                                                                     * 38960020
*********************************************************************** 39040020
         LA    INS1REG,M1MLPTGT INDEX TO INSERTION FOR COMMAND          39120020
*                                  SYSTEM ERROR MESSAGE.                39200020
         B     MATERMED       BRANCH TO TERMINATE EDIT.                 39280020
         SPACE 5                                                        39360020
MADLTMSG EQU   *              FREE SECOND LEVEL MESSAGES.               39440020
*********************************************************************** 39520020
*                                                                     * 39600020
*   IKJPTGT RETURNED A RETURN CODE OF 12 - A SECOND LEVEL MESSAGE     * 39680020
*   CHAIN EXISTS AND THE USER IS IN A PROCEDURE.                      * 39760020
*                                                                     * 39840020
*   THIS SECTION OF CODE WILL RESET THE ECTMSGF IN THE ECT AND        * 39920020
*   RE-ISSUE THE PUTGET MACRO INSTRUCTION.                            * 40000020
*                                                                     * 40080020
*********************************************************************** 40160020
         L     DATAREG,CAPTECT ADDRESS OF ECT.                          40240020
         OI    (ECTMSGF-ECT)(DATAREG),MANO2MSG INDICATE THAT ALL        40320020
*                                  SECOND LEVEL MESSAGES ARE TO         40400020
*                                  BE FLUSHED.                          40480020
         OI    MACFLAGS,MAECTMOD INDICATE THAT ECT WAS MODIFIED.        40560020
         B     MANOMODE       BRANCH TO RE-ISSUE PUTGET.                40640020
         EJECT                                                          40720020
*********************************************************************** 40880020
*                                                                     * 40960020
*   UPON RETURN FROM IKJPTGT, PLACE ADDRESS OF INPUT BUFFER IN THE    * 41040020
*   COMMUNICATION AREA AND INDICATE THAT INPUT BUFFER IS TO BE FREED  * 41120020
*   ON EXIT OUT OF A SUBCOMMAND PROCESSOR.  INVOKE THE COMMAND SCAN   * 41200020
*   SERVICE ROUTINE (IKJSCAN) TO SCAN THE INPUT BUFFER FOR A          * 41280020
*   SUBCOMMAND NAME.  INDICATE TO IKJSCAN THAT INPUT BUFFER IS TO BE  * 41360020
*   SYNTAX CHECKED.  UPON RETURN FROM IKJSCAN, BRANCH TO APPROPRIATE  * 41440020
*   PROCESSING DEPENDING UPON THE RETURN FLAGS.                       * 41520020
*                                                                     * 41600020
*********************************************************************** 41680020
MASCANTM EQU   *                                                        41730020
         NI    CACFLAG4,X255-CAINPROC INDICATE THAT CURRENT             41740020
*                                  SOURCE OF INPUT IS THE TERMINAL.     41750020
         B     MASCANSC            BRANCH TO INVOKE IKJSCAN.            41752020
MASCANPR EQU   *                                                        41754020
         OI    CACFLAG4,CAINPROC INDICATE THAT CURRENT SOURCE OF        41756020
*                                  INPUT IS AN IN-CORE PROCEDURE.       41758020
MASCANSC EQU   *                                                        41758420
         TM    MACFLAGS,MAECTMOD CHECK IF ECT WAS MODIFIED.             41760020
         BZ    MASCAN         IF NOT, BRANCH TO INVOKE IKJSCAN.         41840020
         NI    (ECTMSGF-ECT)(DATAREG),X255-MANO2MSG RESTORE             41920020
*                                  SETTING OF SECOND LEVEL              42000020
*                                  MESSAGE FLAG IN ECT.                 42080020
         NI    MACFLAGS,X255-MAECTMOD SHOW ECT NO LONGER MODIFIED       42160020
MASCAN   EQU   *                                                        42240020
         L     IBFPTREG,(PGPBIBUF-PGPB)(,PTGTREG) ADDRESS OF            42320020
*                                  INPUT BUFFER.                        42400020
         ST    IBFPTREG,CAPTIBFR SAVE ADDRESS OF INPUT BUFFER IN        42480020
*                                  THE COMMUNICATION AREA.              42560020
         OI    CACFLAG4,CAPTGTBF INDICATE THAT IKJPTGT GOT BUFFER       42640020
MA001072 EQU   *                                                  M2108 42680021
         LH    PARMREG0,X0(,IBFPTREG) GET BUFFER LENGTH FIELD OF        42720020
         LA    PARMREG1,X4(,X0)    INPUT BUFFER AND COMPARE WITH        42800020
         CR    PARMREG0,PARMREG1   LENGTH OF CONTROL WORD (4). IF       42880020
         BE    MAINPUT             EQUAL, A NULL LINE WAS ENTERED       42960020
*                                  BRANCH TO CALL INPUT MODE.           43040020
MA001080 EQU   *                                                        43120020
         LA    UPTREG,MASCNFLG ADDRESS OF FLAG WORD.                    43200020
*                                  BUFFER.                              43280020
         XC    MASCNFLG(L'MASCNFLG),MASCNFLG ZERO FLAG WORD.            43360020
         OI    MASCNFLG,MANOSCHK INDICATE TO IKJSCAN THAT NO            43440020
*                                  SYNTAX CHECKING IS TO BE DONE.       43520020
         LA    ECBREG,MASCNOA ADDRESS OF OUTPUT AREA FOR                43600020
*                                  IKJSCAN.                             43680020
         LINK  EP=IKJSCAN,PARAM=(,,,(UPTREG),(ECBREG),                 X43760020
               (IBFPTREG)),MF=(E,CATMPLST)                             X43840020
                              LINK TO IKJSCAN TO SCAN COMMAND.          43920020
         LTR   RETCDREG,RETCDREG TEST RETURN CODE FROM IKJSCAN.         44000020
         BZ    MA001090       IF ZERO, BRANCH TO VERIFY                 44080020
*                                  SUBCOMMAND NAME.                     44160020
         LA    INS1REG,M1MLSCAN INDEX TO INSERTION FOR COMMAND          44240020
*                                  SYSTEM ERROR MESSAGE.                44320020
         B     MATERMED       BRANCH TO TERMINATE EDIT.                 44400020
MA001090 EQU   *                                                        44480020
         SR    BRNCHREG,BRNCHREG ZERO BRANCH TABLE REGISTER.            44560020
         IC    BRNCHREG,MASCNOA+(CSOAFLG-CSOA) OBTAIN RESULT OF         44640020
*                                  IKJSCAN PROCESSING.                  44720020
         LA    BRNCHREG,X1(BRNCHREG,BRNCHREG) APPEND LOW ORDER          44800020
         SLL   BRNCHREG,X22(X0)    ONE BIT TO FLAG BYTE AND SHIFT       44880020
*                                  INTO PROSITION.                      44960020
         BXLE  BRNCHREG,BRNCHREG,MACMDOPN FLGS = X'80' - COMMAND        45040020
*                                  NAME VALID, CONTAINS OPERANDS.       45120020
         BXLE  BRNCHREG,BRNCHREG,MACMDNOP FLAGS = X'40' - COMMAND       45200020
*                                  NAME VALID, NO OPERANDS.             45280020
         BXLE  BRNCHREG,BRNCHREG,MA004010 FLAGS = X'20' -               45360020
*                                  QUESTION MARK ENCOUNTERED.           45440020
         BXLE  BRNCHREG,BRNCHREG,MACKATTN FLAGS = X'10' - BUFFER        45520020
*                                  IS EMPTY.                            45600020
         BXLE  BRNCHREG,BRNCHREG,MA004010 FLAGS = X'08' - INVALID       45680020
*                                  COMMAND ENCOUNTERED.                 45760020
         EJECT                                                          45840020
*********************************************************************** 45920020
*                                                                     * 46000020
*   VERIFY SUBCOMMAND NAME.                                           * 46080020
*                                                                     * 46160020
*   USING THE SUBCOMMAND NAME ENTERED BY THE USER. SEARCH THE TABLE   * 46240020
*   OF VALID EDIT SUBCOMMANDS AND ABBREVIATIONS.  WHEH THE            * 46320020
*   SUBCOMMAND NAME ENTERED BY THE USER IS NOT FOUND, ISSUE AN        * 46400020
*   INVALID SUBCOMMAND MESSAGE TO THE TERMINAL.  FOR A VALID EDIT     * 46480020
*   SUBCOMMAND OTHER THAN ''END'', CALL THE SERVICE ROUTINE HANDLER   * 46560020
*   (IKJEBESR) TO INVOKE THE APPROPRIATE SUBCOMMAND PROCESSOR.  IF    * 46640020
*   AN ''END'' SUBCOMMAND WAS ENTERED, BRANCH TO PERFORM END          * 46720020
*   PROCESSING.                                                       * 46800020
*                                                                     * 46880020
*********************************************************************** 46960020
MACMDOPN EQU   *                                                        47040020
         MVI   CAPTIBFR,CAOPERND INDICATE TO SUBCOMMAND PROCESSOR       47120020
*                                  THAT SUBCOMMAND CONTAINS             47200020
*                                  OPERANDS.                            47280020
MACMDNOP EQU   *                                                        47360020
         L     PTSCMREG,MASCNOA+(CSOACNM-CSOA) ADDRESS OF CURRENT       47440020
*                                  SUBCOMMAND NAME.                     47520020
         LH    SCLENREG,MASCNOA+(CSOALNM-CSOA) LENGTH OF CURRENT        47600020
*                                  SUBCOMMAND NAME.                     47680020
         CH    SCLENREG,MAMAXCLN COMPARE SUBCOMMAND NAME LENGTH TO      47730020
*                                  MAXIMUM ALLOWABLE.                   47740020
         BH    MA004020       IF LENGTH EXCEEDS MAXIMUM, BRANCH         47750020
*                                  TO SEND 'INVALID SUBCOMMAND'         47752020
*                                  MESSAGE.                             47754020
         ST    PTSCMREG,CAPTSCMD SAVE ADDRESS OF SUBCOMMAND NAME        47760020
         STH   SCLENREG,CASCMDLN   AND LENGTH FOR USE BY A              47840020
*                                  SUBCOMMAND PROCESSOR.                47920020
         BCTR  SCLENREG,X0    REDUCE LENGTH BY ONE FOR LINE             48000020
*                                  NUMBER COMPARISON.                   48080020
         EX    SCLENREG,MALNPPCK CHECK IF CURRENT SUBCOMMAND IS         48160020
*                                  A LINE NUMBER.                       48240020
         BL    MA002010       IF SUBCOMMAND NAME NOT NUMERIC,           48320020
*                                  BRANCH TO CHECK IF SUBCOMMAND        48400020
         LR    TBLENREG,SCLENREG LENGTH OF SUBCOMMAND NAME              48480020
*                                  FOR MOVE INTO ECT.                   48560020
         L     SCMDREG,MAEBELI ADDRESS OF SUBCOMMAND LOAD MODULE        48640020
*                                  NAME.                                48720020
         B     MA002055       BRANCH TO INVOKE SUBCOMMAND               48800020
*                                  PROCESSOR.                           48880020
MA002010 EQU   *                                                        48960020
         LA    SCLENREG,X1(,SCLENREG) ADD ONE TO LENGTH TO              49040020
*                                  REPRESENT ACTUAL LENGTH              49120020
*                                  RETURNED BY IKJSCAN.                 49200020
         SR    TBLENREG,TBLENREG INITIALIZE REGISTER TO CONTAIN         49280020
*                                  SUBCOMMAND LENGTH.                   49360020
         STH   TBLENREG,MACFLAGS ZERO FLAG BYTES.                       49440020
         L     TBLPTREG,MAIBMTBL ADDRESS OF IBM SUBCOMMAND TABLE.       49520020
MA002020 EQU   *                                                        49600020
         IC    TBLENREG,X0(,TBLPTREG) LENGTH OF CURRENT ENTRY           49680020
*                                  IN SUBCOMMAND NAME TABLE.            49760020
         CR    TBLENREG,SCLENREG DETERMINE IF THE LENGTH OF THE         49840020
*                                  CURRENT TABLE ENTRY EQUALS           49920020
*                                  THE LENGTH OF THE SUBCOMMAND         50000020
*                                  NAME ENTERED BY THE USER.            50080020
         BE    MA002040       WHEN LENGTHS ARE EQUAL, BRANCH TO         50160020
*                                  COMPARE SUBCOMMAND NAMES.            50240020
MA002030 EQU   *                                                        50320020
         CLI   X0(TBLPTREG),MATBLEND CHECK FOR END OF TABLE.            50400020
         BE    MA002045       IF END OF TABLE REACHED, BRANCH TO        50480020
*                                  CHECK IF BOTH SUBCOMMAND             50560020
*                                  TABLES HAVE BEEN SEARCHED.           50640020
         XI    MACFLAGS,MAABBREV INDICATE A TEST FOR HALF OF A          50720020
*                                  TABLE ENTRY.                         50800020
         BNZ   MA002035       IF ABBREVIATION FLAG WAS OFF,             50880020
*                                  BRANCH TO COMPUTE POINTER TO         50960020
*                                  ABBREVIATION.                        51040020
         LA    TBLPTREG,X9(TBLENREG,TBLPTREG) OTHERWISE, COMPUTE        51120020
*                                  A POINTER TO THE SUBCOMMAND          51200020
*                                  NAME IN THE NEXT TABLE ENTRY.        51280020
         B     MA002020       BRANCH TO CHECK NEXT SUBCOMMAND           51360020
*                                  NAME.                                51440020
MA002035 EQU   *                                                        51520020
         LA    TBLPTREG,X1(TBLENREG,TBLPTREG) COMPUTE ADDRESS OF        51600020
*                                  ABBREVIATION FOR THIS ENTRY.         51680020
         B     MA002020       BRANCH TO CHECK ABBREVIATION.             51760020
MA002040 EQU   *                                                        51840020
         BCTR  TBLENREG,X0    REDUCE TABLE ENTRY LENGTH BY ONE          51920020
*                                  FOR NAME COMPARISON.                 52000020
         EX    TBLENREG,MACMDCK DETERMINE IF SUBCOMMAND NAME            52080020
*                                  ENTERED BY USER IS THE SAME          52160020
*                                  AS CURRENT TABLE ENTRY.              52240020
         BE    MA002050       WHEN A MATCH IS FOUND, BRANCH TO          52320020
*                                  CALL THE SERVICE ROUTINE             52400020
*                                  HANDLER.                             52480020
         XI    MACFLAGS,MAABBREV INDICATE A TEST FOR HALF OF A          52560020
*                                  TABLE ENTRY.                         52640020
         BNZ   MA002043       IF ABBREVIATION FLAG WAS OFF,             52720020
*                                  BRANCH TO COMPUTE POINTER TO         52800020
*                                  ABBREVIATION.                        52880020
         LA    TBLPTREG,X10(TBLENREG,TBLPTREG) OTHERWISE, COMPUTE       52960020
*                                  A POINTER TO THE SUBCOMMAND          53040020
*                                  NAME IN THE NEXT TABLE ENTRY.        53120020
         B     MA002020       BRANCH TO CHECK NEXT SUBCOMMAND           53200020
*                                  NAME.                                53280020
MA002043 EQU   *                                                        53360020
         LA    TBLPTREG,X2(TBLENREG,TBLPTREG) COMPUTE ADDRESS OF        53440020
*                                  ABBREVIATION FOR THIS ENTRY.         53520020
         B     MA002020       BRANCH TO CHECK ABBREVIATION.             53600020
MA002045 EQU   *                                                        53680020
         XI    MACFLAG2,MATABLE1 INDICATE A TEST FOR IBM OR USER        53760020
*                                  SUBCOMMAND TABLE.                    53840020
         BZ    MA004020       WHEN BOTH TABLES HAVE BEEN SEARCHED       53920020
*                                  AND NO MATCH FOUND, BRANCH TO        54000020
*                                  PUT INVALID SUBCOMMAND MESSAGE       54080020
         L     TBLPTREG,MAUSRTBL ADDRESS OF USER SUBCOMMAND TABLE       54160020
         B     MA002020       BRANCH TO SEARCH USER TABLE.              54240020
MA002050 EQU   *                                                        54320020
         LA    SCMDREG,X2(TBLENREG,TBLPTREG) ADDRESS OF                 54400020
*                                  SUBCOMMAND NAME.                     54480020
         TM    MACFLAGS,MAABBREV CHECK IF THIS IS AN ABBREVIATION       54560020
*                                  ENTRY.                               54640020
         BO    MA002055       IF AN ABBREVIATION, BRANCH TO             54720020
*                                  INVOKE SUBCOMMAND PROCESSOR.         54800020
         SR    TBLPTREG,TBLPTREG ZERO LENGTH REGISTER.                  54810020
         IC    TBLPTREG,X0(,SCMDREG) OBTAIN LENGTH OF                   54880020
*                                  ABBREVIATION.                        54960020
         LA    SCMDREG,X1(TBLPTREG,SCMDREG) COMPUTE ADDRESS OF          55040020
*                                  LOAD MODULE NAME.                    55120020
         BCTR  TBLPTREG,X0    REDUCE LENGTH BY ONE.                     55170020
MA002055 EQU   *                                                        55200020
         L     PARMREG1,CAPTECT ADDRESS OF ECT.                         55280020
         MVI   (ECTSCMD-ECT)(PARMREG1),MABLANK MOVE IN BLANK.           55360020
         MVC   (ECTSCMD-ECT+X1)(L'ECTSCMD-X1,PARMREG1),(ECTSCMD-ECT)(PAX55440020
               RMREG1)             BLANK OUT SUBCOMMAND NAME.           55520020
         EX    TBLENREG,MAECTSNM MOVE SUBCOMMAND NAME INTO ECT.         55600020
         XC    MASRPLST(X8),MASRPLST ZERO PARAMETER LIST.               55680020
         IKJEBESH (COMMREG),(SCMDREG),PARAM=((COMMREG)),               X55760020
               MF=(E,MASRPLST) CALL SUBCOMMAND PROCESSOR.               55840020
         EJECT                                                          55920020
*********************************************************************** 56000020
*                                                                     * 56080020
*   UPON RETURN FROM SUBCOMMAND PROCESSOR, TEST RETURN CODES TO       * 56160020
*   DETERMINE SUBSEQUENT PROCESSING.  POSSIBLE RETURN CODES AND       * 56240020
*   CORRESPONDING ACTIONS ARE --                                      * 56320020
*        00 -- SUCCESSFUL OPERATION, OBTAIN NEXT SUBCOMMAND.          * 56400020
*        04 -- SUCCESSFUL OPERATION, INVOKE INPUT MODE.               * 56480020
*        08 -- I/O ERROR ENCOUNTERED BY A SUBCOMMAND PROCESSOR THAT   * 56560020
*              INVOKED IKJEBECO OR IKJEBEFC, SUBCOMMAND PROCESSOR     * 56640020
*              COMPLETED ABNORMALLY - OBTAIN NEXT SUBCOMMAND.         * 56720020
*        12 -- I/O ERROR ENCOUNTERED ON UTILITY DATA SET, TERMINATE   * 56800020
*              THE EDIT FUNCTION.                                     * 56880020
*        16 -- A SYNTAX CHECKER OR LANGUAGE PREPROCESSOR HAS BECOME   * 56960020
*              NON-OPERATIONAL, SUBCOMMAND PROCESSOR COMPLETED        * 57040020
*              ABNORMALLY - INVOKE SCAN PROCESSOR TO ATTEMPT          * 57120020
*              RECOVERY.                                              * 57200020
*                                                                     * 57280020
*********************************************************************** 57360020
         B     MASCMRET(RETCDREG) RETURN CODE BRANCH TABLE.             57440020
MASCMRET EQU   *                                                        57520020
         B     MACKATTN       CODE = 00 -- GET NEXT SUBCOMMAND.         57600020
         B     MAINPUT        CODE = 04 -- INVOKE INPUT MODE.           57680020
         B     MADELETE       CODE = 08 -- CLEAR INPUT AND OUTPUT       57760020
*                                  QUEUES UNCONDITIONALLY.              57810020
*                                  TERMINATE EDIT (DELETING INPUT       57820020
*                                  STACK) IF CURRENT INPUT SOURCE       57830020
*                                  IS AN IN-CORE PROCEDURE.             57832020
         B     MAEXIT         CODE = 12 -- TERMINATE.                   57840020
*                             CODE = 16 -- ATTEMPT SYNTAX CHECKER       57846020
*                                  RECOVERY.                            57852020
         BAL   BRNCHREG,MAFREEBF BRANCH TO FREE SUBCOMMAND BUFFER       57854020
*                                  BEFORE RECOVERY ATTEMPT.             57856020
         LA    BRNCHREG,MACKATTN SET BRANCH ADDRESS FOR                 57858020
*                                  SUCCESSFUL RETURN FROM SCAN.         57864020
*                                  SCAN CAN BE CALLED AT MOST           57870020
*                                  TWO TIMES -- 1. TO ATTEMPT           57876020
*                                  RECOVERY AND 2. TO CLEAN-UP IF       57882020
*                                  RECOVERY IS NOT POSSIBLE.            57888020
*                                  THIS ADDRESS MUST REMAIN FOR         57894020
*                                  BOTH SITUATIONS SO THAT NORMAL       57900020
*                                  SUBCOMMAND RETURN LOGIC CAN BE       57906020
*                                  EXECUTED.                            57912020
MASYNR20 EQU   *                                                        57920020
         TM    CACFLAG4,CASCRC20 CHECK IF RECOVERY IN PROCESS.          58160020
         BZ    MASYNRCV       IF NOT IN PROCESS, BRANCH TO              58240020
*                                  INDICATE THAT RECOVERY IS TO         58320020
*                                  BE ATTEMPTED.                        58400020
         NI    CACFLAG4,X255-CASCRC20 INDICATE THAT RECOVERY            58480020
*                                  FAILED AND THAT SYNTAX CHECKER       58560020
*                                  SHOULD BE DELETED.                   58640020
         B     MASCANON       BRANCH TO INVOKE SCAN PROCESSOR.          58720020
MASYNRCV EQU   *                                                        58800020
         OI    CACFLAG4,CASCRC20 INDICATE THAT SYNTAX CHECKER           58880020
*                                  RECOVERY SHOULD BE ATTEMPTED.        58960020
         B     MASCANON       BRANCH TO INVOKE SCAN PROCESSOR.          59040020
         EJECT                                                          59120020
MADELETE EQU   *                                                        59170020
*********************************************************************** 59180020
*                                                                     * 59190020
*    ONE OF THE FOLLOWING CONDITIONS HAS OCCURRED --                  * 59192020
*                                                                     * 59194020
*         (1) A SUBCOMMAND HAS COMPLETED WITHOUT ACCOMPLISHING ITS    * 59196020
*             REQUESTED FUNCTION (RETURN CODE TO IKJEBEMA IS 8).      * 59198020
*                                                                     * 59198420
*         (2) AN INVALID SUBCOMMAND HAS BEEN ENCOUNTERED.             * 59198820
*                                                                     * 59199220
*    ACTION --                                                        * 59199620
*                                                                     * 59199720
*         (1) INPUT SOURCE IS THE TERMINAL -- ISSUE TCLEARQ FOR       * 59199820
*             INPUT AND FOR OUTPUT, CONTINUING PROCESSING.            * 59199920
*                                                                     * 59200020
*         (2) INPUT SOURCE IS AN IN-CORE PROCEDURE -- TERMINATE       * 59210020
*             EDIT, CLEARING INPUT AND OUTPUT QUEUES AND              * 59220020
*             DELETING THE INPUT STACK.                               * 59222020
*                                                                     * 59224020
*********************************************************************** 59226020
         SPACE 2                                                        59226420
         TM    CACFLAG4,CAINPROC DETERMINE IF SOURCE OF INPUT IS        59226520
*                                  IN-CORE PROCEDURE.                   59226620
         BO    MAEXIT         IF SO, BRANCH TO TERMINATE EDIT.          59236620
         L     EPLOCREG,MAPTBMA2 ADDRESS OF TCLEARQ SUBROUTINE.         59246620
         CALL  (15),ID=3,MF=(E,MASRPLST) BRANCH TO CLEAR INPUT         X59248620
                                         QUEUE.                         59249020
*                                                                       59250620
*    FALL THROUGH TO CHECK IF THE ATTENTION ECB HAS BEEN POSTED.        59252620
*                                                                       59253020
         EJECT                                                          59253120
MACKATTN EQU   *                                                        59253320
*********************************************************************** 59280020
*                                                                     * 59360020
*   UPON RETURN FROM INPUT MODE OR A SUBCOMMAND PROCESSOR, CHECK THE  * 59440020
*   ATTENTION ISSUED FLAG AND THE LINE TO BE VERIFIED FLAGS.  WHEN    * 59520020
*   THE ATTENTION ISSUED FLAG IS ON, TURN IT AND THE LINE TO BE       * 59600020
*   VERIFIED FLAG OFF, AND CONTINUE PROCESSING BASED ON          A42593 59610021
*   THE ATTENTION BUFFER POINTER (CAATNBUF). (IF THE             A42953 59620021
*   ADDRESS IS ZERO, THE CAPTIBFR FIELD HAS ALREADY BEEN         A42593 59630021
*   UPDATED.  IF THE ADDRESS IS NON-ZERO,  IT IS TO BE PLACED    A42593 59640021
*   IN THE CAPTIBFR FIELD AFTER THE CURRENT SUBCOMMAND BUFFER    A42593 59650021
*   IS FREED.  IN EITHER CASE, A BRANCH IS TAKEN TO CALL THE     A42593 59660021
*   COMMAND SCAN SERVICE ROUTINE TO SCAN FOR THE SUBCOMMAND      A42593 59670021
*   NEXT TO BE-PROCESSED.) IF NO                                 A42593 59680021
*   ATTENTION WAS ISSUED, TEST THE LINE TO BE VERIFIED FLAG.  IF THE  * 59760020
*   LINE TO BE VERIFIED FLAG AND THE VERIFY FLAG ARE BOTH ON, INVOKE  * 59840020
*   IKJEBEMS TO VERIFY THE LAST LINE.  IF VERIFICATION WAS NOT        * 59920020
*   REQUESTED, TURN LINE TO BE VERIFIED FLAG OFF AND GET NEXT         * 60000020
*   SUBCOMMAND.                                                       * 60080020
*                                                                     * 60160020
*********************************************************************** 60240020
         TM    CAATTN,CAATTNIS CHECK IF ATTENTION WAS ISSUED.           60320020
         BZ    MA002060       IF NOT, BRANCH TO CHECK IF LINE IS        60400020
*                                  TO BE VERIFIED.                      60480020
         OC    CAATNBUF+X1(X3),CAATNBUF+X1 DETERMINE IF BUFFER   A42953 60490021
*                                  HAS BEEN OBTAINED THROUGH     A42953 60500021
*                                  ATTENTION PROCESSING          A42953 60510021
         BZ    MA002057       IF NOT, BYPASS BUFFER PROCESSING   A42953 60520021
*                                  BELOW.                        A42953 60530021
         BAL   BRNCHREG,MAFREEBF FREE LAST SUBCOMMAND BUFFER.    A42953 60540021
MA002056 EQU   *                                                 A42953 60550021
         MVC   CAPTIBFR+X1(X3),CAATNBUF+X1 UPDATE CURRENT BUFFER A42953 60560021
*                                  ADDRESS.                      A42953 60570021
         OI    CACFLAG4,CAPTGTBF INDICATE THAT BUFFER WAS        A42953 60580021
*                                  OBTAINED THROUGH PUTGET.      A42953 60590021
         XC    CAATNBUF(X4),CAATNBUF ZERO ATTENTION BUFFER PTR   A42953 60600021
MA002057 EQU   *                                                 A42953 60610021
         NI    CAATTN,X255-CAATTNIS TURN OFF ATTN ISSUED FLAG    A42953 60620021
         NI    CACFLAG1,X255-CALNTOVF TURN OFF LINE TO BE VERIFIED      60640020
*                                  FLAG.                                60720020
         NI    CAPTIBFR,X255-CAOPERND INDICATE NO OPERANDS              60770020
         L     IBFPTREG,CAPTIBFR ADDRESS OF TERMINAL INPUT BUFFER       60800020
         B     MA001072       BRANCH TO INVOKE IKJSCAN.           M2108 60880021
MA002060 EQU   *                                                        60960020
         BAL   BRNCHREG,MAFREEBF BRANCH TO FREE INPUT BUFFER.           61040020
MA002065 EQU   *                                                        61120020
         TM    CACFLAG1,CALNTOVF+CAVRFYSW CHECK IF VERIFY IS            61200020
*                                  REQUESTED AND IF LINE IS TO          61280020
*                                  BE VERIFIED.                         61360020
         BNO   MA002070       IF NOT, BRANCH TO MAKE SURE LINE          61440020
*                                  TO BE VERIFIED FLAG IS OFF.          61520020
         OI    CACFLAG4,CATPUTVF SET FLAG FOR IKJEBEMS TO               61600020
*                                  INDICATE THAT A VERIFY IS            61680020
*                                  REQUESTED.                           61760020
         LA    LEV1REG,M1ERROR4 RELATIVE ERROR TO BE PROCESSED.         61840020
         BAL   SRRTNREG,MAMSGRTN BRANCH TO PUT ERROR MESSAGE.           61920020
MA002070 EQU   *                                                        62000020
         NI    CACFLAG1,X255-CALNTOVF TURN OFF LINE TO BE               62080020
*                                  VERIFIED FLAG.                       62160020
         B     MAGETSUB       BRANCH TO GET NEXT SUBCOMMAND.            62240020
         EJECT                                                          62320020
*559200,588800                                                          62400020
*********************************************************************** 62480020
*                                                                     * 62560020
*   TERMINATION PROCESSING.                                           * 62640020
*                                                                     * 62720020
*   WHEN AN I/O ERROR WAS ENCOUNTERED ON THE UTILITY DATA SET OR WHEN * 62800020
*   AN 'END' SUBCOMMAND IS ENCOUNTERED, TERMINATE THE EDIT FUNCTION.  * 62880020
*   (1.) INVOKE IKJEBEEX TO TERMINATE THE UTILITY DATA SET ACCESS     * 62960020
*   METHOD.  (2.) INVOKE THE SCAN SUBCOMMAND WITH A 'SCAN OFF'        * 63040020
*   SUBCOMMAND TO TERMINATE SYNTAX CHECKING WHEN IT HAD BEEN IN USE.  * 63120020
*   (3.) CALL IKJEBESR TO DELETE THE PERMANENTLY RESIDENT SERVICE     * 63200020
*   ROUTINES.  (4.) DELETE IKJEBESR AND (5.) ISSUE FREEMAIN MACRO     * 63280020
*   INSTRUCTIONS FOR THE TERMINAL INPUT BUFFER, ATTENTION BUFFER,     * 63360020
*   AND COMMUNICATION AREA.   (6.) RETURN TO THE TMP.                 * 63440020
*                                                                     * 63520020
*********************************************************************** 63600020
MAEXIT   EQU   *                                                        63680020
         SR    TMPCDREG,TMPCDREG SET NORMAL RETURN CODE.                63760020
         TM    MACFLAGS,MAENDPRC CHECK IF END SUBCOMMAND WAS            63840020
*                                  PROCESSED.                           63920020
         BO    MAEXIT1        IF SO, BRANCH TO FREE COMMUNICATION       64000020
*                                  AREA.                                64080020
         L     EPLOCREG,MAPTBMA2 ADDRESS OF FREEMAIN/INPUT STACK        64160020
*                                  CLEAN-UP ROUTINE.                    64240020
         CALL  (15),ID=1,MF=(E,MASRPLST) BRANCH TO FREE INPUT          X64320020
                                   BUFFER AND CLEAR INPUT QUEUES.       64400020
         IKJEBESH (COMMREG),IKJEBEXT,PARAM=((COMMREG)),                X64480020
               MF=(E,MASRPLST) INVOKE END TO PERFORM CLEAN-UP          X64560020
                                   PROCESSING.                          64640020
MAEXIT0  EQU   *                                                        64690020
         LR    TMPCDREG,RETCDREG SAVE RETURN CODE.                      64720020
MAEXIT1  EQU   *                                                        64800020
         L     SAVEREG,X4(,SAVEREG) ADDRESS OF HIGHER SAVE AREA.        64880020
         FREEMAIN R,LV=CADLEN,A=(COMMREG),SP=SUBPOOL1 FREE             X64960020
                                   COMMUNICATION AREA.                  65040020
         LR    RETCDREG,TMPCDREG SET RETURN CODE FOR TMP.               65120020
MAEXIT2  EQU   *                                                 A45002 65160021
         RETURN (14,12),,RC=(15) RETURN TO THE TMP.                     65200020
         EJECT                                                          65280020
MATERMED EQU   *                                                        65360020
*********************************************************************** 65440020
*                                                                     * 65520020
*   WHEN THE CONTROLLER DISCOVERA A LOGIC ERROR, CALL MESSAGE ROUTINE * 65600020
*   TO PUT TERMINATION MESSAGE AND RETURN TO THE TMP.                 * 65680020
*                                                                     * 65760020
*********************************************************************** 65840020
         LA    LEV1REG,M1ERROR2 RELATIVE ERROR TO BE PROCESSED.         65920020
         LR    INS2REG,RETCDREG SAVE RETURN CODE FOR INSERTION.         66000020
MACALMSG EQU   *                                                        66080020
         LA    SRRTNREG,MAEXIT ADDRESS OF EXIT.                         66160020
         SPACE 5                                                        66240020
MAMSGRTN EQU   *                                                        66320020
*********************************************************************** 66400020
*                                                                     * 66480020
*   CALL MESSAGE ROUTINE TO PUT ERROR MESSAGE.  IF RETURN CODE IS     * 66560020
*   NOT ZERO, TERMINATE EDIT.                                         * 66640020
*                                                                     * 66720020
*********************************************************************** 66800020
         CALL  IKJEBMA1,((COMMREG),(LEV1REG),(LEV2REG),(INS1REG),      X66880020
               (INS2REG)),MF=(E,MAMGPLST) BRANCH TO PUT MESSAGE.        66960020
         LTR   RETCDREG,RETCDREG TEST FOR RETURN CODE ZERO.             67040020
         BCR   ZERO,SRRTNREG  IF ZERO, RETURN TO CALLER.                67120020
         CH    15,RETCODE4             IS RETURN CODE 4         SA62903 67140021
         BCR   ZERO,SRRTNREG           CONTINUE IF ATTENTION    SA62903 67160021
         B     MAEXIT         AND BRANCH TO TERMINATE.                  67200020
         EJECT                                                          67280020
MAFREEBF EQU   *                                                        67360020
*********************************************************************** 67440020
*                                                                     * 67520020
*   SUBROUTINE USED TO FREE INPUT BUFFER ACQUIRED BY IKJPTGT.         * 67600020
*   ADDRESS OF BUFFER IS IN COMMUNICATION AREA AT CAPTIBFR AND LENGTH * 67680020
*   IS FIRST HALFWORD OF BUFFER.                                      * 67760020
*                                                                     * 67840020
*********************************************************************** 67920020
         L     EPLOCREG,MAPTBMA2 ADDRESS OF FREEMAIN/INPUT STACK        68000020
*                                  CLEAN-UP ROUTINE.                    68080020
         CALL  (15),ID=0,MF=(E,MAFREMNL) BRANCH TO FREE INPUT          X68160020
                                   BUFFER.                              68240020
         BR    BRNCHREG       RETURN TO CALLER.                         68320020
         EJECT                                                          68400020
*********************************************************************** 68480020
*                                                                     * 68560020
*   USER ENTERED INVALID SUBCOMMAND.  BRANCH TO MESSAGE ROUTINE TO    * 68640020
*   PUT MESSAGE.  UPON RETURN, CHECK IF INPUT BUFFER MUST BE FREED.   * 68720020
*   BRANCH TO CHECK IF ATTENTION RECEIVED DURING PROCESSING.          * 68800020
*                                                                     * 68880020
*********************************************************************** 68960020
MA004010 EQU   *                                                        69040020
         SR    PTSCMREG,PTSCMREG SPECIFY THAT NO MESSAGE INSERTION      69090020
*                                  IS TO BE MADE.                       69100020
MA004020 EQU   *                                                        69440020
         LR    INS1REG,PTSCMREG SET UP PARAMETERS FOR MESSAGE           69520020
         LR    INS2REG,SCLENREG    ROUTINE.                             69600020
         LA    LEV1REG,M1ERROR3 RELATIVE ERROR TO BE PROCESSED.         69680020
         BAL   SRRTNREG,MAMSGRTN BRANCH TO PUT ERROR MESSAGE.           69760020
         B     MADELETE       BRANCH TO DETERMINE IF EDIT MUST          69810020
*                                  BE TERMINATED.                       69820020
         EJECT                                                          70000020
MAAERTRY EQU   *                                                        70080020
*********************************************************************** 70160020
*                                                                     * 70240020
*   THIS ABNORMAL END RETRY ROUTINE IS SPECIFIED AT THE TIME THE      * 70320020
*   STAE MACRO INSTRUCTION IS ISSUED.  THE RETRY ROUTINE IS GIVEN     * 70400020
*   CONTROL AFTER THE STAE EXIT ROUTINE (IKJEBEAE) HAS COMPLETED      * 70480020
*   PROCESSING.                                                       * 70560020
*                                                                     * 70640020
*   THE RETRY ROUTINE WILL RELOAD THE CONTROLLER REGISTERS AND        * 70720020
*   WILL BUILD AN ''END'' COMMAND TO BE PROCESSED BY THE MAIN         * 70800020
*   SECTION OF THE CONTROLLER.  AT CONCLUSION OF PROCESSING, THE      * 70880020
*   RETRY ROUTINE BRANCHES SO THAT IKJSCAN CAN SCAN THE NEW BUFFER.   * 70960020
*                                                                     * 71040020
*********************************************************************** 71120020
         DROP  BASEREG        DROP BASE REGISTER.                       71200020
         USING MAAERTRY,EPLOCREG ESTABLISH ADDRESSABILITY TO THIS       71280020
*                                  CODE BASED ON ENTRY ADDRESS.         71360020
         LTR   PARMREG0,PARMREG0 CHECK IF WORK AREA WAS AVAILABLE       71440020
         BNZ   MA010010       IF NOT, BRANCH TO EXIT TO TMP.            71520020
         L     COMMREG,X0(,PARMREG1) PLACE ADDRESS OF COMMUNICA-        71600020
*                                  TION AREA IN COMMREG.                71680020
         B     MA010020       BRANCH TO RESTORE BASE REGISTER.          71760020
MA010010 EQU   *                                                        71840020
*                                                                       71920020
*   WHEN STAE IS UNABLE TO OBTAIN A WORK AREA, THE ADDRESS OF THE       72000020
*   COMMUNICATION AREA IS NOT AVAILABLE.  NO FURTHER PROCESSING IS      72080020
*   POSSIBLE.                                                           72160020
*                                                                       72240020
         SVC   EXIT           RETURN TO THE TMP.                        72320020
MA010020 EQU   *                                                        72400020
         LA    SAVEREG,CASVAREA RE-INITIALIZE SAVE AREA POINTER.        72480020
         L     BASEREG,XBASEREG(,SAVEREG) RE-INITIALIZE BASE            72560020
*                             REGISTER.                                 72640020
         DROP  EPLOCREG       DROP TEMPORARY BASE REGISTER.             72720020
         USING MA000010,BASEREG RE-ESTABLISH ADDRESSABILITY TO          72800020
*                             THIS CODE.                                72880020
         EJECT                                                          72882020
*********************************************************************** 72890020
*                                                                     * 72930020
*    THE END SUBCOMMAND PROCESSOR IS INVOKED --                       * 72940020
*                                                                     * 72950020
*    1. TO FREEMAIN PREVIOUS COMMAND BUFFER (IF NECESSARY)            * 72952020
*    2. TO ALLOW THE TERMINAL USER TO SAVE DATA SET IF                * 72954020
*       IT HAS BEEN MODIFIED SINCE LAST SAVED                         * 72956020
*    3. TO PERFORM REQUIRED TERMINATION PROCESSING                    * 72958020
*                                                                     * 72958420
*    NOTE -- AS A CONVENTION, THE 'MAENDPRC' BIT OF THE MAIN          * 72958820
*    CONTROLLER WORK AREA IS SET TO 1 PRIOR TO INVOKING IKJEBEEN.     * 72959220
*    THIS CONVENTION IS ESTABLISHED TO COMMUNICATE THE FACT           * 72959620
*    THAT THE END PROCESSOR IS BEING INVOKED WITHOUT A CORRESPONDING  * 72959720
*    COMMAND BUFFER ADDRESS IN THE EDIT COMMUNICATION AREA.           * 72959820
*                                                                     * 72959920
*********************************************************************** 72986620
         OI    MACFLAGS,MAENDPRC INDICATE THAT NO SUBCOMMAND BUFFER     72996620
*                                  FOR IKJEBEEN.                        73008620
         IKJEBESH (COMMREG),IKJEBEEN,PARAM=((COMMREG)),MF=(E,MASRPLST) X73010620
                                   INVOKE END SUBCOMMAND PROCESSOR.     73012620
         B     MAEXIT2              BRANCH TO RETURN TO TMP WITH A45002 73112621
*                                   RETURN CODE 12               A45002 73212621
         EJECT                                                          73440020
*********************************************************************** 73520020
*                                                                     * 73600020
*   EQUATES, CONSTANTS AND AREAS USED BY THIS MODULE.                 * 73680020
*                                                                     * 73760020
*********************************************************************** 73840020
MAECTSNM MVC   (ECTSCMD-ECT)(*-*,PARMREG1),X0(PTSCMREG) MOVE            73920020
*                                  SUBCOMMAND NAME TO ECT.              74000020
MACMDCK  CLC   X0(*-*,PTSCMREG),X1(TBLPTREG) COMPARE CURRENT            74080020
*                                  SUBCOMMAND NAME IN TABLE WITH        74160020
*                                  THAT ENTERED BY THE USER.            74240020
MALNPPCK CLC   X0(*-*,PTSCMREG),MACONS1 COMPARISON USED TO              74320020
*                                  DETECT A LINE NUMBER                 74400020
*                                  SUBCOMMAND.                          74480020
MACONS1  DC    CL8'00000000'  CONSTANT USED TO CHECK FOR A LINE         74560020
*                                  NUMBER COMMAND.                      74640020
PTGTPLST PUTGET OUTPUT=(0,SINGLE,MODE),TERMGET=(EDIT,WAIT),            X74720020
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),MF=L                  74800020
PTGTPLEN EQU   *-PTGTPLST     LENGTH OF MACRO EXPANSION.                74880020
MASTAXLF STAX  0,MF=L         STAX MACRO -- LIST FORM.                 X74888020
                                   NOTE -- THE ONLY PARAMETERS         X74896020
                                   MAINTAINED  AS THEY APPEAR IN       X74904020
                                   THIS EXPANSION ARE THE INPUT        X74912020
                                   BUFFER LENGTH AND ADDRESS).          74920020
MASTAXLN EQU   *-MASTAXLF     LENGTH OF STAX PARAMETER LIST.            74928020
MASTAELF STAE  MF=L           STAE MACRO - LIST FORM.                   74936020
MASTAELN EQU   *-MASTAELF     LENGTH OF STAE PARAMETER LIST.            74944020
SCNONMSG DC    AL2(SCNONEND-*),AL2(0),CL2'ON' SCAN ON MESSAGE.          74960020
SCNONEND EQU   *              SCAN ON MESSAGE END.                      75040020
MACONS2  DC    CL5'INPUT'     INPUT SUBCOMMAND NAME.                    75440020
MAPTUT   DC    A(IKJEBEUT)    ADDRESS OF UTILITY ACCESS INTERFACE       75520020
MAPTBMA2 DC    A(IKJEBMA2)    ADDRESS OF FREEMAIN/INPUT STACK           75600020
*                                  CLEAN-UP ROUTINE.                    75680020
MAEBEIP  DC    A(MA8IP002)    ADDRESS OF INPUT LOAD MODULE NAME.        75760020
MAEBELI  DC    A(MA8LI002)    ADDRESS OF LOAD MODULE NAME FOR           75840020
*                                  LINE INSERT/REPLACE/DELETE.          75920020
MAIBMTBL DC    A(IKJEBMA8)    ADDRESS OF IBM SUBCOMMAND TABLE.          76000020
MAUSRTBL DC    A(IKJEBMA9)    ADDRESS OF USER SUBCOMMAND TABLE.         76080020
MAPTAT   DC    A(IKJEBEAT)    ADDRESS OF ATTENTION EXIT.                76160020
MAPTAE   DC    A(IKJEBEAE)    ADDRESS OF ABNORMAL END EXIT.             76240020
MAMAXCLN DC    H'8'           MAXIMUM LENGTH FOR A SUBCOMMAND NAME.     76290020
RETCODE4 DC    H'4'                    RETURN CODE 4            SA62903 76300021
EXIT     EQU   3              SVC NUMBER FOR SVC EXIT.                  76320020
RCODE12  EQU   12             RETURN CODE 12.                           76400020
SUBPOOL1 EQU   1              SUBPOOL NUMBER.                           76480020
ZERO     EQU   B'1000'        CONDITION CODE ZERO.                      76560020
MABLANK  EQU   C' '           CHARACTER BLANK.                          76640020
MANOSCHK EQU   X'80'          INDICATE TO IKJSCAN THAT NO SYNTAX        76720020
*                                  CHECKING OF SUBCOMMAND NAME IS       76800020
*                                  TO BE DONE.                          76880020
MANO2MSG EQU   X'80'          INDICATE IN ECT THAT SECOND LEVEL         76960020
*                                  MESSAGES ARE TO BE FLUSHED.          77040020
MATBLEND EQU   X'FF'          SUBCOMMAND TABLE END INDICATOR.           77120020
XBASEREG EQU   (BASEREG*4)+((6*4)-4) OFFSET IN SAVE AREA TO             77200020
*                                  BASEREG (REGISTER).                  77280020
XPTGTREG EQU   (PTGTREG*4)+((6*4)-4) OFFSET IN SAVE AREA TO             77360020
*                                  PTGTREG (REGISTER).                  77440020
X0       EQU   0              OFFSET ZERO.                              77520020
X1       EQU   1              OFFSET 1.                                 77600020
X2       EQU   2              OFFSET 2.                                 77680020
X3       EQU   3              OFFSET 3.                                 77760020
X4       EQU   4              OFFSET 4.                                 77840020
X5       EQU   5              OFFSET 5.                                 77920020
X8       EQU   8              OFFSET 8.                                 78000020
X9       EQU   9              OFFSET 9.                                 78080020
X10      EQU   10             OFFSET 10.                                78160020
X12      EQU   12             OFFSET 12.                                78240020
X14      EQU   14             OFFSET 14.                                78320020
X15      EQU   15             OFFSET 15.                                78400020
X16      EQU   16             OFFSET 16.                                78480020
X22      EQU   22             OFFSET 22.                                78560020
X72      EQU   72             OFFSET 72.                                78640020
X255     EQU   255            OFFSET 255.                               78720020
         TITLE 'IKJEBMA1 - MESSAGE PROCESSING FOR IKJEBEMA'             78800020
IKJEBMA1 CSECT                                                          78880020
*********************************************************************** 78960020
*                                                                     * 79040020
*   MESSAGE ROUTINE.                                                  * 79120020
*                                                                     * 79200020
*   THIS SUBROUTINE CONVERTS THE RELATIVE ERROR NUMBER (INPUT IN      * 79280020
*   REGISTER 1) TO A MESSAGE NUMBER AND INVOKES IKJEBEMS TO PUT       * 79360020
*   THE ERROR MESSAGE.  THE RETURN CODE RETURNED BY IKJEBEMS IS       * 79440020
*   PRESERVED IN REGISTER 15 ON EXIT.                                 * 79520020
*                                                                     * 79600020
*********************************************************************** 79680020
         IKJEBESV (14,12),,,                                           X79760020
               COMMREG=X0(,PARMREG1) SAVE ENTRY REGISTERS.              79840020
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         79920020
*                                  COMMUNICATION AREA.                  80000020
         LR    DATAREG,PARMREG1 SAVE PARAMETER LIST ADDRESS.            80080020
         L     PARMREG1,X4(,PARMREG1) OBTAIN RELATIVE ERROR TO BE       80160020
*                                  PROCESSED.                           80240020
         B     MA005010(PARMREG1) ENTRY CODE BRANCH TABLE.              80320020
MA005010 EQU   *                                                        80400020
         B     MA005020       1 - NO CORE AVAILABLE.                    80480020
         B     MA005030       2 - COMMAND SYSTEM ERROR.                 80560020
         B     MA005050       3 - INVALID SUBCOMMAND.                   80640020
         B     MA005060       4 - VERIFY REQUEST.                       80720020
         SPACE 2                                                        80800020
MA005020 EQU   *                                                        80880020
         LA    LEV1REG,M312   RELATIVE MESSAGE TO BE PUT TO THE         80960020
*                                  TERMINAL.                            81040020
         LA    INS1REG,M1INS001 ADDRESS OF INSERTION RECORD FOR         81120020
*                                  FIRST LEVEL MESSAGE.                 81200020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        81280020
         SR    INS2REG,INS2REG     OR INSERTIONS ARE REQUIRED.          81360020
         B     MA005090       BRANCH TO PUT MESSAGE.                    81440020
         EJECT                                                          81490020
MA005030 EQU   *                                                        81600020
         L     INS1REG,X12(,DATAREG) INDEX INTO SERVICE ROUTINE         81680020
*                                  NAME TABLE.                          81760020
         LA    INS1REG,M1MLTABL(INS1REG) ADDRESS OF APPROPRIATE         81840020
*                                  SERVICE ROUTINE NAME.                81920020
         MVC   MALNIN1(X12),X0(INS1REG) MOVE ROUTINE NAME TO            82000020
*                                  INSERTION RECORD.                    82080020
         LA    INS1REG,MAPTIN2 ADDRESS OF SECOND INSERTION RECORD       82160020
         MVC   X0(X8,INS1REG),M1CONS1 INITIALIZE POINTER, LENGTH        82240020
*                                  AND OFFSET.                          82320020
         L     INS2REG,X16(,DATAREG) OBTAIN RETURN CODE AND             82400020
         CVD   INS2REG,X8(,INS1REG) CONVERT TO DECIMAL.                 82480020
         OI    X15(INS1REG),M1MLZONE CHANGE ZONE ON LAST BYTE.          82560020
         UNPK  X9(X3,INS1REG),X14(X2,INS1REG) CONVERT TO EBCDIC         82640020
         MVC   X8(X2,INS1REG),X10(INS1REG) AND MOVE TO INSERTION.       82720020
         ST    INS1REG,MAPTIN1 CHAIN INSERTION RECORDS.                 82800020
         LA    LEV1REG,M313   OBTAIN RELATIVE MESSAGE NUMBERS FOR       82880020
         LA    LEV2REG,M3131       FIRST AND SECOND LEVEL MESSAGE       82960020
         SR    INS1REG,INS1REG SHOW NO INSERTION IN FIRST LEVEL         83040020
         LA    INS2REG,MAMSGIN1    MESSAGE AND OBTAIN ADDRESS OF        83120020
*                                  INSERTION LIST FOR SECOND            83200020
*                                  LEVEL MESSAGE.                       83280020
         B     MA005090       BRANCH TO PUT MESSAGE.                    83360020
         SPACE 2                                                        83440020
MA005050 EQU   *                                                        83520020
         LM    PTSCMREG,SCLENREG,X12(DATAREG) OBTAIN ADDRESS OF         83600020
*                                  SUBCOMMAND NAME AND LENGTH.          83680020
         LTR   INS1REG,PTSCMREG  DETERMINE IF INSERTION IS PROVIDED.    83730020
         BNZ   MA005053       IF SO, BRANCH TO PROCESS INSERTION.       83740020
         B     MA005056       BRANCH TO PROCESS REMAINING PARAMETERS.   83752020
MA005053 EQU   *                                                        83754020
         MVC   MAPTIN1(M1INS003-M1INS002),M1INS002 CREATE               83760020
*                                  INSERTION RECORD FOR                 83840020
*                                  SUBCOMMAND NAME.                     83920020
         BCTR  SCLENREG,X0    REDUCE SUBCOMMAND LENGTH BY 1 AND         84000020
         EX    SCLENREG,M1MVC001   MOVE TO INSERTION RECORD.            84080020
         LA    INS1REG,MAMSGIN1 ADDRESS OF INSERTION RECORD FOR         84130020
*                                  FIRST LEVEL MESSAGE.                 84140020
MA005056 EQU   *                                                        84150020
         LA    LEV1REG,M366   RELATIVE MESSAGE TO BE PUT TO THE         84160020
*                                  TERMINAL.                            84240020
         SR    LEV2REG,LEV2REG SHOW THAT NO SECOND LEVEL MESSAGE        84480020
         SR    INS2REG,INS2REG     OR INSERTION IS REQUIRED.            84560020
         B     MA005090       BRANCH TO PUT MESSAGE.                    84640020
         SPACE 2                                                        84720020
MA005060 EQU   *                                                        84800020
         SR    LEV1REG,LEV1REG INDICATE A VERIFY REQUEST BY             84880020
         SR    LEV2REG,LEV2REG     SPECIFYING RELATIVE MESSAGE          84960020
         LA    INS1REG,CATEMPBF ADDRESS OF VERIFY LINE.                 85040020
         SR    INS2REG,INS2REG     MESSAGE OR INSERTIONS.               85120020
         SPACE 2                                                        85200020
MA005090 EQU   *                                                        85280020
         IKJEBEML (LEV1REG),(LEV2REG),(INS1REG),(INS2REG),             X85360020
               MF=(E,MAMGPLST) CALL IKJEBEMS.                           85440020
MA005093 EQU   *                                                        85520020
         IKJEBERT (14,12),,RC=(15) RETURN TO CALLER.                    85600020
         SPACE 2                                                        85680020
M1ERROR1 EQU   0              RELATIVE ERROR 1 - NO CORE MESSAGE.       85760020
M1ERROR2 EQU   4              RELATIVE ERROR 2 - COMMAND SYSTEM         85840020
*                                  ERROR.                               85920020
M1ERROR3 EQU   8              RELATIVE ERROR 3 - INVALID                86000020
*                                  SUBCOMMAND NAME.                     86080020
M1ERROR4 EQU   12             RELATIVE ERROR 4 - VERIFY REQUEST.        86160020
M1MLTABL DS    0F             TABLE OF SERVICE ROUTINE NAMES.           86240020
M1MLSTAX EQU   0*12           OFFSET TO STAX INSERTION.                 86320020
M1NAME01 EQU   *                                                        86400020
         DC    AL2(M1NAME02-*) INSERTION LENGTH.                        86480020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      86560020
         DC    C'STAX'        SERVICE ROUTINE NAME.                     86640020
M1NAME02 EQU   *                                                        86720020
         DC    (12-(M1NAME02-M1NAME01))C' ' FILL TO 3 WORDS.            86800020
M1MLSTAE EQU   1*12           OFFSET TO STAE INSERTION.                 86880020
M1NAME03 EQU   *                                                        86960020
         DC    AL2(M1NAME04-*) INSERTION LENGTH.                        87040020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      87120020
         DC    C'STAE'        SERVICE ROUTINE NAME.                     87200020
M1NAME04 EQU   *                                                        87280020
         DC    (12-(M1NAME04-M1NAME03))C' ' FILL TO 3 WORDS.            87360020
M1MLPTGT EQU   2*12           OFFSET TO PUTGET INSERTION.               87440020
M1NAME05 EQU   *                                                        87520020
         DC    AL2(M1NAME06-*) INSERTION LENGTH.                        87600020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      87680020
         DC    C'PUTGET'      SERVICE ROUTINE NAME.                     87760020
M1NAME06 EQU   *                                                        87840020
         DC    (12-(M1NAME06-M1NAME05))C' ' FILL TO 3 WORDS.            87920020
M1MLSCAN EQU   3*12           OFFSET TO SCAN INSERTION.                 88000020
M1NAME07 EQU   *                                                        88080020
         DC    AL2(M1NAME08-*) INSERTION LENGTH.                        88160020
         DC    AL2(M3131IN1)  OFFSET TO INSERTION.                      88240020
         DC    C'SCAN'        SERVICE ROUTINE NAME.                     88320020
M1NAME08 EQU   *                                                        88400020
         DC    (12-(M1NAME08-M1NAME07))C' ' FILL TO 3 WORDS.            88480020
M1CONS1  DC    A(0),H'6',AL2(M3131IN2) POINTER, LENGTH, AND             88560020
*                                  OFFSET FOR COMMAND SYSTEM            88640020
*                                  ERROR MESSAGE, RETURN CODE           88720020
*                                  INSERTION.                           88800020
M1MVC001 MVC   MAINS1(*-*),X0(PTSCMREG) MOVE SUBCOMMAND NAME TO         88880020
*                                  INSERTION RECORD FOR MESSAGE.        88960020
M1INS001 IKJEBEMG 0,M312IN1,'EDIT' COMMAND NAME INSERTION.              89040020
M1INS002 IKJEBEMG 0,M366IN1,'        ' BASIC INSERTION FOR             X89120020
                                   INVALID SUBCOMMAND MESSAGE.          89200020
M1INS003 EQU   *                                                        89280020
M1MLZONE EQU   X'0F'          EBCDIC NUMERIC ZONE BITS.                 89360020
         IKJEBEMI (312,313,366) MESSAGE EQUATES.                        89440020
         TITLE 'IKJEBMA2 - INPUT STACK CLEAN-UP ROUTINE'                89520020
IKJEBMA2 CSECT                                                          89600020
         IKJEBESV (14,12),,,COMMREG=(9) SAVE ENTRY REGISTERS.           89680020
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO THE         89760020
*                                  COMMUNICATION AREA.                  89840020
         LR    DATAREG,PARMREG1 SAVE WORKAREA ADDRESS.                  89920020
         LA    PARMREG0,X1(,X0) CONSTANT = 1.                           90000020
         CH    PARMREG0,X2(,RETREG) CHECK ENTRY CODE.                   90080020
         BE    MA201010       ENTRY CODE = 1, BRANCH TO ISSUE           90160020
*                                  TCLEARQ AND STACK DELETE=ALL.        90240020
         BH    MA201005       ENTRY CODE = 0, CHECK IF CURRENT          90480020
*                                  INPUT BUFFER MUST BE FREED.          90560020
         LA    PARMREG0,X2    CREATE CONSTANT OF 2.                     90610020
         CH    PARMREG0,X2(,RETREG) CHECK FOR ENTRY CODE 2 OR 3.        90612020
         BE    MA201030       ENTRY CODE = 2, BRANCH TO ISSUE STACK     90620020
*                                  DELETE=ALL.                          90630020
         B     MA201010       ENTRY CODE = 3, BRANCH TO ISSUE           90630420
*                                  TCLEARQ ONLY.                        90630820
MA201005 EQU   *                                                        90632020
         TM    CACFLAG4,CAPTGTBF CHECK IF BUFFER MUST BE FREED.         90640020
         BZ    MA201050       IF NOT, BRANCH TO RETURN TO CALLER.       90720020
         L     IBFPTREG,CAPTIBFR ADDRESS OF BUFFER TO BE FREED.         90800020
         LH    IBFPTREG,X0(,IBFPTREG) LENGTH OF BUFFER.                 90880020
         NI    CAPTIBFR,X255-CAOPERND SET OPERAND FLAG TO ZERO.         90960020
         FREEMAIN E,LV=(IBFPTREG),A=CAPTIBFR,SP=SUBPOOL1,              X91040020
               MF=(E,(DATAREG)) FREE INPUT BUFFER.                      91120020
         NI    CACFLAG4,X255-CAPTGTBF INDICATE THAT INPUT BUFFER        91200020
*                                  WAS FREED.                           91280020
         B     MA201050       BRANCH TO RETURN TO CALLER.               91360020
MA201010 EQU   *                                                        91440020
         TCLEARQ INPUT        CLEAR INPUT QUEUES.                       91520020
         LA    PARMREG0,X1    CREATE CONSTANT OF 1.                     91570020
         CH    PARMREG0,X2(,RETREG) DETERMINE IF ENTRY CODE IS 1        91580020
*                                 OR 3.                                 91582020
         BNE   MA201050       IF ENTRY CODE = 3, RETURN                 91590020
*                                 TO CALLING ROUTINE.                   91592020
MA201030 EQU   *                                                        91680020
         XC    X0(X4,DATAREG),X0(DATAREG) ZERO STACK PARAMETER          91760020
*                                  BLOCK.                               91840020
         LM    R2,R5,CATMPLST+X12 SAVE PREVIOUS SERVICE ROUTINE         91920020
*                                  LIST IN CASE OF ATTENTION.           92000020
         STACK PARM=(DATAREG),DELETE=ALL,MF=(E,CATMPLST) DELETE        X92080020
                                   ALL BUT TERMINAL FROM STACK.         92160020
         STM   R2,R5,CATMPLST+X12 RESTORE PREVIOUS SERVICE              92240020
*                                  ROUTINE PARAMETER LIST.              92320020
MA201050 EQU   *                                                        92400020
         IKJEBERT (14,12),,RC=(15) RETURN TO CALLER.                    92480020
         TITLE 'IKJEBMA8 - IBM SUPPLIED SUBCOMMAND TABLE'               92560020
         IKJEBEST (*,,IKJEBELI), LINE INSERT/REPLACE/DELETE            X92640020
               (BOTTOM,B,IKJEBEBO), BOTTOM                             X92720020
               (CHANGE,C,IKJEBECH), CHANGE                             X92800020
               (DELETE,D,IKJEBEDE), DELETE                             X92880020
               (DOWN,,IKJEBEDO), DOWN                                  X92960020
               (END,,IKJEBEEN), END                                    X93040020
               (FIND,F,IKJEBEFI), FIND                                 X93120020
               (FORMAT,FORM,IKJEBEFO), FORMAT                          X93200020
               (HELP,H,IKJEBEHE), HELP                                 X93280020
               (INPUT,I,IKJEBEIP), INPUT                               X93360020
               (INSERT,IN,IKJEBEIS), INSERT                            X93440020
               (LIST,L,IKJEBELT), LIST                                 X93520020
               (MERGE,M,IKJEBEME), MERGE                               X93600020
               (PROFILE,PROF,IKJEBEHE), PROFILE                  A42956X93680021
               (RENUM,REN,IKJEBERE), RENUMBER                          X93760020
               (RUN,R,IKJEBERU), RUN                                   X93840020
               (SAVE,S,IKJEBESA), SAVE                                 X93920020
               (SCAN,SC,IKJEBESC), SCAN                                X94000020
               (TABSET,TAB,IKJEBETA), TABSET                           X94080020
               (TOP,,IKJEBETO), TOP                                    X94160020
               (UP,,IKJEBEUP), UP                                      X94240020
               (VERIFY,V,IKJEBEVE), VERIFY                             X94320020
               CSECT=IBM     IBM SUPPLIED SUBCOMMAND TABLE.             94400020
         TITLE 'IKJEBMA9 - USER SUPPLIED SUBCOMMAND TABLE'              94480020
         IKJEBEST CSECT=USER  USER SUPPLIED SUBCOMMAND TABLE.           94560020
         TITLE 'IKJEBEMA - MAPPING MACRO DSECTS'                        94640020
         IKJEBECA                                                       94720020
         SPACE 2                                                        94800020
*********************************************************************** 94880020
*                                                                     * 94960020
*   DEFINE MAIN CONTROLLER WORK AREA IN THE COMMUNICATION AREA.       * 95040020
*                                                                     * 95120020
*********************************************************************** 95200020
         ORG   CAMAWKA        DEFINE MAIN CONTROLLER WORK AREA.         95280020
MASRPLST DS    2F             PARAMETER LIST FOR SUBCOMMAND.            95360020
MAMGPLST DS    5F             PARAMETER LIST FOR MESSAGE ROUTINE.       95440020
*                             CONTROL FLAGS - SEE CAMAWKA IN            95640020
*                                  IKJEBECA.                            95840020
         ORG   CAMAWKA        RE-USE CONTROLLER WORK AREA.              96080020
MASCNFLG DS    F              FLAG WORK FOR IKJSCAN.                    96160020
MASCNOA  DS    2F             IKJSCAN OUTPUT AREA.                      96240020
MALINKSF DS    2F             PARAMETER LIST FOR LINK SVC.              96320020
         ORG   CAMAWKA        OVERLAY CONTROLLER WORK AREA.             96400020
MAFREMNL DS    3F             PARAMETER LIST FOR FREEMAIN.              96480020
         ORG   CAMAWKA        DEFINE MAIN CONTROLLER WORK AREA.         96560020
MAPGPB   DS    4F             PUTGET PARAMETER BLOCK.                   96640020
         ORG   CATEMPBF       DEFINE INSERTION RECORD FORMAT.           96720020
MAMSGIN1 DS    0F             INSERTION RECORD FOR IKJEBEMS.            96800020
MAPTIN1  DS    F              POINTER TO NEXT INSERTION.                96880020
MALNIN1  DS    H              LENGTH OF INSERTION RECORD.               96960020
MAOFFIN1 DS    H              OFFSET IN MESSAGE TO INSERTION.           97040020
MAINS1   DS    CL80           INSERTION TEXT.                           97120020
MAMSGIN2 DS    0F             INSERTION RECORD FOR IKJEBEMS.            97200020
MAPTIN2  DS    F              POINTER TO NEXT INSERTION.                97280020
MALNIN2  DS    H              LENGTH OF INSERTION RECORD.               97360020
MAOFFIN2 DS    H              OFFSET IN MESSAGE TO INSERTION.           97440020
MAINS2   DS    CL80           INSERTION TEXT.                           97520020
         EJECT                                                          97600020
         IKJCPPL                                                        97680020
         EJECT                                                          97760020
         IKJECT                                                         97840020
         EJECT                                                          97920020
         IKJCSOA                                                        98000020
         EJECT                                                          98080020
         IKJPGPB                                                        98160020
         END                                                            98240020
