         TITLE 'TEST MAINLINE MONITOR  IKJEGMNL'                        00080020
*********************************************************************** 00160020
*                                                                       00240020
* STATUS --                                                             00320020
*    VERSION NO. 01, OS/360 RELEASE NO. 20                              00370020
*                                                                       00400020
* FUNCTION --                                                           00480020
*    THIS MODULE RECEIVES CONTROL FROM THE INITIALIZATION MODULE        00640020
*    (IKJEGINT) OF THE TEST DEBUGGING PACKAGE OF TSO AS THE RESULT      00720020
*    OF AN XCTL.IT FINISHES INITIALIZATION AND IS THEREAFTER RE-        00800020
*    SPONSIBLE FOR THE ACQUISITION OF TEST COMMANDS FROM THE TER-       00880020
*    MINAL AND THE ROUTING OF CONTROL TO ONE OR ANOTHER OF THE VAR-     00960020
*    IOUS TEST COMMAND PROCESSORS OR TO THE PROGRAM BEING TESTED,       01040020
*    ACCORDING TO THE USER'S WISHES.                                    01120020
*                                                                       01200020
* ENTRY POINTS --                                                       01280020
*    IKJEGMNL                                                           01440020
*                                                                       01520020
* INPUT  --                                                             01600020
*    TEST COMMUNICATION TABLE (TCOMTAB) POINTER IN GPR 9.               01760020
*                                                                       01840020
* OUTPUT --                                                             01920020
*    NONE                                                               02050020
*                                                                       02080020
* EXTERNAL REFERENCES --                                                02160020
*         IKJEGIO  FOR TERMINAL I/O (VIA BRANCH)                        02240020
*         IKJSCAN  TO SCAN THE SUBCOMMAND INPUT BUFFER                  03090020
*         IKJDAIR  TO UNALLOCATE DATASETS ALLOCATED BY TEST OR THE PP   03100020
*         IKJEGSTA  IS MAINLINE'S STAE EXIT ROUTINE                     03110020
*         IKJEGATN  IS MAINLINE'S ATTENTION EXIT ROUTINE                03112020
*         IKJEFT04  IS BOTH THE TMP'S AND MAINLINES' STAI EXIT ROUTINE  03114020
*                                                                       03120020
* EXITS, NORMAL --                                                      03170020
*         LINK TO COMMAND PROCESSING PROGRAM                            03180020
*         RETURN TO TMP ('END' OR 'RUN'),RETURN CODE=0                  03190020
*                                                                       03190420
* EXITS, ERROR --                                                       03192020
*         NONE                                                          03200020
*                                                                       03280020
* TABLES/WORKAREAS --                                                   03330020
*    TCOMTAB  POINTED AT BY REGISTER 9, IS THE COMMUNICATIONS TABLE FOR 03340020
*    THE TEST PROCESSOR                                                 03352020
*                                                                       03354020
*    TPL  POINTED TO BY REGISTER 10 IS THE TEST PARAMETER LIST          03356020
*    THE TPL WAS PASSED TO INITIALIZATION BY THE TMP                    03358020
*                                                                       03358420
*    WORKAREA POINTER IN TCOMTAB IS THE MAIN WORKAREA FOR MAINLINE.     03358820
*                                                                       03359220
*    OUTBUF IS USED PRIMARILY FOR OUTPUT MESSAGES                       03359620
*                                                                       03359720
* ATTRIBUTES --                                                         03360020
*    RE-ENTRANT                                                         03520020
*    REFRESHABLE                                                        03600020
*                                                                       03680020
* CHARACTER CODE DEPENDENCY --                                          03730020
*    NONE                                                               03740020
*                                                                       03750020
* NOTES --                                                              03752020
*    REGISTER CONVENTIONS FOR MAINLINE ARE AS FOLLOWS                   03752420
*    REG 9  TCOMTAB POINTER                                             03752820
*    REG 10  TPL POINTER                                                03753220
*    REG 11  ONLY USED FOR LINK REGISTER                                03753620
*    REG 12 IS THE BASE REGISTER                                        03753720
*    REGISTER 0,1,14,15 ARE USED BY MOST SUBROUTINES BAL-ED TO.         03753820
*                                                                       03754020
*********************************************************************** 03760020
         EJECT                                                          03840020
IKJEGMNL CSECT                                                          03920020
*RELEASE 21                                                             03970021
*C720000,742400                                                  M2013  03980021
*                                                                       04000020
         USING TCOMTAB,R9     COMMUNICATION TABLE ADDRESSABILITY.       04080020
         USING *,R12          PROGRAM ADDRESSABILITY.                   04160020
         LR    R12,R15        *                                         04240020
         USING TPL,R10        *                                         04320020
         SPACE                                                          04400020
*        COMPLETE THE INITIALIZATION OF THE TCOMTAB WITH THE ADDRESSES  04480020
*        OF RESIDENT ROUTINES AND TABLES.                               04560020
         SPACE                                                          04640020
         OI    CONAREA+X3,X7  ADJUST CONVERT AREA POINTER.              04720020
         MVC   TGETADDR(N24),IOCONS VARIOUS COMMON ENTRY POINTS.        04800020
         MVC   OPCODTAB(X4),OPCDTBAD  INITIALIZE OP CODE TABLE          04880020
         MVC   TSTDDM(X4),IKJEGDDM  INITIALIZE DAIR MESSAGE MAKER ADR   04960020
         LA    R4,IKJEGEXP    GET ADDRESS OF EXPAND ROUTINE             04980020
         ST    R4,TSTEXPAN    PUT IT IN TCOMTAB                         05000020
         LA    R4,ABTAB       R4=ADDR OF RESIDENT ABEND TABLE.          05040020
         ST    R4,ABENTAB     PLACE ADDR IN TCOMTAB.                    05120020
         MVC   TSTRETRY(X4),RETRYAD  RETRY ADDRESS FOR STAE.            05200020
         BAL   R11,STOPALL    INSURE ALL TASKS ARE STOPED INITIALLY     05280020
         BAL   R11,QUAL       AUTOMATIC QUALIFY FIRST TIME IN.          05360020
*        UPON TAKING OVER A TASK PASSED BY THE TMP, A TERMINAL ELEMENT  05370020
*        WILL BE ADDED, SO THAT, TEST'S INPUT WILL COME FROM THE        05380020
*        TERMINAL.                                                      05390020
         BAL   R11,ADD        ADD AN ELEM TO THE STACK, IF NEEDED.      05400020
         SPACE                                                          05440020
*        ISSUE STAX MACRO TO ENABLE THE TEST ATTENTION EXIT ROUTINE.    05520020
*        ISSUE STAE MACRO TO ENABLE THE TEST STAE EXIT ROUTINE.         05600020
         SPACE                                                          05680020
         L     R8,ATTNBUF     R8=STAX PARAMETER LIST ADDR.              05760020
         LA    R1,ATTNLEN(R8)  SKIP ATTENTION BUFFER.                   05840020
ATTNLEN  EQU   132            LENGTH OF ATTENTION BUFFER.               05920020
         MVC   X0(STAXLEN,R1),STAXLIST  MOVE L FORM INTO LIST.          06000020
         L     R5,ATTNEP      R5=ENTRY POINT OF ATTN ROUTINE.           06080020
         LA    R6,TEST        R6=ADDRESS OF MODE MESSAGE                06160020
         LA    R7,X6          R7=LENGTH OF TEST                         06240020
         LA    R2,ATTNLEN     LENGTH OF INBUFFER.                       06320020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT                      06400020
         STAX (5),OBUF=((6),(7)),IBUF=((8),(2)),USADDR=(9),MF=(E,(1)), *06480020
               REPLACE=NO                                               06560020
         LTR   R15,R15        CHECK RET CODE.                           06640020
         BNZ   STAXFAIL       THIS CAN NEVER HAPPEN. BUT IF IT EVER    *06690020
                              DOES,MAINLINE WILL CATCH IT.              06740020
         L     R1,WORKAREA    R1=ADDR OF STAE PARAMETER LIST.           06800020
         MVC   X0(STAELEN,R1),STAELIST MOVE L-FORM INTO LIST.           06880020
         MVC   X0(X4,R1),TSTSTAE  EP FOR STAE EXIT ROUTINE.             06960020
         STAE  MF=(E,(1))     ISSUE STAE MACRO.                         07040020
         LTR   R15,R15        WAS RETURN CODE ZERO                      07120020
         BNZ   NOCORE         ISSUE MESSAGE AND GO AWAY.                07200020
SCREQ1   BAL   R11,FREINBUF   FREE INBUF AND PDL IF ANY.                07280020
SCREQ    EQU   *                                                        07360020
         BAL   R11,GET6K      GET THE 6K RESERVE IF FREED.              07440020
         NC    INBUF(X4),INBUF Q.IS A COMMAND IN STORAGE.               07520020
         BNZ   SCAN           YES,LINK TO COMMAND SCAN ROUTINE.         07600020
         NC    SUBCHAIN(X4),SUBCHAIN Q. COMMAND CHAIN IN PROGRESS.      07680020
         BNZ   JUSTGET        YES,SKIP MODE MESSAGE.                    07760020
         LA    R1,MODE        R1=PARMLIST ADDR FOR MODE MESSAGE.        07840020
         BAL   R11,TPG        PUT/GET                                   07920020
         BAL   R11,ADD        ADD A TERM ELEM TO THE STACK              07960020
         SPACE                                                          08000020
SCAN     EQU   *                                                        08080020
*        TRANSLATE AND TEST COMMAND TO DETERMINE IF IT IS AN ASSIGNMENT 08160020
*        COMMAND.IF NOT,LINK TO COMMAND SCAN SERVICE ROUTINE TO SCAN    08240020
*        VERB OF COMMAND.                                               08320020
         SPACE                                                          08400020
         L     R4,INBUF       R4=COMMAND ADDR.                          08480020
         LH    R3,X0(,R4)     NO,USE COMMAND ACTUAL LENGTH.             08560020
         LA    R1,X4          CONSTANT OF FOUR                          08580020
         CR    R1,R3          IS THIS A NULL LINE                       08600020
         BE    SCREQ1         YES --- BRANCH                            08620020
LOOP0    EQU   *                                                        08630020
         CLI   X4(R4),BLANK   CHECK FOR LEADING BLANK                   08640020
         BNE   LOOP           CONTINUE.                                 08650020
         LA    R4,X1(R4)      BUMP ONE.                                 08660020
         BCT   R3,LOOP0       CHECK IF ANOTHER LEADING BLANK.           08670020
         B     SCREQ1         ALL BLANKS REQUEST NEW LINE.              08680020
LOOP     EQU   *                                                        08690020
         CLI   X4(R4),BLANK   BLANK AS A DELIMITER.                     08700020
         BE    SCAN1          CAN'T BE PACH COMMAND.                    08710020
         CLI   X4(R4),LEFTPARN  LOOK FOR LEFT PAREN                     08720020
LEFTPARN EQU   C'('           LEFT PAREN                                08800020
         BE    SCAN1          THIS IS NOT A PATCH                       08880020
         CLI   X4(R4),EQUALS  LOOK FOR EQUALS                           08960020
EQUALS   EQU   C'='           EQUAL SIGN                                09040020
         BE    SCPCH          THIS IS A PATCH                           09120020
         LA    R4,X1(R4)      ADD ONE TO ADDRESS                        09200020
         BCT   R3,LOOP        FIND = OR (                               09280020
         B     SCAN1          NO FIND. CONTINUE                         09360020
SCPCH    EQU   *              PATCH                                     09440020
         MVI   X4(R4),BLANK   BLANK OUT EQUAL SIGN FOR PARSE.           09520020
BLANK    EQU   C' '           BLANK.                                    09600020
         L     R6,PATCHSID    OBTAIN ID FOR PATCH.                      09680020
         LH    R6,X0(R6)      *                                         09760020
         B     SCLINK         LINK TO ASSIGNMENT COMMAND.               09840020
SCAN1    EQU   *                                                        09920020
*        LINK TO COMMAND SCAN SERVICE ROUTINE TO SCAN VERB OF COMMAND.  10000020
         SPACE                                                          10080020
         L     R4,INBUF       R4=COMMAND ADDRESS                        10160020
         L     R1,WORKAREA    R1=PARAMETER LIST ADDR.                   10240020
         LA    R2,N24(,R1)    R2=ADDR OF FLAG WORD.                     10320020
         LA    R3,N28(,R1)    R3=ADDR OF OUTPUT AREA.                   10400020
         MVI   X0(R2),X80     INDICATE NO SYNTAX CHECK.                 10480020
         MVC   X0(N12,R1),PARMLIST MOVE SERVICE ROUTINE PARMS           10560020
*                             TO LIST.                                  10640020
         STM   R2,R4,N12(R1)   PLACE SCAN ROUTINE PARMS IN LIST.        10720020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT           10800020
         LINK  EP=IKJSCAN     LINK TO COMMAND SCAN SERVICE ROUTINE.     10880020
BLOW1    EQU   *                                                        10960020
         CH    R15,EIGHT      Q.WAS SCAN SUUCESSFUL(RC NOT=8).          11040020
         BE    TMPRTURN       NO,FOLD UP TENT.                          11120020
         NI    TSTFLGS3,XFF-NOPARMS  RESET NOPARMS SWITCH               11200020
         TM    X6(R3),X40     ARE THERE ANY PARAMETERS.                 11280020
         BZ    PARMS          YES.                                      11360020
         OI    TSTFLGS3,NOPARMS  SET NO PARMS BIT IN TCOMTAB.           11440020
PARMS    EQU   *              *                                         11520020
         L     R4,X0(,R3)     R4=COMMAND VERB ADDR.                     11600020
         LH    R5,X4(,R3)     R5=COMMAND VERB LENGTH.                   11680020
         L     R7,NAMELIST    R7=IKJEGSCD ADDR.                         11760020
         LR    R0,R5          SAVE ACTUAL LENGTH.                       11860020
         SR    R6,R6          CLEAR R6.                                 12000020
         BCTR  R5,X0          R5=EXECUTE LENGTH.                        12080020
LOOP2    EQU   *                                                        12160020
         TM    X0(R7),FF       Q.END OF NAME TABLE.                     12240020
FF       EQU   X'FF'          END OF LIST INDICATOR.                    12320020
         BO    NOSHOW         YES,VERB IS NOT A VALID COMMAND.          12400020
         IC    R6,X0(,R7)     NO,R6=TABLE ENTRY LENGTH.                 12480020
         CLR   R0,R6          Q.ARE LENGTHS EQUAL.                      12560020
         BE    FLDCMPR        YES,COMPARE TEXT.                         12640020
BUMP     EQU   *              NO,CHECK NEXT ENTRY.                      12720020
         LA    R7,X2(R6,R7)    R7=ADDR OF NEXT ENTRY IN IKJEGSCD.       12800020
         B     LOOP2          RETURN FOR CHECK.                         12880020
NOSHOW   EQU   *                                                        12960020
         LA    R6,X1          LENGTH OF ONE.                            12970020
         CLR   R0,R6          CHECK THE LENGTHS.                        12980020
         BNE   SKIP7          NO COMPARE. SKIP.                         12990020
         CLI   X0(R4),CHARH   IS IT HELP........                        13000020
         BE    HELP1          YES. ATTACH 'HELP'                        13010020
SKIP7    EQU   *                                                        13020020
         LA    R6,X4          LENGTH OF HELP.                           13040020
         CLR   R0,R6          CHECK LENGTHS.                            13120020
         BNE   SKIP4          NO COMPARE. SKIP.                         13200020
         CLC   X0(X4,R4),HELP  IS IT HELP..........                     13280020
         BE    HELP1          YES. ATTACH HELP.                         13360020
SKIP4    EQU   *                                                        13440020
         LA    R6,X3          LENGTH FOR 'END'                          13520020
         CLR   R0,R6          Q.ARE LENGTHS EQUAL.                      13600020
         BNE   NOSHOW1        NOT 'END'                                 13680020
         CLC   X0(X3,R4),END  HAS 'END' BEEN ENTERED.                   13760020
         BE    ENDIT1         IT'S ALL OVER                             13840020
         SPACE                                                          13920020
NOSHOW1  EQU   *              INVALID SUBCOMMAND                        14000020
*        LINE RECEIVED DID NOT HAVE A VALID VERB AS THE FIRST FIELD.    14080020
*        WRITE A DIAGNOSTIC MESSAGE TO THE TERMINAL AND GET ANOTHER     14160020
*        LINE.                                                          14240020
         SPACE                                                          14320020
         LA    R1,BADVERB     R1=ADDR OF IKJEGIO1 PARMLIST.             14400020
         BAL   R11,TPUT       PUT THE MESSAGE.                          14480020
         B     SCREQ1          NO,GET ANOTHER COMMAND.                  14560020
         SPACE                                                          14640020
GET6K    EQU   *                                                        14720020
         L     R1,SCPP4K      GET THE 4K ADDRESS.                       14800020
         LTR   R1,R1          IS THERE 4K RESERVED......                14880020
         BCR   NZ,R11         YES. RETURN.                              14960020
         L     R0,CORE6K      SP=2,LENGTH=6144                          15040020
         GETMAIN  R,LV=(0)    GET CORE.                                 15120020
BLOW2    EQU   *                                                        15200020
         ST    R1,SCPP4K      RE-INITIALIZE SCPP4K IN TCOMTAB.          15280020
         BR    R11            RETURN.                                   15360020
         SPACE                                                          15440020
FREINBUF EQU   *              FREE 'INBUF' AND ZERO POINTER             15520020
         L     R1,ECBTMPA     POINT TO ATTN ECB                         15600020
         TM    X0(R1),TESTATTN  HAS ATTENTION BEEN HIT Q.Q.Q.           15680020
         BO    PDLFREE        YES. DON'T FREE INPUT BUFFER.             15760020
         L     R1,INBUF       R1=ADDR OF BUFFER                         15840020
         LTR   R1,R1          Q.IS INBUF ZERO.                          15920020
         BZ    PDLFREE        YES, CHECK ON TSTANSPL.                   16000020
         LH    R0,X0(R1)      R0=LENGTH OF BUFFER FOR FREEMAIN          16080020
         O     R0,SP1         INDICATE SUBPOOL 1.                       16160020
         XC    INBUF(X4),INBUF  CLEAR INBUF                             16200020
         FREEMAIN R,LV=(0),A=(1) FREE THE BUFFER.                       16240020
PDLFREE  EQU   *                                                        16400020
         SPACE                                                          16450020
*        FREE THE PDL IF ONE                                            16500020
         SPACE                                                          16550020
         L     R1,WORKAREA    MOVE THE PDL ADDRESS IN CASE OF ABEND     16600020
         MVC   X0(X4,R1),TSTANSPL  MOVE IT, IN ORDER TO ZERO IT         16650020
         XC    TSTANSPL(X4),TSTANSPL   ZERO BEFORE FREEING              16700020
         IKJRLSA (R1)         RELEASE THE PDL                           16750020
SIFREE   EQU   *                                                        16758020
         SPACE                                                          16766020
         SPACE                                                          16774020
*        CHECK TO SEE IF A SYMBOL INFORMATION BLOCK CHAIN EXISTS. IF    16782020
*        SO, LOOP THRU THE CHAIN FREEING EACH BLOCK                     16790020
         L     R14,SICHAIN    ADDR OF HEAD OF CHAIN                     16798020
         XC    SICHAIN(X4),SICHAIN  ZERO IN CASE OF ABEND               16806020
LOOP4    EQU   *                                                        16814020
         LTR   R1,R14         Q. END OF CHAIN.                          16822020
         BCR   Z,R11          RETURN TO CALLER                          16830020
         L     R14,SILINK(R14)  R14=ADDR OF NEXT SIB,IF ANY             16838020
SILINK   EQU   12             *                                         16846020
         L     R0,CORESIB     SIB CORE SUBPOOL AND LENGTH               16854020
         FREEMAIN  R,LV=(0),A=(1)  FREE THIS SIB                        16862020
         B     LOOP4          LOOP ------                               16870020
         SPACE                                                          16880020
COMPARE  CLC   X1(X1,R7),X0(R4)  COMPARE.                               16960020
         SPACE                                                          17040020
FLDCMPR  EQU   *                                                        17120020
         EX    R5,COMPARE     Q.DOES VERB MATCH THIS ENTRY.             17200020
         BNE   BUMP           NO,TRY NEXT ENTRY.                        17280020
         IC    R6,X1(R6,R7)    YES,R6=ENTRY TABLE INDEX.                17360020
SCLINK   EQU   *                                                        17390020
         SPACE                                                          17420020
*        EXPAND BLDL ENTRY AND USE IT TO LINK TO THE PROPER COMMAND     17450020
         SPACE                                                          17480020
         STC   R6,TSTRETRY    INDICATE LINKEE FOR STAE,IF NECESSARY     17510020
         LCR   R1,R6          COMPLIMENT ID FOR EXPAND ROUTINE          17540020
         LA    R15,IKJEGEXP   GET A BLDL ENTRY                          17570020
         BALR  R14,R15        EXPECT ADDRESS IN REG 1                   17600020
         LTR   R6,R1          IS THERE A BLDL ENTRY                     17630020
         BZ    NIXMSG         PRINT 'COMMAND NOT SUPPORTED'             17660020
LINK     EQU   *                                                        17690020
         SPACE                                                          17720020
*        ISSUE LINK USING NEWLY EXPANDED BLDL ENTRY                     17750020
         SPACE                                                          17780020
         STM   R2,R12,N28(R13)  SAVE REGS FOR LINK RETRY                17810020
LINKSC   EQU   *              LINK TO SUBCOMMAND                        17840020
         L     R15,WORKAREA   ADDRESS FOR THE LIST FORM.                17870020
         MVC   X0(LINKFMLN,R15),LINKFORM LIST FORM TO GOTTON AREA       17880020
         NI    TSTFLGS1,XFF-TSTFIRST-RANGESW  RESET SWITCHES IF ON.     17886020
         NI    TSTFLGS3,XFF-SYMMESG   RESET SYM MESSAGE SWITCH.         17892020
         OI    TSTFLGS3,TSTLINK  SET BIT FOR STAE RETRY IF LINK FAILS   17900020
         LINK  DE=(6),SF=(E,(15))  LINK TO SUBCOMMAND                   17930020
BLOWSC   EQU   *                                                        17960020
         NI    TSTFLGS3,XFF-TSTLINK  RESET LINK ABEND BIT               17990020
         XC    TSTRSTRT(X4),TSTRSTRT  INSURE RESTART ADDR ZEROED        18020020
         XC    ABENTAB1(X4),ABENTAB1  ZERO  FOR 'STA' FOR 1ST LVL       18050020
         MVC   TSTRETRY(X4),RETRYAD  SETUP RETRY ADDRESS FOR 'STA'      18080020
         SPACE                                                          18110020
*        RETURN CODE CHECK                                              18140020
         SPACE                                                          18400020
RCCHECK  EQU   *                                                        18480020
         B     HERE(R15)       BRANCH ACCORDING TO RETURN CODE.         18560020
HERE     EQU   *              *                                         18640020
         B     CLEAN          RC=0,GET ANOTHER COMMAND.                 18720020
         B     IKJEGCTL       RC=4,'GO',GO TO CTL SUBROUTINE.           18800020
         B     ENDIT1         RC=8,'END',FOLD UP TENT.                  18880020
         B     RUNRTURN       RC=12,'RUN',FOLD UP TENT,NO DETACH.       18960020
SMTRC16  B     ATTNPROC       RC=16,ATTENTION INT. PROCESSING.          19040020
         B     STAERTRN       RETURN FROM A S.C. WHICH ABENDED.         19120020
CLEAN    EQU   *              CLEAN RETURN.                             19150020
         TM    TSTFLGS4,TSTFLUSH   Q. IS THERE A NEED TO FLUSH.         19180020
         BNO   CLEAN1         NO.                                       19210020
STAERTRN EQU   *              STAE RETURN.                              19240020
         NI    TSTFLGS4,XFF-TSTFLUSH  INSURE RESET OF FLAG.             19270020
         BAL   R11,FLUSH      TCLEARQ AND MAYBE STACK FLUSH.            19300020
CLEAN1   EQU   *              CONTINUE PROCESSING.                      19330020
         TM    TSTFLGS1,ENDSW HAS EITHER 'RUN' OR 'END' BEEN ENTERED    19360020
         BO    TMPRTURN       YES.FOLD.                                 19440020
         L     R1,ECBTMPA     GET ATTENTION ECB.                        19460020
         TM    X0(R1),TESTATTN  DID IKJEGATN POST Q.Q.Q.                19480020
         BO    ATTNPROC       YES. PROCESS THE ATTENTION REQUEST.       19500020
         B     SCREQ1          GET ANOTHER COMMAND.                     19520020
         SPACE                                                          19600020
         EJECT                                                          19630020
*        THIS ROUTINE IF GIVEN AN ID WILL FIND A CORRESPONDING BLDL     19660020
*        ENTRY.  IF GIVE AN ADDRESS TO A THREE CHARACTER LOAD MODULE    19690020
*        SUFFIX, WILL OBTAIN THE I.D. AND THEN FIND THE CORRESPONDING   19720020
*        BLDL ENTRY.                                                    19750020
*        THE I.D. IF NEEDED WILL BE GOTTEN FROM MODULE IKJEGSCD VIA     19780020
*        A NAME MATCH SEARCH.                                           19810020
*        WHEN FOUND THE ID IS USED TO INDEX INTO SCPPAD TO FIND THE     19840020
*        ADDRESS OF THE COMPRESSED BLDL ENTRY.                          19870020
*        THE COMPRESSED BLDL ENTRY IS THEN EXPANDED TO FULL FORM AND    19900020
*        THE ADDRESS IS PASSED BACK IN REGISTER ONE.                    19930020
*        IF EITHER THE NAME WAS NOT FOUND IN IKJEGSCD OR THE NAME WAS   19960020
*        NOT FOUND BY BLDL A ZERO ADDRESS IS RETURNED IN REGISTER ONE.  19990020
*        REGISTER ONE UPON ENTRY WILL CONTAIN A POINTER TO A THREE      20020020
*        CHARACTER SUFFIX OR THE COMPLIMENT OF THE ID                   20050020
*        AN EXAMPLE OF SUFFIX IS 'ASN' FOR LOAD MODULE 'IKJEGASN'       20080020
*        THIS ROUTINE IS POINTED TO BY 'TSTEXPAN' IN TCOMTAB            20110020
         SPACE                                                          20140020
IKJEGEXP EQU   *              EXPAND THE COMPRESSED BLDL                20170020
         USING *,R15          ESTABLISH ADDRESS ABILITY                 20200020
         STM   R2,R12,N28(R13)  SAVE THE REGISTERS                      20230020
         L     R12,BASEAD     PICK UP MY BASE                           20260020
         DROP  R15            *                                         20290020
         LCR   R6,R1          TEST FOR I.D. OR POINTER                  20320020
         BP    EXPAND         IT IS AN I.D. --BRANCH                    20350020
         L     R2,SCDNAMES    ACCESS THE MEMBER NAMES                   20380020
         SR    R6,R6          CLEAR THE COUNTER                         20410020
EXPLOOP  EQU   *                                                        20440020
         CLI   X0(R2),X0      AT THE END OF THE TABLE Q.Q.Q.            20470020
         BE    EXPERROR       PASSBACK A ZERO BLDL ADDRESS              20500020
         CLC   X0(X3,R1),X0(R2)   CHECK THE THREE CHARACTER SUFFIX      20530020
         LA    R2,X3(R2)      POINT THE THE NEXT SUFFIX                 20560020
         LA    R6,X1(R6)      ADD ONE TO THE COUNTER                    20590020
         BNE   EXPLOOP        NO MATCH --- LOOP                         20620020
EXPAND   EQU   *                                                        20650020
         BCTR  R6,X0          R6=(INDEX-1)                              20680020
         L     R1,SCPPAD      R1=ADDR OF BEGINNING OF ENTRY TABLE       20710020
         SLL   R6,X2          R6=((INDEX-1)*4)                          20740020
         L     R7,X0(R1,R6)   R15= BLDL ADDRESS OR ZERO                 20770020
         LTR   R7,R7          IS THERE A BLDL ENTRY Q.Q.Q.              20800020
*                             HIGH BIT ON INDICATES A BLDL ENTRY        20830020
         BNM   EXPERROR       NO BLDL ENTRY --BRANCH                    20860020
         L     R1,BLDLIST     FULL SIZE ENTRY ADDRESS                   20890020
         MVC   X5(X3,R1),X0(R7)  MOVE NAME                              20920020
         MVC   N13(X4,R1),X3(R7)   MOVE INDICATORS AND 1ST TXT TTR      20950020
         MVC   N23(X1,R1),X7(R7)   MOVE BYTE 2 OF MODULE ATTRIBUTES     20980020
         MVC   N25(X7,R1),X8(R7)   MOVE MAIN STORAGE REQUIREMENTS       21010020
*                                  MOVE 1ST TEXT RECORD LENGTH          21040020
*                                  MOVE ALIAS ENTRY POINT               21070020
         MVC   N35(X3,R1),N15(R7)   MOVE ALIAS OFFSET                   21100020
         MVC   N38(X5,R1),X0(R1)  MOVE FIRST FIVE OF NAME.              21130020
         MVC   N43(X3,R1),N18(R7)    MOVE TRUE NAME                     21160020
EXPEXIT  EQU   *                                                        21190020
         LM    R2,R12,N28(R13)   RESORE REGS                            21220020
         SR    R15,R15        RETURN CODE OF ZERO                       21250020
         BR    R14            RETURN                                    21280020
EXPERROR EQU   *                                                        21310020
         SR    R1,R1          RETURN A BLDL ADDRESS OF ZERO             21370020
         B     EXPEXIT        RETURN TO CALLER                          21400020
         EJECT                                                          21430020
         SPACE                                                          21680020
NIXMSG   EQU   *                                                        21760020
*        PRINT A 'COMMAND NOT AVAILABLE' MESSAGE TO THE TERMINAL.       21840020
         SPACE                                                          21920020
         LA    R1,MNMSG1      R1=IKJEGIO1 PARMS ADDR.                   22000020
         BAL   R11,TPUT       PUT THE MESSAGE                           22080020
         TM    TSTFLGS1,ENDSW+RUNSW  Q.IS 'END' NOT SUPPORTED.          22100020
         BM    TMPRTURN       YES. EXIT ...                             22120020
         B     SCREQ1         CHECK RETURN CODES FROM IKJEGIO1.         22160020
JUSTGET  EQU   *                                                        22240020
*        GET A NEW COMMAND WITHOUT ISSUING MODE MESSAGE.                22320020
         SPACE                                                          22400020
         BAL   R11,TGET       GET FROM WITHIN. NO IO DONE.              22480020
         B     SCREQ          PROCESS THE SUBCOMMAND IN SUBCOM CHAIN.   22560020
         SPACE                                                          22640020
TGET     EQU   *              TGET REQUEST FOR 'IO1'                    22720020
         L     R15,TGETADDR   GET.                                      22800020
         B     TGO            GO TO 'IO1'                               22880020
TPG      EQU   *              TPUTGET REQUEST FOR 'IO1'                 22960020
         L     R15,TPUTGET    R15='IO1' ADDRESS FOR A PUT/GET.          23040020
         B     TGO            GO TO 'IO1'                               23120020
TPUT     EQU   *              TPUT REQUEST FOR 'IO1'                    23200020
         LCR   R1,R1          COMPLIMENT FOR A MESSAGE.                 23280020
         L     R15,TPUTADDR   R15='IO1' ADDRESS FOR A PUT.              23360020
TGO      EQU   *              GO TO 'IO1'                               23440020
         BALR  R14,R15        GO.                                       23520020
         C     R15,IOFAIL     DID THE IO FAIL..........                 23600020
         BE    ENDITERR       FOLD.                                     23680020
         C     R15,ATTNCODE   IS THERE AN ATTENTION REQUEST.            23760020
         BCR   NE,R11         NO.RETURN.                                23840020
ATTNPROC EQU   *                                                        23920020
*        DETERMINE WHETHER ATTENTION INTERRUPT WAS PROCESSED BY TEST    24000020
*        OR TMP.IF TMP,FOLD UP AND RETURN,OTHERWISE,PROCESS COMMAND     24080020
*        RECEIVED.                                                      24160020
         SPACE                                                          24240020
         TM    TSTFLGS1,ENDSW HAS EITHER 'RUN' OR 'END' BEEN ENTERED.   24320020
         BO    TMPRTURN       YES.FOLD.                                 24400020
         L     R1,ECBTMPA     R1=ATTENTION ECB ADDR.                    24480020
         TM    X0(R1),TESTATTN Q.DID TEST POST ECB (X'48').             24560020
TESTATTN EQU   X'48'          TEST ATTN POST CODE.                      24640020
         BNO   ENDIT1         NO,FOLD UP TENT.                          24720020
         XC    X0(X4,R1),X0(R1)  ZERO ATTENTION ECB.                    24800020
         BAL   R11,PDLFREE    FREE PDL BUT NOT INPUT BUFFER.            24880020
         B     SCREQ          PROCESS COMMAND RECEIVED.                 24960020
IKJEGCTL EQU   *                                                        25040020
*        ACCOMPLISH ENTRY INTO PROGRAM BEING TESTED BY POSTING ITS ECB  25120020
*        AND ISSUE A WAIT ON ECBLIST (TCOMTAB).INTERPRET REASONS FOR    25200020
*        RESUMPTION OF CONTROL AND ROUTE CONTROL TO PROPER ROUTINE.     25280020
         SPACE                                                          25360020
         BAL   R11,FREINBUF   CLEAN UP AFTER 'GO'.                      25440020
         L     R2,ECBTST      R2=TEST DISPATCHABILITY ECB ADDR.         25520020
         XC    X0(X4,R2),X0(R2)  CLEAR TESTS ECB.                       25600020
         BAL   R11,GET6K      GET THE 6K RESERVE IF FREED.              25680020
         OC    TSTGO(X4),TSTGO  PSEUDO BREAK NEXT.                      25760020
         BNZ   POST           YES. PSEUDO BREAK GETS PRIORITY.          25840020
         L     R1,ECBTMPA     POINT TO ATTN ECB                         25920020
         TM    X0(R1),TESTATTN  HAS ATTENTION BEEN HIT Q.Q.Q.           26000020
         BO    ATTNPROC       PROCESS THE ATTENTION.                    26080020
         L     R3,TSTSVCQ     ADDR OF MULTI-TASKING ECB QUEUE FOR SVC'S 26140020
         LTR   R3,R3          IS THEIR A MULTI-TASKING QUEUE            26200020
         BZ    POST           NO, GO LET PROBLEM PROGRAM CONTINUE       26260020
         BAL   R11,REMOVE     REMOVE THE TERM ELEM OFF THE STACK        26320020
         POST  ECBPP          MAKE PROGRAM BEING TESTED DISPATCHABLE    26380020
         SR    R0,R0          CLEAR TO ZEROES FOR LATER USE             26440020
         LA    R1,TSTSVCQ-X4  MAKE ADDR OF QUEUE LOOK LIKE AN ELEMENT   26500020
LOOP8    LR    R2,R1          ADDR OF ELEMENT LOOKING AT                26560020
         L     R1,X4(R2)      ADDRESS OF NEXT ELEMENT IN QUEUE          26620020
         C     R0,X4(R1)      IS THE NEXT ELEMENT THE LAST              26680020
         BNE   LOOP8          NO, GO LOOK AT NEXT ELEMENT               26740020
         ST    R0,X4(R2)      YES, DEQUEUE LAST ELEMENT FROM QUEUE      26800020
         POST  (1),(0)        POST SVC WAITING ON LAST ELEMENT          26860020
         B     WAIT           GO START TASKS AND WAIT FOR AN EVENT      26920020
POST     MVI   TSTMTASK,X0    TURN OFF MULTI TASK SWITCH.               27120020
         BAL   R11,REMOVE     REMOVE THE TERM ELEM OFF THE STACK        27240020
         POST  ECBPP          MAKE PROGRAM BEING TESTED DISPATCHABLE.   27280020
WAIT     EQU   *                                                        27360020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT      27440020
         BAL   R11,START      START THE TASK OR TASKS.                  27520020
         WAIT  ECBLIST=ECBLIST  TEST CREAKS TO A HALT.                  27600020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT      27680020
         BAL   R11,STOP       STOP THE TASK OR TASKS.                   27760020
         SPACE                                                          27840020
*        DETERMINE WHICH ECB WAS POSTED AND TAKE APPROPRIATE ACTION.    27920020
         SPACE                                                          28000020
         L     R1,ECBLOG      CHECK IF STOP/MODIFY WAS ENTERED BY OP.   28080020
         TM    X0(R1),X40     *                                         28160020
         BO    ENDIT1         YES IT WAS. TERMINATE.....                28240020
         L     R2,ECBTST      TEST'S ECB.                               28320020
         TM    X0(R2),TESTPOST Q.WAS TEST ECB POSTED(40 OR 44).         28400020
TESTPOST EQU   X'44'          POST MASK FOR SVC 61 POST.                28480020
         BZ    STAICHK        NO,CHECK STAI ECB.                        28560020
         BO    DEFER          YES,SVC 61 POST,GO TO IKJEGAT1.           28640020
         SPACE                                                          28720020
*        TEST ECB WAS POSTED BY BREAKPOINT SVC.CHECK 'TSTGO' IN TCOMTAB 28800020
*        TO SEE IF BREAKPOINT WAS SET BY USER OR BY TEST.               28880020
         SPACE                                                          28960020
         BAL   R11,QUAL       REQUALIFY IF NECESSARY.                   29040020
         BAL   R11,ADD        ADD A TERM ELEM TO THE STACK              29080020
         L     R1,TSTGO       SET R1 FOR POSSIBLE PARAMETER TO SVC97    29120020
         LTR   R1,R1          Q. IST 'TSTGO' FIELD ZERO.                29200020
         BZ    BRKCHK         YES,TEST DID NOT SET THE BREAKPOINT.      29280020
         SPACE                                                          29360020
*        PSEUDO BREAKPOINT WAS SET BY TEST. CHECK IF PSEUDO WAS SET     29440020
*        WITHIN A BREAK ELEMENT. IF SO,ADJUST TSTGO. IN ALL CASES       29520020
*        RETURN IC BACK TO THE PRB(IRB)                                 29600020
         SPACE                                                          29680020
PSEUDO   EQU   *                                                        29760020
         L     R4,PPRB        OBTAIN PROB. PROGRAM RB ADDR.             29840020
         L     R5,BREAKTAB    GET THE BREAK ELEMENT QUEUE               29920020
LOOP6    EQU   *                                                        30000020
         LTR   R5,R5          Q. HAVE ALL BREAK ELEMENTS BEEN CHECKED.  30080020
         BZ    PSEUDO1        YES. RESTORE THE SAVED I.C.               30160020
         USING BRKELEM,R5     BREAK ELEMENT ADDRESSABILITY              30240020
         LA    R0,BRKINST     OBTAIN BEGINNING OF INSTR. FIELD          30320020
         LA    R2,BRKINST+X6  OBTAIN END OF INSTR. FIELD.               30400020
         LA    R3,X0(R1)      CLEAR HIGH BYTE OF TSTGO.                 30480020
         CR    R3,R0          Q. IS IC WITHIN BREAK ELEMENT.            30560020
         BL    MISS           NO. BRANCH.                               30640020
         CR    R3,R2          Q. IS IC WITHIN BREAK ELEMENT.            30720020
         BNH   HIT            YES. BRANCH                               30800020
MISS     EQU   *                                                        30880020
         L     R5,BRKLINK     GET NEXT ELEMENT , IF ONE.                30960020
         B     LOOP6          LOOP                                      31040020
HIT      EQU   *                                                        31120020
         SR    R3,R0          COMPUTE OFFSET INTO BRKINST               31200020
         A     R3,BRKADDR     CREATE A NEW 'TSTGO' ADDRESS              31280020
         N     R1,ALLREGS     SAVE THE HIGH BYTE OF I.C.                31360020
         OR    R1,R3          MERGE THE NEW I.C. WITH THE OLD.          31440020
         SPACE                                                          31520020
*        RESTORE PP'S CORRECT I.C. BACK TO HIS RB.                      31600020
         SPACE                                                          31680020
PSEUDO1  EQU   *                                                        31760020
         L     R0,PPTCB       'TSTGO' TO PP'S RB                        31840020
         O     R0,ICCHANGE    DITTO.                                    31920020
         SVC   TESTSVC        SAME.                                     32000020
         XC    TSTGO(X6),TSTGO ZERO OUT 'TSTGO' FOR NEXT USE.           32080020
         NI    TSTFLGS3,XFF-TSTSTAI  TURN OFF THE STAI BIT.             32160020
         TM    TSTFLGS2,TSTLDF  COMING FROM LOAD,DEL,GET,FREE.....      32240020
         BZ    SCREQ          NO. GET NEXT SUBCOMMAND.                  32320020
FROMLDF  EQU   *                                                        32400020
         L     R0,PPTCB       CURRENT TCB FOR PP.                       32480020
         O     R0,RGCHANGE    RESTORE ALL PP REGS.                      32560020
         L     R1,WORKAREA    ADDRESSABILITY.                           32640020
         LA    R1,CWORKLDF-TSTCWORK(R1)  GET PP REGS ADDRESS.           32720020
         O     R1,ALLREGS     CHANGE EM ALL.                            32800020
         SVC   TESTSVC        *                                         32880020
         DELETE EP=IKJEGLDF   DELETE PP PORTION.                        32960020
         NI    TSTFLGS2,XFF-TSTLDF RESET LOAD,DEL,GET,FREE BIT.         33040020
         BAL   R11,DCBFREE    FREE THE DCB IF NOT IN OVERLAY.           33120020
         L     R1,OUTBUF      MESSAGE POINTERS FROM LDF ARE IN OUTBUF   33200020
         OC    X0(X4,R1),X0(R1) HAS A MESSAGE BEEN PASSED....           33280020
         BZ    SCREQ          NO. GET ANOTHER SUBCOMMAND.               33360020
         BAL   R11,TPUT        PUT OUT THE MESSAGES.                    33440020
         B     SCREQ          GET THE NEXT SUBCOMMAND.                  33520020
         SPACE                                                          33600020
DCBFREE  EQU   *                                                        33680020
         L     R3,WORKAREA    AREA FOR LIST FORM.                       33760020
LOOP1    EQU   *                                                        33840020
         L     R4,TSTDCB      GET THE Q OF DCBS.                        33920020
         TM    TSTFLGS1,ENDSW  IF ENDING CLOSE ALL DCBS AND FREE.       34000020
         BO    FREEDCB        'END' OR 'RUN' HAS BEEN ENTERED.          34080020
         LTR   R4,R4          HIGH BIT ON DON'T FREE,ZERO FIELD ALSO    34160020
         BCR   NEG+Z,R11      NEGATIVE OR ZERO....RETURN.               34240020
FREEDCB  EQU   *                                                        34320020
         LTR   R4,R4              TEST FOR ZERO.                        34400020
         BCR   Z,R11              IF ZERO RETURN.                       34480020
         LA    R5,X4(R4)      DCB ADDRESS.                              34560020
         TM    DCBOFLGS(R5),X10  CHECK IF OPEN DCB.                     34640020
         BZ    NOCLOSE        DCB ALREADY CLOSED.                       34720020
DCBOFLGS EQU   48                                                       34800020
         MVC   X0(CLLEN,R3),CLFORM  CLOSE LIST FORM TO WORKAREA.        34880020
         CLOSE ((5)),MF=(E,(3))  CLOSE.                                 34960020
NOCLOSE  EQU   *              *                                         35040020
         MVC   TSTDCB(X4),X0(R4)  PUSH UP ON QUEUE                      35120020
         FREEMAIN  R,LV=100,A=(4),SP=1  FREE                            35200020
         B     LOOP1          GET THE NEXT DCB IF ONE....               35280020
BRKCHK   EQU   *                                                        35360020
*        CHECK TO SEE IF A BREAK ELEMENT EXISTS FOR THE LOCATION AT     35440020
*        WHICH THE BREAKPOINT OCCURRED.IF SO,INITIALIZE ANY COMMAND     35520020
*        CHAIN WHICH MAY BE SPECIFIED AND ENTER COMMAND MODE.IF NOT,    35600020
*        RETURN TO THE PROGRAM IN WHICH THE BREAKPOINT OCCURRED WITH-   35680020
*        OUT FURTHER PROCESSING.                                        35760020
         SPACE                                                          35840020
         L     R4,ECBPP       R4=ADDR OF SVC 97 SVRB.                   35920020
         L     R4,RBLINK(R4)  ADDRESS OF RB FOR BREAKPOINTED PROG.      36000020
         L     R5,BREAKTAB    R5=HEAD OF BREAK ELEMENT QUEUE.           36080020
LOOP2A   EQU   *                                                        36160020
         LTR   R5,R5          Q.ANY MORE BREAK ELEMENTS.                36240020
         BZ    QPPEND         SEE IF THE PP ENDED.                      36320020
         USING BRKELEM,R5     BREAK ELEMENT ADDRESSABILITY.             36400020
         CLC   BRKADDR+X1(X3),RBOPSWIC(R4) Q.THIS BREAK ELEM THE ONE.   36480020
         BE    ATLOC          YES,INITIALIZE CHAIN AND ENTER CMD MODE.  36560020
         L     R5,BRKLINK     NO,CHECK NEXT ELEMENT ON QUEUE.           36640020
         B     LOOP2A         *                                         36720020
* PRINT THE 'AT' BREAKPOINT MESSAGE.                                    36800020
ATLOC    EQU   *              AT..........                              36880020
         L     R1,OUTBUF      R1=OUTPUT BUFFER ADDRESS.                 36960020
         LA    R2,X8(R1)      R2=IS TO BE CONSTRUCTED MSG PTR.          37040020
         SR    R3,R3          R3=NO SECOND LEVEL MSG.                   37120020
         STM   R2,R3,X0(R1)   PARM LIST FOR 'IO1'                       37200020
         L     R3,AT          GET THE 'AT' MSG.                         37280020
         LH    R4,X0(R3)      GET 'AT' MSG LENGTH.                      37360020
         EX    R4,MOVEAT      MOVE THE 'AT' MSG TO OUTBUFFER.           37440020
         AR    R2,R4          UPDATE OUTBUF POINTER.                    37520020
         LA    R3,N160(R1)    GET WORK ADDRESS FOR CONVERT.             37600020
         UNPK  X1(X5,R3),BRKDISP(X3)  MAKE DISPLACEMENT PRINTABLE.      37680020
         TR    X1(X4,R3),TABLE-XF0    *                                 37760020
         LA    R8,X4          4 BYTES OF OUTPUT FROM UNPK               37840020
ATLOOP   EQU   *              SUPPRESS LEADING ZEROS LOOP.              37920020
         CLI   X1(R3),XF0     CHECK IF LEADING ZERO.                    38000020
         BNE   PUTPLUS        PUT A PLUS SIGN BEFORE OFFSET.            38080020
         MVC   X1(X3,R3),X2(R3)  SHIFT LEFT CHARACTER.                  38160020
         BCT   R8,ATLOOP      CHECK FOR MORE LEADING ZEROS.             38240020
         B     ATNAME         BRKDISP EQUALS ZERO.                      38320020
PUTPLUS  EQU   *              HIT A BREAKPOINT WITHIN A RANGE           38400020
         MVI   X0(R3),PLUS    PUT A PLUS SIGN IN FRONT OF OFFSET        38480020
         LA    R8,X1(R8)      ADD PLUS SIGN LENGTH.                     38560020
         AR    R4,R8          UPDATE CURRENT LENGTH.                    38640020
         EX    R8,MOVEAT      MOVE '+ (OFFSET)' TO OUTBUFFER.           38720020
         AR    R2,R8          UPDATE OUTBUFFER POINTER.                 38800020
         MVC   X0(FROMLEN,R2),FROM  MOVE ' FROM ' TO OUTBUFFER.         38880020
         LA    R8,FROMLEN     GET LENGTH OF FROM DC                     38960020
         AR    R2,R8          UPDATE OUTBUFFER POINTER.                 39040020
         AR    R4,R8          UPDATE CURRENT LENGTH.                    39120020
ATNAME   EQU   *              MOVE BRK NAME TO OUTBUFFER.               39200020
         EX    R4,MOVEAT      MOVE THE 'AT' MSG TO OUTBUFFER.           39280020
         L     R3,BRKNAME     GET THE ADDRESS STRING.                   39360020
         LA    R7,MAXLEN      GET MAX. LENGTH TO PRINT.                 39440020
MAXLEN   EQU   154            *                                         39520020
         SR    R7,R4          R7=MAX.LENGTH-AT MSG LENGTH               39600020
         LH    R6,X0(R3)      GET ADDR. STRING LENGTH.                  39680020
         CR    R6,R7          DOES ADDR.STRING EXCEED MAX.LENGTH.       39760020
         BL    SKIP1          NO.GO TO SKIP1.                           39840020
         LR    R6,R7          REPLACE WITH MAX. LENGTH.                 39920020
SKIP1    EQU   *              *                                         40000020
         LA    R3,X2(R3)      POINT TO BRKNAME PLUS TWO                 40080020
         EX    R6,MOVEAT      MOVE THE ADDRESS STRING TO OUTBUFFER      40160020
         AR    R4,R6          GET WHOLE MESSAGE LENGTH                  40240020
         SLL   R4,N16         PUT LENGTH IN 1ST HALF WORD               40320020
         ST    R4,X8(R1)      PUT LENGTH OF MESSAGE IN OUTBUFFER        40400020
         TM    BRKFLGS,BRKNONOT CHECK IF 'NONOTIFY'                     40480020
         BO    NONOT          YES DON'T PRINT.                          40560020
         BAL   R11,TPUT       PUT THE MESSAGE.                          40640020
*        INITIALIZE COMMAND CHAIN WORD IN TCOMTAB.                      40720020
         SPACE                                                          40800020
NONOT    EQU   *              *                                         40880020
         MVC   SUBCHAIN(X4),BRKCHAIN PLACE CHAIN ADDR IN TCOMTAB.       40960020
         B     SCREQ          ENTER COMMAND MODE.                       41040020
         SPACE                                                          41120020
MOVEAT   MVC   X0(X0,R2),X0(R3)  MOVE A PART OF AT MSG TO OUTBUF        41200020
         SPACE                                                          41280020
QPPEND   EQU   *              DID PROBLEM PROGRAM TERMINATE.            41360020
         L     R1,CVT         ADDRESS OF THE CVT                        41410020
         LA    R1,CVTEXIT(R1) ADDRESS OF SVC 3 INSTR IN CVT             41460020
         L     R0,PPTCB       TCB ADDRESS FOR SVC 97.                   41520020
         O     R0,ICCHANGE    IC CHANGE INDICATOR.                      41600020
         SVC   TESTSVC        BUMP IC BY TWO.                           41680020
         LA    R1,NORMTERM    'NORMAL TERMINATION' MESSAGE              41760020
         BAL   R11,TPUT       PUT THE MESSAGE.                          41840020
         B     SCREQ          ENTER COMMAND MODE.                       41920020
         SPACE                                                          42000020
STAICHK  EQU   *                                                        42080020
*        IF THE STAI ECB IS POSTED,THE PROGRAM BEING TESTED HAS         42160020
*        SUFFERED AN ABEND CONDITION WHICH HAS BEEN INTERCEPTED         42240020
*        BY THE TMP STAI EXIT ROUTINE. THE PROGRAM HAS BEEN MADE        42320020
*        NON-DISPATCHABLE THROUGH USE OF THE SETTASK MACRO.             42400020
         SPACE                                                          42480020
         L     R3,ECBTMPS     R3=STAI ECB ADDR.                         42560020
         TM    X0(R3),POSTFLAG Q.IS STAI ECB POSTED.                    42640020
POSTFLAG EQU   X'40'          NORMAL POST MASK.                         42720020
         BZ    TERMCHK        NO,CHECK PROGRAM NORMAL TERMINATION ECB.  42800020
*        YES, PLACE PSEUDO-BREAK AT ABENDING PROGRAM'S RESUME ADDRESS   42880020
*        AND POST THE TMP STAI EXIT ROUTINE COMPLETE WITH A X'7F',      42960020
*        WHICH WILL ALLOW PROGRAM RECOVERY.                             43040020
         SPACE                                                          43120020
         MVI   X0(R3),X0      CLEAR ECB.                                43200020
         L     R3,X0(R3)      LOAD THE ECB.                             43210020
         LTR   R1,R3          PASS PARMS AND CHECK ADDRESS.             43220020
         BZ    SKIP111        DON'T GO.                                 43230020
         L     R15,X0(R3)     PICK UP THE IKJEFT04 MSG PRINT RTN.       43240020
         BALR  R14,R15        PRINT 'ENDED DUE TO ERROR'                43260020
SKIP111  EQU   *                                                        43270020
         TM    TSTFLGS2,TSTLDF  Q.DID LOAD,DELETE,GET OR FREE BOMB.     43310020
         L     R1,WORKAREA    GET REGS IF LDF ABENDED.                  43360020
         L     R3,REGSAVE2    REGS TO GO TO REGSAVE2 FOR SVC.           43440020
         MVC   X0(N64,R3),CWORKLDF-TSTCWORK(R1) *                       43520020
         BO    SKIP2          YES. WE HAVE PP REGS.                     43600020
         SPACE                                                          43610020
*        ALL RBS ARE PURGED UP TO THE MOST CURRENT STAE/STAI EXIT PRB.  43620020
*        IF THERE ARE NONE OF THESE, THEN PURGE BACK TO THE MOST        43630020
*        CURRENT PRB AFTER THE LAST SVRB.                               43640020
*        IF THERE ARE NO PRBS TO RETRY, AND THERE IS ONLY ONE TASK      43650020
*        UNDER TEST THEN PRINT 'NOTHING LEFT TO TEST' AND QUIT.         43660020
*        IF THE ABENDED TASK IS NOT THE HIGHEST TASK, SET A PSEUDO      43670020
*        BREAKPOINT IN ITS MOTHER AND LET THE DAUGHTER ABEND.           43680020
         SPACE                                                          43690020
         L     R7,TPLNTCB     GET THE ABENDED TCB.                      43700020
         LA    R7,X0(R7)      CLEAR THE HIGH BYTE.                      43710020
         ST    R7,PPTCB       SAVE THE TCB FOR STATUS START.            43720020
         L     R2,TCBRBP-TCB(R7)  STAI EXIT PRB.                        43730020
LOOP7    EQU   *                                                        43740020
         L     R2,RBLINK(R2)  HOPEFULLY AN SVRB.                        43750020
LOOP7A   EQU   *                                                        43760020
         L     R4,RBLINK(R2)  HOPEFULLY A PRB.                          43770020
         TM    RBSTAB+X1(R2),X80   DOES R4 CONTAIN A TCB PTR.           43780020
         BO    QRETRY         YES.RETRY MOTHER OR END.                  43790020
         CLI   RBSIZE(R4),X4  Q.IS THIS A PRB WITH NO EXSAVE            43800020
         BNE   LOOP7          NO. LOOP.                                 43810020
         LR    R5,R2          PUT SVRB ADDRESS IN R5                    43820020
LOOP7B   EQU   *                                                        43830020
         L     R5,RBLINK(R5)  SEARCH FOR AN SVRB.                       43840020
         TM    RBSTAB+X1(R5),X80  Q.IS THE LINK FIELD A TCB POINTER.    43850020
         BO    AOK            FOUND END OF THE CHAIN.                   43860020
         TM    RBSTAB(R5),XC0 Q.IS THIS AN SVRB.                        43870020
         BNO   LOOP7B         NO. LOOP.                                 43880020
         CLC   X88(X5,R5),ABEND  Q.IS IT STAE/STAI SVRB                 43890020
         BE    AOK            YES. R2=SVRB,R4=RETRY PRB.                43900020
         LR    R2,R5          SET R2 TO THIS SVRB.                      43910020
         B     LOOP7A         GET PRB AND START OVER.                   43920020
QRETRY   EQU   *                                                        43930020
         L     R5,TCBOTC-TCB(R7)  GET THE MOTHER TCB.                   43940020
         LA    R5,X0(R5)      CLEAR THE HIGH BYTE.                      43950020
         C     R5,TSTTCB      Q. IS THE MOTHER OF TPLNTCB TEST TCB.     43960020
         BNE   SOMTHING       SKIP THE NOTHING CODE.                    43970020
NOTHING  LA    R1,MGNOTRY     'NO ACTIVE PROGRAM LEFT TO TEST'          43980020
         B     PUTEND         PRINT MSG AND EXIT.                       43990020
SOMTHING EQU   *                                                        44000020
         ST    R5,PPTCB       SAVE THE MOTHER AND SET A PSEUDO BRKPT.   44010020
         L     R6,TCBRBP-TCB(R5)  GET THE FIRST RB .                    44020020
LOOP7C   EQU   *                                                        44030020
         TM    RBSTAB(R6),X80   Q.IS THIS A PRB(IRB)                    44040020
         BZ    SETPSEUD       YES SET A PSEUDO BRKPT.                   44050020
         L     R6,RBLINK(R6)  GET THE NEXT RB.                          44060020
         B     LOOP7C         LOOP UNTIL A PRB(IRB) IS FOUND.           44070020
SETPSEUD EQU   *                                                        44080020
         MVC   TSTGO(X4),RBOPSW+X4(R6)  SAVE THE I.C.                   44090020
         MVC   TSTGO+X4(X1),RBWCF(R6) SAVE THE WAIT COUNT.              44100020
         LR    R0,R6          GET THE TARGET PRB ADDRESS.               44110020
         O     R0,WAITOFF     CODE TO ZERO THE WAIT COUNT.              44120020
         SVC   TESTSVC        ZERO THE WAIT COUNT.                      44130020
         LA    R1,TSTGO+6     ADDRESS OF PSEUDO BREAKPT.                44140020
         LR    R0,R6          GET THE TARGET PRB ADDRESS.               44150020
         O     R0,ICCHANGE    CHANGE THE I.C. CODE                      44160020
         SVC   TESTSVC        CHANGE THE INSTRUCTION COUNTER.           44170020
         STATUS START,TCB=(7)   START THE ABENDED TCB.                  44180020
         LA    R0,PPEXIT+X2   RETRY AT SVC 3                            44190020
         B     STAIPOST       LET THE ABEND CONTINUE.                   44200020
AOK      EQU   *                                                        44210020
         MVC   X0(N64,R3),RBGRSAVE(R2)  SAVE THE REGISTERS.             44240020
         OC    TSTGO(X4),RBAPSW(R4)  SAVE ABENDED I.C.                  44320020
         BNZ   SKIP2          SKIP THE NEXT BIT OF CODE.                44400020
         MVC   TSTGO(X4),RBOPSW+X4(R4)  SET UP TEST GO.                 44480020
SKIP2    EQU   *              *                                         44560020
         OI    TSTFLGS3,TSTSTAI  INDICATE THAT THE DAUGHTER ABENDED.    44640020
         LA    R0,TSTGO+X6    RETRY ADDRESS.                            44720020
STAIPOST EQU   *              POST IKJEFT04(TEST/TMP STAI EXIT)         44760020
         L     R1,TPLNECB     POST ECB FOR THE TMP STAI EXIT RTN.       44800020
         O     R0,POST7F      POST STAI ECB WITH A '7F'                 44880020
         POST  (1),(0)        POST STAI ECB WITH X'7F'.                 44960020
         B     WAIT           ALLOW RECOVERY BY WAITING ON PSEUDO-      45040020
*                             BREAK TO OCCUR.                           45120020
         SPACE                                                          45200020
TERMCHK  EQU   *                                                        45280020
*        IF THE PROBLEM PROGRAM HAS TERMINATED NORMALLY, THE TERMIN-    45360020
*        ATION ECB WILL HAVE BEEN POSTED.THE PROGRAM HAS RETURNED TO    45440020
*        THE SYSTEM AND IS NO LONGER AVAILABLE FOR TESTING. A MESSAGE   45520020
*        TO THAT EFFECT IS WRITTEN AND TEST RETURNS TO THE TMP.         45600020
         SPACE                                                          45680020
         LA    R1,TERM0       R1= 'IO1' MESSAGE PARAMETER.              45760020
         BAL   R11,TPUT       PUT THE MESSAGE.                          45840020
         B     ENDIT1         FOLD UP TENT.                             45920020
         SPACE                                                          45923020
STAXFAIL EQU   *              STAX FAILURE.                             45926020
         LA    R1,RESTART1    SET THE RESTART ADDRESS.                  45929020
         ST    R1,TSTRSTRT    DITTO                                     45932020
         BR    R1             GO TO RESTART1 AND CLEANUP.               45935020
         EJECT                                                          45940020
         SPACE                                                          45960020
TMPRTURN EQU   *                                                        46000020
         SPACE                                                          46040020
*        FOLLOWING IS THE GENERAL CLEAN UP LOGIC TO ALLOW CONTROL TO    46080020
*        RETURN TO THE TMP WITH ALL STORAGE AND SYSTEM FACILITIES USED  46160020
*        BY TEST FREE FOR USE BY THE TMP.                               46240020
         SPACE                                                          46320020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT      46400020
         SPACE                                                          46410020
*        CANCEL TEST STAX BUT DONT EVER REISSUE THIS CANCEL             46420020
*        TWO CANCELS RESULT IN TMP'S STAX BEING CANCELLED               46430020
         SPACE                                                          46440020
         LA    R1,RESTART1    IF ABEND DURING END PROCESSING            46450020
         ST    R1,TSTRSTRT    SET RESTART ADDRESS FOR STAE              46460020
         STAX                                                           46470020
RESTART1 EQU   *                                                        46480020
         LA    R1,RESTRT1A    SET NEXT RESTART ADDRESS FOR STAE RTRY    46500020
         ST    R1,TSTRSTRT    DITTO                                     46520020
         L     R1,ECBTMPA     POINT TO ATTN ECB                         46560020
         NI    X0(R1),XFF-TESTATTN+X40  TURN OFF ONE BIT,IF ON          46640020
         SPACE                                                          46720020
         BAL   R11,DCBFREE    FREE ALL THE DCBS.                        46800020
RESTRT1A EQU   *                                                        46820020
         LA    R1,RESTRT1B    SET NEXT RESTART ADDRESS FOR STAE RTRY    46840020
         ST    R1,TSTRSTRT    DITTO                                     46860020
         BAL   R11,FREINBUF   CLEAN UP AFTER CP.                        46880020
RESTRT1B EQU   *                                                        46900020
         LA    R1,RESTRT1C    SET NEXT RESTART ADDRESS FOR STAE RTRY    46920020
         ST    R1,TSTRSTRT    DITTO                                     46940020
*        FREE STORAGE RESERVED FOR COMMAND PROCESSORS.                  46960020
         SPACE                                                          47040020
         L     R1,SCPP4K      R1=ADDR OF RESERVED STORAGE.              47120020
         LTR   R1,R1          IS THERE 4K TO FREE.......                47200020
         BZ    SKIP3          NO. CANNOT FREE NOTHING.                  47280020
         L     R0,CORE6K      SP=2,LENGTH=6144                          47360020
         XC    SCPP4K(X4),SCPP4K  ZERO IN CASE OF ABEND                 47400020
         FREEMAIN R,LV=(0),A=(1)  FREE THE CORE.                        47440020
SKIP3    EQU   *                                                        47520020
RESTRT1C EQU   *                                                        48020020
         LA    R1,RESTRT1D    SET NEXT RESTART ADDRESS FOR STAE RTRY    48520020
         ST    R1,TSTRSTRT    DITTO                                     49020020
*        CHECK TO SEE IF AN IN-CORE SYMBOL TABLE(CHAIN) EXISTS. IF SO,  49760020
*        LOOP THROUGH THE CHAIN FREEING EACH BLOCK.                     49840020
         SPACE                                                          49920020
         L     R2,SYMTABLE    R2=ADDR OF HEAD OF CHAIN.                 50000020
         XC    SYMTABLE(X4),SYMTABLE  ZERO IN CASE OF ABEND             50040020
LOOP5    EQU   *                                                        50080020
         LTR   R2,R2          Q.END OF CHAIN.                           50160020
         BZ    WORKFREE       YES,FORTFAHREN MIT DER REINIGUNG.         50240020
         LR    R1,R2          NO,R1=SYMBOL ELEMENT ADDR FOR FREEMAIN.   50320020
         LA    R0,SYSMLEN     GET SYMBOL COMMON SECTION LENGTH          50400020
SYSMLEN  EQU   16             *                                         50480020
         O     R0,SP1         INSERT IN HIGH BYTE SUBPOOL NUMBER        50560020
         AH    R0,SYMBLEN(R1) GET SYMBOL BLOCK SIZE                     50640020
SYMBLEN  EQU   14             DISPLACEMENT INTO BLOCK                   50720020
         L     R2,SYMLINK(R2) GET THE NEXT ONE.                         50800020
         FREEMAIN R,LV=(0),A=(1)  FREE THE SYMBOL ELEMENT.              50880020
SYMLINK  EQU   0              LINK FIELD.                               50960020
         B     LOOP5          CHECK FOR ANOTHER SYMBOL ELEMENT.         51040020
         SPACE                                                          51120020
WORKFREE EQU   *                                                        51200020
RESTRT1D EQU   *                                                        51220020
         LA    R1,RESTRT1E    SET NEXT RESTART ADDRESS FOR STAE RTRY    51240020
         ST    R1,TSTRSTRT    DITTO                                     51260020
*        FREE THE STORAGE GOTTEN BY THE INITIALIZATION ROUTINE FOR      51280020
*        WORK AREAS AND THE TCOMTAB.                                    51360020
         SPACE                                                          51380020
         BAL   R11,REMOVE     REMOVE THE TERM ELEM OFF THE STACK        51400020
         SPACE                                                          51440020
         TM    TSTFLGS1,RUNSW  SHOULD SUBTASK BE DETACHED.              51520020
         BZ    DETACH         YES.DETACH AND WIPE OUT HIS REGION.       51600020
         L     R2,TSTSVCQ     GET MULTI TASK ECB QUEUE.                 51680020
         XC    TSTSVCQ(X4),TSTSVCQ  ZERO IN CASE OF ABEND               51720020
QLOOP    EQU   *                                                        51760020
         LTR   R1,R2          TEST IF QUEUE IS EMPTY.                   51840020
         L     R3,X4(R2)      GET THE LINK FIELD.                       51920020
         BZ    OUT            IT'S EMPTY.                               52000020
         POST  (1)            POST EACH ONE.                            52080020
         LR    R2,R3          GET THE LINK FIELD.                       52160020
         B     QLOOP          LOOP.                                     52240020
OUT      EQU   *                                                        52320020
RESTRT1E EQU   *                                                        52360020
         LA    R1,RESTRT1F    SET NEXT RESTART ADDRESS FOR STAE RTRY    52400020
         ST    R1,TSTRSTRT    DITTO                                     52440020
         MVI   TSTMTASK,X0    RESET SVC' MULTI TASK SWITCH.             52560020
         POST ECBPP           POST WILL OCCUR ONLY FOR 'RUN'            52640020
ENDIT2   EQU   *              CAME FROM DETACH.                         52720020
         L     R2,TSTTRN      GET THE HEAD OF TRN QUEUE.                52800020
         XC    TSTTRN(X4),TSTTRN  ZERO FOR ABEND PROCESSING             52840020
LOOP3    LTR   R1,R2          LINK PTR OR HEAD.                         52880020
         BZ    OUT1           IF ZERO ...END OF QUEUE...                52960020
         L     R0,CORETRN     SP=1,LENGTH=12                            53040020
         L     R2,X0(R2)      GET THE LINK POINTER.                     53120020
*              FREE THE SVC INFO BLOCKS CONTROL WORD QUEUE.             53200020
         FREEMAIN  R,LV=(0),A=(1)  FREE THE CORE.                       53280020
         B     LOOP3          LOOP                                      53360020
OUT1     EQU   *              *                                         53440020
RESTRT1F EQU   *                                                        53450020
         LA    R1,RESTART2    IF ABEND LINKING TO DAIR                  53460020
         ST    R1,TSTRSTRT    SET RESTART ADDRESS FOR STAE              53480020
         L     R0,TSTTCB      TCB ADDRESS FOR DAIR LIST                 53520020
         BAL   R11,UNALLOCT   UNALLOC ALL DATA SETS UNDER THIS TCB      53600020
RESTART2 EQU   *                                                        53640020
         LA    R1,RESTRT2A    SET NEXT RESTART ADDRESS FOR STAE RTRY    53650020
         ST    R1,TSTRSTRT    DITTO                                     53660020
         L     R0,TSTTCB      SET TEST'S TCBTRN FIELD TO '0'            53680020
         SR    R1,R1          ZERO.                                     53760020
         O     R0,TCBTRNFL    *                                         53840020
         SVC   TESTSVC        CHANGE IT.                                53920020
         MVC   TSTCURLD(FRELEN),FREELIST MOVE LFORM LIST INTO TCOMTAB.  54000020
RESTRT2A EQU   *                                                        54010020
         LA    R1,RESTART3    IF ABEND ON THIS FREEMAIN                 54020020
         ST    R1,TSTRSTRT    STAE WILL RESTART FROM HERE.              54040020
         LA    R1,TSTCURLD    R1=ADDR OF FREEMAIN PARM LIST.            54080020
         NI    CONAREA+X3,XF8    ROUND DOWN TO DOUBLE WORD BOUNDRY.     54160020
         L     R13,X4(R13)    RESTORE R13 BEFORE FREEING REGSAVE1       54240020
         FREEMAIN L,LA=GETMNLA,A=SCPPAD,SP=1,MF=(E,(1))                 54320020
RESTART3 EQU   *                                                        54340020
         LA    R1,RESTART4    IF ABEND ON THIS FREEMAIN                 54360020
         ST    R1,TSTRSTRT    STAE WILL RESTART FROM HERE.              54380020
         LR    R1,R9          R1=TCOMTAB ADDR FOR FREEMAIN.             54400020
         FREEMAIN R,LV=TCOMLEN,A=(1),SP=1 FREE TCOMTAB.                 54480020
RESTART4 EQU   *                                                        54520020
         SPACE                                                          54560020
         SPACE                                                          54640020
         RETURN (14,12),RC=0                                            54720020
         EJECT                                                          54760020
         SPACE                                                          54800020
DETACH   EQU   *              *                                         54880020
*        CHECK  TO SEE IF A SUB-TASK EXISTS.IF SO SET TERMINATION       54960020
*       ECB, SO THAT THE TMP WILL DETACH IT.                            55040020
         SPACE                                                          55120020
         L     R3,ECBTERM     TERMONATION ECB FOR THE SUBTASK.          55420020
         XC    X0(X4,R3),X0(R3)  ZERO THE COMPLETION.                   55720020
         MVI   X0(R3),X40     SET TERMINATION ECB FOR DETACH.           56020020
         BAL   R11,STOPALL    FOR END, STOP TWICE - TMP WILL START      56120020
*                              ONCE AND DETACH TASK NON-DISPATCHABLE    56220020
         B     ENDIT2         CLEAN UP GO BACK TO THE TMP               56320020
         SPACE                                                          56880020
STOP     EQU   *              STOP ONE OR ALL.                          56960020
         NC    TSTGO(X4),TSTGO  PSEUDO BREAKPOINT.....                  57040020
         BZ    STOPALL        NO. STOP THEM ALL.                        57120020
         STATUS STOP,TCB=PPTCB  STOP ONLY ONE.                          57200020
         BR    R11            RETURN.                                   57280020
STOPALL  EQU   *                                                        57360020
         STATUS STOP          STOP THEM ALL.                            57440020
         BR    R11            RETURN.                                   57520020
         SPACE                                                          57600020
START    EQU   *              START PPTCB OR ALL.                       57680020
         NC    TSTGO(X4),TSTGO  PSEUDO BREAKPOINT SET.Q.Q.Q.            57760020
         BZ    STARTALL       NO,START THEM ALL.                        57840020
         STATUS START,TCB=PPTCB YES,START ONLY PP TCB.                  57920020
*        THIS SOLVES A TIMING PROBLEM.                                  57926020
*        IF REMOVED, TEST WILL STILL WORK.                              57932020
*        THIS MUST BE ISSUED AFTER THE STATUS START.                    57938020
         L     R1,TSTTCB      FORCE A TRANSIENT REFRESH.                57944020
*        NOTE -- CODE OF 00 TO SVC DOES NOTHING.                        57950020
         LA    R0,X0(R1)      HIGH BYTE CODE OF 00 WILL CAUSE AN        57956020
*                             EXIT FROM THE TRANSIENT AREA WHICH        57962020
*                             WILL CAUSE ANY SVC'S THAT DIDN'T          57968020
*                             GET REFRESHED AFTER SWAP IN ,TO BE        57974020
*                             REFRESHED.                                57980020
         SVC   TESTSVC        CAUSE SVC TO ISSUE SVC 3                  57986020
         BR    R11            RETURN.                                   58000020
STARTALL EQU   *                                                        58080020
         STATUS START         START THEM ALL.                           58160020
*        THIS SOLVES A TIMING PROBLEM.                                  58166020
*        IF REMOVED, TEST WILL STILL WORK.                              58172020
*        THIS MUST BE ISSUED AFTER THE STATUS START.                    58178020
         L     R1,TSTTCB      FORCE A TRANSIENT REFRESH.                58184020
*        NOTE -- CODE OF 00 TO SVC DOES NOTHING.                        58190020
         LA    R0,X0(R1)      HIGH BYTE CODE OF 00 WILL CAUSE AN        58196020
*                             EXIT FROM THE TRANSIENT AREA WHICH        58202020
*                             WILL CAUSE ANY SVC'S THAT DIDN'T          58208020
*                             GET REFRESHED AFTER SWAP IN ,TO BE        58214020
*                             REFRESHED.                                58220020
         SVC   TESTSVC        CAUSE SVC TO ISSUE SVC 3                  58226020
         BR    R11            RETURN.                                   58240020
         EJECT                                                          58242020
         SPACE                                                          58244020
*        A TERMINAL ELEMENT IS ADDED WHEN TEST INITIALLY DETERMINES     58246020
*        THAT IT'S INPUT IS FROM THE TERMINAL. THE IKJEGIO MODULE       58248020
*        UPON GETTING A RET CODE OF 0 FROM A PUTGET , TURNS ON A BIT    58250020
*        INDICATING INPUT FORM THE TERMINAL.                            58252020
*        MAINLINE WILL PLACE A TERMINAL ELEM ON THE STACK WHILE         58254020
*        TEST IS RUNNING, AND REMOVES IT UPON POSTING THE PROB. PROG.   58256020
*        IF TEST IS RUNNING WITHIN THE STACK THIS IS NOT DONE.          58258020
         SPACE                                                          58260020
ADD      EQU   *              ADD A TERM ELEM TO THE STACK              58262020
         SR    R0,R0          ZERO INDICATES 'ADD'                      58264020
         TM    TSTFLGS4,TSTA  RUNNING FROM THE TERMINAL Q.Q.Q.          58266020
         BCR   Z,R11          NO. RETURN.                               58268020
         TM    TSTFLGS4,TSTB  TERM ELEM ALREADY ADDED.                  58270020
         BCR   ONES,R11       YES RETURN.                               58272020
         B     LIKECODE       CONSERVE CODE.                            58274020
REMOVE   EQU   *              REMOVE THE TERM ELEM OFF THE STACK        58276020
         LA    R0,X1          ONE INDICATES 'REMOVE'                    58278020
         TM    TSTFLGS4,TSTB  IS THERE AN ELEM TO REMOVE.               58280020
         BCR   Z,R11          NO. RETURN.                               58282020
LIKECODE EQU   *              CONSERVE CORE.                            58284020
         L     R1,WORKAREA    PARM LIST TO WORKAREA.                    58286020
         LA    R2,N16(R1)     STACK LIST OFFSET.                        58288020
         MVC   X0(N12,R1),PARMLIST  SET UP PARMLIST.                    58290020
         MVC   X0(STACKLEN,R2),STACKLST  SET UP STACK LIST.             58292020
         ST    R2,N12(R1)     PUT THE STACKLIST ADDR IN PARM LIST       58294020
         BCT   R0,ADD1                                                  58296020
         STACK DELETE=TOP,MF=(E,(1))                                    58298020
         NI    TSTFLGS4,XFF-TSTB  INDICATES NO ELEMENT.                 58300020
         BR    R11            RETURN.                                   58302020
ADD1     EQU   *              PLACE A TERM ELEM ON TOP OF STACK.        58304020
         STACK TERM=*,MF=(E,(1))                                        58306020
         OI    TSTFLGS4,TSTB  INDICATE AN ELEMENT.                      58308020
         BR    R11            RETURN.                                   58310020
         SPACE                                                          58310120
FLUSH    EQU   *              TCLEARQ AND MAYBE A STACK FLUSH.          58310220
         TCLEARQ  INPUT                                                 58310320
         TM    TSTFLGS4,TSTA  Q. IS TEST COMING OUT OF A STACK.         58310420
         BCR   ONES,R11       NO. RETURN TO CALLER.                     58310520
         L     R1,WORKAREA    GET LIST AREA POINTER.                    58310620
         LA    R14,N16(R1)    GET PARM BLOCK POINTER.                   58310720
         MVC   X0(N12,R1),PARMLIST  MOVE UPT, ECT, CPECB PTRS.          58310820
         MVC   X0(STACKLEN,R14),STACKLST MOVE STACK LIST                58310920
         ST    R14,N12(R1)    STORE PARM BLOCK PTR.                     58311020
         STACK  DELETE=ALL,MF=(E,(1))                                   58311120
         BR    R11            RETURN.                                   58311220
         SPACE                                                          58312020
         SPACE                                                          58320020
RUNRTURN EQU   *                                                        58400020
*        SET UP A PARAMETER-LESS COMMAND IN STORAGE FOR THE 'OFF'       58480020
*        COMMAND PROCESSOR. SET 'RUNSW' IN TCOMTAB AND THE 'OFF'        58560020
*        INDEX IN REGISTER 6 TO CAUSE THE 'OFF' PROCESSOR TO BE ENTERED 58640020
*        TO REMOVE ALL BREAKPOINTS.                                     58720020
         SPACE                                                          58800020
         L     R2,TPLCTCB     OBTAIN INITIAL SAVE AREA ADDRESS.         58880020
         L     R2,TCBFSA-TCB(R2)  INITIAL SAVE AREA.                    58960020
         L     R3,CVT         CVT POINTER.                              59040020
CVT      EQU   16             CVT AT LOC X'10'                          59120020
         LA    R3,CVTEXIT(R3) ADDRESS OF AN SVC 3 INSTRUCTION.          59200020
CVTEXIT  EQU   80             OFFSET FOR CVT SVC 3.                     59280020
         ST    R3,N12(R2)     PP WILL EXIT ON BR R14.                   59360020
         L     R1,PPTCB       GET THE PROBLEM PROGRAMS TCB ADR          59440020
         L     R4,TCBRBP-TCB(R1)  GET THE PP'S SVRB ADDR                59520020
         LA    R0,X0(R1)      PPTCB  ADR TO SVC 97                      59600020
         O     R0,RGCHANGE    CHANGE REG 14 TO POINT TO SVC 3           59680020
         LA    R1,PPEXIT      POINT TO R14 VALUE                        59760020
         C     R1,RBGR14(R4)  Q. DOES PP'S R14 STILL POINT TO SVC97     59840020
         BNE   NOCHANGE       NO. DONT CHANGE R14                       59920020
         ST    R3,PPEXIT      ADR OF SVC 3 FOR R14 CHANGE               60000020
         O     R1,CHANGE14    HIGH BYTE PARM TO PASS TO SVC 97          60080020
         SVC   TESTSVC        CHANGE THE PP'S R14                       60160020
NOCHANGE EQU   *              *                                         60240020
         OI    TSTFLGS1,RUNSW TURN ON RUNSW.                            60320020
ENDIT1   EQU   *              'END' WILL NOT TURN ON RUN SWITCH.        60400020
         OI    TSTFLGS1,ENDSW TURN ON ENDSW.                            60480020
         L     R6,OFFSID      OBTAIN ID FOR OFF.                        60560020
         LH    R6,X0(R6)      *                                         60640020
         B     SCLINK         LINK TO 'OFF'.                            60720020
         SPACE                                                          60730020
ENDITERR EQU   *              COMING FROM A TEST ERROR.                 60740020
         BAL   R11,FLUSH      TCLEARQ AND MAYBE STACK FLUSH.            60750020
         B     ENDIT1         GO THRU END PROCESSING.                   60760020
         SPACE                                                          60800020
DEFER    EQU   *              *                                         60880020
         L     R1,ECBPP       OBTAIN SVRB ADDRESS FOR SVC61             60960020
         LM    R3,R4,RBEXSAVE(R1) GET THE TCB ADR AND SVC INFO BLK PTR  61040020
         LTR   R3,R3          TCB ADDRESS IS ZERO , IGNORE              61120020
         BZ    NOGET          ZERO....IGNORE....                        61200020
         L     R0,CORETRN     SP=1 , LENGTH=12                          61280020
         GETMAIN  R,LV=(0)    GET CORE FOR CONTROL WORDS.               61360020
         MVC   X0(X4,R1),TSTTRN  SAVE THE LINK FIELD.                   61440020
         STM   R3,R4,X4(R1)   TCB ADDR. AND SVC INFO BLK TO LIST..      61520020
         ST    R1,TSTTRN      SAVE CORE ADDRESS                         61600020
NOGET    EQU   *              *                                         61680020
         OC    DEFERTAB(X4),DEFERTAB  Q.NEED TO GO TO 'AT'              61760020
         BZ    IKJEGCTL       A.NO  ....POST.                           61840020
         OI    TSTFLGS1,TSTBUILD  SET SWITCH FOR IKJEGAT1               61920020
*                             CWORKCMD CONTAINS LOADNAME,LOADBGN        62000020
         L     R6,ATSID       OBTAIN ID FOR AT.                         62080020
         LH    R6,X0(R6)      *                                         62160020
         B     SCLINK         LINK TO IKJEGAT1                          62240020
QUAL     EQU   *              RE-QUALIFY.                               62320020
         SPACE                                                          62330020
*        AUTOMATIC QUALIFICATION TAKES PLACE WHEN A BREAKPOINT IS       62340020
*        HIT EITHER UNDER A NEW TCB OR UNDER A NEW RB                   62350020
*        THE CHECK IS MADE USING PPRB AND TSTAQUAL                      62360020
         SPACE                                                          62370020
         L     R4,PPTCB       FIND CURRENT RB ADDRESS.                  62400020
         L     R2,TCBRBP-TCB(R4) *                                      62480020
         L     R1,RBLINK(R2)  *                                         62560020
         LA    R1,X0(R1)      CLEAR HIGH BYTE.                          62640020
         L     R2,PPRB        GET LAST BREAKPOINTED RB.                 62720020
         LA    R2,X0(R2)      CLEAR HIGH BYTE.                          62800020
         ST    R1,PPRB        SAVE THE NEW PRB ADDRESS.                 62810020
         TM    RBSTAB(R1),X40  Q.IS THIS AN IRB.                        62813020
         BCR   ONES,R11       YES. DO NOT QUALIFY.                      62816020
         L     R14,RBCDE(R1)  GET THE CDE POINTER.                      62820020
         LA    R14,X0(R14)    CLEAR THE HIGH BYTE.                      62830020
         LTR   R14,R14        Q.IS THE CDE PTR. ZERO.                   62840020
*        THE CDE POINTER IS ZERO WHEN A BREAKPT IS HIT IN A STAE EXIT   62850020
         BCR   Z,R11          YES. CANNOT AUTOMATICALLY QUALIFY.        62860020
         CR    R1,R2          Q.IS REQUALIFICATION NEEDED.              62870020
         LR    R2,R14         PUT THE CDE PTR INTO R2                   62880020
         BNE   REQUAL         REQUALIFY TO THIS BREAKPOINTED RB         62900020
         SPACE                                                          62920020
*        CHECK THE NAME AND EPA.  AN EQUAL RB ADDRESS DOES NOT          62930020
*        INDICATE THE SAME R.B. AS PREVIOUSLY QUALIFIED.                62940020
         SPACE                                                          62950020
         CLC   TSTAQUAL(X8),CDNAME(R2)  SAME NAME AS BEFORE.            62960020
         BNE   REQUAL         REQUALIFY AUTOMATICLY                     62970020
         CLC   TSTAQUAL+X9(X3),CDENTPT(R2)  CHECK EPA-ES                62980020
         BCR   EQ,R11         SAME AS BEFORE. RETURN.                   62990020
REQUAL   EQU   *                                                        63000020
         MVC   TSTAQUAL(N12),CDNAME(R2)  SAVE NAME AND EPA              63010020
         MVI   TSTCURCT,X0    ZERO CURRENT CSECT NAME.                  63120020
GOTCDE   EQU   *              GOT THE CORRECT CDE.                      63280020
         MVC   TSTCURLD(X8),CDNAME(R2) REINITIALIZE CURRENT LOADNAME    63360020
MINOR    EQU   *              *                                         63440020
         TM    CDEATR1(R2),MINORBIT  IS IT A MINOR.                     63520020
         LR    R14,R2         SAVE THE CDE ADDRESS                      63560020
         L     R2,CDEXLMJ(R2)  WANT A MAJOR.                            63600020
         BO    MINOR          NOT A MAJOR.                              63680020
         L     R1,XLNUM(R2)   GET THE NUMBER OF EXTENTS.                63760020
         SLL   R1,X2          TIMES 4.                                  63840020
         L     R2,XLADR(R1,R2)  GET THE MEMBER ADDRESS.                 63920020
         TM    CDATTR2(R14),CDOVLBIT  CHECK IF OVERLAY.                 63923020
         BO    OVERLAY        YES. SPECIAL HANDLING.                    63926020
         TM    CDATTR2(R14),CDOBJBIT  TEST IF OSLOADED                  63930020
         BNO   SKIP6          NO --BRANCH                               63940020
         LA    R2,N16(R2)     ADD 16 TO BYPASS PREFIX.                  63950020
SKIP6    EQU   *                                                        63960020
         ST    R2,PPLOAD      RE-INITIALIZE PPLOAD.                     64000020
         ST    R2,TSTSYMBA    DITTO.                                    64080020
         BR    R11            RETURN.                                   64160020
OVERLAY  EQU   *              QUALIFY TO ROOT SEGMENT                   64160120
*                             R2=ADDRESS OF SEGTAB CSECT.               64160220
         LR    R15,R2         SAVE THE EXTENT LIST ADDR.                64160320
         LA    R0,X4          SET INDEX,4 REGIONS MAX.                  64160420
         SR    R14,R14        CLEAR FOR INSERT.                         64160520
CKREGION EQU   *                                                        64160620
         IC    R14,X8(R2)     GET SEG NO. OF REGION                     64160720
         TM    N10(R2),XFF    ARE THEIR ANY MORE REGIONS.               64160820
         BZ    LASTREGN       NO, GO FIGURE LEN OF SEGTAB.              64160920
         BCT   R0,SETNEXT1    YES, GO SET TO CHECK NEXT.                64161020
LASTREGN EQU   *              LAST REGION.                              64161120
         SLL   R14,X2         MULTIPLY LAST SEG NO. BY 4.               64161220
         LA    R2,N24(R14,R15) XLADDR PLUS LENGTH OF SEGTAB.            64161320
*        AT THIS POINT R2'S LOW TWO BITS ARE ZERO.                      64161420
         LA    R14,X4         ALIGN TO A DOUBLE WORD.                   64161520
         NR    R14,R2         DITTO.                                    64161620
*        R14 RESULT IS EITHER 0 OR FOUR.                                64161720
*        IF ON DOUBLE WORD BNDY 0 IS ADDED TO R2                        64161820
*        IF NOT ON A DWORD BNDY 4 IS ADDED TO R2                        64161920
         ALR   R2,R14         DITTO                                     64162020
         B     SKIP6          SAVE ROOT SEG ADDR.                       64162120
SETNEXT1 EQU   *              BUMP BY TWO.                              64162220
         LA    R2,X2(R2)      DITTO.                                    64162320
         B     CKREGION       LOOP.                                     64162420
         EJECT                                                          64164020
         SPACE                                                          64168020
*        THIS IS THE STAE RETRY ROUTINE FOR THE MAINLINE MODULE         64172020
*        OF TEST.                                                       64176020
*        IT GETS CONTROL ON ALL ABENDS WHEN NOT IN SUBCOMMAND MODE.     64180020
*        ABENDS WHICH ARE HANDLED ARE AS FOLLOWS.                       64184020
*           ABEND IN END PROCESSING                                     64188020
*           LINK AND ATTACH FAILURES.                                   64192020
*           LINK TO SUBCOMMAND FAILURES.                                64196020
*              THIS FAILURE IS RETRIED AFTER SCPP4K IS FREED.           64200020
*              ABEND CODE 106 FROM A SUBCOMMAND FAILURE WILL NOT        64204020
*              BE RETRIED.                                              64208020
*           XCTL FAILURES GOING FROM ONE LOAD OF A SUBCOMMAND, TO       64212020
*           ANOTHER                                                     64216020
*           IF LINK FAILURE TO 'AT' IN DEFER BREAKPT PROCESSING,        64220020
*           THE PP WILL BE TOLD TO CONTINUE.                            64224020
         SPACE                                                          64228020
RETRY    EQU   *                                                        64240020
         USING *,R15           ESTABLISH ADDRESSABILITY                 64320020
         L     R12,BASEAD     *                                         64400020
         DROP  R15            *                                         64480020
         L     R7,CVT         CVTPTR                                    64560020
         L     R8,X0(R7)      NEW/CURRENT WORDS.                        64640020
         L     R8,X4(R8)      CURRENT TCB.                              64720020
         L     R9,TCBTRN-TCB(R8)  TCOMTAB ADDRESS.                      64800020
         L     R13,REGSAVE1   RESET R13                                 64880020
         LM    R2,R11,N28(R13) RESTORE REGISTERS.                       64960020
         LTR   R0,R0          104 BYTE WORKAREA Q.Q.Q.                  65040020
         BNZ   RETRY1         NO. SKIP FREEMAIN.                        65120020
         L     R0,CORE104     SUBPOOL AND LENGTH.                       65200020
         FREEMAIN R,LV=(0),A=(1)  FREE THE STAE WORKAREA.               65280020
RETRY1   EQU   *                                                        65360020
         L     R1,WORKAREA    R1=ADDR OF STAE PARM LIST.                65520020
         MVC   X0(STAELEN,R1),STAELIST  MOVE L-FORM TO LIST.            65600020
         MVC   X0(X4,R1),TSTSTAE  EP FOR STAE EXIT ROUTINE.             65680020
         STAE  MF=(E,(1))     ISSUE STAE AGAIN...                       65840020
         L     R15,TSTRSTRT   FETCH THE RESTART ADDRESS IF ONE          65850020
         LTR   R15,R15        IS THERE ONE Q.Q.Q.                       65860020
         BCR   NZ,R15         YES. GO THERE                             65870020
         TM    TSTFLGS1,ENDSW  TEST IF ABEND OCCURRED AT 'END' TIME     65880020
         BO    TMPRTURN       CLEAN UP AND RETURN TO THE TMP.           65890020
         TM    TSTFLGS3,TSTHELP  DID ATTACH FAIN FOR HELP.              65920020
         BO    NOHELP         GET ANOTHER COMMAND.                      66000020
         TM    TSTFLGS3,TSTLINK  IS THIS A SUBCOMMAND RETRY.....        66080020
         BZ    ENDITERR       NO. RETURN TO THE TMP.                    66160020
         NI    TSTFLGS3,XFF-TSTLINK  TURN LINK BIT OFF.                 66240020
         NI    TSTFLGS1,XFF-TSTPRINT-TSTFIRST-PCHLSTVL-RANGESW *        66320020
         TM    TSTFLGS2,TSTXCTL  DID SC FAIL GOING TO 2ND LOAD          66400020
         BO    XCTLON         YES..BRANCH...                            66480020
         L     R1,SCPP4K      GET 4K ADDRESS IF ONE.                    66560020
         LTR   R1,R1          4K.... YES OR NO.                         66640020
         BZ    QUIT           NO. LINK FAILED TWICE. QUIT.......        66720020
         L     R14,TSTTCB     OBTAIN TCB POINTER                        66800020
         CLC   TCBCMP+X1-TCB(X2,R14),CMP106 CHECK COMPLETION CODE       66880020
         BE    GOT106         PRINT 'LINK TO SC FAILED'                 66960020
         XC    SCPP4K(X4),SCPP4K  ZERO IN CASE OF ABEND                 67000020
         L     R0,CORE6K      SP=2,LENGTH=6144                          67040020
         FREEMAIN R,LV=(0),A=(1)  FREE INORDER TO RETRY THE LINK.       67120020
         B     LINKSC         RETRY THE LINK TO SUBCOMMAND.             67280020
XCTLON   EQU   *              *                                         67360020
         NI    TSTFLGS2,XFF-TSTXCTL  TURN OFF XCTL SWITCH               67440020
         B     SCREQ1         REQUEST ANOTHER COMMAND                   67520020
GOT106   EQU   *              PRINT 'LINK TO SC FAILED'                 67600020
         LA    R1,SCFAIL      DITTO                                     67680020
         BAL   R11,TPUT       PRINT IT                                  67760020
         TM    TSTFLGS1,TSTBUILD  IS THIS A DEFER BREAK POINT           67840020
         BO    BUILDON        YES. IGNORE DEFER BREAK POINT.            67920020
         B     SCREQ1         PUT OUT 'TEST' MODE MESSAGE.              68000020
BUILDON  NI    TSTFLGS1,XFF-TSTBUILD  CONTINUE PROCESSING               68080020
         B     IKJEGCTL       GO TO P.P.                                68160020
QUIT     EQU   *                                                        68240020
         LA    R1,SCFAIL      'CANNOT LINK TO SUBCOMMAND'               68320020
         B     PUTEND         PUT MESSAGE AND TERMINATE.                68400020
NOCORE   EQU   *                                                        68480020
         LA    R1,COREFAIL    INSUFFICIENT STORAGE.                     68560020
PUTEND   EQU   *                                                        68640020
         BAL   R11,TPUT       PUT THE MESSAGE.                          68720020
         TM    TSTFLGS1,TSTBUILD  IS THIS A DEFER BREAK POINT           68800020
         BO    BUILDON        YES. IGNORE DEFER BREAK POINT.            68880020
         B     ENDITERR       FOLD.                                     68960020
         SPACE                                                          69040020
*        THE FOLLOWING SECTION IS SPECIAL FOR THE HELP SUBCOMMAND.      69120020
HELP1    EQU   *              HELP PROCESSING.                          69200020
         L     R1,TPLCBUF     GET COMMAND BUFFER.                       69280020
         LH    R0,X0(R1)      PICK UP LENGTH TO FREE.                   69360020
         LTR   R0,R0          LENGTH ZERO.......                        69440020
         BZ    SKIP5          YES...SKIP...                             69520020
         O     R0,SP1         FREE IT.                                  69600020
         FREEMAIN R,LV=(0),A=(1) *                                      69680020
SKIP5    EQU   *                                                        69760020
         L     R0,INBUF       GET HELP BUFFER.                          69840020
         ST    R0,TPLCBUF     SET UP FOR ***HELP***                     69920020
         XC    INBUF(X4),INBUF  ZERO INPUT BUFFER.                      70000020
         L     R2,ECBTERM     TERMINATION ECB FOR HELP.                 70080020
         XC    X0(X4,R2),X0(R2)  ZERO IT                                70160020
         L     R15,WORKAREA   AREA FOR LIST FORM OF ATTACH.             70240020
         XC    X0(ATTCHLLN,R15),X0(R15) ATTACH LIST FORM.               70320020
         MVI   N20(R15),X2    SET ROLL OUT BITS.                        70400020
         L     R6,TPLECT      ECT ADDRESSABILITY.                       70480020
         LR    R7,R15         WORKAREA ADDRESSABILITY.                  70560020
         USING ECT,R6         *                                         70640020
         USING TSTCWORK,R7    *                                         70720020
         MVC   CWORKLDF(X8),ECTPCMD  SAVE THE COMMAND NAME.             70800020
         MVC   ECTPCMD(X8),TEST      ENTER TEST'S NAME.                 70880020
         LA    R4,HELPEXIT    STAI EXIT FOR ***HELP***                  70960020
         LR    R1,R10         PASS TO ***HELP*** CPPL.                  71040020
         ATTACH EP=HELP,ECB=(2),MF=(E,(1)),SF=(E,(15)),SHSPV=78,       *71140020
               STAI=((4),0),SZERO=NO  ATTACH.                           71240020
BLOW3    EQU   *                                                        71360020
         CH    R15,EIGHT      Q.ENOUGH CORE FOR AN S.C.B.               71370020
         BNE   HELP2          A.YES                                     71380020
         MVC   ECTPCMD(X8),CWORKLDF  RESTORE THE COMMAND NAME.          71390020
         B     NOCORE         'NOT ENOUGH CORE TO PROCESS'              71400020
HELP2    EQU   *                                                        71410020
         LR    R3,R1          ***HELP*** TCB                            71440020
         ST    R1,TSTHTCB     SAVE FOR ATTENTION PROCESSING.            71460020
         OI    TSTFLGS3,TSTHELP  TURN ON THE HELP ATTACH SWITCH         71480020
         WAIT  ECBLIST=HLPLIST  WAIT FOR HELP                           71520020
         L     R4,WORKAREA+X8 DETACH NEEDS A POINTER TO THE TCB  M2013  72000021
         MVC   X0(LEN2C,R4),DAIR2C  UNALLOC TCB.                        72080020
         ST    R3,X4(R4)      TCB TO LIST                               72160020
         LR    R1,R4          DAIR LIST TO R1                           72240020
         BAL   R11,DAIR       SETUP AND LINK TO DAIR                    72320020
         MVC   X0(X4,R4),X0(R2)  SAVE THE ECB CODE                      72400020
         LA    R1,TSTHTCB     POINTER TO TCB.                           72480020
         DETACH  (1)          DETACH ***HELP***                         72560020
NOHELP   NI    TSTFLGS3,XFF-TSTHELP TURN OFF HELP SWITCH.               72640020
         MVC   ECTPCMD(X8),CWORKLDF  RESTORE THE COMMAND NAME.          72720020
         DROP  R6                                                       72800020
         DROP  R7                                                       72880020
         XC    X0(X4,R2),X0(R2)  CLEAR THE ECB.                         72890020
         L     R1,ECBTMPA     ADDRESSABILITY TO ATTN ECB.               72900020
         TM    X0(R1),TESTATTN  TEST IF TEST OR TMP OR NO POST.         72910020
         BM    ENDIT1         CLEAN UP AND GO BACK TO TMP.              72920020
         MVI   X0(R1),X0      CLEAR THE ECB.                            72930020
         BO    SCREQ          GET BUFFER GOTTEN BY ATTENTION.           72940020
         OC    X1(X2,R4),X1(R4)  DID HELP ABEND QQQ.                    72960020
         BZ    SCREQ          NO....GET ANOTHER COMMAND.                73040020
         LR    R15,R4         POINTER TO SAVED ECB TO R15               73120020
         LM    R0,R1,MHELP    PASS 1ST AND 2ND LEVEL TO MSGBUILD.       73200020
         BAL   R11,MSGBUILD   GO TO BUILD 2ND LEVEL MSG.                73280020
         BAL   R11,TPUT       PRINT.                                    73360020
         B     SCREQ          GET THE NEXT COMMAND.                     73440020
         SPACE                                                          73520020
HELPEXIT RETURN  RC=16        CONTINUE ABEND.                           73600020
         SPACE                                                          73680020
UNALLOCT EQU   *              UNALLOCATE BY TCB  CODE  2C               73760020
         L     R1,WORKAREA    ADDRESSABILITY TO GENERAL WORKAREA.       73840020
         MVC   X0(LEN2C,R1),DAIR2C  UNALLOC TCB.                        73920020
         ST    R0,X4(R1)      TCB TO LIST.                              74000020
DAIR     EQU   *                                                        74080020
         L     R14,WORKAREA   OBTAIN ADDRESSABILITY TO CWORKLDF         74160020
         LA    R14,CWORKLDF-TSTCWORK+N16(R14) ADDR OF DAIR PARM LM2013  74240021
         MVC   X0(N12,R14),PARMLIST  MOVE IN FIRST PORTION.             74320020
         L     R0,TPLPSCB     PSCB TO SECOND PORTION.                   74400020
         STM   R0,R1,N12(R14)  PSCB,DAIR PARMS TO LIST.                 74480020
         LR    R1,R14         DAIR LIST TO R1 FOR INPUT.                74560020
         LINK  EP=IKJDAIR     LINK TO DAIR                              74640020
BLOWDAIR EQU   *              BLOW POINT                                74720020
         BR    R11            RETURN.                                   74800020
*****************************************************************       74880020
*INPUT*  R14 WORK REGISTER.                                     *       74960020
*        R15 ECB ADDRESS OR TCBCMP.                             *       75040020
*        R0  1ST LEVEL MSG POINTER.                             *       75120020
*        R1  2ND LEVEL MSG POINTER.                             *       75200020
*OUTPUT* OUTBUF=A(1ST),A(2ND),2ND LVL MSG                       *       75280020
*****************************************************************       75360020
MSGBUILD EQU   *              BUILD 2ND LEVEL MSG,AND SETUP FOR TPUT.   75440020
         L     R14,OUTBUF     OUTBUF WILL CONTAIN THE 2ND LEVEL MSG.    75520020
         ST    R0,X0(R14)     STORE 1ST LEVEL MSG.                      75600020
         LR    R0,R15         SAVE ECB ADDRESS.                         75680020
         LH    R15,X0(R1)     LENGTH OF SECOND LEVEL.                   75760020
         EX    R15,MOVEMSG    MOVE 2ND LEVEL.                           75840020
         LA    R15,X8-X3(R14,R15)  GET ADDR OF END OF 2ND LEVEL MSG.    75920020
         LR    R1,R0          MOVE ECB ADDRESS                          76000020
         UNPK  X0(X3,R15),X1(X2,R1)  UNPACK COMP.CODE.                  76080020
         OI    X2(R15),XF0    PREPARE FOR TRANSLATE.                    76160020
         TR    X0(X3,R15),TABLE-XF0 MAKE PRINTABLE.                     76240020
         LA    R1,X8(R14)     POINT TO 2ND LEVEL.                       76320020
         ST    R1,X4(R14)     SET UP POINTER TO 2ND LVL.                76400020
         LR    R1,R14         READY FOR 'IO'                            76480020
         BR    R11            RETURN.                                   76560020
MOVEMSG  MVC   X8(X0,R14),X0(R1)  MOVE 2ND LEVEL MSG.                   76640020
*******************************************************************     76720020
         SPACE                                                          76800020
*                   CONSTANTS AND DSECTS                                76880020
         SPACE                                                          76960020
         SPACE                                                          77040020
IOCONS   DS    0F             EP'S FOR IKJEGIO1 & IKJEGCVT.             77120020
         DC    V(IKJEGGT)     GETLINE EP                                77200020
         DC    V(IKJEGPT)     PUTLINE EP                                77280020
         DC    V(IKJEGPG)     PUTGET EP                                 77360020
         DC    V(IKJEGCVT)    CONVERT ROUTINE EP.                       77440020
         DC    V(IKJEGBLD)    COMMON ADDRESS BUILD ROUTINE.             77520020
         DC    V(IKJEGSTA)    STAE EXIT ROUTINE ENTRY POINT.            77600020
ATTNEP   DC    V(IKJEGATN)    ATTENTION EXIT ROUTINE ENTRY POINT.       77680020
IKJEGDDM DC    V(IKJEGDDM)    DAIR DISASTER MESSAGE MAKER ROUTINE       77760020
MODE     DC    A(TEST1)            ADDRESS OF TEST MODE MESSAGE.        77840020
         DC    A(0)           *                                         77920020
IOFAIL   DC    A(4)           RC=4 FROM IKJEGIO.                        78000020
ATTNCODE DC    A(16)          RETURN CODE ON ATTENTION INTERRUPT.       78080020
SP1      DC    X'01000000'    SUBPOOL ONE INDICATOR.                    78160020
CORETRN  DC    AL1(1),AL3(12)  CONTROL WORDS FOR SVC INFO BLKS.         78240020
CORE104  DC    AL1(0),AL3(104)  STAE 104 BYTE WORKAREA.                 78320020
CORE6K   DC    AL1(2),AL3(6144)  SUBCOMMAND RESERVE STORAGE             78400020
CORESIB  DC    AL1(1),AL3(16)  SP=1,LENGTH=16  SIB CORE                 78440020
RETRYAD  DC    A(RETRY)       STAE RETRY.                               78480020
BASEAD   DC    A(IKJEGMNL)    MAINLINE ENTRY POINT ADDRESS/BASE         78560020
END      DC    C'END '        SUBCOMMAND CALLED 'END'                   78640020
HELP     DC    C'HELP'        HELP SUBCOMMAND.                          78720020
NAMELIST DC    V(IKJEGSCD)    ADDR OF BEGINNING OF COMMAND TABLE.       78880020
         SPACE                                                          78940020
*        THE FOLLOWING ARE POINTERS TO 1ST AND 2ND LEVEL MESSAGES       79000020
         SPACE                                                          79060020
NORMTERM DC    A(NORMTM1,NORMTM2)  'NORMAL TERMINATION' MESSAGE         79120020
BADVERB  DC    A(CMDMSG1,CMDMSG2)  'INVALID COMMAND'                    79180020
MNMSG1   DC    A(CMDMSG3,CMDMSG4)   'COMMAND NOT SUPPORTED'             79240020
SMTATTN  DS    0X             FOR SMT TEST CASES.                       79270020
TERM0    DC    A(TERM2,TERM3)  'PROGRAM UNDER TEST HAS TERMINATED'      79300020
MHELP    DC    A(MHELP1,MHELP2)  'HELP FAILED'                          79360020
SCFAIL   DC    A(MMAIN1,MSUBC2)   'LINK TO SUBCOMMAND FAILED'           79420020
COREFAIL DC    A(MMAIN1,MCORE2)  'INSUFFICIENT STORAGE'                 79480020
MGNOTRY  DC    A(MGNOTRY1,0)  'NO ACTIVE PROGRAM LEFT TO TEST'          79510020
         SPACE                                                          79540020
AT       DC    A(ATMSG)       FRONT PART OF BREAKPOINT MSG              79600020
OPCDTBAD DC    V(IKJEGCOP)    OP CODE TABLE ADDRESS.                    79760020
SCDNAMES DC    V(IKJEGNAM)    LOAD MODULE NAMES TABLE                   79820020
ATSID    DC    V(IKJEGAID)    AT'S ID                                   79880020
OFFSID   DC    V(IKJEGOID)    OFF'S ID                                  79940020
PATCHSID DC    V(IKJEGPID)    PATCH'S ID                                80000020
TABLE    DC    C'0123456789ABCDEF' TABLE FOR TRANSLATE.                 80080020
TEST1    DC    X'00090000'    LENGTH OF TEST + LENGTH OF THIS WORD.     80160020
         DC    CL1' '         FUDGE                                     80240020
TEST     DC    CL8'TEST'      TEST                                      80320020
FROM     DC    C' FROM '      FROM                                      80400020
FROMLEN  EQU   *-FROM         FROM LENGTH                               80480020
ABEND    DC    C'ABENDB'      ABEND CONSTANT.                           80490020
         SPACE                                                          80500020
*        IC TABLE FOR ABENDS                                            80520020
         SPACE                                                          80540020
ABTAB    DS    0F             ABEND VECTOR TABLE FOR RESIDENT CODE.     80560020
         DC    AL1(SYMCODE),VL3(IKJEGBLO)  LINK TO SYM FAILED.          80640020
         DC    AL1(ATCHCODE),AL3(BLOW3)  ATTACH HELP FAILURE.           80720020
         DC    AL1(CORECODE),AL3(BLOW2)  INSUFFICIENT STORAGE.          80800020
         DC    AL1(SCANCODE),AL3(BLOW1)  LINK TO IKJSCAN FAILED.        80880020
         DC    AL1(DAIRCODE),AL3(BLOWDAIR)  LINK TO DAIR FAILED.        80960020
         DC    AL1(0),AL3(BLOWSC) WILL RETRY, NO MESSAGE PRINTED.       81040020
         DC    X'FFFF'        STOPPER.                                  81120020
CMP106   DC    X'1060'        ABEND COMPLETION CODE 106                 81200020
EIGHT    DC    H'8'           CONSTANT OF EIGHT.                        81240020
         SPACE                                                          81280020
SVC      SVC   TESTSVC        TEST SVC                                  81360020
*TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT           81440020
TESTSVC  EQU   97             TEST'S SVC                                81520020
         SPACE                                                          81540020
*        LIST FORMS                                                     81560020
         SPACE                                                          81580020
         IKJDAP2C                                                       81600020
DA2CLEN  EQU   *              LENGTH                                    81680020
IKJEGMNL CSECT                                                          81760020
DAIR2C   DC    (DA2CLEN-DAPB2C)X'0'  INITIALIZE BEFORE ORGS             81840020
         ORG   DA2CCD-DAPB2C+DAIR2C    *                                81920020
         DC    XL2'002C'      CODE                                      82000020
         ORG   DA2CLEN-DAPB2C+DAIR2C   *                                82080020
LEN2C    EQU   *-DAIR2C       *                                         82160020
STAXLIST DS    0F                                                       82240020
         STAX  STAXLIST,REPLACE=NO,MF=L                                 82320020
STAXLEN  EQU   *-STAXLIST     L FORM LENGTH                             82400020
FREELIST FREEMAIN L,MF=L      *                                         82480020
FRELEN   EQU   *-FREELIST     *                                         82560020
LINKFORM LINK  SF=L                                                     82640020
LINKFMLN EQU   *-LINKFORM     LENGTH.                                   82720020
CLFORM   CLOSE CLFORM,MF=L    *                                         82800020
CLLEN    EQU   *-CLFORM       LENGTH OF CLOSE L-FORM.                   82880020
STAELIST STAE  MF=L           STAE L-FORM.                              82960020
STAELEN  EQU   *-STAELIST     STAE L-FORM LENGTH.                       83040020
NONAME   DSECT                                                          83120020
ATTCHLFM ATTACH EP=IKJEFH01,SF=L *                                      83200020
ATTCHLLN EQU   *-ATTCHLFM     *                                         83280020
IKJEGMNL CSECT                                                          83360020
ZERO     DC    F'0'           ZERO                                      83440020
TCBTRNFL DC    X'10000000'    INDICATE CHANGE TCBTRN FIELD.             83520020
ICCHANGE DC    X'08000000'    IC CHANGE INDICATOR.                      83600020
RGCHANGE DC    X'04000000'    CHANGE PP REGS CODE.                      83680020
WAITOFF  DC    X'01000000'    CODE FOR SVC97 TO ZERO WAIT CNT.          83720020
ALLREGS  DC    X'FF000000'    CHANGE ALL PP REGS.                       83760020
CHANGE14 DC    X'0E000000'    CHANGE REGISTER 14                        83840020
POST7F   DC    X'3F000000'    POST CODE OF '7F'                         83920020
         SPACE                                                          83940020
*        EQUATES                                                        83960020
         SPACE                                                          83980020
RBGRSAVE EQU   32             GR SAVE IN RB                             84000020
RBGR14   EQU   RBGRSAVE+56    REGISTER 14 SAVE IN SVRB                  84080020
RBAPSW   EQU   4              APSW FIELD IN RB.                         84160020
RBSIZE   EQU   9              SIZE OF RB.                               84180020
RBWCF    EQU   28             WAIT COUNT.                               84200020
RBLINK   EQU   28             RB LINK FIELD DISPLACEMENT.               84240020
RBOPSW   EQU   16             RESUME PSW DISPLACEMENT IN RB.            84320020
RBOPSW2W EQU   RBOPSW+4       2ND WORD OF RBOPSW.                       84400020
RBOPSWIC EQU   RBOPSW+5       IC OF RBOPSW                              84480020
RBSTAB   EQU   10             DISP OF STATUS BITS IN RB.                84560020
RBCDE    EQU   12             *                                         84640020
RBEXSAVE EQU   96             RB EXTENDED SAVE AREA ADDRESS.            84720020
CDNAME   EQU   8              *                                         84800020
CDENTPT  EQU   17             CDE EPA                                   84840020
CDEATR1  EQU   0              *                                         84880020
MINORBIT EQU   X'04'          *                                         84960020
CDATTR2  EQU   20             CDE ATTRIBUTES NO. TWO                    84980020
CDOBJBIT EQU   X'80'          LOADED BY THE OSLOADER                    85000020
CDOVLBIT EQU   X'04'          INDICATES OVERLAY PROGRAM.                85020020
CDEXLMJ  EQU   20             *                                         85040020
LLSNE    EQU   0              *                                         85120020
XLADR    EQU   8              *                                         85200020
XLNUM    EQU   4              EXTENT LIST ADDRESS.                      85280020
SCANCODE EQU   10             LINK TO IKJSCAN FAILED.                   85360020
DAIRCODE EQU   9              LINK TO DAIR FAILED                       85440020
SYMCODE  EQU   8              LINK TO IKJEGSYM FAILED                   85520020
ATCHCODE EQU   5                                                        85600020
PARSCODE EQU   3              LINK TO PARSE FAILED                      85680020
CORECODE EQU   1                                                        85760020
X0       EQU   0              HEXIDECIMAL 0                             85840020
X1       EQU   1              HEXIDECIMAL 1                             85920020
X2       EQU   2              HEXIDECIMAL 2                             86000020
X3       EQU   3              HEXIDECIMAL 3                             86080020
X4       EQU   4              HEXIDECIMAL 4                             86160020
X5       EQU   5              HEXIDECIMAL 5                             86240020
X6       EQU   6              HEXIDECIMAL 6                             86320020
X7       EQU   7              HEXIDECIMAL 7                             86400020
X8       EQU   8              HEXIDECIMAL 8                             86480020
X9       EQU   9              HEXIDECIMAL 9                             86560020
N10      EQU   10             NUMBER 10                                 86600020
N12      EQU   12             TWELVE                                    86640020
N13      EQU   13             THIRTEEN.                                 86720020
N14      EQU   14             FOURTEEN.                                 86800020
N15      EQU   15             FIFTEEN.                                  86880020
N16      EQU   16             SIXTEEN                                   86960020
N17      EQU   17             SEVENTEEN.                                87040020
N18      EQU   18             EIGHTEEN.                                 87120020
N20      EQU   20             TWENTY.                                   87200020
N23      EQU   23             TWENTY THREE.                             87280020
N24      EQU   24             TWENTY FOUR.                              87360020
N25      EQU   25             TWENTY FIVE.                              87440020
N28      EQU   28             TWENTY EIGHT.                             87520020
N35      EQU   35             THIRTY FIVE.                              87600020
N38      EQU   38             THIRTY EIGHT.                             87680020
N43      EQU   43             FORTY THREE.                              87760020
N64      EQU   64             SIXTY FOUR.                               87840020
N160     EQU   160            ONE SIXTY                                 87920020
N1024    EQU   1024           ONE K.                                    88000020
N2048    EQU   2048           TWO K.                                    88080020
X10      EQU   X'10'                                                    88160020
X40      EQU   X'40'          BLANK,POST FLAG,OR HEX 40                 88240020
X80      EQU   X'80'          HEXIDECIMAL 80                            88320020
X88      EQU   X'88'          DISPLACEMENT OF C'ABEND' IN SVRB.         88360020
XC0      EQU   X'C0'          HEXIDECIMAL C0                            88400020
XF0      EQU   X'F0'          HEXIDECIMAL F0                            88480020
XF8      EQU   X'F8'          HEXIDECIMAL F8                            88560020
XFF      EQU   X'FF'          HEXIDECIMAL FF                            88640020
Z        EQU   8              ZERO CODITION CODE.                       88720020
ONES     EQU   1              ONES CONDITION CODE.                      88740020
STACKLST STACK MF=L                                                     88760020
STACKLEN EQU   *-STACKLST                                               88780020
EQ       EQU   8              EQUAL CONDITION CODE.                     88800020
NE       EQU   7              NE CONDITION CODE.                        88880020
NZ       EQU   7              NZ CONDITION CODE.                        88960020
NEG      EQU   4              NEGATIVE CONDITION.                       89040020
PLUS     EQU   C'+'           PLUS SIGN                                 89120020
CHARH    EQU   C'H'           CHARACTER 'H'                             89160020
         BRKELEM                                                        89200020
         SPACE                                                          89280020
         TSTCWORK                                                       89360020
         SPACE                                                          89440020
         TCOMTAB                                                        89520020
PPEXIT2H EQU   PPEXIT+2       2ND HALF WORD OF PPEXIT                   89600020
HLPLIST  EQU   ECBLIST+4      HELP'S ECBS                               89680020
         SPACE                                                          89760020
         IKJTPL                                                         89840020
         SPACE                                                          89920020
         IKJTCB                                                         90000020
         SPACE                                                          90080020
         IKJECT                                                         90160020
         SPACE                                                          90240020
         IKJCSOA                                                        90320020
*        COMMAND SCAN                                                   90400020
         IKJCSPL                                                        90480020
*        DEFAULT                                                        90560020
         IKJDFPL                                                        90640020
*        DEFAULT                                                        90720020
         IKJDFPB                                                        90800020
*        DAIR                                                           90880020
         IKJDAP08                                                       90960020
*        DAIR                                                           91040020
         IKJDAP1C                                                       91120020
*        DAIR                                                           91200020
         IKJDAP18                                                       91280020
*        DAIR                                                           91360020
         IKJDAPL                                                        91440020
         REGEQU                                                         91520020
IKJEGXNL CSECT                                                          91600020
         SPACE                                                          91640020
*        MESSAGES USED BY THE TEST MAINLINE MONITOR MODULE.             91680020
         SPACE                                                          91760020
TERM2    EQU   *              *                                         92400020
         DC    AL2(TERM2L,0)  *                                         92480020
         DC    C'IKJ57025I '  *                                         92560020
         DC    C'PROGRAM UNDER TEST HAS TERMINATED+'  *                 92640020
TERM2L   EQU   *-TERM2        *                                         92720020
         DS    0H             *                                         92800020
TERM3    EQU   *              *                                         92880020
         DC    AL2(TERM3L,0)  *                                         92960020
         DC    C'IKJ57025I '  *                                         93040020
         DC    C'BREAKPOINTS ARE NO LONGER VALID.'          *           93120020
TERM3L   EQU   *-TERM3        *                                         93200020
         DS    0H             *                                         93280020
ATMSG    EQU   *              *                                         93360020
         DC    AL2(ATMSGL),X'0000' *                                    93440020
         DC    C'IKJ57024I AT '    *                                    93520020
ATMSGL   EQU   *-ATMSG             *                                    93600020
         DS    0H                  *                                    93680020
CMDMSG1  EQU   *                                                        93760020
         DC    AL2(CMDMSG1L)  *                                         93840020
         DC    2X'0'          *                                         93920020
         DC    C'IKJ57021I '  *                                         94000020
         DC    C'INVALID COMMAND+'   *                                  94080020
CMDMSG1L EQU   *-CMDMSG1      *                                         94160020
         DS    0H             *                                         94240020
CMDMSG2  EQU   *                                                        94320020
         DC    AL2(CMDMSG2L)  *                                         94400020
         DC    2X'0'          *                                         94480020
         DC    C'IKJ57021I '  *                                         94560020
         DC    C'THE FIRST FIELD OF THE COMMAND ENTERED IS NOT A COMMANC94640020
               D IN TEST MODE'                                          94720020
CMDMSG2L EQU   *-CMDMSG2      *                                         94800020
*                                                                       94880020
         DS    0H             *                                         94960020
CMDMSG3  EQU   *                                                        95040020
         DC    AL2(CMDMSG3L)  *                                         95120020
         DC    2X'0'          *                                         95200020
         DC    C'IKJ57022I COMMAND NOT SUPPORTED+'  *                   95280020
CMDMSG3L EQU   *-CMDMSG3      *                                         95360020
         DS    0H             *                                         95440020
CMDMSG4  EQU   *                                                        95520020
         DC    AL2(CMDMSG4L)  *                                         95600020
         DC    2X'0'          *                                         95680020
         DC    C'IKJ57022I THE COMMAND ENTERED IS NOT SUPPORTED' *      95760020
         DC    C' IN TEST MODE IN THIS SYSTEM' *                        95840020
CMDMSG4L EQU   *-CMDMSG4      *                                         95920020
         DS    0H             *                                         96000020
NORMTM1  EQU   *              *                                         96080020
         DC    AL2(NORMTM1L)  *                                         96160020
         DC    2X'0'          *                                         96240020
         DC    C'IKJ57023I '  *                                         96320020
         DC    C'PROGRAM UNDER TEST HAS TERMINATED NORMALLY+' *         96400020
NORMTM1L EQU   *-NORMTM1      *                                         96480020
         DS    0H             *                                         96560020
NORMTM2  EQU   *              *                                         96640020
         DC    AL2(NORMTM2L)  *                                         96720020
         DC    2X'0'          *                                         96800020
         DC    C'IKJ57023I '  *                                         96880020
         DC    C'BREAKPOINTS SET ARE STILL VALID.'          *           96960020
NORMTM2L EQU   *-NORMTM2      *                                         97040020
MMAIN1   DC    Y(MMAIN1L,0),C'IKJ57026I '  *                            97120020
         DC    C'TEST ENDED DUE TO ERROR+' *                            97200020
MMAIN1L  EQU   *-MMAIN1                                                 97280020
MSUBC2   DC    Y(MSUBC2L,0),C'IKJ57026I LINK TO SUBCOMMAND FAILED.' *  *97360020
               COMMENT                                                  97440020
MSUBC2L  EQU   *-MSUBC2                                                 97520020
MCORE2   DC    Y(MCORE2L,0),C'IKJ57026I INSUFFICIENT STORAGE' *         97600020
MCORE2L  EQU   *-MCORE2                                                 97680020
MHELP1   DC    Y(MHELP1L,0),C'IKJ57027I HELP FAILED+' *                 97760020
MHELP1L  EQU   *-MHELP1       *                                         97840020
MHELP2   DC    Y(MHELP2L,0),C'IKJ57027I ABEND CODE SYSTEM=' *           97920020
MHELP2L  EQU   *-MHELP2+3     *                                         98000020
MGNOTRY1 DC    Y(MGNOTRYL,0),C'IKJ57028I NO ACTIVE PROGRAM LEFT' 1LVL   98020020
MGNOTRYL EQU   *-MGNOTRY1     LENGTH.                                   98040020
LAST     EQU   *                                                        98080020
         END                                                            98160020
