 TITLE 'IKJEGQFY'                                                       00070020
*********************************************************************** 00140020
*                                                                     * 00210020
* STATUS                                                              * 00280020
*    CHANGE LEVEL 000                                                 * 00350020
*                                                                     * 00420020
* FUNCTION/OPERATION                                                  * 00490020
*    THIS ROUTINE IS CALLED BY THE SUBCOMMAND PROCESSOR (OS TIME-     * 00560020
*    SHARING OPTION FOR MVT) TO SET AND RESET THE BASE ADDRESS USED TO* 00630020
*    RESOLVE RELATIVE AND SYMBOLIC ADDRESSES.  IT CAN ALSO ASSOCIATE  * 00700020
*    THE LOAD MODULE NAME AND CSECT NAME WITH THEIR CURRENT ADDRESS IN* 00770020
*    THE REGION.                                                      * 00840020
*                                                                     * 00910020
* ENTRY POINTS                                                        * 00980020
*         IKJEGQFY - GOES TO PARSE TO EXAMINE THE SUBCOMMAND          * 01050020
*                                                                     * 01120020
* INPUT                                                               * 01190020
*    ONE LINE OF INPUT FROM THE TERMINAL INTO THE INPUT BUFFER        * 01260020
*                                                                     * 01330020
* OUTPUT                                                              * 01400020
*    1.  ERROR MESSAGES TO THE MESSAGE WRITER                         * 01470020
*    2.  RETURN CODES                                                 * 01540020
*    *       0 - SUCCESSFUL COMPLETION OR MODULE NOT FOUND            * 01610020
*    *       4 - QUALIFICATION TO A NEW TCB                           * 01660020
*    *       8 - RETURN CODE TO HAVE PARSE ISSUE A 'REENTER'          * 01670020
*    *      12 - PARSE VALIDITY CHECK EXIT ERROR RETURN CODE          * 01672020
*    *      16 - AN ATTENTION HAS BEEN SCHEDULED                      * 01680020
*    *      20 - STAE RETRY HAS INTERCEPTED AN ABEND                  * 01730020
*                                                                     * 01750020
* EXTERNAL REFERENCES                                                 * 01820020
*         IKJPARS - TO SCAN THE INPUT BUFFER FOR SYNTAX CHECKING OF   * 01890020
*         ADDRESSES AND KEYWORD IF SPECIFIED AND TO PROMPT THE USER   * 01960020
*         FOR VALID INPUT WHEN NECESSARY.  AT ENTRY TO IKJPARS, REG   * 02030020
*         ONE POINTS TO A PARAMETER LIST WITH THE FOLLOWING FORMAT -  * 02100020
*         00 - POINTER TO UPT                                         * 02170020
*         04 - POINTER TO ECT                                         * 02240020
*         08 - POINTER TO CP ECB                                      * 02310020
*         12 - POINTER TO PARAMETER DESCRIPTOR LIST (PDL)             * 02380020
*         16 - POINTER TO ANSWER PLACE                                * 02450020
*         20 - POINTER TO COMMAND BUFFER                              * 02520020
*         24 - POINTER TO USERWORK AREA (QUALIFY'S SAVE AREA)         * 02590020
*                                                                     * 02640020
*         IKJEGCVT - CONVERTS AN ABSOLUTE ADDRESS, AN EXPRESSION, AN  * 02660020
*         INDIRECT ADDRESS, OR A FULLY QUALIFIED ADDRESS TO BINARY.   * 02730020
*         AT ENTRY REGISTER ONE CONTAINS THE COMPLEMENT OF THE PDL    * 02800020
*         ADDRESS TO INDICATE AN ADDRESS CONVERSION AND REGISTER ZERO * 02870020
*         IS SET NEGATIVE TO INDICATE CONVERT TO BINARY.              * 02940020
*                                                                     * 02990020
*         IKJEGI01 - OUTPUTS ERROR MESSAGES.  AT ENTRY REGISTER ONE   * 03010020
*         CONTAINS THE ADDRESS OF THE LENGTH FIELD OF THE OUTPUT      * 03080020
*         BUFFER.                                                     * 03130020
*                                                                     * 03140020
*         IKJEGSYM - RESOLVES THE ENTRYNAME ADDRESS ASSOCIATED WITH   * 03150020
*         THE GIVEN LOADNAME.                                         * 03200020
*                                                                     * 03220020
* EXITS,NORMAL                                                        * 03290020
*         RETURN VIA REGISTER 14 TO THE CALLER                        * 03360020
*                                                                     * 03430020
* EXITS,ERROR                                                         * 03500020
*         RETURN TO CALLER VIA REGISTER 14                            * 03570020
*                                                                     * 03620020
* TABLES/WORK AREAS                                                   * 03630020
*    TCOMTAB                                                          * 03632020
*    *    PPTCB - UPDATED WHEN QUALIFICATION IS TO A NEW TCB          * 03634020
*    *    PPRB  - QUALIFICATION IS TO A NEW TCB                       * 03636020
*    *    PPLOAD - UPDATED FOR ALL QUALIFICATION                      * 03638020
*    *    TSTSYMBA - UPDATED FOR LOADNAME/LOADNAME.ENTRYNAME          * 03638420
*    *               QUALIFICATION.                                   * 03638820
*    *    TSTCURLD - UPDATED FOR QUALIFICATION TO A NEW LOADNAME      * 03639220
*    *    TSTCURCT - UPDATED FOR QUALIFICATION TO A NEW ENTRYNAME     * 03639620
*                                                                     * 03639720
*    WORKSP - QUALIFY WORKAREA                                        * 03639820
*                                                                     * 03640020
* ATTRIBUTES                                                          * 03710020
*    REENTRANT                                                        * 03780020
*                                                                     * 03790020
* CHARACTER CODE DEPENDENCY                                           * 03830020
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL            * 03840020
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS            * 03842020
*    EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN * 03844020
*    ARRANGED SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY       * 03846020
*    REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW          * 03848020
*    DEFINITIONS.                                                     * 03848420
*                                                                     * 03850020
* NOTES                                                               * 03920020
*                                                                     * 03990020
*********************************************************************** 04060020
         EJECT                                                          04130020
IKJEGQFY CSECT                                                          04200020
ZERO     EQU   0                        PARAMETER REGISTER              04270020
PARAMREG EQU   1                        PARAMETER REGISTER              04340020
WORKE    EQU   2                        EVEN WORK REGISTER              04410020
WORKO    EQU   3                        ODD WORK REGISTER               04480020
REG4     EQU   4                        WORK REGISTERS                  04550020
REG5     EQU   5                        *                               04620020
REG6     EQU   6                        *                               04690020
REG7     EQU   7                        *                               04760020
REG8     EQU   8                        *                               04830020
REG9     EQU   9                        POINTER TO TCOMTAB              04900020
REG10    EQU   10                       POINTER TO WORK AREA            04970020
R11      EQU   11                       WORK REGISTER - POINTER TO PDL  05040020
BASEREG  EQU   12                       BASE FOR CSECT                  05110020
SAVEREG  EQU   13                       SAVE AREA ADDRESS REG           05180020
RETREG   EQU   14                       ADDRESS OF RETURN POINT         05250020
ADDREG   EQU   15                       ADDRESS REGISTER                05320020
RETCODE EQU    15                       RETURN CODE REGISTER            05390020
         SPACE                                                          05460020
* FIELD AND NUMBER EQUATES                                              05530020
ONE      EQU   1                        ONE                             05600020
TWO      EQU   2                        NUMBER 2                        05670020
THREE    EQU   3                        NO. 3                           05740020
PARSCODE EQU   3                        PARSE LINK FAILED CODE          05810020
FOUR     EQU   4                        FOUR                            05880020
TCBADR   EQU   4                        DISPLACEMENT FOR CURRENT        05950020
*                                       TCB ADDR                        06020020
FIVE     EQU   5                        NO. 5                           06090020
SIX      EQU   6                        SIX                             06160020
EIGHT    EQU   8                        EIGHT                           06230020
SYMCODE  EQU   8                        SYM LINK FAILED CODE            06280020
NINE     EQU   9                        NINE                            06300020
TEN      EQU   10                       TEN                             06370020
TWELVE   EQU   12                       NUMBER 12                       06420020
N14      EQU   14                       NUMBER 14                       06440020
SIXTEEN  EQU   16                       SIXTEEN                         06510020
TWENTY   EQU   20                       NO. 20                          06580020
THIRTY2  EQU   32                       OFFSET FOR MESSAGE              06650020
FORTY    EQU   40                       OFFSET                          06720020
FIFTY6   EQU   56                       NUMBER 56                       06790020
FIFTY8   EQU   58                       NUMBER 58                       06860020
SIXTY    EQU   60                       NO. 60                          06930020
OFFSET   EQU   64                       OFFSET INTO COMMON WORK AREA    07000020
SIXTY8    EQU   68                       NUMBER 68                      07070020
HEX03    EQU   X'03'                    INDICATES FULLWORD BOUNDARY     07140020
REGTYPE  EQU   X'38'                    INDICATES REGISTER TYPE ADDR    07210020
TESTSVC  EQU   97                       BREAKPOINT SVC                  07280020
LLCHAIN  EQU   0                        POINTER TO NEXT LLE             07350020
LLCDPTR  EQU   4                        POINTER TO CDE FROM LLE         07420020
CDATTR   EQU   0                        ATTRIBUTES FOUND IN CDE         07490020
ZEROIT   EQU   X'00'                    ZERO                            07560020
ZEROBYTE EQU   X'00'                    BYTE OF ZEROES                  07630020
HEX01    EQU   X'01'                    MASK FOR TESTING P-BIT OF       07700020
*                                       PSW'S AMWP FIELD                07770020
NOPRINT  EQU   X'20'                    NOPRINT SETTING                 07840020
PRINT    EQU   X'DF'                    SETTING TO RESET SWITCH         07910020
ONBIT    EQU   X'80'                    INDICATES HIGH ORDER BIT ON     07980020
MINOR    EQU   X'04'                    MINOR CDE                       08050020
HEXF0    EQU   X'F0'                    MASK FOR PROTECTION KEY OF PSW  08120020
HEXFF    EQU   X'FF'                    STAE ADDR TABLE END INDICATOR   08190020
CDNAME   EQU   8                        MODULE OR ALIAS NAME            08260020
CDXL     EQU   20                       POINTER TO EXTENT LIST          08330020
XLCSECTS EQU   4                        NUMBER OF CSECTS                08400020
BLANK    EQU   C' '                     BLANK                           08470020
PLUS     EQU   C'+'                     PLUS SIGN FOR FIRST LEVEL MSG   08540020
L1       EQU   1                        LENGTH OF 1                     08610020
L3       EQU   3                        LENGTH OF 3                     08680020
L4       EQU   4                        LENGTH OF 4                     08750020
L6       EQU   6                        LENGTH OF 6                     08820020
L7       EQU   7                        LENGTH OF 7                     08890020
L8       EQU   8                        LENGTH OF 8                     08960020
         SPACE                                                          09030020
         SAVE  (14,12),,IKJEGQFY        SAVE REGISTERS                  09100020
         LR    BASEREG,ADDREG           SET UP ADDRESSABILITY           09170020
         USING IKJEGQFY,BASEREG         *                               09240020
         USING TCOMTAB,REG9             SET UP ADDRESSABILITY TO        09310020
*                                          COMMUNICATION WORK AREA      09380020
         L     REG5,REGSAVE2            GET POINTER TO MY SAVE AREA     09450020
         ST    SAVEREG,FOUR(ZERO,REG5)  SAVE ADDR OF CALLER'S SAVE AREA 09520020
         ST    REG5,EIGHT(SAVEREG)      SAVE ADDR OF MY SAVE AREA       09590020
         LR    SAVEREG,REG5             PUT ADDRESS OF MY SAVE AREA     09660020
*                                          IN REGISTER 13               09730020
         L     REG10,WORKAREA           GET ADDRESS OF COMMON WORK AREA 09800020
         USING TSTCWORK,REG10           ESTABLISH ADDRESSABILITY TO     09870020
*                                          WORK AREA                    09940020
         LA    REG10,CWORKCMD           R10=ADDRESS OF QUALIFY'S WORK   10010020
*                                          AREA                         10080020
         DROP  REG10                                                    10150020
         USING WORKSP,REG10             SET UP ADDRESSABILITY TO MY     10220020
*                                          WORK AREA                    10290020
         SAVE  (14,12)                  SAVE REGISTERS IN MY SAVE AREA  10360020
*                                          IN CASE STAE EXIT GETS       10430020
*                                          CONTROL                      10500020
         SPACE                                                          10550020
         MVC   PPTCBSAV(FOUR),PPTCB        SAVE CURRENT PPTCB           10560020
         MVC   PPRBSAV(FOUR),PPRB          SAVE CURRENT RB PTR          10562020
         SPACE                                                          10570020
*                                                                       10640020
*        ISSUE STAE FOR PARSE AND SYM LINK                              10710020
*                                                                       10780020
         LA    REG4,STATBL              GET ADDR OF IC TABLE            10850020
         ST    REG4,ABENTAB1            SAVE IN ABENTAB1 ENTRY          10920020
*                                  FOR STAE                             10990020
         SPACE                                                          11060020
         MVC   TSTRETRY+ONE(THREE),RETRYADR   SET UP ADDR OF RETRY      11130020
         L     REG4,TSTSTAE             GET ADDR OF STAE EXIT           11200020
*                                       ROUTINE                         11270020
         LA    ADDREG,BLDMSG            GET WKAREA ADDR                 11340020
         MVC   ZERO(STAELEN,ADDREG),STAELIST  MOVE STAE LIST            11410020
         SPACE                                                          11480020
         STAE  (4),MF=(E,(15))          ISSUE STAE MACRO                11550020
         SPACE                                                          11620020
         LTR   RETCODE,RETCODE          CHECK FOR A VALID RETURN        11690020
*                                       CODE                            11760020
SMTSTAE  DS    0H                       SMT TEST LABEL FOR STAE MACRO   11810020
         BZ    SETUP                    YES...                          11830020
         SPACE                                                          11900020
         L     PARAMREG,MSG05           GET ADDR OF 'INSUFFICIENT       11970020
*                                       CORE' MSG                       12110020
         B     PUTMSG                   PUT OUT MSG                     12390020
         SPACE                                                          12460020
* THIS SECTION PREPARES FOR PASSING CONTROL TO THE PARSE ROUTINE        12530020
         SPACE                                                          12600020
SETUP    EQU   *                        SET UP FOR PARSE                12670020
         DROP  REG10                                                    12740020
         SPACE                                                          12810020
         USING PPLUPT,REG10             SET UP ADDRESSABILITY TO        12880020
*                                       PARSE PARAMETER LIST            12950020
         SPACE                                                          13020020
         MVC   PPLUPT(FOUR),TSTUPT      MOVE USER PROFILE TABLE INTO    13090020
*                                       WORKAREA                        13160020
         MVC   PPLECT(FOUR),TSTECT      MOVE ENVIRONMENT CONTROL TABLE  13230020
         MVC   PPLECB(FOUR),TSTCPECB    MOVE COMMAND PROCESSOR EVENT    13300020
*                                       CONTROL BLOCK                   13370020
         MVC   PPLPCL(FOUR),PCLISTA     MOVE ADDR OF PARAMETER CONTROL  13420020
*                                       LIST                            13440020
         LA    REG4,TSTANSPL            GET PTR TO ANSWER PLACE         13510020
         ST    REG4,PPLANS              STORE IN WORKAREA               13560020
         MVC   PPLCBUF(FOUR),INBUF      MOVE PTR TO COMMAND BUFFER      13580020
         ST    SAVEREG,PPLUWA           SAVE PTR TO QUALIFY'S WORKAREA  13650020
         DROP  REG10                                                    13790020
         USING WORKSP,REG10             SET UP ADDRESSABILITY TO        13860020
*                                       WORKAREA                        13930020
         LR    PARAMREG,REG10           PUT ADDRESS OF PARAMETER LIST   14000020
*                                          INTO REGISTER 1              14070020
         LINK  EP=IKJPARS               GO TO PARSE ROUTINE             14140020
         SPACE                                                          14190020
SMTPARS  DS    0H                       SMT TEST LABEL FOR PARSE LINK   14200020
         SPACE                                                          14210020
PARSBLOW EQU   *                                                        14280020
         LTR   RETCODE,RETCODE          DID PARSE COMPLETE SUCCESSFULLY 14350020
         BNZ   CHKCODE                  NO, FIND TYPE OF ERROR          14420020
         L     R11,TSTANSPL             GET ADDRESS OF PDL              14490020
         USING IKJPARMD,R11             GET ADDRESSABILITY TO PDL       14560020
         LA    R11,ADDR                 R11=ADDRESS OF ADDRESS PDE      14630020
         DROP  R11                                                      14700020
         USING IKJPARMA,R11             GET ADDRESSABILITY TO PDE       14770020
         SPACE                                                          14840020
CHECKADR EQU   *                        CHECK FOR ARGUMENT BEING LOAD-  14910020
*                                          NAME OR ADDRESS              14980020
         CLC   PDEUSER(L4),NOBINARY     IS ARGUMENT BINARY ADDRESS      15050020
         BE    CHKSYM                   NO, CHECK FOR SYMBOL.SYMBOL     15120020
         L     WORKE,PDEUSER            PICK UP CONVERTED ADDRESS       15190020
         LA    WORKE,ZERO(ZERO,WORKE)   CLEAR HIGH ORDER BYTE OF REG    15260020
         ST    WORKE,PPLOAD             STORE ADDRESS IN FIELD OF       15330020
*                                          TCOMTAB FOR CURRENTLY        15400020
*                                          QUALIFIED BASE FOR RELATIVES 15470020
         SPACE                                                          15680020
         DROP  R11                      DROP ADDRESS PDE BASE           15750020
         L     R11,TSTANSPL             R11 = ADDRESS OF PDL            15820020
         USING IKJPARMD,R11             GET ADDRESSABILITY TO PDL       15890020
         SR    REG4,REG4                CLEAR REG                       15960020
         CH    REG4,TCBNAME             WAS TCB SPECIFIED W/O LOADNM    16030020
         SPACE                                                          16150020
         LA    R11,ADDR                 SET R11 TO ADDR OF PDE          16160020
         DROP  R11                      DROP PDL ADDRESSABILITY         16162020
         USING IKJPARMA,R11             SET UP ADDRESSABILITY TO PDE    16164020
         SPACE                                                          16170020
         BE    SYMCHK                   TCB NOT SPECIFIED...            16180020
         SPACE                                                          16190020
         TM    PDEFLG1,ONBIT            WAS ADDR FULLY QUALIFIED        16220020
         BZ    TCBINVAL                 NO, PUT OUT 'TCB INVALID' MSG   16230020
         SPACE                                                          16232020
         L     PARAMREG,MSG13           YES, PUT OUT 'TCB IGNORED' MSG  16234020
         B     PUTMSG                   PRINT INFORMATION MSG           16236020
         SPACE                                                          16238020
TCBINVAL L     PARAMREG,MSG10           IF SO, GET ADDR OF 'TCB         16240020
*                                       INVALID' MSG                    16310020
         B     PUTMSG                   PRINT ERROR MESSAGE             16380020
         SPACE                                                          16450020
SYMCHK   TM    PDEFLG3,ONBIT            TEST FOR .CSECT.SYMBOL          16730020
         BO    QFYCCO                   YES...RETURN                    16800020
         SPACE                                                          16870020
         TM    PDEFLG4,RELADDR          TEST FOR RELATIVE ADDR          16940020
         BO    QFYCCO                   YES...                          17010020
         SPACE                                                          17080020
         ST    WORKE,TSTSYMBA           QUALIFICATION MUST BE           17150020
*                                       .ENTRYNAME...SAVE NEW BASE      17220020
*                                       FOR SYMBOLICS                   17290020
         MVI   TSTCURCT,BLANK           BLANK OUT CSECTNAME IN          17360020
         MVC   CSECTNM1(L7),TSTCURCT    TCOMTAB                         17430020
         LA    REG4,TSTCURCT            GET FIELD ADDR                  17500020
         LH    REG5,PDELEN2             AND LENGTH OF CSECT NAME        17570020
         BCTR  REG5,ZERO                DECREMENT BY 1 FOR MOVE         17640020
         L     WORKO,PDECTNAM           GET PTR TO NAME                 17710020
         EX    REG5,EXMOVE              MOVE CSECT NAME TO TCOMTAB      17780020
         B     QFYCCO                   GO TO WRAP UP ROUTINE           17850020
         SPACE                                                          17920020
CHKCODE  EQU   *                        EXAMINE RETURN CODE FROM PARSE  17990020
         STC   RETCODE,CODESAVE         SAVE RETURN CODE                18060020
         LA    REG5,RTNCODE             GO TO PROPER BRANCH             18130020
RTNCODE  B     ZERO(RETCODE,REG5)       IN BRANCH TABLE                 18200020
         SPACE                                                          18270020
         B     RC04                     RC=4  UNABLE TO PROMPT          18340020
         B     CODE16                   RC=8  ATTN SCHEDULED            18410020
         B     NOPARSE                  RC=12 UNABLE TO PARSE           18480020
         B     NOCORE                   RC=16 NO CORE AVAILABLE         18550020
NOCONVRT EQU   *                        RC=20 CONVERT FAILED            18600020
         SPACE                                                          18610020
         CLI   CONVRTCD,SIXTEEN         GET RETURN CODE SAVED           18612020
*                                       FROM BAD CONVERT                18614020
         BL    QFYCCO                   IF 0,4,8, OR 12, SET RETURN     18616020
*                                       CODE TO 0 FOR MAINLINE          18618020
         BE    CODE16                   IF 16, SET RETURN CODE TO       18618420
*                                       16 FOR ATTENTION SCHEDULED      18618820
         SPACE                                                          18619220
RC20     LA    RETCODE,TWENTY           ELSE, SET RETURN CODE TO 20     18619620
*                                       FOR MAINLINE                    18619720
         B     QFYRET                   GO TO WRAP-UP PROCEDURE         18619820
         SPACE                                                          18619920
RC04     OI    TSTFLGS4,TSTFLUSH        INITILIAZE STACK FLUSH          18636620
*                                       FOR MAINLINE                    18646620
         B     QFYCCO                   RETURN TO MAINLINE              18648620
         SPACE                                                          18653320
NOCORE   EQU   *                        STORAGE NOT AVAILABLE           18670020
         L     PARAMREG,MSG05           GET ADDR OF 'NO CORE' MSG       18690020
         B     PUTMSG                   BRANCH TO RTN WHICH GOES TO     18760020
*                                          MSGWRITER                    18830020
         SPACE                                                          19180020
CODE16   EQU   *                        SET RETURN CODE TO 16 FOR       19250020
*                                          ATTENTION SCHEDULED          19320020
         XR    RETCODE,RETCODE          CLEAR REGISTER                  19390020
         LA    RETCODE,SIXTEEN(ZERO,RETCODE) SET RETURN CODE TO 16      19460020
*                                          FOR ATTENTION SCHEDULED      19530020
         B     QFYRET                   GO TO WRAP UP PROCEDURE         19600020
         SPACE                                                          19670020
NOPARSE  EQU   *                        UNABLE TO PARSE                 19740020
         L     PARAMREG,MSG04           GET ADDR OF MSG                 19810020
         SPACE                                                          19880020
PUTMSG   EQU   *                        PUT MESSAGE OUT TO TERMINAL     19950020
         SPACE                                                          20010020
         LCR   PARAMREG,PARAMREG        MAKE NEGATIVE TO INDICATE       20020020
*                                       ERROR MSG TO TERMINAL           20090020
         L     ADDREG,TPUTADDR          GET ADDR OF MESSAGE WRITER -    20160020
*                                       IKJEGIO                         20230020
         BALR  RETREG,ADDREG            GO TO IKJEGIO                   20300020
         SPACE                                                          20350020
         STC   RETCODE,CODESAVE         SAVE CODE TO TEST               20370020
         CLI   CODESAVE,SIXTEEN         WAS I/O RETURN CODE 0,4,8,      20440020
*                                       OR 12                           20510020
         BL    QFYCCO                   YES...RETURN TO MAINLINE WITH   20580020
*                                       A RETURN CODE OF 0.             20650020
         SPACE                                                          20720020
         BE    CODE16                   IF 16, SET RETURN CODE FOR      20790020
*                                       ATTENTION SCHEDULED, AND        20860020
*                                       RETURN TO MAINLINE.             20930020
         B     RC20                     ELSE, SET RETURN CODE TO        21000020
*                                       20 FOR MAINLINE.                21050020
         SPACE                                                          21070020
CHKSYM   EQU   *                        CHECK FOR SYMBOL.SYMBOL         21140020
         TM    PDEFLG2,ONBIT            IS THERE AN ENTRYNAME           21210020
*                                          PARAMETER IN THE PDE         21280020
         BO    MOVENM                   YES, ARGUMENT IS                21350020
*                                          LOADNAME.CSECTNAME           21420020
ONLYSYM  EQU   *                        FOUND PDE TO CONTAIN ONLY A     21490020
*                                          SYMBOL                       21560020
         LM    WORKE,WORKO,PDEADRPT     PICK UP PTR TO SYMBOL AND FLAGS 21630020
         STM   WORKE,WORKO,PDELDNAM     STORE IN LOADNAME ENTRIES OF    21700020
*                                          PDE                          21770020
         MVI   PDEADRPT,ZEROIT          CLEAR OUT STRING FIELD          21840020
         MVC   STRING1(L7),PDEADRPT     COMPLETE CLEARING FIELD         21910020
         SPACE                                                          21980020
MOVENM   EQU   *                        MOVE LOADNAME TO TEST FIELD     22050020
         MVI   NEWLOAD,BLANK            BLANK OUT NEWLOAD FIELD IN      22120020
         MVC   NEWLOAD1(L7),NEWLOAD        THE WORK AREA                22190020
         LH    WORKE,PDELEN1            PICK UP LENGTH OF LOADNAME      22260020
         L     WORKO,PDELDNAM           GET POINTER TO NAME             22330020
         LA    REG4,NEWLOAD             GET ADDR OF WORK AREA FIELD     22400020
         BCTR  WORKE,ZERO               DECREMENT LENGTH BY ONE         22470020
         EX    WORKE,EXMOVE             MOVE NEW NAME TO WORK AREA      22540020
         DROP  R11                                                      22610020
         L     R11,TSTANSPL             R11=ADDRESS OF PDL              22680020
         USING IKJPARMD,R11             GET ADDRESSABILITY TO PDL       22750020
         SPACE                                                          22820020
ISTCB    EQU   *                        CHECK FOR TCB SPECIFIED         22890020
         XR    REG4,REG4                CLEAR REGISTER                  22960020
         CH    REG4,TCBNAME             WAS TCB PARAMETER GIVEN         23030020
         BNE   YESTCB                   YES, SET UP SEARCH FOR NAME     23100020
         LA    R11,ADDR                 R11=ADDRESS OF ADDRESS PDE      23170020
         DROP  R11                                                      23240020
         USING IKJPARMA,R11             GET ADDRESSABILITY TO PDE       23310020
         MVI   TCBFLG,TCBNOSP           INDICATE TCB NOT SPECIFIED      23380020
         EJECT                                                          23450020
*****************************************************************       23520020
*                                                               *       23590020
*        THIS ROUTINE INITIALIZES A SEARCH FOR THE LOADNAME     *       23660020
*        THROUGH EACH TASK UNDER THE TEST TCB.                  *       23730020
*                                                               *       23800020
*****************************************************************       23870020
         SPACE                                                          23940020
         L     WORKO,TSTTCB             GET THE ADDR OF TEST'S TCB      24010020
*                                       FROM TCOMTAB                    24080020
         USING TCB,WORKO                SET UP ADDRESSABILITY TO TCB    24150020
         SPACE                                                          24220020
DAUGHTER L     WORKE,D(WORKO)           GET ADDR OF DAUGHTER TCB        24290020
         LTR   WORKE,WORKE              IS THERE A DAUGHTER             24360020
         BNZ   SETSRCH                  YES...GO SEARCH FOR LOADNAME    24430020
         SPACE                                                          24500020
SISTER   L     WORKE,S(WORKO)           GET ADDR OF SISTER TCB          24570020
         LTR   WORKE,WORKE              IS THERE A SISTER               24640020
         BNZ   SETSRCH                  YES...SEARCH FOR LOADNAME       24710020
         SPACE                                                          24780020
MOTHER   CLC   M+ONE(THREE,WORKO),TSTTCB+ONE  DOES MOTHER = TEST TCB    24850020
         BE    NOFIND                   YES...PUT OUT ' NO FIND' MSG    24920020
         SPACE                                                          24990020
         L     WORKO,M(WORKO)           NO...GET ADDR OF MOTHER TCB     25060020
         B     SISTER                   SEARCH 'SISTER' CHAIN           25130020
         SPACE                                                          25200020
SETSRCH  ST    WORKE,TCBUSED            SAVE TCB ADDRESS                25270020
         DROP  WORKO                    DROP ADDRESSABILITY TO          25320020
*                                       TEST'S TCB                      25330020
         USING TCB,WORKE                ADDRESSABILITY FOR TCB BEING    25332020
*                                       USED                            25334020
         CLC   TCBUSED+ONE(THREE),ONE(WORKE)   IS THERE AN RB           25340020
         BE    NORB                     NO....(TCBRBP FIELD POINTS      25410020
*                                       TO THE TCB ITSELF RATHER THAN   25480020
*                                       TO AN RB)                       25550020
         SPACE                                                          25600020
         TM    TCBFLGS5,TCBFC           IS THIS TASK TERMINATED         25610020
         BNO   SEARCHRB                 NO...SEARCH THE RB CHAIN        25612020
*                                       FOR THIS TCB                    25614020
         SPACE                                                          25620020
NORB     LR    WORKO,WORKE              INITIALIZE TO SEARCH FOR        25690020
         B     DAUGHTER                 THE NEXT LOWER TCB              25760020
         EJECT                                                          26110020
*********************************************************************   26180020
*                                                                   *   26250020
* THE SEARCH IS NOW BEGUN THROUGH RB'S AND LLE'S TO GET TO CDE'S AND*   26320020
* LOOK FOR MATCHING LOADNAME                                        *   26390020
*                                                                   *   26460020
*********************************************************************   26530020
         SPACE                                                          26600020
SEARCHRB EQU   *                        BEGIN SEARCH OF RB CHAIN        26670020
         L     WORKO,TCBRBP             GET PTR TO RB QUE               26810020
         USING RBSECT,WORKO             SET UP ADDRESSABILITY           26880020
         SPACE                                                          26950020
ISRBOK   EQU   *                        CHECK FOR TYPE OF RB            27020020
         TM    RBSTAB1,RBFTP            IS RB A PRB                     27090020
         BNZ   NEXTRB                   NO, CHECK FOR NEXT RB           27160020
         SPACE                                                          27230020
GETCODE  L     REG4,RBCDE               GET PTR TO CDE                  27300020
         BAL   REG8,GETXL               BRANCH TO EXAMINE CDE           27370020
         SPACE                                                          27440020
NEXTRB   EQU   *                        SET UP FOR SEARCHING NEXT RB    27510020
         L     WORKO,RBLINK             GET PTR TO NEXT RB              27580020
         LA    WORKO,ZERO(ZERO,WORKO)   CLEAR HIGH ORDER BYTE           27650020
         CLR   WORKO,WORKE              IS POINTER TO TCB               27720020
         BE    CHKLLE                   YES, BEGIN SEARCH THRU LOAD     27790020
*                                          LIST                         27860020
         BNE   ISRBOK                   NO, CHECK FOR TYPE OF RB        27930020
         SPACE                                                          28000020
         DROP  WORKO                                                    28070020
         SPACE                                                          28140020
GETXL    EQU   *                        LOOK FOR LOAD NAME              28210020
         L     REG5,CDXL(ZERO,REG4)     PICK UP XL POINTER              28280020
TESTNM   EQU   *                        CHECK FOR NAME                  28350020
         CLC   CDNAME(L8,REG4),NEWLOAD  DO LOADNAMES MATCH              28420020
         BE    CHKATTR                  YES, CHECK ATTRIBUTES           28490020
         TM    CDATTR(REG4),MINOR       IS THIS A MINOR CDE             28560020
         BO    MINORCDE                 YES, MINOR CDE                  28630020
         BR    REG8                     NO, RETURN TO CALLER            28700020
         SPACE                                                          28770020
MINORCDE EQU   *                                                        28840020
         LR    REG4,REG5                THIS IS A MINOR CDE             28910020
         B     GETXL                    CHECK LOADNAME IN MAJOR CDE     28980020
         SPACE                                                          29050020
CHKATTR  EQU   *                        LOADNAMES MATCHED - FIND XL     29120020
         TM    CDATTR(REG4),MINOR       IS THIS A MINOR CDE             29260020
         BZ    GOTOXL                   NO GO TO XL                     29330020
         L     REG5,CDXL(ZERO,REG5)     THIS IS A MINOR CDE, GET PTR    29400020
*                                          TO XL                        29470020
         SPACE                                                          29540020
GOTOXL   EQU   *                        GET FIRST CSECT ADDRESS FROM XL 29610020
         LA    REG6,FOUR                PUT A FOUR IN REG               29680020
         L     REG7,XLCSECTS(ZERO,REG5) PICK UP NUMBER CSECTS           29750020
         LA    REG7,TWO(ZERO,REG7)      ACCOUNT FOR PRECEEDING 8 BYTES  29820020
         MR    REG6,REG6                GET DISPLACEMENT INTO XL        29890020
*                                          FOR ADDRESS OF FIRST CSECT   29960020
         L     REG7,ZERO(REG7,REG5)     PICK UP ADDRESS OF FIRST CSECT  30030020
         ST    REG7,CSECTADR            SAVE ADDRESS OF CSECT           30100020
         B     CHKCSECT                 CHECK FOR CSECT GIVEN           30170020
         SPACE                                                          30240020
CHKLLE   EQU   *                        RB CHAIN EXHAUSTED WITHOUT A    30310020
*                                          MATCH - BEGIN SEARCH THRU    30380020
*                                          LLE'S                        30450020
         L     REG4,TCBLLS              GET PTR TO LOAD LIST            30520020
TESTREG  LTR   REG4,REG4                HAS A MODULE BEEN LOADED        30590020
         BZ    NOMATCH                  NO, UNSUCCESSFUL SEARCH         30660020
         LR    REG6,REG4                SAVE LOAD LIST ADDR             30730020
         L     REG4,LLCDPTR(ZERO,REG4)  GET POINTER TO CDE              30800020
         BAL   REG8,GETXL               BRANCH TO EXAMINE CDE           30870020
NEXTLLE  EQU   *                        GET POINTER TO NEXT LLE         30940020
         LR    REG4,REG6                RESTORE LOAD LIST ADDR          31010020
         L     REG4,LLCHAIN(ZERO,REG4)  PICK UP POINTER                 31080020
         B     TESTREG                  CHECK FOR MODULE BEING LOADED   31150020
         SPACE                                                          31220020
* THIS CODE IS ENTERED WHEN IT IS INITIALLY DETERMINED THAT A TCB       31290020
* ADDRESS WAS SPECIFIED.                                                31360020
         SPACE                                                          31430020
YESTCB   EQU   *                        BEGIN PREPARATION TO SEARCH     31500020
*                                          FROM SPECIFIED TCB THROUGH   31570020
*                                          RB'S AND LLE'S TO CDE'S TO   31640020
*                                          FIND MATCHING LOADNAME       31710020
         MVI   TCBFLG,TCBGIVEN          SET SWITCH TO INDICATE TCB      31780020
*                                          SPECIFIED                    31850020
         DROP  R11                                                      31920020
         L     R11,TSTANSPL             R11=ADDRESS OF PDL              31990020
         USING IKJPARMD,R11             GET ADDRESSABILITY TO PDL       32060020
         LA    R11,ADDRTCB              R11=ADDRESS OF TCB PDE          32130020
         DROP  R11                                                      32200020
         USING IKJPARMA,R11             GET ADDRESSABILITY TO PDE       32270020
         L     WORKE,PDEUSER            GET BINARY ADDRESS OF TCB       32340020
         ST    WORKE,TCBUSED            SAVE TCB ADDRESS                32410020
         DROP  R11                                                      32480020
         L     R11,TSTANSPL             R11=ADDRESS OF PDL              32550020
         USING IKJPARMD,R11             GET ADDRESSABILITY TO PDL       32620020
         LA    R11,ADDR                 R11=ADDRESS OF ADDRESS PDE      32690020
         DROP  R11                                                      32760020
         USING IKJPARMA,R11             GET ADDRESSABILITY TO PDE       32830020
         B     SEARCHRB                 BEGIN SEARCH OF RB CHAIN        32900020
         SPACE                                                          32970020
* THIS CODE IS ENTERED WHEN A SEARCH THROUGH RB QUEUES AND LLE'S HAS    33040020
* FOUND NO MATCH IN LOADNAME FOR THE TCB SEARCHED                       33110020
NOMATCH  EQU   *                        HERE IT IS DETERMINED WHETHER   33180020
*                                          MORE TCB'S CAN BE CHECKED    33250020
*                                          FOR OR NOT                   33320020
         TM    TCBFLG,TCBGIVEN          WAS A TCB SPECIFIED BY THE      33390020
*                                          USER                         33460020
         BO    ERRCOND                  YES, PUT OUT ERROR MESSAGE      33530020
         LR    WORKO,WORKE              GET ADDR OF NEXT LOWER TCB      33600020
         B     DAUGHTER                 GO THROUGH LOOP AGAIN           33670020
         SPACE                                                          33740020
ERRCOND  EQU   *                        SET UP MESSAGE FOR MODULE NOT   33810020
*                                          FOUND                        33880020
         L     WORKE,MSG01              GET PTR TO MSG ADDR             33950020
         BAL   REG8,FIXMSG              GET FIRST LEVEL MESSAGE MOVED   34020020
*                                          TO BUFFER - POINTER TO       34090020
*                                          SECOND LEVEL MSG WILL NOT    34160020
*                                          BE CORRECT                   34230020
         LR    REG4,PARAMREG            BEGINNING OF BUFFER             34300020
         LA    REG4,FORTY(ZERO,REG4)    GET DISPLACEMENT TO INSERT      34370020
*                                       LOADNAME                        34440020
         SPACE                                                          34490020
         L     WORKO,PDELDNAM           GET POINTER TO LOADNAME         34500020
         LA    REG5,ONE(ZERO,REG6)      SAVE FIRST LEVEL MESG LENGTH    34510020
*                                       (PLUS ONE FOR MOVE INSTRUCTION) 34560020
         SPACE                                                          34570020
         LH    REG6,PDELEN1             GET LENGTH OF LOADNAME          34580020
         BCTR  REG6,ZERO                DECREMENT BY ONE FOR MOVE INSTR 34650020
         EX    REG6,EXMOVE              MOVE LOADNAME TO FIRST LEVEL    34720020
*                                       MESSAGE                         34790020
         SPACE                                                          34840020
         LA    REG5,TWO(REG6,REG5)      GET TOTAL LENGTH OF FIRST LEVEL 34860020
*                                       MESSAGE                         34930020
         STC   REG5,NINE(PARAMREG)      SAVE IN LENGTH FIELD OF MSG     35000020
         SPACE                                                          35050020
         LA    REG4,ONE(REG6,REG4)      GET DISPLACEMENT FOR INSERTING  35070020
*                                       PLUS SIGN                       35140020
         MVI   ZERO(REG4),PLUS          MOVE IN PLUS SIGN               35210020
         LA    REG4,TWO(REG4)           GET DISPLACEMENT FOR SECOND     35280020
*                                       LEVEL MESSAGE (ONE FOR PLUS     35330020
*                                       SIGN AND ONE FOR ROUNDING UP)   35340020
         N     REG4,MASKUP              ROUND UP TO HALF-WORD BOUNDARY  35342020
         ST    REG4,FOUR(ZERO,PARAMREG) STORE IN SECOND WORD OF BFFR    35350020
         SPACE                                                          35400020
         IC    REG5,ONE(ZERO,REG7)      GET LENGTH OF SECOND LEVEL MSG  35420020
         BCTR  REG5,ZERO                DECREMENT BY ONE FOR MOVE       35470020
         LR    WORKO,REG7               PUT MSG ADDR INTO REG 3         35490020
         EX    REG5,EXMOVE              MOVE IN SECOND LEVEL MSG        35560020
         SPACE                                                          35610020
         LA    REG4,N14(ZERO,REG4)      ADJUST DISPLACEMENT TO INSERT   35620020
*                                       LOADNAME                        35622020
         L     WORKO,PDELDNAM           GET PTR TO LOADNAME             35624020
         EX    REG6,EXMOVE              MOVE LOADNAME TO SECOND LEVEL   35626020
*                                       MESSAGE                         35628020
         B     PUTMSG                   PUT OUT MESSAGE                 35630020
         SPACE                                                          35980020
NOFIND   EQU   *                        SINCE LOADNAME COULD NOT BE     36050020
*                                          FOUND TESTS ARE MADE TO SEE  36120020
*                                          IF USER SPECIFIED LOADNAME.  36190020
*                                          ENTRYNAME OR JUST SYMBOL     36260020
         TM    PDEFLG2,ONBIT            WAS SYMBOL.SYMBOL INDICATED     36330020
         BZ    FIXPDE                   NO, CLEAN UP PDE                36400020
         SPACE                                                          36470020
LDCST    EQU   *                        SET UP MESSAGE FOR UNABLE TO    36540020
*                                          QUALIFY ARGUMENT AS          36610020
*                                          LOADNAME.CSECTNAME           36680020
         L     WORKE,MSG02              GET PTR TO MSG ADDR             36750020
         BAL   REG8,FIXMSG              GET FIRST LEVEL MESSAGE MOVED   36820020
*                                          TO BUFFER AND POINTERS       36890020
*                                          INITIALIZED                  36960020
         SPACE                                                          37030020
         LR    REG4,PARAMREG            SAVE BEGIN ADDR OF BUFFER       37080020
         LA    PARAMREG,FORTY(ZERO,REG4)  GET DISPL TO INSERT           37090020
*                                         LOADNAME.CSECTNAME            37092020
         SPACE                                                          37094020
         LR    ZERO,R11                 PUT PDE ADDR INTO REG 0         37096020
         L     ADDREG,TSTADDR           GET ADDR OF BUILD RTN           37098020
         BALR  RETREG,ADDREG            GO BUILD INSERT                 37098420
         SPACE                                                          37098520
         LR    REG5,ZERO                GET NO. BYTES INSERTED          37098620
         MVI   ZERO(PARAMREG),PLUS      PUT PLUS SIGN INTO MSG          37120520
         LA    REG6,TWO(REG5,REG6)      ADD INSERT LENGTH (+1 FOR PLUS  37122520
*                                       SIGN) TO ORIGINAL LENGTH        37122620
         STC   REG6,NINE(ZERO,REG4)     SAVE IN MESSAGE                 37128620
         SPACE                                                          37131620
         LR    PARAMREG,REG4            RESTORE BEGIN ADDR OF BUFFER    37134620
         B     PUTMSG                   PUT OUT MSG AND RETURN          37146420
         SPACE                                                          37158220
CONVERT  EQU   *                        THIS ROUTINE GIVES CONTROL TO   37170020
*                                       CONVERT TO GET A BINARY ADDR    37240020
         LCR   PARAMREG,R11             PUT COMPLEMENT OF POINTER TO    37310020
*                                          PDE INTO REG 1 TO INDICATE   37380020
*                                          AN ADDRESS CONVERT NEEDED    37450020
         XR    ZERO,ZERO                INDICATE THAT A BINARY CONVERT  37520020
*                                          IS NEEDED                    37590020
         OI    TSTFLGS3,NOPRINT         SET SWITCH FOR IKJEGSYM NOT TO  37660020
*                                          PRINT A MESSAGE IF AN ERROR  37730020
*                                          OCCURS                       37800020
         L     ADDREG,TSTCONVT          GET ADDRESS OF CONVERT ROUTINE  37870020
         BALR  RETREG,ADDREG            GO TO CONVERT ROUTINE           37940020
         NI    TSTFLGS3,PRINT           RESET SWITCH                    38010020
         LTR   RETCODE,RETCODE          WAS CONVERT SUCCESSFUL          38080020
         BNZ   CHKATTN                  NO, CHECK FOR ATTENTION         38150020
*                                          SCHEDULED                    38220020
         TM    PDEUSER,ONBIT            IS ADDRESS IN USERWORD          38290020
         BZ    SETPPLD                  YES...GO SET PPLOAD             38360020
         SPACE                                                          38430020
         L     WORKE,PDEUSER            NO...MUST PICK UP PTR           38480020
*                                       TO SI BLOCK                     38490020
         MVC   PDEUSER(L4),ZERO(WORKE)  MOVE ADDR INTO USER WORD        38492020
         SPACE                                                          38494020
SETPPLD  EQU   *                        PUT CONVERTED ADDRESS INTO      38500020
*                                          TCOMTAB                      38570020
         MVC   PPLOAD(L4),PDEUSER       SET NEW BASE FOR RELATIVES      38640020
         B     QFYRET                   RETURN                          38710020
         SPACE                                                          38780020
CHKATTN  EQU   *                        CHECK FOR ATTENTION SCHEDULED   38850020
         STC   RETCODE,CODESAVE         STORE CODE                      38920020
         CLI   CODESAVE,SIXTEEN         WAS ATTENTION SCHEDULED         38990020
         BE    QFYRET                   YES, RETURN                     39060020
         SPACE                                                          39110020
         L     WORKE,MSG03              GET PTR TO MSG ADDR             39130020
         BAL   REG8,FIXMSG              SET UP FIRST LEVEL MSG          39200020
*                                          BUFFER                       39270020
         L     WORKO,PDEADRPT           GET ADDRESS OF STRING           39340020
         LH    REG7,PDELEN3                GET LENGTH OF NAME           39410020
         BCTR  REG7,ZERO                DECREMENT ONE FOR EX INSTR      39480020
         LA    REG4,THIRTY2(ZERO,REG4)    ADJUST POINTER FOR MOVE       39550020
         EX    REG7,EXMOVE              MOVE LOADNAME OR SYMBOL INTO    39620020
*                                       MESSAGE                         39690020
         LA    REG4,ONE(REG4,REG7)      GET DISPLACEMENT TO INSERT      39740020
*                                       PLUS SIGN                       39750020
         MVI   ZERO(REG4),PLUS          MOVE IN PLUS SIGN               39752020
         SPACE                                                          39754020
         LA    REG6,THREE(REG6,REG7)    GET TOTAL LENGTH OF 1ST LEVEL   39756020
*                                       MSG (ORIGINAL LENGTH +1 FOR     39758020
*                                       MSG MOVE +1 FOR SYMBOL MOVE,    39758420
*                                       AND +1 FOR PLUS SIGN).          39758820
         STC   REG6,NINE(PARAMREG)      SAVE IN LENGTH FIELD OF MSG     39758920
         SPACE                                                          39759220
         B     PUTMSG                   PUT OUT MESSAGE FOR UNABLE      39760020
*                                          TO QUALIFY AS LOADNAME       39830020
*                                          NOR SYMBOL                   39900020
         SPACE                                                          39970020
FIXPDE   EQU   *                        ADJUSTMENTS MUST BE MADE FOR    40040020
*                                          PDE                          40110020
         MVC   PDEADRPT(L8),PDELDNAM    MOVE SYMBOL INFORMATION BACK    40180020
*                                          TO SYMBOL SLOT IN PDE        40250020
         MVI   PDELDNAM,ZERO            CLEAR OUT LOADNAME SLOT         40320020
         MVC   LDNM1(L7),PDELDNAM                                       40390020
         B     CONVERT                  GO TO CONVERT TO RESOLVE        40460020
*                                          ADDRESS                      40530020
         SPACE                                                          40600020
CHKCSECT EQU   *                        THIS CODE IS ENTERED IF A MATCH 40670020
*                                          WERE FOUND TO LOADNAME       40740020
         C     WORKE,PPTCB              WAS LOADNAME FOUND ON A NEW     40810020
*                                          TCB                          40880020
         BNE   NEWTCB                   YES, NEW TCB GIVEN              40950020
         MVI   TCBUSED,NOTNEW           SET HIGH ORDER BYTE EQUAL TO    41020020
*                                          X'80' TO INDICATE LOADNAME   41090020
*                                          FOUND ON OLD TCB             41160020
TSTENTRY TM    PDEFLG2,ONBIT            WAS ENTRYNAME SPECIFIED         41230020
         BNO   NOENTRY                  NO, SET UP TCOMTAB INFO         41300020
         SPACE                                                          41370020
* SET UP TO GO TO IKJEGSYM                                              41440020
         LR    PARAMREG,R11             PUT POINTER TO PDE IN REG1      41510020
         MVI   PDEADRPT,ZEROBYTE        CLEAR STRING ADDRESS AREA       41580020
         MVC   STRING1(L6),PDEADRPT        IN PDE                       41650020
         LA    ADDREG,BLDMSG            GET WKAREA ADDR                 41790020
         MVC   ZERO(SYMLEN,ADDREG),SYMLIST  MOVE SYM LIST               41860020
         SPACE                                                          41930020
         LINK  MF=(E,(1)),SF=(E,(15))   RESOLVE SYMBOLS                 42000020
         SPACE                                                          42050020
         SPACE                                                          42062020
SYMBLOW  EQU   *                                                        42070020
         LTR   RETCODE,RETCODE          IS RETURN CODE ZERO             42140020
         BNZ   TESTCODE                 NO, CHECK FURTHER               42210020
         MVI   TSTCURCT,BLANK           BLANK OUT CSECT NAME            42280020
         MVC   CSECTNM1(L7),TSTCURCT       IN TCOMTAB                   42350020
         LA    REG4,TSTCURCT            GET ADDR OF FIELD               42420020
         LH    REG5,PDELEN2             GET LENGTH OF NAME              42490020
         BCTR  REG5,ZERO                DECREMENT BY ONE                42560020
         L     WORKO,PDECTNAM           GET POINTER TO NAME             42630020
         EX    REG5,EXMOVE              MOVE CSECT NAME TO TCOMTAB      42700020
         SPACE                                                          42750020
         L     REG7,PDEUSER             PICK UP ADDRESS RETURNED        42770020
         S     REG7,TSTWHR              GET DISPLACEMENT OF CSECT       42820020
*                                       FROM BEGIN OF LOAD MODULE       42830020
         A     REG7,CSECTADR            ADD LOAD MODULE ADDR            42832020
*                                       (FIRST CSECT ADDR) FOUND BY     42834020
*                                       QUALIFY'S SEARCH                42836020
         SPACE                                                          42840020
SETTCOM  EQU   *                        PUT LATEST INFO IN TCOMTAB      42910020
         ST    REG7,TSTSYMBA            STORE NEW BASE ADDRESS IN       43050020
         ST    REG7,PPLOAD                 FIELDS OF TCOMTAB            43120020
         LM    REG6,REG7,NEWLOAD        PICK UP NEW LOADNAME            43190020
         STM   REG6,REG7,TSTCURLD       STORE IN QUALIFIED LOADNAME     43260020
*                                       FIELD OF TCOMTAB                43330020
         SPACE                                                          43380020
**************************************************************          43390020
*                                                            *          43392020
*        THE FOLLOWING ROUTINE WILL INITIALIZE TO PRINT      *          43394020
*        A MESSAGE INDICATING THE TCB ADDRESS UNDER WHICH    *          43396020
*        QUALIFICATION HAS TAKEN PLACE.                      *          43398020
*                                                            *          43398420
**************************************************************          43398820
         SPACE                                                          43399220
         ST    WORKE,TCBSAVE            SAVE TCB ADDR                   43399620
         L     WORKE,MSG08              GET PTR TO INFORMATION MSG      43399720
         BAL   REG8,FIXMSG              MOVE MSG TO OUTPUT BUFFER       43399820
         SPACE                                                          43399920
         LA    REG4,ONE(REG6,REG4)      GET BUFFER LOCATION FOR TCB     43423220
*                                       ADDRESS INSERT                  43433220
         UNPK  ZERO(L7,REG4),TCBSAVE+ONE(FOUR)  UNPACK TCB ADDR         43443220
         OI    FIVE(REG4),HEXF0         SET SIGN PORTION OF LAST BYTE   43445220
         SPACE                                                          43445620
         TR    ZERO(SIX,REG4),TAB-HEXF0    TRANSLATE TCB ADDR TO        43446020
*                                          PRINTABLE HEX                43446420
         LA    REG6,L7(REG6)            GET NEW LENGTH OF MSG           43446520
*                                       (ORIGINAL LENGTH + 1 FOR MOVE   43446620
*                                       + SIX FOR TCB ADDR)             43454420
         STC   REG6,NINE(PARAMREG)      SAVE IN OUTPUT BUFFER           43456420
         SPACE                                                          43458420
         LCR   PARAMREG,PARAMREG        GET COMPLEMENT FOR MSG          43460420
         L     ADDREG,TPUTADDR          GET I/O ROUTINE ADDR            43460820
         BALR  RETREG,ADDREG            GO PUT OUT INFORMATION MSG      43461220
         SPACE                                                          43461620
         STC   RETCODE,CODESAVE         SAVE RETURN CODE                43462020
         CLI   CODESAVE,SIXTEEN         CHECK FOR ATTN SCHEDULED        43462120
         BE    CODE16                   IF SO, SET RETURN CODE TO 16    43481520
*                                       FOR MAINLINE                    43491520
         SPACE                                                          43493520
**************************************************************          43495520
         SPACE                                                          43501220
         OC    TSTGO(FOUR),TSTGO        TEST IF A NEW TCB WAS           43520620
*                                       QUALIFIED                       43540020
         LA    RETCODE,FOUR             IF SO, SET RETURN CODE TO 4     43610020
         BNZ   QFYRET1                  AND BRANCH                      43680020
         SPACE                                                          43750020
QFYCCO   EQU   *                        THIS IS A WRAP UP ROUTINE       43820020
         XR    RETCODE,RETCODE          SET RETURN CODE TO ZERO         43890020
QFYRET   EQU   *                        RETURN TO MAINLINE              43960020
         MVC   PPTCB(FOUR),PPTCBSAV     RESTORE ORIGINAL PPTCB IN       44010020
*                                       TCOMTAB                         44020020
         MVC   PPRB(FOUR),PPRBSAV       RESTORE ORIGINAL RB             44022020
QFYRET1  EQU   *                        EQUATE LABEL                    44024020
         SPACE                                                          44030020
         L     SAVEREG,FOUR(ZERO,SAVEREG) RESTORE REG 13                44170020
         RETURN (14,12),,RC=(15)        RETURN TO CALLER - IKJEGMN1     44240020
         SPACE                                                          44310020
         SPACE                                                          44380020
NEWTCB   EQU   *                        LOADNAME FOUND ON A NEW TCB     44450020
         L     REG4,PPRB                GET CURRENT RB                  44520020
         L     REG5,BREAKTAB            GET PTR TO BREAK TABLE          44590020
*                                       FROM TCOMTAB                    44660020
         USING BRKELEM,REG5             SET UP ADDRESSABILITY TO        44730020
*                                       BREAK TABLE                     44800020
         SPACE                                                          44870020
         L     REG6,TCBRBP              GET PTR TO RB QUE               45010020
         USING RBSECT,REG6              SET UP ADDRESSABILITY TO        45080020
*                                       NEW RB                          45150020
         SPACE                                                          45160020
         LTR   REG5,REG5                HAS A BREAKPOINT BEEN SET       45170020
         BZ    SETTCB                   NO, BRANCH                      45180020
         SPACE                                                          45190020
         SPACE                                                          45220020
PRBTST   LA    REG6,ZERO(ZERO,REG6)     CLEAR HIGH-ORDER BYTE           45290020
         TM    RBSTAB1,RBFTSIRB         IS RB A PRB OR AN IRB           45360020
         BZ    RBTST                    YES...                          45430020
         SPACE                                                          45500020
         L     REG6,RBLINK              NO...BUMP TO NEXT RB            45570020
         B     PRBTST                   CHECK AGAIN                     45640020
         SPACE                                                          45710020
RBTST    TM    RBOPSW+ONE,HEXF0         CHECK PSW FOR KEY 0             45780020
         BZ    NOQUAL                   KEY IS ZERO, NO QUALIFICATION   45850020
         SPACE                                                          45920020
         TM    RBOPSW+ONE,HEX01         CHECK P-BIT OF PSW'S AMWP       45990020
         BZ    NOQUAL                   P-BIT OFF INDICATES             46060020
*                                       SUPERVISOR STATE...NO GOOD      46130020
         SPACE                                                          46200020
         DROP  REG6                                                     46270020
         USING RBSECT,REG4              SET UP ADDRESSABILITY TO        46340020
*                                       OLD RB                          46410020
         SPACE                                                          46480020
CHKBRK   CLC   RBOPSW+FIVE(THREE),BRKADDR+ONE   COMPARE INSTR ADDR      46550020
*                                               OF CURRENT RB'S PSW     46620020
*                                               TO BRKADDR              46690020
         BE    MATCH                    BRANCH IF MATCH IS FOUND        46760020
         SPACE                                                          46830020
         L     REG5,BRKLINK             GET BRKLINK ENTRY               46900020
         LTR   REG5,REG5                IS IT ZERO (END OF CHAIN)       46970020
         BZ    SETTCB                   YES...GO SET PPTCB              47040020
         B     CHKBRK                   NO...CHK NEXT BREAK ELEMENT     47110020
         SPACE                                                          47180020
MATCH    LA    PARAMREG,BRKINST         PTR TO BRKINSTR IN              47250020
*                                       BREAK TABLE                     47320020
         L     ZERO,PPRB                GET CUR RB ADDR FROM TCOMTAB    47390020
         O     ZERO,ICCHNG              SET HIGH BYTE TO X'08'          47460020
         SVC   TESTSVC                  ISSUE IC CHANGE SVC             47530020
         SPACE                                                          47600020
SETTCB   L     REG5,PPTCB               GET CUR PROB PGM TCB ADDR       47670020
         ST    REG5,TCBUSED             SAVE ADDRESS OF OLD TCB         47740020
         LA    WORKE,ZERO(ZERO,WORKE)   CLEAR HIGH-ORDER BYTE           47810020
         ST    WORKE,PPTCB              PUT THE NEW TCB ADDRESS IN      47880020
*                                          TCOMTAB                      47950020
         SPACE                                                          48020020
         DROP  REG4                                                     48090020
         USING RBSECT,REG6              ADDRESSABILITY TO NEW RB        48160020
         SPACE                                                          48230020
SETPRB   LA    ZERO,ZERO(REG6)          GET ADDR OF NEW RB              48300020
         ST    ZERO,PPRB                SAVE NEW RB ADDR                48370020
         SPACE                                                          48377020
         L     WORKO,RBCDE              GET PTR TO CDE                  48384020
         LA    WORKO,ZERO(WORKO)        CLEAR HIGH BYTE                 48391020
         LTR   WORKO,WORKO              CHECK IF CDE ADDR IS ZERO       48398020
         BNZ   SETAQUAL                 IF NOT, CHANGE 'TSTAQUAL'       48405020
*                                       IN TCOMTAB                      48412020
         SPACE                                                          48419020
         MVI   TSTAQUAL,ZEROBYTE        IF SO, SET FIRST BYTE OF        48426020
*                                       TSTAQUAL TO ZERO                48433020
         B     SETTSTGO                 BRANCH TO SET 'TSTGO' IN        48440020
*                                       TCOMTAB                         48447020
         SPACE                                                          48454020
SETAQUAL EQU   *                        INITIALIZE TO REQUALIFY         48461020
         MVC   TSTAQUAL(TWELVE),CDNAME(WORKO)   PUT LOADNAME AND        48468020
*                                       ENTRY POINT ADDR INTO TSTAQUAL  48475020
         SPACE                                                          48482020
SETTSTGO MVC   TSTGO(FOUR),RBOPSW+FOUR  SAVE NEW RB'S PSW INSTR ADDR    48489020
         SPACE                                                          48510020
         LA    PARAMREG,TSTGO+SIX       REG1 = PTR TO SVC               48580020
         O     ZERO,ICCHNG              SET HIGH ORDER BYTE TO X'08'    48650020
         SVC   TESTSVC                  ISSUE SVC TO CHANGE IC          48720020
         SPACE                                                          48790020
         L     ZERO,PPRB                REG0 = PTR TO NEW RB            48860020
         MVC   TSTGO+FOUR(ONE),RBWCF    SAVE WAIT COUNT OF NEW RB       48930020
         O     ZERO,WAITCNT             PUT WAIT COUNT INDIC INTO HIGH  49000020
*                                       ORDER BYTE.                     49070020
         SVC   TESTSVC                  ISSUE SVC TO TURN OFF WAIT CNT  49210020
         SPACE                                                          49280020
         DROP  REG6                                                     49350020
         SPACE                                                          49420020
         B     TSTENTRY                 BRANCH TO TEST FOR ENTRY NAME   49490020
         SPACE                                                          49560020
NOQUAL   EQU   *                                                        49630020
         L     PARAMREG,MSG11           PTR TO MSG                      49700020
         B     PUTMSG                   PUT OUT 'QUALIFY FAILED' MSG    49770020
         SPACE                                                          49840020
NOENTRY  EQU   *                        LOADNAME WAS FOUND BUT          49910020
*                                          ENTRYNAME NOT SPECIFIED      49980020
         MVI   TSTCURCT,ZEROBYTE        ZERO OUT FIELD IN TCOMTAB FOR   50050020
         MVC   CSECTNM1(L7),TSTCURCT       CURRENTLY QUALIFIED CSECT    50120020
*                                          NAME                         50190020
         B     SETTCOM                  FINISH PUTTING INFO IN TCOMTAB  50260020
         SPACE                                                          50330020
TESTCODE EQU   *                        CHECK CODE ON RETURN FROM       50400020
*                                          IKJEGSYM                     50470020
         CLI   TCBUSED,NOTNEW           WAS NEW TCB USED                50540020
         BE    STOREC                   NO, CHECK RETURN CODE           50610020
         MVC   PPTCB(L4),TCBUSED        RESTORE PPTCB                   50680020
         SPACE                                                          50750020
STOREC   EQU   *                        CHECK RETURN CODE               50820020
         STC   RETCODE,CODESAVE         SAVE CODE TO TEST               50890020
         CLI   CODESAVE,SIXTEEN         WAS AN ATTENTION SCHEDULED      50960020
         BE    QFYRET                   YES, RETURN TO CALLER           51030020
         B     LDCST                    NO, PUT OUT MESSAGE FOR UNABLE  51100020
*                                          TO QUALIFY LOADNAME.         51170020
*                                          CSECTNAME                    51240020
         SPACE                                                          51310020
FIXMSG   EQU   *                        SET UP MSG BUFFER               51380020
         L     WORKO,ZERO(ZERO,WORKE)   GET POINTER TO FIRST LEVEL MSG  51450020
         L     REG7,FOUR(ZERO,WORKE)    GET POINTER TO SECOND LEVEL MSG 51520020
         L     PARAMREG,OUTBUF          GET ADDRESS OF OUTPUT BUFFER    51590020
         LR    REG4,PARAMREG            PUT ADDRESS IN REGISTER 4       51660020
         LA    REG4,EIGHT(ZERO,REG4)    OFFSET FOR FIRST LEVEL MSG      51730020
         ST    REG4,ZERO(ZERO,PARAMREG) STORE POINTER TO FIRST MESSAGE  51800020
         ST    REG7,FOUR(ZERO,PARAMREG) STORE POINTER TO SECOND MSG     51870020
         LH    REG6,ZERO(ZERO,WORKO)    PICK UP LENGTH OF FIRST MSG     51940020
         BCTR  REG6,ZERO                DECREMENT FOR EX INSTRUCTION    52010020
         EX    REG6,EXMOVE              MOVE FIRST MESSAGE TO BUFFER    52080020
         BR    REG8                     RETURN TO CALLER                52150020
         EJECT                                                          52570020
********************************************************************    52640020
*                                                                  *    52710020
*THIS ROUTINE WILL BE ENTERED BY PARSE TO MAKE A VALIDITY CHECK ON *    52780020
* THE FIRST QUALIFY POSITIONAL PARAMTER.  IF THE PARAMETER IS AN   *    52850020
* EXPRESSION, AN INDIRECT ADDRESS, AN ABSOLUTE ADDRESS, OR A FULLY *    52920020
* QUALIFIED ADDRESS CONTROL IS GIVEN TO THE CONVERT ROUTINE TO CONVERT  52990020
* THE ADDRESS TO BINARY.                                           *    53060020
*                                                                  *    53130020
********************************************************************    53200020
         SPACE                                                          53270020
QFYVALCK EQU   *                        VALIDITY CHECK ROUTINE          53340020
         SAVE  (14,12),,QFYVALCK        SAVE REGISTERS FROM PARSE       53410020
         L     REG5,FOUR(ZERO,PARAMREG) GET ADDRESS OF QUALIFY'S SAVE   53480020
*                                          AREA                         53550020
         L     BASEREG,SIXTY8(ZERO,REG5) SET UP ADDRESSABILITY WITH     53620020
*                                          MAINLINE OF QUALIFY          53690020
         L     REG9,FIFTY6(ZERO,REG5)   RESTORE REGISTER 9 WITH ADDR    53760020
*                                          OF TCOMTAB                   53830020
         L     REG10,SIXTY(ZERO,REG5)   WORKAREA ADDRESSABILITY         53900020
         SPACE                                                          53970020
         L     REG6,REGSAVE3            GET ADDRESS OF SAVE AREA FOR    54040020
*                                          THIS ROUTINE                 54110020
         ST    SAVEREG,FOUR(ZERO,REG6)  SAVE ADDRESS OF PARSE SAVE AREA 54180020
         ST    REG6,EIGHT(ZERO,SAVEREG) STORE ADDRESS OF NEW SAVE AREA  54250020
*                                          IN PARSE SAVE AREA           54320020
         LR    SAVEREG,REG6             PUT ADDRESS OF NEW SAVE AREA    54390020
*                                          IN REGISTER 13               54460020
         SPACE                                                          54530020
* BEGIN TESTS OF PARAMETER                                              54600020
         L     R11,ZERO(ZERO,PARAMREG)   PUT ADDRESS OF PDE IN REG 11   54670020
         ST    PARAMREG,PDESAVE         SAVE PARSE PARAM LIST ADDR      54740020
         XR    REG4,REG4                CLEAR REGISTER FOR TEST         54810020
         CH    REG4,PDEINDCT            IS ADDRESS INDIRECT             54880020
         BNE   PREPCONV                 YES, SET UP FOR CONVERT ROUTINE 54950020
         TM    PDEFLG4,REGTYPE          IS IT A REGISTER ADDRESS        55020020
         BM    REGMSG                   YES, PUT OUT MESSAGE FOR        55090020
*                                          INVALID ADDRESS              55160020
         CLI   PDEFLG4,SYMADDR          IS ADDRESS A SYMBOLIC           55230020
         BNE   WHATISIT                 NO, DETERMINE WHETHER OR NOT    55300020
*                                          TO CONVERT                   55370020
         CLI   PDESIGN,ZEROBYTE         IS ADDRESS AN EXPRESSION        55440020
         BNE    PREPCONV                 YES, SET UP FOR CONVERT RTN    55510020
         TM    PDEFLG1,ONBIT            IS ADDRESS FULLY QUALIFIED      55580020
         BZ    CHKCT                    NO, SET UP FOR RETURN TO PARSE  55650020
         SPACE                                                          55930020
PREPCONV EQU   *                        SET UP FOR CONVERT ROUTINE      56000020
         LCR   PARAMREG,R11             PUT TWO'S COMPLEMENT OF ADDR    56070020
*                                          OF PDE IN REGISTER 1 TO      56140020
*                                          INDICATE THAT THIS IS TO BE  56210020
*                                          AN ADDRESS CONVERT           56280020
         XR    ZERO,ZERO                INDICATE THAT A BINARY CONVERT  56350020
*                                          IS DESIRED                   56420020
         L     ADDREG,TSTCONVT          GET ADDRESS OF CONVERT ROUTINE  56490020
         BALR  RETREG,ADDREG            GO TO CONVERT ROUTINE           56560020
         LTR   RETCODE,RETCODE          WAS CONVERT SUCCESSFUL          56630020
         BNZ   BADCONV                  NO...HAVE PARSE PUT OUT         56700020
*                                       'REENTER'                       56770020
         TM    PDEUSER,ONBIT            IS ADDRESS IN USERWORD          56840020
         BZ    GOBACK                   YES, RETURN TO PARSE            56910020
         L     WORKE,PDEUSER            GET POINTER TO SI BLOCK         56980020
         L     WORKO,ZERO(ZERO,WORKE)   PICK UP ADDR                    57050020
         ST    WORKO,PDEUSER            STORE IN USERWORD               57120020
         B     GOBACK                   RETURN TO PARSE                 57190020
         SPACE                                                          57260020
CHKLENG  EQU   *                        CHECK LENGTH OF SYMBOLIC        57330020
         XR    REG5,REG5                CLEAR REGISTER                  57400020
         LA    REG5,L8(ZERO,REG5)       PUT AN 8 IN REGISTER            57470020
         CH    REG5,PDELEN3             DOES SYMBOL EXCEED 8 BYTES      57540020
         BL    EXCEEDS                  YES, PUT OUT MESSAGE            57610020
BACK     L     REG4,NOBINARY            PICK UP INDICATION FOR ADDRESS  57680020
*                                          NOT CONVERTED TO BINARY      57750020
         ST    REG4,PDEUSER             PLACE IN PDE                    57820020
         SPACE                                                          57890020
GOBACK   EQU   *                        RETURN                          57960020
         XR    RETCODE,RETCODE          SET RETURN CODE TO ZERO         58030020
         L     SAVEREG,FOUR(ZERO,SAVEREG) RESTORE REG 13                58100020
         RETURN (14,12),,RC=(15)        RETURN TO PARSE                 58170020
         SPACE                                                          58240020
CHKCT    EQU   *                        TEST FOR CSECTNAME.SYMBOL       58310020
         TM    PDEFLG2,ONBIT            CSECTNAME GIVEN                 58380020
         BZ    CHKLENG                  NO, TEST LENGTH OF SYMBOLIC     58450020
         B     PREPCONV                 RESOLVE CSECTNAME ADDRESS       58520020
         SPACE                                                          58590020
WHATISIT  EQU  *                        DETERMINE WHETHER OR NOT TO     58660020
*                                          CONVERT ADDRESS              58730020
         TM    PDEFLG1,ONBIT            LOADNAME GIVEN                  58800020
         BZ    PREPCONV                 NO, CONVERT ADDRESS             58870020
         TM    PDEFLG3,ONBIT            FULLY QUALIFIED NAME GIVEN      59080020
         BO    PREPCONV                 YES, CONVERT ADDRESS            59150020
         B     BACK                     INPUT WAS LOADNAME.CSECTNAME    59220020
*                                          RETURN TO IKJPARS WITH CODE  59290020
*                                          OF ZERO                      59360020
         SPACE                                                          59430020
EXCEEDS  EQU   *                        PREPARE TO PUT OUT MESSAGE FOR  59500020
*                                          LENGTH OF SYMBOL TOO GREAT   59570020
         L     WORKE,MSG06              GET PTR TO MSG ADDR             59640020
         B     MSGOUT                   BRANCH TO PUT OUT MESSAGE       59710020
         SPACE                                                          59780020
REGMSG   L     WORKE,MSG07              GET PTR TO MSG ADDR             59850020
         SPACE                                                          59920020
MSGOUT   BAL   REG8,BLDMSGS             GO SET UP 1ST LEVEL MSG         59990020
         SPACE                                                          60060020
         L     REG5,PDESAVE             GET PTR TO PARSE PARAMETER      60130020
*                                       LIST                            60200020
         L     REG6,FOUR(WORKE)         GET 2ND LEVEL MSG ADDR          60270020
         ST    REG6,EIGHT(REG5)         SAVE IN PARSE PARAMETER LIST    60340020
         ST    REG6,FOUR(PARAMREG)      SAVE IN OUTPUT BUFFER           60390020
         SPACE                                                          60400020
         LCR   PARAMREG,PARAMREG        GET COMPLEMENT TO INDICATE      60410020
*                                          ERROR MSG TO TERMINAL        60480020
         L     ADDREG,TPUTADDR          GET ADDR OF MESSAGE RTN         60550020
         BALR  RETREG,ADDREG            GO, PUT OUT MESSAGE             60620020
         LTR   RETCODE,RETCODE          WAS MESSAGE SUCCESSFULLY        60690020
*                                          HANDLED                      60760020
         BNZ   SAVECODE                 NO, SAVE RETURN CODE            60830020
         B     SETCODE8                 HAVE PARSE PUT OUT 'REENTER'    60900020
         SPACE                                                          60970020
         SPACE 2                                                        61390020
BLDMSGS  L     REG4,OUTBUF              GET ADDR OF OUTPUT BFFR         61460020
         LR    PARAMREG,REG4            PUT INTO REG1                   61530020
         LA    REG4,EIGHT(REG4)         ADDR FOR MSG TEXT               61600020
         ST    REG4,ZERO(PARAMREG)      SAVE IN OUTPUT BFFR             61670020
         XC    FOUR(FOUR,PARAMREG),FOUR(PARAMREG)  CLEAR SECOND ADDR    61740020
         L     WORKO,ZERO(ZERO,WORKE)   GET 1ST LEVEL MSG ADDR          61810020
         SR    REG5,REG5                CLEAR REG                       61880020
         IC    REG5,ONE(WORKO)          GET MSG LENGTH                  61950020
         SPACE                                                          62020020
         BCTR  REG5,ZERO                DECREMENT BY 1 FOR MOVE         62090020
         EX    REG5,EXMOVE              MOVE 1ST LEVEL MSG TO           62160020
*                                       OUTPUT BUFFER                   62230020
         SPACE                                                          62300020
         LA    PARAMREG,ONE(REG5,REG4)  SET PTR TO OUTPUT BFFR          62370020
*                                       LOCATION FOR INSERT             62440020
         LR    ZERO,R11                 ADDR OF PDE IN REG 0            62510020
         SPACE                                                          62580020
         L     ADDREG,TSTADDR           ADDR OF BUILD RTN               62650020
         BALR  RETREG,ADDREG            GO BUILD INSERT                 62720020
         SPACE                                                          62790020
         L     PARAMREG,OUTBUF          GET PTR TO OUTPUT BFFR          62860020
         LA    REG5,ONE(REG5)           GET ORIGINAL LENGTH             62930020
         AR    REG5,ZERO                ADD NO. BYTES INSERTED          63000020
         LA    REG4,ZERO(REG5,REG4)     GET LOCATION IN OUTPUT          63070020
*                                       BFFR TO INSERT PLUS SIGN        63140020
         MVI   ZERO(REG4),PLUS          PUT PLUS SIGN INTO MSG          63210020
         LA    REG5,ONE(REG5)           ADD ONE TO TOTAL LENGTH         63280020
*                                       TO ACCOUNT FOR PLUS SIGN        63350020
         STC   REG5,NINE(ZERO,PARAMREG) SAVE TOTAL MSG LENGTH           63420020
         BR    REG8                     RETURN TO CALLING RTN           63490020
         EJECT                                                          63560020
********************************************************************    63630020
*                                                                  *    63700020
*   THIS ROUTINE WILL BE ENTERED BY PARSE TO MAKE A VALIDITY CHECK *    63770020
*   ON THE ADDRESS SPECIFIED FOR THE TCB KEYWORD.                  *    63840020
*                                                                  *    63910020
********************************************************************    63980020
         SPACE 2                                                        64050020
QFYCHECK EQU   *                                                        64120020
         SAVE  (14,12),,QFYCHECK        SAVE REGISTERS FROM PARSE       64190020
         L     REG5,FOUR(ZERO,PARAMREG) GET ADDRESS OF QUALIFY'S        64260020
*                                          SAVE AREA                    64330020
         L     BASEREG,SIXTY8(ZERO,REG5) GET ADDRESSABILITY WITH        64400020
*                                          MAINLINE OF QUALIFY          64470020
         L     REG9,FIFTY6(ZERO,REG5)   RESTORE REG9 WITH ADDRESS OF    64540020
*                                          TCOMTAB                      64610020
         L     REG10,SIXTY(ZERO,REG5)   WORKAREA ADDRESSABILITY         64680020
         SPACE                                                          64750020
         L     REG6,REGSAVE3            GET ADDRESS OF SAVE AREA FOR    64820020
*                                          THIS ROUTINE                 64890020
         ST    SAVEREG,FOUR(ZERO,REG6)  SAVE ADDRESS OF PARSE SAVE AREA 64960020
         ST    REG6,EIGHT(ZERO,SAVEREG) STORE ADDRESS OF NEW SAVE AREA  65030020
*                                          IN PARSE SAVE AREA           65100020
         LR    SAVEREG,REG6             PUT ADDRESS OF NEW SAVE AREA    65170020
*                                          IN REGISTER 13               65240020
* GET TCB ADDRESS CONVERTED TO BINARY                                   65310020
         L     R11,ZERO(ZERO,PARAMREG)  GET ADDR OF PDE                 65380020
         ST    PARAMREG,PDESAVE         SAVE PARSE PARAM LIST ADDR      65450020
         LCR   PARAMREG,R11             PUT COMPLEMENT OF ADDRESS OF    65520020
*                                          PDE IN REGISTER TO INDICATE  65590020
*                                          ADDRESS CONVERT              65660020
         XR    ZERO,ZERO                INDICATE BINARY CONVERT         65730020
         L     ADDREG,TSTCONVT          GET ADDRESS OF CONVERT ROUTINE  65800020
         BALR  RETREG,ADDREG            GO TO CONVERT ADDR              65870020
         LTR   RETCODE,RETCODE          WAS CONVERT SUCCESSFUL          65940020
         BNZ   BADCONV                  NO, SET ERROR CODE              66010020
         L     WORKO,PDEUSER                                            66080020
         TM    PDEUSER,ONBIT            IS CONVERTED ADDR IN USER WORD  66150020
         BZ    NOSYM                    YES...                          66220020
         SPACE                                                          66290020
         L     WORKO,ZERO(ZERO,WORKO)   NO, GET ADDR FROM SI BLOCK      66360020
         ST    WORKO,PDEUSER            AND SAVE                        66430020
NOSYM    EQU   *                                                        66500020
         LH    WORKO,PDEINDCT           GET INDIRECT ADDR COUNT         66570020
         LTR   WORKO,WORKO              IS IT ZERO                      66640020
         BNZ   FULLWORD                 NO...CHECK BOUNDARY             66710020
         SPACE                                                          66780020
         TM    PDEFLG4,REGTYPE          IS THIS A REGISTER ADDR         66850020
         BZ    FULLWORD                 NO...                           66920020
         SPACE                                                          66990020
         B     REGMSG                   SET UP FOR 'INVALID REGISTER    67060020
*                                       ADDR' MSG                       67130020
         SPACE                                                          67200020
FULLWORD TM    PDEUSER3,HEX03           FULLWORD BOUNDARY               67270020
         BZ    CHKTCB                   YES...CHECK IF TCB EXISTS       67340020
*                                       AT SPECIFIED ADDRESS            67410020
         SPACE                                                          67480020
         L     WORKE,MSG09              GET PTR TO MSG ADDR             67550020
         B     MSGOUT                   PRINT INVALID BNDRY MSG         67620020
         SPACE                                                          67690020
*****************************************************************       67760020
*                                                               *       67830020
*        THE FOLLOWING ROUTINE WILL CHECK WHETHER OR NOT A TCB  *       67900020
*        UNDER TEST ACTUALLY EXISTS AT THE SPECIFIED ADDRESS.   *       67970020
*                                                               *       68040020
*****************************************************************       68110020
         SPACE                                                          68180020
CHKTCB   L     REG7,PDEUSER             GET SPECIFIED TCB ADDR          68250020
         LA    REG7,ZERO(ZERO,REG7)     CLEAR HIGH BYTE AND SAVE        68320020
         SPACE                                                          68390020
         L     REG4,TSTTCB              TEST'S TCB                      68460020
         LA    REG8,ZERO(REG4)          CLEAR HIGH BYTE AND SAVE        68530020
DAU      L     REG5,D(REG4)             GET ADDR OF DAUGHTER TCB        68600020
         LTR   REG5,REG5                IS THERE A DAUGHTER             68670020
         BNZ   CHKADDR                  YES...CHECK IF VALID            68740020
         SPACE                                                          68810020
SIS      L     REG5,S(REG4)             GET ADDR OF SISTER TCB          68880020
         LTR   REG5,REG5                IS THERE A SISTER               68950020
         BNZ   CHKADDR                  YES...CHECK IF VALID            69020020
         SPACE                                                          69090020
MOTH     L     REG4,M(REG4)             GET ADDR OF MOTHER TCB          69160020
         LA    REG4,ZERO(REG4)          CLEAR HIGH BYTE                 69230020
         CR    REG4,REG8                DOES MOTHER = TEST TASK         69300020
         BNE   SIS                      NO...CHECK SISTER TASK          69370020
         SPACE                                                          69440020
         L     WORKE,MSG12              YES...PUT OUT 'INVALID TCB'     69510020
         B     MSGOUT                   MESSAGE                         69580020
         SPACE                                                          69650020
CHKADDR  LA    REG5,ZERO(ZERO,REG5)     CLEAR HIGH BYTE                 69720020
         CR    REG5,REG7                DOES THIS TCB ADDR MATCH        69790020
*                                       THE GIVEN TCB ADDR              69860020
         BE    RETPARSE                 YES...ADDR IS VALID, RETURN     69930020
*                                       TO PARSE                        70000020
         SPACE                                                          70070020
         LR    REG4,REG5                GET NEXT LOWER TCB IN CHAIN     70140020
         B     DAU                      LOOP UNTIL DONE                 70210020
         SPACE                                                          70280020
*****************************************************************       70350020
         SPACE 2                                                        70420020
RETPARSE EQU   *                        RETURN TO PARSE                 70490020
         L     SAVEREG,FOUR(ZERO,SAVEREG) RESTORE REG 13                70560020
         RETURN (14,12),,RC=(15)        RETURN TO PARSE                 70630020
         SPACE                                                          70700020
BADCONV  EQU   *                        CONVERT RTN NOT SUCCESSFUL      70770020
         L     REG4,PDESAVE             GET PARSE PARAM LIST ADDR       70840020
         MVC   EIGHT(FOUR,REG4),PDEUSER PUT ADDR OF SECOND LEVEL        70910020
*                                       MSG IN PARSE PARAMETER LIST     70980020
         SPACE                                                          71030020
SAVECODE STC   RETCODE,CONVRTCD         SAVE RETURN CODE                71040020
         CLI   CONVRTCD,EIGHT           COMPARE TO EIGHT                71042020
         BNH   SETCODE8                 IF 4 OR 8, SET RETURN CODE      71044020
*                                       TO 8 FOR PARSE                  71046020
         SPACE                                                          71048020
         LA    RETCODE,TWELVE           ELSE, SET RETURN CODE TO 12     71048420
*                                       FOR PARSE                       71048820
         B     RETPARSE                 RETURN TO PARSE                 71049220
         SPACE                                                          71050020
SETCODE8 XR    RETCODE,RETCODE          CLEAR REGISTER                  71120020
         LA    RETCODE,EIGHT(ZERO,RETCODE) RETURN CODE OF 8 FOR PARSE   71190020
*                                          TO ISSUE 'REENTER'           71260020
         B     RETPARSE                 RETURN TO PARSE                 71330020
         EJECT                                                          71400020
*************************************************************           71470020
*                                                           *           71540020
*        STAE RETRY ROUTINE                                 *           71610020
*                                                           *           71680020
*************************************************************           71750020
         SPACE 2                                                        71820020
RETRY    EQU   *                        RETRY ADDR                      71890020
         L     REG4,CVTPTR              GET CVT ADDR                    71960020
         USING CVTDSECT,REG4            ADDRESSABILITY TO CVT           72030020
         SPACE                                                          72100020
         L     REG4,CVTTCBP             GET ADDR OF CURRENT             72170020
         L     REG4,TCBADR(ZERO,REG4)   TCB (TEST'S TCB)                72240020
         DROP REG4                                                      72310020
         SPACE                                                          72380020
         USING TCB,REG4                 ADDRESSABILITY TO TCB           72450020
         L     REG9,TCBTRN              TCBTRN FIELD OF TEST'S TCB      72520020
*                                       CONTAINS PTR TO TCOMTAB         72590020
         SPACE                                                          72660020
         L     SAVEREG,REGSAVE2         GET ADDR OF QUALIFY'S           72730020
*                                       SAVEAREA                        72800020
         L     BASEREG,SIXTY8(ZERO,SAVEREG)  RE-ESTABLISH MODULE        72870020
*                                            ADDRESSABILITY             72940020
         SPACE                                                          73010020
         LTR   ZERO,ZERO                CHECK IF WORKAREA WAS           73080020
*                                       AVAILABLE                       73150020
         BNZ   NOWORK                   NO...                           73220020
         SPACE                                                          73290020
         FREEMAIN R,LV=104,A=(1)        YES...FREE IT                   73360020
         SPACE                                                          73430020
NOWORK   LA    RETCODE,TWENTY           SET RETURN CODE TO 20           73500020
         B     QFYRET                   RETURN TO MAINLINE              73570020
         EJECT                                                          73640020
EXMOVE   MVC   ZERO(ZERO,REG4),ZERO(WORKO) MOVE INSTRUCTION TO BE       73710020
*                                          EXECUTED                     73780020
         SPACE                                                          73850020
******************************************************************      73920020
*                                                                *      73990020
*              CONSTANTS                                         *      74060020
*                                                                *      74130020
******************************************************************      74200020
*                                                                       74270020
         SPACE                                                          74340020
         DS    0F                       ALIGNMENT                       74410020
NOEXP    DC    X'FF000000'              SYMBOLIC OF NOT AN ADDRESS      74480020
*                                          EXPRESSION                   74550020
MASKUP   DC    X'FFFFFFFE'              MASK FOR ROUNDING UP            74600020
NOBINARY DC    X'FFFFFFFF'              SYMBOLIC FOR ADDRESS NOT        74620020
*                                          CONVERTED TO BINARY          74690020
ICCHNG   DC    X'08000000'              IC CHANGE FLAG                  74760020
WAITCNT  DC    X'01000000'              FLAG TO TURN OFF WAIT CNT       74830020
TAB      DC    C'0123456789ABCDEF'      TABLE FOR TCB ADDR TRANSLATE    74880020
PCLISTA  DC    V(IKJEGPCL)              ADDRESS OF PCLIST CSECT         74900020
MSG01    DC    A(QM01)                  MSG 1 PTR                       74970020
MSG02    DC    A(QM02)                  MSG 2 PTR                       75040020
MSG03    DC    A(QM03)                  MSG 3 PTR                       75110020
MSG04    DC    A(QM04)                  MSG 4 PTR                       75180020
MSG05    DC    A(QM05)                  MSG 5 PTR                       75250020
MSG06    DC    A(QM06)                  MSG 6 PTR                       75320020
MSG07    DC    A(QM07)                  MSG 7 PTR                       75390020
MSG08    DC    A(QM08)                  MSG 8 PTR                       75460020
MSG09    DC    A(QM09)                  MSG 9 PTR                       75530020
MSG10    DC    A(QM010)                 MSG 10 PTR                      75600020
MSG11    DC    A(QM011)                 MSG 11 PTR                      75670020
MSG12    DC    A(QM012)                 MSG 12 PTR                      75740020
MSG13    DC    A(QM013)                 MSG 13 PTR                      75810020
         SPACE                                                          75880020
RETRYADR DC    AL3(RETRY)               RETRY ROUTINE ADDR FOR STAE     75950020
         SPACE                                                          76020020
STAELIST STAE  STAELIST,MF=L            LIST FORM OF STAE               76090020
STAELEN  EQU   *-STAELIST               LENGTH OF STAE LIST             76160020
         SPACE                                                          76230020
         SPACE                                                          76300020
SYMLIST  LINK  EP=IKJEGSYM,SF=L         LIST FORM OF LINK               76370020
SMTSYM   DS    0H                       SMT TEST LABEL FOR SYM LINK     76420020
         SPACE                                                          76430020
SYMLEN   EQU   *-SYMLIST                LENGTH OF SYM LIST              76440020
         SPACE                                                          76510020
ZEROH    DC    H'0'                     HALFWORD OF ZERO                76580020
         SPACE 2                                                        76650020
*****************************************************************       76720020
*                                                               *       76790020
*        STAE ADDRESS TABLE                                     *       76860020
*                                                               *       76930020
*****************************************************************       77000020
         SPACE 2                                                        77070020
STATBL   EQU   *                                                        77140020
         DC    AL1(PARSCODE),AL3(PARSBLOW)  PARSE LINK FAILED           77210020
         DC    AL1(SYMCODE),AL3(SYMBLOW)   SYM LINK FAILED              77280020
         DC    AL1(HEXFF)                  TABLE END                    77350020
         EJECT                                                          77420020
********************************************************************    77490020
*                                                                  *    77560020
* IKJEGMSQ IS THE MESSAGE CSECT FOR IKJEGQFY, THE QUALIFY SUBCOMMAND    77630020
*OF TEST.  THE FIRST SECTION CONTAINS ADCONS FOR THE FIRST AND     *    77700020
*SECOND LEVEL MESSAGES.  THE ADCONS ARE IN PAIRS WITH THE SECOND   *    77770020
*BEING EQUAL TO ZERO IF THERE IS NO SECOND LEVEL MSG               *    77840020
*                                                                  *    77910020
********************************************************************    77980020
         SPACE 2                                                        78050020
IKJEGMSQ CSECT                          MESSAGE CSECT                   78120020
         SPACE                                                          78190020
QM01     DC    A(QM1)                   MESSAGE 1                       78470020
         DC    A(QM2)                   MESSAGE 1                       78540020
QM02     DC    A(QM1)                   MESSAGE 2                       78610020
         DC    A(QM3)                   MESSAGE 2                       78680020
QM03     DC    A(QM1)                   MESSAGE 3                       78750020
         DC    A(QM4)                   MESSAGE 3                       78820020
QM04     DC    A(QM15)                  MESSAGE 4 (PARSE RC=12)         78890020
         DC    A(QM11)                  MESSAGE 4                       78960020
QM05     DC    A(QM6)                   MESSAGE 5 (PARSE RC=16)         79030020
         DC    A(0)                     2ND LEVEL IS NULL               79100020
QM06     DC    A(QM7)                   MESSAGE 6                       79170020
         DC    A(QM8)                   MESSAGE 6                       79240020
QM07     DC    A(QM7)                   MESSAGE 7                       79310020
         DC    A(QM9)                   MESSAGE 7                       79380020
QM08     DC    A(QM10)                  MESSAGE 8                       79450020
         DC    A(0)                     2ND LEVEL IS NULL               79520020
QM09     DC    A(QM7)                   MESSAGE 9                       79590020
         DC    A(QM12)                  MESSAGE 9                       79660020
QM010    DC    A(QM13)                  MESSAGE 10                      79730020
         DC    A(0)                     2ND LEVEL IS NULL               79800020
QM011    DC    A(QM5)                   MESSAGE 11                      79870020
         DC    A(QM14)                  MESSAGE 11                      79940020
QM012    DC    A(QM7)                   MESSAGE 12                      80010020
         DC    A(QM16)                  MESSAGE 12                      80080020
QM013    DC    A(QM17)                  MESSAGE 13                      80150020
         DC    A(QM18)                  MESSAGE 13                      80220020
         SPACE                                                          80290020
QM1      DC    AL2(QM1E-QM1)            LENGTH                          80360020
         DC    AL2(0)                   FIELD                           80430020
         DC    C'IKJ57270I UNABLE TO QUALIFY '                          80500020
QM1E     EQU   *                                                        80570020
         SPACE                                                          80640020
         DS    0H                       HALFWORD BOUNDARY               80710020
QM2      DC    AL2(QM2E-QM2)            LENGTH                          80780020
         DC    AL2(0)                   FIELD                           80850020
         DC    C'IKJ57270I          NOT FOUND RELATED TO SPECIFIED TCB' 80920020
QM2E     EQU   *                                                        80990020
         SPACE                                                          81060020
         DS    0H                       HALFWORD BOUNDARY               81130020
QM3      DC    AL2(QM3E-QM3)            LENGTH                          81200020
         DC    AL2(0)                   FIELD                           81270020
         DC    C'IKJ57270I INPUT NOT RESOLVED AS LOADNAME.CSECTNAME'    81340020
QM3E     EQU   *                                                        81410020
         SPACE                                                          81480020
         DS    0H                       HALFWORD BOUNDARY               81550020
QM4      DC    AL2(QM4E-QM4)            LENGTH                          81620020
         DC    AL2(0)                   FIELD                           81690020
         DC    C'IKJ57270I INPUT NOT RESOLVED AS LOADNAME OR SYMBOL'    81760020
QM4E     EQU   *                                                        81830020
         SPACE                                                          81900020
         DS    0H                       HALFWORD BOUNDARY               81970020
QM5      DC    AL2(QM5E-QM5)            LENGTH                          82040020
         DC    AL2(0)                   FIELD                           82110020
         DC    C'IKJ57271I QUALIFY FAILED+'                             82180020
QM5E     EQU   *                                                        82250020
         SPACE                                                          82320020
         DS    0H                       HALFWORD BOUNDARY               82390020
QM6      DC    AL2(QM6E-QM6)            LENGTH                          82460020
         DC    AL2(0)                   FIELD                           82530020
         DC    C'IKJ57275I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  82600020
QM6E     EQU   *                                                        82670020
         SPACE                                                          82740020
         DS    0H                       HALFWORD BOUNDARY               82810020
QM7      DC    AL2(QM7E-QM7)            LENGTH                          82880020
         DC    AL2(0)                   FIELD                           82950020
         DC    C'IKJ57272I INVALID ADDRESS  '                           83020020
QM7E     EQU   *                                                        83090020
         SPACE                                                          83160020
         DS    0H                       HALFWORD BOUNDARY               83230020
QM8      DC    AL2(QM8E-QM8)            LENGTH                          83300020
         DC    AL2(0)                   FIELD                           83370020
         DC    C'IKJ57272I LENGTH EXCEEDS EIGHT CHARACTERS'             83440020
QM8E     EQU   *                                                        83510020
         SPACE                                                          83580020
         DS    0H                       HALFWORD BOUNDARY               83650020
QM9      DC    AL2(QM9E-QM9)            LENGTH                          83720020
         DC    AL2(0)                   FIELD                           83790020
         DC    C'IKJ57272I REGISTER NOTATION MUST BE INDIRECT GENERAL R*83860020
               EGISTER'                                                 83930020
QM9E     EQU   *                                                        84000020
         SPACE                                                          84070020
         DS    0H                       HALFWORD BOUNDARY               84140020
QM10     DC    AL2(QM10E-QM10)          LENGTH                          84210020
         DC    AL2(0)                   FIELD                           84280020
         DC    C'IKJ57277I QUALIFICATION IS UNDER TCB AT '   TEXT       84350020
QM10E    EQU   *                                                        84420020
         DS    0H                       HALFWORD BOUNDARY               84490020
QM11     DC    AL2(QM11E-QM11)          LENGTH                          84560020
         DC    AL2(0)                   FIELD                           84630020
         DC    C'IKJ57276I PARSE ERROR CODE 12'                         84700020
QM11E    EQU   *                                                        84770020
         SPACE                                                          84840020
         DS    0H                       HALFWORD BOUNDARY               84910020
QM12     DC    AL2(QM12E-QM12)          LENGTH                          84980020
         DC    AL2(0)                   FIELD                           85050020
         DC    C'IKJ57272I FULLWORD BOUNDARY REQUIRED'                  85120020
QM12E    EQU   *                                                        85190020
         SPACE                                                          85260020
         DS    0H                       HALFWORD BOUNDARY               85330020
QM13     DC    AL2(QM13E-QM13)          MSG LENGTH                      85400020
         DC    AL2(0)                   FIELD                           85470020
         DC    C'IKJ57273I LOADNAME REQUIRED WITH TCB PARAMETER'        85540020
QM13E    EQU   *                                                        85610020
         SPACE                                                          85680020
         DS    0H                       HALFWORD BOUNDARY               85750020
QM14     DC    AL2(QM14E-QM14)          MSG LENGTH                      85820020
         DC    AL2(0)                   *                               85890020
         DC    C'IKJ57271I ATTEMPT QUALIFICATION AT NEXT BREAKPOINT'    85960020
QM14E    EQU   *                                                        86030020
         SPACE                                                          86100020
         DS    0H                       HALFWORD BOUNDARY               86170020
QM15     DC    AL2(QM15E-QM15)          LENGTH                          86240020
         DC    AL2(0)                   FIELD                           86310020
         DC    C'IKJ57276I QUALIFY FAILED, COMMAND SYSTEM ERROR+'       86380020
QM15E    EQU   *                                                        86450020
         SPACE                                                          86520020
         DS    0H                       HALFWORD BOUNDARY               86590020
QM16     DC    AL2(QM16E-QM16)          LENGTH                          86660020
         DC    AL2(0)                   FIELD                           86730020
         DC    C'IKJ57272I NO TCB EXISTS AT SPECIFIED ADDRESS'          86800020
QM16E    EQU   *                                                        86870020
         SPACE                                                          86940020
         DS    0H                       HALFWORD BOUNDARY               87010020
QM17     DC    AL2(QM17E-QM17)          LENGTH                          87080020
         DC    AL2(0)                   FIELD                           87150020
         DC    C'IKJ57274I SPECIFIED TCB IGNORED+'  MSG TEXT            87220020
QM17E    EQU   *                                                        87290020
         SPACE                                                          87340020
         DS    0H                       ALIGNMENT                       87350020
QM18     DC    AL2(QM18E-QM18)          LENGTH                          87352020
         DC    AL2(0)                   FIELD                           87354020
         DC    C'IKJ57274I TCB KEYWORD IS IGNORED WHEN'                 87356020
         DC    C' QUALIFYING TO AN ADDRESS'     MSG TEXT                87358020
QM18E    EQU   *                                                        87358420
         EJECT                                                          87360020
         DS    0F                       ALIGNMENT                       87430020
IKJEGPCL IKJPARM DSECT=IKJPARMD                                         87500020
ADDR     IKJPOSIT ADDRESS,PROMPT='ADDRESS',VALIDCK=QFYVALCK             87570020
TCBNAME  IKJKEYWD                                                       87640020
         IKJNAME 'TCB',SUBFLD=TCBADDR                                   87710020
TCBADDR  IKJSUBF                                                        87780020
ADDRTCB  IKJPOSIT  ADDRESS,PROMPT='TCB ADDRESS',VALIDCK=QFYCHECK        87850020
         IKJENDP                                                        87920020
         EJECT                                                          87990020
         TCOMTAB                        COMMUNICATIONS WORK AREA        88060020
CSECTNM1 EQU   TSTCURCT+1               SECOND BYTE OF TSTCURCT         88130020
PPTCB1   EQU   PPTCB+1                  SECOND BYTE OF FIELD            88200020
         EJECT                                                          88270020
WORKSP   DSECT                          WORK AREA DSECT                 88340020
PARSPARM EQU   *                        PARAMETER LIST FOR PARSE        88410020
PTUPT    DS    A                        POINTER TO UPT                  88480020
PTECT    DS    A                        POINTER TO ECT                  88550020
PTCPECB  DS    A                        POINTER TO CP ECB               88620020
PTPCL    DS    A                        POINTER TO PCL                  88690020
PTANSW   DS    A                        POINTER TO ANSWER PLACE         88760020
PTBUFF   DS    A                        POINTER TO COMMAND BUFFER       88830020
PTAREA   DS    A                        POINTER TO USER WORK AREA       88900020
NEWLOAD  DS    2F                       LOADNAME GIVEN BY USER          88970020
NEWLOAD1 EQU   NEWLOAD+1                SECOND BYTE OF NEWLOAD FIELD    89040020
PPRBSAV  DS    A                        SAVE AREA FOR PPRB              89110020
PPTCBSAV DS    A                        SAVE AREA FOR PPTCB             89160020
TCBSAVE  DS    A                        SAVE AREA FOR QUALIFIED TCB     89162020
PDESAVE  DS    A                        PTR TO PARSE PARAMETER LIST     89180020
PROTKEY  DS    X                        PROTECTION KEY FOR TEST         89250020
TCBFLG   DS    X                        SWITCH FOR TCB                  89320020
TCBGIVEN EQU   X'80'                    TCB SPECIFIED                   89390020
TCBNOSP  EQU   X'00'                    TCB NOT SPECIFIED               89460020
CODESAVE DS    X                        RETURN CODE SAVED FOR TESTING   89530020
CONVRTCD DS    X                        CONVERT RETURN CODE             89580020
         DS    0F                       ALIGNMENT                       89600020
CSECTADR DS    A                        ADDRESS OF FIRST CSECT          89670020
TCBUSED  DS    A                        ADDRESS OF TCB USED             89740020
BLDMSG   DS    18C                      WORK AREA TO BUILD MESSAGE      89810020
BLDMSG1  EQU   BLDMSG+1                 SECOND BYTE                     89880020
NEWADDR  EQU   X'00'                    INDICATES NEW TCB ADDR          89950020
NOTNEW   EQU   X'80'                    INDICATES TCB ADDR IN PPTCB     90020020
*                                          IS THE ONE LOADNAME WAS      90090020
*                                          FOUND ON                     90160020
TCBUSED1 EQU   TCBUSED+1                SECOND BYTE OF TCBUSED          90230020
         EJECT                                                          90300020
         IKJPARMA                                                       90370020
LDNM1    EQU   PDELDNAM+1               SECOND BYTE OF LOADNAME SLOT    90440020
STRING1  EQU   PDEADRPT+1               SECOND BYTE OF STRING           90510020
USEWRD   EQU   PDEUSER+1                SECOND BYTE OF USERWORD         90580020
PDEUSER3 EQU   PDEUSER+3                FOURTH BYTE OF USER WORD        90630020
         EJECT                                                          90650020
         TSTCWORK                                                       90720020
         EJECT                                                          90790020
         BRKELEM                                                        90860020
         EJECT                                                          90930020
CVTDSECT DSECT                                                          91000020
         CVT                                                            91070020
         EJECT                                                          91140020
         IKJTCB                         TCB DSECT                       91210020
         SPACE                                                          91280020
S        EQU   TCBNTC-TCB               SISTER TASK                     91350020
M        EQU   TCBOTC-TCB               MOTHER TASK                     91420020
D        EQU   TCBLTC-TCB               DAUGHTER TASK                   91490020
         EJECT                                                          91560020
         IKJRB                          RB DSECT                        91630020
         EJECT                                                          91700020
         IKJPPL                         PARSE PARAMETER LIST DSECT      91770020
         END                                                            91840020
