         TITLE 'IKJEGDCB, THE LISTDCB FUNCTION OF THE TEST COMMAND'     00080020
IKJEGDCB CSECT                                                          00160020
*********************************************************************** 00240020
* STATUS  CHANGE LEVEL 000                                            * 00320020
*                                                                     * 00400020
* FUNCTION/OPERATION                                                  * 00480020
*    THIS COMMAND PROGRAM RECEIVES CONTROL FROM THE TEST COMMAND      * 00560020
*    PROCESSOR.  IT DISPLAYS ALL OR PART OF THE DCB AT A USER         * 00640020
*    SPECIFIED ADDRESS.                                               * 00720020
*                                                                     * 00800020
* ENTRY POINTS                                                        * 00880020
*         IKJEGDCB-PROCESSES THE FIELDS OF THE DCB                    * 00960020
*         IKJEGDVK-VALIDITY CHECKS THE ADDRESS OF THE DCB             * 01040020
*                                                                     * 01120020
* INPUT                                                               * 01200020
*    ONE LINE OF INPUT FROM THE TERMINAL CONTAINING THE COMMAND       * 01280020
*                                                                     * 01360020
* OUTPUT                                                              * 01440020
*    LINES OF OUTPUT TO THE TERMINAL OR SPECIFIED DATA SET CONTAINING * 01520020
*    DESCRIPTIVE HEADERS AND THE REQUESTED DCB FIELDS.                * 01600020
*                                                                     * 01680020
* EXTERNAL REFERENCES                                                 * 01760020
*         IKJPARS  - TO SCAN THE INPUT BUFFER                         * 01840020
*         IKJEGCVT - TO CHECK AND CONVERT THE ADDRESS AND TO          * 01920020
*    CONVERT THE DCB FIELDS TO PRINTABLE HEXADECIMAL.                 * 02000020
*         IKJEGIO  - TO OUTPUT THE DCB HEADERS AND FIELDS             * 02080020
*         IKJEGBLD - TO BUILD AN ADDRESS STRING FOR A MESSAGE         * 02160020
*                                                                     * 02240020
* EXITS,NORMAL                                                        * 02320020
*         IKJPARS-VIA REGISTER 14 WITH ONE OF THE FOLLOWING RETURN    * 02370020
*    CODES IN REGISTER 15-                                            * 02380020
*    0   INDICATING TO CONTINUE PROCESSING THE COMMAND BUFFER         * 02390020
*    8   INDICATING IKJPARS SHOULD PROMPT WITH REENTER                * 02400020
*    12  INDICATING IKJPARS SHOULD RETURN TO IKJEGDCB WITH A RETURN   * 02450020
*    *   CODE OF 20.                                                  * 02460020
*                                                                     * 02470020
*         IKJEGMNL-VIA REGISTER 14 WITH ONE OF THE FOLLOWING RETURN   * 02480020
*    CODES IN REGISTER 15.                                            * 02530020
*    0   NORMAL RETURN                                                * 02540020
*    16  INDICATING AN ATTENTION INTERRUPT WAS ENCOUNTERED            * 02550020
*                                                                     * 02800020
* EXITS,ERROR                                                         * 02880020
*         IKJEGMNL-VIA REGISTER 14 WITH A RETURN CODE OF 20 IN        * 02930020
*    REGISTER 15 INDICATING THE STAE RETRY ROUTINE WAS ENTERED.       * 02940020
*                                                                     * 03120020
* TABLES/WORK AREAS                                                   * 03200020
*                                                                     * 03250020
*    TCOMTAB - DSECT CONTAINING THE ADDRESS OF THE OUTPUT BUFFER,     * 03280020
*    THE COMMAND BUFFER, LISTDCB'S WORKAREA AND SAVEAREA.             * 03360020
*                                                                     * 03410020
*    DCBWKARA - CONTAINS THE PARAMETER LIST FOR IKJPARS, THE BUFFERS, * 03440020
*    USED TO BUILD THE FIELD HEADERS AND FIELDS FOR                   * 03520020
*    OUTPUT, AND THE SWITCHES USED BY IKJEGDCB.                       * 03600020
*                                                                     * 03680020
* ATTRIBUTES                                                          * 03760020
*    REENTRANT ROUTINE                                                * 03840020
*    REFRESHABLE ROUTINE                                              * 03920020
*                                                                     * 04000020
* CHARACTER CODE DEPENDENCY                                           * 04080020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL            * 04160020
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT * 04240020
*    TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED  * 04320020
*    SO THAT REDEFINITION OF CHARACTER CONSTANTS, BY REASSEMBLY,      * 04400020
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITION.          * 04480020
*                                                                     * 04560020
* NOTES                                                               * 04640020
*    ABBREVIATIONS COMMONLY USED IN THE COMMENTS BESIDE THE CODE-     * 04720020
*    1.   PDL-PARAMETER DESCRIPTOR LIST                               * 04800020
*    2.   PDE-PARAMETER DESCRIPTOR ENTRY                              * 04880020
*    3.   PCL-PARAMETER CONTROL LIST                                  * 04960020
*    COMMENTS ON STATEMENTS USUALLY START IN COLUMN 36.               * 05010020
*    STAERTN IS THE ENTRY POINT INTO THE STAE RETRY ROUTINE.  THIS    * 05020020
*    CODE IS ENTERED FROM IKJEGSTA.                                   * 05030020
*********************************************************************** 05040020
         EJECT                                                          05120020
R0       EQU    0                 REGISTER 0                            05200020
R1       EQU    1                 REGISTER 1                            05280020
R2       EQU    2                 USED TO INDEX THROUGH OUTPUT BUFFER   05360020
R3       EQU    3                 USED AS BASE FOR DCB BEING PROCESSED  05440020
R4       EQU    4                 REGISTER 4                            05520020
R5       EQU    5                 BASE OF IKJEGDCB'S WORKAREA           05600020
R6       EQU    6                 REGISTER 6                            05680020
R7       EQU    7                 REGISTER 7                            05760020
R8       EQU    8                 BASE FOR IKJPARMD                     05840020
R9       EQU    9                 BASE FOR TCOMTAB                      05920020
R10      EQU   10                 USED TO ADDRESS OUTPUT BUFFERS        06000020
R11      EQU   11                 USED TO ADDRESS OUTPUT BUFFERS        06080020
R12      EQU   12                 PROGRAM BASE                          06160020
R13      EQU   13                 POINTER TO IKJEGDCB'S SAVEAREA        06240020
R14      EQU   14                 REGISTER 14                           06320020
R15      EQU   15                 REGISTER 15                           06400020
** THE FOLLOWING EQUATES ARE USED AS DISPLACEMENTS IN INSTRUCTIONS   ** 06480020
** AND TO INDICATE THE RELATIVE ADDRESS OF FIELDS WITHIN A DCB.      ** 06560020
D0       EQU    0                 DISPLACEMENT OF 0                     06640020
D1       EQU    1                 DISPLACEMENT OF 1                     06720020
D2       EQU    2                 DISPLACEMENT OF 2                     06800020
D4       EQU    4                 DISPLACEMENT OF 4                     06880020
D5       EQU    5                 DISPLACEMENT OF 5                     06960020
D8       EQU    8                 DISPLACEMENT OF 8                     07040020
D10      EQU   10                 DISPLACEMENT OF 10                    07120020
D12      EQU   12                 DISPLACEMENT OF 12                    07200020
D14      EQU   14                 DISPLACEMENT OF 14                    07280020
D32      EQU   32                 DISPLACEMENT OF 32                    07360020
D35      EQU   35                 DISPLACEMENT OF 35                    07440020
D40      EQU   40                 DISPLACEMENT OF 40                    07520020
D44      EQU   44                 DISPLACEMENT OF 44                    07600020
D56      EQU   56                 DISPLACEMENT OF 56                    07680020
D68      EQU   68                 DISPLACEMENT OF 68                    07760020
D84      EQU   84                 DISPLACEMENT OF 84                    07840020
** THE FOLLOWING EQUATES ARE USED IN TESTING AND IN DISPLACEMENTS    ** 07920020
HEXBF    EQU   X'BF'              USED TO TURN SECTION HEADER SW OFF    08000020
HEXDF    EQU   X'DF'              USED TO TURN OFF FIELD HEADER SWITCH  08080020
HEXEF    EQU   X'EF'              USED TO TURN OFF FIELD SWITCH         08160020
HEXCF    EQU   X'CF'              USED TO TURN OFF FIELD HEADER AND     08240020
*                                 FIELD SWITCHES                        08320020
HEXFF    EQU   X'FF'              HEX  'FF'                             08400020
HEX10    EQU   X'10'              USED TO TEST OFLGS OF DCB TO          08480020
*                                 DETERMINE IF DCB IS OPEN OR CLOSED    08560020
ALLCHECK EQU   X'80'              SWITCH INDICATING ALL FIELDS ARE TO   08640020
*                                 BE OUTPUTTED                          08720020
SECHDRCK EQU   X'40'              SWITCH INDICATING SECTION HEADER IS   08800020
*                                 TO BE OUTPUTTED                       08880020
HDRCHECK EQU   X'20'              SWITCH INDICATING FIELD HEADERS ARE   08960020
*                                 TO BE OUTPUTTED.                      09040020
FLDCHECK EQU   X'10'              SWITCH INDICATING CONTENTS OF FIELDS  09120020
*                                 ARE TO BE OUTPUTTED                   09200020
ZERO     EQU   X'0000'            USED TO TURN PDE'S OFF AND ALSO TO    09280020
*                                 TEST TO SEE IF FIELD WAS SPECIFIED    09360020
PDELEN   EQU   53                 NUMBER OF BYTES MINUS 1 OF THE FIELD  09440020
*                                 PDES                                  09520020
FLAG     EQU   X'80'              USED TO SET FLAG BYTE OF THE FIELD    09600020
*                                 PDE PASSED TO IKJEGCVT                09680020
TYPE     EQU   X'04'              INDICATES HEXADECIMAL TO IKJEGCVT     09760020
BLANK    EQU   C' '               BLANK                                 09840020
RET16    EQU   16                 USED IN TESTING AND SETTING OF A      09920020
*                                 RETURN CODE OF 16                     10000020
REGSMSK  EQU   X'38'              USED TO TEST FOR ADDRESS              10080020
*                                 BEING SPECIFIED AS REGISTER           10160020
HEXTHREE EQU   X'03'              USED TO TEST FOR ADDRESS BEING ON A   10240020
*                                 FULLWORD BOUNDARY ALSO INDICATES      10320020
*                                 STAE CODE FOR 'LINK FAILED'           10400020
HEXZERO  EQU   X'0000'            USED TO TEST FOR INDIRECT ADDRESSING  10480020
*                                 AGAINST INDIRECT FIELD OF ADDR PDE    10560020
RETCOD0  EQU    0                 USED TO SET RETURN CODES              10640020
RETCODE8 EQU    8                 USED TO SET AND TEST RETURN CODE 8    10720020
RETCOD12 EQU   12                 USED TO SET RETURN CODE TO            10800020
*                                 IKJPARS TO 12                         10880020
RETCOD20 EQU   20                 USED TO SET THE RETURN CODE TO        10960020
*                                 IKJEGMNL TO 20 INDICATING STAE        11040020
*                                 EXIT ROUTINE WAS ENTERED              11120020
FACTOR   EQU   11                 NUMBER OF BYTES PER SECTION           11200020
*                                 OF CODE IN SUBTAB1                    11280020
LINELGTH EQU   80                 DEFAULT LINE LENGTH FOR TERMINAL      11360020
** THE FOLLOWING EQUATES ARE USED IN THE LENGTH FIELDS OF            ** 11440020
** INSTRUCTIONS TO DESCRIBE THE NUMBER OF BYTES TO PROCESS.  THEY ARE** 11520020
** ALSO USED TO INDICATE THE NUMBER OF BYTES A PARTICULAR FIELD IN   ** 11600020
** THE DCB CONTAINS.                                                 ** 11680020
L0       EQU    0                 LENGTH OF 0                           11760020
L1       EQU    1                 LENGTH OF 1                           11840020
L2       EQU    2                 LENGTH OF 2                           11920020
L3       EQU    3                 LENGTH OF 3                           12000020
L4       EQU    4                 LENGTH OF 4                           12080020
L7       EQU    7                 LENGTH OF 7                           12160020
L8       EQU    8                 LENGTH OF 8                           12240020
L9       EQU    9                 LENGTH OF 9                           12320020
L52      EQU   52                 LENGTH OF DCB IN BYTES                12400020
L79      EQU   79                 LENGTH OF 79                          12480020
L159     EQU   159                LENGTH OF 159                         12560020
         EJECT                                                          12640020
         SAVE  (14,12),,*          SAVE IKJEGMNL'S REGISTERS            12720020
         LR    R12,R15             LOAD ADDRESS OF THIS MODULE          12800020
         USING IKJEGDCB,R12        ESTABLISH PROGRAM ADDRESSABILITY     12880020
         USING TCOMTAB,R9          ESTABLISH TCOMTAB ADDRESSABILITY     12960020
         L     R15,REGSAVE2        LOAD ADDRESS OF NEW SAVE AREA        13040020
         ST    R13,D4(R15)         STORE REGISTER 13 IN NEW SAVE AREA   13120020
         ST    R15,D8(R13)         STORE NEW SAVE AREA ADDRESS          13200020
         LR    R13,R15             R13 NOW POINTS TO NEW SAVE AREA      13280020
         L     R6,WORKAREA         LOAD ADDRESS OF TEST WORKAREA        13360020
         USING TSTCWORK,R6         ESTABLISH ADDRESSABILITY             13440020
         LA    R5,CWORKCMD         SKIP CONVERT WORK AREA               13520020
         USING DCBWKARA,R5         ESTABLISH WORKAREA ADDRESSABILITY    13600020
         DROP  R6                  RELEASE R6 FOR LATER USE             13680020
         L     R6,MSGADDR          POINT TO MESSAGE CSECT               13760020
         USING IKJEGMSG,R6         ESTABLISH ADDRESSABILITY TO MSG      13840020
*                                  CSECT                                13920020
         STM   R14,R12,D12(R13)    SAVE LISTDCB'S REGISTERS             14000020
         SPACE                                                          14080020
**********************************************************************  14160020
*                      ISSUE STAE                                    *  14240020
**********************************************************************  14320020
         SPACE                                                          14400020
         LA    R4,STATBL           GET ADDRESS OF STAE ABEND TABLE      14480020
         ST    R4,ABENTAB1         SAVE THIS ADDRESS FOR STAE ROUTINE   14560020
         MVC   TSTRETRY+D1(L3),RETRYADR  SAVE ADDR OF RETRY ROUTINE     14640020
         LA    R15,STAEAREA        GET ADDRESS OF STAE WORKAREA         14720020
         MVC   D0(STAELEN,R15),STAELIST PUT STAE LIST FORM INTO         14800020
*                                  WORKAREA                             14880020
         L     R4,TSTSTAE          GET ADDR OF STAE EXIT ROUTINE        14960020
         STAE  (4),MF=(E,(15))     ISSUE STAE MACRO                     15040020
         LTR   R15,R15             RETURN CODE ZERO FROM STAE           15120020
SMTSTAE  DS    0H                  SMT LABEL FOR TEST CASE TDCB2700     15170020
         BZ    SETPARSE            YES, CONTINUE PROCESSING             15200020
STAEMSG1 EQU   *                                                        15280020
**STORAGE FOR STAE REQUEST WAS NOT AVAILABLE.  SET UP TO WRITE MSG   ** 15360020
         LA    R1,MSG02            NO, POINT TO MSG02 FOR IKJ57207I     15440020
         B     MSGIOCTD            GO TO MESSAGE ROUTINE                15520020
SETPARSE EQU   *                                                        15600020
**THIS CODE SETS UP TO GO TO IKJPARS TO VALIDITY CHECK THE COMMAND   ** 15680020
**BUFFER.                                                            ** 15760020
         XC    PPLLIST(TYPECODE-PPLLIST),PPLLIST  CLEAR WORKAREA        15840020
         LR    R4,R5               ESTABLISH ADDRESSABILITY TO PARSE    15920020
         USING PPL,R4              PARAMETER LIST                       16000020
         MVC   PPLUPT(L4),TSTUPT   PUT ADDR UPT INTO PARAMETER LIST     16080020
         MVC   PPLECT(L4),TSTECT   PUT ADDR ECT INTO PARAMETER LIST     16160020
         MVC   PPLECB(L4),TSTCPECB PUT ADDR ECB INTO PARAMETER LIST     16240020
         MVC   PPLPCL(L4),PCLADDR  PUT ADDR OF PCL INTO PARAMETER LIST  16320020
         LA    R2,TSTANSPL         PUT POINTER TO ANSWER PLACE INTO     16400020
         ST    R2,PPLANS           PARAMETER LIST TO PARSE              16480020
         MVC   PPLCBUF(L4),INBUF   PUT ADDR OF COMMAND BUFFER INTO      16560020
*                                  PARAMETER LIST FOR PARSE             16640020
         ST    R13,PPLUWA          PUT POINTER TO SAVE AREA INTO LIST   16720020
         LR    R1,R4               REGISTER 1 POINTS TO PARAMETER LIST  16800020
         LINK  EP=IKJPARS          GO TO PARSE                          16960020
PARSBLOW EQU   *                   LABEL USED BY STAE RETRY ROUTINE     17040020
SMTPARS  DS    0H                  SMT LABEL FOR TEST CASE TDCB2600     17090020
         B     PARSDONE            GO TO PARSDONE                       17120020
IKJEGDVK EQU   *                                                        17200020
** THIS CODE IS RESPONSIBLE FOR ANALYSING THE PARAMETERS FOR LISTDCB ** 17250020
** AFTER IKJPARS HAS CHECKED THEM FOR SYMTAX ERRORS.  CONTROL IS     ** 17260020
** PASSED TO THIS ROUTINE BY A LINK FROM IKJPARS.                    ** 17270020
         SAVE  (14,12),,*          SAVE PARSE REGISTERS                 17280020
         L     R9,D4(R1)           OBTAIN ADDRESS OF LISTDCB SAVEAREA   17360020
         L     R12,D68(R9)         RESTORE PROGRAM ADDRESSABILITY       17440020
         L     R5,D40(R9)          RESTORE WORKAREA ADDRESSABILITY      17520020
         L     R6,D44(R9)          RESTORE MSG CSECT ADDRESSABILITY     17600020
         L     R9,D56(R9)          RESTORE TCOMTAB ADDRESSABILITY       17680020
         L     R15,REGSAVE3        LOAD SAVE AREA FOR IKJEGCVT          17760020
         ST    R13,D4(R15)         SAVE ADDR OF PARSE'S SAVEAREA        17840020
         ST    R15,D8(R13)         SAVE ADDR OF VALIDITY CHECK RTN'S    17920020
*                                  SAVEAREA IN PARSE'S SAVEAREA         18000020
         LR    R13,R15             LOAD NEW SAVEAREA ADDRESS            18080020
         L     R2,D0(R1)           GET ADDRESS OF PDE                   18160020
         LA    R7,D8(R1)           SAVE ADDR OF 3RD PARAMETER FROM      18240020
*                                  PARSE                                18320020
         USING IKJPARMA,R2         ESTABLISH ADDRESSABILITY TO          18400020
*                                  PARAMETER DESCRIPTOR ENTRY (PDE)     18480020
         CLC   PDEINDCT(L2),WORDZERO TEST TO SEE IF INDIRECT            18560020
*                                  ADDRESSING WAS USED                  18640020
         BNE   CONVERT             NO, GO SET UP FOR IKJEGCVT           18720020
         TM    PDEFLG4,REGSMSK     YES, IS TYPE OF ADDR REGISTER        18800020
         BZ    CONVERT             NO, GO SET UP FOR IKJEGCVT           18880020
         LA    R1,MSG05            YES, POINT TO MSG05 FOR IKJ57208I    18960020
         B     VALMSGIO            GO TO VALIDITY CHECK MESSAGE I/O RTN 19040020
CONVERT  EQU   *                                                        19120020
** THIS ROUTINE SETS UP THE PARAMETERS AND THEN GOES TO IKJEGCVT FOR ** 19200020
** BINARY CONVERSION OF THE DCB ADDRESS.                             ** 19280020
         LR    R1,R2               PUT ADDRESS OF ADDR PDE INTO REG 1   19360020
         LNR   R1,R1               NEGATE REGISTER 1 TO INDICATE ADDR   19440020
*                                  CONVERSION                           19520020
         XR    R0,R0               RO IS POSITIVE TO INDICATE BINARY    19600020
*                                  CONVERSION                           19680020
         L     R15,TSTCONVT        OBTAIN ADDR OF ENTRY POINT TO        19760020
*                                  IKJEGCVT FROM TCOMTAB                19840020
         BALR  R14,R15             GO TO IKJEGCVT                       19920020
         LPR   R1,R1               RESET REGISTER 1 TO POSITIVE         20000020
         B     CONVTAB(R15)        BRANCH INTO TABLE INDEXED BY         20080020
*                                  CONTENTS OF REGISTER 15              20160020
CONVTAB  EQU   *                                                        20240020
         B     BOUNDCK             0-CONTINUE PROCESSING                20320020
         B     SETMSG              4-SET BY IKJEGCVT-MOVE MSG ADDR      20400020
         B     SETMSG2             8-SET BY IKJEGSYM-MOVE MSG ADDR      20480020
         B     SETMSG2             12-SET BY IKJEGSYM-MOVE MSG ADDR     20560020
         B     SET12               16-ATTENTION INTERRUPT-RETURN        20640020
         B     SET12               20-IKJEGCVT OR IKJEGSYM BLEW         20720020
SETMSG2  EQU   *                                                        20800020
         MVC   D0(L4,R7),PDEUSER   PUT MSG ADDR INTO PARAMETER LIST     20880020
SET12    EQU   *                                                        20960020
         ST    R15,REG15           SAVE RETURN CODE FOR LATER USE       21040020
         LA    R15,RETCOD12        SET RETURN CODE TO 12                21120020
         B     PARSRTRN            GO RETURN TO IKJPARS                 21200020
SETMSG   EQU   *                                                        21280020
         MVC   D0(L4,R7),PDEUSER   PUT MSG ADDR INTO PARAMETER LIST     21360020
SET8     EQU   *                                                        21440020
         LA    R15,RETCODE8        SET RETURN CODE TO 8                 21520020
         B     PARSRTRN            PREPARE TO RETURN TO IKJPARS         21600020
         SPACE                                                          21680020
BOUNDCK  EQU   *                                                        21760020
         L     R3,PDEUSER          LOAD SAVEPTR (WORD PASSED TO PARSE)  21840020
         LTR   R3,R3               WAS ADDRESS RESOLVED BY IKJEGSYM     21920020
         BP    NOSYM               NO, BRANCH TO GET ADDRESS            22000020
         L     R3,D0(R3)           YES, LOAD CONVERTED BINARY ADDRESS   22080020
NOSYM    EQU    *                                                       22160020
         L     R4,REGSAVE2         LOAD ADDR OF LISTDCBS REGISTERS      22240020
         ST    R3,D32(R4)          SAVE CONVERTED ADDRESS IN REG 3      22320020
*                                  FOR MAINLINE CODE                    22400020
         LA    R3,L52(R3)          GET ADDRESS OF END OF DCB            22480020
         C     R3,TSTTOP           IS ADDRESS IN CORE                   22560020
         BNH   BOUNDARY            YES, GO CHECK BOUNDARY ALIGNMENT     22640020
         LA    R1,MSG03            NO, POINT TO MSG03 FOR IKJ57208I     22720020
         B     VALMSGIO            GO TO VALIDITY CHECK MESSAGE I/O RTN 22800020
BOUNDARY EQU   *                                                        22880020
         TM    D35(R4),HEXTHREE    IS ADDRESS ON FULL WORD BOUNDARY     22960020
         BZ    SET0                IF YES, RETURN TO PARSE              23040020
         LA    R1,MSG04            NO, POINT TO MSG04 FOR IKJ57208I     23120020
VALMSGIO EQU   *                                                        23200020
** THIS SETS UP TO GO TO IKJEGIO TO WRITE A MESSAGE                  ** 23280020
         MVC   D0(L4,R7),D4(R1)    PUT 2ND LEVEL MSG INTO PARMLIST      23360020
         MVC   OUTPTR2(L4),D4(R1)  PUT 2ND LEVEL MSG INTO PARM LIST     23440020
*                                  FOR IO ROUTINE                       23520020
         L     R7,OUTBUF           GET ADDRESS OF OUTPUT BUFFER         23600020
         ST    R7,OUTPTR1          SAVE ADDRESS OF OUTPUT BUFFER        23680020
         L     R1,D0(R1)           GET ADDRESS OF FIRST LEVEL MESSAGE   23760020
         XC    D0(L4,R7),D0(R7)    CLEAR 1ST HALF WORD OF OUTPUT        23840020
*                                  BUFFER                               23920020
         XR    R4,R4               CLEAR REGISTER 4                     24000020
         LH    R4,D0(R1)           PUT LENGTH OF MESSAGE INTO REGISTER  24080020
         BCTR  R4,D0               TAKE ONE FROM LENGTH OF MSG          24160020
         EX    R4,MOVEMSG          GO MOVE FIRST LEVEL MESSAGE INTO     24240020
*                                  OUTPUT BUFFER                        24320020
         LA    R4,D1(R4)           RESTORE REG 4 TO LENGTH OF MSG       24400020
         AR    R7,R4               UPDATE TO NEXT AVAILABLE POSITION    24480020
         LR    R0,R2               PASS ADDR OF ADDR PDE TO ADDR BUILT  24560020
*                                  ROUTINE-IKJEGBLD                     24640020
         LR    R1,R7               PASS POINTER TO AREA TO PUT ADDR     24720020
*                                  STRING BUILT BY ADDR BUILD ROUTINE   24800020
         L     R15,TSTADDR         GET ADDRESS OF ADDRESS ROUTINE       24880020
         BALR  R14,R15             GO TO ADDRESS BUILD ROUTINE          24960020
         AR    R4,R0               UPDATE LENGTH OF MESSAGE TO INCLUDE  25040020
*                                  ADDRESS STRING                       25120020
         MVI   D0(R1),PLUSSIGN     INDICATE 2ND LEVEL MSG EXISTS        25200020
         LA    R4,D1(R4)           UPDATE LENGTH OF MESSAGE             25280020
         L     R7,OUTPTR1          GET ADDRESS OF FIRST MSG ENTRY       25360020
         STH   R4,D0(R7)           PUT TOTAL LENGTH INTO MESSAGE ENTRY  25440020
         LA    R1,OUTPTR1          GET ADDRESS OF ADDRESS PARM LIST     25520020
         LNR   R1,R1               NEGATE REGISTER 1 WITH ADDRESS       25600020
*                                  COMPLEMENT                           25680020
         L     R15,TPUTADDR        LOAD ADDRESS OF IKJEGIO              25760020
         BALR  R14,R15             OUTPUT THE MESSAGE                   25840020
         LPR   R1,R1               RESTORE REGISTER 1 TO POSITIVE       25920020
         LTR   R15,R15             RETURN CODE FROM IO A ZERO           26000020
         BZ    SET8                YES, MESSAGE WAS WRITTEN-RETURN      26080020
         B     SET12               NO, MESSAGE WAS NOT WRITTEN-RETURN   26160020
SET0     EQU   *                                                        26240020
         XR    R15,R15             INDICATE PARAMETER IS VALID          26320020
PARSRTRN EQU   *                                                        26400020
         DROP  R2                  RELEASE ADDRESSABILITY TO ADDR PDE   26480020
         L     R13,D4(R13)         RESTORE ADDRESS OF PARSE SAVEAREA    26560020
         RETURN (14,12),,RC=(15)   RESTORE REGISTERS AND RETURN         26640020
MOVEMSG  MVC   D4(L0,R7),D4(R1)    MOVE FIRST LEVEL MESSAGE             26720020
*********************************************************************** 26800020
*        THE FOLLOWING CODE IS EXECUTED UPON COMPLETION OF IKJPARS    * 26880020
*********************************************************************** 26960020
PARSDONE EQU   *                                                        27040020
** THE FOLLOWING IS A BRANCH TABLE USED TO DETERMINE WHERE CONTROL   ** 27120020
** SHOULD BE GIVEN AFTER RETURNING FROM IKJPARS.                     ** 27200020
         B     PARSTAB(R15)       BRANCH TO TABLE INDEXED BY CONTENTS   27280020
*                                 OF REGISTER 15                        27360020
PARSTAB  EQU   *                                                        27440020
         B     PDLADDR            RETURN CODE 0-CONTINUE PROCESSING     27520020
         B     FLUSHIT            RETURN CODE 4-GO BACK TO IKJEGMNL     27600020
         B     DCBRC16            RETURN CODE 8-ATTENTION INTERRUPT     27680020
         B     PARMSG2            RETURN CODE 12-GO WRITE MESSAGE       27760020
         B     STAEMSG1           RETURN CODE 16-GO WRITE MESSAGE       27840020
         B     CHKRET             RETURN CODE 20-GO CHECK FOR CODE      27920020
PARMSG2  EQU   *                                                        28320020
** THIS SETS UP TO WRITE MESSAGES IKJ57206I                         **  28400020
         LA    R1,MSG01           POINT TO MSG01                        28480020
         B     MSGIOCTD           GO PREPARE TO WRITE MESSAGE           28560020
PDLADDR  EQU   *                                                        28640020
         DROP  R6                 RELEASE REGISTER 6 FOR LATER USE      28720020
         L     R8,TSTANSPL        OBTAIN ADDRESS OF PARSE PARAMETER     28800020
*                                 DESCRIPTOR LIST (PDL)                 28880020
         USING IKJPARMD,R8        ESTABLISH PDL ADDRESSABILITY          28960020
FIELDCHK EQU   *                                                        29040020
** THIS CODE TESTS TO SEE IF THE FIELD PARAMETER WAS CODED ON THE    ** 29120020
** CONTROL STATEMENT.                                                ** 29200020
         USING IHADCB,R3          ESTABLISH ADDRESSABILITY TO DCB       29280020
         CLC   DCBFIELD(L2),WORDZERO WAS FIELD PARAMETER SPECIFIED      29360020
         BNE   SCANPDES           YES, GO SCAN DCBFIELDS                29440020
         OI    OUTPUTSW,ALLCHECK  NO, INDICATE ALL DCBFIELDS ARE TO BE  29520020
*                                 OUTPUTTED                             29600020
         MVI   RELAD,HEXFF        SET THE FIRST PARSE DESCRIPTOR        29680020
*                                 ENTRY (PDE) TO NON ZERO               29760020
         MVC   RELAD+D1(PDELEN),RELAD  SET REMAINING PDES NON ZERO      29840020
         MVC   FTEK(L4),WORDZERO  ZERO DCBFTEK AND DCBBFALN PDES        29920020
         TM    DCBOFLGS,HEX10     IS THIS AN OPEN DCB                   30000020
         BZ    CLOSED             NO, GO HANDLE FOR CLOSED              30080020
         MVI   DDNAM,HEXZERO      YES, ZERO OUT PDES DESCRIBING A       30160020
         MVC   DDNAM+D1(L7),DDNAM CLOSED DCB                            30240020
         B     PRINTCHK           GO SEE IF PRINT WAS SPECIFIED         30320020
CLOSED   EQU   *                                                        30400020
         MVI   TIOT,ZERO          ZERO OUT PDES DESCRIBING AN           30480020
         MVC   TIOT+D1(L9),TIOT   OPEN DCB                              30560020
         B     PRINTCHK           GO SEE IF PRINT WAS SPECIFIED         30640020
SCANPDES EQU   *                                                        30720020
         CLC   OFLGS(L2),WORDZERO WAS DCBOFLGS SPECIFIED                30800020
         BE    TRIHDR             NO, GO CHECK COMMON HEADER FIELD      30880020
         TM    DCBOFLGS,HEX10     YES, IS THIS AN OPEN DCB              30960020
         BZ    TRIHDR             NO, GO CHECK COMMON HEADER FIELD      31040020
         MVC   OFLGS(L2),WORDZERO YES, TURN OFF CLOSED DCBOFLGS PDE     31120020
         MVC   OFLGS2(L2),HEXFFFF TURN ON OPEN DCBOFLGS PDE             31200020
TRIHDR   EQU   *                                                        31280020
** THIS CODE TESTS TO SEE IF ONE OF THE FOLLOWING OR ALL OF THE      ** 31360020
** FOLLOWING FIELDS ARE SPECIFIED- DCBHIARC,DCBFTEK OR DCBBFALN      ** 31440020
** THE CODE WILL LEAVE ONE OF THE PDES ON TO BE PROCESSED AND WILL   ** 31520020
** TURN THE REST OF THEM OFF.  THIS IS TO AVOID OUTPUTTING THE SAME  ** 31600020
** FIELD THREE TIMES.                                                ** 31680020
         CLC   HIARC(L2),WORDZERO WAS THE DCBHIARC FIELD SPECIFIED      31760020
         BNE   CLEAR2             YES, CLEAR DCBFTEK AND DCBBFALN PDES  31840020
         CLC   FTEK(L2),WORDZERO  WAS THE DCBFTEK FIELD SPECIFIED       31920020
         BE    PRINTCHK           NO, GO SEE IF PRINT WAS SPECIFIED     32000020
         MVC   BFALN(L2),WORDZERO YES, ZERO OUT DCBBFALN PDE            32080020
         B     PRINTCHK           GO SEE IF PRINT WAS SPECIFIED         32160020
CLEAR2   EQU   *                                                        32240020
         MVC   FTEK(L4),WORDZERO  CLEAR DCBFTEK AND DCBBFALN PDES       32320020
PRINTCHK EQU   *                                                        32400020
** THIS CODE IS RESPONSIBLE FOR DETERMINING IF THE PRINT PARAMETER   ** 32480020
** WAS SPECIFED.                                                     ** 32560020
         CLC   PRINT(L2),WORDZERO WAS PRINT SPECIFIED                   32640020
         BNE   PRNTSPEC           YES, PDE NON ZERO BRANCH              32720020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)     INITIALIZE OUTPUT FLAGS    32800020
*                                 IN TCOMTAB                            32880020
         B     TABLESCN           GO DETERMINE LENGTH OF OUTPUT LINE    32960020
PRNTSPEC EQU   *                                                        33040020
** THIS CODE IS EXECUTED WHEN THE USER HAS SPECIFIED AN OUTPUT DATA  ** 33120020
** SET.  IT SAVES THE ADDRESS OF THE DSNAME PDE FOUND IN THE PDL     ** 33200020
** PASSED BY PARSE AND SETS A FLAG IN TCOMTAB TO INDICATE THIS       ** 33280020
** CONDITION TO IKJEGIO.                                             ** 33360020
         LA    R2,DSNAM           LOAD ADDRESS OF DSNAME PDE            33440020
         OI    TSTFLGS1,TSTPRINT  SET FLAG IN TCOMTAB TO INDICATE       33520020
*                                 USER SPECIFIED OUTPUT DATA SET        33600020
         ST    R2,PRINTFLG        STORE ADDR OF DSNAME PDE              33680020
TABLESCN EQU   *                                                        33760020
** THIS CODE IS RESPONSIBLE FOR DETERMINING THE LENGTH OF THE OUTPUT ** 33840020
** LINE.  THE DEFAULT IS 80 IF THE USER SPECIFIED AN OUTPUT LINE     ** 33920020
** GREATER THAN 80 OR LESS THAN 40.  IKJEGDCB TRIES TO GIVE A GOOD   ** 34000020
** FORMAT FOR THOSE OUTPUT LINES IN THE RANGE OF 40 TO 80.           ** 34080020
         LA    R4,LINELGTH        LOAD DEFAULT LINE LENGTH              34160020
         CH    R4,TMPLL           COMPARE TO TERMINAL LINE LENGTH       34240020
         BNH   LINESET            BRANCH IF 80 IS LOW OR EQUAL TO       34320020
*                                 TERMINAL LINE LENGTH                  34400020
         LA    R4,D40                                                   34480020
         CH    R4,TMPLL           COMPARE 40 WITH TMP LINE LENGTH       34560020
         BH    DEFAULT            BRANCH IF 40 IS HIGHER THAN TERMINAL  34640020
*                                 LINE LENGTH                           34720020
         LH    R4,TMPLL           USE SPECIFIED LINE LENGTH             34800020
         B     LINESET            GO SET LINE LENGTH                    34880020
DEFAULT  EQU   *                                                        34960020
         LA    R4,LINELGTH        DEFAULT LINE LENGTH                   35040020
LINESET  EQU   *                                                        35120020
         STH   R4,LINELEN         STORE OUTPUT LINE LENGTH              35200020
         L     R10,OUTBUF         GET ADDRESS OF OUTPUT BUFFER          35280020
         MVI   D4(R10),BLANK      BLANK OUT OUTPUT BUFFER               35360020
         MVC   D5(L159,R10),D4(R10)                                     35440020
         XC    D0(L4,R10),D0(R10) CLEAR 1ST 4 BYTES OF OUTBUF           35520020
         LA    R2,OFLGS2+D2       GET ADDRESS OF END OF DSECT           35600020
         ST    R2,ENDEND          STORE LAST PDE ADDRESS+2              35680020
         XR    R2,R2              INITIALIZE LENGTH OF OUTPUT TO ZERO   35760020
         LA    R6,RELAD           POINT TO FIRST PDE                    35840020
PDECHECK EQU   *                                                        35920020
         CLC   D0(L2,R6),WORDZERO IS THIS FIELD DESIRED                 36000020
         BNE   SBRTNSVR           BRANCH IF DESIRED                     36080020
PDECHK   EQU   *                                                        36160020
         LA    R6,D2(R6)          NO, POINT TO NEXT PDE                 36240020
         C     R6,ENDEND          ARE THERE MORE PDE'S                  36320020
         BE    PDLEND             NO, GO TO END PROCESSING              36400020
         B     PDECHECK           YES, CHECK NEXT PDE                   36480020
SBRTNSVR EQU   *                                                        36560020
         LR    R11,R6             PRESERVE R6                           36640020
         LA    R7,RELAD           ADDRESS OF FIRST PDE                  36720020
         SR    R11,R7             FIND RELATIVE POSITION OF PDE         36800020
         LA    R10,FACTOR         LOAD MULTIPLICATION FACTOR            36880020
         LA    R7,SUBTAB1         LOAD ADDRESS OF TABLE                 36960020
         MR    R10,R10            COMPUTE PROPER OFFSET                 37040020
         AR    R7,R11             ADD OFFSET TO BASE                    37120020
         BR    R7                 GO TO PROPER SUBROUTINE               37200020
         SPACE                                                          37280020
*********************************************************************** 37360020
* THE FOLLOWING CODE CONSISTS OF 27 SUBROUTINES CORRESPONDING TO THE  * 37440020
* FIELDS OF DCB.  EACH SUBROUTINE MOVES THE RELATIVE ADDRESS, FIELD   * 37520020
* LENGTH, HEADER LENGTH, AND HEADER TO A COMMON BUFFER.  CONTROL IS   * 37600020
* THEN PASSED EITHER TO THE CONVERSION ROUTINE OR TO A HEADER OUTPUT  * 37680020
* ROUTINE AND THEN TO A CONVERSION ROUTINE.  THE SUBROUTINE FOR DDNAM * 37760020
* WILL PASS CONTROL TO A VALIDITY CHECKING ROUTINE.  IT IS ESSENTIAL  * 37840020
* FOR PROPER LOGIC FLOW THAT EACH SUBROUTINE HAVE THE SAME LENGTH.    * 37920020
*********************************************************************** 38000020
         SPACE                                                          38080020
SUBTAB1  EQU   *                                                        38160020
**THE FOLLOWING CODE SETS UP FOR FIELDS IN THE DEVICE INTERFACE         38240020
DSRELAD  EQU    *                                                       38320020
         MVC   HDRBUFFR(L'HDRRELAD),HDRRELAD  MOVE HEADING IN           38400020
         MVI   HDRLENTH,L'HDRRELAD MOVE LENGTH OF HEADER IN             38480020
         MVI   FLDLENTH,L4         MOVE IN FIELD LENGTH                 38560020
         LA    R4,DCBRELAD         MOVE IN RELATIVE ADDRESS             38640020
         B     HDROUTPT            GO WRITE SECTION HDR OUT             38720020
DSKEYCN  EQU    *                                                       38800020
         MVC   HDRBUFFR(L'HDRKEYCN),HDRKEYCN MOVE HEADING IN            38880020
         MVI   HDRLENTH,L'HDRKEYCN MOVE LENGTH OF HEADER IN             38960020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 39040020
         LA    R4,DCBKEYCN         MOVE IN RELATIVE ADDRESS             39120020
         B     CVTANDIO            GO SET UP FOR CONVERSION             39200020
DSFDAD   EQU    *                                                       39280020
         MVC   HDRBUFFR(L'HDRFDAD),HDRFDAD  MOVE IN HEADING             39360020
         MVI   HDRLENTH,L'HDRFDAD  MOVE LENGTH OF HEADER IN             39440020
         MVI   FLDLENTH,L8         MOVE IN FIELD LENGTH                 39520020
         LA    R4,DCBFDAD          MOVE IN RELATIVE ADDRESS             39600020
         B     CVTANDIO            GO SET UP FOR CONVERSION             39680020
DSDVTBL  EQU    *                                                       39760020
         MVC   HDRBUFFR(L'HDRDVTBL),HDRDVTBL  MOVE HEADING IN           39840020
         MVI   HDRLENTH,L'HDRDVTBL MOVE LENGTH OF HEADER IN             39920020
         MVI   FLDLENTH,L3         MOVE LENGTH OF FIELD IN              40000020
         LA    R4,DCBDVTBL+D1      MOVE IN RELATIVE ADDRESS             40080020
         B     CVTANDIO            GO SET UP FOR CONVERSION             40160020
DSKEYLE  EQU    *                                                       40240020
         MVC   HDRBUFFR(L'HDRKEYLE),HDRKEYLE   MOVE HEADING IN          40320020
         MVI   HDRLENTH,L'HDRKEYLE MOVE LENGTH OF HEADING IN            40400020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 40480020
         LA    R4,DCBKEYLE         MOVE IN RELATIVE ADDRESS             40560020
         B     CVTANDIO            GO SET UP FOR CONVERSION             40640020
DSDEVT   EQU    *                                                       40720020
         MVC   HDRBUFFR(L'HDRDEVT),HDRDEVT  MOVE HEADING IN             40800020
         MVI   HDRLENTH,L'HDRDEVT  MOVE LENGTH OF HEADING IN            40880020
         MVI   FLDLENTH,L1         MOVE LENGTH OF FIELD IN              40960020
         LA    R4,DCBDEVT          MOVE IN RELATIVE ADDRESS             41040020
         B     CVTANDIO            GO SET UP FOR CONVERSION             41120020
DSTRBAL  EQU    *                                                       41200020
         MVC   HDRBUFFR(L'HDRTRBAL),HDRTRBAL  MOVE HEADING IN           41280020
         MVI   HDRLENTH,L'HDRTRBAL MOVE LENGTH OF HEADING IN            41360020
         MVI   FLDLENTH,L2         MOVE LENGTH OF FIELD IN              41440020
         LA    R4,DCBTRBAL         MOVE IN RELATIVE ADDRESS             41520020
         B     CVTANDIO            GO SET UP FOR CONVERSION             41600020
**THE FOLLOWING CODE SETS UP FOR FIELDS IN THE COMMON INTERFACE         41680020
DSBUFNO  EQU    *                                                       41760020
         MVC   HDRBUFFR(L'HDRBUFNO),HDRBUFNO  MOVE HEADING IN           41840020
         MVI   HDRLENTH,L'HDRBUFNO MOVE LENGTH OF HEADING IN            41920020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 42000020
         LA    R4,DCBBUFNO         MOVE IN RELATIVE ADDRESS             42080020
         B     HDROUTPT            GO WRITE SECTION HEADER OUT          42160020
DSBUFCB  EQU    *                                                       42240020
         MVC   HDRBUFFR(L'HDRBUFCB),HDRBUFCB   MOVE HEADING IN          42320020
         MVI   HDRLENTH,L'HDRBUFCB MOVE LENGTH OF HEADING IN            42400020
         MVI   FLDLENTH,L3         MOVE LENGTH OF FIELD IN              42480020
         LA    R4,DCBBUFCB+D1      MOVE IN RELATIVE ADDRESS             42560020
         B     CVTANDIO            GO SET UP FOR CONVERSION             42640020
DSBUFL   EQU    *                                                       42720020
         MVC   HDRBUFFR(L'HDRBUFL),HDRBUFL  MOVE HEADING IN             42800020
         MVI   HDRLENTH,L'HDRBUFL  MOVE LENGTH OF HEADING IN            42880020
         MVI   FLDLENTH,L2         MOVE LENGTH OF FIELD IN              42960020
         LA    R4,DCBBUFL          MOVE IN RELATIVE ADDRESS             43040020
         B     CVTANDIO            GO SET UP FOR CONVERSION             43120020
DSDSORG  EQU    *                                                       43200020
         MVC   HDRBUFFR(L'HDRDSORG),HDRDSORG  MOVE HEADING IN           43280020
         MVI   HDRLENTH,L'HDRDSORG MOVE LENGTH OF HEADING IN            43360020
         MVI   FLDLENTH,L2         MOVE LENGTH OF FIELD IN              43440020
         LA    R4,DCBDSORG         MOVE IN RELATIVE ADDRESS             43520020
         B     CVTANDIO            GO SET UP FOR CONVERSION             43600020
DSIOBAD  EQU   *                                                        43680020
         MVC   HDRBUFFR(L'HDRIOBAD),HDRIOBAD  MOVE HEADING IN           43760020
         MVI   HDRLENTH,L'HDRIOBAD MOVE LENGTH OF HEADING IN            43840020
         MVI   FLDLENTH,L4         MOVE LENGTH OF FIELD IN              43920020
         LA    R4,DCBIOBAD         MOVE IN RELATIVE ADDRESS             44000020
         B     CVTANDIO            GO SET UP FOR CONVERSION             44080020
**THE FOLLOWING CODE SETS UP FOR FIELDS IN THE FOUNDATION EXTENSION     44160020
DSHIARC  EQU   *                                                        44240020
         MVC   HDRBUFFR(L'HDRHIARC),HDRHIARC  MOVE HEADING IN           44320020
         MVI   HDRLENTH,L'HDRHIARC MOVE LENGTH OF HEADING IN            44400020
         MVI   FLDLENTH,L1         MOVE LENGTH OF FIELD IN              44480020
         LA    R4,DCBBFTEK         MOVE IN RELATIVE ADDRESS             44560020
         B     HDROUTPT            GO WRITE SECTION HEADER OUT          44640020
DSBFTEK  EQU   *                                                        44720020
         MVC   HDRBUFFR(L'HDRBFTEK),HDRBFTEK  MOVE HEADING IN           44800020
         MVI   HDRLENTH,L'HDRBFTEK MOVE LENGTH OF HEADER IN             44880020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 44960020
         LA    R4,DCBBFTEK         MOVE IN RELATIVE ADDRESS             45040020
         B     CVTANDIO            GO SET UP FOR CONVERSION             45120020
DSBFALN  EQU   *                                                        45200020
         MVC   HDRBUFFR(L'HDRBFALN),HDRBFALN  MOVE HEADING IN           45280020
         MVI   HDRLENTH,L'HDRBFALN MOVE LENGTH OF HEADING IN            45360020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 45440020
         LA    R4,DCBBFALN         MOVE IN RELATIVE ADDRESS             45520020
         B     CVTANDIO            GO SET UP FOR CONVERSION             45600020
DSEODAD  EQU   *                                                        45680020
         MVC   HDRBUFFR(L'HDREODAD),HDREODAD  MOVE HEADING IN           45760020
         MVI   HDRLENTH,L'HDREODAD MOVE LENGTH OF HEADING IN            45840020
         MVI   FLDLENTH,L3         MOVE IN FIELD LENGTH                 45920020
         LA    R4,DCBEODAD+D1      MOVE IN RELATIVE ADDRESS             46000020
         B     CVTANDIO            GO SET UP FOR CONVERSION             46080020
DSRECFM  EQU   *                                                        46160020
         MVC   HDRBUFFR(L'HDRRECFM),HDRRECFM  MOVE HEADING IN           46240020
         MVI   HDRLENTH,L'HDRRECFM MOVE LENGTH OF HEADING IN            46320020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 46400020
         LA    R4,DCBRECFM         MOVE IN RELATIVE ADDRESS             46480020
         B     CVTANDIO            GO SET UP FOR CONVERSION             46560020
DSEXLST  EQU   *                                                        46640020
         MVC   HDRBUFFR(L'HDREXLST),HDREXLST  MOVE HEADING IN           46720020
         MVI   HDRLENTH,L'HDREXLST MOVE IN LENGTH OF HEADING            46800020
         MVI   FLDLENTH,L3         MOVE IN FIELD LENGTH                 46880020
         LA    R4,DCBEXLST+D1      MOVE IN RELATIVE ADDRESS             46960020
         B     CVTANDIO            GO SET UP FOR CONVERSION             47040020
**THE FOLLOWING CODE SETS UP FOR FIELDS IN A CLOSED FOUNDATION          47120020
DSDDNAM  EQU   *                                                        47200020
         MVC   HDRBUFFR(L'HDRDDNAM),HDRDDNAM  MOVE HEADING IN           47280020
         MVI   HDRLENTH,L'HDRDDNAM MOVE LENGTH OF HEADING IN            47360020
         MVI   FLDLENTH,L8         MOVE IN FIELD LENGTH                 47440020
         LA    R4,DCBDDNAM         MOVE IN RELATIVE ADDRESS             47520020
         B     HDROUTPT            GO WRITE SECTION HEADER OUT          47600020
DSOFLG1  EQU   *                                                        47680020
         MVC   HDRBUFFR(L'HDROFLGS),HDROFLGS MOVE HEADING IN            47760020
         MVI   HDRLENTH,L'HDROFLGS MOVE LENGTH OF HEADING IN            47840020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 47920020
         LA    R4,DCBOFLGS         MOVE IN RELATIVE ADDRESS             48000020
         B     CVTANDIO            GO SET UP FOR CONVERSION             48080020
DSIFLG   EQU   *                                                        48160020
         MVC   HDRBUFFR(L'HDRIFLG),HDRIFLG  MOVE HEADING IN             48240020
         MVI   HDRLENTH,L'HDRIFLG  MOVE LENGTH OF HEADING IN            48320020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 48400020
         LA    R4,DCBIFLG          MOVE IN RELATIVE ADDRESS             48480020
         B     CVTANDIO            GO SET UP FOR CONVERSION             48560020
DSMACR   EQU   *                                                        48640020
         MVC   HDRBUFFR(L'HDRMACR),HDRMACR  MOVE HEADING IN             48720020
         MVI   HDRLENTH,L'HDRMACR  MOVE LENGTH OF HEADING IN            48800020
         MVI   FLDLENTH,L2         MOVE IN FIELD LENGTH                 48880020
         LA    R4,DCBMACR          MOVE IN RELATIVE ADDRESS             48960020
         B     CVTANDIO            GO SET UP FOR CONVERSION             49040020
**THE FOLLOWING CODE SETS UP FOR FIELDS IN AN OPEN FOUNDATION           49120020
DSTIOT   EQU   *                                                        49200020
         MVC   HDRBUFFR(L'HDRTIOT),HDRTIOT  MOVE HEADING IN             49280020
         MVI   HDRLENTH,L'HDRTIOT  MOVE LENGTH OF HEADING IN            49360020
         MVI   FLDLENTH,L2         MOVE IN FIELD LENGTH                 49440020
         LA    R4,DCBTIOT          MOVE IN RELATIVE ADDRESS             49520020
         B     HDROUTPT            GO WRITE SECTION HEADER OUT          49600020
DSMACRF  EQU   *                                                        49680020
         MVC   HDRBUFFR(L'HDRMACRF),HDRMACRF  MOVE HEADING IN           49760020
         MVI   HDRLENTH,L'HDRMACRF MOVE LENGTH OF HEADING IN            49840020
         MVI   FLDLENTH,L2         MOVE IN FIELD LENGTH                 49920020
         LA    R4,DCBMACRF         MOVE IN RELATIVE ADDRESS             50000020
         B     CVTANDIO            GO SET UP FOR CONVERSION             50080020
DSIFLGS  EQU   *                                                        50160020
         MVC   HDRBUFFR(L'HDRIFLGS),HDRIFLGS  MOVE HEADING IN           50240020
         MVI   HDRLENTH,L'HDRIFLGS MOVE LENGTH OF HEADING IN            50320020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 50400020
         LA    R4,DCBIFLGS         MOVE IN RELATIVE ADDRESS             50480020
         B     CVTANDIO            GO SET UP FOR CONVERSION             50560020
DSDEBAD  EQU   *                                                        50640020
         MVC   HDRBUFFR(L'HDRDEBAD),HDRDEBAD  MOVE HEADING IN           50720020
         MVI   HDRLENTH,L'HDRDEBAD MOVE IN LENGTH OF HEADING            50800020
         MVI   FLDLENTH,L3         MOVE IN FIELD LENGTH                 50880020
         LA    R4,DCBDEBAD+D1      MOVE IN RELATIVE ADDRESS             50960020
         B     CVTANDIO            GO SET UP FOR CONVERSION             51040020
DSOFLG2  EQU   *                                                        51120020
         MVC   HDRBUFFR(L'HDROFLGS),HDROFLGS MOVE HEADING IN            51200020
         MVI   HDRLENTH,L'HDROFLGS MOVE LENGTH OF HEADING IN            51280020
         MVI   FLDLENTH,L1         MOVE IN FIELD LENGTH                 51360020
         LA    R4,DCBOFLGS         MOVE IN RELATIVE ADDRESS             51440020
         B     CVTANDIO            GO SET UP FOR CONVERSION             51520020
**  THE FOLLOWING CODE OUTPUTS THE SECTION HEADERS                   ** 51600020
HDROUTPT EQU   *                                                        51680020
         TM    OUTPUTSW,ALLCHECK   ARE ALL THE FIELDS TO BE OUTPUTTED   51760020
         BZ    DDCHECK2            NO, GO CHECK FOR DDNAME PDE          51840020
         LTR   R2,R2               YES, IS THERE PREVIOUS OUTPUT        51920020
         BZ    CONTINUE            NO, GO PREPARE HEADER                52000020
         L     R10,OUTBUF          YES, POINT TO OUTPUT BUFFER          52080020
         LA    R14,D4(R2)          SET LENGTH OF OUTPUT                 52160020
         STH   R14,D0(R10)         STORE LENGTH IN OUTPUT BUFFER        52240020
         OI    OUTPUTSW,HDRCHECK   INDICATE HEADER BEING OUTPUTTED      52320020
         OI    OUTPUTSW,SECHDRCK   INDICATE SECTION HEADER IS TO BE     52400020
*                                  OUTPUTTED                            52480020
         BAL   R14,DCBIO           GO SET UP PARAMETER LIST FOR I/O     52560020
         XR    R2,R2               RESET OUTPUT COUNTER                 52640020
CONTINUE EQU   *                                                        52720020
         XR    R11,R11             CLEAR A REGISTER                     52800020
         IC    R11,HDRCOUNT        LOAD OFFSET TO PROPER INSTRUCTION    52880020
         LA    R7,D14(R11)         POINT TO NEXT HEADER                 52960020
         STC   R7,HDRCOUNT         SET COUNTER FOR NEXT HEADER          53040020
         LA    R7,HDRTAB           POINT TO TABLE                       53120020
         AR    R7,R11              ADD OFFSET TO TABLE ADDRESS          53200020
         L     R10,OUTBUF          POINT TO OUTPUT BUFFER               53280020
         BR    R7                  GO MOVE HEADER TO OUTPUT BUFFER      53360020
HDRTAB   EQU   *                                                        53440020
         MVC   D4(L'HEADER1,R10),HEADER1  MOVE HEADER TO BUFFER         53520020
         LA    R14,L'HEADER1       STORE LENGTH                         53600020
         B     HDRIO               GO OUTPUT HEADER                     53680020
         MVC   D4(L'HEADER2,R10),HEADER2  MOVE HEADER TO BUFFER         53760020
         LA    R14,L'HEADER2       STORE LENGTH                         53840020
         B     HDRIO               GO OUTPUT HEADER                     53920020
         MVC   D4(L'HEADER3,R10),HEADER3  MOVE HEADER TO BUFFER         54000020
         LA    R14,L'HEADER3       STORE LENGTH                         54080020
         B     HDRIO               GO OUTPUT HEADER                     54160020
         MVC   D4(L'HEADER4,R10),HEADER4  MOVE HEADER TO BUFFER         54240020
         LA    R14,L'HEADER4       STORE LENGTH                         54320020
HDRIO    EQU   *                                                        54400020
         LA    R14,D4(R14)         SET LENGTH OF OUTPUT                 54480020
         NI    OUTPUTSW,HEXCF      TURN OFF FIELD AND HEADER SWITCHES   54560020
         STH   R14,D0(R10)         PUT LENGTH AT BEGINNING OF BUFFER    54640020
         BAL   R14,DCBIO           GO PUT OUT THE HEADER                54720020
DDCHECK2 EQU   *                                                        54800020
         LA    R11,DDNAM           GET ADDRESS OF DCBDDNAM PDE          54880020
         CR    R6,R11              IS THIS DDNAM FIELD                  54960020
         BE    TRNSLATE            IF YES GO VALIDITY CHECK THE FIELD   55040020
         SPACE                                                          55120020
*********************************************************************** 55200020
* THE FOLLOWING CODE WILL SET UP CONVERSION AND OUTPUT OF REQUESTED   * 55280020
* FIELDS.  WHEN SECTION IS REACHED, RELATIVE ADDRESS, FIELD LENGTH    * 55360020
* HEADER LENGTH, AND HEADER WILL BE IN THE COMMON BUFFERS.            * 55440020
*********************************************************************** 55520020
         SPACE                                                          55600020
CVTANDIO EQU   *                                                        55680020
         XR    R7,R7                                                    55760020
         XR    R10,R10                                                  55840020
         SR    R0,R0               ZERO OUT REGISTER                    55920020
         OI    OUTPUTSW,HDRCHECK   TURN ON FIELD HEADER SWITCH          56000020
         IC    R7,FLDLENTH         LOAD FIELD LENGTH                    56080020
         ST    R0,HDROFFST         CLEAR OUT HDROFFST AND FLDOFFST      56160020
         IC    R10,HDRLENTH        LOAD HEADER LENGTH                   56240020
         AR    R7,R7               DOUBLE FOR TRUE PRINTABLE LENGTH     56320020
         LR    R0,R10              LOAD HEADER LENGTH                   56400020
         SR    R0,R7               DIFFERENCE BETWEEN HEADER AND FIELD  56480020
         LPR   R0,R0               ASSURE THAT DIFFERENCE IS POSITIVE   56560020
         SRL   R0,D1               SHIFT TO DIVIDE BY TWO               56640020
         CR    R7,R10              WHICH IS LONGER                      56720020
         BH    FLDLONGR            IF FIELD IS LONGER, BRANCH           56800020
         STH   R0,FLDOFFST         STORE IN WORK AREA                   56880020
         SR    R0,R0               CLEAR OUT REGISTER                   56960020
         LR    R7,R10              R7 NOW CONTAINS OUTPUT LENGTH        57040020
FLDLONGR EQU   *                                                        57120020
         STH   R0,HDROFFST         STORE IN WORK AREA                   57200020
         AR    R7,R2               COMPUTE TENTATIVE OUTPUT LENGTH      57280020
         CH    R7,LINELEN          IS FIELD LONGER THAN OUTPUT LINE     57360020
         BNH   MOREROOM            BRANCH IF THE FIELD CAN FIT          57440020
         L     R11,OUTBUF          OBTAIN ADDRESS OF OUTBUF             57520020
         LA    R10,D2(R2)          ADD TWO BYTES TO LENGTH OF OUTPUT    57600020
         STH   R10,D0(R11)         STORE LENGTH OF OUTPUT               57680020
         BAL   R14,DCBIO           GO OUTPUT LINES                      57760020
         SR    R7,R2               RESET LENGTH OF CURRENT FIELD        57840020
         XR    R2,R2               RESET LINE TO ZERO                   57920020
         OI    OUTPUTSW,HDRCHECK   TURN ON FIELD HEADER SWITCH          58000020
         SPACE                                                          58080020
*********************************************************************** 58160020
* THE FOLLOWING IS REACHED WHEN THERE IS MORE ROOM IN OUTPUT BUFFER   * 58240020
* IT SETS UP FOR IKJEGCVT WHICH WILL CONVERT THE FIELD AND MOVE THE   * 58320020
* HEADER AND FIELD TO THE PROPER BUFFERS.                             * 58400020
*********************************************************************** 58480020
MOREROOM EQU   *                                                        58560020
         SR    R7,R2                                                    58640020
         MVI   CVTLL,HEXZERO      ZERO OUT 1ST BYTE OF LENGTH           58720020
         MVC   CVTLL+D1(L1),FLDLENTH  MOVE LENGTH OF FIELD INTO         58800020
*                                 PARAMETER LIST                        58880020
         ST    R4,STRNGPTR        STORE POINTER TO FIELD CONTENTS       58960020
         MVI   FLAGS,FLAG         MOVE FLAG TO PARAMETER LIST           59040020
         MVI   TYPECODE,TYPE      MOVE TYPE CODE (HEX) TO LIST          59120020
         LNR   R0,R7              INDICATE CONVERSION TO PRINTABLE      59200020
         LA    R1,STRNGPTR        LOAD ADDRESS OF PARAMETER LIST        59280020
         L     R15,TSTCONVT       LOAD ADDRESS OF IKJEGCVT              59360020
         BALR  R14,R15            GO CONVERT THE FIELD                  59440020
         LPR   R0,R0              RESTORE REGISTER 0 TO POSITIVE        59520020
         LTR   R15,R15            IS RETURN CODE ZERO                   59600020
         BNZ   SEVRET             NO, GO HANDLE SERVICE ROUTINE CODE    59680020
         L     R10,OUTBUF         YES, POINT TO OUTPUT BUFFER           59760020
         LH    R11,FLDOFFST                                             59840020
         AR    R11,R10            ADD IN OFFSET FOR FORMATTING          59920020
         LA    R11,D84(R11)       POINT TO POSITION IN FIELD BUFFER     60000020
         AR    R11,R2             GET PROPER DISPLACEMENT INTO BUFFER   60080020
         L     R10,CONAREA        POINT TO CONVERT OUTPUT AREA          60160020
         XR    R1,R1              CLEAR A REGISTER                      60240020
         IC    R1,D0(R10)         OBTAIN LENGTH OF DCB FIELD FROM       60320020
*                                 FIRST BYTE OF CONVERTED AREA          60400020
         BCTR  R1,R0              TAKE ONE FROM LENGTH                  60480020
         EX    R1,MOVE2           GO MOVE FIELD INTO BUFFER             60560020
         LH    R10,HDROFFST                                             60640020
         L     R11,OUTBUF         GET ADDRESS OF OUTPUT BUFFER          60720020
         AR    R11,R10                                                  60800020
         LA    R10,HDRBUFFR       GET ADDRESS OF FIELD HEADER           60880020
         AR    R11,R2             GET PROPER DISPLACEMENT INTO BUFFER   60960020
         XR    R1,R1              CLEAR REGISTER 1                      61040020
         IC    R1,HDRLENTH        OBTAIN LENGTH OF DCB FIELD            61120020
         BCTR  R1,R0              TAKE ONE FROM LENGTH                  61200020
         EX    R1,MOVE3           GO MOVE FIELD NAME INTO BUFFER        61280020
         AR    R2,R7              RESET OUTPUT CHARACTER COUNT          61360020
         LA    R2,D2(R2)          2 SPACES BETWEEN THIS AND NEXT FIELD  61440020
         B     PDECHK             GO CHECK TO SEE IF THERE ARE MORE     61520020
*                                 FIELDS TO BE OUTPUTTED                61600020
         SPACE                                                          61680020
*********************************************************************** 61760020
* THE FOLLOWING CODE SETS UP A PARAMETER LIST FOR IKJEGIO WHICH WILL  * 61840020
* OUTPUT THE LINE(S).  THIS CODE IS BRANCHED TO FROM CVTANDIO, DCBRET,* 61920020
* AND HDROUTPT.  UPON ENTRY OUTBUF POINTS TO THE DATA TO BE OUTPUTTED.* 62000020
*********************************************************************** 62080020
         SPACE                                                          62160020
DCBIO    EQU   *                                                        62240020
         L     R1,OUTBUF          POINT TO OUTPUT BUFFER                62320020
         ST    R1,OUTPTR1         STORE POINTER IN PARAMETER LIST       62400020
         L     R0,PRINTFLG        SEND IKJEGIO POINTER TO DSNAME PDE    62480020
*                                 THE FIRST TIME                        62560020
         XR    R1,R1              CLEAR A REGISTER                      62640020
         ST    R1,PRINTFLG        CLEAR PRINTFLG TO AVOID SENDING       62720020
*                                 THE ADDRESS OF THE DSNAME PDE TO      62800020
*                                 IKJEGIO MORE THAN ONCE                62880020
         ST    R1,OUTPTR2         INDICATE NO SECOND LEVEL OUTPUT       62960020
         LA    R1,OUTPTR1         POINT TO PARAMETER LIST               63040020
         L     R15,TPUTADDR       LOAD ADDRESS OF IKJEGIO               63120020
         ST    R14,REG14          SAVE CONTENTS OF REGISTER 14          63200020
         BALR  R14,R15            GO TO IKJEGIO TO OUTPUT DATA          63280020
         LTR   R15,R15            RETURN CODE FROM IO A ZERO            63360020
         BZ    CLEARBUF           YES, GO CLEAR BUFFERS                 63440020
         B     SEVRET             NO, GO HANDLE SERVICE ROUTINE CODES   63520020
CLEARBUF EQU   *                                                        63600020
         L     R10,OUTBUF         GET ADDRESS OF OUTPUT BUFFER          63680020
         MVI   D4(R10),BLANK      CLEAR OUTPUT AREA                     63760020
         MVC   D5(L79,R10),D4(R10)                                      63840020
         L     R14,REG14          RESTORE CONTENTS OF REGISTER 14       63920020
         TM    OUTPUTSW,FLDCHECK  WAS A FIELD JUST PUT OUT              64000020
         BZ    FURTHCHK           NO, GO CHECK FOR FIELD HEADER         64080020
         NI    OUTPUTSW,HEXEF     YES, TURN OFF FIELD SWITCH            64160020
         TM    OUTPUTSW,SECHDRCK  IS SECTION HEADER TO BE OUTPUTTED     64240020
         BZ    BRANCH1            NO, CONTINUE PROCESSING               64320020
         NI    OUTPUTSW,HEXBF     YES, TURN OFF SECTION HEADER SWITCH   64400020
         XC    D0(L4,R10),D0(R10) CLEAR FIRST FOUR BYTES OF OUTBUF      64480020
*                                 TO INDICATE A LINE SHOULD BE SKIPPED  64560020
         B     DCBIO              GO BACK TO I/O ROUTINE                64640020
BRANCH1  EQU   *                                                        64720020
         BR    R14                RETURN TO CALLING ROUTINE             64800020
FURTHCHK EQU   *                                                        64880020
         TM    OUTPUTSW,HDRCHECK  WAS A FIELD HEADER JUST PUT OUT       64960020
         BZ    BRANCH1            NO, BRANCH TO RETURN TO CALLER        65040020
         NI    OUTPUTSW,HEXDF     YES, TURN OFF FIELD HEADER SWITCH     65120020
         L     R11,OUTBUF         GET ADDRESS OF OUTPUT BUFFER          65200020
         LA    R10,D84(R11)       POINT TO FIELD BUFFER                 65280020
         LR    R1,R2              GET LENGTH OF DATA TO BE OUTPUTTED    65360020
         BCTR  R1,R0              TAKE ONE FROM LENGTH                  65440020
         EX    R1,MOVE3           MOVE FIELD DATA INTO OUTPUT BUFFER    65520020
         OI    OUTPUTSW,FLDCHECK  INDICATE FIELD DATA TO BE OUTPUTTED   65600020
         MVI   D0(R10),BLANK      CLEAR WORK BUFFER                     65680020
         MVC   D1(L79,R10),D0(R10)                                      65760020
         B     DCBIO              GO TO I/O ROUTINE                     65840020
*********************************************************************** 65890020
* THE FOLLOWING CODE SCANS THE DDNAME FIELD AND CONVERTS THE FIELD TO * 65900020
* PRINTABLES.  A NON PRINTABLE IS CONVERTED TO A PERIOD.  ACCEPTED    * 65910020
* CHARACTERS ARE ALL OF THE ALPHANUMERIC, NATIONAL, THE QUOTE SIGN,   * 65912020
* AND BLANKS.                                                         * 65914020
*********************************************************************** 65916020
TRNSLATE EQU   *                                                        65920020
         MVC   DDNAMBUF(L8),D0(R4) COPY DDNAME INTO WORKAREA            66000020
         TR    DDNAMBUF(L8),TRTABLE TRANSLATE DDNAM TO PRINTABLES       66080020
         LA    R10,L8             LOAD LENGTH OF DDNAME                 66160020
         AR    R10,R2             ADD PREVIOUS OUTPUT LENGTH            66240020
         CH    R10,LINELEN        DOES DDNAM FIT IN OUTPUT LINE         66320020
         BH    NOFIT              BRANCH IF NOT ENOUGH ROOM             66400020
         B     MOVEIT             GO PUT DDNAME FIELD IN WORK BUFFER    66480020
NOFIT    EQU   *                                                        66560020
         BAL   R14,DCBIO          OUTPUT FIELDS AND HEADERS             66640020
         XR    R2,R2                                                    66720020
MOVEIT   EQU   *                                                        66800020
         L     R11,OUTBUF         POINT TO OUTPUT BUFFER                66880020
         AR    R11,R2                                                   66960020
         LA    R10,D84(R11)       POINT TO FIELD BUFFER                 67040020
         OI    OUTPUTSW,HDRCHECK  TURN ON FIELD HEADER SWITCH           67120020
         MVC   D4(L'HDRDDNAM,R11),HDRBUFFR MOVE HEADING INTO I/O BUFFER 67200020
         MVC   D0(L8,R10),DDNAMBUF  MOVE DDNAME TO FIELD BUFFER         67280020
*                                 FROM DCB                              67360020
         LA    R2,D10(R2)         RESET LINE LENGTH                     67440020
         B     PDECHK             GO CHECK NEXT PDE                     67520020
DCBRC16  EQU   *                                                        68000020
         LA    R15,RET16          SET RETURN CODE TO 16 (ATTENTION)     68080020
         B     EXITNOW            RETURN TO IKJEGMNL                    68160020
FIELDMSG EQU   *                                                        68240020
         L     R6,MSGADDR         GET ADDRESS OF LISTDCB'S MSG CSECT    68320020
         USING IKJEGMSG,R6        ESTABLISH ADDRESSABILITY              68400020
         LA    R1,MSG06           POINT TO MSG06 FOR IKJ57209I          68480020
MSGIOCTD EQU   *                                                        68560020
         ST    R1,REG14           DO NOT OUTPUT FIELD MISSING MESSAGE   68640020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)     INDICATE I/O TO TERMINAL   68720020
         LCR   R1,R1              NEGATIVE FOR MESSAGES                 68800020
         L     R15,TPUTADDR       LOAD ADDRESS OF IKJEGIO               68880020
         BALR  R14,R15            PUT OUT THE MESSAGE                   68960020
         LPR   R1,R1              RESTORE REGISTER 1 TO POSITIVE        69040020
         LTR   R15,R15            RETURN CODE FROM IO A ZERO            69120020
         BNZ   SEVRET             NO, MESSAGE WAS NOT WRITTEN-BRANCH    69200020
DCBRET0  EQU   *                                                        69280020
         LA    R15,RETCOD0        SET RETURN CODE FOR IKJEGMNL TO 0     69360020
RETURN   EQU   *                                                        69440020
         CLC   REG14,WORDZERO     DID IKJEGDCB CALL IKJEGIO             69520020
         BE    FIELDMSG           NO, GO WRITE MESSAGE                  69600020
EXITNOW  EQU   *                                                        69680020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)     TURN OFF OUTPUT FLAG       69760020
*                                 IN TCOMTAB                            69840020
         L     R13,D4(R13)        RESTORE REGISTER 13                   69920020
         RETURN (14,12),T,RC=(15) RETURN TO IKJEGMNL                    70000020
FLUSHIT  EQU   *                                                        70050020
         OI    TSTFLGS4,TSTFLUSH  INDICATE TO IKJEGMNL TO FLUSH STACK   70060020
RETURN0  EQU   *                                                        70080020
         XR    R15,R15            SET RETURN CODE TO ZERO               70160020
         B     EXITNOW            RETURN TO IKJEGMNL                    70240020
CHKRET   EQU   *                                                        70320020
         L     R15,REG15          PUT SAVED RETURN CODE INTO REG 15     70400020
SEVRET   EQU   *                                                        70480020
         B     RETTAB(R15)        GO THRU FOLLOWING TABLE INDEXED BY    70560020
*                                 CONTENTS OF REGISTER 15               70640020
RETTAB   EQU   *                                                        70720020
         B     RETURN0            0-FROM SERVICE ROUTINE-RETURN-0       70800020
         B     RETURN0            4-FROM SERVICE ROUTINE-RETURN-0       70880020
         B     RETURN0            8-FROM SERVICE ROUTINE-RETURN-0       70960020
         B     RETURN0            12-FROM SERVICE ROUTINE RETURN-0      71040020
         B     EXITNOW            16-FROM SERVICE ROUTINE-RETURN 16     71120020
         B     EXITNOW            20-FROM SERVICE ROUTINE-RETURN 20     71200020
PDLEND   EQU   *                                                        71280020
         LTR   R2,R2              IS THERE ANY MORE OUTPUT              71360020
         BZ    DCBRET0            IF NO, BRANCH                         71440020
         LA    R2,D2(R2)          ADD 2 BYTES TO OUTPUT LENGTH          71520020
         L     R10,OUTBUF         GET ADDRESS OF OUTPUT BUFFER          71600020
         STH   R2,D0(R10)         STORE LENGTH OF OUTPUT IN BUFFER      71680020
         BAL   R14,DCBIO          GO OUTPUT HEADERS AND FIELDS          71760020
         B     DCBRET0            RETURN TO IKJEGMNL                    71840020
**********************************************************************  71920020
*                     STAE RETRY ROUTINE                             *  72000020
**********************************************************************  72080020
STAERTN  EQU   *                                                        72160020
         DROP  R6                 DROP ADDRESSABILITY TO MSG CSECT      72240020
         L     R6,CVTPTR          GET CVT ADDRESS                       72320020
         USING CVTDSECT,R6        ESTABLISH ADDRESSABILITY TO CVT       72400020
         L     R6,CVTTCBP         GET ADDRESS OF TCB WORDS              72480020
         L     R6,D4(R6)          GET ADDRESS OF CURRENT TCB            72560020
         DROP  R6                 DROP ADDRESSABLITY TO CVT             72640020
         USING TCB,R6             ESTABLISH ADDRESSABILITY TO TCB       72720020
         L     R9,TCBTRN          PICK UP POINTER TO TCOMTAB FROM       72800020
*                                 TCBTRN FIELD OF TEST'S TCB            72880020
         L     R13,REGSAVE2       GET ADDR OF LISTDCB'S REGISTERS       72960020
         L     R12,D68(R13)       RESET BASE REGISTER                   73040020
         LTR   R0,R0              IS WORKAREA AVAILABLE                 73120020
         BNZ  NOWORK              NO, SET RETURN CODE TO IKJEGMNL       73200020
         FREEMAIN  R,LV=104,A=(1) YES, FREE AREA                        73280020
NOWORK   EQU   *                                                        73360020
         LA    R15,RETCOD20       INDICATE STAE EXIT RTN ENTERED        73440020
         B     EXITNOW            GO BACK TO IKJEGMNL                   73520020
TRTABLE  EQU   *                                                        73600020
         DC    256CL1'.'          INITIALIZE TO 256 PERIODS             73680020
         ORG   TRTABLE+(C'A')     GO TO POSITION +193 IN TABLE          73760020
         DC    C'ABCDEFGHI'       FIRST THIRD OF ALPHABET               73840020
         ORG   TRTABLE+(C'J')     GO TO POSITION +209 IN TABLE          73920020
         DC    C'JKLMNOPQR'       SECOND THIRD OF ALPHABET              74000020
         ORG   TRTABLE+(C'S')     GO TO POSITION +226 IN TABLE          74080020
         DC    C'STUBWXYZ'        THIRD THIRD OF ALPHABET               74160020
         ORG   TRTABLE+(C'0')     GO TO POSITION +240 IN TABLE          74240020
         DC    C'0123456789'      ACCEPT NUMBERS                        74320020
         ORG   TRTABLE+(C'''')    GO TO POSITION +125 IN TABLE          74400020
         DC    C''''              ACCEPT QUOTES                         74480020
         ORG   TRTABLE+(C'=')     GO TO POSITION +126 IN TABLE          74560020
         DC    C'='               ACCEPT EQUAL MARKS                    74640020
         ORG   TRTABLE+(C'$')     GO TO POSITION +91 IN TABLE           74720020
         DC    C'$'               ACCEPT DOLLAR SIGN                    74800020
         ORG   TRTABLE+(C' ')     GO TO POSITION +64 IN TABLE           74880020
         DC    C' '               ACCEPT BLANK                          74960020
         ORG   TRTABLE+256        GO TO END OF TABLE                    75040020
         EJECT                                                          75120020
HDRRELAD DC    C'RELAD'           FIELD HEADER IN DEVICE INTERFACE SEG  75200020
HDRKEYCN DC    C'KEYCN'           FIELD HEADER IN DEVICE INTERFACE SEG  75280020
HDRFDAD  DC    C'FDAD'            FIELD HEADER IN DEVICE INTERFACE SEG  75360020
HDRDVTBL DC    C'DVTBL'           FIELD HEADER IN DEVICE INTERFACE SEG  75440020
HDRKEYLE DC    C'KEYLE'           FIELD HEADER IN DEVICE INTERFACE SEG  75520020
HDRDEVT  DC    C'DEVT'            FIELD HEADER IN DEVICE INTERFACE SEG  75600020
HDRTRBAL DC    C'TRBAL'           FIELD HEADER IN DEVICE INTERFACE SEG  75680020
HDRBUFNO DC    C'BUFNO'           FIELD HEADER IN COMMON INTERFACE      75760020
HDRBUFCB DC    C'BUFCB'           FIELD HEADER IN COMMON INTERFACE      75840020
HDRBUFL  DC    C'BUFL'            FIELD HEADER IN COMMON INTERFACE      75920020
HDRDSORG DC    C'DSORG'           FIELD HEADER IN COMMON INTERFACE      76000020
HDRIOBAD DC    C'IOBAD'           FIELD HEADER IN COMMON INTERFACE      76080020
HDRHIARC DC    C'HIARC-BFTEK-BFALN' TRI HEADERS IN FOUNDATION EXTENSION 76160020
HDRBFTEK DC    C'BFTEK-HIARC-BFALN' TRI HEADERS IN FOUNDATION EXTENSION 76240020
HDRBFALN DC    C'BFALN-HIARC-BFTEK' TRI HEADERS IN FOUNDATION EXTENSION 76320020
HDREODAD DC    C'EODAD'           FIELD HEADER IN FOUNDATION EXTENSION  76400020
HDRRECFM DC    C'RECFM'           FIELD HEADER IN FOUNDATION EXTENSION  76480020
HDREXLST DC    C'EXLST'           FIELD HEADER IN FOUNDATION EXTENSION  76560020
HDRDDNAM DC    C'DDNAM'           FIELD HEADER IN CLOSED FOUNDATION     76640020
HDROFLGS DC    C'OFLGS'           FIELD HEADER IN CLOSED FOUNDATION     76720020
HDRIFLG  DC    C'IFLG'            FIELD HEADER IN CLOSED FOUNDATION     76800020
HDRMACR  DC    C'MACR'            FIELD HEADER IN CLOSED FOUNDATION     76880020
HDRTIOT  DC    C'TIOT'            FIELD HEADER IN OPEN FOUNDATION       76960020
HDRMACRF DC    C'MACRF'           FIELD HEADER IN OPEN FOUNDATION       77040020
HDRIFLGS DC    C'IFLGS'           FIELD HEADER IN OPEN FOUNDATION       77120020
HDRDEBAD DC    C'DEBAD'           FIELD HEADER IN OPEN FOUNDATION       77200020
HEADER1  DC    C'DEVICE INTERFACE SEGMENT'  DCB SECTION HEADER          77280020
HEADER2  DC    C'COMMON INTERFACE'          DCB SECTION HEADER          77360020
HEADER3  DC    C'FOUNDATION EXTENSION'      DCB SECTION HEADER          77440020
HEADER4  DC    C'FOUNDATION'                DCB SECTION HEADER          77520020
WORDZERO DC    X'00000000'        WORD OF ZEROES                        77600020
HEXFFFF  DC    X'FFFF'            USED TO TURN ON PDES DESCRIBING THE   77680020
*                                 DCB FIELDS                            77760020
MSGADDR  DC    V(IKJEGMSG)        ADDRESS OF MESSAGE CSECT              77840020
PCLADDR  DC    V(IKJEGPCL)        ADDRESS OF PARAMETER CONTROL LIST     77920020
*                                 FOR IKJPARS                           78000020
RETRYADR DC    AL3(STAERTN)       ADDR OF STAE EXIT ROUTINE             78080020
** THE FOLLOWING IS THE STAE MESSAGE TABLE                           ** 78160020
STATBL   DS    0F                                                       78240020
         DC    AL1(HEXTHREE),AL3(PARSBLOW)  PARSE LINK FAILED           78320020
         DC    AL1(HEXFF)                   END OF STATE ABEND TABLE    78400020
MOVE2    MVC   D0(L0,R11),D1(R10) MOVE FIELD INTO BUFFER                78480020
MOVE3    MVC   D4(L0,R11),D0(R10) MOVE FIELD HEADER OR DATA INTO BUFFER 78560020
STAEL    DS    0F                                                       78640020
STAELIST STAE  STAELIST,MF=L       LIST FORM OF STAE MACRO              78720020
STAELEN  EQU   *-STAELIST          LENGTH OF STAE LIST FORM             78800020
         EJECT                                                          78880020
DCBWKARA DSECT                                                          78960020
PPLLIST DS    7F        PARSE PARAMETER LIST DESCRIBED IN IKJPPL        79040020
*                       MACRO                                           79120020
HDRBUFFR DS    5F       BUFFER FOR ONE FIELD HEADER                     79200020
PRINTFLG DS    F        ADDRESS OF DSNAME PDE FOR IKJEGIO               79280020
ENDEND   DS    F        ADDRESS OF LAST FIELD PDE + 2                   79360020
DDNAMBUF DS    2F       BUFFER FOR DDNAM FIELD                          79440020
OUTPTR1  DS    F        FIRST OUTPUT POINTER FOR IKJEGIO                79520020
OUTPTR2  DS    F        SECOND OUTPUT POINTER FOR IKJEGIO               79600020
** THE FOLLOWING FIELD IS INITIALIZED IN THE DCBIO ROUTINE.  BEFORE  ** 79680020
** RETURNING TO IKJEGMNL THIS FIELD IS CHECKED FOR A 0 INDICATING    ** 79760020
** IKJEGIO WAS NOT CALLED TO OUTPUT A FIELD.                         ** 79840020
REG14    DS    F        REGISTER 14 SAVEAREA                            79920020
REG15    DS    F        RETURN CODE SAVEAREA                            80000020
HDROFFST DS    CL2      OFFSET FOR FORMATTING                           80160020
FLDOFFST DS    CL2      OFFSET FOR FORMATTING                           80240020
HDRLENTH DS    CL1      LENGTH OF PRECEDING FIELD HEADER                80320020
FLDLENTH DS    CL1      LENGTH OF DCB FIELD                             80400020
OUTPUTSW DS    CL1      OUTPUT FLAGS                                    80480020
HDRCOUNT DS    CL1      NUMBER OF SECTION HEADERS ALREADY OUT           80560020
** THE FOLLOWING FOUR FIELDS MAKE UP THE PARAMETER LIST FOR IKJEGCVT ** 80640020
STRNGPTR DS    F        POINTER TO FIELD TO BE CONVERTED                80720020
CVTLL    DS    CL2      LENGTH OF FIELD TO BE CONVERTED                 80800020
FLAGS    DS    CL1      FLAG FOR IKJEGCVT                               80880020
TYPECODE DS    CL1      TYPE OF INPUT DATA TO IKJEGCVT (HEX)            80960020
LINELEN  DS    H        OUTPUT LINE LENGTH                              81000020
STAEL2   DS    0F                                                       81040020
STAEAREA DS    3F       WORKAREA FOR STAE                               81120020
         EJECT                                                          81200020
IKJEGMSG CSECT                                                          81280020
**THIS IS THE MESSAGE CSECT FOR IKJEGDCB, THE LISTDCB FUNCTION OF    ** 81360020
**TEST.  THE FIRST SECTION CONTAINS ADCONS FOR THE FIRST AND SECOND  ** 81440020
**LEVEL MESSAGES.  THE SECOND ADCON IS ZERO IF NO SECOND LEVEL       ** 81520020
**MESSAGE EXISTS.                                                    ** 81600020
MSG01    DC    A(MSG206IA)   ADDRESS OF FIRST LEVEL MSG IKJ57206I       81840020
         DC    A(MSG206IB)   ADDRESS OF SECOND LEVEL MSG IKJ57206I      81920020
MSG02    DC    A(MSG207I)    ADDRESS OF FIRST LEVEL MSG IKJ57207I       82000020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    82080020
MSG03    DC    A(MSG208IA)   ADDRESS OF FIRST LEVEL MSG IKJ57208I       82160020
         DC    A(MSG208IB)   ADDRESS OF SECOND LEVEL MSG IKJ57208I      82240020
MSG04    DC    A(MSG208IA)   ADDRESS OF FIRST LEVEL MSG IKJ57208I       82320020
         DC    A(MSG208IC)   ADDRESS OF SECOND LEVEL MSG IKJ57208I      82400020
MSG05    DC    A(MSG208IA)   ADDRESS OF FIRST LEVEL MSG IKJ57208I       82480020
         DC    A(MSG208ID)   ADDRESS OF SECOND LEVEL MSG IKJ57208I      82560020
MSG06    DC    A(MSG209I)    ADDRESS OF FIRST LEVEL MSG IKJ57209I       82640020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    82720020
MSG206IA DS    0H                                                       83600020
         DC    AL2(END206IA-MSG206IA)  LENGTH OF MESSAGE                83680020
         DC    AL2(0)                  TWO BYTES OF ZERO                83760020
         DC    C'IKJ57206I LISTDCB FAILED, COMMAND '  MESSAGE TEXT      83840020
         DC    C'SYSTEM ERROR+'                       MESSAGE TEXT      83920020
END206IA EQU   *                                                        84000020
MSG206IB DS    0H                                                       84080020
         DC    AL2(END206IB-MSG206IB)  LENGTH OF MESSAGE                84160020
         DC    AL2(0)                  TYPE BYTES OF ZERO               84240020
         DC    C'IKJ57206I PARSE ERROR CODE 12'        MESSAGE TEXT     84320020
END206IB EQU   *                                                        84400020
MSG207I  DS    0H                                                       84480020
         DC    AL2(END207I-MSG207I)    LENGTH OF MESSAGE                84560020
         DC    AL2(0)                  TWO BYTES OF ZERO                84640020
         DC    C'IKJ57207I NOT ENOUGH MAIN STORAGE TO' MESSAGE TEXT     84720020
         DC    C' EXECUTE COMMAND'                     MESSAGE TEXT     84800020
END207I  EQU   *                                                        84880020
MSG208IA DS    0H                                                       84960020
         DC    AL2(END208IA-MSG208IA)  LENGTH OF MESSAGE                85040020
         DC    AL2(0)                  TWO BYTES OF ZERO                85120020
         DC    C'IKJ57208I INVALID ADDRESS '           MESSAGE TEXT     85200020
END208IA EQU   *                                                        85280020
MSG208IB DS    0H                                                       85360020
         DC    AL2(END208IB-MSG208IB)  LENGTH OF MESSAGE                85440020
         DC    AL2(0)                  TWO BYTES OF ZERO                85520020
         DC    C'IKJ57208I DCB EXTENTS OUTSIDE'       MESSAGE TEXT      85600020
         DC    C' MAIN STORAGE'                       MESSAGE TEXT      85680020
END208IB EQU   *                                                        85760020
MSG208IC DS    0H                                                       85840020
         DC    AL2(END208IC-MSG208IC)  LENGTH OF MESSAGE                85920020
         DC    AL2(0)                  TWO BYTES OF ZERO                86000020
         DC    C'IKJ57208I FULLWORD BOUNDARY REQUIRED' MESSAGE TEXT     86080020
END208IC EQU   *                                                        86160020
MSG208ID DS    0H                                                       86240020
         DC    AL2(END208ID-MSG208ID)  LENGTH OF MESSAGE                86320020
         DC    AL2(0)                  TWO BYTES OF ZERO                86400020
         DC    C'IKJ57208I REGISTER NOTATION MUST BE ' MESSAGE TEXT     86480020
         DC    C'INDIRECT GENERAL REGISTER'            MESSAGE TEXT     86560020
END208ID EQU   *                                                        86640020
MSG209I  DS    0H                                                       86720020
         DC    AL2(END209I-MSG209I)    LENGTH OF MESSAGE                86800020
         DC    AL2(0)                  TWO BYTES OF ZERO                86880020
         DC    C'IKJ57209I DCB FIELD NAME REQUIRED '   MESSAGE TEXT     86960020
         DC    C'AFTER FIELD KEYWORD'                  MESSAGE TEXT     87040020
END209I  EQU   *                                                        87120020
PLUSSIGN EQU   C'+'                    PLUS SIGN FOR INDICATING 2ND     87200020
*                                      MESSAGE EXISTS                   87280020
IKJEGDCB CSECT                                                          87360020
         EJECT                                                          87440020
IKJEGPCL IKJPARM                                                        87520020
ADDRESS  IKJPOSIT ADDRESS,VALIDCK=IKJEGDVK,PROMPT='ADDRESS OF DCB'      87600020
PRINT    IKJKEYWD                                                       87680020
         IKJNAME   'PRINT',SUBFLD=DSNAME                                87760020
DCBFIELD IKJKEYWD                                                       87840020
         IKJNAME   'FIELD',SUBFLD=FIELDNAM                              87920020
DSNAME   IKJSUBF                                                        88000020
DSNAM    IKJPOSIT  DSNAME,PROMPT='DSNAME'                               88080020
FIELDNAM IKJSUBF                                                        88160020
RELAD    IKJKEYWD                                                       88240020
         IKJNAME   'DCBRELAD'                                           88320020
KEYCN    IKJKEYWD                                                       88400020
         IKJNAME   'DCBKEYCN'                                           88480020
FDAD     IKJKEYWD                                                       88560020
         IKJNAME   'DCBFDAD'                                            88640020
DVTBL    IKJKEYWD                                                       88720020
         IKJNAME   'DCBDVTBL'                                           88800020
KEYLE    IKJKEYWD                                                       88880020
         IKJNAME   'DCBKEYLE'                                           88960020
DEVT     IKJKEYWD                                                       89040020
         IKJNAME   'DCBDEVT'                                            89120020
TRBAL    IKJKEYWD                                                       89200020
         IKJNAME   'DCBTRBAL'                                           89280020
BUFNO    IKJKEYWD                                                       89360020
         IKJNAME   'DCBBUFNO'                                           89440020
BUFCB    IKJKEYWD                                                       89520020
         IKJNAME   'DCBBUFCB'                                           89600020
BUFL     IKJKEYWD                                                       89680020
         IKJNAME   'DCBBUFL'                                            89760020
DSORG    IKJKEYWD                                                       89840020
         IKJNAME   'DCBDSORG'                                           89920020
IOBAD    IKJKEYWD                                                       90000020
         IKJNAME   'DCBIOBAD'                                           90080020
HIARC    IKJKEYWD                                                       90160020
         IKJNAME   'DCBHIARC'                                           90240020
FTEK     IKJKEYWD                                                       90320020
         IKJNAME   'DCBBFTEK'                                           90400020
BFALN    IKJKEYWD                                                       90480020
         IKJNAME   'DCBBFALN'                                           90560020
EODAD    IKJKEYWD                                                       90640020
         IKJNAME   'DCBEODAD'                                           90720020
RECFM    IKJKEYWD                                                       90800020
         IKJNAME   'DCBRECFM'                                           90880020
EXLST    IKJKEYWD                                                       90960020
         IKJNAME   'DCBEXLST'                                           91040020
DDNAM    IKJKEYWD                                                       91120020
         IKJNAME   'DCBDDNAM'                                           91200020
OFLGS    IKJKEYWD                                                       91280020
         IKJNAME   'DCBOFLGS'                                           91360020
IFLG     IKJKEYWD                                                       91440020
         IKJNAME   'DCBIFLG'                                            91520020
MACR     IKJKEYWD                                                       91600020
         IKJNAME   'DCBMACR'                                            91680020
TIOT     IKJKEYWD                                                       91760020
         IKJNAME   'DCBTIOT'                                            91840020
MACRF    IKJKEYWD                                                       91920020
         IKJNAME   'DCBMACRF'                                           92000020
IFLGS    IKJKEYWD                                                       92080020
         IKJNAME   'DCBIFLGS'                                           92160020
DEBAD    IKJKEYWD                                                       92240020
         IKJNAME   'DCBDEBAD'                                           92320020
OFLGS2   IKJKEYWD                                                       92400020
         IKJNAME   'DCBOFLG2'                                           92480020
         IKJENDP                                                        92560020
         EJECT                                                          92640020
         IKJPARMA                                                       92720020
        SPACE                                                           92800020
        SPACE                                                           92880020
        SPACE                                                           92960020
         IKJPPL                                                         93040020
         EJECT                                                          93120020
CVTDSECT DSECT                                                          93200020
         CVT                                                            93280020
         EJECT                                                          93360020
         IKJTCB                                                         93440020
         EJECT                                                          93520020
         TCOMTAB                                                        93600020
         EJECT                                                          93680020
         TSTCWORK                                                       93760020
         SPACE                                                          93840020
         SPACE                                                          93920020
         SPACE                                                          94000020
         SPACE                                                          94080020
         SPACE                                                          94160020
         EJECT                                                          94240020
         DCBD  DSORG=PS,DEVD=DA                                         94320020
         END                                                            94400020
