         TITLE 'TSO EDIT COMMAND  MERGE SUBCOMMAND  IKJEBEME'           00100020
IKJEBEME CSECT                                                          00200020
*A159100,159260-159292,160400,312700-313100,314700-316800,317700 A42948 00250020
*A317900-317980,318900-320999,525100-525492,707200-707220        A42948 00270020
*C314200,317000,317800,321000                                    A42948 00280020
*D313200,318000-318200,368000                                    A42948 00290020
*A159560,159800-159820,339500-341300,450691-450693,451657-451659 A45104 00291021
*A486600-486900,487200-487800,525600-526100,526332-527521,707050 A45104 00292021
*A707120-707160,739500-739800,745500-745800,783600-783800        A45104 00293021
*C450690-450698,707000                                           A45104 00294021
*D340000-341200,486600,487200,526000-527000                      A45104 00295021
*A486500-486520                                                  A50953 00295421
*C486000                                                         A50953 00297021
*A041700,159296-159297,159860,420024,420090-420367               A50476 00305021
*A663600-663900,747500-747600,782420                             A50476 00326521
*C041600,073600,102600,691600,782400                             A50476 00341221
*D146500,147200,691900-692000,764000,782500-783200,803100-803200 A50476 00355921
*D803400,803800                                                  A50476 00370621
*A361500                                                          M5135 00371021
*A491746-491750,491790                                            M5137 00371821
*C280000,339500,451889                                          SA66978 00375821
*A451909-451969                                                 SA66978 00379821
*********************************************************************** 00385321
*                                                                     * 00400020
* STATUS VERSION NO. 01, OS/360 RELEASE NO. 20                        * 00700020
*                                                                     * 01000020
* FUNCTION -- IKJEBEME IS THE EDIT MERGE SUBCOMMAND. IT WILL EITHER   * 01040020
*    A) COPY ALL OR PART OF THE EDIT DATA SET INTO ITSSELF AT SOME    * 01080020
*    SPECIFIED LOCATION OR B) MERGE ALL OR PART OF ANOTHER DATA SET   * 01120020
*    INTO THE ONE BEING EDITED.                                       * 01160020
*                                                                     * 01500020
*    IKJPARS SCANS THE OPERANDS AND PROMPTS FOR VALID SYNTAX. IKJEBEDA* 01510020
*    IS CALLED TO ALLOCATE A TEMPORARY QSAM DATA SET TO WHICH THE EDIT* 01520020
*    UTILITY DATA SET IS COPIED BY IKJEBEFC. A MODEL OF THE SYSTEM    * 01530020
*    MERGE COMMAND IS BUILT AND PASSED TO IKJEBECI WHICH THEN INVOKES * 01540020
*    SYSTEM MERGE. IF SUCCESSFUL, IKJEBECO IS CALLED TO CREATE ANOTHER* 01550020
*    UTILITY DATA SET AND COPY THE MERGED DATA SET TO IT. IF THE DATA * 01560020
*    SET TYPE IS ITF, IKJEBEMR IS CALLED TO RE-TRANSLATE THE INTER-   * 01570020
*    MEDIATE DATA SET. IKJEBEEX IS GIVEN CONTROL TO DELETE THE OLD    * 01580020
*    UTILITY DATA SET. CONTROL IS RETURNED TO IKJEBEMA WITH THE RETURN* 01590020
*    CODE IN REGISTER 15.                                             * 01600020
*                                                                     * 02900020
* ENTRY POINTS -- IKJEBEME, MAIN ENTRY POINT                          * 02930020
*                                                                     * 02960020
* INPUT -- REGISTER ONE POINTS TO THE COMMUNICATION AREA              * 03030020
*                                                                     * 03100020
* OUTPUT -- FOUR RETURN CODES ARE POSSIBLE                            * 03200020
*                                                                     * 03300020
*    0 - SUCCESSFUL COMPLETION                                        * 03400020
*                                                                     * 03450020
*    8 - UNSUCCESSFUL COMPLETION                                      * 03500020
*                                                                     * 03550020
*    12 - I/O ERROR IN THE UTILITY DATA SET                           * 03600020
*                                                                     * 03610020
*    16 - SYNTAX CHECKER NOT OPERATIONAL                              * 03650020
*                                                                     * 03700020
* EXTERNAL REFERENCES --                                              * 03800020
*                                                                     * 03900020
*         IKJPARS  TMP SERVICE ROUTINE,SCANS OPERANDS AND PROMPTS FOR * 04000020
*         SYNTAX VALIDITY                                             * 04060020
*                                                                     * 04130020
*         IKJPUTL  I/O SERVICE ROUTINE, PUTS MODE MESSAGE TO     A50476 04160021
*                  THE TERMINAL                                  A50476 04170021
*                                                                     * 04200020
*         IKJEBEDA EDIT SERVICE ROUTINE, ALLOCATES QSAM DATA SET AND  * 04300020
*         MARKS DSE ENTRY                                             * 04400020
*                                                                     * 04500020
*         IKJEBEFC EDIT FINAL COPY ROUTINE, COPIES EDIT UTILITY DATA  * 04600020
*         SET TO QSAM DATA SET                                        * 04700020
*                                                                     * 04800020
*         IKJEBECI EDIT COMMAND INVOKER, INVOKES SYSTEM MERGE         * 04900020
*                                                                     * 05100020
*         IKJEBECO EDIT INITIAL COPY ROUTINE, CREATES UTILITY DATA    * 05200020
*         SET AND COPIES MERGED DATA SET TO IT                        * 05300020
*                                                                     * 05400020
*         IKJEBEEX EDIT FINAL PROCESSING ROUTINE, UNALLOCATES THE     * 05600020
*         EDIT UTILITY DATA SET                                       * 05800020
*                                                                     * 06000020
*         IKJEBEMS EDIT MESSAGE SELECTION ROUTINE, CAUSES TERMINAL    * 06100020
*         MESSAGES TO BE PRINTED                                      * 06200020
*                                                                     * 06300020
*         IKJEBEUT EDIT UTILITY ROUTINE, PERFORMS READS AND DELETES   * 06500020
*         ON THE UTILITY DATA SET                                     * 06700020
*                                                                     * 06900020
*         IKJEBEMR DELETES ITF REVERSE POLISH DATA SET AND BUILDS A   * 07000020
*         NEW ONE                                                     * 07100020
*                                                                     * 07200020
*         MACROS USED                                                 * 07260020
*                                                                     * 07330020
*         PUTLINE  CALLS IKJPUTL                                 A50476 07360021
*                                                                     * 07400020
*         LINK     PASSES CONTROL TO NON-EDIT MODULES                 * 07420020
*                                                                     * 07440020
*         IKJEBEML ADDRESSES PARAMETER LIST AND INVOKES IKJEBEMS      * 07540020
*                                                                     * 07700020
*         IKJEBESV ENTRY LINKAGE AND ADDRESSABILITY                   * 07900020
*                                                                     * 08200020
*         IKJEBERT EXIT LINKAGE                                       * 08300020
*                                                                     * 08400020
*         IKJEBEMI GENERATES EQUATES FOR MESSAGES                     * 08410020
*                                                                     * 08420020
*         IKJEBEMG GENERATES PARMLIST FOR MESSAGE INSERTION           * 08430020
*                                                                     * 08440020
*         IKJEBECA GENERATES COMMUNICATION AREA DSECT                 * 08450020
*                                                                     * 08460020
*         IKJPARM  ESTABLISHES BEGINNING OF PARAMETER CONTROL LIST    * 08530020
*         FOR IKJPARS                                                 * 08610020
*                                                                     * 08700020
*         IKJPOSIT ESTABLISHES PARAMETER CONTROL ENTRIES FOR DSNAME   * 08800020
*                                                                     * 09000020
*         IKJIDENT ESTABLISHES PARAMETER CONTROL ENTRIES FOR LINE     * 09100020
*         NUMBERS                                                     * 09200020
*                                                                     * 09300020
*         IKJKEYWD ESTABLISHES PARAMETER CONTROL EMTRIES FOR RENUM    * 09400020
*                                                                     * 09500020
*         IKJSUBF  ESTABLISHES PARAMETER CONTOL ENTRIES FOR INCREMENT * 09600020
*         AND LINE NUMBER                                             * 09700020
*                                                                     * 09800020
*         IKJNAME  RENUM KEYWORD NAME                                 * 09900020
*                                                                     * 10000020
*         IKJENDP  END OF PARAMETER CONTROL LIST                      * 10100020
*                                                                     * 10200020
*         IKJPPL   MAPPING MACRO OF PARSE PARMLIST                    * 10220020
*                                                                     * 10240020
*         IKJPTPB  MAPPING MACRO OF PUTLINE PARM BLOCK           A50476 10260021
*                                                                     * 10280020
*         IKJCPPL  MAPPING MACRO OF COMMAND PROCESSOR PARMLIST        * 10300020
*                                                                     * 10320020
*         IKJIOPL  MAPPING MACRO OF I/O SERVICE ROUTINE PARMLIST      * 10340020
*                                                                     * 10360020
*         IKJECT   MAPPING MACRO OF ENVIRONMENT CONTROL TABLE         * 10380020
*                                                                     * 10400020
*         IKJRLSA  RELEASES CORE USED BY IKJPARS FOR PDL              * 10500020
*                                                                     * 10600020
* EXITS, NORMAL -- TO IKJEBEMA WITH RETURN CODE IN REGISTER 15        * 10700020
*                                                                     * 10800020
* EXITS, ERROR -- NONE                                                * 10900020
*                                                                     * 11000020
* TABLES/WORK AREAS -- 1 IKJEBECA, THE EDIT COMMUNICATION AREA        * 11020020
*    CONTAINS PARAMETER LIST STORAGE FOR SERVICE ROUTINES NEEDED BY   * 11040020
*    IKJEBEME, A WORK AREA, THE POINTER TO THE INPUT BUFFER, AND      * 11060020
*    NUMEROUS FLAG BYTES                                              * 11080020
*    2 IKJPARS PARAMETER CONTROL LIST SPECIFIES POSITIONAL OPERANDS   * 11100020
*    THAT IKJPARS IS EXPECTED TO SCAN OFF                             * 11120020
*    3 IKJPARS PARAMETER DESCRIPTOR LIST CONTAINS POINTERS TO AND LEN-* 11140020
*    GTHS OF PARSED OPERANDS                                          * 11160020
* ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                  * 12060020
*                                                                     * 13100020
* CHARACTER CODE DEPENDENCY -- NONE.                                  * 13110020
*                                                                     * 13120020
* NOTES -- STANDARD CONVENTIONS                                       * 13140020
*                                                                     * 13160020
*********************************************************************** 13200020
         EJECT                                                          13250020
*THE FOLLOWING EQU'S ALLOW SYMBOLIC ADDRESSING OF REGISTERS             13300020
         SPACE                                                          13400020
PARMREG0 EQU   0                       CONTAINS ADDR OF COMMAREA FOR UT 13500020
PARMREG1 EQU   1                       CONTAINS PARAMETERS FOR CALLS TO 13600020
*                                      PARSE, DA, UT, AND SYNCHECKER    13700020
ANSREG   EQU   2                       CONTAINS ADDR OF PDL             13800020
LENREG   EQU   2                       CONTAINS LENGTH OF OPERAND       13900020
*                                      BEING MOVED TO BUFFER            14000020
INBREG   EQU   3                       CONTAINS ADDR OF INPUT BUFFER    14100020
LLNREG   EQU   3                       CONTAINS DISPLACEMENT TO CURRENT 14200020
*                                      POSITION IN BUFFER               14300020
WKREG    EQU   4                       GENERAL REGISTER                 14400020
MCMDREG  EQU   5                       CONTAINS ADDR OF OPERAND TO BE   14500020
*                                      MOVED TO BUFFER                  14600020
TLNREG   EQU   6                       CONTAINS TOTAL LENGTH OF BUFFER  14700020
MSGREG   EQU   7                       ADDRESSABILITY OF MESSAGE CSECT  14740020
ECTREG   EQU   8                       ADDRESSABILITY OF THE ECT        14760020
WKREGB   EQU   8                       BRANCH REGISTER IN MOVE ROUTINE  14780020
COMMREG  EQU   9                       CONTAINS ADDR OF COMMUNICATION   14800020
*                                      AREA                             14900020
BASEREG  EQU   11                      BASE REGISTER FOR THIS CSECT     15000020
DATAREG  EQU   12                      CONTAINS ADDR OF PDL             15100020
SAVEREG  EQU   13                      CONTAINS ADDR OF SAVE AREA       15200020
RETREG   EQU   14                      CONTAINS ADDR OF RETURN ENTRY PT 15300020
CALLREG  EQU   15                      CONTAINS BRANCH ADDR             15400020
RETCDREG EQU   15                      CONTAINS ADDR OF RETURN PT,      15500020
*                                      RETURN CODE ON EXIT.             15600020
*THE FOLLOWING EQU'S ALLOW SYMBOLIC REFERENCE TO CHARACTER              15700020
*AND DECIMAL CONSTANTS                                                  15800020
         SPACE                                                          15900020
D0       EQU   0                       DISPLACEMENT OF 0                15906020
D1       EQU   1                       DISPLACEMENT OF 1                15908020
D2       EQU   2                       DISPLACEMENT OF 2         A42948 15910020
D3       EQU   3                       DISPLACEMENT OF 3                15912020
D4       EQU   4                       DISPLACEMENT OF 4                15918020
D7       EQU   7                       DISPLACEMENT OF 7                15924020
D12      EQU   12                      DISPLACEMENT OF 12        A42948 15926020
D14      EQU   14                      DISPLACEMENT OF 14        A42948 15928020
D16      EQU   16                      DISPLACEMENT OF 16        A42948 15928420
D20      EQU   20                      DISPLACEMENT OF 20        A42948 15928820
D22      EQU   22                      DISPLACEMENT OF 22        A42948 15929220
L0       EQU   0                       LENGTH OF ZERO            A50476 15929621
L10      EQU   10                      LENGTH OF TEN             A50476 15929721
KONE     EQU   1                       CONSTANT OF 1                    15930020
KTWO     EQU   2                       CONSTANT OF 2                    15936020
KTHREE   EQU   3                       CONSTANT OF 3                    15938020
KFOUR    EQU   4                       CONSTANT OF 4                    15942020
KFIVE    EQU   5                       CONSTANT OF 5                    15948020
KSIX     EQU   6                       CONSTANT OF 6                    15954020
KSEVEN   EQU   7                       CONSTANT OF 7             A45104 15956021
KEIGHT   EQU   8                       CONSTANT OF 8                    15960020
KTEN     EQU   X'0A'                   CONSTANT OF HEX 10               15966020
KTWELVE  EQU   12                      CONSTANT OF 12                   15972020
K16      EQU   16                      CONSTANT OF 16                   15974020
K40      EQU   40                      CONSTANT OF 40                   15978020
NE       EQU   7                       'NOT EQUAL' MASK FOR BCR  A45104 15980021
GE       EQU   10                      'GREATER THAN OR EQUAL'   A45104 15981021
*                                      MASK FOR BCR              A45104 15982021
MEZERO   EQU   X'00'                   BIT MASK                         15984020
MERDC    EQU   X'00'                   READ CURRENT RCD CODE     A50476 15986021
MERDP    EQU   X'01'                   READ FIRST RECORD UT ENTRY CODE  15990020
MEFORTY  EQU   X'40'                   BIT MASK                         15992020
MEEIGHTY EQU   X'80'                   BIT MASK                         15996020
MELEN    EQU   4                       DISPLACEMENT IN PDL ENTRY        16002020
MEFLG    EQU   6                       DISPLACEMENT IN PDL ENTRY        16008020
MEOFF    EQU   X'00'                   BIT MASK                         16014020
MEQ      EQU   X'40'                   DSNAME QUOTED BIT IN PDL         16020020
MEOPRD   EQU   X'80'                   OPERAND PRESENT BIT IN PDL       16026020
LENGTH   EQU   0                       CONSTANT OF 0                    16032020
MEBLANK  EQU   C' '                    CHARACTER BLANK                  16038020
SLASH    EQU   C'/'                    CHARACTER SLASH           A42948 16040020
MEASTRK  EQU   C'*'                    CHARACTER ASTERISK               16044020
MELPAREN EQU   C'('                    CHARACTER LEFT PARENTHESIS       16050020
MERPAREN EQU   C')'                    CHARACTER RIGHT PARENTHESIS      16056020
MEQUOTE  EQU   C''''                   CHARACTER QUOTE                  16062020
MECZERO  EQU   C'0'                    CHARACTER ZERO                   16068020
NOBR     EQU   0                       CONSTANT OF 0                    16074020
MEALL    EQU   X'FF'                   BIT MASK                         16080020
         EJECT                                                          19520020
*********************************************************************** 19600020
         IKJEBESV (14,12),,*           ENTRY LINKAGE                    19700020
         SPACE                                                          19800020
         USING IKJEBECA,COMMREG        COMMUNICATIONS AREA              19900020
         NI    MEDAALP,MEZERO          SET ALLOC DONE SW OFF            20000020
         L     MSGREG,MEMSGADR         ADDR OF MSG CSECT                20030020
         USING IKJEBMEM,MSGREG         ADDRESSABILITY OF MSG CSECT      20060020
         XC    MEPARMM(K40),MEPARMM    ZERO OUT PARM LIST FOR MSGS      20080020
         XC    MECODE,MECODE           INIT RETURN CODE TO ZERO         20090020
         TM    CAPTIBFR,CAOPERND       OPERANDS PRESENT                 20100020
         BNO   ME002600                BR TO PUT OUT MSG                20170020
         EJECT                                                          20250020
**********************************************************************  20300020
*                                                                    *  20400020
*IKJPARS WILL SCAN THE OPERANDS ON THE SUBCOMMAND AND PROMPT FOR     *  20500020
*REQUIRED OPERANDS THAT ARE MISSING. PARSE REQUIRES A SEVEN WORD     *  20600020
*PARAMETER LIST. THE FIRST TWO WORDS (PTRS TO THE UPT AND THE ECT)   *  20700020
*ARE INITIALIZED BY THE TMP. THE THIRD WORD (PTR TO THE EDIT         *  20800020
*ATTENTION ECB) IS INITIALIZED BY THE EDIT CP. THE FOLLOWING CODE    *  20900020
*INITIALIZES THE FOURTH THROUGH THE SEVENTH WORDS (PTRS TO THE PCL,  *  21000020
*THE ANSWER PLACE WHERE PARSE WILL PLACE THE ADDRESS OF THE PDL,     *  21100020
*THE COMMAND BUFFER, AND THE USER WORK AREA.                         *  21200020
*                                                                    *  21300020
**********************************************************************  21400020
         LA    PARMREG1,CATMPLST       ADDR OF TMP SR PARMLIST          21500020
         USING PPL,PARMREG1            ADDRESSABILITY OF PPL DSECT      21600020
         L     WKREG,MEPCLADR          ADDRESS OF PCL                   21700020
         ST    WKREG,PPLPCL            FOURTH WD OF PARMLIST            21800020
         LA    ANSREG,CAPTPRSD         ADDR OF ANSWER PLACE WHERE ADDR  21900020
         ST    ANSREG,PPLANS           OF PDL WILL BE PLACED BY PARSE   22000020
         L     INBREG,CAPTIBFR         ADDR OF INPUT BUFFER             22100020
         ST    INBREG,PPLCBUF          SIXTH WORD OF PARMLIST           22200020
         ST    SAVEREG,PPLUWA          ADDR OF USER WORK AREA           22300020
         DROP  PARMREG1                                                 22400020
         LINK  EP=IKJPARS              LINK TO PARSE TO SCAN SUBCMD     22500020
         SPACE                                                          22600020
ME000100 EQU   *                                                        22700020
         B     ME000100+D4(RETCDREG)   PARSE RETURN CODE BR TABLE       22800020
         B     ME000200                00  SUCCESSFUL COMPLETION        22900020
         B     ME003250                04  UNABLE TO PROMPT             23000020
         B     ME002000                08  ATTENTION ISSUED             23100020
         B     ME002900                12  INVALID PARAMETERS           23200020
         B     ME002800                16  NOT ENOUGH CORE              23270020
         EJECT                                                          23350020
*********************************************************************** 23400020
*                                                                     * 23500020
*IF ONLY ONE LINE NUMBER IS GIVEN, PARSE ASSUMES IT IS LINENUM1.      * 23600020
*IKJEBEME ASSUMES IT IS LINENUM3 AS LINENUM2 MUST BE PRESENT IF LINE- * 23700020
*NUM1 IS GIVEN. IF TWO NUMBERS ARE GIVEN, BOTH PARSE AND IKJEBEME     * 23800020
*ASSUME THEY ARE LINENUM1 AND LINENUM2. THE FOLLOWING CODE CHECKS TO  * 23900020
*SEE IF LINENUM2 IS GIVEN AND MOVES LINENUM1 TO LINENUM3 WHEN ONLY ONE* 24000020
*NUMBER IS GIVEN.                                                     * 24100020
*                                                                     * 24200020
*********************************************************************** 24300020
ME000200 L     DATAREG,CAPTPRSD        ESTABLISH ADDRESSABILITY OF THE  24400020
         USING MEPCLL,DATAREG          PDL FROM PARSE                   24500020
         TM    MEPCE3+MEFLG,MEOPRD     IS LINENUM2 PRESENT              24600020
         BO    ME000300                YES BR  ALL LINE NUMBERS PRESENT 24700020
         TM    MEPCE2+MEFLG,MEOPRD     IS LINENUM1 PRESENT              24800020
         BZ    ME000300                NO BR ONLY LINENUM3 IS GIVEN     24900020
         LA    WKREG,MEPCE2            ADDR OF PTR TO LTNENUM1          25100020
         MVC   MEPCE4(KEIGHT),D0(WKREG) MOVE POINTERS TO LINENUM3       25200020
         NI    MEPCE2+MEFLG,MEALL-MEOPRD TURN SWITCH FOR LINENUM1 OFF   25400020
         EJECT                                                          25550020
*********************************************************************** 25600020
*                                                                     * 25700020
*IKJEBEDA WILL ALLOCATE A SEQUENTIAL DATA SET WITH A DISPOSITION OF   * 25800020
*NEW, CATLG, DELETE.                                                  * 25900020
*                                                                     * 26000020
*********************************************************************** 26100020
ME000300 NI    CASAFLAG,MEZERO         SET SAVEDS FLAG SW OFF           26200020
         BAL   WKREG,ME002480          BR TO CALL IKJEBEDA              26300020
         OI    MEDAALP,MEEIGHTY        SETSW ON FOR ALLOC DONE          26600020
*********************************************************************** 26900020
*                                                                     * 27000020
*IKJEBEFC WILL COPY THE EDIT UTILITY DATA SET INTO THE QSAM DATA SET  * 27100020
*ALLOCATED BY DAIR.                                                   * 27200020
*                                                                     * 27300020
*********************************************************************** 27400020
         IKJEBESH (COMMREG),IKJEBEFC,PARAM=((COMMREG)),MF=(E,MEPARMM)   27500020
         SPACE                                                          27610020
ME000400 EQU   *                                                        27700020
         B     ME000400+D4(RETCDREG)   FC RETURN CODE BR TABLE          27800020
         B     ME000500                00  SUCCESSFUL COMPLETION        27900020
         B     ME000500                04  EMPTY DATA SET       SA66978 28000021
         B     ME003250                08  QSAM ERROR                   28100020
         B     ME003300                12  I/O ERROR                    28200020
*********************************************************************** 28300020
*                                                                     * 28400020
*IKJEBEDA WILL UNALLOCATE THE SEQUENTIAL DATA SET WITH DISPOSITION=   * 28500020
*OLD,KEEP.                                                            * 28600020
*                                                                     * 28700020
*********************************************************************** 28800020
ME000500 EQU   *                                                        28900020
         OI    CASAFLAG,CASADISP       SET SWITCH                       28950020
         BAL   WKREG,ME002480          BR TO CALL IKJEBEDA              29000020
         EJECT                                                          29500020
*********************************************************************** 29600020
*                                                                     * 29700020
*THE FOLLOWING SECTION BUILDS A MODEL OF THE SYSTEM MERGE COMMAND IN  * 29800020
*A BUFFER FROM INFORMATION OBTAINED FROM THE SUBCOMMAND OPERANDS. THE * 29900020
*SYSTEM COMMAND HAS THE FORMAT                                        * 30000020
*        MERGE DSNAME1 (LINENUM1 LINENUM2) DSNAME2 (LINENUM3)         * 30100020
*DSNAME1 WILL BE THE NAME GIVEN BY THE USER OR THE DSNAME FROM IKJDAIR* 30200020
*IF THE USER SPECIFIED *.                                             * 30300020
*LINENUMS 1 AND 2 ARE AS SPECIFIED BY THE USER ON THE SUB-COMMAND.    * 30400020
*DSNAME2 WILL BE THE DSNAME FROM IKJDAIR.                             * 30500020
*LINENUM3 IS EITHER AS SPECIFIED ON THE SUB-COMMAND OR IF '*' IS      * 30600020
*SPECIFIED, THE CURRENT VALUE OF THE LINE POINTER IS USED.            * 30700020
*IF RENUM IS SPECIFIED, IT WILL BE INCLUDED IN THE MODEL COMMAND.     * 30800020
*                                                                     * 30900020
*********************************************************************** 31000020
         LA    LLNREG,MECMOPDS         INIT DISP TO BEG OF MODEL OPDS   31100020
         LA    TLNREG,KTEN             LENGTH OF HEADER+COMMAND         31200020
         L     MCMDREG,MEPCE1          PTR TO DSNAME                    31260020
         LA    LENREG,KONE             LENGTH OF ASTERISK        A42948 31270020
         CH    LENREG,MEPCE1+D4        IS LENGTH EQUAL TO ONE    A42948 31310020
         BNE   ME000525                IF NOT BRANCH AROUD CHECK A42948 31420020
         CLI   D0(MCMDREG),MEASTRK     DSNAME=*                  A42948 31470020
         BNE   ME000525                BR NO TO LOAD DA DSNAME   A42948 31520020
         LH    LENREG,CASADSNL         LENGTH OF DA DSNAME       A42948 31570020
         LA    MCMDREG,CASADSN         PTR TO DA DSNAME          A42948 31620020
         BAL   WKREG,ME002550          BR TO MOVE QUOTE          A42948 31670020
         B     ME000850                BR TO CONT PROCESSING     A42948 31680020
ME000525 LH    LENREG,MEPCE1+MELEN     GET LENGTH OF DSN         A42948 31700020
         TM    MEPCE1+MEFLG,MEQ        DSNAME QUOTED                    31720020
         BO    ME000600                BR YES                           31740020
         BAL   WKREG,ME002500          MOVE PARTIALLY QUALIFIED DSN     31760020
         TM    MEPCE1+D14,MEOPRD       WAS MEMBER SPECIFIED      A42948 31770020
         BNO   ME000800                IF NOT CONTINUE CHECKS    A42948 31772020
         BAL   WKREG,ME002505          PERFORM MEMBER MOVE       A42948 31774020
         MVC   D0(KTWO,LLNREG),MERPB   MOVE FINAL PAREND AND BLK A42948 31776020
         LA    LLNREG,KTWO(LLNREG)     UPDATE DISPLACEMENT       A42948 31778020
         LA    TLNREG,KTWO(TLNREG)     UPDATE TOTAL LENGTH       A42948 31778420
         B     ME000800                CONTINUE CHECKS           A42948 31780020
ME000600 BAL   WKREG,ME002550          BR TO MOVE QUOTE                 31840020
         TM    MEPCE1+D14,MEOPRD       WAS MEMBER SPECIFIED      A42948 31890020
         BNO   ME000800                IF NOT CONTINUE CHECKS    A42948 31990020
         BCTR  LLNREG,D0               DECREMENT DISPLACEMENT    A42948 32040020
         BAL   WKREG,ME002505          MOVE MEMBER NAME          A42948 32090020
         MVC   D0(D3,LLNREG),MERPBQ    MOVE IN PAREND,QUOTE,BLK  A42948 32092020
         LA    LLNREG,D3(LLNREG)       UPDATE DISPLACEMENT       A42948 32094020
         LA    TLNREG,D2(TLNREG)       UPDATE TOTAL LENGTH       A42948 32096020
ME000800 TM    MEPCE1+D22,MEOPRD       WAS PASSWORD SPECIFIED    A42948 32098020
         BNO   ME000850                IF NOT CONTINUE CHECKS    A42948 32098420
         BCTR  LLNREG,D0               DECREMENT DISPLACEMENT    A42948 32098820
         MVI   D0(LLNREG),SLASH        MOVE IN SLASH             A42948 32099220
         LA    LLNREG,D1(LLNREG)       UPDATE DISPLACEMENT       A42948 32099620
         LH    LENREG,MEPCE1+D20       GET PASSWORD LENGTH       A42948 32099720
         L     MCMDREG,MEPCE1+D16      GET PASSWORD DISPLACEMENT A42948 32099820
         BAL   WKREG,ME002500          MOVE IN PASSWORD          A42948 32099920
ME000850 TM    MEPCE2+MEFLG,MEOPRD     LINENUM1 GIVEN            A42948 32100020
         BZ    ME000900                NO BR FOR SECOND DSNAME          32200020
         LH    LENREG,MEPCE2+MELEN     YES GET LINENUM1 LENGTH          32300020
         L     MCMDREG,MEPCE2          PTR TO LINENUM1                  32400020
         BAL   WKREG,ME002500          BR TO MOVE SUBROUTINE            32500020
         LH    LENREG,MEPCE3+MELEN     LENGTH OF LINENUM2               32600020
         L     MCMDREG,MEPCE3          PTR TO LINENUM2                  32700020
         BAL   WKREG,ME002500          BR TO MOVE SUBROUTINE            32800020
ME000900 LH    LENREG,CASADSNL         LENGTH OF DA DSNAME              32900020
         LA    MCMDREG,CASADSN         DAIR DSNAME PTR                  33100020
         BAL   WKREG,ME002550          BR TO MOVE DSNAME                33200020
         L     MCMDREG,MEPCE4          PTR TO LINE NUMBER               33300020
         CLI   D0(MCMDREG),MEASTRK     LINENUM3=*                       33400020
         BE    ME002400                YES BR TO GET CURRENT LINE PTR   33600020
         LH    LENREG,MEPCE4+MELEN     NO GET LENGTH OF LINENUM3        33700020
ME001100 BAL   WKREG,ME002500          BR TO MOVE SUBROUTINE            33900020
ME001105 CLI   MEPCE6+D1,KONE          CHECK IF NUM/NONUM       SA66978 33950021
*                                      KEYWORD SPECIFIED         A45104 33954021
         BL    ME001180                IF NOT, CONTINUE PROCESS  A45104 33958021
         BH    ME001160                IF 'NONUM', BRANCH TO     A45104 33962021
*                                      PROCESS                   A45104 33966021
         MVC   D0(KTHREE,LLNREG),MENUM MOVE 'NUM' KEYWD TO MODEL A45104 33970021
         TM    MEPCS21+MEFLG,MEOPRD    CHECK IF LINE NUMBER      A45104 33974021
*                                      POSITION ENTERED          A45104 33978021
         BO    ME001120                IF SO, BRANCH TO PROCESS  A45104 33982021
*                                      SUBFIELD                  A45104 33986021
         MVI   D3(LLNREG),MEBLANK      IF NOT, MOVE BLANK        A45104 33990021
         LA    LLNREG,KFOUR(,LLNREG)   INCREMENT DISPLACEMENT    A45104 33994021
         LA    TLNREG,KFOUR(,TLNREG)   INCREMENT TOTAL LENGTH    A45104 33998021
         B     ME001180                BRANCH TO CONTINUE        A45104 34002021
ME001120 EQU   *                                                 A45104 34006021
         MVC   D3(MENUMLEN-D3,LLNREG),MENUM+D3 MOVE SUBFIELD     A45104 34010021
*                                      MAP TO MODEL BUFFER       A45104 34014021
         LH    LENREG,MEPCS21+MELEN    OBTAIN LENGTH OF OPERAND  A45104 34018021
         BCTR  LENREG,D0               DECREMENT FOR MOVE        A45104 34022021
         L     WKREG,MEPCS21           OBTAIN ADDRESS OF LINE    A45104 34026021
*                                      NUMBER POSITION ENTERED   A45104 34030021
         EX    LENREG,MEMVCLNP         MOVE LINE NUMBER POSITION A45104 34034021
*                                      OPERAND                   A45104 34038021
         TM    MEPCS22+MEFLG,MEOPRD    CHECK IF LINE NUMBER      A45104 34042021
*                                      LENGTH SPECIFIED          A45104 34046021
         BZ    ME001140                IF NOT, UPDATE REGISTERS  A45104 34050021
         L     WKREG,MEPCS22           OBTAIN ADDRESS OF LINE    A45104 34054021
*                                      NUMBER LENGTH ENTERED     A45104 34058021
         MVC   MENUMLNL-MENUM(KONE,LLNREG),D0(WKREG) MOVE DIGIT  A45104 34062021
*                                      TO SUBFIELD               A45104 34066021
ME001140 EQU   *                                                 A45104 34070021
         LA    LLNREG,MENUMLEN(,LLNREG) INCREMENT DISPLACEMENT   A45104 34074021
         LA    TLNREG,MENUMLEN(,TLNREG) INCREMENT TOTAL LENGTH   A45104 34078021
         B     ME001180                 BRANCH TO CONTINUE       A45104 34082021
MEMVCLNP MVC   MENUMLNP-MENUM(*-*,LLNREG),D0(WKREG) MOVE LINE    A45104 34086021
*                                       NUMBER POSITION TO MODEL A45104 34090021
ME001160 EQU   *                                                 A45104 34094021
         MVC   D0(KSIX,LLNREG),MENONUM MOVE 'NONUM ' OPERAND     A45104 34098021
         LA    LLNREG,KSIX(,LLNREG)    INCREMENT DISPLACEMENT    A45104 34102021
         LA    TLNREG,KSIX(,TLNREG)    INCREMENT TOTAL LENGTH    A45104 34106021
ME001180 EQU   *                                                 A45104 34110021
         TM    CACFLAG1,CANONUM        DS LINE-NUMBERED          A45104 34114021
         BNZ   ME002460                BR NOT TO MOVE NONUM2     A45104 34118021
         B     ME002370                IF LINE-NUMBERED, BRANCH  A45104 34122021
*                                      TO MOVE NUM2 KEYWORD      A45104 34126021
*                                      (WITH SUBFIELD)           A45104 34130021
ME001200 MVC   D0(KFIVE,LLNREG),MERENUM MOVE 'RENUM' TO MODEL           34150020
         LA    LLNREG,KFIVE(LLNREG)    INCREMENT DISPLACEMENT           34200020
         LA    TLNREG,KFIVE(TLNREG)    INCREMENT TOTAL LENGTH           34250020
         TM    MEPCS11+MEFLG,MEOPRD    LINENUM PRESENT                  34700020
         BZ    ME001400                NO BR TO TOTAL                   34800020
         MVI   D0(LLNREG),MELPAREN     YES MOVE '(' TO MODEL            34900020
         LA    LLNREG,KONE(LLNREG)     LENGTH=1                         35000020
         LA    TLNREG,KONE(TLNREG)     TOTAL LENGTH                     35100020
         LH    LENREG,MEPCS11+MELEN    LENGTH OF LINENUM                35200020
         L     MCMDREG,MEPCS11         PTR TO LINENUM                   35300020
         BAL   WKREG,ME002500          BR TO MOVE SUBROUTINE            35400020
         TM    MEPCS12+MEFLG,MEOPRD    INCREMENT PRESENT                35500020
         BZ    ME001300                NO BR TO MOVE RIGHT PAREN        35600020
         LH    LENREG,MEPCS12+MELEN    LENGTH OF INCREMENT              35700020
         L     MCMDREG,MEPCS12         PTR TO INCREMENT                 35800020
         BAL   WKREG,ME002500          BR TO MOVE ROUTINE               35900020
ME001300 BCTR  LLNREG,NOBR             TOTAL DISP-1   NO BLANK          36000020
         MVI   D0(LLNREG),MERPAREN     MOVE ')' TO MODEL                36100020
         LA    LLNREG,KONE(LLNREG)     ACCOUNT FOR PARENTHESIS    M5135 36150021
ME001400 EQU   *                                                        36160020
         CLI   CADSCODE,CABASIC        DS TYPE=BASIC                    36220020
         BNE   ME001450                BR NO                            36280020
         MVC   D0(KSIX,LLNREG),MEBASIC MOVE ' BASIC' TO MODEL           36340020
         LA    TLNREG,KSIX(TLNREG)     TOTAL LENGTH                     36400020
ME001450 STH   TLNREG,MCMLEN           TOTAL LENGTH OF MODEL COMMAND    36500020
         MVC   MCMMRG(KSIX),MEMERGE    MOVE 'MERGE ' TO MODEL           36700020
         XC    MCMRES(L'MCMRES),MCMRES ZERO HALFWORD FOR SCAN           36750020
         EJECT                                                          36850020
*********************************************************************** 36900020
*                                                                     * 37000020
*IKJEBECI WILL ATTACH THE SYSTEM MERGE COMMAND, IKJEBMIN, WHICH WILL  * 37100020
*DO THE ACTUAL MERGE. A TWO-WORD PARAMETER LIST IS PASSED TO IKJEBECI.* 37200020
*WORD1 IS A POINTER TO THE COMMUNICATIONS AREA  WORD2 IS A POINTER TO * 37300020
*THE BUFFER CONTAINING THE MODEL COMMAND.                             * 37400020
*                                                                     * 37500020
*********************************************************************** 37600020
         ST    COMMREG,MECIPLST        PTR TO COMM AREA                 37700020
         LA    WKREG,MCMLEN            ADDR OF BUFFER                   37800020
         ST    WKREG,MECIPLST+D4       SECOND WORD OF PARMLIST          37900020
         LA    WKREG,MECIPLST          ADDR OF PARMLIST                 37940020
         IKJEBESH (COMMREG),IKJEBECI,PARAM=((WKREG)),MF=(E,MEPARMM)     37980020
         SPACE                                                          38120020
         TM    CAATTN,CAATTNIS         ATTENTION ISSUED                 38300020
         BO    ME001800                BR YES TO TERMINATE              38400020
         LTR   RETCDREG,RETCDREG       NO RETURN CODE=0                 38500020
         BNZ   ME003250                BR NO TO TERMINATE               38507020
         EJECT                                                          38514020
*********************************************************************** 38521020
*                                                                     * 38528020
*IKJEBEDA IS CALLED TO RE-ALLOCATE THE OUTPUT QSAM DATA SET.          * 38535020
*                                                                     * 38542020
*********************************************************************** 38549020
         OI    CASAFLAG,CASAUNCG       SECOND REQUEST FOR ALLOCATION    38563020
         BAL   WKREG,ME002480          BR TO CALL IKJEBEDA              38566020
*********************************************************************** 38572020
*                                                                     * 38800020
*IKJEBECO WILL COPY THE MERGED (QSAM) DATA SET TO A  NEW UTILITY DATA * 38900020
*SET. IF THE DATA SET TYPE IS NOT IPLI OR BASIC, IKJEBEEX WILL UN-    * 38940020
*ALLOCATE THE UTILITY DATA SET. THE CORE USED FOR THE PDL BY IKJPARS  * 38980020
*IS RELEASED,  AND CONTROL IS RETURNED TO IKJEBEMA WITH A RETURN CODE * 39020020
*OF ZERO IN REGISTER 15.                                              * 39060020
*                                                                     * 39400020
*********************************************************************** 39500020
         MVC   CAPTPDCB(L'CAPTPDCB),CAPTCDCB HAVE CURRENT DCB PTR TO    39600020
*                                      PREVIOUS DCB PTR                 39700020
         XC    CAPTCDCB(L'CAPTCDCB),CAPTCDCB ZERO CURRENT DCB PTR       39800020
         NI    CASAFLAG,MEALL-CASAINCP INIT COPY SW OFF                 39900020
         IKJEBESH (COMMREG),IKJEBECO,PARAM=((COMMREG)),MF=(E,MEPARMM)   40000020
         SPACE                                                          40110020
ME001500 EQU   *                                                        40200020
         B     ME001500+D4(RETCDREG)   CO RETURN CODE BR TABLE          40300020
         B     ME001600                00  NORMAL COMPLETION            40400020
         B     ME002470                04  EMPTY DATA SET               40500020
         B     ME002350                08  UNSUCCESSFUL OPERATION       40600020
         SPACE                                                          40601020
*********************************************************************** 40602020
*                                                                     * 40603020
*IKJEBEDA IS CALLED TO UNALLOCATE THE OUTPUT QSAM DATA SET.           * 40604020
*                                                                     * 40605020
*********************************************************************** 40606020
ME001600 EQU   *                                                        40606520
         OI    CASAFLAG,CASADISP+CASAUNCG SET SWITCH                    40606920
         BAL   WKREG,ME002480          BR TO CALL IKJEBEDA              40607020
         NI    MEDAALP,MEALL-MEEIGHTY  SET ALLOC DONE SW OFF            40609020
         EJECT                                                          40610020
*********************************************************************** 40620020
*                                                                     * 40640020
*IF THE DATA SET TYPE IS IPLI OR BASIC, IKJEBEMR IS CALLED TO DELETE  * 40660020
*THE OLD POLISH DATA SET AND BUILD A NEW ONE.                         * 40680020
*                                                                     * 40700020
*********************************************************************** 40720020
         OI    CASAFLAG,CASAINCP       SET INIT COPY SW ON              40760020
         OI    CACFLAG2,CADSMODS       INDICATE DATA SET MODIFIED       40807020
         L     WKREG,CACURNUM          CURRENT LINE PTR                 40814020
         ST    WKREG,CAIMLLNO          LAST LINE USED IN INPUT MODE     40821020
         CLI   CADSCODE,CAIPLI         DATA SET TYPE IPLI               40900020
         BE    ME001650                YES BR TO DELETE POLISH DS       40910020
         CLI   CADSCODE,CABASIC        DS TYPE=BASIC                    40920020
         BNE   ME001700                BR NO TO CONTINUE                40930020
ME001650 EQU   *                                                        40936020
         IKJEBESH (COMMREG),IKJEBEMR,PARAM=((COMMREG)),MF=(E,MEPARMM)   40942020
         SPACE                                                          40960020
ME001675 EQU   *                                                        40966020
         B     ME001675+D4(RETCDREG)   MR RC BRANCH TABLE               40972020
         B     ME001700                00  SUCCESSFUL OPERATION         40982020
         B     ME002300                04  UNSUCCESSFUL OPERATION       40992020
         B     ME002200                08  SYN CHECKER NOT OPERATIONAL  41002020
         B     ME003250                12  I/O ERROR ON NEW UTIL        41012020
         SPACE                                                          41020020
ME001700 L     WKREG,CAPTCDCB          CURRENT DCB PTR                  41100020
         MVC   CAPTCDCB(L'CAPTCDCB),CAPTPDCB MOVE PREVIOUS DCB PTR TO   41200020
*                                      CURRENT DCB PTR                  41300020
         ST    WKREG,CAPTPDCB          SAVE CURRENT IN PREVIOUS         41400020
         BAL   WKREGB,ME002495         BR TO CLOSE OLD UTILITY          41410020
         EJECT                                                          42000520
*********************************************************************** 42001020
*                                                                     * 42002020
* IKJPUTL IS INVOKED TO PUT THE 'MERGED' MESSAGE TO THE USER.    A50476 42002421
*                                                                     * 42004020
*********************************************************************** 42005020
         SPACE                                                          42007021
         XC    MEPUTPB(PTPBL),MEPUTPB  ZERO PARAMETER BLOCK      A50476 42009021
         LA    WKREG,MEPUTPB           OBTAIN PARAMETER BLOCK    A50476 42011021
*                                      ADDRESS                   A50476 42011421
         ST    WKREG,CATMPLST+IOPLIOPB-IOPL CHAIN TO PARM LIST   A50476 42011821
         L     WKREG,MEMSGADR          OBTAIN ADDRESS OF MESSAGE A50476 42012121
*                                      CSECT                     A50476 42012321
         USING IKJEBMEM,WKREG          ADDRESSABILITY            A50476 42013121
         PUTLINE OUTPUT=(MEOUTPUT,SINGLE,DATA),MF=(E,CATMPLST)   A50476 42013221
         DROP  WKREG                   END MSG ADDRESSABILITY    A50476 42013321
         LA    RETREG,KFOUR            OBTAIN CONSTANT FOR       A50476 42013421
*                                      RETURN CODE COMPARISON    A50476 42013621
         CR    RETREG,RETCDREG         CHECK RETURN CODE         A50476 42013821
         BH    ME001750                IF ZERO, CONTINUE NORMAL  A50476 42014021
*                                      PROCESSING                A50476 42014221
         BE    ME001900                IF ATTN ECB POSTED, BR    A50476 42014621
*                                      TO FREE PDL AND EXIT      A50476 42015021
         LA    RETREG,K16              OBTAIN CONSTANT FOR       A50476 42015421
*                                      RETURN CODE COMPARISON    A50476 42015821
         CR    RETREG,RETCDREG         CHECK RETURN CODE         A50476 42016221
         BE    ME002800                IF CONDITIONAL GETMAIN    A50476 42016621
*                                      FAILURE, BR TO DIAGNOSE   A50476 42017021
         B     ME003000                OTHERWISE, ISSUE COMMAND  A50476 42017421
*                                      SYSTEM ERROR DIAGNOSTIC   A50476 42017821
         SPACE 2                                                        42018221
**************************************************************** A50476 42018621
*                                                                A50476 42019021
* OUTPUT OF 'MERGED' MESSAGE WAS SUCCESSFUL.  READ CURRENT LINE  A50476 42019421
* LINE REFERENCE INTO VERIFY BUFFER AND SET 'LINE TO BE          A50476 42019821
* VERIFIED' SWITCH ON.                                           A50476 42020221
*                                                                A50476 42020621
**************************************************************** A50476 42021021
         SPACE                                                          42021421
ME001750 EQU   *                                                 A50476 42021821
         L     WKREG,CAPTCDCB          OBTAIN ADDRESS OF CURRENT A50476 42022221
*                                      UTILITY DCB               A50476 42022621
         ST    WKREG,MEUTPLST          STORE IN FIRST PARAMETER  A50476 42023121
*                                      WORD                      A50476 42023521
         MVI   MEUTPLST,MERDC          SPECIFY READ CURRENT OP   A50476 42023921
         LA    WKREG,CACURNUM          OBTAIN RECORD KEY ADDR    A50476 42024321
         ST    WKREG,MEUTWD2           STORE IN LIST             A50476 42024721
         LA    WKREG,CATEMPBF+D12      OBTAIN ADDRESS OF VERIFY  A50476 42024821
*                                      BUFFER                    A50476 42025221
         ST    WKREG,MEUTWD3           STORE IN LIST             A50476 42025621
         MVI   MEUTWD3,MEEIGHTY        MARK END-OF-LIST          A50476 42026021
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),MEUTPLST), A50476X42027621
               MF=(E,MEPARMM)          INVOKE IKJEBEUT           A50476 42029621
         LTR   RETCDREG,RETCDREG       CHECK IF READ SUCCESSFUL  A50476 42030021
         BNZ   ME003300                IF NOT, BRANCH TO         A50476 42030421
*                                      INDICATE I/O ERROR        A50476 42030821
         OI    CACFLAG1,CALNTOVF       IF SO, INDICATE A LINE    A50476 42030921
*                                      TO BE VERIFIED            A50476 42036721
         EJECT                                                          42052321
ME001800 TM    MEDAALP,MEEIGHTY        DAIR ALLOCATION PERFORMED        42100020
         BZ    ME001900                NO BR TO RELEASE PARSE CORE      42200020
*********************************************************************** 42300020
*                                                                     * 42400020
*IKJEBEDA WILL UNALLOCATE THE SEQUENTIAL DATA SET WITH DISPOSITION=   * 42500020
*OLD,KEEP.                                                            * 42600020
*                                                                     * 42700020
*********************************************************************** 42800020
         OI    CASAFLAG,CASADISP+CASAUNCG SET SWITCH                    42850020
         NI    MEDAALP,MEALL-MEEIGHTY  TURN OFF ALLOC SWITCH            42900020
         BAL   WKREG,ME002480          BR TO CALL IKJEBEDA              43100020
ME001900 TM    CAPRSPDL,CAFREEDL       PDL SW ON                        43200020
         BNZ   ME002000                NO SKIP RELEASE                  43300020
         IKJRLSA CAPTPRSD              RELEASE PARSE TABLE CORE         43600020
         OI    CAPRSPDL,CAFREEDL       TURN PDL SW ON                   43650020
         SPACE                                                          43700020
ME002000 EQU   *                                                        43800020
         LH    RETCDREG,MECODE         SET RETURN CODE                  44000020
         IKJEBERT (14,12),,RC=(15)     RESTORE REGISTERS AND RETURN     44300021
*                                      WITH RETURN CODE IN REGISTER 15  44400020
         EJECT                                                          44450020
ME002200 EQU   *                                                        44500020
         LA    WKREG,K16               SET RETURN CODE = 16             44550020
         STH   WKREG,MECODE            SAVE RETURN CODE                 44560020
         L     WKREG,CAPTCDCB          PTR TO NEW DCB                   44562020
         MVC   CAPTCDCB,CAPTPDCB       MOVE PTR TO OLD DCB              44564020
         ST    WKREG,CAPTPDCB          PTR TO NEW DCB                   44566020
         BAL   WKREGB,ME002495         BR TO CLOSE OLD UTILITY DS       44570020
         B     ME001900                BR TO END PROCESSING             44600020
         SPACE                                                          44800020
ME002300 EQU   *                                                        44850020
         L     WKREG,CAPTCDCB          POINTER TO NEW UTILITY DS DCB    44900020
         MVC   CAPTCDCB(L'CAPTCDCB),CAPTPDCB SWITCH UTIL DCB POINTERS   44950020
         ST    WKREG,CAPTPDCB          SAVE POINTER TO NEW DCB          45000020
ME002350 EQU   *                                                        45010020
         BAL   WKREGB,ME002495         BR TO CLOSE OLD DCB              45050020
         B     ME003250                BR TO SET RETURN CODE            45060020
         SPACE                                                          45065020
ME002370 EQU   *                                                        45067020
         MVC   D0(KFIVE,LLNREG),MENUM2 MOVE 'NUM2(' TO MODEL     A45104 45069021
         ST    LLNREG,MESAVE           SAVE ADDRESS OF NUM2      A45104 45069121
*                                      KEYWORD FOR POSSIBLE      A45104 45069221
*                                      LATER USE                 A45104 45069321
         LA    LLNREG,KFIVE(LLNREG)    INCREMENT DISPLACEMENT    A45104 45069421
         LA    TLNREG,KFIVE(TLNREG)    INCREMENT TOTAL           A45104 45069821
         SR    LENREG,LENREG           CLEAR REGISTER                   45069920
         IC    LENREG,CALINE           BEGINNING SEQUENCE COLUMN        45070020
         BAL   WKREGB,ME002490         BR TO CONVERT SUB-ROUTINE        45090020
         LA    LENREG,KTHREE           MAX LENGTH = 3                   45092020
         LA    MCMDREG,KFIVE(MCMDREG)  INCREMENT POINTER                45094020
ME002380 EQU   *                                                        45096020
         CLI   D0(MCMDREG),MECZERO     IS DIGIT = 0                     45098020
         BNE   ME002385                BR NO TO STORE                   45098420
         LA    MCMDREG,KONE(MCMDREG)   INCREMENT POINTER                45098820
         BCT   LENREG,ME002380         DECREMENT LENGTH AND LOOP        45099220
ME002385 EQU   *                                                        45099620
         BAL   WKREG,ME002500          MOVE VALUE TO MODEL              45099720
         SR    LENREG,LENREG           CLEAR REGISTER                   45133220
         IC    LENREG,CALENGTH         LENGTH OF SEQUENCE FIELD         45143220
         BAL   WKREGB,ME002490         BR TO CONVERT ROUTINE            45153220
         L     WKREG,D4(MCMDREG)       CONVERTED LENGTH                 45155220
         STC   WKREG,D0(LLNREG)        MOVE TO MODEL                    45157220
         MVI   D1(LLNREG),MERPAREN     MOVE ')' TO MODEL                45159220
         LA    LLNREG,KTWO(LLNREG)     INCREMENT DISPLACEMENT           45165220
         LA    TLNREG,KTWO(TLNREG)     INCREMENT TOTAL LENGTH           45165620
         BAL   WKREG,ME002540          MOVE BLANK TO MODEL       A45104 45165721
         BAL   WKREGB,ME002580         BRANCH TO SET NUM KEYWORD A45104 45165821
*                                      AND SUBFIELD AS NECESSARY A45104 45165921
         B     ME001200                BR TO FINISH MODEL               45166020
         SPACE                                                          45187720
ME002400 L     LENREG,CACURNUM         CURRENT LINE             SA66978 45188921
         LTR   LENREG,LENREG           CHECK FOR EMPTY DATA SET SA66978 45190921
         BZ    ME001105                YES-- DO NOT MOVE        SA66978 45192921
*                                      LINE NUMBER              SA66978 45194921
         TM    CACFLAG1,CANONUM        DS LINE NUMBERED         SA66978 45196921
         BNZ   ME002410                BR NO TO FIND REL REC NUM        45200020
         L     LENREG,CACURNUM         CURRENT LINE                     45230020
         BAL   WKREGB,ME002490         BR TO CONVERT LINE NUMBER        45260020
         B     ME001100                BR TO MAIN ROUTINE               45900020
         SPACE                                                          46000020
ME002410 LA    LENREG,KONE             SET COUNT=1                      46100020
         L     WKREG,CAPTCDCB          PTR TO CURRENT DCB               46200020
         ST    WKREG,MEUTPLST          FIRST WD OF PARMLIST             46300020
         MVI   MEUTPLST,MERDP          ENTRY CODE=X'01' READ PREVIOUS   46400020
         LA    WKREG,CACURNUM          PTR TO BINARY KEY OF RCD         46500020
         ST    WKREG,MEUTWD2           STORE IN UT PARMLIST             46550020
         XC    MEUTWD3(L'MEUTWD3),MEUTWD3 NO BUFFER                     46600020
         MVI   MEUTWD3,MEEIGHTY        PARMLIST DELIMITER               46700020
ME002420 LA    PARMREG1,MEUTPLST       ADDR OF PARMLIST                 46800020
         LR    PARMREG0,COMMREG        ADDR OF COMM AREA                46900020
         L     CALLREG,CAPTUT          ADDR OF IKJEBEUT                 47000020
         BALR  RETREG,CALLREG          BR TO READ RECORD                47100020
         SPACE                                                          47200020
ME002430 EQU   *                                                        47300020
         B     ME002430+D4(RETCDREG)   UT RETURN CODE BR TABLE          47400020
         B     ME002440                00  SUCCESSFUL                   47500020
         B     ME002450                04  EOD                          47600020
         B     ME003300                08  I/O ERROR                    47700020
ME002440 LA    LENREG,KONE(LENREG)     COUNT=COUNT+1                    47800020
         XC    MEUTWD2(L'MEUTWD2),MEUTWD2 NO PTR TO KEY. USE UT'S       47900020
*                                      INTERNAL REFERENCE               48000020
         MVI   MEUTWD2,MEEIGHTY        PARMLIST DELIMITER               48100020
         B     ME002420                BR TO READ NEXT RECD             48200020
ME002450 BAL   WKREGB,ME002490         BR TO CONVERT REL REC NUM        48230020
         B     ME001100                BR TO MOVE RELATIVE       A50953 48600021
*                                      RECORD NUMBER AND TO      A50953 48650021
*                                      COMPLETE BFR PROCESSING   A50953 48652021
ME002460 MVC   D0(KSEVEN,LLNREG),MENONUM2 MOVE 'NONUM2 ' TO      A45104 48660021
*                                      MODEL BUFFER              A45104 48690021
         LA    TLNREG,KSEVEN(TLNREG)   INCR TOTAL LENGTH         A45104 48720021
         BAL   WKREGB,ME002580         BRANCH TO SET NONUM       A45104 48750021
*                                      KEYWORD IF NECESSARY      A45104 48780021
         B     ME001450                BR TO MAIN ROUTINE               48820020
         SPACE                                                          49005020
ME002470 EQU   *                                                        49007020
         BAL   WKREGB,ME002495         BR TO CLOSE NEW UTILITY DCB      49009020
         B     ME002700                BR TO PUT OUT MSG                49035520
         SPACE                                                          49036020
*********************************************************************** 49036520
*                                                                     * 49037020
*THIS SUBROUTINE CALLS IKJEBEDA FOR ALLOCATION OR UNALLOCATION OF THE * 49037520
*TEMPORARY QSAM DATA SET.                                             * 49038020
*                                                                     * 49038520
*********************************************************************** 49039020
ME002480 EQU   *                                                        49039520
         IKJEBESH (COMMREG),IKJEBEDA,PARAM=((COMMREG)),MF=(E,MEPARMM)   49040020
         SPACE                                                          49040520
         LTR   RETCDREG,RETCDREG       RC = 0                           49041020
         BCR   8,WKREG                 BR YES TO COMPLETE               49041420
         LA    ANSREG,KEIGHT           CONSTANT OF 8                    49041520
         AH    RETCDREG,MECODE         ADD ANY RC ALREADY GOTTEN        49041920
         CR    RETCDREG,ANSREG         IS RC STILL 8                    49045420
         BE    ME002485                BR YES                           49045520
         SR    RETCDREG,ANSREG         SET HIGHER RC                    49045920
ME002485 EQU   *                                                        49046020
         STH   RETCDREG,MECODE         SAVE RC                          49046420
         B     ME001800                BR TO TERMINATE                  49046520
         SPACE                                                          49052420
*********************************************************************** 49055820
*                                                                     * 49059220
*THIS SUBROUTINE CONVERTS A NUMBER TO DECIMAL AND SETS UP REGISTERS   * 49062620
*FOR THE MOVE ROUTINE.                                                * 49066020
*                                                                     * 49069420
*********************************************************************** 49072820
ME002490 CVD   LENREG,MEPACK           CONVERT NUMBER TO DECIMAL        49076220
         UNPK  MELNUM(KEIGHT),MEPACK+D3(KFIVE) UNPACK NUMBER            49079620
         OI    MELNUM+D7,MECZERO       INSURE LAST DIGIT IS CHAR ZERO   49083020
         LA    LENREG,KEIGHT           LENGTH OF NUMBER                 49086420
         LA    MCMDREG,MELNUM          PTR TO CONVERTED NUMBER          49089820
         BR    WKREGB                  RETURN TO CALLER                 49093220
*********************************************************************** 49143220
*                                                                     * 49163220
*THIS CODE CALLS IKJEBEEX TO CLOSE A UTILITY DATA SET AND SWITCHES THE* 49165220
*DCB POINTERS UPON RETURN.                                            * 49165320
*                                                                     * 49165420
*********************************************************************** 49165520
ME002495 EQU   *                                                        49174120
         L     WKREG,CAPTCDCB          POINTER TO CURRENT DCB           49174220
         LTR   WKREG,WKREG             CHECK DATA SET ALLOCATED   M5137 49174621
         BZ    ME002497                IF NOT, BYPASS CLOSE       M5137 49175021
         IKJEBESH (COMMREG),IKJEBEEX,PARAM=((WKREG),(COMMREG)),        *49176220
               MF=(E,MEPARMM)                                           49176620
         SPACE                                                          49178620
ME002497 EQU   *                                                  M5137 49179021
         MVC   CAPTCDCB(L'CAPTCDCB),CAPTPDCB RESTORE PTR TO OTHER DCB   49180220
         XC    CAPTPDCB,CAPTPDCB       ZERO OLD POINTER                 49182620
         BR    WKREGB                  RETURN TO CALLER                 49182720
         EJECT                                                          49182820
*********************************************************************** 49191420
*                                                                     * 49200020
*THE FOLLOWING CODE IS A SUB-ROUTINE TO MOVE THE OPERAND POINTED TO   * 49300020
*BY MCMDREG TO THE MODEL COMMAND BUFFER. THE TOTAL DISPLACEMENT AND   * 49400020
*BUFFER LENGTH TO DATE ARE ACCUMULATED AND A BLANK IS PLACED IN THE   * 49500020
*BUFFER FOLLOWING THE OPERAND.                                        * 49600020
*                                                                     * 49700020
*********************************************************************** 49800020
ME002500 LA    WKREGB,ME002540         REGULAR MOVE BRANCH POINT        49860020
ME002525 BCTR  LENREG,NOBR             DECR LENGTH BY ONE FOR EXECUTE   49920020
         EX    LENREG,MECMDMVC         MOVE OPERAND TO MODEL            50000020
         LA    LENREG,KONE(LENREG)     PLUS ONE FOR EXECUTE             50100020
         AR    LLNREG,LENREG           TOTAL DISPLACEMENT               50200020
         AR    TLNREG,LENREG           TOTAL LENGTH                     50300020
         BR    WKREGB                  RETURN TO DSN MOVE IF NECESSARY  50350020
ME002540 MVI   D0(LLNREG),MEBLANK      MOVE BLANK TO MODEL              50420020
         LA    LLNREG,KONE(LLNREG)     PLUS ONE FOR BLANK               50500020
         LA    TLNREG,KONE(TLNREG)     TOTAL LENGTH                     50600020
         BR    WKREG                   RETURN TO MAIN ROUTINE           50700020
MECMDMVC MVC   D0(LENGTH,LLNREG),D0(MCMDREG) MOVE OPERAND TO MODEL      50750020
*********************************************************************** 50800020
*                                                                     * 50900020
*THE FOLLOWING SECTION OF CODE MOVES A QUOTE (') BEFORE AND AFTER THE * 51000020
*DSNAMES TO INSURE FULLY-QUALIFIED DATA SET NAMES.                    * 51100020
*                                                                     * 51200020
*********************************************************************** 51300020
ME002550 MVI   D0(LLNREG),MEQUOTE      MOVE QUOTE TO MODEL              51400020
         LA    LLNREG,KONE(LLNREG)     DISPLACEMENT +1                  51500020
         LA    TLNREG,KONE(TLNREG)     TOTAL LENGTH                     51600020
         LA    WKREGB,ME002575         DSN MOVE BRANCH POINT            51630020
         B     ME002525                BR TO DO MOVE                    51660020
ME002575 MVC   D0(KTWO,LLNREG),MEQB    MOVE '  TO MODEL                 51690020
         LA    LLNREG,KTWO(LLNREG)     DISP+2 FOR QUOTE AND BLANK       51720020
         LA    TLNREG,KTWO(TLNREG)     TOTAL LENGTH + 2                 51750020
         BR    WKREG                   BR TO MAIN ROUTINE               52500020
*                                                                A42948 52510020
*THE FOLLOWING SECTION OF CODE MOVES IN A LEFT PAREND AND THE    A42948 52520020
*MEMBER NAME                                                     A42948 52530020
*                                                                A42948 52540020
ME002505 BCTR  LLNREG,D0               DECREMENT DISPLACEMENT    A42948 52542020
         MVI   D0(LLNREG),MELPAREN     MOVE IN LEFT PAREND       A42948 52544020
         LA    LLNREG,D1(LLNREG)       UPDATE DISPLACEMENT       A42948 52546020
         LH    LENREG,MEPCE1+D12       GET LENGTH OF NAME        A42948 52548020
         L     MCMDREG,MEPCE1+KEIGHT   GET DISPLACEMENT OF NAME  A42948 52548420
         BAL   WKREGB,ME002525         PERFORM ACTUAL MOVE       A42948 52548820
         BR    WKREG                   BR TO CALLER              A42948 52549220
         EJECT                                                          52550020
**************************************************************** A45104 52560021
*                                                                A45104 52562021
*   THE FOLLOWING SECTION OF CODE SETS THE 'NUM' OR 'NONUM'      A45104 52563021
*   (ACCORDING TO THE LINE NUMBER STATUS OF THE EDIT DATA SET)   A45104 52564021
*   WHEN BOTH OF THE FOLLOWING CONDITIONS ARE TRUE --            A45104 52565021
*                                                                A45104 52566021
*       1.  NEITHER THE 'NUM' NOR THE 'NONUM' KEYWORD WAS        A45104 52568421
*           ON THE SUBCOMMAND.                                   A45104 52568821
*                                                                A45104 52569021
*       2.  '*' WAS SPECIFIED (OR DEFAULTED) AS 'DATA SET NAME'  A45104 52569221
*           ON THE SUBCOMMAND.                                   A45104 52569421
*                                                                A45104 52569621
**************************************************************** A45104 52570021
ME002580 EQU   *                                                 A45104 52580021
         CLI   MEPCE6+D1,KONE          CHECK IF NUM/NONUM KEYWD  A45104 52590021
*                                      ENTERED ON SUBCOMMAND     A45104 52592021
         BCR   GE,WKREGB               IF EITHER SPECIFIED,      A45104 52595021
*                                      RETURN TO CALLER          A45104 52598021
         L     WKREG,MEPCE1            OBTAIN PDE ADDRESS FOR    A45104 52601021
*                                      'DATA SET NAME'           A45104 52604021
         CLI   D0(WKREG),MEASTRK       CHECK IF DSNAME='*'       A45104 52607021
         BCR   NE,WKREGB               IF NOT, RETURN TO CALLER  A45104 52610021
         TM    CACFLAG1,CANONUM        CHECK IF EDIT DATA SET    A45104 52613021
*                                      IS 'NONUM'                A45104 52616021
         BO    ME002585                IF SO, BRANCH TO SET      A45104 52619021
*                                      'NONUM' KEYWORD           A45104 52622021
         L     WKREG,MESAVE            OBTAIN ADDRESS OF NUM2    A45104 52633221
*                                      KEYWORD (IN MODEL BUFFER) A45104 52636221
         LA    WKREG,D4(,WKREG)        OBTAIN ADDRESS OF NUM2    A45104 52639221
*                                      KEYWORD'S SUBFIELD        A45104 52642221
         LR    LENREG,LLNREG           MAKE COPY OF CURRENT BFR  A45104 52645221
*                                      ADDRESS                   A45104 52648221
         SR    LENREG,WKREG            COMPUTE LENGTH OF SUBFLD  A45104 52651221
         BCTR  LENREG,D0               ADJUST LENGTH FOR MVC     A45104 52654221
         MVC   D0(KTHREE,LLNREG),MENUM MOVE 'NUM' KEYWORD TO     A45104 52657221
*                                      MODEL                     A45104 52660221
         EX    LENREG,MEMVCNUM         COPY NUM2 SUBFIELD AFTER  A45104 52663221
*                                      NUM KEYWORD               A45104 52666221
         LA    LLNREG,KFOUR(LENREG,LLNREG) INCREMENT             A45104 52669221
*                                      DISPLACEMENT IN BFR       A45104 52672221
         LA    TLNREG,KFOUR(LENREG,TLNREG) INCREMENT TOTAL       A45104 52675221
*                                      LENGTH OF BFR             A45104 52678221
         BR    WKREGB                  RETURN TO CALLER          A45104 52681221
ME002585 EQU   *                                                 A45104 52684221
         MVC   D7(KFIVE,LLNREG),MENONUM MOVE NONUM KEYWORD TO    A45104 52687221
*                                      MODEL BUFFER              A45104 52690221
         LA    TLNREG,KFIVE(,TLNREG)   INCREMENT BUFFER LENGTH   A45104 52693221
         BR    WKREGB                  RETURN TO CALLER          A45104 52696221
MEMVCNUM MVC   D3(*-*,LLNREG),D0(WKREG) MOVE SUBFIELD AFTER NUM  A45104 52699221
*                                      KEYWORD                   A45104 52722121
         EJECT                                                   A45104 52732121
*********************************************************************** 52742121
*                                                                     * 52752121
*THE FOLLOWING MACROS SET UP PARMLISTS FOR ALL MESSAGES PUT OUT BY    * 52800020
*IKJEBEME.                                                            * 52900020
*                                                                     * 53000020
*********************************************************************** 53100020
ME002600 EQU   *                                                        53120020
         MVC   MELEV1(KTWO),MEM550     SET UP LEVEL1 PLIST              53140020
         B     ME003200                BR TO PUT OUT MSG                53160020
         SPACE                                                          53180020
ME002700 EQU   *                                                        53200020
         OI    MEDAALP,MEFORTY         SET EMPTY DS SWITCH ON           53210020
         MVC   MELEV1(KTWO),MEM501     SET UP LEVEL1 PLIST              53220020
         B     ME003200                BR TO PUT OUT MSG                53240020
         SPACE                                                          53260020
ME002800 EQU   *                                                        53280020
         MVC   MELEV1(KTWO),MEM312     SET UP LEVEL1 PLIST              53340020
         LA    WKREG,MEL1IN1           ADDR OF INSERTION PLIST          53400020
         ST    WKREG,MEIN1PT           CHAIN PLISTS                     53500020
         MVC   MEL1IN1(MEMG1L),MEMG1   LEVEL1 INSERTION                 53600020
         B     ME003200                BR TO PUT OUT MSG                53700020
         SPACE                                                          53800020
ME002900 EQU   *                                                        53820020
         MVC   MEL1IN1(MEMG3L),MEMG3   SET UP INSERTION PLIST           53840020
         B     ME003100                BR TO FINISH PLIST               53860020
         SPACE                                                          53880020
ME003000 EQU   *                                                        53900020
         MVC   MEL1IN1(MEMG4L),MEMG4   SET UP INSERTION PLIST           53920020
ME003100 EQU   *                                                        53940020
         MVC   MELEV1(KFOUR),MEM313    SET UP LEVEL1 PLIST              54020020
         LA    WKREG,MEL1IN1           ADDR OF INSERTION PLIST          54100020
         ST    WKREG,MEIN2PT           CHAIN PLISTS                     54200020
         LA    WKREG,MEL2IN2           ADDR OF INSERTION PLIST          54400020
         ST    WKREG,MEL1IN1           CHAIN PLISTS                     54500020
         MVC   MEL2IN2(MEMG2L),MEMG2   LEVEL2 INSERTION2                54600020
         SRL   RETCDREG,KONE           ADJUST R15 FOR INDEIXING         54700020
         LH    WKREG,MECDTAB(RETCDREG) PICK UP PRINTABLE CHARACTER      54800020
         STH   WKREG,MEIN2             STORE IN INSERT2                 54900020
ME003200 EQU   *                                                        55900020
         IKJEBEML ,,,,MF=(E,MEPARMM)   ML MACRO  E FORM                 57000020
         SPACE                                                          57050020
         TM    MEDAALP,MEFORTY         IS EMPTY DS SW ON                57060020
         BNZ   ME003275                BR YES                           57070020
ME003250 EQU   *                                                        57080020
         LA    WKREG,KEIGHT            SET RETURN CODE TO 8             57090020
         STH   WKREG,MECODE            SAVE RC                          57092020
         B     ME001800                BR TO COMPLETE                   57094020
ME003275 EQU   *                                                        57096020
         NI    MEDAALP,MEALL-MEFORTY   TURN EMPTY DS SW OFF RC=0        57098020
         B     ME001800                RETURN TO MAIN ROUTINE           57100020
         SPACE                                                          57130020
ME003300 EQU   *                                                        57140020
         LA    WKREG,KTWELVE           SET RETURN CODE = 12             57150020
         STH   WKREG,MECODE            SAVE RETURN CODE                 57152020
         B     ME001800                BR TO TERMINATE                  57160020
         SPACE                                                          65300020
*********************************************************************** 66000020
         SPACE                                                          66100020
         IKJEBEMI (312,313,501,550)    MESSAGE EQUATE MACRO             66200020
*                                                                       66300020
         SPACE                                                          66310020
MEMSGADR DC    V(IKJEBMEM)             ADDR OF MSG CSECT                66320020
         SPACE                                                          66330020
IKJEBMEM CSECT                                                          66340020
         SPACE                                                          66350020
MEOUTPUT DS    0F                      OUTPUT DESCRIPTOR FOR     A50476 66360021
*                                      'MERGED' MESSAGE          A50476 66362021
         DC    AL2(L10)                LIST LENGTH IS TEN        A50476 66370021
         DC    AL2(L0)                 ALWAYS ZERO               A50476 66380021
         DC    C'MERGED'               MESSAGE TEXT              A50476 66390021
MEM312   EQU   *                                                        66400020
         DC    AL2(M312)               REL LEV1 MSG NUMBER              66450020
         SPACE                                                          66700020
MEM313   EQU   *                                                        66800020
         DC    AL2(M313)               REL LEV1 MSG NUMBER              66830020
         DC    AL2(M3131)              REL LEV2 MSG NUMBER              66860020
         SPACE                                                          67100020
MEM550   EQU   *                                                        67600020
         DC    AL2(M550)               REL LEV1 MSG NUMBER              67650020
         SPACE                                                          67900020
MEM501   EQU   *                                                        68000020
         DC    AL2(M501)               REL LEV1 MSG NUMBER              68050020
         SPACE                                                          68300020
         DS    0F                                                       68350020
MEMG1    EQU   *                                                        68400020
         IKJEBEMG 0,M312IN1,'MERGE'                                     68500020
MEMG1L   EQU   *-MEMG1                                                  68600020
         SPACE                                                          68700020
         DS    0F                                                       68800020
MEMG2    EQU   *                                                        68900020
         IKJEBEMG 0,M3131IN2,'00'                                       69000020
MEMG2L   EQU   *-MEMG2                                                  69100020
         SPACE                                                          69110020
         DS    0F                                                       69115020
MEMG3    IKJEBEMG 0,M3131IN1,'PARSE'                                    69120020
MEMG3L   EQU   *-MEMG3                                                  69130020
         SPACE                                                          69140020
         DS    0F                                                       69150020
MEMG4    IKJEBEMG 0,M3131IN1,'PUTLINE'                           A50476 69160021
MEMG4L   EQU   *-MEMG4                                                  69170020
         SPACE                                                          69180020
         DS    0F                                                       69300020
IKJEBEME CSECT                                                          69500020
         SPACE                                                          69700020
MECDTAB  DS    0H                                                       70000020
         DC    C'  040812'             TABLE OF PRINTABLE CHARACTERS    70060020
         DC    C'162024'               EXTENSTION OF TABLE              70120020
         SPACE                                                          70220020
MEMERGE  DC    CL6'MERGE '             MERGE OPERAND FOR MODEL          70400020
MERENUM  DC    CL5'RENUM'              RENUM OPERAND FOR MODEL          70500020
MENONUM  DC    CL6'NONUM '             NONUM OPERAND FOR MODEL   A45104 70700021
MENONUM2 DC    CL7'NONUM2 '            NONUM2 OPERAND FOR MODEL  A45104 70705021
MENUM    DC    C'NUM('                 NUM OPERAND FOR MODEL            70710020
MENUMLNP DC    CL6' '                  POSITION FOR LINE NUMBER  A45104 70712021
MENUMLNL DC    CL1' '                  LENGTH FOR LINE NUMBER    A45104 70713021
MENUMEND DC    C') '                   TRAILER FOR NUM MODEL     A45104 70714021
MENUMLEN EQU   *-MENUM                 LENGTH OF MODEL ENTRY     A45104 70715021
MENUM2   DC    CL5'NUM2('              NUM2 OPERAND FOR MODEL    A45104 70716021
MERPB    DC    C') '                   RIGHT PAREND AND BLANK    A42948 70720020
MERPBQ   DC    C')'' '                 PAREND QUOTE AND BLANK    A42948 70722020
MEQB     DC    C''' '                  QUOTE AND BLANK FOR DSN MOVE     70730020
MEBASIC  DC    C' BASIC'               BASIC OPERAND FOR MODEL          70760020
         DS    0F                                                       70800020
MEPCLADR DC    V(IKJEBME0)             ADDRESS OF PCL                   71500020
         EJECT                                                          71900020
IKJEBME0 IKJPARM  DSECT=MEPCLL         BEGINNING OF PCL                 72400020
         SPACE                                                          72500020
MEPCE1   IKJPOSIT DSTHING,PROMPT='''FROM'' DATA SET NAME',             X72550020
               HELP=('THE NAME OF A DATA SET FROM WHICH DATA WILL BE TAX72600020
               KEN AS INPUT TO THE MERGE.')                             72650020
         SPACE                                                          72720020
MEPCE2   IKJIDENT 'LINE NUMBER',MAXLNTH=8,FIRST=NUMERIC,OTHER=NUMERIC   72800020
         SPACE                                                          72900020
MEPCE3   IKJIDENT 'LINE NUMBER',MAXLNTH=8,FIRST=NUMERIC,OTHER=NUMERIC   73000020
         SPACE                                                          73100020
MEPCE4   IKJIDENT 'LINENUMBER OR *',ASTERISK,MAXLNTH=8,                X73200020
               FIRST=NUMERIC,OTHER=NUMERIC,DEFAULT='*'                  73300020
         SPACE                                                          73400020
MEPCE5   IKJKEYWD                                                       73600020
         SPACE                                                          73700020
         IKJNAME  'RENUM',SUBFLD=MEPCS1                                 73800020
         SPACE                                                          73900020
MEPCE6   IKJKEYWD                                                       73950021
         IKJNAME 'NUM',SUBFLD=MEPCS2                             A45104 73960021
         IKJNAME 'NONUM'                                         A45104 73970021
         SPACE                                                          73980021
MEPCS1   IKJSUBF                                                        74000020
         SPACE                                                          74100020
MEPCS11  IKJIDENT 'LINE NUMBER',MAXLNTH=8,FIRST=NUMERIC,OTHER=NUMERIC   74200020
         SPACE                                                          74300020
MEPCS12  IKJIDENT 'INCREMENT',MAXLNTH=8,FIRST=NUMERIC,OTHER=NUMERIC     74400020
         SPACE                                                          74500020
MEPCS2   IKJSUBF                                                        74550021
MEPCS21  IKJIDENT 'LINE NUMBER POSITION',MAXLNTH=5,              A45104X74560021
               FIRST=NUMERIC,OTHER=NUMERIC                       A45104 74570021
MEPCS22  IKJIDENT 'LINE NUMBER LENGTH',MAXLNTH=1,FIRST=NUMERIC   A45104 74580021
         IKJENDP                                                        74600020
         EJECT                                                          74700020
         IKJPTPB                       PUTGET PARM BLOCK DSECT   A50476 74750021
PTPBL    EQU   *-PTPB                  LENGTH OF BLOCK           A50476 74760021
         EJECT                                                          74770021
*********************************************************************** 74800020
COMMAREA IKJEBECA                      COMMUNICATION AREA               74900020
         EJECT                                                          75000020
*********************************************************************** 75200020
         ORG   CASCWKA                 WORK AREA                        75300020
         SPACE                                                          75400020
MEPARMM  DS    10F                     MESSAGE PARMLIST                 75600020
MELEV1   EQU   MEPARMM                 LEVEL1                           75700020
MEIN1PT  EQU   MELEV1+4                PTR TO 1ST LEVEL INSERTION       75800020
MEIN2PT  EQU   MELEV1+8                PTR TO LEV2 INSERTION            75900020
MEL1IN1  EQU   MELEV1+12               LEVEL1 INSERTION                 76000020
MEIN1L   EQU   MEL1IN1+4               LENGTH OF LEVEL1 INSERTION       76100020
MEIN1    EQU   MEIN1L+4                LEVEL1 INSERTION                 76200020
MEEND    EQU   MEIN1+8                 END OF INSERT1 PLIST             76300020
MEL2IN2  EQU   MEEND                   LEVEL2 INSERTION2                76500020
MEIN2L   EQU   MEL2IN2+4               LENGTH OF INSERTION2             76600020
MEIN2    EQU   MEIN2L+4                INSERTION2                       76700020
         SPACE                                                          76800020
MEUTPLST DS    F                       UT PARMLIST                      76900020
MEUTWD2  DS    F                       RESERVED                         77000020
MEUTWD3  DS    F                       BYTE1=X'80'  PARMLIST DELIMITER  77100020
         SPACE                                                          77200020
MEDAALP  DS    X                       FLOW CONTROL SWITCH              77800020
*                                      X'80'=QSAM ALLOC DONE            77850020
*                                      X'40'=DS IS EMPTY                77900020
         SPACE                                                          78020020
MECIPLST DS    2F                      COMMAND INVOKER PARMLIST         78200020
         SPACE                                                          78210020
MEPUTPB  DS    0F                      PUTLINE PARM BLOCK        A50476 78240021
         ORG   MEPUTPB+PTPBL           ORG FOR LENGTH OF BLOCK   A50476 78242021
MECODE   DS    H                       RETURN CODE                      78350020
MESAVE   DS    F                       USED TO SAVE AN ADDRESS   A45104 78360021
*                                      OF DATA IN MODEL BUFFER   A45104 78380021
         SPACE                                                          78400020
         ORG   CABFRPL                 WORK AREA                        78500020
         SPACE                                                          78600020
MCMLEN   DS    H                       LENGTH OF MODEL COMMAND BUFFER   78800020
MCMRES   DS    H                       RESERVED                         78900020
MCMMRG   DS    CL6                     MERGE OPERAND                    79100020
MECMOPDS DS    CL146                   OPERANDS FOR MODEL COMMAND       79200020
         SPACE                                                          79300020
         DS    0D                                                       79600020
MEPACK   DS    D                       AREA FOR CONVERTING LINENUM3     79700020
MELNUM   DS    D                       AREA FOR UNPACKING LINENUM3      79800020
         EJECT                                                          80100020
         IKJPPL                        PARSE PARMLIST DSECT             80300020
         SPACE                                                          80302021
         IKJIOPL                       IO SERVICE ROUTINE PLIST DSECT   80360020
         END                                                            80500020
