         TITLE 'TSO EDIT COMMAND  RENUMBER BASIC  IKJEBERN'             00150020
IKJEBERN CSECT                                                          00200020
*C 466000,541000                                                 A45103 00250021
*A 222183-222189,222261-222279,223576-223590,427010-427800       A50491 00260021
*  C 505000                                                     SA68905 00260121
*A 433010-446600,620946-620958                                   A50491 00270021
*  A 505060-505420                                              SA68905 00270121
*C 222259,222327,427000                                          A50491 00280021
*D 222263-222273,431000-447000                                   A50491 00290021
*A 121500-121600                                                  M5144 00300021
*********************************************************************** 00500020
* STATUS- VERSION NO. 01, OS/360 RELEASE NO. 20                       * 00600020
*                                                                     * 00700020
* FUNCTION- THIS MODULE PROVIDES FOR THE RENUMBERING OF A BASIC DATA  * 00750020
*    SET. IT IS CALLED BY THE EDIT RENUMBER SUBCOMMAND, IKJEBERE, TO  * 00800020
*    RENUMBER THE BASIC SOURCE AND SEQUENCE FIELDS.                   * 00850020
*                                                                     * 01000020
* ENTRY POINTS- IKJEBERN, THE MAIN AND ONLY ENTRY POINT.              * 01100020
*                                                                     * 01300020
* INPUT- REGISTER 1 POINTS TO A TWO-WORD PARAMETER LIST AS FOLLOWS-   * 01400020
*    WORD ONE - POINTER TO THE EDIT COMMUNICATION AREA.               * 01500020
*    WORD TWO - POINTER TO THE RENUMBER PARAMETERS-                   * 01600020
*    1  OLD LINE NUMBER                                               * 01610020
*    2  NEW LINE NUMBER                                               * 01620020
*    3  INCREMENT FOR RENUMBERING                                     * 01650020
*                                                                     * 02000020
* OUTPUT- A RETURN CODE IS PASSED IN REGISTER 15. THREE RETURN CODES  * 02100020
*    ARE POSSIBLE.                                                    * 02150020
*    0 - SUCCESSFUL COMPLETION                                        * 02200020
*    4 - UNSUCCESSFUL COMPLETION                                      * 02300020
*    8 - I/O ERROR ON THE UTILITY DATA SET                            * 02310020
*                                                                     * 02350020
* EXTERNAL REFERENCES-                                                * 02400020
*         IKJEBEUT - READS THE UTILITY DATA SET                       * 02500020
*         IKJEBEMS - SENDS MESSAGES TO THE TERMINAL USER              * 02550020
*   MACROS USED-                                                      * 02560020
*         IKJEBESV - STANDARD ENTRY LINKAGE                           * 02570020
*         IKJEBERT - STANDARD EXIT LINKAGE                            * 02580020
*         IKJEBEML - STANDARD MESSAGE PARAMETER LIST                  * 02590020
*         IKJEBEMG - STANDARD MESSAGE INSERTION PARAMETER LIST        * 02592020
*         IKJEBECA - COMMUNICATION AREA DSECT MAPPING MACRO           * 02594020
*                                                                     * 02596020
* EXITS, NORMAL- TO IKJEBERE WITH RETURN CODE IN REGISTER 15          * 02600020
*                                                                     * 02650020
* EXITS, ERROR- TO IKJEBERE WITH RETURN CODE IN REGISTER 15           * 02700020
*                                                                     * 02800020
* TABLES/WORK AREAS- THE EDIT COMMUNICATION AREA IS USED FOR WORK     * 03900020
*    SPACE.                                                           * 04100020
*                                                                     * 04150020
* ATTRIBUTES- REFRESHABLE, ENABLED, NON-PRIVILEGED                    * 04200020
*                                                                     * 04300020
* CHARACTER CODE DEPENDENCY- THIS MODULE IS DEPENDENT ON THE NUMBERS  * 04400020
*    1-9 BEING REPRESENTED BY CONSECUTIVE BIT REPRESENTATIONS         * 04450020
*                                                                     * 04500020
* NOTES- REGISTER USAGE                                               * 05500020
*    PARMREG0      0                   USED BY MACROS                 * 05550020
*    PARMREG1      1                   USED BY MACROS                 * 05560020
*    REG1          1                   PTR TO PARAMETERS              * 05570020
*    RWORK         2                   WORK REGISTER                  * 05580020
*    RCOUNT        3                   USED FOR SQUEEZE               * 05590020
*    RLGTH         3                   CONVERTING/STORE NUMBER        * 05592020
*    RTBL          4                   OLD/NEW TBL PTR                * 05594020
*    RSRC          5                   PTR TO SOURCE READ IN          * 05596020
*    RINCR         5                   INCREMENT                      * 05598020
*    RBUFF         6                   PTR TO WORK BUFFER             * 05600020
*    RLASTNO       6                   LAST NUMBER USED               * 05700020
*    RNUM          7                   OLD LINE NUMBER (PARAMETER)    * 05800020
*    RTRNM         8                   LINK REG                       * 05900020
*    COMMREG       9                   PTR TO COMM REGION             * 06000020
*    BASEREG       11                  BASE                           * 06100020
*    RETREG        14                  RETURN REG                     * 06200020
*    RETCDREG      15                  BRANCH/RETURN CODES            * 06300020
*    RCODE         15                  CODES                          * 06400020
*                                                                     * 06450020
*    STANDARD LINKAGE CONVENTIONS ARE USED.                           * 06452020
*                                                                     * 06454020
*********************************************************************** 06460020
         EJECT                                                          06470020
         IKJEBESV   (14,12),,*,COMMREG=0(1)                             06500020
         SPACE                                                          06550020
         USING IKJEBECA,COMMREG        ESTABLISH ADDRESSABILITY         06600020
         L     RWORK,FOUR(REG1)        PTR TO PARMS                     06700020
         MVC   OLDNUMB(TWELVE),O(RWORK)  MOVE PARAMS                    06750020
         XC    ADDKEY(FOUR),ADDKEY     ZERO FIRST ADDRESS               06900020
         XC    RTNCODE(TWO),RTNCODE    INIT RETURN CODE                 07000020
         NI    ERRBITS,FLGOF           TURN OFF ALL ERROR FLAGS         07100020
         L     RNUM,OLDNUMB            NUMBER TO SRCH FOR               07300020
         XC    TABNO(SIX),TABNO        TBLS USED, TBLS, SCAN NUM        07400020
         MVC   READCB(FOUR),CAPTCDCB   PTR TO DATA SET                  07500020
         MVC   RDPARMS(FOUR),READCB    PTR TO DATA SET                  07600020
         MVC   MINSIZ(EIGHT),MININUM   INIT SIZE FOR GETMAIN            07700020
         MVI   RDPARMS,READWKEY        SEARCH FOR OLD NUMBER            07800020
         LA    RWORK,RDKEY                                              07900020
         ST    RWORK,RDKEYPTR          STORE PTR TO KEY                 08000020
         ST    RNUM,RDKEY              STORE OLD LINE NO                08100020
         BAL   RTRNM,READ              READ IN RECORD                   08200020
         LTR   RCODE,RCODE             TAKE CORRECT ACTION              08300020
         BNZ   NOTFOUND                4 (NOT FOUND)                    08400020
         MVI   RDPARMS,READPREV        KEY-READ PREVIOUS RECORD         08600020
         BAL   RTRNM,READ              READ IN RECORD                   08700020
         LTR   RCODE,RCODE             TAKE CORRECT ACTION              08800020
         BNZ   TBLBLD                  4(NOT FOUND) -IMPOSSIBLE         08900020
         CLC   KEY(FOUR),STLINENO      KEY OF PREVIOUS RECORD GTR THAN  09200020
*                                      STARTING NUMBER                  09250020
         BNL   NOTCOMPT                NO-ERROR                         09300020
TBLBLD   EQU   *                                                        09400020
*                                                                       09500020
*        BUILD RENUMBER TABLE                                           09600020
*        OLD LINE NUMBER               4 BYTES BINARY NUMBER            09700020
*        NEW LINE NUMBER               4 BYTES BINARY NUMBER            09800020
*                                                                       09900020
         BAL   RTRNM,GETTABLE          ALLOCATE FIRST TBL               10000020
         L     RINCR,INCR                                               10100020
         L     RLASTNO,STLINENO        START                            10200020
         SR    RLASTNO,RINCR           SUB INCREMENT                    10300020
         MVI   RDPARMS,READFST         READ FIRST RECORD                10400020
         XC    RDKEYPTR(FOUR),RDKEYPTR  ZERO-NO KEY                     10500020
BUILDTBL EQU   *                                                        10600020
         BAL   RTRNM,READ              READ IN RECORD                   10700020
         LTR   RCODE,RCODE             TAKE CORRECT ACTION              10800020
         BNZ   SEEEND                  4(NOT FOUND)                     10900020
         LA    RWORK,EIGHT(RTBL)       ROOM FOR ENTRY IN TABLE          11100020
         C     RWORK,TBLEND                                             11200020
         BNH   ROOM                    YES                              11300020
         BAL   RTRNM,GETTABLE          NO-GET NEXT TABLE AREA           11400020
ROOM     EQU   *                                                        11500020
         L     RWORK,KEY                                                11600020
         ST    RWORK,O(RTBL)           STORE OLD LINE NUM               11700020
         CR    RNUM,RWORK              OLD LINE NO. LESS THAN KEY       11800020
         BNH   NEWNUM                  NO-CHANGE LINE NO.               11900020
         ST    RWORK,FOUR(RTBL)        NEW=OLD                          12000020
UPTBL    EQU   *                                                        12100020
         TM    CACFLAG3,CAIMINPT       INPUT LINES ENTERED        M5144 12150021
         BNO   UPTBL2                  NO                         M5144 12160021
         C     RWORK,CAIMLLNO          MATCH                            12200020
         BNE   UPTBL2                  NO                               12300020
         MVC   BAIMLLNO(FOUR),FOUR(RTBL)  SAVE FOR RETURN               12400020
UPTBL2   EQU   *                                                        12500020
         C     RWORK,CACURNUM          MATCH                            12600020
         BNE   UPTBL3                  NO                               12700020
         MVC   BACURNUM(FOUR),FOUR(RTBL)  SAVE FOR RETURN               12800020
UPTBL3   EQU   *                                                        12900020
         LA    RTBL,EIGHT(RTBL)        UPDATE PTR                       13000020
         MVI   RDPARMS,READNEXT        READ NEXT RECORD                 13100020
         LA    RWORK,RDKEY                                              13200020
         ST    RWORK,RDKEYPTR          STORE PTR TO KEY IN PARM LIST    13300020
         MVC   RDKEY(FOUR),KEY         STORE OLD KEY                    13400020
         B     BUILDTBL                BUILDTBL                         13500020
NEWNUM   EQU   *                                                        13600020
         AR    RLASTNO,RINCR           NEW=LAST + INCREMENT             13700020
         ST    RLASTNO,FOUR(RTBL)      STORE NEW LINE NO. IN TBL        13800020
         B     UPTBL                   CONTINUE                         13900020
SEEEND   EQU   *                                                        14000020
         ST    RTBL,TBLEND2            NO-STORE TBL END                 14100020
         ST    RLASTNO,NEWLAST         SAVE NEW LAST NUMBER             14200020
         ST    RINCR,NEWINCR           SAVE NEW INCREMENT               14300020
         MVI   RDPARMS,READFST         READ FIRST RECORD                15000020
         XC    RDKEYPTR(FOUR),RDKEYPTR  ZERO KEY                        15100020
RENUM    EQU   *                                                        15200020
         BAL   RTRNM,READ              READ IN RECORD                   15300020
         LTR   RCODE,RCODE             TAKE CORRECT ACTION              15400020
         BNZ   FINRENUM                4 NOT FOUND-DONE                 15500020
         MVC   LASTNUMB(FOUR),KEY      SAVE KEY OF RECORD READ          15700020
         LA    RSRC,DATA               PTR TO SOURCE                    15800020
         LA    RBUFF,DATA2             PTR TO BUFFER                    15900020
         LH    RCOUNT,LL               LENGTH RECORD                    16000020
         SH    RCOUNT,THIRTENN         MINUS LENGTH,NUMBER,+1           16100020
         TM    CACFLAG2,CARECFM        VARIABLE RECORD                  16200020
         BO    SEESQU2                 NO-FIXED                         16300020
         LA    RSRC,EIGHT(RSRC)        YES-UPDATE PTR TO DATA           16400020
         LA    RBUFF,EIGHT(RBUFF)      UPDATE PTR IN BUFFER             16500020
SEESQU2  EQU   *                                                        16600020
         ST    RBUFF,STSRC             SAVE START OF SOURCE(NEW)        16700020
         ST    RSRC,STSRCOLD           SAVE START OF SOURCE(OLD)        16800020
         MVI   O(RBUFF),BLNK           MOVE IN BLANK                    16900020
         EX    RCOUNT,BLANKM           PROPAGATE BLANKS                 17000020
         LA    RCOUNT,ONE(RCOUNT)      CORRECT LENGTH OF DATA           17100020
         LA    RWORK,O(RCOUNT,RBUFF)   PTR TO END OF DATA               17200020
         ST    RWORK,ENDSRC                                             17300020
SQU      EQU   *                                                        17400020
         CLI   O(RSRC),BLNK            BLANK                            17500020
         BE    SQU32                   YES-OMIT                         17600020
         MVC   O(ONE,RBUFF),O(RSRC)    NO STORE                         17700020
         CLI   O(RSRC),QUOTC           QUOTE                            17800020
         BE    QUOTE                   YES                              17900020
         CLI   O(RSRC),DQUTC           DOUBLE QUOTE                     18000020
         BE    QUOTE                   YES                              18100020
SQU2     EQU   *                                                        18200020
         LA    RBUFF,ONE(RBUFF)        UPDATE PTRS                      18300020
SQU32    EQU   *                                                        18400020
         LA    RSRC,ONE(RSRC)                                           18500020
         BCT   RCOUNT,SQU              LOOP                             18600020
FINSQU   EQU   *                                                        18700020
         MVI   GOTOBIT,FLGOF           TURN OFF GO TO STATEMENT FLAG    18800020
         L     RBUFF,STSRC             RELOAD PTR TO START OF SOURCE    18900020
         CLC   O(FOUR,RBUFF),CGOTO     IS IT GOTO                       19000020
         BE    GOTO                    YES-CHANGE LINE NO.              19100020
         CLC   O(TWO,RBUFF),CIF        IS IT IF                         19200020
         BE    IF                      YES-CHANGE LINE NO.              19300020
         CLC   O(FIVE,RBUFF),CGOSUB    IS IT GOSUB                      19400020
         BE    GOSUB                   YES-CHANGE LINE NO.              19500020
         CLC   O(TEN,RBUFF),CPRUS      IS IT PRINTUSING                 19600020
         BE    PRU                     YES-CHANGE LINE NO.              19700020
         CLC   O(THIRTEEN,RBUFF),CMPRUS IS IT MATPRINTUSING             19800020
         BE    MATPRU                  YES-CHANGE LINE NO.              19900020
         EJECT                                                          19950020
*  THE RECORD, COMPRESSED IN SOME CASES, IS CHANGED BACK                20000020
*  TO ITS ORIGINAL FORMAT AND WRITTEN OUT                               20050020
STOREKEY EQU   *                                                        20400020
         MVC   KEY(FOUR),LASTNUMB      LAST KEY                         20450020
         MVC   KEY2(FOUR),LASTNUMB     LAST KEY                         20500020
         LA    RSRC,KEY                OLD KEY                          20800020
         ST    RSRC,RDKEYPTR           PTR TO KEY                       20850020
         MVC   RDPARMS(FOUR),READCB    PTR TO UTILITY DATA SET          20900020
         MVI   RDPARMS,READWKEY        READ KEY                         21000020
         XC    READPTR,READPTR         LOCATE MODE                      21100020
         MVI   RDKEYPTR,ENDFLAG        FLAG END                         21200020
         IKJEBESH  (COMMREG),IKJEBEUT,PARAM=((COMMREG),RDPARMS),       X21300020
               MF=(E,RPLIST)                                            21400020
         B     WRITE1(RCODE)           TAKE CORRECT ACTION              21500020
WRITE1   EQU   *                                                        21600020
         B     NEXTRNUM                0  GOOD                          21700020
         B     ERROR                   4  ERROR                         21800020
         B     IOERR                   8  I/O ERROR                     21900020
         B     NETHNGLZ                12 INVALID LINE NO               22000020
NEXTRNUM EQU   *                                                        22100020
         BAL   RTRNM,GETADDR           GET NEXT LINE NUMBER             22100420
         L     WRA,ADDKEY              GET KEY                          22100820
         MVC   KEY2(FOUR),FOUR(WRA)    REPLACE KEY WITH NEW KEY         22101220
         MVC   KEY(FOUR),FOUR(WRA)     MOVE NEW KEY INTO NEW RCD        22101620
         MVC   LL2(FOUR),LL            MOVE LENGTH                      22102020
         MVI   DATA2,BLANK             BLANK OUT FIRST BYTE OF BFR      22104020
         MVC   DATA2+L1(T55),DATA2     BLANK BUFFER                     22110020
         LR    WRB,PARMREG1            PTR TO OLD RCD                   22112020
         BAL   RETREG,POINDATA         GET PTR TO BEG AND END           22120020
         LR    OLD,DATPTR              PTR TO BEG OF OLD RCD            22122020
         ST    ENDPTR,EOLD             SAVE PTR TO EOD                  22124020
         LA    WRB,KEY                 PTR TO NEW RCD                   22126020
         BAL   RETREG,POINDATA         GET PTRS TO BEG AND END OF DATA  22128020
         LR    NEW,DATPTR              PTR TO BEG OF NEW RCD            22128420
         ST    ENDPTR,ENEW             SAVE END PTR                     22128820
         LA    WRB,KEY2                PTR TO RCD TO BE BUILT           22137020
         BAL   RETREG,POINDATA         GET PTR TO BEG AND END           22140520
COMPX    EQU   *                                                        22144020
         C     NEW,ENEW                END OF DATA                      22144120
         BNL   EXOUT                   IF DONE, GO TO EXIT RTN          22144220
         C     OLD,EOLD                END OF DATA                      22144420
         BNL   EXOUT                   IF SO, EXIT                      22144820
         CLI   O(NEW),ZERO             BYTE LT ZERO                     22145220
         BL    NOTNUM                  IF SO, BRANCH                    22145620
         CLI   O(NEW),NINE             BYTE GT NINE                     22145720
         BH    NOTNUM                  IF SO, BRANCH                    22145820
         CLI   O(OLD),ZERO             BYTE LT ZERO                     22145920
         BL    NOTNUM                  IF SO, BRANCH                    22147720
         CLI   O(OLD),NINE             BYTE GT NINE                     22147820
         BNH   MOVNXTNM                IF NOT, BRANCH                   22150320
NOTNUM   EQU   *                                                        22152420
         CLC   O(L1,NEW),O(OLD)        COMPARE BYTES                    22155620
         BNE   NOCOMPX                 IF NOT EQUAL, BRANCH             22157720
         CLI   O(OLD),QUOTC            IS CHARACTER A QUOTE             22159720
         BE    QPRCX                   IF SO, PROCESS SEPARATELY        22164720
         CLI   O(OLD),DQUTC            IS CHARACTER A DOUBLE QUOTE      22165120
         BE    QPRCX                   IF SO, PROCESS SEPARATELY        22165520
ENQTX    EQU   *                       ENTRY FROM STRING PROC RTN       22165920
         MVC   O(L1,DATPTR),O(OLD)     MOVE TO NEW RCD                  22170720
         LA    NEW,L1(NEW)             INCREMENT PTR                    22175720
         LA    OLD,L1(OLD)             INCREMENT PTR                    22180720
         LA    DATPTR,L1(DATPTR)       INCREMENT PTR                    22185720
INCFAKE  EQU   *                                                        22190720
         C     NEW,ENEW                END OF DATA                      22195720
         BNL   ENDNEW                  IF SO BRANCH                     22200720
         C     OLD,EOLD                END OF OLD DATA                  22205720
         BNL   ENDOLD                  IF SO BRANCH                     22210720
         B     COMPX                   CONTINUE COMPARES                22215720
QPRCX    EQU   *                       PROCESS QUOTED STRINGS           22217720
         MVC   DELIM,O(OLD)            SAVE TYPE OF QUOTE        A50491 22218321
QPRCX2   EQU   *                                                 A50491 22218921
         MVC   O(L1,DATPTR),O(OLD)     MOVE TO NEW RECORD               22219720
         LA    OLD,L1(OLD)             INCREMENT OLD PTR                22220120
         LA    NEW,L1(NEW)             INCREMENT NEW PTR                22220520
         LA    DATPTR,L1(DATPTR)       INCREMENT DATA PTR               22220620
         C     OLD,EOLD                END OF DATA                      22223920
         BNL   TESTNETH                IF SO, TEST IF UNBALANCED A50491 22225921
*                                        QUOTES ALLOWED          A50491 22226121
         C     NEW,ENEW                END OF DATA               A50491 22226221
         BNL   TESTNETH                IF SO, TEST IF UNBALANCED A50491 22227121
*                                        QUOTES ALLOWED          A50491 22227521
         CLC   DELIM,O(OLD)            TEST FOR END QUOTE        A50491 22227921
         BE    ENQTX                   IF SO, RETURN TO MAIN CODE       22230620
         B     QPRCX2                  IF NOT, CONTINUE SCAN     A50491 22232721
NOCOMPX  EQU   *                       BYTES DID NOT COMPARE            22234120
         CLI   O(OLD),BLANK            IS OLD BYTE A BLANK              22237420
         BNE   INCNEWQ                 IF NOT, BRANCH                   22240720
         MVI   O(DATPTR),BLANK         MOVE BLANK INTO BFR              22242720
         LA    DATPTR,L1(DATPTR)       INCREMENT PTR                    22244720
         LA    OLD,L1(OLD)             INCREMENT PTR                    22246720
         B     INCFAKE                 CONTINUE                         22247120
INCNEWQ  EQU   *                                                        22255920
         CLI   O(NEW),BLANK            IS NEW BYTE A BLANK              22257920
         BNE   QUERCHAR                IF NOT, BRANCH                   22259920
         LA    NEW,L1(NEW)             INCREMENT PTR                    22261920
         B     INCFAKE                 CONTINUE                         22263920
QUERCHAR EQU   *                                                        22264320
         B     NETHNGLZ                ERROR                            22275620
CKA      EQU   *                                                        22276020
         CLI   0(NEW),ZERO             BYTE A DIGIT                     22276420
         BL    NETHNGLZ                IF NOT, BRANCH                   22276820
         CLI   O(NEW),NINE             BYTE A DIGIT                     22277220
         BH    NETHNGLZ                IF NOT, BRANCH                   22277320
MOVNXTNM EQU   *                                                        22277620
         MVC   O(L1,DATPTR),O(NEW)     MOVE DIGIT                       22279620
         LA    DATPTR,L1(DATPTR)       INCREMENT PTR                    22281620
         LA    NEW,L1(NEW)             INCREMENT NEW PTR                22282020
         C     NEW,ENEW                END OF DATA                      22282120
         BNL   ENDNEW                  IF SO EXIT                       22282220
         CLI   O(NEW),ZERO             IS NEW BYTE LT ZERO              22282320
         BL    ENDNEWNM                IF SO, END OF DIGITS             22292320
         CLI   O(NEW),NINE             IS BYTE GT NINE                  22315820
         BH    ENDNEWNM                IF SO, END OF DIGITS             22325820
         B     MOVNXTNM                CONTINUE SCAN                    22327820
ENDNEWNM EQU   *                                                        22328220
INCOLRNO EQU   *                                                        22328620
         LA    OLD,L1(OLD)                                              22329020
         C     OLD,EOLD                END OF DATA                      22329420
         BNL   ENDOLD                  IF SO, BRANCH                    22337220
         CLI   O(OLD),BLANK            BLANK CHAR                       22339220
         BE    INCOLRNO                IF SO, CONTINUE                  22341220
         CLI   O(OLD),ZERO             IS BYTE LT ZERO                  22343220
         BL    ENDLDNM                 IF SO, END OF DIGITS             22343620
         CLI   O(OLD),NINE             IS BYTE GT NINE                  22344020
         BH    ENDLDNM                 IF SO, END OF DIGITS             22344420
         B     ENDNEWNM                CONTINUE SCAN                    22344820
ENDLDNM  EQU   *                                                        22344920
         BCTR  OLD,PARMREG0            LOOK AT PREVIOUS BYTE            22347720
         CLI   O(OLD),BLANK            WAS IT A BLANK                   22349720
         BNE   RESOLD                  IF NOT, BRANCH AROUND            22350120
         MVI   O(DATPTR),BLANK         ADD BLANK TO RCD                 22350520
         LA    DATPTR,L1(DATPTR)       INCREMENT PTR                    22353320
RESOLD   LA    OLD,L1(OLD)             RESET OLD PTR                    22353420
         B     INCFAKE                 CONTINUE SCAN                    22356920
TESTNETH EQU    *                                                A50491 22357621
         BAL   RTRNM,TESTUNBQ          TEST IF UNBALANCED QUOTES A50491 22358321
*                                      ALLOWED; NO RETURN IF NOT A50491 22359021
WRAPUP   EQU   *                                                        22359720
ENDNEW   EQU   *                                                        22361720
EXOUT    EQU   *                                                        22362120
ENDOLD   EQU   *                                                        22362220
         TM    CACFLAG2,CARECFM        FIXED FORMAT                     22362520
         BZ    VRXX                    IF NOT, BRANCH                   22365320
         SR    WRA,WRA                 ZERO REGISTER                    22368120
         IC    WRA,CALENGTH            GET LENGTH OF LINE NUMBER        22370920
         LR    ENDPTR,DATPTR           SAVE PTR                         22372920
         AR    DATPTR,WRA              INCREMENT PTR                    22373720
         LA    WRA,LL2                 POINT TO LL PART OF RCD          22375720
         LH    WRB,O(WRA)              GET LENGTH                       22376220
         SR    DATPTR,WRA              GET LENGTH                       22376420
         CR    DATPTR,WRB              COMPARE WITH MAX                 22378820
         BNH   WRITLST                 IF OKAY, GO TO WRITE RTN         22379220
         SR    DATPTR,WRB              GET LENGTH OF OVERFLOW           22379320
         BCTR  ENDPTR,PARMREG0         INIT PTR TO LAST BYTE            22379720
LOPXC    EQU   *                                                        22381320
         CLI   O(ENDPTR),BLANK         IS BYTE A BLANK                  22381420
         BNE   OFLOMSG                 IF NOT, OVERFLOW                 22381520
         BCTR  ENDPTR,PARMREG0         DECREMENT PTR                    22381620
         BCT   DATPTR,LOPXC            LOOP TO SCANN ALL OVERFLOW       22381720
         B     WRITLST                 GO TO WRITE RTN                  22381820
VRXX     EQU   *                                                        22381920
         LA    WRA,LL2                 PTR TO LL PART                   22382020
         LH    WRB,LL2                 LENGTH                           22382120
         LR    ENDPTR,DATPTR           SAVE PTR                         22384120
         SR    DATPTR,WRA              GET NEW LENGTH                   22384520
         CH    DATPTR,CALRECL          IS IT TOO LONG                   22384920
         BH    BLNKSRCH                IF SO, MAYBE TRUNC               22385320
         STH   DATPTR,LL2              SAVE NEW LENGTH                  22385720
         B     WRITLST                 GO TO WRITE RTN                  22386120
BLNKSRCH EQU   *                                                        22386220
         LH    WRA,CALRECL             MAX LENGTH                       22386520
         SH    DATPTR,CALRECL          GET OVERFLOW                     22386920
         BCTR  ENDPTR,PARMREG0         POINT TO LAST BYTE               22387320
FNDOF    EQU   *                                                        22412920
         CLI   O(ENDPTR),BLANK         IS BYTE A BLANK                  22415720
         BNE   OFLOVX                  IF NOT, OVERFLOW                 22418520
         BCTR  ENDPTR,PARMREG0         POINT TO NEXT BYTE               22421320
         BCTR  WRA,PARMREG0            DECREMENT COUNT                  22423320
         BCT   DATPTR,FNDOF            CONTINUE SCAN                    22424120
         STH   WRA,LL2                 SAVE NEW LENGTH                  22428920
         B     WRITLST                 GO TO WRITE RTN                  22429320
OFLOVX   EQU   *                                                        22429420
         LH    WRA,CALRECL             MAX LENGTH                       22429520
         STH   WRA,LL2                 SAVE IN RECORD                   22429620
         B     OFLOMSG                 WRITE OVERFLOW MSG               22433820
WRITLST  EQU   *                                                        22438020
         MVC   RDPARMS(FOUR),REDCB     PTR TO NEW UTILITY DS DCB        22454820
         MVI   RDPARMS,WRITERCD        WRITE NEW RECORD                 22459020
         LA    RSRC,KEY2               POINT TO RECORD                  22469020
         ST    RSRC,RDKEYPTR           PTR TO RCD INTO PARMLIST         22479020
         MVI   RDKEYPTR,ENDFLAG        END OF PARMS FLAG                22479420
         IKJEBESH (COMMREG),IKJEBEUT,PARAM=((COMMREG),RDPARMS),        X22486220
               MF=(E,RPLIST)                                            22488220
         B     WRITE2(RCODE)           CHECK RETURN CODE                22490220
WRITE2   EQU   *                                                        22490620
         B     NXXTRNUM                0 NO ERROR                       22491020
         B     ERROR                   4 ERROR EXIT                     22491420
         B     IOERR                   8 I/O ERROR                      22491820
         B     NETHNGLZ                12 NUMBER TOO HIGH               22491920
NXXTRNUM EQU   *                                                        22492220
         LA    RWORK,RDKEY                                              22493220
         ST    RWORK,RDKEYPTR          STORE PTR TO KEY                 22500020
         MVC   RDPARMS(FOUR),READCB    SWITCH TO READ DCB               22550020
         MVI   RDPARMS,READNEXT        KEY FOR READ NEXT                22560020
         MVC   RDKEY(FOUR),LASTNUMB    STORE LAST LINE NO. USED         22600020
         B     RENUM                   LOOP THROUGH DATA SET            22700020
         EJECT                                                          22750020
*  THIS ROUTINE GETS A POINTER TO THE RECORD IN WRB AND RETURNS         22760020
*  A POINTER TO THE BEGINNING OF THE DATA PORTION IN DATPTR             22770020
*  AND A POINTER TO THE END OF THE DATA PORTION PLUS ONE IN ENDPTR      22780020
POINDATA EQU   *                                                        22782020
         MVC   LHALF(L2),L4(WRB)       GET                              22790020
         LH    WRC,LHALF               LENGTH                           22792020
         LA    WRB,L4(WRB)             INC BY LEN OF KEY                22794020
         AR    WRC,WRB                 POINT NEAR END                   22796020
         TM    CACFLAG1,CANONUM        IS DS NUMBERED                   22798020
         BZ    NUMBRD                  IF SO PROCESS AS SUCH            22798420
         LA    WRB,L4(WRB)             POINT TO BEG OF DATA PORTION     22798820
         B     OUTPT                   GO TO EXIT                       22799220
NUMBRD   EQU   *                                                        22799620
         SR    WRA,WRA                 ZERO REG                         22799720
         IC    WRA,CALINE              GET OFFSET OF LINE NUMBER        22799820
         LA    WRD,L1                  IS IT ONE                        22799920
         CR    WRA,WRD                 IF NUMBER IS AT END              22833220
         BNE   LCALDCD                 THEN BRANCH                      22843220
         IC    WRA,CALENGTH            GET LENGTH OF NUMBER             22853220
         AR    WRB,WRA                 INCREMENT BEG PTR BY LEN         22863220
         LA    WRB,L4(WRB)             INC TO POINT PAST LL00           22865620
         B     OUTPT                   GO TO EXIT                       22866020
LCALDCD  EQU   *                                                        22866420
         LR    WRC,WRB                 PTR TO LL00                      22866520
         AR    WRC,WRA                 ADD OFFSET OF LINE NUM           22866620
         LA    WRC,L3(WRC)             ADD LL00 LEN - 1                 22877720
         LA    WRB,L4(WRB)             INC BY LEN OF LL00               22887720
OUTPT    EQU   *                                                        22888120
         LR    DATPTR,WRB              PTR TO BEG OF DATA PORTION       22888520
         LR    ENDPTR,WRC              PTR PAST EOD OF RCD              22888620
         BR    RETREG                  RETURN TO CALLER                 22888720
GOTO     EQU   *                                                        22888920
         OI    GOTOBIT,GOTOFLAG        TURN ON GO TO FLAG               22900020
         L     RWORK,STSRC                                              23000020
         LA    RWORK,FOUR(RWORK)       PTR PAST KEYWD TO NUMBER         23100020
GOTO2    EQU   *                                                        23200020
         ST    RWORK,LINEPTR           STORE                            23300020
         BAL   RTRNM,INITBLNK          BLANK BUFFER                     23350020
         BAL   RTRNM,CHANGE            CHANGE NUMBER                    23500020
         BAL   RTRNM,STORSRC           SCAN                             23550020
         L     RWORK,LINEPTR           PTR TO NUMBER                    23600020
         AH    RWORK,SRCLGTH           PTR TO NUMBER                    23650020
         TM    GOTOBIT,GOTOFLAG        IS IT A GO TO STATEMENT          23700020
         BZ    NOGOTO                  BR NO                            23750020
         CLI   O(RWORK),COMA           IS THIS COMPUTED GOTO            23800020
         BE    COMPUTED                IF COMPUTED GOTO BRANCH          23850020
         CLC   O(TWO,RWORK),CHON       COMPUTED GOTO                    23900020
         BE    COMPUTE2                YES                              23950020
NOGOTO   EQU   *                                                        24000020
SEELGTH  EQU   *                                                        24050020
         S     RBUFF,STSRCOLD          CALC NEW LENGTH                  24100020
         LA    RWORK,TWELVE(RBUFF)     FOR NUMBER, LENGTH               24150020
         TM    CACFLAG2,CARECFM        IS IT VARIABLE                   24200020
         BO    FIXED                   IF FIXED, BRANCH                 24250020
         CH    RWORK,TWO55             IS IT TOO BIG                    24300020
         BH    NETHNGLZ                IF SO, BRANCH                    24350020
         STH   RWORK,LL                STORE NEW LGTH                   24400020
         B     STOREKEY                WRITE RCD AND CONTINUE           24450020
FIXED    EQU   *                                                        24500020
         LH    RLGTH,LL                LENGTH OF RECORD                 24550020
         CR    RWORK,RLGTH             LINE TOO BIG                     24600020
         BH    NETHNGLZ                IF SO, BRANCH                    24650020
         B     STOREKEY                WRITE RECORD AND CONTINUE        24700020
CHANGE   EQU   *                       CHANGE OLD SOURCE NUMBER         26165520
*                                                                       26174120
*        THE FOLLOWING ROUTINE CONVERTS THE EBCDIC LINE NUMBER FROM     26200020
*        THE SOURCE AND RETURNS THE UPDATED EBCDIC NUMBER FOR THE       26300020
*        CORRESPONDING NEW LINE NUMBER                                  26400020
*                                                                       26500020
         L     RWORK,LINEPTR                                            26600020
         LR    RLGTH,RWORK                                              26700020
CCHANGE  EQU   *                                                        26800020
         C     RLGTH,ENDSRC            AT END                           26900020
         BNL   FNDNUM                  YES-DONE WITH NUMBER             27000020
         CLI   O(RLGTH),C'0'           DIGIT                            27100020
         BL    FNDNUM                  BR NO                            27200020
         CLI   O(RLGTH),C'9'           DIGIT                            27300020
         BH    FNDNUM                  NO                               27400020
         LA    RLGTH,ONE(RLGTH)        INCREMENT LENGTH                 27500020
         B     CCHANGE                 BR TO CHARACTER CHANGE           27600020
FNDNUM   EQU   *                                                        27700020
         SR    RLGTH,RWORK             CALC LENGTH OLD SRCE NUMBER      27800020
         STH   RLGTH,SRCLGTH           STORE                            27900020
         LTR   RLGTH,RLGTH             VALID LINE NUMBER                28000020
         BNP   NETHNGLZ                NO-ERROR                         28100020
         CH    RLGTH,NUM8              VALID LENGTH                     28200020
         BH    NETHNGLZ                NO-ERROR                         28300020
         BCTR  RLGTH,O                 SUB 1 FOR EX                     28400020
         EX    RLGTH,PACKN             PACK ORIGINAL SOURCE NUM         28500020
         CVB   R0,DOUBLE               CONVERT TO BINARY                28600020
         XC    TABNO+L4(TWO),TABNO+L4  ZERO NUM TABLES USES             28700020
         MVI   DEFINED,FLGOF           INIT-NUMBER NOT DEFINED          28800020
BGNSCAN  EQU   *                                                        28900020
         B     SCANTBL                 GET ADDRESS OF TABLE             29000020
SCANNUM  EQU   *                                                        29100020
         C     R0,O(RTBL)              ENTRIES EQUAL                    29200020
         BE    FNDENTRY                YES                              29300020
SCANNUM2 EQU   *                                                        29400020
         LA    RTBL,EIGHT(RTBL)        UPDATE                           29500020
         C     RTBL,TBLEND             AT END                           29600020
         BL    SCANNUM                 NO-CONTINUE                      29700020
         CLC   TABNO(TWO),TABNO+L4     LAST TABLE                       29800020
         BNE   BGNSCAN                 NO-CONTINUE                      29900020
         TM    DEFINED,EIGTY           DEFINED                          30000020
         BZ    NETHNGLZ                NO-ERROR                         30100020
         L     RWORK,DOUBLE            LOAD NEW NUMBER                  30200020
         CVD   RWORK,DOUBLE                                             30300020
         UNPK  LINENUM(EIGHT),DOUBLE(EIGHT)  NEW NUMB NOW IN LINENUM    30400020
         LA    RLGTH,EIGHT                                              30500020
         LA    RWORK,LINENUM           PTR TO NUMBER                    30600020
SCANZERO EQU   *                                                        30700020
         CLI   O(RWORK),C'0'           LEADING ZERO                     30800020
         BNE   SIZEDONE                NO                               30900020
         LA    RWORK,ONE(RWORK)        UPDATE TO NEXT                   31000020
         BCT   RLGTH,SCANZERO          DECREMENT LENGTH-CONTINUE        31100020
         LA    RLGTH,ONE               ALL ZERO-STORE ONE               31200020
         BCTR  RWORK,O                 PT TO LAST DIGIT                 31300020
SIZEDONE EQU   *                                                        31400020
         OI    LINENUM+L7,MASK1        CHANGE SIGN                      31500020
         STH   RLGTH,NEWLGTH           STORE LENGTH NEW NUMBER          31600020
         MVC   LINENUM(EIGHT),O(RWORK) MOVE OVER LEADING ZERO           31700020
         BR    RTRNM                   RETURN                           31800020
FNDENTRY EQU   *                                                        31900020
         TM    DEFINED,EIGTY           DEFINED ALREADY                  32000020
         BO    NETHNGLZ                YES-DEFINED TWICE                32100020
         OI    DEFINED,EIGTY           SET FLAG-DEFINED                 32200020
         MVC   DOUBLE(FOUR),FOUR(RTBL) SAVE NEW NUMBER                  32300020
         B     SCANNUM2                CONTINUE SCAN FOR DUPLICATES     32400020
GOSUB    EQU   *                                                        32500020
         L     RWORK,STSRC             PTR TO SQUEEZED SOURCE           32600020
         LA    RWORK,FIVE(RWORK)       PTR TO NUMBER                    32700020
         B     GOTO2                   CHANGE/STORE                     32800020
STORSRC  EQU   *                       STORE START OF SOURCE/FIRST NUMB 32900020
*                                                                       33000020
*        THE FOLLOWING ROUTINE STORES THE OLD SOURCE UP TO THE LINE     33100020
*        NUMBER THAT WAS CONVERTED                                      33200020
         L     RSRC,STSRC              PTR TO SQUEEZED SOURCE           33300020
         L     RBUFF,STSRCOLD          PTR TO OLD DATA AREA             33400020
         L     RLGTH,LINEPTR           PTR TO NUMBER                    33500020
         SR    RLGTH,RSRC                                               33600020
         BCTR  RLGTH,O                 MINUS 1 FOR EX                   33700020
         EX    RLGTH,COPYSRC           COPY                             33800020
         LA    RWORK,ONE(RBUFF,RLGTH)  UPDATE TO NEXT                   33900020
STORNEWN EQU   *                                                        34000020
*                                                                       34100020
*        THE FOLLOWING ROUTINE STORES THE NEW LINE NUMBER IN THE        34200020
*        CONVERTED SOURCE                                               34300020
*                                                                       34400020
         MVI   O(RWORK),BLNK           NEXT CHAR=BLANK                  34500020
         LH    RLGTH,NEWLGTH           LENGTH NEW NUMBER                34600020
         BCTR  RLGTH,O                 MINUS 1 FOR EX                   34700020
         EX    RLGTH,STORNUM           STORE NEW NUMBER                 34800020
         LA    RBUFF,TWO(RWORK,RLGTH)  UPDATE PAST BLANK,NUMBER         34900020
         BR    RTRNM                   RETURN                           35000020
IF       EQU   *                                                        35100020
         L     RWORK,STSRC             CALC PTR TO END OF SOURCE        35200020
         AH    RWORK,LL                OLD LENGTH                       35300020
         SH    RWORK,THIRTENN          PTR TO LAST CHARACTER            35400020
NEXTIF   EQU   *                                                        35500020
         CLI   O(RWORK),BLNK           BLANK                            35600020
         BNE   NEXTIF3                 NO-FOUND DIGIT                   35700020
         BCT   RWORK,NEXTIF            DECREMENT PTR-CONTINUE           35800020
NEXTIF2  EQU   *                                                        35900020
         CLI   O(RWORK),C'0'           DIGIT                            36000020
         BNL   NEXTIF4                 YES-CONTINUE                     36100020
NEXTIF5  EQU   *                                                        36200020
         LA    RWORK,ONE(RWORK)        RESET PTR TO FIRST DIGIT OF NUM  36300020
         B     GOTO2                   CONVERT AND CHANGE               36400020
NEXTIF4  EQU   *                                                        36500020
         CLI   O(RWORK),C'9'           DIGIT                            36600020
         BH    NEXTIF5                 NO-END OF NUMB                   36700020
NEXTIF3  EQU   *                                                        36800020
         BCT   RWORK,NEXTIF2           CONTINUE                         36900020
PRU      EQU   *                                                        37000020
         LA    RWORK,TEN               NUMBER OF KEY CHARACTERS         37100020
PRU2     EQU   *                                                        37200020
         A     RWORK,STSRC             PAST KEY WORDS                   37300020
         ST    RWORK,LINEPTR           STORE PTR TO NUMBER              37400020
         BAL   RTRNM,INITBLNK          INIT BUFFER TO BLANKS            37500020
         BAL   RTRNM,CHANGE            CONVERT NUMBER                   37600020
         BAL   RTRNM,STORSRC           STORE KEY WDS, NUMBER            37700020
*                                      RBUFF POINTS TO NEXT FREE CHAR   37800020
STOREEND EQU   *                                                        37900020
*                                                                       38000020
*        THE FOLLOWING ROUTINE STORES THE OLD SOURCE FROM THE LAST      38100020
*        LINE NUMBER THAT WAS CONVERTED UP TO THE END                   38200020
*                                                                       38300020
         L     RSRC,LINEPTR            PTR. TO NUMBER                   38400020
         AH    RSRC,SRCLGTH            PTR PAST OLD SOURCE              38500020
         LH    RLGTH,LL                CALC NUM CHARS STILL TO STORE    38600020
         SH    RLGTH,TWELVEN           NUMBER/LENGTH                    38700020
         LR    RWORK,RSRC                                               38800020
         S     RWORK,STSRC             NUM CHARS. USED                  38900020
         SR    RLGTH,RWORK             NUM CHARS. LEFT                  39000020
         CH    RLGTH,NUM0              ANY LEFT                         39100020
         BE    SEELGTH                 NO                               39200020
         BCTR  RLGTH,O                 SUB1                             39300020
         EX    RLGTH,COPYEND           STORE END                        39400020
         LA    RBUFF,ONE(RLGTH,RBUFF)  PTR TO NEXT FREE                 39500020
*                                      ELIMINATE TRAILING BLANKS        39600020
BLNKLOOP EQU   *                                                        39700020
         BCTR  RBUFF,O                 PT AT CHAR                       39800020
         CLI   O(RBUFF),BLNK           BLANK                            39900020
         BE    BLNKLOOP                YES-CONTINUE                     40000020
         LA    RBUFF,ONE(RBUFF)        UPDATE TO NEXT FREE              40100020
         B     SEELGTH                 SEE IF ROOM                      40200020
MATPRU   EQU   *                                                        40300020
         LA    RWORK,THIRTEEN          NUMBER OF KEY CHARACTERS         40400020
         B     PRU2                    GET NEW POINTER                  40500020
COMPUTED EQU   *                                                        40600020
         MVI   O(RBUFF),COMA           INIT FIRST COMMA                 40700020
         LA    RBUFF,ONE(RBUFF)        UPDATE TO NEXT FREE BUFFER CHAR  40800020
         ST    RBUFF,FREE              SAVE FREE PTR                    40900020
         LA    RWORK,ONE(RWORK)        UPDATE TO NUMBER                 41000020
         ST    RWORK,LINEPTR           STORE PTR TO NUMBER              41100020
         BAL   RTRNM,CHANGE            CALL NEW REFERENCE               41200020
         L     RWORK,FREE              LOAD PTR TO NEXT FREE BYTE       41300020
         BAL   RTRNM,STORNEWN          STORE NEW REFERENCE              41400020
         C     RBUFF,STSRC             PAST MAX  (WAY PAST)             41500020
         BNL   NETHNGLZ                YES                              41600020
         L     RWORK,LINEPTR           PTR TO NUMBER JUST STORED        41700020
         AH    RWORK,SRCLGTH           +LENGTH OLD NUMBER               41800020
         CLI   O(RWORK),COMA           MORE                             41900020
         BE    COMPUTED                YES                              42000020
COMPUTE2 EQU   *                                                        42100020
*                                      NO-COPY END OF SOURCE            42200020
         LA    RBUFF,ONE(RBUFF)        ADD BLANK                        42300020
         B     STOREEND                STORE AND CHECK                  42400020
QUOTE    EQU   *                                                        42500020
         MVC   DELIM(ONE),O(RSRC)      SAVE DELIM                       42600020
QUOTE1   BCT   RCOUNT,QUOTE2           UPDATE LENGTH LEFT        A50491 42700021
*                                      UNBALANCED QUOTE FOUND    A50491 42701021
         BAL   RTRNM,TESTUNBQ          TEST UNBALANCED QUOTES    A50491 42740021
*                                      ALLOWED; NO RETURN IF NOT A50491 42760021
         B     FINSQU                  UNBALANCED QUOTES ALLOWED A50491 42780021
QUOTE2   EQU   *                                                        42800020
         LA    RSRC,ONE(RSRC)          UPDATE PAST QUOTE                42900020
         LA    RBUFF,ONE(RBUFF)                                         43000020
         MVC   O(ONE,RBUFF),O(RSRC)    SAVE CHAR                        43200020
         CLC   O(ONE,RSRC),DELIM       DELIM                            43300020
         BNE   QUOTE1                  IF NOT, CONTINUE          A50491 43301021
         B     SQU2                    END OF STRING             A50491 43470021
TESTUNBQ EQU   *                                                 A50491 43540021
         L     RBUFF,STSRC             SET PTR TO STATEMENT      A50491 43610021
         CLC   O(L'END,RBUFF),END      TEST FOR END STATEMENT    A50491 43680021
         BCR   EIGHT,RTRNM             END ALLOWS UNBAL. QUOTES  A50491 43750021
         CLI   O(RBUFF),IMAGE          TEST FOR IMAGE STATEMENT  A50491 43820021
         BCR   EIGHT,RTRNM             IMAGE ALLOWS UNBAL. QUOTS A50491 43890021
         CLC   O(L'PAUSE,RBUFF),PAUSE  TEST FOR PAUSE STATEMENT  A50491 43960021
         BCR   EIGHT,RTRNM             PAUSE ALLOWS UNBAL.QUOTES A50491 44030021
         BCR   EIGHT,RTRNM             REM ALLOWS UNBAL. QUOTES  A50491 44170021
         CLC O(L'RESTORE,RBUFF),RESTORE  TEST FOR RESTORE STMNT  A50491 44240021
         BCR   EIGHT,RTRNM             RESTORE ALLOWS UNBAL. QTS A50491 44310021
         CLC   O(L'RETURN,RBUFF),RETURN  TEST FOR RETURN STMNT   A50491 44380021
         BCR   EIGHT,RTRNM             RETURN ALLOWS UNBAL. QTS  A50491 44450021
         CLC O(L'STOP,RBUFF),STOP      TEST FOR STOP STATEMENT   A50491 44520021
         BCR   EIGHT,RTRNM             STOP ALLOWS UNBAL. QUOTES A50491 44590021
         B     NETHNGLZ                ELSE, BAD CHAR. STRING    A50491 44660021
READ     EQU   *                                                        44800020
*                                      READ IN RELOAD                   44900020
         LA    RWORK,REINAREA          ADDRESS TO READ INTO             45000020
         ST    RWORK,READPTR           STORE                            45100020
         MVI   READPTR,ENDFLAG         SET END PTR                      45200020
         IKJEBESH  (COMMREG),IKJEBEUT,PARAM=((COMMREG),RDPARMS),       X45300020
               MF=(E,RPLIST)                                            45400020
         CH    RCODE,NUM8              I/O ERROR                        45500020
         BE    IOERR                   YES                              45600020
         BR    RTRNM                   NO-CONTINUE                      45700020
GETTABLE EQU   *                                                        45800020
*                                                                       45900020
*        THE FOLLOWING ROUTINE ALLOCATES THE RENUMBER TABLE             46000020
*                                                                       46100020
*                                      ALLOCATE TABLE-500 ENTRIES       46200020
         LH    RWORK,TABNO             NUM TO DATE                      46300020
         SLL   RWORK,THREE             MULT BY 8(LENGTH EACH ENTRY)     46400020
         LA    RTBL,TBLADDR(RWORK)     ADDRESS FIRST TABLE / LENGTH     46500020
         GETMAIN VC,LA=MINSIZ,A=(RTBL),SP=1,MF=(E,RPLIST)        A45103 46600020
         CH    RCODE,NUM0              SUCCESS                          46700020
         BNE   NOTABLE                 NO-ERROR                         46800020
         LH    RWORK,TABNO             NUM PREVIOUS                     46900020
         LA    RCODE,ONE(RWORK)        UPDATE                           47000020
         STH   RCODE,TABNO             STORE UPDATED NUMBER             47100020
         L     RWORK,FOUR(RTBL)        LENGTH                           47200020
         A     RWORK,O(RTBL)           +START ADDRESS=END               47300020
         ST    RWORK,TBLEND            STORE END OF TABLE               47400020
         ST    RWORK,FOUR(RTBL)                                         47500020
         L     RTBL,O(RTBL)            LOAD ADDRESS TABLE               47600020
         BR    RTRNM                   RETURN                           47700020
GETADDR  EQU   *                                                        47800020
*                                                                       47900020
*        THE FOLLOWING ROUTINE RETURNS THE NEXT NEW LINE NUMBER         48000020
*                                                                       48100020
         CLC   ADDKEY(FOUR),NUM0       FIRST TIME                       48200020
         BNE   GETADDR2                NO-CONTINUE                      48300020
         MVI   TABNO+THREE,MASK2       INIT -ONE USED                   48400020
         MVC   ADDKEY(FOUR),TBLADDR    ADDRESS FIRST TABLE              48500020
         BR    RTRNM                   RETURN                           48600020
GETADDR2 EQU   *                                                        48700020
         L     RTBL,ADDKEY             PREVIOUS ADD.                    48800020
         LA    RTBL,EIGHT(RTBL)        PTR TO NEXT ENTRY                48900020
         LH    RWORK,TABNO+TWO         NUM USED                         49000020
         CH    RWORK,TABNO             ON LAST                          49100020
         BL    GETADDR3                NO                               49200020
         C     RTBL,TBLEND2            AT END                           49300020
         BNL   NEXTTBL2                YES-ERROR                        49400020
         B     STORADDR                CONTINUE                         49500020
GETADDR3 EQU   *                                                        49600020
         BCTR  RWORK,O                 LOOK AT CURRENT                  49700020
         SLL   RWORK,THREE             MULT BY 8 (FOR EACH ENTRY)       49800020
         C     RTBL,TBLADDR+FOUR(RWORK) END OF TBL                      49900020
         BL    STORADDR           GO STORE ADDRESS              SA68905 50500021
         LH    RWORK,TABNO+TWO    NUM USED                      SA68905 50506021
         LA    RWORK,ONE(RWORK)   INCREMENT BY ONE              SA68905 50512021
         STH   RWORK,TABNO+TWO    NUM USED                      SA68905 50518021
         BCTR  RWORK,0            RESTORE ORIGINAL COUNT        SA68905 50524021
         SLL   RWORK,THREE        MULT BY 8(FOR EACH ENTRY)     SA68905 50530021
         L     RTBL,TBLADDR(RWORK) START OF THIS ENTRY          SA68905 50536021
         B     STORADDR           CONTINUE                      SA68905 50542021
STORADDR EQU   *                                                        50550020
         ST    RTBL,ADDKEY             STORE                            50560020
         BR    RTRNM                   RETURN                           50570020
INITBLNK EQU   *                       INIT BUFFER TO BLANKS            51200020
         L     RSRC,STSRCOLD           PTR TO SOURCE AREA               51300020
         MVI   O(RSRC),BLNK            MOVE IN BLANK                    51400020
         MVC   ONE(T55,RSRC),O(RSRC)   SET TO BLANK                     51500020
         BR    RTRNM                   RETURN                           51600020
SCANTBL  EQU   *                                                        51700020
         LH    RWORK,TABNO+FOUR        NO. USED SO FAR                  51800020
         LA    RWORK,ONE(RWORK)        UPDATE                           51900020
         STH   RWORK,TABNO+FOUR        STORE                            52000020
         BCTR  RWORK,O                 RESTORE ORIGINAL COUNT           52100020
         SLL   RWORK,THREE             MULTIPLY BY 8-PTR TO NEXT ENTRY  52200020
         L     RTBL,TBLADDR(RWORK)     START OF TABLE                   52300020
         CLC   TABNO(TWO),TABNO+FOUR   ALL USED                         52400020
         BE    SCANTBL2                YES                              52500020
         LA    RWORK,TBLADDR+FOUR(RWORK) PTR END OF TABLE ENTRY         52600020
         MVC   TBLEND(FOUR),O(RWORK)   STORE END ADDRESS                52700020
         B     SCANNUM                 RETURN                           52800020
SCANTBL2 EQU   *                                                        52900020
         MVC   TBLEND(FOUR),TBLEND2    END OF TABLE                     53000020
         B     SCANNUM                 RETURN                           53100020
FINRENUM EQU   *                       FINISHED-FREE BLOCKS             53200020
         LH    RCOUNT,TABNO            NUM TABLES ALLOCATED             53300020
         LTR   RCOUNT,RCOUNT           ANY TABLES                       53400020
         BZ    FINISH                  NO                               53500020
         LA    RTBL,TBLADDR            ADDRESS FIRST TABLE STORED HERE  53600020
FREELOOP EQU   *                                                        53700020
         L     RWORK,FOUR(RTBL)        END OF TABLE                     53800020
         S     RWORK,O(RTBL)           END-START=LENGTH                 53900020
         ST    RWORK,FOUR(RTBL)        STORE LENGTH                     54000020
         FREEMAIN V,A=(RTBL),SP=1,MF=(E,RPLIST)                  A45103 54100020
         LA    RTBL,EIGHT(RTBL)        UPDATE TO NEXT ENTRY             54200020
         BCT   RCOUNT,FREELOOP         BRANCH TO CONTINUE               54300020
FINISH   EQU   *                                                        54400020
         LH    RCODE,RTNCODE           RETURN CODE                      54500020
         LTR   RCODE,RCODE             RETURN CODE = 0                  54550020
         BNE   RTNBAD                  NO                               54600020
         L     RWORK,INCR              INCREMENT                        54700020
         ST    RWORK,CAINCRE           UPDATE                           54800020
         ST    RWORK,CAIMLINC          UPDATE                           54900020
         MVC   CAIMLLNO(FOUR),BAIMLLNO UPDATE                           55000020
         MVC   CACURNUM(FOUR),BACURNUM UPDATE                           55100020
RTNBAD   EQU   *                                                        55200020
         IKJEBERT (14,12),RC=(15)                                       55400020
         SPACE                                                          55450020
*********************************************************************** 55500020
*                                                                     * 55550020
*        SEND MESSAGE TO TERMINAL USER                                * 55600020
*                                                                     * 55650020
*********************************************************************** 55700020
SENDERR  EQU   *                                                        55900020
         IKJEBEML ,,,,MF=(E,RPLIST)                                     55950020
         SPACE                                                          56000020
         TM    ERRBITS,EXIT            CONTINUE                         56800020
         BO    WRITLST                 BR YES                           56900020
         B     ERROR                   BR TO END PROCESSING             56950020
         EJECT                                                          57000020
*********************************************************************** 57050020
*                                                                     * 57100020
*        MESSAGE 312                                                  * 57150020
*                                                                     * 57160020
*********************************************************************** 57170020
NOTABLE  EQU   *                                                        57200020
         XC    RPLIST(K40),RPLIST      INIT PARMLIST TO 0               57250020
         MVC   LEVEL1(TWO),RM312       SET UP LEVEL1 PARMLIST           57300020
         MVC   INS1(RMGL),RMG          SET UP INSERTION PARMLIST        57350020
         NI    ERRBITS,FLGOF           TURN OFF CONTINUE FLAG           57350420
CHAIN    EQU   *                                                        57352020
         LA    WRA,INS1                CHAIN INSERTION1 PARMLIST        57360020
         ST    WRA,LEV1IN              TO LEVEL1 PARMLIST               57370020
         B     SENDERR                 BR TO SEND MESSAGE TO USER       57400020
         SPACE                                                          57450020
*********************************************************************** 57460020
*                                                                     * 57470020
*        MESSAGE 503                                                  * 57480020
*                                                                     * 57490020
*********************************************************************** 57492020
NOTCOMPT EQU   *                                                        57800020
         XC    RPLIST(K40),RPLIST      INIT PARMLIST TO 0               57850020
         MVC   LEVEL1(TWO),RM503       SET UP LEVEL1 PARMLIST           58000020
         NI    ERRBITS,FLGOF           TURN OFF CONTINUE FLAG           58050020
         B     SENDERR                 BR TO SEND MESSAGE TO USER       59500020
         SPACE                                                          59550020
*********************************************************************** 59560020
*                                                                     * 59570020
*        MESSAGE 504                                                  * 59580020
*                                                                     * 59590020
*********************************************************************** 59592020
NOTFOUND EQU   *                                                        59600020
         XC    RPLIST(K40),RPLIST      INIT PARMLIST TO 0               59650020
         MVC   LEVEL1(TWO),RM504       SET UP LEVEL1 PARMLIST           59700020
         MVI   INS1O,M504IN1           PTR TO INSERTION PT              59750020
         L     WRA,RDKEY               BINARY KEY OF RCD                59760020
         BAL   RTRNM,CNVSTRP           BR TO CONVERT AND STRIP          59770020
         NI    ERRBITS,FLGOF           TURN OFF CONTINUE FLAG           59772020
         B     CHAIN                   BR TO CHAIN PARMLISTS            59780020
         SPACE                                                          59790020
*********************************************************************** 59792020
*                                                                     * 59794020
*        MESSAGE 507                                                  * 59796020
*                                                                     * 59798020
*********************************************************************** 59798420
OFLOMSG  EQU   *                                                        59850020
         XC    RPLIST(K40),RPLIST      INIT PARMLIST TO 0               59850420
         MVC   LEVEL1(FOUR),RM507      SET UP LEVEL1 PARMLIST           59852020
         L     WRA,DOUBLE              NUMBER TO BE CONVERTED           59854020
         BAL   RTRNM,CNVSTRP           BR TO CONVERT AND STRIP          59856020
         LH    WRA,INS1L               THE CONVERTED NUMBER (LINE LEN)  59858020
         BCTR  WRA,O                   IS IN INSERTION2. THE CONVERT    59858820
         EX    WRA,IN2MVC              ROUTINE HAS SET IT UP AS INSERT- 59859220
*                                      TION1. AN MVC IS DONE TO MOVE    59859620
*                                      THE INSERTION1 PARMLIST TO THE   59859720
*                                      INSERTION2 PARMLIST.             59859820
         MVI   INS1O,M507IN1           PTR TO INSERTION PT              59859920
         MVI   INS2O,M5071IN1          PTR TO INSERTION PT              59863220
         L     WRA,KEY2                NUMBER TO BE CONVERTED           59865220
         BAL   RTRNM,CNVSTRP           BR TO CONVERT AND STRIP          59865620
         LA    WRA,INS2                CHAIN INSERTION2 PARMLIST TO     59866020
         ST    WRA,LEV2IN              LEVEL1 PARMLIST                  59866420
         OI    ERRBITS,EXIT            SET FLAG TO INDICATE CONTINUE    59866520
         B     CHAIN                   BR TO CHAIN INSERTION1 PARMLIST  59866620
         SPACE                                                          59869920
**********************************************************************  59870020
*                                                                    *  59872020
*        MESSAGE 565                                                 *  59872420
*                                                                    *  59872820
**********************************************************************  59873220
NETHNGLZ EQU   *                                                        59876720
         XC    RPLIST(K40),RPLIST      INIT PARMLIST TO 0               59877120
         MVC   LEVEL1(FOUR),RM565      SET UP LEVEL1 PARMLIST           59878720
         MVI   INS1O,M565IN1           PTR TO INSERTION PT              59879120
         L     WRA,LASTNUMB            NUMBER TO BE CONVERTED           59879520
         BAL   RTRNM,CNVSTRP           BR TO CONVERT AND STRIP          59879920
         NI    ERRBITS,FLGOF           TURN OFF CONTINUE FLAG           59881920
         B     CHAIN                   BR TO CHAIN PARMLISTS            59886620
         SPACE                                                          59888620
*********************************************************************** 59890620
*                                                                     * 59892620
*        THIS SUBROUTINE CONVERTS A NUMBER IN REGISTER WRA            * 59893020
*        TO DECIMAL. THE LEADING ZEROES ARE THEN STRIPPED             * 59893120
*        OFF THE NUMBER AND THE INSERTION PARAMETER LIST              * 59893220
*        IS SET UP.                                                   * 59919920
*                                                                     * 59929920
*********************************************************************** 59939920
CNVSTRP  EQU   *                                                        59941920
         CVD   WRA,DOUBLE              CONVERT NUMBER TO DECIMAL        59943920
         UNPK  IN1(EIGHT),DOUBLE+L3(FIVE) UNPK INTO INSERTION1          59945920
         OI    IN1+L7,MASK1            INSURE LAST DIGIT IS CHAR        59946320
         LA    WRC,EIGHT               MAXIMUM                          59946420
         LA    WRB,IN1                 INSERTION                        59946520
FLOOP    EQU   *                                                        59955420
         CLI   O(WRB),ZERO             IS DIGIT A CHARACTER ZERO        59957420
         BNE   FOUND                   BR NO                            59959420
         LA    WRB,ONE(WRB)            INCREMENT DISPLACEMENT           59961420
         BCT   WRC,FLOOP               LOOP THROUGH INSERTION           59963420
         MVI   IN1,ZERO                NUMBER IS 0                      59963820
         B     ADDX                    BR TO INC COUNT                  59964220
FOUND    EQU   *                                                        59966420
         BCTR  WRC,O                   MINUS 1 FOR EX                   59981720
         EX    WRC,INSRTMVC            MOVE TO STRIP LEADING ZEROES     59982120
ADDX     LA    WRC,FIVE(WRC)           OFFSET + 1 FOR EX                60005620
SAVEL    EQU   *                                                        60015620
         STH   WRC,INS1L               LENGTH OF INSERTION              60025620
         BR    RTRNM                   RETURN TO CALLER                 60027620
         SPACE                                                          60029220
*********************************************************************** 60029320
*                                                                     * 60029420
*        I/O ERROR OCCURRED                                           * 60037220
*                                                                     * 60039220
*********************************************************************** 60041220
IOERR    EQU   *                                                        60043220
         LA    WRA,EIGHT               SET RETURN CODE TO 8             60045220
         STH   WRA,RTNCODE             SAVE RETURN CODE                 60047220
         B     FINRENUM                BR TO END PROCESSING             60049220
         SPACE                                                          60051220
*********************************************************************** 60051620
*                                                                     * 60052020
*        ERROR ROUTINE                                                * 60052420
*                                                                     * 60052820
*********************************************************************** 60052920
ERROR    EQU   *                       IMPOSSIBLE ERROR                 60100020
NEXTTBL2 EQU   *                       ERROR                            60110020
         LA    WRA,FOUR                SET RETURN CODE TO 4             60150020
         STH   WRA,RTNCODE             SAVE RETURN CODE                 60160020
         B     FINRENUM                BR TO END PROCESSING             60170020
         EJECT                                                          60180020
RMG      IKJEBEMG 0,M312IN1,'RENUM'                                     60350020
RMGL     EQU   *-RMG                                                    60400020
         SPACE                                                          60410020
RM312    DC    AL2(M312)               RELATIVE LEVEL1 MESSAGE NUM      60460020
RM503    DC    AL2(M503)               RELATIVE LEVEL1 MESSAGE NUM      60462020
RM504    DC    AL2(M504)               RELATIVE LEVEL1 MESSAGE NUM      60470020
RM507    DC    AL2(M507)               RELATIVE LEVEL1 MESSAGE NUM      60480020
         DC    AL2(M5071)              RELATIVE LEVEL2 MESSAGE NUM      60482020
RM565    DC    AL2(M565)               RELATIVE LEVEL1 MESSAGE NUM      60490020
         DC    AL2(M5651)              RELATIVE LEVEL2 MESSAGE NUM      60492020
         SPACE                                                          60494020
PACKN    PACK  DOUBLE(EIGHT),O(O,RWORK) PACK ORIGINAL SOURCE NUMBER     60500020
COPYSRC  MVC   O(O,RBUFF),O(RSRC)      MOVE DATA BACK TO INPUT AREA     60600020
STORNUM  MVC   ONE(O,RWORK),LINENUM    COPY NEW LINE NUMBER             60700020
COPYEND  MVC   O(O,RBUFF),O(RSRC)      COPY REST OF INPUT               60800020
BLANKM   MVC   ONE(O,RBUFF),O(RBUFF)   INIT BUFFER TO BLANK             60900020
INSRTMVC MVC   IN1(O),0(WRB)           STRIP LEADING ZEROES             60950020
IN2MVC   MVC   INS2(O),INS1            MOVE INSERT1 PLIST TO INSERT2    61000020
MOVEROLD MVC   O(O,DATPTR),O(OLD)      MOVE OLD DATA                    61060020
MOVERNEW MVC   O(O,DATPTR),O(NEW)      MOVE NEW DATA                    61070020
         SPACE                                                          61080020
MININUM  DC    F'400'                  MINIMUM SIZE-50 STATE            61100020
         DC    F'4000'                 MAX WANTED AT ONE TIME           61200020
NUM0     DC    F'0'                    0                                61300020
NUM1     DC    H'1'                    1                                61400020
NUM2     DC    H'2'                    2                                61500020
NUM5     DC    H'5'                    5                                61600020
NUM8     DC    H'8'                    8                                61700020
TWELVEN  DC    H'12'                   12                               61800020
THIRTENN DC    H'13'                   13                               61900020
TWO55    DC    H'255'                  255                              62000020
CHON     DC    C'ON'                   KEYWORD CONSTANT                 62070020
CGOTO    DC    C'GOTO'                 KEYWORD CONSTANT                 62080020
CIF      DC    C'IF'                   KEYWORD CONSTANT                 62090020
CGOSUB   DC    C'GOSUB'                KEYWORD CONSTANT                 62092020
CPRUS    DC    C'PRINTUSING'           KEYWORD CONSTANT                 62094020
CMPRUS   DC    C'MATPRINTUSING'        KEYWORD CONSTANT                 62094420
END      DC    C'END'                  END STATEMENT             A50491 62094621
IMAGE    EQU   C':'                    FIRST CHAR OF IMAGE STMNT A50491 62095321
PAUSE    DC    C'PAUSE'                PAUSE STATEMENT           A50491 62095421
REM      DC    C'REM'                  REMARK STATEMENT          A50491 62095521
RESTORE  DC    C'RESTORE'              RESTORE STATEMENT         A50491 62095621
RETURN   DC    C'RETURN'               RETURN STATEMENT          A50491 62095721
STOP     DC    C'STOP'                 STOP STATEMENT            A50491 62095821
         SPACE                                                          62096020
         IKJEBEMI (312,503,504,507,565)                                 64100020
         EJECT                                                          64150020
         IKJEBECA                                                       70800020
         EJECT                                                          70850020
REDCB    EQU CAPTPDCB                  PTR TO UTILITY DATA SET          70900020
         ORG   CASRWKA                 WORK AREA                        71000020
         SPACE                                                          71050020
TBLADDR  DS    6F                      START TABLE/END TABLE            71300020
MINSIZ   DS    2F                      GETMAIN SIZE SPECIFICATIONS      71400020
TBLEND2  DS    F                       WPRD FIELD                       71500020
NEWLAST  DS    F                       NEW LAST NUMBER                  71600020
NEWINCR  DS    F                       NEW INCREMENT                    71700020
TABNO    DS    6X                      NUM TABLES/NUM USED/NUM USED FOR 71800020
*                                      SCAN                             71850020
RPLIST   DS    10F                     WORK SPACE FOR MACROS            71900020
LEVEL1   EQU   RPLIST                  LEVEL1 AND LEVEL2 MSG NUMBERS    71950020
LEV1IN   EQU   LEVEL1+4                PTR TO INSERTION1 PARMLIST       71960020
LEV2IN   EQU   LEVEL1+8                PTR TO INSERTION2 PARMLIST       71970020
INS1     EQU   LEVEL1+12               PTR TO NEXT INSERTION            71980020
INS1L    EQU   INS1+4                  INSERTION1 LENGTH                71990020
INS1O    EQU   INS1+7                  INSERTION1 OFFSET                71992020
IN1      EQU   INS1+8                  INSERTION1                       71994020
INS2     EQU   IN1+8                   PTR TO NEXT INSERTION            71996020
INS2L    EQU   INS2+5                  INSERTION2 LENGTH                71998020
INS2O    EQU   INS2+7                  INSERTION2 OFFSET                71998420
IN2      EQU   INS2+8                  INSERTION2                       71998820
         SPACE                                                          71999220
*        3F    IKJEBEUT PARM LIST                                       72000020
RDPARMS  DS    F                       PTR TO DATA SET(KEY IN BYTE 1)   72100020
RDKEYPTR DS    F                       PTR TO KEY                       72200020
READPTR  DS    F                       PTR TO INPUT AREA                72300020
*                                                                       72400020
RDKEY    DS    F                       STORE KEY                        72500020
ADDKEY   DS    F                       WORK WORD                        72600020
TBLEND   DS    F                       WORK WORD                        72700020
STSRC    DS    F                       PTR TO START SQUEEZED SOURCE     72800020
STSRCOLD DS    F                       PTR TO START OF DATA IN INPUT    72900020
LINEPTR  DS    F                       PTR TO NUMBER TO BE CHANGED      73000020
ENDSRC   DS    F                       PTR TO END OF DATA               73100020
EOLD     DS    F                       END OF OLD DATA PORTION          73150020
*        PARAMETERS PASSED                                              73200020
DOUBLE   EQU   *                                                        73250020
OLDNUMB  DS    F                       NUMB AT WHICH TO START RENUM     73300020
STLINENO DS    F                       NEW FIRST NUMBER                 73400020
INCR     DS    F                       INCREMENT                        73500020
*                                                                       73600020
LASTNUMB DS    F                       LAST NUMBER READ IN              73700020
READCB   DS    F                       PTR TO DATA SET TO READ IN       73800020
FREE     DS    F                       PTR TO NEXT FREE LOCATION        73900020
BAIMLLNO DS    F                       SAVE NEW CACURNUM                74000020
BACURNUM DS    F                       SAVE NEW CACURNUM                74100020
SRCLGTH  DS    H                       LENGTH OF LINE REFERENCE IN INP. 74200020
NEWLGTH  DS    H                       LENGTH OF NEW LINE REFERENCE     74300020
RTNCODE  DS    H                       RETURN                           74400020
LHALF    DS    H                       HALFWORD FOR LL ALIGNMENT        74450020
LINENUM  DS    8X                      NEW NUMBER                       74500020
ERRBITS  DS    X                       FLAGS FOR ERROR MSGS             74600020
DELIM    DS    X                       QUOTE OR DOUBLE QUOTE            74700020
DEFINED  DS    X                       WORKSPACE-DEFINED/NOT DEFINED    74800020
GOTOBIT  DS    X                       FLAG-GOTO STATEMENT              74900020
ENEW     DS    F                       END OF NEW DATA                  74970020
         ORG   ,                       RESUME CSECT                     75000020
REINAREA EQU   CATEMPBF                TEMP BFR                         75100020
KEY      EQU   REINAREA                                                 75200020
LL       EQU   REINAREA+4                                               75300020
DATA     EQU   REINAREA+8                                               75400020
ERRMSG   EQU   DATA                    ERROR MSG BUFFER                 75500020
RDBUFF2  EQU   REINAREA+264                                             75600020
KEY2     EQU   RDBUFF2                                                  75700020
LL2      EQU   RDBUFF2+4                                                75800020
DATA2    EQU   RDBUFF2+8                                                75900020
         EJECT                                                          75950020
*        REGISTER EQUATES                                               75960020
R0       EQU   0                       WORK REG                         75970020
PARMREG0 EQU   0                       0 PARM                           75980020
PARMREG1 EQU   1                       1 PARM                           75990020
REG1     EQU   1                       WORK REG                         75992020
RWORK    EQU   2                       WORK REG                         75994020
WRA      EQU   2                       WORK REG                         75994420
RCOUNT   EQU   3                       USED FOR SQUEEZE                 75996020
RLGTH    EQU   3                       CONVERTING/STORE NUMBER          75998020
WRB      EQU   3                       WORK REG                         75998120
RTBL     EQU   4                       OLD/NEW TABLE PTR                75998420
WRC      EQU   4                       WORK REG                         75998520
RSRC     EQU   5                       PTR TO SOURCE READ IN            75998820
RINCR    EQU   5                       INCREMENT                        75998920
WRD      EQU   5                       WORK REG                         75999020
RBUFF    EQU   6                       PTR TO WORK BUFFER               75999120
RLASTNO  EQU   6                       LAST NUMBER USED                 75999220
DATPTR   EQU   6                       DATA POINTER                     75999620
RNUM     EQU   7                       OLD LINE NUMBER                  76024320
OLD      EQU   7                       OLD DATA POINTER                 76028320
RTRNM    EQU   8                       USED FOR LINKAGE                 76034320
NEW      EQU   8                       NEW DATA POINTER                 76036320
COMMREG  EQU   9                       PTR TO COMMUNICATION AREA        76044320
ENDPTR   EQU   10                      PTR TO END OF DATA               76044720
BASEREG  EQU   11                      BASE REGISTER                    76046320
DATAREG  EQU   12                      NOT USED                         76046720
SAVEREG  EQU   13                      PTR TO SAVE AREA                 76047120
RETREG   EQU   14                      RETURN REG                       76048320
RETCDREG EQU   15                      BRANCH/RETURN CODES              76048720
RCODE    EQU   15                      RETURN CODE ON I/O REQUESTS      76049120
         EJECT                                                          76049520
*        NUMERIC EQUATES                                                76049620
O        EQU   0                       CONSTANT 0                       76050020
ONE      EQU   1                       CONSTANT 1                       76051620
L1       EQU   1                       CONSTANT 1                       76052020
TWO      EQU   2                       CONSTANT 2                       76053620
L2       EQU   2                       CONSTANT 2                       76055620
THREE    EQU   3                       CONSTANT 3                       76068420
L3       EQU   3                       CONSTANT 3                       76068820
FOUR     EQU   4                       CONSTANT 4                       76070420
L4       EQU   4                       CONSTANT 4                       76070820
FIVE     EQU   5                       CONSTANT 5                       76071220
SIX      EQU   6                       CONSTANT 6                       76072420
L7       EQU   7                       CONSTANT 7                       76072820
EIGHT    EQU   8                       CONSTANT 8                       76074420
TEN      EQU   10                      CONSTANT 10                      76074620
TWELVE   EQU   12                      CONSTANT 12                      76074720
THIRTEEN EQU   13                      CONSTANT 13                      76074820
K40      EQU   40                      CONSTANT 40                      76083120
T55      EQU   255                     CONSTANT 255                     76085120
         EJECT                                                          76087120
*        CHARACTER AND HEXADECIMAL EQUATES                              76089120
READFST  EQU   X'04'                   READ FIRST RECORD DATA SET       76091620
READPREV EQU   X'01'                   READ RECORD PREV. TO CURRENT     76100020
READWKEY EQU   X'00'                   READ CURRENT REFERENCED RECORD   76200020
READNEXT EQU   X'02'                   READ RECORD AFTER CURRENT REF.   76300020
ENDFLAG  EQU   X'80'                   FLAG- END OF PLIST               76400020
WRITERCD EQU   X'20'                   WRITE RECORD IN PLACE            76500020
FLGOF    EQU   X'00'                   OP FOR OFF FLAG                  76560020
GOTOFLAG EQU   X'80'                   FLAG FOR GO TO STATEMENT         76562020
BLNK     EQU   C' '                    BLANK OPERAND                    76570020
FOXES    EQU   X'FF'                   PLUG FOR TABLE                   76572020
BLANK    EQU   C' '                    CONSTANT BLANK                   76574020
ZERO     EQU   C'0'                    CONSTANT ZERO                    76576020
NINE     EQU   C'9'                    CONSTANT NINE                    76626020
EXIT     EQU   X'80'                   EXIT AFTER PRINTING              76733720
EIGTY    EQU   X'80'                   BIT ON OPERAND                   76783720
MASK1    EQU   X'F0'                   SIGN MASK                        76833720
MASK2    EQU   X'01'                   ONE TABLE USED                   76883720
COMA     EQU   C','                    COMMA OPERAND                    76933720
QUOTC    EQU   C''''                   QUOTE OPERAND                    76983720
DQUTC    EQU   C'"'                    DOUBLE QUOTE OPERAND             77033720
         END                                                            77083720
