         TITLE 'TEST INITIALIZATION           IKJEGINT'                 00080020
*********************************************************************** 00160020
* STATUS --                                                             00240020
*    VERSION NO. 02, OS/360 RELEASE NO. 21                       A43321 00290021
*                                                                       00320020
* FUNCTION --                                                           00400020
*    THIS MODULE RECEIVES CONTROL FROM THE TMP AS THE RESULT OF         00560020
*    A LINK.IT IS THE PRIMARY INITIALIZATION ROUTINE OF THE TEST        00640020
*    CONVERSATIONAL DEBUGGING PACKAGE FOR TSO.THIS ROUTINE ACQUIRES     00720020
*    STORAGE NEEDED BY TEST,LOCATES SUB-COMMANDS VIA BLDL,INITIAL-      00800020
*    IZES THE COMMUNICATION TABLE AND SETS UP INITIAL QUALIFICATION     00880020
*    FOR ANY SUB-TASK WHICH EXISTS.IF NONE EXISTS,THE TEST LOADER       00960020
*    IS ATTACHED TO BRING IN THE REQUESTED PROGRAM AS A SUB-TASK        01040020
*    OF THE TEST TASK.                                                  01120020
*                                                                       01200020
* ENTRY POINTS --                                                       01360020
*    IKJEGINT                                                           01440020
*                                                                       01520020
* INPUT --                                                              01600020
*    TEST PARAMETER LIST (TPL) POINTED TO BY REGISTER 1.                01760020
*                                                                       01840020
* OUTPUT --                                                             01920020
*    TCOMTAB IS INITIALIZED FOR TEST'S MAINLINE ROUTINE                 02080020
*                                                                       02160020
* EXTERNAL REFERENCES --                                                02320020
*         IKJPARS  LINKED - TO PARSE TEST COMMAND.                      02400020
*         IKJEGLDR ATTACHED - TO BRING IN REQUESTED PROGRAM.            02560020
*         IKJEGIO BRANCHED - TO WRITE DIAGNOSTIC MESSAGES.              02610020
*         IKJDAIR LINKED - TO ALLOCATE AND UNALLOCATED DATA SETS        02620020
*         IKJDFLT LINKED - TO DEFAULT THE USER SUPPLIED DS.             02630020
*                                                                       02640020
* EXITS, NORMAL --                                                      02720020
*         XCTL TO IKJEGMNL.                                             02880020
*                                                                       02960020
* EXITS, ERROR --                                                       03040020
*         RETURN TO TMP. RETURN CODE 4.                                 03200020
*                                                                       03280020
* TABLES/WORKAREAS --                                                   03330020
*    TCOMTAB IS THE TEST COMMUNICATION TABLE BUILT BY INITIALIZATION    03340020
*    WORKAREAS HUNG FROM THIS TABLE ARE GOTTEN BY THIS MODULE           03350020
*    OUTBUF, ATTNBUF, CONAREA, BLDLIST, SCPPAD, REGSAVE1-5, SCPP4K      03352020
*                                                                       03354020
* ATTRIBUTES --                                                         03360020
*    RE-ENTRANT.                                                        03520020
*    REFRESHABLE.                                                       03600020
*                                                                       03650020
* CHARACTER CODE DEPENDENCY --                                          03660020
*    NONE                                                               03670020
*                                                                       03672020
* NOTES --                                                              03674020
*    REGISTER CONVENTION FOR INITIALIZATION ARE AS FOLLOWS              03676020
*    REG 9 IS TCOMTAB POINTER                                           03678020
*    REG 10 IS THE TPL(TEST PARAMETER LIST) POINTER                     03678420
*    REG 11 ONLY USED FOR LINK REGISTER                                 03678820
*    REG 12 IS THE BASE REGISTER                                        03679220
*    REGISTER 0,1,14,15 ARE USED BY MOST SUBROUTINE'S BAL-ED TO.        03679620
*                                                                       03680020
*********************************************************************** 03760020
         EJECT                                                          03840020
IKJEGINT CSECT                                                          03920020
*RELEASE 21 CHANGES                                              A43321 03925021
*A286100-287000,288000-288800,297800-304000,353250,863450,       A43321 03930021
*A867250-867700                                                  A43321 03932021
*A625300                                                          M1568 03934021
*D                                                               A43321 03935021
*RELEASE 21.6 CHANGES                                            A52066 03945021
*A626100                                                         A52066 03985021
*D625300                                                         A52066 03995021
*                                                                       04000020
         SAVE  (14,12),,*     SAVE CALLER'S REGS.                       04080020
         LR    R12,R15        ESTABLISH PROGRAM ADDRESSABILITY.         04160020
         USING IKJEGINT,R12   *                                         04240020
INTBASE  EQU   *                                                        04320020
         LR    R10,R1         TPL ADDRESSABILITY.                       04400020
         USING TPL,R10        *                                         04480020
         SPACE                                                          04560020
*        GETMAIN FOR SUFFICIENT STORAGE FOR TCOMTAB.PRIOR TO INIT-      04640020
*        IALIZATION OF TCOMTAB, THE AREA WILL BE USED AS A PARA-        04720020
*        METER LIST FOR A STAE MACRO INSTRUCTION AND A LIST-TYPE        04800020
*                              GETMAIN.                                 04880020
         SPACE                                                          04960020
         LA    R0,TCOMLEN     R0=LV VALUE FOR GETMAIN.                  05040020
         O     R0,SP1         INDICATE SUBPOOL 1.                       05120020
         GETMAIN R,LV=(0)     GET STORAGE FOR TCOMTAB.                  05200020
         SPACE                                                          05280020
         LR    R9,R1          TCOMTAB ADDRESSABILITY.                   05360020
         USING TCOMTAB,R9     *                                         05440020
         SPACE                                                          05520020
*        BUILD PARAMETER LIST AND ISSUE STAE MACRO.                     05600020
         SPACE                                                          05680020
         MVC   TCOMTAB(STAELFLN),STAELF BUILD LIST.                     05760020
         ST    R9,X4(R1)      TCOMTAB IS PARAMETER.                     05840020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT        05920020
         STAE  MF=(E,TCOMTAB) ISSUE STAE MACRO.                         06000020
         XC    TCOMTAB(CLEARLEN),TCOMTAB ZERO OUT TCOMTAB.              06080020
         XC    CLEARLEN(CLEARLN1,R9),CLEARLEN(R9)  ZERO THE REST.       06160020
          L     R4,CVT         CVT ADDR.                                06240020
CVT       EQU   16             DITTO.                                   06320020
          MVC   TSTTOP(X4),CVTMZ00(R4) HIGHEST ADDR. IN MACHINE         06400020
CVTMZ00   EQU   164            HEX 'A4' INTO CVT                        06480020
          L     R4,X0(R4)      NEW-CURRENT ADDR.                        06560020
         MVC   TSTTCB+X1(X3),X5(R4)  TSTTCB=TEST'S TCB                  06640020
         MVC   TGETADDR(N12),IOCONS  MOVE IO'S EPAS TO TCOMTAB.         06720020
         MVC   TSTGO+X6(X2),SVC  PSEUDO BREAKPOINT SVC.                 06800020
         L     R4,TPLCECB     ATTACHED CP ECB ADDRESS.                  06880020
         L     R5,TPLIECB     STAI ECB ADDRESS.                         06960020
         L     R6,TPLAECB     ATTN ECB ADDRESS.                         07040020
         L     R7,TPLMECB     STOP/MODIFY ECB.                          07120020
         STM   R4,R7,ECBTERM  SAVE.                                     07200020
         L     R4,TPLUPT      SETUP PARMLIST.                           07280020
         L     R5,TPLECT      DITTO.                                    07360020
         STM   R4,R6,PARMLIST  UPT ADDR,ECT ADDR,ATTN ECB ADDR          07440020
         LTR   R15,R15        WAS RET.CODE ZERO.                        07520020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT         07600020
         BNZ   NOCORE         NO. ISSUE DIAGNOSTIC AND FADE.            07680020
         SPACE                                                          07760020
         L     R0,TSTTCB      CHANGE TEST'S TCBTRN FIELD W/TCOMTAB      07840020
         O     R0,TCBTRNFL    *                                         07920020
         LR    R1,R9          TCOMTAB TO TCBTRN                         08000020
         SVC   TESTSVC        CHANGE IT.                                08080020
*        BUILD ADDRESS LISTS AND PARAMETER LIST FOR LU-TYPE GETMAIN.    08160020
         SPACE                                                          08240020
         L     R1,SCDSCPP     LOAD UP LENGTHS OF VARIOUS ELEMENTS.      08320020
         LH    R0,X0(R1)      *                                         08400020
         LA    R1,OUTBUFLN    *                                         08480020
         LA    R2,ATNBUFLN    *                                         08560020
         LA    R3,CONARLN     *                                         08640020
         L     R4,SCDBLDL     *                                         08720020
         LH    R4,X0(R4)      *                                         08800020
         LA    R5,CWORKLEN    *                                         08880020
         LA    R6,REGSVLN     *                                         08960020
         STM   R0,R6,GETMNLA  AND STORE IN LA LIST.                     09040020
         OI    LAEND-X4,X80   FLAG END OF LIST.                         09120020
         SPACE                                                          09200020
*        LOAD UP PARAMETER REGISTERS AND ISSUE E-FORM GETMAIN.          09280020
         SPACE                                                          09360020
         LA    R1,TSTCURLD    R1=GETMAIN PARM LIST ADDR.                09440020
         LA    R2,GETMNLA      R2=LA LIST ADDR.                         09520020
         LA    R3,SCPPAD      R3=A LIST ADDR.                           09600020
         GETMAIN LU,LA=(2),A=(3),SP=1,MF=(E,(1)) GET STORAGE ELEMENTS.  09680020
BLOW1    EQU   *              RESUME ADDRESS ON ABEND.                  09760020
         L     R2,REGSAVE1    R2=NEW REGSAVE ADDR.                      09840020
         ST    R13,X4(R2)      SAVE BACKWARD POINTER.                   09920020
         ST    R2,X8(R13)      SAVE FORWARD POINTER.                    10000020
         LR    R13,R2         R13=NEW REGSAVE ADDR.                     10080020
         LA    R3,N72(R2)     2ND SAVE AREA ADDRESS.                    10160020
         LA    R4,N72(R3)     3RD SAVE AREA ADDRESS.                    10240020
         LA    R5,N72(R4)     4TH SAVE AREA ADDRESS.                    10320020
         LA    R6,N72(R5)     5TH SAVE AREA ADDRESS.                    10400020
         STM   R3,R6,REGSAVE2  SET REGSAVE2 THRU REGSAVE5.              10480020
         SPACE                                                          10560020
*        ISSUE A GETMAIN FOR 6K OF STORAGE FROM SUBPOOL 2 TO BE HELD    10640020
*        IN RESERVE FOR TRANSIENT COMMAND PROCESSORS.                   10720020
         SPACE                                                          10800020
         L     R0,CORE6K      SP=2,LENGTH=6144                          10880020
         GETMAIN R,LV=(0)     GET BACK-UP STORAGE FOR S.C. 'S           10960020
BLOW2    EQU   *              RESUME ADDRESS ON ABEND.                  11040020
         SPACE                                                          11120020
*        PLACE CURRENTLY KNOWN ADDRESSES AND VALUES IN TCOMTAB.         11200020
         SPACE                                                          11280020
         ST    R1,SCPP4K      BACK-UP STORAGE ADDRESS TO TCOMTAB.       11360020
         L     R2,SCPPAD      TEST ECB ADDR  TO TCOMTAB.                11440020
         AL    R2,GETMNLA     TEST ECB IS THE LAST WORD OF 'SCPPAD'     11520020
         SL    R2,FOUR        BACK UP BY FOUR.                          11600020
         ST    R2,ECBTST      SAVE TEST ECB ADDRESS.                    11680020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT       11760020
         GTSIZE                                                         11840020
         LR    R11,R1         PUT THE TERMINAL LENGTH IN R11.           11920020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT      12000020
         SLL   R11,N16        SHIFT FOR STORE.                          12080020
         STM   R10,R11,TPLPTR  TPL ADDR TO TCOMTAB.                     12160020
*                             ALSO TERMINAL LINE LENGTH TO TCOMTAB      12240020
         L     R3,WORKAREA    R3=WORKAREA ADDR.                         12320020
         SPACE                                                          12400020
*        BUILD PARAMETER LIST FOR BLDL TO LOCATE ALL COMMANDS IN TEST   12480020
*        MODE.NAMES ARE MOVED INTO EACH ENTRY FROM CONSTANT AREA.       12560020
         SPACE                                                          12640020
         L     R4,SCPP4K      R4=ADDR OF WORK AREA.                     12720020
         L     R5,SCDNAMES    R5=ADDR OF BACK PORTION OF 1ST LOADNAME   12800020
         SR    R8,R8          R8=COUNTER.                               12880020
         LA    R4,X8(,R4)     R4=1ST ENTRY ADDR.                        12960020
         LA    R7,N58          R7=ENTRY LENGTH.                         13040020
LOOP1    EQU   *                                                        13120020
         TM    X0(R5),XFF     Q.ALL ENTRIES INITIALIZED.                13200020
         BZ    BLDL           YES,RESET REGS AND ISSUE BLDL.            13280020
         LA    R8,X1(,R8)     NO,BUMP COUNTER.                          13360020
         MVC   X0(X5,R4),IKJEG FRONT PORTION OF LOAD NAME.              13440020
         MVC   X5(X3,R4),X0(R5) COMPLETE LOAD NAME.                     13520020
         LA    R5,X3(R5)      ADDRESS OF NEXT BACK PORTION.             13600020
         AR    R4,R7          R4=ADDR OF NEXT ENTRY.                    13680020
         B     LOOP1          INITIALIZE NEXT ENTRY.                    13760020
BLDL     EQU   *                                                        13840020
         L     R4,SCPP4K      R4=WORK AREA ADDR.                        13920020
         SR    R5,R5          DCB ADDRESS OF ZERO.                      14000020
         LA    R4,X4(,R4)     R4=BLDL LIST ADDR.                        14080020
         STH   R8,X0(,R4)     PLACE COUNT OF ENTRIES IN LIST.           14160020
         STH   R7,X2(,R4)     PLACE ENTRY LENGTH IN LIST.               14240020
         BLDL  (5),(4)        ISSUE BLDL.                               14320020
         SPACE                                                          14400020
*        CHECK RESULTS OF BLDL.UNLESS THERE WAS A PERMANENT ERROR,      14480020
*        COLLAPSE LIST INFORMATION INTO BLDL TABLE POINTED TO BY        14560020
*        'BLDLIST' IN TCOMTAB.                                          14640020
         SPACE                                                          14720020
         C     R15,EIGHT      Q.WAS THERE A PERMANENT ERROR.            14800020
         BE    BLDLERR        YES,PRINT MESSAGE AND RETURN TO TMP.      14880020
*                             NO,COLLAPSE VALID ENTRIES IN BLDLIST.     14960020
         SPACE                                                          15040020
         LA    R4,X4(,R4)     R4=ADDR OF 1ST ENTRY.                     15120020
         L     R3,SCPPAD      R3=ADDR OF ENTRY POINT TABLE.             15200020
         L     R6,BLDLIST     R6=BLDL TABLE ADDR.                       15280020
         LA    R2,N58(,R6)    R2=1ST COLLAPSED ENTRY ADDR.              15360020
LOOP2    EQU   *                                                        15440020
         XC    X0(X8,R3),X0(R3) LENGTH OF EIGHT IN ORDER TO CLEAR ECB   15520020
         TM    N10(R4),XFF     Q.WAS THIS NAME FOUND BY BLDL.           15600020
         BZ    SKIPNAME       NO,BUMP ENTRY AND SCPP EP TABLE POINTERS. 15680020
         MVC   X0(N58,R6),X0(R4)  MOVE 58 BYTE ENTRY FOR SKELETON       15760020
         MVC   X0(X3,R2),X5(R4)  MOVE NAME.                             15840020
         MVC   X3(X4,R2),N13(R4) MOVE INDICATORS AND 1ST TEXT TTR.      15920020
         MVC   X7(X1,R2),N23(R4)  MOVE BYTE 2 OF MODULE ATTRIBUTES.     16000020
         MVC   X8(X7,R2),N25(R4) MOVE MAIN STORE REQUIREMENTS FOR SC    16080020
*                             MOVE 1ST TEXT RECORD LENGTH               16160020
*                             MOVE ALIAS EP                             16240020
         MVC   N15(X3,R2),N35(R4)  MOVE TRUE NAME OFFSET.               16320020
         MVC   N18(X3,R2),N43(R4)  MOVE TRUE NAME.                      16400020
         ST    R2,X0(,R3)     PLACE COLLAPSED ENTRY ADDR IN EP TABLE.   16480020
         OI    X0(R3),X80     INDICATE THAT IT IS A BLDL ENTRY.         16560020
         LA    R2,SIZE(R2)    NEXT COLLAPSED ENTRY.                     16640020
SKIPNAME EQU   *                                                        16720020
         LA    R3,X4(,R3)     R3=ADDR OF NEXT SLOT IN EP TABLE.         16800020
         AR    R4,R7          R4=NEXT FULL BLDL ENTRY ADDR.             16880020
         BCT   R8,LOOP2       INITIALIZE NEXT COLLAPSED ENTRY.          16960020
         SPACE                                                          17040020
*        LOCATE TEST TCB AND SAVE ADDRESS IN TSTTCB (TCOMTAB).THEN      17120020
*        DETERMINE IF ANY SUB-TASKS EXIST.                              17200020
         SPACE                                                          17280020
         OC    PPTCB(X4),TPLNTCB  MOVE AND TEST ABENDING TCB PTR.       17360020
         BNZ   STAI           YES,ABEND,SKIP NEXT TEST.                 17440020
         OC    PPTCB(X4),TPLCTCB  MOVE AND TEST ATTACHED TCB PTR.       17520020
         BZ    PARSE          IF NO SUB-TASKS,PARSE TEST COMMAND.       17600020
         B     TURNON         TURN ON TEST BIT(S)                       17680020
STAI     EQU   *                                                        17760020
         OI    TSTFLGS3,TSTSTAI  TURN ON STAI INDICATOR FOR SVC97       17840020
         XC    TPLNTCB(X4),TPLNTCB  ZERO ABENDED TCB POINTER.           17920020
TURNON   EQU   *                                                        18000020
         SPACE                                                          18080020
*        SUB-TASK WAS INTERCEPTED THROUGH ATTENTION OR STAI.CHECK ALL   18160020
*        SUB-TASKS FOR DATA SAVED BY SVC 61 (TCBTRN NOT = 0) AND RE-    18240020
*        CHAIN ALL DATA FROM TSTTRN IN TCOMTAB.RESET TCBTRN & TCBTSTCP. 18320020
         SPACE                                                          18400020
          L     R4,TSTTCB       TEST'S TCB.                             18480020
         OI    TSTFLGS4,TSTA  INDICATE NEED FOR A TERMINAL ELEMENT.     18520020
         LA    R8,X0(R4)      CLEAR HIGH BYTE AND SAVE.                 18560020
DAU      L     R5,D(R4)       OBTAIN DAUGHTER.                          18640020
         LTR   R5,R5          IS THERE A DAUGHTER.                      18720020
         BNZ   CHK            YES.PROCESS.                              18800020
SIS      L     R5,S(R4)       OBTAIN SISTER IF ONE.                     18880020
         LTR   R5,R5          IS THERE ONE.                             18960020
         BNZ   CHK            YES.GO PROCESS.                           19040020
MOTH     L     R4,M(R4)       LOAD MOTHER TASK.                         19120020
         LA    R4,X0(R4)      CLEAR HIGH BYTE.                          19200020
         CR    R4,R8          DOES MOTHER = TEST TASK.                  19280020
         BNE   SIS            NO. CHECK SISTER TCB.                     19360020
         B     BREAKIN        YES. DONE....                             19440020
CHK      LA    R5,X0(R5)      CLEAR HIGH BYTE.                          19520020
         BAL   R11,TRNCHECK   CHECK THE TCBTRN FIELD                    19600020
         LR    R4,R5          FIND NEXT TCB UNDER TEST.                 19680020
         B     DAU            LOOP UNTIL DONE.                          19760020
TRNCHECK EQU   *                                                        19840020
         L     R6,TCBTRN-TCB(R5)  TCBTRN MAY CONTAIN A QUEUE.           19920020
         LA    R6,X0(R6)      CLEAR HIGH BYTE                           20000020
         LTR   R6,R6          Q. HAS SVC61 BEEN HERE..                  20080020
         BZ    SETTRN         NO. TURN ON BIT AND SET FIELD.            20160020
         L     R0,CORETRN     SP=1,LENGTH=12                            20240020
*              CONTROL BLOCK=LINK FIELD,TCB FIELD,BLOCK PTR.            20320020
         GETMAIN  R,LV=(0)    GET SVC INFO BLOCK CONTROL WORDS.         20400020
         MVC   X0(X4,R1),TSTTRN LINK FIELD TO PUSH DOWN QUEUE.          20480020
         STM   R5,R6,X4(R1)   TCB ADDR,SVC INFO BLOCK PTR.              20560020
         ST    R1,TSTTRN      HANG CONTROL WORDS TO TSTTRN WORD.        20640020
SETTRN   EQU   *              *                                         20720020
         SPACE                                                          20800020
*        SET UP R0 FOR LINKAGE TO TEST SVC IN ORDER TO TURN ON BIT      20880020
*        TCBTSTCP IN THE TARGET TCB.                                    20960020
         SPACE                                                          21040020
         LR    R0,R5          R0=TARGET TCB ADDR.                       21120020
         O     R0,TSTCPON     INDICATE TCBTSTCP 'ON'.                   21200020
         SVC   TESTSVC        TURN ON BIT.                              21280020
         SPACE                                                          21360020
*        SET R0 AND R1 FOR LINKAGE TO TEST SVC IN ORDER TO REPLACE      21440020
*        THE TCBTRN FIELD WITH THE ADDRESS OF TCOMTAB.                  21520020
         SPACE                                                          21600020
         LR    R0,R5          R0=TARGET TCB ADDR.                       21680020
         LR    R1,R9          R1=NEW VALUE (TCOMTAB ADDR).              21760020
         O     R0,TCBTRNFL    INDICATE ACTION(TCBTRN CHANGE).           21840020
         SVC   TESTSVC        CHANGE TCBTRN.                            21920020
         BR    R11            CHECK THE NEXT TCB UNDER TEST.            22000020
         SPACE                                                          22080020
*        LOCATE PRB FOR PROGRAM BEING TESTED.SET A PSEUDO-BREAKPOINT    22160020
*        AT THE RESUME ADDRESS CONTAINED IN THE RBOPSW.                 22240020
         SPACE                                                          22320020
BREAKIN  EQU   *                                                        22400020
         L     R6,TPLCTCB     MOTHER TASK.                              22480020
         L     R6,TCBFSA-TCB(R6)  INITIAL SAVE AREA.                    22560020
         LA    R4,PPEXIT      'NORMAL TERMINATION' EXIT.                22640020
         ST    R4,N12(R6)     *                                         22720020
         L     R7,PPTCB       THE ABEND TASK OR THE HIGHEST TASK (ATTN) 22800020
         L     R2,TCBRBP-TCB(R7)  1ST RB.                               22880020
         TM    TSTFLGS3,TSTSTAI  TEST FOR STAI OR ATTENTION.            22960020
         BO    STAI1          IT'S AN ABEND. PROCESS RETRY.             23040020
ATTN     EQU   *                                                        23120020
         LR    R4,R2          SET REGISTER FOR ATTN.                    23200020
LOOP     EQU   *                                                        23280020
         TM    RBSTAB(R4),X80   TEST FOR PRB(IRB)                       23360020
         BZ    FOUND          FOUND A PRB(IRB)                          23440020
         L     R4,RBLINK(R4)  GET THE NEXT R.B.                         23520020
         B     LOOP           LOOP UNTIL PRB(IRB) IS FOUND.             23680020
STAI1    EQU   *                                                        23680920
         SPACE                                                          23681820
*        ALL RBS ARE PURGED UP TO THE MOST CURRENT STAE/STAI EXIT PRB.  23682720
*        IF THERE ARE NONE OF THESE, THEN PURGE BACK TO THE MOST        23683620
*        CURRENT PRB AFTER THE LAST SVRB.                               23684520
*        IF THERE ARE NO PRBS TO RETRY, AND THERE IS ONLY ONE TASK      23685420
*        UNDER TEST THEN PRINT 'NOTHING LEFT TO TEST' AND QUIT.         23686320
*        IF THE ABENDED TASK IS NOT THE HIGHEST TASK, SET A PSEUDO      23687220
*        BREAKPOINT IN ITS MOTHER AND LET THE DAUGHTER ABEND.           23688120
         SPACE                                                          23689020
LOOP7    EQU   *                                                        23689920
         L     R2,RBLINK(R2)  HOPEFULLY AN SVRB.                        23690820
LOOP7A   EQU   *                                                        23691720
         L     R4,RBLINK(R2)  HOPEFULLY A PRB.                          23692620
         TM    RBSTAB+X1(R2),X80   DOES R4 CONTAIN A TCB PTR.           23693520
         BO    QRETRY         YES.RETRY MOTHER OR END.                  23694420
         CLI   RBSIZE(R4),X4  Q.IS THIS A PRB WITH NO EXSAVE            23695320
         BNE   LOOP7          NO. LOOP.                                 23696220
         LR    R5,R2          PUT SVRB ADDRESS IN R5                    23697120
LOOP7B   EQU   *                                                        23698020
         L     R5,RBLINK(R5)  SEARCH FOR AN SVRB.                       23698920
         TM    RBSTAB+X1(R5),X80  Q.IS THE LINK FIELD A TCB POINTER.    23699820
         BO    AOK            FOUND END OF THE CHAIN.                   23700720
         TM    RBSTAB(R5),XC0 Q.IS THIS AN SVRB.                        23701620
         BNO   LOOP7B         NO. LOOP.                                 23702520
         CLC   X88(X5,R5),ABEND  Q.IS IT STAE/STAI SVRB                 23703420
         BE    AOK            YES. R2=SVRB,R4=RETRY PRB.                23704320
         LR    R2,R5          SET R2 TO THIS SVRB.                      23705220
         B     LOOP7A         GET PRB AND START OVER.                   23706120
QRETRY   EQU   *                                                        23707020
         NI    TSTFLGS3,XFF-TSTSTAI  TURN OFF ABEND BIT.                23707920
*        BIT TURNED OFF SO PP'S REGS WONT GET MESSED UP.                23708820
         L     R5,TCBOTC-TCB(R7)  GET THE MOTHER TCB.                   23709720
         LA    R5,X0(R5)      CLEAR THE HIGH BYTE.                      23710620
         C     R5,TSTTCB      Q. IS THE MOTHER OF TPLNTCB TEST TCB.     23711520
         BNE   SOMTHING       SKIP THE NOTHING CODE.                    23712420
NOTHING  LA    R1,MGNOTRY     'NO ACTIVE PROGRAM LEFT TO TEST'          23713320
         B     PUTRTURN       PRINT MSG AND EXIT.                       23714220
SOMTHING EQU   *                                                        23715120
         ST    R5,PPTCB       SAVE THE MOTHER AND SET A PSEUDO BRKPT.   23716020
         L     R6,TCBRBP-TCB(R5)  GET THE FIRST RB .                    23716920
LOOP7C   EQU   *                                                        23717820
         TM    RBSTAB(R6),X80   Q.IS THIS A PRB(IRB)                    23718720
         BZ    SETPSEUD       YES SET A PSEUDO BRKPT.                   23719620
         L     R6,RBLINK(R6)  GET THE NEXT RB.                          23720520
         B     LOOP7C         LOOP UNTIL A PRB(IRB) IS FOUND.           23721420
SETPSEUD EQU   *                                                        23722320
         MVC   TSTGO(X4),RBOPSW+X4(R6)  SAVE THE I.C.                   23723220
         MVC   TSTGO+X4(X1),RBWCF(R6) SAVE THE WAIT COUNT.              23724120
         LR    R0,R6          GET THE TARGET PRB ADDRESS.               23725020
         O     R0,WAITOFF     CODE TO ZERO THE WAIT COUNT.              23725920
         SVC   TESTSVC        ZERO THE WAIT COUNT.                      23726820
         LA    R1,TSTGO+6     ADDRESS OF PSEUDO BREAKPT.                23727720
         LR    R0,R6          GET THE TARGET PRB ADDRESS.               23728620
         O     R0,ICCHANGE    CHANGE THE I.C. CODE                      23729520
         SVC   TESTSVC        CHANGE THE INSTRUCTION COUNTER.           23730420
         STATUS START,TCB=(7)   START THE ABENDED TCB.                  23731320
         LA    R0,PPEXIT+X2   RETRY AT SVC 3                            23732220
         B     STAIPOST       LET THE ABEND CONTINUE.                   23733120
AOK      EQU   *                                                        23734020
         L     R3,REGSAVE2    SAVE AREA FOR ABENDING REGS.              23734920
         MVC   X0(N64,R3),RBGRSAVE(R2)  SAVE THE REGISTERS.             23735820
         OC    TSTGO(X4),RBAPSW(R4)  SAVE ABENDED I.C.                  23736720
         BNZ   SKIP5          SKIP THE NEXT BIT OF CODE.                23737620
FOUND    EQU   *                                                        23738520
         MVC   TSTGO(X4),RBOPSW+X4(R4)  SET UP TEST GO.                 23739420
SKIP5    EQU   *                                                        23740320
         MVC   TSTGO+X4(X1),RBWCF(R4)  SAVE THE WAIT COUNT.             23741220
         LA    R0,X0(R4)      PASS RB ADDRESS TO SVC 97                 23742120
         O     R0,WAITOFF     TURN WAIT COUNT OFF.                      23743020
         SVC   TESTSVC        TURN OFF WAIT COUNT FOR A SHORT TIME.     23743920
         LA    R0,X0(R4)      CHANGE THE PP'S I.C.                      23744820
         O     R0,ICCHANGE    DITTO.                                    23745720
         LA    R1,TSTGO+X6    PSEUDO BREAKPOINT ADDRESS.                23746620
         SVC   TESTSVC        CHANGE PP I.C.                            23747520
         LA    R0,TSTGO+X6    RETRY ADDRESS.                            23748420
STAIPOST EQU   *              POST IKJEFT04(TEST/TMP STAI EXIT)         23749320
         L     R1,TPLNECB     POST ECB FOR TMP STAI EXIT RTN.           23750220
         O     R0,POST7F      POST STAI ECB WITH A '7F'                 23751120
         POST  (1),(0)        POST                                      23752020
         STATUS  START        MAKE ALL SUBTASKS DISPATCHABLE.           23752920
         B     WAIT           ALLOW RECOVERY,BY WAITING FOR PSEUDO      23753820
*                             BREAK TO OCCUR.                           23754720
         SPACE                                                          25680020
*        ISSUE 'TEST' MODE MESSAGE USING PUTLINE SERVICE ROUTINE.       25760020
         SPACE                                                          25840020
MODEGO   EQU   *                                                        25920020
*        BUILD A PARAMETER LIST IN THE GENERAL WORKAREA FOR AN XCTL     26000020
*        TO THE MAINLINE MONITOR MODULE.                                26080020
         SPACE                                                          26160020
         MVC   PPEXIT(X4),SVC  INITIALIZE PPEXIT W/SVC TRACE&SVC EXIT   26240020
         L     R15,WORKAREA    R15=PARM LIST ADDR.                      26320020
         MVC   X0(XCTLLEN,R15),XCTLFORM MOVE IN L-FORM LIST.            26400020
         XCTL  EP=IKJEGMNL,SF=(E,(15))  *                               26480020
BLOW3    EQU   *                                                        26560020
         SPACE                                                          26640020
*        BUILD PARAMETER LIST AND PARSE TEST COMMAND.                   26720020
         SPACE                                                          26800020
PARSE    EQU   *                                                        26880020
         L     R1,WORKAREA    R1=PARAMETER LIST ADDR.                   26960020
         L     R2,PCLADDR     R2=PCL ADDR.                              27040020
         MVC   X0(N12,R1),PARMLIST MOVE IN SERVICE ROUTINE PARMLIST.    27120020
         LA    R3,TSTANSPL    R3=ANSWER PLACE ADDR.                     27200020
         L     R4,TPLTBUF     R4=TEST COMMAND BUFFER.                   27280020
         STM   R2,R4,N12(R1)   PARSE PARAMETERS TO LIST.                27360020
         LINK  EP=IKJPARS     PARSE THE COMMAND.                        27440020
BLOW5    EQU   *                                                        27520020
         LTR   R15,R15        Q.IS RETURN CODE ZERO.                    27600020
         BNZ   TMPRTURN       NO,RETURN TO TMP.                         27680020
         L     R8,TSTANSPL    R8=ADDR OF PARSE-PRODUCED PDL.            27760020
         USING IKJPARMD,R8    PDL ADDRESSABILITY.                       27840020
         SPACE                                                          27920020
*        SET UP PARAMETERS FOR THE 'DEFAULT' SERVICE ROUTINE IF THE     28000020
*        SPECIFIED DSNAME IS NOT FULLY QUALIFIED.                       28080020
         SPACE                                                          28160020
         L     R1,WORKAREA    R1=STANDARD PARAMETER LIST ADDR.          28240020
BLANK    EQU   C' '           THIS IS A BLANK (X'40').                  28560020
         USING INDFLTPM,R1    ESTABLISH ADDRESSABILITY TO DEFAULTA43321 28610021
*                             WORKAREA                           A43321 28620021
         MVC   INDFLTPL(DFPLDFPB-DFPLUPT+L'DFPLDFPB),PARMLIST    A43321 28630021
*                             MOVE STANDARD POINTERS TO LIST     A43321 28640021
         MVI   INTSTDSN,BLANK BLANK OUT DATA SET NAME AREA       A43321 28690021
         MVC   INTSTDSN+X1(L'INTSTDSN-X1),INTSTDSN               A43321 28700021
         L     R2,DSNAME      R2=ADDR OF DSNAME FROM DSNAME PDE.        28720020
         LH    R3,DSNAME+X4   R3 = DSNAME LENGTH.                A43321 28800021
         STH   R3,INDSNLEN    DSNAME LENGTH SAVED FOR DEFAULT    A43321 28880021
         BCTR  R3,X0          REDUCE LENGTH FOR EXECUTE.                28960020
         EX    R3,DSNMVC      MOVE DSNAME TO DSNAME AREA.               29040020
         SPACE                                                          29120020
         TM    DSNAME+X6,FULLQUAL Q.IS DSNAME FULLY QUALIFIED.          29200020
FULLQUAL EQU   B'01000000'    BIT TO INDICATE 'FULLY-QUALIFIED'.        29280020
         BO    DAIR           IF B'01000000',YES,ALLOCATE.              29360020
         CLI   LOADOBJ+X1,LOADON Q.IS LOAD SPECIFIED.                   29440020
         LA    R2,LOAD        YES,USE 'LOAD' QUALIFIER.                 29520020
         BE    NEXT1          *                                         29600020
         LA    R2,OBJECT      NO,USE 'OBJECT' QUALIFIER.                29680020
NEXT1    EQU   *                                                        29760020
         LA    R3,X1(,R3)     RESTORE DSNAME LENGTH.             A43321 29780021
         LA    R4,X2(,R0)     CONSTANT FOR COMPARES              A43321 29800021
         SR    R3,R4          IF USER NAME IS 2 CHARS OR LESS,   A43321 29820021
         BNH   DSN01030       BRANCH TO INDICATE SIMPLE NAME     A43321 29840021
         LA    R5,INTSTDSN(R3) ADDRESS NEXT-TO-LAST CHARACTER    A43321 29860021
DSN01010 EQU   *                                                 A43321 29880021
         CLI   X0(R5),INDSNPER IS CHARACTER A PERIOD             A43321 29900021
         BE    DSN01020       IF SO, QUALIFIER CHECK REQUIRED    A43321 29920021
         BCTR  R5,R0          ADDRESS NEXT CHARACTER TO LEFT     A43321 29940021
         BCT   R3,DSN01010    DECREMENT LENGTH AND REPEAT AS     A43321 29960021
*                             LONG AS LENGTH .GT. 0              A43321 29980021
         B     DSN01030       BRANCH TO INVOKE DEFAULT           A43321 30000021
DSN01020 EQU   *                                                 A43321 30020021
         SH    R3,INDSNLEN    SUBTRACT FULL LENGTH FROM LENGTH   A43321 30040021
         LCR   R3,R3          COMPLEMENT TO GET QUALIFIER LENGTH A43321 30060021
         BCTR  R3,X0          REDUCE LENGTH FOR EXECUTE          A43321 30070021
         EX    R3,QUALCHK     DETERMINE IF QUALIFIER IS EITHER   A43321 30080021
*                             OBJ OR LOAD                        A43321 30100021
         BNE   DSN01030       IF NEITHER OF THE ABOVE, BRANCH TO A43321 30120021
*                             INVOKE DEFAULT                     A43321 30140021
         LA    R3,X1(,R3)     RESTORE QUALIFIER LENGTH           A43321 30160021
         LH    R4,INDSNLEN    GET DSNAME LENGTH                  A43321 30180021
         SR    R4,R3          SUBTRACT QUALIFIER LENGTH          A43321 30200021
         STH   R4,INDSNLEN    UPDATE DSNAME LENGTH TO LOGICALLY  A43321 30220021
*                             REMOVE RIGHTMOST QUALIFIER         A43321 30240021
DSN01030 EQU   *                                                 A43321 30260021
         LA    R4,INDSNLEN    R4 = DSNAME ADDRESS                A43321 30280021
         MVC   INDFLTPB+DFPBPSCB-DFPB(L'DFPBPSCB),TPLPSCB        A43321 30300021
*                             PUT ADDRESS OF PSCB IN PARMLIST    A43321 30320021
         MVI   INDFLTPB+DFPBCNTL-DFPB,DFPBUID SET CONTROL BYTE   A43321 30340021
         LA    R6,INDFLTPB    ADDRESS OF DEFAULT PARM BLOCK      A43321 30360021
         LINK  EP=IKJDFLT,PARAM=(,,,(R6),(R4),,(R2)),MF=(E,(1))  A43321X30380021
                              LINK TO DEFAULT SERVICE ROUTINE    A43321 30400021
         SPACE                                                          30560020
*        CHECK RETURN CODES FROM 'DEFAULT' SERVICE ROUTINE. IF THE      30640020
*        ATTEMPT TO ADD QUALIFIERS AND USERID IS UNSUCCESSFUL, WRITE    30720020
*        A DIAGNOSTIC MESSAGE TO THE TERMINAL.                          30800020
         SPACE                                                          30880020
         C     R15,TWENTY4    Q.DID AN ATTENTION INTERRUPT OCCUR.       30960020
         BE    TMPRTURN       YES,RETURN TO THE TMP.                    31040020
*        WRITE DIAGNOSTIC MESSAGES.                                     31120020
         SPACE                                                          31200020
DAIR     EQU   *                                                        31280020
*        BUILD PARAMETER LIST FOR DAIR SERVICE ROUTINE AND REQUEST      31360020
*        ALLOCATION OF DATA SET AS 'OLD' USING CODE '08'.               31440020
         SPACE                                                          31520020
         MVI   TSTCURLD,X0    FIRST TIME SWITCH FOR OBJECT(PDS)         31600020
DAIROBJ  EQU   *              ENTRY FOR OBJECT(PDS) ALLOCATION.         31680020
         L     R1,WORKAREA    CREATE A DAIR PARM BLOCK                  31760020
         MVC   X0(LEN08,R1),DAIR08  MOVE BASIC PARM BLOCK               31840020
         LA    R3,N98(,R1)    R3=DSNAME AREA ADDR.                      31920020
         CLI   LOADOBJ+X1,LOADON Q.IS 'LOAD' SPECIFIED.                 32000020
         ST    R3,X8(R1)      DSNAME AREA ADDRESS TO LIST               32080020
         BE    NOMEMBER       LOAD SPECIFIED,FORGET MEMBER.             32160020
         TM    TSTCURLD,XFF   CHECK FOR OBJECT (PDS)                    32240020
         BZ    NOMEMBER       DO NOT ALLOCATE TO MEMBER                 32320020
MEMON    EQU   255                                                      32400020
LOADON   EQU   1                                                        32480020
         IC    R3,DSNAME+N13   R3=MEMBER NAME LENGTH.                   32560020
         L     R4,DSNAME+X8    R4=ADDR OF MEMBER NAME.                  32640020
         BCTR  R3,X0          REDUCE LENGTH FOR EXECUTE.                32720020
         EX    R3,MEMMOVE     MOVE MEMBER NAME TO DAIR PARM BLOCK.      32800020
NOMEMBER EQU   *                                                        32880020
PRESENT  EQU   X'80'          PRESENT -- NOT ABSENT                     32888020
         TM    PASSWORD+X6,PRESENT  IS PASSWORD PRESENT                 32896020
         BZ    NOPASSWD       NO -- BRANCH                              32904020
         IC    R3,PASSWORD+X5  GET PASSWORD LENGTH                      32912020
         L     R4,PASSWORD    POINT TO THE PASSWORD                     32920020
         BCTR  R3,X0          DECREMENT FOR THE EXECUTE                 32928020
         EX    R3,MOVEPASS    MOVE PASSWORD TO DAIR LIST                32936020
NOPASSWD EQU   *                                                        32944020
         BAL   R11,DAIR1      ALLOCATE THE DATA SET                     32960020
         LTR   R0,R15         TEST THE RETURN CODE.                     33040020
         BNZ   MAKEMSG        BAD CODE .PRINT MESSAGE AND RETURN.       33120020
         SPACE                                                          33140020
*        TWO TIMES THRU HERE INDICATES PDS OBJECT                       33160020
         SPACE                                                          33180020
         TM    TSTCURLD,XFF   TEST FOR PREVIOUS ALLOCATION              33200020
         L     R1,WORKAREA    GET PARM ADDR.                            33280020
         MVC   TSTCURLD(X8),N12(R1)  SAVE DDNAME FOR IKJEGLDR.          33360020
         BNZ   ALLOCTER       ALLOCATE FOR PSUEDO SYSTERM DD            33440020
        SPACE                                                           33520020
         SPACE                                                          33560020
*        IF SEQUENTIAL,OBJECT IS ASSUMED.                               33600020
         SPACE                                                          33640020
PS       EQU   X'40'          PHYSICAL SEQUENTIAL                       33680020
         TM    DA08DSO-DAPB08(R1),PS   IS THIS A SEQUENTIAL DATA SET    33720020
         BO    SEQOBJ         SET TO OBJECT                             33760020
         SPACE                                                          33800020
*        MUST BE PDS LOAD                                               33840020
         SPACE                                                          33880020
         NC    DSNAME+X9(X3),DSNAME+X9 Q.IS MEMBER SPECIFIED            33920020
         BNZ   ATTACH1        YES,O.K. TO ATTACH                        33960020
         SPACE                                                          34000020
*        IF MEMBER NAME NOT GIVEN, DEFAULT TO 'TEMPNAME'                34040020
         SPACE                                                          34080020
         MVC   DSNAME+X9(X3),TEMPNAME+X1  MOVE POINTER TO 'TEMPNAME'    34160020
         MVI   DSNAME+N13,X8  MOVE LENGTH OF TEMPNAME.                  34200020
         B     ATTACH1        ATTACH......                              34240020
         SPACE                                                          34320020
FREINBUF EQU   *              FREE  INBUF  AND ZERO POINTER             34400020
         L     R1,INBUF       R1=ADDR OF BUFFER                         34480020
         LTR   R1,R1          IS INBUF ALREADY ZERO                     34560020
         BCR   Z,R11          YES.RETURN.                               34640020
         LH    R0,X0(R1)      R0=LENGTH OF BUFFER FOR FREEMAIN.         34720020
         O     R0,SP1         INDICATE SUBPOOL 1                        34800020
         FREEMAIN R,LV=(0),A=(1) FREE THE BUFFER.                       34880020
         XC    INBUF(X4),INBUF CLEAR INBUF.                             34960020
         BR    R11            RETURN.                                   35040020
         SPACE                                                          35120020
DSNMVC  MVC   N100(X0,R1),X0(R2)  *                                     35200020
MEMMOVE  MVC   N52(X0,R1),X0(R4)  *                                     35280020
MOVEPASS MVC   DA08PSWD-DAPB08(X0,R1),X0(R4)  MOVE THE PASSWORD         35320020
QUALCHK  CLC   X1(*-*,R5),X0(R2) CHECK FOR EQUAL QUALIFIERS      A43321 35325021
        SPACE                                                           35360020
         SPACE                                                          35440020
ATTACH1  EQU   *              *                                         35520020
         GETMAIN R,LV=100,SP=1 GET STORAGE FOR A DCB (LV=96)            35600020
         SPACE                                                          35680020
BLOW5A   EQU   *              *                                         35760020
         LA    R1,X0(R1)      CLEAR THE HIGH BYTE.                      35840020
         ST    R1,TSTDCB      SAVE THE DCB CORE ADDRESS.                35920020
         XC    X0(X4,R1),X0(R1)  ZERO THE LINK FIELD.                   36000020
         LA    R1,X4(R1)      GET THE DCB ADDRESS.                      36080020
         LR    R4,R1          SAVE DCB ADDRESS                          36160020
         MVC   X0(N88,R1),ADDCB CONSTRUCT DCB.                          36240020
         MVC   DCBDDNAM(X8,R1),TSTCURLD  MOVE IN DDNAME.                36320020
         MVC   N88(X4,R1),LFORM MOVE IN OPEN L-FORM                     36400020
         MVC   N92(X4,R1),CLFORM MOVE IN CLOSE L-FORM.                  36480020
         LA    R6,N88(,R1)    R6=EXECUTE FORM LIST ADDR.                36560020
         OPEN  ((4)),MF=(E,(6)) OPEN THE DATA SET.                      36640020
         SR    R5,R5          CLEAR R5.                                 36720020
         IC    R5,DSNAME+N13   R5=MEMBER NAME LENGTH.                   36800020
         L     R6,DSNAME+X8    R6=MEMBER NAME ADDR.                     36880020
         L     R1,BLDLAREA    GET THE ADDRESS FOR THE BLDL ENTRY        36960020
DCBLEN   EQU   96             *                                         37040020
         MVC   X0(X4,R1),LSTDSCP PUT LIST DESCRIPTION IN LIST.          37120020
         MVC   X4(X8,R1),BLANKS  BLANK MEMBER NAME FIELD                37200020
         BCTR  R5,X0          DECREMENT LENGTH FOR EXECUTE.             37280020
         EX    R5,MEMMVC      MOVE IN MEMBER NAME.                      37360020
         LR    R5,R1          SAVE LIST ADDR.                           37440020
         BLDL  (4),(5)        COMPLETE THE LIST.                        37520020
         TM    BLDLATR1+X4(R5),OVLAYBIT  TEST FOR OVERLAY.              37600020
OVLAYBIT EQU   X'20'          OVERLAY BIT.                              37680020
         BZ    SKIP3          SKIP AROUND.                              37760020
         MVI   TSTDCB,X80     TURN ON HIGH BIT TO INDICATE OVLY.        37840020
BLDLATR1 EQU   22             *                                         37920020
BLDLATR2 EQU   23             *                                         38000020
SKIP3    EQU   *                                                        38080020
         LTR   R15,R15        Q.BLDL SUCCESSFUL.                        38160020
         BNZ   BADMEM         'MEMBER NOT FOUND'                        38240020
         CLI   LOADOBJ+X1,LOADON  Q.LOAD OR OBJECT.                     38320020
         BE    ATTACH         A.LOAD (PDS)                              38400020
         BAL   R11,CLOSE      OBJECT (PDS).                             38480020
         L     R1,WORKAREA    PLACE FOR DAIR PARM BLOCK LIST            38560020
         MVC   X0(LEN2C,R1),DAIR2C   UNALLOC BY DDNAME.                 38620020
         MVC   DA2CDDN-DAPB2C(X8,R1),TSTCURLD  MOVE IN THE DDNAME.      38680020
         MVI   DA2CFLG-DAPB2C+X1(R1),X1 CODE TO UNALLOC BY DDNAME.      38740020
         BAL   R11,DAIR1      UNALLOCATE BY DDNAME                      38800020
         B     DAIROBJ        REALLOCATE TO DSN(MEMBER)                 38880020
SEQOBJ   EQU   *                                                        38900020
OBJON    EQU   2              INDICATES OBJECT                          38920020
         MVI   LOADOBJ+X1,OBJON  SET TO OBJECT , IF NOT SUPPLIED        38940020
ALLOCTER EQU   *              ALLOCATE TO THE TERMINAL  CODE  1C        38960020
         L     R1,WORKAREA    ADDRESSABILITY TO GENERAL WORKAREA.       39040020
         MVC   X0(LEN1C,R1),DAIR1C  ALLOCATE THE TERMINAL               39120020
         LR    R2,R1          SAVE ADDRESS TO WORKAREA.                 39200020
         BAL   R11,DAIR1      SETUP AND LINK TO DAIR                    39280020
         LTR   R0,R15         TEST AND SAVE RETURN CODE                 39360020
         BNZ   MAKEMSG        PRINT 'DAIR FAILURE'                      39440020
         MVC   TERMDD(X8),X8(R2) SAVE TERMINAL DD NAME FOR OSLOADER     39520020
ATTACH  EQU   *                                                         39600020
*        SET UP PARAMETERS FOR ATTACHING THE TEST LOADER AS A SUB-TASK  39680020
*        AND ZERO THE TASK COMMUNICATION ECB'S.                         39760020
         SPACE                                                          39840020
         SR    R0,R0          CLEAR R0.                                 39920020
         L     R3,TPLSTAI     R3=STAI EXIT ADDRESS.                     40000020
         L     R2,ECBTERM     R2=PP TERMINATION ECB ADDR.               40080020
         ST    R0,X0(,R2)     ZERO THE TERMINATION ECB.                 40160020
         SPACE                                                          40240020
         L     R15,WORKAREA    R15=ADDR OF GENERAL WORK AREA.           40320020
         L     R4,TPLSPLS     R4=ADDR OF PARMS FOR STAI EXIT.           40400020
         LA    R15,N100(,R15)   R15=ATTACH PARMLIST ADDR.               40480020
         XC    X0(ATTCHLLN,R15),X0(R15) ZERO.                           40560020
         MVI   N20(R15),X2    SET ROLLOUT BITS.                         40640020
         L     R1,TPLECT      OBTAIN ECT POINTER                        40720020
         MVC   ECTPCMD-ECT(X8,R1),TEST  MOVE TEST NAME INTO ECT         40800020
         LR    R1,R9          R1=TCOMTAB ADDRESS                        40880020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT      40960020
         ATTACH EP=IKJEGLDR,ECB=(2),MF=(E,(1)),SF=(E,(15)),SHSPV=78,   *41040020
               STAI=((3),(4)),SZERO=NO   ATTACH LOADER.                 41120020
BLOW6    EQU   *                                                        41200020
         C     R15,EIGHT      Q.IS THERE NO CORE.                       41206020
         BE    NOCORE1        A.YES THERE IS NO CORE.                   41212020
         LA    R1,X0(R1)      CLEAR HIGH BYTE.                          41220020
         ST    R1,TPLCTCB     SET ATTACHED TCB ADDRESS FOR TMP.         41240020
*        WAIT ON ECB LIST FOR LOADER TO BRING IN REQUESTED PROGRAM.     41280020
         SPACE                                                          41360020
WAIT     EQU   *              *                                         41440020
         WAIT  ECBLIST=ECBTST ISSUE THE WAIT.                           41520020
         SPACE                                                          41600020
*        THE ONLY INDICATION OF A NORMAL LOAD IS THE POSTING OF THE     41680020
*        TEST ECB.ANY OTHER POST INDICATES A RETURN TO THE TMP.         41760020
         SPACE                                                          41840020
         L     R5,ECBTST      TEST ECB ADDRESS.                         41920020
         TM    X0(R5),X44     X'44' IS A POST FROM SVC 61.              42000020
         BO    POST61         POST SVC 61.                              42080020
         L     R1,TPLECT      OBTAIN ECT POINTER.                       42160020
         LA    R1,ECTPCMD-ECT(R1)  POINT TO PRIMARY COMMAND NAME.       42240020
         O     R1,HIGHBIT     TURN ON HIGHBIT.                          42320020
*        ISSUE TIME SHARING EVENT MACRO.(ATTACH TIME)                   42400020
         TSEVENT PPMODE                                                 42480020
         BAL   R11,FROMLDR    CLOSE THE DCB, AND FREE CORE              42560020
         TM    X0(R5),X44     X'40' IS NORMAL LOAD.                     42640020
         MVI   X0(R5),X0      ZERO ECB.                                 42720020
         BZ    STAICHK        CHECK STAI ECB.                           42800020
         SPACE                                                          42880020
*        SET QUALIFICATION FOR LOADED MODULE.                           42960020
         SPACE                                                          43040020
         NI    TSTFLGS3,XFF-TSTSTAI  INSURE THAT STAI BIT IS OFF.       43120020
         L     R4,PPTCB       R4=PP TCB ADDR.                           43200020
         L     R5,TCBRBP-TCB(,R4) R5=ACTIVE RB ADDR.                    43280020
         L     R5,RBLINK(,R5) R5=PRB ADDR FOR PP.                       43360020
         TM    TSTFLGS3,TSTGOSW  IS IT SPECIAL BREAKPOINT.              43440020
         BO    SPECIAL        YES IT IS.                                43520020
         L     R1,TSTGO       ADDRESS OF CLOBBERED INSTRUCTION.         43600020
         LR    R0,R4          TCB ADDRESS FOR SVC 97                    43680020
         O     R0,ICCHANGE    IC CHANGE CODE.                           43760020
         SVC   TESTSVC        BACK UP IC BY TWO.                        43840020
         B     CONTINUE       CONTINUE PROCESSING.                      43920020
SPECIAL  EQU   *                                                        44000020
         L     R1,RBOPSW+X4(R5) OBTAIN I.C.                             44080020
         MVC   X0(X2,R1),TSTGO  RESTORE 2 BYTES OF INSTRUCTION.         44160020
         NI    TSTFLGS3,XFF-TSTGOSW TURN OFF THE PSEUDO SPECIAL SW.     44240020
         LA    R1,PPEXIT      CHANGE REGISTER FOURTEEN.                 44320020
         ST    R1,PPEXIT      R1 MUST CONTAIN ADDR. OF VALUE.           44400020
         O     R1,CHANGE14    *                                         44480020
         L     R0,PPTCB       PPS TCB POINTER.                          44560020
         O     R0,RGCHANGE    CHANGE REGISTER 14 FOR NORMAL TERMINATE   44640020
         SVC   TESTSVC        SAME HERE..                               44720020
CONTINUE EQU   *                                                        44800020
         XC    TSTGO(X6),TSTGO  ZERO PSEUDO BREAK FIELD IN TCOMTAB.     44880020
         B     MODEGO         ISSUE MODE MESSAGE AND GO TO MAINLINE.    44960020
         SPACE                                                          45040020
POST61   EQU   *              POST SVC 61.                              45120020
         XC    X0(X4,R5),X0(R5) CLEAR TEST'S ECB.                       45200020
         L     R2,ECBPP       OBTAIN SVC61'S SVRB ADDRESS.              45280020
         TM    TSTFLGS3,TSTGOSW  TEST IF LOADER IS XCTLING.             45360020
         BZ    POST6A         NO POST. BRANCH.                          45440020
         LM    R3,R4,RBEXSAVE(R2) GET THE TCB ADR AND SVC INFO BLK PTR  45520020
         LTR   R3,R3          IF TCB SLOT IS ZERO , IGNORE.             45600020
         BZ    NOGET          TCB ADDR=0 , DONT GET CORE.               45680020
         L     R0,CORETRN     SP=1 , LENGTH=12                          45760020
         GETMAIN  R,LV=(0)  GET CORE FOR CONTROL WORDS.                 45840020
         MVC   X0(X4,R1),TSTTRN  PUSH DOWN QUEUE.                       45920020
         STM   R3,R4,X4(R1)   TCB ADDR , SVC BLOCK PTR TO WORDS.        46000020
         ST    R1,TSTTRN      ADD CONTROL WORDS TO QUEUE.               46080020
NOGET    EQU   *              *                                         46160020
         L     R1,RBLINK(R2)  GET PRB(IRB) ADDRESS                      46240020
         TM    RBCDE(R1),X2   TEST XCTL BIT IN FL-CDE FIELD.            46320020
         L     R1,RBCDE(R1)   XCTLEE CDE.                               46400020
         BZ    POST6A         BRANCH IF NOT XCTL.                       46480020
         L     R6,CDEEPA(R1)  XCTLEE  E.P. ADDRESS.                     46560020
         MVC   TSTGO(X2),X0(R6)  SAVE 2 BYTES OF INSTR.                 46640020
         MVC   X0(X2,R6),SVC  PLANT SVC                                 46720020
POST6A   EQU   *                                                        46800020
         MVI   TSTMTASK,X0    RESET ONE TIME SWITCH FOR SVCS.           46880020
         POST  ECBPP          MAKE SVC 61 DISPATCHABLE.                 46960020
         B     WAIT           WAIT AGAIN.                               47040020
FROMLDR  EQU   *              CAME FROM IKJEGLDR                        47120020
         TM    TERMDD,XFF     Q. DOES TERM DD GET UNALLOCATED.          47200020
         BZ    SKIP4          NO. NEVER ALLOCATED.                      47280020
         L     R1,WORKAREA    WORKAREA ADDRESSABILITY.                  47360020
         MVC   X0(LEN2C,R1),DAIR2C   UNALLOC BY DDNAME.                 47420020
         MVC   DA2CDDN-DAPB2C(X8,R1),TERMDD    MOVE IN THE DDNAME.      47480020
         MVI   DA2CFLG-DAPB2C+X1(R1),X1 CODE TO UNALLOC BY DDNAME.      47540020
         LR    R2,R11         SAVE LINK REGISTER.                       47600020
         BAL   R11,DAIR1      UNALLOCATE.......                         47680020
         LR    R11,R2         RESTORE THE LINK REGISTER.                47760020
CLOSE    EQU   *              *                                         47840020
SKIP4    EQU   *              *                                         47920020
         L     R4,TSTDCB      GET THE DCB ADDRESS - 4                   48000020
         LTR   R4,R4          DID WE GO THRU THE 'ATTACH1' CODE         48080020
         BCR   NEG+Z,R11      RETURN UNLESS POSITIVE AND NON-ZERO       48160020
Z        EQU   8              ZERO CONDITION CODE                       48240020
NEG      EQU   4              NEGATIVE CONDITION.                       48320020
         LA    R4,X4(R4)      GET THE DCB ADDRESS.                      48400020
         TM    DCBOFLGS(R4),X10   HAS THE DCB BEEN OPENED               48480020
DCBOFLGS EQU   48             DCB OPEN FLAGS.                           48560020
         BZ    NOCLOSE        THE DCB IS NOT OPEN                       48640020
         LA    R6,CLLISTAD(R4)  R6=CLOSE LIST ADDRESS.                  48720020
CLLISTAD EQU   92             *                                         48800020
         CLOSE ((4)),MF=(E,(6)) CLOSE DCB                               48880020
NOCLOSE  EQU   *              *                                         48960020
         L     R1,TSTDCB      GET THE DCB CORE ADDRESS.                 49040020
         FREEMAIN R,LV=100,A=(1),SP=1 FREE THE STORAGE.                 49120020
         XC    TSTDCB(X4),TSTDCB  ZERO THE DCB POINTER.                 49200020
         BR    R11            RETURN.                                   49280020
         SPACE                                                          49360020
CLCID    CLC   X0(X0,R3),X0(R4)  COMPARE THE USERID.                    49440020
MOVEMEMB MVC   X0(X0,R2),X0(R3)  MOVE MEMBER NAME TO MESSAGE            49520020
         SPACE                                                          49600020
BADMEM   EQU   *              'MEMBER XXX NOT IN DATA SET XXX' *        49680020
         L     R1,OUTBUF      ADDRESSABILITY TO OUTPUT BUFFER.          49760020
         LA    R2,X8(R1)      POINTER TO THE NEW 1ST LEVEL MSG.         49840020
         SR    R3,R3          ZERO FOR STORE.                           49920020
         STM   R2,R3,X0(R1)   1ST AND 2ND LEVEL POINTERS.               50000020
         L     R2,MEMMSG      ADDRESSABILITY TO 1ST MSG TEXT.           50080020
         MVC   X8(MEM1STL,R1),X0(R2)  MOVE BASIC TEXT.                  50160020
         LA    R2,X8+INSERT1(R1)  MEMBER INSERT LOCATION.               50240020
         L     R3,DSNAME+X8   MEMBER POINTER.                           50320020
         SR    R4,R4          CLEAR                                     50400020
         IC    R4,DSNAME+N13  GET THE LENGTH OF MEMBER NAME             50480020
         BCTR  R4,X0          DECREMENT FOR EXECUTE                     50560020
         EX    R4,MOVEMEMB    MOVE MEMBER NAME TO MESSAGE.              50640020
         LA    R2,X8+INSERT2(R1)  DATA SET NAME POSITION.               50720020
         L     R3,WORKAREA    ADDRESSABILITY TO DSNAME.                 50800020
         LA    R3,N100(R3)    ACTUAL DATA SET NAME.                     50880020
         L     R4,TPLPSCB     ADDRESSABILITY TO PSCB.                   50960020
         SR    R5,R5          ZERO FOR INSERT CHAR.                     51040020
         IC    R5,PSCBUSRL-PSCB(R4)  GET THE LENGTH OF USERID.          51120020
         BCTR  R5,X0          MINUS ONE.                                51200020
         EX    R5,CLCID       COMPARE FOR USERID PREFIX.                51280020
         BNE   MOVEDSN        MOVE IN THE DATA SET NAME.                51360020
         LA    R3,X2(R5,R3)   UP POINTER PASS USERID.                   51440020
MOVEDSN  MVC   X0(N35,R2),X0(R3)  MOVE MOST OF THE DATA SET NAME.       51520020
PUTRTURN EQU   *              PUT AND RETURN TO TMP.                    51600020
         LA    R11,TMPRTURN   BR R11 WILL RETURN.                       51680020
TPUT     EQU   *              TPUT REQUEST FOR 'IO1'                    51760020
         LCR   R1,R1          COMPLIMENT FOR A MESSAGE.                 51840020
         L     R15,TPUTADDR   R15=ADDR. FOR A PUT REQUEST.              51920020
TGO      EQU   *              GO TO 'IO1'                               52240020
         BALR  R14,R15        GO.                                       52320020
         C     R15,ATTNCODE   IS THERE AN ATTENTION REQUEST.            52400020
         BCR   NE,R11         NO. RETURN.                               52480020
         B     TMPRTURN       RETURN TO THE TMP.                        52485020
         SPACE                                                          52490020
STAICHK  EQU   *                                                        52495020
         L     R5,ECBTMPS     GET STAI ECB.                             52500020
         TM    X0(R5),X40     Q. HAS IT BEEN POSTED BY IKJEFT04.        52505020
         BZ    TMPRTURN       NO. MUST BE SOMETHING ELSE.               52510020
         MVI   X0(R5),X0      CLEAR THE ECB.                            52515020
         L     R5,X0(R5)      GET THE ECB PARM LIST ADDRESS.            52520020
         LTR   R1,R5          IS THERE AN ADDRESS.                      52525020
         BZ    TMPRTURN       NO. RETURN TO THE TMP.                    52530020
         L     R15,X0(R5)     GET BRANCH TO ADDRESS.(IKJEFT04)          52535020
         BALR  R14,R15        GO TO THE IKJEFT04 ROUTINE.               52540020
*        AT THIS TIME 'PROG ENDED DUE TO ERROR' MSG IS PRINTED.         52545020
         SPACE                                                          52560020
TMPRTURN EQU   *                                                        52640020
*        THIS SECTION OF CODE CLEANS UP AND RETURNS TO THE TMP IF FOR   52720020
*        ANY REASON THE INITIALIZATION OF TEST HAS FAILED.              52800020
         SPACE                                                          52880020
         MVI   TSTDCB,X0      INDICATE DCB MAY BE FREED.                52960020
         BAL   R11,FROMLDR    CLOSE AND FREE THE DCB.                   53040020
         BAL   R11,FREINBUF   FREE THE INPUT BUFFER IF ONE.             53120020
         BAL   R11,RELEASE    RELEASE THE PDL.                          53200020
         L     R1,SCPP4K      R1=SCPP RESERVE AREA ADDR.                53360020
         L     R0,CORE6K      SP=2,LENGTH=6144                          53440020
         FREEMAIN R,LV=(0),A=(1)    FREE IT.                            53520020
BLOW2LOC EQU   *                                                        53600020
         L     R0,TSTTCB      TCB ADDRESS FOR DAIR LIST                 53680020
         BAL   R11,UNALLOCT   UNALLOC ALL DATA SETS UNDER TEST'S TCB    53760020
         SPACE                                                          53762020
*        SOMETHING WENT WRONG, CLEAR THE INPUT BUFFERS.                 53764020
         TCLEARQ  INPUT                                                 53766020
         SPACE                                                          53768020
*        SOMETHING WENT WRONG , SO FLUSH THE STACK.                     53776020
         SPACE                                                          53784020
         L     R1,WORKAREA    PUT THE LIST INTO WORKAREA                53792020
         LA    R2,N16(R1)     SPACE FOR THE REST OF THE LIST.           53800020
         MVC   X0(N12,R1),PARMLIST   MOVE IN STANDARD PARM LIST.        53808020
         MVC   X0(STACKLEN,R2),STACKLST   MOVE LIST FORM OF STACK.      53816020
         ST    R2,N12(R1)     POINT TO LIST FORM.                       53824020
         STACK  DELETE=ALL,MF=(E,(1))   FLUSH THE STACK.                53832020
         L     R0,TSTTCB      CHANGE TEST'S TCBTRN FIELD TO '0'         53840020
         SR    R1,R1          ZERO.                                     53920020
         O     R0,TCBTRNFL    *                                         54000020
         SVC   TESTSVC        CHANGE IT.                                54080020
         MVC   TSTCURLD(FREMNLEN),FREMNLF MOVE L-FORM TO TCOMTAB.       54160020
         LA    R1,TSTCURLD    R1=FREEMAIN PARMLIST ADDR.                54240020
         LA    R2,GETMNLA     R2=LENGTH LIST ADDR.(LA LIST)             54320020
         LA    R3,SCPPAD      R3=LOCATION LIST ADDR.(A LIST)            54400020
         L     R13,X4(R13)    ADDR OF TMP SAVE AREA.                    54480020
         FREEMAIN L,LA=(2),A=(3),SP=1,MF=(E,(1)) FREE ELEMENTS.         54560020
BLOW1LOC EQU   *                                                        54640020
         SPACE                                                          54646020
*        THE SETTING OF THE ATTACHED ECB TO X'40000000' CAUSES          54652020
*        THE TMP TO DETACH THE SUBTASK.                                 54658020
         SPACE                                                          54664020
DETACH   EQU   *              FORCE A DETACH OF THE SUBTASK             54670020
         SR    R2,R2          ZERO                                      54676020
         L     R3,ECBTERM     GET THE ATTACHED ECB.                     54682020
         ST    R2,X0(R3)      ZERO THE ECB.                             54688020
         C     R2,TPLCTCB     CHECK IF ONE WAS ATTACHED.                54694020
         BE    NODETACH       SKIP THE POST SETTING.                    54700020
         MVI   X0(R3),X40     SET THE POST BIT FOR DETACH.              54706020
NODETACH EQU   *                                                        54712020
         LR    R1,R9          R1=TCOMTAB ADDR.                          54720020
         LA    R0,TCOMLEN     R0=TCOMTAB LENGTH.                        54800020
         O     R0,SP1         INSERT SUBPOOL NUMBER IN HIGH BYTE.       54880020
         FREEMAIN R,LV=(0),A=(1) FREE IT.                               54960020
         SPACE                                                          55040020
*        RESTORE REGISTERS AND RETURN TO THE TMP.                       55120020
         SPACE                                                          55200020
         RETURN (14,12),RC=4  RETURN TO TMP WITH RETURN CODE=4.         55280020
UNALLOCT EQU   *              UNALLOCATE BY TCB  CODE  2C               55360020
         L     R1,WORKAREA    ADDRESSABILITY TO GENERAL WORKAREA.       55440020
         LTR   R1,R1          TEST IF INITIALIZED.                      55520020
         BCR   Z,R11          NO.RETURN.                                55600020
         MVC   X0(LEN2C,R1),DAIR2C  UNALLOC TCB.                        55680020
         ST    R0,X4(R1)      TCB TO LIST.                              55760020
DAIR1    EQU   *                                                        55840020
         L     R14,WORKAREA   OBTAIN ADDRESSABILITY TO CWORKLDF         55920020
         LA    R14,CWORKLDF-TSTCWORK(R14) ADDR OF DAIR PARM LIST        56000020
         MVC   X0(N12,R14),PARMLIST  MOVE IN FIRST PORTION.             56080020
         L     R0,TPLPSCB     PSCB TO SECOND PORTION.                   56160020
         STM   R0,R1,N12(R14)  PSCB,DAIR PARMS TO LIST.                 56240020
         LR    R1,R14         DAIR LIST TO R1 FOR INPUT.                56320020
         LINK  EP=IKJDAIR     LINK TO DAIR                              56400020
         BR    R11            RETURN.                                   56480020
         SPACE                                                          56560020
RELEASE  EQU   *              RELEASE THE PDL                           56640020
         IKJRLSA TSTANSPL     RELEASE THE NEW PDL                       56720020
         XC    TSTANSPL(X4),TSTANSPL  ZERO TEST ANSWER PLACE            56800020
         BR    R11            RETURN.                                   56880020
         SPACE                                                          56960020
         SPACE                                                          58320020
NOCORE   EQU   *                                                        58400020
*        WRITE STORAGE DIAGNOSTIC AND RETURN TO THE TMP.                58480020
         SPACE                                                          58560020
         LA    R4,STORMSG     R4=ADDR OF DIAGNOSTIC.                    58720020
         BAL   R11,BLOWPUT    WRITE IT.                                 58800020
         B     BLOW1LOC       RETURN TO TMP.                            58880020
         SPACE                                                          58890020
NOCORE1  EQU   *                                                        58900020
         LA    R1,STORMSG     PRINT 'INSUFFICIENT CORE'                 58910020
         B     PUTRTURN       PRINT AND EXIT.                           58920020
         SPACE                                                          58960020
BLDLERR  EQU   *                                                        59040020
*        WRITE 1ST & 2ND LEVEL BLDL ERROR MESSAGES.RETURN TO  THE TMP.  59120020
X44      EQU   X'44'          HEXIDECIMAL 44.                           59200020
         SPACE                                                          59280020
         LA    R4,BLDLMSG     R4=ADDR OF DIAGNOSTIC.                    59360020
         BAL   R11,BLOWPUT    WRITE IT.                                 59440020
         B     TMPRTURN       RETURN TO TMP.                            59520020
         SPACE                                                          59600020
MAKEMSG  EQU   *              MAKE A DAIR MESSAGE                       59680020
         L     R15,IKJEGDDM   GET MSG MAKERS ADDRESS                    59760020
         BALR  R14,R15        SET UP MESSAGE ROUTINE                    59840020
         L     R1,OUTBUF      OUTBUF CONTAINS POINTERS FOR MSGS         59920020
         B     PUTRTURN       PRINT MESSAGE AND QUIT                    60000020
         SPACE                                                          60080020
INTSTAE  EQU   *                                                        60160020
*        STAE EXIT ROUTINE FOR THE INITIALIZATION PHASE OF TEST.        60240020
         SPACE                                                          60320020
         DROP  R12            ADDRESSABILITY.                           60400020
         USING *,R15          *                                         60480020
         BAL   R11,SETREGS    SETUP SOME BASIC REGISTERS                60560020
         XC    TSTCURLD(X8),TSTCURLD CLEAR TSTCURLD FOR USE AS PARMS.   60640020
         UNPK  TSTCURLD+X4(X5),TCBCMPC-TCB(X3,R4) UNPK COMP. CODE.      60720020
         TR    TSTCURLD+X4(X3),TRTABLE-XF0 MAKE PRINTABLE               60800020
         XC    TSTCURLD(X4),TSTCURLD   CLEAR FOR TEST                   60880020
         OC    TSTCURLD+X1(X3),RBAPSW+X1(R10)  SAVE RESUME ADDRESS      60960020
         BNZ   GOTPSW         GOT A GOOD PSW                            61040020
         MVC   TSTCURLD+X1(X3),RBOPSW+X5(R10)  SAVE RESUME ADDRESS      61120020
GOTPSW   EQU   *              GOT A GOOD ONE.                           61200020
         LA    R0,HOMEBASE    R0=RETRY ROUTINE E.P.                     61280020
         LA    R15,X4         R15=RETRY INDICATOR.                      61360020
         BR    R14            RETURN FOR RETRY.                         61440020
         SPACE                                                          61520020
*        DETERMINE IF THE ABEND WAS PREDICTED.IF SO,DETACH ANY SUB-TASK 61600020
*        WHICH MAY EXIST AND WRITE THE PROPER DIAGNOSTIC.OTHERWISE      61680020
*        WRITE AN 'UNPREDICTABLE ERROR' DIAGNOSTIC 2ND LEVEL MESSAGE    61760020
*        AND RETURN TO THE TMP.                                         61840020
         SPACE                                                          61920020
HOMEBASE EQU   *                                                        62000020
         DROP  R15            *                                         62080020
         USING *,R15          *                                         62160020
         BAL   R11,SETREGS    SETUP SOME BASIC REGISTERS                62240020
         L     R12,BASEAD     SETUP THE BASE REGISTER.                  62320020
         DROP  R15            RESET ORIGINAL ADDRESSABILITY             62400020
         USING IKJEGINT,R12   *                                         62480020
         L     R9,TCBTRN-TCB(R4)  GET TCOMTAB ADDRESS.                  62560020
         L     R13,REGSAVE1   RELOAD SAVE AREA ADDRESS.          A52066 62610021
         L     R10,TPLPTR     SETUP ADDRESSABILITY TO TPL               62640020
         LTR   R0,R0          CHECK FOR 104 BYTE W.A.                   62720020
         BNZ   NOWA           NO. WORK AREA                             62800020
         L     R0,CORE104     SP NUMBER AND LENGTH                      62880020
         FREEMAIN  R,LV=(0),A=(1)  FREE                                 62960020
NOWA     EQU   *              *                                         63040020
         LA    R4,ABENDLST    R4=ADDR OF LIST OF ABEND LOCATIONS.       63200020
LOOP5    EQU   *                                                        63280020
         L     R5,X0(,R4)     R5=PREDICTED ABEND RESUME POINT.          63360020
         LTR   R5,R5          Q.END OF LIST.                            63440020
         BM    MSGPROC        YES,WRITE MESSAGE.                        63520020
         C     R5,TSTCURLD    Q.THIS POINT=ABEND RESUME ADDR.           63600020
         BE    MSGPROC        YES,WRITE MESSAGE.                        63680020
         LA    R4,N16(,R4)    NO,TRY NEXT POINT.                        63760020
         B     LOOP5          *                                         63840020
         SPACE                                                          63920020
SETREGS  EQU   *              SET UP BASIC PROCESSING REGISTERS         64000020
         L     R2,CVT         CVT POINTER                               64080020
         L     R3,X0(R2)      NEW/CURRENT WORDS.                        64160020
         L     R4,X4(R3)      CURRENT TCB.                              64240020
         L     R7,TCBNSTAE-TCB(R4)  SCB ADDRESS.                        64320020
         LM    R7,R10,X0(R7)   LINK , EXIT EP , TCOMTAB , PRB           64400020
         BR    R11            RETURN                                    64480020
         SPACE                                                          64560020
MSGPROC  EQU   *                                                        64640020
*        PLACE 2ND LEVEL MESSAGE IN OUTPUT BUFFER,ADD MESSAGE ID (FROM  64720020
*        1ST LEVEL MESSAGE) AND ABEND CODE, LINK TO OUTPUT ROUTINE TO   64800020
*        WRITE THE MESSAGE(S) AND RETURN TO THE TMP.                    64880020
         SPACE                                                          64960020
         GETMAIN  R,LV=56     GET STORAGE FOR 2ND LVL MSG.              65040020
         L     R2,N12(R4)     CLEAN UP ADDRESS.                         65120020
         L     R5,X4(R4)      1ST LEVEL MESSAGE.                        65200020
         LR    R6,R1          GOTTEN STORAGE ADDRESS.                   65280020
         STM   R5,R6,TSTCURCT 1ST AND 2ND.                              65360020
         L     R7,X8(R4)      2ND LVL MSG                               65440020
         MVC   X0(X4,R6),X0(R7)  MOVE LENGTH.                           65520020
         MVC   X4(N10,R6),X4(R5)  MOVE 1ST ID TO 2ND.                   65600020
         MVC   N14(N16,R6),ABENDCOD  'ABEND CODE XXX. '                 65680020
         MVC   N26(X3,R6),TSTCURLD+X4  MOVE ABEND CODE.                 65760020
         MVC   N30(N26,R6),X4(R7)  MOVE 2ND TO GOTTEN CORE              65840020
         LA    R4,TSTCURCT    ADDR. OF 1ST AND 2ND.                     65920020
         LR    R3,R6          SAVE ADDRESS.                             66000020
         BAL   R11,BLOWPUT    PUT THE MESSAGE.                          66080020
         LR    R1,R3          GOTTEN CORE ADDRESS.                      66160020
         FREEMAIN  R,LV=56,A=(1)  FREE.                                 66240020
         BR    R2             GO TO CLEAN UP ADDRESS.                   66320020
BLOWPUT  EQU   *              PRINT MSG AND FOLD.                       66400020
* DO NOT USE R2,R3,R4                                                   66480020
         NC    REGSAVE1(X4),REGSAVE1  DID WE BLOW AT BLOW1.             66560020
         BNZ   SKIP1          YES. NO GETMAIN.                          66640020
         LR    R8,R13         SAVE REG 13.                              66720020
         GETMAIN R,LV=VALUE   GET STORAGE.                              66800020
VALUE    EQU   64+72+72       WORKAREA+REGSAVE1+REGSAVE5                66880020
         LA    R5,X0(R1)      CLEAR HIGH BYTE.                          66960020
         LA    R6,CWORKIO-TSTCWORK  OFFSET INTO WORKAREA FOR IO.        67040020
         SR    R5,R6          CWORKIO OFFSET FOR IO.                    67120020
         LA    R6,N64(R1)     ADDR=REGSAVE1 ADDR.                       67200020
         LA    R7,N72(R6)     ADDR=REGSAVE5 ADDR.                       67280020
         STM   R5,R6,WORKAREA  SAVE.                                    67360020
         LR    R5,R1          SAVE FOR FREEMAIN.                        67440020
         ST    R7,REGSAVE5    PUT IN PROPER SLOT.                       67520020
         LR    R13,R6         SET UP SAVE AREA.                         67600020
         ST    R8,X4(R13)     SAVE BACK POINTER.                        67680020
         ST    R13,X8(R8)     SAVE FORWARD POINTER.                     67760020
SKIP1    EQU   *              *                                         67840020
         LCR   R1,R4          MESSAGE FOR IO                            67920020
         L     R15,TPUTADDR   IO'S PUTLINE ADDR.                        68000020
         BALR  R14,R15        PUT THE MESSAGE.                          68080020
         NC    BLDLIST(X4),BLDLIST  DID WE BLOW AT BLOW1.               68160020
         BNZ   SKIP2          NO.                                       68240020
         LR    R1,R5          GOTTEN STORAGE.                           68320020
         LR    R13,R8         PUT R13 BACK.                             68400020
         FREEMAIN  R,LV=VALUE,A=(1)                                     68480020
SKIP2    EQU   *              *                                         68560020
         BR    R11            RETURN.                                   68640020
         SPACE                                                          68720020
MEMMVC   MVC   X4(X0,R1),X0(R6)  *                                      68800020
ADDCB    DCB   DSORG=PO,MACRF=(R) DEFINE A DCB.                         68880020
**********************************************************************  68960020
LFORM    OPEN  (,(INPUT)),MF=L OPEN LIST FORM.                          69040020
CLFORM   CLOSE (CLFORM),MF=L  CLOSE LIST FORM.                          69120020
LSTDSCP  DC    X'0001003A'    BLDL LIST DESCRIPTION.                    69200020
BLANKS   DC    CL8' '         8 BLANKS                                  69280020
ABENDCOD DC    CL16'SYSTEM CODE XXX '  FOR 2ND LEVEL MESSAGE.           69360020
DCBDDNAM EQU   40             DISPLACEMENT OF DDNAME FIELD IN DCB       69440020
         SPACE                                                          69520020
         SPACE                                                          69600020
*********************************************************************** 69680020
LOAD     DC    C'LOAD    '    'LOAD' DEFAULT QUALIFIER.                 69760020
OBJECT   DC    C'OBJ     '    'OBJECT' DEFAULT QUALIFIER.               69840020
IKJEG    DC    C'IKJEG'       FRONT OF EVERY LOAD NAME.                 69920020
IOCONS   DS    0F             V-CONS FOR IKJEGIO1 E.P.'S.               70000020
         DC    V(IKJEGGT)     GETLINE ENTRY                             70080020
         DC    V(IKJEGPT)     PUTLINE ENTRY                             70160020
         DC    V(IKJEGPG)     PUTGET ENTRY                              70240020
SCDNAMES DC    V(IKJEGNAM)    SUBCOMMAND LOAD NAMES                     70320020
SCDBLDL  DC    V(IKJEGBSZ)    PTR TO 'BLDLIST' SIZE (IKJEGSCD)          70400020
SCDSCPP  DC    V(IKJEGSSZ)    PTR TO SCPPAD SIZE                        70480020
IKJEGDDM DC    V(IKJEGDDM)    DAIR DISASTER MESSAGE MAKER ROUTINE       70560020
HIGHBIT  DC    X'80000000'    'OR' IN HIGH BIT.                         70640020
TSTCPON  DC    X'40000000'    *                                         70720020
TCBTRNFL DC    X'10000000'    *                                         70800020
CHANGE14 DC    X'0E000000'    CHANGE REGISTER 14.                       70880020
RGCHANGE DC    X'04000000'    CHANGE A REGISTER.                        70960020
ICCHANGE DC    X'08000000'    CHANGE THE IC                             71040020
WAITOFF  DC    X'01000000'    TURN OFF WAIT COUNT FIELD IN PP.          71120020
FOUR     DC    F'4'           FOUR.                                     71200020
POST7F   DC    X'3F000000'    POST STAI EXIT WITH A '7F'                71280020
BASEAD   DC    A(IKJEGINT)    BASE ADDRESS FOR THIS MODULE.             71360020
CORE6K   DC    AL1(2),AL3(6144)  SUBCOMMAND RESERVE STORAGE             71440020
CORE104  DC    AL1(0),AL3(104)  104 BYTE STAE W.A.                      71520020
STORMSG  DC    A(FAILURE,CORE2ND)  INSUFFICIENT STORAGE                 71600020
BLDLMSG  DC    A(FAILURE,BLDL2ND)  PERMANENT ERROR DURING BLDL          71680020
MEMMSG   DC    A(MEM1ST,0)    MEMBER NOT IN DATA SET                    71760020
MGNOTRY  DC    A(MGNOTRY1,0)  'NO ACTIVE PROGRAM LEFT TO TEST'          71800020
PCLADDR  DC    V(IKJEGYNT)    *                                         71840020
ZERO     DC    F'0'           ZERO                                      71920020
EIGHT    DC    F'8'           EIGHT                                     72000020
TWELVE   DC    F'12'          TWELVE                                    72080020
TWENTY4  DC    F'24'          TWENTY FOUR.                              72160020
SP1      DC    X'01000000'    SUB-POOL ONE INDICATOR.                   72240020
CORETRN  DC    AL1(1),AL3(12)  CONTROL WORDS FOR SVC INFO BLOCK.        72320020
ATTNCODE DC    F'16'          RETURN CODE ON ATTENTION INTERRUPT.       72400020
SVC      SVC   TESTSVC        TEST SVC                                  72480020
         SVC   EXITSVC        EXIT SVC                                  72560020
         IKJDAP08                                                       72640020
DA08LEN  EQU   *              DSECT LENGTH                              72720020
IKJEGINT CSECT                                                          72800020
DAIR08   DC    (DA08LEN-DAPB08)X'0'  INITIALIZE BEFORE ORGS             72880020
         ORG   DA08CD-DAPB08+DAIR08    *                                72960020
         DC    XL2'0008'      CODE                                      73040020
         ORG   DA08DDN-DAPB08+DAIR08   *                                73120020
         DC    CL8' '         DDNAME                                    73200020
         ORG   DA08UNIT-DAPB08+DAIR08  *                                73280020
         DC    CL8' '         UNITNAME                                  73360020
         ORG   DA08SER-DAPB08+DAIR08   *                                73440020
         DC    CL8' '         VOLUME SERIAL NUMBER                      73520020
         ORG   DA08MNM-DAPB08+DAIR08   *                                73600020
         DC    CL8' '         MEMBER NAME                               73680020
         ORG   DA08PSWD-DAPB08+DAIR08  *                                73760020
         DC    CL8' '         PASSWORD                                  73840020
         ORG   DA08DSP1-DAPB08+DAIR08  *                                73920020
         DC    AL1(DA08SHR)   DISP=SHR                                  74000020
         ORG   DA08LEN-DAPB08+DAIR08   *                                74080020
LEN08    EQU   *-DAIR08       *                                         74160020
         IKJDAP1C                                                       74240020
DA1CLEN  EQU   *              DSECT LENGTH                              74320020
IKJEGINT CSECT                                                          74400020
DAIR1C   DC    (DA1CLEN-DAPB1C)X'0'  INITIALIZE BEFORE ORGS             74480020
         ORG   DA1CCD-DAPB1C+DAIR1C    *                                74560020
         DC    XL2'001C'      CODE                                      74640020
         ORG   DA1CDDN-DAPB1C+DAIR1C   *                                74720020
         DC    CL8' '         DDNAME                                    74800020
         ORG   DA1CLEN-DAPB1C+DAIR1C   *                                74880020
LEN1C    EQU   *-DAIR1C       *                                         74960020
         IKJDAP2C                                                       76160020
DA2CLEN  EQU   *              DSECT LENGTH                              76240020
IKJEGINT CSECT                                                          76320020
DAIR2C   DC    (DA2CLEN-DAPB2C)X'0'  INITIALIZE BEFORE ORGS             76400020
         ORG   DA2CCD-DAPB2C+DAIR2C    *                                76480020
         DC    XL2'002C'      CODE                                      76560020
         ORG   DA2CLEN-DAPB2C+DAIR2C   *                                76640020
LEN2C    EQU   *-DAIR2C       *                                         76720020
ABENDLST DS    0F                                                       76800020
ABTAB    DS    0F             *                                         76840020
         DC    A(BLOW1)       GETMAIN FAILURE.                          76880020
         DC    A(FAILURE,GETAB2ND)  *                                   76960020
         DC    A(BLOW1LOC)    *                                         77040020
         DC    A(BLOW2)       *                                         77120020
         DC    A(FAILURE,GETAB2ND)  *                                   77200020
         DC    A(BLOW2LOC)    *                                         77280020
         DC    A(BLOW3)       XCTL TO IKJEGMN1 FAILURE.                 77360020
         DC    A(FAILURE,XCTL2ND)   XCTL TO MAINLINE FAILURE            77440020
         DC    A(TMPRTURN)    *                                         77520020
         DC    A(BLOW5)       LINK TO PARSE FAILURE.                    77600020
         DC    A(FAILURE,LINK2ND)  LINK TO PARSE FAILURE                77680020
         DC    A(TMPRTURN)    *                                         77760020
         DC    A(BLOW6)       ATTACH IKJEGLDR FAILURE.                  77840020
         DC    A(FAILURE,ATTCH2ND)  ATTACH LOADER FAILURE.              77920020
         DC    A(TMPRTURN)    *                                         78000020
         DC    4X'FF'         END-OF-LIST FLAG.                         78080020
         DC    A(FAILURE,NOIDEA)  UNPREDICTABLE FAILURE                 78160020
         DC    A(TMPRTURN)    *                                         78240020
         SPACE                                                          78320020
TRTABLE  DC    C'0123456789'  HEX-CHARACTER CONVERSION TABLE.           78400020
         DC    C'ABCDEF'      *                                         78480020
TEMPNAME DC    A(*+4),C'TEMPNAME' THIS IS THE MEMBER NAME IF NONE .     78560020
TEST     DC    CL8'TEST'      TEST CONSTANT                             78640020
ABEND    DC    C'ABENDB'      ABEND CONSTANT.                           78680020
         SPACE                                                          78720020
STAELF   STAE  INTSTAE,PARAM=INTBASE,MF=L                               78800020
STAELFLN EQU   *-STAELF                                                 78880020
STACKLST STACK DELETE=ALL,MF=L       LIST FORM.                         78960020
STACKLEN EQU   *-STACKLST     LENGTH OF STACK LIST.                     79040020
XCTLFORM XCTL  EP=IKJEGMNL,SF=L                                         79120020
XCTLLEN  EQU   *-XCTLFORM                                               79200020
NONAME   DSECT                                                          79280020
ATTCHLFM ATTACH EP=IKJEGLDR,SF=L                                        79360020
ATTCHLLN EQU   *-ATTCHLFM                                               79440020
IKJEGINT CSECT                                                          79520020
FREMNLF  FREEMAIN L,MF=L                                                79600020
FREMNLEN EQU   *-FREMNLF                                                79680020
IKJEGYNT IKJPARM                                                        79760020
DSNAME   IKJPOSIT DSNAME,PROMPT='DSNAME'                                79840020
STRING   IKJPOSIT QSTRING                                               79920020
LOADOBJ  IKJKEYWD DEFAULT='LOAD'                                        80000020
         IKJNAME 'LOAD'                                                 80080020
         IKJNAME 'OBJECT'                                               80160020
CPNOCP   IKJKEYWD DEFAULT='NOCP'                                        80240020
         IKJNAME 'CP'                                                   80320020
         IKJNAME 'NOCP'                                                 80400020
         IKJENDP                                                        80480020
         SPACE                                                          80560020
*              GENERAL EQUATES.                                         80640020
X0       EQU   0              HEXIDECIMAL 0                             80720020
X1       EQU   1              HEXIDECIMAL 1                             80800020
X2       EQU   2              HEXIDECIMAL 2                             80880020
X3       EQU   3              HEXIDECIMAL 3                             80960020
X4       EQU   4              HEXIDECIMAL 4                             81040020
X5       EQU   5              HEXIDECIMAL 5                             81120020
X6       EQU   6              HEXIDECIMAL 6                             81200020
X7       EQU   7              HEXIDECIMAL 7                             81280020
X8       EQU   8              HEXIDECIMAL 8                             81360020
X9       EQU   9              HEXIDECIMAL 9                             81440020
X10      EQU   X'10'          HEXIDECIMAL 10                            81520020
N10      EQU   10             TEN                                       81600020
N12      EQU   12             TWELVE                                    81680020
N13      EQU   13             THIRTEEN.                                 81760020
N14      EQU   14             FOURTEEN.                                 81840020
N15      EQU   15             FIFTEEN.                                  81920020
N16      EQU   16             SIXTEEN.                                  82000020
N17      EQU   17             SEVENTEEN.                                82080020
N18      EQU   18             EIGHTEEN.                                 82160020
N20      EQU   20             TWENTY.                                   82240020
N21      EQU   21             TWENTY ONE                                82320020
N23      EQU   23             TWENTY THREE.                             82400020
N24      EQU   24             TWENTY FOUR                               82480020
N25      EQU   25             TWENTY-FIVE.                              82560020
N26      EQU   26             TWENTY SIX                                82640020
N30      EQU   30             THIRTY.                                   82720020
N35      EQU   35             THIRTY FIVE.                              82800020
N43      EQU   43             FORTY THREE.                              82880020
N52      EQU   52             FIFTY TWO                                 82960020
N58      EQU   58             FIFTY EIGHT                               83040020
N64      EQU   64             SIXTY FOUR.                               83120020
N72      EQU   72             SEVENTY TWO.                              83200020
N80      EQU   80             EIGHTY                                    83280020
N88      EQU   88             EIGHTY EIGHT                              83360020
N92      EQU   92             NINETY TWO                                83440020
N98      EQU   98             NINETY EIGHT                              83520020
N99      EQU   99             NINETY NINE                               83600020
N100     EQU   100            ONE HUNDRED                               83680020
N101     EQU   101            ONE HUNDRED ONE                           83760020
N160     EQU   160            ONE HUNDRED SIXTY                         83840020
X0F      EQU   X'0F'          HEXIDECIMAL 0F                            83920020
X40      EQU   X'40'          HEXIDECIMAL 40                            83960020
X80      EQU   X'80'          HEXIDECIMAL 80                            84000020
X88      EQU   X'88'          DISPLACEMENT OF C'ABEND' IN SVRB.         84040020
XC0      EQU   X'C0'          HEXIDECIMAL C0                            84080020
XF0      EQU   X'F0'          HEXIDECIMAL F0                            84160020
XFF      EQU   X'FF'          HEXIDECIMAL FF                            84240020
NE       EQU   7              NOT EQUAL CONDITION.                      84320020
SIZE     EQU   21             COMPRESSED BLDL ENTRY SIZE.               84400020
RBAPSW   EQU   4              APSW IN RB.                               84480020
RBSIZE   EQU   9              SIZE OF RB.                               84520020
RBSTAB   EQU   10             DISP OF STATUS/ATTRIBUTE BITS (RB).       84560020
RBCDE    EQU   12             DISP OF CDE POINTER (RB).                 84640020
RBOPSW   EQU   16             DISP OF RESUME PSW (RB).                  84720020
RBWCF    EQU   28             WAIT COUNT.                               84760020
RBLINK   EQU   28             DISP OF LINK FIELD (RB).                  84800020
RBGRSAVE EQU   32             REGSAVE AREA IN SVRB.                     84880020
RBEXSAVE EQU   96             RB EXTENDED SAVE AREA.                    84960020
         SPACE                                                          85040020
CDATTR   EQU   0              DISP OF ATTRIBUTE BITS (CDE).             85120020
CDNAME   EQU   8              DISP OF MODULE NAME FIELD (CDE).          85200020
CDEEPA   EQU   16             CDE E.P.A.                                85280020
CDATTR2  EQU   20             DISP OF EXTENT LIST POINTER (CDE).        85360020
         SPACE                                                          85440020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT       85520020
TESTSVC  EQU   97             TEST'S SVC                                85600020
EXITSVC  EQU   3              EXIT SVC NUMBER                           85680020
         SPACE                                                          85760020
OUTBUFLN EQU   168            OUTPUT BUFFER LENGTH.                     85840020
REGSVLN  EQU   360            REGISTER SAVE AREAS (5) LENGTH.           85920020
CONARLN  EQU   72             CONVERT OUTPUT AREA LENGTH (+8).          86000020
GENWKLN  EQU   400            GENERAL WORK AREA LENGTH.                 86080020
ATTNLEN  EQU   132            ATTN INPUT BUFFER LENGTH.                 86160020
STAXLEN  EQU   20             STAX LIST FORM LENGTH.                    86240020
ATNBUFLN EQU   ATTNLEN+STAXLEN  ATTN INPUT BUFFER + STAX INPUT PARMS    86320020
PASSWORD EQU   DSNAME+16      POINTER,LEN,FLGS,RES                      86340020
INDSNPER EQU   C'.'           CHARACTER PERIOD.                  A43321 86345021
         EJECT                                                          86360020
         TCOMTAB                                                        86400020
BLDLAREA EQU   CONAREA        AREA TO SAVE BLDL ENTRY FOR 'LDR'         86480020
TERMDD   EQU   TSTCONVT       DDNAME SAVE FOR ALLOCATED SYSTERM DD      86560020
CLEARLN1 EQU   TCOMLEN-CLEARLEN  THE REST OF TCOMTAB TO ZERO.           86640020
         SPACE                                                          86720020
INDFLTPM DSECT                                                   A43321 86725021
INDFLTPL DS    4F             DEFAULT SERVICE ROUTINE PARM LIST  A43321 86730021
INDFLTPB DS    3F             DEFAULT SERVICE ROUTINE PARM BLOCK A43321 86735021
         DS    70C            RESERVED, TO PRESERVE ALIGNMENT    A43321 86740021
INDSNLEN DS    H              LENGTH OF DATA SET NAME            A43321 86745021
INTSTDSN DS    CL44           DATA SET NAME FROM TEST COMMAND    A43321 86750021
         EJECT                                                          86755021
         IKJDFPL                                                 A43321 86760021
         EJECT                                                          86765021
         IKJDFPB                                                 A43321 86770021
         EJECT                                                          86775021
         TSTCWORK                                                       86800020
         IKJTPL                                                         86880020
         SPACE                                                          86960020
         IKJPSCB                                                        87040020
         SPACE                                                          87120020
         IKJTCB                                                         87200020
M        EQU   TCBOTC-TCB     MOTHER TASK.                              87280020
S        EQU   TCBNTC-TCB     SISTER TASK.                              87360020
D        EQU   TCBLTC-TCB     DAUGHTER TASK.                            87440020
         SPACE                                                          87520020
         IKJECT                                                         87600020
         SPACE                                                          87680020
*        PARSE                                                          87760020
         IKJPPL                                                         87840020
*        DAIR                                                           87920020
         IKJDAPL                                                        88000020
         REGEQU                                                         88080020
         SPACE                                                          88160020
IKJEGXNT CSECT                                                          88240020
         DS    0H             *                                         89040020
MEM1ST   EQU   *              *                                         89120020
         DC    AL2(MEM1STL,0) *                                         89200020
         DC    C'IKJ57005I '  *                                         89280020
INSERT1  EQU   *-MEM1ST+7     INSERT MEMBER NAME.                       89360020
         DC    C'MEMBER          NOT IN DATA SET ' *                    89440020
INSERT2  EQU   *-MEM1ST       INSERT DATA SET NAME.                     89520020
MEM1STL  EQU   *-MEM1ST+35    *                                         89600020
         DS    0H                                                       89680020
FAILURE  EQU   *                                                        89760020
         DC    AL2(FAILUREL)        *                                   89840020
         DC    2X'00'         *                                         89920020
         DC    C'IKJ57001I TEST ENDED DUE TO ERROR+'  *                 90000020
FAILUREL EQU   *-FAILURE      *                                         90080020
         DS    0H             *                                         90160020
CORE2ND  EQU   *                                                        90240020
         DC    AL2(CORE2NDL)        *                                   90320020
         DC    2X'00'         *                                         90400020
         DC    C'IKJ57001I INSUFFICIENT STORAGE'            *           90480020
CORE2NDL EQU   *-CORE2ND      *                                         90560020
         DS    0H             *                                         90640020
BLDL2ND  EQU   *                                                        90720020
         DC    AL2(BLDL2NDL)        *                                   90800020
         DC    2X'00'         *                                         90880020
         DC    C'IKJ57001I PERMANENT ERROR DURING BLDL'     *           90960020
BLDL2NDL EQU   *-BLDL2ND      *                                         91040020
         DS    0H             *                                         91120020
GETAB2ND EQU   *                                                        91200020
         DC    AL2(GETAB2L)         *                                   91280020
         DC    2X'00'         *                                         91360020
         DC    C'GETMAIN FAILURE'       *                               91440020
GETAB2L  EQU   *-GETAB2ND+26   *                                        91520020
         DS    0H             *                                         91600020
XCTL2ND  EQU   *                                                        91680020
         DC    AL2(XCTL2NDL)        *                                   91760020
         DC    2X'00'         *                                         91840020
         DC    C'XCTL FAILURE'          *                               91920020
XCTL2NDL EQU   *-XCTL2ND+26     *                                       92000020
         DS    0H             *                                         92080020
*        MORE MESSAGES.                                                 92160020
LINK2ND  EQU   *                                                        92240020
         DC    AL2(LINK2NDL,0)        *                                 92320020
         DC    C'LINK FAILURE'  *                                       92400020
LINK2NDL EQU   *-LINK2ND+26     *                                       92480020
         DS    0H             *                                         92560020
ATTCH2ND EQU   *                                                        92640020
         DC    AL2(ATTCH2L)         *                                   92720020
         DC    2X'00'         *                                         92800020
         DC    C'ATTACH FAILURE'  *                                     92880020
ATTCH2L  EQU   *-ATTCH2ND+26    *                                       92960020
         DS    0H             *                                         93040020
NOIDEA   EQU   *                                                        93120020
         DC    AL2(NOIDEAL)         *                                   93200020
         DC    2X'00'         *                                         93280020
         DC    C' '           UNPREDICTABLE ERROR(NO MSG)               93360020
NOIDEAL  EQU   *-NOIDEA+26      *                                       93440020
         DS    0H             *                                         93520020
MGNOTRY1 DC    Y(MGNOTRYL,0),C'IKJ57002I NO ACTIVE PROGRAM LEFT' 1LVL   93540020
MGNOTRYL EQU   *-MGNOTRY1     LENGTH.                                   93560020
         SVC   TESTSVC        DITTO.                                    93580020
LAST     EQU   *                                                        93600020
         SPACE                                                          93680020
         SPACE                                                          93760020
         END   IKJEGINT                                                 93840020
