         TITLE 'IKJEGIO   TEST I/O MODULE'                              00060020
*********************************************************************** 00110020
* STATUS -- VERSION NO. 02, OS/360 RELEASE NO. 21                     * 00112021
*                                                                     * 00114020
* FUNCTION                                                            * 00116020
*    THIS MODULE IS RESPONSIBLE FOR I/O REQUESTS FROM THE TEST        * 00118020
*    MODULES.  IT HANDLES REQUESTS FROM ANY TEST MODULE WHICH         * 00118420
*    WISHES TO GET OR PUT A LINE FROM OR TO THE TERMINAL, OR IN       * 00118820
*    THE CASE OF THE LIST PROCESSORS, FOR OUTPUT WITH THE PRINT       * 00119220
*    KEYWORD SPECIFIED, TO AN OUTPUT DATA SET.                        * 00119620
*                                                                     * 00119720
* ENTRY POINTS                                                        * 00119820
*                                                                     * 00119920
*    IKJEGPT-ENTERED FOR ALL REQUESTS FOR OUTPUT TO THE TERMINAL      * 00139920
*            OR TO AN OUTPUT DATA SET.  I/O WILL ONLY PRINT INTO      * 00149920
*            PHYSICAL SEQUENTIAL DATA SETS.                           * 00159920
*                                                                     * 00166620
*    IKJEGPG-ENTERED FOR ALL REQUESTS FOR INPUT FROM THE TERMINAL     * 00168620
*            OR FROM A SUB-COMMAND CHAIN.                             * 00170620
*                                                                     * 00172620
*    IKJEGPG-THIS ROUTINE IS USED TO PUT OUT THE INITIAL INFORMATION  * 00173020
*            AND TO WAIT FOR THE IMMEDIATE RESPONSE FROM THE USER.    * 00173120
*                                                                     * 00173220
* INPUT                                                               * 00189920
*    INPUT PARAMETERS FOR IKJEGPT ARE PROVIDED IN REGISTER 0 AND 1.   * 00199920
*    IF REGISTER 1 IS NEGATIVE, THE DATA GOING TO THE TERMINAL IS     * 00200320
*    AN ERROR MESSAGE AND THE DOUBLE WORD PARAMETER LIST POINTS TO    * 00200720
*    THE FIRST AND SECOND LEVEL MESSAGES.                             * 00201120
*                                                                     * 00201520
*    IF REGISTER 1 IS NEGATIVE WE HAVE DATA GOING TO A TERMINAL       * 00201620
*    OR TO A DATA SET.  TSTPRINT SWITCH DETERMINES IF THE OUTPUT IS   * 00201720
*    TO A TERMINAL OR A DATASET.  IF TSTPRINT SWITCH IS ON, REGISTER  * 00201820
*    1 CONTAINS A POINTER TO A DOUBLEWORD.  THE FIRST WORD POINTS TO  * 00201920
*    THE INFORMATION TO BE PUT OUT, THE SECOND WORD IS ZERO.  REGISTER* 00202320
*    ZERO IS ZERO IF THE DATA SET IS ALREADY OPEN OR A POINTER TO A   * 00202720
*    DSNAME PDE IF THE DATA SET IS TO BE OPEN.                        * 00203120
*                                                                     * 00203220
*    WHEN CALLING IKJEGPG REGISTER ONE CONTAINS A POINTER TO THE      * 00203320
*    FIRST MESSAGE AND THE SECOND WORD CONTAINS A POINTER TO THE      * 00203720
*    SECOND LEVEL MESSAGE IF ONE EXISTS, OTHERWISE IT IS ZERO.        * 00203820
*                                                                     * 00203920
*    IKJEGIO IS ENTERED AT THE IKJEGGT ENTRY POINT FOR ALL REQUEST    * 00205920
*    FOR INPUT FROM THE TERMINAL.  THERE ARE NO INPUT PARAMERERS,     * 00206320
*    THE ASSUMPTION BEING THAT IKJEGIO IS TO ACQUIRE A SINGLE LINE    * 00206420
*    OR A SUBCOMMAND CHAIN FROM THE TERMINAL.                         * 00206520
*                                                                     * 00206620
* OUTPUT                                                              * 00206720
*    IKJEGIO WILL PRINT MESSAGES AND DATA TO TERMINAL.  VARIABLE      * 00206820
*    BLOCKED DATA SETS WILL BE WRITTEN INTO IF REQUESTED.  IF NEEDED  * 00207620
*    NEW DATA SETS WILL BE ALLOCATED.                                 * 00208020
*                                                                     * 00208420
*    WHEN IKJEGIO GETS A LINE FROM THE TERMINAL THE ADDRESS OF THE    * 00208820
*    INPUT LINE IS PLACED INBUF FOUND IN TCOMTAB.                     * 00209220
*                                                                     * 00209620
* EXTERNAL REFERENCES                                                 * 00209720
*                                                                     * 00209820
*    IKJPUTL-PUTS LINE TO TERMINAL.                                   * 00210120
*    IKJGETL-GETS LINE FROM TERMINAL.                                 * 00210520
*    IKJPTGT-PUTS LINE TO TERMINAL AND WAITS FOR REPLY.               * 00210620
*    IKJDAIR-DYNAMIC ALLOCATION ROUTINE.                              * 00210720
*                                                                     * 00210820
* EXIT,NORMAL                                                         * 00210920
*    RETURN VIA GENERAL PURPOSE REGISTER FOURTEEN.                    * 00211020
*    RETURN CODE ZERO IN GENERAL PURPOSE REGISTER FIFTEEN.            * 00211120
*                                                                     * 00211520
* EXIT,ERROR                                                          * 00211920
*    RETURN VIA GENERAL PURPOSE REGISTER FOURTEEN.                    * 00212020
*    RETURN CODE FOUR - UNSUCCESSFUL REQUEST.                         * 00212120
*    RETURN CODE SIXTEEN - ATTENTION IN EFFECT.                       * 00212220
*                                                                     * 00212320
* TABLES/WORKAREAS                                                    * 00212420
* ATTRIBUTES                                                          * 00212820
*    REENTRANT,REFRESHABLE                                            * 00212920
*                                                                     * 00213320
* NOTES                                                               * 00213420
*********************************************************************** 00213720
         SPACE                                                          00214120
IKJEGIO  CSECT               STARTING POINT OF I/O MODULE.              00214520
*RELEASE 21                                                             00214621
*A007588                                                         A49889 00214721
*C007590                                                         A49889 00214821
         ENTRY IKJEGPT,IKJEGGT,IKJEGPG                                  00214920
BASELOC EQU    *             EQUATE ENTRY POINT TO THIS ADDRESS         00215320
IKJEGPT  EQU   *                                                        00215720
IOLVL01  SAVE  (14,12),,*                                               00216120
         USING IKJEGPT,R15   USE ENTRY POINT FOR ADDRESSING             00217420
         L     R12,BASE      PLACE BEGINNING ADDRESS OF PROG IN R12     00218920
         B     PUTLINE       BRANCH TO PUTLINE ROUTINE                  00220420
IKJEGPG  EQU   *                                                        00221920
         SAVE  (14,12)       SAVE REGISTERS                             00223420
         DROP  R15           DROP REG15 AS BASE REGISTER                00224920
         USING IKJEGPG,R15   USE ENTRY POINT FOR ADDRESSING             00226420
         L     R12,BASE      PLACE BEGINNING ADDR OF PROG IN R12        00227920
         B     PUTGET        BRANCH TO PUTGET ROUTINE                   00229420
IKJEGGT  EQU   *                                                        00230920
         SAVE  (14,12)       SAVE REGISTERS                             00232420
         DROP  R15                                                      00233920
         USING IKJEGGT,R15   USE ENTRY POINT FOR ADDRESSING             00235420
         L     R12,BASE      LOAD BEGINNING ADDRESS OF PROGRAM IN       00236920
         DROP  R15                                                      00238420
         USING BASELOC,R12   USE BEGINNING ADDRESS AS BASE ADDR         00239920
         USING TCOMTAB,R9    USE REG9 TO ADDRESS TCOMTAB                00241420
         SPACE                                                          00242920
************************************************************            00252920
** HAVING SAVED REGISTERS,WE WILL OBTAIN THE ADDRESS IF   **            00254920
** OUR SAVE AREA FROM TCOMTAB. BACK AND FORWARD POINTERS  **            00256920
** WILL BE PLACED IN RESPECTIVE SAVE AREAS. THE INPUT     **            00257320
** BUFFER ADDRESS WILL BE OBTAINED FROM TCOMTAB AND THEN  **            00262020
** BLANKED OUT. SUBCHAIN FOUND IN TCOMTAB WILL BE CHECKED **            00264020
** FOR ZERO. IF NOT ZERO WE MUST GET DATA FROM SUB-       **            00266020
** COMMAND CHAIN.                                         **            00266420
************************************************************            00266820
         SPACE                                                          00271520
         L     R4,REGSAVE5   PLACE ADDR OF MY SAVEAREA INTO R4          00271620
*                            FROM TCOMTAB AND PLACE IN REG4             00273620
         ST    R13,@4(R4)    PLACE ADDR OF CALLERS SAVEAREA             00275620
*                            INTO MY SAVEAREA FORWARD POINTER           00276020
         LR    R13,R4        PLACE MY SAVE AREA DDR IN REG13            00276120
         L     R1,INBUF      GET ADDRESS OF INPUT AREA FROM             00276220
*                            TCOMTAB AND PLACE IN REG1                  00276320
         L     R2,SUBCHAIN   GET SUBCHAIN ADDRESS FROM TCOMTAB          00281020
         LTR   R2,R2         TEST FOR ADDRESS BEING PRESENT             00281120
         BZ    A00700        IF ZERO NONE PRESENT BRANCH OUT            00283120
************************************************************            00285120
** SUB-COMMAND TESTED OTHER THAN ZERO WHICH MEANS WE      **            00285520
** ARE TO PROCESS A SUBCOMMAND CHAIN. REGISTER2 WILL BE   **            00285620
** USED TO SCAN THE CHAIN. WE WILL LOOK FOR A SEMI-COLON  **            00285720
** OR ZEROS. WHEN A SEMI-COLON IS FOUND THIS INDICATES    **            00285820
** THE END OF ONE COMMAND. THIS COMMAND WILL BE PLACED    **            00298120
** INTO AN INBUF AREA GOTTEN WITH A GETMAIN. THE ADDRESS  **            00298520
** OF THE GETMAIN AREA IS PLACED INTO INBUF AND A RETURN  **            00298920
** TO MAINLINE EXECUTED.WHEN ZERO IS FOUND THIS INDICATES **            00299320
** END OF THE CHAIN                                       **            00299720
************************************************************            00299820
         XR    R3,R3         ZERO OUT R3 TO USE IT AS LENGTH COUNTER    00299920
         XR    R4,R4         WE NEED R4 TO ACT AS LENGTH COUNTER        00300020
         LA    R2,@2(R2)     INCREMENT R2 PASS LENGTH FIELD             00310020
         LR    R6,R2         PLACE BEGINNING ADDR OF CHAIN IN R6        00310420
A005000  EQU   *             EQUATE LABEL TO THS ADDRESS                00310520
         CLI   @0(R2),HEX00  CHECK TO SEE IF WE ARE AT THE END          00310620
         BNE   A00500        IF NOT AT END OF SUBCMD THEN BRANCH        00310720
         NI    TSTFLGS2,HEXFF-LEFTPREN TURN OFF LEFT PREN SW            00314820
         NI    TSTFLGS2,HEXFF-FIRSTQSW TURN OFF FIRST QUOTE SW          00316820
         B     A00519        BRANCH TO TERMINATE SUBCMD PROCESSING      00318820
A00500   EQU   *             EQUATE LABEL TO THIS ADDRESS               00318920
         CLI   @0(R2),HEX4D  DO WE HAVE A LEFT PARENTHESIS              00323020
         BNE   A00501        IF NOT THEN BRANCH TO CHECK SOME MORE      00323120
         TM    TSTFLGS2,FIRSTQSW SEE IF A FIRST QUOTE WAS FOUND         00325120
         BO    A00505        IF ON DONT KEEP COUNT OF THIS PAREN        00327120
         LA    R3,@1(R3)     KEEP A COUNT OF PARENS IN R3               00331220
         OI    TSTFLGS2,LEFTPREN TURN ON LEFT PARENTHESIS FOUND SW      00331320
         B     A00505        BRANCH TO INCREMENT POINTER AND COUNT      00333320
************************************************************            00335320
** THE SUBCOMMAND CHAIN IS SCANNED USING THIS SCAN        **            00339420
** WE CHECK FOR A SEMI-COLON,LEFT AND RIGHT PARENTHESIS   **            00339520
** AND END OF THE CHAIN. IF AN APOSTROPHY IS ENCOUNTERED  **            00341520
** SWITCHES ARE TURNED ON SO THAT SEMI-COLONS AND         **            00343520
** PARENTHESIS OCCURRING WITHIN THE APOSTROPHIES ARE      **            00354420
** DISREGARDED.                                           **            00354820
************************************************************            00355220
A00501   EQU   *             EQUATE LABEL TO THIS ADDRESS               00355620
         CLI   @0(R2),HEX5D  CHECK FOR A RIGHT PAREN                    00355720
         BNE   A00502        IF NOT EQUAL TO ) THEN BRANCH              00355820
         TM    TSTFLGS2,FIRSTQSW  SEE IF A QUOTE HAS BEEN FOUND YET     00355920
         BO    A00505        IF ON THEN DISREGARD THIS PAREN            00357920
         TM    TSTFLGS2,LEFTPREN SEE IF A LEFT PREN SW EXIST            00359920
         BNO   A00505        IF IT DOESNT THEN BRANCH                   00360020
         BCTR  R3,@0         DECREMENT REG3 BY ONE                      00362020
         LTR   R3,R3         SEE IF LEFT AND RIGHT PARENS BALANCE       00364020
         BNZ   A00505        IF THEY DONT THEN BRANCH TO CHECK MORE     00364420
         NI    TSTFLGS2,HEXFF-LEFTPREN TURN OFF LEFT PREN SW SINCE      00364820
*                            RIGHT PARENTHESIS BALANCE IT OUT           00365220
         LA    R4,@1(R4)     INCREMENT LENGTH BY ONE                    00365320
         LA    R2,@1(R2)     LETS SEE IF WE THIS IS THE LAST PAREN      00365420
         CLI   @0(R2),HEX00  CHECK FOR END OF CHAIN INDICATOR           00369020
         BE    A00519        IF WE ARE THEN BRANCH TO LEAVE             00371020
         BCTR  R2,@0         OTHERWISE BACK R2 UP ONE                   00371420
         BCTR  R4,@0         RETURN R4 TO ORIGINAL VALUE                00371820
         B     A00505        BRANCH TO CONTINUE PROCESSING              00372220
A00502   EQU   *             EQUATE LABEL TO THIS ADDRESS               00372620
         CLI   @0(R2),HEX5E  CHECK FOR A SEMICOLON                      00372720
         BNE   A00503        IF NOT A SEMICOLON THEN BRANCH             00376320
         TM    TSTFLGS2,FIRSTQSW SEE IF A QUOTE HAS BEEN FOUND YET      00376420
         BO    A00505        IF ON THEN SKIP THE FOLLOWING CODE         00378420
         TM    TSTFLGS2,LEFTPREN HAS A LEFT PARENTHESIS BEEN FOUND YET  00378820
         BO    A00505        IF ON BRANCH TO CONTINEU THE SCAN          00379220
         BCTR  R2,@0         DECREMENT R2 TO SIMULATE LENGTH FLD        00379620
         B     A00520        OTHERWISE BRANCH TO REMOVE SUBCOMD         00380020
A00503   EQU   *             EQUATE LABEL TO THIS ADDRESS               00383620
         TM    TSTFLGS2,FIRSTQSW SEE IF A QUOTE HAS BEEN FOUND YET      00383720
         BO    A00504        IF ON THEN LEAVE THIS CODE ALONE           00385720
         CLI   @0(R2),HEX7D  IF NOT ON THEN CHECK FOR A QUOTE           00386120
         BNE   A00505        IF NOT PRESENT THEN CONTINUE SCAN          00386520
         OI    TSTFLGS2,FIRSTQSW TURN ON A QUOTE FOUND SW               00386920
         B     A00505        BRANCH TO CONTINUE THE SCAN                00387320
A00504   EQU   *             EQUATE LABEL TO THIS ADDRESS               00390920
         CLI   @0(R2),HEX7D  CHECK FOR AN IMBEDDED QUOTE                00391020
         BNE   A00505        IF NOT ON THEN BRANCH TO CONTINUE SCAN     00393020
         LA    R4,@1(R4)     INCREMENT COUNT REG                        00393420
         LA    R2,@1(R2)     INCREMENT SCAN REG                         00393820
         CLI   @0(R2),HEX7D  CHECK FOR THE MATE OF THE FIRST            00394220
*                            IMBEDDED QUOTE THERE SHOULD BE ONE         00394620
         BE    A00505        IF THERE IS ONE THEN ALL IS OK BRANCH      00395820
*                            TO CONTINUE SCAN                           00397820
         XI    TSTFLGS2,FIRSTQSW TURN OFF THE FIRST QUOTE SW            00397920
         B     A005000       BRANCH TO CONTINUE SCANNING                00398020
************************************************************            00398120
** IN THIS SCAN REGISTER 3 IS USED TO KEEP COUNT OF       **            00401220
** LEFT PARENTHESIS, REGISTER 4 IS USED TO RECORD THE     **            00401620
** LENGTH OF THE INDIVIDUAL COMMANDS IN THE CHAIN         **            00401720
** REGISTER 2 IS USED FOR SCANNING FOR THE VARIOUS        **            00401820
** INDICATORS (EG. SEMI-COLON), REGISTER 6 CONTAINS       **            00401920
** THE BEGINNING ADDRESS OF THE COMMAND. REGISTER         **            00403920
** 5 CONTAINS THE END ADDRESS OF THE CHAIN, REGISTER      **            00404320
** 8 CONTAINS THE LENGTH OF THE CHAIN, REGISTER 7         **            00404420
** IS USED FOR MISCELLANEOUS JOBS.                        **            00404720
************************************************************            00405120
A00505   EQU   *             EQUATE LABEL TO THIS ADDRESS               00405220
         LA    R4,@1(R4)     INCREMENT COUNT REG BY ONE                 00405320
         LA    R2,@1(R2)     INCREMENT SCAN REG BY ONE                  00405420
         B     A005000       BRANCH TO CONTINUE SCAN                    00406320
A00519   EQU   *             EQUATE LABEL TO THIS ADDRESS               00406720
         XR    R2,R2         ZERO OUT REG2                              00407120
A00520   EQU   *             EQUATE LABEL TO THIS ADDRESS               00407520
         ST    R2,SUBCHAIN   UPDATE SUBCHAIN POINTER IN                 00407620
*                            TCOMTAB TO ADDRESS NEXT COMMAND            00408020
A00530   EQU   *             EQUATE LABEL TO THIS ADDRESS               00408120
         LTR   R4,R4         MAKE SURE WE HAVE A LENGTH FOR             00417020
*                            THE SUB-COMMAND                            00419020
         BNZ   A00540        IF WE DO HAVE A CHAIN THEN BRANCH          00419420
         B     A00505        OTHERWISE BRANCH TO PROCESS NEXT CHAIN     00419820
*                            INSTRUCTION                                00419920
A00540   EQU   *             EQUATE LABEL TO THIS ADDRESS               00420020
         LA    R4,@4(@0,R4)  ADD 4 BYTES TO REG4 FOR LL FIELD           00422020
         L     R1,WORKAREA   LOAD ADDR OF WORKAREA FROM                 00424020
*                            TCOMTAB INTO REG1                          00426020
         LA    R7,@48(R1)    PLACE ADDRESS FROM WORKAREA INTO           00426420
*                            REG4 FOR RETURN AREA FROM GETMAIN          00426520
         GETMAIN EC,LV=(4),A=(7),SP=1,MF=(E,(1))                        00439120
*                            ISSUE A GETMAIN FOR INPUT BUF AREA         00441120
         LTR   R15,R15       TEST FOR SUCCESSFUL GETMAIN                00443120
         BNZ   A50002        IF SUCCESSFUL CONTINUE IN LINE             00443520
         L     R1,@0(R7)     PLACE ADDR OF GOTTEN CORE IN REG1          00443920
         ST    R1,INBUF      PLACE INPUT ADDRESS INTO TCOMTAB AT        00444320
*                            INBUF                                      00444420
         BCTR  R4,@0         SUBTRACT ONE FROM REG4 SO AS NOT TO        00446420
*                            EXCEED INPUT BUFFER WHEN BLANKED OUT       00448420
         BCTR  R4,@0         DECREMENT FOR EXECUTE                      00448820
         MVI   @0(R1),HEX40  PLACE A BLANK INTO FIRST BYTE OF AREA      00450420
         EX    R4,BLANKOUT   SPREAD THIS BLANK THRU ENTIRE AREA         00450820
         LA    R4,@2(@0,R4)  ADD1 TO R4 TO RESTORE TO ORIGINAL          00451220
         XC    @0(@4,R1),@0(R1) ZERO OUT FIRST 4 BYTES ON INPUT         00451620
         STH   R4,@0(R1)     PLACE LENGTH INTO FIRST 2 BYTES            00451720
*                            OF INPUT BUFFER                            00452220
         LA    R7,@4         PLACE A 4 INTO REG7                        00452620
         SR    R4,R7         SUBTRACT 4 BYTES FOR LENGTH                00453020
         BCTR  R4,@0         DECREMENT R4 BY 1                          00453120
         EX    R4,A00702     MOVE COMMAND FROM SUB-COMMAND              00453220
*                            CHAIN TO INPUT BUFFER                      00456220
A00600   EQU   *             EQUATE LABEL TO THIS ADDRESS               00458220
         B     A10000        BRANCH TO RETURN TO CALLER                 00460220
BLANKOUT MVC   @1(@1,R1),@0(R1) BLANKS OUT GETMAIN AREA                 00460620
A00702   MVC   @4(@1,R1),@0(R6)  MOVE SUB-COMMAND FROM CHAIN TO         00461020
*                            INPUT BUFFER                               00461420
A10002   EQU   *             EQUATE LABEL TO THIS ADDRESS               00461820
         LA    R15,@16       PLACE A RETURN CODE OF 16 INTO R15         00461920
A10000   EQU   *             EQUATE LABEL TO THIS ADDRESS               00462020
         L     R13,@4(R13)   RESTORE ENTERING REG SAVE AREA             00462120
         RETURN (14,12),RC=(15)  RETURN TO CALLER WITH RC IN R15        00464320
A00700   EQU   *             EQUATE LABEL TO THIS ADDRESS               00464420
************************************************************            00466420
**  NO SUBCOMMAND CHAIN HAS BEEN SPECIFIED.WE ARE         **            00468420
**  LOOKING FOR INFORMATION FROM THE TERMINAL.            **            00468820
************************************************************            00471020
         L     R1,WORKAREA   PLACE WORKAREA ADDRESS INTO R1             00471120
         MVC   @0(@12,R1),PARMLIST MOVE UPT,ECT AND CPECB INTO          00473120
*                            WORKAREA AS PART OF PARAMETER LIST         00475120
************************************************************            00475520
** WE WILL BUILD A PARAMETER LIST FOR GETLINE SERVICE     **            00476020
** ROUTINE                                                **            00476420
************************************************************            00476820
         LA    R4,@20(R1)    GET ADDRESS FROM WITHIN WORKAREA           00476920
         MVC   @0(PARMSIZE,R4),MACRO MOVE PARM LIST CREATED BY          00481120
*                            GETLINE LIST FORM INTO WORKAREA            00483120
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION                  00485120
************************************************************            00485220
** A CHECK MUST BE MADE FOR THE POSTING OF THE LOGON      **            00485320
** LOGOFF ECB OR FOR THE POSTING OF AN ATTENTION ECB. IF  **            00489520
** EITHER HAS BEEN POSTED A RETURN IS MADE TO THE CALLING **            00489620
** PROGRAM WITH A RETURN CODE OF 16. TO CHECK FOR ECB     **            00491620
** POSTING WE CHECK THE FIRST BIT OF THE HIGH ORDER       **            00493620
** BYTE WITHIN THE ECB.                                   **            00493720
************************************************************            00497920
         GETLINE PARM=(4),MF=(E,(1)) ISSUE GETLINE EXECUTE FORM         00498020
         L     R3,@4(R4)     PLACE POINTER TO INPUT AREA INTO R3        00500020
         ST    R3,@12(R4)    PLACE THIS POINTER BACK INTO PARM          00502020
*                            SO IT AGREES WITH DSECT USED LATER         00502120
         B     A01002        BRANCH TO CHECK RETURN CODE                00506320
PUTGET   EQU   *             EQUATE LABEL TO THIS ADDRESS               00506420
************************************************************            00508420
**   THIS  ENTRY POINT IS USED WHEN INFORMATION IS PUT    **            00510420
** TO THE TERMINAL AND AN ANSWER IS EXPECTED. THE PUTGET  **            00510520
** SERVICE ROUTINE IS USED                                **            00519420
************************************************************            00521420
         USING BASELOC,R12                                              00521820
         USING TCOMTAB,R9                                               00522220
         L     R4,REGSAVE5   PLACE ADDR OF MY SAVEAREA INTO R4          00522620
*                            FROM TCOMTAB AND PLACE IN REG0             00523020
         ST    R13,@4(R4)    PLACE ADDRESS OF CALLERS SAVEAREA          00523120
*                            INTO MY SAVEAREA AS FORWARD POINTER        00523220
         LR    R13,R4        PLACE ADDRESS OF MY SAVEAREA INTO R13      00525220
         L     R4,WORKAREA   GET WORKAREA ADDR FROM TCOMTAB             00527220
*                            INTO REG4                                  00527320
         MVC   @0(@12,R4),PARMLIST MOVE UPT,ECT AND CPECB INTO          00527420
*                            WORKAREA                                   00527820
         LA    R3,@20(R4)    GET ADDRESS OF AREA WITHIN WORKAREA        00528220
         ST    R3,@12(R4)    PLACE POINTER TO LIST FORM INTO R3         00528620
         L     R11,@0(R1)    PLACE PTR TO MSG INTO R11                  00528720
         L     R6,@4(R1)     PLACE POSSIBLE 2 LEVEL MSG PTR IN R6       00529620
         LA    R5,@40(R4)    PLACE ADDRESS FROM WORKAREA INTO R5        00530020
************************************************************            00530420
** THE OUTPUT LINE WILL BE PASSED TO THE PUTGET ROUTINE   **            00530820
** IN A MESSAGE POINTER BLOCK.  IT CONSIST OF THE ADDRESS **            00531220
** OF THE MESSAGE, THE NUMBER OF SEGMENTS TO THE MESSAGE  **            00531320
** AND THE ADDRESS OF THE NEXT LEVEL MESSAGE IF THERE IS  **            00531420
** ANOTHER LEVEL OTHERWISE THIS POINTER IS OMITTED.       **            00531520
************************************************************            00532920
         MVC   @40(@24,R4),MSGPOINT  MOVE CONSTANTS INTO WORKAREA       00534920
         USING MULDSECT,R5   USE REG5 TO ADDRESS MSG PARM LIST          00535320
         ST    R11,MSGPTR1   PLACE PTR TO FIRST MSG INTO                00535720
*                            MSG PARM LIST                              00536720
         ST    R6,MSGPTR2    PLACE PTR TO 2 MSG INTO PARM LIST          00537120
         LA    R8,FINALEVL   GET ADDRESS OF LAST LEVEL MSG              00537520
         ST    R8,NEXTLVL    STORE THIS ADDRESS INTO MSG PARM LIST      00537620
         LTR   R6,R6         TEST IF 2 LEVEL DOES EXIST                 00537720
         BNZ   A02000        IF ONE DOES EXIST THEN BRANCH              00538120
         LA    R5,ONELEVEL   PLACE ADDRESS OF FIRST LEVEL PORTION       00538520
*                            INTO REG 5                                 00538920
         MVC   @0(PUTGETSZ,R3),PUTGETIT MOVE PARM FIELD CREATED         00549920
*                            BY LIST FORM OF PUTGET INTO WORKAREA       00551920
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION                  00553920
*                            LOGON/LOGOFF ECB,IF POSTED RETURN          00554320
REISSUE  EQU   *             REISSUE THE PUTGET AFTER RC OF 12          00554720
         LR    R1,R4         PLACE POINTER TO PARM LIST IN R1           00555120
   PUTGET  PARM=(3),OUTPUT=((5),SINGLE,MODE),MF=(E,(1))                 00555520
         LA    R8,@12        TEST FOR NON-TWELVE RET CODE.              00557520
         CR    R15,R8        IF TWELVE MUST SET BIT AND REISSUE.        00559520
         BNE   RCCHECK       OTHERWISE, CHECK FOR OTHERS.               00559920
         SPACE                                                          00560320
*        RETURN CODE OF 12 INDICATES THAT TEST IS RUNNING OUT OF        00560720
*        A STACK AND A PREVIOUS SECOND LEVEL MESSAGE HAS BEEN           00560820
*        ISSUED AND PAUSE WAS NOT USED IN THE LAST PROFILE COMMAND.     00560920
         SPACE                                                          00562020
         L     R8,TSTECT     OBTAIN THE ECT POINTER.                    00564020
         OI    ECTMSGF-ECT(R8),HEX80   FLUSH THE 2ND LEVEL MSG.         00564120
         B     REISSUE       REISSUE THE PUTGET.                        00564220
A02000   EQU   *             EQUATE LABEL TO THIS ADDRESS               00564320
         MVC   @0(PUTGETLN,R3),PUTGETML MOVE LIST FORM INTO WORKAREA    00566520
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION                  00568520
         LR    R1,R4         PLACE POINTER TO PARMLIST IN R1            00570520
         PUTGET PARM=(3),OUTPUT=((5),MULTLVL),MF=(E,(1))                00570920
A20001   EQU   *             EQUATE LABEL TO THIS ADDRESS               00571020
RCCHECK  EQU   *             CHECK RETURN CODES HERE.                   00571320
         LA    R8,@8         TEST FOR ALL CODES.                        00571720
         CR    R15,R8        COMPARE AGAINST AN EIGHT.                  00571820
         BE    RET16         GOT AN 8 , SEND BACK A 16 (ATTENTION)      00571920
         BH    RET4          GOT 12 OR UP , SEND BACK A 4 (NO LINE)     00574420
         LTR   R15,R15       TEST , IF COMING FROM TERMINAL             00576420
         BNZ   RET0          NO. COMING FROM A STACK.                   00578420
         OI    TSTFLGS4,TSTA TELL MAINLINE OF THIS.                     00578820
RET0     EQU   *             GOT A 0 OR 4 , SEND BACK A 0 (A.O.K.)      00579220
A02002   EQU   *                                                        00579620
************************************************************            00581920
** THE ADDRESS OF THE INPUT BUFFER FROM PUTGET IS         **            00582020
** RETURNED IN THE LAST WORD OF THE PARM BLOCK PASSED TO  **            00582120
** PUTGET.                                                 **           00582220
************************************************************            00582620
          USING PUTGETDS,R3  USE REG4 TO ADDRESS PARM LIST              00583020
         SR    R15,R15       CODE ZERO.                                 00585020
         L     R1,INBUFPTR   PLACE POINTER TO INBUF IN REG1             00585420
         ST    R1,INBUF      PLACE POINTER IN TCOMTAB                   00585820
         B     A10000        BRANCH TO RETURN TO CALLER                 00586220
A01000   EQU   *             EQUATE LABEL TO THIS ADDRESS               00586320
         LA     R8,@16       PLACE A MAX CODE IN R8                     00586420
         CR    R15,R8        CHECK IF R15 CONTAINS MAX CODE             00588620
         BNH   A010001       IF IT DOESNT THEN BRANCH                   00588720
         LA    R15,@16       PLACE A MAX CODE OF 16 INTO R15            00588820
A010001  EQU   *             EQUATE LABEL TO THIS ADDRESS               00590820
         L     R8,A0301(R15) BRANCH TO PROPER CODE HANDLER              00590920
         BR    R8            BRANCH TO PROPER CODE HANDLER              00591020
A01002   EQU   *             EQUATE LABEL TO THIS ADDRESS               00591120
         LA    R8,@24        PLACE A 24 FOR COMPARISON IN R8            00593120
         CR    R15,R8        CHECK R15 AGAINST THIS 24                  00593220
         BNH   A01003        IF NOT GREATER THAN THIS BRANCH            00593320
         LA    R15,@24       OTHERWISE PLACE A 24 INTO R15              00593520
A01003   EQU   *             EQUATE LABEL TO THIS ADDRESS               00593920
         L     R8,A0300(R15) PLACE CORRECT ADDRESS IN R8                00597020
         BR    R8            BRANCH TO THIS PROCESSOR                   00597420
A02007   EQU   *             EQUATE LABEL TO THIS ADDRESS               00597820
RET16    EQU   *             RETURN A CODE OF 16 TO CALLER.             00599820
         LA    R15,@16       PLACE A 16 ATTN CODE IN R15                00599920
         B     A10000        BRANCH TO RETURN TO CALLER                 00600020
A02008   EQU   *             EQUATE LABEL TO THIS ADDRESS               00600420
RET4     EQU   *             RETURN A CODE OF 4 TO CALLER.              00601520
         LA    R15,@4        PLACE A NO SUCCESS CODE IN R15             00603520
         B     A10000        BRANCH TO RETURN TO CALLER                 00603620
PUTLINE  EQU   *             EQUATE LABEL TO THIS ADDRESS               00603720
************************************************************            00603820
** ENTRY POINT FOR PUTLINE OPERATION OF I/O MODULE        **            00606720
** THIS ROUTINE WILL PUT A LINE OF DATA TO A TERMINAL     **            00608720
** OR TO A DATA SET                                       **            00609120
************************************************************            00609520
         USING BASELOC,R12                                              00609620
         USING TCOMTAB,R9                                               00609720
         L     R4,REGSAVE5   PLACE ADDR OF MY SAVEAREA INTO R4          00610520
*                            FROM TCOMTAB AND PLACE IN REG4             00610920
         ST    R13,@4(R4)    PLACE ADDR OF CALLERS SAVEAREA             00611320
*                            INTO MY SAVEAREA AS FORWARD POINTER        00611720
         LR    R13,R4        PLACE MY SAVEAREA ADDR INTO R13            00611820
************************************************************            00611920
** AFTER SETTING UP SAVE AREAS AND ESTABLISHING           **            00612020
** ADDRESSABILITY A TEST IS MADE OF THE TSTPRINT SWITCH   **            00612120
** FOUND IN TCOMTAB. IF NOT ON THE INFORMATION IS GOING   **            00612220
** TO A TERMINAL AND NOT TO A DATA SET. A TEST IS MADE    **            00612320
** OF REGISTER 1 TO DETERMINE IF IT IS POSITIVE OR        **            00612420
** NEGATIVE. IF POSITIVE OUTPUT IS DATA, IF NEGATIVE      **            00613120
** OUTPUT IS MESSAGE. THE PUTLINE MACRO TREATS EACH       **            00613520
** DIFFERENTLY. THE LINE IS PUT TO THE TERMINAL USING     **            00613920
** PUTLINE MACRO                                          **            00614320
************************************************************            00614420
         LR    R8,R0         SAVE REG0 IN REG8                          00614520
         L     R2,WORKAREA   GET ADDRESS OF WORKAREA FROM               00614720
*                            TCOMTAB                                    00615120
         LTR   R1,R1         DO WE HAVE A MSG                           00615220
         BM    A00800        IF A MSG THEN IT GOES TO THE TERMINAL      00617720
         TM    TSTFLGS1,TSTPRINT TEST PRINT SWITCH BEING ON             00618120
         BO    A01100        IF NOT ON OUTPUT IS TO THE                 00618220
*                            TERMINAL,IF ON OUTPUT IS TO A              00618320
*                            DATA SET                                   00620320
A00800   EQU   *             EQUATE LABEL TO THIS ADDRESS               00620420
         L     R2,WORKAREA   PLACE WORKAREA ADDR INTO R2                00620620
         USING TSTCWORK,R2   USE R2 TO ADDRESS IO'S WORKAREA            00621020
         LA    R2,CWORKIO    PLACE ADDR OF IO'S WORKAREA IN R2          00621120
         MVC   @0(@12,R2),PARMLIST MOVE UPT,ECT AND CPECB INTO          00621820
*                            WORKAREA                                   00622220
         LA    R4,@20(R2)    LOAD ADDRESS FROM WITHIN                   00622620
*                            WORKAREA INTO REG4                         00623020
         LTR   R1,R1         TEST REG1 FOR NEGATIVE OR POSITIVE         00623120
         BH    A00902        IF POSITIVE THEN BRANCH TO PROCESS         00623220
************************************************************            00623320
** IF OUTPUT IS DATA GO TO A01000 OTHERWISE CONTINUE IN   **            00624020
** LINE.                                                  **            00624120
************************************************************            00624520
         LCR   R1,R1         LOAD COMPLIMENT INTO R1                    00624920
A00900   EQU   *             EQUATE LABEL TO THIS ADDRESS               00625320
         L     R11,@0(R1)    PLACE POINTER TO FIRST MSG IN R11          00625420
         L     R3,@4(R1)     PLACE POSSIBLE POINTER TO NEXT LEVEL       00625520
*                            MESSAGE INTO REG3                          00627820
************************************************************            00627920
**  THIS ROUTINE WILL REMOVE EXCESS BLANKS FROM           **            00628020
**  MESSAGES BEFORE PUTTING THE MESSAGE OUT TO THE TERMINAL*            00630020
************************************************************            00630420
TIGHTEN  EQU   *             EQUATE LABEL TO THIS ADDRESS               00630520
         LH    R5,@0(R11)    R5=MSG LENGTH                              00631120
         LA    R6,@0(R5,R11) R6=END OF MSG ADDR                         00631520
         BCTR  R5,@0         DECREASE LENGTH FOR EXECUTE.               00631920
         LR    R4,R11        R4=MSG POINTER.                            00632320
CKBLANK  EQU   *                                                        00632520
         CLC   @0(@2,R4),TWOBLNKS Q.TWO BLANKS IN A ROW                 00632620
         BNE   INCREMNT      NO,BUMP POINTER,DECREASE COUNT             00632720
         EX    R5,SHIFTMSG   SQUEEZE A BLANK.                           00632820
         BCTR  R6,@0         BACK UP MSG END POINTER                    00633320
         BCTR  R4,@0         TEMPORARILY BACK UP MSG POINTER.           00633720
INCREMNT EQU   *                                                        00634120
         LA    R4,@1(R4)     BUMP MSG POINTER.                          00634220
         BCT   R5,CKBLANK    DECREASE R5 AND CHECK AGAIN.               00634320
         SR    R6,R11        WHEN R5=0,ESTABLISH NEW MSG LENGTH.        00634420
         CH    R6,@0(R11)    Q.ANY SQUEEZING DONE.                      00634620
         BE    NOSTUFF       NO,DO NOT STORE LENGTH.                    00634720
         STH   R6,@0(R11)    AND STUFF BACK IN CONTROL WORD.            00634820
NOSTUFF  EQU   *                                                        00634920
         CR    R11,R3        HAVE BOTH MSG BEEN TIGHTENED               00635420
         BE    A00904        IF THEY HAVE THEN BR TO LEAVE ROUTINE      00635520
         LTR   R3,R3         SEE IF A 2ND LEVEL EXIST                   00635920
         BZ    A00904        IF NONE DO THEN WE ARE DONE TIGHTENING     00636320
         LR    R11,R3        OTHERWISE LETS TIGHTEN THE 2ND LEVEL       00636420
         B     TIGHTEN       AND BR BACK TO OUT TIGHTENING ROUTINE      00638520
SHIFTMSG MVC   @0(@1,R4),@1(R4)  MOVE ENTIRE MSG 1 BYTE TO THE LEFT     00638920
A00904   EQU   *             EQUATE LABEL TO THIS ADDRESS               00639320
         LA    R4,@20(R2)    RESET PARMLIST ADDR IN R4                  00639720
         L     R11,@0(R1)    RESTORE REG11 TO FIRST LEVEL MSG           00639820
         LA    R5,@40(R2)    GET AN ADDRESS FROM WITHIN THE WORK        00640220
         MVC   @40(@24,R2),MSGPOINT MOVE MSG POINTER PARM LIST INTO     00640620
*                            THE WORKAREA                               00641020
         USING MULDSECT,R5   ADDRESS MSG POINTER PARM LIST WITH  R5     00641320
         ST    R11,MSGPTR1   PLACE POINTER TO FIRST MSG INTO            00641720
*                            FIRST MSG POINTER FIELD OF PARM LIST       00641820
         ST    R3,MSGPTR2    PLACE 2 MSG POINTER INTO NEXT POINTER      00641920
         LA    R6,FINALEVL   PLACE ADDRESS OF FINAL LEVEL MSG IN R6     00642020
         ST    R6,NEXTLVL    PLACE POINTER TO NEXT MSG IN PARM LIST     00642620
*                            DATA OUTPUT                                00643020
************************************************************            00643120
** THERE ARE THREE DIFFERENT PUTLINES ROUTINES. ONE FOR   **            00643220
** SINGLE LEVEL MESSAGES, ONE FOR MULTI-LEVEL MESSAGES    **            00643620
** AND ONE FOR DATA.                                      **            00643720
************************************************************            00644320
         LTR   R3,R3         SEE IF THERE IS ANOTHER LEVEL MSG          00644420
         BZ    A00801        IF THERE ISNT ANY OTHER LEVEL BRANCH       00644820
         MVC   @0(PUTMSG3,R4),PUTMSG2 OTHERWISE MOVE IN MULTILVL        00645220
*                            PUTLINE PARM LIST                          00645320
         BAL   R14,A80000    BRANCH TO CHECK ATTN                       00645420
*                            OR ATTENTION HAS BEEN REQUESTED            00646020
         LR    R1,R2         PLACE POINTER TO PARM LIST IN R1           00646120
************************************************************            00646520
** MULTI-LEVEL MESSAGE PUTLINE ROUTINE                    **            00646620
************************************************************            00646720
         PUTLINE PARM=(4),OUTPUT=((5),TERM,MULTLVL,INFOR),MF=(E,(1))    00647120
         TM    TSTFLGS2,TMYIOMSG WAS THIS AN IO MSG                     00647220
         BO    A50030        IF IT WAS, GO TO RETURN                    00647320
         B     A01000        BRANCH TO CHECK RETURN CODE                00653320
A00801   EQU   *             EQUATE LABEL TO THIS ADDRESS               00653720
         LA    R5,ONELEVEL   PLACE ONE LEVEL ADDRESS INTO R5            00655720
         ST    R11,MSGPTR1   PLACE POINTER TO FIRST MSG INTO PTR1       00655820
         MVC   @0(PUTMSG1,R4),PUTMSG MOVE PARMLIST CREATED              00657820
         LR    R1,R2         PLACE POINTER TO PARM LIST IN R1           00657920
************************************************************            00659920
** SINGLE LEVEL MESSAGE PUTLINE ROUTINE                   **            00669120
************************************************************            00671120
         PUTLINE PARM=(4),OUTPUT=((5),TERM,SINGLE,INFOR),MF=(E,(1))     00671520
         TM    TSTFLGS2,TMYIOMSG  SEE IF MY MESSAGE SW IS ON            00671920
         BO    A50030        IF IT IS ON THEN BRANCH TO RETURN          00672020
         B     A01000        BRANCH TO CHECK RETURN CODE                00674020
A00902   EQU   *             EQUATE LABEL TO THIS ADDRESS               00676020
         L     R5,@0(R1)     PLACE POINTER TO DATA FIELD INTO R5        00678020
         LH    R10,@0(R5)    PLACE LINE LENGTH INTO R10                 00678420
         LTR   R10,R10       SEE IF THIS QUANTITY IS 0                  00678520
         BZ    A00903        IF ZERO, CARRIAGE RETURN REQUESTED         00678620
A00901   EQU   *             EQUATE LABEL TO THIS ADDRESS               00678720
         MVC   @0(PUTDATA1,R4),PUTDATA MOVE PARM FIELD INTO             00680420
         BAL   R14,A80000    BRANCH TO CHECK ATTN                       00682420
         LR    R1,R2         PLACE POINTER TO PARM LIST IN R1           00682820
************************************************************            00683220
** DATA PUTLINE ROUTINE                                   **            00683620
************************************************************            00683720
         PUTLINE PARM=(4),OUTPUT=((5),TERM,SINGLE,DATA),MF=(E,(1))      00683820
         TM    TSTFLGS2,TMYIOMSG   SEE IF MY MSG SW IS ON               00683920
         BO    A50030        IF IT IS THEN BRANCH                       00685420
         B     A01000        BRANCH TO CHECK RETURN CODE                00687420
A00903   EQU   *             EQUATE LABEL TO THIS ADDRESS               00687820
*                            THIS ROUTINE WILL SPACE THE CARRIAGE       00687920
         MVI   @1(R5),HEX05  PLACE A LENGTH OF 5 INTO FIRST HAFWD       00688020
         MVI   @4(R5),BLANK  PLACE HEX 40 INTO FIRST BYTE               00688420
         MVC   @0(SPACESZ,R4),PUTSPACE MOVE SPACING PUTLINE LIST        00690320
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION AND LOGON        00692320
         LR    R1,R2         PLACE PARAMETER PTR INTO R1                00692720
         PUTLINE PARM=(4),OUTPUT=((5),TERM,SINGLE,DATA),MF=(E,(1))      00693120
         B     A01000        BR TO CHECK RETURN CODE                    00693520
A01100   EQU   *                                                        00693920
************************************************************            00694020
** WE ARRIVE HERE WHEN THE TSTPRINT SWITCH IS ON. AT      **            00695620
** THIS POINT INFORMATION IS GOING TO A DATA SET. IF REG0=**            00696020
** ZERO THEN THE DATA SET HAS BEEN PREVIOUSLY OPENED AND  **            00696420
** ALL WE DO IS PUT THE INFORMATION OUT. IF REG0 IS NOT   **            00696820
** ZERO THAN IT CONTAINS THE ADDRESS OF A DSNAME PDE      **            00697220
** (PARAMETER DESCRIPTOR ELEMENT-SEE PARSE FOR FURTHER    **            00697620
** INFORMATION). WE MUST CHECK TO SEE THAT THERE IS AN    **            00698020
** OPEN OUTPUT DATA SET AND THAT IT HAS THE SAME DSNAME   **            00698420
** AS THE ONE SPECIFIED.IF IT HAS THE SAME NAME WE        **            00698520
** FORMAT THE LINE VARIABLE BLOCK AND PUT IT OUT. IF      **            00698620
** IT IS NOT THE SAME NAME WE CLOSE THE OPEN DATA SET     **            00698720
** AND ALLOCATE DYNAMICALLY ANOTHER DATA SET USING        **            00700220
** DAIR. WE MUST CREATE A DCB FOR THIS DATA SET AND       **            00700320
** OPEN THIS DCB.                                         **            00700420
************************************************************            00700820
         L     R10,@4(R1)    PLACE MULTILEVEL POINTER INTO REG10        00701220
         L     R11,@0(R1)    PLACE PTR TO FIRST MSG INTO R11            00701620
         LR    R1,R11        PLACE POINTER INTO REG1                    00702020
         LTR   R0,R0         TEST REG0 FOR ZERO,IF SO                   00702420
         BZ    A01202        DATA SET ALREADY OPEN SO BRANCH            00702820
*                            IF NOT OUR WORK BEGINS                     00703220
         L     R5,TSTIODCB   LOAD ADDRESS OF POSSIBLE OPEN              00703320
*                            DCB FROM TCOMTAB                           00703420
         LTR   R5,R5         TEST TO SEE IF THERE IS AN OPEN DCB        00704120
         USING DSNAMPDE,R8   USE REG8 TO ADDRESS DSNAME PDE             00704520
         BZ    A01400        IF NO DCB THEN BRANCH FOR GETMAIN          00704920
         TM    FLAGRES1,HEX40 SEE IF THIS NAME WANTS DEFAULT NAMING     00705020
         BNO   A01400        IF IT DOES THEN GO TO DEF BEFORE COMPARE   00705420
         LR    R6,R5         SAVE DCB ADDRESS IN REG6                   00705520
         LA    R5,@104(R5)   GET ADDRESS PASS DCB FOR DSNAME            00705620
A01111   EQU   *             EQUATE LABEL TO THIS ADDRESS               00707020
         LH    R4,LENDSNME   PLACE LENGTH OF DSNAME INTO REG4           00707420
************************************************************            00707820
** WHEN IO OPENED THE DATA SET IT PLACED THE LENGTH AND   **            00707920
** DSNAME INTO THE FIRST 46 BYTES PRECEDING THE DCB.      **            00708020
** WE ACCESS THIS AREA AND COMPARE LENGTH WITH THAT IN    **            00708420
** PDE POINTED TO BY REG1                                 **            00708820
************************************************************            00709220
         LH    R7,@0(R5)     OBTAIN LENGTH OF DSNAME FROM               00709620
*                            MY CREATED HOLD AREA                       00709720
         CR    R7,R4         COMPARE LENGTHS OF DSNAMES                 00711120
A01200   BNE   A01400        IF NOT EQUAL THEY'RE NOT THE SAME          00711220
         L     R4,STRNGPTR   PLACE POINTER TO DSNAME INTO REG4          00711620
         LA    R6,@2(R5)     PLACE ADDRESS TO DSNAME FROM MY            00712020
*                            AREA INTO REG5                             00712420
         BCTR  R7,@0         DECREMENT R7 FOR EX INSTRUCTION            00712520
         EX    R7,A01210     EXECUTE COMPARE USING MY LENGTH            00712620
A01201   BNE   A01400        IF NOT EQUAL DATA SET IS NOT OPEN          00713020
************************************************************            00713420
** WE HAVE AN OPEN DATA SET TO PUT THE LINE TO THEREFORE  **            00713820
** WE WILL FORMAT THE LINE VARIABLE BLOCK AND PUT IT TO   **            00713920
** THE OPEN DATA SET                                      **            00714020
************************************************************            00714120
A01202   EQU   *             EQUATE LABEL TO THIS ADDRESS               00714220
         LR    R0,R11        PLACE POINTER TO OUTPUT LINE IN R0         00714320
         L     R1,TSTIODCB   PLACE ADDRESS OF DCB INTO R1               00714720
A01203   EQU   *             EQUATE LABEL TO THIS ADDRESS               00715120
         BAL   R14,A80000    BRANCH TO CHECK ATTN AND LOGON             00715520
         PUT   (1),(0)       PUT OUT THE DATA TO THE OPEN DS            00724320
         XR    R15,R15       ZERO OUT REG15 FOR RETURN CODE             00724720
         B     A10000        BRANCH TO RETURN TO CALLER                 00724820
A01400   EQU   *             EQUATE LABEL TO THIS ADDRESS               00726820
         LA    R7,@20(R2)    PLACE POINTER TO RETURN AREA IN R7         00728820
         GETMAIN EC,LV=TLEN,SP=1,A=(7),MF=(E,(2)) ISSUE GETMAIN FOR DCB 00730820
         LTR   R15,R15       SEE IF GETMAIN WAS SUCCESSFUL              00732820
         BNZ   A50002        IF IT WASNT THEN BRANCH FOR MSG            00733220
         L     R4,@0(R7)     PLACE ADDR OF GOTTEN CORE IN R4            00733620
         B     A01510        BRANCH TO CONTINUE PROCESSING              00734020
CKDSNAME EQU   *                                                        00734120
************************************************************            00734220
** WE BRANCH HERE WHEN THERE IS A DATA SET ALREADY OPEN   **            00734320
** AND IT IS NOT THE ONE WE WANT. THEREFORE WE MUST CLOSE **            00737920
** THE OPEN DATA SET AND OPEN A NEW AND PROPER ONE        **            00739920
************************************************************            00741920
         STM   R14,R12,@12(R13) SAVE MY REGISTERS IN REGSAVE2           00742320
         TM    FLAGRES1,HEX40  SEE IF THIS NAME WENT TO DEFAULT         00742720
         BO    A01503        IF IT HASNT THEN WE HAVE CKED NAME         00743120
         L     R4,TSTIODCB   WE MUST COMPARE DEF NAME WITH OPEN DS      00743220
         LTR   R4,R4         FIRST SEE IF WE HAVE AN OPEN DCB           00743620
         BZ    A01503        IF NO DCB THEN DONT COMPARE                00744020
         LA    R4,@104(R4)   ACCESS DSNAME HELD IN DCB                  00744420
         LH    R7,@0(R4)     LOAD LENGTH OF NAME INTO R7                00744820
         LH    R6,@0(R5)     LOAD LENGTH OF DEF NAME INTO R6            00744920
         CR    R6,R7         ARE THE LENGTHS EQUAL                      00745020
         BNE   A01503        IF NOT THE SAME DS IS NOT OPEN             00745120
         LA    R6,@2(R5)     PLACE ADDRESS OF DEF NAME IN R6            00746820
         LA    R4,@2(R4)     PLACE ADDRESS OF DCB NAME IN R4            00748820
         BCTR  R7,@0         SET R7 UP FOR EX INSTRUCTION               00749220
         EX    R7,A01210     COMPARE NAMES                              00749620
         BE    A01202        IF EQUAL THEN DS IS ALREADY OPEN           00750020
A01503   EQU   *             EQUATE LABEL TO THIS ADDRESS               00750120
         L     R3,TSTIODSN   PLACE POINTER TO DSNAME QUEUE IN R3        00750220
         LTR   R3,R3         DOES ONE EXIST                             00752120
         BZ    A01504        IF NOT THEN BR TO CREATE ONE               00752220
A01501   EQU   *             EQUATE LABEL TO THIS ADDRESS               00752320
         LH    R6,@4(R3)     PLACE LENGTH OF NAME INTO R6               00752420
         LH    R7,@0(R5)     PLACE LENGTH OF ENTERED NAME IN R7         00754420
         CR    R6,R7         ARE THEY THE SAME LENGTH                   00754820
         BNE   A01502        IF NOT THEN BR TO GET NEXT HOLD AREA       00755220
         BCTR  R6,@0         IF EQUAL THEN LETS LOOK AT THE NAME        00755620
         EX    R6,SAMENAME   SEE IF THEY ARE THE SAME NAMES             00755720
         BNE   A01502        IF NOT THEN BR TO GET NEXT NAME            00755820
         OI    TSTFLGS3,OPENMOD OTHERWISE TURN ON DISP=MOD SW           00756820
         B     A01509        AND BR TO PROCESS OLD DATA SET             00757220
A01502   EQU   *             EQUATE LABEL TO THIS ADDRESS               00757620
         L     R3,@0(R3)     PLACE PTR TO NEXT NAME INTO R3             00757720
         LTR   R3,R3         SEE IF THERE IS ANOTHER NAME               00757820
         BNZ   A01501        IF MORE THEN BR TO PROCESS                 00758220
         L     R3,TSTIODSN   OTHERWISE PLACE PTR TO QUEUE IN R3         00758620
A01504   EQU   *             EQUATE LABEL TO THIS ADDRESS               00758720
         LA    R1,@20(,R2)    REMOTE PARAMETER LIST ADDRESS.     A49889 00758821
         GETMAIN EC,LV=50,SP=1,A=(2),MF=(E,(1)) ISSUE GETMAIN    A49889 00759021
         LTR   R15,R15       SEE IF GETMAIN WAS SUCCESSFUL              00759420
         BNZ   A50002        IF NOT THEN BR FOR ERROR MSG               00759520
         L     R6,@0(R2)     PLACE ADDR OF GETMAIN INTO R6              00759620
         ST    R3,@0(R6)     PLACE POINTER TO LAST NAME INTO            00761220
*                            NEW GETMAIN AREA AS BACKWARD PTR           00761620
         ST    R6,TSTIODSN   PLACE POINTER TO GETMAIN INTO TCOMTAB      00763620
         LH    R7,@0(R5)     PLACE LENGTH OF NAME INTO R7               00764020
         STH   R7,@4(R6)     AND PLACE IT INTO NEW GETMAIN AREA         00764120
         BCTR  R7,@0         DECREMENT R7 FOR EX INSTRUCTION            00764220
         EX    R7,MOVEIN     MOVE NAME INTO GETMAIN AREA                00764320
A01509   EQU   *             EQUATE LABEL TO THIS ADDRESS               00765120
         L     R4,TSTIODCB   PLACE PTR TO CURRENT DCB INTO R4           00765520
         LTR   R4,R4         MAKE SURE THAT A DCB IS OPEN               00765920
         BZ    A01508        IF THERE IS NONE, RETURN TO MNLN CODE      00766020
         LA    R6,@96(@0,R4) PLACE ADDR OF LIST FORM OF CLOSE IN R6     00766420
************************************************************            00766820
** TO KEEP PROGRAM REFRESHABLE THE LIST FORM OF THE CLOSE **            00766920
** MACRO WAS USED TO GENERATE A PARAMETER LIST. THE       **            00767020
** EXECUTE FORM WILL ACCESS THIS LIST                     **            00767120
************************************************************            00767220
         BAL   R14,A80000    BRANCH TO CHECK ATTN                       00767320
*                            LOGON/LOGOFF ECB,IF POSTED RETURN          00767420
         CLOSE ((4)),MF=(E,(6)) USE EXECUTE FORM OF CLOSE               00767520
         XC    TSTIODCB(@4),TSTIODCB ZERO OUT DCB PTR                   00767820
         FREEPOOL  (4)       FREE QSAM BUFFERS                          00767920
         FREEMAIN R,LV=TLEN,A=(4),SP=1  ISSUE FREEMAIN ON OLD DCB       00768020
A01508   EQU   *             EQUATE LABEL TO THIS ADDRESS               00768420
         LM    R14,R12,@12(R13) RESTORE MY ENTERING REGISTERS           00768520
         BR    R14           AND RETURN TO CALLING ROUTINE              00768620
A01510   EQU   *             EQUATE LABEL TO THIS ADDRESS               00768720
************************************************************            00770120
** WE NOW WILL USE DAIR (DYNAMIC ALLOCATION INTERFACE     **            00770520
** ROUTINE) TO ALLOCATE A DDNAME FOR US.WE PASS DAIR A    **            00770620
** PARAMETER LIST CREATED IN OUR WORKAREA.ONCE WE HAVE    **            00770720
** A DDNAME WE PLACE THIS INTO OUR DCB AND THEN OPEN IT   **            00770820
************************************************************            00772820
         USING DAPL,R2       ADDRESS DAIR DSECT WITH REG1               00772920
         MVC   DAPLUPT,TSTUPT  MOVE UPT,ECT AND CPECB FROM              00773820
         MVC   DAPLECT,TSTECT TCOMTAB TO DAIR PARAMETER LIST            00774220
         MVC   DAPLECB,TSTCPECB *                                       00774320
         L     R3,TPLPTR     PLACE POINTER TO TMP INTO R3               00774420
         USING TPL,R3        USE REG3 TO ADDRESS TMP DSECT              00774820
         L     R3,TPLPSCB    PLACE POINTER TO PSCB INTO R3              00775220
         ST    R3,DAPLPSCB   PLACE THIS POINTER INTO PARM BLOCK         00775620
         USING DAPB08,R4     USE REG4 TO ADDRESS DAIR PDE               00775720
         ST    R4,DAPLDAPB   STORE THIS ADDRESS INTO PARAMETER LIST     00776020
         XC    DAPB08(DA08LEN),DAPB08 INITIALIZE DAIR PARM BLOCK        00776420
         MVI   DA08DDN,BLANK MOVE BLANK INTO DDNAME FIELD.              00776520
         MVC   DA08DDN+@1(@7),DA08DDN BLANK OUT DDNAME FIELD            00776620
         MVI   DA08UNIT,BLANK BLANK CHAR INTO UNIT FIELD                00776720
         MVC   DA08UNIT+@1(@7),DA08UNIT BLANK OUT UNIT FIELD            00776820
         MVI   DA08SER,BLANK MOVE BLANK INTO SERIAL FIELD               00785020
         MVC   DA08SER+@1(@7),DA08SER BLANK OUT SERIAL FIELD            00787020
         MVI   DA08MNM,BLANK MOVE BLANK INTO MEMBER NAME FIELD          00787120
         MVC   DA08MNM+@1(@7),DA08MNM BLANK OUT MEMBER NAME FIELD       00787220
         MVI   DA08PSWD,BLANK MOVE BLANK INTO PASSWORD FIELD            00789220
         MVC   DA08PSWD+@1(@7),DA08PSWD BLANK OUT PASSWORD FIELD        00791220
         MVC   DA08UNIT,SYSDA SYSDA UNIT REQUIRED.                      00793220
         MVI   DA08CD+@1,HEX08 CODE TO DAIR                             00793320
         MVI   DA08DSP1,DA08OLD ALLOCATE DATA SET OLD                   00794220
         MVI   DA08DPS2,DA08KEEP DISP EQUAL KEEP                        00794620
         MVI   DA08DPS3,DA08KEP  KEEP DESIRED                           00795020
         LA    R5,PASSDCB(R4)    GET ADDRESS PASS DCB                   00795420
         USING DSNDSECT,R5  USE R5 TO ADDRESS DSNAME DSECT              00795820
         MVI   DSLNGTH,BLANK  MOVE A BLANK INTO FIRST BYTE              00795920
         MVC   DSLNGTH+ONE(DSNLEN),DSLNGTH BLANK OUT FIELD              00798120
         ST    R5,DA08PDSN   PLACE LOCATION OF DSNAME INTO DAIR         00800120
         USING DSNAMPDE,R8   ESTABLISH PDE ADDRESSABILITY               00800220
         TM    FLAGRES3,HEX80 TEST FOR PRESENCE OF PASSWORD             00800320
         BNO   NOPSWRD       BRANCH IF NO PASSWORD                      00800420
         L     R6,PSWRDPTR   ACCESS PTR TO PASSWORD                     00800520
         LH    R3,LENPSWRD   ACCESS LENGTH OF PASSWORD                  00800620
         BCTR  R3,R0         DECREMENT FOR EXECUTE                      00800720
         EX    R3,MVCPSWRD   TO MOVE PASSWORD INTO DAIR PARM BLOCK      00800820
NOPSWRD  EQU   *                                                        00800920
         L     R6,STRNGPTR   ACCESS PTR TO DSNAME                       00801020
         LH    R3,LENDSNME   LOAD LENGTH INTO REG3                      00801320
         EX    R3,MOVDSNAM   MOVE DSNAME INTO SPECIAL AREA              00801420
         STH   R3,DSLNGTH    STORE LENGTH OF DNAME INTO AREA            00801520
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION                  00801620
         TM    FLAGRES1,HEX40 SEE IF THE DSNAME WAS QUOTED              00802020
         BO    A01600        IF IT WAS THEN FORGET THIS ROUTINE         00802420
         LA    R3,DA08LEN(R4) OTHERWISE SET UP FOR DEFAULT NAMING       00802520
         L     R1,DAPLPSCB   PLACE PSCB ADDR INTO R1                    00804720
         USING DFPB,R3       ESTABLISH DEFAULT ADDRESSABILITY           00805720
         ST    R1,DFPBPSCB   ST PSCB ADDR IN PARM BLOCK                 00806720
         ST    R5,DFPBDSN    STORE DSN PTR IN PARM BLOCK                00807720
         LA    R1,TESTLIST   PLACE ADDR OF QUALIFIER INTO R1            00808920
         ST    R1,DFPBQUAL   ADDR OF QUALIFIER                          00809120
         MVI   DFPBCODE,DFPB00 CODE INTO PARM BLOCK                     00809320
         MVI   DFPBCNTL,DFPBUID CONTROL CODE INTO PARM BLOCK            00809520
         L     R1,DAPLPSCB   PLACE ADDR OF PSCB INTO R1                 00809720
         ST    R3,DAPLPSCB   PLACE PTR TO DEFAULT PDE INTO PARM LIST    00811820
         LR    R3,R1         PLACE PSCB PTR INTO R3                     00812220
         LR    R1,R2         PLACE PTR TO PARM LIST INTO R1             00812620
         LINK  EP=IKJDFLT                                               00813020
         LTR   R15,R15       SEE IF DEFAULT WAS SUCCESSFUL              00813420
         BNZ   A01601        IF IT WASNT THEN BR TO ERROR ANALYSIS      00813520
         ST    R3,DAPLPSCB   OTHERWISE REPLACE PSCB ADDR INTO DAIR PARM 00813620
         B     A01600        AND BR TO PROCESS DYNAMIC ALLOCATION       00815620
MVCPSWRD MVC   DA08PSWD(@1),@0(R6)  MOVE IN PASSWORD                    00815820
A01601   EQU   *             EQUATE LABEL TO THIS ADDRESS               00816020
         CH    R15,ATTN24    SEE IF AN ATTENTION WAS ISSUED             00816620
         BE    A10002        IF IT WAS THEN BR TO RETURN TO CALLER      00817020
A01600   EQU   *             EQUATE LABEL TO THIS ADDRESS               00817420
         BAL   R14,CKDSNAME  BRANCH TO CK IF THIS DS EXIST              00817820
TODAIR   EQU   *                                                        00817920
         LA    R10,MSGBUILD  R10,ADDR OF MSGBUILD ROUTINE.              00819820
         TM    FLAGRES2,HEX80  TEST IF MEMBER NAME SPECIFIED            00820220
         BO    BADDS         YES,PUT OUT ERROR MSG.                     00822320
         TM    TSTFLGS3,OPENMOD SEE IF NAME WAS FOUND BEFORE            00822420
         BNO   DOLINK        IF NOT DO NOT MAKE MOD                     00822820
         NI    TSTFLGS3,HEXFF-OPENMOD TURN OFF FOUND IT SW              00823220
         MVI   DA08DSP1,DA08MOD ALLOCATE DATA SET MOD                   00823320
DOLINK   EQU   *                                                        00823420
         LR    R1,R2         PLACE PARAMETER LIST FOR DAIR IN R1        00823520
         LINK  EP=IKJDAIR    BRANCH TO DAIR                             00824120
         LTR   R0,R15        TEST REG15 FOR SUCCESSFUL RETURN           00824520
         BZ    A01700        CHECK DATA SET ORGANIZATION.               00824920
         LA    R6,@8         R6=8.                                      00825320
         CR    R6,R15        Q.DAIR FAILED WITH RC OF 8.                00825420
         BE    CKDARC        YES,CHECK FOR NOT CATALOGED.               00825520
TODDM    EQU   *                                                        00827320
         LR    R1,R2         R1=DAIR PARM LIST ADDRESS.                 00827420
         L     R15,TSTDDM    R15=IKJEGDDM ENTRY POINT.                  00827820
         BALR  R14,R15       BRANCH TO IKJEGDDM.                        00828220
         BAL   R10,BADDS     TAKE DATA SET NAME FROM QUEUE.             00828620
         L     R1,OUTBUF     R1=ERROR MSG VECTORS.                      00829020
         B     A50006        SET MESSAGE INDICATOR.                     00829120
CKDARC   EQU   *                                                        00829220
         CLC   DA08DARC,DARC1708 Q.UNCATALOGE ERROR.                    00829320
         BNE   TODDM         NO,PUT OUT ERROR MESSAGE.                  00829720
         MVI   DA08CTL,DA08ABKL MOVE WE WANT BLOCKS.                    00830120
         MVI   DA08DSP1,DA08NEW DATA SET IS NEW.                        00830520
         MVI   DA08DPS2,DA08CAT CATLG DATA SET.                         00830920
         MVI   DA08DPS3,DA08CATL CATLG CONDITIONAL DISPOSITION.         00831020
         MVC   DA08PQTY,PRMSPACE MOVE SPACE**                           00831120
         MVC   DA08SQTY,SECSPACE EQUAL(BLK,(1,100))                     00831920
         B     TODAIR        GO TO DAIR.                                00832320
A01700   EQU   *             EQUATE LABEL TO THIS ADDRESS               00832720
         LA    R14,MSGBUILD  R14=ADDRESS OF MESSAGE BUILD RTN.          00832820
         TM    DA08DSO,NEWDS Q.IS THIS A NEW DATA SET.                  00833220
         BZ    CONTINUE      YES,PROCESS IT.                            00833320
         TM    DA08DSO,PSDS  Q.IS IT PHYSICAL SEQUENTIAL.               00833420
         BNO   BADDS         NO,WRITE ERROR MESSAGE.                    00833520
CONTINUE EQU   *                                                        00841420
         LA    R7,DA08DDN    OBTAIN ADDRESS OF DDNAME FROM              00841820
*                            PARM LIST RETURNED BY DAIR                 00842220
         MVC   @0(@8,R2),@0(R7)   MOVE DDNAME TO WORKAREA TO SAVE IT    00842620
         LR    R7,R2         MAKE REG 7 POINT TO WORKAREA               00844620
************************************************************            00846620
** AT THIS TIME DAIR HAS SET UP A DD CARD FOR US AND      **            00848620
** WE ARE NOW READY TO OPEN THE DATA SET. WE WILL ISSUE   **            00849020
** A GETMAIN TO HOLD OUR DCB, MOVE THE DCB INTO THE       **            00849120
** GETMAIN AREA THEN OPEN IT.                             **            00849220
************************************************************            00849320
A01701   EQU   *             EQUATE LABEL TO THIS ADDRESS               00849820
         USING IHADCB,R4                                                00850620
         MVC   IHADCB(LENDCB),MYDCB MOVE MYDCB INTO GOTTEN CORE         00850720
         MVC   LENDCB+IHADCB(LENCLF),CLFORM MOVE IN CLOSE               00852720
         LA    R6,LENDCB+LENCLF+IHADCB GET ADDRESS FOR OPEN             00854720
         MVC   @0(LENOLF,R6),LFORM MOVE IN OPEN                         00856720
         MVC   DCBDDNAM,@0(R7) MOVE DDNAME FROM DAIR                    00856820
         BAL   R14,A80000    BRANCH TO CHECK ATTENTION                  00856920
         OPEN  ((4)),MF=(E,(6)) OPEN DATA SET FOR USE                   00857020
         TM    DCBOFLGS,HEX10  TEST IF OPEN SUCCECCFUL                  00857120
         BNO   A50001        BRANCH TO PUT OUT ERROR MSG                00857220
************************************************************            00859220
** IF WE GET THIS FAR THE DCB HAS BEEN OPENED SUCCESSFULLY**            00861220
** AND WE ARE READY TO START PUTTING DATA INTO IT.        **            00861620
** REGISTER 11 CONTAINS THE ORIGINAL CONTENTS OF REGISTER1**            00862020
** WE WILL RESTORE REG1 AND THEN CHECKS IF THE  DATA      **            00862420
** WAS A MESSAGE OR IT WAS DATA.  WE DONT WANT TO FORMAT  **            00862820
** MESSAGES BECAUSE WE COULD ABEND WITH PROTECTION EXCEP  **            00862920
** IF THE MESSAGE IS IN THE MESSAGE MODULE.               **            00863020
************************************************************            00863120
         ST    R4,TSTIODCB   PLACE ADDRESS TO DCB IN TCOMTAB            00863520
         LR    R1,R11        RESTORE REG1 TO POINT TO OUTPUT            00865120
         B     A01202        BRANCH TO PROCESS NEXT COMMAND             00865220
A01210   CLC   @0(@1,R6),0(R4)  COMPARE DSNAMES                         00867220
************************************************************            00869220
**                                                        **            00869320
**                   PUTLINE LIST MACRO EXPANSIONS        **            00870220
**                                                        **            00870620
************************************************************            00871020
PUTDATA PUTLINE OUTPUT=(PUTOUT,TERM,SINGLE,DATA),MF=L                   00871420
PUTDATA1 EQU   *-PUTDATA     THIS INSTRUCTION OBTAINS THE LENGTH        00871820
PUTMSG   PUTLINE OUTPUT=(PUTOUT,TERM,SINGLE,INFOR),MF=L                 00871920
PUTMSG1  EQU   *-PUTMSG      THIS GETS THE LENGHT OF THE PARM FLD       00872020
PUTMSG2  PUTLINE OUTPUT=(PUTOUT,TERM,MULTLVL,INFOR),MF=L                00872120
PUTMSG3  EQU   *-PUTMSG2     OBTAIN LENGTH OF PARM LIST                 00873720
GETLINE  EQU   *                                                        00874120
SERVICE  EQU   *                                                        00874520
MACRO    GETLINE  ,MF=L      LIST FORM OF GETLINE -CREATES PARM         00874920
PARMSIZE EQU   *-MACRO       LENGTH OF PARM FIELD USED IN MVC           00875320
PUTGETIT PUTGET  MF=L                                                   00875420
PUTGETSZ EQU   *-PUTGETIT                                               00875820
PUTGETML PUTGET OUTPUT=(PUTOUT,MULTLVL),MF=L                            00876220
PUTGETLN EQU   *-PUTGETML    FIND CORRECT LENGTH OF LIST                00876620
PUTSPACE PUTLINE OUTPUT=(PUTOUT,DATA),TERMPUT=(EDIT),MF=L               00877020
SPACESZ  EQU   *-PUTSPACE    SIZE OF LIST                               00877120
A50000   EQU   *             EQUATE LABEL TO THIS ADDRESS               00877820
         LR    R0,R15        R0=RETURN CODE FOR DDM.                    00878220
         L     R15,TSTDDM    R15=EP OF DDM ROUTINE.                     00878620
         BALR  R14,R15       FORMAT DIAGNOSTIC MSGS.                    00878720
         L     R1,OUTBUF     R1=ADDR OF 1ST & 2ND MSG VECTORS.          00878820
         B     A50006        WRITE MSGS TO TERMINAL.                    00879220
A50001   EQU   *             EQUATE LABEL TO THIS ADDRESS               00879320
         L     R1,MSSG1      PLACE ADDRESS OF MSG1 INTO R1              00879420
         B     MSGBUILD      BRANCH TO PROCESS MSG                      00879520
A50002   EQU   *             EQUATE LABEL TO THIS ADDRESS               00879720
         L     R1,MSSG5      PLACE ADDRESS OF MSG5 INTO R1              00880120
         B     A50006        BRANCH TO PROCESS MSG                      00880220
BADDS    EQU   *                                                        00881620
         L     R3,TSTIODSN   R3=ADDR TO DSNAME QUEUE.                   00882020
         L     R4,ZERO(R3)   R4=NEXT DSNAME ON QUEUE.                   00882420
         ST    R4,TSTIODSN   REMOVE DSNAME FROM QUEUE.                  00882820
         FREEMAIN R,LV=50,A=(3),SP=1  ISSUE FREEMAIN FOR DSNAME         00883220
         L     R1,MSSG6       PLACE ADDRESS OF MSG6 INTO R1.            00883620
         BR    R10           BRANCH TO PROCESS MSG.                     00884020
A50006   EQU   *             EQUATE LABEL TO THIS ADDRESS               00884420
         LCR   R1,R1         LOAD COMPLIMENT OF REG1                    00884520
         OI    TSTFLGS2,TMYIOMSG  TURN ON MY OWN MSG SW                 00884620
         B     A00800        BRANCH TO PUT MSG OUT TO TERM              00884720
A50030   EQU   *             EQUATE LABEL TO THIS ADDRESS               00885520
         LA    R15,@4        PLACE A RETURN CODE OF 4 INTO R15          00885920
         XI    TSTFLGS2,TMYIOMSG   TURN OFF MY MSG SW                   00886020
         B     A10000        BRANCH TO RETURN TO CALLER                 00886120
A80000   EQU   *                                                        00886220
         L     R7,ECBLOG     LOAD LOGON ECB ADDRESS FROM                00886620
*                            TCOMTAB INTO REG7                          00887020
         TM    @0(R7),HEX40  TEST HIGH ORDER BIT BEING ON               00887120
         BO    A10002        IF NOT ON CHECK ATTN ECB NEXT              00887220
         L     R7,ECBTMPA    LOAD ATTENTION ECB ADDRESS FROM            00887320
*                            TCOMTAB INTO REG7                          00887420
         TM    @0(R7),HEX40  TEST HIGH ORDER BIT BEING ON               00887520
         BO    A10002        IF NOT ON ALL IS WELL OTHERWISE BR         00888820
         BR    R14           RETURN TO CALLER                           00888920
MSGBUILD EQU   *                                                        00889020
         L     R7,OUTBUF     R7=ADDR OF 1ST AND 2ND MSG VECTOR.         00889420
         MVC   @4(@4,R7),@4(R1) GET 2ND LEVEL MSG POINTER.              00889820
         LA    R6,@8(R7)     R6=ADDR OF 1ST LEVEL MSG.                  00890220
         ST    R6,ZERO(R7)   MOVE IN 1ST LEVEL MSG VECTOR.              00890320
         L     R4,ZERO(R1)   R4=POINTER TO 1ST LEVEL MESSAGE.           00890420
         LH    R6,ZERO(R4)   R6=LENGTH OF MESSAGE.                      00890820
         LR    R3,R6         R3=EXECUTE LENGTH.                         00891220
         BCTR  R6,ZERO       R6=EXECUTE LENGTH.                         00891620
         LA    R7,@8(R7)     BUMP 8 PASS PARAMETER LIST.                00891720
         EX    R6,MSGMOVE    MOVE IN MESSAGE                            00892120
         LA    R7,ONE(R6,R7) R7=PTR TO NEXT OUTPUT BYTE.                00941820
         LH    R6,LENDSNME   R6=LENGTH OF DSNAME.                       00991820
         TM    FLAGRES1,QUOTED IS DSNAME QUOTED.                        01041820
         BNO   NOTQUOTE      NO DO NOT GET A QUOTE.                     01091820
         MVI   ZERO(R7),QUOTE MOVE A QUOTE INTO MESSAGE.                01141820
         LA    R3,ONE(R3)    ADD 1 TO LENGTH FOR QUOTE.                 01191820
         LA    R7,ONE(R7)    UPDATE PTR TO MSG.                         01241820
NOTQUOTE EQU   *                                                        01291820
         L     R4,STRNGPTR   R4=PTR TO DSNAME.                          01341820
         BCTR  R6,ZERO       R6=EXECUTE LENGTH.                         01391820
         EX    R6,MSGMOVE    MOVE DSNAME INTO MESSAGE STRING.           01441820
         LA    R7,ONE(R6,R7) UPDATE OUTPUT POINTER.                     01491820
         LA    R3,ONE(R6,R3) R3=UPDATED LENGTH.                         01541820
         TM    FLAGRES2,MEMBER MEMBER NAME SPECIFIED.                   01591820
         BNO   NOMEMBER      NO, END MESSAGE.                           01641820
         MVI   ZERO(R7),OPEN OPEN PARENTHESIS NOW IN MSG STRING.        01691820
         LH    R6,LENMEMBR   R6=LENGTH OF MEMBER NAME.                  01741820
         BCTR  R6,ZERO       R6=EXECUTE LENGTH.                         01791820
         LA    R7,ONE(R7)    UPDATE OUTPUT POINTER.                     01841820
         L     R4,PTRMEMBR   R4=PTR TO MEMBER NAME.                     01891820
         EX    R6,MSGMOVE    MEMBER NAME NOW IN MESSAGE.                01941820
         LA    R3,@3(R6,R3) UPDATE OUTPUT LENGTH.                       01991820
         LA    R7,ONE(R6,R7) UPDATE OUTPUT POINTER.                     02041820
         MVI   ZERO(R7),CLOSE CLOSE PARENTHESIS NOW IN MSG STRING.      02091820
         LA    R7,ONE(R7)    UPDATE OUTPUT POINTER.                     02141820
NOMEMBER EQU   *                                                        02191820
         TM    FLAGRES1,QUOTED DSNAME QUOTED.                           02241820
         BNO   NOQUOTE       NO,DO NOT MOVE IN QUOTE.                   02291820
         MVI   ZERO(R7),QUOTE QUOTE NOW IN MSG STRING.                  02341820
         LA    R3,ONE(R3)    UPDATE LENGTH OF OUTPUT.                   02391820
NOQUOTE  EQU   *                                                        02441820
         L     R1,OUTBUF     R7=FIRST BYTE OF THE MESSAGE.              02491820
         L     R4,@4(R1)     R4=PTR TO 2ND LEVEL MSG.                   02541820
         LTR   R4,R4         Q.IS THERE A 2ND LEVEL MSG.                02591820
         BZ    NO2ND         NO,DO NOT ADD -+- SIGN.                    02641820
         MVI   ONE(R7),PLUS  MOVE IN PLUS SIGN.                         02691820
         LA    R3,ONE(R3)    UPDATE LENGTH.                             02741820
NO2ND    EQU   *                                                        02791820
         STH   R3,@8(R1)     LENGTH OF MESSAGE NOW IN LENGTH FIELD.     02841820
         B     A50006        SET MESSAGE INDICATOR.                     02891820
MSGMOVE  MVC   ZERO(ONE,R7),ZERO(R4) MOVE MESSAGE INTO BUFFER.          02941820
A01001   MVC   @1(@1,R1),@0(R1)                                         02991820
         USING DSNDSECT,R5   USE R5 TO ADDRESS DSNAME DSECT             03041820
MOVDSNAM MVC   DSNAME(@1),@0(R6) MOVES DSNAME  TO GETMAIN AREA          03091820
MOVEIN   MVC   @6(@1,R6),@2(R5)                                         03141820
SAMENAME CLC   @6(@1,R3),@2(R5)   SEE IF NAMES ARE THE SAME             03191820
************************************************************            03241820
** THIS IS THE OPEN EXIT ROUTINE WHICH CHECKS FOR BLKSIZE **            03291820
** BEING PRESENT.  IF NONE IS PRESENT WE USE A DEFAULT    **            03341820
** BLKSIZE OF 1629.                                       **            03391820
************************************************************            03441820
         CNOP  0,4           SPACE TO A FULLWORD BOUNDARY               03491820
LIST     DC    X'85'         EXIT CODE FOR OPEN ROUTINE                 03541820
         DC    AL3(EXIT)     ADDRESS OF OPEN EXIT ROUTINE               03591820
EXIT     EQU   *             EQUATE LABEL TO THIS ADDRESS               03641820
         USING IHADCB,R4   USE REG4 TO ADDRESS DCB                      03691820
         TM    DCBRECFM,VARIABLE Q.RECORD FORMAT VARIABLE               03741820
         BZ    DEFAULT2      NO DEFAULT TO VARIABLE BLOCK               03791820
         TM    DCBRECFM,UREC Q.IS IT UNDEFINED                          03841820
         BO    DEFAULT2      YES,DEFAULT TO VARIABLE BLOCK              03891820
         CLC   DCBLRECL,LRECL Q.LRECL GT 124                            03941820
         BNL   CKBLK         YES,CHECK BLKSIZE                          03991820
         MVC   DCBLRECL,LRECL MOVE IN DEFAULT LRECL                     04041820
CKBLK    EQU   *                                                        04091820
         CLC   DCBBLKSI,SMALLBLK Q.BLKSIZE GT 128                       04141820
         BNL   FINISH        YES,RETURN TO OPEN                         04191820
         MVC   DCBBLKSI,SMALLBLK MOVE IN DEFAULT BLKSIZE                04241820
FINISH   EQU   *                                                        04291820
         BR    R14           RETURN TO OPEN ROUTINE                     04341820
DEFAULT2 EQU   *                                                        04391820
         MVI   DCBRECFM,VB   MAKE RECFM VARIABLE                        04441820
         MVC   DCBBLKSI,BLKSIZE MOVE BLKSIZE IN                         04491820
         MVC   DCBLRECL,LRECL MOVE IN DEFAULT LRECL                     04541820
         BR    R14           RETURN TO OPEN ROUTINE                     04591820
A7SYNAD  EQU   *             SYNAD ROUTINE                              04641820
         L     R1,MSSG6      GET SYNAD MSG ADDRESS INTO R1              04691820
         L     R2,OUTBUF     GET OUTPUT ADDRESS INTO REG2               04741820
         MVC   @0(@35,R2),@0(R1) MOVE MESSAGES INTO OUTPUT              04791820
         LA    R3,@8(R2)     GET ADDRESS OF FIRST MSG IN R3             04841820
         ST    R3,@0(R2)     PLACE ADDRESS OF MSG INTO OUTPUT           04891820
         LA    R3,@32(R2)    GET ADDR OF 2 MSG INTO R3                  04941820
         ST    R3,@4(R2)     PLACE ADDRESS OF 2 MSG INTO OUTPUT         04991820
         SYNADAF ACSMETH=QSAM ISSUE SYNAD MACRO                         05041820
         MVC   @32(@79,R2),@49(R1) MOVE SYNAD INFOR INTO OUTPUT         05091820
*                            SYNAD INFOR MAKES UP SECOND LEVEL          05141820
*                            MESSAGE                                    05191820
         SYNADRLS            ISSUE SYNAD RELEASE MACRO                  05241820
         LR    R1,R2         PLACE POINTER TO MSG INTO R1               05291820
         LCR   R1,R1         LOAD COMPLIMENT OF REG 1                   05341820
         OI    TSTFLGS2,TMYIOMSG TURN ON MY MSG SW                      05391820
         B     A00800        BRANCH TO PUT MSG OUT TO TERM              05441820
         DS    0F                                                       05491820
PUTOUT EQU *                                                            05541820
************************************************************            05591820
**                                                        **            05641820
**              EQUATES                                   **            05691820
**                                                        **            05741820
************************************************************            05791820
UREC     EQU   X'C0'         UNDEFINED RECORD                           05841820
QUOTE    EQU   C''''         QUOTE SIGN                                 05891820
PLUS     EQU   C'+'          A PLUS SIGN FOR BUILDING MESSAGES.         05941820
TWO      EQU   2             VALUE OF 2                                 05991820
ZERO     EQU   0             VALUE OF ZERO                              06041820
ONE      EQU   1             VALUE OF ONE                               06091820
VB       EQU   X'50'         VARIABLE BLOCK RECORD.                     06141820
VARIABLE EQU   X'40'         VARIABLE RECORD.                           06191820
BLOCK    EQU   X'10'         BLOCK RECORD.                              06241820
OPEN     EQU   C'('          OPEN PARENTHESIS FOR MESSAGE.              06291820
CLOSE    EQU   C')'          CLOSE PARENTHESIS.                         06341820
@4       EQU   4             VALUE OF 4                                 06391820
@5       EQU   5             VALUE OF 5                                 06441820
@7       EQU   7                                                        06491820
@16      EQU   16            VALUE OF 16                                06501820
@48      EQU   48            VALUE OF 48                                06511820
HEX40    EQU   X'40'                                                    06521820
HEXFF    EQU   X'FF'                                                    06531820
NEWDS    EQU   X'FF'                                                    06533820
PSDS     EQU   X'40'                                                    06535820
MEMBER   EQU   X'80'                                                    06537820
QUOTED   EQU   X'40'                                                    06539820
@6       EQU   6             VALUE OF 6                                 06539920
@96      EQU   96            VALUE OF 96                                06559920
ON       EQU   X'08'         TURNS ON SWITCHES                          06569920
@0       EQU   0             VALUE OF ZERO                              06579920
@1       EQU   1             VALUE OF 1                                 06586620
HEX4D    EQU   X'4D'                                                    06588620
HEX7D    EQU   X'7D'                                                    06590620
HEX5E    EQU   C';'                                                     06592620
HEX5D    EQU   X'5D'                                                    06593020
OFF      EQU   X'08'         TURNS OFF SWITCHES                         06593120
@2       EQU   2             VALUE OF 2                                 06593220
@64      EQU   64            VALUE OF 64                                06609920
@3       EQU   3             VALUE OF 3                                 06619920
R0       EQU   0             REGISTER ZERO                              06621920
R1       EQU   1             REGISTER 1                                 06623920
R2       EQU   2             REGISTER 2                                 06625920
R3       EQU   3             REGISTER 3                                 06626320
R4       EQU   4             REGISTER 4                                 06626420
R5       EQU   5             REGISTER 5                                 06626520
R6       EQU   6             REGISTER 6                                 06632120
R7       EQU   7             REGISTER 7                                 06634120
R8       EQU   8             REGISTER 8                                 06636120
R9       EQU   9             REGISTER 9                                 06636520
R10      EQU   10            REGISTER 10                                06636920
R11      EQU   11            REGISTER 11                                06637320
R12      EQU   12            REGISTER 12                                06637420
R13      EQU   13            REGISTER 13                                06637520
R14      EQU   14            REGISTER 14                                06637620
R15      EQU   15            REGISTER 15                                06643220
@84      EQU   84            VALUE OF 84                                06643320
@43      EQU   43            VALUE OF 43                                06645320
HEX08    EQU   X'08'                                                    06647320
HEX00    EQU   X'00'                                                    06647720
HEX20    EQU   X'20'                                                    06648120
LEFTPREN EQU   B'00001000'                                              06648520
FIRSTQSW EQU   B'00000100'                                              06648620
HEX80    EQU   X'80'         HEXIDECIMAL 80                             06648720
OPENMOD  EQU   B'00001000'                                              06662920
HEXC0    EQU   X'C0'                                                    06672920
HEX50    EQU   X'50'         HEXIDECIMAL 50                             06674920
BLANK    EQU   X'40'         A BLANK                                    06676920
@12      EQU   12                                                       06677320
@20      EQU   20                                                       06682020
HEX05    EQU   X'05'                                                    06684020
HEX15    EQU   X'15'                                                    06686020
HEX04    EQU   X'04'                                                    06686420
HEX10    EQU   X'10'                                                    06686820
@40      EQU   40                                                       06691520
@24      EQU   24                                                       06691620
@104     EQU   104                                                      06693620
@8       EQU   8                                                        06695620
@100     EQU   100                                                      06696020
@35      EQU   35                                                       06696120
@32      EQU   32                                                       06696220
@79      EQU   79                                                       06696320
@49      EQU   49                                                       06701020
CYLCODE  EQU   X'C0'                                                    06701120
BLKCODE  EQU   X'40'                                                    06703120
***********************************************************             06705120
**               DAIR PDE CONSTANTS                      **             06705520
***********************************************************             06705620
BASE     DC    A(BASELOC)    POINTER TO BEGINNING OF PROG               06705720
DISPOLD  DC    X'010808'     CREATE DISP=(OLD,KEEP)                     06705820
DISPNEW  DC    X'040204'     CREATES DISP=(NEW,DELETE)                  06718120
DISPMOD  DC    X'020808'     DISP=MOD,KEEP                              06718520
LRECL    DC    H'125'        DEFAULT LRECL                              06718920
TESTLIST DC    C'TESTLIST'   QUALIFIER FOR DEFAULT NAMING ROUTINE       06719320
SYSDA    DC    C'SYSDA   '                                              06719720
PRMSPACE DC    F'1'          CREATE**                                   06719820
SECSPACE DC    F'100'        **SPACE=(BLK,(1,100))                      06719920
BLKSIZE  DC    H'1629'       DEFAULT BLKSIZE                            06720020
DARC1708 DC    X'1708'       DAIR CATALOG ERROR CODE.                   06730020
SMALLBLK DC    H'129'        SMALLEST BLKSIZE                           06730420
DAIRLIST DS    0H            CONSTANTS FOR DAIR                         06730520
         DC    12X'0'                                                   06730620
         DC    24C' '                                                   06730720
         DC    16X'0'                                                   06734820
         DC    16C' '                                                   06736820
         DC    8X'0'                                                    06738820
DAIRLEN  EQU   *-DAIRLIST                                               06738920
***********************************************************             06743020
**           MESSAGE FORMAT FOR PUTLINE                  **             06743120
***********************************************************             06745120
MSGPOINT DS    1F            CONSTANT FIELD TO FILL DSECT WITH          06747120
         DC    X'00000001'   INDICATES ONLY ONE PART TO MSG             06751220
         DS    1F            POINTER TO 1ST LEVEL MSG                   06751320
         DC    X'00000000'                                              06753320
         DC    X'00000001'   INDICATES ONLY ONE PART                    06755320
         DS    1F            POINTER TO 2ND LEVEL MSG                   06759420
***********************************************************             06759520
**     MSG VCONS FOR REFERENCING THE MSG CSECT           **             06761520
***********************************************************             06763520
MSSG1    DC    V(IKJEGIM1)   POINTS TO MSG 1 IN MSG CSECT               06774420
MSSG5    DC    V(IKJEGIM5)   POINTS TO MSG IN MSG CSECT                 06774820
MSSG6    DC    V(IKJEGIM6)   POINTS TO MSG IN MSG CSECT                 06775220
***********************************************************             06775620
**        BRANCHES FOR VARIOUS RETURN CODES              **             06775720
***********************************************************             06775820
A0300    DC    A(A02002)     BRANCH TO PLACE INBUF ADDR IN INBUF        06775920
         DC    A(A02002)     BRANCH TO PLACE INBUF ADDR IN INBUF        06777920
         DC    A(A02007)     BRANCH PLACE ATTENTION CODE IN R15         06779920
         DC    A(A02008)     BRANCH TO INDICATE NO LINE GOTTEN          06780020
A0301    DC    A(A10000)     BRANCH TO RETURN TO CALLER                 06782020
         DC    A(A02007)     BRANCH TO PLACE ATTN CODE IN R15           06784020
         DC    A(A02008)     BRANCH TO PUT NO GOOD CODE IN R15          06784420
         DC    A(A02008)     AGAIN NO GOOD CODE IN R15                  06784820
A03003   DC    A(A10000)     BRANCH TO RETURN TO CALLER                 06785220
         DC    A(A10000)     BRANCH TO RSTURN TO                        06785320
         DC    A(A10000)     BRANCH TO RETURN TO CALLER                 06785420
         DC    A(A02007)     BRANCH FOR ATTN PLACE A 16 IN R15          06789020
         DC    A(A02008)     BRANCH FOR NO SUCCESS CODE                 06791020
         DC    A(A02008)     BRANCH FOR NO SUCCESS CODE                 06791420
         DC    A(A02008)     BRANCH FOR NO SUCCESS CODE                 06791820
         DC    A(A02008)     BRANCH FOR NO SUCCESS CODE                 06792220
         DS    0H                                                       06792620
ATTN24   DC    X'0018'                                                  06792720
TWOBLNKS DC    X'4040'                                                  06796320
MYDCB    DCB   MACRF=(PM),DSORG=PS,EXLST=LIST,SYNAD=A7SYNAD             06796420
LENDCB   EQU   *-MYDCB       LENGTH OF YMDCB                            06798420
CLFORM   CLOSE (CLFORM),MF=L  LIST FORM OF CLOSE                        06798820
LENCLF   EQU   *-CLFORM      LENGTH OF CLOSE MACRO                      06799220
LFORM    OPEN  (,(OUTPUT)),MF=L  LIST FORM OF OPEN                      06799620
LENOLF   EQU   *-LFORM       LENGTH OF OPEN MACRO                       06800020
***********************************************************             06803620
**                                                       **             06803720
**          MESSAGE CSECT FOR IKJEGIO                    **             06805720
**                                                       **             06806120
***********************************************************             06806520
IKJEGIOM CSECT               MESSAGE CSECT                              06806920
*RELEASE 21                                                             06807021
*A007588                                                         A49889 06807121
*C007590                                                         A49889 06807221
         ENTRY IKJEGIM1                                                 06807320
         ENTRY IKJEGIM5                                                 06810920
         ENTRY IKJEGIM6                                                 06811020
IKJEGIM1 DC    A(ERRMSG1)                                               06813020
         DC    X'00000000'                                              06813420
IKJEGIM5 DC    A(ERRMSG5)                                               06813820
         DC    X'00000000'                                              06814220
IKJEGIM6 DC    A(IKJEGOM6)                                              06814620
         DC    A(IKJEGOM7)                                              06815820
         DS    0H                                                       06817820
ERRMSG8  DC    AL2(ERR1-ERRMSG8)                                        06817920
         DC    AL2(0)                                                   06818020
         DC    C'IKJ57400I '                                            06818120
         DC    C'PERMANENT I/O ERROR'                                   06821220
ERR1     EQU   *                                                        06821620
         DS    0H                                                       06821720
ERRMSG9  DC    X'004F0000'   LENGTH OF MSG FROM SYSNAD                  06821820
         DS    0H                                                       06821920
ERRMSG1  DC    AL2(ERR2-ERRMSG1)                                        06823920
         DC    AL2(0)                                                   06824320
         DC    C'IKJ57401I '                                            06824420
         DC    C'UNABLE TO OPEN DATA SET '                              06824720
ERR2     EQU   *                                                        06825120
         DS    0H                                                       06825220
ERRMSG5  DC    AL2(ERR6-ERRMSG5)                                        06825320
         DC    AL2(0)                                                   06825420
         DC    C'IKJ57403I '                                            06826320
         DC    C'NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'            06826720
ERR6     EQU   *                                                        06827120
         DS    0H                                                       06827520
         DS    0H                                                       06827620
ERRMSG12 DC    AL2(END12-ERRMSG12)                                      06828020
         DC    AL2(0)                                                   06828120
         DC    C'IKJ57404I '                                            06837020
         DC    C'UNABLE TO QUALIFY DATA SET NAME'                       06839020
END12    EQU   *                                                        06839420
         DS    0H                                                       06839820
IKJEGOM6 EQU   *                                                        06839920
         DC    AL2(ENDIM6-IKJEGOM6)                                     06840020
         DC    AL2(0)                                                   06842020
         DC    C'IKJ57405I '                                            06844020
         DC    C'UNABLE TO PRINT INTO DATA SET '                        06846020
ENDIM6   EQU   *                                                        06846420
         DS    0H                                                       06846520
IKJEGOM7 EQU   *                                                        06859120
         DC    AL2(ERR10-IKJEGOM7)                                      06861120
         DC    AL2(0)                                                   06863120
         DC    C'IKJ57405I '                                            06863520
         DC    C'PRINT DATA SET MUST BE PHYSICAL SEQUENTIAL'            06863920
ERR10    EQU   *                                                        06864320
TCOMTAB TCOMTAB                                                         06864420
****************** SHORT TMP DSECT FOR PSCB PTR ****************        06866420
TMPDSECT DSECT                                                          06868420
PSCBPTR  DS   A                                                         06870420
************************************************************            06870820
**                                                        **            06871220
**              DSNDSECT - DSNAME DSECT                   **            06871620
**                                                        **            06871720
************************************************************            06872220
DSNDSECT DSECT               DSECT POINTED TO BY DAIR PARM FLD          06872620
DSLNGTH  DS    CL2           LENGTH OF DSNAME                           06873020
DSNAME   DS    CL44          ACTUAL DSNAME                              06873120
DSNLEN   EQU   *-DSNDSECT    LENGTH OF DSNAMPDE DSECT                   06873220
TLEN     EQU   LENDCB+LENCLF+LENOLF+DSNLEN TOTAL LENGTH FOR GETMAIN     06876220
************************************************************            06878220
**                                                        **            06880220
**              DSNAMPDE -DSNAME PDE DSECT                **            06880620
**                                                        **            06881020
************************************************************            06881420
DSNAMPDE DSECT               DSECT DESCRIBING PDE                       06881820
STRNGPTR DS    CL4           PTR TO DSNAME                              06881920
LENDSNME DS    CL2           LENGTH OF DSNAME                           06882020
FLAGRES1 DS    CL2           FLAGS AND RESERVE BYTE                     06882120
PTRMEMBR DS    CL4           POINTER TO MEMBER NAME                     06884320
LENMEMBR DS    CL2           MEMBER NAME LENGTH                         06884420
FLAGRES2 DS    CL2           FLAGS AND RESERVE BYTE                     06886420
PSWRDPTR DS    CL4           PTR TO PASSWORD                            06886920
LENPSWRD DS    CL2           LENGTH OF PASSWORD                         06887420
FLAGRES3 DS    CL2           FLAGS AND RESERVE BYTE                     06887920
************************************************************            06888420
**                                                        **            06888820
**    MESSAGE POINTER PARAMETER LIST DSECT                **            06891020
**                                                        **            06891120
************************************************************            06893120
MULDSECT DSECT               DSECT WHICH ADDRESSES MSG POINTER LIST     06895120
NEXTLVL  DS    A             POINTER TO NEXT MSG                        06895520
ONELEVEL EQU   *             IF ONLY ONE MSG WE BEGIN HERE              06896020
SEGMENTS DS    A             NUMBER OF PARTS TO MSG                     06896420
MSGPTR1  DS    A             ACTUAL POINTER TO MSG                      06896820
FINALEVL DS    A             INDICATES THAT NO MORE LEVELS EXIST        06896920
SEGMNTS  DS    A             NUMBER OF PARTS TO 2 MSG                   06901120
MSGPTR2  DS    A             ACTUAL ADDRESS OF 2 MSG                    06903120
************************************************************            06905120
**                                                        **            06905220
**                PUT GET DSECT                           **            06905320
**                                                        **            06909520
************************************************************            06909620
PUTGETDS DSECT               DSECT THAT ADDRESSES PUTGET LIST           06911620
ZAP      DS    CL12                                                     06913620
INBUFPTR DS    A             POINTER TO INBUF AREA                      06913720
************************************************************            06917920
**                 TMP DSECT NEEDED FOR PSCB              **            06918020
************************************************************            06920020
         IKJTPL                                                         06922020
*******************************************************                 06922120
**                                                   **                 06926320
**        TEST WORKAREA DSECT                        **                 06926420
**                                                   **                 06928420
*******************************************************                 06930420
        TSTCWORK                                                        06930520
         IKJECT                                                         06939420
         DCBD  DSORG=PS                                                 06943220
PASSDCB  EQU   LENDCB+LENCLF+LENOLF  ADDRESS FOR DSNAME DSECT           06945220
         IKJDAP04                                                       06947220
         IKJIOPL                                                        06947320
         IKJPTPB                                                        06947420
         IKJGTPB                                                        06947820
         IKJPGPB                                                        06948220
         IKJDFPL                                                        06948620
         IKJDFPB                                                        06948720
         IKJDAPL                                                        06949620
         EJECT                                                          06950020
IKJEGDDM CSECT                                                          06950420
         SPACE                                                          06950820
*        THIS CLOSED SUBROUTINE IS AVAILABLE TO ALL TEST ROUTINES       06951220
*        FOR THE PURPOSE OF CREATING THE APPROPRIATE FIRST- AND         06951320
*        SECOND-LEVEL DIAGNOSTIC MESSAGES IN THE CASE OF AN UNSUC-      06951420
*        CESSFUL RETURN FROM DAIR.                                      06951520
*              INPUT REGISTERS - R0 DAIR RETURN CODE.                   06952920
*                                R1 DAIR PARM LIST ADDRESS.             06954920
*                                R9 TCOMTAB ADDRESS.                    06955320
*                                R13 REGISTER SAVE AREA ADDRESS.        06955720
*                                R14 RETURN ADDRESS.                    06956720
*                                R15 IKJEGDDM ENTRY POINT.              06957120
*                                                                       06957520
*              OUTPUT - FIRST- AND SECOND-LEVEL MESSAGE VECTORS ARE     06957620
*                       RETURNED IN A LIST POINTED TO BY 'OUTBUF' OF    06957720
*                       TCOMTAB.                                        06958120
         SPACE                                                          06958520
         USING TCOMTAB,R9     TCOMTAB ADDRESSABILITY.                   06958920
         USING DAPB08,R1      DAIR PARM BLOCK ADDRESSABILITY.           06969920
         USING *,R15          PROGRAM ADDRESSABILITY.                   06971920
         SAVE  (14,12)        SAVE CALLER'S REGS.                       06973920
         L     R4,OUTBUF      R4=ADDR OF MESSAGE VECTORS.               06974320
         XC    D4(L8,R4),D4(R4) CLEAR VECTOR AND CONTROL WORD.          06974720
         LA    R5,D8(R4)      R5=ADDR OF 1ST-LEVEL MSG.                 06975120
         LR    R11,R5         R11 ALSO.                                 06975520
         MVI   D12(R4),BLANKER BLANK TEXT AREA.                         06977520
BLANKER  EQU   C' '                                                     06979520
         ST    R5,D0(R4)      INITIALIZE 1ST-LEVEL VECTOR.              06979920
         MVC   D13(L155,R4),D12(R4) FINISH BLANKING TEXT AREA.          06980320
         LA    R5,D4(R5)      R5=TEXT AREA ADDR.                        06980720
         SR    R3,R3          CLEAR R3 FOR EXECUTES.                    06980820
         L     R6,NA1CON      R6=ADDR OF ALLOC MSG SEGMENT 1.           06980920
         IC    R3,D0(R6)      R3=SEGMENT LENGTH.                        06982020
         LA    R7,D1(R6)      R7=SEGMENT TEXT ADDR.                     06984020
         BAL   R14,EXECUTE    MOVE SEGMENT.                             06984120
         LR    R2,R0          PLACE RETURN CODE IN INDEX REG.           06984220
         L     R1,D16(R1)     R1=DAIR PARM BLOCK ADDR.                  06984320
         LA  R14,@8          TO TEST RETURN CODE                        06984920
         CR    R14,R2        TEST FOR RC 8                              06985520
         BE    RC8           BRANCH IF RC=8                             06986120
         LA    R14,@4(R14)   TO TEST NEXT RETURN CODE                   06986720
         CR  R14,R2          TEST FOR RETURN CODE 12                    06987320
         BE    RC12          BRANCH IF RC=12                            06987920
         LA    R14,@4(R14)   BUMP FOR NEXT TEST                         06988520
         CR    R14,R2        TEST FOR RETURN CODE 16                    06989120
         BE    RC16          BRANCH IF RC=16                            06989720
         B     ALLRC         BRANCH FOR ANY OTHER RETURN CODE           06990320
RC16     EQU   *              RETURN CODE 16.                           06990920
         L     R8,NA401CON    R8=ADDR OF REMAINDER OF 1ST-LEVEL.        06991020
         BAL   R10,DSNMOVE    FILL IN REMAINDER OF 1ST-LEVEL.           06991320
         MVI   D19(R4),ZERODDM MOVE IN UNIQUE ID.                       06991720
ZERODDM  EQU   C'0'                                                     06991820
         MVC   D4(L4,R4),NA402CON INITIALIZE 2ND-LEVEL VECTOR.          06991920
         B     EXCALLER       RETURN TO CALLER.                         06994420
RC12     EQU   *                                                        06996420
         CLC   DA08DARC(L2),TWO1C Q.DARC=21C.                           06998420
         BNE   DARC218        NO,CHECK 218.                             06998820
         L     R8,NA411CON    R8=ADDR OF 1ST-LEVEL REMAINDER.(6708)     06999220
         BAL   R10,DSNMOVE    FILL IN REMAINDER.                        06999620
         MVI   D18(R4),ONEDDM MOVE IN UNIQUE ID.                        07001920
         MVI   D19(R4),SEVNDDM MOVE IN UNIQUE ID.                       07002820
ONEDDM   EQU   C'1'                                                     07014020
         MVC   D4(L4,R4),NA412CON INITIALIZE 2ND-LEVEL VECTOR.          07014920
         B     EXCALLER       RETURN TO CALLER.                         07015820
DARC218  EQU   *                                                        07016720
         CLC   DA08DARC(L2),TWO18 Q.DARC=218.                           07017620
         BNE   DARC214        NO,CHECK 214.                             07018520
CTRC04   EQU   *                                                        07018920
         L     R8,NA421CON    R8=ADDR OF 1ST-LEVEL REMAINDER.(218)      07019420
         BAL   R10,DSNMOVE    COMPLETE 1ST-LEVEL MSG.                   07020320
         MVI   D19(R4),TWODDM MOVE IN UNIQUE ID.                        07021220
TWODDM   EQU   C'2'                                                     07022120
         MVC   D4(L4,R4),NA422CON INITIALIZE 2ND-LEVEL VECTOR.          07023020
         B     EXCALLER       RETURN TO CALLER.                         07023920
DARC214  EQU   *                                                        07024320
         CLC   DA08DARC(L2),TWO14 Q. DARC=214.                          07024720
         BNE   DARC210        NO, CHECK 210                             07025320
         L     R8,NA411CON    R8+ADDR OF 1ST LEVEL REMAINDER            07025720
         BAL   R10,DSNMOVE    COMPLETE 1ST LEVEL MSG                    07026120
         MVI   D18(R4),ONEDDM MOVE IN UNIQUE ID.                        07026520
         MVI   D19(R4),SEVNDDM MOVE IN UNIQUE ID.                       07026720
         MVC   D4(L4,R4),NA461CON INITIALIZE 2ND LEVEL VECTOR.          07027120
         B     EXCALLER       RETURN TO CALLER                          07027220
DARC210  EQU   *                                                        07027320
         CLC   DA08DARC(L2),TWO10 Q.DARC=210.                           07027520
         BNE   DARC334                                                  07027820
         L     R8,NA441CON    R8=ADDR OF 1ST-LEVEL REMAINDER.           07028420
         BAL   R10,DSNMOVE    COMPLETE 1ST-LEVEL MSG.                   07029020
         MVI   D19(R4),FOURDDM MOVE IN UNIQUE ID.                       07029620
FOURDDM  EQU   C'4'                                                     07030220
         MVC   D4(L4,R4),NA442CON INITIALIZE 2ND-LEVEL VECTOR.          07031120
         B     EXCALLER       RETURN TO CALLER.                         07032020
DARC334  EQU   *                                                        07032920
         CLC   DA08DARC(L2),THREE34 Q.DARC=334.                         07033820
         BNE   DARC4714        NO, CHECK 4714                           07034720
         LR    R6,R5          SAVE R5 CONTENTS.                         07035620
         LA    R5,D18(R4)     RESET R5 TO BEGINNING OF TEXT.            07036520
         L     R7,NA451ACN    R7=1ST-LEVEL BEGINNING SEGMENT ADDR.      07037420
         IC    R3,D0(R7)      R3=LENGTH.                                07038320
         LA    R7,D1(R7)      R7=TEXT ADDR.                             07039220
         BAL   R14,EXECUTE    MOVE SEGMENT.                             07040120
         LR    R5,R6          SET R5 BACK UP AGAIN.                     07041020
         L     R8,NA451BCN    R8=1ST-LEVEL REMAINDER ADDR.              07041920
         BAL   R10,DSNMOVE    COMPLETE 1ST-LEVEL MSG.                   07042820
         B     EXCALLER       RETURN TO CALLER.                         07043720
DARC4714 EQU   *                                                        07044620
         CLC   DA08DARC(L2),FOUR714 Q. DARC=4714                        07044720
         BNE   DARC330        NO, CHECK 330                             07044820
         L     R8,NA481CON    R8=ADDR OF FIRST LEVEL REMAINDER          07044920
         BAL   R10,DSNMOVE    COMPLETE FIRST LEVEL MSG                  07045020
         MVI   D18(R4),ONEDDM MOVE IN UNIQUE ID.                        07045120
         MVI   D19(R4),ATEDDM MOVE IN UNIQUE ID.                        07045220
         MVC   D4(L4,R4),NA482CON INITIALIZE 2ND LEVEL VECTOR           07045320
         B     EXCALLER       RETURN TO CALLER                          07045720
ATEDDM   EQU   C'8'                                                     07046120
DARC330  EQU   *                                                        07046520
         CLC   DA08DARC,THREE30 Q. DARC=330                             07047220
         BNE   GPERROR        NO, USE ALL PURPOSE MSG                   07047320
         LA    R5,D12(R4)     R5= TEXT AREA ADDR                        07047420
         L     R6,NA491CON    ADDR OF FIRST MSG SEGMENT                 07047820
         XR    R3,R3          ZERO REG 3                                07048220
         IC    R3,D0(R6)      ACCESS LENGTH OF SEGMENT                  07048620
         LA    R7,D1(R6)      SEGMENT TEST ADDR                         07049020
         BAL   R14,EXECUTE    MOVE SEGMENT                              07049120
         LA    R7,DA08MNM     CREATE PTR TO MEMBER NAME                 07049520
         LA    R3,L7          EXECUTE LENGTH FOR MEMBER NAME            07049920
         BAL   R14,EXECUTE    MOVE SEGMENT                              07050520
         L     R8,NA491ACN    ADDR OF NEXT SEGMENT                      07056920
         IC    R3,D0(R8)      LENGTH OF SEGMENT                         07057220
         LA    R7,D1(R8)      MSG TEXT                                  07057320
         BAL   R14,EXECUTE    MOVE MEMBER NAME AND SEGMENT              07057520
         L     R8,NA491BCN    LAST MSG SEGMENT                          07058120
         BAL   R10,DSNMOVE    MOVE DSNAME AND SEGMENT                   07058720
         B     EXCALLER       RETURN TO CALLER                          07059320
GPERROR  EQU   *                                                        07059920
         L     R8,NA431CON    R8=1ST-LEVEL REMAINDER ADDR.              07060520
         BAL   R10,DSNMOVE    COMPLETE 1ST-LEVEL MSG.                   07061120
         MVI   D19(R4),THREDDM MOVE IN UNIQUE ID.                       07061720
THREDDM  EQU   C'3'                                                     07062320
         LA    R5,D1(R5,R11)  RESET R5 TO 2ND-LEVEL BEGINNING.          07062920
         N     R5,HALFRND     ROUND R5 TO HALF-WORD BOUNDARY.           07063520
         LR    R11,R5         R11=ADDR OF 2ND LEVEL MSG ALSO.           07064120
         XC    D0(L4,R5),D0(R5) CLEAR CONTROL WORD.                     07064720
         ST    R5,D4(R4)      SET 2ND-LEVEL VECTOR.                     07065320
         LA    R5,D4(R5)      R5=2ND-LEVEL TEXT ADDR.                   07065920
         B     *-D4(R2)       BRANCH FOR DA OR CATALOG 2ND-LEVEL.       07066520
         B     CATERR         CATALOG ERROR MSG.                        07067120
DAERROR  EQU   *                                                        07067720
         CLI   DA08DARC,FOUR7 Q. DARC=47XX                              07068320
         BE    DARC47XX       IF SO,ANOTHER MSG                         07068920
         L     R7,NA432ACN    R7=DA ERROR 1ST SEGMENT ADDR.             07069520
         LA    R8,DA08DARC    R8=DA ERROR CODE ADDR.                    07070120
         B     BLD2ND         FINISH 2ND-LEVEL.                         07070720
DARC47XX EQU   *                                                        07071320
         L     R7,NA432CCN    IST SEGMENT ADDR                          07071920
         LA    R8,DA08DARC    ERROR CODE ADDR                           07072520
         B     BLD2ND         FINISH 2ND LEVEL                          07073120
CATERR   EQU   *                                                        07073720
         L     R7,NA432BCN    R7=CATALOG ERROR 1ST SEGMENT ADDR.        07074320
         LA    R8,DA08CTRC    R8=CATALOG ERROR CODE ADDR.               07074920
BLD2ND   EQU   *                                                        07075520
         IC    R3,D0(R7)      R3=LENGTH OF SEGMENT.                     07076120
         LA    R7,D1(R7)      R7=TEXT ADDR                              07076720
         BAL   R14,EXECUTE    MOVE SEGMENT INTO BUFFER.                 07077320
         UNPK  D0(L5,R5),D0(L3,R8) UNPACK ERROR CODE INTO MSG.          07077920
         TR    D0(L4,R5),TRTAB-D240 TRANSLATE FOR LETTERS.              07078520
         LA    R5,D4(R5)      BUMP R5 FOR LENGTH.                       07079120
         SR    R5,R11         R5=MSG LENGTH.                            07079720
         STH   R5,D0(R11)     STORE IN CONTROL WORD OF 2ND-LEVEL.       07080320
         B     EXCALLER       RETURN TO CALLER.                         07080920
ALLRC    EQU   *                                                        07081920
         MVC   D0(L4,R4),NA500CON ST ADDRESS OF FIRST LEVEL MSG         07082920
         ST    R11,D4(R4)    PTR TO SECOND LEVEL                        07083920
         LA    R5,@4(R11)    INITIALIZE PTR TO TEXT                     07084920
         L     R7,NA501CON   ADDRESS OF SECOND LEVEL                    07085920
         CVD   R2,RCODE(R4)  CONVERT RETURN CODE                        07086920
         LH    R8,RCODE+@6(R4) ACCESS I BYTES OF RC                     07087920
         SRL   R8,D4         SHIFT OUT SIGN BITS                        07088920
         STH   R8,RCODE+@6(R4) RESTORE RETURN CODE                      07089920
         LA    R8,RCODE+@6(R4) CREATE PTR TO RC                         07090920
         B     BLD2ND        BUILD SECOND LEVEL MSG                     07091920
RCODE    EQU   160                                                      07092920
RC8      EQU   *                                                        07095420
         CLC   DA08CTRC(L2),CODE4 Q.CTRC=4.                             07096720
         BE    CTRC04         YES, SET UP MSG                           07098020
         CLC   DA08CTRC(L2),CODE8 Q.CTRC=8.                             07099320
         BE    NOTINMSG       YES,SET UP CATALOG MSG.                   07100620
         CLC   DA08CTRC(L2),CODEC Q.CTRC=C.                             07101920
         BE    NOTINMSG       YES,DITTO.                                07103220
         CLC   DA08CTRC(L2),CODE10 Q.CTRC=10.                           07104520
         BNE   GPERROR        NO,USE GENERAL-PURPOSE MSG.               07105820
NOTINMSG EQU   *                                                        07107120
         L     R8,NA471CON    R8=1ST-LEVEL REMAINDER ADDR.              07108420
         BAL   R10,DSNMOVE    COMPLETE 1ST-LEVEL.                       07109720
         MVI   D19(R4),SEVNDDM MOVE IN UNIQUE ID.                       07111020
SEVNDDM  EQU   C'7'                                                     07112320
EXCALLER EQU   *                                                        07113620
         RETURN (14,12),RC=0  RETURN TO CALLER.                         07114920
         SPACE                                                          07116220
EXECUTE  EQU   *                                                        07117520
         EX    R3,SUPERMVC    MOVE TEXT ACCORDING TO LENGTH IN R3.      07118820
         LA    R5,D2(R3,R5)   INCREMENT TEXT POINTER REG.               07120120
         BR    R14            RETURN.                                   07121420
SUPERMVC MVC   D0(L1,R5),D0(R7)                                         07122720
         SPACE                                                          07124020
DSNMOVE  EQU   *                                                        07125320
         L     R6,DA08PDSN    R6=DSNAME BLOCK ADDR.                     07126620
         IC    R3,D1(R6)      R3=DSNAME LENGTH.                         07127920
         BCTR  R3,@0         *                                          07129220
         LA    R7,D2(R6)      R7=DSNAME TEXT ADDR.                      07130520
         BAL   R14,EXECUTE    MOVE TEXT.                                07131820
         IC    R3,D0(R8)      R3=REMAINDER LENGTH.                      07133120
         LA    R7,D1(R8)      R7=REMAINDER TEXT ADDR.                   07134420
         BAL   R14,EXECUTE    MOVE REMAINDER.                           07135720
         SR    R5,R11         COMPUTE LENGTH.                           07137020
         STH   R5,D0(R11)     STORE IN CONTROL WORD OF 1ST-LEVEL.       07138320
         BR    R10            RETURN.                                   07139620
         SPACE                                                          07140920
NA1CON   DC    V(IKJEGNM1)    MESSAGE ADDRESS CONSTANTS.                07142220
NA401CON DC    V(IKJEGNM2)                                              07143520
NA402CON DC    V(IKJEGNM3)                                              07144820
NA411CON DC    V(IKJEGNM4)                                              07146120
NA412CON DC    V(IKJEGNM5)                                              07147420
NA421CON DC    V(IKJEGNM6)                                              07148720
NA422CON DC    V(IKJEGNM7)                                              07150020
NA441CON DC    V(IKJEGNM8)                                              07151320
NA442CON DC    V(IKJEGNM9)                                              07152620
NA451ACN DC    V(IKJEGNMA)                                              07153920
NA451BCN DC    V(IKJEGNMB)                                              07155220
NA461CON DC    V(IKJEGNMC)                                              07156520
NA431CON DC    V(IKJEGNMD)                                              07157820
NA432ACN DC    V(IKJEGNME)                                              07159120
NA432BCN DC    V(IKJEGNMF)                                              07160420
NA432CCN DC    V(IKJEGNMH)                                              07161720
NA471CON DC    V(IKJEGNMG)                                              07163020
NA481CON DC    V(IKJEGNMI)                                              07164320
NA482CON DC    V(IKJEGNMJ)                                              07165620
NA491CON DC    V(IKJEGNMK)                                              07166920
NA491ACN DC    V(IKJEGNML)                                              07168220
NA491BCN DC    V(IKJEGNMM)                                              07169520
NA500CON DC    V(IKJEGNMN)                                              07170820
NA501CON DC    V(IKJEGNMO)                                              07172120
HALFRND  DC    X'FFFFFFFE'    HALF-WORD ROUNDING VALUE.                 07173420
TWO1C    DC    X'21C'         DARC RETURN CODE.                         07174720
TWO18    DC    X'218'         DITTO.                                    07176020
TWO10    DC    X'210'         DITTO.                                    07177320
TWO14    DC    X'214'         DITTO                                     07178620
THREE30  DC    X'330'         DITTO                                     07179920
THREE34  DC    X'334'         DITTO.                                    07181220
FOUR714  DC    X'4714'        DITTO                                     07182520
FOUR7    EQU   X'47'          DITTO                                     07183820
CODE4    DC    X'0004'        CTRC RETURN CODE                          07185120
CODE8    DC    X'0008'        CTRC RETURN CODE.                         07186420
CODEC    DC    X'000C'        DITTO.                                    07187720
CODE10   DC    X'0010'        DITTO.                                    07189020
TRTAB    DC    C'0123456789ABCDEF' HEX CONVERT TRANSLATE TABLE.         07190320
         SPACE                                                          07191620
D0       EQU   0                                                        07192920
D1       EQU   1                                                        07194220
D2       EQU   2                                                        07195520
D3       EQU   3                                                        07196820
D4       EQU   4                                                        07198120
D5       EQU   5                                                        07199420
D6       EQU   6                                                        07200720
D7       EQU   7                                                        07202020
D8       EQU   8                                                        07203320
D9       EQU   9                                                        07204620
D10      EQU   10                                                       07205920
D11      EQU   11                                                       07207220
D12      EQU   12                                                       07208520
D13      EQU   13                                                       07209820
D16      EQU   16                                                       07211120
D18      EQU   18                                                       07212420
D19      EQU   19                                                       07213720
D240     EQU   240                                                      07215020
         SPACE                                                          07216320
L1       EQU   1                                                        07217620
L2       EQU   2                                                        07218920
L3       EQU   3                                                        07220220
L4       EQU   4                                                        07221520
L5       EQU   5                                                        07222820
L6       EQU   6                                                        07224120
L7       EQU   7                                                        07225420
L8       EQU   8                                                        07226720
L155     EQU   155                                                      07228020
         SPACE                                                          07229320
         IKJDAP08                                                       07230620
DA08LEN  EQU  *-DAPB08       LENGTH OF DSECT                            07231920
         SPACE                                                          07233220
IKJEGDMG CSECT                                                          07234520
         ENTRY IKJEGNM1,IKJEGNM2,IKJEGNM3,IKJEGNM4,IKJEGNM5,IKJEGNM6    07235820
         ENTRY IKJEGNM7,IKJEGNMD,IKJEGNME,IKJEGNMF,IKJEGNM8,IKJEGNM9    07237120
         ENTRY IKJEGNMA,IKJEGNMB,IKJEGNMC,IKJEGNMG,IKJEGNMH,IKJEGNMI    07238420
         ENTRY IKJEGNMJ,IKJEGNMK,IKJEGNML,IKJEGNMM,IKJEGNMN,IKJEGNMO    07239720
         SPACE                                                          07241020
IKJEGNM1 DC    AL1(L'IKJ1-1)                                            07242320
IKJ1     DC    C'IKJ5744 I         DATA SET '                           07243620
IKJEGNM2 DC    AL1(L'IKJ40-1)                                           07244920
IKJ40    DC    C'NOT ALLOCATED, TOO MANY DATA SETS+'                    07246220
IKJEGNM3 DC    Y(END402,0),C'IKJ57440I USE FREE COMMAND TO FREE UNUSED C07247520
               DATA SETS'                                               07248820
END402   EQU   *-IKJEGNM3                                               07250120
IKJEGNM4 DC    AL1(L'IKJ41-1)                                           07251420
IKJ41    DC    C'NOT ALLOCATED+'                                        07252720
IKJEGNM5 DC    Y(END412,0),C'IKJ57441I INVALID UNIT IN USER ATTRIBUTE DA07254020
               ATA SET'                                                 07255320
END412   EQU   *-IKJEGNM5                                               07256620
IKJEGNM6 DC    AL1(L'IKJ42-1)                                           07257920
IKJ42    DC    C'NOT ALLOCATED, REQUIRED VOLUME NOT MOUNTED+'           07307920
IKJEGNM7 DC    Y(END422,0),C'IKJ57442I VOLUME NOR CVOL NOT ON SYSTEM AND07357920
               D CANNOT BE ACCESSED'                                    07407920
END422   EQU   *-IKJEGNM7                                               07457920
IKJEGNMD DC    AL1(L'IKJ43-1)                                           07507920
IKJ43    DC    C'NOT ALLOCATED, SYSTEM ERROR+'                          07557920
IKJEGNME DC    AL1(L'IKJ432A-1)                                         07607920
IKJ432A  DC    C'IKJ57443I DYNAMIC ALLOCATION ERROR CODE '              07657920
IKJEGNMF DC    AL1(L'IKJ432B-1)                                         07707920
IKJ432B  DC    C'IKJ57443I CATALOG ERROR CODE '                         07757920
IKJEGNMH DC    AL1(L'IKJ432C-1)                                         07767920
IKJ432C  DC    C'IKJ57443I DADSM ERROR CODE '                           07777920
IKJEGNM8 DC    AL1(L'IKJ44-1)                                           07807920
IKJ44    DC    C'ALREADY IN USE, TRY LATER+'                            07857920
IKJEGNM9 DC    Y(END442,0),C'IKJ57444I DATA SET IS ALLOCATED TO ANOTHERC07907920
                JOB OR USER'                                            07957920
END442   EQU   *-IKJEGNM9                                               08007920
IKJEGNMA DC    AL1(L'IKJ45A-1)  *                                       08057920
IKJ45A   DC    C'45I INVALID'                                           08107920
IKJEGNMB DC    AL1(L'IKJ45B-1)  *                                       08157920
IKJ45B   DC    C'EXCEEDS 44 CHARACTERS'                                 08207920
IKJEGNMC DC    Y(END461,0),C'IKJ57417I NO UNIT AVAILABLE'               08257920
END461   EQU   *-IKJEGNMC                                               08357920
IKJEGNMG DC    AL1(L'IKJ47-1)  *                                        08407920
IKJ47    DC    C'NOT IN CATALOG'                                        08457920
IKJEGNMI DC    AL1(L'IKJ48-1)                                           08467920
IKJ48    DC    C'NOT ALLOCATED, NOT ENOUGH SPACE ON VOLUMES+'           08477920
IKJEGNMJ DC    Y(END482,0),C'IKJ57418I USE DELETE COMMAND TO DELETE UNUS08487920
               SED DATA SETS'                                           08499920
END482   EQU   *-IKJEGNMJ                                               08501920
IKJEGNMK DC    AL1(L'IKJ49-1)                                           08503920
IKJ49    DC    C'IKJ57411I MEMBER '                                     08505920
IKJEGNML DC    AL1(L'IKJ49A-1)                                          08506320
IKJ49A   DC    C' SPECIFIED BUT '                                       08506720
IKJEGNMM DC    AL1(L'IKJ49B-1)                                          08507120
IKJ49B   DC    C' NOT A PARTITIONED DATA SET'                           08507520
IKJEGNMN DC    Y(END500,0),C'IKJ57413I COMMAND SYSTEM ERROR+'           08507620
END500   EQU   *-IKJEGNMN                                               08507720
IKJEGNMO DC    AL1(L'IKJ50-1)                                           08537720
IKJ50    DC    C'IKJ57413I DAIR ERROR CODE '                            08567720
         END                                                            08607820
