 TITLE 'IKJEGAT - AT SUBCOMMAND OF TSO/TEST'                            00050020
*****************************  PROLOGUE  ****************************** 00100020
*                                                                     * 00150020
* STATUS                                                              * 00200020
*    CHANGE LEVEL 001                                                 * 00250021
*                                                                     * 00300020
* FUNCTION/OPERATION                                                  * 00350020
*    THIS MODULE CONTAINS LOGIC FOR THE AT SUBCOMMAND OF THE 'TEST'   * 00400020
*    PACKAGE FOR THE TIME SHARING OPTION (TSO) FOR OS/360 MVT.  IT    * 00450020
*    HAS TWO FUNCTIONS-                                               * 00500020
*    1.  DETERMINE IF AT WERE ISSUED FOR A DEFER REQUEST OR TO MAKE   * 00550020
*    ACTIVE BREAKPOINTS.  IF THE REQUEST IS TO BUILD THE DEFER        * 00600020
*    QUEUE THIS MODULE XCTL'S TO THE SECOND LOAD OF AT.               * 00650020
*    2.  INSERTS BREAKPOINTS AT SPECIFIED LOCATIONS IN THE PROBLEM    * 00700020
*    PROGRAM AND SAVES ANY ASSOCIATED SUBCOMMAND CHAIN FOR THE        * 00750020
*    ADDRESSES SPECIFIED.                                             * 00800020
*                                                                     * 00850020
* ENTRY POINTS                                                        * 00900020
*         IKJEGAT - DETERMINES WHETHER THE MODULE WERE ENTERED DUE    * 00950020
*         TO A USER-ORIENTED REQUEST OR BECAUSE A NEW LOAD MODULE     * 01000020
*         HAS BEEN BROUGHT INTO CORE AND IT IS NECESSARY TO SEARCH    * 01050020
*         THE DEFER QUEUE FOR REQUESTS AGAINST THAT MODULE.           * 01060020
*                                                                     * 01150020
* INPUT                                                               * 01200020
*    A FLAG (TSTFLGS1-BIT 5) IN THE COMMUNICATIONS TABLE INDICATING   * 01250020
*    THE TYPE OF ENTRANCE IS PROVIDED.  SHOULD THE AT ROUTINE BE      * 01300020
*    ENTERED BECAUSE A NEW MODULE HAS BEEN BROUGHT INTO CORE THE FIRST* 01350020
*    TWO WORDS IN AT'S WORK AREA WILL CONTAIN THE NAME OF THE MODULE. * 01400020
*                                                                     * 01450020
* OUTPUT                                                              * 01500020
*    OUTPUT CONSISTS OF-                                              * 01550020
*    1.  DIAGNOSTIC MESSAGES.                                         * 01600020
*    2.  A BREAK ELEMENT QUEUE POINTED TO BY BREAKTAB IN TCOMTAB IN   * 01650020
*    THE FORMAT DESCRIBED BY THE BRKELEM DSECT.                       * 01700020
*    3.  RETURN CODES AS LISTED BELOW-                                * 01750020
*                                                                     * 01760020
*    0 - MAINLINE MAY REISSUE TEST MODE MESSAGE TO GET ANOTHER        * 01800020
*    SUBCOMMAND                                                       * 01850020
*    4 - RESUME PROBLEM PROGRAM                                       * 01900020
*    16 - ATTENTION HAS BEEN SCHEDULED                                * 01950020
*    20 - INDICATE RETURN FROM RETRY ROUTINE                          * 02000020
*                                                                     * 02050020
* EXTERNAL ROUTINES--                                                 * 02100020
*         1.  IKJPARS - TO SCAN THE INPUT BUFFER FOR SYNTAX CHECKING  * 02150020
*         OF ADDRESSES AND KEYWORDS IF SPECIFIED AND TO PROMPT THE    * 02200020
*         USER FOR VALID INPUT WHEN NECESSARY.  AT ENTRY TO IKJPARS   * 02250020
*         REGISTER ONE POINTS TO A PARAMETER LIST WITH THE            * 02300020
*         FOLLOWING FORMAT-                                           * 02350020
*                                                                     * 02360020
*         0 - POINTER TO UPT                                          * 02400020
*         4 - POINTER TO ECT                                          * 02450020
*         8 - POINTER TO CP ECB                                       * 02500020
*         12 - POINTER TO PARAMETER DESCRIPTOR CONTROL LIST           * 02550020
*         16 - POINTER TO ANSWER PLACE                                * 02600020
*         20 - POINTER TO COMMAND BUFFER                              * 02650020
*         24 - POINTER TO USER WORK AREA (AT'S SAVE AREA)             * 02700020
*                                                                     * 02710020
*         2.  IKJEGCVT - CONVERTS AN ABSOLUTE ADDRESS, AN EXPRESSION, * 02750020
*         AN INDIRECT ADDRESS, OR A FULLY QUALIFIED ADDRESS TO        * 02800020
*         BINARY.  AT ENTRY, REGISTER ONE CONTAINS THE COMPLEMENT     * 02850020
*         OF THE PDE ADDRESS TO INDICATE AN ADDRESS CONVERSION        * 02900020
*         AND REGISTER ZERO IS SET NEGATIVE TO INDICATE A CONVERT     * 02950020
*         TO BINARY. IN MOST CASES A SWITCH MUST BE SET IN TCOMTAB    * 03000020
*         TO TELL CONVERT THAT A RANGE IS POSSIBLE.  FOR A VALUE      * 03050020
*         CONVERSION TO BINARY REGISTER 1 CONTAINS A POINTER TO THE   * 03100020
*         COUNT PDE.                                                  * 03150020
*                                                                     * 03160020
*         3.  IKJEGIO - OUTPUTS ERROR MESSAGES.  AT ENTRY, REGISTER   * 03200020
*         ONE CONTAINS THE COMPLEMENT OF THE ADDRESS OF THE           * 03250020
*         MESSAGE POINTER/POINTERS.                                   * 03300020
*                                                                     * 03350020
* EXITS, NORMAL--                                                     * 03400020
*         IF IT IS DETERMINED THAT AT WERE ISSUED TO PUT A DEFER BREAK* 03450020
*         ELEMENT ON THE QUEUE THIS MODULE XCTL'S TO THE SECOND LOAD  * 03500020
*         MODULE OF AT IKJEGATD.  OTHERWISE, RETURN IS VIA REGISTER   * 03550020
*         14 TO THE CALLER.                                           * 03600020
*                                                                     * 03650020
* EXITS, ERROR--                                                      * 03700020
*         RETURN VIA REGISTER 14 TO THE CALLER.                       * 03750020
*                                                                     * 03800020
* TABLES/WORK AREAS --                                                * 03850020
*    THIS MODULE USES WORK AREAS AS DESCRIBED BY THE FOLLOWING DSECTS * 03900020
*    1.  TCOMTAB - TEST'S COMMUNICATION WORK AREA                     * 03950020
*    2.  WORKSP - AT'S WORK AREA, A PART OF TEST'S WORK AREA DEFINED  * 04000020
*    BY THE TSTCWORK DSECT AS CWORKCMD                                * 04050020
*    3.  IKJPARMD - INFORMATION FROM IKJPARS                          * 04100020
*    4.  CONPLACE - INFORMATION FROM IKJEGCVT                         * 04150020
*                                                                     * 04200020
* ATTRIBUTES --                                                       * 04250020
*    REENTRANT, REFRESHABLE.                                          * 04300020
*                                                                     * 04350020
* CHARACTER CODE DEPENDENCY --                                        * 04400020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESEN-  * 04450020
*    TATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE  * 04500020
*    ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO THAT * 04550020
*    REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT* 04600020
*    IN A CORRECT MODULE FOR THE NEW DEFINITIONS.                     * 04650020
*                                                                     * 04700020
* NOTES --                                                            * 04750020
*    NONE.                                                            * 04800020
*                                                                     * 04850020
*********************************************************************** 04900020
         EJECT                                                          05100020
IKJEGAT  CSECT                          AT ROUTINE OF TSO/TEST          05110020
*RELEASE 21 CHANGES                                                     05120021
*C441220                                                         A43350 05130021
*C185500                                                         A46741 05140021
*C258500                                                         A46741 05142021
*REGISTER EQUATES                                                       05150020
R0       EQU   0                        REGISTER 0                      05200020
R1       EQU   1                        REGISTER 1                      05250020
R2       EQU   2                        REGISTER 2                      05300020
R3       EQU   3                        REGISTER 3                      05350020
R4       EQU   4                        REGISTER 4                      05400020
R5       EQU   5                        REGISTER 5                      05450020
R6       EQU   6                        REGISTER 6                      05500020
R7       EQU   7                        REGISTER 7                      05550020
R8       EQU   8                        REGISTER 8                      05600020
R9       EQU   9                        REGISTER 9                      05650020
R10      EQU   10                       REGISTER 10                     05700020
R11      EQU   11                       REGISTER 11                     05750020
R12      EQU   12                       REGISTER 12                     05800020
R13      EQU   13                       REGISTER 13                     05850020
R14      EQU   14                       REGISTER 14                     05900020
R15      EQU   15                       REGISTER 15                     05950020
         SPACE                                                          06000020
* SPECIAL EQUATES                                                       06050020
ZERO     EQU   0                        NUMBER 0                        06100020
ONE      EQU   1                        NUMBER 1                        06150020
TWO      EQU   2                        NUMBER 2                        06200020
THREE    EQU   3                        NUMBER 3                        06250020
FOUR     EQU   4                        NUMBER 4                        06300020
FIVE     EQU   5                        NUMBER 5                        06350020
SIX      EQU   6                        NUMBER 6                        06400020
SEVEN    EQU   7                        NUMBER 7                        06450020
EIGHT    EQU   8                        NUMBER 8                        06500020
TEN      EQU   10                       NUMBER 10                       06550020
ELEVEN   EQU   11                       NUMBER 11                       06600020
TWELVE   EQU   12                       NUMBER 12                       06650020
SIXTEEN  EQU   16                       NUMBER 16                       06700020
TWENTY   EQU   20                       NUMBER 20                       06750020
TWENTY4  EQU   24                       NUMBER 24                       06800020
TWENTY6  EQU   26                       NUMBER 26                       06850020
TWENTY8  EQU   28                       NUMBER 28                       06900020
THIRTY   EQU   30                       NUMBER 30                       06950020
FORTY3   EQU   43                       NUMBER 43                       07000020
FORTY6   EQU   46                       NUMBER 46                       07050020
FORTY7   EQU   47                       NUMBER 47                       07100020
FIFTY6   EQU   56                       NUMBER 56                       07150020
SIXTY8   EQU   68                       NUMBER 68                       07200020
SEVENTY2 EQU   72                       NUMBER 72                       07250020
L1       EQU   1                        LENGTH 1                        07300020
L2       EQU   2                        LENGTH 2                        07350020
L3       EQU   3                        LENGTH 3                        07400020
L4       EQU   4                        LENGTH 4                        07450020
L5       EQU   5                        LENGTH 5                        07500020
L8       EQU   8                        LENGTH 8                        07600020
L25      EQU   25                       LENGTH 25                       07650020
L30      EQU   30                       LENGTH 30                       07700020
L34      EQU   34                       LENGTH 34                       07750020
L46      EQU   46                       LENGTH 46                       07800020
L69      EQU   69                       LENGTH 69                       07850020
L94      EQU   94                       LENGTH 94                       07900020
L98      EQU   98                       LENGTH 98                       07950020
FACTOR   EQU   8                        DISPLACEMENT FOR MESSAGE        08000020
*                                          POINTERS                     08050020
HEX01    EQU   X'01'                    USED IN 370 OP CODE CHECK       08060020
HEX05    EQU   X'05'                    USED IN 370 OP CODE CHECK       08070020
HEXB2    EQU   X'B2'                    USED IN 370 OP CODE CHECK       08080020
HEXFF    EQU   X'FF'                    END FLAG FOR PARSE'S PARM LIST  08100020
DMELOAD  EQU   0                        OFFSET FOR LOADNAME IN DME      08150020
DMEDBE   EQU   8                        OFFSET FOR POINTER TO FIRST DBE 08200020
DMEDME   EQU   12                       OFFSET FOR POINTER TO NEXT DME  08250020
DBEPDL   EQU   0                        OFFSET IN DBE FOR PDL POINTER   08300020
DBEINBUF EQU   4                        OFFSET IN DBE FOR POINTER       08350020
*                                          TO INPUT BUFFER              08400020
DBEDBE   EQU   8                        OFFSET IN DBE FOR POINTER       08450020
*                                          TO NEXT DBE                  08500020
Z        EQU   8                        CONDITION CODE ZERO.            08520020
ONBIT    EQU   X'80'                    HIGH ORDER BIT IS ON            08550020
REGTYPE  EQU   X'38'                    INDICATES REGISTER ADDRESS      08600020
BADBOUND EQU   X'01'                    SETTING TO TEST FOR ADDRESS ON  08650020
*                                          HALFWORD BOUNDARY            08700020
BLANK    EQU   C' '                     BLANK                           08750020
PLUS     EQU   C'+'                     CHARACTER PLUS SIGN             08800020
FCODE    EQU   X'10'                    FULLWORD DECIMAL TYPE CODE      08850020
CZERO    EQU   C'0'                     CHARACTER ZERO                  08900020
F0       EQU   X'F0'                    ZERO                            08950020
EXPFLGS5 EQU   8                        OFFSET INTO EXPRESSION          09000020
*                                          PDE FOR FLAGS5               09050020
DECVAL   EQU   X'04'                    DECIMAL EXPRESSION VALUE        09150020
SETOFF   EQU   X'FB'                    TURN OFF TSTBUILD FLAG          09200020
         SPACE                                                          09250020
MSG1     EQU   0*FACTOR                 OFFSET FOR MESSAGE 1            09300020
MSG2     EQU   1*FACTOR                 OFFSET FOR MESSAGE 2            09350020
MSG3     EQU   2*FACTOR                 OFFSET FOR MESSAGE 3            09400020
MSG4     EQU   3*FACTOR                 OFFSET FOR MESSAGE 4            09450020
MSG5     EQU   4*FACTOR                 OFFSET FOR MESSAGE 5            09500020
MSG6     EQU   5*FACTOR                 OFFSET FOR MESSAGE 6            09550020
MSG7     EQU   6*FACTOR                 OFFSET FOR MESSAGE 7            09600020
MSG8     EQU   7*FACTOR                 OFFSET FOR MESSAGE 8            09650020
MSG9     EQU   8*FACTOR                 OFFSET FOR MESSAGE 9            09700020
MSG10    EQU   9*FACTOR                 OFFSET FOR MESSAGE 10           09750020
MSG11    EQU   10*FACTOR                OFFSET FOR MESSAGE 11           09800020
MSG12    EQU   11*FACTOR                OFFSET FOR MESSAGE 12           09850020
MSG13    EQU   12*FACTOR                OFFSET FOR MESSAGE 13           09900020
         SPACE                                                          09950020
         SAVE (14,12),,IKJEGAT          SAVE CALLER'S REGISTERS         10050020
         LR    R12,R15                  ESTABLISH ADDRESSABILITY        10100020
         USING IKJEGAT,R12                 FOR THIS CSECT               10150020
         USING TCOMTAB,R9               ESTABLISH ADDRESSABILITY TO     10200020
*                                          COMMUNICATION WORK AREA      10250020
         L     R5,REGSAVE2              R5=ADDR OF AT'S SAVE AREA       10300020
         ST    R13,FOUR(ZERO,R5)        STORE BACKWARD CHAIN POINTER    10350020
         ST    R5,EIGHT(ZERO,R13)       STORE FORWARD POINTER           10400020
         LR    R13,R5                   R13=ADDRESS OF AT'S SAVE AREA   10450020
         L     R10,WORKAREA             R10=ADDRESS OF COMMON WORKAREA  10500020
         USING TSTCWORK,R10             ESTABLISH ADDRESSABILITY        10550020
*                                          TO TEST'S WORKAREA           10600020
         LA    R10,CWORKCMD             R10=ADDRESS OF AT'S WORKAREA    10650020
         DROP  R10                                                      10700020
         USING WORKSP,R10               ESTABLISH ADDRESSABILITY TO     10750020
*                                          WORK AREA                    10800020
         MVC   MAINTRY(L4),TSTRETRY     SAVE MAINLINE'S RETRY           10810020
*                                          ROUTINE ADDRESS              10820020
         STM   R14,R12,TWELVE(R13)      SAVE AT'S REGISTERS             10850020
         LA    R6,ABENDTAB              R6=ADDRESS OF ABEND TABLE       10900020
         ST    R6,ABENTAB1              SAVE IN TCOMTAB                 10950020
         MVC   STAEL(STAELENG),STAELIST MOVE LIST FORM OF STAE          11000020
*                                          TO WORK AREA                 11050020
         LA    R1,STAEL                 R1=ADDRESS OF LIST FORM         11100020
*                                          OF STAE MACRO                11150020
         L     R8,TSTSTAE               R8=ADDRESS OF STAE EXIT ROUTINE 11200020
         MVC   RETRY1(L3),RETRYA1       SAVE ADDRESS OF AT'S RETRY      11250020
*                                          ROUTINE IN TCOMTAB           11300020
         STAE  (R8),XCTL=NO,MF=(E,(R1)) CREATE A NEW STAE REQUEST       11350020
         LTR   R15,R15                  WAS STAE SUCCESSFUL             11400020
SMTSTAE  BZ    CONTINUE                 YES. CONTINUE.                  11700020
         SPACE                                                          12150020
STAE4    EQU   *                        PUT OUT INSUFFICENT CORE MSG    12200020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     12250020
         LA    R1,MSG7(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTERS  12300020
         BAL   R5,PUTMSG                BRANCH TO PUT OUT INSUFFICIENT  12350020
*                                          CORE MESSAGE                 12400020
         B     ISBLDON                  CHECK FOR BUILD SWITCH ON       12500020
         SPACE                                                          12550020
CONTINUE EQU   *                        PROCESSING AFTER ISSUING STAE   12600020
         TM    TSTFLGS1,TSTBUILD        IS AT LOGIC RECEIVING CONTROL   12650020
*                                          TO CREATE ACTIVE BREAK       12700020
*                                          ELEMENTS FROM THE DEFER      12750020
*                                          QUEUE FOR A NEWLY LOADED     12800020
*                                          MODULE                       12850020
         BO    FROMDEFR                 YES, HANDLE DEFER QUEUE         12900020
         SPACE                                                          12950020
* CREATE THE PARAMETER LIST REQUIRED AND LINK TO IKJPARS TO SCAN THE    13000020
* SUBCOMMAND AND VALIDITY CHECK THE INPUT.                              13050020
         LM    R2,R4,PARMLIST           PICK UP POINTERS TO UPT, ECT,   13100020
*                                          AND CP ECB                   13150020
         ST    R2,PARMS+PPLUPT-PPL      SAVE PTR TO UPT                 13200020
         ST    R3,PARMS+PPLECT-PPL      SAVE PTR TO ECT                 13250020
         ST    R4,PARMS+PPLECB-PPL      SAVE PTR TO CP'S ECB            13300020
         L     R2,PCLISTA               R2=ADDRESS OF PCL               13350020
         ST    R2,PARMS+PPLPCL-PPL      SAVE PTR TO PCL                 13400020
         LA    R3,TSTANSPL              R3=POINTER TO ANSWER PLACE      13450020
         ST    R3,PARMS+PPLANS-PPL      SAVE PTR TO ANSWER PLACE        13500020
         L     R4,INBUF                 R4=ADDRESS OF SUBCOMMAND BUFFER 13550020
         ST    R4,PARMS+PPLCBUF-PPL     SAVE PTR TO BUFFER              13600020
         ST    R13,PARMS+PPLUWA-PPL     SAVE PTR TO AT'S WORK AREA      13650020
         LA    R1,PARMS                 R1=ADDRESS OF PARAMETER LIST    13700020
         LINK  EP=IKJPARS               GO TO PARSE ROUTINE             13750020
SMTPARS  DS    0X                       FOR SMT TEST CASES.             13770020
BLOW5    EQU   *                        RESUME ADDRESS IN CASE LINK     13800020
*                                          FAILS                        13850020
         SPACE                                                          13900020
* RETURN FROM IKJPARS                                                   13950020
         LTR   R15,R15                  WAS PARSE SUCCESSFUL            14000020
         BNZ   CHKCODE(R15)             NO, FIND OUT WHY                14050020
         L     R11,TSTANSPL             R11=POINTER TO PDL              14100020
         USING IKJPARMD,R11             SET UP ADDRESSABILITY TO PDL    14150020
         LA    R2,TWO                   R2=TWO                          14200020
         CH    R2,DEFER                 WAS DEFER SPECIFIED             14250020
         LA    R11,ADDR                 R11=ADDRESS OF ADDRESS PDE      14300020
         DROP  R11                                                      14350020
         USING IKJPARMA,R11             SET UP ADDRESSABILITY TO        14400020
*                                          ADDRESS PDE                  14450020
         BE    TRANSFER                 YES, XCTL TO SECOND LOAD OF AT  14500020
         SPACE                                                          14550020
* THIS ROUTINE IS ENTERED TO MAKE ACTIVE BREAK ELEMENTS AT THE          14600020
* LOCATIONS SPECIFIED BY THE SUBCOMMAND PARAMETERS.                     14650020
         SPACE                                                          14700020
         XR    R3,R3                    INITIALIZE INDICATOR FOR        14710020
*                                          CONVERTED PDE'S              14720020
WASITCVD EQU   *                        MAKE SURE ALL PDE'S ARE         14750020
*                                          CONVERTED                    14800020
         TM    PDEUSER,PDECONVD         HAS PDE BEEN CONVERTED          14950020
         BZ    CONVPDE                  NO, CONVERT PDE                 15000020
         LA    R3,ONE(ZERO,R3)          SET INDICATOR FOR PDE           15050020
*                                          CONVERTED                    15100020
         SPACE                                                          15150020
MOREPDES EQU   *                        ARE THERE MORE PDE'S            15200020
         L     R11,PDE2CHAI             R11=PDE CHAIN CONTENTS          15250020
         LA    R11,ZERO(R11)            CLEAR HIGH ORDER BYTE           15300020
         LTR   R11,R11                  IS CHAIN FIELD EMPTY            15350020
         BNZ   WASITCVD                 NO, CHECK FOR PDE CONVERTED     15400020
         LTR   R3,R3                    WAS AT LEAST ONE PDE            15450020
*                                          CONVERTED                    15500020
         BZ    EXITOK                   NO, RETURN TO MAINLINE          15550020
         SPACE                                                          15650020
BLDBREAK EQU   *                        PREPARE TO GO TO SUBROUTINE TO  15700020
*                                          BUILD BREAK ELEMENTS         15750020
         L     R1,TSTANSPL              R1=ADDRESS OF PDL               15800020
         BAL   R14,BREAKRTN             BRANCH TO BUILD BREAK ELEMENT   15850020
         LTR   R15,R15                  WAS BREAK REQUEST HANDLED OK    15900020
         BNZ   NOBREAK                  NO, PUT OUT MESSAGE             15950020
         SPACE                                                          16000020
CODE0    EQU   *                        SET RETURN CODE TO ZERO         16050020
         XR    R15,R15                  ZERO REGISTER                   16100020
         B     RETMAIN                  PREPARE TO RETURN TO MAINLINE   16150020
         SPACE                                                          16200020
NOBREAK  EQU   *                        SUBROUTINE WAS UNABLE TO        16500020
*                                          ESTABLISH BREAKPOINT         16550020
         LA    R4,SIXTEEN               R4=16 - ATTENTION INDICATOR     16600020
         CLR   R4,R15                   DID SUBROUTINE FIND ATTN        16650020
*                                          SCHEDULED                    16700020
         BE    RETMAIN                  YES, RETURN TO MAINLINE         16750020
         B     CODE0                    NO, SET CODE TO ZERO            16800020
         SPACE                                                          16850020
CONVPDE  EQU   *                        ADDRESS PDE MUST BE SENT TO     16900020
*                                          CONVERT TO ESTABLISH A       16950020
*                                          BINARY ADDRESS               17000020
         LCR   R1,R11                   R1=COMPLEMENT OF ADDRESS OF PDE 17050020
*                                          TO INDICATE ADDRESS CONVERT  17100020
         XR    R0,R0                    R0=ZERO TO INDICATE CONVERT TO  17150020
*                                          BINARY                       17200020
         L     R15,TSTCONVT             R15=ADDRESS OF CONVERT ROUTINE  17250020
         OI    TSTFLGS1,RANGESW         TELL CONVERT A RANGE IS         17300020
*                                          POSSIBLE                     17350020
         BALR  R14,R15                  GO TO CONVERT                   17400020
         LTR   R15,R15                  WAS CONVERT SUCCESSFUL          17450020
         BNZ   WHYNOT                   NO, FIND OUT WHY NOT            17500020
         TM    PDEUSER,PDESIB           IS ADDRESS IN USERWORD          17550020
         BZ    TRYRANGE                 YES, CHECK FOR RANGE            17600020
         L     R2,PDEUSER               R2=POINTER TO SI BLOCK          17650020
         MVC   PDEUSER(L4),ZERO(R2)     MOVE BINARY ADDRESS TO USERWORD 17700020
         SPACE                                                          17750020
TRYRANGE EQU   *                        MAKE CERTAIN BINARY ADDRESS IN  17800020
*                                          SECOND HALF OF PDE IF RANGE  17850020
*                                          SPECIFIED                    17900020
         OC    PDE2USER(L4),PDE2USER    WAS RANGE GIVEN                 17950020
         BZ    TESTBND                  NO, CHECK BOUNDARY              18000020
         TM    PDE2USER,PDESIB          DOES USERWORD POINT TO A BINARY 18050020
*                                          ADDRESS                      18100020
         BZ    CHKORDER                 NO, TEST FOR FIRST ADDRESS      18150021
*                                          LESS THAN SECOND             18200021
         L     R2,PDE2USER              R2=POINTER TO SI BLOCK          18250020
         MVC   PDE2USER(L4),ZERO(R2)    MOVE BINARY ADDRESS TO USERWORD 18300020
         SPACE                                                          18350020
CHKORDER EQU   *                        CHECK FOR FIRST ADDRESS OF      18400020
*                                          RANGE LESS THAN SECOND       18450020
         CLC   USER1(L3),USER2          IS FIRST ADDRESS LOW            18500020
         BH    BADORDER                 NO, PUT OUT MESSAGE      A46741 18550021
         TM    BOUNDARY,BADBOUND        IS FIRST ADDRESS FOR HALFWORD   18600020
*                                          BOUNDARY                     18650020
         BNO   FLAGOK                   YES, FLAG PDE CONVERTED         18700020
         SPACE                                                          18750020
OFFBOUND EQU   *                        SET UP MESSAGE FOR ADDRESS NOT  18800020
*                                          ON HALFWORD BOUNDARY         18850020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     18900020
         LA    R1,MSG10(ZERO,R1)        INDEX FOR PROPER MESSAGE        18950020
         B     FIXSTRNG                 ADD ADDRESS STRING TO MESSAGE   19000020
         SPACE                                                          19050020
BADORDER EQU   *                        SET UP MESSAGE FOR FIRST        19100020
*                                          ADDRESS OF RANGE MUST BE     19150020
*                                          LESS THAN SECOND             19200020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     19250020
         LA    R1,MSG2(ZERO,R1)         INDEX FOR PROPER MESSAGE        19300020
         SPACE                                                          19350020
FIXSTRNG EQU   *                        ADD ADDRESS STRING TO MESSAGE   19400020
         LR    R0,R11                   R0=ADDRESS OF ADDRESS PDE       19450020
         BAL   R5,BLDMSG                INSERT INVALID ADDRESS INTO     19500020
*                                          MESSAGE                      19550020
         BAL   R5,PUTMSG                PUT OUT ERROR MESSAGE           19600020
         B     MOREPDES                 CHECK FOR MORE PDES             19650020
         SPACE                                                          19700020
FLAGOK   EQU   *                        FLAG PDE CONVERTED              19750020
         OI    PDEUSER,PDECONVD         SET FLAG                        19800020
         LA    R3,ONE(ZERO,R3)          SET INDICATOR FOR PDE CONVERTED 19850020
         B     MOREPDES                 CHECK FOR MORE PDES             19900020
         SPACE                                                          19950020
TESTBND  EQU   *                        IS SINGLE ADDRESS ON HALFWORD   20000020
*                                          BOUNDARY                     20050020
         TM    BOUNDARY,BADBOUND        IS BOUNDARY OK                  20100020
         BNO   FLAGOK                   YES, FLAG PDE CONVERTED         20150020
         L     R1,MSGADDR               NO, PREPARE MESSAGE             20200020
         LA    R1,MSG3(R1)              R1=POINTER TO MESSAGE POINTER   20250020
         B     FIXSTRNG                 ADD ADDRESS STRING TO MESSAGE   20300020
         SPACE                                                          20350020
WHYNOT   EQU   *                        FIND OUT WHY CONVERT FAILED     20400020
         LA    R2,SIXTEEN               R2=SIXTEEN                      20450020
         CLR   R2,R15                   WAS ATTENTION SCHEDULED         20500020
         BE    RETMAIN                  YES, RETURN TO MAINLINE         20550020
         NI    PDEUSER,HEXFF-PDECONVD   INSURE CONVERTED FLAG IS OFF    20560020
         B     MOREPDES                 IKJEGSYM WILL HAVE PUT OUT A    20600020
*                                          MESSAGE IF IT WERE UNABLE    20650020
*                                          TO RESOLVE THE ADDRESS -     20700020
*                                          CHECK FOR MORE PDE'S         20750020
         SPACE                                                          20800020
BLDMSG   EQU   *                        PREPARE INVALID ADDRESS MESSAGE 20850020
         L     R2,OUTBUF                R2=POINTER TO OUTPUT BUFFER     20900020
         MVC   FOUR(L4,R2),FOUR(R1)     MOVE ADDRESS OF SECOND LEVEL    20950020
*                                          MESSAGE TO BUFFER            21000020
         LA    R6,EIGHT(R2)             R6=POINTER TO FIRST LEVEL       21050020
*                                          MESSAGE FOR OUTPUT           21100020
         ST    R6,ZERO(R2)              PUT POINTER INTO BUFFER         21150020
         L     R1,ZERO(R1)              R1=POINTER TO FIRST LEVEL MSG   21200020
         TM    PDE2FLG2,ONBIT           ENTRYNAME OF RANGE GIVEN        21250020
         BO    BLD2                     YES, MOVE FIRST LEVEL MESSAGE   21300020
*                                          TO BUFFER                    21350020
         TM    PDE2FLG3,ONBIT           STRING OF RANGE GIVEN           21400020
         BO    BLD2                     YES, MOVE FIRST LEVEL MESSAGE   21450020
*                                          TO BUFFER                    21500020
         MVC   EIGHT(L30,R2),ZERO(R1)   MOVE FIRST LEVEL MESSAGE TO     21550020
*                                          BUFFER                       21600020
         LA    R1,THIRTY(R6)            R1=POINTER TO AREA FOR ADDRESS  21650020
*                                          STRING TO BE BUILT           21700020
         SPACE                                                          21750020
GOSTRING EQU   *                        GO BUILD STRING                 21800020
         L     R15,TSTADDR              R15=ADDRESS OF ROUTINE TO BUILD 21850020
*                                          ADDRESS STRING               21900020
         BALR  R14,R15                  GO BUILD MESSAGE                21950020
         LH    R6,ZERO(R6)              R6=LENGTH OF MESSAGE            22000020
         AR    R6,R0                    R6=LENGTH OF MESSAGE WITH       22050020
*                                          ADDRESS STRING               22100020
         LR    R4,R6                    R4=TOTAL LENGTH OF MSG          22150020
         LA    R4,EIGHT(R4)             ACCOUNT FOR TWO PREFACE WORDS   22200020
         AR    R4,R2                    POINTER TO END OF MSG           22250020
         MVI   ZERO(R4),PLUS            MOVE PLUS SIGN TO END OF        22300020
*                                          MSG TO DENOTE FIRST LEVEL    22350020
         LA    R6,ONE(R6)               INCREMENT TOTAL LENGTH COUNT    22400020
         STH   R6,EIGHT(R2)             SAVE IN MESSAGE                 22450020
         LR    R1,R2                    R1=POINTER TO MESSAGE ADDRESS   22500020
         BR    R5                       RETURN TO CALLER                22550020
         SPACE                                                          22600020
BLD2     EQU   *                        MOVE FIRST LEVEL RANGE          22650020
*                                          MESSAGE TO BUFFER            22700020
         MVC   EIGHT(L46,R2),ZERO(R1)   MOVE FIRST LEVEL MESSAGE        22750020
         LA    R1,FORTY6(R6)            R1=POINTER TO AREA FOR          22800020
*                                          ADDRESS STRING TO BE BUILT   22850020
         B     GOSTRING                 GO BUILD STRING                 22900020
         SPACE                                                          22950020
FROMDEFR EQU   *                        THIS ROUTINE IS ENTERED TO MAKE 23000020
*                                          ACTIVE BREAKPOINTS FOR A     23050020
*                                          LOAD MODULE BROUGHT INTO     23100020
*                                          CORE                         23150020
         TM    LOADATTR,OVLYBIT         IS LOAD MODULE IN OVERLAY       23160020
         BO    FIXSYMSW                 YES, TELL SYM NOT TO PRINT MSGS 23170020
         SPACE                                                          23180020
HANDLED  EQU   *                        HANDLE DEFER BREAKPOINTS        23190020
         OC    DEFERTAB(L4),DEFERTAB    IS THE DEFER QUEUE EMPTY        23200020
         BZ    CODE4                    YES, RETURN TO MAINLINE WITH A  23250020
*                                          CODE OF FOUR                 23300020
         L     R8,DEFERTAB              R8=POINTER TO FIRST DME         23350020
         SPACE                                                          23400020
CHKMATCH EQU   *                        COMPARE LOADNAMES               23450020
         CLC   LDNAME(L8),DMELOAD(R8)   DOES THE DME LOADNAME           23500020
*                                          EQUAL THE INPUT LOADNAME     23550020
         BNE   MOREDMES                 NO, CHECK FOR MORE DME'S        23600020
         L     R7,DMEDBE(ZERO,R8)       R7=POINTER TO FIRST DBE         23650020
         SPACE                                                          23700020
ACCESS   EQU   *                        GET ADDR OF FIRST ADDR PDE      23750020
         L     R11,DBEPDL(ZERO,R7)      R11=POINTER TO PDL              23800020
         DROP  R11                                                      23850020
         USING IKJPARMD,R11             ESTABLISH ADDRESSABILITY TO PDL 23900020
         LA    R11,ADDR                 R11=ADDRESS OF ADDRESS PDE      23950020
         DROP  R11                                                      24000020
         USING IKJPARMA,R11             ESTABLISH ADDRESSABILITY TO     24050020
*                                          ADDRESS PDE                  24100020
         XR    R3,R3                    INITIALIZE INDICATOR FOR        24150020
*                                          CONVERTED PDES               24200020
         SPACE                                                          24250020
CONVDEFR EQU   *                        CONVERT PDE'S ON DEFER QUEUE    24300020
*                                          FOR ONE DBE                  24350020
         TM    PDEUSER,PDEYECH          CHECK FOR USELESS PDE           24360020
         BO    ANOTHER                  IF SO, GET ANOTHER PDE          24370020
         SPACE                                                          24380020
         OI    TSTFLGS1,RANGESW         TELL CONVERT A RANGE IS         24400020
*                                          POSSIBLE                     24450020
         LCR   R1,R11                   LOAD COMPLEMENT OF ADDRESS OF   24650020
*                                          PDE FOR ADDRESS CONVERT      24700020
         XR    R0,R0                    INDICATE BINARY CONVERT         24750020
         L     R15,TSTCONVT             R15=ADDRESS OF CONVERT ROUTINE  24800020
         BALR  R14,R15                  CONVERT PDE                     24850020
         LTR   R15,R15                  WAS CONVERSION OK               24900020
         BNZ   SETUSER                  NO, INSURE CONVERTED FLAG IS    24950020
*                                          OFF                          24952020
         TM    PDEUSER,PDESIB           IS BINARY ADDR IN USERWORD      24960020
         BZ    ASKRANGE                 YES, CHECK FOR ADDR RANGE       25000020
         L     R6,PDEUSER               R6=POINTER TO SI BLOCK          25050020
         MVC   PDEUSER(L4),ZERO(R6)     MOVE BINARY ADDRESS TO USERWORD 25100020
         SPACE                                                          25150020
ASKRANGE EQU   *                        SEE IF SECOND USERWORD CONTAINS 25200020
*                                          A BINARY ADDRESS             25250020
         OC    PDE2USER(L4),PDE2USER    WAS RANGE GIVEN                 25300020
         BZ    BNDTEST                  NO, CHECK BOUNDARY              25350020
         TM    PDE2USER,PDESIB          DOES USERWORD POINT TO SI BLOCK 25400020
         BZ    TSTORDER                 NO, TEST FOR FIRST ADDRESS      25450020
*                                          LESS THAN SECOND             25500020
         L     R6,PDE2USER              R6=POINTER TO SI BLOCK          25550020
         MVC   PDE2USER(L4),ZERO(R6)    MOVE BINARY ADDRESS TO USERWORD 25600020
         SPACE                                                          25650020
TSTORDER EQU   *                        CHECK FOR FIRST ADDRESS OF      25700020
*                                          RANGE LESS THAN SECOND       25750020
         CLC   USER1(L3),USER2          IS FIRST ADDRESS LOW            25800020
         BH    ORDERBAD                 NO, PUT OUT MESSAGE      A46741 25850021
         TM    BOUNDARY,BADBOUND        IS FIRST ADDRESS FOR HALF-WORD  25900020
*                                          BOUNDARY                     25950020
         BNO   FLAGPDE                  YES, FLAG PDE CONVERTED         26000020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     26050020
         LA    R1,MSG10(R1)             INDEX FOR PROPER MESSAGE        26100020
         SPACE                                                          26150020
FIXMSG   EQU   *                        ADD ADDRESS STRING TO MESSAGE   26200020
         LR    R0,R11                   R0=ADDRESS OF ADDRESS PDE       26250020
         BAL   R5,BLDMSG                ADD ADDRESS STRING              26300020
         BAL   R5,PUTMSG                PUT OUT MESSAGE                 26350020
         B     ANOTHER                  CHECK FOR MORE PDES             26400020
         SPACE                                                          26410020
FIXSYMSW EQU   *                        TELL SYM NOT TO PRINT MSGS      26420020
         OI    TSTFLGS3,SYMMESG          SET SWITCH IN TCOMTAB          26430020
         B     HANDLED                  SET DEFER BREAKPOINTS           26440020
         SPACE                                                          26450020
ORDERBAD EQU   *                        SET UP MESSAGE FOR FIRST        26500020
*                                          ADDRESS OF RANGE MUST BE     26550020
*                                          LESS THAN SECOND             26600020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     26650020
         LA    R1,MSG2(ZERO,R1)         INDEX FOR PROPER MESSAGE        26700020
         B     FIXMSG                   ADD ADDRESS STRING TO MESSAGE   26750020
         SPACE                                                          26800020
BNDTEST  EQU   *                        IS SINGLE ADDRESS ON HALF-WORD  26850020
*                                          BOUNDARY                     26900020
         TM    BOUNDARY,BADBOUND        IS BOUNDARY OK                  26950020
         BNO   FLAGPDE                  YES, FLAG PDE CONVERTED         27000020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     27050020
         LA    R1,MSG3(R1)              INDEX FOR MESSAGE FOR ADDRESS   27100020
*                                          NOT ON HALF-WORD BOUNDARY    27150020
         B     FIXMSG                   ADD ADDRESS STRING TO MESSAGE   27200020
         SPACE                                                          27250020
FLAGPDE  EQU   *                        FLAG PDE CONVERTED              27300020
         OI    PDEUSER,PDECONVD         SET FLAG                        27350020
         LA    R3,ONE(ZERO,R3)          SET INDICATOR FOR PDE CONVERTED 27400020
         SPACE                                                          27450020
ANOTHER  EQU   *                        CHECK FOR MORE PDE'S            27500020
         L     R11,PDE2CHAI             R11=PDE CHAIN CONTENTS          27550020
         LA    R11,ZERO(R11)            CLEAR HIGH ORDER BYTE           27600020
         LTR   R11,R11                  IS CHAIN EMPTY                  27650020
         BNZ   CONVDEFR                 NO, CONVERT NEXT PDE            27700020
         LTR   R3,R3                    IS AT LEAST ONE PDE CONVERTED   27750020
         BZ    DBELINK                  NO, CHECK FOR MORE DBE'S        27800020
         L     R1,DBEPDL(ZERO,R7)       R1=POINTER TO PDL               27850020
         BAL   R14,BREAKRTN             BRANCH TO BUILD BREAK ELEMENTS  27900020
         SPACE                                                          27950020
DBELINK  EQU   *                        CHECK FOR MORE DBE'S            28000020
         OC    DBEDBE(L4,R7),DBEDBE(R7) IS DBE LINK FIELD ZERO          28050020
         BZ    CODE4                    YES, RETURN TO MAINLINE WITH    28100020
*                                          CODE OF FOUR                 28150020
         L     R7,DBEDBE(ZERO,R7)       R7=POINTER TO NEXT DBE          28200020
         B     ACCESS                   ACCESS FIRST ADDRESS PDE        28250020
         SPACE                                                          28300020
SETUSER  EQU   *                        INSURE FLAG FOR PDE CONVERTED   28350020
*                                          IS NOT ON                    28400020
         MVI   PDEUSER,ZERO             INSURE X'FF' MADE ZERO          28450020
         B     ANOTHER                  CHECK FOR MORE PDE'S            28500020
         SPACE                                                          28650020
MOREDMES EQU   *                        TEST FOR MORE DME'S             28700020
         OC    DMEDME(L4,R8),DMEDME(R8) IS LINK FIELD EMPTY             28750020
         BZ    CODE4                    YES, RETURN WITH CODE OF FOUR   28800020
         L     R8,DMEDME(ZERO,R8)       R8=ADDRESS OF NEXT DME          28850020
         B     CHKMATCH                 BRANCH TO COMPARE DME LOADNAME  28900020
*                                          WITH INPUT                   28950020
         SPACE                                                          29000020
CODE4    EQU   *                        SET RETURN CODE TO FOUR FOR     29050020
*                                          THE PROBLEM PROGRAM TO       29100020
*                                          BE CONTINUED                 29150020
         NI    TSTFLGS3,HEXFF-SYMMESG   TURN OFF SYM MSG SWITCH         29200020
         NI    TSTFLGS1,SETOFF          TURN OFF TSTBUILD FLAG          29250020
         LA    R15,FOUR                 SET CODE TO FOUR                29260020
         B     RETMAIN                  RETURN TO MAINLINE              29300020
         SPACE                                                          29350020
TRANSFER EQU   *                        TRANSFER CONTROL TO THE SECOND  29400020
* LOAD MODULE OF IKJEGAT TO HANDLE THE DEFER REQUEST                    29450020
         SPACE 3                                                        29452020
*        THIS XCTL USES THE BLDL ENTRY FOR IKJEGATD WHICH WAS CREATED   29460020
*        BY MAINLINE IN INITIALIZATION. THIS BLDL ENTRY SHOULD IMPROVE  29470020
*        PERFORMANCE OF SUB-COMMANDS XCTLING BETWEEN LOAD MODULES.      29480020
         SPACE 2                                                        29490020
         LA    R1,ATD           PTR TO CONSTANT NAME                    29492020
         L     R15,TSTEXPAN     ADDRESS OF EXPANSION ROUTINE            29494020
         BALR  R14,R15          GO DO EXPANDING                         29496020
         LTR   R6,R1            WAS BLDL ENTRY RETURNED                 29498020
SMTXCTL1 BZ    NOBLDL                   BRANCH IF NOT.                  29498220
         MVC   XCTLL(XCTLEN),XLIST      MOVE LIST FORM OF XCTL TO WORK  29498520
*                                          AREA                         29498620
         ST    R10,XCTLPARM             SAVE ADDRESS OF WORK AREA IN    29498720
*                                          XCTL PARAMETER LIST          29498820
         ST    R11,PDEADDR              SAVE ADDRESS OF FIRST ADDR PDE  29499220
         LA    R1,XCTLPARM              R1=ADDRESS OF PARAMETER LIST    29499320
         LA    R15,XCTLL                R15=ADDRESS OF LIST FORM OF     29499420
*                                          MACRO                        29501520
         L     R13,FOUR(ZERO,R13)       RESTORE R13                     29503520
         L     R14,TWELVE(R13)          RESTORE R14                     29503920
         MVC   RETRY1(L3),MAINTRY1      RESTORE ADDR OF MAINLINE'S      29507120
*                                          RETRY ROUTINE                29507520
         OI    TSTFLGS2,TSTXCTL         SET BIT FOR AT XCTL'S           29507920
         XCTL  (2,12),DE=(6),SF=(E,(15))  TO SECOND LOAD.               29510920
         SPACE 2                                                        29514120
*        THE FOLLOWING XCTL IS EXECUTED IF THE BLDL ISSUED BY MAINLINE  29517320
*        WAS NOT SUCCESSFUL AND THE BLDL ENTRY IS NOT AVAILABLE FOR     29520520
*        USE IN THE XCTL.                                               29523720
         SPACE 2                                                        29526920
NOBLDL   DS    0H                                                       29530120
         MVC   XCTLL(XCTLEN),XLIST      MOVE LIST FORM OF XCTL TO WORK  29533320
*                                          AREA                         29550020
         ST    R10,XCTLPARM             SAVE ADDRESS OF WORK AREA IN    29650020
*                                          XCTL PARAMETER LIST          29700020
         ST    R11,PDEADDR              SAVE ADDRESS OF FIRST ADDR PDE  29750020
         LA    R1,XCTLPARM              R1=ADDRESS OF PARAMETER LIST    29800020
         LA    R15,XCTLL                R15=ADDRESS OF LIST FORM OF     29850020
*                                          MACRO                        29900020
         L     R13,FOUR(ZERO,R13)       RESTORE R13                     29950020
         L     R14,TWELVE(R13)          RESTORE R14                     30000020
         MVC   RETRY1(L3),MAINTRY1      RESTORE ADDR OF MAINLINE'S      30002020
*                                          RETRY ROUTINE                30004020
         OI    TSTFLGS2,TSTXCTL         SET BIT FOR AT XCTL'S           30010020
* TRANSFER CONTROL TO THE SECOND LOAD MODULE OF AT                      30050020
         XCTL  (2,12),EP=IKJEGATD,MF=(E,(1)),SF=(E,(15))                30100020
SMTXCTL2 DS    0X                       FOR SMT TEST CASES.             30120020
         SPACE                                                          30150020
         SPACE                                                          30300020
*********************************************************************** 30400020
*        THE FOLLOWING INSTRUCTIONS CONSTITUTE A CLOSED SUBROUTINE FOR  30450020
*        CREATING ACTIVE BREAKPOINTS FROM PDL'S PASSED FROM EITHER THE  30500020
*        MAIN PROCESSING SECTION OF 'AT', OR FROM THE 'DEFER' PROCES-   30550020
*        SING SECTION. PDL'S MUST CONTAIN ADDRESS PDE'S WHICH HAVE AL-  30600020
*        READY BEEN SENT TO THE CONVERT ROUTINE(IKJEGCVT) AND WHICH     30650020
*        CONTAIN THE ACTUAL BINARY ADDRESS IN THE USER WORD OF THE PDE. 30700020
*        INPUT WILL CONSIST OF THE PDL ADDRESS IN REGISTER 1, TCOMTAB   30750020
*        ADDRESS IN REGISTER 9, PROGRAM BASE IN REGISTER 12, A RETURN   30800020
*        ADDRESS IN REGISTER 14 AND A SAVE AREA ADDRESS IN REGISTER 13. 30850020
*                                                                       30900020
*********************************************************************** 30950020
         DROP  R11                                                      31000020
         SPACE                                                          31050020
BREAKRTN EQU   *              BEGINNING OF SUBROUTINE                   31100020
         SAVE  (14,12)        SAVE CALLER'S REGISTERS.                  31150020
         L     R8,WORKAREA    R8=COMMON WORK AREA ADDR.                 31200020
         USING TSTCWORK,R8    WORK AREA ADDRESSABILITY.                 31250020
         LA    R4,CWORKCMD    R4=REGSAVE AREA FOR SUBROUTINE.           31300020
         ST    R4,EIGHT(R13)  STORE FORWARD POINTER.                    31350020
         ST    R13,FOUR(R4)   STORE BACKWARD POINTER.                   31400020
         LR    R13,R4         R13=NEW SAVE AREA ADDR.                   31450020
         DROP  R10                                                      31500020
         USING WORKSP,R13     GET ADDRESSABILITY TO WORKAREA            31550020
         USING IKJPARMD,R1    PDL ADDRESSABILITY.                       31600020
         LA    R10,ADDR       R10=ADDRESS PDE ADDR.                     31650020
         USING IKJPARMA,R10   PDE ADDRESSABILITY.                       31700020
         SPACE                                                          31750020
TESTCONV EQU   *              CHECK FOR CONVERTED PDE                   31800020
         TM    PDEUSER,PDECONVD  HAS PDE BEEN CONVERTED                 31850020
         BO    SUPRLOOP       YES, TRY FOR PROTECTION CHECK             31900020
         L     R10,PDE2CHAI   R10=CHAIN POINTER FOR ADDR LIST           31950020
         LA    R10,ZERO(R10)  CLEAR HIGH ORDER BYTE                     32000020
         LTR   R10,R10        Q.IS A LIST POINTER PRESENT               32050020
         BZ    ROUTRTN        NO, RETURN                                32100020
         B     TESTCONV       CHECK FOR THIS PDE CONVERTED              32150020
         SPACE                                                          32200020
SUPRLOOP EQU   *              GET STORAGE REQUIRED FOR BRK. ELEMENT     32250020
         L     R2,PDEUSER     R2=STORAGE ADDR TO SET BREAKPOINT.        32300020
         OC    ZERO(L2,R2),ZERO(R2)     TRY FOR PROT CHECK              32350020
         SPACE                                                          32400020
BLOW1    EQU   *              RESUME ADDR IF PROTECTION CHECK OCCURS    32450020
         LA    R2,ZERO(R2)    CLEAR HIGH ORDER BYTE                     32500020
         BAL   R11,SIZECALC   CALCULATE SIZE FOR GETMAIN.               32550020
* SIZE FOR GETMAIN IS RETURNED IN REGISTER ZERO.                        32600020
         LR    R0,R1          R1=NUMBER BYTES REQUIRED                  32650020
         O     R0,SP1         INDICATE SUBPOOL 1.                       32700020
         ST    R0,BYTENUMB    SAVE IN WORKAREA                          32750020
         GETMAIN R,LV=(0)     GET STORAGE REQUIRED FOR BRK ELEMENT.     32800020
SMTGET01 DS    0X                       FOR SMT TEST CASES.             32820020
         SPACE                                                          32850020
BLOW2    EQU   *              HERE'S THE RESUME ADDR IF THE GETMAIN     32900020
* BLOWS FOR LACK OF STORAGE.                                            32950020
         LR    R3,R1          R3=BREAK ELEMENT ADDR.                    33000020
         USING BRKELEM,R3     BREAK ELEMENT ADDRESSABILITY.             33050020
         XC    BRKELEM(BRKLEN),BRKELEM  ZERO BREAK ELEMENT              33100020
         LA    R4,BRKLEN(R3)  R4=ADDR STRING SAVE ADDR.                 33150020
         SPACE                                                          33200020
*        THE FOLLOWING INSTRUCTIONS BUILD THE ADDRESS STRING AS ENTERED 33250020
*        BY THE USER INTO THE ADDRESS STRING SAVE AREA FOR THIS BREAK-  33300020
*        POINT.                                                         33350020
         LA    R1,TWO(R4)     R1=SAVE AREA POINTER FOR BUILD.           33400020
         LCR   R1,R1          SET REGISTER NEGATIVE TO TELL BUILD       33450020
*                                ROUTINE THAT A MAXIMUM OF 100          33500020
*                                BYTES TO BE BUILT                      33550020
         LR    R0,R10         R0=ADDRESS OF ADDRESS PDE                 33600020
         L     R15,TSTADDR    R15=ADDRESS OF ADDRESS STRING             33650020
*                                BUILD ROUTINE                          33700020
         BALR  R14,R15        GO TO BUILD ROUTINE                       33750020
         STH   R0,ZERO(R4)    SAVE LENGTH OF STRING                     33800020
         SPACE                                                          33850020
CHNSAVE  EQU   *              HANDLE SUBCOMMAND CHAIN                   33900020
         TM    PDEUSER,PDEADLST Q.IS PDE FLAGGED AS A LIST PDE.         33950020
         BO    GOBUILD        YES, DON'T CHECK FOR CHAIN                34000020
         LA    R5,SEVEN(R1)   SET CHAIN SAVE ADDRESS REGISTER           34050020
         N     R5,DBLBND      ROUND UP TO DOUBLE WORD FOR FREEMAIN      34100020
         ST    R5,CHNADDR     SAVE IN WORK AREA                         34150020
         L     R1,FOUR(R13)   R1=ADDRESS OF CALLER'S SAVE AREA          34200020
         L     R1,TWENTY4(R1) R1=PDL POINTER                            34250020
         L     R7,SBCMDCHN    R7=CHAIN STRING ADDRESS.                  34300020
         LA    R7,ZERO(R7)    CLEAR HIGH ORDER BYTE                     34350020
         LTR   R7,R7          Q.IS A CHAIN SPECIFIED.                   34400020
         BZ    NOCHAIN        NO, BUILD THE BREAK ELEMENT.              34450020
         LH    R6,SBCMDLEN    R6=LENGTH OF COMMAND CHAIN                34500020
         STH   R6,ZERO(R5)    PLACE CHAIN LENGTH IN SAVE AREA.          34550020
         BCTR  R6,ZERO        DECREMENT R6 FOR EXECUTE.                 34600020
         EX    R6,CHNMVC      MOVE CHAIN TO SAVE AREA.                  34650020
         LA    R6,THREE(R6)   R6=LENGTH OF COMMAND CHAIN+LENGTH FIELD   34700020
         ALR   R6,R5          R6=POINTER TO LAST BYTE OF CHAIN SAVE     34750020
*                                AREA                                   34800020
         XC    ZERO(L1,R6),ZERO(R6) ZERO LAST BYTE                      34850020
         B     GOBUILD        BUILD BREAK ELEMENT                       34900020
         SPACE                                                          34950020
CHNMVC   MVC   TWO(ONE,R5),ZERO(R7) EXECUTE MVC FOR COMMAND CHAINS.     35000020
         SPACE                                                          35050020
NOCHAIN  EQU   *              NO CHAIN SAVE ADDRESS                     35100020
         SR    R5,R5          ZERO REGISTER                             35150020
         ST    R5,CHNADDR     SAVE IN WORK AREA                         35200020
         SPACE                                                          35250020
GOBUILD  EQU   *                                                        35300020
         BAL   R11,BUILD      BUILD BREAK ELEMENT.                      35350020
         SPACE                                                          35400020
NEXTCHAI EQU   *              EXAMINE CHAIN FIELD                       35450020
         L     R10,PDE2CHAI   R10=CHAIN POINTER FOR ADDR LIST.          35500020
         LA    R10,ZERO(R10)  CLEAR HIGH ORDER BYTE.                    35550020
         LTR   R10,R10        Q.IS A LIST POINTER PRESENT.              35600020
         BZ    ROUTRTN        NO, ALL DONE, RETURN.                     35650020
         TM    PDEUSER,PDECONVD  Q.WAS PDE CONVERTED                    35700020
         BZ    NEXTCHAI       NO, ARE MORE PDE'S CHAINED                35750020
         OI    PDEUSER,PDEADLST FLAG THE PDE AS A MEMBER OF A LIST.     35800020
         B     SUPRLOOP       CALCULATE SIZE, BUILD BREAKPOINT.         35850020
         SPACE                                                          35900020
SIZECALC EQU   *              THIS SERIES OF INSTRUCTIONS CALCULATES    35950020
*THE SIZE REQUIRED FOR A SPECIFIC BREAKPOINT, COMPRISING BREAK          36000020
*ELEMENT, ADDRESS STRING SAVE AREA AND COMMAND CHAIN SAVE AREA.         36050020
         SPACE                                                          36100020
         DROP  R1                                                       36150020
         USING IKJPARMD,R7    ESTABLISH ADDRESSABILITY TO PDL IN R7     36200020
         SR    R1,R1          CLEAR ACCUMULATOR.                        36250020
         AH    R1,PDELEN2     R1=CSECT NAME LENGTH.                     36300020
         BZ    ADDRCHK        NO LOAD OR CSECT NAME.                    36350020
         LA    R1,ONE(R1)     BUMP FOR PRECEDING PERIOD.                36400020
         AH    R1,PDELEN1     ADD IN LOAD NAME LENGTH.                  36450020
         TM    PDEFLG3,AFLG   Q.ANY ADDRESS.                            36500020
         BZ    CHNCALC1       NO,  COMPUTE CHAIN LENGTH.                36550020
         LA    R1,ONE(R1)     YES, BUMP FOR TRAILING PERIOD.            36600020
         SPACE                                                          36650020
ADDRCHK  EQU   *              DETERMINE ADDRESS TYPE                    36700020
         TM    PDEFLG4,SYMADDR Q.IS IT ABSOLUTE, RELATIVE OR GENERAL    36750020
*                               REGISTER                                36800020
         BO    ADDADDR        NO, SKIP BUMP FOR PUNCTUATION OR          36850020
*                                LETTER                                 36900020
         LA    R1,ONE(R1)     BUMP FOR PUNCTUATION OR LETTER            36950020
         SPACE                                                          37000020
ADDADDR  EQU   *              CALCULATE CORE NEEDED FOR ADDR STRING     37050020
         AH    R1,PDELEN3     ADD ADDRESS STRING LENGTH.                37100020
         LA    R1,BRKLEN(R1)  ADD BREAK ELEMENT LENGTH.                 37150020
         L     R7,PDEEXPTR    R7=ADDRESS OF 1ST EXPRESSION.             37200020
         AH    R1,PDEINDCT    R1=(BRK+ADDR+IND.COUNT).                  37250020
         SPACE                                                          37300020
CALCLOOP EQU   *              ADD IN CORE FOR EXPRESSION                37350020
         LA    R7,ZERO(R7)    CLEAR HIGH ORDER BYTE                     37400020
         LTR   R7,R7          Q.ANY EXPRESSION.                         37450020
         BZ    CHNCALC        NO, CHECK ON CHAIN.                       37500020
         AH    R1,FOUR(R7)    R1=(BRK+ADDR+EXP LEN).                    37550020
         AH    R1,TEN(R7)     R1=(BRK+ADDR+EXP+IND.COUNT).              37600020
         LA    R1,ONE(R1)     R1=(BRK+ADDR+EXP+IND+SIGN LEN).           37650020
         TM    EXPFLGS5(R7),DECVAL IS EXPRESSION DECIMAL VALUE          37700020
         BZ    KEEPON         NO, CONTINUE                              37750020
         LA    R1,ONE(R1)     R1=(BRK+ADDR+EXP+IND+SIGN LEN).           37800020
         SPACE                                                          37850020
KEEPON   EQU   *              CHECK FOR ANOTHER EXPRESSION PDE          37900020
         L     R7,TWELVE(R7)  R7=NEXT EXPRESSION ADDRESS.               37950020
         B     CALCLOOP       GET 'EM ALL.                              38000020
         SPACE                                                          38010020
CHNCALC1 EQU   *                                                        38020020
         LA    R1,BRKLEN(R1)  ADD BREAK ELEMENT LENGTH.                 38030020
         SPACE                                                          38050020
CHNCALC  EQU   *              ACCOUNT FOR SUBCOMMAND CHAIN              38100020
         CH    R1,MAXLEN2     IS ACCUMULATED LENGTH FOR STRING GREATER  38150020
*                                THAN 100                               38200020
         BH    CHGREG         YES, LIMIT THE LENGTH                     38250020
         SPACE                                                          38300020
CHNCALC2 EQU   *              CALCULATE NEEDS FOR SUBCOMMAND CHAIN      38350020
         L     R7,FOUR(R13)   R7=ADDR OF CALLER'S SAVE AREA             38400020
         L     R7,TWENTY4(R7) R7=PDL ADDRESS                            38450020
         LA    R1,TWO(R1)     ADD IN ADDR SAVE LENGTH FIELD 2 BYTES.    38500020
         TM    PDEUSER,PDEADLST  Q.IS THIS A LIST PDE(NOT THE 1ST).     38550020
         BCR   ONE,R11        YES, DONE, RETURN TO CALLER.              38600020
         LA    R1,SEVEN(R1)   NO, ROUND R1 UP TO DBL BOUND.             38650020
         N     R1,DBLBND      *                                         38700020
         LH    R0,SBCMDCHN+FOUR  GET THE CHAIN LENGTH.                  38720020
         LTR   R0,R0          Q. IS THERE A CHAIN.                      38740020
         BCR   Z,R11          A. NO. RETURN.                            38760020
         ALR   R1,R0          R1=(BRK+ADDR SAVE+CHAIN LEN).             38780020
         LA    R1,THREE(R1)   ADD IN CHAIN SAVE LENGTH FIELD 3 BYTES.   38800020
         BR    R11            RETURN TO CALLER.                         38850020
         SPACE                                                          38900020
CHGREG   EQU   *              LIMIT ADDRESS STRING LENGTH TO 100        38950020
         LH    R1,MAXLEN2     R1=MAXIMUM LENGTH FOR BREAK ELEMENT       39000020
*                                AND ADDRESS STRING                     39050020
         B     CHNCALC2       CLACULATE NEEDS FOR SUBCOMMAND CHAIN      39100020
         DROP  R7                                                       39150020
         USING IKJPARMD,R1    ESTABLISH ADDRESSABILITY TO PDL IN R1     39200020
         SPACE                                                          39250020
BUILD   EQU    *              THIS SERIES OF INSTRUCTIONS BUILDS A      39300020
*BREAK ELEMENT AND SETS A BREAK SVC INTO THE PROBLEM PROGRAM.  IF THE   39350020
*PDE PASSED IS ONE OF A RANGE, ALL BREAK ELEMENTS ARE BUILT FOR THE     39400020
*RANGE AND ALL SVC'S INSERTED IN THE PROBLEM PROGRAM.                   39450020
         SPACE                                                          39500020
         LA    R2,ZERO(R2)    CLEAR HIGH ORDER BYTE OF ADDR             39550020
         LA    R6,BREAKTAB    R6=HEAD OF BREAK ELEMENT CHAIN.           39600020
         L     R7,BREAKTAB    R7=1ST ELEMENT ON CHAIN.                  39650020
         SPACE                                                          39700020
SEQLOOP  EQU   *              EXAMINE CURRENT CHAIN                     39750020
         LTR   R7,R7          Q.ANY MORE ELEMENTS ON CHAIN.             39800020
         BZ    ADDL           NO, ADD CURRENT ELEMENT TO CHAIN.         39850020
         L     R8,BRKADDR-BRKELEM(R7) R8=BRK ADDR OF 1ST BRKPOINT.      39900020
         CR    R8,R2          Q.ADDRESS FOR NEW BREAKPOINT HIGH.        39950020
         BE    DUPLICAT       DUPLICATE BREAK ADDR FOUND                40000020
         BH    ADDL           HIGH, ADD NEW BREAK ELEM HERE.            40050020
         SPACE                                                          40100020
CONTCHK  EQU   *              CONTINUE SEARCHING QUEUE                  40150020
         LA    R6,BRKLINK-BRKELEM(R7) R6=NEW LINK FIELD ADDR.           40200020
         L     R7,BRKLINK-BRKELEM(R7) R7=NEXT BREAK ELEMENT ADDR.       40250020
         B     SEQLOOP        TRY AGAIN.                                40300020
         SPACE                                                          40350020
ADDL     EQU   *              ADJUST POINTERS FOR NEW ELEMENTS          40400020
         ST    R6,SAVEPTR     SAVE LINK FIELD POINTER                   40450020
         ST    R3,ZERO(R6)    PLACE NEW BRK ELEM ADDR IN CHAIN.         40500020
         ST    R7,BRKLINK     HOOK CHAIN TO NEW BRK LINK FIELD.         40550020
         ST    R2,BRKADDR     PLACE INSTR ADDR IN BRK ELEM.             40600020
         ST    R4,BRKNAME     PLACE ADDR SAVE AREA ADDR IN BRKELEM.     40650020
         L     R5,CHNADDR     PICK UP CHAIN SAVE AREA ADDR              40700020
         ST    R5,BRKCHAIN    PLACE CHAIN SAVE AREA ADDR IN BRK ELEM.   40750020
         L     R1,FOUR(R13)   R1=ADDR OF AT'S SAVE AREA                 40800020
         L     R1,TWENTY4(R1) R1=ADDR OF PDL                            40850020
         TM    COUNT+ONE,FF   Q.IS COUNT SPECIFIED.                     40900020
FF       EQU   X'FF'          TEST MASK.                                40950020
         BZ    SKIPCT         NO, LEAVE COUNT FIELD ZERO.               41000020
         L     R1,CONAREA     R1=IKJEGCVT OUTPUT AREA ADDR.             41050020
         MVC   BRKCOUNT(TWO),THREE(R1) SET COUNT FIELD.                 41100020
         MVC   BRKCOUNT+TWO(TWO),THREE(R1) *                            41150020
         SPACE                                                          41200020
SKIPCT   EQU   *              SAVE BREAK INSTRUCTION                    41250020
         MVC   BRKINST+TWO(SIX),INITCON INITIALIZE INSTR. SAVE FIELD.   41300020
         L     R6,PDEUSER     R6=BINARY ADDR FROM PDE.                  41350020
         LA    R6,ZERO(R6)    ZERO HIGH BYTE.                           41400020
         SR    R2,R6          R2=DISP FROM BEGINNING OF RANGE(IF RANGE) 41450020
         STH   R2,BRKDISP     PLACE DISPLACEMENT IN BRK ELEM.           41500020
         L     R2,BRKADDR     RESET R2.                                 41550020
         L     R1,FOUR(R13)   R1=ADDRESS OF CALLER'S SAVE AREA.         41600020
         L     R1,TWENTY4(R1) R1=ADDRESS OF PDL.                        41650020
         TM    NONOT+ONE,TWO  Q.NONOTIFY SPECIFIED.                     41700020
         BZ    NOTIFY         NO, DON'T SET SWITCH.                     41750020
         OI    BRKFLGS,BRKNONOT YES, SET SWITCH.                        41800020
         SPACE                                                          41850020
NOTIFY   EQU   *              CHECK FOR ADDRESS IN A LIST               41900020
         TM    PDEUSER,PDEADLST  Q.IS BREAK ONE OF A LIST.              41950020
         BZ    NOLIST         NO, DON'T SET SWITCH.                     42000020
         OI    BRKFLGS,BRKLIST YES, DO.                                 42050020
         SPACE                                                          42100020
NOLIST   EQU   *              CHECK FOR BAL OR BALR INSTR.              42150020
         CLI   ZERO(R2),BAL   Q.IS IT BAL INSTR.                        42200020
BAL      EQU   X'45'          BAL OP CODE.                              42250020
         BE    BALI           YES, SET BALSW BIT IN BRK ELEM.           42300020
         CLI   ZERO(R2),BALR  Q.IS IT BALR INSTR.                       42350020
BALR     EQU   X'05'          BALR OP CODE.                             42400020
         BNE   LENGTH         NEITHER, CHECK LENGTH.                    42450020
         SPACE                                                          42500020
BALI     EQU   *              SET ELEMENT TO INDICATE BAL               42550020
*                                OR BALR INSTRUCTION                    42600020
         OI    BRKFLGS,BALSW  TURN ON BIT.                              42650020
         SPACE                                                          42700020
LENGTH   EQU   *              DETERMINE INSTRUCTION LENGTH              42750020
         TM    ZERO(R2),LENBITS Q.HOW LONG IS INSTRUCTION.              42800020
LENBITS  EQU   X'C0'          LENGTH BITS OF OP CODE.                   42850020
         BO    SIXBYTE        SIX BYTES.                                42900020
         BM    FOURBYTE       FOUR BYTES.                               42950020
         MVC   BRKINST(TWO),ZERO(R2) SAVE INSTRUCTION.                  43000020
         LA    R2,TWO(R2)     BUMP INSTR ADDR REGISTER.                 43050020
         B     CHECKMOR       CHECK FOR MORE IN RANGE.                  43100020
         SPACE                                                          43150020
FOURBYTE EQU   *              INSTRUCTION LENGTH=4                      43200020
         MVC   BRKINST(FOUR),ZERO(R2) SAVE INSTRUCTION.                 43250020
         LA    R2,FOUR(R2)    BUMP INSTR ADDR REGISTER.                 43300020
         B     CHECKMOR       CHECK FOR MORE IN RANGE.                  43350020
         SPACE                                                          43400020
SIXBYTE  EQU   *              INSTRUCTION LENGTH=6                      43450020
         MVC   BRKINST(SIX),ZERO(R2) SAVE INSTRUCTION.                  43500020
         LA    R2,SIX(R2)     BUMP INSTR ADDR REGISTER.                 43550020
         SPACE                                                          43600020
CHECKMOR EQU   *              DOES INSTR. HAVE VALID OP CODE            43650020
         L     R1,BRKADDR     R1=POINTER TO BREAK INSTR.                43700020
         L     R8,OPCODTAB    R8=POINTER TO TABLE OF OP CODES           43750020
         XR    R7,R7          CLEAR REGISTER                            43800020
         IC    R7,ZERO(R1)    R7=OP CODE OF INSTRUCTION                 43850020
         LA    R6,FIVE        R6=5                                      43900020
         MR    R6,R6          GET INDEX FOR OP CODE TABLE               43950020
         LA    R8,ZERO(R7,R8) R8=ADDRESS FOR OP CODE TEST               44000020
         TM    ZERO(R8),FF    WAS OP CODE VALID                         44050020
         BNZ   OPCODEOK                 BRANCH IF VALID 360 OP CODE     44059020
         SPACE                                                          44068020
         CLI   ZERO(R1),HEXB2           ELSE CHECK FOR 370 OP CODE      44077020
         BNE   BADOPCD                  BRANCH IF INVALID OP CODE       44086020
         CLI   ONE(R1),HEX05            CHECK FOR INVALID 370 OP CODE   44095020
         BH    BADOPCD                  BRANCH IF INVALID               44104020
         CLI   ONE(R1),HEX01            CHECK AGAIN                     44113020
         BNH   BADOPCD                  BRANCH IF INVALID        A43350 44122021
         SPACE                                                          44131020
OPCODEOK EQU   *                        OP CODE IS VALID                44140020
         MVC   ZERO(L2,R1),RSVC SET BREAKPOINT SVC IN INSTR.            44150020
         L     R6,PDE2USER    R6=END OF RANGE(IF RANGE).                44200020
         LA    R6,ZERO(R6)    CLEAR HIGH ORDER BYTE                     44250020
         CR    R2,R6          Q. IS NEXT INSTRUCTION HIGH               44300020
         BCR   TWO,R11        YES, RETURN TO CALLER                     44350020
         OI    BRKFLGS,BRKRANGE NO, WE'RE IN A VALID RANGE.             44400020
         OC    ZERO(TWO,R2),ZERO(R2) VALIDITY CHECK NEW LOCATION.       44450020
         SPACE                                                          44500020
BLOW3    EQU   *              RESUME ADDRESS IN CASE OF PROTECTION      44550020
*                                CHECK                                  44600020
         XR    R0,R0          CLEAR REGISTER                            44650020
         LA    R0,BRKLEN(R0)  R0=LENGTH FOR GETMAIN                     44700020
         O     R0,SP1         INDICATE SUBPOOL 1                        44750020
         ST    R0,BYTENUMB    SAVE IN WORKAREA                          44800020
         GETMAIN R,LV=(0)                                               44850020
SMTGET02 DS    0X                       FOR SMT TEST CASES.             44870020
         SPACE                                                          44900020
BLOW4    EQU   *              RESUME ADDRESS IN CASE OF GETMAIN         44950020
*                                FAILURE                                45000020
         XC    ZERO(BRKLEN,R1),ZERO(R1) CLEAR IT.                       45050020
         OI    BRKFLGS-BRKELEM(R1),BRKRANGE TURN ON RANGE SWITCH.       45100020
         LA    R6,BRKLINK     R6=LINK FIELD ADDR IN PREVIOUS BRK ELEM.  45150020
         L     R7,BRKLINK     R7=CONTENTS OF THAT LINK FIELD.           45200020
         LR    R3,R1          R3=ADDR OF NEW BRK ELEM.                  45250020
         B     SEQLOOP        BUILD IT.                                 45300020
         SPACE                                                          45350020
BADOPCD  EQU   *                        A BAD OP CODE HAS BEEN FOUND    45400020
         L     R1,OUTBUF                R1=ADDRESS OF OUTPUT AREA       45450020
         LA    R8,EIGHT(ZERO,R1)        R8=ADDRESS FOR FIRST LEVEL MSG  45500020
         ST    R8,ZERO(ZERO,R1)         SAVE ADDRESS IN FIRST WORD OF   45550020
*                                          OUTPUT AREA                  45600020
         L     R7,MSGADDR               R7=POINTER TO MESSAGE CSECT     45650020
         OC    USER2(L3),USER2          IS ADDRESS IN A RANGE           45700020
         BNZ   RANGMSG                  YES, BUILD MESSAGE FOR RANGE    45750020
         LA    R7,MSG9(ZERO,R7)         R7=POINTER TO FIRST LEVEL       45800020
*                                          MESSAGE POINTER              45850020
         L     R5,FOUR(ZERO,R7)         R5=POINTER TO SECOND LEVEL MSG  45900020
         ST    R5,FOUR(ZERO,R1)         SAVE IN OUTPUT BUFFER           45950020
         L     R7,ZERO(ZERO,R7)         R7=POINTER TO FIRST LEVEL MSG   46000020
         MVC   ZERO(L69,R8),ZERO(R7)    MOVE FIRST LEVEL MESSAGE TO     46050020
*                                          OUTPUT AREA                  46100020
         LA    R8,FORTY3(ZERO,R8)       R8=POINTER TO STRING IN MSG     46150020
         SPACE                                                          46200020
STRLENG  EQU   *                        GET LENGTH OF STRING            46250020
         LH    R5,ZERO(R4)              R5=LENGTH OF STRING             46300020
         LA    R7,TWENTY6               R7=MAXIMUM ADDRESS LENGTH FOR   46350020
*                                          MESSAGE                      46400020
         CLR   R7,R5                    IS ADDRESS STRING LONGER THAN   46450020
*                                          26 BYTES                     46500020
         BL    EX26                     YES, MOVE ONLY 26 BYTES INTO    46550020
*                                          MESSAGE                      46600020
         SPACE                                                          46650020
DECR     EQU   *                        DECREMENT FOR EXECUTE INSTR.    46700020
         BCTR  R5,ZERO                  DECREMENT BY ONE                46750020
         LR    R7,R4                    R7=ADDR OF STRING               46800020
         LA    R7,TWO(R7)               R7=ADDR OF BEGINNING OF STRING  46850020
         EX    R5,MOVEADDR              MOVE ADDR STRING TO MSG.        46950020
         LA    R5,ONE(R5)               R5=LENGTH OF STRING             46960020
         LA    R8,ZERO(R5,R8)           R8=LENGTH OF MSG. SO FAR        47000020
         MVI   ZERO(R8),PLUS            MOVE IN PLUS SIGN TO DENOTE     47050020
*                                          FIRST LEVEL MSG              47100020
         LA    R5,ONE(R5)               INCREMENT COUNT FOR PLUS SIGN   47150020
         AH    R5,EIGHT(R1)             GET TOTAL LENGTH FOR MSG        47200020
         STH   R5,EIGHT(R1)             SAVE IN MSG                     47250020
         SPACE                                                          47300020
MSGROUTN EQU   *                        PREPARE TO PUT OUT MESSAGE      47350020
         LCR   R1,R1                    LOAD COMPLEMENT TO INDICATE     47400020
*                                          ERROR MSG TO TERMINAL        47450020
         L     R15,TPUTADDR             R15=ADDR OF MESSAGE WRITER      47500020
         BALR  R14,R15                  PUT OUT MESSAGE                 47550020
         LTR   R15,R15                  WAS I/O SUCCESSFUL              47600020
         SPACE                                                          47650020
RESET    EQU   *                        RESET LINK FIELD                47700020
         L     R6,SAVEPTR               R6=POINTER TO PREVIOUS LINK     47750020
*                                          FIELD                        47800020
         MVC   ZERO(L4,R6),BRKLINK      RESET PREVIOUS LINK FIELD       47850020
         L     R0,BYTENUMB              R0=NUMBER OF BYTES LAST GOTTEN  47900020
*                                          AND SUBPOOL NUMBER           47950020
         FREEMAIN R,LV=(0),A=(R3)       FREEMAIN LAST CORE GOTTEN       48000020
         BNZ   RETURNRC                 I/O NOT SUCCESSFUL - RETURN     48050020
         BR    R11                      CHECK FOR MORE ELEMENTS TO      48100020
*                                          BE BUILT                     48150020
         SPACE                                                          48200020
MOVEADDR MVC   ZERO(ZERO,R8),ZERO(R7)   MOVE INSTRUCTION FOR BAD        48250020
*                                          OP CODE MESSAGE              48300020
         SPACE                                                          48350020
EX26     EQU   *                        ADDRESS STRING LONGER THAN 26   48400020
*                                          BYTES                        48450020
         LR    R5,R7                    LIMIT MSG STRING TO 26 BYTES    48500020
         B     DECR                     MOVE IN STRING                  48550020
         SPACE                                                          48600020
RANGMSG  EQU   *                        PREPARE TO PUT OUT MSG FOR      48650020
*                                          INVALID OP CODE IN RANGE     48700020
         LA    R7,MSG8(ZERO,R7)         R7=POINTER TO FIRST LEVEL MSG   48750020
*                                          POINTER                      48800020
         L     R5,FOUR(ZERO,R7)         R5=POINTER TO SECOND LEVEL MSG  48850020
         ST    R5,FOUR(ZERO,R1)         SAVE IN OUTPUT BUFFER           48900020
         L     R7,ZERO(R7)              R7=POINTER TO FIRST LEVEL MSG   48950020
         MVC   ZERO(L98,R8),ZERO(R7)    MOVE MSG TO OUTPUT BUFFER       49000020
         LA    R8,FORTY7(ZERO,R8)       R8=PTR TO DISPLACEMENT PART     49050020
*                                          OF MESSAGE                   49100020
         UNPK  ZERO(L5,R8),BRKDISP(L3)  UNPACK DISPLACEMENT             49150020
         TR    ZERO(L4,R8),TABLE-CZERO  TRANSLATE DISPLACEMENT          49200020
         MVI   FOUR(R8),BLANK           MOVE IN BLANK AFTER DISP.       49250020
         SR    R7,R7                    CLEAR COUNTER FOR NO. BYTES     49300020
*                                          TO SHIFT MESSAGE             49350020
         LA    R5,THREE                 R5=COUNT OF THREE               49400020
         SPACE                                                          49450020
LOOP     EQU   *                        DETERMINE NUMBER BYTES          49500020
*                                          TO SHIFT MESSAGE             49550020
         CLI   ZERO(R8),F0              IS THIS BYTE = 0                49600020
         BNE   OUTLOOP                  NO, PREPARE TO FILL IN ADDRESS  49650020
         MVC   ZERO(L25,R8),ONE(R8)     SHIFT MESSAGE TO LEFT 1 BYTE    49700020
         LA    R7,ONE(R7)               INCREMENT COUNTER FOR NUMBER OF 49750020
*                                          BYTES SHIFTED                49800020
         BCT   R5,LOOP                  CHECK FOR END OF LOOP           49850020
         SPACE                                                          49900020
OUTLOOP  EQU   *                        PREPARE TO FILL IN ADDRESS      49950020
*                                          PART OF MESSAGE              50000020
         LA    R8,TWENTY4(ZERO,R8)      R8=PTR. TO ADDRESS PORTION      50050020
*                                          OF MESSAGE IF NO SHIFTS      50100020
         SR    R8,R7                    R8=PTR TO ADDRESS PORTION       50150020
*                                          OF MESSAGE                   50200020
         SPACE                                                          50250020
* DETERMINE LENGTH OF MESSAGE SO FAR                                    50300020
         LR    R7,R8                    R7=PTR TO ADDRESS PORTION       50350020
         LA    R5,EIGHT(R1)             R5=PTR TO BEGINNING OF MSG      50400020
         SR    R7,R5                    R7=LENGTH OF MSG SO FAR         50450020
         STH   R7,EIGHT(R1)             SAVE LENGTH IN MSG              50500020
         B     STRLENG                  BRANCH TO MOVE ADDR INTO MSG    50550020
         SPACE                                                          50600020
         SPACE                                                          50650020
ROUTRTN  EQU   *                        NORMAL RETURN TO CALLER.        50700020
         SR    R15,R15                  INDICATE NORMAL RETURN.         50750020
         SPACE                                                          50760020
RETURNRC EQU   *                        ABNORMAL RETURN TO CALLER.      50800020
         L     R13,FOUR(R13)            RESET R13 TO RESTORE CALLER'S   50850020
*                                          REGISTERS                    50900020
         RETURN (14,12),RC=(15)         RETURN TO CALLER.               50950020
         SPACE                                                          51000020
DUPLICAT EQU   *                        DUPLICATE BREAK ADDR FOUND      51050020
         MVC   ZERO(L2,R8),INSTBRK(R7)  RESTORE INSTRUCTION             51100020
         OI    BRKFLGS1-BRKELEM(R7),BRKINACT    SET FLAG FOR OLD DUP    51110020
*                                          INACTIVE                     51120020
         B     ADDL                     ADD NEW ELEMENT BEFORE OLD      51150020
*                                          DUPLICATE                    51200020
         SPACE                                                          51210020
INITCON  EQU   *                                                        51250020
         NOPR  R1                       PADDING NOP.                    51300020
         NOPR  R1                       PADDING NOP.                    51350020
RSVC     SVC   TSTSVC                   BREAKPOINT SVC.                 51400020
TSTSVC   EQU   97                       SVC NUMBER                      51450020
         DROP  R13                                                      51500020
         USING WORKSP,R10               GET ADDRESSABILITY TO WORKAREA  51550020
         SPACE                                                          51600020
         ORG   *-4                      REUSE SPACE FOR ZERO COND. CODE 51650020
CHKCODE  EQU   *                        THIS CODE IS ENTERED TO         51700020
*                                          DETERMINE WHY PARSE WAS      51750020
*                                          UNSUCCESSFUL                 51800020
         ORG                                                            51810020
         B     EXITOK1                  USER SPECIFIED NO PROMPT        51850020
         B     SET16                    ATTENTION INTERRUPT             51900020
         B     INVPARM                  AN INVALID PARAMETER WAS USED   51950020
*                                          IN PARSE                     52000020
         B     NOCORE                   INSUFFICIENT CORE               52050020
         B     PICKUP                   GET RETURN CODE FROM WORK AREA  52100020
         SPACE                                                          52110020
EXITOK1  EQU   *                                                        52120020
         OI    TSTFLGS4,TSTFLUSH        INDICATE FLUSH OF STACK.        52130020
         B     EXITOK         RETURN TO IKJEGMNL.                       52140020
         SPACE                                                          52150020
PICKUP   EQU   *                        PICK UP RETURN CODE AND RETURN  52200020
         L     R15,PARSECD              GET RETURN CODE                 52250020
         B     RETMAIN                  RETURN TO MAINLINE              52260020
         SPACE                                                          52300020
NOCORE   EQU   *                        PUT OUT MSG. FOR INSUFFICIENT   52310020
*                                          STORAGE                      52320020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     52350020
         LA    R1,MSG7(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTERS  52400020
         SPACE                                                          52450020
GOMSG    EQU   *                        HAVE I/O ROUTINE PUT OUT MSG    52500020
         BAL   R5,PUTMSG                PUT OUT MESSAGE                 52550020
         B     CODE0                    SET RETURN CODE TO ZERO AND     52600020
*                                          RETURN TO MAINLINE           52650020
         SPACE                                                          52700020
INVPARM  EQU   *                        SET UP MESSAGE FOR UNABLE       53150020
*                                          TO PARSE                     53200020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     53250020
         LA    R1,MSG6(R1)              INDEX FOR PROPER MESSAGE        53300020
         B     GOMSG                    PUT OUT MESSAGE                 53350020
         SPACE                                                          53400020
PUTMSG   EQU   *                        HAVE IKJEGIO PUT OUT MESSAGE    53450020
         LCR   R1,R1                    LOAD COMPLEMENT TO INDICATE     53500020
*                                          ERROR MESSAGE TO TERMINAL    53550020
         L     R15,TPUTADDR             R15=ADDRESS OF MESSAGE WRITER   53600020
*                                          ROUTINE OF IKJEGIO           53650020
         BALR  R14,R15                  GO WRITE OUT MESSAGE            53700020
         LTR   R15,R15                  WAS I/O SUCCESSFUL              53750020
         BCR   EIGHT,R5                 YES, RETURN TO CALLER           53800020
         LA    R2,SIXTEEN               R2=16 - ATTENTION INDICATION    53850020
         CLR   R2,R15                   WAS AN ATTENTION SCHEDULED      53900020
         BE    ISBLDON                  YES, IS BUILD SWITCH ON FOR     53950020
*                                          DEFERRED QUEUE CHECK         54000020
         BR    R5                       I/O ERROR - RETURN TO CALLER    54050020
         SPACE                                                          54100020
SET16    EQU   *                        SET RETURN CODE TO 16 FOR       54150020
         LA    R15,SIXTEEN                 ATTENTION SCHEDULED          54200020
         B     RETMAIN                  RETURN TO MAINLINE              54250020
         SPACE                                                          54300020
ISBLDON  EQU   *                        WAS AT ENTERED TO BUILD ACTIVE  54350020
*                                          BREAKPOINTS FROM THE DEFER   54400020
*                                          QUEUE                        54450020
         TM    TSTFLGS1,TSTBUILD        IS BUILD SWITCH ON              54500020
         BNO   RETMAIN                  NO, RETURN TO MAINLINE          54550020
         B     CODE4                    SET RETURN CODE TO 4            54650020
         SPACE                                                          54700020
RETRY    EQU   *                        AT'S RETRY ROUTINE IN CASE OF   54750020
*                                          AN ABEND                     54800020
         L     R5,CVTPTR                R5=ADDRESS OF CVT               54850020
         USING CVT,R5                   ESTABLISH ADDRESSABILITY        54900020
*                                          TO CVT                       54950020
         L     R5,CVTTCBP               R5=POINTER TO DOUBLE WORD       55000020
*                                          OF POINTERS TO NEXT-TO-BE    55050020
*                                          DISPATCHED TCB AND CURRENT   55100020
*                                          TCB                          55150020
         DROP  R5                                                       55200020
         L     R5,FOUR(R5)              R5=POINTER TO CURRENT TCB       55250020
*                                          (TEST'S TCB)                 55300020
         USING TCB,R5                   ESTABLISH ADDRESSABILITY TO     55350020
*                                          TEST'S TCB                   55400020
         L     R9,TCBTRN                R9=ADDRESS OF TCOMTAB           55450020
         DROP  R5                                                       55500020
         L     R13,REGSAVE2             R13=ADDRESS OF AT'S SAVE AREA   55550020
         L     R12,SIXTY8(R13)          RESTORE BASE REGISTER           55600020
         LTR   R0,R0                    DID STAE ROUTINE GET CORE       55650020
         BNZ   DIDNOT                   STAE DID NOT GET CORE -         55700020
*                                          BRANCH AROUND FREEMAIN       55750020
         FREEMAIN R,LV=104,A=(R1)       FREE CORE GOTTEN BY STAE        55800020
         SPACE                                                          55850020
DIDNOT   EQU   *                        CONTINUE RETRY ROUTINE          55900020
         TM    TSTFLGS1,TSTBUILD        WAS THIS MODULE ENTERED TO      55950020
*                                          BUILD ACTIVE BREAKPOINTS     56000020
*                                          FROM THE DEFER QUEUE         56050020
         BO    CODE4                    YES, SET CODE TO 4              56100020
         LA    R15,TWENTY               R15=20 - INDICATES RETURN FROM  56150020
*                                          RETRY ROUTINE                56200020
         B     RETMAIN                  RETURN TO MAINLINE              56250020
         SPACE                                                          56300020
         EJECT                                                          56350020
* THIS SECTION RECEIVES CONTROL FROM IKJPARS ONCE IKJPARS HAS SCANNED   56400020
* AN ADDRESS AND HAS DETERMINED THAT IT IS SYNTACTICALLY CORRECT.       56450020
* FURTHER VALIDITY CHECKING OF THE ADDRESS IS PERFORMED TO ENSURE       56500020
* THAT THE ADDRESS IS AN ACCEPTABLE TYPE FOR THE AT SUBCOMMAND.  IF AN  56550020
* ADDRESS IS FOUND TO BE UNACCEPTABLE, A MESSAGE IS ISSUED TO THE       56600020
* USER BEFORE CONTROL IS RETURNED TO IKJPARS.                           56650020
         SPACE                                                          56700020
AT1ADDVC EQU   *                        VALIDITY CHECK FOR ADDRESS      56750020
         DROP  R10                                                      56800020
         SAVE  (14,12),,AT1ADDVC        SAVE REGISTERS FROM PARSE       56850020
         L     R5,FOUR(ZERO,R1)         R5=ADDR OF AT'S SAVE AREA       56900020
         L     R12,SIXTY8(ZERO,R5)      GET ADDRESSABILITY WITH MAIN    56950020
*                                          SECTIONS                     57000020
         L     R9,FIFTY6(ZERO,R5)       R9=ADDR OF TCOMTAB              57050020
         L     R6,REGSAVE3              R6=ADDR OF EXIT ROUTINE'S       57100020
*                                          SAVE AREA                    57150020
         ST    R13,FOUR(ZERO,R6)        SAVE ADDR OF PARSE'S SAVE AREA  57200020
         ST    R6,EIGHT(ZERO,R13)       SAVE ADDR OF EXIT'S SAVE AREA   57250020
*                                          IN PARSE'S SAVE AREA         57300020
         LR    R13,R6                   R13=ADDR OF THIS ROUTINE'S SAVE 57350020
*                                          AREA                         57400020
         L     R10,WORKAREA             R10=ADDRESS OF COMMON WORKAREA  57410020
         USING TSTCWORK,R10             ESTABLISH ADDRESSABILITY TO IT  57420020
         LA    R10,CWORKCMD             R10=ADDRESS OF AT'S WORKAREA    57430020
         DROP  R10                                                      57440020
         USING WORKSP,R10               ESTABLISH ADDRESSABILITY TO     57442020
*                                          AT'S WORKAREA                57444020
         LA    R7,EIGHT(R1)             R7=ADDR OF LAST WORD OF         57450020
*                                          PARSE'S PARM LIST            57500020
         SPACE                                                          57550020
* BEGIN TESTS OF ADDRESS                                                57600020
         L     R11,ZERO(ZERO,R1)        R11=ADDRESS OF PDE              57650020
         USING IKJPARMA,R11             ESTABLISH ADDRESSABILITY TO PDE 57700020
         XR    R4,R4                    CLEAR REGISTER FOR TESTS        57750020
         CH    R4,PDEINDCT              IS ADDRESS INDIRECT             57800020
         BNE   CHKRANGE                 YES, WAS A RANGE GIVEN          57850020
         TM    PDEFLG4,REGTYPE          IS ADDRESS REGISTER TYPE        57900020
         BM    STORMSG                  YES, PUT OUT ERROR MESSAGE      57950020
         SPACE                                                          58000020
* BEGIN TESTS TO DETERMINE IF RANGE WERE SPECIFIED                      58050020
CHKRANGE EQU   *                        WAS A RANGE SPECIFIED           58100020
         TM    PDE2FLG2,ONBIT           ENTRYNAME GIVEN IN SECOND PDE   58150020
         BO    RANGE                    YES, CHECK FOR VALID ADDRESS    58200020
         TM    PDE2FLG3,ONBIT           STRING GIVEN                    58250020
         BO    RANGE                    YES, CHECK FOR VALID ADDRESS    58300020
         SPACE                                                          58350020
NORANGE  EQU   *                        RANGE NOT GIVEN - TEST FOR      58400020
*                                          FULLY QUALIFIED NAME         58450020
         TM    PDEFLG1,ONBIT            LOADNAME GIVEN                  58500020
         BZ    EXITCONV                 NO, CONVERT ADDRESS             58550020
         TM    PDEFLG3,ONBIT            STRING GIVEN                    58600020
         BZ    EXITCONV                 NO, CONVERT ADDRESS             58650020
         B     TESTSYM                  INSURE ADDRESS STRING IS NOT    58700020
*                                          SYMBOL WITH LENGTH GREATER   58750020
*                                          THAN EIGHT                   58800020
         SPACE                                                          58850020
EXITCONV EQU   *                        SET UP FOR GOING TO CONVERT     58900020
*                                          ROUTINE                      58950020
         LCR   R1,R11                   R1=COMPLEMENT OF ADDRESS OF PDE 59000020
*                                          TO INDICATE ADDRESS CONVERT  59050020
         XR    R0,R0                    R0=ZERO TO INDICATE CONVERT TO  59100020
*                                          BINARY                       59150020
         OI    TSTFLGS1,RANGESW         TELL CONVERT TO EXPECT A RANGE  59170020
         L     R15,TSTCONVT             R15=ADDRESS OF CONVERT ROUTINE  59200020
         BALR  R14,R15                  GET ADDRESS CONVERTED           59250020
         LTR   R15,R15                  WAS CONVERT SUCCESSFUL          59300020
         BNZ   NOTCONV(R15)             NO, SEE IF PDE USELESS          59350020
         TM    PDEUSER,PDESIB           IS ADDRESS IN USERWORD          59400020
         BZ    INWORD                   YES, CHECK BOUNDARY             59450020
         L     R6,PDEUSER               R6=ADDRESS OF SI BLOCK          59500020
         MVC   PDEUSER(L4),ZERO(R6)     MOVE ADDRESS INTO USERWORD      59550020
         SPACE                                                          59600020
INWORD   EQU   *                        ADDRESS IS IN USERWORD          59650020
         TM    BOUNDARY,BADBOUND        IS ADDRESS FOR HALF-WORD        59700020
*                                          BOUNDARY                     59750020
         BO    BOUNDMSG                 NO, PUT OUT MESSAGE             59800020
         OI    PDEUSER,PDECONVD         SET FLAG FOR PDE CONTAINING     59850020
*                                          BINARY ADDRESS               59900020
         SPACE                                                          59950020
EXITOK   EQU   *                        SET RETURN CODE TO ZERO         60000020
         XR    R15,R15                  ZERO REGISTER                   60050020
         SPACE                                                          60100020
RETPARSE EQU   *                        RETURN FOR PARSE                60150020
RETMAIN  EQU   *                        RETURN FOR MAINLINE             60200020
         L     R13,FOUR(ZERO,R13)       RESTORE R13                     60250020
         RETURN (14,12),,RC=(15)        RETURN                          60300020
         SPACE                                                          60350020
         ORG   *-4                      REUSE SPACE FOR ZERO COND. CODE 60360020
NOTCONV  EQU   *                        CHECK RETURN CODES              60400020
         ORG                                                            60450020
         B     EXIT8                    RETURN CODE 4                   60500020
         B     EXIT8                    RETURN CODE 8                   60550020
         B     EXIT8                    RETURN CODE 12                  60600020
         B     EXIT12                   RETURN CODE 16                  60650020
         B     EXIT12                   RETURN CODE 20                  60700020
         SPACE                                                          60750020
EXIT12   EQU   *                        SET RETURN TO PARSE TO 12 SO    60800020
*                                          THAT IT WILL RETURN TO AT    60810020
         ST    R15,PARSECD              SAVE RETURN CODE IN WORK AREA   60850020
         LA    R15,TWELVE               SET RETURN CODE TO 12           60900020
         B     RETPARSE                 RETURN TO PARSE                 60910020
         SPACE                                                          60950020
STORMSG  EQU   *                        PUT OUT MESSAGE FOR INVALID     61200020
*                                          ADDRESS - REGISTER SPECIFI-  61250020
*                                          CATION NOT ALLOWED           61300020
         TM    PDE2FLG2,ONBIT           WAS ENTRYNAME OF RANGE GIVEN    61350020
         BO    STMSG2                   YES, PREPARE RANGE MESSAGE      61400020
         TM    PDE2FLG3,ONBIT           WAS STRING GIVEN                61450020
         BO    STMSG2                   YES, PREPARE RANGE MESSAGE      61500020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     61550020
         LA    R1,MSG1(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTER   61600020
         SPACE                                                          61650020
SETADDR  EQU   *                        ADD ADDRESS STRING TO MSG       61700020
         LR    R0,R11                   R0=ADDRESS OF ADDRESS PDE       61750020
         BAL   R5,BLDMSG                ADD ADDRESS STRING              61800020
         SPACE                                                          61850020
PUTOUT   EQU   *                        PUT OUT MESSAGE                 61900020
         L     R5,FOUR(R1)              R5=POINTER TO SECOND LEVEL MSG  61950020
         ST    R5,PDEUSER               SAVE IN PDE USERWORD            62000020
         LCR   R1,R1                    LOAD COMPLEMENT TO INDICATE     62050020
*                                          ERROR MESSAGE TO TERMINAL    62100020
         L     R15,TPUTADDR             R15=ADDRESS OF MESSAGE WRITER   62150020
         BALR  R14,R15                  GO WRITE OUT MESSAGE            62200020
         LTR   R15,R15                  WAS I/O SUCCESSFUL              62250020
         BNZ   CLEAR12                  NO,GO TO CHECK I/O R.C.         62260020
         MVC   ZERO(L4,R7),PDEUSER      ADDR OF 2ND LEVEL FOR PARSE     62270020
         B     EXIT8A                   RETURN TO PARSE.                62280020
         SPACE                                                          62302020
CLEAR12  EQU   *                                                        62303020
         LA    R5,FOUR                  FOUR IN REGISTER 5              62304020
         CR    R15,R5                   COMPARE TO RETURN CODE FROM I/O 62305020
         BH    EXIT12                   I/O RET CODE IS 16, GO SAVE IT  62306020
         XR    R15,R15                  SET RETURN CODE TO ZERO         62310020
         B     EXIT12                   HAVE PARSE QUIT                 62320020
         SPACE                                                          62350020
EXIT8    EQU   *                        SET RETURN CODE TO PARSE TO     62400020
*                                          HAVE PARSE ISSUE 'REENTER'   62450020
         TM    TSTFLGS1,RANGESW         IF RANGE SPECIFIED, WHICH ADDR  62455020
*                                        IS BAD                         62460020
         MVC   ZERO(L4,R7),PDEUSER      GAMBLE FIRST BAD, PASS ADDR OF  62465020
*                                        SECOND LEV BACK TO PARSE       62470020
         BO    EXIT8A                   FIRST BAD, GO RETURN TO PARSE   62475020
         MVC   ZERO(L4,R7),PDE2USER     SECOND BAD, PASS ADDR OF SECOND 62480020
*                                        LEVEL MESSAGE TO PARSE         62485020
         SPACE                                                          62490020
EXIT8A   EQU   *                        SET RETURN CODE TO 8            62492020
         LA    R15,EIGHT                SET CODE TO EIGHT               62500020
         B     RETPARSE                 RETURN TO PARSE                 62550020
         SPACE                                                          62600020
TESTSYM  EQU   *                        IS STRING A SYMBOL WITH         62650020
*                                          LENGTH GREATER THAN 8        62700020
         CLI   PDELEN4,EIGHT            IS LENGTH GREATER THAN 8        62750020
         BNH   EXITOK                   NO, RETURN TO PARSE WITHOUT     62760020
*                                          CONVERTING ADDR AS DEFER     62770020
*                                          MIGHT BE SPECIFIED           62780020
         TM    PDEFLG4,SYMADDR          IS STRING A SYMBOL              62800020
         BNO   EXITOK                   NO, RETURN TO PARSE             62810020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     62850020
         LA    R1,MSG12(R1)             R1=ADDRESS OF MESSAGE POINTER   62860020
         B     SETADDR                  ADD ADDRESS STRING TO MSG       62900020
         SPACE                                                          62950020
STMSG2   EQU   *                        SET UP FOR RANGE MESSAGE -      63000020
*                                          INVALID REGISTER NOTATION    63050020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     63100020
         LA    R1,MSG11(R1)             INDEX FOR REGISTER MESSAGE      63150020
         B     SETADDR                  ADD STRING TO MESSAGE           63200020
         SPACE                                                          63250020
BOUNDMSG EQU   *                        PREPARE MESSAGE FOR ADDRESS NOT 63300020
*                                          ON HALF-WORD BOUNDARY        63350020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     63400020
         LA    R1,MSG3(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTER   63450020
         B     SETADDR                  ADD STRING TO MESSAGE           63500020
         SPACE                                                          63550020
RANGE    EQU   *                        AN ADDRESS RANGE WAS GIVEN      63600020
         CH    R4,PDE2INDC              IS SECOND ADDRESS INDIRECT      63650020
         BNE   ISITFULL                 YES, IS FIRST FULLY QUALIFIED   63700020
         TM    PDE2FLG4,REGTYPE         IS REGISTER SPECIFIED           63750020
         BM    STMSG2                   BUILD MESSAGE FOR ADDRESS       63800020
*                                          REQUIRED TO BE STORAGE       63850020
         SPACE                                                          63900020
ISITFULL EQU   *                        CHECK FOR FIRST ADDRESS FULLY   63950020
*                                         QUALIFIED                     64000020
         TM    PDEFLG1,ONBIT            LOADNAME GIVEN                  64050020
         BZ    GOTOCONV                 NO, CONVERT ADDRESSES           64100020
         TM    PDEFLG3,ONBIT            STRING GIVEN                    64150020
         BZ    GOTOCONV                 NO, CONVERT ADDRESSES           64200020
         SPACE                                                          64250020
* FIRST ARGUMENT OF THE RANGE IS A FULLY QUALIFIED ADDRESS.  CHECK      64300020
* THE SECOND ARGUMENT.                                                  64350020
         SPACE                                                          64400020
         TM    PDE2FLG1,ONBIT           LOADNAME GIVEN                  64450020
         BZ    GOTOCONV                 NO, CONVERT ADDRESSES           64500020
         TM    PDE2FLG3,ONBIT           STRING GIVEN                    64550020
         BZ    GOTOCONV                 NO, CONVERT ADDRESSES           64600020
         CLI   PDELEN4,EIGHT            IS LENGTH OF STRING GREATER     64650020
*                                          THAN 8                       64660020
         BNH   CHKPDE2                  NO, CHECK SECOND HALF PDE       64670020
         TM    PDEFLG4,SYMADDR          IS STRING A SYMBOL              64680020
         BNO   CHKPDE2                  NO, CHECK SECOND HALF PDE       64690020
         SPACE                                                          64700020
SYMMSG2  EQU   *                        PUT OUT MSG FOR RANGE CONTAINS  64750020
*                                          SYMBOL WITH LENGTH GREATER   64760020
*                                          THAN 8                       64770020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     64780020
         LA    R1,MSG13(R1)             R1=ADDRESS OF MESSAGE POINTER   64790020
         B     SETADDR                  ADD STRING TO MESSAGE           64792020
         SPACE                                                          64800020
CHKPDE2  EQU   *                        CHECK LAST PART OF RANGE FOR    64810020
*                                          SYMBOL WITH LENGTH GREATER   64820020
*                                          THAN 8                       64830020
         CLI   PDE2LEN4,EIGHT           IS LENGTH GREATER THAN 8        64840020
         BNH   EXITOK                   NO, RETURN WITHOUT CONVERTING   64842020
*                                          REQUEST MAY BE DEFER         64844020
         TM    PDE2FLG4,SYMADDR         IS STRING A SYMBOL              64846020
         BNO   EXITOK                   NO, RETURN TO PARSE             64848020
         B     SYMMSG2                  YES, PUT OUT MESSAGE            64848420
         SPACE                                                          64848820
GOTOCONV EQU   *                        SINCE BOTH ADDRESSES            64850020
* ARE NOT FULLY QUALIFIED BOTH WILL BE CONVERTED.  THE BINARY ADDRESSES 64900020
* TO BE VALID MUST MEET TWO CONDITIONS-  THE FIRST MUST BE LESS THAN    64950020
* THE SECOND AND THE FIRST MUST ADDRESS A HALF-WORD BOUNDARY.           65000020
         SPACE                                                          65050020
         OI    TSTFLGS1,RANGESW         TELL CONVERT TO EXPECT A RANGE  65100020
         LCR   R1,R11                   R1=COMPLEMENT OF ADDRESS OF PDE 65150020
*                                          TO INDICATE ADDRESS CONVERT  65200020
         XR    R0,R0                    R0=ZERO TO INDICATE CONVERT     65250020
*                                          TO BINARY                    65300020
         L     R15,TSTCONVT             R15=ADDRESS OF CONVERT ROUTINE  65350020
         BALR  R14,R15                  GO TO CONVERT                   65400020
         LTR   R15,R15                  WAS CONVERT SUCCESSFUL          65450020
         BNZ   NOTCONV(R15)             NO, SEE IF PDE USELESS          65500020
         SPACE                                                          65550020
* CONVERT WAS SUCCESSFUL.  THIS ROUTINE MAKES SURE THE BINARY ADDRESSES 65600020
* ARE IN USERWORDS AND THAT THE FIRST ADDRESS IS LESS THAN THE SECOND.  65650020
         SPACE                                                          65700020
         TM    PDEUSER,PDESIB           IS FIRST ADDRESS IN USERWORD    65750020
         BO    MOVEADR                  NO, PUT IT THERE                65800020
         SPACE                                                          65850020
CHKUSER2 EQU   *                        LOOK AT SECOND PDE OF RANGE     65900020
         TM    PDE2USER,PDESIB          IS SECOND ADDRESS IN USERWORD   65950020
         BO    MOVADDR2                 NO, PUT IT THERE                66000020
         SPACE                                                          66050020
COMPUSER EQU   *                        COMPARE ADDRESSES               66100020
         CLC   USER1(L3),USER2          IS FIRST ADDRESS GREATER THAN   66150020
*                                          SECOND                       66200020
         BH    FIRSTHI                  YES, PUT OUT ERROR MESSAGE      66250020
         TM    BOUNDARY,BADBOUND        IS FIRST ADDRESS FOR HALF-WORD  66300020
*                                          BOUNDARY                     66350020
         BO    BNDMSG2                  NO, PUT OUT MESSAGE             66400020
         OI    PDEUSER,PDECONVD         FLAG PDE AS CONVERTED           66450020
         B     EXITOK                   RETURN TO PARSE                 66500020
         SPACE                                                          66550020
MOVEADR  EQU   *                        FIRST CONVERTED ADDRESS IN      66600020
*                                          SI BLOCK                     66650020
         L     R5,PDEUSER               R5=ADDRESS OF SI BLOCK          66700020
         L     R5,ZERO(ZERO,R5)         R5=CONVERTED ADDRESS            66750020
         ST    R5,PDEUSER               STORE IN FIRST USERWORD         66800020
         B     CHKUSER2                 CHECK FOR CONVERTED ADDRESS IN  66850020
*                                          SECOND USERWORD              66900020
         SPACE                                                          66950020
BNDMSG2  EQU   *                        FIRST ADDRESS OF RANGE NOT      67000020
*                                          ON HALF-WORD BOUNDARY        67050020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     67100020
         LA    R1,MSG10(R1)             INDEX FOR RANGE MESSAGE         67150020
         B     SETADDR                  ADD ADDRESS STRING TO MSG       67200020
         SPACE                                                          67250020
MOVADDR2 EQU   *                        SECOND CONVERTED ADDRESS IN     67300020
*                                          SI BLOCK                     67350020
         L     R5,PDE2USER              R5=ADDRESS OF SI BLOCK          67400020
         L     R5,ZERO(ZERO,R5)         R5=CONVERTED ADDRESS            67450020
         ST    R5,PDE2USER              STORE IN SECOND USERWORD        67500020
         B     COMPUSER                 COMPARE ADDRESSES               67550020
         SPACE                                                          67600020
FIRSTHI  EQU   *                        PREPARE TO WRITE MESSAGE FOR    67650020
*                                          FIRST ADDRESS EXCEEDS SECOND 67700020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     67750020
         LA    R1,MSG2(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTER   67800020
         B     SETADDR                  ADD ADDRESS STRING TO MSG       67850020
         DROP  R10                                                      67860020
         SPACE                                                          67900020
* THIS SECTION RECEIVES CONTROL FROM IKJPARS ONCE IKJPARS HAS SCANNED   67950020
* A PARENTHESIZED STRING (KNOWN AS THE SUB-COMMAND CHAIN) AND HAS       68000020
* DETERMINED THAT IT IS SYNTACTICALLY CORRECT.  FURTHER VALIDITY        68050020
* CHECKING OF THE SUB-COMMAND CHAIN IS PERFORMED.  IF THE SUB-COMMAND   68100020
* CHAIN IS FOUND TO BE UNACCEPTABLE, A MESSAGE IS ISSUED TO THE USER    68150020
* BEFORE CONTROL IS RETURNED TO IKJPARS.                                68200020
         SPACE                                                          68250020
AT1SUBVC EQU   *                        SUB-COMMAND VALIDITY CHECK      68300020
         SAVE (14,12),,AT1SUBVC         SAVE IKJPARS' REGISTERS         68350020
         L     R5,FOUR(ZERO,R1)         R5=ADDR OF AT'S SAVE AREA       68400020
         LA    R7,EIGHT(R1)             R7=POINTER TO PARSE'S PARM      68450020
*                                          FOR SECOND LEVEL MSG         68500020
         L     R12,SIXTY8(ZERO,R5)      ESTABLISH ADDRESSABILITY WITH   68550020
*                                          MAINLINE OF AT               68600020
         L     R9,FIFTY6(ZERO,R5)       R9=ADDR OF TCOMTAB              68650020
         L     R6,REGSAVE3              R6=ADDR OF EXIT'S SAVE AREA     68700020
         ST    R13,FOUR(ZERO,R6)        SAVE ADDRESS OF PARSE'S SAVE    68750020
*                                          AREA                         68800020
         ST    R6,EIGHT(ZERO,R13)       SAVE ADDRESS OF EXIT'S SAVE     68850020
*                                          AREA IN PARSE'S SAVE AREA    68900020
         LR    R13,R6                   R13=ADDR OF EXIT'S SAVE AREA    68950020
         L     R10,WORKAREA             R10=ADDRESS OF COMMON WORKAREA  68960020
         USING TSTCWORK,R10             ESTABLISH ADDRESSABILITY TO IT  68970020
         LA    R10,CWORKCMD             R10=ADDRESS OF AT'S WORKAREA    68980020
         DROP  R10                                                      68990020
         SPACE                                                          69000020
* THIS EXIT CHECKS THE LENGTH OF THE SUBCOMMAND STRING FOR A MAXIMUM    69050020
* OF 255.  IF IT IS GREATER A MESSAGE IS ISSUED.                        69100020
         SPACE                                                          69150020
         L     R6,ZERO(ZERO,R1)         R6=ADDR OF SUB-COMMAND PDE      69200020
         LA    R4,MAXLEN                R4=255                          69250020
         CH    R4,COMLEN(ZERO,R6)       IS LENGTH GREATER THAN 255      69300020
         BL    TOOLONG                  YES, PUT OUT ERROR MESSAGE      69350020
         B     EXITOK                   LENGTH OK, RETURN TO IKJPARS    69400020
         SPACE                                                          69450020
TOOLONG  EQU   *                        PREPARE TO PUT OUT MESSAGE FOR  69500020
*                                          SUB-COMMAND CHAIN LENGTH     69550020
*                                          EXCEEDS 255                  69600020
         L     R1,MSGADDR               R1=ADDR OF MESSAGE CSECT        69650020
         LA    R1,MSG4(ZERO,R1)         R1=ADDR OF MESSAGE POINTER      69700020
         SPACE                                                          69710020
PUTOUT2  EQU   *                        PUT OUT MESSAGE                 69720020
         MVC   ZERO(L4,R7),FOUR(R1)     SAVE ADDR OF SECOND LEVEL MSG   69730020
*                                          IN PARSE'S PARAMETERS        69740020
         LCR   R1,R1                    LOAD COMPLEMENT TO INDICATE     69742020
*                                          ERROR MESSAGE TO TERMINAL    69750020
         L     R15,TPUTADDR             R15=ADDRESS OF MESSAGE WRITER   69760020
         BALR  R14,R15                  GO WRITE MESSAGE                69770020
         LTR   R15,R15                  WAS I/O SUCCESSFUL              69780020
         BZ    EXIT8A                   YES, HAVE PARSE PROMPT          69790020
         B     EXIT12                   HAVE PARSE QUIT                 69792020
         SPACE                                                          69800020
* THIS SECTION RECEIVES CONTROL FROM IKJPARS ONCE IKJPARS HAS SCANNED   69850020
* THE KEYWORD COUNT AND ITS SUBFIELD INTEGER AND HAS DETERMINED THAT    69900020
* IT IS SYNTACTICALLY CORRECT.  FURTHER VALIDITY CHECKING OF THE        69950020
* INTEGER IS PERFORMED.  IF THE INTEGER IS FOUND TO BE UNACCEPTABLE,    70000020
* A MESSAGE IS ISSUED TO THE USER BEFORE CONTROL IS RETURNED TO PARSE.  70050020
         SPACE                                                          70100020
AT1CTVC  EQU   *                        VALIDITY CHECK FOR COUNT        70150020
         SAVE  (14,12),,AT1CTVC         SAVE IKJPARS' REGISTERS         70200020
         L     R5,FOUR(ZERO,R1)         R5=ADDR OF AT'S SAVE AREA       70250020
         L     R12,SIXTY8(ZERO,R5)      ESTABLISH ADDRESSABILITY WITH   70300020
*                                          MAINLINE OF AT               70350020
         L     R9,FIFTY6(ZERO,R5)       R5=ADDR OF TCOMTAB              70400020
         L     R6,REGSAVE3              R6=ADDR OF EXIT'S SAVE AREA     70450020
         ST    R13,FOUR(ZERO,R6)        SAVE ADDRESS OF PARSE'S SAVE    70500020
*                                          AREA                         70550020
         ST    R6,EIGHT(ZERO,R13)       SAVE ADDRESS OF EXIT'S SAVE     70600020
*                                          AREA IN PARSE'S SAVE AREA    70650020
         LR    R13,R6                   R13=ADDR OF EXIT'S SAVE AREA    70700020
         L     R10,WORKAREA             R10=ADDRESS OF COMMON WORKAREA  70710020
         USING TSTCWORK,R10             ESTABLISH ADDRESSABILITY TO IT  70720020
         LA    R10,CWORKCMD             R10=ADDRESS OF AT'S WORKAREA    70730020
         DROP  R10                                                      70740020
         LA    R7,EIGHT(R1)             R7=POINTER TO PARSE'S PARM      70750020
*                                           FOR SECOND LEVEL MSG        70800020
         L     R1,ZERO(ZERO,R1)         R1=ADDR OF COUNT PDE            70850020
         SR    R0,R0                    ZERO REGISTER - CONVERT TO      70900020
*                                          BINARY                       70950020
         MVI   SEVEN(R1),FCODE          MOVE IN TYPE CODE FOR IKJEGCVT  71000020
         L     R15,TSTCONVT             R15=EP OF IKJEGCVT              71050020
         BALR  R14,R15                  CONVERT COUNT TO BINARY         71100020
         LTR   R15,R15                  WAS CONVERT SUCCESSFUL          71150020
         BNZ   RETPARSE                 NO, ATTENTION SCHEDULED         71200020
         LA    R2,TWO                   R2=TWO                          71250020
         XR    R3,R3                    CLEAR REGISTER                  71300020
         L     R4,CONAREA               R4=ADDRESS OF PLACE WHERE       71350020
*                                          CONVERT RETURNS NUMBER       71400020
         USING CONBYTE,R4               GET ADDRESSABILITY TO CONAREA   71450020
         L     R5,COUNTMAX              R5=MAXIMUM COUNT                71500020
         L     R6,CONCOUNT              R6=COUNT GIVEN                  71550020
         LTR   R6,R6                    IS COUNT = ZERO                 71600020
         BZ    EXITOK                   YES, RETURN TO PARSE            71650020
         CLR   R6,R5                    IS COUNT GREATER THAN 65535     71700020
         BH    BADCOUNT                 YES, PUT OUT ERROR MESSAGE      71750020
         BCTR  R6,ZERO                  DECREMENT BY ONE                71800020
         ST    R6,CONCOUNT              STORE BACK IN COUNT AREA        71850020
         B     EXITOK                   COUNT OK - RETURN TO PARSE      71900020
         SPACE                                                          71950020
BADCOUNT EQU   *                        PUT OUT MESSAGE FOR COUNT       72000020
*                                          EXCEEDS MAXIMUM              72050020
         LR    R5,R1                    R5=ADDR OF COUNT PDE            72100020
         L     R1,OUTBUF                R1=ADDR OF OUTPUT AREA          72150020
         LA    R8,EIGHT(R1)             R8=ADDR FOR FIRST LEVEL MSG     72200020
         ST    R8,ZERO(R1)              SAVE ADDR IN FIRST WORD OF      72250020
*                                          OUTPUT AREA                  72300020
         L     R6,MSGADDR               R6=POINTER TO MESSAGE CSECT     72350020
         LA    R6,MSG5(R6)              R6=POINTER TO FIRST LEVEL MSG   72400020
*                                          POINTER                      72450020
         L     R4,FOUR(R6)              R4=POINTER TO SECOND LEVEL MSG  72500020
         ST    R4,FOUR(R1)              SAVE IN OUTPUT BUFFER           72550020
         L     R6,ZERO(R6)              R6=POINTER TO FIRST LEVEL MSG   72600020
         MVC   ZERO(L34,R8),ZERO(R6)    MOVE FIRST LEVEL MSG TO BUFFER  72650020
         L     R5,ZERO(R5)              R5=POINTER TO COUNT STRING      72700020
         MVC   TWENTY8(L5,R8),ZERO(R5)  MOVE COUNT INTO MESSAGE         72750020
         B     PUTOUT2                  PUT OUT MESSAGE                 72800020
         SPACE                                                          72850020
         DROP  R4                                                       72900020
         SPACE                                                          72950020
         SPACE                                                          73050020
GETL     GETMAIN EC,SP=ONE,MF=L         LIST FORM OF GETMAIN            73100020
GETLEN   EQU   *-GETL                   LENGTH OF LIST FORM             73150020
STAELIST DS    0F                       NAME OF LIST FORM OF STAE       73200020
         STAE  MF=L                     LIST FORM OF MACRO              73250020
STAELENG EQU   *-STAELIST               LENGTH OF MACRO LIST FORM       73300020
XLIST    EQU  *                         LIST FORM OF XCTL MACRO         73350020
         XCTL  EP=IKJEGATD,SF=L         LIST FORM                       73400020
XCTLEN   EQU  *-XLIST                   LENGTH OF LIST FORM OF MACRO    73450020
         EJECT                                                          73500020
         SPACE                                                          73550020
* CONSTANTS                                                             73600020
         DS    0H                       ALIGNMENT                       73650020
MAXLEN2  DC    AL2(BRKLEN+100)          MAXIMUM LENGTH FOR BREAK ELE-   73700020
*                                          MENT AND ADDRESS STRING      73750020
         DS    0F                       ALIGNMENT                       73800020
SP1      DC    X'01000000'              SUBPOOL 1 INDICATOR.            73850020
DBLBND   DC    X'FFFFFFF8'              MASK FOR ROUNDING TO DBL BOUND  73900020
ATD      DC    C'ATD'                   CONSTANT USED BY MNLN BLDL RTNE 73910020
RETRYA   DC    A(RETRY)                 ADDRESS OF RETRY ROUTINE        73950020
RETRYA1  EQU   RETRYA+1                 SECOND BYTE OF RETRYA           74000020
MSGADDR  DC    V(IKJEGATM)              ADDRESS OF MESSAGE CSECT        74050020
PCLISTA  DC    V(IKJEGAPL)              ADDRESS OF PCL                  74100020
COUNTMAX DC    X'0000FFFF'              MAXIMUM COUNT INTEGER - 65535   74150020
TABLE    DC    C'0123456789ABCDEF'      TRANSLATE TABLE                 74200020
ABENDTAB EQU   *                        TABLE FOR ABEND MESSAGES        74250020
         DS    0F                       ALIGNMENT                       74300020
         DC    AL1(7)                   CODE FOR PROTECTION CHECK       74350020
         DC    AL3(BLOW1)               RESUME ADDRESS FOLLOWING        74400020
*                                          INITIAL PROTECTION CHECK     74450020
         DC    AL1(1)                   CODE FOR INSUFFICIENT STORAGE   74500020
         DC    AL3(BLOW2)               RESUME ADDRESS FOLLOWING        74550020
*                                          INITIAL GETMAIN              74600020
         DC    AL1(7)                   CODE FOR PROTECTION CHECK       74650020
         DC    AL3(BLOW3)               RESUME ADDRESS FOLLOWING        74700020
*                                          ADDITIONAL PROTECTION CHECK  74750020
         DC    AL1(1)                   CODE FOR INSUFFICIENT STORAGE   74800020
         DC    AL3(BLOW4)               RESUME ADDRESS FOLLOWING        74850020
*                                          ADDITIONAL BREAK ELEMENT     74900020
*                                          GETMAIN                      74950020
         DC    AL1(3)                   CODE FOR LINK FAILED            75000020
         DC    AL3(BLOW5)               RESUME ADDRESS FOLLOWING LINK   75050020
*                                          TO IKJPARS                   75100020
         DC    X'FF'                    END OF TABLE                    75250020
         DS    0F                       ALIGNMENT                       75350020
         EJECT                                                          75400020
IKJEGATM CSECT                                                          75450020
         SPACE                                                          75500020
* THE MESSAGE CSECT IS ARRANGED SO THAT A LIST OF ADDRESSES AT THE      75550020
* BEGINNING POINTS TO THE MESSAGES.  FOR EACH MESSAGE THERE IS A        75600020
* POSSIBILITY OF MORE THAN ONE MESSAGE LEVEL WITH A POINTER NEEDED      75650020
* FOR EACH.  IF A MESSAGE HAS FEWER THAN THE MAXIMUM NUMBER OF LEVELS   75700020
* A WORD OF ZEROES IS USED FOR EACH NON-USED LEVEL POINTER.  THE        75750020
* MESSAGES THEMSELVES BEGIN WITH A HALF WORD OF MESSAGE LENGTH          75800020
* (INCLUDING THE TWO PREFACE HALF WORDS) AND A HALF WORD OF ZEROES FOR  75850020
* THE OFFSET FIELD FOLLOWED BY THE MESSAGE ITSELF.                      75900020
         SPACE                                                          75950020
MSG01    DC    A(AT1M1)                 ADDRESS FOR MESSAGE 1           76000020
         DC    A(AT1M2)                 ADDRESS FOR MESSAGE 1           76050020
MSG02    DC    A(AT1M15)                ADDRESS FOR MESSAGE 2           76100020
         DC    A(AT1M17)                ADDRESS FOR MESSAGE 2           76150020
MSG03    DC    A(AT1M1)                 ADDRESS FOR MESSAGE 3           76200020
         DC    A(AT1M3)                 ADDRESS FOR MESSAGE 3           76250020
MSG04    DC    A(AT1M4)                 ADDRESS FOR MESSAGE 4           76300020
         DC    A(AT1M5)                 ADDRESS FOR MESSAGE 4           76350020
MSG05    DC    A(AT1M6)                 ADDRESS FOR MESSAGE 5           76400020
         DC    A(AT1M20)                ADDRESS FOR MESSAGE 5           76450020
MSG06    DC    A(AT1M8)                 ADDRESS FOR MESSAGE 6           76500020
         DC    A(AT1M9)                 ADDRESS FOR MESSAGE 6           76550020
MSG07    DC    A(AT1M19)                ADDRESS FOR MESSAGE 7           76600020
         DC    A(0)                     NO SECOND LEVEL MESSAGE         76650020
MSG08    DC    A(AT1M11)                ADDRESS FOR MESSAGE 8           76700020
         DC    A(AT1M12)                ADDRESS FOR MESSAGE 8           76750020
MSG09    DC    A(AT1M13)                ADDRESS FOR MESSAGE 9           76800020
         DC    A(AT1M14)                ADDRESS FOR MESSAGE 9           76850020
MSG010   DC    A(AT1M15)                ADDRESS FOR MESSAGE 10          77000020
         DC    A(AT1M16)                ADDRESS FOR MESSAGE 10          77050020
MSG011   DC    A(AT1M15)                ADDRESS FOR MESSAGE 11          77100020
         DC    A(AT1M18)                ADDRESS FOR MESSAGE 11          77150020
MSG012   DC    A(AT1M1)                 ADDRESS FOR MESSAGE 12          77200020
         DC    A(AT1M21)                ADDRESS FOR MESSAGE 12          77250020
MSG013   DC    A(AT1M15)                ADDRESS FOR MESSAGE 13          77260020
         DC    A(AT1M22)                ADDRESS FOR MESSAGE 13          77270020
         SPACE                                                          77300020
         DS    0H                       ALIGNMENT                       77350020
AT1M1    DC    AL2(AT1E1-AT1M1)         LENGTH OF MESSAGE               77400020
         DC    AL2(0)                   FILLER                          77450020
         DC    C'IKJ57300I INVALID ADDRESS '                            77500020
AT1E1    EQU   *                        END OF MESSAGE                  77550020
         SPACE                                                          77600020
         DS    0H                       ALIGNMENT                       77650020
AT1M2    DC    AL2(AT1E2-AT1M2)         LENGTH OF MESSAGE               77700020
         DC    AL2(0)                   FILLER                          77750020
         DC    C'IKJ57300I REGISTER NOTATION MUST BE INDIRECT '         77800020
         DC    C'GENERAL REGISTER'                                      77850020
AT1E2    EQU   *                        END OF MESSAGE                  77900020
         SPACE                                                          77950020
         DS    0H                       ALIGNMENT                       78000020
AT1M3    DC    AL2(AT1E3-AT1M3)         LENGTH OF MESSAGE               78050020
         DC    AL2(0)                   FILLER                          78100020
         DC    C'IKJ57300I HALFWORD BOUNDARY REQUIRED'                  78150020
AT1E3    EQU   *                        END OF MESSAGE                  78200020
         SPACE                                                          78250020
         DS    0H                       ALIGNMENT                       78300020
AT1M4    DC    AL2(AT1E4-AT1M4)         LENGTH OF MESSAGE               78350020
         DC    AL2(0)                   FILLER                          78400020
         DC    C'IKJ57302I COMMAND CHAIN TOO LONG+'                     78450020
AT1E4    EQU   *                        END OF MESSAGE                  78500020
*THE MESSAGE CSECT CONTINUES                                            78550020
         SPACE                                                          78600020
         DS    0H                       ALIGNMENT                       78650020
AT1M5    DC    AL2(AT1E5-AT1M5)         LENGTH OF MESSAGE               78700020
         DC    AL2(0)                   FILLER                          78750020
         DC    C'IKJ57302I COMMAND CHAIN LENGTH MAY NOT EXCEED 255'     78800020
         DC    C' BYTES'                                                78850020
AT1E5    EQU   *                        END OF MESSAGE                  78900020
         SPACE                                                          78950020
         DS    0H                       ALIGNMENT                       79000020
AT1M6    DC    AL2(AT1E6-AT1M6)         LENGTH OF MESSAGE               79050020
         DC    AL2(0)                   FILLER                          79100020
         DC    C'IKJ57303I INVALID COUNT      +'                        79150020
AT1E6    EQU   *                        END OF MESSAGE                  79200020
         SPACE                                                          79250020
         DS    0H                       ALIGNMENT                       79600020
AT1M8    DC    AL2(AT1E8-AT1M8)         LENGTH OF MESSAGE               79650020
         DC    AL2(0)                   FILLER                          79700020
         DC    C'IKJ57307I AT FAILED, COMMAND SYSTEM ERROR+'            79750020
AT1E8    EQU   *                        END OF MESSAGE                  79800020
         SPACE                                                          79850020
         DS    0H                       ALIGNMENT                       79900020
AT1M9    DC    AL2(AT1E9-AT1M9)         LENGTH OF MESSAGE               79950020
         DC    AL2(0)                   FILLER                          80000020
         DC    C'IKJ57307I PARSE ERROR CODE 12'                         80050020
AT1E9    EQU   *                        END OF MESSAGE                  80100020
         SPACE                                                          80150020
*THE MESSAGE CSECT CONTINUES                                            80500020
         SPACE                                                          80550020
         DS    0H                       ALIGNMENT                       80600020
AT1M11   DC    AL2(AT1E11-AT1M11)       LENGTH OF MESSAGE               80650020
         DC    AL2(0)                   FILLER                          80700020
         DC    C'IKJ57305I NO BREAKPOINTS ESTABLISHED FROM +     OF '   80750020
         DC    C'RANGE BEGINNING '                                      80800020
AT1E11   EQU   *                        END OF MESSAGE                  80850020
         SPACE                                                          80900020
         DS    0H                       ALIGNMENT                       80950020
AT1M12   DC    AL2(AT1E12-AT1M12)       LENGTH OF MESSAGE               81000020
         DC    AL2(0)                   FILLER                          81050020
         DC    C'IKJ57305I INVALID OP CODE'                             81100020
AT1E12   EQU   *                        END OF MESSAGE                  81150020
         SPACE                                                          81200020
         DS    0H                       ALIGNMENT                       81250020
AT1M13   DC    AL2(AT1E13-AT1M13)       LENGTH OF MESSAGE               81300020
         DC    AL2(0)                   FILLER                          81350020
         DC    C'IKJ57306I NO BREAKPOINT ESTABLISHED AT '               81400020
AT1E13   EQU   *                        END OF MESSAGE                  81450020
         SPACE                                                          81500020
         DS    0H                       ALIGNMENT                       81550020
AT1M14   DC    AL2(AT1E14-AT1M14)       LENGTH OF MESSAGE               81600020
         DC    AL2(0)                   FILLER                          81650020
         DC    C'IKJ57306I INVALID OP CODE'                             81700020
AT1E14   EQU   *                        END OF MESSAGE                  81750020
         SPACE                                                          81800020
         DS    0H                       ALIGNMENT                       81850020
AT1M15   DC    AL2(AT1E15-AT1M15)       LENGTH OF MESSAGE               81900020
         DC    AL2(0)                   FILLER                          81950020
         DC    C'IKJ57301I INVALID ADDRESS RANGE BEGINNING '            82000020
AT1E15   EQU   *                        END OF MESSAGE                  82050020
         SPACE                                                          82100020
         DS    0H                       ALIGNMENT                       82150020
AT1M16   DC    AL2(AT1E16-AT1M16)       LENGTH OF MESSAGE               82200020
         DC    AL2(0)                   FILLER                          82250020
         DC    C'IKJ57301I HALFWORD BOUNDARY REQUIRED'                  82300020
AT1E16   EQU   *                        END OF MESSAGE                  82350020
*THE MESSAGE CSECT CONTINUES                                            82400020
         SPACE                                                          82450020
         DS    0H                       ALIGNMENT                       82500020
AT1M17   DC    AL2(AT1E17-AT1M17)       LENGTH OF MESSAGE               82550020
         DC    AL2(0)                   FILLER                          82600020
         DC    C'IKJ57301I FIRST ADDRESS MAY NOT EXCEED LAST IN A '     82650020
         DC    C'RANGE'                                                 82700020
AT1E17   EQU   *                        END OF MESSAGE                  82750020
         SPACE                                                          82800020
         DS    0H                       ALIGNMENT                       82850020
AT1M18   DC    AL2(AT1E18-AT1M18)       LENGTH OF MESSAGE               82900020
         DC    AL2(0)                   FILLER                          82950020
         DC    C'IKJ57301I REGISTER NOTATION MUST BE INDIRECT '         83000020
         DC    C'GENERAL REGISTER'                                      83050020
AT1E18   EQU   *                        END OF MESSAGE                  83100020
         SPACE                                                          83150020
         DS    0H                       ALIGNMENT                       83200020
AT1M19   DC    AL2(AT1E19-AT1M19)       LENGTH OF MESSAGE               83250020
         DC    AL2(0)                   FILLER                          83300020
         DC    C'IKJ57308I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  83350020
AT1E19   EQU   *                        END OF MESSAGE                  83450020
         SPACE                                                          83500020
         DS    0H                       ALIGNMENT                       83550020
AT1M20   DC    AL2(AT1E20-AT1M20)       LENGTH OF MESSAGE               83600020
         DC    AL2(0)                   FILLER                          83650020
         DC    C'IKJ57303I COUNT MUST BE BETWEEN 0 AND 65535'           83700020
AT1E20   EQU   *                        END OF MESSAGE                  83750020
         DS    0H                       ALIGNMENT                       83760020
AT1M21   DC    AL2(AT1E21-AT1M21)       LENGTH OF MESSAGE               83770020
         DC    AL2(0)                   FILLER                          83780020
         DC    C'IKJ57300I SYMBOL LENGTH EXCEEDS EIGHT CHARACTERS'      83790020
AT1E21   EQU   *                        END OF MESSAGE                  83792020
         SPACE                                                          83800020
         DS    0H                       ALIGNMENT                       83850020
AT1M22   DC    AL2(AT1E22-AT1M22)       LENGTH OF MESSAGE               83900020
         DC    AL2(0)                   FILLER                          83950020
         DC    C'IKJ57301I SYMBOL LENGTH EXCEEDS EIGHT CHARACTERS'      84000020
AT1E22   EQU   *                        END OF MESSAGE                  84050020
         SPACE                                                          84060020
IKJEGAT CSECT                                                           84100020
         EJECT                                                          84150020
IKJEGAPL IKJPARM DSECT=IKJPARMD                                         84200020
ADDR     IKJPOSIT ADDRESS,LIST,RANGE,                                  *84250020
               PROMPT='ADDRESS POSITIONAL PARAMETER',VALIDCK=AT1ADDVC   84300020
SBCMDCHN IKJPOSIT PSTRING,VALIDCK=AT1SUBVC                              84350020
COUNT   IKJKEYWD                                                        84400020
        IKJNAME 'COUNT',SUBFLD=INTEGER                                  84450020
NONOT   IKJKEYWD DEFAULT='NOTIFY'                                       84500020
        IKJNAME 'NOTIFY'                                                84550020
        IKJNAME 'NONOTIFY'                                              84600020
DEFER    IKJKEYWD DEFAULT='NODEFER'                                     84650020
        IKJNAME 'NODEFER'                                               84700020
        IKJNAME 'DEFER'                                                 84750020
INTEGER IKJSUBF                                                         84800020
NUMBER IKJIDENT 'INTEGER',FIRST=NUMERIC,OTHER=NUMERIC,MAXLNTH=5,       *84850020
               PROMPT='INTEGER',VALIDCK=AT1CTVC                         84900020
         IKJENDP                                                        84950020
         EJECT                                                          85000020
WORKSP   DSECT                          AT'S WORK AREA                  85050020
*THE FIRST TWO WORDS ARE INPUT FROM MAINLINE WHEN AT IS TO CREATE       85100020
*ACTIVE BREAK ELEMENTS FROM THE DEFER QUEUE.  WHEN AT IS ENTERED        85150020
*BECAUSE A NEW MODULE HAS BEEN BROUGHT INTO STORAGE THE LAST 64         85200020
*BYTES OF THIS WORK AREA MUST BE RESERVED FOR A REGISTER SAVE AREA      85250020
*TO BE USED BY IKJEGLDF.                                                85300020
LDNAME   DS    2F                       LOADNAME AT IS WORKING WITH     85350020
LDNM1    EQU   LDNAME+1                 BYTE 1 OF LDNAME                85400020
PARSECD  EQU   LDNAME                   SAVE RETURN CODE FROM PARSE     85410020
BYTENUMB DS    F                        SAVE AREA FOR NUMBER OF BYTES   85450020
*                                          LAST GOTTEN AND SUBPOOL      85500020
*                                          NUMBER                       85550020
LOADATTR EQU   BYTENUMB                 FLAG TO INDICATE OVERLAY FOR    85560020
*                                          NEW MODULE                   85570020
         ORG   *-TWELVE                 TO BEGINNING OF WORK AREA       85600020
PARMS    EQU   *                        PARAMETERS FOR PARSE            85650020
PTUPT    DS    A                        POINTER TO UPT                  85700020
PTECB    DS    A                        POINTER TO ECB                  85750020
PTCPECB  DS    A                        POINTER TO CP ECB               85800020
PTPCL    DS    A                        POINTER TO PCL                  85850020
PTANSWPL DS    A                        POINTER TO ANSWER PLACE         85900020
PTCOMBUF DS    A                        POINTER TO COMMAND BUFFER       85950020
PTSAVE   DS    A                        POINTER TO AT'S SAVE AREA       86000020
         ORG   *-SIXTEEN                BACK 16 BYTES                   86050020
GETCORE  GETMAIN EC,SP=ONE,MF=L         RESERVE FOR LIST FORM OF        86100020
*                                          GETMAIN                      86150020
ADDRCORE EQU   GETCORE+4                SECOND WORD OF LIST FORM        86200020
STAEL    DS    0F                       NAME OF LIST FORM OF STAE MACRO 86250020
         STAE  MF=L                    FOR LIST FORM OF STAE MACRO      86300020
         ORG   WORKSP+SEVENTY2          GET PAST REGISTER SAVE AREA     86350020
SAVEPTR  DS    F                        SAVE POINTER TO PREVIOUS        86400020
*                                          LINK FIELD                   86450020
CHNADDR  DS    F                        SAVE AREA FOR CHAIN ADDRESS     86500020
         ORG   WORKSP+SEVENTY2          GET PAST REGISTER SAVE AREA     86550020
XCTLPARM DS    F                        WORK AREA ADDRESS               86600020
PDEADDR  DS    F                        ADDRESS OF FIRST ADDR. PDE      86650020
MAINTRY  DS    F                        SAVE ADDR OF MAINLINE'S RETRY   86660020
MAINTRY1 EQU   MAINTRY+1                SECOND BYTE OF MAINTRY          86670020
XCTLL    XCTL  EP=IKJEGATD,SF=L         FOR LIST FORM OF MACRO          86700020
         EJECT                                                          86750020
TCB      IKJTCB                         TCB EXPANSION                   86800020
         EJECT                                                          86850020
CVT      DSECT                          CVT DSECT                       86900020
         CVT                                                            86950020
         EJECT                                                          87000020
         IKJPARMA                       PDE DSECT                       87050020
         EJECT                                                          87100020
         BRKELEM              BREAK ELEMENT DSECT.                      87150020
INSTBRK  EQU   BRKINST-BRKELEM OFFSET FOR SAVED INSTR.                  87200020
         EJECT                                                          87250020
         TCOMTAB                        COMMUNICATIONS TABLE DSECT      87300020
         EJECT                                                          87350020
         TSTCWORK                       DSECT FOR WORKAREA              87400020
         EJECT                                                          87450020
         IKJPPL                                                         87500020
         EJECT                                                          87550020
CONPLACE DSECT                          DSECT FOR CONAREA               87600020
         DS    D                        ALIGNMENT                       87650020
         ORG   *-ONE                    BACK UP ONE                     87700020
CONBYTE  DS    X                        LENGTH BYTE                     87750020
CONCOUNT DS    H                        RETURN COUNT                    87800020
         SPACE                                                          87850020
* EQUATES WHICH MUST FOLLOW DSECTS                                      87900020
BOUNDARY EQU   PDEUSER+3                LOW ORDER BYTE OF USERWORD 1    87950020
BOUND2   EQU   PDE2USER+3               LOW ORDER BYTE OF USERWORD 2    88000020
USER1    EQU   PDEUSER+1                SECOND BYTE OF USERWORD 1       88050020
USER2    EQU   PDE2USER+1               SECOND BYTE OF USERWORD 2       88100020
COMLEN   EQU   4                        LENGTH OF SUB-COMMAND PDE       88150020
COMFLGS  EQU   6                        FLAGS FOR SUB-COMMAND CHAIN     88200020
MAXLEN   EQU   255                      MAXIMUM LENGTH OF CHAIN         88250020
COUNTLEN EQU   4                        OFFSET FOR LENGTH OF COUNT IN   88300020
*                                          PDE                          88350020
COUNTFLG EQU   6                        OFFSET FOR COUNT FLAGS IN PDE   88400020
COUNTPTR EQU   0                        OFFSET FOR POINTER TO COUNT IN  88450020
*                                          PDE                          88500020
SBCMDLEN EQU   SBCMDCHN+4               LENGTH OF SUB-COMMAND CHAIN     88550020
RETRY1   EQU   TSTRETRY+1               SECOND BYTE OF TSTRETRY         88600020
PDELEN4  EQU   PDELEN3+1                SECOND BYTE OF PDELEN3          88610020
PDE2LEN4 EQU   PDE2LEN3+1               SECOND BYTE OF PDE2LEN3         88620020
OVLYBIT  EQU   X'20'                    FLAG TO INDICATE OVERLAY        88630020
         END                                                            88650020
SAVE                                                                    88700020
