         TITLE 'IKJEGOFF, ''OFF'' SUBCOMMAND OF TEST'                   00060020
         SPACE 2                                                        00112020
************************************************************            00120020
*                                                         **            00170020
* STATUS                                                  **            00180020
*    CHANGE LEVEL 000                                     **            00230020
*                                                         **            00240020
* FUNCTION                                                **            00300020
*    OFF BASICALLY REMOVES WHATEVER BREAKPOINTS THE 'AT'  **            00350020
*    SUB-COMMAND HAD ESTABLISHED. IT HAS THE FACILITY TO  **            00360020
*    REMOVE ALL THE BREAKPOINTS IN EFFECT, OR ONLY THOSE  **            00420020
*    SPECIFIED BY THE USER.                               **            00480020
*    PARSE IS USED TO SCAN WHATEVER ADDRESS PARAMETERS    **            00600020
*    ARE USED WITH OFF. IF NONE, THEN ALL BREAKPOINTS ARE **            00660020
*    REMOVED.                                             **            00720020
*    WHEN PARSE RETURNS WITH A VALID ADDRESS, BREAKTAB,   **            00780020
*    FOUND IN TCOMTAB, IS TESTED. IF IT IS ZERO, THERE    **            00840020
*    ARE NO BREAKPOINTS. IF OTHER THAN ZERO, THE          **            00900020
*    BREAKPOINT QUEUE IS ACCESSED AND THE ORIGINAL        **            00960020
*    INSTRUCTIONS ARE PUT BACK.                           **            01080020
*    ONCE THE BREAKPOINT QUEUE HAS BEEN PROCESSED,        **            01140020
*    THE DEFERRED QUEUE IS ACCESSED VIA DEFERTAB (FOUND   **            01200020
*    IN TCOMTAB). IF DEFERTAB IS ZERO, NONE EXISTS.       **            01260020
*    IF A DEFERRED QUEUE DOES EXIST, IT IS SEARCHED BY    **            01320020
*    COMPARING LOADNAMES. (A FULLY QUALIFIED ADDRESS      **            01380020
*    MUST HAVE BEEN SPECIFIED). WHEN A BREAK ELEMENT IS   **            01440020
*    FOUND, IT IS CLEARED.                                **            01500020
*    IF DURING THE EXECUTION OF THE PROBLEM PROGRAM, A    **            01560020
*    BREAKPOINT IS ENCOUNTERED, IT WILL BE REMOVED BY     **            01620020
*    ACCESSING THE OLD PSW FOUND IN THE RB. WITH THE      **            01680020
*    INSTRUCTION COUNTER (FOUND IN THE RB), THE           **            01740020
*    ORIGINAL INSTRUCTION MAY NOW BE PUT BACK.            **            01800020
*                                                         **            01920020
* ENTRY POINTS                                            **            01980020
*         IKJEGOFF - MAIN ENTRY POINT                     **            02030020
*         ADDRVLCK -VALIDITY CHECK ROUTINE                **            02040020
*                                                         **            02100020
* INPUT                                                   **            02150020
*    ONE OR MORE LINES OF INPUT FROM THE TERMINAL INTO    **            02152020
*    THE INPUT BUFFER.                                    **            02154020
*                                                         **            02154420
* OUTPUT                                                  **            02156020
*    1.  ERROR MESSAGES TO THE MESSAGE WRITER             **            02158020
*    2.  RETURN CODES                                     **            02158420
*    *          00 - SUCCESSFUL COMPLETION OR BREAKPOINTS **            02158820
*    *               NOT REMOVED                          **            02159220
*    *          08 - HAVE PARSE ISSUE A 'REENTER'         **            02159320
*    *          12 - PARSE VALIDITY CHECK EXIT ERROR      **            02159420
*    *               RETURN CODE                                        02159520
*    *          16 - AN ATTENTION HAS BEEN SCHEDULED      **            02159620
*    *          20 - STAE RETRY HAS INTERCEPTED AN ABEND  **            02174720
*                                                         **            02189820
* EXTERNAL REFERENCES                                     **            02204920
*         IKJPARS - CHECKS SYNTAX OF ADDRESSES            **            02220020
*                                                         **            02280020
*         IKJEGIO - PRINTS ERROR MESSAGES.  AT ENTRY,     **            02340020
*         *         REGISTER ONE CONTAINS THE ADDRESS OF  **            02400020
*         *         THE OUTPUT BUFFER.                    **            02450020
*                                                         **            02452020
*         IKJEGCVT - CONVERTS AN ABSOLUTE ADDRESS, AN     **            02454020
*         *          EXPRESSION, AN INDIRECT ADDRESS, OR  **            02456020
*         *          A FULLY QUALIFIED ADDRESS TO BINARY. **            02458020
*         *          AT ENTRY, REG 1 CONTAINS THE         **            02458420
*         *          COMPLEMENT OF THE PDL ADDRESS TO     **            02458820
*         *          INDICATE AN ADDRESS CONVERSION, AND  **            02459220
*         *          REG 0 IS SET NEGATIVE TO INDICATE    **            02459620
*         *          CONVERT TO BINARY.                   **            02459720
*                                                         **            02460020
* EXITS,NORMAL                                            **            02520020
*          RETURN TO MAINLINE VIA REGISTER 14             **            02580020
*                                                         **            02640020
* EXITS,ERROR                                             **            02690020
*          RETURN TO MAINLINE VIA REGISTER 14             **            02692020
*                                                         **            02694020
* TABLES/WORK AREAS                                       **            02696020
*    TCOMTAB -                                            **            02698020
*    *     BREAKTAB - PTR TO ACTIVE BREAK ELEMENTS        **            02698420
*    *     DEFERTAB - PTR TO DEFERRED BREAK ELEMENTS      **            02698820
*    WORKDSCT - OFF'S WORKAREA                            **            02699220
*                                                         **            02699620
* ATTRIBUTES                                              **            02700020
*    REENTRANT AND REFRESHABLE                            **            02750020
*                                                         **            02760020
* CHARACTER CODE DEPENDENCY                               **            02820020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL**            02830020
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS**            02840020
*    EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE     **            02850020
*    CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF     **            02860020
*    'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN **            02870020
*    A CORRECT MODULE FOR THE NEW DEFINITIONS.            **            02872020
*                                                         **            02872420
* NOTES                                                   **            02874020
*                                                         **            02880020
************************************************************            02940020
         EJECT                                                          02990020
IKJEGOFF CSECT                                                          02992020
         SPACE 2                                                        02994020
************************************************************            03000020
** THIS IS THE BEGINNING POINT OF 'OFF'. REGISTERS WILL   **            03060020
** BE SAVED AND ADDRESSABILITY ESTABLISHED. FORWARD AND   **            03120020
** BACKWARD POINTERS WILL BE PLACED IN RESPECTIVE         **            03180020
** SAVEAREAS. WE WILL LINK TO PARSE TO SCAN OFF PARAMETERS**            03240020
** AND VALIDITY CHECK THE ADDRESSES IF ANY ARE RECEIVED   **            03300020
************************************************************            03360020
         SPACE                                                          03410020
         ENTRY IKJEGVCK                                                 03420020
         SAVE  (14,12)       SAVE REGISTERS USING SAVE MACRO            03480020
         SPACE                                                          03530020
         LR    R11,R15       PLACE ENTERING ADDRESS INTO R11            03540020
         USING IKJEGOFF,R11  USE ENTERING ADDRESS FOR ADDRESSING        03600020
         USING TCOMTAB,R9    USE REG9 TO ADDRESS TCOMTAB                03660020
         USING TCB,R1        USE REG1 TO ADDRESS TCB                    03720020
         USING RBSECT,R7     USE REG7 TO ADDRESS RB DSECT               03780020
         SPACE                                                          03830020
         L     R4,REGSAVE2   GET ADDRESS OF OFF'S SAVEAREA FROM TCOM    03840020
         ST    R4,@8(R13)    PASS TO CALLER OFF'S SAVEAREA ADDR         03900020
         ST    R13,@4(R4)    STORE USER SAVEAREA ADDRESS INTO           03960020
*                            OFF'S SAVEAREA                             04020020
         LR    R13,R4        PUT PTR TO OFF'S SAVE AREA INTO REG13      04080020
         STM    @14,@12,@12(R13) SAVE OFF'S REGISTERS                   04140020
         SPACE                                                          04190020
         MVC   TSTRETRY+@1(@3),ARETRY PLACE RETRY ADDRESS INTO TCOMTAB  04200020
         LA    R10,STAETAB   PLACE ADDRESS OF STAE TABLE IN R10         04260020
         ST    R10,ABENTAB1  PLACE STAE TABLE ADDRESS INTO TCOMTAB      04320020
         SPACE                                                          04330020
         L     R2,WORKAREA   PLACE POINTER TO WORKAREA INTO REG 10      04340020
         USING TSTCWORK,R2   ESTABLISH ADDRESSABILITY                   04360020
         LA    R2,CWORKCMD   R10 = ADDRESS OF OFF'S WORKAREA            04380020
         DROP  R2            DROP TEST'S WORKAREA POINTER               04400020
         USING WORKDSCT,R2   SET UP ADDRESSABILITY TO OFF'S WORKAREA    04420020
         SPACE                                                          04440020
         MVC   WORKLST(@12),LISTSTAE   MOVE LIST FORM OF STAE INTO      04460020
*                                      WORKAREA                         04480020
         L     R3,TSTSTAE    GET STAE'S ADDRESS FROM TCOMTAB            04500020
         LA    R4,WORKLST          GET ADDR OF LIST FOR STAE            04530020
         SPACE                                                          04540020
         STAE  (R3),MF=(E,(R4))    ISSUE STAE                           04560020
         SPACE                                                          04610020
         LTR   R15,R15       CHECK FOR RETURN CODE ZERO                 04680020
SMTSTAE  DS    0H            SMT TEST LABEL FOR STAE MACRO              04730020
         BZ    CKENDSW       RETURN CODE = ZERO                         04740020
         SPACE                                                          04800020
NOROOM   EQU   *             EQUATE LABEL TO THIS ADDRESS               05160020
         L     R1,MSSG10     PLACE INSUFFICIENT STORAGE MSG IN R1       05220020
PRINTMSG EQU   *             EQUATE LABEL TO THIS ADDRESS               05280020
         B     PUTMSG        GO PUT OUT ERROR MESSAGE                   05340020
         SPACE                                                          05400020
CKENDSW  EQU   *             EQUATE LABEL TO THIS ADDRESS               05460020
         TM    TSTFLGS1,ENDSW    CHECK IF IN END PROCESSING             05520020
         BNO   @00002        IF NOT THEN BRANCH TO PARSE INPUT LINE     05580020
         SPACE                                                          05581020
         LA    R1,DCBSAVE    POINTER TO SAVE AREA FOR DCB ADDRESS       05582020
         MVC   ZERO(CLOSELN,R1),CLOSELST  MOVE CLOSE LIST TO WORKAREA   05583020
         SPACE                                                          05584020
         L     R4,TSTIODCB   GET POINTER TO I/O DCB                     05585020
         LTR   R4,R4         CHECK IF I/O DCB IS OPEN                   05586020
         BZ    SYM           BRANCH IF NOT                              05587020
         XC   TSTIODCB,TSTIODCB       CLEAR OUT DCB ADDRESS ENTRY       05587420
         SPACE                                                          05588020
         CLOSE ((R4)),MF=(E,(1))      CLOSE I/O DCB                     05589020
         SPACE                                                          05590020
         FREEPOOL (4)         FREE QSAM BUFFERS                         05590420
         SPACE                                                          05590820
         FREEMAIN R,LV=152,A=(4),SP=1     FREE I/O DCB                  05591020
         SPACE                                                          05594020
SYM      L     R3,TSTSYMWK   GET POINTER TO SYMBOL WORKAREA             05595020
         LTR   R3,R3         DOES SYMBOL PROCESSING WORKAREA EXIST      05596020
         BZ    OUT           BRANCH IF NOT                              05597020
         SPACE                                                          05598020
         L     R4,@72(R3)    GET POINTER TO SYMBOL DCB                  05599020
         TM    DCBOFLGS(R4),HEX10  IS SYMBOL DCB OPEN                   05600020
         BZ    FREEWK         BRANCH IF NOT                             05600720
         XC   TSTSYMWK,TSTSYMWK    CLEAR SYMBOL WORKAREA POINTER        05601420
         SPACE                                                          05602020
         LA    R1,DCBSAVE    POINTER TO SAVE AREA FOR DCB               05603020
         MVC   ZERO(CLOSELN,R1),CLOSELST  MOVE CLOSE LIST TO WORKAREA   05604020
         SPACE                                                          05605020
         CLOSE ((R4)),MF=(E,(1))   CLOSE SYMBOL WORKAREA DCB            05606020
         SPACE                                                          05607020
FREEWK   FREEMAIN R,LV=800,A=(3),SP=1     FREE SYMBOL WORKAREA          05609020
         SPACE                                                          05611020
         DROP  R2                                                       05612020
OUT      EQU   *                                                        05613020
         L     R1,TSTIODSN   PLACE POINTER TO IO DSN AREA IN R1         05640020
         LTR   R1,R1         SEE IF AN AREA EXISTS                      05700020
         BZ    @001B2        IF NOT, BRANCH TO FREE ELEMENTS            05760020
         SPACE                                                          05810020
@00001   EQU   *             EQUATE LABEL TO THIS ADDRESS               05820020
         L     R2,@0(R1)     PLACE POINTER TO NEXT AREA INTO R2         05880020
         FREEMAIN R,LV=50,SP=1,A=(1) ISSUE FREEMAIN                     05940020
         SPACE                                                          05990020
         LTR   R2,R2         SEE IF ANOTHER AREA EXISTS                 06000020
         BZ    @001B2        IF NO MORE THEN BRANCH TO FREE ELEMENTS    06060020
         LR    R1,R2         OTHERWISE PLACE POINTER INTO R1            06120020
         B     @00001        AND BRANCH TO FREE THIS AREA               06180020
         SPACE                                                          06230020
@00002   EQU   *             EQUATE LABEL TO THIS ADDRESS               06240020
         TM    TSTFLGS3,NOPARMS SEE IF ANY PARAMETERS WERE ENTERED      06300020
         BO    @001B2        IF NOT, THEN SKIP PARSE                    06360020
         SPACE                                                          06460020
         L     R2,WORKAREA   GET ADDRESS OF WORKAREA                    06500020
         USING TSTCWORK,R2   ESTABLISH ADDRESSABILITY                   06540020
         LA    R2,CWORKCMD   POINTER TO OFF'S WORKAREA                  06580020
         DROP  R2            DROP TEST'S WORKAREA BASE                  06620020
         USING PPLUPT,R2     SET UP ADDRESSABILITY TO PARSE             06660020
*                            PARAMETER LIST                             06720020
         SPACE                                                          06780020
         MVC   PPLUPT(@4),TSTUPT      MOVE UPT INTO WORKAREA            06840020
         MVC   PPLECT(@4),TSTECT      MOVE ECT INTO WORKAREA            06900020
         MVC   PPLECB(@4),TSTCPECB    MOVE CPECB INTO WORKAREA          06960020
         MVC   PPLPCL(@4),PCLISTA     MOVE ADDRESS OF PCL               07020020
         LA    R3,TSTANSPL            GET POINTER TO ANSWER PLACE       07030020
         ST    R3,PPLANS              PUT INTO PARAMETER LIST           07040020
         MVC   PPLCBUF(@4),INBUF      MOVE POINTER TO COMMAND BUFFER    07070020
         ST    R13,PPLUWA             STORE POINTER TO OFF'S SAVE AREA  07072020
         SPACE                                                          07074020
         LR    R1,R2         PLACE PARM LIST ADDR INTO R1               07080020
         SPACE                                                          07090020
         DROP  R2            DROP PARAM LIST BASE                       07100020
         USING WORKDSCT,R2   SET UP ADDRESSABILITY TO WORKAREA          07110020
         SPACE 2                                                        07130020
************************************************************            07140020
**  OFF NOW LINKS TO PARSE WITH THE ADDRESS OF THE PARSE  **            07200020
**  PARAMETER LIST IN REGISTER 1.  THE ADDRESS VALIDITY   **            07260020
**  CHECKING WILL BE DONE BY CONVERT AND SYM, VIA OFF.    **            07320020
************************************************************            07500020
         SPACE                                                          07550020
         LINK  EP=IKJPARS    GO TO PARSE TO GET SCANNING DONE           07560020
SMTPARS  DS    0H            SMT TEST LABEL FOR PARSE LINK MACRO        07570020
         SPACE                                                          07610020
BLOWUP1  EQU   *             EQUATE LABEL IN CASE OF ABEND              07620020
         SPACE                                                          07650020
         LA    R3,BRTAB      GET ADDRESS OF BRANCH TABLE                07680020
         B     ZERO(R3,R15)  USE RETURN CODE IN REG 15                  07710020
*                            AS AN INDEX TO THE BRANCH TABLE            07740020
BRTAB    B     @0000A        PARSE RETURN CODE = 0                      07800020
         B     @000021       PARSE RETURN CODE = 4                      07860020
         B     @00003        PARSE RETURN CODE = 8                      07920020
         B     @000031       PARSE RETURN CODE = 12                     07980020
         B     @00004        PARSE RETURN CODE = 16                     08040020
         B     @00005        PARSE RETURN CODE = 20                     08100020
         SPACE                                                          08160020
@000021  OI    TSTFLGS4,TSTFLUSH   INITIALIZE STACK FLUSH               08210020
*                                  FOR MAINLINE                         08260020
         B     @003E5        RETURN TO MAINLINE                         08310020
         SPACE                                                          08460020
@00003   EQU   *             EQUATE LABEL FOR RETURN CODE = 8           08520020
         LA    R15,@16       SET ATTENTION SCHEDULED CODE               08580020
         B     @003E6        RETURN TO MAINLINE                         08640020
         SPACE                                                          08700020
@000031  EQU   *             RETURN CODE = 12                           08760020
         L     R1,PARSERR1   SET UP FOR ERROR CODE 12 MESSAGE           08810020
         B     PUTMSG        PUT OUT MESSAGE AND RETURN                 08812020
         SPACE                                                          08820020
@00004   EQU   *             RETURN CODE = 16                           08870020
         L     R1,PARSERR2   PLACE ERROR MESSAGE INTO R1                08880020
         SPACE                                                          08940020
PUTMSG   EQU   *             I/O INTERFACE                              08950020
         LCR   R1,R1         MAKE REGISTER NEGATIVE TO INDICATE         08960020
*                            ERROR MESSAGE                              08970020
         L     R15,TPUTADDR  GET ADDRESS OF IKJEGIO                     08980020
         BALR  R14,R15       GO PUT OUT MESSAGE                         08982020
         SPACE                                                          08990020
         STC   R15,CONVRTCD  SAVE RETURN CODE                           08992020
         CLI   CONVRTCD,@16  WAS I/O RETURN CODE 0, 4, 8 OR 12          08992420
         BL    @003E5        YES...RETURN TO MAINLINE WITH              08992820
*                            A RETURN CODE OF 0                         08993220
         SPACE                                                          08994020
@00005   EQU   *             PARSE RETURN CODE = 20                     08996020
         CLI   CONVRTCD,@16  GET RETURN CODE SAVED FROM                 08998020
*                            VALIDITY EXIT (OR FROM I/O)                08998420
         BE    @00003        IF 16, SET RETURN CODE FOR                 08998820
*                            ATTENTION SCHEDULED                        08999220
         SPACE                                                          08999620
RC20     LA    R15,@20       ELSE, SET RETURN CODE TO 20 FOR            08999720
*                            MAINLINE                                   08999820
         B     @003E6        RETURN TO MAINLINE                         08999920
         EJECT                                                          09019920
@0000A   EQU   *             EQUATE LABEL TO THIS ADDRESS               09040020
         USING IKJPARMA,R3   USE REG 3 TO ADDRESS PDE FOR OFF           09060020
         L     R3,TSTANSPL   GET ADDRESS OF PDE FROM TCOMTAB            09120020
         LA    R3,@8(R3)     ADVANCE ADDRESS TO POINT TO PDE            09180020
@000A0   EQU   *             EQUATE LABEL TO THIS ADDRESS               09240020
         USING IKJPARMA,R3   USE REG3 TO ADDRESS PARSE PDE              09300020
         SPACE                                                          09350020
************************************************************            09360020
**  A CHECK IS MADE TO DETERMINE IF ANY QUEUE ELEMENTS    **            09420020
** WERE SPECIFIED WITH THE OFF COMMAND.  IF NOT, ALL      **            09480020
** ELEMENTS ARE REMOVED FROM THE BREAKTAB QUEUE AND THE   **            09540020
** DEFERTAB QUEUE.                                        **            09600020
************************************************************            09660020
         SPACE                                                          09710020
         L     R5,PDEUSER    PLACE USERWORD FROM PDE INTO R5            09720020
         LTR   R5,R5         SEE IF SYM RESOLVED THE ADDRESS            09780020
         BH    @000A01       IF NOT NEG THEN THIS IS THE ADDRESS        09840020
         L     R5,@0(R5)     PLACE ACTUAL ADDRESS INTO R5               09900020
         ST    R5,PDEUSER    PLACE ADDRESS INTO USERWORD                09960020
         SPACE                                                          10010020
@000A01  EQU   *             EQUATE LABEL TO THIS ADDRESS               10020020
         LA    R5,@0(R5)     ZERO OUT HIGH ORDER BYTE OF ADDRESS        10080020
         LTR   R5,R5         WE MUST CHECK FOR AN ABSOLUTE ADDRESS      10140020
         BNZ   CONTINUE      CONTINUE IF ONE EXISTS                     10200020
         SPACE                                                          10250020
         TM    PDEFLG1,HEX80 SEE IF A LOADNAME WAS ENTERED              10260020
         BO    @007A1        IF IT WAS THEN BRANCH TO CHECK DEFER       10320020
         B     @004A2        BRANCH TO CHECK WHAT TO DO                 10380020
         SPACE                                                          10440020
@001B2   EQU   *             EQUATE LABEL TO THIS ADDRESS               10500020
         L     R4,BREAKTAB   GET PTR TO FIRST ACTIVE BREAK ELEMENT      10560020
@001B1   LTR   R4,R4         CHECK IF BREAK ELEMENT IS PRESENT          10620020
         BZ    @011A1        IF NOT, GO CHECK DEFER QUEUE               10680020
         LR    R3,R4         PLACE POINTER TO BREAK ELEMENT IN R3       10740020
         USING BRKELEM,R3    USE REG3 TO ADDRESS BREAK ELEMENT Q        10800020
         SPACE                                                          10850020
@001B4   EQU   *             EQUATE LABEL TO THIS ADDRESS               10860020
         L     R3,BRKLINK    PLACE POINTER TO NEXT ELEMENT IN R3        10920020
         LTR   R3,R3         ARE THERE ANY MORE ELEMENTS LEFT           10980020
         BZ    @001B6        IF NOT THEN BRANCH                         11040020
         SPACE                                                          11090020
@001B5   EQU   *             EQUATE LABEL TO THIS ADDRESS               11100020
         ST    R3,BREAKTAB   UPDATE BREAKTAB TO REFLECT THE CHANGE      11270020
         BAL   R14,REMOVAL   BRANCH TO REMOVE THIS BREAK ELEMENT        11280020
         LR    R4,R3         PLACE POINTER TO NEXT ELEMENT IN R4        11340020
         B     @001B4        BRANCH TO PROCESS                          11460020
         SPACE                                                          11510020
@001B6   EQU   *             EQUATE LABEL TO THIS ADDRESS               11520020
         ST    R3,BREAKTAB   UPDATE BREAKTAB                            11580020
         BAL   R14,REMOVAL   BRANCH TO REMOVE ELEMENT                   11640020
         B     @011A1        BRANCH TO CHECK DEFERRED QUEUE             11700020
         SPACE                                                          11750020
         DROP  R3                                                       11760020
         USING IKJPARMA,R3   USE REG3 TO ADDRESS PARSE'S PDE            11820020
         EJECT                                                          12350020
************************************************************            12540020
**  IN ORDER TO DETERMINE WHETHER A RANGE OF ADDRESSES OR **            12600020
**  A LIST OF ADDRESSES WAS SPECIFIED, THE 2ND PDE IS     **            12660020
**  CHECKED. (WHEN 'RANGE' AND 'LIST' ARE SPECIFIED IN    **            12720020
**  THE IKJPOSIT MACRO, A DOUBLE PDE IS CREATED WITH A    **            12780020
**  CHAIN WORD AS THE LAST ENTRY.)  IF THE 2ND PDE IS     **            12840020
**  ZERO, ONLY A SINGLE ADDRESS OR A LIST WAS SPECIFIED.  **            12900020
**  IF THE CHAIN WORD IS X'FF000000', A SINGLE ADDRESS    **            12960020
**  WAS SPECIFIED.                                        **            13010020
************************************************************            13020020
         SPACE                                                          13070020
CONTINUE EQU   *             EQUATE LABEL TO THIS ADDRESS               13072020
         L     R4,BREAKTAB   GET PTR TO ACTIVE QUEUE                    13072420
         XR    R10,R10       ZERO OUT REG 10 TO USE AS FORWARD POINTER  13074020
         SPACE                                                          13076020
         LA    R8,PDECHAIN   PLACE ADDRESS OF SECOND PDE IN R3          13080020
*                            FOLLOWING THE FIRST PDE                    13140020
         DROP  R3            DROP R3 AS A POINTER TO PDE                13200020
         USING IKJPARMA,R8   USE R8 AS PDE POINTER                      13260020
         SPACE                                                          13320020
         L     R6,PDEUSER    GET ADDRESS POINTER FROM SECOND PDE        13380020
         LTR   R6,R6         IF ZERO, A RANGE DOES NOT EXIST -- COULD   13440020
*                            BE EITHER A SINGLE ADDR OR LIST            13500020
         BZ    @003A1        IF NOT ZERO WE HAVE A RANGE                13560020
         SPACE                                                          13610020
         LTR   R6,R6         IF NEG THEN SYM HAS RESOLVED THE ADDR      13620020
         BH    @002H3        IF POSITIVE THEN USERWORD IS THE ADDR      13680020
         SPACE                                                          13730020
         L     R6,@0(R6)     PLACE POINTER TO ADDRESS INTO R6           13740020
         ST    R6,PDEUSER    PLACE ACTUAL ADDRESS INTO USERWORD         13800020
         DROP R8             DROP R8 AS POINTER TO PDL                  13860020
         USING IKJPARMA,R3   USE REG 3 TO ADDRESS PDL                   13920020
         SPACE                                                          13970020
************************************************************            14280020
** A COMPARISON IS MADE BETWEEN THE BREAKPOINT QUEUE      **            14340020
** INSTRUCTION ADDRESS AND THE ADDRESS GIVEN WITH THE OFF **            14400020
** COMMAND. IF THE ADDRESS GIVEN WITH OFF IS EQUAL OR LOWER*            14460020
** THAN THE QUEUED ADDRESS, THE ADDRESS MAY BE WITHIN     **            14520020
** THE SPECIFIED RANGE. A COMPARISON WILL BE MADE WITH    **            14580020
** THE OTHER HALF OF THE SPECIFIED RANGE.                 **            14640020
************************************************************            14700020
         SPACE                                                          14710020
@002H3   EQU   *             EQUATE LABEL TO THIS ADDRESS               14750020
         USING BRKELEM,R4    USE REG 4 TO ADDRESS BREAK TABLE           14752020
         SPACE                                                          14752420
         CR    R5,R6         CHECK IF FIRST RANGE ADDR IS EQUAL OR      14752820
*                            LESS THAN THE SECOND                       14753220
         BNH   RANGEOK       IF SO, RANGE IS VALID                      14753620
         SPACE                                                          14753720
         L     R1,MSSG12     RANGE IS INVALID --                        14753820
         B     ADCK0001      GO PRINT MESSAGE                           14753920
         SPACE                                                          14764920
RANGEOK  L     R7,BRKADDR    GET ADDRESS OF INSTRUCTION FROM            14776020
*                            BREAKPOINT QUEUE                           14787020
         CR    R5,R7         COMPARE INSTRUCTION ADDRESS WITH           14798020
*                            ADDRESS SPECIFIED WITH OFF                 14809020
         BNH   @003H1        IF EQUAL OF LOW, ADDRESS IS POSSIBLY       14820020
*                            WITHIN RANGE. BRANCH FOR NEXT CHECK        14880020
         SPACE                                                          14930020
@003C1   EQU   *             EQUATE LABEL TO THIS ADDRESS               14940020
         LR    R10,R4        PLACE POINTER TO PREVIOUS ELEMENT IN R10   15000020
         L     R4,BRKLINK    PLACE ADDRESS OF NEXT BREAKELEMENT IN R4   15060020
@003C2   EQU   *             EQUATE LABEL TO THIS ADDRESS               15120020
         LTR   R4,R4         CHECK TO SEE THAT THERE IS                 15180020
*                            ANOTHER ELEMENT ON THE QUEUE               15240020
         BNZ   RANGEOK       IF NOT ZERO THEN BRANCH TO PROCESS         15300020
         SPACE                                                          15350020
@003CC   EQU   *             EQUATE LABEL TO THIS ADDRESS               15360020
         TM    TSTFLGS2,TWHRLOAD SEE IF WE ARE LOOKING OR GETTING       15420020
         BO    ADCK0027      IF JUST LOOKING, THEN RETURN TO VALIDITY   15480020
*                            EXIT                                       15530020
         TM    PDEFLG1,HEX80 SEE IF A FULLY QUALIFIED NAME WAS ENTERED  15540020
         BO    @007A1        IT WAS,BRANCH TO CHECK DEFERRED QUEUE      15600020
         B     @004A3        IF FINISHED WITH THIS PDE, SEE IF MORE     15660020
         EJECT                                                          15710020
************************************************************            15780020
**  THE FOLLOWING ROUTINE WILL PROCESS A LIST OF ADDRESSES.*            15840020
**  AT ENTRY, REG 5 CONTAINS THE ADDRESS ENTERED WITH THE **            15900020
**  OFF COMMAND. THIS ADDRESS IS COMPARED WITH THE        **            15960020
**  INSTRUCTION ADDRESS. IF THE ADDRESSES ARE EQUAL, THE  **            16010020
**  INSTRUCTION ADDRESS WILL BE REMOVED FROM THE BREAKTAB **            16020020
**  QUEUE. IF NOT EQUAL, THIS ROUTINE IS EXECUTED AGAIN   **            16080020
**  WITH THE ADDRESS OF THE NEXT PDE (FOUND IN THE CHAIN  **            16130020
**  WORD OF THIS PDE).                                    **            16132020
************************************************************            16140020
         SPACE                                                          16150020
@003A1   EQU   *             EQUATE LABEL TO ADDRESS                    16190020
         USING BRKELEM,R4    USE REG4 TO ADDRESS BREAK TABLE            16200020
         L     R7,BRKADDR    GET INSTRUCTION ADDR FROM BREAK ELEMENT    16260020
         CR    R5,R7         COMPARE ADDRESS FROM OFF COMMAND           16320020
*                            WITH INSTRUCTION ADDRESS                   16380020
         BE    @003A2        IF EQUAL BRANCH TO REMOVE ELEMENT          16440020
         SPACE                                                          16490020
         LR     R10,R4       SAVE POINTER TO PREVIOUS QUEUE ELEMENT     16500020
         L     R4,BRKLINK    GET ADDRESS OF NEXT BREAKPOINT             16560020
*                            QUEUE ELEMENT                              16620020
         LTR   R4,R4         MAKE SURE WE HAVE MORE                     16680020
         BNZ   @003A1        BRANCH TO PROCESS                          16740020
         B     @003CC        IF FINISHED WITH THIS PDE SEE IF MORE      16800020
         SPACE                                                          16850020
@004A1   EQU   *             EQUATE LABEL TO THIS ADDRESS               16860020
         LTR   R6,R6         TEST IF RANGE WAS ENTERED                  16920020
         BNZ   @003C2        BRANCH TO PROCESS RANGE                    16980020
         TM    PDEFLG1,HEX80 WAS THE ENTERED ADDRESS FULLY QUALIFIED    17100020
         BO    @007A1        IF SO, CHECK THE DEFER QUEUE               17160020
         SPACE                                                          17210020
@004A2   EQU   *             EQUATE LABEL TO THIS ADDRESS               17220020
         TM    TSTFLGS2,TWHRLOAD SEE IF WE ARE LOOKING OR GETTING       17280020
         BNO   @004A3        BRANCH IF NOT ON TO PROCESS MORE           17340020
         NI    TSTFLGS2,HEXFF-TWHRLOAD TURN OFF LOOKING SWITCH          17400020
         NI    TSTFLGS3,HEXFF-TDUPNAME TURN OFF DUPLICATE NAME SWITCH   17460020
         B     ADCK0270      BRANCH TO ADDRESS VALIDITY CHECKING        17520020
         SPACE                                                          17570020
@004A3   EQU   *             EQUATE LABEL TO THIS ADDRESS               17580020
         L     R3,PDE2CHAI   GET ADDRESS OF NEXT PDE                    17640020
         LA    R3,@0(R3)     ZERO OUT ANY HIGH ORDER DATA               17700020
         LTR   R3,R3         MAKE SURE THERE ARE MORE PDE'S TO PROCESS  17760020
         BNZ   @000A0        BRANCH IF A CHAIN WORD EXISTS              17820020
         SPACE                                                          17880020
@003E5   EQU   *             EQUATE LABEL TO THIS ADDRESS               17940020
         XR    R15,R15       ZERO OUT R15 FOR RETURN CODE               18000020
         SPACE                                                          18030020
@003E6   EQU   *             EQUATE LABEL TO THIS ADDRESS               18060020
         DROP  R2            DROP ADDRESSABILITY TO WORKAREA            18095020
         SPACE                                                          18096020
         L     R13,@4(R13)   PLACE CALLERS SAVE AREA ADDR IN R13        18120020
         RETURN (14,12),RC=(15)                                         18180020
         EJECT                                                          18210020
@003H1   CR    R6,R7         COMPARE UPPER LIMIT OF RANGE               18240020
*                            TO SEE IF ADDRESS IS IN BETWEEN            18300020
         BNL   @003A2        IF RANGE IS HIGHER OR EQUAL TO             18360020
*                            BREAKPOINT QUEUE ADDRESS THIS              18420020
*                            ADDRESS IS WITHIN THE RANGE SPECIFIED      18480020
         B     @003C1        BRANCH TO GET NEXT QUEUE ELEMENT           18540020
         SPACE                                                          18590020
************************************************************            18660020
**  REG 10  IS A BACKPOINTER TO THE PREVIOUS QUEUE ELEMENT.*            18720020
**  REGISTER 4 IS THE POINTER TO THE CURRENT QUEUE        **            18780020
**  ELEMENT. INITIALLY REG 10 IS CHECKED TO SEE IF IT IS  **            18840020
**  ZERO. IF ZERO, THE FIRST ELEMENT ON THE QUEUE HAS BEEN**            18900020
**  FOUND EQUAL TO THE SPECIFIED ADDRESS. THE QUEUE WILL  **            18960020
**  BE UPDATED BY PUTTING THE FORWARD POINTER (BRKLINK)   **            19020020
**  INTO REGISTER 5 AND STORING IT IN BREAKTAB.           **            19080020
************************************************************            19140020
         SPACE                                                          19150020
@003A2   EQU   *             FLOWCHART SYMBOL EQUATED TO THIS ADDRESS   19190020
         TM    TSTFLGS2,TWHRLOAD ARE WE LOOKING OR REMOVING             19200020
         BNO   @003A22       IF NOT LOOKING THEN BRANCH                 19260020
         SPACE                                                          19310020
ADCKOK   EQU   *                                                        19320020
         NI    TSTFLGS2,HEXFF-TWHRLOAD TURN OFF TWHRLOAD SWITCH         19380020
         NI    TSTFLGS3,HEXFF-TDUPNAME TURN OFF DUPLICATE NAME SWITCH   19440020
         B     ADDFOUND      BRANCH TO VALIDITY CHECKING ROUTINE        19500020
         SPACE                                                          19550020
@003A22  EQU   *             EQUATE LABEL TO THIS ADDRESS               19560020
         LTR   R10,R10       CHECK REG10 FOR ZERO,IF ZERO               19620020
         BNZ   @003A4        WE ARE ACCESSING FIRST ELEMENT             19680020
*                            OF QUEUE,OTHERWISE OTHER THAN FIRST        19740020
         L     R2,BRKLINK    PLACE ADDRESS OF NEXT BREAK ELEMENT        19800020
*                            INTO REG2                                  19860020
         ST    R2,BREAKTAB   SINCE THIS IS FIRST ELEMENT OF QUEUE       19920020
*                            UPDATE BREAKTAB IN TCOMTAB                 19980020
         SPACE                                                          20030020
************************************************************            20040020
** IF THERE IS ONLY ONE ELEMENT ON THE QUEUE, BRKLINK     **            20100020
** WOULD BE ZERO AND WE WOULD ZERO OUT BREAKTAB. IF MORE  **            20160020
** THAN ONE ELEMENT, BRKLINK CONTAINS NEXT ADDRESS.       **            20220020
** BREAKTAB NOW POINTS TO THE NEXT ELEMENT.               **            20280020
************************************************************            20340020
         SPACE                                                          20390020
         B     @003C5         BRANCH TO REMOVE ELEMENT                  20400020
         SPACE                                                          20450020
@003A4   EQU   *              EQUATE LABEL TO THIS ADDR                 20460020
         SPACE                                                          20510020
************************************************************            20520020
** IF REG10 IS NOT ZERO THEN WE ARE ACCESSING AN          **            20580020
** ELEMENT OTHER THAN THE FIRST ONE. WE WILL TAKE THE     **            20640020
** FORWARD POINTER (EITHER AN ADDRESS OR ZERO), AND       **            20700020
** STORE IT IN THE PREVIOUS QUEUE ELEMENT.THIS UPDATES    **            20760020
** THE QUEUE.                                             **            20820020
************************************************************            20880020
         SPACE                                                          20930020
         L     R2,BRKLINK    PLACE ADDRESS OF NEXT BREAK ELEMENT        20940020
*                            INTO REG2                                  21000020
         DROP  R4            REMOVE REG 4 AS BASE REG                   21060020
         USING BRKELEM,REG10 USE REG10 TO ADDRESS BREAK ELEMENT         21120020
         ST    R2,BRKLINK    PLACE ADDRESS OF NEXT BREAK ELEMENT IN     21180020
*                            IN PREVIOUS QUEUE ELEMENT(COULD BE 0)      21240020
         DROP  R10           REMOVE REG 10 AS BASE                      21300020
         USING BRKELEM,REG4  RESTORE REG4 AS ADDRESSING REG             21360020
         SPACE                                                          21410020
@003C5   EQU   *             FLOWCHART SYMBOL EQUAL THIS ADDRESS        21420020
         BAL   R14,REMOVAL   BRANCH TO REMOVE ELEMENT                   21480020
         LR    R4,R2         RESTORE REG4 TO NEXT BREAK ELEMENT         21540020
         B     @004A1        OTHERWISE BRANCH                           21600020
         EJECT                                                          21650020
REMOVAL  EQU   *             ENTRY POINT FOR REMOVAL SUB-ROUTINE        21660020
         SPACE                                                          21710020
************************************************************            21720020
** UPON ENTERING THIS REMOVAL SUBROUTINE, REGISTER 4      **            21780020
** CONTAINS THE ADDRESS OF THE BREAKPOINT ELEMENT TO      **            21840020
** BE REMOVED. INITIALLY WE WILL FREE THE BREAKNAME AREA  **            21900020
** AND THE SUBCOMMAND STRING AREA (IF THERE ARE ANY).     **            21960020
************************************************************            22020020
         SPACE                                                          22070020
         L     R7,WORKAREA   PLACE WORKAREA ADDRESS INTO REG7           22080020
         USING TSTCWORK,R7   ESTABLISH ADDRESSABILITY                   22140020
         LA    R7,CWORKCMD   R7 = ADDRESS OF OFF'S WORKAREA             22190020
         DROP  R7            DROP TEST'S WORKAREA POINTER               22192020
         USING WORKDSCT,R7   USE REG 7 TO ADDRESS WORKAREA              22200020
         SPACE                                                          22250020
         STM   R0,R15,TEMPSAV   SAVE REGS                               22252020
         DROP  R7            DROP OFF'S WORKAREA POINTER                22254020
         SPACE                                                          22256020
         L     R1,BRKNAME    PLACE ADDRESS OF ADDRESS STRING            22260020
*                            AREA INTO REG1                             22320020
         TM    BRKFLGS,BRKRANGE  SEE IF THIS ADDRESS IS ONE OF A RANGE  22380020
         BNO   @003D5        IF IT ISNT THEN BRANCH TO FREE AREA        22440020
         L     R7,BREAKTAB   ACCESS QUEUE FROM THE BEGINNING            22500020
         DROP  R4            REMOVE REG4 FROM ADDRESSING BRKELEM        22560020
         USING BRKELEM,R7    USE REG 7 TO ADDRESS BREKELEM              22620020
         SPACE                                                          22670020
@003C6   EQU   *             EQUATE LABEL TO THIS ADDRESS               22680020
         LA    R7,@0(R7)     ZERO OUT ANY HIGH ORDER DATA               22740020
         LTR   R7,R7         SEE IF ANY MORE ELEMENTS EXIST             22800020
         BZ    @003D5        IF NONE DO THEN BRANCH TO FREE AREA        22860020
         SPACE                                                          22910020
         L     R3,BRKNAME    PLACE ADDRESS LIST IN R3                   22920020
         CR    R1,R3         SEE IF THEY POINT TO THE SAME PLACE        22980020
         BNE   @003D4        NOT EQUAL, BRANCH TO GET NEXT ONE          23040020
         SPACE                                                          23090020
         CR    R4,R7         SEE IF THIS IS THE ONE WE ARE REMOVING     23100020
         BE    @003D4        THEY ARE, BRANCH TO GET NEXT ELEMENT       23160020
         B     @003D6        OTHERWISE BRANCH FROM THIS ROUTINE         23220020
         SPACE                                                          23270020
@003D4   EQU   *             EQUATE LABEL TO THIS ADDRESS               23280020
         L     R7,BRKLINK    PLACE ADDRESS OF NEXT ELEMENT INTO REG7    23340020
         B     @003C6        BRANCH TO PROCESS THIS ELEMENT             23400020
         SPACE                                                          23450020
@003D5   EQU   *             EQUATE LABEL TO THIS ADDRESS               23460020
         LA    R1,@0(R1)     ZERO OUT HIGH ORDER DATA                   23520020
         LH    R7,ZERO(R1)    GET LENGTH OF BREAK NAME                  23560020
         LA    R7,@2(ZERO,R7)   ADD TWO FOR LENGTH                      23600020
         LR    R0,R7          PLACE CONTENTS IN R0                      23640020
         O     R0,SUBPOOL1    OR IN SUBPOOL NUMBER                      23680020
         SPACE                                                          23750020
         FREEMAIN R,LV=(0),A=(1)                                        23760020
*                            FREE CORE GOTTEN FOR ADDRESS STRING        23820020
         SPACE                                                          23870020
@003D6   EQU   *             EQUATE LABEL TO THIS ADDRESS               23880020
         DROP  R7            REMOVE REG7 FROM ADDRESSING BREKELEMT      23940020
         USING BRKELEM,R4    AGAIN USE REG 4 TO ADDRESS BRKELEMT        24000020
         SPACE                                                          24010020
         TM    BRKFLGS,BRKINACT   IS THIS BREAKPOINT INACTIVE           24020021
         BO    @006H3              YES...GO REMOVE IT                   24030020
         L     R1,BRKCHAIN   PLACE ADDR OF SUB-COMMAND CHAIN            24060020
*                            INTO REG1                                  24120020
         LA    R1,@0(R1)     ZERO OUT HIGH ORDER BYTE                   24180020
         LTR   R1,R1         TEST THAT THERE IS A SUB-COMMAND CHAIN     24240020
         BZ    @005B1        BRANCH IF NONE                             24300020
         SPACE                                                          24350020
************************************************************            24360020
** THIS ROUTINE CHECKS TO SEE IF THE BREAKPOINT WAS       **            24420020
** CREATED AS ONE OF A RANGE OF ADDRESSES. IF IT WAS AND  **            24480020
** IF A SUBCHAIN EXIST THEN MORE THEN ONE BREAKPOINT MAY  **            24540020
** BE POINTING TO THIS SUBCOMMAND CHAIN. WE MUST CHECK    **            24600020
** THIS POSSIBILITY BEFORE REMOVING IT.                   **            24660020
************************************************************            24720020
         SPACE                                                          24770020
@003D7   EQU   *             EQUATE LABEL TO THIS ADDRESS               24780020
         DROP  R4            REMOVE REG4 FROM ADDRESSING BRK ELEM QUEUE 24840020
         USING BRKELEM,R7    USE REG7 TO ADDRESS BRKELEMT QUEUE         24900020
         L     R7,BREAKTAB   OTHERWISE PLACE BREAKTAB ADDRESS INTO R7   24960020
         LA    R7,@0(R7)     ZERO OUT HIGH ORDER DATA                   25020020
         LTR   R7,R7         SEE IF BREAKTAB IS NOW ZERO                25080020
         BZ    ZAPIT01       IF IT IS THEN REMOVE SUB COMMAND           25140020
         SPACE                                                          25190020
TEST01   EQU   *             EQUATE LABEL TO THIS ADDRESS               25200020
         L     R3,BRKCHAIN   PLACE ADDRESS OF CHAIN INTO R3             25320020
         CR    R1,R3         COMPARE ADDRESSES TO SEE IF THIS IS        25380020
*                            WITHIN THE SAME RANGE                      25440020
         BNE   TEST02        BRANCH IF NOT                              25500020
         SPACE                                                          25550020
         CR    R4,R7         SEE IF THIS IS THE ONE TO BE REMOVED       25560020
         BE    TEST02        THEY ARE, BRANCH TO GET ANOTHER ONE        25620020
         B     @005B1        IF IT IS THEN LEAVE ALL ALONE              25680020
         SPACE                                                          25730020
TEST02   EQU   *             EQUATE LABEL TO THIS ADDRESS               25740020
         L     R7,BRKLINK    PLACE ADDRESS OF NEXT BREAK ELEMENT        25800020
*                            INTO REG7                                  25860020
         LA    R7,@0(R7)     ZERO OUT HIGH ORDER OF REG                 25920020
         LTR   R7,R7         SEE IF THERE ARE ANY MORE BREAK ELEMENT    25980020
         BZ    ZAPIT01       IF NO MORE BREAK ELEMENTS THEN REMOVE      26040020
         B     TEST01        OTHERWISE BRANCH TO PROCESS NEW ELEMENT    26100020
         SPACE                                                          26150020
ZAPIT01  EQU   *             EQUATE LABEL TO THIS ADDRESS               26160020
         DROP  R7            REMOVE REG7 FROM ADDRESSING BREAK QUEUE    26220020
         USING BRKELEM,R4    USE REG4 TO ADDRESS BREAK ELEMENT Q        26280020
         SPACE                                                          26330020
         L     R7,SUBCHAIN   GET PTR TO SUBCOMMAND CHAIN                26332020
         LTR   R7,R7         CHECK IF EMPTY                             26334020
         BZ    FREEBRK       IF SO, FREE BREAKCHAIN                     26336020
         SPACE                                                          26338020
         L     R3,BRKCHAIN   GET ADDR OF BREAKCHAIN                     26338420
         CLR   R3,R7         COMPARE BRKCHN PTR TO SUBCHN PTR           26338820
         BH    FREEBRK       IF HIGH, FREE BREAKCHAIN                   26339220
         SPACE                                                          26339620
         AH    R3,ZERO(R3)   ELSE, ADD LENGTH OF CHAIN TO BRKCHN PTR    26339720
         CLR   R3,R7         COMPARE RESULTING ADDR TO SUBCHN PTR       26339820
         BH    @005B1        IF HIGH, THERE IS MORE IN THE CHAIN---     26339920
*                            DON'T FREE IT YET                          26359920
         SPACE                                                          26369920
FREEBRK  LH   R0,@0(R1)      PLACE LENGTH OF SUBCHAIN INTO R0           26380020
         LA    R3,@1         PLACE A 1 INTO REG3 TO BE ADDED TO         26400020
         AR    R0,R3         REG0 TO GET PROPER LENGTH                  26460020
         O     R0,SUBPOOL1    PLACE SUBPOOL NUMBER INTO R0              26510020
         SPACE                                                          26570020
         FREEMAIN R,LV=(0),A=(1)                                        26580020
         SPACE                                                          26630020
@005B1   EQU   *             FLOWCHART EQUATED TO THIS ADDRESS          26640020
         L     R7,BRKRB      PLACE POINTER TO BRK ELEMENT RB IN R7      26700020
         LTR   R7,R7         SEE IF AN RB EXISTS                        26760020
         BZ    @005D1        BRANCH IF NOT                              26820020
         SPACE                                                          26870020
         USING RBSECT,R7     USE REG7 TO ADDRESS RB                     26880020
         L     R1,BRKADDR    PLACE INSTRUCTION ADDRESS INTO R1          26940020
         L     R3,RBOPSW+@4  PLACE IC INTO R3                           27000020
         LA    R3,@0(R3)     REMOVE ANY HIGH ORDER DATA                 27060020
         LA    R10,BRKINST   PLACE ADDRESS OF INSTRUCTION IN BRKEA Q    27120020
         CR    R10,R3        SEE IF THE IC AND INST ADDR ARE THE SAME   27180020
         BE    @005C1        IF SO, REPLACE THE IC                      27240020
         SPACE                                                          27290020
         LA    R1,@2(R1)     ADD 2 TO INSTRUCTION ADDRESS               27300020
         LA    R10,@2(R10)   ADD 2 TO ADDRESS OF THE INSTRUCTION        27360020
         CR    R10,R3        SEE IF THE IC AND THIS ADDRESS AGREE       27420020
         BNE   @005D1        BRANCH IF NOT EQUAL                        27540020
         SPACE                                                          27590020
@005C1   EQU   *             EQUATE LABEL TO THIS ADDRESS               27600020
         L     R0,BRKRB      PLACE RB ADDRESS INTO R0                   27660020
         L     R3,RBOPSW+@4  PLACE THE IC INTO REG3                     27720020
         SRL   R3,@24        MOVE OUT ALL GARBAGE                       27780020
         SLL   R3,@24        MOVE HIGH ORDER BYTE BACK INTO PLACE       27840020
         OR    R1,R3         PLACE THIS HIGH ORDER BYTE INTO R1         27900020
         O     R0,SVCCODE    OR IN CORRECT SVC CODE                     27960020
         SVC   TSTSVC        ISSUE TEST SVC                             28020020
         SPACE                                                          28070020
@005D1   EQU   *             EQUATE LABEL TO THIS ADDRESS               28080020
         L     R7,BRKADDR    PLACE ADDRESS OF ADDRESS STRING INTO R7    28200020
         CLC   @0(@2,R7),SVC97 IS THE INSTRUCTION AN SVC 97             28260020
         BNE   @006H3        IF NOT EQUAL THEN BRANCH TO LEAVE          28320020
         SPACE                                                          28370020
         STM   @14,@12,@12(R13)  SAVE  REGISTERS                        28380020
         OI    TSTFLGS1,BOMBSW   TURN ON ABEND SW IN CASE OF 0C1 ABEND  28440020
         MVC   @0(@2,R7),BRKINST RESTORE INSTRUCTION                    28500020
         SPACE                                                          28550020
FREEIT   EQU   *             EQUATE LABEL TO THIS ADDRESS               28560020
         NI    TSTFLGS1,HEXFF-BOMBSW TURN OFF ABEND SWITCH              28620020
@006H3   EQU   *             EQUATE LABEL TO THIS ADDRESS               28680020
         LR    R1,R4         PLACE ADDRESS OF ELEMENT TO BE FREED IN R1 28740020
         FREEMAIN R,LV=40,A=(1),SP=1  ISSUE FREEMAIN                    29280020
         SPACE                                                          29330020
         SPACE                                                          31430020
@006HB   EQU   *             EQUATE LABEL TO THIS ADDRESS               31440020
         L     R7,WORKAREA   PLACE WORKAREA ADDRESS INTO REG7           31560020
         USING TSTCWORK,R7   ESTABLISH ADDRESSABILITY                   31620020
         LA    R7,CWORKCMD   R7 = ADDRESS OF OFF'S WORKAREA             31670020
         DROP  R7            DROP TEST'S WORKAREA POINTER               31672020
         USING WORKDSCT,R7   ADDRESS OF OFF'S WORKAREA                  31674020
         SPACE                                                          31676020
         LM    R0,R15,TEMPSAV   RESTORE REGS                            31678020
         DROP  R7            DROP OFF'S WORKAREA POINTER                31678420
         SPACE                                                          31678820
         BR    R14           RETURN TO CALLER                           31680020
         EJECT                                                          31730020
@007A1   EQU   *             FLOWCHART EQUATED TO ADDR                  31740020
         USING DEFERPDE,R1   USE REG1 TO ADDRESS PDE IN DEFER TBL       31800020
          SPACE                                                         31850020
************************************************************            31860020
** THE FOLLOWING ROUTINE WILL ACCESS THE DEFERRED         **            31920020
** TABLE QUEUE. THIS QUEUE IS POINTED TO BY A WORD IN     **            31980020
** TCOMTAB CALLED DEFERTAB. IF OFF HAS BEEN SPECIFIED     **            32040020
** WITH NO ADDRESSES, THE ENTIRE DEFERRED QUEUE WILL BE   **            32100020
** CLEARED (IF ONE EXISTS). IF OFF HAS BEEN SPECIFIED WITH *            32160020
** A QUALIFIED ADDRESS, THE BREAKPOINT ELEMENT WILL BE    **            32220020
** REMOVED FROM THE DEFERRED QUEUE.                       **            32280020
************************************************************            32340020
         SPACE                                                          32390020
         L     R4,DEFERTAB   GET DEFER TABLE POINTER FROM TCOMTAB       32400020
@007A11  LTR   R4,R4         CHECK IF THE DEFER QUEUE EXISTS            32460020
         BNZ   @007C1        IF IT DOES BRANCH                          32520020
         SPACE                                                          32570020
************************************************************            32580020
** SINCE THERE IS NO DEFER TABLE, THE FOLLOWING BRANCH    **            32640020
** WILL CHECK IF ANY BREAKPOINTS HAVE BEEN REMOVED. IF    **            32700020
** NOT, AN ERROR MESSAGE WILL BE PUT OUT INDICATING NO    **            32760020
** BREAKPOINTS COULD BE FOUND.                            **            32820020
************************************************************            32880020
         SPACE                                                          32930020
         B     @004A2        BRANCH TO EXIT CHECK ROUTINE               32940020
         SPACE                                                          32990020
@007C1   EQU   *             FLOWCHART SYMBOL EQUATED TO THIS ADDRESS   33000020
         TM    PDEFLG3,HEX80 SEE IF AN ADDRESS WAS ENTERED              33060020
         BO    @007C2        IF SO, BRANCH                              33120020
         SPACE                                                          33170020
         TM    PDEFLG2,HEX80 SEE IF A CSECT NAME WAS ENTERED            33180020
         BNO   @004A2        IF NOT THEN WE ARE DONE HERE               33240020
         SPACE                                                          33290020
         OI    TSTFLGS3,TCSECTCK TURN ON CSECT ONLY SWITCH              33300020
         SPACE                                                          33310020
*************************************************************           33350020
**   LOADNAMES WILL BE COMPARED SO AS TO REMOVE THE        **           33352020
**   CORRECT ELEMENT FROM THE QUEUE.                       **           33354020
*************************************************************           33358420
         SPACE                                                          33358820
@007C2   L      R6,WORKAREA    GET WORKAREA ADDRESS FROM TCOMTAB        33359220
         USING TSTCWORK,R6     ESTABLISH ADDRESSABILITY                 33359620
         LA    R6,CWORKCMD     R6 = ADDRESS OF OFF'S WORKAREA           33359720
         DROP  R6              DROP TEST'S WORKAREA POINTER             33359820
         USING WORKDSCT,R6     ADDRESS OF OFF'S WORKAREA                33359920
         SPACE                                                          33376620
         LA    R6,TEMPSAV      GET ADDR FOR TEMPORARY WORKAREA          33386620
         DROP  R6              DROP OFF'S WORKAREA POINTER              33388620
         SPACE                                                          33390620
         MVI    @0(R6),HEX40   MOVE A BLANK INTO FIRST BYTE             33392620
         MVC    @1(@7,R6),@0(R6) SPREAD BLANK THRU 7 BYTES              33393020
         LH     R2,PDELEN1     GET LENGTH OF MY LOADNAME FROM PDL       33393120
         L      R1,PDELDNAM    GET POINTER TO MY LOADNAME FROM PDL      33393220
         BCTR   R2,@0          DECREMENT R2 BY 1 FOR EX INST            33398820
         EX     R2,MOVENAME    MOVE LOADNAME INTO WORKAREA              33400820
         SPACE                                                          33402820
         CLC    @0(@8,R4),@0(R6)  COMPARE LOADNAME IN DEFERRED TABLE    33403220
*                              WITH LOADNAME IN WORKAREA                33403620
         BE    @007F1        IF EQUAL, GO COMPARE ENTRYNAMES            33404020
         SPACE                                                          33404120
*************************************************************           33406420
**  THE LOADNAMES COMPARED DID NOT MATCH. THE CHAIN ADDRESS *           33408420
**  TO THE NEXT LOADNAME WILL BE CHECKED TO DETERMINE IF   **           33408820
**  THERE ARE ANY MORE LOADNAMES IN THE QUEUE. IF SO, THE  **           33409220
**  NEXT LOADNAME WILL BE CHECKED.                         **           33409620
*************************************************************           33409720
         SPACE                                                          33424120
         USING DEFERRED,R4   USE REG4 TO ADDRESS DEFER TABLE            33434120
         SPACE                                                          33439220
         L     R4,DMEDME     GET POINTER TO NEXT LOADNAME IN R4         33453620
         LTR    R4,R4         MAKE SURE THAT ONE EXISTS                 33468020
         BNZ    @007C2        IF THERE IS ONE WORK ON IT                33482420
         B      @004A2        OTHERWISE BRANCH TO SEE IF DONE           33496820
         SPACE                                                          33511220
@007F1   EQU   *             EQUATE LABEL TO THIS ADDRESS               33525620
         LR    R8,R4         SAVE POINTER TO BEGINNING OF GROUP         33540020
         SPACE                                                          33590020
@007F2   EQU   *             EQUATE LABEL TO THIS ADDRESS               33600020
         L     R5,DMEDBE     PLACE POINTER TO FIRST ELEMENT IN R5       33720020
         USING DBEPTRQ,R5    USE REG 5 TO ADDRESS QUEUE ELEMENTS        33780020
         SPACE                                                          33830020
@007F22  EQU   *             EQUATE LABEL TO THIS ADDRESS               33840020
         L     R1,DBEPDL     PLACE POINTER TO PDL INTO REG1             33900020
         LA    R1,@8(R1)     ADD EIGHT TO REG1                          33960020
@007F21  EQU   *             EQUATE LABEL TO THIS ADDRESS               34020020
         LH    R2,DEFLEN2    PLACE LENGTH OF ADDRESS IN R2              34080020
         L     R7,DEFENTY    PLACE POINTER TO ENTRYNAME IN R7           34140020
         SPACE                                                          34190020
         USING IKJPARMA,R3   USE REG 3 TO ADDRESS PDL FROM PARSE        34200020
         LH    R6,PDELEN2    PLACE LENGTH OF ENTRYNAME FROM OFF         34260020
*                            INTO REG 6                                 34320020
         L     R10,PDECTNAM  PLACE POINTER TO ENTRYNAME FROM OFF        34380020
*                            INTO REG 10                                34440020
         SPACE                                                          34490020
************************************************************            34500020
** REG1 IS POINTING TO THE PDL WITHIN THE DEFERRED TABLE, **            34560020
** AND REG3 POINTS TO THE PDL FROM PARSE. THE ENTRYNAME   **            34620020
**  LENGTHS WILL BE COMPARED TO DETERMINE WHETHER OR NOT  **            34680020
** THEY ARE EQUAL. IF NOT, THE NAMES CANNOT BE THE SAME,  **            34740020
** SO THE THE NEXT PDL IS ACCESSED AND THE COMPARE IS     **            34800020
** EXECUTED AGAIN.                                        **            34860020
************************************************************            34920020
         SPACE                                                          34970020
         CR    R2,R6         COMPARE LENGTHS OF NAME                    34980020
         BE    @007F4        IF EQUAL BRANCH TO CHECK ACTUAL NAME       35040020
         SPACE                                                          35090020
@007F3   EQU   *             EQUATE LABEL TO THIS ADDRESS               35100020
         L     R1,DEFCHAIN   PLACE POINTER TO NEXT LIST ELEMENT IN R1   35160020
         LA   R1,@0(R1)      REMOVE ANY HIGH ORDER DATA                 35220020
         LTR  R1,R1          SEE IF THIS IS ONE OF A LIST               35280020
         BZ   @007F31        IF NOT THEN BRANCH TO PROCESS NONE LIST    35340020
         SPACE                                                          35390020
         OI   TSTFLGS2,TOFFDEF OTHERWISE TURN ON LIST SWITCH            35400020
         B    @007F21        AND BRANCH TO PROCESS THE NEXT PDE         35460020
         SPACE                                                          35510020
@007F31  EQU  *              EQUATE LABEL TO THIS ADDRESS               35520020
         L     R5,DBEDBE     GET POINTER TO NEXT PDL INTO REG 4         35640020
         LTR   R5,R5         TEST IF THERE ARE ANYMORE TO PROCESS       35700020
         BNZ   @007F22       IF WE HAVE MORE THEN BRANCH TO PROCESS     35760020
         B    @007H42        BRANCH TO RETURN TO MAINLINE               35820020
         SPACE                                                          35870020
@007F4   EQU   *             EQUATE LABEL TO THIS ADDRESS               35880020
         SPACE                                                          35930020
************************************************************            35940020
** IF  THE LENGTHS ARE EQUAL, A COMPARE IS MADE ON THE    **            36000020
** ACTUAL NAMES. IF THEY ARE EQUAL, THE PDL IS REMOVED    **            36060020
** FROM THE TABLE.                                        **            36120020
*************************************************************           36240020
         SPACE                                                          36290020
         BCTR  R6,@0         SET REG 6 UP FOR EXECUTE INSTRUCTION       36300020
         EX    R6,COMPENTY   COMPARE ACTUAL ENTRYNAMES                  36360020
         BE    @007F5        WE HAVE FOUND THE SAME NAMES BRANCH        36420020
         B     @007F3        OTHERWISE BRANCH TO ACCESS NEXT PDL        36480020
         SPACE                                                          36530020
@007F5   EQU   *             EQUATE LABEL TO THIS ADDRESS               36540020
         TM    TSTFLGS3,TCSECTCK    CHECK IF CSECT-ONLY SWITCH IS ON    36600020
         BZ    @007G4               IF NOT, GO PROCESS ADDRESS          36650020
         SPACE                                                          36652020
         OI    TSTFLGS3,TDUPNAME TURN ON DUPLICATE NAME SWITCH          36660020
         B     @008A1        BRANCH TO REMOVE ELEMENT FROM QUEUE        36720020
         EJECT                                                          36770020
****************************************************************        36780020
*  THE FOLLOWING CODE WILL CHECK THE BREAK ELEMENT TO FIND A  **        36830020
*  MATCH FOR THE SPECIFIED ADDRESS.                           **        36840020
****************************************************************        36890020
         SPACE                                                          38810020
@007G4   EQU   *             EQUATE LABEL TO THIS ADDRESS               38820020
         L     R14,WORKAREA  GET ADDR OF TEST'S WORKAREA                38870020
         USING TSTCWORK,R14  ESTABLISH ADDRESSABILITY                   38920020
         LA    R14,CWORKCMD  ADDR OF OFF'S WORKAREA                     38930020
         DROP  R14           DROP TEST'S WORKAREA PTR                   38932020
         USING WORKDSCT,R14  ADDRESSABILITY TO OFF'S WORKAREA           38934020
         SPACE                                                          38936020
         STM   R0,R12,TEMPSAV   SAVE ENTERING REGISTERS                 38938020
         DROP  R14           DROP POINTER TO OFF'S WORKAREA             38938420
         SPACE                                                          38940020
************************************************************            39000020
** THIS ROUTINE CHECKS THE ADDRESS AS IT APPEARS ON THE   **            39060020
** DEFERRED QUEUE. THERE MAY BE MANY ADDRESS              **            39120020
** EXPRESSIONS TO COMPARE OUT AND THEY NEED NOT           **            39180020
** BE ENTERED IN THE SAME ORDER AS THEY APPEAR ON THE     **            39240020
** DEFERRED QUEUE.  IF AN EQUAL IS FOUND, A CHECK MUST BE **            39300020
** MADE TO SEE IF THIS IS AN ADDRESS OF A RANGE.          **            39360020
** IF IT IS, AND IF ONLY ONE ADDRESS OF THE RANGE HAS     **            39420020
** BEEN ENTERED, AN APPROPRIATE MESSAGE IS PUT OUT. IF A  **            39480020
** RANGE HAS BEEN ENTERED, AND ONLY A SINGLE ADDRESS      **            39540020
** EXISTS ON THE  QUEUE, A MESSAGE IS LIKEWISE PUT OUT.   **            39600020
************************************************************            39660020
         SPACE                                                          39710020
         XR    R10,R10       ZERO OUT REG10 FOR LATER COMPARISON        39780020
ADDR0010 EQU   *             EQUATE LABEL TO THIS ADDRESS               39840020
         L     R2,PDEEXPTR   PUT POINTER TO ADDRESS EXPRESSION IN R2    39900020
         LA    R2,@0(R2)     ZERO OUT HIGH ORDER BYTE OF REGISTER       39960020
         LTR   R2,R2         SEE IF AN ADDRESS EXPRESSION EXISTS        40020020
         BNZ   ADDR0011      THERE IS AN EXPRESSION BRANCH TO PROCESS   40080020
         SPACE                                                          40130020
         USING DEFERPDE,R1   USE REG1 TO ADDRESS DEFERRED PDE           40140020
         L     R2,DEFEXPR    SEE IF THE DEFERRED ELEM HAS AN EXPR       40200020
         LA    R2,@0(R2)     REMOVE ANY HIGH ORDER DATA                 40260020
         LTR   R2,R2         IS THERE AN EXPRESSION ON THE DEFER        40320020
         BNZ    @007H4       NO, BRANCH TO GET NEXT ELEMENT             40380020
         B     ADDR0300      YES, BRANCH TO PROCESS ADDRESS ONLY        40440020
         SPACE                                                          40490020
ADDR0011 EQU   *             EQUATE LABEL TO THIS ADDRESS               40500020
         USING IKJPARMA,R2   USE REG2 TO ADDRESS PDE FROM OFF           40560020
         DROP  R3            REMOVE REG3 AS BASE TO PDE                 40620020
         SPACE                                                          40800020
         L     R14,WORKAREA  GET ADDRESS OF TEST'S WORKAREA             40850020
         STM   R0,R5,@0(R14) SAVE REGISTERS                             40852020
         SPACE                                                          40854020
         LR    R2,R3         PLACE ADDRESS OF OFF PDE INTO R2           40860020
         L     R3,PDEEXPTR   PLACE ADDR OF EXPRESSION IN R3             40920020
         LR    R10,R2        SAVE POINTER TO OFF PDE IN R10             40980020
         LA    R5,@16        WE WILL NEED A 16 LATER FOR SUBTRACTION    41040020
         SPACE                                                          41090020
         L     R6,DEFEXPR    GET THE ADDRESS EXPRESSION ON THE          41100020
*                            DEFERRED QUEUE                             41160020
         LA    R6,@0(R6)     ZERO OUT HIGH ORDER BYTE OF REG            41220020
         LTR   R6,R6         SEE IF THIS PDE HAS AN ADDRESS EXPRESSION  41280020
         BZ    ADDR0200      NO, IT CANT BE SIMILAR TO OFF              41340020
         XR    R7,R7         YES, IT COULD BE SIMILAR                   41400020
*                            ZERO OUT REG7 TO BE USED AS COUNTER        41460020
         SPACE                                                          41510020
ADDR0020 EQU   *             EQUATE LABEL TO THIS ADDRESS               41520020
         USING ADDREXP,R3    USE REG3 TO ADDRESS ADDR EXPRESSION        41580020
         LA    R7,@1(R7)     ADD 1 TO REG 7 AS COUNTER                  41640020
         L     R3,ADDEXPR    PLACE POINTER TO ADDR EXPR IN R3           41700020
         LA    R3,@0(R3)     ZERO OUT HIGH ORDER BYTE BEFORE CK         41760020
         LTR   R3,R3         IS THIS THE LAST EXPRESSION                41820020
         BZ    ADDR0030      YES, BRANCH TO PROCESS DEF PDE             41880020
         B     ADDR0020      NO, BRANCH TO CHECK MORE EXPRESSIONS       41940020
         SPACE                                                          41990020
ADDR0030 EQU   *             EQUATE LABEL TO THIS ADDRESS               42000020
         XR    R4,R4         ZERO OUT REG4 TO USE AS COUNTER            42060020
ADDR0040 EQU   *             EQUATE LABEL TO THIS ADDRESS               42120020
         USING ADDREXP,R6    USE REG6 TO ADDRESS EXPRESSION             42180020
         DROP  R3            REMOVE REG3 FROM ADDRESSING EXPR PDE       42240020
         SPACE                                                          42290020
         LA    R4,@1(R4)     ADD 1 TO R4 TO BE USED AS COUNT            42300020
         L     R6,ADDEXPR    PUT POINTER TO NEXT ADDRESS EXPR IN R6     42360020
         LA    R6,@0(R6)     ZERO OUT HIGH ORDER BYTE OF R6             42420020
         LTR   R6,R6         TEST TO SEE IF THIS IS THE LAST ONE        42480020
         BZ    ADDR0041      IF NO MORE THEN BRANCH OUT OF LOOP         42540020
         B     ADDR0040      OTHERWISE REMAIN IN LOOP                   42600020
         SPACE                                                          42650020
ADDR0041 EQU   *             EQUATE LABEL TO THIS ADDRESS               42660020
         CR    R4,R7         DO THE SAME NUMBER OF EXPRESSIONS EXIST    42720020
*                            ON THE OFF AND DEFER PDES                  42780020
         BNE   ADDR0200      IF A DIFFERENT NUMBER EXIST THEY ARE NOT   42840020
*                            THE SAME                                   42900020
         LA    R4,@1(R4)     INCREMENT R4 TO SET UP COMPARES            42960020
         LA    R7,@1(R7)     INCREMENT R7 TO EQUAL R4                   43020020
         SPACE                                                          43070020
ADDR0050 EQU   *             EQUATE LABEL TO THIS ADDRESS               43080020
         LH     R3,PDELEN3   PLACE LENGTH OF ADDRESS IN R3              43140020
         LH     R6,DEFLEN3   DO LIKEWISE FOR THE DEFERRED ADDRESS       43200020
ADDR0060 EQU   *             EQUATE LABEL TO THIS ADDRESS               43260020
         CR    R6,R3         CHECK IF THE LENGTHS ARE THE SAME          43320020
         BNE   ADDR0080      BRANCH IF NOT EQUAL                        43380020
         SPACE                                                          43430020
         L     R7,PDEADRPT   PLACE POINTER TO ADDR IN R7                43440020
         L     R8,DEFADDR    GET THE ACTUAL ADDRESSES AND COMPARE       43500020
*                            THEM                                       43560020
         LTR   R7,R7         CHECK IF THIS IS THE COMPLEMENT OF         43620020
*                            REGISTER 7                                 43680020
         BL    ADDR0080      IF IT IS THEN THIS ADDRESS HAS             43740020
*                            ALREADY BEEN COMPARED                      43800020
         SPACE                                                          43850020
ADDR0070 EQU   *             EQUATE LABEL TO THIS ADDRESS               43860020
         BCTR  R3,@0         DECREMENT R3 FOR EXECUTE INSTRUCTION       43920020
         EX    R3,COMPADDR   COMPARE THE ADDRESSES USING R3 FOR LENGTH  43980020
         BNE   ADDR0080      IF NOT EQUAL THEN BRANCH                   44040020
         B     ADDR0090      ELSE, BRANCH TO GET NEXT ONE               44100020
         SPACE                                                          44150020
ADDR0080 EQU   *             EQUATE LABEL TO THIS ADDRESS               44160020
         L     R2,PDEEXPTR   PUT POINTER TO ADDRESS EXPRESSION IN R2    44220020
         LA    R2,@0(R2)     ZERO OUT HIGH ORDER BYTE OF R2             44280020
         LTR   R2,R2         SEE IF THERE ARE MORE EXPRESSIONS          44340020
         BZ    ADDR0200      BRANCH IF NOT                              44400020
         SPACE                                                          44450020
         SR    R2,R5         OTHERWISE SUBTRACT 16 FROM REG2            44460020
*                            TO SIMILATE A FULL ADDRESS PDE             44520020
         B     ADDR0050      BRANCH TO BEGIN THIS CHECKING OVER         44580020
         SPACE                                                          44630020
ADDR0090 EQU   *             EQUATE LABEL TO THIS ADDRESS               44640020
         LCR   R7,R7         LOAD THE COMPLEMENT OF R7 TO INCICATE      44700020
*                            THAT THIS ADDRESS HAS BEEN COMPARED        44760020
         ST    R7,PDEADRPT   PLACE THE COMPLEMENT BACK INTO PDE         44820020
         SPACE                                                          44870020
         L     R1,DEFEXPR    PUT NEXT ADDRESS EXPRESSION FROM THE DEF   44880020
*                            PDE INTO REG1 FOR FURTHER CHECKING         44940020
         SR    R1,R5         SUBTRACT 16 FROM R1 TO SIMULATE A          45000020
*                            FULL ADDRESS PDE                           45060020
         LR    R2,R10        PLACE ADDRESS OF STARTING PDE IN R2        45120020
         BCT   R4,ADDR0050   REDUCE R4 BY 1 AND IF NOT ZERO THEN        45180020
*                            BRANCH TO PROCESS NEXT EXPRESSION          45240020
         SPACE                                                          45290020
         L     R1,@4(R14)    RESTORE R1 TO ENTERING PDE ADDRESS         45300020
ADDR0092 EQU   *             EQUATE LABEL TO THIS ADDRESS               45360020
         LR    R2,R10        RESTORE R2 TO ENTERING PDE ADDRESS         45420020
         SPACE                                                          45470020
ADDR0093 EQU   *             EQUATE LABEL TO THIS ADDRESS               45480020
         L     R3,PDEADRPT   PLACE FIRST ADDRESS INTO R3                45540020
         LTR   R3,R3         SEE IF THIS IS A COMPLEMENT                45600020
         BNL   ADDR0101      IF NOT THEN BRANCH AROUND LCR              45660020
         SPACE                                                          45710020
         LCR   R3,R3         LOAD PROPER ADDRESS INTO R3                45720020
         ST    R3,PDEADRPT   PLACE CORRECT ADDRESS INTO PDE             45780020
ADDR0101 EQU   *             EQUATE LABEL TO THIS ADDRESS               45840020
         L     R2,PDEEXPTR   PLACE ADDRESS OF FIRST ADDRESS EXPRESSION  45900020
*                            INTO R2                                    45960020
         LA    R2,@0(R2)     ZERO OUT ANY HIGH ORDER DATA               46020020
         LTR   R2,R2         CHECK FOR COMPLEMENT OR ZERO               46080020
         BZ    ADDR0110      IF ZERO THEN NO MORE EXIST                 46140020
         SPACE                                                          46190020
         BH    ADDR0120      IF GREATER THAN ZERO THEN NOT COMPL        46200020
         LCR   R2,R2         RECOMPLEMENT THE ADDRESS TO OBTAIN         46260020
*                            CORRECT ADDRESS                            46320020
         ST    R2,PDEADRPT   PLACE CORRECT ADDRESS BACK INTO PDE        46380020
ADDR0120 EQU   *             EQUATE LABEL TO THIS ADDRESS               46440020
         SR    R2,R5         SUBTRACT 16 FROM R2 TO SIMULATE            46500020
*                            A COMPLETE ADDRESS PDE                     46560020
         B     ADDR0093      BRANCH TO PROCESS NEXT ADDRESS EXPR        46620020
         SPACE                                                          46670020
ADDR0110 EQU   *             EQUATE LABEL TO THIS ADDRESS               46680020
         TM    TSTFLGS2,CKADDR SEE IF CLEAR ADDR SWITCH IS ON           46740020
         BO    ADDR0210      IF IT IS THEN BRANCH                       46800020
         L     R5,@20(R14)   RESTORE R5 TO PTRTODBE VALUE               46860020
         LR    R2,R10        OTHERWISE RESTORE R2 TO PDE ADDRESS        46920020
         CR    R12,R2        SEE IF ADDRESS ARE EQUAL                   46980020
         BE    ADDR0130      BRANCH TO REMOVE                           47040020
         SPACE                                                          47090020
         LA    R1,DEFSEC     OTHERWISE PUT ADDRESS OF SECOND PDE        47100020
*                            INTO REG1 TO SEE IF ONE EXISTS             47160020
         TM    DEFLAGS3,HEX80  CHECK IF AN ADDRESS EXISTS               47220020
         BNO   ADDR0100      IF NOT, THEN CHECK OFF PDE                 47280020
         SPACE                                                          47330020
         LA    R2,PDECHAIN   PLACE ADDRESS OF SECOND PDE IN R2          47340020
         TM    PDEFLG3,HEX80 DOES THE SEC PDE CONTAINS AN ADDRESS       47400020
         BNO   ADDR0210      IF IT DOESNT THEN THIS IS AN ERROR         47460020
         LR    R12,R2        SAVE ADDRESS OF 2 PDE IN R9                47520020
         LR    R3,R2         PUT ADDRESS OF PDE INTO R3                 47580020
         B     ADDR0010      OTHERWISE BRANCH TO PROCESS 2ND PDE        47640020
         SPACE                                                          47690020
ADDR0100 EQU   *             EQUATE LABEL TO THIS ADDRESS               47700020
         LA    R2,PDECHAIN   PLACE ADDRESS OF SECOND PDE IN R2          47760020
         TM    PDEFLG3,HEX80 CHECK IF AN ADDRESS DOES EXIST             47820020
         BO    ADDR0210      IF IT DOES THEN THERE IS AN ERROR          47880020
         SPACE                                                          47930020
ADDR0130 EQU   *             EQUATE LABEL TO THIS ADDRESS               47940020
         L     R14,WORKAREA  POINTER TO TEST'S WORKAREA                 47990020
         USING TSTCWORK,R14  ESTABLISH ADDRESSABILITY                   47992020
         SPACE                                                          47994020
         LA    R14,CWORKCMD  ADDRESS OF OFF'S WORKAREA                  47996020
         DROP  R14           DROP WORKAREA BASE                         47998020
         USING WORKDSCT,R14  ADDRESSABILITY TO OFF'S WORKAREA           47998420
         SPACE                                                          47998820
         LM    R0,R12,TEMPSAV RESTORE REGISTERS TO ENTERING VALUE       48000020
         DROP  R14           DROP OFF'S WORKAREA POINTER                48050020
         SPACE                                                          48052020
         B     @008A1        BRANCH TO CONTINUE INLINE PROCESSING       48060020
ADDR0200 EQU   *             EQUATE LABEL TO THIS ADDRESS               48120020
         OI    TSTFLGS2,CKADDR TURN ON CLEAR ALL LCRS SWITCH            48180020
         B     ADDR0092      BRANCH TO CLEAR ALL LCR ADDRESS            48240020
         SPACE                                                          48290020
ADDR0210 EQU   *             EQUATE LABEL TO THIS ADDRESS               48300020
         NI    TSTFLGS2,HEXFF-CKADDR TURN OFF CLEAR ADDR SWITCH         48360020
         L     R14,WORKAREA  POINTER TO TEST'S WORKAREA                 48410020
         USING TSTCWORK,R14  ADDRESSABILITY TO TEST'S WORKAREA          48412020
         LA    R14,CWORKCMD  GET ADDRESS OF OFF'S WORKAREA              48412420
         SPACE                                                          48414020
         DROP  R14           DROP TEST'S WORKAREA POINTER               48416020
         USING WORKDSCT,R14  ADDRESS OFF'S WORKAREA                     48418020
         LM    R0,R12,TEMPSAV RESTORE ENTERING REGISTERS                48420020
         DROP  R14           DROP OFF'S WORKAREA POINTER                48470020
         B     @007H4        BRANCH TO CONTINUE INLINE PROCESSING       48480020
         SPACE                                                          48530020
ADDR0300 EQU   *             EQUATE LABEL TO THIS ADDRESS               48540020
         LH    R2,DEFLEN3    PUT LENGTH OF ADDRESS FROM DEFER Q IN R2   48600020
         L     R12,DEFADDR   PUT POINTER TO ADDRESS IN DEFER Q IN R12   48660020
         USING IKJPARMA,R3   USE REG3 INSTEAD                           48720020
         LH     R6,PDELEN3   GET LENGTH OF ADDRESS FROM PDE             48780020
*                            CREATED FOR OFF                            48840020
         L     R7,PDEADRPT   PLACE POINTER TO ADDR IN OFFPDE INTO R7    48900020
         CR    R6,R2         COMPARE LENGTHS OF ADDRESS STRINGS         48960020
         BNE   @007H4        IF LENGTHS ARE NOT EQUAL ADDRESSES         49020020
*                            ARE NOT EQUAL. IF EQUAL COMPARE ACTUAL     49080020
         BCTR  R6,@0         DECREMENT R6 BY ONE FOR EXECUTE CODE       49140020
         EX    R6,COMPARIT   COMPARE ADDRESSES                          49200020
         BNE   @007H4        IF NOT EQUAL THEN BRANCH                   49260020
         SPACE                                                          49310020
         CR    R10,R1        SEE IF REG10 EQUALS REG1                   49320020
         BNE   ADDR0310      IF THEY ARENT EQUAL THEN BRANCH            49380020
         LA    R2,@36        WE HAVE TO RESTORE TO FIRST PDE            49440020
         SR    R1,R2         SO WE SUBTRACT 36 FROM EACH SECOND         49500020
         SR    R3,R2         PDE                                        49560020
         B     @008A1        AND BRANCH TO PROCESS THE FOUND PDE        49620020
         SPACE                                                          49670020
ADDR0310 EQU   *             EQUATE LABEL TO THIS ADDRESS               49680020
         LTR   R10,R10       SEE IF WE ARE CHECKING 2ND PDE             49740020
         BNZ   ADDR0130      WE ARE, THEN IT WAS SUCCESSFUL, BRANCH     49800020
         LA    R1,DEFSEC     PLACE ADDRESS OF SECOND PDE IN R1          49860020
         LA    R3,PDECHAIN   PLACE ADDRESS OF SECOND PDE IN R3          49920020
         LR    R10,R1        LOAD R10 WITH R1                           49980020
         TM    PDEFLG3,HEX80 IS THERE IS A SECOND PDE FROM OFF          50040020
         BNO   ADDR0400      IF NOT, THEN BRANCH                        50100020
         SPACE                                                          50150020
         TM    DEFLAGS3,HEX80  SEE IF A SEC PDE EXISTS IN DEFER Q       50160020
         BNO   @007H4        IF IT DOESNT THEN AN ERROR EXISTS          50220020
         B     ADDR0010      OTHERWISE BRANCH TO PROCESS SEC PDE        50280020
         SPACE                                                          50330020
ADDR0400 EQU   *             EQUATE LABEL TO THIS ADDRESS               50340020
         TM    DEFLAGS3,HEX80   SEE IF A SEC PDE EXIST ON DEFER Q       50400020
         BO    @007H4        IF ON THEN WE HAVE AN ERROR CONDITION      50460020
         SH    R3,THIRTYSX   RESTORE R3 TO ENTERING PDE ADDRESS         50520020
         SH    R1,THIRTYSX   GET R1 BACK TO START OF PDE                50580020
         B     @008A1        BRANCH TO REMOVE THIS PDE                  50640020
         SPACE                                                          50690020
@007H4   EQU   *             EQUATE LABEL TO THIS ADDRESS               50700020
         L     R1,DEFCHAIN   PLACE CHAINWORD INTO R1                    50760020
         LA    R1,@0(R1)     ZERO OUT ANY HIGH ORDER DATA               50820020
         LTR   R1,R1         SEE IF A CHAINWORD EXISTS                  50880020
         BZ    @007H41       BRANCH IF NOT                              50940020
         OI    TSTFLGS2,TOFFDEF TURN ON CHAINWD SWITCH                  51000020
         B     @007F21        AND BRANCH TO PROCESS THIS PDE            51060020
         SPACE                                                          51110020
@007H41  EQU   *             EQUATE LABEL TO THIS ADDRESS               51120020
         NI    TSTFLGS2,HEXFF-TOFFDEF TURN OFF LIST SWITCH IF ON        51180020
         L     R2,DBEDBE     GET ADDRESS OF ANY ADDITIONAL PDE          51240020
*                            ASSOCIATED WITH THIS LOADNAME              51300020
         LTR   R2,R2         MAKE SURE THERE ARE MORE                   51360020
         BNZ   @007H5        IF STILL MORE TO PROCESS THEN BRANCH       51420020
         SPACE                                                          51470020
@007H42  EQU  *              EQUATE LABEL TO THIS ADDRESS               51480020
         NI    TSTFLGS3,HEXFF-TCSECTCK    TURN OFF CSECT-ONLY SWITCH    51530020
         TM    TSTFLGS3,TDUPNAME OTHERWISE SEE IF AN ENTERED ADDRESS    51540020
*                            WAS FOUND ON THE DEFERRED QUEUE            51600020
         BNO   @004A2        IF NOT, THEN BRANCH                        51660020
         SPACE                                                          51710020
         NI    TSTFLGS3,HEXFF-TDUPNAME  TURN OFF NAME ALREADY FOUND SW  51720020
         TM    TSTFLGS2,TWHRLOAD     CHECK IF STILL IN VALIDITY EXIT    51770020
         BO    ADCKOK                IF SO, GO BACK TO EXIT ROUTINE     51772020
         SPACE                                                          51780020
         B     @004A3        ELSE, CHECK NEXT ENTERED ADDRESS           51790020
         SPACE                                                          51830020
************************************************************            51840020
**  A CHECK HAS BEEN MADE FOR MORE QUEUE ELEMENTS UNDER   **            51900020
**  THE SPECIFIED LOADNAME. IF MORE EXIST, THE NEXT ELEMENT*            51960020
**  IS NOW ACCESSED.                                      **            52020020
************************************************************            52080020
         SPACE                                                          52130020
@007H5   EQU   *             EQUATE LABEL TO THIS ADDRESS               52140020
         LR    R5,R2         PLACE ADDRESS OF NEXT QUEUE                52200020
*                            ELEMENT INTO REG5                          52260020
         L     R1,DBEPDL     PUT POINTER TO PDL INTO REG1               52320020
         AH    R1,EIGHT      ADVANCE PDL POINTER PASS CONTROL FIELD     52380020
         B      @007G4       BRANCH TO PROCESS NEXT PDE                 52440020
         SPACE                                                          52490020
@008A1   EQU   *             EQUATE LABEL TO THIS ADDRESS               52500020
         TM    DEFUSER,HEX10 SEE IF THIS IS A USELESS PDE               52560020
         BNO   @008A12       IF NOT FLAGGED THEN MOVE ON                52620020
         TM    TSTFLGS3,TCSECTCK ARE WE REMOVING PDES BY CSECT NAME     52680020
         BO    @008A12       IF WE ARE THEN ALSO MOVE ON                52740020
         B     @007H4        CHECK FOR DUPLICATE BREAKPOINTS            52800020
         SPACE                                                          52850020
@008A12  EQU   *             EQUATE LABEL TO THIS ADDRESS               52860020
         L     R2,DEFCHAIN   PLACE CHAINWORD INTO R2                    52920020
         LA    R2,@0(R2)     ZERO OUT ANY HIGH ORDER DATA               52980020
         LTR   R2,R2         SEE IF A CHAIN WORD EXISTS                 53040020
         BZ    @008A11       IF NOT THEN BRANCH                         53100020
         SPACE                                                          53150020
         OI    TSTFLGS2,TOFFDEF   TURN ON CHAINWORD SWITCH              53160020
         MVI   DEFUSER,HEX10   INDICATE A REMOVED PDE FROM THE LIST     53220020
@008A11  EQU   *             EQUATE LABEL TO THIS ADDRESS               53280020
         TM    TSTFLGS2,TWHRLOAD ARE WE LOOKING OR REMOVING             53340020
         BNO   @008A2        IF NOT IN VALIDITY CHECKING THEN BRANCH    53400020
*                            TO REMOVE THE DEFERRED ELEMENT             53460020
         SPACE                                                          53510020
         TM    TSTFLGS3,TDUPNAME WAS A DUPLICATE NAME CHECK WAS DONE    53520020
         BO    @008A2        IF WE HAVE THEN BRANCH TO REMOVE IT        53580020
         OI    TSTFLGS3,TDUPNAME TURN ON DUPLICATE NAME SWITCH          53640020
         B     @007H4        AND BRANCH TO LOOK FOR DUPLICATE ADDR      53700020
         SPACE                                                          53750020
@008A2   EQU   *             EQUATE LABEL TO THIS ADDRESS               53760020
         TM    TSTFLGS2,TOFFDEF SEE IF CHAINWD SWITCH IS ON             53820020
         BNO   @008A21       IF NOT, THEN BRANCH TO REMOVE PDE          53880020
         SPACE                                                          53930020
         MVI   DEFUSER,HEX10    OTHERWISE RENDER THIS PDE USELESS       53940020
         TM    TSTFLGS3,TCSECTCK ARE WE ARE CHECKING CSECTS ONLY        54000020
         BO    @007F3        IF WE ARE BRANCH TO CSECT CHECK ROUTINE    54060020
         B     @007H4        AND BRANCH CHECK IF DONE                   54120020
         SPACE                                                          54170020
@008A21  EQU   *             EQUATE LABEL TO THIS ADDRESS               54180020
         LA    R1,DBEPDL     PLACE ADDRESS OF POINTER INTO R1           54240020
         IKJRLSA (1)         RELEASE THE CORE FOR THE PDL               54300020
          SPACE                                                         54350020
         XR    R0,R0          ZERO OUT R0 TO STORE INTO POINTER         54360020
         ST    R0,DBEPDL     ZERO OUT POINTER TO PDL                    54420020
         LR    R4,R8          PLACE ADDRESS TO BEGINNING OF Q IN R4     54480020
         L     R5,DMEDBE     PLACE POINTER TO DBE INTO R5               54540020
         L     R1,DBEPDL     PLACE POINTER TO PDL INTO R1               54600020
         LTR   R1,R1          IS THIS IS THE ONE REMOVED                54660020
         BNZ   @008D1         IF NOT, THEN BRANCH                       54720020
         SPACE                                                          54770020
         L     R12,DBEINBUF  PUT POINTER TO ENTERED COMMAND IN R12      54800020
         LH    R6,@0(R12)     PUT LENGTH OF COMMAND INTO R6             54840020
         FREEMAIN R,LV=(6),A=(12),SP=1         FREE COMMAND BUFFER      54900020
         SPACE                                                          54950020
         L     R6,DMEDME     PLACE POINTER TO OTHER LOADNAMES IN R6     54980020
         L     R12,DBEDBE    PLACE POINTER TO NEXT QUEUE EL IN R12      55030020
         FREEMAIN R,LV=12,A=(5),SP=1    FREE DBE                        55080020
         SPACE                                                          55130020
         LTR   R12,R12        SEE IF MORE QUEUE ELEMENTS EXIST          55140020
         BNZ  @008C31         IF THERE ARE MORE THEN BRANCH             55200020
         SPACE                                                          55250020
@008B00  EQU  *               EQUATE LABEL TO THIS ADDRESS              55260020
         L    R4,DEFERTAB     PUT POINTER TO DEFER Q IN R4              55320020
         L     R8,DMEDME     PUT POINTER TO NEXT LOADNAME IN R8         55380020
         CR   R8,R6           IS THIS ADDRESS EQUAL TO R6               55440020
         BNE  @008B10         IF NOT, CHECK FURTHER                     55500020
         SPACE                                                          55550020
         ST   R8,DEFERTAB     PUT NEXT LOADNAME PTR INTO DEFERTAB       55560020
@008B05  EQU  *               EQUATE LABEL TO THIS ADDRESS              55620020
         FREEMAIN R,LV=16,A=(4),SP=1  FREE UP THE QUEUE ELEMENT         55680020
         SPACE                                                          55730020
         B     @004A2         BRANCH TO CHECK IF DONE                   55740020
         SPACE                                                          55790020
@008B10  EQU   *              EQUATE LABEL TO THIS ADDRESS              55800020
         L     R12,DEFERTAB   PUT POINTER TO BEGINNING OF Q IN R12      55860020
@008B15  EQU   *              EQUATE LABEL TO THIS ADDRESS              55920020
         LR    R4,R8          PLACE NEXT LOADNME POINTER INTO R4        55980020
         L     R8,DMEDME     PLACE POINTER TO NEXT LOADNAME IN R8       56040020
         CR    R8,R6          SEE IF THIS ONE IS EQUAL TO R6            56100020
         BNE   @008B20        IF NOT THEN BRANCH TO LOOK FURTHER        56160020
         ST    R8,@12(R12)    OTHERWISE PLACE THIS ADDR INTO LAST DME   56220020
         B     @008B05        AND BRANCH TO FREE UP THIS DME            56280020
        SPACE                                                           56330020
@008B20  EQU   *              EQUATE LABEL TO THIS ADDRESS              56340020
         L     R12,@12(R12)   PLACE DME ADDRESS INTO R12                56400020
         B     @008B15        BRANCH TO PROCESS NEXT DME                56460020
         SPACE                                                          56510020
@008C31  EQU      *           EQUATE LABEL TO THIS ADDRESS              56520020
         ST    R12,DMEDBE    STORE POINTER TO NEXT DBE IN               56580020
*                             IN PREVIOUS DBE                           56640020
@008C3   EQU      *           EQUATE LABEL TO THIS ADDRESS              56700020
         TM    TSTFLGS3,TCSECTCK SEE IF A CSECT ONLY WAS ENTERED        56760020
         BO    @007F31        IF SO, THEN BRANCH                        56820020
         SPACE                                                          56870020
         L     R5,DMEDBE     PLACE POINTER TO DBE INTO R5               56900020
         L     R1,DBEPDL     PLACE POINTER TO PDL INTO R1.              56950020
         B     @007H41        BR TO PROCESS FOR DUPNAME                 57000020
         SPACE                                                          57050020
@008D1   EQU   *              EQUATE LABEL TO THIS ADDRESS              57060020
         LR    R4,R5          PLACE PREVIOUS POINTER INTO R4            57120020
         L     R5,DBEDBE     PLACE POINTER TO NEXT DBE IN R5            57180020
         L     R1,DBEPDL     PLACE POINTER TO PDL INTO R1.              57240020
         LTR   R1,R1          SEE IF THIS IS THE ONE REMOVED            57300020
         BNZ   @008D1         IF NOT, THEN BRANCH FOR NEXT ONE          57360020
         SPACE                                                          57410020
         L     R12,DBEINBUF  PUT POINTER TO ENTERED ADDRESS IN R12      57440020
         LH    R6,@0(R12)     PUT LENGTH OF ADDRESS INTO R6             57480020
         FREEMAIN R,LV=(6),A=(12),SP=1   FREE COMMAND BUFFER            57540020
         SPACE                                                          57590020
         L     R12,DBEDBE    PLACE PTR TO NEXT QUEUE ELM INTO R12       57620020
         FREEMAIN R,LV=12,A=(5),SP=1    FREE DEFER BREAK ELEMENT        57660020
         SPACE                                                          57710020
         ST      R12,@8(R4)   PLACE POINTER TO NEXT DBE IN LAST DBE     57720020
         LR      R5,R4        PLACE POINTER TO QUEUE ELEMENT IN R5      57780020
         TM      TSTFLGS3,TCSECTCK    ARE WE CHECKING CSECTS ONLY       57840020
         BO      @007F31      IF SO, THEN BRANCH TO CSECT AREA          57900020
         B       @007H41      OTHERWISE BRANCH TO CHECK NEXT ELEM       57960020
         SPACE                                                          58010020
@011A1   EQU   *                                                        58680020
         L     R4,DEFERTAB    PLACE POINTER TO DEFER Q INTO R4          58740020
         LTR   R4,R4          SEE IF A QUEUE EXIST                      58800020
         BZ    @003E5         IF NOT, RETURN TO MAINLINE                58860020
         SPACE                                                          58910020
@011A2   EQU   *              EQUATE LABEL TO THIS ADDRESS              58920020
         L     R5,DMEDBE     PLACE POINTER TO FIRST DBE IN R5           58980020
         L     R3,DMEDME     PLACE POINTER TO NEXT LOADNAME IN R3       59040020
         FREEMAIN R,LV=16,A=(4),SP=1  FREE THE FIRST ELEMENT            59100020
         SPACE                                                          59150020
@011A3   EQU    *             EQUATE LABEL TO THIS ADDRESS              59160020
         LA    R1,DBEPDL     PLACE POINTER TO PDL INTO R1               59220020
         IKJRLSA (1)          RELEASE THIS PDL                          59280020
         SPACE                                                          59330020
         L     R2,DBEDBE     PUT POINTER TO NEXT DBE INTO R2            59360020
         L     R4,DBEINBUF   PUT POINTER TO INPUT COMMAND IN R4         59410020
         FREEMAIN R,LV=12,A=(5),SP=1  FREE THIS ELEMENT                 59460020
         SPACE                                                          59510020
         LH     R5,@0(R4)     PLACE LENGTH OF INPUT AREA IN R5          59520020
         SPACE                                                          59570020
         FREEMAIN R,LV=(5),A=(4),SP=1 FREE INPUT AREA                   59580020
         SPACE                                                          59630020
         LTR     R2,R2        SEE IF ANYMORE ELEMENTS EXIST             59640020
         BZ      @011A4       IF NOT THEN BRANCH TO CHECK IF            59700020
*                             ANYMORE LOADNAMES EXIST                   59760020
         LR      R5,R2        OTHERWISE PLACE POINTER INTO R5           59820020
         B       @011A3       BRANCH TO REMOVE THIS PDL AND DBE         59880020
         SPACE                                                          59930020
@011A4   EQU     *            EQUATE LABEL TO THIS ADDRESS              59940020
         LTR      R3,R3       SEE IF ANYMORE LOADNAMES EXIST            60000020
         BNZ      @011A5      IF MORE THEN BRANCH TO REMOVE THEM        60060020
         ST       R3,DEFERTAB ZERO OUT DEFER TABLE POINTER              60120020
         B        @003E5      IF NO MORE THEN BRANCH TO GO BACK         60180020
         SPACE                                                          60230020
@011A5   EQU      *           EQUATE LABEL TO THIS ADDRESS              60240020
         LR      R4,R3        OTHERWISE PLACE POINTER INTO R4 AND       60300020
         B       @011A2       BRANCH TO PROCESS THIS QUEUE ELEMENT      60360020
         EJECT                                                          60390020
********************************************************                60420020
** THIS IS THE BEGINNING OF THE ADDRESS VALIDITY      **                60480020
** CHECK ROUTINE ENTERED AUTOMATICALLY FROM PARSE.    **                60540020
********************************************************                60600020
         SPACE                                                          60650020
IKJEGVCK EQU   *              EQUATE LABEL TO THIS ADDRESS              60660020
         SAVE  (14,12)        SAVE REGISTERS                            60720020
         USING IKJEGVCK,R15   USE REG15 AS BASE REGISTER                60780020
         SPACE                                                          60830020
         L     R2,@4(R1)      PLACE POINTER TO OFF'S SAVE AREA IN R2    60840020
         LM    R3,R11,@32(R2) PARTIALLY RESTORE OFF'S REGISTERS         60900020
         DROP  R15            DROP REG 15 AS A BASE REG                 60960020
         USING IKJEGOFF,R11   USE REG11 AS BASE REGISTER                61020020
         SPACE                                                          61070020
         L     R4,REGSAVE3    PLACE ADDRESS OF MY SAVE AREA IN R4       61080020
         ST    R4,@8(R13)     PLACE BACKWARD POINTER                    61140020
         ST    R13,@4(R4)     PALCE FORWARD POINTER                     61200020
         LR    R13,R4         PLACE POINTER TO MY SAVEAREA INTO R13     61260020
         SPACE                                                          61310020
         L     R2,WORKAREA    GET ADDRESS OF TEST'S WORKAREA            61312020
         USING TSTCWORK,R2    SET UP ADDRESSABILITY TO TEST'S WORKAREA  61314020
         LA    R2,CWORKCMD    GET ADDRESS OF OFF'S WORKAREA             61316020
         DROP  R2             DROP TEST WORKAREA BASE                   61318020
         USING WORKDSCT,R2    SET UP ADDRESSABILITY TO WORK DSECT       61318420
         SPACE                                                          61318820
         ST    R1,PARSLST     SAVE PTR TO PARSE VALIDITY PARAM LIST     61319220
         DROP  R2             DROP WORKAREA ADDRESSABILITY              61319320
         SPACE                                                          61319620
         USING IKJPARMA,R3    USE REG3 TO ADDRESS PDE FROM OFF          61320020
         L     R3,BREAKTAB    PLACE POINTER TO ACTIVE QUEUE IN R3       61380020
         LA    R3,@0(R3)      ZERO OUT ANY HIGH ORDER DATA              61440020
         LTR   R3,R3          SEE IF ANY BREAK ELEMENTS EXIST           61500020
         BNZ   ADDSTART       BRANCH TO PROCESS THE ENTERED ADDRESS     61560020
         SPACE                                                          61610020
         L     R3,DEFERTAB    PLACE POINTER TO DEFER TABLE IN R3        61620020
         LA    R3,@0(R3)      ZERO OUT ANY HIGH ORDER DATA              61680020
         LTR   R3,R3          SEE IF A POINTER DOES EXIST               61740020
         BNZ   ADDSTART       IF IT DOES THEN BRANCH TO PROCESS         61800020
         SPACE                                                          61850020
         L     R1,MSSG8       PLACE NO ELEMENTS EXIST MSG IN R1         61860020
         XR    R4,R4          CLEAR OUT SECOND LEVEL MESSAGE POINTER    61920020
*                             NONE EXISTS.                              61970020
         BAL   R12,ADCK0013   BRANCH TO PUT MESSAGE OUT TO TERMINAL     61980020
         SPACE                                                          62030020
         XR    R15,R15        ZERO OUT REG 15 AS A RETURN CODE          62040020
         B     ADCK0014       BRANCH TO RETURN TO PARSE                 62100020
         SPACE                                                          62150020
ADDSTART EQU    *             EQUATE LABEL TO THIS ADDRESS              62160020
         L      R3,@0(R1)     PLACE POINTER TO PDE INTO R3              62220020
         TM    PDEFLG1,HEX80  WE WILL CHECK IF ANY ADDRESSES WERE       62280020
*                             SPECIFIED                                 62340020
         BO    ADCK0020       IF THERE IS A LOADNAME THEN BRANCH        62400020
         TM    PDEFLG2,HEX80  WAS AN ENTRYNAME SPECIFIED                62460020
         BO    ADCK0020       IF SO THEN BRANCH TO CHECK IT             62520020
         BAL   R12,ADCK0000   IF NOT, CHECK FURTHER                     62580020
         SPACE                                                          62590020
         LR    R8,R3          SAVE FIRST PDE ADDRESS                    62600020
         LA    R3,PDECHAIN    GET ADDRESS OF SECOND PDE                 62610020
         SPACE                                                          62620020
         BAL   R12,ADCK0000   GO CHECK SECOND PDE ADDRESS               62628420
         SPACE                                                          62628520
ADCK000A LR    R3,R8          RESTORE FIRST PDE ADDRESS                 62628820
         B     ADCK0020       GO TO CONVERT                             62629220
         SPACE                                                          62630020
ADDFOUND EQU   *              EQUATE LABEL TO THIS ADDRESS              62640020
         XR    R15,R15        PLACE A ZERO RETURN CODE INTO R15         62700020
         XR    R4,R4          SINCE NO 2ND LEVEL MSG ZERO OUT PTR       62760020
         B     ADCK0014       BRANCH TO RETURN TO PARSE                 62820020
         SPACE                                                          62870020
ADCK0000 EQU   *              EQUATE LABEL TO THIS ADDRESS              62880020
         TM    PDEFLG4,HEX20  SEE IF REGISTER NOTATION WAS USED         62940020
         BNO   ADCK0030       IF IT WASNT THEN BRANCH TO CHECK MORE     63000020
         LH    R7,PDEINDCT    PLACE INDIRECT ADDRESSING COUNT IN  R7    63060020
         LTR   R7,R7          TEST IF INDIRECT ADDRESSING WAS USED      63120020
         BZ    ADCK000B       IF NOT, PUT OUT MESSAGE                   63180020
         SPACE                                                          63230020
         BR    R12            IF SO, RETURN                             63232020
         SPACE                                                          63234020
ADCK000B L     R1,MSSG1       PLACE MSG NO INDIRECTING INTO R1          63240020
         SPACE                                                          63290020
********************************************************                63300020
** THIS ROUTINE WILL TRANSFER A MESSAGE FROM THE      **                63360020
** MESSAGE CSECT TO AN OUTPUT AREA AND THEN BRANCH    **                63420020
** TO TEST'S ADDRESS BUILD ROUTINE TO CONSTRUCT AN    **                63480020
** INVALID ADDRESS MESSAGE.                           **                63540020
********************************************************                63600020
         SPACE                                                          63650020
ADCK0001 EQU   *             EQUATE LABEL TO THIS ADDRESS               63660020
         L     R8,@0(R1)     PLACE POINTER TO FIRST MSG INTO R8         63780020
         L     R4,@4(R1)     PLACE 2ND LEVEL MSG INTO REG10             63840020
         LH    R6,@0(R8)     PLACE LENGTH OF MSG INTO R6                63900020
         L     R5,OUTBUF     PLACE ADDRESS OF OUTPUT AREA INR5          63960020
         MVI   @0(R5),BLANK  PLACE A BLANK INTO FIRST BYTE OF OUTPUT    64020020
         MVC   @1(@60,R5),@0(R5) SPREAD THIS BLANK THRU OUTPUT          64080020
         SPACE                                                          64130020
         BCTR  R6,@0         DECREMENT R6 FOR EXECUTE INSTRUCTION       64140020
         EX    R6,CHANGEO    MOVE MSG FROM MSG CSECT TO OUTPUT          64200020
         LA    R6,@10(R6)    RESTORE R6 TO ORIGINAL VALUE + 8 BYTES     64260020
         AR    R5,R6         INCREMENT R5 TO POINT AFTER MESSAGE        64320020
         LR    R1,R5         PLACE POINTER TO END OF MSG IN R1          64380020
         LR    R0,R3         PLACE POINTER TO PDE INTO R0               64440020
         L     R15,TSTADDR   PLACE ADDR OF MSG BUILD ROUTINE IN R15     64500020
         BALR  R14,R15       BRANCH TO ADDRESS BUILD ROUTINE            64560020
         SPACE                                                          64610020
         SR    R5,R6         RESTORE R5 TO BEGINNING ADDR OF OUTBUF     64620020
         AR    R6,R0         ADD ADDRESS LENGTH TO MESSAGE LENGTH       64680020
ADCK0012 EQU   *             EQUATE LABEL TO THS ADDRESS                64740020
         AR    R5,R6         MAKE R5 POINT TO END OF ENTIRE MESSAGE     64800020
         MVI   @0(R5),PLUS   MOVE A + INTO END OF MESSAGE               64860020
         SR    R5,R6         RESTORE R5 TO BEGINNING OF OUTBUF          64920020
         SH    R6,SEVEN      REDUCE R6 BY 8 BYTES                       64980020
         STH   R6,@8(R5)     PLACE LENGTH OF MESSAGE INTO OUTBUF        65040020
         LA    R6,@8(R5)     PLACE POINTER TO MESSAGE INTO R4           65100020
         ST    R6,@0(R5)     STORE THIS INTO FIRST WORD OF OUTPUT       65160020
         ST    R4,@4(R5)     STORE THIS AS SECOND POINTER               65220020
         LR    R1,R5         PLACE POINTER TO OUTPUT LINE IN R1         65280020
         BAL   R12,ADCK0013  BRANCH TO PUT MESSAGE OUT TO TERMINAL      65340020
         SPACE                                                          65390020
         LA    R15,@8        SET RETURN CODE TO 8 FOR PARSE             65400020
*                            TO PROMPT                                  65450020
         B     ADCK0014      BRANCH TO RETURN TO PARSE                  65460020
         SPACE                                                          65510020
ADCK0013 EQU    *            EQUATE LABEL TO THIS ADDRESS               65520020
         LCR   R1,R1         LOAD COMPLIMENT OF R1 AS INDICATOR         65580020
         L     R15,TPUTADDR  PLACE ADDRESS OF IO MODULE INTO R15        65640020
         BALR  R14,R15       BRANCH TO IO MODULE TO PUT MSG OUT         65700020
         SPACE                                                          65750020
         LTR   R15,R15       TEST THE RETURN CODE FROM IO               65760020
         BZ    ADCK0010      BRANCH TO RETURN TO PARSE WITH RC OF8      65820020
         LA    R8,@16        OTHERWISE CHECK ATTENTION                  65880020
         CR    R15,R8        SEE IF ATTENTION WAS ISSUED                65940020
         BE    SAVECODE      IF SO, SAVE RETURN CODE                    66060020
         SPACE                                                          66110020
ADCK0010 EQU   *             EQUATE LABEL TO THIS ADDRESS               66120020
         BR    R12           BRANCH TO RETURN TO NEXT INSTRUCTION       66180020
         SPACE                                                          66230020
ADCK0014 EQU   *             EQUATE LABEL TO THIS ADDRESS               66240020
         L     R2,WORKAREA   PLACE POINTER TO WORKAREA INTO R2          66360020
         USING TSTCWORK,R2   SET UP ADDRESSABILITY TO TEST'S WORKAREA   66410020
         LA    R2,CWORKCMD   GET ADDRESS OF OFF'S WORKAREA              66412020
         DROP  R2            DROP TEST WORKAREA BASE                    66414020
         USING WORKDSCT,R2   SET UP ADDRESSABILITY TO OFF'S WORKAREA    66416020
         SPACE                                                          66418020
         L     R2,PARSLST                                               66418420
         ST    R4,@8(R2)     SET UP 2ND LEVEL MSG IN PARAMETER LIST     66420020
         LR    R1,R2         PLACE POINTER TO LIST INTO R1              66540020
         L     R13,@4(R13)   PLACE CALLERS SAVE AREA INTO R13           66660020
         SPACE                                                          66690020
         RETURN (14,12),RC=(15)      RETURN TO PARSE TO SCAN MORE       66720020
         EJECT                                                          66750020
ADCK0020 EQU   *             EQUATE LABEL TO THIS ADDRESS               66780020
         TM    PDEFLG1,HEX80 CHECK IF LOADNAME WAS ENTERED              66840020
         BNO   ADCK0021      IF NONE THEN DONT TURN ON SYM SWITCH       66900020
         OI    TSTFLGS3,SYMMESG  TURN ON SWITCH TO STOP SYM'S MSG       66960020
ADCK0021 EQU   *             EQUATE LABEL TO THIS ADDRESS               67020020
         OI    TSTFLGS1,RANGESW  TURN ON RANGE SWITCH                   67080020
         LR    R1,R3         PLACE POINTER TO PDE INTO R1               67140020
         LCR   R1,R1         LOAD COMPLIMENT OF R1 AS INDICATOR TO CVT  67200020
         L     R15,TSTCONVT  PLACE ADDRESS OF CONVERT INTO R15          67260020
         BALR  R14,R15       BRANCH TO CONVERT                          67320020
         SPACE                                                          67330020
         LR    R2,R3         SAVE PTR TO FIRST PDE                      67332020
         TM    TSTFLGS1,RANGESW   CHECK IF RANGE SWITCH IS ON           67340020
         BO    PDE1               IF SO, ONLY FIRST PDE  WAS PROCESSED  67350020
         SPACE                                                          67360020
         LA    R3,PDECHAIN   GET PTR TO SECOND PDE                      67364020
PDE1     L     R4,PDEUSER    GET ADDR OF SECOND LEVEL MSG IN            67366020
*                            CASE OF BAD CONVERT                        67368020
         LR    R3,R2         RESET PTR TO FIRST PDE                     67368420
         SPACE                                                          67370020
         NI    TSTFLGS3,HEXFF-SYMMESG TURN OFF SYM MSG SWITCH           67380020
         NI    TSTFLGS1,HEXFF-RANGESW  TURN OFF CVT RANGE SWITCH        67440020
         LTR   R15,R15       SEE IF CONVERT WAS SUCCESSFUL              67500020
         BZ    ADCK0100      IF IT WAS THEN BRANCH                      67560020
         SPACE                                                          67610020
         LA    R8,@16        CHECK IF ATTENTION WAS ISSUED              67680020
         CR    R15,R8        CHECK IF ATTENTION WAS ISSUED              67740020
         BNE   ADCK0024      IF NOT, CHECK FOR LOADNAME                 67800020
         SPACE                                                          67810020
SAVECODE STC   R15,CONVRTCD  ELSE, SAVE RETURN CODE                     67852020
         LA    R15,@12       SET RETURN CODE TO 12 FOR PARSE            67854020
         B     ADCK0014      BRANCH TO RETURN TO PARSE                  67856020
         SPACE                                                          67858020
ADCK0024 TM    PDEFLG1,HEX80 CHECK IF LOADNAME WAS ENTERED              67860020
         BO    ADCK0025      IF IT IS THEN WE HAVE MORE TO DO           67920020
         LA    R15,@8        ELSE, SET RETURN CODE TO 8 FOR REENTER     67980020
         B     ADCK0014      AND BRANCH TO RETURN                       68040020
         SPACE                                                          68090020
*                            IF ADDRESS IS QUALIFIED IT COULD BE ON     68100020
*                            THE DEFERRED QUEUE                         68160020
ADCK0025 EQU   *             EQUATE LABEL TO THIS ADDRESS               68220020
         LR    R2,R3         SAVE POINTER TO FIRST PDE IN R2            68280020
         LA    R3,PDECHAIN   PLACE ADDRESS OF SECOND PDE IN R3          68340020
         TM    PDEFLG1,HEX80 SEE IF THE SECOND ADDRESS IS QUALIFIED     68400020
         BO    ADCK0028      IF IT IS THEN BRANCH TO CHECK DEFER        68460020
         TM    PDEFLG3,HEX80 SEE IF ANY ADDRESS DOES EXIST IN           68520020
*                            THE SECOND PDE                             68580020
         SPACE                                                          68630020
************************************************************            68640020
**    IF THE FIRST ADDRESS IS FULLY QUALIFIED AND THE     **            68700020
**  SECOND PDE CONTAINS NO ADDRESS AT ALL, THEN A SINGLE  **            68760020
**  ADDRESS MAY EXIST ON THE DEFERRED QUEUE. BEFORE A     **            68820020
**  MESSAGE IS PUT OUT TO THE TERMINAL, A CHECK MUST BE   **            68880020
**  MADE TO DETERMINE IF A SINGLE ADDRESS EXISTS.         **            68940020
************************************************************            69000020
         SPACE                                                          69050020
         BNO   ADCK0028      IF NONE EXIST CHECK DEFERRED QUEUE         69060020
         B     ADCK0029      OTHERWISE BRANCH TO PUT MESSAGE OUT        69120020
         SPACE                                                          69170020
ADCK0027 EQU   *             EQUATE LABEL TO THIS ADDRESS               69180020
         TM    PDEFLG1,HEX80 WAS A FULLY QUALIFIED NAME WAS ENTERED     69240020
         BO    @007A1        IF IT WAS BRANCH TO CHECK DEFERRED Q       69300020
         XI    TSTFLGS2,TWHRLOAD IF DONE TURN OFF LOOKING SWITCH        69360020
ADCK0270 EQU   *             EQUATE LABEL TO THIS ADDRESS               69420020
         L     R1,MSSG3      PUT UNABLE TO LOCATE MESSAGE INTO OUTPUT   69480020
         B     ADCK0001      BRANCH TO PUT MESSAGE OUT TO TERMINAL      69540020
         SPACE                                                          69590020
ADCK0028 EQU   *             EQUATE LABEL TO THIS ADDRESS               69600020
         LR    R3,R2         RESTORE R3 TO POINT TO FIRST PDE           69660020
         OI    TSTFLGS2,TWHRLOAD TURN ON LOOKING BUT NOT REMOVING       69720020
         B     @007A1        BRANCH TO MAIN OFF TO SEE IF WE CAN        69780020
*                            FIND THIS ADDRESS ON THE DEFER TABLE       69840020
         SPACE                                                          69890020
ADCK0029 EQU   *             EQUATE LABEL TO THIS ADDRESS               69900020
         L     R1,MSSG4      PUT UNABLE TO CONVERT MESSAGE INTO R1      69960020
         L     R4,PDEUSER    PUT POSSIBLE MESSAGE POINTER INTO R4       70020020
         B     ADCK0001      BRANCH TO MESSAGE OUT TO TERMINAL          70080020
         SPACE                                                          70130020
ADCK0100 EQU   *             EQUATE LABEL TO THIS ADDRESS               70140020
         OI    TSTFLGS2,TWHRLOAD TURN ON LOOKING BUT NOT REMOVING       70200020
         B     @000A0        BRANCH TO LOOK FOR THIS ADDRESS ON QUE     70260020
         SPACE                                                          70310020
ADCK0030 EQU   *             EQUATE LABEL TO THIS ADDRESS               70320020
         TM    PDEFLG4,LFPR  CHECK IF FLOATING POINT WAS USED           70380020
         BO    ADCK0031      IF IT IS THEN ADDRESS IS INVALID           70440020
         TM    PDEFLG4,SFPR  CHECK FLOATING POINT                       70500020
         BO    ADCK0031      IF IT IS THEN ADDRESS IS INVALID           70560020
         BR    R12           OTHERWISE BRANCH TO PROCESS FURTHER        70620020
         SPACE                                                          70670020
ADCK0031 EQU   *             EQUATE LABEL TO THIS ADDRESS               70680020
         L     R1,MSSG1      LOAD MESSAGE THAT FLOATING POINT REG ARE   70740020
*                            INVALID                                    70800020
         B     ADCK0001      BRANCH TO PUT OUT MESSAGE                  70860020
         SPACE 3                                                        70910020
************************************************************            70920020
**             STAE RETRY CODE AND CONSTANTS                            70980020
************************************************************            71040020
         SPACE 3                                                        71090020
LISTSTAE STAE  MF=L           LIST FORM OF STAE                         71100020
ARETRY   DC    AL3(RETRY)     ADDRESS OF RETRY ROUTINE                  71160020
         DS    0F                                                       71220020
STAETAB  EQU   *                                                        71280020
         DC    A(FREEIT)      POINTER TO WHERE WE MOVE INST BACK IN     71340020
         DC    X'03'          POINTER TO CORRECT MESSAGE                71400020
         DC    AL3(BLOWUP1)   POINTER TO POSSIBLE BLOW UP AREA          71460020
         DC    X'FF'          END OF TABLE                              71520020
         DS    0H             ALIGNMENT TO HALFWORD BOUNDARY            71580020
RETRY    EQU   *              BEGINNING OF RETRY ROUTINE                71640020
         L     R4,CVTPTR      PLACE ADDRESS OF CVT INTO R4              71700020
         USING CVT,R4         SET UP ADDRESSABILITY TO CVT DSECT        71760020
         L     R4,CVTTCBP     GET ADDRESS OF CURRENT TCB                71820020
         L     R4,TCBADR(@0,R4) FROM CVT                                71880020
         DROP  R4                                                       71940020
         USING TCB,R4         USE R4 TO ADDRESS TCB DSECT               72000020
         SPACE                                                          72050020
         L     R9,TCBTRN      PLACE TEST CONTROL CORE TABLE ADDR IN R9  72060020
         L     R13,REGSAVE2   PLACE POINTER TO MY SAVEAREA INTO R13     72120020
         L     R11,MYBASE(R13) RESTORE MY BASE REGISTER                 72180020
         LTR   @0,@0          TEST REG0 FOR ZERO                        72240020
         BNZ   NOWORK         IF NOT ZERO STAE DID NOT WORK             72300020
         SPACE                                                          72350020
         FREEMAIN R,LV=104,A=(1) IF ZERO THEN ISSUE FREEMAIN            72360020
         SPACE                                                          72410020
NOWORK   EQU   *              IF NOT ZERO BRANCH HERE                   72420020
         L     R2,WORKAREA    PLACE WORKAREA POINTER IN REG2            72480020
         USING TSTCWORK,R2    SET UP ADDRESSABILITY                     72540020
         LA    R2,CWORKCMD    R2 = ADDRESS OF OFF'S WORKAREA            72590020
         SPACE                                                          72592020
         DROP  R2             DROP ADDRESS OF TEST'S WORKAREA           72594020
         USING WORKDSCT,R2    ADDRESSABILITY TO OFF'S WORKAREA          72596020
         SPACE                                                          72598020
         MVC   WORKLST(@12),LISTSTAE   MOVE LIST FORM OF STAE INTO      72598420
*                                      WORKAREA                         72598820
         LA    R1,WORKLST     PLACE ADDRESS OF LIST FORM IN R1          72600020
         L     R2,TSTSTAE     GET STAE'S ADDRESS FROM TCOMTAB           72660020
         SPACE                                                          72710020
         STAE  (R2),MF=(E,(1))  ISSUE STAE MACRO                        72720020
         SPACE                                                          72770020
         LM    @14,@12,@12(R13) RESTORE MY REGISTERS                    72780020
         TM    TSTFLGS1,BOMBSW  SEE IF AN 0C4 ABEND OCCURRED IN         72840020
*                               PUTTING BACK INSTRUCTION                72890020
         BO    FREEIT         IF SO, THEN BRANCH TO FREE BREAK ELEM     72900020
         SPACE                                                          72950020
         NI    TSTFLGS3,HEXFF-TCSECTCK-TDUPNAME TURN OFF MY SWITCHES    72960020
         NI    TSTFLGS2,HEXFF-TOFFDEF-TTESTTCB-TWHRLOAD AND THESE TOO   73020020
         L     R13,REGSAVE2   PLACE MY SAVE AREA INTO REG13             73080020
         LA    R15,@20        PLACE A RETURN CODE OF 20 INTO R15        73140020
         B     @003E6         BRANCH TO RETURN TO MAINLINE              73200020
         TITLE 'IKJEGOFF, ''OFF'' SUBCOMMAND, MACROS AND CONSTANTS'     73250020
************************************************************            73260020
**                                                        **            73320020
**                        PARSE PARAMETER LIST            **            73380020
**                                                        **            73440020
************************************************************            73500020
IKJEGPCL IKJPARM                                                        73560020
GETADDR  IKJPOSIT  ADDRESS,LIST,RANGE,VALIDCK=IKJEGVCK                  73620020
         IKJENDP                                                        73680020
         EJECT                                                          73710020
PCLISTA  DC    V(IKJEGPCL)        ADDRESS OF PCL CSECT                  73740020
COMPENTY CLC   @0(@1,R7),@0(R10)  THIS INSTRUCTION COMPARES ENTRYNAMES  73800020
COMPADDR CLC   @0(@1,R7),@0(R8) CHECK ADDRESSES IF EQUAL                73860020
COMPARIT CLC   @0(@1,R7),@0(R12) COMPARE ADDRESSES                      73920020
MOVENAME MVC   @0(@1,R6),@0(R1)  MOVE LOADNAME INTO WORKAREA            73980020
MOV2OUT  MVC   @37(@1,R5),@0(R4) MOVE ADDRESS FROM PDE TO OUTPUT        74040020
CHANGEO  MVC   @8(@1,R5),@0(R8) MOVE MESSAGE FROM CSECT TO OUTPUT       74100020
TSTMAP   DC    X'00'         REMOVE THIS CARD AND PLACE SW INTO TCOMTAB 74160020
         SPACE                                                          74170020
CLOSELST CLOSE (CLOSELST),MF=L     LIST FORM OF CLOSE                   74180020
CLOSELN  EQU   *-CLOSELST    LENGTH OF CLOSE LIST                       74190020
         SPACE                                                          74200020
         DS    0F                                                       74220020
ANDVALUE DC    X'0000000F'    MASK VALUE                                74280020
SVCCODE  DC    X'08000000'    IC CHANGE CODE                            74340020
SUBPOOL1 DC    X'01000000'    SUBPOOL ONE                               74400020
EIGHT    DC    X'0008'        NO. 8                                     74460020
SEVEN    DC    X'0007'        NO. 7                                     74520020
FOUR     DC    X'0004'        NO. 4                                     74580020
SIXTEEN  DC    X'0010'        NO. 16                                    74640020
SVC97    DC    X'0A61'        SVC 97 CODE                               74700020
THIRTYSX DC    X'0024'        NO. 36                                    74760020
MSSG1    DC    V(IKJEGMS1)    ADDRESS OF 'INVALID ADDRESS' MESSAGE      74820020
MSSG3    DC    V(IKJEGMS3)    ADDRESS OF 'INVALID BREAKPOINT' MSG       74880020
MSSG4    DC    V(IKJEGMS4)    ADDRESS OF 'INVALID ADDRESS' MESSGAE      74940020
MSSG8    DC    V(IKJEGMS8)    ADDRESS OF 'NO BREAKPOINTS FOUND' MSG     75000020
PARSERR1 DC    V(IKJEGMS9)    ADDRESS OF 'PARSE RC = 12' MESSAGE        75060020
MSSG10   EQU   *              EQUATE MSG10 TO THIS ADDRESS              75120020
PARSERR2 DC    V(IKJEGMSA)    ADDRESS OF 'NO CORE' MESSAGE              75180020
MSSG12   DC    A(IKJEGM12)    POINTER TO INVALID RANGE MSG ADDRESS      75250020
         EJECT                                                          75290020
************************************************************            75300020
**                                                        **            75360020
**             EQUATES                                    **            75420020
**                                                        **            75480020
************************************************************            75540020
         SPACE                                                          75590020
         REGEQU               REGISTER EQUATES                          75592020
         SPACE                                                          75594020
BLANK    EQU   X'40'          BLANK                                     76560020
PLUS     EQU   C'+'           PLUS SIGN                                 76610020
MYBASE   EQU   64             REG 11 DISPLACEMENT                       76620020
REG10    EQU   10             REG 10                                    76680020
REG4     EQU   4              REG 4                                     76740020
@12      EQU   12             NO. 12                                    76800020
@10      EQU   10             NO. 10                                    76860020
@16      EQU   16             NO. 16                                    76920020
@21      EQU   21             NO. 21                                    76980020
@20      EQU   20             NO. 20                                    77040020
@60      EQU   60             NO. 60                                    77100020
@39      EQU   39             NO. 39                                    77160020
@37      EQU   37             NO. 37                                    77220020
@24      EQU   24             NO. 24                                    77280020
@36      EQU   36             NO. 36                                    77340020
@0       EQU   0              NO. 0                                     77400020
@3       EQU   3              NO. 3                                     77460020
@68      EQU   68             NO. 68                                    77520020
@2       EQU   2              NO. 2                                     77580020
@9       EQU   9              NO. 9                                     77640020
HEX80    EQU   X'80'          HEX 80                                    77700020
HEXFF    EQU   X'FF'          HEX FF                                    77760020
HEX40    EQU   X'40'          HEX 40                                    77820020
HEX04    EQU   X'04'          HEX 04                                    77880020
HEX10    EQU   X'10'          HEX 10                                    77940020
DCBOFLGS EQU   X'30'          DISPLACEMENT TO OPEN/CLOSE FLAG IN DCB    77960020
@72      EQU   72             DISPLACEMENT IN TSTSYMWK FOR DCB ADDR     77980020
@7       EQU   7              NO. 7                                     78000020
@1       EQU   1              NO. 1                                     78060020
@8       EQU   8              NO. 8                                     78110020
ZERO     EQU   0              NO. 0                                     78180020
@4       EQU   4              NO. 4                                     78240020
@32      EQU   32             NO. 32                                    78300020
@52      EQU   52             NO. 52                                    78360020
HEX20    EQU   X'20'          HEX 20                                    78420020
HEX18    EQU   X'18'          HEX 18                                    78480020
TSTSVC   EQU   97             BREAKPOINT SVC                            78540020
ON       EQU   X'80'          MASK SWITCH                               78600020
OFF      EQU   X'80'          MASK                                      78660020
CKADDR   EQU   B'00010000'    MASK                                      78720020
TCBADR   EQU   4              DISPLACEMENT TO TCB                       78780020
@14      EQU   14             NO. 14                                    78840020
@64      EQU   64             NO. 64                                    78900020
         EJECT                                                          78950020
********************************************************                78960020
**                                                    **                79020020
**         MESSAGE CSECT FOR IKJEGOFF                 **                79080020
**                                                    **                79140020
********************************************************                79200020
IKJEGMSG CSECT               MESSAGE CSECT FOR OFF MESSAGES             79260020
         ENTRY IKJEGMS1                                                 79320020
         ENTRY IKJEGMS3                                                 79380020
         ENTRY IKJEGMS4                                                 79440020
         ENTRY IKJEGMS8                                                 79500020
         ENTRY IKJEGMS9                                                 79560020
         ENTRY IKJEGMSA                                                 79620020
IKJEGMS1 DC    A(ERRINVAL)   INVALID ADDRESS MESSAGE                    79740020
         DC    A(ERRMSG1)    INVALID REGISTER NOTATION MESSAGE          79800020
IKJEGMS3 DC    A(ERRNOBRK)   INVALID BREAKPOINT MESSAGE                 79860020
         DC    A(ERRMSG3)    UNABLE TO LOCATE BREAKPOINT MESSAGE        79920020
IKJEGMS4 DC    A(ERRINVAL)   INVALID ADDRESS MESSAGE                    79980020
         DC    A(ERRMSG4)    UNABLE TO CONVERT MESSAGE                  80040020
IKJEGMS8 DC    A(ERRMSG8)    NO BREAKPOINTS MESSAGE                     80100020
         DC    AL4(0)        NULL MESSAGE FIELD                         80160020
IKJEGMS9 DC    A(ERRMSG9)    ERROR MESSAGE                              80220020
         DC    A(ERRMSG13)   PARSE RC = 12 MESSAGE                      80280020
IKJEGMSA DC    A(ERRMSG11)   PARSE RC = 16 MESSAGE                      80340020
         DC    AL4(0)        NULL MESSAGE                               80400020
*                                                                       80530020
IKJEGM12 DC    A(ERRMSG14)   POINTER TO INVALID RANGE MESSAGE           80540020
         DC    A(ERRMSG15)   SECOND LEVEL MESSAGE                       80550020
         SPACE 2                                                        80570020
         DS    0H            ALIGNMENT                                  80580020
ERRINVAL DC    AL2(ERR1-ERRINVAL)      LENGTH                           80640020
         DC    AL2(0)                  NULL FIELD                       80700020
         DC    C'IKJ57030I INVALID ADDRESS'   MSG TEXT                  80760020
ERR1     EQU   *             EQUATE LABEL                               80820020
         SPACE                                                          80870020
         DS    0H            ALIGNMENT                                  80880020
ERRMSG1  DC    AL2(ERR2-ERRMSG1)   LENGTH                               80940020
         DC    AL2(0)         NULL FIELD                                81000020
         DC    C'IKJ57030I'   MSG                                       81060020
         DC    C' REGISTER NOTATION MUST BE INDIRECT GENERAL REGISTER'  81120020
ERR2     EQU   *             EQUATE LABEL                               81240020
         SPACE                                                          81290020
         DS    0H            ALIGNMENT                                  81300020
ERRMSG3  DC    AL2(ERR4-ERRMSG3)  LENGTH                                81360020
         DC    AL2(0)        NULL FIELD                                 81420020
         DC    C'IKJ57031I '                                            81480020
         DC    C'UNABLE TO LOCATE ADDRESS ON ACTIVE OR DEFERRED QUEUE'  81540020
ERR4     EQU   *                                                        81600020
         SPACE                                                          81650020
         DS    0H              ALIGNMENT                                81660020
ERRMSG4  DC    AL2(ERR5-ERRMSG4)    LENGTH                              81720020
         DC    AL2(0)          NULL FIELD                               81780020
         DC    C'IKJ57030I '   MSG NO.                                  81840020
         DC    C'UNABLE TO CONVERT THIS ADDRESS TO BINARY'   TEXT       81900020
ERR5     EQU   *                                                        81960020
         SPACE                                                          82010020
         DS    0H                    ALIGNMENT                          82020020
ERRNOBRK  DC    AL2(ERR6-ERRNOBRK)   LENGTH                             82080020
         DC    AL2(0)                NULL FIELD                         82140020
         DC    C'IKJ57031I  '                    MSG NO.                82200020
         DC    C'INVALID BREAKPOINT ADDRESS'     TEXT                   82260020
ERR6     EQU   *                                                        82320020
         SPACE                                                          82370020
         DS    0H               ALIGNMENT                               82380020
ERR8     EQU   *                                                        82440020
         SPACE                                                          82490020
         DS    0H                 ALIGNMENT                             82500020
ERRMSG8  DC    AL2(ERR9-ERRMSG8)  LENGTH                                82560020
         DC    AL2(0)             NULL FIELD                            82620020
         DC    C'IKJ57036I '      MSG NO.                               82680020
         DC    C'NO BREAKPOINTS FOUND'     TEXT                         82740020
ERR9     EQU   *                                                        82800020
         SPACE                                                          82850020
        DS    0H                 ALIGNMENT                              82860020
ERRMSG9 DC    AL2(ERR10-ERRMSG9)   LENGTH                               82920020
        DC    AL2(0)             NULL FIELD                             82980020
         DC    C'IKJ57033I OFF FAILED, COMMAND SYSTEM ERROR+'  TEXT     83040020
ERR10   EQU   *                                                         83100020
         SPACE                                                          83150020
         SPACE                                                          83450020
        DS    0H                    ALIGNMENT                           83460020
ERRMSG11 DC   AL2(ERR12-ERRMSG11)   LENGTH                              83520020
         DC   AL2(0)                NULL FIELD                          83580020
         DC   C'IKJ57035I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'   83640020
ERR12    EQU  *                                                         83700020
         SPACE                                                          83750020
         SPACE                                                          84010020
         DS    0H               ALIGNMENT                               84050020
ERRMSG13 DC    AL2(ERR14-ERRMSG13)   MSG LENGTH                         84052020
         DC    AL2(0)                 NULL FIELD                        84054020
         DC    C'IKJ57033I PARSE ERROR CODE 12'     MSG TEXT            84056020
ERR14    EQU   *                                                        84059220
         SPACE                                                          84062520
         DS    0H                      ALIGNMENT                        84065720
ERRMSG14 DC    AL2(ERR15-ERRMSG14)    LENGTH                            84068920
         DC    AL2(0)                    FIELD                          84072120
         DC    C'IKJ57032I INVALID RANGE BEGINNING'    MSG TEXT         84075320
ERR15    EQU   *                                                        84078520
         SPACE                                                          84081720
         DS    0H                      ALIGNMENT                        84084920
ERRMSG15 DC    AL2(MSGEND-ERRMSG15)    LENGTH                           84088120
         DC    AL2(0)                  FIELD                            84091320
         DC    C'IKJ57032I FIRST ADDRESS OF RANGE MUST NOT BE HIGHER'   84094520
         DC    C' THAN LAST ADDRESS'          MSG TEXT                  84097720
MSGEND   EQU   *                                                        84100920
         EJECT                                                          84104120
************************************************************            84107320
**                                                        **            84120020
**                  TCOMTAB DSECT                         **            84180020
**                                                        **            84240020
************************************************************            84300020
TCOMTAB TCOMTAB                                                         84360020
BOMBSW EQU   TSTFIRST                                                   84420020
************************************************************            84480020
**                                                        **            84540020
**                TCB DSECT                               **            84600020
**                                                        **            84660020
************************************************************            84720020
TCB       IKJTCB                                                        84780020
************************************************************            84840020
**                                                        **            84900020
**             CVT DSECT MACRO EXPANSION                  **            84960020
**                                                        **            85020020
************************************************************            85080020
CVT      DSECT                                                          85140020
         CVT                                                            85200020
         EJECT                                                          85250020
************************************************************            85260020
**                                                        **            85320020
**                  RB DSECT                              **            85380020
**                                                        **            85440020
************************************************************            85500020
         SPACE                                                          85610020
         IKJRB               REQUEST BLOCK DSECT                        85620020
         EJECT                                                          86090020
************************************************************            86100020
**                                                        **            86160020
**                   DEFERRED QUEUE ELEMENT               **            86220020
**                                                        **            86280020
************************************************************            86340020
DEFERRED DSECT                DSECT TO ACCESS DEFERRED QUEUE            86400020
*                                                                       86450020
DMELOAD  DS    CL8           LOADNAME                                   86480020
DMEDBE   DS    A             POINTER TO NEXT DEFER BREAK ELEMENT        86530020
DMEDME   DS    A             POINTER TO NEXT DEFER MODULE NAME          86580020
DBEPTRQ DSECT                 DSECT THAT POINTS TO QUEUE ELEMENTS       86640020
DBEPDL   DS    A             POINTER TO PDL                             86700020
DBEINBUF DS    A             POINTER TO INBUF AREA                      86760020
DBEDBE   DS    A             POINTER TO NEXT DBE                        86810020
         EJECT                                                          86870020
************************************************************            86880020
**                                                        **            86940020
**                     BREAKPOINT QUEUE DSECT             **            87000020
**                                                        **            87060020
************************************************************            87120020
         BRKELEM                                                        87180020
         EJECT                                                          87230020
************************************************************            87240020
**                                                        **            87300020
**             DSECT DESCRIBING  PARSE ADDR*SS PDE        **            87360020
**                                                        **            87420020
************************************************************            87480020
         IKJPARMA                                                       87540020
         EJECT                                                          87590020
************************************************************            87600020
**                                                        **            87660020
**                           WORKAREA DSECT               **            87720020
**                                                        **            87780020
************************************************************            87840020
WORKDSCT DSECT               DSECT TO ADDRESS INNER WORKAREA            87900020
*                                                                       87950020
PARSPARM DS    7F            RESERVE 28 BYTES FOR PARSE PARAM LIST      87960020
TEMPSAV  DS    16F           REGISTER SAVE AREA                         87970020
DCBSAVE  DS    A             ADDRESS OF DCB                             87990020
FIRSTPDE DS    A             ADDRESS OF FIRST PDE                       88020020
REGSAVE  DS    A             USED TO SAVE REG 15 (RETURN CODE)          88040020
PARSLST  DS    A             ADDR OF  PARSE VALIDITY PARAM LIST         88060020
WORKLST  DS    3F            WORK AREA FOR STAE LIST                    88080020
CONVRTCD DS    A             SAVE AREA FOR CONVERT RETURN CODE          88130020
REGHOLD   DS   CL12          REGISTER SAVE                              88140020
         EJECT                                                          88190020
         IKJPPL               PARSE PARAMETER LIST DSECT                88192020
         EJECT                                                          88194020
         TSTCWORK             TEST WORKAREA DSECT                       88196020
         EJECT                                                          88198020
************************************************************            88200020
**         DEFER QUEUE  PDE                               **            88260020
************************************************************            88320020
DEFERPDE DSECT               DSECT USED TO ADDR PDE ON DEFERRED Q       88380020
*                                                                       88430020
DEFLOAD  DS    A             POINTER TO LOADNAME                        88440020
DEFLEN1  DS    CL1           LENGTH OF LOADNAME                         88500020
DEFLAGS1 DS    CL1           FLAGS                                      88560020
DEFRES1  DS    CL1           RESERVED                                   88620020
DEFENTY  DS    A             PTR TO ENTRYNAME                           88680020
DEFLEN2  DS    CL1           LENGTH OF ENTRYNAME                        88740020
DEFLAGS2 DS    CL1           FLAGS                                      88800020
DEFRES2  DS    CL1           RESERVED                                   88860020
DEFADDR  DS    A             SYMBOL ADDRESS                             88920020
DEFLEN3  DS    CL2           LENGTH OF SYMBOL STRING                    88980020
DEFLAGS3 DS    CL1           FLAGS                                      89040020
DEFRES3  DS    CL1           RESERVED                                   89100020
DEFSKIP2 DS    CL4           NOT NEEDED                                 89160020
DEFEXPR  DS    A             POINTER TO ADDRESS EXPRESSION              89220020
DEFUSER  DS    A             USER WORD                                  89280020
DEFSEC   EQU   *             EQUATE SECOND PDE TO THIS ADDRESS          89340020
FILLIT   DS    CL36          NOT USED                                   89400020
DEFCHAIN DS    A             CHAIN ADDRESS                              89460020
         EJECT                                                          89510020
************************************************************            89520020
**         ADDRESS EXPRESSION PDE                         **            89580020
************************************************************            89640020
ADDREXP  DSECT               DSECT FOR ADDRESS EXPRESSION               89700020
ADDRPTR  DS    A             POINTER TO ACTUAL STRING                   89760020
ADDRLEN  DS    CL2           LENGTH OF STRING                           89820020
ADDRRES  DS    CL2           RESERVED                                   89880020
ADDRFLG  DS    CL1           FLAGS                                      89940020
ADDRSIGN DS    CL1           SIGN                                       90000020
ADDRIND  DS    CL2           INDIRECT ADDRESSING                        90060020
ADDEXPR  DS    A             POINTER TO NEXT EXPR ZERO IF NONE          90120020
         END                                                            90180020
