DEB      TITLE 'IKJEGDEB - TSO TEST LIST DEB ROUTINE'                   00080020
*********************************************************************** 00160020
* TITLE      IKJEGDEB - TSO TEST LIST DEB ROUTINE                     * 00240020
*                                                                     * 00320020
* STATUS --                                                           * 00400020
*   CHANGE LEVEL 000                                                  * 00480020
*                                                                     * 00560020
* FUNCTION/OPERATION --                                               * 00640020
*    THIS COMMAND PROGRAM RECEIVES CONTROL FROM THE TEST SUBCOMMAND   * 00720020
*    PROCESSOR.  IT DISPLAYS ALL OR PART OF THE DEB AT THE SPECIFIED  * 00800020
*    ADDRESS.                                                         * 00880020
*                                                                     * 00960020
* ENTRY POINTS --                                                     * 01040020
*         IKJEGDEB   MAIN ENTRY TO LISTDEB                            * 01120020
*         DEBVALCK   PARSE VALIDITY CHECK EXIT FOR ADDRESS OF DEB     * 01200020
*                                                                     * 01280020
* INPUT --                                                            * 01360020
*    ONE LINE OF INPUT FROM THE TERMINAL CONTAINING THE SUBCOMMAND    * 01440020
*                                                                     * 01520020
* OUTPUT --                                                           * 01600020
*    LINES OF OUTPUT TO THE TERMINAL OR SPECIFIED DATA SET CONTAINING * 01680020
*    DESCRIPTIVE HEADERS AND THE REQUESTED DEB FIELDS.                * 01760020
*                                                                     * 01840020
* EXTERNAL REFERENCES --                                              * 01920020
*         1.  IKJPARS  - TO SCAN THE INPUT BUFFER                     * 02000020
*         2.  IKJEGCVT - TO CHECK AND CONVERT THE ADDRESS,            * 02080020
*         AND TO CONVERT THE DEB TO PRINTABLE HEX                     * 02160020
*         3.  IKJEGIO  - TO OUTPUT THE HEADER AND DEB FIELDS          * 02240020
*                                                                     * 02320020
* EXITS, NORMAL --                                                    * 02400020
*         RETURN TO IKJEGMNL VIA REGISTER 14                          * 02480020
*                                                                     * 02560020
* EXITS, ERROR --                                                     * 02640020
*         NONE                                                        * 02720020
*                                                                     * 02800020
* TABLES/WORK AREAS --                                                * 02880020
*    TCOMTAB - TEST TABLE AND WORKAREA                                * 02960020
*                                                                     * 03040020
* ATTRIBUTES --                                                       * 03120020
*    REENTRANT ROUTINE                                                * 03200020
*    REFRESHABLE ROUTINE                                              * 03280020
*                                                                     * 03360020
* CHARACTER CODE DEPENDENCY --                                        * 03440020
*    RE-ASSEMBLY IS REQUIRED FOR CHANGE OF CODE                       * 03520020
*                                                                     * 03600020
* NOTES --                                                            * 03680020
*    THE LISTDEB ROUTINE WILL PRINT ONLY THE BASIC SECTION AND ANY    * 03760020
*    DIRECT ACCESS SECTIONS OF THE SPECIFIED DEB.                     * 03840020
*    THE SPECIFIED DEB IS ASSUMED TO BE A VALID DEB.                  * 03920020
*                                                                     * 04000020
*********************************************************************** 04080020
         EJECT                                                          04160020
         TCOMTAB                                                        04240020
         SPACE 2                                                        04320020
         TSTCWORK                                                       04400020
         SPACE 2                                                        04480020
         IKJPPL                                                         04560020
         EJECT                                                          04640020
IKJEGDEB CSECT                                                          04720020
*********************************************************************** 04800020
*                                                                     * 04880020
*                            REGISTER EQUATES                         * 04960020
*                                                                     * 05040020
*********************************************************************** 05120020
         SPACE 2                                                        05200020
R0       EQU   0                   REGISTER 0                           05280020
R1       EQU   1                   REGISTER 1                           05360020
R2       EQU   2                   REGISTER 2                           05440020
R3       EQU   3                   REGISTER 3                           05520020
R4       EQU   4                   REGISTER 4                           05600020
R5       EQU   5                   BASE FOR DBWKAREA                    05680020
R6       EQU   6                   REGISTER 6                           05760020
R7       EQU   7                   REGISTER 7                           05840020
R8       EQU   8                   BASE FOR IKJPARMD                    05920020
R9       EQU   9                   BASE FOR TCOMTAB                     06000020
R10      EQU   10                  REGISTER 10                          06080020
R11      EQU   11                  REGISTER 11                          06160020
R12      EQU   12                  PROGRAM BASE                         06240020
R13      EQU   13                  REGISTER 13                          06320020
R14      EQU   14                  REGISTER 14                          06400020
R15      EQU   15                  REGISTER 15                          06480020
         SPACE 2                                                        06560020
*********************************************************************** 06640020
*                                                                     * 06720020
*        OTHER EQUATES                                                * 06800020
*                                                                     * 06880020
*********************************************************************** 06960020
         SPACE 2                                                        07040020
PLUSSIGN EQU   C'+'                INDICATE IST LEV MESG HAS 2ND LEV    07120020
N30      EQU   30                  DECIMAL 30                           07200020
N0       EQU   0                   DECIMAL 0                            07280020
N1       EQU   1                   DECIMAL 1                            07360020
N2       EQU   2                   DECIMAL 2                            07440020
N3       EQU   3                   DECIMAL 3                            07520020
N4       EQU   4                   DECIMAL 4                            07600020
N5       EQU   5                   DECIMAL 5                            07680020
N6       EQU   6                   DECIMAL 6                            07760020
N104     EQU   104                 DECIMAL 104                          07840020
N8       EQU   8                   DECIMAL 8                            07920020
N9       EQU   9                   DECIMAL 9                            08000020
N10      EQU   10                  DECIMAL 10                           08080020
N11      EQU   11                  DECIMAL 11                           08160020
N12      EQU   12                  DECIMAL 12                           08240020
N13      EQU   13                  DECIMAL 13                           08320020
N14      EQU   14                  DECIMAL 14                           08400020
N15      EQU   15                  DECIMAL 15                           08480020
N16      EQU   16                  DECIMAL 16                           08560020
N17      EQU   17                  DECIMAL 17                           08640020
N20      EQU   20                  DECIMAL 20                           08720020
N21      EQU   21                  DECIMAL 21                           08800020
N24      EQU   24                  DECIMAL 24                           08880020
N25      EQU   25                  DECIMAL 25                           08960020
N26      EQU   26                  DECIMAL 26                           09040020
N28      EQU   28                  DECIMAL 28                           09120020
N29      EQU   29                  DECIMAL 29                           09200020
N31      EQU   31                  DECIMAL 31                           09250020
N32      EQU   32                  DECIMAL 32                           09280020
N35      EQU   35                  DECIMAL 35                           09360020
N40      EQU   40                  DECIMAL 40                           09440020
N51      EQU   51                  DECIMAL 51                           09600020
N56      EQU   56                  DECIMAL 56                           09680020
N68      EQU   68                  DECIMAL 68                           09760020
N79      EQU   79                  DECIMAL 79                           09840020
N80      EQU   80                  DECIMAL 80                           09920020
NOTSYM   EQU   10                  BC INSTR MASK, BRANCH POSTIVE OR 0   09970020
         SPACE 2                                                        10000020
*********************************************************************** 10080020
*                                                                     * 10160020
*        TO LIMIT THE SIZE OF IKJEGDEB, THE MAJORITY OF THE FIELD     * 10240020
*        HEADERS HAVE BEEN EQUATED TO FIELDS IN THE PARSE CSECT,      * 10320020
*        IKJEGDBP.  THOSE EQUATES ARE AT THE END OF THE MODULE.  THE  * 10400020
*        FOLLOWING EQUATES SET UP THOSE FIELD HEADER EQUATES.         * 10480020
*                                                                     * 10560020
*********************************************************************** 10640020
         SPACE 2                                                        10720020
LENKEYWD EQU   6                   LENGTH OF IKJKEYWD PCE               10800020
LENNAME  EQU   13                  LENGTH OF IKJNAME PCE                10880020
FLDHDR   EQU   LENKEYWD+LENNAME    NORMAL DISPLACEMENT BETWEEN FIELD    10960020
*                                   HEADERS IN PARSE CSECT, IKJEGDBP    11040020
FIRSTHDR EQU   108                 DISPLACEMENT INTO PARSE CSECT,       11120020
*                                   IKJEGDBP, OF FIRST FIELD HDR, NMSUB 11200020
         EJECT                                                          11280020
         SAVE  (14,12),,*                                               11360020
         LR    R12,R15                                                  11440020
         USING IKJEGDEB,R12        ESTABLISH PROGRAM ADDRESSABILITY     11520020
         USING TCOMTAB,R9          ESTABLISH TCOMTAB ADDRESSABILITY     11600020
         L     R15,REGSAVE2        ADDRESS OF LISTDEB SAVE AREA         11680020
         ST    R13,N4(R15)         STORE REGISTER 13 NEW SAVE AREA      11760020
         ST    R15,N8(R13)         STORE NEW SAVE AREA ADDRESS          11840020
         LR    R13,R15             R13 NOW POINTS TO NEW SAVE AREA      11920020
         L     R7,WORKAREA         ADDR OF GENERAL WORK AREA FOR CMDS   12000020
         USING TSTCWORK,R7                                              12080020
         LA    R5,CWORKCMD         ADDRESS OF WORK AREA FOR CMDS        12160020
         USING DBWKAREA,R5         ESTABLISH WORK AREA ADDRESSABILITY   12240020
         DROP  R7                                                       12320020
         LA    R1,ABENDTAB         ADDRESS OF PREDICTABLE ABEND TABLE   12400020
         ST    R1,ABENTAB1         INTO TCOMTAB FOR STAE EXIT ROUTINE   12480020
         MVC   TSTRETRY+N1(N3),RETRYADR     ADDR OF RETRY ROUTINE       12560020
*                                   INTO TCOMTAB FOR STAE EXIT ROUTINE  12640020
         L     R3,TSTSTAE          ADDRESS OF STAE EXIT ROUTINE         12720020
         LA    R1,STAELIST         STAE PARAMETER LIST                  12800020
         ST    R12,N68(R13)        SAVE MY BASE IN MY SAVE AREA         12880020
         MVC   N0(N12,R1),LFSTAE   STAE PARAMETER LIST TO WORK AREA     12960020
         STAE  (3),CT,PARAM=(9),XCTL=NO,MF=(E,(1))                      13040020
         LTR   R15,R15             WAS STAE ISSUED SUCCESSFULLY         13120020
SMTSTAE  DS    0H                  SMT TESTCASE LABEL                   13140020
*                                   INSUFFICIENT CORE TO ISSUE STAE     13160020
*                                   TESTCASE ID  TDEB2800               13180020
         BZ    GOPARSE             YES, GO SET UP TO PARSE COMMAND      13200020
         L     R6,=A(IKJEGDBM)     ADDRESS OF MESSAGE SECTION           13600020
         USING IKJEGDBM,R6                                              13680020
         LA    R1,MESGNO3          ADDR OF NOT ENOUGH CORE MESSAGE      13760020
         B     MSGIO               GO PUT OUT MESSAGE AND RETURN        13840020
         DROP  R6                                                       13920020
GOPARSE  EQU   *                                                        14000020
         MVI   OUTPUTSW,HEX00      ZERO OUTPUT SWITCH                   14080020
         LR    R1,R5               R1 POINTS TO LIST FOR PARSE          14160020
         USING PPL,R1                                                   14240020
         MVC   PPLUPT(N4),TSTUPT   POINTER TO UPT FOR PARSE             14320020
         MVC   PPLECT(N4),TSTECT   POINTER TO ECT FOR PARSE             14400020
         MVC   PPLECB(N4),TSTCPECB POINTER TO CP ECB FOR PARSE          14480020
         MVC   PPLPCL(N4),PCLADDR  ADDR OF PCL INTO PARSE LIST          14560020
         LA    R2,TSTANSPL         LOAD ADDRESS OF ANSWER PLACE         14640020
         ST    R2,PPLANS           PTR TO ANSWER PLACE                  14720020
         MVC   PPLCBUF(N4),INBUF   PTR TO COMMAND BUFFER                14800020
         ST    R13,PPLUWA          PTR TO SAVE AREA                     14880020
         DROP  R1                                                       14960020
         LINK  EP=IKJPARS          GO TO PARSE                          15040020
PABEND1  EQU   *                   POSSIBLE ABEND RESUME ADDRESS        15120020
SMTPARS  DS    0H                  SMT TESTCASE LABEL                   15140020
*                                   LINK TO PARSE FAILED                15160020
*                                   TESTCASE ID  TDEB2700               15180020
         B     PARSDONE            GO TO PARSDONE                       15200020
         SPACE 1                                                        15280020
*********************************************************************** 15360020
*   THIS IS THE PARSE ADDRESS VALIDITY CHECK EXIT ROUTINE             * 15440020
*********************************************************************** 15520020
         SPACE 1                                                        15600020
DEBVALCK SAVE  (14,12),,*                                               15680020
         LR    R2,R1               ADDR OF PARSE LIST FOR VALIDITY      15760020
*                                   CHECK ROUTINES                      15840020
         L     R9,N4(R1)           LOAD R9 WITH ADDRESS OF SAVE AREA    15920020
         L     R12,N68(R9)         RESTORE BASE REGISTER                16000020
         L     R5,N40(R9)          RESTORE WORKAREA ADDRESSABILITY      16080020
         L     R1,N0(R1)           ADDRESS OF ADDRESS PDE               16160020
         LCR   R1,R1               NEGATIVE                             16240020
         L     R9,N56(R9)          RESTORE TCOMTAB ADDRESSABILITY       16320020
         L     R15,REGSAVE3        LOAD SAVE AREA FOR IKJEGCVT          16400020
         LCR   R0,R1               R0 INDICATES CONVERT TO BINARY       16480020
         ST    R13,N4(R15)         STORE OLD SAVE AREA ADDRESS          16560020
         ST    R15,N8(R13)         STORE NEW SAVE AREA ADDRESS          16640020
         LR    R13,R15                                                  16720020
         L     R15,TSTCONVT        ENTRY POINT OF IKJEGCVT              16800020
         BALR  R14,R15             GO TO IKJEGCVT                       16880020
         LPR   R1,R1               POSTIVE POINTER TO ADDRESS PDE       16960020
         LTR   R15,R15             IS RETURN CODE 0                     17040020
         BZ    BOUNDCK             YES, GO CHECK FOR VALID ADDRESS      17120020
         LA    R6,N4               UNSUCCESSFUL R.C. FROM CONVERT       17200020
         CR    R6,R15              WAS CONVERT UNABLE TO CONVERT        17280020
         BNE   STOP                NO, WORST TROUBLES, GO SET TO END    17360020
         MVC   N8(N4,R2),N32(R1)   PASS PTR TO 2ND LEV MESG TO PARSE    17440020
RETCODE8 LA    R15,N8              RC=8, HAVE PARSE GIVE REENTER MESG   17520020
PARSRTRN L     R13,N4(R13)                                              17600020
         RETURN  (14,12),,RC=(15)  RESTORE REGISTERS AND RETURN         17680020
BOUNDCK  EQU   *                                                        17760020
         L     R3,N32(R1)          LOAD SAVEPTR (WORD PASSED TO PARSE)  17840020
         LTR   R3,R3               WAS ADDRESS RESOLVED BY IKJEGSYM     17920020
         BC    NOTSYM,NOSYM        BRANCH IF IKJEGSYM WAS NO CALLED     18000020
         L     R3,N0(R3)           LOAD WORD USED BY IKJEGSYM           18080020
         ST    R3,N32(R1)          USER WORD IN PDE = ADDRESS OF DEB    18160020
NOSYM    L     R6,REGSAVE2                                              18240020
         ST    R3,N32(R6)                                               18320020
REGTEST  EQU   *                                                        18400020
         L     R6,=A(IKJEGDBM)     ADDRESS OF MESSAGE SECTION           18480020
         USING IKJEGDBM,R6                                              18560020
         LH    R4,N26(R1)          LOAD INDIRECT COUNT                  18640020
         LTR   R4,R4               IS ADDRESS INDIRECT                  18720020
         BNZ   FULLWORD            IF INDIRECT BRANCH                   18800020
         TM    N24(R1),HEX38       REGISTER                             18880020
         BZ    FULLWORD            IF NOT REGISTER BRANCH               18960020
         LA    R1,M330L2A          ADDR OF REGISTER ADDR INVALID MESG   19040020
         B     MESSAGIO            PUT OUT THE MESSAGE                  19120020
FULLWORD TM    N35(R1),HEX03       ADDRESS ON FULL WORD                 19200020
         BNZ   SETMESG             NO, GO GIVE INVALID ADDRESS MESSAGE  19280020
         LA    R1,N31(R3)          ADDR OF END OF BASIC SECTION OF DEB  19360020
         C     R1,TSTTOP           IS BASIC SECTION OF DEB IN CORE      19440020
         BH    BADDEB              NO, GO GIVE DEB OUTSIDE CORE MESSAGE 19520020
         SR    R0,R0               CLEAR REGISTER TO ZERO               19600020
         IC    R0,N16(R3)          NUMBER OF EXTENTS IN DATASET         19680020
         SLA   R0,N4               LENGTH OF ALL DIRECT ACCESS SECTIONS 19760020
         AR    R0,R1               ENDING ADDRESS OF DEB                19840020
         C     R0,TSTTOP           DOES DEB EXTEND OUTSIDE STORAGE      19920020
         BNH   PARSRTRN            NO, ADDR OK, GO RETURN TO PARSE      20000020
BADDEB   EQU   *                                                        20080020
         LA    R1,M330L2C          2ND LEV MSG ADDR, DEB OUTSIDE CORE   20160020
         B     MESSAGIO            GO GIVE MESSAGE                      20240020
SETMESG  EQU   *                                                        20320020
         LA    R1,M330L2B          ADDR OF INVALID BOUNDARY MESSAGE     20400020
MESSAGIO EQU   *                                                        20480020
         ST    R1,OUTPTR2          ADDRESS OF SECOND LEV TO DOUBLE WORD 20560020
         ST    R1,N8(R2)           ALSO PASS ADDR BACK TO PARSE         20640020
         L     R3,OUTBUF           ADDRESS OF BUFFER FOR FIRST LEVEL    20720020
         MVC   N0(N30,R3),M330L1   BASIC FIRST LEVEL TO OUTPUT BUFFER   20800020
         DROP  R6                                                       20880020
         LA    R1,N30(R3)          NEXT POSITION IN BUFFER              20960020
         L     R0,N0(R2)           PTR TO ADDRESS PDE                   21040020
         L     R15,TSTADDR         POINTER TO ADDRESS BUILD ROUTINE     21120020
         BALR  R14,R15             GO ADD ADDRESS TO MESSAGE            21200020
         AH    R0,N0(R3)           LENGTH OF FIRST LEVEL MESSAGE        21280020
         MVI   N0(R1),PLUSSIGN     INDICATE 1ST LEV HAS A 2ND LEV       21360020
         LR    R1,R0               LEN OF 1ST LEV - PLUS SIGN           21440020
         LA    R1,N1(R1)           LENGTH OF FIRST LEVEL MESSAGE        21520020
         STH   R1,N0(R3)           PREFIX MESSAGE WITH LENGTH           21600020
         ST    R3,OUTPTR1          ADDR OF FIRST LEVEL TO DOUBLE WORD   21680020
         LA    R1,OUTPTR1          ADDRESS OF DOUBLE WORD FOR I/O       21760020
         LCR   R1,R1               NEGATIVE FOR MESSAGES                21840020
         L     R15,TPUTADDR        LOAD ADDRESS OF IKJEGIO1             21920020
         BALR  R14,R15             OUTPUT THE MESSAGE                   22000020
         LTR   R15,R15             IS RETURN CODE 0                     22080020
         BZ    RETCODE8            YES, GO BACK TO PARSE WITH RC=8      22160020
         LA    R6,N4               UNSUCCESSFUL I/O R.C.                22240020
         CR    R15,R6              COULD I/O PUT OUT MESSAGE            22320020
         BNE   STOP                WORST TROUBLES, GO SAVE R.C.         22400020
         SR    R15,R15             CREATE 0 R.C. FOR MAINLINE           22480020
STOP     EQU   *                                                        22560020
         ST    R15,REG14           SAVE R.C.                            22640020
         LA    R15,N12             HAVE PARSE CLEAN UP AND END          22720020
         B     PARSRTRN            GO BACK TO PARSE                     22800020
         SPACE 1                                                        22880020
*********************************************************************** 22960020
* THE FOLLOWING CODE CHECKS THE FIELD,PRINT, AND ADDRESS PDE'S.  IF   * 23040020
* FIELD IS NOT SPECIFIED, THE PROGRAM SETS ALL THE FIELD PDE'S        * 23120020
* NON-ZERO.  IF PRINT IS SPECIFIED THE ADDRESS OF THE PRINT DATA SET  * 23200020
* PDE IS STORED IN PRINTFLG AND LATER PASSED TO IKJEGIO1.  THE ADDRESS* 23280020
* OF THE DEB IS FOUND IN THE USER WORD OF THE PARSE PARM LIST AFTER   * 23360020
* CONTROL IS RETURNED FROM IKJEGCVT.                                  * 23440020
*********************************************************************** 23520020
         SPACE 1                                                        23600020
PARSDONE EQU   *                                                        23680020
         LTR   R15,R15             IS RETURN CODE 0                     23760020
         BNZ   DEBRET1             IF NO BRANCH TO DEBRET1              23840020
         L     R6,N24(R3)          ADDRESS OF DCB FOR THIS DEB          23920020
         TM    DSORG(R6),ISAM      IS THIS DEB FOR A ISAM DATASET       24000020
PABEND2  EQU   *                                                        24080020
         BZ    NOTISAM1            NO, GO ON                            24160020
         OI    OUTPUTSW,ISAMBIT    YES, INDICATE FOR LATER PROCESSING   24240020
NOTISAM1 EQU   *                                                        24320020
         L     R8,TSTANSPL         FIND ADDRESS OF PARSE PDL            24400020
         USING IKJPARMD,R8         ESTABLISH PDL ADDRESSABILITY         24480020
         CLI   DEBFIELD+N1,HEX00   WAS FIELD SPECIFIED                  24560020
         BNE   PRINTCHK            IF SPECIFIED CHECK FOR PRINT KEYWORD 24640020
         OI    OUTPUTSW,ALLCHECK                                        24720020
         MVI   NMSUB,HEXFF         INDICATE THAT FIRST FIELD IS DESIRED 24800020
         MVC   NMSUB+N1(N51),NMSUB   INDICATE ALL FIELDS ARE DESIRED    24880020
PRINTCHK EQU   *                                                        24960020
         CLI   PRINT+N1,HEX00      WAS A PRINT DATA SET SPECIFIED       25040020
         BNE   PRNTSPEC            IF NOT ZERO PRINT WAS SPECIFIED      25120020
         SR    R2,R2                                                    25200020
         B     TABLESCN            GO CHECK OUTPUT LINE LENGTH          25280020
PRNTSPEC LA    R2,DSNAM                                                 25360020
         OI    TSTFLGS1,TSTPRINT                                        25440020
         EJECT                                                          25520020
*********************************************************************** 25600020
* THE FOLLOWING CODE STARTS WITH THE FIRST FIELD PDE AND DETERMINES   * 25680020
* WHETHER OR NOT THE FIELD CORRESPONDING TO THAT PDE IS DESIRED.  IF  * 25760020
* IT IS, CONTROL IS PASSED TO THE PROPER SUBROUTINE.  IF NOT, THE NEXT* 25840020
* PDE IS CHECKED UNTIL ALL THE PDE'S HAVE BEEN EXAMINED.              * 25920020
*********************************************************************** 26000020
         SPACE 1                                                        26080020
TABLESCN EQU   *                                                        26160020
         LA    R4,N40              MINIMIN LINE LENGTH                  26240020
         CH    R4,TMPLL            IS USER SPECIFIED LINE LENGTH LESS   26320020
         BH    LL80                YES, GO USE 80 FOR LINE LENGTH       26400020
         LA    R4,N80              NO, MAXIMUM LINE LENGTH              26480020
         CH    R4,TMPLL            IS SPECIFIED LINE LENGTH GREATER     26560020
         BL    LL80                YES, GO USE 80 FOR LINE LENGTH       26640020
         LH    R4,TMPLL            NO, USE SPECIFIED LINE LENGTH        26720020
         B     LINESET             GO SET LINE LENGTH                   26800020
LL80     LA    R4,N80              DEFAULT LINE LENGTH TO 80            26880020
LINESET  ST    R4,LINELEN          STORE LINE LENGTH                    26960020
         ST    R2,PRINTFLG         INDICATE OUTPUT TO TERM OR DS        27040020
         L     R10,OUTBUF          ADDRESS OF OUTPUT BUFFER             27120020
         MVI   N4(R10),BLANK       CLEAR OUTPUT                         27200020
         MVC   N5(N79,R10),N4(R10)  BUFFER TO BLANKS                    27280020
         LA    R11,BUFFER          ADDR OF DEB BUFF FOR CONVERTED FLDS  27360020
         MVC   N0(N80,R11),N4(R10) CLEAR DEB FIELD BUFFER               27440020
         MVC   NMEXTSTR(N1),N16(R3)    NUMBER OF EXTENTS IN DEB         27520020
         MVC   EXTCTR(N1),N16(R3)        ALSO IN EXTENT COUNTER         27600020
         CLI   N28(R3),HEX04       IS THE DEB FOR A DASD DATASET        27680020
         BE    CHECKEXT            YES, GO CHECK NUMBER OF EXTENTS      27760020
         OI    OUTPUTSW,NOTDASD    NO, INDICATE WHY NO DASD SECTION     27840020
         B     SETPTRS             GO SET UP TO SEARCH FIELD PDE        27920020
CHECKEXT EQU   *                                                        28000020
         CLI   N16(R3),HEX00       ARE THEIR ANY EXTENTS                28080020
         BNE   SETPTRS             YES, GO SET UP FIELD PDE SEARCH      28160020
         OI    OUTPUTSW,NOEXTENT   NO, INDICATE WHY NO DASD SECTION     28240020
SETPTRS  EQU   *                                                        28320020
         LA    R2,DVMOD                                                 28400020
         ST    R2,FSTPDEND         ADDR OF 1ST PDE OF 2ND SECTION       28480020
         LA    R2,NMTRK            ADDR OF LAST PDE OF 2ND SECTION      28560020
         LA    R2,N2(R2)           ADDRESS GREATER THAN LAST PDE        28640020
         ST    R2,LASTPDE          SAVE FOR END INDICATOR               28720020
         LA    R6,NMSUB            POINT TO FIRST PDE                   28800020
         SR    R2,R2                                                    28880020
         L     R4,=A(IKJEGDBP)     ADDRESS OF PARSE CSECT               28960020
         USING IKJEGDBP,R4                                              29040020
PDECHECK CLI   N1(R6),HEX00        WAS THIS FIELD SPECIFIED             29120020
         BNE   SBRTNSVR            IF FIELD IS REQUESTED BRANCH         29200020
         LA    R6,N2(R6)           OTHERWISE POINT TO NEXT PDE          29280020
         C     R6,LASTPDE          ARE THERE MORE PDES                  29360020
         BE    PDLEND              IF NO MORE BRANCH TO PDLEND          29440020
         B     PDECHECK            CHECK THE NEXT PDE                   29520020
SBRTNSVR EQU   *                                                        29600020
         LR    R11,R6              PRESERVE R6                          29680020
         LA    R7,NMSUB            ADDRESS OF FIRST PDE                 29760020
         SR    R11,R7              FIND RELATIVE POSITION OF PDE        29840020
         LA    R10,N11             LOAD MULTIPLICATION FACTOR           29920020
         LA    R7,SUBTAB1          LOAD ADDRESS OF TABLE                30000020
         MR    R10,R10             COMPUTE PROPER OFFSET                30080020
         AR    R7,R11              ADD OFFSET TO BASE                   30160020
         BR    R7                  GO TO PROPER SUBROUTINE              30240020
         SPACE 1                                                        30320020
*********************************************************************** 30400020
*   THE FOLLOWING CODE CONSISTS OF 26 SUBROUTINES CORRESPONDING       * 30480020
*   TO THE 26 FIELDS OF THE DEB.  EACH SUBROUTINE MOVES THE RELATIVE  * 30560020
*   ADDRESS, HEADER LENGTH, FIELD LENGTH, AND HEADER TO A COMMON      * 30640020
*   BUFFER.  CONTROL IS THEN PASSED TO A COMMON CONVERSION AND        * 30720020
*   I/O ROUTINE.  IT IS ESSENTIAL FOR PROPER LOGIC FLOW THAT EACH     * 30800020
*   SUBROUTINE HAVE THE SAME LENGTH                                   * 30880020
*********************************************************************** 30960020
         SPACE 1                                                        31040020
SUBTAB1  EQU   *                                                        31120020
DEB00B   MVC   HDRBUF(N5),HDRNMSUB FIELD HEADER TO HEADER BUFFER        31200020
         MVI   HDRLEN,N5           LENGTH OF FIELD HEADER               31280020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  31360020
         MVI   RELADR,N0           DISPLACEMENT OF FIELD INTO DEB       31440020
         B     HEADERCK            GO CHECK FOR SECTION HEADER          31520020
DEB01B   MVC   HDRBUF(N5),HDRTCBAD FIELD HEADER TO FIELD BUFFER         31600020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           31680020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  31760020
         MVI   RELADR,N1           DISPLACEMENT OF FIELD INTO DEB       31840020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        31920020
DEB04B   MVC   HDRBUF(N5),HDRAMLNG FIELD HEADER TO HEADER BUFFER        32000020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           32080020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  32160020
         MVI   RELADR,N4           DISPLACEMENT OF FIELD INTO DEB       32240020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        32320020
DEB05B   MVC   HDRBUF(N5),HDRDEBAD FIELD HEADER TO HEADER BUFFER        32400020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           32480020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  32560020
         MVI   RELADR,N5           DISPLACEMENT OF FIELD INTO DEB       32640020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        32720020
DEB08B   MVC   HDRBUF(N5),HDROFLGS FIELD HEADER TO HEADER BUFFER        32800020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           32880020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  32960020
         MVI   RELADR,N8           DISPLACEMENT OF FIELD INTO DEB       33040020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        33120020
DEB09B   MVC   HDRBUF(N5),HDRIRBAD FIELD HEADER TO HEADER BUFFER        33200020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           33280020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  33360020
         MVI   RELADR,N9           DISPLACEMENT OF FIELD INTO DEB       33440020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        33520020
*                                                                       33600020
*        CONTINUE                                                       33680020
*                                                                       33760020
DEB12B   MVC   HDRBUF(N5),HDROPATB FIELD HEADER TO HEADER BUFFER        33840020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           33920020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  34000020
         MVI   RELADR,N12          DISPLACEMENT OF FIELD INTO DEB       34080020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        34160020
DEB13B   MVC   HDRBUF(N5),HDRQSCNT FIELD HEADER TO HEADER BUFFER        34240020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           34320020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  34400020
         MVI   RELADR,N13          DISPLACEMENT OF FIELD INTO DEB       34480020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        34560020
DEB14B   MVC   HDRBUF(N5),HDRFLGS1 FIELD HEADER TO HEADER BUFFER        34640020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           34720020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  34800020
         MVI   RELADR,N14          DISPLACEMENT OF FIELD INTO DEB       34880020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        34960020
DEB15B   MVC   HDRBUF(L'HDRRSRVD),HDRRSRVD                              35040020
         MVI   HDRLEN,L'HDRRSRVD   LENGTH OF DEB FIELD HEADER           35120020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  35200020
         MVI   RELADR,N15          DISPLACEMENT OF FIELD INTO DEB       35280020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        35360020
DEB16B   MVC   HDRBUF(N5),HDRNMEXT FIELD HEADER TO HEADER BUFFER        35440020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           35520020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  35600020
         MVI   RELADR,N16          DISPLACEMENT OF FIELD INTO DEB       35680020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        35760020
DEB17B   MVC   HDRBUF(N5),HDRUSPRG FIELD HEADER TO HEADER BUFFER        35840020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           35920020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  36000020
         MVI   RELADR,N17          DISPLACEMENT OF FIELD INTO DEB       36080020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        36160020
DEB20B   MVC   HDRBUF(N5),HDRPRIOR FIELD HEADER TO HEADER BUFFER        36240020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           36320020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  36400020
         MVI   RELADR,N20          DISPLACEMENT OF FIELD INTO DEB       36480020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        36560020
DEB21B   MVC   HDRBUF(N5),HDRECBAD FIELD HEADER TO HEADER BUFFER        36640020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           36720020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  36800020
         MVI   RELADR,N21          DISPLACEMENT OF FIELD INTO DEB       36880020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        36960020
DEB24B1  MVC   HDRBUF(L'HDRPROTG),HDRPROTG                              37040020
         MVI   HDRLEN,L'HDRPROTG   LENGTH OF DEB FIELD HEADER           37120020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  37200020
         MVI   RELADR,N24          DISPLACEMENT OF FIELD INTO DEB       37280020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        37360020
DEB25B   MVC   HDRBUF(N5),HDRDCBAD FIELD HEADER TO HEADER BUFFER        37440020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           37520020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  37600020
         MVI   RELADR,N25          DISPLACEMENT OF FIELD INTO DEB       37680020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        37760020
DEB28B   MVC   HDRBUF(N5),HDREXSCL FIELD HEADER TO HEADER BUFFER        37840020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           37920020
         MVI   FLDLEN,N1           LENGTH OF DEB FIELD                  38000020
         MVI   RELADR,N28          DISPLACEMENT OF FIELD INTO DEB       38080020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        38160020
DEB29B   MVC   HDRBUF(N5),HDRAPPAD FIELD HEADER TO HEADER BUFFER        38240020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           38320020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  38400020
         MVI   RELADR,N29          DISPLACEMENT OF FIELD INTO DEB       38480020
         B     CVTANDIO            GO CONVERT FIELD TO PRINTABLE        38560020
         SPACE 1                                                        38640020
*********************************************************************** 38720020
*   THE FOLLOWING ROUTINES HANDLE THE DIRECT ACCESS SECTIONS          * 38800020
*********************************************************************** 38880020
         SPACE 1                                                        38960020
DEB00DA  MVC   HDRBUF(N5),HDRDVMOD FIELD HEADER TO HEADER BUFFER        39040020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           39120020
         MVI   FLDLEN,N1           LENGTH OF FIELD                      39200020
         MVI   RELADR,N0           DISPL OF FIELD INTO DASD SEC OF DEB  39280020
         B     FIRSTSEC            GO CHECK FOR ALL FIELDS REQUESTED    39360020
DEB01DA  MVC   HDRBUF(N5),HDRUCBAD FIELD HEADER TO HEADER BUFFER        39440020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           39520020
         MVI   FLDLEN,N3           LENGTH OF DEB FIELD                  39600020
         MVI   RELADR,N1           DISPL OF FIELD INTO DASD SEC OF DEB  39680020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     39760020
DEB04DA  MVC   HDRBUF(N5),HDRBINUM FIELD HEADER TO HEADER BUFFER        39840020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           39920020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  40000020
         MVI   RELADR,N4           DISPL OF FIELD INTO DASD SEC OF DEB  40080020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     40160020
DEB06DA  MVC   HDRBUF(N5),HDRSTRCC FIELD HEADER TO HEADER BUFFER        40240020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           40320020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  40400020
         MVI   RELADR,N6           DISPL OF FIELD INTO DASD SEC OF DEB  40480020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     40560020
DEB08DA  MVC   HDRBUF(N5),HDRSTRHH FIELD HEADER TO HEADER BUFFER        40640020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           40720020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  40800020
         MVI   RELADR,N8           DISPL OF FIELD INTO DASD SEC OF DEB  40880020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     40960020
DEB10DA  MVC   HDRBUF(N5),HDRENDCC FIELD HEADER TO HEADER BUFFER        41040020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           41120020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  41200020
         MVI   RELADR,N10          DISPL OF FIELD INTO DASD SEC OF DEB  41280020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     41360020
DEB12DA  MVC   HDRBUF(N5),HDRENDHH FIELD HEADER TO HEADER BUFFER        41440020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           41520020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  41600020
         MVI   RELADR,N12          DISPL OF FIELD INTO DASD SEC OF DEB  41680020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     41760020
DEB14DA  MVC   HDRBUF(N5),HDRNMTRK FIELD HEADER TO FIELD BUFFER         41840020
         MVI   HDRLEN,N5           LENGTH OF DEB FIELD HEADER           41920020
         MVI   FLDLEN,N2           LENGTH OF DEB FIELD                  42000020
         MVI   RELADR,N14          DISPL OF FIELD INTO DASD SEC OF DEB  42080020
         B     SECNDSEC            GO CHECK POINTER TO DASD SECTION     42160020
*                                                                       42240020
*        ANALYZE POSITION IN DEB                                        42320020
*                                                                       42400020
FIRSTSEC EQU   *                                                        42480020
         TM    OUTPUTSW,ANYSECND   IS THEIR A DIRECT ACCESS SECTION     42560020
         BM    NOSECOND            NO, GO CLEAN UP AND GIVE MESSAGE     42640020
         TM    OUTPUTSW,ALLCHECK   ARE ALL FIELDS REQUESTED             42720020
         BO    HEADERCK            YES, GO PUT OUT DASD SECTION HDR     42800020
SECNDSEC EQU   *                                                        42880020
         TM    OUTPUTSW,ANYSECND   IS THEIR A DIRECT ACCESS SECTION     42960020
         BM    NOSECOND            NO, GO CLEAN UP AND GIVE MESSAGE     43040020
         TM    OUTPUTSW,DASDSEC    IS POINTER TO SECOND SECTION OK      43120020
         BO    CVTANDIO            YES, GO CONVERT FIELD                43200020
         LTR   R2,R2               IS THEIR PREVIOUS OUTPUT             43280020
         BZ    SETSECPT            NO, GO POINT TO DASD SECTION         43360020
         L     R10,OUTBUF          POINT TO OUTPUT BUFFER               43440020
         LA    R14,N2(R2)          SET LENGTH OF OUTPUT                 43520020
         SLL   R14,N16             LENGTH IN HIGH ORDER HALF            43600020
         ST    R14,N0(R10)         PREFIX OUTPUT WITH LENGTH            43680020
         NI    OUTPUTSW,(HEXFF-FLDCHECK)                                43760020
         OI    OUTPUTSW,HDRCHECK                                        43840020
         BAL   R14,DEBIO           GO PUT OUT FIRST SECTION HDRS        43920020
*                                   AND FIELD DATA                      44000020
         SR    R2,R2               NO OUTPUT TO PUT OUT                 44080020
SETSECPT EQU   *                                                        44160020
         LA    R3,N32(R3)          POINT TO SECOND SECTION - DASD       44240020
         TM    OUTPUTSW,ISAMBIT    IS DEB FOR A ISAM DATASET            44320020
         BZ    NOTISAM2            NO, GO ON                            44400020
         LA    R3,N16(R3)          YES, SKIP ISAM SECTION               44480020
NOTISAM2 EQU   *                                                        44560020
         OI    OUTPUTSW,DASDSEC    INDICATE POINTER TO DASD SEC OK      44640020
         B     CVTANDIO            GO CONVERT DEB FIELD                 44720020
HEADERCK EQU   *                                                        44800020
         TM    OUTPUTSW,ALLCHECK   ARE ALL FIELDS REQUESTED             44880020
         BZ    CVTANDIO            IF NO PROCESS THE FIELD              44960020
         LTR   R2,R2               IS THERE PREVIOUS OUTPUT             45040020
         BZ    NOOUTPUT            NO, GO GET SECTION HEADERS           45120020
         L     R10,OUTBUF          POINT TO OUTPUT BUFFER               45200020
         LA    R14,N2(R2)          SET LENGTH OF OUTPUT                 45280020
         SLL   R14,N16             LENGTH IN HIGH ORDER HALFWORD        45360020
         ST    R14,N0(R10)         STORE IN OUTPUT BUFFER               45440020
         NI    OUTPUTSW,(HEXFF-FLDCHECK) INDICATE NOT A FIELD           45520020
         OI    OUTPUTSW,HDRCHECK   INDICATE A HEADER                    45600020
         BAL   R14,DEBIO           PUT OUT HEADER AND FIELD             45680020
         SR    R2,R2               RESET OUTPUT COUNTER                 45760020
NOOUTPUT C     R6,FSTPDEND         IN SECTION1 OR SECTION2              45840020
         L     R10,OUTBUF          POINT TO OUTPUT BUFFER               45920020
         BNL   SECT2IO             IF IN SECTION2 BRANCH                46000020
         MVC   N4(L'HEADER1,R10),HEADER1                                46080020
         LA    R14,L'HEADER1       LOAD LENGTH OF HEADER                46160020
         B     HDR10               OUTPUT THE HEADER                    46240020
SECT2IO  EQU   *                                                        46320020
         SR    R0,R0               SPACE                                46400020
         L     R1,OUTBUF            A                                   46480020
         ST    R0,N0(R1)             LINE                               46560020
         ST    R1,OUTPTR1             BETWEEN                           46640020
         LA    R1,OUTPTR1              SECTIONS                         46720020
         L     R15,TPUTADDR        ADDRESS OF I/O MODULE                46800020
         BALR  R14,R15             GO SPACE A LINE                      46880020
         LTR   R15,R15             IS I/O OK                            46960020
         BNZ   DEBRET              NO, GO SET UP RETURN                 47040020
         MVC   N4(L'HEADER2,R10),HEADER2    MOVE HEADER TO BUFFER       47120020
         LA    R14,L'HEADER2                                            47200020
         NI    OUTPUTSW,(HEXFF-ALLCHECK)                                47280020
         LA    R3,N32(R3)          ADDR OF FIRST DASD SECTION           47360020
         TM    OUTPUTSW,ISAMBIT    IS DEB FOR A ISAM DATASET            47440020
         BZ    NOTISAM3            NO, GO ON                            47520020
         LA    R3,N16(R3)          YES, SKIP ISAM SECTION               47600020
NOTISAM3 EQU   *                                                        47680020
         OI    OUTPUTSW,DASDSEC    INDICATE PTR TO SECOND SECTION OK    47760020
HDR10    LA    R14,N4(R14)         SET LENGTH OF OUTPUT                 47840020
         NI    OUTPUTSW,(HEXFF-HDRCHECK-FLDCHECK)                       47920020
         SLL   R14,N16             LENGTH IN HIGH ORDER HALFWORD        48000020
         ST    R14,N0(R10)         STORE LENGTH IN OUTPUT BUFFER        48080020
         BAL   R14,DEBIO           PUT OUT THE HEADER                   48160020
         SPACE 1                                                        48240020
*********************************************************************** 48320020
*   THE FOLLOWING CODE DETERMINES WHETHER THE OUTPUT LINE IS ALREADY  * 48400020
*   FULL.  IF FULL CONTROL IS PASSED TO DEBIO.  WHEN THIS SECTION IS  * 48480020
*   REACHED, R6 POINTS TO THE PDE OF THE FIELD BEING PROCESSED, AND   * 48560020
*   FLDLEN, HDRLEN, RELADR, AND HDRBUF CONTAIN THE PROPER INFORMATION * 48640020
*   FOR THAT FIELD.                                                   * 48720020
*********************************************************************** 48800020
         SPACE 1                                                        48880020
CVTANDIO EQU   *                                                        48960020
         SR    R7,R7                                                    49040020
         SR    R10,R10                                                  49120020
         IC    R7,FLDLEN           LOAD FIELD LENGTH                    49200020
         IC    R10,HDRLEN          LOAD HEADER LENGTH                   49280020
         AR    R7,R7               DOUBLE FOR TRUE PRINTABLE LENGTH     49360020
         CR    R7,R10              WHICH IS LONGER                      49440020
         BH    FLDLONGR            IF FIELD IS LONGER, BRANCH           49520020
         LR    R7,R10              R7 CONTAINS OUTPUT LENGTH            49600020
FLDLONGR AR    R7,R2               CALCULATE TOTAL NEW OUTPUT LENGTH    49680020
         C     R7,LINELEN          IS THERE ROOM FOR THIS FIELD         49760020
         BNH   MOREROOM            BRANCH IF THE FIELD CAN FIT          49840020
         L     R11,OUTBUF          POINT TO OUTPUT BUFFER               49920020
         LA    R10,N2(R2)          LENGTH OF OUTPUT BUFFER              50000020
         SLL   R10,N16             LENGTH IN HIGH ORDER HALFWORD        50080020
         ST    R10,N0(R11)         STORE LENGTH OF OUTPUT               50160020
         TM    OUTPUTSW,HDRCHECK                                        50240020
         BZ    HEADERIO            GO SET UP TO OUTPUT FIELD HDRS       50320020
         OI    OUTPUTSW,FLDCHECK                                        50400020
         B     DEBIOGO             GO SETUP TO OUTPUT LINE              50480020
HEADERIO NI    OUTPUTSW,(HEXFF-FLDCHECK)                                50560020
         OI    OUTPUTSW,HDRCHECK                                        50640020
DEBIOGO  BAL   R14,DEBIO           GO TO INTERNAL I/O ROUTINE           50720020
         SR    R7,R2               RESET LENGTH OF FIELD TO BE CONVRTED 50800020
         ST    R6,FSTADDR                                               50880020
         SR    R2,R2               SET OUTPUT LENGTH TO ZERO            50960020
          SPACE                                                         51040020
*********************************************************************** 51120020
*   THE FOLLOWING CODE IS REACHED WHEN THERE IS MORE ROOM IN THE      * 51200020
*   OUTPUT BUFFER.  IT SETS UP FOR DEBCVT WHICH WILL CONVERT THE      * 51280020
*   FIELD TO PRINTABLE HEXADECIMAL AND MOVE THE HEADERS AND FIELD     * 51360020
*   TO THE PROPER BUFFERS                                             * 51440020
*********************************************************************** 51520020
          SPACE                                                         51600020
MOREROOM EQU   *                                                        51680020
         LTR   R2,R2                                                    51760020
         BNZ   RESET               MORE ROOM IN BUFFER, GO ADD          51840020
         ST    R6,FSTADDR                                               51920020
RESET    SR    R7,R2                                                    52000020
         SR    R10,R10                                                  52080020
         IC    R10,RELADR          FIND OFFSET OF FIELD                 52160020
         AR    R10,R3              ADD OFFSET TO BASE                   52240020
         ST    R10,STRNGPTR        STORE IN LIST FOR IKJEGCVT           52320020
         SPACE 1                                                        52400020
*********************************************************************** 52480020
*  THE FOLLOWING CODE SETS UP THE PARAMETER LIST FOR IKJEGCVT WHICH   * 52560020
*  WILL CONVERT THE DEB FIELD TO PRINTABLE HEXADECIMAL.  IT THEN      * 52640020
*  DETERMINES WHETHER THE HEADER FOR THAT FIELD HAS BEEN OUTPUTTED,   * 52720020
*  AND MOVES THE CONVERTED FIELD TO THE PROPER BUFFER.                * 52800020
*********************************************************************** 52880020
         SPACE                                                          52960020
DEBCVT   EQU   *                                                        53040020
         MVI   CVTLL,HEX00         ZERO OUT TOP BYTE OF LENGTH          53120020
         MVC   CVTLL+N1(N1),FLDLEN   MOVE LENGTH OF FIELD TO PARM LIST  53200020
         MVI   FLAGS,FLAG          MOVE FLAG TO LIST                    53280020
         MVI   TYPE,TYPECODE       MOVE IN CODE FOR HEX                 53360020
         LA    R1,STRNGPTR         POINT TO PARM LIST                   53440020
         LCR   R0,R1               R0 NEGATIVE FOR CONVERT TO PRINTABLE 53520020
         L     R15,TSTCONVT        LOAD ADDRESS OF IKJEGCVT             53600020
         BALR  R14,R15             GO TO IKJEGCVT                       53680020
         LTR   R15,R15             IS RETURN CODE 0                     53760020
         BNZ   DEBRET              IF NO BRANCH                         53840020
         L     R10,CONAREA         LOAD ADDRESS OF CONVERTED FIELDS     53920020
         TM    OUTPUTSW,HDRCHECK   IS HEADER OUT                        54000020
         BZ    HDRNTOUT            BRANCH IF NOT OUT YET                54080020
         L     R11,OUTBUF          POINT TO OUTPUT BUFFER               54160020
         AR    R11,R2              SKIP PREVIOUS DATA                   54240020
         IC    R1,FLDLEN           GET LENGTH OF FIELD                  54320020
         AR    R1,R1               DOUBLE FOR PRINTABLE LENGTH          54400020
         BCTR  R1,R0               LEN-1 FOR EXECUTE INSTR              54480020
         EX    R1,MOVE2            MOVE CONVERTED FIELD TO OUTBUF       54560020
         B     CVTRTRN             GO CHECK FOR MORE FIELDS             54640020
HDRNTOUT LA    R11,BUFFER          POINT TO FIELD BUFFER                54720020
         AR    R11,R2                                                   54800020
         IC    R1,FLDLEN           GET LENGTH OF FIELD                  54880020
         AR    R1,R1               DOUBLE FOR PRINTABLE LENGTH          54960020
         BCTR  R1,R0               LEN-1 FOR EXECUTE INSTR              55040020
         EX    R1,MOVE3            MOVE FIELD TO BUFFER IN WORKAREA     55120020
         L     R11,OUTBUF          ADDRESS OF OUTPUT BUFFER             55200020
         LA    R10,HDRBUF          ADDRESS OF HEADER BUFFER             55280020
         AR    R11,R2                                                   55360020
         SR    R1,R1                                                    55440020
         IC    R1,HDRLEN           GET HEADER LENGTH                    55520020
         BCTR  R1,R0               LEN-1 FOR EXECUTE INSTR              55600020
         EX    R1,MOVE4            MOVE FIELD HEADER TO OUTBUF          55680020
CVTRTRN  LA    R6,N2(R6)                                                55760020
         LA    R2,N2(R2)           SET FOR TWO SPACES BETWEEN FIELDS    55840020
         AR    R2,R7                                                    55920020
         C     R6,LASTPDE          ARE THERE ANY MORE PDE'S             56000020
         BE    PDLEND              BRANCH IF NO                         56080020
         B     PDECHECK            GO CHECK NEXT PDE                    56160020
          SPACE                                                         56240020
*********************************************************************** 56320020
* THE FOLLOWING CODE CONTAINS THE HEART OF THE LOGIC OF THE PROGRAM.  * 56400020
* IT SETS UP THE PARAMETER LIST FOR IKJEGIO1 WHICH WILL OUTPUT THE    * 56480020
* LINE OF DATA.  IT THEN DETERMINES WHAT KIND OF DATA, WHETHER HEADER * 56560020
* OR FIELD, WAS OUTPUTTED.  IF FIELD DATA WAS PUT OUT IT CHECKS FOR   * 56640020
* FURTHER EXTENTS OF THOSE FIELDS, AND FOR FURTHER FIELDS.  IF A      * 56720020
* FIELD HEADER WAS PUT OUT IT SETS UP THE BUFFERS AND THE PARAMETER   * 56800020
* LIST TO OUTPUT THE CORRESPONDING FIELDS.                            * 56880020
* UPON REACHING THIS SECTION, R2 CONTAINS THE OUTPUT LINE LENGTH,     * 56960020
* OUTPUTSW INDICATES THE KIND OF DATA IN THE BUFFER, R6 POINTS TO THE * 57040020
* PDE OF THE NEXT FIELD, EXTCTR CONTAINS THE NUMBER OF REMAINING      * 57120020
* EXTENTS, AND R3 POINTS TO THE DEB.                                  * 57200020
*********************************************************************** 57280020
         SPACE                                                          57360020
DEBIO    EQU   *                                                        57440020
         OI    OUTPUTSW,SOMEOUT    INDICATE WE PUT OUT A LINE           57520020
         L     R1,OUTBUF           POINT TO BUFFER                      57600020
         ST    R1,OUTPTR1          STORE POINTER IN LIST                57680020
         L     R0,PRINTFLG                                              57760020
         SR    R1,R1                                                    57840020
         ST    R1,PRINTFLG                                              57920020
         ST    R1,OUTPTR2          ZERO OUT SECOND WORD OF LIST         58000020
         LA    R1,OUTPTR1          POINT TO PARM LIST                   58080020
         L     R15,TPUTADDR        LOAD ADDRESS OF IKJEGIO1             58160020
         ST    R14,REG14           STORE RETURN ADDRESS                 58240020
         BALR  R14,R15             GO TO IKJEGIO1                       58320020
         LTR   R15,R15             IS RETURN CODE 0                     58400020
         BNZ   DEBRET              IF NO RETURN                         58480020
         L     R10,OUTBUF                                               58560020
         MVI   N4(R10),BLANK                                            58640020
         MVC   N5(N79,R10),N4(R10)                                      58720020
         L     R14,REG14           RESTORE RETURN ADDRESS               58800020
         TM    OUTPUTSW,FLDCHECK   WAS A FIELD JUST PUT OUT             58880020
         BZ    FURTHRCK            BRANCH IF NOT A FIELD                58960020
BRANCH2  EQU   *                   CONVERTED FIELDS WERE JUST PUT OUT   59040020
         BCTR  R6,R0               POINT BACK                           59120020
         BCTR  R6,R0                 TO PDE                             59200020
         LA    R10,BUFFER                                               59280020
         MVI   N0(R10),BLANK                                            59360020
         MVC   N1(N79,R10),N0(R10)                                      59440020
         CLC   FSTADDR(N4),FSTPDEND   IN BASIC OR DASD SECTION          59520020
         BL    S1OUTPUT            IF IN SECTION1 BRANCH                59600020
         LA    R6,N2(R6)                                                59680020
         SR    R10,R10                                                  59760020
         IC    R10,EXTCTR          LOAD EXTENT COUNTER                  59840020
         BCTR  R10,R0              DECREMENT EXTENT COUNTER             59920020
         STC   R10,EXTCTR                                               60000020
         LTR   R10,R10             ARE THERE MORE EXTENTS               60080020
         BZ    NOMOREXT            BRANCH IF NO MORE                    60160020
         L     R6,FSTADDR          POINT TO FIRST PDE FOR OUTPUT LINE   60240020
         LA    R3,N16(R3)          POINT TO NEXT EXTENT                 60320020
         SR    R2,R2                                                    60400020
         B     PDECHECK            CHECK NEXT PDE                       60480020
FURTHRCK TM    OUTPUTSW,HDRCHECK   WAS A FIELD HEADER JUST PUT OUT      60560020
         BZ    BRANCH1             IF NO BRANCH TO SETUP RETURN         60640020
         LA    R10,BUFFER                                               60720020
         L     R11,OUTBUF                                               60800020
         LR    R1,R2                                                    60880020
         BCTR  R1,R0               LEN-1 FOR EXECUTE INSTR              60960020
         EX    R1,MOVE4            MOVE FIELDS TO OUTBUF                61040020
         OI    OUTPUTSW,FLDCHECK                                        61120020
         B     DEBIO               GO SETUP TO PUT OUT LINE             61200020
BRANCH1  BR    R14                 SECTION 1 OR 2 HEADER PUT OUT        61280020
NOMOREXT EQU   *                                                        61360020
         NI    OUTPUTSW,(HEXFF-HDRCHECK)     INDICATE NO HEADER YET     61440020
         MVC   EXTCTR(N1),NMEXTSTR  RESET EXTENT COUNTER FOR FIELDS     61520020
         L     R3,TSTANSPL         ADDRESS OF PDL                       61600020
         L     R3,N40(R3)          ADDR OF DEB FROM ADDRESS PDE         61680020
         LA    R3,N32(R3)          ADDRESS OF FIRST DASD SECTION        61760020
         BR    R14                 RETURN TO MAIN ROUTINE               61840020
S1OUTPUT LA    R6,N2(R6)           RESTORE PDE POINTER                  61920020
         NI    OUTPUTSW,(HEXFF-HDRCHECK)                                62000020
         NI    OUTPUTSW,(HEXFF-FLDCHECK)                                62080020
         BR    R14                 RETURN TO MAIN ROUTINE               62160020
         SPACE                                                          62240020
*********************************************************************** 62320020
*   THE FOLLOWING CODE IS REACHED WHEN THERE ARE NO MORE FIELDS.      * 62400020
*   IT CHECKS THE BUFFER FOR MORE DATA, IN WHICH CASE A BRANCH IS     * 62480020
*   MADE TO DEBIO.  IF THERE ARE MORE EXTENTS IS THEN PASSED TO       * 62560020
*   TABLESCN WHICH WILL PROCESS THE NEXT EXTENT.  OTHERWISE CONTROL   * 62640020
*   IS RETURNED AND PASSED TO DEBRET PRIOR TO RETURN TO IKJEGMN1.     * 62720020
*********************************************************************** 62800020
         SPACE 1                                                        62880020
PDLEND   EQU   *                                                        62960020
         LTR   R2,R2               IS THERE ANY MORE OUTPUT             63040020
         BNZ   PUTITOUT            YES, GO PUT OUT REST OF OUTPUT       63120020
         TM    OUTPUTSW,SOMEOUT    DID WE OUTPUT ANY FIELDS             63200020
         BO    DEBRET              YES, GO SET UP RETURN TO MAINLINE    63280020
         L     R6,=A(IKJEGDBM)     ADDRESS OF MESSAGE SECTION           63360020
         USING IKJEGDBM,R6                                              63440020
         LA    R1,MESGNO5          ADDR OF BAD FIELD KYWD ON CMD MESG   63520020
         DROP  R6                                                       63600020
         B     MSGIO               GO PUT OUT MESSAGE                   63680020
PUTITOUT EQU   *                                                        63760020
         L     R10,OUTBUF          LOAD ADDRESS OF OUTPUT BUFFER        63840020
         LA    R1,N2(R2)           LENGTH OF OUTPUT BUFFER              63920020
         SLL   R1,N16              LENGTH IN HIGH ORDER HALFWORD        64000020
         ST    R1,N0(R10)          STORE LENGTH OF OUTPUT               64080020
         TM    OUTPUTSW,HDRCHECK                                        64160020
         BZ    TURNONHD            GO SET UP FOR FIELD HEADER           64240020
         OI    OUTPUTSW,FLDCHECK                                        64320020
         B     BRANCH              GO SET UP TO OUTPUT FIELDS           64400020
TURNONHD NI    OUTPUTSW,(HEXFF-FLDCHECK)                                64480020
         OI    OUTPUTSW,HDRCHECK                                        64560020
BRANCH   BAL   R14,DEBIO           GO SETUP TO OUTPUT LINE              64640020
         B     DEBRET              RETURN TO IKJEGMN1                   64720020
NOSECOND EQU   *                                                        64800020
         LTR   R2,R2               IS THEIR ANY FIELDS TO PUT OUT       64880020
         BZ    GIVEMESG            NO, GO GIVE MESSAGE                  64960020
         L     R10,OUTBUF          ADDRESS OF OUTPUT BUFFER             65040020
         LA    R1,N2(R2)           LENGTH OF DATA TO PUT OUT            65120020
         SLL   R1,N16              LENGTH IN HIGH ORDER HALFWORD        65200020
         ST    R1,N0(R10)          PREFIX OUTPUT WITH LENGTH            65280020
         NI    OUTPUTSW,(HEXFF-FLDCHECK)                                65360020
         OI    OUTPUTSW,HDRCHECK                                        65440020
         BAL   R14,DEBIO           GO PUT OUT FIELD HDRS AND FIELDS     65520020
         SR    R2,R2               NO MORE OUTPUT                       65600020
GIVEMESG EQU   *                                                        65680020
         L     R6,=A(IKJEGDBM)     ADDRESS OF MESSAGE SECTION           65760020
         USING IKJEGDBM,R6                                              65840020
         TM    OUTPUTSW,NOTDASD    NO DASD SECTION BECAUSE NOT A DASD   65920020
         BO    PUTMSG6A            YES, GO GIVE NOT A DASD MESSAGE      66000020
         LA    R1,MESGNO4          NO, GIVE ZERO EXTENT MESSAGE         66080020
         B     MSGAGOGO            GO PUT OUT MESSAGE                   66160020
PUTMSG6A EQU   *                                                        66240020
         LA    R1,MESGNO4B         ADDR OF DATASET NOT ON DASD MESSAGE  66320020
         DROP  R6                                                       66400020
MSGAGOGO EQU   *                                                        66480020
         LNR   R1,R1               REGISTER 1 IS NEGATIVE FOR MESSAGES  66560020
         L     R15,TPUTADDR        ADDRESS OF TEST'S I/O MODULE         66640020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)                                66720020
         BALR  R14,R15             GO PUT OUT MESSAGE                   66800020
         B     DEBRET              GO SET RETURN CODE                   66880020
          SPACE                                                         66960020
*********************************************************************** 67040020
*   THE FOLLOWING CODE PROCESSES THE VARIOUS RETURN CODES AND         * 67120020
*    RETURNS TO MAINLINE.                                             * 67200020
*********************************************************************** 67280020
          SPACE                                                         67360020
DEBRETRY EQU   *                                                        67440020
         L     R9,CVTPTR           ADDRESS OF CVT                       67520020
         L     R9,CVTTCBP-CVT(R9)  POINTER TO NEW, CURRENT TCBS         67600020
         L     R9,N4(R9)           ADDRESS OF CURRENT TCB IS TEST TCB   67680020
         L     R9,TCBTRN-TCB(R9)   ADDRESS OF TCOMTAB                   67760020
         L     R13,REGSAVE2        ADDRESS OF MY SAVE AREA              67840020
         L     R12,N68(R13)        MY BASE                              67920020
         LA    R8,N20              ABEND RETURN CODE FOR MAINLINE       68000020
         LTR   R0,R0               DID STAE GET CORE                    68080020
         BNZ   RETURN              NO, GO RETURN TO MAINLINE            68160020
         FREEMAIN  R,LV=N104,A=(R1),SP=N0   FREE STAE CORE              68240020
         B     RETURN              GO RETURN TO MAINLINE                68320020
EXITERR  EQU   *                                                        68400020
         L     R15,REG14           VALIDITY EXIT SAVED RET CODE         68480020
DEBRET   EQU   *                                                        68560020
         LA    R8,N16              ATTENTION RETCODE                    68640020
         CR    R8,R15              DID SOMEONE HIT ATTENTION            68720020
         BE    RETURN              IF YES BRANCH                        68800020
         LA    R8,N20              ABEND RETURN CODE                    68880020
         CR    R8,R15              DID SOMEONE ABEND                    68960020
         BE    RETURN              YES, GO SET RETURN                   69040020
         SR    R8,R8               RETCODE IS ZERO                      69120020
         B     RETURN              GO RETURN TO MAINLINE                69200020
DEBRET1  EQU   *                   PARSE RETURN CODE ANALYSIS           69280020
         L     R6,=A(IKJEGDBM)     ADDRESS OF MESSAGE SECTION           69360020
         USING IKJEGDBM,R6                                              69440020
         LA    R8,N8               ATTENTION R.C. FROM PARSE IS 8       69520020
         CR    R8,R15              HAS AN ATTENTION BEEN SCHEDULED      69600020
         LA    R8,N16              MAINLINE ATTENTION R.C. IS 16        69680020
         BE    RETURN              ATTENTION SCHEDULED, GO SET UP RET   69760020
         LA    R8,N20              VALIDITY EXIT ERR R.C. FROM PARSE    69840020
         CR    R8,R15              DID VALIDITY EXIT SEEK TO END        69920020
         BE    EXITERR             VALIDITY EXIT TERM., GO SET RETURN   70000020
         LA    R8,N16              NO CORE R.C. FROM PARSE              70080020
         CR    R8,R15              IS R.C. FROM PARSE 16                70160020
         LA    R1,MESGNO3          SET NO CORE MESSAGE                  70240020
         BE    MSGIO               IF R.C. 16, GO GIVE NO CORE MESSAGE  70320020
         LA    R8,N12              INVALID PARMS R.C. FROM PARSE        70400020
         CR    R8,R15              IS R.C. FROM PARSE 12                70480020
         LA    R1,MESGNO2          SET INVALID PARMS MESSAGE            70560020
         BE    MSGIO               IF R.C. 12, GO GIVE INVALID MESSAGE  70640020
         DROP  R6                                                       70800020
         SR    R8,R8               PARSE RC=4, NO MESSAGE               70850020
         OI    TSTFLGS4,TSTFLUSH   IF STACK, TELL MNL TO FLUSH          70852020
         B     RETURN              GO RETURN TO CALLER                  70860020
MSGIO    EQU   *                                                        70880020
         LNR   R1,R1               NEGATIVE REISTER 1 FOR MESSAGE       70960020
         L     R15,TPUTADDR        ADDRESS OF TEST'S I/O MODULE         71040020
         BALR  R14,R15             GO HAVE MESSAGE PUT OUT              71120020
         B     DEBRET              GO CHECK RETURN CODE FROM I/O        71200020
RETURN   EQU   *                                                        71280020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)                                71360020
         LR    R15,R8              RETCODE IN PROPER REGISTER           71440020
         L     R13,N4(R13)                                              71520020
         RETURN (14,12),T,RC=(15)                                       71600020
         EJECT                                                          71680020
*********************************************************************** 71760020
*                                                                     * 71840020
*                            HEADERS AND OTHER CONSTANTS              * 71920020
*                                                                     * 72000020
*********************************************************************** 72080020
         SPACE 2                                                        72160020
HDRRSRVD DC    C'RESERVED'                      DEB FIELD HEADER        72240020
HDRPROTG DC    C'PROTG/DEBID'                   DEB FIELD HEADER        72320020
HEADER1  DC    C'BASIC SECTION'                 DEB SECTION HEADER      72400020
HEADER2  DC    C'DIRECT ACCESS SECTION'         DEB SECTION HEADER      72480020
FLAG     EQU   X'80'               FLAG FOR IKJEGCVT                    72560020
TYPECODE EQU   X'04'               TYPE CODE FOR HEX FOR CONVERT        72640020
BLANK    EQU   C' '                                                     72720020
HEXFF    EQU   X'FF'                                                    72800020
HEX00    EQU   X'00'                                                    72880020
HEX38    EQU   X'38'                                                    72960020
HEX03    EQU   X'03'                                                    73040020
HEX04    EQU   X'04'                                                    73120020
HEX0F    EQU   X'0F'                                                    73200020
PCLADDR  DC    A(IKJEGDBP)         ADDRESS OF PARSE PCL CSECT           73280020
ABENDTAB DS    0F                                                       73360020
         DC    X'03'               LINK FAILED CODE                     73440020
         DC    AL3(PABEND1)        RESUME IC AFTER LINK                 73520020
         DC    X'0B'               INVALID DEB CODE                     73600020
         DC    AL3(PABEND2)        RESUME IC AFTER CHECK DSORG IN DCB   73680020
         DC    X'FF'               END OF TABLE INDICATOR               73760020
RETRYADR DC    AL3(DEBRETRY)       ADDRESS OF DEB STAE RETRY ROUTINE    73840020
LFSTAE   DS    0F                                                       73920020
         STAE  MF=L                                                     74000020
MOVE2    MVC   N4(N0,R11),N1(R10)                                       74080020
MOVE3    MVC   N0(N0,R11),N1(R10)                                       74160020
MOVE4    MVC   N4(N0,R11),N0(R10)                                       74240020
PDELENTH EQU   51                  TOTAL LENGTH OF FIELD PDES           74320020
ALLCHECK EQU   X'80'               OUTPUT FLAG FOR HEADER1              74400020
SOMEOUT  EQU   X'40'               FLAG FOR ANY OUTPUT, CHECK BAD PARMS 74480020
HDRCHECK EQU   X'20'               OUTPUT FLAG FOR FIELD HEADERS        74560020
FLDCHECK EQU   X'10'               OUTPUT FLAG FOR FIELDS               74640020
DASDSEC  EQU   X'08'               FLAG FOR SECOND SECTION POINTER      74720020
ISAMBIT  EQU   X'04'               FLAG FOR DEB ASSOCIATED WITH ISAM DS 74800020
ANYSECND EQU   X'03'               NO DIRECT ACCESS SECTION             74880020
NOTDASD  EQU   X'02'               NO DASD SECTION - DS NOT ON A DASD   74960020
NOEXTENT EQU   X'01'               NO DASD SECTION - 0 EXTENTS          75040020
ISAM     EQU   X'80'               ISAM ORGANIZATION CODE IN DCB        75120020
DSORG    EQU   26                  OFFSET INTO DCB OF DSORG CODE        75200020
OFFSET   EQU   64                  OFFSET OF DBWKAREA INTO TEST WRKAREA 75280020
         EJECT                                                          75360020
DBWKAREA DSECT                                                          75440020
PARSELST DS    7F                  PARM LIST FOR PARSE                  75520020
PRINTFLG DS    1F                  ADDRESS OF PRINT PDL                 75600020
OUTPUTSW DS    CL1                 OUTPUT FLAGS                         75680020
         DS    CL2                 TWO BYTES                            75760020
EXTCTR   DS    CL1                 NO. OF EXTENTS STILL TO BE PROCESSED 75840020
FSTADDR  DS    1F                  ADDR OF PDE OF 1ST FLD ON OUTPUT LNE 75920020
FSTPDEND DS    1F                  ADDRESS OF DVMOD PDE                 76000020
LASTPDE  DS    1F                  ADDRESS OF NMTRK PDE +2              76080020
BUFFER   DS    20F                 BUFFER FOR CONVERTED FIELDS          76160020
RELADR   DS    CL1                 OFFSET OF FIELD INTO THE DEB         76240020
FLDLEN   DS    CL1                 LENGTH OF DEB FIELD                  76320020
HDRLEN   DS    CL1                 LENGTH OF DEB FIELD HEADER           76400020
NMEXTSTR DS    CL1                 NUMBER OF EXTENTS IN DEB             76480020
HDRBUF   DS    3F                  BUFFER FOR CURR DEB FLD HEADER       76560020
LINELEN  DS    1F                  MAXIMUN LENGTH OF OUTPUT LINE        76640020
* IT IS ESSENTIAL THAT THE FOLLOWING 6 AREAS BE CONTIGUOUS AND IN ORDER 76720020
STRNGPTR DS    1F                  CONVERT PARM LIST - PTR TO FIELD     76800020
CVTLL    DS    CL2                                     LENGTH OF FIELD  76880020
FLAGS    DS    CL1                                     FLAGS            76960020
TYPE     DS    CL1                                     TYPE OF DATA     77040020
OUTPTR1  DS    1F                  I/O PARM LIST - PTR TO IST I/O BUFF  77120020
OUTPTR2  DS    1F                                  PTR TO 2ND I/O BUFF  77200020
REG14    DS    1F                  REG 14 OR VALIDITY CHECK EXIT R.C.   77280020
         ORG   DBWKAREA            GO BACK TO BEGINNING OF WORK AREA    77360020
STAELIST DS    3F                  PARAMETER LIST FOR STAE              77440020
         EJECT                                                          77520020
IKJEGDBM CSECT                                                          77600020
MESGNO2  DC    A(M332L1)           ADDR OF FIRST LEV MESG, IKJ57332I    77840020
         DC    A(M332L2A)          ADDRESS OF SECOND LEVEL              77920020
MESGNO3  DC    A(M333L1)           ADDR OF FIRST LEV MESG, IKJ57333I    78000020
         DC    F'0'                NO SECOND LEVEL MESSAGE              78080020
MESGNO4  DC    A(M334L1)           ADDR OF FIRST LEV MESG, IKJ57334I    78160020
         DC    A(M334L2A)          ADDRESS OF SECOND LEVEL MESSAGE      78240020
MESGNO4B DC    A(M334L1)           ADDR OF FIRST LEV MESG, IKJ57334I    78320020
         DC    A(M334L2B)          ADDRESS OF SECOND LEVEL MESSAGE      78400020
MESGNO5  DC    A(M335L1)           ADDR OF FIRST LEV MESG, IKJ57335I    78480020
         DC    F'0'                NO SECOND LEVEL MESSAGE              78560020
*                                                                       78640020
*        MESSAGES                                                       78720020
*                                                                       78800020
M330L1   DS    0H                                                       78880020
         DC    H'30'                                       BUFFER LEN   78960020
         DC    H'0'                                        ZEROES       79040020
         DC    C'IKJ57330I INVALID ADDRESS '               MESG TEXT    79120020
M330L2A  DS    0H                                                       79200020
         DC    H'65'                                       BUFFER LEN   79280020
         DC    H'0'                                        ZEROES       79360020
         DC    C'IKJ57330I REGISTER NOTATION MUST BE I'    MESG TEXT    79440020
         DC    C'NDIRECT GENERAL REGISTER'                 MESG TEXT    79520020
M330L2C  DS    0H                                                       79600020
         DC    H'46'                                       BUFFER LEN   79680020
         DC    H'0'                                        ZEROES       79760020
         DC    C'IKJ57330I DEB EXTENTS OUTSIDE MAIN ST'    MESG TEXT    79840020
         DC    C'ORAGE'                                    MESG TEXT    79920020
M330L2B  DS    0H                                                       80000020
         DC    H'40'                                       BUFFER LEN   80080020
         DC    H'0'                                        ZEROES       80160020
         DC    C'IKJ57330I FULLWORD BOUNDARY REQUIRED'     MESG TEXT    80240020
M332L1   DS    0H                                                       80960020
         DC    H'51'                                       BUFFER LEN   81040020
         DC    H'0'                                        ZEROES       81120020
         DC    C'IKJ57332I LISTDEB FAILED, COMMAND SYS'    MESG TEXT    81200020
         DC    C'TEM ERROR+'                               MESG TEXT    81280020
M332L2A  DS    0H                                                       81360020
         DC    H'33'                                       BUFFER LEN   81440020
         DC    H'0'                                        ZEROES       81520020
         DC    C'IKJ57332I PARSE ERROR CODE 12'            MESG TEXT    81600020
M333L1   DS    0H                                                       81680020
         DC    H'56'                                       BUFFER LEN   81760020
         DC    H'0'                                        ZEROES       81840020
         DC    C'IKJ57333I NOT ENOUGH MAIN STORAGE TO '    MESG TEXT    81920020
         DC    C'EXECUTE COMMAND'                          MESG TEXT    82000020
M334L1   DS    0H                                                       82080020
         DC    H'56'                                       BUFFER LEN   82160020
         DC    H'0'                                        ZEROES       82240020
         DC    C'IKJ57334I DEB DOES NOT HAVE A DIRECT '    MESG TEXT    82320020
         DC    C'ACCESS SECTION+'                          MESG TEXT    82400020
M334L2A  DS    0H                                                       82480020
         DC    H'43'                                       BUFFER LEN   82560020
         DC    H'0'                                        ZEROES       82640020
         DC    C'IKJ57334I DEBNMEXT FIELD IN DEB IS ZE'    MESG TEXT    82720020
         DC    C'RO'                                       MESG TEXT    82800020
M334L2B  DS    0H                                                       82880020
         DC    H'79'                                       BUFFER LEN   82960020
         DC    H'0'                                        ZEROES       83040020
         DC    C'IKJ57334I DATASET ASSOCIATED WITH DEB'    MESG TEXT    83120020
         DC    C' NOT ON A DIRECT ACCESS STORAGE DEVIC'    MESG TEXT    83200020
         DC    C'E'                                        MESG TEXT    83280020
M335L1   DS    0H                                                       83360020
         DC    H'57'                                       BUFFER LEN   83440020
         DC    H'0'                                        ZEROES       83520020
         DC    C'IKJ57335I DEB FIELD NAME REQUIRED'        MESG TEXT    83600020
         DC    C' AFTER FIELD KEYWORD'                     MESG TEXT    83680020
IKJEGDEB CSECT                                                          83760020
         EJECT                                                          83840020
*                                                                       83920020
*        PARSE MACROS                                                   84000020
*                                                                       84080020
         SPACE 2                                                        84160020
IKJEGDBP IKJPARM                                                        84240020
ADDRESS  IKJPOSIT  ADDRESS,VALIDCK=DEBVALCK,PROMPT='ADDRESS OF DEB'     84320020
PRINT    IKJKEYWD                                                       84400020
         IKJNAME   'PRINT',SUBFLD=DSNAME                                84480020
DEBFIELD IKJKEYWD                                                       84560020
         IKJNAME   'FIELD',SUBFLD=FIELDNAM                              84640020
DSNAME   IKJSUBF                                                        84720020
DSNAM    IKJPOSIT  DSNAME,PROMPT='DATA SET NAME'                        84800020
FIELDNAM IKJSUBF                                                        84880020
NMSUB    IKJKEYWD                                                       84960020
         IKJNAME  'DEBNMSUB'                                            85040020
TCBAD    IKJKEYWD                                                       85120020
         IKJNAME  'DEBTCBAD'                                            85200020
AMLNG    IKJKEYWD                                                       85280020
         IKJNAME  'DEBAMLNG'                                            85360020
DEBAD    IKJKEYWD                                                       85440020
         IKJNAME  'DEBDEBAD'                                            85520020
OFLGS    IKJKEYWD                                                       85600020
         IKJNAME  'DEBOFLGS'                                            85680020
IRBAD    IKJKEYWD                                                       85760020
         IKJNAME  'DEBIRBAD'                                            85840020
OPATB    IKJKEYWD                                                       85920020
         IKJNAME  'DEBOPATB'                                            86000020
QSCNT    IKJKEYWD                                                       86080020
         IKJNAME  'DEBQSCNT'                                            86160020
FLGS1    IKJKEYWD                                                       86240020
         IKJNAME   'DEBFLGS1'                                           86320020
RSVD     IKJKEYWD                                                       86400020
         IKJNAME  'DEBRSRVD'                                            86480020
NMEXT    IKJKEYWD                                                       86560020
         IKJNAME  'DEBNMEXT'                                            86640020
USPRG    IKJKEYWD                                                       86720020
         IKJNAME  'DEBUSPRG'                                            86800020
PRIOR    IKJKEYWD                                                       86880020
         IKJNAME  'DEBPRIOR'                                            86960020
ECBAD    IKJKEYWD                                                       87040020
         IKJNAME  'DEBECBAD'                                            87120020
PROTG    IKJKEYWD                                                       87200020
         IKJNAME  'DEBPROTG'                                            87280020
         IKJNAME  'DEBDEBID'                                            87360020
DCBAD    IKJKEYWD                                                       87440020
         IKJNAME  'DEBDCBAD'                                            87520020
EXSCL    IKJKEYWD                                                       87600020
         IKJNAME  'DEBEXSCL'                                            87680020
APPAD    IKJKEYWD                                                       87760020
         IKJNAME  'DEBAPPAD'                                            87840020
DVMOD    IKJKEYWD                                                       87920020
         IKJNAME  'DEBDVMOD'                                            88000020
UCBAD    IKJKEYWD                                                       88080020
         IKJNAME  'DEBUCBAD'                                            88160020
BINUM    IKJKEYWD                                                       88240020
         IKJNAME  'DEBBINUM'                                            88320020
STRCC    IKJKEYWD                                                       88400020
         IKJNAME  'DEBSTRCC'                                            88480020
STRHH    IKJKEYWD                                                       88560020
         IKJNAME  'DEBSTRHH'                                            88640020
ENDCC    IKJKEYWD                                                       88720020
         IKJNAME  'DEBENDCC'                                            88800020
ENDHH    IKJKEYWD                                                       88880020
         IKJNAME  'DEBENDHH'                                            88960020
NMTRK    IKJKEYWD                                                       89040020
         IKJNAME  'DEBNMTRK'                                            89120020
         IKJENDP                                                        89200020
*                                                                       89280020
*        THE FOLLOWING STATEMENTS EQUATE THE FIELD HEADERS IN THE PARSE 89360020
*        CSECT                                                          89440020
*                                                                       89520020
HDRNMSUB EQU   IKJEGDBP+FIRSTHDR               FIELD HEADER IN PDL      89600020
HDRTCBAD EQU   HDRNMSUB+FLDHDR                 FIELD HEADER IN PDL      89680020
HDRAMLNG EQU   HDRTCBAD+FLDHDR                 FIELD HEADER IN PDL      89760020
HDRDEBAD EQU   HDRAMLNG+FLDHDR                 FIELD HEADER IN PDL      89840020
HDROFLGS EQU   HDRDEBAD+FLDHDR                 FIELD HEADER IN PDL      89920020
HDRIRBAD EQU   HDROFLGS+FLDHDR                 FIELD HEADER IN PDL      90000020
HDROPATB EQU   HDRIRBAD+FLDHDR                 FIELD HEADER IN PDL      90080020
HDRQSCNT EQU   HDROPATB+FLDHDR                 FIELD HEADER IN PDL      90160020
HDRFLGS1 EQU   HDRQSCNT+FLDHDR                 FIELD HEADER IN PDL      90240020
HDRNMEXT EQU   HDRFLGS1+FLDHDR+FLDHDR          FIELD HEADER IN PDL      90320020
HDRUSPRG EQU   HDRNMEXT+FLDHDR                 FIELD HEADER IN PDL      90400020
HDRPRIOR EQU   HDRUSPRG+FLDHDR                 FIELD HEADER IN PDL      90480020
HDRECBAD EQU   HDRPRIOR+FLDHDR                 FIELD HEADER IN PDL      90560020
HDRDCBAD EQU   HDRECBAD+FLDHDR+FLDHDR+LENNAME  FIELD HEADER IN PDL      90640020
HDREXSCL EQU   HDRDCBAD+FLDHDR                 FIELD HEADER IN PDL      90720020
HDRAPPAD EQU   HDREXSCL+FLDHDR                 FIELD HEADER IN PDL      90800020
HDRDVMOD EQU   HDRAPPAD+FLDHDR                 FIELD HEADER IN PDL      90880020
HDRUCBAD EQU   HDRDVMOD+FLDHDR                 FIELD HEADER IN PDL      90960020
HDRBINUM EQU   HDRUCBAD+FLDHDR                 FIELD HEADER IN PDL      91040020
HDRSTRCC EQU   HDRBINUM+FLDHDR                 FIELD HEADER IN PDL      91120020
HDRSTRHH EQU   HDRSTRCC+FLDHDR                 FIELD HEADER IN PDL      91200020
HDRENDCC EQU   HDRSTRHH+FLDHDR                 FIELD HEADER IN PDL      91280020
HDRENDHH EQU   HDRENDCC+FLDHDR                 FIELD HEADER IN PDL      91360020
HDRNMTRK EQU   HDRENDHH+FLDHDR                 FIELD HEADER IN PDL      91440020
         SPACE 4                                                        91520020
CVT      DSECT                                                          91600020
         CVT                                                            91680020
         EJECT                                                          91760020
         IKJTCB                                                         91840020
         END                                                            91920020
