BEPS TITLE 'TSO EDIT COMMAND  PROCESSOR TABLE SEARCH  IKJEBEPS'         00600020
IKJEBEPS CSECT                                                          01200020
*********************************************************************** 01800020
*                                                                     * 02400020
*STATUS  --  VERSION NO. 01, O/S RELEASE NO. 20.                      * 03000020
*                                                                     * 03600020
*FUNCTION  --  THIS ROUTINE SEARCHES A TABLE OF CONSTANTS (CONTAINED  * 04200020
*   IN THE CSECT 'IKJEBEPD') FOR AN ENTRY CONTAINING A GIVEN DATA SET * 04800020
*   TYPE NAME OR FOR AN ENTRY CONTAINING A GIVEN DSNAME QUALIFIER AND * 05400020
*   THE DEFAULT DATA SET TYPE NAME FOR THAT QUALIFIER.                * 06000020
*                                                                     * 06600020
*   IKJEBEPS AND IKJEBEPD ARE THE 1ST AND 2ND CSECTS OF 1 LOAD MODULE.* 07200020
*                                                                     * 07800020
*ENTRY POINTS  --                                                     * 08400020
*        IKJEBEPS - BY A BRANCH-AND-LINK, FOR A TABLE SEARCH.         * 09000020
*                                                                     * 09600020
*INPUT  --  IF REGISTER 1 IS NEGATIVE, IT IS CONSIDERED THE COMPLE-   * 10200020
*   MENTED ADDRESS OF A NAME LEFT-JUSTIFIED IN AN 8-BYTE AREA AND     * 10800020
*   PADDED WITH BLANKS, AND THE TABLE SEARCH IS DONE ON THE DSNAME    * 11400020
*   QUALIFIERS IN THE TABLE.  OTHERWISE REGISTER 1 IS CONSIDERED THE  * 12000020
*   ADDRESS OF A NAME, AND THE SEARCH IS DONE ON DATA SET TYPE NAMES. * 12600020
*                                                                     * 13200020
*OUTPUT  --  IF A TABLE ENTRY IS FOUND, REGISTER 15 IS SET TO 0 AND   * 13800020
*   REGISTER 1 POINTS TO THE BEGINNING OF THE TABLE ENTRY.  OTHERWISE * 14400020
*   REGISTER 15 IS SET TO 4.                                          * 15000020
*                                                                     * 15600020
*EXTERNAL REFERENCES  --                                              * 16200020
*        TABLE    - IN THE CSECT 'IKJEBEPD'                           * 16800020
*   MACROS USED --                                                    * 16900020
*   IKJEBECA -- DEFINES PROCESSOR DATA TABLE PORTION OF EDIT          * 17000020
*   COMMUNICATION AREA.                                               * 17100020
*                                                                     * 17400020
*EXITS,NORMAL  --  BY A BRANCH TO THE CALLER, WITH RETURN CODE IN     * 18000020
*   REGISTER 15 AND POINTER IN REGISTER 1 (WHEN RETURN CODE IS ZERO). * 18600020
*                                                                     * 19200020
*EXITS,ERROR  --  NONE.                                               * 19800020
*                                                                     * 20400020
*TABLES/WORK AREAS  --  PROCESSOR DATA TABLE, CSECT 'IKJEBEPD'        * 21000020
*                                                                     * 21600020
*ATTRIBUTES  --  REFRESHABLE, ENABLED, NON-PRIVILEGED, READ-ONLY.     * 22200020
*                                                                     * 22800020
*NOTES  --  THERE IS CHARACTER-CODE INDEPENDENCE.                     * 23400020
*                                                                     * 24000020
*********************************************************************** 24600020
         EJECT                                                          25200020
         SPACE                                                          26400020
*********************************************************************** 27000020
* REGISTER EQUATES -                                                    27600020
*********************************************************************** 28200020
         SPACE                                                          28800020
PARMREG  EQU   1                        ADDR OF INPUT DSTYPE OR         29400020
*                                       COMPLEMENT ADDR OF DSNAME       30000020
*                                       QUALIFIER OR ADDR OF FOUND      30600020
*                                       TABLE ENTRY.                    31200020
REG02    EQU   2                                                        31800020
TBLNTRY@ EQU   7                        WORKING PT TO TABLE             32400020
REG12    EQU   12                                                       33000020
BASEREG  EQU   12                       BASE REGISTER                   33600020
SAVAREA@ EQU   13                       ADDR OF REGISTER SAVE AREA      34200020
REG14    EQU   14                                                       34800020
RETURN@  EQU   14                       ADDR OF RETURN POINT.           35400020
CODEREG  EQU   15                       RETURN CODE - 0/FOUND, 4/NOT    36000020
         SPACE                                                          36600020
*********************************************************************** 37200020
* CONSTANT EQUATES -                                                    37800020
*********************************************************************** 38400020
         SPACE                                                          39000020
O        EQU   0                                                        39600020
RETCOD4  EQU   4                        'NOT FOUND' RETURN CODE         40200020
FOURTHWD EQU   12                                                       41400020
EIGHTHWD EQU   28                                                       42000020
TBLEND   EQU   X'0'                     TO TEST END-OF-TABLE MARKER.    43200020
ATRIBUT2 EQU   42                       OFFSET TO 2ND DATA SET          43800020
*                                       ATTRIBUTE BYTE IN TABLE.        44400020
DEFAULT  EQU   X'40'                    BIT SIGNIFYING WHETHER          45000020
*                                       DSTYPE IS THE DEFAULT FOR       45600020
*                                       THE DSNAME QUALIFIER -          46200020
*                                       1/YES, 0/NO.                    46800020
*                                       1/YES, 0/NO.                    47400020
*                                       1/YES, 0/NO.                    48000020
         EJECT                                                          48600020
*********************************************************************** 49200020
* ENTRY LINKAGE -                                                       49800020
*********************************************************************** 50400020
         SPACE                                                          51000020
         STM   REG14,REG12,FOURTHWD(SAVAREA@) SAVE REG 0-12,14,15.      51600020
         BALR  BASEREG,O                ESTABLISH ADDRESSABILITY.       52200020
         USING *,BASEREG                                                52800020
         SPACE                                                          53400020
*********************************************************************** 54000020
* PROCESSING -                                                          54600020
*********************************************************************** 55200020
         SPACE                                                          55800020
         L     TBLNTRY@,ATABLE          GET ADDR OF 1ST TBL ENTRY.      56400020
         USING IKJEBECA,TBLNTRY@                                        56700020
         LTR   PARMREG,PARMREG          IS INPUT NEGATIVE -             57000020
         BM    QUALFIER                  IF YES, BRANCH TO SEARCH       57600020
*                                                DSNAME QUALIFIERS.     58200020
*                                        IF NO, SEARCH DSTYPES.         58800020
TYPECOMP CLC   O(L'CADSTYPE,PARMREG),CADSTYPE CMP INPUT NAME WITH       59400020
*                                       CURRENT DSTYPE NAME -           60000020
         BE    POINT                     IF SAME, BRANCH TO SET PT      60600020
*                                                 TO CURR TBL ENTRY.    61200020
         CLI   TBLNTRYL(TBLNTRY@),TBLEND IF DIFFERENT, ARE THERE ANY    61800020
*                                                      MORE ENTRIES-    62400020
         BE    NOTFOUND                   IF NOT, BRANCH TO SET 'NOT    63000020
*                                                 FOUND' RET CODE.      63600020
         LA    TBLNTRY@,TBLNTRYL(TBLNTRY@) IF SO, GET ADDR NEXT         64200020
*                                                 ENTRY.                64800020
         B     TYPECOMP                 BRANCH TO DSTYPE COMPARE.       65400020
QUALFIER LCR   PARMREG,PARMREG          COMPLEMENT INPUT.               66000020
QUALCOMP CLC   O(L'CADSQUAL,PARMREG),CADSQUAL  CMP INPUT                66600020
*                                       NAME WITH CURR QUALIFIER -      67200020
         BE    DFALTASK                  IF SAME, BRANCH TO FIND        67800020
*                                                 IF DEFAULT TYPE.      68400020
ANYMORQL CLI   TBLNTRYL(TBLNTRY@),TBLEND IF DIFFERENT, ARE THERE ANY    69000020
*                                                      MORE ENTRIES-    69600020
         BE    NOTFOUND                   IF NOT, BRANCH TO SET 'NOT    70200020
*                                                 FOUND' RET CODE.      70800020
         LA    TBLNTRY@,TBLNTRYL(TBLNTRY@) IF SO, GET ADDR NEXT         71400020
*                                                 ENTRY.                72000020
         B     QUALCOMP                 BRANCH TO QUALIFIER CMP.        72600020
DFALTASK TM    CADSATR2,CADSNDEF  IS THIS THE DEFAULT                   73200020
*                                       DSTYPE FOR THE QUALIFIER -      73800020
         BNO   ANYMORQL                  IF NOT, BRANCH TO END-TEST.    74400020
POINT    LR    PARMREG,TBLNTRY@          IF SO, SET PT CURR ENTRY.      75000020
         SR    CODEREG,CODEREG          SET RET CODE 0 (FOUND).         75600020
         B     EXEUNT                   GO TO EXIT LINKAGE.             76200020
NOTFOUND LA    CODEREG,RETCOD4          SET RET CODE 4 (NOT FOUND).     76800020
         EJECT                                                          77400020
*********************************************************************** 78000020
* EXIT LINKAGE -                                                        78600020
*********************************************************************** 79200020
         SPACE                                                          79800020
         SPACE                                                          80400020
         SPACE                                                          81000020
EXEUNT   L     RETURN@,FOURTHWD(SAVAREA@) RESTORE REGISTERS 14 AND      81600020
         LM    REG02,REG12,EIGHTHWD(SAVAREA@) 2 THROUGH 12.             82200020
         BR    RETURN@                  RETURN CONTROL TO CALLER.       82800020
         SPACE                                                          83400020
*********************************************************************** 84000020
* ADDRESS CONSTANT -                                                    84600020
*********************************************************************** 85200020
         SPACE                                                          85800020
ATABLE   DC    V(IKJEBEPD)         ADDR OF PROCESSOR DATA TABLE         86200020
         IKJEBECA COMAREA=PDTABLE                                       86600020
TBLNTRYL EQU   CAPDEND-CAPD        LENGTH OF TABLE                      86800020
         END                                                            87000020
