         TITLE 'GO RUN CALL COMMAND PROCESSOR (IKJEGGO)'                00100020
IKJEGGO  CSECT                                                          00200020
*RELEASE 21 CHANGES                                                     00250021
*A157500,476500,476600,479100,479500,479600,479700,479800        A46752 00300021
*C487000                                                         A46752 00350021
*D479000,480000,481000,485000,486000                             A46752 00400021
*RELEASE 21.6 CHANGES                                                   00450021
*A288500,288600                                                 SA53666 00460021
*C259000,351000,371200                                          SA53666 00470021
*A606500                                                        SA53665 00480021
*********************************************************************** 00500020
* STATUS CHANGE LEVEL 000                                             * 00600020
*                                                                     * 00700020
* FUNCTION                                                            * 00750020
*    GO-CAUSES THE MODE TO CHANGE FROM COMMAND (IN WHICH YOU MAY ENTER* 00800020
*    TEST COMMANDS) TO PROBLEM PROGRAM.  GO WITHOUT THE ADDRESS       * 00900020
*    PARAMETER CAUSES EXECUTION TO BEGIN AT THE INITIAL ENTRY         * 01000020
*    POINT IF THE PROBLEM PROGRAM HAD BEEN LOADED BY TEST OR          * 01100020
*    CAUSES EXECUTION TO BEGIN FROM THE POINT OF INTERRUPTION.        * 01200020
*    GO WITH AN ADDRESS CAUSES EXECUTION TO PROCEED AS IF A           * 01300020
*    BRANCH HAD BEEN TAKEN TO THAT ADDRESS.  WHEN A BREAKPOINT        * 01400020
*    IS ENCOUNTERED OR EXECUTION IS COMPLETED THE MODE IS CHANGED     * 01500020
*    BACK TO COMMAND MODE.                                            * 01600020
*                                                                     * 01700020
*    CALL-DIFFERS FROM 'GO' IN THAT IT INITIALIZES REGISTERS 1, 14,   * 01800020
*    AND 15 OF THE PROBLEM PROGRAM'S REGISTERS AT THE TIME            * 01900020
*    EXECUTION BEGINS THUS ALLOWING FOR THE PASSING OF A              * 02000020
*    PARAMETER LIST TO THE PROBLEM PROGRAM.  REGISTER 1 IS SET TO     * 02100020
*    A DUMMY PARAMETER LIST IF 'PARM' IS NOT SPECIFIED.  THE HIGH     * 02200020
*    ORDER BIT OF THE LAST PARAMETER IS SET TO 1 IF 'VL' IS           * 02300020
*    SPECIFIED.  REGISTER 14 WILL CONTAIN THE RETURN ADDRESS          * 02400020
*    WHICH WILL CAUSE A CHANGE IN THE MODE BACK TO THE COMMAND        * 02500020
*    MODE IN WHICH TEST COMMANDS CAN BE ISSUED.  IF THE 'RETURN'      * 02600020
*    KEYWORD IS SPECIFIED, REGISTER 14 IS SET TO THE RETURN           * 02700020
*    ADDRESS SPECIFIED.  THE ADDRESS PARAMETER MUST BE SPECIFIED      * 02800020
*    WITH THE CALL COMMAND.                                           * 02900020
*                                                                     * 03000020
*    RUN-DIFFERS FROM 'GO' IN THAT IT REMOVES ALL THE BREAKPOINTS     * 03100020
*    ESTABLISHED BY 'AT' AND ADJUSTS THE ENVIRONMENT SO THAT          * 03200020
*    TEST IS REMOVED UPON TERMINATION OF THE PROBLEM PROGRAM.         * 03300020
*                                                                     * 03400020
* ENTRY POINTS                                                        * 03500020
*                                                                     * 03600020
*         IKJEGGO-ENTERED VIA LINK FROM IKJEGMNL.  REGISTER 9 WILL    * 03700020
*    POINT TO TCOMTAB, THE COMMON DSECT USED BY TEST.  THIS IS THE    * 03800020
*    ENTRY POINT WHEN THE GO COMMAND HAS BEEN ISSUED.                 * 03900020
*                                                                     * 04000020
*         IKJEGRUN-ENTERED VIA LINK FROM IKJEGMNL.  REGISTER 9 WILL   * 04100020
*    POINT TO TCOMTAB, THE COMMON DSECT USED BY TEST.  THIS IS THE    * 04200020
*    ENTRY POINT WHEN THE RUN COMMAND HAS BEEN ISSUED.                * 04300020
*                                                                     * 04400020
*         IKJEGCAL-ENTERED VIA LINK FROM IKJEGMNL.  REGISTER 9 WILL   * 04500020
*    POINT TO TCOMTAB, THE COMMAND DSECT USED BY TEST.  THIS IS THE   * 04600020
*    ENTRY POINT WHEN THE CALL COMMAND HAS BEEN ISSUED.               * 04700020
*                                                                     * 04800020
*         IKJEGCHK-ENTERED FROM IKJPARS.  REGISTER 1 POINTS TO A      * 04900020
*    THREE WORD PARAMETER LIST.  THE FIRST WORD POINTS TO THE         * 05000020
*    ADDRESS PDE BUILT BY IKJPARS, THE SECOND WORD POINTS TO          * 05100020
*    TCOMTAB AND THE THIRD WORD IS TO BE USED BY THE VALIDITY         * 05200020
*    CHECK ROUTINE TO PASS A POINTER TO A SECOND LEVEL MESSAGE        * 05300020
*    BACK TO IKJPARS.  THIS ROUTINE IS RESPONSIBLE FOR VALIDITY       * 05400020
*    CHECKING ALL PARAMETERS FOR GO, CALL, AND RUN.                   * 05500020
*                                                                     * 05550020
*         IKJEGBLD-TO BUILD ADDRESS STRING FOR A MESSAGE.             * 05560020
*    REGISTER 0 WILL CONTAIN THE ADDRESS OF THE ADDRESS PARAMETER     * 05570020
*    DESCRIPTOR ENTRY (PDE).  REGISTER 1 WILL CONTAIN A POINTER       * 05580020
*    TO THE AREA THE STRING IS TO BE BUILT IN.  UPON RETURN FROM      * 05590020
*    THE ADDRESS BUILD ROUTINE REGISTER 0 WILL CONTAIN THE LENGTH     * 05592020
*    OF THE ADDRESS STRING AND REGISTER 1 WILL CONTAIN A POINTER      * 05594020
*    TO THE BYTE FOLLOWING THE LAST ONE IN THE ADDRESS STRING.        * 05596020
*                                                                     * 05600020
* INPUT                                                               * 05700020
*    THE REQUESTED FUNCTION WILL BE POINTED TO BY THE INBUF FIELD     * 05800020
*    FOUND IN TCOMTAB.  THE FORMAT OF THE GO STATEMENT IS             * 05900020
*    GO ADDR       WHERE THE ADDRESS IS AN OPTIONAL PARAMETER.        * 06000020
*    THE RUN STATEMENT ALSO HAS THE ADDRESS AS AN OPTIONAL PARAMETER  * 06100020
*    AND ITS FORMAT IS                                                * 06200020
*    RUN ADDR                                                         * 06300020
*    THE CALL STATEMENT HAS THE FOLLOWING FORMAT WITH ALL PARAMETERS  * 06400020
*    OPTIONAL EXCEPT THE ADDRESS PARAMETER.                           * 06500020
*    CALL ADDR PARM(ADDR-LIST) VL RETURN(ADDR)                        * 06600020
*                                                                     * 06700020
* OUTPUT                                                              * 06800020
*    GO AND CALL WILL CAUSE THE EXECUTION OF THE PROBLEM PROGRAM      * 06900020
*    WHICH CHANGES THE MODE TO PROBLEM PROGRAM UNTIL A BREAKPOINT HAS * 07000020
*    BEEN ENCOUNTERED OR UNTIL COMPLETE EXECUTION OF THE PROBLEM      * 07100020
*    PROGRAM, AT WHICH POINT GO AND CALL CHANGE THE MODE BACK TO THE  * 07200020
*    COMMAND MODE IN WHICH TEST COMMANDS MAY BE ENTERED.              * 07300020
*    RUN CAUSES THE EXECUTION OF THE PROBLEM PROGRAM WHICH CHANGES THE* 07400020
*    MODE TO PROBLEM PROGRAM AND UPON COMPLETION OF EXECUTION THE MODE* 07500020
*    WILL REMAIN PROBLEM PROGRAM.  RUN WIPES OUT ALL TRACES OF TEST.  * 07600020
*                                                                     * 07700020
* EXTERNAL REFERENCES                                                 * 07800020
*                                                                     * 07900020
*         IKJPARS-TO VALIDITY CHECK AND SCAN THE COMMAND BUFFER.      * 08000020
*    REGISTER 1 WILL POINT TO A 7 WORD PARAMETER LIST.                * 08100020
*                                                                     * 08200020
*         IKJEGCVT-TO CONVERT THE ADDRESS TO BINARY.  REGISTER 1      * 08300020
*    WILL BE THE ADDRESS COMPLEMENT OF THE ADDRESS PDE.  REGISTER 0   * 08400020
*    WILL BE POSITIVE TO INDICATE BINARY CONVERSION.                  * 08500020
*                                                                     * 08600020
*         IKJEGIO-TO WRITE DIAGNOSTIC MESSAGES.  REGISTER 1 WILL      * 08700020
*    POINT TO A TWO WORD PARAMETER LIST.  THE FIRST WORD WILL BE A    * 08800020
*    POINTER TO THE FIRST LEVEL MESSAGE.  THE SECOND WORD WILL        * 08900020
*    BE A POINTER TO THE SECOND LEVEL MESSAGE OR ZERO IF NO           * 09000020
*    SECOND LEVEL MESSAGE EXISTS.                                     * 09100020
*    NOTE  REGISTER 1 WILL BE A NEGATIVE POINTER                      * 09200020
*                                                                     * 09300020
*         IKJEGBLD-TO BUILD ADDRESS STRING FOR A MESSAGE. REGISTER 0  * 09400020
*    WILL CONTAIN THE ADDRESS OF THE ADDRESS PARAMETER DESCRIPTOR     * 09500020
*    ENTRY (PDE).  REGISTER 1 WILL CONTAIN A POINTER TO THE AREA      * 09600020
*    THE STRING IS BEING BUILT IN.  UPON RETURN FROM THE ADDRESS      * 09650020
*    BUILD ROUTINE REGISTER 0 WILL CONTAIN THE LENGTH OF THE ADDRESS  * 09700020
*    STRING AND REGISTER 1 WILL CONTAIN A POINTER TO THE BYTE         * 09750020
*    FOLLOWING THE LAST ONE IN THE ADDRESS STRING.                    * 09800020
*                                                                     * 10200020
* EXITS, NORMAL                                                       * 10300020
*                                                                     * 10400020
*         IKJPARS-VIA BRANCH REGISTER 14 FROM ADDRCHK WITH ONE OF THE * 10450020
*    FOLLOWING RETURN CODES IN REGISTER 15-                           * 10550020
*    0   INDICATING TO CONTINUE PROCESSING THE COMMAND BUFFER         * 10700020
*    8   INDICATING IKJPARS SHOULD PROMPT WITH REENTER                * 10800020
*    12  INDICATING IKJPARS SHOULD RETURN TO IKJEGGO WITH A RETURN    * 10850020
*    *   CODE OF 20                                                   * 10860020
*                                                                     * 10900020
*         IKJEGMNL-VIA BRANCH REGISTER 14 FROM IKJEGCAL AND IKJEGGO   * 10950020
*    WITH ONE OF THE FOLLOWING RETURN CODES IN REGISTER 15-           * 11000020
*    4    NORMAL END OF PROCESSING                                    * 11200020
*    16   INDICATING AN ATTENTION INTERRUPT WAS ENCOUNTERED           * 11300020
*    *    DURING PROCESSING                                           * 11400020
*                                                                     * 11500020
*         IKJEGMNL-VIA BRANCH REGISTER 14 FROM IKJEGRUN WITH ONE      * 11550020
*    OF THE FOLLOWING RETURN CODES IN REGISTER 15-                    * 11600020
*    12   NORMAL END OF PROCESSING                                    * 11700020
*    16   INDICATING AN ATTENTION INTERRUPT WAS ENCOUNTERED           * 11800020
*    *    DURING PROCESSING                                           * 11900020
*                                                                     * 12000020
* EXITS, ERROR                                                        * 12100020
*         IKJEGMNL-VIA BRANCH REGISTER 14 WITH A RETURN CODE OF 20    * 12150020
*    IN REGISTER 15 INDICATING THE STAE RETRY ROUTINE WAS ENTERED.    * 12200020
*                                                                     * 12400020
* TABLES/WORKAREA                                                     * 12500020
*    THIS MODULE USES THE COMMON DSECT OF THE TEST PACKAGE-TCOMTAB.   * 12600020
*    THE WORKAREA CAN BE FOUND AT A DISPLACEMENT OF X'40' FROM THE    * 12700020
*    AREA POINTED TO BY WORKAREA IN TCOMTAB.  THE PARAMETER CONTROL   * 12800020
*    LIST FOR IKJPARS IS BUILT IN THE WORKAREA.  TCOMTAB CONTAINS     * 12900020
*    POINTERS TO THIS MODULE'S SAVEAREA, A POINTER TO THE COMMAND     * 13000020
*    BUFFER, AND A POINTER TO THE OUTPUT BUFFER.                      * 13100020
*                                                                     * 13200020
* ATTRIBUTES                                                          * 13300020
*    REENTRANT, REFRESHABLE                                           * 13400020
*                                                                     * 13500020
* CHARACTER CODE DEPENDENCY                                           * 13600020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL            * 13700020
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT * 13800020
*    TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED  * 13900020
*    SO THAT REDEFINITION OF CHARACTER CONSTANTS, BY REASSEMBLY,      * 14000020
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.         * 14100020
*                                                                     * 14200020
* NOTES                                                               * 14300020
*    ABBREVIATIONS COMMONLY USED IN THE COMMENTS BESIDE THE CODE      * 14400020
*    1.   PDL-PARAMETER DESCRIPTOR LIST                               * 14500020
*    2.   PDE-PARAMETER DESCRIPTOR ENTRY                              * 14600020
*    3.   PCL-PARAMETER CONTROL LIST                                  * 14700020
*    THE COMMENTS ON THE STATEMENTS GENERALLY START IN COLUMN 30.     * 14750020
*    STAERTN IS THE ENTRY POINT TO THE STAE RETRY ROUTINE AND IS      * 14760020
*    ENTERED FROM IKJEGSTA.                                           * 14770020
*********************************************************************** 14800020
         EJECT                                                          14900020
         ENTRY  IKJEGRUN                                                14950020
         ENTRY  IKJEGCAL                                                14960020
         SPACE 3                                                        14970020
L0       EQU    0            LENGTH OF 0                                15000020
L2       EQU    2            LENGTH OF 2                                15100020
L3       EQU    3            LENGTH OF 3                                15200020
L4       EQU    4            LENGTH OF 4                                15300020
D0       EQU    0            DISPLACEMENT OF 0                          15500020
D1       EQU    1            DISPLACEMENT OF 1                          15600020
D4       EQU    4            DISPLACEMENT OF 4                          15700020
D6       EQU    6            DISPLACEMENT OF 6                   A46752 15750021
D8       EQU    8            DISPLACEMENT OF 8                          15800020
D12      EQU   12            DISPLACEMENT OF 12                         15900020
D68      EQU   68            DISPLACEMENT FROM WHERE REGSAVE2 POINTS    16200020
*                            FOR BASE REGISTER FOR RUN GO AND CALL      16300020
B24      EQU   24            USED IN SHIFT INSTRUCTION                  16400020
FACTOR   EQU    3            USED TO CALCULATE MSG DISPLACEMENT         16500020
ZERO     EQU    0            LENGTH OR DISPLACEMENT OF 0                16600020
ONE      EQU    1            LENGTH OR DISPLACEMENT OF 1                16700020
TWO      EQU    2            LENGTH OR DISPLACEMENT OF 2                16800020
THREE    EQU    3            LENGTH OR DISPLACEMENT OF 3                16900020
FOUR     EQU    4            LENGTH OR DISPLACEMENT OF 4                17000020
EIGHT    EQU    8            LENGTH OR DISPLACEMENT OF 8                17100020
TWELVE   EQU   12            LENGTH OR DISPLACEMENT OF 12               17200020
RET16    EQU   16            USED TO SET RETURN CODE FOR IKJEGMNL       17300020
RETCOD20 EQU   20            USED TO SET RETURN CODE FOR IKJEGMNL       17400020
TSTSVC   EQU   97            BREAKPOINT SVC NUMBER.                     17500020
RBOPSW   EQU   16            DISPLACEMENT OF RESUME PSW IN RB.          17600020
RBLINK   EQU   28            DISPLACEMENT OF LINK FIELD IN RB.          17700020
HEXONE   EQU   X'01'         INDICATOR GETMAIN FAILED                   17800020
HEXTHREE EQU   X'03'         INDICATOR LINK FAILED                      17900020
HEXOF    EQU   X'0F'         BINARY '00001111'                          18000020
HEXFF    EQU   X'FF'         INDICATOR OF END OF STAE ABEND TABLE       18200020
MSG1     EQU   1             REPRESENTS MSGS IKJ57421I A AND B          18300020
MSG2     EQU   2             REPRESENTS MSGS IKJ57422I                  18400020
MSG3     EQU   3             REPRESENTS MSGS IKJ57423I A AND B          18500020
MSG4     EQU   4             REPRESENTS MSGS IKJ57424I A AND B          18600020
MSG5     EQU   5             REPRESENTS MSGS IKJ57426I A AND B          18700020
MSG6     EQU   6             REPRESENTS MSGS IKJ57427I A AND B          18800020
         USING TCOMTAB,R9    TCOMTAB ADDRESSABILITY                     19400020
         SPACE                                                          19500020
GO       EQU   *             GO COMMAND OF TEST                         19600020
         SAVE  (14,12),,*    SAVE CALLER'S REGISTERS                    19700020
         LR    R12,R15       ESTABLISH ADDRESSABILITY TO BEGINNING      19730020
         USING IKJEGGO,R12   OF PROGRAM                                 19760020
         LA    R11,FOUR      REG 11 CONTAINS RETURN CODE FROM GO        19800020
         LR    R2,R11        SAVE CODE FOR PARSBILD ROUTINE             19900020
         SPACE                                                          20000020
         BAL   R10,SETUP      SETUP R13 AND ISSUE STAE.                 20200020
INIT     EQU   *                                                        20400020
         TM    TSTFLGS3,NOPARMS  HAS AN ADDRESS BEEN SUPPLIED.          20600020
         BO    RESUME         NO. ADDRESS. JUST CONTINUE.               20800020
         SPACE                                                          21400020
** BUILD PARAMETER LIST AND PARSE THE GO COMMAND.                    ** 21500020
         SPACE                                                          21600020
         L     R4,GOCON      REG 4 CONTAINS GO PARAMETER CONTROL        21700020
*                            LIST (PCL) ADDRESS                         21800020
         BAL   R10,PARSBILD  BUILD PARM LIST (REG 1 RETURN WITH ADDR    21900020
         SPACE                                                          22000020
** CHECK TO SEE IF AN ADDRESS IS SPECIFIED.  IF SO USE IT TO ALTER   ** 22100020
** THE PROGRAM'S RESUME ADDRESS, OTHERWISE BACK THE CURRENT RESUME   ** 22200020
** ADDRESS UP TWO BYTES TO CONTINUE.                                    22300020
         SPACE                                                          22400020
         SR    R5,R5         CLEAR REGISTER 5                           22500020
         L     R7,TSTANSPL   REG 7 CONTAINS ADDRESS OF PDL              22600020
         USING GORUNDUM,R7   ESTABLISH PDL ADDRESSABILITY               22700020
         LA    R7,ADDR       REG 7 CONTAINS ADDR OF ADDRESS PDE         22800020
         USING IKJPARMA,R7   ESTABLISH PDE ADDRESSABILITY               22900020
         O     R5,PDEUSER    REG 5 CONTAINS ADDRESS IF SPECIFIED        23000020
         BZ    RESUME        NONE SPECIFIED, USE RESUME ADDR.           23100020
         SPACE                                                          23200020
SETWAIT  EQU   *             TURN OFF WAIT COUNT                        23300020
         L     R0,PPTCB      ADDR SPECIFIED, REG 0 CONTAINS ADDR OF     23400020
*                            PROBLEM PROGRAM TCB                        23500020
         O     R0,WAITOFF    INDICATE TURN OFF WAIT COUNT.              23600020
         SVC   TSTSVC        TURN IT OFF.                               23700020
         B     PSWSET        SPECIFIED, USE IT.                         23800020
         SPACE                                                          23900020
BREAKTST EQU   *             SET PSEUDO BREAKPOINT                      24000020
** REGISTER 5 CONTAINS THE PRESUMED NEW IC ADDR FOR THE PROGRAM.     ** 24100020
** DETERMINE IF A USER INSERTED BREAKPOINT EXISTS AT THAT ADDR.      ** 24200020
         SPACE                                                          24300020
         L     R4,BREAKTAB   REG 4 CONTAINS ADDR OF FIRST ELEMENT       24400020
         SPACE                                                          24500020
LOOP1    EQU   *                                                        24600020
**THIS CODE TESTS TO SEE IF THE NEW IC IS ON THE BREAK ELEMENT CHAIN ** 24700020
         LTR   R4,R4         IS THIS THE END OF CHAIN                   24800020
         BZ    PSWSET        YES, ADDR NOT A BREAKPOINT                 24900020
         USING BRKELEM,R4    ESTABLISH BREAK ELEMENT ADDRESSABILITY     25000020
         C     R5,BRKADDR    IS ADDR SPECIFIED THIS BREAK ADDR          25100020
         BE    BREAK         YES, GO SET UP TO CHANGE THE IC            25200020
         L     R4,BRKLINK    NO, POINT TO NEXT BREAK ELEMENT            25300020
         B     LOOP1         GO TEST FOR BREAK POINT AT PRESUMED NEW    25400020
*                            IC ADDRESS                                 25500020
         SPACE                                                          25600020
RESUME   EQU   *             SETS UP TO USE RESUME IC                   25700020
         C     R11,RUNCODE   IS THIS A 'RUN' REQUEST                    25800020
         BE    RESET               GO RESET TCB FIELDS          SA53666 25900021
         L     R5,PPTCB      REG 5 POINTS TO THE PROBLEM PROGRAM TCB    26000020
         L     R5,TCBRBP-TCB(L0,R5) REG 5 POINTS TO THE BREAKPOINT      26100020
*                                  SVRB                                 26200020
         L     R5,RBLINK(L0,R5)    REG 5 POINTS TO THE PROBLEM PROGRAM  26300020
*                                  REQUEST BLOCK                        26400020
         L     R5,RBOPSW+D4(L0,R5) PICK UP THE RESUME IC FROM THE OLD   26500020
*                            PSW (RBOPSW) IN THE REQUEST BLOCK          26600020
         LA    R5,D0(L0,R5)  CLEAR HIGH ORDER BYTE                      26700020
         CLC   D0(L2,R5),SVC IS BREAKPOINT INSTR THERE                  26800020
         BE    BREAKTST      YES, CHECK FOR USER-SET BREAKPOINT         26900020
         B     EXIT          NO, GO RETURN TO MAINLINE                  27000020
BREAK    EQU   *                                                        27100020
** SET REGISTER 5 TO POINT TO INSTRUCTION SAVED IN THE BREAK ELEMENT.** 27200020
** THE PROBLEM PROGRAM WILL RESUME AT THAT POINT.                    ** 27300020
         LA    R5,BRKINST    REG 5 CONTAINS ADDRESS OF SAVED INST       27400020
PSWSET   EQU   *             CHANGE IC                                  27600020
         L     R3,PPRB       GET ADDRESS OF PROBLEM PROGRAM REQUEST     27700020
*                            BLOCK                                      27800020
         IC    R3,RBOPSW+D4(R3) GET THE ILC, CC AND PROG MASK FROM      27900020
*                            OLD  PSW                                   28000020
         SLL   R3,B24        PUT IN THE HIGH ORDER BYTE OF REG 3        28100020
         LA    R1,D0(R5)     CLEAR HIGH ORDER BYTE OF REG 1             28200020
         OR    R1,R3         PUT ILC,CC AND PROG MASK OF OLD PSW INTO   28300020
*                            HIGH ORDER BYTE OF REGISTER 1              28400020
         L     R0,PPTCB      REG 0 CONTAINS ADDR OF PP TCB              28500020
         O     R0,ICCHANGE   INDICATE IC CHANGE                         28600020
         SVC   TSTSVC        GO CHANGE THE IC                           28800020
         C     R11,RUNCODE   IS THIS A RUN REQUEST ?            SA53666 28850021
         BE    RESET         YES, GO RESET TCB FIELDS           SA53666 28860021
         SPACE                                                          28900020
EXIT     EQU   *             SET PROPER RETURN CODE (CONTAINED IN R11)  29000020
         LR    R15,R11       PUT RETURN CODE INTO REGISTER 15           29100020
         SPACE                                                          29200020
RETURN   EQU   *             RETURN TO IKJEGMNL                         29300020
         L     R13,D4(L0,R13)     RESET SAVE AREA POINTER               29400020
         RETURN  (14,12),RC=(15)  RETURN TO IKJEGMNL                    29500020
FLUSHIT  EQU   *                                                        29510020
         OI    TSTFLGS4,TSTFLUSH  INDICATE IKJEGMNL SHOULD FLUSH STACK  29520020
EXIT0    EQU   *                                                        29550020
         XR    R15,R15        SET RETURN CODE                           29560020
         B     RETURN         RETURN TO IKJEGMNL                        29570020
ATTNEXIT EQU   *                                                        29600020
         LA    R15,RET16      INDICATE ATTENTION INTERRUPT ENCOUNTERED  29700020
         B     RETURN         GO SET UP TO RETURN TO IKJEGMNL           29800020
CHKRET   EQU   *                                                        29850020
         L     R1,WORKAREA    LOAD ADDR OF WORKAREA                     29852020
         USING TSTCWORK,R1    ESTABLISH ADDRESSABILITY                  29854020
         LA    R6,CWORKCMD    SKIP CONVERT AREA                         29856020
         USING GOWKAREA,R6    ESTABLISH WORKAREA ADDRESSABILITY         29858020
         DROP  R1             RELEASE REGISTER 1 FOR FUTURE USE         29858420
         L     R15,REGSAVE    PUT SAVED RETURN CODE INTO REG 15         29858820
         DROP  R6             RELEASE REGISTER 6 FOR FUTURE USE         29859220
SEVRET   EQU   *                                                        29870020
         B     RETTAB(R15)    GO THROUGH FOLLOWING TABLE INDEXED        29872020
*                             CONTENTS OF REGISTER 15                   29874020
RETTAB   EQU   *                                                        29876020
         B     EXIT0          0-FROM SERVICE ROUTINE-RETURN 0           29878020
         B     EXIT0          4-FROM SERVICE ROUTINE-RETURN 0           29880020
         B     EXIT0          8-FROM SERVICE ROUTINE-RETURN 0           29890020
         B     EXIT0          12-FROM SERVICE ROUTINE-RETURN 0          29892020
         B     RETURN         16-FROM SERVICE ROUTINE-RETURN 16         29894020
         B     RETURN         20-FROM SERVICE ROUTINE-RETURN 20         29896020
         SPACE                                                          29896520
SETUP    EQU   *                                                        29897020
         L     R15,REGSAVE2   SUBCOMMAND SAVE AREA.                     29897520
         ST    R15,D8(R13)    FOWARD POINTER.                           29898020
         ST    R13,D4(R15)    BACK POINTER.                             29898520
         LR    R13,R15        SET REGISTER 13                           29899020
**********************************************************************  29900020
*              ISSUE STAE FOR GO, RUN, AND CALL                      *  30000020
**********************************************************************  30100020
STAECODE EQU   *                                                        30200020
         STM   R14,R12,D12(R13)    SAVE OUR REGISTERS                   30300020
         L     R1,WORKAREA   LOAD ADDR OF WORKAREA                      30400020
         USING TSTCWORK,R1   ESTABLISH ADDRESSABILITY                   30500020
         LA    R6,CWORKCMD   SKIP CONVERT WORKAREA                      30600020
         USING GOWKAREA,R6   ESTABLISH WORKAREA ADDRESSABILITY          30700020
         DROP  R1            RELEASE REGISTER 1 FOR FUTURE USE          30800020
         LA    R5,STATBL     GET ADDRESS OF STAE ABEND TABLE            30900020
         ST    R5,ABENTAB1   SAVE THIS ADDRESS FOR STAE ROUTINE         31000020
         MVC   TSTRETRY+D1(L3),RETRYADR  SAVE ADDRESS OF RETRY ROUTINE  31100020
         LA    R15,STAEAREA  GET ADDRESS OF STAE WORKAREA               31200020
         DROP  R6            RELEASE REGISTER 6 FOR FUTURE USE          31300020
         MVC   D0(STAELEN,R15),STAELIST MOVE STAE LIST FORM INTO        31400020
*                             WORKAREA                                  31500020
         L     R5,TSTSTAE     GET ADDR OF STAE EXIT ROUTINE             31600020
         STAE  (5),MF=(E,(15))  ISSUE STAE MACRO                        31700020
         LTR   R15,R15       RETURN CODE FROM STAE A 0                  31750020
SMTSTAE  DS    0H            SMT LABEL FOR TEST CASES TGO01500          31760020
*                            AND TCAL2900                               31770020
         BNZ   CODE16        NO, GO WRITE MESSAGE                       31800020
         BR    R10            RETURN TO CALLER.                         32800020
         SPACE                                                          34600020
         SPACE                                                          34700020
IKJEGRUN DS    0D            RUN COMMAND OF TEST                        34750020
         SAVE  (14,12),,IKJEGRUN                                        34800020
         L     R12,BASECON-IKJEGRUN(R15)  SETUP BASE REG.               34850020
         LA    R11,TWELVE     SET RUN RETURN CODE.                      34900020
         LR    R2,R11         SET RUN INDICATOR FOR PARSE EXIT.         34950020
         BAL   R10,SETUP      SETUP R13 AND ISSUE STAE.                 35000020
         TM    TSTDCB,HIGHBIT  IS THIS AN OVERLAY MODULE                35050020
         BZ    INIT          NO, GO SET RESUME IC               SA53666 35100021
         LA    R3,MSG3       YES, PREPARE TO WRITE MESSAGE IKJ57423I    35150020
         B     MSGRTN        GO TO THE MESSAGE ROUTINE                  35200020
RESET    EQU   *                                                        35250020
**       RESET TEST BIT AND TCBTRN FIELD FOR ALL TASKS UNDER TEST.   ** 35400020
         SPACE                                                          35500020
         L     R4,TSTTCB     REG 4 CONTAINS ADDR OF TEST'S TCB          35600020
         LA    R8,D0(R4)     CLEAR HIGH ORDER BYTE AND SAVE             35700020
DAU      EQU   *                                                        35800020
         L     R5,D(R4)      GET THE ADDR OF THE LAST DAUGHTER TASK     35900020
         LTR   R5,R5         IS THERE A DAUGHTER TASK                   36000020
         BNZ   PROCESS       YES, GO PROCESS                            36100020
SIS      EQU   *                                                        36200020
         L     R5,S(R4)      NO, GET ADDRESS OF NEXT SISTER TCB IF ONE  36300020
         LTR   R5,R5         WAS THERE A SISTER TASK                    36400020
         BNZ   PROCESS       YES, GO PROCESS                            36500020
MOTH     EQU   *                                                        36600020
         L     R4,M(R4)      NO, GET ADDRESS OF MOTHER TASK             36700020
         LA    R4,D0(R4)     CLEAR HIGH ORDER BYTE                      36800020
         CR    R4,R8         DOES MOTHER TASK = TEST TASK               36900020
         BNE   SIS           NO, GO CHECK FOR ANOTHER SISTER TCB        37000020
RUNRTN   EQU   *                                                        37060020
         B     EXIT           ALL DONE, RETURN TO MAINLINE      SA53666 37120021
PROCESS  EQU   *                                                        37200020
         LA    R5,D0(R5)     CLEAR HIGH ORDER BYTE                      37300020
         CLC   TCBPKF-TCB(ONE,R5),TCBPKF-TCB(R4) DOES THIS TCB HAVE     37350020
*                            THE SAME KEY AS TEST'S TCB                 37400020
         BNE   BUMPTCB       NO, THE TASK IS NOT UNDER TEST             37450020
         LR    R0,R5         R0=TARGET TCB ADDR FOR SVC 97.             37700020
         O     R0,OFFBIT     INDICATE TEST BIT 'OFF'.                   37800020
         SVC   TSTSVC        FLIP THE BIT.                              37900020
         LR    R0,R5         R0=TARGET TCB ADDR FOR SVC 97.             38100020
         O     R0,TRNSET     INDICATE RESET TCBTRN.                     38200020
         SR    R1,R1         R1=NEW TCBTRN VALUE(ZERO).                 38300020
         SVC   TSTSVC        RESET TCBTRN.                              38400020
         SPACE                                                          38600020
BUMPTCB  EQU   *             GET ADDRESS OF NEXT TCB                    38700020
         LR    R4,R5         FIND NEXT TCB UNDER TEST                   38800020
         B     DAU           LOOP UNTIL FINISHED                        38900020
         SPACE                                                          39000020
         SPACE                                                          39600020
IKJEGCAL DS    0D            CALL COMMAND OF TEST                       39900020
         SAVE  (14,12),,IKJEGCAL                                        40200020
         L     R12,BASECON-IKJEGCAL(R15)  SETUP BASE REG.               40500020
         LA    R11,FOUR       RETURN CODE FOR GO.                       40800020
         LA    R2,EIGHT       CALL CODE FOR PARSE VALIDITY EXIT.        41100020
         BAL   R10,SETUP     SETUP R13 AND BRANCH TO STAE               41200020
         SPACE                                                          41400020
** BUILD PARAMETER LIST AND PARSE THE CALL COMMAND.                  ** 41500020
         SPACE                                                          41600020
         L     R4,CALLCON    REG 4 CONTAINS ADDRESS OF CALL'S PARAMETER 41700020
*                            CONTROL LIST                               41800020
         BAL   R10,PARSBILD  GO BUILD PARAMETER LIST FOR IKJPARS        41900020
**IKJPARS BUILDS A PARAMETER DESCRIPTOR LIST (PCL) AND PASSES BACK A ** 42000020
**POINTER TO IT IN TSTANSPL FOUND IN TCOMTAB.                        ** 42100020
         L     R8,TSTANSPL   REG 8 CONTAINS THE PDL ADDR                42200020
         USING CALLDUMM,R8   ESTABLISH ADDRESSABILITY FOR PDL           42300020
         SPACE                                                          42400020
** MOVE PROBLEM PROGRAMS REGISTERS INTO WORKING STORAGE IN ORDER TO  ** 42500020
** MAKE THE REQUESTED CHANGES WITH A SINGLE ISSUANCE OF SVC 97       ** 42600020
         SPACE                                                          42700020
         L     R4,WORKAREA   REG 4 CONTAINS THE COMMON WORKAREA ADDRESS 42800020
         USING TSTCWORK,R4   ESTABLISH WORKAREA ADDRESSABILITY          42900020
         LA    R4,CWORKCMD   REG 4 CONTAINS COMMAND WORKAREA ADDRESS    43000020
         DROP  R4            RELEASE REGISTER FOR FUTURE USE            43050020
         L     R5,PPTCB      REG 5 CONTAINS THE ADDR OF THE PROBLEM     43100020
*                            PROGRAM TASK CONTROL BLOCK (TCB)           43200020
         USING TCB,R5        ESTABLISH TCB ADDRESSABILITY               43300020
         L     R6,TCBRBP     REG 6 CONTAINS THE ADDR OF SVC 97 SVRB     43400020
         MVC   ZERO(REGS,R4),RBLEN(R6) MOVE PROBLEM PROGRAM'S REGISTERS 43500020
*                            INTO COMMAND'S WORKAREA                    43600020
REGS     EQU   64            LENGTH OF REGISTER SAVEAREA                43700020
RBLEN    EQU   32            DISPLACEMENT OF REGSAVE AREA INTO SVRB     43800020
         SPACE                                                          43900020
**       CALCULATE AMOUNT OF STORAGE REQUIRED FOR PARAMETER LIST     ** 44000020
         SPACE                                                          44100020
         TM    PARM+ONE,HEXOF WAS PARM SPECIFIED IN CALL COMMAND        44200020
         BZ    NOPARM        NO, BUILD A NULL PARAMETER LIST            44300020
         LA    R7,PARMADDR   YES, GET THE ADDR OF THE FIRST PARM ADDR   44400020
*                            PARAMETER DESCRIPTOR ENTRY (PDE)           44500020
         LA    R6,TWELVE     REG 6 IS AN ACCUMULATOR-HERE IS SET FOR    44600020
*                            LENGTH OF ONE ADDRESS AND TWO CONTROL      44700020
*                            WORDS                                      44800020
LOOP3    EQU   *             EXAMINE PARM CHAIN                         44900020
** THIS CODE DETERMINES THE SIZE OF THE AREA FOR THE PARAMETER LIST  ** 45000020
** THAT IS TO BE BUILT.                                              ** 45100020
         L     R7,PDECHAIN   OBTAIN THE ADDR OF THE NEXT ADDRESS PDE    45200020
         LA    R7,ZERO(R7)   CLEAR HIGH ORDER BYTE                      45300020
         LTR   R7,R7         WAS THERE ANOTHER ADDRESS PDE              45400020
         BZ    BLDLST        NO, ISSUE GETMAIN AND BUILD PARMLIST       45500020
         LA    R6,FOUR(R6)   YES, BUMP ACCUMULATOR                      45600020
         B     LOOP3         GO FIND NEXT ADDR PDE IF ONE EXISTS        45700020
         SPACE                                                          45800020
SMTGET01 DS    0H            SMT LABEL FOR TEST CASE TGO01500           45850020
BLDLST   EQU   *             OBTAIN CORE FOR PARAMETER LIST             45900020
         LR    R0,R6         PUT LENGTH OF GETMAIN INTO REGISTER 0      46000020
         O     R0,SP1        INDICATE SUBPOOL 1 IN HIGH ORDER BYTE      46100020
         GETMAIN R,LV=(0)    ISSUE GETMAIN FOR STORAGE                  46200020
         SPACE                                                          46300020
BLOW1    EQU   *             RESUME ADDRESS IN CASE GETMAIN FAILS       46400020
         LA    R3,CALLPARM   GET ADDRESS OF BEGINNING OF PARAMETER LIST 46500020
*                            CHAINNED FROM A WORD IN TCOMTAB            46600020
         SPACE                                                          46700020
LOOP4    EQU   *             CHECK FOR MORE PARAMETER LISTS             46800020
         OC    ONE(THREE,R3),ONE(R3) ANY MORE PARAMETER LISTS AROUND    46900020
         BZ    ADDL          NO, GO ADD NEW LIST TO THE CHAIN           47000020
         L     R3,ZERO(R3)   YES, GET ADDRESS OF NEXT PARAMETER LIST    47100020
         B     LOOP4         GO SEE IF IT IS LAST ON CHAIN              47200020
         SPACE                                                          47300020
ADDL     EQU   *             ADD NEW PARAMETER LIST TO CHAIN IN TCOMTAB 47400020
         ST    R1,ZERO(R3)   PUT ADDR OF NEW LIST INTO FIRST WORD OF    47500020
*                            LAST ENTRY OF CHAIN                        47600020
         XC    ZERO(EIGHT,R1),ZERO(R1)  ZERO FIRST EIGHT         A46752 47650021
*                            BYTES OF PARAMETER BUFFER           A46752 47660021
         STH   R6,FOUR(R1)   PLACE LENGTH OF NEW LIST INTO THE LENGTH   47700020
*                            FIELD OF NEW ENTRY ON CHAIN                47800020
         LA    R1,D6(R1)     POINT TO HALFWORD OF ZEROS          A46752 47910021
         ST    R1,TWO(R1)    STORE ADDRESS OF HALFWORD OF        A46752 47950021
*                            ZEROS FOR DUMMY PARM LIST           A46752 47960021
         LA    R1,L2(R1)     POINT TO BEGINNING OF ACTUAL        A46752 47970021
*                            PARAMETER ADDRESS LIST              A46752 47980021
         ST    R1,REG1(R4)   REPLACE PP REG 1 CONTENTS                  48200020
REG1     EQU   4             DISPLACEMENT OF REG 1 IN SAVEAREA          48300020
         TM    PARM+ONE,HEXOF WAS PARM SPECIFIED                        48400020
         BZ    VARLIST       NO - CHECK FOR VL KEYWORD           A46752 48700021
         SPACE                                                          48800020
PARMSET  EQU   *                                                        48900020
** BUILD PARAMETER LIST FROM ADDRESS PDE USER FIELDS                 ** 49000020
         LA    R7,PARMADDR   REG 7 CONTAINS ADDR OF FIRST PARAMETER     49100020
*                            ADDRESS PDE                                49200020
         SPACE                                                          49300020
LOOP5    EQU   *             SET UP PARAMETER                           49400020
         MVC   ZERO(FOUR,R1),PDEUSER MOVE ADDR INTO NEW PARAMETER LIST  49500020
         L     R7,PDECHAIN   REG 7 POINTS TO NEXT ADDRESS PDE           49600020
         LA    R7,ZERO(R7)   CLEAR HIGH ORDER BYTE                      49700020
         LTR   R7,R7         WERE THERE ANY MORE PDES                   49800020
         BZ    VARLIST       NO, CHECK IF LIST IS VARIABLE LENGTH       49900020
         LA    R1,FOUR(R1)   YES, BUMP LIST POINTER                     50000020
         B     LOOP5         AND GO MOVE NEXT ADDR INTO NEW LIST        50100020
         SPACE                                                          50200020
NOPARM   EQU   *             NO PARAMETERS WERE GIVEN                   50300020
         LA    R6,TWELVE     SET ACCUMULATOR FOR ONE ELEMENT            50400020
         B     BLDLST        GO GETMAIN FOR PARAMETER LIST              50500020
         SPACE                                                          50600020
VARLIST  EQU   *             CHECK FOR 'VL' SPECIFIED                   50700020
         TM    VLIST+ONE,HEXOF  WAS 'VL' SPECIFIED                      50800020
         BZ    RETNCHK          NO, GO CHECK FOR RETURN KEYWORD         50900020
         OI    ZERO(R1),HIGHBIT YES, FLAG HIGH ORDER BYTE OF LAST       51000020
*                               ELEMENT OF LIST WITH A X'80'            51100020
         SPACE                                                          51200020
RETNCHK  EQU   *              IF THE RETURN KEYWORD IS SPECIFIED,       51300020
* SET THE CONTENTS OF PP REG 14 TO THE SPECIFIED ADDRESS, OTHERWISE     51400020
* POINT REG 14 TO A BREAK SVC IN THE TCOMTAB.                           51500020
         SPACE                                                          51600020
         TM    RETKEY+ONE,HEXOF WAS 'RETURN' SPECIFIED                  51700020
         BZ    BREAKIT        NO, SET REG 14 FOR BREAK                  51800020
         LA    R7,RETADDR     REG 7 CONTAINS ADDRESS OR RETURN ADDR PDE 51900020
         MVC   REG14(FOUR,R4),PDEUSER MOVE ADDR INTO REG 14             52000020
         B     ZAPREGS        RESET ALL PP REGS                         52100020
         SPACE                                                          52200020
BREAKIT  EQU   *              SET REG 14                                52300020
         LA    R7,PPEXIT      REG 7 CONTAINS ADDR OF BREAK SVC          52400020
         ST    R7,REG14(R4)   RESET REGISTER 14 WITH THIS ADDRESS       52500020
REG14    EQU   56             DISPLACEMENT OF REG 14 IN SAVE AREA       52600020
         SPACE                                                          52700020
ZAPREGS  EQU   *              RESTORE ALL PP REGS, PICKING UP CHANGES   52800020
         SPACE                                                          52900020
         LA    R7,BRADDR      REG 7 CONTAINS ADDR OF BRANCH ADDR PDE    53000020
         L     R5,PDEUSER     REG 5 CONTAINS THE BRANCH ADDRESS         53100020
         ST    R5,REG15(R4)   PLACE ENTRY ADDR IN PP R15.               53200020
REG15    EQU   60             DISPLACEMENT OF REG 15 IN SAVE AREA.      53300020
         L     R0,PPTCB       REG 0 CONTAINS TCB PARM FOR SVC 97        53400020
         O     R0,REGSET      INDICATE REGISTER CHANGE.                 53500020
         LR    R1,R4          REG 1 CONTAINS REG PARM FOR SVC 97        53600020
         O     R1,ALLREGS     INDICATE REPLACE OF ALL 16 REGISTERS      53700020
         SVC   TSTSVC         ZAP 'EM                                   53800020
**HAVING SET ADDRESS AT WHICH PROBLEM PROGRAM IS TO RESUME EXECUTION**  53900020
**IN REGISTER 5 AND A 'GO' RETURN CODE IN REGISTER 11, ENTER 'GO'   **  54000020
**LOGIC TO EFFECT RESET OF RIGHT-HALF PP RBOPSW AND RETURN TO       **  54100020
**IKJEGMNL.                                                         **  54200020
         SPACE                                                          54300020
         SPACE                                                          54400020
         B     SETWAIT        ENTER 'GO' LOGIC                          54500020
         SPACE                                                          54600020
ADDRCHK  EQU   *              THIS SECTION ACTS AS A VALIDITY CHECK     54700020
* EXIT FOR PARSE FOR ALL ADDRESS PARAMETERS FOR GO, RUN, OR CALL        54800020
         SAVE  (14,12),,ADDRCHK                                         55200020
         L     R12,BASECON-ADDRCHK(R15)   SETUP BASE REG.               55400020
         L     R9,FOUR(R1)    REG 9 CONTAINS ADDRESS OF TCOMTAB         55600020
         L     R7,ZERO(R1)    REG 7 CONTAINS ADDRESS OF ADDRESS PDE     55700020
         LA    R8,D8(R1)      SAVE ADDRESS OF THIRD WORD IN LIST        55800020
         L     R4,REGSAVE3    REG 4 CONTAINS NEW SAVEAREA ADDRESS       55900020
         ST    R13,FOUR(R4)   STORE BACK POINTER.                       56000020
         ST    R4,EIGHT(R13)  STORE FORWARD POINTER.                    56100020
         LR    R13,R4         SET NEW SAVE ADDR IN REG 13               56200020
         OC    PDEINDCT(TWO),PDEINDCT WAS INDIRECT ADDRESSING SPECIFIED 56300020
         BNZ   CONVERT        YES, VALID STORAGE ADDR, CONVERT IT       56400020
         TM    PDEFLG4,GENR+LFPR+SFPR WAS REG TYPE ADDRESSING USED      56500020
         BNZ   BUMRTURN       YES, INVALID ADDR, REQUEST MSG & PROMPT   56600020
         SPACE                                                          56700020
CONVERT  EQU   *              CONVERT THE ADDRESS, USING IKJEGCVT       56800020
         SPACE                                                          56900020
         LR    R1,R7          REG 1 CONTAINS ADDR OF ADDRESS PDE        57000020
         LCR   R1,R1          NEGATIVE FOR ADDR CONVERSION              57100020
         SR    R0,R0          REG 0 IS POSITIVE TO INDICATE BINARY      57200020
*                             CONVERSION                                57300020
         L     R15,TSTCONVT   REG 15 CONTAINS ADDR OF IKJEGCVT ENTRY PT 57400020
         BALR  R14,R15        ATTEMPT TO CONVERT THE ADDRESS            57500020
         LPR   R1,R1          RESTORE REGISTER 1 TO POSITIVE            57600020
         B     RETAB(R15)     BRANCH THROUGH FOLLOWING TABLE INDEXED    57700020
*                             BY CONTENTS IN REGISTER 15                57800020
RETAB    EQU   *                                                        57900020
         B     RET0           0-CONTINUE PROCESSING                     58000020
         B     SETMSG         4-IKJEGCVT CODE-RETURN TO IKJPARS         58100020
         B     SETMSG2        8-IKJEGSYM CODE-RETURN TO IKJPARS         58200020
         B     SETMSG2        12-IO ERROR-RETURN TO IKJPARS             58300020
         B     RETURN12       16-ATTENTION INTERRUPT-RETURN TO PARSE    58400020
         B     RETURN12       20-IKJEGCVT OR IKJEGSYM BLEW              58450020
SETMSG   EQU   *                                                        58500020
**THIS CODE PASSES THE ADDRESS OF A SECOND LEVEL MESSAGE FROM        ** 58600020
**IKJEGCVT OR IKJEGSYM BACK TO IKJPARS.  THE ADDRESS IS PICKED UP IN ** 58700020
**THE PDEUSER WORD AND PLACED IN THE THIRD WORD OF THE PARAMETER LIST** 58800020
**PASSED BY IKJPARS.  IF NO SECOND LEVEL EXISTS THE PDEUSER WORD WILL** 58900020
**WORD WILL CONTAIN X'FF000000'                                      ** 59000020
         MVC   D0(L4,R8),PDEUSER   PUT ADDR SECOND LEVEL MSG INTO       59100020
*                                  PARAMETER LIST                       59200020
RETURN8  EQU   *                                                        59250020
         LA    R15,EIGHT     SET RETURN CODE TO IKJPARS TO 8            59260020
         B     CHKRTURN      GO SET UP TO RETURN TO IKJPARS             59270020
SETMSG2  EQU   *                                                        59500020
         MVC   D0(L4,R8),PDEUSER   PUT ADDRESS OF SECOND LEVEL MESSAGE  59600020
*                                  INTO PARAMETER LIST                  59700020
RETURN12 EQU   *                                                        59750020
         L     R1,WORKAREA    LOAD ADDR OF WORKAREA                     59760020
         USING TSTCWORK,R1    ESTABLISH ADDRESSABILITY                  59760420
         LA    R6,CWORKCMD    SKIP CONVERT AREA                         59760820
         USING GOWKAREA,R6    ESTABLISH WORKAREA ADDRESSABILITY         59761220
         DROP  R1             RELEASE REGISTER 1 FOR FUTURE USE         59761620
         ST    R15,REGSAVE    SAVE RETURN CODE FOR LATER USE            59761720
         DROP  R6             RELEASE REG 6 FOR FUTURE USE              59761820
         LA    R15,TWELVE     SET RETURN CODE FOR IKJPARS               59770020
         B     CHKRTURN       GO RETURN TO IKJPARS                      59780020
RET0     EQU   *                                                        59900020
         TM    PDEUSER,HIGHBIT IS ADDRESS IN SYM INFO BLOCK             60000020
HIGHBIT  EQU   B'10000000'    HIGH ORDER BIT MASK.                      60100020
         BZ    SET0           NO, LEAVE PDEUSER FIELD ALONE             60200020
         L     R1,PDEUSER     YES, REG 1 CONTAINS ADDR OF SYM INFO      60300020
*                             BLOCK                                     60400020
         MVC   PDEUSER(FOUR),ZERO(R1) MOVE ACTUAL ADDRESS INTO PDEUSER. 60500020
SET0     EQU   *                                                        60600020
         MVI   PDEUSER,PDECONVD    INDICATE ADDRESS CONVERTED   SA53665 60650021
         XR    R15,R15        INDICATE VALID PARAMETER TO IKJPARS       60700020
CHKRTURN EQU   *                                                        60800020
         L     R13,FOUR(R13)  RESET REGISTER 13 TO RETURN TO IKJPARS    60900020
         RETURN (14,12),RC=(15) RETURN TO IKJPARS                       61000020
BUMRTURN EQU   *                                                        61700020
** BUILD MESSAGE TO INFORM USER ADDRESS IS INCORRECTLY SPECIFIED.    ** 61800020
         L     R6,ADDRMSG     GET ADDRESS OF MESSAGE CSECT              61900020
         USING IKJEGMSG,R6    ESTABLISH ADDRESSABILITY TO MSG CSECT     62000020
         LA    R3,MSG006      POINT TO MSG006 - MSG ADDR LIST           62100020
         DROP  R6             RELEASE REGISTER 6                        62200020
         MVC   D0(L4,R8),D4(R3)   PUT ADDR OF 2ND LEVEL MSG INTO        62300020
*                             PARAMETER LIST TO IKJPARS                 62400020
         L     R5,OUTBUF      GET ADDRESS OF OUTPUT BUFFER              62500020
         L     R1,WORKAREA    GET ADDRESS OF GENERAL WORKAREA           62600020
         USING TSTCWORK,R1    GET ADDRESSABILITY TO DSECT               62700020
         LA    R6,CWORKCMD    SKIP CONVERT AREA                         62800020
         USING GOWKAREA,R6    ESTABLISH ADDRESSABILITY TO WORKAREA      62900020
         DROP  R1             RELEASE REGISTER 1                        63000020
         ST    R5,ADDRONE     SAVE ADDRESS OF 1ST LEVEL MSG             63100020
         XC    D0(L4,R5),D0(R5) CLEAR 1ST HALFWORD OF OUTPUT BUFFER     63400020
         MVC   ADDRTWO(L4),D4(R3)  PUT ADDR OF 2ND LEVEL MSG INTO       63450020
*                             PARMLIST FOR IO ROUTINE                   63452020
         L     R3,D0(R3)      POINT TO FIRST LEVEL MSG                  63454020
         LH    R8,D0(R3)      GET LENGTH OF MESSAGE                     63600020
         EX    R8,MOVEMSG     GO MOVE MSG INTO OUTPUT BUFFER            63800020
         AR    R5,R8          UPDATE POINTER TO NEXT AVAILABLE          64000020
*                             POSITION                                  64100020
         LR    R0,R7          PASS ADDR OF ADDRESS PDE TO ADDRESS       64200020
*                             BUILD ROUTINE                             64300020
         LR    R1,R5          PASS POINTER TO AREA TO PUT ADDR          64400020
*                             STRING BUILT BY ADDRESS ROUTINE           64500020
         L     R15,TSTADDR    GET ADDRESS OF ADDRESS ROUTINE            64600020
         BALR  R14,R15        GO TO ADDRESS BUILD ROUTINE               64700020
         AR    R8,R0          UPDATE LENGTH OF MESSAGE TO INCLUDE       64800020
*                             ADDRESS STRING                            64900020
         MVI   D0(R1),PLUSSIGN    INDICATE SECOND LEVEL MSG EXISTS      65000020
         LA    R8,D1(R8)      UPDATE LENGTH OF MESSAGE                  65100020
         L     R5,ADDRONE     GET ADDR OF BEGINNING OF OUTPUT BUFFER    65200020
         STH   R8,D0(R5)      PUT LENGTH OF MSG INTO BEGINNING OF       65300020
*                             OUTPUT BUFFER                             65400020
         LA    R1,ADDRONE     GET ADDR OF BEGINNING OF ADDR LIST        65500020
         DROP  R6             RELEASE REGISTER 6 FOR FUTURE USE         65600020
         LNR   R1,R1          NEGATE REG 1 WITH ADDR COMPLEMENT         65700020
         L     R15,TPUTADDR   LOAD ADDRESS OF IKJEGIO                   65800020
         BALR  R14,R15        OUTPUT THE MESSAGE                        65900020
         LTR   R15,R15        RETURN FROM IO A ZERO                     66050020
         BZ    RETURN8        YES, MESSAGE WAS WRITTEN-RETURN           66100020
         B     RETURN12       NO, MESSAGE WAS NOT WRITTEN-RETURN        66150020
MOVEMSG  MVC   D4(L0,R5),D4(R3)  MOVE 1ST LEVEL MSG INTO BUFFER         66900020
         SPACE                                                          67000020
PARSBILD EQU   *              THESE INSTRUCTIONS BUILD A STANDARD PARSE 67100020
* PARAMETER LIST AND LINK TO IKJPARS.  THE PCL ADDRESS TO BE USED IS    67200020
* PASSED BY THE CALLER IN REG 4.  REGS 1 AND 5 ARE CLOBBERED.           67300020
         LR    R1,R6          REGISTER 1 CONTAINS ADDR OF GENERAL       67400020
*                             WORKAREA                                  67500020
         USING PPL,R1         ESTABLISH ADDRESSABILITY TO PARSE         67800020
*                             PARAMETER LIST                            67900020
         MVC   PPLUPT(L4),TSTUPT  PUT ADDR UPT INTO PARAMETER LIST      68000020
         MVC   PPLECT(L4),TSTECT  PUT ADDR ECT INTO PARAMETER LIST      68100020
         MVC   PPLECB(L4),TSTCPECB PUT ADDR ECB INTO PARAMETER LIST     68200020
         ST    R4,PPLPCL     PUT ADDR OF PCL INTO PARAMETER LIST        68300020
         LA    R5,TSTANSPL        PUT POINTER TO ANSWER PLACE INTO      68400020
         ST    R5,PPLANS          PARAMETER LIST TO IKJPARS             68500020
         MVC   PPLCBUF(L4),INBUF  PUT ADDRESS OF COMMAND BUFFER INTO    68600020
*                                 PARAMETER LIST FOR PARSE              68700020
         ST    R9,PPLUWA          PUT ADDRESS OF TCOMTAB INTO LIST      68800020
         DROP  R1             DROP ADDRESSABILITY TO PARSE PARAMETER    68900020
*                             LIST                                      69000020
         LINK  EP=IKJPARS     PARSE THE COMMAND.                        69100020
PARSBLOW EQU   *              LABEL USED BY STAE RETRY ROUTINE          69200020
SMTPARS  DS    0H             SMT LABEL FOR TEST CASES TGO01500 AND     69250020
*                             TCAL2800                                  69260020
         B     PARSTAB(R15)   GO HANDLE RETURN CODE FROM IKJPARS        69300020
PARSTAB  EQU   *                                                        69400020
         B     CODE0          0-CONTINUE PROCESSING                     69500020
         B     FLUSHIT        4-GO BACK TO IKJEGMNL                     69600020
         B     ATTNEXIT       8-ATTENTION ENCOUNTERED-EXIT              69700020
         B     CODE12         12-GO WRITE PROPER MESSAGE                69800020
         B     CODE16         16-GO WRITE PROPER MESSAGE                69900020
         B     CHKRET         20-RETURN TO IKJEGMNL                     70000020
CODE0    EQU   *                                                        70100020
         BR    R10            GO BACK TO CALLING ROUTINE                70200020
CODE12   EQU   *                                                        72100020
** REGISTER 2 CONTAIN A CODE INDICATING WHICH ROUTINE USED IKJPARS   ** 72200020
** THE FOLLOWING BRANCH TABLE IS USED TO FIND THE APPROPRIATE MESSAGE** 72300020
         B     MSGTAB2(R2)    GO TO PROPER ROUTINE                      72400020
MSGTAB2  EQU   *                                                        72500020
         NOP   MSGTAB2        NO FUNCTION EXISTS                        72600020
         B     GOMSG2         4-CODE FOR GO                             72700020
         B     CALLMSG2       8-CODE FOR CALL                           72800020
         B     RUNMSG2        12-CODE FOR RUN                           72900020
GOMSG2   EQU   *                                                        73000020
         LA    R3,MSG1        INDICATE MESSAGE NUMBER                   73100020
         B     MSGRTN         GO TO MESSAGE ROUTINE                     73200020
CALLMSG2 EQU   *                                                        73300020
         LA    R3,MSG5        INDICATE MESSAGE NUMBER                   73400020
         B     MSGRTN         GO TO MESSAGE ROUTINE                     73500020
RUNMSG2  EQU   *                                                        73600020
         LA    R3,MSG4        INDICATE MESSAGE NUMBER                   73700020
         B     MSGRTN         GO TO MESSAGE ROUTINE                     73800020
CODE16   EQU   *                                                        73900020
         LA    R3,MSG2        INDICATE MESSAGE NUMBER                   74000020
         B     MSGRTN         GO TO MESSAGE ROUTINE                     74100020
STAERTN  EQU   *                                                        74200020
         SPACE                                                          74300020
         SPACE                                                          74400020
*********************************************************************   74500020
*                    STAE EXIT ROUTINE                              *   74600020
*********************************************************************   74700020
         SPACE                                                          74800020
         DROP  R5             DROP PREVIOUS ADDRESSABILITY TO TCB       74850020
         L     R2,CVTPTR      GET CVT ADDRESS                           74900020
         USING CVTDSECT,R2    ESTABLISH ADDRESSABILITY TO CVT           75000020
         L     R2,CVTTCBP     GET ADDRESS OF TCB WORDS                  75100020
         L     R2,D4(R2)      GET ADDRESS OF CURRENT TCB                75200020
         DROP  R2             DROP ADDRESSABILITY TO CVT                75300020
         USING TCB,R2         ESTABLISH ADDRESSABILITY TO TCB           75400020
         L     R9,TCBTRN      PICK UP POINTER TO TCOMTAB FROM           75500020
*                             TCBTRN FIELD OF TEST'S TCB                75600020
         L     R13,REGSAVE2   GET ADDR OF GO, CALL, RUN REGISTERS       75700020
         L     R12,D68(R13)   RESET ADDRESSABILITY                      75800020
         LTR   R0,R0          IS WORKAREA AVAILABLE                     75900020
         BNZ   NOWORK         NO, GO SET RETURN CODE FOR IKJEGMNL       76000020
         FREEMAIN R,LV=104,A=(1) YES, FREE AREA                         76100020
NOWORK   EQU   *                                                        76200020
         LA    R15,RETCOD20   SET RETURN CODE FOR IKJEGMNL INDICATING   76300020
*                             STAE EXIT ROUTINE ENTERED                 76400020
         B     RETURN         GO SET UP TO RETURN TO IKJEGMNL           76500020
MSGRTN   EQU   *                                                        76600020
         L     R1,ADDRMSG     OBTAIN ADDRESS OF MESSAGE CSECT           76700020
         SLA   R3,FACTOR      CALCULATE MESSAGE DISPLACEMENT            76800020
         AR    R1,R3          ADDR OF MSG=ADDR MSG CSECT PLUS MSG       76900020
*                             DISPLACEMENT                              77000020
         LA    R3,EIGHT       GO BACK 8 BYTES FOR CORRECT               77100020
         SR    R1,R3          DISPLACEMENT                              77200020
         LNR   R1,R1          NEGATE REGISTER 1 WITH ADDR COMPLEMENT    77300020
         L     R15,TPUTADDR   OBTAIN ADDR OF IKJEGIO FROM TCOMTAB       77400020
         BALR  R14,R15        GO TO IKJEGIO TO HAVE MESSAGE OUTPUTTED   77500020
         LPR   R1,R1          RESTORE REGISTER 1 TO POSITIVE            77600020
         LA    R1,RET16       WAS RETURN CODE FROM IKJEGIO              77700020
         CR    R15,R1         A 16                                      77800020
         BE    ATTNEXIT       YES, INDICATE ATTENTION ENCOUNTERED       77900020
         B     EXIT0          NO, RETURN TO IKJEGMNL                    78000020
         EJECT                                                          78100020
IKJEGPAR  IKJPARM DSECT=GORUNDUM                                        78200020
ADDR     IKJPOSIT ADDRESS,VALIDCK=ADDRCHK                               78300020
         IKJENDP                                                        78400020
IKJEGPAS IKJPARM DSECT=CALLDUMM                                         78500020
BRADDR   IKJPOSIT ADDRESS,PROMPT='BRANCH ADDRESS',VALIDCK=ADDRCHK       78600020
PARM     IKJKEYWD                                                       78700020
         IKJNAME  'PARM',SUBFLD=PARMSFLD                                78800020
VLIST    IKJKEYWD                                                       78900020
         IKJNAME 'VL'                                                   79000020
RETKEY   IKJKEYWD                                                       79100020
         IKJNAME 'RETURN',SUBFLD=RETSFLD                                79200020
PARMSFLD IKJSUBF                                                        79300020
PARMADDR IKJPOSIT ADDRESS,LIST,VALIDCK=ADDRCHK,PROMPT='PARAMETER ADDRESX79400020
               S(ES)'                                                   79500020
RETSFLD  IKJSUBF                                                        79600020
RETADDR  IKJPOSIT ADDRESS,VALIDCK=ADDRCHK,PROMPT='RETURN ADDRESS'       79700020
         IKJENDP                                                        79800020
         EJECT                                                          79900020
* * * * * * * * * * * * * * * CONSTANTS * * * * * * * * * * * * * * *   80000020
RET4     DC    A(4)           GO/CALL RETURN CODE                       80100020
RUNCODE  DC    A(12)          RUN RETURN CODE                           80200020
SP1      DC    X'01000000'    SUBPOOL 1 INDICATOR                       80300020
ALLREGS  DC    X'FF000000'    ALL REGISTER REPLACE CODE FOR SVC 97      80400020
REGSET   DC    X'04000000'    REGISTER SET ENTRY CODE FOR SVC 97        80500020
OFFBIT   DC    X'20000000'    TEST LIST 'OFF' ENTRY CODE FOR SVC 97     80600020
TRNSET   DC    X'10000000'    TCBTRN RESET ENTRY CODE FOR SVC 97        80700020
WAITOFF  DC    X'01000000'    WAIT RESET ENTRY CODE FOR SVC 97          80800020
GOCON    DC    V(IKJEGPAR)    ADDRESS OF GO/RUN PCL                     81000020
CALLCON  DC    V(IKJEGPAS)    ADDRESS OF CALL PCL                       81100020
BASECON  DC    A(IKJEGGO)     PROGRAM BASE ADDRESS                      81200020
ICCHANGE DC    X'08000000'    RBOPSW IC CHANGE CODE                     81300020
ADDRMSG  DC    V(IKJEGMSG)    ADDRESS OF MESSAGE CSECT                  81400020
SVC      SVC   TSTSVC         BREAKPOINT SVC INSTRUCTION                81500020
RETRYADR DC    AL3(STAERTN)   ADDRESS OF STAE EXIT ROUTINE              81600020
**  THE FOLLOWING IS THE STAE MESSAGE TABLE                          ** 81700020
STATBL   DS    0F                                                       81800020
         DC    AL1(HEXONE),AL3(BLOW1)       GETMAIN FAILED              81900020
         DC    AL1(HEXTHREE),AL3(PARSBLOW)  PARSE LINK FAILED           82000020
         DC    AL1(HEXFF)                   END OF STAE ABEND TABLE     82100020
STAEL    DS    0F                                                       82200020
STAELIST STAE  STAELIST,MF=L  LIST FORM OF STAE MACRO                   82300020
STAELEN  EQU   *-STAELIST     LENGTH OF LIST FORM OF STAE MACRO         82400020
         EJECT                                                          82500020
IKJEGMSG CSECT                                                          82600020
**THIS IS THE MESSAGE CSECT FOR IKJEGRUN, IKJEGCAL AND IKJEGGO, THE  ** 82700020
**GO, CALL, AND RUN SUBCOMMANDS OF TEST.  THE FIRST SECTION CONTAINS ** 82800020
**ADCONS FOR THE FIRST AND SECOND LEVEL MESSAGES.  THE SECOND ADCON  ** 82900020
**IS ZERO IF NO SECOND LEVEL MESSAGE EXISTS.  THE SECOND SECTION     ** 83000020
**CONTAINS THE MESSAGE ENTRIES.  THE FIRST TWO BYTES OF EACH ENTRY   ** 83100020
**CONTAINS THE LENGTH OF THE ENTIRE ENTRY.  THE NEXT TWO BYTES       ** 83200020
**CONTAIN ZEROES AND THE REST OF THE ENTRY CONTAINS THE MESSAGE TEXT.** 83300020
MSG001   DC    A(MSG421IA)   ADDRESS OF FIRST LEVEL MESSAGE IKJ57421I   83600020
         DC    A(MSG421IB)   ADDRESS OF SECOND LEVEL MESSAGE IKJ57421I  83700020
MSG002   DC    A(MSG422I)    ADDRESS OF FIRST LEVEL MESSAGE IKJ57422I   83800020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    83900020
MSG003   DC    A(MSG423IA)   ADDRESS OF FIRST LEVEL MESSAGE IKJ57423I   84000020
         DC    A(0)          NO SECOND LEVEL MESSAGE                    84100020
MSG004   DC    A(MSG424IA)   ADDRESS OF FIRST LEVEL MESSAGE IKJ424I     84200020
         DC    A(MSG424IB)   ADDRESS OF SECOND LEVEL MESSAGE IKJ57424I  84300020
MSG005   DC    A(MSG426IA)   ADDRESS OF FIRST LEVEL MESSAGE IKJ57426I   84600020
         DC    A(MSG426IB)   ADDRESS OF SECOND LEVEL MESSAGE IKJ57426I  84700020
MSG006   DC    A(MSG427IA)   ADDRESS OF FIRST LEVEL MESSAGE IKJ57427I   84800020
         DC    A(MSG427IB)   ADDRESS OF SECOND LEVEL MESSAGE IKJ57427I  84900020
MSG421IA DS    0H                                                       86600020
         DC    AL2(END421IA-MSG421IA)  LENGTH OF MESSAGE                86700020
         DC    AL2(0)                  TWO BYTES OF ZERO                86800020
         DC    C'IKJ57421I GO FAILED, COMMAND '       MESSAGE TEXT      86900020
         DC    C'SYSTEM ERROR+'                       MESSAGE TEXT      87000020
END421IA EQU   *                                                        87100020
MSG421IB DS    0H                                                       87200020
         DC    AL2(END421IB-MSG421IB)  LENGTH OF MESSAGE                87300020
         DC    AL2(0)                  TWO BYTES OF ZERO                87400020
         DC    C'IKJ57421I PARSE ERROR CODE 12'       MESSAGE TEXT      87500020
END421IB EQU   *                                                        87600020
MSG422I  DS    0H                                                       88200020
         DC    AL2(END422I-MSG422I)    LENGTH OF MESSAGE                88300020
         DC    AL2(0)                  TWO BYTES OF ZERO                88400020
         DC    C'IKJ57422I NOT ENOUGH MAIN '          MESSAGE TEXT      88500020
         DC    C'STORAGE TO EXECUTE COMMAND'          MESSAGE TEXT      88600020
END422I  EQU   *                                                        88700020
MSG423IA DS    0H                                                       88800020
         DC    AL2(END423IA-MSG423IA)  LENGTH OF MESSAGE                88900020
         DC    AL2(0)                  TWO BYTES OF ZERO                89000020
         DC    C'IKJ57423I OVERLAY PROGRAMS NOT SUPPORTED '   MSG TEXT  89600020
         DC    C'BY RUN SUBCOMMAND, USE GO SUBCOMMAND'        MSG TEXT  89660020
END423IA EQU   *                                                        89730020
MSG424IA DS    0H                                                       89800020
         DC    AL2(END424IA-MSG424IA)  LENGTH OF MESSAGE                89900020
         DC    AL2(0)                  TWO BYTES OF ZERO                90000020
         DC    C'IKJ57424I RUN FAILED, COMMAND'       MESSAGE TEXT      90100020
         DC    C' SYSTEM ERROR+'                      MESSAGE TEXT      90200020
END424IA EQU   *                                                        90300020
MSG424IB DS    0H                                                       90400020
         DC    AL2(END424IB-MSG424IB)  LENGTH OF MESSAGE                90500020
         DC    AL2(0)                  TWO BYTES OF ZERO                90600020
         DC    C'IKJ57424I PARSE ERROR CODE 12'       MESSAGE TEXT      90700020
END424IB EQU   *                                                        90800020
MSG426IA DS    0H                                                       92400020
         DC    AL2(END426IA-MSG426IA)  LENGTH OF MESSAGE                92500020
         DC    AL2(0)                  TWO BYTES OF ZERO                92600020
         DC    C'IKJ57426I CALL FAILED, COMMAND '     MESSAGE TEXT      92700020
         DC    C'SYSTEM ERROR+'                       MESSAGE TEXT      92800020
END426IA EQU   *                                                        92900020
MSG426IB DS    0H                                                       93000020
         DC    AL2(END426IB-MSG426IB)  LENGTH OF MESSAGE                93100020
         DC    AL2(0)                  TWO BYTES OF ZERO                93200020
         DC    C'IKJ57426I PARSE ERROR CODE 12'       MESSAGE TEXT      93300020
END426IB EQU   *                                                        93400020
MSG427IA DS    0H                                                       94000020
         DC    AL2(END427IA-MSG427IA)  LENGTH OF MESSAGE                94100020
         DC    AL2(0)                  TWO BYTES OF ZERO                94200020
         DC    C'IKJ57427I INVALID ADDRESS '           MESSAGE TEXT     94300020
END427IA EQU   *                                                        94400020
MSG427IB DS    0H                                                       94500020
         DC    AL2(END427IB-MSG427IB)  LENGTH OF MESSAGE                94600020
         DC    AL2(0)                  TWO BYTES OF ZERO                94700020
         DC    C'IKJ57427I REGISTER NOTATION '         MESSAGE TEXT     94800020
         DC    C'MUST BE INDIRECT GENERAL REGISTER'    MESSAGE TEXT     94900020
END427IB EQU   *                                                        95000020
PLUSSIGN EQU   C'+'          PLUS SIGN FOR INDICATING 2ND LEVEL MSG     95100020
         EJECT                                                          95200020
         SPACE                                                          95300020
         SPACE                                                          95400020
         TCOMTAB                                                        95500020
         EJECT                                                          95600020
         SPACE                                                          95700020
         BRKELEM                                                        95800020
         EJECT                                                          95900020
         SPACE                                                          96000020
         TSTCWORK                                                       96100020
         SPACE                                                          96200020
         SPACE                                                          96300020
         SPACE                                                          96400020
         SPACE                                                          96500020
         SPACE                                                          96600020
         IKJPPL                                                         96700020
         SPACE                                                          96800020
         SPACE                                                          96900020
         SPACE                                                          97000020
         SPACE                                                          97100020
GOWKAREA DSECT                                                          97200020
PPLAREA  DS    7F            PARSE PARAMETER LIST-DESCRIPTION IN PPL    97300020
*                            MACRO EXPANSION                            97400020
ADDRONE  DS    A             ADDRESS OF FIRST LEVEL MESSAGE             97500020
ADDRTWO  DS    A             ADDRESS OF SECOND LEVEL MESSAGE            97600020
REGSAVE  DS    F             SERVICE ROUTINE RETURN CODE SAVEAREA       97650020
STAEAREA DS    3F            STAE WORKAREA                              97700020
         EJECT                                                          97800020
         SPACE                                                          97900020
         IKJPARMA                                                       98000020
         EJECT                                                          98100020
         SPACE                                                          98200020
         IKJTCB                                                         98300020
M        EQU   TCBOTC-TCB    MOTHER TASK                                98400020
S        EQU   TCBNTC-TCB    SISTER TASK                                98500020
D        EQU   TCBLTC-TCB    DAUGHTER TASK                              98600020
         EJECT                                                          98700020
CVTDSECT DSECT                                                          98800020
         CVT                                                            98900020
         EJECT                                                          99000020
         SPACE                                                          99100020
         REGEQU                                                         99200020
         SPACE                                                          99300020
         END                                                            99400020
