         TITLE 'TSO EDIT COMMAND - IKJEBEMS - MESSAGE SELECT ROUTINE'   00200020
IKJEBEMS CSECT                                                          00400020
*********************************************************************** 00500020
*                                                                     * 00600020
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 00700020
*                                                                     * 00800020
* FUNCTION --                                                         * 00900020
*    THIS PROGRAM USES THE PUTLINE SERVICE ROUTINE FOR                * 01000020
*    TERMINAL OUTPUT OF EDIT MESSAGES.  IT LOADS THE APPROPRIATE      * 01100020
*    MESSAGE MODULE, AND SELECTS THE REQUESTED MESSAGE FROM IT.       * 01200020
*    INSERTIONS AND SECOND-LEVEL MESSAGES ARE PROCESSED IN            * 01300020
*    BUILDING PARAMETERS FOR PUTLINE.  PUTLINE IS INVOKED VIA         * 01400020
*    LINK MACRO FOR TERMINAL OUTPUT OF THE DESIRED MESSAGE. PRIOR TO  * 01500020
*    RETURN TO THE CALLING ROUTINE THE IN-CORE MESSAGE MODULE IS      * 01600020
*    DELETED FROM MAIN STORAGE.                                       * 01700020
*                                                                     * 01800020
*    A SECOND FUNCTION OF THIS ROUTINE IS TO CAUSE TERMINAL           * 01900020
*    OUTPUT OF THE CURRENT LINE WHEN 'VERIFY ON' IS IN EFFECT.        * 02000020
*    WHEN THE 'CATPUTVF' BIT IN THE EDIT COMMUNICATION AREA IS B'1',  * 02100020
*    THE VERIFY BUFFER ADDRESS IS LOADED FROM WORD TWO OF THE         * 02200020
*    PARAMETER LIST, AND A DATA OUTPUT DESCRIPTOR IS BUILT FOR        * 02300020
*    PUTLINE.  IKJPUTL IS THEN INVOKED VIA LINK MACRO.                * 02400020
*                                                                     * 02500020
* ENTRY POINTS --                                                     * 02600020
*         IKJEBEMS - INVOKED BY IKJEBESH MACRO FROM ANY EDIT ROUTINE  * 02700020
*         THAT ISSUES MESSAGES                                        * 02800020
*                                                                     * 02900020
* INPUT --                                                            * 03000020
*    1. REGISTER ZERO (0) CONTAINS A POINTER TO THE EDIT COMMUNICATION* 03100020
*    AREA.                                                            * 03200020
*                                                                     * 03300020
*    2.  REGISTER ONE (1) CONTAINS A POINTER TO A PARAMETER LIST      * 03400020
*    CONTAINING -                                                     * 03500020
*                                                                     * 03600020
*    A.  BYTE MESSAGE MODULE INDICATOR (X'01'-X'07')                  * 03700020
*    B.  BYTE RELATIVE FIRST-LEVEL MESSAGE NUMBER                     * 03800020
*    C.  HALFWORD RELATIVE SECOND-LEVEL MESSAGE NUMBER                * 03900020
*    D.  FULLWORD ADDRESS OF FIRST FIRST-LEVEL INSERTION              * 04000020
*    E.  FULLWORD ADDRESS OF FIRST SECOND-LEVEL INSERTION             * 04100020
*                                                                     * 04200020
* OUTPUT --                                                           * 04300020
*    REGISTER FIFTEEN (15) CONTAINS THE IKJPUTL RETURN CODE,          * 04400020
*    INDICATING WHETHER THE MESSAGE OUTPUT WAS SUCCESSFUL OR NOT.     * 04500020
*    RETURN CODES ARE -                                               * 04600020
*                                                                     * 04700020
*    00 - SUCCESSFUL OPERATION                                        * 04800020
*    04 - PROCESSING INTERRUPTED BY ATTENTION INTERRUPT               * 04900020
*    08 - NOWAIT SPECIFIED - OUTPUT NOT SENT                          * 05000020
*    12 - INVALID PARAMETERS                                          * 05100020
*    16 - GETMAIN FAILURE                                             * 05200020
*                                                                     * 05300020
* EXTERNAL REFERENCES --                                              * 05400020
*                                                                     * 05500020
*         IKJEBEM1-M7 - SEVEN EDIT MESSAGE MODULES LOADED AND DELETED * 05600020
*         AS REQUIRED.  THESE MODULES CONTAIN CONTROL LISTS FOR ALL   * 05700020
*         EDIT MESSAGES.                                              * 05800020
*                                                                     * 05900020
*         IKJPUTL - PUTLINE SERVICE ROUTINE, INVOKED VIA LINK MACRO   * 06000020
*         TO PUT EDIT MESSAGES TO THE TERMINAL                        * 06100020
*                                                                     * 06200020
*    MACROS USED --                                                   * 06300020
*                                                                     * 06400020
*         DELETE   - CAUSES THE MAIN STORAGE AREA OCCUPIED BY A       * 06500020
*         MESSAGE MODULE TO BE RELEASED                               * 06600020
*                                                                     * 06700020
*         LOAD     - LOADS MESSAGE MODULES INTO MAIN STORAGE          * 06800020
*                                                                     * 06900020
*         IKJEBESV - SAVE CALLER'S REGISTERS AND ESTABLISH            * 07000020
*         ADDRESSABILITY                                              * 07100020
*                                                                     * 07200020
*         IKJEBERT - RESTORE CALLER'S REGISTERS AND RETURN            * 07300020
*         WITH RETURN CODE IN REGISTER FIFTEEN (15)                   * 07400020
*                                                                     * 07500020
*         PUTLINE  - ESTABLISHES IKJPUTL PARAMETER LIST AND           * 07600020
*         LINK TO IKJPUTL                                             * 07700020
*                                                                     * 07800020
*         IKJEBECA - DSECT FOR EDIT COMMUNICATION AREA                * 07900020
*                                                                     * 08000020
* EXITS, NORMAL --                                                    * 08100020
*    RETURN TO CALLER BY BRANCHING ON REGISTER FOURTEEN (14) WITH     * 08200020
*    REGISTER FIFTEEN (15) SET TO THE PUTLINE RETURN CODE             * 08300020
*                                                                     * 08400020
* EXITS, ERROR -- NONE                                                * 08500020
*                                                                     * 08600020
* TABLES/WORK AREAS --                                                * 08700020
*                                                                     * 08800020
*    THE EDIT COMMUNICATION AREA CONTAINS A WORK AREA FOR THIS MODULE,* 08900020
*    CONTROL INFORMATION AND BUFFER AREAS.                            * 09000020
*                                                                     * 09100020
*    IKJPUTL OUTPUT AREA - USED BY THE PUTLINE SERVICE ROUTINE TO     * 09200020
*    CONSTRUCT THE OUTPUT LINES FOR FIRST- AND SECOND-LEVEL MESSAGES. * 09300020
*                                                                     * 09400020
*    THERE ARE TWO POSSIBLE FORMATS -                                 * 09500020
*                                                                     * 09600020
*    1.  FIRST- AND SECOND-LEVEL SPECIFIED -                          * 09700020
*                                                                     * 09800020
*    A.  POINTER TO SECOND LEVEL OUTPUT AREA                          * 09900020
*    B.  NUMBER OF MESSAGE SEGMENTS                                   * 10000020
*    C.  POINTER TO FIRST MESSAGE SEGMENT - BASIC MESSAGE             * 10100020
*    D.  (LIST OF POINTERS TO SUCCESSIVE SEGMENTS.  THE MAXIMUM       * 10200020
*    NUMBER OF INSERTIONS IS 255 FOR THE PUTLINE ROUTINE.)            * 10300020
*                                                                     * 10400020
*    NOTE - IN THE SECOND-LEVEL OUTPUT DESCRIPTOR,  IKJEBEMS SETS     * 10500020
*    THE POINTER TO THE NEXT-LEVEL DESCRIPTOR TO X'FF000000' TO       * 10600020
*    INDICATE THAT THERE IS NO THIRD-LEVEL OUTPUT.                    * 10700020
*                                                                     * 10800020
*    2.  THE SINGLE-LEVEL FORMAT IS THE SAME EXCEPT THAT              * 10900020
*    THERE IS NO POINTER TO THE SECOND-LEVEL OUTPUT.                  * 11000020
*                                                                     * 11100020
* ATTRIBUTES --                                                       * 11200020
*    REFRESHABLE, ENABLED, NON-PRIVILEGED                             * 11300020
*                                                                     * 11400020
* CHARACTER CODE DEPENDENCY -- NONE                                   * 11500020
*                                                                     * 11600020
* NOTES --                                                            * 11700020
*    FOUR (4) INSERTIONS ARE PRESENTLY SUPPORTED FOR EDIT MESSAGES.   * 11800020
*                                                                     * 11900020
*********************************************************************** 12000020
         SPACE 2                                                        21000020
*********************************************************************** 21200020
*                                                                       21400020
*                             REGISTER EQU'S                            21600020
*                                                                       21800020
*********************************************************************** 22000020
COMMREG  EQU   9              COMMUNICATION AREA PTR                    22200020
BASEREG  EQU   11             CODE BASE REGISTER                        22400020
DATAREG  EQU   12             POINTS TO DYNAMIC CORE                    22600020
SAVEREG  EQU   13             POINTS TO CURRENT SAVE AREA               22800020
RETREG   EQU   14             RETURN ADDR FROM LINKAGE                  23000020
RETCDREG EQU   15             CONTAINS RETURN CODE                      23200020
PARMREG1 EQU   1              PARAMETER REGISTER 1                      23400020
PARMREG0 EQU   0              PARAMETER REGISTER 0                      23600020
NOBRANCH EQU   0              USED IN BCTR WHEN NO BRANCH IS DESIRED    23800020
WR1      EQU   2              WORK REGISTER                             24000020
WR2      EQU   3              WORK REGISTER                             24200020
WR3      EQU   4              WORK REGISTER                             24400020
WR4      EQU   5              WORK REGISTER                             24600020
WR5      EQU   6              WORK REGISTER                             24800020
WR6      EQU   7              WORK REGISTER                             25000020
         SPACE 2                                                        25200020
*********************************************************************** 25400020
*                                                                       25600020
*                            SPECIAL EQU'S                              25800020
*                                                                       26000020
*********************************************************************** 26200020
         SPACE 2                                                        26400020
ZERO     EQU   0              DISPLACEMENT OF ZERO                      26600020
ONE      EQU   1              DISPLACEMENT OF ONE                       26800020
TWO      EQU   2              DISPLACEMENT OF TWO                       27000020
FOUR     EQU   4              DISPLACEMENT OF FOUR                      27200020
FIVE     EQU   5              DISPLACEMENT OF FIVE                      27400020
LENGTH5  EQU   5              LENGTH OF FIVE                            27600020
SEVEN    EQU   7              DISPLACEMENT OF SEVEN                     27800020
EIGHT    EQU   8              DISPLACEMENT OF EIGHT                     28000020
LENGTH8  EQU   8              LENGTH OF EIGHT                           28200020
TWELVE   EQU   12             DISPLACEMENT OF TWELVE                    28400020
LENGTH20 EQU   20             LENGTH OF TWENTY                          28600020
BLANK    EQU   C' '           CHARACTER BLANK                           28800020
CHARZERO EQU   C'0'           CHARACTER ZERO                            29000020
         EJECT                                                          29200020
         IKJEBESV (14,12),,,COMMREG=(0) ENTRY LINKAGE                   29400020
         USING IKJEBECA,COMMREG         DEFINE COMM AREA                29600020
         USING DATA,DATAREG             DEFINE DYNAM DATA               29800020
         LA   DATAREG,CAMSWKA           LOAD PTR TO DYNAMIC AREA        30000020
         EJECT                                                          30400020
*********************************************************************** 30600020
*                                                                       30800020
* THIS SECTION HANDLES THE BUILDING OF THE LEVEL 1 AND LEVEL 2 MSG      31000020
* CHAINS AND THE REQUIRED PARAMETER LISTS                               31200020
*********************************************************************** 31400020
         LR    WR2,PARMREG1             COPY PARAMETER LIST ADDRESS     31600020
         USING INPARMD,WR2              ESTABLISH PARAMETER             31800020
*                                       ADDRESSABILITY                  32000020
         TM    CACFLAG4,CATPUTVF        IS TERMINAL OUTPUT OF THE       32200020
*                                       VERIFY LINE REQUESTED           32400020
         BO    MSVERIFY                 IF SO BRANCH TO PROCESS         32600020
         LH    WR3,RLEV2MSG             GET LEVEL 2 NUMBER              32800020
         LTR   WR3,WR3                  WAS SECOND LEVEL MSG PROVIDED   33000020
         BNZ   LEVEL2                   BRANCH IF YES                   33200020
         MVC   PTLPBLK(LENGTH20),PUTLNL1 MOVE PARM BLOCK TO DYNAM AREA  33400020
         B     BLDPARM                  BRANCH TO PROCESS MESSAGE       33600020
LEVEL2   MVC   PTLPBLK(LENGTH20),PUTLNL2 MOVE PARM BLOCK TO DYNAM AREA X33800020
                                        LEVEL MESSAGES TO DYNAMIC AREA  34000020
BLDPARM  EQU   *                                                        34200020
         SR    WR4,WR4                  ZERO INDEX REGISTER.            34700020
         IC    WR4,MSLOADMD             GET MODULE INDICATOR FROM       35200020
*                                       THE PARAMETER LIST              35700020
         LA    WR4,MSTBLOAD(WR4)        ADDRESS LAST CHARACTER OF       36400020
*                                       MODULE NAME                     36600020
         MVC   MSLOADNM(SEVEN),MSNMLOAD MOVE FIRST SEVEN CHAR-          36800020
*                                       ACTERS TO WORK AREA             37000020
         MVC   MSLOADNM+SEVEN(ONE),ZERO(WR4) MOVE FINAL CHARACTER       37200020
*                                            TO WORK AREA               37400020
         LOAD  EPLOC=MSLOADNM           LOAD MESSAGE MODULE             37600020
         ST    PARMREG0,CAPTMSGM        UPDATE POINTER TO MSG MODULE    37800020
MSNOLOAD EQU   *                                                        38000020
         SR    WR4,WR4                  ZERO INDEX                      38200020
         IC    WR4,MSGRELNO             GET RELATIVE MESSAGE NUMBER     38400020
*                                       FOR INDEXING PURPOSES           38600020
         SLL   WR4,TWO                  MULTIPLY BY 4 TO GET OFFSET     38800020
*                                       INTO VECTOR TABLE               39000020
         L     WR5,CAPTMSGM             POINT TO MESSAGE MODULE         39200020
         L     WR4,ZERO(WR4,WR5)        POINT TO FIRST LEVEL MSG        39400020
         LA    WR4,FOUR(,WR4)           AT LENGTH HALFWORD              39600020
         ST    WR4,ML1SG1               STORE PTR IN PUTLINE PARM LIST  39800020
         LA    WR5,FOUR                 POINT TO SECOND LEVEL MESSAGE   40000020
         SR    WR4,WR5                                                  40200020
         L     WR5,IN1PTR                                               40400020
         LTR   WR5,WR5                  WAS AN INSERTION PROVIDED       40600020
         BNZ   MSLV1INS                 IF SO BRANCH TO PROCESS         40800020
*                                       INSERTIONS                      41000020
         LA    WR5,ONE                  OTHERWISE SET NO. OF            41200020
         ST    WR5,ML1SGNUM             SEGMENTS TO ONE                 41400020
         B     MSL2TEST                 BRANCH TO CHECK FOR LEVEL       41600020
*                                       2 MESSAGE                       41800020
MSLV1INS EQU   *                                                        42000020
         LA    PARMREG1,ML1LST          INIT PARM BLOCK ADDRESS         42200020
         BAL   WR6,MSINSERT             INVOKE INSERTION SUBROUTINE     42400020
         ST    WR3,ML1SGNUM             STORE NUMBER OF SEGMENTS IN     42600020
*                                       PARAMETER LIST                  42800020
MSL2TEST EQU   *                                                        43000020
         LH    WR3,RLEV2MSG             LOAD RELATIVE LEVEL 2 NUMBER    43200020
         LTR   WR3,WR3                  IS A LEVEL 2 MESSAGE REQUESTED  43400020
         BNZ   MSLV2MSG                 IF SO BRANCH TO PROCESS         43600020
*                                       LEVEL 2 MESSAGE                 43800020
         LA    WR3,ML1SGNUM             FOR LEVEL 1 MSGS WITH NO        44000020
         ST    WR3,PUTLOUT              LEVEL 2, STORE ADDR OF WORD     44200020
         B     OUTPUT                   CONTAINING NO. OF SEGMENTS      44400020
*                                       IN PARAMETER LIST AND BRANCH    44600020
*                                       TO LINK TO PUTLINE              44800020
MSLV2MSG EQU   *                                                        45000020
         L     WR4,ZERO(,WR4)           CHAIN DOWN MESSAGE LISTS        45200020
         BCT   WR3,MSLV2MSG             TO ACCESS LEVEL 2 MESSAGE       45400020
         LA    WR4,FOUR(,WR4)           ADDRESS BASIC SEGMENT           45600020
         ST    WR4,ML2SG2               AND STORE IN PARAMETER BLOCK    45800020
         L     WR5,IN2PTR               LOAD INSERTION LIST ADDR        46000020
         LTR   WR5,WR5                  ANY LEVEL 2 INSERTS PROVIDED    46200020
         BZ    MSNOL2IN                 IF NOT BRANCH TO SET UP         46400020
*                                       FINAL PARAMETERS                46600020
         LA    PARMREG1,ML2LST          SPECIFY ADDR OF PARM BLOCK 2    46800020
         BAL   WR6,MSINSERT             CALL SUBRTN FOR LEV 2 INSERTS   47000020
         B     MSL2SET                  BRANCH TO COMPLETE PARAMETERS   47200020
MSNOL2IN EQU   *                                                        47400020
         LA    WR3,ONE                  NO INSERTIONS -- ONE SEGMENT    47600020
MSL2SET  EQU   *                                                        47800020
         ST    WR3,ML2SGNUM             SET NO. OF MESSAGE SEGMENTS     48000020
         LA    WR3,ML1LST                                               48200020
         ST    WR3,PUTLOUT              SET PARM LIST OUTPUT ADDR       48400020
         LA    WR3,ML2LST                                               48600020
         ST    WR3,ML2PTR               CHAIN PARM BLOCK 1 TO 2         48800020
         MVC   ML3PTR(FOUR),SEG3FLG     SPECIFY NO LEVEL 3 OUTPUT       49000020
*                                                                       49200020
*        PARAMETERIZATION IS COMPLETE                                   49400020
OUTPUT   LA    WR1,PTLPBLK                                              49600020
         ST    WR1,CATMPLST+IOPLIOPB-IOPL POINT TO PUTLINE PARM LIST    49800020
         PUTLINE MF=(E,CATMPLST) CALL PUTLINE                           50000020
         TM    CACFLAG4,CATPUTVF        IS VERIFY SWITCH ON -           50030020
         BZ    MSDELETE                 IF NOT, BRANCH TO DELETE        50060020
*                                       MESSAGE MODULE.                 50090020
         XI    CACFLAG4,CATPUTVF        IF SO, TURN SWITCH OFF          50120020
         B     MSRETURN                 AND BRANCH TO RETURN            50150020
MSDELETE EQU   *                                                        50180020
         LR    WR4,RETCDREG             SAVE PUTLINE RETURN CODE        50210020
         DELETE EPLOC=MSLOADNM          DELETE MESSAGE MODULE           50240020
         LR    RETCDREG,WR4             RESTORE PUTLINE RETURN CODE     50270020
MSRETURN EQU   *                                                        50300020
         IKJEBERT (14,12),,RC=(15)      RETURN LINKAGE                  50330020
         EJECT                                                          50400020
*********************************************************************** 50600020
*                                                                       50800020
* THIS SUBROUTINE IS USED TO PROCESS INSERTIONS FOR EDIT MESSAGES       51000020
* UPON ENTRY REGISTER ONE POINTS TO THE PARAMETER BLOCK FOR PUTLINE     51200020
* AND REGISTER SIX ADDRESSES THE FIRST INSERTION LIST                   51400020
*                                                                       51600020
*********************************************************************** 51800020
         SPACE 2                                                        52000020
MSINSERT EQU   *                                                        52200020
         LA    WR3,FOUR                 MAXIMUM NO. OF INSERTIONS       52400020
*                                       IS FOUR                         52600020
         LR    WR1,WR3                  COPY VALUE FOR INDEXING         52800020
MSINSLP  EQU   *                                                        53000020
         LA    PARMREG0,FOUR(,WR5)      ADDRESS INSERTION               53200020
         ST    PARMREG0,TWELVE(,PARMREG1) STORE SEGMENT IN PARM BLOCK   53400020
         L     WR5,ZERO(,WR5)           CHAIN TO FIND NEXT INSERTION    53600020
         LTR   WR5,WR5                  ARE THERE ANY MORE INSERTS      53800020
         BZ    MSCNTINS                 IF NOT, BRANCH TO COUNT         54000020
*                                       MESSAGE SEGMENTS                54200020
         AR    PARMREG1,WR1             BUMP SEGMENT ADDRESS BY FOUR    54400020
         BCT   WR3,MSINSLP              LOOP FOUR TIMES                 54600020
         LA    WR3,ONE(,WR3)            ADJUST COUNT BY ADDING ONE      54800020
MSCNTINS EQU   *                                                        55000020
         IC    WR3,MSINSTAB(WR3)        DETERMINE NO. OF MSG SGMTS.     55200020
         BR    WR6                      RETURN TO MAINLINE ROUTINE      55400020
         EJECT                                                          55600020
*********************************************************************** 55800020
* THIS SECTION CAUSES THE VERIFY LINE TO BE PRINTED AT THE TERMINAL.    56000020
* THE FORMAT IS --                                                      56200020
* 0            8    9                                                   56400020
* LINE NUMBER  ' '  RECORD TEXT WITHOUT LINE NUMBER                     56600020
*********************************************************************** 56800020
         SPACE 2                                                        57000020
MSVERIFY EQU   *                                                        57200020
         MVC   PTLPBLK(LENGTH20),PUTLNL3 MOVE DATA PARM BLOCK TO        57600020
*                                        WORK AREA                      57800020
         L     WR1,IN1PTR                                               58000020
         USING RECORD,WR1          ESTABLISH ADDRESSABILITY FOR RECORD  58200020
         TM    CACFLAG1,CANONUM    WAS 'NONUM' SPECIFIED                58400020
         BO    MSNOSEQ               YES - TREAT DATA SET WITH NO LINE X58600020
                                           NUMBERS                      58800020
         LH    WR4,INRECLEN          NO - GET RECORD LENGTH             59000020
         SR    WR5,WR5                    SET LINE NUMBER FIELD LENGTH  59200020
         IC    WR5,CALENGTH                                             59400020
         LA    WR3,FIVE(,WR5)             SET DATA LENGTH (ADJUSTING    59600020
         SR    WR4,WR3                    FOR MVC)                      59800020
         CLI   CALINE,ONE          DOES LINE NUMBER BEGIN IN FIRST BYTE 60000020
         BNE   MSMVCBFR              NO - MOVE BUFFER TO SUPPRESS LINE X60200020
                                          NUMBER FIELD                  60400020
         LA    WR6,INDATA(WR5)     ADDRESS BYTE AFTER LINE NUMBER FIELD 60600020
         EX    WR4,VRFYMVC1        OVERLAY LINE NUMBER                  60800020
         L     WR6,RECKEY          SAVE RECORD KEY                      61000020
         B     MSSEQNO             ORGANIZE RECORD AS DATA LINE         61200020
         SPACE 2                                                        61400020
MSMVCBFR EQU   *                                                        61600020
         IC    WR5,CALINE          OBTAIN START POSITION FOR            61650020
*                                  SEQUENCE NUMBER                      61700020
         BCTR    WR5,NOBRANCH      TRANSLATE INTO TRUE NUMBER           61750020
*                                  OF CHARACTERS THAT CAN BE            61760020
*                                  EDITED                               61770020
         CR    WR4,WR5             COMPARE PREVIOUS COMPUTATION         61780020
*                                  OF NUMBER OF DATA CHARACTERS         61790020
*                                  TO BE MOVED(ADJUSTED FOR MVC)        61792020
*                                  TO TRUE NUMBER OF DATA BYTES         61794020
*                                                                       61794420
* NOTE -- THE DATA LENGTH BASED ON THE SEQUENCE NUMBER START POSITION   61794820
* CAN NEVER EXCEED THE DATA LENGTH COMPUTATION BASED ON SEQUENCE        61795220
* NUMBER LENGTH AND DECREMENTED FOR MVC BY MORE THAN ONE CHARACTER.     61795620
         BL    MSMVCBF1            IF LENGTHS ARE EQUAL, BYPASS         61796020
*                                  CODE TO ADJUST LENGTH FOR MOVE       61798020
         BCTR  WR5,NOBRANCH        ADJUST LENGTH FOR MVC                61798420
         LR    WR4,WR5             SET LENGTH FOR MVC                   61798820
MSMVCBF1 EQU   *                                                        61799220
         L     WR6,RECKEY          SAVE RECORD KEY                      61800020
         EX    WR4,VRFYMVC3        MOVE RECORD TO DATA LINE             62000020
MSSEQNO  EQU   *                                                        62200020
         LA    WR4,TWO(,WR4)       ADD 2 FOR TRUE DATA LENGTH           62400020
         MVI   OUTBLANK,BLANK      MOVE ' ' AFTER LINE NUMBER           62600020
         LR    WR2,WR4             SAVE OUTPUT RECORD LENGTH            62800020
         CVD   WR6,VRFYBUFF                                             63000020
         UNPK  SEQFIELD(LENGTH8),VRFYPAK(LENGTH5) CONVERT FIELD TO      63200020
         OI    SEQSIGN,CHARZERO    CHARACTER DIGITS AND ADJUST SIGN     63400020
         EJECT                                                          63600020
         SPACE 2                                                        63800020
*THIS SECTION ADJUSTS RECORD BY SUPPRESSING UP TO 3 LEAD ZEROES         64000020
         SPACE 2                                                        64200020
         LH    WR4,THREE           SET COUNTER                          64400020
         LA    WR5,SEQFIELD        ADDRESS LINE NUMBER                  64600020
MSLZLOOP CLI   ZERO(WR5),CHARZERO  IS BYTE A CHARACTER ZERO             64800020
         BNE   MSCNTLZ               NO - COUNT LEADING ZEROES          65000020
         LA    WR5,ONE(,WR5)         YES - ADDRESS NEXT BYTE            65200020
         BCT   WR4,MSLZLOOP                REPEAT LOOP THREE TIMES      65400020
MSCNTLZ  SH    WR4,THREE           WR4 CONTAINS - NUMBER OF LEAD ZEROES 65600020
         BZ    NOZEROES            IF ZERO, NO MOVE NECESSARY           65800020
         LPR   WR4,WR4             CHANGE SIGN TO POSITIVE              66000020
         LR    WR3,WR2             GET DATA LENGTH                      66200020
         LA    WR2,SEVEN           COMPUTE NUMBER OF SIGNIFICANT DIGITS 66400020
         SR    WR2,WR4             IN LINE NUMBER                       66600020
         AR    WR3,WR2             COMPUTE RECORD LENGTH FOR MVC        66800020
         EX    WR3,VRFYMVC2        SUPPRESS LEADING ZEROES IN RECORD    67000020
STRECINS LA    WR3,FIVE(,WR3)      ADD 5 FOR DATA LENGTH                67200020
         STH   WR3,OUTRCLEN        STORE IN DATA LINE                   67400020
         SR    WR4,WR4                                                  67600020
         STH   WR4,OUTRCOFF        STORE OFFSET OF ZERO                 67800020
         LA    WR3,OUTRCLEN        ADDRESS DATA LINE                    68000020
         ST    WR3,PUTLOUT         AND STORE IN PARM BLOCK              68200020
         B     OUTPUT              BRANCH TO INVOKE PUTLINE             68400020
         SPACE 2                                                        68600020
NOZEROES LA    WR3,SEVEN(,WR2)     LENGTH OF LINE NUMBER FIELD TO BE   X68800020
                                   ADDED TO RECORD LENGTH               69000020
         B     STRECINS            FINISH DATA LINE                     69200020
         EJECT                                                          69400020
         SPACE 2                                                        69600020
*********************************************************************** 69800020
*                                                                       70000020
* THIS SECTION CAUSES THE VERIFY LINE TO BE PRINTED AT THE TERMINAL     70200020
* WHEN 'NONUM' WAS SPECIFIED.                                           70400020
*                                                                       70600020
*********************************************************************** 70800020
         SPACE 2                                                        71000020
MSNOSEQ  EQU   *                                                        71200020
         LA    WR1,TWELVE(,WR1)     READDRESS THE DATA LINE SO          71400020
*                                   THAT THE INPUT LINE NEED NOT BE     71600020
*                                   MOVED                               71800020
         LA    WR3,OUTRCLEN         ADDRESS DATA LINE                   72000020
         ST    WR3,PUTLOUT          AND STORE IN PARM BLOCK             72200020
         B     OUTPUT               BRANCH TO INVOKE PUTLINE            72400020
         EJECT                                                          72600020
*********************************************************************** 72800020
*                                                                       73000020
*                            LOCAL STORAGE                              73200020
*                                                                       73400020
*********************************************************************** 73600020
         SPACE 2                                                        73800020
         SPACE 2                                                        74000020
*FOLLOWING ARE MVC'S FOR VERIFYING LINE                                 74200020
         SPACE 1                                                        74400020
VRFYMVC1 MVC   OUTDATA(ZERO),ZERO(WR6)                                  74600020
VRFYMVC2 MVC   SEQFIELD(ZERO),ZERO(WR5)                                 74800020
VRFYMVC3 MVC   OUTDATA(ZERO),INDATA                                     75000020
         SPACE 1                                                        75200020
THREE    DC    H'3'                     CONSTANT FOR SUPPRESSION        75400020
*                                       OF LEADING ZEROES               75600020
         SPACE 1                                                        75800020
SEG3FLG  DC    X'FF000000'              INDICATES NO LEVEL 3 MSG        76000020
         SPACE 1                                                        76200020
PUTLNL1  PUTLINE OUTPUT=(0,SINGLE),MF=L                                 76400020
         SPACE 1                                                        76600020
PUTLNL2  PUTLINE OUTPUT=(0,MULTLVL),MF=L                                76800020
         SPACE                                                          77000020
PUTLNL3 PUTLINE OUTPUT=(0,DATA),MF=L                                    77200020
         SPACE 1                                                        77400020
* THE FOLLOWING ARE THE FIRST SEVEN CHARACTERS OF ALL MESSAGE           77600020
* CSECT NAMES                                                           77800020
         SPACE                                                          78000020
MSNMLOAD DC    C'IKJEBEM'               7 CHARACTER PREFIX FOR          78200020
*                                       MESSAGE MODULE NAMES            78400020
         SPACE                                                          78600020
* THE FOLLOWING TABLE CONTAINS ONE-BYTE ENTRIES FOR THE LAST            78700020
* CHARACTER OF MESSAGE MODULE NAMES                                     78800020
         SPACE 2                                                        78900020
MSTBLOAD DC    C'0123456789'            THE LAST CHARACTER OF THE       79000020
*                                       MODULE NAME IS A DIGIT 0-9      79100020
*                                       1-7 ARE CURRENTLY USED          79200020
*                                       0,8, AND 9 ARE FOR EXPANSION    79300020
         SPACE                                                          79800020
* THE FOLLOWING TABLE IS USED TO DETERMINE THE NUMBER OF MESSAGE        80000020
* SEGMENTS THAT HAVE BEEN PROCESSED BY THIS ROUTINE                     80200020
         SPACE                                                          80400020
MSINSTAB DC    X'060504030201'          INSERTION COUNT TABLE           80600020
         EJECT                                                          80800020
         IKJEBECA     ,  DEFINE COMMUNICATION AREA                      81000020
         EJECT                                                          81200020
DATA     DSECT                                                          81400020
         SPACE                                                          81600020
MSLOADNM DS    CL8                      MESSAGE MODULE NAME             81800020
         SPACE                                                          82600020
* THE NEXT SECTION DEFINES THE PARAMETER BLOCK FOR PUTLINE              82800020
PTLPBLK DS    5F                        PUTLINE PARMBLOCK               83000020
         ORG   PTLPBLK                  PARMBLOCK ORGANIZATION          83200020
PUTLCTL  DS    H                        CONTROL INFORMATION             83400020
PUTLOPT  DS    H                        OUTPUT OPTIONS                  83600020
PUTLOUT  DS    F                        ADDRESS OF OUTPUT LINE          83800020
PUTLFRMT DS    F                        ADDRESS OF FORMATTED LINE       84000020
PUTLQOPT DS    F                        QUEUE OPTIONS                   84200020
PUTLSA   DS    F                        ADDRESS OF SAVE AREA            84400020
         ORG   ,                        END OF PARAMETER BLOCK          84600020
         SPACE                                                          84800020
* THE FOLLOWING BLOCK IS THE FIRST LEVEL OUTPUT DESCRIPTOR              85000020
ML1LST   DS    7F                       LEVEL 1 OUTPUT DESCRIPTOR       85200020
         ORG   ML1LST                   ORGANIZATION OF DESCRIPTOR -    85400020
ML2PTR   DS    F                        THIS ADDRESSES LEVEL 2          85600020
*                                       DESCRIPTOR IF PROVIDED. THIS    85800020
*                                       LOCATION  IS ADDRESSED IN       86000020
*                                       THE PARMBLOCK LOCATION PUTLOUT  86200020
*                                       WHEN LEVEL 2 IS PROVIDED        86400020
ML1SGNUM DS    F                        NO. OF SEGMENTS IN LEVEL 1      86600020
*                                       MSG. THIS LOCATION IS           86800020
*                                       ADDRESSED IN PUTLOUT WHEN       87000020
*                                       WHEN NO LEVEL 2 IS PROVIDED     87200020
ML1SG1   DS    5F                       SPACE FOR ADDRESS OF BASIC      87400020
*                                       SEGMENT AND UP TO FOUR          87600020
*                                       MESSAGE INSERTIONS              87800020
         ORG   ,                        END OF LEVEL 1 DESCRIPTOR       88000020
         SPACE                                                          88200020
* THE FOLLOWING BLOCK IS THE LEVEL 2 OUTPUT DESCRIPTOR                  88400020
ML2LST   DS    7F                       LEVEL 2 OUTPUT DESCRIPTOR       88600020
         SPACE                                                          88800020
         ORG   ML2LST                   ORGANIZATION OF DESCRIPTOR -    89000020
ML3PTR   DS    F                        ADDR OF LEVEL 3 MSG IS          89200020
*                                       ALWAYS X'FF000000' SINCE EDIT   89400020
*                                       HAS NO LEVEL 3 MSGS             89600020
ML2SGNUM DS    F                        NUMBER OF SGMTS IN LEVEL 2      89800020
ML2SG2   DS    5F                       ADDR OF BASIC SEGMENT AND       90000020
*                                       UP TO FOUR INSERTIONS           90200020
         ORG   ,                        END OF DESCRIPTOR               90400020
         EJECT                                                          90600020
INPARMD  DSECT                                                          90800020
         SPACE                                                          91000020
* THIS DSECT DESCRIBES THE 3 WORD PARAMETER LIST PASSED TO IKJEBEMS     91200020
* VIA REGISTER 1                                                        91400020
         SPACE                                                          91600020
MSGNUM   DS    0H                       LEVEL 1 MESSAGE NUMBER          91800020
MSLOADMD DS    X                        BYTE 1 - MODULE INDICATOR       92000020
MSGRELNO DS    X                        BYTE 2 - RELATIVE MSG. NO.      92200020
RLEV2MSG DS    H                        RELATIVE LEVEL 2 MSG NO.        92400020
IN1PTR   DS    F                        ADDR OF FIRST LEVEL 1 INSERT    92600020
*                                       ALSO ADDRESSES THE VERIFY       92800020
*                                       BUFFER WHEN THIS FUNCTION       93000020
*                                       IS REQUESTED                    93200020
IN2PTR   DS    F                        ADDR OF FIRST LEVEL 2 INSERT    93400020
         EJECT                                                          93600020
RECORD   DSECT                          USED TO ADDRESS INPUT AND       93800020
*                                       DATA RECORDS FOR VERIFY LINE    94000020
         SPACE                                                          94200020
VRFYBUFF DS    276X                     MAXIMUM LENGTH OF BUFFER        94400020
         SPACE                                                          94600020
         ORG   VRFYBUFF                 INPUT ORGANIZATION -            94800020
         SPACE                                                          95000020
         DS    3F                       USED ONLY IN DATA LINE          95200020
RECKEY   DS    F                        INPUT RECORD KEY                95400020
INRECLEN DS    H                        INPUT RECORD LENGTH             95600020
         DS    H                        ALWAYS ZERO IN INPUT RECORD     95800020
INDATA   DS    256X                     TEXT OF INPUT RECORD            96000020
         ORG   ,                        END OF INPUT ORGANIZATION       96200020
         SPACE                                                          96400020
         ORG   VRFYBUFF                 DATA LINE ORGANIZATION          96600020
         SPACE                                                          96800020
         DS    3X                       NOT USED                        97000020
VRFYPAK  DS    X                        UNPK BEGINS AT THIS BYTE        97200020
OUTRCLEN DS    H                        LENGTH OF DATA LINE             97400020
OUTRCOFF DS    H                        ALWAYS ZERO                     97600020
SEQFIELD DS    7X                       SEVEN UNPACKED DIGITS           97800020
SEQSIGN  DS    X                        SIGNED DIGIT                    98000020
OUTBLANK DS    X                        ' ' USED FOR SEPARATION         98200020
OUTDATA  DS    248X                     TEXT OF VERIFY LINE             98400020
         ORG   ,                        END OF DATA LINE ORGANIZATION   98600020
         EJECT                                                          98800020
         IKJIOPL                        DSECT FOR I/O PARM BLOCK        99000020
         END                                                            99200020
