PSW      TITLE 'IKJEGPSW - TSO TEST LIST PSW ROUTINE'                   00100020
IKJEGPSW CSECT                                                          00200020
*********************************************************************** 00300020
* TITLE      IKJEGPSW - TSO TEST LIST PSW ROUTINE                     * 00400020
*                                                                     * 00500020
* STATUS --                                                           * 00600020
*    CHANGE LEVEL 000                                                 * 00700020
*                                                                     * 00800020
* FUNCTION/OPERATION --                                               * 00900020
*    THIS COMMAND PROGRAM RECEIVES CONTROL FROM THE TEST SUBCOMMAND   * 01000020
*    PROCESSOR.  IT DISPLAYS THE PSW OF THE PROBLEM PROG OR THE PSW   * 01100020
*    AT A SPECIFIED ADDRESS.                                          * 01200020
*                                                                     * 01300020
* ENTRY POINTS --                                                     * 01400020
*         IKJEGPSW    MAIN ENTRY TO LISTPSW ROUTINE                   * 01500020
*         PSWVALCK    ENTRY TO PARSE ADDRESS VALIDITY CHECK EXIT RT   * 01600020
*                                                                     * 01700020
* INPUT --                                                            * 01800020
*    ONE LINE OF INPUT FROM THE TERMINAL CONTAINING THE SUBCOMMAND    * 01900020
*                                                                     * 02000020
* OUTPUT --                                                           * 02100020
*    LINES OF OUTPUT TO THE TERMINAL OR TO A SPECIFIED DATA SET,      * 02200020
*    THE FIRST BEING A HEADER AND THE SECOND THE PSW FIELDS           * 02300020
*                                                                     * 02400020
* EXTERNAL REFERENCES --                                              * 02500020
*         1.  IKJPARS  - TO SCAN THE INPUT BUFFER                     * 02600020
*         2.  IKJEGCVT - TO CHECK AND CONVERT THE ADDR, IF SPECIFIED, * 02700020
*         AND TO CONVERT THE PSW TO PRINTABLE HEX                     * 02800020
*         3.  IKJEGIO  - TO OUTPUT THE HEADER AND PSW                 * 02900020
*                                                                     * 03000020
* EXITS, NORMAL --                                                    * 03100020
*         RETURN TO IKJEGMNL VIA REGISTER14                           * 03200020
*                                                                     * 03300020
* EXITS, ERROR --                                                     * 03400020
*         NONE                                                        * 03500020
*                                                                     * 03600020
* TABLES/WORK AREAS --                                                * 03700020
*    TCOMTAB - TEST TABLE AND WORKAREA                                * 03800020
*                                                                     * 03900020
* ATTRIBUTES --                                                       * 04000020
*    REENTRANT ROUTINE                                                * 04100020
*    REFRESHABLE ROUTINE                                              * 04200020
*                                                                     * 04300020
* CHARACTER CODE DEPENDENCY --                                        * 04400020
*    RE-ASSEMBLY IS REQUIRED FOR CHANGE OF CODE                       * 04500020
*                                                                     * 04600020
* NOTES --                                                            * 04700020
*    IF AN ADDRESS IS SPECIFIED NEITHER BOUNDARY ALIGNMENT OR DATA    * 04800020
*    VALIDITY IS CHECKED                                              * 04900020
*                                                                     * 05000020
*********************************************************************** 05100020
         EJECT                                                          05200020
*********************************************************************** 05300020
*                                                                     * 05400020
*          REGISTER EQUATES                                           * 05500020
*                                                                     * 05600020
*********************************************************************** 05700020
         SPACE 2                                                        05800020
R0       EQU   0                   REGISTER 0                           05900020
R1       EQU   1                   REGISTER 1                           06000020
R2       EQU   2                   REGISTER 2                           06100020
R3       EQU   3                   REGISTER 3                           06200020
R4       EQU   4                   REGISTER 4                           06300020
R5       EQU   5                   CONTAINS ADDRESS OF WORKAREA         06400020
R6       EQU   6                   REGISTER 6                           06500020
R7       EQU   7                   REGISTER 7                           06600020
R8       EQU   8                   REGISTER 8                           06700020
R9       EQU   9                   BASE FOR TCOMTAB                     06800020
R10      EQU   10                  REGISTER 10                          06900020
R11      EQU   11                  NOT USED                             07000020
R12      EQU   12                  BASE FOR IKJEGPSW                    07100020
R13      EQU   13                  REGISTER 13                          07200020
R14      EQU   14                  REGISTER 14                          07300020
R15      EQU   15                  REGISTER 15                          07400020
         SPACE 2                                                        07500020
*********************************************************************** 07600020
*                                                                     * 07700020
*        OTHER EQUATES                                                * 07800020
*                                                                     * 07900020
*********************************************************************** 08000020
N0       EQU   0                   DECIMAL 0                            08100020
N1       EQU   1                   DECIMAL 1                            08200020
N2       EQU   2                   DECIMAL 2                            08300020
N3       EQU   3                   DECIMAL 3                            08400020
N4       EQU   4                   DECIMAL 4                            08500020
N5       EQU   5                   DECIMAL 5                            08600020
N6       EQU   6                   DECIMAL 6                            08700020
N7       EQU   7                   DECIMAL 7                            08800020
N8       EQU   8                   DECIMAL 8                            08900020
N9       EQU   9                   DECIMAL 9                            09000020
N10      EQU   10                  DECIMAL 10                           09100020
N11      EQU   11                  DECIMAL 11                           09200020
N12      EQU   12                  DECIMAL 12                           09300020
N16      EQU   16                  DECIMAL 16                           09400020
N20      EQU   20                  DECIMAL 20                           09500020
N22      EQU   22                  DECIMAL 22                           09550020
N24      EQU   24                  DECIMAL 24                           09600020
N26      EQU   26                  DECIMAL 26                           09700020
N28      EQU   28                  DECIMAL 28                           09800020
N30      EQU   30                  DECIMAL 30                           09900020
N32      EQU   32                  DECIMAL 32                           10000020
N40      EQU   40                  DECIMAL 40                           10100020
N65      EQU   65                  DECIMAL 65                           10200020
N66      EQU   66                  DECIMAL 66                           10300020
N67      EQU   67                  DECIMAL 67                           10400020
N68      EQU   68                  DECIMAL 68                           10500020
N79      EQU   79                  DECIMAL 79                           10600020
N80      EQU   80                  DECIMAL 80                           10700020
N104     EQU   104                 DECIMAL 104                          10800020
PLUSSIGN EQU   C'+'                PLUS SIGN INDICATE 1ST LEV HAS A 2ND 10900020
NOTSYM   EQU   10                  BC INSTR MASK, BRANCH POSTIVE OR 0   10950020
ADDR     EQU   X'80'               ADDRESS STRING INDICATOR IN PDE      10960020
         EJECT                                                          11000020
         SAVE  (14,12),,*          SAVE MAINLINE'S REGS                 11100020
         LR    R12,R15             USE ENTRY POINT FOR BASE             11200020
         USING IKJEGPSW,R12        ESTABLISH PROGRAM ADDRESSABILITY     11300020
         USING TCOMTAB,R9          ESTABLISH TCOMTAB ADDRESSABILITY     11400020
         L     R15,REGSAVE2        LOAD ADDRESS OF NEW SAVE AREA        11500020
         ST    R13,N4(R15)         STORE REG 13 IN NEW SAVE AREA        11600020
         ST    R15,N8(R13)         STORE NEW SAVE AREA ADDRESS          11700020
         LR    R13,R15             R13 NOW HAS NEW SAVE AREA ADDRESS    11800020
         L     R7,WORKAREA         LOAD ADDRESS OF TEST WORKAREA        11900020
         USING TSTCWORK,R7                                              12000020
         LA    R5,CWORKCMD         ADDRESS OF WORK AREA FOR CMDS        12100020
         USING PSWAREA,R5          ESTABLISH ADDRESSABILITY             12200020
         DROP  R7                                                       12300020
         LA    R1,ABENDTAB         ADDRESS OF PREDICTABLE ABEND TABLE   12400020
         ST    R1,ABENTAB1         INTO TCOMTAB FOR STAE EXIT ROUTINE   12500020
         MVC   TSTRETRY+N1(N3),RETRYADR     STAE RETRY ADDRESS          12600020
*                                    INTO TCOMTAB FOR STAE EXIT ROUTINE 12700020
         L     R3,TSTSTAE          ADDRESS OF STAE EXIT ROUTINE         12800020
         LA    R1,STAELIST         STAE PARAMETER LIST                  12900020
         ST    R12,N68(R13)        SAVE MY BASE IN MY SAVE AREA         13000020
         MVC   N0(N12,R1),LFSTAE   STAE PARAMETER LIST TO WORK AREA     13100020
         STAE  (3),CT,PARAM=(9),XCTL=NO,MF=(E,(1))                      13200020
         LTR   R15,R15             WAS STAE ISSUED SUCCESSFULLY         13300020
SMTSTAE  DS    0H                  SMT TESTCASE LABEL                   13320020
*                                   INSUFFICIENT CORE TO ISSUE STAE     13340020
*                                   TESTCASE ID  TPSW2400               13360020
         BZ    GOPARSE             YES, GO SET UP TO PARSE COMMAND      13400020
         L     R6,=A(IKJEGPWM)     ADDRESS OF MESSAGE SECTION           13900020
         USING IKJEGPWM,R6                                              14000020
         LA    R1,MESGNO3          ADDRESS OF NOT ENOUGH CORE MESG      14100020
         B     MSGIOCTD            GO PUT OUT MESSAGE AND RETURN        14200020
         DROP  R6                                                       14300020
GOPARSE  EQU   *                                                        14400020
         LR    R1,R5               ADDR OF WORK AREA, BUILD PARSE LIST  14500020
         USING PPL,R1                                                   14600020
         MVC   PPLUPT(N4),TSTUPT   POINTER TO UPT FOR PARSE             14700020
         MVC   PPLECT(N4),TSTECT   POINTER TO ECT FOR PARSE             14800020
         MVC   PPLECB(N4),TSTCPECB POINTER TO CP ECB FOR PARSE          14900020
         MVC   PPLPCL(N4),PCLADDR  POINTER TO PCL FOR PARSE             15000020
         LA    R2,TSTANSPL         LOAD ADDRESS OF PARSE ANSWER PLACE   15100020
         ST    R2,PPLANS           STORE IN PARM LIST FOR PARSE         15200020
         MVC   PPLCBUF(N4),INBUF   POINTER TO COMMAND INPUT BUFFER      15300020
         ST    R9,PPLUWA           STORE ADDRESS OF TCOMTAB             15400020
         DROP  R1                                                       15500020
         LINK  EP=IKJPARS          PARSE THE COMMAND                    15600020
PABEND1  EQU   *                   POSSIBLE ABEND RESUME ADDRESS        15700020
SMTPARS  DS    0H                  SMT TESTCASE LABEL                   15720020
*                                   LINK TO PARSE FAILED                15740020
*                                   TESTCASE ID  TPSW2100               15760020
         B     PARSEEND            AFTER PARSE IS COMPLETE, BRANCH      15800020
         SPACE                                                          15900020
*********************************************************************** 16000020
*        THE FOLLOWING IS EXECUTED IMMEDIATELY BEFORE A BRANCH TO     * 16100020
*        IKJEGCVT WHICH VALIDITY CHECKS THE ADDRESS SPECIFIED BY USER * 16200020
*        THIS CODE WILL NOT BE EXECUTED IF THE USER DOES NOT SPECIFY  * 16300020
*        AN ADDRESS                                                   * 16400020
*********************************************************************** 16500020
         SPACE                                                          16600020
PSWVALCK SAVE  (14,12),,*          SAVE PARSE REGISTERS                 16700020
         LR    R2,R1               ADDR OF PARSE LIST FOR EXIT RT       16800020
         L     R9,N4(R1)           RESTORE TCOMTAB ADDRESSABILITY       16900020
         L     R12,REGSAVE2        LOAD ADDRESS OF PSW REGISTERS        17000020
         L     R5,N40(R12)         RESTORE WORKAREA ADDRESS             17100020
         L     R12,N68(R12)        RESTORE PROGRAM ADDRESSABILITY       17200020
         L     R15,REGSAVE3        LOAD ADDRESS OF NEW SAVE AREA        17300020
         ST    R13,N4(R15)         STORE REG 13 IN NEW SAVE AREA        17400020
         ST    R15,N8(R13)         STORE NEW SAVE AREA ADDRESS          17500020
         LR    R13,R15             R13 NOW HAS NEW SAVE AREA ADDRESS    17600020
         L     R1,N0(R1)           POINTER TO ADDRESS PDE               17700020
         LNR   R1,R1               NEGATIVE, ADDR CONVERSION            17800020
         LPR   R0,R1               POSTIVE, CONVERT TO BINARY           17900020
         L     R15,TSTCONVT        LOAD ADDRESS OF IKJEGCVT             18000020
         BALR  R14,R15             VALIDITY CHECK THE ADDRESS           18100020
         SPACE 1                                                        18200020
*********************************************************************** 18300020
*        THE FOLLOWING CODE IS EXECUTED UPON RETURN FROM IKJEGCVT     * 18400020
*********************************************************************** 18500020
         SPACE 1                                                        18600020
         LPR   R1,R1               ADDRESS OF ADDRESS PDE               18700020
         LTR   R15,R15             IS RETURN CODE 0                     18800020
         BZ    CHKADDR             YES, GO CHECK ADDRESS                18900020
         MVC   N8(N4,R2),N32(R1)   PASS ADDR OF 2ND LEV MESG TO PARSE   19000020
         LA    R6,N4               CONVERT UNSUCCESSFUL RETURN CODE     19100020
         CR    R6,R15              WAS CONVERT UNSUCCESSFUL             19200020
         BNE   STOP                NO, WORST TROUBLES, GO SET ENDUP     19300020
         LA    R15,N8              R.C.=8, HAVE PARSE PRINT REENTER     19400020
PARSRTRN L     R13,N4(R13)                                              19500020
         RETURN (14,12),,RC=(15)   RESTORE REGISTERS AND RETURN         19600020
CHKADDR  EQU   *                                                        19700020
         L     R3,N32(R1)          CONVERTED ADDR - USER WORD IN PDE    19800020
         LTR   R3,R3               WAS PASSED ADDR A SYMBOL             19900020
         BC    NOTSYM,CHKMORE      NO, GO CHECK ADDRESS FUTHER          20000020
         L     R3,N0(R3)           WORD USED BY IKJEGSYM                20100020
CHKMORE  EQU   *                                                        20200020
         SR    R15,R15             SUCCESSFUL RETCODE FOR PARSE         20300020
         L     R6,=A(IKJEGPWM)     ADDRESS OF MESSAGE SECTION           20400020
         USING IKJEGPWM,R6                                              20500020
         LH    R4,N26(R1)          INDIRECT COUNT                       20600020
         LTR   R4,R4               IS ADDRESS INDIRECT                  20700020
         BZ    CHKREG              NO, GO CHECK FOR REGISTER ADDRESS    20800020
CHKEND   EQU   *                                                        20900020
         LA    R3,N7(R3)           ADDRESS OF END OF PSW                21000020
         C     R3,TSTTOP           END ADDRESS OUT OF CORE              21100020
         BNH   PARSRTRN            NO, ADDR OK, GO RETURN TO PARSE      21200020
         LA    R3,M340L2B          YES, ADDR OF SECOND LEVEL MESSAGE    21300020
         ST    R3,OUTPTR2          TO A DOUBLE WORD FOR I/O             21400020
         B     GIVEMESG            GO GIVE ERROR MESSAGE                21500020
CHKREG   EQU   *                                                        21600020
         TM    N24(R1),HEX38       WAS ADDRESS A REGISTER               21700020
         BZ    CHKEND              NO, GO SEE IF COMPLETE PSW IN CORE   21800020
         LA    R3,M340L2A          ADDRESS OF SECOND LEV MESG           21900020
         ST    R3,OUTPTR2          TO A DOUBLE WORD FOR I/O             22000020
GIVEMESG EQU   *                                                        22100020
         LR    R0,R1               POINTER TO ADDRESS PDE               22200020
         L     R3,OUTBUF           ADDR OF OUTPUT BUFFER, BUILD MESG    22300020
         MVC   N0(N30,R3),M340L1   MOVE FIRST LEVEL TO OUTPUT BUFFER    22400020
         ST    R3,OUTPTR1          ADDR OF FIRST LEVEL TO DOUBLE WORD   22500020
         LA    R1,N30(R3)          ADDR OF POSITION IN MESG FOR ADDR    22600020
         L     R15,TSTADDR         POINTER TO ADDR BUILD ROUTINE        22700020
         BALR  R14,R15             GO ADD ADDRESS TO MESSAGE            22800020
         AH    R0,N0(R3)           LENGTH OF FIRST LEVEL MESSAGE        22900020
         MVI   N0(R1),PLUSSIGN     INDICATE FIRST LEV HAS A SECOND LEV  23000020
         LR    R1,R0               LEN OF FIRST LEV - PLUS SIGN         23100020
         LA    R1,N1(R1)           LENGTH OF FIRST LEVEL MESSAGE        23200020
         STH   R1,N0(R3)           LEN TO OUTPUT BUFF, PREFIX MESG      23300020
         LA    R1,OUTPTR1          ADDRESS OF DOUBLE WORD FOR I/O       23400020
         DROP  R6                                                       23500020
         MVC   N8(N4,R2),N4(R1)    PASS ADDR OF 2ND LEV MESG TO PARSE   23600020
         LNR   R1,R1               REGISTER 1 IS NEGATIVE FOR MESSAGES  23700020
         L     R15,TPUTADDR        ADDRESS OF TEST'S I/O MODULE         23800020
         BALR  R14,R15             GO HAVE MESSAGE PUT OUT              23900020
         LTR   R15,R15             IS R.C. 0, I/O SUCCESSFUL            24000020
         BNE   IOFAILED            NO, GO CHECK R.C. FROM I/O           24100020
         LA    R15,N8              YES, PROMPT R.C. FOR PARSE           24200020
         B     PARSRTRN            GO RETURN TO PARSE                   24300020
IOFAILED EQU   *                                                        24400020
         LA    R6,N4               I/O UNSUCCESSFUL RETURN CODE         24500020
         CR    R6,R15              WAS I/O UNSUCCESSFUL                 24600020
         BNE   STOP                NO, WORST TROUBLES, GO SET ENDUP     24700020
         SR    R15,R15             YES, CREATE 0 R.C. FOR MAINLINE      24800020
STOP     EQU   *                                                        24900020
         ST    R15,ANSWPLAC        SAVE ENDUP RETURN CODE               25000020
         LA    R15,N12             SET ENDUP R.C. FOR PARSE             25100020
         B     PARSRTRN            GO RETURN TO PARSE                   25200020
         SPACE 1                                                        25300020
*********************************************************************** 25400020
*        THE FOLLOWING IS THE CODE EXECUTED UPON RETURN FROM PARSE    * 25500020
*********************************************************************** 25600020
         SPACE 1                                                        25700020
PARSEEND EQU   *                                                        25800020
         LTR   R15,R15             IS RETURN CODE 0                     25900020
         BNZ   PSWRET1             IF NO, BRANCH                        26000020
         L     R8,TSTANSPL         LOAD ADDRESS OF PDL                  26100020
         USING IKJPARMD,R8         ESTABLISH PDL ADDRESSABILITY         26200020
         LA    R4,N40              A OUTPUT LINE LENGTH                 26300020
         CH    R4,TMPLL            IS USER SPECIFIED LINE LENGTH LESS   26400020
         BH    LL80                YES, GO USE 80 FOR LINE LENGTH       26500020
         LA    R4,N80              NO, ANOTHER LINE LENGTH              26600020
         CH    R4,TMPLL            IS SPECIFIED LINE LENGTH GREATER     26700020
         BL    LL80                YES, GO USE 80 FOR LINE LENGTH       26800020
         LH    R4,TMPLL            NO, USE SPECIFIED LINE LENGTH        26900020
         B     LINESET             GO SET LINE LENGTH                   27000020
LL80     LA    R4,N80              DEFAULT LINE LENGTH TO 80            27100020
LINESET  ST    R4,LINELEN          STORE OUTPUT LINE LENGTH             27200020
         CLI   PRINTIT+N1,HEX00    WAS PRINT SPECIFIED                  27300020
         BNZ   PRINTSPC            BRANCH IF YES                        27400020
         XC    PRINTFLG(N4),PRINTFLG                                    27500020
         B     ADDRCHK             GO CHECK FOR ADDRESS                 27600020
PRINTSPC OI    TSTFLGS1,TSTPRINT   INDICATE I/O TO DATA SET             27700020
         LA    R3,DSNAME           ADDRESS OF DSNAME PDE                27800020
         ST    R3,PRINTFLG         STORE ADDRESS OF PDE                 27900020
ADDRCHK  EQU   *                                                        28000020
         L     R3,PDEUSWD          USER WORD IN ADDR PDE                28100020
         LTR   R3,R3               WAS ADDRESS SPECIFIED BY USER        28200020
         BNZ   ADRSPECF            IF YES GO TO ADRSPECF                28300020
         TM    PDEFLAG3,ADDR       WAS ADDRESS SPECIFIED BY USER        28350020
         BO    ADRSPECF            YES, GO GET SPECIFIED PSW            28360020
         SPACE 1                                                        28400020
*********************************************************************** 28500020
*        THE FOLLOWING CODE LOCATES THE PROBLEM PROGRAM PSW           * 28600020
*********************************************************************** 28700020
         SPACE 1                                                        28800020
         L     R2,PPTCB            LOAD R2 WITH PROBLEM PROGRAM TCB     28900020
         L     R2,TCBRBP-TCB(R2)   LOAD SVRB ADDRESS                    29000020
         L     R2,RBLINK-RBSECT(R2)   LOAD REQUEST BLOCK ADDRESS        29100020
         MVC   PSWBUF(N8),RBOPSW-RBSECT(R2)  MOVE PSW TO WORK AREA      29200020
         B     PSWCONVT            BRANCH TO CONVERT PSW TO PRINTABLE   29300020
ADRSPECF EQU   *                                                        29400020
         L     R3,PDEUSWD          USER WORD OF PDE                     29500020
         LTR   R3,R3               WAS ADDRESS SYMBOLIC                 29600020
         BP    PSWNOSYM            BRANCH IF NO                         29700020
         L     R3,N0(R3)           LOAD WORD USED BY IKJEGSYM           29800020
PSWNOSYM MVC   PSWBUF(N8),N0(R3)   MOVE PSW TO WORK AREA                29900020
         SPACE 1                                                        30000020
*********************************************************************** 30100020
*        THE FOLLOWING CODE WILL CONVERT THE PSW FROM MACHINE         * 30200020
*        REPRESENTATION TO PRINTABLE HEX                              * 30300020
*********************************************************************** 30400020
         SPACE 1                                                        30500020
PSWCONVT EQU   *                                                        30600020
         L     R15,TSTCONVT        LOAD ADDRESS OF IKJEGCVT             30700020
         LA    R14,PSWBUF          POINT TO BINARY PSW                  30800020
         ST    R14,STRNGPTR        STORE IN PDE FOR IKJEGCVT            30900020
         MVC   CVTLL(N2),PSWLEN    STORE LENGTH OF PSW IN LIST          31000020
         MVI   FLAGS,FLAG          STORE FLAG IN PDE                    31100020
         MVI   TYPECODE,TYPE       STORE TYPE (HEX) IN PDE              31200020
         LA    R1,STRNGPTR         LOAD ADDRESS OF PDE                  31300020
         LNR   R0,R1               R0 NEGATIVE - CONVERT TO PRINTABLE   31400020
         BALR  R14,R15             GO CONVERT THE PSW TO PRINTABLE      31500020
         LTR   R15,R15             RETURN CODE 0                        31600020
         BNZ   PSWRET              IF NO, BRANCH                        31700020
         SPACE 1                                                        31800020
*********************************************************************** 31900020
*        THE FOLLOWING MOVES THE THREE FIELDS TO BE PRINTED IN HEX TO * 32000020
*        THE OUTPUT FIELD BUFFER                                      * 32100020
*********************************************************************** 32200020
         SPACE 1                                                        32300020
         L     R2,CONAREA          LOAD ADDRESS OF HEX PSW              32400020
         MVI   START,BLANK         BLANK OUT FIRST BYTE OF PSW BUFFER   32500020
         MVC   START+N1(N67),START   BLANK OUT REMAINDER OF PSW BUFFER  32600020
         MVC   KEY(N1),N3(R2)        MOVE KEY TO OUTPUT BUFFER          32700020
         MVC   INTRPTCD(N4),N5(R2)   MOVE INTRPT CODE TO OUTPUT BUFFER  32800020
         MVC   INSTRADR(N6),N11(R2)  MOVE INSTR ADDR TO OUTPUT BUFFER   32900020
         SPACE 1                                                        33000020
*********************************************************************** 33100020
*        THE FOLLOWING CONVERTS THE REMAINING PSW FIELDS TO PRINTABLE * 33200020
*        BINARY AND TRANSFERS THEM TO THE OUTPUT BUFFER               * 33300020
*        THE SECTION OF THE BINARY PSW TO BE CONVERTED IS PUT IN REG7.* 33400020
*        BITS ARE SHIFTED ONE BY ONE INTO REG6.  ACCORDING AS THE BIT * 33500020
*        IS A ZERO OR A ONE A PRINTABLE ZERO OR ONE IS ADDED INTO R10 * 33600020
*        WHEN REG10 IS FULL (AFTER 4 BITS ARE CONVERTED) IT IS STORED * 33700020
*        IN THE WORKAREA.                                             * 33800020
*********************************************************************** 33900020
         SPACE 1                                                        34000020
         MVC   PSWBUF+N2(N1),PSWBUF+N4    MOVE BINARY FIELDS TOGETHER   34100020
         SR    R3,R3                                                    34200020
         SR    R2,R2                                                    34300020
         IC    R3,ZERO             LOAD CHARACTER 0 INTO REGISTER       34400020
         IC    R2,ONE              LOAD CHARACTER 1 INTO REGISTER       34500020
         SR    R6,R6                                                    34600020
         LA    R4,N4               BIT COUNTER                          34700020
         L     R7,PSWBUF           LOAD BINARY PSW                      34800020
         LA    R8,SYSMASK          POINT TO OUTPUT AREA FOR FIELDS      34900020
LOOP1    SLDL  R6,N1(R0)           SHIFT ONE BIT INTO R6                35000020
         LTR   R6,R6               IS IT A ZERO                         35100020
         BE    ZEROBIT             IF YES, BRANCH                       35200020
ONEBIT   SLL   R10,N8(R0)          OTHERWISE IT IS A ONE                35300020
         AR    R10,R2              PUT A CHARACTER ONE IN LOW BYTE      35400020
         SR    R6,R6               ZERO OUT R6 FOR NEXT BIT             35500020
         B     EIGHTBCT            GO CHECK IF R10 IS FULL              35600020
ZEROBIT  SLL   R10,N8(R0)                                               35700020
         AR    R10,R3              PUT A CHARACTER ZERO IN LOW BYTE     35800020
EIGHTBCT BCT   R4,LOOP1            IF R10 IS NOT FULL, BRANCH           35900020
         ST    R10,N0(R8)          STORE R10 IN WORK AREA               36000020
         LA    R8,N4(R8)           INCREMENT OUTPUT POINTER             36100020
         LA    R4,TABLE            LOAD END OF PROCESSING CHECK         36200020
         CR    R8,R4               ARE ALL BITS CONVERTED               36300020
         BE    OUTPUTIT            IF YES, OUTPUT DATA                  36400020
         LA    R4,N4               RESET COUNTER FOR 4 MORE BITS        36500020
         B     LOOP1               CONVERT NEXT FOUR BITS               36600020
         SPACE                                                          36700020
*********************************************************************** 36800020
*        THE FOLLOWING CODE SETS THE OUTPUT LINE LENGTH               * 36900020
*********************************************************************** 37000020
         SPACE 1                                                        37100020
OUTPUTIT MVC   SYSMASK2(N8),SYSMASK     MOVE TO FIELD BUFFER            37200020
         MVC   AMWP2(N4),AMWP           MOVE TO FIELD BUFFER            37300020
         MVC   ILC2(N2),ILC             MOVE TO FIELD BUFFER            37400020
         MVC   CC2(N2),CC               MOVE TO FIELD BUFFER            37500020
         MVC   PROGM2(N4),PROGMASK      MOVE TO FIELD BUFFER            37600020
         L     R10,OUTBUF               POINT TO OUTPUT BUFFER          37700020
         CLI   LINELEN+N3,HEX43    IS LINE LEN LESS THAN HEADER LEN     37800020
         BL    BUILDIT             YES, GO BUILD 2 OUTPUT LINES         37900020
         LA    R2,N66              OUTPUT DATA LENGTH-1                 38000020
         LA    R3,HEADER           ADDRESS OF HEADER TO PUT OUT         38100020
         LA    R6,START            ADDRESS OF PSW DATA TO PUT OUT       38200020
         BAL   R8,PSWIO            GO PUT OUT LINES                     38300020
         B     PSWRET              GO SET UP FOR RETURN TO CALLER       38400020
BUILDIT  EQU   *                                                        38500020
         LA    R2,N40              MINIMUN LINE LENGTH                  38600020
         LA    R3,N4(R2)           MINMIUN LL PLUS CC FIELD             38700020
         C     R3,LINELEN          WILL CC FIELD FIT IN LINE            38800020
         BH    FULLLINE            NO, LINE FULL, GO PUT OUT            38900020
         LR    R2,R3               LENGTH SO FAR                        39000020
         LA    R3,N11(R2)          LEN SO FAR PLUS PROG MASK FIELD      39100020
         C     R3,LINELEN          WILL PROG MASK FIT IN LINE           39200020
         BH    FULLLINE            NO, LINE FULL, GO PUT OUT            39300020
         LR    R2,R3               YES, PUT IT OUT                      39400020
FULLLINE EQU   *                                                        39500020
         BCTR  R2,N0               OUTPUT DATA LENGTH-1                 39600020
         LA    R3,HEADER           ADDRESS OF HEADER TO PUT OUT         39700020
         LA    R6,START            ADDRESS OF PSW DATA TO PUT OUT       39800020
         BAL   R8,PSWIO            GO PUT OUT LINES                     39900020
         LA    R3,N1(R2,R3)        ADDR OF REST OF HEADER TO PUT OUT    40000020
         LA    R6,N1(R2,R6)        ADDR OF REST OF PSW DATA             40100020
         LA    R8,N65              MAXMIUN LENGTH OF HEADER MINUS 2     40200020
         SR    R8,R2               LEN OF DATA MINUS ONE                40300020
         LR    R2,R8               IN PROPER REGISTER                   40400020
         BAL   R8,PSWIO            GO PUT OUT LAST TWO LINES            40500020
         B     PSWRET              GO SET FOR RETURN TO CALLER          40600020
         SPACE 1                                                        40700020
*********************************************************************** 40800020
*        THE FOLLOWING ROUTINE BUILDS AND PUTS OUT THE HEADER AND PSW * 40900020
*        LINES.  R2 IS THE LENGTH-1 OF OUTPUT, R3 IS THE STARTING     * 41000020
*        ADDRESS OF THE HEADER AND R6 IS THE STARTING ADDRESS OF THE  * 41100020
*        PSW DATA.  R8 IS THE RETURN ADDRESS.                         * 41200020
*********************************************************************** 41300020
         SPACE 1                                                        41400020
PSWIO    EQU   *                                                        41500020
         L     R10,OUTBUF          ADDRESS OF COMMON TEST OUTPUT BUFF   41600020
         MVI   N0(R10),HEX40       BLANK                                41700020
         MVC   N1(N79,R10),N0(R10)     OUTBUF                           41800020
         ST    R10,OUTPTR1         SET UP DOUBLE WORD FOR I/O           41900020
         XC    OUTPTR2(N4),OUTPTR2  INDICATE NO SECOND LINE             42000020
         EX    R2,MOVE2            MOVE HEADER TO OUTBUF                42100020
         LA    R2,N5(R2)           LENGTH OF OUTPUT FOR I/O             42200020
         SLL   R2,N16              LENGTH IN HIGH ORDER HALF WORD       42300020
         ST    R2,N0(R10)          PREFIX OUTPUT WITH LENGTH            42400020
         L     R15,TPUTADDR        ADDRESS OF I/O ROUTINE               42500020
         LA    R1,OUTPTR1          POINT TO DOUBLE WORD FOR I/O         42600020
         L     R0,PRINTFLG         INDICATE LINE TO DATASET OR TERMINAL 42700020
         XC    PRINTFLG(N4),PRINTFLG                                    42800020
         BALR  R14,R15             GO TO I/O ROUTINE, PUT OUT HEADER    42900020
         LTR   R15,R15             IS RETURN CODE 0                     43000020
         BNZ   PSWRET              NO, GO SET UP FOR ERROR RETURN       43100020
         SRL   R2,N16              LENGTH IN LOW ORDER HALFWORD OF REG  43200020
         SH    R2,FOUR             LEN-1 OF PSW DATA TO MOVE            43300020
         EX    R2,MOVE3            MOVE PSW DATA TO OUTBUF              43400020
         L     R15,TPUTADDR        ADDRESS OF I/O ROUTINE               43500020
         L     R0,PRINTFLG         INDICATE LINE TO OPEN D.S. OR TERM   43600020
         BALR  R14,R15             GO TO I/O ROUTINE, PUT OUT PSW       43700020
         LTR   R15,R15             IS RETURN CODE 0                     43800020
         BNZ   PSWRET              NO, GO SET UP FOR ERROR RETURN       43900020
         BR    R8                  YES, RETURN TO CALLER                44000020
         SPACE 1                                                        44100020
*********************************************************************** 44200020
* THE FOLLOWING CODE PROCESSES RETURN CODES AND SETS UP FOR OUTPUT OF * 44300020
* MESSAGES.  PSWRET ANALYSES CODES FROM IKJEGIO1 AND IKJEGCVT.        * 44400020
* PSWRET1 ANALYSES RETURN CODES FROM PARSE.                           * 44500020
*********************************************************************** 44600020
         SPACE 1                                                        44700020
PSWRETRY EQU   *                                                        44800020
         L     R9,CVTPTR           ADDRESS OF CVT                       44900020
         L     R9,CVTTCBP-CVT(R9)  POINTER TO NEW, CURRENT TCBS         45000020
         L     R9,N4(R9)           ADDRESS OF CURRENT TCB IS TEST TCB   45100020
         L     R9,TCBTRN-TCB(R9)   ADDRESS OF TCOMTAB                   45200020
         L     R13,REGSAVE2        ADDRESS OF MY SAVE AREA              45300020
         L     R12,N68(R13)        MY BASE                              45400020
         LA    R8,N20              ABEND RETURN CODE FOR MAINLINE       45500020
         LTR   R0,R0               DID STAE GET CORE                    45600020
         BNZ   RETURN              NO, GO RETURN TO MAINLINE            45700020
         FREEMAIN  R,LV=N104,A=(R1),SP=N0   FREE STAE CORE              45800020
         B     RETURN              GO RETURN TO MAINLINE                45900020
EXITERR  EQU   *                                                        46000020
         L     R15,ANSWPLAC        VALIDITY EXIT SAVED RETURN CODE      46100020
PSWRET   EQU   *                                                        46200020
         LA    R8,N16                                                   46300020
         CR    R8,R15              RETURN CODE 16                       46400020
         BE    RETURN              IF YES BRANCH                        46500020
         LA    R8,N20              TEST ABEND RETURN CODE               46600020
         CR    R8,R15              DID SOME ONE ABEND                   46700020
         BE    RETURN              YES, GO SET RETURN                   46800020
         SR    R8,R8               SET RETURN CODE TO 0                 46900020
         B     RETURN              GO SET UP RETURN                     47000020
PSWRET1  EQU   *                   PARSE RETURN CODE ANALYSIS           47100020
         L     R6,=A(IKJEGPWM)     ADDRESS OF MESSAGE SECTION           47200020
         USING IKJEGPWM,R6                                              47300020
         LA    R8,N8               PARSE ATTENTION R.C.                 47400020
         CR    R8,R15              WAS AN ATTENTIOM SCHEDULED           47500020
         LA    R8,N16              MAINLINE ATTENTION RETURN CODE       47600020
         BE    RETURN              IF ATT SCHEDULED, GO SET UP RETURN   47700020
         LA    R8,N20              VALIDITY EXIT SEEKS END, R.C.  PARSE 47800020
         CR    R8,R15              DID VALIDITY EXIT SEEK TERMINATION   47900020
         BE    EXITERR             IF YES, GO SET UP RETURN             48000020
         LA    R8,N16              PARSE R.C. FOR NO CORE AVAILABLE     48100020
         CR    R8,R15              WAS PARSE ABLE TO GET CORE           48200020
         LA    R1,MESGNO3          NO, ADDR OF NOT ENOUGH CORE MESSAGE  48300020
         BE    MSGIOCTD            GO HAVE MESSAGE PUT OUT              48400020
         LA    R8,N12              PARSE R.C. FOR INVALID PARAMETERS    48500020
         CR    R8,R15              WERE INVALID PARMS SPECIFIED         48600020
         LA    R1,MESGNO2          YES, ADDR OF INVALID PARMS MESSAGE   48700020
         BE    MSGIOCTD            GO HAVE MESSAGE PUT OUT              48800020
         DROP  R6                                                       49000020
         SR    R8,R8               PARSE RC=4, NO MESSAGE               49050020
         OI    TSTFLGS4,TSTFLUSH   IF STACK, TELL MNL TO FLUSH          49052020
         B     RETURN              GO RETURN TO CALLER                  49060020
MSGIOCTD EQU   *                                                        49100020
         LNR   R1,R1               REGISTER 1 IS NEGATIVE FOR MESSAGES  49200020
         L     R15,TPUTADDR        ADDRESS OF TEST'S I/O MODULE         49300020
         BALR  R14,R15             GO HAVE MESSAGE PUT OUT              49400020
         B     PSWRET              GO ANALYZE RC FROM I/O               49500020
RETURN   EQU   *                                                        49600020
         NI    TSTFLGS1,(HEXFF-TSTPRINT)                                49700020
         LR    R15,R8              RETCODE IN PROPER REGISTER           49800020
         L     R13,N4(R13)                                              49900020
         RETURN  (14,12),T,RC=(15)                                      50000020
         EJECT                                                          50100020
************************************************************            50200020
*                                                          *            50300020
*            MISCELLANEOUS CONSTANTS                       *            50400020
*                                                          *            50500020
************************************************************            50600020
         SPACE 2                                                        50700020
HEADER   DC    C'SYSTEM MASK  KEY  AMWP  INTRPT CODE  ILC  CC  PROG MAS*50800020
               K  INSTR ADDR'                                           50900020
OFFSET   EQU   64                  OFFSET OF PSWAREA INTO TEST AREA     51000020
HEX00    EQU   X'00'                                                    51100020
HEX38    EQU   X'38'                                                    51200020
HEX43    EQU   X'43'                                                    51300020
HEX40    EQU   X'40'                                                    51400020
PSWLEN   DC    X'0008'             LENGTH OF PSW                        51500020
FLAG     EQU   X'80'               FLAG FOR IKJEGCVT                    51600020
TYPE     EQU   X'04'               TYPE OF VALUE (HEX)                  51700020
ZERO     DC    C'0'                CHARACTER ZERO                       51800020
ONE      DC    C'1'                CHARACTER ONE                        51900020
TABLEVAL DC    X'0A0B04050D06050D' LENGTH OF PSW OUTPUT FIELDS, ONE     52000020
*                                  BYTE PER FIELD IN REVERSE ORDER      52100020
HEXFF    EQU   X'FF'                                                    52200020
PCLADDR  DC    A(IKJEGPWP)         ADDRESS OF PARSE CSECT               52300020
ABENDTAB DS    0F                                                       52400020
         DC    X'03'               LINK FAILED CODE                     52500020
         DC    AL3(PABEND1)        RESUME IC AFTER LINK                 52600020
         DC    X'FF'               END OF TABLE INDICATOR               52700020
RETRYADR DC    AL3(PSWRETRY)       ADDR OF PSW STAE RETRY ROUTINE       52800020
LFSTAE   DS    0F                                                       52900020
         STAE  MF=L                                                     53000020
MOVE2    MVC   N4(N1,R10),N0(R3)   MOVE HEADER TO OUTBUF                53100020
MOVE3    MVC   N4(N1,R10),N0(R6)   MOVE PSW DATA TO OUTBUF              53200020
FOUR     DC    H'4'                AMOUNT TO SUBTRACT FOR MOVE3         53300020
BLANK    EQU   C' '                                                     53400020
         EJECT                                                          53500020
PSWAREA  DSECT                                                          53600020
PARSELST DS    7F                  PARSE PARM LIST                      53700020
ANSWPLAC DS    1F                  VALIDITY CHECK EXIT RC FOR MAINLINE  53800020
PSWBUF   DS    2F                  BUFFER FOR PSW                       53900020
* IT IS ESSENTIAL THAT THE FOLLOWING 4 AREAS BE CONTIGUOUS AND IN ORDER 54000020
STRNGPTR DS    1F                  POINTER TO PSW                       54100020
CVTLL    DS    CL2                 LENGTH OF PSW                        54200020
FLAGS    DS    CL1                 FLAG FOR IKJEGCVT                    54300020
TYPECODE DS    CL1                 TYPE CODE (HEX) FOR IKJEGCVT         54400020
LINELEN  DS    1F                  OUTPUT LINE LENGTH                   54500020
PRINTFLG DS    1F                  ADDRESS OF DSNAME PDE OR ZERO        54600020
* IT IS ESSENTIAL THAT THE FOLLOWING 7 AREAS BE CONTIGUOUS AND IN ORDER 54700020
SYSMASK  DS    2F                  PRINTABLE SYSTEM MASK                54800020
         DS    1F                  WORD                                 54900020
AMWP     DS    1F                  PRINTABLE AMWP                       55000020
ILC      DS    CL2                 PRINTABLE ILC                        55100020
CC       DS    CL2                 PRINTABLE CC                         55200020
PROGMASK DS    1F                  PRINTABLE PROGRAM MASK               55300020
TABLE    DS    2F                  TABLE                                55400020
*IT IS ESSENTIAL THAT THE FOLLOWING 17 AREAS BE CONTIGUOUS AND IN ORDER 55500020
START    DS    CL2                 BLANKS                               55600020
SYSMASK2 DS    CL8                 PRINTABLE SYSTEM MASK                55700020
         DS    CL4                 BLANKS                               55800020
KEY      DS    CL1                 PRINTABLE KEY                        55900020
         DS    CL3                 BLANKS                               56000020
AMWP2    DS    CL4                 PRINTABLE AMWP                       56100020
         DS    CL5                 BLANKS                               56200020
INTRPTCD DS    CL4                 PRINTABLE INTERRUPTION CODE          56300020
         DS    CL7                 BLANKS                               56400020
ILC2     DS    CL2                 PRINTABLE INSTRUCTION LENGTH CODE    56500020
         DS    CL2                 BLANKS                               56600020
CC2      DS    CL2                 PRINTABLE CONDITION CODE             56700020
         DS    CL5                 BLANKS                               56800020
PROGM2   DS    CL4                 PRINTABLE PROGRAM MASK               56900020
         DS    CL6                 BLANKS                               57000020
INSTRADR DS    CL6                 PRINTABLE INSTRUCTION COUNTER        57100020
         DS    CL2                 BLANKS                               57200020
* IT IS ESSENTIAL THAT THE FOLLOWING 2 AREAS BE CONTIGUOUS AND IN ORDER 57300020
OUTPTR1  DS    1F                  POINTER TO FIRST OUTPUT BUFFER       57400020
OUTPTR2  DS    1F                  POINTER TO SECOND OUTPUT BUFFER      57500020
         ORG   PSWAREA             GO BACK TO BEGINNING OF WORK AREA    57600020
STAELIST DS    3F                  PARAMETER LIST FOR STAE              57700020
IKJEGPSW CSECT                                                          57800020
         EJECT                                                          57900020
         TCOMTAB                                                        58000020
         SPACE 2                                                        58100020
         TSTCWORK                                                       58200020
         SPACE 4                                                        58300020
         IKJPPL                                                         58400020
         EJECT                                                          58500020
IKJEGPWM CSECT                                                          58600020
MESGNO2  DC    A(M342L1)           ADDR OF FIRST LEVEL MESG, IKJ57342I  58900020
         DC    A(M342L2A)          ADDRESS OF SECOND LEVEL MESSAGE      59000020
MESGNO3  DC    A(M343L1)           ADDR OF FIRST LEVEL MESG, IKJ57343I  59100020
         DC    F'0'                NO SECOND LEVEL MESSAGE              59200020
*                                                                       59300020
*        MESSAGES                                                       59400020
*                                                                       59500020
M340L1   DS    0F                                                       59600020
         DC    H'30'                                       BUFFER LEN   59700020
         DC    H'0'                                        ZEROES       59800020
         DC    C'IKJ57340I INVALID ADDRESS '               MESG TEXT    59900020
M340L2A  DS    0F                                                       60000020
         DC    H'65'                                       BUFFER LEN   60100020
         DC    H'0'                                        ZEROES       60200020
         DC    C'IKJ57340I REGISTER NOTATION MUST BE '     MESG TEXT    60300020
         DC    C'INDIRECT GENERAL REGISTER'                MESG TEXT    60400020
M340L2B  DS    0F                                                       60500020
         DC    H'46'                                       BUFFER LEN   60600020
         DC    H'0'                                        ZEROES       60700020
         DC    C'IKJ57340I PSW EXTENTS OUTSIDE MAIN'       MESG TEXT    60800020
         DC    C' STORAGE'                                 MESG TEXT    60900020
M342L1   DS    0F                                                       61800020
         DC    H'51'                                       BUFFER LEN   61900020
         DC    H'0'                                        ZEROES       62000020
         DC    C'IKJ57342I LISTPSW FAILED, COMMAND SY'     MESG TEXT    62100020
         DC    C'STEM ERROR+'                              MESG TEXT    62200020
M342L2A  DS    0F                                                       62300020
         DC    H'33'                                       BUFFER LEN   62400020
         DC    H'0'                                        ZEROES       62500020
         DC    C'IKJ57342I PARSE ERROR CODE 12'            MESG TEXT    62600020
M343L1   DS    0F                                                       62700020
         DC    H'56'                                       BUFFER LEN   62800020
         DC    H'0'                                        ZEROES       62900020
         DC    C'IKJ57343I NOT ENOUGH MAIN STORAGE TO'     MESG TEXT    63000020
         DC    C' EXECUTE COMMAND'                         MESG TEXT    63100020
IKJEGPSW CSECT                                                          63200020
         EJECT                                                          63300020
*                                                                       63400020
*        PARSE MACROS                                                   63500020
*                                                                       63600020
IKJEGPWP IKJPARM                                                        63700020
PRINTIT  IKJKEYWD                                                       63800020
         IKJNAME  'PRINT',SUBFLD=PRINTDSN                               63900020
PSWADDR  IKJKEYWD                                                       64000020
         IKJNAME  'ADDR',SUBFLD=ADDRPSW                                 64100020
ADDRPSW  IKJSUBF                                                        64200020
ADDRESS  IKJPOSIT  ADDRESS,VALIDCK=PSWVALCK,PROMPT='ADDRESS OF PSW'     64300020
PRINTDSN IKJSUBF                                                        64400020
DSNAME   IKJPOSIT  DSNAME,PROMPT='DATA SET NAME'                        64500020
         IKJENDP                                                        64600020
         SPACE 2                                                        64700020
PDEUSWD  EQU   ADDRESS+N32         IN ADDRESS PDE, USER WORD            64800020
PDEFLAG3 EQU   ADDRESS+N22         IN ADDR PDE, FLAGS FOR ADDR STRING   64850020
         EJECT                                                          64900020
CVT      DSECT                                                          65000020
         CVT                                                            65100020
         EJECT                                                          65200020
         IKJTCB                                                         65300020
         EJECT                                                          65400020
         IKJRB                                                          65500020
         END                                                            65600020
