         TITLE 'TEST LOADER       IKJEGLDR'                             00200020
*********************************************************************** 00400020
*                                                                       00600020
* STATUS --                                                             00650020
*    VERSION NO. 01, OS/360 RELEASE NO. 21                              00700020
*                                                                       00750020
* FUNCTION --                                                           00800020
*    THIS MODULE IS ATTACHED AS A SUB-TASK OF THE TEST CONVERSA-        01600020
*    TIONAL DEBUGGING PACKAGE OF TSO.THE ATTACH IS ISSUED BY            01800020
*    IKJEGINT.IKJEGLDR ANALYZES THE PARAMETERS RETURNED BY THE          02000020
*    PARSE ROUTINE.IF 'LOAD' WAS SPECIFIED,THE PROGRAM TO BE TEST-      02200020
*    ED IS BROUGHT INTO STORAGE VIA CONTENTS SUPERVISION.IF 'OB-        02400020
*    JECT' WAS SPECIFIED,THE PROGRAM IS BROUGHT IN VIA THE OS LOAD-     02600020
*    ER.PARAMETER LISTS ARE BUILT FOR THE PROGRAM, THE FORMAT AP-       02800020
*    PROPRIATE TO A COMMAND OR NON-COMMAND ACCORDING AS 'CP' OR         03000020
*    'NOCP' WAS SPECIFIED.                                              03200020
*                                                                       03250020
*    AFTER ALL THIS HAS BEEN DONE IKJEGLDR WILL 'XCTL' TO THE           03300020
*    USER REQUESTED PROGRAM.                                            03360020
*                                                                       03400020
* ENTRY POINTS --                                                       03600020
*    IKJEGLDR                                                           04000020
*                                                                       04200020
* INPUT --                                                              04400020
*    TEST COMMUNICATION TABLE POINTED TO BY REGISTER 1.                 04800020
*                                                                       04810020
*    TPL POINTED TO BY TPLPTR IN TCOMTAB                                04850020
*                                                                       04860020
*    THE DCB OPENED BY IKJEGINT IS HUNG FROM TSTDCB IN TCOMTAB          04900020
*                                                                       04910020
*    THE BLDL ENTRY GOTTEN BY IKJEGINT IS LOCATED AT BLDLAREA           04950020
*    BLDLAREA IS EQUATED TO CONAREA IN TCOMTAB                          05000020
*                                                                       05010020
*    THE PDL(PARAMETER DISCRIPTOR LIST) IS PASSED AT TSTANSPL           05050020
*    IN TCOMTAB                                                         05100020
*                                                                       05150020
* OUTPUT --                                                             05200020
*    REGISTER 1 POINTS TO THE PARAMETER LIST BUILT FOR THE PROGRAM      05600020
*    TO BE TESTED.                                                      05800020
*                                                                       06000020
* EXTERNAL REFERENCES --                                                06200020
*         IKJEGIO- TO WRITE DIAGNOSTIC MESSAGES TO THE TERMINAL IN      07000020
*         THE CASE OF ERROR.                                            07200020
*                                                                       07400020
* EXITS, NORMAL --                                                      07600020
*         XCTL TO THE EPA OF THE PROGRAM TO BE TESTED.                  08200020
*                                                                       08800020
* EXITS, ERROR --                                                       09000020
*         RETURN VIA REGISTER 14.                                       09400020
*                                                                       09600020
* TABLES/WORKAREAS --                                                   09650020
*    TCOMTAB POINTED TO BY REG 9, IS TEST'S COMMUNICATION TABLE         09700020
*                                                                       09710020
*    TPL POINTED TO BY REGISTER 10 IS THE TEST PARAMETER LIST           09750020
*                                                                       09760020
*    PDL POINTED TO BY TSTANSPL IN TCOMTAB                              09770020
*                                                                       09780020
*    WORKAREA POINTED TO BY TCOMTAB IS THE GENERAL W.A. FOR ALL OF TEST 09790020
*                                                                       09792020
* ATTRIBUTES --                                                         09800020
*    RE-ENTRANT                                                         10200020
*    REFRESHABLE                                                        10400020
*                                                                       10600020
* CHARACTER CODE DEPENDENCY --                                          10650020
*    NONE                                                               10700020
*                                                                       10750020
* NOTES --                                                              10760020
*    REGISTER CONVENTIONS FOR LOADER ARE AS FOLLOWS                     10770020
*    REG 9  TCOMTAB POINTER                                             10780020
*    REG 10 TPL POINTER                                                 10790020
*    REG 11 ONLY USED FOR LINK REGISTER                                 10792020
*    REG 12 IS THE BASE REGISTER                                        10794020
*                                                                       10796020
*********************************************************************** 10800020
         EJECT                                                          11000020
IKJEGLDR CSECT                                                          11200020
*RELEASE 21 CHANGES                                                     11250020
*A112500,113000,113500,113600,272500,284500,356100-357600,484500 A50991 11350020
*A490500,610500,610600                                           A50991 11360020
*                                                                       11400020
         SAVE  (14,12),,*                                               11600020
         BALR  R12,X0         PROGRAM ADDRESSABILITY.                   11800020
         USING *,R12          *                                         12000020
         LR    R9,R1          R9=TCOMTAB ADDRESS.                       12200020
         USING TCOMTAB,R9     TCOMTAB ADDRESSABILITY.                   12400020
         USING ECT,R2         ECT ADDRESSABILITY.                       12600020
         L     R8,TSTANSPL    R8=ADDR OF PASSED PDL.                    12800020
         USING IKJPARMD,R8    *                                         13000020
         LR    R4,R13         R4=BACK POINTER.                          13200020
         L     R13,REGSAVE2   R13=NEW REGSAVE AREA ADDR.                13400020
         ST    R4,X4(R13)     STORE BACK POINTER IN NEW AREA.           13600020
         ST    R13,X8(R4)     STORE FORE POINTER IN OLD AREA.           13800020
         L     R3,CVT         GET CVT ADDRESS                           14000020
CVT      EQU   16             CVT POINTER                               14200020
         L     R4,X0(R3)      GET TCB WORDS ADDRESS                     14400020
         L     R7,X4(R4)      GET CURRENT TCB ADDRESS                   14600020
         ST    R7,PPTCB       INITIALIZE THE PPTCB IN TCOMTAB           14800020
         L     R10,TPLPTR     GET TPL ADDRESS                           15000020
         USING TPL,R10         TPL ADDRESSABILITY                       15200020
         ST    R7,TPLCTCB     INITIALIZE TPL ATTACHED TCB SLOT          15400020
         L     R2,TPLECT      ECT POINTER.                              15600020
         XC    ECTRCDF(X2),ECTRCDF  ZERO RETURN CODE.                   15800020
         SPACE                                                          15830020
*        IF LOAD KEYWORD SPECIFIED, THEN FETCH WILL LOAD.               15860020
*        ELSE, IT WAS OBJECT WHICH WAS SPECIFIED, IN WHICH CASE         15890020
*        THE OSLOADER IS USED TO DUE THE LOAD.                          15920020
         SPACE                                                          15950020
         CLI   LOADOBJ+X1,LOAD Q.IS 'LOAD' SPECIFIED.                   16000020
LOAD     EQU   1              *                                         16200020
         BNE   OSLOAD         NO,USE OS LOADER.                         16400020
*                             YES,USE PROGRAM FETCH.                    16600020
         L     R4,TSTDCB      GET THE DCB ADDRESS - 4                   16800020
         LA    R4,X4(R4)      GET THE DCB ADDRESS.                      17000020
         L     R5,BLDLAREA    GET THE BLDL ENTRY ADDRESS.               17200020
DCBLEN   EQU   96             DCB LENGTH                                17400020
         L     R2,TPLECT      ECT POINTER.                              17600020
         MVC   ECTPCMD(X8),X4(R5)  PUT MEMBER NAME IN ECT.              17800020
         SPACE                                                          17840020
*        WAS CP SPECIFIED, IF YES THEN PROMPT FOR THE COMMAND.          17880020
*        IF NO, THEN PROCEED.                                           17920020
         SPACE                                                          17960020
PARMSET  EQU   *                                                        18000020
         CLI   CPNOCP+X1,CP    Q.IS 'CP' SPECIFIED.                     18200020
CP       EQU   1              COMMAND PROCESSOR                         18400020
         BE    CMDPRMPT       YES,REQUEST A COMMAND.                    18600020
         SPACE                                                          18640020
*        IF A PARM STRING WERE ENTERED, GET A BUFFER AND FILL IT.       18680020
*        OTHERWISE , PROCEED                                            18720020
         SPACE                                                          18760020
         NC    STRING+X1(X3),STRING+X1  PARM STRING SPECIFIED Q.        18800020
         BNZ   PARMSTRG       YES,SET UP PARMS.                         19000020
         GETMAIN R,LV=8       GET STORAGE FOR PARMLIST.                 19200020
         LA    R3,X4(R1)      PARMS ADDR.                               19400020
         SR    R4,R4          EMPTY LIST.                               19600020
         O     R3,HIGHBIT     INDICATE LAST ELEMENT OF LIST.            19800020
         STM   R3,R4,X0(R1)   INITIALIZE EMPTY LIST                     20000020
         LR    R7,R1          SAVE THE PARAMETER LIST ADDRESS.          20200020
GOPP     EQU   *                                                        20400020
         BAL   R11,SETTRN     TCBTCP BIT=1 TCBTRNB=TCOMTAB ADDRESS.     20600020
         L     R2,TPLECT      ECT POINTER.                              20800020
         LA    R3,ECTPCMD     POINTER TO THE MEMBER NAME.               21000020
         L     R4,TSTTCB       THIS IS THE JOB STEP TCB.                21200020
         SPACE                                                          21220020
*        IF THE MODULE IS ALREADY IN CORE , SET A PSUEDO BREAKPT.       21240020
*        IF IT IS NOT IN CORE , WHICH IS THE 99.9999 PERCENT CASE,      21260020
*        THE BREAK POINT WILL BE SET BY THE IKJEGINT MODULE             21280020
*        AFTER BEING POSTED BY SVC 61.                                  21300020
         SPACE                                                          21320020
         L     R1,TCBJPQ-TCB(R4)  FIRST CDE.                            21400020
CDELOOP  EQU   *                                                        21600020
         LA    R1,X0(R1)      CLEAR THE HIGH BYTE.                      21800020
         LTR   R1,R1          IS IT THE END OF CDE'S                    22000020
         BZ    LLSLOOK        LOOK ON THE LOAD LIST...                  22200020
         CLC   CDENAME(X8,R1),X0(R3)  CHECK THE NAME.                   22400020
         BE    SETPSEUD          FOUND A MATCH.                         22600020
         L     R1,CDENEXT(R1)   GET THE NEXT CDE ADDRESS.               22800020
         B     CDELOOP        LOOP.......                               23000020
LLSLOOK  EQU   *                                                        23200020
         L     R1,TCBLLS-TCB(R4)  GET LOAD LIST BEGIN.                  23400020
LLSLOOP  EQU   *                                                        23600020
         LTR   R1,R1          CHECK FOR END OF LOAD LIST.               23800020
         BZ    OUT            NOFIND GET OUT.                           24000020
         LM    R1,R2,LLSNE(R1)  R1=NEXT ENTRY...R2=CDE PTR.             24200020
         CLC   CDENAME(X8,R2),X0(R3)  SEE IF NAME IS IN CORE.           24400020
         BNE   LLSLOOP        NO FIND LOOP.....                         24600020
         LR    R1,R2          CDE ADDRESS TO R1.                        24800020
SETPSEUD EQU   *              *                                         25000020
         L     R2,CDEEPA(R1)  GET THE ENTRY POINT.                      25200020
         MVC   TSTGO(X2),X0(R2)  SAVE THE INSTR.                        25400020
         MVC   X0(X2,R2),SVC  SET THE PSEUDO BREAK POINT.               25600020
OUT      EQU   *                                                        25800020
         L     R15,WORKAREA   ADDR OF XCTL LIST FORM FOR XCTL.          26000020
         MVC   X0(XCTLLEN,R15),XCTLFORM  *                              26200020
         OI    TSTFLGS3,TSTGOSW    SET SPECIAL PSEUDO BP SWITCH.        26400020
         CLI   LOADOBJ+X1,LOAD  LOAD OR OBJECT...                       26600020
         LR    R1,R7          PARMAMETER LIST TO REGISTER ONE...        26800020
         L     R13,X4(R13)    FIX UP REGISTER 13 FOR PP                 27000020
         BNE   XCTLOBJ        OBJECT...                                 27200020
         BAL   R14,ATNCHK     GO SEE IF AN ATTENTION WAS POSTED  A50991 27250020
         L     R4,TSTDCB      GET THE DCB ADDRESS - 4                   27400020
         LA    R4,X4(R4)      GET THE DCB ADDRESS.                      27600020
         L     R5,BLDLAREA    GET THE BLDL ENTRY ADDRESS.               27800020
         LA    R5,X4(R5)           OFFSET INTO BLDL ENTRY.              28000020
         XC    N28(N44,R13),N28(R13)  ZERO REGS FOR PROTECTION.         28100020
         XCTL  (2,12),DCB=(4),DE=(5),SF=(E,(15))                        28200020
XCTLOBJ  EQU   *                                                        28400020
         BAL   R14,ATNCHK     GO SEE IF AN ATTENTION WAS POSTED  A50991 28450020
         XC    N28(N44,R13),N28(R13)  ZERO REGS FOR PROTECTION.         28500020
         XCTL  (2,12),EPLOC=(3),SF=(E,(15))                             28600020
         SPACE                                                          28800020
         SPACE                                                          29000020
CMDPRMPT EQU   *                                                        29200020
*        REQUEST A COMMAND FOR THE PROGRAM BEING TESTED.                29400020
         SPACE                                                          29600020
         LA    R1,CMDCON      R1=ADDR OF MESSAGE POINTERS.              29800020
         BAL   R11,TPG        'ENTER COMMAND FOR CP'                    30000020
         SPACE                                                          30200020
*        BUILD PARMLIST FOR COMMAND SCAN SERVICE ROUTINE AND SCAN THE   30400020
*        VERB FIELD OF THE COMMAND RECEIVED FROM THE TERMINAL.          30600020
         GETMAIN R,LV=16      GET CORE FOR CPPL                         30800020
         LR    R7,R1          SAVE ADDRESS.                             31000020
         USING CPPL,R7        *                                         31200020
         SPACE                                                          31400020
         L     R1,WORKAREA    R1=ADDR OF PARM LIST.                     31600020
         MVC   X0(N12,R1),PARMLIST MOVE IN STANDARD PARMS.              31800020
         LA    R2,N24(,R1)    R2=FLAG WORD ADDR.                        32000020
         LA    R3,N28(,R1)    R3=OUTPUT AREA ADDR.                      32200020
         L     R4,INBUF       CPPL COMMAND BUFFER =IN BUFFER.           32400020
         ST    R4,CPPLCBUF     INITIALIZE CPPL.                         32600020
         MVC   CPPLUPT(N12),TPLUPT  DITTO.                              32800020
         SR    R5,R5          FLAG WORD.                                33000020
         STM   R2,R5,N12(R1)   MOVE IN FLAG & OUTPUT AREA ADDRS.        33200020
         ST    R5,INBUF       CLEAR TEST'S INPUT BUFFER POINTER.        33400020
         OI    X0(R2),NOSYNTAX INDICATE 'NO SYNTAX CHECK'.              33600020
NOSYNTAX EQU   X'80'          NO SYNTAX CHECK                           33800020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT       34000020
         LINK  EP=IKJSCAN     SCAN VERB FIELD OF COMMAND.               34200020
         L     R2,TPLECT      ECT POINTER.                              34400020
         NI    ECTSWS,XFF-ECTNOPD  TURN OFF PARM SW.                    34600020
         TM    X6(R3),X40     Q.COMMAND NAME W/NO FIELDS.               34800020
         BZ    SKIP           SWITCH OFF.                               35000020
         OI    ECTSWS,ECTNOPD  TURN SWITCH ON.                          35200020
SKIP     EQU   *              *                                         35400020
         B     GOPP           PLACE PSEUDO-BREAK & ENTER PP.            35600020
ATNCHK   EQU   *                                                 A50991 35610020
         L     R4,ECBTMPA     GET ADDRESS OF ATTENTION ECB.      A50991 35650020
         TM    ZERO(R4),ATTNBIT HAS AN ATTENTION BEEN POSTED     A50991 35700020
         BO    RET4           IF SO, LET'S GET OUT OF HERE       A50991 35750020
         BR    R14            OTHERWISE, RETURN TO CALLER        A50991 35760020
         SPACE                                                          35800020
PARMSTRG EQU   *                                                        36000020
*        SET UP SPECIFIED PARM STRING AS POINTED TO FROM A STANDARD     36200020
*        VARIABLE LIST.                                                 36400020
         SPACE                                                          36600020
         L     R4,STRING      R4=ADDR OF CHARACTER STRING.              36800020
         LH    R2,STRING+X4    R2=LENGTH OF STRING.                     37000020
         CL    R2,AHUNDRED    DOES IT EXCEED MAXIMUM Q.                 37200020
         LA    R1,HUNMSG      'STRING EXCEEDS MAX LENGTH'               37400020
         BH    PUTRTURN       PUT W/RETURN...RC=0                       37600020
         LA    R0,X6(,R2)     R0=LENGTH OF STRING & POINTER.            37800020
         GETMAIN R,LV=(0)     GET STORAGE FOR LIST AND STRING.          38000020
         LA    R3,X4(,R1)     R3=ADDR FOR PASSED PARM STRING.           38200020
         STH   R2,X4(R1)      MOVE LENGTH TO PARMS.                     38400020
         BCTR  R2,X0          DECREMENT FOR EXECUTE.                    38600020
         EX    R2,STRMVC      MOVE THE STRING.                          38800020
         O     R3,HIGHBIT     INDICATE LAST LIST ELEMENT.               39000020
         ST    R3,X0(,R1)     STORE PARM POINTER IN LIST.               39200020
         LR    R7,R1          SAVE THE PARAMETER LIST ADDRESS.          39400020
         B     GOPP           PLACE PSEUDO-BREAK, ENTER PP.             39600020
         SPACE                                                          39800020
STRMVC   MVC   X6(X0,R1),X0(R4)         *                               40000020
         SPACE                                                          40200020
OSLOAD   EQU   *                                                        40400020
*        SET UP PARM LIST AND DDNAME LIST FOR OS LOADER.LOAD THE        40600020
*        PROCESSING PORTION OF THE LOADER,BRANCH TO IT AND DELETE       40800020
*        IT UPON ITS RETURN.                                            41000020
         SPACE                                                          41200020
         GETMAIN  R,LV=OBJCORE  GET CORE FOR OSLOAD PARMS               41400020
         LA    R2,X8(R1)      OPTION LIST ADDRESS.                      41800020
         LA    R3,OPTCORE(R2)  POINT BEYOND OPTIONS                     42000020
         O     R3,HIGHBIT     INDICATE LAST ELEMENT.                    42200020
         MVC   X0(OPTLN,R2),OPTIONS MOVE IN OPTIONS.                    42400020
         XC    X0(N98,R3),X0(R3) CLEAR DDNAME LIST.                     42600020
         MVC   N98-X8(X8,R3),TERMDD  PLACE DDNAME INTO LIST             42800020
         MVI   X1(R3),N96     DDNAME LIST LENGTH.                       43000020
         MVC   X2(X8,R3),TSTCURLD MOVE DDNAME TO SYSLIN SLOT IN LIST.   43200020
         STM   R2,R3,X0(R1)    INITIALIZE LIST.                         43400020
         LR    R2,R1          SAVE LIST ADDR.                           43600020
         LOAD  EP=IEWLOAD      LOAD THE OS LOADER.                      43800020
         LR    R15,R0         R15=0S LOADER ENTRY POINT.                44000020
         LR    R1,R2          R1=LIST ADDR.                             44200020
         BALR  R14,R15        ENTER THE OS LOADER TO LOAD THE           44400020
*                             PROGRAM TO BE TESTED.                     44600020
         C     R15,FOUR       Q.IS PROGRAM SUCCESSFULLY LOADED.         44800020
         BH    RET0           NO. DEPART.                               45000020
         LR    R3,R1          SAVE NAME POINTER IN R3.                  45200020
         DELETE EP=IEWLOAD     DELETE THE OS LOADER.                    45400020
         LR    R1,R2          R1=ADDR OF STORAGE GOTTEN FOR LOADER.     45600020
         FREEMAIN  R,LV=OBJCORE,A=(1)  FREE THE PARM CORE               45800020
         SPACE                                                          46000020
*        ISSUE A LOAD FOR THE PROGRAM BROUGHT IN BY THE OS LOADER       46200020
*        IN ORDER TO GET IT ON THE LOAD LIST.SAVE THE PROGRAM NAME      46400020
*        IN TSTCURLD OF TCOMTAB AND SET UP PARAMETERS REQUIRED BY       46600020
*        THE PROGRAM.                                                   46800020
         SPACE                                                          47000020
         L     R2,TPLECT      ECT POINTER.                              47200020
         MVC   ECTPCMD(X8),X0(R3)  PUT MEMBER NAME IN ECT.              47400020
         B     PARMSET        SET UP PARAMETERS FOR THE PROGRAM.        47600020
SETTRN   EQU   *              TCBTCP BIT=1,TCBTRNB=TCOMTAB ADDR.        47800020
         LR    R1,R9          TCOMTAB ADDR.                             48000020
         L     R0,PPTCB       OUR TCB ADDRESS...                        48200020
         O     R0,TCBTRNFL    TCBTRNB=TCOMTAB ADDRESS.                  48400020
         BAL   R14,ATNCHK     GO SEE IF AN ATTENTION WAS POSTED  A50991 48450020
         SVC   TESTSVC        DITTO                                     48600020
         L     R0,PPTCB       OUR TCB ADDRESS...                        48800020
         O     R0,TSTCPON     TCBTCP BIT=1.                             49000020
         BAL   R14,ATNCHK     GO SEE IF AN ATTENTION WAS POSTED  A50991 49050020
         SVC   TESTSVC        DITTO                                     49200020
         BR    R11            RETURN.                                   49400020
RET4     LA    R15,X4         RC=4                                      49600020
         B     RETURN         RETURN.                                   49800020
RET0     SR    R15,R15        RC=0                                      50000020
RETURN   EQU   *              RETURN.                                   50200020
         L     R13,X4(R13)     ADDRESS OF REGSAVE AREA                  50400020
         RETURN (14,12),RC=(15)  RETURN.                                50600020
PUTRTURN EQU   *              PRINT W/RETURN RC=0                       50800020
         LA    R11,RET0       R11 NORMALLY A LINK REG.                  51000020
TPUT     EQU   *              *                                         51200020
         LCR   R1,R1          COMPLIMENT FOR MESSAGE.                   51400020
         L     R15,TPUTADDR   PUT A LINE.                               51600020
         B     TGO            SKIP TO BALR.                             51800020
TPG      EQU   *              PUT/GET                                   52000020
         L     R15,TPUTGET    DITTO.                                    52200020
TGO      EQU   *              *                                         52400020
         BALR  R14,R15        GO TO 'IO'                                52600020
         C     R15,IOGOOD     SUCCESS Q.                                52800020
         BH    RET4           RETURN WITH A CODE OF 4.                  53000020
         BR    R11            RETURN.                                   53200020
         EJECT                                                          53240020
         SPACE                                                          53280020
*        EQUATES AND CONSTANTS                                          53320020
         SPACE                                                          53360020
X0       EQU   0              HEXIDECIMAL 0                             53400020
X1       EQU   1              HEXIDECIMAL 1                             53600020
X2       EQU   2              HEXIDECIMAL 2                             53800020
X3       EQU   3              HEXIDECIMAL 3                             54000020
X4       EQU   4              HEXIDECIMAL 4                             54200020
X5       EQU   5              HEXIDECIMAL 5                             54400020
X6       EQU   6              HEXIDECIMAL 6                             54600020
X7       EQU   7              HEXIDECIMAL 7                             54800020
X8       EQU   8              HEXIDECIMAL 8                             55000020
X9       EQU   9              HEXIDECIMAL 9                             55200020
N12      EQU   12             TWELVE.                                   55400020
N15      EQU   15             FIFTEEN.                                  55600020
BLANK    EQU   X'40'          BLANK.                                    55800020
X40      EQU   X'40'          HEXIDECIMAL '40'                          56000020
XFF      EQU   X'FF'          HEXIDECIMAL 'FF'                          56200020
N22      EQU   22             TWENTY TWO.                               56400020
N24      EQU   24             TWENTY FOUR.                              56600020
N25      EQU   25             TWENTY FIVE.                              56800020
N28      EQU   28             TWENTY EIGHT.                             57000020
N44      EQU   44             FORTY FOUR.                               57100020
N48      EQU   48             FORTY EIGHT.                              57200020
N50      EQU   50             FIFTY.                                    57400020
N96      EQU   96             NINETY SIX.                               57600020
N98      EQU   98             NINETY EIGHT.                             57800020
XCTLFORM XCTL  EP=XCTLFORM,SF=L                                         58000020
XCTLLEN  EQU   *-XCTLFORM     *                                         58200020
OPTIONS  DS    0F             ROUND TO FULL WORD                        58400020
         DC    AL2(OPTLN-2)   LENGTH OF LIST.                           58600020
         DC    C'TERM,NOPRINT,NCAL,NOMAP,NORES,LET,NAME=TEMPNAME'      *58700020
               OSLOADER PARAMETERS                                      58800020
OPTLN    EQU   *-OPTIONS                                                59000020
OPTLN1   DS    0F             ROUND TO FULL WORD                        59050020
OPTCORE  EQU   OPTLN1-OPTIONS  OPTIONS CORE REQUIREMENT                 59100020
OBJCORE  EQU   8+OPTCORE+12*8  TOTAL PARAMETER CORE FOR OSLOADER        59150020
MINORBIT EQU   X'04'          MINOR BIT IN CDE ATTR 1.                  59200020
LLSNE    EQU   0              *                                         59400020
LLSCDE   EQU   4              DISPLACEMENT INTO LLS.                    59600020
CDEATR1  EQU   0              DISPLACEMENT INTO CDE.                    59800020
CDENEXT  EQU   0              NEXT CDE ADDR.                            60000020
CDENAME  EQU   8              CDE NAME.                                 60200020
CDEEPA   EQU   16             CDE NAME.                                 60400020
CDEATR2  EQU   20             CDE ATTRIBUTE 2.                          60600020
CDEXLMJ  EQU   20             DISPLACEMENT INTO CDE.                    60800020
XLADR    EQU   12             DISPLACEMENT INTO EXTENT LIST.            61000020
ATTNBIT  EQU   B'01000000'    TO TEST IF ATTENTION HAS           A50991 61050020
ZERO     EQU   0              BEEN POSTED                        A50991 61060020
AHUNDRED DC    A(100)         *                                         61200020
FOUR     DC    F'4'           FOUR                                      61400020
IOGOOD   EQU   FOUR           CONDITION CODE OF 4                       61600020
HIGHBIT  DC    X'80000000'    HIGH ORDER BIT                            61800020
TSTCPON  DC    X'40000000'    INDICATE TCBTST 'ON'                      62000020
TCBTRNFL DC    X'10000000'    CHANGE THE TCBTRN FIELD                   62200020
CMDCON   DC    A(CMDMSG,0)    'ENTER COMMAND FOR CP'                    62500020
HUNMSG   DC    A(HUNMSG1,HUNMSG2)  'STRING EXCEEDS LENGTH OF 100'       62800020
SVC      SVC   TESTSVC        SVC INSTRUCTION TO BE PLACED IN PP.       63200020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT       63400020
TESTSVC  EQU   97             TEST'S SVC                                63600020
         EJECT                                                          63640020
         SPACE                                                          63680020
*        PARSE CONSTANTS AND DSECT                                      63720020
         SPACE                                                          63760020
         SPACE                                                          63800020
IKJEGYDR IKJPARM                                                        64000020
DSNAME   IKJPOSIT DSNAME                                                64200020
STRING   IKJPOSIT QSTRING                                               64400020
LOADOBJ  IKJKEYWD                                                       64600020
         IKJNAME 'LOAD'                                                 64800020
         IKJNAME 'OBJECT'                                               65000020
CPNOCP   IKJKEYWD                                                       65200020
         IKJNAME 'CP'                                                   65400020
         IKJNAME 'NOCP'                                                 65600020
         IKJENDP                                                        65800020
         SPACE                                                          66000020
         TCOMTAB                                                        66200020
BLDLAREA EQU   CONAREA        BLDL ENTRY ADDRESS.                       66400020
TERMDD   EQU   TSTCONVT       DD NAME ALLOCATED TO SYSTERM.             66600020
         SPACE                                                          66800020
         IKJCPPL                                                        67000020
         SPACE                                                          67200020
         IKJECT                                                         67400020
         SPACE                                                          67600020
         IKJTPL                                                         67800020
         SPACE                                                          68000020
         IKJTCB                                                         68200020
         SPACE                                                          68400020
         REGEQU                                                         68600020
         SPACE                                                          68800020
IKJEGXDR CSECT                MESSAGES FOR IKJEGLDR.                    69000020
         DS    0H                                                       69600020
HUNMSG1  DC    AL2(HUNMSG1L,0) *                                        69800020
         DC    C'IKJ05708I PARAMETER STRING LENGTH EXCEEDED'   *        70000020
HUNMSG1L EQU   *-HUNMSG1      *                                         70200020
         DS    0H                                                       70400020
HUNMSG2  DC    AL2(HUNMSG2L,0) *                                        70600020
         DC    C'IKJ05708I MAX. LENGTH IS 100'    *                     70800020
HUNMSG2L EQU   *-HUNMSG2      *                                         71000020
         DS    0H                                                       71200020
CMDMSG   EQU   *                                                        71400020
         DC    AL2(LAST-CMDMSG) MESSAGE LENGTH.                         71600020
         DC    2X'00'         CURRENT OFFSET (NOT USED).                71800020
         DC    C'IKJ057090A ENTER COMMAND FOR CP' *                     72000020
LAST     EQU   *                                                        72200020
         END                                                            72400020
