         TITLE 'IKJEGLST, ''LIST'' SUBCOMMAND OF TEST, FIRST LOAD'      00060020
*********************************************************************** 00120020
*                                                                       00240020
* STATUS--VERSION NO. 01, OS/360 RELEASE NO. 20                         00300020
*                                                                       00360020
* FUNCTION--                                                            00650020
*    THIS MODULE IS THE FIRST LOAD OF THE 'LIST' SUBCOMMAND OF TEST.    00652020
*    IT IS ENTERED INITIALLY WHENEVER A LIST SUBCOMMAND IS ENCOUNTERED  00656020
*    BY THE TEST MAINLINE ROUTINE. THE LIST SUBCOMMAND OF TEST          00658020
*    DISPLAYS REQUESTED AREAS OF MAIN STORAGE AND/OR THE GENERAL        00658420
*    AND FLOATING POINT REGISTERS. THIS MODULE PREFORMS THE LIST        00658820
*    INITIALIZATION FUNCTION, THE LIST IN HEXADECIMAL FORMAT FUNCTION,  00659220
*    AND THE LIST GENERAL AND FLOATING POINT REGISTERS FUNCTION.        00659620
*                                                                       00660020
* ENTRY POINTS--                                                        00720020
*         IKJEGLST                                                      00780020
*         1. ENTERED FROM TEST MAINLINE FOR THE LIST SUB-CMD.           00840020
*         2. ENTERED FROM IKJEGLSA WITH 'PCHLSTVL' SW IN TSTFLGS1       00900020
*         SET TO ONE IF THE NEXT ADDRESS IN AN ADDRESS LIST             00960020
*         IS REGISTER TYPE OR IF THE FORMAT TYPE IS HEX (X).            01020020
*         IKJPARSE  TO PARSE THE CUBCOMMAND BUFFER.                     01070020
*                                                                       01080020
* INPUT--                                                               01140020
*   ONE LINE OF INPUT FROM TERMINAL IN INPUT BUFFER.                    01200020
*                                                                       01260020
* OUTPUT--                                                              01430020
*    LINES TO THE TERMINAL DISPLAYING REQUESTED DATA, OR, IF THE        01432020
*    PRINT KEYWORD WAS SPECIFIED, THE DATA IS WRITTEN TO A DATA SET.    01434020
*                                                                       01440020
* EXTERNAL REFERENCES--                                                 01560020
*         IKJEGCVT  FOR CONVERSION OF ADDRESSES AND DATA FROM MACHINE   01790020
*         FORMAT TO PRINTABLE FORMAT. FOR CONVERSION OF ADDRESSES,      01792020
*         CVT IS ENTERED WITH THE HIGH ORDER BIT OF REG 0 SET TO ONE    01794020
*         AND REGISTER 1 CONTAINING THE COMPLEMENT OF THE ADDRESS OF    01796020
*         AN ADDRESS PDE. THE ADDRESS PDE DESCRIBES THE ADDRESS TO BE   01798020
*         CONVERTED. FOR DATA CONVERSIONS, REG 0 IS SET TO ZERO, AND    01798420
*         REG 1 CONTAINS THE ADDRESS OF A VALUE PDE DESCRIBING THE      01798820
*         DATA TO BE CONVERTED.                                         01799220
*                                                                       01799620
*         IKJEGIO  TO OUTPUT DATA TO THE TERMINAL OR TO A PRINT DATA    01799720
*         SET, AND TO OUTPUT MESSAGES TO THE TERMINAL. TO OUTPUT DATA,  01799820
*         REG 1 CONTAINS THE ADDRESS OF A 2 WORD LIST, THE FIRST WORD   01799920
*         CONTAINS THE ADDRESS OF A DATA BUFFER AND THE SECOND WORD     01819920
*         CONTAINS BINARY ZEROS. FOR MESSAGES, REG 1 CONTAINS THE       01829920
*         COMPLEMENT OF THE ADDRESS OF A 2 WORD LIST. THE FIRST WORD    01839920
*         HAS A POINTER TO THE FIRST LEVEL MESSAGE AND THE SECOND WORD  01846620
*         HAS A POINTER TO THE SECOND LEVEL MESSAGE OR IS BINARY ZERO.  01848620
*         IKJPARSE  TO PARSE THE SUB-COMMAND CHAIN.                     01860020
*                                                                       01920020
* EXITS, NORMAL--                                                       02270020
*         BRANCH REGISTER 14 TO THE ORIGINAL CALLER OF LIST WHEN THE    02272020
*         LAST ADDRESS PDE HAS BEEN PROCESSED.                          02274020
*         XCTL TO IKJEGLSA IF TYPE ATTRIBUTE IS ONE OF THE FOLLOWING-   02276020
*         A, B, C, D, E, F, H, I, P, Q, S, V, Y, OR Z.                  02278020
*                                                                       02280020
* EXITS, ERROR--                                                        02340020
*         NONE                                                          02400020
*                                                                       02460020
* TABLES/WORK AREAS --                                                  02520020
*    TCOMTAB  POINTED AT BY REG 9, IS THE COMMUNICATIONS TABLE FOR THE  02570020
*    TEST PROCESSOR.                                                    02572020
*                                                                       02574020
*    LSTWORK  THE MAPPING DSECT FOR THE WORK AREA USED BY IKJEGLST AND  02576020
*    IKJEGLSA. IT HOLDS WORKING COPIES OF THE ATTRIBUTES, ADDRESSES     02578020
*    FOR THE DATA CURRENTLY BEING LISTED, PARAMETER LISTS FOR CALLING   02578420
*    VARIOUS ROUTINES, AND A DATA BUFFER FOR REMOVING BREAKPOINT SVC'S  02578820
*                                                                       02579220
*    PARAMETER DESCRIPTOR LIST  (PDE) SET UP BY PARSE                   02579620
*                                                                     * 02880020
* ATTRIBUTES--                                                          02940020
*    REENTRANT, REFRESHABLE, PROBLEM PROGRAM.                           03000020
*                                                                       03050020
* CHARACTER CODE DEPENDENCY--                                           03052020
*                                                                       03054020
* NOTES--                                                               03056020
*                                                                       03060020
*********************************************************************** 03180020
         TITLE 'IKJEGLST, ''LIST'', EUQATES'                            03240020
IKJEGLST CSECT                                                          03300020
         SPACE 1                                                        03360020
*********************************************************************** 03420020
         SPACE 1                                                        03480020
*  REGISTER EQUATES.                                                    03540020
         SPACE                                                          03600020
R0       EQU   0                   WORK REG                             03660020
R1       EQU   1                   PARAMETER REG                        03720020
R2       EQU   2                   WORK REG                             03780020
R3       EQU   3                   WORK REG                             03840020
R4       EQU   4                   IN PROCESS SECTION, LENTH CNTRL CTR  03900020
R5       EQU   5                   WORK REG                             03960020
R6       EQU   6                   IN PROCESS SECTION, CUR BUF PTR      04020020
R7       EQU   7                   INTERNAL LINKAGE REGISTER            04080020
R8       EQU   8                   POINTS TO CURRENT ADDRESS PDE        04140020
R9       EQU   9                   BASE FOR TCOMTAB DSECT               04200020
R10      EQU   10                  BASE FOR LSTWORK DSECT               04260020
R11      EQU   11                  *** SPARE REGISTER, FOR MAINTAINANCE 04320020
R12      EQU   12                  PROGRAM BASE REGISTER                04380020
R13      EQU   13                  PROGRAM SAVE AREA                    04440020
R14      EQU   14                  EXTERNAL LINKAGE REGISTER            04500020
R15      EQU   15                  EXTERNAL LINKAGE REGISTER            04560020
         SPACE 1                                                        04620020
*********************************************************************** 04680020
         SPACE 2                                                        04740020
*  DATA EQUATES FOR OPERANDS OF IMMEDIATE TYPE INSTRUCTIONS.            04800020
         SPACE                                                          04860020
NULL     EQU   0                   USED FOR BALR R,0 AND BCTR R,0.      04920020
ZERO     EQU   0                   SYMBOLIC EQUATE                      04980020
ONE      EQU   1                   SYMBOLIC EQUATE                      05040020
TWO      EQU   2                   SYMBOLIC EQUATE                      05100020
THREE    EQU   3                   USED WHERE AN ABSOLUTE 3 IS REQ'D    05160020
FOUR     EQU   4                   SYMBOLIC EQUATE                      05220020
FIVE     EQU   5                   SYMBOLIC EQUATE                      05280020
EIGHT    EQU   8                   SYMBOLIC EQUATE                      05340020
TWELVE   EQU   12                  SYMBOLIC FOR 12, USED AS AN RC       05390020
SIXTEEN  EQU   16                  SYMBOLIC EQUATE                      05400020
TWENTY   EQU   20                  ERROR RETURN CODE                    05450020
HEX80    EQU   X'80'               SYMBOLIC MASK                        05460020
HEXFF    EQU   X'FF'               SYMBOLIC MASK                        05520020
         SPACE                                                          05580020
BLANK    EQU   C' '                SYMBOLIC FOR BLANK (SPACE).          05640020
PERIOD   EQU   C'.'                SYMBOLIC EQUATE                      05700020
CHAR0    EQU   C'0'                SYMBOLIC FOR  CHARACTER 0            05820020
CHARPLUS EQU   C'+'                SYMBOLIC FOR A PLUS SIGN             05880020
CHAR9    EQU   C'9'                SYMBOLIC FOR CHARACTER 9             05940020
BALRCODE EQU   X'05'               OP CODE FOR BALR INSTRUCTION         06000020
BALCODE  EQU   X'45'               OP CODE FOR BAL INSTRUCTION          06060020
         SPACE                                                          06120020
CFLDMASK EQU   B'00011111'         MASK TO ISOLATE REMAINDERS FOR C TYP 06180020
DWBDY    EQU   B'00000111'         USED TO TEST ADDRS FOR DBL WRD BDY.  06240020
FWBDY    EQU   B'00000011'                                FULL          06300020
HWBDY    EQU   B'00000001'                                HALF          06360020
INSTRLEN EQU   B'11000000'         FOR TESTING 1ST 2 BITS OF INSTRS     06420020
PACKMSK  EQU   X'6F'               USED TO SET UP LNTHS FOR PACK INSTR  06480020
         SPACE                                                          06540020
*  SYMBOLIC OFFSETS FOR THE SYMINFO BLOCK.                              06550020
         SPACE                                                          06560020
SIDATAPT EQU   0                   OFFSET TO DATA ADDR IN SI-BLOCK      06600020
SITYPE   EQU   4                   OFFSET TO TYPE FIELD OF SI-BLOCK     06660020
SIMUL    EQU   6                   OFFSET TO LAST 2 BYTES OF MLTPLCTY   06720020
SILEN    EQU   8                   OFFSET TO LNTH IN SYMINFO            06780020
SINXTPTR EQU   12                  OFFSET INTO SYMINFO BLK FOR CHAIN PT 06840020
SYMINFOL EQU   16                  SYMBOLIC FOR LENGTH OF SYMINFO BLK   06900020
         SPACE                                                          06910020
LSTBUFL  EQU   82                  LENGTH TO BE BLANKED IN BUFFER       06960020
MAXLINE  EQU   100                 MAX LINE LENGTH FOR OUTPUT           07020020
LSTIBLK  EQU   31                  LNTH OF DATA MOVED TO HOLD AREA      07080020
LL00LEN  EQU   4                   SYMBOLIC FOR LENGTH OF LL00 FIELD    07140020
ADDRLEN  EQU   7                   LENGTH OF AN ADDR FIELD IN THE BUF   07200020
RADDRLEN EQU   3                   LENGTH OF REGISTER ADDRESS FIELD     07260020
VPDELEN  EQU   8                   SYMBOLIC FOR LENGTH OF A VALUE PDE   07320020
MINLL    EQU   40                  MINIMUM LINE LNTH FORMATTED BY LIST  07380020
STDLL    EQU   81                  DEFAULT LINE LNTH WHEN TMPLL IS LOW  07440020
         SPACE                                                          07500020
H2ND     EQU   1                   OFFSET TO 2ND BYTE OF A HALFWORD     07560020
F1STHALF EQU   0                   OFFSET TO 1ST HALFWORD OF A FIELD    07620020
LL00OFF  EQU   0                   OFFSET INTO BUFFER FOR LL00 FIELD    07680020
DATAOFF  EQU   4                   OFFSET TO DATA PORTION OF BUFFER     07740020
R1OFF    EQU   24                  OFFSET INTO SAVE AREA FOR REG 1      07790020
R6OFF    EQU   44                  OFFSET INTO SAVE AREA FOR REG 6      07800020
R10OFF   EQU   60                  OFFSET INTO SAVE AREA FOR R10        07850020
SP1      EQU   1                   DISPLACEMENT FOR 1 SPACE IN BUF      07920020
SP2      EQU   2                   SYMBOLIC FOR 2 SPACES                07980020
SP4      EQU   4                   FOR INCREMENTING PAST 4 SPACES       08040020
SP5      EQU   5                   DISPLACEMENT FOR 5 SPACES IN BUF     08100020
CONDATA  EQU   1                   OFFSET TO DATA IN CONVERT OUTPUT     08160020
CONLFLD  EQU   0                   OFFSET TO LNTHFLD IN CONVERT OUTPUT  08220020
FOREPTR  EQU   8                   OFFSET TO FOREWARD PTR IN SAVE AREA  08280020
BACKPTR  EQU   4                   OFFSET TO BACKWARD PTR IN SAVE AREA  08340020
CVTSPACE EQU   64                  OFFSET INTO COMMON WORK AREA FOR LST 08400020
LSTWRKPT EQU   0                   OFFSET INTO PARM LIST FOR DSECT BASE 08460020
LSTPDEPT EQU   4                   OFFSET INTO PARM LIST FOR PDE ADDR   08520020
         SPACE                                                          08580020
ATTNBIT  EQU   B'01000000'                                              08640020
EQZERO   EQU   8                   COND CODE MASK FOR CC OF 0           08700020
NOTONES  EQU   14                  COND. CODE MASK FOR CC OF 0, 1, OR 2 08760020
         SPACE                                                          08820020
GRINCR   EQU   1                   USED BY LSTREG TO INCRE GEN REG NO.  08880020
GRMAX    EQU   15                  HIGHEST GENERAL REGISTER NUMBER      08940020
GRFLENO  EQU   11                  LNTH OF OUTPUT DATA, GEN REG F FRMT  09000020
GRXLENO  EQU   8                   LNTH OF OUTPUT DATA, GEN REG IN HEX  09060020
RBGRSAVE EQU   32                  OFFSET INTO SVRB FOR REG SAVE AREA   09120020
         SPACE                                                          09180020
FPRINCR  EQU   2                   INCREMENT FOR FLOATING POINT REGS    09240020
FPRMAX   EQU   6                   MAX FLOATING POINT REG NUMBER        09300020
REINLEN  EQU   4                   LNTH OF INPUT DATA FOR 'RE' ADDRS    09360020
RDINLEN  EQU   8                   LNTH OF INPUT DATA FOR 'RD' ADDRS    09420020
REXLENO  EQU   8                   LNTH OF HEX OUTPUT FOR 'RE' ADDRS    09480020
RDXLENO  EQU   16                  LNTH OF HEX OUTPUT FOR 'RD' ADDRS    09540020
REELENO  EQU   15                  LNTH OF 'E' FORMAT OUTPUT            09600020
RDDLENO  EQU   24                  LNTH OF 'D' FORMAT OUTPUT            09660020
         SPACE                                                          09720020
HEXDLEN  EQU   4                   DEFAULT LENGTH FOR HEX FORMAT        09780020
         SPACE 2                                                        09840020
*  EQUATES FOR THE INTERNAL ASSEMBLER TYPE CODES.                       09850020
         SPACE                                                          09860020
CHARCODE EQU   X'00'               TYPE ATTRIBUTE =CHAR                 09900020
HEXCODE  EQU   X'04'                ''     ''     =HEXADECIMAL          09960020
BINCODE  EQU   X'08'                ''     ''     =BINARY               10020020
ICODE    EQU   X'0C'                ''     ''     =INSTRUCTION          10080020
FCODE    EQU   X'10'                ''     ''     =FIXED PT, FULLWORD   10140020
HCODE    EQU   X'14'                ''     ''       ''   '', HALFWORD   10200020
ECODE    EQU   X'18'                ''     ''     =FLT PT, FULLWORD     10260020
DCODE    EQU   X'1C'                ''     ''      ''  '', DBL WORD     10320020
AQCODE   EQU   X'20'                ''     ''     =A AND Q ADDR CONST   10380020
YCODE    EQU   X'24'                ''     ''     =Y ADDR CONST         10440020
SCODE    EQU   X'28'                ''     ''     =S ADDR CONST         10500020
VCODE    EQU   X'2C'                ''     ''     =V ADDR CONST         10560020
PACKCODE EQU   X'30'                ''     ''     =PACKED DECIMAL       10620020
ZONECODE EQU   X'34'                ''     ''     =ZONED DECIMAL        10680020
LCODE    EQU   X'38'                ''     ''     =FLT PT, EXTENDED     10740020
         SPACE                                                          10800020
MSGMULTI EQU   8                   MULTIPLIER FOR MSG PARM LIST LNTH.   10860020
MSG01    EQU   0*MSGMULTI          OFFSET FOR MESSAGE NUMBER 01         10920020
MSG02    EQU   1*MSGMULTI          *          ''             02         10980020
MSG03    EQU   2*MSGMULTI          *          ''             03         11040020
MSG04    EQU   3*MSGMULTI          *          ''             04         11100020
MSG05    EQU   4*MSGMULTI          *          ''             05         11160020
MSG06    EQU   5*MSGMULTI          *          ''             06         11220020
MSG07    EQU   6*MSGMULTI          *          ''             07         11230020
      TITLE 'IKJEGLST, ''LIST'', INITIALIZATION/COMPLETION ROUTINES'    11280020
*********************************************************************** 11340020
*                                                                     * 11400020
*  PROGRAM BEGINS WITH STANDARD LINKAGE CONVENTIONS.                  * 11460020
*                                                                     * 11520020
*********************************************************************** 11580020
         SPACE                                                          11640020
LIST     SAVE  (14,12),,*                                               11700020
         LR    R12,R15             R12=BASE REG FOR PROG ADDRESSABILITY 11760020
         USING IKJEGLST,R12                                             11820020
         USING TCOMTAB,R9          COMMUNICATION TABLE ADDRESSABILITY.  11880020
         L     R6,REGSAVE2         R6=NEXT SAVE AREA                    11940020
         ST    R6,FOREPTR(R13)     FOREWARD CHAIN SAVE AREAS.           12000020
         ST    R13,BACKPTR(R6)     BACKWARD CHAIN SAVE AREAS.           12060020
         LR    R13,R6              R13=NEXT REGSAVE AREA ADDR.          12120020
         SPACE                                                          12220020
         TM    TSTFLGS1,PCHLSTVL   IS ENTRY FROM IKJEGLSA               12240020
         BO    IKJEGLSS            IF YES, BRANCH AROUND WORKAREA SETUP 12300020
         SPACE                                                          12360020
*  INITIALIZE WORKING STORAGE                                           12420020
         SPACE                                                          12470020
         L     R10,WORKAREA        PICK UP ADDR OF GENERAL WORK SPACE   12480020
         USING TSTCWORK,R10                                             12540020
         LA    R10,CWORKCMD        SET UP PTR TO WORK CORE FOR SUB-CMDS 12600020
         USING LSTWORK,R10                                              12660020
         XC    LSTWORK(LWLNTH),LSTWORK CLEAR WORK AREA                  12720020
         MVC   LXCTL(XCTLLEN),XCTLLF   MOVE LIST FORM OF XCTL TO DSECT  12780020
         XC    LSTRETCD,LSTRETCD       CLEAR RETURN CODE SAVE AREA      12790020
*                                                                       12830020
*  SET UP FOR AND ISSUE THE  STAE  MACRO                                12832020
*                                                                       12834020
LSTINT10 EQU   *                                                        12834420
         MVC   RETRYSAV,TSTRETRY+ONE   SAVE ADDR OF MAINLN RETRY RTN    12834820
         MVC   TSTRETRY+ONE(THREE),RETRYAD+ONE  MOVE ADDR TO TCOMTAB    12836020
         LA    R1,STAELIST         PTR TO LIST FORM MACRO               12838020
         L     R2,TSTSTAE          PTR TO TEST STAE MODULE              12838420
         STM   R10,R12,R10OFF(R13)     SAVE BASE PTR                    12838820
         STAE  (R2),CT,MF=(E,(R1))                                      12839220
         SPACE                                                          12839620
         LTR   R15,R15             TEST RETURN CODE                     12839720
SMTSTAE  DS    0H                  SMT TEST LABEL FOR STAE MACRO        12847220
         BZ    STAEOK              CONTINUE IF ZERO                     12854920
         SPACE                                                          12862420
         B     PRC16               ELSE, PRINT GETMAIN ERROR MSG        12869920
         SPACE                                                          12880020
*********************************************************************** 12900020
*                                                                     * 12960020
*  INITIALIZE PARAMETER LIST, TEST FOR A SCHEDULED ATTENTION, AND IF  * 13020020
*  NO ATTENTION IS PENDING, LINK TO PARSE.                            * 13080020
*                                                                     * 13140020
*********************************************************************** 13200020
STAEOK   EQU   *                                                        13210020
         LA    R1,LSTABEND         GET ADDR OF ABEND VECTOR TABLE       13212020
         ST    R1,ABENTAB1         SET UP SUB-CMD ABEND TABLE           13214020
         TM    TSTFLGS1,PCHLSTVL   WAS ENTRY FROM IKJEGLSA              13220020
         BO    MORE02              IF YES, GO PROCESS                   13230020
         SPACE                                                          13240020
*  IF ENTRY WAS NOT FROM IKJEGLSA, THIS IS THE FIRST ENTRY, INITILIZE.  13242020
         SPACE                                                          13244020
         LA    R1,PARSEPL          PTR TO PARSE LIST                    13250020
         USING PPL,R1              ADDRESSABILITY FOR LIST              13300020
         L     R2,TSTUPT           PTR TO UPT                           13310020
         L     R3,TSTECT           PTR TO ECT                           13310420
         L     R4,TSTCPECB         PTR TO P/P ECB                       13310820
         ST    R2,PPLUPT           PUT PTR TO UPT INTO PARSE LIST       13312020
         ST    R3,PPLECT           PUT PTR TO ECT INTO PARSE LIST       13316020
         ST    R4,PPLECB           PUT PTR TO P/P ECB INTO PARSE LIST   13318420
         L     R2,PARSEPCL         PTR TO PARSE PCL                     13318820
         LA    R3,TSTANSPL         PTR TO ANSWER PLACE                  13318920
         L     R4,INBUF            PTR TO INPUT BUFFER                  13319020
         ST    R2,PPLPCL           PUT PTR TO PARSE PCL INTO PARSE LIST 13319220
         ST    R3,PPLANS           PUT PTR TO ANS PLACE INTO PARSE LIST 13319720
         ST    R4,PPLCBUF          PUT PTR TO INPUT BUF INTO PARSE LIST 13319920
         SPACE                                                          13369920
*  R6 SHOULD STILL CONTAIN THE SAVE AREA ADDRESS AT THIS POINT.         13500020
         SPACE                                                          13510020
         ST    R6,PPLUWA           PUT INTO PARSE LIST                  13550020
         DROP  R1                                                       13600020
         SPACE                                                          13680020
         LINK  EP=IKJPARS          LINK TO THE PARSE ROUTINE            13740020
         SPACE                                                          13750020
SMTPARS  DS    0H                  SMT TEST LABEL FOR PARSE LINK        13760020
         SPACE                                                          13770020
PARSEBLO EQU   *                                                        13790020
         SPACE 2                                                        13800020
*  TEST THE RETURN CODE FROM PARSE                                      13860020
         SPACE                                                          13920020
         LTR   R15,R15             TEST FOR RC=0                        13980020
         BNZ   PARSRC(R15)         IF NON-ZERO, BRANCH TO BRANCH TABLE  14040020
         L     R8,TSTANSPL         PICK UP ADDRESS OF PDL               14160020
         USING IKJPARMD,R8                                              14220020
         SPACE                                                          14280020
*********************************************************************** 14340020
*  NEXT EXTRACT THE NECESSARY DATA FROM THE ADDRESS PDE AND SET UP    * 14400020
*  THE ADDRESS INFORMATION FIELDS. CONVERT THE LENGTH AND MULTIPLICITY* 14460020
*  FACTORS TO BINARY IF THEY WERE SUPPLIED. SET THE TSTPRINT SWITCH   * 14520020
*  IF PRINT HAS BEEN SPECIFIED.                                       * 14580020
*********************************************************************** 14640020
         SPACE                                                          14700020
         CH    R15,PRINT           TEST FOR PRINT KEYWORD SPECIFIED     14760020
         BE    NOPRINT             IF NOT, BRANCH AROUND SETUP          14820020
         OI    TSTFLGS1,TSTPRINT   SET THE PRINT SPECIFIED FLAG         14880020
NOPRINT  EQU   *                                                        14940020
         CH    R15,TYPE            WAS A TYPE KEYWORD USED              15000020
         BE    NOTYPE              IF NOT, BRANCH                       15060020
         OI    LSTFLGS,TYPEFLG     IF TYPE USED, SET FLAG               15120020
NOTYPE   EQU   *                                                        15180020
         LH    R2,TYPE             PICK UP NUMBER OF TYPE KEYWORD OR 0  15240020
         IC    R2,TYPETBL(R2)      GET HEX CODE FOR FORMAT TYPE         15300020
         STC   R2,A1TYPE           PLACE TYPE CODE IN ADDR 1 DESCRIPTOR 15360020
         STC   R2,TYPESAVE         SAVE TYPE FOR POSSIBLE ADDR LIST     15420020
         CH    R15,LATTR           WAS THE LENGTH ATTR KEYWORD USED     15480020
         BE    NOLENGTH            IF NOT, BRANCH                       15540020
         OI    LSTFLGS,LNTHFLG     IF LENGTH GIVEN, SET FLAG            15600020
NOLENGTH EQU   *                                                        15660020
         CH    R15,MATTR           WAS MULTIPLICITY GIVEN               15720020
         BE    NOMULTI             IF NOT, BRANCH                       15780020
         OI    LSTFLGS,MULTIFLG    IF GIVEN, SET FLAG                   15840020
NOMULTI  EQU   *                                                        15900020
         L     R2,OUTBUF           GET PTR TO THE OUTPUT BUFFER         15960020
         XC    LL00OFF(LL00LEN,R2),LL00OFF(R2)   CLEAR LL00 FLD TO ZERO 16020020
         MVI   DATAOFF(R2),BLANK   MOVE A BLANK TO START OF DATA AREA   16080020
         MVC   DATAOFF+ONE(LSTBUFL,R2),DATAOFF(R2)     BLANK OUT BUFFER 16140020
         ST    R2,IOLIST           SET UP IO PARM LIST                  16200020
         LA    R3,MINLL            SET UP TO SEE THAT TMPLL=MIN LINE    16260020
         CH    R3,TMPLL            Q. IS TMPLL GT OR EQ TO MINIMUM      16320020
         LA    R3,STDLL            SET UP STANDARD LINE LNTH DEFAULT    16380020
         BH    LSTMN02             IF TMPLL LT MINIMUM, BRANCH          16440020
         CH    R3,TMPLL            IS TMPLL GREATER THAN STANDARD LL    16500020
         BL    LSTMN02             IF SO, USE STANDARD LINE LENGTH      16560020
         LH    R3,TMPLL            IF TMPLL NLT MIN, USE TMPLL          16620020
LSTMN02  EQU   *                                                        16680020
         LA    R2,DATAOFF(R3,R2)   R2=PTR TO END OF BUFFER+1            16740020
         ST    R2,ENDOBUF          SETUP END OF BUFFER ADDRESS          16800020
         LA    R8,ADDR1            SET UP ADDRESS OF ADDR PDE AS BASE   16860020
         USING IKJPARMA,R8         ADDRESSABILITY FOR ADDR PDE DSECT    16920020
         EJECT                                                          16980020
*********************************************************************** 17040020
*                                                                     * 17100020
*  BEGINNING OF REPEAT SECTION.  THE ROUTINE BELOW IS RE-ENTERED IF   * 17160020
*  A LIST OF ADDRESSES HAS BEEN GIVEN.                                * 17220020
*                                                                     * 17280020
*********************************************************************** 17340020
LSTMN04  EQU   *                                                        17400020
         L     R2,LMATTR           GET LENGTH AND MULTIPLICITY ATTR'S   17460020
         ST    R2,A1LMATTR             AND SET ADDRESS 1 ATTRIBUTES.    17520020
         TM    PDE2FLG3,AFLG       WAS A SECOND ADDRESS GIVEN           17580020
         L     R15,PDEUSER         GET DATA ADDR OR SI PTR              17640020
         BO    LSTMN05             IF YES, BRANCH                       17700020
         TM    PDE2FLG2,CTNAMFLG   WAS 2ND ADDRESS A CSECT NAME         17760020
         BNO   LSTMN06             BRANCH IF NO 2ND ADDRESS             17820020
LSTMN05  EQU   *                                                        17880020
         OI    COMFLGS,TWOADDRS    SET FLAG TO INDICATE ADDRESS RANGE   17940020
LSTMN06  EQU   *                                                        18000020
         LTR   R15,R15             IF R15 NEG, R15 POINTS TO SYMINFO    18060020
         BM    SYM1                IF SYMBOLIC, BRANCH                  18120020
LSTMN07  EQU   *                                                        18180020
         ST    R15,A1              SAVE ADDR OF CURRENT INPUT           18240020
         TM    COMFLGS,TWOADDRS    WERE TWO ADDRESSESS SPECIFIED        18300020
         BZ    ONLYONE             IF ONLY ONE ADDR, BRANCH             18360020
         L     R15,PDE2USER            GET SECOND ADDR OR SI PTR        18420020
         LTR   R15,R15             IF R15 NEG, R15 POINTS TO SYMINFO    18480020
         BNM   ONLYONE             IF ADDR2 IS SYMBOLIC, BRANCH         18540020
         L     R15,SIDATAPT(R15)   PICK UP INPUT ADDR FROM SYMINFO BLK  18600020
ONLYONE  EQU   *                                                        18660020
         ST    R15,A2              SET A2 TO CURRENT SECOND ADDR        18720020
         LA    R15,HOLDAREA        MAKE A PTR TO DATA HOLDING AREA      18780020
         ST    R15,VPDEPT          SET UP VALUE PDE FOR DATA CONVERT    18840020
         SPACE                                                          18900020
*  NEXT TEST WHETHER ADDR IS REGISTER TYPE                              18960020
         SPACE                                                          19020020
         TM    PDEFLG4,GENR+LFPR+SFPR  IS ADDRESS TYPE REGISTER         19080020
         BZ    NOTREG              IF NOT, BRANCH                       19140020
         NC    PDEINDCT,PDEINDCT   IF REG, IS IT INDIRECT               19200020
         BZ    LSTREG              IF REG ADDR NOT INDIRECTED, BR       19260020
         SPACE                                                          19320020
*  NEXT TEST WHETHER ADDRESS IS RELATIVE                                19380020
         SPACE                                                          19440020
NOTREG   EQU   *                                                        19500020
         TM    PDEFLG4,CTONLY      IS ADDRESS A CSECT ONLY              19550020
         BO    LSTMN09             IF CSECT ONLY, BRANCH                19552020
         TM    PDEFLG4,RELADDR     IS ADDRESS TYPE RELATIVE             19560020
         BZ    LSTMN10             IF NOT RELATIVE, BRANCH              19620020
         NC    PDEINDCT,PDEINDCT   IF RELATIVE, IS IT INDIRECTED        19680020
         BNZ   LSTMN10             IF INDIRECTED, BRANCH                19740020
         TM    PDEEXPTR,HEXFF      IF RELATIVE, IS IT AN EXPRESSION     19800020
         BNO   LSTMN10             IF START OF AN EXPRESSION, BRANCH    19860020
         OI    A1FLG,A1REL         TURN ON ADDRESS IS RELATIVE FLAG     19920020
         TM    PDEFLG2,CTNAMFLG    IS RELATIVE ADDR QUALIFIED           19930020
         BNO   LSTMN14             IF NOT QUALIFIED, BRANCH             19940020
         SPACE                                                          19950020
*********************************************************************** 19961020
*                                                                     * 19970020
*  IF THE ADDRESS IS A QUALIFIED RELATIVE, CALCULATE THE BASE FOR     * 19971020
*   RELATIVES BY CONVERTING THE RELATIVE OFFSET TO BINARY AND         * 19972020
*    SUBTRACTING IT FROM THE RESOLVED CURRENT ADDRESS. THIS BASE      * 19973020
*     ADDRESS IS KEPT IN 'PPTEMP' FOR USE BY IKJEGCVT.                * 19974020
*                                                                     * 19975020
*********************************************************************** 19976020
         XC    HOLDAREA(APL),HOLDAREA  CLEAR AN AREA FOR AN ADDR PDE    19977020
         L     R2,PDEUSER          GET BINARY START ADDRESS             19978020
         SPACE                                                          19979020
*  NEXT MOVE THE ADDRESS POINTER AND THE LENGTH TO THE NEW ADDR PDE.    19979120
         SPACE                                                          19979220
         MVC   HOLDAREA+PDEADRPT-IKJPARMA(PDERSV3-PDEADRPT),PDEADRPT    19979320
         MVI   HOLDAREA+PDEEXPTR-IKJPARMA,HEXFF  INDICATE NOT INDIRECT  19979420
         SPACE                                                          19979520
*  THE ADDRESS TYPE FIELD IS ZERO WHICH IS THE CODE FOR ABSOLUTE.       19979620
         SPACE                                                          19979720
         LA    R1,HOLDAREA         SET UP A POINTER TO NEW PDE.         19979820
         L     R15,TSTCONVT        GET ADDRESS OF CONVERT ROUTINE       19979920
         SR    R0,R0               MAKE REG 0, ZERO FOR CONVERT TO BIN  19980020
         LCR   R1,R1               MAKE REG 1 NEGATIVE FOR ADDR CONVERT 19980120
         BALR  R14,R15             GO CONVERT RELATIVE OFFSET TO BINARY 19980220
         LTR   R15,R15             IS THE RETURN CODE ZERO              19980320
         L     R1,HOLDAREA+PDEUSER-IKJPARMA  GET CONVERTED DATA         19980420
         BNZ   LSTCVTRC            IF RC WAS NOT 0, BRANCH              19980520
         SR    R2,R1               SUBTRACT OFFSET FROM ADDRESS         19980620
         ST    R2,PPTEMP           SET UP DIFFERENCE AS BASE FOR RELS   19980720
         B     LSTMN14             BRANCH AROUND SET UP FOR ABSOLUTE    19980920
         SPACE                                                          19990020
LSTMN09  EQU   *                                                        20000020
         OI    A1FLG,A1SYM         INDICATE ADDRESS IS A SYMBOLIC TYPE  20010020
LSTMN10  EQU   *                                                        20040020
         XC    APDE(APL),APDE      CLEAR ADDRESS PDE,                   20100020
         OI    APDE+(PDEFLG4-IKJPARMA),ABSADDR  SET FLAG FOR ABSOLUTE   20160020
         OI    APDE+(PDEFLG3-IKJPARMA),AFLG     SET FLAG, ADDR PRESENT  20220020
         SPACE                                                          20230020
*  TEST FORMAT TYPE TO BE USED                                          20240020
         SPACE                                                          20250020
LSTMN14  EQU   *                                                        20280020
         CLI   A1TYPE,HEXCODE      IS REQUESTED FORMAT HEX              20460020
         BE    LSTHEX              IF HEX, BRANCH                       20520020
         SPACE 2                                                        20530020
*        THIS XCTL USES THE BLDL ENTRY FOR IKJEGLSA WHICH WAS CREATED   20570020
*        BY MAINLINE IN INITIALIZATION. THIS BLDL ENTRY SHOULD IMPROVE  20620020
*        PERFORMANCE OF SUB-COMMANDS XCTLING BETWEEN LOAD MODULES.      20630020
         SPACE 2                                                        20632020
         LA    R1,LSA           PTR TO CONSTANT NAME                    20634020
         L     R15,TSTEXPAN     ADDRESS OF EXPANSION ROUTINE            20636020
         BALR  R14,R15          GO DO EXPANDING                         20638020
         LTR   R6,R1            WAS BLDL ENTRY RETURNED                 20638420
         BZ    NOBLDL           BRANCH IF NOT                           20638820
         L     R13,BACKPTR(R13) ADDR OF CALLERS SAVE AREA               20639220
         LA    R15,LXCTL        PTR TO PARM LIST                        20639620
         LA    R1,LXCTL1        SET UP PTR TO LIST'S PARM LIST          20639720
         ST    R8,LSTPDEPT(R1)     PASS A PTR TO THE CURRENT ADDR PDE   20639820
         ST    R10,LSTWRKPT(R1)    PASS THE BASE ADDR OF LSTWORK DSECT  20644820
         OI    TSTFLGS2,TSTXCTL TURN ON XCTL IN PROGRESS BIT            20649920
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  SET UP MNL STAE            20654920
         XCTL  (2,12),DE=(6),SF=(E,(15))                                20659920
         SPACE 2                                                        20669920
*        THE FOLLOWING XCTL IS EXECUTED IF THE BLDL ISSUED BY MAINLINE  20679920
*        WAS NOT SUCCESSFUL AND THE BLDL ENTRY IS NOT AVAILABLE FOR     20686620
*        USE IN THE XCTL.                                               20688620
         SPACE 2                                                        20690620
NOBLDL   DS    0H                                                       20692620
         L     R13,BACKPTR(R13)    PICK UP ADDR OF CALLERS SAVE AREA    20693320
         LA    R15,LXCTL           SET UP PTR TO LIST FORM OF XCTL MAC  20700020
         LA    R1,LXCTL1           SET UP PTR TO LIST'S PARM LIST       20820020
         ST    R8,LSTPDEPT(R1)     PASS A PTR TO THE CURRENT ADDR PDE   20880020
         ST    R10,LSTWRKPT(R1)    PASS THE BASE ADDR OF LSTWORK DSECT  20940020
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  USE MAINLINES RETRY RTN    20990020
         OI    TSTFLGS2,TSTXCTL    INDICATE XCTL WITHIN LIST SUB-CMD    20992020
*********************************************************************** 21010020
*                                                                     * 21020020
*  IF FORMAT TYPE WAS A, B, C, D, E, F, H, I, L, P, S, Y, OR Z---     * 21060020
*  XCTL TO SECOND LOAD MODULE OF LIST.                                * 21120020
*  IF THE XCTL FAILS, THE TEST MAINLINE STAE RETRY ROUTINE WILL BE    * 21122020
*  ENTERED. (FIELD 'TSTRETRY' IN TCOMTAB POINTS TO MAINLINE RTN ACROSS* 21124020
*  THE XCTL).                                                         * 21126020
*                                                                     * 21130020
*********************************************************************** 21140020
         SPACE                                                          21180020
         XCTL  (2,12),EP=IKJEGLSA,SF=(E,(15))                           21240020
         SPACE                                                          21290020
SMTXCTL  DS    0H          SMT TEST LABEL FOR XCTL MACRO                21292020
         EJECT                                                          21300020
*********************************************************************** 21360020
*                                                                     * 21420020
*  THIS ENTRY POINT IS USED BY IKJEGLSA, THE 2ND LOAD OF LIST, IF     * 21480020
*  AN ADDRESS LIST IS BEING PROCESSED AND---                          * 21540020
*        1 THE NEXT ADDRESS IN THE LIST IS A REG ADDR.                  21600020
*        2 THE NEXT ADDRESS IN THE LIST IS SYMBOLIC AND THE SYMBOLS'  * 21660020
*          TYPE ATTRIBUTE IS HEX AND HAS NOT BEEN OVER-RIDDEN         * 21720020
*          BY THE USER.                                                 21780020
*        3 THE NEXT ADDRESS HAS NO ASSOCIATED ATTRIBUTES AND DEFAULTS   21840020
*          TO HEXADECIMAL FORMAT.                                       21900020
*  AFTER SETUP, CONTROL IS PASSED TO THE REPEAT ROUTINE.              * 21960020
*                                                                     * 22020020
*********************************************************************** 22080020
         SPACE                                                          22140020
IKJEGLSS DS    0H                                                       22200020
         L     R8,LSTPDEPT(R1)     PICK UP PTR TO CURRENT ADDR PDE      22260020
         L     R10,LSTWRKPT(R1)    SET UP BASE REG FOR LSTWORK DSECT    22320020
         NI    TSTFLGS2,HEXFF-TSTXCTL  TURN OFF XCTL IN PROGRESS SW     22370020
         B     LSTINT10            GO ISSUE STAE, THEN PROCESS NXT ADDR 22380020
         SPACE 3                                                        22440020
MORE     EQU   *                                                        23520020
         L     R6,OUTBUF           LOAD PTR TO OUTPUT BUFFER            23580020
         ST    R6,IOLIST           SET UP THE IO PARM LIST              23640020
         BAL   R7,LSTIO            GO TO OUTPUT ROUTINE                 23700020
         SPACE                                                          23760020
         L     R8,PDE2CHAI         GET ADDR OF NEXT PDE FROM CHAIN PTR  23820020
MORE02   EQU   *                                                        23880020
         XC    LSTRPT(RPTSIZE),LSTRPT  CLEAR ADDR PORTION OF WORK AREA  23940020
         IC    R2,TYPESAVE         GET TYPE CODE OR DEFAULT TYPE CODE   24000020
         STC   R2,A1TYPE           SET FORMAT TYPE (EXCEPT FOR SYMBOLS) 24060020
         B     LSTMN04             GO BACK AND PROCESS NEXT ADDR        24120020
         EJECT                                                          24180020
*********************************************************************** 24190020
*                                                                     * 24200020
*  COMPLETION ROUTINE, TESTS FOR ADDITIONAL ADDRESSES TO LIST AND     * 24210020
*  SETS A 0 RETURN CODE. WHEN ALL ADDRESSES HAVE BEEN PROCESSED,      * 24220020
*  THE ROUTINE RETURNS TO THE CALLER.                                 * 24230020
*                                                                     * 24231020
*********************************************************************** 24232020
         SPACE                                                          24233020
LSTCC0   EQU   *                                                        24234020
         TM    COMFLGS,OUTCORE     WAS THE LAST LIST TRUNCATED          24234420
         BZ    LSTOK               IF LAST LIST COMPLETE, BRANCH        24234820
         BAL   R7,LSTOUT           IF TRUNCATED, GO PUT OUT MSG         24234920
LSTOK    EQU   *                                                        24240820
         TM    PDE2CHAI,HEXFF      IS THERE ANOTHER ADDRESS PDE         24246920
         BNO   MORE                IF YES, BRANCH                       24252820
LSTMN90  EQU   *                                                        24258720
         NI    TSTFLGS1,HEXFF-TSTPRINT-TSTFIRST-PCHLSTVL-RANGESW        24264620
         L     R15,LSTRETCD        PICK UP RETURN CODE                  24270520
         L     R13,BACKPTR(R13)    GET ADDR OF PREVIOUS SAVE AREA.      24276420
         RETURN (14,12),RC=(15)    RETURN TO CALLER                     24282320
         SPACE 2                                                        24288220
LSTCVTRC EQU   *                                                        24292220
         CH    R15,H16             IS RC=16                             24292620
         BNE   LSTCC0              OTHERWISE, GO CHECK FOR MORE ADDRS   24293420
LSTCC16  EQU   *                                                        24294120
         LA    R15,SIXTEEN         R15=16                               24300020
         ST    R15,LSTRETCD        RC=16                                24360020
         B     LSTMN90             GO CLEAN UP AND RETURN               24420020
         EJECT                                                          24480020
*  BRANCH TABLE ENTERED WHEN THE RETURN CODE FROM IKJPARS IS GREATER  * 24540020
*  THAN ZERO.                                                         * 24600020
         SPACE                                                          24660020
         ORG   *-4                 REUSE SPACE FOR ZERO COND CODE       24720020
PARSRC   EQU   *                                                        24780020
         ORG                                                            24840020
         B     PRC04               RC = 4, UNABLE TO PROMPT             24900020
         B     LSTCC16             ATTN SCHEDULED, GO SET RC=16         24960020
         B     PRC12               INVALID PARM, SHOULD NOT OCCUR       25020020
         B     PRC16               INSUFFIENT STORAGE FOR PARSE         25030020
         B     LSTMN90             RC=20, TERMINATE IMMEDIATELY         25032020
         SPACE                                                          25032420
PRC04    OI    TSTFLGS4,TSTFLUSH   INITIALIZE STACK FLUSH FOR           25032820
*                                  MAINLINE                             25033220
         B     LSTMN90             RETURN TO MAINLINE                   25033620
         SPACE                                                          25034020
PRC12    EQU   *                                                        25060020
         LA    R3,MSG06            LIST FAILED, UNABLE TO PARSE         25070020
         B     PRCMSGS             GO TO COMMON MSG SETUP ROUTINE       25071020
PRC16    EQU   *                                                        25080020
         LA    R3,MSG03            LIST FAILED, INSUFFIENT STORAGE      25090020
         SPACE                                                          25100020
*  COMMON PARSE ERROR MESSAGE SETUP ROUTINE.                            25110020
         SPACE                                                          25120020
PRCMSGS  EQU   *                                                        25121020
         L     R2,LSTMSG           GET ADDR OF MSG CSECT                25130020
         LA    R2,ZERO(R3,R2)      ADD OFFSET TO DESIRED MSG ADCONS     25131020
         LM    R2,R3,ZERO(R2)      PICK UP ADDR'S OF MESSAGES           25132020
         STM   R2,R3,IOLIST            INTO PARM LIST.                  25440020
         LA    R1,IOLIST           SET UP ADDR OF PARM LIST,            25500020
         LCR   R1,R1                   INDICATE OUTPUT IS MSG           25560020
         BAL   R7,LSTIO2           GO OUTPUT MESSAGE.                   25620020
         B     LSTMN90             GO CLEAN UP, RETURN TO CALLER RC=0   25680020
         EJECT                                                          26640020
*********************************************************************** 26700020
*                                                                     * 26760020
*  SYMBOLIC ADDRESS SETUP ROUTINE. THIS ROUTINE SETS UP THE A1 FIELD  * 26820020
*  AND FILLS IN ANY ATTRIBUTES NOT OVER-RIDDEN BY THE USER.           * 26880020
*  AT ENTRY, REGISTER 15 POINTS TO THE SYMINFO BLOCK FOR ADDRESS 1    * 27000020
*********************************************************************** 27060020
SYM1     EQU   *                                                        27120020
         TM    LSTFLGS,TYPEFLG     WAS A TYPE GIVEN BY THE USER         27180020
         BO    HAVETYPE            IF GIVEN, IGNORE ATTRS OF SYMBOL     27240020
         SR    R2,R2               CLEAR A REG,                         27300020
         IC    R2,SITYPE(R15)         PICK UP THE TYPE,                 27360020
         STC   R2,A1TYPE                   AND MAKE IT THE TYPE FOR A1  27420020
HAVETYPE EQU   *                                                        27480020
         TM    LSTFLGS,LNTHFLG     WAS LNTH ATTR GIVEN BY USER          27540020
         BO    SYM1L               IF GIVEN, IGNORE ATTRS OF SYMBOL     27600020
         LH    R2,SILEN(R15)       PICK UP SYMS LENGTH ATTR             27660020
         STH   R2,A1L              ESTABLISH SYMS LNTH FOR THIS DATA    27720020
SYM1L    EQU   *                                                        27780020
         TM    LSTFLGS,MULTIFLG    WAS MULTIPLICITY ATTR GIVEN BY USER  27840020
         BO    SYM1M               IF GIVEN, IGNORE ATTRS OF SYMBOL     27900020
         LH    R2,SIMUL(R15)       PICK UP SYMS MULTIPLICITY FACTOR     27960020
         STH   R2,A1M              EST. SYMS MULTI FOR THIS DATA        28020020
SYM1M    EQU   *                                                        28080020
         OI    A1FLG,A1SYM         SET FLAG TO INDICATE ADDR SYMBOLIC   28140020
         L     R15,SIDATAPT(R15)   GET PTR TO INPUT FROM SYMINFO        28200020
         B     LSTMN07             RETURN TO MAINLINE SETUP ROUTINE     28260020
         TITLE 'IKJEGLST, ''LIST'', HEX FORMATTING ROUTINE'             28320020
*********************************************************************** 28380020
*                                                                     * 28440020
*  LIST AREAS OF CORE IN HEX FORMAT.                                  * 28500020
*        FIRST ANALYZE THE ADDRESS(ES) AS TO TYPE AND NUMBER.         * 28560020
*                                                                     * 28620020
*********************************************************************** 28680020
         SPACE                                                          28740020
LSTHEX   EQU   *                                                        28800020
         MVI   VPDET,HEXCODE       SET TYPE CODE FIELD TO HEX           28860020
         LH    R5,A1L              GET USER SPECIFIED LENGTH            28920020
         SR    R0,R0               CLEAR FOR COMPARE                    28980020
         CH    R0,A1M              WAS MULTIPLICITY GIVEN               29040020
         BNZ   LSTX04              IF YES, BRANCH AROUND DEFAULT        29100020
         MVI   A1M+H2ND,ONE        DEFAULT MULTIPLICITY TO ONE          29160020
LSTX04   EQU   *                                                        29220020
         TM    COMFLGS,TWOADDRS    HOW MANY ADDRESSES WERE GIVEN        29280020
         BO    LSTX24              IF TWO, BRANCH                       29340020
         OI    COMFLGS,ARTIMSW     INDICATE CONTROL IS ARTIFICIAL       29400020
         CR    R0,R5               WAS A LENGTH GIVEN OR IMPLIED        29460020
         BNE   LSTX06              IF YES, BRANCH                       29520020
         LA    R5,HEXDLEN          SET DEFAULT LNTH FOR HEX             29580020
         STH   R5,A1L              SAVE DEFAULTED LENGTH                29630020
LSTX06   EQU   *                                                        29632020
         B     LSTX18              GO TO LENGTH SPECIFIED ROUTINE       29634020
LSTX08   EQU   *                                                        29640020
         LA    R4,ONE              SET CONTROL TO 1 GROUP PER LINE      29700020
         STH   R4,ARTIFMUL         SET ARTIFICIAL MULTIPLICITY          29760020
         SPACE                                                          29820020
*********************************************************************** 29880020
*                                                                     * 29940020
*  DETERMINE WHETHER ADDRESS IS RELATIVE, SYMBOLIC, OR ABSOLUTE.      * 30000020
*                                                                     * 30060020
*********************************************************************** 30120020
LSTX10   EQU   *                                                        30180020
         LA    R3,FOUR             SET A CONSTANT OF 4                  30240020
         CR    R3,R4               COMPARE IT TO NUMBER OF GRPS TO LIST 30300020
         BNH   LSTX12              IF 4 OR MORE GROUPS, BRANCH          30360020
         L     R15,ENDOBUF         GET END OF BUFFER ADDRESS            30420020
         OI    COMFLGS,DATASIZE    IF LESS THAN 4 GROUPS, SET SW        30480020
         ST    R15,ENDOGRP         SET END OF GROUP TO END OF BUF       30540020
LSTX12   EQU   *                                                        30600020
         STH   R5,VPDEL            SET LENGTH FIELD OF VALUE PDE        30660020
         STH   R5,A1L              RECORD LENGTH FINALLY CHOSEN         30720020
         TM    A1FLG,A1SYM         TEST ADDR TYPE                       30780020
         BZ    LSTX14              IF ADDR IS ABSOLUTE, BRANCH          30840020
         BO    LSTX40              IF ONES, ADDR IS SYMBOLIC            30900020
         SPACE                                                          30960020
*  IF ADDRESS TYPE IS RELATIVE, FALL THROUGH AND SET UP FOR RELATIVES.  31021020
         SPACE                                                          31022020
         MVC   APDE(APL),IKJPARMA  MOVE ORIGINAL PDE TO WORK AREA       31030020
LSTX14   EQU   *                                                        31080020
         LA    R2,A1               GET ADDR OF INPUT DATA PTR           31140020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) STORE IT IN THE ADDR PDE     31200020
         B     LSTX50              GO TO MAIN ROUTINE FOR HEX.          31260020
         SPACE                                                          31320020
*********************************************************************** 31380020
*                                                                     * 31440020
*  ROUTINE WHEN LNTH WAS SPECIFIED, OR AVAILABLE THRU A SYMBOLIC ADDR.* 31500020
*                                                                     * 31560020
*********************************************************************** 31620020
LSTX18   EQU   *                                                        31680020
         BAL   R14,LSTLMTCK        GO TEST FOR EXTENSION BEYOND CORE    31730020
         LTR   R15,R15             WAS REMAINING MULTIPLICITY ZERO      31732020
         BZ    LSTX19              IF MULTIPLICITY NON-ZERO, BRANCH     31734020
         MVI   A1M+H2ND,ONE        SET MULTIPLICITY TO ONE              31736020
         LH    R5,LASTLEN          GET REMAINING LENGTH                 31738020
         XC    LASTLEN,LASTLEN     CLEAR LASTLEN TO PREVENT RE-USE      31738120
         STH   R5,A1L              SET REQUEST LENGTH TO LAST LENGTH    31738420
LSTX19   EQU   *                                                        31738820
         LA    R2,FOUR             SET UP TEST VALUE                    31740020
         CR    R5,R2               IS LENGTH GREATER THAN 4             31800020
         BNH   LSTX08              IF NOT, GO USE ACTUAL LENGTH         31860020
         LA    R1,FWBDY            SET UP TO TEST IF LNTH/4 HAS REMAIN  31920020
         LR    R4,R5               GET A WORKING COPY OF THE LENGTH     31980020
         NR    R1,R4               PLACE ANY REMAINDER IN R1            32040020
         SRL   R4,TWO              DIVIDE LENGTH BY 4                   32100020
         STH   R4,ARTIFMUL         SAVE ARTIFICIAL MULTIPLICITY         32160020
LSTX20   EQU   *                                                        32220020
         LR    R5,R2               SET UP LENGTH REGISTER               32280020
         STH   R1,REMAIN           SAVE REMAINDER                       32340020
         STH   R1,REMAIN2          SAVE A COPY OF THE REMAINDER         32400020
         B     LSTX10              RETURN TO MAINLINE                   32460020
         SPACE                                                          32520020
*********************************************************************** 32580020
*                                                                     * 32640020
*  ROUTINE TO SET UP FOR TWO ADDRESSES.                               * 32700020
*                                                                     * 32760020
*********************************************************************** 32820020
LSTX24   EQU   *                                                        32880020
         LA    R2,HEXDLEN          SET UP DEFAULT LENGTH FOR HEX        32940020
         L     R4,A2               R4=ADDR OF END OF INPUT DATA FLD.    33000020
         S     R4,A1               CALCULATE RANGE IN BYTES.            33060020
         LA    R4,ONE(R4)          INCLUDE BYTE AT 2ND ADDRESS          33120020
         LA    R1,FWBDY            SET UP TO DETERMINE REMAINDER OF L/4 33180020
         NR    R1,R4               PLACE ANY REMAINDER IN R1            33240020
         SRA   R4,TWO              DIVIDE LENGTH BY 4                   33300020
         BNZ   LSTX20              IF QUOTIENT NON-ZERO, BRANCH         33360020
         LR    R5,R1               SET LENGTH TO REMAINDER              33420020
         B     LSTX08              RETURN TO MAINLINE                   33480020
         SPACE                                                          33540020
*  ROUTINE TO SET UP FOR SYMBOLIC ADDRESSES                             33600020
         SPACE                                                          33660020
LSTX40   EQU   *                                                        33720020
         BAL   R7,LSTSYM           GO MOVE SYMBOLIC ADDR TO BUF         33780020
         CH    R4,HONE             HOW MANY FIELDS ARE TO BE LISTED     33840020
         BH    LSTX42              IF MORE THAN 1 + A REMAINDER, BRANCH 33900020
         CH    R4,A1M              ARE THERE MORE FIELDS TO LIST        33960020
         BL    LSTX42              IF MORE, BRANCH                      34020020
         LH    R15,A1L             GET LENGTH OF PRIMARY FIELD          34080020
         AH    R15,REMAIN          ADD ANY REMAINDER                    34140020
         AR    R15,R15             DOUBLE LENGTH TO GET OUTPUT LENGTH   34200020
         LA    R15,SP4(R6,R15)     CALCULATE BUF PTR AT END OF DATA     34260020
         C     R15,ENDOBUF         WILL DATA FIT                        34320020
         BNH   LSTX57              IF DATA WILL FIT, BRANCH             34380020
         SPACE                                                          34440020
*  IF DATA WILL NOT FIT, FALL THROUGH AND PUT OUT ADDRESS SEPARATELY.   34500020
         SPACE                                                          34560020
LSTX42   EQU   *                                                        34620020
         BAL   R7,LSTIO            GO OUTPUT ADDR ONLY                  34680020
         B     LSTX54              GO OUTPUT DATA                       34740020
         EJECT                                                          34800020
*********************************************************************** 34860020
*  PROCESS LOOP FOR HEX FORMATTING ROUTINE                              34920020
*                                                                     * 34980020
*        DURING THE PROCESSING CYCLE, THE REGISTER USAGE IS AS FOLLOWS* 35040020
*              R0 CONTAINS A NEG (-) NUMBER TO SHOW CONVERT TO PRINT  * 35100020
*              R5 CONTAINS THE ADDR OF THE OUTPUT BUFFER.               35160020
*              R6 CONTAINS THE ADDR ON THE NEXT AVAILABLE BYTE IN BUF * 35220020
*                                                                     * 35280020
*        OUTPUT IS PLACED IN THE BUFFER IN ONE OF THE FOLLOWING       * 35340020
*        FORMATS, DEPENDING ON LINE SIZE. (AN X REPRESENTS A GROUP OF * 35400020
*        2, 4, 6, OR 8 CHARACTERS OF DATA AND ADDR IS RELATIVE OR     * 35460020
*        ABSOLUTE. SYMBOL INDICATES SYMBOLIC ADDR.)                   * 35520020
*        1.    ADDR  X X X X  X X X X                                 * 35580020
*        2.    ADDR  X X X X                                          * 35640020
*                    X X X X                                          * 35700020
*        3.    ADDR                                                   * 35760020
*                X X X X                                              * 35820020
*                X X X X                                              * 35880020
*        4.    SYMBOL  X           IF ADDR SYMBOLIC AND ONLY 1 GROUP  * 35940020
*        5.    SYMBOL                                                 * 36000020
*              ADDR  X X X X  X X X X   (SEE 1, 2, AND 3 ABOVE)       * 36060020
*        6.    ADDR  X                                                * 36120020
*              ADDR  X                                                * 36180020
*               ETC.    (THIS FORMAT RESULTS FROM USING MULTIPLICITY) * 36240020
*********************************************************************** 36300020
LSTX50   EQU   *                                                        36360020
         L     R6,OUTBUF           GET PTR TO OUTPUT BUFFER             36420020
         LA    R6,DATAOFF(R6)      INCRE BUF PTR PAST LL00 FIELD        36480020
         L     R3,CONAREA          R3=PTR TO CONVERT OUTPUT AREA        36540020
LSTX52   EQU   *                                                        36600020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  36660020
         SPACE                                                          36720020
*********************************************************************** 36780020
*                                                                     * 36840020
*  IF ADDRESS WAS SYMBOLIC AND THERE ARE 2 OR MORE FIELDS THE ROUTINE * 36900020
*  IS ENTERED HERE. AFTER THE SYMBOL IS PRINTED ON A SEPARATE LINE.   * 36960020
*                                                                     * 37020020
*********************************************************************** 37080020
LSTX54   EQU   *                                                        37140020
         L     R15,TSTCONVT        PTR TO CONVERT ROUTINE               37200020
         LA    R1,APDE             PTR TO ADDR PDE, ADDR TO CONVERT     37260020
         LCR   R1,R1               INDICATE ADDR CONVERSION.            37320020
         SR    R0,R0               SET R0 NEGATIVE TO                   37380020
         BCTR  R0,NULL                 INDICATE CONVERT TO PRINTABLE    37440020
         BALR  R14,R15             GO TO CONVERT ROUTINE                37500020
         LTR   R15,R15             TEST CONVERT RETURN CODE.            37560020
         BNZ   LSTCVTRC            IF NON-ZERO, BRANCH                  37620020
         MVC   ZERO(ADDRLEN,R6),CONDATA(R3)  MOVE ADDR TO BUF           37680020
         LA    R6,ADDRLEN(R6)      INCRE BUF PTR PAST ADDR              37740020
         TM    COMFLGS,DATASIZE    ARE THERE 4 FIELDS TO LIST           37800020
         BO    LSTX57              IF LESS THAN 4, BRANCH               37860020
         LR    R2,R5               GET LENGTH OF AN OUTPUT FIELD        37920020
         SLL   R2,TWO+ONE          LNTH*4*2  4=NO. OF FLDS, 2=PRINTSIZE 37980020
         LA    R2,SP5(R6,R2)       CALCULATE BUF PTR AFTER 4 FIELDS     38040020
         C     R2,ENDOBUF          WILL 4 GROUPS + ADDR FIT IN BUF      38100020
         BNH   LSTX56              IF GRPS+ADDR WILL FIT, BRANCH        38160020
         OI    COMFLGS,NOINDENT    SET SW TO PREVENT INDENTATION.       38220020
         BAL   R7,LSTIO            GO OUTPUT ADDR ONLY                  38280020
         S     R2,AFLEN            REDUCE OUTPUT LINE LNTH BY ADDR+2SP  38340020
LSTX55   EQU   *                                                        38400020
         SR    R0,R0               SET R0 TO A (-1) TO SHOW             38460020
         BCTR  R0,NULL                 CONVERTION TO PRINTABLE.         38520020
         SPACE                                                          38580020
*********************************************************************** 38640020
*                                                                     * 38700020
*  DATA CONVERT LOOP                                                  * 38760020
*  IF THE NEXT GROUPS OF DATA WILL FIT INTO THE BUFFER OR IF THE ADDR * 38820020
*  WAS SYMBOLIC AND THERE IS ONLY ONE GROUP, THIS ROUTINE IS ENTERED. * 38880020
*                                                                     * 38940020
*********************************************************************** 39000020
LSTX56   EQU   *                                                        39060020
         ST    R2,ENDOGRP          SAVE STOP ADDR FOR 4 GROUPS          39120020
LSTX57   EQU   *                                                        39180020
         LA    R1,VPDE             SET UP FIELDS TO CONVERT A VALUE     39240020
         LA    R6,SP1(R6)          INCRE BUF PTR AN EXTRA SPACE         39300020
LSTX59   EQU   *                                                        39360020
         LA    R6,SP1(R6)          INCRE BUF PTR FOR SPACE BETWN GRPS   39420020
         SPACE                                                          39480020
         L     R15,TSTCONVT        GET ADDR OF CONVERT ROUTINE          39540020
         BALR  R14,R15             GO TO CONVERT ROUTINE                39600020
         LTR   R15,R15             TEST RETURN CODE                     39660020
         BNZ   LSTCVTRC            IF RC=NON-ZERO, BRANCH               39720020
         IC    R15,CONLFLD(R3)     PICK UP LENGTH OF CONVERTED DATA     39780020
         BCTR  R15,NULL            REDUCE LENGTH BY 1 FOR MVC INSTR     39840020
         EX    R15,DATAMOVE        MOVE CONVERTED DATA TO BUF           39900020
         LA    R6,ONE(R15,R6)      INCRE BUF PTR PAST A DATA FIELD      39960020
         L     R15,VPDEPT              R15=ADDR OF LAST INPUT DATA      40020020
         AH    R15,VPDEL           UPDATE DATA PTR BY LNTH OF LAST FLD  40080020
         ST    R15,VPDEPT          SET UP VALUE PDE FOR NEXT DATA       40140020
         BCT   R4,LSTX62           HAS CONTROL REACHED 0, IF NOT, BRNCH 40200020
         CH    R4,REMAIN           IS REMAINDER 0, (NOTE- R4=0)         40260020
         BE    LSTX66              IF ZERO, BRANCH TO TEST FOR COMPL    40320020
         LH    R2,REMAIN           PICK UP REMAINDE LENGTH              40380020
         STH   R2,VPDEL            SET VALUE LENGTH AND                 40440020
         STH   R4,REMAIN           SET REMAINDER TO 0 (NOTE-- R4=0)     40500020
         LA    R4,ONE              SET A CONTROL VALUE OF 1             40560020
LSTX62   EQU   *                                                        40620020
         C     R6,ENDOGRP          TEST FOR END OF A GROUP OF 4 FIELDS  40680020
         BL    LSTX59              IF NOT, GO PUT NEXT FIELD IN BUF     40740020
         TM    COMFLGS,SECOND      IS THIS THE 2ND GROUP OF 4           40800020
         BO    LSTX76              IF 2ND GROUP, BRANCH                 40860020
         SPACE 2                                                        40920020
*********************************************************************** 40980020
*  AT THIS POINT, ONE GROUP OF 4 IS IN THE BUF AND A TEST MUST BE MADE* 41040020
*  IF A SECOND GROUP OF 4 WILL FIT. IF IT WILL FIT, AN EXTRA SPACE IS * 41100020
*  INSERTED IN THE BUF TO SEPARATE THE GROUPS OF 4.                   * 41160020
*********************************************************************** 41220020
         SPACE                                                          41280020
         LR    R2,R5               GET LENGTH OF AN OUTPUT FIELD        41340020
         SLL   R2,TWO+ONE          L*4*2, LNTH TIMES FLDS/GRP TIMES 2.  41400020
         LA    R2,SP5(R6,R2)       INCRE BUF PTR BY 2SP+3SP+(4*DATALEN) 41460020
         OI    COMFLGS,SECOND      SET FLAG TO SHOW SECOND GRP          41520020
         C     R2,ENDOBUF          TEST WHETHER RESULT IS PAST BUF END  41580020
         BNH   LSTX56              IF DATA WILL FIT, BRANCH             41640020
         SPACE                                                          41700020
LSTX64   EQU   *                                                        41760020
         BAL   R7,LSTIO            GO OUTPUT DATA IN BUF                41820020
         LR    R2,R5               GET LENGTH OF AN OUTPUT FIELD        41880020
         SLL   R2,TWO+ONE          L*4*2, LNTH TIMES FLDS/GRP TIMES 2   41940020
         LA    R2,SP5(R6,R2)       CALCULATE BUF PTR AFTER 4 MORE FLDS  42000020
         TM    COMFLGS,NOINDENT    TEST IF DATA TO BE INDENTED          42060020
         BO    LSTX55              IF NO INDENTATION REQUIRED, BRANCH   42120020
         LA    R6,ADDRLEN(R6)      INCRE BUF PTR FOR INDENTATION        42180020
         LA    R2,ADDRLEN(R2)      INCRE STOP ADDR BY INDENTATION       42240020
         B     LSTX55              GO BACK TO DATA PROCESS LOOP         42300020
         SPACE                                                          42360020
LSTX66   EQU   *                                                        42420020
         TM    COMFLGS,ARTIMSW     WAS CONTROL TRU MULTIPLICITY         42480020
         BNO   LSTX68              IF TRU, BRANCH                       42540020
         LH    R2,A1M              PICK UP TRU MULTIPLICITY             42600020
         BCT   R2,LSTX72           DECRE IT AND TEST FOR COMPLETION     42660020
LSTX68   EQU   *                                                        42720020
         TM    COMFLGS,OUTCORE     WAS REQUEST TRUNCATED BY TOP ADDR    42770020
         BO    LSTX84              IF TRUNCATED, BRANCH                 42772020
LSTX70   EQU   *                                                        42774020
         BAL   R7,LSTIO            GO OUTPUT LAST BUF                   42780020
         B     LSTCC0              GO BACK TO MAINLINE.                 42840020
LSTX72   EQU   *                                                        42900020
         STH   R2,A1M              SAVE REMAINING TRU MULTIPLICITY      42960020
         LH    R2,REMAIN2          PICK UP SAVED REMAINDER              43020020
         STH   R2,REMAIN           RESTORE IT TO REMAINDER FIELD        43080020
         LH    R4,ARTIFMUL         RESET CONTROL TO ARTIFICIAL MULTIP.  43140020
         STH   R5,VPDEL            RESET INPUT DATA LENGTH              43200020
LSTX76   EQU   *                                                        43260020
         BAL   R7,LSTIO            GO OUTPUT CURRENT BUF LOAD           43320020
         NI    COMFLGS,HEXFF-SECOND    TURN OFF SECOND GRP FLAG         43380020
         B     LSTX52              GO SET UP ANOTHER LINE.              43440020
         SPACE                                                          43490020
LSTX84   EQU   *                                                        43492020
         LH    R4,LASTLEN          PICK UP POSSIBLE SHORT FIELD LENGTH  43494020
         LTR   R4,R4               IS THERE A SHORT FIELD TO LIST       43496020
         BZ    LSTX70              IF NOT, OR IF DONE, BRANCH           43498020
         LA    R5,FOUR             SET UP GROUP LENGTH                  43498420
         CR    R4,R5               IS THERE MORE THAN ONE GROUP         43498820
         BNH   LSTX90              IF NOT, BRANCH                       43499220
         LA    R15,FWBDY           PREPARE TO ISOLATE ODD NO. OF BYTES  43499620
         NR    R15,R4              ISOLATE BYTES NOT A MULTIPLE OF 4    43499720
         SRL   R4,TWO              DIVIDE NO. OF BYTES BY 4             43499820
LSTX86   EQU   *                                                        43499920
         STH   R15,REMAIN2         SAVE ODD BYTES                       43519920
         STH   R4,ARTIFMUL         SAVE QUOTIENT AS ARTIFICIAL MULTI    43529920
         LA    R2,ONE              SET TRUE MULTIPLICITY TO ONE         43539920
         XC    LASTLEN,LASTLEN     MAKE LAST LENGTH ZERO TO STOP LOOP   43546620
         B     LSTX72              GO FINISH LISTING CORE               43548620
         SPACE                                                          43550620
LSTX90   EQU   *                                                        43552620
         LR    R5,R4               SET FOR LENGTH EQUALS REMAINDER      43553020
         SR    R15,R15             SET FOR REMAINDER OF ZERO            43553120
         LA    R4,ONE              SET ARTIFICIAL MULTIPLICITY FOR 1    43553220
         B     LSTX86              GO FINISH SETUP                      43569920
         TITLE 'IKJEGLST, ''LIST'', REGISTER LISTING ROUTINE'           43586620
*********************************************************************** 43603320
*                                                                     * 43620020
*  LIST REGISTER ROUTINE, LIST THE GENERAL OR FLOATING POINT REGISTERS* 43680020
*  IN HEXADECIMAL FORMAT. WILL LIST EITHER A SINGLE REGISTER OR A     * 43740020
*  RANGE OF REGISTERS.                                                  43800020
*                                                                     * 43860020
*********************************************************************** 43920020
         SPACE                                                          43980020
LSTREG   EQU   *                                                        44040020
         L     R2,A1               GET REG NUMBER OF FIRST ADDRESS      44100020
         L     R6,OUTBUF           ADDR OF OUTPUT BUF                   44160020
         LA    R6,DATAOFF(R6)      INCREMENT BUF PTR PAST LL00 FIELD    44220020
         TM    PDEFLG4,GENR        IS ADDR TYPE GENERAL REGISTER        44280020
         BNO   LSTREG30            IF NOT, BRANCH TO FLOATING PT        44340020
         SPACE                                                          44400020
*  SETUP ROUTINE FOR LISTING CONTENTS OF GENERAL REGISTERS.             44460020
         SPACE                                                          44520020
         CLI   A1TYPE,FCODE        IS REQUESTED FORMAT FIXED PT BINARY  44580020
         LA    R4,GRFLENO          SET UP OUTPUT LNTH FOR FIXED PT      44640020
         BE    LSTREG08            IF FIXED, SETUP IS COMPLETE, BRANCH  44700020
         SPACE                                                          44760020
*  IF FORMAT IS NOT F TYPE, DEFAULT TYPE TO HEX                         44820020
         SPACE                                                          44880020
         MVI   A1TYPE,HEXCODE      SET TYPE FIELD                       44940020
         LA    R4,GRXLENO          SET UP OUTPUT LNTH FOR HEX DATA      45000020
         SPACE                                                          45060020
*  NEXT, SET UP A PTR TO THE GENERAL REGISTER SAVE AREA OF THE        * 45120020
*  SVRB OF THE BREAKPOINT SVC ON THE TCB OF THE INTERRUPTED PROB PROG * 45180020
         SPACE                                                          45240020
LSTREG08 EQU   *                                                        45300020
         L     R5,PPTCB            GET ADDRESS OF PROB PROG TCB         45360020
         USING TCB,R5              ADDRESSABILITY FOR TCB MAP DSECT     45420020
         L     R5,TCBRBP           GET ADDRESS OF TEST'S BRKPT SVRB     45480020
         DROP  R5                                                       45540020
         LA    R5,RBGRSAVE(R5)     SET UP ADDRESS OF REG SAVE AREA      45600020
         SPACE                                                          45660020
         MVI   REMAIN+ONE,GRINCR   SET REG NO. INCREMENT FOR GEN REGS   45720020
         LA    R3,FOUR             SET INPUT DATA LENGTH (AND INCRE)    45780020
         LA    R1,GRMAX            SET MAX REG NUMBER FOR GEN REGS      45840020
         STH   R3,VPDEL            SET INPUT DATA LENGTH                45900020
         LA    R15,RADDRLEN+SP2(R4)    LNTH OF 1 OUTPUT FIELD TIMES     45950020
         SLL   R15,TWO                     FOUR=REQUIRED LINE LNTH.     45952020
         LA    R15,THREE*SP2(R15,R6) INCRE LNTH FOR INTER-DATA-GRP SP'S 45954020
         MVI   REMAIN2+ONE,SP2     SET UP SPACING FACTOR                45956020
         EJECT                                                          45960020
*********************************************************************** 46020020
*                                                                     * 46080020
*  COMMON PART OF SETUP ROUTINE, USED BY BOTH FLOATING PT AND GENERAL * 46140020
*  REGISTER ROUTINES.  AT ENTRY, REGISTERS MUST BE AS FOLLOWS         * 46200020
*        1  MAXIMUM REGISTER NUMBER FOR THE REG TYPE BEING LISTED     * 46260020
*        2  REGISTER NUMBER OF THE FIRST REGISTER TO BE LISTED        * 46320020
*        3  INPUT DATA INCREMENT (FOR INCREMENTING CORE ADDRESSES     * 46380020
*           OF THE RB OR TCB REG SAVE AREA.                           * 46440020
*        4  OUTPUT DATA LENGTH OR MAX OUTPUT DATA LENGTH.             * 46500020
*        5  ADDRESS OF THE APPROPIATE REGISTER SAVE AREA              * 46560020
*        6  PTR TO THE FIRST DATA BYTE OF THE OUTPUT BUFFER           * 46620020
*        REMAIN    CONTAINS APPROPIATE INCREMENT FOR REG NUMBERS      * 46670020
*        REMAIN2   CONTAINS SPACING FACTOR USED FOR GROUP SEPARATION  * 46672020
*                                                                     * 46680020
*********************************************************************** 46740020
LSTREG20 EQU   *                                                        46800020
         C     R15,ENDOBUF         IS CUR LINE LNTH ENOUGH FOR 4 GRPS   47040020
         BNH   LSTREG22            IF LINE LNTH IS OK, BRANCH           47160020
         SPACE                                                          47220020
*********************************************************************** 47270020
*  IF LINE LENGTH TOO SMALL FOR 4 GENERAL REGS OR 2 FLOATING PT REG,  * 47330020
*  USE THE NORMAL END OF BUFFER ADDRESS AS A STOPPER AND PUT AS MANY  * 47332020
*  GROUPS ON ONE ONE AS WILL FIT.                                     * 47334020
*********************************************************************** 47450020
         SPACE                                                          47460020
         L     R15,ENDOBUF         GET END OF BUFFER ADDRESS            47520020
         SPACE                                                          47570020
LSTREG22 EQU   *                                                        47580020
         ST    R15,ENDOGRP         SET END OF LINE (STOPPER) FOR LSTREG 47640020
         STH   R3,A1L              SET INPUT DATA INCREMENT             47700020
         LR    R3,R2               GET FIRST REG NUMBER TO BE LISTED    47760020
         ST    R5,REGSTART         SAVE START ADDRESS OF REG SAVE AREA  47820020
         SLL   R3,TWO              MULTIPLY REG NUMBER BY 4 FOR OFFSET  47880020
         AR    R5,R3               ADD OFFSET TO REG SAVE START ADDR    47940020
         C     R2,A2               COMPARE 1ST ADDR TO LAST (TEST WRAP) 48000020
         BNH   LSTREG24            IF REGS DO NOT WRAP, BRANCH          48060020
         ST    R1,A2               IF REGS WRAP, SET 2ND ADDR TO MAX    48120020
         OI    COMFLGS,WRAPSW          REG NUMBER AND TURN ON WRAP SW.  48180020
LSTREG24 EQU   *                                                        48240020
         IC    R15,A1TYPE          GET FORMAT TYPE FOR THIS REQUEST     48300020
         MVC   APDE(APL),PDELDNAM  MOVE THE ADDRESS PDE TO WORKING CORE 48360020
         STC   R15,VPDET           SET VALUE PDE TO PROPER FORMAT TYPE  48420020
         LA    R1,A1               GET PTR TO CURRENT REG ADDRESS AND   48480020
         ST    R1,APDE+(PDEADRPT-IKJPARMA)  SET ADDR PDE PTR TO IT.     48540020
         B     LSTREG50            GO PROCESS LIST REG REQUEST          48600020
         EJECT                                                          48660020
*********************************************************************** 48720020
*                                                                     * 48780020
*  SETUP ROUTINE FOR LISTING THE CONTENTS OF THE FLOATING POINT REGS.   48840020
*                                                                     * 48900020
*********************************************************************** 48960020
LSTREG30 EQU   *                                                        49080020
         TM    PDEFLG4,SFPR        TEST REG TYPE FOR RE OR RD           49140020
         BO    LSTREG40            IF RE, BRANCH                        49200020
         TM    LSTFLGS,TYPEFLG     WAS TYPE SPECIFIED BY THE USER       49260020
         BZ    LSTREG32            IF NOT, BRANCH, AND DEFAULT TO 'D'   49320020
         LA    R4,RDXLENO          SET UP FOR POSSIBLE HEX OUTPUT       49380020
         CLI   A1TYPE,HEXCODE      WAS THE SPECIFIED TYPE HEX           49440020
         BE    LSTREG34            IF HEX, BRANCH                       49500020
LSTREG32 EQU   *                                                        49560020
         LA    R4,RDDLENO          SET UP OUTPUT LENGTH FOR 'D' FORMAT  49620020
         MVI   A1TYPE,DCODE        SET TYPE TO 'D'                      49680020
LSTREG34 EQU   *                                                        49740020
         MVI   VPDEL+ONE,RDINLEN   SET INPUT DATA LENGTH FOR 'D' TYPE   49800020
         B     LSTREG46            GO TO COMMON FLT PT SETUP ROUTINE    49850020
         SPACE                                                          49860020
LSTREG40 EQU   *                                                        51000020
         TM    LSTFLGS,TYPEFLG     WAS TYPE SPECIFIED BY THE USER       51060020
         BZ    LSTREG42            IF NOT, BRANCH, AND DEFAULT TO 'E'   51120020
         LA    R4,REXLENO          SET UP FOR POSSIBLE HEX OUTPUT       51180020
         CLI   A1TYPE,HEXCODE      WAS THE SPECIFIED TYPE HEX           51240020
         BE    LSTREG44            IF HEX, BRANCH                       51300020
LSTREG42 EQU   *                                                        51360020
         LA    R4,REELENO          SETUP OUTPUT LNTH FOR 'E' FORMAT     51420020
         MVI   A1TYPE,ECODE        SET TYPE TO 'E'                      51480020
LSTREG44 EQU   *                                                        51540020
         MVI   VPDEL+ONE,REINLEN   SET INPUT DATA LENGTH FOR 'E' TYPE   51600020
         SPACE                                                          51670020
*********************************************************************** 51710020
*  COMMON SET UP FOR FLOATING POINT REGS.                             * 51712020
*        SET REGISTER NUMBER INCREMENT                                  51714020
*        SET CORE ADDRESS INCREMENT                                     51716020
*        GET REGISTER SAVE AREA ADDRESS FOR FLOATING POINT REGISTERS    51718020
*********************************************************************** 51718420
LSTREG46 EQU   *                                                        51718820
         MVI   REMAIN+ONE,FPRINCR  SET REG NUMBER INCREMENT             51719220
         LA    R3,RDINLEN          SET INPUT DATA ADDR INCREMENT        51719620
         LA    R1,FPRMAX           MAX REG NUMBER                       51719720
         SPACE                                                          51719820
         L     R5,PPTCB            GET PTR TO TCB FOR BREAKPOINTED TASK 51719920
         LA    R15,L'TCBFRS        LNTH OF TCB FLOATING PT REG SAVE     51739920
         SR    R5,R15              BACK UP TCB PTR TO TCB PREFIX        51749920
         USING TCBFIX,R5           ADDRESSABILITY FOR TCB PREFIX        51759920
         LA    R5,TCBFRS           GET PTR TO FLOATING PT REG SAVE      51766620
         DROP  R5                                                       51768620
         LA    R15,RADDRLEN+SP2(R4)    CALCULATE LENGTH OF OUTPUT       51769020
         AR    R15,R15             DOUBLE IT FOR LENTH OF TWO FIELDS    51769420
         LA    R15,SP4(R15,R6)     CALCULATE SPACE FOR 2 REGS IN BUF    51769820
         MVI   REMAIN2+ONE,SP4     SET SPACING FACTOR FOR FLT PT REGS   51770220
         B     LSTREG20            RETURN TO LIST REG MAINLINE          51770620
         EJECT                                                          51773320
*********************************************************************** 51780020
*                                                                     * 51840020
*  LIST REGISTER MAINPROCESS ROUTINE, AT ENTRY, THE FOLLOWING REGS    * 51900020
*  ARE INITIALIZED                                                    * 51960020
*        2  CURRENT REG NUMBER                                        * 52020020
*        4  LENGTH OF AN OUTPUT DATA FIELD                            * 52080020
*        5  PTR TO REG SAVE AREA FOR CURRENT REGISTER                 * 52140020
*        6  CURRENT BUFFER PTR                                        * 52200020
*  OTHER REGISTERS WITH CONSTANT USES ARE,                            * 52260020
*        3  PTR TO CONVERT OUTPUT AREA                                * 52320020
*                                                                     * 52380020
*********************************************************************** 52440020
LSTREG50 EQU   *                                                        52500020
         L     R3,CONAREA          SET UP A PTR TO CONAREA              52560020
LSTREG54 EQU   *                                                        52620020
         SR    R0,R0               CLEAR REG 0 TO 0 THEN MAKE IT NEG    52680020
         BCTR  R0,NULL                 TO INDICATE CONVERT TO PRINTABLE 52740020
LSTREG56 EQU   *                                                        52800020
         LA    R1,APDE             R1=ADDR OF ADDRESS PDE               52860020
         L     R15,TSTCONVT        R15=ADDR OF IKJEGCVT                 52920020
         LCR   R1,R1               R1 NEG INDICATES ADDR CONVERSION     52980020
         BALR  R14,R15             GO CONVERT ADDR                      53040020
         LTR   R15,R15             TEST RETURN CODE                     53100020
         BNZ   LSTCVTRC            IF NON-ZERO, BRANCH                  53160020
         IC    R15,CONLFLD(R3)     PICK UP LENGTH OF ADDRESS FIELD      53220020
         BCTR  R15,NULL            DECREMENT LENGTH FOR AN MVC INSTR    53280020
         EX    R15,DATAMOVE        MOVE ADDRESS TO BUFFER               53340020
         LA    R6,ONE(R15,R6)      INCREMENT BUF PTR PAST DATA          53400020
         ST    R5,VPDEPT           SET VALUE PDE TO ADDR OF REG CONTENT 53460020
         L     R15,TSTCONVT        R15=ADDR OF CONVERT ROUTINE          53520020
         LA    R1,VPDE             R1=ADDR OF VALUE PDE                 53580020
         BALR  R14,R15             GO CONVERT REG CONTENTS              53640020
         LTR   R15,R15             TEST RETURN CODE                     53700020
         BNZ   LSTCVTRC            IF NON-ZERO, BRANCH                  53760020
         IC    R15,CONLFLD(R3)     PICK UP LENGTH OF CONVERTED DATA     53820020
         BCTR  R15,NULL            DECREMENT BY 1 FOR AN MVC INSTR      53880020
         EX    R15,REGMOVE         MOVE CONVERTED DATA TO BUFFER        53940020
         LA    R6,SP2(R4,R6)       INCREMENT BUF PTR PAST DATA          54000020
         C     R2,A2               IS ADDR JUST PROCESSED END OF RANGE  54060020
         BNL   LSTREG70            IF YES, BRANCH, AND TEST FOR WRAP    54120020
         AH    R2,REMAIN           INCREMENT REG NUMBER                 54180020
         AH    R5,A1L              INCREMENT INPUT DATA PTR             54240020
LSTREG60 EQU   *                                                        54300020
         ST    R2,A1               STORE ADDR OF NEXT REG TO LIST       54360020
         LA    R15,SP2+RADDRLEN(R4,R6)  CALCULATE PTR AFTER NXT FLD     54420020
         AH    R15,REMAIN2         ADD APPROPIATE SPACING FACTOR        54470020
         C     R15,ENDOGRP         WILL ANOTHER ADDR + DATA FIT IN BUF  54480020
         BH    LSTREG62            IF NOT, BRANCH                       54540020
         AH    R6,REMAIN2          INCRE BUF PTR BY INTER-GROUP SPACE   54600020
         B     LSTREG56            GO PROCESS NEXT REG                  54660020
         SPACE                                                          54720020
LSTREG62 EQU   *                                                        54780020
         BAL   R7,LSTIO            ELSE, GO OUTPUT BUFFER               54840020
         B     LSTREG54            GO LIST MORE REGS                    54900020
LSTREG70 EQU   *                                                        54960020
         TM    COMFLGS,WRAPSW      ELSE TEST FOR WRAP                   55020020
         BNO   LSTREG80            IF NOT, LISTING IS DONE, BRANCH      55080020
         L     R5,REGSTART         ELSE GET REG SAVE START ADDR         55140020
         L     R15,PDE2USER        GET 2ND REG NUMBER GIVEN BY USER     55200020
         SR    R2,R2                   SET UP ADDR FOR REG 0            55260020
         ST    R15,A2                  SET ADDR2 TO LAST REG ADDR       55320020
         NI    COMFLGS,HEXFF-WRAPSW    TURN OFF WRAP SW                 55380020
         B     LSTREG60            GO PROCESS REMAIN REGS               55440020
LSTREG80 EQU   *                                                        55500020
         BAL   R7,LSTIO            GO OUTPUT LAST DATA                  55560020
         B     LSTCC0              RETURN TO LIST MAINLINE              55620020
REGMOVE  MVC   SP2(NULL,R6),CONDATA(R3)   MOVES DATA TO BUFFER          55680020
         TITLE 'IKJEGLST, ''LIST'', COMMON INTERFACE WITH IKJEGIO'      55740020
*********************************************************************** 55800020
*                                                                     * 55860020
*  THIS ROUTINE SETS UP THE PTRS AND CALLS IKJEGIO1 TO OUTPUT A LINE  * 55920020
*  OF DATA. AT ENTRY, THE FOLLOWING REGS ARE SET.                     * 55980020
*        R6  POINTS TO THE NEXT AVAILABLE BYTE IN THE BUFFER          * 56040020
*        R7  HAS THE RETURN POINT ADDRESS                             * 56100020
*                                                                     * 56160020
*  THE CONTENTS OF REGS 0, 1, 6, 14, AND 15 ARE MODIFIED BY THIS RTN  * 56220020
*                                                                     * 56280020
*********************************************************************** 56340020
         SPACE                                                          56400020
LSTIO    EQU   *                                                        56460020
         LA    R1,IOLIST           SET UP PTR TO I WORD PARM LIST       56520020
         LR    R15,R6              R15=PTR TO 'END OF DATA'+1           56580020
         L     R6,OUTBUF           R6=PTR TO BEGINNING OF BUF           56640020
         SR    R15,R6              CALCULATE LENGTH OF DATA             56700020
         STH   R15,F1STHALF(R6)    LNTH TO 1ST HALF WORD OF BUFFER      56760020
         SPACE                                                          56820020
*  COMMON PORTION OF IO ROUTINE.                                        56880020
         SPACE                                                          56930020
LSTIO1   EQU   *                                                        56940020
         TM    TSTFLGS1,TSTPRINT+TSTFIRST  IS OUTPUT TO A DS 1ST TIME   57000020
         L     R15,TPUTADDR        SET UP ADDRESS OF IKJEGIO1           57060020
         BM    FIRSTIO             IF OUTPUT TO DS 1ST TIME, BRANCH     57120020
         SR    R0,R0               IF NOT 1ST TIME, INDICATE SO BY R0=0 57180020
LSTIO4   EQU   *                                                        57240020
         BALR  R14,R15             GO TO IKJEGIO1                       57300020
         MVI   DATAOFF(R6),BLANK   MOVE A BLANK TO START OF DATA AREA   57360020
         MVC   DATAOFF+ONE(LSTBUFL,R6),DATAOFF(R6)     BLANK OUT BUFFER 57420020
         LA    R6,DATAOFF(R6)      INCRE BUF PTR PAST LL00 FIELD        57480020
         LTR   R15,R15             TEST RETURN CODE                     57540020
         BCR   EQZERO,R7           IF ZERO, RETURN TO CALLER            57600020
         TM    COMFLGS,PARSEFLG    IS THIS A PARSE EXIT                 57660020
         BCR   ONE,R7              IF PARSE EXIT, RETURN TO IT.         57720020
         CH    R15,H16             IF RC=16, BRANCH                     57780020
         BE    LSTCC16             IF RC=16, BRANCH                     57840020
         XC    LSTRETCD,LSTRETCD   SET THE RETURN CODE TO 0             57900020
         B     LSTMN90             GO CLEAN UP AND RETURN               57960020
         SPACE                                                          58020020
*********************************************************************** 58080020
*                                                                     * 58140020
*  THIS ROUTINE IS ENTERED AT THIS POINT WITH R1=COMPLIMENT OF THE    * 58200020
*  ADDRESS OF THE TWO WORD LIST IF OUTPUT IS A MESSAGE.               * 58260020
*                                                                     * 58320020
*********************************************************************** 58380020
LSTIO2   EQU   *                                                        58440020
         L     R6,OUTBUF           SET R6 TO POINT AT OUTPUT BUF        58500020
         B     LSTIO1              GO TO COMMON PART OF IO ROUTINE      58560020
         SPACE                                                          58620020
FIRSTIO  EQU   *                                                        58680020
         L     R14,TSTANSPL        PICK UP BASE ADDR FOR PARSE DSECT    58740020
         USING IKJPARMD,R14        ADDRESSABILITY FOR THE PDL           58800020
         LA    R0,DSNAME           SET UP PTR TO THE DSNAME PDE         58860020
         OI    TSTFLGS1,TSTFIRST   SET FIRST TIME SWITCH TO 1           58920020
         DROP  R14                                                      58980020
         B     LSTIO4              RETURN TO MAIN IO ROUTINE            59040020
         TITLE 'IKJEGLST, ''LIST'', GENERAL SUBROUTINES'                59100020
*********************************************************************** 59160020
*                                                                     * 59220020
*  THIS CLOSED SUBROUTINE CHECKS SEGMENTS OF CORE FOR INSERTED BREAK- * 59280020
*  POINTS AND REPLACES THEM WITH THE ORIGINAL CONTENS OF THE LOCATION.* 59340020
*  THE ROUTINE MOVES THE NEXT 32 BYTES TO BE LISTED TO A WORKAREA AND * 59400020
*  SCANS THE BREAK ELEMENT QUEUE FOR ANY BREAK POINT SVC'S WITHIN THE * 59460020
*  32 BYTE FIELD. WHEN A BREAKPOINT SVC IS FOUND TO BE IN THE RANGE,  * 59520020
*  THE ORIGINAL INSTRUCTION IS MOVED (1ST 2 BYTES) INTO WORK AREA OVER* 59580020
*  THE BREAKPOINT SVC.  REGISTERS ARE SAVED AND RESTORED.          *    59640020
*                                                                     * 59700020
*  INPUT A1=ORIGINAL START ADDR OF DATA IN HOLD AREA                  * 59760020
*        VPDEPT=ADDR OF NEXT BYTE OF THE HOLD AREA TO BE LISTED.        59820020
*                                                                     * 59880020
*********************************************************************** 59940020
         SPACE                                                          60000020
LSTBPT   EQU   *                                                        60060020
         SAVE  (14,12)             STANDARD SAVE                        60120020
         SPACE                                                          60180020
*  CALCULATE THE NEW DATA ADDRESS.                                      60240020
         SPACE                                                          60300020
         L     R3,VPDEPT           GET ADDR OF NEXT BYTE OF HOLDAREA    60360020
         LA    R5,HOLDAREA         SET UP START ADDR OF HOLDING CORE    60420020
         SR    R3,R5               DETERMINE NUMBER OF BYTES USED       60480020
         A     R3,A1               INCRE INPUT CORE ADDR BY AMT LISTED  60540020
         LA    R4,LSTIBLK(R3)      ESTABLISH ADDR OF END OF NEXT BLK    60600020
         C     R4,TSTTOP           IS END ADDR GREATER THAN HIGHEST     60660020
         BH    LSTBPT30            IF OUT OF CORE, BRANCH TO ADJUST RTN 60720020
         LA    R1,LSTIBLK          USE STANDARD LENGTH FOR HOLD DATA    60780020
LSTBPT04 EQU   *                                                        60840020
         EX    R1,HOLDMVC          MOVE DATA TO HOLDING AREA            60900020
         SPACE                                                          60960020
*  IF THE DATA ADDRESS IS NOT ON A HALF WORD BOUNDARY, R0 WILL CONTAIN  61020020
*  A ONE (1), IF THE DATA ADDRESS IS ON A HALFWORD BOUNDARY, R0 WILL    61080020
*  CONTAIN A ZERO (0). THE CONTENTS OF R0 WILL THEN BE USED TO ADJUST   61140020
*  THE DATA ADDRESS AND THE HOLDAREA ADDRESS. THIS ADJUSTMENT IS TO     61200020
*  TAKE CARE OF THE CASE WHERE THE DATA START ADDRESS IS THE SECOND     61260020
*  BYTE OF A BREAKPOINT.                                                61320020
         SPACE                                                          61380020
         LA    R0,ONE              SET THE LOW ORDER BIT ON IN REG 0    61440020
         NR    R0,R3               TEST DATA ADDRESS FOR A HALFWORD BDY 61500020
         SR    R3,R0               ADJUST DATA START ADDRESS IF NEEDED  61560020
         SR    R5,R0               MAKE SAME CHANGE FOR HOLDAREA ADDR   61620020
         L     R6,BREAKTAB         GET PTR TO FIRST BREAK ELEMENT       61680020
         USING BRKELEM,R6          ADDRESSABILITY FOR BREAK ELEMENT     61740020
         LTR   R6,R6               IS THERE A 1ST BREAK ELEMENT         61800020
         BP    LSTBPT12            IF THERE IS A BREAK ELEMENT, BRANCH  61860020
         B     LSTBPT20            IF NONE, RETURN                      61920020
         SPACE                                                          61980020
LSTBPT08 EQU   *                                                        62040020
         L     R6,BRKLINK          PICK UP FOREWARD PTR                 62100020
         LTR   R6,R6               TEST FOR ANOTHER                     62160020
         BNP   LSTBPT20            IF NO MORE, BRANCH                   62220020
LSTBPT12 EQU   *                                                        62280020
         C     R3,BRKADDR          COMPARE START ADDR TO BREAKPOINT     62340020
         BH    LSTBPT08            IF BRK-PT LOW, NOT IN RANGE, BRANCH  62400020
         C     R4,BRKADDR          COMPARE END ADDR TO BREAKPOINT       62460020
         BNL   LSTBPT40            IF END ADDR HI OR EQ, ADDR IN RANGE  62520020
LSTBPT20 EQU   *                                                        62580020
         AR    R3,R0               RE-ADJUST DATA ADDRESS AS NEEDED     62640020
         AR    R5,R0               DO THE SAME FOR HOLD AREA ADDRESS.   62700020
         ST    R3,A1               SAVE ACTUAL CORE ADDR OF CUR DATA    62760020
         ST    R5,VPDEPT           RESET VALUE PDE TO PT AT HOLD AREA   62820020
         RETURN (14,12)            RETURN TO CALLER                     62880020
         SPACE                                                          62940020
LSTBPT30 EQU   *                                                        63000020
         L     R1,TSTTOP           PICK UP HIGHEST CORE ADDR            63060020
         LR    R4,R1               SET TOP ADDR AS TOP OF CORE          63120020
         SR    R1,R3               DETERMINE REMAINING LENGTH IN BYTES  63180020
         B     LSTBPT04            RETURN TO MAIN LSTBPT FLOW           63240020
         SPACE                                                          63300020
*********************************************************************** 63360020
*  IF A BREAK POINT IS FOUND IN THE RANGE, THE FOLLOWING CODE           63420020
*  WILL REPLACE THE BREAK POINT SVC WITH THE ORIGINAL INSTRUCTION       63480020
*********************************************************************** 63540020
         SPACE                                                          63600020
LSTBPT40 EQU   *                                                        63660020
         L     R2,BRKADDR          R2=ADDR OF BREAKPOINT SVC            63720020
         SR    R2,R3               DETERMINE OFFSET INTO HOLD AREA,     63780020
         AR    R2,R5               ADD THE ADDR OF HOLDAREA             63840020
         SPACE                                                          63900020
*  R2 NOW POINTS TO THE SVC INSTRUCTION IN THE HOLD AREA. TEST WHETHER  63960020
*    THE BREAK ELEMENT IS STILL ACTIVE.                                 64010020
         SPACE                                                          64020020
         TM    BRKFLGS1,BRKINACT   IS THIS BREAK ELEMENT STILL ACTIVE   64070020
         BO    LSTBPT08            IF NOT, BRANCH                       64072020
         SPACE                                                          64074020
*  IF THE BREAK ELEMENT IS STILL ACTIVE, REPLACE THE BREAKPOINT SVC     64076020
*    WITH THE DATA FROM THE BREAK ELEMENT.                              64076420
         SPACE                                                          64078020
         MVC   ZERO(TWO,R2),BRKINST    REPLACE SAVED INSTR              64080020
         B     LSTBPT08            RETURN TO SEARCH LOOP                64140020
         SPACE                                                          64200020
HOLDMVC  MVC   HOLDAREA(NULL),ZERO(R3) MOVE SEGMENT OF CORE TO HOLD.    64260020
         DROP  R6                                                       64320020
         EJECT                                                          64380020
*********************************************************************** 64440020
*                                                                     * 64500020
*  GENERAL SUBROUTINE FOR MOVING SYMBOLIC ADDRESSES TO THE OUTPUT BUF * 64560020
*        AT ENTRY,  R6 SHOULD POINT TO FIRST BYTE OF OUTPUT AREA      * 64620020
*                   R7 POINTS TO RETURN POINT.                        * 64680020
*********************************************************************** 64740020
         SPACE                                                          64800020
LSTSYM   EQU   *                                                        64860020
         OI    APDE+(PDEFLG2-IKJPARMA),CTNAMFLG TURN ON 'QUALIFIED' SW  64920020
*  TURN RELATIVE ADDR FLAG ON, AND ABSOLUTE ADDR SW OFF                 64980020
         XI    APDE+(PDEFLG4-IKJPARMA),RELADDR+ABSADDR                  65040020
         LA    R2,A1               GET ADDR OF INPUT DATA PTR           65100020
         ST    R2,APDE+(PDEADRPT-IKJPARMA) PUT IT IN THE ADDRESS PDE    65160020
         L     R6,OUTBUF           GET PTR TO THE OUTPUT BUFFER         65220020
         LA    R6,DATAOFF(R6)      INCRE BUFFER PTR PAST LL00 FIELD     65280020
         BAL   R14,LSTAMV          GO MOVE THE ADDRESS TO THE BUFFER    65340020
         L     R15,A1              R15=START ADDR OF DATA               65400020
         ST    R15,PPTEMP          MAKE START OF DATA ADDR BASE FOR REL 65460020
         L     R3,CONAREA                                               65520020
         SR    R0,R0               R0=0                                 65580020
         BCTR  R0,NULL             MAKE NEG TO SHOW CONVERT TO PRINT    65640020
         BAL   R14,LSTBPT          GO CLEAR BREAKPOINT SVC'S FROM DATA  65700020
         BR    R7                  RETURN TO CALLER                     65760020
         EJECT                                                          65770020
*********************************************************************** 65810020
*  THIS ROUTINE WILL ADD THE PRODUCT OF THE LENGTH AND MULTIPLICITY   * 65860020
*  TO THE START ADDRESS AND COMPARE THE SUM TO 'TSTTOP'. IF THE       * 65910020
*  SUM EXCEEDS 'TSTTOP', A NEW MULTIPLICITY IS CALCULATED AND SWITCH  * 65960020
*  'OUTCORE' IN COMFLGS IS SET, THE NUMBER OF BYTES NOT OUT           * 66010020
*  OF CORE IS PLACED 'LASTLEN', AND THE CALCULATED MULTIPLICITY IS    * 66060020
*  STORED IN 'A1M'.                                                   * 66110020
*  RETURN CODES---   4  IF 'NEW' MULTIPLICITY IS ZERO                 * 66160020
*                    0  FOR ALL OTHER CASES.                          * 66210020
*********************************************************************** 66260020
LSTLMTCK EQU   *                                                        66310020
         SAVE  (0,12)                                                   66360020
         L     R2,A1               GET DATA START ADDR                  66410020
         LH    R3,A1L              GET LENGTH FOR THIS REQUEST          66460020
         LA    R2,ZERO(ZERO,R2)    CLEAR HIGH BYTE FOR CALCULATION      66510020
         MH    R3,A1M              MULTIPLY  (LENGTH X MULTIPLICITY)    66560020
         AR    R3,R2               ADD START ADDR TO LENGTH OF REQUEST  66610020
         BCTR  R3,NULL             DECREMENT TO MAKE EXCLUSIVE          66620020
         C     R3,TSTTOP           COMPARE POTENTIAL END ADDR TO TOP    66660020
         BH    LSTLMT20            IF REQUEST GOES OUT OF CORE, BRANCH  66710020
LSTLMT10 EQU   *                                                        66760020
         SR    R15,R15             SET RETURN CODE TO ZERO              66810020
LSTLMT14 EQU   *                                                        66860020
         RETURN  (0,12)                                                 66910020
         SPACE                                                          66960020
LSTLMT20 EQU   *                                                        67010020
         L     R5,TSTTOP           GET LAST MACHINE ADDRESS             67060020
         SR    R4,R4               CLEAR EVEN REG FOR DIVIDE            67110020
         LH    R3,A1L              GET LENGTH FOR THIS REQUEST          67160020
         SR    R5,R2               TOP ADDR - START ADDR                67210020
         LA    R5,ONE(ZERO,R5)     ADD ONE TO MAKE LASTLEN INCLUSIVE    67220020
         DR    R4,R3               DIVIDE BYTES IN CORE BY LENGTH       67260020
         STH   R5,A1M              SET NEW MULTIPLICITY                 67310020
         STH   R4,LASTLEN          SAVE NO. OF BYTES IN CORE            67360020
         OI    COMFLGS,OUTCORE                                          67410020
         LTR   R5,R5               WAS REMAINING MULTI ZERO             67460020
         BNZ   LSTLMT10            IF NOT, BRANCH                       67510020
         LA    R15,FOUR            SET RETURN CODE TO FOUR              67520020
         B     LSTLMT14            GO RETURN WITH A RC=4                67560020
         SPACE                                                          67610020
LSTOUT   EQU   *                                                        67612020
         L     R2,LSTMSG              PTR TO MSG CSECT                  67614020
         LM    R2,R3,MSG07(R2)        PTRS TO FIRST AND SECOND LEVEL    67616020
         STM   R2,R3,IOLIST           PUT INTO PARM LIST                67618020
         LA    R1,IOLIST              PTR TO PARM LIST                  67618420
         LCR   R1,R1                  INDICATE THIS IS A MESSAGE        67618820
         B     LSTIO2                 GO TO I/O ROUTINE                 67619220
         EJECT                                                          67620020
*********************************************************************** 67680020
*                                                                     * 67740020
*  GENERAL SUBROUTINE FOR MOVING ADDRESSES TO THE OUTPUT BUFFER.      * 67800020
*        AT ENTRY,  R6 SHOULD POINT TO THE NEXT AVAILABLE BUFFER BYTE * 67860020
*                   R8 SHOULD CONTAIN THE ADDRESS OF THE ADDR PDE.    * 67920020
*        AT-EXIT,   R6 CONTAINS THE UPDATED BUFFER PTR, AND           * 67980020
*                   THE OUTPUT BUFFER CONTAINS THE ADDRESS STRING.    * 68040020
*                                                                     * 68100020
*********************************************************************** 68160020
LSTAMV   EQU   *                                                        68220020
         SAVE  (14,12)             SAVE CALLERS REGS                    68280020
         TM    PDEFLG1,LDNAMFLG    WAS A LOADNAME USED                  68340020
         BZ    LSTAMV04                IF NOT, BRANCH                   68400020
         LH    R2,PDELEN1          PICK UP LENGTH OF LOAD NAME          68460020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR     68520020
         L     R15,PDELDNAM        PICK UP PTR TO LOAD NAME             68580020
         EX    R2,SYMMOVE          MOVE SYMBOL TO OUTPUT LOCATION       68640020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST LOADNAME      68700020
LSTAMV04 EQU   *                                                        68760020
         TM    PDEFLG2,CTNAMFLG    WAS ENTRY NAME SPECIFIED             68820020
         BZ    LSTAMV08                IF NOT, BRANCH                   68880020
         MVI   ZERO(R6),PERIOD     MOVE IN SEPARATOR                    68940020
         LA    R6,L'PERIOD(R6)     INCREMENT BUF PTR PAST PREFIX        69000020
         LH    R2,PDELEN2          GET LENGTH OF ENTRY NAME AND         69060020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR     69120020
         L     R15,PDECTNAM        PICK UP PTR TO ENTRY NAME            69180020
         EX    R2,SYMMOVE          MOVE NAME TO OUTPUT AREA             69240020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST ENTRYNAME     69300020
         TM    PDEFLG4,CTONLY      IS ADDR TYPE STAND ALONE ENTRYNAME   69360020
         BO    LSTAMV16                IF STAND ALONE ENTRYNAME, BRANCH 69420020
         MVI   ZERO(R6),PERIOD     MOVE IN SEPARATOR                    69480020
         LA    R6,L'PERIOD(R6)     INCREMENT BUF PTR PAST PREFIX        69540020
LSTAMV08 EQU   *                                                        69600020
         LH    R2,PDELEN3          PICK UP LENGTH OF WYMBOL AND         69960020
         BCTR  R2,NULL                 DECREMENT BY 1 FOR MVC INSTR     70020020
         L     R15,PDEADRPT        R15=PTR TO SYMBOL                    70080020
         EX    R2,SYMMOVE          MOVE SYMBOL TO OUTPUT AREA           70140020
         LA    R6,ONE(R2,R6)       INCREMENT BUF PTR PAST SYMBOL        70200020
LSTAMV16 EQU   *                                                        70260020
         ST    R6,R6OFF(R13)       MODIFY REG 6 CONTENTS (IN SAVE AREA) 70320020
         RETURN (14,12)            RETRUN TO CALLER WITH HIS REGS       70380020
SYMMOVE  MVC   ZERO(NULL,R6),ZERO(R15)  FOR MOVING NAMES TO BUFFER      70440020
         TITLE 'IKJEGLST, ''LIST'', PARSE EXIT SUB-ROUTINES'            70500020
*********************************************************************** 70560020
*                                                                     * 70620020
*  ENTRY POINT FOR LENGTH VALIDITY CHECK EXIT ROUTINE.                * 70680020
*                                                                     * 70740020
*********************************************************************** 70800020
LSTVALEN EQU   *                                                        70860020
         SAVE  (14,12)             SAVE PARSE REGS                      70920020
         LA    R14,OFFSETL1(R15)   SET UP ADDR OF LNTH/MULTI ROUTINE    70980020
         SR    R4,R4               INDICATE LENGTH PARAMETER            71040020
         B     OFFSET1(R15)        GO TO COMMON LINK CONVENTION RTNJ    71100020
         SPACE                                                          71160020
*********************************************************************** 71220020
*                                                                     * 71280020
*  ENTRY POINT FOR MULTIPLICITY VALIDITY CHECK EXIT ROUTINE.          * 71340020
*                                                                     * 71400020
*********************************************************************** 71460020
LSTVALMT EQU   *                                                        71520020
         SAVE  (14,12)             SAVE PARSE REGS                      71580020
         LA    R14,OFFSETM1(R15)   SET UP ADDR OF LNTH/MULTI ROUTINE    71640020
         LA    R4,TWO              INDICATE MULTIPLICITY PARAMETER      71700020
         B     OFFSET2(R15)        GO TO COMMON LINK CONVENTION RTN     71760020
         SPACE                                                          71820020
*********************************************************************** 71880020
*                                                                     * 71940020
*  ENTRY POINT FOR ADDRESS VALIDITY CHECK EXIT ROUTINE.               * 72000020
*                                                                     * 72060020
*********************************************************************** 72120020
LSTVALAD SAVE  (14,12)             SAVE PARSE PREGS                     72180020
         LA    R14,OFFSETAD(R15)   SET UP ADDR OF ADDRESS VALIDITY RTN  72240020
         SPACE                                                          72300020
LSTVALCM EQU   *                                                        72360020
OFFSET1  EQU   *-LSTVALEN                                               72420020
OFFSET2  EQU   *-LSTVALMT                                               72480020
         L     R12,FOUR(R1)        R12=PTR TO LIST'S SAVE AREA          72540020
         LR    R3,R1               SAVE REG1                            72600020
         LM    R6,R12,R6OFF(R12)   RESTORE REQUIRED REGS OF LIST        72660020
         L     R2,REGSAVE3         PTR TO NEW SAVE AREA                 72720020
         ST    R2,FOREPTR(R13)     FOREWARD CHAIN SAVE AREAS.           72780020
         ST    R13,BACKPTR(R2)     BACKWARD CHAIN SAVE AREAS.           72840020
         LR    R13,R2              SET NEW SAVE AREA                    72900020
         L     R8,ZERO(R3)         GET ADDR OF PDE                      72960020
         SR    R0,R0               INDICATE CONVERT TO BINARY           73020020
         ST    R0,IOLIST+FOUR      ZERO 2ND LEVEL MSG PTR FIELD         73070020
         BR    R14                 GO TO PROPER RTN                     73080020
         EJECT                                                          73140020
*********************************************************************** 73200020
*                                                                     * 73260020
*  ADDRESS VALIDITY ROUTINE. AT ENTRY, R0=0, AND R2=PTR TO ADDR PDE.  * 73320020
*                                                                     * 73380020
*********************************************************************** 73440020
LSTADR   EQU   *                                                        73500020
OFFSETAD EQU   *-LSTVALAD                                               73560020
         SPACE                                                          73620020
         USING IKJPARMA,R8         ADDRESSABILITY FOR THE ADDR PDE      73680020
         LCR   R1,R8               INDICATE ADDR CONVERSION             73740020
         L     R15,TSTCONVT        GET ADDR OF IKJEGCVT                 73800020
         OI    TSTFLGS1,RANGESW    SET SW TO SHOW ADDR MAY BE A RANGE   73860020
         BALR  R14,R15             GO TO CONVERT ROUTINE                73920020
         LTR   R15,R15             TEST CONVERT RTN CODE                73980020
         BNZ   LSTADR12            IF NON-ZERO, BRANCH                  74040020
         TM    PDE2FLG3,AFLG       WAS A SECOND ADDR GIVEN              74100020
         BO    LSTADR04            IF YES, BRANCH                       74160020
         TM    PDE2FLG4,CTONLY     WAS A 2ND ADDR GIVEN AS ENTRY NAME   74220020
         BZ    LSTADR06            IF NO 2ND ADDRESS, BRANCH            74280020
LSTADR04 EQU   *                                                        74340020
         TM    PDEFLG4,GENR+LFPR+SFPR  IS 1ST ADDR A REG TYPE           74400020
         BZ    LSTADR26            IF NOT, BRANCH                       74460020
         CH    R0,PDEINDCT         IS 1ST REG ADDR INDIRECTED           74520020
         BNE   LSTADR26            IF INDIRECT, BRANCH, ADDR IS CORE    74580020
         SPACE                                                          74640020
*  ADDRESS 1 IS A REG ADDRESS, NOW TEST ADDRESS 2.                      74700020
         SPACE                                                          74760020
         CH    R0,PDE2INDC         IS 2ND REG ADDR INDIRECTED           74820020
         BNE   LSTADR50            IF INDIRECT, ERROR, BRANCH           74880020
         CLC   PDEFLG4,PDE2FLG4    COMPARE TYPES FOR 1ST AND 2ND ADDRS  74940020
         BNE   LSTADR24            IF NOT EQ, ERROR, BRANCH             75000020
LSTADR06 EQU   *                                                        75060020
         SR    R15,R15             SET RETURN CODE TO 0                 75120020
LSTADR08 EQU   *                                                        75180020
         L     R13,BACKPTR(R13)    PICK UP CALLERS SAVE AREA ADDRESS    75240020
         L     R1,R1OFF(R13)       PICK UP PTR TO PARM LIST FROM PARSE  75290020
         MVC   EIGHT(FOUR,R1),IOLIST+FOUR  PASS PTR TO 2ND LEVEL MSG    75292020
         NI    TSTFLGS1,HEXFF-RANGESW  CLEAR RANGE SW FOR RE-USE        75294020
         RETURN (14,12),,RC=(15)   RETURN TO PARSE                      75300020
         SPACE                                                          75360020
LSTADR12 EQU   *                                                        75420020
         C     R15,FSIXTEEN        WAS RETURN CODE A 16 OR 20           75470020
         BNL   LSTADR16            IF 16 OR 20, BRANCH                  75472020
         TM    TSTFLGS1,RANGESW    WAS 1ST OR 2ND PDE IN ERROR          75474020
         LA    R1,PDEUSER          ANTICIPATE 1ST PDE IN ERROR          75476020
         BO    LSTADR14            IF 1ST ADDR IN ERROR, BRANCH         75478020
         LA    R1,PDE2USER         IF 2ND PDE IN ERROR, RE-INITIALIZE   75478420
LSTADR14 EQU   *                                                        75478820
         MVC   IOLIST+FOUR(FOUR),ZERO(R1)  SAVE PTR TO 2ND LEVEL MSG    75479220
         SPACE                                                          75503720
LSTADR15 EQU   *                                                        75515820
         LA    R15,EIGHT           SET RETURN CODE TO 8.                75527920
         B     LSTADR08            BRANCH TO RETURN RTN                 75540020
         SPACE                                                          75600020
LSTADR16 EQU   *                                                        75650020
         ST    R15,LSTRETCD        SAVE RC TO PASS BACK TO MAINLINE     75652020
         LA    R15,TWELVE          SET RC=12 TO PARSE                   75654020
         B     LSTADR08            GO RETURN TO PARSE                   75656020
         SPACE                                                          75660020
LSTADR24 EQU   *                                                        76200020
         TM    PDE2FLG4,GENR+SFPR+LFPR  IS ADDR 2 REGISTER TYPE         76260020
         BNM   LSTADR50            IF NOT REG TYPE, BRANCH              76320020
         LA    R15,MSG01           GET OFFSET TO MESSAGE                76380020
         B     LSTADR70            GO TO MSG ROUTINE                    76440020
         SPACE                                                          76500020
*  IF ADDRESS 1 IS A CORE ADDRESS AND A RANGE WAS GIVEN, ADDRESS 2    * 76510020
*  MUST ALSO BE A CORE ADDRESS.                                       * 76520020
         SPACE                                                          76530020
LSTADR26 EQU   *                                                        76550020
         TM    PDE2FLG4,GENR+LFPR+SFPR  IS 2ND ADDR REG TYPE            76552020
         BZ    LSTADR30            IF NOT REG, BRANCH                   76554020
         CH    R0,PDE2INDC         IF 2ND ADDR REG TYPE, IS IT INDIRECT 76556020
         BE    LSTADR50            IF 2ND ADDR REG TYPE, BRANCH         76558020
         SPACE                                                          76558420
*  IF AN ADDRESS RANGE HAS BEEN SPECIFIED AND THE ADDRESSES ARE CORE  * 76560020
*  ADDRESS 1 MUST BE LESS THAN OR EQUAL TO ADDRESS 2.                 * 76620020
         SPACE                                                          76680020
LSTADR30 EQU   *                                                        76740020
         L     R3,PDEUSER          GET 1ST ADDR OR SI PTR (SYM-INFO)    76800020
         LTR   R3,R3               IS 1ST ADDR AN SI PTR                76860020
         BNM   LSTADR32            IF NOT AN SI PTR, BRANCH             76920020
         L     R3,SIDATAPT(R3)     GET ACTUAL DATA ADDR FROM SI BLK     76980020
LSTADR32 EQU   *                                                        77040020
         L     R4,PDE2USER         GET 2ND ADDR OR SI PTR               77100020
         LTR   R4,R4               IS 2ND ADDR AN SI BLK PTR            77160020
         BNM   LSTADR36            IF NOT AN SI BLOCK PTR, BRANCH       77220020
         L     R4,SIDATAPT(R4)     GET ACTUAL DATA ADDRESS              77280020
LSTADR36 EQU   *                                                        77340020
         CR    R3,R4               COMPARE DATA ADDR 1 WITH DATA ADDR2  77400020
         BNH   LSTADR06            IF ADDR 1 IS EQUAL OR HIGH, BRANCH   77460020
         SPACE                                                          77520020
*  IF ADDRESS 2 IS LOWER THAN ADDRESS 1, THE RANGE IS INVALID AND AN  * 77580020
*  ERROR MESSAGE MUST BE ISSUED.                                      * 77640020
         SPACE                                                          77700020
         LA    R15,MSG05           SET UP OFFSET TO MSG PTRS            77760020
         B     LSTADR70            GO TO MSG SETUP ROUTINE              77820020
         SPACE                                                          77880020
LSTADR50 EQU   *                                                        77940020
         LA    R15,MSG04           GET OFFSET FOR ERROR MESSAGE         78000020
         B     LSTADR70            GO TO MESSAGE SET UP ROUTINE         78060020
         SPACE                                                          78120020
*  INVALID ADDRESS AND ADDRESS RANGE MESSAGE SETUP ROUITNE            * 78180020
*        AT ENTRY, R15 CONTAINS THE OFFSET TO THE DESIRED MSG LIST.     78240020
         SPACE                                                          78300020
LSTADR70 EQU   *                                                        78360020
         L     R6,OUTBUF           GET ADDRESS OF OUTPUT BUFFER         78420020
         L     R2,LSTMSG           GET ADDRESS OF MESSAGE CSECT         78480020
         LA    R2,ZERO(R15,R2)     SET UP PTR TO MESSAGE PTR'S          78540020
         LM    R3,R4,ZERO(R2)      GET PTRS TO THE TWO MESSAGES         78600020
         LH    R5,ZERO(R3)         GET LENGTH OF 1ST LEVEL MSG          78660020
         BCTR  R5,NULL             DECREMENT LENGTH FOR MVC INSTR       78720020
         EX    R5,MSGMOVE          MOVE MESSAGE TO BUFFER               78780020
         LA    R3,ZERO(R6)         SAVE BUFFER START ADDR/CLEAR HI BYTE 78840020
         LA    R6,ONE(R5,R6)       INCREMENT BUFFER PTR                 78900020
         SPACE                                                          80290020
*  SET UP FOR, AND CALL, MESSAGE BUILD ROUTINE TO CONSTRUCT ADDRESS IN  80300020
*    THE ERROR MESSAGE ALREADY IN THE OUTPUT BUFFER.                    80310020
         SPACE                                                          80320020
         LR    R0,R8               PASS ADDRESS OF ADDR PDE IN REG 0    80330020
         LCR   R1,R6               PASS NEG PTR TO NEXT BYTE OF BUFF    80332020
         L     R15,TSTADDR         GET ADDRESS OF ADDR BUILD ROUTINE    80334020
         BALR  R14,R15             GO TO ADDR BUILD RTN                 80336020
         MVI   ZERO(R1),CHARPLUS   MOVE 2ND LEVEL MSG INDICATOR TO MSG  80338020
         LA    R6,ONE(ZERO,R1)     INCREMENT BUF PTR PAST PLUS SIGN     80338420
LSTADR78 EQU   *                                                        80338820
         SR    R6,R3               CALCULATE NO. OF BYTES OF MESSAGE    80340020
         STH   R6,ZERO(R3)         SET LNTH FLD OF 1ST LEVEL MESSAGE    80400020
         STM   R3,R4,IOLIST        SET UP IOLIST TO POINT TO MSG'S      80460020
LSTADR82 EQU   *                                                        80520020
         LA    R1,IOLIST           SET UP ADDR OF LIST FOR LSTIO        80580020
         LCR   R1,R1               INDICATE                             80640020
         OI    COMFLGS,PARSEFLG    INDICATE PARSE EXIT RTN              80700020
         BAL   R7,LSTIO2           GO TO IO RTN TO OUTPUT MSG           80760020
         NI    COMFLGS,HEXFF-PARSEFLG  TURN OFF PARSE EXIT FLAG         80820020
LSTADR86 EQU   *                                                        80830020
         C     R15,FSIXTEEN        IS RETURN CODE 16 OR GREATER         80870020
         BNL   LSTADR16            IF RETURN CODE 16 OR 20, BRANCH      80872020
         NC    IOLIST+FOUR(FOUR),IOLIST+FOUR  IS THERE A 2ND LEVEL MSG  80874020
         BNZ   LSTADR15            IF A 2ND LEVEL MSG PRESENT, BRANCH   80876020
         MVI   IOLIST+FOUR,HEXFF    FLAG WORD FOR NO 2ND LEVEL MSG      80878020
         B     LSTADR15            GO RETURN TO PARSE                   80878420
         SPACE                                                          80940020
MSGMOVE  MVC   ZERO(NULL,R6),ZERO(R3)  MOVES MSG'S FROM CSECT TO BUF    81000020
         DROP  R8                                                       81060020
         EJECT                                                          81120020
*********************************************************************** 81180020
*                                                                     * 81240020
*  LENGTH/MULTIPLICITY VALIDITY ROUTINE, AT ENTRY,                    * 81300020
*        R0=0, R2=PTR TO THE PDE, AND R4= EITHER 0 FOR LENGTH         * 81360020
*        VALIDITY CHECK, OR 2 FOR MULTIPLICITY VALIDITY CHECK.        * 81420020
*                                                                     * 81480020
*********************************************************************** 81540020
         SPACE                                                          81600020
LSTLM    EQU   *                                                        81660020
OFFSETL1 EQU   *-LSTVALEN          OFFSET FROM LNTH VALIDCK E.P.        81720020
OFFSETM1 EQU   *-LSTVALMT          OFFSET FROM MULTIPLICITY VALIDCK EP  81780020
         LA    R1,VPDE             SET UP REG 1 TO CONVERT A VALUE      81840020
         MVC   VPDE(VPDELEN),ZERO(R8)  MOVE IDENT PDE TO WORKING CORE   81900020
         MVI   VPDET,HCODE         INDICATE TYPE IS FIXED PT HALFWORD   81960020
         L     R15,TSTCONVT        ADDR OF IKJEGCVT                     82020020
         BALR  R14,R15             GO TO CONVERT RTN                    82080020
         LTR   R15,R15             TEST RETURN CODE                     82140020
         BNZ   LSTADR86            IF NON-ZERO, BRANCH, GO TEST RC      82200020
         L     R15,CONAREA         ADDR OF CONVERT OUTPUT AREA          82260020
         LA    R15,CONDATA(R15)    INCREMENT PTR PAST LENGTH FIELD      82320020
         LH    R0,ZERO(R15)        PICK UP CONVERTED VALUE              82380020
         CH    R0,H256             COMPARE ATTR TO MAX                  82440020
         BH    LSTERR              IF HIGH, ERROR, BRANCH               82500020
         LTR   R0,R0               TEST FOR LENTH/MULTI EQ 0            82550020
         STH   R0,LMATTR(R4)       SAVE CONVERTED ATTRIBUTE             82560020
         BNZ   LSTADR06            IF LENTH/MULTI NON-ZERO, BRANCH      82672020
         SPACE                                                          82680020
LSTERR   EQU   *                                                        83180020
         LA    R15,MSG02           SET UP OFFSET TO MSG ADCONS          83182020
         L     R2,LSTMSG           PTR TO MSG CSECT                     83190020
         L     R3,ZERO(R15,R2)     PICK UP ADDRESS OF 1ST LEVEL MSG     83190420
         L     R6,OUTBUF           PTR TO COMMON BUFFER                 83202820
         LH    R5,ZERO(R3)         PICK UP LENGTH FIELD                 83203620
         BCTR  R5,NULL             DECREMENT LENGTH FOR MOVE            83204020
         EX    R5,MSGMOVE          MOVE MSG TO BUFFER                   83204420
         LA    R3,ZERO(R6)         SAVE BUFFER START ADDR               83204520
         LA    R6,ONE(R5,R6)       INCREMENT BUF PTR PAST BASE MSG      83204620
         LTR   R4,R4               IS THE LENGTH BEING CHECKED          83209220
         L     R4,FOUR(R15,R2)     PICK UP ADDRESS OF 2ND LEVEL MSG     83209320
         BZ    LENERR              BRANCH IF SO                         83209620
         MVC   ZERO(L'MULTIP,R6),MULTIP  MOVE 'MULTIPLICITY+' INTO MSG  83213720
         LA    R6,L'MULTIP(ZERO,R6)    INCREMENT BUF PTR PAST ATTR NAME 83215720
         B     LSTADR78            GO PRINT MESSAGE                     83217320
LENERR   EQU   *                                                        83219520
         MVC   ZERO(L'LENTH,R6),LENTH  MOVE 'LENGTH+' INTO MSG          83239120
         LA    R6,L'LENTH(ZERO,R6) INCREMENT BUF PTR PAST ATTR NAME     83241120
         B     LSTADR78            GO PRINT MESSAGE                     83243120
         SPACE 2                                                        83243520
DATAMOVE MVC   ZERO(NULL,R6),CONDATA(R3)   FOR MOVING DATA TO BUFFER    83243620
         EJECT                                                          83250820
*********************************************************************** 83253720
*                                                                       83256620
*        STAE RETRY ROUTINE                                             83259520
*                                                                       83262420
*********************************************************************** 83265320
         SPACE 3                                                        83268220
RETRY    EQU   *                                                        83271120
         L     R4,CVTPTR           PTR TO CVT                           83274020
         USING CVTDSECT,R4         ADDRESSABILITY FOR CVT               83276920
         L     R4,CVTTCBP          TCB PTR                              83279820
         L     R4,FOUR(R4)         CURRENT TCB PTR                      83282720
         DROP  R4                                                       83285620
         USING TCB,R4              TCB ADDRESSABILITY                   83288520
         L     R9,TCBTRN           TCOMTAB PTR                          83291420
         L     R13,REGSAVE2        PTR TO SAVE AREA                     83294320
         LM    R10,R12,R10OFF(R13)     RESTORE MODULE ADDRESSABILITY    83297220
         LTR   R0,R0               WAS WORKSPACE FREED                  83300120
         BNZ   LSTFREE             GO TO FREE WORKSPACE                 83303020
         FREEMAIN R,LV=104,A=(1)   FREE WORKSPACE                       83305920
LSTFREE  EQU   *                                                        83308820
         LA    R15,TWENTY          INDICATE ERROR RETURN                83311720
         ST    R15,LSTRETCD        SAVE RETURN CODE                     83314620
         B     LSTMN90             RETURN                               83317520
         TITLE 'IKJEGLST, ''LIST'', PARSE DISCRIPTOR MACROS'            83320420
IKJEGPMA IKJPARM                                                        83323320
ADDR1 IKJPOSIT ADDRESS,LIST,RANGE,PROMPT='ADDRESS OR REGISTER',        C83340020
               VALIDCK=LSTVALAD                                         83400020
TYPE     IKJKEYWD                                                       83460020
         IKJNAME 'C'               CHARACTER FORMAT                     83520020
         IKJNAME 'X'               HEXADECIMAL                          83580020
         IKJNAME 'B'               BINARY                               83640020
         IKJNAME 'F'               FIXED PT BINARY, FULLWORD            83700020
         IKJNAME 'H'               FIXED PT BINARY, HALFWORD            83760020
         IKJNAME 'E'               FLOATING PT, SINGLE PRECISION        83820020
         IKJNAME 'D'               FLOATING PT, DOUBLE PRECISION        83880020
         IKJNAME 'A'               ADDRESS CONSTANT, FULLWORD           83940020
         IKJNAME 'Y'               ADDRESS CONSTANT, HALFWORD           84000020
         IKJNAME 'S'               ADDRESS CONSTANT, BASE/DISPLACEMENT  84060020
         IKJNAME 'P'               PACKED DECIMAL                       84140020
         IKJNAME 'Z'               ZONED DECIMAL                        84220020
         IKJNAME 'I'               INSTRUCTION FORMAT                   84300020
LATTR    IKJKEYWD                                                       84360020
         IKJNAME 'LENGTH',SUBFLD=LENCD                                  84420020
MATTR    IKJKEYWD                                                       84480020
         IKJNAME 'MULTIPLE',SUBFLD=MULCD                                84540020
PRINT    IKJKEYWD                                                       84600020
         IKJNAME 'PRINT',SUBFLD=DSNAM                                   84660020
LENCD    IKJSUBF                                                        84720020
LENGTH   IKJIDENT 'LENGTH',MAXLNTH=3,FIRST=NUMERIC,OTHER=NUMERIC,      C84780020
               PROMPT='LENGTH',VALIDCK=LSTVALEN                         84840020
MULCD    IKJSUBF                                                        84900020
MULTI    IKJIDENT 'MULTIPLICITY FACTOR',FIRST=NUMERIC,OTHER=NUMERIC,   C84960020
               PROMPT='MULTIPLICITY FACTOR',VALIDCK=LSTVALMT            85020020
DSNAM    IKJSUBF                                                        85080020
DSNAME   IKJPOSIT DSNAME,PROMPT='OUTPUT DATA SET NAME'                  85140020
         IKJENDP                                                        85200020
         TITLE 'IKJEGLST, ''LIST'', CONSTANTS AND DSECTS'               85260020
LSTMSG   DC    V(IKJEGMSA)         PTR TO MSG CSECT                     85320020
PARSEPCL DC    V(IKJEGPMA)         PTR TO PARSE PCL                     85370020
RETRYAD  DC    A(RETRY)            PTR TO STAE RETRY CODE               85430020
         SPACE                                                          85440020
XCTLLF  XCTL  ,SF=L                MODEL FOR LIST FORM OF XCTL MACRO    85500020
XCTLLEN  EQU   *-XCTLLF            LENGTH OF LIST FORM OF XCTL MACRO    85560020
         SPACE                                                          85620020
FFOUR    DC    F'4'                CONSTANT OF FOUR, GENERAL USE        85680020
FSIXTEEN DC    F'16'               CONSTANT OF 16, GENERAL USE          85690020
         SPACE                                                          85700020
LENTH    DC    C'LENGTH+'          KEYWORD TO MOVE IN MESSAGE           85730020
MULTIP   DC    C'MULTIPLICITY+'             ''                          85732020
         SPACE                                                          85732820
SMTLABL  DS    0H                  SMT TEST LABEL FOR XCTL MACRO        85732920
LSA      DC    C'LSA'              CONSTANT USED BY MAINLINE BLDL RTNE  85733220
         SPACE                                                          85733620
CONLEN   EQU   13                  LENGTH OF THE PREVIOUS CONSTANTS     85734020
         DS    0F                                                       85740020
SPMASK   DC    X'01000000'         SUB-POOL NUMBER MASK FOR FREEMAIN    85800020
         SPACE                                                          85860020
HONE     DC    H'1'                CONSTANT OF 1, GENERAL USE           85920020
H16      DC    H'16'               CONSTANT OF SIXTEEN, GENERAL USE     85980020
H256     DC    H'256'              CONSTANT OF 256, GENERAL USE         86040020
AFLEN    DC    A(ADDRLEN+SP1+SP1)  LENGTH OF ADDR FLD (+ 2 SPACES)      86100020
         SPACE 2                                                        86160020
LSTABEND EQU   *                                                        86210020
         DS    0F                                                       86212020
         DC    AL1(3)              CODE FOR LINK TO PARSE FAILED        86214020
         DC    AL3(PARSEBLO)       ADDRESS OF POTENTIAL ABEND           86216020
         DC    X'FF'               TABLE STOPPER                        86218020
         SPACE 2                                                        86218420
*********************************************************************** 86220020
*  THIS TABLE CONVERTS THE NUMBER OF THE TYPE KEYWORD SPECIFIED, TO   * 86280020
*  A HEXADECIMAL CODE USED INTERNALLY BY TEST.                        * 86340020
*        THE FIRST CODE BYTE (X'04' FOR HEX) IS PICKED UP IF THE TYPE * 86400020
*        KEYWORD WAS NOT SPECIFIED AND THE PDE IS ZERO. THE TYPE CODE * 86460020
*        OF X'0C' IS NOT CURRENTLY USED BY THE ASSEMBLER AND IS USED  * 86520020
*        HERE FOR INSTRUCTION FORMAT, TYPE 'I'. THE ORDER OF THIS     * 86580020
*        TABLE DIRECTLY CORRESPONDS TO THE ORDER OF THE IKJNAME MACROS* 86640020
*        FOR THE TYPE KEYWORD.                                        * 86700020
         SPACE                                                          86760020
TYPETBL  EQU   *                                                        86820020
         DC    X'04'               CODE FOR HEX FORMAT, DEFAULT TYPE    86880020
         DC    X'00'                ''  ''  CHARACTER FORMAT            86940020
         DC    X'04'                ''  ''  HEXFORMAT, USER GIVEN       87000020
         DC    X'08'                ''  ''  BINARY FORMAT               87060020
         DC    X'10'                ''  ''  FIXED PT BINARY 'F'         87120020
         DC    X'14'                ''  ''    ''   ''   ''   'H'        87180020
         DC    X'18'                ''  ''  FLOATING PT 'E'             87240020
         DC    X'1C'                ''  ''     ''    '' 'D'(TYPE -DN-)  87300020
         DC    X'20'                ''  ''  A TYPE ADDRESS CONSTANT     87360020
         DC    X'24'                ''  ''  Y  ''    ''      ''         87420020
         DC    X'28'                ''  ''  S  ''    ''      ''         87480020
         DC    X'30'                ''  ''  PACKED DECIMAL FORMAT       87540020
         DC    X'34'                ''  ''  ZONED DECIMAL FORMAT        87600020
         DC    X'0C'                ''  ''  INSTRUCTION FORMAT, TYPE I  87720020
         SPACE 3                                                        87780020
         EJECT                                                          87900020
LSTWORK  DSECT                                                          87960020
         SPACE                                                          88020020
*********************************************************************** 88080020
*                                                                     * 88140020
*  ---NOTICE---                                                       * 88200020
*                                                                     * 88260020
***** THERE IS A DUPLICATE OF THIS DSECT IN IKJEGLSA AND ANY CHANGES ** 88320020
*****  TO THE DSECT MUST BE MADE IN BOTH MODULES.                    ** 88380020
*                                                                     * 88440020
*  THIS DSECT MAPS A SECTION OF THE COMMON WORKING CORE POINTED TO    * 88500020
*  BY 'WORKAREA' IN TCOMTAB.                                          * 88560020
*                                                                     * 88620020
*********************************************************************** 88680020
         SPACE                                                          88740020
DWORK    DS    D                   DOUBLE WORD WORKAREA                 88800020
         ORG   DWORK               USE WORK AREA FOR XCTL LIST          88860020
LXCTL1   DS    2A                  PROBLEM PROG PARAMETER LIST          88920020
PARSEPL  DS    7F                  PARSE CALLING PARAMETER LIST.        88980020
         ORG   PARSEPL             REUSE CORE USED BY PARSE PARM LIST   89040020
LSTRPT   EQU   *                   START OF SECTION REUSED FOR ADDR LST 89100020
APDE     DS    9F                  WORKING COPY OF THE ADDRESS PDE      89160020
A1       DS    A                   CONTAINS CURRENT ADDR OF INPUT       89220020
A1LMATTR DS    F                   LENGTH AND MULTIPLICITY FACTORS      89280020
         ORG   A1LMATTR            PLACE LNTH AND MULTI IN ONE FULLWORD 89340020
A1L      DS    H                   LENGTH                               89400020
A1M      DS    H                   MULTPLICITY FACTOR                   89460020
A1FLG    DS    X                   FLAG BYTE FOR ADDR1 INFORMATION      89520020
A1FPD    EQU   X'80'               FLOATING PT DBL                      89580020
A1FPE    EQU   X'40'               FLOATING PT SINGLE                   89640020
A1GEN    EQU   X'20'               GENERAL REG                          89700020
A1REG    EQU   X'10'               ADDRESS 1 IS A REG.                  89760020
         SPACE                                                          89820020
A1ABS    EQU   X'00'               ADDR IS ABSOLUTE                     89880020
A1SYM    EQU   X'03'               ADDR IS SYMBOLIC                     89940020
A1REL    EQU   X'01'               ADDR IS RELATIVE                     90000020
         SPACE                                                          90060020
A1TYPE   DS    X                   CONTAINS TYPE CODE FOR ADDR1         90120020
REMAIN   DS    H                   REMAINDER                            90180020
A2       DS    A                   SECOND ADDR IF A RANGE WAS GIVEN     90240020
ARTIFMUL DS    H                   VALUE OF ARTIFICIAL MULTIPLICITY     90300020
DATAINCR EQU   ARTIFMUL            NAME OF FIELD USED IN LIST REGS      90360020
REMAIN2  DS    H                   BACKUP COPY OF REMAINDER             90420020
REGSTART DS    F                   START ADDR OF REG SAVE AREA TO LIST  90480020
LSTRETCD DS    F                   HOLDS RETURN CODE                    90540020
LASTLEN  DS    H                   CONTAINS REMAINDER FROM LSTLMTCK     90590020
COMFLGS  DS    X                   FLAG BYTES FOR PROCESS CONTROL       90600020
TWOADDRS EQU   X'80'               1 INDICATE ADDR RANGE                90660020
ARTIMSW  EQU   X'40'               1 INDICATE CONTROL IS ARTIFICIAL     90720020
NOINDENT EQU   X'20'               1 INDICATES DATA NOT TO BE INDENTED  90780020
SECOND   EQU   X'10'               1 INDICATES PROCESSING 2ND GROUP     90840020
WRAPSW   EQU   X'08'               1 INDICATES 2ND REG LOWER THAN 1ST   90900020
PARSEFLG EQU   X'04'               SW SHOWS IO REQUESTED BY PARSE EXIT  90960020
OUTCORE  EQU   X'02'               REQUEST EXTENDS OUT OF CORE          91010020
DATASIZE EQU   X'01'               SYMBOLIC FOR NUMBER OF HEX FLDS/GRP  91012020
         SPACE                                                          91020020
*  THE FOLLOWING FIELDS DEFINE A VALUE PDE FOR CONVERTING DATA.         91080020
VPDE     DS    0F                  VALUE PDE FOR CONVERTING DATA        91140020
VPDEPT   DS    A                   PTR TO DATA                          91200020
VPDEL    DS    H                   LENGTH OF DATA FOR CONVERSION        91260020
VPDEFLG  DS    X                   FLAGS                                91320020
VPDET    DS    X                   HEX TYPE CODE FOR VALUE.             91380020
         SPACE                                                          91440020
RPTSIZE  EQU   *-LSTRPT            LNTH OF REUSED SECTION.              91500020
LMATTR   DS    F                   LENGTH AND MULTIPLICITY FACTOR FLD'S 91560020
         ORG   LMATTR              PLACE LNTH AND MULTI IN ONE FULLWORD 91620020
BINLEN   DS    H                   CONVERTED LENGTH GIVEN BY USER       91680020
BINMUL   DS    H                   CONVERTED MLTPLCTY GIVEN BY USER     91740020
LXCTL    XCTL  ,SF=L               RESERVE SPACE FOR LIST FORM OF XCTL  91800020
ENDOBUF  DS    A                   CONTAINS MAX BUF ADDR + 1            91860020
ENDOGRP  DS    A                   CONTAINS GROUP STOP ADDRESS          91920020
IOLIST   DS    2F                  MSG PTR LIST FOR IKJEGIO1            91980020
         SPACE                                                          92040020
TYPESAVE DS    X                   CONTAINS SPECIFIED OR DEFAULTED TYPE 92100020
RETRYSAV DS    AL3                 CONTAINS MAINLINES STAE RETRY ADDR   92150020
LSTFLGS  DS    X                   FLAG BYTES TO SAVE PARSE DATA        92160020
TYPEFLG  EQU   B'10000000'         SET TO ONE IF TYPE KEYWORD USED      92220020
LNTHFLG  EQU   B'01000000'         SET TO ONE IF LENGTH KEYWORD USED    92280020
MULTIFLG EQU   B'00100000'         SET TO ONE IF MULTIPLICITY GIVEN     92340020
         SPACE                                                          92400020
         DS    X                   SPILL BYTE FOR HOLDAREA  ON ODD ADDR 92460020
         DS    0D                  ALIGN HOLDAREA                       92520020
HOLDAREA DS    XL32                HOLDS DATA BEING CONVERTED CURRENTLY 92580020
STAELIST STAE  MF=L                                                     92630020
         SPACE                                                          92640020
LWLNTH   EQU   *-LSTWORK           LENGTH OF DSECT                      92700020
         EJECT                                                          92760020
IKJEGMSA CSECT                                                          92820020
*********************************************************************** 92880020
*                                                                     * 92940020
*  MESSAGE CSECT FOR IKJEGLST, LIST SUB-CMD OF TEST.                  * 93000020
*  THE FIRST SECTION CONTAINS ADCONS FOR THE FIRST AND SECOND LEVEL   * 93060020
*  MESSAGES. THE ADCONS ARE IN PAIRS WITH THE 2ND =0 IN THERE IS NO   * 93120020
*  SECOND LEVEL MSG.                                                  * 93180020
*                                                                     * 93240020
*********************************************************************** 93300020
         SPACE                                                          93360020
LSTM01   DC    A(MA)               INVALID RANGE MSG                    93420020
         DC    A(MA1)                  BECAUSE REG TYPES DIFFER         93480020
         SPACE                                                          93540020
LSTM02   DC    A(MB)               INVALID LENGTH ATTRIBUTE MSG         93600020
         DC    A(MB1)                    VALID VALUES ARE 1 TO 256      93660020
         SPACE                                                          93720020
LSTM03   DC    A(ME)               LIST FAILED, COMMAND SYSTEM ERR MSG  93780020
         DC    A(0)                    BECAUSE OF INSUFFIENT STORAGE    93840020
         SPACE                                                          93900020
         SPACE                                                          94080020
LSTM05   DC    A(MA)               INVALID RANGE MSG                    94140020
         DC    A(MA2)                  BECAUSE REG AND CORE TYPES MIXED 94200020
         SPACE                                                          94260020
LSTM06   DC    A(MA)               INVALID RANGE MSG                    94320020
         DC    A(MA3)                  BECAUSE 2ND CORE ADDR LT 1ST     94380020
         SPACE                                                          94390020
LSTM07   DC    A(MD)               LIST FAILED MSG                      94400020
         DC    A(MD1)                  BECAUSE CAN'T PARSE, PARSE RC=12 94410020
         SPACE                                                          94420020
LSTM08   DC    A(MF)               LIST REQUEST INCOMPLETE MSG          94434020
         DC    A(MF1)                  BECAUSE MAX VALID ADDR EXCEEDED  94436020
         SPACE 2                                                        94440020
*                                                                       94490020
*        FOLLOWING ARE THE MESSAGE TEXTS                                94492020
*                                                                       94494020
         DS    0H                                                       94500020
MA       DC    AL2(MAE-MA)         LENGTH OF ENTIRE MESSAGE             94560020
         DC    AL2(0)              OFFSET FIELD                         94620020
         DC    C'IKJ57240I INVALID ADDRESS'  TXT FOR MSG 01             94680020
         DC    C' RANGE BEGINNING '          MSG 01 CONT.               94690020
MAE      EQU   *                                                        94740020
         DS    0H                                                       94800020
MA1      DC    AL2(MA1E-MA1)       LNTH OF MSG TXT AND HEADER           94860020
         DC    AL2(0)              OFFSET FIELD                         94920020
         DC    C'IKJ57240I REGISTER TYPE'    TXT FOR MSG 01             94980020
         DC    C' OF SECOND ADDRESS DIF'     MSG 01 CONT.               95040020
         DC    C'FERS FROM FIRST'            MSG 01 CONT.               95100020
MA1E     EQU   *                                                        95160020
         DS    0H                                                       95220020
MA2      DC    AL2(MA2E-MA2)       LENGTH OF MSG TXT AND HEADER         95280020
         DC    AL2(0)              OFFSET FIELD                         95340020
         DC    C'IKJ57240I RANGE CONTAI'     TXT FOR MSG 05             95400020
         DC    C'NS BOTH A STORAGE AND '     MSG 05 CONT.               95460020
         DC    C'A REGISTER ADDRESS'         MSG 05 CONTINUED           95520020
MA2E     EQU   *                                                        95580020
         DS    0H                                                       95640020
MA3      DC    AL2(MA3E-MA3)       LNTH OF MSG AND HEADER               95700020
         DC    AL2(0)              OFFSET FIELD                         95760020
         DC    C'IKJ57240I ADDRESS TYPE'     TXT FOR MSG 06             95820020
         DC    C' IS STORAGE AND SECOND'     MSG 06 CONT.               95880020
         DC    C' ADDRESS IS LESS THAN '     MSG 06 CONT.               95940020
         DC    C'FIRST'                      MSG 06 CONT.               96000020
MA3E     EQU   *                                                        96060020
         SPACE                                                          96120020
         DS    0H                                                       96180020
MB       DC    AL2(MBE-MB)         LENGTH OF ENTIRE MESSAGE             96240020
         DC    AL2(0)              OFFSET FIELD                         96300020
         DC    C'IKJ57241I INVALID ' TEXT                               96380020
MBE      EQU   *                                                        96420020
         SPACE                                                          96532020
         DS    0H                                                       96534020
MB1      DC    AL2(MB1E-MB1)       LENGTH OF MESSAGE                    96536020
         DC    AL2(0)              OFFSET FIELD                         96538020
         DC    C'IKJ57241I THE VALID RANGE IS FROM 1 TO 256'  MSG TEXT  96538420
MB1E     EQU   *                                                        96538820
         SPACE                                                          96540020
*        MESSAGES FOR SYSTEM ERRORS                                     96590020
         SPACE                                                          96600020
         DS    0H                                                       97370020
MD       DC    AL2(MDE-MD)         LENGTH OF MESSAGE                    97372020
         DC    AL2(0)              OFFSET FIELD                         97374020
         DC    C'IKJ57247I LIST FAILED, COMMAND SYSTEM ERROR+'  MSG TXT 97376020
MDE      EQU   *                                                        97378020
         SPACE                                                          97378420
         DS    0H                                                       97378520
MD1      DC    AL2(MD1E-MD1)       LENGTH OF ENTIRE MESSAGE             97378820
         DC    AL2(0)              OFFSET FIELD                         97379220
         DC    C'IKJ57247I PARSE ERROR CODE 12'    MSG TEXT             97379620
MD1E     EQU   *                                                        97379720
         SPACE                                                          97379820
         DS    0H                                                       97379920
ME       DC    AL2(MEE-ME)         LENGTH OF ENTIRE MSG                 97399920
         DC    AL2(0)              OFFSET FIELD                         97409920
         DC    C'IKJ57248I NOT ENOUGH MAIN STORAGE TO'   MSG TEXT       97419920
         DC    C' EXECUTE COMMAND'                       MSG TEXT CONT  97426620
MEE      EQU   *                                                        97428620
         SPACE                                                          97430620
         DS    0H                                                       97432620
MF       DC    AL2(MFE-MF)         LENGTH OF ENTIRE MSG                 97433020
         DC    AL2(0)              OFFSET FIELD                         97433120
         DC    C'IKJ57249I LIST REQUEST INCOMPLETE+'  MSG TEXT          97433220
MFE      EQU   *                                                        97447420
         SPACE                                                          97457420
         DS    0H                                                       97459420
MF1      DC    AL2(MF1E-MF1)       LENGTH OF ENTIRE MESSAGE             97461420
         DC    AL2(0)              OFFSET FIELD                         97461520
         DC    C'IKJ57249I REQUEST EXCEEDED '   TEXT MSG 09, 2ND LEVEL  97466220
         DC    C'GREATEST VALID ADDRESS'        TEXT CONTINUED          97468220
MF1E     EQU   *                                                        97470220
         EJECT                                                          97471120
         TCOMTAB                                                        97475820
         SPACE 3                                                        97490020
         IKJPARMA                                                       97500020
APL      EQU   PDECHAIN-IKJPARMA   SYMBOLIC LENGTH OF AN ADDRESS PDE    97560020
         SPACE 3                                                        97610020
         TSTCWORK                                                       97620020
         EJECT                                                          97670020
         BRKELEM                                                        97680020
         SPACE 3                                                        97730120
         IKJPPL                                                         97730420
         EJECT                                                          97730520
CVTDSECT DSECT                                                          97730820
         CVT                                                            97732020
         EJECT                                                          97734020
         IKJTCB                                                         97740020
         END                                                            97800020
