 TITLE 'IKJEGATD - THE SECOND LOAD MODULE OF THE AT SUBCOMMAND'         00050020
*****************************  PROLOGUE  ****************************** 00100020
*                                                                     * 00150020
* STATUS                                                              * 00200020
*   CHANGE LEVEL 000.                                                 * 00250020
*                                                                     * 00300020
* FUNCTION/OPERATION                                                  * 00350020
*    THIS MODULE CONSTRUCTS A DEFER QUEUE FOR SAVING REQUESTS FOR     * 00400020
*    ESTABLISHING BREAKPOINTS UNTIL THE CONCERNED MODULE IS BROUGHT   * 00450020
*    INTO CORE.                                                       * 00500020
*                                                                     * 00550020
* ENTRY POINTS                                                        * 00600020
*          IKJEGATD - ENTERED FROM IKJEGAT, THE FIRST LOAD MODULE OF  * 00650020
*          THE AT SUBCOMMAND.  IT FIRST CHECKS TO MAKE CERTAIN ALL    * 00700020
*          ADDRESSES FOR THE DEFER                                    * 00710020
*          REQUEST ARE FULLY QUALIFIED AND SPECIFY THE SAME           * 00750020
*          LOADNAME.                                                  * 00800020
*                                                                     * 00850020
* INPUT                                                               * 00900020
*    REGISTER 1 POINTS TO A PARAMETER LIST OF TWO WORDS, THE FIRST    * 00950020
*    SPECIFYING THE ADDRESS OF AT'S WORK AREA AND THE SECOND CONTAIN- * 01000020
*    ING THE ADDRESS OF THE FIRST ADDRESS PDE.  TSTANSPL IN TCOMTAB,  * 01050020
*    THE COMMUNICATION AREA, POINTS TO A PDL WHICH HAS BEEN PARSED    * 01100020
*    AND VALIDITY CHECKED.                                            * 01150020
*                                                                     * 01200020
* OUTPUT                                                              * 01250020
*    OUTPUT CONSISTS OF THE FOLLOWING                                 * 01300020
*    1.  DIAGNOSTIC MESSAGES                                          * 01350020
*    2.  A DEFER QUEUE POINTED TO BY DEFERTAB IN TCOMTAB IN THE       * 01400020
*    FORMAT DESCRIBED UNDER THE SYMBOL NEWQ.                          * 01450020
*    3.  RETURN CODES AS LISTED BELOW-                                * 01500020
*                                                                     * 01510020
*    0 - MAINLINE MAY REISSUE THE TEST MODE MESSAGE AND GET ANOTHER   * 01550020
*    SUBCOMMAND                                                       * 01600020
*    16 - ATTENTION HAS BEEN SCHEDULED                                * 01650020
*    20 - INDICATES RETURN FROM THE RETRY ROUTINE                     * 01700020
*                                                                     * 01750020
* EXTERNAL REFERENCES                                                 * 01800020
*         IKJEGIO OUTPUTS ERROR MESSAGES.  AT ENTRY, REGISTER ONE     * 01850020
*         CONTAINS THE COMPLEMENT OF THE ADDRESS OF THE MESSAGE PTRS. * 01900020
*                                                                     * 01950020
* EXITS, NORMAL--                                                     * 02000020
*         RETURN VIA REGISTER 14 TO THE CALLER                        * 02050020
*                                                                     * 02100020
* TABLES/WORK AREAS --                                                * 02150020
*    THIS MODULE USES TWO WORK AREAS                                  * 02200020
*    1.  SUBCOMMAND WORK AREA DESCRIBED BY WORKSP DSECT               * 02250020
*    2.  TEST COMMUNICATION WORK AREA DESCRIBED BY TCOMTAB DSECT      * 02300020
*                                                                     * 02350020
* ATTRIBUTES --                                                       * 02400020
*    REENTRANT, REFRESHABLE                                           * 02450020
*                                                                     * 02500020
* CHARACTER CODE DEPENDENCY --                                        * 02550020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESEN-  * 02600020
*    TATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO THE  * 02650020
*    ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO THAT * 02700020
*    REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT* 02750020
*    IN A CORRECT MODULE FOR THE NEW DEFINITIONS.                     * 02800020
*                                                                     * 02850020
* NOTES --                                                            * 02900020
*    NONE.                                                            * 02950020
*                                                                     * 03000020
*********************************************************************** 03050020
         EJECT                                                          03100020
IKJEGATD CSECT                          SECOND LOAD MODULE OF AT        03110020
* REGISTER EQUATES                                                      03150020
R0       EQU   0                        REGISTER 0                      03200020
R1       EQU   1                        REGISTER 1                      03250020
R2       EQU   2                        REGISTER 2                      03300020
R3       EQU   3                        REGISTER 3                      03350020
R4       EQU   4                        REGISTER 4                      03400020
R5       EQU   5                        REGISTER 5                      03450020
R6       EQU   6                        REGISTER 6                      03500020
R7       EQU   7                        REGISTER 7                      03550020
R8       EQU   8                        REGISTER 8                      03600020
R9       EQU   9                        REGISTER 9                      03650020
R10      EQU   10                       REGISTER 10                     03700020
R11      EQU   11                       REGISTER 11                     03750020
R12      EQU   12                       REGISTER 12                     03800020
R13      EQU   13                       REGISTER 13                     03850020
R14      EQU   14                       REGISTER 14                     03900020
R15      EQU   15                       REGISTER 15                     03950020
         SPACE                                                          04000020
* SPECIAL EQUATES                                                       04050020
ONBIT    EQU   X'80'                    HIGH ORDER BIT IS ON            04100020
BLANK    EQU   C' '                     BLANK                           04150020
DMELOAD  EQU   0                        OFFSET FOR LOADNAME IN DME      04200020
DMEDBE   EQU   8                        OFFSET FOR POINTER TO FIRST DBE 04250020
DMEDME   EQU   12                       OFFSET FOR POINTER TO NEXT DME  04300020
DBEPDL   EQU   0                        OFFSET IN DBE FOR PDL POINTER   04350020
DBEINBUF EQU   4                        OFFSET IN DBE FOR POINTER TO    04400020
*                                          INPUT BUFFER                 04450020
DBEDBE   EQU   8                        OFFSET IN DBE FOR POINTER TO    04500020
*                                          NEXT DBE                     04550020
SETOFF   EQU   X'BF'                    TURN OFF XCTL SWITCH            04560020
         SPACE                                                          04600020
ZERO     EQU   0                        NUMBER 0                        04650020
ONE      EQU   1                        NUMBER 1                        04700020
FOUR     EQU   4                        NUMBER 4                        04750020
TWELVE   EQU   12                       NUMBER 12                       04800020
SIXTEEN  EQU   16                       NUMBER 16                       04850020
TWENTY   EQU   20                       NUMBER 20                       04900020
TWENTY8  EQU   28                       NUMBER 28                       04950020
SIXTY8   EQU   68                       NUMBER 68                       05000020
SEVENTY2 EQU   72                       NUMBER 72                       05050020
L2       EQU   2                        LENGTH 2                        05100020
L3       EQU   3                        LENGTH 3                        05150020
L7       EQU   7                        LENGTH 7                        05200020
L4       EQU   4                        LENGTH 4                        05250020
L8       EQU   8                        LENGTH 8                        05300020
FACTOR   EQU   8                        DISPLACEMENT FOR MESSAGE        05350020
*                                          POINTERS                     05400020
CVTADDR  EQU   X'10'                    ADDRESS OF CVT                  05450020
         SPACE                                                          05500020
MSG1     EQU   0*FACTOR                 OFFSET FOR MESSAGE 1            05550020
MSG2     EQU   1*FACTOR                 OFFSET FOR MESSAGE 2            05600020
MSG3     EQU   2*FACTOR                 OFFSET FOR MESSAGE 3            05650020
         SPACE                                                          05700020
*                                          ROUTINE OF TSO/TEST          05800020
         SAVE  (14,12),,IKJEGATD        SAVE CALLER'S REGISTERS         05850020
         LR    R12,R15                  ESTABLISH ADDRESSABILITY FOR    05900020
         USING IKJEGATD,R12                THIS CSECT                   05950020
         USING TCOMTAB,R9               ESTABLISH ADDRESSABILITY TO     06000020
*                                          COMMUNICATION WORK AREA      06050020
         L     R5,REGSAVE2              R5=ADDR OF AT'S SAVE AREA       06100020
         NI    TSTFLGS2,SETOFF          TURN OFF XCTL SWITCH            06110020
         LR    R13,R5                   R13=ADDR OF AT'S SAVE AREA      06150020
         STM   R14,R12,TWELVE(R13)      SAVE AT'S REGISTERS IN CASE OF  06200020
*                                          AN ABEND                     06250020
         L     R10,ZERO(ZERO,R1)        R10=ADDRESS OF AT'S WORK AREA   06300020
         USING WORKSP,R10               ESTABLISH ADDRESSABILITY TO IT  06350020
         MVC   RETRY1(L3),RETRY2A1      SAVE THE ADDR OF THIS ROUTINE'S 06400020
*                                          RETRY ROUTINE                06450020
         MVC   STAEL(STAELENG),STAELIST MOVE LIST FORM OF STAE TO       06460020
*                                          WORK AREA                    06470020
         LA    R1,STAEL                 R1=ADDR OF LIST FORM            06480020
         L     R8,TSTSTAE               R8=ADDR OF STAE EXIT ROUTINE    06490020
         STAE  (R8),XCTL=NO,MF=(E,(R1)) CREATE NEW STAE REQUEST         06492020
         LTR   R15,R15                  WAS STAE SUCCESSFUL             06494020
SMTSTAE  BNZ   NOCORE                   NO. PRINT'INSUFFICIENT CORE'    06496020
*                                          STORAGE MESSAGE              06498020
         L     R11,PDEADDR              R11=POINTER TO FIRST ADDRESS    06500020
*                                          PDE                          06550020
         USING IKJPARMA,R11             ESTABLISH ADDRESSABILITY TO PDE 06600020
         XR    R7,R7                    R7=0 INDICATES FIRST VALID      06650020
*                                          PDE YET TO BE ENCOUNTERED    06700020
         SPACE                                                          06750020
ISITCONV EQU   *                        CHECK FOR CONVERTED PDE         06800020
         TM    PDEUSER,PDECONVD         HAS PDE BEEN CONVERTED          06850020
         BO    DEFERMSG                 PUT OUT MESSAGE FOR DEFER MUST  06900020
*                                          BE USED WITH FULLY QUALIFIED 06950020
*                                          ADDRESS                      07000020
         TM    PDE2FLG1,ONBIT           WAS A RANGE GIVEN               07050020
         BZ    ASKFIRST                 NO, TEST FOR FIRST UNRESOLVED   07100020
*                                          PDE                          07150020
         CLC   PDELEN1(L2),PDE2LEN1     DO LOADNAMES HAVE THE SAME      07200020
*                                          NUMBER OF CHARACTERS         07250020
         BNE   BADLDNM                  NO, PUT OUT ERROR MSG           07300020
         L     R2,PDELDNAM              R2=ADDRESS OF FIRST LOADNAME    07350020
         L     R6,PDE2LDNA              R6=ADDRESS OF SECOND LOADNAME   07400020
         LH    R4,PDELEN1               R4=LENGTH OF LOADNAMES          07450020
         BCTR  R4,ZERO                  DECREMENT FOR EXECUTE INSTR.    07500020
         EX    R4,COMPARE               DO LOADNAMES MATCH              07550020
         BNE   BADLDNM                  LOADNAMES DON'T MATCH - PUT OUT 07600020
*                                          ERROR MESSAGE                07650020
         SPACE                                                          07700020
ASKFIRST EQU   *                        IS THIS FIRST UNRESOLVED PDE    07750020
         LTR   R7,R7                    IS THE SWITCH ZERO              07800020
         BZ    MOVELOAD                 YES, MOVE LOADNAME TO WORKAREA  07850020
         LH    R4,PDELEN1               R4=LENGTH OF NEW LOADNAME       07900020
         CLR   R5,R4                    IS LENGTH EQUAL TO LENGTH OF    07950020
*                                          FIRST                        08000020
         BNE   BADLDNM                  NO, PUT OUT MESSAGE - LOADNAMES 08050020
*                                          FOR A DEFER REQUEST MUST     08100020
*                                          BE THE SAME                  08150020
         LA    R6,LDNAME                R6=POINTER TO LOADNAME IN       08200020
*                                          WORKAREA                     08250020
         L     R2,PDELDNAM              R2=POINTER TO NEW LOADNAME      08300020
         BCTR  R4,ZERO                  DECREMENT FOR EXECUTE INSTR     08350020
         EX    R4,COMPARE               COMPARE LOADNAMES               08400020
         BNE   BADLDNM                  LOADNAMES DON'T MATCH - PUT OUT 08450020
*                                          ERROR MESSAGE                08500020
         SPACE                                                          08550020
NAMESOK  EQU   *                        THE LOADNAMES MATCH             08600020
         L     R11,PDE2CHAI             R11=PDE CHAIN                   08650020
         LA    R11,ZERO(R11)            CLEAR HIGH ORDER BYTE           08700020
         LTR   R11,R11                  IS CHAIN EMPTY                  08750020
         BZ    SEARCHQ                  YES, CHECK FOR DEFER QUEUE      08800020
         B     ISITCONV                 CHECK FOR PDE CONVERTED         08850020
         SPACE                                                          08860020
COMPARE  CLC   ZERO(ZERO,R6),ZERO(R2)   COMPARE INSTRUCTION             08950020
         SPACE                                                          09000020
DEFERMSG EQU   *                        PREPARE TO OUTPUT MESSAGE FOR   09050020
*                                          FULLY QUALIFIED ADDRESS MUST 09100020
*                                          BE GIVEN WITH DEFER          09150020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     09200020
         LA    R1,MSG2(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTERS  09250020
         B     PUTMSG                   PUT OUT MESSAGE AND RETURN      09300020
         SPACE                                                          09350020
BADLDNM  EQU   *                        PREPARE TO OUTPUT MESSAGE FOR   09400020
*                                          ALL LOADNAMES ON A DEFER     09450020
*                                          REQUEST MUST BE SAME         09500020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     09550020
         LA    R1,MSG3(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTERS  09600020
         B     PUTMSG                   PUT OUT MESSAGE AND RETURN      09650020
         SPACE                                                          09700020
MOVELOAD EQU   *                        FIRST UNRESOLVED PDE FOUND      09750020
         LA    R7,ONE(ZERO,R7)          SET SWITCH FOR FIRST UNRESOLVED 09800020
*                                          PDE                          09850020
         MVI   LDNAME,BLANK             BLANK OUT LOADNAME FIELD IN     09900020
         MVC   LDNM1(L7),LDNAME            WORKAREA                     09950020
         L     R6,PDELDNAM              R6=ADDRESS OF LOADNAME          10000020
         LA    R4,LDNAME                R4=ADDRESS FOR LOADNAME IN      10050020
*                                          WORKAREA                     10100020
         LH    R5,PDELEN1               R5=LENGTH OF LOADNAME STRING    10150020
         BCTR  R5,ZERO                  DECREMENT FOR MOVE INST         10200020
         EX    R5,LOADMVC               MOVE LOADNAME TO WORKAREA       10250020
         LA    R5,ONE(ZERO,R5)          R5=LENGTH OF LOADNAME           10300020
         B     NAMESOK                  CHECK FOR MORE PDE'S            10350020
         SPACE                                                          10400020
LOADMVC  MVC   ZERO(ZERO,R4),ZERO(R6)   MOVE LOADNAME TO WORKAREA       10450020
         SPACE                                                          10500020
SEARCHQ  EQU   *                        ARE ANY DME'S ON THE DEFER      10550020
*                                          QUEUE                        10600020
         OC    DEFERTAB(L4),DEFERTAB    IS THE QUEUE EMPTY              10650020
         BZ    NEWQ                     YES, ESTABLISH THE QUEUE        10700020
         L     R2,DEFERTAB              R2=ADDRESS OF FIRST DME ON THE  10750020
*                                          QUEUE                        10800020
         SPACE                                                          10850020
TESTNAME EQU   *                        COMPARE LOADNAMES               10900020
         CLC   LDNAME(L8),DMELOAD(R2)   DOES NEW LOADNAME EQUAL TO ONE  10950020
*                                          IN DME                       11000020
         BNE   NEXTDME                  NO, ARE THERE MORE DME'S        11050020
         L     R3,DMEDBE(ZERO,R2)       R3=POINTER TO FIRST DBE         11100020
         SPACE                                                          11150020
TRYDBE   EQU   *                        IS THIS LAST DBE FROM DME       11200020
         OC    DBEDBE(L4,R3),DBEDBE(R3) IS DBE LINK FIELD ZERO          11250020
         BZ    GETDBE                   YES, GET CORE FOR NEXT DBE      11300020
         L     R3,DBEDBE(ZERO,R3)       R3=POINTER TO NEXT DBE          11350020
         B     TRYDBE                   IS THIS LAST DBE FROM DME       11400020
         SPACE                                                          11450020
NEXTDME  EQU   *                        ARE MORE DME'S ON THE QUEUE     11500020
         OC    DMEDME(L4,R2),DMEDME(R2) IS LINK FIELD EMPTY             11550020
         BZ    NEWDME                   YES, GET CORE FOR ANOTHER DME   11600020
         L     R2,DMEDME(ZERO,R2)       R2=POINTER TO NEXT DME          11650020
         B     TESTNAME                 BRANCH TO COMPARE LOADNAMES     11700020
         SPACE                                                          11750020
NEWQ     EQU   *                        THE DEFER QUEUE MUST BE FIRST   11800020
* ESTABLISHED.  THE DEFER MODULE ELEMENT HAS THESE FIELDS-              11850020
* DMELOAD(LOAD NAME) - 8 BYTES, DMEDBE(POINTER TO FIRST DEFER BREAK     11900020
* ELEMENT) - 4 BYTES, AND DMEDME(DME LINK FIELD) - 4 BYTES.             11950020
* THE DEFER BREAK ELEMENT HAS THESE THREE FIELDS-  DBEPDL(POINTER TO    12000020
* THE PDL) - 4 BYTES, DBEINBUF(POINTER TO INPUT COMMAND BUFFER) - 4     12050020
* BYTES, AND DBEDBE(POINTER TO NEXT DBE) - 4 BYTES.                     12100020
         SPACE                                                          12150020
         MVC   GETCORE(GETLEN),GETL     MOVE LIST FORM OF GETMAIN TO    12200020
*                                          WORKAREA                     12250020
         LA    R1,GETCORE               R1=ADDRESS OF LIST FORM         12300020
         GETMAIN EC,LV=TWENTY8,A=ADDRCORE,SP=ONE,MF=(E,(R1)) GET CORE   12350020
*                                          FOR FIRST DME AND DBE        12400020
         LTR   R15,R15                  WAS CORE GOTTEN                 12450020
SMTGET01 BNZ   NOCORE                   NO. PRINT'INSUFFICIENT CORE'    12500020
         L     R2,ADDRCORE              R2=ADDRESS OF GOTTEN CORE       12550020
         ST    R2,DEFERTAB              SET POINTER IN TCOMTAB          12600020
         SPACE                                                          12650020
BLDELEMS EQU   *                        ACTUAL BUILDING OF ELEMENTS IS  12700020
*                                          DONE HERE                    12750020
         MVC   DMELOAD(L8,R2),LDNAME    PUT LOADNAME IN DME             12800020
         LA    R3,SIXTEEN(ZERO,R2)      R3=ADDRESS OF FIRST DBE FROM    12850020
*                                          DME                          12900020
         ST    R3,DMEDBE(ZERO,R2)       PUT ADDRESS OF FIRST DBE INTO   12950020
*                                          DME                          13000020
         XC    DMEDME(L4,R2),DMEDME(R2) ZERO DME LINK FIELD             13050020
         L     R4,TSTANSPL              R4=ADDRESS OF PDL               13100020
         ST    R4,DBEPDL(ZERO,R3)       SAVE IN DBE                     13150020
         XC    TSTANSPL(L4),TSTANSPL    CLEAR POINTER TO PDL            13200020
         L     R4,INBUF                 R4=POINTER TO INPUT BUFFER      13250020
         ST    R4,DBEINBUF(R3)          SAVE IN DBE                     13300020
         XC    INBUF(L4),INBUF          CLEAR INBUF IN TCOMTAB          13350020
         XC    DBEDBE(L4,R3),DBEDBE(R3) ZERO DBE LINK FIELD             13400020
         B     CODE0                    RETURN TO MAINLINE WITH DEFER   13450020
*                                          QUEUE SUCCESSFULLY BUILT     13500020
         SPACE                                                          13550020
NEWDME   EQU   *                        A NEW DME MUST BE ESTABLISHED   13600020
         MVC   GETCORE(GETLEN),GETL     MOVE LIST FORM OF GETMAIN TO    13650020
*                                          WORKAREA                     13700020
         LA    R1,GETCORE               R1=ADDRESS OF LIST FORM         13750020
         GETMAIN EC,LV=TWENTY8,A=ADDRCORE,SP=ONE,MF=(E,(R1)) GET CORE   13800020
*                                          FOR NEW DME                  13850020
         LTR   R15,R15                  WAS CORE GOTTEN                 13900020
SMTGET02 BNZ   NOCORE                   NO. PRINT'INSUFFICIENT CORE'    13950020
         L     R3,ADDRCORE              R3=ADDRESS OF NEW DME           14000020
         ST    R3,DMEDME(ZERO,R2)       LINK NEW DME TO LAST DME        14050020
         LR    R2,R3                    R2=ADDRESS OF NEW DME           14100020
         B     BLDELEMS                 BRANCH TO FILL IN FIELDS OF     14150020
*                                          DME AND DBE                  14200020
         SPACE                                                          14250020
GETDBE   EQU   *                        A NEW DEFER BREAK ELEMENT MUST  14300020
*                                          BE ESTABLISHED               14350020
         MVC   GETCORE(GETLEN),GETL     MOVE LIST FORM OF GETMAIN TO    14400020
*                                          WORK AREA                    14450020
         LA    R1,GETCORE               R1=ADDRESS OF L FORM OF MACRO   14500020
         GETMAIN EC,LV=TWELVE,A=ADDRCORE,SP=ONE,MF=(E,(R1)) GET CORE    14550020
*                                          FOR NEW DBE                  14600020
         LTR   R15,R15                  WAS CORE GOTTEN                 14650020
SMTGET03 BNZ   NOCORE                   NO. PRINT'INSUFFICIENT CORE'    14700020
         L     R4,ADDRCORE              R4=ADDRESS OF GOTTEN CORE       14750020
         ST    R4,DBEDBE(ZERO,R3)       CHAIN NEW DBE TO LAST DBE       14800020
         XC    DBEDBE(L4,R4),DBEDBE(R4) ZERO NEW DBE LINK FIELD         14850020
         L     R5,TSTANSPL              R5=ADDRESS OF PDL               14900020
         ST    R5,DBEPDL(ZERO,R4)       SAVE POINTER TO PDL IN NEW DBE  14950020
         XC    TSTANSPL(L4),TSTANSPL    CLEAR POINTER TO PDL            15000020
         L     R5,INBUF                 R5=POINTER TO INPUT BUFFER      15050020
         ST    R5,DBEINBUF(R4)          SAVE IN DBE                     15100020
         XC    INBUF(L4),INBUF          CLEAR INBUF IN TCOMTAB          15150020
         B     CODE0                    RETURN TO MAINLINE WITH DEFER   15200020
*                                          ELEMENT SUCCESSFULLY         15250020
*                                          ESTABLISHED                  15300020
         SPACE                                                          15350020
NOCORE   EQU   *                        THERE IS INSUFFICIENT CORE TO   15400020
*                                          SET UP DEFER ELEMENT         15450020
         L     R1,MSGADDR               R1=ADDRESS OF MESSAGE CSECT     15500020
         LA    R1,MSG1(ZERO,R1)         R1=ADDRESS OF MESSAGE POINTERS  15550020
         SPACE                                                          15600020
PUTMSG   EQU   *                        HAVE IKJEGIO PUT OUT MESSAGE    15650020
         LCR   R1,R1                    LOAD COMPLEMENT TO INDICATE     15700020
*                                          ERROR MESSAGE TO TERMINAL    15750020
         L     R15,TPUTADDR             R15=ADDRESS OF MESSAGE WRITER   15800020
*                                          ROUTINE OF IKJEGIO           15850020
         BALR  R14,R15                  GO WRITE OUT MESSAGE            15900020
         LTR   R15,R15                  WAS I/O SUCCESSFUL              15950020
         BZ    CODE0                    YES, RETURN TO MAINLINE WITH    16000020
*                                          CODE EQUAL TO ZERO           16050020
         LA    R2,SIXTEEN               R2=16 - ATTENTION INDICATION    16100020
         CLR   R2,R15                   WAS AN ATTENTION SCHEDULED      16150020
         BE    RETMAIN                  RETURN  TO MAINLINE - ATTENTION 16200020
*                                          SCHEDULED                    16250020
         SPACE                                                          16300020
CODE0    EQU   *                        SET RETURN CODE TO ZERO         16350020
         XR    R15,R15                  R15=0                           16400020
         B     RETMAIN                  RETURN TO MAINLINE              16450020
         SPACE                                                          16500020
RETRY2   EQU   *                        RETRY ROUTINE IN CASE OF        16550020
*                                          AN ABEND                     16600020
         L     R5,CVTPTR                R5=ADDRESS OF CVT               16650020
         USING CVT,R5                   ESTABLISH ADDRESSABILITY TO IT  16700020
         L     R5,CVTTCBP               R5=POINTER TO DOUBLE WORD OF    16750020
*                                          POINTERS TO NEXT TO BE DIS-  16800020
*                                          PATCHED AND CURRENT TCB'S    16850020
         DROP  R5                                                       16900020
         L     R5,FOUR(R5)              R5=POINTER TO CURRENT TCB       16950020
*                                          (TEST'S TCB)                 17000020
         USING TCB,R5                   ESTABLISH ADDRESSABILITY TO IT  17050020
         L     R9,TCBTRN                R5=ADDRESS OF TCOMTAB           17100020
         DROP  R5                                                       17150020
         L     R13,REGSAVE2             R13=ADDRESS OF AT'S SAVE AREA   17200020
         L     R12,SIXTY8(R13)          RESTORE BASE REGISTER           17250020
         LTR   R0,R0                    DID STAE ROUTINE GET CORE       17300020
         LM    R2,R12,TWENTY8(R5)       RESTORE REGS 2-12               17350020
         BNZ   DIDNOT                   NO, STAE DID NOT GET CORE -     17400020
*                                          BRANCH AROUND FREEMAIN       17450020
         FREEMAIN R,LV=104,A=(R1)       FREE CORE GOTTEN BY STAE        17500020
         SPACE                                                          17550020
DIDNOT   EQU   *                        CONTINUE RETRY ROUTINE          17600020
         LA    R15,TWENTY               R15=20 - INDICATES RETURN FROM  17650020
*                                       RETRY ROUTINE                   17700020
         SPACE                                                          17750020
RETMAIN  EQU   *                        RETURN TO MAINLINE              17800020
         L     R13,FOUR(ZERO,R13)       RESTORE R13                     17850020
         RETURN (14,12),,RC=(15)        RETURN                          17900020
         SPACE                                                          17950020
GETL     GETMAIN EC,SP=ONE,MF=L         LIST FORM OF GETMAIN            18000020
GETLEN   EQU   *-GETL                   LENGTH OF LIST FORM             18050020
STAELIST DS    0F                       NAME OF LIST FORM OF STAE       18060020
         STAE  MF=L                                                     18070020
STAELENG EQU   *-STAELIST               LENGTH OF LIST FORM OF MACRO    18080020
         SPACE                                                          18100020
* CONSTANTS                                                             18150020
         DS    0F                       ALIGNMENT                       18200020
SP1      DC    X'01000000'              SUBPOOL 1 INDICATOR             18250020
RETRY2A  DC    A(RETRY2)                ADDRESS OF RETRY ROUTINE        18300020
RETRY2A1 EQU   RETRY2A+1                SECOND BYTE OF RETRY2A          18350020
MSGADDR  DC    V(IKJEGM2)               ADDRESS OF MESSAGE CSECT        18400020
         DS    0F                       ALIGNMENT                       18450020
          EJECT                                                         18500020
IKJEGM2  CSECT                          MESSAGE CSECT                   18550020
         SPACE                                                          18600020
* THE MESSAGE CSECT IS ARRANGED SO THAT A LIST OF ADDRESSES AT THE      18650020
* BEGINNING POINTS TO THE MESSAGES.  FOR EACH MESSAGE THERE IS A        18700020
* POSSIBIBLITY OF MORE THAN ONE MESSAGE LEVEL WITH A POINTER NEEDED     18750020
* FOR EACH.  IF A MESSAGE HAS FEWER THAN THE MAXIMUM NUMBER OF LEVELS   18800020
* A WORD OF ZEROES IS USED FOR EACH NON-USED LEVEL POINTER.  THE        18850020
* MESSAGES THEMSELVES BEGIN WITH A HALF-WORD OF MESSAGE LENGTH          18900020
* (INCLUDING THE TWO PREFACE HALF-WORDS) AND A HALF-WORD OF ZEROES FOR  18950020
* THE OFFSET FIELD FOLLOWED BY THE MESSAGE ITSELF.                      19000020
         SPACE                                                          19050020
MSG01    DC    A(AT2M2)                 ADDRESS FOR MESSAGE 1           19100020
         DC    A(0)                     ADDRESS FOR MESSAGE 1           19150020
MSG02    DC    A(AT2M1)                 ADDRESS FOR MESSAGE 2           19200020
         DC    A(AT2M3)                 ADDRESS FOR MESSAGE 2           19250020
MSG03    DC    A(AT2M1)                 ADDRESS FOR MESSAGE 3           19300020
         DC    A(AT2M4)                 ADDRESS FOR MESSAGE 3           19350020
         SPACE                                                          19400020
         DS    0H                       ALIGNMENT                       19450020
AT2M1    DC    AL2(AT2E1-AT2M1)         LENGTH OF MESSAGE               19500020
         DC    AL2(0)                   FILLER                          19550020
         DC    C'IKJ57309 UNABLE TO ESTABLISH DEFER BREAKPOINT+' TXT    19600020
AT2E1    EQU   *                        END OF AT2M1                    19650020
         SPACE                                                          19700020
         DS    0H                       ALIGNMENT                       19750020
AT2M2    DC    AL2(AT2E2-AT2M2)         LENGTH OF MESSAGE               19800020
         DC    AL2(0)                   FILLER                          19850020
         DC    C'IKJ57308 NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND' * 19900020
AT2E2    EQU   *                        END OF AT2M2                    20000020
         SPACE                                                          20050020
         DS    0H                       ALIGNMENT                       20100020
AT2M3    DC    AL2(AT2E3-AT2M3)         LENGTH OF MESSAGE               20150020
         DC    AL2(0)                   FILLER                          20200020
         DC    C'IKJ57309 FULLY QUALIFIED ADDRESS MUST BE GIVEN'  TXT   20250020
AT2E3    EQU   *                        END OF AT2M3                    20300020
         SPACE                                                          20350020
         DS    0H                       ALIGNMENT                       20400020
AT2M4    DC    AL2(AT2E4-AT2M4)         LENGTH OF MESSAGE               20450020
         DC    AL2(0)                   FILLER                          20500020
         DC    C'IKJ57309 ALL LOADNAMES FOR A DEFER REQUEST MUST ' TXT  20550020
         DC    C'BE THE SAME'           MSG TXT                         20600020
AT2E4    EQU   *                        END OF AT2M4                    20650020
         SPACE                                                          20700020
         EJECT                                                          20750020
WORKSP   DSECT                          AT'S WORK AREA                  20800020
*THE FIRST TWO WORDS ARE INPUT FROM MAINLINE WHEN AT IS TO CREATE       20850020
*ACTIVE BREAK ELEMENTS FROM THE DEFER QUEUE.  WHEN AT IS ENTERED        20900020
*BECAUSE A NEW MODULE HAS BEEN BROUGHT INTO STORAGE THE LAST 64         20950020
*BYTES OF THIS WORK AREA MUST BE RESERVED FOR A REGISTER SAVE AREA      21000020
*TO BE USED BY IKJEGLDF.                                                21050020
LDNAME   DS    2F                       LOADNAME AT IS WORKING WITH     21100020
LDNM1    EQU   LDNAME+1                 BYTE 2 OF LDNAME                21150020
PARSECD  EQU   LDNAME                   SAVE RETURN CODE FROM PARSE     21160020
BYTENUMB DS    F                        SAVE AREA FOR NUMBER BYTES      21200020
*                                          LAST GOTTEN AND SUBPOOL      21250020
*                                          NUMBER                       21300020
         ORG   *-TWELVE                 TO BEGINNING OF WORK AREA       21350020
PARMS    EQU   *                        PARAMETERS FOR PARSE            21400020
PTUPT    DS    A                        POINTER TO UPT                  21450020
PTECB    DS    A                        POINTER TO ECB                  21500020
PTCPECB  DS    A                        POINTER TO CP ECB               21550020
PTPCL    DS    A                        POINTER TO PCL                  21600020
PTANSWPL DS    A                        POINTER TO ANSWER PLACE         21650020
PTCOMBUF DS    A                        POINTER TO COMMAND BUFFER       21700020
PTSAVE   DS    A                        POINTER TO AT'S SAVE AREA       21750020
         ORG   *-SIXTEEN                BACK 16 BYTES                   21800020
GETCORE  GETMAIN EC,SP=ONE,MF=L         RESERVE FOR LIST FORM OF        21850020
*                                          GETMAIN                      21900020
ADDRCORE EQU   GETCORE+4                SECOND WORD OF LIST FORM        21950020
STAEL    DS    0F                       NAME OF LIST FORM OF STAE MACRO 22000020
         STAE  MF=L                    FOR LIST FORM OF STAE MACRO      22050020
         ORG   WORKSP+SEVENTY2          GET PAST REGISTER SAVE AREA     22100020
SAVEPTR  DS    F                        SAVE POINTER TO PREVIOUS        22150020
*                                          LINK FIELD                   22200020
CHNADDR  DS    F                        SAVE AREA FOR CHAIN ADDRESS     22250020
         ORG   WORKSP+SEVENTY2          GET PAST REGISTER SAVE AREA     22260020
XCTLPARM DS    F                        WORK AREA ADDRESS               22300020
PDEADDR  DS    F                        ADDRESS OF FIRST ADDRESS PDE    22350020
MAINTRY  DS    F                        SAVE ADDR OF MAINLINE'S RETRY   22360020
MAINTRY1 EQU   MAINTRY+1                SECOND BYTE OF MAINTRY          22370020
         EJECT                                                          22400020
         IKJPARMA                       PDE DSECT                       22450020
         EJECT                                                          22500020
TCB      IKJTCB                         EXPANSION OF TCB                22550020
         EJECT                                                          22600020
CVT      DSECT                          DSECT FOR CVT                   22650020
         CVT                                                            22700020
         EJECT                                                          22750020
         TCOMTAB                        COMMUNICATIONS TABLE DSECT      22800020
         EJECT                                                          22850020
* EQUATES WHICH MUST FOLLOW DSECTS                                      22900020
BOUNDARY EQU   PDEUSER+3                LOW ORDER BYTE OF USERWORD 1    22950020
BOUND2   EQU   PDE2USER+3               LOW ORDER BYTE OF USERWORD 2    23000020
USER1    EQU   PDEUSER+1                SECOND BYTE OF USERWORD 1       23050020
USER2    EQU   PDE2USER+1               SECOND BYTE OF USERWORD 2       23100020
RETRY1   EQU   TSTRETRY+1               SECOND BYTE OF TSTRETRY         23150020
         END                                                            23200020
