         TITLE 'OS360 - TSO  EDIT COMMAND  IKJEBEMR-ITF INTERFACE'      00300020
IKJEBEMR CSECT                                                          00600020
*********************************************************************** 00900020
*                                                                     * 01200020
* STATUS -- VERSION NO. 001, OS/360 RELEASE NO. 20                    * 02100020
*                                                                     * 03000020
* FUNCTION -- THIS MODULE PROVIDES FOR THE RETRANSLATION OF THE ITF   * 03070020
*    REVERSE POLISH DATA SET AFTER A MERGE OR RENUMBER OPERATION. THE * 03140020
*    SYNTAX CHECKER IS CALLED TO DELETE THE OLD INTERMEDIATE DATA SET * 03210020
*    (BIT1 OF BYTE1 OF THE OPTION WORD SET TO 1). USING IKJEBEUT, THE * 03280020
*    EDIT UTILITY DATA SET IS READ AND PASSED LINE BY LINE TO THE SYN-* 03350020
*    TAX CHECKER TO BUILD A NEW INTERMEDIATE DATA SET (BIT0 OF BYTE1  * 03420020
*    SET TO 1).                                                       * 03490020
*                                                                     * 06000020
* ENTRY POINTS -- IKJEBEMR, MAIN ENTRY POINT.                         * 06100020
*                                                                     * 06200020
* INPUT -- REGISTER ONE POINTS TO THE COMMUNICATION AREA.             * 06400020
*                                                                     * 06600020
* OUTPUT -- THREE RETURN CODES CAN BE PASSED IN REGISTER 15.          * 06900020
*                                                                     * 07200020
*    0 - SUCCESSFUL COMPLETION                                        * 07500020
*                                                                     * 07800020
*    4 - UNSUCCESSFUL COMPLETION                                      * 08100020
*                                                                     * 08150020
*    8 - SYNTAX CHECKER NOT OPERATIONAL                               * 08400020
*                                                                     * 08450020
* EXTERNAL REFERENCES --                                              * 09000020
*                                                                     * 09600020
*         SYNTAX CHECKER CALLED TO DELETE AND BUILD THE POLISH DS     * 09900020
*                                                                     * 10500020
*         IKJEBEUT       CALLED TO READ THE UTILITY DATA SET          * 10800020
*                                                                     * 11400020
*         IKJEBEMS       CALLED TO SEND MESSAGES                      * 11700020
*                                                                     * 11900020
*         IKJEBEEX       CALLED TO DELETE THE NEW UTILITY DATA SET    * 12100020
*                                                                     * 12300020
*         MACROS USED --                                              * 12600020
*                                                                     * 12900020
*         IKJEBEML       INVOKES IKJEBEMS                             * 13200020
*                                                                     * 13500020
*         IKJEBEMG       CREATES MESSAGE INSERTION PARMLIST           * 13800020
*                                                                     * 14100020
*         IKJEBEMI       DEFINES EQUATES FOR MESSAGES                 * 14400020
*                                                                     * 14700020
*         IKJEBESV       ENTRY LINKAGE                                * 15000020
*                                                                     * 15300020
*         IKJEBESH       INVOKES EDIT MODULES                         * 15360020
*                                                                     * 15420020
*         IKJEBECA       DEFINES EDIT COMMUNICATION AREA              * 15480020
*                                                                     * 15540020
*         IKJEBERT       EXIT LINKAGE                                 * 15630020
*                                                                     * 15720020
*         CALL           INVOKES THE SYNTAX CHECKER                   * 15810020
*                                                                     * 15900020
* EXITS, NORMAL -- TO CALLER WITH RETURN CODE IN REGISTER 15          * 16500020
*                                                                     * 17400020
* EXITS, ERROR -- NONE                                                * 17700020
*                                                                     * 18000020
* TABLES/WORK AREAS -- IKJEBECA, THE EDIT COMMUNICATION AREA          * 18300020
*                                                                     * 18600020
*    CASRWKA   IKJEBEUT PARMLIST, SYNTAX CHECKER PARMLIST             * 18900020
*                                                                     * 19200020
*    CATEMPBF  READ-INTO BUFFER, MESSAGE PARMLIST                     * 19500020
*                                                                     * 19800020
* ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                  * 20100020
*                                                                     * 20400020
* CHARACTER CODE DEPENDENCY -- NONE                                   * 20460020
*                                                                     * 20520020
* NOTES -- STANDARD CONVENTIONS                                       * 20580020
*                                                                     * 20640020
*********************************************************************** 20700020
         EJECT                                                          21000020
*THE FOLLOWING EQU'S ALLOW SYMBOLIC ADDRESSING OF REGISTERS.            21300020
         SPACE                                                          21600020
PARMREG0 EQU   0                       CONTAINS ADDR OF COMMAREA FOR UT 21900020
PARMREG1 EQU   1                       CONTAINS ADDR OF COMM AREA ON    22200020
*                                      ENTRY. CONTAINS PARAMETERS FOR   22500020
*                                      CALLS TO MS AND SYNTAX CHECKER   22800020
WKREG    EQU   2                       GENERAL WORK REGISTER            23100020
MSGREG   EQU   4                       ADDRESSABILITY                   23400020
COMMREG  EQU   9                       CONTAINS ADDR OF COMMUNICATION   23700020
*                                      AREA                             24000020
BASEREG  EQU   11                      BASE REGISTER FOR THIS CSECT     24300020
DATAREG  EQU   12                      NOT USED                         24600020
SAVEREG  EQU   13                      CONTAINS ADDR OF SAVE AREA       24900020
RETREG   EQU   14                      CONTAINS ADDR OF RETURN ENTRY PT 25200020
CALLREG  EQU   15                      CONTAINS ADDR OF UT              25500020
RETCDREG EQU   15                      CONTAINS ADDR OF ENTRY PT,       25800020
*                                      CONTAINS RETURN CODE ON EXIT     26100020
         SPACE                                                          26400020
*THE FOLLOWING EQU'S ALLOW SYMBOLIC REFERENCE TO CHARACTER AND DECIMAL  26700020
*CONSTANTS.                                                             27000020
         SPACE                                                          27300020
D0       EQU   0                       DISPLACEMENT OF 0                27310020
D4       EQU   4                       DISPLACEMENT OF 4                27340020
D8       EQU   8                       DISPLACEMENT OF 8                27350020
KONE     EQU   1                       CONSTANT OF 1                    27352020
KFOUR    EQU   4                       CONSTANT OF 4                    27360020
KEIGHT   EQU   8                       CONSTANT OF 8                    27380020
K12      EQU   12                      CONSTANT OF 12                   27390020
K256     EQU   256                     CONSTANT OF 256                  27420020
MREIGHTY EQU   X'80'                   BIT MASK                         27430020
MRALL    EQU   X'FF'                   BIT MASK                         27440020
MROUTEC  EQU   X'02'                   READ NEXT ENTRY CODE FOR UT      27450020
MRDELCD  EQU   X'40'                   DELETE OPTION CODE               27460020
MRPRESV  EQU   X'47'                   BIT MASK                         27470020
MRPRES   EQU   X'87'                   BIT MASK                         27480020
MRINCD   EQU   X'80'                   INPUT OPTION CODE                27490020
MRRDF    EQU   X'04'                   READ FIRST RECORD ENTRY CODE     27500020
MRM      EQU   C'M'                    CHARACTER M                      27510020
         EJECT                                                          31500020
*********************************************************************** 31800020
         IKJEBESV (14,12),,*           ENTRY LINKAGE                    32100020
         SPACE                                                          32400020
         USING IKJEBECA,COMMREG        COMM AREA ADDRESSABILITY         32700020
         L     MSGREG,MRMSGADR         ADDR OF MESSAGE CSECT            33000020
         USING IKJEBMRM,MSGREG         ADDRESSABILITY OF MSG CSECT      33300020
*********************************************************************** 33350020
*                                                                     * 33400020
*THE SYNTAX CHECKER IS CALLED TO DELETE THE REVERSE POLISH DATA SET.  * 33450020
*                                                                     * 33500020
*********************************************************************** 33550020
         L     CALLREG,CAPTCHK         ADDR OF SYNTAX CHECKER           33560020
         LTR   CALLREG,CALLREG         SYNTAX CHECKER PRESENT           33570020
         BZ    MR001000                BR NO TO TERMINATE               33580020
         LA    PARMREG1,CASYNLST       ADDR OF PARMLIST FOR CHECKER     33600020
         LA    WKREG,MRSYNPLT          ADDR OF DELETE PARMLIST          33900020
         ST    WKREG,CASYNBFR          FIRST WD OF PARMLIST             34200020
         OI    CASYNCD2,MRDELCD        SET OPTION WORD CODE FOR DELETE  34500020
         NI    CASYNCD2,MRPRESV        PRESERVE BITS 5-7                34800020
         XC    MRSTART(L'MRSTART),MRSTART SET START LINE TO BINARY0'S   35100020
         MVC   MRSTOP(KFOUR),MRBNINES  SET END LINE TO BINARY 9'S       35400020
         CALL  (15)                    GO TO CHECKER TO DELETE REVERSE  36000020
*                                      POLISH DATA SET                  36300020
         SPACE                                                          36600020
         NI    CASYNCD2,MRALL-MRDELCD  RESET OPTION WD CD BYTE          36900020
MR000100 EQU   *                                                        37200020
         B     MR000100+D4(RETCDREG)   SYN CHK RC BR TABLE              37500020
         B     MR000200                00  SUCCESSFUL COMPLETION        37800020
         B     MR000150                04  ERROR, BUF CHECK COMPLETE    38100020
         B     MR001300                08  ERROR, BUF CHECK INCOMPLETE  38400020
         B     MR001300                12  LAST STMT IN BUF INCOMPLETE  38700020
         B     MR001400                16  NOT ENOUGH CORE              39000020
         B     MR001650                20  SYN CHKER NOT OPERATIONAL    39300020
         EJECT                                                          39600020
*********************************************************************** 39640020
*                                                                     * 39680020
*IKJEBEUT IS CALLED TO READ THE EDIT UTILITY DATA SET, ONE LINE AT A  * 39720020
*TIME, UNTIL THE ENTIRE UTILITY HAS BEEN READ.                        * 39760020
*                                                                     * 39800020
*********************************************************************** 39840020
MR000150 EQU   *                                                        39890020
         TM    CACFLAG1,CASCANSW       IS SCAN ALLOWED                  39892020
         BNZ   MR001625                BR YES TO SET RC=4               39894020
MR000200 L     WKREG,CAPTCDCB          PTR TO CURRENT DCB               39900020
         ST    WKREG,MRUTPLST          FIRST WORD OF PARMLIST           40200020
         MVI   MRUTPLST,MRRDF          ENTRY CODE=X'04' READ FIRST RCD  40500020
         XC    MRUTWD2(L'MRUTWD2),MRUTWD2 SET SCND WD OF PLIST TO ZERO  40800020
         MVI   MRUTWD2,MREIGHTY        PARMLIST DELIMITER=X'80'         41400020
MR000300 LA    PARMREG1,MRUTPLST       ADDR OF PARMLIST FOR UT          42000020
         LR    PARMREG0,COMMREG        ADDR OF COMM AREA                42300020
         L     CALLREG,CAPTUT          ADDR OF IKJEBEUT                 42600020
         BALR  RETREG,CALLREG          BR TO READ RECORD                42900020
         SPACE                                                          43200020
MR000400 EQU   *                                                        43500020
         B     MR000400+D4(RETCDREG)   UT RETURN CODE BR TABLE          43800020
         B     MR000500                00  SUCCESSFUL COMPLETION        44100020
         B     MR001000                04  EOD                          44400020
         B     MR001600                08  IO ERROR                     44700020
         EJECT                                                          45000020
*********************************************************************** 45040020
*                                                                     * 45080020
*EACH LINE READ BY IKJEBEUT IS PASSED TO THE SYNTAX CHECKER IN        * 45120020
*MRSYNBFR TO BUILD A NEW REVERSE POLISH DATA SET.                     * 45160020
*                                                                     * 45200020
*********************************************************************** 45240020
MR000500 OI    CASYNCD2,MRINCD         OPTION WD CD=INPUT               45300020
         NI    CASYNCD2,MRPRES         PRESERVE BITS 5-7                45600020
         TM    CACFLAG2,CARECFM        RECFM=VARIABLE                   45900020
         BZ    MR000900                BR YES                           46000020
         MVC   MRSYNBFR+D4(K256),D8(PARMREG1) STRIP KEY & LL00          46100020
MR000600 L     WKREG,MRBUFHDR          HEADER FOR BUFFER                46200020
         ST    WKREG,MRSYNBFR                                           46300020
         LA    WKREG,MRSYNBFR          PTR TO BUFFER                    46500020
         ST    WKREG,CASYNBFR          STORE IN PARMLIST                46800020
         LA    PARMREG1,CASYNLST       ADDR OF CHECKER PARMLIST         47100020
         L     CALLREG,CAPTCHK         ADDR OF SYNTAX CHECKER           47400020
         CALL  (15)                    GO TO CHECKER WITH ONE LINE      47700020
         SPACE                                                          48000020
         NI    CASYNCD2,MRALL-MRINCD   RESET OPTION WD CD BYTE          48300020
         LTR   RETCDREG,RETCDREG       RC = 0                           48350020
         BZ    MR000800                BR TO CONTINUE                   48400020
         LA    WKREG,KFOUR             CONSTANT OF 4                    48450020
         CR    RETCDREG,WKREG          RETURN CODE = 4                  48460020
         BE    MR000800                BR YES TO CONTINUE               48470020
         B     MR000100                BR TO PUT ERROR MSG              48500020
         SPACE                                                          51000020
MR000800 MVI   MRUTPLST,MROUTEC        YES SET UT ENTRY CODE=X'02'      51300020
         B     MR000300                LOOP UNTIL ALL LINES ARE READ    51600020
MR000900 MVC   MRSYNBFR+D4(K256),D4(PARMREG1) STRIP KEY ONLY            51900020
         B     MR000600                CONTINUE PROCESSING              52500020
         SPACE                                                          52800020
MR001000 SR    RETCDREG,RETCDREG       RC=0                             53100020
MR001100 IKJEBERT (14,12),,RC=(15)     EXIT LINKAGE                     53400020
         SPACE                                                          53700020
         EJECT                                                          54600020
*********************************************************************** 54670020
*                                                                     * 54740020
*WHEN RETURN CODES 8 AND 12 ARE RECEIVED, MESSAGE 313 IS ISSUED.      * 54810020
*WHEN RETURN CODE 16 IS PASSED, MESSAGE 312 IS ISSUED.                * 54860020
*                                                                     * 54950020
*********************************************************************** 55020020
MR001300 EQU   *                                                        55070020
         MVC   MRLEV1(MRM313L),MRM313  SET UP LEV1 PLIST                55090020
         LA    WKREG,MRL1IN1           CHAIN                            55200020
         ST    WKREG,MRIN2PT           PARMLISTS                        55500020
         MVC   MRIN1(D8),CASYNAME      NAME OF CHECKER                  55800020
         LA    WKREG,MRL2IN2           CHAIN                            55810020
         ST    WKREG,MRL1IN1           PARMLISTS                        55820020
         MVI   MRIN1L,K12              LENGTH OF INSERTION              55850020
         MVI   MRIN1O,M3131IN1         INSERTION POINT                  55900020
         MVC   MRL2IN2(MRMG3L),MRMG3   SET UP INSERT2 PLIST             56700020
         SRL   RETCDREG,KONE           SHIFT R15 FOR INDEXING           56750020
         LH    WKREG,MRRCTAB(RETCDREG) PICK UP PRINTABLE CHARACTER      56800020
         STH   WKREG,MRIN2             AND MOVE TO INSERTION            57000020
         B     MR001500                BR TO PUT MESSAGE                58500020
         SPACE                                                          58800020
MR001400 MVC   MRLEV1(MRM312L),MRM312  SET UP LEV1 PLIST                59100020
         LA    WKREG,MRL1IN1           CHAIN                            59400020
         ST    WKREG,MRIN1PT           PARMLISTS                        59700020
         L     WKREG,CAPTSCMD          PTR TO SUBCOMMAND                60000020
         CLI   D0(WKREG),MRM           1ST LETTER=M                     60300020
         BE    MR001450                BR YES                           60600020
         MVC   MRL1IN1(MRMG2L),MRMG2   SET UP INSERTION FOR RENUM       60900020
         B     MR001500                BR TO PUT MESSAGE                61200020
MR001450 MVC   MRL1IN1(MRMG1L),MRMG1   SET UP INSERTION FOR MERGE       61500020
         B     MR001500                BR TO PUT MESSAGE                61800020
         SPACE                                                          61900020
MR001500 EQU   *                                                        62100020
         IKJEBEML ,,,,MF=(E,MRPARM)    LINK TO IKJEBEMS                 62400020
         SPACE                                                          62430020
         B     MR001625                BR TO SET RETURN CODE            62430420
*********************************************************************** 62432020
*                                                                     * 62434020
*IF RETRANSLATION COULD NOT BE ACCOMPLISHED, THE NEW EDIT UTILITY DATA* 62436020
*SET IS DELETED BY A CALL TO IKJEBEEX, AND THE OLD UTILITY IS RESTORED* 62438020
*TO 'CURRENT' STATUS.                                                 * 62440020
*                                                                     * 62442020
*********************************************************************** 62444020
MR001600 EQU   *                                                        62446020
         L     WKREG,CAPTCDCB          PTR TO CURRENT DCB               62448020
         IKJEBESH (COMMREG),IKJEBEEX,PARAM=((WKREG),(COMMREG)),        X62450020
               MF=(E,MRPARM)                                            62452020
         SPACE                                                          62550020
         MVC   CAPTCDCB(L'CAPTCDCB),CAPTPDCB SET CURRENT = OLD UTIL DS  62580020
         XC    CAPTPDCB,CAPTPDCB       NO PREVIOUS DCB                  62610020
         LA    RETCDREG,K12            SET RETURN CODE TO 12            62620020
         B     MR001100                RETURN                           62630020
MR001625 EQU   *                                                        62660020
         LA    RETCDREG,KFOUR          SET RC=4                         62670020
         B     MR001100                RETURN                           63000020
         SPACE                                                          63010020
MR001650 EQU   *                                                        63020020
         LA    RETCDREG,KEIGHT         SET RETURN CODE = 8              63030020
         B     MR001100                BR TO RETURN                     63040020
         SPACE                                                          63300020
         IKJEBEMI (312,313)            MESSAGE EQUATE MACRO             63600020
         EJECT                                                          63900020
MRMSGADR DC    V(IKJEBMRM)             ADDR OF MSG CSECT                64200020
         SPACE                                                          64500020
IKJEBMRM CSECT                                                          64800020
         SPACE                                                          65100020
MRM312   IKJEBEML M312,0,0,0,MF=L                                       65400020
MRM312L  EQU   *-MRM312                                                 65700020
         SPACE                                                          66000020
MRM313   IKJEBEML M313,M3131,0,0,MF=L                                   66300020
MRM313L  EQU   *-MRM313                                                 66600020
         SPACE                                                          66900020
         DS    0F                                                       67200020
MRMG1    IKJEBEMG 0,M312IN1,'MERGE'                                     67500020
MRMG1L   EQU   *-MRMG1                                                  67800020
         SPACE                                                          68100020
         DS    0F                                                       68400020
MRMG2    IKJEBEMG 0,M312IN1,'RENUM'                                     68700020
MRMG2L   EQU   *-MRMG2                                                  69000020
         SPACE                                                          69300020
         DS    0F                                                       69600020
MRMG3    IKJEBEMG 0,M3131IN2,'00'                                       69900020
MRMG3L   EQU   *-MRMG3                                                  70200020
         SPACE                                                          70500020
MRRCTAB  DS    0H                       TABLE OF                        70550020
         DC    C'00040812'              PRINTABLE RETURN CODES          70600020
IKJEBEMR CSECT                                                          70800020
         SPACE                                                          71100020
         DS    0F                                                       71400020
         SPACE                                                          73200020
MRBNINES DC    F'99999999'             ENDING LINE NUMBER               73500020
MRBUFHDR DC    X'00010000'             HEADER FOR BUFFER                74900020
*********************************************************************** 74950020
         EJECT                                                          75000020
         IKJEBECA                      COMMUNICATIONS AREA              75300020
         EJECT                                                          75600020
         ORG   CASRWKA                 WORKAREA                         75900020
         SPACE                                                          76200020
MRSYNPLT DS    0F                      SYNTAX CHECKER PARMLIST          76220020
MRRESV   DS    F                       RESERVED                         76240020
MRSTART  DS    F                       STRTING LINE NUMBER FOR DELETE   76260020
MRSTOP   DS    F                       ENDING LINE NUMBER FOR DELETE    76280020
         SPACE                                                          76300020
MRUTPLST DS    F                       PARMLIST FOR IKJEBEUT            76320020
MRUTWD2  DS    F                       SECOND WORD                      76340020
MRUTWD3  DS    F                       THIRD WORD                       76360020
         SPACE                                                          76380020
         ORG   CATEMPBF                WORK AREA                        76400020
         SPACE                                                          76420020
MRPARM   DS    12F                     MESSAGE PARMLISTS                76520020
MRLEV1   EQU   MRPARM                  LEV1 PARMLISTS                   76800020
MRIN1PT  EQU   MRLEV1+4                PTR TO LEV1 INSERTION PLIST      77100020
MRIN2PT  EQU   MRLEV1+8                PTR TO LEV2 INSERTION PLIST      77400020
MRL1IN1  EQU   MRLEV1+12               INSERTION1 PARMLIST              77700020
MRIN1L   EQU   MRL1IN1+5               LENGTH OF INSERTION              77750020
MRIN1O   EQU   MRL1IN1+7               INSERTION POINT                  77800020
MRIN1    EQU   MRL1IN1+8               INSERTION1                       78000020
MRL2IN2  EQU   MRIN1+16                INSERTION2 PARMLIST              78300020
MRIN2L   EQU   MRL2IN2+4               LENGTH OF INSERTION2             78600020
MRIN2    EQU   MRIN2L+4                INSERTION2                       78900020
         SPACE                                                          83100020
         DS    0F                                                       83200020
MRSYNBFR DS    F                       BUFFER FOR                       83300020
         DS    256C                    SYNTAX CHECKER                   83400020
         SPACE                                                          83700020
         END                                                            84000020
