         TITLE 'IKJEGLSA, ''LIST'' SUBCOMMAND OF TEST, SECOND LOAD'     00060020
*********************************************************************** 00120020
*                                                                       00360020
* STATUS --                                                             00370020
* RELEASE 21 CHANGES:                                                   00382021
*  APAR #45476                                                          00382421
*   D565200 D569300 D570500-571200 D572400 D573600-583800 D595121       00384021
*   C564600 C569400 C570600 C576000                                     00386021
*   A562700 A569900-569920 A570520 A571100 A573500-575600 A576500-      00388021
*   577000 A595000-595100 A595123-595125                                00388421
*                                                                       00390020
* FUNCTION --                                                           00420020
*    THIS MODULE IS THE SECOND LOAD OF IKJEGLST, THE LIST SUBCOMMAND.   00430020
*    IT IS ENTERED WHEN THE OUTPUT TYPE IS ONE OF THE FOLLOWING- A, B,  00440020
*    C, D, E, F, H, I, L, P, Q, S, V, Y, OR Z.  THE ROUTINE CALLS       00450020
*    IKJEGCVT TO CONVERT THE DATA (EXCEPT FOR CHARACTER, BINARY, OR     00460020
*    ZONED FORMATS WHICH ARE DONE WITHIN THIS MODULE), FORMATS THE      00470020
*    DATA IN THE BUFFER, AND GOES TO IKJEGIO TO OUTPUT THE DATA. THIS   00480020
*    MODULE LISTS AREAS OF CORE IN ONE OF THE ABOVE NAMED FORMATS.      00490020
*                                                                       00892020
* ENTRY POINTS --                                                       00900020
*         IKJEGLSA  MAIN ENTRY PT, ENTERED BY XCTL FROM IKJEGLST        00960020
*                                                                       00970020
* INPUT --                                                              01020020
*    REG 1 POINTS TO A 2 WORD LIST, THE FIRST WORD IS A POINTER TO      01030020
*    THE CURRENT ADDRESS PDE AND THE SECOND WORD IS A POINTER TO THE    01040020
*    'LSTWORK' DSECT WHICH HAS ALREADY BEEN INITIALIZED.                01050020
*    REG 9 CONTAINS THE ADDRESS OF 'TCOMTAB', THE COMMUNICATIONS DSECT  01060020
*                                                                       01140020
* OUTPUT --                                                             01200020
*    LINES TO THE TERMINAL DISPLAYING REQUESTED DATA OR, IF THE PRINT   01270020
*    KEYWORD HAS BEEN SPECIFIED, THE REQUESTED DATA IS WRITTEN TO THE   01280020
*    DESIGNATED DATA SET.                                               01290020
*                                                                       01320020
* EXTERNAL REFERENCES --                                                01380020
*         IKJEGCVT  FOR CONVERSION OF ADDRESSES AND DATA FROM MACHINE   01390020
*         FORMAT TO PRINTABLE FORMAT. FOR CONVERSION OF ADDRESSES,      01400020
*         CVT IS ENTERED WITH THE HIGH ORDER BIT OF REG 0 SET TO ONE    01410020
*         AND REGISTER 1 CONTAINING THE COMPLEMENT OF THE ADDRESS OF    01420020
*         AN ADDRESS PDE. THE ADDRESS PDE DESCRIBES THE ADDRESS TO BE   01430020
*         CONVERTED.  FOR DATA CONVERSIONS, REG 0 IS SET TO ZERO, AND   01431020
*         REG 1 CONTAINS THE ADDRESS OF A VALUE PDE DESCRIBING THE      01432020
*         TO BE CONVERTED.                                              01433020
*                                                                       01434020
*         IKJEGIO  TO OUTPUT DATA TO THE TERMINAL OR TO A PRINT DATA    01435020
*         SET, AND TO OUTPUT MESSAGES TO THE TERMINAL. TO OUTPUT DATA,  01436020
*         REG 1 CONTAINS THE ADDRESS OF A 2 WORD LIST. THE FIRST WORD   01437020
*         CONTAINS THE ADDRESS OF A DATA BUFFER AND THE SECOND WORD     01438020
*         CONTAINS BINARY ZEROS. FOR MESSAGES, REG 1 CONTAINS THE       01439020
*         COMPLEMENT OF THE ADDRESS OF A 2 WORD LIST. THE FIRST WORD    01439120
*         HAS A POINTER TO THE FIRST LEVEL MESSAGE AND THE SECOND WORD  01439220
*         HAS A POINTER TO THE SECOND LEVEL MESSAGE OR IS BINARY ZEROS  01439320
*                                                                       01680020
* EXITS, NORMAL --                                                      01690020
*         BR 14  TO THE ORIGINAL CALLER OF IKJEGLST WHEN THE LAST       01700020
*         ADDRESS PDE HAS BEEN PROCESSED.                               01710020
*         XCTL  TO IKJEGLST IF THE NEXT ADDRESS IN A LIST OF ADDRESSES  01720020
*         IS REGISTER TYPE, OR IF THE FORMAT TYPE IS HEX (X).           01730020
*                                                                       01980020
* EXITS, ERROR --                                                       02050020
*         NONE                                                          02060020
*                                                                       02100020
* TABLES/WORK AREAS --                                                  02160020
*    TCOMTAB  POINTED AT BY REG 9, IS THE COMMUNICATIONS TABLE FOR THE  02170020
*    TEST PROCESSOR.                                                    02180020
*                                                                       02181020
*    LSTWORK  THE MAPPING DSECT FOR THE WORK AREA USED BY IKJEGLST AND  02190020
*    IKJEGLSA. IT HOLDS WORKING COPIES OF THE ATTRIBUTES, ADDRESSES     02200020
*    FOR THE DATA CURRENTLY BEING LISTED, PARAMETER LISTS FOR CALLING   02210020
*    VARIOUS ROUTINES, AND A DATA BUFFER FOR REMOVING BREAKPOINT SVC'S  02211020
*                                                                       02211120
*    PARAMETER DESCRIPTOR LIST  (PDE) SET UP BY PARSE                   02212020
*                                                                       02520020
* ATTRIBUTES --                                                         02580020
*    REENTRANT, REFRESHABLE, PROBLEM PROGRAM.                           02640020
*                                                                       02650020
* CHARACTER CODE DEPENDENCY --                                          02660020
*                                                                       02700020
* NOTES --                                                              02950020
*                                                                       02960020
*********************************************************************** 03000020
         EJECT                                                          03060020
IKJEGLSA CSECT                                                          03120020
*RELEASE 21.6 CHANGES                                                   03170021
*A597812                                                        SA52082 03172021
*A587818                                                        SA52082 03172421
*C597820                                                        SA52082 03174021
*D597710                                                        SA52082 03176021
         SPACE 1                                                        03180020
*********************************************************************** 03190020
*  REGISTER EQUATES.                                                    03240020
         SPACE                                                          03300020
R0       EQU   0                   WORK REG                             03360020
R1       EQU   1                   WORK REG                             03420020
R2       EQU   2                   WORK REG                             03480020
R3       EQU   3                   WORK REG                             03540020
R4       EQU   4                   USED IN PROCESS SECTION FOR CONTROL  03600020
R5       EQU   5                   WORK REG                             03660020
R6       EQU   6                   IN PROCESS SECTION, CUR BUF PTR      03720020
R7       EQU   7                   INTERNAL LINKAGE REGISTER            03780020
R8       EQU   8                   POINTS TO CURRENT ADDRESS PDE        03840020
R9       EQU   9                   BASE FOR TCOMTAB DSECT               03900020
R10      EQU   10                  BASE FOR LSTWORK DSECT               03960020
R11      EQU   11                  SPACE REGISTER                       04020020
R12      EQU   12                  PROGRAM BASE REGISTER                04080020
R13      EQU   13                  PROGRAM SAVE AREA                    04140020
R14      EQU   14                  EXTERNAL LINKAGE REGISTER            04200020
R15      EQU   15                  EXTERNAL LINKAGE REGISTER            04260020
*********************************************************************** 04380020
         SPACE 2                                                        04440020
*  DATA EQUATES FOR OPERANDS OF IMMEDIATE TYPE INSTRUCTIONS.            04500020
         SPACE                                                          04560020
NULL     EQU   0                   USED FOR BALR R,0 AND BCTR R,0.      04620020
ZERO     EQU   0                   SYMBOLIC EQUATE                      04680020
ONE      EQU   1                   SYMBOLIC EQUATE                      04740020
TWO      EQU   2                   SYMBOLIC EQUATE                      04800020
THREE    EQU   3                   SYMBOLIC EQUATE                      04860020
FOUR     EQU   4                   SYMBOLIC EQUATE                      04920020
FIVE     EQU   5                   SYMBOLIC EQUATE                      04980020
SIX      EQU   6                   USED AS THE MAX INSTRUCTION LENGTH   04990020
EIGHT    EQU   8                   SYMBOLIC EQUATE                      05040020
SIXTEEN  EQU   16                  SYMBOLIC EQUATE                      05100020
HEX0A    EQU   X'0A'               USED IN SIGNTBL FOR ZONED FORMAT     05160020
HEX80    EQU   X'80'               SYMBOLIC MASK                        05220020
HEXFF    EQU   X'FF'               SYMBOLIC MASK                        05280020
         SPACE                                                          05340020
BLANK    EQU   C' '                SYMBOLIC FOR BLANK (SPACE).          05400020
PERIOD   EQU   C'.'                SYMBOLIC FOR PERIOD (.)              05460020
CHARPLUS EQU   C'+'                SYMBOLIC FOR A PLUS SIGN             05520020
CHAR0    EQU   C'0'                SYMBOLIC FOR  CHARACTER 0            05580020
CHAR1    EQU   C'1'                SYMBOLIC FOR A CHARACTER 1           05640020
CHAR9    EQU   C'9'                SYMBOLIC FOR CHARACTER 9             05700020
         SPACE                                                          05880020
CFLDMASK EQU   B'00011111'         MASK TO ISOLATE REMAINDERS FOR C TYP 05940020
DWBDY    EQU   B'00000111'         USED TO TEST ADDRS FOR DBL WRD BDY.  06000020
FWBDY    EQU   B'00000011'                                FULL          06060020
HWBDY    EQU   B'00000001'                                HALF          06120020
INSTRLEN EQU   B'11000000'         FOR TESTING 1ST 2 BITS OF INSTRS     06180020
PACKMSK  EQU   X'6F'               USED TO SET UP LNTHS FOR PACK INSTR  06240020
         SPACE                                                          06250020
*  EQUATES FOR OFFSETS INTO A SYMINFO BLOCK.                            06260020
         SPACE                                                          06300020
SIDATAPT EQU   0                   OFFSET INTO SYMINFO BLK FOR DATA PTR 06360020
SITYPE   EQU   4                   OFFSET INTO SYMINFO FOR TYPE         06420020
SIMUL    EQU   6                   OFFSET TO LAST 2 BYTES OF MLTPLCTY   06480020
SILEN    EQU   8                   OFFSET TO LNTH IN SYMINFO            06540020
SINXTPTR EQU   12                  OFFSET INTO SYMINFO BLK FOR CHAIN PT 06600020
SYMINFOL EQU   16                  SYMBOLIC FOR LENGTH OF SYMINFO BLK   06660020
         SPACE                                                          06670020
LL00LEN  EQU   4                   SYMBOLIC FOR LENGTH OF LL00 FIELD    06720020
LSTBUFL  EQU   82                  LENGTH TO BE BLANKED IN BUFFER       06780020
MINLL    EQU   40                  MINIMUM LINE LNTH FORMATTED BY LIST  06840020
STDLL    EQU   81                  DEFAULT LINE LNTH WHEN TMPLL IS LOW  06900020
CHARLEN  EQU   32                  LENGTH OF AN OUTPUT FLD, CHAR FORMAT 06960020
SP1      EQU   1                   USED TO INCREMENT BY 1 SPACE         07020020
SP2      EQU   2                   USED TO INCREMENT BY 2 SPACES        07080020
SP4      EQU   4                   FOR INCREMENTING PAST 4 SPACES       07140020
         SPACE                                                          07200020
H2ND     EQU   1                   OFFSET TO 2ND BYTE OF A HALFWORD     07260020
F1STHALF EQU   0                   OFFSET TO 1ST HALFWORD OF A FIELD    07320020
LL00OFF  EQU   0                   OFFSET INTO BUFFER FOR LL00 FIELD    07380020
ADDRLEN  EQU   7                   SYMBOLIC LNTH OF ABS/REL ADDRESSES   07440020
BFLDLEN  EQU   8                   SYMBOLIC LNTH OF 1 BINARY FIELD      07500020
BDATALEN EQU   1                   SYMBOLIC LNTH OF INPUT FOR 1 BIN FLD 07560020
SIGNLEN  EQU   1                   LENGTH OF A SING FIELD               07620020
DATAOFF  EQU   4                   OFFSET TO DATA PORTION OF BUFFER     07680020
MSGOFFST EQU   80                  OFFSET INTO BUFFER FOR PLACING MSG   07690020
R6OFF    EQU   44                  OFFSET INTO SAVE AREA FOR REG 6      07740020
R10OFF   EQU   60                  OFFSET INTO SAVE AREA FOR R10        07790020
TYPELEN  EQU   1                   SYMBOLIC LNTH OF TYPE FIELD IN MSG   07820020
         SPACE                                                          07860020
LSTWRKPT EQU   0                   PARM LIST OFFSET TO LSTWORK BASE     07920020
LSTPDEPT EQU   4                   PARM LIST OFFSET TO CUR ADDR PDE     07980020
         SPACE                                                          08040020
L0AOFF   EQU   DATAOFF+ADDRLEN     OFFSET TO FIRST INSTR FROM BUF BEGIN 08100020
FOREPTR  EQU   8                   OFFSET TO FOREWARD PTR IN SAVE AREA  08160020
BACKPTR  EQU   4                   OFFSET TO BACKWARD PTR IN SAVE AREA  08220020
FIRSTI   EQU   DATAOFF+ADDRLEN+SP4 OFFSET INTO BUF OF 1ST INSTR, I TYPE 08280020
CONLNTH  EQU   0                   OFFSET INTO CONVERT AREA FOR LENGTH  08340020
CONDATA  EQU   1                   OFFSET INTO CONAREA TO START OF DATA 08400020
MAXLINE  EQU   100                 MAX LINE LENGTH FOR OUTPUT           08460020
LSTIBLK  EQU   31                  LNTH OF DATA MOVED TO HOLD AREA      08520020
CVTSPACE EQU   64                  OFFSET INTO COMMON WORK AREA FOR LST 08580020
ATTNBIT  EQU   B'01000000'                                              08640020
EQZERO   EQU   8                   COND CODE MASK FOR CC OF 0           08700020
NOTONES  EQU   14                  COND. CODE MASK FOR CC OF 0, 1, OR 2 08760020
         SPACE                                                          08820020
MAXPLEN  EQU   16                  LENGTH LIMIT FOR P,Z,L TYPES         08880020
POUTMAX  EQU   32                  MAX OUTPUT LNTH FOR P TYPE           08940020
ZOUTMAX  EQU   17                  MAX OUTPUT LNTH FOR Z TYPE           09000020
LOUTMAX  EQU   32                  MAX OUTPUT LNTH FOR L TYPE           09060020
MAXFLEN  EQU   8                   LENGTH LIMIT FOR F,E,H,D TYPES       09120020
FOUTMAX  EQU   20                  MAX OUTPUT LNTH FOR F,H TYPES        09180020
EOUTMAX  EQU   23                  MAX OUTPUT LNTH FOR E,D TYPES        09240020
MAXALEN  EQU   4                   LENGTH LIMIT FOR A,Q,V TYPE          09300020
AOUTMAX  EQU   11                  MAX OUTPUT LNTH FOR A,V,Q TYPES      09360020
MAXYLEN  EQU   2                   LENGTH LIMIT FOR Y,S TYPES           09420020
YOUTMAX  EQU   6                   MAX OUTPUT LNTH FOR Y TYPE           09480020
SOUTMAX  EQU   8                   MAX OUTPUT LNTH FOR S TYPE           09540020
MAXGENR  EQU   15                  MAXIMUM GENERAL REGISTER NUMBER      09600020
TWENTY   EQU   20                  NUMBER FOR COMPARE                   09660020
MAXFPR   EQU   6                   MAXIMUM FLOATING PT REG NUMBER       09720020
         SPACE 2                                                        09780020
*  EQUATES FOR INTERNAL ASSEMBLER-TYPE-CODES.                           09790020
         SPACE                                                          09800020
CHARCODE EQU   X'00'               TYPE ATTRIBUTE =CHAR                 09840020
HEXCODE  EQU   X'04'                ''     ''     =HEXADECIMAL          09900020
BINCODE  EQU   X'08'                ''     ''     =BINARY               09960020
ICODE    EQU   X'0C'                ''     ''     =INSTRUCTION          10020020
FCODE    EQU   X'10'                ''     ''     =FIXED PT, FULLWORD   10080020
HCODE    EQU   X'14'                ''     ''       ''   '', HALFWORD   10140020
ECODE    EQU   X'18'                ''     ''     =FLT PT, FULLWORD     10200020
DCODE    EQU   X'1C'                ''     ''      ''  '', DBL WORD     10260020
AQCODE   EQU   X'20'                ''     ''     =A AND Q ADDR CONST   10320020
YCODE    EQU   X'24'                ''     ''     =Y ADDR CONST         10380020
SCODE    EQU   X'28'                ''     ''     =S ADDR CONST         10440020
VCODE    EQU   X'2C'                ''     ''     =V ADDR CONST         10500020
PACKCODE EQU   X'30'                ''     ''     =PACKED DECIMAL       10560020
ZONECODE EQU   X'34'                ''     ''     =ZONED DECIMAL        10620020
LCODE    EQU   X'38'                ''     ''     =FLT PT, EXTENDED     10680020
         SPACE                                                          10740020
MSGMULTI EQU   8                   MULTIPLIER FOR MSG PARM LIST LNTH.   10800020
MSG05    EQU   0*MSGMULTI          OFFSET TO MESSAGE NUMBER 05          11100020
MSG06    EQU   1*MSGMULTI            ''   ''  ''       ''   06          11160020
MSG07    EQU   2*MSGMULTI            ''   ''  ''       ''   07          11170020
MSG03    EQU   3*MSGMULTI            ''   ''  ''       ''   03          11180020
MSG08    EQU   4*MSGMULTI            ''   ''  ''       ''   08          11190020
         TITLE 'IKJEGLSA, ''LIST'', INITIALIZATION SECTION.'            11220020
*********************************************************************** 11280020
*                                                                     * 11340020
*  PROGRAM BEGINS WITH STANDARD LINKAGE CONVENTIONS.                  * 11400020
*                                                                     * 11460020
*********************************************************************** 11520020
         SPACE                                                          11580020
LIST     SAVE  (14,12),,*                                               11640020
         LR    R12,R15             R12=BASE REG FOR PROG ADDRESSABILITY 11700020
         USING LIST,R12                                                 11760020
         USING TCOMTAB,R9          COMMUNICATION TABLE ADDRESSABILITY.  11820020
         L     R4,REGSAVE2         R4=NEXT SAVE AREA                    11880020
         ST    R4,FOREPTR(R13)     FOREWARD CHAIN SAVE AREAS.           11940020
         ST    R13,BACKPTR(R4)     BACKWARD CHAIN SAVE AREAS.           12000020
         LR    R13,R4              R13=NEXT REGSAVE AREA ADDR.          12060020
         SPACE 1                                                        12120020
         L     R8,LSTPDEPT(R1)     GET PTR TO CURRENT ADDRESS PDE       12180020
         L     R10,LSTWRKPT(R1)    GET BASE ADDR FOR LSTWORK DSECT      12240020
         USING IKJPARMA,R8         ADDRESSABILITY FOR ADDR PDE DSECT    12300020
         USING LSTWORK,R10                                              12360020
         SPACE                                                          12420020
*                                                                       12470020
*        ISSUE STAE MACRO                                               12472020
*                                                                       12474020
         NI    TSTFLGS2,HEXFF-TSTXCTL  TURN OFF XCTL IN PROGRESS SW     12474420
         MVC   TSTRETRY+ONE(THREE),RETRYAD+ONE  MOVE ADDR TO TCOMTAB    12476020
         LA    R1,STAELIST         PTR TO LIST FORM MACRO               12478020
         L     R2,TSTSTAE          PTR TO TEST STAE MODULE              12478420
         STM   R10,R12,R10OFF(R13)     SAVE BASE PTR                    12478820
         STAE  (R2),CT,MF=(E,(R1))                                      12479220
         SPACE                                                          12479620
         LTR   R15,R15             TEST RETURN CODE                     12479720
SMTSTAE  DS    0H                  SMT TEST LABEL FOR STAE MACRO        12489720
         BZ    STAEOK              CONTINUE IF ZERO                     12499920
         B     PRC16               ELSE, PRINT GETMAIN ERROR MSG        12509920
         SPACE                                                          12511920
STAEOK   EQU   *                                                        12519920
         SPACE                                                          12526620
*********************************************************************** 12533320
*                                                                     * 12540020
*  BEGINNING OF REPEAT SECTION.  THE ROUTINE BELOW IS RE-ENTERED IF   * 12600020
*  A LIST OF ADDRESSES HAS BEEN GIVEN.                                * 12660020
*                                                                     * 12720020
*********************************************************************** 12780020
LSTMN04  EQU   *                                                        12840020
         L     R2,LMATTR           GET LENGTH AND MULTIPLICITY ATTR'S   12900020
         ST    R2,A1LMATTR             AND SET ADDRESS 1 ATTRIBUTES.    12960020
         SPACE                                                          13020020
         TM    PDE2FLG3,AFLG       WAS A SECOND ADDRESS GIVEN           13080020
         L     R15,PDEUSER         GET DATA ADDR OR SI PTR              13140020
         BO    LSTMN05             IF YES, BRANCH                       13200020
         TM    PDE2FLG2,CTNAMFLG   WAS 2ND ADDRESS A CSECT NAME         13260020
         BNO   LSTMN06             BRANCH IF NO 2ND ADDRESS             13320020
LSTMN05  EQU   *                                                        13380020
         OI    COMFLGS,TWOADDRS    SET FLAG TO INDICATE ADDRESS RANGE   13440020
LSTMN06  EQU   *                                                        13500020
         LTR   R15,R15             IF R15 NEG, R15 POINTS TO SYMINFO    13560020
         BM    SYM1                IF SYMBOLIC, BRANCH                  13620020
LSTMN07  EQU   *                                                        13680020
         ST    R15,A1              SAVE ADDR OF CURRENT INPUT           13740020
         TM    COMFLGS,TWOADDRS    WERE TWO ADDRESSESS SPECIFIED        13800020
         BZ    ONLYONE             IF ONLY ONE ADDR, BRANCH             13860020
         L     R15,PDE2USER            GET SECOND ADDR OR SI PTR        13920020
         LTR   R15,R15             IF R15 NEG, R15 POINTS TO SYMINFO    13980020
         BNM   ONLYONE             IF ADDR2 IS SYMBOLIC, BRANCH         14040020
         L     R15,SIDATAPT(R15)   PICK UP INPUT ADDR FROM SI BLOCK     14100020
ONLYONE  EQU   *                                                        14160020
         ST    R15,A2              SET A2 TO CURRENT SECOND ADDR        14220020
         LA    R15,HOLDAREA        MAKE A PTR TO DATA HOLDING AREA      14280020
         ST    R15,VPDEPT          SET UP VALUE PDE FOR DATA CONVERT    14340020
         SPACE                                                          14400020
*  NEXT TEST WHETHER ADDR IF REG TYPE                                   14460020
         SPACE                                                          14520020
         TM    PDEFLG4,GENR+LFPR+SFPR  IS ADDRESS TYPE REGISTER         14580020
         BZ    NOTREG                           IF NOT, BRANCH          14640020
         NC    PDEINDCT,PDEINDCT               IF REG, IS IT INDIRECT   14700020
         BZ    LSTREG              IF REG IS NOT INDIRECTED, BRANCH     14760020
         SPACE                                                          14820020
*  NEXT TEST WHETHER ADDRESS IS RELATIVE                                14880020
         SPACE                                                          14940020
NOTREG   EQU   *                                                        15000020
         TM    PDEFLG4,CTONLY      IS ADDRESS A CSECT NAME              15050020
         BO    LSTMN09             IF CSECT NAME, BRANCH                15052020
         TM    PDEFLG4,RELADDR     IS ADDRESS TYPE RELATIVE             15060020
         BZ    LSTMN10             IF NOT RELATIVE, BRANCH              15120020
         NC    PDEINDCT,PDEINDCT   IF RELATIVE, IS IT INDIRECTED        15180020
         BNZ   LSTMN10             IF INDIRECTED, BRANCH                15240020
         TM    PDEEXPTR,HEXFF      IF RELATIVE, IS IT AN EXPRESSION     15300020
         BNO   LSTMN10             IF START OF AN EXPRESSION, BRANCH    15360020
         OI    A1FLG,A1REL         TURN ON ADDRESS IS RELATIVE FLAG     15420020
         TM    PDEFLG2,CTNAMFLG    IS RELATIVE ADDR QUALIFIED           15430020
         BNO   LSTMN14             IF NOT QUALIFIED, BRANCH             15440020
         SPACE                                                          15450020
*********************************************************************** 15460020
*                                                                     * 15470020
*  IF THE ADDRESS IS A QUALIFIED RELATIVE, CALCULATE THE BASE FOR     * 15471020
*   RELATIVES BY CONVERTING THE RELATIVE OFFSET TO BINARY AND         * 15472020
*    SUBTRACTING IT FROM THE RESOLVED CURRENT ADDRESS. THIS BASE      * 15473020
*     ADDRESS IS KEPT IN 'PPTEMP' FOR USE BY IKJEGCVT.                * 15474020
*                                                                     * 15475020
*********************************************************************** 15476020
         XC    HOLDAREA(APL),HOLDAREA  CLEAR AN AREA FOR AN ADDR PDE    15477020
         L     R2,PDEUSER          GET BINARY START ADDRESS             15478020
         SPACE                                                          15479020
*  NEXT MOVE THE ADDRESS POINTER AND THE LENGTH TO THE NEW ADDR PDE.    15479120
         SPACE                                                          15479220
         MVC   HOLDAREA+PDEADRPT-IKJPARMA(PDERSV3-PDEADRPT),PDEADRPT    15479320
         MVI   HOLDAREA+PDEEXPTR-IKJPARMA,HEXFF  INDICATE NOT INDIRECT  15479420
         SPACE                                                          15479520
*  THE ADDRESS TYPE FIELD IS ZERO WHICH IS THE CODE FOR ABSOLUTE.       15479620
         SPACE                                                          15479720
         LA    R1,HOLDAREA         SET UP A POINTER TO NEW PDE.         15479820
         L     R15,TSTCONVT        GET ADDRESS OF CONVERT ROUTINE       15479920
         SR    R0,R0               MAKE REG 0, ZERO FOR CONVERT TO BIN  15480020
         LCR   R1,R1               MAKE REG 1 NEGATIVE FOR ADDR CONVERT 15480120
         BALR  R14,R15             GO CONVERT RELATIVE OFFSET TO BINARY 15480220
         LTR   R15,R15             IS THE RETURN CODE ZERO              15480320
         L     R1,HOLDAREA+PDEUSER-IKJPARMA  GET CONVERTED DATA         15480420
         BNZ   LSTCVTRC            IF RC WAS NOT 0, BRANCH              15480520
         SR    R2,R1               SUBTRACT OFFSET FROM ADDRESS         15480620
         ST    R2,PPTEMP           SET UP DIVVERENCE AS BASE FOR RELS   15480720
         B     LSTMN14             BRANCH AROUND SET UP FOR ABSOLUTE    15480920
         SPACE                                                          15530920
LSTMN09  EQU   *                                                        15532920
         OI    A1FLG,A1SYM         TURN ON ADDR IS SYMBOLIC FLAG        15534920
LSTMN10  EQU   *                                                        15540020
         XC    APDE(APL),APDE      CLEAR ADDRESS PDE,                   15600020
         OI    APDE+(PDEFLG3-IKJPARMA),AFLG     SET FLAG, ADDR PRESENT  15660020
         OI    APDE+(PDEFLG4-IKJPARMA),ABSADDR  SET FLAG FOR ABSOLUTE   15720020
LSTMN14  EQU   *                                                        15780020
         SPACE                                                          15840020
*  NOW PICK UP TYPE FIELD AND USE AS INDEX INTO BRANCH TABLE.           15900020
         SR    R15,R15             CLEAR REG                            15960020
         IC    R15,A1TYPE              PICK UP TYPE CODE                16020020
         B     TYPEBTBL(R15)               AND BRANCH INTO BRANCH TABLE 16080020
         SPACE                                                          16140020
TYPEBTBL EQU   *                                                        16200020
         B     LSTCHAR             CODE X'00' FOR CHAR                  16260020
         B     LSTHEX              CODE X'04' FOR HEXADECIMAL           16320020
         B     LSTBIN              CODE X'08' FOR BINARY                16380020
         B     LSTINSTR            CODE X'0C' INSTRUCTION FORMAT        16440020
         B     FCON                CODE X'10' FOR FULLWORD FIXED PT     16500020
         B     HCON                CODE X'14' FOR HALFWORD FIXED PT     16560020
         B     ECON                CODE X'18' FOR SHORT FLT PT          16620020
         B     DCON                CODE X'1C' FOR LONG FLT PT           16680020
         B     ACON                CODE X'20' FOR A AND Q ADDR CNSTNTS  16740020
         B     YCON                CODE X'24' FOR Y ADDR CONSTANTS      16800020
         B     SCON                CODE X'28' FOR S ADDR CONSTANTS      16860020
         B     ACON                CODE X'2C' FOR V ADDR CONSTANTS      16920020
         B     PACKED              CODE X'30' FOR PACKED DECIMAL        16980020
         B     ZONED               CODE X'34' FOR ZONED DECIMAL         17040020
         B     LCON                CODE X'38' FOR EXTENDED FLT PT       17100020
         TITLE 'IKJEGLSA, ''LIST'', XCTL FOR REG ADDR OR HEX FORMAT'    17160020
*  IF FORMAT TYPE IS HEX (X), OR, IF THE ADDRESS TYPE IS REG, XCTL TO * 17212020
*  IKJEGLST WITH THE 'PCHLSTVL' SW IN 'TCOMTAB(TSTFLGS1)' SET TO 1    * 17214020
*  TO SHOW ENTRY FROM IKJEGLSA                                          17216020
         SPACE                                                          17218020
LSTHEX   EQU   *                                                        17220020
LSTREG   EQU   *                                                        17280020
         SPACE                                                          17290020
*        THIS XCTL USES THE BLDL ENTRY FOR IKJEGLST WHICH WAS CREATED   17330020
*        BY MAINLINE IN INITIALIZATION. THIS BLDL ENTRY SHOULD IMPROVE  17332020
*        PERFORMANCE OF SUB-COMMANDS XCTLING BETWEEN LOAD MODULES.      17334020
         SPACE 2                                                        17336020
         LA    R1,LST           PTR TO CONSTANT NAME                    17338020
         L     R15,TSTEXPAN     ADDRESS OF EXPANSION ROUTINE            17338420
         BALR  R14,R15          GO DO EXPANDING                         17338820
         LTR   R6,R1            WAS BLDL ENTRY RETURNED                 17339220
         BZ    NOBLDL           BRANCH IF NOT                           17339620
         L     R13,BACKPTR(R13) ADDR OF CALLERS SAVE AREA               17339720
         LA    R15,LXCTL        PTR TO PARM LIST                        17339820
         LA    R1,LXCTL1        SET UP PTR TO LIST'S PARM LIST          17339920
         ST    R8,LSTPDEPT(R1)     PASS A PTR TO THE CURRENT ADDR PDE   17359920
         ST    R10,LSTWRKPT(R1)    PASS THE BASE ADDR OF LSTWORK DSECT  17369920
         OI    TSTFLGS1,PCHLSTVL   INDICATE CALL IS FROM IKJEGLSA       17371920
         OI    TSTFLGS2,TSTXCTL TURN ON XCTL IN PROGRESS BIT            17379920
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  SET UP MNL STAE            17386620
         XCTL  (2,12),DE=(6),SF=(E,(15))                                17388620
         SPACE 2                                                        17390620
*        THE FOLLOWING XCTL IS EXECUTED IF THE BLDL ISSUED BY MAINLINE  17392620
*        WAS NOT SUCCESSFUL AND THE BLDL ENTRY IS NOT AVAILABLE FOR     17393020
*        USE IN THE XCTL.                                               17393120
         SPACE 2                                                        17393220
NOBLDL   DS    0H                                                       17424920
         L     R13,BACKPTR(R13)    PICK UP ADDR OF CALLERS SAVE AREA    17456620
         LA    R15,LXCTL           SET UP PTR TO LIST FORM OF XCTL MAC  17488320
         LA    R1,LXCTL1           SET UP PTR TO LIST XCTL PARM LIST    17520020
         ST    R8,LSTPDEPT(R1)     PASS PTR TO CUR ADDR PDE             17580020
         ST    R10,LSTWRKPT(R1)    PASS BASE ADDR OF LSTWORK DSECT      17640020
         OI    TSTFLGS1,PCHLSTVL   INDICATE CALL IS FROM IKJEGLSA       17700020
         OI    TSTFLGS2,TSTXCTL    INDICATE XCTL WITHIN LIST SUB-CMD    17710020
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  USE MAINLINES RETRY RTN    17750020
         SPACE                                                          18000020
         XCTL  (2,12),EP=IKJEGLST,SF=(E,(15))                           18060020
         SPACE                                                          18110020
SMTXCTL  DS    0H            SMT TEST LABEL FOR XCTL MACRO              18112020
         TITLE 'IKJEGLSA, ''LIST'', WRAPUP AND NON-ZERO RETURN CODES'   18120020
*********************************************************************** 18180020
*                                                                     * 18240020
*  COMPLETION ROUTINE, TESTS FOR ADDITIONAL ADDRESSES TO LIST AND     * 18300020
*  SETS A 0 RETURN CODE. WHEN ALL ADDRESSES HAVE BEEN PROCESSED,      * 18360020
*  THE ROUTINE RETURNS TO THE CALLER.                                 * 18420020
*                                                                     * 18480020
*********************************************************************** 18540020
         SPACE                                                          18600020
LSTCC0   EQU   *                                                        18660020
         TM    COMFLGS,OUTCORE     WAS THERE AN OUT OF CORE REQUEST     18710020
         BZ    LSTOK               BRANCH IF NOT                        18710420
         BAL   R7,LSTOUT           GO PUT OUT MESSAGE IF SO             18712020
LSTOK    EQU   *                                                        18714020
         TM    PDE2CHAI,HEXFF      IS THERE ANOTHER ADDRESS PDE         18720020
         BNO   MORE                IF YES, BRANCH                       18780020
LSTMN90  EQU   *                                                        18840020
*  TURN OFF ALL SWITCH'S WHICH MAY HAVE BEEN USED.                      18900020
         NI    TSTFLGS1,HEXFF-TSTPRINT-TSTFIRST-PCHLSTVL-RANGESW        18960020
         L     R15,LSTRETCD        PICK UP RETURN CODE                  19020020
         L     R13,BACKPTR(R13)    GET ADDR OF PREVIOUS SAVE AREA.      19080020
         RETURN (14,12),RC=(15)    RETURN TO CALLER                     19140020
         SPACE                                                          19200020
MORE     EQU   *                                                        19260020
         L     R6,OUTBUF           GET ADDR OF OUTPUT BUFFER            19320020
         ST    R6,IOLIST           SET UP THE IO PARM LIST              19380020
         BAL   R7,LSTIO            GO TO IO RTN TO VERTICAL SPACE 1     19440020
         SPACE                                                          19500020
         XC    LSTRPT(RPTSIZE),LSTRPT  CLEAR ADDR PORTION OF WORK AREA  19560020
         L     R8,PDE2CHAI         GET ADDR OF NEXT PDE FROM CHAIN PTR  19620020
         IC    R2,TYPESAVE         GET TYPE CODE OR DEFAULT TYPE CODE   19680020
         STC   R2,A1TYPE           SET FORMAT TYPE (EXCEPT FOR SYMBOLS) 19740020
         B     LSTMN04             GO BACK AND PROCESS NEXT ADDR        19800020
         SPACE                                                          19860020
LSTCC16  EQU   *                                                        19920020
         LA    R15,SIXTEEN         R15=16                               19980020
         ST    R15,LSTRETCD        RC=16                                20040020
         B     LSTMN90             GO CLEAN UP AND RETURN               20100020
         SPACE                                                          20160020
LSTCVTRC EQU   *                                                        20220020
         CH    R15,H16             IS RC=16                             20280020
         BE    LSTCC16             IF EQUAL, ATTN, BRANCH               20340020
         B     LSTCC0              OTHERWISE, GO CHECK FOR MORE ADDRS   20400020
         EJECT                                                          20460020
*********************************************************************** 20520020
*                                                                     * 20580020
*  SYMBOLIC ADDRESS SETUP ROUTINE. THIS ROUTINE SETS UP THE A1 FIELD  * 20640020
*  AND FILLS IN ANY ATTRIBUTES NOT OVER-RIDDEN BY THE USER.           * 20700020
*                                                                     * 20760020
*********************************************************************** 20820020
SYM1     EQU   *                                                        20880020
         TM    LSTFLGS,TYPEFLG     WAS A TYPE GIVEN BY THE USER         20940020
         BO    HAVETYPE            IF GIVEN, IGNORE ATTRS OF SYMBOL     21000020
         SR    R2,R2               CLEAR A REG,                         21060020
         IC    R2,SITYPE(R15)          PICK UP THE TYPE,                21120020
         STC   R2,A1TYPE                   AND MAKE IT THE TYPE FOR A1  21180020
HAVETYPE EQU   *                                                        21240020
         TM    LSTFLGS,LNTHFLG     WAS LNTH ATTR GIVEN BY USER          21300020
         BO    SYM1L               IF GIVEN, IGNORE ATTRS OF SYMBOL     21360020
         LH    R2,SILEN(R15)       PICK UP SYMS LENGTH ATTR             21420020
         STH   R2,A1L              ESTABLISH SYMS LNTH FOR THIS DATA    21480020
SYM1L    EQU   *                                                        21540020
         TM    LSTFLGS,MULTIFLG    WAS MULTIPLICITY ATTR GIVEN BY USER  21600020
         BO    SYM1M               IF GIVEN, IGNORE ATTRS OF SYMBOL     21660020
         LH    R2,SIMUL(R15)       PICK UP SYMS MULTIPLICITY FACTOR     21720020
         STH   R2,A1M              EST. SYMS MULTI FOR THIS DATA        21780020
SYM1M    EQU   *                                                        21840020
         L     R15,SIDATAPT(R15)   GET PTR TO INPUT FROM SYMINFO BLOCK  21900020
         OI    A1FLG,A1SYM         SET FLAG TO INDICATE ADDR SYMBOLIC   21960020
         B     LSTMN07             RETURN TO MAINLINE SETUP ROUTINE     22020020
         TITLE 'IKJEGLSA, ''LIST'', CHARACTER FORMATTING ROUTINE'       22080020
*********************************************************************** 22140020
*                                                                     * 22200020
*  CHARACTER FORMATTING ROUTINE.                                      * 22260020
*                                                                     * 22320020
*********************************************************************** 22380020
         SPACE                                                          22440020
LSTCHAR  EQU   *                                                        22500020
         TM    COMFLGS,TWOADDRS    TEST FOR 1 OR 2 ADDRESSES            22560020
         BO    LSTC20              IF TWO, BRANCH                       22620020
         SR    R0,R0               SET UP A CONSTANT OF 0               22680020
         CH    R0,A1M              WAS MULTIPLICITY GIVEN               22740020
         BNE   LSTC04              IF GIVEN, BRANCH                     22800020
         MVI   A1M+H2ND,ONE        DEFAULT MULTIPLICITY TO ONE          22860020
LSTC04   EQU   *                                                        22920020
         CH    R0,A1L              WAS A LENGTH GIVEN                   22980020
         BNE   LSTC06              IF GIVEN, BRANCH                     23040020
         MVI   A1L+H2ND,ONE        DEFAULT LENGTH TO ONE                23100020
         SPACE                                                          23159720
LSTC06   EQU   *                                                        23160020
         BAL   R14,LSTLMTCK        GO CHECK UPPER ADDR OF THIS REQUEST  23210020
         LTR   R15,R15             HAS THE MULTIPLICITY BECOME ZERO     23212020
         BNZ   LSTCC0              IF ZERO, BRANCH                      23214020
         LH    R1,A1L              GET LENGTH GIVEN BY USER             23220020
         CH    R1,H32              COMPARE IT TO MAX-CHARS/LINE         23280020
         BH    LSTC24              IF GREATER THAN MAX, BRANCH          23340020
LSTC08   EQU   *                                                        23400020
         XC    REMAIN,REMAIN       SET REMAINDER TO 0                   23460020
         LH    R4,A1M              SET CONTROL TO MULTIPLICITY          23520020
LSTC10   EQU   *                                                        23580020
         STH   R1,VPDEL            PUT LENGTH IN VALUE PDE AND          23640020
         STH   R1,A1L                  IN LENGTH FIELD.                 23700020
         TM    A1FLG,A1SYM         TEST ADDRESS TYPE OF ADDR 1.         23760020
         BZ    LSTC12              IF TYPE IS ABSOLUTE, BRANCH          23820020
         BO    LSTC40              IF TYPE IS SYMBOLIC, BRANCH          23880020
         SPACE                                                          23940020
*  SETUP ROUTINE FOR RELATIVE TYPE ADDRESSES                            24000020
         SPACE                                                          24060020
         MVC   APDE(APL),IKJPARMA  MOVE ORIGINAL PDE TO WORK AREA       24130020
         SPACE                                                          24180020
LSTC12   EQU   *                                                        24240020
         LA    R2,A1               SET UP PTR TO CURRENT ADDRESS FLD    24300020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) STORE IT IN THE ADDR PDE     24360020
         B     LSTC50              GO TO CHAR PROCESS ROUTINE           24420020
         SPACE 3                                                        24480020
*  SETUP ROUTINE FOR TWO ADDRESSES                                      24540020
         SPACE                                                          24600020
LSTC20   EQU   *                                                        24660020
         L     R1,A2               R3=ADDR2                             24720020
         S     R1,A1               ADDR2-ADDR1=LNTH EXCLUDING END BYTE  24780020
         LA    R1,ONE(R1)          ADD 1 TO INCLUDE BYTE AT END         24840020
         STH   R1,A1L              SET LENGTH TO A2-A1+1                24900020
         MVI   A1M+H2ND,ONE        SET MULTIPLICITY TO ONE              24960020
         CH    R1,H32              IS COMPUTED LNTH GT MAX-CHARS/LINE   25020020
         BNH   LSTC08              IF NOT GREATER THAN MAX, BRANCH      25080020
         B     LSTC26              BRANCH TO ROUTINE FOR MULTIPLE LINES 25140020
         SPACE                                                          25200020
LSTC24   EQU   *                                                        25260020
         OI    COMFLGS,ARTIMSW     TURN ON ARTIFICIAL MULTIPLICITY SW   25320020
LSTC26   EQU   *                                                        25380020
         LA    R2,CFLDMASK         MASK TO ISOLATE REMAINDER            25440020
         LH    R4,A1L              R4=LENGTH TO BE LISTED               25500020
         NR    R2,R4               R2=REMAINDER OF LNTH/CHARLEN         25560020
         SRL   R4,FIVE             DIVIDE LNTH BY 32                    25620020
         STH   R2,REMAIN           SAVE REMAINDER                       25680020
         STH   R2,REMAIN2          SAVE A COPY OF THE REMAINDER         25740020
         STH   R4,ARTIFMUL         SAVE CONTROL, (QUOTIENT). R4=CONTROL 25800020
         LA    R1,CHARLEN          SET UP MAX-CHARS/LINE AS LENGTH      25860020
         B     LSTC10              RETURN TO COMMON SETUP RTN           25920020
         SPACE 2                                                        25980020
*  SETUP ROUTINE FOR SYMBOLIC ADDRESSES                                 26040020
         SPACE                                                          26100020
LSTC40   EQU   *                                                        26160020
         BAL   R7,LSTSYM           GO MOVE SYMBOL TO BUF                26220020
         L     R3,CONAREA          SET UP PTR TO CONVERT OUTPUT AREA    26280020
         CH    R4,HONE             IS CONTROL = 1                       26340020
         BH    LSTC42              IF GREATER THAN 1 BRANCH             26400020
         SR    R15,R15             MAKE A ZERO CONSTANT                 26460020
         CH    R15,ARTIFMUL        IS THERE AN ARTIFICIAL MULTIPLICITY  26520020
         BNE   LSTC42              IF YES, BRANCH                       26580020
         CH    R15,REMAIN          IS THERE A REMAINDER                 26640020
         BNE   LSTC42              IF YES, BRANCH                       26700020
         LH    R15,A1L             GET LENGTH OF OUTPUT FIELD           26760020
         LA    R15,SP2(R6,R15)     CALCULATE BUF PTR AT END OF DATA     26820020
         C     R15,ENDOBUF         WILL ADDR + DATA FIT IN THE BUFFER   26880020
         BNH   LSTC58              IF DATA WILL FIT, BRANCH             26940020
         SPACE                                                          27000020
LSTC42   EQU   *                                                        27060020
         BAL   R7,LSTIO            GO OUTPUT ADDR ON A SEPARATE LINE    27120020
         B     LSTC54              GO OUTPUT REL ADDRS AND DATA.        27180020
         SPACE                                                          27240020
*********************************************************************** 27300020
*                                                                     * 27360020
*  PROCESS LOOP OF LSTCHAR SUBROUTINE. CALLS 'LSTBPT' TO REMOVE ANY   * 27420020
*  BREAKPOINTS FROM THE INPUT DATA, THEN CALLS IKJEGCVT TO CONVERT    * 27480020
*  THE DATA ADDRESS TO PRINTABLE, AND THEN TRANSLATES UNPRINTABLES TO * 27540020
*  PERIODS. WHER BUF IS READY, LSTIO IS CALLED TO OUTPUT A LINE OF    * 27600020
*  DATA. IF THE ADDRESS WAS SYMBOLIC, THE ROUTINE MAY BE ENTERED AT   * 27660020
*  LSTC54 OR LSTC58, NORMAL ENTRY IS TO LSTC50.                       * 27720020
*  AT THIS POINT, THE ADDRESS IS IN THE BUFFER AND THE DATA MUST BE   * 27780020
*  MOVE TO THE BUFFER AND HAVE THE UNPRINTABLES TRANSLATED TO PERIODS * 27840020
*                                                                     * 27900020
*********************************************************************** 27960020
LSTC50   EQU   *                                                        28020020
         L     R6,OUTBUF           GET PTR TO OUTPUT BUFFER             28080020
         LA    R6,DATAOFF(R6)      INCRE BUF PTR PAST LL00 FIELD        28140020
LSTC52   EQU   *                                                        28200020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  28260020
LSTC54   EQU   *                                                        28320020
         L     R15,TSTCONVT        ADDR OF CONVERT ROUTINE              28380020
         LA    R1,APDE             R1=ADDR OF ADDR PDE                  28440020
         SR    R0,R0               R0=0                                 28500020
         LCR   R1,R1               MAKE NEGATIVE FOR ADDR CONVERSION    28560020
         BCTR  R0,NULL             R0 NEGATVE FOR CONVERT TO PRINTABLE  28620020
         BALR  R14,R15             GO CONVERT AN ADDR TO PRINTABLE      28680020
         LTR   R15,R15             TEST RETURN CODE                     28740020
         BNZ   LSTCVTRC            IF RC IS NON-ZERO, GO ANALYZE.       28800020
         L     R1,CONAREA          ADDR OF CONVERT OUTPUT AREA          28860020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R1)    MOVE CONVERTED ADDR      28920020
         LA    R6,ADDRLEN(R6)      INCRE BUF PTR PAST ADDR              28980020
LSTC58   EQU   *                                                        29040020
         LH    R1,A1L              GET PERMANENT DATA LENGTH            29100020
         LH    R2,VPDEL            PICK UP LENGTH OF THIS DATA FIELD    29160020
         LA    R1,SP2(R1,R6)       CALCULATE POTENTIAL END OF LINE ADDR 29220020
         C     R1,ENDOBUF          WILL DATA + ADDR FIT IN THE BUFFER   29280020
         BNH   LSTC64              IF ADDR+DATA WILL FIT, BRANCH        29340020
         BAL   R7,LSTIO            OTHERWISE, GO OUTPUT ADDR ON SEP LN  29400020
LSTC64   EQU   *                                                        29460020
         MVC   TWO*SP1(CHARLEN,R6),HOLDAREA    MOVE MAX POSSIBLE BYTES  29520020
         TR    TWO*SP1(CHARLEN,R6),TRTABLE     TRANSLATE TO PRINTABLE   29580020
         LA    R6,TWO*SP1(R2,R6)   INCRE BUF PTR PAST DATA              29640020
         BAL   R7,LSTIO            GO OUTPUT THE DATA                   29700020
         A     R2,VPDEPT           CALCULATE NEW INPUT ADDR             29760020
         ST    R2,VPDEPT           SET NEW INPUT ADDRESS                29820020
         BCT   R4,LSTC52           TEST AND DECREMTN CNTRL              29880020
         CH    R4,REMAIN           IS REMAINDER NON-ZERO                29940020
         BE    LSTC70              IF NOT, BRANCH                       30000020
         LH    R1,REMAIN           R1=REMAINDER LENGTH                  30060020
         STH   R1,VPDEL            SET VALUE PDE FOR REMAINDED LNTH     30120020
         STH   R4,REMAIN           SET REMAINDER TO ZERO                30180020
         LA    R4,ONE              SET CONTROL TO 1 FIELD.              30240020
         B     LSTC52              GO BACK AND PROCESS REMAINDER        30300020
         SPACE                                                          30360020
LSTC70   EQU   *                                                        30420020
         TM    COMFLGS,ARTIMSW     WAS CONTROL AN ARTIFICIAL MLTPLCTY   30480020
         BNO   LSTCC0              IF NOT, RETURN TO LIST MAINLINE      30540020
         LH    R15,A1M             R15=TRUE MULTIPLICITY                30600020
         BCT   R15,LSTC74          TEST AND DECRE MULTIPLICITY          30660020
         B     LSTCC0              IF NO MORE TO DO, RETURN TO MAINLINE 30720020
LSTC74   EQU   *                                                        30780020
         STH   R15,A1M             SAVE DECREMENTED VALUE               30840020
         LH    R1,A1L              R1=LENGTH OF AN OUTPUT FIELD.        30900020
         LH    R2,REMAIN2          PICK UP REMAINDER                    30960020
         LH    R4,ARTIFMUL         RESET CONTROL TO ARTIFICIAL MLTPLCTY 31020020
         STH   R1,VPDEL            RESET LENGTH OF OUTPUT FIELD         31080020
         STH   R2,REMAIN           RESET REMAINDER                      31140020
         B     LSTC52              GO PROCESS NEXT FIELD                31200020
         TITLE 'IKJEGLSA, ''LIST'', FORMAT INITIALIZATION'              31426220
*********************************************************************** 31430820
*                                                                     * 31435420
*  THE FOLLOWING ROUTINES SET UP LIMITS AND DEFAULT VALUES FOR THEIR  * 31440020
*  RESPECTIVE ASSEMBLER TYPES.  AFTER SETUP, CONTROL IS PASSED TO     * 31500020
*  A COMMON ROUTINE TO CHECK VALUES AND SET ANY NECESSARY DEFAULTS.   * 31560020
*                                                                     * 31620020
*********************************************************************** 31680020
         SPACE                                                          31740020
PACKED   EQU   *                                                        31800020
         LA    R0,MAXPLEN          R0= LNTH LIMIT                       31860020
         SR    R1,R1               R1=SHIFT VALUE TO DIVIDE BY 1        31920020
         LA    R2,ONE              R2=DEFAULT LNTH                      31980020
         LA    R3,POUTMAX          R3=LNTH MAX FOR OUTPUT               32040020
         B     LSTGEN00            GO TO COMMAN ROUTINE                 32100020
         SPACE                                                          32160020
ZONED    EQU   *                                                        32220020
         LA    R0,MAXPLEN          SAME LIMIT AS PACKED                 32280020
         SR    R1,R1               R1=SHIFT VALUE TO DIVIDE BY 1        32340020
         LA    R2,ONE              DEFAULT LNTH                         32400020
         LA    R3,ZOUTMAX          MAX FLD SIZE FOR Z OUTPUT            32460020
         B     LSTGEN00            GO TO COMMON ROUTINE                 32520020
         SPACE                                                          32580020
LCON     EQU   *                                                        32640020
         LA    R15,HEXCODE         CONVERT TO HEX CHAR FOR PRINTING     32690020
         LA    R0,MAXPLEN          SAME LIMIT AS PACKED                 32700020
         LA    R1,FOUR             R1=SHIFT VALUE TO DIVIDE BY 16       32760020
         LA    R2,SIXTEEN          DEFAULT LENGTH                       32820020
         LA    R3,LOUTMAX          MAX FLD SIZE FOR L OUTPUT            32880020
         B     LSTGEN00            GO TO COMMON ROUTINE                 32940020
         SPACE                                                          33000020
FCON     EQU   *                                                        33060020
         LA    R0,MAXFLEN          R0=LENGTH LIMIT                      33120020
         LA    R1,TWO              R1=SHIFT VALUE TO DIVIDE BY 4        33180020
         LA    R2,FOUR             DEFAULT LENGTH                       33240020
         LA    R3,FOUTMAX          MAX OUTPUT LNTH                      33300020
         B     LSTGEN00            GO TO COMMON ROUTINE                 33360020
         SPACE                                                          33420020
ECON     EQU   *                                                        33480020
         LA    R0,MAXFLEN          SAME LIMIT AS F TYPE                 33540020
         LA    R1,TWO              R1=SHIFT VALUE TO DIVDIE BY 4        33600020
         LA    R2,FOUR             DEFAUT LENGTH                        33660020
         LA    R3,EOUTMAX          MAX OUTPUT FIELD SIZE                33720020
         B     LSTGEN00            GO TO COMMON ROUTINE                 33780020
         SPACE                                                          33840020
HCON     EQU   *                                                        33900020
         LA    R0,MAXFLEN          SAME LIMIT AS F TYPE                 33960020
         LA    R1,ONE              R1=SHIFT VALUE TO DIVIDE BY 2        34020020
         LA    R2,TWO              DEFAULT LENGTH                       34080020
         LA    R3,FOUTMAX          SAME LIMIT AS F TYPE                 34140020
         B     LSTGEN00            GO TO COMMON ROUTINE                 34200020
         SPACE                                                          34260020
DCON     EQU   *                                                        34320020
         LA    R0,MAXFLEN          SAME LIMIT AS F TYPE                 34380020
         LA    R1,THREE            R1=SHIFT VALUE TO DIVIDE BY 8        34440020
         LA    R2,EIGHT            DEFAULT LENGTH                       34500020
         LA    R3,EOUTMAX          SAME LIMIT AS E TYPE                 34560020
         B     LSTGEN00            GO TO COMMON ROUTINE                 34620020
         SPACE                                                          34680020
ACON     EQU   *                   ALSO Q AND V FORMATS                 34740020
         LA    R0,MAXALEN          R0=LNTH LIMIT                        34800020
         LA    R1,TWO              R1=SHIFT VALUE TO DIVIDE BY 4        34860020
         LA    R2,FOUR             DEFAULT LENGTH                       34920020
         LA    R3,AOUTMAX          MAX OUTPUT FLD SIZE                  34980020
         B     LSTGEN00            GO TO COMMON ROUTINE                 35040020
         SPACE                                                          35100020
YCON     EQU   *                                                        35160020
         LA    R0,MAXYLEN          LENGTH LIMIT                         35220020
         LA    R1,ONE              R1=SHIFT VALUE TO DIVIDE BY 2        35280020
         LA    R2,TWO              DEFAULT LENGTH                       35340020
         LA    R3,YOUTMAX          MAX OUTPUT FLD SIZE                  35400020
         B     LSTGEN00            GO TO COMMON ROUTINE                 35460020
         SPACE                                                          35520020
SCON     EQU   *                                                        35580020
         LA    R0,MAXYLEN          SAME LIMIT AS Y TYPE BUT MUST BE EQ  35640020
         TM    LSTFLGS,LNTHFLG     DID USER SPECIFY LENGTH              35700020
         BNO   SCON04              IF NOT, USE DEFAULT LENGTH           35760020
         CH    R0,A1L              IS LNTH EXACTLY TWO                  35820020
         BNE   LSTSERR             IF LENGTH NOT 2, BRANCH              35880020
SCON04   EQU   *                                                        35940020
         LA    R1,ONE              R1=SHIFT VALUE TO DIVIDE BY TWO      36000020
         LA    R2,TWO              DEFAULT LENGTH                       36060020
         LA    R3,SOUTMAX          MAX OUTPUT FIELD SIZE                36120020
         B     LSTGEN00            GO TO COMMON ROUTINE                 36180020
LSTSERR  EQU   *                                                        36240020
         L     R2,LSTMSG           R2=ADDR MSG CSECT                    36300020
         LM    R2,R3,MSG05(R2)     PTRS TO 1ST AND 2ND LEVEL MSGS       36360020
         STM   R2,R3,IOLIST            TO PARM LIST                     36420020
         LA    R1,IOLIST           R1=ADDR OF PARM LIST                 36480020
         LCR   R1,R1               INDICATE OUTPUT IS MSG               36540020
         BAL   R7,LSTIO2           GO OUTPUT MSG                        36600020
         B     LSTCC0              GO CHECK FOR OTHER ADDRESSES         36660020
         TITLE 'IKJEGLSA, ''LIST'', GENERAL FORMATTING ROUTINE'         36720020
*********************************************************************** 36780020
*                                                                     * 36840020
*  GENERAL ROUTINE FOR LISTING DATA IN P, S, AQV, H, F, E, D, AND L   * 36900020
*  FORMATS. THE ROUTINE IS ENTERED FROM THE SETUP ROUTINE FOR THE     * 36960020
*  REGUESTED TYPE. AT ENTRY THE FOLLOWING REGS MUST BE SET.           * 37020020
*        R0=MAXIMUM LENGTH FOR THE PARTICULAR CONSTANT TYPE.          * 37080020
*        R1=A SHIFT VALUE FOR DIVIDING A RANGE INTO DEFAULT SIZED FLDS* 37140020
*        R2=THE DEFAULT LENGTH TO BE USED IF NONE GIVEN BY USER       * 37200020
*        R3=MAXIMUM LENGTH FOR OUTPUT IN THE GIVEN DATA TYPE.         * 37260020
*        R15=HEX CODE FOR REQUESTED TYPE                              * 37320020
*                                                                     * 37380020
*********************************************************************** 37440020
         SPACE                                                          37500020
LSTGEN00 EQU   *                                                        37560020
         STC   R15,VPDET           TYPE CODE TO PDE FOR CONVERT         37620020
         TM    COMFLGS,TWOADDRS    TEST FOR ONE ON TWO ADDRS            37680020
         BO    LSTGEN20            IF TWO, BRANCH                       37740020
*  SET UP FOR 1 ADDRESS                                                 37800020
         SR    R15,R15             GET A ZERO COMPAREND                 37860020
         CH    R15,A1M             WAS MULTIPLICITY GIVEN               37920020
         BNE   LSTGEN04            IF GIVEN, BRANCH                     37980020
         MVI   A1M+H2ND,ONE        DEFAULT MULTIPLICITY TO ONE          38040020
LSTGEN04 EQU   *                                                        38100020
         CH    R15,A1L             WAS LENGTH GIVEN                     38160020
         BE    LSTGEN08            IF NOT, BRANCH AND USE DEFAULT LNTH  38220020
         LH    R2,A1L              PICK UP GIVEN LENGTH                 38340020
LSTGEN08 EQU   *                                                        38400020
         CR    R2,R0               TEST REQUESTED FIELD LENGTH          38460020
         STH   R2,VPDEL            LENGTH TO VALUE PDE, ANTICIPATE OK.  38520020
         BH    LSTGEN90            IF LENGTH GREATER THAN MAX, BRANCH   38580020
         STH   R2,A1L              SAVE LENGTH TO BE USED IN THIS LIST  38630020
         BAL   R14,LSTLMTCK        GO CHECK UPPER ADDR OF THIS REQUEST  38632020
         LTR   R15,R15             WAS REMAINING MULTIPLICITY ZERO      38634020
         BNZ   LSTCC0              IF ZERO, BRANCH                      38636020
         LH    R4,A1M              SET CONTROL TO MULTIPLICITY          38640020
LSTGEN10 EQU   *                                                        38700020
         TM    A1FLG,A1SYM         WHAT IS THE ADDRESS TYPE             38760020
         BZ    LSTGEN12            IF ADDRESS IS ABSOLUTE, BRANCH       38820020
         BO    LSTGEN40            IF SYMBOLIC, BRANCH                  38880020
         SPACE                                                          38940020
*  IF THE ADDRESS TYPE IS RELATIVE, FALL THRU AND SET UP FOR RELATIVES  39000020
         SPACE                                                          39060020
         MVC   APDE(APL),IKJPARMA  MOVE ORIGINAL PDE TO WORK AREA       39130020
LSTGEN12 EQU   *                                                        39180020
         LA    R2,A1               GET PTR TO INPUT DATA ADDRESS        39240020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) STORE IT IN THE ADDR PDE     39300020
         CLI   A1TYPE,ZONECODE     IS REQUESTED FORMAT ZONED            39360020
         BE    LSTZ50              IF ZONED, BRANCH TO SPECIAL RTN      39420020
         B     LSTGEN50            GO PROCESS DATA                      39480020
         SPACE                                                          39540020
*  SET UP FOR 2 ADDRESSES                                               39600020
LSTGEN20 EQU   *                                                        39660020
         STH   R2,VPDEL            FOR ADDR RANGE, USE DEFAULT LNTH     39720020
         L     R4,A2               R4=2ND ADDRESS IN RANGE              39780020
         AR    R4,R2               INCLUDE FIELD AT 2ND ADDRESS         39840020
         C     R4,TSTTOP           DOES THIS ADDR EXCEED HIGHEST ADDR   39900020
         BNH   LSTGEN24            IF NOT, BRANCH                       39960020
         SR    R4,R2               EXCLUDE LAST FIELD IF OUT OF CORE    40020020
LSTGEN24 EQU   *                                                        40080020
         S     R4,A1               CALCULATE RANGE IN BYTES             40140020
         SRA   R4,ZERO(R1)         DIVIDE RANGE BY FIELD LENGTH         40200020
         B     LSTGEN10            GO BACK TO COMMON RTN.               40260020
         SPACE                                                          40320020
LSTGEN40 EQU   *                                                        40380020
         BAL   R7,LSTSYM           GO MOVE SYMBOLS TO BUF               40440020
         CH    R4,HONE             TEST CONTROL FOR MORE THAN 1 FIELD   40500020
         BH    LSTGEN42            IF MORE THAN 1, BRANCH               40560020
         LA    R15,ONE(R3,R6)      R15=MAX POSSIBLE NEEDED LNTH         40620020
         C     R15,ENDOBUF         WOULD THIS BE OUT OF BUF.            40680020
         BH    LSTGEN42            IF OUT OF BUF, BRANCH                40740020
         L     R3,CONAREA          SET UP PTR TO CONVERT OUTPUT AREA    40800020
         CLI   A1TYPE,ZONECODE     IS OUTPUT FORMAT TO BE ZONED         40860020
         BE    LSTZ58              IF ZONED, BRANCH TO SPECIAL RTN      40920020
         B     LSTGEN58            OTHERWISE, DATA WILL FIT, PROCESS IT 40980020
LSTGEN42 EQU   *                                                        41040020
         BAL   R7,LSTIO            GO OUTPUT THE SYMBOLIC ADDRESS       41100020
         CLI   A1TYPE,ZONECODE     IS OUTPUT FORMAT TO BE ZONED         41160020
         BE    LSTZ54              IF ZONED, BRANCH TO SPECIAL RTN      41220020
         B     LSTGEN54            GO PROCESS ADDRESSES AND DATA        41280020
         SPACE 2                                                        41340020
*********************************************************************** 41400020
*                                                                     * 41460020
*  MAIN PROCESS PORTION OF THE GENERAL LIST ROUTINE                     41520020
*        FIRST, GO CONVERT THE ADDRESS TO PRINTABLE                   * 41580020
*  AT THIS POINT, THE ADDRESS HAS BEEN PLACED IN THE BUFFER.          * 41640020
*        NEXT, GO CONVERT THE DATA TO THE PROPER FORMAT AND MOVE IT   * 41700020
*        TO THE BUFFER.                                               * 41760020
*********************************************************************** 41820020
LSTGEN50 EQU   *                                                        41880020
         L     R6,OUTBUF           GET PTR TO THE OUTPUT BUFFER         41940020
         LA    R6,DATAOFF(R6)      INCRE BUFFER PTR PAST LL00 FIELD     42000020
LSTGEN52 EQU   *                                                        42060020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  42120020
LSTGEN54 EQU   *                                                        42180020
         SR    R0,R0               R0=0                                 42240020
         LA    R1,APDE             R1=ADDR OF ADDRESS PDE               42300020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          42360020
         BCTR  R0,NULL             R0=NEGATIVE FOR CONVERT TO PRINTABLE 42420020
         LCR   R1,R1               R1=NEG TO SHW ADDRESS CONVERSION     42480020
         BALR  R14,R15             GO TO CONVERT ROUTINE                42540020
         LTR   R15,R15             TEST RETURN CODE FROM IKJEGCVT       42600020
         BNZ   LSTCVTRC            IF NON-ZERO, GO ANALYZE              42660020
         L     R3,CONAREA          ADDR OF CONVERT OUTPUT AREA          42720020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R3)  MOVE CONVERTED ADDR TO BUF 42780020
         LA    R6,ADDRLEN(R6)      INCREMENT BUF PTR PAST ADDRESS       42840020
LSTGEN58 EQU   *                                                        42900020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          42960020
         LA    R1,VPDE             R1=ADDR OF VALUE PDE                 43020020
         BALR  R14,R15             GO CONVERT DATA TO PROPER FORMAT     43080020
         LTR   R15,R15             TEST RETURN CODE FROM IKJEGCVT       43140020
         BNZ   LSTCVTRC            IF NON-ZERO, BRANCH AND ANALYZE      43200020
         IC    R15,CONLNTH(R3)     GET LENGTH OF CONVERTED DATA         43260020
         BCTR  R15,NULL            DECREMENT LENGTH FOR MVC INSTR       43320020
         EX    R15,DATAMOVE        MOVE CONVERTED DATA TO BUF           43380020
         LA    R6,SP2+ONE(R15,R6)  INCREMENT BUF PTR PAST SPACE+DATA    43440020
         L     R15,VPDEPT          R15=PTR TO LAST DATA                 43500020
         AH    R15,VPDEL           ADD LNTH OF DATA JUST PROCESSED      43560020
         ST    R15,VPDEPT          STORE UPDATE DATA PTR                43620020
         BAL   R7,LSTIO            GO OUTPUT ADDR AND 1 FIELD           43680020
         BCT   R4,LSTGEN52         IF MORE FIELDS, LOOP BACK            43740020
         B     LSTCC0              OTHERWISE, GO TO COMPLETION RTN      43800020
         SPACE                                                          43860020
         SPACE                                                          43920020
*  MGS FORMATTING ROUTINE FOR LSTGEN AND LST I ROUTINES.                43980020
LSTGEN90 EQU   *                                                        44040020
         L     R2,LSTMSG           R2=ADDR OF MESSAGE CSECT             44100020
         LM    R2,R3,MSG05(R2)     ADDRESS OF 1ST AND 2ND LEVEL MSG'S   44160020
         L     R14,OUTBUF          R3=ADDR OF OUTPUT BUFFER             44280020
         SR    R5,R5               R5=0                                 44340020
         LH    R4,ZERO(R2)         R2=LENGTH OF MESSAGE                 44400020
         BCTR  R4,NULL             DECREMENT LENGTH FOR MVC INSTR       44460020
         EX    R4,MSGMOVE1         MOVE MSG TO BUF                      44520020
         LR    R2,R14              RESET POINTER TO 2ND LEVEL MSG       44530020
         IC    R5,VPDET            PICK UP TYPE CODE FOR DATA           44580020
         SRL   R5,TWO              DIVIDE HEX TYPE CODE BY 4 FOR INDEX  44640020
         LA    R14,ZERO(R4,R14)    SET UP PTR TO TYPE FIELD IN MSG      44760020
         LA    R5,LSTTYPE(R5)      SET UP PTR TO TYPE CODE              44820020
         MVC   ZERO(TYPELEN,R14),ZERO(R5)  MOVE TYPE CODE TO MSG        44880020
LSTGEN94 EQU   *                                                        44950020
         LA    R1,IOLIST           R1=ADDR OF PARM LIST FOR IKJEGIO1    45000020
         STM   R2,R3,IOLIST        SET UP IO PARM LIST                  45060020
         LCR   R1,R1               MAKE NEGATIVE TO SHOW MSG            45120020
         BAL   R7,LSTIO2           GO OUTPUT MSG.                       45180020
         B     LSTCC0              RETURN FOR NEXT DATA                 45240020
MSGMOVE1 MVC   ZERO(NULL,R14),ZERO(R2)  MOVES MSG'S TO THE BUFFER       45300020
         TITLE 'IKJEGLSA, ''LIST'', ZONED DECIMAL FORMATTING ROUTINE'   45360020
*********************************************************************** 45420020
*                                                                     * 45480020
*  AFTER BEING SETUP BY THE COMMON ROUTINE, CONTROL IS PASSED TO THIS * 45540020
*  ROUTINE IF THE FORMAT IS TO BE ZONED. ENTRY IS AS FOLLOWS          * 45600020
*        TO LSTZ50 FOR RELATIVE AND ABSOLUTEADDRESSES                 * 45660020
*        TO LSTZ54 FOR SYMBOLIC ADDRESSES WITH MULTIPLE OUTPUT LINES  * 45720020
*        TO LSTZ58 FOR SYMBOLIC ADDRESSES WITH ONLY ONE OUTPUT LINE   * 45780020
*                                                                     * 45840020
*  THIS ROUTINE VALIDITY CHECKS THE DATA TO ASSURE ZONED FORMAT, MOVES* 45900020
*  THE CORRECT SIGN TO THE BUFFER, THE DATA TO THE BUFFER, AND SETS   * 45960020
*  THE ZONE FIELD OF THE RIGHTMOST BYTE.                              * 46020020
*                                                                     * 46080020
*********************************************************************** 46140020
         SPACE                                                          46200020
LSTZ50   EQU   *                                                        46260020
         L     R6,OUTBUF           GET PTR TO THE OUTPUT BUFFER         46320020
         LA    R6,DATAOFF(R6)      INCRE BUFFER PTR PAST LL00 FIELD     46380020
LSTZ52   EQU   *                                                        46440020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  46500020
LSTZ54   EQU   *                                                        46560020
         SR    R0,R0               R0=0                                 46620020
         LA    R1,APDE             R1=ADDR OF ADDRESS PDE               46680020
         L     R15,TSTCONVT        ADDR OF CONVERT ROUTINE              46740020
         BCTR  R0,NULL             R0=-1 TO INDICATE CONVERT TO PRNTBL  46800020
         LCR   R1,R1               R1=NEG TO INDICATE ADDR CONVERSION   46860020
         BALR  R14,R15             GO TO CONVERT ROUTINE                46920020
         LTR   R15,R15             TEST RETURN CODE FROM IKJEGCVT       46980020
         BNZ   LSTCVTRC            IF NON-ZERO, GO ANALYZE              47040020
         L     R3,CONAREA          R3=ADDR OF CONVERT OUTPUT AREA       47100020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R3)  MOVE ADDRESS TO BUF        47160020
         LA    R6,ADDRLEN(R6)      INCREMENT BUF PTR PAST ADDR          47220020
LSTZ58   EQU   *                                                        47280020
         LH    R15,VPDEL           R15=DATA FIELD LENGTH                47340020
         LR    R3,R15              SAVE A COPY OF THE LENGTH            47400020
         BCTR  R15,NULL            REDUCE LENGTH BY 1 FOR SS INSTR      47460020
         L     R1,VPDEPT           R1=PTR TO DATA                       47520020
         SR    R2,R2               CLEAR A REG                          47580020
         IC    R2,ZERO(R15,R1)     PICK UP LAST BYTE OF DATA FIELD      47640020
         CH    R2,SIGNPAT          TEST FOR VAL ZONE                    47700020
         BL    LSTZ90              IF SIGN FLD LESS THAN X'A0', BRANCH  47760020
         SRL   R2,FOUR             DISCARD RIGHT HALF OF BYTE           47820020
         IC    R2,SIGNTBL(R2)      PICK UP CORRECT SIGN                 47880020
         STC   R2,SP2(R6)          PLACE SIGN IN BUFFER                 47940020
         LA    R6,SP2+SIGNLEN(R6)  INCREMENT BUF PTR PAST SIGN          48000020
         AR    R15,R1              R15=ADDR OF LAST DATA BYTE IN BUF    48060020
         MVZ   ZERO(ONE,R15),VALZONE   MOVE A VALID ZONE TO SIGN BYTE   48120020
         LR    R15,R3              SET SAVED COPY OF THE DATA LENGTH    48180020
         LA    R3,ZERO(R3,R1)      INCREMENT DATA PTR TO NEXT DATA      48240020
         ST    R3,VPDEPT           SAVE UPDATED PTR                     48300020
         SPACE                                                          48360020
*  NEXT, ELIMINATE LEADING ZEROS (EXCEPT IF CONSTANT EQUALS).           48420020
         SPACE                                                          48480020
         BCT   R15,LSTZ66          IF LNTH GREATER THAN ONE, BRANCH     48540020
LSTZ62   EQU   *                                                        48600020
         EX    R15,ZDATAMVC        MOVE DATA TO BUF                     48660020
         LA    R15,ONE(R15)        INCREMENT DATA LNTH BY ONE           48720020
LSTZ64   EQU   *                                                        48780020
         CLI   ZERO(R6),CHAR0      CHAR MUST BE 0 OR GREATER            48840020
         BL    LSTZ90              IF LOW, BRANCH                       48900020
         CLI   ZERO(R6),CHAR9      CHAR MUST BE 9 OR LESS               48960020
         BH    LSTZ90              IF GREATER THAN 9, ERROR, BRANCH     49020020
         LA    R6,ONE(R6)          INCREMENT BUF PTR TO NEXT DATA       49080020
         BCT   R15,LSTZ64          DECRE REMAINING LNTH, TEST FOR DONE  49140020
         BAL   R7,LSTIO            IF DONE, GO OUTPUT DATA              49200020
         BCT   R4,LSTZ52           TEST FOR MORE TO DO                  49260020
         B     LSTCC0              GO TO COMPLETION ROUTINE             49320020
         SPACE                                                          49380020
LSTZ66   EQU   *                                                        49440020
         CLI   ZERO(R1),CHAR0      IS THIS CHAR A ZERO                  49500020
         BNE   LSTZ62              IF NOT, BRANCH                       49560020
         LA    R1,ONE(R1)          INCREMENT DATA PTR TO NEXT BYTE      49620020
         BCT   R15,LSTZ66          DECRE BYTE COUNT AND CHECK FOR DONE  49680020
         B     LSTZ62              IF ONLY ONE BYTE REMAINS, BRANCH     49740020
         SPACE                                                          49800020
LSTZ90   EQU   *                                                        49860020
         L     R2,LSTMSG           GET ADDR OF MSG CSECT                49920020
         LM    R2,R3,MSG06(R2)     PICK UP 1ST AND 2ND LEVEL MSG        49980020
         B     LSTGEN94            GO COMPLETE MESSAGE SETUP            49981020
         SPACE                                                          50290020
ZDATAMVC MVC   ZERO(NULL,R6),ZERO(R1)  FOR MOVING RAW DATA TO BUFFER    50340020
         TITLE 'IKJEGLSA, ''LIST'', BINARY FORMATTING ROUTINE'          50400020
*********************************************************************** 50460020
*                                                                     * 50520020
*  THE FOLLOWING SUBROUTINE LIST AREAS OF CORE IN THE BINARY OUTPUT   * 50580020
*  FORMAT. CONVERSION TO PRINTABLE IS DONE IN THIS ROUTINE.           * 50640020
*********************************************************************** 50700020
LSTBIN   EQU   *                                                        50760020
         TM    COMFLGS,TWOADDRS    TEST FOR 1 OR 2 ADDRESSES            50820020
         BO    LSTB20              IF TWO, BRANCH                       50880020
         SR    R0,R0               R0=0                                 50940020
         CH    R0,A1M              WAS A MULTIPLICITY GIVEN             51000020
         BNE   LSTB04              IF GIVEN, BRANCH                     51060020
         MVI   A1M+H2ND,ONE        DEFAULT MULTIPLICITY TO ONE          51120020
LSTB04   EQU   *                                                        51180020
         CH    R0,A1L              WAS A LNTH GIVEN                     51240020
         BNE   LSTB06              IF GIVEN, BRANCH                     51300020
         MVI   A1L+H2ND,ONE        DEFAULT LENGTH TO ONE                51360020
LSTB06   EQU   *                                                        51420020
         BAL   R14,LSTLMTCK        GO CHECK UPPER ADDR OF THIS REQUEST  51470020
         LTR   R15,R15             IS REMAINING MULTIPLICITY ZERO       51472020
         BNZ   LSTB80              IF ZERO, BRANCH                      51474020
         LH    R4,A1M              SET UP CONTROL                       51480020
         LH    R5,A1L              SET UP LENGTH CTR                    51540020
LSTB10   EQU   *                                                        51600020
         TM    A1FLG,A1SYM         WAS ADDR SYMBOLIC, REL, OR ABS.      51660020
         BZ    LSTB12              IF ADDRESS IS ABSOLUTE, BRANCH       51720020
         BO    LSTB40              IF SYMBOLIC, BRANCH                  51780020
         SPACE                                                          51840020
*  IF THE ADDRESS TYPE IS RELATIVE, FALL THRU AND SET UP FOR RELATIVES  51900020
         SPACE                                                          51960020
         MVC   APDE(APL),IKJPARMA  MOVE ORIGINAL PDE TO WORK AREA       52030020
LSTB12   EQU   *                                                        52080020
         LA    R1,A1               GET PTR TO INPUT DATA ADDRESS        52140020
         ST    R1,APDE+(PDEADRPT-IKJPARMA) SET UP PTR IN ADDRESS PDE    52200020
         L     R6,OUTBUF           GET PTR TO THE OUTPUT BUFFER         52260020
         LA    R6,DATAOFF(R6)      INCRE BUFFER PTR PAST LL00 FIELD     52320020
LSTB52   EQU   *                                                        52380020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  52440020
         LA    R1,APDE             R1=ADDR OF ADDRESS PDE               52500020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          52560020
         SR    R0,R0               ZERO REG                             52610020
         BCTR  R0,NULL             MAKE REG 0 NEG FOR CONVERT TO PRINT  52620020
         LCR   R1,R1               R1=NEG, SHOW CONVERT AN ADDRESS      52680020
         BALR  R14,R15             GO TO CONVERT ROUTINE                52740020
         LTR   R15,R15             TEST RETURN CODE FROM CONVERT        52800020
         BNZ   LSTCVTRC            IF NON-ZERO, GO ANALYZE FURTHER      52860020
         L     R3,CONAREA          R3=ADDR OF CONVERT OUTPUT AREA       52920020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R3)  MOVE CONVERTED ADDR TO BUF 52980020
         LA    R6,ADDRLEN(R6)      INCRE BUF PTR PAST ADDR FIELD        53040020
LSTB58   EQU   *                                                        53100020
         LA    R1,BFLDLEN+SP2(R6)  COMPUTE BUF PTR AFTER 1 FLD + 2 SP'S 53160020
         C     R1,ENDOBUF          WILL A DATA BYTE FIT.                53220020
         BNH   LSTB60              IF MORE DATA WILL FIT, GO PROCESS    53280020
         BAL   R7,LSTIO            IF DATA WONT FIT, GO OUTPUT BUF      53340020
         B     LSTB52              GO CONVERT ANOTHER ADDR              53400020
         SPACE                                                          53460020
LSTB60   EQU   *                                                        53520020
         L     R1,VPDEPT           R1=PTR TO CUR BYTE OF INPUT DATA     53580020
         LA    R15,EIGHT           SET UP LOOP CONTROL                  53640020
         LA    R2,HEX80            INITIALIZE TEST MASK                 53700020
         LA    R6,SP2(R6)          INCRE BUF PTR FOR 2 BLANKS           53760020
LSTB62   EQU   *                                                        53820020
         EX    R2,BTM              TEST BIT FOR 1 OR 0                  53880020
         BO    LSTB68              IF ONE, BRANCH                       53940020
         MVI   ZERO(R6),CHAR0      MOVE A ZERO TO THE BUF FOR THIS BIT  54000020
LSTB64   EQU   *                                                        54060020
         LA    R6,BDATALEN(R6)     INCRE BUF PTR PAST DATA              54120020
         SRL   R2,ONE              MOVE MASK TO TEST NEXT BIT           54180020
         BCT   R15,LSTB62          TEST FOR DONE                        54240020
         LA    R1,BDATALEN(R1)     INCREMENT DATA PTR TO NEXT BYTE      54300020
         ST    R1,VPDEPT           SAVE UPDATED DATA ADDRESS            54360020
         BCT   R5,LSTB58           IF MORE BYTES TO DO,BRANCH           54420020
         BAL   R7,LSTIO            ELSE, GO OUTPUT BUF                  54480020
         LH    R5,A1L              RELOAD LENGTH IN CASE MORE TO LIST   54540020
         BCT   R4,LSTB52           IF MULTIPLICITY NOT ZERO DO MORE     54600020
         B     LSTCC0              IF DONE, RETURN TO MAIN ROUTINE      54660020
LSTB68   EQU   *                                                        54720020
         MVI   ZERO(R6),CHAR1      MOVE A ONE TO THE BUF FOR THIS BIT   54780020
         B     LSTB64              RETURN TO INCRE PTRS                 54840020
BTM      TM    ZERO(R1),NULL       FOR TESTING BITS FOR 0 OR 1.         54900020
         SPACE                                                          54960020
LSTB20   EQU   *                                                        55020020
         L     R1,A1               GET START ADDR                       55080020
         L     R5,A2               GET ENDING ADDR                      55140020
         BCTR  R1,NULL             DECREMENT A1 TO GET INCLUSIVE LENGTH 55200020
         SR    R5,R1               COMPUTE LNTH, R5 IS LNTH CNTRL REG   55260020
         STH   R5,A1L              STORE LENGTH FOR LATER               55310020
         LA    R4,ONE              SET MULTIPLICITY CONTROL TO 1.       55320020
         B     LSTB10              GO SET UP ADDRESSES.                 55380020
         SPACE                                                          55440020
LSTB40   EQU   *                                                        55500020
         BAL   R7,LSTSYM           GO INITIALIZE BUF WITH SYMBOL        55560020
         B     LSTB58              GO TO BINARY PROCESS ROUTINE         55620020
         SPACE                                                          55670020
LSTB80   EQU   *                                                        55672020
         LH    R5,LASTLEN          AMT OF REQUEST STILL IN CORE         55674020
         LA    R4,ONE              SET MULTIPLICITY CNTRL TO ONE        55678420
         STH   R4,A1M              SAVE MULTIPLICITY CNTRL              55678820
         STH   R5,A1L              SAVE REMAINING LENGTH                55679220
         B     LSTB10              GO LIST QUANTITY WITHIN CORE         55679620
         TITLE 'IKJEGLSA, ''LIST'', INSTRUCTION FORMATTING ROUTINE'     55680020
*********************************************************************** 55740020
*                                                                     * 55800020
*  THIS ROUTINE WILL OUTPUT DATA IN THE INSTRUCTION FORMAT.           * 55860020
*  CONTROL CAN BE BY LNTH (INCLUDING RANGE), BY MULTIPLICITY, OR BY   * 55920020
*  BOTH, WITH THE ROUTINE ENDING WHEN EITHER MULTIPLICITY REACHES 0,  * 55980020
*  OR WHEN THE NEXT-INSTR-ADDR IS INCRE PAST THE STOP ADDRESS.       *  56040020
*  WITHIN THE PROCESS SECTION (BEGINS AT LSTI50) REGS AND CONTROLS    * 56100020
*  ARE SET AS FOLLOWS.                                                * 56160020
*                                                                     * 56220020
*        R2    CONTAINS THE STOP ADDR                           A45476* 56270021
*        R3    CONTAINS THE CURRENT TRUE DATA ADDRESS                 * 56280020
*        R4    CONTAINS THE MULTIPLICITY OR 32767.                    * 56340020
*        R5    CONTAINS A COUNTER FOR REFRESHING HOLDAREA.            * 56400020
*        R6    IS THE CURRENT BUFFER PTR                        A45476* 56460021
*                                                                     * 56580020
*********************************************************************** 56640020
LSTINSTR EQU   *                                                        56760020
         STC   R15,VPDET           TYPE CODE TO VALUE PDE.              56820020
         L     R3,A1               SET UP CURRENT TRUE DATA ADDR        56880020
         LA    R3,ZERO(ZERO,R3)    CLEAR HIGH ORDER BYTE FOR CALCULATE  56930020
         TM    COMFLGS,TWOADDRS    IF ADDRESS RANGE WAS NOT GIVEN 5476  56940021
         BNO   LSTI05               ... THEN BRANCH             A45476  56990021
*  PROCESS ADDRESS RANGE                                        A45476  56992021
         L     R2,A2               SET 2ND ADDRESS IN ANTICIPATION      57000020
         LA    R2,ONE(R2)          ADD 1 TO MAKE RANGE INCULSIVE        57050020
         LH    R4,MAXHWRD          SET MULTI=32767 FOR LOOP CONTROL 76  57052021
         B     LSTI20                                           A45476  57060021
*  PROCESS SINGLE ADDRESS                                       A45476  57070021
LSTI05   DS    0H                                               A45476  57110021
         SR    R15,R15             CONSTANT OF 0 FOR COMPARE            57120020
         LH    R4,A1M              R4=MULTPLICITY OR 0                  57180020
         LH    R2,A1L              R2=LENGTH OR 0                       57300020
         TM    LSTFLGS,LNTHFLG     IF LENGTH WAS GIVEN          A45476  57350021
         BO    LSTI06              ... THEN BRANCH               A45476 57400021
         TM    LSTFLGS,MULTIFLG    IF MULTIPLICITY WAS NOT GIVEN A45476 57450021
         BNO   LSTI06              ... THEN BRANCH               A45476 57500021
         LH    R2,MAXHWRD          SET LENGTH=32767 FOR LOOP CONTROL 76 57550021
         B     LSTI07                                            A45476 57560021
LSTI06   DS    0H                                                A45476 57600021
         LH    R4,MAXHWRD          SET MULTI=32767 FOR LOOP CONTROL 476 57650021
LSTI07   DS    0H                                                A45476 57700021
         AR    R2,R3               CALCULATE STOP ADDR AS ADDR1+LENGTH  58440020
LSTI20   EQU   *                                                        58500020
         C     R2,TSTTOP           IS STOP ADDRESS OUT OF CORE          58510020
         BNH   LSTI21              IF STOP ADDR WITHIN CORE, BRANCH     58520020
         L     R2,TSTTOP           GET HIGHEST CORE ADDR FOR STOPPER    58530020
         LA    R2,ONE(ZERO,R2)     INCRE BY ONE FOR USE AS A STOPPER    58532020
         EJECT                                                   A45476 58534021
LSTI21   EQU   *                                                        58540020
         ST    R2,A2               ADDR2 IS STOP ADDR                   58560020
         TM    A1FLG,A1SYM         TEST ADDR TYPE                       58620020
         BZ    LSTI22              IF ADDRESS IS ABSOLUTE, BRANCH       58680020
         BO    LSTI40              IF SYMBOLIC, BRANCH                  58740020
         SPACE                                                          58800020
*  IF THE ADDRESS TYPE IS RELATIVE, FALL THRU AND SET UP FOR RELATIVES  58860020
         SPACE                                                          58920020
         MVC   APDE(APL),IKJPARMA  MOVE ORIGINAL PDE TO WORK AREA       58990020
LSTI22   EQU   *                                                        59040020
         LA    R2,APDE+PDEUSER-IKJPARMA    GET PTR TO DATA ADDRESS      59100020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) STORE IT IN THE ADDR PDE     59160020
         B     LSTI50              GO PROCESS.                          59220020
         SPACE                                                          59280020
LSTI40   EQU   *                                                        59340020
         BAL   R7,LSTSYM           GO MOVE SYM TO BUF                   59400020
         LA    R2,APDE+PDEUSER-IKJPARMA    GET PTR TO DATA ADDRESS      59410020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) STORE IT IN THE ADDR PDE     59420020
         TM    COMFLGS,TWOADDRS    TEST FOR 1 OR 2 ADDRS                59430020
         L     R2,CONAREA          GET ADDR OF CONVERT OUTPUT AREA      59460020
         BO    LSTI42              IF AN ADDR RANGE WAS USED, BRANCH    59490020
         LA    R15,ONE             MAKE A CONSTANT OF 1 FOR COMPARISON  59491020
         CH    R15,A1M             IF MULTIPLICITY GT ONE        A45476 59500021
         BL    LSTI42              ...THEN BRANCH                A45476 59510021
         ST    R3,APDE+PDEUSER-IKJPARMA    STORE CURRENT DATA ADDR      59512220
         TM    LSTFLGS,LNTHFLG      IF ONLY ONE INSTR TO LIST,   A45476 59512321
         BNO   LSTI54               ...THEN BRANCH               A45476 59512521
         EJECT                                                   A45476 59513021
LSTI42   EQU   *                                                        59516120
         BAL   R7,LSTIO            GO OUTPUT SYMBOLIC ADDRESS           59517020
         B     LSTI51              GO PROCESS LIST REQUEST      SA52082 59518021
         SPACE 2                                                        59580020
*  PROCESS ADDRESS FOR THE FIRST LINE OF OUTPUT.                        59640020
         SPACE                                                          59700020
LSTI50   EQU   *                                                        59760020
         L     R6,OUTBUF           GET PTR TO THE OUTPUT BUFFER         59770020
         LA    R6,DATAOFF(R6)      INCREMENT BUF PTR PAST LL00  FIELD   59780021
         BAL   R14,LSTBPT          GO REMOVE BREAKPOINT SVC'S FROM DATA 59781020
         L     R2,CONAREA          ADDR OF CONVERT OUTPUT AREA  SA52082 59781221
LSTI51   DS    0X                                                       59781821
         LA    R5,L'HOLDAREA/SIX   SET UP COUNTER FOR DATA IN H SA52082 59782021
LSTI52   EQU   *                                                        59790020
         ST    R3,APDE+PDEUSER-IKJPARMA    STORE CUR DATA ADDRESS       59800020
         SR    R0,R0               R0=0                                 59940020
         LA    R1,APDE             R1=ADDR OF THE ADDRESS PDE           60000020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          60060020
         BCTR  R0,NULL             MAKE R0 NEG FOR CONVERT TO PRINTABLE 60120020
         LCR   R1,R1               R1 NEG TO SHOW ADDR CONVERSION       60180020
         BALR  R14,R15             GO TO CONVERT ROUTINE                60240020
         LTR   R15,R15             TEST RETURN CODE.                    60300020
         BNZ   LSTCVTRC            IF NON-ZERO, BRANCH                  60360020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R2)  CONVERTED DATA TO BUF      60480020
         LA    R6,ADDRLEN(R6)      INCRE BUF PTR PAST LL00 FIELD        60540020
         EJECT                                                          60660021
*  CONVERT ONE INSTRUCTION, AND MOVE IT INTO THE BUFFER.                60720021
LSTI54   EQU   *                                                        60850020
         LA    R1,VPDE             ADDR OF THE VALUE PDE                60900020
         L     R15,TSTCONVT        ADDR OF CONVERT ROUTINE.             60960020
         BALR  R14,R15             GO TO CONVERT ROUTINE                61020020
         LTR   R15,R15             TEST RETURN CODE                     61080020
         BNZ   LSTI80              IF NON-ZERO, BRANCH                  61140020
         IC    R15,CONLNTH(R2)     PICK UP LENGTH OF CONVERTED DATA     61200020
         BCTR  R15,NULL            DECREMENT LNTH FOR MVC INSTR         61440020
         EX    R15,INSTRMVC        MOVE CONVERTED DATA TO BUF           61500020
         LA    R6,ONE+SP4(R15,R6)  INCRE BUF PTR PAST DATA AND SPACES   61560020
         SPACE                                                          61620020
*  NEXT, INCREMENT THE POINTERS PAST THE INSTRUCITON JUST PROCESSED.    61680020
         SPACE                                                          61740020
LSTI66   EQU   *                                                        61800020
         L     R15,VPDEPT          R15=ADDR OF DATA JUST CONVERTED      61860020
         TM    ZERO(R15),INSTRLEN  TEST INSTR LENGTH FOR 2, 4, OR 6     61920020
         BM    LSTI68              IF INSTR BEGINS 10 OR 01, LNTH=4, GO 61980020
         LA    R15,TWO(R15)        INCRE DATA PTR BY 2 IF LNTH 2 OR 6   62040020
         LA    R3,TWO(R3)          ALSO INCRE TRUE ADDR BY 2            62100020
         BZ    LSTI70              IF INSTR BEGINS 00, LNTH=2, BRANCH   62160020
         SPACE                                                          62220020
*  IF THE INSTRUCITON BEGINS 11, THE LNTH=6, 2 HAS ALREADY BEEN ADDED   62280020
*  SO FALL THRU AND ADD 4 MORE. THIS INSTR IS BRANHCED TO IF LNTH=4.    62340020
         SPACE                                                          62400020
LSTI68   EQU   *                                                        62460020
         LA    R15,FOUR(R15)       INCRE DATA PTR BY 4 IF LNTH 4 OR 6   62520020
         LA    R3,FOUR(R3)         ALSO INCRE TRUE ADDR BY 4            62580020
LSTI70   EQU   *                                                        62640020
         C     R3,A2               COMPARE UPDATED ADDR TO STOP ADDR    62700020
         ST    R15,VPDEPT          STORE UPDATED ADDR IN VALUE PDE      62760020
         BNL   LSTI74              IF PAST LIMIT, BRANCH TO FINALE      62820020
         BCT   R4,LSTI64           IF CONTROL-1 NOT ZERO, DO ANOTHER    62880020
LSTI74   EQU   *                                                        62940020
         BCTR  R3,NULL             DECRE ADDR TO TEST FOR OUT-OF-CORE   62950020
         C     R3,TSTTOP           WAS LISTING STOPPED BY TOP OF CORE   62990020
         BH    LSTI78              IF INSTR IN BUF OUT-OF-CORE, BRANCH  62992020
         BAL   R7,LSTIO            GO OUTPUT FINAL DATA                 63000020
         B     LSTCC0              RETURN TO MAIN ROUTINE               63060020
         SPACE                                                          63110020
LSTI78   EQU   *                                                        63112020
         OI    COMFLGS,OUTCORE     SET REQUEST EXTENDS OUT OF CORE SW   63116020
         B     LSTCC0              GO TO COMPLETION ROUTINE             63118020
         EJECT                                                          63120021
LSTI64   EQU   *                                                        63180020
         BAL   R7,LSTIO            GO OUTPUT DATA                       63240020
         BCT   R5,LSTI52           IF MODE DATA IN HOLDAREA, BRANCH     64090020
         BAL   R14,LSTBPT          GO REMOVE BREAKPOINT SVC'S           64140020
         LA    R5,L'HOLDAREA/SIX   RESET HOLDAREA COUNTER               64150020
         B     LSTI52              GO UPDATE THE CURRENT DATA ADDRESS   64200020
         SPACE                                                          64260020
LSTI80   EQU   *                                                        64320020
         C     R15,FFOUR           IS THE RETURN CODE 4                 64380020
         BNE   LSTCVTRC            IF NOT 4, GO ANALYZE                 64440020
         SPACE                                                          64750020
*  IF THE RETURN CODE WAS 4, AN INVALID OP CODE WAS ENCOUNTERED, AND    64760020
*     A MESSAGE INDICATING WHERE MUST BE PUT OUT.                       64770020
         SPACE                                                          64780020
         L     R15,OUTBUF          GET START ADDRESS OF OUTPUT BUFFER   64790020
         LR    R14,R15             SAVE START ADDRESS OF BUFFER         64790120
         LA    R15,DATAOFF(R15)    INCREMENT ADDRESS PAST LL00 FIELD    64791020
         SR    R6,R15              CALCUALTE LENGTH OF ADDRESS IN BUF   64792020
         SPACE                                                          64794020
*  NEXT, BYPASS ANY LEADING BLANKS IN THE ADDRESS ALREADY IN THE BUF.   64795020
         SPACE                                                          64796020
LSTI84   EQU   *                                                        64796120
         BCTR  R6,NULL             REDUCE LENGTH BY ONE FOR MVC INSTR   64797020
         CLI   ZERO(R15),BLANK     IS THE NEXT CHARACTER IN BUF A BLANK 64798020
         BNE   LSTI86              IF NOT A BLANK, BRANCH               64799020
         LA    R15,ONE(R15)        INCREMENT BUF ADDR TO NEXT CHAR      64799120
         B     LSTI84              LOOP BACK TO CHECK NEXT CHARACTER    64799220
         SPACE                                                          64799320
LSTI86   EQU   *                                                        64799420
         L     R2,LSTMSG           ADDR OF MSG CSECT                    64800020
         LM    R2,R3,MSG07(R2)     PICK UP PTRS TO 1ST AND 2ND LVL MSGS 64870020
         LH    R4,ZERO(R2)         PICK UP LENGTH OF 1ST LEVEL MSG      64880020
         BCTR  R4,NULL             DECREMENT LENGTH BY 1 FOR MVC INSTR  64890020
         EX    R4,MSGMOVE2         MOVE MESSAGE TO BUFFER               64900020
         LA    R2,MSGOFFST(R14)    INCREMENT PTR TO MSG AREA            64910020
         LA    R14,MSGOFFST+ONE(R4,R14) INCREMENT BUF PTR PAST MESSAGE  64911020
         EX    R6,MSGMOVE3         MOVE ADDRESS INTO 1ST LVL MSG        64913020
         LA    R6,TWO(R6,R4)       CALCUALTE TOTAL LENGTH OF MSG        64914020
         STH   R6,ZERO(R2)         STORE LENGTH IN MSG LENGTH FIELD     64915020
         B     LSTGEN94            GO COMPLETE IO RTN SETUP             64931020
         SPACE                                                          64932020
MSGMOVE2 MVC   MSGOFFST(NULL,R14),ZERO(R2)   MOVES 1ST LEVEL MSG TO BUF 64940020
MSGMOVE3 MVC   ZERO(NULL,R14),ZERO(R15)    MOVES ADDRESS INTO MESSAGES  64950020
INSTRMVC MVC   SP4(NULL,R6),CONDATA(R2)  MOVES INSTRUCTIONS TO BUF      64980020
         TITLE 'IKJEGLSA, ''LIST'', LSTIO SUBROUTINE FOR OUTPUT'        65100020
*********************************************************************** 65160020
*                                                                     * 65220020
*  THES ROUTINE SETS UP THE PTRS AND CALLS IKJEGIO1 TO OUTPUT A LINE  * 65280020
*  OF DATA. AT ENTRY, THE FOLLOWING REGS ARE SET.                     * 65340020
*        R6  POINTS TO THE NEXT AVAILABLE BYTE IN THE BUFFER          * 65400020
*        R7  HAS THE RETURN POINT ADDRESS                             * 65460020
*                                                                     * 65520020
*  THE CONTENTS OF REGS 0, 1, 6, 14, AND 15 ARE MODIFIED BY THIS RTN  * 65580020
*                                                                     * 65640020
*********************************************************************** 65700020
         SPACE                                                          65760020
LSTIO    EQU   *                                                        65820020
         LA    R1,IOLIST           SET UP PTR TO 2 WORD LIST            65880020
         LR    R15,R6              R15=PTR TO 'END OF DATA'+1           65940020
         L     R6,OUTBUF           R6=PTR TO BEGINNING OF BUF           66000020
         SR    R15,R6              CALCULATE LENGTH OF DATA             66060020
         STH   R15,F1STHALF(R6)    LNTH TO 1ST HALF WORD OF BUFFER      66120020
         SPACE                                                          66180020
*  COMMON PORTION OF IO ROUTINE.                                        66240020
LSTIO1   EQU   *                                                        66300020
         TM    TSTFLGS1,TSTPRINT+TSTFIRST  IS OUTPUT TO A DS 1ST TIME   66360020
         L     R15,TPUTADDR        SET UP ADDRESS OF IKJEGIO1           66420020
         BM    FIRSTIO             IF OUTPUT TO DS 1ST TIME, BRANCH     66480020
         SR    R0,R0               IF NOT 1ST TIME, INDICATE SO BY R0=0 66540020
LSTIO4   EQU   *                                                        66600020
         BALR  R14,R15             GO TO IKJEGIO1                       66660020
         MVI   DATAOFF(R6),BLANK   MOVE A BLANK TO START OF DATA AREA   66720020
         MVC   DATAOFF+ONE(LSTBUFL,R6),DATAOFF(R6)     BLANK OUT BUFFER 66780020
         LA    R6,DATAOFF(R6)      INCRE BUF PTR PAST LL00 FIELD        66840020
         LTR   R15,R15             TEST RETURN CODE                     66900020
         BCR   EQZERO,R7           IF ZERO, RETURN TO CALLER            66960020
         TM    COMFLGS,PARSEFLG    IS THIS A PARSE EXIT                 67020020
         BCR   ONE,R7              IF PARSE EXIT, RETURN TO IT.         67080020
         CH    R15,H16             IF RC=16, BRANCH                     67140020
         BE    LSTCC16             IF RC=16, BRANCH                     67200020
         XC    LSTRETCD,LSTRETCD   SET THE RETURN CODE TO 0             67260020
         B     LSTMN90             GO CLEAN UP AND RETURN               67320020
         SPACE                                                          67380020
*********************************************************************** 67440020
*                                                                     * 67500020
*  THIS ROUTINE IS ENTERED AT THIS POINT WITH R1=COMPLIMENT OF THE    * 67560020
*  ADDRESS OF THE TWO WORD LIST IF OUTPUT IS A MESSAGE.               * 67620020
*                                                                     * 67680020
*********************************************************************** 67740020
LSTIO2   EQU   *                                                        67800020
         L     R6,OUTBUF           SET R6 TO POINT AT OUTPUT BUF        67860020
         B     LSTIO1              GO TO COMMON PART OF IO ROUTINE      67920020
         SPACE                                                          67980020
FIRSTIO  EQU   *                                                        68040020
         L     R14,TSTANSPL        PICK UP BASE ADDR FOR PARSE DSECT    68100020
         USING IKJPARMD,R14        ADDRESSABILITY FOR THE PDL           68160020
         LA    R0,DSNAME           SET UP PTR TO THE DSNAME PDE         68220020
         OI    TSTFLGS1,TSTFIRST   SET FIRST TIME SWITCH TO 1           68280020
         DROP  R14                                                      68340020
         B     LSTIO4              RETURN TO MAIN IO ROUTINE            68400020
         TITLE 'IKJEGLSA, ''LIST'', GENERAL USE SUBROUTINES'            68460020
*********************************************************************** 68520020
*                                                                     * 68580020
*  THIS CLOSED SUBROUTINE CHECKS SEGMENTS OF CORE FOR INSERTED BREAK- * 68640020
*  POINTS AND REPLACES THEM WITH THE ORIGINAL CONTENTS OF THE LOCATION* 68700020
*  THE ROUTINE MOVES THE NEXT 32 BYTES TO BE LISTED TO A WORKAREA AND * 68760020
*  SCANS THE BREAK ELEMENT QUEUE FOR ANY BREAK POINT SVC'S WITHIN THE * 68820020
*  32 BYTE FIELD. WHEN A BREAKPOINT SVC IS FOUND TO BE IN THE RANGE,  * 68880020
*  THE ORIGINAL INSTRUCTION IS MOVED (1ST 2 BYTES) INTO WORK AREA OVER* 68940020
*  THE BREAKPOINT SVC.  REGISTERS ARE SAVED AND RESTORED.          *    69000020
*  INPUT A1=ORIGINAL START ADDR OF DATA IN HOLD AREA                  * 69060020
*        VPDEPT=ADDR OF NEXT BY OF HOLD AREA TO BE LISTED             * 69120020
*                                                                     * 69180020
*********************************************************************** 69240020
         SPACE                                                          69300020
LSTBPT   EQU   *                                                        69360020
         SAVE  (14,12)             STANDARD SAVE                        69420020
         SPACE                                                          69480020
*  CALCULATE THE NEW DATA ADDRESS.                                      69540020
         SPACE                                                          69600020
         L     R3,VPDEPT           GET ADDR OF NEXT BYTE OF HOLDAREA    69660020
         LA    R5,HOLDAREA         SET UP START ADDR OF HOLDING CORE    69720020
         SR    R3,R5               DETERMINE NUMBER OF BYTES USED       69780020
         A     R3,A1               INCRE INPUT CORE ADDR BY AMT LISTED  69840020
         LA    R4,LSTIBLK(R3)      ESTABLISH ADDR OF END OF NEXT BLK    69900020
         C     R4,TSTTOP           IS END ADDR GREATER THAN HIGHEST     69960020
         BH    LSTBPT30            IF OUT OF CORE, BRANCH TO ADJUST RTN 70020020
         LA    R1,LSTIBLK          USE STANDARD LENGTH FOR HOLD DATA    70080020
LSTBPT04 EQU   *                                                        70140020
         EX    R1,HOLDMVC          MOVE DATA TO HOLDING AREA            70200020
         SPACE                                                          70260020
*  IF THE DATA ADDRESS IS NOT ON A HALF WORD BOUNDARY, R0 WILL CONTAIN  70320020
*  A ONE (1), IF THE DATA ADDRESS IS ON A HALFWORD BOUNDARY, R0 WILL    70380020
*  CONTAIN A ZERO (0). THE CONTENTS OF R0 WILL THEN BE USED TO ADJUST   70440020
*  THE DATA ADDRESS AND THE HOLDAREA ADDRESS. THIS ADJUSTMENT IS TO     70500020
*  TAKE CARE OF THE CASE WHERE THE DATA START ADDRESS IS THE SECOND     70560020
*  BYTE OF A BREAKPOINT.                                                70620020
         SPACE                                                          70680020
         LA    R0,ONE              SET THE LOW ORDER BIT ON IN REG 0    70740020
         NR    R0,R3               TEST DATA ADDRESS FOR A HALFWORD BDY 70800020
         SR    R3,R0               ADJUST DATA START ADDRESS IF NEEDED  70860020
         SR    R5,R0               MAKE SAME CHANGE FOR HOLDAREA ADDR   70920020
         L     R6,BREAKTAB         GET PTR TO FIRST BREAK ELEMENT       70980020
         USING BRKELEM,R6          ADDRESSABILITY FOR KREAK ELEMENT     71040020
         LTR   R6,R6               IS THERE A 1ST BREAK ELEMENT         71100020
         BP    LSTBPT12            IF THERE IS A BREAK ELEMENT, BRANCH  71160020
         B     LSTBPT20            IF NONE, RETURN                      71220020
         SPACE                                                          71280020
LSTBPT08 EQU   *                                                        71340020
         L     R6,BRKLINK          PICK UP FOREWARD PTR                 71400020
         LTR   R6,R6               TEST FOR ANOTHER                     71460020
         BNP   LSTBPT20            IF NO MORE, BRANCH                   71520020
LSTBPT12 EQU   *                                                        71580020
         C     R3,BRKADDR          COMPARE START ADDR TO BREAKPOINT     71640020
         BH    LSTBPT08            IF BRK-PT LOW, NOT IN RANGE, BRANCH  71700020
         C     R4,BRKADDR          COMPARE END ADDR TO BREAKPOINT       71760020
         BNL   LSTBPT40            IF END ADDR HI OR EQ, ADDR IN RANGE  71820020
LSTBPT20 EQU   *                                                        71880020
         AR    R3,R0               RE-ADJUST DATA ADDRESS AS NEEDED     71940020
         AR    R5,R0               DO THE SAME FOR HOLD AREA ADDRESS.   72000020
         ST    R3,A1               SAVE ACTUAL CORE ADDR OF CUR DATA    72060020
         ST    R5,VPDEPT           RESET VALUE PDE TO PT AT HOLD AREA   72120020
         RETURN (14,12)            RETURN TO CALLER                     72180020
         SPACE                                                          72240020
LSTBPT30 EQU   *                                                        72300020
         L     R1,TSTTOP           PICK UP HIGHEST CORE ADDR            72360020
         LR    R4,R1               SET TOP ADDR AS TOP OF CORE          72420020
         SR    R1,R3               DETERMINE REMAINING LENGTH IN BYTES  72480020
         B     LSTBPT04            RETURN TO MAIN LSTBPT FLOW           72540020
         SPACE                                                          72600020
*  IF A BREAK POINT IS FOUND IN THE RANGE, THE FOLLOWING CODE           72660020
*  WILL REPLACE THE BREAK POINT SVC WITH THE ORIGINAL INSTRUCTION       72720020
         SPACE                                                          72780020
LSTBPT40 EQU   *                                                        72840020
         L     R2,BRKADDR          R2=ADDR OF BREAKPOINT SVC            72900020
         SR    R2,R3               DETERMINE OFFSET INTO HOLD AREA,     72960020
         AR    R2,R5               ADD THE ADDR OF HOLDAREA             73020020
         SPACE                                                          73080020
*  R2 NOW POINTS TO THE SVC INSTRUCTION IN THE HOLD AREA. TEST WHETHER  73256420
*    THE BREAK ELEMENT IS STILL ACTIVE.                                 73256820
         SPACE                                                          73257220
         TM    BRKFLGS1,BRKINACT   IS THIS BREAK ELEMENT STILL ACTIVE   73257620
         BO    LSTBPT08            IF NOT, BRANCH                       73257720
         SPACE                                                          73257820
*  IF THE BREAK ELEMENT IS STILL ACTIVE, REPLACE THE BREAKPOINT SVC     73257920
*    WITH THE DATA FROM THE BREAK ELEMENT.                              73273420
         SPACE                                                          73289020
         MVC   ZERO(TWO,R2),BRKINST        REPLACE SAVED INSTR          73304520
         B     LSTBPT08            RETURN TO SEARCH LOOP                73320020
HOLDMVC  MVC   HOLDAREA(NULL),ZERO(R3) MOVE SEGMENT OF CORE TO HOLD.    73380020
         DROP  R6                                                       73440020
         EJECT                                                          73500020
*********************************************************************** 73560020
*                                                                     * 73620020
*  GENERAL SUBROUTINE FOR MOVING SYMBOLIC ADDRESSES TO THE OUTPUT BUF * 73680020
*        AT ENTRY,  R6 SHOULD POINT TO FIRST BYTE OF OUTPUT AREA      * 73740020
*                   R7 POINTS TO RETURN POINT.                        * 73800020
*********************************************************************** 73860020
         SPACE                                                          73920020
LSTSYM   EQU   *                                                        73980020
         OI    APDE+(PDEFLG2-IKJPARMA),CTNAMFLG TURN ON 'QUALIFIED' SW  74040020
*  TURN RELATIVE ADDR FLAG ON, AND ABSOLUTE ADDR SW OFF                 74100020
         XI    APDE+(PDEFLG4-IKJPARMA),RELADDR+ABSADDR                  74160020
         LA    R2,A1               GET ADDR OF INPUT DATA PTR           74220020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) PUT IT IN THE ADDRESS PDE    74280020
         L     R6,OUTBUF           GET PTR TO START OF OUTPUT BUFFER    74340020
         LA    R6,DATAOFF(R6)      INCREMENT PTR PAST LL00 FIELD        74400020
         BAL   R14,LSTAMV          GO MOVE THE ADDRESS TO THE BUFFER    74460020
         L     R15,A1              R15=START ADDR OF DATA               74520020
         ST    R15,PPTEMP          MAKE START OF DATA ADDR BASE FOR REL 74580020
         SR    R0,R0               R0=0                                 74640020
         BCTR  R0,NULL             MAKE REG 0 NEG FOR CNVRT TO PRINT    74700020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  74760020
         BR    R7                  RETURN TO CALLER                     74820020
         EJECT                                                          74870020
*********************************************************************** 74872020
*  THIS ROUTINE WILL ADD THE PRODUCT OF THE LENGTH AND MULTIPLICITY   * 74872420
*  TO THE START ADDRESS AND COMPARE THE SUM TO 'TSTTOP'. IF THE       * 74872820
*  SUM EXCEEDS 'TSTTOP', A NEW MULTIPLICITY IS CALCULATED AND SWITCH  * 74873220
*  'OUTCORE' IN COMFLGS IS SET, THE NUMBER OF BYTES NOT OUT           * 74873620
*  OF CORE IS PLACED 'LASTLEN', AND THE CALCULATED MULTIPLICITY IS    * 74873720
*  STORED IN 'A1M'.                                                   * 74873820
*  RETURN CODES---   4  IF 'NEW' MULTIPLICITY IS ZERO                 * 74873920
*                    0  FOR ALL OTHER CASES.                          * 74923920
*********************************************************************** 74973920
LSTLMTCK EQU   *                                                        74983920
         SAVE  (0,12)                                                   74993920
         L     R2,A1               GET DATA START ADDR                  75003920
         LH    R3,A1L              GET LENGTH FOR THIS REQUEST          75013920
         LA    R2,ZERO(ZERO,R2)    CLEAR HIGH BYTE FOR CALCULATION      75015920
         MH    R3,A1M              MULTIPLY  (LENGTH X MULTIPLICITY)    75017920
         AR    R3,R2               ADD START ADDR TO LENGTH OF REQUEST  75019920
         BCTR  R3,NULL             DECREMENT TO MAKE EXCLUSIVE          75020320
         C     R3,TSTTOP           COMPARE POTENTIAL END ADDR TO TOP    75021920
         BH    LSTLMT20            IF REQUEST GOES OUT OF CORE, BRANCH  75022320
LSTLMT10 EQU   *                                                        75022720
         SR    R15,R15             SET RETURN CODE TO ZERO              75023120
LSTLMT14 EQU   *                                                        75023520
         RETURN  (0,12)                                                 75023620
         SPACE                                                          75023720
LSTLMT20 EQU   *                                                        75023820
         L     R5,TSTTOP           GET LAST MACHINE ADDRESS             75073820
         SR    R4,R4               CLEAR EVEN REG FOR DIVIDE            75083820
         LH    R3,A1L              GET LENGTH FOR THIS REQUEST          75093820
         SR    R5,R2               TOP ADDR - START ADDR                75103820
         LA    R5,ONE(ZERO,R5)     MAKE LASTLEN INCLUSIVE               75105820
         DR    R4,R3               DIVIDE BYTES IN CORE BY LENGTH       75113820
         STH   R5,A1M              SET NEW MULTIPLICITY                 75115820
         STH   R4,LASTLEN          SAVE NO. OF BYTES IN CORE            75117820
         OI    COMFLGS,OUTCORE                                          75119820
         LTR   R5,R5               WAS REMAINING MULTI ZERO             75121820
         BNZ   LSTLMT10            IF NOT, BRANCH                       75122220
         LA    R15,FOUR            SET RETURN CODE TO FOUR              75122320
         B     LSTLMT14            GO RETURN WITH A RC=4                75122620
         SPACE                                                          75122720
LSTOUT   EQU   *                                                        75123020
         L     R2,LSTMSG              PTR TO MSG CSECT                  75123420
         LM    R2,R3,MSG08(R2)        PTRS TO FIRST AND SECOND LEVEL    75123520
         STM   R2,R3,IOLIST           PUT INTO PARM LIST                75123620
         LA    R1,IOLIST              PTR TO PARM LIST                  75123720
         LCR   R1,R1                  INDICATE THIS IS A MESSAGE        75173720
         B     LSTIO2                 GO TO I/O ROUTINE                 75183720
         EJECT                                                          75223720
*********************************************************************** 76800020
*                                                                     * 76860020
*  GENERAL SUBROUTINE FOR MOVING ADDRESSES TO THE OUTPUT BUFFER.      * 76920020
*        AT ENTRY,  R6 SHOULD POINT TO THE NEXT AVAILABLE BUFFER BYTE * 76980020
*                   R8 SHOULD CONTAIN THE ADDRESS OF THE ADDR PDE.    * 77040020
*        AT-EXIT,   R6 CONTAINS THE UPDATED BUFFER PTR, AND           * 77100020
*                   THE OUTPUT BUFFER CONTAINS THE ADDRESS STRING.    * 77160020
*                                                                     * 77220020
*********************************************************************** 77280020
LSTAMV   EQU   *                                                        77340020
         SAVE  (14,12)             SAVE CALLERS REGS                    77400020
         TM    PDEFLG1,LDNAMFLG    WAS A LOADNAME USED                  77460020
         BZ    LSTAMV04                IF NOT, BRANCH                   77520020
         LH    R2,PDELEN1          PICK UP LENGTH OF LOAD NAME          77580020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR.    77640020
         L     R15,PDELDNAM        PICK UP PTR TO LOAD NAME             77700020
         EX    R2,SYMMOVE          MOVE SYMBOL TO BUFFER                77760020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST NAME          77820020
LSTAMV04 EQU   *                                                        77880020
         TM    PDEFLG2,CTNAMFLG    WAS ENTRY NAME SPECIFIED             77940020
         BZ    LSTAMV08                IF NOT, BRANCH                   78000020
         MVI   ZERO(R6),PERIOD     MOVE IN ENTRY NAME PREFIX            78060020
         LA    R6,L'PERIOD(R6)     INCREMENT BUF PTR PAST PREFIX        78120020
         LH    R2,PDELEN2          GET LENGTH OF ENTRY NAME AND         78180020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR.    78240020
         L     R15,PDECTNAM        PICK UP PTR TO ENTRY NAME            78300020
         EX    R2,SYMMOVE          MOVE NAME TO OUTPUT AREA             78360020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST ENTRY NAME    78420020
         TM    PDEFLG4,CTONLY      IS ADDR TYPE STAND ALONE ENTRYNAME   78480020
         BO    LSTAMV16                IF STAND ALONE ENTRYNAME, BRANCH 78540020
         MVI   ZERO(R6),PERIOD     MOVE IN SYMBOL SEPARATOR             78600020
         LA    R6,L'PERIOD(R6)     INCREMENT BUF PTR PAST PREFIX        78660020
LSTAMV08 EQU   *                                                        78720020
         LH    R2,PDELEN3          PICK UP LENGTH OF WYMBOL AND         79080020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR.    79140020
         L     R15,PDEADRPT        R15=PTR TO SYMBOL                    79200020
         EX    R2,SYMMOVE          MOVE SYMBOL TO OUTPUT AREA           79260020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST SYMBOL        79320020
LSTAMV16 EQU   *                                                        79380020
         ST    R6,R6OFF(R13)       MODIFY REG 6 CONTENTS (IN SAVE AREA) 79440020
         RETURN (14,12)            RETRUN TO CALLER WITH HIS REGS       79500020
         SPACE                                                          79560020
SYMMOVE  MVC   ZERO(NULL,R6),ZERO(R15)  FOR MOVING NAMES TO BUFFER      79620020
DATAMOVE MVC   SP2(NULL,R6),CONDATA(R3) MOVES CONVERTED DATA TO BUFFER  79740020
         SPACE 2                                                        79750020
*********************************************************************** 79790020
*                                                                       79792020
*        STAE RETRY ROUTINE                                             79794020
*                                                                       79846020
*********************************************************************** 79848020
         SPACE 3                                                        79848420
RETRY    EQU   *                                                        79848520
         L     R4,CVTPTR           PTR TO CVT                           79851520
         USING CVTDSECT,R4         ADDRESSABILITY FOR CVT               79851920
         L     R4,CVTTCBP          TCB PTR                              79852320
         L     R4,FOUR(R4)         CURRENT TCB PTR                      79852720
         DROP  R4                                                       79852820
         USING TCB,R4              TCB ADDRESSABILITY                   79852920
         L     R9,TCBTRN           TCOMTAB PTR                          79853020
         L     R13,REGSAVE2        PTR TO SAVE AREA                     79853120
         LM    R10,R12,R10OFF(R13)     RESTORE MODULE ADDRESSABILITY    79853220
         LTR   R0,R0               WAS WORKSPACE FREED                  79854920
         BNZ   LSTFREE             GO TO FREE WORKSPACE                 79857920
         FREEMAIN R,LV=104,A=(R1)  FREE WORKSPACE                       79860920
LSTFREE  EQU   *                                                        79863920
         LA    R15,TWENTY          INDICATE ERROR RETURN                79866920
         ST    R15,LSTRETCD        SAVE RETURN CODE                     79869920
         B     LSTMN90             RETURN                               79879920
         EJECT                                                          79880021
*                                                                       79890021
*  ERROR SUBROUTINE                                                     79892021
*                                                                       79894021
PRC16    DS    0H                                                       79896021
         LA    R3,MSG03      LOAD ADDR OF ERROR MESSAGE                 79896421
PRCMSGS  DS    0H                                                       79896821
         L     R2,LSTMSG     GET ADDR OF MSG CSECT                      79897221
         LA    R2,0(R3,R2)   ADD OFFSET TO MSG ADCON                    79897621
         LM    R2,R3,0(R2)   PLACE ADDR OF MESSAGES INTO                79901521
         STM   R2,R3,IOLIST  ...IO PARAMETER LIST                       79903521
         LA    R1,IOLIST     LOAD ADDR OD IO PARAMETER LIST             79903921
         LCR   R1,R1         INDICATE OUTPUT IS MSG                     79904321
         BAL   R7,LSTIO2     CALL OUTPUT ROUTINE                        79904721
         B     LSTMN90       GO TO EXIT ROUTINE                         79905121
         EJECT                                                          79905521
LSTMSG   DC    V(IKJEGMSB)         PTR TO MSG CSECT                     79909421
RETRYAD  DC    A(RETRY)            PTR TO STAE RETRY ROUTINE            79913320
FFOUR    DC    F'4'                CONSTANT OF 4, GENERAL USE           79920020
         DS    0F                                                       79980020
SPMASK   DC    X'01000000'         SUBPOOL NUMBER MASK FOR FREEMAIN     80040020
HONE     DC    H'1'                CONSTANT OF 1, GENERAL USE           80100020
H16      DC    H'16'               CONSTANT OF 16, GENERAL USE          80160020
H32      DC    H'32'               CONSTANT OF 32                       80220020
MAXHWRD  DC    H'32767'            MAX POSITIVE HALFWORD VALUE          80280020
         SPACE                                                          80330020
SMTLABL  DS    0H                  SMT TEST LABEL FOR XCTL MACRO        80330420
LST      DC    C'LST'              CONSTANT USED BY MAINLINE BLDL RTNE  80332020
         SPACE                                                          80340020
         ORG   *-HEX0A             ACCOUNT FOR X'00H TO X'09' IN TABLE  80400020
SIGNTBL  EQU   *                   TABLE FOR CONVERTING A ZONE TO SIGN  80460020
         ORG   *+HEX0A             RESET LOC CTR TO ACTUAL TABLE        80520020
         DC    C'+-+-++'           ACTUAL SIGN TABLE                    80580020
         SPACE                                                          80640020
         DS    0H                                                       80700020
SIGNPAT  DC    X'00A0'             USED TO TEST FOR VALID SIGN          80760020
VALZONE  DC    C'0'                USED TO GET A NUMERIC ZONE           80820020
         SPACE 2                                                        80880020
*********************************************************************** 80890020
*                                                                     * 80900020
*  THIS TABLE IS USED TO CONVERT THE HEX TYPE CODES TO THEIR CHARACTER  80940020
*  EQUIVALENT FOR PLACING THE FORMAT TYPE IN MESSAGES.                  81000020
*                                                                     * 81010020
*********************************************************************** 81020020
         SPACE                                                          81060020
LSTTYPE  DC    C'CXBIFHEDAYSVPZ'   EBCDIC FOR DATA TYPE CODES           81120020
         EJECT                                                          81180020
*********************************************************************** 81240020
*                                                                       81300020
*  THE FOLLOWING TABLE IS USED TO TRANSLATE UNPRINTABLE CHARACTERS    * 81360020
*  TO PERIODS (.) SO THAT THEY WILL BE ACCEPTABLE TO THE TERMINAL.    * 81420020
*  USED WHEN OUTPUT TYPE IS 'C'.                                      * 81480020
*********************************************************************** 81540020
         SPACE                                                          81600020
TRTABLE  EQU   *                                                        81660020
         DC    256C'.'             ALL CHARS NOT OTHERWISE DEFINED ='.' 81720020
         ORG   TRTABLE+X'40'       BLANK OR SPACE                       81790020
         DC    AL1(*-TRTABLE)      DEFINE                               81840020
         ORG   TRTABLE+X'4A'       CENT, PERIOD, LT, LEFT PAREND,       81850020
*                                  PLUS, VERTICAL BAR, AMPERSAND        81860020
         DC    7AL1(*-TRTABLE)     DEFINE                               81870020
         ORG   TRTABLE+X'5A'       EXCLAMATION, DOLLAR, PERIOD,         81880020
*                                  RIGHT PAREND, SEMICOLON,             81890020
*                                  LOGICAL NOT, DASH, SLASH             81900020
         DC    8AL1(*-TRTABLE)     DEFINE                               81910020
         ORG   TRTABLE+C','        COMMA, PERCENT, UNDERLINE, GT, QUES. 81920020
         DC    5AL1(*-TRTABLE)     DEFINE                               82200020
         ORG   TRTABLE+C':'        COLON, LB., AT, APSTRPHE, EQ, DBL Q. 82280020
         DC    6AL1(*-TRTABLE)     DEFINE                               82320020
         ORG   TRTABLE+C'A'-C' '   LOWER CASE 'A' TO 'I'                82380020
         DC    9AL1(*-TRTABLE)     DEFINE                               82440020
         ORG   TRTABLE+C'J'-C' '   LOWER CASE 'J' TO 'R'                82500020
         DC    9AL1(*-TRTABLE)     DEFINE                               82560020
         ORG   TRTABLE+C'S'-C' '   LOWER CASE 'S' TO 'Z'                82620020
         DC    8AL1(*-TRTABLE)     DEFINE                               82680020
         ORG   TRTABLE+C'A'        UPPER CASE 'A' TO 'I'                82740020
         DC    9AL1(*-TRTABLE)     DEFINE                               82800020
         ORG   TRTABLE+C'J'        UPPER CASE 'J' TO 'R'                82860020
         DC    9AL1(*-TRTABLE)     DEFINE                               82920020
         ORG   TRTABLE+C'S'        UPPER CASE 'S' TO 'Z'                82980020
         DC    8AL1(*-TRTABLE)     DEFINE                               83040020
         ORG   TRTABLE+C'0'        NUMERALS '0' TO '9'                  83100020
         DC    10AL1(*-TRTABLE)    DEFINE                               83160020
         ORG   TRTABLE+256         SET LOCATION CTR TO END OF TRTABLE   83220020
         EJECT                                                          83280020
*********************************************************************** 83340020
*                                                                       83400020
*                                                                       83460020
*  ---NOTICE---  THIS DSECT IS A COPY OF THE ONE PRODUCED BY THE PARSE  83520020
*                MACROS IN IKJEGLST. THIS DSECT MUST BE UPDATED         83580020
*                WHENEVER THE PARSE MACROS ARE CHANGED OR WHEN THEIR    83640020
*                EXPANSION CHANGES.                                     83700020
*********************************************************************** 83760020
IKJPARMD DSECT                                                          83820020
         DS    2A                  CHAIN PTR                            83880020
ADDR1    DS    9A                  ADDRESS PDE FOR 1ST ADDR OF RANGE    83940020
         DS    9A                  ADDRESS PDE FOR 2ND ADDR OF RANGE    84000020
         DS    A                   CHAIN ADDRESS                        84060020
TYPE     DS    AL2                 TYPE KEYWORD PDE                     84120020
LATTR    DS    AL2                 LENGTH ATTRIBUTE PDE                 84180020
MATTR    DS    AL2                 MULTIPLICITY ATTRIBUTE PDE           84240020
PRINT    DS    AL2                 PRINT KEYWORD PDE                    84300020
LENGTH   DS    2A                  LENGTH SUBFIELD                      84360020
MULTI    DS    2A                  MULTIPLICITY SUBFIELD                84420020
DSNAME   DS    6A                  DSNAME SUBFIELD OF PRINT KEYWORD     84480020
         DS    0D                  ALIGNMENT FOR STORAGE PURPOSES       84540020
         SPACE                                                          84600020
IKJEGLSA CSECT                                                          84660020
         EJECT                                                          84720020
LSTWORK  DSECT                                                          84780020
         SPACE                                                          84840020
*********************************************************************** 84900020
*                                                                     * 84960020
*  ---NOTICE---                                                       * 85020020
*                                                                     * 85080020
***** THERE IS A DUPLICATE OF THIS DSECT IN IKJEGLST AND ANY CHANGES ** 85140020
*****  TO THE DSECT MUST BE MADE IN BOTH MODULES.                    ** 85200020
*                                                                     * 85260020
*  THIS DSECT MAPS A SECTION OF THE COMMON WORKING CORE POINTED TO    * 85320020
*  BY 'WORKAREA' IN TCOMTAB.                                          * 85380020
*                                                                     * 85440020
*********************************************************************** 85500020
         SPACE                                                          85560020
DWORK    DS    D                   DOUBLE WORD WORKAREA                 85620020
         ORG   DWORK               USE WORK AREA FOR XCTL LIST          85680020
LXCTL1   DS    2A                  LIST PARM LIST FOR XCTL              85740020
PARSEPL  DS    7F                  PARSE CALLING PARAMETER LIST.        85800020
         ORG   PARSEPL             REUSE CORE USED BY PARSE PARM LIST   85860020
LSTRPT   EQU   *                   START OF SECTION REUSED FOR ADDR LST 85920020
APDE     DS    9F                  WORKING COPY OF THE ADDRESS PDE      85980020
A1       DS    A                   CONTAINS CURRENT ADDR OF INPUT       86040020
A1LMATTR DS    F                   LENGTH AND MULTIPLICITY FACTORS      86100020
         ORG   A1LMATTR            PLACE LNTH AND MULTI IN ONE FULLWORD 86160020
A1L      DS    H                   LENGTH                               86220020
A1M      DS    H                   MULTPLICITY FACTOR                   86280020
A1FLG    DS    X                   FLAG BYTE FOR ADDR1 INFORMATION      86340020
A1FPD    EQU   X'80'               FLOATING PT DBL                      86400020
A1FPE    EQU   X'40'               FLOATING PT SINGLE                   86460020
A1GEN    EQU   X'20'               GENERAL REG                          86520020
A1REG    EQU   X'10'               ADDRESS 1 IS A REG.                  86580020
         SPACE                                                          86640020
A1ABS    EQU   X'00'               ADDR IS ABSOLUTE                     86700020
A1SYM    EQU   X'03'               ADDR IS SYMBOLIC                     86760020
A1REL    EQU   X'01'               ADDR IS RELATIVE                     86820020
         SPACE                                                          86880020
A1TYPE   DS    X                   CONTAINS TYPE CODE FOR ADDR1         86940020
REMAIN   DS    H                   REMAINDER                            87000020
A2       DS    A                   SECOND ADDR IF A RANGE WAS GIVEN     87060020
ARTIFMUL DS    H                   VALUE OF ARTIFICIAL MULTIPLICITY     87120020
REMAIN2  DS    H                   BACKUP COPY OF REMAINDER             87180020
REGSTART DS    F                   START ADDR OF REG SAVE AREA TO LIST  87240020
LSTRETCD DS    F                   HOLDS RETURN CODE                    87300020
LASTLEN  DS    H                   CONTAINS REMAINDER FROM LSTLMTCK     87350020
COMFLGS  DS    X                   FLAG BYTES FOR PROCESS CONTROL       87360020
TWOADDRS EQU   X'80'               1 INDICATE ADDR RANGE                87420020
ARTIMSW  EQU   X'40'               1 INDICATE CONTROL IS ARTIFICIAL     87480020
NOINDENT EQU   X'20'               1 INDICATES DATA NOT TO BE INDENTED  87540020
SECOND   EQU   X'10'               1 INDICATES PROCESSING 2ND GROUP     87600020
WRAPSW   EQU   X'08'               1 INDICATES 2ND REG LOWER THAN 1ST   87660020
PARSEFLG EQU   X'04'               SW SHOWS IO REQUESTED BY PARSE EXIT  87720020
OUTCORE  EQU   X'02'               REQUEST EXTENDS OUT OF CORE          87770020
DATASIZE EQU   X'01'               SYMBOLIC FOR NUMBER OF HEX FLDS/GRP  87772020
         SPACE                                                          87780020
*  THE FOLLOWING FIELDS DEFINE A VALUE PDE FOR CONVERTING DATA.         87840020
VPDE     DS    0F                  VALUE PDE FOR CONVERTING DATA        87900020
VPDEPT   DS    A                   PTR TO DATA                          87960020
VPDEL    DS    H                   LENGTH OF DATA FOR CONVERSION        88020020
VPDEFLG  DS    X                   FLAGS                                88080020
VPDET    DS    X                   HEX TYPE CODE FOR VALUE.             88140020
         SPACE                                                          88200020
RPTSIZE  EQU   *-LSTRPT            LNTH OF REUSED SECTION.              88260020
LMATTR   DS    F                   LENGTH AND MULTIPLICITY FACTOR FLD'S 88320020
         ORG   LMATTR              PLACE LNTH AND MULTI IN ONE FULLWORD 88380020
BINLEN   DS    H                   CONVERTED LENGTH GIVEN BY USER       88440020
BINMUL   DS    H                   CONVERTED MLTPLCTY GIVEN BY USER     88500020
LXCTL    XCTL  ,SF=L               RESERVE SPACE FOR LIST FORM OF XCTL  88560020
ENDOBUF  DS    A                   CONTAINS MAX BUF ADDR + 1            88620020
ENDOGRP  DS    A                   CONTAINS GROUP STOP ADDRESS          88680020
IOLIST   DS    2F                  MSG PTR LIST FOR IKJEGIO1            88740020
         SPACE                                                          88800020
TYPESAVE DS    X                   CONTAINS SPECIFIED OR DEFAULTED TYPE 88860020
RETRYSAV DS    AL3                 CONTAINS MAINLINES STAE RETRY ADDR   88910020
LSTFLGS  DS    X                   FLAG BYTES TO SAVE PARSE DATA        88920020
TYPEFLG  EQU   B'10000000'         SET TO ONE IF TYPE KEYWORD USED      88980020
LNTHFLG  EQU   B'01000000'         SET TO ONE IF LENGTH KEYWORD USED    89040020
MULTIFLG EQU   B'00100000'         SET TO ONE IF MULTIPLICITY GIVEN     89100020
         SPACE                                                          89160020
         DS    X                   SPILL BYTE FOR HOLDAREA  ON ODD ADDR 89220020
         DS    0D                  ALIGN HOLDAREA                       89280020
HOLDAREA DS    XL32                HOLDS DATA BEING CONVERTED CURRENTLY 89340020
STAELIST STAE  MF=L                                                     89390020
         SPACE                                                          89400020
LWLNTH   EQU   *-LSTWORK           LENGTH OF DSECT                      89460020
         EJECT                                                          89520020
IKJEGMSB CSECT                                                          89580020
         SPACE                                                          89640020
*  MESSAGE CSECT FOR IKJEGLST, LIST SUB-CMD OF TEST.                  * 89700020
*  THE FIRST SECTION CONTAINS ADCONS FOR THE FIRST AND SECOND LEVEL   * 89760020
*  MESSAGES. THE ADCONS ARE IN PAIRS WITH THE 2ND =0 IN THERE IS NO   * 89820020
*  SECOND LEVEL MSG.                                                  * 89880020
         SPACE                                                          89940020
LSTM05   DC    A(MD)               INVALID LENGTH MSG, 1ST LEVEL        90660020
         DC    A(0)                    NO 2ND LEVEL FOR THIS ONE        90720020
         SPACE                                                          90780020
LSTM06   DC    A(ME)               INVALID DATA MSG, 1ST LEVEL          90840020
         DC    A(0)                    NO 2ND LEVEL FOR THIS ONE        90900020
         SPACE                                                          90910020
LSTM07   DC    A(MF)               INVALID INSTRUCTION CODE MSG, 1ST    90920020
         DC    A(0)                    NO 2ND LEVEL MSG FOR THIS ONE    90930020
         SPACE                                                          90932020
LSTM03   DC    A(MC)               LIST FAILED, COMMAND SYSTEM ERR MSG  90940020
         DC    A(0)                    BECAUSE OF INSUFFIENT STORAGE    90950020
         SPACE                                                          90952020
LSTM08   DC    A(MA)               LIST REQUEST INCOMPLETE MSG          90954020
         DC    A(MA1)                  BECAUSE MAX VALID ADDR EXCEEDED  90956020
         SPACE 2                                                        90960020
         DS    0H                                                       92640020
MD       DC    AL2(MDE-MD)         LENGTH OF ENTIRE MESSAGE             92700020
         DC    AL2(0)              OFFSET FIELD                         92760020
         DC    C'IKJ57243I INVALID LENGTH FOR TYPE S'       MSG TEXT    92820020
MDE      EQU   *                                                        92880020
MD1      EQU   *                                                        92940020
         SPACE                                                          93000020
         DS    0H                                                       93060020
ME       DC    AL2(MEE-ME)         LENGTH OF ENTIRE MESSAGE             93120020
         DC    AL2(0)              OFFSET FIELD                         93180020
         DC    C'IKJ57244I INVALID DATA FOR TYPE Z'         MSG TEXT    93240020
MEE      EQU   *                                                        93300020
ME1      EQU   *                                                        93360020
         SPACE                                                          93370020
         DS    0H                                                       93380020
MF       DC    AL2(MFE-MF)         LENGTH OF ENTIRE MESSAGE             93390020
         DC    AL2(0)              OFFSET FIELD                         93400020
         DC    C'IKJ57245I INVALID INSTRUCTION CODE AT '     MSG TEXT   93410020
MFE      EQU   *                                                        93411020
MF1      EQU   *                                                        93412020
         SPACE                                                          93412120
         DS    0H                                                       93412420
MC       DC    AL2(MCE-MC)         LENGTH OF ENTIRE MESSAGE             93412820
         DC    AL2(0)              OFFSET FIELD                         93412920
         DC    C'IKJ57248 NOT ENOUGH MAIN STORAGE TO'  MSG TEXT         93426720
         DC    C' EXECUTE COMMAND'                     MSG TEXT CONY    93427120
MCE      EQU   *                                                        93428320
         SPACE                                                          93434020
         DS    0H                                                       93436020
MA       DC    AL2(MAE-MA)         LENGTH OF ENTIRE MSG                 93438020
         DC    AL2(0)              OFFSET FIELD                         93438420
         DC    C'IKJ57246I LIST REQUEST INCOMPLETE+'   MSG TEXT         93438520
MAE      EQU   *                                                        93438620
         SPACE                                                          93438720
         DS    0H                                                       93441120
MA1      DC    AL2(MA1E-MA1)       LENGTH OF ENTIRE MSG                 93443120
         DC    AL2(0)              OFFSET FIELD                         93443520
         DC    C'IKJ57246I REQUEST EXCEEDED '   TEXT MSG 08, 2ND LEVEL  93446820
         DC    C'GREATEST VALID ADDRESS'        TEXT CONTINUED          93447220
MA1E     EQU   *                                                        93458720
         TITLE 'IKJEGLSA, ''LIST'', TCOMTAB, COMMUNICATIONS DSECT'      93460020
         TCOMTAB                                                        93463320
         TITLE 'IKJEGLSA, ''LIST'', IKJPARMA, ADDRESS PDE MAP DSECT'    93466620
         IKJPARMA                                                       93480020
APL      EQU   PDECHAIN-IKJPARMA   SYMBOLIC LENGTH OF AN ADDRESS PDE    93540020
         TITLE 'IKJEGLSA, ''LIST'', BRKELEM, BREAK ELEMENT MAP DSECT'   93550020
         BRKELEM                                                        93600020
CVTDSECT DSECT                                                          93650020
         CVT                                                            93652020
         IKJTCB                                                         93654020
         END                                                            93660020
