         TITLE  'IKJEGEQU, THE EQUATE AND DROP COMMANDS OF TEST'        00060020
IKJEGEQU CSECT                                                          00120020
*RELEASE 21 CHANGES                                                     00170021
*C865800,867000                                                  A43351 00220021
**********************************************************************  00240020
* STATUS  CHANGE LEVEL  000                                          *  00300020
*                                                                    *  00360020
* FUNCTION                                                           *  00420020
*    THIS MODULE IS RESPONSIBLE FOR BUILDING AND MAINTAINING AN IN   *  00480020
*    CORE SYMBOL TABLE.  EACH ENTRY IN THE TABLE CONTAINS A POINTER  *  00540020
*    TO THE NEXT ENTRY, THE LOAD ADDRESS OF THE SYMBOL, THE          *  00600020
*    ATTRIBUTES OF THE SYMBOL AND THE LENGTH OF THE SYMBOL ALONG WITH*  00660020
*    THE SYMBOL.  A NEW ENTRY IS BUILT FOR EACH NEW SYMBOL.  IF A    *  00720020
*    SYMBOL ALREADY EXISTS IN THE TABLE, THE LOAD ADDRESS AND        *  00780020
*    ATTRIBUTES MAY BE OVERRIDEN.  IF THE ATTRIBUTES ARE NOT         *  00840020
*    SPECIFIED THE DEFAULTS TAKEN WILL BE TYPE-HEX, LENGTH-4 AND     *  00900020
*    MULTIPLICITY-1.  THE MODULE IS CAPABLE OF DEFAULTING THE        *  00960020
*    LENGTH AND/OR MULTIPLICITY FOR THE DIFFERENT TYPES.  THIS       *  01020020
*    MODULE IS ALSO CAPABLE OF DELETING A LIST OF ENTRIES OR ALL     *  01080020
*    ENTRIES FROM THE IN CORE SYMBOL TABLE.                          *  01140020
*                                                                    *  01200020
* ENTRY POINTS                                                       *  01260020
*                                                                    *  01320020
*         IKJEGEQU-ENTERED VIA A LINK FROM IKJEGMNL.  REGISTER 9     *  01370020
*    WILL POINT TO TCOMTAB, THE COMMON DSECT USED BY TEST.  THIS IS  *  01380020
*    THE ENTRY POINT WHEN ADDING OR UPDATING AN ENTRY IN THE         *  01430020
*    SYMBOL TABLE POINTED TO BY SYMTABLE IN TCOMTAB.                 *  01440020
*                                                                    *  01620020
*         IKJEGDRP-ENTERED VIA A LINK FROM IKJEGMNL.  REGISTER 9     *  01670020
*    WILL POINT TO TCOMTAB, THE COMMON DSECT USED BY TEST.  THIS IS  *  01680020
*    THE ENTRY POINT WHEN DELETING AN ENTRY FROM THE SYMBOL TABLE    *  01730020
*    POINTED TO BY SYMTABLE IN TCOMTAB.                              *  01740020
*                                                                    *  01920020
*         IKJEGVDK-ENTERED FROM IKJPARS.  REGISTER 1 POINTS TO A     *  01970020
*    THREE WORD PARAMETER LIST.  THE FIRST WORD IS A POINTER TO THE  *  01980020
*    PDE, THE SECOND WORD IS A POINTER TO IKJEGEQU'S OR IKJEGDRP'S   *  02030020
*    SAVEAREA.  THE THIRD WORD IS TO BE USED BY THE VALIDITY CHECK   *  02040020
*    ROUTINE TO PASS A POINTER TO A SECOND LEVEL MESSAGE BACK TO     *  02090020
*    IKJPARS.                                                        *  02100020
*                                                                    *  02340020
* INPUT                                                              *  02400020
*    THE REQUESTED FUNCTION WILL BE POINTED TO BY INBUF IN TCOMTAB.  *  02460020
*    FOR THE EQUATE VERB, THE SYMBOL AND ADDRESS PARAMETERS MUST BE  *  02520020
*    SPECIFIED.  THE REST OF THE PARAMETERS ARE OPTIONAL.            *  02580020
*    THE FORMAT OF THE EQUATE STATEMENT IS                           *  02640020
*    EQUATE SYMBOL ADDR TYPE LENGTH(X) MULTIPLE(X) WHERE X IS AN     *  02700020
*    INTEGER.                                                        *  02750020
*    THE SYMBOL IS AN OPTIONAL PARAMETER FOR THE DROP VERB.  THE     *  02760020
*    FORMAT OF THE DROP STATEMENT IS                                 *  02820020
*    DROP SYMBOL OR DROP OR DROP SYMBOL,SYMBOL WHERE THE LIST IS     *  02880020
*    ENCLOSED BY PARENTHESIS.                                        *  02930020
*                                                                    *  02940020
* OUTPUT                                                             *  03000020
*    IKJEGEQU WILL PUT THE ADDRESS OF THE IN CORE SYMBOL TABLE IN THE*  03060020
*    SYMTABLE FIELD IN TCOMTAB.  THE ADDRESS OF EACH NEW ENTRY CAN BE*  03120020
*    FOUND IN THE FIRST WORD OF THE PREVIOUS ENTRY.                  *  03180020
*    IKJEGDRP WILL DELETE AN ENTRY FROM THE IN CORE SYMBOL TABLE AND *  03240020
*    UPDATE THE AFFECTED POINTER TO REFLECT THE DELETION.  IF ALL THE*  03300020
*    ENTRIES ARE DELETED SYMTABLE WILL CONTAIN ZEROES.               *  03360020
*                                                                    *  03420020
* EXTERNAL REFERENCES                                                *  03480020
*                                                                    *  03540020
*         IKJPARS-TO VALIDITY CHECK AND SCAN THE COMMAND BUFFER.     *  03590020
*    REGISTER 1 WILL POINT TO A 7 WORD PARAMETER LIST.               *  03600020
*                                                                    *  03720020
*         IKJEGCVT-TO CONVERT THE ADDRESS, MULTIPLICITY AND LENGTH   *  03770020
*    ATTRIBUTES TO BINARY.  REGISTER 1 WILL BE THE ADDRESS COMPLEMENT*  03780020
*    OF THE ADDRESS PDE FOR THE ADDRESS CONVERSION AND WILL BE THE   *  03830020
*    ADDRESS OF THE PDE FOR THE ATTRIBUTE CONVERSIONS.  REGISTER 0   *  03840020
*    WILL BE POSITIVE TO INDICATE BINARY CONVERSION.                 *  03890020
*                                                                    *  04140020
*         IKJEGIO-TO WRITE DIAGNOSTIC MESSAGES.  REGISTER 1 WILL     *  04190020
*    POINT TO A TWO WORD PARAMETER LIST.  THE FIRST WORD WILL BE A   *  04200020
*    POINTER TO THE FIRST LEVEL MESSAGE.  THE SECOND WORD WILL BE A  *  04250020
*    POINTER TO THE SECOND LEVEL MESSAGE OR ZERO IF NO SECOND        *  04260020
*    LEVEL MESSAGE EXISTS.                                           *  04310020
*    NOTE  REGISTER 1 IS A NEGATIVE POINTER                          *  04320020
*                                                                    *  04560020
*         IKJEGBLD-TO BUILD ADDRESS STRING FOR A MESSAGE.  REGISTER  *  04610020
*    0 WILL CONTAIN THE ADDRESS OF THE ADDRESS PARAMETER DESCRIPTOR  *  04620020
*    ENTRY (PDE).  REGISTER 1 WILL CONTAIN A POINTER TO THE AREA THE *  04670020
*    STRING IS TO BE BUILT IN.  UPON RETURN FROM THE ADDRESS BUILD   *  04680020
*    ROUTINE REGISTER 0 WILL CONTAIN THE LENGTH OF THE ADDRESS STRING*  04730020
*    AND REGISTER 1 WILL CONTAIN A POINTER TO THE BYTE FOLLOWING THE *  04740020
*    LAST ONE IN THE ADDRESS STRING.                                 *  04790020
*                                                                    *  05100020
* EXITS, NORMAL                                                      *  05160020
*                                                                    *  05220020
*         IKJPARS-ONE OF THE FOLLOWING RETURN CODES WILL BE PASSED   *  05270020
*    VIA REGISTER 15.                                                *  05280020
*    0   INDICATING TO CONTINUE PROCESSING THE COMMAND BUFFER        *  05330020
*    8   INDICATING IKJPARS SHOULD PROMPT WITH REENTER               *  05340020
*    12  INDICATING IKJPARS SHOULD RETURN TO IKJEGEQU WITH A         *  05390020
*    *   RETURN CODE OF 20.                                          *  05400020
*                                                                    *  05520020
*         IKJEGMNL-VIA REGISTER 14 WITH ONE OF THE FOLLOWING         *  05570020
*    RETURN CODES IN REGISTER 15-                                    *  05580020
*    0   NORMAL RETURN CODE                                          *  05630020
*    16  INDICATING AN ATTENTION INTERRUPT WAS ENCOUNTERED           *  05640020
*    *   DURING PROCESSING                                           *  05690020
*                                                                    *  05880020
* EXITS, ERROR                                                       *  05940020
*         IKJEGMNL-VIA REGISTER 14 WITH A RETURN CODE OF 20 IN       *  05990020
*    REGISTER 15 TO INDICATE THE STAE RETRY ROUTINE WAS ENTERED.     *  06000020
*                                                                    *  06120020
* TABLES/WORKAREAS                                                   *  06180020
*    THIS MODULE USES THE COMMON DSECT OF THE TEST PACKAGE-TCOMTAB.  *  06240020
*    THE WORKAREA IS LABELED AREAWORK AND CAN BE FOUND AT A          *  06300020
*    DISPLACEMENT OF X'40' FROM THE AREA POINTED TO BY WORKAREA IN   *  06360020
*    TCOMTAB.  THE PARAMETER CONTROL LIST FOR IKJPARS IS BUILT IN THE*  06420020
*    WORKAREA ALONG WITH SWITCHES USED BY THIS MODULE TO PROCESS.    *  06480020
*    TCOMTAB CONTAINS POINTERS TO THIS MODULE'S SAVEAREA, A POINTER  *  06540020
*    TO THE COMMAND BUFFER CONTAINING THE REQUEST, AND A POINTER TO  *  06600020
*    AN OUTPUT BUFFER.                                               *  06660020
*                                                                    *  06720020
* ATTRIBUTES                                                         *  06780020
*    REENTRANT, REFRESHABLE                                          *  06840020
*                                                                    *  06900020
* CHARACTER CODE DEPENDENCY                                          *  06960020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL           *  07020020
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT*  07080020
*    TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED *  07140020
*    SO THAT REDEFINITION OF CHARACTER CONSTANTS, BY REASSEMBLY,     *  07200020
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.        *  07260020
*                                                                    *  07320020
* NOTES                                                              *  07380020
*    ABBREVIATIONS COMMONLY USED IN THE COMMENTS BESIDE THE CODE-    *  07440020
*    1.   PDL-PARAMETER DESCRIPTOR LIST                              *  07500020
*    2.   PDE-PARAMETER DESCRIPTOR ENTRY                             *  07560020
*    3.   PCL-PARAMETER CONTROL LIST                                 *  07620020
*    COMMENTS GENERALLY START IN COLUMN 35.                          *  07670020
*    STAERTN IS THE ENTRY POINT FOR THE STAE RETRY ROUTINE AND IS    *  07672020
*    ENTERED FROM IKJEGSTA.                                          *  07674020
**********************************************************************  07680020
         EJECT                                                          07740020
** THE COMMENTS FOR THE FOLLOWING STATEMENTS START IN COLUMN 25.    **  07790020
R0       EQU    0       REGISTER 0                                      07800020
R1       EQU    1       REGISTER 1                                      07860020
R2       EQU    2       REGISTER 2                                      07920020
R5       EQU    5       REGISTER 5                                      07980020
R6       EQU    6       REGISTER 6                                      08040020
R7       EQU    7       REGISTER 7                                      08100020
R9       EQU    9       REGISTER 9                                      08160020
R12      EQU   12       REGISTER 12                                     08220020
R13      EQU   13       REGISTER 13                                     08280020
R14      EQU   14       REGISTER 14                                     08340020
R15      EQU   15       REGISTER 15                                     08400020
** THE FOLLOWING EQUATES ARE USED AS REGISTER NOTATION THROUGHOUT THE** 08460020
** MODULE.                                                           ** 08520020
PARMREG  EQU    1       USED TO PASS PARAMETERS TO OTHER MODULES        08580020
MSGREG   EQU    2       USED TO INDICATE MSG NUMBER TO BE OUTPUTTED     08640020
LASTENTR EQU    2       POINTS TO THE LAST ENTRY IN THE INCORE          08700020
*                       SYMBOL TABLE                                    08760020
WORKREG  EQU    3       GENERAL WORK REGISTER                           08820020
EVEN     EQU    4       USED AS AN EVEN REGISTER FOR MULTIPLICATION     08880020
STRNGPTR EQU    4       USED IN VALIDITY CHECK ROUTINE-PT TO VALUE      08940020
OUTBUFRG EQU    4       USED TO INDEX THROUGH OUTPUT BUFFER             09000020
ADDRBASE EQU    4       USED TO ADDRESS ADDRESS PDE AFTER RETURNING     09060020
*                       FROM IKJPARS                                    09120020
FSTMSG   EQU    5       USED TO ADDRESS FIRST LEVEL MESSAGE             09180020
SECNDMSG EQU    5       USED TO ADDRESS SECOND LEVEL MESSAGE            09240020
ODD      EQU    5       USED AS ODD REGISTER FOR MULTIPLICATION         09300020
ATTREG   EQU    6       USED TO ADDRESS THE ENTRY IN THE INCORE SYMBOL  09360020
*                       TABLE                                           09420020
DISPLREG EQU    7       USED TO DETERMINE WHAT CODE IS TO BE PROCESSED  09480020
*                       AFTER RETURNING FROM IKJEGIO                    09540020
WORKREG2 EQU    7       USED AS A GENERAL REGISTER                      09600020
PDLBASE  EQU    8       USED TO ADDR PDL AFTER RETURNING FROM IKJPARS   09660020
PDEPTR   EQU    8       USED TO ADDR THE PDE FROM PARSE IN THE VALIDITY 09720020
*                       CHECK ROUTINE                                   09780020
TABBASE  EQU    9       USED TO ADDRESS TCOMTAB                         09840020
WORKBASE EQU   10       USED TO ADDRESS WORKAREA                        09900020
BASEREG  EQU   11       BASE REGISTER FOR ADDRESSABILITY WITHIN CSECT   09960020
ENTRYREG EQU   12       USED TO ADDRESS NEW ENTRY IN INCORE SYMBOL      10020020
*                       TABLE                                           10080020
RETURN   EQU   14       CONTAINS ADDRESS OF NEXT SEQUENTIAL INST        10140020
RETCODE  EQU   15       USED FOR RETURNING RETURN CODES                 10200020
** THE FOLLOWING EQUATES ARE USED THROUGHOUT THE PROGRAM FOR LENGTHS,** 10260020
** AND DISPLACEMENTS IN INSTRUCTIONS.                                ** 10320020
L0       EQU    0       LENGTH OF 0                                     10380020
L1       EQU    1       LENGTH OF 1                                     10440020
L2       EQU    2       LENGTH OF 2                                     10500020
L3       EQU    3       LENGTH OF 3                                     10560020
L4       EQU    4       LENGTH OF 4                                     10620020
L5       EQU    5       LENGTH OF 5                                     10680020
L10      EQU   10       LENGTH OF 10                                    10740020
L16      EQU   16       LENGTH OF 16                                    10860020
L29      EQU   29       LENGTH OF 29                                    10920020
L35      EQU   35       LENGTH OF 35                                    10980020
D0       EQU    0       DISPLACEMENT OF 0                               11040020
D1       EQU    1       DISPLACEMENT OF 1                               11100020
D2       EQU    2       DISPLACEMENT OF 2                               11160020
D3       EQU    3       DISPLACEMENT OF 3                               11220020
D4       EQU    4       DISPLACEMENT OF 4                               11280020
D5       EQU    5       DISPLACEMENT OF 5                               11340020
D6       EQU    6       DISPLACEMENT OF 6                               11400020
D7       EQU    7       DISPLACEMENT OF 7                               11460020
D8       EQU    8       DISPLACEMENT OF 8                               11520020
D9       EQU    9       DISPLACEMENT OF 9                               11580020
D10      EQU   10       DISPLACEMENT OF 10                              11640020
D11      EQU   11       DISPLACEMENT OF 11                              11700020
D12      EQU   12       DISPLACEMENT OF 12                              11760020
D14      EQU   14       DISPLACEMENT OF 14                              11820020
D15      EQU   15       DISPLACEMENT OF 15                              11880020
D16      EQU   16       DISPLACEMENT OF 16                              11940020
D28      EQU   28       DISPLACEMENT OF 28                              12000020
D29      EQU   29       DISPLACEMENT OF 29                              12060020
D33      EQU   33       DISPLACEMENT OF 33                              12120020
D34      EQU   34       DISPLACEMENT OF 34                              12180020
D39      EQU   39       DISPLACEMENT OF 39                              12240020
D52      EQU   52       DISPLACEMENT OF 52                              12300020
D54      EQU   54       DISPLACEMENT OF 54                              12360020
D56      EQU   56       DISPLACEMENT OF 56                              12420020
D60      EQU   60       DISPLACEMENT OF 60                              12480020
D64      EQU   64       DISPLACEMENT OF 64                              12540020
D67      EQU   67       DISPLACEMENT OF 67                              12600020
D68      EQU   68       DISPLACEMENT OF 68                              12660020
D75      EQU   75       DISPLACEMENT OF 75                              12720020
FACTOR   EQU    3       USED TO CALCULATE MESSAGE DISPLACEMENT          12780020
ONE      EQU    1       NUMERICAL ONE                                   12840020
ONES     EQU    1       USED IN TM INSTRUCTION                          12900020
TWO      EQU    2       NUMERICAL TWO                                   12960020
EIGHT    EQU    8       NUMERICAL EIGHT                                 13020020
ZERO     EQU    0       NUMERICAL 0                                     13080020
TWELVE   EQU   12       NUMBER OF BYTES IN EACH ENTRY OF ATTRTAB        13140020
BLANK    EQU   C' '     BLANK                                           13200020
REGSMASK EQU   X'38'    USED TO TEST FLAG 4 OF ADDR PDE                 13260020
HEXZERO  EQU   X'00'    USED IN TESTING SWITCHES                        13320020
HEXONE   EQU   X'01'    USED IN TESTING SWITCHES                        13380020
HEXTWO   EQU   X'02'    USED IN TESTING SWITCHES                        13440020
HEXTHREE EQU   X'03'    SIGNIFIES TO STAE THAT A LINK FAILED            13500020
HEXFOUR  EQU   X'04'    USED IN TESTING SWITCHES                        13560020
HEXEIGHT EQU   X'08'    USED IN TESTING SWITCHES                        13620020
HEX14    EQU   X'14'    USED TO SET TYPE CHARACTER OF PDE               13680020
HEX80    EQU   X'80'    USED TO TEST FOR ADDRESS OF BINARY ADDR         13740020
HEXFB    EQU   X'FB'    USED TO SET ALLSW                               13800020
HEXFD    EQU   X'FD'    USED TO TURN CMMNDSW OFF                        13860020
HEXFE    EQU   X'FE'    USED TO TURN DUPLSW OR LOWSW OFF                13920020
HEXFF    EQU   X'FF'    SIGNIFIES END OF STAE ABEND TABLE               13980020
RET0     EQU    0       USED TO SET RETURN CODE                         14040020
RET8     EQU    8       USED TO SET RETURN CODE                         14100020
RET12    EQU   12       USED TO SET RETURN CODE                         14160020
RET16    EQU   16       USED TO SET RETURN CODE                         14220020
RET20    EQU   20       USED TO SET RETURN CODE                         14280020
MSG1     EQU    1       REPRESENTS MSGS IKJ57291I-A AND B               14400020
MSG2     EQU    2       REPRESENTS MSG IKJ57292I                        14460020
MSG3     EQU    3       REPRESENTS MSGS IKJ57293I-A AND B               14520020
MSG4     EQU    4       REPRESENTS MSGS IKJ57293I-A AND C               14580020
MSG7     EQU    7       REPRESENTS MSG IKJ57296I                        14640020
MSG8     EQU    8       REPRESENTS MSG IKJ57297I                        14700020
MSG9     EQU    9       REPRESENTS MSGS IKJ57298I-A AND B               14760020
         SPACE 3                                                        14830020
         ENTRY IKJEGDRP                                                 14840020
         SPACE 3                                                        14850020
** THE COMMENTS FOR THE FOLLOWING STATEMENTS START IN COLUMN 35.     ** 14870020
         SPACE                                                          14872020
         SAVE  (14,12),,*         SAVE REGISTERS                        14880020
         LR    BASEREG,R15        ESTABLISH ADDRESSABILITY FOR          14940020
         USING IKJEGEQU,BASEREG   THIS CSECT-BASEREG IS BASE            15000020
         USING TCOMTAB,TABBASE    USE TABBASE TO ADDR TCOMTAB           15060020
         L     WORKREG,WORKAREA   OBTAIN ADDR OF WORKAREA FROM TCOMTAB  15120020
         USING TSTCWORK,WORKREG   ESTABLISH ADDRESSABILITY TO ENTIRE    15180020
*                                 WORKAREA                              15240020
         LA    WORKBASE,CWORKCMD  GET ADDRESS OF IKJEGEQU'S             15300020
*                                 WORKAREA                              15360020
         USING AREAWORK,WORKBASE  USE WORKBASE TO ADDRESS WORKAREA      15420020
         DROP  WORKREG            DROP ADDRESSABILITY TO ENTIRE         15480020
*                                 WORKAREA                              15540020
         XC    PPLAREA(ENDWORK-PPLAREA),PPLAREA CLEAR WORKAREA          15600020
         B     PARS01C1           GO SET UP SAVEAREAS                   15660020
         DROP  BASEREG                                                  15720020
IKJEGDRP EQU   *                                                        15780020
         SAVE  (14,12),,*         SAVE REGISTERS                        15840020
         USING IKJEGDRP,R15       ESTABLISH ADDRESSABILITY              15900020
         L     BASEREG,BASE       GET ADDRESS OF BEGINNING OF PROGRAM   15960020
         DROP  R15                                                      16020020
         USING IKJEGEQU,BASEREG   BASEREG IS THE BASE REGISTER          16080020
         USING TCOMTAB,TABBASE    USE TABBASE TO ADDR TCOMTAB           16140020
         L     WORKREG,WORKAREA   OBTAIN ADDR OF WORKAREA FROM TCOMTAB  16200020
         USING TSTCWORK,WORKREG   ESTABLISH ADDRESSABILITY TO ENTIRE    16260020
*                                 WORKAREA                              16320020
         LA    WORKBASE,CWORKCMD  GET ADDRESS OF IKJEGDRP'S WORKAREA    16380020
         USING AREAWORK,WORKBASE  USE WORKBASE TO ADDRESS WORKAREA      16440020
         DROP WORKREG             DROP ADDRESSABILITY TO ENTIRE         16500020
*                                 WORKAREA                              16560020
         XC    PPLAREA(ENDWORK-PPLAREA),PPLAREA CLEAR WORKAREA          16620020
         OI    DROPSW,HEXTWO      INDICATE DROP FUNCTION REQUESTED      16680020
** THE FOLLOWING CODE SETS UP THE SAVEAREAS FOR THE EQUATE AND DROP  ** 16740020
** FUNCTIONS.                                                        ** 16800020
PARS01C1 EQU   *                                                        16860020
         MVC   LNGTWORK(L3),CHARZERO   INITIALIZE LENGTH TO CHARACTER   16920020
*                                 ZERO                                  16980020
         L     R15,REGSAVE2       GET ADDRESS OF SAVEAREA FROM          17040020
*                                 TCOMTAB                               17100020
         ST    R13,D4(R15)        STORE ADDRESS OF IKJEGMNL SAVEAREA    17160020
         ST    R15,D8(R13)        STORE ADDR OF OUR SAVEAREA            17220020
         LR    R13,R15            PUT ADDRESS OF OUR SAVEAREA INTO      17280020
*                                 REGISTER 13                           17340020
         STM   R14,R12,D12(R13)   SAVE OUR REGISTERS                    17400020
*********************************************************************   17460020
*                   ISSUE STAE FOR DROP AND EQUATE                  *   17520020
*********************************************************************   17580020
         LA    WORKREG,STATBL     GET ADDRESS OF STAE ABEND TABLE       17640020
         ST    WORKREG,ABENTAB1   SAVE THIS ADDRESS FOR STAE ROUTINE    17700020
         MVC   TSTRETRY+D1(L3),RETRYADR SAVE ADDRESS OF RETRY ROUTINE   17760020
         L     WORKREG,TSTSTAE    GET ADDR OF STAE EXIT ROUTINE         17820020
         LA    R15,STAEAREA       GET ADDR OF STAE WORKAREA             17880020
         MVC   D0(STAELEN,R15),STAELIST  MOVE STAE LIST FORM INTO       17940020
*                                 WORKAREA                              18000020
         STAE  (3),MF=(E,(15))    ISSUE STAE MACRO                      18060020
         LTR   R15,R15            IS RETURN CODE ZERO                   18120020
SMTSTAE  DS    0H                 SMT LABEL FOR TEST CASE TEQU5500      18170020
         BZ    PARS01F2           YES, CONTINUE PROCESSING              18180020
PARS01G1 EQU   *                                                        18240020
** STORAGE FOR STAE REQUEST WAS NOT AVAILABLE.  SET UP TO WRITE MSG  ** 18300020
         LA    MSGREG,MSG2        PREPARE TO WRITE MSG IKJ57292I        18360020
         B     MSG06A1            GO TO MESSAGE ROUTINE                 18420020
PARS01F2 EQU   *                                                        18470020
         TM    TSTFLGS3,NOPARMS   WERE PARAMETERS SPECIFIED             18472020
         BZ    PARS01A3           YES, GO TO PARSE                      18474020
         TM    DROPSW,HEXTWO      NO, CHECK FOR DROP COMMAND            18476020
         BO    SYM02A1            YES, SKIP GOING TO PARSE              18478020
PARS01A3 EQU   *                                                        18480020
** THIS CODE BUILDS THE PARAMETER LIST IN THE WORKAREA TO GO TO      ** 18540020
** IKJPARS TO SCAN AND VALIDITY CHECK THE PARAMETERS OF THE COMMAND  ** 18600020
** BUFFER.                                                           ** 18660020
         LR    WORKREG2,WORKBASE  ESTABLISH ADDRESSABILITY TO PARSE     18720020
         USING PPL,WORKREG2       PARAMETER LIST                        18780020
         MVC   PPLUPT(L4),TSTUPT  PUT ADDR UPT INTO PARAMETER LIST      18840020
         MVC   PPLECT(L4),TSTECT  PUT ADDR ECT INTO PARAMETER LIST      18900020
         MVC   PPLECB(L4),TSTCPECB PUT ADDR ECB INTO PARAMETER LIST     18960020
         TM    DROPSW,HEXTWO      IS THE REQUEST TO DELETE AN ENTRY     19020020
*                                 FROM THE IN CORE SYMBOL TABLE         19080020
         BZ    PARS01C3           NO, GO SET UP PCL FOR EQUATE          19140020
         MVC   PPLPCL(L4),PARSDROP YES, PUT ADDR OF DROP'S PCL INTO     19200020
*                                 PARAMETER LIST                        19260020
         B     PARS01D3           GO SET UP REST OF PARAMETER LIST      19320020
PARS01C3 EQU   *                                                        19380020
         MVC   PPLPCL(L4),PARSADDR PUT ADDR OF EQUATE'S PCL INTO        19440020
*                                 PARAMETER LIST                        19500020
PARS01D3 EQU   *                                                        19560020
         LA    WORKREG,TSTANSPL   GET ADDR OF ANSWER PLACE FOR IKJPARS  19620020
         ST    WORKREG,PPLANS     PUT ADDRESS INTO THE PCL FOR IKJPARS  19680020
         MVC   PPLCBUF(L4),INBUF  MOVE COMMAND BUFFER ADDRESS           19740020
*                                 INTO PARAMETER LIST                   19800020
         ST    R13,PPLUWA         PUT ADDR OF THIS MODULE'S SAVEAREA    19860020
*                                 INTO PARAMETER LIST                   19920020
         LR    PARMREG,WORKBASE   REG 1 POINTS TO PARAMETER LIST        19980020
         DROP  WORKREG2           DROP ADDRESSABILITY TO PARSE          20040020
*                                 PARAMETER LIST                        20100020
         LINK  EP=IKJPARS         GO TO IKJPARS                         20160020
PARSBLOW EQU   *                  LABEL USED BY STAE RETRY ROUTINE      20220020
SMTPARS  DS    0H                 SMT LABEL FOR TEST CASES TEQU4900     20270020
*                                 AND TDRP1600                          20272020
** THE FOLLOWING BRANCH TABLE IS USED TO DETERMINE ACTION TO BE      ** 20280020
** TAKEN AFTER RETURNING FROM IKJPARS DEPENDENT ON THE RETURN CODE   ** 20340020
** FROM IKJPARS IN REGISTER 15.                                      ** 20400020
         B     PARS01F3(RETCODE)  BRANCH TO TABLE INDEXED BY CONTENTS   20460020
*                                 OF REGISTER 15                        20520020
PARS01F3 EQU   *                                                        20580020
         B     SYM02A1            0 - CONTINUE PROCESSING               20640020
         B     EXIT05G5           4 - RETURN TO IKJEGMNL                20700020
         B     ATTN05H4           8 - ATTENTION ENCOUNTERED             20760020
         B     PARS01J4           12 - GO WRITE ERROR MESSAGE           20820020
         B     PARS01G1           16 - GO WRITE ERROR MESSAGE           20880020
         B     EXIT05E2           20 - GO HANDLE SERVICE RTN CODE       20940020
PARS01J4 EQU   *                                                        21480020
         TM    DROPSW,HEXTWO      WAS DROP FUNCTION REQUESTED           21540020
         BZ    PARS01K4           NO, GO WRITE MESSAGE FOR EQUATE       21600020
         LA    MSGREG,MSG9        PREPARE TO WRITE MSG IKJ57298I        21660020
         B     MSG06A1            GO WRITE MESSAGE                      21720020
PARS01K4 EQU   *                                                        21780020
         LA    MSGREG,MSG1        PREPARE TO WRITE MSG IKJ57291I        21840020
         B     MSG06A1            GO WRITE MESSAGE                      21900020
SYM02A1  EQU   *                                                        21960020
** THE FOLLOWING CODE GETS THE LOAD ADDRESS OF THE SYMBOL FROM THE   ** 22020020
** PARAMETER DESCRIPTOR LIST (PDL) BUILT BY IKJPARS.  IT CHECKS TO   ** 22080020
** SEE IF THE ADDRESS IS ALREADY IN THE IN CORE SYMBOL TABLE.  THE   ** 22140020
** ADDRESS OF THE PDL IS FOUND IN TSTANSPL IN TCOMTAB                ** 22200020
         L     PDLBASE,TSTANSPL   OBTAIN ADDR OF PDL                    22260020
         L     WORKREG2,D8(PDLBASE)  GET ADDRESS OF SYMBOL              22320020
         L     WORKREG,SYMTABLE   GET ADDRESS OF SYMBOL TABLE           22380020
         LA    LASTENTR,SYMTABLE  OBTAIN ADDR OF LAST ENTRY             22440020
         TM    DROPSW,HEXTWO      WAS DROP FUNCTION REQUESTED           22500020
         BC    ONES,DROP09A1      YES, GO HANDLE REQUEST                22560020
         LA    ADDRBASE,D16(PDLBASE) NO, GET ADDRESS OF ADDRESS PDE     22620020
         USING IKJPARMA,ADDRBASE  ADDRBASE ADDRESSES ADDRESS PDE        22680020
         TM    PDEUSER,HEX80      IS LOAD ADDR OF SYMBOL IN PDL         22740020
         BZ    SYM02D2A           YES, PICK ADDRESS UP AND TEST FOR     22800020
*                                 SYMBOL TABLE                          22860020
** THIS CODE PICKS THE LOAD ADDRESS UP FROM THE SYM INFO BLOCK       ** 22920020
** POINTED TO BY THE LAST WORD IN THE ADDRESS PDE.                   ** 22980020
         L     R5,PDEUSER         NO, GET ADDRESS OF SI BLOCK           23040020
         L     R5,D0(R5)          GET LOAD ADDRESS OF SYMBOL            23100020
         B     SYM02D2            GO SEE IF SYMBOL TABLE EXIST          23160020
SYM02D2A EQU   *                                                        23220020
         L     R5,PDEUSER         GET ADDRESS OF SYMBOL FROM PDL        23280020
SYM02D2  EQU   *                                                        23340020
         LTR   WORKREG,WORKREG    ARE THERE ANY ENTRIES IN THE IN CORE  23400020
*                                 SYMBOL TABLE                          23460020
         BZ    SYM02E3            NO, GO SET UP FOR GETMAIN             23520020
SYM02D3  EQU   *                                                        23580020
** THIS CODE CHECKS TO SEE IF THE LENGTH OF THE NEW SYMBOL IS THE    ** 23640020
** SAME AS THE LENGTH OF ANY SYMBOL ALREADY IN THE IN CORE SYMBOL    ** 23700020
** TABLE.                                                            ** 23760020
         CLC   D12(L2,PDLBASE),D14(WORKREG) ARE LENGTHS THE SAME        23820020
         BE    SYM02D3A           YES, GO SEE IF SYMBOLS ARE SAME       23880020
SYM02D3B EQU   *                                                        23940020
** THIS CODE IS ENTERED FROM SYM02D3A AND IS RESPONSIBLE FOR SETTING ** 24000020
** UP TO CHECK THE NEXT ENTRY IN THE TABLE FOR DUPLICATE SYMBOLS     ** 24060020
         LR    LASTENTR,WORKREG   NO, SAVE ADDR OF LAST ENTRY SCANNED   24120020
         L     WORKREG,D0(WORKREG) GET ADDRESS OF NEXT ENTRY            24180020
         LTR   WORKREG,WORKREG    WAS THERE ANOTHER ENTRY               24240020
         BNZ   SYM02D3            YES, CONTINUE SEARCH FOR SYMBOL       24300020
SYM02E3  EQU   *                                                        24360020
** THIS CODE CALCULATES THE LENGTH OF THE ENTRY                      ** 24420020
         XR    R1,R1              CLEAR A REGISTER                      24480020
         LH    R1,D12(PDLBASE)    OBTAIN LENGTH OF SYMBOL               24540020
SMTGET01 DS    0H                 SMT LABEL FOR TESTCASE TEQU5600 -     24590020
*                                 THIS LABEL MUST COME BEFORE THE LAST  24592020
*                                 MODIFICATION OF REGISTER 1 WHEN       24594020
*                                 ISSUING THE GETMAIN.                  24598020
         LA    R1,D16(R1)         ADD 16 TO IT FOR ENTRY SIZE           24600020
         LR    R0,R1              PUT LENGTH INTO REGISTER 0            24660020
SYM02F3  EQU   *                                                        24720020
** THIS CODE GETS THE MAIN STORAGE FOR THE TABLE ENTRY               ** 24780020
         O     R0,POOLONE         PUT SUBPOOL NUMBER INTO HIGH ORDER    24840020
*                                 BYTE OF REGISTER 0                    24900020
         GETMAIN  R,LV=(0)        ISSUE GETMAIN                         24960020
SYM02G3  EQU   *                  LABEL FOR STAE RETRY ROUTINE          25020020
         LR    ENTRYREG,R1        SAVE ADDRESS OF GETMAIN AREA          25080020
         USING ENTRY,ENTRYREG     USE ENTRYREG TO ADDRESS TABLE ENTRY   25140020
         XC    D0(L16,ENTRYREG),D0(ENTRYREG) CLEAR 16 BYTES OF ENTRY    25200020
         ST    R5,ADDRSYM         PUT LOAD ADDRESS OF SYMBOL INTO ENTRY 25260020
         XR    R6,R6              CLEAR A REGISTER                      25320020
         LH    R6,D12(PDLBASE)    GET LENGTH OF SYMBOL                  25380020
         STH   R6,SYMLNGTH        PUT LENGTH OF SYMBOL INTO TABLE ENTRY 25440020
         BCTR  R6,ZERO            TAKE ONE FROM LENGTH OF SYMBOL        25500020
         EX    R6,SYM02G3A        GO MOVE SYMBOL INTO ENTRY OF TABLE    25560020
         ST    ENTRYREG,D0(LASTENTR) PUT ADDRESS OF NEW ENTRY INTO      25620020
*                                 FIRST WORD OF PREVIOUS ENTRY          25680020
         B     TYPE03A1           GO GET TYPE ATTRIBUTE                 25740020
SYM02G3A MVC   D16(L0,ENTRYREG),D0(WORKREG2) MOVE SYMBOL INTO ENTRY     25800020
SYM02D3D CLC   D0(L0,WORKREG2),D16(WORKREG)  ARE THE SYMBOLS THE SAME   25860020
SYM02D3A EQU   *                                                        25920020
         XR    R6,R6              CLEAR A REGISTER                      25980020
         LH    R6,D12(PDLBASE)    PUT LENGTH OF SYMBOL IN A REGISTER    26040020
         BCTR  R6,ZERO            SUBTRACT ONE FROM LENGTH OF SYMBOL    26100020
         EX    R6,SYM02D3D        GO CHECK TO SEE IF SYMBOLS ARE SAME   26160020
         BNE   SYM02D3B           NO, CONTINUE SEARCHING ENTRIES        26220020
SYM02D4  EQU   *                                                        26280020
         LR    ENTRYREG,WORKREG   PUT ADDRESS OF ENTRY INTO REGISTER    26400020
         USING ENTRY,ENTRYREG     ENTRYREG ADDRESSES TABLE ENTRY        26460020
         L     R6,ADDRSYM         GET EXISTING LOAD ADDRESS             26510020
         CR    R5,R6              WAS SAME LOAD ADDRESS SPECIFIED       26512020
         BNE   SYM02E4            NO, SAVE ADDRESS SPECIFIED            26514020
         OI    DUPLSW,HEXONE      YES, INDICATE ENTRY ALREADY EXISTS    26516020
         B     TYPE03A1           GO GET TYPE ATTRIBUTE                 26518020
SYM02E4  EQU   *                                                        26518420
         ST    R5,ADDRSYM         PUT LOAD ADDRESS OF SYMBOL INTO TABLE 26520020
TYPE03A1 EQU   *                                                        26580020
** THIS CODE PUTS THE TYPE ATTRIBUTE INTO THE IN CORE SYMBOL TABLE IF** 26640020
** AN ENTRY DOES NOT ALREADY EXISTS AND OVERRIDES THE TYPE FIELD IF  ** 26700020
** THE ENTRY FOR THIS LOAD ADDRESS ALREADY EXISTS.                   ** 26760020
         XR    WORKREG2,WORKREG2  CLEAR A REGISTER                      26820020
         LH    WORKREG2,D52(PDLBASE)    OBTAIN TYPE SPECIFIED FROM      26880020
*                                 TYPE KEYWORD INDICATOR FIELD IN PDL   26940020
         DROP  ADDRBASE           DROP ADDRESSABILITY TO ADDR PDE       27000020
         LA    ATTREG,ATTRTAB     OBTAIN ADDRESS OF BEGINNING OF        27060020
*                                 ATTRIBUTE TABLE                       27120020
         LTR   WORKREG2,WORKREG2  WAS TYPE SPECIFIED                    27180020
         BNZ   TYPE03B2           YES, GO FIGURE TABLE DISPLACEMENT     27240020
         TM    DUPLSW,HEXONE      NO, DID ENTRY ALREADY EXIST           27300020
         BC    ONES,LNG04A1A      YES, GO GET LENGTH ATTRIBUTE          27360020
         LA    WORKREG2,TWO       NO, DEFAULT TYPE TO HEX               27420020
TYPE03B2 EQU   *                                                        27480020
** THIS CODE FIGURES THE DISPLACEMENT NEEDED INTO THE ATTRIBUTE      ** 27540020
** TABLE THAT IS USED TO ASSURE THE ATTRIBUTES ARE SPECIFIED         ** 27600020
** CORRECTLY.  THE PDL CONTAINS A FIELD WHICH CONTAINS A NUMBER AND  ** 27660020
** THAT NUMBER MULTIPLIED BY A FACTOR IS USED AS AN INDEX TO         ** 27720020
** DETERMINE THE TYPE SPECIFIED.                                     ** 27780020
         LR    EVEN,WORKREG2      PUT INDEX FACTOR INTO A REGISTER      27840020
         LA    ODD,TWELVE         PUT NUMBER OF BYTES IN EACH TABLE     27900020
*                                 ENTRY OF ATTRTAB INTO A REGISTER      27960020
         MR    EVEN,EVEN          MULTIPLY THE INDEX FACTOR BY          28020020
*                                 THE NUMBER OF BYTES IN EACH ENTRY     28080020
*                                 TO GET THE CORRECT DISPLACEMENT       28140020
*                                 INTO THE ATTRIBUTE TABLE              28200020
         AR    ATTREG,ODD         ADD THE START OF THE TABLE TO         28260020
*                                 THE DISPLACEMENT TO FIND THE          28320020
*                                 LIST IN USE                           28380020
         LA    ODD,TWELVE                                               28440020
         SR    ATTREG,ODD         PLACE POINTER TO BEGINNING OF LIST    28500020
         TM    DUPLSW,HEXONE      DOES AN ENTRY ALREADY EXIST           28560020
         BC    ONES,TYPE03B4      YES, GO CHECK FOR SAME TYPE           28620020
         MVC   ATTRTYPE(L1),D0(ATTREG)  NO, MOVE THE TYPE FIELD INTO    28680020
*                                 ENTRY OF IN CORE SYMBOL TABLE         28740020
         B     LNG04A1            GO GET LENGTH ATTRIBUTE               28800020
TYPE03B4 EQU   *                                                        28860020
** THIS CODE TESTS TO SEE IF THE SAME TYPE ATTRIBUTE WAS GIVEN FOR   ** 28920020
** THE NEW ENTRY AS THE OLD.                                         ** 28980020
         CLC   D8(L1,WORKREG),D0(ATTREG)  ARE THE TYPES THE SAME        29040020
         BE    LNG04A1            YES, GO GET LENGTH ATTRIBUTE          29100020
         XC    ATTRTYPE(ATTRLNTH-ATTRTYPE),ATTRTYPE  NO-CLEAR OLD ENTRY 29160020
*                                 OUT                                   29220020
         MVC   D8(L1,WORKREG),D0(ATTREG) MOVE TYPE ATTRIBUTE            29280020
*                                 INTO TABLE                            29340020
         NI    DUPLSW,HEXFE       TURN DUPLICATE ENTRY SWITCH OFF       29400020
         B     LNG04A1            GO GET LENGTH ATTRIBUTE               29460020
LNG04A1A EQU   *                                                        29520020
** THIS CODE IS RESPONSIBLE FOR FINDING THE CORRECT ENTRY IN ATTRTAB ** 29580020
** THAT DESCRIBES THIS TYPE ATTRIBUTE.                               ** 29640020
         CLC   D0(L1,ATTREG),ATTRTYPE ENTRIES CORRESPOND                29700020
         BE    LNG04A1            YES, CONTINUE PROCESSING              29760020
         LA    ATTREG,TWELVE(ATTREG) NO, GO TO NEXT ENTRY IN ATTRTAB    29820020
         B     LNG04A1A           GO CHECK THIS ENTRY                   29880020
LNG04A1  EQU   *                                                        29940020
** THE FOLLOWING CODE IS RESPONSIBLE FOR PUTTING THE LENGTH ATTRIBUTE** 30000020
** INTO THE IN CORE SYMBOL TABLE.  IF DEALING WITH A NEW ENTRY AND   ** 30060020
** THE LENGTH WAS NOT SPECIFIED THE DEFAULT WILL BE ONE.  IF THE NEW ** 30110020
** ENTRY IS OVERRIDING AN EXISTING ENTRY THE DEFAULT WILL BE THAT OF ** 30112020
** THE OLD ENTRY.                                                    ** 30114020
         XR    R5,R5              CLEAR A REGISTER                      30300020
         LH    R5,D54(PDLBASE)    OBTAIN LENGTH ATTRIBUTE INDICATOR     30360020
*                                 FROM PDL                              30420020
         LTR   R5,R5              WAS LENGTH ATTRIBUTE SPECIFIED        30480020
         BNZ   LNG04A2            YES, GO CHECK VALUE                   30540020
** THIS CODE DETERMINES IF THE ENTRY OVERLAID AN EXISTING ENTRY.     ** 30600020
         TM    DUPLSW,HEXONE      IS THIS A NEW ENTRY                   30780020
         BNZ   MULT05A1           NO, GO GET MULTIPLICITY ATTRIBUTE     30840020
** THIS CODE IS EXECUTED IF THE LENGTH ATTRIBUTE WAS NOT SPECIFIED.  ** 30960020
         MVC   ATTRLNTH+D1(L1),D7(ATTREG)  PUT LENGTH INTO TABLE        31140020
         B     MULT05A1           GO GET MULTIPLICITY ATTRIBUTE         31200020
LNG04A2  EQU   *                                                        31260020
         XR    R5,R5              CLEAR A REGISTER                      31320020
         LH    R5,D64(PDLBASE)    OBTAIN THE NUMBER OF BYTES SPECIFIED  31380020
*                                 IN THE LENGTH ATTRIBUTE               31440020
         L     R7,D60(PDLBASE)    OBTAIN ADDR OF CHAR STRING            31500020
         SLL   R5,TWO             MULTIPLY NUMBER OF BYTES OF LENGTH    31560020
*                                 ATTR BY 4 IN ORDER TO USE THE         31620020
*                                 FOLLOWING BRANCH TABLE                31680020
TABLE    EQU   *                                                        31740020
         B     TABLE(R5)          BRANCH INTO TABLE INDEXED BY THE      31800020
*                                 THE CONTENTS OF R5                    31860020
         B     LNGONE             BRANCH TO HANDLE ONE BYTE             31920020
         B     LNGTWO             BRANCH TO HANDLE TWO BYTES            31980020
         B     LNGTHREE           BRANCH TO HANDLE THREE BYTES          32040020
LNGONE   EQU   *                                                        32100020
** THIS CODE HANDLES THE CASE OF THE LENGTH ATTRIBUTE BEING ONE BYTE ** 32160020
         MVC   LNGTWORK+D2(L1),D0(R7)   PUT SPECIFIED LENGTH INTO       32220020
*                                 WORKAREA                              32280020
         B     LNGTEST            GO TEST VALUE                         32340020
LNGTWO   EQU   *                                                        32400020
** THIS CODE HANDLES THE CASE OF THE LENGTH ATTRIBUTE BEING TWO BYTES** 32460020
         MVC   LNGTWORK+D1(L2),D0(R7)  PUT SPECIFIED LENGTH INTO        32520020
*                                 WORKAREA                              32580020
         B     LNGTEST            GO TEST VALUE                         32640020
LNGTHREE EQU   *                                                        32700020
** THIS CODE HANDLES THE CASE OF THE LENGTH ATTRIBUTE BEING THREE    ** 32760020
** BYTES.                                                            ** 32820020
         MVC   LNGTWORK(L3),D0(R7) PUT SPECIFIED LENGTH INTO WORKAREA   32880020
LNGTEST  EQU   *                                                        32940020
         CLC   LNGTWORK(L3),D1(ATTREG)  TEST TO SEE IF VALUE SPECIFIED  33000020
*                                 IS LESS THAN MINIMUN VALUE ALLOWED    33060020
         BL    LNG04A3            YES, TAKE DEFAULT AND WRITE MESSAGE   33120020
         CLC   LNGTWORK(L3),D4(ATTREG) TEST TO SEE IF VALUE SPECIFIED   33180020
*                                 IS GREATER THAN MAXIMUN VALUE         33240020
*                                 ALLOWED                               33300020
         BH    LNG04B3            YES, TAKE DEFAULT AND WRITE MESSAGE   33360020
         MVI   D67(PDLBASE),HEX14 NO, SET TYPE CHARACTER OF PDE         33420020
LNG04C2  EQU   *                                                        33480020
** THIS ROUTINE SETS UP THE PARAMETERS TO GO TO IKJEGCVT FOR VALUE   ** 33540020
** CONVERSION TO BINARY.  REG 1 IS POSITIVE TO INDICATE VALUE        ** 33600020
** CONVERSION AND CONTAINS THE ADDRESS OF THE PDE.                   ** 33660020
         LA    PARMREG,D60(PDLBASE) PUT ADDR OF LENGTH PDE INTO REG 1   33720020
LNG04D2  EQU   *                                                        33780020
** ENTRY POINT FOR OTHER ROUTINES NEEDING TO GO TO CONVERT FOR VALUE ** 33840020
** CONVERSION.                                                       ** 33900020
         XR    R0,R0              CLEAR REG 0 TO INDICATE BINARY        33960020
*                                 CONVERSION                            34020020
         L     R15,TSTCONVT       OBTAIN ADDR OF IKJEGCVT FROM TCOMTAB  34080020
         BALR  RETURN,R15         GO TO CONVERT ROUTINE                 34140020
         LTR   R15,R15            IS RETURN CODE FROM IKJEGCVT 0        34200020
         BZ    LNG04F3            YES, CONTINUE PROCESSING              34260020
         BNZ   EXIT05F2           NO, GO TO CHECK SERVICE RTN RETURN    34320020
*                                 CODE                                  34380020
LNG04B3  EQU   *                                                        34440020
         LA    MSGREG,MSG4        PREPARE TO WRITE MSG IKJ57293I        34500020
         B     LNG04A3A           GO GET MESSAGE                        34560020
LNG04A3  EQU   *                                                        34620020
         LA    MSGREG,MSG3        PREPARE TO WRITE MSG IKJ57293I        34680020
         OI    LOWSW,HEXONE       INDICATE VALUE SPECIFIED WAS TOO LOW  34740020
LNG04A3A EQU   *                                                        34800020
** THIS CODE IS EXECUTED IF THE LENGTH ATTRIBUTE WAS INCORRECT.  THE ** 34860020
** DEFAULT VALUE WILL BE SUBSTITUTED AND THE USER WILL BE INFORMED.  ** 34920020
         MVC   ATTRLNTH+D1(L1),D7(ATTREG) MOVE THE LENGTH ATTRIBUTE     34980020
*                                 INTO THE TABLE                        35040020
         LA    R14,LNG4A3A1       GET ADDRESS OF CONTINUING CODE        35100020
BLDMSG   EQU   *                                                        35160020
** THIS CODE DOES THE INITIAL WORK OF FINDING THE APPROPRIATE MESSAGE** 35220020
** AND SETTING UP THE CORRECT POINTERS TO THE WORK BUFFERS WHEN A    ** 35280020
** MESSAGE HAS TO BE BUILT.  REGISTER 14 WILL CONTAIN THE ADDRESS OF ** 35340020
** THE ROUTINE CONTROL SHOULD BE GIVEN BACK TO.                      ** 35400020
LNG4A3A  EQU   *                                                        35460020
         L     OUTBUFRG,OUTBUF    OBTAIN ADDR OF OUTPUT BUFFER          35520020
*                                 FROM TCOMTAB                          35580020
         ST    OUTBUFRG,ADDRONE   SAVE ADDRESS OF FIRST BUFFER          35640020
         L     WORKREG,ADDRMSGS   OBTAIN ADDR OF MESSAGE CSECT          35700020
         SLA   MSGREG,FACTOR      CALCULATE MSG DISPLACEMENT            35760020
         AR    MSGREG,WORKREG     ADDR OF MSGS=ADDR OF CSECT            35820020
*                                 PLUS DISPLACEMENT                     35880020
         LA    WORKREG,EIGHT                                            35940020
         SR    MSGREG,WORKREG     GO BACK EIGHT FOR PROPER MESSAGE      36000020
         XR    R7,R7              CLEAR A REGISTER                      36060020
         L     FSTMSG,D0(MSGREG)  OBTAIN ADDR OF FIRST MSG              36120020
         LH    R7,D0(FSTMSG)      PUT LENGTH OF MSG INTO THAT REGISTER  36180020
         XC    D0(L4,OUTBUFRG),D0(OUTBUFRG) CLEAR FIRST 4 BYTES OF      36240020
*                                 OUTBUF                                36300020
         LA    OUTBUFRG,D4(OUTBUFRG)  OUTBUFRG POINTS TO FIRST MESSAGE  36360020
*                                 AREA                                  36420020
         BR    R14                RETURN TO CALLING ROUTINE             36480020
LNG4A3A2 MVC   D0(L0,OUTBUFRG),SYMBOL MOVE SYMBOL INTO MESSAGE          36540020
LNG4A3A1 EQU   *                                                        36600020
** THIS CODE HANDLES THE BUILDING OF MESSAGE IKJ57293I               ** 36660020
         MVC   D0(L29,OUTBUFRG),D4(FSTMSG) MOVE FIRST PART OF MSG       36720020
*                                 IKJ57293I INTO OUTPUT BUFFER          36780020
         LA    OUTBUFRG,D29(OUTBUFRG)  UPDATE PT TO NEXT PART OF MSG    36840020
         LA    FSTMSG,D33(FSTMSG) GET ADDR OF SECOND PART OF MSG        36900020
         XR    WORKREG,WORKREG    CLEAR A REGISTER                      36960020
         LH    WORKREG,SYMLNGTH   GET LENGTH OF SYMBOL                  37020020
         AR    R7,WORKREG         CALCULATE LENGTH OF MSG TO INCLUDE    37080020
*                                 SYMBOL PORTION                        37140020
         BCTR  WORKREG,ZERO       TAKE ONE FROM LENGTH OF SYMBOL        37200020
         EX    WORKREG,LNG4A3A2   MOVE SYMBOL INTO MESSAGE              37260020
         LA    WORKREG,D1(WORKREG) UPDATE POINTER TO NEXT AVAILABLE     37320020
         AR    OUTBUFRG,WORKREG   POSITION IN BUFFER                    37380020
LNG04A3C EQU   *                                                        37440020
** THIS CODE HANDLES THE SECOND PART OF THE FIRST MESSAGE            ** 37500020
         MVC   D0(L16,OUTBUFRG),D0(FSTMSG)  MOVE 2ND PART OF FIRST      37560020
*                                 MESSAGE INTO BUFFER                   37620020
         LA    OUTBUFRG,D15(OUTBUFRG)  UPDATE OUTBUF POINTER TO NEXT    37680020
*                                 AVAILABLE POSITION OF THE MESSAGE     37740020
         CLC   D10(L1,ATTREG),CHARZERO IS LENGTH TWO CHARACTERS         37800020
         BNE   LNG04A3D           YES, GO HANDLE TWO CHARACTERS         37860020
         MVC   D0(L1,OUTBUFRG),D11(ATTREG) NO, MOVE LENGTH FIELD INTO   37920020
*                                 MESSAGE                               37980020
         LA    OUTBUFRG,D1(OUTBUFRG) UPDATE OUTBUF PT FOR PLACEMENT     38040020
*                                 OF PLUS SIGN                          38100020
         B     LNG04A3E           GO GET THE SECOND LEVEL MESSAGE       38160020
LNG04A3D EQU   *                                                        38220020
** THIS CODE HANDLES THE CASE OF THE LENGTH FIELD OF THE MESSAGE     ** 38280020
** TAKING TWO BYTES.                                                 ** 38340020
         LA    R7,D1(R7)          INCREMENT LENGTH OF MSG BY 1          38400020
         MVC   D0(L2,OUTBUFRG),D10(ATTREG) MOVE LENGTH FIELD INTO       38460020
*                                 MESSAGE                               38520020
         LA    OUTBUFRG,D2(OUTBUFRG)  UPDATE OUTBUF PT FOR PLACEMENT    38580020
*                                 OF PLUS SIGN                          38640020
LNG04A3E EQU   *                                                        38700020
** THIS CODE IS RESPONSIBLE FOR PUTTING THE SECOND LEVEL MESSAGE     ** 38760020
** INTO THE OUTPUT BUFFER.                                           ** 38820020
         MVI   D0(OUTBUFRG),PLUSSIGN  INDICATE 2ND LEVEL MESSAGE EXISTS 38880020
         LA    OUTBUFRG,D1(OUTBUFRG)  UPDATE OUTBUF PT FOR PLACEMENT    38940020
*                                 OF NEXT MESSAGE                       39000020
         LA    R7,D1(R7)          INCREMENT LENGTH OF MESSAGE BY 1      39060020
         L     FSTMSG,ADDRONE     OBTAIN ADDR OF BEGINNING OF OUTBUF    39120020
         STH   R7,D0(FSTMSG)      STORE LENGTH OF MESSAGE INTO 1ST      39180020
*                                 HALFWORD OF 1ST MESSAGE               39240020
LNG04A3J EQU   *                                                        39300020
         EX    OUTBUFRG,LNG04A3K  TEST TO SEE IF OUTBUFRG POINTS TO     39360020
*                                 A FULLWORD BOUNDARY                   39420020
         BC    EIGHT,LNG04A3L     YES, CONTINUE PROCESSING              39480020
         LA    OUTBUFRG,D1(OUTBUFRG) NO, GO TO NEXT BYTE                39540020
         B     LNG04A3J           GO TEST BOUNDARY AGAIN                39600020
LNG04A3K EQU   *                                                        39660020
         TM    FULLWORD,HEXZERO   OUTBUFRG ON FULLWORD BOUNDARY         39720020
LNG04A3L EQU   *                                                        39780020
         ST    OUTBUFRG,ADDRTWO   SAVE ADDRESS OF SECOND LEVEL MESSAGE  39840020
         XC    D0(L4,OUTBUFRG),D0(OUTBUFRG) ZERO 1ST 4 BYTES            39900020
*                                 OF SECOND LEVEL MESSAGE               39960020
         LA    OUTBUFRG,D4(OUTBUFRG) UPDATE BUFFER POINTER TO 2ND       40020020
*                                 MESSAGE LOCATION                      40080020
         L     SECNDMSG,D4(MSGREG) OBTAIN ADDR OF SECOND MESSAGE        40140020
         XR    R7,R7              CLEAR A REGISTER                      40200020
         LH    R7,D0(SECNDMSG)    OBTAIN LENGTH OF SECOND MESSAGE       40260020
         MVC   D0(L35,OUTBUFRG),D4(SECNDMSG)  PUT 1ST PART OF 2ND MSG   40320020
*                                 INTO OUTPUT BUFFER                    40380020
         LA    OUTBUFRG,D34(OUTBUFRG) UPDATE BUFFER PT TO TYPE FIELD    40440020
*                                 OF MSG                                40500020
         LA    SECNDMSG,D39(SECNDMSG) UPDATE POINTER TO 2ND PART OF     40560020
*                                 MESSAGE                               40620020
         CLI   D8(ATTREG),BLANK   IS TYPE ONE CHARACTER                 40680020
         BE    LNG04A3F           YES, GO HANDLE ONE CHARACTER          40740020
** THIS CODE HANDLES THE MOVE OF A TYPE FIELD OF TWO BYTES INTO THE  ** 40800020
** MESSAGE.                                                          ** 40860020
         LA    R7,D1(R7)          ADD ONE TO LENGTH OF MESSAGE          40920020
         MVC   D0(L2,OUTBUFRG),D8(ATTREG) MOVE TYPE INTO MESSAGE        40980020
         LA    OUTBUFRG,D2(OUTBUFRG) UPDATE PT TO NEXT AVAILABLE        41040020
*                                 POSITION                              41100020
         B     LNG04A3G           GO GET SECOND PART                    41160020
LNG04A3F EQU   *                                                        41220020
** THIS CODE HANDLES THE MOVE OF A ONE BYTE TYPE FIELD INTO THE      ** 41280020
** MESSAGE.                                                          ** 41340020
         MVC   D0(L1,OUTBUFRG),D9(ATTREG) MOVE TYPE FIELD INTO          41400020
*                                 MESSAGE                               41460020
         LA    OUTBUFRG,D1(OUTBUFRG) UPDATE PT TO NEXT AVAILABLE        41520020
*                                 POSITION                              41580020
LNG04A3G EQU   *                                                        41640020
** THIS CODE IS RESPONSIBLE FOR HANDLING THE SECOND PART OF THE      ** 41700020
** SECOND LEVEL MESSAGE.                                             ** 41760020
         MVC   D0(L5,OUTBUFRG),D0(SECNDMSG) MOVE 2ND PART OF MSG INTO   41820020
*                                 OUTPUT BUFFER                         41880020
         LA    OUTBUFRG,D4(OUTBUFRG) UPDATE OUTBUF PT TO LENGTH FIELD   41940020
         TM    LOWSW,HEXONE       WAS VALUE SPECIFIED TOO LOW           42000020
         BC    ONES,LNG04A3M      YES, GO PICK UP LOWEST VALUE ALLOWED  42060020
**THIS CODE HANDLES PUTTING THE HIGHEST VALUE ALLOWED INTO THE       ** 42120020
**MESSAGE.                                                           ** 42180020
         CLC   D4(L2,ATTREG),CHARZERO IS LENGTH FIELD ONE BYTE          42240020
         BE    LNG04A3H           YES, GO HANDLE ONE BYTE               42300020
**THIS CODE HANDLES THE CASE OF MOVING TWO BYTES                     ** 42360020
         LA    R7,D1(R7)          NO, ADD ONE TO LENGTH OF MESSAGE      42420020
         MVC   D0(L2,OUTBUFRG),D5(ATTREG) MOVE LENGTH INTO MESSAGE      42480020
         B     LNG04A3I           GO PREPARE TO WRITE MESSAGE           42540020
LNG04A3H EQU   *                                                        42600020
**THIS CODE HANDLES THE CASE OF MOVING A LENGTH FIELD OF ONE BYTE    ** 42660020
         MVC   D0(L1,OUTBUFRG),D6(ATTREG) MOVE LENGTH INTO MESSAGE      42720020
         B     LNG04A3I           GO PREPARE TO WRITE MESSAGE           42780020
LNG04A3M EQU   *                                                        42840020
** THIS CODE HANDLES PUTTING THE LOWEST VALUE ALLOWED INTO THE       ** 42900020
** MESSAGE.                                                          ** 42960020
         NI    LOWSW,HEXFE        TURN VALUE SWITCH OFF                 43020020
         CLC   D1(L2,ATTREG),CHARZERO IS LENGTH FIELD ONE BYTE          43080020
         BE    LNG04A3N           YES, GO HANDLE ONE BYTE               43140020
** THIS CODE HANDLES THE CASE OF MOVING TWO BYTES                    ** 43200020
         LA    R7,D1(R7)          NO, ADD ONE TO LENGTH OF MESSAGE      43260020
         MVC   D0(L2,OUTBUFRG),D2(ATTREG) MOVE LENGTH INTO MESSAGE      43320020
         B     LNG04A3I           GO PREPARE TO WRITE MESSAGE           43380020
LNG04A3N EQU   *                                                        43440020
** THIS CODE HANDLES THE CASE OF MOVING A LENGTH FIELD OF ONE BYTE   ** 43500020
         MVC   D0(L1,OUTBUFRG),D3(ATTREG)   MOVE LENGTH INTO MESSAGE    43560020
LNG04A3I EQU   *                                                        43620020
** THIS CODE PUTS THE LENGTH FIELD INTO THE FIRST TWO BYTES OF THE   ** 43680020
** SECOND LEVEL MESSAGE AND PREPARES THE PARAMETER LIST TO IKJEGIO   ** 43740020
** AND THEN GOES TO THAT MODULE TO HAVE THE MESSAGE PRINTED.         ** 43800020
         L     SECNDMSG,ADDRTWO   OBTAIN ADDR OF START OF SECOND MSG    43860020
         STH   R7,D0(SECNDMSG)    PUT LENGTH OF MSG INTO FIRST          43920020
*                                 HALFWORD OF OUTPUT BUFFER             43980020
         XR    DISPLREG,DISPLREG  INDICATE MAINLINE CALLING MSGRTN      44040020
         LA    PARMREG,ADDRONE    GET ADDR OF MESSAGE POINTERS          44100020
         B     MSG06C1            GO TO MESSAGE ROUTINE                 44160020
LNG04F3  EQU   *                                                        44220020
** THIS CODE IS RESPONSIBLE FOR MOVING THE BINARY REPRESENTATION OF  ** 44280020
** THE ATTRIBUTE INTO THE SYMBOL TABLE.                              ** 44340020
         L     R7,CONAREA         GET ADDRESS OF CONVERTED ATTRIBUTE    44400020
         XR    R5,R5              CLEAR A REGISTER                      44460020
         IC    R5,D0(R7)          GET LENGTH OF CONVERTED AREA          44520020
         LA    R7,D1(R7)          UPDATE PT TO BEGINNING OF OUTPUT      44580020
         TM    MULTSW,HEXFOUR     WAS CONVERSION FOR MULTIPLICITY       44640020
*                                 ATTRIBUTE                             44700020
         BC    ONES,LNG04F4       YES, GO MOVE MULTIPLICITY INTO TABLE  44760020
         LA    R0,ONE                                                   44820020
         CR    R5,R0              NO, IS THERE ONE CONVERTED BYTE       44880020
         BE    LNG04G3            YES, GO MOVE ONE BYTE INTO TABLE      44940020
         MVC   ATTRLNTH(L2),D0(R7) NO, MOVE LENGTH ATTRIBUTE INTO TABLE 45000020
         B     MULT05A1           GO GET MULTIPLICITY ATTRIBUTE         45060020
LNG04G3  EQU   *                                                        45120020
** MOVES ONE BYTE INTO LENGTH ATTRIBUTE FIELD.  ENTERED FROM LNG04F3 ** 45180020
         MVC   ATTRLNTH+D1(L1),D0(R7) MOVE LENGTH ATTRIBUTE INTO TABLE  45240020
         B     MULT05A1           GO GET MULTIPLICITY ATTRIBUTE         45300020
LNG04F4  EQU   *                                                        45360020
** THIS CODE MOVES THE MULTIPLICITY ATTRIBUTE INTO THE INCORE SYMBOL ** 45420020
** TABLE.  ENTERED FROM LNG04F3.                                     ** 45480020
         LA    R0,ONE                                                   45540020
         CR    R5,R0              IS THERE ONE CONVERTED BYTE           45600020
         BE    LNG04F4A           YES, GO MOVE MULTIPLICITY ATTRIBUTE   45660020
         MVC   ATTRMULT+D1(L2),D0(R7) MOVE TWO BYTES INTO SYMBOL TABLE  45720020
         B     EXIT05H5           GO PROCESS SYMBOL                     45780020
LNG04F4A EQU   *                                                        45840020
** MOVES ONE BYTE INTO MULTIPLICITY ATTRIBUTE FIELD OF SYMBOL TABLE  ** 45900020
         MVC   ATTRMULT+D2(L1),D0(R7) MOVE MULTIPLICITY INTO TABLE      45960020
         B     EXIT05H5           GO PROCESS SYMBOL                     46020020
MULT05A1 EQU   *                                                        46080020
** THE FOLLOWING CODE TESTS TO SEE IF THE MULTIPLICITY FACTOR WERE   ** 46140020
** SPECIFIED AND IF NOT PUTS THE DEFAULT OF ONE INTO THE TABLE.      ** 46200020
         OI    MULTSW,HEXFOUR     SET SWITCH TO INDICATE                46260020
*                                 PROCESSING OF MULTIPLICITY            46320020
         XR    R5,R5              CLEAR A REGISTER                      46380020
         LH    R5,D56(PDLBASE)    OBTAIN MULTIPLICITY INDICATOR         46440020
*                                 FROM PDL                              46500020
         LTR   R5,R5              WAS MULTIPLICITY SPECIFIED            46560020
         BNZ   MULT05B2           YES, GO PREPARE TO GO TO IKJEGCVT     46620020
** THIS CODE IS EXECUTED WHEN THE MULTIPLICITY ATTRIBUTE WAS NOT     ** 46680020
** SPECIFIED.  IT CHECKS TO SEE IF THIS ENTRY EXISTED BEFORE.  IF SO ** 46740020
** THE DEFAULT WILL BE THE PREVIOUS VALUE, IF NOT THE DEFAULT WILL BE** 46800020
** ONE.                                                              ** 46860020
         TM    DUPLSW,HEXONE      DID ENTRY EXIST BEFORE                46920020
         BC    ONES,EXIT05H5      YES, SET UP TO RETURN                 46980020
         MVC   ATTRMULT+D2(L1),BINRYONE  NO, PUT A ONE IN THE           47040020
*                                 MULTIPLICITY FIELD OF THE IN CORE     47100020
*                                 SYMBOL TABLE                          47160020
         B     EXIT05H5           GO SET UP TO RETURN                   47220020
MULT05B2 EQU   *                                                        47280020
** SETS REGISTER 1 UP TO GO TO IKJEGCVT.                             ** 47340020
         LA    PARMREG,D68(PDLBASE) PUT ADDR MULTIPLICITY PDE INTO      47400020
*                                 REGISTER 1                            47460020
         MVI   D75(PDLBASE),HEX14 SET TYPE FIELD OF PDE                 47520020
         B     LNG04D2            GO SET UP FOR CONVERSION              47580020
EXIT05E2 EQU   *                                                        47640020
* THE FOLLOWING CODE HANDLES THE SERVICE ROUTINE RETURN CODES         * 47700020
         L     R15,REGSAVE        GET RETURN CODE FROM SAVEAREA         47760020
EXIT05F2 EQU   *                                                        47820020
         B     EXIT05G2(R15)      INDEX THROUGH TABLE BY CONTENTS OF    47880020
*                                 REGISTER 15                           47940020
EXIT05G2 EQU   *                                                        48000020
         B     EXIT05H5           0 - FROM SERVICE ROUTINE-RETURN 0     48060020
         B     EXIT05H5           4 - FROM SERVICE ROUTINE-RETURN 0     48120020
         B     EXIT05H5           8 - FROM SERVICE ROUTINE-RETURN 0     48180020
         B     EXIT05H5           12 - FROM SERVICE ROUTINE-RETURN 0    48240020
         B     EXIT05J5           16 - FROM SERVICE ROUTINE-RETURN 16   48300020
         B     EXIT05J5           20 - FROM SERVICE ROUTINE-RETURN 20   48360020
ATTN05H4 EQU   *                                                        48420020
         LA    RETCODE,RET16      SET RETURN CODE TO 16 TO INDICATE     48480020
*                                 ATTENTION ENCOUNTERED                 48540020
         B     EXIT05J5           GO PREPARE TO LEAVE                   48600020
EXIT05J4 EQU   *                                                        48660020
         LA    R15,RET20          SET RETURN CODE TO 20 TO INDICATE     48720020
*                                 STAE EXIT ROUTINE WAS ENTERED         48780020
         B     EXIT05J5           GO PREPARE TO LEAVE                   48840020
EXIT05G5 EQU   *                                                        48890020
         OI    TSTFLGS4,TSTFLUSH  INDICATE IKJEGMNL SHOULD FLUSH STACK  48892020
EXIT05H5 EQU   *                                                        48900020
** THIS SETS THE RETURN CODE TO IKJEGMNL TO ZERO.                    ** 48960020
         LA    RETCODE,RET0       SET RETURN CODE TO ZERO               49020020
EXIT05J5 EQU   *                                                        49080020
         L     R13,D4(R13)        RESTORE SAVEAREA ADDRESS              49140020
         RETURN  (14,12),RC=(15)  RELOAD REGISTERS AND RETURN           49200020
MSG06A1  EQU   *                                                        49260020
** THIS IS ENTERED WHEN A MESSAGE SHOULD BE PRINTED AND AFTERWARDS   ** 49320020
** IKJEGEQU SHOULD TERMINATE.                                        ** 49380020
         OI    WRAPUP,HEXEIGHT    INDICATE PROCESSING SHOULD END        49440020
         XR    DISPLREG,DISPLREG  INDICATE MAINLINE CALLING MSGRTN      49500020
MSG06B1  EQU   *                                                        49560020
** THIS CODE DETERMINES THE MESSAGE OR MESSAGES THAT ARE TO BE       ** 49620020
** WRITTEN.  WHEN THE MSGRTN IS ENTERED MSGREG WILL CONTAIN THE      ** 49680020
** NUMBER OF THE MESSAGE TO BE WRITTEN.  THIS NUMBER IS MULTIPLIED   ** 49740020
** BY A FACTOR TO GET THE CORRECT OFFSET OF THE MESSAGE IN THE       ** 49800020
** MESSAGE CSECT.  REG 1 WILL BE MADE NEGATIVE AND POINT TO A TWO    ** 49860020
** WORD AREA.  THE FIRST WORD WILL POINT TO A MESSAGE AND THE SECOND ** 49920020
** WORD WILL POINT TO THE SECOND LEVEL MESSAGE IF ONE EXISTS.        ** 49980020
** IKJEGIO WILL THEN BE CALLED TO WRITE OUT THE MESSAGE.             ** 50040020
         L     PARMREG,ADDRMSGS   OBTAIN ADDR OF MESSAGE CSECT          50100020
         SLA   MSGREG,FACTOR      CALCULATE MESSAGE DISPLACEMENT        50160020
         AR    PARMREG,MSGREG     ADDR OF MESSAGE = ADDR MSG CSECT      50220020
*                                 PLUS MSG DISPLACEMENT                 50280020
         LA    MSGREG,EIGHT                                             50340020
         SR    PARMREG,MSGREG     GO BACK 8 BYTES FOR CORRECT           50400020
*                                 DISPLACEMENT                          50460020
MSG06C1  EQU   *                                                        50520020
         LNR   PARMREG,PARMREG    NEGATE REG 1 WITH ADDR COMPLEMENT     50580020
         L     R15,TPUTADDR       OBTAIN ADDR OF IKJEGIO FROM           50640020
*                                 TCOMTAB                               50700020
         BALR  RETURN,R15         GO TO IKJEGIO TO HAVE MESSAGE         50760020
*                                 OUTPUTTED                             50820020
         LPR   PARMREG,PARMREG    RESTORE REGISTER 1 TO POSITIVE        50880020
         B     MSGTAB(DISPLREG)   BRANCH THROUGH THE FOLLOWING TABLE    50940020
*                                 BY CONTENTS OF REGISTER 7             51000020
MSGTAB   EQU   *                                                        51060020
         B     MSG06E2            GO BACK TO MAINLINE CODE              51120020
         B     VDCK08E3           GO BACK TO VALIDITY CHECK ROUTINE     51180020
         B     DROP09D1(RETCODE)  GO BACK TO DROP CODE                  51240020
MSG06E2  EQU   *                                                        51300020
** USED TO DETERMINE PROCESSING AFTER RETURNING FROM IKJEGIO         ** 51360020
         LTR   R15,R15            RETURN CODE FROM IO A ZERO            51420020
         BNZ   EXIT05F2           NO, GO HANDLE RETURN CODE             51480020
** THE FOLLOWING CODE IS EXECUTED WHEN DISPLREG CONTAINS A ZERO      ** 51540020
** INDICATING THE MESSAGE WAS PUT OUT FROM EQUATE'S MAINLINE INSTEAD ** 51600020
** OF THE VALIDITY CHECK ROUTINE.                                    ** 51660020
         TM    WRAPUP,HEXEIGHT    YES, SHOULD EQUATE TERMINATE          51720020
         BZ    MULT05A1           NO, GO GET MULTIPLICITY ATTR          51780020
MSG06E3  EQU   *                                                        51840020
         B     EXIT05H5           YES, GO SET RETURN CODE AND RETURN    51900020
DROP09A1 EQU   *                                                        51960020
** WHEN THIS ROUTINE IS ENTERED WORKREG2 POINTS TO THE SYMBOL TO BE  ** 52020020
** DELETED IF ONE WERE SPECIFIED.  WORKREG CONTAINS THE CONTENTS OF  ** 52080020
** SYMTABLE AND LASTENTR IS A POINTER TO SYMTABLE.  THE FOLLOWING    ** 52140020
** CODE IS RESPONSIBLE FOR HANDLING THE DROP VERB.  IT REMOVES AN    ** 52200020
** ENTRY OR ALL ENTRIES FROM THE IN CORE SYMBOL TABLE.               ** 52260020
         LA    PDLBASE,D8(PDLBASE) BASE POINTS TO FIRST SYMBOL PDE      52320020
         LTR   WORKREG,WORKREG    DOES THE INCORE SYMBOL TABLE EXIST    52380020
         BNZ   DROP09A2           YES, GO HANDLE REQUEST                52440020
DROP09B1 EQU   *                                                        52500020
         LA    MSGREG,MSG7        PREPARE TO WRITE MSG IKJ57296I        52560020
         B     MSG06A1            GO TO MESSAGE ROUTINE                 52620020
DROP09A2 EQU   *                                                        52680020
         TM    TSTFLGS3,NOPARMS   WAS A SYMBOL SPECIFIED                52740020
         BNO   DROP09A3           YES, GO CHECK FOR ENTRY IN TABLE      52800020
** THE FOLLOWING CODE SETS UP TO DELETE THE IN CORE SYMBOL TABLE     ** 52860020
         OI    ALLSW,HEXFOUR      INDICATE ALL ENTRIES TO BE DELETED    52920020
DROP09C2 EQU   *                                                        52980020
         L     LASTENTR,D0(WORKREG) SAVE ADDRESS OF NEXT ENTRY          53040020
         LTR   LASTENTR,LASTENTR  IS THERE ANOTHER ENTRY                53100020
         BNZ   DROP09A5           YES, GO FIGURE SIZE OF ENTRY          53160020
         ST    LASTENTR,SYMTABLE  INDICATE IN CORE SYMBLE TABLE EMPTY   53220020
         NI    ALLSW,HEXFB        NO, INDICATE THIS IS LAST ENTRY TO    53280020
*                                 BE DELETED                            53340020
         B     DROP09A5           GO FIGURE SIZE OF ENTRY               53400020
** THIS SECTION OF CODE SCANS THE IN CORE SYMBOL TABLE FOR THE ENTRY ** 53460020
** REQUESTED TO BE DELETED.                                          ** 53520020
DROP09A3 EQU   *                                                        53580020
         CLC   D4(L2,PDLBASE),D14(WORKREG) ARE FIELD LENGTHS SAME       53640020
         BE    DRP9A31            YES, GO CHECK SYMBOLS                 53700020
DRP9A34  EQU   *                                                        53760020
         LR    LASTENTR,WORKREG   NO, SAVE POINTER TO NEXT TO LAST      53820020
*                                 ENTRY BEING SCANNED                   53880020
         L     WORKREG,D0(WORKREG) GET ADDRESS OF NEXT ENTRY            53940020
         LTR   WORKREG,WORKREG    WAS THERE ANOTHER ENTRY               54000020
         BNZ   DROP09A3           YES, GO CONTINUE CHECKING             54060020
         LA    MSGREG,MSG8        NO, PREPARE TO WRITE MSG IKJ57297I    54120020
         BAL   R14,LNG4A3A        GO FIND APPROPRIATE MESSAGE           54180020
DROP09C3 EQU   *                                                        54240020
** THIS CODE GETS CONTROL FROM LNG4A3A AFTER THE MESSAGE HAS BEEN    ** 54300020
** LOCATED AND THE WORK BUFFER HAS BEEN SET UP.  REGISTER 7 WILL     ** 54360020
** CONTAIN THE LENGTH OF THE MESSAGE WHICH DOES NOT INCLUDE THE      ** 54420020
** SYMBOL PORTION.  OUTBUFRG POINTS TO A DISPLACEMENT OF 4 INTO THE  ** 54480020
** OUTPUT AREA.  FSTMSG POINTS TO THE MESSAGE TEXT.                  ** 54540020
         L     WORKREG,D0(PDLBASE) GET ADDRESS OF SYMBOL                54600020
         MVC   D0(L10,OUTBUFRG),D4(FSTMSG) MOVE MSG NUMBER INTO BUFFER  54660020
         LA    OUTBUFRG,D10(OUTBUFRG)      UPDATE BUFFER POINTER        54720020
         LA    FSTMSG,D14(FSTMSG) UPDATE MESSAGE POINTER                54780020
         LH    R6,D4(PDLBASE)     PUT LENGTH OF SYMBOL INTO A REGISTER  54840020
         BCTR  R6,ZERO            TAKE ONE FROM LENGTH OF SYMBOL        54900020
         EX    R6,DRP09B3A        GO MOVE SYMBOL INTO OUTPUT BUFFER     54960020
         LA    R6,D1(R6)          RESET REG 6 TO LENGTH OF SYMBOL       55020020
         AR    OUTBUFRG,R6        UPDATE BUFFER POINTER FOR NEXT PART   55080020
*                                 OF MESSAGE                            55140020
         AR    R6,R7              SAVE TOTAL LENGTH OF MSG IN REG 6     55200020
         BCTR  R7,ZERO            TAKE ONE FROM LENGTH OF REST OF MSG   55260020
         EX    R7,DRP09B3B        GO MOVE REST OF MSG INTO BUFFER       55320020
         XC    ADDRTWO(L4),ADDRTWO INDICATE NO SECOND LEVEL             55380020
         L     FSTMSG,ADDRONE     OBTAIN ADDR OF BEGINNING OF OUTBUF    55440020
         STH   R6,D0(FSTMSG)      STORE LENGTH OF MESSAGE INTO FIRST    55500020
*                                 HALFWORD OF MESSAGE                   55560020
         LA    PARMREG,ADDRONE    GET ADDRESS OF MESSAGE POINTER        55620020
         LA    DISPLREG,D8        INDICATE DROP CODE CALLING MSG RTN    55680020
         B     MSG06C1            GO TO THE MESSAGE ROUTINE             55740020
DRP09B3A MVC   D0(L0,OUTBUFRG),D0(WORKREG) MOVE SYMBOL INTO BUFFER      55800020
DRP09B3B MVC   D0(L0,OUTBUFRG),D0(FSTMSG) MOVE REST OF MSG INTO BUFFER  55860020
DROP09D1 EQU   *                                                        55920020
** THE FOLLOWING BRANCH TABLE IS USED TO DETERMINE WHERE CONTROL     ** 55980020
** SHOULD BE GIVEN AFTER RETURNING FROM IKJEGIO.                     ** 56040020
         B     DROP09D5           GO SEE IF THERE IS ANOTHER ENTRY      56100020
*                                 TO DELETE                             56160020
         B     DROP09D5           SAME AS ABOVE                         56220020
         B     EXIT05F2           GO HANDLE SERVICE RTN RETURN CODE     56280020
         B     EXIT05F2           GO HANDLE SERVICE RTN RETURN CODE     56340020
         B     EXIT05F2           GO HANDLE SERVICE RTN RETURN CODE     56400020
DRP9A32  CLC   D0(L0,WORKREG2),D16(WORKREG) ARE SYMBOLS THE SAME        56460020
DRP9A31  EQU   *                                                        56520020
         LH    R6,D4(PDLBASE)     PUT LENGTH OF SYMBOL INTO REGISTER    56580020
         BCTR  R6,ZERO            TAKE ONE FROM LENGTH OF SYMBOL        56640020
         EX    R6,DRP9A32         GO SEE IF SYMBOLS ARE SAME            56700020
         BNE   DRP9A34            NO, CONTINUE SCANNING                 56760020
DROP09A4 EQU   *                                                        56820020
** THIS CODE PLACES THE POINTER TO THE ENTRY FOLLOWING THE ENTRY TO  ** 56880020
** BE DELETED INTO THE ENTRY IN FRONT OF THE ENTRY TO BE DELETED.    ** 56940020
         MVC   D0(L4,LASTENTR),D0(WORKREG) MOVE FORWARD POINTER INTO    57000020
*                                 PREVIOUS ENTRY                        57060020
DROP09A5 EQU   *                                                        57120020
** THIS CODE CALCULATES THE LENGTH OF THE ENTRY TO BE DELETED        ** 57180020
         XR    R1,R1              CLEAR A REGISTER                      57240020
         LH    R1,D14(WORKREG)    GET LENGTH OF SYMBOL AND ADD 16 TO    57300020
         LA    R1,D16(R1)         IT FOR ENTRY SIZE                     57360020
         LR    R0,R1              PUT LENGTH INTO REGISTER 0 FOR        57420020
*                                 FREEMAIN                              57480020
         LR    R1,WORKREG         PUT ADDRESS OF AREA TO BE DELETED     57540020
*                                 INTO REGISTER 1                       57600020
         O     R0,POOLONE         PUT SUBPOOL NUMBER INTO HIGH ORDER    57660020
*                                 BYTE OF REGISTER 0                    57720020
         FREEMAIN  R,LV=(0),A=(1) ISSUE FREEMAIN                        57780020
DROP09C5 EQU   *                                                        57840020
         TM    ALLSW,HEXFOUR      ARE ALL ENTRIES TO BE DELETED         57900020
         BZ    DROP9C5A           NO, GO TEST FOR NEXT ENTRY            57960020
         LR    WORKREG,LASTENTR   YES, GET ADDRESS OF NEXT ENTRY        58020020
         B     DROP09C2           GO SET UP TO DELETE NEXT ENTRY        58080020
DROP9C5A EQU   *                                                        58130020
         TM    TSTFLGS3,NOPARMS   WERE SYMBOLS SPECIFIED                58132020
         BO    EXIT05H5           NO, RETURN TO IKJEGMNL                58134020
DROP09D5 EQU   *                                                        58140020
** THIS CODE TESTS THE WORD FOLLOWING THE SYMBOL PDE FOR NON ZERO    ** 58200020
** WHICH INDICATES THERE IS A LIST OF SYMBOLS TO BE PROCESSED.       ** 58260020
         CLC   D8(L0,PDLBASE),ENDCHAIN IS THERE ANOTHER SYMBOL          58320020
         BE    EXIT05H5           NO, GO RETURN TO IKJEGMNL             58380020
DROP09D4 EQU   *                                                        58440020
         L     WORKREG,SYMTABLE   GET ADDRESS OF SYMBOL TABLE           58500020
         LTR   WORKREG,WORKREG    DOES THE INCORE SYMBOL TABLE EXIST    58560020
         BZ    DROP09B1           NO, GO WRITE MESSAGE                  58620020
         L     PDLBASE,D8(PDLBASE) YES, POINT TO NEXT SYMBOL PDE        58680020
         LA    LASTENTR,SYMTABLE   GET ADDRESS OF LAST ENTRY            58740020
         L     WORKREG2,D0(PDLBASE) GET ADDRESS OF SYMBOL               58800020
         B     DROP09A3            GO FIND SYMBOL IN SYMBOL TABLE       58860020
IKJEGVDK EQU   *                                                        58920020
** THIS CODE IS RESPONSIBLE FOR ANALYSING THE PARAMETERS FOR EQUATE  ** 58980020
** AFTER PARSE HAS CHECKED ONE FOR SYNTAX ERRORS.                    ** 59040020
         SAVE  (14,12)            SAVE PARSE'S REGISTERS                59100020
         L     R15,D4(R1)         OBTAIN ADDR OF SAVEAREA               59160020
         LM    R2,R12,D28(R15)    RESTORE REGISTERS                     59220020
         L     R15,REGSAVE3       GET ADDR OF VALIDITY CHECK RTN'S      59280020
*                                 SAVEAREA                              59340020
         ST    R15,D8(R13)        STORE ADDRESS OF NEW SAVEAREA         59400020
         ST    R13,D4(R15)        STORE CALLERS SAVEAREA ADDRESS        59460020
*                                 IN VALIDITY RTN'S SAVEAREA            59520020
         LR    R13,R15            R13 POINTS TO VALIDITY CHECK          59700020
*                                 RTN'S SAVEAREA                        59760020
         L     PDEPTR,D0(PARMREG) PDEPTR POINTS TO THE PDE PASSED       59820020
*                                 TO THE VALIDITY RTN FROM              59880020
*                                 IKJPARS                               59940020
         LA    WORKREG2,D8(PARMREG) SAVE ADDR OF THIRD WORD OF          60000020
*                                 PARAMETER LIST                        60060020
         L     ATTREG,ADDRMSGS    OBTAIN ADDR OF MESSAGE CSECT          60120020
         USING IKJEGMSG,ATTREG    ESTABLISH ADDRESSABILITY TO CSECT     60180020
         TM    CMMNDSW,HEXTWO     IS THIS THE ADDRESS EXIT              60240020
         BC    ONES,VDCK08A1      NO, GO TO THE ATTRIBUTE EXIT          60300020
** THIS CODE ASSURES THAT THE ADDRESS WAS NOT SPECIFIED AS A REGISTER** 60360020
** ADDRESS UNLESS THE REGISTER WAS USED FOR INDIRECT ADDRESSING.     ** 60420020
** THE CHECK IS FIRST MADE ON THE INDIRECT COUNT FIELD OF THE PDE    ** 60480020
** AND IF THIS IS NON ZERO INDIRECT ADDRESSING WAS USED.  THE ADDRESS** 60540020
** IS SPECIFIED CORRECTLY AND PROCESSING IS CONTINUED AT VDCK07G2.   ** 60600020
** IF THE INDIRECT COUNT FIELD IS ZERO A CHECK HAS TO BE MADE IN     ** 60660020
** FLAGS 4 OF THE PDE.  FLAGS 4 INDICATES THE TYPE OF ADDRESS.  IF   ** 60720020
** THE TYPE IS GENERAL REGISTER, DOUBLE PRECISION FLOATING POINT     ** 60780020
** REGISTER OR SINGLE PRECISION FLOATING POINT REGISTER THE ADDRESS  ** 60840020
** IS INCORRECTLY SPECIFIED AND THE VALIDITY CHECK ROUTINE WILL      ** 60900020
** RETURN TO PARSE WITH A RETURN CODE OF EIGHT.                      ** 60960020
         USING IKJPARMA,PDEPTR    ESTABLISH ADDRESSABILITY TO ADDR PDE  61020020
         CLC   PDEINDCT(L2),HEXZER0 WAS INDIRECT ADDRESSING USED        61080020
         BNE   VDCK07G2           YES, GO PROCESS                       61140020
         TM    PDEFLG4,REGSMASK   NO, IS TYPE OF ADDR REGISTER          61200020
         BNZ   VDCK07F3           YES, GO WRITE MESSAGE                 61260020
VDCK07G2 EQU   *                                                        61320020
** THIS CODE SETS UP THE REGISTERS TO GO TO IKJEGCVT (CONVERT) TO    ** 61380020
** CONVERT THE ADDRESS TO BINARY.                                    ** 61440020
         OI    CMMNDSW,HEXTWO     TURN SWITCH ON TO INDICATE THE        61500020
*                                 ADDRESS EXIT HAS BEEN TAKEN           61560020
         XR    R0,R0              CLEAR REG 0 TO INDICATE BINARY        61620020
*                                 CONVERSION NEEDED                     61680020
         LNR   PARMREG,PDEPTR     REG 1 SHOULD BE NEGATIVE TO           61740020
*                                 INDICATE ADDRESS CONVERSION AND       61800020
*                                 SHOULD POINT TO THE PDE               61860020
         L     R15,TSTCONVT       OBTAIN ADDRESS OF IKJEGCVT FROM       61920020
*                                 TCOMTAB                               61980020
         BALR  RETURN,R15         GO TO IKJEGCVT TO CONVERT THE         62040020
*                                 ADDRESS TO BINARY                     62100020
         LPR   PARMREG,PARMREG    RESTORE REGISTER 1 TO POSITIVE        62160020
         B     VDCK07J2(RETCODE)  TAKE ONE OF THE FOLLOWING BRANCHES    62220020
*                                 DEPENDENT ON THE CONTENTS OF REG 15   62280020
VDCK07J2 EQU   *                                                        62340020
** USED TO DETERMINE WHAT TO DO UPON RETURN FROM IKJEGCVT            ** 62400020
         B     VDCK08C1           GO HANDLE 0 RETURN FROM IKJEGCVT      62460020
         B     VDCK07K3           GO HANDLE 4 RETURN FROM IKJEGCVT      62520020
         B     VDCK08C2           GO HANDLE 8 RETURN FROM IKJEGSYM      62580020
         B     VDCK08C2           GO HANDLE 12 RETURN FROM IKJEGSYM     62640020
         B     VDCK08D2           16 - ATTENTION INTERRUPT-RETURN       62700020
         B     VDCK08D2           20 - CONVERT OR SYM BLEW-RETURN       62760020
VDCK07K3 EQU   *                                                        62820020
         NI    CMMNDSW,HEXFD      INDICATE ADDRESS NOT PROCESSED        62880020
         B     VDCK08B3           GO INDICATE PARSE SHOULD PROMPT       63060020
*                                 WITH REENTER                          63120020
VDCK7F3  EQU   *                                                        63180020
         MVC   D4(L0,OUTBUFRG),D4(FSTMSG)  MOVE MSG INTO BUFFER         63240020
VDCK07F3 EQU   *                                                        63300020
         LA    MSGREG,EQUM005     PREPARE TO WRITE MSG IKJ57294I        63360020
         L     OUTBUFRG,OUTBUF    GET ADDRESS OF OUTPUT BUFFER FROM     63420020
*                                 TCOMTAB                               63480020
         XC    D0(L4,OUTBUFRG),D0(OUTBUFRG) CLEAR FIRST HALFWORD OF     63540020
*                                 BUFFER                                63600020
         ST    OUTBUFRG,ADDRONE   SAVE ADDRESS OF 1ST LEVEL MSG         63660020
         MVC   ADDRTWO(L4),D4(MSGREG) PUT ADDR OF 2ND LEVEL MSG INTO    63720020
*                                 PARAMETER LIST FOR IO                 63780020
         MVC   D0(L4,WORKREG2),D4(MSGREG) PUT ADDRESS OF 2ND LEVEL      63840020
*                                 MSG INTO 3RD WORD OF PARAMETER LIST   63900020
*                                 FROM IKJPARS                          63960020
         L     FSTMSG,D0(MSGREG)  OBTAIN ADDR OF 1ST LEVEL MESSAGE      64020020
         XR    WORKREG2,WORKREG2  CLEAR A REGISTER                      64080020
         LH    WORKREG2,D0(FSTMSG) GET LENGTH OF 1ST LEVEL MESSAGE      64140020
         BCTR  WORKREG2,ZERO      TAKE ONE FROM LENGTH OF MESSAGE       64200020
         EX    WORKREG2,VDCK7F3   MOVE 1ST LEVEL MSG INTO BUFFER        64260020
         LA    WORKREG2,D1(WORKREG2) RESTORE REG TO ORIGINAL MSG LENGTH 64320020
         AR    OUTBUFRG,WORKREG2  UPDATE TO NEXT AVAILABLE POSITION     64380020
*                                 IN BUFFER                             64440020
         LR    R0,PDEPTR          PASS ADDR OF ADDR PDE TO ADDR BUILD   64500020
*                                 ROUTINE                               64560020
         LR    PARMREG,OUTBUFRG   PASS POINTER TO AREA TO PUT ADDR      64620020
*                                 STRING BUILT BY ADDR BUILD ROUTINE    64680020
         L     R15,TSTADDR        GET ADDRESS OF ADDRESS ROUTINE        64740020
         BALR  R14,R15            GO TO ADDRESS BUILD ROUTINE           64800020
         AR    WORKREG2,R0        UPDATE LENGTH OF MSG TO INCLUDE       64860020
*                                 THE ADDRESS STRING                    64920020
         MVI   D0(PARMREG),PLUSSIGN  INDICATE 2ND LEVEL MSG EXISTS      64980020
         LA    WORKREG2,D1(WORKREG2) UPDATE LENGTH OF MSG TO INCLUDE    65040020
*                                 PLUS SIGN                             65100020
         L     OUTBUFRG,ADDRONE   GET ADDR OF BEGINNING OF OUTPUT       65160020
*                                 BUFFER                                65220020
         STH   WORKREG2,D0(OUTBUFRG) PUT TOTAL LENGTH INTO MSG ENTRY    65280020
         LA    PARMREG,ADDRONE    GET ADDR OF ADDRESS PARAMETER LIST    65340020
VDCK07F5 EQU   *                                                        65400020
** CALCULATES PROPER DISPLACEMENT THAT BRINGS CONTROL BACK TO THE    ** 65460020
** VALIDITY CHECK ROUTINE AFTER GOING TO THE MESSAGE ROUTINE.        ** 65520020
         LA    DISPLREG,D4        INDICATE VALIDITY CHECK RTN GOING TO  65580020
*                                 MESSAGE ROUTINE                       65640020
         B     MSG06C1            GO TO THE MESSAGE ROUTINE             65700020
VDCK08E3 EQU   *                                                        65760020
         LTR   R15,R15            RETURN CODE FROM IO A ZERO            65820020
         BZ    VDCK08B4           YES, RETURN TO IKJPARS WITH AN 8      65880020
         B     VDCK08D2           NO, RETURN TO IKJPARS WITH A 12       65940020
VDCK08A1 EQU   *                                                        66000020
** THIS CODE IS RESPONSIBLE FOR CHECKING THE INTERGER SUPPLIED FOR   ** 66060020
** LENGTH OR MULTIPLICITY BEING SPECIFIED LESS THAN ONE OR GREATER   ** 66120020
** THAN 256.                                                         ** 66180020
         XR    WORKREG,WORKREG    CLEAR A REGISTER                      66240020
         L     STRNGPTR,D0(PDEPTR) GET ADDR OF CHARACTER STRING         66300020
         LH    WORKREG,D4(PDEPTR) OBTAIN LENGTH OF ATTRIBUTE            66360020
         SLL   WORKREG,TWO        MULTIPLY BY FOUR                      66420020
VDCKTAB3 EQU   *                                                        66480020
         B     VDCKTAB3(WORKREG)  GO PROCESS ACCORDING TO THE NUMBER    66540020
*                                 OF BYTES IN THE ATTRIBUTE             66600020
         B     VDCKONE            GO HANDLE ONE BYTE                    66660020
         B     VDCKTWO            GO HANDLE TWO BYTES                   66720020
         B     VDCKTHRE           GO HANDLE THREE BYTES                 66780020
** VDCKONE,VDCKTWO, AND VDCKTHREE ALL HAVE THE RESPONSIBILITY OF     ** 66840020
** CHECKING TO MAKE SURE THE INTERGER SUPPLIED IS NOT ZERO OR GREATER** 66900020
** THAN 256.                                                         ** 66960020
VDCKONE  EQU   *                                                        67020020
         CLC   D0(L1,STRNGPTR),CHARZERO  IS INTERGER ZERO               67080020
         BE    VDCK08A2           YES, GO PREPARE TO WRITE A MESSAGE    67140020
         B     VDCK08C1           NO, GO SET UP TO RETURN               67200020
VDCK08A2 EQU   *                                                        67260020
** THIS SETS UP THE BUFFERS TO OUTPUT MESSAGE IKJ57295I              ** 67320020
         LA    MSGREG,EQUM006     POINT TO ADDR LIST FOR IKJ57295I      67380020
         MVC   D0(L4,WORKREG2),D4(MSGREG)  PUT ADDR OF 2ND LEVEL MSG    67440020
*                                 INTO 3RD WORD OF PARAMETER LIST       67500020
*                                 FROM IKJPARS                          67560020
         MVC   ADDRONE(L4),D0(MSGREG)  PUT ADDR 1ST LEVEL MSG INTO      67620020
*                                 PARAMETER LIST FOR IO                 67680020
         MVC   ADDRTWO(L4),D4(MSGREG) PUT ADDR OF 2ND LEVEL MSG INTO    67740020
*                                 PARAMETER LIST FOR IO                 67800020
         LA    PARMREG,ADDRONE    POINT TO ADDRESS LIST FOR MSGS        67860020
         B     VDCK07F5           GO PREPARE TO GO TO MSG ROUTINE       67920020
VDCKTWO  EQU   *                                                        67980020
         CLC   D0(L2,STRNGPTR),CHARZERO IS INTERGER ZERO                68040020
         BE    VDCK08A2           YES, GO PREPARE TO WRITE A MESSAGE    68100020
         B     VDCK08C1           NO, GO SET UP TO RETURN               68160020
VDCKTHRE EQU   *                                                        68220020
         CLC   D0(L3,STRNGPTR),CHARZERO IS INTERGER ZERO                68280020
         BE    VDCK08A2           YES, GO PREPARE TO WRITE A MESSAGE    68340020
         CLC   D0(L3,STRNGPTR),MAXLNGTH IS INTERGER GREATER THAN 256    68400020
         BH    VDCK08A2           YES, GO PREPARE TO WRITE A MESSAGE    68460020
VDCK08C1 EQU   *                                                        68520020
** THIS SETS THE RETURN CODE BACK TO IKJPARS TO A ZERO               ** 68580020
         LA    RETCODE,RET0       SET RETURN CODE TO ZERO               68640020
VDCK08D1 EQU   *                                                        68700020
** THIS CODE IS RESPONSIBLE FOR RESTORING IKJPARS'S REGISTERS AND    ** 68760020
** RETURNING TO IKJPARS WITH A CONDITION CODE IN REGISTER 15 TO      ** 68820020
** INDICATE TO PARSE WHAT EQUATE WANTS PARSE TO DO NEXT.             ** 68880020
         DROP  ATTREG             DROP ADDRESSABILITY TO MSG CSECT      68940020
         L     R13,D4(R13)        RESTORE SAVEAREA ADDRESS              69000020
         RETURN (14,12),RC=(15)   RELOAD REGISTERS AND RETURN           69060020
VDCK08C2 EQU   *                                                        69120020
         MVC   D0(L4,WORKREG2),PDEUSER PUT ADDR OF SECOND LEVEL MSG     69180020
*                                 INTO PARAMETER LIST                   69240020
VDCK08D2 EQU   *                                                        69300020
         ST    R15,REGSAVE        SAVE RETURN CODE FOR LATER USE        69360020
         LA    RETCODE,RET12      SET RETURN CODE TO 12                 69420020
         B     VDCK08D1           GO PREPARE TO RETURN TO IKJPARS       69480020
VDCK08B3 EQU   *                                                        69540020
         MVC   D0(L4,WORKREG2),PDEUSER PUT ADDR OF SECOND LEVEL MSG     69600020
*                                 INTO PARAMETER LIST                   69660020
VDCK08B4 EQU   *                                                        69720020
         LA    RETCODE,RET8       SET RETURN CODE TO 8                  69780020
         B     VDCK08D1           GO PREPARE TO RETURN TO IKJPARS       69840020
         DROP  PDEPTR             DROP ADDRESSABILITY TO PDE            69900020
**********************************************************************  69960020
*                        STAE RETRY ROUTINE                          *  70020020
**********************************************************************  70080020
STAERTN  EQU   *                                                        70140020
         L     WORKREG,CVTPTR     GET CVT ADDRESS                       70200020
         USING CVTDSECT,WORKREG   ESTABLISH ADDRESSABILITY TO CVT       70260020
         L     WORKREG,CVTTCBP    GET ADDRESS OF TCB ADDRESS            70320020
         L     WORKREG,D4(WORKREG) GET ADDRESS OF CURRENT TCB           70380020
         DROP  WORKREG            DROP ADDRESSABILITY TO CVT            70440020
         USING TCB,WORKREG        ESTABLISH ADDRESSABLITY TO TCB        70500020
         L     R9,TCBTRN          PICK UP POINTER TO TCOMTAB FROM       70560020
*                                 TCBTRN FIELD OF TEST'S TCB            70620020
         L     R13,REGSAVE2       GET ADDRESS OF REGISTERS              70680020
         L     BASEREG,D64(R13)   RESET ADDRESSABILITY                  70740020
         LTR   R0,R0              IS WORKAREA AVAILABLE                 70800020
         BNZ   EXIT05J4           NO, GO SET RETURN CODE TO IKJEGMNL    70860020
         FREEMAIN R,LV=104,A=(1)  YES, FREE AREA                        70920020
NOWORK   EQU   *                                                        70980020
         B     EXIT05J4           GO SET RETURN CODE FOR IKJEGMNL       71040020
ATTRTAB  EQU   *                                                        71100020
** THIS TABLE CONTAINS THE PROPER DATA TYPE REPRESENTATION FOR THE   ** 71160020
** VARIOUS TYPE ATTRIBUTES ALONG WITH THE MIN LENGTH FOLLOWED BY THE ** 71220020
** MAX LENGTH THAT CAN BE SPECIFIED FOR EACH TYPE.  THESE LENGTHS ARE** 71280020
** FOLLOWED BY THE DEFAULT LENGTH.                                   ** 71340020
CENTRY   DC    X'00'              TYPE ATTRIBUTE IS CHARACTER           71400020
         DC    C'001'             MIN LENGTH                            71460020
         DC    C'256'             MAX LENGTH                            71520020
         DC    X'01'              DEFAULT LENGTH IN BINARY              71580020
         DC    C' C'              TYPE IN PRINTABLE FORM                71640020
         DC    C'01'              LENGTH IN PRINTABLE FORM              71700020
XENTRY   DC    X'04'              TYPE ATTRIBUTE IS HEX                 71760020
         DC    C'001'             MIN LENGTH                            71820020
         DC    C'256'             MAX LENGTH                            71880020
         DC    X'04'              DEFAULT LENGTH IN BINARY              71940020
         DC    C' X'              TYPE IN PRINTABLE FORM                72000020
         DC    C'04'              LENGTH IN PRINTABLE FORM              72060020
BENTRY   DC    X'08'              TYPE ATTRIBUTE IS BINARY              72120020
         DC    C'001'             MIN LENGTH                            72180020
         DC    C'256'             MAX LENGTH                            72240020
         DC    X'01'              DEFAULT LENGTH IN BINARY              72300020
         DC    C' B'              TYPE IN PRINTABLE FORM                72360020
         DC    C'01'              LENGTH DEFAULT IN PRINTABLE FORM      72420020
IENTRY   DC    X'0C'              TYPE ATTRIBUTE IS INSTRUCTION         72480020
         DC    C'001'             MIN LENGTH                            72540020
         DC    C'256'             MAX LENGTH                            72600020
         DC    X'01'              DEFAULT LENGTH                        72660020
         DC    C' I'              TYPE IN PRINTABLE FORM                72720020
         DC    C'01'              DEFAULT LENGTH IN PRINTABLE FORM      72780020
FENTRY   DC    X'10'              TYPE ATTRIBUTE IS FIXED PT, FULLWORD  72840020
         DC    C'001'             MIN LENGTH                            72900020
         DC    C'008'             MAX LENGTH                            72960020
         DC    X'04'              DEFAULT LENGTH                        73020020
         DC    C' F'              TYPE IN PRINTABLE FORM                73080020
         DC    C'04'              DEFAULT IN PRINTABLE FORM             73140020
HENTRY   DC    X'14'              TYPE ATTRIBUTE IS FIXED PT, HALFWORD  73200020
         DC    C'001'             MIN LENGTH                            73260020
         DC    C'008'             MAX LENGTH                            73320020
         DC    X'02'              DEFAULT LENGTH IN BINARY              73380020
         DC    C' H'              TYPE IN PRINTABLE FORM                73440020
         DC    C'02'              DEFAULT LENGTH IN PRINTABLE FORM      73500020
EENTRY   DC    X'18'              TYPE ATTRIBUTE IS FLT PT. FULLWORD    73560020
         DC    C'001'             MIN LENGTH                            73620020
         DC    C'008'             MAX LENGTH                            73680020
         DC    X'04'              DEFAULT LENGTH IN BINARY              73740020
         DC    C' E'              TYPE IN PRINTABLE FORM                73800020
         DC    C'04'              DEFAULT LENGTH IN PRINTABLE FORM      73860020
DENTRY   DC    X'1C'              TYPE ATTRIBUTE IS FLT PT. DBLWORD     73920020
         DC    C'001'             MIN LENGTH                            73980020
         DC    C'008'             MAX LENGTH                            74040020
         DC    X'08'              DEFAULT LENGTH                        74100020
         DC    C' D'              TYPE IN PRINTABLE FORM                74160020
         DC    C'08'              DEFAULT LENGTH IN PRINTABLE FORM      74220020
AQENTRY  DC    X'20'              TYPE ATTRIBUTE IS A AND Q ADDR CONST  74280020
         DC    C'001'             MIN LENGTH                            74340020
         DC    C'004'             MAX LENGTH                            74400020
         DC    X'04'              DEFAULT LENGTH IN BINARY              74460020
         DC    C' A'              TYPE IN PRINTABLE FORM                74520020
         DC    C'04'              DEFAULT LENGTH IN PRINTABLE FORM      74580020
YENTRY   DC    X'24'              TYPE ATTRIBUTE IS Y ADDR CONSTANT     74640020
         DC    C'001'             MIN LENGTH                            74700020
         DC    C'002'             MAX LENGTH                            74760020
         DC    X'02'              DEFAULT LENGTH                        74820020
         DC    C' Y'              TYPE IN PRINTABLE FORM                74880020
         DC    C'02'              DEFAULT LENGTH IN PRINTABLE FORM      74940020
SENTRY   DC    X'28'              TYPE ATTRIBUTE IS S ADDR CONSTANT     75000020
         DC    C'002'             MIN LENGTH                            75060020
         DC    C'002'             MAX LENGTH                            75120020
         DC    X'02'              DEFAULT LENGTH IN BINARY              75180020
         DC    C' S'              TYPE IN PRINTABLE FORM                75240020
         DC    C'02'              DEFAULT LENGTH IN PRINTABLE FORM      75300020
PENTRY   DC    X'30'              TYPE ATTRIBUTE IS PACKED DECIMAL      75360020
         DC    C'001'             MIN LENGTH                            75420020
         DC    C'016'             MAX LENGTH                            75480020
         DC    X'01'              DEFAULT LENGTH IN BINARY              75540020
         DC    C' P'              TYPE IN PRINTABLE FORM                75600020
         DC    C'01'              DEFAULT LENGTH IN PRINTABLE FORM      75660020
ZENTRY   DC    X'34'              TYPE ATTRIBUTE IS ZONED DECIMAL       75720020
         DC    C'001'             MIN LENGTH                            75780020
         DC    C'016'             MAX LENGTH                            75840020
         DC    X'01'              DEFAULT LENGTH                        75900020
         DC    C' Z'              TYPE IN PRINTABLE FORM                75960020
         DC    C'01'              DEFAULT LENGTH IN PRINTABLE FORM      76020020
         EJECT                                                          76080020
BINRYONE DC    X'01'              BINARY ONE-USED IN DEFAULT IN LENGTH  76140020
*                                 ATTRIBUTE FIELD                       76200020
FULLWORD DC    X'03'              USED TO TEST FOR FULLWORD BOUNDARY    76260020
HEXZER0  DC    X'0000'            USED TO TEST FOR INDIRECT ADDRESSING  76320020
ENDCHAIN DC    X'FF000000'        USED TO TEST FOR END OF PDL CHAIN     76380020
CHARZERO DC    C'000000'          USED FOR INITIALIZING AND TESTING     76440020
*                                 VALUE SPECIFIED FOR MULTIPLICITY AND  76500020
*                                 LENGTH ATTRIBUTES                     76560020
MAXLNGTH DC    C'256'             MAXIMUN LENGTH ALLOWED SPECIFIED      76620020
*                                 FOR LENGTH AND MULTIPLICITY           76680020
*                                 ATTRIBUTES                            76740020
BASE     DC    A(IKJEGEQU)        ADDRESS OF IKJEGEQU CSECT             76800020
ADDRMSGS DC    V(IKJEGMSG)        ADDRESS OF MESSAGE CSECT              76860020
PARSADDR DC    V(IKJEGPAR)        ADDRESS OF PCL FOR IKJPARS-EQUATE     76920020
PARSDROP DC    V(IKJEGPRS)        ADDRESS OF PCL FOR IKJPARS-DROP       76980020
POOLONE  DC    X'01000000'        SUBPOOL NUMBER FOR GETMAIN            77040020
** THE FOLLOWING IS THE STAE MESSAGE TABLE                           ** 77100020
STATBL   DS    0F                                                       77160020
         DC    AL1(HEXTHREE),AL3(PARSBLOW)  PARSE LINK FAILED           77220020
         DC    AL1(HEXONE),AL3(SYM02G3)     GETMAIN FAILED              77280020
         DC    AL1(HEXFF)                   END OF STAE ABEND TABLE     77340020
RETRYADR DC    AL3(STAERTN)       ADDRESS OF STAE EXIST ROUTINE         77400020
STAEL2   DS    0F                                                       77460020
STAELIST STAE  STAELIST,MF=L      LIST FORM STAE MACRO                  77520020
STAELEN  EQU   *-STAELIST         LENGTH OF STAE LIST                   77580020
         EJECT                                                          77640020
IKJEGMSG  CSECT                                                         77700020
**THIS IS THE MESSAGE CSECT FOR IKJEGEQU AND IKJEGDRP, THE EQUATE AND** 77760020
**DROP FUNCTIONS OF TEST.  THE FIRST SECTION CONTAINS ADCONS FOR THE ** 77820020
**FIRST AND SECOND LEVEL MESSAGES.  THE SECOND ADCON IS ZERO IF NO   ** 77880020
**SECOND LEVEL MESSAGE EXISTS.                                       ** 77940020
EQUM001  DC    A(MSG291IA)   ADDRESS OF FIRST LEVEL MSG IKJ57291I       78120020
         DC    A(MSG291IB)   ADDRESS OF SECOND LEVEL MSG IKJ57291I      78180020
EQUM002  DC    A(MSG292I)    ADDRESS OF FIRST LEVEL MSG IKJ57292I       78240020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    78300020
EQUM003  DC    A(MSG293IA)   ADDRESS OF FIRST LEVEL MSGI IKJ57293I      78360020
         DC    A(MSG293IB)   ADDRESS OF SECOND LEVEL MSG IKJ57293I      78420020
EQUM004  DC    A(MSG293IA)   ADDRESS OF FIRST LEVEL MSG IKJ57293I       78480020
         DC    A(MSG293IC)   ADDRESS OF SECOND LEVEL MSG IKJ57293I      78540020
EQUM005  DC    A(MSG294IA)   ADDRESS OF FIRST LEVEL MSG IKJ57294I       78600020
         DC    A(MSG294IB)   ADDRESS OF SECOND LEVEL MSG IKJ57294I      78660020
EQUM006  DC    A(MSG295IA)   ADDRESS OF FIRST LEVEL MSG IKJ57295I       78720020
         DC    A(MSG295IB)   ADDRESS OF SECOND LEVEL MSG IKJ57295I      78780020
EQUM007  DC    A(MSG296I)    ADDRESS OF FIRST LEVEL MSG IKJ57296I       78840020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    78900020
EQUM008  DC    A(MSG297I)    ADDRESS OF FIRST LEVEL MSG IKJ57297I       78960020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    79020020
EQUM009  DC    A(MSG298IA)   ADDRESS OF FIRST LEVEL MSG IKJ57298I       79080020
         DC    A(MSG298IB)   ADDRESS OF SECOND LEVEL MSG IKJ57298I      79140020
MSG291IA DS    0H                                                       79920020
         DC    AL2(END291IA-MSG291IA)  LENGTH OF MESSAGE                79980020
         DC    AL2(0)                  TWO BYTES OF ZERO                80040020
         DC    C'IKJ57291I EQUATE FAILED, COMMAND'     MESSAGE TEXT     80100020
         DC    C' SYSTEM ERROR+'                       MESSAGE TEXT     80160020
END291IA EQU   *                                                        80220020
MSG291IB DS    0H                                                       80280020
         DC    AL2(END291IB-MSG291IB)  LENGTH OF MESSAGE                80340020
         DC    AL2(0)                  TWO BYTES OF ZERO                80400020
         DC    C'IKJ57291I PARSE ERROR CODE 12'        MESSAGE TEXT     80460020
END291IB EQU   *                                                        80520020
MSG292I  DS    0H                                                       80580020
         DC    AL2(END292I-MSG292I)    LENGTH OF MESSAGE                80640020
         DC    AL2(0)                  TWO BYTES OF ZERO                80700020
         DC    C'IKJ57292I NOT ENOUGH MAIN STORAGE'    MESSAGE TEXT     80760020
         DC    C' TO EXECUTE COMMAND'                  MESSAGE TEXT     80820020
END292I  EQU   *                                                        80880020
MSG293IA DS    0H                                                       80940020
         DC    AL2(END293IA-MSG293IA)  LENGTH OF MESSAGE                81000020
         DC    AL2(0)                  TWO BYTES OF ZERO                81060020
         DC    C'IKJ57293I INVALID LENGTH FOR '       MESSAGE TEXT      81120020
         DC    C', DEFAULTED TO  '                    MESSAGE TEXT      81180020
END293IA EQU   *                                                        81240020
MSG293IB DS    0H                                                       81300020
         DC    AL2(END293IB-MSG293IB)  LENGTH OF MESSAGE                81360020
         DC    AL2(0)                  TWO BYTES OF ZERO                81420020
         DC    C'IKJ57293I MINIMUM LENGTH FOR TYPE  ' MESSAGE TEXT      81480020
         DC    C' IS  '                               MESSAGE TEXT      81540020
END293IB EQU   *                                                        81600020
MSG293IC DS    0H                                                       81660020
         DC    AL2(END293IC-MSG293IC)  LENGTH OF MESSAGE                81720020
         DC    AL2(0)                  TWO BYTES OF ZERO                81780020
         DC    C'IKJ57293I MAXIMUM LENGTH FOR TYPE  ' MESSAGE TEXT      81840020
         DC    C' IS  '                               MESSAGE TEXT      81900020
END293IC EQU   *                                                        81960020
MSG294IA DS    0H                                                       82020020
         DC    AL2(END294IA-MSG294IA)  LENGTH OF MESSAGE                82080020
         DC    AL2(0)                  TWO BYTES OF ZERO                82140020
         DC    C'IKJ57294I INVALID ADDRESS '          MESSAGE TEXT      82200020
END294IA EQU   *                                                        82260020
MSG294IB DS    0H                                                       82320020
         DC    AL2(END294IB-MSG294IB)  LENGTH OF MESSAGE                82380020
         DC    AL2(0)                  TWO BYTES OF ZERO                82440020
         DC    C'IKJ57294I REGISTER NOTATION MUST BE' MESSAGE TEXT      82500020
         DC    C' INDIRECT GENERAL REGISTER'          MESSAGE TEXT      82560020
END294IB EQU   *                                                        82620020
MSG295IA DS    0H                                                       82680020
         DC    AL2(END295IA-MSG295IA)  LENGTH OF MESSAGE                82740020
         DC    AL2(0)                  TWO BYTES OF ZERO                82800020
         DC    C'IKJ57295I INVALID MULTIPLICITY OR '  MESSAGE TEXT      82860020
         DC    C'LENGTH SPECIFIED+'                   MESSAGE TEXT      82920020
END295IA EQU   *                                                        82980020
MSG295IB DS    0H                                                       83040020
         DC    AL2(END295IB-MSG295IB)  LENGTH OF MESSAGE                83100020
         DC    AL2(0)                  TWO BYTES OF ZERO                83160020
         DC    C'IKJ57295I THE VALID RANGE IS FROM '  MESSAGE TEXT      83220020
         DC    C'1 TO 256'                            MESSAGE TEXT      83280020
END295IB EQU   *                                                        83340020
MSG296I  DS    0H                                                       83400020
         DC    AL2(END296I-MSG296I)    LENGTH OF MESSAGE                83460020
         DC    AL2(0)                  TWO BYTES OF ZERO                83520020
         DC    C'IKJ57296I SYMBOL TABLE IS EMPTY'     MESSAGE TEXT      83580020
END296I  EQU   *                                                        83640020
MSG297I  DS    0H                                                       83700020
         DC    AL2(END297I-MSG297I)    LENGTH OF MESSAGE                83760020
         DC    AL2(0)                  TWO BYTES OF ZERO                83820020
         DC    C'IKJ57297I  NOT FOUND IN SYMBOL TABLE'  MESSAGE TEXT    83880020
END297I  EQU   *                                                        83940020
MSG298IA DS    0H                                                       84600020
         DC    AL2(END298IA-MSG298IA)  LENGTH OF MESSAGE                84660020
         DC    AL2(0)                  TWO BYTES OF ZERO                84720020
         DC    C'IKJ57298I DROP FAILED, COMMAND'      MESSAGE TEXT      84780020
         DC    C' SYSTEM ERROR+'                      MESSAGE TEXT      84840020
END298IA EQU   *                                                        84900020
MSG298IB DS    0H                                                       84960020
         DC    AL2(END298IB-MSG298IB)  LENGTH OF MESSAGE                85020020
         DC    AL2(0)                  TWO BYTES OF ZERO                85080020
         DC    C'IKJ57298I PARSE ERROR CODE 12'       MESSAGE TEXT      85140020
END298IB EQU   *                                                        85200020
PLUSSIGN EQU   C'+'                    PLUS SIGN FOR INDICATING SECOND  85260020
*                                      LEVEL MESSAGE EXISTS             85320020
         EJECT                                                          85380020
IKJEGPAR IKJPARM DSECT=DSECTEQU                                         85440020
GETSYMBL IKJIDENT 'SYMBOL',MAXLNTH=8,OTHER=ALPHANUM,                   x85500020
               PROMPT='SYMBOL'                                          85560020
GETADDR  IKJPOSIT ADDRESS,PROMPT='ADDRESS',VALIDCK=IKJEGVDK             85620020
TYPEADDR IKJKEYWD                                                       85680020
         IKJNAME 'C'                                                    85740020
         IKJNAME 'X'                                                    85800020
         IKJNAME 'B'                                                    85860020
         IKJNAME 'I'                                                    85920020
         IKJNAME 'F'                                                    85980020
         IKJNAME 'H'                                                    86040020
         IKJNAME 'E'                                                    86100020
         IKJNAME 'D'                                                    86160020
         IKJNAME 'A'                                                    86220020
         IKJNAME 'Y'                                                    86280020
         IKJNAME 'S'                                                    86340020
         IKJNAME 'P'                                                    86400020
         IKJNAME 'Z'                                                    86460020
TYPELNTH IKJKEYWD                                                       86520020
         IKJNAME 'LENGTH',SUBFLD=LENGTHCD                        A43351 86580021
TYPEMULT IKJKEYWD                                                       86640020
         IKJNAME 'MULTIPLE',SUBFLD=MULTCD                        A43351 86700021
LENGTHCD IKJSUBF                                                        86760020
LENGTH   IKJIDENT  'LENGTH',FIRST=NUMERIC,OTHER=NUMERIC,MAXLNTH=3,     *86820020
               PROMPT='INTEGER FOR LENGTH',VALIDCK=IKJEGVDK             86880020
MULTCD   IKJSUBF                                                        86940020
MULTPCTY IKJIDENT  'MULTIPLICITY FACTOR',FIRST=NUMERIC,OTHER=NUMERIC,  *87000020
               PROMPT='INTEGER FOR MULTIPLICITY',VALIDCK=IKJEGVDK       87060020
         IKJENDP                                                        87120020
IKJEGPRS IKJPARM DSECT=DSECTDRP                                         87180020
DROPSYM  IKJIDENT 'SYMBOL',LIST,MAXLNTH=8,OTHER=ALPHANUM,              *87240020
               PROMPT='SYMBOL'                                          87292020
         IKJENDP                                                        87300020
         EJECT                                                          87360020
CVTDSECT DSECT                                                          87420020
         CVT                                                            87480020
         EJECT                                                          87540020
         IKJTCB                                                         87600020
         EJECT                                                          87660020
TCOMTAB  TCOMTAB                                                        87720020
         EJECT                                                          87780020
         TSTCWORK                                                       87840020
         SPACE                                                          87900020
         SPACE                                                          87960020
         SPACE                                                          88020020
         SPACE                                                          88080020
         EJECT                                                          88140020
AREAWORK DSECT                                                          88200020
PPLAREA  DS    7F                 PARSE PARAMETER LIST-DESCRIPTION      88260020
*                                 IN PPL MACRO EXPANSION                88320020
** THE FOLLOWING TWO WORDS CANNOT BE SEPARATED.  USED AS A PARAMETER ** 88380020
** LIST TO GO TO IKJEGIO.                                            ** 88440020
ADDRONE  DS     A                 SAVEAREA FOR ADDR OF 1ST LEVEL MSG    88500020
ADDRTWO  DS     A                 SAVEAREA FOR ADDR OF 2ND LEVEL MSG    88560020
REGSAVE  DS     F                 SAVEAREA FOR SERVICE RTN RETURN CODES 88620020
STAEL    DS    0F                 ALIGN TO FULLWORD BOUNDARY            88680020
STAEAREA DS    18C                STAE LIST FORM WORKAREA               88740020
LNGTWORK DS    3X                 WORKAREA FOR LENGTH ATTRIBUTE         88800020
DUPLSW   EQU    *                 BIT 1 INDICATES ON (X'01')            88860020
CMMNDSW  EQU    *                 ADDR EXIT SWITCH ON -(X'02')          88920020
MULTSW   EQU    *                 BIT 3 INDICATES ON (X'04')            88980020
WRAPUP   DS     X                 TERMINATE SWITCH ON - (X'08')         89040020
LOWSW    EQU    *                 LOW VALUE SWITCH ON - (X'01')         89100020
DROPSW   EQU    *                 DROP SWITCH ON - (X'02')              89160020
ALLSW    DS     X                 DELETE ENTRIE TABLE ON - (X'04')      89220020
ENDWORK  EQU    *                                                       89280020
         EJECT                                                          89340020
ENTRY    DSECT                                                          89400020
** THE FOLLOWING SEVEN FIELDS CANNOT BE SEPARATED.                   ** 89460020
TABENTR  DS    0F                                                       89520020
CHAIN    DS     A                 POINTER TO NEXT ENTRY IN SYM TABLE    89580020
ADDRSYM  DS     A                 LOAD ADDRESS OF SYMBOL                89640020
ATTRTYPE DS     X                 TYPE ATTRIBUTE FIELD                  89700020
ATTRMULT DS    3X                 MULTIPLICITY ATTRIBUTE FIELD          89760020
ATTRLNTH DS    2X                 LENGTH ATTRIBUTE FIELD                89820020
SYMLNGTH DS    2X                 LENGTH OF SYMBOL                      89880020
SYMBOL   DS    8X                 SYMBOL FIELD                          89940020
         EJECT                                                          90000020
IKJPARMA IKJPARMA                                                       90060020
         SPACE                                                          90120020
         SPACE                                                          90180020
         SPACE                                                          90240020
         SPACE                                                          90300020
         IKJPPL                                                         90360020
         END                                                            90420020
