         TITLE 'IKJEGCVT, THE CONVERSION ROUTINE OF TEST'               00030020
*RELEASE 21.6 CHANGES                                                   00032021
*A530700-530760                                                  A49893 00034021
*D530800                                                         A49893 00036021
*A129700                                                        SA55218 00038021
*C127300,127600,131800                                          SA55218 00038421
*D126800                                                        SA55218 00038821
*A497920,497940,498100                                          SA60586 00039221
*****************************  PROLOGUE  ****************************** 00040020
* STATUS  CHANGE LEVEL  001                                           * 00080021
*                                                                     * 00140020
* FUNCTION                                                            * 00160020
*    THIS MODULE IS A UTILITY PROGRAM USED BY THE 'TEST' PACKAGE      * 00200020
*    OF THE TIME SHARING OPTION (TSO) FOR OS/360 MVT.  IT IS          * 00220020
*    CALLED BY VARIOUS TEST ROUTINES TO PERFORM DATA TRANSLATION      * 00240020
*    TO/FROM BINARY FROM/TO A PRINTABLE FORMAT.  THIS ROUTINE IS      * 00260020
*    ABLE TO CONVERT TO BINARY FROM THE FOLLOWING PRINTABLE FOR-      * 00280020
*    MATS- A, B, D, E, F, H, P, S, X, AND Y.  IN ADDITION, IT IS      * 00300020
*    ABLE TO CONVERT FROM BINARY TO THE FOLLOWING PRINTABLE FOR-      * 00320020
*    MATS- A, D, E, F, H, I, P, S, X, AND Y.                          * 00340020
*                                                                     * 00360020
* ENTRY POINTS                                                        * 00380020
*                                                                     * 00400020
*    IKJEGCVT-ENTRY POINT FOR ADDRESS AND VALUE CONVERSIONS.          * 00420020
*                                                                     * 00440020
*    IKJEGCOP-ENTRY POINT FOR THE OPCODE TABLE.                       * 00450020
*                                                                     * 00452020
* INPUT                                                               * 00460020
*    GENERAL PURPOSE REGISTER ZERO                                    * 00500020
*         IF NEGATIVE, INDICATES CONVERSION TO PRINTABLE FORMAT.      * 00520020
*         IF POSITIVE, INDICATES CONVERSION TO BINARY FORMAT.         * 00540020
*    GENERAL PURPOSE REGISTER ONE POINTS TO A PARSE-LIKE PARAME-      * 00580020
*    TER DESCRIPTOR LIST (PDL) CONTAINING AN ADDRESS OR A VALUE       * 00600020
*    PARSE-LIKE DESCRIPTOR ENTRY (PDE)                                * 00620020
*         IF NEGATIVE, INDICATES AN ADDRESS CONVERSION.               * 00640020
*         IF POSITIVE, INDICATES A VALUE CONVERSION.                  * 00660020
*                                                                     * 00680020
* OUTPUT                                                              * 00700020
*    FOR ADDRESS CONVERSION                                           * 00740020
*         1).  BINARY TO PRINTABLE CONVERSION OUTPUT IS RETURNED      * 00760020
*              IN CONAREA.                                            * 00780020
*         2).  PRINTABLE TO BINARY CONVERSION OUTPUT IS RETURNED      * 00800020
*              IN THE USER WORD OF THE ADDRESS PDE.                   * 00840020
*    FOR VALUE CONVERSION                                             * 00880020
*         THIS ROUTINE PLACES IN A SECTION OF CORE, POINTED TO        * 00900020
*         TO BY 'CONAREA' IN THE TEST COMMUNICATION TABLE (TCOMTAB)   * 00920020
*         THE FOLLOWING                                               * 00940020
*         1).  LENGTH OF CONVERTED OUTPUT.  (FIRST BYTE).             * 00980020
*         2).  ACTUAL CONVERTED OUTPUT.  (REMAINING BYTES).           * 01000020
*                                                                     * 01020020
* EXTERNAL REFERENCES                                                 * 01040020
*                                                                     * 01060020
*    IKJEGSYM - THE CONVERT ROUTINE CALLS UPON IKJEGSYM TO PER-       * 01080020
*               FORM RESOLUTION FOR ALL SYMBOLIC ADDRESSES AS         * 01100020
*               WELL AS FOR THE SYMBOLIC PART OF ADDRESS EXPRES-      * 01120020
*               SIONS.  IT EXPECTS IKJEGSYM TO SET THE FIRST BYTE     * 01140020
*               OF THE USER WORD OF THE ADDRESS PDE TO X'80' AND      * 01160020
*               TO SET THE REMAINING THREE BYTES TO POINT TO A        * 01180020
*               SYMBOL INFORMATION BLOCK (SYMINFO) WHOSE FIRST        * 01200020
*               WORD CONTAINS THE BINARY REPRESENTATION OF THE        * 01220020
*               ADDRESS.                                              * 01240020
*                                                                     * 01260020
*    IKJEGIO  - I/O IS CALLED TO WRITE DIAGNOSTIC MESSAGES. REGISTER  * 01270020
*               1 (A NEGATIVE POINTER) WILL POINT TO A TWO WORD       * 01272020
*               PARAMETER LIST.  THE FIRST WORD WILL BE A POINTER     * 01274020
*               TO THE FIRST LEVEL MESSAGE.  THE SECOND WORD WILL     * 01276020
*               BE A POINTER TO THE SECOND LEVEL MESSAGE OR ZERO      * 01278020
*               IF NO SECOND LEVEL MESSAGE EXISTS.                    * 01278420
*                                                                     * 01278820
*    IKJEGBLD - BLD IS CALLED TO ATTACH THE INVALID ADDRESS TO        * 01279220
*               THE FIRST LEVEL MESSAGE.  REGISTER 1 WILL POINT TO    * 01279620
*               TO THE AREA TO BUILD THE ADDRESS STRING.  REGISTER    * 01279720
*               0 WILL POINT TO THE ADDRESS PDE.                      * 01279820
*                                                                     * 01279920
* EXITS,NORMAL                                                        * 01280020
*    RETURN VIA GENERAL PURPOSE REGISTER FOURTEEN.                    * 01320020
*    RETURN CODE ZERO IN GENERAL PURPOSE REGISTER FIFTEEN.            * 01340020
*                                                                     * 01380020
* EXIT,ERROR                                                          * 01400020
*    RETURN VIA GENERAL PURPOSE REGISTER FOURTEEN.                    * 01420020
*    RETURN CODE FOUR (4) - UNABLE TO CONVERT VALUE.                  * 01440020
*    RETURN CODE SIXTEEN (16) - ATTENTION IN EFFECT.                  * 01460020
*                                                                     * 01480020
* TABLES/WORKAREAS                                                    * 01490020
* ATTRIBUTES                                                          * 01500020
*    REENTRANT, REFRESHABLE                                           * 01520020
*                                                                     * 01580020
* NOTES                                                               * 01600020
*                                                                     * 01620020
*********************************************************************** 01640020
         TITLE 'IKJEGCVT ADDRESS AND VALUE ROUTING ROUTINE.'            01660020
IKJEGCVT CSECT                                                          01680020
*RELEASE 21 CHANGES                                              A43355 01690021
*A476601-476604                                                  A43355 01692021
*C476600                                                         A43355 01694021
*A453700                                                         A43371 01696021
*C091438                                                         A46765 01698021
         ENTRY IKJEGBLO                                                 01700020
         ENTRY IKJEGBL1                                                 01710020
CVTBEGIN SAVE  (14,12),,*                                               01720020
         LR    R12,R15                 R12=ADDR OF BEGINNING OF CSECT.  01740020
         USING CVTBEGIN,R12            CSECT ADDRESSABILITY.            01760020
         USING TCOMTAB,R9              TCOMTAB ADDRESSABILITY.          01780020
         L     R15,REGSAVE4            R15=ADDR OF MODULE SAVE AREA.    01800020
         ST    R13,FOUR(R15)           SAVE ADDR OF CALLER SAVE AREA.   01820020
         ST    R15,EIGHT(R13)          ADDR IN CALLER SAVE AREA.        01840020
         LR    R13,R15                 R13=ADDR OF MODULE SAVE AREA.    01860020
         SPACE                                                          01880020
*********************************************************************** 01900020
*                                                                     * 01920020
*        THE FOLLOWING INSTRUCTIONS ROUTE CONTROL TO THE PROPER       * 01940020
*        CONVERSION AREA, ADDRESS OR EXPRESSION VALUE.                * 01960020
*                                                                     * 01980020
*********************************************************************** 02000020
         SPACE                                                          02020020
         LTR   R1,R1                   Q.AN ADDRESS CONVERSION.         02040020
         BP    VALCVT                  R1 IS POSITIVE, VALUE CONVERSION 02060020
         SPACE                                                          02080020
*********************************************************************** 02100020
* THE FOLLOWING INSTRUCTIONS DETERMINE IF THE ADDRESS CONVERSION IS   * 02120020
* TO BE TO OR FROM BINARY.                                            * 02140020
*********************************************************************** 02160020
         SPACE                                                          02180020
         L     R3,WORKAREA             R3=ADDRESS OF WORKAREA.          02190020
         LCR   R1,R1                   R1=ADDRESS POSITIVE.             02200020
         LR    R8,R1                   R8=ADDRESS OF PDE.               02210020
         USING IKJPARMA,R8             PDE ADDRESSABILITY.              02212020
         LTR   R0,R0                   Q.CONVERSION TO BINARY.          02220020
         BM    FROMBIN                 RO IS NEG CVT FROM BINARY.       02240020
         TITLE 'IKJEGCVT ADDRESS VALIDITY CHECKING ROUTINE.'            02260020
TOBIN    EQU   *                                                        02280020
         SPACE                                                          02300020
*********************************************************************** 02320020
*                                                                     * 02340020
*        THE FOLLOWING INSTRUCTIONS CONVERTS AN ADDRESS FROM          * 02360020
*        PRINTABLE CHARACTERS TO IT BINARY FORMAT.                    * 02380020
*                                                                     * 02400020
*********************************************************************** 02420020
         SPACE                                                          02500020
* THE TEST UNDER MASK ROUTES CONTROL TO THE PROPER CONVERSION CODE.   * 02520020
         SPACE                                                          02540020
         TM    PDEFLG4,ABSCOMPL        Q.IS ADDR ABSOLUTE.              02560020
         BZ    NOENTRY                 YES,CONVERT AN ABSOLUTE ADDR.    02580020
         TM    PDEFLG4,SYMADDR         Q.IS ADDR SYMBOLIC.              02600020
         BO    SYMFOUND                YES,CONVERT A SYMBOLIC ADDR.     02620020
         TM    PDEFLG4,RELADDR         Q.IS ADDR A RELATIVE.            02640020
         BO    RELFOUND                YES,CONVERT A RELATIVE ADDR.     02660020
         TM    PDEFLG4,CTONLY          Q.ONLY ENTRYNAME SPECIFIED.      02680020
         BO    ENTNAME                 YES,GET ADDR OF ENTRYNAME.       02700020
         SPACE                                                          02720020
*********************************************************************** 02740020
* THIS SECTION OF CODE CONVERTS REGISTERS FROM ITS PRINTABLE FORMAT   * 02760020
* TO ITS BINARY FORMAT.  IF THE REGISTER IS A GENERAL PURPOSE         * 02780020
* REGISTER AND IS INDIRECTED, THE VALUE POINTED TO BY THE INDIRECT    * 02800020
* WILL BE CONVERTED TO BINARY AND RETURNED IN THE USERWORD.           * 02820020
*********************************************************************** 02840020
         SPACE                                                          02860020
REGFOUND EQU   *                                                        02880020
         LH    R4,PDELEN3              R4=LENGTH OF INPUT.              02900020
         LA    R5,PKLEN                R5=LENGTH OF PACKED DATA.        02920020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH.               02940020
         OR    R4,R5                   R4=L1 & L2.                      02960020
         L     R2,PDEADRPT             R2=ADDR OF INPUT.                02980020
         EX    R4,REGPK                REG NOW PACKED DATA.             03000020
         CVB   R4,ZERO(R3)             R4=BINARY VALUE OF REG.          03020020
         ST    R4,ZERO(R3)             BINARY NOW IN WORKAREA.          03040020
         SPACE                                                          03060020
* CHECK  TO DETERMINE IF INDIRECT ADDRESSING HAS BEEN SPECIFIED.      * 03080020
         SPACE                                                          03100020
         LH    R7,PDEINDCT             R7=INDIRECT VALUE.               03120020
         CH    R7,ZEROS                Q.IS INDIRECT SPECIFIED.         03140020
         BE    EXPVAL                  NO,CHECK FOR MORE EXP VALUES.    03160020
         SPACE                                                          03180020
*********************************************************************** 03200020
* THE FOLLOWING INSTRUCTIONS LOCATES THE REGISTER SPECIFIED IN THE    * 03220020
* PROBLEM PROGRAM TCB TO GET THE CONTENT OF THE REGISTER.             * 03240020
*********************************************************************** 03260020
         SPACE                                                          03280020
         L     R5,PPTCB                R5=ADDR OF PPTCB.                03300020
         SR    R6,R6                   R6=0.                            03320020
         IC    R6,THREE(R3)            R6=REGISTER NUMBER IN BINARY.    03340020
         SLL   R6,TWO                  R6=REGISTER OFFSET VALUE.        03360020
         L     R5,ZERO(R5)             R5=ADDR OF SVRB.                 03380020
         L     R5,TCBGRS(R6,R5)        R5=CONTENT OF REGISTER IN PPTCB. 03400020
         LA    R5,ZERO(R5)             CLEAR HIGH ORDER BYTE.           03420020
         ST    R5,ZERO(R3)             CONTENT OF REG NOW IN WORKAREA.  03440020
         BCT   R7,NEXTADDR             GET NEXT ADDR.                   03460020
         B     EXPVAL                  CHECK FOR INDIRECTING.           03480020
REGPK    PACK  ZERO(ONE,R3),ZERO(ONE,R2) INPUT NOW PACKED DECIMAL.      03500020
         SPACE                                                          03520020
*********************************************************************** 03540020
* THIS SECTION OF CODE CONVERTS A RELATIVE ADDRESS FROM ITS PRINT-    * 03560020
* ABLE FORMAT TO ITS BINARY FORMAT.  TO GET THE REQUIRED ADDRESS      * 03580020
* THE BINARY VALUE OF THE RELATIVE IS ADDED TO PPLOAD IF AN ENTRYNAME * 03600020
* WAS NOT SPECIFIED.  IF AN ENTRYNAME IS SPECIFIED CONTROL IS PASSED  * 03620020
* TO SYM TO RESOLVE THE ABSOLUTE ADDRESS OF THE ENTRYNAME.  THE       * 03640020
* RELATIVE VALUE IS THEN ADDED TO THE ABSOLUTE ADDRESS.               * 03660020
*********************************************************************** 03680020
         SPACE                                                          03700020
RELFOUND EQU   *                                                        03720020
         TM    PDEFLG2,CTNAMFLG        Q.ENTRYNAME SPECIFIED.           03760020
         BNO   NOENTRY                 NO,SKIP LINK TO SYM.             03780020
         NI    PDEFLG3,(HEXFF-AFLG)    TURN OFF PARAMETER SWITCH.       03800020
         BAL   R10,SYMLINK             GO CALL IKJEGSYM.                03820020
         OI    PDEFLG3,AFLG            TURN PARAMETER SWITCH ON.        03840020
         LTR   R15,R15                 Q.ENTRYNAME FOUND.               03860020
         BNZ   RETURN                  RETURN TO CALLER.                03880020
         NI    PDEFLG3,(HEXFF-AFLG)    TURN OFF PARAMETER SWITCH.       03900020
NOENTRY  EQU   *                                                        03920020
         SPACE                                                          03940020
*********************************************************************** 03960020
* THIS AREA OF CODE CONVERTS RELATIVE AND ABSOLUTE INPUT CHARACTERS   * 03980020
* TO BINARY VIA THE HEXBIN VALUE CONVERSION ROUTINE.                  * 04000020
*********************************************************************** 04020020
         SPACE                                                          04040020
         LA    R1,PDEADRPT             R1=ADDR OF VALUE TYPE PDE.       04050020
         BAL   R14,HEXBIN              LINK TO HEX TO BINARY ROUTINE.   04080020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           04120020
         SR    R4,R4                   R4=0.                            04160020
         IC    R4,ZERO(R2)             R4=LENGTH OF RELATIVE.           04180020
         LA    R2,ONE(R2)              R2=OUTPUT STRING ADDRESS.        04200020
         L     R2,ZERO(R2)             R2=OUTPUT STRING.                04220020
         LA    R5,FOUR                 R5=4.                            04240020
         SR    R5,R4                   R5=NUMBER OF NONE VALID DIGITS.  04260020
         SLL   R5,THREE                R5=NUMBER OF BITS TO SHIFT.      04280020
         SRL   R2,ZERO(R5)             RELATIVE NOW RIGHT JUSTIFIED.    04300020
         ST    R2,ZERO(R3)             RELATIVE NOW IN WORKAREA.        04320020
         TM    PDEFLG4,ABSCOMPL        Q.ABSOLUTE SPECIFIED.            04340020
         BZ    INDIRECK                YES,CHECK FOR INDIRECKS.         04360020
         TM    PDEFLG3,AFLG            Q.ABSOLUTE ADDRESS IN USERWORD.  04380020
         BO    INFOSKIP                NO,GET PPLOAD.                   04400020
         LA    R7,PDEUSER              R7=QUALIFIED BASE ADDRESS.       04420020
         OI    PDEFLG3,AFLG            TURN PARAMETER SWITCH ON.        04440020
         B     PPSKIP                  SKIP PPLOAD CODE.                04460020
INFOSKIP EQU   *                                                        04480020
         LA    R7,PPLOAD               R7=ADDR OF CURRENT BASE FOR REL. 04500020
PPSKIP   EQU   *                                                        04520020
         MVC   FOUR(FOUR,R3),ZERO(R7)  MOVE CURRENT BASE INTO WORKAREA. 04540020
         L     R7,FOUR(R3)             R7=CURRENT BASE FOR RELATIVE.    04560020
         AL    R7,ZERO(R3)             R7=ABSOLUTE ADDRESS IN BINARY.   04580020
         ST    R7,ZERO(R3)             MOVE ABSOLTE ADDRESS TO WORKAREA 04600020
         SPACE                                                          04640020
*********************************************************************** 04840020
* THE FOLLOWING CODE WILL DETERMINE IF INDIRECTING WAS SPECIFIED. IF  * 04860020
* INDIRECTING IS SPECIFIED THE VALUE POINTED TO BY THE INDIRECT WILL  * 04880020
* BE PROCESSED.                                                       * 04900020
*********************************************************************** 04920020
         SPACE                                                          04940020
INDIRECK EQU   *                                                        04960020
         LH    R7,PDEINDCT             R7=INDIRECT COUNT.               04980020
         LTR   R7,R7                   Q.IS INDIRECTING REQUESTED.      05000020
         BZ    EXPVAL                  NO,CHECK FOR EXPRESSION VALUES.  05020020
         NI    PDEFLG5,HEXFF-PURESYM   TURN OFF SYMINFO SWITCH.         05040020
NEXTADDR EQU   *                                                        05080020
         CLC   TSTTOP(FOUR),ZERO(R3)   Q.ADDRESS IN STORAGE RANGE.      05100020
         BL    OUTCORE                 NO,PUT OUT ERROR MSG.            05120020
         L     R6,ZERO(R3)             R6=ADDR OF NEXT VALUE.           05140020
         MVC   ZERO(FOUR,R3),ZERO(R6)  NEW VALUE NOW IN WORKAREA.       05160020
         MVI   ZERO(R3),ZERO           CLEAR HIGH ORDER BYTE.           05180020
         BCT   R7,NEXTADDR             DECREMENT INDIRECT COUNT.        05200020
         SPACE                                                          05220020
*********************************************************************** 05240020
* THE FOLLOWING INSTRUCTIONS CHECK FOR AN ADDRESS EXPRESSION VALUE.   * 05260020
* IF AN ADDRESS EXPRESSION IS INDICATED IT IS CONVERTED TO BINARY AND * 05280020
* ADDED TO THE ADDRESS ALREADY CALCULATED.                            * 05300020
*********************************************************************** 05320020
         SPACE                                                          05340020
EXPVAL   EQU   *                                                        05360020
         CLI   PDEEXPTR,EXP            Q.EXPRESSION SPECIFIED.          05380020
         BE    SKIPEXP                 NO,SKIP CODE TO TURN OFF SWITCH. 05400020
         NI    PDEFLG5,HEXFF-PURESYM   TURN OFF SYMINFO SWITCH.         05420020
SKIPEXP  EQU   *                                                        05440020
         L     R1,PDEEXPTR             R1=PT TO EXPRESSION PDE          05480020
         MVC   WORK4(ONE,R3),PDESIGN   SAVE EXPRESSION SIGN.            05520020
MOREVAL  EQU   *                                                        05580020
         LTR   R1,R1                   Q.MORE ADDRESS EXPRESSIONS.      05600020
         BM    CORECK                  NO,CHECK MAXIMUM CORE SIZE.      05620020
         SPACE                                                          05640020
*********************************************************************** 05660020
* THE FOLLOWING INSTRUCTION DETERMINE IF THE VALUE IS HEX OR DECML.   * 05680020
*********************************************************************** 05700020
         SPACE                                                          05720020
HEXCK    EQU   *                                                        05740020
         TM    EIGHT(R1),HEX           Q.IS THE VALUE A HEX VALUE.      05760020
         BO    HEXVAL                  YES,CONVERT THE VALUE TO BINARY. 05780020
         SPACE                                                          05800020
* THIS AREA OF CODE CONVERTS A DECML VALUE TO BINARY BY A LINK TO     * 05820020
* FIXBIN(DECIMAL TO BINARY) ROUTINE.                                  * 05840020
         SPACE                                                          05860020
         SR    R5,R5                   R5=0,FOR FIXBIN ROUTINE.         05880020
         L     R0,ZERO(R3)             R0=ADDRESS.                      05900020
         BAL   R14,FAQVBIN             LINK TO FIXBIN CONVERT ROUTINE.  05920020
         SPACE                                                          05960020
*********************************************************************** 05980020
* THE FOLLOWING CODE ALTERS THE BINARY ADDRESS ALREADY COMPUTED WITH  * 06000020
* THE RESULTS OF THE BINARY VALUE RETURNED FROM THE CONVERSION        * 06020020
* ROUTINE.                                                            * 06040020
*********************************************************************** 06060020
         SPACE                                                          06080020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              06120020
         LA    R2,ONE(R2)              R2=PT TO OUTPUT FROM FAQVBIN.    06140020
         L     R4,ZERO(R2)             R4=VALUE RETURNED BY FAQVBIN.    06160020
TESTSIGN EQU   *                                                        06180020
         CLI   WORK4(R3),EXPPLUS       Q.EXPRESSION VALUE SIGN POSITIVE 06190020
         BE    PLUSEXP                 YES,ADD VALUE TO ADDRESS.        06200020
*********************************************************************** 06210020
* THE FOLLOWING INSTRUCTION SUBTRACTS FROM THE BINARY ADDRESS THE     * 06220020
* BINARY VALUE RETURNED FROM THE CONVERSION ROUTINE.                  * 06230020
*********************************************************************** 06240020
         SPACE                                                          06250020
         SR    R0,R4                   R4=ALTERED ADDRESS.              06260020
MOVEALT  EQU   *                                                        06270020
         ST    R0,ZERO(R3)             ALTERED ADDRESS NOW IN WORKAREA. 06280020
         LH    R7,EXPIND(R1)           R7=EXP INDIRECT COUNT.           06290020
         LTR   R7,R7                   Q.IS INDIRECTING REQUESTED.      06300020
         BZ    NEXTEXP                 NO,CHECK NEXT EXP VALUE.         06310020
EXPADDR  EQU   *                                                        06320020
         CLC   TSTTOP(FOUR),ZERO(R3)   Q.ADDRESS IN STORAGE RANGE.      06330020
         BL    OUTCORE                 NO,PUT OUT ERROR MESSAGE.        06340020
         L     R6,ZERO(R3)             R6=ADDR OF NEXT VALUE.           06350020
         MVC   ONE(THREE,R3),ONE(R6)   NEW VALUE NOW IN WORKAREA.       06360020
         BCT   R7,EXPADDR              DECREMENT INDIRECT COUNT.        06370020
NEXTEXP  EQU   *                                                        06380020
         MVC   WORK4(ONE,R3),NINE(R1)  SAVE SIGN OF EXPRESSION.         06390020
         L     R1,ONE2(R1)             R1=NEXT EXP ADDRESS.             06440020
         B     MOREVAL                 CHECK FOR MORE EXP.              06640020
         SPACE                                                          06660020
*********************************************************************** 06680020
* THE FOLLOWING INSTRUCTION ADDS TO THE BINARY ADDRESS THE BINARY     * 06700020
* VALUE  RETURNED FROM THE VALUE CONVERSION ROUTINE.                  * 06720020
*********************************************************************** 06740020
         SPACE                                                          06760020
PLUSEXP  EQU   *                                                        06780020
         AR    R0,R4                   R4=ALTERED ADDRESS.              06800020
         B     MOVEALT                 MOVE ALTERED ADDR INTO WORKAREA. 06820020
         SPACE                                                          06840020
*********************************************************************** 06860020
* THIS AREA OF CODE CONVERTS A HEX VALUE TO TO BINARY BY USING THE    * 06880020
* HEX TO BINARY VALUE CONVERSION ROUTINE.                             * 06900020
*********************************************************************** 06920020
         SPACE                                                          06940020
HEXVAL   EQU   *                                                        06960020
         L     R0,ZERO(R3)             R0=ADDRESS VALUE.                06980020
         BAL   R14,HEXBIN              CONVERT HEX TO BINARY.           07000020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          07020020
         MVC   ZERO(FOUR,R3),ONE(R2)   BINARY VALUE NOW IN WORKAREA.    07060020
         L     R4,ZERO(R3)             R4=BINARY VALUE.                 07080020
         SR    R6,R6                   R6=0                             07100020
         IC    R6,ZERO(R2)             R6=LENGTH OF BINARY VALUE.       07120020
         LA    R7,FOUR                 R7=4.                            07140020
         SR    R7,R6                   R7=4-LENGTH OF BINARY.           07160020
         SLL   R7,THREE                R7=R7X8.                         07180020
         SRL   R4,ZERO(R7)             R4=VALUE RIGHT JUSTIFIED.        07200020
         B     TESTSIGN                CHECK FOR + OR - SIGN.           07240020
         SPACE                                                          07260020
*********************************************************************** 07280020
* THE FOLLOWING INSTRUCTIONS CONVERTS A SYMBOLIC ADDRESS FROM         * 07300020
* PRINTABLE CHARACTERS TO IT BINARY VALUE.  THIS CONVERSION IS DONE   * 07320020
* BY USING THE SYMBOLIC CONVERSION OF IKJEGSYM.                       * 07340020
*********************************************************************** 07360020
         SPACE                                                          07380020
SYMFOUND EQU   *                                                        07400020
         SPACE                                                          07410020
* CHECK LENGTH FOR MORE THAN 8 BYTES.                                 * 07420020
         SPACE                                                          07430020
         CLI   PDELEN3+ONE,LENSYM      Q.IS SYMBOL GT 8 CHARACTERS.     07440020
         BH    SYMERROR                YES,WRITE ERROR MESSAGE.         07460020
         BAL   R10,SYMLINK             GO CALL IKJEGSYM.                07500020
         LTR   R15,R15                 Q.IS THE RC=0.                   07520020
         BNZ   RETURN                  RETURN TO CALLER.                07540020
         SPACE                                                          07560020
*********************************************************************** 07580020
* THIS SECTION OF CODE GET THE BINARY ADDRESS FROM IKJEGSYM AND MOVES * 07600020
* IT INTO THE ADDRESS SAVE AREA.                                      * 07620020
*********************************************************************** 07640020
         SPACE                                                          07660020
         L     R2,PDEUSER              R2=ADDRESS OF SYMINFO.           07700020
         MVC   ZERO(FOUR,R3),ZERO(R2)  BINARY ADDRESS NOW IN WORKAREA.  07740020
         B     INDIRECK                CHECK FOR INDIRECKS.             07760020
         SPACE                                                          07780020
*********************************************************************** 07800020
* THIS SECTION OF CODE PUTS OUT AN ERROR MESSAGE INDICATING THAT THE  * 07820020
* LENGTH OF THE SYMBOLIC IS GREATER THAN EIGHT CHARACTERS.            * 07840020
*********************************************************************** 07860020
         SPACE                                                          07880020
SYMERROR EQU   *                                                        07900020
         L     R4,MSG001               R4=ADDR OF MSG PARM LIST.        07920020
         B     RITERROR                WRITE ERROR MSG.                 07940020
         SPACE                                                          07960020
*********************************************************************** 07980020
* THIS SECTION OF CODE CHECKS TO DETERMINE IF THE ADDRESS COMPUTED IS * 08000020
* WITHIN THE MAXIMUM STORAGE AREA.                                    * 08020020
*********************************************************************** 08040020
         SPACE                                                          08060020
CORECK   EQU   *                                                        08080020
         TM    PDEUSER,PDESIB          Q.ADDRES OF SYM INFO NEEDED.     08120020
         BO    NOCORECK                YES,SKIP CORE CHECK.             08140020
         CLC   TSTTOP(FOUR),ZERO(R3)   Q.IS ADDR IN STORAGE.            08200020
         BL    OUTCORE                 NO,PREPARE ERROR MESSAGE.        08220020
         MVC   PDEUSER+ONE(THREE),ONE(R3) ADDR NOW IN USERWORD.         08230020
         SPACE                                                          08280020
NOCORECK EQU   *                                                        08300020
         SR    R15,R15                 RC=0.                            08320020
         SPACE                                                          08340020
*********************************************************************** 08360020
* THIS SECTION CHECKS TO DETERMINE IF A RANGE OF ADDRESSES HAVE BEEN  * 08380020
* REQUESTED.  A CHECK IS MADE FIRST TO DETERMINE IF A RANGE IS        * 08390020
* POSSIBLE.  THE NEXT CHECK WILL DETERMINE IF A RANGE WAS SPEDIFIED.  * 08400020
* THE FIRST WORD OF THE SECOND PDL IS TESTED FOR ZEROES, WHICH        * 08410020
* INDICATES THAT THE RANGE WAS NOT SPECIFIED.                         * 08420020
*********************************************************************** 08520020
         SPACE                                                          08540020
         TM    TSTFLGS1,RANGESW        Q.IS A RANGE POSSIBLE.           08560020
         BZ    RETURN                  NO,RETURN                        08580020
         SPACE                                                          08590020
* A RANGE IS POSSIBLE.  TURN SWITCH OFF AND CHECK FOR A RANGE.        * 08600020
         SPACE                                                          08610020
         NI    TSTFLGS1,HEXFF-RANGESW  TURN RANGE SWITCH OFF.           08620020
         LA    R1,PDECHAIN             R1=ADDRESS OF SECOND PDL.        08640020
         NC    ZERO(TWO8,R1),ZERO(R1)  Q.RANGE SPECIFIED.               08660020
         BZ    RETURN                  NO,RETURN                        08680020
         LR    R8,R1                   BUMP ADDRESSABILITY.             08690020
         B     TOBIN                   CONVERT 2ND ADDRESS.             08700020
         SPACE                                                          08720020
*********************************************************************** 08740020
* THE FOLLOW INSTRUCTION ANALYZE THE NON-ZERO RETURN CODE TO          * 08760020
* DETERMINE WHY THE CONVERSION FAILED.  THE RETURN CODE PASSED        * 08780020
* TO THE CALLING ROUTINE WILL REFLECT THE RESMIT OF THE ANALYSIS.     * 08800020
*********************************************************************** 08820020
         SPACE                                                          08840020
SYMFAIL  EQU   *                                                        08860020
         LA    R15,FOUR                SET RETURN CODE=4.               08880020
         B     RETURN                  RETURN TO CALLER.                08900020
         SPACE                                                          08920020
ENTNAME  EQU   *                                                        08940020
         LA    R10,ENDLINK             R14=CALLER ADDRESS.              09000020
         SPACE                                                          09002020
*********************************************************************   09010020
*        THIS SUBROUTINE DOES THE LINK TO SYM.                      *   09012020
*********************************************************************   09014020
         SPACE                                                          09016020
SYMLINK  EQU   *                                                        09020020
         LR    R7,R1                   SAVE PTR TO PDE FOR SYM.         09040020
         LA    R1,SMTSYM2              R1=PTR TO CONSTANT NAME-BLDL.    09050020
         L     R15,TSTEXPAN            R15=ADDR OF EXPANSION ROUTINE.   09060020
         BALR  R14,R15                 GO TO DO EXPANDING.              09070020
         LTR   R6,R1                   Q.WAS BLDL ENTRY RETURNED.       09080020
         BZ    NOBLDL                  NO,DO LINK WITHOUT BLDL ENTRY.   09090020
         SPACE                                                          09100020
*********************************************************************** 09110020
* IF BLDL ENTRY IS AVAILABLE, A LINK TO SYM IS DONE WITH THIS ENTRY.  * 09112020
*********************************************************************** 09114020
         SPACE                                                          09116020
         LA    R15,FORTY(R3)           R15=ADDR IS WORKAREA FOR LIST.   09118020
         MVC   ZERO(LINKLSTL,R15),LINKLST MOVE LINK LIST TO WORKAREA.   09118420
         LR    R1,R7                   R7=ADDR OF PDE FOR SYM.          09118820
         LINK  DE=(6),MF=(E,(1)),SF=(E,(15)) ISSUE LINK WITH BLDL.      09119220
IKJEGBLO EQU   *                                                        09119320
*                                      IKJEGBLO MUST FOLLOW THIS LINK.  09119420
         BR    R10                     RETURN TO CALLER.                09119520
         SPACE                                                          09119620
*********************************************************************** 09119720
* IF THE BLDL ISSUED BY MAINLINE WAS NOT SUCCESSFUL, AND THE BLDL     * 09119820
* ENTRY IS NOT AVAILABLE, A LINK TO SYM IS DONE WITHOUT THE BLDL      * 09119920
* ENTRY.                                                              * 09133220
*********************************************************************** 09135220
         SPACE                                                          09143220
NOBLDL   EQU   *                                                        09143520
         LR    R1,R7                   R1=PTR TO PDE FOR SYM     A46765 09143821
         LINK  EP=IKJEGSYM,MF=(E,(1))  ISSUE LINK WITHOUT BLDL          09144120
IKJEGBL1 EQU   *                                                        09144420
SMTSYM1  DS    0H                      SMT TESTCASE LABEL               09144720
*                                       LINK TO SYM FAILED              09145020
*                                       TESTCASE ID  TTSTC120           09145320
*                                       TESTCASE ID  TEQU5300           09145620
         BR    R10                     RETURN TO CALLER.                09146520
ENDLINK  EQU   *                                                        09146720
         LTR   R15,R15                 Q.RC=0.                          09160020
         BNZ   RETURN                  RETURN TO CALLER.                09180020
         B     NOCORECK                CHECK FOR RANGE.                 09200020
         SPACE                                                          09220020
*********************************************************************** 09240020
*                                                                     * 09260020
*        THE FOLLOWING INSTRUCTIONS CONVERTS AN ADDRESS FROM          * 09280020
*        ITS BINARY FORMAT TO ITS PRINTABLE FORMAT.                   * 09300020
*                                                                     * 09320020
         SPACE                                                          09340020
FROMBIN  EQU   *                                                        09360020
         SPACE                                                          09380020
* THE TEST UNDER MASK ROUTES CONTROL TO THE PROPER CONVERSION CODE.   * 09400020
         SPACE                                                          09420020
         TM    PDEFLG4,ABSCOMPL        Q.IS BINARY TO BE ABSOLUTE ADDR. 09440020
         BZ    BINABT                  YES,CONVERT TO ABSOLUTE ADDR.    09460020
         TM    PDEFLG4,RELADDR         Q.IS BINARY TO BE A REL ADDR.    09480020
         BO    BINREL                  YES,CONVERT TO RELATIVE ADDR.    09500020
         SPACE                                                          09520020
*********************************************************************** 09540020
* THIS SECTION OF CODE CONVERTS BINARY TO REGISTER NOTATION. IF THE   * 09560020
* REGISTER IS A GENERAL PURPOSE REGISTER IT PRINTABLE VALUE WILL      * 09580020
* HAVE CHARACTER  -R-    FOLLOWING IT. IF IT IS A FLOATING POINT      * 09600020
* REGISTER THE LETTER -D- OR -E- WILL FOLLOW DEPENDING IF IT IS A     * 09620020
* SINGLE OR DOUBLE PRECISION.                                         * 09640020
*********************************************************************** 09660020
         SPACE                                                          09680020
         L     R5,PDEADRPT             R5=ADDR OF INPUT STRING.         09700020
         SR    R6,R6                   R6=0.                            09720020
         IC    R6,REGIN(R5)            R6=ADDR STRING.                  09740020
         CVD   R6,ZERO(R3)             REGISTER NOW PACKED DECIMAL.     09780020
         OI    SEVEN(R3),SIGNF         CHANGE SIGN TO X'F'.             09800020
         UNPK  ZERO(TWO,R3),SIX(TWO,R3) REGISTER NOW IN PRINTABLE FORM. 09820020
         SPACE                                                          09840020
*********************************************************************** 09860020
* THE FOLLOWING INSTRUCTION WHICH TYPE OF REGISTER HAS BEEN SPECIFIED * 09880020
* AND BRANCHES TO TO PROPER CODE TO MOVE IN THE PROPER LETTERS(R,RE,  * 09900020
* OR RD).                                                             * 09920020
*********************************************************************** 09940020
         SPACE                                                          09960020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       09980020
         MVC   ONE(TWO,R2),ZERO(R3)    MOVE ADDR INTO OUTPUT AREA       10000020
         SR    R15,R15                 RC=0.                            10020020
         MVI   ZERO(R2),THREE          MOVE LENGTH INTO CONAREA.        10040020
         TM    PDEFLG4,DOBMASK         Q.IS REGISTER DOUBLE PRECISION.  10060020
         BO    RDMOVE                  YES,MOVE IN D.                   10080020
         TM    PDEFLG4,SINMASK         Q.IS REGISTER SINGLE PRECISION.  10100020
         BO    REMOVE                  YES,MOVE IN E.                   10120020
         SPACE                                                          10140020
*********************************************************************** 10160020
* THE FOLLOWING WILL ALTER THE REG VALUE BY HAVING A (R) FOLLOWING    * 10180020
* IT.                                                                 * 10200020
*********************************************************************** 10220020
         SPACE                                                          10240020
         MVI   THREE(R2),RSIGN         APPEND -R- TO END OF OUTPUT.     10260020
         CLI   ONE(R2),F0              Q.IS FIRST BYTE A HEX -F0-.      10280020
         BNE   RETURN                  NO,RETURN TO CALLER.             10300020
         MVI   ONE(R2),BLANK           BLANK NOW IN FIRST BYTE.         10320020
         B     RETURN                  RETURN TO CALLER.                10340020
         SPACE                                                          10360020
*********************************************************************** 10380020
* THIS SECTION OF CODE ALTERS THE REGISTER VALUE BY APPENDING A (RD)  * 10400020
* TO THE END OF IT AND MOVE THE OUTPUT INTO CONVAREA.                 * 10420020
*********************************************************************** 10440020
         SPACE                                                          10460020
RDMOVE   EQU   *                                                        10480020
         MVC   ONE(ONE,R2),ONE(R3)     REG NUMBER NOW IN CONAREA.       10500020
         MVI   TWO(R2),RDSIGN          MOVE D TO RIGHT OF OUTPUT.       10520020
         MVI   ZERO(R2),TWO            MOVE LENGTH INTO CONAREA.        10540020
         B     RETURN                  RETURN TO CALLER.                10560020
*********************************************************************** 10580020
* THIS SECTION FO CODE ALTERS THE REGISTER VALUE BY PPPENDING A "RE"  * 10600020
* TO THE END OF IT AND MOVES THE OUTPUT INTO CONAREA.                   10620020
*********************************************************************** 10640020
         SPACE                                                          10660020
REMOVE   EQU   *                                                        10680020
         MVC   ONE(ONE,R2),ONE(R3)     MOVE REGISTER INTO CONAREA.      10700020
         MVI   TWO(R2),RESIGN          MOVE R TO RIGHT OF OUTPUT.       10720020
         MVI   ZERO(R2),TWO            MOVE LENGTH INTO CONAREA.        10740020
         B     RETURN                  RETURN TO CALLER.                10760020
         SPACE                                                          10780020
*********************************************************************** 10800020
* THIS SECTION OF CODE CONVERTS BINARY TO IT ABSOLUTE FORMAT. THE     * 10820020
* OUTPUT IS STORED IN CONAREA.                                        * 10840020
*********************************************************************** 10860020
         SPACE                                                          10880020
BINABT   EQU   *                                                        10900020
         LA    R7,ZERO                 R7=0.                            10920020
         L     R2,PDEADRPT             R2=ADDRESS OF INPUT STRING.      10940020
         LA    R6,SIX                  R6=LENGTH,6.                     10960020
         MVC   ZERO(FOUR,R3),ZERO(R2)  INPUT NOW IN WORKAREA.           11000020
         L     R5,ZERO(R3)             R5=INPUT STRING.                 11020020
         SLL   R5,EIGHT                ISOLATE LOW ORDER 3 BYTES.       11040020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              11060020
         LA    R0,NINE                 R0=9.                            11080020
NEXTBITS EQU   *                                                        11100020
         SR    R4,R4                   R4=0.                            11120020
         SLDL  R4,FOUR                 ISOLATE 4 BITS.                  11140020
         CR    R4,R0                   Q.ARE BITS GT 9.                 11160020
         BH    ADDRHI                  YES.                             11180020
         SPACE                                                          11200020
* THE 4 BITS ARE NUMERIC. MAKE PRINTABLE BY ADDING X'F0'.             * 11220020
         SPACE                                                          11240020
         LA    R4,F0(R4)               R4=PRINTABLE BYTE.               11260020
BYTEMOVE EQU   *                                                        11280020
         STC   R4,ONE(R2)              PUT BYTE INTO CONAREA.           11300020
         LA    R2,ONE(R2)              R2=ADDR OF NEXT OUTPUT AREA.     11320020
         LA    R7,ONE(R7)              INCREMENT BYTE COUNTER.          11340020
         CR    R7,R6                   Q.ARE THERE MORE BITS.           11360020
         BNE   NEXTBITS                YES,GET NEXT 4 BITS.             11380020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           11420020
         MVI   ZERO(R2),LEN7           MOVE LENGTH INTO CONAREA.        11440020
         MVI   SEVEN(R2),PERIOD        APPEND -.- TO END OF OUTPUT.     11460020
         SR    R15,R15                 SET RC=0.                        11480020
         B     RETURN                  RETURN TO CALLER.                11500020
         SPACE                                                          11520020
* THE 4 BITS AREA ALPHABETIC. CONVERT PRINTABLE BY ADDING X'B7'.      * 11540020
         SPACE                                                          11560020
ADDRHI   EQU   *                                                        11580020
         LA    R4,B7(R4)               R4=PRINTABLE BYTE.               11600020
         B     BYTEMOVE                MOVE BYTE OF OUTPUT TO CONAREA.  11620020
         SPACE                                                          11640020
*********************************************************************** 11660020
* THIS SECTION OF CODE CONVERTS BINARY TO A RELATIVE ADDRESS. THE     * 11680020
* OUTPUT IS STORED IN CONAREA                                         * 11700020
*********************************************************************** 11720020
         SPACE                                                          11740020
BINREL   EQU   *                                                        11760020
         TM    PDEFLG2,CTNAMFLG        Q.IS QUALIFY SPECIFIED.          11800020
         BZ    GETPP                   NO,GET ADDRESS FROM PPLOAD.      11820020
         L     R2,PPTEMP               R2=BASE FOR RELATIVES.           11840020
BASEMOVE EQU   *                                                        11860020
         L     R4,PDEADRPT             R4=ADDRESS OF INPUT STRING.      11880020
         MVC   ZERO(FOUR,R3),ZERO(R4)  GET INPUT STRING.                11900020
         L     R4,ZERO(R3)             R4=INPUT STRING.                 11920020
         SR    R4,R2                   R4=REALTIVE VALUE IN BINARY.     11940020
         ST    R4,ONE6(R3)             PUT INPUT INTO FAKE PDE.         11960020
         LA    R4,ONE6(R3)             R4=ADDRESS OF INPUT VALUE.       11980020
         ST    R4,EIGHT(R3)            ADDRESS IN FAKE VALUE PDE.       12000020
         LA    R5,FOUR                 R5=A LENGTH OF FOUR.             12020020
         STH   R5,ONE2(R3)             MOVE LENGTH INTO PDE.            12040020
         LA    R1,EIGHT(R3)            R1=ADDRESS OF FAKE PDE.          12060020
         BAL   R14,BINHEX              LINK TO BINHEX RT.               12080020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           12100020
         LA    R2,ONE(R2)              R2=ADDRESS OF OUTPUT STRING.     12120020
         LA    R5,SEVEN                R5=7.                            12140020
F0CHECK  EQU   *                                                        12160020
         CLI   ZERO(R2),F0             Q.IS BYTE FIRST VALID CHAR.      12180020
         BNE   ONEF0                   YES,FORMAT OUTPUT.               12200020
         LA    R2,ONE(R2)              ADVANCE POINTER.                 12220020
         BCT   R5,F0CHECK              CHECK LAST DITIT.                12240020
ONEF0    EQU   *                                                        12260020
         EX    R5,RELMOVE              MOVE REL INTO WORKAREA.          12300020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           12320020
         MVI   ZERO(R2),BLANK          BLANK IN FIRST BYTE OF CONAREA.  12340020
         MVC   ONE(FIVE,R2),ZERO(R2)   CONAREA NOW HAS SIX BLANKS.      12360020
         MVI   ZERO(R2),SEVEN          LENGTH NOW IN CONAREA.           12380020
         LA    R6,SIX                  R6=6.                            12400020
         SR    R6,R5                   R6=OFFSET IN CONAREA.            12420020
         LA    R2,ONE(R6,R2)           R2=ADDR OF OUTPUT LOCATION.      12440020
         EX    R5,REL4MAT              MOVE OUTPUT INTO CONAREA.        12460020
         BCTR  R2,ZERO                 R2=ADDR OF BYTE BEFORE 1ST DIGIT 12480020
         MVI   ZERO(R2),PLUS           PRECEDE OUTPUT WITH A PLUS SIGN. 12500020
         SR    R15,R15                 RC=0.                            12520020
         B     RETURN                  RETURN TO CALLER.                12540020
RELMOVE  MVC   ZERO(ONE,R3),ZERO(R2)   MOVE REL INTO WORKAREA.          12560020
REL4MAT  MVC   ZERO(ONE,R2),ZERO(R3)   MOVE REL OUTPUT INTO CONAREA.    12580020
OUTCORE  EQU   *                                                        12600020
         L     R4,MSG002               R4=ADDR OF MSG PARM LIST.        12620020
RITERROR EQU   *                                                        12640020
         MVC   PDEUSER(FOUR),FOUR(R4)  2ND LEVEL MSG ADDR IN USER.      12700020
         LR    R0,R8                   R0=ADDR OF PDE.                  12720020
         L     R2,ZERO(R4)             R5=ADDR OF MSG PARM LIST.SA55218 12730021
         LH    R5,ZERO(R2)             R5=LENGTH OF MSG.        SA55218 12760021
         L     R6,OUTBUF               R6=PTR TO GENERAL OUTPUT BUFFER  12780020
         BCTR  R5,ZERO                 R5=EXECUTE LENGTH.               12800020
         EX    R5,MSGMOVE              MOVE INVALID ADDRESS MSG.        12820020
         LA    R1,ONE(R5,R6)           R1=PTR TO AREA TO BUILD STRING.  12840020
         L     R15,TSTADDR             R15=ADDR OF BUILD RTN.           12860020
         BALR  R14,R15                 BUILD OUTPUT MSG.                12880020
         MVI   ZERO(R1),PLUS           MOVE INTO MSG A PLUS SIGN.       12900020
         AR    R5,R0                   R5=TOTAL LENGTH OF MSG.          12920020
         LA    R5,TWO(R5)              *                                12940020
         MVC   ZERO(FOUR,R3),OUTBUF    SET UP MSG PARM LIST.            12960020
         MVC   FOUR(FOUR,R3),FOUR(R4)  2ND LEVEL MSG PT         SA55218 12970021
*                                      IN PARM LIST.                    12972021
         STH   R5,ZERO(R6)             LENGTH OF MSG IN BUFFER.         12980020
ERRORPK  EQU   *                                                        13000020
         LCR   R1,R3                   R1,NOW NEG FOR IKJEGIO1.         13020020
         L     R15,TPUTADDR            R15=ENTRY POINT OF IKJEGIO1.     13040020
         BALR  R14,R15                 PUT OUT ERROR MSG.               13060020
         LTR   R15,R15                 Q.IKJEGIO1 SUCCESSFUL.           13080020
         BNZ   RETURN                  RESTORE CALLER REGISTERS.        13100020
IOOK     EQU   *                                                        13120020
         LA    R15,FOUR                R15=RC OF 4.                     13140020
         B     RETURN                  RESTORE CALLER REGISTERS.        13160020
MSGMOVE  MVC   ZERO(ONE,R6),ZERO(R2)   INVALID ADDRESS MSG NOW  SA55218 13180021
*                                      IN BUFF.                         13190021
GETPP    EQU   *                                                        13200020
         L     R2,PPLOAD               R2=CURRENT BASE FOR RELATIVES.   13220020
         B     BASEMOVE                MOVE IN INPUT STRING.            13240020
         TITLE 'IKJEGCVT VALUE CONVERSION ROUTINE.'                     13260020
*********************************************************************** 13280020
* THE FOLLOWING INSTRUCTION DETRRMINE IF THE VALUE CONVERSION IS TO   * 13300020
* BE TO OR FROM BINARY.                                               * 13320020
*********************************************************************** 13340020
         SPACE                                                          13360020
YHCODE   EQU   *                                                        13380020
         LA    R5,ONE                  R5=1. INDICATES H OR Y SPECIFIED 13400020
         B     NOTHORY                 BRANCH TO PROPER RTN.            13420020
         SPACE                                                          13440020
VALCVT   EQU   *                                                        13460020
         LTR   R0,R0                   Q.IS THE CONVERSION TO BINARY.   13480020
         BM    FROMBI                  NO,CONVERT VALUE TO PRINTABLE.   13500020
         SPACE                                                          13520020
*********************************************************************** 13540020
* THE FOLLOWING INSTRUCTIONS CONVERTS A VALUE FROM PRINTABLE     *      13560020
* CHARACTERS TO ITS BINARY FORMAT.                                    * 13580020
*********************************************************************** 13600020
         SPACE                                                          13620020
VALTOBIN EQU   *                                                        13640020
         SR    R5,R5                   R5=O. NOT H OR Y SWITCH.         13660020
         CLI   SEVEN(R1),HCODE         Q.H SPECIFIED.                   13680020
         BE    YHCODE                  YES,SET H OR Y SWITCH.           13700020
         CLI   SEVEN(R1),YCODE         Q.Y SPECIFIED.                   13720020
         BE    YHCODE                  YES,SET H OR Y SWITCH.           13740020
         SPACE                                                          13760020
*********************************************************************** 13780020
* THE FOLLOWING BRANCH ROUTINE ROUTES CONTROL TO THE DIFFERENT TYPES  * 13800020
* OF CONVERSIONS.                                                     * 13820020
*********************************************************************** 13840020
         SPACE                                                          13860020
NOTHORY  EQU   *                                                        13880020
         SR    R6,R6                   R6=0.                            13900020
         IC    R6,SEVEN(R1)            R6=TYPE CODE IN HEX.             13920020
         L     R15,ACONLST(R6)         R15=ADDRESS OF CVT RTN.          13940020
         BALR  R14,R15                 GOTO PROPER CONVERT RTN.         13960020
         USING BASEADDR,R14            R14=TEMP BASE REGISTER.          13980020
BASEADDR EQU   *                                                        14000020
         L     R12,CVTBASE             R12=ADDR OF IKJEGCVT.            14020020
         DROP  R14                     R14 NO LONGER BASE REGISTER.     14040020
RETURN   EQU   *                                                        14060020
         L     R13,FOUR(R13)           R13=ADDR OF CALLER SAVE AREA.    14080020
         RETURN (14,12),,RC=(15)       RESTORE CALLERS REGISTERS.       14100020
         SPACE                                                          14120020
BINBIN   EQU   *                                                        14140020
         SPACE                                                          14160020
*********************************************************************** 14180020
*                                                                     * 14200020
*        THIS ROUTINE CONVERTS PRINTABLE BYTES OF THE BINARY        *   14220020
*        FORMAT INTO ITS ONE BIT BINARY VALUE.                        * 14240020
*                                                                     * 14260020
*********************************************************************** 14280020
         SPACE                                                          14300020
         SR    R8,R8                   R8=0.                            14320020
         IC    R8,VALLEN(R1)           R8=LENGTH OF INPUT.              14340020
         LA    R0,EIGHT                R0=8.                            14360020
         SR    R7,R7                   R7=0.                            14380020
         SR    R6,R6                   R6=0.                            14400020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       14420020
         LA    R2,ONE(R2)              R2=OUTPUT AREA PLUS 1.           14440020
         L     R3,ZERO(R1)             R3=ADDRESS OF INPUT STRING.      14460020
         SR    R1,R1                   R1=0.                            14480020
INIT     EQU   *                                                        14500020
         LA    R5,ONE                  R5=1                             14520020
         LCR   R5,R5                   R5=32 BINARY ONES.               14540020
         SR    R4,R4                   R4=0.                            14560020
NEXTBYTE TM    ZERO(R3),F1             Q.IS THE BYTE A ONE.             14580020
         BO    AONE                    YES,MOVE IN AN ON BIT.           14600020
         SLL   R4,ONE                  MOVE IN A ZERO.                  14620020
         B     SKIPONE                 SKIP ONES ROUTINE.               14640020
AONE     EQU   *                                                        14660020
         SLDL  R4,ONE                  MOVE IN ONE ON BIT.              14680020
SKIPONE  EQU   *                                                        14700020
         LA    R3,ONE(R3)              INCREMENT INPUT ADDRESS.         14720020
         LA    R6,ONE(R6)              INCREMENT SAVE BYTE COUNTER.     14740020
         LA    R7,ONE(R7)              INCREMENT BYTE COUNTER.          14760020
         CLR   R0,R7                   BYTE COUNT=8.                    14780020
         BNE   NOT8                    NO,COMPARE SAVE COUNT TO LENGHT. 14800020
         SR    R7,R7                   RE-INITIATE BYTE COUNT.          14820020
         STC   R4,ZERO(R2)             MOVE BYTE INTO CONAREA.          14840020
         LA    R1,ONE(R1)              INCREMENT LENGTH COUNTER.        14860020
         LA    R2,ONE(R2)              INCREMENT CONAREA POINTER        14880020
NOT8     CLR   R6,R8                   LENGTH=SAVE,BYTE COUNT.          14900020
         BE    BYTESEND                MOVE BYTE INTO CONAREA.          14920020
         LTR   R7,R7                   BYTE COUNT=0.                    14940020
         BZ    INIT                    YES,CHECK NEXT EIGHT BYTES.      14960020
         B     NEXTBYTE                GET NEXT BYTE.                   14980020
BYTESEND EQU   *                                                        15000020
         LTR   R7,R7                   BYTE COUNT=0.                    15020020
         BZ    NOOUT                   YES,OUTPUT IS IN OUTPUT AREA.    15040020
         LA    R8,EIGHT                R8=8.                            15060020
         SR    R8,R7                   R7=NUMBER OF LEADING ZEROS.      15080020
         SLL   R4,ZERO(R8)             LEFT JUSTIFY OUTPUT              15100020
         STC   R4,ZERO(R2)             MOVE OUTPUT INTO CONAREA.        15120020
         LA    R1,ONE(R1)              R1=LENGTH OF OUTPUT PLUS 1.      15140020
NOOUT    EQU   *                                                        15160020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       15180020
         STC   R1,ZERO(R2)             PUT OUTPUT LENGTH INTO CONAREA.  15200020
         SR    R15,R15                 SET RC=0.                        15220020
         BR    R14                     RETURN TO CALLER.                15240020
PKBIN    EQU   *                                                        15260020
         SPACE                                                          15280020
*********************************************************************** 15300020
*                                                                     * 15320020
*        THIS ROUTINE CONVERTS PRINTABLE CHARACTERS TO PACKED         * 15340020
*        DECIMAL.                                                     * 15360020
*                                                                     * 15380020
*********************************************************************** 15400020
         SPACE                                                          15420020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          15440020
         L     R4,WORKAREA             R4=ADDRESS OF WORKAREA.          15460020
         LH    R6,FOUR(R1)             R6=LENGTH OF INPUT.              15480020
         L     R3,ZERO(R1)             R3=ADDRESS OF INPUT STRING.      15500020
         LR    R8,R3                   R8=ADDR OF INPUT STRING.         15520020
         SPACE                                                          15530020
*        THIS SECTION OF CODE CHECKS FOR A SIGN.                      * 15540020
         SPACE                                                          15550020
         CLI   ZERO(R3),SIGNNEG        Q.IS SIGN NEGATIVE.              15560020
         BE    ADDADDR                 YES.                             15580020
         CLI   ZERO(R3),PLUSSIGN       Q.IS SIGN POSITIVE.              15600020
         BNE   NOSIGN                  YES.                             15620020
ADDADDR  LA    R3,ONE(R3)              R3=ADDRESS OF INPUT MINUS SIGN.  15640020
         BCTR  R6,ZERO                 DECREMENT LENGTH.                15660020
NOSIGN   EQU   *                                                        15680020
         CLI   FIVE(R1),ONE6           Q.LENGTH GT 16.                  15700020
         BH    PKLG                    YES.                             15720020
         SPACE                                                          15740020
*********************************************************************** 15760020
*                                                                     * 15780020
*        THIS SECTION OF CODE CONVERTS TO PACK THE VALUE LESS THAN    * 15800020
*        SEVENTEEN BYTES.                                             * 15820020
*                                                                     * 15830020
*********************************************************************** 15840020
         SPACE                                                          15860020
         LR    R7,R6                   R7=LENGTH OF INPUT.              15880020
         SRL   R6,ONE                  R6=LENGTH DIVIDED BY 2.          15900020
         SLL   R6,FOUR                 R6=L1                            15920020
         BCTR  R7,ZERO                 R7=EXECUTE INPUT LENGTH.         15940020
         OR    R6,R7                   R6=L1 AND L2.                    15960020
         EX    R6,PACK4                INPUT STRING IS NOW PACKED DEC.  15980020
         SRL   R6,FOUR                 ISOLATE LENGTH OF OUTPUT.        16000020
         LA    R6,ONE(R6)              R6=EXACT LENGTH OF PACKED DEC.   16020020
         STC   R6,ZERO(R2)             MOVE LENGTH INTO CONAREA.        16040020
         LA    R3,ZERO(R6,R4)          R3=ADDRESS OF LAST OUTPUT BYTE.  16060020
         BCTR  R3,ZERO                 *                                16080020
         CLI   ZERO(R8),SIGNNEG        Q.INPUT NEGATIVE.                16100020
         BNE   NO                      NO,MOVE IN POSITIVE SIGN.        16120020
         MVN   ZERO(ONE,R3),OFFSETD    MOVE IN NEG SIGN.                16140020
PKMOVE   EX    R6,OUTPUT               MOVE OUTPUT INTO CONAREA.        16160020
PKBEND   SR    R15,R15                 SET RETURN CODE.                 16180020
         BR    R14                     RETURN TO CALLING ROUTINE.       16200020
NO       EQU   *                                                        16220020
         MVN   ZERO(ONE,R3),OFFSETC    MOVE IN POSITIVE SIGN.           16240020
         B     PKMOVE                  MOVE OUTPUT INTO CONAREA.        16260020
PACK4    PACK  ZERO(ONE,R4),ZERO(ONE,R3)   INPUT NOW PACK DATA.         16280020
PKLG     EQU   *                                                        16300020
         STC   R6,ZERO(R4)             LENGTH NOW IN WORKAREA.          16320020
         TM    ZERO(R4),ODDLEN         Q.LENGTH ODD.                    16340020
         BO    LNODD                   YES,CONVERT ODD NUMBER OF BYTES. 16360020
         SPACE                                                          16380020
*********************************************************************** 16400020
*                                                                     * 16420020
*        THIS SECTION OF CODE CONVERTS AN EVEN NUMBER OF PRINTABLE    * 16440020
*        CHARACTERS TO PACKED DECIMAL.                                * 16460020
*                                                                     * 16480020
*********************************************************************** 16500020
         SPACE                                                          16520020
         PACK   ONE(NINE,R2),ZERO(ONE6,R3)  PACK FIRST 16 BYTES         16540020
         LA    R7,ONE6                 R7=16.                           16560020
         SR    R6,R7                   R6=LENGTH MINUS 16.              16580020
         LR    R7,R6                   R7=R6.                           16600020
         SRL   R6,ONE                  R6=LENGTH DIVIDED BY 2.          16620020
         BCTR  R7,ZERO                 R7=LENGTH FOR EXECUTE.           16640020
         SLL   R7,TWO8                 R7=LENGTH HIGH ORDER 4 BITS.     16660020
         SLDL  R6,FOUR                 R6=L1 AND L2 FOR EXECUTE.        16680020
         EX    R6,PACK2                PACK 2ND HALF OF INPUT STRING.   16700020
         SRL   R6,FOUR                 R6=LENGTH OUT PACKED DECIMAL.    16720020
         LA    R4,ZERO(R6,R4)          R4=ADDRESS OF SIGN BYTE.         16740020
         CLI   ZERO(R8),SIGNNEG        Q.SIGN NEGATIVE.                 16760020
         BNE   NO2                     NO,MOVE POSITIVE SIGN.           16780020
         MVN   ZERO(ONE,R4),OFFSETD    MOVE IN NEG SIGN.                16800020
MOVEZ    L     R4,WORKAREA             R4=ADDRESS OF WORKAREA.          16820020
         MVZ   ZERO(ONE,R4),NINE(R2)   MOVE ZONE BITS OF 1ST PACKED DEC 16840020
         EX    R6,OUTPUT2              MOVE 2ND PACKED INTO CONAREA.    16860020
         LA    R10,TEN(R6)             TOTAL LENGTH OF OUTPUT.          16880020
         STC   R10,ZERO(R2)            MOVE LENGTH INTO CONAREA.        16900020
         B     PKBEND                  SET RETURN CODE TO 0.            16920020
LNODD    EQU   *                                                        16940020
         SPACE                                                          16960020
*********************************************************************** 16980020
*                                                                     * 17000020
*        THIS  AREA OF CODE CONVERTS AN ODD NUMBER OF PRINTABLE       * 17020020
*        CHARACTERS TO PACKED DECIMAL.                                * 17040020
*                                                                     * 17060020
*********************************************************************** 17080020
         SPACE                                                          17100020
         PACK  ZERO(NINE,R4),ZERO(ONE6,R3) INPUT=PACKED DECIMAL FORMAT. 17120020
         XC    NINE(TWO,R4),NINE(R4)   ADD TWO BYTES OF ZEROS TO INPUT. 17140020
         NI    EIGHT(R4),AZERO         ALTER SIGN TO ZERO.              17160020
         MVO   ZERO(TEN,R4),ZERO(NINE,R4) SHIFT PACKED DEC 4 BITS.      17180020
         LA    R4,ONE(R4)              R4=ADDR OF PACKED DECIMAL.       17200020
         LA    R7,ONE6                 R7=169.                          17220020
         SR    R6,R7                   R6=LENGTH MINUS 16.              17240020
         LR    R7,R6                   R7=LENGTH MINUS 16.              17260020
         SRL   R6,ONE                  R6=LENGTH DIVIDED BY 2.          17280020
         BCTR  R7,ZERO                 R7=LENGTH DIVIDED BY 2 MINUS 1.  17300020
         SLL   R7,TWO8                 R7=LENGTH IN HIGH ORDER BYTE     17320020
         SLDL  R6,FOUR                 R6=L1 AND L2 FOR EXECUTE.        17340020
         EX    R6,PACK3                PACK 2ND HALF OF INPUT STRING.   17360020
         SRL   R6,FOUR                 R6=LENGTH OF PACKED DECIMAL.     17380020
         LA    R4,EIGHT(R6,R4)         R4=ADDR OF SIGN BYTE.            17400020
         CLI   ZERO(R8),SIGNNEG        Q.SIGN NEGATIVE.                 17420020
         BNE   POSITIVE                NO,MOVE POSITIVE SIGN.           17440020
         MVN   ZERO(ONE,R4),OFFSETD    MOVE IN NEG SIGN.                17460020
TLENGTH  LA    R6,NINE(R6)             R6=LENGTH OF OUTPUT              17480020
         STC   R6,ZERO(R2)             MOVE LENGTH INTO CONAREA.        17500020
         BCTR  R6,ZERO                 R6=LENGTH FOR EXECUTE.           17520020
         L     R4,WORKAREA             R4=ADDRESS OF WORKAREA.          17540020
         LA    R4,ONE(R4)              R4=ACTURAL ADDRESS OF INPUT      17560020
         B     PKMOVE                  MOVE OUTPUT INTO CONAREA.        17580020
POSITIVE EQU   *                                                        17600020
         MVN   ZERO(ONE,R4),OFFSETC    MOVE IN POSITIVE SIGN.           17620020
         B     TLENGTH                 GET LENGTH OF THE OUTPUT.        17640020
PACK3    PACK  EIGHT(ONE,R4),ONE6(ONE,R3)  PACK 2ND HALF OF INPUT.      17660020
INPUT    MVC   ZERO(ONE,R4),ZERO(R3)   MOVE INPUT INTO WORK AREA.       17680020
OUTPUT   MVC   ONE(ONE,R2),ZERO(R4)    MOVE OUTPUT INTO CONAREA.        17700020
PACK2    PACK  ZERO(ONE,R4),ONE6(ONE,R3) PACK 2ND HALF OF STRING.       17720020
OUTPUT2  MVC   NINE(ONE,R2),ZERO(R4)   MOVE 2ND HALF INTO CONAREA.      17740020
NO2      EQU   *                                                        17760020
         MVN   ZERO(ONE,R4),OFFSETC    MOVEINNEG SIGN.                  17780020
         B     MOVEZ                   CONTINUE PROCESSING.             17800020
HEXBIN   EQU   *                                                        17820020
         SPACE                                                          17840020
*********************************************************************** 17860020
* THE FOLLOWING LINES OF CODE CONVERTS HEXADECIMAL BYTES TO BINARY.   * 17870020
* THIS ROUTINE CANNOT USE REGISTER 8, BECAUSE THE ADDRESS CONVERSION  * 17880020
* ROUTINE USES THIS ROUTINE AND REGISTER 8 IS THE PDE ADDRESSABILITY  * 17890020
* REGISTER.                                                           * 17900020
*********************************************************************** 17920020
         SPACE                                                          17930020
         L     R2,CONAREA              R2=CONVERT OUTPUT AREA ADDR.     17940020
         LH    R4,FOUR(R1)             R4=LENGTH OF INPUT.              17960020
         LR    R5,R4                   R5=LENGTH TO EXECUTE-TRANSLATE.  17980020
         BCTR  R5,ZERO                 DECREMENT LENGTH.                18000020
         L     R6,ZERO(R1)             R6=ADDRESS OF INPUT STRING.      18020020
         L     R3,WORKAREA             R3=ADDR OF TEMP. STORAGE         18040020
         EX    R5,SAFEMOVE             MOVE STRING INTO TEMP STORE      18060020
         LR    R6,R3                   R6=NEW STRING ADDR               18080020
         EX    R5,TRSLATE              TRANSLATE STRING                 18100020
         LR    R10,R4                  R10=HEX LENGTH                   18120020
         LA    R10,ONE(R10)            R10=LENGTH PLUS 1                18140020
         SRL   R10,ONE                 R10=LENGTH OF BINARY             18160020
         STC   R10,ZERO(R2)            STORE LENGTH FOR RETURN          18180020
         SLL   R10,FOUR                L1 TO HIGH END OF BYTE           18200020
         OR    R10,R4                  R10=L1 AND L2                    18220020
         EX    R10,PACK                CONVERT TO BINARY                18240020
         SR    R15,R15                 RETURN CODE=0.                   18260020
         BR    R14                     RETURN                           18280020
TRSLATE  TR    ZERO(ONE,R6),TRTABLE    ALTER PRINTABLES FOR CVT.        18300020
SAFEMOVE MVC   ZERO(ONE,R3),ZERO(R6)   INPUT NOW IN WORKAREA.           18320020
PACK     PACK  ONE(ONE,R2),ZERO(ONE,R6) INPUT NOW IN BINARY FORMAT.     18340020
         ORG   *-193                   BYPASS ZEROES IN TABLE.          18360020
TRTABLE  EQU   *                                                        18380020
         ORG   *+193                   RESET TABLE TO CORRECT IC.       18400020
         DC    X'FAFBFCFDFEFF'         *   TRANSLATE   TABLE          * 18420020
         DC    41X'00'                 *         FOR                  * 18440020
         DC    X'F0F1F2F3F4'           *    PRINTABLE HEXADECIMAL     * 18460020
         DC    X'F5F6F7F8F9'           *  TO BINARY ROUTINE.          * 18480020
         DC    C'ABCDEF'               *                              * 18500020
         DS    0H                      RESET TO HALFWORD BOUNDARY.      18520020
         SPACE                                                          18540020
*********************************************************************** 18560020
* THIS ROUTINE CONVERTS F,A,Q, AND V TYPE ADDRESSES TO BINARY.        * 18580020
* (R8 CAN NOT BE USE IN THIS ROUTINE.)                                * 18600020
*********************************************************************** 18620020
         SPACE                                                          18640020
FAQVBIN  EQU   *                                                        18660020
         LA    R7,ONE                  SET SWITCH.                      18680020
         L     R3,WORKAREA             R3=ADDR OF WORKAREA.             18700020
         LH    R2,FOUR(R1)             R2=PACK COUNT.                   18720020
         BCTR  R2,ZERO                 *                                18740020
         L     R4,ZERO(R1)             R4=ADDR OF INPUT STRING.         18760020
         CLI   ZERO(R4),SIGNNEG        Q.VALUE NEGATIVE.                18780020
         BE    NEGATIVE                YES,FLIP SWITCH NEGATIVE.        18800020
         CLI   ZERO(R4),PLUSSIGN       Q.PLUS SIGN ENTERED.             18820020
         BNE   NOSIGN2                 NO,DO NOT ACCOUNT FOR SIGN.      18840020
SIGN     EQU   *                                                        18860020
         LA    R4,ONE(R4)              INCREASE ADDR TO BYPASS SIGN.    18880020
         BCTR  R2,ZERO                 R2=1 LESS BECAUSE OF SIGN.       18900020
         B     NOSIGN2                 SKIP COMPLEMENT CODE.            18920020
NEGATIVE EQU   *                                                        18940020
         LCR   R7,R7                   FLIP SWITCH NEGATIVE.            18960020
         B     SIGN                    ALTER LENGTH.                    18980020
NOSIGN2  EQU   *                                                        19000020
         O     R2,ORREG                R2=L1 AND L2.                    19020020
         EX    R2,PACK1                CONVERT STRING TO PACKED DEC.    19040020
         LTR   R7,R7                   VALUE NEGATIVE                   19060020
         BH    POSIT                   NO,SKIP COMPLEMENT.              19080020
         MVN   SEVEN(ONE,R3),NEGSIGN   MAKE SIGN NEGATIVE.              19100020
POSIT    EQU   *                                                        19120020
         CVB   R4,ZERO(R3)             CONVERT INPUT TO BINARY.         19140020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          19160020
         LA    R2,ONE(R2)              R2=BYPASS LENGTH FIELD.          19180020
         SR    R15,R15                 RETURN CODE=0.                   19200020
         LTR   R5,R5                   Q.H OR Y TYPE SPECIFIED.         19220020
         BNZ   HORY                    YES,MOVE ONLY HALFWORD.          19240020
         ST    R4,ZERO(R2)             MOVE VALUE INTO OUTPUT AREA.     19260020
         BCTR  R2,ZERO                 R2=ADDR OF LENGTH BYTE.          19280020
         MVI   ZERO(R2),FOUR           MOVE LENGTH INTO OUTPUT AREA.    19300020
         BR    R14                     RETURN.                          19320020
HORY     EQU   *                                                        19340020
         STH   R4,ZERO(R2)             MOVE VALUE INTO OUTPUT AREA.     19360020
         BCTR  R2,ZERO                 R2=ADDR OF LENGTH BYTE.          19380020
         MVI   ZERO(R2),TWO            LENGTH NOW IN OUTPUT AREA.       19400020
         BR    R14                     RETURN TO CALLER.                19420020
PACK1    PACK  ZERO(ONE,R3),ZERO(ONE,R4) INPUT NOW PACKED DECIMAL.      19440020
         SPACE                                                          19460020
**********************************************************************  19480020
*        THE FOLLOWING INSTRUCTIONS WILL CONVERT PRINTABLE CHARACTERS * 19500020
*        TO BINARY IN THE SCON FORMAT.                                * 19520020
*********************************************************************** 19540020
         SPACE                                                          19560020
SCONBIN  EQU   *                                                        19580020
         L     R6,WORKAREA             R6=ADDR OF WORKAREA.             19600020
         L     R3,ZERO(R1)             R3=ADDR OF INPUT STRING.         19620020
         LH    R2,FOUR(R1)             R2=LENGTH OF INPUT.              19640020
         BCTR  R2,ZERO                 R2=EXECUTE LENGTH.               19660020
         EX    R2,SCONMOVE             MOVE INPUT INTO WORKAREA.        19680020
         LR    R3,R6                   R3=ADDR OF WORKAREA.             19700020
FINDOPEN EQU   *                                                        19720020
         LA    R3,ONE(R3)              R3=ADDR OF NEXT BYTE.            19740020
         CLI   ZERO(R3),OPEN           Q.OPEN PARENTHESIS FOUND.        19760020
         BNE   FINDOPEN                NO,CHECK NEXT BYTE.              19780020
         LR    R7,R3                   R7=ADDR OF OPEN PARENTHESIS.     19800020
         SR    R7,R6                   R7=LENGHT OF DISP.               19820020
         CLI   TWO(R3),CLOSE           Q.CLOSE PARENTHESIS FOUND.       19840020
         BNE   PACKTWO                 NO,PACK TWO BYTES.               19860020
         PACK  EIGHT(EIGHT,R6),ONE(ONE,R3) REGISTER NOW PACK DATA.      19880020
BINREG   EQU   *                                                        19900020
         CVB   R5,EIGHT(R6)            REG NOW BINARY DATA.             19920020
         SLL   R5,ONE2                 REG IN HI ORDER OF SECOND BYTE.  19940020
         SPACE                                                          19960020
* THE FOLLOWING LINES OF CODE CONVERTS THE DISP TO BINARY             * 19980020
         SPACE                                                          20000020
         BCTR  R7,ZERO                 R7=EXECUTE LENGTH.               20020020
         LA    R8,OUTLEN               R8=OUTPUT LENGTH.                20040020
         OR    R7,R8                   R7=LENGTH1 AND LENGTH2.          20060020
         EX    R7,PACKDATA             PACK THE ZONE DISP DATA.         20080020
         CVB   R8,EIGHT(R6)            DISP NOW BINARY DATA.            20100020
         OR    R5,R8                   R5=SCON IN BINARY.               20120020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              20140020
         MVI   ZERO(R2),TWO            LENGTH NOW IN CONAREA.           20160020
         LA    R2,ONE(R2)              R2=ADDR ONE PASS CONAREA.        20180020
         STH   R5,ZERO(R2)             SCON IN CONAREA.                 20200020
         SR    R15,R15                 RC=0.                            20220020
         BR    R14                     RETURN.                          20240020
PACKTWO  EQU   *                                                        20260020
         PACK  EIGHT(EIGHT,R6),ONE(TWO,R3) REGISTER NOW PACK DATA.      20280020
         B     BINREG                  CONVERT REGISTER TO BINARY.      20300020
SCONMOVE MVC   ZERO(ONE,R6),ZERO(R3)   INPUT NOW IN WORKAREA.           20320020
PACKDATA PACK  EIGHT(ONE,R6),ZERO(ONE,R6) DISP NOW PACK DATA.           20340020
         SPACE                                                          20360020
*********************************************************************** 20380020
* THE FOLLOWING INSTRUCTIONS CONVERTS A VALUE FROM BINARY TO ITS      * 20400020
* PRINTABLE FORMAT.                                                   * 20420020
*********************************************************************** 20440020
         SPACE                                                          20460020
HYCODE   EQU   *                                                        20480020
         LA    R5,ONE                  R5=1,INDICATES H OR Y SPECIFIED. 20500020
         B     NOHORY                  GET TYPE CODE.                   20520020
FROMBI   EQU   *                                                        20540020
         SR    R5,R5                   R5=0. NOT H OR Y SWITCH.         20560020
         CLI   SEVEN(R1),HCODE         Q.H SPECIFIED.                   20580020
         BE    HYCODE                  YES,SET H OR Y SWITCH.           20600020
         CLI   SEVEN(R1),YCODE         Q.Y CODE SPECIFIED.              20620020
         BE    HYCODE                  YES,SET H OR Y SWITCH.           20640020
NOHORY   EQU   *                                                        20660020
         SR    R6,R6                   R6=0                             20680020
         IC    R6,SEVEN(R1)            R6=TYPE CODE IN HEX.             20700020
         L     R15,ACONLST2(R6)        R15=ADDRESS OF CVT RTN.          20720020
         BALR  R14,R15                 GOTO PROPER CVT RTN.             20740020
         USING ADDRBASE,R14            R14=TEMP BASE REGISTER.          20760020
ADDRBASE EQU   *                                                        20780020
         L     R12,CVTBASE             R12=ADDR OF IKJEGCVT.            20800020
         DROP  R14                     R14,NO LONGER BASE REGISTER.     20820020
         B     RETURN                  RETURN TO CALLER.                20840020
         SPACE                                                          20860020
BINPK    EQU   *                                                        20880020
         SPACE                                                          20900020
*********************************************************************** 20920020
*                                                                     * 20940020
*        THIS ROUTINE CONVERTS PACKED DECIMAL DATA TO PRINTABLE       * 20960020
*        CHARACTERS.                                                  * 20980020
*                                                                     * 21000020
*********************************************************************** 21020020
         SPACE                                                          21040020
         LA    R8,BADPK                R8=HEX -09-.                     21060020
         SR    R6,R6                   R6=0.                            21080020
         L     R3,ZERO(R1)             R3=ADDRESS OF INPUT STRING.      21100020
         LH    R4,FOUR(R1)             R4=LENGTH OF INPUT.              21120020
         LR    R5,R3                   R5=ADDRESS OF INPUT STRING.      21140020
         LR    R2,R4                   R2=LENGTH OF INPUT.              21160020
NEXTPK   EQU   *                                                        21180020
         BCT   R2,BYTECK               CHECK FOR VALID PK DATA.         21200020
         IC    R6,ZERO(R5)             R5=LAST BYTE.                    21220020
         SRDL  R6,FOUR                 RISOLATE HIGH ORDER 4 BITS.      21240020
         CLR   R6,R8                   Q.IS HITH ORDER 4 BITS VALID.    21260020
         BH    PKERROR                 NO,WRITE ERROR MESSAGE.          21280020
         SRL   R7,LOWORDER             LOW ORDER 4 BITS ISOLATED.       21300020
         CLR   R7,R8                   Q.LOW ORDER 4 BITS VALID.        21320020
         BNH   PKERROR                 NO,WRITE ERROR MESSAGE.          21340020
         B     SKIPPKCK                SKIP PACK VALIDITY CHECK.        21360020
BYTECK   EQU   *                                                        21380020
         IC    R6,ZERO(R5)             R6=BYTE OF PACKED DATA.          21400020
         SRDL  R6,FOUR                 ISOLATE HIGH ORDER 4 BITS.       21420020
         CLR   R6,R8                   Q.HIGH ORDER 4 BITS VALID.       21440020
         BH    PKERROR                 NO,WRITE ERROR MESSAGE.          21460020
         SRL   R7,LOWORDER             LOW ORDER 4 BITS ISOLATED.       21480020
         CLR   R7,R8                   Q.LOW ORDER 4 BITS VALID.        21500020
         BH    PKERROR                 NO,WRITE ERROR MESSAGE.          21520020
         LA    R5,ONE(R5)              R5=ADDR OF NEXT BYTE.            21540020
         B     NEXTPK                  GET NEXT BYTE.                   21560020
SKIPPKCK EQU   *                                                        21580020
         LA    R6,ZERO(R4,R3)          R6=ADDR OF LAST BYTE OF INPUT.   21600020
         BCTR  R6,ZERO                 *                                21620020
         L     R2,WORKAREA             R2=ADDRESS OF WORKAREA.          21640020
         LA    R5,ZERO(R4,R2)          R5=ADDRESS OF SIGN BYTE.         21660020
         BCTR  R5,ZERO                 *                                21680020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH.               21700020
         EX    R4,MOVEPK               MOVE INPUT INTO WORKAREA.        21720020
         LA    R4,ONE(R4)              R4=CORRECT LENGTH.               21740020
         OI    ZERO(R5),SIGNF          ALTER SIGN TO X'F'               21760020
         LA    R5,ONE(R4,R2)           R5=ADDRESS OF EDIT OUTPUT AREA.  21780020
         MVC   ZERO(THREE2,R5),PATTERN MOVE PATTERN INTO WORKAREA.      21800020
         SLL   R4,ONE                  R4=LENGTH TIMES 2.               21802020
         BCTR  R4,ZERO                 R4=LENGTH MINUS ONE.             21810020
         LR    R7,R4                   R7=NEW LENGTH.                   21812020
         BCTR  R7,ZERO                 R7=NEW LENGTH MINUS 1.           21880020
         LA    R1,ZERO(R5,R7)          R1=ADDR OF LAST BYTE OF OUTPUT.  21900020
         LR    R7,R1                   R7=ADDR OF LAST BYTE OF OUTPUT.  21920020
         EX    R4,ZONEPK               INPUT NOW ZONE DECIMAL.          21940020
         CLI   ZERO(R1),BLANK          Q.IS LAST CHARACTER A BLANK.     21960020
         BNE   NOBLANK                 NO,SKIP MOVE IN ZERO CODE.       21980020
         MVI   ZERO(R1),AZERO          MOVE IN A CHARACTER -0-.         22000020
NOBLANK  EQU   *                                                        22020020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              22040020
         TM    ZERO(R6),PLUSBIT        LOW ORDER BIT OF BYTE ON.        22060020
         BZ    ITSPLUS                 NO,THE STRING IS POSITIVE        22080020
         TM    ZERO(R6),PLUSBITS       Q.IS SIGN NEGATIVE.              22100020
         BO    ITSPLUS                 NO,IT MUST BE POSITIVE.          22120020
         BCTR  R1,ZERO                 R1=ADDR OF SIGN LOCATION.        22140020
         MVI   ZERO(R1),SIGNNEG        PUT SIGN IN OUTPUT AREA.         22160020
PUTOUT   EQU   *                                                        22180020
         LA    R7,ONE(R7)              R7=END OF ZONED DATA ADDR.       22200020
         SR    R7,R1                   R7=LENGTH OF ZONED DATA.         22220020
         EX    R7,MOVEOUT              MOVE OUTPUT INTO OUTPUT AREA.    22240020
         LA    R7,ONE(R7)              R4=LENGTH OF OUTPUT.             22260020
         STC   R7,ZERO(R2)             LENGTH OF OUTPUT NOW IN CONAREA. 22280020
         SR    R15,R15                 SET RETURN CODE TO 0.            22300020
         BR    R14                     RETURN                           22320020
ITSPLUS  EQU   *                                                        22340020
         BCTR  R1,ZERO                 R1=ADDR OF SIGN LOCATION.        22360020
         MVI   ZERO(R1),PLUSSIGN       PUT PLUS SIGN IN OUT PUT AREA.   22380020
         B     PUTOUT                  MOVE OUTPUT INTO CONAREA.        22400020
ZONEPK   EDMK  ZERO(ONE,R5),ZERO(R2)   STRING NOW PRINTABLE CHARACTERS. 22420020
MOVEPK   MVC   ZERO(ONE,R2),ZERO(R3)   MOVE INPUT INTO WORKAREA.        22440020
MOVEOUT  MVC   ONE(ONE,R2),ZERO(R1)    MOVE OUTPUT INTO OUTPUT AREA.    22460020
PKERROR  EQU   *                                                        22480020
         L     R3,MSG003               R3=ADDR OF MSG PARM LIST.        22500020
         B     ERRORPK                 WRITE ERROR MESSAGE.             22520020
BINAQVY  EQU   *                                                        22540020
         SPACE                                                          22560020
*********************************************************************** 22580020
*                                                                     * 22600020
*        THIS ROUTINE CONVERTS A,Q,V, AND Y TYPE CONSTANTS FROM       * 22620020
*        BINARY TO PRINTABLE CHARACTERS.  WHEN THE TYPE OS H OR Y,    * 22640020
*        REGISTER 5 MUST CONTAIN A VALUE GREATER THAN ZERO('0')       * 22660020
*        OTHERWISE REGISTER 5 WILL BE ZERO.                           * 22680020
*                                                                     * 22700020
*********************************************************************** 22720020
         SPACE                                                          22740020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           22760020
         LH    R4,FOUR(R1)             R4=LENGTH OF INPUT.              22780020
         L     R1,ZERO(R1)             R1=ADDRESS OF INPUT STRING.      22800020
         L     R10,WORKAREA            R10=ADDRESS OF WORKAREA.         22820020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH.               22840020
         EX    R4,AQVYMOVE             MOVE INPUT INTO WORKAREA.        22860020
         L     R1,ZERO(R10)            R1=INPUT STRING.                 22880020
         LA    R5,THREE                R5=3.                            22900020
         SR    R5,R4                   R5=LENGTH MINUS 3.               22920020
         M     R4,FULL8                R5=NUMBER OF BITS TO SHIFT.      22940020
         SRL   R1,ZERO(R5)             INPUT RIGHT JUSTIFIED.           22960020
         N     R1,MASKSIGN             TURN HIGH ORDER BIT OFF.         22980020
         CVD   R1,ZERO(R10)            STRING NOW PACK DECIMAL.         23000020
         OI    SEVEN(R10),SIGNF        ALTER SIGN TO HEX F.             23020020
         UNPK  EIGHT(ONE5,R10),ZERO(EIGHT,R10) ZONED DECIMAL DATA.      23040020
         LA    R1,TWO3(R10)            R1=END OF OUTPUT ADDR.           23060020
         LA    R5,ONE4                 R5=14.                           23080020
         LA    R10,EIGHT(R10)          R10=PTR TO OUTPUT DATA.          23100020
BUMP     CLI   ZERO(R10),AZERO         Q.VALID DATA FOUND.              23120020
         BNE   NOBUMP                  YES,COMPUTE LENGTH OF OUTPUT.    23140020
         LA    R10,ONE(R10)            BUMP PTR TO OUTPUT.              23160020
         BCT   R5,BUMP                 ALL OUTPUT TESTED FOR A ZERO.    23180020
NOBUMP   EQU   *                                                        23200020
         SR    R1,R10                  R1=LENGTH OF OUTPUT.             23220020
         STC   R1,ZERO(R2)             LENGTH NOW IN CONAREA.           23240020
         BCTR  R1,ZERO                 R1=EXECUTE LENGTH.               23260020
         EX    R1,MOVE2                OUTPUT NOW IN CONAREA.           23280020
         SR    R15,R15                 RC=0.                            23300020
         BR    R14                     RETURN TO CALLER.                23320020
MOVE2    MVC   ONE(ONE,R2),ZERO(R10)   MOVE OUTPUT TO CONAREA.          23340020
AQVYMOVE MVC   ZERO(ONE,R10),ZERO(R1)  INPUT NOW IN WORKAREA.           23360020
         SPACE                                                          23380020
BINFDEC  EQU   *                                                        23400020
         SPACE                                                          23420020
*********************************************************************** 23440020
*                                                                     * 23460020
*        THIS ROUTINE CONVERTS BINARY TO FIXED DECIMAL PRINTABLE.     * 23480020
*                                                                     * 23500020
*********************************************************************** 23520020
         SPACE                                                          23540020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          23560020
         SR    R8,R8                   INITIALIZE GT SWITCH.            23580020
         LH    R6,FOUR(R1)             R6=LENGTH OF INPUT STRING.       23600020
         L     R3,ZERO(R1)             R3=ADDR OF INPUT STRING.         23620020
         L     R4,WORKAREA             R4=ADDR OF WORKAREA.             23640020
         MVI   ONE(R2),PLUSSIGN        PUT PLUS SIGN INTO OUTPUT AREA.  23660020
         SPACE                                                          23680020
*        IS THE LENGTH OF THE BINARY VALUE GREATER THAN 4 BYTES.      * 23700020
         SPACE                                                          23720020
         CL    R6,FIXLEN               Q.LENGTH GT 4 BYTES.             23740020
         BH    GREATER                 YES,CONVERT FIRST 4 BYTES.       23760020
         SPACE                                                          23780020
*********************************************************************** 23800020
*                                                                     * 23820020
*        THIS SECTION CONVERT ONLY FOUR BYTES OF BINARY DIGITS TO     * 23840020
*        ITS PRINTABLE FORM.                                          * 23860020
*                                                                     * 23880020
*********************************************************************** 23900020
         SPACE                                                          23920020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               23940020
         EX    R6,MOVEIN               INPUT NOW IN WORKAREA.           23960020
         LA    R6,ONE(R6)              R6=CORRECT LENGTH.               23980020
         L     R1,ZERO(R4)             R1=INPUT STRING.                 24000020
         MVI   ONE(R2),PLUSSIGN        PUT PLUS SIGN INTO OUTPUT AREA.  24020020
REGALTER EQU   *                                                        24040020
         LA    R0,EIGHT                R0=EIGHT.                        24060020
         LA    R5,FOUR                 R5=4.                            24080020
         SR    R5,R6                   R5=4 MINUS LENGTH.               24100020
         LTR   R5,R5                   Q.IS LENGTH 4.                   24120020
         BZ    NOSRL                   YES,SKIP RIGHT JUSTIFY.          24140020
         MR    R4,R0                   R4=SHIFT FACTOR.                 24160020
         SRA   R1,ZERO(R5)             RIGHT JUSTIFY INPUT.             24180020
NOSRL    EQU   *                                                        24200020
         LTR   R1,R1                   Q.IS VALUE NON-NEGATIVE.         24220020
         BNM   NONNEG                  YES,SKIP COMPLEMENT ROUTINE.     24240020
         SPACE                                                          24250020
*        THIS AREA COMPLEMENTS THE NEGATIVE BINARY VALUE.             * 24260020
         SPACE                                                          24270020
         LCR   R1,R1                   R1,NOW POSITIVE FOR CONVERT.     24280020
         MVI   ONE(R2),SIGNNEG         MOVE IN NEG SIGN.                24300020
         SPACE                                                          24320020
NONNEG   EQU   *                                                        24340020
         L     R3,WORKAREA             R3=ADDRESS OF WORKAREA.          24360020
GREATEND EQU   *                                                        24380020
         CVD   R1,ZERO(R3)             STRING IS NOW PACKED DECIMAL.    24400020
         LTR   R8,R8                   Q.LENGTH GT 4 BYTES.             24420020
         BZ    SKIP1                   NO,SKIP ADD ROUTINE              24440020
         SPACE                                                          24460020
*********************************************************************** 24480020
*                                                                     * 24500020
*        THIS SECTION ADDS THE REMAINDER OF THE INPUT STRING          * 24520020
*        (PACKED DECIMAL) TO THE ALREADY COMPUTED PACKED BYTES        * 24540020
*        OF THE STRING AND CONVERTS THE STRING TO ZONED DECIMAL.      * 24560020
*                                                                     * 24580020
*********************************************************************** 24600020
         SPACE                                                          24620020
         LTR   R7,R7                   Q.IS ADD ONE SWITCH ON.          24640020
         BZ    NOTON                   NO,DO NOT ADD ONE.               24660020
         AP    PACKANS(TEN,R3),PACKONE YES,ADD ONE.                     24680020
NOTON    EQU   *                                                        24700020
         AP    PACKANS(TEN,R3),ZERO(EIGHT,R3) ADD 2ND WORD TO 1ST WORD. 24720020
         MVN   PACKSIGN(ONE,R3),MASKSIGN   SET SIGN BITS TO HEX F.      24740020
         MVC   WORK3(TWO0,R3),PATTERN  PUT PATTERN INTO WORKAREA.       24760020
         MVI   FDECSTAR(R3),STARTER    STARTER CHAR NOW IN WORKAREA.    24780020
         LA    R1,FDECSTAR+ONE(R3)     R1=ADDR OF LAST BYTE.            24800020
         EDMK  WORK3(TWO0,R3),PACKANS(R3)  BLANK OUT LEADING ZEROS.     24820020
         LA    R4,FIXED(R3)            R4=END OF ZONED DATA.            24840020
         SR    R4,R1                   R4=NUMBER OF OUTPUT DIGITS.      24860020
         STC   R4,ZERO(R2)             LENGTH NOW IN OUTPUT AREA.       24880020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH                24900020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH.               24920020
         LR    R3,R1                   R3=ADDR OF SIGNIFICANCE BYTES.   24940020
         EX    R4,MOVE                 MOVE OUTPUT INTO CONAREA.        24960020
         SR    R15,R15                 R15=RC 0.                        24980020
         BR    R14                     RETURN                           25000020
         SPACE                                                          25020020
SKIP1    EQU   *                                                        25040020
         SPACE                                                          25060020
*********************************************************************** 25080020
*                                                                     * 25100020
*        THIS SECTION OF CODE CONVERTS FROM PACKED DECIMAL TO         * 25120020
*        ZONED THE INPUT WITH A LENGTH OF FOUR OR LESS.               * 25140020
*                                                                     * 25160020
*********************************************************************** 25180020
         SPACE                                                          25200020
         LA    R1,NOFZONE-TWO(R3)      R1=ADDR FOR STARTER CHAR.        25220020
         MVC   WORK5(ONE7,R3),PATTERN  PUT PATTERN INTO WORKAREA.       25240020
         MVI   ZERO(R1),STARTER        STARTER CHAR NOW IN PATTERN.     25260020
         LA    R1,ONE(R1)              R1=ADDR OF LAST BYTE.            25280020
         EDMK  WORK5(ONE6,R3),ZERO(R3) INPUT NOW ZONED DECIMAL.         25300020
NOF0MOVE EQU   *                                                        25320020
         LR    R0,R3                   R0=ADDR OF WORKAREA.             25340020
         LR    R3,R1                   R3=ADDRESS OF ZONED DECIMAL.     25360020
         LA    R6,NOFZONE              R6=END OF ZONE DECIMAL.          25380020
         AR    R6,R0                   R6=END OF OUTPUT.                25400020
         SR    R6,R1                   R6=LENGTH OF OUTPUT.             25420020
         EX    R6,MOVE                 MOVE OUTPUT INTO CONAREA.        25440020
         LA    R6,ONE(R6)              R6=LENGTH OF OUTPUT.             25460020
         STC   R6,ZERO(R2)             MOVE LENGTH INTO CONAREA.        25480020
         SR    R15,R15                 R15=RC 0.                        25500020
         BR    R14                     RETURN                           25520020
GREATER  EQU   *                                                        25540020
         SPACE                                                          25560020
*********************************************************************** 25580020
*                                                                     * 25600020
*        THIA AREA OF CODE CONVERTS A BINARY VALUE TO PACKED DECIMAL  * 25620020
*        WHOSE LENGTH IS GREATER THAN FOUR BYTES.  ONLY THE HIGH      * 25640020
*        ORDER FOUR BYTES ARE PACKED.                                 * 25660020
*                                                                     * 25680020
*********************************************************************** 25700020
         SPACE                                                          25720020
         XC    ZERO(EIGHT,R4),ZERO(R4) INPUT AREA NOW CLEARED.          25740020
         SR    R7,R7                   R7=0.                            25760020
         LA    R1,SEVEN                R2=7.                            25780020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               25800020
         SR    R1,R6                   R2=NUMBER OF LEADING ZEROES.     25820020
         LA    R4,ZERO(R1,R4)          NEW ADDR OF WORKAREA.            25840020
         EX    R6,MOVEIN               MOVE INPUT INTO WORKAREA.        25860020
         L     R3,WORKAREA             R3=ADDR OF WORKAREA.             25880020
         TM    ZERO(R4),VALCK          Q.IS INPUT NEGATIVE.             25900020
         BZ    NOTNEG                  NO,DO NOT COMPLEMENT.            25920020
         MVI   ONE(R2),SIGNNEG         MOVE IN NEG SIGN.                25940020
         MVI   EIGHT(R4),NEGBYTE       SET AN AREA                      25960020
         MVC   NINE(SEVEN,R4),EIGHT(R4)            TO 2 WORDS OF ONES.  25980020
         XC    EIGHT(EIGHT,R3),ZERO(R3) FLIP BITS POSITIVE.             26000020
         LA    R3,EIGHT(R3)            R3=ADDR OF INPUT.                26020020
         LA    R7,ONE                  R7=1,INDICATE NEG & GT 4 BYTES.  26040020
NOTNEG   EQU   *                                                        26060020
         SPACE                                                          26080020
*********************************************************************** 26100020
*                                                                     * 26120020
*        THE FOLLOWING CODE CALCULATES THE VALUE OF THE HIGH ORDER    * 26140020
*        BYTES OF THE INPUT STRING THAT EXCEEDS FOUR BYTES.           * 26160020
*                                                                     * 26180020
*********************************************************************** 26200020
         SPACE                                                          26220020
         L     R4,WORKAREA             R4=ADDR OF WORKAREA.             26240020
         L     R5,ZERO(R3)             R5=INPUT STRING.                 26260020
         LA    R2,ONE                  R2=1.                            26280020
         MVC   PACKWORK(TEN,R4),PACKVAL INITIAL VALUE IN PACK WORKAREA. 26300020
         XC    PACKANS(TEN,R4),PACKANS(R4) ZERO OUT PACK ANSWER PLACE.  26320020
         LA    R6,FIXCOUNT             R6=31,LOOP COUNT.                26340020
         LR    R1,R2                   R1=1.                            26360020
         OI     SIGNIT(R4),SIGNF       PACK SIGN NOW X'F'.              26380020
NEXTBIT  EQU   *                                                        26400020
         NR    R2,R5                   SET UP TEST REGISTER.            26420020
         BZ    NOTON2                  NO,JUST ADVANCE PACK VALUE.      26440020
         AP    PACKANS(TEN,R4),PACKWORK(TEN,R4) COMPUTE PACK VALUE.     26460020
NOTON2   EQU   *                                                        26480020
         AP    PACKWORK(TEN,R4),PACKWORK(TEN,R4) UPDATE PACK VALUE.     26500020
         AR    R1,R1                   UPDATE BIT INDICATOR.            26520020
         LR    R2,R1                   R2=BIT INDICATOR.                26540020
         BCT   R6,NEXTBIT              IF MORE BITS TEST NEXT ONE.      26560020
         SPACE                                                          26580020
*********************************************************************** 26600020
*                                                                     * 26620020
*        THE FOLLOWING CODE CHECK THE HIGH ORDER BIT OF THE SECOND    * 26640020
*        WORD OF THE INPUT STRING TO DETERMINE IF IT IS ON. IF IT IS  * 26660020
*        ON IT WILL BE TURNED OFF AND THE VALUE OF IT WILL BE ADDED   * 26680020
*        TO THE FINAL VALUE. NO PROCESSING WILL BE DONE TO REFLECT    * 26700020
*        THE BIT BEINGING OFF.                                        * 26720020
*                                                                     * 26740020
*********************************************************************** 26760020
         SPACE                                                          26780020
BITCK    EQU   *                                                        26800020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          26820020
         LA    R8,ONE                  SET GT SWITCH = GT 4 BYTES.      26840020
         L     R1,FOUR(R3)             R1=2ND WORK OF INPUT STRING.     26860020
         TM    FOUR(R3),HION           Q.HI ORDER BIT ON.               26880020
         BNO   NONNEG                  NO, BIT IS OFF.                  26900020
         SLL   R1,ONE                  DROP HI ORDER BIT.               26920020
         SRL   R1,ONE                  ISOLATE REMAINDER OF BITS.       26940020
         AP    PACKANS(TEN,R4),LASTPACK  COMPUTE PACKED VALUE.          26960020
         B     NONNEG                  CONTINUE PROCESSING.             26980020
MOVE     MVC   TWO(ONE,R2),ZERO(R3)    MOVE OUTPUT INTO CONAREA.        27000020
MOVEIN   MVC   ZERO(ONE,R4),ZERO(R3)   MOVE INPUT INTO WORKAREA.        27020020
MOVEZERO MVC   EIGHT(ONE,R3),ZERO(R3)  MOVE ZEROS INTO WORKAREA.        27040020
BINHEX   EQU   *                                                        27060020
         SPACE                                                          27080020
*********************************************************************** 27100020
* THIS ROUTINE CONVERTS BINARY TO PRINTABLE HEXADECIMAL.              * 27120020
*********************************************************************** 27140020
         SPACE                                                          27160020
         L     R3,WORKAREA             R3=ADDRESS OF WORKAREA.          27180020
         LR    R4,R3                   R4=ADDRESS OF WORKAREA.          27190020
         L     R2,CONAREA              R2=OUTPUT AREA ADDRESS.          27200020
         LA    R2,ONE(R2)              ADVANCE PASS LENGTH AREA.        27220020
         LH    R10,FOUR(R1)            R10=LENGTH OF INPUT.             27240020
         BCTR  R10,ZERO                R10=EXECUTE LENGTH.              27260020
         L     R1,ZERO(R1)             R1=ADDRESS OF INPUT STRING.      27300020
         EX    R10,BHMOVE              MOVE INPUT TO EVEN BOUNDARY.     27320020
         LA    R10,ONE(R10)            R10=ACTUAL LENGTH OF INPUT.      27340020
         SLL   R10,ONE                 R10=LENGTH OF OUTPUT.            27360020
         SR    R1,R1                   CLEAR LENGTH COUNTER.            27370020
NEXTWORD EQU   *                                                        27380020
         L     R7,ZERO(R4)             GET A WORD OF INPUT.             27400020
         SR    R5,R5                   CLEAR COUNTER.                   27420020
MOREBITS EQU   *                                                        27440020
         SR    R6,R6                   CLEAR WORK REGISTER.             27460020
         SLDL  R6,FOUR                 MOVE J BITS INTO WORK REG.       27480020
         CL    R6,FULLNINE             Q.BITS GT 9.                     27500020
         BH    GREAT                   YES,CONVERT TO ALPHABETIC.       27520020
         LA    R6,F0(R6)               CONVERT TO HEX VALUE.            27540020
NEXT     EQU   *                                                        27560020
         STC   R6,ZERO(R2)             MOVE TO CONAREA.                 27580020
         LA    R2,ONE(R2)              INCREMENT CONAREA POINTER.       27600020
         LA    R5,ONE(R5)              INCREMENT INPUT COUNTER.         27620020
         LA    R1,ONE(R1)              INCREMENT LENGTH COUNTER.        27640020
         BCT   R10,BHEXGO              Q.MORE INPUT.                    27660020
BHEXEND  EQU   *                                                        27680020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       27700020
         STC   R1,ZERO(R2)             PUT LENGTH INTO  CONAGRA.        27720020
         SR    R15,R15                 RC=0.                            27740020
         BR  R14                       RETURN TO CALLER.                27760020
BHEXGO   EQU   *                                                        27780020
         CL    R5,FULL8                Q.ANOTHER WORD NEEDED.           27800020
         BE    ADVANCE                 YES,INCREMENT R4 4 BYTES.        27820020
         B     MOREBITS                GET NEXT 4 BITS.                 27840020
ADVANCE  EQU   *                                                        27860020
         LA    R4,FOUR(R4)             R4=NEXT FOUR BYTES ADDRESS.      27880020
         B     NEXTWORD                GET NEW WORD.                    27900020
GREAT    EQU   *                                                        27920020
         LA    R6,B7(R6)               CONVERT TO HEX VALUE.            27940020
         B     NEXT                    MOVE BYTE TO CONAREA.            27960020
BHMOVE   MVC   ZERO(ONE,R4),ZERO(R1)   MOVE INPUT TO EVEN BOUNDARY.     27980020
R0       EQU   0                       ******************************** 28000020
R1       EQU   1                       *                              * 28020020
R2       EQU   2                       *        REGISTERS             * 28040020
R3       EQU   3                       *                              * 28060020
R4       EQU   4                       *         EQUATES              * 28080020
R5       EQU   5                       *                              * 28100020
R6       EQU   6                       *                              * 28120020
R7       EQU   7                       *                              * 28140020
R8       EQU   8                       *                              * 28160020
R9       EQU   9                       *         REGISTERS            * 28180020
R10      EQU   10                      *                              * 28200020
R11      EQU   11                      *         EQUATES              * 28220020
R12      EQU   12                      *                              * 28240020
R13      EQU   13                      *                              * 28260020
R14      EQU   14                      *                              * 28280020
R15      EQU   15                      ******************************** 28300020
BASEDISP EQU   2                                                        28320020
EXPPLUS  EQU   C'+'                                                     28340020
B7       EQU   X'B7'                   FOR ALPHABETIC CONVERSION        28360020
F0       EQU   X'F0'                   FOR NUMERIC CONVERSIONS          28380020
ZERO     EQU   0                                                        28400020
ONE      EQU   1                                                        28420020
TWO      EQU   2                                                        28440020
THREE    EQU   3                                                        28460020
FOUR     EQU   4                                                        28480020
FIVE     EQU   5                                                        28500020
SIX      EQU   6                                                        28520020
SEVEN    EQU   7                                                        28540020
EIGHT    EQU   8                                                        28560020
NINE     EQU   9                                                        28580020
TEN      EQU   10                                                       28600020
ONE2     EQU   12                                                       28620020
HEXFF    EQU   X'FF'                                                    28640020
HEX00    EQU   X'00'                                                    28660020
HEX40    EQU   X'40'                                                    28680020
HEX80    EQU   X'80'                                                    28700020
HEXC0    EQU   X'C0'                                                    28720020
HEXF0    EQU   X'F0'                                                    28740020
HEX04    EQU   X'04'                                                    28760020
HEX0F    EQU   X'0F'                                                    28780020
HEX08    EQU   X'08'                                                    28800020
HEX18    EQU   X'18'                                                    28820020
HEX01    EQU   X'01'                                                    28830020
HEX02    EQU   X'02'                                                    28832020
HEX03    EQU   X'03'                                                    28834020
HEX05    EQU   X'05'                                                    28836020
EXP      EQU   X'FF'                                                    28840020
ONE3     EQU   13                                                       28860020
ONE1     EQU   11                                                       28880020
ONE4     EQU   14                                                       28900020
ONE5     EQU   15                                                       28920020
ONE6     EQU   16                                                       28940020
ONE9     EQU   19                                                       28960020
TWO1     EQU   21                                                       28980020
TWO4     EQU   24                                                       29000020
EXPIND   EQU   10                                                       29020020
TWO2     EQU   22                                                       29040020
TWO3     EQU   23                                                       29060020
TWO6     EQU   26                                                       29080020
ONE7     EQU   17                                                       29100020
NOFZONE  EQU   34                                                       29120020
TWO7     EQU   27                                                       29140020
TWO8     EQU   28                                                       29160020
THREE1   EQU   31                                                       29180020
THREE2   EQU   32                                                       29200020
THREE6   EQU   36                                                       29220020
FORTY    EQU   40                                                       29230020
CLEAR    EQU  X'00'                                                     29240020
VALLEN   EQU   5                                                        29260020
STARTER  EQU   X'21'                                                    29280020
LENGTH   EQU   21                      OFFSET INTO PDE FOR SYM LEN.     29300020
LENSYM   EQU   8                       MAXIMUM LEN FOR SYMBLES.         29320020
PACKSIGN EQU   25                                                       29340020
OUTLEN   EQU   X'70'                                                    29360020
MASKVAL  EQU   X'7F'                                                    29380020
WORK2    EQU   16                                                       29400020
WORK3    EQU   26                                                       29420020
FIXED    EQU   47                      OFFSET TO END OF ZONED DATA.     29440020
WORK4    EQU   8                                                        29460020
WORK5    EQU   18                                                       29480020
FDECSTAR EQU   44                                                       29500020
OPTAB4   EQU   4                                                        29520020
NEGBYTE  EQU   X'FF'                                                    29540020
SIGNNEG  EQU   C'-'                                                     29560020
PLUSSIGN EQU   C'+'                                                     29580020
BLANK    EQU   C' '                                                     29600020
HION     EQU   X'80'                                                    29620020
AZERO    EQU   C'0'                                                     29640020
PLUS     EQU   C'+'                                                     29660020
MINUS    EQU   C'-'                                                     29680020
OPSSVAL  EQU   X'20'                                                    29700020
NXTPDE   EQU   20                                                       29720020
USERWD   EQU   16                                                       29740020
OPRRVAL  EQU   X'04'                                                    29780020
OPSIVAL  EQU   X'1C'                                                    29800020
OPRSVAL  EQU   X'0C'                                                    29820020
CLOSE    EQU   C')'                                                     29840020
OPEN     EQU   C'('                                                     29860020
COMMA    EQU   C','                                                     29880020
PERIOD   EQU   C'.'                                                     29900020
LEN7     EQU   X'07'                                                    29920020
LEN4     EQU   X'04'                                                    29940020
ABTMASK  EQU   X'FF'                                                    29960020
SYMMASK  EQU   X'80'                                                    29980020
RELMASK  EQU   X'40'                                                    30000020
GENMASK  EQU   X'20'                                                    30020020
DOBMASK  EQU   X'10'                                                    30040020
SINMASK  EQU   X'08'                                                    30060020
FLAGS4   EQU   24                                                       30080020
INDIRECT EQU   X'00'                                                    30100020
INDVAL   EQU   26                                                       30120020
BADPK    EQU   X'09'                                                    30140020
LOWORDER EQU   28                                                       30160020
TCBGRS   EQU   32                                                       30180020
RS1R     EQU   X'10'                                                    30200020
MAXCORE  EQU   180                                                      30220020
TWO0     EQU   20                                                       30240020
SYMINFO  EQU   32                                                       30260020
ENTRYFLG EQU   14                                                       30280020
FLAGS3   EQU   22                                                       30300020
SYMCK    EQU   X'80'                                                    30320020
SYMLEN   EQU   16                                                       30340020
SYMOFF   EQU   X'00'                                                    30360020
VALCK    EQU   X'80'                                                    30380020
SIGNF    EQU   X'0F'                                                    30400020
RSIGN    EQU   C'R'                                                     30420020
PLUSBIT  EQU   X'01'                                                    30440020
PLUSBITS EQU   X'0F'                                                    30460020
ODDLEN   EQU   X'01'                                                    30480020
INNAME   EQU   X'04'                                                    30500020
HCODE    EQU   X'14'                                                    30520020
HEX      EQU   X'02'                                                    30540020
F1       EQU   X'01'                                                    30560020
STCTLM   EQU   X'B6'                   OP CODE FOR STCTL.               30570020
SIOFOP   EQU   X'9C'                   OP CODE FOR SIO AND SIOF.        30572020
SRPOP    EQU   X'F0'                   OP CODE FOR SRP.                 30574020
B2       EQU   X'B2'                   FIRST BYTES FOR 370 2 BYTE       30576020
*                                      OP CODES.                        30578020
CHARS    EQU   C'S'                                                     30578420
CHARF    EQU   C'F'                                                     30578820
PDESAVE  EQU   60                      OFFSET INTO WORKAREA OF PDE ADDR 30580020
YCODE    EQU   X'24'                                                    30600020
FIXCOUNT EQU   31                      LOOP COUNT FOR FIXDEC.           30620020
FEXPPDE  EQU   16                                                       30640020
SIGNIT   EQU   25                      LOC OF SIGN BYTE OF PACK DATA.   30660020
ADDRLEN  EQU   20                                                       30680020
PKLEN    EQU   X'70'                                                    30700020
INPUTADD EQU   16                                                       30720020
REGIN    EQU   3                                                        30740020
TWO5     EQU   25                                                       30760020
RDSIGN   EQU   C'D'                                                     30780020
RESIGN   EQU   C'E'                                                     30800020
PACKANS  EQU   16                      ANSWER PLACE OFFSET FOR PACK.    30820020
PACKWORK EQU   26                      OFFSET FOR UPDATED PACK VALUE.   30840020
FIXLEN   DC    F'4'                    FULL WORD 4.                     30860020
FULLNINE DC    F'9'                    FULL WORD 9.                     30880020
FULL8    DC    F'8'                    FULL WORD 8.                     30900020
MASKSIGN DC    X'7FFFFFFF'             USED TO TURN OFF HIGH ORDER BIT. 30920020
PACKONE  DC    PL10'1'                 PACKED DECIMAL 1.                30940020
ZEROS    DC    X'0000'                 HALFWORD OF DECIMAL ZEROES.      30960020
OFFSETC  DC    X'FC'                   NUMERIC C FOR PACK SIGN.         30980020
OFFSETD  DC    X'FD'                   NUMERIC D FOR PACK SIGN.         31000020
PATTERN  DC    X'40'                   PATTERN FIELD FOR THE EDIT       31020020
         DC    31X'20'                 AND MARK INSTRUCTION.            31040020
NEGSIGN  DC    P'-1'                   PACKED DECIMAL -1.               31060020
         DS    0F                                                       31080020
ORREG    DC    X'00000070'             OUTPUT LENGTH FOR EXECUTE.       31100020
COMPFLD  DC    X'FFFFFFFF'             FULL WORD OF ONES.               31120020
         DS    0X                                                       31140020
PACKVAL  DC    PL10'4294967296'        PACK DECIMAL VALUE FOR FIXDEC.   31160020
LASTPACK DC    PL10'2147483648'        *                                31180020
BKPLUS   DC    C' +'                   MSG PLUS SIGN.                   31200020
SMTSYM2  DC    C'SYM'                  CONSTANT NAME FOR BLDL           31203020
*                                       SMT TESTCASE LABEL              31206020
*                                       LINK TO SYM FAILED              31209020
*                                       TESTCASE ID  TTSTC120           31212020
*                                       TESTCASE ID  TEQU5300           31215020
         DS     0F                                                      31220020
MSG001   DC    V(IKJEGM01)             ADDR OF LENGTH EXCEEDS EIGHT.    31240020
MSG002   DC    V(IKJEGM02)             ADDR OF OUTCORE MSG PARM.        31260020
MSG003   DC    V(IKJEGM03)             ADDR OF PACK DATA MSG PARM.      31280020
MSG004   DC    V(IKJEG1IA)             ADDR OF INVALID ADDR MSG.        31300020
LINKLST  LINK  SF=L                    LIST FORM OF LINK.               31310020
LINKLSTL EQU   *-LINKLST               LENGTH OF LIST FORM OF LINK.     31312020
         TITLE 'IKJEGCVT CONVERT BRANCH TABLE.'                         31320020
*********************************************************************** 31340020
* THE FOLLOWING LIST OF ADCONS AND VCONS ROUTES CONTROL TO THE PROPER * 31360020
* PRINTABLE TO BINARY CONVERSION ROUTINE.  THE VCONS ROUTE CONTROL TO * 31380020
* THE 2ND CSECT OF CONVERT WHICH CONTAINS THE INSTRUCTION AND FLOATING* 31400020
* POINT CONVERSIONS.                                                  * 31420020
*********************************************************************** 31440020
         SPACE                                                          31460020
ACONLST  EQU   *                                                        31480020
         DC    A(RETURN)               CODE X'00' FOR CHAR.             31500020
         DC    A(HEXBIN)               CODE X'04' FOR HEX.              31520020
         DC    A(BINBIN)               CODE X'08' FOR BINARY.           31540020
         DC    A(RETURN)               CODE X'0C' FOR INST FROM BIN.    31560020
         DC    A(FAQVBIN)              CODE X'10' FOR FULLWORD FIXED PT 31580020
         DC    A(FAQVBIN)              CODE X'14' FOR HALFWORD FIXED PT 31600020
         DC    V(IKJEGFTB)             CODE X'18' FOR SHORT FLT PT.     31620020
         DC    V(IKJEGFTB)             CODE X'1C' FOR LONG FLT PT.      31640020
         DC    A(FAQVBIN)              CODE X'20' FOR A AND Q ADDRESS.  31660020
         DC    A(FAQVBIN)              CODE X'24' FOR Y ADDR CONSTANTS. 31680020
         DC    A(SCONBIN)              CODE X'28' FOR S ADDR CONSTANTS. 31700020
         DC    A(FAQVBIN)              CODE X'2C' FOR V ADDR CONSTANTS. 31720020
         DC    A(PKBIN)                CODE X'30' FOR PACKED DECIMAL.   31740020
         DC    A(RETURN)               CODE X'34' FOR ZONED DECIMAL.    31760020
         DC    A(RETURN)               CODE X'38' FOR EXTENDED FLT PT.  31780020
         SPACE                                                          31800020
*********************************************************************** 31820020
* THE FOLLOWING LIST OF ADCONS AND VCONS ROUTES CONTROL TO THE PROPER * 31840020
* BINARY TO PRINTABLE CONVERSION ROUTINE.  THE VCONS ROUTES CONTROL TO* 31860020
* THE 2ND CSECT OF CONVERT WHICH CONTAINS THE INSTRUCTION AND FLOATING* 31880020
* POINT CONVERSIONS.                                                  * 31900020
*********************************************************************** 31920020
         SPACE                                                          31940020
ACONLST2 EQU   *                                                        31960020
         DC    A(RETURN)               CODE X'00' FOR CHAR.             31980020
         DC    A(BINHEX)               CODE X'04' FOR HEXADECIMAL.      32000020
         DC    A(RETURN)               CODE X'08' FOR BINARY.           32020020
         DC    V(IKJEGIST)             CODE X'0C' FOR INSTRUCTION.      32040020
         DC    A(BINFDEC)              CODE X'10' FOR FULLWORD FIXED PT 32060020
         DC    A(BINFDEC)              CODE X'14' FOR HALFWORD FIXED PT 32080020
         DC    V(IKJEGBFT)             CODE X'18' FOR SHORT FLT PT.     32100020
         DC    V(IKJEGBFT)             CODE X'1C' FOR LONG FLT PT.      32120020
         DC    A(BINAQVY)              CODE X'20' FOR A AND Q ADDRESS.  32140020
         DC    A(BINAQVY)              CODE X'24' FOR Y ADDR CONSTANTS. 32160020
         DC    V(IKJEGBIS)             CODE X'28' FOR S ADDR CONSTANTS. 32180020
         DC    A(BINAQVY)              CODE X'2C' FOR V ADDR CONSTANTS. 32200020
         DC    A(BINPK)                CODE X'30' FOR V ADDR CONSTANTS. 32220020
         DC    A(RETURN)               CODE X'34' FOR ZONED DECIMAL.    32240020
         DC    A(RETURN)               CODE X'38' FOR EXTENDED FLT PT.  32260020
CVTBASE  DC    A(CVTBEGIN)             ADDR OF IKJEGCVT.                32280020
         TITLE 'IKJEGCVT PDE DSECT.'                                    32282020
         IKJPARMA                                                       32290020
         TITLE 'IKJEGCVT TEST COMMUNICATION TABLE.'                     32300020
         TCOMTAB                                                        32320020
         TITLE 'IKJEGCVT INSTRUCTION CONVERSION ROUTINE.'               32340020
IKJEGCVX   CSECT                                                        32360020
         SPACE                                                          32380020
*********************************************************************** 32400020
*                                                                     * 32420020
* THIS CSECT IS AN EXTENTION OF THE CONVERT ROUTINE.  THE INSTRUCTION * 32440020
* CONVERSIONS FROM BINARY TO PRINTABLE CHARACTERS ARE FOUND IN THIS   * 32460020
* CSECT.                                                              * 32480020
*                                                                     * 32500020
*********************************************************************** 32520020
         SPACE                                                          32540020
         ENTRY IKJEGIST                                                 32560020
         ENTRY IKJEGBIS                                                 32580020
         SPACE                                                          32600020
*********************************************************************** 32620020
* THE FOLLOWING INSTRUCTIONS CONVERT AN INSTRUCTION IN STORAGE FROM   * 32640020
* ITS BINARY VALUE TO ITS PRINTABLE FORMAT.  A VALIDITY CHECK  IS     * 32660020
* TAKEN TO DETERMINE IF THE OP CODE IS VALID.  IF THE OP CODE IS IN-  * 32680020
* VALID AN ERROR MESSAGE IS PRINTED DESCRIBING THE CONDITION.         * 32700020
*********************************************************************** 32720020
         SPACE                                                          32740020
IKJEGIST EQU   *                                                        32760020
         LR    R12,R15                 R12=ADDRESS OF IKJEGCVX.         32780020
         USING IKJEGCVX,R12            IKJEGCVX ADDRESSABILITY.         32800020
         USING TCOMTAB,R9              TCOMTAB ADDRESSABILITY.          32820020
         L     R3,ZERO(R1)             R3=PT TO THE INPUT STRING.       32840020
         SR    R5,R5                   R5=ZERO.                         32860020
         L     R7,WORKAREA             R7=ADRESS OF WORKAREA.           32862020
         USING CVTWORK,R7              USE R7 TO ADDRESS WORKAREA.      32864020
         MVI   CODE370,HEX00           CLEAR 370 FLAG INITIALLY.        32870020
         CLI   ZERO(R3),STCTLM         Q.IS OP CODE STCTL-5 CHARS.      32872020
         BNE   NOTCTL                  NO,CHECK FOR 2 BYTE OP CODE.     32874020
         OI    CODE370,CHAR5           YES,TURN ON 5 CHAR FLAG.         32876020
NOTCTL   EQU   *                                                        32878020
         CLI   ZERO(R3),B2             Q.IS OP CODE TWO BYTES.          32878420
         BNE   ONEBYTOP                NO,GET OP CODE.                  32878820
         CLI   ONE(R3),HEX05           YES,Q.IS 2 BYTE CODE VALID.      32879220
         BH    NOOPCODE                NO,ERROR MESSAGE.                32879620
         OI    CODE370,B2FLAG          YES,VALID. TURN ON 2 BYTE FLAG.  32879720
         IC    R5,ONE(R3)              R5=SECOND OP CODE BYTE.          32879820
         CLI   ONE(R3),HEX02           Q.IS OP CODE STIDP-5 CHARS.      32879920
         BNE   CHECKDC                 NO,CHECK FOR STIDC.              32886620
SET5FLG  EQU   *                                                        32888620
         OI    CODE370,CHAR5           YES,TURN ON 5 CHAR FLAG.         32889020
         B     COMMONOP                GET INDEX FACTOR TO TABLE.       32890620
CHECKDC  EQU   *                                                        32892620
         CLI   ONE(R3),HEX03           Q.IS OP CODE STIDC-5 CHARS       32893020
         BNE   COMMONOP                NO,GET INDEX FACTOR TO TABLE.    32893120
         B     SET5FLG                 YES,SET 5 CHAR FLAG ON.          32893220
ONEBYTOP EQU   *                                                        32899920
         IC    R5,ZERO(R3)             R5=THE OP CODE IN BINARY.        32906620
COMMONOP EQU   *                                                        32908620
         LA    R2,FIVE                 R2=HEX 5.                        32913320
         MR    R4,R2                   R5=INDEX FACTOR TO GET MNEMONIC. 32920020
         L     R2,CONAREA              R2=ADDRESS OF THE OUTPUT AREA.   32940020
         L     R6,OPCODTAB             R6=ADDR OF OPCODETAB.            32960020
         TM    CODE370,B2FLAG          Q.IS OP CODE 2 BYTES.            32970020
         BNO   ADDROP                  NO,LEAVE ADDR OF TABLE ALONE.    32972020
         XR    R15,R15                 YES,CLEAR OUT R15.               32974020
         LA    R15,OPTABLN             R15=DISPLACEMENT TO 2 BYTE TAB.  32974420
         AR    R6,R15                  R6=ADDR OF 2 BYTE OP TABLE.      32974820
ADDROP   EQU   *                                                        32976020
         LA    R6,ZERO(R5,R6)          R6=ADDRESS OF OPCODE.            32980020
         TM    CODE370,CHAR5           Q.IS MNEUMONIC 5 CHARS.          32990020
         BNO   MOVEMNEU                NO,MOVE 4 CHARS FROM TABLE.      32992020
         MVI   ONE(R2),CHARS           YES,MOVE IN FIRST S CHAR.        32994020
         LA    R2,ONE(R2)              R2=ADDR OF 4 BYTES LEFT.         32996020
MOVEMNEU EQU   *                                                        32998020
         MVC   ONE(FOUR,R2),ZERO(R6)   PRINTABLE OP CODE IN CONAREA.    33000020
         CLI   ZERO(R3),SIOFOP         Q.IS OP CODE SIOF.               33010020
         BNE   MVBLANK                 NO,MOVE BLANK PAST MNEUMONIC.    33012020
         TM    ONE(R3),HEX01           YES.Q.IS OP CODE SIOF.           33014020
         BNO   MVBLANK                 NOT SIOF. MOVE BLANK.            33016020
         MVI   FOUR(R2),CHARF          IS SIOF. ADD F TO MNEUMONIC.     33018020
MVBLANK  EQU   *                                                        33018420
         MVI   FIVE(R2),BLANK          MOVE IN BLANK PASS MNEMONIC.     33020020
         LA    R2,SIX(R2)              R2=UPDATED OUTPUT POINTER.       33040020
         DROP  R7                      DROP ADDRESSABILITY TO WORKAREA  33050020
         SPACE                                                          33060020
*********************************************************************** 33080020
* THE FOLLOWING INSTRUCTION FINDS THE PROPER INDEX VALUE FOR THE      * 33100020
* BRANCH TABLE.  THE BRANCH TABLE ROUTES CONTROL TO THE PROPER FORMAT * 33120020
* ROUTINE.                                                            * 33140020
*********************************************************************** 33160020
         SPACE                                                          33180020
         SR    R4,R4                   R4=ZERO.                         33200020
         IC    R4,OPTAB4(R6)           R4=INDEX VALUE TO ROUTINE.       33220020
         B     INSTBRTB(R4)            BRANCH TO REQUIRED ROUTINE.      33240020
         SPACE                                                          33260020
* THE FOLLOWING TABLE ROUTES CONTROL TO THE PROPER FORMAT ROUTINE.    * 33280020
         SPACE                                                          33300020
INSTBRTB EQU   *                                                        33320020
         B     NOOPCODE                THE OP CODE IS INVALID,ERROR MSG 33340020
         B     OPRR                    OP=RR FORMAT.                    33360020
         B     OPRR                    OP=RR FORMAT WITH 1 REGISTER.    33380020
         B     OPRS                    OP=RS FORMAT.                    33400020
         B     OPRS                    OP=RS FORMAT ONE REGISTER.       33420020
         B     OPSVC                   OP=SVC.                          33440020
         B     OPSI                    OP=SI FORMAT.                    33460020
         B     OPSI                    OP=SI WITHOUT THE IMMEDIATE.     33480020
         B     OPSS                    OP=SS WITH ONE LENGTH.           33500020
         B     OPSS                    OP=SS WITH TWO LENGTH.           33520020
         B     OPRX                    OP=RX FORMAT.                    33540020
         SPACE                                                          33560020
*********************************************************************** 33580020
* THE FOLLOWING INSTRUCTIONS CONVERTS AND FORMAT THE RR INSTRUCTIONS  * 33600020
* WITH BOTH OPERANDS IN THE OPERAND FIELD.                            * 33620020
*********************************************************************** 33640020
         SPACE                                                          33660020
OPRR     EQU   *                                                        33680020
         LA    R8,TEN                  R8=LENGTH OF OUTPUT              33700020
         LA    R7,TWO                  R7=2.                            33720020
         LA    R5,OPRRVAL              R5=HEX 4.                        33740020
         CR    R4,R5                   Q.RR FORMAT WITH ONE REGISTER.   33760020
         BE    OP1R                    NO,SKIP 1 REGISTER SWITCH SET.   33780020
         LA    R7,ONE                  SET ONE REGISTER SWITCH.         33800020
         LA    R8,SEVEN                SET LENGTH FOR ONE REGISTER.     33820020
OP1R     EQU   *                                                        33840020
         IC    R4,ONE(R3)              R4=OPERANDS R1 AND R2.           33860020
         SRDL  R4,EIGHT                R5=R1 AND R2 IN HIGH ORDER BYTE. 33880020
         L     R6,WORKAREA             R6=ADDRESS OF WORKAREA.          33900020
GET1OR2  EQU   *                                                        33920020
         SR    R4,R4                   R4=0.                            33940020
         SLDL  R4,FOUR                 ISOLATE NEXT 4 BITS OP OPERAND   33960020
         CVD   R4,ZERO(R6)             REGISTER NOW DECIMAL.            33980020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  34000020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) R1 NOW ZONED DECIMAL.         34020020
         CLI   ONE(R6),F0              Q.IS REGISTER 1 OR 2 DIGITS.     34040020
         BNE   TWODIGIT                REGISTER IS TWO DIGITS.          34060020
         BCTR  R8,ZERO                 R8=CORRECTED LENGTH.             34080020
         MVC   ZERO(ONE,R2),TWO(R6)    REGISTER NOW IN OUTPUT AREA.     34090020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           34120020
GETCOMMA EQU   *                                                        34140020
         MVI   ZERO(R2),COMMA          SEPERATE OPERANDS.               34160020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           34180020
         BCT   R7,GET1OR2              Q.IS R2 COMPLETED.               34200020
         L     R2,CONAREA              YES,FIND LENGTH AREA.            34220020
         STC   R8,ZERO(R2)             LENGTH NOW IN CONAREA.           34240020
         SR    R15,R15                 RC=0.                            34260020
         BR    R14                     RETURN                           34280020
TWODIGIT EQU   *                                                        34300020
         MVC   ZERO(TWO,R2),ONE(R6)    REGISTER NOW IN OUTPUT AREA.     34320020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER.           34340020
         B     GETCOMMA                GET A COMMA.                     34360020
         SPACE                                                          34380020
*********************************************************************** 34400020
* THE FOLLOWING INSTRUCTIONS CONVERT AND FORMAT THE RS INSTRUCTION    * 34420020
* TYPE R1 AND R3 OPERAND FIELD.                                       * 34440020
*********************************************************************** 34460020
         SPACE                                                          34480020
OPRS     EQU   *                                                        34500020
         LA    R8,FIVE                 R8=LENG OF MNEMONIC AND A BLANK. 34520020
         LA    R7,TWO                  R7=2.                            34540020
         LA    R5,OPRSVAL              R5=HEX 0C.                       34560020
         CR    R4,R5                   Q.FORMAT 1 OR 2 REGISTERS.       34580020
         BE    RS2R                    2 REGISTERS,SKIP 1 SET.          34600020
         LA    R7,ONE                  R7=1.                            34620020
RS2R     EQU   *                                                        34640020
         IC    R4,ONE(R3)              R4=OPERANDS R1 AND R2.           34660020
         SRDL  R4,EIGHT                R5=R1 AND R3 IN HI ORDER BYTE.   34680020
         L     R6,WORKAREA             R6=ADDRESS OF WORKAREA.          34700020
         USING CVTWORK,R6              USE R6 TO ADRESS WORKAREA.       34710020
GET1OR3  EQU   *                                                        34720020
         SR    R4,R4                   R4=0.                            34740020
         SLDL  R4,FOUR                 ISOLATE NEXT 4 BITS.             34760020
         CVD   R4,ZERO(R6)             REGISTER NOW DECIMAL.            34780020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  34800020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) R1 NOW ZONED DECIMAL.         34820020
         CLI   ONE(R6),F0              Q.IS REGISTER 1 OR 2 DIGITS.     34840020
         BNE   TWOVAL                  R IS TWO DIGITS.                 34860020
         LA    R8,ONE(R8)              R8=LENGTH PLUS 1.                34880020
         MVC   ZERO(ONE,R2),TWO(R6)    REGISTER NOW IN OUTPUT AREA.     34900020
         LA    R2,ONE(R2)              UPDATE OUTPUT AREA.              34920020
PUTCOMMA EQU   *                                                        34940020
         MVI   ZERO(R2),COMMA          SEPERATE OPERANDS.               34960020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           34980020
         LA    R8,ONE(R8)              R8=LENGTH PLUS 1.                35000020
         BCT   R7,GET1OR3              Q.IS REG COMPLETED.              35020020
         SPACE                                                          35040020
*********************************************************************** 35060020
* THE FOLLOWING LINES OF CODE CONVERTS THE STORAGE OPERAND OF THE RS  * 35080020
* INSTRUCTION FORMAT.                                                 * 35100020
*********************************************************************** 35120020
         SPACE                                                          35140020
         MVC   ZERO(TWO,R6),TWO(R3)    INPUT NOW IN WORKAREA.           35160020
         SR    R4,R4                   R4=0.                            35180020
         L     R5,ZERO(R6)             R5=STORAGE OPERAND               35200020
         SLDL  R4,FOUR                 R4=BASE REGISTER.                35220020
         SRL   R5,TWO0                 R5=DISPLACEMENT                  35240020
         CVD   R5,ZERO(R6)             DISP NOW PACKED DECIMAL.         35260020
         MVC   EIGHT(SIX,R6),PATTERN2  MOVE PATTERN INTO WORKAREA.      35280020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  35300020
         LA    R1,ONE3(R6)             R1=ADDR OF LAST BYTE.            35320020
         EDMK  EIGHT(SIX,R6),FIVE(R6)  DISP NOW ZONED DECIMAL.          35340020
         LA    R7,ONE4(R6)             R7=END OF ZONED DECIMAL.         35360020
         SR    R7,R1                   R7=LENGTH OF ZONED DECIMAL.      35380020
         LA    R8,ZERO(R7,R8)          R8=LENGTH PLUS DISP LENGTH.      35400020
         BCTR  R7,ZERO                 R6=EXECUTE LENGTH.               35420020
         EX    R7,DISPMOVE             MOVE DISP TO CONAREA.            35440020
         LA    R2,ONE(R7,R2)           UPDATE OUTPUT POINTER.           35460020
         MVI   ZERO(R2),OPEN           MOVE IN OPEN PARENTHESIS.        35480020
         SPACE                                                          35500020
*********************************************************************** 35520020
* THIS SECTION OF CODE CONVERT THE BASE REGISTER OF THE STORAGE       * 35540020
* OPERAND AND MOVE IT INTO THE OUTPUT AREA.                           * 35560020
*********************************************************************** 35580020
         SPACE                                                          35600020
         CVD   R4,ZERO(R6)             REGISTER NOW PACKED DECIMAL.     35620020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  35640020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) BASE NOW ZONED DECIMAL.       35660020
         CLI   ONE(R6),F0              Q.BASE 1 OR 2 DIGITS.            35680020
         BNE   TWOBASE                 BASE IS TWO DIGITS.              35700020
         LA    R8,ONE(R8)              R8=LENGTH NOW INCLUDES BASE.     35720020
         MVC   ONE(ONE,R2),TWO(R6)     BASE NOW IN OUTPUT AREA.         35740020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER            35760020
ENDBASE  EQU   *                                                        35780020
         MVI   ZERO(R2),CLOSE          MOVE IN A CLOSE PARENTHESIS.     35800020
         LA    R8,TWO(R8)              R8=LENGTH PLUS 2.                35820020
         L     R2,CONAREA              R2=OUTPUT AREA ADDRESS.          35840020
         TM    CODE370,CHAR5           Q.IS MNEUMONIC 5 CHARS.          35850020
         BNO   COMEND                  NO,STORE LENGTH.                 35852020
         LA    R8,ONE(R8)              YES,LENGTH+1 CHAR.               35854020
COMEND   EQU   *                                                        35856020
         STC   R8,ZERO(R2)             LENGTH NOW IN CONAREA.           35860020
         SR    R15,R15                 RC=0.                            35880020
         BR    R14                     RETURN.                          35900020
         DROP  R6                      DROP ADRESSABILITY TO WORKAREA   35910020
DISPMOVE MVC   ZERO(ONE,R2),ZERO(R1)   MOVE DISP INTO CONAREA.          35920020
TWOBASE  EQU   *                                                        35940020
         LA    R8,TWO(R8)              INCREMENT LENGTH FOR 2 DIGITS.   35960020
         MVC   ONE(TWO,R2),ONE(R6)     BASE NOW IN OUTPUT AREA.         35980020
         LA    R2,THREE(R2)            UPDATE OUTPUT POINTER.           36000020
         B     ENDBASE                 GET CLOSE PARENTHESIS.           36020020
TWOVAL   EQU   *                                                        36040020
         LA    R8,TWO(R8)              R8=LENGTH PLUS 2.                36060020
         MVC   ZERO(TWO,R2),ONE(R6)    R NOW IN OUTPUT AREA.            36080020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER.           36100020
         B     PUTCOMMA                GET COMMA.                       36120020
         SPACE                                                          36140020
*********************************************************************** 36160020
* THE FOLLOWING INSTRUCTIONS CONVERTS A SVC INSTRUCTION TO ITS        * 36180020
* PRINTABLE FORMAT.                                                   * 36200020
*********************************************************************** 36220020
         SPACE                                                          36230020
OPSVC    EQU   *                                                        36240020
         SR    R4,R4                   R4=0.                            36260020
         IC    R4,ONE(R3)              R4=IMMEDIATE FIELD.              36280020
         L     R6,WORKAREA             R6=ADDRESS OF WORKAREA.          36300020
         CVD   R4,ZERO(R6)             I FIELD NOW PACKED DECIMAL.      36320020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  36340020
         LA    R1,ONE3(R6)             R1=ADDR OF LAST BYTE.            36360020
         MVC   EIGHT(SEVEN,R6),PATTERN2  MOVE IN PATTERN.               36380020
         EDMK  EIGHT(SIX,R6),FIVE(R6)  I FIELD NOW ZONED DECIMAL.       36400020
         LA    R7,ONE4(R6)             R7=END OF ZONED DECIMAL.         36420020
         SR    R7,R1                   R7=LENGTH OF SIGNIFICANT DIGITS. 36440020
         LA    R8,FIVE(R7)             R8=LENGTH OF OUTPUT.             36460020
         BCTR  R7,ZERO                 R7=EXECTUE LENGTH.               36480020
         EX    R7,SVCMOVE              MOVE I FIELD INTO CONAREA.       36500020
         L     R2,CONAREA              R2=CONAREA ADDRESS.              36520020
         STC   R8,ZERO(R2)             LENGTH NOW IN CONAREA.           36540020
         SR    R15,R15                 RC=0.                            36560020
         BR    R14                     RETURN TO CALLER.                36580020
SVCMOVE  MVC   ZERO(ONE,R2),ZERO(R1)   MOVE I FIELD INTO CONAREA.       36600020
         SPACE                                                          36620020
*********************************************************************** 36640020
* THE FOLLOWING INSTRUCTIONS CONVERTS A SI INSTRUCTION TO PRINTABLE   * 36660020
* CHARACTERS AND FORMAT IT IN ITS MACHINE INSTRUCTION FORMAT.         * 36680020
*********************************************************************** 36700020
         SPACE                                                          36720020
OPSI     EQU   *                                                        36740020
         LR    R0,R4                   SAVE INDEX VALUE                 36760020
         L     R6,WORKAREA             R6=ADDRESS OF WORKAREA.          36780020
         USING CVTWORK,R6              USE R6 TO ADDRESS WORKAREA       36790020
         MVC   ZERO(TWO,R6),TWO(R3)    STORAGE OPERAND NOW IN WORKAREA. 36800020
         SR    R4,R4                   R4=0.                            36820020
         L     R5,ZERO(R6)             R5=STORAGE OPERAND.              36840020
         SLDL  R4,FOUR                 R4=BASE REGISTER.                36860020
         SRL   R5,TWO0                 R5=DISPLACEMENT.                 36880020
         CVD   R5,ZERO(R6)             DISP NOW PACKED DECIMAL.         36900020
         MVC   EIGHT(SIX,R6),PATTERN2  MOVE PATTERN INTO WORKAREA.      36920020
         OI    SEVEN(R6),SIGNF         SIGN NOW HEX F.                  36940020
         LA    R1,ONE3(R6)             R1=ADDR OF LAST BYTE.            36960020
         EDMK  EIGHT(SIX,R6),FIVE(R6)  DISP NOW ZONED DECIMAL.          36980020
         LA    R7,ONE4(R6)             R7=END OF ZONED DECIMAL.         37000020
         SR    R7,R1                   R7=LENGTH OF ZONED DECIMAL.      37020020
         LA    R8,FIVE(R7)             R8=LENGTH PLUS DISP.             37040020
         BCTR  R7,ZERO                 R7=EXECUTE LENGTH.               37060020
         EX    R7,DISPMOVE             MOVE DISP TO CONAREA             37080020
         LA    R2,ONE(R7,R2)           UPDATE OUTPUT POINTER.           37100020
         MVI   ZERO(R2),OPEN           MOVE OPEN PARENTHESIS TO CONAREA 37120020
         SPACE                                                          37140020
*********************************************************************** 37160020
* THIS SECTION OF CODE CONVERT THE BASE REGISTER OF THE STORAGE       * 37180020
* OPERAND AND MOVE IT INTO THE OUTPUT AREA.                           * 37200020
*********************************************************************** 37220020
         SPACE                                                          37240020
         CVD   R4,ZERO(R6)             REGISTER NOW PACKED DECIMAL.     37260020
         OI    SEVEN(R6),SIGNF         SIGN HEX F.                      37280020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) BASE NOW ZONED DECIMAL.       37300020
         CLI   ONE(R6),F0              Q.BASE 1 OR 2 DIGITS.            37320020
         BNE   SIBASE2                 BASE IS TWO DIGITS.              37340020
         LA    R8,ONE(R8)              R8=LENGTH NOW INCLUDES BASE.     37360020
         MVC   ONE(ONE,R2),TWO(R6)     BASE NOW IN OUTPUT AREA.         37380020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER.           37400020
ENDISP   EQU   *                                                        37420020
         MVI   ZERO(R2),CLOSE          MOVE IN A CLOSE PARENTHESIS.     37440020
         LA    R8,TWO(R8)              R8=LENGTH + 2.                   37460020
         SPACE                                                          37470020
* CHECK TO DETERMINE IF A SCON IS BEING CONVERTED TO PRINTABLE.       * 37480020
         SPACE                                                          37490020
         LTR   R0,R0                  Q.SCON PROCESSING.                37500020
         BZ    SCON                    YES,FINISH SCON CONVERSION.      37520020
* CHECK TO DETERMINE IF THE FORMAT REQUESTED IS WITH OR WITHOUT AN    * 37540020
* IMMEDIATE FIELD.                                                    * 37560020
         SPACE                                                          37580020
         LA    R1,OPSIVAL              R1='14'.                         37600020
         CLR   R1,R0                   Q.IMMEDIATE FIELD REQUESTED.     37620020
         BNE   IMMED                   YES,GET IMMEDIATE FIELD.         37630020
         TM    CODE370,CHAR5           Q.IS MNEUMONIC 5 CHARS.          37640020
         BNO   ENDOPSI                 NO,END FORMAT AND RETURN.        37642020
         LA    R8,ONE(R8)              YES,R8=LENGTH+EXTRA CHAR.        37644020
         B     ENDOPSI                 END FORMAT AND RETURN.           37646020
         DROP  R6                      DROP ADDRESSABILITY TO WORKAREA  37648020
         SPACE                                                          37650020
*********************************************************************** 37660020
* THE FOLLOWING INSTRUCTIONS CONVERT THE IMMEDIATE FIELD TO PRINTABLE * 37680020
* CHARACTERS AND MOVE THEM TO THE OUTPUT AREA.                        * 37700020
*********************************************************************** 37720020
         SPACE                                                          37730020
IMMED    EQU   *                                                        37732020
         LA    R1,TWO                                                   37740020
         SR    R4,R4                   R4=0                             37760020
         IC    R4,ONE(R3)              R4=IMMEDIATE FIELD.              37780020
         SRDL  R4,FOUR                 ISOLATE FIRST 4 BITS.            37800020
         LA    R7,NINE                 R7=9.                            37820020
NEXT4I   EQU   *                                                        37840020
         CLR   R4,R7                   Q-4 BITS GT 9.                   37860020
         BH    SIHI                    YES,CONVERT TO ALPHABETIC.       37880020
         LA    R4,F0(R4)               R4=4 BIT NOW PRINTABLE.          37900020
MOVEI    STC   R4,ZERO(R6)             MOVE BYTE INTO WORKAREA.         37920020
         LA    R6,ONE(R6)              R6=ADDR ONE PASS WORKAREA.       37940020
         SR    R4,R4                   CLEAR REG4.                      37960020
         SLDL  R4,FOUR                 ISOLATE NEXT FOUR BITS.          37980020
         BCT   R1,NEXT4I               IF R1=0,CONTINUE,ELSE CVT NEXT 4 38000020
         MVC   ONE(SIX,R2),HEXI       MOVE INTO CONAREA THE I PATTERN.  38020020
         L     R6,WORKAREA             R6=ADDRESS OF WORKAREA.          38040020
         MVC   FOUR(TWO,R2),ZERO(R6)  MOVE IMMEDIATE DATA INTO CONAREA  38060020
         LA    R8,SIX(R8)              LENGTH NOW=OUTPUT LENGTH.        38080020
         B     ENDOPSI                 GO SET RETURN CODE.              38100020
SIBASE2  EQU   *                                                        38120020
         LA    R8,TWO(R8)              R8=LENGTH + 2 FOR 2 BASE DIGITS. 38140020
         MVC   ONE(TWO,R2),ONE(R6)     BASE NOW IN OUTPUT AREA.         38160020
         LA    R2,THREE(R2)            UPDATE OUTPUT POINTER.           38180020
         B     ENDISP                  GET CLOSE PARENTHESIS.           38200020
* MOVE LENGTH INTO CONAREA,GET RETURN CODE=O AND RETURN TO CALLER.    * 38220020
ENDOPSI  EQU   *                                                        38240020
         L     R2,CONAREA              R2=ADDRESS OF CONAREA.           38260020
         STC   R8,ZERO(R2)             LENGTH NOW IN CONAREA.           38280020
         SR    R15,R15                 RC=0.                            38300020
         BR    R14                     RETURN TO CALLER.                38320020
* CONVERT THE ALPHABETIC HEX VALUES TO PRINTABLE CHARACTERS.          * 38340020
SIHI     EQU   *                                                        38360020
         LA    R4,B7(R4)               R4=4 BITS NOW PRINTABLE.         38380020
         B     MOVEI                   GET IMMEDIATE FIELD.             38400020
         SPACE                                                          38410020
*********************************************************************** 38420020
* THE FOLLOWING INSTRUCTIONS CONVERTS THE STORAGE OPERANDS OF THE     * 38440020
* SS INSTRUCTION TO ITS PRINTABLE FORM.                               * 38460020
*********************************************************************** 38480020
         SPACE                                                          38490020
OPSS     EQU   *                                                        38500020
         LR    R0,R4                   SAVE INDEX FACTOR.               38520020
         LA    R8,FIVE                 R8=LENGTH OF MNEMONIC + 0.       38540020
         LA    R10,TWO                 R10=2.                           38560020
         L     R6,WORKAREA             R6=ADDRESS OF THE WORKAREA AREA. 38580020
         USING CVTWORK,R6              USE R6 TO ADDRESS WORKAREA       38590020
         CLI   ZERO(R3),SRPOP          Q.IS OP CODE SRP.                38592020
         BNE   GETB2D2                 NO,GET B1D1.                     38594020
         OI    CODE370,SSIMM           YES,TURN ON SS,L1,I3 FLAG.       38596020
GETB2D2  EQU   *                                                        38600020
         MVC   ZERO(TWO,R6),TWO(R3)    MOVE STORAGE OPERAND TO WORKAREA 38620020
         L     R4,ZERO(R6)             R0=STORAGE OPERANDS.             38640020
         SRL   R4,ONE6                 ISOLATE FIRST OPERAND.           38660020
         SRDL  R4,ONE2                 R4=BASE REGISTER.                38680020
         SRL   R5,TWO0                 R5=DISPLACEMENT.                 38700020
         CVD   R5,ZERO(R6)             DISP NOW PACKED DECIMAL.         38720020
         MVC   EIGHT(SIX,R6),PATTERN2  MOVE PATTERN INTO WORKAREA.      38740020
         OI    SEVEN(R6),SIGNF         SIGN NOW X'F'.                   38760020
         LA    R1,ONE3(R6)             R1=ADDR OF LAST BYTE.            38780020
         EDMK  EIGHT(SIX,R6),FIVE(R6)  DISP NOW ZONED DECIMAL.          38800020
         LA    R7,ONE4(R6)             R7=END OF ZONED DECIMAL.         38820020
         SR    R7,R1                   LENGTH OF DISP.                  38840020
         LA    R8,ONE(R7,R8)           R8=NEW LENGTH.                   38860020
         BCTR  R7,ZERO                 R7=EXECUTE LENGTH.               38880020
         EX    R7,DISPMOVE             MOVE DISP TO CONAREA.            38900020
         LA    R2,ONE(R7,R2)           UPDATE OUTPUT POINTER.           38920020
         MVI   ZERO(R2),OPEN           MOVE IN OPEN PARENTHESIS.        38940020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           38960020
         LA    R7,ONE                  R7=1.                            38980020
         CLR   R10,R7                  Q.IS THIS THE CVT FOR B2D2       39000020
         BE    CVTB2D2                 YES,CONVERT B2D2.                39020020
         SR    R4,R4                   R4=0.                            39040020
         IC    R4,ONE(R3)              R4=LENGTH FIELD OF THE INST.     39060020
         LA    R7,OPSSVAL              R7=TYPE FORMAT INDICATOR.        39080020
         CLR   R7,R0                   Q.IS LENGTH L1 & L2.             39100020
         BNE   SSL2                    YES,IS L1 & L2.                  39110020
         TM    CODE370,SSIMM           NO.Q.IS IT L1 & I3.              39120020
         BNO   SSL1                    NO,ONLY L1.                      39122020
         SPACE                                                          39130020
* CONVERT LENGTH FIELD TO REFLECT A L1 & L2 LENGTH FIELD.             * 39140020
         SPACE                                                          39150020
SSL2     EQU   *                                                        39152020
         SRDL  R4,FOUR                 R4=L1.                           39160020
SSL1     EQU   *                                                        39180020
         LA    R4,ONE(R4)              R4=CORRECT LENGTH TO BE CONVERT. 39200020
         CVD   R4,ZERO(R6)             LENGTH NOW PACKED DECIMAL.       39220020
         MVC   EIGHT(FOUR,R6),PATTERN2 LENGTH NOW ZONED DECIMAL.        39240020
         OI    SEVEN(R6),SIGNF         SIGN NOW X'F'.                   39260020
         EDMK  EIGHT(FOUR,R6),SIX(R6)  LENGTH NOW ZONED DECIMAL.        39280020
         LA    R7,ONE2(R6)             R7=END OF ZONED DECIMAL.         39300020
         SR    R7,R1                   R7=LENGTH OF LENGTH.             39320020
         LA    R8,ZERO(R7,R8)          R8=UPDATED LENGTH.               39340020
         BCTR  R7,ZERO                 R7=EXECUTE LENGTH.               39360020
         EX    R7,DISPMOVE             MOVE LENGTH INTO CONAREA.        39380020
         LA    R2,ONE(R7,R2)          UPDATE OUTPUT POINTER.            39400020
         MVI   ZERO(R2),COMMA          SEPERATE LENGTH & BASE.          39420020
         LA    R8,ONE(R8)              UPDATE OUTPUT COUNTER.           39440020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           39460020
NOLENGTH EQU   *                                                        39480020
         SR    R4,R4                   R4=0.                            39500020
         IC    R4,TWO(R3)              R4=BASE + GARBAGE.               39520020
         SRL   R4,FOUR                 ISOLATE BASE.                    39540020
         CVD   R4,ZERO(R6)             REGISTER NOW DECIMAL.            39560020
         OI    SEVEN(R6),SIGNF         SIGN NOW X'F'.                   39580020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) BASE NOW ZONED DECIMAL.       39600020
         CLI   ONE(R6),F0              Q.IS BASE 1 OR 2 DIGITS.         39620020
         BNE   SSBASE2                 BASE IS 2 DIGITS.                39640020
         LA    R8,ONE(R8)              R8=LENGTH + NEXT OPERAND FIELD.  39660020
         MVC   ZERO(ONE,R2),TWO(R6)    REGISTER NOW IN OUTPUT AREA.     39680020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           39700020
SSCOMMA  EQU   *                                                        39720020
         MVI   ZERO(R2),CLOSE          MOVE IN CLOSE PARENTHESIS.       39740020
         MVI   ONE(R2),COMMA           SEPERATE OPERANDS.               39760020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER.           39780020
         LA    R8,TWO(R8)              UPDATE OUTPUT COUNTER.           39800020
         LA    R3,TWO(R3)              R3=ADDR OF B1D1.                 39820020
         BCT   R10,GETB2D2             IF BEDE IS COMPLETED RETURN.     39840020
         BCTR  R8,ZERO                 R8=CORRECT LENGTH.               39860020
         TM    CODE370,SSIMM           Q.IS IT SS,L1 & I3.              39870020
         BNO   SSRETURN                NO.FINISH UP AND RETURN.         39872020
         LA    R8,ONE(R8)              UPDATE OUTPUT CTR FOR COMMA.     39874020
         S     R3,THREEWD              R3=INPUT POINTER TO L1 & I3.     39876020
         SR    R4,R4                   CLEAR R4.                        39890020
         IC    R4,ZERO(R3)             R4= L1 & I3 IN BINARY.           39892020
         SLL   R4,TWO8                 CLEAR OUT L1.                    39892420
         SRL   R4,TWO8                 ISOLATE I3.                      39892820
         CVD   R4,ZERO(R6)             I3 NOW DECIMAL.                  39892920
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) I3 NOW ZONED DECIMAL.         39893020
         OI    TWO(R6),HEXF0           SIGN NOW HEX F.                  39893120
         CLI   ONE(R6),F0              Q.IS I3 1 OR 2 DIGITS.           39895120
         BNE   ITWODIG                 I3 IS 2 DIGITS.                  39897120
         LA    R8,ONE(R8)              UPDATE OUTPUT LENGTH 1 DIGIT.    39897520
         MVC   ZERO(ONE,R2),TWO(R6)    I3 NOW IN OUTPUT AREA.           39897920
         B     SSRETURN                FINISH UP AND RETURN.            39898320
ITWODIG  EQU   *                                                        39898420
         LA    R8,TWO(R8)              UPDATE OUTPUT PTR 2 DIGITS.      39900420
         MVC   ZERO(TWO,R2),ONE(R6)    I3 NOW IN OUTPUT AREA.           39900820
SSRETURN EQU   *                                                        39931520
         L     R2,CONAREA              R2=ADDR OF OUTPUTAREA.           39937220
         STC   R8,ZERO(R2)             LENGTH NOW IN OUTPUT AREA.       39942920
         SR    R15,R15                 RC=0.                            39948620
         BR    R14                     RETURN TO CALLER.                39954320
CVTB2D2  EQU   *                                                        39960020
         LA    R7,OPSSVAL              R7=X'00'.                        39980020
         CR    R0,R7                   Q.IS LENGTH L1 OR L1 AND L2.     40000020
         BE    NOLENGTH                LENGTH IS L1 ONLY.               40020020
         SR    R4,R4                   R4=0.                            40040020
         BCTR  R3,ZERO                 R3=PTR TO LENGTH FIELD.          40060020
         IC    R4,ZERO(R3)             R4=LENGTH FIELD.                 40080020
         SLL   R4,TWO8                 CLEAR OUT L1.                    40100020
         SRL   R4,TWO8                 ISOLATE L2.                      40120020
         LA    R3,ONE(R3)              ADVANCE INPUT POINTER.           40140020
         B     SSL1                    CONVERT L2.                      40160020
SSBASE2  EQU   *                                                        40180020
         MVC   ZERO(TWO,R2),ONE(R6)    REGISTER NOW IN OUTPUT AREA.     40200020
         LA    R2,TWO(R2)              R2=UPDATED OUTPUT PTR.           40220020
         LA    R8,TWO(R8)              UPDATE LENGTH COUNTER.           40240020
         B     SSCOMMA                 MOVE IN A COMMA.                 40260020
OPRX     EQU   *                                                        40280020
         DROP  R6                      DROP ADDRESSABILITY TO WORKAREA  40282020
         SPACE                                                          40290020
*********************************************************************** 40300020
* THE FOLLOWING INSTRUCTIONS CONVERTS AND FORMATS THE RX INSTRUCTIONS * 40320020
*********************************************************************** 40340020
         SPACE                                                          40350020
         LA    R8,FIVE                 R8=LENGTH OF MNEMONIC + A BLANK. 40360020
         SR    R0,R0                   R8=LENGTH OF MNEMONIC+A BLANK.   40380020
         LA    R7,ONE                  R7=ONE.                          40400020
         IC    R4,ONE(R3)              R4=R1 & X2 FIELDS.               40420020
         SRDL  R4,EIGHT                R5=R1&X2 IN HIGH ORDER BYTE.     40440020
         L     R6,WORKAREA             R6=ADDR OF WORKAREA.             40460020
B2ORX2   EQU   *                                                        40480020
         SR    R4,R4                   R4=0.                            40500020
         SLDL  R4,FOUR                 ISOLATE NEXT 4 BITS OF OPERAND.  40520020
         CVD   R4,ZERO(R6)             REGISTER NOW DECIMAL.            40540020
         OI    SEVEN(R6),SIGNF         SIGN NOW X'F'.                   40560020
         UNPK  ZERO(THREE,R6),SIX(TWO,R6) R1 NOW ZONED DECIMAL.         40580020
         CLI   ONE(R6),F0              Q.IS REGISTER 1 OR 2 DIGITS.     40600020
         BNE   TWOCHAR                 REGISTER IS 2 CHARACTERS.        40620020
         LA    R8,ONE(R8)              R8=LENGTH + NEXT OPERAND FIELD.  40640020
         MVC   ZERO(ONE,R2),TWO(R6)    REGISTER NOW IN OUTPUT AREA.     40660020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           40680020
COMMAGET EQU   *                                                        40700020
         MVI   ZERO(R2),COMMA          SEPERATE OPERAND FIELDS.         40720020
         LA    R2,ONE(R2)              UPDATE OUTPUT POINTER.           40740020
         LA    R8,ONE(R8)              R8=LENGTH OF OUTPUT SO FAR.      40760020
         BCT   R7,B2ORX2               IF 7=2 CONBERT B2.               40780020
         LTR   R0,R0                   Q.B2 FIELD COMPLETED.            40800020
         BNZ   CLOSERX                 YES,CLOSE RX ROUTINE.            40820020
         LH    R4,BASEDISP(R3)         R4=BASE + DISP.                  40840020
         SLL   R4,TWO0                 DROP BASE REG.                   40860020
         SRL   R4,TWO0                 ISOLATE DISP.                    40880020
         CVD   R4,ZERO(R6)             DISP NOW PACKED DECIMAL.         40900020
         MVC   EIGHT(SIX,R6),PATTERN2  MOVE PATTERN INTO WORKAREA.      40920020
         OI    SEVEN(R6),SIGNF         SIGN NOW X'F'.                   40940020
         LA    R1,ONE3(R6)             R1=ADDR OF LAST BYTE.            40960020
         EDMK  EIGHT(SIX,R6),FIVE(R6)  DISP NOW ZONED DECIMAL.          40980020
         LA    R7,ONE4(R6)             R7=END OF ZONED DECIMAL.         41000020
         SR    R7,R1                   R7=LENGTH OF ZONED DECIMAL.      41020020
         LA    R8,ONE(R7,R8)           R8=LENGTH + DISP LENGTH.         41040020
         BCTR  R7,ZERO                 R7=EXECUTE LENGTH.               41060020
         EX    R7,DISPMOVE             MOVE DISP TO CONAREA.            41080020
         LA    R2,ONE(R7,R2)           UPDATE OUTPUT POINTER.           41100020
         MVI   ZERO(R2),OPEN           MOVE IN C'('.                    41120020
         LA    R2,ONE(R2)              UPDATE OUTPUT PTR.               41140020
*        CONVERT AND FORMAT THE INDEX AND BASE REGISTER               * 41160020
         SR    R10,R10                 R10=0.                           41180020
         LA    R7,TWO                  R7=2.                            41200020
         IC    R10,BASEDISP(R3)        R6=BASE + DISP.                  41220020
         SLL   R10,TWO0                MOVE BASE TO HI ORDER.           41240020
         OR    R5,R10                  R5=X2 AND B2.                    41260020
         LA    R0,ONE                  R0=1,INDICATES DISP COMPLETED.   41280020
         B     B2ORX2                  FORMAT X2 & BE FIELD.            41300020
CLOSERX  EQU   *                                                        41320020
         BCTR  R2,ZERO                 R2=PTR TO PARENTHESIS FIELD.     41340020
         MVI   ZERO(R2),CLOSE          MOVE CLOSE PARENTHESIS IN.       41360020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          41380020
         STC   R8,ZERO(R2)             LENGTH OF OUTPUT NOW IN CONAREA. 41400020
         SR    R15,R15                 RETURN CODE =0.                  41420020
         BR    R14                     RETURN                           41440020
TWOCHAR  EQU   *                                                        41460020
         MVC   ZERO(TWO,R2),ONE(R6)    REGISTER NOW IN OUTPUT AREA.     41480020
         LA    R2,TWO(R2)              UPDATE OUTPUT POINTER.           41500020
         LA    R8,TWO(R8)              R8=LENGTH + NEXT OPERAND FIELD.  41520020
         B     COMMAGET                GO MOVE IN COMMA.                41540020
*********************************************************************** 41560020
* THIS SECTION OF CODE CONVERTS BINARY INPUT TO ITS PRINTABLE SCON    * 41580020
* FORMAT (DISP(BASE)).                                                * 41600020
*********************************************************************** 41620020
IKJEGBIS EQU   *                                                        41640020
         DROP  R12                     GET NEW BASE REGISTER.           41660020
         USING *,R15                   R15 IS NEW BASE REGISTER.        41680020
         L     R12,BASECON             R12=ADDRESS OF IKJEGCV2.         41700020
         DROP  R15                     GET NEW BASE REGISTER.           41720020
         USING IKJEGCVX,R12            IKJEGCVX ADDRESSABILITY.         41740020
         USING TCOMTAB,R9              TCOMTAB ADDRESSABILITY.          41760020
         SR    R4,R4                   R4=0.                            41780020
         L     R3,ZERO(R1)             R3=ADDR OF INPUT STRING.         41800020
         L     R2,CONAREA              R2=ADDR OF OUTPUT AREA.          41820020
         LA    R2,ONE(R2)              R2=ADDR ONE PASS LENGTH BYTE.    41840020
         BCTR  R3,ZERO                 R3=INPUT PTR-1.                  41860020
         BCTR  R3,ZERO                 R3=INPUT PTR-2.                  41880020
         B     OPSI                    CONVERT DISP(BASE).              41900020
SCON     EQU   *                                                        41920020
         LA    R5,FIVE                 R5=5.                            41940020
         SR    R8,R5                   R8=SCON LENGTH.                  41960020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              41980020
         STC   R8,ZERO(R2)             MOVE LENGTH INTO CONAREA.        42000020
         SR    R15,R15                 R15=0.                           42020020
         BR    R14                     RETURN TO CALLER.                42040020
BASECON  DC    A(IKJEGCVX)             ADDR OF IKJEGCVX.                42060020
NOOPCODE EQU   *                                                        42080020
         LA    R15,FOUR                RC=4.                            42100020
         BR    R14                     RETURN.                          42120020
         DS    0F                                                       42140020
HEXI     DC    C',X''  '''             IMMEDIATE PATTERN.               42160020
PATTERN2 DC    X'40'                   ******************************** 42180020
         DC    3X'20'                  * PATTERN FIELD FOR THE EDIT   * 42200020
         DC    X'21'                   * AND MARK INSTRUCTION.        * 42220020
         DC    5X'20'                  ******************************** 42240020
THREEWD  DC    F'3'                    THREE                            42250020
         TITLE 'IKJEGCVT PRINTABLE OPCODES TABLE.'                      42260020
*********************************************************************** 42270020
* THIS CSECT CONTAINS THE PRINTABLE OPCODES WITH THEIR RELATED        * 42272020
* INSTRUCTION FORMAT CODE.                                            * 42274020
*********************************************************************** 42276020
         SPACE                                                          42278020
IKJEGCOP  CSECT                                                         42280020
         DC    4XL5'00'                CODE=00,INVALID OP CODE.         42300020
         DC    C'SPM '                 SPM OP CODE.                     42320020
         DC    X'08'                   CODE=08,RR FORMAT-1 OPERAND.     42340020
         DC    C'BALR'                 BALR OP CODE.                    42360020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42380020
         DC    C'BCTR'                 BCTR OP CODE.                    42400020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42420020
         DC    C'BCR '                 BCR OP CODE.                     42440020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42460020
         DC    C'SSK '                 SSK OP CODE.                     42480020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42500020
         DC    C'ISK '                 ISK OP CODE.                     42520020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42540020
         DC    C'SVC '                 SVC INSTRUCTION.                 42560020
         DC    X'14'                   CODE=10,RR FORMAT-1 OPERAND.     42580020
         DC    3XL5'00'                CODE=00,INVALID OP CODE.         42600020
         DC    C'MVCL'                 MVCL OP CODE.  370.              42610020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42612020
         DC    C'CLCL'                 CLCL OP CODE.  370.              42614020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42616020
         DC    C'LPR '                 LPR OP CODE.                     42620020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42640020
         DC    C'LNR '                 LNR OP CODE.                     42660020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42680020
         DC    C'LTR '                 LTR OP CODE.                     42700020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42720020
         DC    C'LCR '                 LCR OP CODE.                     42740020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42760020
         DC    C'NR  '                 NR OP CODE.                      42780020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42800020
         DC    C'CLR '                 CLR OP CODE.                     42820020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42840020
         DC    C'OR  '                 OR OP CODE.                      42860020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42880020
         DC    C'XR  '                 XR OP CODE.                      42900020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42920020
         DC    C'LR  '                 LR OP CODE.                      42940020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    42960020
         DC    C'CR  '                 CR OP CODE.                      42980020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43000020
         DC    C'AR  '                 AR OP CODE.                      43020020
         DC    X'04'                   CODEV04,RR FORMAT-2 OPERANDS.    43040020
         DC    C'SR  '                 SR OP CODE.                      43060020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43080020
         DC    C'MR  '                 MR OP CODE.                      43100020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43120020
         DC    C'DR  '                 DR OP CODE.                      43140020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43160020
         DC    C'ALR '                 ALR OP CODE.                     43180020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43200020
         DC    C'SLR '                 SLR OP CODE.                     43220020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43240020
         DC    C'LPDR'                 LPDR OP CODE.                    43260020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43280020
         DC    C'LNDR'                 LNDR OP CODE.                    43300020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43320020
         DC    C'LTDR'                 LTDR OP CODE.                    43340020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43360020
         DC    C'LCDR'                 LCDR OF CODE.                    43380020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43400020
         DC    C'HDR '                 HDR OP CODE.                     43420020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43440020
         DC    C'LRDR'                 LRDR OP CODE.                    43460020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43480020
         DC    C'MXR '                 MXR OP CODE.                     43500020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43520020
         DC    C'MXDR'                 MXDR OP CODE.                    43540020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43560020
         DC    C'LDR '                 LDR OP CODE.                     43580020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43600020
         DC    C'CDR '                 CDR OP CODE.                     43620020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43640020
         DC    C'ADR '                 ADR OP CODE.                     43660020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43680020
         DC    C'SDR '                 SDR OP CODE.                     43700020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERADS.     43720020
         DC    C'MDR '                 MDR OP CODE.                     43740020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43760020
         DC    C'DDR '                 DDR OP CODE.                     43780020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43800020
         DC    C'AWR '                 AWR OP CODE.                     43820020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43840020
         DC    C'SWR '                 SWR OP CODE.                     43860020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43880020
         DC    C'LPER'                 LPER OP CODE.                    43900020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43920020
         DC    C'LNER'                 LNER OP CODE.                    43940020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    43960020
         DC    C'LTER'                 LTER OP CODE.                    43980020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44000020
         DC    C'LCER'                 LCER OP CODE.                    44020020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44040020
         DC    C'HER '                 HER OP CODE.                     44060020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44080020
         DC    C'LRER'                 LRER OP CODE.                    44100020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44120020
         DC    C'AXR '                 AXR OP CODE.                     44140020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44160020
         DC    C'SXR '                 SXR OP CODE.                     44180020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44200020
         DC    C'LER '                 LER OP CODE.                     44220020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44240020
         DC    C'CER '                 CER OP CODE.                     44260020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44280020
         DC    C'AER '                 AER OP CODE.                     44300020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44320020
         DC    C'SER '                 SER OP CODE.                     44340020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44360020
         DC    C'MER '                 MER OP CODE.                     44380020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44400020
         DC    C'DER '                 DER OP CODE.                     44420020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44440020
         DC    C'AUR '                 AUR OP CODE.                     44460020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44480020
         DC    C'SUR '                 SUR OP CODE.                     44500020
         DC    X'04'                   CODE=04,RR FORMAT-2 OPERANDS.    44520020
         DC    C'STH '                 STH OP CODE.                     44540020
         DC    X'28'                   CODE=28,RX FORMAT.               44560020
         DC    C'LA  '                 LA OP CODE.                      44580020
         DC    X'28'                   CODE=28,RX FORMAT.               44600020
         DC    C'STC '                 STC OP CODE.                     44620020
         DC    X'28'                   CODE=28,RX FORMAT.               44640020
         DC    C'IC  '                 IC  OP CODE.                     44660020
         DC    X'28'                   CODE=28,RX FORMAT.               44680020
         DC    C'EX  '                 EX OP CODE.                      44700020
         DC    X'28'                   CODE=28,RX FORMAT.               44720020
         DC    C'BAL '                 BAL OP CODE.                     44740020
         DC    X'28'                   CODE=28,RX FORMAT.               44760020
         DC    C'BCT '                 BCT OP CODE.                     44780020
         DC    X'28'                   CODE=28,RX FORMAT.               44800020
         DC    C'BC  '                 BC OP CODE.                      44820020
         DC    X'28'                   CODE=28,RX FORMAT.               44840020
         DC    C'LH  '                 LH OP CODE.                      44860020
         DC    X'28'                   CODE=28,RX FORMAT.               44880020
         DC    C'CH  '                 CH OP CODE.                      44900020
         DC    X'28'                   CODE=28,RX FORMAT.               44920020
         DC    C'AH  '                 AH OP CODE.                      44940020
         DC    X'28'                   CODE=28,RX FORMAT.               44960020
         DC    C'SH  '                 SH OP CODE.                      44980020
         DC    X'28'                   CODE=28,RX FORMAT.               45000020
         DC    C'MH  '                 MH OP CODE.                      45020020
         DC    X'28'                   CODE=28,RX FORMAT.               45040020
         DC    XL5'00'                 CODE=00,INVALID OP CODE.         45060020
         DC    C'CVD '                 CVD OP CODE.                     45080020
         DC    X'28'                   CODE=28,RX FORMAT.               45100020
         DC    C'CVB '                 CVB OP CODE                      45120020
         DC    X'28'                   CODE=28,RX FORMAT.               45140020
         DC    C'ST  '                 ST OP CODE.                      45160020
         DC    X'28'                   CODE=28,RX FORMAT.               45180020
         DC    3XL5'00'                CODE=00,INVALID OP CODE.         45200020
         DC    C'N   '                 N OP CODE.                       45220020
         DC    X'28'                   CODE=28,RX FORMAT.               45240020
         DC    C'CL  '                 CL OP CODE.                      45260020
         DC    X'28'                   CODE=28,RX FORMAT.               45280020
         DC    C'O   '                 O OP CODE.                       45300020
         DC    X'28'                   CODE=28,RX FORMAT.               45320020
         DC    C'X   '                 X OP CODE.                       45340020
         DC    X'28'                   CODE=28,RX FORMAT.               45360020
         DC    C'L   '                 L OP CODE                 A43371 45370021
         DC    X'28'                   CODE=28,RX FORMAT.               45400020
         DC    C'C   '                 C OP CODE.                       45420020
         DC    X'28'                   CODE=28,RX FORMAT.               45440020
         DC    C'A   '                 A OP CODE.                       45460020
         DC    X'28'                   CODE=28,RX FORMAT.               45480020
         DC    C'S   '                 S OP CODE.                       45500020
         DC    X'28'                   CODE=28,RX FORMAT.               45520020
         DC    C'M   '                 M OP CODE.                       45540020
         DC    X'28'                   CODE=28,RX FORMAT.               45560020
         DC    C'D   '                 D OP CODE.                       45580020
         DC    X'28'                   CODE=28,RX FORMAT.               45600020
         DC    C'AL  '                 AL OP CODE.                      45620020
         DC    X'28'                   CODE=28,RX FORMAT.               45640020
         DC    C'SL  '                 SL OP CODE.                      45660020
         DC    X'28'                   CODE=28,RX FORMAT.               45680020
         DC    C'STD '                 STD OP CODE.                     45700020
         DC    X'28'                   CODE=28,RX FORMAT.               45720020
         DC    6XL5'00'                CODE=00,INVALID OP CODE.         45740020
         DC    C'MXD '                 MXD OP CODE.                     45760020
         DC    X'28'                   CODE=28,RX FORMAT.               45780020
         DC    C'LD  '                 LD OP CODE.                      45800020
         DC    X'28'                   CODE=28,RX FORMAT.               45820020
         DC    C'CD  '                 CD OP CODE.                      45840020
         DC    X'28'                   CODE=28,RX FORMAT.               45860020
         DC    C'AD  '                 AD OP CODE.                      45880020
         DC    X'28'                   CODE=28,RX FORMAT.               45900020
         DC    C'SD  '                 SD OP CODE.                      45920020
         DC    X'28'                   CODE=28,RX FORMAT.               45940020
         DC    C'MD  '                 MD OP CODE.                      45960020
         DC    X'28'                   CODE=28,RX FORMAT.               45980020
         DC    C'DD  '                 DD OP CODE.                      46000020
         DC    X'28'                   CODE=28,RX FORMAT.               46020020
         DC    C'AW  '                 AW OP CODE.                      46040020
         DC    X'28'                   CODE=28,RX FORMAT.               46060020
         DC    C'SW  '                 SW OP CODE.                      46080020
         DC    X'28'                   CODE=28,RX OP CODE.              46100020
         DC    C'STE '                 STE OP CODE.                     46120020
         DC    X'28'                   CODE=28,RX FORMAT.               46140020
         DC    7XL5'00'                CODE=00,INVALID OP CODE.         46160020
         DC    C'LE  '                 LE OP CODE.                      46180020
         DC    X'28'                   CODE=28,RX FORMAT.               46200020
         DC    C'CE  '                 CE OP CODE.                      46220020
         DC    X'28'                   CODE=28,RX FORMAT.               46240020
         DC    C'AE  '                 AE OP CODE.                      46260020
         DC    X'28'                   CODE=28,RX FORMAT.               46280020
         DC    C'SE  '                 SE OP CODE.                      46300020
         DC    X'28'                   CODE=28,RX FORMAT.               46320020
         DC    C'ME  '                 ME OP CODE.                      46340020
         DC    X'28'                   CODE=28,RX FORMAT.               46360020
         DC    C'DE  '                 DE OP CODE.                      46380020
         DC    X'28'                   CODE=28,RX FORMAT.               46400020
         DC    C'AU  '                 AU OP CODE.                      46420020
         DC    X'28'                   CODE=28,RX FORMAT.               46440020
         DC    C'SU  '                 SU OP CODE.                      46460020
         DC    X'28'                   CODE=28,RX FORMAT.               46480020
         DC    C'SSM '                 SSM OP CODE.                     46500020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 46520020
         DC    XL5'00'                 CODE=00 INVALID OP CODE.         46540020
         DC    C'LPSW'                 LPSW OP CODE.                    46560020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 46580020
         DC    C'DIAG'                 DIAGNOSE INSTRUCTION.            46600020
         DC    X'18'                   CODE=18,DIAGNOSE FOR CE.         46620020
         DC    C'WRD '                 WRD OP CODE.                     46640020
         DC    X'18'                   CODE=18,5I FORMAT.               46660020
         DC    C'RDD '                 RDD OP CODE.                     46680020
         DC    X'18'                   CODE=18,SI FORMAT.               46700020
         DC    C'BXH '                 BXH OP CODE.                     46720020
         DC    X'0C'                   CODE=0C,RS FORMAT.               46740020
         DC    C'BXLE'                 BXLE OP CODE.                    46760020
         DC    X'0C'                   CODE=0C,RS FORMAT.               46780020
         DC    C'SRL '                 SRL OP CODE.                     46800020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      46820020
         DC    C'SLL '                 SLL OP CODE.                     46840020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      46860020
         DC    C'SRA '                 SRA OP CODE.                     46880020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      46900020
         DC    C'SLA '                 SLA OP CODE.                     46920020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      46940020
         DC    C'SRDL'                 SRDL OP CODE.                    46960020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      46980020
         DC    C'SLDL'                 SLDL OP CODE.                    47000020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      47020020
         DC    C'SRDA'                 SRDA OP CODE.                    47040020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      47060020
         DC    C'SLDA'                 SLDA OP CODE.                    47080020
         DC    X'10'                   CODE=10,RS FORMAT WITH 1 R.      47100020
         DC    C'STM '                 STM OP CODE.                     47120020
         DC    X'0C'                   CODE=0C,RS FORMAT.               47140020
         DC    C'TM  '                 TM OP CODE.                      47160020
         DC    X'18'                   CODE=1C,SI FORMAT.               47180020
         DC    C'MVI '                 MVI OP CODE.                     47200020
         DC    X'18'                   CODE=1C,SI FORMAT.               47220020
         DC    C'TS  '                 TS OP CODE.                      47240020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 47260020
         DC    C'NI  '                 NI OP CODE.                      47280020
         DC    X'18'                   CODE=18,SI FORMAT.               47300020
         DC    C'CLI '                 CLI OP CODE.                     47320020
         DC    X'18'                   CODE=18,SI FORMAT.               47340020
         DC    C'OI  '                 OI OP CODE.                      47360020
         DC    X'18'                   CODE=18,SI FORMAT.               47380020
         DC    C'XI  '                 XI OP CODE.                      47400020
         DC    X'18'                   CODE=18,SI FORMAT.               47420020
         DC    C'LM  '                 LM OP CODE.                      47440020
         DC    X'0C'                   CODE=0C,RS FORMAT.               47460020
         DC    3XL5'00'                CODE=00,INVALID OP CODE.         47480020
         DC    C'SIO '                 SIO OP CODE.                     47500020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 47520020
         DC    C'TIO '                 TIO OP CODE.                     47540020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 47560020
         DC    C'HIO '                 HIO OP CODE.                     47580020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 47600020
         DC    C'TCH '                 TCH OP CODE.                     47620020
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT THE I. 47640020
         DC    15XL5'00'               CODE=00,INVALID OP CODES. A43355 47660021
         DC    C'MC  '                 MC OP CODE. 370           A43355 47660121
         DC    X'18'                   CODE=18,SI FORMAT         A43355 47660221
         DC    6XL5'00'                CODE=00,INVALID OP CODES. A43355 47660421
         DC    C'TCTL'                 STCTL OP CODE. 370               47662020
         DC    X'0C'                   CODE=0C,RS FORMAT                47664020
         DC    C'LCTL'                 LCTL OP CODE. 370.               47670020
         DC    X'0C'                   CODE=0C,RS FORMAT.               47672020
         DC    5XL5'00'                CODE=00,INVALID OP CODES.        47674020
         DC    C'CLM '                 CLM OP CODE. 370.                47676020
         DC    X'0C'                   CODE=0C,R1,M3.                   47678020
         DC    C'STCM'                 STCM OP CODE. 370.               47678420
         DC    X'0C'                   CODE=0C,R1,M3.                   47678820
         DC    C'ICM '                 ICM OP CODE. 370.                47679220
         DC    X'0C'                   CODE=0C,R1,M3.                   47679620
         DC    17XL5'00'               CODE=00,INVALID OP CODES.        47679720
         DC    C'MVN '                 MVN OP CODE.                     47680020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47700020
         DC    C'MVC '                 MVC OP CODE.                     47720020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47740020
         DC    C'MVZ '                 MVZ OP CODE.                     47760020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47780020
         DC    C'NC  '                 NC OP CODE.                      47800020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47820020
         DC    C'CLC '                 CLC OP CODE.                     47840020
         DC    X'20'                   CODE=20,SS FORAMT L1.            47860020
         DC    C'OC  '                 OC OP CODE.                      47880020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47900020
         DC    C'XC  '                 XC OP CODE.                      47920020
         DC    X'20'                   CODE=20,SS FORMAT L1.            47940020
         DC    4XL5'00'                CODE=00,INVALID OP CODE.         47960020
         DC    C'TR  '                 TR OP CODE.                      47980020
         DC    X'20'                   CODE=20,SS FORMAT L1.            48000020
         DC    C'TRT '                 TRT OP CODE.                     48020020
         DC    X'20'                   CODE=20,SS FORMAT L1.            48040020
         DC    C'ED  '                 ED OP CODE.                      48060020
         DC    X'20'                   CODE=20,SS FORMAT L1.            48080020
         DC    C'EDMK'                 EDMK OP CODE.                    48100020
         DC    X'20'                   CODE=20,SS FORMAT L1.            48120020
         DC    16XL5'00'               CODE=00,INVALID OP CODE.         48140020
         DC    C'SRP '                  SRP OP CODE. 370.               48150020
         DC    X'20'                   CODE=20 SS FORMAT L1 WITH I.     48152020
         DC    C'MVO '                 MVO OP CODE.                     48160020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48180020
         DC    C'PACK'                 PACK OP OCDE.                    48200020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48220020
         DC    C'UNPK'                 UNPK OP CODE.                    48240020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48260020
         DC    4XL5'00'                CODE=00,INVALID OP CODE.         48280020
         DC    C'ZAP '                 ZAP OP CODE.                     48300020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48320020
         DC    C'CP  '                 CP OP CODE.                      48340020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48360020
         DC    C'AP  '                 AP OP CODE.                      48380020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48400020
         DC    C'SP  '                 SP OP CODE.                      48420020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48440020
         DC    C'MP  '                 MP OP CODE.                      48460020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48480020
         DC    C'DP  '                 DP OP CODE.                      48500020
         DC    X'24'                   CODE=24,SS FORMAT L1 & L2.       48520020
         DC    2XL5'00'                CODE=00,INVALID OP CODE.         48540020
OPTABLN  EQU   *-IKJEGCOP              LENGTH OF ONE BYTE OP TABLE      48542020
         SPACE                                                          48544020
*********************************************************************** 48550020
* BEGINNING OF 370 TWO BYTE OP CODE TABLE. EACH OP CODE BEGINS WITH   * 48552020
* ONE BYTE OF B2 AND THEN ANOTHER UNIQUE SECOND BYTE. THIS TABLE      * 48554020
* INCLUDES ONLY UP TO THE STCK OP CODE AND CAN BE EXPANDED IN THE     * 48556020
* FUTURE IF NECESSARY.                                                * 48558020
*********************************************************************** 48558420
         SPACE                                                          48558820
         DC    2XL5'00'                CODE=00,INVALID OP CODES.        48559220
         DC    C'TIDP'                 STIDP OP CODE. 370.              48559620
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT I.     48559720
         DC    C'TIDC'                 STIDC OP CODE. 370.              48559820
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT I.     48559920
         DC    C'SCK '                 SCK OP CODE. 370.                48566620
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT I.     48568620
         DC    C'STCK'                 STCK OP CODE. 370.               48570620
         DC    X'1C'                   CODE=1C,SI FORMAT WITHOUT I.     48572620
         TITLE 'IKJEGCVT' CVT MESSAGE CSECT.                            48573320
IKJEGFLT CSECT                                                          48580020
         SPACE                                                          48600020
*********************************************************************** 48620020
*                                                                     * 48640020
* THIS CSECT IS AN EXTENSION OF THE CONVERT ROUTINE(IKJEGCVT).  THE   * 48660020
* FOLLOWING LINES OF CODE IN THIS CSECT WILL CONVERT THE FLOATING     * 48680020
* POINT DATA.                                                         * 48700020
*********************************************************************** 48720020
         SPACE                                                          48740020
REMAIN   EQU   X'01'                                                    48760020
AONE1    EQU   X'F1'                                                    48780020
AFIVE    EQU   C'5'                                                     48800020
DOBLEND  EQU   24                      END OF DOUBLE ZONED DECIMAL.     48820020
ADJUST37 EQU   37                                                       48840020
SINGEND  EQU   15                      END OF SINGLE ZONED DECIMAL.     48860020
OFFSET39 EQU   39                                                       48880020
CARRYVAL EQU   X'F1'                   ZONED DECIMAL 1.                 48900020
HEX85    EQU   X'85'                                                    48920020
HEX10    EQU   X'10'                                                    48940020
HEX0C    EQU   X'0C'                                                    48960020
THREE0   EQU   30                                                       48980020
FIVE6    EQU   56                                                       49000020
HEX1C    EQU   X'1C'                                                    49040020
OFFSET40 EQU   40                                                       49060020
FIVE3    EQU   53                                                       49080020
FIVE4    EQU   54                                                       49100020
HEX20    EQU   X'20'                                                    49120020
SIX4     EQU   64                                                       49140020
ONE8     EQU   18                                                       49160020
         ENTRY IKJEGFTB                                                 49180020
         ENTRY IKJEGBFT                                                 49200020
         SPACE                                                          49220020
*********************************************************************** 49240020
*                                                                     * 49260020
* THE FOLLOWING INSTRUCTIONS CONVERT A FLOATING POINT BINARY VALUE    * 49280020
* TO ITS PRINTABLE FORMAT.                                            * 49300020
*                                                                     * 49320020
*********************************************************************** 49340020
         SPACE                                                          49360020
IKJEGBFT EQU   *                                                        49380020
         LR    R12,R15                 R12= ADDRESS OF IKJEGFLT.        49400020
         USING IKJEGFLT,R12            IKJEGFLT ADDRESSABILITY.         49420020
         L     R3,WORKAREA             R3=ADDRESS OF WORKAREA.          49440020
         USING CVTWORK,R3              WORKAREA ADDRESSABILITY.         49460020
         LH    R6,FOUR(R1)             R6=LENGTH OF INPUT.              49480020
         LR    R0,R6                   SAVE LENGTH OF INPUT.            49500020
         L     R1,ZERO(R1)             R1=ADDRESS OF INPUT STRING.      49520020
         XC    FLTINPUT,FLTINPUT       CLEAR INPUT AREA OF GARBAGE.     49540020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               49560020
         BCTR  R6,ZERO                 *                                49580020
         LTR   R6,R6                   Q.SKIP MOVE INSTRUCTION.         49600020
         BM    SKIPMOVE                YES,SKIP MOVE INSTRUCTION.       49620020
         EX    R6,FLTMOVE              MOVE INPUT INTO WORKAREA.        49640020
SKIPMOVE EQU   *                                                        49660020
         LM    R4,R5,FLTINPUT          INPUT NOW IN WORK REGISTERS.     49680020
         IC    R7,ZERO(R1)             R7=CHARACTERISTICS.              49700020
         N     R7,SIGNOFF              TURN OFF FRACTION SIGN.          49720020
         LTR   R6,R6                   Q.EXP ONLY SPECIFIED.            49740020
         BM    EXPONLY                 YES,CONVERT EXPONENT.            49760020
         LTR   R4,R4                   Q.ZERO FRACTION SPECIFIED.       49780020
         BNZ   NONZERO                 NO, GO GET EXPONENT.     SA60586 49792021
         LTR   R5,R5                   Q.IS THIS SINGLE         SA60586 49794021
*                                      PRECISSION.                      49796021
         BZ    ZEROFRAC                YES,PASS A ZERO.                 49800020
NONZERO  DS    0H                                               SA60586 49810021
         SH    R7,FLTCHAR              DECIMAL POINT NOW 6 DIGITS TO    49820020
*                                      RIGHT AND EXP VALUE DETERMINE.   49840020
         LTR   R5,R5                   Q.IS THIS SINGLE PRECISION.      49860020
         BNZ   FLTLONG                 NO,CONVERT LONG PRECISION.       49880020
         SPACE                                                          49900020
*********************************************************************** 49920020
* THIS SECTION OF CODE WILL CONVERT THE FRACTION OF A SINGLE          * 49940020
* PRECISION FLOATING POINT BINARY TO ZONED DECIMAL                    * 49960020
*********************************************************************** 49980020
         SPACE                                                          50000020
         CVD   R4,PACKAREA             FRACTION NOW CONVERTED TO PACKED 50020020
         OI    PACKAREA+SEVEN,SIGNF    DECIMAL.                         50040020
         UNPK  FLTSTG(ONE5),PACKAREA   FRACTION NOW ZONED DECIMAL       50060020
         LA    R6,FLTSTG+ONE5          R6=ADDR OF END OF ZONED DEC.     50080020
SUPPRESS EQU   *                                                        50100020
* THE FOLLOWING INSTRUCTIONS SUPPRESSES LEADING ZEROES.               * 50120020
         SPACE                                                          50140020
         LA    R8,FLTSTG               R8=ADDR OF ZONED DATA.           50160020
FLTLOOP  EQU   *                                                        50180020
         CLI   ZERO(R8),F0             SUPPRESS INSIGNIFICANT LEADING   50200020
         BNE   SIGFOUND                ZEROES.                          50220020
         LA    R8,ONE(R8)              GET NEXT DIGIT.                  50240020
         B     FLTLOOP                 CHECK NEXT DIGIT.                50260020
SIGFOUND EQU   *                                                        50280020
         SR    R2,R2                   R0=0                             50300020
         SR    R6,R8                   R6=LENGTH OF SIGNIFICANT DATA.   50320020
         STH   R6,FLTLEN               LENGTH NOW IN SAVE AREA.         50340020
         LTR   R7,R7                   Q.WHICH TYPE OF CVT IS NEEDED.   50360020
         BP    FLTADD                  DECIMAL ADD TO ITSELF.           50380020
         BM    FLTDIV                  DIVISION BY TWO.                 50400020
         EX    R6,ZONEMOVE             LEFT JUSTIFY ZONED DATA.         50420020
        LA     R8,FLTSTG                                                50440020
        LA     R8,ZERO(R6,R8)                                           50460020
         B     CHAR                    COMPUTE EXP VALUE.               50480020
FLTADD   EQU   *                                                        50500020
         SPACE                                                          50520020
*********************************************************************** 50540020
*                                                                     * 50560020
* THE FOLLOWING INSTRUCTIONS CONVERT THE ZONED DECIMAL FRACTION TO ITS* 50580020
* PROPER INTEGER FORM.                                                * 50600020
*                                                                     * 50620020
*********************************************************************** 50640020
         SPACE                                                          50660020
         LA    R5,FLTSTG+OFFSET40      MANTISSA RIGHT ALIGNED.          50680020
         SLL   R7,TWO                  MULTIPLY EXP BY FOUR.            50700020
         SR    R5,R6                   R5=PTR TO NEW WORKAREA.          50720020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               50740020
         EX    R6,ALIGNMVC             MOVE FRACTION FOR ADDITION.      50760020
GETLEN   LH    R6,FLTLEN               R6=LENGTH OF FRACTION.           50780020
FLTSIM   EQU   *                                                        50800020
         LA    R8,FLTSTG+OFFSET39      SET UP TO BEGIN ADD.             50820020
         SR    R5,R5                   R5=0                             50840020
ADDNEXT  IC    R4,ZERO(R8)             R4=BYTE TO BE CONVERTED.         50860020
         N     R4,FLTCLEAR             R4=4 BIT VALUE.                  50880020
         AR    R4,R4                   ADD DIGIT TO ITSELF.             50900020
         AR    R4,R5                   ADD PREVIOUS CARRY.              50920020
         LA    R5,ONE                  R5=CARRY VALUE.                  50940020
         SH    R4,FLT10                IS THERE A CARRY.                50960020
         BNM   ACARRY                  YES.                             50980020
         AH    R4,FLT10                RESTORE VALUE.                   51000020
         SR    R5,R5                   CLEAR CARRY VALUE.               51020020
ACARRY   EQU   *                                                        51040020
         LA    R4,F0(R4)               CONVERT VALUE TO PRINTABLE.      51060020
         STC   R4,ZERO(R8)             SAVE THE RESULTS.                51080020
         BCTR  R8,ZERO                 ADJUST POINTER.                  51100020
         BCT   R6,ADDNEXT              ADD NEXT BYTE.                   51120020
         LH    R6,FLTLEN               R6=LENGTH.                       51140020
         LTR   R5,R5                   Q.IS THERE A CARRY.              51160020
         BZ    LASTZERO                NO,DO NOT MOVE IN A 1.           51180020
         MVI   ZERO(R8),AONE1          MOVE IN A PRINTABLE 1.           51200020
         BCTR  R8,ZERO                 POINT TO NEXT BYTE.              51220020
         AR    R6,R5                   UPDATE NUMBER OF DIGITS.         51240020
         STH   R6,FLTLEN               SAVE LENGTH.                     51260020
         LA    R5,FLTSTG               R5=ADDR OF WORK AREA.            51280020
         CR    R5,R8                   ANY TRUNCATION NEEDED.           51300020
         BE    TRUNCATE                YES.                             51320020
LASTZERO BCT   R7,FLTSIM               NO.                              51340020
         LA    R8,ONE(R8)              ADJUST ZONE DECIMAL POINTER.     51360020
         EX    R6,ZONEMOVE             ADJUST ZONED DECIMAL.            51380020
         LA    R8,FLTSTG               R8=ADDR OF ZONE DECIMAL.         51400020
         CH    R6,FLT17          Q.ZONE DECIMAL TOO LONG.               51420020
         BL    NOTLONG           NO,SKIP LENGTH CORRECTION.             51440020
         LA    R8,ONE7(R8)                                              51460020
         MVI   FLTLEN+ONE,ONE7   NEW LENGTH IN LENGTH FIELD.            51480020
         B     CHAR              GO CONVERT CHARACTERISTICS.            51500020
NOTLONG  EQU   *                                                        51520020
         LA    R8,ZERO(R6,R8)          R8=PTR TO END OF ZONED DATA.     51540020
         B     CHAR                    GO CONVERT CHARACTERISTICS.      51560020
TRUNCATE EQU   *                                                        51580020
         SH    R6,FLTDEC2              CORRECT LENGTH FOR TRUNCATION.   51600020
         STH   R6,FLTLEN               NEW LNG IN LNG SAVE AREA.        51620020
         SH    R2,FLTDEC2                                               51640020
         LA    R8,FLTSTG+ADJUST37      RIGHT ADJUST THE NUMBER          51660020
FBYTEMVC MVC   TWO(ONE,R8),ZERO(R8)    IN WORK AREA.                    51680020
         BCTR  R8,ZERO                 ALTER POINTER TO NEXT TYTE.      51700020
         BCT   R6,FBYTEMVC             GET NEXT BYTE.                   51720020
         LH    R6,FLTLEN               R6=NEW LENGTH.                   51740020
         CH    R7,HALFONE              Q.LAST MULTIPLY.                 51760020
         BNE   NOTLAST                 NO,DO NOT ALTER POINTER.         51780020
         LA    R8,TWO(R8)              R8=PT TO SIGNIFICANT DIGITS.     51800020
NOTLAST  EQU   *                                                        51820020
         B     LASTZERO                CHECK FOR MORE VALUES TO ADD.    51840020
FLTDIV   EQU   *                                                        51860020
         SPACE                                                          51880020
*********************************************************************** 51900020
*                                                                     * 51920020
* THE FOLLOWING LINES OF CODE CONVERTS THE ZONED DECIMAL MANTISSA TO  * 51940020
* ITS PROPER ZONED DECIMAL MANTISSA.                                  * 51960020
*                                                                     * 51980020
*********************************************************************** 52000020
         SPACE                                                          52020020
         LPR   R7,R7                   R7,NOW POSITIVE.                 52040020
         SLL   R7,TWO                  MULTIPLY BY FOUR.                52060020
         BCTR  R6,ZERO                 R6=LENGTH OF ZONED DECIMAL.      52080020
         EX    R6,ZONEMOVE             LEFT JUSTIFY ZONED DECIMAL.      52100020
SCALE    LH    R6,FLTLEN               LENGTH NOW IN REGISTER.          52120020
         SR    R5,R5                   R5=ZERO.                         52140020
         LA    R8,FLTSTG               R8=POINTER TO ZONED DECIMAL.     52160020
         CLI   ZERO(R8),AZERO          CHECK TO SUPPRESS LEADING ZEROS. 52180020
         BNE   NEXTDIV                 BRANCH PROCESS DIGIT.            52200020
         BCTR  R6,ZERO                 DECREMENT LENGTH.                52220020
         STH   R6,FLTLEN               SAVE CORRECT LENGTH.             52240020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               52260020
         EX    R6,ZONEJUST             LEFT JUSTIFY THE SIGNIF.DIGITS.  52280020
         SR    R5,R5                   R5=ZERO.                         52300020
         LA    R6,ONE(R6)              R6=CORRECT LENGTH.               52320020
NEXTDIV  EQU   *                                                        52340020
         IC    R4,ZERO(R8)             SIMULATE DIVISION BY TWO.        52360020
         N     R4,FLTCLEAR             R4=4 BIT VALUE.                  52380020
         SRL   R4,ONE                  R4=VALUE DIVIDED BY TWO.         52400020
         AR    R4,R5                   COMBINE THE PARTIAL QUOTIENT.    52420020
         LA    R4,F0(R4)               VALUE NOW PRINTABLE CHARACTER.   52440020
         SR    R5,R5                   R5=ZERO.                         52460020
         TM    ZERO(R8),REMAIN         CHECK FOR REMAINDER.             52480020
         BZ    SKIPCARY                SKIP CARRY FLAG SET.             52500020
         LA    R5,FIVE                 R5=5,CARRY FLAG.                 52520020
SKIPCARY EQU   *                                                        52540020
         STC   R4,ZERO(R8)             MOVE NEW VALUE IN STRING.        52560020
         LA    R8,ONE(R8)              UPDATE STRING POINTER.           52580020
         BCT   R6,NEXTDIV              BRANCH TO PROCESS NEXT DIGIT.    52600020
         LH    R6,FLTLEN               R6=CORRECT LENGTH.               52620020
         LTR   R5,R5                   ANY FINAL PARTIAL QUOTIENT.      52640020
         BZ    NOFINAL                 NO,SKIP FINAL ADJUSTMENT.        52660020
         CH    R6,FLT20                Q.FINAL PARTIAL QUOTIENT.        52680020
         BNL   ADJUSTIT                YES,ADJUST RESULTS.              52700020
         MVI   ZERO(R8),AFIVE          MOVE IN A CHARACTER FIVE.        52720020
         LA    R2,ONE(R2)              INCREMENT POINTER.               52740020
         LA    R6,ONE(R6)                                               52760020
         STH   R6,FLTLEN               SAVE LENGTH.                     52780020
JUSTEND  EQU   *                                                        52800020
         LA    R8,ONE(R8)              UPDATE POINTER.                  52820020
NOFINAL  EQU   *                                                        52840020
         BCT   R7,SCALE                BRANCH IF SCALING IS NOT ZERO.   52860020
CHAR     EQU   *                                                        52880020
*********************************************************************** 52900020
*                                                                     * 52920020
* THE FOLLOWING LINES OF CODE CALCULATE THE NUMBER OF SIGNIFICANT     * 52940020
* DIGITS AND ROUND OFF THE SIGNIFICANTS.                              * 52960020
*                                                                     * 52980020
*********************************************************************** 53000020
         SPACE                                                          53020020
         CLI   FLTSTG,AZERO            Q.AN ZERO.                       53040020
         BNE   NOZERO                  NO,CONTINUE PROCESSING.          53060020
         BCTR  R8,ZERO                 DECREMENT R8 BY ONE       A49893 53070021
         LH    R6,FLTLEN               R6 = LENGTH               A49893 53072021
         BCTR  R6,ZERO                 DECREMENT THE LEN BY ONE  A49893 53074021
         STH   R6,FLTLEN               STORE THE LENGTH AWAY     A49893 53076021
         EX    R6,MOVEFLT              LEFT JUSTIFY ZONE DECIMAL.       53100020
NOZERO   EQU   *                                                        53120020
         LR    R4,R0                   R4=LENGTH OF INPUT.              53140020
         BCTR  R4,ZERO                 R4=FRACTION LENGTH.              53160020
         LR    R5,R4                   R5=FRACTION LENGTH.              53180020
         SLL   R4,ONE                  ******************************** 53200020
         LA    R5,ONE(R5)              * CALCULATE THE NUMBER OF      * 53220020
         SRL   R5,ONE                  * SIGNIFICANT DIGITS.          * 53240020
         AR    R4,R5                   ******************************** 53260020
         CH    R4,FLT17                Q.LENGTH GREATER THAN 16.        53280020
         BL    NOALTER                 NO,DO NOT ALTER LENGTH.          53300020
         BCTR  R4,ZERO                 R4=CORRECT SIGNIFICANT LENGTH.   53320020
NOALTER  EQU   *                                                        53340020
         CH    R4,FLTLEN               Q.SIGNIFICANT GREATER THAN LENG. 53360020
         BH    ENDSIGNF                NO,SKIP SIGNIFICANT ALTER.       53380020
         LR    R0,R4                   R0=NUMBER OF SIGNIFICANT DIGITS. 53400020
         LA    R5,ONE                  R5=1.                            53420020
         NR    R5,R4                   Q.LENGTH ODD.                    53440020
         BM    SKIPSHIF                YES,DO NOT SHIFT.                53460020
         BCTR  R4,ZERO                 SET UP EVEN SIGNIFICANT.         53480020
SKIPSHIF EQU   *                                                        53500020
         SRL   R4,ONE                  CALCULATE NUMBER OF OUTPUT BUTES 53520020
         LA    R4,ONE(R4)              FOR PACK INSTRUCTION.            53540020
         CH    R0,FLT17                Q.INPUT 17 BYTES.                53560020
         BE    SIMPACK                 YES,SIMULATE PACK INSTRUCTION.   53580020
         LR    R5,R0                   R5=NUMBER OF SIGNIFICANT DIGITS. 53600020
         BCTR  R5,ZERO                 R5=EXECUTE LENGTH.               53620020
         SLL   R4,FOUR                 R4=LENGTH IN HIGH OFDER 4 BITS.  53640020
         OR    R5,R4                   R5=LENGTH 1 AND LENGTH 2.        53660020
         EX    R5,ROUNDPK              PACK SIGNIFICANT DIGITS.         53680020
         SRL   R5,FOUR                 CLEAR LENGTH 2.                  53700020
         SLL   R5,FOUR                 *                                53720020
         EX    R5,ADD5                 ADD 5 TO SIGNIFICANT DIGITS.     53740020
         LR    R4,R0                   R4=LENGTH OF SIGNIFICANT DIGITS. 53760020
         BCTR  R4,ZERO                 R4=EXECUTE LENGTH.               53780020
         SLL   R4,FOUR                 R4=LENGTH 1 IN HIGH ORDER 4 BITS 53800020
         SRL   R5,FOUR                 R5=LENGTH 2 IN LOW ORDER.        53820020
         LA    R7,ONE                  R7=1,FOR EVEN ODD CHECK.         53840020
         NR    R7,R0                   Q.SIGNIFICANTS ODD.              53860020
         BM    ODDSIGNF                YES,CHECK FOR CARRY.             53880020
         CLI   FLTINPUT,HEX9           Q.IS THERE A CARRY.              53900020
         BNH   NOEXPJST                NO,DO NOT ADJUST.                53920020
ANEXPJST EQU   *                                                        53940020
         BCTR  R2,ZERO                 ACCOUNT FOR EXPONENT.            53960020
         LA    R4,ONE6(R4)              ACCOUNT FOR CARRY DIGIT.        53980020
NOEXPJST EQU   *                                                        54000020
         OR    R5,R4                   R5=LENGTH 1 AND 2.               54020020
         EX    R5,UNPKSIG              UNPACK SIGNIFICANT DIGITS.       54040020
ENDSIG   EQU   *                                                        54060020
         LR    R8,R0                   R8=NUMBER OF SIGNIFICANT DIGITS. 54080020
         STH   R8,FLTLEN               CORRECT LENGTH IN SAVE AREA.     54100020
         LA    R5,FLTSTG               R5=ADDR OF SIGNIFICANT DIGITS.   54120020
         LA    R8,ZERO(R5,R8)          R8=PTR TO END OF SIGNIFICANTS.   54140020
         BCTR  R8,ZERO                 POINT TO LAST BYTE.              54160020
         OI    ZERO(R8),HEXF0          ALTER SIGN TO PRINTABLE.         54180020
         LA    R8,ONE(R8)              R8=PTR TO END OF SIGNIFICANTS.   54200020
         B     ENDSIGNF                CALCULATE EXPONENT.              54220020
ODDSIGNF EQU   *                                                        54240020
         CLI   FLTINPUT,HEX00          Q.IS THERE A CARRY.              54260020
         BE    NOEXPJST                NO,DO NOT ADJUST.                54280020
         B     ANEXPJST                YES,ACCOUNT FOR EXPONENT.        54300020
         SPACE                                                          54320020
*********************************************************************** 54340020
*                                                                     * 54360020
* THIS AREA OF CODE PACKS AN AREA 17 BYTES IN LENGTH AND ROUNDS THE   * 54380020
* VALUE.                                                              * 54400020
*                                                                     * 54420020
*********************************************************************** 54440020
         SPACE                                                          54460020
SIMPACK  EQU   *                                                        54480020
         PACK  FLTINPUT(NINE),FLTSTG(ONE6) PACK FIRST 15 BYTES.         54500020
         PACK  FLTINPUT+EIGHT(TWO),FLTSTG+ONE5(THREE) NEXT THREE.       54520020
         OI    FLTINPUT+NINE,SIGNF   SIGN ALTERED FOR ADD.              54540020
         MVC   FLTSTG(ONE9),FLTPATTN PATTERN NOW IN WORKAREA.           54560020
         AP    FLTINPUT(TEN),PACK5(ONE) ROUND VALUE.                    54580020
         CLI   FLTINPUT,HEX9           Q.IS THERE A CARRY.              54600020
         BNH   NOJSTEXP                NO,DO NOT ADJUST.                54620020
         BCTR  R2,ZERO                 ACCOUNT FOR EXPONENT.            54640020
NOJSTEXP EQU   *                                                        54660020
         ED    FLTSTG(TWO0),FLTINPUT   SIGNIFICANTS NOW ZONED DECIMAL.  54680020
         LA    R8,FLTSTG               R8=POINTER TO FLTSTG.            54700020
FINDNO0  EQU   *                                                        54720020
         CLI   ZERO(R8),AZERO          Q.NON-ZERO FOUND.                54740020
         BNE   JUSTSNFT                YES,LEFT JUSTIFY.                54760020
         LA    R8,ONE(R8)              POINT TO NEXT BYTE.              54780020
         B     FINDNO0                 GET NEXT BYTE.                   54800020
JUSTSNFT EQU   *                                                        54820020
         MVC   FLTSTG(ONE7),ZERO(R8)   LEFT JUSTIFY VALUE.              54840020
         B     ENDSIG                  END SIGNIFICANTS.                54860020
ENDSIGNF EQU   *                                                        54880020
         SR    R6,R2                   R6=EXPONENT VALUE.               54900020
         MVC   ZERO(FIVE,R8),EXPCHAR   EXPONENT PATTERN IN STRING.      54920020
         LTR   R6,R6                   IS EXPONENT NEGATIVE.            54940020
         BNM   SKIPNEG                 SKIP NEGATIVE SIGN MOVE.         54960020
         MVI   TWO(R8),SIGNNEG         NEGATIVE SIGN NOW IN STRING.     54980020
SKIPNEG  EQU   *                                                        55000020
         CVD   R6,PACKAREA             EXPONENT NOW PACKED DECIMAL.     55020020
         OI    PACKAREA+SEVEN,SIGNF    SIGN NOW X'F'.                   55040020
         UNPK  THREE(TWO,R8),PACKAREA+SIX(TWO) EXPONENT NOW IN STRING.  55060020
         CLI   THREE(R8),AZERO         IS FIRST CHARACTER A ZERO.       55080020
         BNE   BLKSKIP                 NO,DO NOT MOVE IN A BLANK.       55100020
         MVI   THREE(R8),BLANK         FIRST CHARACTER NOW A BLANK.     55120020
BLKSKIP  EQU   *                                                        55140020
         LA    R8,FLTSTG-TWO           R8=ADDRESS FOR MANTISSA SIGN.    55160020
         MVC   ZERO(TWO,R8),FRACSIGN   FRACTION + SIGN NOW IN STRING.   55180020
         TM    ZERO(R1),HION           IS FRACTION NEGATIVE.            55200020
         BZ    PLUSFRAC                NO,DO NOT MOVE IN NEGATIVE SIGN. 55220020
         MVI   ZERO(R8),MINUS          MINUS SIGN NOW IN STRING.        55240020
PLUSFRAC EQU   *                                                        55260020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       55280020
         LH    R6,FLTLEN               R6=LENGTH OF MANTISSA.           55300020
         LA    R6,SEVEN(R6)            R6=LENGTH OF OUTPUT STRING.      55320020
         STC   R6,ZERO(R2)             LENGTH OF OUTPUT NOW IN CONAREA. 55340020
         BCTR  R6,ZERO                 R6=EXECUTE LENGTH.               55360020
         EX    R6,OUTMVC               MOVE STRING INTO OUTPUT AREA.    55380020
ENDFLT   SR    R15,R15                 R15=ZERO.                        55400020
         BR    R14                     RETURN TO CALLER.                55420020
*********************************************************************** 55440020
*                                                                     * 55460020
* THE FOLLOWING LINES OF CODE CALCULATE THE EXPONENT AND MOVE IT'S    * 55480020
* PRINTABLE REPRESENTATION INTO CONAREA.                              * 55500020
*                                                                     * 55520020
*********************************************************************** 55540020
         SPACE                                                          55560020
EXPONLY  EQU   *                                                        55580020
         L     R2,CONAREA              R2=ADDR OF CONAREA.              55600020
         SH    R7,FLT64                R7=EXPONENT IN BINARY.           55620020
         MVC   ONE(FOUR,R2),EXPCHAR+ONE EXPONENT SIGN NOW IN CONAREA.   55640020
         LTR   R7,R7                   Q.EXPONENT NEGATIVE.             55660020
         BNM   PLUSEXP2                NO,SKIP COMPLEMENT.              55680020
         MVI   TWO(R2),MINUS           NEGATIVE SIGN NOW IN CONAREA.    55700020
PLUSEXP2 EQU   *                                                        55720020
         CVD   R7,PACKAREA             EXP NOW PACKED DECIMAL.          55740020
         OI    PACKAREA+SEVEN,SIGNF    SIGN NOW X'F'.                   55760020
         UNPK  FLTSTG(TWO),PACKAREA+SIX(TWO) EXP NOW ZONED DECIMAL.     55780020
         CLI   FLTSTG,F0               Q.FIRST CHAR A ZERO.             55800020
         BNE   NOF0                    NO,DO NOT MOVE IN BLANK.         55820020
         MVI   FLTSTG,BLANK            BLANK NOW IN EXP FIELD.          55840020
NOF0     EQU   *                                                        55860020
         MVC   THREE(TWO,R2),FLTSTG    EXP NOW IN CONAREA.              55880020
         MVI   ZERO(R2),FOUR           LENGTH NOW IN CONAREA.           55900020
         B     ENDFLT                  SET RETURN CODE & RETURN.        55920020
*********************************************************************** 55940020
*                                                                     * 55960020
* THIS SECTION OF CODE MOVES INTO CONAREA(OUTPUT AREA) THE OUTPUT FOR * 55980020
* A FRACTION ZERO.                                                    * 56000020
*                                                                     * 56020020
*********************************************************************** 56040020
         SPACE                                                          56060020
ZEROFRAC EQU   *                                                        56080020
         L     R2,CONAREA              R2=ADDRESS OF OUTPUT AREA.       56100020
         MVC   ZERO(THREE,R2),FLPTZERO PRINTABLE +0 NOW IN CONAREA.     56120020
         B     ENDFLT                  GO,SET RETURN CODE & RETURN.     56140020
*********************************************************************** 56160020
*                                                                     * 56180020
* THE FOLLOWING INSTRUCTIONS CONVERT THE FRACTION OF A DOUBLE         * 56200020
* PRECISION FLOATING POINT BINARY TO ZONED DECIMAL.                   * 56220020
*                                                                     * 56240020
*********************************************************************** 56260020
FLTLONG  EQU   *                                                        56280020
         SH    R7,DOBLFLT              MOVE DEC PT 8 MORE DIGITS RIGHT. 56300020
         D     R4,CVTVAL               ALTER FRACTION FOR CONVERSION.   56320020
         CVD   R5,PACKAREA             FRACTION NOW BEING CONVERTED TO  56340020
         OI    PACKAREA+SEVEN,SIGNF    PACKED DECIMAL.                  56360020
         UNPK  FLTSTG(ONE5),PACKAREA   PARTIAL CONVERT OF FRACTION.     56380020
         CVD   R4,PACKAREA             REMAINDER OF FRACTION NOW BEING  56400020
         OI    PACKAREA+SEVEN,SIGNF    CONVERTED TO PACK DECIMAL.       56420020
         UNPK  REMDATA(NINE),PACKAREA  REMIANDER OF FRACTION CONVERTED. 56440020
         LA    R6,FLTSTG+DOBLEND       R6=ADDRESS OF END OF ZONED DEC.  56460020
         B     SUPPRESS                GO SUPPRESS LEADING ZEROES.      56480020
ADJUSTIT EQU   *                                                        56500020
         BCTR  R8,ZERO                 R8=PTR TO LAST BYTE.             56520020
         IC    R4,ZERO(R8)                                              56540020
         TM    ZERO(R8),HEX9           Q.IS IT EQUAL TO NINE.           56560020
         BO    ADJUST2                 YES                              56580020
         LA    R4,ONE(R4)              CARRY NEXT TO LAST BYTE ONE.     56600020
         STC   R4,ZERO(R8)             MOVE BYTE INTO STRING.           56620020
         B     JUSTEND                 CHECK SCALING.                   56640020
ADJUST2  EQU   *                                                        56660020
         BCTR  R6,ZERO                 DECREMENT LENGTH.                56680020
         BCTR  R2,ZERO                 DECREMENT EXPONENT.              56700020
         STH   R6,FLTLEN               SAVE LENGTH.                     56720020
         B     ADJUSTIT                GET NEXT BYTE.                   56740020
         EJECT                                                          56760020
*********************************************************************** 56780020
*                                                                     * 56800020
* THE FOLLOWING INSTRUCTIONS CONVERT PRINTABLE DATA IN STANDARD OR    * 56820020
* SCIENTIFIC NOTATION TO ITS SINGLE OR DOUBLE PRECISION FLOATING      * 56840020
* POINT REPRESENTATION.                                               * 56860020
*                                                                     * 56880020
*********************************************************************** 56900020
IKJEGFTB EQU   *                                                        56920020
         DROP  R12            GET NEW BASE REGISTER                     56940020
         USING *,R15          ESTABLISH ADDRESSABILITY                  56960020
         L     R12,FLTCON     R12=ADDRESS OF IKJEGFLT                   56980020
         DROP  R15            GET NEW BASE REGISTER                     57000020
         USING IKJEGFLT,R12   IKJEGFLT ADDRESSABILITY                   57020020
         USING TCOMTAB,R9     TCOMTAB ADDRESSABILITY                    57040020
         L     R3,WORKAREA    GET WORK SPACE                            57060020
         USING CVTWORK,R3     ESTABLISH ADDRESSABILITY                  57080020
         XC    ZERO(SIX4,R3),ZERO(R3)  CLEAR OUT WORK AREA              57100020
         STC   R6,TYPE        STORE TYPE CODE E OR D                    57120020
         LH    R4,FOUR(R1)    LOAD LENGTH OF INPUT STRING               57140020
         EJECT                                                          57160020
*********************************************************************** 57180020
* THE FOLLOWING CODE SCANS THE INPUT STRING SAVING THE COEFFICIENT    * 57200020
* SIGN, THE EXPONENT SIGN, THE ADDRESS OF THE COEFFICIENT AND THE     * 57220020
* EXPONENT.                                                           * 57240020
*********************************************************************** 57260020
         SPACE                                                          57280020
         LA    R6,FRACSGN    POINT TO LOCATION FOR COEFFICIENT SIGN     57300020
         LA    R2,SCAN1                                                 57320020
         L     R7,ZERO(R1)    POINT TO INPUT STRING                     57340020
         MVI   EXPSIGN,PLUS   DEFAULT EXPONENT TO POSITIVE              57360020
         SR    R5,R5          DEFAULT EXPONENT TO ZERO                  57380020
SCAN0    CLI   ZERO(R7),MINUS IS COEFFICIENT NEGATIVE                   57400020
         BE    STORSIG1       IF YES BRANCH                             57420020
         CLI   ZERO(R7),PLUS  IS COEFFICIENT POSITIVE                   57440020
         BE    STORSIG1       IF YES BRANCH                             57460020
         MVI   ZERO(R6),PLUS  DEFAULT TO POSITIVE                       57480020
         BR    R2             BRANCH TO SCAN1 OR SCANDONE               57500020
STORSIG1 MVC   ZERO(ONE,R6),ZERO(R7)                                    57520020
         LA    R7,ONE(R7)     POINT TO NEXT CHARACTER BEYOND SIGN       57540020
         BCTR  R4,R2          BRANCH TO SCAN1 OR SCANDONE               57560020
SCAN1    SR    R8,R8          INITLZ DIGIT COUNT OF COEFFICIENT         57580020
         LR    R1,R7          SAVE ADDRESS OF COEFFICIENT               57600020
SCAN2    CLI   ZERO(R7),RESIGN     IS THE CHARACTER AN 'E'              57620020
         BE    EFOUND         IF YES BRANCH                             57640020
         CLI   ZERO(R7),HEX85 LOWER CASE E                              57660020
         BE    EFOUND         IF YES BRANCH                             57680020
         LA    R8,ONE(R8)     ADD ONE TO COEFFICIENT DIGIT COUNT        57700020
         LA    R7,ONE(R7)     POINT TO NEXT CHARACTER                   57720020
         BCT   R4,SCAN2       BRANCH AND DECREMENT STRING LENGTH        57740020
         B     NUMCHECK       IF STRING LENGTH ZERO BRANCH              57760020
EFOUND   LA    R7,ONE(R7)     POINT TO NEXT CHARACTER                   57780020
         LA    R6,EXPSIGN     POINT TO LOCATION FOR EXPONENT SIGN       57800020
         BCTR  R4,R0          DECREMENT STRING LENGTH                   57820020
         BAL   R2,SCAN0       CHECK FOR EXPONENT SIGN                   57840020
SCANDONE BCTR  R4,R0          DECREMENT STRING LENGTH                   57860020
         EX    R4,PACKE       PACK THE EXPONENT                         57880020
         CVB   R5,NUM4        CONVERT THE EXPONENT TO BINARY            57900020
         EJECT                                                          57920020
*********************************************************************** 57940020
* THE FOLLOWING CODE CHECKS FOR AN INPUT OF ZERO AND THEN BRANCHES TO * 57960020
* THE PROPER CODE TO PACK THE INPUT NUMBER DEPENDING ON WHETHER IT IS * 57980020
* AN INTEGER, A PROPER FRACTION, OR AN IMPROPER FRACTION.             * 58000020
*********************************************************************** 58020020
         SPACE                                                          58040020
NUMCHECK L     R2,CONAREA     POINT TO OUTPUT AREA                      58060020
         XC    ZERO(THREE2,R2),ZERO(R2) CLEAR IT OUT                    58080020
         LA    R15,RETURN1    SAVE IN OTHERWISE USELESS REGISTER        58100020
         MVI   NUM1,AZERO     MOVE IN CHARACTER ZERO                    58120020
         MVC   NUM1+ONE(TWO6),NUM1      SPREAD IT ALONG                 58140020
         BCTR  R8,R0          DECREMENT COEFFICIENT DIGIT COUNT FOR EX  58160020
         EX    R8,CLC1        IS COEFFICIENT ZERO                       58180020
         BCR   EIGHT,R15      IF YES GO TO RETURN1                      58200020
         LA    R8,ONE(R8)     RESTORE COEFFICIENT DIGIT COUNT           58220020
CLI      CLI   ZERO(R1),HEXF0      IS THERE A HIGH ORDER ZERO           58240020
         BNE   CLICLI         IF NO BRANCH                              58260020
         BCTR  R8,R0          DECREMENT DIGIT COUNT                     58280020
         LA    R1,ONE(R1)     POINT PAST ZERO                           58300020
         B     CLI            CHECK NEXT CHARACTER                      58320020
CLICLI   EQU   *                                                        58350020
         CLI   EXPSIGN,PLUS   IS NUMBER AN INTEGER                      58360020
         BE    INTEGER        IF YES THE NUMBER IS A PURE INTEGER       58380020
         CH    R5,HALFZERO    CHECK FOR XXXXE-0 INPUT                   58400020
         BE    INTEGER        IF SO NUMBER IS REALLY AN INTEGER         58420020
         CR    R8,R5          IS NUMBER PURE FRACTION                   58440020
         BNH   FRACTION       IF YES BRANCH                             58460020
MIXED    EQU   *              THE NUMBER IS MIXED INTEGER AND FRACTION  58480020
         OI    FLAG,HEXC0     INDICATE MIXED                            58500020
         LR    R10,R8         SAVE COEFFICIENT DIGIT COUNT              58520020
         SR    R10,R5         COMPUTE NUMBER OF DIGITS IN INTEGER PART  58540020
         BCTR  R10,R0         DECREMENT FOR EX                          58560020
         XC    NUM1(TWO7),NUM1                                          58580020
         EX    R10,PACKA      PACK THE INTEGER INTO NUM1                58600020
         LA    R10,ONE(R10)   RESTORE REGISTER 10                       58620020
         AR    R1,R10         POINT PAST INTEGER PART OF COEFFICIENT    58640020
         LR    R8,R5          SAVE R5=EXPONENT                          58660020
         LR    R6,R1          POINT TO FRACTION COEFFICIENT             58680020
CLI2     CLI   ZERO(R6),HEXF0                                           58700020
         BNE   LR8            IF NO GET OUT                             58720020
         LA    R6,ONE(R6)     POINT TO NEXT CHARACTER                   58740020
         BCT   R8,CLI2        HAVE WE FINISHED CHECKING                 58760020
         NI    FLAG,HEXFF-HEX80    IF YES THERE IS NO FRACTION PART     58780020
LR8      LR    R8,R5                                                    58800020
         SRL   R8,ONE                                                   58820020
         LR    R4,R8                                                    58840020
         SLL   R8,FOUR                                                  58860020
         AR    R8,R5                                                    58880020
         BCTR  R8,R0          R8=EXECUTE LENGTH.                        58900020
         EX    R8,PACKB       PACK THE FRACTION PART OF USER NUMBER     58920020
         LA    R4,NUM3+TWO(R4)     POINT TO END OF PACKED FRACTION      58940020
         MVN   ZERO(ONE,R4),HALFZERO                                    58960020
         LA    R4,ONE         R4=1.                                     58980020
         NR    R4,R5          IS EXPONENT EVEN OR ODD                   59000020
         BNZ   MIXED2         IF EVEN BRANCH                            59020020
         MVO   NUM3(ONE6),NUM3(ONE6)                                    59040020
MIXED2   MVN   NUM3+ONE5(ONE),PACK10+ONE                                59060020
         B     PACKDONE       PACKING IS DONE, BRANCH OUT               59080020
INTEGER  EQU   *                                                        59100020
         OI    FLAG,HEX40     INDICATE INTEGER                          59120020
         LR    R10,R8         SAVE R8=COEFFICIENT DIGIT COUNT           59140020
         AR    R10,R5         ADD EXPONENT TO GET FULL SIZE             59160020
         BCTR  R8,R0          DECREMENT FOR MOVE                        59180020
         C     R10,TWENTY7    HOW LONG IS INTEGER                       59200020
         BNL   LEFTADJ        IF LONGER THAN BUFFER LEFT ADUUST IT      59220020
         LA    R6,NUM3+ONE1                                             59240020
         SR    R6,R10         ALTER INTEGER POINTER.                    59260020
         EX    R8,MOVEA       RIGHT ADJUST INTEGER .                    59280020
         B     PACKINT        PACK THE INTEGER                          59300020
LEFTADJ  EX    R8,MOVE1       LEFT ADJUST INTEGER.                      59320020
PACKINT  PACK  NUM2+TWO(EIGHT),NUM1(ONE5)                               59340020
         PACK  NUM2+NINE(SEVEN),NUM1+ONE4(ONE3)                         59360020
         B     PACKDONE       PACKING IS DONE, GET OUT                  59380020
FRACTION EQU   *              NUMBER IS A PURE FRACTION                 59400020
         OI    FLAG,HEX80     TURN ON FRACTION FLAG                     59420020
         MVI   NUM2,AZERO     MOVE IN CHARACTER ZERO                    59440020
         MVC   NUM2+ONE(FIVE3),NUM2     SPREAD IT ALONG                 59460020
         LA    R0,FIVE4       NUMBER OF DIGITS FOR MULTIPLYING          59480020
         CR    R5,R0          HOW MANY DIGITS IN FRACTION               59500020
         BNH   LESS55         IF 54 OR LESS BRANCH                      59520020
         S     R5,TWENTY7     SUBRACT 27                                59540020
         OI    FLAG,HEX04     SET FLAG TO INDICITE NOT FULL FRACTION    59560020
         CR    R5,R0          IS FRACTION STILL TOO LARGE               59580020
         BNH   LESS55         IF SMALL ENOUGH BRANCH                    59600020
         S     R5,TWENTY7     MAKE NUMBER SMALL ENOUGH                  59620020
         OI    FLAG,HEX08     SET FLAG TO INDICATE FAKING               59640020
LESS55   LA    R6,NUM2(R5)    PACK THE FRACTION                         59660020
         SR    R6,R8          ALTER FRACTION POINTER.                   59680020
         BCTR  R8,R0          R8=EXECUTE LENGTH.                        59700020
         EX    R8,MOVEA       LEFT ADJUST FRACTION.                     59720020
         PACK  NUM4(EIGHT),NUM3+SEVEN(ONE5)                             59740020
         PACK  NUM3+EIGHT(EIGHT),NUM1+ONE1(ONE1)                        59760020
         MVN   NUM3+ONE5(ONE),NUM3+SIX                                  59780020
         PACK  NUM3(EIGHT),NUM2+ONE2(ONE5)                              59800020
         PACK  NUM1+EIGHT(EIGHT),NUM2(ONE1)                             59820020
         MVN   NUM1+ONE5(ONE),NUM2+ONE1                                 59840020
         MVC   NUM2(THREE2),NUM1+EIGHT                                  59860020
         XC    NUM3(TWO4),NUM3                                          59880020
         MVN   NUM4+SEVEN(ONE),PACK10+ONE                               59900020
         B     INTGREND       GO TO FRACTION PROCESSING PART            59920020
         EJECT                                                          59940020
*********************************************************************** 59960020
*                                                                     * 59980020
* THIS CODE IS REACHED WHEN PACKING AND FORMATTING ARE COMPLETED      * 60000020
* FOR INTEGER OR MIXED DATA.  IT SETS UP AND BEGINS CONVERSION OF     * 60020020
* THE INTEGER PORTION TO FLOATING POINT REPRESENTATION.               * 60040020
*                                                                     * 60060020
*********************************************************************** 60080020
         SPACE                                                          60100020
PACKDONE EQU   *              PACKING IS DONE                           60120020
         SR    R5,R5          INITIALIZE DIVISION COUNTER               60140020
LA       LA    R4,THREE2(R2)  POINT TO LOCATION FOR FRACTION MANTISSA   60160020
         LA    R1,DIVIDE      SAVE ADDRESS IN OTHERWISE UNUSED REG.     60180020
         LA    R8,MORENUM7    SAVE ADDRESS IN OTHERWISE UNUSED REG.     60200020
DIVIDE   DP    NUM2(ONE6),TWO56(TWO) DIVIDE TO OBTAIN HEX DIGITS        60220020
         LA    R5,TWO(R5)     INCREMENT TNCE FOR EACH DIVISION BY 16    60240020
         MVC   NUM4+SIX(TWO),NUM2+ONE4                                  60260020
         ZAP   NUM2(ONE6),NUM2(ONE4) RIGHT ADJUST QUOTIENT              60280020
         C     R10,TWENTY7    WAS FULL INTEGER INVOLVED IN DIVISION     60300020
         BH    MORENUM1       NO.                                       60320020
         CVB   R0,NUM4                                                  60340020
         STC   R0,ZERO(R4)    STORE HEX DIGIT PAIR IN OUTPUT AREA       60360020
         BCTR  R4,R0          POINT ONE BYTE LEFT FOR NEXT TIME         60380020
         EJECT                                                          60400020
*********************************************************************** 60420020
*                                                                     * 60440020
* THE FOLLOWING CODE IS EXECUTED IF THE FULL INTEGER IS BEING INVOLVED* 60460020
* IN DIVISION AND CALCULATION OF THE EQUIVALENT HEX REPRESENTATION. IT* 60480020
* DECREMENTS THE INTEGER DIGIT COUNTER (R10) AND IF PROCESSING IS NOT * 60500020
* DONE RETURNS TO DIVIDE THE INTEGER AGAIN.                           * 60520020
*                                                                     * 60540020
*********************************************************************** 60560020
         LA    R6,THREE                                                 60580020
         CR    R10,R6         HOW BIG WAS DIGIT COUNT                   60600020
         BL    INTGRND1       IF 1 OR 2 WE ARE DONE DIVIDING            60620020
         LA    R7,NUM2+ONE6                                             60640020
         LR    R6,R10         SAVE R10                                  60660020
         SRL   R6,ONE         COMPUTE COUNT IN BYTES                    60680020
         SR    R7,R6          POINT TO FRONT OF QUOTIENT                60700020
         BCTR  R10,R0         DECREMENT DIGIT COUNT                     60720020
         BCTR  R10,R0         DECREMENT DIGIT COUNT                     60740020
         LA    R6,ONE         TO CHECK R10 FOR EVEN OR ODD              60760020
         NR    R6,R10         TO CHECK R10 FOR EVEN OR ODD              60780020
         BZ    ZEROFOX        IF R10 IS EVEN BRANCH                     60800020
         TM    ZERO(R7),HEXF0 CHECK FOR HIGH ORDER ZERO                 60820020
         BCR   SEVEN,R1       BRANCH IF NONE TO DIVIDE                  60840020
         B     BCTR           GO DECREMENT DIVISION COUNTER.            60860020
ZEROFOX  TM    ZERO(R7),HEX0F IS NEXT DIGIT ZERO ALSO                   60880020
         BCR   SEVEN,R1       BRANCH IF NONE TO DIVIDE                  60900020
BCTR     BCTR  R10,R1         DECREMENT INTEGER LENGTH AND REDIVIDE     60920020
         B     INTGRND1       GO PROCESS FRACTION PART.                 60940020
         EJECT                                                          60960020
*********************************************************************** 60980020
*                                                                     * 61000020
* THE FOLLOWING CODE IS EXECUTED IF THE FULL INTEGER PART WAS NOT     * 61020020
* INVOLVED IN DIVISION. IT RECALCULATES THE INTEGER DIGIT COUNT AND   * 61040020
* FORMATS THE DIVIDEND FOR THE NEXT DIVISION.                         * 61060020
*                                                                     * 61080020
*********************************************************************** 61100020
         SPACE                                                          61120020
MORENUM1 EQU   *                                                        61140020
         S     R10,TWENTY7                                              61160020
         MP    NUM2(ONE6),PACK10(TWO)   SHIFT LEFT ONE DIGIT            61180020
         BCT   R10,MORENUM2   IF NOT ZERO CONTINUE SHIFTING             61200020
MORENUM3 TM    NUM2+TWO,HEX0F IS FIRSTT OUT                             61220020
         BZ    MORENUM6       IF YES BRANCH                             61240020
         BR    R8             IF NO GO TO MORENUM7                      61260020
MORENUM2 MP    NUM2(ONE6),PACK10(TWO)   SHIFT LEFT ONE DIGIT            61280020
         TM    NUM2+TWO,HEXF0                                           61300020
         BCR   SEVEN,R8       IF DIGIT NOT ZERO BRANCH TO MORENUM7      61320020
         BCT   R10,MORENUM4   OTHERWISE DECREMENT DIGIT COUNT           61340020
         BR    R8             IF DIGIT COUNT IS ZERO BRANCH             61360020
MORENUM4 MP    NUM2(ONE6),PACK10(TWO) MULTIPLY TO SHIFT OUT ZERO        61380020
         BR    R8             BRANCH TO MORENUM7                        61400020
MORENUM6 BCTR  R10,R0         DECREMENT INTEGER COUNTER                 61420020
MORENUM7 BCTR  R10,R0         DECREMENT INTEGER COUNTER                 61440020
MORENUM8 A     R10,TWENTY7    RESTORE FULL INTEGER DIGIT COUNTER        61460020
         BR    R1             GO BACK TO DIVIDE                         61480020
         EJECT                                                          61500020
*********************************************************************** 61520020
*                                                                     * 61540020
* THE FOLLOWING CODE IS REACHED WHEN THE INTEGER PROCESSING IS        * 61560020
* COMPLETE. IT WILL PROCESS THE FRACTION IF ANY.                      * 61580020
*                                                                     * 61600020
*********************************************************************** 61620020
         SPACE                                                          61640020
INTGRND1 EQU   *              INTEGER PART IS CONVERTED TO FLOATING PT  61660020
         LR    R8,R5          LOAD DIGIT COUNT                          61680020
         SRL   R8,ONE         COMPUTE BYTE COUNT                        61700020
         BCTR  R8,R0          DECREMENT FOR MOVE                        61720020
         EX    R8,MOVEB       LEFT ADJUST FRACTION PART IN CONAREA      61740020
         TM    TWO(R2),HEXF0  IS FIRST DIGIT ZERO                       61760020
         BNZ   INTGRND2       IF NO, OKAY AND BRANCH                    61780020
         BCTR  R5,R0          SUBRRACT FROM DIGIT COUNT (AND EXPONENT)  61800020
         MVO   TWO(EIGHT,R2),TWO(EIGHT,R2)   SHIFT THE MANTISSA         61820020
         MVN   NINE(ONE,R2),HALFZERO    PUT IN A ZERO                   61840020
INTGRND2 EQU   *                                                        61860020
         STC   R5,NUM5        SAVE FOR POSSIBLE USE LATER               61880020
         LA    R10,HEX40      LOAD BASE FOR EXPONENT                    61900020
         CLI   FRACSGN,PLUS   IS NUMBER POSITIVE                        61920020
         BE    PLUS3          IF YES BRANCH                             61940020
         LA    R10,HEX80(R10) OTHERWISE CHANGE THE BASE                 61960020
PLUS3    AR    R10,R5         COMPUTE THE EXPONENT                      61980020
         STC   R10,ONE(R2)    SAVE IT                                   62000020
         TM    FLAG,HEX80     WAS THERE A FRACTION PART                 62020020
         BCR   EIGHT,R15      IF NO GO TO RETURN1                       62040020
INTGREND LA    R4,ONE3(R2)    POINT TO FRACTION MANTISSA                62060020
FRAC1    LA    R8,EIGHT       NUMBER OF SIGNIFICANT DIGITS TO FIGURE    62080020
         SR    R5,R5          MULTIPLICATION COUNTER                    62100020
         SR    R7,R7          CLEAR OUT A REGISTER                      62120020
         TM    FLAG,HEX40     WAS THERE AN INTEGER PART                 62140020
         BZ    MULTIPLY       IF NO START WORKING ON FRACTION           62160020
         MVC   NUM2(ONE6),NUM3     SET UP AREA FOR FRACTION CONVERSION  62180020
         MVN   NUM1+ONE5(ONE),PACK10+ONE                                62200020
MULTIPLY MP    NUM2(ONE6),TWO56(TWO)                                    62220020
         MP    NUM1(ONE6),TWO56(TWO)                                    62240020
         MVO   NUM1(TWO),NUM1(TWO) SHIFT LEFT TO MAKE ROOM FOR SIGN     62260020
         MVN   NUM1+ONE(ONE),PACK10+ONE                                 62280020
         AP    NUM2(ONE6),NUM1(TWO)     ADD TO LOW ORDER PART OF NUM2   62300020
         STH   R7,NUM1        CLEAR OUT HIGH TWO BYTES                  62320020
         CLC   NUM2(TWO),HALFZERO  IS OVERFLOW ZERO                     62340020
         BE    NEXTCHK1       IF YES BRANCH                             62360020
NEXTCHK2 TM    FLAG,HEX0C     IS EITHER FAKING FLAG STILL ON            62380020
         BZ    NEXTCHK4       IF NO BRANCH                              62400020
         BM    NEXTCHK8       IF ONLY ONE ON BRANCH                     62420020
NEXTCHK7 NI    FLAG,(HEXFF-HEX08)  TURN OFF ONE FAKING FLAG             62440020
NEXTCHK9 MVC   NUM1(ONE6),NUM2     SHIFT STUFF TO LOW ORDER BUFFER      62460020
         XC    NUM2(ONE6),NUM2     CLEAR OUT HIGH ORDER BUFFER          62480020
         MVO   NUM2+ONE4(TWO),NUM1(TWO)                                 62500020
         MVN   NUM2+ONE5(ONE),PACK10+ONE                                62520020
         STH   R7,NUM1                                                  62540020
NEXTCHKB LA    R5,TWO(R5)     INCREMENT MULTIPLY COUNTER                62560020
         B     MULTIPLY       GO DO IT AGAIN                            62580020
NEXTCHK8 NI    FLAG,(HEXFF-HEX04)  TURN OFF REMAINING FAKING FLAG       62600020
         B     NEXTCHK9       GO TO COMMON FAKING PART                  62620020
NEXTCHK1 TM    FLAG,HEX20     ARE WE COMPUTING SIGNIFICANT DIGITS YES   62640020
         BZ    NEXTCHKB       IF NO BRANCH                              62660020
NEXTCHK4 OI    FLAG,HEX20     INDICATE SIGNIFICANT DIGIT FIGURING       62680020
         MVO   NUM4+SIX(TWO),NUM2(TWO)  MOVE INTO CLEAN AREA            62700020
         STH   R7,NUM2        CLEAR OUT HIGH TWO BYTES                  62720020
         CVB   R0,NUM4        CONVERT TO TWO HEX DIGITS                 62740020
         STC   R0,ZERO(R4)    SAVE THEM                                 62760020
         LA    R4,ONE(R4)     POINT ONE BYTE RIGHT FOR NEXT PAIR        62780020
         BCT   R8,MULTIPLY    IF LESS THAN EIGHT BYTES BRANCH           62800020
         LA    R4,ONE3(R2)    POINT TO BEGINNING OF MANTISSA            62820020
         TM    ZERO(R4),HEXF0 IS THERE A HIGH ORDER ZERO                62840020
         BNZ   FRACDONE       IF NO BRANCH                              62860020
         MVO   ZERO(EIGHT,R4),ZERO(EIGHT,R4)                            62880020
         LA    R5,ONE(R5)     ADD TO THE MULTIPLY COUNTER               62900020
         EJECT                                                          62920020
*********************************************************************** 62940020
*                                                                     * 62960020
* THE FOLLOWING CODE IS REACHED WHEN THE MANTISSA PORTION OF THE      * 62980020
* FLOATING POINT RESULT HAS BEEN CALCULATED. IT WILL CALCULATE THE    * 63000020
* CHARACTERISTIC OR ALIGN THE MANTISSA PORTION OF THE FRACTION IF THE * 63020020
* USER ENTERED NUMBER WAS A FRACTION OR MIXED INTEGER AND FRACTION    * 63040020
*                                                                     * 63060020
*********************************************************************** 63080020
FRACDONE EQU   *                                                        63100020
         LA    R2,ONE(R2)     POINT PAST THE LENGTH FIELD               63120020
FRAC2    LA    R10,HEX40      LOAD BASE FOR EXPONENT                    63140020
         STC   R5,NUM7        SAVE MULTIPLICATION COUNTER               63160020
         SR    R10,R5         FIGURE THE EXPONENT                       63180020
         CLI   FRACSGN,PLUS   IS NUMBER POSITIVE                        63200020
         BE    PLUS1          IF POSITIVE BRANCH                        63220020
         LA    R10,HEX80(R10) INDICATE NEGATIVE NUMBER                  63240020
PLUS1    TM    FLAG,HEX40     WAS THERE AN INTEGER PART                 63260020
         BNZ   INTNFRAC       IF YES BRANCH                             63280020
         STC   R10,ZERO(R2)   SAVE THE EXPONENT                         63300020
         MVC   ONE(EIGHT,R2),ONE2(R2)                                   63320020
         BCTR  R2,R15         RESTORE R2 AND GO TO RETURN1              63340020
INTNFRAC SR    R10,R10        CLEAR OUT A REGISTER                      63360020
         SR    R1,R1          CLEAR OUT A REGISTER                      63380020
         IC    R10,NUM7       LOAD FRACTION MULTIPLY COUNT              63400020
         IC    R1,NUM5        LOAD INTEGER DIVISION COUNT               63420020
         LA    R1,TWO(R1,R10) NUMBER OF DIGIT PLACES TO SHIFT TO ALIGN  63440020
         LM    R4,R5,ONE2(R2)                                           63460020
         LM    R6,R7,ONE6(R2)                                           63480020
         LA    R0,SIX4                                                  63500020
         SLL   R1,TWO                                                   63520020
         CR    R1,R0          DO WE NEED SHIFT MORE THAN 64 BITS        63540020
         BNL   SHIFT64        IF YES BRANCH                             63560020
         SRL   R0,ONE                                                   63580020
         CR    R1,R0          DO WE NEED SHIFT MORE THAN 32 BITS        63600020
         BNL   SHIFT32        IF YES BRANCH                             63620020
         SRDL  R4,ZERO(R1)                                              63640020
         SRDL  R6,ZERO(R1)                                              63660020
         A     R4,ZERO(R2)                                              63680020
         A     R5,FOUR(R2)                                              63700020
         A     R7,EIGHT(R2)                                             63720020
         LR    R6,R7                                                    63740020
         STM   R4,R6,ZERO(R2)                                           63760020
         BCTR  R2,R15         RESTORE R2 AND GO TO RETURN1              63780020
SHIFT32  SR    R1,R0                                                    63800020
         SRDL  R4,ZERO(R1)                                              63820020
         A     R4,FOUR(R2)                                              63840020
         A     R5,EIGHT(R2)                                             63860020
         STM   R4,R5,FOUR(R2)                                           63880020
         BCTR  R2,R15         RESTORE R2 AND GO TO RETURN1              63900020
SHIFT64  SRDL  R4,ZERO(R1)                                              63920020
         A     R4,EIGHT(R2)                                             63940020
         ST    R4,EIGHT(R2)                                             63960020
BCTR2    BCTR  R2,R0          DECREMENT BY ONE                          63980020
*********************************************************************** 64000020
* THE FOLLOWING CODE COMPUTES THE OUTPUT LENGTH EITHER FOUR OR EIGHT  * 64020020
* BYTES AND SAVES THE LENGTH IN CONAREA FOR IKJEGPCH. IT THEN CHECKS  * 64040020
* THE FLOATING POINT REPRESENTATION AND ROUNDS IT IF NECESSARY.       * 64060020
* FINALLY IT CHECKS THE HIGH ORDER MANTISSA BYTE FOR ZERO             * 64080020
*********************************************************************** 64100020
         SPACE                                                          64120020
RETURN1  MVI   ZERO(R2),HEX08 SET LENGTH TO 8                           64140020
         LA    R15,ENDFLT     POINT TO ENDFLT                           64160020
         CLI   TYPE,HEX1C     DOUBLE OR SINGLE PRECISION                64180020
         BE    LNGROUND       IF DOUBLE BRANCH                          64200020
         MVI   ZERO(R2),HEX04 SET LENGTH TO 4                           64220020
SHTROUND EQU   *              ROUND THE RESULT                          64240020
         LA    R2,ONE(R2)     POINT PAST LENGTH FIELD                   64260020
         CLI   FOUR(R2),HEX80 IS IT NECESSARY TO CHANGE OUTPUT          64280020
         BCR   FOUR,R15       IF NO ROUNDING NEXESSARY GO TO ENDFLT     64300020
         L     R4,ZERO(R2)    LOAD RESULT                               64320020
         LA    R5,ONE                                                   64340020
         AR    R4,R5          ADD ONE                                   64360020
         ST    R4,ZERO(R2)    STORE RESULT                              64380020
         B     FINALCK        CHECK FOR 0 HIGH ORDER MANTISSA BYTE.     64400020
LNGROUND EQU   *                                                        64420020
         LA    R2,ONE(R2)     POINT PAST LENGTH FIELD                   64440020
         CLI   EIGHT(R2),HEX80     IS IT NECESSARY TO CHANGE OUTPUT     64460020
         BCR   FOUR,R15       IF NO ROUNDING NEXESSARY GO TO ENDFLT     64480020
         LD    R2,ZERO(R2)         LOAD INTO FLOATING PT REGISTER       64500020
         XC    ONE(SEVEN,R2),ONE(R2)    CLEAR OUT FRACTION              64520020
         MVI   SEVEN(R2),HEX01     MOVE IN ONE                          64540020
         AW    R2,ZERO(R2)         ADD TO ROUND                         64560020
         STD   R2,ZERO(R2)    REPLACE RESULT                            64580020
FINALCK  CLI   ONE(R2),HEX00                                            64600020
         BCR   SEVEN,R15      IF NOT ZERO GO TO ENDFLT                  64620020
         MVI   ONE(R2),HEX10                                            64640020
         BR    R15            GO TO ENDFLT                              64660020
CVTWORK  DSECT                                                          64680020
         SPACE                                                          64700020
*********************************************************************** 64720020
*                                                                     * 64740020
* THIS DSECT MAPS A SECTION OF THE WORKAREA POINTED TO BY 'WORKAREA'  * 64760020
* IN TCOMTAB.                                                         * 64780020
*                                                                     * 64800020
*********************************************************************** 64820020
         SPACE                                                          64840020
FLTINPUT DS    D              LOCATION FOR FLTPT INPUT STRING.          64860020
PACKAREA DS    D              LOCATION FOR PACKED DECIMAL CONSTANTS     64880020
FLTSTG   DS    5D             FLOATING PT WORKAREA.                     64900020
FLTLEN   DS    H              SAVE LENGTH AREA.                         64920020
         ORG   *-58           POINT TO BEGINNING OF WORK AREA           64940020
NUM2     DS    4F             WORK SPACE FOR CONVERSION                 64960020
NUM1     DS    4F             ***                                       64980020
NUM3     DS    4F             ***                                       65000020
NUM4     DS    2F             AREA FOR CVB OF EXPONENT AND DIGITS       65020020
FRACSGN  DS    CL1            SIGN OF USER ENTERED FRACTION OR PLUS     65040020
EXPSIGN  DS    CL1            SIGN OF USER ENTERED EXPONENT OR PLUS     65060020
FLAG     DS    CL1            USED TO INDICATE NUMBER TYPE              65080020
EXPON    DS    CL1            USER ENTERED EXPONENT OR ZERO             65100020
NUM7     DS    CL1            ***                                       65120020
NUM5     DS    CL1            ***                                       65140020
COEFF    DS    CL1            COEFFICIENT DIGIT COUNT                   65160020
TYPE     DS    CL1            INDICATES DOUBLE OR SINGLE PRECISION      65180020
         ORG   *-1            BACK UP ONE BYTE                          65186020
CODE370  DS    X                       370 OP CODE FLAG.                65192020
B2FLAG   EQU   X'10'                   OP CODE IS 2 BYTES.              65194020
CHAR5    EQU   X'01'                   MNEUMONIC IS 5 CHARS.            65196020
SSIMM    EQU   X'02'                   SS FORMAT,L1 & I3.               65198020
IKJEGFLT CSECT                                                          65200020
FLTMOVE  MVC   FLTINPUT+ONE(ONE),ONE(R1) FRACTION NOW IN WORKAREA.      65220020
MOVEFLT  MVC   FLTSTG(ONE),FLTSTG+ONE  LEFT JUSTIFY ZONE DECIMAL.       65240020
ALIGNMVC MVC   ZERO(ONE,R5),ZERO(R8)   FRACTION NOW MOVED FOR ADD.      65260020
ZONEMOVE MVC   FLTSTG(ONE),ZERO(R8)    ZONED DECIMAL NOW LEFT JUSTIVIED 65280020
ZONEJUST MVC   ZERO(ONE,R8),ONE(R8)    INPUT NOW LEFT JUSTIFIED.        65300020
OUTMVC   MVC   ONE(ONE,R2),FLTSTG-TWO  MOVE STRING INTO OUTPUT AREA     65320020
PACKA    PACK  NUM2(ONE6),ZERO(ZERO,R1)                                 65340020
PACKB    PACK  NUM3+TWO(ZERO),ZERO(ZERO,R1)                             65360020
PACKC    PACK  ZERO(ONE6,R6),ZERO(ZERO,R4)                              65380020
PACKD    PACK  NUM2+SEVEN(ZERO),ZERO(ZERO,R1)                           65400020
PACKE    PACK  NUM4+SIX(TWO),ZERO(ZERO,R7)                              65420020
CLC1     CLC   ZERO(ZERO,R1),NUM1                                       65440020
MOVE1    MVC   NUM1(ZERO),ZERO(R1)                                      65460020
MOVEA    MVC   ZERO(ZERO,R6),ZERO(R1)                                   65480020
MOVEB    MVC   TWO(ZERO,R2),ONE(R4)                                     65500020
ROUNDPK  PACK  FLTINPUT(ONE),FLTSTG(ONE) SIGNIFICANT DIGITS NOW PACKED. 65520020
ADD5     AP    FLTINPUT(ONE),PACK5(ONE) ROUND VALUE.                    65540020
UNPKSIG  UNPK  FLTSTG(ONE),FLTINPUT(ONE) SIGNIFICANT DIGITS NOW ZONED.  65560020
         DS    0F                                                       65580020
SIGNOFF  DC    X'0000007F'    VALUE TO CLEAR HIGH ORDER.                65600020
FLTCON   DC    A(IKJEGFLT)    ADDR OF FLOATING POINT ROUTINE.           65620020
CVTVAL   DC    X'3B9ACA00'    10**9 USED TO CONVERT FIXED DEC.          65640020
FLTCLEAR DC    X'0000000F'    FULL WORD 15                              65660020
DOBLFLT  DC    X'0008'        HALFWORD 8 FOR CHARACTERISTICS.           65680020
FLT20    DC    H'20'          HALFWORD 20.                              65700020
PACK10   DC    PL2'10'        PACKED 10                                 65720020
SIXTEEN  DC    PL2'16'        PACKED 16                                 65740020
TWO56    DC    PL2'256'       PACKED 256                                65760020
HALFZERO DC    H'0'           HALFWORD ZERO                             65780020
FLT17    DC    H'17'          HALFWORD 179                              65800020
HALFONE  DC    H'1'           HALFWORD 1.                               65820020
TWENTY7  DC    F'27'          FULLWORD 27                               65840020
FLTDEC2  DC    H'2'           FIXED DECIMAL 2 FOR FLOATING PT.          65860020
FLTCHAR  DC    X'0046'        FLOATING PT CHARACTERISTIC + 6.           65880020
FLT64    DC    H'64'          HALF WORD 64.                             65900020
FLT10    DC    H'10'          HALF WORD 10.                             65920020
FLTSHORT DC    X'0018'        HEX VALUE FOR SINGLE PRESICION.           65940020
EXPCHAR  DC    C' E+  '       EXPONENT PATTERN.                         65960020
FLPTZERO DC    X'02'          OUTPUT FOR ZERO VALUE.                    65980020
         DC    C'+0'          *                                         66000020
FRACSIGN DC    C'+.'          FRACTION SIGN PATTERN.                    66020020
FLTPATTN DC    C'0'           PATTERN FOR EDIT INSTRUCTION.             66040020
         DC    18X'20'        *                                         66060020
PACK5    DC    P'5'           PACKED 5                                  66080020
REMDATA  EQU   FLTSTG+15      LOC FOR REMAINDER OF FLT PT.              66100020
HEX9     EQU   X'09'          A HEX 9.                                  66120020
IKJEGMSG CSECT                                                          66140020
         ENTRY IKJEGM01                                                 66160020
         ENTRY IKJEGM02                                                 66180020
         ENTRY IKJEGM03                                                 66200020
         ENTRY IKJEG1IA                                                 66220020
         SPACE                                                          66240020
*********************************************************************** 66260020
* THE FOLLOWING LINES FO CODE IS THE MESSAGE CSECT FOR IKJEGCVT, THE  * 66280020
* CONVERSION ROUTINE OF TEST.  THE FIRST SECTION CONTANS ADCONS FOR   * 66300020
* THE FIRST AND SECOND LEVEL MESSAGES.                                * 66320020
*********************************************************************** 66340020
         SPACE                                                          66360020
IKJEGM01 DC    A(IKJEG1IA)    POINTER TO MESSAGE.                       66380020
         DC    A(MSG100IB)    POINTER TO MESSAGE.                       66400020
IKJEGM02 DC    A(IKJEG1IA)    POINTER TO MESSAGE.                       66420020
         DC    A(MSG100IC)    POINTER TO MESSAGE.                       66440020
IKJEGM03 DC    A(MSG101IA)    POINTER TO MESSAGE.                       66460020
         DC    A(0)           POINTER TO MESSAGE.                       66480020
         DS    0H                                                       66490020
IKJEG1IA DC    AL2(MSG1002A-IKJEG1IA)         MSG TEXT.                 66500020
         DC    AL2(0)                         MSG TEXT.                 66520020
         DC    C'IKJ57100I INVALID ADDRESS '  MSG TEXT.                 66540020
MSG1002A EQU   *                                                        66542020
         DS    0H                             MSG TEXT.                 66550020
MSG100IB DC    AL2(MSG1002B-MSG100IB)         MSG TEXT.                 66560020
         DC    AL2(0)                         MSG TEXT.                 66580020
         DC    C'IKJ57100I LENGTH EXCEEDS EIGHT CHARACTERS'  MSG TEXT.  66600020
MSG1002B EQU   *                                                        66602020
         DS    0H                                                       66610020
MSG100IC DC    AL2(MSG1002C-MSG100IC)         MSG TEXT.                 66620020
         DC    AL2(0)                         MSG TEXT.                 66640020
         DC    C'IKJ57100I ADDRESS EXCEEDS MAXIMUM'    MESG TEXT        66647020
         DC    C' STORAGE SIZE'                        MESG TEXT        66654020
MSG1002C EQU   *                                                        66662020
         DS    0H                                                       66670020
MSG101IA DC    AL2(MSG102IA-MSG101IA)            MSG TEXT.              66680020
         DC    AL2(0)                            MSG TEXT.              66700020
         DC    C'IKJ57101I INVALID DATA FOR TYPE P'   MSG TEXT.         66720020
MSG102IA EQU   *                                                        66722020
         END                                                            66820020
