         TITLE 'IKJEGPCH, ''ASSIGN'' SUBCOMMAND OF TEST, INITIALIZE'    00050020
*********************************************************************** 00060020
*                                                                     * 00110020
* STATUS--                                                            * 00120020
*    VERSION NUMBER 01, OS/360 RELEASE 20                             * 00170020
*                                                                     * 00220020
* FUNCTION--                                                          * 00230020
*    THIS MODULE WILL INITIALIZE AREA 'PCHWORK', CALL IKJPARSE,       * 00370020
*    VALIDITY CHECK THE VALUES (IN A PARSE EXIT ROUTINE), THEN XCTL   * 00380020
*    TO MODULE IKJEGASN WHICH DOES THE ACTUAL PATCHING.               * 00390020
*                                                                     * 00410020
* ENTRY POINTS--                                                      * 00460020
*         IKJEGPCH  MAIN ENTRY POINT, ENTERED FROM IKJEGMNL           * 00510020
*         PCHVALTP  PARSE EXIT ROUTINE FOR VALIDITY CHECKING VALUES   * 00560020
*         PCHVALAD  PARSE EXIT ROUTINE FOR ADDRESS CONVERSION         * 00610020
*                                                                     * 00660020
* INPUT--                                                             * 00670020
*    THE SUBCOMMAND BUFFER AS ENTERED BY THE USER.                    * 00680020
*                                                                     * 00690020
* OUTPUT--                                                            * 00700020
*    AREA 'PCHWORK' INITIALIZED TO PREFORM THE PATCH REQUESTED.       * 00710520
*                                                                     * 00710820
* EXTERNAL REFERENCES--                                               * 00711220
*         IKJEGCVT FOR CONVERSION OF ADDRESSES TO BINARY.             * 00711620
*         IKJEGI01 FOR OUTPUTTING MESSAGES.                           * 00714020
*         IKJPARSE FOR PARSING THE SUBCOMMAND STRING.                 * 00716020
*                                                                     * 00718020
* EXITS, NORMAL--                                                     * 00720020
*         XCTL TO MODULE 'IKJEGASN'                                   * 00792020
*                                                                     * 00800020
* EXITS, ERROR--                                                      * 00810020
*         BR 14 TO CALLER WITH A RETURN CODE OF ZERO IF AN ERROR      * 00812020
*         OCCURED DURING PARSE OR CONVERT.                            * 00816020
*         BR 14 TO CALLER WITH RETURN CODE SIXTEEN IF AN ATTENTION    * 00818020
*         IS SCHEDULED.                                               * 00818820
*         BRANCH REGISTER 14 RETURNING TO CALLER WITH A CONDITION CODE* 00820020
*         OF TWENTY (20) FROM THE STAE RETRY ROUTINE AFTER AN ABEND.  * 00830020
*                                                                     * 00840020
* TABLES/WORK AREAS --                                                * 00890020
*    1 TCOMTAB, POINTED AT BY REG 9 IS THE TEST COMMUNICATIONS TABLE  * 00900020
*    2 PCHWORK, A DESECT WHICH DESCRIBES PART OF THE COMMON WORKING   * 00950020
*    CORE MAINTAINED BY TEST AND POINTED AT BY HWORKAREA' IN TCOMTAB. * 00960020
*    3 PARAMETER DESCRIPTOR LIST (PDL) PREPARED BY IKJPARSE TO        * 01010020
*    DESCRIBE THE VARIOUS FIELDS OF THE PARSED SUBCOMMAND             * 01020020
*                                                                     * 01030020
* ATTRIBUTES--                                                        * 01040020
*    REENTRANT, REFRESHABLE, PROBLEM PROGRAM.                         * 01090020
*                                                                     * 01140020
* CHARACTER CODE DEPENDENCY--                                         * 01190020
*    OPERATION OF THIS MODULE REQUIRES AND DEPENDS ON THE BIT         * 01200020
*    PATTERNS AND BINARY VALUES OF THE EBCDIC CHARACTER SET.          * 01210020
*    THE DEPENDENCY IS IN TABLE 'PCHTRTBL'. OTHER PORTIONS OF         * 01220020
*    THIS MODULE REQUIRES ONLY REASSEMBLY FOR CHANGE OF CODE.         * 01230020
*                                                                     * 01240020
* NOTES--                                                             * 01250020
*    THIS MODULE REQUIRES THE STANDARD INSTRUCTION SET.               * 01260020
*                                                                     * 01310020
*********************************************************************** 01320020
IKJEGPCH CSECT                                                          01370020
         SPACE                                                          01380020
*  REGISTER EQUATES.                                                    01430020
         SPACE                                                          01440020
R0       EQU   0                   GENERAL USE AND PARAMETER REG        01490020
R1       EQU   1                   GENERAL USE AND PARAMETER REG        01500020
R2       EQU   2                   GENERAL USE REG                      01550020
R3       EQU   3                   GENERAL USE REG                      01560020
R4       EQU   4                   GENERAL USE REG                      01610020
R5       EQU   5                   GENERAL USE REG                      01620020
R6       EQU   6                   GENERAL USE REG                      01670020
R7       EQU   7                   GENERAL USE REG                      01720020
R8       EQU   8                   BASE REG FOR PDE'S                   01770020
R9       EQU   9                   BASE REG FOR TCOMTAB, COMM. DSECT    01820020
R10      EQU   10                  INTERNAL LINK REG FOR THIS MODULE    01870020
R11      EQU   11                  BASE REG FOR THIS PROGRAM.           01880020
R12      EQU   12                  *                                    01890020
R13      EQU   13                  PTR TO CURRENT SAVE AREA.            01900020
R14      EQU   14                  GENERAL USE, AND RETURN ADDR REG     01910020
R15      EQU   15                  GENERAL USE, RETURN CODE, CALL REG   01920020
         SPACE 2                                                        01970020
*  DATA EQUATES FOR OPERANDS OF IMMEDIATE TYPE INSTRUCTIONS.            02020020
         SPACE                                                          02030020
CHARA    EQU   C'A'                                                     02040020
CHARZ    EQU   C'Z'                                                     02050020
NULL     EQU   0                   USED FOR BALR R,0 AND BCTR R,0.      02060020
ZERO     EQU   0                                                        02070020
ONE      EQU   1                   SYMBOLIC FOR THE NUMBER 1            02080020
TWO      EQU   2                   SYMBOLIC FOR THE NUMBER '2'          02090020
THREE    EQU   3                   SYMBOLIC FOR THE QUANTITY '3'        02100020
FOUR     EQU   4                                                        02150020
EIGHT    EQU   8                                                        02160020
TWELVE   EQU   12                  SYMBOLIC FOR 12, USED AS AN RC       02170020
SIXTEEN  EQU   16                                                       02210020
TWENTY   EQU   20                  VALUE FOR COMPARE                    02220020
B1       EQU   1                   USED AS A SHIFT VALUE TO DIVIDE BY 2 02270020
B24      EQU   24                  SHIFT VALUE TO GET TO HIGH ORDER     02280020
R1OFF    EQU   24                  OFFSET INTO SAVE AREA FOR REG 1      02290020
R5OFF    EQU   40                  OFFSET INTO SAVE AREA FOR REG 5      02330020
R6OFF    EQU   44                  OFFSET INTO SAVE AREA FOR REG 6      02340020
R10OFF   EQU   60                  OFFSET INTO SAVE AREA FOR R10        02390020
DEC0     EQU   C'0'                                                     02440020
DEC1     EQU   C'1'                EBCDIC ONE FOR IMMEDIATE OPERANDS    02450020
DEC9     EQU   C'9'                                                     02460020
LCE      EQU   X'85'               EBCDIC CODE FOR A LOWER CASE 'E'     02510020
UCE      EQU   C'E'                USED IN IMMEDIATE OPERANDS           02520020
PLUS     EQU   C'+'                USED IN IMMEDIATE OPERANDS           02570020
MINUS    EQU   C'-'                USED IN IMMEDIATE OPERANDS           02580020
QUOTE    EQU   C''''               USED FOR SCANNING CHAR STRINGS.      02630020
RPAREND  EQU   C')'                END DELIMITER FOR SCON               02640020
LOW      EQU   4                   SYMBOLIC FOR BR ON COND CODE 1       02690020
HIGH     EQU   2                   SYMBOLIC FOR BR ON COND CODE 2       02700020
HIGHMASK EQU   X'20'               MASK FOR BRANCH HIGH                 02700120
LOEQMASK EQU   X'D0'               MASK FOR BRANCH LOW OR EQUAL         02700220
ODD      EQU   X'01'               FOR TESTING WHETHER AN ADDR IS ODD.  02700420
TESTSVC  EQU   97                  SVC NUMBER FOR THE TEST SVC.         02700820
SIDATAPT EQU   0                   OFFSET INTO SYM-INFO BLOCK FOR DATA  02700920
SYMINFOL EQU   16                  SYMBOLIC FOR LENGTH OF SYMINFO BLK   02701020
M2OFFSET EQU   80                  OFFSET INTO BUFFER FOR 2ND LEVEL MSG 02703020
LL00IDL  EQU   14                  LENGTH OF LL00 AND ID FLDS OF MSG    02705020
BDYOSET  EQU   M2OFFSET+LL00IDL    OFFSET FOR MOVING BDY TYPE TO MSG    02707020
TYPEOSET EQU   30                  OFFSET FOR MOVING TYPE CHAR TO MSG   02709020
DATAOSET EQU   32                  OFFSET FOR MOVING DATA INTO MSG      02709420
CGRPLEN  EQU   64                  QUANTITY OF CHAR DATA FOR ONE GROUP  02709820
         SPACE                                                          02709920
FOREPTR  EQU   8                   OFFSET TO FOREWARD PTR IN SAVE AREA  02710020
BACKPTR  EQU   4                   OFFSET TO BACKWARD PTR IN SAVE AREA  02720020
CONLNTH  EQU   0                   OFFSET INTO CONVERT OUTPUT FOR LNTH  02730020
CONDATA  EQU   1                   OFFSET INTO CONVERT OUTPUT FOR DATA  02740020
GRPCH    EQU   X'04'               CODE FOR PATCHING GENERAL REGS       02750020
FPPCH    EQU   X'02'               CODE FOR PATCHING FLT PT REGS        02760020
         SPACE                                                          02810020
LOTOHI   EQU   24                  SHIFT VALUE TO GET LOW BYTE TO HIGH  02820020
LOGONBIT EQU   X'40'               FOR TESTING AND ECB FOR LOGON POSTED 02870020
DWBDY    EQU   B'00000111'         USED TO TEST ADDRS FOR DBL WRD BDY.  02880020
FWBDY    EQU   B'00000011'                                FULL          02930020
HWBDY    EQU   B'00000001'                                HALF          02980020
         SPACE                                                          03030020
HEXFF    EQU   X'FF'                                                    03080020
ATTNBIT  EQU   B'01000000'                                              03130020
         SPACE                                                          03180020
*  THE FOLLOWING TABLE CONTAINS THE INTERNAL ASSEMBLER TYPE CODES.      03230020
         SPACE                                                          03240020
CHARCODE EQU   X'00'               TYPE ATTRIBUTE =CHAR                 03290020
HEXCODE  EQU   X'04'                ''     ''     =HEXADECIMAL          03340020
BINCODE  EQU   X'08'                ''     ''     =BINARY               03390020
FCODE    EQU   X'10'                ''     ''     =FIXED PT, FULLWORD   03440020
HCODE    EQU   X'14'                ''     ''       ''   '', HALFWORD   03490020
ECODE    EQU   X'18'                ''     ''     =FLT PT, FULLWORD     03540020
DCODE    EQU   X'1C'                ''     ''      ''  '', DBL WORD     03590020
AQCODE   EQU   X'20'                ''     ''     =A AND Q ADDR CONST   03600020
YCODE    EQU   X'24'                ''     ''     =Y ADDR CONST         03650020
SCODE    EQU   X'28'                ''     ''     =S ADDR CONST         03660020
VCODE    EQU   X'2C'                ''     ''     =V ADDR CONST         03710020
PACKCODE EQU   X'30'                ''     ''     =PACKED DECIMAL       03720020
ZONECODE EQU   X'34'                ''     ''     =ZONED DECIMAL        03770020
         SPACE                                                          03780020
*  SYMBOLIC OFFSETS INTO THE MESSAGE CSECT FOR VARIOUS MESSAGE ADCONS.  03830020
         SPACE                                                          03840020
MFACTOR  EQU   8                   MULTIPLIER TO GET OFFSET INTO MSG CT 03890020
PCHMSG00 EQU   0*MFACTOR           1ST MSG IN MSG CSECT                 03900020
PCHMSG01 EQU   1*MFACTOR           2ND     ''                           03950020
PCHMSG02 EQU   2*MFACTOR           3RD     ''                           03960020
PCHMSG03 EQU   3*MFACTOR           4TH     ''                           04010020
PCHMSG04 EQU   4*MFACTOR           5TH     ''                           04020020
PCHMSG05 EQU   5*MFACTOR           6TH     ''                           04070020
PCHMSG06 EQU   6*MFACTOR           7TH     ''                           04080020
         EJECT                                                          04140020
*  SYMBOLIC OFFSETS INTO A VALUE PDE.                                   04190020
         SPACE                                                          04200020
PDEXADRP EQU   0                   PTR TO EXP VALUE    4 BYTES LONG     04250020
PDEXLEN1 EQU   PDEXADRP+4          LENGTH OF EXP VALUE 2                04260020
PDEXFLG1 EQU   PDEXLEN1+4          FLAG BYTE ONE       1                04310020
PDEXSIGN EQU   PDEXFLG1+1          SIGN FOR THIS VALUE 1                04320020
PDEXINDC EQU   PDEXSIGN+1          LEVELS OF INDIRECT  2                04370020
PDEXPTR1 EQU   PDEXINDC+2          PTR TO NEXT EXP     4                04380020
         SPACE 3                                                        04430020
DECEXP   EQU   B'00000100'         IF EXPRESSION IS DECIMAL             04440020
HEXEXP   EQU   B'00000010'         IF EXPRESSION IS HEX                 04490020
PDEVALPT EQU   0                   PTR TO DATA STRING  4 BYTES LONG     04500020
PDEVALEN EQU   PDEVALPT+4          LENGTH OF STRING    2                04550020
PDEVALFG EQU   PDEVALEN+2          FLAG BYTE ONE       1                04560020
PDEVALTP EQU   PDEVALFG+1          ASSEMBLER TYPE      1                04610020
PDEVALNX EQU   PDEVALTP+1          PTR TO NEXT IF LIST 4                04620020
LVALPDE  EQU   PDEVALNX+4          LENGTH OF A VALUE PDE                04670020
         TITLE 'IKJEGPCH, ''SET'' SUBCOMMAND OF TEST, INITIALIZATION'   04680020
*********************************************************************** 04730020
*                                                                     * 04740020
*  BEGIN WITH THE STANDARD LINKAGE CONVENTIONS.                       * 04790020
*                                                                     * 04800020
*********************************************************************** 04850020
PATCH    SAVE  (14,12),,*                                               04860020
         LR    R11,R15             PICK UP ENTRY POINT ADDR FOR BASE    04910020
         USING IKJEGPCH,R11                                             04920020
         USING TCOMTAB,R9                                               04970020
         L     R6,REGSAVE2         ADDR OF SAVE AREA                    04980020
         ST    R6,FOREPTR(R13)     FORWARD AND BACKWARD CHAIN           05030020
         ST    R13,BACKPTR(R6)         THE SAVE AREAS.                  05040020
         LR    R13,R6              SET PTR TO NEW SAVE AREA             05090020
         SPACE                                                          05100020
         L     R10,WORKAREA        GET PTR TO WORKING CORE              05150020
         USING TSTCWORK,R10                                             05160020
         LA    R10,CWORKCMD        SET UP BASE OF SUB-CMD WORK CORE     05210020
         USING PCHWORK,R10                                              05220020
         XC    PCHWORK(LPCHWORK),PCHWORK  CLEAR THE CORE                05270020
*                                                                       05280020
*        ISSUE STAE MACRO                                               05330020
*                                                                       05340020
         MVC   RETRYSAV,TSTRETRY+ONE   SAVE ADDR OF MAINLINE RETRY RTN  05350020
         MVC   TSTRETRY+ONE(THREE),RETRYAD+ONE  MOVE ADDR TO TCOMTAB    05390020
         LA    R1,STAELIST         PTR TO LIST FORM MACRO               05400020
         L     R2,TSTSTAE          PTR TO TEST STAE MODULE              05450020
         STM   R10,R12,R10OFF(R13)      SAVE BASE PTR                   05500020
         STAE  (R2),CT,MF=(E,(R1))                                      05510020
         LTR   R15,R15             TEST RETURN CODE                     05520020
         BZ    STAEOK              CONTINUE IF ZERO                     05570020
         B     PARSRC16            PRINT ERROR MESSAGE IF SO            05640020
STAEOK   EQU   *                                                        05690020
         LA    R1,PCHABEND         GET ADDR OF ABEND VECTOR TABLE       05692020
         ST    R1,ABENTAB1         SET UP SUB-CMD ABEND TABLE           05694020
         SPACE                                                          05700020
*********************************************************************** 05750020
*                                                                     * 05760020
*  SET UP PARAMETER LIST FOR CALLING PARSE.                           * 05810020
*                                                                     * 05820020
*********************************************************************** 05870020
         SPACE                                                          05880020
         LA    R1,PPCL             PTR TO PARSE LIST                    05882020
         USING PPL,R1              ADDRESSABILITY FOR LIST              05884020
         L     R2,TSTUPT           PTR TO UPT                           05890020
         L     R3,TSTECT           PTR TO ECT                           05892020
         L     R4,TSTCPECB         PTR TO P/P ECB                       05894020
         ST    R2,PPLUPT           PUT PTR TO UPT INTO PARSE LIST       05900020
         ST    R3,PPLECT           PUT PTR TO ECT INTO PARSE LIST       05920020
         ST    R4,PPLECB           PUT PTR TO P/P ECB INTO PARSE LIST   05924020
         L     R2,PARSEPCL         PTR TO PARSE PCL                     05926020
         LA    R3,TSTANSPL         PTR TO ANSWER PLACE                  05926420
         L     R4,INBUF            PTR TO INPUT BUFFER                  05926820
         ST    R2,PPLPCL           PUT PTR TO PARSE PCL INTO PARSE LIST 05928020
         ST    R3,PPLANS           PUT PTR TO ANS PLACE INTO PARSE LIST 05928820
         ST    R4,PPLCBUF          PUT PTR TO INPUT BUF INTO PARSE LIST 05929620
         SPACE                                                          05959720
*  R6 SHOULD STILL CONTAIN THE SAVE AREA ADDRESS AT THIS POINT.         05989820
         SPACE                                                          05999820
         ST    R6,PPLUWA           PUT INTO PARSE LIST                  06019920
         DROP  R1                                                       06029920
         SPACE                                                          06050020
         LINK  EP=IKJPARS          LINK TO THE PARSE RTN.               06060020
PARSEBLO EQU   *                                                        06070020
         SPACE                                                          06110020
*********************************************************************** 06120020
*                                                                     * 06170020
*  TEST RETURN CODE FROM PARSE.                                       * 06180020
*       IF 0 FALL THRU AND SET UP TO GO TO IKJEGCVT TO CONVERT VALUE. * 06230020
*       IF NON-ZERO, GO ANALYZE FURTHER.                              * 06240020
*                                                                     * 06290020
*********************************************************************** 06300020
         SPACE                                                          06350020
         LTR   R15,R15             TEST RETURN CODE FROM PARSE.         06400020
         BNZ   PARSRC(R15)         IF NON-ZERO, GO ANALYZE FURTHER.     06410020
         L     R8,TSTANSPL         GET PTR TO THE PDL                   06420020
         USING IKJPARMD,R8                                              06470020
         MVC   VPDE(LVALPDE),VAL   COPY THE CURRENT VALUE PDE           06480020
         LA    R8,ADDR             SET UP A BASE REG FOR ADDR PDE       06530020
         USING IKJPARMA,R8                                              06540020
         TM    PDEFLG4,GENR+SFPR+LFPR  IS ADDRESS TYPE REGISTER         06590020
         BZ    PCH010              IF NOT REG, BRANCH                   06640020
         NC    PDEINDCT,PDEINDCT   IF REG, IS IT INDIRECTED             06650020
         BNZ   PCH012              IF INDIRECTED, BRANCH                06660020
PCH010   EQU   *                                                        06710020
         MVC   A1TYPE,PDEFLG4      MOVE ADDR TYPE TO WORKING CORE       06720020
PCH012   EQU   *                                                        06770020
         L     R2,PDEUSER          GET RESOLVED ADDRESS OR SI PTR       06780020
         LTR   R2,R2               IS ADDR SYMBOLIC                     06830020
         BNM   PCH018              IF NOT SYMBOLIC, BRANCH              06840020
         L     R2,SIDATAPT(R2)     GET ACTUAL ADDR FROM SI BLOCK        06890020
PCH018   EQU   *                                                        06900020
         ST    R2,A1               SAVE RESOLVED ADDR IN WORKING CORE   06950020
         DROP  R8                                                       06960020
         SPACE                                                          07010020
*        AT THIS POINT CONTROL IS PASSED TO 'IKJEGASN', THE MAIN        07020020
*        PROCESSING MODULE FOR THE 'SET' SUBCOMMAND.                    07070020
*        THIS XCTL USES THE BLDL ENTRY FOR IKJEGASN WHICH WAS CREATED   07070820
*        BY MAINLINE IN INITIALIZATION. THIS BLDL ENTRY SHOULD IMPROVE  07071220
*        PERFORMANCE OF SUB-COMMANDS XCTLING BETWEEN LOAD MODULES.      07071620
         SPACE 2                                                        07071720
         LA    R1,ASN           PTR TO CONSTANT NAME                    07072020
         L     R15,TSTEXPAN     ADDRESS OF EXPANSION ROUTINE            07074020
         BALR  R14,R15          GO DO EXPANDING                         07076020
         LTR   R6,R1            WAS BLDL ENTRY RETURNED                 07078020
         BZ    NOBLDL           BRANCH IF NOT                           07078420
         L     R13,BACKPTR(R13) ADDR OF CALLERS SAVE AREA               07078820
         LA    R15,XCTLLST      PTR TO PARM LIST                        07079220
         XC    XCTLLST(XCTLLSTL),XCTLLST  CLEAR LIST                    07079620
         OI    TSTFLGS2,TSTXCTL TURN ON XCTL IN PROGRESS BIT            07079720
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  SET UP MNL STAE            07079820
         XCTL  (2,12),DE=(6),SF=(E,(15))                                07079920
         SPACE 2                                                        07080020
*        THE FOLLOWING XCTL IS EXECUTED IF THE BLDL ISSUED BY MAINLINE  07100020
*        WAS NOT SUCCESSFUL AND THE BLDL ENTRY IS NOT AVAILABLE FOR     07110020
*        USE IN THE XCTL.                                               07120020
         SPACE 2                                                        07120420
NOBLDL   DS    0H                                                       07122020
         L     R13,BACKPTR(R13)     ADDR OF CALLERS SAVE AREA           07130020
         LA    R15,XCTLLST          PTR TO PARM LIST                    07140020
         XC    XCTLLST(XCTLLSTL),XCTLLST   CLEAR XCTL PARM LIST TO 0    07142020
         OI    TSTFLGS2,TSTXCTL    TURN ON XCTL IN PROGRESS SW          07150020
         MVC   TSTRETRY+ONE(THREE),RETRYSAV  SET UP 'MNL'S STAE RETRY   07160020
         SPACE 2                                                        07170020
         XCTL  (2,12),EP=IKJEGASN,SF=(E,(15))                           07190020
         SPACE 3                                                        07200020
*     RETURN TO MAINLINE IN AN ERROR CASE.                              07250020
         SPACE                                                          07260020
PCHRET1  EQU   *                                                        07310020
         SPACE                                                          07320020
*  TURN OFF SWITCHES USED BY PATCH.                                     07370020
         SPACE                                                          07380020
         NI    TSTFLGS1,HEXFF-PCHLSTVL                                  07430020
         L     R15,PCHRETCD        PICK UP PRESET RETURN CODE.          07440020
         L     R13,BACKPTR(R13)    GET ADDR OF PREVIOUS SAVE AREA.      07490020
         RETURN  (14,12),T,RC=(15) RETURN TO THE CALLER                 07500020
         EJECT                                                          07550020
PCHVALTP EQU   *                                                        07560020
         SAVE  (14,12)                                                  07610020
         LA    R14,OFFSETTP(R15)   SET UP CORRECT VALIDITY RTN ADDR.    07620020
         B     OFFSET1(R15)        GO TO COMMON LINK CONVENTION RTN.    07670020
         SPACE                                                          07680020
PCHVALAD EQU   *                                                        07730020
         SAVE  (14,12)                                                  07740020
         LA    R14,OFFSETAD(R15)   SET UP CORRECT VALIDITY RTN ADDR.    07790020
PCHVALCM EQU   *                                                        07800020
OFFSET1  EQU   *-PCHVALTP          OFFSET TO GET TO COMMON LINK RTN.    07850020
         L     R12,FOUR(R1)        R12=PTR TO LIST'S SAVE AREA          07860020
         LR    R3,R1               SAVE REG1                            07910020
         LM    R6,R12,R6OFF(R12)   RESTORE REQUIRED REGS OF LIST        07960020
         L     R2,REGSAVE3         PTR TO NEW SAVE AREA                 08010020
         ST    R2,FOREPTR(R13)     FOREWARD CHAIN SAVE AREAS.           08060020
         ST    R13,BACKPTR(R2)     BACKWARD CHAIN SAVE AREAS.           08110020
         LR    R13,R2              SET NEW SAVE AREA                    08160020
         L     R1,ZERO(R3)         GET ADDR OF PDE TO VALIDITY CHECK.   08210020
         SR    R0,R0               SET TO INDICATE CONVERT TO BINARY.   08220020
         ST    R0,MSGPLIST+FOUR      CLEAR 2ND LEVEL MSG PTR FIELD      08222020
         BR    R14                 GO TO REQUESTED ROUTINE.             08230020
         SPACE 2                                                        08240020
*  MAIN PORTION OF THE ADDRESS VALIDITY CHECKING ROUTINE.               08290020
         SPACE                                                          08340020
PCHADDR  EQU   *                                                        08390020
OFFSETAD EQU   *-PCHVALAD          OFFSET FOR ADDR VALIDITY CHECK RTN.  08400020
         LCR   R1,R1               INDICATE REGISTER CONVERSION.        08450020
         L     R15,TSTCONVT        ADDR OF CONVERT ROUTINE FOR CALL.    08460020
         BALR  R14,R15             GO TO CONVERT ROUTINE.               08510020
         LTR   R15,R15             TEST THE RETURN CODE FROM CVT.       08520020
         BNZ   PRCNOTZ             IF RC FROM IKJEGCVT NON-ZERO, BRANCH 08570020
RETTOPAR EQU   *                                                        08640020
         L     R13,BACKPTR(R13)    GET ADDR OF PREVIOUS SAVE AREA.      08690020
         L     R1,R1OFF(ZERO,R13)  PICK UP PTR TO PARSE PARM LIST       08692020
         MVC   EIGHT(FOUR,R1),MSGPLIST+FOUR  PASS PTR TO 2ND LEVEL MSG  08694020
         RETURN (14,12),,RC=(15)    RETURN TO THE PARSE ROUTINE.        08700020
         SPACE                                                          08710020
PRCNOTZ  EQU   *                                                        08720020
         CH    R15,HSIXTEEN        IS RC 16 OR 20                       08730020
         BNL   PRC1620             IF 16 OR 20, BRANCH                  08740020
         L     R4,ZERO(ZERO,R3)    PICK UP PTR TO THE ADDR PDE          08740420
         USING IKJPARMA,R4                                              08740820
         L     R15,PDEUSER         PICK UP PTR TO 2ND LEVEL MSG OR 'FF' 08741220
         ST    R15,MSGPLIST+FOUR   SAVE IT IN MSGPLIST                  08741620
         DROP  R4                                                       08741720
PRC8     EQU   *                                                        08742020
         LA    R15,EIGHT           SET RC TO PARSE TO 8                 08744020
         B     RETTOPAR            GO RETURN TO PARSE                   08746020
PRC1620  EQU   *                                                        08748020
         ST    R15,PCHRETCD        SAVE RETURN CODE FROM CVT            08748420
         LA    R15,TWELVE          SET RC TO 12 FOR PARSE               08748820
         B     RETTOPAR            GO RETURN TO PARSE                   08749220
         EJECT                                                          08750020
*  MAIN PORTION OF THE VALUE VALIDITY CHECKING ROUTINE.                 08760020
         SPACE                                                          08810020
PCHVALUE EQU   *                                                        08820020
OFFSETTP EQU   *-PCHVALTP          OFFSET FOR VALUE VALIDITY CHECK RTN. 08870020
         TR    PDEVALTP(ONE,R1),PCHTRTBL TRANSLATE TYPE TO UPPER CASE   08880020
         SR    R5,R5               INITIALIZE FOR LATER INSERT CHAR.    08930020
         CLI   PDEVALTP(R1),CHARA  IS TYPE BELOW 'A' IN COLLATING SEQ   08940020
         BL    INVTYPE             IF YES, GO TO ERROR ROUTINE.         08990020
         CLI   PDEVALTP(R1),CHARZ  IS TYPE ABOVE 'Z' IN COLLATING SEQ.  09000020
         BH    INVTYPE             IF YES, TO TO ERROR ROUTINE.         09050020
         IC    R5,PDEVALTP(R1)     PICK UP TYPE CHAR FROM PDE.          09060020
         STC   R5,TYPESAVE         SAVE CHARACTER USED FOR TYPE.        09110020
         LA    R14,TYPETBL(R5)     SET UP ADDR OF CORRESPONDING CODE.   09120020
         CLI   ZERO(R14),HEXFF     IS THE TYPE CODE X'FF'               09170020
         BE    INVTYPE             IF EQUAL, TYPE IS INVALID, BRANCH.   09180020
         IC    R5,ZERO(R14)        PICK UP HEX CODE FOR TYPE.           09190020
         STC   R5,PDEVALTP(R1)     STORE TYPE CODE IN VALUE PDE.        09200020
         LH    R2,PDEVALEN(R1)     R2=LENGTH OF DATA STRING.            09210020
         L     R6,PDEVALPT(R1)     R6=ADDR OF DATA STRING               09220020
         LTR   R2,R2               IS THE STRING LNTH ZERO              09230020
         LR    R7,R1               SAVE PTR TO VALUE PDE IN R7.         09240020
         BZ    INVTYPE             IF STRING LNTH 0,BRANCH              09290020
         B     VBTABLE(R5)         BRANCH TO BRANCH TABLE OFFSET BY TYP 09300020
VBTABLE  EQU   *                                                        09350020
         B     CVAL                CODE X'00' FOR CHAR                  09360020
         B     XVAL                CODE X'04' FOR HEXADECIMAL           09410020
         B     BVAL                CODE X'08' FOR BINARY                09420020
         B     XVAL                CODE X'0C' THIS CODE NOT USED.       09470020
         B     FVAL                CODE X'10' FOR FULLWORD FIXED PT     09480020
         B     HVAL                CODE X'14' FOR HALFWORD FIXED PT     09530020
         B     EVAL                CODE X'18' FOR SHORT FLT PT          09540020
         B     DVAL                CODE X'1C' FOR LONG FLT PT           09590020
         B     AQVAL               CODE X'20' FOR A AND Q ADDR CNSTNTS  09600020
         B     YVAL                CODE X'24' FOR Y ADDR CONSTANTS      09650020
         B     SVAL                CODE X'28' FOR S ADDR CONSTANTS      09660020
         B     AQVAL               CODE X'2C' FOR V ADDR CONSTANTS      09710020
         B     PVAL                CODE X'30' FOR PACKED DECIMAL        09720020
         B     ZVAL                CODE X'34' FOR ZONED DECIMAL         09730020
         SPACE                                                          09740020
VALOK    EQU   *                                                        09750020
CVAL     EQU   *                                                        09760020
         SR    R15,R15             SET THE RETURN CODE TO ZERO.         09770020
         B     RETTOPAR            GO RETURN TO PARSE.                  09780020
         EJECT                                                          09830020
*********************************************************************** 09840020
*                                                                     * 09890020
*  THE FOLLOWING ROUTINES CHECK THE VALIDITY OF THE INPUT STRING      * 09900020
*  AGAINST THE REQUIREMENTS FOR THE PARTICULAR TYPE SPECIFIED.        * 09950020
*  AT ENTRY, THE REGISTERS ARE SET AS FOLLOWS.                        * 09960020
*        R1    PTR TO VALUE PDE                                       * 10010020
*        R2    LENGTH OF STRING                                       * 10020020
*        R5    TYPE CODE (IN HEX)                                     * 10070020
*        R6    PTR TO START OF STRING                                 * 10080020
*        R7    PTR TO VALUE PDE                                       * 10130020
*                                                                     * 10140020
*********************************************************************** 10190020
         SPACE                                                          10200020
FVAL     EQU   *                                                        10250020
         LA    R5,FMAX             SET UP TPR TO MAX VALUE FOR F TYPE   10260020
         B     VALNUM              GO TO NUMERIC CHECK ROUTINE          10310020
HVAL     EQU   *                                                        10320020
         LA    R5,HMAX             SET UP TPR TO MAX VALUE FOR H TYPE   10370020
         B     VALNUM              GO TO NUMERIC CHECK ROUTINE          10380020
AQVAL    EQU   *                                                        10430020
         CLI   ZERO(R6),MINUS      A - SIGN  IS INVAL, CHECK FOR IT     10440020
         BE    INVCHAR             IF - SIGN, BRANCH TO ERROR ROUTINE   10490020
         B     FVAL                GO TO NUMERIC CHECK ROUTINE          10550020
YVAL     EQU   *                                                        10560020
         CLI   ZERO(R6),MINUS      A - SIGN IS INVAL, CHECK FOR IT      10610020
         BE    INVCHAR             IF - SIGN, BRANCH TO ERROR ROUTINE   10620020
         B     HVAL                GO TO NUMERIC CHECK ROUTINE          10680020
         SPACE                                                          10730020
*  THE FOLLOWING ROUTINE SETS UP FOR AND CALLS THE NUMERIC SCAN RTN.    10740020
*  IT THE CHECKS THAT THE VALUE DOESN'T EXCEED THE MAXIMUM.             10790020
         SPACE                                                          10800020
VALNUM   EQU   *                                                        10850020
         CLI   ZERO(R6),MINUS      IS CONSTANT PRECEDED BY A - SIGN     10860020
         BE    SIGNIST             IF YES, BRANCH                       10910020
         CLI   ZERO(R6),PLUS       IF NOT A - SIGN, IS IT A + SIGN      10920020
         BNE   DIGITIST            IF NOT A SIGN, GO CHECK DIGITS       10970020
SIGNIST  EQU   *                                                        10980020
         BCTR  R2,NULL             DECREMENT LENGTH 1 FOR SIGN          11030020
         LA    R6,ONE(R6)          INCREMENT STRING PTR PAST SIGN       11040020
DIGITIST EQU   *                                                        11090020
         LR    R3,R2               SAVE LENGTH                          11100020
         LR    R4,R6                   AND PTR TO START OF DATA         11150020
         BAL   R14,NUMSCAN         GO CERTIFY FIELD AS NUMERIC          11160020
         LTR   R15,R15             TEST RETURN CODE                     11210020
         BNZ   INVCHAR             IF RC NON-ZERO, BRANCH TO ERROR RTN  11220020
         CH    R3,ZERO(R5)         CHECK LENGTH OF INPUT STRING         11270020
         BL    VALOK               LENGTH LESS THAN MAX, BRANCH         11280020
         BH    TOOBIG1             LENGTH GREATER THAN MAX, BRANCH      11330020
         SPACE                                                          11340020
*  IF LENGTH EQUALS MAX, COMPARE TO MAX NUMBER FOR THIS CONSTANT TYPE   11390020
         SPACE                                                          11400020
         BCTR  R3,NULL             DECREMENT LENGTH FOR CLC INSTR       11450020
         EX    R3,DATACLC1         COMPARE STRING TO MAX                11460020
         BL    VALOK               IF LOW, BRANCH, CONSTANT OK          11510020
         BH    TOOBIG2             IF HIGH, BRANCH, CONSTANT IN ERROR   11520020
         L     R6,PDEVALPT(R7)     RESET PTR TO START OF VALUE STRING   11570020
         CLI   ZERO(R6),MINUS      IS THE FIRST CHAR A MINUS SIGN       11580020
         BE    VALOK               IF YES, VALUE IS OK                  11630020
         B     TOOBIG2             IF NOT, BRANCH, CONSTANT IN ERROR    11640020
         SPACE 2                                                        11690020
*  THE FOLLOWING ROUTINE CHECKS THE VALIDITY OF PACKED AND ZONED CONS   11700020
         SPACE                                                          11750020
ZVAL     EQU   *                                                        11760020
         LA    R5,ZMAX             SET UP PTR TO MAX LEN                11810020
         B     ZPVAL02             GO TO COMMON RTN                     11820020
PVAL     EQU   *                                                        11870020
         LA    R5,PMAX             SET UP PTR TO MAX LEN                11880020
ZPVAL02  EQU   *                                                        11930020
         CLI   ZERO(R6),MINUS      IS THE FIRST CHAR A MINUS SIGN       11940020
         BE    ZPVAL04             IF - SIGN, BRANCH                    11990020
         CLI   ZERO(R6),PLUS       IS THE FIRST CHAR A PLUS SIGN        12000020
         BNE   ZPVAL06             IF NOT SIGN, GO TEST FOR NUMBERS     12050020
ZPVAL04  EQU   *                                                        12060020
         BCTR  R2,NULL             DECREMENT LENGTH FOR SIGN            12110020
         LA    R6,ONE(R6)          INCRE THE PTR PAST SIGN              12120020
ZPVAL06  EQU   *                                                        12170020
         CH    R2,ZERO(R5)         IS LENGTH OK                         12180020
         BH    TOOBIG1             IF TOO LONG, BRANCH TO ERROR         12230020
         BAL   R14,NUMSCAN         GO CHECK THAT STRING IS NUMERIC      12240020
         LTR   R15,R15             TEST RETURN CODE                     12290020
         BZ    VALOK               IF RC=0, VALUE IS VALID              12300020
         B     INVCHAR             IF RC NON-ZERO, CONSTANT IN ERROR    12350020
         SPACE                                                          12360020
XVAL     EQU   *                                                        12410020
         LR    R4,R2               R4=INPUT STRING LENGTH               12420020
         CH    R4,XMAX             TEST LENGTH FOR MAX                  12470020
         BH    TOOBIG1             IF GREATER THAN MAX, BRANCH TO ERR   12480020
         BCTR  R4,NULL             DECRE LNTH FOR TRT INSTR             12530020
         EX    R4,VTRT1            TRANSLATE AND TEST FOR VALID CHARS   12540020
         BZ    VALOK               IF CC=0, STRING IS VALID HEX         12590020
         B     INVCHAR             OTHERWISE, BRANCH TO ERROR           12600020
VTRT1    TRT   ZERO(NULL,R6),XTRTT  FOR TESTING FOR VALID HEX DIGITS    12650020
         SPACE                                                          12660020
         SPACE                                                          12710020
DVAL     EQU   *                                                        12720020
         LA    R5,DMAX             SET UP PTRS TO MAX VALUES FOR D TYPE 12770020
         LA    R8,DMAXNEG          POINT TO CONSTANTS FOR NEG EXPONENT  12772020
         B     VALFPNUM            GO TO COMMON FLOATING PT NUM RTN.    12780020
         SPACE                                                          12830020
EVAL     EQU   *                                                        12840020
         LA    R5,EMAX             MAXIMUM VALUES FOR E TYPE            12890020
         LA    R8,DMAXNEG          POINT TO CONSTANTS FOR NEG EXPONENT  12892020
VALFPNUM EQU   *                                                        12900020
         CLI   ZERO(R6),MINUS      DOES STRING BEGIN WITH A - SIGN      12950020
         BE    FPSIGN1             IF YES, BRANCH                       12960020
         CLI   ZERO(R6),PLUS       DOES IT BEGIN WITH A + SIGN          13010020
         BNE   NOFPS1              IF NO SIGN, SKIP PTR ADJUSTMENT      13020020
FPSIGN1  EQU   *                                                        13070020
         LA    R6,ONE(R6)          INCRE PTR PAST SIGN                  13080020
         BCTR  R2,NULL             REDUCE LENGTH 1 FOR SIGN             13130020
NOFPS1   EQU   *                                                        13140020
         LR    R4,R6               SAVE START OF NUMERIC FIELD IN R4    13190020
         LR    R3,R2               SAVE ADJUSTED LENGTH IN R3           13200020
         BAL   R14,NUMSCAN         GO SCAN FOR DECIMAL DIGITS           13250020
         LTR   R15,R15             TEST RETURN CODE                     13260020
         BZ    FPEXP               IF ZERO, FIELD HAS NO EXPONENT       13310020
         CLI   ZERO(R6),LCE        WAS NON-NUMERIC CHAR A LOWER CASE E  13320020
         BE    FPEXP               IF YES, BRANCH                       13370020
         CLI   ZERO(R6),UCE        WAS IT AN UPPER CASE E               13380020
         BNE   INVCHAR             IF NEITHER, BRANCH TO ERROR          13430020
         SPACE 2                                                        13430420
*********************************************************************** 13432020
* THE FOLLOWING CODE CHECKS THAT THE USER ENTERED VALUE IS NOT TOO    * 13432420
* LARGE OR TOO SMALL. THE PROBLEM THIS POSES IS CLEAR IF WE NOTE THAT,* 13432820
* FOR EXAMPLE, 1E+60,10E+59,100E+58 AND 1000E+57 ARE IDENTICAL VALUES.* 13433220
* FOR INTEGRAL VALUES THE EXPONENT PLUS THE LENGTH OF THE COEFFICIENT * 13433620
* MUST NOT EXCEED 76. IF THE SUM IS LESS THAN 76 THE VALUE IS VALID.  * 13433720
* IF THE SUM IS EXACTLY 76 THEN THE COEFFICIENT MUST BE CHECKED TO SEE* 13433820
* THAT THE VALUE ENTERED DOES NOT EXCEED 7.237005...E+75. FOR         * 13433920
* FRACTION VALUES IE VALUES WITH A NEGATIVE EXPONENT THE UNSIGNED     * 13447920
* EXPONENT MINUS THE COEFFICIENT LENGTH MUST NOT EXCEED 78. IF THE SUM* 13457920
* IS LESS THAN 78 THE VALUE IS VALID. IF THE SUM IS EXACTLY 78 THEN   * 13459920
* THE COEFFICIENT MUST BE CHECKED TO SEE THAT THE VALUE ENTERED IS    * 13461920
* GREATER THAN 5.397605...E-79. ONE ALSO MIGHT EXPECT THE SINGLE      * 13466620
* PRECISION POSITIVE LIMIT TO BE 7.2370055E+75. THE LIMIT IS LOWER    * 13468620
* BECAUSE THE FLOATING POINT CONVERSION ROUTINE IN IKJEGCVT ROUNDS    * 13470620
* THE RESULT.                                                         * 13471020
*********************************************************************** 13471320
         SPACE 2                                                        13473320
FPEXP    EQU   *                                                        13476020
         SR    R3,R2               R3 IS NOW COEFFICIENT LENGTH         13490020
         BZ    INVFORMT            IF ZERO LENGTH PUT OUT MESSAGE       13492020
         LR    R15,R3              SAVE A COPY OF COEFFICIENT LENTH     13492420
         LR    R14,R4              SAVE START ADDR OF COEFFICIENT       13492820
VALCHK1  EQU   *                                                        13494020
         CLI   ZERO(R4),DEC0       IS LEADING DIGIT A ZERO              13494420
         BNE   VALCHK3             IF NO BRANCH                         13496020
         LA    R4,ONE(R4)          OTHERWISE POINT TO NEXT DIGIT        13498020
         BCT   R3,VALCHK1          IF MORE DIGITS CHECK NEXT DIGIT      13498420
         LR    R3,R15              RESTORE COEFFICIENT LENGTH           13498520
         LR    R4,R14              RESTORE COEFFICIENT START ADDR       13498620
VALCHK3  EQU   *                                                        13499220
         CH    R3,ZERO(R5)         HOW LONG IS COEFFICIENT              13499620
         BH    TOOBIG1             IF TOO LONG PUT OUT MESSAGE          13550020
         LR    R0,R3               SAVE COEFFICIENT LENGTH              13560020
         LTR   R2,R2               WAS AN EXPONENT ENTERED              13610020
         BZ    VALOK               IF NO VALUE IS OKAY, BRANCH          13620020
         CLI   ONE(R6),MINUS       IS EXPONENT NEGATIVE                 13670020
         BNE   PLUSEXP             IF NO SKIP CODE FOR FRACTION VALUE   13680020
         LCR   R3,R3               MAKE NEGATIVE                        13730020
         B     VALCHK2             SKIP CODE FOR POSITIVE EXPONENT      13740020
PLUSEXP  EQU   *                                                        13790020
         CLI   ONE(R6),PLUS        IS EXPONENT EXPLICITLY POSITIVE      13792020
         BNE   NOEXPSGN            IF NO SKIP CODE FOR AN EXPLICIT SIGN 13800020
VALCHK2  EQU   *                                                        13850020
         LA    R6,ONE(R6)          INCREMENT FOR SIGN                   13860020
         BCTR  R2,NULL             DECREMENT FOR SIGN                   13910020
NOEXPSGN EQU   *                                                        13920020
         LA    R6,ONE(R6)          INCREMENT FOR E                      13970020
         BCTR  R2,NULL             DECREMENT FOR E                      13980020
         CH    R2,TWO(R5)          HOW LONG IS EXPONENT                 14030020
         BH    TOOBIG2             IF TOO LONG PUT OUT MESSAGE          14040020
         LR    R15,R2              SAVE EXPONENT LENGTH                 14090020
         BCTR  R15,NULL            DECREMENT FOR EXECUTE                14100020
         EX    R15,DATAPACK        PACK THE EXPONENT                    14150020
         BAL   R14,NUMSCAN         GO CHECK FOR NUMERIC DIGITS ONLY     14160020
         LTR   R15,R15             WERE THEY ALL NUMERIC                14210020
         BNZ   INVCHAR             IF NO PUT OUT MESSAGE                14220020
         CVB   R0,HOLDAREA+ONE     CONVERT EXPONENT TO BINARY           14270020
         AR    R0,R3               ADD (OR SUBTRACT) COEFFICIENT LENGTH 14272020
         LA    R5,FOUR(R5)         POINT TO POSITIVE CONSTANTS          14274020
         LA    R15,HIGHMASK        LOAD MASK FOR EXECUTION OF BRANCH    14276020
         LTR   R3,R3               IS EXPONENT NEGATIVE                 14278020
         BNM   VALCHK4             IF NOT BRANCH                        14278420
         LR    R5,R8               POINT TO NEGATIVE CONSTANTS          14278820
         LA    R15,LOEQMASK        LOAD MASK FOR BRANCH LOW OR EQUAL    14279220
VALCHK4  EQU   *                                                        14279620
         CH    R0,ZERO(R5)         HOW LARGE IS EXPONENT                14279720
         BH    TOOBIG2             IF TOO LARGE PUT OUT MESSAGE         14279820
         BL    VALOK               IF LOWER THAN LIMIT VALUE IS OKAY    14279920
         LPR   R3,R3               MAKE COEFFICIENT LENGTH POSITIVE     14280020
         BCTR  R3,NULL             DECREMENT FOR COMPARISON TO LIMIT    14296620
         EX    R3,DATACLC1         COMPARE TO LIMITING COEFFICIENT      14306620
         EX    R15,BRANCH          BRANCH IF COEFFICIENT IS NOT VALID   14308620
         B     VALOK               OTHERWISE VALUE IS VALID             14310620
DATAPACK PACK  HOLDAREA+ONE(EIGHT),ZERO(ZERO,R6)                        14312620
BRANCH   NOP   TOOBIG2                                                  14313020
         SPACE                                                          14313320
BVAL     EQU   *                                                        14330020
         CH    R2,XMAX             TEST LENGTH, DOES IT EXCEED MAX      14340020
         BH    TOOBIG1             IF YES, BRANCH TO ERROR              14390020
BINVLOOP EQU   *                                                        14400020
         CLI   ZERO(R6),DEC0       IS CURRENT CHAR A ZERO               14450020
         BE    BIN0                IF YES, BRANCH, CHAR IS VALID        14460020
         CLI   ZERO(R6),DEC1       IS CURRENT CHAR A ONE                14510020
         BNE   INVCHAR             IF NEITHER 0, NOR 1, CHAR INVALID    14520020
BIN0     EQU   *                                                        14570020
         LA    R6,ONE(R6)          INCREMENT PTR TO NEXT CHAR           14580020
         BCT   R2,BINVLOOP         DECRE LNTH AND TEST FOR DONE         14630020
         B     VALOK               RETURN, ALL CHARS VALID              14640020
DATACLC1 CLC   ZERO(NULL,R4),TWO(R5)  COMPARES DIGIT STRINGS TO MAX     14690020
         SPACE 2                                                        14700020
*  ROUTINE TO TEST VALIDITY OF S TYPE VALUES.                           14750020
         SPACE                                                          14760020
SVAL     EQU   *                                                        14810020
         LA    R5,SMAX1            SET PTR TO SCON LIMITS               14820020
SCON04   EQU   *                                                        14870020
         LR    R3,R2               SAVE A COPY OF ORIGINAL LNTH         14880020
         LR    R4,R6               SAVE A COPY OF DATA START ADDR       14930020
         BAL   R14,NUMSCAN         GO SCAN FOR VALID DIGITS             14940020
         B     SCON06(R15)         USE RETURN CODE AS BRANCH INDEX      14990020
         SPACE                                                          15000020
*  IF RETURN CODE IS ZERO, DATA DOES NOT CONTAIN PARENDS, AN ERROR.     15050020
         SPACE                                                          15060020
SCON06   B     INVFORMT            IF RC=0, BRANCH                      15110020
         SPACE                                                          15120020
*  IF RETURN CODE IS 4, CHECK NON-NUMERIC FOR LEFT OR RIGHT PAREND      15170020
         SPACE                                                          15180020
         SR    R3,R2               CALCULATE LNTH OF NUMERIC PORTION    15230020
         BZ    INVCHAR             IF NO NUMERICS, BRANCH               15240020
         CH    R3,ZERO(R5)         DOES LNTH EXCEED MAX                 15290020
         BH    TOOBIG1             IF LNTH EXCEEDS MAX, BRANCH          15300020
         BL    SCON12              IF LNTH IS LESS THAN MAX, BRANCH     15350020
         SPACE                                                          15360020
*  IF LENGTH EQUALS MAXIMUM, COMPARE VALUE TO MAX VALUE.                15410020
         SPACE                                                          15420020
         BCTR  R3,NULL             DECREMENT LNTH FOR CLC INSTR         15470020
         EX    R3,DATACLC1         COMPARE DATA TO MAX VALUE            15480020
         BH    TOOBIG2             IF VALUE EXCEEDS MAX, BRANCH         15530020
SCON12   EQU   *                                                        15540020
         CLC   ZERO(ONE,R6),SMAXL(R5) COMPARE NON-NUMERIC TO EXPECTED   15590020
         BNE   INVCHAR             IF NOT EXPECTED DELIMITER, BRANCH    15600020
         CLI   ZERO(R6),RPAREND    IS THIS THE FINAL DELIMITER          15650020
         LA    R5,SMAX2            INCRE LIMIT PTR TO REG LIMITS        15660020
         LA    R6,ONE(R6)          INCRE DATA PTR TO NEXT DATA BYTE     15710020
         BE    SCON20              IF FINAL DELIMITER, BRANCH OUT       15720020
         BCT   R2,SCON04           IF MORE CHARACTERS, BRANCH BACK      15770020
         B     INVCHAR             GO TO ERROR ROUTINE                  15780020
         SPACE                                                          15830020
SCON20   EQU   *                                                        15840020
         BCT   R2,INVCHAR          IF MORE CHARACTERS, ERROR, BRANCH    15890020
         B     VALOK               OTHERWISE, VALUE IS OK, RETURN       15900020
         SPACE 2                                                        15950020
INVFORMT EQU   *                                                        15960020
         LA    R15,PCHMSG03        SET MSG CODE FOR MSG NUMBER 3        16010020
         BAL   R14,MSGSETUP        GO MOVE MESSAGES TO BUFFER           16020020
         B     VMSGOUT             GO OUTPUT MESSAGE                    16070020
         SPACE                                                          16080020
INVCHAR  EQU   *                                                        16130020
         LA    R15,PCHMSG00        SET MSG CODE FOR MSG 0               16140020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            16190020
         B     VMSGOUT             GO COMPLETE MSG                      16200020
         SPACE                                                          16250020
TOOBIG1  EQU   *                                                        16260020
         LA    R15,PCHMSG01        SET MSG CODE FOR MSG 1               16310020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            16320020
         B     VMSGOUT             GO OUTPUT MSG                        16370020
         SPACE                                                          16380020
TOOBIG2  EQU   *                                                        16430020
         LA    R15,PCHMSG02        SET MSG CODE FOR MSG 2               16440020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            16490020
         SPACE                                                          16500020
VMSGOUT  EQU   *                                                        16550020
         LH    R2,PDEVALEN(R7)     GET LENGTH OF INPUT                  16560020
         CH    R2,VALLMT           IS IT 3 OR GREATER                   16610020
         LA    R3,TWO              INITIALIZE TO MOVE 3 BYTES TO BUF    16620020
         BNL   VLENOK              IF LENGTH 3 OR GREATER, GO MOVE 3    16670020
         LR    R3,R2               OTHER WISE, USE ACTUAL LENGTH        16680020
         BCTR  R3,NULL                 DECRE BY ONE FOR MVC.            16730020
VLENOK   EQU   *                                                        16740020
         MVC   TYPEOSET(ONE,R5),TYPESAVE   MOVE VALUES 'TYPE' INTO MSG  16790020
         L     R15,PDEVALPT(R7)    ADDR OF DATA STRING                  16800020
         EX    R3,VMVC             MOVE 1ST CHARACTERS OF               16850020
         BAL   R14,PCHIO           GO OUTPUT THE MESSAGES               16860020
         CH    R15,HSIXTEEN        TEST RETURN CODE                     16870020
         BL    PRC8                RETURN TO PARSE WITH RC=8            16880020
         B     PRC1620             STORE RET CODE AND RETURN TO PARSE   16890020
VMVC     MVC   DATAOSET(NULL,R5),ZERO(R15)  MOVES 1ST DATA CHARS TO MSG 16920020
         SPACE 2                                                        16970020
*********************************************************************** 16980020
*                                                                     * 17030020
*  MESSAGE SET UP ROUTINE MOVES THE FIRST AND SECOND LEVEL MESSAGES   * 17040020
*  TO THE BUFFER AND SETS UP THE IO PARAMETER LIST. AT ENTRY,         * 17090020
*        R14   CONTAINS THE RETURN ADDRESS                            * 17100020
*        R15   CONTAINS THE OFFSET TO THE MESSAGE ADCONS              * 17150020
*  AT EXIT FROM THIS ROUTINE,                                         * 17160020
*        R5    CONTAINS A PTR TO THE START OF THE OUTPUT BUFFER       * 17210020
*        IOLIST CONTAINS PTRS TO THE 1ST AND 2ND LEVEL MESSAGES.      * 17220020
*                                                                     * 17270020
*********************************************************************** 17280020
MSGSETUP EQU   *                                                        17330020
         SAVE  (14,12)             SAVE CALLERS REGS                    17340020
         L     R5,OUTBUF           R5=PTR TO OUTPUT BUFFER              17390020
         A     R15,PCHMSGCT        R15=ADDR OF MSG LIST                 17400020
         SR    R6,R6               SET UP 2ND LEVEL MSG PTR AS ZERO     17450020
         LM    R2,R3,ZERO(R15)     GET ADDRESSES OF MSGS.               17460020
         LH    R4,ZERO(R2)         PICK UP MESSAGE LENGTH               17510020
         BCTR  R4,NULL             DECREMENT LNTH FOR MVC INSTR         17520020
         EX    R4,MSGMVC1          MOVE 1ST LEVEL MSG TO BUF            17570020
         LTR   R3,R3               TEST FOR A SECOND LEVEL MSG          17580020
         BZ    MSGSET20            IF NO SECOND LEVEL MSG, BRANCH       17630020
         LH    R4,ZERO(R3)         PICK UP MESSAGE LENGTH               17640020
         BCTR  R4,NULL             DECREMENT LNTH FOR MVC INSTR         17690020
         EX    R4,MSGMVC2          MOVE 2ND MSG TO BUF                  17700020
         MVC   M2OFFSET(LL00IDL,R5),ZERO(R5) MOVE IN CONTROL FLD AND ID 17750020
         LA    R4,ONE+LL00IDL(R4)  CALCULATE TOTAL LNTH OF 2ND LVL MSG  17760020
         STH   R4,M2OFFSET(R5)     SET 2ND LEVEL MSG LNTH FIELD         17810020
         LA    R6,M2OFFSET(R5)     CALCULATE ADDR OF 2ND LEVEL MSG      17820020
MSGSET20 EQU   *                                                        17870020
         ST    R5,R5OFF(R13)       SET UP REG 5 FOR CALLER              17880020
         STM   R5,R6,MSGPLIST      SET UP IO PARAMETER LIST             17930020
         RETURN (14,12)            GO BACK TO CALLER                    17940020
MSGMVC1  MVC   ZERO(NULL,R5),ZERO(R2)  MOVES 1ST LEVEL MSGS TO BUFFER   17990020
MSGMVC2  MVC   M2OFFSET+LL00IDL(NULL,R5),TWO(R3)  MOVES 2ND LVL MSG'S   18000020
         SPACE 2                                                        18050020
*  GENERAL OUTPUT ROUTINE, INTER FACES WITH IKJEGIO1.                   18060020
         SPACE                                                          18110020
PCHIO    EQU   *                                                        18120020
         LA    R1,MSGPLIST         SET UP ADDR OF MSG PARM LIST         18170020
         L     R15,TPUTADDR        ADDR OF PUTLINE EP OF IKJEGIO1       18180020
         LCR   R1,R1               MAKE R1 NEG TO INDICATE MSG          18230020
         BR    R15                 GO TO IO RTN (R14 HAS RETURN ADDR)   18240020
         SPACE                                                          18290020
BDYIO    EQU   *                                                        18300020
         BAL   R14,PCHIO           GO OUTPUT THE MESSAGES               18350020
         B     CVTRC               GO ANALYZE RETURN CODE               18360020
         SPACE                                                          18410020
INVTYPE  EQU   *                                                        18590020
         LA    R15,FOUR            SET RC=J SO PARSE WILL PROMPT        18600020
         B     RETTOPAR            GO RETURN TO PARSE.                  18650020
CVTRC    EQU   *                                                        18660020
         CH    R15,HSIXTEEN        IS THE RETURN CODE 16                18710020
         BE    PCHCC16             IF RC=16, BRANCH TO RC=16 RTN.       18720020
         B     PCHRET1             OTHERWISE, BRANCH TO WRAPUP RTN.     18770020
         SPACE 2                                                        18780020
*********************************************************************** 18830020
*                                                                     * 18840020
*  THE FOLLOWING ROUTINE CHECKS THAT EACH CHAR IN A STRING IS NUMERIC * 18890020
*        INPUT IS   R2 CONTAINS LENGTH OF STRING                      * 18900020
*                   R6 CONTAINS PTR TO START OF STRING                * 18950020
*                   R14 CONTAINS RETURN ADDRESS                       * 18960020
*                                                                     * 19010020
*********************************************************************** 19020020
         SPACE                                                          19070020
NUMSCAN  EQU   *                                                        19080020
         LA    R15,FOUR            SET ERROR RETURN CODE                19130020
NUMSCAN2 EQU   *                                                        19140020
         CLI   ZERO(R6),DEC0       IS CHAR EQ OR GT AN EBCDIC '0'       19190020
         BCR   LOW,R14             IF NOT, RETURN WITH RC=4             19200020
         CLI   ZERO(R6),DEC9       IS CHAR EQ OR LT AN EBCDIC '9'       19250020
         BCR   HIGH,R14            IF NOT, RETURN WITH RC=4             19260020
         LA    R6,ONE(R6)          INCREMENT PTR TO STRING              19310020
         BCT   R2,NUMSCAN2         DECREMENT LENGTH AND LOOP IF MORE    19320020
         SR    R15,R15             SET RETURN CODE TO 0                 19370020
         BR    R14                 RETURN TO CALLER                     19380020
         TITLE 'IKJEGPCH, ASSIGN SUBCOMMAND OF TEST, ERROR ROUTINES'    19430020
PCHCC16  EQU   *                                                        19440020
         LA    R15,SIXTEEN         SETUP A RETURN CODE OF 16.           19490020
         ST    R15,PCHRETCD        STORE RETURN CODE IN RC FIELD.       19500020
         B     PCHRET1             GO RETURN TO CALLER                  19550020
         ORG   *-4                 REUSE SPACE NOT NEEDED FOR RC=0      19560020
PARSRC   EQU   *                                                        19610020
         ORG                                                            19620020
         B     PARSRC04            RETURN CODE OF 4 ROUTINE.            19670020
         B     PCHCC16             GO SET RETURN CODE FOR ATTN DETECTED 19680020
         B     PARSRC12            GO TO ROUTINE FOR RC 12.             19730020
         B     PARSRC16            RETURN CODE IS 16                    19740020
         B     PCHRET1             RETURN TO MAINLINE IMMEDIATELY       19750020
         SPACE                                                          19760020
*  IF PARSE RETURN CODE WAS 4, ENTER HERE AFTER PARSE                   19770020
         SPACE                                                          19780020
PARSRC04 EQU   *                                                        19782020
         OI    TSTFLGS4,TSTFLUSH   TELL MNLINE TO FLUSH STACK           19782420
         XR    R15,R15             ZERO RETURN CODE TO MNLINE           19784020
         ST    R15,PCHRETCD        STORE RETURN CODE IN RC FIELD        19786020
         B     PCHRET1             RETURN TO MNLINE                     19786420
         SPACE                                                          19788020
*  IF PARSE RETURN CODE WAS 12, ENTER HERE AFTER PARSE                  19788420
         SPACE                                                          19788820
PARSRC12 EQU   *                                                        19789220
         LA    R15,PCHMSG04        SET UP OFFSET TO MSG FOR RC=12       19789620
         B     PARSCM10            GO TO COMMON MSG ROUTINE             19789720
         SPACE                                                          19790020
*  IF THE RETURN CODE WAS 16, THIS ROUTINE IS BRANCHED TO AFTER PARSE.* 19800020
         SPACE                                                          19850020
PARSRC16 EQU   *                                                        19860020
         LA    R15,PCHMSG05        OFFSET TO INSUFFIENT STORAGE MSG     19910820
PARSCM10 EQU   *                                                        19912020
         BAL   R14,MSGSETUP        GO MOVE MESSAGE TO BUFFER            19920020
         B     BDYIO               USE SAME ERR RTN AS BOUNDARY ERRORS. 19970020
         EJECT                                                          19980020
*********************************************************************** 20030020
*                                                                       20040020
*        STAE RETRY ROUTINE                                             20090020
*                                                                       20100020
*********************************************************************** 20150020
         SPACE 3                                                        20160020
RETRY    EQU   *                                                        20210020
         L     R4,CVTPTR           PTR TO CVT                           20220020
         USING CVTDSECT,R4         ADDRESSABILITY FOR CVT               20270020
         L     R4,CVTTCBP          TCB PTR                              20280020
         L     R4,FOUR(R4)         CURRENT TCB PTR                      20330020
         DROP  R4                                                       20340020
         USING TCB,R4              TCB ADDRESSABILITY                   20390020
         L     R9,TCBTRN           TCOMTAB PTR                          20400020
         L     R13,REGSAVE2        PTR TO SAVE AREA                     20450020
         LM    R10,R12,R10OFF(R13)     RESTORE MODULE ADDRESSABILITY    20460020
         LTR   R0,R0               WAS WORKSPACE FREED                  20510020
         BNZ   PCHFREE             GO TO FREE WORKSPACE                 20520020
         FREEMAIN R,LV=104,A=(R1)  FREE WORKSPACE                       20570020
PCHFREE  EQU   *                                                        20580020
         LA    R15,TWENTY          INDICATE ERROR RETURN                20630020
         ST    R15,PCHRETCD        SAVE RETURN CODE                     20640020
         B     PCHRET1             RETURN                               20690020
         TITLE 'IKJEGPCH, ASSIGN, CONSTANTS, DSECTS, AND PARSE MACROS'  20700020
DATAMVC1 MVC   ZERO(NULL,R15),ONE(R1)  MOVES DATA TO USERS CORE         20750020
DATAMVC2 MVC   ONE(ZERO,R1),ZERO(R15)   USED TO MOVE DATA INTO CONAREA  20760020
DATAMVC3 MVC   ONE(ZERO,R15),HOLDAREA+ONE  MOVES DATA TO CONVERT AREA   20810020
PCHTR    TR    ZERO(ZERO,R15),PCHTRTBL    TRANSLATE TO UPPER CASE       20820020
         SPACE 2                                                        20870020
*  THE FOLLOWING CONSTANTS MUST REMAIN TOGETHER WITH NEGZONE FIRST    * 20880020
*  AND POSZONE SECOND. THEY ARE USED IN SUBROUTINE 'ZONERTN'.         * 20930020
         SPACE                                                          20940020
NEGZONE  DC    Z'-1'               BYTE WITH NEGATIVE ZONE FIELD.       20990020
POSZONE  DC    Z'+1'               BYTE WITH POSITIVE ZONE FIELD.       21000020
         SPACE 2                                                        21050020
FONE     DC    F'1'                FOR ROUNDING HALFWORD ADDRS          21060020
FTHREE   DC    F'3'                *            FULLWORD                21110020
FFOUR    DC    F'4'                CONSTANT FOR COMPARE                 21120020
FSEVEN   DC    F'7'                *            DBL WORD                21170020
         SPACE                                                          21180020
HFOUR    DC    H'4'                GENERAL CONSTANT OF 4                21230020
HEIGHT   DC    H'8'                GENERAL CONSTANT OF 8                21240020
HSIXTEEN DC    H'16'               USED TO TEST FOR RC=16               21290020
         SPACE                                                          21300020
VALLMT   DC    H'3'                NUMBER OF CHARS OF VALUE IN MSG MA1  21350020
         SPACE                                                          21360020
HB       DC    C'HALF'             MOVED INTO ERROR MSG MB3T            21410020
FB       DC    C'FULL'             MOVED INTO ERROR MSG MB3T            21420020
DB       DC    C'DBL'              MOVED INTO ERROR MSG MB3T            21470020
         SPACE 2                                                        21472020
ASN      DC    C'ASN'              CONSTANT USED BY MAINLINE BLDL RTNE  21474020
         SPACE 2                                                        21480020
GRDATA   DS    0F                                                       21530020
GRINCR   DC    H'1'                INCRE VALUE FOR GEN REG ADDRS        21540020
GRLIM    DC    H'15'               MAX GEN REG ADDR                     21590020
         SPACE                                                          21600020
FPRDATA  DS    0F                                                       21650020
FPRINCR  DC    H'2'                INCRE VALUE FOR FL PT REGS.          21660020
FPRLIM   DC    H'6'                MAX FL PT REG ADDR                   21710020
         SPACE                                                          21720020
LADRINCR DC    X'02000008'         USED TO INCR REG NO. AND DATA ADDR   21770020
         SPACE                                                          21780020
FMAX     DC    H'10'               MAX NUMBER OF CHAR IN F CONSTANT     21830020
         DC    C'2147483648'       MAX NUMBER FOR A,F,Q, AND V TYPES    21840020
HMAX     DC    H'5'                MAX NUMBER OF CHAR IN H CONSTANT     21890020
         DC    C'32768'            MAX NUMBER FOR H AND Y TYPES         21900020
ZMAX     DC    H'16'               MAX NUMBER OF DIGITS IN ZONED DATA   21950020
PMAX     DC    H'31'               MAX LENGTH FOR PACKED STRING         21960020
         SPACE                                                          22010020
*  LIMITS FOR 'D' TYPE FLOATING POINT CONSTANTS.                        22020020
         SPACE                                                          22030020
DMAX     DC    H'17'               COEFFICIENT LENGTH LIMIT             22070020
         DC    H'2'                EXPONENT LENGTH LIMIT                22080020
         DC    H'76'               POSITIVE EXPONENT VALUE LIMIT        22130020
         DC    C'72370055773322621'     POS COEFFICIENT VALUE LIMIT     22140020
DMAXNEG  DC    H'78'               NEGATIVE EXPONENT VALUE LIMIT        22190020
         DC    C'53976053469340278'     NEG COEFFICIENT VALUE LIMIT     22200020
         SPACE                                                          22210020
*  LIMITS FOR 'E' TYPE FLOATING POINT CONSTANTS.                        22250020
         SPACE                                                          22260020
EMAX     DC    H'8'                COEFFICIENT LENGTH LIMIT             22310020
         DC    H'2'                EXPONENT LENGTH LIMIT                22320020
         DC    H'76'               POSITIVE EXPONENT VALUE LIMIT        22370020
         DC    C'72370053'         POSITIVE COEFFICIENT VALUE LIMIT     22380020
         SPACE                                                          22500020
XMAX     DC    H'64'               LIMITS FOR X, C, AND B TYPE CONSTANT 22550020
         SPACE                                                          22560020
SMAX1    DC    H'4'                MAX LNTH FOR SCON DISPLACEMENT FLD   22610020
         DC    C'4095'             MAX VALUE FOR DISPLACEMENT           22620020
SMAXL    EQU   *-SMAX1             SYMBOLIC OFFSET TO DELIMITER         22670020
         DC    C'('                BEGIN DELIMITER FOR REG NUMBER       22680020
         SPACE                                                          22730020
SMAX2    DC    H'2'                MAX LNTH FOR SCON REG NUMBER FLD     22740020
         DC    CL4'15'             MAX VALUE FOR SCON REG NUMBER        22790020
         DC    C')'                END DELIMITER FOR REG NUMBER         22800020
         SPACE                                                          22850020
PCHMSGCT DC    V(IKJEGMSC)           ADDR OF MESSAGE CSECT              22860020
         SPACE                                                          22910020
PARSEPCL DC    V(IKJEGPMB)         ADDRESS OF PARSE PARM CNTRL LIST     22920020
         SPACE                                                          22970020
RETRYAD  DC    A(RETRY)            ADDRESS OF STAE RETRY ROUTINE        22980020
         SPACE                                                          22990020
PCHABEND EQU   *                                                        23000020
         DS    0F                                                       23002020
         DC    AL1(3)              CODE FOR LINK TO PARSE FAILED        23010020
         DC    AL3(PARSEBLO)       ADDRESS OF POTENTIAL ABEND           23020020
         DC    X'FF'               TABLE STOPPER                        23022020
         EJECT                                                          23030020
         DS    0D                                                       23032020
PCHTRTBL DC    256AL1(*-PCHTRTBL)  LOWER TO UPPER CASE TR TABLE         23040020
         ORG   PCHTRTBL+C'A'-X'40' SET LOCATION CTR TO LOWER CASE 'A'   23090020
         DC    (C'Z'-C'A'+1)AL1(*-PCHTRTBL+X'40')  DEFINES UPPER CASE   23100020
         ORG                                                            23150020
         SPACE 2                                                        23160020
*********************************************************************** 23210020
*  THE FOLLOWING TABLE IS USED TO CHECK AND TO CONVERT THE ASSEMBLER  * 23220020
*  TYPE CODES FOR VALUES INTO A HEX CODE FOR INTERNAL PROCESSING. THIS* 23270020
*  CODE IS THE SAME AS THAT USED BY THE ASSEMBLER IN SYM RECORDS.     * 23280020
         SPACE                                                          23330020
         ORG   *-C'A'              BACK UP LOC CTR TO ORGIN TABLE       23340020
TYPETBL  EQU   *                                                        23390020
         ORG   *+C'A'              ONLY USE SPACE FOR UPPER CASE ALPHA  23400020
         DC    X'2008001C'         CODES FOR A, B, C, AND D TYPE CONS.  23450020
         DC    X'1810FF14'         CODES FOR E, F, INV, AND H CONS.     23460020
         DC    (C'P'-C'H'-1)X'FF'  CODES FOR INV'S BETWEEN H AND P      23510020
         DC    X'30'               CODE FOR P TYPE CONSTANTS.           23520020
         DC    (C'S'-C'P'-1)X'FF'  CODES FOR INV'S BETWEEN P AND S.     23570020
         DC    X'28FFFFFF'         CODE FOR S TYPE CONS AND 3 INVS.     23580020
         DC    X'FF042434'         CODES FOR INV, X, Y, AND Z CONS.     23630020
*********************************************************************** 23640020
         SPACE 2                                                        23690020
XTRTT    EQU   *                                                        23700020
         DC    256X'01'            NON-ZERO VALUE FOR NON-HEX DIGITS    23750020
         ORG   XTRTT+C'A'-C' '     POSITION FOR LOWER CASE 'ABCDEF'     23760020
         DC    6AL1(0)             DEFINE LOWER CASE ABCDEF             23810020
         ORG   XTRTT+C'A'          POSITION FOR UPPER CASE 'ABCDEF'     23820020
         DC    6AL1(0)             DEFINE UPPER CASE ABCDEF             23870020
         ORG   XTRTT+C'0'          POSITION FOR DECIMAL DIGITS 0-9      23880020
         DC    10AL1(0)            DEFINE DECIMAL DIGITS 0-9            23930020
         EJECT                                                          23940020
*  PARSE MACROS                                                         23990020
         SPACE                                                          24000020
IKJEGPMB IKJPARM                                                        24050020
ADDR     IKJPOSIT  ADDRESS,PROMPT='ADDRESS',VALIDCK=PCHVALAD            24060020
VAL      IKJPOSIT  VALUE,LIST,ASIS,PROMPT='VALUE',VALIDCK=PCHVALTP      24110020
         IKJENDP                                                        24120020
         EJECT                                                          24170020
*                                                                       24172020
*        FOLLOWING IS A MAP OF THE WORK AREA USED BY THE PATCH MODULES  24174020
*                                                                       24176020
PCHWORK  DSECT                                                          24180020
XCTLLST  XCTL  SF=L                PARM LIST                            24250020
XCTLLSTL EQU   *-XCTLLST           LENGTH OF LIST                       24252020
         ORG   XCTLLST             REUSE SPACE OF THE XCTL PARM LIST    24260020
PPCL     DS    7F                  SPACE FOR PARSE PARM LIST            24280020
         SPACE                                                          24282020
ADDRINCR DS    F                   FULLWORD TO HOLD CONSTANTS FOR REGS  24290020
MAXRADDR EQU   ADDRINCR+2          OFFSET FOR MAX REG NUMBER            24300020
PCHRETCD DS    F                   HOLDS CURRENT RETURN CODE            24350020
VPDE     DS    3F                  HOLDS CURRENT COPY OF THE VALUE PDE  24360020
A1       DS    F                   HOLDS CURRENT ADDR TO BE PATCHED     24410020
DUMMYPDE DS    XL(LVALPDE)         RESERVE SPACE FOR COPY OF VALUE PDE. 24420020
A1L      DS    H                   HOLDS CURRENT STRING LNTH FOR 'C'    24470020
A1TYPE   DS    X                   CONTAINS TYPE ASSOCIATED WITH VALUE  24480020
RETRYSAV DS    AL3                 CONTAINS ADDR OF MAINLINE STAE RETRY 24490020
         DS    XL1                 INCREMENT LOCATION CTR BY 1.         24530020
         DS    0D                                                       24540020
         ORG   *-1                 POSITION FOR LENGTH BYTE OF HOLDAREA 24590020
CONAREA1 DS    XL41                USED FOR ADDRESSING PURPOSES ONLY.   24600020
         ORG   CONAREA1            RE-USE SPACE FOR ACTUAL HOLDAREA     24650020
HOLDAREA DS    XL65                TEMP HOLD AREA FOR DATA CONVERSION   24660020
MSGPLIST DS    2F                  PARM LIST FOR CALLING IKJEGIO1.      24710020
STAELIST STAE  MF=L                PARM LIST FOR STAE                   24720020
TYPESAVE DS    C                   FOR SAVING USER SUPPLIED TYPE CODE   24780020
LPCHWORK EQU   *-PCHWORK           LENGTH OF TOTAL DSECT.               24830020
         EJECT                                                          24832020
         TCOMTAB                                                        24840020
         TITLE 'IKJEGPCH, MESSAGE CSECT'                                24890020
IKJEGMSC CSECT                                                          24900020
*  VALUE INVALID BECAUSE IT CONTAINS AN INVALID CHARACTER FOR THIS TYPE 24950020
         SPACE                                                          24960020
MSG00    DC    A(MA1L)             FIRST LEVEL                          25010020
         DC    A(MB1L)             SECOND LEVEL                         25020020
         SPACE 2                                                        25070020
*  VALUE INVALID BECAUSE THE DATA STRING IS TOO LONG                    25080020
         SPACE                                                          25130020
MSG01    DC    A(MA1L)             FIRST LEVEL                          25140020
         DC    A(MC1L)             SECOND LEVEL                         25190020
         SPACE 2                                                        25200020
*  VALUE INVALID BECAUSE IT EXCEEDS THE ABSOLUTE MAXIMUM FOR THIS TYPE  25250020
         SPACE                                                          25260020
MSG02    DC    A(MA1L)             FIRST LEVEL                          25310020
         DC    A(MD1L)             SECOND LEVEL                         25320020
         SPACE 2                                                        25370020
*  VALUE INVALID BECAUSE THE DATA STRING HAS THE WRONG FORMAT           25380020
         SPACE                                                          25430020
MSG03    DC    A(MA1L)             FIRST LEVEL                          25440020
         DC    A(ME1L)             SECOND LEVEL                         25490020
         SPACE 2                                                        25500020
*  ASSIGNMENT FAILED, COMMAND SYSTEM ERROR, PARSE ERROR CODE 12         25640020
         SPACE                                                          25650020
MSG04    DC    A(MA4L)             FIRST LEVEL                          25660020
         DC    A(MB4L)             SECOND LEVEL                         25662020
         SPACE 2                                                        25664020
*  NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND                           25666020
         SPACE                                                          25668020
MSG05    DC    A(MA3L)             FIRST LEVEL                          25668420
         DC    A(0)                NO SECOND LEVEL FOR THIS ONE         25668820
         EJECT                                                          25670020
         DS    0H                                                       25680020
MA1L     DC    AL2(MA1E-MA1L)      MESSAGE LENGTH                       25730020
         DC    AL2(0)              OFFSET FIELD                         25740020
         DC    C'IKJ57060I VALUE BEGINNING  ''    INVALID+'  MSG TEXT   25790020
MA1E     EQU   *                                                        25800020
         SPACE                                                          25850020
         DS    0H                                                       25860020
MB1L     DC    AL2(MB1E-MB1T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  25910020
MB1T     DC    C'DATA STRING CONTAINS AN INVALID CHARACTER' MSG TEXT    25920020
MB1E     EQU   *                                                        25970020
         SPACE                                                          25980020
         DS    0H                                                       26030020
MC1L     DC    AL2(MC1E-MC1T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  26040020
MC1T     DC    C'DATA STRING TOO LONG'                      MSG TEXT    26090020
MC1E     EQU   *                                                        26100020
         SPACE                                                          26150020
         DS    0H                                                       26160020
MD1L     DC    AL2(MD1E-MD1T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  26210020
MD1T     DC    C'ABSOLUTE VALUE TOO GREAT'                  MSG TEXT    26220020
MD1E     EQU   *                                                        26270020
         SPACE                                                          26280020
         DS    0H                                                       26330020
ME1L     DC    AL2(ME1E-ME1T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  26340020
ME1T     DC    C'DATA FORMAT IS INCORRECT'                  MSG TEXT    26390020
ME1E     EQU   *                                                        26400020
         SPACE                                                          26450020
         DS    0H                                                       26752420
MA4L     DC    AL2(MA4E-MA4L)      MESSAGE LENGTH                       26752820
         DC    AL2(0)              OFFSET FIELD                         26753220
         DC    C'IKJ57067I ASSIGNMENT FAILED, COMMAND SYSTEM ERROR+' *  26753620
MA4E     EQU   *                                                        26761920
         SPACE                                                          26765620
         DS    0H                                                       26769320
MB4L     DC    AL2(MB4E-MB4T)      MSG LENGTH (WITHOUT ID OR LNTH FLD)  26773020
MB4T     DC    C'PARSE ERROR CODE 12'  MSG TEXT                         26776720
MB4E     EQU   *                                                        26780420
         SPACE                                                          26784120
         DS    0H                                                       26787820
MA3L     DC    AL2(MA3E-MA3L)      MESSAGE LENGTH                       26791520
MA3T     DC    C'IKJ57065I NOT ENOUGH MAIN STORAGE'    MSG TEXT         26795220
         DC    C' TO EXECUTE COMMAND'                  MSG TEXT CONT.   26798920
MA3E     EQU   *                                                        26802620
         EJECT                                                          26806320
         IKJPARMA                  EXPAND THE ADDR PDE MAPPING DSECT    26810020
         SPACE 3                                                        26812020
         TSTCWORK                  EXPAND TEST'S CORE MAPPING DSECT     26820020
         EJECT                                                          26830020
CVTDSECT DSECT                                                          26870020
         CVT                                                            26880020
         IKJTCB                                                         26930020
         IKJPPL                                                         26932020
         END                                                            26940020
