BEUI TITLE 'EDIT COMMAND ACCESS METHOD-UTILITY INITIALIZATION-IKJEBEUI' 00200020
IKJEBEUI CSECT                                                          00400020
* A 290300-294600,631830-631950                                 A59609  00450021
* C 630700                                                      A59609  00500021
* D 390600-294200                                               A59609  00550021
*********************************************************************** 00600020
*                                                                     * 01000020
*STATUS -- VERSION NO. 01, OS/360 RELEASE NO 20                       * 01200020
*                                                                     * 01400020
*FUNCTION -- THIS ROUTINE PREPARES THE EDIT UTILITY DATA SET FOR      * 01600020
*   PROCESSING BY PERFORMING THE FOLLOWING-                           * 01800020
*      -OBTAINS CORE STORAGE FOR A WORKAREA, CALLED UTILWORK. THIS    * 02000020
*       AREA IS CLEARED TO ZERO.                                      * 02200020
*      -THAT PORTION OF THE WORKAREA RESERVED FOR SAVEAREAS IS        * 02400020
*       INITIALIZED BY PRE-CHAINING EACH OF THE APEAS.                * 02600020
*      -THE DCB FOR THE UTILITY DATA SET IS PLACED IN THE WORKAREA.   * 02800020
*      -A UTILITY DATA SET IS ALLOCATED BY USING THE IKJDAIR ROUTINE  * 03000020
*      -THE UTILITY DATA SET IS OPENED.                               * 03200020
*      -OBTAINS CORE STORAGE FOR BUFFERS WHEN ACCESSING THE UTILITY   * 03400020
*       DATA SET.                                                     * 03600020
*      -INITIALIZES ADDITIONAL FIELDS IN THE WORKAREA, SUCH AS THE    * 03800020
*       LIST FORMS OF THE READ, WRITE, AND XDAP MACROS.               * 04000020
*      -LOADS IN THE ACCESSING LOAD MODULE (IKJEBEAA) AND SAVES       * 04200020
*       ITS ADDRESS IN THE UTILITY WORKAREA                           * 04400020
*                                                                     * 04600020
*ENTRY POINTS --                                                      * 04800020
*       IKJEBEUI             -VIA A LINK OR LOAD-CALL                 * 05000020
*                                                                     * 05200020
*INPUT --  REGISTER 1 CONTAINS THE ADDRESS OF THE EDIT COMMUNICATION  * 05400020
*   AREA, IKJEBECA                                                    * 05600020
*                                                                     * 05800020
*OUTPUT -- PERFORMS THE OPERATIONS DESCRIBED UNDER 'FUNCTION' ABOVE.  * 06000020
*   REGISTERS ARE AS DESCRIBED UNDER 'EXIT' BELOW.                    * 06200020
*                                                                     * 06250020
*EXTERNAL REFERENCES --                                               * 06300020
*       IKJDAIR              -ALLOCATES THE UTILITY DATA SET          * 06350020
*       MACROS USED                                                   * 06400020
*         GETMAIN            -CORE FOR WORKAREA AND BUFFERS           * 06600020
*         FREEMAIN           -RELEASE CORE ON ERROR CONDITIONS        * 06800020
*         OPEN               -OPENS UTILITY DATA SET                  * 07000020
*         CLOSE              -CLOSE DATA SET ON ERROR CONDITIONS      * 07200020
*         LOAD               -ACCESS LOAD MODULE, IKJEBEAA            * 07400020
*                                                                     * 07600020
*EXITS,NORMAL -- RETURNS ON REGISTER 14                               * 07800020
*   REGISTER 15 CONTAINS A RETURN CODE OF ZERO.                       * 08000020
*   REGISTER 0  CONTAIN S THE ADDRESS OF THE UTILITY WORKAREA/DCB.    * 08200020
*                                                                     * 08400020
*EXITS,ERROR--                                                        * 08600020
*   REGISTER 15 CONTAINS A RETURN CODE AS FOLLOWS-                    * 08800020
*     4- NOT ENOUGH CORE AVAILABLE                                    * 09000020
*     8- UTILITY DATA SET NOT AVAILABLE                               * 09200020
*    12 - UNABLE TO OPEN DATA SET                                     * 09400020
*                                                                     * 09600020
*TABLES/WORK AREAS --                                                 * 09800020
*       DEPENDENT ON THE EDIT COMMUNICATIONS AREA (IKJEBECA) FOR-     * 10000020
*         -INVOCATION OF IKJDAIR                                      * 10200020
*         -WRITING OUT MESSAGES                                       * 10400020
*       BUILDS AND INITIALIZES THE UTILITY WORKAREA (UTILWORK) AS     * 10600020
*       DESCRIBED ABOVE                                               * 10800020
*                                                                     * 11000020
*ATRRIBUTES -- REFRESHABLE,ENABLED,NON-PRIVILEGED                     * 11200020
*                                                                     * 11400020
*NOTES -- REGISTER DEFINITIONS AS DEFINED BELOW.                      * 11600020
*                                                                     * 11700020
*   THIS ROUTINE IS CHARACTER CODE INDEPENDENT                        * 11800020
*                                                                     * 12000020
*********************************************************************** 12200020
       EJECT                                                            12400020
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS                              12600020
PARMREG0 EQU   0                       PARM POINTER                     12800020
PARMREG1 EQU   1                       PARM POINTER                     13000020
WORK2    EQU   2                       WORK REGISTER                    13200020
LINK5    EQU   5                        LINK REGISTER FOR MESSAGES      13260020
WORK3    EQU   3                       WORK REGISTER                    13320020
WORK4    EQU   4                       WORK REGISTER                    13400020
WORK6    EQU   6                       WORK REGISTER                    13600020
WORK8    EQU   8                       TEMPORARY WORKAREA ADDRESSING    13800020
LINK9    EQU   10                      SUBROUTINE LINK REGISTER         14000020
COMMREG  EQU   9                       EDIT COMMUNICATIONS AREA         14200020
BASEREG  EQU   11                      BASE REGISTER                    14400020
DATAREG  EQU   12                      UTILITY WORK AREA ADDRESSING     14600020
SAVEREG  EQU   13                      SAVE AREA ADDRESSING             14800020
RETREG   EQU   14                      RETURN REGISTER                  15000020
RETCDREG EQU   15                      RETURN CODE                      15200020
ENTRY    EQU   15                      ENTRY POINT ADDRESS              15400020
         SPACE                                                          15600020
*   DEFINITIONS                                                         15800020
OPEN     EQU   X'10'                   OPEN TEST FLAG                   16000020
SAVENO   EQU   6                       NO. OF STACKED SAVE AREAS        16200020
SAVEL    EQU   72                      SAVE AREA LENGTH                 16400020
K255     EQU   255                     CONSTANT OF 255                  16600020
EIGHT    EQU   8                       CONSTANT OF EIGHT                16800020
FOUR     EQU   4                       CONSTANT OF FOUR                 17000020
X2       EQU   2                       OFFSET OF TWO                    17100020
X8       EQU   8                       OFFSET OF EIGHT                  17200020
X4       EQU   4                       OFFSET OF FOUR                   17240020
X12      EQU   12                      OFFSET OF TWELVE                 17280020
X48      EQU   48                      OFFSET OF FORTY-EIGHT            17320020
X66      EQU   66                      OFFSET OF SIXTY-SIX              17360020
SPONE    EQU   1                       SUBPOOL NUMBER                   17400020
OPENERR  EQU   12                      RETURN CODE //OPEN ERROR         17600020
SID      EQU   X'31'                   OPERATION CODE//SEARCH ID        17800020
TIC      EQU   8                       OFFSET TO TIC CCW                18000020
TICCODE  EQU   X'08'                   OPERATION CODE//TRANSFER         18200020
ONE      EQU   1                       CONSTANT OF ONE                  18400020
ZERO     EQU   0                       CONSTANT OF ZERO                 18600020
X20      EQU   20                      OFFSET OF TWENTY                 18800020
THREE    EQU   3                       CONSTANT OF 3                    18810020
FIVE     EQU   5                       CONSTANT OF 5                    18820020
SIX      EQU   6                       CONSTANT OF SIX                  18830020
LENGTH4  EQU   X'04'                   FOR LENGTH OF MESSAGE OPEN ERROR 18840020
X26      EQU   26                       USED TO CLEAR MESSAGE AREA      18850020
X240     EQU   240                      FOR START OF TRANSLATE TABLE    18860020
MGCOREB  EQU   40                      OFFSET TO MESSAGE BLOCK          18870020
MGCOREBO EQU   MGCOREB+6               OFFSET IN MESSAGE BLOCK          18880020
MGCOREBL EQU   MGCOREB+5               OFFSET TO LENGTH FIELD           18890020
MGCOREBM EQU   MGCOREB+8               OFFSET TO MESSAGE INSERTION      18900020
         EJECT                                                          18910020
*   ALLOCATION ERROR CODES                                              18920020
CTRC0028 EQU   X'0028'                 CATALOG I/O ERROR CODE           18930020
DARC0214 EQU   X'0214'                 DYNAMIC ALLOCATION ERROR CODE    18940020
DARC021C EQU   X'021C'                 DYNAMIC ALLOCATION ERROR CODE    18950020
DARC0220 EQU   X'0220'                 DYNAMIC ALLOCATION ERROR CODE    18960020
         SPACE 2                                                        19000020
*   MESSAGE REFERENCES                                                  19200020
         SPACE                                                          19400020
         SPACE                                                          19600020
         IKJEBEMI (301,304,305,309,312,313,318)                         19800020
         EJECT                                                          20000020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          20200020
         IKJEBESV  (14,12),T,*             SAVE THE REGISTERS           20400020
         USING IKJEBECA,COMMREG                                         20600020
         SPACE 2                                                        20800020
*   OBTAIN A WORKAREA FOR ALL UTILITY ROUTINES AND MACROS               21000020
*   AND CORE FOR THE ACCESS METHOD BUFFERS                              21100020
         MVC   GMLIST(GMEND-GM),GM     LIST FORM TO WORKAREA            21200020
         LA    PARMREG1,GMLIST         ADDRESS OF LIST FORM             21400020
         GETMAIN EC,A=GMADDR,MF=(E,(1)) GET A WORKAREA                  21600020
         LTR   RETCDREG,RETCDREG       WAS CORE AVAILABLE               21800020
         BNZ   UI3                     NO--GO GIVE A MESSAGE            22000020
         L     DATAREG,GMADDR          ADDRESS OF WORKAREA              22200020
         USING UTILWORK,DATAREG                                         22400020
         LA    WORK8,TEMPAREA          SERVICE ROUTINE WORKAREA         22600020
         USING UIWORK,WORK8                                             22800020
         SPACE 2                                                        23000020
*   CLEAR WORKAREA AND BUFFER CORE TO ZERO                              23200020
         LR    WORK2,DATAREG            STARTING ADDRESS                23400020
         L     PARMREG1,BUFLNG          BUFFER LENGTH                   23500020
         LA    PARMREG0,UTILSIZE-ONE(PARMREG1)  TOTAL LENGTH - ONE      23600020
UICLR1   LA    PARMREG1,K255           MAXIMUM AMOUNT PER PASS(256)     23640020
         CR    PARMREG0,PARMREG1       COMPARE ACTUAL TO MAXIMUM        23680020
         BNL   UICLR2                  BRANCH TO CLEAR 256 BYTES        23720020
         LR    PARMREG1,PARMREG0       USE ACTUAL, LESS THAN 256        23760020
UICLR2   EX    PARMREG1,UICLEAR        CLEAR SPECIFIED AMOUNT           23800020
         LA    PARMREG1,ONE(PARMREG1)  AMOUNT OF BYTES CLEARED          23840020
         AR    WORK2,PARMREG1          NEW STARTING ADDRESS             23880020
         SR    PARMREG0,PARMREG1       ANY MORE BYTES LEFT TO CLEAR     23920020
         BNM   UICLR1                  YES-MAKE ANOTHER PASS            23960020
         SPACE 2                                                        24000020
*   SET UP FIRST SAVE AREA AND CHAIN ALL SAVE AREAS.                  * 24200020
         LA    PARMREG1,SAVEAREA-SAVEL START OF SAVE AREA.              24400020
         LA    WORK2,SAVENO            NUMBER OF SAVE AREAS             24600020
         LR    WORK4,SAVEREG           CALLING PROGRAMS SAVE AREA       24800020
UICHAIN  LA    PARMREG1,SAVEL(PARMREG1)  NEXT SAVEAREA                  25000020
         ST    WORK4,FOUR(PARMREG1)     BACK CHAIN TO LAST              25200020
         ST    PARMREG1,EIGHT(WORK4)    FORWARD CHAIN LAST TO CURRENT   25400020
         LR    WORK4,PARMREG1          LAST IN CHAIN                    25600020
         BCT   WORK2,UICHAIN           REPEAT UNTIL ALL CHAINED         25800020
         SR    PARMREG1,PARMREG1       SET LAST FORWARD                 26000020
         ST    PARMREG1,EIGHT(WORK4)      CHAIN TO ZERO                 26200020
         SPACE 2                                                        26400020
*   MOVE DCB TO WORKAREA AND SET IT UP HERE                             26600020
         MVC   UTILDCB(DCBEND-BSAMDCB),BSAMDCB  DCB TO WORK AREA        26800020
         SPACE 2                                                        27000020
*   OBTAIN A UTILITY DATA SET AND PLACE DDNAME IN THE DCB               27200020
         MVC   UIDAIR(DAIRSIZE),DAIRCODE  PARM LIST FOR DAIR            27400020
         SPACE 2                                                        27410020
**********************************************************************  27420020
*   HERE WE FIGURE OUT HOW MUCH SPACE WILL BE NEEDED FOR THE UTILITY    27430020
*   DATA SET--- USE DEFAULTS IF NEW DATA SET                            27440020
         TM    CAEDFLAG,CAEDDISP       IS DATA SET OLD OR NEW           27450020
         BZ    UINEW                   NEW - USE DEFAULTS               27460020
         LH    WORK3,CALRECL           GET LRECL FOR DATA SET           27470020
         LA    WORK3,SIX(WORK3)        ACCOUNT FOR LOCATORS AND KEY     27480020
         M     WORK2,CAUTILNO          GET US TOTAL BYTES IN DATA SET   27490020
         D     WORK2,UTILDIV           GETS US NUMBER OF DB'S NEEDED    27500020
         A     WORK3,PRIMARY           ADD SPACE ENOUGH FOR NEW RECORDS 27510020
         ST    WORK3,UIDAIR+DA08PQTY-DAPB08   STORE PRIMARY SPACE FOR   27520020
*                                       DAIR SERVICE ROUTINE            27530020
UINEW    EQU   *                                                        27540020
         LA    PARMREG1,UIDAIR         ADDRESS OF LIST                  27600020
         ST    PARMREG1,CATMPLST+DAPLDAPB-DAPL BLOCK ADDRESS TO LIST    27800020
         L     PARMREG1,CAPTTMP        TMP TO CP ADDRESS LIST           28000020
         USING CPPL,PARMREG1                                            28200020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'CPPLPSCB),CPPLPSCB PSCB ADDRESS 28400020
         DROP  PARMREG1                                                 28600020
         LA    PARMREG1,CATMPLST       TOTAL PARM LIST                  28800020
         LINK  EP=IKJDAIR              OBTAIN A UTILITY DATA SET        29000020
         LTR   RETCDREG,RETCDREG       CHECK NORMAL COMPLETION  A59609  29030021
         BZ    UIALOCOK                RC=X'00', CONTINUE       A59609  29060021
         CH    RETCDREG,UIDAIR30       CHECK DAIR STAE ENTERED  A59609  29120021
         BE    UIFREE                  RC=X'30', TERMINATE      A59609  29180021
         CH    RETCDREG,UIDAIR08       CHECK FOR RC=X'08',X'04' A59609  29240021
         BL    UISYSER                 RC=X'04', INVALID PARM   A59609  29300021
         BE    UICTLGER                RC=X'08', CATLG ERROR    A59609  29330021
         CH    RETCDREG,UIDAIR10       CHECK FOR RC=X'0C',X'10' A59609  29360021
         BL    UIALOCER                RC=X'0C', DYN ALLOC ERR  A59609  29420021
         BE    UINOTIOT                RC=X'10', NO TIOT ENTRY  A59609  29430021
*                                      AVAILABLE                A59609  29440021
         B     UISYSER                 OTHER RETURN CODES, SEND A59609  29450021
*                                      SYSTEM ERROR MESSAGE     A59609  29460021
UIALOCOK EQU   *                                                        29480020
         MVC   DCBDDNAM(EIGHT),UIDAIR+DA08DDN-DAPB08 DDNAME TO DCB      29600020
         SPACE 2                                                        29800020
*   OPEN THE DCB HERE.                                                  30000020
         MVC   UIOPEN(OPENLEND-OPENL),OPENL  LIST FORM TO WORKAREA      30200020
         LA    PARMREG1,UIOPEN               ADDRESS OF LIST FORM       30400020
         LA    WORK2,UTILDCB           DCB ADDRESS                      30600020
         OPEN  ((WORK2)),MF=(E,(1))    OPEN THE UTILITY DCB             30800020
         TM    DCBOFLGS,OPEN           WAS OPEN SUCCESSFUL              31000020
         BZ    UI12                    NO--                             31200020
         SPACE 2                                                        34600020
*   CHAIN THE BUFFERS                                                   34800020
         LA    WORK6,UTILSIZE(DATAREG) ADDRESS ACCESS METHOD BUFFERS    34860020
         USING BUFFER,WORK6                                             34920020
         LA    WORK4,DABUFNO           NUMBER OF DATA BUFFERS           35000020
         ST    WORK6,DCBBUFAD          FIRST BUFFER IN CHAIN            35200020
CHAIN    LA    WORK2,BUFSIZE(WORK6)    ADDRESS OF NEXT BUFFER, IF ANY   35400020
         ST    WORK2,BUFCHAIN          NEXT BUFFER ADDRESS TO PREVIOUS  35600020
         ST    WORK6,BBKCHAIN-BUFFER(WORK2) PREVIOUS BUFFER TO NEXT     35800020
         LR    WORK6,WORK2             NEXT BUFFER ADDRESS              36000020
         BCT   WORK4,CHAIN             REPEAT UNTIL ALL CHAINED         36200020
         LA    WORK6,BUFSIZE(WORK6)    STEP TO NEXT BUFFER              36400020
         ST    WORK6,DCBWRKAD          ADDRESS OF WORK BUFFER           36600020
         SPACE 2                                                        36800020
*   LOAD IN THE ACCESSING ROUTINES HERE                                 37000020
         LOAD   EP=IKJEBEAA            BRING IN EDIT ACCESS METHOD      37200020
         SPACE 2                                                        37400020
*   SAVE ADDRESS OF ACCESS METHOD HERE                                  37600020
         LR    PARMREG1,PARMREG0       ADDRESS OF LOADED ROUTINE        37800020
         USING VECTABLE,PARMREG1                                        38000020
         ST    PARMREG1,VTABLE         SAVE IN WORKAREA                 38200020
         MVC   DCBSYNAD(FOUR),SY       SYNAD ADDRESS TO DCB             38400020
         DROP  PARMREG1                                                 38600020
         SPACE 2                                                        38800020
*   SET UP THE LIST FORMS OF THE XDAP, READ, AND WRITE MACROS           39000020
         MVC   XDAPWLST(READEND-XDAP),XDAP LIST FORMS TO WORKAREA       39200020
         LA    WORK4,XWECB             ECB ADDRESS                      39400020
         ST    WORK4,XWIOB+FOUR        STORE IN IOB                     39600020
         LA    WORK4,XWCCWS            ADDRESS OF CCWS                  39800020
         ST    WORK4,XWCCWAD           STORE IN IOB                     40000020
         ST    WORK4,XWCCWS+TIC        STORE IN TIC CCW                 40200020
         MVI   XWCCWS+TIC,TICCODE      RESTORE OPERATION CODE           40400020
         LA    WORK4,WCCHHR            SEARCH ADDRESS                   40600020
         ST    WORK4,XWCCWS            STORE IN SEARCH CCW              40800020
         MVI   XWCCWS,SID              RESTORE OPERATION CODE           41000020
         SPACE 2                                                        41200020
*   SET UP XDAP READ FORM CCWS                                          41400020
         LA    WORK4,XRECB             ECB ADDRESS                      41600020
         ST    WORK4,XRIOB+FOUR        STORE IN IOB                     41800020
         LA    WORK4,XRCCWS            ADDRESS OF CCWS                  42000020
         ST    WORK4,XRCCWAD           STORE IN IOB                     42200020
         ST    WORK4,XRCCWS+TIC        STORE IN TIC CCW                 42400020
         MVI   XRCCWS+TIC,TICCODE      RESTORE OPERATION CODE           42600020
         LA    WORK4,RCCHHR            SEARCH ADDRESS                   42800020
         ST    WORK4,XRCCWS            STORE IN SEARCH CCW              43000020
         MVI   XRCCWS,SID              RESTORE OPERATION CODE           43200020
         SPACE 2                                                        43400020
*   EXIT HERE IF EVERYTHING IS OKAY.                                    43600020
UI0      SR    RETCDREG,RETCDREG       SET RETURN CODE  = 0             43800020
         L     WORK4,FOUR(SAVEREG)     PREVIOUS SAVE AREA               44000020
         ST    DATAREG,X20(WORK4)      SET UP RETURN REGISTER 0         44200020
UI00     EQU   *                       ALL RETURNS THRU HERE            44400020
         IKJEBERT (14,12),T,RC=(15)    RESTORE THE REGISTERS            44600020
         SPACE 2                                                        44800020
*********************************************************************** 44808020
*   CATALOG ERROR IN ALLOCATION                                         44816020
UICTLGER EQU   *                                                        44824020
         LH    WORK2,UIDAIR+DA08CTRC-DAPB08  CATALOG ERROR CODE         44832020
         XC    MSGAREA(X48),MSGAREA    CLEAR MESSAGE AREA               44840020
         LA    PARMREG1,CTRC0028       WAS CATALOG ERROR                44848020
         CR    PARMREG1,WORK2            CODE X'0028'                   44856020
         BE    UICTIOER                YES,GO SET UP I/O ERROR MSG      44864020
*                                      NO,ISSUE MSG WITH ERROR CODE     44872020
         LA    PARMREG1,M3042IN1       INITIALIZE OFFSET IN LEVEL       44880020
         STH   PARMREG1,MGBUILDO         2 INSERTION BLOCK              44888020
         L     PARMREG1,CTLGERPB       RELATIVE MESSAGE NUMBERS         44896020
         BAL   LINK5,UIDAIRCD          GO ISSUE MSG WITH ERROR CODE     44904020
         B     UIFREE                  GO CLEAN UP                      44912020
         SPACE 2                                                        44920020
*   CATALOG I/O ERROR MESSAGE                                           44928020
UICTIOER EQU   *                                                        44936020
         L     PARMREG1,CTIOERPB       RELATIVE MESSAGE NUMBERS         44944020
UIALOCMG EQU   *                                                        44952020
         ST    PARMREG1,MSGAREA        MSG PARM LIST, NO INSERTIONS     44960020
         BAL   LINK5,MSG               GO ISSUE MESSAGE                 44968020
         B     UIFREE                  GO CLEAN UP                      44976020
         SPACE 2                                                        44984020
*********************************************************************** 45000020
*   UNABLE TO ALLOCATE UTILITY DATA SET                                 45200020
UIALOCER EQU   *                                                        45220020
         LH    WORK2,UIDAIR+DA08DARC-DAPB08 DYNAMIC ALLOC ERROR CODE    45227020
         XC    MSGAREA(X48),MSGAREA    CLEAR MESSAGE AREA               45234020
         LA    PARMREG1,DARC0220       WAS DYNAMIC ALLOCATION           45241020
         CR    PARMREG1,WORK2            ERROR CODE X'0220'             45248020
         BE    UIDC0220                YES,ISSUE MSG                    45255020
         LA    PARMREG1,DARC0214       WAS DYNAMIC ALLOCATION           45262020
         CR    PARMREG1,WORK2            ERROR CODE X'0214'             45269020
         BE    UIDC0214                YES,ISSUE MSG                    45276020
         LA    PARMREG1,DARC021C       WAS DYNAMIC ALLOCATION           45283020
         CR    PARMREG1,WORK2            ERROR CODE X'021C'             45290020
         BE    UIDC021C                YES,ISSUE MSG                    45297020
*                                      NO,ISSUE MESSAGE WITH ERROR CODE 45304020
         LA    PARMREG1,M3041IN1       INITIALIZE OFFSET IN LEVEL       45311020
         STH   PARMREG1,MGBUILDO         2 INSERTION BLOCK              45318020
         L     PARMREG1,ALOCERPB       RELATIVE MESSAGE NUMBERS         45325020
         BAL   LINK5,UIDAIRCD          GO ISSUE MESSAGE WITH ERROR CODE 45332020
         B     UIFREE                  GO CLEAN UP                      45339020
         SPACE 2                                                        45346020
*   INSUFFICIENT SPACE ON VOLUMES MESSAGE                               45353020
UIDC0220 EQU   *                                                        45360020
         L     PARMREG1,DC0220PB       RELATIVE MESSAGE NUMBERS         45367020
         B     UIALOCMG                GO ISSUE MESSAGE                 45374020
         SPACE 2                                                        45381020
*   INVALID UNIT IN USER ATTRIBUTE DATA SET MESSAGE                     45388020
UIDC0214 EQU   *                                                        45395020
         L     PARMREG1,DC0214PB       RELATIVE MESSAGE NUMBERS         45402020
         B     UIALOCMG                GO ISSUE MESSAGE                 45409020
         SPACE 2                                                        45416020
*   NO UNIT AVAILABLE MESSAGE                                           45423020
UIDC021C EQU   *                                                        45430020
         L     PARMREG1,DC021CPB       RELATIVE MESSAGE NUMBERS         45437020
         B     UIALOCMG                GO ISSUE MESSAGE                 45444020
         SPACE 3                                                        45460020
UINOTIOT EQU   *                                                        45480020
         XC    MSGAREA(X12),MSGAREA    CLEAR MSG AREA                   45490020
         L     PARMREG1,NOTIOTPB       RELATIVE MESSAGE NUMBERS         45500020
         B     UIALOCMG                GO ISSUE MESSAGE                 45510020
         SPACE 3                                                        45540020
UIFREE   BAL   LINK9,UI40               GO PERFORM CLEAN UP             45560020
         LA    RETCDREG,EIGHT          SET RETURN CODE                  46000020
         B     UI00                    RETURN TO CALLER                 46200020
         SPACE 3                                                        46207020
*********************************************************************** 46214020
*   SYSTEM ERROR, ISSUE MSG WITH RETURN CODE FROM DAIR                  46222020
UISYSER  EQU   *                                                        46230020
         XC    MSGAREA(X66),MSGAREA    CLEAR MESSAGE AREA               46238020
         MVC   MSGAREA(X4),SYSERRPB    RELATIVE MSG NUMBERS             46246020
         LA    WORK2,MGBUILD            GET ADDRESS OF 2ND LEVEL        46256020
         ST    WORK2,MSGAREA+EIGHT      INITIALIZE AREA                 46263020
         LA    WORK2,MGBUILD2           SET UP 2ND 2ND LEVEL            46270020
         ST    WORK2,MGBUILD            POINT TO NEXT INSERTION         46277020
         MVI   MGBUILDL,L'IKJDAIR+FOUR  SET LENGTH FIELD                46284020
         LA    WORK2,M3131IN1           GET RELATIVE OFFSET             46291020
         STH   WORK2,MGBUILDO           STORE IN MESSAGE BLOCK          46298020
         MVC   IOMSG(L'IKJDAIR),IKJDAIR MOVE INSERTION INTO BLOCK       46305020
         LA    WORK2,M3131IN2           GET 2ND RELATIVE OFFSET         46312020
         STH   WORK2,MGBLD2O2           STORE IN MESSAGE BLOCK          46319020
         SRL   RETCDREG,ONE            SET UP FOR INSERTION PICK UP     46326020
         LH    WORK2,CODETAB-X2(RETCDREG) GET CODE IN REG               46333020
         STH   WORK2,IOMSG2             STORE 2ND INSERTION             46340020
         MVI   MGBLD2L,SIX             MOVE LENGTH INTO BLOCK           46350020
         BAL   LINK5,MSG                GO PUT OUT MESSAGE              46368020
         B     UIFREE                   GO TO CLEAN UP                  46375020
         SPACE 2                                                        46400020
*********************************************************************** 46600020
*   DATA SET NOT USABLE// OPEN ERROR                                    46800020
UI12     EQU   *                                                        46860020
         XC    MSGAREA(X48),MSGAREA    CLEAR MESSAGE AREA               46960020
         MVC   MSGAREA(X4),OPENERPB    RELATIVE MSG NUMBERS             47060020
         BAL   LINK5,MSG               PUT OUT MESSAGE                  47340020
         BAL   LINK9,UI50              PERFORM CLEANUP                  47400020
         LA    RETCDREG,OPENERR        SET RETURN CODE                  47600020
         B     UI00                    RETURN TO CALLER                 47800020
         SPACE 2                                                        48000020
*   CONVERT ALLOCATION ERROR CODE TO EBCDIC HEX AND ISSUE MESSAGE       48005020
UIDAIRCD EQU   *                                                        48010020
         STH   WORK2,SAVEAREA          ERROR CODE                       48015020
         ST    PARMREG1,MSGAREA        RELATIVE MSG NUMBERS INTO LIST   48020020
         LA    PARMREG1,MGBUILD        INITIALIZE POINTER TO LEVEL      48025020
         ST    PARMREG1,MSGAREA+EIGHT    2 INSERTION BLOCK              48030020
         MVI   MGBUILDL,EIGHT          MSG TEXT LENGTH + FOUR           48035020
         UNPK  IOMSG(FIVE),SAVEAREA(THREE) TRANSLATE ERROR CODE INTO    48040020
         TR    IOMSG(FOUR),TRANTAB-X240      HEX CHARACTERS             48045020
MSG      EQU   *                                                        48050020
         IKJEBEML ,,,,MF=(E,MSGAREA)                                    48100020
         BR    LINK5                   RETURN                           48150020
MSGCORE  EQU   MSG+4                   USE CA FOR MESSAGE               48200020
         SPACE 3                                                        48250020
**********************************************************************  48300020
*   NOT ENOUGH MAIN STORAGE TO EXECUTE ---------                        48350020
UI3      EQU   *                                                        48450020
         XC    CASRWKA(X48),CASRWKA    CLEAR MESSAGE AREA               48550020
         MVC   CASRWKA(X2),NOCOREPB    RELATIVE MSG NUMBER              48650020
         LA    WORK2,CASRWKA+MGCOREB   SET UP INSERTION BLOCK           48750020
         ST    WORK2,CASRWKA+FOUR      POINT TO INSERTION BLOCK         48950020
         LA    PARMREG1,M312IN1        INITIALIZE OFFSET IN LEVEL 1     49030020
         STH   PARMREG1,CASRWKA+MGCOREBO INSERTION BLOCK                49110020
         MVI   CASRWKA+MGCOREBL,L'COMMAND+FOUR  SET UP LENGTH           49190020
         MVC   CASRWKA+MGCOREBM(L'COMMAND),COMMAND MOVE TEXT TO BLOCK   49270020
         OC    CAPTCDCB+ONE(THREE),CAPTCDCB+ONE ANY SUBCOMMANDS YET     49350020
         BZ    UI31                    NO,GO ISSUE MSG TEXT 'COMMAND'   49550020
         L     PARMREG1,CAPTTMP        ADDRESS OF CPPL                  49750020
         L     PARMREG1,CPPLECT-CPPL(PARMREG1) GET ECT ADDRESS          49950020
         MVC   CASRWKA+MGCOREBM(EIGHT),ECTSCMD-ECT(PARMREG1)            50150020
UI31     LA    PARMREG1,CASRWKA        SET UP ADDRESS FOR MESSAGE       50350020
         BAL   LINK5,MSGCORE           GO PUT MESSAGE                   50550020
UI4      LA    RETCDREG,FOUR           SET RETURN CODE                  50750020
         B     UI00                    RETURN TO CALLER                 50950020
         EJECT                                                          53000020
*   ENTER THIS SECTION ON ERROR CONDITIONS FOR CLEANUP                  53200020
         SPACE 2                                                        53400020
*   UNALLOCATE THE UTILITY DATA SET HERE                                54800020
UI50     MVC   UIDAIR(DDSIZE),DCODE    PARM LIST FOR DAIR               55000020
         MVC   UIDAIR+DA18DDN-DAPB18(L'DCBDDNAM),DCBDDNAM DDNAME        55200020
         LA    PARMREG1,UIDAIR         ADDRESS OF LIST                  55400020
         ST    PARMREG1,CATMPLST+DAPLDAPB-DAPL BLOCK ADDRESS TO LIST    55600020
         L     PARMREG1,CAPTTMP        ADDRESS OF CPPL LIST             55800020
         USING CPPL,PARMREG1                                            56000020
         MVC   CATMPLST+DAPLPSCB-DAPL(L'CPPLPSCB),CPPLPSCB PSCB ADDRESS 56200020
         DROP  PARMREG1                                                 56400020
         LA    PARMREG1,CATMPLST       TOTAL PARM LIST FOR DAIR         56600020
         LINK  EP=IKJDAIR              UNALLOCATE THE DATA SET          56800020
         SPACE 2                                                        57000020
*   FREE THE WORKAREA CORE HERE                                         57200020
UI40     LR    PARMREG1,DATAREG        WORKAREA ADDRESS                 57400020
         LA    PARMREG1,ZERO(PARMREG1) INSURE HIGH ORDER CLEAR          57600020
         FREEMAIN R,LV=CORESIZE,A=(1),SP=SPONE                          57800020
         BR    LINK9                   RETURN TO CALLER                 58000020
         EJECT                                                          58200020
         SPACE 2                                                        62000020
         DROP  BASEREG,COMMREG,DATAREG,WORK8                            62200020
         SPACE                                                          62400020
*   CONSTANT AREA FOR IKJEBEUI                                          62600020
UICLEAR  XC    ZERO(ONE,WORK2),ZERO(WORK2)  CLEARS CORE                 62800020
UTILDIV  DC    A(BLKSIZE-CONTRLOV)     USABLE AREA IN DATA BLOCK        62900020
BUFLNG   DC    A(BSIZE)                LENGTH OF BUFFER CORE            62960020
CODETAB  DS    0H                                                       63030020
         DC    C'0408121620242832364044' MSG INSERTION TABLE    A59609  63070021
TRANTAB  DC    C'0123456789ABCDEF'     TRANSLATE TABLE                  63110020
IKJDAIR  DC    C'DAIR'                 MESSAGE INSERTION                63150020
COMMAND  DC    C'COMMAND '             INSERTION FOR INSUFFICIENT       63160020
*                                      CORE MSG, SHOULD BE EIGHT        63170020
*                                      CHARACTERS LONG                  63180020
UIDAIR08 DC    H'8'                    DAIR RC=X'08' CATLG ERR  A59609  63183021
UIDAIR10 DC    H'16'                   DAIR RC=X'10' NO TIOT    A59609  63186021
*                                      ENTRIES AVAILABLE        A59609  63189021
UIDAIR30 DC    H'48'                   DAIR RC=X'30' DAIR STAE  A59609  63192021
*                                      EXIT ENTERED             A59609  63195021
         SPACE                                                          63200020
*   PARAMETER LIST FOR DAIR --- UTILITY DATA SET ALLOCATION             63400020
         DS    0D                                                       63600020
DAIRCODE DC    H'08'                   ENTRY CODE                       63800020
FLAGS    DC    H'0'                    RETURN SETTINGS                  64000020
DARC     DC    H'0'                    ERROR CODE---DYNAMIC ALLOCATION  64200020
CTRC     DC    H'0'                    ERROR CODE---CATALOG             64400020
DSNAMPTR DC    A(DSNAME)               POINTER TO DSNAME                64600020
DDNAME   DC    8C' '                   DDNAME RETURNED                  64800020
UNITNAME DC    8C' '                   UNIT NAME                        65000020
SERIALNO DC    8C' '                   VOLUME SERIAL NO.                65200020
BLCKSIZE DC    F'1688'                    AVERAGE RECORD LENGTH         65400020
PRIMARY  DC    F'400'                    PRIMARY SPACE                  65600020
SECOND   DC    F'200'                    SECONDARY SPACE                65800020
DIRECT   DC    F'0'                    DIRECTORY SPACE                  66000020
MEMBER   DC    8C' '                   MEMBER NAME                      66200020
PASSWORD DC    8C' '                   PASSWORD                         66400020
DISP1    DC    X'04'                   DATA SET STATUS//NEW             66600020
DISP2    DC    X'04'                   NORMAL DISPOSITION//DELETE       66800020
DISP3    DC    X'04'                   CONDITIONAL DISPOSITION//DELETE  67000020
CONTROL  DC    X'40'                   DAIR CONTROL                     67200020
RESERVED DC    AL3(0)                  NOT USED                         67400020
DSORG    DC    X'00'                   DSORG TYPE RETURNED              67600020
DAIRSIZE EQU   *-DAIRCODE              LENGTH OF PARM LIST              67800020
         SPACE 2                                                        67830020
*   DATA SET NAME FOR PERMANENTLY ALLOCATED UTILITY DATA SET            67860020
         DS    0H                                                       67890020
DSNAME   DC    X'0005'                 LENGTH OF DSNAME                 67920020
         DC    C'&&EDIT'               DSNAME                           67950020
         SPACE 2                                                        68000020
*   PARAMETER LIST FOR DAIR --- UTILITY DATA SET UNALLOCATION           68200020
         DS    0D                                                       68400020
DCODE    DC    H'24'                   ENTRY CODE                       68600020
DFLAGS   DC    H'0'                    RETURN SETTINGS                  68800020
DDARC    DC    H'0'                    ERROR CODE ---DYNAMIC ALLOCATION 69000020
DCTRC    DC    H'0'                    ERROR CODE ---CATALOG            69200020
DDSPTR   DC    F'0'                    DATA SET NAME POINTER            69400020
DDDNAME  DC    8C' '                   DDNAME                           69600020
DMEMBER  DC    8C' '                   MEMBER NAME                      69800020
DSYSCLS  DC    H'0'                    FOR SYSOUT DS USE                70000020
DDISP2   DC    X'40'                   NORMAL DISPOSITION//DELETE       70200020
DCONTROL DC    X'00'                   DAIR CONTROL                     70400020
DDSIZE   EQU   *-DCODE                 LENGTH OF PARM LIST              70600020
         EJECT                                                          72000020
*********************************************************************** 72030020
*   RELATIVE MESSAGE NUMBERS FOR MESSAGE PARAMETER LISTS                72060020
         DS    0F                                                       72090020
         SPACE                                                          72120020
CTLGERPB DC    AL2(M304U)              UTILITY DS NOT ALLOCATED         72150020
         DC    AL2(M3042)              CATALOG ERROR CODE ( )           72180020
         SPACE                                                          72210020
CTIOERPB DC    AL2(M304U)              UTILITY DS NOT ALLOCATED         72240020
         DC    AL2(M3043)              CATALOG I/O ERROR                72270020
         SPACE                                                          72300020
ALOCERPB DC    AL2(M304U)              UTILITY DS NOT ALLOCATED         72330020
         DC    AL2(M3041)              DYNAMIC ALLOC ERROR CODE ( )     72360020
         SPACE                                                          72390020
DC0214PB DC    AL2(M318U)              UTILITY DS NOT ALLOCATED         72420020
         DC    AL2(M3181)              INVALID UNIT IN USER ATTRIB DS   72450020
         SPACE                                                          72480020
DC021CPB DC    AL2(M318U)              UTILITY DS NOT ALLOCATED         72510020
         DC    AL2(M3182)              NO UNIT AVAILABLE                72540020
         SPACE                                                          72570020
DC0220PB DC    AL2(M305U)              UTILITY DS NOT ALLOCATED         72600020
         DC    AL2(M3051)              NO SPACE ON VOLUMES              72630020
         SPACE                                                          72660020
NOTIOTPB DC    AL2(M301U)              TOO MANY DATA SETS               72690020
         DC    AL2(M3011)              USE FREE COMMAND                 72720020
         SPACE                                                          72750020
SYSERRPB DC    AL2(M313)               COMMAND SYSTEM ERROR             72780020
         DC    AL2(M3131)              (DAIR) ERROR CODE ( )            72810020
         SPACE                                                          72840020
OPENERPB DC    AL2(M309U)              UTILITY DS NOT USABLE            72870020
         DC    AL2(M3093)              CANNOT OPEN DATA SET             72900020
         SPACE                                                          72930020
NOCOREPB DC    AL2(M312)               NOT ENOUGH CORE TO EXECUTE ( )   72960020
         SPACE 2                                                        73000020
         EJECT                                                          74400020
*********************************************************************** 74600020
BSAMDCB  DCB   DSORG=PS,RECFM=F,MACRF=(WP),BLKSIZE=BLKSIZE              74800020
DCBEND   EQU   *                       END OF DCB                       75000020
*********************************************************************** 75200020
         SPACE 2                                                        75400020
GM       GETMAIN EC,LV=CORESIZE,A=0,SP=SPONE,MF=L   GETMAIN LIST        75600020
GMEND    EQU   *                       END OF GETMAIN LIST              75800020
OPENL    OPEN  (,(OUTPUT)),MF=L        LIST FORM                        76000020
OPENLEND EQU   *                       END OF LIST FORM                 76200020
         SPACE 2                                                        76500020
*********************************************************************** 76800020
*   THE FOLLOWING SECTION (XDAP, READ, AND WRITE FORMS) IS MOVED TO     77000020
*     THE WORKAREA WITH ONE INSTRUCTION AND SHOULD NOT BE ALTERED.      77200020
XDAP     XDAP  ECB,WI,0,0,BLKSIZE,MF=L XDAP LIST FORM                   77400020
XDAPEND  EQU   *                       END OF XDAP LIST FORM            77600020
WRITEB   WRITE WDECB,SF,MF=L           BSAM WRITE//LIST FORM            77800020
WRITEEND EQU   *                       END OF WRITE LIST FORM           78000020
READ     XDAP  RDECB,RI,0,0,BLKSIZE,MF=L  LIST FORM//XDAP READ          78200020
READEND  EQU   *                       END OF READ LIST FORM            78400020
*********************************************************************** 78600020
         EJECT                                                          78800020
UIWORK   DSECT                                                          79000020
*   DESCRIPTIONS ON THE USE OF THE TEMPORARY WORK SPACE USED BY         79200020
*     THIS ROUTINE IN THE 'TEMPAREA' FIELD OF UTILWORK.                 79400020
         SPACE                                                          79600020
UIALL    EQU   *                       GENERAL LIST FORM AREA           79800020
UIDAIR   EQU   *                       DAIR CONTROL LIST                80000020
         SPACE                                                          80200020
         ORG   UIALL                   USE SAME AREA                    80400020
UIOPEN   OPEN  (,(OUTPUT)),MF=L        OPEN MACRO,  LIST FORM           80600020
         SPACE                                                          80800020
         ORG   UIALL                   USE SAME AREA                    81600020
UIGM     GETMAIN EC,LV=CORESIZE,A=0,SP=SPONE,MF=L   GETMAIN LIST        81800020
UIGMADDR DS    1F                      ONE WORD ADDRESS FOR GETMAIN     82000020
         SPACE                                                          82200020
UIEND    EQU   *                                                        82400020
*********************************************************************** 82600020
         IKJDAP08                                                       82800020
*********************************************************************** 83000020
         IKJDAP18                                                       83200020
*********************************************************************** 83400020
         SPACE 2                                                        83600020
         IKJCPPL                                                        83800020
*********************************************************************** 84000020
         SPACE 2                                                        84200020
         IKJDAPL                                                        84400020
         SPACE 2                                                        84600020
         IKJECT                                                         84800020
         IKJEBEUW                                                       85000020
         EJECT                                                          85200020
*********************************************************************** 85400020
         IKJEBECA                                                       85600020
         SPACE 2                                                        85800020
*********************************************************************** 86000020
         ORG   CATEMPBF                TEMPORARY WORKAREA               86200020
GMLIST   GETMAIN EC,LV=0,A=0,SP=SPONE,MF=L  GETMAIN LIST                86400020
GMADDR   DS    1F                      GETMAIN ADDRESS                  86600020
*********************************************************************** 86800020
         END                                                            87000020
         EJECT                                                          87200020
