         TITLE 'IKJEGASN, ''ASSIGN'' SUBCOMMAND OF TEST'                00010020
*********************************************************************** 00020020
*                                                                     * 00030020
* STATUS--                                                            * 00040020
*    VERSION NUMBER 01, OS/360 RELEASE 21                             * 00050021
*                                                                     * 00060020
* FUNCTION--                                                          * 00070020
*    THIS MODULE WILL REPLACE THE CONTENTS OF USER DESIGNATED AREAS   * 00080020
*    OF CORE STORAGE OR REGISTERS WITH VALUES SUPPLIED BY THE USER.   * 00090020
*    CORE STORAGE AREAS ARE PATCHED USING AN 'MVC' INSTRUCTION AND    * 00100020
*    REGISTER CONTENTS ARE MODIFIED BY CALLING SVC 97 (DECIMAL) TO DO * 00110020
*    THE ACTUAL DATA INSERTION.                                       * 00120020
*                                                                     * 00130020
* ENTRY POINTS--                                                      * 00140020
*         IKJEGASN  MAIN ENTRY POINT, ENTERED FROM IKJEGPCH BY AN XCTL* 00150020
*                                                                     * 00160020
* INPUT--                                                               00170020
*    PCHWORK   THE ASSIGNMENT COMMAND WORKAREA INITIALIZED BY         * 00182020
*    MODULE IKJEGPCH AND CONTAINING THE FIRST OR ONLY VALUE PDE AND   * 00184020
*    THE NECESSARY VARIABLES TO PREFORM THE PATCH.                    * 00186020
*                                                                     * 00190020
* OUTPUT--                                                            * 00200020
*    THE CONVERTED VALUE IN THE REQUESTED CORE STORAGE LOCATION OR    * 00210020
*    REGISTER.                                                        * 00220020
*                                                                     * 00230020
* EXTERNAL REFERENCES--                                               * 00240020
*         IKJEGCVT FOR CONVERSION OF ADDRESSES TO BINARY AND VALUES TO* 00250020
*         THE MACHINE FORMAT OF THE TYPE SPECIFIED.                   * 00260020
*         IKJEGI01 FOR OUTPUTTING MESSAGES.                           * 00270020
*                                                                     * 00280020
* EXITS, NORMAL--                                                     * 00290020
*         BRANCH REGISTER 14 RETURNING TO CALLER WITH A CONDITION CODE* 00300020
*         OF ZERO FOR SUCCESSFUL COMPLETION OR DIAGNOSTIC ERROR AND A * 00310020
*         RETURN CODE OF SIXTEEN (16) IF AN ATTENTION HAS BEEN        * 00320020
*         SCHEDULED.                                                  * 00322020
*                                                                     * 00330020
* EXITS, ERROR--                                                      * 00340020
*         BRANCH REGISTER 14 RETURNING TO CALLER WITH A CONDITION CODE* 00350020
*         OF TWENTY (20) FROM THE STAE RETRY ROUTINE AFTER AN ABEND.  * 00360020
*                                                                     * 00370020
* TABLES/WORK AREAS --                                                * 00380020
*    1 TCOMTAB, POINTED AT BY REG 9 IS THE TEST COMMUNICATIONS TABLE  * 00390020
*    2 PCHWORK, A DESECT WHICH DESCRIBES PART OF THE COMMON WORKING   * 00400020
*    CORE MAINTAINED BY TEST AND POINTED AT BY 'WORKAREA' IN TCOMTAB. * 00410020
*    3 PARAMETER DESCRIPTOR LIST (PDL) PREPARED BY IKJPARSE TO        * 00420020
*    DESCRIBE THE VARIOUS FIELDS OF THE PARSED SUBCOMMAND             * 00430020
*                                                                     * 00440020
* ATTRIBUTES--                                                        * 00450020
*    REENTRANT, REFRESHABLE, PROBLEM PROGRAM.                         * 00460020
*                                                                     * 00470020
* CHARACTER CODE DEPENDENCY--                                         * 00480020
*    OPERATION OF THIS MODULE REQUIRES AND DEPENDS ON THE BIT         * 00490020
*    PATTERNS AND BINARY VALUES OF THE EBCDIC CHARACTER SET.          * 00500020
*    THE DEPENDENCY IS IN TABLE 'PCHTRTBL'. OTHER PORTIONS OF         * 00510020
*    THE MODULE REQUIRE ONLY REASSEMBLY FOR CHANGE OF CODE.           * 00520020
*                                                                     * 00530020
* NOTES--                                                             * 00540020
*    THIS MODULE REQUIRES THE STANDARD INSTRUCTION SET.               * 00550020
*                                                                     * 00560020
*********************************************************************** 00570020
IKJEGASN CSECT                                                          00580020
*RELEASE 21 CHANGES                                                     00582021
*A  005820-005844,011820,111203-111512                           A43335 00584021
*D  111205-111445                                                A43335 00584421
*A  005864-005884                                                A53662 00586421
*C  111497                                                       A53662 00588421
         SPACE                                                          00590020
*  REGISTER EQUATES.                                                    00600020
         SPACE                                                          00610020
R0       EQU   0                   REGISTER EQUATE                      00620020
R1       EQU   1                   PARAMETER REGISTER                   00630020
R2       EQU   2                   REGISTER EQUATE                      00640020
R3       EQU   3                   REGISTER EQUATE                      00650020
R4       EQU   4                   REGISTER EQUATE                      00660020
R5       EQU   5                   REGISTER EQUATE                      00670020
R6       EQU   6                   REGISTER EQUATE                      00680020
R7       EQU   7                   REGISTER EQUATE                      00690020
R8       EQU   8                   REGISTER EQUATE                      00700020
R9       EQU   9                   BASE REG FOR TCOMTAB, COMM. DSECT    00710020
R10      EQU   10                  INTERNAL LINK REG FOR THIS MODULE    00720020
R11      EQU   11                  BASE REG FOR THIS PROGRAM.           00730020
R12      EQU   12                  *                                    00740020
R13      EQU   13                  PTR TO CURRENT SAVE AREA.            00750020
R14      EQU   14                                                       00760020
R15      EQU   15                                                       00770020
         SPACE 2                                                        00780020
*  DATA EQUATES FOR OPERANDS OF IMMEDIATE TYPE INSTRUCTIONS.            00790020
         SPACE                                                          00800020
NULL     EQU   0                   USED FOR BALR R,0 AND BCTR R,0.      00810020
ZERO     EQU   0                                                        00820020
ONE      EQU   1                   SYMBOLIC FOR THE NUMBER 1            00830020
TWO      EQU   2                   SYMBOLIC FOR THE NUMBER '2'          00840020
THREE    EQU   3                   SYMBOLIC FOR THE QUANTITY '3'        00850020
FOUR     EQU   4                                                        00860020
EIGHT    EQU   8                                                        00870020
TWELVE   EQU   12                  SYMBOLIC FOR VALUE 12, GENERAL USE   00872020
SIXTEEN  EQU   16                                                       00880020
TWENTY   EQU   20                  VALUE FOR COMPARE                    00890020
B1       EQU   1                   USED AS A SHIFT VALUE TO DIVIDE BY 2 00900020
R5OFF    EQU   40                  OFFSET INTO SAVE AREA FOR REG 5      00910020
R10OFF   EQU   60                  OFFSET INTO SAVE AREA FOR R10        00920020
PLUS     EQU   C'+'                USED IN IMMEDIATE OPERANDS           00930020
MINUS    EQU   C'-'                USED IN IMMEDIATE OPERANDS           00940020
QUOTE    EQU   C''''               USED FOR SCANNING CHAR STRINGS.      00950020
ODD      EQU   X'01'               FOR TESTING WHETHER AN ADDR IS ODD.  00960020
TESTSVC  EQU   97                  SVC NUMBER FOR THE TEST SVC.         01010020
M2OFFSET EQU   80                  OFFSET INTO BUFFER FOR 2ND LEVEL MSG 01020020
LL00IDL  EQU   14                  LENGTH OF LL00 AND ID FLDS OF MSG    01030020
BDYOSET  EQU   M2OFFSET+LL00IDL    OFFSET FOR MOVING BDY TYPE TO MSG    01040020
TOFFSET  EQU   0                   OFFSET TO TYPE FLD OF MSG (LENERR)   01042020
VOFFSET  EQU   2                   OFFSET TO VALUE STRING IN MSG        01044020
CGRPLEN  EQU   64                  QUANTITY OF CHAR DATA FOR ONE GROUP  01050020
         SPACE                                                          01060020
FOREPTR  EQU   8                   OFFSET TO FOREWARD PTR IN SAVE AREA  01070020
BACKPTR  EQU   4                   OFFSET TO BACKWARD PTR IN SAVE AREA  01080020
CONLNTH  EQU   0                   OFFSET INTO CONVERT OUTPUT FOR LNTH  01090020
CONDATA  EQU   1                   OFFSET INTO CONVERT OUTPUT FOR DATA  01100020
GRPCH    EQU   X'04'               CODE FOR PATCHING GENERAL REGS       01110020
FPPCH    EQU   X'02'               CODE FOR PATCHING FLT PT REGS        01120020
         SPACE                                                          01130020
LOTOHI   EQU   24                  SHIFT VALUE TO GET LOW BYTE TO HIGH  01140020
LOGONBIT EQU   X'40'               FOR TESTING AND ECB FOR LOGON POSTED 01150020
DWBDY    EQU   B'00000111'         USED TO TEST ADDRS FOR DBL WRD BDY.  01160020
FWBDY    EQU   B'00000011'                                FULL          01170020
HWBDY    EQU   B'00000001'                                HALF          01180020
INSTRLEN EQU   B'11000000'  FOR TESTING 1ST 2 BITS OF OP CODE    A43335 01182021
         SPACE                                                          01190020
HEXFF    EQU   X'FF'                                                    01200020
ATTNBIT  EQU   B'01000000'                                              01210020
         SPACE                                                          01220020
*  THE FOLLOWING TABLE CONTAINS THE INTERNAL ASSEMBLER TYPE CODES.      01230020
         SPACE                                                          01240020
CHARCODE EQU   X'00'               TYPE ATTRIBUTE =CHAR                 01250020
HEXCODE  EQU   X'04'                ''     ''     =HEXADECIMAL          01260020
BINCODE  EQU   X'08'                ''     ''     =BINARY               01270020
FCODE    EQU   X'10'                ''     ''     =FIXED PT, FULLWORD   01280020
HCODE    EQU   X'14'                ''     ''       ''   '', HALFWORD   01290020
ECODE    EQU   X'18'                ''     ''     =FLT PT, FULLWORD     01300020
DCODE    EQU   X'1C'                ''     ''      ''  '', DBL WORD     01310020
AQCODE   EQU   X'20'                ''     ''     =A AND Q ADDR CONST   01320020
YCODE    EQU   X'24'                ''     ''     =Y ADDR CONST         01330020
SCODE    EQU   X'28'                ''     ''     =S ADDR CONST         01340020
VCODE    EQU   X'2C'                ''     ''     =V ADDR CONST         01350020
PACKCODE EQU   X'30'                ''     ''     =PACKED DECIMAL       01360020
ZONECODE EQU   X'34'                ''     ''     =ZONED DECIMAL        01370020
         SPACE                                                          01380020
*  SYMBOLIC OFFSETS INTO THE MESSAGE CSECT FOR VARIOUS MESSAGE ADCONS.  01390020
         SPACE                                                          01400020
MFACTOR  EQU   8                   MULTIPLIER TO GET OFFSET INTO MSG CT 01410020
PCHMSG00 EQU   0*MFACTOR           1ST MSG IN MSG CSECT                 01420020
PCHMSG01 EQU   1*MFACTOR           2ND     ''                           01430020
PCHMSG02 EQU   2*MFACTOR           3RD     ''                           01440020
PCHMSG03 EQU   3*MFACTOR           4TH     ''                           01450020
PCHMSG04 EQU   4*MFACTOR           5TH     ''                           01452020
PCHMSG05 EQU   5*MFACTOR           6TH     ''                           01454020
         EJECT                                                          01460020
*  SYMBOLIC OFFSETS INTO A VALUE PDE.                                   01470020
         SPACE                                                          01480020
PDEXADRP EQU   0                   PTR TO EXP VALUE    4 BYTES LONG     01490020
PDEXLEN1 EQU   PDEXADRP+4          LENGTH OF EXP VALUE 2                01500020
PDEXFLG1 EQU   PDEXLEN1+4          FLAG BYTE ONE       1                01510020
PDEXSIGN EQU   PDEXFLG1+1          SIGN FOR THIS VALUE 1                01520020
PDEXINDC EQU   PDEXSIGN+1          LEVELS OF INDIRECT  2                01530020
PDEXPTR1 EQU   PDEXINDC+2          PTR TO NEXT EXP     4                01540020
         SPACE 3                                                        01550020
DECEXP   EQU   B'00000100'         IF EXPRESSION IS DECIMAL             01560020
HEXEXP   EQU   B'00000010'         IF EXPRESSION IS HEX                 01610020
PDEVALPT EQU   0                   PTR TO DATA STRING  4 BYTES LONG     01620020
PDEVALEN EQU   PDEVALPT+4          LENGTH OF STRING    2                01630020
PDEVALFG EQU   PDEVALEN+2          FLAG BYTE ONE       1                01640020
PDEVALTP EQU   PDEVALFG+1          ASSEMBLER TYPE      1                01650020
PDEVALNX EQU   PDEVALTP+1          PTR TO NEXT IF LIST 4                01660020
LVALPDE  EQU   PDEVALNX+4          LENGTH OF A VALUE PDE                01670020
         TITLE 'IKJEGASN, ''ASSIGN'' SUBCOMMAND OF TEST, INITIALIZE'    01680020
*********************************************************************** 01690020
*                                                                     * 01700020
*  BEGIN WITH THE STANDARD LINKAGE CONVENTIONS.                       * 01710020
*                                                                     * 01720020
*********************************************************************** 01730020
PATCH    SAVE  (14,12),,*                                               01740020
         LR    R11,R15             PICK UP ENTRY POINT ADDR FOR BASE    01750020
         USING IKJEGASN,R11                                             01760020
         USING TCOMTAB,R9                                               01770020
         L     R6,REGSAVE2         ADDR OF SAVE AREA                    01780020
         ST    R6,FOREPTR(R13)     FORWARD AND BACKWARD CHAIN           01790020
         ST    R13,BACKPTR(R6)         THE SAVE AREAS.                  01800020
         LR    R13,R6              SET PTR TO NEW SAVE AREA             01810020
         SPACE                                                          01820020
         L     R10,WORKAREA        GET PTR TO WORKING CORE              01830020
         USING TSTCWORK,R10                                             01840020
         LA    R10,CWORKCMD        SET UP BASE OF SUB-CMD WORK CORE     01850020
         USING PCHWORK,R10                                              01860020
         SPACE                                                          01870020
*  SET UP THE ABEND VECTOR TABLE.                                       01880020
         SPACE                                                          01890020
         LA    R15,PCHABEND        GET ADDR OF ABEND VECTOR TABLE       01900020
         ST    R15,ABENTAB1        SET UP TCOMTAB PTR TO ABEND VECTOR   01910020
         SPACE                                                          01920020
*                                                                       01930020
*        ISSUE STAE MACRO                                               01940020
*                                                                       01950020
         NI    TSTFLGS2,HEXFF-TSTXCTL  TURN OFF XCTL IN PROGRESS SW     01952020
         MVC   TSTRETRY+ONE(THREE),RETRYAD+ONE  MOVE ADDR TO TCOMTAB    01960020
         LA    R1,STAELIST         PTR TO LIST FORM MACRO               01970020
         L     R2,TSTSTAE          PTR TO TEST STAE MODULE              01980020
         STM   R10,R12,R10OFF(R13)    SAVE BASE PTR                     01990020
         STAE  (R2),CT,MF=(E,(R1))                                      02000020
         LTR   R15,R15             TEST RETURN CODE                     02010020
         BZ    PCH020              CONTINUE IF ZERO                     02020020
         B     PRC16               PRINT ERROR MESSAGE IF SO            02050020
         SPACE                                                          02150020
*********************************************************************** 02200020
*                                                                     * 02250020
*  AT THIS POINT, INITIALIZATION IS COMPLETE. THE PCHWORK DSECT HAS   * 02300020
*  BEEN SET UP BY IKJEGPCH AND PROCESSING MAY BEGIN.                  * 02350020
*        NEXT, TEST FOR THE 3 SPECIAL TYPES OF C, X, AND Z. IF NONE   * 02400020
*        OF THESE, FALL THROUGH AND GO TO CONVERT.                    * 02450020
*********************************************************************** 02500020
PCH020   EQU   *                                                        02520020
         CLI   VPDE+PDEVALTP,HEXCODE   IS THE TYPE HEX                  02530020
         BE    XTYPE               IF HEX, BRANCH                       02540020
         CLI   VPDE+PDEVALTP,CHARCODE  IS THE TYPE CHARACTER            02540420
         BE    CTYPE               IF CHARACTER, BRANCH                 02540820
         CLI   VPDE+PDEVALTP,ZONECODE  IS THE TYPE ZONED DECIMAL        02540920
         BE    ZTYPE               IF ZONED, BRANCH                     02541020
         SPACE                                                          02541420
*  TYPE WAS NOT ONE OF THE SPECIAL 3.  NEXT GO CONVERT THE VALUE.       02541820
*  REGISTERS MUST BE SET UP AS FOLLOWS.                                 02541920
*        0     SET TO ZERO TO SHOW CONVERT TO BINARY                    02542020
*        1     POSITIVE ADDR OF THE VALUE PDE                           02542420
*        14    LINK REGISTER                                            02542820
*        15    ENTRY POINT OF CONVERT ROUTINE                           02542920
         SPACE                                                          02543020
         SR    R0,R0               REG 0 TO ZERO                        02543420
         LA    R1,VPDE             REG 1 = ADDR OF VALUE PDE            02543820
         L     R15,TSTCONVT        GET ADDR OF CONVERT ROUTINE          02543920
         SPACE                                                          02544020
         BALR  R14,R15             GO CONVERT A VALUE                   02546020
         LTR   R15,R15             IS RETURN CODE ZERO                  02548020
         BNZ   CVTRC               IF NON ZERO, BRANCH                  02550020
         SPACE                                                          02560020
         IC    R15,VPDE+PDEVALTP   GET INPUT FORMAT TYPE                02560420
         B     TYPEBTBL(R15)       GO TO PROPER ADDRESS ANALYSIS RTN    02560820
         SPACE                                                          02560920
         ORG   *-BINCODE           ELIMINATE SPACE FOR C AND X CODES    02561020
TYPEBTBL EQU   *                                                        02563020
         ORG   *+BINCODE           RESET LOCATION CTR FOR BRANCH TABLE  02565020
         B     BTYPE               CODE X'08' FOR BINARY                02567020
         B     XTYPE               CODE X'0C' THIS CODE NOT USED.       02569020
         B     FTYPE               CODE X'10' FOR FULLWORD FIXED PT     02569420
         B     HTYPE               CODE X'14' FOR HALFWORD FIXED PT     02569820
         B     ETYPE               CODE X'18' FOR SHORT FLT PT          02569920
         B     DTYPE               CODE X'1C' FOR LONG FLT PT           02570020
         B     AQTYPE              CODE X'20' FOR A AND Q ADDR CNSTNTS  02580020
         B     YTYPE               CODE X'24' FOR Y ADDR CONSTANTS      02590020
         B     STYPE               CODE X'28' FOR S ADDR CONSTANTS      02600020
         B     VTYPE               CODE X'2C' FOR V ADDR CONSTANTS      02610020
         B     PTYPE               CODE X'30' FOR PACKED DECIMAL        02620020
         TITLE 'IKJEGASN, ''ASSIGN'' SUBCOMMAND OF TEST, MAIN PROCESS'  02630020
PCH038   EQU   *                                                        02640020
BTYPE    EQU   *                                                        02650020
PTYPE    EQU   *                                                        02660020
         TM    A1TYPE,GENR+SFPR+LFPR   IS ADDRESS TYPE REGISTER         02670020
         BNZ   REGADDR             IF ADDR IS REG TYPE, BRANCH          02680020
PCH040   EQU   *                                                        02690020
         SR    R2,R2               CLEAR REG 2                          02700020
         L     R1,CONAREA          GET PTR TO DATA AREA                 02710020
         IC    R2,CONLNTH(R1)      GET LNTH OF DATA TO BE MOVED         02720020
         BAL   R14,PCHMOVE         GO TO MOVE DATA ROUTINE              02730020
PCH044   EQU   *                                                        02740020
         TM    VPDE+PDEVALNX,HEXFF IS THERE ANOTHER VALUE TO PROCESS    02750020
         BO    PCHRET1             IF NO MORE VALUES, BRANCH            02760020
         L     R3,A1               GET LAST OUTPUT ADDR                 02770020
         LA    R3,ONE(R2,R3)       INCRE OUTPUT ADDR BY LAST DATA LNTH  02780020
         ST    R3,A1                                                    02790020
         SPACE                                                          02800020
*  IF MORE VALUES, RESET AND GO BACK FOR NEXT                           02810020
         SPACE                                                          02820020
PCH046   EQU   *                                                        02830020
         L     R4,VPDE+PDEVALNX    GET ADDR OF NEXT VALUE PDE           02840020
         MVC   VPDE(LVALPDE),ZERO(R4)  MOVE NEXT VALUE PDE TO DSECT     02850020
         OI    TSTFLGS1,PCHLSTVL   TURN ON THE LIST OF VALUES SW        02860020
         B     PCH020              GO BACK THROUGH PROCESS              02870020
         SPACE                                                          02900020
*  TURN OFF SWITCHES USED BY PATCH.                                     02910020
         SPACE                                                          02920020
PCHRET1  EQU   *                                                        02922020
         NI    TSTFLGS1,HEXFF-PCHLSTVL-TSTFIRST                         02930020
         L     R15,PCHRETCD        PICK UP PRESET RETURN CODE.          02940020
         L     R13,BACKPTR(R13)    GET ADDR OF PREVIOUS SAVE AREA.      02950020
         RETURN  (14,12),T,RC=(15) RETURN TO THE CALLER                 02960020
         SPACE                                                          02960420
CVTRC    EQU   *                                                        02960820
         CH    R15,HSIXTEEN        IS THE RETURN CODE 16                02961220
         BE    PCHCC16             IF RC=16, BRANCH TO RC=16 RTN.       02961620
         B     PCHRET1             OTHERWISE, BRANCH TO WRAPUP RTN.     02961720
         SPACE                                                          02962020
PCHCC16  EQU   *                                                        02964020
         LA    R15,SIXTEEN         SETUP A RETURN CODE OF 16.           02966020
         ST    R15,PCHRETCD        STORE RETURN CODE IN RC FIELD.       02968020
         B     PCHRET1             GO RETURN TO CALLER                  02968420
         EJECT                                                          02970020
*********************************************************************** 02980020
*                                                                     * 02990020
*  THE ADDRESS HAS NOW BEEN DETERMINED TO BE A CORE TYPE AND THE DATA * 03000020
*  HAS BEEN CONVERTED TO ITS PROPER CORE FORMAT. THE FOLLOWING CODE   * 03010020
*  WILL--                                                             * 03020020
*                                                                     * 03030020
*        1. INITIALIZE THE REGISTERS TO MOVE THE DATA TO ITS PROPER   * 03040020
*           LOCATION.                                                 * 03050020
*        2. TEST FOR AN ATTENTION POSTED.                             * 03060020
*        3. TEST FOR  A SCHEDULED LOGOFF.                             * 03070020
*        4.  REMOVE ANY BREAKPOINT SVC'S FROM THE TARGET AREA AND     * 03072020
*            FLAG THE BREAK ELEMENTS INACTIVE.                        * 03074020
*        5. MOVE THE DATA TO THE REQUESTED LOCATION USING AN EX INSTR * 03080020
*                                                                       03090020
*        AT ENTRY,  R1  POINTS TO THE INPUT DATA ADDR MINUS ONE (1).  * 03100020
*                   R2  CONTAINS THE LENGTH OF DATA TO BE MOVED       * 03110020
*                   R14 CONTAINS THE RETURN ADDRESS.                  * 03120020
*                   A1  CONTAINS THE OUTPUT AREA ADDRESS              * 03130020
*                                                                     * 03140020
*********************************************************************** 03150020
PCHMOVE  EQU   *                                                        03160020
         LR    R7,R14              SAVE REG 14                          03162020
         BCTR  R2,NULL             DECREMENT LNTH FOR THE MVC INSTR     03180020
         SPACE                                                          03190020
         L     R3,ECBTMPA          PICKUP ADDR OF ATTENTION ECB.        03200020
         TM    ZERO(R3),ATTNBIT    IS AN ATTENTION POSTED               03210020
         BO    PCHCC16             BRANCH IF AN ATTENTION WAS POSTED    03220020
         L     R3,ECBLOG           GET PTR TO THE LOGON/LOGOFF ECB      03230020
         TM    ZERO(R3),LOGONBIT   IS LOGOFF SCHEDULED                  03240020
         BO    PCHCC16             IF LOGOFF SCHEDULED, BRANCH          03250020
         BAL   R14,ASNBPT          GO REMOVE BREAKPTS AND BRK ELEMENTS  03260020
         LTR   R15,R15             TEST RETURN CODE FROM BRK-PT RTN     03262020
         BNZ   CVTRC               IF RETURN CODE IS NON-ZERO, BRANCH   03264020
         L     R15,A1              GET A PTR TO THE OUTPUT AREA.        03266020
         EX    R2,DATAMVC1         MOVE DATA TO REQUESTED LOCATION.     03270020
PCHABND1 EQU   *                   MARK ADDRESS OF POTENTIAL ABEND      03280020
         SPACE                                                          03290020
         LR    R14,R7              RESTORE REG 14                       03302020
         BR    R14                 RETURN TO CALLER                     03304020
         EJECT                                                          03310020
*********************************************************************** 03320020
*                                                                     * 03330020
*  THE FOLLOWING ROUTINE PROCESSES DATA STRINGS FOR ZONED TYPE VALUES * 03340020
*  THE ROUTINE PROCESSES THE STRINGS AS FOLLOWS.                      * 03350020
*        1. DETERMINE WHETHER A SIGN WAS SPECIFIED AND SET UP TO USE  * 03360020
*           IT.  ADJUST DATA LENGTH AND PTR IF NECESSARY.             * 03370020
*        2. MOVE DATA TO CONAREA AND RETURN TO MAIN ROUTINE.          * 03380020
*                                                                     * 03390020
*********************************************************************** 03400020
         SPACE                                                          03410020
ZTYPE    EQU   *                                                        03420020
         LA    R4,NEGZONE          SET UP PTR TO A NEGATIVE ZONE.       03430020
         LH    R2,VPDE+PDEVALEN    GET THE LENGTH OF DATA STRING        03440020
         L     R15,VPDE+PDEVALPT   GET ADDR OF START OF DATA STRING     03450020
         CLI   ZERO(R15),MINUS     DOES STRING BEGIN WITH A MINUS SIGN  03460020
         BE    SIGN                IF SO, GO ADJUST PTRS FOR SIGN.      03470020
         LA    R4,POSZONE          RESET PTR TO A POSITIVE ZONE         03480020
         CLI   ZERO(R15),PLUS      DOES STRING BEGIN WITH A PLUS SIGN   03490020
         BNE   NOSIGN              IF NOT, SKIP SETUP FOR SIGN.         03500020
SIGN     EQU   *                                                        03510020
         LA    R15,ONE(R15)        INCRE DATA PTR PAST SIGN.            03520020
         BCTR  R2,NULL             DECREMENT LENGTH BY 1 FOR SIGN       03530020
         SPACE                                                          03540020
NOSIGN   EQU   *                                                        03550020
         L     R1,CONAREA          GET ADDR OF CONVERT WORK AREA.       03560020
         STC   R2,CONLNTH(R1)      SET LENGTH OF CONVERTED CONSTANT     03570020
         BCTR  R2,NULL             REDUCE LENGTH FOR MVC INSTR.         03580020
         EX    R2,DATAMVC2         MOVE DATA TO CONAREA.                03590020
         LA    R1,CONDATA(R2,R1)   INCREMENT PTR TO LAST BYTE OF CON.   03600020
         MVZ   ZERO(ONE,R1),ZERO(R4)   MOVE CORRECT ZONE (SIGN) TO CON. 03610020
         B     PCH038              GO PERFORM PATCH                     03620020
         EJECT                                                          03630020
*********************************************************************** 03640020
*                                                                     * 03650020
*  THIS ROUTINE CHECKS BOUNDARY ALIGNMENT AND ADDRESS TYPE FOR        * 03660020
*  FULLWORD TYPE CONSTANTS (A, E, F, Q, AND V).                       * 03670020
*                                                                     * 03680020
*********************************************************************** 03690020
         SPACE                                                          03700020
AQTYPE   EQU   *                                                        03710020
ETYPE    EQU   *                                                        03720020
FTYPE    EQU   *                                                        03730020
VTYPE    EQU   *                                                        03740020
         TM    A1TYPE,SFPR         IS ADDR SINGLE PREC FLT PT REG       03750020
         BO    ETYP10              IF YES, GO CHECK THAT TYPE IS 'E'    03760020
         TM    A1TYPE,LFPR         IS ADDR DBL PREC FLT PT REG          03770020
         BO    DTYPE20             IF YES, GO TO ERR RTN.               03780020
         TM    A1TYPE,GENR         IS ADDR A GENERAL REGISTER           03790020
         BNO   BDYFWTST            IF NOT, GO CHECK BDY FOR CORE PATCH  03800020
REGINCRF EQU   *                                                        03810020
         L     R15,GRDATA          GET CONSTANTS FOR GEN REGS.          03820020
         MVI   PPTCB,GRPCH         SET CODE FOR A GENERAL REG PATCH     03830020
REGPCH   EQU   *                                                        03840020
         ST    R15,ADDRINCR        STORE CONSTANTS IN TEST AREA.        03850020
         L     R1,CONAREA          SET UP ADDR OF CONVERT AREA.         03860020
         L     R2,A1               GET REGISTER ADDR TO BE PATCHED      03870020
         LA    R1,CONDATA(R1)      INCRE DATA PTR PAST LENGTH           03880020
         SLL   R2,LOTOHI           SHIFT REG NO. TO HIGH ORDER BYTE     03890020
         OR    R1,R2               PLACE REG ADDR IN BYTE 0 OF REG 1.   03900020
         BAL   R14,CALLSVC         GO ISSUE SVC TO PATCH REG IN TCBREGS 03910020
         TM    VPDE+PDEVALNX,HEXFF ARE THERE MORE VALUES TO PROCESS     03920020
         BO    PCHRET1             IF NO MORE VALUES, BRANCH            03930020
         L     R2,A1               GET REGISTER NUMBER JUST PATCHED     03940020
         AH    R2,ADDRINCR         ADD  THE ADDR INCREMENT              03950020
         CH    R2,MAXRADDR         IS UPDATED REG  NO. GREATER THAN MAX 03960020
         ST    R2,A1               SAVE UPDATED ADDR, ANTICIPATING OK   03970020
         BNH   PCH046              IF REG NO. NOT GT MAX, BRANCH        03980020
         SR    R2,R2               OTHER WISE, RESET ADDR TO ZERO       03990020
         ST    R2,A1               SAVE RESET REG ADDRESS               04000020
         B     PCH046              GO PROCESS NEXT VALUE                04010020
         SPACE                                                          04012020
ETYP10   EQU   *                                                        04014020
         TM    VPDE+PDEVALTP,ECODE IS DATA TYPE 'E'                     04016020
         BO    REGINCRE            IF 'E', BRANCH                       04018020
ETYP20   EQU   *                                                        04018420
         LA    R15,PCHMSG02        SET UP OFFSET TO MSG ADCONS          04018820
         B     TYPERR              GO TO THE DATA TYPE ERROR MSG RTN    04019220
         EJECT                                                          04020020
*********************************************************************** 04030020
*                                                                     * 04040020
*  THE FOLLOWING CODE TESTS FOR AN ATTENTION, ISSUES SVC 97, AND      * 04050020
*  ANALYZES THE RETURN CODE.                                          * 04060020
*                                                                     * 04070020
*********************************************************************** 04080020
         SPACE                                                          04090020
CALLSVC  EQU   *                                                        04100020
         SAVE  (14,12)             SAVE CALLER REGS                     04110020
         L     R0,PPTCB            PICK UP ADDR TYPE BYTE AND TCB ADDR. 04120020
         NI    PPTCB,HEXFF-GRPCH-FPPCH  CLEAR THE HIGH BYTE             04130020
         L     R3,ECBTMPA          GET ADDR OF ATTENTION ECB.           04140020
         TM    ZERO(R3),ATTNBIT    IS AN ATTENTION POSTED               04150020
         BO    PCHCC16             IF YES, GO TO CLEANUP ROUTINE.       04160020
         L     R3,ECBLOG           GET PTR TO LOGON ECB                 04170020
         TM    ZERO(R3),LOGONBIT   IS LOGOFF SCHEDULED                  04180020
         BO    PCHCC16             IF YES, BRANCH                       04190020
         SPACE                                                          04200020
         SVC   TESTSVC             CALL THE SVC RTN TO PATCH REGISTERS  04210020
         SPACE                                                          04220020
         LTR   R15,R15             TEST SVC RETURN CODE FOR ZERO.       04230020
         BNZ   CALLSVC4            IF RETURN CODE NON-ZERO, BRANCH      04240020
         RETURN (14,12)            RESTORE REGS AND RETURN TO CALLER    04250020
         SPACE                                                          04260020
CALLSVC4 EQU   *                                                        04270020
         LA    R15,EIGHT           SETUP A RETURN CODE OF 8.            04280020
         ST    R15,PCHRETCD        STORE IT IN RETURN CODE AREA.        04290020
         B     PCHRET1             GO TO CLEANUP ROUTINE.               04300020
         EJECT                                                          04310020
BDYFWTST EQU   *                                                        04320020
         TM    A1+THREE,FWBDY      TEST IF ADDRESS IS A FULL WORD BDY   04330020
         BZ    PCH040              IF BOUNDARY OK, BRANCH               04340020
         TM    TSTFLGS1,PCHLSTVL   IS VALUE PART OF A LIST OF VALUES    04350020
         BZ    FBDYERR             IF ADDR BDY IS WRONG, GO TO ERR RTN. 04360020
         SPACE                                                          04370020
*********************************************************************** 04380020
*                                                                     * 04390020
*  IF VALUE IS PART OF A LIST OF VALUES, ROUND ADDR UP TO NEXT FULL   * 04400020
*  BOUNDARY BY ADDING 3 THEN ROUNDING DOWN TO AN ADDR THAT ENDS WITH  * 04410020
*  TWO BINARY ZERO'S.                                                 * 04420020
*                                                                     * 04430020
*********************************************************************** 04440020
         SPACE                                                          04450020
         L     R15,A1              GET CURRENT ADDRESS                  04460020
         AL    R15,FTHREE          ADD 3 TO INCRE TO OR PAST NXT F BDY  04470020
         ST    R15,A1              REPLACE ADDRESS                      04480020
         NI    A1+THREE,HEXFF-FWBDY  ROUND ADDR DOWN TO EXACT BDY       04490020
         B     PCH040              GO PATCH A CORE LOCATION             04500020
         SPACE 2                                                        04510020
DTYPE    EQU   *                                                        04520020
         TM    A1TYPE,LFPR         IS ADDR DBL PRECISION FLT PT REG     04530020
         BO    REGINCRD            IF YES, GO SET UP CORRECT CONSTANTS  04540020
         TM    A1TYPE,GENR+SFPR    IS ADDR A 4 BYTE REG TYPE            04550020
         BNZ   LENERR              IF 4 BYTE REG TYPE, BRANCH           04560020
         TM    A1+THREE,DWBDY      IS OUTPUT ADDR ON A DBL WORD BDY     04570020
         BZ    PCH040              IF DBL WORD BDY, BRANCH              04580020
         SPACE                                                          04590020
         TM    TSTFLGS1,PCHLSTVL   IS THIS VALUE PART OF A LIST.        04600020
         BZ    DBDYERR             IF NOT, BRANCH TO ERROR ROUTINE.     04610020
         L     R15,A1              GET ADDR TO BE ROUNDED               04620020
         AL    R15,FSEVEN          INCRE IT TO OR PAST NXT DBL WORD BDY 04630020
         ST    R15,A1              REPLACE ORIGINAL ADDRESS             04640020
         NI    A1+THREE,HEXFF-DWBDY  ROUND ADDR DOWN TO EXACT BDY       04650020
         B     PCH040              GO PATCH AREA OF CORE                04660020
         SPACE                                                          04662020
DTYPE20  EQU   *                                                        04662420
         LA    R15,PCHMSG03        SET UP OFFSET TO MSG ADCONS          04664020
         B     TYPERR              GO TO THE DATA TYPE ERROR MSG RTN    04666020
         SPACE 2                                                        04670020
REGADDR  EQU   *                                                        04680020
         L     R3,CONAREA          GET ADDR OF CONVERT OUTPUT AREA      04690020
         USING CONAREA1,R3                                              04700020
         SR    R2,R2               CLEAR REG AND                        04710020
         IC    R2,CONLNTH+CONAREA1 GET LENGTH OF CONVERTED DATA         04720020
         TM    A1TYPE,LFPR         IS ADDR DBL PRECISION FLT PT REG     04730020
         BO    REGADDR1            IF REG ADDR IS 'D' TYPE, BRANCH      04740020
         CH    R2,HFOUR            COMPARE CONSTANT LENGTH TO 4.        04750020
         BE    REGADDR2            IF EQUAL, GO DETERMINE REG TYPE      04760020
         BH    LENERR              IF HIGH, GO TO ERROR ROUTINE.        04770020
         LCR   R2,R2               MAKE LENGTH NEGATIVE.                04780020
         L     R4,CONDATA+CONAREA1  GET LEFT JUSTIFIED CONSTANT         04790020
         AH    R2,HFOUR            SUBTRACT LENGTH FROM 4.              04800020
         SLL   R2,THREE            MULTIPLY LENGTH BY 8 TO GET BIT LNTH 04810020
         SRL   R4,ZERO(R2)         RIGHT JUSTIFY CONSTANT.              04820020
         ST    R4,CONDATA+CONAREA1 STORE RIGHT JUSTIFIED CONSTANT       04830020
         MVI   CONLNTH+CONAREA1,FOUR  STORE LENGTH IN LNTH FIELD        04840020
REGADDR2 EQU   *                                                        04840420
         TM    A1TYPE,GENR         IS REG TYPE GENERAL REGISTER         04842020
         BO    REGINCRF            IF GENERAL REG, BRANCH               04844020
         CLI   VPDE+PDEVALTP,HEXCODE   IS THE DATA TYPE HEX             04848020
         BE    REGINCRE            IF HEX, BRANCH                       04848420
         B     ETYP20              IF NOT, GO TO ERROR MSG ROUTINE      04848820
         SPACE                                                          04849220
REGADDR1 EQU   *                                                        04880020
         CLI   VPDE+PDEVALTP,HEXCODE   IS THE DATA TYPE HEX             04882020
         BNE   DTYPE20             IF NOT, BRANCH TO ERROR MSG RTN      04884020
         CH    R2,HEIGHT               COMPARE LENGTH TO 8.             04890020
         BE    REGINCRD                IF 8, GO TO REG PATCH ROUTINE.   04900020
         BH    LENERR                  IF GREATER THAN 8, GO TO ERROR.  04910020
         SPACE                                                          04920020
*  IF ADDR IS FOR A DBL PRECISION FLOATING PT REG AND LENGTH IS LESS    04930020
*     THAN 8, RIGHT JUSTIFY THE CONSTANT AND PAD WITH ZEROS.            04940020
         SPACE                                                          04950020
         LCR   R2,R2               MAKE CONSTANT LENGTH NEGATIVE,       04960020
         LM    R4,R5,CONDATA+CONAREA1  PICK UP THE CONVERTED DATA       04970020
         SPACE                                                          04980020
*  THE NEXT INSTRUCTION EFFECTIVELY SUBSTRACTS THE LENGTH FROM 8.       04990020
         SPACE                                                          05000020
         AH    R2,HEIGHT           ADD NEG LENGTH TO PLUS 8.            05010020
         SLL   R2,THREE            MULTIPLY NEG LNTH BY 8 FOR BIT LNTH  05020020
         SRDL  R4,ZERO(R2)         RIGHT JUSTIFY THE CONSTANT           05030020
         STM   R4,R5,CONDATA+CONAREA1  JUSTIFIED/PADDED DATA TO CONAREA 05040020
         MVI   ZERO(R3),EIGHT      SET LENGTH FIELD TO 8.               05050020
REGINCRD EQU   *                                                        05060020
         MVI   PPTCB,FPPCH         SET CODE FOR FLT PT REG PATCH        05070020
         L     R15,FPRDATA         SET CONSTANTS FOR FL PT REGS.        05080020
         B     REGPCH              GO TO REGISTER PATCH ROUTINE.        05090020
         SPACE                                                          05100020
REGINCRE EQU   *                                                        05110020
         OI    A1+THREE,ODD        MAKE REG NUMBER ODD FOR 'E' TYPE     05120020
         B     REGINCRD            GO TO REG PATCH ROUTINE              05130020
         SPACE 3                                                        05140020
         DROP  R3                                                       05150020
         EJECT                                                          05160020
*********************************************************************** 05170020
*                                                                     * 05180020
*  HEX PATCH ROUTINE, DATA IS CONVERTED TO HEX BY IKJEGCVT 4 BYTES    * 05190020
*  AT A TIME. THE LAST OR ONLY FIELD MAY BE LESS THAN 4 BYTES.        * 05200020
*                                                                     * 05210020
*********************************************************************** 05220020
         SPACE                                                          05230020
XTYPE    EQU   *                                                        05240020
         MVC   DUMMYPDE(LVALPDE),VPDE  COPY THE PDE FOR MODIFICATION    05250020
         LH    R2,VPDE+PDEVALEN    GET LNTH OF INPUT STRING             05260020
         L     R15,VPDE+PDEVALPT   GET PTR TO INPUT STRING              05270020
         LR    R4,R2               SAVE THE LENGTH OF THE STRING.       05280020
         BCTR  R2,NULL             REDUCE LENGTH FOR TR INSTR.          05290020
         EX    R2,PCHTR            TRANSLATE TO UPPER CASE.             05300020
         LA    R2,EIGHT            SET LIMIT FOR FIELD LENGTH           05310020
         CR    R4,R2               IS INPUT LENGTH GREATER THAN 8       05320020
         BNH   XTYPE04             IF NOT GREATER THAN 8, BRANCH        05330020
         STH   R2,DUMMYPDE+PDEVALEN  IF LNTH GT 8, CONVERT 8 AT A TIME  05340020
         SPACE                                                          05350020
*  INITIALIZE TO CONVERT A VALUE TO HEX.                                05360020
         SPACE                                                          05370020
XTYPE04  EQU   *                                                        05380020
         L     R2,DUMMYPDE+PDEVALPT  PICK UP PTR TO DATA                05390020
         LA    R5,HOLDAREA+ONE     R5=ADDR OF TEMPORARY HOLDING AREA    05400020
         SR    R0,R0               R0=0                                 05410020
         LA    R1,DUMMYPDE         SET PTR TO VALUE PDE FOR CONVERT     05420020
HEXCVT   EQU   *                                                        05430020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          05440020
         BALR  R14,R15             GO TO CONVERT RTN                    05450020
         LTR    R15,R15            TEST RETURN CODE FROM IKJEGCVT       05460020
         BNZ   CVTRC               IF NON-ZERO, GO ANALYZE              05470020
         L     R15,CONAREA         PICK OF ADDR OF CONVET OUTPUT AREA   05480020
         USING CONAREA1,R15                                             05490020
         LH    R3,DUMMYPDE+PDEVALEN  GET LNTH OF INPUT JUST CONVERTED   05500020
         L     R14,CONAREA1+CONDATA  PICK UP CONVERTED DATA             05510020
         DROP  R15                                                      05520020
         ST    R14,ZERO(R5)        SAVE IT TEMPORARILY IN HOLD AREA     05530020
         SPACE                                                          05540020
*********************************************************************** 05550020
*  IF THERE ARE MORE THAN 8 BYTES OF INPUT, ADJUST THE POINTERS AND   * 05560020
*   CONTINUE IN THIS LOOP UNTIL ALL DATA HAS BEEN PROCESSED.          * 05570020
*********************************************************************** 05580020
         SPACE                                                          05590020
         SR    R4,R3               DECREMENT AMT TO CONVERT BY AMT DONE 05600020
         BZ    XTYPE08             WHEN ALL BYTES ARE CONVERTED, BRANCH 05610020
         AR    R2,R3               INCREMENT PTR TO INPUT DATA FOR NEXT 05620020
         ST    R2,DUMMYPDE+PDEVALPT  STORE UPDATED ADDR IN VALUE PDE    05630020
         LA    R5,FOUR(R5)         INCREMENT CUR HOLD AREA PTR          05640020
         CH    R4,HEIGHT           IS REMAINDER LESS THAN 8.            05650020
         BNL   HEXCVT              IF MORE TO CONVERT, BRANCH           05660020
         STH   R4,DUMMYPDE+PDEVALEN  STORE REMAINING LNTH IN PDE        05670020
         B     HEXCVT              GO CONVERT REMAINING DATA            05680020
REGHEX   EQU   *                                                        05690020
         CH    R3,HEIGHT           IS LENGTH OF CONVERTED DATA GT 8.    05700020
         BNL   LENERR              IF 8 OR GREATER, GO TO ERROR RTN     05710020
         LM    R14,R15,HOLDAREA+ONE  PICK UP CONVERTED DATA             05720020
         SRDL  R14,FOUR            RIGHT JUSTIFY CONSTANT               05730020
         STM   R14,R15,HOLDAREA+ONE  PLACE DATA BACK INTO HOLDING AREA  05740020
         L     R15,CONAREA         GET ADDR OF CONVERT OUTPUT AREA      05750020
         LA    R3,ONE(R3)          INCRMENT LENGTH OF OUTPUT DATA       05760020
         B     NOTODD              GO TO COMMON HEX PREP ROUTINE.       05770020
         SPACE                                                          05780020
*********************************************************************** 05790020
*                                                                     * 05800020
*  THE FOLLOWING ROUTINE IS ENTERED WHEN ALL INPUT BYTES HAVE BEEN    * 05810020
*  CONVERTED TO HEX.                                                  * 05820020
*  AT ENTRY, REG 5 POINTS TO THE NEXT AREA OF HOLDAREA                * 05830020
*            REG 14 CONTAINS THE LAST CONVERTED BYTES                 * 05840020
*            REG 15 POINTS TO THE CONVERT AREA                        * 05850020
*                                                                     * 05860020
*********************************************************************** 05870020
         SPACE                                                          05880020
XTYPE08  EQU   *                                                        05890020
         LH    R3,VPDE+PDEVALEN    GET TOTAL LNTH OF INPUT STRING       05900020
         SRL   R3,B1               DIVIDE LNTH BY 2, DISCARD REMAINDER  05910020
         TM    VPDE+PDEVALEN+ONE,ODD  IS LNTH AN ODD NUMBER OF BYTES    05920020
         BZ    NOTODD              IF NOT, BRANCH                       05930020
         SLL   R14,FOUR            ELIMINATE LEADIN HALF BYTE 0         05940020
         ST    R14,ZERO(R5)        STORE LAST DATA AFTER ADJUSTMENT     05950020
         TM    A1TYPE,GENR+SFPR+LFPR   IS ADDRESS REG TYPE              05960020
         BNZ   REGHEX              IF NOT, TRULY REG, BRANCH            05970020
         L     R2,A1               GET RECIEVING ADDRESS                05980020
         LA    R2,ZERO(R3,R2)      POINT TO LAST BYTE OF TARGET AREA    05990020
         LA    R5,HOLDAREA+ONE     PICK UP ADDR OF HOLDING AREA         06000020
         LA    R4,ZERO(R3,R5)      POINT TO LAST BYTE IN HOLDING AREA   06010020
         SPACE                                                          06020020
*  IF THE NUMBER OF HEX CHARACTERS SUPPLIED IS ODD, GET ONE HEX DIGIT   06030020
*     FROM THE LAST BYTE OF THE TARGET AREA TO FILL OUT THE LAST BYTE   06040020
*         OF PATCH DATA.                                                06050020
         SPACE                                                          06060020
         MVN   ZERO(ONE,R4),ZERO(R2)   MOVE IN 2ND HALF.                06070020
         LA    R3,ONE(R3)          INCREMENT COUNT FOR DATA             06080020
NOTODD   EQU   *                                                        06090020
         L     R15,CONAREA         GET PTR TO CONVERT OUTPUT AREA       06100020
         USING CONAREA1,R15                                             06110020
         STC   R3,CONAREA1         STORE DATA COUNT IN CONVERT LEN FLD  06120020
         BCTR  R3,NULL             DECREMENT COUNT FOR MVC INSTR        06130020
         EX    R3,DATAMVC3         MOVE DATA FROM HOLD TO CONVERT AREA  06140020
         B     PCH038              GO PROCESS DATA.                     06150020
         DROP  R15                                                      06160020
         EJECT                                                          06170020
*********************************************************************** 06180020
*                                                                     * 06190020
*  THE FOLLOWING ROUTINE HANDLES THE TWO BYTE CONSTANTS SUCH AS H, S, * 06200020
*  AND Y.  THE ROUTINE FIRST CHECKS WHETHER THE ADDRESS IS REGISTER OR* 06210020
*  CORE. FOR CORE TYPES THE BOUNDARY ALIGNMENT IS CHECKED AND FOR     * 06220020
*  LISTS OF VALUES, ADJUSTED TO A HALF WORD BOUNDARY.  FOR REGISTER   * 06230020
*  ADDRESSES, A FURTHER CHECK IS MADE TO SEE IF THE CONSTANT TYPE IS  * 06240020
*  'H'.FOR H TYPE CONSTANTS, THE DATA IS EXTENDED TO FULLWORD SIZE TO * 06250020
*  ACCOUNT FOR THE SIGN. S OR Y TYPE CONSTANTS ARE HANDLED AS BYTE    * 06260020
*  CONSTANTS.  FLOATING POINT REGISTER ADDRESSES ARE INVALID.         * 06270020
*                                                                     * 06280020
*********************************************************************** 06290020
         SPACE                                                          06300020
HTYPE    EQU   *                                                        06310020
STYPE    EQU   *                                                        06320020
YTYPE    EQU   *                                                        06330020
         TM    A1TYPE,SFPR         IS ADDRESS A SHORT FLT PT REG TYPE   06340020
         BO    ETYP20              IF YES, BRANCH TO ERROR RTN.         06350020
         TM    A1TYPE,LFPR         IS ADDRESS A LONG FLT PT REG TYPE    06352020
         BO    DTYPE20             IF YES, BRANCH                       06354020
         TM    A1TYPE,GENR         IS ADDRESS A GENERAL REGISTER TYPE   06360020
         BO    HREGADDR            IF GENERAL REGISTER TYPE, BRANCH     06370020
         TM    A1+THREE,HWBDY      IS ADDRESS ON A HALFWORD BDY         06380020
         BZ    PCH040              IF HALF WORD BDY, BRANCH             06390020
         TM    TSTFLGS1,PCHLSTVL   IF DATA PART OF A LIST OF VALUES     06400020
         BNO   HBDYERR             IF NOT, GO TO ERROR TRN              06410020
         SPACE                                                          06420020
*  ADDR HAS BEEN FOUND TO BE A BYTE BDY, AND DATA PART OF A LIST OF   * 06430020
*  VALUES.  THE ADDRESS MUST BE ROUNDED UP TO THE NEXT HALFWORD BDY.  * 06440020
         SPACE                                                          06450020
         L     R15,A1              GET CURRENT ADDRESS                  06460020
         AL    R15,FONE            INCREMENT ADDR TO NEXT HALFWORD BDY  06470020
         ST    R15,A1              SAVE UPDATED ADDR                    06480020
         B     PCH040              GO DO PATCH                          06490020
         SPACE 2                                                        06500020
HREGADDR EQU   *                                                        06510020
         CLI   VPDE+PDEVALTP,HCODE IS THE CONSTANT TYPE 'H'             06520020
         BNE   REGADDR             IF NOT, BRANCH TO BYTE TYPE RTN.     06530020
         L     R3,CONAREA          PICK UP ADDR OF CONVERT OUTPUT AREA  06540020
         USING CONAREA1,R3                                              06550020
         LH    R4,CONAREA1+ONE     LOAD 2 BYTE CONSTANT INTO 4 BYTE REG 06560020
         ST    R4,CONAREA1+ONE     STORE EXTENDED CONSTANT BACK.        06570020
         MVI   ZERO(R3),FOUR       SET CONSTANTS LENGTH TO 4.           06580020
         B     REGINCRF            GO PROCESS AS A FULLWORD CONSTANT.   06590020
         DROP  R3                                                       06600020
         EJECT                                                          06610020
*********************************************************************** 06620020
*  ROUTINE TO HANDLE CHARACTER TYPE DATA.                             * 06630020
*        THIS DATA HAS NO MAXIMUM LENGTH RESTRICTION, AND IF THE INPUT* 06640020
*        DATA STRING IS LONGER THAN 64 BYTES, IT MUST BE PROCESSED    * 06650020
*        IN GROUPS OF 63 OR 64 CHARACTERS AT A TIME. THE GROUP SIZE   * 06660020
*        VARIES TO ALLOW EACH STRING BEING PROCESSED TO CONTAIN ONLY  * 06670020
*        PAIRS OF SINGLE QUOTES--- SINCE SINGLE QUOTES ARE A SPECIAL  * 06680020
*        CASE.                                                        * 06690020
*********************************************************************** 06700020
CTYPE    EQU   *                                                        06710020
         L     R2,VPDE+PDEVALPT    PTR TO INPUT STRING                  06720020
         LH    R3,VPDE+PDEVALEN    LNTH OF INPUT STRING                 06730020
CTYPE04  EQU   *                                                        06740020
         LA    R4,CGRPLEN          SET UP MAX QUANTITY FOR 1 PASS       06750020
         STH   R3,A1L              SAVE ORIGINAL OR REMAINING LENGTH    06760020
         CR    R3,R4               IS LENGTH OF DATA STRING GT MAX      06770020
         BNH   CTYPE20             IF LENGTH NOT GT MAX, BRANCH         06780020
         LR    R3,R4               SET CURRENT LENGTH TO MAX            06790020
         STH   R3,VPDE+PDEVALEN    SAVE LNTH TO BE USED FOR THIS GROUP  06800020
         LA    R5,ZERO(R2,R3)      SET UP PTR TO 1ST BYTE OF NXT GROUP  06810020
         CLI   ZERO(R5),QUOTE      IS THAT CHARACTER A SINGLE QUOTE     06820020
         BNE   CTYPE20             IF NOT, BRANCH                       06830020
         BCTR  R5,NULL             BACK UP PTR TO LAST BYTE OF THIS GRP 06840020
         CLI   ZERO(R5),QUOTE      IS THIS CHARACTER A QUOTE            06850020
         BNE   CTYPE20             IF NOT, BRANCH                       06860020
         SPACE                                                          06870020
*  IF QUOTES EXTEND ACROSS GROUPS, THE FOLLOWING CODE ADJUSTS THE       06880020
*     GROUP LENGTH AS NECESSARY TO INSURE THE GROUP TO BE PROCESSED     06890020
*        CONTAINS ONLY PAIRED SINGLQUOTES. (NO. OF QUOTES/GRP NOT ODD)  06900020
         SPACE                                                          06910020
         LR    R5,R2               GET PTR TO START OF DATA STRING      06920020
         SR    R15,R15             INITIALZE QUOTE COUNTER TO ZERO      06930020
CTYPE08  EQU   *                                                        06940020
         CLI   ZERO(R5),QUOTE      IS THIS DATA CHAR A QUOTE            06950020
         BNE   CTYPE12             IF NOT, BRANCH                       06960020
         LA    R15,ONE(R15)        IF CHAR WAS A QUOTE, INCRE COUNTER   06970020
CTYPE12  EQU   *                                                        06980020
         LA    R5,ONE(R5)          INCRE DATA STRING PTR TO NXT CHAR    06990020
         BCT   R4,CTYPE08          IF MORE CHARACTERS TO CHECK, BRANCH  07000020
         LA    R4,ONE              MAKE A MASK TO ISOLATE LOW ORDER BIT 07010020
         NR    R4,R15              ISOLATE LOW ORDER BIT OF QUOTE COUNT 07020020
         SR    R3,R4               SUBTRACT 1 FROM LNTH IF COUNT ODD    07030020
         STH   R3,VPDE+PDEVALEN    STORE ADJUSTED LENGTH IN PDE         07040020
         B     CTYPE20             BO PROCESS THIS GROUP                07050020
         EJECT                                                          07060020
*********************************************************************** 07070020
*                                                                     * 07080020
*  THE FOLLOWING ROUTINE SCANS CHARACTER CONSTANTS FOR SINGLE QUOTES. * 07090020
*  USERS MUST SPECIFY TWO SINGLE QUOTES FOR EACH ONE DESIRED IN THE   * 07100020
*  OUTPUT. THIS ROUTINE SQUEEZES OUT THE EXTRA QUOTES AND MOVES THE   * 07110020
*  PROCESSED CONSTANT TO THE TEMPORARY HOLD AREA. THE CONVERT AREA IS * 07120020
*  NOT USED BECAUSE THE CONSTANT AFTER PROCESSING MAY BE UP TO 64     * 07130020
*  BYTES LONG. IN THIS ROUTINE, REGS ARE USED AS FOLLOWS--            * 07140020
*        R1    POINTS TO NEXT AVAILABLE BYTE IN HOLDARA.              * 07150020
*        R2    POINTS TO THE NEXT INPUT BYTE TO BE TESTED.            * 07160020
*        R3    CONTIANS VALUE LENGTH, IT IS DECREMENTED 1 FOR EACH '' * 07170020
*        R4    CONAINS INCREMENT FOR BXLE INSTR                       * 07180020
*        R5    CONTAINS COMPAREND FOR BYLE INSTR (PTR TO END OF INPUT * 07190020
*        R14   USED TO CALCULATE NUMBER OF BYTES SCANED               * 07200020
*        R15   POINTS TO BEGINNING BYTE OF CURRENT SCAN.              * 07210020
*                                                                     * 07220020
*********************************************************************** 07230020
         SPACE                                                          07240020
CTYPE20  EQU   *                                                        07250020
         L     R1,CONAREA          GET PTR TO CONVERTED DATA AREA       07260020
         LA    R5,ZERO(R3,R2)      SET UP BXLE COMPAREND AS INPUT ADDR  07270020
         LA    R4,ONE              SET BXLE INSTR INCRE                 07280020
         SR    R5,R4                   + LENGTH OF DATA - 1.            07290020
         LR    R15,R2              SAVE STARTING POINT IN STRING.       07300020
         SPACE                                                          07310020
CLOOP    EQU   *                                                        07320020
         CLI   ZERO(R2),QUOTE      IS THIS CHARACTER A SINGLE QUOTE     07330020
         BE    QUOTEFND            BRANCH IF CHAR=QUOTE                 07340020
CLOOP1   EQU   *                                                        07350020
         BXLE  R2,R4,CLOOP         INCRE STRING PTR, LOOP IF MORE TO DO 07360020
         SPACE                                                          07370020
         LR    R14,R2              CALCULATE NUMBER OF BYTES SCANNED    07380020
         SR    R14,R15                 AS CUR STRING PTR - BEGIN PTR.   07390020
         BZ    DONE                IS RESULT IS 0, BRANCH AROUND MVC.   07400020
         BCTR  R14,NULL            DECRE COUNT FOR MVC INSTR            07410020
         EX    R14,DATAMVC2        MOVE REMAINING DATA TO HOLDAREA      07420020
DONE     EQU   *                                                        07430020
         L     R1,CONAREA          GET PTR TO CONVERTED DATA AREA       07440020
         STC   R3,CONLNTH(R1)      STORE LNTH IN CONVERTED DATA AREA    07450020
         SPACE                                                          07460020
*  SETUP TO DO PATCH BY DETERMINING WHETHER ADDRESS IS REG OR CORE      07470020
         TM    A1TYPE,GENR+SFPR+LFPR   IS ADDRESS TYPE REGISTER         07480020
         LR    R5,R3               GET ADJUSTED DATA LNTH OF LAST PATCH 07490020
         BNZ   REGADDR             IF REGISTER TYPE, BRANCH             07500020
         LR    R2,R3               SET UP LENGTH FOR  THE PCHMOVE RTN   07510020
         BAL   R14,PCHMOVE         GO MOVE DATA                         07520020
         LH    R3,A1L              GET REMAINING LNTH OF DATA STRING    07530020
         SH    R3,VPDE+PDEVALEN    SUBTRACT THE LNTH JUST PROCESSED     07540020
         BZ    PCH044              IF ALL DATA PROCESSED, BRANCH        07550020
         SPACE                                                          07560020
*  UPDATE THE INPUT AND OUTPUT POINTERS FOR THE DATA ALREADY USED.      07570020
         SPACE                                                          07580020
         L     R2,VPDE+PDEVALPT    GET CURRENT OUTPUT ADDRESS           07590020
         L     R4,A1               GET CURRENT OUTPUT ADDRESS           07600020
         AH    R2,VPDE+PDEVALEN    INCRE PTR PAST DATA PROCESSED        07610020
         AR    R4,R5               ADD LNTH OF AREA JUST PATCHED        07620020
         ST    R2,VPDE+PDEVALPT    SAVE UPDATED DATA ADDR IN VALUE PDE  07630020
         STH   R3,VPDE+PDEVALEN    SAVE UPDATED LNTH IN VALUE PDE       07640020
         ST    R4,A1               STORE UPDATED OUTPUT ADDRESS         07650020
         B     CTYPE04             GO BACK AND PROCESS MORE OF STRING   07660020
         SPACE                                                          07670020
*********************************************************************** 07680020
*                                                                     * 07690020
*  THIS ROUTINE IS ENTERED WHEN THE CHARACTER SCAN ROUTINE FINDS A    * 07700020
*  SINGLE QUOTE. IT MOVES THE SCANNED DATA TO HOLDAREA, ADJUSTS THE   * 07710020
*  NECESSARY PTRS, AND DECREMENTS THE VALUES LENGTH BY 1.             * 07720020
*                                                                     * 07730020
*********************************************************************** 07740020
         SPACE                                                          07750020
QUOTEFND EQU   *                                                        07760020
         LR    R14,R2              CALCULATE NUMBER OF BYTES SCANNED    07770020
         SR    R14,R15                 AS CUR STRING PTR - BEGIN PTR.   07780020
         EX    R14,DATAMVC2        MOVE SCANNED DATA TO CUR HOLD POS.   07790020
         BCTR  R3,NULL             DECREMENT VALUES LENGTH BY 1.        07800020
         AR    R2,R4               INCREMENT STRING PTR PAST QUOTE.     07810020
         LA    R1,ONE(R14,R1)      INCREMENT CUR HOLD AREA PTR          07820020
         LA    R15,ONE(R2)         RESET BEGIN PTR TO ENXT BYTE TO SCAN 07830020
         B     CLOOP1              GO BACK TO SCAN LOOP AT BXLE INSTR.  07840020
         TITLE 'IKJEGASN, ASSIGN SUBCOMMAND, ERROR ROUTINES'            07852020
*********************************************************************** 07860020
*                                                                     * 07870020
*  MESSAGE SET UP ROUTINE MOVES THE FIRST AND SECOND LEVEL MESSAGES   * 07880020
*  TO THE BUFFER AND SETS UP THE IO PARAMETER LIST. AT ENTRY,         * 07890020
*        R14   CONTAINS THE RETURN ADDRESS                            * 07900020
*        R15   CONTAINS THE OFFSET TO THE MESSAGE ADCONS              * 07910020
*  AT EXIT FROM THIS ROUTINE,                                         * 07920020
*        R5    CONTAINS A PTR TO THE START OF THE OUTPUT BUFFER       * 07930020
*        IOLIST CONTAINS PTRS TO THE 1ST AND 2ND LEVEL MESSAGES.      * 07940020
*                                                                     * 07950020
*********************************************************************** 07960020
MSGSETUP EQU   *                                                        07970020
         SAVE  (14,12)             SAVE CALLERS REGS                    07980020
         L     R5,OUTBUF           R5=PTR TO OUTPUT BUFFER              07990020
         A     R15,PCHMSGCT        R15=ADDR OF MSG LIST                 08000020
         SR    R6,R6               SET UP 2ND LEVEL MSG PTR AS ZERO     08010020
         LM    R2,R3,ZERO(R15)     GET ADDRESSES OF MSGS.               08020020
         LH    R4,ZERO(R2)         PICK UP MESSAGE LENGTH               08030020
         BCTR  R4,NULL             DECREMENT LNTH FOR MVC INSTR         08040020
         EX    R4,MSGMVC1          MOVE 1ST LEVEL MSG TO BUF            08050020
         LTR   R3,R3               TEST FOR A SECOND LEVEL MSG          08060020
         BZ    MSGSET20            IF NO SECOND LEVEL MSG, BRANCH       08070020
         LH    R4,ZERO(R3)         PICK UP MESSAGE LENGTH               08080020
         BCTR  R4,NULL             DECREMENT LNTH FOR MVC INSTR         08090020
         EX    R4,MSGMVC2          MOVE 2ND MSG TO BUF                  08100020
         MVC   M2OFFSET(LL00IDL,R5),ZERO(R5) MOVE IN CONTROL FLD AND ID 08110020
         LA    R4,ONE+LL00IDL(R4)  CALCULATE TOTAL LNTH OF 2ND LVL MSG  08120020
         STH   R4,M2OFFSET(R5)     SET 2ND LEVEL MSG LNTH FIELD         08130020
         LA    R6,M2OFFSET(R5)     CALCULATE ADDR OF 2ND LEVEL MSG      08140020
MSGSET20 EQU   *                                                        08150020
         ST    R5,R5OFF(R13)       SET UP REG 5 FOR CALLER              08160020
         STM   R5,R6,MSGPLIST      SET UP IO PARAMETER LIST             08170020
         RETURN (14,12)            GO BACK TO CALLER                    08180020
MSGMVC1  MVC   ZERO(NULL,R5),ZERO(R2)  MOVES 1ST LEVEL MSGS TO BUFFER   08190020
MSGMVC2  MVC   M2OFFSET+LL00IDL(NULL,R5),TWO(R3)  MOVES 2ND LVL MSG'S   08200020
         SPACE 2                                                        08210020
*  GENERAL OUTPUT ROUTINE, INTER FACES WITH IKJEGIO1.                   08220020
         SPACE                                                          08230020
PCHIO    EQU   *                                                        08280020
         LA    R1,MSGPLIST         SET UP ADDR OF MSG PARM LIST         08330020
         L     R15,TPUTADDR        ADDR OF PUTLINE EP OF IKJEGIO1       08380020
         LCR   R1,R1               MAKE R1 NEG TO INDICATE MSG          08430020
         BR    R15                 GO TO IO RTN (R14 HAS RETURN ADDR)   08480020
         SPACE                                                          08530020
HBDYERR  EQU   *                                                        08580020
         LA    R15,PCHMSG00        OFFSET FOR ADDR BDY ERROR MSG        08630020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            08680020
         MVC   BDYOSET(L'HB,R5),HB MOVE REQUIRED BDY TO MSG             08730020
         B     BDYIO               GO TO CALL PCHIO                     08780020
         SPACE                                                          08830020
FBDYERR  EQU   *                                                        08880020
         LA    R15,PCHMSG00        OFFSET FOR ADDR BDY ERR MSG          08930020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            08980020
         MVC   BDYOSET(L'FB,R5),FB MOVE REQUIRED BDY TO MSG             09030020
         B     BDYIO               GO TO CALL PCHIO                     09080020
         SPACE                                                          09130020
DBDYERR  EQU   *                                                        09180020
         LA    R15,PCHMSG00        OFFSET FOR ADDR BDY ERR MSG          09230020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            09280020
         MVC   BDYOSET(L'DB,R5),DB MOVE REQUIRED BDY TO MSG             09330020
BDYIO    EQU   *                                                        09380020
         BAL   R14,PCHIO           GO OUTPUT THE MESSAGES               09430020
         B     CVTRC               GO ANALYZE RETURN CODE               09480020
         SPACE                                                          09530020
LENERR   EQU   *                                                        09580020
         LA    R15,PCHMSG01        OFFSET FOR MSG 'LENGTH ERROR ...'    09630020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            09680020
         LA    R15,MA1TYPE         SET UP OFFSET TO MSG INSERT          09682020
         SPACE                                                          09684020
*********************************************************************** 09686020
*  COMMON ROUTINE TO MOVE TYPE AND BEGINNING OF VALUE TO A MSG        * 09686420
*  INPUT R5    CONTAINS THE ADDRESS OF THE BEGINNING OF THE MSG       * 09686820
*        R15   CONTAINS THE OFFSET INTO THE MSG FOR THE INSERTION     * 09687220
*********************************************************************** 09688020
LENERR06 EQU   *                                                        09688420
         LH    R2,VPDE+PDEVALEN    PICK UP LENGTH FOR INPUT STRING      09690020
         LA    R3,TWO              SET UP A CONSTANT OF 2               09700020
         CR    R2,R3               IS STRING LENGTH GREATER THAN 2      09710020
         BH    LENERR10            IF GREATER THAN 2, BRANCH            09720020
         LR    R3,R2               IF NOT GREATER THAN 2, USE TRU LNTH  09722020
         BCTR  R3,NULL             DECREMENT LENGTH FOR MVC INSTR       09724020
LENERR10 EQU   *                                                        09726020
         LA    R5,ZERO(R15,R5)     SET UP ADDRESS FOR INSERT            09726420
         L     R15,VPDE+PDEVALPT   GET PTR TO INPUT DATA STRING         09728020
         EX    R3,LENMVC           MOVE BEGINNING OF VALUE TO MSG       09728420
         SR    R2,R2               SET UP TO PICK UP TYPE               09728820
         IC    R2,VPDE+PDEVALTP    PICK UP HEX CODE OF DATA TYPE        09729220
         SRL   R2,TWO              DIVIDE TYPE CODE BY 4                09729620
         IC    R2,TCODETBL(R2)     PICK UP TYPE CODE IN EBCDIC          09729720
         STC   R2,TOFFSET(R5)      PLACE TYPE INTO MESSAGE              09729820
         B     BDYIO               GO TO CALL PCHIO                     09730020
LENMVC   MVC   VOFFSET(NULL,R5),ZERO(R15)  MOVES DATA STRING TO MSG     09990020
         SPACE                                                          10000020
TYPERR   EQU   *                                                        10010020
         BAL   R14,MSGSETUP        GO MOVE MSG TO BUFFER                10022020
         LA    R15,MA2TYPE         SET UP OFFSET TO MSG INSERT          10024020
         B     LENERR06            GO TO COMMON INSERTION ROUTINE       10026020
*                                                                       10030020
*        SET UP FOR 'INSUFFICIENT STORAGE' MESSAGE                      10080020
*                                                                       10130020
PRC16    EQU   *                                                        10180020
         L     R2,PCHMSGCT         GET ADDR OF MSG CSECT                10330020
         LM    R2,R3,PCHMSG04(R2)  PICK UP ADDR'S OF MESSAGES           10430020
         STM   R2,R3,MSGPLIST          INTO PARM LIST.                  10480020
         B     BDYIO               GO CLEAN UP, RETURN TO CALLER RC=0   10680020
         EJECT                                                          10990020
*********************************************************************** 11000020
*                                                                     * 11010020
*  THIS CLOSED SUBROUTINE CHECKS THE TARGET AREA FOR INSERTED         * 11029820
*  BREAK POINTS BY SEARCHING THE BREAK ELEMENT QUEUE FOR ADDRESSES    * 11034020
*  WHICH FALL WITHIN THE AREA ABOUT TO BE PATCHED.                    * 11036020
*  WHEN A BREAK POINT IS FOUND WITHIN THE TARGET AREA, THE ORIGINAL   * 11038020
*  DATA IS MOVED FROM THE BREAK ELEMENT BACK TO ITS ORIGINAL LOCATION * 11040020
*  OVERLAYING THE BREAK POINT SVC. THE BREAK ELEMENT IS FLAGGED       * 11042020
*  INACTIVE, AND A SWITCH IS SET INDICATING A MESSAGE MUST BE ISSUED  * 11042120
*  TO TELL THE USER THAT BREAKPOINTS HAVE BEEN OVERLAYED.             * 11042220
*                                                                     * 11042320
*  INPUT  A1=START ADDRESS OF THE TARGET AREA                         * 11045320
*         R2 CONTAINS THE LENGTH OF THE PATCH DATA                    * 11045720
*         R1 CONTAINS THE ADDRESS OF THE INPUT PATCH DATA             * 11046120
*  OUTPUT R15 CONTAINS A RETURN CODE OF ZERO, OR THE ERROR RETURN     * 11048120
*             CODE FROM IKJEGIO.                                      * 11050120
*                                                                     * 11051620
*********************************************************************** 11054620
ASNBPT   EQU   *                                                        11057620
         SAVE  (14,12)             STANDARD SAVE                        11060620
         L     R15,REGSAVE3        PTR TO 2ND SUB-CMD SAVE AREA         11070620
         ST    R15,FOREPTR(ZERO,R13)   FORWARD AND                      11072620
         ST    R13,BACKPTR(ZERO,R15)       BACKWARD CHAIN SAVE AREAS    11072720
         LR    R13,R15             ESTABLISH NEW SAVE AREA              11072820
         SR    R15,R15             PRESET RETURN CODE TO ZERO           11074520
         L     R3,A1               GET START ADDR OF AREA TO PATCH      11076320
         LA    R4,ZERO(R2,R3)      CALCULATE DATA END ADDRESS           11078020
         LA    R5,ONE(ZERO,R1)     SET UP PTR TO INPUT DATA STRING      11079720
         C     R4,TSTTOP           IS END ADDR GREATER THAN HIGHEST     11081420
         BNH   ASNBPT04            IF NOT OUT OF CORE, BRANCH           11083120
         L     R4,TSTTOP           IF OUT OF CORE, USE HIGHEST ADDR     11084820
         SPACE                                                          11086520
*********************************************************************** 11086920
*  IF THE DATA ADDRESS IS NOT ON A HALF WORD BOUNDARY, R0 WILL CONTAIN* 11088220
*  A ONE (1), IF THE DATA ADDRESS IS ON A HALFWORD BOUNDARY, R0 WILL  * 11098220
*  CONTAIN A ZERO (0). THE CONTENTS OF R0 WILL THEN BE USED TO ADJUST * 11100220
*  THE DATA ADDRESS AND THE HOLDAREA ADDRESS. THIS ADJUSTMENT IS TO   * 11100620
*  TAKE CARE OF THE CASE WHERE THE DATA START ADDRESS IS THE SECOND   * 11101020
*  BYTE OF A BREAKPOINT.                                              * 11101420
*********************************************************************** 11101520
         SPACE                                                          11101820
ASNBPT04 EQU   *                                                        11101920
         LA    R0,ONE              SET THE LOW ORDER BIT ON IN REG 0    11102020
         NR    R0,R3               TEST DATA ADDRESS FOR A HALFWORD BDY 11102120
         SR    R3,R0               ADJUST DATA START ADDRESS IF NEEDED  11102220
         SR    R5,R0               MAKE SAME CHANGE FOR HOLDAREA ADDR   11106720
         L     R6,BREAKTAB         GET PTR TO FIRST BREAK ELEMENT       11108720
         USING BRKELEM,R6          ADDRESSABILITY FOR BREAK ELEMENT     11110720
         LTR   R6,R6               IS THERE A 1ST BREAK ELEMENT         11111120
         BP    ASNBPT12            IF THERE IS A BREAK ELEMENT, BRANCH  11111220
         B     ASNBPT20            IF NONE, RETURN                      11111320
         SPACE                                                          11111420
ASNBPT08 EQU   *                                                        11116020
         L     R6,BRKLINK          PICK UP FOREWARD PTR                 11116120
         LTR   R6,R6               TEST FOR ANOTHER                     11118120
         BNP   ASNBPT20            IF NO MORE, BRANCH                   11120120
         SPACE                                                          11120221
* CHECK WHETHER ANY BYTE OF THE INSTRUCTION IN THE BREAK ELEMENT A43335 11120321
* WILL BE OVERLAYED BY THIS PATCH                                A43335 11120421
         SPACE                                                          11122821
ASNBPT12 EQU   *                                                        11125321
         L      R8,BRKADDR        GET START ADDR OF BRKELEM INST A43335 11135321
         LA     R7,ZERO(R0,R8)    COPY START ADDR, CLEAR HI BYTE A43335 11137321
         TM     BRKINST,INSTRLEN  TEST INST LNTH IN OP CODE      A43335 11139321
         BM     ASNBPT14          IF INSTR LNTH 4, BRANCH        A43335 11141321
         LA     R8,TWO(R0,R8)     INCRE END PTR BY 2             A43335 11143321
         BZ     ASNBPT16          IF INST LNTH WAS 2, BRANCH     A43335 11143721
ASNBPT14 EQU    *                                                A43335 11144121
         LA     R8,FOUR(R0,R8)    INCRE END PTR BY 4 (LNTH 4-6)  A43335 11144221
ASNBPT16 EQU    *                                                A43335 11144321
         CR     R3,R8             IS DATA START PAST INST END    A43335 11144421
         BNL    ASNBPT08          IF PAST, BRANCH, NO HIT        A43335 11147721
         CR     R4,R7             IF DATA END PAST INST START    A53662 11149721
         BNL    ASNBPT40          IF PAST, BRANCH, THIS IS HIT   A43335 11150121
ASNBPT20 EQU   *                                                        11151221
         L     R13,BACKPTR(ZERO,R13)   GET CALLERS SAVE AREA ADDR       11154520
         RETURN (14,12),RC=(15)    RETURN TO CALLER                     11157620
         SPACE                                                          11158420
*********************************************************************** 11160320
*  IF A BREAK POINT IS FOUND IN THE RANGE, THE FOLLOWING CODE           11164220
*  WILL REPLACE THE BREAK POINT SVC WITH THE ORIGINAL INSTRUCTION       11164320
*********************************************************************** 11166320
         SPACE                                                          11166720
ASNBPT40 EQU   *                                                        11167120
         TM    BRKFLGS1,BRKINACT   IS THE BREAKPOINT ACTIVE             11184420
         BO    ASNBPT08            IF INACTIVE, IGNORE THIS BREAK ELEM  11184820
         TM    TSTFLGS1,TSTFIRST   HAS THE MESSAGE ALREADY BEEN GIVEN   11184920
         BZ    ASNBPT50            IF NOT, GO ISSUE BRK-PTS OVERLAYED   11185020
ASNBPT42 EQU   *                                                        11185120
         L     R2,BRKADDR          GET ADDR OF BRKPOINT SVC             11185220
         MVC   ZERO(TWO,R2),BRKINST    MOVE 2 BYTES OF SAVED INSTR BACK 11185620
         OI    BRKFLGS1,BRKINACT   INDICATE BREAK ELEMENT IS INACTIVE   11185720
         B     ASNBPT08            RETURN TO SEARCH LOOP                11186020
         SPACE                                                          11188020
ASNBPT50 EQU   *                                                        11188420
         L     R15,PCHMSGCT        ADDR OF MSG CSECT                    11191020
         MVC   MSGPLIST(EIGHT),PCHMSG05(R15)  MOVE MSG ADCONS TO IO LST 11193020
         BAL   R14,PCHIO           GO TO IO CALLING ROUTINE             11193420
         LTR   R15,R15             TEST RC FROM IKJEGIO                 11193820
         BNZ   ASNBPT20            IF RETURN CODE NON-ZERO, BRANCH      11196920
         OI    TSTFLGS1,TSTFIRST   INDICATE MSG HAS BEEN ISSUED         11198920
         B     ASNBPT42            RETURN TO BREAK-PT SEARCH RTN        11199020
         DROP  R6                                                       11200120
         EJECT                                                          11203220
*********************************************************************** 11206320
*                                                                       11209420
*        STAE RETRY ROUTINE                                             11219720
*                                                                       11230020
*********************************************************************** 11280020
         SPACE 3                                                        11330020
RETRY    EQU   *                                                        11380020
         L     R4,CVTPTR           PTR TO CVT                           11390020
         USING CVTDSECT,R4         ADDRESSABILITY FOR CVT               11400020
         L     R4,CVTTCBP          TCB PTR                              11410020
         L     R4,FOUR(R4)         CURRENT TCB PTR                      11420020
         DROP  R4                                                       11430020
         USING TCB,R4              TCB ADDRESSABILITY                   11440020
         L     R9,TCBTRN           TCOMTAB PTR                          11450020
         L     R13,REGSAVE2        PTR TO SAVE AREA                     11460020
         LM    R10,R12,R10OFF(R13)     RESTORE MODULE ADDRESSABILITY    11470020
         LTR   R0,R0               WAS WORKSPACE FREED                  11480020
         BNZ   PCHFREE             GO TO FREE WORKSPACE                 11490020
         FREEMAIN R,LV=104,A=(R1)  FREE WORKSPACE                       11500020
PCHFREE  EQU   *                                                        11510020
         LA    R15,TWENTY          INDICATE ERROR RETURN                11520020
         ST    R15,PCHRETCD        SAVE RETURN CODE                     11530020
         B     PCHRET1             RETURN                               11540020
         TITLE 'IKJEGASN, ASSIGN, CONSTANTS, DSECTS, AND PARSE MACROS'  11550020
DATAMVC1 MVC   ZERO(NULL,R15),ONE(R1)  MOVES DATA TO USERS CORE         11560020
DATAMVC2 MVC   ONE(ZERO,R1),ZERO(R15)       MOVE DATA INTO CONAREA      11570020
DATAMVC3 MVC   ONE(ZERO,R15),HOLDAREA+ONE   MOVES DATA FROM HOLD TO     11580020
*                                           CONVERT AREA                11590020
PCHTR    TR    ZERO(ZERO,R15),PCHTRTBL   FOR TRANSLATING TO UPPER CASE. 11600020
         SPACE 2                                                        11610020
*  THE FOLLOWING CONSTANTS MUST REMAIN TOGETHER WITH NEGZONE FIRST    * 11620020
*  AND POSZONE SECOND. THEY ARE USED IN SUBROUTINE 'ZONERTN'.         * 11630020
         SPACE                                                          11640020
NEGZONE  DC    Z'-1'               BYTE WITH NEGATIVE ZONE FIELD.       11650020
POSZONE  DC    Z'+1'               BYTE WITH POSITIVE ZONE FIELD.       11660020
         SPACE 2                                                        11670020
FONE     DC    F'1'                FOR ROUNDING HALFWORD ADDRS          11680020
FTHREE   DC    F'3'                *            FULLWORD                11690020
FSEVEN   DC    F'7'                *            DBL WORD                11700020
FFOUR    DC    F'4'                CONSTANT FOR COMPARE                 11710020
         SPACE                                                          11720020
HFOUR    DC    H'4'                GENERAL CONSTANT OF 4                11730020
HEIGHT   DC    H'8'                GENERAL CONSTANT OF 8                11740020
HSIXTEEN DC    H'16'               USED TO TEST FOR RC=16               11750020
         SPACE                                                          11760020
HB       DC    C'HALF'             MOVED INTO ERROR MSG MB3T            11770020
FB       DC    C'FULL'             MOVED INTO ERROR MSG MB3T            11780020
DB       DC    C'DBL'              MOVED INTO ERROR MSG MB3T            11790020
         SPACE 2                                                        11800020
GRDATA   DS    0F                                                       11810020
GRINCR   DC    H'1'                INCRE VALUE FOR GEN REG ADDRS        11820020
GRLIM    DC    H'15'               MAX GEN REG ADDR                     11830020
         SPACE                                                          11840020
FPRDATA  DS    0F                                                       11850020
FPRINCR  DC    H'2'                INCRE VALUE FOR FL PT REGS.          11860020
FPRLIM   DC    H'7'                MAX FL PT REG ADDR                   11870020
         SPACE                                                          11880020
LADRINCR DC    X'02000008'         USED TO INCR REG NO. AND DATA ADDR   11890020
         SPACE                                                          11900020
PCHABEND DS    0F                  ABEND VECTOR TABLE FOR PATCH         11910020
         DC    AL1(7)              CODE FOR USER CAUSED PROTECTION CHK  11920020
         DC    AL3(PCHABND1)       ANTICIPATED ABEND ADDR FROM DATA MVC 11930020
         DC    X'FF'               INDICATE END OF ABEND TABLE          11940020
         SPACE                                                          11950020
TCODETBL DC    C'CXBXFHEDAYSVPZ'   TABLE TO CONVERT TYPE CODES TO CHAR  11952020
         SPACE                                                          11954020
PCHMSGCT DC    V(IKJEGMSD)         ADDR OF MESSAGE CSECT                11960020
RETRYAD  DC    A(RETRY)            ADDRESS OF STAE RETRY ROUTINE        11970020
         EJECT                                                          11980020
PCHTRTBL DC    256AL1(*-PCHTRTBL)  LOWER TO UPPER CASE TR TABLE         11990020
         ORG   PCHTRTBL+C'A'-X'40' SET LOCATION CTR TO LOWER CASE 'A'   12000020
         DC    (C'Z'-C'A'+1)AL1(*-PCHTRTBL+X'40')  DEFINES UPPER CASE   12010020
         ORG                                                            12020020
         TITLE 'IKJEGASN, ''ASSIGN'' SUBCOMMAND MESSAGE CSECT'          12032020
IKJEGMSD CSECT                                                          12034020
**********************************************************************  12036020
*                                                                     * 12038020
*  MESSAGE CSECT FOR MODULE IKJEGASN OF THE SET SUBCOMMAND OF TEST.   * 12038420
*        THE FIRST SECTION OF THE CSECT CONTAINS ADDRESS CONSTANTS FOR* 12038820
*        THE FIRST AND SECOND LEVEL MESSAGES. EACH PAIR OF ADDRESS    * 12039220
*        CONSTANTS LOGICALLY CONNECTS A FIRST LEVEL MESSAGE TO THE    * 12039620
*        APPROPIATE SECOND LEVEL MESSAGE. MESSAGES ARE REFERENCED BY  * 12039720
*        AN OFFSET INTO THE MESSAGE CSECT FOR THE DESIRED PAIR OF     * 12039820
*        ADDRESS CONSTANTS.                                           * 12039920
*        THE SECOND SECTION CONTAINS THE ACTUAL MESSAGES. EACH FIRST  * 12041020
*        LEVEL MESSAGE IS PRECEDED BY A HALF WORD LENGTH FIELD,       * 12041420
*        FOLLOWED BY A HALFWORD OF BINARY ZEROS, NEXT IS THE MESSAGE  * 12041820
*        ID NUMBER, AND LAST IS THE ACTUAL MESSAGE TEXT.              * 12041920
*        FOR SECOND LEVEL MESSAGES, ONLY THE TEXT IS INCLUDED AND     * 12042020
*        THE REMAINDER OF THE MESSAGE IS CONSTRUCTED AT MESSAGE OUTPUT* 12042420
*        TIME.                                                        * 12042820
*                                                                     * 12043220
**********************************************************************  12043320
         SPACE 2                                                        12043520
*  INVALID ADDRESS, HALF/FULL/DBL WORD BOUNDARY REQUIRED                12043920
         SPACE                                                          12044320
MSG00    DC    A(MA0L)             FIRST LEVEL                          12044420
         DC    A(MB0L)             SECOND LEVEL                         12044520
         SPACE 2                                                        12044920
*  LENGTH ERROR FOR VALUE BEGINNING -'...                               12045020
         SPACE                                                          12045120
MSG01    DC    A(MA1L)             FIRST LEVEL                          12045520
         DC    A(MB1L)             SECOND LEVEL                         12045620
         SPACE 2                                                        12046020
*  DATA 'TYPE' ERROR FOR VALUE BEGINNING -'...    ---E TYPE REG---      12046120
         SPACE                                                          12046220
MSG02    DC    A(MA2L)             FIRST LEVEL                          12046320
         DC    A(MB2L)             SECOND LEVEL                         12046420
         SPACE 2                                                        12046520
*  DATA 'TYPE' ERROR FOR VALUE BEGINNING -'...   ---D TYPE REG---       12046620
         SPACE                                                          12046820
MSG03    DC    A(MA2L)             FIRST LEVEL                          12046920
         DC    A(MC2L)             SECOND LEVEL                         12047020
         SPACE 2                                                        12047120
*  NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND                           12047220
         SPACE                                                          12047320
MSG04    DC    A(MA4L)             FIRST LEVEL MSG                      12047420
         DC    A(0)                NO SECOND LEVEL FOR THIS ONE         12047520
         SPACE 2                                                        12047620
*  DATA AREA CONTAINED BREAKPOINTS                                      12047720
         SPACE                                                          12047820
MSG05    DC    A(MA5L)             FIRST LEVEL                          12047920
         DC    A(MB5L)             SECOND LEVEL                         12049220
         EJECT                                                          12049620
         DS    0H                                                       12050020
MA0L     DC    AL2(MA0E-MA0L)      MESSAGE LENGTH                       12052020
         DC    AL2(0)              OFFSET FIELD                         12052120
         DC    C'IKJ57062I INVALID ADDRESS+'                MSG TEXT    12060120
MA0E     EQU   *                                                        12062120
         SPACE                                                          12064120
         DS    0H                                                       12066120
MB0L     DC    AL2(MB0E-MB0T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  12068120
MB0T     DC    C'    WORD BOUNDARY REQUIRED'                MSG TEXT    12068520
MB0E     EQU   *                                                        12068920
         SPACE                                                          12069320
         DS    0H                                                       12069720
MA1L     DC    AL2(MA1E-MA1L)      LENGTH OF ENTIRE MESSAGE             12069820
         DC    AL2(0)              OFFSET FIELD                         12069920
         DC    C'IKJ57063I LENGTH ERROR FOR'     MSG TEXT               12072420
         DC    C' VALUE BEGINNING '              MSG TEXT CONT.         12074420
MA1TYPE  EQU   *-MA1L                            OFFSET FOR TYPE CODE   12076420
         DC    C' ''   +'                        MSG TEXT CONT.         12076820
MA1E     EQU   *                                                        12077220
         SPACE                                                          12077320
         DS    0H                                                       12077420
MB1L     DC    AL2(MB1E-MB1T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  12077620
MB1T     DC    C'DATA LENGTH EXCEEDS REGISTER'              MSG TEXT    12077720
         DC    C' CAPACITY'                                 MSG TEXT    12077820
MB1E     EQU   *                                                        12077920
         SPACE                                                          12080320
         DS    0H                                                       12082320
MA2L     DC    AL2(MA2E-MA2L)      LENGTH OF ENTIRE MESSAGE             12084320
         DC    AL2(0)              OFFSET FIELD                         12084720
         DC    C'IKJ57064I DATA ''TYPE'' ERROR'  MSG TEXT               12085120
         DC    C' FOR VALUE BEGINNING '          MSG TEXT CONT.         12085420
MA2TYPE  EQU   *-MA2L              OFFSET FOR TYPE CODE                 12085820
         DC    C' ''   +'                        MSG TEXT CONT.         12085920
MA2E     EQU   *                                                        12088220
         SPACE                                                          12088620
         DS    0H                                                       12089020
MB2L     DC    AL2(MB2E-MB2T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  12089420
MB2T     DC    C'VALID DATA TYPES ARE ''X'' OR'  MSG TEXT               12089820
         DC    C' ''E'' FOR REGISTER TYPE E'     MSG TEXT CONT.         12089920
MB2E     EQU   *                                                        12090020
         SPACE                                                          12092020
         DS    0H                                                       12092420
MC2L     DC    AL2(MC2E-MC2T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  12092820
MC2T     DC    C'VALID DATA TYPES ARE ''X'' OR'  MSG TEXT               12092920
         DC    C' ''D'' FOR REGISTER TYPE D'     MSG TEXT CONT.         12093020
MC2E     EQU   *                                                        12093320
         SPACE                                                          12093720
         DS    0H                                                       12093820
MA4L     DC    AL2(MA4E-MA4L)      MESSAGE LENGTH                       12093920
         DC    AL2(0)              OFFSET FIELD                         12096820
         DC    C'IKJ57065I NOT ENOUGH MAIN '     MSG TEXT               12097220
         DC    C'STORAGE TO EXECUTE COMMAND'     MSG TEXT CONT.         12097620
MA4E     EQU   *                                                        12097720
         SPACE                                                          12099720
         DS    0H                                                       12099820
MA5L     DC    AL2(MA5E-MA5L)      LENGTH OF ENTIRE MESSAGE             12099920
         DC    AL2(0)              OFFSET FIELD                         12100020
         DC    C'IKJ57066I DATA AREA CONTAINED'  MSG TEXT               12102020
         DC    C' BREAKPOINT(S)+'                MSG TEXT CONT.         12102420
MA5E     EQU   *                                                        12102520
         SPACE                                                          12104020
         DS    0H                                                       12104420
MB5L     DC    AL2(MB5E-MB5L)      ENTIRE LENGTH OF MESSAGE             12104820
         DC    AL2(0)              OFFSET FIELD                         12105220
         DC    C'IKJ57066I BREAKPOINTS WERE'     MSG TEXT               12105320
         DC    C' DEACTIVATED, TO ACTIVATE, USE' MSG TEXT CONT.         12105420
         DC    C' THE ''AT'' COMMAND'            MSG TEXT CONT.         12105520
MB5E     EQU   *                                                        12105920
         TITLE 'IKJEGASN, ASSIGN SUBCOMMAND, CONSTANTS AND MACROS'      12106720
*                                                                       12113920
*        FOLLOWING IS A MAP OF THE WORK AREA USED BY THE PATCH MODULES  12121620
*                                                                       12128820
PCHWORK  DSECT                                                          12136020
XCTLLST  XCTL  SF=L                PARM LIST                            12143220
XCTLLSTL EQU   *-XCTLLST           SYMBOLIC LENGTH OF XCTL PARM LIST    12150420
         ORG   XCTLLST             REUSE SPACE OF THE XCTL PARM LIST    12157620
PPCL     DS    7F                  SPACE FOR PARSE PARM LIST            12164820
         SPACE                                                          12172020
ADDRINCR DS    F                   FULLWORD TO HOLD CONSTANTS FOR REGS  12179220
MAXRADDR EQU   ADDRINCR+2          OFFSET FOR MAX REG NUMBER            12186420
PCHRETCD DS    F                   HOLDS CURRENT RETURN CODE            12193620
VPDE     DS    3F                  HOLDS CURRENT COPY OF THE VALUE PDE  12200820
A1       DS    F                   HLODS CURRENT ADDR TO BE PATCHED     12208020
DUMMYPDE DS    XL(LVALPDE)         RESERVE SPACE FOR COPY OF VALUE PDE. 12215220
A1L      DS    H                   HOLDS CURRENT STRING LNTH FOR 'C'    12222420
A1TYPE   DS    X                   CONTAINS TYPE ASSOCIATED WITH VALUE  12229620
RETRYSAV DS    AL3                 CONTAINS ADDR OF MAINLINE STAE RETRY 12236820
         DS    XL1                 INCREMENT LOCATION CTR BY 1.         12244020
         DS    0D                                                       12251220
         ORG   *-1                 POSITION FOR LENGTH BYTE OF HOLDAREA 12258420
CONAREA1 DS    XL41                USED FOR ADDRESSING PURPOSES ONLY.   12265620
         ORG   CONAREA1            RE-USE SPACE FOR ACTUAL HOLDAREA     12272820
HOLDAREA DS    XL65                TEMP HOLD AREA FOR DATA CONVERSION   12280020
MSGPLIST DS    2F                  PARM LIST FOR CALLING IKJEGIO1.      12330020
STAELIST STAE  MF=L                PARM LIST FOR STAE                   12380020
TYPESAVE DS    C                   FOR SAVING USER SUPPLIED TYPE CODE   12400020
LPCHWORK EQU   *-PCHWORK           LENGTH OF TOTAL DSECT.               12410020
         EJECT                                                          12412020
         BRKELEM                                                        12414020
         SPACE 3                                                        12414420
         TSTCWORK                  EXPAND TEST'S CORE MAPPING DSECT     12414820
         EJECT                                                          12416020
         TCOMTAB                                                        12420020
         EJECT                                                          12430020
         IKJPARMA                  EXPAND THE ADDR PDE MAPPING DSECT    12440020
         EJECT                                                          12510020
CVTDSECT DSECT                                                          12550020
         CVT                                                            12560020
         EJECT                                                          12562020
         IKJTCB                                                         12570020
         END                                                            14701720
