BEUT TITLE 'EDIT UTILITY DATA SET INTERFACE ROUTINE --- IKJEBEUT'       00300020
IKJEBEUT CSECT                                                          00600020
*********************************************************************** 00900020
*                                                                     * 01800020
*STATUS -- VERSION NO. 01,OS/360 RELEASE NO. 20                       * 02100020
*                                                                     * 02400020
*FUNCTION   -THIS ROUTINE SERVES AS AN INTERFACE BETWEEN ALL EDIT     * 02700020
*   SUBCOMMANDS AND COPY ROUTINES THAT MUST ACCESS THE UTILITY DATA   * 03000020
*   SET.  THIS ROUTINE MUST BE USED ANYTIME RECORDS ARE TO BE         * 03300020
*   PLACED IN THE DATA SET, DELETED FROM THE DATA SET, OR READ FROM   * 03600020
*   THE DATA SET.                                                     * 03900020
*       THE OPERATION THAT IS PERFORMED IS DETERMINED BY THE INPUT    * 04200020
*   PARAMETER LIST AS DESCRIBED BELOW.  THE ADDRESS OF THE DESIRED    * 04500020
*   ROUTINE IS SELECTED FROM A VECTOR TABLE WHICH IS THE FIRST CSECT  * 04800020
*   IN THE ACCESS METHOD LOAD MODULE AND WHOSE ADDRESS IS CONTAINED   * 05100020
*   IN THE UTILITY DATA SET WORK AREA.                                * 05400020
*       THE APPROPIATE ROUTINE (READ, WRITE, OR DELETE) IS CALLED     * 05700020
*   BY THIS ROUTINE WITH THE SAME INPUT PARAMETER LIST PASSED TO THEM.* 06000020
*       IF A DELETE OR WRITE OPERATION IS SUCCESSFUL, A SWITCH IS     * 06300020
*   SET (BIT CADSMODS OF CACFLAG2) IN THE EDIT COMMUNICATIONS AREA.   * 06600020
*   THIS SWITCH IS ALWAYS TURNED OFF BY THE SAVE SUBCOMMAND AND       * 06900020
*   INTERROGATED BY THE END SUBCOMMAND.                               * 07200020
*       ALL WRITE OPERATIONS WILL TEST TO SEE IF THE DATA SET IS LINE * 07500020
*   NUMBERED. IF THE RECORDS ARE TO BE NUMBERED, THIS ROUTINE TAKES   * 07800020
*   THE 4-BYTE BINARY KEY THAT PREFIXES EACH RECORD AND CONVERTS IT   * 08100020
*   TO DECIMAL-EBCDIC.  IT IS THEN MOVED INTO THE PROPER PLACE IN THE * 08400020
*   RECORD.  THIS NUMBER IS ALSO CHECKED TO SEE THAT FOR ITS          * 08700020
*   SPECIFIED LENGTH, THAT ITS VALUE DOES NOT EXCEED THE UPPER        * 09000020
*   LIMIT.  IF THE NUMBER IS TOO LARGE, A MESSAGE WILL BE ISSUED.     * 09300020
*        IN THE EVENT THAT AN I/O ERROR WAS ENCOUNTERED IN ONE OF     * 09600020
*   THE CALLED ROUTINES, THIS ROUTINE USES THE IKJEBEMS ROUTINE TO    * 09900020
*   WRITE OUT THE MESSAGE. THE SYNADAF ERROR INFORMATION WILL HAVE    * 10200020
*   BEEN PREVIOUSLY STORED IN THE UTILITY WORKAREA FOR USE BY THIS    * 10500020
*   ROUTINE.                                                          * 10800020
*                                                                     * 11100020
*ENTRY POINT-  AT IKJEBEUT VIA A LINK OR LOAD-CALL                    * 11400020
*                                                                     * 11700020
*INPUT-  REGISTER 0 POINTS TO THE EDIT COMMUNICATIONS AREA            * 12000020
*        A ONE TO THREE WORD PARAMETER LIST POINTED TO BY REGISTER 1  * 12300020
*                                                                     * 12600020
*   READ OPERATIONS                                                   * 12900020
*     WORD1-   CODE PLUS POINTER TO UTILITY WORKAREA-DCB              * 13200020
*        CODES- '00'  -READ RECORD LAST REFERENCED BY ACCESS METHOD   * 13500020
*               '01'  -READ RECORD PRIOR TO LAST REFERENCED           * 13800020
*               '02'  -READ RECORD AFTER LAST REFERENCED              * 14100020
*               '04'  -READ FIRST RECORD IN DATA SET                  * 14400020
*               '05'  -READ LAST RECORD IN DATA SET                   * 14700020
*     WORD2-   OPTIONALLY CONTAINS A POINTER TO A 4-BYTE BINARY KEY   * 15000020
*        THAT REPLACES THE LAST REFERENCED KEY IN THE ACCESS METHOD   * 15300020
*        BEFORE THE OPERATION TAKES PLACE                             * 15600020
*     WORD3-   OPTIONALLY CONTAINS A POINTER WHICH IS AN ADDRESS      * 15900020
*        OF WHERE THE RECORD IS TO BE PLACED                          * 16200020
*                                                                     * 16500020
*   DELETE OPERATIONS                                                 * 16800020
*     WORD1-   CODE PLUS POINTER TO UTILITY WORKAREA-DCB              * 17100020
*        CODE-  '10'  -DELETE LAST REFERENCED OR AS SPECIFIED         * 17400020
*                      BY THE KEY INDICATED IN WORD2                  * 17700020
*     WORD2-   OPTIONALLY CONTAINS A POINTER TO A 4-BYTE BINARY KEY   * 18000020
*        THAT REPLACES THE LAST REFERENCED KEY IN THE ACCESS METHOD   * 18300020
*        BEFORE THE OPERATION TAKES PLACE                             * 18600020
*     WORD3-   NOT USED                                               * 18900020
*                                                                     * 19200020
*   WRITE OPERATIONS                                                  * 19500020
*     WORD1-   CODE PLUS POINTER TO UTILITY WORKAREA-DCB              * 19800020
*        CODE-  '20'  -WRITE THE INDICATED RECORD IN THE DATA SET     * 20100020
*     WORD2-   POINTER TO THE RECORD WHICH IS TO BE PLACED IN THE     * 20400020
*        DATA SET.                                                    * 20700020
*     WORD3-   NOT USED                                               * 21000020
*                                                                     * 21300020
*                                                                     * 21600020
*OUTPUT- REGISTERS AS DESCRIBED UNDER 'EXIT' BELOW                    * 21900020
*   USES THE IKJEBEMS ROUTINE TO WRITE OUT I/O ERROR OR INVALID       * 22200020
*   LINE NUMBER MESSAGES.                                             * 22500020
*                                                                     * 22800020
*EXTERNAL REFERENCES --                                               * 23100020
*       IKJEBEMS             WRITES OUT ERROR MESSAGES                * 23400020
*       IKJEBEDR             DELETES RECORDS                          * 23700020
*       IKJEBERR             READS RECORDS                            * 24000020
*       IKJEBEWR             WRITES RECORDS                           * 24300020
*                                                                     * 24600020
*EXITS,NORMAL-  A RETURN CODE IN REGISTER 15 AS FOLLOWS-              * 24900020
*        RETURN CODE = 0    THE READ, WRITE, OR DELETE OPERATION      * 25200020
*          WAS SUCCESSFUL.  FOR READ OPERATIONS, THE RECORD WAS       * 25500020
*          EITHER MOVED TO THE LOCATION SPECIFIED BY THE USER, OR     * 25800020
*          IF NO ADDRESS WAS SPECIFIED, REGISTER 1 POINTS AT THE      * 26100020
*          RECORD                                                     * 26400020
*                                                                     * 26700020
*        RETURN CODE = 4    THE SPECIFIED RECORD FOR A DELETE OR      * 27000020
*          READ OPERATION DOES NOT EXIST                              * 27300020
*                                                                     * 27600020
*EXITS,ERROR-   A RETURN CODE IN REGISTER 15 AS FOLLOWS-              * 27900020
*        RETURN CODE =  8  -I/O ERROR ENCOUNTERED                     * 28200020
*        RETURN CODE = 12  -INVALID LINE NUMBER                       * 28500020
*          THIS ROUTINE INITIATES THE WRITING OF THE ERROR MESSAGES   * 28800020
*          THIS ROUTINE WILL WRITE OUT THE I/O ERROR MESSAGE.         * 29100020
*                                                                     * 29400020
*TABLES/WORK AREAS --                                                 * 29700020
*       THIS ROUTINE IS DEPENDENT UPON THE EDIT COMMUNICATIONS        * 30000020
*   AREA, IKJEBECA, FOR THE FOLLOWING-                                * 30300020
*         -THE ADDRESS OF THE UTILITY WORKAREA/DCB                    * 30600020
*         -LINE NUMBER INFORMATION                                    * 30900020
*         -THE UTILITY DATA SET MODIFIED SWITCH                       * 31200020
*                                                                     * 31500020
*       THIS ROUINE IS DEPENDENT ON THE UTILITY WORKAREA, UTILWORK,   * 31800020
*   FOR THE FOLLOWING-                                                * 32100020
*         -ADDRESS OF THE EDIT ACCESS METHOD MODULE, IKJEBEAA.        * 32400020
*                                                                     * 32700020
*ATTRIBUTES- REFRESHABLE,ENABLED,NON-PRIVILEGED                       * 33000020
*                                                                     * 33300020
*NOTES- THE CONVERSION OF THE KEY VALUE INTO A STATEMENT SEQUENCE     * 33600020
*   NUMBER IS DEPENDENT ON THE EBCDIC CHARACTER SET                   * 33900020
*                                                                     * 34200020
*********************************************************************** 34500020
         EJECT                                                          34800020
*   THE FOLLOWING ARE REGISTER ASSIGNMENTS                              35100020
PARMREG0 EQU   0                       PARM POINTER                     35400020
PARMREG1 EQU   1                       PARM POINTER                     35700020
WORK2    EQU   2                       WORK REGISTER                    36000020
WORK3    EQU   3                       WORK REGISTER                    36300020
LINK5    EQU   5                       LINK REGISTER                    36400020
WORK4    EQU   4                       WORK REGISTER                    36600020
WORK6    EQU   6                       WORK REGISTER                    36900020
WORK8    EQU   8                       VECTOR TABLE ADDRESSING          37200020
COMMREG  EQU   9                       COMMUNICATION AREA ADDRESSING    37500020
BASEREG  EQU   11                      BASE REGISTER                    37800020
DATAREG  EQU   12                      UTILITY WORK AREA ADDRESSING     38100020
SAVEREG  EQU   13                      SAVE AREA ADDRESSING             38400020
RETREG   EQU   14                      RETURN REGISTER                  38700020
RETCDREG EQU   15                      RETURN CODE                      39000020
ENTRY    EQU   15                      ENTRY POINT ADDRESS              39300020
         SPACE 2                                                        39600020
*   DEFINITIONS                                                         39900020
ONE      EQU   1                       CONSTANT OF ONE                  40200020
LENL     EQU   4                       LENGTH OF LENGTH PREFIX          40500020
NRF      EQU   4                       RECORD DOES NOT EXIST CODE       40800020
MAXNO    EQU   8                       MAXIMUM LINE NUMBER LENGTH       41100020
IOERROR  EQU   8                       I/O ERROR CODE                   41400020
EIGHT    EQU   8                       CONSTANT OF 8                    41500020
INVALNUM EQU   12                      RETURN CODE, INVALID NUMBER      41700020
WORD1    EQU   0                       OFFSET TO 1ST PARM INPUT WORD    42000020
WORD2    EQU   4                       OFFSET TO 2ND PARM INPUT WORD    42300020
WORD3    EQU   8                       OFFSET TO 3RD PARM INPUT WORD    42600020
ALL      EQU   X'FF'                   ALL BITS//IN SWITCH              42900020
NUMZONE  EQU   X'F0'                   NUMERIC ZONE                     43200020
LAST     EQU   X'80'                   LAST ENTRY INDICATOR             43500020
ZERO     EQU   0                       CONSTANT OF ZERO                 43800020
X0       EQU   0                       OFFSET OF 0                      44100020
L4       EQU   4                       LENGTH OF 4                      44400020
X24      EQU   24                      OFFSET OF 24                     44700020
TIMES4   EQU   2                       MULTIPLICATION FACTOR            45000020
         SPACE 2                                                        45300020
*   MESSAGE REFERENCES                                                  45600020
SYNADL   EQU   78                      LENGTH OF SYNAD MESSAGES         45900020
         SPACE                                                          46200020
         IKJEBEMI (309,402)                                             46500020
         EJECT                                                          46800020
*   PERFORM THE INITIALIZATION OPERATIONS HERE                          47100020
         IKJEBESV  (14,12),T,*,COMMREG=(0)                              47400020
         USING IKJEBECA,COMMREG                                         47700020
         L     DATAREG,WORD1(PARMREG1) UTILITY DATA SET WORKAREA        48000020
         USING UTILWORK,DATAREG                                         48300020
         L     WORK8,VTABLE            ADDRESS OF ACCESS METHOD//TABLE  48600020
         USING VECTABLE,WORK8                                           48900020
         SPACE 2                                                        49200020
*   INSURE THAT THE ERROR SWITCH IS OFF                                 49500020
         NI    DCBSTATS,ALL-ERROR      INSURE ERROR SWITCH IS OFF       49800020
         SPACE                                                          50100020
         SPACE                                                          50400020
*   DETERMINE THE TYPE OF OPERATION HERE                                50700020
         CLI   X0(PARMREG1),WRITE      IS THIS A WRITE OPERATION        51000020
         BE    UT9                     YES- GO PROCESS                  51300020
         TM    X0(PARMREG1),DELETE     IS THIS A DELETE OPERATION       51600020
         BO    UT4                     YES-GO PROCESS                   51900020
         SPACE 2                                                        52200020
*   THIS IS A READ OPERATION                                          * 52500020
UT5      L     ENTRY,RR                ADDRESS OF READ ROUTINE          52800020
         BALR  RETREG,ENTRY            PERFORM THE READ OPERATION       53100020
         SPACE 2                                                        53400020
*   DETERMINE IF ERROR MESSAGE IS REQUIRED                              53700020
UT6      LA    WORK6,NRF               CONSTANT OF FOUR                 54000020
         CLR   RETCDREG,WORK6          RETURN CODE LARGER THAN FOUR     54300020
         BH    UT7                     YES--GO GIVE ERROR MESSAGE       54600020
         EJECT                                                          54900020
*   RETURN TO THE CALLING ROUTINE HERE                                  55200020
UT8      EQU   *                                                        55500020
         L     DATAREG,WORD2(SAVEREG)  PREVIOUS SAVE AREA               55800020
         ST    PARMREG1,X24(DATAREG)   SET UP REGISTER 1 FOR RETURN     56100020
         IKJEBERT (14,12),T,RC=(15)    RESTORE THE REGISTERS            56400020
         SPACE 2                                                        56700020
*   THIS IS A WRITE OPERATION                                         * 57000020
UT9      TM    CACFLAG1,CANONUM        IS THIS A NON-LINE NUMBERED DS   57300020
         BO    UT91                    YES-NO NUMBER PROCESSING         57600020
         SPACE 2                                                        57900020
*   INSURE GIVEN LINE NUMBER VALUE IS NOT GREATER THAN LIMIT            58200020
         L     WORK2,WORD2(PARMREG1)   RECORD ADDRESS                   58500020
         SR    WORK4,WORK4             ZERO REGISTER                    58800020
         IC    WORK4,CALENGTH          LINE NO. LENGTH                  59100020
         SLL   WORK4,TIMES4            LENGTH TIMES FOUR                59400020
         L     WORK3,UTTABLE-L4(WORK4) UPPER LIMIT FOR LENGTH NO.       59700020
         CL    WORK3,X0(WORK2)         IS TABLE ENTRY GREATER THAN      60000020
*                                        KEY VALUE ON RECORD            60300020
         BL    UT10                    NO--GO GIVE ERROR MESSAGE        60600020
         SPACE 2                                                        60900020
*   CONVERT THE NUMBER TO DECIMAL-EBCDIC HERE                           61200020
         MVC   UTNUMB(KEYL),X0(WORK2)   INSURE ALIGNMENT                61500020
         L     WORK3,UTNUMB            BINARY LINE NUMBER               61800020
         CVD   WORK3,UTNUMB            CONVERT TO DECIMAL               62100020
         UNPK  UTDEC(MAXNO),UTNUMB(MAXNO)  SET UP FOR EBCDIC            62400020
         OI    UTDECL,NUMZONE          INSURE CORRECT ZONE/LAST DOGIT   62700020
         SPACE                                                          63000020
*   COMPUTE ADDRESS OF LINE NUMBER                                      63300020
         SR    WORK3,WORK3             ZERO                             63600020
         IC    WORK3,CALINE            OFFSET TO LINE NUMBER            63900020
         LA    WORK2,KEYL+LENL-ONE(WORK3,WORK2) ADDRESS OF LINE NUMBER  64200020
         IC    WORK3,CALENGTH          LENGTH OF LINE NUMBER            64500020
         LA    WORK4,MAXNO             MAXIMUM LINE NUMBER LENGTH       64800020
         SR    WORK4,WORK3             POSITIONING INDEX FACTOR         65100020
         LA    WORK4,UTDEC(WORK4)      MOVE FROM ADDRESS                65400020
         BCTR  WORK3,ZERO              DECREMENT FOR EXECUTE            65700020
         EX    WORK3,UTMOVE            LINE NUMBER TO RECORD            66000020
         SPACE 2                                                        66300020
*   PERFORM THE WRITE OPERATION HERE                                    66600020
UT91     L     ENTRY,WR                ADDRESS OF WRITE ROUTINE         66900020
         BALR  RETREG,ENTRY            PERFORM THE WRITE OPERATION      67200020
         B     UT3                     GO CHECK IF SUCCESSFUL           67500020
         SPACE 2                                                        67800020
*   THIS IS A DELETE OPERATION                                        * 68100020
UT4      TM    ZERO(PARMREG1),LAST     MORE THAN ONE PARM               68400020
         BO    UT41                    NO--                             68700020
         L     PARMREG0,WORD2(PARMREG1) YES-SET UP SECOND PARAMETER     69000020
         B     UT42                    KEY IS SET UP-CONTINUE           69300020
UT41     SR    PARMREG0,PARMREG0       SHOW NO KEY SPECIFIED            69600020
UT42     L     PARMREG1,WORD1(PARMREG1)  WORK AREA ADDRESS              69900020
         L     ENTRY,DR                ADDRESS OF DELETE ROUTINE        70200020
         BALR  RETREG,ENTRY            GO DELETE THE RECORD             70500020
         SPACE 2                                                        70800020
*   CHECK IF THE DELETE OR WRITE WAS SUCCESSFUL HERE                    71100020
UT3      LA    WORK6,NRF               CONSTANT OF FOUR                 71400020
         CLR   RETCDREG,WORK6          RETURN CODE LARGER THAN FOUR     71700020
         BH    UT7                     YES-GO GIVE I/O ERROR MESSAGE    72000020
         BE    UT8                     RECORD DID NOT EXIST             72300020
         OI    CACFLAG2,CADSMODS       INDICATE DATA SET MODOFIED       72600020
         MVC   CAUTILNO(L'CAUTILNO),DCBRECNO FROM UTILWORK TO COMM AREA 72700020
         B     UT8                     RETURN                           72900020
         SPACE 2                                                        73200020
UT7      EQU   *                                                        73500020
*   WRITE OUT THE I/O ERROR MESSAGE HERE                              * 73800020
         MVC   MSGAREA(IOERREND-IOERR),IOERR SET 1ST MESSAGE BLOCK      74000020
         XC    MGBUILD(EIGHT),MGBUILD  ZERO THE MESSAGE BLOCK           74200020
         LA    WORK2,MGBUILD           GET READY TO ATTACH BLOCKS       74400020
         ST    WORK2,MSGAREA+EIGHT     POINT TO 2ND LEVEL BLOCK         74600020
         LA    WORK2,M3092IN1          GET RELATIVE OFFSET              74800020
         STH   WORK2,MGBUILDO          SET IN BLOCK                     75000020
         MVI   MGBUILDL,SYNADL+L4      SET LENGTH VALUE                 75200020
         BAL   LINK5,MSG               GO PRINT MESSAGE                 75400020
         SPACE                                                          75900020
         LA    RETCDREG,IOERROR        SET I/O ERROR CODE               76200020
         B     UT8                     RETURN TO CALLER                 76500020
         SPACE 2                                                        76800020
*   ISSUE MESSAGE ABOUT TOO LARGE A LINE NUMBER                         77100020
UT10     EQU   *                                                        77400020
         MVC   MSGAREA(INVALEND-INVAL),INVAL  LIST FORM OF ML MACRO     77700020
         MVC   MGBUILD(INVALGE-INVALG),INVALG SET UP FOR INSERTION      77770020
         SRL   WORK4,TIMES4            RESET LINE NO. LENGTH            77840020
         LA    WORK4,L4(WORK4)         UP COUNT BY FOUR                 77910020
         STC   WORK4,MGBUILDL          SET LENGTH OF INSERTION          77980020
         LA    WORK4,MGBUILD           GET ADDRESS OF 2ND LEVEL BLOCK   78050020
         ST    WORK4,MSGAREA+L4        CONNECT BLOCKS                   78120020
         BAL   LINK5,MSG               GO PRINT MESSAGE                 78190020
         LA    RETCDREG,INVALNUM       RETURN CODE FOR NUMBER TOO LARGE 78300020
         B     UT8                     RETURN                           78600020
         SPACE 3                                                        78660020
MSG      EQU   *                                                        78720020
         IKJEBEML ,,,,MF=(E,MSGAREA)                                    78780020
         BR    LINK5                   RETURN TO CALLING POINT          78840020
         SPACE                                                          78900020
*********************************************************************** 79200020
*   CONSTANT AREA FOR THE IKJEBEUT ROUTINE                              79500020
         SPACE                                                          79800020
IOERR    IKJEBEML M309U,M3092,,,MF=L                                    80000020
IOERREND EQU   *                                                        80200020
         SPACE 3                                                        80400020
*********************************************************************** 80600020
*   INSERTION BLOCK FOR TOO LARGE A LINE NUMBER                         80800020
INVALG   IKJEBEMG 0,M402IN1,'99999999'                                  81000020
INVALGE  EQU   *                                                        81200020
         SPACE 2                                                        81400020
*********************************************************************** 81600020
         SPACE 2                                                        82500020
*********************************************************************** 82800020
*   INVALID LINE NUMBER MESSAGE                                         83100020
INVAL    IKJEBEML M402,,,,MF=L                                          83400020
INVALEND EQU   *                       END OF LIST FORM                 83700020
         SPACE                                                          84000020
*********************************************************************** 84300020
UTMOVE   MVC   X0(ONE,WORK2),X0(WORK4) MOVES NUMBERS INTO RECORDS       84600020
UTTABLE  DC    F'9'                    UPPER                            84900020
         DC    F'99'                    LIMITS                          85200020
         DC    F'999'                    FOR                            85500020
         DC    F'9999'                    EACH                          85800020
         DC    F'99999'                    LENGTH                       86100020
         DC    F'999999'                    OF                          86400020
         DC    F'9999999'                    LINE                       86700020
         DC    F'99999999'                    NUMBER                    87000020
         SPACE                                                          87300020
         DROP  BASEREG,COMMREG,DATAREG,WORK8                            87600020
         EJECT                                                          87900020
         IKJEBEUW                                                       88200020
         SPACE 2                                                        88500020
*********************************************************************** 88800020
*   DESCRIPTION ON USE OF 'TEMPAREA' FIELD OF UTILITY WORKAREA          89100020
UTNUMB   EQU   TEMPAREA                WORKAREA FOR CONVERT             89400020
UTDEC    EQU   TEMPAREA+8              CONTAINS DECIMAL NUMBER          89700020
UTDECL   EQU   UTDEC+7                 ADDRESS OF LAST CHARACTER        90000020
*********************************************************************** 90300020
         EJECT                                                          90600020
         IKJEBECA                                                       90900020
         END                                                            91200020
