 TITLE 'TSO ''EDIT'' COMMAND - ''VERIFY'' SUBCOMMAND - IKJEBEVE'        00400020
IKJEBEVE CSECT                                                          00800020
*********************************************************************** 01200020
*                                                                     * 01600020
* STATUS -- VERSION NO. 01, OS/360 RELEASE NO. 20                     * 02000020
*                                                                     * 02400020
* FUNCTION -- THIS ROUTINE IS THE VERIFY SUBCOMMAND WHICH RESETS THE  * 02600020
*    VERIFY SWITCH IN THE COMMUNICATION AREA.                         * 02800020
*                                                                     * 06400020
*    VERIFY     - VERIFY SWITCH(CAVRFYSW) IN EDIT COMM AREA TURNED ON * 06800020
*    VERIFY ON  -   ''     ''      ''     ''  ''   ''   ''    ''   ON * 07200020
*    VERIFY OFF -   ''     ''      ''     ''  ''   ''   ''    ''   OFF* 07600020
*                                                                     * 08000020
* ENTRY POINTS -- IKJEBEVE, MAIN ENTRY POINT                          * 08400020
*                                                                     * 09600020
* INPUT -- REGISTER 1 POINTS TO THE COMMUNICATION AREA                * 10000020
*                                                                     * 11200020
* OUTPUT -- TWO RETURN CODES ARE POSSIBLE IN REGISTER 15              * 11600020
*    0 -- SUCCESSFUL COMPLETION                                       * 11650020
*    8 -- UNSUCCESSFUL COMPLETION                                     * 12000020
*                                                                     * 12050020
* EXTERNAL REFERENCES --                                              * 12100020
*         IKJPARS   - CHECKS SYNTAX OF THE SUBCOMMAND                 * 12200020
*         IKJEBEMS  - SEND MESSAGES TO THE USER                       * 12300020
*         MACROS USED                                                 * 12400020
*         LINK     - PASSES CONTROL TO IKJPARS                        * 14400020
*         IKJPARM  - ) CONSTRUCTS                                     * 14800020
*         IKJKEYWD - )  PARAMETER CONTROL &                           * 15200020
*         IKJNAME  - )   PARAMETER DESCRIPTOR                         * 15600020
*         IKJENDP  - )    LISTS (PCL,PDL)                             * 16000020
*         IKJRLSA  - FREES STORAGE FOR PDL                            * 16400020
*         IKJEBECA - DEFINES DUMMY SECTION FOR EDIT COMM AREA         * 16800020
*         IKJEBESV - GENERATES ENTRY LINKAGE ) CHAINED                * 17200020
*         IKJEBERT - GENERATES EXIT LINKAGE  )  SAVE AREAS            * 17600020
*         IKJEBEMG - GENERATES A FORMATTED MESSAGE INSERTION          * 18000020
*         IKJEBEML - GENERATES MESSAGE SELECTION PARM LIST & CALLS    * 18400020
*                     IKJEBEMS THRU IKJEBESR                          * 18800020
*                                                                     * 19200020
* EXITS, NORMAL -- TO IKJEBEMA WITH RETURN CODE 0 IN REGISTER 15.     * 19600020
*                                                                     * 20400020
* EXITS, ERROR -- NONE                                                * 20800020
*                                                                     * 21200020
* TABLES/WORK AREAS -- IKJEBECA, EDIT COMMUNICATION AREA              * 21600020
*                                                                     * 22400020
* ATTRIBUTES -- REFRESHABLE, ENABLED, NON-PRIVILEGED                  * 22500020
*                                                                     * 22600020
* CHARACTER CODE DEPENDENCY -- NONE                                   * 22700020
*                                                                     * 22800020
* NOTES -- STANDARD CONVENTIONS                                       * 22900020
*                                                                     * 23200020
*********************************************************************** 24400020
 EJECT                                                                  24800020
*********************************************************************** 25200020
*                             ENTRY CODE                              * 25600020
*********************************************************************** 26000020
 SPACE                                                                  26400020
         IKJEBESV (14,12),,*                                            26800020
 SPACE                                                                  27200020
*********************************************************************** 27600020
*                             PROCESSING                              * 28000020
*********************************************************************** 28400020
         USING IKJEBECA,COMMREG         ESTABLISH ADDRESSABILITY        30400020
 SPACE                                                                  31200020
*********************************************************************** 31600020
* IF SUBCOMMAND HAS OPERAND, CALL PARSE.  OTHERWISE BRANCH TO TURN ON * 32000020
* VERIFY SWITCH.                                                      * 32400020
*********************************************************************** 32800020
 SPACE                                                                  33200020
         TM    CAPTIBFR,CAOPERND        IS THERE AN OPERAND             33600020
         BZ    SETON                    NO,BRANCH TO SET SW ON          34000020
         MVC   CATMPLST+PPLPCL-PPL(WORD),VERFYPCL YES,SET PT PCL        34400020
         LA    WORKREG,CAPTPRSD                                         34800020
         ST    WORKREG,CATMPLST+PPLANS-PPL SET PT ANSWER PLACE          35200020
         MVC   CATMPLST+PPLCBUF-PPL(WORD),CAPTIBFR SET PT INPUT BFR     35600020
PARSE    EQU   *                                                        36000020
         LA    PARMREG1,CATMPLST        SET PT TO PARM LIST             36400020
         LINK  EP=IKJPARS                                               36800020
         B     PARSEBT(RETCDREG)        BRANCH ACCORDING TO RET CODE    37200020
PARSEBT  EQU   *        **********RETURN CODE************ACTION******** 37600020
         B     SUCCESS   00 (SUCCESSFUL COMPLETION) - CONTINUE          38000020
         B     BADRETCD  04 (UNABLE TO PROMPT     ) - EXIT              38400020
         B     SETRETCD  08 (ATTENTION INTERRUPT  ) - EXIT              38800020
         B     LOGICERR  12 (INVALID PARAMETERS   ) - ISSUE MSG         39200020
         B     NOROOM    16 (NO SPACE AVAILABLE   ) - ISSUE MSG         39600020
 SPACE                                                                  40000020
*********************************************************************** 40400020
* IF 'ON' WAS SPECIFIED TURN ON THE VERIFY SWITCH.  OTHERWISE TURN    * 40800020
* IT OFF.                                                             * 41200020
*********************************************************************** 41600020
 SPACE                                                                  42000020
SUCCESS  EQU   *                                                        42400020
         L     PDLBASE,CAPTPRSD         SET PDL ADDRESSABILITY          42800020
         USING VERFYPDL,PDLBASE         ESTABLISH ADDRESSABILITY        43200020
         CLI   OPERAND+ONE,ON           WAS ON SPECIFIED                43600020
         BE    SETON                    YES,BRANCH TO TURN ON VERIFY SW 44400020
         NI    CACFLAG1,VEALL-CAVRFYSW  NO, TURN OFF VERIFY SWITCH      44800020
         B     RELEASE                  BRANCH TO FREE PARSE CORE       45200020
SETON    EQU   *                                                        45600020
         OI    CACFLAG1,CAVRFYSW        TURN ON VERIFY SWITCH           46000020
 SPACE                                                                  46400020
*********************************************************************** 46800020
* IF PARSE WAS CALLED FREE THE CORE USED FOR THE PDL                  * 47200020
*********************************************************************** 47600020
         TM    CAPRSPDL,CAFREEDL        WAS PARSE CALLED                47700020
         BNZ   SETRETCD                 BR NO                           47800020
 SPACE                                                                  48000020
RELEASE  EQU   *                        YES,RELEASE CORE                49600020
         IKJRLSA CAPTPRSD               FREE PDL CORE                   49800020
         OI    CAPRSPDL,CAFREEDL        SET PDL SWITCH ON               50000020
 SPACE                                                                  50400020
*********************************************************************** 50800020
*                             EXIT CODE                               * 51200020
*********************************************************************** 51600020
 SPACE                                                                  52000020
SETRETCD EQU   *                                                        52400020
         SR    RETCDREG,RETCDREG        SET RETURN CODE TO ZERO         52800020
RETRN    EQU   *                                                        52850020
         IKJEBERT (14,12),RC=(15)                                       53200020
 SPACE                                                                  53600020
*********************************************************************** 54000020
* THE FOLLOWING CODE IS BRANCHED-TO FROM THE PARSE BRANCH TABLE TO    * 54400020
* ISSUE MESSAGES OR TO RELEASE CORE.                                  * 54800020
*********************************************************************** 55200020
 SPACE                                                                  55600020
LOGICERR MVC   CASCWKA(MSGLISTL),LLOGICER SET PARM LIST                 55800020
         B     ISSUEMSG                 BRANCH TO ISSUE MSG             56400020
NOROOM   MVC   CASCWKA(MSGLISTL),LNOROOM  SET PARM LIST                 56800020
ISSUEMSG EQU   *                                                        57200020
@@@@@@@@ IKJEBEML ,,,,MF=(E,CASCWKA)    CALL IKJEBEMS THRU IKJEBESR     57600020
         SPACE                                                          57650020
BADRETCD EQU   *                                                        57700020
         LA    RETCDREG,EIGHT           SET RETURN CODE TO 8            57750020
         B     RETRN                    BR TO EXIT LINKAGE              58000020
 EJECT                                                                  59600020
*********************************************************************** 60000020
*                             CONSTANTS                               * 60400020
*********************************************************************** 60800020
 SPACE                                                                  61200020
VERFYPCL DC    V(IKJEBVE0)              ADDR OF PCL                     61600020
 SPACE                                                                  62000020
* MESSAGE SELECTION LIST-FORM MACROS -                                  62400020
 SPACE                                                                  62800020
VERIFY   IKJEBEMG  0,M312IN1,'VERIFY'                                   63000020
CODE     IKJEBEMG 0,M3131IN2,'12'                                       63200020
PARSEX   IKJEBEMG  CODE,M3131IN1,'PARSE'                                63400020
LLOGICER IKJEBEML  M313,M3131,0,PARSEX,MF=L                             63700020
LNOROOM  IKJEBEML  M312,0,VERIFY,0,MF=L                                 64000020
* MESSAGE MANIPULATION EQUATES                                          64100020
MSGLISTL EQU   *-LNOROOM                                                64200020
DWD      EQU   8                        DOUBLE WORD LENGTH              64500020
 EJECT                                                                  64800020
*********************************************************************** 65200020
* MACROS TO GENERATE PARAMETER CONTROL LIST AND PROVIDE SYMBOLIC      * 65600020
* REFERENCE TO PARAMETER DESCRIPTOR LIST.                             * 66000020
*********************************************************************** 66400020
 SPACE                                                                  66800020
IKJEBVE0 IKJPARM DSECT=VERFYPDL                                         67200020
OPERAND  IKJKEYWD DEFAULT='ON'                                          67600020
         IKJNAME 'ON'                                                   68000020
         IKJNAME 'OFF'                                                  68400020
         IKJENDP                                                        68800020
 EJECT                                                                  69200020
         IKJEBECA                                                       69600020
 EJECT                                                                  70000020
         IKJPPL                                                         70400020
IKJEBEVE CSECT                          RESUME PROGRAM CSECT            70800020
*********************************************************************** 71200020
*                             EQUATES                                 * 71600020
*********************************************************************** 72000020
 SPACE                                                                  72400020
* REGISTERS -                                                           72800020
 SPACE                                                                  73200020
PARMREG0 EQU   0        NOT USED                                        73230020
PARMREG1 EQU   1        PARAMETER REGISTER                              73260020
WORKREG  EQU   3        WORK REGISTER                                   73290020
PDLBASE  EQU   4        BASE REGISTER FOR PDL                           73320020
COMMREG  EQU   9        BASE REGISTER FOR EDIT COMMUNICATION AREA       73350020
BASEREG  EQU   11       GENERAL BASE REGISTER                           73380020
DATAREG  EQU   12       NOT USED                                        73410020
SAVEREG  EQU   13       NOT USED                                        73440020
RETREG   EQU   14       NOT USED                                        73470020
RETCDREG EQU   15       RETURN CODE REGISTER                            73500020
 SPACE                                                                  76000020
* CONSTANTS -                                                           76400020
WORD     EQU   4        FOUR BYTES                                      76600020
ONE      EQU   1        CONSTANT OF ONE                                 76800020
ON       EQU   X'01'    BIT MASK                                        77000020
VEALL    EQU   X'FF'    BIT MASK                                        77200020
EIGHT    EQU   8        CONSTANT OF 8                                   77250020
 SPACE                                                                  77600020
* MESSAGE NUMBERS -                                                     78000020
 SPACE                                                                  78400020
         IKJEBEMI (312,313)                                             78800020
 SPACE                                                                  79200020
         END                                                            79600020
