 TITLE 'IKJEGATN - ATTENTION ROUTINE FOR TSO/TEST'                      00050020
*********************************************************************** 00100020
*                                                                     * 00150020
* STATUS                                                              * 00200020
*    VERSION NO. 01, OS/360 RELEASE NO. 21.7                          * 00250021
*                                                                     * 00300020
* FUNCTION/OPERATION                                                  * 00350020
*    THIS ATTENTION EXIT ROUTINE IS CALLED BY THE SYSTEM ATTENTION    * 00400020
*    HANDLING ROUTINE.  INACTED BY STRIKING THE ATTENTION KEY OF AN   * 00450020
*    OS/TS TERMINAL, ITS PURPOSE IS TO FORCE UNSCHEDULED BREAKPOINTS  * 00500020
*    IN ORDER TO HALT OPERATION OF A PROBLEM PROGRAM OR INFORM A TEST * 00550020
*    SUBCOMMAND PROCESSING PROGRAM THAT AN ATTENTION HAS OCCURRED.    * 00600020
*                                                                     * 00650020
* ENTRY POINTS                                                        * 00700020
*    IKJEGATN                                                           00750020
*                                                                     * 00800020
* INPUT                                                               * 00850020
*    1.  REGISTER 1 CONTAINS THE ADDRESS OF A PARAMETER LIST          * 00900020
*    *   WHICH CONSISTS OF                                              00950020
*    *   A.  POINTER TO TERMINAL ATTENTION INTERRUPT ELEMENT            01000020
*    *   B.  POINTER TO INPUT BUFFER                                    01050020
*    *   C.  POINTER TO TCOMTAB                                         01100020
*    2.  REGISTER 13 CONTAINS SAVE AREA ADDRESS                       * 01150020
*    3.  REGISTER 14 CONTAINS RETURN ADDRESS                          * 01200020
*    4.  REGISTER 15 CONTAINS ENTRY POINT ADDRESS                     * 01250020
*                                                                     * 01300020
* OUTPUT                                                              * 01350020
*    1.  REGISTER 15 CONTAINS A RETURN CODE OF ZERO                   * 01400020
*    2.  INBUF - POINT TO INPUT COMMAND                               * 01650020
*    3.  ECBTMP IS POSTED WITH A X'48' TO SIGNIFY AN ATTENTION IS     * 01700020
*    *   SCHEDULED                                                      01750020
*                                                                     * 01800020
* EXTERNAL REFERENCES                                                 * 01850020
*         IKJSCAN - DETERMINE TYPE OF INPUT                           * 01900020
*         GETLINE -                                                   * 02000020
*         A.  GET SEGMENTS OTHER THAN THE FIRST FOR INPUT             * 02050020
*         B.  GET A LINE FROM THE TERMINAL AFTER THE TEST MODE        * 02100020
*             MESSAGE IS ISSUED BY THIS ROUTINE                       * 02150020
*         PUTLINE -                                                     02200020
*         A.  ISSUE TEST MODE MESSAGE                                   02250020
*         B.  WRITE OUT CHAINED SECOND LEVEL MESSAGE                    02300020
*                                                                     * 02350020
* EXITS, NORMAL                                                       * 02400020
*         RETURN VIA REGISTER 14                                        02450020
*                                                                     * 02500020
* EXITS, ERROR                                                        * 02550020
*         NONE                                                          02600020
*                                                                     * 02650020
* TABLES AND WORKAREAS                                                * 02700020
*    WORKAREA IS AS DESCRIBED BY WORKSP DSECT                         * 02710020
*                                                                     * 02750020
* ATTRIBUTES                                                          * 02800020
*    REENTRANT ROUTINE                                                * 02850020
*                                                                     * 02900020
* CHARACTER CODE DEPENDENCY                                             02910020
*    NONE                                                               02920020
*                                                                       02930020
* NOTES                                                               * 02950020
*    NONE                                                             * 03000020
*********************************************************************** 03050020
         EJECT                                                          03100020
IKJEGATN CSECT                                                          03150020
*RELEASE 21 CHANGES                                                     03160021
*A327100,327200,284100,31600-31900                              SA55218 03170021
*D289500                                                        SA55218 03180021
*C284000,2500                                                   SA55218 03190021
* REGISTER EQUATES                                                      03200020
ZERO     EQU   0                        PARAMETER REGISTER              03250020
PARAMREG EQU   1                        PARAMETER REGISTER              03300020
WORKE    EQU   2                        EVEN WORK REGISTER              03350020
WORKO    EQU   3                        ODD WORK REGISTER               03400020
REG4     EQU   4                        WORK REGISTERS                  03450020
REG5     EQU   5                        *                               03500020
REG6     EQU   6                        *                               03550020
REG7     EQU   7                        *                               03600020
REG8     EQU   8                        ADDRESSABILITY TO WORK SPACE    03650020
TCOMADDR EQU   9                        ADDRESS OF TCOMTAB              03700020
REG10    EQU   10                       WORK REGISTER                   03750020
REG11    EQU   11                       WORK REGISTER                   03800020
BASE     EQU   12                       BASE REGISTER                   03850020
SAVEREG  EQU   13                       SAVE AREA ADDRESS REGISTER      03900020
RETREG   EQU   14                       ADDRESS OF RETURN POINT         03950020
ADDREG   EQU   15                       ADDRESS REGISTER                04000020
RETCODE  EQU   15                       RETURN CODE REGISTER            04050020
         SPACE                                                          04100020
* OTHER EQUATES                                                         04150020
ONE      EQU   1                        NUMBER 1                        04200020
TWO      EQU   2                        NUMBER 2                        04250020
FOUR     EQU   4                        NUMBER 4                        04300020
FIVE     EQU   5                        NUMBER 5                        04350020
SIX      EQU   6                        NUMBER 6                        04400020
EIGHT    EQU   8                        NUMBER 8                        04500020
TWELVE   EQU   12                       NUMBER 12                       04550020
L1       EQU   1                        LENGTH 1                        04700020
L2       EQU   2                        LENGTH 2                        04750020
L3       EQU   3                        LENGTH 3                        04800020
L4       EQU   4                        LENGTH 4                        04850020
ONBIT    EQU   X'80'                    HIGH ORDER BIT ON               04950020
RBLINK   EQU   28                       OFFSET INTO RB FOR LINK FIELD   05000020
RBSTAB   EQU   10                       OFFSET INTO RB FOR ATTRIBUTES   05050020
RBOK     EQU   X'80'                    BIT SETTING TO TEST FOR RB      05052020
*                                          AN IRB OR PRB                05054020
RBKEY    EQU   17                       OFFSET INTO RB FOR PSW KEY      05060020
PBIT     EQU   X'01'                    SIGNIFIES P BIT ON IN PSW       05070020
KEYZERO  EQU   X'F0'                    BIT SETTING TO TEST FOR KEY     05080020
*                                          ZERO                         05090020
RESADDR  EQU   20                       OFFSET INTO RB FOR IC           05100020
MINUS    EQU   C'-'                     CHARACTER '-'                   05150020
FACTOR   EQU   8                        INDEX TO GET MESSAGE POINTER    05200020
MSG1     EQU   0*FACTOR                 OFFSET FOR MESSAGE 1            05250020
WAITCNT  EQU   28                       OFFSET INTO RB FOR WAIT         05300020
*                                          COUNT                        05350020
         SPACE                                                          05400020
         SAVE  (14,12),,*               SAVE REGISTERS                  05450020
         LR    BASE,ADDREG              GET ENTRY POINT ADDRESS         05500020
         USING IKJEGATN,BASE            ESTABLISH ADDRESSABILITY        05550020
         USING ATTNPARM,PARAMREG        ESTABLISH ADDRESSABILITY TO     05600020
*                                          INPUT PARAMETERS             05650020
         L     TCOMADDR,USERINFO        GET POINTER TO TCOMTAB          05700020
         USING TCOMTAB,TCOMADDR         ESTABLISH ADDRESSABILITY        05750020
         L     REG8,WORKAREA            GET POINTER TO WORK AREA        05800020
         USING TSTCWORK,REG8            ESTABLISH ADDRESSABILITY TO IT  05850020
         LA    REG8,CWORKATN            R8=ADDRESS OF ATTENTION'S WORK  05900020
*                                          AREA                         05950020
         DROP  REG8                                                     06000020
         ST    SAVEREG,FOUR(ZERO,REG8)  SAVE ADDR OF CALLER'S SAVE AREA 06050020
         ST    REG8,EIGHT(ZERO,SAVEREG) STORE ATTN'S SAVE AREA POINTER  06100020
*                                          IN CALLER'S SAVE AREA        06150020
         LR    SAVEREG,REG8             R13=ATTN'S SAVE AREA POINTER    06200020
*                                          AND WORK AREA POINTER        06250020
         USING WORKSP,SAVEREG           ESTABLISH ADDRESSABILITY TO     06300020
*                                          WORK AREA                    06350020
         XC    ZEROWORK(ZEROLEN),ZEROWORK ZERO WORK AREA                06400020
         L     REG4,ATTNBUF             GET POINTER TO COMMAND BUFFER   06450020
         L     REG5,TAIEPTR             R5=POINTER TO TAIE              06500020
         DROP  PARAMREG                                                 06550020
         USING TAIE,REG5                ESTABLISH ADDRESSABILITY TO     06600020
*                                          TAIE                         06650020
         LH    REG5,TAIEMSGL            R5=MESSAGE LENGTH               06700020
         LTR   REG5,REG5                IS LENGTH ZERO                  06750020
         BZ    CODE0                    YES, RETURN                     06800020
         MVC   GETCORE(GETLEN),GETL     MOVE LIST FORM TO WORK AREA     06850020
         LA    PARAMREG,GETCORE         PUT ADDR OF LIST IN REG1        06900020
         LA    REG5,FOUR(ZERO,REG5)     R5=AMOUNT OF CORE NEEDED        06950020
         GETMAIN EC,LV=(REG5),A=ADDRCORE,SP=1,MF=(E,(1)) GET CORE FOR   07000020
*                                          INPUT BUFFER                 07050020
         LTR   RETCODE,RETCODE          WAS GETMAIN SUCCESSFUL          07100020
         BNZ   CODE0                    NO, RETURN                      07150020
         L     REG6,ADDRCORE            R6=ADDR OF GOTTEN CORE          07200020
         ST    REG6,ADDR1               SAVE IN WORK AREA               07250020
         STH   REG5,ZERO(ZERO,REG6)     SAVE LENGTH OF BUFFER           07300020
         XC    TWO(L2,REG6),TWO(REG6)   ZERO OFFSET FIELD               07350020
         LA    REG6,FOUR(ZERO,REG6)     R6=POINTER FOR BEGINNING OF     07400020
*                                          LINE                         07450020
         LA    REG7,FIVE                R7=5                            07500020
         SR    REG5,REG7                R5=LENGTH OF INPUT MINUS        07550020
*                                          ONE FOR EXECUTE INSTR.       07600020
         EX    REG5,MOVELINE            MOVE INPUT LINE TO GOTTEN CORE  07650020
         SPACE                                                          07700020
AROUND   EQU   *                        PROCEDURE FOR SCANNING          07750020
*                                          COMMAND                      07800020
         LA    PARAMREG,PARMS           R1=ADDRESS OF PARAMETER LIST    07850020
*                                          FOR SCAN                     07900020
         USING CSPL,PARAMREG            ESTABLISH ADDRESSABILITY TO IT  07950020
         LM    WORKE,REG4,TSTUPT        GET POINTERS TO UPT, ECT, AND   08000020
*                                          CP ECB FROM TCOMTAB          08050020
         ST    WORKE,CSPLUPT            SAVE PTR TO UPT                 08100020
         ST    WORKO,CSPLECT            SAVE PTR TO ECT                 08150020
         ST    REG4,CSPLECB             SAVE PTR TO CP'S ECB            08200020
         LA    REG5,FLGWORD             GET POINTER TO FLAG WORD        08300020
         ST    REG5,CSPLFLG             SAVE PTR TO FLAG WORD           08350020
         LA    REG6,OUTAREA             GET POINTER TO OUTPUT AREA      08400020
         ST    REG6,CSPLOA              SAVE PTR TO OUTPUT AREA         08450020
         L     REG7,ADDR1               GET POINTER TO COMMAND BUFFER   08500020
         ST    REG7,CSPLCBUF            SAVE PTR TO BUFFER              08550020
         MVC   FLGWORD(L4),SCANFLAG     SET SCAN FLAG FOR NO SYNTAX     08600020
*                                          CHECK                        08650020
         DROP  PARAMREG                                                 08700020
         LINK  EP=IKJSCAN               SCAN INPUT LINE                 08750020
         LTR   RETCODE,RETCODE          SCAN SUCCESSFUL                 08800020
         BNZ   CHKLINE                  NO, ASSUME NON-QUESTION,        08850020
*                                          NON-NULL LINE -- IF          08900020
*                                          OTHER, MAINLINE WILL         08950020
*                                          DISCOVER                     09000020
         LA    REG5,OUTAREA             R5=ADDRESS OF SCAN'S OUTPUT     09050020
*                                          AREA                         09100020
         USING CSOA,REG5                ESTABLISH ADDRESSABILITY TO IT  09150020
         TM    CSOAFLG,CSOANOC          WAS INPUT A NULL LINE           09200020
         BO    FREEBUF1                 YES, FREE CORE FOR BUFFER       09250020
         TM    CSOAFLG,CSOAQM           WAS A QUESTION MARK INPUT       09300020
         BO    QUESTION                 YES PERFORM I/O                 09350020
         DROP  REG5                                                     09400020
         SPACE                                                          09450020
CHKLINE  EQU   *                        CHECK FOR MORE THAN 1 PHYSICAL  09500020
*                                          LINE                         09550020
         XC    SUBCHAIN(L4),SUBCHAIN    CLEAR SUBCHAIN FIELD            09600020
         L     REG5,TSTECT              R5=ADDRESS OF ECT               09650020
         USING ECT,REG5                 ESTABLISH ADDRESSABILITY TO IT  09700020
         OI    ECTMSGF,ONBIT            INDICATE SECOND LEVEL MESSAGES  09750020
*                                          TO BE CLEARED                09800020
         DROP  REG5                                                     09850020
         L     REG5,ADDR1               R5=ADDR OF BUFFER               09900020
         XC    TWO(L2,REG5),TWO(REG5)   ZERO OFFSET FIELD               09950020
         LH    REG4,ZERO(ZERO,REG5)     GET LENGTH OF BUFFER            10000020
         ALR   REG4,REG5                GET POINTER TO LAST BYTE IN     10050020
         BCTR  REG4,ZERO                   BUFFER                       10100020
         CLI   ZERO(REG4),MINUS         IS LAST BYTE A MINUS SIGN       10150020
         BE    GETMORE                  YES, GET REST OF LOGICAL LINE   10200020
         SPACE                                                          10250020
TSTINBUF EQU   *                        MUST INBUF BE FREED             10300020
         OC    INBUF1(L3),INBUF1        MUST INBUF BE FREED             10350020
         BZ    INSERTA                  NO, INSERT NEW BUFFER ADDR      10400020
         L     PARAMREG,INBUF           R1=ADDR OF CORE TO BE FREED     10450020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF CORE TO BE FREED   10500020
         BAL   REG7,FREECORE            FREE THE BUFFER                 10550020
         SPACE                                                          10600020
INSERTA  EQU   *                        KEEP BUFFER ADDR IN INBUF       10650020
         LA    REG5,ZERO(ZERO,REG5)     CLEAR HIGH ORDER BYTE           10700020
         ST    REG5,INBUF               SAVE BUFFER ADDR IN TCOMTAB     10750020
         TM    TSTFLGS4,TSTA  Q.RUNNING FROM TERMINAL                   10760020
         BO    TCLEARQ        YES.DONT FLUSH THE STACK.                 10770020
         MVC   STACKLST(STACKLEN),STACKL MOVE L FORM OF STACK MACRO     10800020
*                                          TO WORK AREA                 10850020
         LA    PARAMREG,PARMS           R1=ADDRESS OF SERVICE PARMS     11050020
         USING STPL,PARAMREG            ADDRESSABILITY TO STPL          11060020
         LM    WORKE,REG4,TSTUPT        GET SERVICE ROUTINE PARAMETERS  11070020
         ST    WORKE,STPLUPT            SAVE POINTER TO UPT             11080020
         ST    WORKO,STPLECT            SAVE POINTER TO ECT             11090020
         ST    REG4,STPLECB             SAVE POINTER TO ECB             11092020
         LA    REG5,STACKLST            R5=ADDR OF LIST FORM OF MACRO   11094020
         ST    REG5,STPLSTPB            SAVE ADDRESS                    11096020
         DROP  PARAMREG                                                 11098020
         STACK DELETE=ALL,MF=(E,(1))    RESET THE STACK TO THE TERMINAL 11100020
TCLEARQ  EQU   *              CLEAR THE INPUT BUFFERS.                  11120020
         TCLEARQ INPUT                  FLUSH THE TERMINAL INPUT        11150020
*                                          QUEUE                        11200020
         TM    TSTFLGS3,TSTHELP         WAS HELP RUNNING                11250020
         BO    STOPHELP       YES. STOP IT                              11300020
         L     REG5,ECBTST              R5=ADDRESS OF TEST'S ECB        11350020
         TM    ZERO(REG5),WAITBIT       IS TEST WAITING                 11400020
WAITBIT  EQU   X'80'                    ECB WAITING                     11450020
         BO    CONTINUE                 YES, PP MODE - SET BREAKPOINT   11500020
         SPACE                                                          11550020
TESTECB  EQU   *                        RUNNING UNDER TEST OR HELP      11600020
         L     PARAMREG,ECBTMPA         GET ADDR OF ATTENTION ECB       11650020
         TM    ZERO(PARAMREG),ATNSET    HAS ATTENTION BEEN SET          11700020
ATNSET   EQU   X'40'                    ATTENTION BIT                   11750020
         BO    CODE0                    YES, RETURN TO SYSTEM           11800020
         L     ZERO,POSTCODE            R0=POST CODE                    11850020
         POST  (PARAMREG),(ZERO)        POST THE ATTENTION ECB          11900020
         B     CODE0                    RETURN TO SYSTEM                11950020
         SPACE                                                          11960020
STOPHELP EQU   *              STOP HELP FROM RUNNING.                   11970020
         STATUS STOP,TCB=TSTHTCB  STOP HELP DEAD.                       11980020
         B     TESTECB        CONTINUE.                                 11990020
         SPACE                                                          12000020
EXMOVE   MVC   ZERO(ZERO,REG6),FOUR(REG5) MOVE INSTRUCTION TO BE        12250020
*                                          EXECUTED                     12300020
MOVELINE MVC   ZERO(ZERO,REG6),ZERO(REG4) MOVE INSTRUCTION              12350020
         SPACE                                                          12400020
CONTINUE EQU   *                        GET OLD PSW FOR RESUME ADDR     12450020
         OC    TSTGO(L4),TSTGO          HAS A BREAKPOINT BEEN SET       12550020
         BNZ   CODE0                    YES, RETURN                     12600020
         STATUS STOP                    STOP ALL SUBTASKS               12650020
         L     WORKE,TPLPTR             R2=ADDRESS OF TPL               12660020
         L     WORKE,TPLCTCB-TPL(WORKE) R2=PTR TO TEST'S DAUGHTER TCB   12670020
         L     WORKO,ZERO(ZERO,WORKE)   GET POINTER TO RB QUEUE         12700020
         SPACE                                                          12750020
TESTRB   EQU   *                        IS RB OK                        12800020
         TM    RBSTAB(WORKO),RBOK       IS RB A PRB OR AN IRB           12850020
         BZ    CHKKEY                   YES, CHECK FOR PROBLEM          12950020
*                                          PROGRAM STATE                13000020
         SPACE                                                          13050020
NEXTRB   EQU   *                        LOOK AT NEXT RB                 13200020
         L     WORKO,RBLINK(ZERO,WORKO) GET ADDR OF NEXT RB             13250020
         B     TESTRB                      CHECK FOR PRB OR IRB         13300020
         SPACE                                                          13350020
CHKKEY   EQU   *                        CHECK RB FOR PROGRAM BIT ON     13400020
*                                          AND KEY ZERO                 13410020
         TM    RBKEY(WORKO),PBIT        IS PROGRAM STATE BIT ON         13420020
         BZ    NEXTRB                   NO, TRY NEXT RB                 13430020
         TM    RBKEY(WORKO),KEYZERO     IS THE KEY ZERO                 13440020
         BZ    NEXTRB                   NO, TRY NEXT RB                 13442020
         MVC   TSTGO(L4),RESADDR(WORKO) MOVE IC TO TSTGO                13450020
         MVC   WTCOUNT(L1),WAITCNT(WORKO) MOVE WAIT COUNT TO TSTGO      13500020
         LR    ZERO,WORKO               R0=POINTER TO PRB               13550020
*                                          PROGRAM TCB                  13600020
         O     ZERO,WAITOFF             INDICATE WAIT BIT TO BE         13650020
*                                          TURNED OFF                   13700020
         SVC   TESTSVC                  TURN OFF WAIT COUNT IF ON       13750020
*                                          IN ACTIVE IRB OR PRB         13800020
         LR    ZERO,WORKO               R0=POINTER TO PRB               13850020
         O     ZERO,ICCHANGE            INDICATE IC TO BE CHANGED       13900020
         LA    PARAMREG,SVCSAV          R1=POINTER TO SVC IN TSTGO      13950020
         SVC   TESTSVC                  CHANGE IC                       14000020
         STATUS START,TCB=(2)           START TEST'S DAUGHTER TASK      14050020
         SPACE                                                          14100020
CODE0    EQU   *                        SET CODE TO 0                   14300020
         XR    RETCODE,RETCODE          SET RETURN CODE TO ZERO         14350020
         SPACE                                                          14400020
RETURN   EQU   *                        RETURN TO CALLER                14450020
         L     SAVEREG,FOUR(ZERO,SAVEREG) RESTORE ADDR OF CALLER'S SAVE 14500020
*                                          AREA                         14550020
         RETURN (14,12),,RC=(15)        RESTORE REGISTERS AND RETURN    14600020
         SPACE                                                          14650020
TESTNULL EQU   *                        THIS CODE IS ENTERED IF THE     14700020
*                                          SCAN ROUTINE FAILED.  IF     14750020
*                                          THE INPUT LINE IS NOT NULL   14800020
*                                          IT IS ASSUMED NOT TO BE A    14850020
*                                          QUESTION MARK EITHER         14900020
         XR    REG6,REG6                CLEAR REGISTER                  14950020
         LA    REG6,FOUR(ZERO,REG6)     PUT A FOUR IN REG               15000020
         CH    REG6,ZERO(ZERO,REG7)     IS LENGTH OF COMMAND ZERO       15050020
         BE    FREEBUF1                 YES, SET CODE TO ZERO AND       15100020
*                                          RETURN                       15150020
         B     CHKLINE                  ASSUME NOT A QUESTION MARK      15200020
         SPACE                                                          15250020
QUESTION EQU   *                        ENTERED IF QUESTION MARK INPUT  15650020
* PUTLINE IS USED TO OUTPUT THE PENDING SECOND LEVEL MESSAGE, IF ANY.   15700020
         SPACE                                                          15750020
         L     PARAMREG,ADDR1           R1=ADDRESS OF BUFFER            15800020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER             15850020
         BAL   REG7,FREECORE            BRANCH TO ISSUE FREEMAIN        15900020
         SPACE                                                          15950020
         BAL   REG11,IOSETUP            SET UP I/O PARAMETERS           16160020
         MVC   PARMBLK(PTLENGTH),PUTIT  MOVE LIST FORM OF PUTLINE TO    16200020
*                                          WORK AREA                    16250020
         PUTLINE OUTPUT=(ZERO),MF=(E,(1))                               16300020
         SPACE                                                          16550020
* WHETHER PUTLINE IS SUCCESSFUL OR NOT THE MODE MESSAGE WILL BE ISSUED  16600020
*AND A REPLY EXPECTED.                                                  16650020
         SPACE                                                          16700020
         BAL   REG11,IOSETUP            SET UP I/O PARAMETERS           16710020
         L     REG11,MSGADDR            GET ADDR OF MESSAGE CSECT       16750020
         LA    REG11,MSG1(ZERO,REG11)   INDEX FOR MODE MESSAGE          16800020
         MVC   PARMBLK(PTLENGTH),PUTIT  MOVE LIST FORM OF PUTLINE TO    16860020
*                                          WORK AREA                    16870020
         SPACE                                                          16900020
* PUT OUT MESSAGE 'TEST'                                                16950020
         SPACE                                                          17000020
         PUTLINE OUTPUT=((REG11)),MF=(E,(1))                            17050020
         LTR   RETCODE,RETCODE          WAS I/O SUCCESSFUL              17100020
         BNZ   CODE0                    SET RETURN CODE TO 0            17150020
         BAL   REG7,GETALINE            BRANCH TO GET INPUT             17200020
         L     REG7,PARMBLK+GTPBIBUF-GTPB R7=ADDR OF GOTTEN CORE        17250020
         ST    REG7,ADDR1               SAVE ADDR IN WORK AREA          17300020
         B     AROUND                   PREPARE TO GO TO SCAN           17350020
         SPACE                                                          17400020
GETMORE  EQU   *                        GET REST OF INPUT LINE          17450020
         BAL   REG7,GETALINE            BRANCH TO GET REST              17500020
*                                           OF INPUT LINE               17550020
         LTR   RETCODE,RETCODE          WAS I/O SUCCESSFUL              17600020
         BNZ   FREE1                    NO, FREE CORE PASSED            17650020
         MVC   ADDR2(L4),PARMBLK+GTPBIBUF-GTPB PUT ADDR OF BUFFER       17700020
*                                          IN SAVE WORD                 17750020
         SPACE                                                          17800020
* THIS SECTION CALCULATES CORE REQUIREMENTS TO CONCATENATE              17850020
* BUFFERS                                                               17900020
         SPACE                                                          17950020
         LH    REG4,ZERO(ZERO,REG5)     GET LENGTH OF BUFFER1           18000020
         L     REG6,ADDR2               ADDRESS OF BUFFER2              18050020
         LH    REG6,ZERO(ZERO,REG6)     PICK UP LENGTH OF NEW BUFFER    18100020
         ALR   REG4,REG6                GET TOTAL LENGTH OF TWO BUFFERS 18150020
         LA    REG6,FIVE                PUT A FIVE IN REG               18200020
         SR    REG4,REG6                SUBTRACT FOUR FOR PREFACE       18250020
*                                          BYTES ON ONE BUFFER          18300020
*                                          AND ONE FOR CONTINUATION     18350020
         MVC   GETCORE(GETLEN),GETL     MOVE LIST FORM TO WORK AREA     18400020
         LA    PARAMREG,GETCORE         R1=ADDR OF LIST FORM            18450020
         GETMAIN EC,LV=(REG4),A=ADDRCORE,SP=1,MF=(E,(1)) GET CORE TO    18500020
         LTR   RETCODE,RETCODE          WAS CORE GOTTEN                 18600020
         BNZ   FREEBUF2                 NO, FREE BUFFERS AND RETURN     18650020
         L     WORKO,ADDRCORE           R3=ADDR OF GOTTEN CORE          18700020
         ST    WORKO,ADDR3              SAVE IN WORK AREA               18750020
         SPACE                                                          18800020
COMBINE  EQU   *                        THIS ROUTINE GETS COMMAND INTO  18850020
*                                          ONE BUFFER                   18900020
         STH   REG4,ZERO(ZERO,WORKO)    PUT LENGTH IN BUFFER            18950020
         XC    TWO(L2,WORKO),TWO(WORKO) SET OFFSET FIELD TO ZERO        19000020
         LA    REG6,FOUR(ZERO,WORKO)    R6=PTR FOR BEGINNING OF LINE    19050020
         LH    REG4,ZERO(ZERO,REG5)     R5=LENGTH OF BUFFER1            19100020
         LA    REG7,SIX                 R7=6                            19150020
         SR    REG4,REG7                DECREMENT 1 FOR MOVE INSTRUCT-  19200020
*                                          ION, 1 FOR MINUS, AND 4 FOR  19250020
*                                          PREFACE BYTES                19300020
         EX    FOUR,EXMOVE              MOVE IN FIRST PART OF LINE      19350020
         L     REG5,ADDR2               R5=ADDR OF CORE GOTTEN BY       19400020
*                                          GETLINE                      19450020
         LA    REG4,ONE(ZERO,REG4)      TOTAL BYTES MOVED               19500020
         ALR   REG6,REG4                R6=ADDR FOR BEGINNING OF PART   19550020
*                                          OF LINE TO BE INSERTED       19600020
         LA    REG7,FIVE                R7=5                            19650020
         LH    REG4,ZERO(ZERO,REG5)     R4=LENGTH OF GETLINE'S CORE     19700020
         SR    REG4,REG7                DECREMENT 1 FOR EXECUTE         19750020
*                                          INSTRUCTION AND 4 FOR        19800020
*                                          PREFACE BYTES                19850020
         EX    REG4,EXMOVE              COMPLETE CONCATENATION          19900020
         L     PARAMREG,ADDR1           R1=ADDR OF BUFFER1              19950020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER             20000020
         BAL   REG7,FREECORE            FREE BUFFER 1                   20050020
         L     PARAMREG,ADDR2           R1=ADDR OF BUFFER 2             20100020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER 2           20150020
         BAL   REG7,FREECORE            FREE BUFFER 2                   20200020
         L     REG5,ADDR3               R5=ADDR OF INPUT BUFFER         20250020
         B     TSTINBUF                 BRANCH TO SEE IF INBUF IS EMPTY 20300020
         SPACE                                                          20350020
GETALINE EQU   *                        GET A LOGICAL INPUT LINE        20400020
         MVC   PARMBLK(GTLENGTH),GETIT  MOVE L FORM OF MACRO TO WORK    20450020
*                                          AREA                         20500020
         BAL   REG11,IOSETUP            SET UP I/O PARAMETERS           20510020
         GETLINE INPUT=(TERM,LOGICAL),TERMGET=(EDIT,WAIT),MF=(E,(1))    20700020
         BR    REG7                     RETURN TO CALLER                20750020
         SPACE                                                          20800020
FREEBUF1 EQU   *                        FREE FIRST BUFFER GOTTEN        20850020
         L     PARAMREG,ADDR1           R1=ADDRESS OF BUFFER            20900020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER             20950020
         BAL   REG7,FREECORE            BRANCH TO ISSUE FREEMAIN        21000020
         B     CODE0                    RETURN WITH CODE OF 0           21050020
         SPACE                                                          21100020
FREEBUF2 EQU   *                        FREE BUFFER 2                   21150020
         L     PARAMREG,ADDR2           R1=ADDR OF BUFFER 2             21200020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER             21250020
         BAL   REG7,FREECORE            FREE BUFFER 2                   21300020
         SPACE                                                          21350020
FREE1    EQU   *                        FREE FIRST BUFFER GOTTEN AND    21400020
*                                          SET RETURN CODE FOR FLUSHING 21450020
*                                          THE INPUT STACKS             21500020
         L     PARAMREG,ADDR1           R1=ADDR OF BUFFER               21550020
         LH    ZERO,ZERO(ZERO,PARAMREG) R0=LENGTH OF BUFFER             21600020
         BAL   REG7,FREECORE            BRANCH TO ISSUE FREEMAIN        21650020
         B     CODE0                    SET RETURN CODE                 21700020
         SPACE                                                          21750020
FREECORE EQU   *                        PROCEDURE FOR FREEMAIN          21800020
         O     ZERO,SUBPOOL1            SET HIGH ORDER BYTE TO INDICATE 21850020
*                                          SUBPOOL 1                    21900020
         FREEMAIN R,LV=(ZERO),A=(PARAMREG)                              21950020
         BR    REG7                     RETURN TO CALLER                22000020
         SPACE                                                          22010020
IOSETUP  EQU   *                        SET UP I/O PARAMETERS           22020020
         LA    PARAMREG,PARMS           R1=ADDRESS OF PARAMETER LIST    22030020
         USING IOPL,PARAMREG            ESTABLISH ADDRESSABILITY TO IT  22040020
         LM    WORKE,REG4,TSTUPT        GET POINTERS TO UPT, ECT, AND   22042020
*                                          AND CP ECB FROM TCOMTAB      22044020
         ST    WORKE,IOPLUPT            SAVE POINTER TO UPT             22046020
         ST    WORKO,IOPLECT            SAVE POINTER TO ECT             22048020
         ST    REG4,IOPLECB             SAVE POINTER TO ECB             22048420
         LA    WORKE,PARMBLK            R2=PTR TO RETURN PARAMETERS     22048820
         ST    WORKE,IOPLIOPB           SAVE POINTER                    22049220
         BR    REG11                    RETURN TO CALLER                22049620
         DROP  PARAMREG                                                 22049720
         SPACE                                                          22050020
GETL     GETMAIN EC,SP=1,MF=L           L FORM OF GETMAIN               22100020
GETLEN   EQU   *-GETL                   LENGTH OF L FORM OF GETMAIN     22150020
PUTIT    PUTLINE ,MF=L                  L FORM OF PUTGET                22200020
PTLENGTH EQU   *-PUTIT                  LENGTH OF LIST FORM OF PUTLINE  22250020
GETIT    GETLINE INPUT=(TERM,LOGICAL),TERMGET=(EDIT,WAIT),MF=L          22300020
GTLENGTH EQU   *-GETIT                  LENGTH OF LIST FORM OF GETLINE  22350020
STACKL   STACK DELETE=ALL,MF=L          RESET THE INPUT STACK           22400020
STACKLEN EQU   *-STACKL                 LENGTH OF MACRO                 22450020
         SPACE                                                          22500020
IKJEGMSA CSECT                          MESSAGE CSECT                   22550020
         SPACE                                                          22600020
         DS    0D                       ALIGNMENT                       22650020
MSG01    DC    X'00000001'              SEGMENT NUMBER 1                22700020
         DC    A(MSGA)                  POINTER TO MESSAGE 1            22750020
         SPACE                                                          22800020
MSGA     DC    AL2(MSGAEND-MSGA)        LENGTH OF MESSAGE               22850020
         DC    AL2(0)                   FILLER                          22900020
         DC    C' TEST'                 TEST MODE MESSAGE               22950020
MSGAEND  EQU   *                                                        23000020
         SPACE                                                          23050020
IKJEGATN CSECT                                                          23100020
CONSTANT EQU   *                        SECTION FOR CONSTANTS           23150020
         DS    0F                       ALIGNMENT                       23200020
MSGADDR  DC    V(IKJEGMSA)              ADDRESS OF MESSAGE CSECT        23300020
SUBPOOL1 DC    X'01000000'              SPECIFIES SUBPOOL 1             23350020
POSTCODE DC    X'08000000'              POST CODE FOR ATTENTION ECB     23400020
WAITOFF  EQU   SUBPOOL1                 TURN OFF WAIT COUNT             23450020
ICCHANGE DC    X'08000000'              CHANGE IC                       23500020
TESTSVC  EQU   97                       TEST'S SVC                      23550020
SCANFLAG DC    X'80000000'              FLAG FOR NO SYNTAX CHECK        23600020
         EJECT                                                          23650020
         TCOMTAB                                                        23700020
INBUF1   EQU   INBUF+1                  SECOND BYTE OF FIELD            23750020
IC       EQU   TSTGO+4                  AREA TO SAVE INSTRUCTION CODE   23800020
TSTWAIT  EQU   TSTGO+6                  AREA TO SAVE PP WAIT COUNT      23850020
         EJECT                                                          23860020
         IKJTPL                                                         23870020
         EJECT                                                          23900020
         IKJECT                         DSECT FOR ECT                   23950020
         EJECT                                                          24000020
         IKJCSPL                                                        24050020
         EJECT                                                          24100020
         IKJCSOA                                                        24150020
         EJECT                                                          24160020
         IKJSTPL                                                        24170020
         EJECT                                                          24200020
         IKJIOPL                                                        24250020
         EJECT                                                          24300020
         IKJPTPB                                                        24350020
         EJECT                                                          24400020
         IKJGTPB                                                        24450020
         EJECT                                                          24500020
WORKSP   DSECT                          ATTENTION'S WORK AREA           24550020
SAVEAREA DS    18F                      SAVE AREA                       24600020
PARMS    DS    6F                       PARAMETERS FOR IKJSCAN          24650020
OUTAREA  DS    2F                       OUTPUT AREA                     24700020
FLGWORD  DS    1F                       FLAG WORD FOR SCAN              24800020
STACKLST STACK DELETE=ALL,MF=L          RESERVED FOR STACK MACRO        24850020
PARMBLK  EQU   STACKLST                 I/O SERVICE RTN PARAMETER BLOCK 24900020
         DS    3F                       PARAMETERS FOR I/O SERVICE      24950020
*                                          ROUTINES                     25000020
GETCORE  GETMAIN EC,SP=1,MF=L           RESERVE SPACE FOR L FORM        25050020
ADDRCORE EQU   GETCORE+4                ADDR OF WHERE CORE ADDR TO BE   25100020
*                                          RETURNED                     25150020
ADDR1    DS    A                        ADDR OF BUFFER 1                25200020
ADDR2    DS    A                        ADDR OF BUFFER 2                25250020
ADDR3    DS    A                        ADDR OF BUFFER 3                25300020
ZEROWORK EQU   SAVEAREA+12              BEGINNING OF AREA TO ZERO       25350020
ZEROLEN  EQU   *-ZEROWORK               ZERO WORK AREA                  25400020
         EJECT                                                          25450020
         IKJTAIE                                                        25500020
*                                          INTERRUPT ELEMENT            25550020
         SPACE                                                          25600020
ATTNPARM DSECT                          DSECT FOR INPUT PARAMETERS      25650020
TAIEPTR  DS    A                        ADDR OF TAIE                    25700020
INPUTADR DS    A                        ADDR OF INPUT BUFFER            25750020
USERINFO DS    A                        USER INFORMATION - ADDRESS      25800020
*                                          OF TCOMTAB                   25850020
         SPACE                                                          25900020
* EQUATES WHICH MUST FOLLOW DSECTS                                      25950020
WTCOUNT  EQU   TSTGO+4                  SECOND WORD OF TSTGO            26000020
SVCSAV   EQU   TSTGO+6                  OFFSET INTO TSTGO FOR SVC       26050020
         EJECT                                                          26060020
* REGISTER EQUATES                                                      26100020
R0       EQU   0              REGISTER 0                                26150020
R1       EQU   1              REGISTER 1                                26200020
R2       EQU   2              REGISTER 2                                26250020
R3       EQU   3              REGISTER 3                                26300020
R4       EQU   4              REGISTER 4                                26350020
R5       EQU   5              REGISTER 5                                26400020
R6       EQU   6              REGISTER 6                                26450020
R7       EQU   7              REGISTER 7                                26500020
R8       EQU   8              REGISTER 8                                26550020
R9       EQU   9              REGISTER 9                                26600020
R10      EQU   10             REGISTER 10                               26650020
R11      EQU   11             REGISTER 11                               26700020
R12      EQU   12             REGISTER 12                               26750020
R13      EQU   13             REGISTER 13                               26800020
R14      EQU   14             REGISTER 14                               26850020
R15      EQU   15             REGISTER 15                               26900020
         SPACE                                                          26950020
* OTHER EQUATES                                                         27000020
REGSYM   EQU   C'R'           GENERAL REGISTER SYMBOL                   27050020
DECSYM   EQU   C'N'           SYMBOL FOR DECIMAL VALUE                  27100020
REGD     EQU   C'D'           SYMBOL FOR DOUBLE PRECISION FLOATING      27110020
*                                POINT REGISTER                         27120020
REGE     EQU   C'E'           SYMBOL FOR SINGLE PRECISION FLOATING      27130020
*                                POINT REGISTER                         27140020
DOUBLE   EQU   X'10'          FLAG FOR DOUBLE PRECISION                 27142020
SINGLE   EQU   X'08'          FLAG FOR SINGLE PRECISION                 27144020
DECVAL   EQU   X'04'          DECIMAL EXPRESSION VALUE                  27150020
PERCENT  EQU   C'%'           PERCENT SIGN                              27200020
EXPFLGS5 EQU   8              OFFSET INTO EXPRESSION PDE FOR FLAGS      27250020
NINE     EQU   9              NUMBER 9                                  27300020
TEN      EQU   10             NUMBER 10                                 27350020
THIRTEEN EQU   13             NUMBER 13                                 27400020
TWENTY8  EQU   28             NUMBER 28                                 27450020
MAXLEN   EQU   100            MAXIMUM LENGTH OF STRING                  27500020
ADDRLEN  EQU   26             MAXIMUM LENGTH OF STRING FOR MSG          27550020
         SPACE                                                          27600020
IKJEGBLD CSECT                THIS CSECT BUILDS AN ADDRESS STRING TO A  27650020
* MAXIMUM LENGTH OF 100 BYTES.  AS INPUT IT REQUIRES A POINTER TO THE   27700020
* ADDRESS PDE IN REGISTER ZERO AND A POINTER IN REGISTER ONE TO THE     27750020
* AREA IN WHICH THE STRING IS TO BE BUILT.  AT EXIT REGISTER ZERO WILL  27800020
* CONTAIN THE NUMBER OF BYTES CONSTRUCTED AND REGISTER ONE WILL CONTAIN 27850020
* A POINTER TO THE BYTE FOLLOWING THE LAST ONE IN THE ADDRESS STRING.   27900020
* IF ON INPUT REGISTER 1 IS NEGATIVE IT WILL BE KNOWN THAT THE MAXIMUM  27950020
* LENGTH ALLOWED FOR THE STRING IS 26 BYTES                             28000020
         SPACE                                                          28050020
         SAVE  (14,12),,IKJEGBLD SAVE CALLER'S REGISTERS                28100020
         LR    R12,R15        ESTABLISH ADDRESSABILITY FOR THIS         28150020
         USING IKJEGBLD,R12      CSECT                                  28200020
         LR    R10,R0         R10=POINTER TO ADDRESS PDE                28250020
         USING IKJPARMA,R10   ESTABLISH PDE ADDRESSABILITY              28300020
         LTR   R1,R1          IS THE MAXIMUM STRING LENGTH 26 BYTES     28350020
         BNM   RESET          NO, SET MAXIMUM TO 100            SA55218 28400021
         LCR   R1,R1          LOAD COMPLEMENT OF REGISTER ONE   SA55218 28410021
         LA    R9,ADDRLEN     SET MAXIMUM TO 26                         28450020
CLEAR    EQU   *              CLEAR ACCUMULATOR                         28500020
         SR    R4,R4          CLEAR BYTE ACCUMULATOR                    28550020
         TM    PDEFLG1,LDNAMFLG Q.IS LOAD NAME SPECIFIED.               28600020
         BO    LOADYES        YES, PICK UP EVERYTHING.                  28650020
         TM    PDEFLG2,CTNAMFLG Q.IS ENTRYNAME PRESENT.                 28700020
         BO    CSECTYES       YES, PICK UP ENTRY-ADDRESS.               28750020
         B     ADDRONLY       NO, PICK UP ADDR ONLY.                    28800020
         SPACE                                                          28850020
RESET    EQU   *              SET MAXIMUM LENGTH TO 100                 28900020
         LA    R9,MAXLEN      SET MAXIMUM TO 100                        29000020
         B     CLEAR          BEGIN BUILDING ADDRESS STRING             29050020
LOADYES  EQU   *              LOADNAME GIVEN                            29100020
         L     R7,PDELDNAM    R7=ADDR OF LOAD NAME.                     29150020
         LH    R6,PDELEN1     R6=LOAD NAME LENGTH.                      29200020
         BAL   R11,ADMOVE     MOVE LOAD NAME AND BUMP ACCUMULATORS.     29250020
         SPACE                                                          29300020
CSECTYES EQU   *              CSECTNAME GIVEN                           29350020
         L     R7,PDECTNAM    R7=ADDR OF CSECT NAME.                    29400020
         LH    R6,PDELEN2     R6=CSECT NAME LENGTH.                     29450020
         BCTR  R7,ZERO        PICK UP PRECEDING PERIOD.                 29500020
         LA    R6,ONE(R6)     *                                         29550020
         TM    PDEFLG3,AFLG   Q.ANY ADDRESS.                            29600020
         BZ    MOVE           NO, MOVE CSECT NAME.                      29650020
         LA    R6,ONE(R6)     YES, PICK UP TRAILING PERIOD.             29700020
         SPACE                                                          29750020
MOVE     EQU   *              SAVE CSECT NAME                           29800020
         BAL   R11,ADMOVE     MOVE CSECT NAME & ETC.                    29850020
         SPACE                                                          29900020
ADDRONLY EQU   *              CHECK FOR ADDRESS STRING                  29950020
         TM    PDEFLG3,AFLG   Q.ANY ADDR.                               30000020
         BZ    GOBACK         NO, RETURN TO CALLER                      30050020
         L     R7,PDEADRPT    R7=ADDR OF ADDRESS.                       30100020
         LA    R5,PDEADRPT    R5=ADDR OF POINTER TO ADDRESS             30150020
         LH    R6,PDELEN3     R6=ADDRESS STRING LENGTH.                 30200020
         TM    PDEFLG4,ABSCOMPL Q.IS IT ABSOLUTE                        30250020
         BM    RELCHK         NO, CHECK FOR RELATIVE.                   30300020
         B     BUMP           YES, PICK UP PERIOD.                      30350020
         SPACE                                                          30400020
RELCHK   EQU   *              TEST FOR RELATIVE ADDRESS                 30450020
         TM    PDEFLG4,RELADDR Q.IS IT A RELATIVE.                      30500020
         BZ    NEITHER        NO, MOVE STRING.                          30550020
         BCTR  R7,ZERO        YES, PICK UP PLUS SIGN.                   30600020
         SPACE                                                          30650020
BUMP     EQU   *              INCREMENT LENGTH COUNTER                  30700020
         LA    R6,ONE(R6)     BUMP FOR PUNCTUATION.                     30750020
         SPACE                                                          30800020
NEITHER  EQU   *              ADDR IS NEITHER ABSOLUTE NOR RELATIVE     30850020
         BAL   R11,ADMOVE     MOVE ADDRESS STRING & ETC.                30900020
         TM    PDEFLG4,GENR   IS ADDRESS GENERAL REGISTER TYPE          30950020
         BZ    TRYD           NO, TRY FLOATING POINT REGISTER           31000020
         MVI   ZERO(R1),REGSYM MOVE IN REGISTER SYMBOL                  31050020
         SPACE                                                          31060020
BUMPIT   EQU   *              BUMP POINTER AND ACCUMULATOR              31070020
         LA    R1,ONE(R1)     BUMP THE SAVE AREA POINTER                31100020
         LA    R4,ONE(R4)     BUMP THE ACCUMULATOR                      31150020
         SPACE                                                          31200020
GOIND    EQU   *              HANDLE PERCENT SIGNS                      31250020
         BAL   R11,INDIRECT   WHISTLE THROUGH PERCENT SIGNS.            31300020
         SPACE                                                          31350020
ADDRLOOP EQU   *              HANDLE ADDRESS EXPRESSION                 31400020
         OC    THIRTEEN(L3,R5),THIRTEEN(R5) IS THERE AN                 31450020
*                                EXPRESSION PDE                         31500020
         BZ    GOBACK         NO, RETURN TO CALLER                      31550020
         MVC   ZERO(L1,R1),NINE(R5) MOVE SIGN                           31600020
         L     R5,TWELVE(R5)  R5=ADDR OF NEXT EXPRESSION PDE            31650020
         L     R7,ZERO(R5)    R7=ADDR OF EXPRESSION STRING.             31700020
         LH    R6,FOUR(R5)    R6=EXPRESSION LENGTH.                     31750020
         LA    R1,ONE(R1)     BUMP SAVE POINTER.                        31800020
         LA    R4,ONE(R4)     BUMP THE ACCUMULATOR.                     31850020
         BAL   R11,ADMOVE     MOVE EXPRESSION.                          31900020
         TM    EXPFLGS5(R5),DECVAL IS VALUE DECIMAL                     31950020
         BZ    TRYIND         NO, CHECK FOR PERCENT SIGNS               32000020
         MVI   ZERO(R1),DECSYM MOVE IN SYMBOL FOR DECIMAL               32050020
         LA    R1,ONE(R1)     BUMP SAVE POINTER                         32100020
         LA    R4,ONE(R4)     BUMP THE ACCUMULATOR                      32150020
         SPACE                                                          32200020
TRYIND   EQU   *              HANDLE PERCENT SIGNS                      32250020
         BAL   R11,INDIRECT   ZING THROUGH PERCENT SIGNS.               32300020
         B     ADDRLOOP       CHECK FOR MORE EXPRESSIONS.               32350020
         SPACE                                                          32400020
ADMOVE   EQU   *              SAVE PORTION OF ADDRESS                   32450020
         LR    R8,R4          R8=TOTAL LENGTH SO FAR                    32500020
         AR    R8,R6          R8=POSSIBLE LENGTH                        32550020
         CR    R8,R9          WILL LENGTH BE TOO GREAT                  32600020
         BH    DECR           YES, DECREMENT COUNT FOR MOVE             32650020
         AR    R4,R6          BUMP THE ACCUMULATOR.                     32700020
         LTR   R6,R6          IF REG SIX ZERO, DONT DECREMENT   SA55218 32710021
         BZ    GOBACK         LET'S GET OUT OF HERE             SA55218 32720021
         BCTR  R6,ZERO        DECREMENT R6 FOR EXECUTE.                 32750020
         EX    R6,STRMVC      MOVE THE STRING.                          32800020
         LA    R1,ONE(R6,R1)  BUMP THE SAVE AREA POINTER.               32850020
         CR    R8,R9          IS LENGTH EQUAL TO MAXIMUM                32900020
         BE    GOBACK         YES, RETURN TO CALLER                     32950020
         BR    R11            NO, KEEP GOING                            33000020
         SPACE                                                          33050020
STRMVC   MVC   ZERO(ONE,R1),ZERO(R7) MOVE STRING EXECUTED MVC.          33100020
         SPACE                                                          33150020
INDIRECT EQU   *              CHECK FOR INDIRECT ADDRESS                33200020
         LH    R14,TEN(R5)    R14=INDIRECT COUNT.                       33250020
         LTR   R14,R14        Q.ANY COUNT SPECIFIED.                    33300020
         BCR   EIGHT,R11      NO, RETURN TO CALLER.                     33350020
         SPACE                                                          33400020
PCLOOP   EQU   *              SAVE PERCENT SIGN                         33450020
         LR    R8,R4          R8=ACCUMULATED LENGTH COUNT               33500020
         LA    R8,ONE(R8)     BUMP TEST ACCUMULATOR                     33550020
         CR    R8,R9          IS COUNT GREATER THAN MAXIMUM             33600020
         BH    GOBACK         YES, RETURN TO CALLER                     33650020
         MVI   ZERO(R1),PERCENT MOVE IN A PERCENT SIGN.                 33700020
         SPACE                                                          33750020
         LA    R1,ONE(R1)     BUMP SAVE AREA POINTER.                   33800020
         LA    R4,ONE(R4)     BUMP ACCUMULATOR.                         33850020
         BCT   R14,PCLOOP     MOVE 'EM ALL.                             33900020
         CR    R8,R9          IS COUNT EQUAL TO MAXIMUM                 33950020
         BE    GOBACK         YES, ALL THROUGH                          34000020
         BR    R11            NO, KEEP GOING                            34050020
         SPACE                                                          34100020
DECR     EQU   *              DECREMENT COUNT FOR MOVE                  34150020
         BCTR  R6,ZERO        SUBTRACT ONE                              34200020
         B     ADMOVE         TRY AGAIN                                 34250020
         SPACE                                                          34300020
GOBACK   EQU   *              STRING IS BUILT                           34350020
         LR    R0,R4          R0=TOTAL LENGTH OF STRING BUILT           34400020
         LM    R14,R15,TWELVE(R13) RESTORE R14-R15                      34450020
         LM    R2,R12,TWENTY8(R13) RESTORE R2-R12                       34500020
         BR    R14            RETURN TO CALLER                          34550020
         SPACE                                                          34560020
TRYD     EQU   *              IS ADDRESS DOUBLE PRECISION FLOATING      34570020
*                                POINT REGISTER                         34580020
         TM    PDEFLG4,DOUBLE IS FLAG ON                                34590020
         BZ    TRYE           NO, TRY SINGLE PRECISION                  34592020
         MVI   ZERO(R1),REGD  MOVE IN REGISTER SYMBOL                   34594020
         B     BUMPIT         BRANCH TO BUMP COUNTER                    34596020
         SPACE                                                          34600020
TRYE     EQU   *              IS ADDRESS SINGLE PRECISION FLOATING      34610020
*                                POINT REGISTER                         34620020
         TM    PDEFLG4,SINGLE IS FLAG ON                                34630020
         BZ    GOIND          NO, CHECK FOR PERCENT SIGNS               34640020
         MVI   ZERO(R1),REGE  MOVE IN REGISTER SYMBOL                   34642020
         B     BUMPIT         BRANCH TO BUMP COUNTER                    34644020
         SPACE                                                          34646020
         SPACE                                                          34700020
         TSTCWORK             DSECT FOR WORK AREA                       34750020
         SPACE                                                          34800020
         IKJPARMA             DSECT FOR ADDRESS PDE                     34850020
         END                                                            34900020
