BESE TITLE 'TSO EDIT COMMAND  STRING SEARCH SERVICE ROUTINE  IKJEBESE'  00300020
IKJEBESE CSECT                                                          00600020
*A601000,607000                                                 SA67642 00898121
*C606000                                                        SA67642 00898221
*********************************************************************** 00900020
*                                                                     * 01200020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                      * 01500020
*                                                                     * 01800020
*FUNCTION -- THIS ROUTINE WILL SCAN  A RANGE OF LINES AT EVERY        * 02100020
*   OFFSET FOR A GIVEN STRING. TEXT DATA SETS ARE CHECKED ACROSS      * 02400020
*   RECORDS FOR THE STRING ALSO.                                      * 02700020
*                                                                     * 03000020
*ENTRY POINT -- IKJEBESE                                              * 03300020
*                                                                     * 03600020
*INPUT -- REGISTER ZERO CONTAINS A POINTER TO THE EDIT COMMUNICATION  * 03900020
*   AREA, DEFINED BY THE IKJEBECA MACRO. REGISTER ONE POINTS TO       * 04200020
*   A PARAMETER LIST CONTAINING                                       * 04270020
*        WORD 1 - ADDRESS OF UTILITY DATASET DCB                      * 04340020
*        WORD 2 - BYTES 0-1 -- OFFSET AT WHICH TO BEGIN SEARCH        * 04410020
*                 BYTES 2-3 -- LENGTH OF SEARCH STRING                * 04480020
*        WORD 3 - ADDRESS OF SEARCH STRING                            * 04550020
*        WORD 4 - POINTER TO BUFFER TO BE USED, CONTAINING FIRST RCD  * 04620020
*        WORD 5 - POINTER TO DOUBLE WORD CONTAINING RANGE OF LINE     * 04690020
*                 NUMBERS TO SEARCH, BEGINNING WITH NUMBER OF LINE    * 04760020
*                 CURRENTLY IN THE BUFFER. IF THE FIRST LINE NUMBER   * 04830020
*                 OF THIS RANGE IS NEGATIVE THE SECOND NUMBER IS      * 04900020
*                 INSTEAD A COUNT OF THE NUMBER OF RECORDS TO SEARCH  * 04970020
*                                                                     * 05100020
*OUTPUT -- RETURN CODES IN REGISTER 15 ARE (IN HIGH ORDER BYTE)       * 05400020
*   X'00' - TEXT FOUND IN ONE LINE                                    * 05600020
*   X'04' - TEXT FOUND ACROSS LINES                                   * 05800020
*   X'08' - TEXT NOT FOUND                                            * 06000020
*   X'0C' - I/O ERROR ON UTILITY DATASET                              * 06200020
*                                                                     * 06400020
*   OFFSET OF TEXT IN DATA PORTION OF LINE, ORIGIN ONE, IS IN         * 06600020
*   LOW ORDER TWO BYTES OF REGISTER 15                                * 06800020
*                                                                     * 07200020
*EXTERNAL REFERENCES --                                               * 07500020
*        IKJEBEUT -- READS UTILITY DATASET                            * 07800020
*        MACROS USED --                                               * 08100020
*        IKJEBESV -- ENTRY LINKAGE                                    * 08400020
*        IKJEBESV -- ENTRY LINKAGE                                    * 08700020
*        IKJEBERT -- EXIT LINKAGE                                     * 09000020
*        IKJEBESH -- SETS UP PARAMETER LIST AND LINKS TO IKJEBEUT     * 09300020
*                                                                     * 09600020
*EXITS, NORMAL -- RETURN TO CALLER WITH RETURN CODE                   * 09900020
*                                                                     * 10200020
*EXITS, ERROR -- RETURN TO CALLER, RETURN CODE X'0C' FOR I/O ERROR    * 10500020
*                                                                     * 10800020
*TABLES/WORKAREAS -- THE CASCWKA FIELD OF THE COMMUNICATIONS AREA,    * 11100020
*   DEFINED IN THE IKJEBECA MACRO, IS USED FOR                        * 11400020
*   WORK SPACES.  THE BUFFER POINTED TO BY THE CALLER IS ALSO         * 11700020
*   USED FOR SOME WORK SPACE.                                         * 12000020
*                                                                     * 12300020
*ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED.                  * 12600020
*                                                                     * 12900020
*NOTES -- THERE IS NO CHARACTER CODE DEPENDENCY.                      * 12960020
*   IF A STRING IS FOUND ACROSS LINES, THE SECOND RECORD IS PLACED    * 13020020
*   AT A SPECIFIC OFFSET IN THE BUFFER, TO WHICH IKJEBECH IS          * 13080020
*   SENSITIVE.                                                        * 13140020
*********************************************************************** 13200020
         EJECT                                                          13300020
         SPACE                                                          13500020
*  REGISTER AND SPECIAL EQUATES                                         14200020
PARMREG0 EQU   0                   PARAMETER REGISTER                   15000020
PARMREG1 EQU   1                   PARAMETER REGISTER                   15300020
WRA      EQU   2                   GENERAL REGISTER                     15600020
WRB      EQU   3                   GENERAL REGISTER                     15900020
WRC      EQU   4                   GENERAL REGISTER                     16200020
WRD      EQU   5                   GENERAL REGISTER                     16500020
WRE      EQU   6                   GENERAL REGISTER                     16800020
WRF      EQU   7                   GENERAL REGISTER                     17100020
COMMREG  EQU   9                   COMM AREA ADDR REGISTER              17400020
BASEREG  EQU   11                  PROG CSECT BASE REGISTER             17700020
DATAREG  EQU   12                  SPECIAL REGISTER                     18000020
SAVEREG  EQU   13                  SAVE AREA PTR REGISTER               18300020
RETREG   EQU   14                  RETURN ADDR REGISTER                 18600020
RETCDREG EQU   15                  RETURN CODE REGISTER                 18900020
FOUNDAOP EQU   X'04'               OP FOR FOUND ACROSS LINES            19200020
NOTFOUNP EQU   X'08'               OP FOR TEXT NOT FOUND                19500020
IOERROP  EQU   X'0C'               OP FOR I/O ERROR                     19800020
FOUNDOP  EQU   X'00'               OP FOR TEXT FOUND IN ONE LINE        20100020
DATPTR   EQU   10                  PTR REG TO DATA                      20400020
ENDPTR   EQU   8                   REG PTR TO END OF DATA               20700020
NEXTRD   EQU   X'02'               CODE FOR READ NEXT                   21000020
EOPARM   EQU   X'80'               CODE FOR END OF PARM LIST            21300020
L0       EQU   0                   LENGTH                               21600020
L4       EQU   4                   LENGTH                               21900020
RET4     EQU   4                   RETURN CODE                          22200020
L3       EQU   3                   LENGTH                               22500020
L1       EQU   1                   LENGTH                               22800020
L8       EQU   8                   LENGTH                               23100020
L2       EQU   2                   LENGTH                               23400020
L12      EQU   12                  LENGTH                               23700020
SCNDOFF  EQU   264                 OFFSET FOR 2ND RCD MOVE WHEN FOUND   23900020
L255     EQU   255                 LENGTH                               24100020
RDCR     EQU   X'00'               UT CODE FOR READ CURRENT RCD         24300020
         EJECT                                                          24330020
*  ENTRY LINKAGE                                                        24360020
         IKJEBESV (14,12),,,COMMREG=NO                                  24390020
         LR    COMMREG,PARMREG0    POINTER TO COMMUNICATION AREA        24420020
         USING IKJEBECA,COMMREG    ADDRESSABILITY FOR COMMAREA DSECT    24450020
         EJECT                                                          24480020
*  INITIALIZE WORK AREAS                                                24510020
         SR    RETCDREG,RETCDREG   INIT RC TO ZERO                      24600020
         LM    WRA,WRE,L0(PARMREG1) TRANSFER                            24900020
         STM   WRA,WRE,DCBPTR      PARAMETERS                           25200020
         L     PARMREG1,LINRNPTR                                        25500020
         LM    WRA,WRB,L0(PARMREG1) INTO WORK                           25800020
         STM   WRA,WRB,FIRST       AREAS                                26100020
         LTR   WRA,WRA             TEST FIRST LINE NUMBER               26160020
         BNM   SRCH                IF NOT -1 (*) CONTINUE               26220020
         LTR   WRB,WRB             TEST COUNT                           26280020
         BZ    NOTFOUN             IF ZERO, CONSIDER TEXT NOT FOUND     26340020
SRCH     L     WRB,BUFPTR          POINT TO RECORD                      26400020
         BAL   RETREG,POINDATA     LINK TO GET POINTER TO DATA          26700020
*                                  PORTION AND END OF DATA PORTION      27000020
         EJECT                                                          27100020
*  PTR TO DATA IS IN DATPTR, PTR TO END OF DATA IN ENDPTR               27300020
         ST    DATPTR,LINEAD       SAVE DATA PTR                        27600020
         AH    DATPTR,TXTOFF       INCREMENT INIT DATA PTR BY OFFSET    27900020
         BCTR  DATPTR,PARMREG0     SUBT ONE FOR INIT                    28500020
         ST    ENDPTR,EOFIRSDT     SAVE END OF FIRST DATA PORTION PTR   28800020
         L     WRB,BUFPTR          PTR TO RECORD IN BUFFER              29100020
         LH    WRA,L4(WRB)         LENGTH OF RCD                        29400020
         LA    WRA,L3(WRA)         INCREMENT FOR KEY LENGTH             29700020
         LR    PARMREG1,WRB        SAVE PTR TO BUFFER                   30000020
         LA    WRB,CATEMPBF        PTR TO TEMP BUFFER                   30300020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   30600020
SRCHLOOP LA    DATPTR,L1(DATPTR)   INCREMENT PTR                        30900020
         LH    WRA,TXTLNTH         LENGTH OF TEXT                       31200020
         AR    WRA,DATPTR          ADD TO OFFSET                        31500020
         CR    WRA,ENDPTR          WOULD COMPARE BE GT END OF DATA      31800020
         BH    NOTFND              IF SO, BRANCH                        32100020
         L     WRB,TXTPTR          PTR TO TEXT                          32400020
         LH    WRA,TXTLNTH         LENGTH OF COMPARE                    32700020
         BCTR  WRA,PARMREG0        DECREMENT FOR EX                     33000020
         EX    WRA,COMPARE         COMPARE                              33300020
         BE    FOUND               IF FOUND, BRANCH                     33600020
         B     SRCHLOOP            LOOP TO CONTINUE SEARCH              33900020
NOTFND   CLI   CADSCODE,CATEXT     IS DS TEXT TYPE                      34200020
         BE    TEXTYPE             IF SO, BRANCH                        34500020
         XC    TXTOFF,TXTOFF       ZERO OFFSET                          34550020
         SPACE                                                          34800020
*  CHECK FOR MORE LINES TO SCAN                                         35100020
         L     WRA,FIRST           LINE NUM FOR FIRST LINE              35400020
         LTR   WRA,WRA             TEST                                 35700020
         BM    ASTER               IF NEGATIVE, * COUNT FORM WAS USED   36000020
         L     WRA,BUFPTR          PTR TO BUFFER                        36300020
         CLC   L0(L4,WRA),LAST     COMPARE CURRENT TO LAST KEY          36600020
         BNL   NOTFOUN             IF DONE, BRANCH                      36900020
         EJECT                                                          37000020
         SPACE                                                          37200020
*  READ NEXT RECORD                                                     37500020
RNR      LA    WRA,BEUTABA         ADDR OF PARM LIST                    37800020
         L     WRB,DCBPTR          PTR TO CURRENT DCB                   38100020
         L     WRC,BUFPTR          PTR TO INPUT BUFFER                  38400020
         ST    WRB,BEUTABA         STORE INTO PARM LIST                 38700020
         ST    WRC,BEUTABB         ST IN UT PARMS PTR TO KEY            39300020
         MVI   BEUTABA,NEXTRD      UT CODE FOR READ NEXT RCD            39600020
         ST    WRC,BEUTABC         PTR TO INPUT BUFFER IN UT PARMLIST   39900020
         OI    BEUTABC,EOPARM      CODE FOR END OF PARM LIST            40200020
         IKJEBESH   (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),        X40500020
               MF=(E,SHAREA)                                            40800020
         LTR   RETCDREG,RETCDREG   TEST RETURN CODE                     41100020
         BZ    ATNCK               IF ZERO, BRANCH                      41400020
         LA    WRA,RET4            CODE FOR END OF DATA                 41700020
         CR    WRA,RETCDREG        COMPARE                              42000020
         BE    NOTFOUN             IF EOD, BRANCH TO NOT FOUND RTN      42300020
         B     IOERR               ELSE, I/O ERROR OCCURRED             42600020
ATNCK    TM    CAATTN,CAATTNIS     WAS ATTN ISSUED                      42900020
         BNZ   SETATNFL            IF SO, BRANCH                        43200020
         L     WRB,BUFPTR          PTR TO RCD IN BUFFER                 43500020
         LH    WRA,L4(WRB)         LENGTH OF RCD                        43800020
         LA    WRA,L3(WRA)          ADD 3 FOR LENGTH OF KEY-1           44100020
         LA    WRB,CATEMPBF          ADDR OF BUFFER                     44400020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   44700020
         B     SRCH                GO TO SEARCH                         45000020
         EJECT                                                          45100020
*  STRING WAS FOUND IN ONE LINE                                         45200020
FOUND    SR    RETCDREG,RETCDREG   ZERO RC                              45300020
         LR    RETCDREG,DATPTR     ADDR OF STRING IN LINE               45600020
         S     RETCDREG,LINEAD     GET OFFSET                           45900020
         LA    RETCDREG,L1(RETCDREG)                                    46200020
         ST    RETCDREG,LINEAD     STORE                                46500020
         MVI   LINEAD,FOUNDOP      CODE FOR RCD FOUND                   46800020
         L     RETCDREG,LINEAD     LOAD CODE AND OFFSET INTO REG        47100020
         B     OUT                 AND EXIT                             47400020
         SPACE                                                          47500020
*  STRING WAS NOT FOUND AND RANGE OF LINES IS EXHAUSTED                 47600020
NOTFOUN  SR    RETCDREG,RETCDREG   ZERO RC                              47700020
         ST    RETCDREG,LINEAD     ZERO WORD                            48000020
         OI    LINEAD,NOTFOUNP     CODE FOR NOT FOUND                   48300020
         L     RETCDREG,LINEAD     LOAD RETURN CODE REG                 48600020
         B     OUT                 AND EXIT                             48900020
         EJECT                                                          49000020
*  EXIT LINKAGE                                                         49100020
OUT      EQU   *                   PROGRAM EXIT                         49200020
         L     PARMREG1,BUFPTR     PTR TO RCD IN BUFFER                 49500020
         LH    WRA,L4(PARMREG1)    LENGTH OF RCD                        49800020
         LA    WRA,L3(WRA)         INCREMENT BY LENGTH OF KEY           50100020
         LA    WRB,CATEMPBF+L12    PTR TO VERIFY BUFFER                 50400020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   50700020
         L     WRA,LAST            FOR * COUNT FORM OF CHANGE           51000020
         L     WRB,LINRNPTR        RETURN RESIDUAL COUNT LEFT           51300020
         ST    WRA,L4(WRB)          IN ORIGINAL COUNT WORD              51600020
         IKJEBERT   (14,12),,RC=(15)                                    51900020
    EJECT                                                               52000020
*  SEARCH ACROSS LINES FOR TEXT DATASETS ONLY                           52100020
TEXTYPE  EQU   *                                                        52200020
         LA    WRA,BEUTABA         ADDR OF PARM LIST                    52500020
         L     WRB,DCBPTR          PTR TO DCB                           52800020
         ST    WRB,BEUTABA         STORE IN PARM LIST                   53100020
         L     WRB,BUFPTR          PTR TO KEY OF LAST RCD               53150020
         ST    WRB,BEUTABB         STORE IN PARM LIST                   53200020
         MVI   BEUTABA,NEXTRD                                           53400020
         OI    BEUTABB,EOPARM                                           53700020
         IKJEBESH   (COMMREG),IKJEBEUT,PARAM=((COMMREG),(WRA)),        X54000020
               MF=(E,SHAREA)                                            54300020
         LTR   RETCDREG,RETCDREG   TEST RC                              54600020
         BZ    SETUPLN             IF SUCCESSFUL BRANCH                 54900020
         LA    WRA,RET4            CODE FOR END OF DATA                 55200020
         CR    RETCDREG,WRA        COMPARE                              55500020
         BE    NOTFOUN             IF EOD, BRANCH TO NOT FOUND RTN      55800020
         B     IOERR               ELSE, I/O ERROR                      56100020
IOERR    EQU   *                                                        56400020
         SR    RETCDREG,RETCDREG   ZERO RC                              56700020
         ST    RETCDREG,LINEAD     STORE                                57000020
         OI    LINEAD,IOERROP      CODE FOR I/O ERROR                   57300020
         L     RETCDREG,LINEAD     LOAD RC REG                          57600020
         B     OUT                 AND EXIT                             57900020
         EJECT                                                          58000020
*  PTR TO NEW RCD IS IN PARMREG1                                        58200020
SETUPLN  EQU   *                                                        58500020
         LR    WRB,PARMREG1        ADDR OF RCD                          58800020
         BAL   RETREG,POINDATA     LINK TO POINT AT BEG & END OF DATA   59100020
*  DATPTR NOW POINTS AT DATA PORTION OF RCD, ENPTR TO EOD               59400020
         L     WRA,EOFIRSDT        ADDR OF END OF DATA OF FIRST RCD     59700020
         LR    WRB,ENDPTR          GET LENGTH OF                        60000020
         BCTR  ENDPTR,PARMREG0     DEC.SECOND REC.LEN FOR MVC   SA67642 60100021
         SR    WRB,DATPTR          DATA IN 2ND RCD                      60300020
*                                  FIRST                        SA67642 60600021
         LA    ENDPTR,L1(,ENDPTR)  INCR. BY 1 FOR TRUE LENGTH   SA67642 60700021
         EX    WRB,MOVESEC         EXECUTE MOVE TO CONCATENATE DATA     60900020
         AR    WRA,WRB             GET NEW ENDPTR                       61200020
         LA    ENDPTR,L1(WRA)       INCREMENT TO CANCEL DECREMENT       61500020
         L     DATPTR,LINEAD       BEGINNING OF FIRST RCD DATA          61800020
         AH    DATPTR,TXTOFF       RESET POINTER BY OFFSET              61850020
         XC    TXTOFF,TXTOFF       ZERO OFFSET                          61900020
         BCTR  DATPTR,PARMREG0     DECREMENT FOR INIT                   62100020
CROSRCH  LA    DATPTR,L1(DATPTR)   INCREMENT PTR                        62400020
         C     DATPTR,EOFIRSDT     IS PTR BEYOND FIRST RCD              62700020
         BNL   NOTAC               IF SO, TEXT NOT ACROSS LINES         63000020
         LH    WRA,TXTLNTH         LENGTH OF SEARCH TEXT                63300020
         AR    WRA,DATPTR          ADD TO OFFSET                        63600020
         CR    WRA,ENDPTR          WOULD COMPARE OVERFLOW DATA          63900020
         BH    NOTAC               IF SO, BRANCH                        64200020
         L     WRB,TXTPTR          PTR TO TEXT                          64500020
         LH    WRA,TXTLNTH         LENGTH OF COMPARE                    64800020
         BCTR  WRA,PARMREG0        DECREMENT FOR EX                     65100020
         EX    WRA,COMPARE         EXECUTE COMPARE                      65400020
         BE    FOUNDAC             IF FOUND, BRANCH                     65700020
         B     CROSRCH             LOOP TO CONTINUE SEARCH              66000020
         EJECT                                                          66100020
*  STRING WAS FOUND ACROSS LINES                                        66200020
FOUNDAC  EQU   *                                                        66300020
ACROSS   LR    WRE,DATPTR          SAVE PTR TO STRING                   66600020
         L     WRB,BUFPTR          ADDR OF RCD                          66900020
         LH    WRF,LHALF           GET LENGTH OF RCD                    67200020
         BAL   RETREG,POINDATA     LINK TO GET DATA PTRS                67500020
         LR    WRC,PARMREG1        PTR TO RECORD                        67700020
         L     WRB,BUFPTR          PTR TO BUFFER                        67900020
         LH    WRA,CATEMPBF+L4     LL00 OF RECORD                       68100020
         LA    WRA,L3(WRA)         INCREMENT FOR LL00 LENGTH            68300020
         LA    PARMREG1,CATEMPBF   POINT TO BFR INTO WHICH RCD GOES     68500020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   69300020
         LR    PARMREG1,WRC        POINTER TO RECORD                    69600020
         LR    WRA,WRF             LENGTH OF RECORD                     69900020
         LA    WRA,L3(WRA)         INCREMENT FOR LL00 LENGTH            70200020
         LA    WRB,SCNDOFF(WRB)    OFFSET FOR 2ND RCD PLACEMENT         70500020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   70800020
         SR    WRE,DATPTR          GET OFFSET                           71100020
         LA    WRE,L1(WRE)         INCREMENT FOR ORIGIN ONE             71400020
         ST    WRE,LINEAD          STORE                                71700020
         OI    LINEAD,FOUNDAOP     CODE FOR FOUND ACROSS LINES          72000020
         L     RETCDREG,LINEAD     LOAD RET CODE REG                    72300020
         B     OUT                 AND EXIT                             72600020
         EJECT                                                          72700020
*  STRING NOT FOUND, CHECK FOR END OF SEARCH RANGE AND ATTN             72800020
NOTAC    EQU   *                   CHECK FOR FINISHED WITH SEARCH       72900020
         L     WRA,FIRST           FIRST LINE NUM                       73200020
         LTR   WRA,WRA             TEST                                 73500020
         BM    ASTERAC             IF NEGATIVE, * COUNT WAS USED        73800020
         CLC   L0(L4,PARMREG1),LAST  COMPARE RCD 2 KEY TO LAST          74100020
         BH    NOTFOUN             IF OVER RANGE, GO TO SET RC=8        74400020
RESETATN EQU   *                   CHECK FOR ATTN                       74700020
         TM    CAATTN,CAATTNIS     WAS ATTN ISSUED                      75000020
         BNZ   SETATNFL            IF SO, BRANCH                        75300020
RESET    EQU   *                   RESET OFFSET AND MOVE RCD            75600020
         LH    WRA,LHALF                                                75900020
         LA    WRA,L3(WRA)         INCREMENT FOR KEY-1                  76200020
         L     WRB,BUFPTR          ADDR OF BUFFER                       76500020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   76800020
         LA    WRB,CATEMPBF        POINT TO BUFFER                      77100020
         BAL   RETREG,MOVBUF       BRANCH TO MOVE RCD                   77400020
         B     SRCH                GO TO SEARCH LOOP                    77700020
         EJECT                                                          77750020
*  ROUTINE TO FIND BEG AND END OF DATA PORTION OF RCD                   77800020
POINDATA EQU   *                   RTN TO FIND BEG & END OF DATA        78000020
         MVC   LHALF(L2),L4(WRB)   ALIGN LENGTH                         78300020
         LH    WRC,LHALF           LENGTH                               78600020
         LA    WRB,L4(WRB)         INC BY LEN OF KEY TO POINT AT LL00   78900020
         AR    WRC,WRB             ADD TO POINT NEAR END                79200020
         TM    CACFLAG1,CANONUM    IS NONUM SPECIFIED                   79500020
         BZ    NUMBRD              IF NUMBERED, PROCESS AS SUCH         79800020
         LA    WRB,L4(WRB)         POINT TO BEG OF DATA PORTION         80100020
         B     OUTPT               GO TO RTN EXIT                       80400020
NUMBRD   EQU   *                                                        80700020
         SR    WRA,WRA             ZERO REGISTER                        81000020
         IC    WRA,CALINE          GET OFFSET OF LINE NUMBER            81300020
         LA    WRD,L1              IF LINE NUMBER IS AT END             81600020
         CR    WRA,WRD             THEN BRANCH                          81900020
         BNE   LCALDCD             TO ALT METHOD OF LINENUM COUNT       82200020
         IC    WRA,CALENGTH        GET LENGTH OF NUMBER                 82500020
         AR    WRB,WRA             INCREMENT BEG PTR BY LINE LENGTH     82800020
         LA    WRB,L4(WRB)         INCREMENT TO POINT PAST LL00         83100020
         B     OUTPT               GO TO RTN EXIT                       83400020
LCALDCD  EQU   *                   LINE NUM AT END                      83700020
         LR    WRC,WRB             PTR TO LL00 PART OF RCD              83900020
         AR    WRC,WRA             ADD OFFSET OF LINE NUMBER            84100020
         LA    WRC,L3(WRC)         ADD LL00 LEN - 1 SINCE CALINE        84300020
*                                  IS ORIGIN ONE, TO POINT AT EOD+1     84500020
         LA    WRB,L4(WRB)         INC BY LL00 LEN TO POINT AT DATA     84700020
OUTPT    LR    DATPTR,WRB          PTR TO BEG OF DATA PORTION           84900020
         LR    ENDPTR,WRC          PTR ONE BYTE PAST EOD OF RCD         85100020
         BR    RETREG              RETURN TO CALLER                     85800020
         EJECT                                                          85900020
*  FOR * COUNT RANGE, CHECK FOR END OF RANGE                            86000020
ASTER    EQU   *                   CHECK FOR LINES TO SCAN, * CT FRM    86100020
         L     WRA,LAST            COUNT                                86400020
         BCT   WRA,DEC             DECREMENT AND TEST                   86700020
         B     NOTFOUN             IF NO MORE RCDS IN RANGE, BRANCH     87000020
DEC      ST    WRA,LAST            STORE   DECREMENTED COUNT            87300020
         B     RNR                 GO TO READ NEXT RCD                  87600020
ASTERAC  EQU   *                   * COUNT CHECK FOR TEXT DS            87900020
         L     WRA,LAST            COUNT                                88200020
         BCT   WRA,DECA            DECREMENT AND TEST                   88500020
         B     NOTFOUN             IF NO MORE RCDS, BRANCH              88800020
DECA     ST    WRA,LAST            STORE DECREMENTED COUNT              89100020
         B     RESETATN            GO TO CONTINUE PROCESSING            89400020
SETATNFL EQU   *                                                        89700020
         SR    RETCDREG,RETCDREG   ZERO RC                              90000020
         B     OUT                 AND EXIT                             90300020
         EJECT                                                          90900020
*  MOVE ROUTINE AND MVCS AND CLCS FOR EXS                               91200020
MOVBUF   EQU   *                   RTN TO MOVE RCD                      91600020
         MVC   L0(L8,WRB),L0(PARMREG1)  MOVE RECORD                     91700020
         MVC   L8(L255,WRB),L8(PARMREG1)  INTO BUFFER                   91800020
         BR    RETREG              RETURN TO CALLER                     91900020
COMPARE  CLC   L0(L0,WRB),L0(DATPTR)  COMPARE FOR EX FOR STRING         92100020
MOVESEC  MVC   L0(WRB,WRA),L0(DATPTR)  MOVE FOR CONCAT DATA             92200020
         EJECT                                                          92300020
         IKJEBECA                                                       92400020
         EJECT                                                          92500020
*  WORK AREAS                                                           92600020
         ORG   CASRWKA             SERVICE ROUTINE WORKAREA             92700020
EOFIRSDT DS    1F                  ADDR OF END OF FIRST RCD DATA        93000020
RCDAD    DS    1F                  ADDR OF CURRENT RCD                  93300020
KEYLLZZ  DS    2D                  KEY AND LL00 OF 2ND RCD              93600020
LINEAD   DS    1F                  ADDR OF DATA PORTION OF RCD          93900020
SHAREA   DS    10F                 WORK AREA                            94200020
DCBPTR   DS    1F                  PARM                                 94500020
TXTOFF   DS    1H                  INIT OFFSET TO BEGIN SEARCH          94800020
TXTLNTH  DS    1H                  LIST                                 95100020
TXTPTR   DS    1F                  FROM                                 95400020
BUFPTR   DS    1F                  CALLER                               95700020
LINRNPTR DS    1F                  PTR TO LINE RANGE                    96000020
FIRST    DS    1F                  FIRST LINE NUMBER IN RANGE           96300020
LAST     DS    1F                  LAST LINE NUMBER IN RANGE            96600020
BEUTABA  DS    1F                  IKJEBEUT PARM                        96900020
BEUTABB  DS    1F                  LIST                                 97200020
BEUTABC  DS    1F                  IKJEBEUT PARM PTR TO STGE FOR RCD    97500020
LHALF    DS    H                   HALFWORD FOR LENGTH ALIGNMENT        97800020
RDNM     DS    1F                  STGE FOR INITIAL READ LINE NUM       98100020
         ORG   ,                   RESTORE COUNTER                      98400020
         END                                                            98700020
