BERE     TITLE 'TSO EDIT COMMAND  RENUM SUBCOMMAND  IKJEBERE'           00090020
IKJEBERE CSECT                                                          00180020
*A078800,216500,507700-507800,839300                             A42941 00230021
*C154800,175500,455600-455700                                    A42941 00240021
*A089600-090100,134620-134800,166520-167059,187700-189200        A45155 00242021
*A233300-233700,236700-238700,277700-280100,537800-538300        A45155 00242521
*A790220-794020,853210-853510,854200-854300,864100-864400        A45155 00243021
*A885620-886480                                                  A45155 00243521
*C106200,134600,157500,272700-273600,511200,552600,790200,914400 A45155 00244021
*D081000,090000-099000,188100-189900,236700-257400,278100-280800 A45155 00248021
*D538200-540900,792000-795300                                    A45155 00250021
*A574500-574800                                                  A50472 00255021
*C573300-574200                                                  A50472 00260021
*D572400,576000                                                  A50472 00265021
*A359600-359700                                                   M5144 00267021
*********************************************************************** 00270020
*                                                                     * 00360020
*STATUS  --  VERSION NO. 01, O/S RELEASE NO. 20                       * 00450020
*                                                                     * 00540020
*FUNCTION  --  THIS EDIT SUBCOMMAND PROCESSOR RENUMBERS PART OR ALL   * 00630020
*   OF, OR ASSIGNS LINE NUMBERS TO, THE DATA SET BEING EDITED.  IF    * 00720020
*   LINE NUMBER ASSIGNMENT FOR NON-NUMBERED RECORDS CAUSES A          * 00810020
*   RECORD TO BE TRUNCATED, A MESSAGE IS ISSUED.  IF IT CAUSES        * 00900020
*   OVERFLOW, EITHER A NEW RECORD IS CREATED FROM THE OVERFLOW (FOR   * 00990020
*   'TEXT' DATA SETS), OR THE OVERFLOW IS LOST.                       * 01080020
*                                                                     * 01170020
*   A NEW UTILITY DATA SET IS ALLOCATED, AND BECOMES THE EDIT DATA    * 01260020
*   SET UPON SUCCESSFUL RENUMBERING.  IF RENUMBERING IS UNSUCCESSFUL, * 01350020
*   THE OLD UTILITY DATA SET REMAINS THE EDIT DATA SET & THE NEW ONE  * 01440020
*   IS UNALLOCATED.                                                   * 01530020
*                                                                     * 01620020
*ENTRY POINT -- IKJEBERE                                              * 01820020
*                                                                     * 02070020
*INPUT  --  REGISTER 1 CONTAINS A POINTER TO EDIT'S COMMUNICATION     * 02160020
*   AREA, DEFINED IN THE IKJEBECA MACRO.  THIS AREA CONTAINS A        * 02250020
*  POINTER TO THE BUFFER CONTAINING THE RENUM SUBCOMMAND AND A        * 02340020
*   POINTER TO THE CURRENT UTILITY DATA CONTROL BLOCK.                * 02430020
*                                                                     * 02520020
*OUTPUT -- RETURN CODES POSSIBLE IN REGISTER 15 ARE --                * 02610020
*   00 - SUCCESSFUL OPERATION                                         * 02700020
*   08 - UNSUCCESSFUL OPERATION, FLUSH STACK                          * 02750020
*   12 - PERMANENT I/O ERROR ON UTILITY DATA SET                      * 02880020
*                                                                     * 03060020
*EXTERNAL REFERENCES  --                                              * 03150020
*       IKJPARS  - CHECKS SYNTAX OF SUBCOMMAND                        * 03240020
*       IKJEBESR - INVOKES EDIT SERVICE ROUTINES                      * 03330020
*       IKJEBEMS - SENDS MESSAGES TO USER                             * 03420020
*       IKJEBEUT - READS FROM & WRITES TO UTILITY DATA SET            * 03510020
*       IKJEBEUI - ALLOCATES & PREPARES AN OUTPUT DATA SET            * 03600020
*       IKJEBEEX - CLEANS UP & UNALLOCATES OLD UTILITY DATA SET       * 03690020
*       IKJEBEMR - RECONSTRUCTS POLISH DATASETS THROUGH SYNTAX CHKER  * 03780020
*       IKJEBERN - RENUMBERS BASIC DATA SETS                          * 03870020
*       MACROS USED --                                                * 04050020
*          IKJEBESV - GENERATES ENTRY LINKAGE ) CHAINED               * 04140020
*          IKJEBERT - GENERATES EXIT LINKAGE  )  SAVE AREAS           * 04230020
*          IKJEBECA - DUMMY SECTION FOR EDIT COMMUNICATION AREA       * 04320020
*          IKJEBEMG - BUILDS FORMATTED MESSAGE INSERTIONS             * 04410020
*          IKJEBEML - BUILDS PARM LIST FOR & CALLS IKJEBEMS           * 04500020
*          IKJEBESH - BUILDS PARM LIST AND CALLS SERVICE ROUTINES     * 04590020
*          IKJPARM  - ) CONSTRUCT PARAMETER CONTROL                   * 04680020
*          IKJIDENT - ) AND DESCRIPTOR LISTS (PCL,PDL)                * 04770020
*          IKJENDP  - ) FOR IKJPARS                                   * 04860020
*                                                                     * 04950020
*EXITS,NORMAL -- RETURN TO CALLER WITH RETURN CODE AS                 * 05040020
*   DESCRIBED UNDER OUTPUT.                                           * 05130020
*                                                                     * 05220020
*EXITS,ERROR  --  NONE                                                * 05310020
*                                                                     * 05400020
*TABLES/WORK AREAS  --                                                * 05490020
*   CASCWKA IN EDIT'S COMM AREA IS USED AS A WORK AREA.               * 05580020
*   CABFRPL IN EDIT'S COMM AREA IS USED TO FORMAT RECORDS.            * 05670020
*                                                                     * 05760020
*ATTRIBUTES  --  REFRESHABLE, ENABLED, NON-PRIVILEGED.                * 05850020
*                                                                     * 05940020
*NOTES  --  THERE IS CHARACTER-CODE INDEPENDENCE.                     * 06030020
*                                                                     * 06120020
*   THIS ROUTINE IS DESCRIBED IN PLM GY28-6773                        * 06130020
*                                                                     * 06170020
*********************************************************************** 06210020
 EJECT                                                                  06300020
*********************************************************************** 06390020
*                             ENTRY CODE                              * 06480020
*********************************************************************** 06570020
         IKJEBESV (14,12),,*                                            06660020
         EJECT                                                          06700020
 SPACE                                                                  06750020
*********************************************************************** 06840020
*                             PROCESSING                              * 06930020
*********************************************************************** 07020020
 SPACE                                                                  07110020
* INITIALIZE REGISTERS AND WORKAREA -                                   07200020
 SPACE                                                                  07290020
         LR    COMMREG,PARMREG1         KEEP PT EDIT COMM AREA          07380020
         LA    COMMREG,O(COMMREG)       ZERO HIGH ORDER BYTE            07470020
         USING IKJEBECA,COMMREG         ESTABLISH ADDRESSABILITY        07560020
         XC    REKODE(WD),REKODE        RET CODE ZERO FOR NOW           07650020
* BEFORE PROCEEDING ANY FURTHER, IF DATA LENGTH IS LESS THAN LINE NO.   07656020
* LENGTH, INFORM THE USER THAT RENUMBERING IS IMPOSSIBLE.               07662020
         SPACE                                                          07668020
         SR    WR,WR                                                    07674020
         IC    WR,CALENGTH              GET LINE NO. LENGTH             07680020
         LA    WR,WD(WR)                ADD LNG OF CONTROL WORD         07686020
         CH    WR,CALRECL               IS RESULT MORE THAN LRECL       07692020
         BNH   ENUFROOM                 IF NO, SKIP ERROR MSG           07698020
         MVC   RE10AREA(MSGLISTL),LIMPOSSI IF YES,ISSUE MSG             07704020
         IKJEBEML ,,,,MF=(E,RE10AREA)                                   07710020
         MVC   REKODE(WD),RET8          SET RC 8                        07712020
         B     EGGSIT                   BRANCH TO EXIT CODE             07716020
ENUFROOM EQU   *                                                        07722020
         SPACE                                                          07728020
         MVI   REDATA,BLNK              BLANK INPUT AREA                07740020
         MVC   REDATA+BYTE(DATALNG),REDATA                              07830020
         NI    REMYFLAG,X'FF'-NOLINE    IND LINES IN DATA SET    A42941 07880021
         NI    REMYFLAG,X'FF'-ISSTRUNK  IND NO LINES TRUNCATED YET      07920020
         SR    PDLBASE,PDLBASE          IND PARSE NOT CALLED YET        08010020
         LA    LINO,DEFLINUM            INITLZ NEW LINENUM TO 10        08190020
         LR    INCR,LINO                INITLZ INCREMENT TO 10          08280020
         BAL   OLDLINO,@@@@@@@@         IND NO OLD-LINENUM SPEC SO      08370020
*                                       FAR (ILC IN PSW=10,SO           08460020
*                                       REGISTER IS MADE NEGATIVE)      08550020
@@@@@@@@ EQU   *                                                        08640020
         MVC   RECURLIN(WD),CACURNUM    SAVE CURRENT LINE REFERENCE     08730020
         MVC   RELINLIN(WD),CAIMLLNO    SAVE LAST INPUT LINE NO.        08820020
         MVC   RE1STLIN(WD),CASTNUM     SAVE STARTING LINE NO.          08910020
         TM    CACFLAG1,CANONUM         CHECK FOR NONUM DS       A45155 08960021
         BO    SETNONUM                 IF NONUM, BR TO SET      A45155 08970021
*                                       APPROPRIATE FLAG BITS    A45155 08972021
         OI    REMYFLAG,ORIGNUM         IF NUM, INDICATE DATA    A45155 08980021
*                                       SET ORIGINALLY NUMBERED  A45155 08982021
         B     OPQUEST                  BRANCH TO OPERAND SCAN   A45155 08990021
*                                       SECTION                  A45155 08992021
SETNONUM EQU   *                                                 A45155 08996021
         NI    REMYFLAG,X'FF'-ORIGNUM   DS ORIGINALLY NONUM      A45155 09000021
         NI    CACFLAG1,X'FF'-CANONUM   NEW DS WILL BE 'NUM'     A45155 09010021
 EJECT                                                                  09990020
*********************************************************************** 10080020
* IF OPERANDS WERE ENTERED, CALL PARSE AND GET THEM.                  * 10170020
*********************************************************************** 10260020
 SPACE                                                                  10350020
OPQUEST  EQU   *                                                        10440020
         TM    CAPTIBFR,CAOPERND        ARE THERE OPERANDS              10530020
         BZ    RENONUM                  IF NO,BRANCH TO PREPARE  A45155 10620021
*                                       NEW OUTPUT DATA SET             10710020
*                                       IF YES,PREPARE FOR PARSING      10800020
         MVC   CATMPLST+PPLPCL-PPL(WD),PCL@ SET PT TO PCL               10890020
         LA    WR,CAPTPRSD              PTR TO ANSWER PLACE             10980020
         ST    WR,CATMPLST+PPLANS-PPL   SET PT TO ANSWER PLACE          11070020
         MVC   CATMPLST+PPLCBUF-PPL(WD),CAPTIBFR SET PT INPUT BFR       11160020
         LA    PARMREG1,CATMPLST        SET PT TO PARM LIST             11250020
         LINK  EP=IKJPARS                                               11340020
         B     PARSBRTB(RETCDREG)       BRANCH ACCORDING TO             11430020
*                                       RETURN CODE -                   11520020
PARSBRTB EQU   *                                                        11610020
         B     PARSOK    00(SUCCESS         ) - GET ANSWER              11700020
         B     EGGSIT8   04(UNABLE TO PROMPT) - EXIT                    11790020
         B     EGGSITA   08(ATTN ISSUED     ) - EXIT                    11880020
         B     PARSERR   12(INVALID PARMS   ) - ISSUE ERR MSG           11970020
         B     CROWDED   16(NO SPACE        ) - ISSUE ERR MSG           12060020
         EJECT                                                          12110020
EGGSIT8  EQU   *                                                        12120020
         MVC   REKODE(WD),RET8          SET RC 8                        12130020
         B     EGGSITA                                                  12140020
CROWDED  EQU   *                                                        12150020
         MVC   RE10AREA(MSGLISTL),LCROWDED                              12240020
         IKJEBEML ,,,,MF=(E,RE10AREA)                                   12330020
         B     EGGSIT8             BRANCH TO EXIT                       12420020
         EJECT                                                          12460020
 SPACE                                                                  12510020
*********************************************************************** 12600020
* INTERROGATE PARAMETER DESCRIPTOR LIST FROM PARSE                    * 12690020
*********************************************************************** 12780020
 SPACE                                                                  12870020
PARSOK   EQU   *                                                        12960020
         L     PDLBASE,CAPTPRSD         PICK UP PT PDL                  13050020
         USING RENUMPDL,PDLBASE         ESTABLISH ADDRESSABILITY        13140020
         TM    OLDLINUM+OPRNDEX,CAOPERND WAS OLD-LINENUM SPEC           13230020
         BZ    INCRLOOK                 IF NO,BRANCH TO GET INCRE-      13320020
*                                       MENT                            13410020
         TM    REMYFLAG,ORIGNUM         CHECK FOR NUMBERED       A45155 13460021
*                                       DATA SET                 A45155 13462021
         BZ    OLDSPEC                  IF NO, BRANCH TO         A45155 13470021
*                                       SEND ERROR MSG           A45155 13480021
         L     PARMREG1,OLDLINUM        IF YES,GET PT OLD-LINENUM       13500020
         LH    WR,OLDLINUM+OPRNDLNG     GET LNG OF OLD-LINENUM          13590020
         BCTR  WR,O                     MINUS 1 FOR 'EX' INSTRUC        13680020
         EX    WR,PAK                   CHANGE OLD-LINENUM TO           13770020
*                                       PACKED DECIMAL                  13860020
         CVB   OLDLINO,CATEMPBF         BINARY OLD-LINENUM INTO         13950020
*                                       REGISTER                        14040020
INCRLOOK EQU   *                                                        14130020
         TM    INCRMENT+OPRNDEX,CAOPERND WAS INCREMENT SPECIFIED        14220020
         BZ    LINOLOOK                 IF NO,BRANCH TO GET NEW-        14310020
*                                       LINENUM                         14400020
         L     PARMREG1,INCRMENT        IF YES,GET PT TO INCREMENT      14490020
         LH    WR,INCRMENT+OPRNDLNG     GET LNG OF INCREMENT            14580020
         BCTR  WR,O                     MINUS 1 FOR 'EX' INSTRUC        14670020
         EX    WR,PAK                   CHANGE INCREMENT INTO           14760020
*                                       PACKED DECIMAL                  14850020
         CVB   INCR,CATEMPBF            BINARY INCREMENT INTO REG       14940020
         LTR   INCR,INCR                IS INCREMENT ZERO               15030020
         BNZ   LINOLOOK                 IF NO,CONTINUE                  15120020
*                                       IF YES,ISSUE ERROR MESSAGE      15210020
         MVC   RE10AREA(MSGLISTL),LINVRANG                              15300020
         IKJEBEML ,,,,MF=(E,RE10AREA)                                   15390020
         MVC   REKODE(WD),RET8          SET RC 8                        15440020
         B     ERALR                    BRANCH TO EXIT PROCESS   A42941 15480021
LINOLOOK EQU   *                                                        15570020
         TM    NEWLINUM+OPRNDEX,CAOPERND WAS NEW-LINENUM SPECIFIED      15660020
         BZ    RENONUM                  IF NO,BRANCH TO PREPARE  A45155 15750021
*                                       NEW OUTPUT DATA SET             15840020
         L     PARMREG1,NEWLINUM        IF YES,GET PT NEW-LINENUM       15930020
         LH    WR,NEWLINUM+OPRNDLNG     GET LNG OF NEW-LINENUM          16020020
         BCTR  WR,O                     MINUS 1 FOR 'OR'ING INTO        16110020
*                                       L-FIELD OF 'EX' INSTRUCTION     16200020
         EX    WR,PAK                   CHANGE NEW-LINENUM TO           16290020
*                                       PACKED DECIMAL                  16380020
         CVB   LINO,CATEMPBF            BINARY NEW-LINENUM INTO         16470020
*                                       REGISTER                        16560020
 EJECT                                                                  16650020
**************************************************************** A45155 16652021
*                                                                A45155 16660021
*    BEFORE ALLOCATING A SECONDARY UTILITY DATA SET, A CHECK     A45155 16670021
*    IS MADE FOR A 'NONUM' DATA SET.  ( DATA LOSS IS POSSIBLE    A45155 16680021
*    FOR NONUM DATA SETS.)  THE IKJEBRE1 ROUTINE IS CALLED TO    A45155 16690021
*    DETERMINE IF RENUM SHOULD CONTINUE FOR NONUM DATA SETS.     A45155 16692021
*                                                                A45155 16694021
**************************************************************** A45155 16696021
RENONUM  EQU   *                                                 A45155 16696421
         TM    REMYFLAG,ORIGNUM         CHECK FOR NUMBERED DS    A45155 16696821
         BO    PREPNEW                  IF NUM, BR TO ALLOCATE   A45155 16697221
*                                       NEW UTILITY DATA SET     A45155 16697621
         CALL  IKJEBRE1                 CALL SUBROUTINE TO       A45155X16698021
                                        DETERMINE IF RENUMBER IS A45155X16700021
                                        TO CONTINUE              A45155 16702021
         B     NONUMTAB(RETCDREG)       BRANCH INTO TABLE        A45155 16704021
*                                       TO DETERMINE NEXT ACTION A45155 16704421
NONUMTAB EQU   *                                                 A45155 16704821
         B     PREPNEW                  CONTINUE RENUM           A45155 16705221
         B     ERALR1                   RC=4,EXIT TO CONTROLLER, A45155 16705621
*                                       RENUM SUSPENDED          A45155 16705721
         B     EGGSIT8                  RC=8, EXIT TO CONTROLLER A45155 16705821
*                                       SYSTEM ERROR             A45155 16705921
         EJECT                                                          16709921
*********************************************************************** 16740020
* CALL IKJEBEUI(UTILITY DATA SET INITIALIZATION ROUTINE) TO OBTAIN    * 16830020
* AND INITIALIZE A NEW OUTPUT UTILITY DATA SET                        * 16920020
*********************************************************************** 17010020
 SPACE                                                                  17100020
PREPNEW  EQU   *                                                        17190020
         IKJEBESH  (COMMREG),IKJEBEUI,PARAM=((COMMREG)),MF=(E,RESRPLST) 17370020
         LTR   RETCDREG,RETCDREG        WAS IKJEBEUI SUCCESSFUL         17460020
         BZ    CONTXR                   IF SO, CONTINUE                 17510020
         MVC   REKODE(WD),RET8          SET RC 8                        17520020
         B     ERALR                    EXIT                     A42941 17550021
CONTXR   EQU   *                                                        17600020
         ST    PARMREG0,REDCB           IF YES,SAVE PT TO NEW DCB       17640020
 SPACE                                                                  17730020
*********************************************************************** 17820020
* IF DATA SET TYPE IS BASIC, CALL THE SYNTAX CHECKER TO PERFORM       * 17910020
* RENUMBERING.  IF NOT, FIND WHETHER OR NOT THE 'OLD-LINENUM' OPERAND * 18000020
* WAS SPECIFIED, AND GO TO THE APPROPRIATE SECTION OF CODE TO PERFORM * 18090020
* RENUMBERING.                                                        * 18180020
*********************************************************************** 18270020
 SPACE                                                                  18360020
         CLI   CADSCODE,CABASIC         IS THIS A BASIC DATA SET        18450020
         BE    XKBASIC                  IF YES,BRANCH TO USE            18540020
*                                       SYNTAX CHECKER TO RENUMBER      18630020
         LTR   OLDLINO,OLDLINO          IF NO,WAS OLD-LINENUM SPEC      18720020
         BM    RE000010                 IF NOT, BRANCH TO        A45155 18770021
*                                       ADJUST NEW LINENUM VALUE A45155 18820021
         B     READOLD                  BRANCH TO VALIDATE       A45155 18860021
*                                       OLD LINENUM              A45155 18862021
RE000010 EQU   *                                                 A45155 18870021
         ST    LINO,RE1STLIN            SAVE 'NEW LINENUM'       A45155 18920021
         SR    LINO,INCR                SUBTRACT INCREMENT FROM         19080020
*                                       NEW-LINENUM (TO BE ADDED        19170020
*                                       BACK LATER)                     19260020
         EJECT                                                          19300020
 SPACE                                                                  19350020
*********************************************************************** 19440020
* CALL IKJEBEUT(UTILITY DATA SET INTERFACE ROUTINE) TO READ FIRST RCD * 19530020
* IN DATA SET.  IF DATA SET IS EMPTY ISSUE A MESSAGE.  OTHERWISE GO   * 19620020
* TO GENERATE LINE NUMBER.                                            * 19710020
*********************************************************************** 19800020
 SPACE                                                                  19890020
         MVC   REDCB@(WD),CAPTCDCB      SET PT TO UTILITY DCB           19980020
         MVI   REUTPLST,READ1ST         IND READ 1ST RCD                20070020
         XC    REKEY@(WD),REKEY@        IND KEY IRRELEVANT              20160020
         LA    WR,REINAREA                                              20250020
         ST    WR,REBFR@                SET PT TO READ-IN AREA          20340020
         MVI   REBFR@,REFLAG            FLAG END OF LIST                20430020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C20520020
               MF=(E,RESRPLST)                                          20610020
         B     UTBRTBL1(RETCDREG)       BRANCH ACCORDING TO RETURN      20700020
*                                       CODE                            20790020
UTBRTBL1 EQU   *                                                        20880020
         B     GENNUM    0(SUCCESS    ) - GENERATE LINE NUMBER          20970020
         B     MT        4(END OF DATA) - ISSUE MSG                     21060020
         B     IOERR     8(I/O ERROR)   - SET RET CODE TO 12            21150020
IOERR    MVC   REKODE(WD),RC12          SET I/O ERROR RET CODE          21240020
         B     CLOZNEW                  BRANCH TO UNALLOC DCB           21330020
MT       EQU   *                                                        21420020
         MVC   RE10AREA(MSGLISTL),LMT   INITLZ MSG PARM LIST            21510020
         IKJEBEML ,,,,MF=(E,RE10AREA)   ISSUE 'NO LINES IN DATA SET'    21600020
         OI    REMYFLAG,NOLINE          IND NO LINES IN DATA SET A42941 21650021
         B     CLOZNEW             GO TO CLOSE ROUTINE                  21690020
         EJECT                                                          21730020
 SPACE                                                                  21780020
*********************************************************************** 21870020
* SAVE THE CURRENT KEY.                                               * 21960020
* GENERATE THE NEXT LINE-NUMBER, UPDATE THE CURRENT LINE POINTER IF   * 22050020
* THIS IS THE CURRENT LINE, AND, DEPENDING ON THE KIND OF RECORD      * 22140020
* FORMAT, GO TO THE APPROPRIATE SECTION OF CODE TO FORMAT THE RECORD  * 22230020
* SO THAT IKJEBEUT CAN INSERT THE LINE NUMBER FIELD.                  * 22320020
*********************************************************************** 22410020
 SPACE                                                                  22500020
GENNUM   EQU   *                                                        22590020
         MVC   REOLDKEY(WD),REKEY       SAVE THIS KEY                   22680020
         AR    LINO,INCR                GENERATE NEXT LINE NUMBER       22770020
MAINLOOP EQU   *                                                        22860020
         CLC   REKEY(WD),CACURNUM       IS THIS THE CURRENT LINE        22950020
         BNE   FMT                      IF NO,BRANCH TO FORMAT RCD      23040020
         ST    LINO,RECURLIN            IF YES,UPDATE CURRENT LINE      23130020
*                                       NUMBER                          23220020
FMT      EQU   *                                                        23310020
         TM    CACFLAG2,CARECFM         TEST RECORD FORMAT       A45155 23330021
         BO    RENUMBER                 IF FIXED, BRANCH TO      A45155 23350021
*                                       UPDATE KEY               A45155 23370021
         TM    REMYFLAG,ORIGNUM         IS DATA SET LINE-NUMBERED       23400020
         BO    RENUMBER                 IF YES,BRANCH TO UPDATE         23490020
*                                       KEY                             23580020
*                                       IF NO, FALL THROUGH TO   A45155 23670021
*                                       HANDLE VARIABLE NONUM    A45155 23770021
*                                       RECORDS                  A45155 23870021
         EJECT                                                          24070020
 SPACE                                                                  24120020
*********************************************************************** 25920020
* THIS CODE TREATS VARIABLE-LENGTH, NON-NUMBERED RECORDS -            * 26010020
*      SHIFT THE DATA RIGHTWARD TO MAKE ROOM FOR THE SEQUENCE NUMBER, * 26100020
*      AND UPDATE THE LL FIELD.  IF LL IS MADE LARGER THAN CALRECL,     26190020
*      FIND OUT IF THIS IS A 'TEXT' TYPE DATA SET.                    * 26280020
*********************************************************************** 26370020
 SPACE                                                                  26460020
VARIABLE EQU   *                                                        26550020
         SR    LINOLENG,LINOLENG                                        26640020
         IC    LINOLENG,CALENGTH        GET LNG OF LINE NO.             26730020
         LA    WR,REDATA(LINOLENG)      CALC ADDR OF END OF SEQ FLD     26820020
         MVC   RETEMP(DATALNG),REDATA   SHIFT DATA RIGHT TO ACCOM-      26910020
         MVC   O(DATALNG,WR),RETEMP      MODATE SEQUENCE NUMBER         27000020
         AH    LINOLENG,RELL                                            27090020
         STH   LINOLENG,RELL            UPDATE LL-FIELD                 27180020
         SH    LINOLENG,CALRECL         DETERMINE IF TRUNCATION  A45155 27270021
*                                       MAY BE NECESSARY         A45155 27300021
         BNP   RENUMBER                 IF NOT, BRANCH TO UPDATE A45155 27330021
*                                       KEY                      A45155 27360021
         MVC   RELL(HAFWD),CALRECL      SET LL OF MAIN RCD TO MAX       27400020
         CLI   CADSCODE,CATEXT          IF YES,IS THIS A TEXT DATA      27450020
*                                              SET                      27540020
         BE    OFLO                       IF YES,BRANCH TO MAKE         27630020
*                                                OVERFLOW RCD           27720020
         LH    WR,CALRECL               OBTAIN MAXIMUM RECORD    A45155 27770021
*                                       LENGTH                   A45155 27780021
         LA    WR,RELL(WR)              OBTAIN ADDRESS OF FIRST  A45155 27810021
*                                       BYTE IN TRUNCATION       A45155 27830021
         BCTR  LINOLENG,0               DECREMENT LENGTH FOR CLC A45155 27850021
         EX    LINOLENG,NUMBCLC         DETERMINE IF TRUNCATION  A45155 27870021
*                                       PORTION IS ALL BLANKS    A45155 27890021
         BE    RENUMBER                 IF SO, NO MESSAGE        A45155 27910021
*                                       IS NECESSARY, BRANCH TO  A45155 27930021
*                                       UPDATE KEY               A45155 27950021
         OI    REMYFLAG,ISSTRUNK        OTHERWISE, REMEMBER TO   A45155 27970021
*                                       ISSUE MESSAGE            A45155 27990021
         B     RENUMBER                 BRANCH TO UPDATE KEY     A45155 28010021
         EJECT                                                          28120020
 SPACE                                                                  28170020
*********************************************************************** 28260020
* IF A VARIABLE-LENGTH, NON-NUMBERED TEXT RCD WAS MADE LARGER THAN    * 28350020
* CALRECL BYTES, CREATE AN OVERFLOW LINE BY BREAKING OFF THE PRESENT  * 28440020
* LINE (AT A BLANK, IF POSSIBLE).                                     * 28530020
*********************************************************************** 28620020
 SPACE                                                                  28710020
OFLO     EQU   *                                                        28800020
         LR    OVERFLOW,LINOLENG        SAVE LENGTH OF OVERFLOW  A45155 28890021
         SR    LINOLENG,LINOLENG                                        29070020
         IC    LINOLENG,CALENGTH        GET LINE NO. LNG AGAIN          29160020
         LA    BEGNG,REDATA(LINOLENG)   CALC LEFTMOST POINT OF THE      29250020
         LA    BEGNG,O(OVERFLOW,BEGNG)   SCAN FOR BLANK                 29340020
         LA    WR,RELL                                                  29400020
         AH    WR,CALRECL               START SCAN ST END OF BUFFER     29460020
BLNKSCAN EQU   *                                                        29520020
         CLI   0(WR),BLNK               IS THIS CHAR A BLANK            29610020
         BE    SPLIT                    IF YES,BRANCH TO SPLIT OFF      29700020
*                                       OVERFLOW                        29790020
         CR    WR,BEGNG                 IF NO,CAN SCAN CONTINUE         29880020
         BNH   NOBLANK                    IF NO,BRANCH TO BREAK AT      29970020
*                                               END OF BUFFER           30060020
         BCT   WR,BLNKSCAN                IF YES,CONTINUE SCANNING      30150020
NOBLANK  EQU   *                                                        30240020
         LA    WR,RELL                  WHEN NO BLANK FOUND IN          30330020
         AH    WR,CALRECL               BUFFER, RESET PT TO END OF      30420020
*                                       BFR                             30510020
         B     ORIGINAL                 BRANCH TO USE ORIGINAL          30600020
*                                       OVERFLOW LENGTH                 30690020
SPLIT    EQU   *                                                        30780020
         LA    BEGNG,RELL                                               30870020
         LR    WR2,WR                                                   30960020
         SR    WR2,BEGNG                CALC NEW LL                     31050020
         STH   WR2,RELL                 SET IT IN RCD                   31140020
         LA    WR,BYTE(WR)                                              31230020
         LA    WR2,RELL                                                 31290020
         AH    WR2,CALRECL              LOCATE END OF MAX RECORD        31350020
         SR    WR2,WR                   CALC ADDITIONAL OVERFLOW        31410020
         AR    OVERFLOW,WR2             CALC TOTAL OVERFLOW             31500020
ORIGINAL EQU   *                        WHEN NO BLANK FOUND IN          31590020
*                                       BFR,ORIGINAL OVERFLOW           31680020
*                                       VALUE IS STILL CORRECT          31770020
         LA    OVERFLOW,WD(OVERFLOW,LINOLENG)                           31860020
*                                       CALC LL OF OVERFLOW RCD         31950020
         MVC   CATEMPBF(DATALNG),O(WR)                                  32040020
         LA    WR,REDATA2(LINOLENG)     CALC POSITION OF DATA IN        32130020
*                                       OVERFLOW RCD                    32220020
         MVC   O(DATALNG,WR),CATEMPBF   MOVE OVERFLOW DATA INTO         32310020
*                                       OVERFLOW RCD                    32400020
         SLL   OVERFLOW,HAFREG                                          32490020
         ST    OVERFLOW,RELL2           SET LL,00 IN OVERFLOW RCD       32580020
         ST    LINO,REKEY               SET NEW KEY IN MAIN RCD         32670020
         EJECT                                                          32710020
 SPACE                                                                  32760020
*********************************************************************** 32850020
* CALL IKJEBEUT TO WRITE THE MAIN PART OF THE LINE WHICH OVERFLOWED   * 32940020
*********************************************************************** 33030020
 SPACE                                                                  33120020
         MVC   REDCB@(WD),REDCB         SET PT TO NEW UTILITY DCB       33210020
         MVI   REUTPLST,WRITERCD        IND WRITE RCD IN ASCENDING      33300020
*                                       ORDER BY KEY                    33390020
         LA    WR,REINAREA                                              33480020
         ST    WR,REKEY@                SET PT TO RCD                   33570020
         MVI   REKEY@,REFLAG            FLAG END OF LIST                33660020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C33750020
               MF=(E,RESRPLST)                                          33840020
         B     UTBRTBL2(RETCDREG)       BRANCH ACCORDING TO RETURN      33930020
*                                       CODE                            34020020
UTBRTBL2 EQU   *                                                        34110020
         B     WRITOFLO  00(SUCCESS         )-CONTINUE                  34200020
         B     CLOZNEW                  BR TO CLOSE DATA SET            34290020
         B     IOERR     08(I/O ERROR       )-SET RET CODE 12           34380020
         B     CLOZNEW   12(LINE NO. TOO BIG)-UNALLOC NEW UTIL DCB      34470020
         EJECT                                                          34642020
*********************************************************************** 34650020
* PREPARE TO WRITE THE OVERFLOW RCD AS IF IT WERE A NORMAL ONE        * 34740020
*********************************************************************** 34830020
 SPACE                                                                  34920020
WRITOFLO EQU   *                                                        35010020
         AR    LINO,INCR                GENERATE NEXT LINE NUMBER       35100020
         MVC   RELL(DATALNG+WD),RELL2   TRANSFER OVERFLOW DATA &        35190020
*                                       CONTROL WORD TO BUFFER          35280020
         EJECT                                                          35320020
 SPACE                                                                  35370020
*********************************************************************** 35460020
* CALL IKJEBEUT TO WRITE THE RENUMBERED LINE, AFTER UPDATING LAST     * 35550020
* INPUT LINE NUMBER (IF NECESSARY).                                   * 35640020
*********************************************************************** 35730020
RENUMBER EQU   *                                                        35820020
         ST    LINO,REKEY               SET NEW KEY IN RCD              35910020
         TM    CACFLAG3,CAIMINPT        CHECK INPUT PROCESSED     M5144 35960021
         BNO   SKIPINPT                 IF NONE, SKIP LINE TEST   M5144 35970021
         CLC   REOLDKEY(WD),CAIMLLNO    WAS THIS LAST INPUT LINE        36000020
         BNE   SKIPINPT                 IF NO,SKIP INPUT LINE NO.       36090020
*                                       UPDATE                          36180020
         ST    LINO,RELINLIN            IF YES,UPDATE LAST INPUT        36270020
*                                       LINE NO. TEMPORARILY            36360020
SKIPINPT EQU   *                                                        36450020
         MVC   REDCB@(WD),REDCB         SET PT TO UTILITY DCB           36540020
         MVI   REUTPLST,WRITERCD        IND WRITE RCD IN ORDER          36630020
         LA    WR,REINAREA                                              36720020
         ST    WR,REKEY@                SET PT TO RCD                   36810020
         MVI   REKEY@,REFLAG            FLAG END OF PARM LIST           36900020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C36990020
               MF=(E,RESRPLST)                                          37080020
         B     UTBRTBL3(RETCDREG)       BRANCH ACC TO RET CODE          37170020
UTBRTBL3 EQU   *                                                        37260020
         B     TRUNKQ    00(SUCCESS         )-CONTINUE                  37350020
         B     CLOZNEW                  BR TO CLOSE DATA SET            37440020
         B     IOERR     08(I/O ERROR       )-SET RET CODE 12           37530020
         B     CLOZNEW   12(LINE NO. TOO BIG)-UNALLOC NEW DCB           37620020
 SPACE                                                                  37710020
*********************************************************************** 37800020
* IF A LINE WAS JUST TRUNCATED, BUILD MSG INSERTIONS & INFORM THE USER* 37890020
*********************************************************************** 37980020
 SPACE                                                                  38070020
TRUNKQ   EQU   *                                                        38160020
         TM    REMYFLAG,ISSTRUNK        WAS A LINE TRUNCATED            38250020
         BNO   NEXTLINE                 IF NO,BRANCH TO READ NEXT       38340020
         NI    REMYFLAG,X'FF'-ISSTRUNK  IF YES,TURN OFF LINE-           38430020
*                                       TRUNCATED-SWITCH                38520020
 SPACE                                                                  38610020
* BUILD FIRST-LEVEL MESSAGE INSERTION -                                 38700020
 SPACE                                                                  38790020
         L     WR,REKEY                 PICK UP LINE NO.                38880020
         CVD   WR,CASCWKA               CONVERT TO PACKED DECIMAL       38970020
         MVC   M507INS(LINTRCL),LINTRC  INITLZ LINE NO. INSERTION       39060020
         LA    PARMREG1,M507INS+LINTRCL-BYTE INITLZ PT TO END OF        39150020
*                                            INSERTION                  39240020
         EDMK  PATTERN1(PATTERNL),CASCWKA+HAFWD+BYTE UNPAK LINENUM      39330020
         MVC   PATTERN1(DUBLWD),0(PARMREG1) LEFT JUSTIFY                39630020
*                                                INSERTION              39960020
         LA    WR,M507INS+LINTRCL                                       40050020
         SR    WR,PARMREG1              CALC LNG OF INSERTION           40140020
         LA    WR,WD(WR)                                                40180020
         STH   WR,M507INS+WD            SET IT IN INSERTION             40230020
 SPACE                                                                  40320020
* BUILD SECOND LEVEL MESSAGE INSERTION -                                40410020
 SPACE                                                                  40500020
         LH    WR,CALRECL               PICK UP LINE SIZE               40590020
         LA    WR2,WD                   SUBTRACT CONTROL WORD LNG       40680020
         SR    WR,WR2                                                   40770020
         CVD   WR,CASCWKA               CONVERT LINE SIZE TO            40860020
*                                       PACKED DECIMAL                  40950020
         MVC   M507INS2(LNGISL),LNGIS   INITLZ LINE LNG INSERTION       41040020
         EDMK  PATTERN2(WD),CASCWKA+WD+HAFWD UNPACK LINE LENGTH         41130020
         MVC   PATTERN2(HAFWD),O(PARMREG1) LEFT-JUSTIFY                 41220020
*                                               INSERTION               41310020
         LA    WR,M507INS2+LNGISL                                       41400020
         SR    WR,PARMREG1              CALC LNG OF INSERTION           41490020
         LA    WR,WD(WR)                                                41530020
         STH   WR,M507INS2+WD           SET IT IN INSERTION             41580020
 SPACE                                                                  41670020
* ISSUE THE MESSAGE -                                                   41760020
 SPACE                                                                  41850020
         IKJEBEML M507,M5071,M507INS,M507INS2,MF=(E,RE10AREA)           41940020
         EJECT                                                          41980020
 SPACE                                                                  42030020
*********************************************************************** 42120020
* CALL IKJEBEUT TO READ NEXT LINE.  IF FOUND, LOOP TO RENUMBER.  IF   * 42210020
* END OF DATA, CONTINUE PROCESSING.                                   * 42300020
*********************************************************************** 42390020
 SPACE                                                                  42480020
NEXTLINE EQU   *                                                        42570020
         MVI   REDATA,BLNK              BLANK INPUT AREA                42660020
         MVC   REDATA+BYTE(DATALNG),REDATA                              42750020
         MVC   REDCB@(WD),CAPTCDCB      SET PT TO UTILITY DCB           42840020
         MVI   REUTPLST,READNEXT        IND READ NEXT RCD               42930020
         LA    WR,REOLDKEY                                              43020020
         ST    WR,REKEY@                SET PT TO PREVIOUS KEY          43110020
         LA    WR,REINAREA                                              43200020
         ST    WR,REBFR@                SET PT TO READ-IN AREA          43290020
         MVI   REBFR@,REFLAG            FLAG END OF PARM LIST           43380020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C43470020
               MF=(E,RESRPLST)                                          43560020
         B     UTBRTBL4(RETCDREG)       BRANCH ACC TO RET CODE          43650020
UTBRTBL4 EQU   *                                                        43740020
         B     GENNUM    0(SUCCESS    ) - LOOP TO RENUMBER              43830020
         B     IPLIQ     4(END OF DATA) - TEST FOR IPLI DSTYPE          43920020
         B     IOERR     8(I/O ERROR  ) - SET RET CODE 12               44010020
         EJECT                                                          44050020
 SPACE                                                                  44100020
*********************************************************************** 44190020
* IF THIS IS AN IPL1 DATA SET, BRANCH TO THE SYNTAX CHECKER.          * 44280020
* OTHERWISE CALL IKJEBEEX TO CLOSE AND UNALLOCATE THE OLD UTILITY     * 44370020
* DCB, AND UPDATE THE COMMUNICATION AREA WITH A POINTER TO THE NEW    * 44460020
* UTILITY DCB.                                                        * 44550020
*********************************************************************** 44640020
 SPACE                                                                  44730020
IPLIQ    EQU   *                                                        44820020
         CLI   CADSCODE,CAIPLI          IS THIS DATA SET IPLI           44910020
         BE    XKIPLI                   IF YES,BRANCH TO CALL           45000020
*                                       SYNTAX CHECKER                  45090020
CLOZOLD  EQU   *                        IF NO,CALL IKJEBEEX             45180020
         NI    CASYNCD2,X'FF'-RENOSW    RESET OPTION WD TO ZERO         45270020
         L     PARMREG0,CAPTCDCB                                        45320020
         IKJEBESH  (COMMREG),IKJEBEEX,PARAM=((COMMREG)),MF=(E,RESRPLST) 45540020
         NI    CASYNSW,X'FF'-CASYNLN INDICATE LINE NUM TO SYNTAX CHKR   45550020
         TM    REMYFLAG,ORIGNUM    WAS DS PREV NUMBERED          A42941 45560021
         BO    DONTFLP             IF SO DONT TURN ON INPUT BIT  A42941 45570021
         OI    CAIMFLG,CAIMPT      TURN ON PROMPT BIT FOR INPUT         45580020
DONTFLP  EQU   *                                                        45590020
         MVC   CAPTPDCB(WD),CAPTCDCB    PUSH DOWN CURRENT DCB PT        45630020
         MVC   CAPTCDCB(WD),REDCB       SET PT NEW DCB IN COMMAREA      45720020
         EJECT                                                          45760020
 SPACE                                                                  45810020
*********************************************************************** 45900020
* UPDATE CURRENT LINE REFERENCE('*'), LAST LINE NUMBER USED IN INPUT  * 45990020
* MODE, LINE NUMBER INCREMENT, AND STARTING LINE NUMBER.  SET DATA-   * 46080020
* SET-LINE-NUMBERED AND DATA-SET-MODIFIED SWITCHES.                   * 46170020
*********************************************************************** 46260020
 SPACE                                                                  46350020
         CLI   CADSCODE,CABASIC         IS DATA SET 'BASIC'             46440020
         BNE   ALL                      IF NO,PROCEED NORMALLY          46530020
         ST    INCR,CAIMLINC            IF YES,SET INCREMENT ONLY       46620020
         ST    INCR,CAINCRE                                             46660020
         B     SWITCHES                 GO SET SWITCHES                 46710020
ALL      EQU   *                                                        46800020
         MVC   CACURNUM(WD),RECURLIN    CURR LINE REFERENCE('*')        46890020
         MVC   CAIMLLNO(WD),RELINLIN    LAST INPUT LINE                 46980020
         ST    INCR,CAIMLINC            INCREMENT                       47070020
         ST    INCR,CAINCRE                                             47110020
         MVC   CASTNUM(WD),RE1STLIN     STARTING LINE NO.               47160020
SWITCHES EQU   *                                                        47250020
         NI    CACFLAG1,X'FF'-CANONUM   DATA SET NOW LINE-NUMBERED      47340020
         OI    CACFLAG2,CADSMODS        DATA SET MODIFIED               47430020
         EJECT                                                          47470020
 SPACE                                                                  47520020
*********************************************************************** 47610020
* IF VERIFICATION IS IN EFFECT CALL IKJEBEUT TO READ CURRENT LINE,    * 47700020
* AND INDICATE THAT THERE IS A LINE TO BE VERIFIED.                   * 47790020
*********************************************************************** 47880020
 SPACE                                                                  47970020
         TM    CACFLAG1,CAVRFYSW        IS VERIFY SW ON                 48060020
         BNO   PARSASK                  IF NO,BRANCH TO FREE PARSE      48150020
*                                             CORE                      48240020
         MVC   REDCB@(WD),CAPTCDCB      IF YES,SET PT TO UTIL DCB       48330020
         MVI   REUTPLST,READWKEY        IND READ W/ KEY                 48420020
         LA    WR,CACURNUM                                              48510020
         ST    WR,REKEY@                SET PT TO KEY OF CURRENT        48600020
*                                        REFERENCE RECORD               48690020
         LA    WR,CATEMPBF+DUBLWD+WD                                    48780020
         ST    WR,REBFR@                SET PT TO READ-IN AREA          48870020
         MVI   REBFR@,REFLAG            FLAG END OF PARM LIST           48960020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C49050020
               MF=(E,RESRPLST)                                          49140020
         LTR   RETCDREG,RETCDREG        WAS READ SUCCESSFUL             49230020
         BZ    NOPRB                    IF SO, BRANCH                   49320020
*  LINE NUMBER 0 DOES NOT EXIST                                         49330020
         IKJEBEML  M504,0,MOLNZ,O,MF=(E,RE10AREA)                       49370020
         B     PARSASK                 GO TO COMPLETE PROCESSING        49380020
NOPRB    EQU   *                                                        49410020
         OI    CACFLAG1,CALNTOVF        IF YES,IND LINE-TO-BE-VERF      49500020
         B     PARSASK                  BRANCH TO FREE PARSE CORE,      49590020
*                                       IF NEED BE                      49680020
CLOZOLDA EQU   *                   ITF SUCCESSFUL CLEANUP               49690020
         MVC   CAPTCDCB,CAPTPDCB   RESTORE CURRENT DCB PTR              49700020
         B     CLOZOLD        BRANCH TO CLOSE OLD (CURRENT) DCB         49710020
CLOZNEWA EQU   *              FAILURE IN ITF RENUM                      49720020
         NI    CASYNCD2,X'FF'-RENOSW   RESET RENUM SW                   49730020
         MVC   REDCB,CAPTPDCB     RESTORE OLD DCB POINTER               49732020
         EJECT                                                          49750020
 SPACE                                                                  49770020
*********************************************************************** 49860020
* WHENEVER RENUMBERING CANNOT BE ACCOMPLISHED, CALL IKJEBEEX TO CLOSE * 49950020
* AND UNALLOCATE THE NEW UTILITY DCB, AND RESTORE THE DATA-SET-LINE-  * 50040020
* NUMBERED SWITCH TO ITS ORIGINAL STATUS.                             * 50130020
*********************************************************************** 50220020
 SPACE                                                                  50310020
CLOZNEW  EQU   *                                                        50400020
         NI    CASYNCD2,X'FF'-RENOSW    RESET OPTION WD TO ZERO         50490020
         L     PARMREG0,REDCB                                           50670020
         IKJEBESH  (COMMREG),IKJEBEEX,PARAM=((COMMREG)),MF=(E,RESRPLST) 50760020
         TM    REMYFLAG,NOLINE          IS DATA SET EMPTY        A42941 50770021
         BO    ERALR                    YES, LEAVE RETURN CODE=0 A42941 50780021
EGGSITA  EQU   *                                                        50800020
         SR    RETCDREG,RETCDREG        ZERO REGISTER                   50810020
         C     RETCDREG,REKODE          IS RC ZERO                      50820020
         BNE   ERALR                    IF NOT, BRANCH                  50830020
         MVC   REKODE(WD),RET8          SET RC 8                        50840020
ERALR    EQU   *                                                        50842020
         TM    REMYFLAG,ORIGNUM         WAS DATA SET ORIGINALLY         50850020
*                                       LINE-NUMBERED                   50940020
         BO    PARSASK                  IF YES,BRANCH TO FREE PDL       51030020
ERALR1   OI    CACFLAG1,CANONUM         IF NO, INDICATE 'NONUM'  A45155 51120021
 SPACE                                                                  51210020
*********************************************************************** 51300020
* IF PARSE WAS CALLED, FREE THE STORAGE FOR ITS PDL                   * 51390020
*********************************************************************** 51480020
 SPACE                                                                  51570020
PARSASK  EQU   *                                                        51660020
         LTR   PDLBASE,PDLBASE          WAS PARSE CALLED                51750020
         BZ    EGGSIT                   IF NO,BRANCH TO EXIT            51840020
         LA    PDLBASE,CAPTPRSD         IF YES,RELEASE PDL CORE         51930020
         IKJRLSA (PDLBASE)                                              52020020
         OI    CAPRSPDL,CAFREEDL        INDICATE PDL FREED              52030020
         EJECT                                                          52060020
 SPACE                                                                  52110020
*********************************************************************** 52200020
*                             EXIT CODE                               * 52290020
*********************************************************************** 52380020
 SPACE                                                                  52470020
EGGSIT   EQU   *                                                        52560020
         L     RETCDREG,REKODE          SET RETURN CODE                 52650020
         IKJEBERT (14,12),RC=(15)  EXIT FROM PGM                        52740020
         EJECT                                                          52830020
*********************************************************************** 52920020
* THE FOLLOWING CODE IS BRANCHED-TO (AFTER IKJEBEUI IS CALLED TO      * 53010020
* PREPARE A NEW OUTPUT DATA SET) WHEN AN OLD LINE NUMBER WAS SPECI-   * 53100020
* FIED.  IF THE SPECIFIED OLD & NEW LINE NUMBERS WOULD PUT THE        * 53190020
* NUMBERING OUT OF ASCENDING SEQUENCE, THE USER IS NOTIFIED.          * 53280020
* OTHERWISE ALL RECORDS WITH NUMBERS LESS THAN OLD-LINENUM ARE COPIED * 53370020
* INTO THE NEW UTILITY DATA SET.                                      * 53460020
*********************************************************************** 53550020
 SPACE                                                                  53640020
OLDSPEC  EQU   *                                                        53730020
*   ISSUE MESSAGE INDICATING THAT OLD LINE NUMBER SPECIFICATION  A45155 53780021
*   IS INVALID FOR NONUM DATA SETS                               A45155 53830021
         SPACE                                                          53880021
         IKJEBEML M502,0,0,0,MF=(E,RE10AREA)                            54590020
         B     EGGSITA                  BRANCH TO EXIT, RC = 08  A45155 55260021
READOLD  EQU   *                                                        55350020
         MVC   REDCB@(WD),CAPTCDCB      SET PT TO UTILITY DCB           55440020
         MVI   REUTPLST,READWKEY        IND READ W/ KEY                 55530020
         LA    WR,REUTKEY                                               55620020
         ST    WR,REKEY@                SET PT TO KEY                   55710020
         ST    OLDLINO,REUTKEY          SET KEY (OLD-LINENUM)           55800020
         LA    WR,REINAREA                                              55890020
         ST    WR,REBFR@                SET PT INPUT BFR                55980020
         MVI   REBFR@,REFLAG            FLAG END OF PLIST               56070020
 SPACE                                                                  56160020
* CALL UTILITY DATA SET INTERFACE ROUTINE TO READ OLD-LINENUM -         56250020
 SPACE                                                                  56340020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C56430020
               MF=(E,RESRPLST)                                          56520020
         B     UTBRTBL5(RETCDREG)       BRANCH ACC TO RET CODE          56610020
UTBRTBL5 EQU   *                                                        56700020
         B     NEWOLDQ   0(SUCCESS  ) - CONTINUE                        56790020
         B     NONESUCH  4(NOT FOUND) - ISSUE MESSAGE                   56880020
         B     IOERR     8(I/O ERROR) - SET RET CODE 12                 56970020
NONESUCH EQU   *                                                        57060020
         L     WR,OLDLINUM              GET PT TO OLD-LINENUM           57150020
         MVC   PATTERN1(DUBLWD),O(WR)   MOVE IT TO FORMATTED     A50472 57330021
*                                       INSERTION AREA (LINE     A50472 57420021
*                                       NO. IS AS ENTERED WITH   A50472 57450021
*                                       MAXIMUM LENGTH OF 8)     A50472 57480021
         LH    WR,OLDLINUM+OPRNDLNG     GET LENGTH OF OLD-LINENUM       57510020
         LA    WR,WD(WR)                ADD LNG OF HEADER               57640020
         STH   WR,M507INS+WD            SET IT IN INSERTION             57690020
         LA    WR,M504IN1                                               57780020
         STH   WR,M507INS+WD+HAFWD      SET OFFSET                      57870020
         XC    M507INS(WD),M507INS      NO 2ND INSERT                   57900020
         IKJEBEML M504,0,M507INS,0,MF=(E,RE10AREA)                      57930020
         B     CLOZNEW                  BRANCH TO UNALLOC NEW DCB       57960020
         EJECT                                                          58050020
 SPACE                                                                  58140020
* IF NEW-LINENUM IS LESS THAN OLD-LINENUM, SEE IF THE RECORD NUMBER     58230020
* PRECEDING OLD-LINENUM IS LESS THAN NEW-LINENUM.  OTHERWISE BRANCH TO  58320020
* READ FIRST RECORD.                                                    58410020
 SPACE                                                                  58500020
NEWOLDQ  EQU   *                                                        58590020
         CR    LINO,OLDLINO             IS NEW-LINENUM LT OLD           58680020
         BNL   READFUST                 IF NO,BRANCH TO READ 1ST        58770020
         MVC   REDCB@(WD),CAPTCDCB      IF YES,SET PT TO DCB            58860020
         MVI   REUTPLST,READPREV        IND READ PREVIOUS               58950020
         LA    WR,REUTKEY                                               59040020
         ST    WR,REKEY@                SET PT TO KEY                   59130020
         ST    OLDLINO,REUTKEY          SET KEY(OLD-LINENUM)            59220020
         LA    WR,REINAREA                                              59310020
         ST    WR,REBFR@                SET PT TO INPUT BUFFER          59400020
         MVI   REBFR@,REFLAG            FLAG END OF PARM LIST           59490020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C59580020
               MF=(E,RESRPLST)                                          59670020
         B     UTBRTBL6(RETCDREG)       BRANCH ACC TO RET CODE          59760020
UTBRTBL6 EQU   *                                                        59850020
         B     SEQQ      0(SUCCESS  ) - COMPARE LINE NUMBERS            59940020
         B     OLDIS1ST  4(NOT FOUND) - RENUMBER OLD-LINENUM            60030020
         B     IOERR     8(I/O ERROR) - SET RET CODE 12                 60120020
OLDIS1ST EQU   *                                                        60210020
         ST    LINO,RE1STLIN            UPDATE STARTING LINE NO.        60300020
         B     RENUMOLD                 BRANCH TO RENUMBER OLD-         60390020
*                                       LINENUM                         60480020
SEQQ     EQU   *                                                        60570020
         C     LINO,REKEY               IS NEW-LINENUM GT LINENUM       60660020
*                                       PRECEDING OLD-LINENUM           60750020
         BH    READFUST                 IF YES,BRANCH TO READ 1ST       60840020
*                                       IF NO,ISSUE ERROR MSG -         60930020
         MVC   RE10AREA(MSGLISTL),LINVRANG INITLZ PARM LIST             61020020
         IKJEBEML ,,,,MF=(E,RE10AREA)                                   61110020
         B     CLOZNEW                  BRANCH TO UNALLOC NEW DCB       61200020
 SPACE                                                                  61290020
* COPY LINES FROM CURRENT UTILITY TO NEW UTILITY DATA SET UNTIL OLD-    61380020
* LINENUM IS ENCOUNTERED -                                              61470020
 SPACE                                                                  61560020
READFUST EQU   *                                                        61650020
         MVC   REDCB@,CAPTCDCB          SET PT TO DCB                   61740020
         MVI   REUTPLST,READ1ST         IND READ FIRST RCD              61830020
         XC    REKEY@(WD),REKEY@        IND KEY IRRELEVANT              61920020
         LA    WR,REINAREA                                              62010020
         ST    WR,REBFR@                SET PT TO INPUT BFR             62100020
         MVI   REBFR@,REFLAG            FLAG END OF PARM LIST           62190020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C62280020
               MF=(E,RESRPLST)                                          62370020
         B     UTBRTBL7(RETCDREG)       BRANCH ACC TO RET CODE          62460020
UTBRTBL7 EQU   *                                                        62550020
         B     EQOLDQ    0(SUCCESS  ) - CONTINUE                        62640020
         B     CLOZNEW                  BR TO CLOSE DATA SET            62730020
         B     IOERR     8(I/O ERROR) - SET RET CODE 12                 62820020
EQOLDQ   EQU   *                                                        62910020
         C     OLDLINO,REKEY            DOES 1ST KEY EQ OLD-LINUM       63000020
         BNE   COPY                     IF NO,BRANCH TO WRITE RCD       63090020
         ST    LINO,RE1STLIN            IF YES,UPDATE STARTING          63180020
         B     RENUMOLD                 LINE NO. & BRANCH TO            63270020
*                                       RENUMBER OLD-LINENUM            63360020
LTOLDQ   EQU   *                                                        63450020
         C     OLDLINO,REKEY            DOES THIS LINE PRECEDE          63540020
*                                       OLD-LINENUM                     63630020
         BNH   RENUMOLD                 IF NO,BRANCH TO RENUMBER        63720020
*                                       OLD-LINENUM                     63810020
COPY     EQU   *                        IF YES,COPY RCD INTO NEW        63900020
*                                       UTILITY DATA SET -              63990020
         MVC   REDCB@(WD),REDCB         SET PT TO DCB                   64080020
         MVI   REUTPLST,WRITERCD        IND WRITE A RCD                 64170020
         LA    WR,REINAREA                                              64260020
         ST    WR,REKEY@                SET PT TO RCD                   64350020
         MVI   REKEY@,REFLAG            FLAG END OF PLIST               64440020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C64530020
               MF=(E,RESRPLST)                                          64620020
         B     UTBRTBL8(RETCDREG)       BRANCH ACC TO RET CODE -        64710020
UTBRTBL8 EQU   *                                                        64800020
         B     KEEPGOIN  0(SUCCESS   ) - CONTINUE                       64890020
         B     CLOZNEW                  BR TO CLOSE DATA SET            64980020
         B     IOERR     8(I/O ERROR) - SET RET CODE 12                 65070020
KEEPGOIN EQU   *                                                        65160020
         MVC   REDCB@(WD),CAPTCDCB      SET PT DCB                      65250020
         MVI   REUTPLST,READNEXT        IND READ NEXT RCD               65340020
         LA    WR,REUTKEY                                               65430020
         ST    WR,REKEY@                SET PT TO KEY                   65520020
         MVC   REUTKEY(WD),REKEY        SET KEY(FROM PREVIOUS RCD)      65610020
         LA    WR,REINAREA                                              65700020
         ST    WR,REBFR@                SET PT TO INPUT BFR             65790020
         MVI   REBFR@,REFLAG            FLAG END OF PLIST               65880020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C65970020
               MF=(E,RESRPLST)                                          66060020
         B     UTBRTBL9(RETCDREG)       BRANCH ACC TO RET CODE -        66150020
UTBRTBL9 EQU   *                                                        66240020
         B     LTOLDQ    0(SUCCESS)   - LOOP TO COMPARE                 66330020
         B     CLOZNEW                  BR TO CLOSE DATA SET            66420020
         B     CLOZNEW   8(I/O ERROR) - UNALLOC NEW DCB                 66510020
 SPACE                                                                  66600020
*********************************************************************** 66690020
* SAVE THE KEY FROM THE RECORD JUST READ & BRANCH BACK TO THE MAIN    * 66780020
* RENUMBERING LOOP, USING NEW-LINENUM AS THE GENERATED LINE-NUMBER    * 66870020
*********************************************************************** 66960020
 SPACE                                                                  67050020
RENUMOLD EQU   *                                                        67140020
         MVC   REOLDKEY(WD),REKEY                                       67230020
         B     MAINLOOP                 BRANCH BACK TO MAIN LOOP        67320020
 EJECT                                                                  67410020
*********************************************************************** 67500020
* FOLLOWING CODE IS BRANCHED TO WHEN DATA SET TYPE IS IPLI OR BASIC   * 67590020
*********************************************************************** 67680020
 SPACE                                                                  67770020
XKBASIC  EQU   *                                                        67860020
XKIPLI   EQU   *                                                        67910020
GOAHEAD  EQU   *                                                        68670020
         LTR   OLDLINO,OLDLINO          WAS OLD-LINENUM SPEC            68760020
         BNM   SETVALUS                 IF YES,BRANCH TO SET VALUES     68850020
         MVC   REDCB@(WD),CAPTCDCB      IF NO,SET PT TO DCB             68940020
         MVI   REUTPLST,READ1ST         IND READ 1ST RECORD             69030020
         XC    REKEY@(WD),REKEY@        IND KEY IRRELEVANT              69120020
         LA    WR,REINAREA                                              69210020
         ST    WR,REBFR@                SET PT TO INPUT BFR             69300020
         MVI   REBFR@,REFLAG            FLAG END OF PARM LIST           69390020
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),REUTPLST),       C69480020
               MF=(E,RESRPLST)                                          69570020
         B     UTBRTBLX(RETCDREG)       BRANCH ACC TO RET CODE -        69660020
UTBRTBLX EQU   *                                                        69750020
         B     MOVEOLD    0(SUCCESS  ) -SET OLD-LINENUM                 69840020
         B     MT         4(NOT FOUND) -ISSUE MSG                       69930020
         B     IOERR      8(I/O ERROR) -SET RET CODE 12                 70020020
MOVEOLD  EQU   *                                                        70110020
         L     OLDLINO,REKEY                                            70200020
SETVALUS EQU   *                                                        70290020
         ST    OLDLINO,XKOL             SET OLD-LINENUM,                70380020
         ST    LINO,XKNU                    NEW-LINENUM, AND            70470020
         ST    INCR,XKINK                   INCREMENT IN VALUE LIST     70560020
         EJECT                                                          70600020
 SPACE                                                                  70650020
*********************************************************************** 70740020
* IF THIS IS A 'BASIC' DATA SET, CALL THE MODULE WHICH RENUMBERS THE  * 70830020
* UTILITY DATA SET.                                                   * 70920020
*********************************************************************** 71010020
 SPACE                                                                  71100020
         CLI   CADSCODE,CABASIC         IS THIS A 'BASIC' DATA SET      71190020
         BNE   RENUMRUN                 IF NO,BRANCH TO RENUMBER        71280020
*                                             RUN-TIME DATA SET.        71370020
         ST    COMMREG,BASICCOM         IF YES,SET PT TO EDIT COMM AREA 71460020
         LA    WR,XKOL                                                  71490020
         ST    WR,BASICVAL              SET PT TO VALUES                71520020
         MVC   CAPTPDCB(WD),REDCB       SET PT TO NEW UTIL DCB          71590020
         IKJEBESH  (COMMREG),IKJEBERN,PARAM=(BASICLST),MF=(E,RESRPLST)  71640020
         B     RNCKIT(RETCDREG)        CHECK RETURN CODE                71690020
RNCKIT   EQU   *                                                        71700020
         B     RENUMRUN                0 SUCCESSFUL                     71710020
         B     CLOZNEW                 4 ERROR, NO RENUM DONE           71720020
         B     IOERR                   8 ERROR IN I/O, CLOSE DS DCB     71730020
RENUMRUN EQU   *                       IF YES,RENUM RUN-TIME DATA SET-  71910020
         MVC   CAPTPDCB,CAPTCDCB   MOVE CURRENT DCB TO PREVIOUS DCB     72010020
         MVC   CAPTCDCB,REDCB      MOVE NEW DCB INTO CURRENT DCB        72110020
         LR    PARMREG1,COMMREG    POINT TO COMMAREA                    72210020
         SR    WR,WR                   ZERO REG                         72260020
         C     WR,CAPTCHK              IS SYNTAX CHECKER THERE          72270020
         BE    NOMRX                   IF NOT, DONT REDO POLISH DS      72280020
         IKJEBESH  (COMMREG),IKJEBEMR,PARAM=((COMMREG)),MF=(E,RESRPLST) 72310020
         B     MRCKIT(RETCDREG)    CHECK RENUM RETCODE                  72410020
NOMRX    SR    RETCDREG,RETCDREG       ZERO RETURN CODE REG             72460020
MRCKIT   EQU   *                                                        72510020
         B     CLOZOLDA            RC 0 OK, CLEAN UP                    72610020
         B     CLOZNEWA            RC 4 MR FAILED, CLEAN UP             72710020
         B     SETRC16                 RC 8 SET RC 16                   72810020
         NI    CASYNCD2,X'FF'-RENOSW   RESET RENUM SW                   72860020
         B     EGGSITA                 BRANCH TO EXIT                   72870020
SETRC16  EQU   *                                                        72910020
         LA    WR,HAFREG               SET RETURN CODE                  72960020
         ST    WR,REKODE               TO 16                            72970020
         B     CLOZNEWA                AND TERMINATE                    72980020
         EJECT                                                          73010020
*********************************************************************** 73350020
* THE FOLLOWING CODE ISSUES DIAGNOSTIC MESSAGES                       * 73440020
*********************************************************************** 73530020
 SPACE                                                                  73620020
PARSERR  MVC   IN1(IN2-IN1),REPARSE     MOVE NAME OF ROUTINE TO INSERT  73630020
         B     SRERROR                  BR TO SET UP PARMLISTS          73640020
SYNCKERR MVC   IN1(IN2-IN1),RESCHK      MOVE NAME OF CHKR TO INSERTION  73650020
SRERROR  MVC   LEVEL1(MSGLISTL),SRERR   FILL IN LEV1 PARMLIST           73670020
         LA    WR,IN1                   CHAIN                           73680020
         ST    WR,L2INPT                PARMLISTS                       73690020
         LA    WR,IN2                   CHAIN                           73710020
         ST    WR,IN1                   PARMLISTS                       73720020
         MVC   IN2(DUBLWD),M313INB      FILL IN INSERT2 PLIST           73730020
         SRL   RETCDREG,PARMREG1        SHIFT R15 FOR INDEXING          73740020
         LH    WR,RECDTAB(RETCDREG)     PICK UP PRINTABLE CHARACTER     73750020
         STH   WR,IN2INS                STORE IN INSERTION              73760020
         IKJEBEML ,,,,MF=(E,RE10AREA)   LINK TO IKJEBEMS TO PUT ERR MSG 73770020
         B     EGGSITA             BRANCH TO EXIT                       73870020
         EJECT                                                          76000020
*********************************************************************** 76140020
*                             CONSTANTS                               * 76230020
*********************************************************************** 76320020
 SPACE                                                                  76410020
* OBJECTS OF 'EXECUTE' INSTRUCTIONS -                                   76500020
 SPACE                                                                  76590020
PAK      PACK  CATEMPBF(DUBLWD),O(O,PARMREG1) CONVERT OLD-LINENUM,      76680020
*                                       NEW-LINENUM,OR INCREMENT        76770020
*                                       FROM ZONED TO PACKED            76860020
*                                       DECIMAL                         76950020
NUMBCLC  CLC   O(O,WR),BLANKNUM         CMP SEQUENCE FIELD AREA OF      77040020
*                                       RECORD WITH BLANKS              77130020
         EJECT                                                          77280020
* MESSAGE SELECTION PARAMETER LISTS AND FORMATTED INSERTIONS -          77340020
 SPACE                                                                  77400020
LMSG0    DC    A(0)                    PT TO 2ND INSERTION              77490020
         DC    AL2(76)                 LNG OF MSG                       77580020
         DC    AL2(0)                  OFFSET                           77670020
LMT      IKJEBEML M501,0,0,0,MF=L                                       77760020
MSGLISTL EQU   *-LMT                                                    77850020
LINTRC   IKJEBEMG 0,M507IN1,'0'        FILL CHAR FOR 'EDMK' INSTRUC     77950020
         DC    9X'20'                  DIGIT SELECT BYTE                78120020
LINTRCL  EQU   *-LINTRC                                                 78210020
LNGIS    IKJEBEMG 0,M5071IN1,' ' FILL CHAR FOR 'EDMK'                   78300020
         DC    3X'20'                  DIGIT SELECT BYTE                78390020
LNGISL   EQU   *-LNGIS                                                  78480020
LCROWDED IKJEBEML M312,0,RENXX,0,MF=L                                   78680020
RENXX    IKJEBEMG ,M312IN1,'RENUM'                                      78760020
LINVRANG IKJEBEML M503,0,0,0,MF=L                                       78840020
SRERR    IKJEBEML M313,M3131,0,0,MF=L                                   78860020
REPARSE  IKJEBEMG 0,M3131IN1,'PARSE'                                    78866020
RESCHK   IKJEBEMG 0,M3131IN1,'IXXXXXXX'                                 78872020
LIMPOSSI IKJEBEML M560,0,0,0,MF=L                                       78880020
MOLNZ    IKJEBEMG 0,M504IN1,'0'                                         78890020
 SPACE                                                                  78930020
* MISCELLANEOUS -                                                A45155 79020021
         SPACE                                                          79021021
PCL@     DC    V(IKJEBRE4)    ADDRESS OF PARSE PCL               A45155 79022021
RC12     DC    F'12'          I/O ERROR RETURN CODE              A45155 79023021
BLANKNUM DC    CL8' '         BLNK FLD TO CMP W/ SEQ NO. FLD     A45155 79024021
RECDTAB  DS    0H                       TABLE OF PRINTABLE       A45155 79025021
         DC    C'  040812'              CHARACTERS               A45155 79026021
M313INB  DC    A(0)                     PTR TO SECOND INSERTION  A45155 79027021
         DC    AL2(OPRNDEX)             LENGTH OF INSERTION      A45155 79028021
         DC    AL2(M3131IN2)            PTR TO INSERTION POINT   A45155 79029021
RET8     DC    F'8'                     RC FOR FLUSH STACK       A45155 79030021
         EJECT                                                          79031021
**************************************************************** A45155 79032021
*                                                                A45155 79033021
*    THE FOLLOWING SUBROUTINE IS CALLED WHEN RENUM IS ENTERED    A45155 79034021
*    FOR A NONUM DATA SET.  ITS PURPOSE IS TO DETERMINE, WITH    A45155 79035021
*    PROMPTING IF NECESSARY, WHETHER RENUMBERING OF THE DATA     A45155 79036021
*    SET SHOULD BE ALLOWED.                                      A45155 79037021
*                                                                A45155 79038021
*    RENUM IS ALLOWED TO CONTINUE WITHOUT PROMPTING WHEN --      A45155 79039021
*                                                                A45155 79040021
*         (1) THE USER IS A 'NOPROMPT' USER.                     A45155 79041021
*         (2) THE CURRENT SOURCE OF INPUT IS A COMMAND           A45155 79042021
*             PROCEDURE.                                         A45155 79043021
*         (3) THE DATA SET TYPE IS TEXT, AND THE RECORD FORMAT   A45155 79044021
*             IS VARIABLE.                                       A45155 79045021
*                                                                A45155 79048021
*    IF NONE OF THE ABOVE CONDITIONS PERTAINS, A WARNING         A45155 79049021
*    MESSAGE IS SENT TO THE TERMINAL EXPLAINING THAT DATA MAY    A45155 79050021
*    BE OVERLAID (RECFM=F) OR LINES MAY BE TRUNCATED (RECFM=V).  A45155 79051021
*    A MESSAGE IS THEN ISSUED VIA PUTGET, ENABLING THE USER TO   A45155 79052021
*        (1) CONTINUE RENUM OR                                   A45155 79053021
*        (2) ENTER ANOTHER SUBCOMMAND                            A45155 79054021
*                                                                A45155 79055021
*    RETURN CODES FOR THIS ROUTINE ARE AS FOLLOWS --             A45155 79056021
*                                                                A45155 79057021
*        00 - CONTINUE RENUMBER OPERATION                        A45155 79058021
*        04 - USER SUSPENDED RENUM BY ENTERING SUBCOMMAND        A45155 79059021
*        08 - COMMAND SYSTEM ERROR (DIAGNOSED WITH MESSAGE)      A45155 79060021
*                                                                A45155 79061021
**************************************************************** A45155 79062021
         SPACE 2                                                        79063021
IKJEBRE1 CSECT                                                   A45155 79064021
         IKJEBESV (14,12),,*,COMMREG=NO ENTRY LINKAGE            A45155 79065021
         USING IKJEBECA,COMMREG        ESTABLISH ADDRESSABILITY  A45155 79066021
*                                      TO COMMUNICATION AREA     A45155 79067021
         SR    WR,WR                                             A45155 79068021
         STH   WR,RE1RCODE             SET TENTATIVE RC OF ZERO  A45155 79069021
         XC    RE1FLAG(L1),RE1FLAG     ZERO CONTROL FLAG BITS    A45155 79070021
         SR    ZEROREG,ZEROREG         INITIALIZE ONE REGISTER   A45155 79071021
*                                      TO BINARY ZEROES          A45155 79072021
         EJECT                                                          79073021
*                                                                A45155 79074021
*    DETERMINE IF RENUM CAN CONTINUE WITHOUT PROMPTING           A45155 79075021
*                                                                A45155 79076021
         SPACE                                                          79077021
         L     WR,CAPTUPT              OBTAIN ADDRESS OF UPT     A45155 79078021
         TM    UPTSWS-UPT(WR),UPTNPRM  CHECK FOR NOPROMPT USER   A45155 79079021
         BO    RE1EXIT                 IF SO, RETURN TO MAINLINE A45155 79080021
         TM    CACFLAG4,CAINPROC       CHECK FOR PROCEDURE INPUT A45155 79081021
         BO    RE1EXIT                 IF SO, RETURN TO MAINLINE A45155 79082021
         SR    WR,WR                                             A45155 79083021
         IC    WR,CALENGTH             OBTAIN SEQUENCE NUMBER    A45155 79084021
*                                      LENGTH                    A45155 79085021
         LH    WR1,CALRECL             OBTAIN LRECL              A45155 79086021
         TM    CACFLAG2,CARECFM        CHECK RECORD FORMAT       A45155 79087021
         BO    RE100500                IF FIXED, BRANCH TO ISSUE A45155 79088021
*                                      WARNING MESSAGE           A45155 79097021
         CLI   CADSCODE,CATEXT         CHECK FOR TYPE='TEXT'     A45155 79106021
         BE    RE1EXIT                 IF TEXT, RETURN TO        A45155 79106721
*                                      MAINLINE (FOR TEXT DATA   A45155 79107421
*                                      SETS OF VARIABLE RECORD   A45155 79108121
*                                      FORMAT, OVERFLOW LINES    A45155 79108821
*                                      ARE CREATED WHERE         A45155 79109521
*                                      REQUIRED, INSTEAD OF      A45155 79110221
*                                      TRUNCATING LINES.)        A45155 79110921
         SPACE                                                          79111621
*                                                                A45155 79112321
*    ISSUE WARNING MESSAGE FOR FORMAT V DATA SETS.               A45155 79113021
*                                                                A45155 79113721
         SPACE                                                          79114421
         LA    WR,L4(,WR)              OBTAIN NUMBER OF BYTES    A45155 79115121
*                                      IN CONTROL WORD AND       A45155 79115821
*                                      SEQUENCE FIELD            A45155 79116521
         SR    WR1,WR                  COMPUTE MAXIMUM NUMBER    A45155 79117221
*                                      OF DATA BYTES PER LINE    A45155 79117921
         LA    WR,M5692                SET LEVEL-2 RELATIVE MSG  A45155 79119021
         STH   WR,RE1LEV2              NO. IN IKJEBEMS PARMLIST  A45155 79120021
         LA    WR,M5692IN1             OBTAIN OFFSET AND STORE   A45155 79121021
         STH   WR,RE1OFF1              FOR LEVEL-2 INSERTION     A45155 79122021
         CVD   WR1,RE1DWORD            CONVERT INSERTION TEXT    A45155 79123021
*                                      TO DECIMAL                A45155 79124021
         UNPK  RE1TEXT1(L3),RE1DWORD+D6(L2) UNPACK RESULT        A45155 79125021
         MVZ   RE1TEXT1+D2(L1),RE1TEXT1+D1 INSURE CORRECTNESS OF A45155 79125321
*                                      LAST DIGIT                A45155 79125621
         LA    WR2,RE1TEXT1            OBTAIN ADDRESS OF         A45155 79126021
*                                      INSERTION TEXT FIELD FOR  A45155 79127021
*                                      ZERO SUPPRESSION SUBRTN   A45155 79128021
         BAL   RETREG,RE101000         BRANCH TO SUPPRESS ZEROES A45155 79129021
         STH   WR,RE1LEN1              STORE LENGTH IN           A45155 79130021
*                                      INSERTION LIST            A45155 79131021
         ST    ZEROREG,RE1PTR1         SPECIFY ONE INSERTION     A45155 79132021
*                                      ONLY                      A45155 79133021
         B     RE100520                BRANCH TO PROCESS FIRST-  A45155 79134021
*                                      LEVEL MESSAGE             A45155 79135021
         EJECT                                                          79136021
*                                                                A45155 79137021
*   ISSUE WARNING MESSAGE FOR RECORD FORMAT F DATA SETS.         A45155 79138021
*                                                                A45155 79139021
RE100500 EQU   *                                                 A45155 79140021
         LA    WR,M5691                SET LEVEL-2 RELATIVE MSG  A45155 79141021
         STH   WR,RE1LEV2              NO. IN IKJEBEMS PARMLIST  A45155 79142021
         LA    WR,M5691IN1             OBTAIN OFFSET FOR FIRST   A45155 79143021
*                                      LEVEL-2 INSERTION         A45155 79144021
         STH   WR,RE1OFF1              STORE OFFSET IN LIST      A45155 79145021
         IC    WR,CALINE               OBTAIN SEQUENCE NUMBER    A45155 79146021
*                                      START POSITION            A45155 79147021
         LR    WR1,ZEROREG             CLEAR REGISTER FOR IC     A45155 79148021
         IC    WR1,CALENGTH            OBTAIN SEQ. NO. LENGTH    A45155 79149021
         AR    WR1,WR                  COMPUTE LAST POSITION     A45155 79150021
         BCTR  WR1,0                   FOR SEQUENCE NUMBER       A45155 79151021
         CVD   WR,RE1DWORD             CONVERT START POSITION TO A45155 79152021
*                                      DECIMAL                   A45155 79153021
         UNPK  RE1TEXT1(L3),RE1DWORD+D6(L2) UNPACK RESULT        A45155 79154021
         MVZ   RE1TEXT1+D2(L1),RE1TEXT1+D1 INSURE CORRECTNESS    A45155 79154321
*                                      OF LAST DIGIT             A45155 79154621
         LA    WR2,RE1TEXT1            OBTAIN ADDRESS OF         A45155 79155021
*                                      INSERTION TEXT FIELD      A45155 79156021
         BAL   RETREG,RE101000         BRANCH TO SUPPRESS ZEROES A45155 79157021
         STH   WR,RE1LEN1              STORE LENGTH OF FIRST     A45155 79158021
*                                      INSERTION                 A45155 79159021
         LA    WR,RE1PTR2              OBTAIN ADDRESS FOR        A45155 79160021
*                                      SECOND INSERTION          A45155 79161021
         ST    WR,RE1PTR1              CHAIN INSERTIONS          A45155 79162021
         LA    WR,M5691IN2             OBTAIN OFFSET FOR SECOND  A45155 79163021
         STH   WR,RE1OFF2              LEVEL-2 INS. AND STORE    A45155 79164021
         ST    ZEROREG,RE1PTR2         SPECIFY TWO INSERTIONS    A45155 79165021
         CVD   WR1,RE1DWORD            CONVERT END POSITION TO   A45155 79166021
*                                      DECIMAL                   A45155 79167021
         UNPK  RE1TEXT2(L3),RE1DWORD+D6(L2) UNPACK RESULT        A45155 79168021
         MVZ   RE1TEXT2+D2(L1),RE1TEXT2+D1 INSURE CORRECTNESS    A45155 79168321
*                                      OF LAST DIGIT             A45155 79168621
         LA    WR2,RE1TEXT2            OBTAIN ADDRESS OF INS.    A45155 79169021
*                                      TEXT FIELD                A45155 79170021
         BAL   RETREG,RE101000         BRANCH TO SUPPRESS ZEROES A45155 79171021
         STH   WR,RE1LEN2              STORE INSERTION LENGTH    A45155 79172021
*                                                                A45155 79173021
*   COMMON FIRST-LEVEL MESSAGE PROCESSING BEGINS HERE.           A45155 79174021
*                                                                A45155 79175021
RE100520 EQU   *                                                 A45155 79176021
         ST    ZEROREG,RE1INSL1        SPECIFY NO FIRST-LEVEL    A45155 79177021
*                                      INSERTIONS.               A45155 79178021
         LA    WR,RE1PTR1              OBTAIN ADDRESS OF LEVEL-2 A45155 79179021
*                                      INSERTION CHAIN           A45155 79180021
         ST    WR,RE1INSL2             STORE IN IKJEBEMS PLIST   A45155 79181021
         LA    WR,M569                 OBTAIN FIRST-LEVEL        A45155 79182021
*                                      RELATIVE MESSAGE NUMBER   A45155 79183021
         STH   WR,RE1LEV1              STORE IN PARM LIST        A45155 79184021
         BAL   RETREG,RE103000         BRANCH TO ISSUE WARNING   A45155 79185021
*                                      MESSAGE                   A45155 79186021
         OC    RE1RCODE(L2),RE1RCODE   CHECK IF ERROR OR         A45155 79187021
*                                      SUSPENSION BY USER        A45155 79188021
         BNZ   RE1EXIT                 IF SO, RETURN TO CALLER   A45155 79189021
*                                                                A45155 79190021
*    INVOKE PUTGET SERVICE ROUTINE WITH MODE MESSAGE TO          A45155 79191021
*    DETERMINE IF USER WISHES TO RENUMBER DATA SET               A45155 79192021
*                                                                A45155 79193021
RE100550 EQU   *                                                 A45155 79194021
         XC    RE1PGPB(L16),RE1PGPB    ZERO PARAMETER BLOCK      A45155 79195021
         L     WR,RE1PTRE2             ESTABLISH ADDRESSABILITY  A45155 79196021
         USING IKJEBRE2,WR             TO MESSAGE AREA           A45155 79197021
         PUTGET PARM=RE1PGPB,OUTPUT=(RE2PGMSG,SINGLE,MODE),      A45155X79198021
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),               A45155X79199021
               TERMGET=(EDIT,WAIT),MF=(E,CATMPLST)               A45155 79200021
         DROP  WR                      DROP ADDRESSABILITY TO    A45155 79201021
*                                      MESSAGES                  A45155 79202021
         B     RE100600(RETCDREG)      BRANCH INTO TABLE TO      A45155 79203021
*                                      DETERMINE NEXT ACTION     A45155 79204021
*                                      BASED ON RETURN CODE      A45155 79205021
RE100600 EQU   *                                                 A45155 79206021
         B     RE100680                RC=0, BRANCH TO DETERMINE A45155 79207021
*                                      USER'S REQUEST            A45155 79208021
         B     RE100640                RC=4, INPUT FROM SOURCE   A45155 79209021
*                                      OTHER THAN TERMINAL IS    A45155 79210021
*                                      A COMMAND SYSTEM ERROR    A45155 79211021
         B     RE100695                RC=,, ATTENTION INTERRUPT A45155 79212021
         B     RE100620                RC=12, 2ND-LEVEL MESSAGES A45155 79213021
*                                      MUST BE FREED, BRANCH     A45155 79214021
*                                      TO SET ECT SWITCH AND     A45155 79215021
*                                      REISSUE PUTGET            A45155 79216021
         B     RE100640                RC=16, COMMAND SYS ERROR  A45155 79217021
         B     RE100640                RC=20, COMMAND SYS ERROR  A45155 79218021
         B     RE100640                RC=24, COMMAND SYS ERROR  A45155 79219021
         B     RE100660                RC=28, NOT ENOUGH MAIN    A45155 79220021
*                                      STORAGE                   A45155 79221021
RE100620 EQU   *                                                 A45155 79222021
         L     WR,CAPTECT              OBTAIN ADDRESS OF ECT     A45155 79223021
         OI    ECTMSGF-ECT(WR),REFLAG  SET MESSAGE FLUSH SWITCH  A45155 79224021
*                                      ON                        A45155 79225021
         B     RE100550                BRANCH TO REISSUE PUTGET  A45155 79226021
RE100640 EQU   *                                                 A45155 79227021
         OI    RE1FLAG,RE1PGSW         INDICATE PUTGET ERROR     A45155 79228021
         BAL   RETREG,RE102000         BRANCH TO FORMAT MESSAGE  A45155 79229021
         BAL   RETREG,RE103000         BRANCH TO ISSUE MESSAGE   A45155 79230021
         B     RE1EXIT                 BRANCH TO RETURN          A45155 79231021
RE100660 EQU   *                                                 A45155 79232021
         MVC   RE1MSLST(L12),RE1NOCOR  MOVE PARAMETER LIST TO    A45155 79233021
*                                      DYNAMIC AREA              A45155 79234021
         MVI   RE1RCODE+D1,RE1RC8      SET R. C. OF 8            A45155 79235021
         BAL   RETREG,RE103000         BRANCH TO ISSUE MESSAGE   A45155 79236021
         B     RE1EXIT                 BRANCH TO RETURN          A45155 79237021
RE100680 EQU   *                                                 A45155 79238021
         L     WR,CASRPLST             OBTAIN ADDRESS OF PGPB    A45155 79239021
         L     PARMREG1,PGPBIBUF-PGPB(WR) OBTAIN BUFFER ADDRESS  A45155 79240021
         LA    PARMREG0,L4             DETERMINE IF BUFFER       A45155 79241021
         CH    PARMREG0,D0(,PARMREG1)  CONTAINS A NULL LINE      A45155 79242021
         BNE   RE100690                IF NOT, BR TO SET UP      A45155 79243021
*                                      NEXT SUBCOMMAND           A45155 79244021
         O     PARMREG0,RE1SP1         INDICATE SUBPOOL 1        A45155 79244521
         FREEMAIN R,LV=(0),A=(1)       FREE NULL LINE            A45155 79245021
         B     RE1EXIT                 BRANCH TO RETURN          A45155 79246021
RE100690 EQU   *                                                 A45155 79247021
         ST    PARMREG1,CAPTNBFR       STORE ADDRESS OF NEXT     A45155 79248021
*                                      SUBCOMMAND IN APPROPRIATE A45155 79249021
*                                      BUFFER                    A45155 79250021
RE100695 EQU   *                                                 A45155 79251021
         OI    RE1RCODE+D1,RE1RC4      SET RC=4, USER ENTERED    A45155 79252021
*                                      NEW SUBCOMMAND            A45155 79253021
RE1EXIT  EQU   *                                                 A45155 79254021
         LH    RETCDREG,RE1RCODE       OBTAIN RETURN CODE FOR    A45155 79255021
*                                      MAINLINE IKJEBERE         A45155 79256021
         IKJEBERT (14,12),,RC=(15)     RETURN TO MAINLINE RTN    A45155 79257021
         EJECT                                                          79258021
*                                                                A45155 79259021
*    THE FOLLOWING SUBROUTINE SUPPRESSES UP TO 2 LEADING ZEROES  A45155 79260021
*    FROM A 3-BYTE CHARACTER DIGIT FIELD                         A45155 79261021
*                                                                A45155 79262021
         SPACE                                                          79263021
RE101000 EQU   *                                                 A45155 79264021
         LA    WR,C2                   OBTAIN MAXIMUM NUMBER OF  A45155 79265021
*                                      DIGITS TO BE SUPPRESSED   A45155 79266021
RE101300 EQU   *                                                 A45155 79267021
         CLI   D0(WR2),RE1CZERO        CHECK FOR LEADING ZERO    A45155 79268021
         BNE   RE101600                IF NOT, NO FURTHER        A45155 79269021
*                                      SUPPRESSION IS NECESSARY  A45155 79270021
         MVC   D0(L2,WR2),D1(WR2)      OVERLAY LEADING ZERO      A45155 79271021
         BCT   WR,RE101300             DECREMENT COUNT AND       A45155 79272021
*                                      BRANCH IF FURTHER         A45155 79273021
*                                      SUPPRESSION MAY BE        A45155 79274021
*                                      NECESSARY                 A45155 79275021
RE101600 EQU   *                                                 A45155 79276021
         LA    WR,L5(,WR)              COMPUTE LENGTH OF         A45155 79277021
*                                      INSERTION                 A45155 79278021
         BR    RETREG                  RETURN                    A45155 79279021
         EJECT                                                          79280021
*                                                                A45155 79281021
*    THIS SUBROUTINE FORMATS ERROR MESSAGES FOR COMMAND SYSTEM   A45155 79282021
*    ERRORS.                                                     A45155 79283021
*                                                                A45155 79284021
         SPACE                                                          79285021
RE102000 EQU   *                                                 A45155 79286021
         NI    RE1FLAG,X'FF'-RE1PGSW   TURN PUTGET SWITCH OFF    A45155 79287021
         BZ    RE102200                IF FIELD IS ZERO, PUTGET  A45155 79288021
*                                      SERVICE ROUTINE ERROR     A45155 79289021
         MVC   RE1INS1(L15),RE1PLINS   MOVE INSERTION LIST       A45155 79290021
*                                      FOR PUTLINE               A45155 79291021
         B     RE102400                BRANCH TO HANDLE SECOND   A45155 79292021
*                                      INSERTION                 A45155 79293021
RE102200 EQU   *                                                 A45155 79294021
         MVC   RE1INS1(L14),RE1PGINS   MOVE INSERTION LIST       A45155 79295021
*                                      FOR PUTGET                A45155 79296021
RE102400 EQU   *                                                 A45155 79297021
         CVD   RETCDREG,RE1DWORD       CONVERT SERVICE ROUTINE   A45155 79298021
*                                      RETURN CODE TO DECIMAL    A45155 79299021
         UNPK  RE1TEXT2-D1(L3),RE1DWORD+D6(L2) UNPACK TO         A45155 79300021
*                                      INSERTION AREA            A45155 79301021
         MVZ   RE1TEXT2+D1(L1),RE1TEXT2 INSURE CORRECTNESS OF    A45155 79302021
*                                      LAST DIGIT                A45155 79303021
         LA    WR,D6                   OBTAIN LENGTH OF INSERT   A45155 79304021
         STH   WR,RE1LEN2              STORE LENGTH IN LIST      A45155 79305021
         LA    WR,M3131IN2             OBTAIN OFFSET FOR INSERT  A45155 79306021
         STH   WR,RE1OFF2              STORE OFFSET IN LIST      A45155 79307021
         ST    ZEROREG,RE1PTR2         SPECIFY THIS AS LAST      A45155 79308021
*                                      INSERTION                 A45155 79309021
         LA    WR,RE1PTR2              OBTAIN ADDRESS OF SECOND  A45155 79310021
*                                      INSERTION                 A45155 79311021
         ST    WR,RE1PTR1              CHAIN SECOND INSERTION TO A45155 79312021
*                                      FIRST                     A45155 79313021
         LA    WR,M313                 OBTAIN RELATIVE MESSAGE   A45155 79314021
*                                      NUMBER FOR FIRST-LEVEL    A45155 79315021
         STH   WR,RE1LEV1              STORE MESSAGE NUMBER      A45155 79316021
*                                      IN PARAMETER LIST         A45155 79317021
         LA    WR,M3131                OBTAIN RELATIVE MESSAGE   A45155 79318021
*                                      NUMBER FOR SECOND-LEVEL   A45155 79319021
         STH   WR,RE1LEV2              STORE NUMBER IN PARAMETER A45155 79320021
*                                      LIST                      A45155 79321021
         ST    ZEROREG,RE1INSL1        SPECIFY NO FIRST-LEVEL    A45155 79322021
*                                      INSERTIONS                A45155 79323021
         LA    WR,RE1PTR1              OBTAIN ADDRESS OF SECOND- A45155 79324021
*                                      LEVEL MESSAGE INSERTION   A45155 79325021
*                                      CHAIN                     A45155 79326021
         ST    WR,RE1INSL2             STORE IN PARAMETER LIST   A45155 79327021
         MVI   RE1RCODE+D1,RE1RC8      SPECIFY RETURN CODE 8     A45155 79328021
*                                      TO IKJEBERE               A45155 79329021
         BR    RETREG                  RETURN                    A45155 79330021
         EJECT                                                          79331021
*                                                                A45155 79332021
*    THE FOLLOWING SUBROUTINE INVOKES THE MESSAGE SELECT ROUTINE A45155 79333021
*    FOR TERMINAL OUTPUT OF MESSAGES AND DIAGNOSES ANY PUTLINE   A45155 79334021
*    ERRORS THAT MAY OCCUR.                                      A45155 79335021
*                                                                A45155 79336021
RE103000 EQU   *                       ENTRY LINKAGE             A45155 79337021
         IKJEBESV (14,12),,,COMMREG=NO,CODEREG=NO                A45155 79338021
         IKJEBEML ,,,,MF=(E,RE1MSLST)  INVOKE MESSAGE SELECT RTN A45155 79339021
         TM    RE1FLAG,RE1PLSW         CHECK IF PUTLINE ERROR    A45155 79340021
*                                      OCCURRED PREVIOUSLY       A45155 79341021
         BO    RE103900                IF SO, RETURN TO CALLER   A45155 79342021
         B     RE103100(RETCDREG)      OTHERWISE, BRANCH INTO    A45155 79343021
*                                      TABLE BASED ON THE        A45155 79344021
*                                      CURRENT PUTLINE R. C.     A45155 79345021
RE103100 EQU   *                                                 A45155 79346021
         B     RE103900                OUTPUT NORMAL, RETURN TO  A45155 79347021
*                                      CALLER                    A45155 79348021
         B     RE103900                ATTN ECB POSTED, RETURN   A45155 79349021
*                                      TO CALLER                 A45155 79350021
         B     RE103300                COMMAND SYSTEM ERROR,     A45155 79351021
*                                      DIAGNOSE                  A45155 79352021
         B     RE103300                COMMAND SYSTEM ERROR,     A45155 79353021
*                                      DIAGNOSE                  A45155 79354021
*    BRANCH TO NEXT INSTRUCTION OCCURS FOR GETMAIN FAILURES IN   A45155 79355021
*    PUTLINE.  THIS CONDITION IS DIAGNOSED WITH A MESSAGE.       A45155 79356021
         MVC   RE1MSLST(L12),RE1NOCOR  MOVE PARAMETERS TO        A45155 79357021
*                                      DYNAMIC AREA              A45155 79358021
         OI    RE1RCODE+D1,RE1RC8      SET RETURN CODE OF 8      A45155 79359021
         OI    RE1FLAG,RE1PLSW         INDICATE PUTLINE ERROR    A45155 79360021
         BAL   RETREG,RE103000         BRANCH TO ISSUE MESSAGE   A45155 79361021
         B     RE103900                RETURN TO CALLER          A45155 79362021
RE103300 EQU   *                                                 A45155 79363021
         OI    RE1FLAG,RE1PLSW         INDICATE PUTLINE ERROR    A45155 79364021
         BAL   RETREG,RE102000         BRANCH TO FORMAT MESSAGE  A45155 79365021
         BAL   RETREG,RE103000         BRANCH TO ISSUE MESSAGE   A45155 79366021
RE103900 EQU   *                                                 A45155 79367021
         IKJEBERT (14,12)              RETURN TO CALLER          A45155 79368021
         EJECT                                                          79369021
**************************************************************** A45155 79370021
*                                                                A45155 79371021
*    LOCAL STORAGE CONSTANTS FOR THIS ROUTINE                    A45155 79372021
*                                                                A45155 79373021
**************************************************************** A45155 79374021
         SPACE                                                          79375021
RE1NOCOR IKJEBEML M312,,RE1NCINS,,MF=L GENERATE PARAMETER LIST   A45155X79376021
                                       FOR INSUFFICIENT STORAGE  A45155X79377021
                                       MESSAGE                   A45155 79378021
         SPACE                                                          79379021
RE1NCINS IKJEBEMG 0,M312IN1,'RENUM' INSERTION LIST FOR MESSAGE   A45155X79380021
                                       ABOVE                     A45155 79381021
         SPACE                                                          79382021
RE1PLINS IKJEBEMG 0,M3131IN1,'PUTLINE' INSERTION FOR COMMAND     A45155X79383021
                                       SYSTEM ERROR MESSAGE      A45155 79384021
         SPACE                                                          79385021
RE1PGINS IKJEBEMG 0,M3131IN1,'PUTGET'  INSERTION FOR COMMAND     A45155X79386021
                                       SYSTEM ERROR MESSAGE      A45155 79387021
         SPACE                                                          79388021
RE1PTRE2 DC    V(IKJEBRE2)             ADDRESS OF MESSAGE CSECT  A45155 79389021
*                                      FOR IKJEBERE              A45155 79390021
RE1SP1   DS    0F                      SUBPOOL 1 MAXK FOR        A45155 79390221
         DC    X'01000000'             SETTING HIGH ORDER BYTE   A45155 79390421
*                                      OF REGISTER TO HEX 01     A45155 79390621
         EJECT                                                          79391021
IKJEBRE2 CSECT                         MESSAGE CSECT             A45155 79392021
         SPACE                                                          79393021
RE2PGMSG DS    0F                      MODE MESSAGE OUTPUT DESC. A45155 79394021
RE2SEGNO DC    F'1'                    MESSAGE HAS ONE SEGMENT   A45155 79395021
RE2MSGPT DC    A(RE2TEXT)              ADDRESS OF MESSAGE PROPER A45155 79396021
RE2TEXT  DS    0F                      MESSAGE TEXT              A45155 79397021
         DC    AL2(RE2MSEND-*)         LENGTH OF SEGMENT         A45155 79398021
         DC    AL2(0)                  ALWAYS ZERO               A45155 79399021
         DC    C' HIT CARRIER RETURN TO RENUMBER OR ENTER A NEW SUBCOMMX79400021
               AND-'                   MESSAGE TEXT              A45155 79401021
RE2MSEND EQU   *                       END OF LIST               A45155 79402021
 EJECT                                                                  79560020
*********************************************************************** 79650020
* MACROS TO GENERATE PARAMETER CONTROL LIST AND PROVIDE SYMBOLIC      * 79740020
* REFERENCE TO PARAMETER DESCRIPTOR LIST                              * 79830020
*********************************************************************** 79920020
IKJEBRE4 IKJPARM DSECT=RENUMPDL                                         80010020
NEWLINUM IKJIDENT 'LINE NUMBER',ASIS,MAXLNTH=8,FIRST=NUMERIC,          C80100020
               OTHER=NUMERIC                                            80190020
INCRMENT IKJIDENT   'INCREMENT',ASIS,MAXLNTH=8,FIRST=NUMERIC,          C80280020
               OTHER=NUMERIC                                            80370020
OLDLINUM IKJIDENT 'LINE NUMBER',ASIS,MAXLNTH=8,FIRST=NUMERIC,          C80460020
               OTHER=NUMERIC                                            80550020
         IKJENDP                                                        80640020
 SPACE                                                                  80730020
 EJECT                                                                  80820020
         IKJEBECA                                                       80910020
         EJECT                                                          80950020
 SPACE                                                                  81000020
*********************************************************************** 81090020
* STRUCTURE OF SUBCOMMAND WORKAREA AS USED BY IKJEBERE                * 81180020
*********************************************************************** 81270020
 SPACE                                                                  81360020
         ORG   CASCWKA                 BEGNG OF WORKAREA                81450020
RESRPLST DS    5F                      SERVICE RTN PARM LISTT           81540020
 SPACE                                                                  81630020
REUTPLST DS    0F                      IKJEBEUT PARM LIST               81720020
REDCB@   DS    F                       PT TO UTILITY DCB                81810020
REKEY@   DS    F                       PT TO 4-BYTE BINARY KEY          81900020
REBFR@   DS    F                       PT TO BUFFER                     81990020
REUTKEY  DS    F                       KEY                              82080020
 SPACE                                                                  82170020
         ORG   CASCWKA                 BEGNG OF WORKAREA                82260020
RE10AREA DS    10F                     MSG SELECTION PARM LIST          82350020
LEVEL1   EQU   RE10AREA                BEGINNING OF MSG PARMLIST        82360020
L1INPT   EQU   LEVEL1+4                PTR TO LEV1 INSERT1 PLIST        82370020
L2INPT   EQU   LEVEL1+8                PTR TO LEV2 INSERT1 PLIST        82380020
IN1      EQU   LEVEL1+12               BEGINNING OF LEV1 INSERT1 PLIST  82390020
IN1INS   EQU   IN1+8                   INSERTION1                       82400020
IN2      EQU   IN1INS+8                BEGINNING OF LEV2 INSERT1 PLIST  82410020
IN2INS   EQU   IN2+8                   INSERTION2                       82420020
 SPACE                                                                  82440020
M507INS  DS    F                       MSG INSERTION                    82530020
         DS    F                       LNG & OFFSET                     82620020
PATTERN1 DS    10C                     PATTERN FLD FOR 'EDMK'           82710020
         DS    2C                      FILLER                           82800020
M507INS2 DS    F                       MSG INSERTION                    82890020
         DS    F                       LNG & OFFSET                     82980020
PATTERN2 DS    F                       PATTRN FLD FOR 'EDMK'            83070020
 SPACE                                                                  83160020
         ORG   CASCWKA+40              ALIGNMENT                        83250020
REDSNINS DS    18F                     DATA SET NAME MSG INSERTION      83340020
 SPACE                                                                  83430020
         ORG   CASCWKA+172             ALIGNMENT                        83520020
REKODE   DS    F                       RETURN CODE SAVE AREA            83610020
 SPACE                                                                  83700020
REDCB    DS    F                       PT TO NEW UTILITY DCB            83790020
REMYFLAG DS    X                       INTERNAL SWITCHES                83880020
NOLINE   EQU   X'01'                   ON-EMPTY DATA SET/OFF-NOT A42941 83930021
ORIGNUM  EQU   X'04'                   ON-DS ORIG NUMBERED/OFF-NOT      83970020
ISSTRUNK EQU   X'80'                   ON-ISSUE 'TRUNCATED' MSG         84060020
         DS    3X                      FILLER                           84150020
RE1STLIN DS    F                       STARTING LINE NO.                84240020
REOLDKEY DS    F                       KEY FROM LAST RECORD READ        84330020
RELINLIN DS    F                       LAST INPUT LINE NUMBER           84420020
RECURLIN DS    F                       CURRENT LINE REFERENCE           84510020
 SPACE                                                                  84600020
         ORG   CASCWKA+120             ALIGNMENT                        84690020
XKINTFAC DS    F                       INTERFACE WITH SYNTAX CHECKER    84780020
XKOL     DS    F                       OLD-LINENUM                      84870020
XKNU     DS    F                       NEW-LINENUM                      84960020
XKINK    DS    F                       INCREMENT                        85050020
BASICLST DS    0F                      PARM LIST FOR 'BASIC' RENUM      85140020
BASICCOM DS    A                       PT EDIT'S COMM AREA              85230020
BASICVAL DS    A                       PT TO VALUES                     85320020
         ORG   CASCWKA+256             ALIGNMENT IKJEBRE1 WKAREA A45155 85321021
RE1MSLST DS    0F                      MESSAGE PARAMETER LIST    A45155 85322021
RE1LEV1  DS    H                       RELATIVE MESSAGE NUMBER   A45155 85323021
*                                      FOR LEVEL-1 MESSAGE       A45155 85324021
RE1LEV2  DS    H                       RELATIVE MESSAGE NUMBER   A45155 85325021
*                                      FOR LEVEL-2 MESSAGE       A45155 85326021
RE1INSL1 DS    A                       PTR TO FIRST-LEVEL        A45155 85327021
*                                      INSERTION CHAIN           A45155 85328021
RE1INSL2 DS    A                       PTR TO SECOND-LEVEL       A45155 85329021
*                                      INSERTION CHAIN           A45155 85330021
         SPACE                                                          85331021
RE1INS1  DS    0F                      FIRST GENERAL AREA FOR    A45155 85332021
*                                      INSERTION LISTS           A45155 85333021
RE1PTR1  DS    A                       PTR TO NEXT INSERTION     A45155 85334021
RE1LEN1  DS    H                       LENGTH OF INSERTION       A45155 85335021
RE1OFF1  DS    H                       OFFSET OF INSERTION       A45155 85336021
RE1TEXT1 DS    8C                      TEXT OF INSERTION         A45155 85337021
         SPACE                                                          85338021
RE1INS2  DS    0F                      SECOND GENERAL AREA       A45155 85339021
*                                      FOR INSERTION LIST        A45155 85340021
RE1PTR2  DS    A                       PTR TO NEXT INSERTION            85341021
RE1LEN2  DS    H                       LENGTH OF INSERTION       A45155 85342021
RE1OFF2  DS    H                       OFFSET OF INSERTION       A45155 85343021
RE1TEXT2 DS    8C                      TEXT OF INSERTION         A45155 85344021
         SPACE                                                          85345021
RE1DWORD DS    D                       DOUBLE WORD FOR CVD OPS   A45155 85346021
RE1PGPB  DS    4F                      PUTGET PARM BLOCK         A45155 85347021
RE1RCODE DS    H                       RETURN CODE SAVE AREA     A45155 85348021
RE1FLAG  DS    X                       CONTROL FLAG FOR SUBRTN   A45155 85349021
RE1PGSW  EQU   X'80'                   INDICATES ERROR IN PUTGET A45155 85350021
RE1PLSW  EQU   X'40'                   INDICATES ERROR IN PUTL.  A45155 85351021
         EJECT                                                          85360020
         IKJPPL                                                         85410020
         IKJECT                        ECT MAPPING MACRO         A45155 85420021
         EJECT                                                          85423021
         IKJPGPB                       PUTGET PARM BLOCK         A45155 85426021
         IKJUPT                        UPT MAPPING MACRO         A45155 85430021
         EJECT                                                          85450020
IKJEBERE CSECT                         RESUME 'RENUMBER' CTRL SECT      85500020
 EJECT                                                                  85590020
*********************************************************************** 85680020
*                             EQUATES                                 * 85770020
*********************************************************************** 85860020
 SPACE                                                                  85950020
* REGISTERS -                                                           86040020
 SPACE                                                                  86130020
PARMREG0 EQU   0                       PARAMETER REGISTER               86220020
PARMREG1 EQU   1                       PARAMETER REGISTER               86400020
WR1      EQU   1                       WORKING REGISTER          A45155 86410021
WR2      EQU   2                       WORKING REGISTER          A45155 86420021
ZEROREG  EQU   3                       REGISTER TO CONTAIN       A45155 86430021
*                                      ZEROES FOR MSG FORMAT     A45155 86440021
LINOLENG EQU   5                       LENGTH OF SEQUENCE FIELD         86490020
LINO     EQU   6                       'NEW-LINENUM'                    86580020
INCR     EQU   7                       'INCREMENT'                      86670020
OLDLINO  EQU   8                       'OLD-LINENUM'                    86760020
BEGNG    EQU   8                       PTR TO LEFT DATA BYTE            86850020
COMMREG  EQU   9                       EDIT COMM AREA BASE REG          86940020
PDLBASE  EQU   10                      PARM DESCRIPTOR LIST BASE REG    87030020
BASEREG  EQU   11                      GENERAL BASE REGISTER            87120020
DATAREG  EQU   12                      NOT USED                         87210020
WR       EQU   12                      WORKING REGISTER                 87300020
SAVEREG  EQU   13                      SAVE AREA ADDRESS                87390020
RETREG   EQU   14                      RETURN POINT ADDRESS             87480020
RETCDREG EQU   15                      RETURN CODE                      87570020
CALDRTN@ EQU   15                      ADDRESS OF CALLED ROUTINE        87660020
OVERFLOW EQU   15                      LENGTH OF OVERFLOW RECORD        87750020
 SPACE                                                                  87840020
* CONSTANTS -                                                           87930020
 SPACE                                                                  88020020
O        EQU   0                       ZERO                             88110020
BYTE     EQU   1                       LENGTH ONE                       88200020
HAFWD    EQU   2                       LENGTH OF HALF WORD              88290020
WD       EQU   4                       LENGTH OF FULL WORD              88380020
DUBLWD   EQU   8                       LENGTH OF DOUBLE WORD            88470020
HAFREG   EQU   16                      LENGTH OF SHIFT                  88560020
C2       EQU   2                       CONSTANT OF 2             A45155 88562021
L1       EQU   1                       LENGTH OF 1               A45155 88568021
L2       EQU   2                       LENGTH OF 2               A45155 88576021
L3       EQU   3                       LENGTH OF 3               A45155 88584021
L4       EQU   4                       LENGTH OF 4               A45155 88592021
L5       EQU   5                       LENGTH OF 5               A45155 88596021
L12      EQU   12                      LENGTH OF 12              A45155 88598021
L14      EQU   14                      LENGTH OF 14              A45155 88598621
L15      EQU   15                      LENGTH OF 15              A45155 88599221
L16      EQU   16                      LENGTH OF 16              A45155 88600021
D0       EQU   0                       DISPLACEMENT OF 0         A45155 88608021
D1       EQU   1                       DISPLACEMENT OF 1         A45155 88616021
D2       EQU   2                       DISPLACEMENT OF 2         A45155 88620021
D6       EQU   6                       DISPLACEMENT OF 6         A45155 88624021
D7       EQU   7                       DISPLACEMENT OF 7         A45155 88632021
D8       EQU   8                       DISPLACEMENT OF 8         A45155 88640021
RE1RC4   EQU   X'04'                   RETURN CODE 4 INDIC.      A45155 88642021
RE1RC8   EQU   X'08'                   RETURN CODE 8 INDIC.      A45155 88644021
RE1CZERO EQU   C'0'                    CHARACTER ZERO            A45155 88646021
SP1      EQU   1                       INDICATION FOR SUBPOOL 1  A45155 88648021
DEFLINUM EQU   10                      DEFAULT NEW-LINENUM              88650020
DATALNG  EQU   251                     MAX DATA LENGTH                  88740020
ZERO     EQU   C'0'                    ZERO                             88830020
BLNK     EQU   C' '                    BLANK                            88920020
REFLAG   EQU   X'80'                   FLAG FOR END OF PARM LIST        89010020
OPRNDLNG EQU   4                       OFFSET IN PDL FOR LNG            89100020
OPRNDEX  EQU   6                       OFFSET IN PDL FOR OPERAND        89190020
RENOSW   EQU   X'10'                   SWITCH TO IND RENUM              89280020
XKMSGL   EQU   72                      LNG OF SYN CHKR ERROR MSGS       89370020
 SPACE                                                                  89460020
* IKJEBEUT OPTION CODES -                                               89550020
READ1ST  EQU   X'04'                   READ 1ST RCD OF DATA SET         89640020
READPREV EQU   X'01'                   READ PREVIOUS                    89730020
READNEXT EQU   X'02'                   READ CURRENT                     89820020
WRITERCD EQU   X'20'                   WRITE BY KEY                     89910020
READWKEY EQU   X'00'                   READ CURRENT                     90000020
 SPACE                                                                  90090020
* STRUCTURE OF BUFFER AREAS (IN EDIT COMMUNICATION AREA) -              90180020
 SPACE                                                                  90270020
REINAREA EQU   CABFRPL                                                  90360020
REKEY    EQU   REINAREA                                                 90450020
RELL     EQU   REINAREA+4                                               90540020
REDATA   EQU   REINAREA+8                                               90630020
RETEMP   EQU   CABFRPL+264                                              90720020
REOFLO   EQU   CABFRPL+264                                              90810020
REKEY2   EQU   REOFLO                                                   90900020
RELL2    EQU   REOFLO+4                                                 90990020
REDATA2  EQU   REOFLO+8                                                 91080020
 SPACE                                                                  91170020
* MESSAGE NUMBERS AND OFFSETS -                                         91260020
 SPACE                                                                  91350020
         IKJEBEMI (0,312,313,501,502,503,504,507,560,569)        A45155 91440021
PATTERNL EQU   10                      LNG OF 'EDMK' PATTERN FIELD      91530020
         END   IKJEBERE                                                 91620020
