 TITLE 'TSO ''EDIT'' COMMAND - ''SAVE'' SUBCOMMAND - IKJEBESA'          00040020
IKJEBESA CSECT                                                          00050021
*                                                                       00050221
* C 001600,276800,470000                                        A59609  00050421
* A 001680-001920,168680-168760,173400-173600                   A59609  00050621
* A 208300-208500,231020-231060,258570,258710,553700-553900     A59609  00050821
* D 554000                                                      A59609  00051021
*                                                                       00051221
*C517780-517900,659200-659600,694000-694400,740000,740800-741200 A42950 00052021
*D517930-520400                                                  A42950 00054021
*C000947,001055,185200,501200,503200,504400-505200               A42951 00056021
*C506500-508800,586400,666970,678000,678800-680000,701770        A42951 00058021
*D501600-502000,509200-511200,586800-587600                      A42951 00058421
*A000945,001053,505300,586100,666990,701794,806196-806204        A42951 00058821
*C249200,249600,267200,285600-286000,524400,526810,844400        A52001 00059221
*D621650                                                         A52001 00059621
*A249620,A269300-269500,526910-527008,569000-569180,620900       A52001 00060021
*A667160-667184,701864-701872,806329-806336                      A52001 00060421
*A383110,628922-628934,629130-629170,711060-711290                M5145 00065421
*C383100,383120                                                   M5145 00065621
*D711100-711600                                                   M5145 00065821
*A079700-079920,080900-081120,081300                              M4206 00070421
*D079600                                                          M4206 00080421
*                                                                       00080621
* A 406050-406150                                                A56698 00080821
*D340480-340720                                                 SA60415 00080921
*                                                                       00081021
**************************************************************** A42951 00081220
*STATUS  --  VERSION NO. 01. O/S 360 RELEASE NO. 20.             A42951 00081320
*                                                                A42951 00081420
*FUNCTION  --  THIS ROUTINE PERFORMS THE OPERATION OF SAVING THE      * 00081520
*   UTILITY DATA SET THAT IS BEING 'EDIT'ED.                          * 00081820
*                                                                     * 00082120
*   'SAVE' CAUSES THE UTILITY TO BE SAVED WITH THE NAME SPECIFIED ON  * 00082420
*   THE 'EDIT' COMMAND.  'SAVE DSNAME' CAUSES THE UTILITY TO BE SAVED * 00082720
*   WITH THE SPECIFIED NAME.                                          * 00083020
*                                                                     * 00083320
*   A DSNAME NOT ENTERED IN QUOTES IS MADE FULLY-QUALIFIED BY         * 00083620
*   PREFIXING THE USERID AND/OR SUFFIXING THE 'EDIT' DSNAME QUALIFIER,* 00083920
*   IF NECESSARY.  IF ONLY A MEMBER NAME IS SPECIFIED, THE RESULTING  * 00084220
*   DSNAME WILL BE OF THE FORM 'USERID.QUALIFIER(MEMBER)' IF NO MEMBER* 00084520
*   WAS SPECIFIED ON THE 'EDIT' COMMAND, OR 'EDITDSNAME(MEMBER)' IF A * 00084820
*   MEMBER WAS SPECIFIED ON THE 'EDIT' COMMAND.  IF A MEMBER NAME IS  * 00085120
*   NEEDED AND NONE WAS SPECIFIED, '(TEMPNAME)' IS USED.              * 00085420
*                                                                     * 00085720
*   IF THE DATA SET OR MEMBER TO BE SAVED-INTO IS NOT NEW AND IF THAT * 00086020
*   DATA SET OR MEMBER NAME WAS NOT ENTERED ON THE 'EDIT' COMMAND WITH* 00086320
*   THE 'OLD' KEYWORD, THE USER IS PROMPTED TO ENTER ANOTHER DATA SET * 00086620
*   OR MEMBER NAME OR TO HIT THE CARRIAGE-RETURN TO USE THE DATA SET  * 00086920
*   OR MEMBER NAME SPECIFIED.                                         * 00087220
*                                                                     * 00087520
*   AN ATTEMPT TO SAVE INTO AN EXISTING, NON-EMPTY PARTITIONED DATA   * 00087820
*   SET HAVING RECFM, BLKSIZE, OR LRECL INCOMPATIBLE WITH THOSE       * 00088120
*   ATTRIBUTES OF THE UTILITY DATA SET RESULTS IN A DIAGNOSTIC        * 00088420
*   MESSAGE.  OTHERWISE THE DATA SET SAVED-INTO WILL HAVE THE RECFM,  * 00088720
*   BLKSIZE, AND LRECL SPECIFIED OR DEFAULTED ON THE 'EDIT' COMMAND.  * 00089020
*                                                                     * 00089320
* ENTRY POINTS  --                                                    * 00089620
*        IKJEBESA - BY A BRANCH FROM THE CONTROLLER (IKJEBEMA), TO    * 00089920
*   PERMANENTLY SAVE THE UTILITY AS DESCRIBED IN 'FUNCTION  --'.      * 00090220
*                                                                     * 00090520
*INPUT  --  REGISTER 1 CONTAINS THE ADDRESS OF EDIT'S COMMUNICATION   * 00090820
*   AREA.  THIS ARE CONTAINS THE ADDRESS OF THE BUFFER CONTAINING THE * 00091120
*   'SAVE' SUBCOMMAND.                                                * 00091420
*                                                                     * 00091720
*OUTPUT  --  RETURN CODES POSSIBLE IN REGISTER 15 ARE                 * 00092020
*   00 - NORMAL COMPLETION.                                           * 00092320
*   08 - SUBCOMMAND TERMINATION ERROR, INPUT STACK MUST BE CLEARED    * 00092420
*        (AND DELETED IF INPUT SOURCE IS AN IN-CORE PROCEDURE).       * 00092520
*   12 - PERMANENT I/O ERROR ON UTILITY DATA SET.                     * 00092620
*                                                                     * 00092920
*EXTERNAL REFERENCES  --                                              * 00093220
*        IKJPARS  - CHECKS SYNTAX OF SUBCOMMAND AND FORMATS OPERANDS. * 00093520
*        IKJDFLT  - FULLY-QUALIFIES DSNAME AND SEARCHES CATALOG.      * 00093820
*        IKJDAIR  - ALLOCATES AND UNALLOCATES DATA SETS.              * 00094120
*        IKJEBEMS - BUILDS AND SENDS MESSAGES.                        * 00094420
*        IKJPTGT  - SENDS PROMPT MESSAGES.                       A42951 00094520
*        IKJPUTL  - SENDS MODE MESSAGES                          A42951 00094700
*        IKJEBEFC - COPIES RECORDS FROM UTILITY TO 'SAVE' DATA SET.   * 00094820
*        PRIVATE MACROS USED -                                        * 00095020
*          IKJEBESV - ENTRY LINKAGE.                                  * 00095320
*          IKJEBEMG - LIST FORM OF MESSAGE INSERTIONS.                * 00095620
*          IKJEBEML - BUILDS PARM LIST FOR, AND CALLS, IKJEBEMS.      * 00095920
*          IKJEBEMI - DEFINES PARAMETERS FOR IKJEBEMG AND IKJEBEML.   * 00096220
*          IKJEBESH - CALLS EDIT SERVICE ROUTINES.                    * 00096520
*          IKJEBERT - EXIT LINKAGE.                                   * 00097120
*          IKJEBECA - MAPS 'EDIT' COMMUNICATION AREA.                 * 00097420
*        SYSTEM MAPPING MACROS USED -                                 * 00097720
*          IEFTIOT1 - TASK INPUT/OUTPUT TABLE.                        * 00098020
*          IEFUCBOB - UNIT CONTROL BLOCK.                             * 00098320
*          CVT      - COMMUNICATIONS VECTOR TABLE.                    * 00098620
*          IECSDSL1 - DATA SET CONTROL BLOCK.                         * 00098920
*          IKJCPPL  - COMMAND PROCESSOR PARAMETER LIST.               * 00099220
*          IKJPPL   - PARSE PARAMETER LIST.                           * 00099520
*          IKJDAPL  - DAIR PARAMETER LIST.                            * 00099820
*          IKJDAP08 - DAIR PARAMETER BLOCK, ENTRY CODE 8.             * 00100120
*          IKJDAP18 - DAIR PARAMETER BLOCK, ENTRY CODE 18.            * 00100420
*          DCBD     - DATA CONTROL BLOCK.                             * 00100720
*          IKJDFPL  - DEFAULT PARAMETER LIST.                         * 00101020
*          IKJDFPB  - DEFAULT PARAMETER BLOCK.                        * 00101320
*          IKJPSCB  - PROTECTED STEP CONTROL BLOCK.                   * 00101620
*          IKJIOPL  - INPUT/OUTPUT PARAMETER LIST.                    * 00101920
*          IKJPGPB  - PUTGET PARAMETER BLOCK.                         * 00102220
*        OTHER MACROS USED -                                          * 00102520
*          IKJPARM  - BEGIN PARAMETER DESCRIPTOR AND CONTROL LISTS.   * 00102820
*          IKJPOSIT - DEFINE DELIMITED POSITIONAL PARAMETER.          * 00103120
*          IKJIDENT - DEFINE POSITIONAL CHARACTER STRING.             * 00103420
*          IKJENDP  - END PARAMETER CONTROL LIST.                     * 00103720
*          IKJRLSA  - RELEASE CORE FOR PARAMETER DESCRIPTOR LIST.     * 00104020
*          CAMLST   - LIST FORM OF OBTAIN PARAMETER LIST.             * 00104320
*          OBTAIN   - READ DATA SET CONTROL BLOCK.                    * 00104620
**         FREEMAIN - RELEASE CORE FOR PUTGET INPUT.                  * 00104920
*          LINK     - LOAD AND PASS CONTROL TO EXTERNAL PROGRAM.      * 00105220
*          PUTGET  - ISSUE PROMPT MESSAGE.                       A42951 00105320
*          PUTLINE  - ISSUE MODE MESSAGE.                        A42951 00105500
*          DEVTYPE  - GET DEVICE CHARACTERISTICS.                     * 00105820
*          OPEN     - COMPLETE DCB AND PREPARE DATA SET FOR INPUT.    * 00106120
*          DCB      - LIST FORM, DATA CONTROL BLOCK.                  * 00106420
*          BLDL     - GET DIRECTORY INFORMATION.                      * 00106720
*          CLOSE    - RESTORE DCB AND DISCONNECT DATA SET.            * 00107020
*                                                                     * 00107320
*EXITS,NORMAL  --   VIA A BRANCH TO THE CALLER, WITH RETURN CODE AS   * 00107620
*   DESCRIBED IN 'OUTPUT --'.                                         * 00107920
*                                                                     * 00108220
*EXITS,ERROR  --  NONE.                                               * 00108520
*                                                                     * 00108820
*TABLES/WORK AREAS  --  AREAS IN THE COMMUNICATION AREA (IKJEBECA)    * 00109120
*   USED AS WORKING STORAGE ARE - CASCWKA, CATEMPBF, CABFRPL.  AREAS  * 00109420
*   MODIFIED ARE - CAATTNIS, CADSMODS, CADSNLEN, CADSNLN2, CADSNOFF,  * 00109720
*   CADSNOF2, CADSNPTR, CADSNPT2, CADSNREC, CADSNRC2, CAEDALOC,       * 00110020
*   CAEDDDN, CAEDDISP, CAEDDSOR, CAEDFNCP, CAEDUNCG, CAEDMEM,         * 00110320
*   CAEDMEMB, CANTXTSVA, CAPRSPDL, CAPTIBFR, CAPTPRSD, CASAALOC,      * 00110620
*   CASADDN, CASADISP, CASADSN, CASADSNL, CASADSOR, CASAFNCP, CASAMEM,* 00110920
*   CASAMEMB, CASAPSWD, CASAUNCG, CASRPLST.                           * 00111220
*                                                                     * 00111520
*ATTRIBUTES  --  REFRESHABLE, ENABLED, NON-PRIVILEGED.                * 00111820
*                                                                     * 00112120
*NOTES  --  THERE IS CHARACTER-CODE INDEPENDENCE.                     * 00112420
*                                                                     * 00112720
*********************************************************************** 00113020
 EJECT                                                                  00113320
         ENTRY IKJEBESA                                                 00120020
         IKJEBESV (14,12),,*,CODEREG=NO ENTRY LINKAGE.          A59609  00160021
         BALR  BASEREG,PARMREG0 ESTABLISH ADDRESSABILITY FOR    A59609  00168021
         USING *,BASEREG,BASEREG2  THIS ROUTINE                 A59609  00176021
         LA    BASEREG2,SA2048(,BASEREG) INITIALIZE SECOND      A59609  00184021
         LA    BASEREG2,SA2048(,BASEREG2) BASE REGISTER         A59609  00192021
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY TO EDIT        00200020
*                             COMMUNICATION AREA.                       00240020
 SPACE                                                                  00280020
*********************************************************************** 00320020
* INITIALIZATION OF STORAGE AND REGISTERS.                            * 00360020
*********************************************************************** 00400020
 SPACE                                                                  00440020
         XC    SARETCOD(L'SARETCOD),SARETCOD INITLZ RET CODE TO 0.      00480020
         LA    SARETREG,SAENDNIT SET ADDRESS OF END OF RE-              00520020
*                             INITIALIZATION SECTION.                   00560020
SAREINIT EQU   *                                                        00600020
         XC    CASAFLAG(L'CASAFLAG+SABYT+L'CASADSNL),CASAFLAG           00640020
*                             INITLZ SAVE DATA SET FLAGS AND LNG        00680020
*                             TO ZERO.                                  00720020
         MVI   CASADSN,SABLNK                                           00760020
         MVC   CASADSN+SABYT(L'CASADSN+L'CASAMEMB+L'CASADDN+L'CASAPSWD-C00800020
               SABYT),CASADSN INITLZ SAVE DATA SET NAME,MEMBER,         00840020
*                             DDNAME,PASSWORD TO BLANKS.                00880020
         OI    CASAFLAG,CASAFNCP INITLZ BITS TO IND THAT SAVE DATA      00920020
         NI    CAEDFLAG,SAFF-CAEDFNCP SET NAME IS TO BE USED FOR        00960020
*                             FINAL COPY.                               01000020
         BR    SARETREG       RETURN TO CALLING POINT OR CONTINUE.      01120020
SAENDNIT EQU   *                                                        01160020
         L     SAWR1,CAPTTMP  GET PT TO TMP PARAMETER LIST.             01200020
         L     SAWR1,CPPLPSCB-CPPL(SAWR1) GET PT TO PSCB FR LIST.       01240020
         LA    SAWR2,SADAIRPB GET ADDRESS OF DAIR PARAMETER BLOCK.      01280020
         STM   SAWR1,SAWR2,SAPSCB SAVE THESE 2 GOTTEN VALUES.           01320020
         MVI   SASWICHS,O     INITLZ SWITCHES TO OFF.                   01360020
         TM    CAEDFLAG,CAEDDISP WAS 'OLD' SPEC ON 'EDIT' COMMAND -     01400020
         BZ    SAOPTEST       IF NO,GOTO TEST FOR 'SAVE' OPERANDS.      01440020
         OI    SASWICHS,SAEDOL IF YES,REMEMBER 'OLD' ON EDIT.           01480020
SAOPTEST EQU   *                                                        01520020
 SPACE                                                                  01560020
*********************************************************************** 01600020
* IF OPERANDS ARE PRESENT ON THE 'SAVE' SUBCOMMAND, CALL PARSE TO     * 01640020
* SYNTAX CHECK THEM.  IF NOT, 'SAVE' IS INTO THE 'EDIT' DATA SET.     * 01680020
*********************************************************************** 01720020
 SPACE                                                                  01760020
         TM    CASCBFFL,CAOPERND ANY OPERAND ON 'SAVE' SUBCOMMAND-      01800020
         BNO   SANOOP         IF NO,GOTO USE EDIT DATA SET.             01840020
*                             IF YES,PREPARE TO CALL PARSE.             01880020
         L     SAWR3,CAPTIBFR GET PT TO INPUT BUFFER.                   01920020
SAREPARS EQU   *                                                        01960020
         L     SAWR1,SAPCLVCN GET PT TO PARAMETER CONTROL LIST.         02000020
         LA    SADATAR,SAGETPDL SET ADDRESS OF LOOKING-AT-PDL.          02010020
SAPARSE  EQU   *                                                        02020020
         LA    SAWR2,CAPTPRSD GET ADDRESS OF ANSWER PLACE.              02040020
         STM   SAWR1,SAWR3,CATMPLST+PPLPCL-PPL SET GOTTEN POINTERS      02080020
*                             IN PARAMETER LIST.                        02120020
         LA    SAPARMR1,CATMPLST GET ADDRESS OF THIS LIST.              02160020
         LINK  EP=IKJPARS                                               02200020
         B     SAPARSBT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      02240020
SAPARSBT EQU   *              PARSE BRANCH TABLE.                       02280020
         B     O(SADATAR)     00 - SUCCESS,GO LOOK AT PDL.              02320020
         B     SANOTCOM       04 - COULDN'T PROMPT,GO INDICATE          02360020
*                                  FUNCTION NOT COMPLETED.              02400020
         B     SAATTNX        08 - ATTENTION,GO TO EXIT.                02440020
         B     SAM1           12 - BAD PARAMETERS,GO PREPARE FOR        02480020
*                                  MESSAGE CSECT.                       02520020
SAM2     EQU   *              16 - NO CORE,PREPARE FOR MESSAGE.         02560020
         LA    SAPARMR1,SAE2  RELATIVE ERROR NO.                        02600020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             02640020
SAM1     EQU   *                                                        02680020
         LA    SAPARMR1,SAE1  RELATIVE ERROR NO.                        02720020
SAM00    EQU   *                                                        02740020
         LR    SATEMPRC,SARETCDR RETURN CODE FOR INSERTION.             02760020
SAM0     EQU   *                                                        02800020
SACALLA9 EQU   *                                                        02820020
         LA    SARETREG,SAX   ADDRESS OF RETURN POINT(EXIT).            02840020
         L     SACALLAD,SASA9VCN ADDRESS OF MESSAGE CSECT.              02880020
         BR    SACALLAD       GO TO ISSUE MESSAGE.                      02920020
 SPACE                                                                  02960020
*********************************************************************** 03000020
* MOVE DATA SET NAME, MEMBER, PASSWORD INTO COMMUNICATION AREA.       * 03040020
* REMEMBER THE LENGTH OF THE MEMBER NAME AND WHETHER THE OPERAND WAS  * 03080020
* IN QUOTES.                                                          * 03120020
*********************************************************************** 03160020
 SPACE                                                                  03200020
SAGETPDL EQU   *              GET POINTER TO PARAMETER DESCRIPTOR       03240020
         L     SADATAR,CAPTPRSD LIST(PDL) FROM ANSWER PLACE.            03280020
         USING SAPDLSEC,SADATAR ESTABLISH ADDRESSABILITY TO PDL.        03320020
         TM    SAPDLDSN+SAPDLFLG,SAPDLOP WAS A DSNAME SPECIFIED-        03360020
         BNO   SAGETMEM       IF NO, GOTO GET MEMBER NAME.              03400020
         LH    SAL,SAPDLDSN+SAPDLLNG IF YES,GET DSNAME LENGTH.          03440020
         STH   SAL,CASADSNL   SAVE DSNAME LENGTH.                       03480020
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          03520020
         L     SAWR2,SAPDLDSN GET PT TO DATA SET NAME.                  03560020
         EX    SAL,SADSNP2S   MOVE DSNAME FR PDL TO COMM AREA.          03600020
SAGETMEM EQU   *                                                        03640020
         TM    SAPDLDSN+SAPDLMEM+SAPDLFLG,SAPDLOP WAS A MEMBER          03680020
*                             NAME SPECIFIED -                          03720020
         BNO   SAGETPSW       IF NO,GOTO GET PASSWORD.                  03760020
         LH    SAL,SAPDLDSN+SAPDLMEM+SAPDLLNG IF YES,GET MEMBER         03800020
*                             NAME LENGTH.                              03840020
         STH   SAL,SAMEMLNG   SAVE MEMBER NAME LNG.                     03880020
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          03920020
         L     SAWR2,SAPDLDSN+SAPDLMEM GET PT TO MEMBER NAME.           03960020
         EX    SAL,SAMEMP2S   MOVE MEMBER NAME TO COMM AREA.            04000020
SAGETPSW EQU   *                                                        04040020
         TM    SAPDLDSN+SAPDLPSW+SAPDLFLG,SAPDLOP WAS A PASSWORD        04080020
*                             SPECIFIED -                               04120020
         BNO   SAQREMEM       IF NO,GOTO REMEMBER IF OPERAND WAS        04160020
*                             ENTERED IN QUOTES.                        04200020
         LH    SAL,SAPDLDSN+SAPDLPSW+SAPDLLNG IF YES,GET LENGTH OF      04240020
*                             PASSWORD.                                 04280020
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          04320020
         L     SAWR2,SAPDLDSN+SAPDLPSW GET PT TO PASSWORD.              04360020
         EX    SAL,SAPSWP2S   MOVE PASSWORD TO COMM AREA.               04400020
SAQREMEM EQU   *                                                        04440020
         MVC   SAPDLFLS(SABYT),SAPDLDSN+SAPDLFLG SAVE FLAG BYTE FR      04480020
*                             SATA SET NAME PDE.                        04520020
         LA    SAWR1,SAFREED  GET ADDRESS OF END-OF-FREEING-CORE.       04530020
SAFREPDL EQU   *                                                        04540020
 SPACE                                                                  04560020
*********************************************************************** 04600020
* FREE THE CORE TAKEN UP BY THE PDL.                                  * 04640020
*********************************************************************** 04680020
 SPACE                                                                  04720020
         IKJRLSA CAPTPRSD     FREE THE STORAGE GOTTEN BY PARSE.         04800020
         OI    CAPRSPDL,CAFREEDL INDICATE PDL FREED.                    04805020
         BR    SAWR1          RETURN TO CALLING POINT OR CONTINUE.      04810020
SAFREED  EQU   *                                                        04820020
 SPACE                                                                  04840020
*********************************************************************** 04880020
* THIS SECTION USES THE 'DEFAULT' SERVICE ROUTINE TO FULLY-QUALIFY    * 04920020
* THE DATA SET NAME IF IT WAS NOT ENTERED IN QUOTES.  ALSO, IF        * 04960020
* 'DEFAULT' INDICATES THAT THE NAME IS IN THE CATALOGUE, A SWITCH IS  * 05000020
* SET SO THAT NO ATTEMPT IS MADE TO ALLOCATE THE DATA SET AS 'NEW'.   * 05040020
*********************************************************************** 05080020
 SPACE                                                                  05120020
         LA    SAWR1,CASADSNL GET ADDRESS OF DATA SET NAME.             05160020
         L     SAWR2,SAPSCB   GET PT TO PSCB.                           05200020
         LA    SAWR3,CADSQUAL GET PT TO QUALIFIER.                      05240020
         STM   SAWR1,SAWR3,SADFLTPB STORE GOTTEN VALUES.                05280020
         TM    SAPDLFLS,SAPDLQUO WAS DATA SET NAME QUOTED -             05320020
         BZ    SANFULLY       IF NO,GOTO TREAT UNQUALIFIED NAME.        05360020
SAFAKEDF EQU   *                                                        05380020
 SPACE                                                                  05382020
* CONTROL COMES HERE WHEN  (1) A DSNAME WAS ENTERED IN QUOTES, (2) WHEN 05384020
* NO OPERAND WAS ENTERED, (3) WHEN ONLY A MEMBER NAME WAS ENTERED (AND  05386020
* A MEMBER NAME WAS SPECIFIED FOR 'EDIT').  STRIP OFF THE LAST QUALIFI- 05388020
* ER (IF THERE IS ONLY 1 INDEX LEVEL BYPASS CALLING 'DEFAULT') AND ASK  05390020
* 'DEFAULT' TO PLACE IT BACK AGAIN.                                     05392020
 SPACE                                                                  05394020
         OI    CASCBFFL,CAOPERND SET BIT TO IND AN OPERAND WAS          05396020
*                             SPECIFIED,EVEN IF NONE WAS,TO PRE-        05398020
*                             VENT LOOPING BACK TO THIS POINT.          05400020
         OI    SAPDLFLS,SAPDLQUO SET BIT TO IND DSNAME ENTERED IN       05402020
*                             QUOTES, EVEN IF NO OPERANDS ON SAVE.      05404020
         LA    SAWR1,CASADSNL GET ADDRESS OF DATA SET NAME.             05406020
         L     SAWR2,SAPSCB   GET PT TO PSCB.                           05408020
         STM   SAWR1,SAWR2,SADFLTPB STORE GOTTEN VALUES.                05410020
         LA    SAWR3,CASADSN  GET PT TO BEGNG OF DSNAME.                05412020
         LR    SAWR1,SAWR3    SAVE IT FOR LATER USE.                    05414020
         AH    SAWR3,CASADSNL SAVE PT TO END OF DSNAME.                 05416020
         LR    SAWR2,SAWR3    START SEARCHING FOR '.' AT END OF         05418020
*                             DSNAME.                                   05420020
SASTRIP  EQU   *                                                        05422020
         BCTR  SAWR2,O        BACKSPACE WORKING POINTER.                05424020
         CR    SAWR2,SAWR1    IS THERE ONLY 1 INDEX LEVEL -             05426020
         BH    SASTRIPD       IF NO,GOTO COMPARE FOR '.' -              05428020
         LA    SARETCDR,SADF20 IF YES,FAKE A DEFAULT RET CODE 20.       05430020
         B     SALT44         GOTO BUILD MESSAGE INSERTION.             05432020
SASTRIPD EQU   *                                                        05434020
         CLI   O(SAWR2),SADOT IS THIS CHARACTER A '.' -                 05436020
         BNE   SASTRIP        IF NO,LOOP TO CONTINUE SEARCH.            05438020
         SR    SAWR3,SAWR2    CALC LNG OF '.' AND LAST QUALFR.          05440020
         BCTR  SAWR3,O        SUBTRACT 1 FOR USE IN 'EX'.               05442020
         MVC   SAQUALFR(L'SAQUALFR),SADA8O+DA08DDN-DAPB08 INITLZ        05444020
*                             AREA TO CONTAIN QUALFR TO BLANKS.         05446020
         EX    SAWR3,SAMVCQL2 SAVE QUALFR TO PASS TO 'DEFAULT'.         05448020
         EX    SAWR3,SAMVCQUL SET '.' AND QUALFR IN DSNAME TO           05450020
*                             BLANKS.                                   05452020
         LA    SAWR3,SAQUALFR GET PT TO AREA CONTAINING QUALIFIER.      05454020
         ST    SAWR3,SADFLTPB+DFPBQUAL-DFPB SET IT IN PARM BLOCK.       05456020
         SR    SAWR2,SAWR1    COMPUTE NEW LENGTH OF DSNAME.             05458020
         STH   SAWR2,CASADSNL SET IT IN DSNAME HEADER.                  05460020
         B     SACALLDF       GOTO CALL 'DEFAULT' SERVICE ROUTINE.      05462020
SANFULLY EQU   *              ON THE 'SAVE' SUBCOMMAND,                 05480020
         CLI   CASADSN,SABLNK WAS A DATA SET NAME SPEC AT ALL -         05520020
         BNE   SACMPQUL       IF YES,GOTO CMP EDIT,SAVE QUALIFIERS      05560020
         CLI   CASAMEMB,SABLNK IF NO,WAS NEITHER DATA SET NAME NOR      05566020
*                             MEMBER NAME SPECIFIED -                   05572020
         BE    SAATTNX        IF YES,USER SPECIFIED EXTRANEOUS          05578020
*                             INFORMATION AND WAS INFORMED OF THIS      05584020
*                             BY THE PARSING ROUTINE,SO GOTO EXIT.      05590020
         CLI   CAEDMEMB,SABLNK IF NO,WAS A MEMBER SPEC FOR 'EDIT'-      05600020
         BE    SASUFFIX       IF NO,GOTO IND SUFFIX DSNAME QUALFR.      05640020
         MVC   CASADSNL(L'CASADSNL+L'CASADSN),CAEDDSNL IF YES,USE       05680020
*                             EDIT DATA SET NAME FOR THE SAVE.          05720020
         B     SAFAKEDF       GO TO PRESET RETURN CODE.                 05760020
 SPACE                                                                  05800020
*********************************************************************** 05840020
* COMPARE EDIT DATA-SET-NAME-QUALIFIER WITH THE END OF THE SAVE DATA  * 05880020
* SET NAME.  IF NOT EQUAL, QUALIFIER MUST BE ADDED TO SAVE DSNAME.    * 05920020
*********************************************************************** 05960020
 SPACE                                                                  06000020
SACMPQUL EQU   *                                                        06040020
         LA    SAL,CADSQUAL+L'CADSQUAL-SABYT START AT END OF DATA-      06080020
*                             SET-NAME-QUALIFIER FOR SEARCH FOR         06120020
*                             NON-BLANK CHARACTER.                      06160020
SABLANKQ EQU   *                                                        06200020
         CLI   O(SAL),SABLNK  IS THIS A NON-BLANK -                     06240020
         BNE   SACALCL        IF YES,GO COMPUTE QUALIFIER LENGTH.       06280020
         BCT   SAL,SABLANKQ   IF NO,BACK-UP ONE BYTE,GOTO CONTINUE      06320020
*                             SEARCHING.                                06360020
SACALCL  EQU   *              CALCULATE LENGTH FOR QUALIFIER CMP.       06400020
         LA    SAWR2,CADSQUAL GET ADDRESS OF EDIT QUALIFIER.            06440020
         SR    SAL,SAWR2      ADDRESS OF LAST NON-BLANK MINUS.          06480020
*                              ADDRESS OF QUALIFIER YIELDS LENGTH       06520020
*                              OF QUALIFIER MINUS 1.                    06560020
 SPACE                                                                  06600020
*********************************************************************** 06640020
* CALCULATION- (ADDRESS OF END OF DSNAME) MINUS (QUALIFIER LENGTH)    * 06680020
*********************************************************************** 06720020
 SPACE                                                                  06760020
         LA    SAWR2,CASADSN-SABYT ADDRESS OF SAVE DSNAME MINUS 1.      06800020
         AH    SAWR2,CASADSNL ADD LENGTH OF NAME.                       06840020
         SR    SAWR2,SAL       SUBTRACT COMPARISON LENGTH.              06880020
         EX    SAL,SACLCQUL   DOES SAVE DATA SET NAME END IN            06920020
*                             THE EDIT DSNAME QUALIFIER -               06960020
         BNE   SASUFFIX       IF NO,GOTO SUFFIX QUALIFIER.              07000020
         BCTR  SAWR2,O        IF YES,LOOK AT PRECEDING CHARACTER.       07010020
         CLI   O(SAWR2),SADOT IS IT A '.' -                             07020020
         BNE   SASUFFIX       IF NO,GOTO SUFFIX QUALIFIER.              07030020
         LH    SAWR3,CASADSNL IF YES,GET DSNAME LENGTH.                 07040020
         SR    SAWR3,SAL      SUBTRACT LENGTH OF QUALIFIER              07080020
         BCTR  SAWR3,O        FROM DSNAME LENGTH.                       07120020
         EX    SAL,SAMVCQUL   BLANK-OUT QUALIFIER.                      07160020
         MVI   O(SAWR2),SABLNK BLANK-OUT THE '.' .                      07260020
         BCTR  SAWR3,O        SUBTRACT 1 FROM DSNAME LENGTH.            07360020
         STH   SAWR3,CASADSNL UPDATE DSNAME LENGTH.                     07440020
SASUFFIX EQU   *                                                        07480020
 SPACE                                                                  07640020
*********************************************************************** 07680020
* GET USERID FROM PSCB.  IF DATA SET NAME DOESN'T BEGIN WITH IT. THE  * 07720020
* DATA SET MAME MUST BE PREFIXED WITH IT.                               07760020
*********************************************************************** 07800020
 SPACE                                                                  07840020
SACMPUID EQU   *                                                        07880020
         L     SAWR2,SAPSCB   GET PT TO PSCB.                           07920020
         USING PSCB,SAWR2     ADDRESSABILITY TO PSCB.             M4206 07970021
         SR   SAL,SAL         CLEAR REGISTER FOR INSERT.          M4206 07980021
         IC   SAL,PSCBUSRL    GET LENGTH OF USERID.               M4206 07990021
         DROP  SAWR2                                              M4206 07992021
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          08000020
         EX    SAL,SACLCUID   DOES SAVE DATA SET NAME BEGIN WITH        08040020
*                             THE USERID -                              08080020
         BNE   SAIPUSID       IF NOT EQUAL, BR TO ADD USERID      M4206 08090021
         LA    SAL,CASADSN+SABYT(SAL) IF EQUAL, OBTAIN ADDR OF    M4206 08100021
*                             BYTE AFTER USERID IN DSNAME.        M4206 08110021
         CLI   O(SAL),SADOT   TEST BYTE FOR PERIOD.               M4206 08112021
         BE    SACALLDF       IF YES,GO TO CALL 'DEFAULT' ROUTINE.      08120020
SAIPUSID EQU   *                                                  M4206 08130021
         OI    SADFLTPB+DFPBCNTL-DFPB,SADFUSER IF NO,IND PREFIX         08160020
*                             USERID.                                   08200020
 SPACE                                                                  08240020
*********************************************************************** 08280020
* CALL 'DEFAULT' ROUTINE TO BUILD NAME AND EXAMINE CATALOGUE(CODE 0). * 08320020
*********************************************************************** 08360020
 SPACE                                                                  08400020
SACALLDF EQU   *                                                        08440020
         OI    SASWICHS,SADEFCAL SET INTERNAL SWITCH TO REMEMBER        08450020
*                             THAT 'DEFAULT' WAS CALLED.                08460020
         LA    SAWR1,SADFLTPB ADDRESS OF PARAMETER BLOCK INTO           08480020
         ST    SAWR1,CATMPLST+DFPLDFPB-DFPL PARAMETER LIST.             08520020
         LA    SAPARMR1,CATMPLST SET PT TO PARAMETER LIST.              08560020
         LINK  EP=IKJDFLT                                               08600020
         CH    SARETCDR,SADFGT44 DID DSNAME GROW BEYOND 44 CHAR -       08640020
         BNE   SALT44         IF NO,GOTO BUILD INSERTION.               08680020
*                             IF YES,                                   08720020
         B     SADFLTBT(SARETCDR) GO INTO BRANCH TABLE.                 08760020
 SPACE                                                                  08800020
*********************************************************************** 08840020
* BUILD THE SAVE DATA SET NAME MESSAGE-INSERTION. SAWR3 IS WORKING PTR* 08880020
*********************************************************************** 08920020
 SPACE                                                                  08960020
SALT44   EQU   *                                                        09000020
         LA    SAWR3,CADSNRC2 INITLZ WORKING POINTER.                   09040020
         LA    SAPARMR1,CASADSN SET PT TO BEGNG OF DSNAME.              09080020
         TM    SAPDLFLS,SAPDLQUO WAS DSNAME ENTERED IN QUOTES -         09120020
         BNO   SANOTQUO       IF NO,SKIP INSERTING QUOTE.               09160020
         MVI   CADSNRC2,SAQUOTE PUT ' IN INSERTION.                     09200020
         LA    SAWR3,SABYT(SAWR3) BUMP WORKING POINTER.                 09240020
         B     SAINSDSN       GOTO INSERT DSNAME.                       09280020
SANOTQUO EQU   *                                                        09320020
         L     SAWR2,SAPSCB   GET PT TO PSCB.                           09360020
         SR    SAL,SAL                                                  09400020
         IC    SAL,PSCBUSRL-PSCB(SAWR2) GET LNG OF USERID.              09440020
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          09480020
         EX    SAL,SACLCUID   DOES DSNAME BEGIN WITH USERID -           09520020
         BNE   SAINSDSN       IF NO,GOTO INSERT DSNAME.                 09560020
         LA    SAPARMR1,SAHWD(SAL,SAPARMR1) IF YES,MOVE DSNAME PT       09600020
*                             PAST USERID.                              09640020
SAINSDSN EQU   *                                                        09680020
         MVC   O(L'CASADSN,SAWR3),O(SAPARMR1) MOVE DSNAME INTO          09720020
*                             INSERTION.                                09760020
         LA    SAL,CASADSN    GET ADDRESS OF COMPLETE DSNAME.           09800020
         AH    SAL,CASADSNL   ADD LNG TO GET TO END OF DSNAME.          09840020
         SR    SAL,SAPARMR1   SUBTRACT PT TO PARTIAL DSNAME TO GET      09880020
*                             LNG OF INSERTION DSNAME.                  09920020
         AR    SAWR3,SAL      ADD TO WORKING PT TO GET DSNAME END.      09960020
         CLI   CASAMEMB,SABLNK WAS A MEMBER NAME ENTERED -              10000020
         BE    SAINSEND       IF NO,GOTO COMPLETE THE INSERTION.        10040020
         MVI   O(SAWR3),SALPAREN IF YES,INSERT A '('.                   10080020
         MVC   SABYT(L'CASAMEMB,SAWR3),CASAMEMB INSERT MEMBER NAME.     10120020
         LH    SAL,SAMEMLNG   GET LNG OF MEMBER NAME.                   10160020
         AR    SAWR3,SAL      BUMP WORKING PT.                          10200020
         MVI   SABYT(SAWR3),SARPAREN INSERT A ')'.                      10240020
         LA    SAWR3,SAHWD(SAWR3) BUMP WORKING PT.                      10280020
SAINSEND EQU   *                                                        10320020
         CLI   CADSNRC2,SAQUOTE IS THERE AN OPENING QUOTE -             10360020
         BNE   SAINSL         IF NO,GOTO COMPUTE INSERTION LENGTH.      10400020
         MVI   O(SAWR3),SAQUOTE IF YES,INSERT A CLOSING QUOTE.          10440020
         LA    SAWR3,SABYT(SAWR3) BUMP WORKING PT.                      10480020
SAINSL   EQU   *                                                        10520020
         LA    SAWR1,CADSNLN2 GET ADDRESS OF BEGNG OF INSERTION.        10560020
         SR    SAWR3,SAWR1    SUBTRACT IT FROM WORKING PT TO GET        10600020
*                             INSERTION LENGTH.                         10640020
         STH   SAWR3,CADSNLN2 PUT LNG INTO INSERTION HEADER.            10680020
 SPACE                                                                  10720020
*********************************************************************** 10760020
* THE DATA SET NAME INSERTION IS NOW BUILT. BRANCH ON 'DEFAULT' R.C.  * 10800020
*********************************************************************** 10840020
 SPACE                                                                  10880020
         B     SADFLTBT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      10920020
SADFLTBT EQU   *              DEFAULT BRANCH TABLE.                     10960020
         B     SAINCAT        00 - DSNAME WAS IN CATALOGUE,GO TURN      11000020
*                                  ON SWITCH TO REMEMBER THIS.          11040020
         B     SAM3           04 - UNABLE TO PROMPT,GO PREPARE FOR      11080020
*                                  MESSAGE CSECT.                       11120020
         B     SAM4           08 - DSNAME LNG IS OVERGROWN,GO PRE-      11160020
*                                  PARE FOR MESSAGE CSECT.              11200020
         B     SANOTCOM       12 - CTLG I/O ERROR,SYNTAX ERROR,OR       11240020
*                                  CTLG DATA SET NOT AVAILABLE,GO       11280020
*                                  IND FUNCTION NOT COMPLETED.          11320020
         B     SAM10          16 - DATA SET EXISTS AT ANOTHER IN-       11360020
*                                  DEX LEVEL,GO PREPARE FOR MES-        11400020
*                                  SAGE CSECT.                          11440020
         B     SACMPE@S       20 - NOT IN CTLG,GOTO CMP SAVE,EDIT       11480020
*                                  DSNAMES(INCLUDING MEMBERS).          11520020
         B     SAATTNX        24 - ATTENTION,GO TO EXIT.                11560020
         B     SAM3           28 - INVALID PARAMETERS,GO PREPARE        11600020
*                                  FOR MESSAGE CSECT.                   11640020
         B     SAM3           32 - PROMPTING REQUIRED,GO PREPARE        11680020
*                                  DOR MESSAGE CSECT.                   11720020
         B     SACMPE@S       36 - NOT IN CTLG,GOTO CMP SAVE,EDIT       11760020
*                                  DSNAMES(INCLUDING MEMBERS).          11800020
SAM10    EQU   *                                                        11810020
         LA    SAPARMR1,SAE25 RELATIVE ERROR NO.                        11820020
         B     SAM0           BRANCH TO ISSUE ERROR MESSAGE.            11830020
SAM3     EQU   *                                                        11840020
         LA    SAPARMR1,SAE3  RELATIVE ERROR NO.                        11920020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           11960020
SAM4     EQU   *                                                        12000020
         LA    SAPARMR1,SAE4  RELATIVE ERROR NO.                        12040020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             12080020
SAM5     EQU   *                                                        12120020
         LA    SAPARMR1,SAE5  RELATIVE ERROR NO.                        12160020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           12200020
SAINCAT  EQU   *                                                        12240020
         OI    SASWICHS,SAINCTLG 'DEFAULT' FOUND DATA SET NAME IN       12280020
*                             THE CATALOGUE- SET SWITCH TO REMEM-       12320020
*                             BER THIS.                                 12360020
 SPACE                                                                  12400020
*********************************************************************** 12440020
* COMPARE THE 'EDIT' AND 'SAVE' DATA SET NAMES (AND MEMBER NAMES, IF  * 12480020
* ANY), AND UPDATE THE SAVE DATA SET NAME FIELDS IN THE COMMUNICATION * 12520020
* AREA, THE DATA SET NAME MESSAGE INSERTION, AND THE SWITCHES WHICH   * 12560020
* REMEMBER EQUALITY OF 'EDIT' AND 'SAVE' DATA SET AND MEMBER NAMES.   * 12600020
*********************************************************************** 12640020
 SPACE                                                                  12680020
SACMPE@S EQU   *                                                        12720020
         CLC   CASADSN(L'CASADSN+L'CASAMEMB),CAEDDSN DOES THE SAVE      12760020
*                        DSNAME(MEMBER) = THE EDIT DSNAME(MEMBER)-      12800020
         BE    SADSNE2S       IF YES,GOTO MOVE EDIT DSNAME,MEMBER       12840020
*                             NAME,DDNAME TO CORRESPONDING SLOTS        12880020
*                             FOR SAVE AND REMEMBER THAT EDIT DSN=      12920020
*                             SAVE DSN,EDIT DS(MEM)=SAVE DS(MEM).       12960020
         CLC   CASADSN(L'CASADSN),CAEDDSN IF NO,ARE THE DATA SET        13000020
*                             NAMES,AT LEAST,THE SAME -                 13040020
         BNE   SADECIDE       IF NO,GOTO FIND IF MEMBER SPECIFIED,      13080020
*                             AND THEREBY DECIDE WHETHER TO TREAT       13120020
*                             DATA SET AS PARTITIONED OR SEQUENTL.      13160020
         OI    SASWICHS,SAS@EEQ2 IF YES,REMEMBER DSNAME EQUALITY        13200020
*                             BY SETTING SWITCH.                        13240020
         CLI   CASAMEMB,SABLNK WAS MEMBER NAME SPECIFIED ON SAVE -      13280020
         BE    SAINSE2S       IF NO,GOTO MOVE EDIT MESSAGE INSER-       13320020
*                             TION,DSNAME,MEMBER NAME,DDNAME TO         13360020
*                             CORRESPONDING SLOTS FOR SAVE AND          13400020
*                             REMEMBER THAT EDIT AND SAVE DSNAMES       13440020
*                             AND MEMBER NAMES ARE NOW THE SAME.        13480020
         CLI   CAEDMEMB,SABLNK IF YES,WAS MEMBER NAME SPECIFIED ON      13520020
*                             EDIT -                                    13560020
         BNE   SAPO           IF YES,GOTO ALLOCATE PDS.                 13600020
*                             IF NO,PREPARE TO SEND MESSAGE INDI-       13640020
*                             CATING THAT DATA SET IS NOT A PDS.        13680020
         LA    SAWR1,CADSNPTR                                           13720020
         ST    SAWR1,SAMEMPTR PT TO 2ND INSERTION INTO HEADER.          13760020
         LA    SAWR1,M311IN1                                            13800020
         STH   SAWR1,SAMEMOFF OFFSET TO 1ST INSERTION INTO HEADER.      13840020
         LH    SAL,SAMEMLNG   GET LNG OF NAME.                          13860020
         LA    SAL,L'SAMEMLEN+L'SAMEMOFF(SAL) ADD HEADER LENGTH.        13880020
         STH   SAL,SAMEMLEN   LENGTH OF 1ST INSERTION INTO HEADER.      13920020
         XC    CADSNPTR(L'CADSNPTR),CADSNPTR NO THIRD INSERTION.        13960020
         LA    SAWR1,M311IN2                                            14000020
         STH   SAWR1,CADSNOFF OFFSET TO 2ND INSERTION INTO HEADER.      14040020
         MVC   SAMEMREC(L'SAMEMREC),CASAMEMB MEMBER NAME INSERT.        14050020
         LA    SAWR3,SAINSE2S GET ADDRESS OF BRANCH POINT.              14060020
SA311RTN EQU   *                                                        14070020
         SR    SAWR1,SAWR1    NO 2ND-LEVEL MSG.                         14080020
         LR    SAWR2,SAWR1    NO 2ND-LEVEL INSERTIONS.                  14120020
         IKJEBEML M311,(SAWR1),SAMEMPTR,(SAWR2),MF=(E,SA10AREA)         14200020
         TM    CACFLAG4,CAINPROC IS INPUT SOURCE AN IN-CORE PROC -      14210020
         BO    SANOTCOM       IF YES,GO IND FUNCTION NOT COMPLETE.      14220020
         BR    SAWR3          RETURN TO CALLING POINT, OR               14240020
*                             GOTO MOVE EDIT MESSAGE INSERTION,         14260020
*                             DSNAME,MEMBER NAME,DDNAME TO CORRE-       14280020
*                             SPONDING SLOTS FOR SAVE AND REMEMBER      14320020
*                             THAT EDIT AND SAVE DSNAMES AND            14360020
*                             MEMBER NAMES ARE NOW ALIKE.               14400020
 SPACE                                                                  14440020
*********************************************************************** 14480020
* THIS SECTION TRANSFERS INFORMATION IN THE COMMUNICATION AREA FROM   * 14520020
* THE 'EDIT' SLOT TO THE 'SAVE' SLOT.                                 * 14560020
*********************************************************************** 14600020
 SPACE                                                                  14640020
SANOOP   EQU   *                                                        14680020
         MVC   CASAPSWD(L'CASAPSWD),CAEDPSWD TRANSFER PASSWORD.         14720020
SAINSE2S EQU   *                                                        14760020
         MVC   CADSNPT2(L'CADSNPT2+L'CADSNOF2+L'CADSNLN2+L'CADSNRC2),CAC14800020
               DSNPTR         TRANSFER DSNAME MSG INSERTION.            14840020
SADSNE2S EQU   *                                                        14880020
         MVC   CASADSNL(L'CASADSNL+L'CASADSN+L'CASAMEMB+L'CASADDN),CAEDC14920020
               DSNL           TRANSFER DATA SET NAME,MEMBER NAME,       14960020
*                             DDNAME.                                   15000020
         OI    SASWICHS,SAS@EEQ1+SAS@EEQ2 SET SWITCHES TO REMEM-        15040020
*                             BER SAVE AND EDIT DSNAMES,MEMBERS         15080020
*                             ARE IDENTICAL.                            15120020
         LA    SAWR1,CASAMEMB+L'CASAMEMB-SABYT START AT END OF          15123020
*                             MEMBER NAME.                              15126020
SAENDMQ  EQU   *                                                        15129020
         CLI   O(SAWR1),SABLNK IS THIS CHARACTER A BLANK -              15132020
         BNE   SAENDM         IF NO,END OF MEMBER NAME IS FOUND.        15135020
         BCT   SAWR1,SAENDMQ  IF YES,CONTINUE QUEST FOR END.            15138020
SAENDM   EQU   *                                                        15141020
         LA    SAWR2,CASAMEMB-SABYT GET PT TO BEGNG OF NAME.            15144020
         SR    SAWR1,SAWR2    CALC LNG OF MEMBER NAME.                  15147020
         STH   SAWR1,SAMEMLNG SAVE LENGTH.                              15150020
 SPACE                                                                  15160020
*********************************************************************** 15200020
* THE 'SAVE' SUBCOMMAND (1) HAD NO OPERANDS, (2) SPECIFIED THE EDIT   * 15240020
* DATA SET, OR (3) SPECIFIED A DATA SET WHICH DEFAULTED TO THE EDIT   * 15280020
* DATA SET.  IF THE EDIT DATA SET IS NOW ALLOCATED, PREPARE FOR THE   * 15320020
* FINAL COPY.  IF NOT, GO TO DECIDE WHETHER TO TREAT THE DATA SET AS  * 15360020
* PARTITIONED OR AS SEQUENTIAL.                                       * 15400020
*********************************************************************** 15440020
 SPACE                                                                  15480020
         TM    CAEDFLAG,CAEDALOC IS EDIT DATA SET ALLOCATED -           15520020
         BO    SAPOINT1       IF YES,GO PREPARE FOR FINAL COPY.         15560020
 SPACE                                                                  15567020
* IF THERE WERE NO SUBCOMMAND OPERANDS, BRANCH BACK TO THE INVOKATION   15574020
* OF THE 'DEFAULT' ROUTINE BEFORE ALLOCATING, IN ORDER TO OBTAIN MORE   15581020
* SPECIFIC INFORMATION ABOUT THE LOCATE RETURN CODE THAN MIGHT BE       15588020
* OBTAINED LATER FROM DAIR (AFTER ATTEMPTED ALLOCATION WITH DISP=(NEW,  15595020
* CATLG,KEEP) WHICH RESULTS IN DAIR RET CODE 8, CTRC=0008).             15602020
 SPACE                                                                  15609020
         TM    CASCBFFL,CAOPERND ANY OPERAND ON 'SAVE' SUBCOMMAND-      15616020
         BNO   SAFAKEDF       IF NO,GO BACK TO CALL 'DEFAULT'.          15623020
*                             IF YES,CONTINUE.                          15630020
 SPACE                                                                  15640020
*********************************************************************** 15680020
* THE EDIT DATA SET IS NOT ALLOCATED, AND THE NAME OF THE DATA SET TO * 15720020
* BE SAVED-INTO IS IN THE COMMUNICATION AREA IN THE 'SAVE' SLOT.  IF  * 15760020
* A MEMBER NAME WAS SPECIFIED OR IMPLIED TREAT THE DATA SET AS PARTI- * 15800020
* TIONED.  OTHERWISE TREAT IT AS SEQUENTIAL.                          * 15840020
*********************************************************************** 15880020
 SPACE                                                                  15920020
SADECIDE EQU   *                                                        15960020
         CLI   CASAMEMB,SABLNK WAS A MEMBER NAME SPECIFIED -            16000020
         BNE   SAPO           IF YES,GOTO ALLOCATE PDS (MOD).           16040020
*                             IF NO,ALLOCATE SEQ DATA SET (NEW).        16080020
 SPACE                                                                  16120020
*********************************************************************** 16160020
* ATTEMPT TO ALLOCATE A SEQUENTIAL DATA SET, DISP=NEW,CATLG, UNLESS   * 16200020
* THE 'DEFAULT' SERVICE ROUTINE FOUND THE DATA SET CATALOGUED (IN     * 16240020
* THAT EVENT, GO TO ISSUE A MESSAGE THAT DATA SET IS NOT NEW.).       * 16280020
*********************************************************************** 16320020
 SPACE                                                                  16360020
SAPS     EQU   *                                                        16400020
         TM    SASWICHS,SAINCTLG WAS DSNAME CATALOGUED -                16440020
         BO    SANOTNEW       IF YES,GOTO ISSUE MESSAGE.                16480020
         MVC   SADAIRPB(SADA8OL),SADA8O IF NO,INITLZ DAIR PARAME-       16500020
*                             TER BLOCK.                                16520020
         MVC   SADAIRPB+DA08DSP1-DAPB08(DA08CTL+L'DA08CTL-DA08DSP1),SADC16540020
               A8N            TAIL OF PARM BLOCK.                       16560020
         MVC   SADAIRPB+DA08PSWD-DAPB08(L'DA08PSWD),CASAPSWD            16600020
         LA    SAWR1,CASADSNL PT TO DATA SET NAME INTO PARAMETER        16640020
         ST    SAWR1,SADAIRPB+DA08PDSN-DAPB08 BLOCK.                    16680020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     16720020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       16760020
         LA    SARETREG,SAPUTEND GET PT TO END OF COMPUTATION.          16761020
SACMPUTE EQU   *                                                        16762020
         LH    SAWR3,CABLKS   GET BLOCKSIZE OF UTILITY DATA SET.        16763020
         ST    SAWR3,SADAIRPB+DA08BLK-DAPB08 SET IT IN PARM BLOCK.      16764020
 SPACE                                                                  16765020
* COMPUTE PRIMARY AND SECONDARY SPACE QUANTITIES, 'Q' AND 'I'.          16766020
* Q = ((ALPHA+CAUTILNO) X LRECL / BLKSIZE) + 1                          16767020
* I = (BETA X LRECL / BLKSIZE) + 1                                      16768020
 SPACE                                                                  16769020
         LH    SAPARMR1,CALRECL GET LRECL OF UTILITY DATA SET.          16770020
         TM    CACFLAG2,CARECFM IS DATA SET RECFM FIXED -               16771020
         BZ    SAVLRL         IF NO,GOTO USE LRECL GOTTEN.              16772020
         SH    SAPARMR1,SACWL IF YES,SUBTRACT CONTROL WORD LENGTH.      16773020
SAVLRL   EQU   *                                                        16774020
         LA    SAWR2,SAALPHA  GET PRIMARY SPACE CONSTANT(ALPHA).        16775020
         LA    SARETCDR,SABETA GET SECONDARY SPACE CONSTANT(BETA).      16776020
         CLI   CASAMEMB,SABLNK IS SAVE DATA SET A PDS -                 16777020
         BE    SAALBEOK       IF NO,GOTO USE GOTTEN CONSTANTS.          16778020
         LA    SAWR2,SAALPHA2(SAWR2) IF YES,INCREASE ALPHA.             16779020
         LA    SARETCDR,SABETA2(SARETCDR) INCREASE BETA.                16780020
SAALBEOK EQU   *                                                        16781020
         A     SAWR2,CAUTILNO ADD NO. OF UTILITY RECORDS TO ALPHA.      16782020
         MR    SAWR1,SAPARMR1 MULTIPLY BY LRECL.                        16783020
         DR    SAWR1,SAWR3    DIVIDE BY BLKSIZE.                        16784020
         LA    SAWR2,SABYT(SAWR2) ADD 1 IN CASE RESULT IS ZERO.         16785020
         ST    SAWR2,SADAIRPB+DA08PQTY-DAPB08 SET Q IN PARM BLOCK.      16786020
         LR    SAWR2,SARETCDR TRANSFER BETA TO MULTIPLICAND REG.        16787020
         MR    SAWR1,SAPARMR1 MULTIPLY BETA BY LRECL.                   16788020
         DR    SAWR1,SAWR3    DIVIDE BY BLKSIZE.                        16789020
         LA    SAWR2,SABYT(SAWR2) ADD 1 IN CASE RESULT IS ZERO.         16790020
         ST    SAWR2,SADAIRPB+DA08SQTY-DAPB08 SET I IN PARM BLOCK.      16791020
         BR    SARETREG       RETURN TO CALLING POINT OR CONTINUE.      16792020
SAPUTEND EQU   *                                                        16793020
 SPACE                                                                  16794020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            16834020
         CH    SARETCDR,SAOLDRC WAS DATA SET ALREADY ALLOCATED -        16844020
         BE    SANOTNEW       IF YES,GOTO PROMPT FOR NEW NAME OR        16854020
*                             CARRIAGE RETURN.                          16864020
         CH    SARETCDR,SARC16 END OF BRANCH TABLE -            A59609  16868021
         BH    SAM6            IF HIGHER,RETURN = 48 OR         A59609  16872021
*                              UNEXPECTED RETURN CODE           A59609  16876021
         B     SADA08BT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      16880020
SADA08BT EQU   *              DAIR BRANCH TABLE.                        16920020
         B     SAPICKDD       00 - SUCCESS,GO PICK UP DDNAME.           16960020
         B     SAM6           04 - BAD PARAMETERS,GO PREPARE FOR        17000020
*                                  MESSAGE CSECT.                       17040020
         B     SACATERR       08 - CATALOG MANAGEMENT ERROR,GOTO        17080020
*                                  PREPARE FOR DIAGNOSIS.               17120020
         B     SAALCERR       12 - DYNAMIC ALLOCATION ERROR,GOTO        17160020
*                                  PREPARE FOR DIAGNOSIS.               17200020
         B     SAM7           16 - NO TIOT ENTRIES AVAILABLE,GOTO       17240020
*                                  PREPARE FOR MESSAGE CSECT.           17280020
SAM6     EQU   *                                                        17320020
         CH    SARETCDR,SARC48 TEST FOR RC = 48                 A59609  17340021
         BE    SANOTCOM       NO MESSAGE,ALREADY ISSUED BY DAIR A59609  17360021
         LA    SAPARMR1,SAE6  RELATIVE ERROR NO.                        17400020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           17440020
SAM7     EQU   *                                                        17480020
         LA    SAPARMR1,SAE7  RELATIVE ERROR NO.                        17520020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             17560020
SACATERR EQU   *                                                        17600020
         BAL   SARETREG,SACADIAG GOTO DIAGNOSE CATALOG ERROR,           17640020
*                             RETURN HERE IF NO MESSAGE IS TO BE        17680020
*                             ISSUED.                                   17720020
         B     SANOTNEW       GOTO PROMPT FOR CARRIAGE RETURN OR        17760020
*                             NEW NAME.                                 17800020
SAALCERR EQU   *                                                        17840020
         BAL   SARETREG,SAALDIAG GOTO DIAGNOSE ALLOCATION ERROR,        17880020
*                             RETURN HERE IF NO MESSAGE IS TO BE        17920020
*                             ISSUED.                                   17960020
 SPACE                                                                  18000020
*********************************************************************** 18040020
* DATA SET COULD NOT BE ALLOCATED AS NEW AND NO MESSAGE IS TO BE      * 18080020
* ISSUED, OR 'DEFAULT' FOUND THE FULLY-QUALIFIED DATA SET NAME IN THE * 18120020
* CATALOG. SEND MESSAGE INDICATING THAT DATA SET IS NOT NEW, AND      * 18160020
* PROMPT FOR ANOTHER NAME OR A CARRIAGE RETURN(IF CR,USE SAME NAME).  * 18200020
*********************************************************************** 18240020
 SPACE                                                                  18280020
SANOTNEW EQU   *                                                        18320020
         LA    SAWR2,SAPREPUT SET ADDRESS OF END OF MS-INVOKATION.      18330020
SAEXISTS EQU   *                                                        18340020
         MVC   SA10AREA(SAMLLSTL),SAMNOTNU INITLZ MS PARM LIST.         18360020
         LA    SAWR1,M339IN1  GET OFFSET DSNAME INSERTION.              18400020
         STH   SAWR1,CADSNOF2 SET IT IN INSERTION HEADER.               18440020
         IKJEBEML ,,CADSNPT2,,MF=(E,SA10AREA)                           18480020
         XC    SAPTGTPB(SAPUGTL),SAPTGTPB INITLZ PUTGET PARM     A42951 18520020
*                             BLOCK.                                    18560020
         BR    SAWR2          RETURN TO CALLING POINT OR CONTINUE.      18570020
SAPREPUT EQU   *                                                        18580020
         TM    CACFLAG4,CAINPROC IS INPUT SOURCE AN IN-CORE PROC -      18585020
         BO    SACR           IF YES,SKIP PROMPT FOR NEW NAME OR        18590020
*                             CARRIAGE RETURN.                          18595020
         L     SAWR1,SAPUGVCN GET ADDRESS OF OUTPUT.                    18600020
         LA    SAWR2,SAPTGT0  SET ADDRESS OF INPUT EXAMINATION.         18610020
SAPUTGET EQU   *                                                        18620020
         PUTGET PARM=SAPTGTPB,OUTPUT=((SAWR1),SINGLE,PROMPT),          C18640020
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),TERMGET=(EDIT,WAIT), C18680020
               MF=(E,CATMPLST)                                          18720020
         B     SAPTGTBT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      18760020
SAPTGTBT EQU   *              PUTGET BRANCH TABLE.                      18800020
         BR    SAWR2          00 - SUCCESS,GO LOOK AT INPUT.            18810020
SARC4714 DC    XL2'4714'      DYNAMIC ALLOCN RETURN CODE AFTER          18820020
*                             ATTEMPTED ALLOCN WITH DISP=(NEW,          18830020
*                             CATLG),SIGNIFYING NO SPACE AVAILABLE      18840020
*                             (DADSM RETURN CODE X'14').                18850020
         B     O(SAWR2)       04 - LIKEWISE,INPUT NOT FR TERMINAL.      18880020
         B     SAATTNX        08 - ATTENTION,GOTO EXIT.                 18920020
         B     SANOTCOM       12 - CAN'T PROMPT,GO INDICATE             18960020
*                                  FUNCTION NOT COMPLETED.              19000020
         B     SAM8           16 - NO OUTPUT,GO PREPARE FOR             19040020
*                                  MESSAGE CSECT.                       19080020
         B     SAM8           20 - NO INPUT,GO PREPARE FOR MESSAGE      19120020
*                                  CSECT.                               19160020
         B     SAM8           24 - BAD PARAMETERS,GO PREPARE FOR        19200020
*                                  MESSAGE CSECT.                       19240020
         B     SAM2           28 - NO CORE,GO PREPARE FOR MESSAGE       19280020
*                                  CSECT.                               19320020
SAM8     EQU   *                                                        19360020
         LA    SAPARMR1,SAE8  RELATIVE ERROR NO.                        19400020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           19460020
 SPACE                                                                  19520020
*********************************************************************** 19560020
* 'PUTGET' OBTAINED A REPLY TO THE PROMPT.  SAVE THE REPLY, FREE THE  * 19600020
* CORE GOTTEN, AND TEST THE REPLY.  IF A CARRIAGE-RETURN, CONTINUE BY * 19640020
* ATTEMPTING TO ALLOCATE THE DATA SET AS OLD.  OTHERWISE RECALL PARSE * 19680020
* WITH THE NEW INPUT.                                                   19720020
*********************************************************************** 19760020
 SPACE                                                                  19800020
SAPTGT0  EQU   *                                                        19840020
         LA    SAWR3,SAFREEND SET ADDRESS OF END-OF-FREEMAIN.           19850020
SAFREEMN EQU   *                                                        19860020
         L     SAWR2,SAPTGTPB+PGPBIBUF-PGPB GET PT TO INPUT.            19880020
         MVC   SAPTGTIN(SAFF),O(SAWR2) SAVE INPUT.                      19920020
         LH    SAL,O(SAWR2)   GET LENGTH OF INPUT BUFFER.               19960020
         FREEMAIN E,LV=(SAL),A=SAPTGTPB+12,SP=1,MF=(E,SAFREEME)         20000020
         LA    SAWR2,SAWD     LENGTH OF HEADER.                         20040020
         CR    SAL,SAWR2      IS INPUT A HEADER ONLY -                  20080020
         BR    SAWR3          RETURN TO CALLING POINT OR CONTINUE.      20090020
SAFREEND EQU   *                                                        20100020
         BNH   SACR           IF YES,GOTO ALLOCATE AS OLD.              20120020
         BAL   SARETREG,SAREINIT (GOTO REINITLZ STORAGE.)               20160020
         LA    SAWR3,SAPTGTIN IF NO,SET PT TO INPUT BUFFER.             20200020
         NI    SASWICHS,SAEDOL RESET SWITCHES EXCEPT 'EDIT OLD'.        20220020
         B     SAREPARS       GO TO RECALL PARSE.                       20240020
SACR     EQU   *                                                        20280020
 SPACE                                                                  20320020
*********************************************************************** 20360020
* ATTEMPT TO ALLOCATE DATA SET WITH DISPOSITION (OLD,KEEP).           * 20400020
*********************************************************************** 20440020
 SPACE                                                                  20480020
         MVC   SADAIRPB(SADA8OL),SADA8O INITLZ DAIR PARAMETER           20520020
*                             BLOCK.                                    20560020
         MVC   SADAIRPB+DA08PSWD-DAPB08(L'DA08PSWD),CASAPSWD            20600020
         LA    SAWR1,CASADSNL PT TO DATA SET NAME INTO PARAMETER        20640020
         ST    SAWR1,SADAIRPB+DA08PDSN-DAPB08 BLOCK.                    20680020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     20720020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       20760020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            20820020
SADA8EOT CH    SARETCDR,SARC16 END OF BRANCH TABLE ?            A59609  20830021
         BH    SAM6            IF HIGHER,UNEXPECTED RC OR       A59609  20840021
*                              RC = 48                          A59609  20850021
         B     SADA8BT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.       20880020
SADA8BT  EQU   *                                                        20920020
         B     SAPSTEST       00 - SUCCESS,GO SEE IF DATA SET IS        20960020
*                                  REALLY SEQUENTIAL.                   21000020
         B     SAM6           04 - BAD PARAMETERS,GO PREPARE FOR        21040020
*                                  MESSAGE CSECT.                       21080020
         B     SACATER2       08 - CATALOG MANAGEMENT ERROR,GOTO        21120020
*                                  PREPARE FOR DIAGNOSIS.               21160020
         B     SAALCER2       12 - DYNAMIC ALLOCATION ERROR,GOTO        21200020
*                                  PREPARE FOR DIAGNOSIS.               21240020
         B     SAM7           16 - NO TIOT ENTRIES AVAILABLE,GOTO       21280020
*                                  PREPARE FOR MESSAGE CSECT.           21320020
SACATER2 EQU   *                                                        21360020
         BAL   SARETREG,SACADIAG GOTO DIAGNOSE CATALOG ERROR,           21400020
*                             RETURN HERE IF NO MESSAGE ISSUED.         21440020
SAM14    EQU   *                                                        21460020
         LA    SAPARMR1,SAE9  RELATIVE ERROR NO.                        21480020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             21520020
SAALCER2 EQU   *                                                        21560020
         BAL   SARETREG,SAALDIAG GOTO DIAGNOSE ALLOCATION ERROR,        21600020
*                             RETURN HERE IF NO MESSAGE ISSUED.         21640020
SAM16    EQU   *                                                        21660020
         LA    SAPARMR1,SAE10 RELATIVE ERROR NO.                        21680020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             21720020
 SPACE                                                                  21760020
*********************************************************************** 21800020
* DATA SET HAS BEEN ALLOCATED (OLD,KEEP), ON THE ASSUMPTION THAT IT   * 21840020
* IS SEQUENTIAL.  IF IT IS INDEED SEQUENTIAL, BRANCH TO PICK UP       * 21880020
* DDNAME, ETC.  IF IT IS PARTITIONED, UNALLOCATE IT AND BRANCH TO THE * 21920020
* SECTION WHICH TREATS PARTITIONED DATA SETS (USING 'TEMPNAME' AS THE * 21960020
* MEMBER NAME.  FOR ANY OTHER DSORG ISSUE AN ERROR MESSAGE.           * 22000020
*********************************************************************** 22040020
 SPACE                                                                  22080020
SAPSTEST EQU   *                                                        22120020
         TM    SADAIRPB+DA08DSO-DAPB08,DS1ORGPS IS DATA SET REALLY      22160020
*                             PHYSICAL SEQUENTIAL -                     22200020
         BO    SAPIKDD2       IF YES,GOTO PICK UP DDNAME.               22240020
         TM    SADAIRPB+DA08DSO-DAPB08,DS1ORGPO IF NO,IS DATA SET       22280020
*                             PARTITIONED -                             22320020
         BO    SARELYPO       IF YES,GOTO UNALLOCATE DATA SET.          22340020
         CLI   SADAIRPB+DA08DSO-DAPB08,O IF NO,IS DSORG ZERO -          22370020
         BE    SAPIKDD2       IF YES,GOTO PICK UP DDNAME.               22380020
         LA    SAPARMR1,SAE11 IF NO,SET RELATIVE MESSAGE NO.            22400020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             22480020
SARELYPO EQU   *                                                        22560020
 SPACE                                                                  22600020
*********************************************************************** 22640020
* DATA SET TURNED OUT TO BE PARTITIONED.  UNALLOCATE IT, USE          * 22680020
* 'TEMPNAME' AS MEMBER NAME SINCE NONE WAS SPECIFIED, AND UPDATE      * 22720020
* DATA-SET-NAME MESSAGE-INSERTION(S).                                 * 22760020
*********************************************************************** 22800020
 SPACE                                                                  22840020
         LM    SAWR1,SAWR2,SADAIRPB+DA08DDN-DAPB08 SAVE DDNAME.         22880020
         MVC   SADAIRPB(SADA18L),SADA18 INITLZ PARAMETER BLOCK.         22920020
         STM   SAWR1,SAWR2,SADAIRPB+DA18DDN-DAPB18 RESTORE DDNAME.      22960020
         LA    SAWR1,SA18END  GET ADDRESS OF END-OF-UNALLOCN.           22970020
SAUNALLO EQU   *                                                        22980020
         LA    SAPARMR1,CATMPLST SET ADDRESS OF PARM LIST.              23000020
         TM    CAATTN,CAATTNIS IF ATTENTION WAS ISSUED BYPASS CALL      23010020
         BO    SAATTNX        TO DAIR,GOTO ATTENTION EXIT.              23020020
         LINK  EP=IKJDAIR                                               23040020
         TM    CAATTN,CAATTNIS IF ATTENTION WAS ISSUED GO               23043020
         BO    SAATTNX        IMMEDIATELY TO ATTENTION EXIT.            23046020
         BR    SAWR1          RETURN TO CALLING POINT OR CONYINUE.      23050020
SA18END  EQU   *                                                        23060020
         LA    SAWR1,SATEMPNM GET ADDRESS TO GOTO IF SUCCESSFUL.        23070020
SAUNALBR EQU   *                                                        23080020
         NI    CASAFLAG,SAFF-CASAALOC IND DATA SET UNALLOCATED SO       23090020
*                             UNALLOCN IS NOT ATTEMPTED AGAIN.          23100020
         CH    SARETCDR,SARC28 END OF BRANCH TABLE ?            A59609  23102021
         BH    SAM6            IF HIGHER,UNEXPECTED RC OR       A59609  23104021
*                              RC = 48                          A59609  23106021
         B     SADA18BT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      23110020
SADA18BT EQU   *                                                        23120020
         BR    SAWR1          00 - SUCCESSFUL UNALLOCN,CONTINUE.        23122020
SAOLDRC  DC    H'32'          DAIR RETURN CODE AFTER ATTEMPTED          23124020
*                             ALLOCATION, SIGNIFYING THAT EITHER        23126020
*                             (1) DATASET NOT PERMANENTLY ALLOCD,       23128020
*                             REQUESTED STATUS=NEW,AND ALLOCD DISP      23130020
*                             IS NOT 'DELETE' OR (2) DATASET PER-       23132020
*                             MANENTLY ALLOCD AND REQUESTED STATUS      23134020
*                             = NEW.                                    23136020
         B     SAM6           04 - BAD PARAMETERS,GO PREPARE FOR        23140020
*                                  MESSAGE CSECT.                       23150020
         B     SAM11          08 - CATALOG MANAGEMENT ERROR,GO          23160020
*                                  PREPARE FOR MESSAGE CSECT.           23170020
         B     SAM12          12 - DYNAMIC ALLOCATION ERROR,GO          23180020
*                                  PREPARE FOR MESSAGE CSECT.           23190020
         B     SAM6           16 - IMPOSSIBLE,GO PREPARE FOR MSG.       23200020
         B     SAM6           20 - IMPOSSIBLE,GO PREPARE FOR MSG.       23210020
         B     SAM6           24 - IMPOSSIBLE,GO PREPARE FOR MSG.       23220020
         BR    SAWR1          28 - IGNORE.                              23230020
SAM11    EQU   *                                                        23240020
         LA    SAPARMR1,SAE26 RELATIVE ERROR NO.                        23250020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             23260020
SAM12    EQU   *                                                        23270020
         LA    SAPARMR1,SAE27 RELATIVE ERROR NO.                        23280020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             23290020
SATEMPNM EQU   *                                                        23320020
         MVC   CASAMEMB(L'CASAMEMB),TEMPNAME MOVE 'TEMPNAME' TO         23360020
*                             SAVE MEMBER NAME SLOT.                    23400020
         LA    SAWR1,SADWD    GET LNG OF TEMPNAME.                      23410020
         STH   SAWR1,SAMEMLNG SAVE LNG.                                 23420020
 SPACE                                                                  23440020
* ADD MEMBER NAME TO DSNAME MESSAGE INSERTION.                          23480020
 SPACE                                                                  23520020
         LH    SAL,CADSNLN2   GET LNG OF MESSAGE INSERTION.             23560020
         LA    SAWR2,CADSNLN2(SAL) GET PT PAST DSNAME IN INSERT.        23600020
         CLI   CADSNRC2,SAQUOTE IS NAME IN QUOTES -                     23640020
         BNE   SAADDMEM       IF NO,GOTO MOVE IN MEMBER NAME.           23680020
         BCTR  SAWR2,O        IF YES,BACK UP POINTER TO CLOSING '.      23720020
SAADDMEM EQU   *                                                        23760020
         MVC   O(L'TEMPNAM0+L'TEMPNAME,SAWR2),TEMPNAM0 MOVE IN THE      23800020
*                             FOLLOWING TEXT- (TEMPNAME)'.              23840020
         LA    SAL,L'TEMPNAME(SAL) UPDATE INSERTION LENGTH.             23880020
         STH   SAL,CADSNLN2   SAVE LNG IN INSERTION HEADER.             23920020
         TM    SASWICHS,SAS@EEQ2 ARE EDIT AND SAVE DATA SET             23960020
*                             NAMES ALIKE -                             24000020
         BZ    SAPO           IF NO,GOTO TREAT PARTITIONED DATA         24040020
*                             SET.                                      24080020
         MVC   CAEDMEMB(L'CAEDMEMB),CASAMEMB IF YES,UPDATE EDIT         24120020
*                             MEMBER NAME SLOT FROM SAVE SLOT.          24160020
         OI    CAEDFLAG,CAEDDSOR SET BIT TO IND EDIT DSORG = PO.        24200020
         MVC   CADSNPTR(L'CADSNPTR+L'CADSNLEN+L'CADSNOFF+L'CADSNREC),CAC24240020
               DSNPT2         UPDATE EDIT DSNAME MESSAGE INSERT.        24280020
         B     SAPO           GOTO TREAT PARTITIONED DATA SET.          24320020
 SPACE                                                                  24360020
*********************************************************************** 24400020
* A MEMBER WAS SPECIFIED, OR 'TEMPNAME' WAS DEFAULTED-TO.  ATTEMPT TO * 24440020
* ALLOCATE A PARTITIONED DATA SET, DISP=(MOD,CATLG).                  * 24480020
*********************************************************************** 24520020
 SPACE                                                                  24560020
SAPO     EQU   *                                                        24600020
*---------------------------------------------------------------------* 24640020
* I/O OPERATIONS ARE STILL PERFORMED IN THE FINAL COPY ROUTINE,       * 24680020
* IKJEBEFC, NOT IN THIS MODULE.  THUS THE JUST-DESCRIBED ALLOCATION   * 24720020
* (NOT SPECIFYING MEMBER NAME) WILL CAUSE READ-WRITE HEAD TO BE POSI- * 24760020
* TIONED AT BEGINNING OF DIRECTORY, NOT AT END OF DATA SET, WHEN      * 24800020
* FINAL COPY 'OPEN'S DATA SET.  TO AVOID THIS FOR THE TIME BEING,     * 24840020
* ATTEMPT TO ALLOCATE WITH DISP=(NEW,CATLG), SPECIFYING MEMBER. THEN, * 24880020
* IF DATA SET IS NOT NEW, ALLOCATE WITH DISP=(SHR,KEEP), NOT     A52001 24920021
* SPECIFYING MEMBER.  (DATA SET CAN LATER BE ALLOCATED           A52001 24960021
* AS OLD, SPECIFYING MEMBER)                                     A52001 24962021
*---------------------------------------------------------------------* 25000020
         TM    SASWICHS,SAINCTLG WAS DSNAME CATALOGED -                 25040020
         BO    SAPOOLD        IF YES,GOTO ALLOCATE OLD PDS.             25080020
         TM    SASWICHS,SAS@EEQ2 IF NO,ARE EDIT,SAVE DATA SETS THE      25120020
*                             SAME -                                    25160020
         BZ    SAPO2          IF NO, GOTO ALLOC NEW PDS.                25200020
         TM    CAEDFLAG,CAEDDISP IFYES,IS EDIT DATA SET OLD -           25240020
         BO    SAPOOLD        IF YES,GOTO ALLOC OLD PDS.                25280020
SAPO2    EQU   *                                                        25320020
         MVC   SADAIRPB(SADA8OL),SADA8O IF NO,INITLZ DAIR PARAME-       25340020
*                             TER BLOCK.                                25360020
         MVC   SADAIRPB+DA08DSP1-DAPB08(DA08CTL+L'DA08CTL-DA08DSP1),SADC25380020
               A8N            TAIL OF PARM BLOCK.                       25400020
         MVC   SADAIRPB+DA08PSWD-DAPB08(L'DA08PSWD),CASAPSWD            25440020
        MVC   SADAIRPB+DA08MNM-DAPB08(L'DA08MNM),CASAMEMB               25480020
         LA    SAWR1,CASADSNL PASSWORD,MEMBER NAME,PT TO DATA SET       25520020
         ST    SAWR1,SADAIRPB+DA08PDSN-DAPB08 INTO PARAMETER            25560020
*                             BLOCK.                                    25600020
         LA    SAWR1,SANODBKS GET NO. OF DIRECTORY BLOCKS DESIRED.      25640020
         ST    SAWR1,SADAIRPB+DA08DQTY-DAPB08 SET IT IN PARM BLOCK.     25680020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     25720020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       25760020
         BAL   SARETREG,SACMPUTE GOTO COMPUTE SPACE QUANTITIES.         25780020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            25830020
         CH    SARETCDR,SAOLDRC WAS DATA SET ALREADY ALLOCATED -        25840020
         BE    SAPOOLD        IF YES,GOTO ALLOCATE OLD PDS.             25850020
         CH    SARETCDR,SARC16 END OF BRANCH TABLE -            A59609  25857021
         BH    SAM6            IF HIGHER,UNEXPECTED RC OR       A59609  25864021
*                              RC = 48                          A59609  25871021
         B     SADA8BT2(SARETCDR) BRANCH ACCORDING TO RETURN CODE.      25880020
SADA8BT2 EQU   *                                                        25920020
         B     SAOLDCHK       00 - SUCCESS,GOTO CHECK IF DISP IS        25960020
*                                  REALLY 'OLD'.                        26000020
         B     SAM6           04 - BAD PARAMETERS,GO PREPARE FOR        26040020
*                                  MESSAGE CSECT.                       26080020
         B     SACATER3       08 - CATALOG MANAGEMENT ERROR,GOTO        26120020
*                                  PREPARE FOR DIAGNOSIS.               26160020
         B     SAALCER3       12 - DYNAMIC ALLOCATION ERROR,GOTO        26200020
*                                  PREPARE FOR DIAGNOSIS.               26240020
         B     SAM7           16 - NO TIOT ENTRIES AVAILABLE,GOTO       26280020
*                                  PREPARE FOR MESSAGE CSECT.           26320020
SAOLDCHK EQU   *                                                        26326020
         CLI   SADAIRPB+DA08DSP1-DAPB08,DA08OLD DID IKJDAIR CHANGE      26332020
*                             DISP IN PARM BLOCK FROM NEW TO OLD -      26338020
         BNE   SAPIKDDX       IF NO,GOTO GET DDNAME.                    26344020
         OI    CASAFLAG,CASADISP (IND SAVE DATA SET IS 'OLD'.)          26347020
         B     SAPOTEST       IF YES,GOTO TEST DSORG.                   26350020
SACATER3 EQU   *                                                        26360020
         BAL   SARETREG,SACADIAG GOTO DIAGNOSE CATALOG ERROR,           26400020
*                             RETURN HERE IF NO MESSAGE IS ISSUED.      26440020
         B     SAPOOLD        GOTO ALLOCATE OLD PDS.                    26480020
SAALCER3 EQU   *                                                        26520020
         BAL   SARETREG,SAALDIAG GOTO DIAGNOSE ALLOCATION ERROR,        26560020
*                             RETURN HERE IF NO MESSAGE ISSUED.         26600020
SAPOOLD  EQU   *                                                        26640020
*---------------------------------------------------------------------* 26680020
* ALLOCATE PDS,DISP=(SHR,KEEP),NOT SPECIFYING MEMBER. THIS IS    A52001 26720021
* THE ALTERNATIVE TO (MOD,CATLG),WHOSE REASON IS DESCRIBED ABOVE.     * 26760020
*---------------------------------------------------------------------* 26800020
         MVC   SADAIRPB(SADA8OL),SADA8O INITLZ DAIR PARAMETER           26840020
*                             BLOCK.                                    26880020
         MVC   SADAIRPB+DA08PSWD-DAPB08(L'DA08PSWD),CASAPSWD            26920020
         MVC   SADAIRPB+DA08DSP1-DAPB08(SADA8SLN),SADA8S SET     A52001 26930021
*                             STATUS AND DISPOSITION OF SHR,KEEP A52001 26950021
         LA    SAWR1,CASADSNL PASSWORD,PT TO DATA SET NAME INTO         26960020
         ST    SAWR1,SADAIRPB+DA08PDSN-DAPB08 PARAMETER BLOCK.          27000020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     27040020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       27080020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            27280020
         LTR   SARETCDR,SARETCDR WAS ALLOCN SUCCESSFUL -                27480020
         BNZ   SADA8EOT       NO, BRANCH TO DIAGNOSE CONDITION.  A59609 27680021
 SPACE                                                                  28080020
*********************************************************************** 28120020
* DATA SET HAS BEEN ALLOCATED (MOD,CATLG), ON THE ASSUMPTION THAT IT  * 28160020
* IS, OR IS TO BE, PARTITIONED.  IF IT IS ACTUALLY SEQUENTIAL,        * 28200020
* UPDATE THE DATA SET NAME MESSAGE INSERTION(S), ISSUE A MESSAGE IN-  * 28240020
* DICATING THAT THE MEMBER NAME IS IGNORED, UNALLOCATE THE DATA SET,  * 28280020
* AND GO TO PROCESS DATA SET AS SEQUENTIAL.  IF DSORG IS NEITHER PS   * 28320020
* NOR PO, ISSUE AN ERROR MESSAGE.                                     * 28360020
*********************************************************************** 28400020
 SPACE                                                                  28440020
SAPOTEST EQU   *                                                        28480020
*---------------------------------------------------------------------* 28520020
* ACTUALLY,DATA SET IS ALLOCATED AS (SHR,KEEP) W/O MEMBER,AS     A52001 28560021
* EXPLAINED ABOVE.                                               A52001 28600021
*---------------------------------------------------------------------* 28640020
         TM    SADAIRPB+DA08DSO-DAPB08,DS1ORGPO IS DATA SET REALLY      28710020
*                             PARTITIONED -                             28780020
         BO    SAPIKDD3       IF YES,GOTO PICK UP DDNAME.               28850020
*                             IF NO,TRY TREATING IT AS SEQUENTIAL.      28920020
 SPACE                                                                  29000020
*********************************************************************** 29040020
* DATA SET TURNED OUT TO BE SEQUENTIAL.  UNALLOCATE IT, UPDATE THE    * 29080020
* DATA-SET-NAME- MESSAGE-INSERTION(S), AND ISSUE THE MESSAGE STATING  * 29120020
* THAT THE DATA SET IS NOT PARTITIONED.                               * 29160020
*********************************************************************** 29200020
 SPACE                                                                  29240020
SARELYPS EQU   *                                                        29280020
         LM    SAWR1,SAWR2,SADAIRPB+DA08DDN-DAPB08 SAVE DDNAME.         29320020
         MVC   SADAIRPB(SADA18L),SADA18 INITLZ PARAMETER BLOCK.         29360020
         STM   SAWR1,SAWR2,SADAIRPB+DA18DDN-DAPB18 RESTORE DDNAME.      29400020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            29460020
         BAL   SAWR1,SAUNALBR GOTO BRANCH ON RET CODE, RETURN           29540020
*                             HERE IF SUCCESSFUL.                       29620020
SAIGNMEM EQU   *                                                        29720020
         MVC   SAMEMREC(L'SAMEMREC),CASAMEMB MEMBER NAME INTO INSERT.   29740020
         MVC   CASAMEMB(L'CASAMEMB),SADA8O+DA08MNM-DAPB08 BLANK-        29770020
*                             OUT MEMBER NAME.                          29800020
         LA    SAWR1,CADSNPT2                                           29840020
         ST    SAWR1,SAMEMPTR PT TO 2ND INSERTION INTO HEADER.          29880020
         LA    SAWR1,M311IN1                                            29920020
         STH   SAWR1,SAMEMOFF OFFSET TO 1ST INSERTION INTO HEADER.      29960020
         LA    SAL,L'SAMEMLEN+L'SAMEMOFF LNG OF HEADER.                 30000020
         AH    SAL,SAMEMLNG   ADD LNG OF MEMBER NAME.                   30040020
         STH   SAL,SAMEMLEN   LNG OF 1ST INSERTION INTO HEADER.         30080020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 NO THIRD INSERTION.        30120020
         LA    SAWR1,M311IN2                                            30160020
         STH   SAWR1,CADSNOF2 OFFSET TO 2ND INSERTION INTO HEADER.      30200020
         LH    SAWR1,CADSNLN2 GET LNG OF DSNAME INSERTION.              30203020
         BCTR  SAWR1,O        SUBTRACT LNG OF LEFT AND RIGHT            30206020
         BCTR  SAWR1,O        PARENTHESES.                              30209020
         SH    SAWR1,SAMEMLNG SUBTRACT LNG OF MEMBER NAME.              30212020
         STH   SAWR1,CADSNLN2 UPDATE INSERTION LNG.                     30215020
         CLI   CADSNRC2,SAQUOTE IS INSERTION QUOTED -                   30218020
         BNE   SAUDEDIF       IF NO,GOTO ISSUE MESSAGE AND UPDATE       30221020
*                             EDIT DSNAME INSERTION IF NECESSARY.       30224020
         LA    SAWR1,CADSNLN2-SABYT(SAWR1) IF YES,INSERT                30227020
         MVI   O(SAWR1),SAQUOTE CLOSING QUOTE AFTER INSERTION.          30230020
SAUDEDIF EQU   *                                                        30233020
         BAL   SAWR3,SA311RTN GOTO NOTIFY USER THAT DATA SET IS         30333020
*                             NOT PARTITIONED, RETURN HERE UNLESS       30433020
*                             INPUT SOURCE IS AN IN-CORE PROC.          30533020
         TM    SASWICHS,SAS@EEQ2 ARE SAVE,EDIT DATA SETS THE SAME-      30840020
         BZ    SAPS           IF NO,GOTO ALLOC SEQUENTIAL DATASET.      30880020
*                             IF YES,UPDATE EDIT INFORMATION.           30920020
         MVC   CAEDMEMB(L'CAEDMEMB),CASAMEMB BLANK-OUT MEMBER           30960020
*                             NAME IN EDIT SLOT.                        31000020
         MVC   CADSNPTR(L'CADSNPTR+L'CADSNLEN+L'CADSNOFF+L'CADSNREC),CAC31040020
               DSNPT2         UPDATE EDIT-DSNAME MESSAGE-INSERT.        31080020
         OI    SASWICHS,SAS@EEQ1 IND SAVE,EDIT MEMBERS THE SAME.        31120020
         NI    CAEDFLAG,SAFF-CAEDDSOR-CAEDALOC INDICATE EDIT DATA       31160020
*                             SET NOT PARTITIONED,NOT ALLOCATED.        31200020
         B     SAPS           GOTO ALLOC SEQUENTIAL DATA SET.           31240020
 SPACE                                                                  31280020
*********************************************************************** 31320020
* DATA SET IS SUCCESSFULLY ALLOCATED.  PICK UP THE DDNAME RETURNED IN * 31360020
* THE DAIR PARAMETER BLOCK, AND, IF THIS IS THE EDIT DATA SET, INDI-  * 31400020
* CATE THAT IT IS ALLOCATED,    INDICATE ITS DISPOSITION, AND UPDATE  * 31440020
* ITS DDNAME.                                                         * 31480020
*********************************************************************** 31520020
 SPACE                                                                  31560020
*********************************************************************** 31600020
* DATA SET ALLOCATED (NEW,CATLG).                                     * 31640020
*********************************************************************** 31680020
 SPACE                                                                  31720020
SAPICKDD EQU   *                                                        31760020
         CLI   SADAIRPB+DA08DSP1-DAPB08,DA08OLD DID IKJDAIR CHANGE      31763020
*                             DISP IN PARM BLOCK FROM NEW TO OLD -      31766020
         BNE   SANEWOK        IF NO,GOTO GET DDNAME.                    31769020
         LM    SAWR1,SAWR2,SADAIRPB+DA08DDN-DAPB08 IF YES,SAVE          31772020
*                             DDNAME.                                   31775020
         MVC   SADAIRPB(SADA18L),SADA18 INITLZ PARAMETER BLOCK.         31778020
         STM   SAWR1,SAWR2,SADAIRPB+DA18DDN-DAPB18 RESTORE DDNAME.      31781020
         BAL   SAWR1,SAUNALLO GOTO UNALLOCATE,RETURN HERE.              31784020
         BAL   SAWR1,SAUNALBR GOTO BRANCH ON RETURN CODE,RETURN         31787020
*                             HERE IF SUCCESSFUL.                       31790020
         B     SANOTNEW       GOTO ISSUE 'DSNAME EXISTS' MESSAGE.       31793020
SANEWOK  EQU   *                                                        31796020
         MVC   CASADDN(L'CASADDN),SADAIRPB+DA08DDN-DAPB08 GET           31800020
*                             DDNAME.                                   31840020
         OI    CASAFLAG,CASAALOC IND DATA SET ALLOCATED.                31880020
         TM    SASWICHS,SAS@EEQ2 IS THIS THE EDIT DATA SET -            31920020
         BZ    SASKPEFL       IF NO,SKIP SETTING EDIT FLAGS.            31960020
         NI    CAEDFLAG,SAFF-CAEDDSOR-CAEDUNCG IND EDIT DATA IS         32000020
*                             NOW CATALOGUED AND HAS DSORG=PS.          32040020
         OI    CAEDFLAG,CAEDALOC IND EDIT DATA SET ALLOCATED.           32080020
         MVC   CAEDDDN(L'CAEDDDN),CASADDN KEEP DDNAME.                  32120020
SASKPEFL EQU   *                                                        32160020
         B     SAVALIDA       GOTO VALIDATE DATA SET ATTRIBUTES.        32200020
 SPACE                                                                  32240020
*********************************************************************** 32280020
* DATA SET ALLOCATED (OLD,KEEP).                                      * 32320020
*********************************************************************** 32360020
 SPACE                                                                  32400020
SAPIKDD2 EQU   *                                                        32440020
         MVC   CASADDN(L'CASADDN),SADAIRPB+DA08DDN-DAPB08 GET           32480020
*                             DDNAME.                                   32520020
         OI    CASAFLAG,CASADISP+CASAALOC IND DATA SET ALLOCATED,       32560020
*                             DISP=OLD.                                 32600020
         TM    SASWICHS,SAS@EEQ2 IS THIS THE EDIT DATA SET -            32640020
         BZ    SASKPEF2       IF NO,SKIP SETTING EDIT FLAGS.            32680020
         OI    CAEDFLAG,CAEDALOC+CAEDDISP IND EDIT DATA SET IS NOW      32720020
*                             ALLOCATED,DISP=OLD.                       32760020
         MVC   CAEDDDN(L'CAEDDDN),CASADDN KEEP EDIT DDNAME.             32780020
         NI    CAEDFLAG,SAFF-CAEDDSOR-CAEDUNCG IND EDIT DATA SET        32800020
*                             IS NOW CATALOGED AND HAS DSORG=PS.        32840020
SASKPEF2 EQU   *                                                        32880020
         B     SAVALIDA       GOTO VALIDATE DATA SET ATTRIBUTES.        32920020
 SPACE                                                                  32960020
*********************************************************************** 33000020
* DATA SET ALLOCATED (MOD,CATLG).                                     * 33040020
*********************************************************************** 33080020
 SPACE                                                                  33120020
SAPIKDD3 EQU   *                                                        33160020
*---------------------------------------------------------------------* 33200020
* ACTUALLY,DATA SET IS ALLOCATED AS (OLD,KEEP) W/O MEMBER OR AS (NEW, * 33240020
* CATLG) W/ MEMBER, AS DESCRIBED ABOVE. SET BITS TO INDICATE 'OLD' IF * 33280020
* DATA SET IS OLD.                                                    * 33320020
*---------------------------------------------------------------------* 33360020
         CLI   SADAIRPB+DA08MNM-DAPB08,SABLNK WAS DISP=(OLD,KEEP)-      33400020
         BNE   SAPIKDDX       IF NO,SKIP SETTING 'OLD' BIT(S).          33440020
         OI    CASAFLAG,CASADISP IF YES,IND SAVE DATA SET 'OLD'.        33480020
SAPIKDDX EQU   *                                                        33640020
         MVC   CASADDN(L'CASADDN),SADAIRPB+DA08DDN-DAPB08 GET           33680020
*                             DDNAME.                                   33720020
         OI    CASAFLAG,CASAALOC+CASADSOR IND DATA SET ALLOCATED,       33760020
*                             PARTITIONED.                              33800020
         NI    CASAFLAG,SAFF-CASAUNCG IND DATA SET CATALOGED.           33840020
         TM    SASWICHS,SAS@EEQ2 IS THIS THE EDIT DATA SET -            33880020
         BZ    SASKPEF3       IF NO,SKIP SETTING EDIT FLAGS.            33920020
         OI    CAEDFLAG,CAEDALOC+CASADSOR IND THAT EDIT DATA SET        33960020
*                             IS NOW ALLOCATED AND IS PARTITIONED.      34000020
         NI    CAEDFLAG,SAFF-CAEDUNCG IND EDIT DATA SET CATALOGED.      34040020
SASKPEF3 EQU   *                                                        34080020
 SPACE                                                                  34160020
*********************************************************************** 34200020
* VALIDATION OF DATA SET ATTRIBUTES . . . . . . .                     * 34240020
*********************************************************************** 34280020
 SPACE                                                                  34320020
* GET TRACK LENGTH OF OUTPUT DEVICE, SEE IF LARGER THAN EDIT BLKSIZE.   34360020
 SPACE                                                                  34400020
SAVALIDA EQU   *                                                        34440020
         DEVTYPE SADAIRPB+DA08DDN-DAPB08,SADEVTBL,DEVTAB                34480020
         LTR   SARETCDR,SARETCDR WAS DEVTYPE SUCCESSFUL -               34520020
         BZ    SADEVTOK       IF YES,GOTO VALIDATE BLOCKSIZE.           34560020
         LA    SAPARMR1,SAE17 IF NO,SET RELATIVE MESSAGE NO.            34600020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           34660020
SADEVTOK EQU   *                                                        34720020
         LH    SAWR1,CABLKS   GET EDIT BLOCKSIZE.                       34760020
         CH    SAWR1,SADEVTBL+SADEVTRK IS EDIT BLOCKSIZE LESS THAN      34800020
*                             OR EQUAL TO DEVICE TRACK SIZE -           34840020
         BNH   SATRAKOK       IF YES,GOTO FURTHER VALIDATION.           34880020
         LA    SAPARMR1,SAE18 IF NO,SET RELATIVE MESSAGE NO.            34920020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             34960020
 SPACE                                                                  35000020
*********************************************************************** 35040020
* BLOCKSIZE ISN'T GREATER THAN TRACK LENGTH, SO, IF DATA SET IS PAR-  * 35080020
* TITIONED, CONTINUE BY VALIDATING RECFM, BLOCKSIZE, AND LRECL.  IF   * 35120020
* DATA SET IS SEQUENTIAL, ATTRIBUTES WILL BE UPDATED WHEN THE 'CLOSE' * 35160020
* MACRO IS ISSUED.                                                    * 35200020
*********************************************************************** 35240020
 SPACE                                                                  35280020
SATRAKOK EQU   *                                                        35320020
*---------------------------------------------------------------------* 35360020
* ACTUALLY, SINCE A PDS IS PRESENTLY ALLOCATED AS 'OLD' OR 'NEW' IN-  * 35400020
* STEAD OF 'MOD', SKIP THE DATA-SET-ATTRIBUTE-VALIDATION IF THE DATA  * 35440020
* SET IS A NEW PDS (IN THIS CASE ATTRIBUTES WILL BE UPDATED AS WITH A * 35480020
* SEQUENTIAL DATA SET.                                                * 35520020
*---------------------------------------------------------------------* 35560020
         TM    CASAFLAG,CASADISP+CASADSOR IS DATA SET AN OLD PDS -      35600020
         BNO   SAOPEN         IF NO,SKIP VALIDATION AND GOTO OPEN       35640020
*                             FOR BLDL IF NECESSARY.                    35680020
*                             IF YES,START VALIDATION.                  35720020
 SPACE                                                                  35760020
*********************************************************************** 35800020
* SEARCH THE TIOT FOR THE ENTRY CORRESPONDING TO THE DDNAME RETURNED  * 35840020
* BY DAIR.  PICK UP THE VOLUME SERIAL NO. FROM THE UCB (POINTED-TO BY * 35880020
* THE TIOT) AND PLACE IT IN A PARAMETER LIST FOR 'OBTAIN'.  USE THE   * 35920020
* 'OBTAIN' MACRO INSTRUCTION TO READ THE DSCB INTO CORE.              * 35960020
*********************************************************************** 36000020
 SPACE                                                                  36040020
         L     SAWR1,CVTPTR   GET ADDRESS OF COMMUNICATIONS VECTOR      36080020
*                             TABLE (CVT).                              36120020
         L     SAWR1,CVTTCBP-CVT(SAWR1) GET ADDRESS OF NEXT AND         36160020
*                             CURRENT TASK CONTROL BLOCK (TCB)          36200020
*                             POINTER LIST.                             36240020
         L     SAWR1,SAWD(SAWR1) GET ADDRESS OF CURRENT TCB.            36280020
         L     SAWR2,SATWD(SAWR1) GET ADDRESS OF TASK INPUT/OUTPUT      36320020
*                             TABLE (TIOT).                             36360020
         SR    SAL,SAL        ZERO LENGTH REGISTER.                     36400020
SATIOTET EQU   *                                                        36440020
         IC    SAL,TIOELNGH-IEFTIOT1(SAWR2) GET LNG OF DD ENTRY.        36480020
         LTR   SAL,SAL        HAS END OF TIOT BEEN REACHED -            36520020
         BZ    SAM6           IF YES,GOTO PREPARE FOR ERROR MSG.        36560020
         CLC   CASADDN(L'CASADDN),TIOEDDNM-IEFTIOT1(SAWR2) IF NO,       36600020
*                             IS SAVE DDNAME IN THIS DD ENTRY -         36640020
         BE    SAGETUCB       IF YES,GOTO GET ADDRESS OF UNIT           36680020
*                                    CONTROL BLOCK (UCB).               36720020
         AR    SAWR2,SAL      IF NO,ADD  ENGTH OF THIS DD ENTRY TO      36760020
*                                   CURRENT POSITION IN TIOT.           36800020
         B     SATIOTET       GOTO RE-TEST FOR END OF TIOT.             36840020
SAGETUCB EQU   *                                                        36880020
         L     SAWR1,TIOESTTB-IEFTIOT1(SAWR2) GET ADDRESS OF UCB.       36920020
         CLI   UCBID-IEFUCBOB(SAWR1),SAFF IS THIS UNIT A 2321           37110020
*                             DATA CELL -                               37180020
         BE    SAGETVOL       IF NO,GOTO GET VOLUME SERIAL NUMBER.      37250020
         MVC   SAVOLSER(L'SAVOLSER),DCELVOLI-DATACELL(SAWR1) IF         37300020
*                             YES,GET VOLUME SERIAL NO. FOR 2321.       37360020
         B     SAOBTAIN       GOTO OBTAIN DSCB.                         37400020
SAGETVOL EQU   *                                                        37440020
         TM    UCBTBYT3-IEFUCBOB(SAWR1),UCB3DACC IS THIS UNIT A         37450020
*                             DIRECT ACCESS STORAGE DEVICE -            37460020
         BNO   SAM15          IF NO,GOTO PREPARE FOR ERROR MESSAGE.     37470020
         MVC   SAVOLSER(L'SAVOLSER),SRTEVOLI-IEFUCBOB(SAWR1) GET        37480020
*                             VOLUME SERIAL NO. FOR NON-2321.           37520020
SAOBTAIN EQU   *                                                        37560020
         MVC   SAOBFLGS(SACAMLSL),SACAMLST INITLZ 'OBTAIN' CAMLST.      37600020
         LA    SAWR1,CASADSN  GET ADDRESS OF DATA SET NAME.             37640020
         LA    SAWR2,SAVOLSER GET ADDRESS OF VOLUME SERIAL NUMBER.      37680020
         LA    SAWR3,SAOBWORK GET ADDRESS OF OBTAIN WORKAREA.           37720020
         STM   SAWR1,SAWR3,SAOBDSNP POINTERS INTO PARM LIST.            37760020
         OBTAIN SAOBFLGS      READ DSCB INTO CORE.                      37800020
         LTR   SARETCDR,SARETCDR WAS 'OBTAIN' SUCCESSFUL -              37840020
         BZ    SAOBTNOK       IF YES,GOTO VALIDATE ATTRIBUTES.          37880020
         LA    SAPARMR1,SAE19 IF NO,SET RELATIVE MESSAGE NO.            37920020
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.           37980020
SAOBTNOK EQU   *                                                        38040020
         TM    SAOBWORK+DS1RECFM-DS1FMTID,DS1FMT00 IS RCD FORMAT        38140020
*                             SET IN DSCB -                             38240020
         BZ    SABLKVAL       IF NO,SKIP RCD FORMAT CHECKING.           38260020
 SPACE                                                                  38282020
*********************************************************************** 38284020
* CHECK RECORD FORMAT FIELD FOR UNDEFINED RECORD FORMAT, STANDARD     * 38285020
* BLOCKS, OR SPANNED RECORDS.                                         * 38286020
*********************************************************************** 38288020
 SPACE                                                                  38290020
         BO    SAFMTINV       IF YES,AND RECFM=U,GOTO PREPARE FOR       38292020
*                             ERROR MESSAGE.                            38294020
SACHKS   EQU   *                                                        38308020
         TM    SAOBWORK+DS1RECFM-DS1FMTID,DS1FSMAT TEST FOR       M5145 38310021
*                             INVALID ATTRIBUTES.                 M5145 38311021
         BNZ   SAINVFMT       IF ANY, PREPARE FOR ERROR MSG.      M5145 38312021
 SPACE                                                                  38314020
         TM    CACFLAG2,CARECFM IF YES,ARE EDIT RECORDS FIXED -         38320020
         BZ    SAEDVAR        IF NO,GOTO VERIFY SAVE RECFM.             38360020
         TM    SAOBWORK+DS1RECFM-DS1FMTID,DS1FMTF IF YES,IS SAVE        38400020
*                             DATA SET RECORD FORMAT FIXED -            38440020
         BO    SABLKVAL       IF YES,GOTO VALIDATE BLKSIZE.             38480020
SAINVFMT EQU   *                                                        38490020
         LA    SAPARMR1,SAE12 SET RELATIVE ERROR NO.                    38500020
         B     SAFMTIN2       GOTO SET PT TO RECFM FIELD.               38510020
SAFMTINV EQU   *                                                        38520020
         LA    SAPARMR1,SAE20 IF NO,SET RELATIVE MESSAGE NO.            38560020
SAFMTIN2 EQU   *                                                        38580020
         LA    SATEMPRC,SAOBWORK+DS1RECFM-DS1FMTID GET ADDRESS OF       38600020
*                             RECORD FORMAT FIELD IN DSCB.              38640020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             38680020
SAEDVAR  EQU   *                                                        38720020
         TM    SAOBWORK+DS1RECFM-DS1FMTID,DS1FMTV IS SAVE DATA SET      38760020
*                             RECORD FORMAT VARIABLE -                  38800020
         BZ    SAFMTINV       IF NO,GOTO PREPARE FOR MESSAGE.           38840020
*                             IF YES,VALIDATE BLKSIZE.                  38880020
SABLKVAL EQU   *                                                        38920020
         CLC   SAOBWORK+DS1BLKL-DS1FMTID(L'DS1BLKL),SABLKL0 IS          38960020
*                             BLKSIZE SET IN DSCB -                     39000020
         BE    SAOPEN         IF NO,SKIP ATTRIBUTE CHECKING.            39040020
SALRLVAL EQU   *                                                        39360020
         LH    SAWR2,SAOBWORK+DS1LRECL-DS1FMTID GET SAVE LRECL.         39420020
         LH    SAWR1,CALRECL  GET EDIT LRECL.                           39480020
         TM    CACFLAG2,CARECFM ARE EDIT RECORDS FIXED -                39560020
         BZ    SAEDVAR2       IF NO,GOTO VALIDATE LRECL.                39600020
         SH    SAWR1,SACWL    IF YES,SUBTRACT LENGTH OF UTILITY         39640020
*                                    RECORD CONTROL WORD FROM           39680020
*                                    UTILITY LRECL TO GET LRECL TO      39720020
*                                    COMPARE WITH DSCB LRECL.           39760020
         LTR   SAWR2,SAWR2    IS LRECL SET IN DSCB -                    39762020
         BZ    SANOLRL1       IF NOT,SKIP LRECL CHECKING.               39764020
         CR    SAWR1,SAWR2    ARE SAVE,EDIT LRECLS EQUAL -              39766020
         BNE   SALRLMSG       IF NO,GOTO PREPARE MSG.                   39768020
SANOLRL1 EQU   *                                                        39770020
         LH    SADIVDND,SAOBWORK+DS1BLKL-DS1FMTID IF YES,GET            39772020
*                             BLKSIZE FROM DSCB.                        39774020
         SR    SAREMNDR,SAREMNDR CLEAR LEFT HALF OF DIVIDEND.           39776020
         DR    SAREMNDR,SAWR1 DIVIDE SAVE BLKSIZE BY EDIT LRECL.        39778020
         LTR   SAREMNDR,SAREMNDR IS REMAINDER ZERO -                    39780020
         BZ    SAOPEN         IF YES,SKIP ERROR MSG.                    39782020
SABLKMSG EQU   *                                                        39784020
         LA    SAPARMR1,SAE21 IF NO,SET RELATIVE MSG NO.                39786020
         LH    SATEMPRC,SAOBWORK+DS1BLKL-DS1FMTID GET BLKSIZE FROM      39788020
*                             DSCB.                                     39790020
         B    SAM0           BRANCH TO GOTO ISSUE MSG.                  39792020
SAEDVAR2 EQU   *                                                        39800020
         LTR   SAWR2,SAWR2    IS LRECL SET IN DSCB -                    39810020
         BZ    SANOLRL2       IF NOT,SKIP LRECL CHECKING.               39820020
         CR    SAWR1,SAWR2    ARE SAVE,EDIT LRECLS EQUAL -              39870020
         BNE   SALRLMSG       IF NO,GOTO PREPARE FOR MSG.               39880020
SANOLRL2 EQU   *                                                        39890020
         LA    SAWR1,SAWD(SAWR1) IF YES,IS SAVE BLKSIZE GREATER         39900020
         CH    SAWR1,SAOBWORK+DS1BLKL-DS1FMTID THAN OR EQUAL TO         39910020
*                             EDIT LRECL+4 -                            39920020
         BH    SABLKMSG       IF NO,GOTO SET UP MSG.                    39930020
         B     SAOPEN         IF YES, SKIP ERROR MSG.                   39940020
SALRLMSG EQU   *                                                        39950020
         LA    SAPARMR1,SAE22 IF NO,SET RELATIVE MESSAGE NO.            39960020
         LH    SATEMPRC,SAOBWORK+DS1LRECL-DS1FMTID GET LRECL FROM       40000020
*                             DSCB.                                     40040020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             40080020
 SPACE                                                                  40120020
*********************************************************************** 40160020
* OPEN DATA SET FOR OUTPUT.                                           * 40200020
*********************************************************************** 40240020
 SPACE                                                                  40280020
SAOPEN   EQU   *                                                        40320020
*---------------------------------------------------------------------* 40360020
* ACTUALLY, SINCE COPY FUNCTION IS PERFORMED BY FINAL COPY(IKJEBEFC), * 40400020
* MUST OPEN DATA SET ONLY IF IT IS AN OLD PDS(OPEN FOR INPUT, TO PER- * 40440020
* FORM A BLDL).                                                       * 40480020
*---------------------------------------------------------------------* 40520020
         TM    CASAFLAG,CASADISP+CASADSOR IS DATA SET AN OLD PDS -      40560020
         BNO   SAFC           IF NO,GOTO CALL FINAL COPY ROUTINE.       40600020
         TM    SAOBWORK+DS1RECFM-DS1FMTID,DS1FMT00 CHECK IF      A56698 40605021
*                             RECFM IS SET IN DSCB               A56698 40610021
         BZ    SAFC           IF NOT, IT IS NEW DATA SET         A56698 40615021
         L     SAWR1,SADCBVCN IF YES,GET ADDRESS OF DCB LIST FORM.      40620020
         MVC   SADCB(L'SADCB),O(SAWR1) INITLZ DCB.                      40640020
         MVC   SADCB+DCBDDNAM-IHADCB(L'DCBDDNAM),CASADDN DDNAME FR      40680020
*                             DAIR INTO DCB.                            40720020
         MVC   SAOPENPL(L'SAOPENPL),SAOPENLT INITLZ OPEN PLIST.         40760020
         OPEN  (SADCB,(INPUT)),MF=(E,SAOPENPL)                          40800020
         TM    SADCB+DCBOFLGS-IHADCB,SAOPENOK WAS OPEN SUCCESSFUL-      40840020
         BNZ   SABUILDL       IF YES,GOTO PERFORM BLDL ON MEMBER.       40880020
         LA    SAPARMR1,SAE23 IF NO,SET RELATIVE ERROR NO.              40920020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             40960020
 SPACE                                                                  41000020
*********************************************************************** 41040020
* CONSTRUCT A BLDL LIST TO DETERMINE WHETHER THE SPECIFIED OR IMPLIED * 41080020
* MEMBER EXISTS.  SAVE THE BLDL RETURN CODE AND CLOSE THE DCB.        * 41120020
*********************************************************************** 41160020
 SPACE                                                                  41200020
SABUILDL EQU   *                                                        41240020
         MVC   SABLDL(SABLDLLL),SABLDLLT INITLZ BLDL LIST.              41280020
         MVC   SABLDL+SABLDLMN-SABLDLLT(L'SABLDLMN),CASAMEMB SET        41320020
*                             MEMBER NAME IN LIST.                      41360020
         BLDL  SADCB,SABLDL                                             41400020
         LR    SATEMPRC,SARETCDR SAVE RETURN CODE FROM BLDL.            41440020
         MVC   SAOPENPL(L'SAOPENPL),SAOPENLT INITLZ CLOSE PLIST.        41480020
         CLOSE (SADCB,),MF=(E,SAOPENPL)                                 41520020
 SPACE                                                                  41560020
*********************************************************************** 41600020
* IF MEMBER DOES NOT EXIST, GO TO SAVE DATA SET.  IF MEMBER ALREADY   * 41640020
* EXISTS, INFORM THE USER AND PROMPT FOR CARRIAGE-RETURN OR NEW MEM-  * 41680020
* BER NAME, UNLESS THIS IS THE EDIT DATA SET AND 'NEW' WAS NOT        * 41720020
* ENTERED ON THE 'EDIT' COMMAND.                                      * 41760020
*********************************************************************** 41800020
 SPACE                                                                  41840020
         B     SABLDLBT(SATEMPRC) BRANCH ACCORDING TO RETURN CODE.      41880020
SABLDLBT EQU   *                                                        41920020
         B     SAPROMTT       00 - MEMBER EXISTS,TEST FOR PROMPT        41960020
*                                  NECESSARY.                           42000020
         B     SAFC           04 - MEMBER DOESN'T EXIST,GOTO SAVE.      42040020
         LA    SAPARMR1,SAE24 08 - I/O ERROR,SET RELATIVE MSG NO.       42080020
         B     SAM0           BRANCH TO GOTO ISSUE MESSAGE.             42120020
SAPROMTT EQU   *                                                        42160020
         TM    SASWICHS,SAS@EEQ1 IS SAVE INTO EDIT DSNAME(MEMBER)-      42200020
         BZ    SAPROMPT       IF NO,GOTO PROMPT.                        42240020
         OI    CAEDFLAG,CAEDMEM IF YES,IND EDIT MEMBER EXISTS.          42280020
         OI    CASAFLAG,CASAMEM IND SAVE MEMBER EXISTS.                 42320020
         TM    SASWICHS,SAEDOL WAS 'OLD' ENTERED ON EDIT COMMAND -      42360020
         BO    SAFC           IF YES,GOTO SAVE.                         42400020
         NI    SASWICHS,SAFF-SAS@EEQ1 (RESET 'SAVE,EDIT MEMBERS         42410020
*                             EQUAL' SWITCH TO OFF.)                    42420020
SAPROMPT EQU   *              IF NO,PROMPT FOR SAME OR NEW MEMBER.      42440020
         OI    CASAFLAG,CASAMEM IND SAVE MEMBER EXISTS.                 42480020
         BAL   SAWR2,SAEXISTS GOTO TELL USER THAT MEMBER EXISTS,        42570020
*                             RETURN HERE.                              42660020
         TM    CACFLAG4,CAINPROC IS INPUT SOURCE AN IN-CORE PROC -      42680020
         BO    SAFC           IF YES,SKIP PROMPT FOR NEW MEMBER OR      42700020
*                             CARRIAGE RETURN.                          42720020
         L     SAWR1,SAPUGVC2 GET ADDRESS OF OUTPUT.                    42760020
         BAL   SAWR2,SAPUTGET GOTO ISSUE PROMPT,RETURN WITH INPUT.      42860020
 SPACE                                                                  43040020
*********************************************************************** 43080020
* 'PUTGET' OBTAINED A REPLY.  SAVE REPLY, FREE THE CORE GOTTEN, TEST  * 43120020
* THE REPLY.  IF A CARRIAGE RETURN, GOTO USE THE EXISTING MEMBER.     * 43160020
* OTHERWISE REPEAT THE BLDL ON THE MEMBER NAME JUST OBTAINED.         * 43200020
*********************************************************************** 43240020
 SPACE                                                                  43280020
         BAL   SAWR3,SAFREEMN GOTO FREE CORE,RETURN HERE.               43380020
         BNH   SAFC           IF YES,GOTO SAVE.                         43560020
         LA    SAWR3,SAPTGTIN IF NO,SET PT TO INPUT BUFFER.             43600020
         L     SAWR1,SAPCLVC2 GET PT TO PARAMETER CONTROL LIST.         43640020
         BAL   SADATAR,SAPARSE GOTO SCAN INPUT,RETURN ON SUCCESS.       43740020
         L     SADATAR,CAPTPRSD IF YES,GET PT TO PDL FR ANS PLACE.      43920020
         USING SAPDLSC2,SADATAR ESTABLISH ADDRESSABILITY TO PDL.        43960020
         LH    SAL,SAPDLMNM+SAPDLLNG GET MEMBER NAME LENGTH.            44000020
         STH   SAL,SAMEMLNG   SAVE MEMBER NAME LENGTH.                  44040020
         BCTR  SAL,O          SUBTRACT 1 FOR 'EX' INSTRUCTION.          44080020
         L     SAWR2,SAPDLMNM GET PT TO MEMBER NAME.                    44120020
         MVC   CASAMEMB(L'CASAMEMB),SADA8O+DA08MNM-DAPB08 RESET         44130020
*                             SAVE MEMBER SLOT TO BLANKS.               44140020
         EX    SAL,SAMEMP2S   MOVE MEMBER NAME TO COMM AREA.            44160020
         CLC   CAEDDSN(L'CAEDDSN+L'CAEDMEMB),CASADSN ARE SAVE,EDIT      44166020
*                             MEMBERS THE SAME -                        44172020
         BNE   SAIKJRLS       IF NO,GOTO FREE PDL CORE.                 44178020
         OI    SASWICHS,SAS@EEQ1 IF YES,SET 'MEMBERS =' SWITCH ON.      44184020
SAIKJRLS EQU   *                                                        44190020
 SPACE                                                                  44200020
* FREE THE CORE TAKEN UP BY THE PDL.                                    44240020
 SPACE                                                                  44280020
         BAL   SAWR1,SAFREPDL GOTO FREE CORE,RETURN HERE.               44340020
 SPACE                                                                  44400020
* UPDATE SAVE-DATA-SET-NAME MESSAGE-INSERTION WITH NEW MEMBER NAME.     44440020
 SPACE                                                                  44480020
         LA    SAWR1,CADSNLN2-SABYT GET ADDRESS OF INSERTION.           44520020
         AH    SAWR1,CADSNLN2 START SEARCH FOR '(' AT INSERT END.       44560020
SALPSRCH EQU   *                                                        44600020
         CLI   O(SAWR1),SALPAREN IS THIS A '(' -                        44640020
         BE    SAUPDMEM       IF YES,GOTO UPDATE MEMBER IN INSERT.      44680020
         BCT   SAWR1,SALPSRCH IF NO,GOTO CONTINUE SEARCHING LEFT.       44720020
SAUPDMEM EQU   *                                                        44760020
         MVC   SABYT(L'CASAMEMB,SAWR1),CASAMEMB PUT NEW MEMBER          44800020
*                             NAME IN INSERTION.                        44840020
         AH    SAWR1,SAMEMLNG MOVE TO END OF MEMBER NAME.               44880020
         MVI   SABYT(SAWR1),SARPAREN INSERT A ')' AFTER NAME.           44920020
         CLI   CADSNRC2,SAQUOTE IS INSERTION QUOTED -                   44960020
         BNE   SAUPDINL       IF NO,GOTO UPDATE INSERTION LENGTH.       45000020
         MVI   SAHWD(SAWR1),SAQUOTE IF YES,INSERT A QUOTE AT END.       45040020
         LA    SAWR1,SABYT(SAWR1) ADD LNG OF QUOTE TO END-POINTER.      45080020
SAUPDINL EQU   *                                                        45120020
         LA    SAWR2,CADSNLN2-SAHWD GET PT TO BEGNG OF INSERTION.       45160020
         SR    SAWR1,SAWR2    CALC LNG OF UPDATED INSERTION.            45200020
         STH   SAWR1,CADSNLN2 PUT LNG IN INSERTION HEADER.              45240020
         NI    CASAFLAG,SAFF-CASAMEM TURN OFF SAVE-MEM-EXISTS BIT.      45280020
         B     SAOPEN         GOTO OPEN,BLDL,AND CLOSE.                 45320020
SAPOINT1 EQU   *                                                        45360020
*        B    SAFC           FINAL COPY-INSERT POINT 001 LATER.         45400020
 SPACE                                                                  45440020
*********************************************************************** 45480020
* COPY UTILITY DATA SET TO SAVE DATA SET.                             * 45520020
*********************************************************************** 45560020
 SPACE                                                                  45600020
SAFC     EQU   *                                                        45640020
*---------------------------------------------------------------------* 45680020
* ACTUALLY, IF DATA SET IS A PDS ALLOCATED 'SHR,KEEP', IT MUST FIRST  * 45720021
* BE UNALLOCATED, THEN REALLOCATED SPECIFYING MEMBER.                 * 45760020
*---------------------------------------------------------------------* 45800020
         TM    CASAFLAG,CASADISP+CASADSOR IS DATA SET AN OLD PDS -      45840020
         BNO   SACOPY         IF NO,GOTO PERFORM COPY.                  45880020
         MVC   SADAIRPB(SADA18L),SADA18 INITLZ PARAMETER BLOCK FOR      45920020
*                             UNALLOCATION.                             45960020
         MVC   SADAIRPB+DA18DDN-DAPB18(L'DA18DDN),CASADDN SET DDNAME.   46000020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     46040020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       46080020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            46140020
         BAL   SAWR1,SAUNALBR GOTO FIND IF UNALLOCN SUCCESSFUL -        46210020
         TM    SASWICHS,SAS@EEQ2 IF YES, ARE SAVE,EDIT DATA SETS        46280020
*                             THE SAME -                                46320020
         BZ    SAREALOC       IF NO,GOTO REALLOCATE WITH MEMBER.        46360020
         NI    CAEDFLAG,SAFF-CAEDALOC IF YES,IND EDIT DATA SET NOT      46400020
*                             ALLOCATED.                                46440020
SAREALOC EQU   *                                                        46480020
         MVC   SADAIRPB(SADA8OL),SADA8O INITLZ PARAMETER BLOCK FOR      46560020
*                             ALLOCATION.                               46600020
         MVC   SADAIRPB+DA08MNM-DAPB08(L'DA08MNM),CASAMEMB SET          46640020
*                             MEMBER NAME FOR ALLOCATION.               46680020
         LA    SAWR1,CASADSNL GET PT TO DATA SET NAME.                  46720020
         ST    SAWR1,SADAIRPB+DA08PDSN-DAPB08 PUT INTO PARM BLOCK.      46760020
         MVC   SADAIRPB+DA08PSWD-DAPB08(L'DA08PSWD),CASAPSWD SET        46800020
*                             PASSWORD FOR ALLOCATION.                  46840020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            46900020
         LTR   SARETCDR,SARETCDR WAS ALLOCATION SUCCESSFUL -            46960020
         BNZ   SADA8EOT       IF NO,GOTO PREPARE FOR ERROR MSG.  A59609 47000021
         MVC   CASADDN(L'CASADDN),SADAIRPB+DA08DDN-DAPB08 IF YES,       47040020
*                             MOVE DDNAME TO SAVE SLOT.                 47080020
         TM    SASWICHS,SAS@EEQ2 ARE SAVE,EDIT DATA SETS THE SAME-      47120020
         BZ    SACOPY         IF NO,GOTO PERFORM COPY.                  47160020
         OI    CAEDFLAG,CAEDALOC IF YES,IND EDIT DATA SET ALLOCD.       47200020
         MVC   CAEDDDN(L'CAEDDDN),SADAIRPB+DA08DDN-DAPB08 MOVE          47240020
*                             DDNAME TO EDIT SLOT.                      47280020
SACOPY   EQU   *                                                        47320020
         OI    CASAFLAG,CASAALOC IND SAVE DATASET ALLOCATED.            47360020
         LA    SAPARMR0,SARQNRES REQUEST NON-RESIDENT SERVICE RTN.      47400020
         LA    SAPARMR1,SASHPLST SET PT TO PARAMETER LIST.              47440020
         TM    CAATTN,CAATTNIS WAS ATTENTION BUTTON POUNDED -           47480020
         BO    SAATTNX        IF YES,GOTO ATTENTION EXIT.               47520020
*                             IF NO,INVOKE FINAL COPY (IKJEBEFC).       47560020
         IKJEBESH (SACOMMR),IKJEBEFC,PARAM=((SACOMMR)),MF=(E,(1))       47600020
         TM    CAATTN,CAATTNIS WAS ATTENTION ISSUED TO INTERRUPT        47610020
*                             FINAL COPY -                              47620020
         BO    SAATTNX        IF YES,GOTO ATTENTION EXIT.               47630020
         B     SAFCBT(SARETCDR) BRANCH ACCORDING TO RETURN CODE.        47640020
SAFCBT   EQU   *              FINAL COPY BRANCH TABLE.                  47680020
         B     SACOPYOK       00 - COPY WAS SUCCESSFUL,GOTO SET         47720020
*                                  RETURN CODE 0.                       47760020
         B     SAEMPTYU       04 - EMPTY UTILITY DATA SET,GOTO          47800020
*                                  ISSUE MESSAGE.                       47840020
         B     SANOTCOM       08 - QSAM ERROR,GOTO SET RETURN CODE      47880020
*                                  0 (IKJEBEFC ISSUES MESSAGE).         47920020
         LA    SAWR1,SAFCIOE  12 - UTILITY I/O ERROR,SET RETURN         47960020
         STH   SAWR1,SARETCOD      CODE 12 (IKJEBEFC ISSUES MSG).       48000020
         B     SAAFTERC       GOTO STOW AND UNALLOCATE IF NEED BE.      48040020
SAEMPTYU EQU   *                                                        48080020
         MVC   SA10AREA(SAMLLSTL),SANOLINS INITLZ MESSAGE-SELECT        48120020
*                             PARAMETER LIST.                           48160020
         IKJEBEML ,,,,MF=(E,SA10AREA) INVOKE IKJEBEMS.                  48200020
         NI    CACFLAG2,SAFF-CADSMODS TURN OFF 'DATA-SET-MODIFIED'      48210020
*                             SWITCH IN COMMUNICATION AREA.             48220020
         B     SASETRC0       GOTO SET RETURN CODE 0.                   48240020
SACOPYOK EQU   *                                                        48280020
         OI    SASWICHS,SAISSSVD REMEMBER TO ISSUE 'SAVED'              48320020
*                             MESSAGE BEFORE EXIT.                      48360020
SASETRC0 EQU   *                                                        48400020
*     (AT BEGNG OF PROGRAM THERE IS CODE TO) SET RETURN CODE TO 0.      48440020
 SPACE                                                                  48480020
*********************************************************************** 48520020
* IF THE DATA SET IS A PDS, OR IF IT IS NOT THE EDIT DATA SET,        * 48560020
* UNALLOCATE IT IF IT IS NOW ALLOCATED.                               * 48600020
*********************************************************************** 48640020
 SPACE                                                                  48680020
SAAFTERC EQU   *                                                        48720020
SAX      EQU   *                                                        48760020
         TM    CASAFLAG,CASADSOR IS DATA SET PARTITIONED -              48800020
         BO    SAUNALIF       IF YES,GOTO UNALLOCATE IF ALLOCD.         48840020
         TM    SASWICHS,SAS@EEQ2 IF NO,IS THIS THE EDIT DATA SET -      48880020
         BO    SAEDSAVD       IF YES,GOTO ISSUE 'SAVED' IF SAVED.       48920020
SAUNALIF EQU   *                                                        48960020
         TM    CASAFLAG,CASAALOC IF NO,IS DATA SET ALLOCATED -          49000020
         BZ    SAEDSAVD       IF NO,GOTO ISSUE 'SAVED' IF SAVED.        49040020
         MVC   SADAIRPB(SADA18L),SADA18 IF YES,INITLZ PARAMETER         49080020
*                             BLOCK FOR UNALLOCATION.                   49120020
         MVC   SADAIRPB+DA18DDN-DAPB18(L'DA18DDN),CASADDN SET           49160020
*                             DDNAME.                                   49200020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'DAPLPSCB+L'DAPLDAPB),SAPSCB     49240020
*                             PT TO PSCB AND PARM BLOCK TO PLIST.       49280020
         BAL   SAWR1,SAUNALLO GOTO LINK TO DAIR,RETURN HERE.            49340020
         BAL   SAWR1,SAUNALBR GOTO BRANCH ON RETURN CODE, RETURN        49440020
*                             HERE IF SUCCESSFUL.                       49540020
SAUNALCD EQU   *                                                        49680020
         TM    SASWICHS,SAS@EEQ2 WAS THIS EDIT DATA SET -               49760020
         BZ    SAEDSAVD       IF NO,GOTO ISSUE 'SAVED' IF SAVED.        49800020
         NI    CAEDFLAG,SAFF-CAEDALOC IF YES,IND EDIT DATA SET          49840020
*                             UNALLOCATED.                              49880020
SAEDSAVD EQU   *                                                        49920020
         TM    SASWICHS,SAISSSVD WAS FINAL COPY SUCCESSFUL -            49960020
         BZ    SANOTSVD       IF NO,SKIP ISSUANCE OF 'SAVED'.           50000020
 SPACE                                                                  50040020
*********************************************************************** 50080020
* USE PUTLINE TO ISSUE THE 'SAVED' MODE MESSAGE.                 A42951 50120000
*********************************************************************** 50240020
 SPACE                                                                  50280020
         XC    SAPTGTPB(SAPTGTL),SAPTGTPB ZERO PUTLINE PARM      A42951 50320000
*                             BLOCK.                                    50360020
         L     SAWR1,SAPUGVC3 GET ADDRESS OF OUTPUT.                    50400020
         PUTLINE PARM=SAPTGTPB,                                  A42951C50440000
               OUTPUT=((SAWR1),TERM,SINGLE,DATA),                A42951C50480000
               TERMPUT=(EDIT,WAIT,NOHOLD,NOBREAK),               A42951C50520000
               MF=(E,CATMPLST)                                   A42951 50530000
         NI    SASWICHS,SAFF-SAISSSVD TURN OFF BIT TO AVOID LOOPS.      50560020
         NI    CACFLAG2,SAFF-CADSMODS TURN OFF 'DATA-SET-MODIFIED'      50600020
*                             SWITCH IN COMMUNICATION AREA.             50640020
         B     SAPUTLBT(SARETCDR) BRANCH ACCORDING TO RET CODE.  A42951 50650000
SAPUTLBT EQU   *                                                 A42951 50660000
         B     SAATTNX        00 - SUCCESS,GOTO EXIT.            A42951 50670000
         B     SAATTNX        04 - ATTENTION,GOTO EXIT.          A42951 50680000
         B     SAM29          08 - OUTPUT NOT SENT,GO PREPARE    A42951 50690000
*                                  FOR MESSAGE CSECT.            A42951 50700000
         B     SAM29          12 - INVALID PARAMETERS,GO PREPARE A42951 50710000
*                                  FOR MESSAGE CSECT.            A42951 50720000
         B     SAM2           16 - NO CORE,GO PREPARE FOR        A42951 50730000
*                                  MESSAGE CSECT.                A42951 50740000
SAM29    EQU   *                                                 A42951 50800000
         LA    SAPARMR1,SAE29 RELATIVE ERROR NUMBER.             A42951 50840000
         B     SAM00          GOTO SAVE RET CODE FOR MESSAGE.    A42951 50880000
SANOTSVD EQU   *                                                        51160020
SAATTNX  EQU   *                                                        51200020
         LH    SARETCDR,SARETCOD GET RETURN CODE PREVIOUSLY SET.        51240020
         IKJEBERT (14,12),RC=(15)                                       51280020
 SPACE                                                                  51320020
*********************************************************************** 51322020
* UNLESS RET CODE IS ALREADY NON-ZERO, SET RET CODE TO INDICATE THAT  * 51324020
* THIS MODULE'S FUNCTION CANNOT BE COMPLETED.                         * 51326020
*********************************************************************** 51328020
 SPACE                                                                  51330020
SANOTCOM EQU   *                                                        51332020
         LH    SAWR1,SARETCOD GET CURRENT RET CODE.                     51334020
         OR    SAWR1,SAWR1    IS RET CODE ZERO -                        51336020
         BNZ   SAX            IF NO,GOTO EXIT PROCESSING.               51338020
         LA    SAWR1,SARCNOTC IF YES,SET RET CODE TO IND FUNCTION       51340020
         STH   SAWR1,SARETCOD NOT COMPLETE.                             51342020
         B     SAX            GOTO EXIT PROCESSING.                     51344020
 EJECT                                                                  51346020
*********************************************************************** 51360020
* THE FOLLOWING EXAMINES DYNAMIC ALLOCATION AND CATALOG MANAGEMENT    * 51400020
* RETURN CODES (DARC,CTRC) WHENEVER DAIR RETURN CODES 12 (ALLOCATION  * 51440020
* ERROR) OR 8 (CATALOG ERROR) ARE RECEIVED AFTER AN ATTEMPT AT ALLO-  * 51480020
* CATION.  REGISTER 14 CONTAINS THE ADDRESS OF THE POINT TO BRANCH    * 51520020
* BACK TO IF NO MESSAGE IS TO BE ISSUED AFTER EXAMINATION OF DARC OR  * 51560020
* CTRC.                                                               * 51600020
*********************************************************************** 51640020
 SPACE                                                                  51680020
SACADIAG EQU   *                                                        51720020
         LA    SAWR1,SAM14    SET BRANCH POINT IN CASE NO ERROR         51720220
*                             CODE TESTS TEST EQUAL BUT 'DEFAULT'       51720420
*                             WAS CALLED.                               51720620
         CLI   SADAIRPB+DA08CTRC-DAPB08+SABYT,SARC0004 TEST FOR         51721020
*                             CTRC = X'0004' -                          51722020
 SPACE                                                                  51723020
*********************************************************************** 51724020
* CTRC = X'0004'.  'REQUIRED VOLUME NOT MOUNTED'.                     * 51725020
*********************************************************************** 51726020
 SPACE                                                                  51727020
         BE    SAM13          IF EQUAL,GOTO ISSUE MESSAGE.              51728020
SASKP810 EQU   *                                                        51739520
         CLI   SADAIRPB+DA08CTRC-DAPB08+SABYT,SARC0014 IF NOT           51740020
*                             EQUAL,TEST FOR CTRC=X'0014' -             51741020
 SPACE                                                                  51742020
*********************************************************************** 51743020
* CTRC = X'0014'.  'CATALOG ERROR CODE 0014'.                         * 51744020
*********************************************************************** 51745020
 SPACE                                                                  51746020
         BE    SAM14          IF EQUAL,GOTO ISSUE MESSAGE.              51747020
         CLI   SADAIRPB+DA08CTRC-DAPB08+SABYT,SARC001C IF NOT           51748020
*                             EQUAL,TEST FOR CTRC=X'001C' -             51749020
         BE    SACATIOE       IF EQUAL,GOTO PREPARE FOR ERROR MSG.      51749120
SADEFTST EQU   *                                                        51749220
         TM    SASWICHS,SADEFCAL IF NOT EQUAL,HAS 'DEFAULT' BEEN        51749320
*                             CALLED -                                  51749420
         BCR   SAONES,SAWR1   IF YES,GOTO PREPARE FOR ERROR MSG,        51749520
*                             FOR IF 'DEFAULT' WAS CALLED AND THE       51749620
*                             DSNAME WAS NOT FOUND IN CATALOG,          51749720
*                             THERE IS NO NEED TO ATTEMPT ALLOCN        51749820
*                             WITH DISP=(OLD,KEEP).                     51749920
         BR    SARETREG       IF NO,RETURN TO CALLING POINT.            51750020
 SPACE                                                                  51750120
*********************************************************************** 51750220
* CTRC = X'001C'.  'CATALOG I/O ERROR'.                               * 51750320
*********************************************************************** 51750420
 SPACE                                                                  51750520
SACATIOE EQU   *                                                        51750620
         LA    SAPARMR1,SAE28 SET RELATIVE ERROR NUMBER.                51750720
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  51752020
SAALDIAG EQU   *                                                        51760020
         LA    SAWR1,SAM16    SET BRANCH POINT IN CASE NO ERROR         51763020
*                             CODE TESTS TEST EQUAL BUT 'DEFAULT'       51766020
*                             WAS CALLED.                               51769020
         CLC   SADAIRPB+DA08DARC-DAPB08(L'SARC4714),SARC4714 TEST       51772020
*                             FOR DARC=X'4714' -                        51775020
         BNE   SACL02XX       IF NOT EQUAL,GOTO CONTINUE TESTS.  A42950 51778000
 SPACE                                                                  51781000
**************************************************************** A42950 51784000
* DARC=X'4714'. 'NOT ENOUGH SPACE ON VOLS, USE DELETE COMMAND.   A42950 51787000
**************************************************************** A42950 51790000
 SPACE                                                                  52080020
         LA    SAPARMR1,SAE13 RELATIVE ERROR NO.                        52120020
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  52160020
SACL02XX EQU   *                                                        52200020
         CLI   SADAIRPB+DA08DARC-DAPB08,SARC02XX TEST FOR               52240020
*                             DARC=X'02XX' -                            52280020
         BNE   SACLINEW       IF NOT EQUAL,GOTO CONTINUE TESTS.         52320020
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC0204 IF EQUAL,        52360020
*                             TEST FOR DARC=X'0204' -                   52400020
         BNE   SACL020C       IF NOT EQUAL,GOTO CONTINUE TESTS.  A52001 52440021
 SPACE                                                                  52480020
*********************************************************************** 52520020
* DARC = X'0204'.  'NOT ENOUGH MAIN STORAGE TO EXECUTE'.              * 52560020
*********************************************************************** 52600020
 SPACE                                                                  52640020
         B     SAM2           GOTO PREPARE TO CALL MESSAGE CSECT.       52680020
SACL020C EQU   *                                                 A52001 52681021
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC020C TEST      A52001 52691021
*                                 FOR DARC = X'020C'.            A52001 52693021
         BNE   SACL0214       IF NOT EQUAL, CONTINUE TESTING.    A52001 52693421
         SPACE                                                          52693821
**************************************************************** A52001 52694221
* DARC=X'020C' DATA SET IS PERMANENTLY ALLOCATED AS 'SHR',       A52001 52694821
*              CANNOT BE ALLOCATED AS 'OLD'                      A52001 52694921
**************************************************************** A52001 52697521
         SPACE                                                          52700121
         LA    SAPARMR1,SAE34 RELATIVE ERROR NUMBER.             A52001 52700421
         B     SACALLA9       BRANCH TO CALL MESSAGE RTN.        A52001 52700821
SACL0214 EQU   *                                                        52701021
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC0214 TEST FOR         52702821
*                             DARC=X'0214' -                            52705421
         BNE   SACL021C       IF NOT EQUAL,GOTO CONTINUE TESTS.         52708021
 SPACE                                                                  52710621
*********************************************************************** 52713221
* DARC = X'0214'.  'INVALID UNIT IN UADS'.                            * 52715821
*********************************************************************** 52718421
 SPACE                                                                  52721021
         LA    SAPARMR1,SAE30 RELATIVE ERROR NO.                        52723621
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  52726221
SACL021C EQU   *                                                        52728821
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC021C TEST FOR         52731421
*                             DARC=X'021C' -                            52734021
         BNE   SACL0210       IF NOT EQUAL,GOTO CONTINUE TESTS.         52736621
 SPACE                                                                  52739221
*********************************************************************** 52741821
* DARC = X'021C'.  'NO UNIT AVAILABLE'.                               * 52744421
*********************************************************************** 52747021
 SPACE                                                                  52749621
         LA    SAPARMR1,SAE31 RELATIVE ERROR NO.                        52752221
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  52754821
SACL0210 EQU   *                                                        52757421
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC0210  TEST FOR        52760020
*                             DARC=X'0210' -                            52800020
         BNE   SACL0218       IF NOT EQUAL,GOTO CONTINUE TESTS.         52840020
 SPACE                                                                  52880020
*********************************************************************** 52920020
* DARC = X'0210'.  'DATA SET ALREADY IN USE'.                         * 52960020
*********************************************************************** 53000020
 SPACE                                                                  53040020
         LA    SAPARMR1,SAE14 RELATIVE ERROR NO.                        53080020
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  53120020
SACL0218 EQU   *                                                        53160020
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC0218 TEST FOR         53200020
*                             DARC=X'0218' -                            53240020
         BNE   SACLINEW       IF NOT EQUAL,GOTO CONTINUE TESTS.         53280020
 SPACE                                                                  53320020
*********************************************************************** 53360020
* DARC = X'0218'.  'REQUIRED VOLUME NOT MOUNTED'.                     * 53400020
*********************************************************************** 53440020
 SPACE                                                                  53480020
SAM13    EQU   *                                                        53500020
         LA    SAPARMR1,SAE15 RELATIVE ERROR NO.                        53520020
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  53560020
SACLINEW EQU   *                                                        53600020
         CLI   SADAIRPB+DA08DARC-DAPB08,SARC04XX TEST FOR               53601020
*                             DARC=X'04NN' -                            53602020
         BNE   SADEFTST       IF NOT EQUAL,GOTO FIND IF 'DEFAULT'       53602620
*                             WAS CALLED.                               53603220
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC0404 IF EQUAL,        53604020
*                             TEST FOR DARC=X'0404' -                   53605020
         BNE   SACL041C       IF NOT EQUAL,GOTO CONTINUE TESTS.         53606020
 SPACE                                                                  53607020
*********************************************************************** 53608020
* DARC = X'0404'.  'DATA SET NOT ON DIRECT ACCESS DEVICE'.            * 53609020
*********************************************************************** 53610020
 SPACE                                                                  53611020
SAM15    EQU   *                                                        53612020
         LA    SAPARMR1,SAE32 RELATIVE ERROR NO.                        53613020
         B     SACALLA9       GOTO CALL MESSAGE CSECT.                  53614020
SACL041C EQU   *                                                        53615020
         CLI   SADAIRPB+DA08DARC-DAPB08+SABYT,SARC041C TEST FOR         53616020
*                             DARC=X'041C' -                            53617020
         BNE   SADEFTST       IF NOT EQUAL,GOTO FIND IF 'DEFAULT'       53617620
*                             WAS CALLED.                               53618220
 SPACE                                                                  53619020
*********************************************************************** 53620020
* DARC = X'041C'.  'DATA SET ON MULTIPLE VOLUMES'.                    * 53621020
*********************************************************************** 53622020
 SPACE                                                                  53623020
         LA    SAPARMR1,SAE33 RELATIVE ERROR NO.                        53624020
         B     SAM0           GOTO CALL MESSAGE CSECT.                  54224020
 SPACE                                                                  54880020
*********************************************************************** 54920020
* CONSTANTS USED IN IKJEBESA.                                         * 54960020
*********************************************************************** 55000020
 SPACE                                                                  55040020
SAPCLVCN DC    V(IKJEBSA1)    ADDRESS OF DSNAME PCL.                    55080020
SAPCLVC2 DC    V(IKJEBSA2)    ADDRESS OF MEMBER PCL.                    55120020
SAPUGVCN DC    V(IKJEBSA3)    ADDRESS OF PROMPT MESSAGE.                55150020
SAPUGVC2 DC    V(IKJEBSA4)    ADDRESS OF PROMPT MESSAGE(MEMBER).        55180020
SAPUGVC3 DC    V(IKJEBSA5)    ADDRESS OF MODE MESSAGE.                  55210020
SADCBVCN DC    V(IKJEBSA6)    ADDRESS OF DCB, LIST FORM.                55240020
SASA9VCN DC    V(IKJEBSA9)    ADDRESS OF MESSAGE-ISSUING CSECT.         55280020
SADFGT44 DC    H'8'           'DEFAULT' RETURN CODE -- DSNAME           55320020
*                             EXCEEDS 44 CHARACTERS.                    55360020
SARC16   DC    H'16'         RETURN CODE = 16                   A59609  55370021
SARC28   DC    H'28'         RETURN CODE = 28                   A59609  55380021
SARC48   DC    H'48'         RETURN CODE = 48                   A59609  55390021
SACWL    DC    H'4'           LNG OF UTILITY RCD CONTROL WORD.          55440020
SALRECL0 DC    XL2'0'         FOR CHECKING DS1LRECL FIELD IN DSCB.      55480020
SALSTAR0 DC    XL3'0'         FOR CHECKING DS1LSTAR FIELD IN DSCB.      55520020
SABLKL0  DC    XL2'0'         FOR CHECKING DS1BLKL FIELD IN DSCB.       55560020
TEMPNAM0 DC    CL1'('         MEMBER NAME FOR INSERTION TEXT            55600020
TEMPNAME DC    CL10'TEMPNAME)''' WHEN NONE IS SPECIFIED.                55640020
SARC6708 DC    XL2'6708'      DARC=6708 (DATA SET NOT ON VOLUME).       55680020
 SPACE                                                                  55720020
* OBJECTS OF 'EXECUTE' INSTRUCTIONS.                                    55760020
 SPACE                                                                  55800020
SADSNP2S MVC   CASADSN(O),O(SAWR2) MOVE DATA SET NAME FR BUFFER TO      55840020
*                             EDIT COMMUNICATION AREA.                  55880020
SAMEMP2S MVC   CASAMEMB(O),O(SAWR2) MOVE MEMBER NAME FR BUFFER TO       55920020
*                             EDIT COMMUNICATION AREA.                  55960020
SAPSWP2S MVC   CASAPSWD(O),O(SAWR2) MOVE PASSWORD FR BUFFER TO          56000020
*                             EDIT COMMUNICATION AREA.                  56040020
SACLCQUL CLC   O(O,SAWR2),CADSQUAL COMPARE EDIT DATA-SET-NAME-          56080020
*                             QUALIFIER WITH LAST PORTION OF SAVE       56120020
*                             DATA SET NAME.                            56160020
SAMVCQUL MVC   O(O,SAWR2),SADA8O+DA08DDN-DAPB08 DSNAME ENDS IN A        56200020
*                             QUALIFIER,BUT BLANK IT AND TELL           56240020
*                             'DEFAULT' TO PUT IT BACK AGAIN.           56280020
SACLCUID CLC   O(O,SAWR2),CASADSN COMPARE USERID WITH FIRST             56320020
*                             PORTION OF SAVE DATA SET NAME.            56360020
SAMVCQL2 MVC   SAQUALFR-SABYT(O),O(SAWR2) MOVE '.' AND LAST QUALFR      56368020
*                             OF DSNAME TO SAVE AREA, PUTTING THE       56376020
*                             '.' JUST TO THE LEFT OF THE AREA,SO       56384020
*                             THAT AREA CONTAINS ONLY THE QUALFR.       56392020
 SPACE                                                                  56400020
* LIST FORM,DAIR PARAMETER BLOCK,DISP=(OLD,KEEP).                       56440020
 SPACE                                                                  56480020
SADA8O   EQU   *                                                        56520020
         DC    XL2'8'         ENTRY CODE 8 (ALLOCATE A DATA SET).       56560020
         DC    10X'0'         FLAGS,DARC,CTRC,DSNAME PT.                56600020
         DC    3CL8' '        DDNAME,UNITNAME,VOL SERIAL NO.            56640020
         DC    4FL4'0'        BLKSIZE,PRIMARY,SECONDARY,DIRECTORY       56680020
*                             QUANTITIES.                               56720020
         DC    2CL8' '        MEMBER NAME, PASSWORD.                    56760020
         DC    X'00000800'    DISPOSITIONS, CONTROL FLAGS.              56800020
         DC    FL4'0'         RESERVED BYTES(3),DSORG.                  56840020
SADA8OL  EQU   *-SADA8O       LNG OF PARAMETER BLOCK.                   56880020
         SPACE                                                          56890021
* LIST FORM, DAIR PARAMETER BLOCK, DISP=(SHR,KEEP)               A52001 56900021
         SPACE                                                          56910021
SADA8S   EQU   *               STATUS, DISPOSITION BYTES.        A52001 56912021
         DC    AL1(DA08SHR)    STATUS - SHR.                     A52001 56914021
         DC    AL1(DA08KEEP)   DISPOSITION - KEEP.               A52001 56916021
SADA8SLN EQU   *-SADA8S        LENGTH FOR MOVE.                  A52001 56918021
 SPACE                                                                  56920020
* LIST FORM,DAIR PARAMETER BLOCK,DISP=(NEW,CATLG).                      56960020
 SPACE                                                                  57000020
SADA8N   EQU   *                                                        57040020
         DC    X'04'          STATUS=NEW.                               57480020
         DC    X'02'          DISPOSITION=CATLG.                        57520020
         DC    X'08'          CONDITIONAL DISPOSITION=KEEP.             57560020
         DC    X'40'          SPACE REQUEST IN BLOCKSIZE.               57600020
 SPACE                                                                  57680020
* LIST FORM,DAIR PARAMETER BLOCK,DISP2='KEEP'.                          57720020
 SPACE                                                                  57760020
SADA18   EQU   *                                                        57800020
         DC    XL2'18'        ENTRY CODE 18 (UNALLOCATE DATA SET).      57840020
         DC    10X'0'         FLAGS,DARC,CTRC,DSNAME PT.                57880020
         DC    2CL8' '        DDNAME,MEMBER NAME.                       57920020
         DC    XL2'0'         SYSOUT CLASS.                             57960020
         DC    X'08'          DISP2=KEEP.                               58000020
         DC    X'0'           CONTROL BYTE.                             58040020
         DC    CL8' '         JOBNAME.                                  58080020
SADA18L  EQU   *-SADA18       LENGTH OF PARAMETER BLOCK.                58120020
 SPACE                                                                  58160020
* LIST FORM OF MESSAGE-SELECTION PARAMETER LIST FOR 'DATA SET ALREADY   58200020
* EXISTS' MESSAGE.                                                      58240020
 SPACE                                                                  58280020
SAMNOTNU IKJEBEML M339,0,0,0,MF=L DATA SET ALREADY EXISTS.              58320020
SAMLLSTL EQU   *-SAMNOTNU     LNG OF MESSAGE PARAMETER LIST.            58360020
 SPACE                                                                  58400020
* LIST FORM OF MESSAGE-SELECTION PARAMETER LIST FOR 'NO LINES IN        58440020
* DATA SET' MESSAGE.                                                    58480020
 SPACE                                                                  58520020
SANOLINS IKJEBEML M553,,,,MF=L                                          58560020
 SPACE                                                                  58600020
SAPUGTL  EQU   16             LNG OF PUTGET PARM BLOCK.          A42951 58610020
SAPTGTL  EQU   20             LNG OF PUTLINE PARM BLOCK.         A42951 58640000
 SPACE                                                                  58800020
* LIST FORM OF CAMLST PARAMETER LIST FOR 'OBTAIN'.                      58840020
 SPACE                                                                  58880020
SACAMLST CAMLST SEARCH,0,0,0                                            58920020
SACAMLSL EQU   *-SACAMLST     LNG OF LIST.                              58960020
 SPACE                                                                  59000020
* DATA MANAGEMENT PARAMETER LIST FOR OPEN/CLOSE.                        59200020
 SPACE                                                                  59240020
SAOPENLT OPEN  (,),MF=L                                                 59280020
 SPACE                                                                  59320020
* LIST FORM OF BLDL LIST.                                               59360020
 SPACE                                                                  59400020
SABLDLLT DC    FL2'1'         NO. OF ENTRIES.                           59440020
         DC    FL2'14'        ENTRY LENGTH.                             59480020
SABLDLMN DC    CL8' '         MEMBER NAME.                              59520020
         DC    6X'0'          TTRK, Z, C.                               59560020
SABLDLLL EQU   *-SABLDLLT     LNG OF LIST.                              59600020
 SPACE                                                                  59640020
* MACROS TO GENERATE PARAMETER CONTROL LIST (PCL) AND PROVIDE           59680020
* ADDRESSABILITY FOR PARAMETER DESCRIPTOR LIST (PDL).                   59720020
 SPACE                                                                  59760020
IKJEBSA1 IKJPARM DSECT=SAPDLSEC                                         59800020
SAPDLDSN IKJPOSIT DSNAME,PROMPT='VALID DATA SET NAME'                   59840020
         IKJENDP                                                        59880020
 SPACE                                                                  59920020
* MACROS TO GENERATE PCL AND MAP PDL, FOR MEMBER NAME ONLY.             59960020
 SPACE                                                                  60000020
IKJEBSA2 IKJPARM DSECT=SAPDLSC2                                         60040020
SAPDLMNM IKJIDENT 'MEMBER NAME',MAXLNTH=8,FIRST=ALPHA,OTHER=ALPHANUM,  C60080020
               PROMPT='MEMBER NAME ONLY'                                60120020
         IKJENDP                                                        60160020
 SPACE                                                                  60200020
*********************************************************************** 60240020
* EQUATES - REGISTERS USED IN IKJEBESA.                               * 60280020
*********************************************************************** 60320020
 SPACE                                                                  60360020
PARMREG0 EQU   0                                                        60400020
SAPARMR0 EQU   0              SERVICE ROUTINE PARAMETER.                60440020
PARMREG1 EQU   1                                                        60480020
SAPARMR1 EQU   1              SERVICE ROUTINE PARAMETER, OR, IN         60520020
*                             GENERAL, THE ADDRESS OF A SERVICE         60560020
*                             ROUTINE PARAMETER LIST.                   60600020
SAL      EQU   2              CONTAINS LENGTHS.                         60640020
SACOUNT  EQU   2              CONTAINS COUNTERS.                        60680020
SATEMPRC EQU   2              TO SAVE RETURN CODES OR ADDRESSES TO      60720020
*                             BE SENT TO THE MESSAGE-ISSUING SUB-       60760020
*                             ROUTINE, IKJEBSA9.                        60800020
SAWR1    EQU   2              FIRST WORKING REGISTER,FOR TEMPORARY      60840020
*                             POINTERS,VALUES,ETC.                      60880020
SAWR2    EQU   3              SECOND WORKING REGISTER.                  60920020
SAWR3    EQU   4              THIRD WORKING REGISTER.                   60960020
********* NOTE- SAWR1, SAWR2, AND SAWR3 MUST BE IN ASCENDING            61000020
*********       SEQUENCE, FOR USE IN 'STORE MULTIPLE'                   61040020
*********       INSTRUCTIONS.                                           61080020
COMMREG  EQU   9                                                        61120020
SACOMMR  EQU   9              BASE REGISTER FOR EDIT'S                  61160020
*                             COMMUNICATION AREA.                       61200020
BASEREG2 EQU   10              SECOND BASE REG FOR CSECT        A59609  61210021
SA2048   EQU   2048            2K INCREMENT FOR 2ND BASE REG    A59609  61220021
BASEREG  EQU   11                                                       61240020
SABASER  EQU   11             BASE REGISTER FOR CONTROL SECTION.        61280020
DATAREG  EQU   12                                                       61320020
SADATAR  EQU   12             BASE REGISTER FOR PARAMETER               61360020
*                             DESCRIPTOR LIST (PDL) CONSTRUCTED BY      61400020
*                             PARSE.                                    61440020
SAVEREG  EQU   13                                                       61480020
SASAVER  EQU   13             ADDRESS OF SAVE AREA.                     61520020
RETREG   EQU   14                                                       61560020
SARETREG EQU   14             ADDRESS OF RETURN POINT IN CALLING        61600020
*                             ROUTINE.                                  61640020
SAREMNDR EQU   14             EVEN REGISTER OF EVEN-ODD PAIR.           61650020
SADIVDND EQU   15             ODD  REGISTER OF EVEN-ODD PAIR.           61660020
RETCDREG EQU   15                                                       61680020
SARETCDR EQU   15             RETURN CODE TO CALLING ROUTINE.           61720020
SACALLAD EQU   15             ADDRESS OF ENTRY POINT IN CALLED          61760020
*                             ROUTINE.                                  61800020
 SPACE                                                                  61840020
*********************************************************************** 61880020
* EQUATES - DYNAMIC ALLOCATION RETURN CODES.                          * 61920020
*********************************************************************** 61960020
 SPACE                                                                  62000020
SARC02XX EQU   X'02'          DARC = X'02NN'.                           62040020
SARC0204 EQU   X'04'          DARC = X'0204'.                           62080020
SARC020C EQU   X'0C'          DARC = X'020C'.                    A52001 62090021
SARC0210 EQU   X'10'          DARC = X'0210'.                           62120020
SARC0218 EQU   X'18'          DARC = X'0218'.                           62160020
SARC0214 EQU   X'14'          DARC = X'0214'.                           62170020
SARC021C EQU   X'1C'          DARC = X'021C'.                           62175020
SARC04XX EQU   X'04'          DARC = X'04NN'.                           62180020
SARC0404 EQU   X'04'          DARC = X'0404'.                           62185020
SARC041C EQU   X'1C'          DARC = X'041C'.                           62190020
SARC17XX EQU   X'17'          DARC = X'17NN'.                           62200020
SARC1708 EQU   X'08'          DARC = X'1708'.                           62240020
SARC1712 EQU   X'12'          DARC = X'1712'.                           62280020
SARC1716 EQU   X'16'          DARC = X'1716'.                           62320020
 SPACE                                                                  62323020
*********************************************************************** 62326020
* EQUATES - CATALOG MANAGEMENT RETURN CODES.                          * 62329020
*********************************************************************** 62332020
 SPACE                                                                  62335020
SARC0004 EQU   X'04'          CTRC = X'0004'.                           62338020
SARC0008 EQU   X'08'          CTRC = X'0008'.                           62341020
SARC0010 EQU   X'10'          CTRC = X'0010'.                           62344020
SARC0014 EQU   X'14'          CTRC = X'0014'.                           62347020
SARC001C EQU   X'1C'          CTRC = X'001C'.                           62350020
 SPACE                                                                  62360020
*********************************************************************** 62400020
* EQUATES - DATA SET ORGANISATION BYTE IN DATA SET CONTROL BLOCK.     * 62440020
*********************************************************************** 62480020
 SPACE                                                                  62520020
DS1ORGPO EQU   B'00000010'    DSCB DSORG = PARTITIONED.                 62560020
DS1ORGPS EQU   B'01000000'    DSCB DSORG = PHYSICAL SEQUENTIAL.         62600020
DS1ORGIS EQU   B'10000000'    DSCB DSORG = INDEXED SEQUENTIAL.          62640020
DS1ORGDI EQU   B'00100000'    DSCB DSORG = DIRECT.                      62680020
 SPACE                                                                  62720020
DS1FMTF  EQU   B'10000000'    DSCB RECFM = FIXED.                       62760020
DS1FMTV  EQU   B'01000000'    DSCB RECFM = VARIABLE.                    62800020
DS1FMTU  EQU   B'11000000'    DSCB RECFM = UNDEFINED.                   62840020
DS1FMT00 EQU   B'11000000'    DSCB RECFM NOT SET.                       62880020
DS1FMTB  EQU   B'00010000'    DSCB RECFM = BLOCKED.                     62884020
DS1FMTS  EQU   B'00001000'    DSCB RECFM = STANDARD BLOCKS OR           62888020
*                                          SPANNED RECORDS.             62892020
DS1FMTT  EQU   B'00100000'    DSCB RECFM = TRACK OVERFLOW         M5145 62892221
DS1FMTA  EQU   B'00000100'    DSCB RECFM = ANSI CONTROL CHAR.     M5145 62892421
DS1FMTM  EQU   B'00000010'    DSCB RECFM - MACHINE CONTROL CHAR   M5145 62892621
DS1FSMAT EQU   DS1FMTS+DS1FMTM+DS1FMTA+DS1FMTT COMBINATION OF     M5145 62892821
*                             SPANNED (OR STANDARD), ANSI         M5145 62893021
*                             CONTROL, MACHINE CONTROL, TRACK     M5145 62893221
*                             OVERFLOW FORMATS.                   M5145 62893421
DS1CHARF EQU   C'F'           MESSAGE TEXT - 'FIXED'.                   62896020
DS1CHARV EQU   C'V'           MESSAGE TEXT - 'VARIABLE'.                62900020
DS1CHARB EQU   C'B'           MESSAGE TEXT - 'BLOCKED'.                 62904020
DS1CHARS EQU   C'S'           MESSAGE TEXT - 'STANDARD BLOCKS' OR       62908020
*                                            'SPANNED RECORDS'.         62912020
DS1CHART EQU   C'T'           MESSAGE TEXT - 'TRACK OVERFLOW'     M5145 62913021
DS1CHARA EQU   C'A'           MESSAGE TEXT - 'ANSI CONTROL        M5145 62914021
*                                             CHARACTERS'         M5145 62915021
DS1CHARM EQU   C'M'           MESSAGE TEXT - 'MACHINE CONTROL     M5145 62916021
*                                             CHARACTERS'         M5145 62917021
 SPACE                                                                  62920020
*********************************************************************** 62960020
* EQUATES - CONSTANTS FOR GENERAL USE IN IKJEBESA.                    * 63000020
*********************************************************************** 63040020
 SPACE                                                                  63080020
O        EQU   0                                                        63120020
SABYT    EQU   1              BYTE.                                     63160020
SAHWD    EQU   2              HALFWORD.                                 63200020
SAWD     EQU   4              WORD.                                     63240020
SANE     EQU   7              MASK FOR 'BRANCH ON NOT EQUAL'.           63260020
SAONES   EQU   1              MASK FOR 'BRANCH IF ONES'.                63266020
SAEQUAL  EQU   8              MASK FOR 'BRANCH ON EQUAL'.               63272020
SADWD    EQU   8              DOUBLEWORD.                               63280020
SATWD    EQU   12             TRIPLEWORD.                               63320020
SAQWD    EQU   16             QUADWORD.                                 63360020
SAFF     EQU   X'FF'          ONE BYTE OF BINARY ONES.                  63400020
SAFLAG   EQU   X'80'          TO MARK END OF VARIABLE LENGTH            63440020
*                             PARAMETER LISTS.                          63480020
SABLNK   EQU   C' '           BLANK.                                    63520020
SADOT    EQU   C'.'           PERIOD.                                   63560020
SALPAREN EQU   C'('           LEFT PARENTHESIS.                         63600020
SARPAREN EQU   C')'           RIGHT PARENTHESIS.                        63640020
SAQUOTE  EQU   C''''          SINGLE QUOTATION MARK.                    63680020
SADFUSER EQU   B'00100000'    TELLS 'DEFAULT' TO PREFIX DATA SET        63720020
*                             NAME WITH USERID.                         63760020
SADFQUAL EQU   B'00000010'    TELLS 'DEFAULT' TO ADD SPECIFIED          63800020
*                             QUALIFIER TO DATA SET NAME.               63840020
SADF20   EQU   20             RETURN CODE FROM 'DEFAULT' INDICATING     63880020
*                             DSNAME NOT IN CATALOGUE.                  63920020
SARCNOTC EQU   8              RETURN CODE FROM IKJEBESA INDICATING      63930020
*                             FUNCTION NOT COMPLETED.                   63940020
SAFCIOE  EQU   12             RETURN CODE FROM IKJEBESA INDICATING      63960020
*                             UTILITY I/O ERROR.                        64000020
SARQNRES EQU   4              ENTRY CODE TO SERVICE ROUTINE HAND-       64040020
*                             LER REQUESTING NON-RESIDENT SERVICE       64080020
*                             ROUTINE (NAMELY, IKJEBEFC).               64120020
SAOPENOK EQU   X'10'          TO TEST DCBOFLGS FOR OPEN SUCCESS.        64160020
SANODBKS EQU   2              NO. OF DIRECTORY BLOCKS DESIRED FOR       64200020
*                             ALLOCATION OF A PDS.                      64240020
SAALPHA  EQU   400            FACTOR FOR PRIMARY SPACE QUANTITY         64244020
*                             CALCULATION.                              64248020
SABETA   EQU   200            FACTOR FOR SECONDARY SPACE QUANTITY       64252020
*                             CALCULATION.                              64256020
SAALPHA2 EQU   400            INCREMENT TO FACTOR FOR PRIMARY           64260020
*                             SPACE QUANTITY CALCULATION(PDS).          64264020
SABETA2  EQU   200            INCREMENT TO FACTOR FOR SECONDARY         64268020
*                             SPACE QUANTITY CALCULATION(PDS).          64272020
 SPACE                                                                  64280020
*********************************************************************** 64320020
* EQUATES - OFFSETS IN PARAMETER DESCRIPTOR LIST (PDL) AND PARAMETER  * 64360020
*           DESCRIPTOR ENTRIES (PDES) WITHIN PDL. ALSO FLAG-BYTE BITS.* 64400020
*********************************************************************** 64440020
 SPACE                                                                  64480020
SAPDLLNG EQU   4              OFFSET OF LENGTH FIELD FR BEGNG OF        64520020
*                             PDE.                                      64560020
SAPDLFLG EQU   6              OFFSET OF FLAGS FIELD FR BEGNG OF         64600020
*                             PDE                                       64640020
SAPDLOP  EQU   B'10000000'    ON-PT TO OPERAND IS IN PDE/OFF-NO         64680020
*                             OPERAND ENTERED.                          64720020
SAPDLQUO EQU   B'01000000'    ON-DATA SET NAME IN QUOTES/OFF-NOT.       64760020
SAPDLMEM EQU   8              OFFSET OF MEMBER NAME PDE FR BEGNG        64800020
*                             OF PDL.                                   64840020
SAPDLPSW EQU   16             OFFSET OF PASSWORD FR BEGNG OF            64880020
*                             PDL.                                      64920020
 SPACE                                                                  64960020
*********************************************************************** 65000020
* EQUATES - RELATIVE ERROR NUMBERS SET IN IKJEBESA, USED IN IKJEBSA9. * 65040020
*********************************************************************** 65080020
 SPACE                                                                  65120020
SAE1     EQU   0              COMMAND SYSTEM ERROR/PARSE RETURN         65160020
*                             CODE (4,12).                              65200020
SAE2     EQU   4              NOT ENOUGH CORE TO EXECUTE SAVE.          65240020
SAE3     EQU   8              COMMAND SYSTEM ERROR/DEFAULT RETURN       65280020
*                             CODE (4,28,32).                           65320020
SAE4     EQU   12             DSNAME EXCEEDS 44 CHARACTERS.             65360020
SAE5     EQU   16             DSNAME CAN'T BE RESOLVED/DEFAULT          65400020
*                             ERROR CODE 12.                            65440020
SAE6     EQU   20             COMMAND SYSTEM ERROR/DAIR RETURN          65480020
*                             CODE (4                                   65520020
SAE7     EQU   24             TOO MANY DATA SETS/USE FREE COMMAND.      65560020
SAE8     EQU   28             COMMAND SYSTEM ERROR/PUTGET RETURN        65600020
*                             CODE (12,16,20,24).                       65640020
SAE9     EQU   32             SYSTEM ERROR/CATALOG ERROR (CTRC).        65680020
SAE10    EQU   36             SYSTEM ERROR/ALLOCN ERROR CODE (DARC).    65720020
SAE11    EQU   40             (ISAM,DIRECT) DSORG NO GOOD/MUST BE       65760020
*                             PS OR PO.                                 65800020
SAE12    EQU   44             RECORD FORMAT (F,V,FBS,VBS,FS,VS)         65840020
*                             NOT ACCEPTABLE.                           65880020
SAE13    EQU   48             NOT ENOUGH SPACE ON VOLUMES/USE    A42950 65920000
*                             DELETE COMMAND.                    A42950 65960000
SAE14    EQU   52             DATA SET IN USE/ALLOC'D TO ANOTHER        66000020
*                             USER.                                     66040020
SAE15    EQU   56             VOLUME NOT MOUNTED/NOT ON SYSTEM.         66080020
SAE16    EQU   60             DATA SET NOT IN CATALOGUE.                66120020
SAE17    EQU   64             COMMAND SYSTEM ERROR/DEVTYPE RETURN       66160020
*                             CODE (4,8).                               66200020
SAE18    EQU   68             BLOCK WON'T FIT ON TRACK.                 66240020
SAE19    EQU   72             COMMAND SYSTEM ERROR/OBTAIN RETURN        66280020
*                             CODE (4,8,12,16,20).                      66320020
SAE20    EQU   76             EDIT,SAVE DATA SETS INCOMPATIBLE/         66360020
*                             EDIT RECFM=(F,V),SAVE RECFM=(F,V,U).      66400020
SAE21    EQU   80             EDIT,SAVE DATA SETS INCOMPATIBLE/         66440020
*                             EDIT,SAVE BLKSIZES NOT EQUAL.             66480020
SAE22    EQU   84             EDIT,SAVE DATA SETS INCOMPATIBLE/         66520020
*                             EDIT,SAVE LRECLS NOT EQUAL.               66560020
SAE23    EQU   88             DATA SET NOT USABLE/DCBOFLGS=0.           66600020
SAE24    EQU   92             COMMAND SYSTEM ERROR/BLDL RETURN          66640020
*                             CODE (8).                                 66680020
SAE25    EQU   96             DSNAME WILL CREATE INVALID CATALOG        66682020
*                             STRUCTURE/LAST QUALFR IS AN INDEX.        66684020
SAE26    EQU   100            SYSTEM ERROR/DSNAME NOT UNALLOCATED,      66686020
*                             CATALOG ERROR CODE XXXX.                  66688020
SAE27    EQU   104            SYSTEM ERROR/DSNAME NOT UNALLOCATED,      66690020
*                             DYNAMIC ALLOCATION ERROR CODE XXXX.       66692020
SAE28    EQU   108            SYSTEM ERROR/CATALOG I/O ERROR.           66694020
SAE29    EQU   112            COMMAND SYSTEM ERROR/PUTLINE RET   A42951 66697000
*                             CODE (8,12).                       A42951 66699000
SAE30    EQU   116            NOT ALLOCD/INVALID UNIT IN UADS.          66700020
SAE31    EQU   120            NOT ALLOCD/NO UNIT AVAILABLE.             66702020
SAE32    EQU   124            DATASET NOT ON DIRECT ACCESS DEVICE.      66704020
SAE33    EQU   128            DATASET ON MULTIPLE VOLUMES.              66706020
SAE34    EQU   132            DATA SET PERMANENTLY ALLOCATED AS  A52001 66716021
*                             SHR, CANNOT BE ALLOCATED AS OLD    A52001 66718021
*                             WITHOUT FIRST UNALLOCATING.        A52001 66718421
 SPACE                                                                  66720020
IKJEBSA8 CSECT                                                          66760020
         ENTRY IKJEBSA8                                                 66800020
         ENTRY IKJEBSA3                                                 66830020
         ENTRY IKJEBSA4                                                 66860020
         ENTRY IKJEBSA5                                                 66890020
         ENTRY IKJEBSA6                                                 66920020
 SPACE                                                                  66960020
*********************************************************************** 67000020
* THE FOLLOWING CONTROL SECTION CONTAINS PROMPT AND MODE MESSAGE TEXT.* 67040020
*********************************************************************** 67080020
 SPACE                                                                  67120020
* SINGLE-LEVEL PROMPT MESSAGE FOR PUTGET.                               67160020
 SPACE                                                                  67200020
IKJEBSA3 DC    F'1'           NO. OF MESSAGE SEGMENTS.                  67240020
         DC    A(A8M340A)     ADDRESS OF MESSAGE TEXT.                  67280020
A8M340A  DC    X'00450000'    LENGTH OF TEXT.  OFFSET = 0.              67320020
         DC    CL65'IKJ52340A ENTER NEW NAME OR HIT CARRIER RETURN TO RC67360020
               EUSE DATA SET-'                                          67400020
 SPACE                                                                  67440020
* SINGLE-LEVEL PROMPT MESSAGE FOR PUTGET (MEMBER ONLY).                 67480020
 SPACE                                                                  67520020
IKJEBSA4 DC    F'1'           NO. OF MESSAGE SEGMENTS.                  67560020
         DC    A(A8M341A)     ADDRESS OF MESSAGE TEXT.                  67600020
A8M341A  DC    X'00450000'    LENGTH OF TEXT.  OFFSET = 0.              67640020
         DC    CL65'IKJ52341A ENTER NEW MEMBER OR HIT CARRIER RETURN TOC67680020
                REUSE MEMBER-'                                          67720020
 SPACE                                                                  67760020
* MODE MESSAGE FOR PUTLINE ('SAVED').                            A42951 67800000
 SPACE                                                                  67840020
IKJEBSA5 DC    AL2(A8#-*)     LENGTH,INCLUDING HEADER.           A42951 67880000
         DC    XL2'0'         OFFSET.                            A42951 67920000
         DC    C'SAVED'       MODE MESSAGE TEXT.                 A42951 67960000
A8#      EQU   *                                                 A42951 68000000
 SPACE                                                                  68010020
IKJEBSA6 DCB   DSORG=PO,MACRF=(E),DDNAME=OOOOOOOO                       68020020
 SPACE                                                                  68040020
IKJEBSA9 CSECT                                                          68080020
         ENTRY IKJEBSA9                                                 68120020
*********************************************************************** 68160020
* THE FOLLOWING CONTROL SECTION ISSUES MESSAGES BASED UPON A RELATIVE * 68200020
* ERROR NUMBER (PASSED IN REGISTER 'SAPARMR1') AND A RETURN CODE FOR  * 68240020
* INSERTION (PASSED IN REGISTER 'SATEMPRC'), AND RETURNS TO THE       * 68280020
* ADDRESS IN REGISTER 'SARETREG'.                                     * 68320020
*********************************************************************** 68360020
 SPACE                                                                  68400020
         IKJEBESV (14,12),,*,COMMREG=(9)                                68440020
         USING IKJEBECA,COMMREG ESTABLISH ADDRESSABILITY FOR            68480020
*                             COMMUNICATIONS AREA.                      68520020
         B     A9ERRTAB(SAPARMR1) BRANCH ON RELATIVE ERROR NUMBER.      68560020
A9ERRTAB EQU   *              RELATIVE ERROR NUMBER BRANCH TABLE.       68600020
         B     A9M1           COMMAND SYSTEM ERROR/PARSE RETURN         68640020
*                             CODE (4,12).                              68680020
         B     A9M2           NOT ENOUGH CORE TO EXECUTE SAVE.          68720020
         B     A9M3           COMMAND SYSTEM ERROR/DEFAULT RETURN       68760020
*                             CODE (4,28,32).                           68800020
         B     A9M4           DSNAME EXCEEDS 44 CHARACTERS.             68840020
         B     A9M5           DSNAME CAN'T BE RESOLVED/DEFAULT          68880020
*                             ERROR CODE 12.                            68920020
         B     A9M6           COMMAND SYSTEM ERROR/DAIR RETURN          68960020
*                             CODE (4                                   69000020
         B     A9M7           TOO MANY DATA SETS/USE FREE COMMAND.      69040020
         B     A9M8           COMMAND SYSTEM ERROR/PUTGET RETURN        69080020
*                             CODE (12,16,20,24).                       69120020
         B     A9M9           SYSTEM ERROR/CATALOG ERROR (CTRC).        69160020
         B     A9M10          SYSTEM ERROR/ALLOCN ERROR (DARC).         69200020
         B     A9M11          (ISAM,DIRECT) DSORG NO GOOD/MUST BE       69240020
*                             PS OR PO.                                 69280020
         B     A9M12          RECORD FORMAT (F,V,FBS,VBS,FS,VS)         69320020
*                             NOT ACCEPTABLE.                           69360020
         B     A9M13          NOT ENOUGH SPACE ON VOLUMES/USE    A42950 69400000
*                             DELETE COMMAND.                    A42950 69440000
         B     A9M14          DATA SET IN USE/ALLOC'D TO ANOTHER        69480020
*                             USER.                                     69520020
         B     A9M15          VOLUME NOT MOUNTED/NOT ON SYSTEM.         69560020
         B     A9M16          DATA SET NOT IN CATALOGUE.                69600020
         B     A9M17          COMMAND SYSTEM ERROR/DEVTYPE RETURN       69640020
*                             CODE (4,8).                               69680020
         B     A9M18          BLOCK WON'T FIT ON TRACK.                 69720020
         B     A9M19          COMMAND SYSTEM ERROR/OBTAIN RETURN        69760020
*                             CODE (4,8,12,16,20).                      69800020
         B     A9M20          EDIT,SAVE DATA SETS INCOMPATIBLE/         69840020
*                             EDIT RECFM=(F,V),SAVE RECFM=(F,V,U).      69880020
         B     A9M21          EDIT,SAVE DATA SETS INCOMPATIBLE/         69920020
*                             EDIT,SAVE BLOCKSIZES UNEQUAL.             69960020
         B     A9M22          EDIT,SAVE DATA SETS INCOMPATIBLE/         70000020
*                             EDIT,SAVE LRECLS UNEQUAL.                 70040020
         B     A9M23          DATA SET NOT USABLE/DCBOFLGS=0.           70080020
         B     A9M24          COMMAND SYSTEM ERROR/BLDL RETURN          70120020
*                             CODE (8).                                 70160020
         B     A9M25          DSNAME WILL CREATE INVALID CATALOG        70162020
*                             STRUCTURE/LAST QUALFR IS AN INDEX.        70164020
         B     A9M26          SYSTEM ERROR/DSNAME NOT UNALLOCATED,      70166020
*                             CATALOG ERROR CODE XXXX.                  70168020
         B     A9M27          SYSTEM ERROR /DSNAME NOT UNALLOCATED,     70170020
*                             DYNAMIC ALLOCATION ERROR CODE XXXX.       70172020
         B     A9M28          SYSTEM ERROR/CATALOG I/O ERROR.           70174020
         B     A9M29          COMMAND SYSTEM ERROR/PUTLINE RET   A42951 70177000
*                             CODE (8,12).                       A42951 70179400
         B     A9M30          NOT ALLOCD/INVALID UNIT IN UADS.          70180020
         B     A9M31          NOT ALLOCD/NO UNIT AVAILABLE.             70182020
         B     A9M32          DATASET NOT ON DIRECT ACCESS DEVICE.      70184020
         B     A9M33          DATASET ON MULTIPLE VOLUMES.              70186020
         B     A9M34          DATA SET PERMANENTLY ALLOCATED     A52001 70186421
*                             AS SHR, CAN'T BE ALLOCATED OLD     A52001 70186821
*                             WITHOUT UNALLOCATION               A52001 70187221
A9M1     EQU   *                                                        70200020
         MVC   A9L2I1(A9MGPARL),A9MGPARS GET 1ST INSERTION FOR 2ND      70240020
*                             LEVEL MESSAGE.                            70280020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        70320020
A9M3     EQU   *                                                        70360020
         MVC   A9L2I1(A9MGDEFL),A9MGDEFA GET 1ST INSERTION FOR 2ND      70400020
*                             LEVEL MESSAGE.                            70440020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        70480020
A9M5     EQU   *                                                        70520020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      70530020
         LA    A9WR1,M315IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        70540020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               70550020
         LA    A9L1,M315      1ST-LEVEL MESSAGE NO.                     70560020
         LA    A9L2,M3151     2ND-LEVEL MESSAGE NO.                     70570020
         LA    A9I2,A9L2I2    ADDRESS OF 2ND-LEVEL INSERTION.           70590020
         MVC   A9L2I2(A9MGREGL),A9MGREG INITLZ 2ND-LEVEL INSERT.        70600020
         LA    A9WR1,M3151IN1 GET OFFSET TO INSERTION.                  70610020
         STH   A9WR1,A9L2I2+A9WD+A9HWD PUT IT IN INSERTION HEADER.      70620020
         CVD   SATEMPRC,A9CVDARA CHANGE RET CODE TO PACKED-DEC.         70630020
         UNPK  A9L2I2+A9DWD(A9HWD),A9CVDARA(A9DWD) PLACE UNPACKED       70640020
*                             DECIMAL IN INSERTION TEXT.                70650020
         OI    A9L2I2+A9DWD+A9BYT,A9F0 MAKE TEXT PRINTABLE.             70660020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       70670020
A9M6     EQU   *                                                        70680020
         MVC   A9L2I1(A9MGDAIL),A9MGDAIR GET 1ST INSERTION FOR 2ND      70720020
*                             LEVEL MESSAGE.                            70760020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        70800020
A9M8     EQU   *                                                        70840020
         MVC   A9L2I1(A9MGPUTL),A9MGPUTG GET 1ST INSERTION FOR 2ND      70880020
*                             LEVEL MESSAGE.                            70920020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        70960020
A9M12    EQU   *                                                        71000020
 SPACE                                                                  71005020
* ADDRESS OF SAVE DATA SET RECFM BYTE IS EXPECTED IN SATEMPRC.          71010020
 SPACE                                                                  71015020
         MVC   A9L1I1(A9MGF2L),A9MGF2 INITLZ RECFM INSERTION  'F'.      71020020
         LA    A9WR1,M331IN1  GET OFFSET TO INSERTION.                  71025020
         STH   A9WR1,A9L1I1+A9WD+A9HWD PUT IT IN INSERTION HEADER.      71030020
         LA    A9WR1,A9L1I1+A9DWD+A9BYT INITLZ CURRENT POINTER.         71035020
         TM    O(SATEMPRC),DS1FMTF IS RECFM REALLY FIXED -              71040020
         BO    A9FOK          IF YES,CONTINUE BUILDING INSERTION.       71045020
         MVI   A9L1I1+A9DWD,DS1CHARV IF NO,CHANGE 'F' TO 'V'.           71050020
A9FOK    EQU   *                                                        71055020
         TM    O(SATEMPRC),DS1FMTB ARE RECORDS BLOCKED -                71060020
         BNO   A9NOTB         IF NO,CONTINUE BUILDING INSERTION.        71065020
         MVI   O(A9WR1),DS1CHARB IF YES,MOVE 'B' INTO INSERTION.        71070020
         LA    A9WR1,A9BYT(A9WR1) BUMP CURRENT POINTER.                 71075020
A9NOTB   EQU   *                                                        71080020
         TM    O(SATEMPRC),DS1FMTS IS 'S'-BIT ON -                      71085020
         BNO   A9NOTS         IF NO,GOTO CALCULATE INSERTION LNG.       71090020
         MVI   O(A9WR1),DS1CHARS IF YES,MOVE 'S' INTO INSERTION.        71095020
         LA    A9WR1,A9BYT(A9WR1) BUMP CURRENT POINTER.                 71100020
A9NOTS   EQU   *                                                        71105020
         TM    O(SATEMPRC),DS1FMTT  IS 'T' BIT ON                 M5145 71106021
         BNO   A9NOTT         IF NO,CONTINUE BUILDING INSERTION   M5145 71107021
         MVI   O(A9WR1),DS1CHART IF YES,MOVE 'T' TO INSERTION     M5145 71108021
         LA    A9WR1,A9BYT(A9WR1) BUMP CURRENT POINTER.           M5145 71109021
A9NOTT   EQU   *                                                  M5145 71110021
         TM    O(SATEMPRC),DS1FMTA  IS 'A' BIT ON.                M5145 71111021
         BNO   A9NOTA         IF NO,CONTINUE BUILDING INSERTION   M5145 71112021
         MVI   O(A9WR1),DS1CHARA IF YES,MOVE 'A' TO INSERTION     M5145 71113021
         LA    A9WR1,A9BYT(A9WR1) BUMP CURRENT POINTER.           M5145 71114021
A9NOTA   EQU   *                                                  M5145 71115021
         TM    O(SATEMPRC),DS1FMTM  IS 'M' BIT ON.                M5145 71116021
         BNO   A9NOTM         IF NO,CONTINUE BUILDING INSERTION   M5145 71117021
         MVI   O(A9WR1),DS1CHARM IF YES,MOVE 'M' TO INSERTION     M5145 71118021
         LA    A9WR1,A9BYT(A9WR1) BUMP CURRENT POINTER.           M5145 71119021
A9NOTM   EQU   *                                                  M5145 71120021
         LA    A9I1,A9L1I1+A9WD GET ADDRESS OF INSERTION.         M5145 71121021
         SR    A9WR1,A9I1     CALCULATE LENGTH OF INSERTION.      M5145 71122021
         STH   A9WR1,A9L1I1+A9WD SET LEN IN INSERTION HEADER.     M5145 71123021
         LA    A9L1,M331      1ST-LEVEL MESSAGE NUMBER.           M5145 71124021
         LA    A9I1,A9L1I1    PT TO 1ST-LEVEL INSERTION.          M5145 71125021
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.               M5145 71126021
         LR    A9I2,A9L2      NO 2ND-LEVEL INSERTION.             M5145 71127021
         B     A9MESSAG       BRANCH TO ISSUE MESSAGE.            M5145 71128021
A9M17    EQU   *                                                  M5145 71129021
         MVC   A9L2I1(A9MGDEVL),A9MGDEVT GET 1ST INSERTION FOR 2ND      71200020
*                             LEVEL MESSAGE.                            71240020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        71280020
A9M19    EQU   *                                                        71320020
         MVC   A9L2I1(A9MGOBTL),A9MGOBTA GET 1ST INSERTION FOR 2ND-     71360020
*                             LEVEL MESSAGE.                            71400020
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS.        71440020
A9M24   EQU   *                                                         71480020
         MVC   A9L2I1(A9MGBLLL),A9MGBLDL GET 1ST INSERTION FOR 2ND      71520020
*                             LEVEL MESSAGE.                            71560020
A9M1FUNL EQU   *                                                        71600020
         MVC   A9L2I2(A9MGREGL),A9MGREG INITLZ 2ND INSERTION FOR        71640020
*                             2ND LEVEL MESSAGE.                        71680020
         CVD   SATEMPRC,A9CVDARA CHANGE RET CODE FR BINARY TO           71720020
*                             PACKED DECIMAL.                           71760020
         UNPK  A9L2I2+A9DWD(A9HWD),A9CVDARA(A9DWD) PLACE UNPACKED       71800020
*                             DECIMAL IN INSERTION.                     71840020
         OI    A9L2I2+A9DWD+A9BYT,A9F0 MAKE LAST BYTE PRINTABLE.        71880020
         LA    A9WR1,A9L2I2   GET ADDRESS OF 2ND INSERTION.             71920020
         ST    A9WR1,A9L2I1   PUT IT IN 1ST INSERTION HEADER.           71960020
         LA    A9L1,M313      1ST-LEVEL MESSAGE NO.                     72000020
         LA    A9L2,M3131     2ND-LEVEL MESSAGE NO.                     72040020
         SR    A9I1,A9I1      NO INSERTIONS IN 1ST-LEVEL.               72080020
         LA    A9I2,A9L2I1    ADDRESS OF 1ST 2ND-LEVEL INSERTION.       72120020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       72160020
A9M2     EQU   *                                                        72200020
         LA    A9L1,M312      1ST-LEVEL MESSAGE NO.                     72240020
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     72280020
         LA    A9I1,A9MGSAVE  ADDRESS OF 1ST-LEVEL INSERTION.           72320020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   72360020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       72400020
A9M4     EQU   *                                                        72440020
         LA    A9L1,M310      1ST-LEVEL MESSAGE NO.                     72480020
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     72520020
         MVC   A9L1I1(A9MGWHEL),A9MGWHEN INITLZ INSERTION.              72522020
         LA    A9WR1,A9L1I1+A9DWD INITLZ CURR POINTER.                  72524020
         TM    SADFLTPB+DFPBCNTL-DFPB,SADFUSER IS USERID TO BE          72526020
*                             PREFIXED -                                72528020
         BZ    A9NOID         IF NO,SKIP TO SUFFIX QUALIFIER.           72530020
         L     A9WR1,SAPSCB   IF YES,GET PT TO PSCB.                    72532020
         MVC   A9L1I1+A9DWD+A9BYT(A9DWD),O(A9WR1) MOVE IN USERID.       72534020
         SR    A9I1,A9I1      ZERO REGISTER.                            72536020
         IC    A9I1,A9DWD-A9BYT(A9WR1) GET LNG OF USERID.               72538020
         LA    A9WR1,A9L1I1+A9DWD+A9BYT(A9I1) UPDATE CURR POINTER.      72540020
         MVI   O(A9WR1),SADOT INSERT '.' .                              72542020
A9NOID   EQU   *                                                        72544020
         MVC   A9BYT(L'CASADSN,A9WR1),CASADSN MOVE IN DSNAME.           72546020
         AH    A9WR1,CASADSNL UPDATE CURRENT POINTER.                   72548020
         MVI   A9BYT(A9WR1),SADOT INSERT '.' .                          72550020
         MVC   A9HWD(A9DWD,A9WR1),CADSQUAL MOVE IN QUALIFIER.           72552020
         LA    A9WR1,A9DWD+A9BYT(A9WR1) UPDATE CURRENT POINTER.         72554020
A9BLANKQ EQU   *                                                        72556020
         CLI   O(A9WR1),SABLNK IS THIS A BLANK -                        72558020
         BNE   A9NBLANK       IF NO,END OF INSERTION IS FOUND.          72560020
         BCT   A9WR1,A9BLANKQ IF YES,CONTINUE SEARCH FOR NONBLANK.      72562020
A9NBLANK EQU   *                                                        72564020
         MVI   A9BYT(A9WR1),SAQUOTE INSERT CLOSING QUOTE.               72566020
         LA    A9I1,A9L1I1+A9WD-A9HWD ADDRESS OF BEGNG OF INSERT.       72568020
         SR    A9WR1,A9I1     CALC LNG OF INSERTION.                    72570020
         STH   A9WR1,A9L1I1+A9WD PUT IT IN INSERTION HEADER.            72572020
         LA    A9I1,A9L1I1    SET ADDRESS OF INSERTION.                 72574020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   72600020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       72640020
A9M7     EQU   *                                                        72680020
         LA    A9WR1,M301IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        72720020
         STH   A9WR1,CADSNOF2 PUT IT INTO INSERTION HEADER.             72760020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      72800020
         LA    A9L1,M301      1ST-LEVEL MESSAGE NO.                     72840020
         LA    A9L2,M3011     2ND-LEVEL MESSAGE NO.                     72880020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   72960020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       72980020
A9M28    EQU   *                                                        73008020
         LA    A9L2,M3043     2ND-LEVEL MESSAGE NO.                     73016020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   73024020
         B     A9FIN304       GOTO FINISH SETTING PARAMETERS.           73032020
A9M9     EQU   *                                                        73040020
         LA    A9WR1,SADAIRPB+DA08CTRC-DAPB08 GET ADDRESS OF ERROR      73080020
*                             CODE.                                     73120020
         LA    A9L2,M3042     2ND-LEVEL MESSAGE NO.                     73160020
         MVC   A9L2I1(A9MGCTRL),A9MGCTRC INITLZ 2ND-LEVEL INSERT.       73200020
         B     A9PRINTA       GOTO MAKE RETURN CODE PRINTABLE.          73240020
A9M10    EQU   *                                                        73280020
         LA    A9WR1,SADAIRPB+DA08DARC-DAPB08 GET ADDRESS OF ERROR      73320020
*                             CODE.                                     73360020
         LA    A9L2,M3041     2ND-LEVEL MESSAGE NO.                     73400020
         MVC   A9L2I1(A9MGDARL),A9MGDARC INITLZ 2ND-LEVEL INSERT.       73440020
A9PRINTA EQU   *                                                        73480020
         UNPK  A9L2I1+A9DWD(A9WD+A9BYT),O(L'DA08DARC+A9BYT,A9WR1)       73520020
*                             CONVERT RETURN CODE TO PRINTABLE.         73560020
         TR    A9L2I1+A9DWD(A9WD),A9TRTABL-A9C0                         73600020
         LA    A9I2,A9L2I1    ADDRESS OF 2ND-LEVEL INSERTION.           73610020
A9FIN304 EQU   *                                                        73620020
         LA    A9L1,M304      1ST-LEVEL MESSAGE NO.                     73640020
         LA    A9WR1,M304IN1  GET OFFSET TO 1ST-LEVEL INSERT.           73760020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               73800020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      73840020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       73880020
A9M13    EQU   *                                                        73920020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      73960020
         LA    A9WR1,M305IN1  GET OFFSET TO 1ST-LEVEL INSERTION. A42950 74000000
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               74040020
         LA    A9L1,M305      1ST-LEVEL MESSAGE NO.              A42950 74080000
         LA    A9L2,M3051     2ND-LEVEL MESSAGE NO.              A42950 74120000
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   74200020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       74240020
A9M14    EQU   *                                                        74280020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      74320020
         LA    A9WR1,M306IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        74360020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               74400020
         LA    A9L1,M306      1ST-LEVEL MESSAGE NO.                     74440020
         LA    A9L2,M3061     2ND-LEVEL MESSAGE NO.                     74480020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   74560020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       74600020
A9M15    EQU   *                                                        74640020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      74680020
         LA    A9WR1,M303IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        74720020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               74760020
         LA    A9L1,M303      1ST-LEVEL MESSAGE NO.                     74800020
         LA    A9L2,M3031     2ND-LEVEL MESSAGE NO.                     74840020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   74920020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       74960020
A9M16    EQU   *                                                        75000020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      75040020
         LA    A9WR1,M307IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        75080020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               75120020
         LA    A9L1,M307      1ST-LEVEL MESSAGE NO.                     75160020
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     75200020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   75280020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       75320020
A9M11    EQU   *                                                        75360020
 SPACE                                                                  75400020
* IT IS EXPEXTED THAT THE ONE-BYTE DSORG FIELD IS IN, OR HAS BEEN       75440020
* MOVED INTO, THE DAIR (ENTRY CODE X'08') PARAMETER BLOCK.              75480020
 SPACE                                                                  75520020
         CLI   SADAIRPB+DA08DSO-DAPB08,DS1ORGIS IS DSORG 'ISAM' -       75560020
         BNE   A9NOTSPI       IF NO,GOTO GET 'DIRECT' MESSAGE           75600020
*                             INSERTION,SINCE DSORG IS NOT              75640020
*                             SEQUENTIAL,PARTITIONED,OR ISAM.           75680020
         MVC   A9L1I1(A9MGISAL),A9MGISAM IF YES,GET 'ISAM' MESSAGE      75720020
*                             INSERTION.                                75760020
         B     A9DSORG        GOTO FINISH MESSAGE PREPARATION.          75800020
A9NOTSPI EQU   *                                                        75840020
         MVC   A9L1I1(A9MGDIRL),A9MGDIRE GET 'DIRECT' MESSAGE           75880020
*                             INSERTION.                                75920020
A9DSORG  EQU   *                                                        75960020
         LA    A9WR1,CADSNPT2 GET ADDRESS OF 2ND 1ST-LEVEL INSERT.      76000020
         ST    A9WR1,A9L1I1   PUT IT IN 1ST INSERTION'S HEADER.         76040020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 3RD INSERTION.      76080020
         LA    A9WR1,M330IN2  GET OFFSET TO 2ND 1ST-LEVEL INSERT.       76120020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               76160020
         LA    A9L1,M330      1ST-LEVEL MESSAGE NO.                     76200020
         LA    A9L2,M3301     2ND-LEVEL MESSAGE NO.                     76240020
         LA    A9I1,A9L1I1    ADDRESS OF 1ST 1ST-LEVEL INSERTION.       76280020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   76320020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       76360020
A9M18    EQU   *                                                        76400020
         LA    A9L1,M554      1ST-LEVEL MESSAGE NO.                     76440020
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     76480020
         SR    A9I1,A9I1      NO 1ST-LEVEL INSERTION.                   76520020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   76560020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       76600020
A9M20    EQU   *                                                        76640020
 SPACE                                                                  76680020
* ADDRESS OF SAVE DATA SET RECFM BUTE IN DSCB IS EXPECTED IN SATEMPRC.  76720020
 SPACE                                                                  76760020
         LA    A9L2,M5521     SET 2ND-LEVEL MESSAGE NO.                 76800020
         TM    O(SATEMPRC),DS1FMTU IS SAVE RECFM=U -                    76840020
         BM    A9FMTVT        IF NO,GOTO TEST FOR RECFM=V.              76880020
         MVC   A9L2I2(A9MGU2L),A9MGU2 IF YES,SET 2ND 2ND-LEVEL          76920020
*                             INSERTION.                                76960020
         B     A9EDTFMT       GOTO FIND EDIT RECFM.                     77000020
A9FMTVT  EQU   *                                                        77040020
         TM    O(SATEMPRC),DS1FMTV IS SAVE RECFM=V -                    77080020
         BZ    A9FMTU         IF NO,GOTO SET 2ND 2ND-LEVEL INSERT.      77120020
         MVC   A9L2I2(A9MGV2L),A9MGV2 IF YES,SET 2ND 2ND-LEVEL          77160020
*                             INSERT.                                   77200020
         B     A9EDTFMT       GOTO FIND EDIT RECFM.                     77240020
A9FMTU   EQU   *                                                        77280020
         MVC   A9L2I2(A9MGF2L),A9MGF2 SET 2ND 2ND-LEVEL INSERTION.      77320020
A9EDTFMT EQU   *                                                        77360020
         TM    CACFLAG2,CARECFM ARE EDIT RECORDS FIXED -                77400020
         BZ    A9FMTV         IF NO,GOTO SET 1ST 2ND-LEVEL INSERT.      77440020
         MVC   A9L2I1(A9MGF1L),A9MGF1 IF YES,SET 1ST 2ND-LEVEL          77480020
*                             INSERTION.                                77520020
         B     A9M20FUN       GOTO FINISH SETTING-UP INSERTIONS.        77560020
A9FMTV   EQU   *                                                        77600020
         MVC   A9L2I1(A9MGV1L),A9MGV1 SET 1ST 2ND-LEVEL INSERTION.      77640020
         B     A9M20FUN       GOTO FINISH SETTING-UP INSERTIONS.        77680020
A9M21    EQU   *                                                        77720020
 SPACE                                                                  77760020
* BINARY SAVE DATA SET BLKSIZE EXPECTED IN SATEMPRC.                    77800020
 SPACE                                                                  77840020
         LA    A9L2,M5523     SET 2ND-LEVEL MESSAGE NO.                 77880020
         MVC   A9L2I1(A9MGBK1L),A9MGBK1 INITLZ 1ST 2ND-LEVEL            77920020
*                             INSERTION.                                77960020
         MVC   A9L2I2(A9MGBK2L),A9MGBK2 INITLZ 2ND 2ND-LEVEL            78000020
*                             INSERTION.                                78040020
         CVD   SATEMPRC,A9CVDARA CHANGE BLKSIZE FR BINARY TO            78080020
*                             PACKED DECIMAL.                           78120020
         UNPK  A9L2I2+A9DWD(A9WD+A9BYT),A9CVDARA(A9DWD) PLACE           78160020
*                             UNPACKED DECIMAL IN INSERTION.            78200020
         OI    A9L2I2+A9DWD+A9WD,A9F0 MAKE LAST BYTE PRINTABLE.         78240020
         LH    SATEMPRC,CABLKS GET EDIT BLKSIZE.                        78280020
         CVD   SATEMPRC,A9CVDARA CHANGE FR BINARY TO PACKED DEC.        78320020
         UNPK  A9L2I1+A9DWD(A9WD+A9BYT),A9CVDARA(A9DWD) PLACE           78360020
*                             UNPACKED DECIMAL IN INSERTION.            78400020
         OI    A9L2I1+A9DWD+A9WD,A9F0 MAKE LAST BYTE PRINTABLE.         78440020
         B     A9M20FUN       GOTO FINISH SETTING-UP INSERTIONS.        78480020
A9M22    EQU   *                                                        78520020
 SPACE                                                                  78560020
* BINARY SAVE DATA SET LRECL EXPECTED IN SATEMPRC.                      78600020
 SPACE                                                                  78640020
         LA    A9L2,M5522     SET 2ND-LEVEL MESSAGE NO.                 78680020
         MVC   A9L2I1(A9MGLL1L),A9MGLL1 INITLZ 1ST 2ND-LEVEL            78720020
*                             INSERTION.                                78760020
         MVC   A9L2I2(A9MGLL2L),A9MGLL2 INITLZ 2ND 2ND-LEVEL            78800020
*                             INSERTION.                                78840020
         CVD   SATEMPRC,A9CVDARA CHANGE LRECL FR BINARY TO PACKED.      78880020
         UNPK  A9L2I2+A9DWD(A9HWD+A9BYT),A9CVDARA(A9DWD) PLACE          78920020
*                             UNPACKED DECIMAL IN INSERTION.            78960020
         OI    A9L2I2+A9DWD+A9HWD,A9F0 MAKE LAST BYTE PRINTABLE.        79000020
         LH    SATEMPRC,CALRECL GET EDIT LRECL.                         79040020
         TM    CACFLAG2,CARECFM IS EDIT RECFM=F -                       79080020
         BZ    A9EDVAR        IF NO,GOTO BUILD INSERTION.               79120020
         SH    SATEMPRC,A9CWL IF YES,SUBTRACT CONTROL WORD LENGTH.      79160020
A9EDVAR  EQU   *                                                        79200020
         CVD   SATEMPRC,A9CVDARA CHANGE LRECL FR BIMARY TO PACKED.      79240020
         UNPK  A9L2I1+A9DWD(A9HWD+A9BYT),A9CVDARA(A9DWD) PLACE          79280020
*                             UNPACKED DECIMAL IN INSERTION.            79320020
         OI    A9L2I1+A9DWD+A9HWD,A9F0 MAKE LAST BYTE PRINTABLE.        79360020
A9M20FUN EQU   *                                                        79400020
         LA    A9WR1,M552IN2  GET OFFSET TO 2ND 1ST-LEVEL INSERT.       79440020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               79480020
         TM    SASWICHS,SAS@EEQ2 ARE EDIT,SAVE DSNAMES ALIKE -          79520020
         BZ    A9S@ENEQ       IF NO,GOTO INITLZ 1ST 1ST-LEVEL           79560020
*                                   INSERTION.                          79600020
         MVC   A9L1I1(A9MGUTLL),A9MGUTIL IF YES,INITLZ 1ST 1ST-         79640020
*                             LEVEL INSERTION.                          79680020
         B     A9M20REG       GOTO SET REGISTERS.                       79720020
A9S@ENEQ EQU   *                                                        79760020
         MVC   A9L1I1(L'CADSNPTR+L'CADSNLEN+L'CADSNOFF+L'CADSNREC),CADSC79800020
               NPTR           INITLZ 1ST 1ST-LEVEL INSERTION.           79840020
A9M20REG EQU   *                                                        79880020
         LA    A9WR1,M552IN1  GET OFFSET TO 1ST 1ST-LEVEL INSERT.       79890020
         STH   A9WR1,A9L1I1+A9WD+A9HWD PUT IT IN INSERTION HEADER.      79900020
         LA    A9WR1,CADSNPT2 GET PT TO 2ND 1ST-LEVEL INSERTION.        79930020
         ST    A9WR1,A9L1I1   SET IT IN 1ST 1ST-LEVEL INSERTION.        79960020
         LA    A9WR1,A9L2I2   GET PT TO 2ND 2ND-LEVEL INSERTION.        80000020
         ST    A9WR1,A9L2I1   SET IT IN 1ST 2ND-LEVEL INSERTION.        80040020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 NO 3RD 1ST-LEVEL INS.      80080020
         LA    A9L1,M552      SET 1ST-LEVEL MESSAGE NO.                 80120020
         LA    A9I1,A9L1I1    SET PT TO 1ST 1ST-LEVEL INSERTION.        80160020
         LA    A9I2,A9L2I1    SET PT TO 1ST 2ND-LEVEL INSERTION.        80200020
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       80240020
A9M23    EQU   *                                                        80280020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      80320020
         LA    A9WR1,M309IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        80360020
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               80400020
         LA    A9L1,M309      1ST-LEVEL MESSAGE NO.                     80440020
         LA    A9L2,M3093     2ND-LEVEL MESSAGE NO.                     80480020
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   80560020
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       80580020
A9M25    EQU   *                                                        80600420
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 IND NO 2ND INSERTION.      80600820
         LA    A9WR1,M316IN1  GET OFFSET TO 1ST-LEVEL INSERTION.        80601220
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               80601620
         LA    A9L1,M316      1ST-LEVEL MESSAGE NO.                     80602020
         LA    A9L2,M3161     2ND-LEVEL MESSAGE NO.                     80602820
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   80603220
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       80603620
A9M26    EQU   *                                                        80604020
         LA    A9L2,M4244     2ND-LEVEL MESSAGE NO.                     80604420
         MVC   A9L2I2(A9MGCTRL),A9MGCTRC INITLZ 2ND-LEVEL INSERT.       80604820
         LA    A9WR1,M4244IN2 GET OFFSET TO 2ND 2ND-LEVEL INSERT.       80605220
         STH   A9WR1,A9L2I2+A9WD+A9HWD PUT IT IN INSERTION HEADER.      80605620
         LA    A9WR1,SADAIRPB+DA18CTRC-DAPB18 GET ADDRESS OF ERROR      80606020
*                             CODE.                                     80606420
         B     A9PRINTB       GOTO MAKE CODE PRINTABLE.                 80606820
A9M27    EQU   *                                                        80607220
         LA    A9L2,M4242     2ND-LEVEL MESSAGE NO.                     80607620
         MVC   A9L2I2(A9MGDARL),A9MGDARC INITLZ 2ND-LEVEL INSERT.       80608020
         LA    A9WR1,M4242IN2 GET OFFSET TO 2ND 2ND-LEVEL INSERT.       80608420
         STH   A9WR1,A9L2I2+A9WD+A9HWD PUT IT IN INSERTION HEADER.      80608820
         LA    A9WR1,SADAIRPB+DA18DARC-DAPB18 GET ADDRESS OF ERROR      80609220
*                             CODE.                                     80609620
A9PRINTB EQU   *                                                        80610020
         UNPK  A9L2I2+A9DWD(A9WD+A9BYT),O(L'DA18DARC+A9BYT,A9WR1)       80610420
*                             CONVERT ERROR CODE TO PRINTABLE.          80610820
         TR    A9L2I2+A9DWD(A9WD),A9TRTABL-A9C0                         80611220
         LA    A9L1,M424      1ST LEVEL MESSAGE NO.                     80611620
         SR    A9I1,A9I1      NO 1ST-LEVEL INSERTION.                   80612020
         LA    A9I2,A9L2I1    ADDRESS OF 1ST 2ND-LEVEL INSERTION.       80612420
         LA    A9WR1,A9L2I2   GET ADDRESS OF 2ND 2ND-LEVEL INSERT.      80612820
         ST    A9WR1,A9L2I1   PUT IT IN INSERTION HEADER.               80613220
         LA    A9WR1,M4242IN1 GET OFFSET TO 1ST 2ND-LEVEL INSERT.       80613620
         STH   A9WR1,A9L2I1+A9WD+A9HWD PUT IT IN INSERTION HEADER.      80614020
         MVI   A9L2I1+A9DWD,SAQUOTE PUT ' AT BEGNG OF DSNAME TEXT.      80614420
         MVC   A9L2I1+A9DWD+A9BYT(L'CASADSN),CASADSN MOVE IN DSN.       80614820
         LH    A9WR1,CASADSNL GET LNG OF DSNAME.                        80615220
         LA    A9WR1,A9WD+A9HWD(A9WR1) ADD LNG OF HEADER,2 QUOTES.      80615620
         STH   A9WR1,A9L2I1+A9WD SET LNG IN HEADER.                     80616020
         LA    A9WR1,A9L2I1+A9WD-A9BYT(A9WR1) GET PT TO DSN END.        80616420
         MVI   O(A9WR1),SAQUOTE PUT ' AFTER DSNAME.                     80616820
         B     A9MESSAG       GOTO ISSUE MESSAGE.                       80617220
A9M29    EQU   *                                                        80617620
         MVC   A9L2I1(A9MGPTLL),A9MGPTLN GET 1ST INSERTION FOR   A42951 80619600
*                             2ND LEVEL MESSAGE.                 A42951 80620000
         B     A9M1FUNL       GOTO FINISH SETTING-UP PARAMETERS. A42951 80620400
A9M30    EQU   *                                                        80621220
         LA    A9L2,M3181     2ND-LEVEL MSG NO.                         80621620
         B     A9FIN318       GOTO FINISH SETTING PARAMETERS.           80622020
A9M31    EQU   *                                                        80622420
         LA    A9L2,M3182     2ND-LEVEL MESSAGE MO.                     80622820
A9FIN318 EQU   *                                                        80623220
         LA    A9L1,M318      1ST-LEVEL MESSAGE NO.                     80623620
         SR    A9I2,A9I2      NO 2ND-LEVEL INSERTION.                   80624020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 NO 2ND 1ST-LEVEL INS.      80624420
         LA    A9WR1,M318IN1  GET OFFSET TO INSERTION.                  80624820
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               80625220
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       80625820
A9M32    EQU   *                                                        80626420
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 NO 2ND INSERTION.          80626820
         LA    A9WR1,M317IN1  GET OFFSET TO INSERTION.                  80627220
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               80627620
         LA    A9L1,M317      1ST-LEVEL MESSAGE NO.                     80628020
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     80628820
         LR    A9I2,A9L2      NO 2ND-LEVEL INSERTION.                   80629220
         B     A9DSNINS       GOTO SET PT TO 1ST-LEVEL INSERTION.       80629620
A9M33    EQU   *                                                        80630020
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2  NO 2ND INSERTION.         80630420
         LA    A9WR1,M314IN1  GET OFFSET TO INSERTON.                   80630820
         STH   A9WR1,CADSNOF2 PUT IT IN INSERTION HEADER.               80631220
         LA    A9L1,M314      1ST-LEVEL MESSAGE NO.                     80631620
         SR    A9L2,A9L2      NO 2ND-LEVEL MESSAGE.                     80632420
         LR    A9I2,A9L2      NO 2ND-LEVEL INSERTION.                   80632820
         B     A9DSNINS       BRANCH TO SET UP DSNAME INSERTION. A52001 80632921
A9M34    EQU   *                                                 A52001 80633021
         XC    CADSNPT2(L'CADSNPT2),CADSNPT2 NO 2ND INSERTION.   A52001 80633121
         LA    A9WR1,M319IN1  OBTAIN OFFSET FOR DSN INSERTION.   A52001 80633221
         STH   A9WR1,CADSNOF2 SET OFFSET IN INSERTION LIST.      A52001 80633321
         LA    A9L1,M319      FIRST-LEVEL RELATIVE NUMBER.       A52001 80633421
         LA    A9L2,M3191     SECOND-LEVEL RELATIVE NUMBER.      A52001 80633521
         SR    A9I2,A9I2      NO SECOND-LEVEL INSERTIONS.        A52001 80633621
A9DSNINS EQU   *                                                        80634820
         LA    A9I1,CADSNPT2  SET PT TO DSNAME INSERTION.               80636820
 SPACE                                                                  80640020
*********************************************************************** 80680020
* CALL IKJEBEMS TO SELECT AND ISSUE THE MESSAGE(S), AND RETURN TO THE * 80720020
* POINT IN THE MAIN CONTROL SECTION (IKJEBESA) WHOSE ADDRESS IS IN    * 80760020
* REGISTER 14.                                                        * 80800020
*********************************************************************** 80840020
 SPACE                                                                  80880020
A9MESSAG EQU   *                                                        80920020
         IKJEBEML (A9L1),(A9L2),(A9I1),(A9I2),MF=(E,SA10AREA)           80960020
 SPACE                                                                  80964020
         LH    SAWR1,SARETCOD GET CURRENT RET CODE.                     80968020
         OR    SAWR1,SAWR1    IS RET CODE ZERO -                        80972020
         BNZ   A9RETURN       IF NO,GOTO RETURN TO CALLER.              80976020
         LA    SAWR1,SARCNOTC IF YES,SET RET CODE TO IND FUNCTION       80980020
         STH   SAWR1,SARETCOD NOT COMPLETE.                             80984020
 SPACE                                                                  80988020
A9RETURN EQU   *                                                        80992020
         IKJEBERT (14,12),,RC=(15)                                      81000020
 SPACE                                                                  81040020
*********************************************************************** 81080020
* CONSTANTS USED IN IKJEBSA9.                                         * 81120020
*********************************************************************** 81160020
 SPACE                                                                  81200020
A9CWL    DC    H'4'           LNG OF UTILITY RECORD CONTROL WORD.       81240020
A9MGPARS IKJEBEMG 0,M3131IN1,'PARSE' SERVICE ROUTINE NAME INSERT.       81280020
A9MGPARL EQU   *-A9MGPARS     LNG OF INSERTION.                         81320020
A9MGDEFA IKJEBEMG 0,M3131IN1,'DEFAULT' SERVICE RTN NAME INSERTION.      81360020
A9MGDEFL EQU   *-A9MGDEFA     LNG OF INSERTION.                         81400020
A9MGDAIR IKJEBEMG 0,M3131IN1,'DAIR' SERVICE ROUTINE NAME INSERT.        81520020
A9MGDAIL EQU   *-A9MGDAIR     LNG OF INSERTION.                         81560020
A9MGPUTG IKJEBEMG 0,M3131IN1,'PUTGET' SERVICE ROUTINE NAME INSERT.      81600020
A9MGPUTL EQU   *-A9MGPUTG     LNG OF INSERTION.                         81640020
A9MGPTLN IKJEBEMG 0,M3131IN1,'PUTLINE' SERVICE ROUTINE NAME.     A42951 81650000
A9MGPTLL EQU   *-A9MGPTLN     LNG OF INSERTION.                  A42951 81660000
A9MGUNAL IKJEBEMG 0,M3131IN1,'UNALLOCATION' SERVICE RTN NAME INS.       81680020
A9MGUNLL EQU   *-A9MGUNAL     LNG OF INSERTION.                         81720020
A9MGDEVT IKJEBEMG 0,M3131IN1,'DEVTYPE' MACRO NAME INSERTION.            81760020
A9MGDEVL EQU   *-A9MGDEVT     LNG OF INSERTION.                         81800020
A9MGOBTA IKJEBEMG 0,M3131IN1,'OBTAIN' MACRO NAME INSERTION.             81840020
A9MGOBTL EQU   *-A9MGOBTA     LNG OF INSERTION.                         81880020
A9MGBLDL IKJEBEMG 0,M3131IN1,'BLDL' MACRO NAME INSERTION.               81920020
A9MGBLLL EQU   *-A9MGBLDL     LNG OF INSERTION.                         81960020
A9MGREG  IKJEBEMG 0,M3131IN2,'XX' REGISTER RETURN CODE INSERTION.       82000020
A9MGREGL EQU   *-A9MGREG      LNG OF INSERTION.                         82040020
A9MGSAVE IKJEBEMG 0,M312IN1,'SAVE' SUBCOMMAND NAME INSERTION.           82080020
A9MGSAVL EQU   *-A9MGSAVE     LNG OF INSERTION.                         82120020
A9MGWHEN IKJEBEMG 0,M310IN1,'''' DSNAME INSERTION.                      82140020
A9MGWHEL EQU   *-A9MGWHEN     LNG OF INSERTION.                         82160020
A9MGCTRC IKJEBEMG 0,M3042IN1,'CTRC' CATALOG MANAGEMENT RETURN CODE      82200020
*                             INSERTION.                                82240020
A9MGCTRL EQU   *-A9MGCTRC     LNG OF INSERTION.                         82280020
A9MGDARC IKJEBEMG 0,M3041IN1,'DARC' DYNAMIC ALLOCATION RETURN CODE      82320020
*                             INSERTION.                                82360020
A9MGDARL EQU   *-A9MGDARC     LNG OF INSERTION.                         82400020
A9MGISAM IKJEBEMG 0,M330IN1,'ISAM' DSORG INSERTION.                     82440020
A9MGISAL EQU   *-A9MGISAM     LNG OF INSERTION.                         82480020
A9MGDIRE IKJEBEMG 0,M330IN1,'DIRECT' DSORG INSERTION.                   82520020
A9MGDIRL EQU   *-A9MGDIRE     LNG OF INSERTION.                         82560020
A9MGF2   IKJEBEMG 0,M5521IN2,'F' RECFM F INSERTION(SAVE).               82600020
A9MGF2L  EQU   *-A9MGF2       LNG OF INSERTION.                         82640020
A9MGV2   IKJEBEMG 0,M5521IN2,'V' RECFM V INSERTION(SAVE).               82680020
A9MGV2L  EQU   *-A9MGV2       LNG OF INSERTION.                         82720020
A9MGU2   IKJEBEMG 0,M5521IN2,'U' RECFM U INSERTION(SAVE).               82760020
A9MGU2L  EQU   *-A9MGU2       LNG OF INSERTION.                         82800020
A9MGF1   IKJEBEMG 0,M5521IN1,'F' RECFM F INSERTION(EDIT).               82840020
A9MGF1L  EQU   *-A9MGF1       .NG OF INSERTION.                         82880020
A9MGV1   IKJEBEMG 0,M5521IN1,'V' RECFM V INSERTION(EDIT).               82920020
A9MGV1L  EQU   *-A9MGV1       LNG OF INSERTION.                         82960020
A9MGBK1  IKJEBEMG 0,M5523IN1,'BBBBB' BLOCKSIZE INSERTION(EDIT).         83000020
A9MGBK1L EQU   *-A9MGBK1      LNG OF INSERTION.                         83040020
A9MGBK2  IKJEBEMG 0,M5523IN2,'BBBBB' BLOCKSIZE INSERTION(SAVE).         83080020
A9MGBK2L EQU   *-A9MGBK2      LNG OF INSERTION.                         83120020
A9MGLL1  IKJEBEMG 0,M5522IN1,'LLL' LRECL INSERTION(EDIT).               83160020
A9MGLL1L EQU   *-A9MGLL1      LNG OF INSERTION.                         83200020
A9MGLL2  IKJEBEMG 0,M5522IN2,'LLL' LRECL INSERTION(SAVE).               83240020
A9MGLL2L EQU   *-A9MGLL2      LNG OF INSERTION.                         83280020
A9MGUTIL IKJEBEMG 0,M552IN1,'(UTILITY)' FAKE EDIT DSNAME INSERT.        83320020
A9MGUTLL EQU   *-A9MGUTIL     LNG OF INSERTION.                         83360020
A9TRTABL DC    CL16'0123456789ABCDEF' TRANSLATE TABLE FOR               83440020
*                             CONVERSION TO PRINTABLE HEXADECIMAL.      83480020
 SPACE                                                                  83520020
*********************************************************************** 83560020
* EQUATES USED IN IKJEBSA9.                                           * 83600020
*********************************************************************** 83640020
 SPACE                                                                  83680020
A9L1     EQU   3              THE   RELATIVE 1ST-LEVEL MESSAGE NO.      83720020
A9L2     EQU   4              THE   RELATIVE 2ND-LEVEL MESSAGE NO.      83760020
A9I1     EQU   5              PT TO 1ST INSERTION,1ST-LEVEL MSG.        83800020
A9I2     EQU   6              PT TO 1ST INSERTION,2ND-LEVEL MSG.        83840020
A9WR1    EQU   7              FIRST WORKING REGISTER.                   83880020
A9BYT    EQU   1              BYTE.                                     83920020
A9HWD    EQU   2              HALFWORD.                                 83960020
A9WD     EQU   4              WORD.                                     84000020
A9DWD    EQU   8              DOUBLEWORD.                               84040020
A9F0     EQU   C'0'           FOR 'OR'ING INTO UNPACKED DECIMAL         84080020
*                             LAST BYTE.                                84120020
A9C0     EQU   C'0'           CHARACTER ZERO.                           84160020
 SPACE                                                                  84200020
*********************************************************************** 84240020
* EQUATES - RELATIVE MESSAGE NUMBERS AND INSERTION OFFSETS.           * 84280020
*********************************************************************** 84320020
 SPACE                                                                  84360020
         IKJEBEMI (301,302,303,304,305,306,307,309,310,311,312,313,314,C84400020
               315,316,317,318,319,330,331,339,424,552,553,554)  A52001 84440021
 SPACE                                                                  84480020
IEFTIOT1 DSECT                TASK INPUT/OUTPUT TABLE.                  84520020
         IEFTIOT1                                                       84560020
IEFUCBOB DSECT                UNIT CONTROL BLOCK.                       84600020
         IEFUCBOB                                                       84640020
CVT      DSECT                COMMUNICATIONS VECTOR TABLE.              84680020
         CVT   SYS=VMS                                                  84720020
IECDSCB1 DSECT                FORMAT 1 DATA SET CONTROL BLOCK.          84760020
         IECSDSL1 (1)                                                   84800020
         IKJCPPL                                                        84840020
         IKJPPL                                                         84880020
         IKJDAPL                                                        84920020
         IKJDAP08                                                       84960020
         IKJDAP18                                                       85000020
         DCBD  DSORG=PO,DEVD=DA                                         85040020
         IKJDFPL                                                        85080020
         IKJDFPB                                                        85120020
         IKJPSCB                                                        85160020
         IKJIOPL                                                        85200020
         IKJPGPB                                                        85240020
         IKJEBECA                                                       85280020
 SPACE                                                                  85320020
*********************************************************************** 85360020
* DEFINE AREAS IN COMMUNICATION AREA.                                 * 85400020
*********************************************************************** 85440020
 SPACE                                                                  85480020
         ORG   CASCWKA        BEGIN SUBCOMMAND WORKAREA.                85520020
A9CVDARA DS    0D             FOR CONVERTING RETURN CODE IN             85560020
*                             REGISTER TO PACKED DECIMAL.               85600020
SAMEMPTR DS    F              PT TO NEXT INSERTION.                     85640020
SAMEMLEN DS    H              LNG OF MEMBER NAME INSERTION.             85680020
SAMEMOFF DS    H              OFFSET TO MEMBER NAME INSERTION.          85720020
SAMEMREC DS    CL12           MEMBER NAME TEXT - '(XXXXXXXX)'.          85760020
SAPSCB   DS    2F             PT TO PSCB,PT TO DAIR PARM BLOCK.         85800020
SAPDLFLS DS    X              FOR SAVING FLAG BYTE FROM PDL.            85840020
SASWICHS DS    X              LOCAL SWITCHES.                           85880020
SAINCTLG EQU   X'01'          ON-DEFAULT FOUND DSNAME IN                85920020
*                             CATALOG/OFF-DIDN'T.                       85960020
SAS@EEQ1 EQU   X'02'          ON-SAVE AND EDIT DSNAMES AND MEMBER       86000020
*                             NAMES ARE ALIKE/OFF-AREN'T.               86040020
SAS@EEQ2 EQU   X'04'          ON-SAVE AND EDIT DSNAMES ARE ALIKE/       86080020
*                             OFF-AREN'T.                               86120020
SAISSSVD EQU   X'08'          ON-ISSUE 'SAVED' MESSAGE BEFORE           86160020
*                             EXIT/OFF-DON'T.                           86200020
SAEDOL   EQU   X'10'          ON-'OLD' WAS ON EDIT CMD/OFF-WASN'T.      86240020
SADEFCAL EQU   X'20'          ON-'DEFAULT' WAS CALLED/OFF-WASN'T.       86260020
SAMEMLNG DS    H              LENGTH OF MEMBER NAME.                    86280020
SARETCOD DS    H              TO HOLD RETURN CODE FROM IKJEBESA         86320020
*                             UNTIL EXIT.                               86360020
SASHPLST DS    3F             PARAMETER LIST FOR SERVICE ROUTINE        86400020
*                             HANDLER.                                  86440020
SAOPENPL DS    F              OPEN PARAMETER LIST.                      86480020
SADCB    DS    CL96           BPAM DCB.                                 86520020
SA10AREA DS    10F            FOR USE OF IKJEBEML E-FORM.               86560020
SAQUALFR DS    CL8            QUALIFIER TO BE ADDED BY 'DEFAULT'.       86580020
SABLDL   DS    0F             BLDL LIST.                                86600020
SADAIRPB DS    0F             DAIR PARAMETER BLOCK.                     86640020
SADFLTPB DS    0F             DEFAULT PARAMETER BLOCK.                  86680020
SAPTGTPB DS    0F             PUTGET PARAMETER BLOCK.                   86720020
SAFREEME DS    0F             FOR USE OF FREEMAIN E-FORM.               86760020
         ORG   CATEMPBF       BEGIN TEMPORARY BUFFER POOL.              86800020
SADEVTBL DS    0F             DEVTYPE WORKAREA.                         86840020
SADEVTRK EQU   12             OFFSET TO MAX TRACK SIZE.                 86880020
SAOBFLGS DS    F              CAMLST FLAGS FOR OBTAIN.                  86920020
SAOBDSNP DS    F              PT TO DATA SET NAME FOR OBTAIN.           86960020
SAOBVOLP DS    F              PT TO VOLUME SERIAL NO. FOR OBTAIN.       87000020
SAOBWRKP DS    F              PT TO OBTAIN WORK AREA.                   87040020
SAOBWORK DS    350C           OBTAIN WORKAREA.                          87080020
SAVOLSER DS    CL6            VOLUME SERIAL NUMBER.                     87120020
         ORG   CABFRPL        BEGIN BUFFER POOL.                        87160020
A9L1I1   DS    CL132          1ST 1ST-LEVEL MESSAGE INSERTION.          87200020
A9L1I2   DS    CL132          2ND 1ST-LEVEL MESSAGE INSERTION.          87240020
A9L2I1   DS    CL132          1ST 2ND-LEVEL MESSAGE INSERTION.          87280020
A9L2I2   DS    CL132          2ND 2ND-LEVEL MESSAGE INSERTION.          87320020
         ORG   CABFRPL        BEGIN BUFFER POOL.                        87360020
SAPTGTIN DS    CL256          TO SAVE INPUT FROM PUTGET.                87400020
         END                                                            87440020
