SYM      TITLE 'IKJEGSYM - TSO TEST ASSEMBLER SYMBOL PROCESSOR'         00040020
*C343200,352400                                                 SA55699 00050021
* TITLE  IKJEGSYM - TSO TEST ASSEMBLER SYMBOL PROCESSOR               * 00080020
*                                                                     * 00120020
* STATUS --                                                           * 00160020
*    CHANGE LEVEL 000                                                 * 00200020
*                                                                     * 00240020
* FUNCTION/OPERATION --                                               * 00280020
*    THE TEST SYMBOL PROCESSOR PROVIDES MAIN STORAGE ADDRESSES,       * 00320020
*    ASSEMBLER SYMBOL ATTRIBUTES AND CSECT NAMES FOR SYMBOLIC         * 00360020
*    DEBUGGING.                                                       * 00400020
*    BASICALLY MAIN STORAGE ADDRESSES ARE FOUND BY ADDING UP THE      * 00440020
*    MODULES LOADED MAIN STORAGE ADDRESS, CSECT DISPLACEMENT INTO     * 00480020
*    THE MODULE AND SYMBOL DISPLACEMENT INTO THE CSECT.               * 00520020
*    CSECT NAMES AND DISPLACEMENTS ARE FOUND IN THE CESD RECORDS      * 00560020
*    FOR THE MODULE.  IF IT IS A LOAD MODULE THEY RESIDE ON           * 00600020
*    SECONDARY STORAGE. IF IT IS A OBJECT MODULE LOADED VIA THE       * 00640020
*    OS LOADER THE CESD RECORDS ARE IN MAIN STORAGE.                  * 00680020
*    ASSEMBLER SYMBOL ATTRIBUTES AND DISPLACEMENTS ARE ONLY           * 00720020
*    AVAILIABLE FOR LOAD MODULES AND THE TEST PARM MUST BE PASSED     * 00760020
*    TO THE ASSEMBLER AND LINKAGE EDITOR TO OBTAIN THEM.              * 00800020
*    CESD AND SYMBOL INFORMATION CAN ONLY BE OBTAINED FROM LOAD       * 00840020
*    MODULES IF SVC 061 HAS PROCESSED DURING THEIR FETCH TIME.        * 00880020
*    CESD INFORMATION MAY BE OBTAINED FROM AN OBJECT MODULE WHEN      * 00920020
*    CHAINNED FROM THE P/P TCB AND THE CDE INDICATES LOADED BY        * 00960020
*    THE OS LOADER AND THAT CESD RECORDS ARE PRESENT.                 * 01000020
*                                                                     * 01040020
* ENTRY POINTS --                                                     * 01080020
*         IKJEGSYM     ONLY ENTRY POINT TO IKJEGSYM                   * 01120020
*                                                                     * 01160020
* INPUT --                                                            * 01200020
*    REGISTER 1 POINTS TO A PDE CONTAINING THE FOLLOWING ACCEPTED     * 01240020
*    ARGUMENTS                                                        * 01280020
*    LOADNAME ENTRYNAME                                               * 01320020
*    RETURN MAIN STORAGE ADDRESS IN USER FIELD OF PDE                 * 01360020
*    LOADNAME ENTRYNAME SYMBOL                                        * 01400020
*    RETURN SYMINFO BLOCK POINTED TO FROM USER FIELD                  * 01440020
*    IN PDE WITH THE HIGH ORDER BYTE EQUAL TO X'80'                   * 01480020
*    LOADNAME           OFFSET                                        * 01520020
*    RETURN CSECT NAME POINTED TO FROM PTR TO ENTRYNAME               * 01560020
*    FIELD IN PDE                                                     * 01600020
*    MISSING FIELDS ARE FILLED IN FROM THE CURRENTLY QUALIFIED        * 01640020
*    LOADNAME.ENTRYNAME OR IN THE CASE OF ENTRYNAME, DEFAULTED        * 01680020
*    TO THE FIRST CSECT OF THE MODULE                                 * 01720020
*                                                                     * 01760020
* OUTPUT --                                                           * 01800020
*    FILLED IN PDE, POSSIBLE SYMINFO BLOCK AND RETURN CODES           * 01840020
*                                                                     * 01880020
* EXTERNAL REFERENCES --                                              * 01920020
*         IKJEGIO    - ERROR MESSAGES TO TERMINAL                     * 01960020
*         DAIR       - ALLOCATE SYS1.LINKLIB                          * 02000020
*         GETMAIN    - FOR WORK AREA, SYMINFO BLK, DAIR PARM LIST     * 02040020
*         FREEMAIN   - DAIR PARM LIST, STAE WORK AREA                 * 02080020
*         OPEN       - A BPAM DCB FOR READING SYMBOLS                 * 02120020
*         CLOSE      - THE DCB FOR READING SYMBOLS                    * 02160020
*         READ       - SYMBOLS FROM SECONDARY STORAGE                 * 02200020
*         CHECK      - VERIFY READ, WAIT FOR READ TO COMPLETE         * 02240020
*         NOTE       - TTR OF FIRST CESD RECORD IN LOADNAME MEMBER    * 02280020
*         FIND       - POINT TO SYMBOL RCDS IN LOADNAME MEMBER OF PDS * 02320020
*         SYNADAF    - FOR AN I/O ERROR, OBTAIN SYSTEM INFO MESG      * 02360020
*         SYNADRLS   - RELEASE SYNADAF WORK AREA                      * 02400020
*                                                                     * 02440020
* EXITS, NORMAL --                                                    * 02480020
*         RETURN TO CALLER WITH RETURN CODES                          * 02520020
*         0     SUCCESSFULLY COMPLETED                                * 02560020
*         4     PASSED SYMBOLIC NAME NOT FOUND, EITHER LOADNAME       * 02600020
*         ENTRYNAME OR SYMBOLNAME, OR NO CORE AVAILABLE               * 02640020
*         8     UNABLE TO RESOLVE SYMBOLICS AT THIS TIME,             * 02680020
*         CANNOT ISSUE STAE, OPEN DCB, OR ALLOCATE LINKLIB            * 02720020
*         12     AN I/O ERROR HAS OCCURRED WHILE READING SECONDARY    * 02760020
*         STORAGE                                                     * 02800020
*         16     AN ATTENTION OR LOGON/LOGOFF ECB HAS BEEN POSTED     * 02840020
*         20     AN ABEND HAS BEEN INTERCEPTED BY STAE                * 02880020
*         MESSAGES     - MESSAGES ARE SENT TO THE TERMINAL IF AN I/O  * 02920020
*         ERROR HAS OCURRED WHILE READING SECONDARY STORAGE           * 02960020
*         OR WHEN SYMMESG SWITCH, EQUATED TO B'00100000', IN          * 03000020
*         THE TSTFLGS3 FIELD OF TCOMTAB DSECT IS OFF                  * 03040020
*         NO MESSAGES ARE PRINTED WHEN THE REQUEST IS TO RESOLVE      * 03050020
*         A PASSED OFFSET                                             * 03060020
*                                                                     * 03080020
* EXITS, ERROR --                                                     * 03120020
*         N/A                                                         * 03160020
*                                                                     * 03200020
* TABLES/WORKAREAS --                                                 * 03240020
*    TCOMTAB    - COMMUNICATIONS DSECT FOR ALL OF TEST                * 03280020
*    PDE        - CNTRL BLOCK CONTAINNING INPUTED ARGUMENTS           * 03320020
*    SYM RCDS   - ON SECONDARY STORAGE                                * 03360020
*    CESD RCDS  - ON SECONDARY OR IN MAIN STORAGE                     * 03400020
*    SYMTAB     - INCORE SYMBOL TABLE                                 * 03440020
*    SYMWORK    - INTERNAL WORK AREA                                  * 03480020
*    SVCINFO    - TABLE OF SAVED LOAD MODULE INFO BUILT BY            * 03520020
*    TESTRAN SVC 61 (IN DECIMAL)                                      * 03560020
*    SYMINFO    - ANSWER BLOCK RETURNED FOR A SYMBOL REQUEST          * 03600020
*                                                                     * 03640020
* ATTRIBUTES --                                                       * 03680020
*    REENTRANT AND REFRESHABLE                                        * 03720020
*                                                                     * 03760020
* CHARACTER CODE DEPENDENCY --                                        * 03800020
*    RE-ASSEMBLY IS REQUIRED FOR CHANGE OF CODE                       * 03840020
*                                                                     * 03880020
* NOTES --                                                            * 03920020
*    THE SYMBOL PROCESSOR IS SET UP FOR BEST RESPONSE TIME WHILE      * 03960020
*    RESOLVING SYMBOLS PLACED IN THE INCORE SYMBOL TABLE AND THEN     * 04000020
*    PREFIXED WITH THE CURRENTLY QUALIFIED LOADNAME ENTRYNAME.        * 04040020
         EJECT                                                          04080020
         TCOMTAB                                                        04120020
         SPACE 2                                                        04160020
         TSTCWORK                                                       04200020
         EJECT                                                          04240020
IKJEGSYM CSECT                                                          04280020
*                                                                       04320020
*        REGISTER EQUATES                                               04360020
*                                                                       04400020
PARMREG0 EQU   0              REGISTER 0                                04440020
PARMREG1 EQU   1              REGISTER 1                                04480020
PDEB     EQU   2              CONTAINS ADDRESS OF PASSED PDE            04520020
WORK1    EQU   3              REGISTER 3                                04560020
WORK2    EQU   4              REGISTER 4                                04600020
WORK3    EQU   5              REGISTER 5                                04640020
WORK4    EQU   6              REGISTER 6                                04680020
MESGBASE EQU   8              BASE FOR MESSAGE SECTION                  04720020
WORK5    EQU   7              REGISTER 7                                04760020
TCOMTABB EQU   9              BASE FOR TCOMTAB DSECT                    04800020
INFOBLKB EQU   10             BASE FOR INFO BLOCK BUILT FOR PRESENT REQ 04840020
SYMB2    EQU   11             BASE FOR IKJEGMYS CSECT                   04880020
SYMB     EQU   12             BASE FOR IKJEGSYM CSECT                   04920020
SYMWKB   EQU   13             BASE FOR SYM WORK AREA INCLUDES SAVE AREA 04960020
RETURN   EQU   14             REGISTER 14                               05000020
RETCODE  EQU   15             REGISTER 15                               05040020
*                                                                       05080020
*        EQUATES FOR SI INSTRUCTION IMEDIATE OPERANDS                   05120020
*                                                                       05160020
V00      EQU   X'00'                        HEX 00                      05200020
V01      EQU   X'01'                        HEX 01                      05240020
V02      EQU   X'02'                        HEX 02                      05280020
V03      EQU   X'03'                        HEX 03                      05320020
V04      EQU   X'04'                        HEX 04                      05360020
V07      EQU   X'07'                        HEX 07                      05400020
V08      EQU   X'08'                        HEX 08                      05440020
V0F      EQU   X'0F'                        HEX 0F                      05480020
V10      EQU   X'10'                        HEX 10                      05520020
V20      EQU   X'20'                        HEX 20                      05560020
V40      EQU   X'40'                        HEX 40                      05600020
V60      EQU   X'60'                        HEX 60                      05640020
V80      EQU   X'80'                        HEX 80                      05680020
V0C      EQU   X'0C'                        HEX 0C                      05720020
V50      EQU   X'50'                        HEX 50                      05760020
V7F      EQU   X'7F'                        HEX 7F                      05800020
V90      EQU   X'90'                        HEX 90                      05840020
V91      EQU   X'91'                        HEX 91                      05880020
V9F      EQU   X'9F'                        HEX 9F                      05920020
VBF      EQU   X'BF'                        HEX BF                      05960020
VC0      EQU   X'C0'                        HEX C0                      06000020
VDF      EQU   X'DF'                        HEX DF                      06040020
VE0      EQU   X'E0'                        HEX E0                      06080020
VE2      EQU   X'E2'                        HEX E2                      06120020
VEF      EQU   X'EF'                        HEX EF                      06160020
VF0      EQU   X'F0'                        HEX F0                      06200020
VFF      EQU   X'FF'                        HEX FF                      06240020
LSYMRCD  EQU   C'S'                         IDENTIFY LOGICAL SYM RCD    06280020
*                                                                       06320020
*        NUMBER EQUATES                                                 06360020
*                                                                       06400020
N0       EQU   0                            DECIMAL 0                   06440020
N1       EQU   1                            DECIMAL 1                   06480020
N2       EQU   2                            DECIMAL 2                   06520020
N3       EQU   3                            DECIMAL 3                   06560020
N4       EQU   4                            DECIMAL 4                   06600020
N5       EQU   5                            DECIMAL 5                   06640020
N6       EQU   6                            DECIMAL 6                   06680020
N7       EQU   7                            DECIMAL 7                   06720020
N8       EQU   8                            DECIMAL 8                   06760020
N9       EQU   9                            DECIMAL 9                   06800020
N10      EQU   10                           DECIMAL 10                  06840020
N11      EQU   11                           DECIMAL 11                  06880020
N12      EQU   12                           DECIMAL 12                  06920020
N13      EQU   13                           DECIMAL 13                  06960020
N14      EQU   14                           DECIMAL 14                  07000020
N15      EQU   15                           DECIMAL 15                  07040020
N16      EQU   16                           DECIMAL 16                  07080020
N17      EQU   17                           DECIMAL 17                  07120020
N18      EQU   18                           DECIMAL 18                  07160020
N20      EQU   20                           DECIMAL 20                  07200020
N21      EQU   21                           DECIMAL 21                  07240020
N22      EQU   22                           DECIMAL 22                  07280020
N23      EQU   23                           DECIMAL 23                  07320020
N24      EQU   24                           DECIMAL 24                  07360020
N25      EQU   25                           DECIMAL 25                  07400020
N26      EQU   26                           DECIMAL 26                  07440020
N28      EQU   28                           DECIMAL 28                  07480020
N29      EQU   29                           DECIMAL 29                  07520020
N31      EQU   31                           DECIMAL 31                  07560020
N32      EQU   32                           DECIMAL 32                  07600020
N33      EQU   33                           DECIMAL 33                  07640020
N34      EQU   34                           DECIMAL 34                  07680020
N36      EQU   36                           DECIMAL 36                  07720020
N37      EQU   37                           DECIMAL 37                  07760020
N38      EQU   38                           DECIMAL 38                  07800020
N40      EQU   40                           DECIMAL 40                  07840020
N41      EQU   41                           DECIMAL 41                  07880020
N42      EQU   42                           DECIMAL 42                  07920020
N44      EQU   44                           DECIMAL 44                  07960020
N46      EQU   46                           DECIMAL 46                  08000020
N47      EQU   47                           DECIMAL 47                  08040020
N48      EQU   48                           DECIMAL 48                  08080020
N49      EQU   49                           DECIMAL 49                  08120020
N50      EQU   50                           DECIMAL 50                  08160020
N51      EQU   51                           DECIMAL 51                  08200020
N52      EQU   52                           DECIMAL 52                  08240020
N53      EQU   53                           DECIMAL 53                  08280020
N54      EQU   54                           DECIMAL 54                  08320020
N56      EQU   56                           DECIMAL 56                  08360020
N57      EQU   57                           DECIMAL 57                  08400020
N58      EQU   58                           DECIMAL 58                  08440020
N59      EQU   59                           DECIMAL 59                  08480020
N60      EQU   60                           DECIMAL 60                  08520020
N61      EQU   61                           DECIMAL 61                  08560020
N62      EQU   62                           DECIMAL 62                  08600020
N63      EQU   63                           DECIMAL 63                  08640020
N64      EQU   64                           DECIMAL 64                  08680020
N65      EQU   65                           DECIMAL 65                  08720020
N66      EQU   66                           DECIMAL 66                  08760020
N68      EQU   68                           DECIMAL 68                  08800020
N69      EQU   69                           DECIMAL 69                  08840020
N70      EQU   70                           DECIMAL 70                  08880020
N71      EQU   71                           DECIMAL 71                  08920020
N72      EQU   72                           DECIMAL 72                  08960020
N73      EQU   73                           DECIMAL 73                  09000020
N74      EQU   74                           DECIMAL 74                  09040020
N75      EQU   75                           DECIMAL 75                  09080020
N80      EQU   80                           DECIMAL 80                  09120020
N88      EQU   88                           DECIMAL 88                  09160020
N90      EQU   90                           DECIMAL 90                  09200020
N94      EQU   94                           DECIMAL 94                  09240020
N100     EQU   100                          DECIMAL 100                 09280020
N104     EQU   104                          DECIMAL 104                 09320020
N110     EQU   110                          DECIMAL 110                 09360020
N256     EQU   256                          DECIMAL 256                 09400020
N800     EQU   800                          DECIMAL 800                 09440020
*                                                                       09450020
*        CONDITION CODE EQUATES FOR BCR INSTRUCTIONS                    09452020
*                                                                       09454020
ZERO     EQU   8                            BRANCH IF ZERO              09460020
ONES     EQU   1                            BRANCH IF ONES              09462020
NOTZERO  EQU   7                            BRANCH IF NOT ZERO          09464020
LOW      EQU   4                            BRANCH IF LOW               09466020
         SPACE 3                                                        09480020
*********************************************************************** 09520020
*                                                                     * 09560020
*        THIS IS THE ENTRY INITILIZATION AND MAINLINE ROUTINE.        * 09600020
*        SUB-ROUTINES ARE USED TO ANALYZE REQUESTS, GATHER INFO       * 09640020
*        ABOUT THE REQUEST AND RESOLVE THE REQUEST.                   * 09680020
*                                                                     * 09720020
*********************************************************************** 09760020
         SPACE 2                                                        09800020
*                                                                       09840020
*        ENTRY  INITILIZATION                                           09880020
*                                                                       09920020
         STM   RETURN,SYMB,N12(SYMWKB)      SAVE CALLER'S REGISTERS     09960020
         LR    SYMB,RETCODE                 USE ENTRY PT FOR BASE       10000020
         USING IKJEGSYM,SYMB                ESTABLISH ADDRESSABILITY    10040020
         LR    PDEB,PARMREG1                ADDR OF PASSED PDE          10080020
         USING PDE,PDEB                     BASE FOR PDE DSECT          10120020
         MVC   PDEUWORD(N4),NO2NDMSG        NO 2ND LEV MSG TO CALLER    10160020
         USING TCOMTAB,TCOMTABB             BASE FOR TCOMTAB DSECT      10200020
         L     MESGBASE,MESGADDR            ADDRESSABILITY FOR          10240020
         USING IKJEGSMG,MESGBASE             MESSAGE SECTION            10280020
         L     WORK1,TSTSYMWK               ADDR OF SYMWORK IN TCOMTAB  10320020
         LTR   WORK1,WORK1                  IS IT FIRST ENTRY           10360020
         BZ    FIRSTENT                     YES, GO GET CORE-INITILIZE  10400020
         ST    WORK1,N8(SYMWKB)             NO, DO LINKAGE CONVENTIONS  10440020
         ST    SYMWKB,N4(WORK1)                                         10480020
         LR    SYMWKB,WORK1                 ADDR OF SYMWORK, SAVE AREA  10520020
         USING SYMWORK,SYMWKB                                           10560020
         USING INFOBLK,INFOBLKB             BASE FOR INFO BLK DSECT     10600020
*                                                                       10640020
*        BEGIN PROCESSING  -  RESOLVE REQUEST INTO ACTION               10680020
*                                                                       10720020
IKJEGBEG EQU   *                                                        10760020
         ST    SYMB,BASEADDR                MY BASE ADDR IN WORK AREA   10800020
         MVC   CABENDTB(N4),ABENTAB1        SAVE ADDR OF CALLERS STAE   10840020
*                                            ABEND TABLE                10880020
         MVC   CALRETRY(N4),TSTRETRY        SAVE CALLERS STAE RETRY ADR 10920020
         MVC   TSTRETRY+N1(N3),RETRYADR     STAE RETRY ADDR TO TCOMTAB  10960020
         LA    WORK1,ABENDTAB               ADDR OF MY ABEND TABLE      11000020
         ST    WORK1,ABENTAB1               INTO TCOMTAB                11040020
         L     WORK1,TSTSTAE                STAE EXIT ADDRESS           11080020
         LA    PARMREG1,STAELIST            ADDRESS OF STAE LIST        11120020
         STAE  (3),CT,PARAM=(9),XCTL=NO,MF=(E,(1))                      11160020
         LTR   RETCODE,RETCODE              WAS STAE SUCCESSFUL         11200020
SMTSTAE  DS    0H                           SMT TESTCASE LABEL          11206020
*                                            INSUFFICIENT CORE TO ISSUE 11212020
*                                            STAE-RC FROM SYM IS 4      11218020
*                                            TESTCASE ID  TTSTC160      11224020
*                                            TESTCASE ID  TEQU4800      11230020
         BNZ   NOCORE                       NO, GO GIVE MESG, RET CODE  11240020
         XC    TSTWHR(N4),TSTWHR            LOADED ADDR FIELD TO 0      11520020
         TM    PDEFLAG3,V80                 IS AN ADDR STRING PASSED    11560020
         BZ    ONWARD1                      NO, GO ON                   11600020
         TM    PDEFLAG4,V80                 IS A SYMBOL PASSED          11640020
         BZ    ONWARD1                      NO, GO ON                   11680020
         TM    PDEFLAG2,V80                 IS SYMBOL QUALIFIED         11690020
         BO    ONWARD1                      YES, SKIP INCORE SYM TAB    11700020
         BAL   RETURN,SINCORES              NO, GO SEARCH INCORE SYMTB  11720020
         LTR   RETCODE,RETCODE              WAS THE SYMBOL FOUND        11760020
         BZ    FOUNDSYM                     YES, GO BUILD ANSWER BLOCK  11800020
ONWARD1  BAL   RETURN,GETINFO               EVALUATE, GET INFO FOR REQ  11840020
         MVC   TSTWHR(N4),LOADNAMA          LOADED ADDR OF MOD          11880020
         TM    WHATPASS,V02                 WAS A SYMBOL PASSED         11920020
         BO    FINDSYM                      YES, GO FIND SYMBOL         11960020
         TM    WHATPASS,V01                 WAS AN OFFSET PASSED        12000020
         BZ    ENTRYPSD                     NO, GO SEARCH USE ENTRYNAME 12040020
         OI    SWSB,V40                     INDICATE SEARCH USE OFFSET  12080020
         BAL   RETURN,FINDCESD              GO RESOLVE CESD REQUEST     12120020
         B     FENTRY                       FOUND ENTRYNAME DISPLACMENT 12160020
*                                           USING ENTRYNAME AS SEARCH   12200020
ENTRYPSD OI    SWSB,V20                     SEARCH USING ENTRYNAME      12240020
         BAL   RETURN,FINDCESD              GO RESOLVE CESD REQUEST     12280020
         B     FOFFSET                      FOUND ENTRYNAME USING       12320020
*                                             OFFSET AS THE SEARCH      12360020
         SPACE 3                                                        12400020
*********************************************************************** 12440020
*                                                                     * 12480020
*        THE FOLLOWING SUB ROUTINES ARE SERVICE ROUTINES FOR THE      * 12520020
*        MAIN PROCESSING ROUTINES                                     * 12560020
*                                                                     * 12600020
*********************************************************************** 12640020
         SPACE 2                                                        12680020
*                                                                       12720020
*        THIS  ROUTINE FILLS IN THE PDE AFTER A SUCCESSFUL SEARCH       12760020
*        FOR AN ENTRYNAME USING AN OFFSET AS THE SEARCH ARGUMENT        12800020
*                                                                       12840020
FENTRY   LA    WORK1,ENTRYNAM               ADDR OF FOUND ENTRYNAME     12880020
         ST    WORK1,PDEENADD               RETURN IN THE PASSED PDE    12920020
         LA    WORK1,N8                     LENGTH OF PASSED ENTRYNAME  12960020
         STH   WORK1,PDELEN2                RETURN IN THE PASSED PDE    13000020
         OI    PDEFLAG2,V80                 INDICATE ENTRYNAME FOUND    13040020
         SR    RETCODE,RETCODE              SUCCESSFUL RET CODE=0       13080020
         B     TOCALLER                     GO RETURN TO CALLER         13120020
*                                                                       13160020
*        THIS  ROUTINE FILLS IN THE PDE AFTER A SUCCESSFUL SEARCH       13200020
*        FOR A LOADED ADDRESS USING AN ENTRYNAME AS THE SEARCH ARGUMENT 13240020
*                                                                       13280020
FOFFSET  L     WORK1,LOADNAMA               LOADED ADDR OF MODULE       13320020
         A     WORK1,ENTRNAMD               PLUS DISPL OF ENTRYNAME     13360020
         ST    WORK1,PDEUWORD               RETURN IN PASSED PDE        13400020
         SR    RETCODE,RETCODE              SUCCESSFUL RET CODE=0       13440020
         B     TOCALLER                     GO RETURN TO CALLER         13480020
*                                                                       13520020
*        THIS ROUTINE CHECKS THE ATTENTION AND LOGON/LOGOFF ECBS.  IF   13560020
*        THEY HAVE BEEN POSTED, SYM RETURNS TO ITS CALLER WITH A        13600020
*        RETCODE OF 16.  IF NOT THIS ROUTINE RETURNS TO ITS CALLER      13640020
*                                                                       13680020
CHECKECB L     WORK1,ECBTMPA                ADDRESS OF ATTENTION ECB    13720020
         TM    N0(WORK1),V40                HAS ATTENTION ECB BEEN POST 13760020
SMTATTN  DS    0H                           SMT TESTCASE LABEL          13768020
*                                            ATTN DURING SYM PROCESSING 13776020
*                                            RC FROM SYM IS 16          13784020
*                                            TESTCASE ID  TTSTC040      13792020
         BO    CODE16                       YES, RET TO CALLER          13800020
         L     WORK1,ECBLOG                 ADDR OF LOGON/LOGOFF ECB    13840020
         TM    N0(WORK1),V40                HAS LOGON/LOGOFF BEEN POSTD 13880020
         BCR   ZERO,RETURN                  NO, GO BACK TO WHAT YOU     13920020
*                                            WERE DOING                 13960020
CODE16   LA    RETCODE,N16                  REQ TO END, RETCODE=16      14000020
         B     TOCALLER                     GO RETURN TO CALLER         14040020
*                                                                       14080020
*        THIS ROUTINE GIVES AN UNAVAILABLE CORE MESSAGE                 14120020
*                                                                       14160020
NOCORE   EQU   *                                                        14200020
         LA    PARMREG1,NOCOREMG            ADDR OF POINTER TO MESG     14240020
         BAL   RETURN,TERMIO                GO PUT MESG TO TERMINAL     14280020
         LA    RETCODE,N4                   RETURN CODE IS 4            14320020
         B     TOCALLER                     GO RETURN TO CALLER         14360020
*                                                                       14400020
*        THIS IS THE STAE RETRY ROUTINE.                                14440020
*                                                                       14480020
STAERTRY EQU   *                                                        14520020
         L     TCOMTABB,CVTPTR              ADDRESS OF CVT              14560020
         L     TCOMTABB,CVTTCBP-CVT(TCOMTABB)   NEW, CURRENT TCBS       14600020
         L     TCOMTABB,N4(TCOMTABB)        CURRENT TCB IS TEST TCB     14640020
         L     TCOMTABB,TCBTRN-TCB(TCOMTABB)    ADDRESS OF TCOMTAB      14680020
         L     SYMWKB,TSTSYMWK              ADDR OF MY WORK AREA-TCOMTB 14720020
         L     SYMB,BASEADDR                MY BASE REG FROM WORK ARA   14760020
         LTR   PARMREG0,PARMREG0            DID STAE SUCCESSFULLY GET   14800020
         BNZ   DAIRCORE                     NO, GO SEE IF DAIR PARM COR 14840020
         FREEMAIN  R,LV=N104,A=(PARMREG1),SP=N0  FREE STAE CORE         14880020
DAIRCORE EQU   *                                                        14920020
         TM    SWSC,V40                     CORE FOR DAIR PARM LIST     14960020
         BZ    CODE20                       NO, GO GIVE RET CODE=20     15000020
         L     PARMREG1,ADAIRCOR            YES, GET ADDR OF GOTTEN COR 15040020
         FREEMAIN   R,LV=N100,A=(PARMREG1),SP=N1    FREE DAIR PARM LIST 15080020
         NI    SWSC,VBF                     TURN DAIR CORE SWITCH OFF   15120020
CODE20   EQU   *                                                        15160020
         LA    RETCODE,N20                  STAE ENTRY RET CODE         15200020
         B     TOCALLER                     GO RETURN                   15240020
*                                                                       15280020
*        THIS ROUTINE LINKS TO THE TERMINAL I/O ROUTINE TO OUTPUT       15320020
*        ERROR MESSAGES TO THE TERMINAL                                 15360020
*                                                                       15400020
TERMIO   EQU   *                                                        15440020
         TM    TSTFLGS3,SYMMESG             SHOULD WE PRINT A MESSAGE   15520020
         BCR   ONES,RETURN                  NO, RETURN TO CALLER        15560020
         TM    WHATPASS,V01                 WAS AN OFFSET PASSED        15570020
         BCR   ONES,RETURN                  YES, RETURN, NO MESSAGE     15580020
IOERROUT EQU   *                                                        15600020
         MVC   PDEUWORD(N4),N4(PARMREG1)    PASS BACK ADDR OF 2ND LEV   15640020
         ST    RETURN,TERMIO14              SAVE RETURN ADDRESS         15680020
         LNR   PARMREG1,PARMREG1            INDICATE TERMINAL MESSAGE   15720020
         L     RETCODE,TPUTADDR             ADRESS OF TEST I/O RT       15760020
         BALR  RETURN,RETCODE               GO PUT OUT ERROR MESG       15800020
         LA    WORK1,N16                    ATTENTION RETURN CODE       15810020
         CR    RETCODE,WORK1                ATTENTION OR ABEND RET CODE 15820020
         BNL   TOCALLER                     YES, GO PASS IT TO CALLER   15830020
         L     RETURN,TERMIO14              RETURN ADDRESS              16080020
         BR    RETURN                       RETURN TO CALLER            16120020
*                                                                       16160020
*        THIS ROUTINE RETURNS TO THE CALLER OF IKJEGSYM                 16200020
*                                                                       16240020
TOCALLER EQU   *                                                        16280020
         MVC   TSTRETRY(N4),CALRETRY        RESTORE CALLERS STAE RETRY  16320020
         MVC   ABENTAB1(N4),CABENDTB        RESTORE CALLERS ABEND TABLE 16360020
         L     SYMWKB,N4(SYMWKB)            ADDR OF CALLERS SAVE AREA   16400020
TOCALL   EQU   *                                                        16410020
         RETURN    (14,12),,RC=(15)                                     16440020
         SPACE 3                                                        16480020
*********************************************************************** 16520020
*                                                                     * 16560020
*        THIS SUB-ROUTINE ANALYZES THE REQUEST AND GATHERS ALL INFO   * 16600020
*        AVAILIABLE ABOUT THE MODULE INVOLVED.                        * 16640020
*                                                                     * 16680020
*********************************************************************** 16720020
         SPACE 2                                                        16760020
GETINFO  XC    WHATPASS(N3),WHATPASS        SET SWITCHES TO ZERO        16800020
         LA    INFOBLKB,TINFOBLK            ADDR OF TEMP INFO BLOCK     16840020
         MVI   LOADNAME,V40                 BLANK TO TEMP INFO BLOCK    16880020
         MVC   LOADNAME+N1(N23),LOADNAME    CHAR INFO TO BLANKS         16920020
         XC    LOADNAMA(N32),LOADNAMA       OTHER INFO TO ZEROES        16960020
*                                                                       17000020
*        ANALYZE THE PASSED INFORMATION AND REFLECT THE ARGUMENT FORM   17040020
*                                                                       17080020
         TM    PDEFLAG3,V80                 IS AN ADDRESS STRING PASSED 17120020
         BZ    NOADDRST                     NO, GO CHECK FUTHER         17160020
         TM    PDEFLAG4,V80                 IS ADDR STRING A SYM REQ    17200020
         BZ    OFFSETRQ                     NO, GO CHECK FOR OFFSET     17240020
         OI    WHATPASS,VE2                 INDICATE SYMBOL PASSED AND  17280020
*                                            ARGUMENT FORM IS           17320020
*                                            LOADNAME.ENTRYNAME.SYMBOL  17360020
         MVC   PSYMBOL(N8),BLANKS           CLEAR PASSED SYMBOL FIELD   17400020
         LH    WORK1,PDELEN3                LENGTH OF SYMBOL            17440020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     17480020
         LA    WORK2,PSYMBOL                MOVE TO PASSED SYMBOL FIELD 17520020
         L     WORK3,PDEASADD               MOVE FROM LOCATION          17560020
         EX    WORK1,MOVEINST               MOVE SYMBOL TO PSYMBOL      17600020
         B     MODINFO                      GO RESOLVE STATUS OF MODULE 17640020
OFFSETRQ EQU   *                                                        17680020
         OI    WHATPASS,V91                 INDICATE OFFSET PASSED AND  17760020
*                                            THE ARGUMENT FORM IS       17800020
*                                            LOADNAME    OFFSET         17840020
         XC    POFFSET(N4),POFFSET          OFFSET FIELD TO ZEROES      17880020
         LH    WORK1,PDELEN3                LENGTH OF OFFSET            17920020
         LA    WORK2,POFFSET                MOVE TO LOCATION            17960020
         LA    WORK4,N4                     NO. OF BYTES IN A WORD      18000020
         SR    WORK4,WORK1                  NO. OF INDEX BYTES-ALIGN    18040020
         AR    WORK2,WORK4                  OFFSET IN INFO BLOCK        18080020
         L     WORK3,PDEASADD               MOVE FROM LOCATION          18120020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     18160020
         EX    WORK1,MOVEINST               MOVE OFFSET TO POFFSET      18200020
         B     MODINFO                      GO RESOLVE STATUS OF MODULE 18240020
NOADDRST OI    WHATPASS,VC0                 INDICATE ARGUMENT IS        18280020
*                                            LOADNAME.ENTRYNAM          18320020
*                                                                       18360020
*        BUILD AN INFO BLOCK REFLECTING THE MODULE PRESENTLY WORKING    18400020
*        WITH                                                           18440020
*                                                                       18480020
MODINFO  TM    WHATPASS,VC0                 IS ARGUMENT L.E OR JUST L   18520020
         BO    LE                           ARGUMENT IS L.E, GO RESOLVE 18560020
         TM    PDEFLAG1,V80                 ARGUMENT=L, IS IT PASSED    18600020
         BZ    USECURR                      NO, GO GET CURRENT LOADNAME 18640020
         OI    WHATPASS,V08                 INDICATE LOADNAME PASSED    18680020
         LH    WORK1,PDELEN1                LENGTH OF PASSED LOADNAME   18720020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     18760020
         LA    WORK2,TINFOBLK               MOVE TO TEMP INFO BLOCK     18800020
         L     WORK3,PDELNADD               MOVE FROM LOCATION          18840020
         EX    WORK1,MOVEINST               MOVE ENTRYNAME TO INFO BLK  18880020
         CLC   TINFOBLK(N8),TSTCURLD        IS IT THE CURRENT LOADNAME  18920020
         BE    USECURR                      YES, GO USE CURRENT L       18960020
         B     FILLBLK                      GO FILL IN TEMP BLOCK       19000020
LE       TM    PDEFLAG2,V80                 IS ENTRYNAME PASSED         19040020
         BZ    USECURR                      NO, GO USE CURRENT L.E      19080020
         OI    WHATPASS,V04                 INDICATE ENTRYNAME PASSED   19120020
         LH    WORK1,PDELEN2                LENGTH OF PASSED ENTRYNAME  19160020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     19200020
         LA    WORK2,ENTRYNAM               MOVE TO LOCATION IN INFO BK 19240020
         L     WORK3,PDEENADD               MOVE FROM LOCATION          19280020
         EX    WORK1,MOVEINST               MOVE ENTRYNAME TO TEMP INFO 19320020
         TM    PDEFLAG1,V80                 IS LOADNAME PASSED          19360020
         BO    ONWARD01                     YES, GO MOVE TO INFO BLK    19400020
         MVC   LOADNAME(N8),TSTCURLD        NO, USE CURRENTLY QUALIFIED 19440020
         B     ONWARD02                     GO ON                       19480020
ONWARD01 LH    WORK1,PDELEN1                LENGTH OF PASSED LOADNAME   19520020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     19560020
         L     WORK3,PDELNADD               ADDR OF PASSED LOADNAME     19600020
         LA    WORK2,LOADNAME               MOVE TO LOCATION IN INFO BK 19640020
         EX    WORK1,MOVEINST               MOVE LOADNAME TO INFO BLOCK 19680020
         OI    WHATPASS,V08                 INDICATE LOADNAME PASSED    19720020
ONWARD02 CLC   TSTCURLD(N16),TINFOBLK       IS IT CURRENT L.E           19760020
         BE    USECURR                      YES, GO USE CURRENT L.E     19800020
         LA    INFOBLKB,TINFOBLK            USE TEMP BLK FOR BASE       19840020
         B     FILLBLK                      GO FILL IN TEMP BLOCK       19880020
USECURR  LA    INFOBLKB,CINFOBLK            USE CURRENT INFO BLOCK      19920020
         CLC   TSTCURLD(N16),CINFOBLK       IS CURR L.E KNOWN BY SYM    19960020
         BNE   GETCURR                      NO, GO CLEAR AND RE-BUILD   20000020
         CLC   TCBADDR(N4),PPTCB            CURRENT ON SAME TCB         20040020
         BNE   GETCURR                      NO, GO CLEAR AND RE-BUILD   20080020
         L     WORK1,TSTSYMBA               QUALIFIED SYMBOLIC BASE     20120020
         LTR   WORK1,WORK1                  QUALIFING TO A LOADNAME     20160020
         BCR   NOTZERO,RETURN               NO, CURR OK, RET TO CALLER  20200020
GETCURR  MVC   DDNAME(N8),BLANKS            CLEAR DDNAME FIELD          20240020
         MVC   CINFOBLK(N16),TSTCURLD       GET CURRENT L.E             20280020
         XC    LOADNAMA(N32),LOADNAMA       OTHER INFO TO ZEROES        20320020
*                                                                       20360020
*        SEARCH THE INFO BLOCKS CREATED BY THE TESTRAN SVC 61 (IN DEC)  20400020
*                                                                       20440020
FILLBLK  L     WORK1,TSTTRN                 ADDR OF FIRST SVC SAVE INFO 20480020
         LTR   WORK1,WORK1                  IS THEIR A TCB CNTRL BLK    20520020
*                                            FOR THE SVCINFO BLK CHAIN  20560020
         BZ    NOSVCINF                     NO SVCINFO, GO CHECK RB     20600020
         ST    RETURN,SVCBLK14              SAVE RET ADDR IN MAIN RT    20640020
         L     WORK2,PPTCB                  ADDR OF CURR QUALIFIED TCB  20680020
CURRTCB1 EQU   *                                                        20720020
         C     WORK2,N4(WORK1)              IS THIS TCB CNTRL BLK FOR   20760020
*                                            THE CURR QUALIFIED TCB     20800020
         BE    CURRTCB2                     YES, GO SET SEARCH SVC BLKS 20840020
         L     WORK1,N0(WORK1)              NEXT TCB CNTRL BLK ON CHAIN 20880020
         LTR   WORK1,WORK1                  IS THEIR ANYMORE            20920020
         BNZ   CURRTCB1                     YES, GO CHECK FOR CURR TCB  20960020
         B     VERFYTCB                     NO, GO SEARCH ALL VALID TCB 21000020
CURRTCB2 EQU   *                                                        21040020
         LR    WORK5,WORK1                  ADDR OF TCB CNTRL BLK FOR   21080020
*                                            CURRENT QUALIFIED TCB      21120020
         BAL   RETURN,VIEWSVC1              GO SEARCH SVCINFO BLK CHAIN 21160020
*                                                                       21200020
*        GET A TCB ADDRESS FROM THE TCB CNTRL BLK CHAIN FOR EACH        21240020
*        SVCINFO BLOCK CHAIN, VERIFY THE TCB STILL EXISTS AND SEARCH    21280020
*        THE SVCINFO BLOCKS USING LOADNAME AS THE SEARCH ARGUMENT       21320020
*                                                                       21360020
VERFYTCB EQU   *                                                        21400020
         L     WORK1,TSTTRN                 HEAD OF TCB CNTRL BLK CHAIN 21440020
VERFYBEG EQU   *                                                        21480020
         L     WORK2,TSTTCB                 ADDRESS OF TEST TCB         21520020
         LA    WORK3,N0(WORK2)              CLEAR HIGH ORDER BYTE, SAVE 21560020
VERFYDAU EQU   *                                                        21600020
         L     WORK4,TCBLTC-TCB(WORK2)      ADDRESS OF DAUGHTER         21640020
         LA    WORK4,N0(WORK4)              CLEAR HIGH ORDER BYTE       21680020
         LTR   WORK4,WORK4                  IS THEIR A DAUGHTER         21720020
         BNZ   CHKTCB                       YES, GO SEE IF ONE WE WANT  21760020
VERFYSIS EQU   *                                                        21800020
         L     WORK4,TCBNTC-TCB(WORK2)      ADDRESS OF SISTER           21840020
         LA    WORK4,N0(WORK4)              CLEAR HIGH ORDER BYTE       21880020
         LTR   WORK4,WORK4                  IS THEIR A SISTER           21920020
         BNZ   CHKTCB                       YES, GO SEE IF ONE WE WNAT  21960020
VERFYMOM EQU   *                                                        22000020
         L     WORK2,TCBOTC-TCB(WORK2)      ADDRESS OF MOTHER           22040020
         LA    WORK2,N0(WORK2)              CLEAR HIGH ORDER BYTE       22080020
         CR    WORK2,WORK3                  IS MOTHER THE TEST TCB      22120020
         BNE   VERFYSIS                     NO, GO CHECK FOR A SISTER   22160020
         B     VERFYEND                     YES, TCB FROM TCB CNTRL BLK 22200020
*                                            HAS BEEN DETACHED, GO GET  22240020
*                                            NEXT TCB CNTRL BLK         22280020
CHKTCB   EQU   *                                                        22320020
         C     WORK4,N4(WORK1)              IS THIS THE TCB WE WANT     22360020
         BE    TCBMATCH                     YES, GO SET UP TO SEARCH    22400020
*                                            SVC BLKS FOR THIS TCB      22440020
         LR    WORK2,WORK4                  FIND NEXT TCB UNDER TEST    22480020
         B     VERFYDAU                     LOOP UNTIL MATCH OR ALL TCB 22520020
*                                            UNDER TEST HAVE BEEN CHKED 22560020
TCBMATCH EQU   *                                                        22600020
         LR    WORK5,WORK1                  ADDR OF TCB CNTRL BLK       22640020
         BAL   RETURN,VIEWSVC1              GO SEARCH SVC BLK CHAIN     22680020
VERFYEND EQU   *                                                        22720020
         L     WORK1,N0(WORK1)              ADDR OF NEXT TCB CNTRL BLK  22760020
         LTR   WORK1,WORK1                  IS THEIR ANOTHER CHAIN      22800020
         BNZ   VERFYBEG                     YES, GO VERFIY ITS TCB      22840020
         L     RETURN,SVCBLK14              RESTORE RET ADDR IN MAIN RT 22880020
         B     NOSVCINF                     GO SEARCH RB CHAIN          22920020
VIEWSVC1 EQU   *                                                        22960020
         L     WORK5,N8(WORK5)              ADDR OF FIRST BLK ON CHAIN  23000020
         USING SVCINFO,WORK5                                            23040020
VIEWSVC2 EQU   *                                                        23080020
         CLC   LOADNAME(N8),LMODNAME        IS THIS THE SVC BLOCK       23120020
         BE    FOUND1                       YES, GO EXTRACT INFORMATION 23160020
         L     WORK5,NEXTBLK                NO, ADDR OF NEXT SVC BLOCK  23200020
         LTR   WORK5,WORK5                  IS THEIR ANOTHER SVC BLOCK  23240020
         BNZ   VIEWSVC2                     YES, GO SEE IF ITS THE ONE  23280020
         BR    RETURN                       NO, RETURN TO CALLER        23320020
FOUND1   EQU   *                                                        23360020
         L     RETURN,SVCBLK14              ADDR OF MAIN ROUTINE CALLER 23400020
         MVC   LOADNAMA(N4),LMLADDR         GET MAIN STORAGE ADDRESS    23440020
         MVC   ATTRIBUT(N4),LMATTRIB        GET MEMBER ATTRIBUTES       23480020
         MVC   TCBADDR(N4),LMTCB            GET LOADNAME'S TCB ADDRESS  23520020
         MVC   POINTER(N4),BEGTTR           GET TTR OF BEGIN OF MEMBER  23560020
         OI    MODSWS,V90                   INDICATE IT IS A LOAD MOD   23600020
*                                            AND THE TTSVC HAS OPERATED 23640020
         TM    LMFLAGS,V80                  DO WE HAVE A DDNAME FOR PDS 23680020
         BZ    SEELIB                       NO, GO SEE IF LIB=LINKLIB   23720020
         MVC   DDNAME(N8),LMDDNAME          GET DDNAME ALLOCATING PDS   23760020
         OI    MODSWS,V04                   YES, INDICATE DDNAME KNOWN  23800020
         BR    RETURN                       RETURN TO CALLER            23840020
SEELIB   EQU   *                                                        23880020
         TM    LMFLAGS,V40                  IS DATASET LINKLIB          23920020
         BCR   ONES,RETURN                  YES, CAN ALLOCATE, RETURN   23960020
         LA    RETCODE,N44                  NO, SECOND LEV MESG NUMBER  24000020
         B     NOFIND                       GO GIVE MESG, RETURN CODE   24040020
         DROP  WORK5                                                    24080020
*                                                                       24120020
*        SEARCH THE CDE CHAIN AND USE CDE AND EXTENT LIST INFO          24160020
*                                                                       24200020
NOSVCINF EQU   *                                                        24240020
         L     WORK3,PPRB                   ADDRESS OF CURRENT P/P RB   24280020
         L     WORK3,RBCDE-RBSECT(WORK3)    ADDRESS OF CDE              24320020
         CLC   N8(N8,WORK3),LOADNAME        IS THIS THE PASSED LOADNAME 24360020
         BE    FOUND2                       YES, GO EXTRACT INFORMATION 24400020
CDECHAIN EQU   *                                                        24440020
         SR    WORK1,WORK1                  CLEAR REGISTER TO ZERO      24480020
         L     WORK3,TSTTCB                 ADDRESS OF TEST TCB         24520020
         L     WORK3,TCBJPQ-TCB(WORK3)      HEAD OF CDE CHAIN           24560020
         LA    WORK3,N0(WORK3)              CLEAR HIGH ORDER BYTE       24600020
CDE1     EQU   *                                                        24640020
         LTR   WORK3,WORK3                  END OF CDE CHAIN            24680020
         BNZ   CDE2                         NO, GO CONTINUE SEARCH      24720020
         LA    RETCODE,N4                   ERROR, LOADNAME NOT FOUND   24760020
         B     NOFIND                       GO SET UP ERROR MESSAGE     24800020
CDE2     EQU   *                                                        24840020
         CLC   N8(N8,WORK3),LOADNAME        IS CDE FOR PASSED LOADNAME  24880020
         BE    FOUND2                       YES, GO EXTRACT INFORMATION 24920020
         L     WORK3,N0(WORK3)              ADDRESS OF NEXT CDE         24960020
         LA    WORK3,N0(WORK3)              CLEAR HIGH ORDER BYTE       25000020
         B     CDE1                         GO CHECK NEXT CDE           25040020
FOUND2   EQU   *                                                        25080020
         TM    N0(WORK3),V04                IS IT A MINOR CDE           25120020
         BZ    XL                           NO, GO GET XL ADDRESS       25160020
         L     WORK3,N20(WORK3)             YES, ADDRESS OF MAJOR CDE   25200020
XL       EQU   *                                                        25240020
         L     WORK2,N20(WORK3)             ADDRESS OF EXTENT LIST      25280020
         L     WORK1,N4(WORK2)              NO. SCATTERED BLOCKS        25320020
         SLL   WORK1,N2                     TIMES NO. BYTES IN A WORD   25360020
         LA    WORK1,N8(WORK1,WORK2)        ADDR OF FIRST LOADED BLOCK  25400020
         MVC   LOADNAMA+N1(N3),N1(WORK1)    MOVE IT TO INFO BLOCK       25440020
         TM    N20(WORK3),V80               IS IT LOADED VIA OS LOADER  25480020
         BO    OSLOADER                     YES, GO EXTRACT INFO        25520020
         OI    MODSWS,V80                   INDICATE IT IS A LOAD MOD   25560020
         BR    RETURN                       RETURN TO CALLER            25600020
OSLOADER CLI   N7(WORK2),V02                IS THEIR MORE EXTENT INFO   25640020
         BCR   LOW,RETURN                   NO, RETURN TO CALLER        25650020
         L     WORK5,N12(WORK2)             LENGTH OF SECOND EXTENT     25720020
         LA    WORK5,N0(WORK5)              CLEAR HIGH ORDER BYTE       25760020
         LTR   WORK5,WORK5                  IS LEN ZERO                 25800020
         BCR   ZERO,RETURN                  YES, RETURN TO CALLER       25840020
         ST    WORK5,CESDTTR                NO, LENGTH OF CESD INFO     25880020
         MVC   POINTER+N1(N3),N5(WORK1)     ADDR OF OS LOADER CESD INFO 25920020
*                                            INTO INFO BLOCK            25960020
         OI    MODSWS,V20                   INDICATE OS LOADER CESD AVA 26000020
         BR    RETURN                       RETURN TO CALLER            26040020
         SPACE 3                                                        26080020
*********************************************************************** 26120020
*                                                                     * 26160020
*        FOR A REQUEST FOR A SYMBOL, THIS ROUTINE SEARCHES SYM RCDS   * 26200020
*        IN THE LOADNAME MEMBER OF A PDS ON SECONDARY STORAGE.        * 26240020
*                                                                     * 26280020
*********************************************************************** 26320020
         SPACE 2                                                        26360020
FINDSYM  EQU   *                                                        26400020
         TM    MODSWS,V80                   IS IT A LOAD MODULE         26440020
         BO    LMOD                         YES, GO CHECK FOR SYM RCDS  26480020
         LA    RETCODE,N8                   NO, NO SYMS WITH OBJ        26520020
         B     NOFIND                       GO GIVE ERROR MESG          26560020
LMOD     EQU   *                                                        26600020
         TM    ATTRIBUT,V10                 WAS MOD LINKEDIT WITH TEST  26640020
         BO    ONWARDA                      YES, GO ON                  26680020
         LA    RETCODE,N20                  LOADNAME LKED, NO TEST PARM 26720020
         B     NOFIND                       NO, SYM CANNOT BE FOUND     26760020
ONWARDA  TM    ATTRIBUT+N1,V04              ARE SYMBOL RCDS PRESENT     26800020
         BO    ONWARDB                      YES, GO ON                  26840020
         LA    RETCODE,N36                  ENTRYNAME NOT ASM WITH TEST 26880020
         B     NOFIND                       NO, SYM CANNOT BE FOUND     26920020
ONWARDB  CLC   TSTCURLD(N16),LOADNAME       IS IT CURR LOADNAME-ENTRYNA 26960020
         BNE   MBASE                        NO, GO CREATE BASE FOR SYMS 27000020
         CLI   ENTRYNAM,V00                 IS CURR E DEFAULTED TO 1ST  27040020
         BNE   CURROK                       NO, GO USE TCOMTAB SYM BASE 27080020
         OI    SWSB,V10                     SEARCH FOR FIRST CSECT      27120020
         BAL   RETURN,FINDCESD              GO GET FIRST CSECT + DISPL  27160020
         MVI   SWSB,V00                     TURN OFF CESD SWITCHES      27200020
         MVC   TSTCURCT(N8),ENTRYNAM        MAKE FIRST CSECT CURRENT    27240020
         L     WORK1,LOADNAMA               GET LOADED ADDRESS          27280020
         A     WORK1,ENTRNAMD               ADD FIRST CSECT'S DISPL     27320020
         ST    WORK1,TSTSYMBA               CURR SYM BASE TO TCOMTAB    27360020
         ST    WORK1,BASEFSYM               ALSO IN CURRENT INFO BLOCK  27400020
         B     SYMBACK1                     GO ON                       27440020
CURROK   MVC   BASEFSYM(N4),TSTSYMBA        YES, SYM BASE FROM TCOMTAB  27480020
         B     SYMBACK1                     GO ON                       27520020
MBASE    CLI   ENTRYNAM,V00                 IS ENTRY DEFAULTED-1ST CSEC 27560020
         BNE   ENTRYPRS                     NO, ENTRYNAME IS PRESENT    27600020
         OI    SWSB,V10                     SEARCH FOR FIRST CSECT      27640020
         BAL   RETURN,FINDCESD              GO GET FIRST CSECT + DISPL  27680020
         MVI   SWSB,V00                     TURN OFF CESD SWITCHES      27720020
ENTRYPRS TM    MODSWS,V40                   IS ENTRYNAME DISPL PRESENT  27760020
         BO    ADDTOLA                      YES, GO CREATE SYM BASE     27800020
         OI    SWSB,V20                     SEARCH USING ENTRYNAME      27840020
         BAL   RETURN,FINDCESD              GO GET DISPL FOR ENTRYNAME  27880020
         MVI   SWSB,V00                     TURN OFF CESD SWITCHES      27920020
ADDTOLA  L     WORK1,LOADNAMA               LOADED ADDR OF MODULE       27960020
         A     WORK1,ENTRNAMD               ADD DISP OF ENTRYNAME       28000020
         ST    WORK1,BASEFSYM               BASE FOR SYMBOL DISPLACMENT 28040020
SYMBACK1 BAL   RETURN,OPENDCB               GO SET UP DCB FOR READ      28080020
         LA    PARMREG1,PDSDCB              ADDR OF DCB FOR POINT       28120020
SMTSYND1 DS    0H                           SMT TESTCASE LABEL          28128020
*                                            ENTER SYNAD ON SYMBOL READ 28136020
*                                            RC FROM SYM IS 12          28144020
*                                            TESTCASE ID  TTSTC150      28152020
         LA    PARMREG0,POINTER             ADDR OF TTR FOR POINT       28160020
         BAL   RETURN,DOPOINT               GO DO POINT                 28200020
READSYM  BAL   RETURN,DOREAD                GO READ SECONDARY STORAGE   28240020
         CLI   BUFFER,V40                   WAS A SYM/ESD RCD READ      28280020
         BE    SYMRCD1                      YES, GO CHECK FOR GOOD SYM  28320020
         TM    SWSA,V80                     WAS A PART ENTRY SAVED      28360020
         BZ    NOSYM1                       NO, GO GIVE UNRESOLVED CODE 28400020
         BAL   RETURN,INPARTAL              YES, GO CHECK PART ENTRY    28440020
NOSYM1   EQU   *                                                        28480020
         TM    SWSA,V10                     DID WE FIND ENTRYNAME       28520020
         BZ    NOTASM1                      NO, GO GIVE NOT ASEM CODE   28560020
         LA    RETCODE,N24                  YES, SYM NOT FOUND          28600020
         B     NOFIND                       GO GIVE RET CODE, MESG      28640020
NOTASM1  LA    RETCODE,N36                  ENTRYNAME NOT ASM WITH TEST 28680020
         B     NOFIND                       GO GIVE RET CODE, MESG      28720020
SYMRCD1  EQU   *                                                        28760020
         CLI   BUFFER+N1,V00                IS IT A GOOD SYM/ESD RECORD 28800020
         BE    SETUPSYM                     YES, GO SET UP TO ANALYZE   28840020
         TM    SWSA,V80                     NO, WAS A PART ENTRY SAVED  28880020
         BZ    READSYM                      NO, GO READ ANOTHER RECORD  28920020
         BAL   RETURN,INPARTAL              YES, GO CHECK PART ENTRY    28960020
         B     READSYM                      GO READ ANOTHER RECORD      29000020
*                                                                       29040020
*        THIS  ROUTINE ANALYZES A SYMBOL RECORD READ FROM SECONDARY     29080020
*        STORAGE. WORK1 POINTS TO THE BEGINNING OF THE LOGICAL RECORD,  29120020
*        WORK2 POINTS TO THE END OF THE PHYSICAL RECORD, WORK3 POINTS   29160020
*        TO THE CURRENT POSITION IN THE PHYSICAL RECORD, WORK4 WILL     29200020
*        CONTAIN THE NUMBER OF REMAINING DATA BYTES IN THE PRESENT      29240020
*        LOGICAL RECORD AND WORK5 WILL CONTAIN THE NUMBER OF BYTES IN   29280020
*        THE CURRENT ENTRY.                                             29320020
*                                                                       29360020
SETUPSYM EQU   *                                                        29400020
         LA    WORK1,BUFFER                 ADDR BEG OF PHSYICAL RCD    29440020
         LH    WORK2,N2(WORK1)              LENGTH OF PHSYICAL RECORD   29480020
         LA    WORK2,N4(WORK1,WORK2)        ADDR OF END OF PHSYICAL RCD 29520020
         LA    WORK3,N4(WORK1)              ADDR OF FIRST LOGICAL RCD   29560020
         LR    WORK1,WORK3                  ADDR OF FIRST LOGICAL RCD   29600020
ISITASYM CLI   N1(WORK3),LSYMRCD            IS THIS A LOGICAL SYM RCD   29640020
         BE    ONWARDS1                     YES, GO ON                  29680020
         TM    SWSA,V80                     WAS A PART ENTRY SAVED      29720020
         BZ    NOPART                       NO, GO ON                   29760020
         BAL   RETURN,INPARTAL              YES, GO CHECK PART ENTRY    29800020
NOPART   EQU   *                                                        29840020
         LA    WORK3,N80(WORK1)             ADDR OF NEXT LOGICAL RCD    29880020
         LR    WORK1,WORK3                  ADDR OF CURRENT LOGICAL RCD 29920020
         CR    WORK3,WORK2                  IS IT END OF PHSYICAL RCD   29960020
         BNL   READSYM                      YES, GO READ ANOTHER        30000020
         B     ISITASYM                     NO, GO CHECK NEXT LOGICAL   30040020
ONWARDS1 LH    WORK4,N10(WORK3)             LEN DATA IN LOGICAL RCD     30080020
         LA    WORK3,N16(WORK3)             ADDR OF FIRST ENTRY IN RCD  30120020
         TM    SWSA,V80                     WAS LAST ENTRY CONTINUED    30160020
         BO    ALIGNSYM                     YES, GO ALIGN ENTRY         30200020
BACKSYM1 LA    PARMREG1,N20                 MAXIUM ENTRY LENGTH         30240020
         CR    WORK4,PARMREG1               COULD NEXT ENTRY OVERFLOW   30280020
         BL    SAVEPART                     YES, SAVE POSSIBLE PART ENT 30320020
         BAL   RETURN,ENTRYLEN              GO CALCULATE SYM ENTRY LEN  30360020
         TM    N0(WORK3),V80                IS IT A DATA TYPE ENTRY     30400020
         BO    DATATYPE                     YES, GO CHECK               30440020
         BAL   RETURN,NOTDATA               NO, GO ANALYZE NON-DATA     30480020
         B     ENDENTRY                     GO END THIS ENTRY           30520020
DATATYPE TM    SWSA,V40                     SHOULD WE ANALZE ENTRY      30560020
         BZ    ENDENTRY                     NO, GO BYPASS THIS ONE      30600020
         TM    N0(WORK3),V08                IS A NAME PRESENT           30640020
         BO    ENDENTRY                     NO, DO NOT ANALYZE          30680020
         STM   WORK1,WORK3,WORKSAV2         SAVE POINTERS               30720020
         MVC   WAREA3(N8),BLANKS            CLEAR WORK AREA             30760020
         IC    WORK1,N0(WORK3)              GET ORGANIZATION BYTE       30800020
         LA    WORK2,N15                    CREATE 'AND' BYE - 0F       30840020
         NR    WORK1,WORK2                  LEN OF SYMBOL-1             30880020
         LA    WORK2,WAREA3                 MOVE TO LOCATION IN SYMWORK 30920020
         LA    WORK3,N4(WORK3)              ADDRESS OF SYMBOL TO MOVE   30960020
         EX    WORK1,MOVEINST               MOVE SYM TO WORK AREA       31000020
         LM    WORK1,WORK3,WORKSAV2         RESTORE POINTERS            31040020
         CLC   WAREA3(N8),PSYMBOL           IS THIS THE SYMBOL          31080020
         BE    FOUNDSYM                     YES, GO CREATE SYMINFO BLK  31120020
ENDENTRY AR    WORK3,WORK5                  ADDR OF NEXT ENTRY          31160020
         SR    WORK4,WORK5                  LEN OF DATA REMAIN IN RCD   31200020
         LTR   WORK4,WORK4                  IS IT END OF A LOGICAL RCD  31240020
         BP    BACKSYM1                     NO, GO LOOK AT NEXT ENTRY   31280020
         LA    WORK3,N80(WORK1)             YES, ADDR OF NEXT LOGICAL   31320020
         LR    WORK1,WORK3                  ADDR OF CURRENT LOGICAL RCD 31360020
         CR    WORK3,WORK2                  IS IT END OF PHSYICAL RCD   31400020
         BNL   READSYM                      YES, GO READ NEXT PHSYICAL  31440020
         B     ISITASYM                     NO, GO LOOK AT NEXT LOGICAL 31480020
*                                                                       31520020
*        THIS ROUTINE WILL ALIGN A LOGICAL SYM RCD.  PARTIAL SYM INFO   31560020
*        FROM THE PREVIOUS LOGICAL RCD WILL BE PLACED IN FRONT OF THIS  31600020
*        PRESENT SYM RECORD.                                            31640020
*                                                                       31680020
ALIGNSYM STM   WORK1,WORK3,WORKSAVE         SAVE POINTERS               31720020
         L     WORK1,PENTRYLN               LEN OF PART TO ALIGIN       31760020
         AR    WORK4,WORK1                  NEW LEN OF DATA IN LOGICAL  31800020
         LR    WORK2,WORK3                  PRESENT ENTRY ADDRESS       31840020
         SR    WORK2,WORK1                  NEW PRESENT ENTRY ADDRESS   31880020
         LA    WORK3,PARTENTY               MOVE FROM LOCATION          31920020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     31960020
         EX    WORK1,MOVEINST               PREFIX LOG RCD WITH PARTENT 32000020
         LR    WORK3,WORK2                  NEXT ENTRY ADDRESS          32040020
         LM    WORK1,WORK2,WORKSAVE         RESTORE BEGIN-END POINTERS  32080020
         NI    SWSA,V7F                     TURN PARTIAL LAST ENTRY OFF 32120020
         B     BACKSYM1                     GO ANALYZE SYMBOL           32160020
*                                                                       32200020
*        THIS ROUTINE WILL CALCULATE THE LENGTH OF A SYM ENTRY          32240020
*                                                                       32280020
ENTRYLEN STM   WORK1,WORK3,WORKSAV2         SAVE POINTERS               32320020
         LA    WORK5,N4                     BASIC SYM LENGTH-ORGANIZATN 32360020
*                                             PLUS DISP FROM CSECT      32400020
         SR    WORK1,WORK1                  INITIAL LEN OF NAME         32440020
         TM    N0(WORK3),V08                IS NAME PRESENT             32480020
         BO    NONAME                       NO, GO ON                   32520020
         IC    WORK1,N0(WORK3)              GET ORGANIZATION BYTE       32560020
         LA    WORK2,N15                    CREATE 'AND' FIELD - 0F     32600020
         NR    WORK1,WORK2                  LEN OF NAME-1               32640020
         LA    WORK1,N1(WORK1)              LENGTH OF NAME              32680020
         AR    WORK5,WORK1                  ENTRY LEN  PLUS NAME LENGTH 32720020
NONAME   TM    N0(WORK3),V80                IS IT A DATA TYPE           32760020
         BO    DATAENTY                     YES, GO CALCULATE LEN       32800020
         TM    N0(WORK3),VF0                IS NON-DATA TYPE A SPACE    32840020
         BM    GOTLEN                       NO, HAVE LEN, GO RETURN     32880020
         LA    WORK5,N1(WORK5)              YES, ADD ALIGN BYTE FIELD   32920020
         B     GOTLEN                       HAVE LENGTH, GO RETURN      32960020
DATAENTY EQU   *                                                        33000020
         LA    WORK5,N1(WORK5)              YES, ADD LEN OF DATA FIELD  33040020
         TM    N0(WORK3),V40                IS THEIR ANY MULTIPLICITY   33080020
         BZ    NOMULTIP                     NO, GO ON                   33120020
         LA    WORK5,N3(WORK5)              ENTRY LEN PLUS LEN M FIELD  33160020
NOMULTIP TM    N0(WORK3),V10                IS A SCALE FIELD PRESENT    33200020
         BZ    NOSCALE                      NO, GO ON                   33240020
         LA    WORK5,N2(WORK5)              ENTRY LEN PLUS LEN S FIELD  33280020
NOSCALE  LA    WORK2,N4(WORK3,WORK1)        ADDR OF DATA FIELD          33320020
         CLI   N0(WORK2),V08                IS LENGTH FIELD 1 OR 2 BYTE 33360020
         BH    ONEBYTE                      LEN FIELD IS ONE BYTE       33400020
         LA    WORK5,N1(WORK5)              ENTRY LEN +2 BYTE LEN FIELD 33440020
ONEBYTE  LA    WORK5,N1(WORK5)              ENTRY LEN +1 BYTE LEN FIELD 33480020
GOTLEN   LM    WORK1,WORK3,WORKSAV2         RESTORE POINTERS            33520020
         BR    RETURN                       GO CHECK NEXT ENTRY         33560020
*                                                                       33600020
*        THIS ROUTINE WILL SAVE A POSSIBLE PARTIAL ENTRY FOR PREFIXING  33640020
*        TO THE NEXT LOGICAL SYM RCD                                    33680020
*                                                                       33720020
SAVEPART STM   WORK1,WORK3,WORKSAVE         SAVE POINTERS               33760020
         ST    WORK4,PENTRYLN               LENGTH OF PART TO SAVE      33800020
         LR    WORK1,WORK4                  LEN OF PART TO SAVE         33840020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     33880020
         LA    WORK2,PARTENTY               MOVE TO LOCATION            33920020
         EX    WORK1,MOVEINST               SAVE PART ENTRY IN SYMWORK  33960020
         OI    SWSA,V80                     SET LAST ENTRY CONTINUED SW 34000020
         LR    WORK5,WORK4                  SET LEN TO REMAIN DATA BYTS 34040020
         LM    WORK1,WORK3,WORKSAVE         RESTORE POINTERS            34080020
         B     ENDENTRY                     GO END LOGICAL RECORD       34120020
*                                                                       34160020
*        THIS ROUTINE WILL HANDLE NON-DATA TYPES AND DECIDE WHEN TO     34200020
*        ANALYZE SYM ENTRIES.                                           34240020
*                                                                       34280020
NOTDATA  STM   WORK1,WORK3,WORKSAV2         SAVE POINTERS       SA55699 34320021
         MVC   WAREA2(N8),BLANKS            BLANK OUT WORK AREA         34360020
         SR    WORK1,WORK1                  CLEAR REG FOR IC INSTRUCTON 34400020
         IC    WORK1,N0(WORK3)              GET ORGANIZATION BYTE       34440020
         STC   WORK1,WAREA3                 SAVE ORGANIZATION BYTE      34480020
         TM    N0(WORK3),V08                IS THEIR A NAME             34520020
         BO    SEETYPE                      NO, GO CHECK NON-DATA TYPE  34560020
         LA    WORK2,N15                    CREATE 'AND' FIELD - 0F     34600020
         NR    WORK1,WORK2                  LEN OF NAME-1               34640020
         LA    WORK2,WAREA2                 MOVE TO LOC IN SYMWORK      34680020
         LA    WORK3,N4(WORK3)              ADDRESS OF SYMBOL TO MOVE   34720020
         EX    WORK1,MOVEINST               MOVE NAME TO A WORK AREA    34760020
         L     WORK3,WKSAVE3A               RESTORE ADDRESS OF ENTRY    34800021
SEETYPE  NI    WAREA3,VF0                   NON-DATA TYPE INFO          34840020
         CLI   WAREA3,V10                   IS IT A CSECT               34880020
         BNE   ISITDSEC                     NO, GO CHECK FOR A DSECT    34920020
         CLC   WAREA2(N8),ENTRYNAM          IS IT THE ENTRYNAME CSECT   34960020
         BNE   NOCHECK                      NO, GO TURN SWS OFF         35000020
         OI    SWSA,V50                     YES, TURN ANALYZE SWITCH ON 35040020
*                                            AND INDICATE SYMS ARE      35080020
*                                            AVAILABLE FOR THIS         35120020
*                                            ENTRYNAME                  35160020
         NI    SWSA,VDF                     TURN DSECT SW OFF           35200020
RNDATA1  LM    WORK1,WORK3,WORKSAV2         RESTORE POINTERS    SA55699 35240021
         BR    RETURN                       GO RETURN TO CALLER         35280020
NOCHECK  NI    SWSA,V9F                     TURN OFF ANALYZE,DSECT SWS  35320020
         B     RNDATA1                      GO BACK                     35360020
ISITDSEC CLI   WAREA3,V20                   IS IT A DSECT               35400020
         BNE   ISASWON                      NO, GO CHECK ANALYZE SWITCH 35440020
         OI    SWSA,V60                     YES, TURN ON ANALYZE,DSECT  35480020
         MVC   WAREA1(N8),WAREA2            SAVE DSECT NAME NOW SEARCH- 35520020
*                                            ING THROUGH                35560020
         B     RNDATA1                      GO RETURN                   35600020
ISASWON  TM    SWSA,V40                     ARE WE ANALYZING            35640020
         BZ    RNDATA1                      NO, RETURN                  35680020
         CLC   WAREA2(N8),PSYMBOL           YES, IS THIS THE SYMBOL     35720020
         BNE   RNDATA1                      NO, RETURN                  35760020
*                                                                       35800020
*        SYMBOL FOUND, BUT NOT DATA TYPE, WORK3 POINTS TO ENTRY,        35840020
*        WORK1 IS LENGTH OF SYMBOL MINUS ONE                            35880020
*                                                                       35920020
         LA    WORK2,N5(WORK3,WORK1)        WORK2 POINT TO DATA FIELD   35960020
         CLI   WAREA3,V40                   IS IT AN INSTRUCTION        36000020
         BNE   CHECKCCW                     NO, GO CHECK FOR A CCW      36040020
         MVI   N0(WORK2),V0C                YES- TYPE IS 0C             36080020
         NI    N0(WORK3),V0F                TURN OFF ANY ERRENOUS BITS  36120020
         MVI   N1(WORK2),V00                CREATE 1 BYTE LEN FIELD=0   36160020
         B     FOUNDSYM                     GO CREATE ANSWER BLOCK      36200020
CHECKCCW CLI   WAREA3,V50                   IS IT A CCW                 36240020
         BNE   DEFAULT                      NO, GO DEFAULT IT           36280020
         MVI   N0(WORK2),V04                YES, - MAKE IT HEX          36320020
         NI    N0(WORK3),V0F                TURN OFF ANY ERRENOUS BITS  36360020
         MVC   N1(N2,WORK2),CCWLENFD        LENGTH FIELD FOR A CCW      36400020
         B     FOUNDSYM                     GO CREATE ANSWER BLOCK      36440020
DEFAULT  NI    N0(WORK3),V0F                TURN OFF ANY ERRENOUS BITS  36480020
         MVI   N0(WORK2),V04                MAKE IT HEX                 36520020
         MVC   N1(N2,WORK2),DEFLENFD        LEN FIELD FOR DEFAULT       36560020
         B     FOUNDSYM                     GO BUILD ANSWER BLOCK       36600020
*                                                                       36640020
*        THIS ROUTINE WILL SEARCH A PARTIAL SAVED ENTRY FROM A          36680020
*        LOGICAL SYM RECORD FROM SECONDARY STORAGE                      36720020
*                                                                       36760020
INPARTAL EQU   *                                                        36800020
         STM   WORK1,WORK3,WORKSAVE         SAVE POINTERS               36840020
         ST    RETURN,PART14                SAVE RETURN ADDRESS         36880020
         NI    SWSA,V7F                     TURN PARTIAL ENTRY SW OFF   36920020
         LA    WORK3,PARTENTY               ADDRESS OF SAVED PART ENTRY 36960020
         L     WORK4,PENTRYLN               LEN OF SAVED PARTIAL ENTRY  37000020
         LA    WORK2,N0(WORK3,WORK4)        END OF SAVED PART ENTRY     37040020
LENCHECK BAL   RETURN,ENTRYLEN              GO CALCUATE LEN NEXT ENTRY  37080020
         CR    WORK4,WORK5                  IS THEIR A COMPLETE ENTRY   37120020
         BNL   LOOKAT                       YES, GO ON                  37160020
         LM    WORK1,WORK3,WORKSAVE         RESTORE POINTERS            37200020
         L     RETURN,PART14                NO, GET RETURN ADDRESS      37240020
         BR    RETURN                       RETURN TO CALLER            37280020
LOOKAT   TM    N0(WORK3),V80                IS IT A DATA TYPE           37320020
         BO    TYPEDATA                     YES, GO CHECK FUTHER        37360020
         BAL   RETURN,NOTDATA               NO, GO CHECK NON-DATA TYPE  37400020
         B     ENTRYEND                     GO END THIS ENTRY           37440020
TYPEDATA TM    SWSA,V40                     SHOULD WE ANALYZE ENTRY     37480020
         BZ    ENTRYEND                     NO, GO END ENTRY            37520020
         TM    N0(WORK3),V08                IS A NAME PRESENT           37560020
         BO    ENTRYEND                     NO, GO, WE NEED A NAME      37600020
         STM   WORK1,WORK3,WORKSAV2         SAVE POINTERS               37640020
         MVC   WAREA3(N8),BLANKS            CLEAR WORK AREA             37680020
         SR    WORK1,WORK1                  CLEAR REG FOR IC INSTR      37720020
         IC    WORK1,N0(WORK3)              GET ORGANIZATION BYTE       37760020
         LA    WORK2,N15                    CREATE 'AND' BYTE - 0F      37800020
         NR    WORK1,WORK2                  LEN OF SYMBOL-1             37840020
         LA    WORK2,WAREA3                 MOVE TO LOCATION            37880020
         LA    WORK3,N4(WORK3)              ADDRESS OF SYMBOL TO MOVE   37920020
         EX    WORK1,MOVEINST               MOVE SYM TO WORK AREA       37960020
         LM    WORK1,WORK3,WORKSAV2         RESTORE POINTERS            38000020
         CLC   WAREA3(N8),PSYMBOL           IS THIS THE SYMBOL REQUESTD 38040020
         BE    FOUNDSYM                     YES, GO CREATE ANSWER BLOCK 38080020
ENTRYEND AR    WORK3,WORK5                  ADDR OF NEXT ENTRY          38120020
         SR    WORK4,WORK5                  LEN OF DATA REMAIN IN RCD   38160020
         CR    WORK3,WORK2                  ANY MORE ENTRIES IN PARTIAL 38200020
         BL    LENCHECK                     YES, GO CHECK FOR NEXT ONE  38240020
         L     RETURN,PART14                NO, SYMBOL NOT FOUND        38280020
         LM    WORK1,WORK3,WORKSAVE         RESTORE POINTERS            38320020
         BR    RETURN                       RETURN TO CALLER            38360020
         SPACE 3                                                        38400020
*********************************************************************** 38440020
*                                                                     * 38480020
*        FOR A REQUEST FOR A SYMBOL, THIS ROUTINE SEARCHS THE INCORE  * 38520020
*        SYMBOL TABLE                                                 * 38560020
*        IF THE SEARCH IS FOR A DSECT, THE DSECT NAME WILL BE         * 38600020
*        IN WAREA1                                                    * 38640020
*                                                                     * 38680020
*********************************************************************** 38720020
         SPACE 2                                                        38760020
SINCORES MVC   WAREA1(N8),BLANKS            CLEAR SYMBOL WORK AREA      38800020
         LH    WORK1,PDELEN3                LENGTH OF PASSED SYMBOL     38840020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     38880020
         L     WORK3,PDEASADD               ADDR OF PASSED SYMBOL       38920020
         LA    WORK2,WAREA1                 MOVE TO LOCATION            38960020
         EX    WORK1,MOVEINST               MOVE SYMBOL TO WORK AREA    39000020
DSECTIN  L     WORK4,SYMTABLE               ADDR OF INCORE SYM TABLE    39040020
         USING INCORE,WORK4                 BASE FOR DESCRIPTIVE DSECT  39080020
SEARCH3  LTR   WORK4,WORK4                  IS IT LAST INCORE SYM TABLE 39120020
         BC    N7,CSEARCH3                  NO, GO CONTINUE SEARCH      39160020
         LA    RETCODE,N4                   YES, SYMBOL NOT FOUND       39200020
         BR    RETURN                       RETURN TO CALLER            39240020
CSEARCH3 MVC   WAREA2(N8),BLANKS            CLEAR SYMBOL WORK AREA      39280020
         LH    WORK1,LENSYM                 LENGTH OF SYMBOL NAME       39320020
         BCTR  WORK1,N0                     LEN-1 FOR EXECUTE INSTR     39360020
         LA    WORK3,INSYM                  ADDRESS OF SYMBOL           39400020
         LA    WORK2,WAREA2                 MOVE TO LOCATION IN SYMWORK 39440020
         EX    WORK1,MOVEINST               MOVE SYMBOL TO WORK AREA    39480020
         CLC   WAREA1(N8),WAREA2            IS THIS THE SYMBOL          39520020
         BE    FOUND3                       YES, GO EXTRACT INFO        39560020
         L     WORK4,NXINCORE               NO, POINT TO NEXT INCORE    39600020
         B     SEARCH3                      GO LOOK AT NEXT SYM INCORE  39640020
FOUND3   LNR   WORK3,WORK4                  SYM FOUND IN INCORE TABLE   39680020
         DROP  WORK4                                                    39720020
         SR    RETCODE,RETCODE              RETCODE IS ZERO             39760020
         BR    RETURN                       RETURN TO CALLER            39800020
         SPACE 3                                                        39840020
*********************************************************************** 39880020
*                                                                     * 39920020
*        THIS  SUB-ROUTINE OBTAINS CESD INFORMATION EITHER FROM CESD  * 39960020
*        RCDS ON SECONDARY STORAGE OR FROM INCORE CESD INFO SAVED BY  * 40000020
*        THE OS LOADER.  HOW TO SEARCH IS INDICATED BY SWITCHES, SWSB * 40040020
*        AND THEIR ARE THREE POSSIBLTIES- SEARCH USING OFFSET, SEARCH * 40080020
*        USING ENTRYNAME OR SEARCH FOR THE FIRST CSECT.               * 40120020
*********************************************************************** 40160020
         SPACE 2                                                        40200020
*                                                                       40240020
*        FOR   LOAD MODULES THIS ROUTINE READS SECONDARY STORAGES       40280020
*        AND RETURNS THE DESIRED INFORMATION                            40320020
*                                                                       40360020
FINDCESD ST    RETURN,CESD14                SAVE RETURN ADDRESS         40400020
         TM    MODSWS,V80                   IS IT A LOAD OR OBJ MODULE  40440020
         BZ    OBJMOD                       OBJ MOD, GO ANALYZE         40480020
         TM    MODSWS,V10                   HAS THE TTSVC OPERATED      40520020
         BO    SVCDID                       YES, GO ON                  40560020
         LA    RETCODE,N12                  NOT LOADED BY TEST          40600020
         B     NOFIND                       NO, ERROR, NO CESD INFO     40640020
SVCDID   BAL   RETURN,OPENDCB               GO OPEN DCB                 40680020
         TM    MODSWS,V08                   IS A CESD RCD TTR AVAILABLE 40720020
         BZ    USESYMS                      NO, GO USE SYMS TTR         40760020
SMTSYND2 DS    0H                           SMT TESTCASE LABEL          40768020
*                                            ENTER SYNAD ON CESD READ   40776020
*                                            RC FROM SYM IS 12          40784020
*                                            TESTCASE ID  TTSTC150      40792020
         LA    PARMREG0,CESDTTR             YES, USE CESD TTR           40800020
         B     ONWARD99                     GO ON                       40840020
SMTSYND3 DS    0H                           SMT TESTCASE LABEL          40848020
*                                            ENTER SYNAD ON CESD READ   40856020
*                                            RC FROM SYM IS 12          40864020
*                                            TESTCASE ID  TTSTC150      40872020
USESYMS  LA    PARMREG0,POINTER             USE SYM TTR FOR POINT       40880020
ONWARD99 LA    PARMREG1,PDSDCB              ADDR OF DCB FOR POINT       40920020
         BAL   RETURN,DOPOINT               GO ISSUE POINT              40960020
READCESD BAL   RETURN,DOREAD                GO READ FROM SECONDARY STOR 41000020
         CLI   BUFFER,V20                   IS IT A CESD RECORD         41040020
         BE    PROCESS1                     YES, GO PROCESS             41080020
         TM    SWSB,V80                     NO, HAS A CESD RCD BEEN RED 41120020
         BZ    READCESD                     NO, GO READ AGAIN           41160020
         TM    SWSB,V10                     IS SEARCH FOR FIRST CSECT   41200020
         BZ    GIVEERR                      NO, GO SET ERROR CODE       41240020
         MVC   ENTRYNAM(N8),BLANKS          FIRST CSECT NAME IS BLANK   41280020
         MVC   ENTRNAMD(N4),POFFSET         DISPLACEMENT IS OFFSET      41320020
         OI    MODSWS,V40                   INDICATE DISPL PRESENT      41360020
         L     RETURN,CESD14                GET RETURN ADDRESS          41400020
         BR    RETURN                       RETURN TO CALLER            41440020
GIVEERR  EQU   *                                                        41480020
         LA    RETCODE,N32                  ENTRYNAME NOT IN CESD RCDS  41520020
         B     NOFIND                       ERROR, NO MORE CESD RCDS    41560020
PROCESS1 OI    SWSB,V80                     INDICATE CESD RCD READ      41600020
         TM    MODSWS,V08                   IS A CESD TTR AVAILABLE     41640020
         BO    ONWARD98                     YES, GO ON                  41680020
         LA    PARMREG1,PDSDCB              NO, OBTAIN ONE              41720020
         BAL   RETURN,DONOTE                GO NOTE FIRST CESD RECORD   41760020
         ST    PARMREG1,CESDTTR             SAVE TTR                    41800020
         MVC   CESDTTR+N3(N1),POINTER+N3    CONCATENATION NO. TO TTR    41840020
         OI    MODSWS,V08                   INDICATE CESD TTR AVALIABLE 41880020
ONWARD98 LA    WORK2,BUFFER                 ADDR OF PHYSICAL RCD        41920020
         LH    WORK3,N6(WORK2)              LENGTH OF DATA PORTION      41960020
         LA    WORK2,N8(WORK2)              ADDR OF FIRST ENTRY         42000020
         LA    WORK3,N0(WORK3,WORK2)        ADDR OF END OF PHYSICAL RCD 42040020
         TM    SWSB,V20                     IS SEARCH USING ENTRYNAME   42080020
         BO    FINDNAME                     YES, SEARCH USING ENTRYNAME 42120020
         TM    SWSB,V10                     IS SEARCH FOR FIRST CSECT   42160020
         BZ    SEARCH4                      NO, SEARCH USING OFFSET     42200020
         SR    WORK1,WORK1                  YES, CREATE A ZERO OFFSET   42240020
         ST    WORK1,POFFSET                 AND USE OFFSET SEARCH RT   42280020
         TM    ATTRIBUT,V20                 IS LMOD LINK EDITED IN OVLY 42320020
         BZ    SEARCH4                      NO, OFFSET OK, GO SEARCH    42360020
         STM   WORK1,WORK3,WORKSAV2         SAVE POINTERS               42400020
         LA    WORK1,N4                     SET INDEX, 4 REGIONS MAX    42440020
         L     WORK3,LOADNAMA               ADDRESS OF SEGTAB CSECT     42480020
         SR    WORK4,WORK4                  CLEAR REGISTER TO ZERO      42520020
CKREGION EQU   *                                                        42560020
         IC    WORK4,N8(WORK3)              GET LAST SEG. NO. IN REGION 42600020
         TM    N10(WORK3),VFF               ARE THEIR ANY MORE REGIONS  42640020
         BZ    LASTREGN                     NO, GO FIGURE LEN OF SEGTAB 42680020
         BCT   WORK1,SETNEXT1               YES, GO SET TO CHECK NEXT   42720020
         B     LASTREGN                     NO, HAVE 4 REGNS, GO        42760020
SETNEXT1 EQU   *                                                        42800020
         LA    WORK3,N2(WORK3)              SEGTAB PTR TO NEXT REGION   42840020
         B     CKREGION                     GO CHECK NEXT REGION        42880020
LASTREGN EQU   *                                                        42920020
         SLL   WORK4,N2                     MULTIPLY LAST SEG NO. BY 4  42960020
         LA    WORK2,N24(WORK4)             LENGTH OF SEGTAB CSECT      43000020
         ST    WORK2,POFFSET                SAVE                        43040020
         TM    POFFSET+N3,V04               TEST FOR ALIGNMENT          43080020
         BZ    SETSEACH                     ON DOUBLE WORD, GO SEARCH   43120020
         LA    WORK2,N4(WORK2)              ALIGNED ON NEXT DOUBLE WORD 43160020
         ST    WORK2,POFFSET                OFFSET FOR 1ST CSECT SEARCH 43200020
SETSEACH EQU   *                                                        43240020
         LM    WORK1,WORK3,WORKSAV2         RESTORE POINTERS            43280020
*                                                                       43320020
*        SEARCH CESD RCD USING PASSED OFFSET, RETURN ENTRYNAME CONTAIN- 43360020
*        THAT  OFFSET                                                   43400020
*                                                                       43440020
SEARCH4  NI    N8(WORK2),V0F                TURN OFF L.E. SUBCLASS      43480020
         CLI   N8(WORK2),V00                IS IT A SECTION DEFINITION  43520020
         BE    SD                           YES, CHECK FOR RIGHT ONE    43560020
BACK99   LA    WORK2,N16(WORK2)             POINT TO NEXT ENTRY         43600020
         CR    WORK2,WORK3                  IS IT END OF RCD            43640020
         BL    SEARCH4                      NO, CONTINUE SEARCH         43680020
         B     READCESD                     YES, GO READ ANOTHER RCD    43720020
SD       L     WORK4,N8(WORK2)              DISP OF SD ENTRY            43760020
         C     WORK4,POFFSET                IS SD ORGIN PAST OFFSET     43800020
         BH    BACK99                       YES, GO CHECK NEXT CESD     43840020
         L     WORK5,N12(WORK2)             SEGMENT NO. AND LENGTH      43880020
         LA    WORK5,N0(WORK5)              LENGTH OF CSECT             43920020
         ST    WORK5,WAREA1                 LENGTH TO WORK AREA         43960020
         TM    WAREA1+N3,V07                IS LEN DOUBLE WORD MULTIPLE 44000020
         BZ    ONDWORD                      YES, GO CONTINUE            44040020
         SRL   WORK5,N3                     DISCARD 3 LOW ORDER BITS    44080020
         SLL   WORK5,N3                     3 LOW ORDER BITS ARE ZERO   44120020
         LA    WORK5,N8(WORK5)              LEN IS MULTIPLE OF DOUBLE   44160020
ONDWORD  EQU   *                                                        44200020
         AR    WORK4,WORK5                  LEN OF MEMBER, SO FAR       44240020
         L     WORK1,POFFSET                OFFSET PASSED IN PDE        44280020
         CR    WORK1,WORK4                  IS OFFSET IN THIS CSECT     44320020
         BL    FOUND4                       YES, GO FILL IN INFOBLK     44360020
         B     BACK99                       NO, SEARCH SOME MORE        44400020
FOUND4   EQU   *                                                        44440020
         TM    ATTRIBUT,V20                 IS LMOD LINK EDITED IN OVLY 44480020
         BZ    INCORE4                      NO, CSECT INCORE, GO PASS   44520020
         ST    WORK3,WKSAVE3                SAVE END OF CESD RCD ADDR   44560020
         BAL   RETURN,CHKSEGMT              YES, GO SEE IF CSECT INCORE 44600020
         L     WORK3,WKSAVE3                RESTORE END OF CESD RCD PTR 44640020
         LTR   RETCODE,RETCODE              IS CSECT IN CORE            44680020
         BNZ   BACK99                       NO, GO BACK, CONTUNE SEARCH 44720020
INCORE4  EQU   *                                                        44760020
         MVC   ENTRYNAM(N8),N0(WORK2)       CSECT NAME TO ENTRYNAME FLD 44800020
         MVC   ENTRNAMD+N1(N3),N9(WORK2)    GET ENTRYNAME DISPLACMENT   44840020
         OI    MODSWS,V40                   ENTRYNAME DISPLACMENT HERE  44880020
         L     RETURN,CESD14                GET RETURN ADDR             44920020
         BR    RETURN                       RETURN                      44960020
*                                                                       45000020
*        SEARCH CESD RCDS USING PASSED ENTRYNAME  RETURN DISPLACEMENT   45040020
*        BASED ON LINKAGE EDITOR ADDR 00, OF THAT CSECT                 45080020
*                                                                       45120020
FINDNAME CLC   ENTRYNAM(N8),N0(WORK2)       IS THIS THE CSECT           45160020
         BE    FOUND5                       YES, GO EXTRACT DISPLACMENT 45200020
         LA    WORK2,N16(WORK2)             NO, POINT TO NEXT ENTRY     45240020
         CR    WORK2,WORK3                  IS IT THE END OF THE RCD    45280020
         BL    FINDNAME                     NO, GO CHECK NEXT CESD ENTY 45320020
         B     READCESD                     YES, GO READ ANOTHER RECORD 45360020
FOUND5   EQU   *                                                        45400020
         TM    ATTRIBUT,V20                 IS LMOD LINK EDITED IN OVLY 45440020
         BZ    INCORE5                      NO, CSECT INCORE, GO PASS   45480020
         BAL   RETURN,CHKSEGMT              YES, GO SEE IF CSECT INCORE 45520020
         LTR   RETCODE,RETCODE              IS CSECT IN CORE            45560020
         BZ    INCORE5                      YES, GO PASS TO CALLER      45600020
         LA    RETCODE,N40                  NO, PASS 2ND LEVEL MESG NO. 45640020
         B     NOFIND                       GO GIVE RET CODE, MESSAGE   45680020
INCORE5  EQU   *                                                        45720020
         MVC   ENTRNAMD+N1(N3),N9(WORK2)    GET ENTRYNAME DISPLACEMENT  45760020
         OI    MODSWS,V40                   INDICATE DISPLACMENT PRESNT 45800020
         L     RETURN,CESD14                GET RETURN ADDR             45840020
         BR    RETURN                       RETURN                      45880020
*                                                                       45920020
*        IF THE LOAD MODULE IS LINK EDITTED IN OVERLAY, SEE IF SEGMENT  45960020
*        CONTAINNING ENTRYNAME IS IN CORE                               46000020
*                                                                       46040020
CHKSEGMT EQU   *                                                        46080020
         SR    RETCODE,RETCODE              INITIAL INDCATE, SEG INCORE 46120020
         SR    WORK1,WORK1                  CLEAR REGISTER TO ZERO      46160020
         IC    WORK1,N12(WORK2)             SEG NO. OF FOUND ENTRYNAME  46200020
         SLL   WORK1,N2                     MULTIPLY BY FOUR            46240020
         L     WORK3,LOADNAMA               ADDRESS OF SEGTAB CSECT     46280020
         LA    WORK3,N23(WORK3,WORK1)       PTR TO STATUS IND FOR SEGMT 46320020
         TM    N0(WORK3),V03                ARE LOW ORDER 2 BITS 00     46360020
         BCR   ZERO,RETURN                  YES, SEGMENT INCORE, RETURN 46400020
         BO    NOTINMS                      NO, NOT INCORE, GO SET ERR  46440020
         TM    N0(WORK3),V02                ARE LOW ORDER 2 BITS 10     46480020
         BCR   ONES,RETURN                  YES, SEGMENT INCORE, RETURN 46520020
NOTINMS  EQU   *                                                        46560020
         LA    RETCODE,N4                   INDICATE SEGMENT NOT INCORE 46600020
         BR    RETURN                       RETURN TO CALLER            46640020
*                                                                       46680020
*        THIS ROUTINE SEARCHS INCORE CESD INFO BUILT BY THE OS LOADER   46720020
*                                                                       46760020
OBJMOD   TM    MODSWS,V20                   IS OS LOADER CESD INFO AVAB 46800020
SMTOBJ   DS    0H                           SMT TESTCASE LABEL          46808020
*                                            OBJ CESD NOT AVAILABLE     46816020
*                                            RC FROM SYM IS 4           46824020
*                                            TESTCASE ID  TEQU6100      46832020
         BO    CESDHERE                     YES, GO ON                  46840020
         LA    RETCODE,N16                  NO OS LOADER CESD INFO      46880020
         B     NOFIND                       NO, CANNOT RESOLVE          46920020
CESDHERE L     WORK2,POINTER                ADDR OF OS LOADER CESD INFO 46960020
         L     WORK3,CESDTTR                LENGTH OF CESD INFO         47000020
         AR    WORK3,WORK2                  END ADDR OF CESD INFO       47040020
         XC    WAREA1(N16),WAREA1           CLEAR WORK AREAS TO ZEROES  47080020
         TM    SWSB,V20                     IS SEARCH USING ENTRYNAME   47120020
         BO    SEARCH6                      YES, GO FIND DISPLACMENT    47160020
         L     WORK1,POFFSET                SEARCH USING OFFSET         47200020
         LA    WORK1,N8(WORK1)              ADD LEN OF **GO             47240020
         ST    WORK1,POFFSET                NEW OFFSET                  47280020
         B     OBJOFFST                     GO SEARCH USING OFFSET      47320020
*                                                                       47360020
*        THIS ROUTINE SEARCHS OS LOADER CESD INFO FOR A DISPLACEMENT    47400020
*        USING A CSECT NAME AS THE SEARCH ARGUMENT. WORK2 CONTAINS      47440020
*        THE PRESENT ENTRY ADDRESS, WORK3 CONTAINS THE END ADDRESS      47480020
*                                                                       47520020
SEARCH6  CR    WORK2,WORK3                  ANY MORE OS LOADER CESDS    47560020
         BL    CHECK6                       YES, GO CHECK THIS ENTRY    47600020
         LA    RETCODE,N32                  ENTRYNAME NOT IN CESD RCDS  47640020
         B     NOFIND                       NO, ERROR, CANNOT RESOLVE   47680020
CHECK6   CLC   ENTRYNAM(N8),N0(WORK2)       IS THIS THE CSECT           47720020
         BE    FOUND6                       YES, GO EXTRACT DISPLACEMNT 47760020
         LA    WORK2,N12(WORK2)             POINT TO NEXT ENTRY         47800020
         B     SEARCH6                      GO CHECK NEXT ENTRY         47840020
FOUND6   MVC   WAREA1+N1(N3),N9(WORK2)      LOADED ADDR OF THIS CSECT   47880020
         L     WORK4,WAREA1                 ADDR OF ENTRYNAME IN CORE   47920020
         S     WORK4,LOADNAMA               DISPL FROM LOADED ADDR      47960020
         ST    WORK4,ENTRNAMD               SAVE IN INFO BLOCK          48000020
         OI    MODSWS,V40                   INDICATE DISPLACEMENT PRSNT 48040020
         L     RETURN,CESD14                GET RETURN ADDRESS          48080020
         BR    RETURN                       RETURN                      48120020
*                                                                       48160020
*        THIS ROUTINE SEARCHS OS LOADER CESD INFO FOR A CSECT NAME      48200020
*        USING AN OFFSET AS A SEARCH ARGUMENT.  WORK2 CONTAINS THE      48240020
*        PRESENT ENTRY ADDRESS AND WORK3 CONTAINS THE END ADDRESS       48280020
*                                                                       48320020
OBJOFFST L     WORK4,LOADNAMA               MAIN STORAGE LOADED ADDRESS 48360020
         A     WORK4,POFFSET                CREATE WHERE ADDRESS        48400020
         LA    WORK5,N1                     CREATE SMALL ADDRESS        48440020
         SR    WORK1,WORK1                  INDICATE NO CESD ENTRY ADDR 48480020
SEARCH7  CR    WORK2,WORK3                  ANY MORE CESD INFO          48520020
         BL    CHECK7                       YES, GO CHECK THIS ENTRY    48560020
         B     MAYBE7                       NO, GO SEE IF WE FOUND ONE  48600020
CHECK7   MVC   WAREA2+N1(N3),N9(WORK2)      GET LOADED ADDR OF THIS SEC 48640020
         C     WORK4,WAREA2                 IS WHERE ADDR AFTER THIS    48680020
         BNL   FOUND17                      YES, GO CHECK FUTHER        48720020
PTRTONXT LA    WORK2,N12(WORK2)             POINT TO NEXT ENTRY         48760020
         B     SEARCH7                      GO CHECK NEXT ENTRY         48800020
FOUND17  C     WORK5,WAREA2                 IS THIS ADDR AFTER LAST ONE 48840020
         BH    PTRTONXT                     NO, LAST SAVED ONE HIGHER   48880020
         L     WORK5,WAREA2                 YES, GET ITS LOADED ADDR    48920020
         LR    WORK1,WORK2                  POINT TO CLOSEST CSECT ENTY 48960020
         B     PTRTONXT                     GO POINT TO NEXT ONE        49000020
MAYBE7   LTR   WORK1,WORK1                  DID WE FIND ONE             49040020
         BC    N7,FOUND7                    YES, GO MOVE TO ENTRY BLOCK 49080020
         LA    RETCODE,N4                   NO ENTRYNAME FOR OFFSET     49120020
         B     TOCALLER                     NO, ERROR, NO CSECT FOUND   49160020
FOUND7   MVC   ENTRYNAM(N8),N0(WORK1)       ENTRYNAME TO INFO BLK       49200020
         S     WORK5,LOADNAMA               CALCULATE DISPLACEMENT      49240020
         ST    WORK5,ENTRNAMD               DISPLACMENT TO INFO BLOCK   49280020
         OI    MODSWS,V40                   ENTRYNAME DISPLACMENT HERE  49320020
         L     RETURN,CESD14                GET RETURN ADDRESS          49360020
         BR    RETURN                       RETURN                      49400020
         SPACE 3                                                        49440020
*********************************************************************** 49480020
*                                                                     * 49520020
*        THE FOLLOWING SUB-ROUTINES HANDLE SECONDARY STORAGE I/O      * 49560020
*                                                                     * 49600020
*********************************************************************** 49640020
         SPACE 2                                                        49680020
*                                                                       49720020
*        THIS ROUTINE OPENS THE DCB FOR READING SECONDARY STORAGE.      49760020
*        DAIR IS LINKED TO IF IT IS NECESSARY TO ALLOCATE AND OBTAIN    49800020
*        A DDNAME FOR SYS1.LINKLIB                                      49840020
*                                                                       49880020
OPENDCB  ST    RETURN,OPDCB14               SAVE RETURN ADDRESS         49920020
         LA    WORK5,PDSDCB                 ADDR OF DCB IN WORK AREA    49960020
         USING IHADCB,WORK5                 BASE FOR DESCRIPTIVE DSECT  50000020
         TM    MODSWS,V04                   DO WE HAVE A PASSED DDNAME  50040020
         BZ    LINKLIB                      NO, PDS=LINKLIB, GO ALLOCAT 50080020
CHECKDCB TM    DCBOFLGS,V10                 IS DCB OPENED               50120020
         BZ    DOOPEN                       NO, GO OPEN DCB             50160020
         CLC   DDNAME(N8),OPENFDD           IS DCB OPENED FOR PASSED DD 50200020
         BNE   DOCLOSE                      NO, GO DO CLOSE AND OPEN    50240020
OPENDONE L     RETURN,OPDCB14               RESTORE RETURN ADDRESS      50280020
         BR    RETURN                       RETURN TO CALLER            50320020
DOCLOSE  BAL   RETURN,CHECKECB              GO CHECK FOR REQ TO END     50360020
         LA    PARMREG1,CLOSELST            ADDRESS OF CLOSE LIST       50400020
         CLOSE ((WORK5)),MF=(E,(PARMREG1))                              50440020
DOOPEN   MVC   DCBDDNAM(N8),DDNAME          OPEN DCB FOR PASSED DDNAME  50480020
         BAL   RETURN,CHECKECB              GO CHECK FOR REQ TO END     50520020
         LA    PARMREG1,OPENLIST            ADDRESS OF OPEN LIST        50560020
         OPEN  ((WORK5)),MF=(E,(PARMREG1))                              50600020
PABEND3  EQU   *                            POSSIBLE ABEND RESUME ADDR  50640020
         TM    DCBOFLGS,V10                 WAS DCB OPENED SUCCESSFULLY 50680020
         DROP  WORK5                                                    50720020
SMTOPEN  DS    0H                           SMT TESTCASE LABEL          50726020
*                                            OPEN UNSUCCESSFUL          50732020
*                                            RC FROM SYM IS 8           50738020
*                                            TESTCASE ID  TEQU5400      50744020
*                                            TESTCASE ID  TPCH6300      50750020
         BO    OPENOK                       YES, GO ON                  50760020
         LA    RETCODE,N4                   CANNOT OPEN DCB             50800020
         B     SYSERR                       GO SET UP END AND GIVE MESG 50840020
OPENOK   MVC   OPENFDD(N8),DDNAME           INDICATE DD DCB OPENED FOR  50880020
         B     OPENDONE                     GO BACK AND RETURN TO CALLR 50920020
LINKLIB  TM    SWSC,V80                     IS A DDNAME FOR LINKLIB ON  50960020
         BZ    ALLOC                        NO, GO SET TO ALLOC - DAIR  51000020
         MVC   DDNAME(N8),LINKLBDD          YES, MOVE TO INFO BLOCK     51040020
         OI    MODSWS,V04                   INDICATE WE HAVE A DDNAME   51080020
         B     CHECKDCB                     GO CHECK STATUS OF DCB      51120020
ALLOC    EQU   *                                                        51160020
         GETMAIN   R,LV=N100,SP=N1          GET PARM BLOCK TO PASS-DAIR 51200020
PABEND2  EQU   *                            POSSIBLE ABEND RESUME ADDR  51240020
SMTGET01 DS    0H                           SMT TESTCASE LABEL          51250020
*                                            GET FAILED-DAIR PARM LIST  51260020
*                                            TESTCASE ID  TTSTC160      51270020
         OI    SWSC,V40                     INDICATE THEIR IS A PARM    51280020
*                                            LIST TO FREE IN THE STAE   51320020
*                                            RETRY RT IF WE ABEND IN    51360020
*                                            DAIR                       51400020
         ST    PARMREG1,ADAIRCOR            SAVE ADDR OF DAIR LIST CORE 51440020
         USING DAPL,PARMREG1                                            51480020
         MVC   DAPLUPT(N4),TSTUPT           POINTER TO UPT FOR DAIR     51520020
         MVC   DAPLECT(N4),TSTECT           POINTER TO ECT FOR DAIR     51560020
         MVC   DAPLECB(N4),TSTCPECB         POINTER TO CP ECB FOR DAIR  51600020
         L     WORK1,TPLPTR                 OBTAIN POINTER TO THE       51640020
         USING TPL,WORK1                     PROTECTED STEP CONTROL     51680020
         MVC   DAPLPSCB(N4),TPLPSCB          BLOCK FOR DAIR             51720020
         DROP  WORK1                                                    51760020
         LA    WORK1,N20(PARMREG1)          ADDR OF DAIR LIST FOR X'08' 51800020
         ST    WORK1,DAPLDAPB               INTO STANDARD LIST FOR DAIR 51840020
         DROP  PARMREG1                                                 51880020
         USING DAPB08,WORK1                                             51920020
         LA    WORK2,N8                     DAIR REQ TYPE IS X'08'      51960020
         STH   WORK2,DA08CD                 PUT IN DAIR PARM LIST       52000020
         SR    WORK2,WORK2                  CLEAR REG TO ZEROES         52040020
         STH   WORK2,DA08FLG                FLAGS - ZERO                52080020
         ST    WORK2,DA08DARC               ERROR CODES - ZERO          52120020
         LA    WORK2,LINKPDS                ADDR OF DS NAME - LINKLIB   52160020
         ST    WORK2,DA08PDSN               INTO DAIR PARM LIST         52200020
         MVC   DA08DDN(N4),BLANKS           DDNAME IS BLANK             52240020
         MVC   DA08UNIT(N4),BLANKS          UNIT IS BLANK               52280020
         MVC   DA08SER(N4),BLANKS           VOL SER IS BLANK            52320020
         LA    WORK2,N256                   BLOCKSIZE IS 256            52360020
         ST    WORK2,DA08BLK                INTO DAIR LIST              52400020
         XC    DA08PQTY(N12),DA08PQTY       DASD SPACE REQ IS ZERO      52440020
         MVC   DA08MNM(N4),BLANKS           MEMBER NAME IS BLANKS       52480020
         MVC   DA08PSWD(N4),BLANKS          PASSWORD IS BLANK           52520020
         MVI   DA08DSP1,DA08SHR             DISP1 FIELD SET TO SHR      52560020
         MVI   DA08DPS2,DA08KEEP            DISP2 FIELD SET TO KEEP     52600020
         MVI   DA08DPS3,DA08KEP             DISP3 FIELD SET TO KEEP     52640020
         MVI   DA08CTL,V00                  CONTROL FIELD SET TO ZERO   52680020
         LINK  EP=IKJDAIR                   GO TO DAIR                  52720020
PABEND4  EQU   *                            POSSIBLE ABEND RESUME ADDR  52760020
SMTDAIR  DS    0H                           SMT TESTCASE LABEL          52770020
*                                            LINK TO DAIR FAILED        52780020
*                                            TESTCASE ID  TTSTC160      52790020
         LR    WORK4,RETCODE                SAVE DAIR RETURN CODE       52800020
         LTR   PARMREG0,RETCODE             WAS DAIR SUCCESSFUL         52840020
         BZ    ALLOCOK                      YES, GO GET DDNAME          52880020
         L     RETCODE,TSTDDM               NO, ADDR OF DAIR MSG RT     52920020
         BALR  RETURN,RETCODE               GO BUILD ERROR MESG         52960020
ALLOCOK  EQU   *                                                        53000020
         MVC   LINKLBDD(N8),DA08DDN         GET LINKLIB DD OR BLANKS    53040020
         DROP  WORK1                                                    53050020
         FREEMAIN  R,LV=N100,A=(PARMREG1),SP=N1                         53080020
         NI    SWSC,VBF                     TURN PARM LIST GOT SW OFF   53120020
         LTR   PARMREG0,WORK4               DID WE ALLOC LINKLIB        53160020
         BZ    ALLOCOK1                     YES, GO EXTRACT DDNAME      53200020
         L     PARMREG1,OUTBUF              ADDRESS OF MESG D WORD      53240020
         BAL   RETURN,TERMIO                GO PUT MESG OUT             53280020
         LA    RETCODE,N8                   RC=8 FOR CALLER             53320020
         B     TOCALLER                     GO RETURN TO CALLER         53360020
ALLOCOK1 EQU   *                                                        53400020
         MVC   DDNAME(N8),LINKLBDD          MOVE IT TO INFO BLOCK       53440020
         OI    MODSWS,V04                   INDICATE DDNAME PRESENT     53480020
         OI    SWSC,V80                     WE HAVE A DDNAME FOR LINKLB 53520020
         B     CHECKDCB                     GO CHECK STATUS OF DCB      53560020
*                                                                       53600020
*        THIS ROUTINE PERFORMS A POINT TO THE LOADNAME INFO IN THE PDS  53640020
*                                                                       53680020
DOPOINT  ST    RETURN,POINT14               SAVE RETURN ADDRESS         53720020
         BAL   RETURN,CHECKECB              GO CHECK FOR REQ FOR END    53760020
         FIND  (PARMREG1),(PARMREG0),C                                  53800020
         L     RETURN,POINT14               RETURN ADDRESS              53840020
         BR    RETURN                       RETURN TO CALLER            53880020
*                                                                       53920020
*        THIS ROUTINE READS SECONDARY STORAGE                           53960020
*                                                                       54000020
DOREAD   ST    RETURN,READ14                SAVE RETURN ADDRESS         54040020
         LA    WORK4,LSTFREAD               ADDR OF DECB FOR E FORM     54080020
         BAL   RETURN,CHECKECB              GO CHECK FOR REQ FOR END    54120020
         LA    WORK3,BUFFER                 ADDRESS OF INPUT BUFFER     54160020
         LA    WORK5,PDSDCB                 ADDRESS OF DCB              54200020
         READ  (WORK4),SF,(WORK5),(WORK3),,,MF=E                        54240020
         CHECK (WORK4)                                                  54280020
         L     RETURN,READ14                GET RETURN ADDRESS          54320020
         BR    RETURN                       RETURN TO CALLER            54360020
*                                                                       54400020
*        THIS ROUTINE WILL ISSUE A NOTE FOR THE LAST RECORD READ        54440020
*                                                                       54480020
DONOTE   ST    RETURN,NOTE14                SAVE RETURN ADDRESS         54520020
         BAL   RETURN,CHECKECB              GO CHECK FOR REQ TO END     54560020
         NOTE  (PARMREG1)                                               54600020
         L     RETURN,NOTE14                GET RETURN ADDR             54640020
         BR    RETURN                       RETURN TO CALLER            54680020
         SPACE 3                                                        54720020
*********************************************************************** 54760020
*                                                                     * 54800020
*        THESE ROUTINES PERFORM LINKAGE TO THE SECOND SECTION OF SYM  * 54840020
*                                                                     * 54880020
*********************************************************************** 54920020
         SPACE 2                                                        54960020
FOUNDSYM EQU   *                                                        55000020
         LA    PARMREG1,N12                 FORTH ROUTINE IN 2ND SEC    55040020
         B     GOTO2SEC                     GO SET UP FOR 2ND SECTION   55080020
SYSERR   EQU   *                                                        55120020
         LA    PARMREG1,N8                  THIRD ROUTINE IN 2ND SEC    55160020
         B     GOTO2SEC                     GO SET UP FOR 2ND SECTION   55200020
NOFIND   EQU   *                                                        55240020
         LA    PARMREG1,N4                  SECOND ROUTINE IN 2ND SEC   55280020
         B     GOTO2SEC                     GO SET FOR 2ND SECTION      55320020
FIRSTENT EQU   *                                                        55360020
         SR    PARMREG1,PARMREG1            FIRST ROUTINE IN 2ND SEC    55400020
GOTO2SEC L     WORK1,SECENTRY               ADDR OF ENTRY TO 2ND        55440020
         BR    WORK1                        GO TO SECOND CSECT          55480020
         SPACE 3                                                        55520020
*********************************************************************** 55560020
*                                                                     * 55600020
*        CONSTANTS                                                    * 55640020
*                                                                     * 55680020
*********************************************************************** 55720020
         SPACE 2                                                        55760020
DEFAULTM DC    X'000001'                    DEFAULT MULTIPLICITY VALUE  55800020
WLENRCD  DC    C'WRNG.LEN.RECORD'           SYNADAF MESSAGE FOR WRONG   55840020
*                                            LENGTH RECORD              55880020
CCWLENFD DC    H'7'                         CCW LENGTH FIELD            55920020
DEFLENFD DC    H'0'                         DEFAULT LENGTH FIELD        55960020
LINKPDS  DC    H'12'                        LENGTH AND NAME OF LINKLIB  56000020
         DC    C'SYS1.LINKLIB'              FOR DAIR PARM LIST          56040020
SECENTRY DC    A(IKJEGMYS)                  ADDRESS OF SECOND CSECT     56080020
MESGADDR DC    A(IKJEGSMG)                  ADDRESS OF MESSAGE SECTION  56120020
MOVEINST MVC   N0(N1,WORK2),N0(WORK3)       TARGET OF EX INSTR          56160020
ABENDTAB DS    0F                           ABEND IC TABLE FOR STAE     56200020
         DC    X'01'                        NO CORE CODE                56240020
         DC    AL3(PABEND1)                 RESUME IC AFTER GETMAIN     56280020
         DC    X'01'                        NO CORE CODE                56320020
         DC    AL3(PABEND2)                 RESUME IC AFTER GETMAIN     56360020
         DC    X'06'                        OPEN FAILED CODE            56400020
         DC    AL3(PABEND3)                 RESUME IC AFTER OPEN        56440020
         DC    X'09'                        LINK FAILED CODE            56480020
         DC    AL3(PABEND4)                 RESUME IC AFTER LINK        56520020
         DC    X'FF'                        END OF ABEND IC TABLE       56560020
RETRYADR DC    AL3(STAERTRY)                ADDR OF STAE RETRY ROUTINE  56600020
BLANKS   DC    8C' '                        BLANKS FOR CLEARING AREAS   56640020
NO2NDMSG DC    X'FF000000'                  RC NOT 0, NO 2ND LEV MSG IN 56680020
         SPACE 3                                                        56720020
*********************************************************************** 56760020
*                                                                     * 56800020
*        DSECTS                                                       * 56840020
*                                                                     * 56880020
*********************************************************************** 56920020
         SPACE 2                                                        56960020
PDE      DSECT     ,    THIS DSECT DESCRIBES THE PASSED PDE CONTAIN-    57000020
*                       ING THE ACCEPTED ARGUMENTS                      57040020
*                                                                       57080020
PDELNADD DS    A             ADDRESS OF PASSED LOADNAME                 57120020
PDELEN1  DS    H             LENGTH OF PASSED LOADNAME                  57160020
PDEFLAG1 DS    X             FLAGS FOR LOADNAME                         57200020
         DS    X             RESERVED                                   57240020
PDEENADD DS    A             ADDRESS OF PASSED ENTRYNAME                57280020
PDELEN2  DS    H             LENGTH OF PASSED ENTRYNAME                 57320020
PDEFLAG2 DS    X             FLAGS FOR ENTRYNAME                        57360020
         DS    X             RESERVED                                   57400020
PDEASADD DS    A             ADDRESS OF PASSED ADDRESS STRING           57440020
PDELEN3  DS    H             LENGTH OF PASSED ADDRESS STRING            57480020
PDEFLAG3 DS    X             FLAGS FOR ADDRESS STRING                   57520020
         DS    X             RESERVED                                   57560020
PDEFLAG4 DS    X             FLAGS FOR ADDRESS STRING                   57600020
PDESIGN  DS    X             SIGN                                       57640020
PDEIC    DS    H             INDIRECT COUNT                             57680020
PDEEXADD DS    A             ADDRESS OF AN EXPRESSION VALUE PDE         57720020
PDEUWORD DS    F             USER WORD                                  57760020
         SPACE 2                                                        57800020
INFOBLK  DSECT     ,    THIS DSECT DESCRIBES THE INFO BLOCK BUILT TO    57840020
*                       REFLECT THE REQUEST AND INFO KNOWN ABOUT THE    57880020
*                       MODULE                                          57920020
*                                                                       57960020
LOADNAME DS    D             LOADNAME                                   58000020
ENTRYNAM DS    D             ENTRYNAME                                  58040020
DDNAME   DS    D             DDNAME FROM TT SVC OR BLANKS               58080020
LOADNAMA DS    A             LOADNAME MAIN STORAGE ADDRESS              58120020
ENTRNAMD DS    A             ENTRYNAME DISPLACEMENT INTO MODULE         58160020
MODSWS   DS    X             SWITCHES REFLECTING MOULE PASSED           58200020
*                                BIT 0  IF 0 - OBJECT MODULE            58240020
*                                       IF 1 - LOAD MODULE              58280020
*                                BTI 1  IF 0 - NO ENTRYNAME DISPL       58320020
*                                       IF 1 - ENTRYNAME DISPL PRESENT  58360020
*                                BIT 2  IF 0 - NO OS LOADER CESD INFO   58400020
*                                       IF 1 - OS LOADER CESD INFO      58440020
*                                BIT 3  IF 1 - SVC 61 HAS OPERATED      58480020
*                                       IF 0 - SVC 61 DID NOT OPERATE   58520020
*                                BIT 4  IF 1 - LMOD CESD TTR AVALIABLE  58560020
*                                       IF 0 - CESD TTR NOT AVALIABLE   58600020
*                                BIT 5  IF 1 - DDNAME PRESENT           58640020
*                                       IF 0 - LMOD IN SYS1.LINKLIB     58680020
POINTER  DS    F             OBJ-ADDR OF CESD, LOAD-TTR OF SYMBOLS      58720020
CESDTTR  DS    F             LOAD-TTR OF FIRST CESD RCD,                58760020
*                             OBJ-LENGTH OF CESD INFO                   58800020
ATTRIBUT DS    F             LOAD MODULE ATTRIBUTES OR ZERO             58840020
BASEFSYM DS    A             MAIN STORAGE ADDRESS TO ADD SYM DISPL TO   58880020
TCBADDR  DS    F             ADDRESS OF TCB LOADNAME HUNG OFF OF        58920020
         SPACE 2                                                        58960020
SYMINFO  DSECT     ,    THIS DSECT DESCRIBES THE ANSWER BLOCK BUILT     59000020
*                       BY SYM FOR A REQUEST FOR A SYMBOL               59040020
*                                                                       59080020
ZERO1    DS    X             ONE BYTE EQUAL TO ZEROES                   59120020
LOADEDAD DS    AL3           MAIN STORAGE ADDR OF SYMBOL                59160020
TYPE     DS    X             TYPE OF DATA AT THIS LOCATION              59200020
MULTIPLT DS    3X            MULTIPLICITY FACTOR                        59240020
LENGTH   DS    H             LENGTH OF STORAGE RESERVED                 59280020
RESERVD1 DS    H             RESERVED                                   59320020
NEXTANSB DS    F             ADDRESS OF NEXT ANSWER BLOCK               59360020
         SPACE 2                                                        59400020
INCORE   DSECT     ,    THIS DSECT DESCRIBES THE INCORE SYMBOL TABLE    59440020
*                                                                       59480020
NXINCORE DS    F             ADDRESS OF NEXT SYMBOL IN INCORE SYM TABLE 59520020
ZERO2    DS    X             ONE BYTE OF ZEROES                         59560020
LADDRESS DS    AL3           MAIN STORAGE ADDRESS OF SYMBOL             59600020
INCTYPE  DS    X             TYPE OF DATA AT THIS LOCATION              59640020
MULTIPCY DS    3X            MULTIPLICITY FACTOR                        59680020
SIZEFILD DS    H             LENGTH OF STORAGE RESERVED                 59720020
LENSYM   DS    H             NO. BYTES IN SYMBOL NAME                   59760020
INSYM    DS    2F            SYMBOL NAME                                59800020
         SPACE 2                                                        59840020
SVCINFO  DSECT     ,    THIS DSECT DESCRIBES THE INFO BLKS BUILT BY     59880020
*                       THE TESTRAN SVC 61 (IN DEC)                     59920020
*                                                                       59960020
LMODNAME DS    D             NAME OF MEMBER                             60000020
LMLADDR  DS    F             MAIN STORAGE ADDRESS WHERE LOADED          60040020
BEGTTR   DS    F             TTR OF BEGINNING OF MEMBER                 60080020
LMATTRIB DS    H             ATTRIBUTES FOR MEMBER                      60120020
LMFLAGS  DS    X             FLAGS REFLECTING CONTENTS OF SVCINFO BLOCK 60160020
*                                 BIT 0 DDNAME PRESENT                  60200020
*                                 BIT 1 DATASET IS SYS1.LINKLIB         60240020
CONCATNO DS    X             CONCATENATION NO. OF PDS                   60280020
LMDDNAME DS    2F            DDNAME FOR PDS CONTAINING MEMBER           60320020
LMTCB    DS    F             ADDRESS OF TCB LOADNAME HUNG OFF OF        60360020
NEXTBLK  DS    A             ADDR OF NEXT SVC SAVED INFO BLOCK          60400020
         SPACE 2                                                        60440020
SYMWORK  DSECT     ,    THIS DSECT DESCRIBES THE GOTTEN WORK AREA       60480020
*                                                                       60520020
MYSAVE   DS    18F           IKJEGSYM SAVE AREA                         60560020
PDSDCBA  DS    A             CONTAINS ADDR OF DCB FOR  READING SYMS     60600020
CINFOBKA DS    A             CONTAINS ADDR OF CURRENT INFO BLOCK        60640020
TINFOBKA DS    A             CONTAINS ADDR OF TEMPORARY INFO BLOCK      60680020
BUFFERA  DS    A             CONTAINS ADDR OF BUFFER                    60720020
WHATPASS DS    X             REFLECTION OF ARGUEMENT AND WHAT PASSED    60760020
*                                 BIT  0    LOADNAME                    60800020
*                                      1    ENTRYNAME                   60840020
*                                      2    SYMBOL                      60880020
*                                      3    OFFSET                      60920020
*                                      4    LOADNAME PASSED             60960020
*                                      5    ENTRYNAME PASSED            61000020
*                                      6    SYMBOL PASSED               61040020
*                                      7    OFFSET PASSED               61080020
SWSA     DS    X             SWITHCES USED DURING ANALYST OF SYM RCDS   61120020
*                                 BIT  0    LAST ENTRY CONTINUED        61160020
*                                      1    ANALYZE PRESENT ENTRY       61200020
*                                      2    SEARCHING A DSECT           61240020
*                                      3    SYMS AVAILABLE IN SYM RCDS  61280020
*                                           FOR THIS ENTRYNAME          61320020
SWSB     DS    X             CESD PROCESSING SWITCHS                    61360020
*                                 BIT  0    A CESD RCD HAS BEEN READ    61400020
*                                      1    SEARCH USING OFFSET         61440020
*                                      2    SEARCH USING ENTRYNAME      61480020
*                                      3    SEARCH FOR FIRST CSECT      61520020
SWSC     DS    X             UNIQUE SWITCHES                            61560020
*                                 BIT  0    DDNAME FOR LINKLIB KNOWN    61600020
*                                      1    STORAGE PARM LIST FOR DAIR  61640020
PDSDCB   DS    22F           BPAM DCB FOR READING SYMS                  61680020
STAELIST DS    3F            CONTAIN LIST FORM OF STAE MACRO            61720020
OPENLIST DS    2F            CONTAIN LIST FORM OF OPEN MACRO            61760020
CLOSELST DS    2F            CONTAINS LIST FORM OF CLOSE MACRO          61800020
LSTFREAD DS    6F            CONTAINS LIST FORM OF READ MACRO           61840020
OPENFDD  DS    2F            DDNAME DCB CURRENTLY OPENED FOR            61880020
CINFOBLK DS    16F           CURRENTLY QUALIFIED INFOBLK                61920020
TINFOBLK DS    16F           TEMPORARY INFOBLK FOR PRESENT REQUEST      61960020
BUFFER   DS    69F           READ SYM RCDS, BUILD ERROR MESGS           62000020
MIDBUFF  EQU   BUFFER+N100   MIDDLE OF BUFFER, ADDR OF 2ND LEV MESG     62040020
BASEADDR DS    F             BASE FOR IKJEGSYM CSECT                    62080020
WAREA1   DS    D             WORK AREA                                  62120020
WAREA2   DS    D             WORK AREA                                  62160020
WAREA3   DS    D             WORK AREA                                  62200020
ADAIRCOR DS    F             ADDRESS OF GOTTEN CORE FOR DAIR PARM LIST  62240020
CABENDTB DS    F             CONTAIN ADDR OF CALLERS ABEND TABLE        62280020
CALRETRY DS    F             CONTAIN ADDR OF CALLERS STAE RETRY ROUTINE 62320020
PARTENTY DS    5F            POSSIBLE PART ENTRY SAVED BY SYM ANALYZIER 62360020
PENTRYLN DS    F             LEN OF POSSIBLE PART SYM ENTRY SAVED       62400020
PSYMBOL  DS    D             CONTAINS  SYMBOL THAT IS PASSED            62440020
POFFSET  DS    F             CONTAINS  OFFSET THAT IS PASSED            62480020
LINKLBDD DS    2F            IF KNOWN, CONTAINS A DDNAME FOR LINKLIB    62520020
WORKSAVE DS    3F            SAVE AREA FOR WORK REGISTERS               62560020
WKSAVE3  EQU   WORKSAVE+N8   WORK3 SAVE AREA                            62600020
WORKSAV2 DS    3F            INTERNAL ROUTINES SAVE AREA FOR WORK REGS  62640020
WKSAVE3A EQU   WORKSAV2+N8   THIRD WORD OF SAVE AREA                    62650021
CESD14   DS    F             SAVED RETURN ADDR DURING CESD PROCESSING   62680020
NOTE14   DS    F             SAVED RETURN ADDR DURING NOTE PROCESSING   62720020
TERMIO14 DS    F             RETURN ADDR FOR TERMIO PROCESSING          62760020
PART14   DS    F             RETURN ADDR FROM PART ENTRY PROCESSING     62800020
OPDCB14  DS    F             SAVED RETURN ADDR DURING DCB OPEN PROCESS  62840020
POINT14  DS    F             RETURN ADDRESS FOR POINT ROUTINE           62880020
READ14   DS    F             RETURN ADDRESS FOR READ ROUTINE            62920020
SVCBLK14 DS    F             RET ADDR FROM SVCINFO BLK SEARCH ROUTINE   62960020
MSGRT214 DS    F             RET ADDR FROM ADDR BUILD ROUTINE           63000020
ESYMWORK EQU   *          END OF SYMWORK DSECT                          63080020
         SPACE 2                                                        63120020
IHADCB   DCBD  DEVD=DA,DSORG=PO                                         63160020
         SPACE 4                                                        63200020
         IKJTPL                                                         63240020
         EJECT                                                          63280020
         IKJDAPL                                                        63320020
         SPACE 2                                                        63360020
         IKJDAP08                                                       63400020
         EJECT                                                          63440020
IKJEGMYS CSECT                                                          63480020
*                                                                       63520020
*                                                                       63560020
         LR    SYMB2,WORK1                  ADDRESSABILITY              63600020
         USING IKJEGMYS,SYMB2                IKJEGMYS CSECT             63640020
         B     BTABLE(PARMREG1)             GO TO DESIRED ROUTINE       63680020
BTABLE   B     FIRSTIME                     FIRST TIME ROUTINE          63720020
         B     NOTFOUND                     UNRESOLVED SYMBOL ROUTINE   63760020
         B     NOTABLE                      CANNOT PROCESS SYMS ROUTINE 63800020
         B     BUILDSIB                     BUILD SYMINFO BLK ROUTINE   63840020
         SPACE 3                                                        63880020
*********************************************************************** 63920020
*                                                                     * 63960020
*        THIS SUB-ROUTINE PERFORMS FIRST TIME INITILIZATION.          * 64000020
*        A WORK AREA IS GOTTEN AND INITILIZED.                        * 64040020
*                                                                     * 64080020
*********************************************************************** 64120020
         SPACE 2                                                        64160020
FIRSTIME EQU   *                                                        64170020
         GETMAIN   R,LV=N72,SP=N1           GET A TEMPORARY SAVE AREA   64180020
SMTGET02 DS    0H                           SMT TESTCASE LABEL          64182020
*                                            GET FAILED-TEMP SAVE AREA  64184020
*                                            TESTCASE ID  TTSTC160      64186020
         LR    WORK5,PARMREG1               ADDRESS OF GOTTEN CORE      64190020
         L     WORK1,WORKAREA               ADDR OF GENERAL CMD WKAREA  64200020
         USING TSTCWORK,WORK1               BASE FOR DESCRIPTIVE DSECT  64210020
         LA    WORK2,CWORKSYM               ADDR OF SYM PART OF WKAREA  64220020
         MVC   N4(N12,WORK2),LFGET          LIST FORM OF GET TO WKAREA  64230020
         LA    PARMREG1,N4(WORK2)           ADDR OF LIST FORM FOR GET   64240020
         GETMAIN   EC,LV=N800,A=(WORK2),SP=N1,MF=(E,(PARMREG1))         64250020
         LTR   RETCODE,RETCODE              DID WE GET THE CORE         64260020
SMTGET03 DS    0H                           SMT TESTCASE LABEL          64262020
*                                            INSUFFICIENT CORE FOR WORK 64264020
*                                            AREA-RC FROM SYM IS 4      64266020
*                                            TESTCASE ID  TTSTC160      64268020
         BZ    GETOK                        YES, GO CONTINUE PROCESSING 64270020
*                                                                       64280020
*        SETUP TO GIVE INSUFFICIENT MAIN STORAGE MESSAGE                64290020
*                                                                       64300020
         ST    WORK5,N8(SYMWKB)             USE TEMPORARY SAVE AREA     64310020
         ST    SYMWKB,N4(WORK5)              TO PUT OUT INSUFFICIENT    64320020
         LR    SYMWKB,WORK5                  STORAGE MESSAGE            64330020
         SR    WORK5,WORK5                  CLEAR REG FOR LATER USE     64340020
         TM    TSTFLGS3,SYMMESG             SHOULD WE PRINT A MESSAGE   64350020
         BO    FREECORE                     NO, GO FREE TEMP SAVE AREA  64360020
         LA    PARMREG1,NOCOREMG            ADDRESS OF NO CORE MESSAGE  64370020
         MVC   PDEUWORD(N4),N4(PARMREG1)    ADDR OF 2ND LEVEL TO PDE    64380020
         LNR   PARMREG1,PARMREG1            INDICATE TERMINAL MESSAGE   64390020
         L     RETCODE,TPUTADDR             ADDRESS OF TESTS I/O RT     64400020
         BALR  RETURN,RETCODE               GO PUT OUT ERROR MESSAGE    64410020
         LR    WORK5,RETCODE                SAVE RETCODE FROM I/O       64420020
FREECORE EQU   *                                                        64430020
         LR    WORK3,SYMWKB                 ADDR OF TEMP SAVE TO FREE   64440020
         L     SYMWKB,N4(SYMWKB)            ADDR OF CALLERS SAVE AREA   64450020
         FREEMAIN  R,LV=N72,A=(WORK3),SP=N1 FREE TEMPORARY SAVE AREA    64460020
         LTR   WORK5,WORK5                  WAS I/O SUCCESSFUL          64470020
         BZ    RC4                          YES, GO GIVE RETURN CODE 4  64480020
         LR    RETCODE,WORK5                NO, PASS BACK I/O RET CODE  64490020
         B     TOCALL                       GO RETURN TO CALLER         64500020
RC4      EQU   *                                                        64510020
         LA    RETCODE,N4                   NO CORE RETURN CODE IS 4    64520020
         B     TOCALL                       GO RETURN TO CALLER         64530020
*                                                                       64540020
*        INITILIZE WORK AREA                                            64550020
*                                                                       64560020
GETOK    EQU   *                                                        64570020
         FREEMAIN  R,LV=N72,A=(WORK5),SP=N1 FREE TEMPORARY SAVE AREA    64580020
         L     WORK5,CWORKSYM               ADDRESS OF GOTTEN CORE      64590020
         DROP  WORK1                                                    64600020
         ST    WORK5,N8(SYMWKB)             MYSAVE ADDR IN CALLERS AREA 64610020
         ST    SYMWKB,N4(WORK5)             HIS SAVE ADDR IN MY AREA    64620020
         LR    SYMWKB,WORK5                 MY SAVE ADDR IN PROPER REG  64630020
         ST    SYMWKB,TSTSYMWK              WKAREA ADDR INTO TCOMTAB    64640020
         MVC   STAELIST(N12),LFSTAE         LIST FORM OF STAE TO WKAREA 64800020
         MVC   OPENLIST(N8),LFOPEN          OPEN LIST TO THE WORK AREA  64840020
         MVC   CLOSELST(N8),LFCLOSE         CLOSE LIST TO THE WORK AREA 64880020
         MVC   LSTFREAD(N24),SSDECB         LIST FORM READ TO WORK AREA 64920020
         MVC   PDSDCB(N88),BPAMDCB          MOVE DCB TO WORK AREA       64960020
         LA    WORK1,PDSDCB                 ADDR OF DCB                 65000020
         ST    WORK1,PDSDCBA                INTO ADDR PART OF WORK AREA 65040020
         LA    WORK1,CINFOBLK               ADDR OF CURRENT INFO BLOCK  65080020
         ST    WORK1,CINFOBKA               INTO ADDR PART OF WORK AREA 65120020
         LA    WORK1,TINFOBLK               ADDR OF TEMP INFO BLOCK     65160020
         ST    WORK1,TINFOBKA               INTO ADDR PART OF WORK AREA 65200020
         LA    WORK1,BUFFER                 ADDR OF BUFFER              65240020
         ST    WORK1,BUFFERA                INTO ADDR PART OF WORK AREA 65280020
         LA    INFOBLKB,CINFOBLK            ADDR OF WORK AREA TO CLEAR  65320020
         MVI   CINFOBLK,V40                 BLANK TO CURR INFO BLK AREA 65360020
         MVC   CINFOBLK+N1(N23),CINFOBLK    BLANK CHAR INFO             65400020
         XC    LOADNAMA(N32),LOADNAMA       ZERO OUT OUT DATA           65440020
         XC    WHATPASS(N4),WHATPASS        SET ALL SWITCHES TO ZEROES  65520020
         B     IKJEGBEG                     GO BACK TO MAIN STREAM IN   65560020
*                                            FIRST SECTION              65600020
         SPACE 2                                                        65640020
*********************************************************************** 65680020
*                                                                     * 65720020
*        SYMBOL FOUND, BUILD ANSWER BLOCK, RET CODE= ZERO, RETURN     * 65760020
*        WORK3 POINTS TO FOUND SYMBOL                                 * 65800020
*        IF THE SYMBOL WAS FOUND IN A DSECT, THE DSECT NAME WILL BE   * 65840020
*        IN WAREA1                                                    * 65880020
*                                                                     * 65920020
*********************************************************************** 65960020
         SPACE 2                                                        66000020
BUILDSIB EQU   *                                                        66040020
         GETMAIN   R,LV=N16,SP=N1           GET A SYMINFO ANSWER BLOCK  66080020
PABEND1  EQU   *                            POSSIBLE ABEND RESUME ADDR  66120020
SMTGET04 DS    0H                           SMT TESTCASE LABEL          66130020
*                                            GET FAILED-SYMINFO BLK-SIB 66140020
*                                            TESTCASE ID  TTSTC160      66150020
         LA    WORK2,N0(PARMREG1)           ADDR OF GOTTEN CORE         66160020
         LA    WORK1,N1                     CREATE 'OR' REG TO SET HIGH 66200020
         SLL   WORK1,N31                     ORDER BIT ON               66240020
         OR    WORK2,WORK1                  INDICATE POINTER TO ANSW BK 66280020
         ST    WORK2,PDEUWORD               RETURN IT TO CALLER IN PDE  66320020
         LA    WORK2,N0(WORK2)              CLEAR HIGH ORDER BYTE       66360020
         SR    PARMREG1,PARMREG1            CLEAR REGISTER              66400020
         ST    PARMREG1,N12(WORK2)          LAST BLOCK POINTER IS ZERO  66440020
         L     WORK1,SICHAIN                HEAD OF ANSWER BLOCK CHAIN  66480020
         LTR   WORK1,WORK1                  IS THEIR A CHAIN            66520020
         BC    N7,SEARCH9                   YES, GO SEARCH FOR LAST ONE 66560020
         ST    WORK2,SICHAIN                NO, START CHAIN             66600020
         B     GOTBLK                       GO FILL IN ANSWER BLOCK     66640020
SEARCH9  C     PARMREG1,N12(WORK1)          IS IT END OF CHAIN          66680020
         BE    FOUND9                       YES, GO ADD TO CHAIN        66720020
         L     WORK1,N12(WORK1)             NO, POINT TO NEXT BLOCK     66760020
         B     SEARCH9                      GO CHECK FOR END OF CHAIN   66800020
FOUND9   ST    WORK2,N12(WORK1)             LAST BLOCK POINTS TO NEW 1  66840020
         USING SYMINFO,WORK2                BASE FOR DESCRIPTIVE DSECT  66880020
GOTBLK   LTR   WORK3,WORK3                  WHERE WAS SYMBOL FOUND      66920020
         BP    SYMRCD                       IN A SYM RCD ON SEC STORAGE 66960020
         LPR   WORK3,WORK3                  ADDR OF INCORE SYMBOL       67000020
         USING INCORE,WORK3                 BASE FOR INCORE SYMTAB DSEC 67040020
         MVC   ZERO1(N10),ZERO2             INCORE SYM INFO-SYMINFO BLK 67080020
         DROP  WORK3                                                    67120020
         SR    RETCODE,RETCODE              RET CODE EQUAL ZERO         67160020
         B     TOCALLER                     GO BACK TO RET TO CALLER    67200020
*                                                                       67240020
SYMRCD   TM    SWSA,V20                     WAS SYMBOL FOUND IN A DSECT 67280020
         BZ    GOODSYM                      NO, USE BASE FOR SYMS       67320020
         STM   WORK1,WORK3,WORKSAVE         SAVE POINTERS               67360020
         BAL   RETURN,DSECTIN               GO SEARCH INCORE SYMS-DSECT 67400020
         LTR   RETCODE,RETCODE              WAS THE DSECT FOUND         67440020
         BZ    FOUNDD                       YES, GO EXTRACT ADDR        67480020
         LA    RETCODE,N28                  UNRESOLVED, 2ND LEV MESG 28 67520020
         B     NOFIND                       NO, ERROR CANNOT RESOLVE    67560020
FOUNDD   LPR   WORK3,WORK3                  ADDR OF ADDR BASE FOR DSECT 67600020
         L     WORK4,N4(WORK3)              BASE FOR SYMBOL             67640020
         LM    WORK1,WORK3,WORKSAVE         RESTORE POINTERS            67680020
         B     DSECTIN2                     GO FILL IN ANSWER BLOCK     67720020
GOODSYM  L     WORK4,BASEFSYM               BASE FOR SYMBOLS            67760020
DSECTIN2 MVC   WAREA2+N1(N3),N1(WORK3)      ALIGN SYMBOL DISPL          67800020
         L     WORK5,WAREA2                 SYM DISPLACEMENT            67840020
         LA    WORK5,N0(WORK5)              SYM DISP FOR ADDING         67880020
         AR    WORK4,WORK5                  LOADED ADDR OF SYMBOL       67920020
         ST    WORK4,ZERO1                  RETURN IN SYMINFO ANSWER BK 67960020
         SR    WORK1,WORK1                  CLEAR REG FOR IC INSTR      68000020
         IC    WORK1,N0(WORK3)              GET ORGANIZATION TYPE BYTE  68040020
         LA    WORK4,N15                    CREATE 'AND' BYTE           68080020
         NR    WORK1,WORK4                  LENGTH OF NAME-1            68120020
         LA    WORK1,N5(WORK1,WORK3)        ADDR OF DATA TYPE FIELD     68160020
         MVC   TYPE(N1),N0(WORK1)           DATA TYPE TO ANSWER BLOCK   68200020
         CLI   N0(WORK1),V08                DATA TYPE TELLS LEN FIELD   68240020
         BH    LEN1BYTE                     LENGTH FIELD-1 BYTE LONG    68280020
         MVC   LENGTH(N2),N1(WORK1)         2 BYTE LEN FIELD TO ANS BLK 68320020
         LH    WORK5,LENGTH                 LENGTH-1 OF SYMBOL'S CORE   68360020
         LA    WORK5,N1(WORK5)              LENGTH OF RESERVED M.S.     68400020
         STH   WORK5,LENGTH                 LEN TO ANSWER BLOCK         68440020
         LA    WORK1,N3(WORK1)              ADDR OF MULITIPLICITY FIELD 68480020
         B     CHECKM                       GO CHECK FOR MULITIPLICITY  68520020
LEN1BYTE SR    WORK5,WORK5                  CLEAR REGISTER              68560020
         IC    WORK5,N1(WORK1)              GET 1 BYTE LENGTH FIELD     68600020
         LA    WORK5,N1(WORK5)              LEN OF RESERVED CORE        68640020
         STH   WORK5,LENGTH                 LEN FIELD TO ANSWER BLOCK   68680020
         LA    WORK1,N2(WORK1)              ADDR OF MULTIPLICITY FIELD  68720020
CHECKM   TM    N0(WORK3),V40                IS MULTIPLICITY PRESENT     68760020
         BZ    NOM                          NO, GO GET DEFAULT          68800020
         MVC   MULTIPLT(N3),N0(WORK1)       MULTIPLICITY TO ANSWER BLK  68840020
         B     BUILTBLK                     ANSWER BLK BUILT, GO ON     68880020
NOM      EQU   *                                                        68920020
         MVC   MULTIPLT(N3),DEFAULTM        MOVE 1 TO ANSWER BLOCK      68960020
BUILTBLK SR    RETCODE,RETCODE              RETCODE = ZERO              69000020
         B     TOCALLER                     GO RETURN TO CALLER         69040020
         DROP  WORK2                                                    69080020
         SPACE 2                                                        69120020
*********************************************************************** 69160020
*                                                                     * 69200020
*        THIS ROUTINE RETURNS TO THE CALLER WHEN NOT ABLE TO RESOLVE  * 69240020
*        A REQUEST.  ERROR MESSAGES ARE PRINTED IF                    * 69280020
*                  SYMMESG SWITCH, EGUATED TO B'00100000', IN THE     * 69320020
*                  TSTFLGS3 FIELD OF TCOMTAB DSECT IS OFF             * 69360020
*                                                                     * 69400020
*********************************************************************** 69440020
         SPACE 2                                                        69480020
*                                                                       69520020
*        MESSAGE   IKJ57280I                                            69560020
*                                                                       69600020
NOTFOUND EQU   *                                                        69640020
         BAL   RETURN,MSGRT1                GO SET UP FOR MESSAGES      69680020
         MVC   N4(N18,WORK1),M0L1P1         FIRST PART MESG TO BUFFER   69720020
         LA    WORK2,N22                    LEN OF MESSAGE SO FAR       69760020
         BAL   RETURN,MSGRT2                GO ADD ADDRESS TO MESSAGE   69800020
         MVC   N0(N11,PARMREG1),M0L1P2      REST OF MESSAGE TO BUFFER   69840020
         LA    WORK2,N11(WORK2)             FINAL LENGTH OF MESSAGE     69880020
         LA    WORK3,M0L1P1                 PTR TO MESG ID FOR SEC LEV  69920020
         BAL   RETURN,MSGRT3                GO SET UP FOR SECOND LEVEL  69960020
*                                                                       70000020
*        SECOND LEVEL FOR IKJ57280I                                     70040020
*                                                                       70080020
         B     M0GETSEC(WORK5)              GO GET PROPER SECOND LEVEL  70120020
M0GETSEC B     CODEONLY                     GO GIVE RETCODE ONLY        70160020
         B     NOFIND04                     ERROR CODE 04, MESG M0L2A   70200020
         B     NOFIND08                     ERROR CODE 08, MESG M0L2B   70240020
         B     NOFIND12                     ERROR CODE 12, MESG M0L2C   70280020
         B     NOFIND16                     ERROR CODE 16, MESG M0L2D   70320020
         B     NOFIND20                     ERROR CODE 20, MESG M0L2E   70360020
         B     NOFIND24                     ERROR CODE 24, MESG M0L2F   70400020
         B     NOFIND28                     ERROR CODE 28, MESG M0L2G   70440020
         B     NOFIND32                     ERROR CODE 32, MESG M0L2H   70480020
         B     NOFIND36                     ERROR CODE 36, MESG M0L2I   70520020
         B     NOFIND40                     ERROR CODE 40, MESG M0L2J   70560020
         B     NOFIND44                     ERROR CODE 44, MESG M0L2K   70600020
NOFIND04 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         70640020
         MVC   N8(N61,WORK1),M0L2AP1        BASIC TEXT TO MESSAGE       70680020
         LA    WORK2,N69(WORK2)             LENGTH OF SECOND LEVEL MESG 70720020
         B     DOPRINT                      GO PRINT MESSAGE            70760020
NOFIND08 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         70800020
         MVC   N8(N50,WORK1),M0L2BP1        BASIC TEXT TO MESSAGE       70840020
         LA    WORK2,N58(WORK2)             LENGTH OF SECOND LEVEL MESG 70880020
         B     DOPRINT                      GO PRINT MESSAGE            70920020
NOFIND12 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSGAE         70960020
         MVC   N8(N62,WORK1),M0L2CP1        BASIC TEXT TO MESSAGE       71000020
         LA    WORK2,N70(WORK2)             LENGTH OF SECOND LEVEL MESG 71040020
         B     DOPRINT                      GO PRINT MESSAGE            71080020
NOFIND16 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         71120020
         MVC   N8(N66,WORK1),M0L2DP1        BASIC TEXT TO MESSAGE       71160020
         LA    WORK2,N74(WORK2)             LENGTH OF SECOND LEVEL MESG 71200020
         B     DOPRINT                      GO PRINT MESSAGE            71240020
NOFIND20 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         71280020
         MVC   N8(N65,WORK1),M0L2EP1        BASIC TEXT TO MESSAGE       71320020
         LA    WORK2,N73(WORK2)             LENGTH OF SECOND LEVEL MESG 71360020
         B     DOPRINT                      GO PRINT MESSAGE            71400020
NOFIND24 MVC   N0(N8,WORK1),PSYMBOL         SYMBOL TO MESSAGE           71440020
         MVC   N8(N34,WORK1),M0L2FP1        BASIC TEXT TO MESSAGE       71480020
         MVC   N42(N8,WORK1),LOADNAME       LOADNAME TO MESSAGE         71520020
         MVI   N50(WORK1),V40               BLANK SEPARATOR             71560020
         MVC   N51(N8,WORK1),ENTRYNAM       CSECT NAME TO MESSAGE       71600020
         LA    WORK2,N59(WORK2)             LENGTH OF SECOND LEVEL MESG 71640020
         B     DOPRINT                      GO PRINT MESSAGE            71680020
NOFIND28 MVC   N0(N8,WORK1),PSYMBOL         SYMBOL TO MESSAGE           71720020
         MVC   N8(N16,WORK1),M0L2GP1        BASIC TEXT TO MESSAGE       71760020
         MVC   N24(N8,WORK1),WAREA1         DSECT NAME TO MESSAGE       71800020
         MVC   N32(N33,WORK1),M0L2GP2       OTHER TEXT TO MESSAGE       71840020
         LA    WORK2,N65(WORK2)             LENGTH OF SECOND LEVEL MESG 71880020
         B     DOPRINT                      GO PRINT MESSAGE            71920020
NOFIND32 MVC   N0(N8,WORK1),ENTRYNAM        ENTRYNAME TO MESSAGE        71960020
         MVC   N8(N40,WORK1),M0L2HP1        BASIC TEXT TO MESSAGE       72000020
         MVC   N48(N8,WORK1),LOADNAME       LOADNAME TO MESSAGE         72040020
         LA    WORK2,N56(WORK2)             LENGTH OF SECOND LEVEL MESG 72080020
         B     DOPRINT                      GO PRINT MESSAGE            72120020
NOFIND36 MVC   N0(N8,WORK1),ENTRYNAM        CSECT NAME TO MESSAGE       72160020
         MVC   N8(N63,WORK1),M0L2IP1        BASIC TEXT TO MESSAGE       72200020
         LA    WORK2,N71(WORK2)             LENGTH OF SECOND LEVEL MESG 72240020
         B     DOPRINT                      GO PRINT MESSAGE            72280020
NOFIND40 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         72320020
         MVC   N8(N25,WORK1),M0L2JP1        BASIC TEXT TO MESSAGE       72360020
         MVC   N33(N8,WORK1),ENTRYNAM       CSECT NAME TO MESSAGE       72400020
         MVC   N41(N20,WORK1),M0L2JP2       OTHER TEXT TO MESSAGE       72440020
         LA    WORK2,N61(WORK2)             LENGTH OF SECOND LEVEL MESG 72480020
         B     DOPRINT                      GO PRINT MESSAGE            72520020
NOFIND44 MVC   N0(N8,WORK1),LOADNAME        LOADNAME TO MESSAGE         72560020
         MVC   N8(N57,WORK1),M0L2KP1        BASIC TEXT TO MESSAGE       72600020
         LA    WORK2,N65(WORK2)             LENGTH OF SECOND LEVEL MESG 72640020
         B     DOPRINT                      GO PRINT MESSAGE            72680020
*                                                                       72720020
*        MESSAGE   IKJ57281I                                            72760020
*                                                                       72800020
NOTABLE  EQU   *                                                        72840020
         BAL   RETURN,MSGRT1                GO SET UP FOR MESSAGES      72880020
         MVC   N4(N17,WORK1),M1L1P1         FIRST PART MESG TO BUFFER   72920020
         LA    WORK2,N21                    LENGTH OF MESG, SO FAR      72960020
         BAL   RETURN,MSGRT2                GO ADD ADDRESS TO MESSAGE   73000020
         MVC   N0(N29,PARMREG1),M1L1P2      REST OF MESSAGE TO BUFFER   73040020
         LA    WORK2,N29(WORK2)             FINAL LENGTH OF MESSAGE     73080020
         LA    WORK3,M1L1P1                 ADDR OF ID FOR SECOND LEVEL 73120020
         BAL   RETURN,MSGRT3                GO SET UP FOR SECOND LEVEL  73160020
*                                                                       73200020
*        SECOND LEVEL FOR IKJ57281I                                     73240020
*                                                                       73280020
         B     M1GETSEC(WORK5)              GO GET PROPER SECOND LEVEL  73320020
M1GETSEC B     CODEONLY                     GO GIVE RET CODE ONLY       73360020
         B     SYSERR04                     ERROR CODE 04, MESG M1L2B   73400020
SYSERR04 MVC   N0(N28,WORK1),M1L2BP1        BASIC TEXT TO MESSAGE       73440020
         MVC   N28(N8,WORK1),DDNAME         DDNAME TO MESSAGE           73480020
         LA    WORK2,N36(WORK2)             LENGTH OF SECOND LEVEL MESG 73520020
         B     DOPRINT                      GO PRINT MESSAGE            73560020
*                                                                       73600020
*        SUB ROUTINES FOR MESSAGE BUILDING                              73640020
*                                                                       73680020
MSGRT1   EQU   *                                                        73720020
         LR    WORK4,PARMREG1               RETURN CODE FOR CALLER      73760020
         LR    WORK5,RETCODE                SECOND LEVEL MESSAGE NUMBER 73800020
         TM    TSTFLGS3,SYMMESG             SHOULD WE PRINT A MESSAGE   73840020
         BO    CODEONLY                     NO, GO GIVE RETURN CODE     73880020
         LTR   RETCODE,RETCODE              IS UNRESOLVED RETURN CODE 0 73920020
         BZ    CODEONLY                     YES, GO GIVE RETURN CODE    73960020
         LA    WORK1,BUFFER                 ADDR OF FIRST LEVEL BUFFER  74000020
         ST    WORK1,WAREA3                 TO A DOUBLE WORD FOR I/O    74040020
         LA    WORK3,MIDBUFF                ADDR OF SECOND LEVEL BUFFER 74080020
         ST    WORK3,WAREA3+N4              TO A DOUBLE WORD FOR I/O    74120020
         BR    RETURN                       RETURN TO CALLER            74160020
MSGRT2   EQU   *                                                        74200020
         ST    RETURN,MSGRT214              SAVE RETURN ADDRESS         74240020
         LA    PARMREG1,N0(WORK1,WORK2)     NEXT LOCATION IN BUFFER     74280020
         LR    PARMREG0,PDEB                POINTER TO ADDRESS PDE      74320020
         L     RETCODE,TSTADDR              PTR TO ADDRESS BUILD RT     74360020
         BALR  RETURN,RETCODE               GO ADD ADDRESS TO MESSAGE   74400020
         AR    WORK2,PARMREG0               LENGTH OF MESSAGE, SO FAR   74440020
         L     RETURN,MSGRT214              RETURN ADDRESS              74480020
         BR    RETURN                       RETURN TO CALLER            74520020
MSGRT3   EQU   *                                                        74560020
         SLL   WORK2,N16                    LL00 FIELD FOR FIRST LEV    74600020
         ST    WORK2,BUFFER                 PREFIX MESG WITH LL00 FIELD 74640020
         LA    WORK1,MIDBUFF                ADDR OF SECOND LEVEL BUFFER 74680020
         MVC   N4(N10,WORK1),N0(WORK3)      MESG ID FOR SECOND LEVEL    74720020
         LA    WORK2,N14                    LENGTH OF SECOND LEV SO FAR 74760020
         LA    WORK1,N0(WORK1,WORK2)        NEXT LOATION IN BUFFER      74800020
         BR    RETURN                       RETURN TO CALLER            74840020
*                                                                       74880020
*        PUT OUT MESSAGE                                                74920020
*                                                                       74960020
DOPRINT  SLL   WORK2,N16                    CREATE LL00 FIELD           75000020
         ST    WORK2,MIDBUFF                PREFIX 2ND LEV MESG - LL00  75040020
         LA    PARMREG1,WAREA3              POINTER TO POINTERS         75080020
         BAL   RETURN,TERMIO                GO PUT MESG TO TERMINAL     75120020
CODEONLY EQU   *                                                        75160020
         LR    RETCODE,WORK4                RETURN CODE FOR CALLER      75200020
         B     TOCALLER                     GO BACK                     75240020
         SPACE 2                                                        75280020
*********************************************************************** 75320020
*                                                                     * 75360020
*        THIS IS THE SYNAD ROUTINE FOR READING SECONDARY  STORAGE.    * 75400020
*        THE SYNADAF ROUTINE IS USED TO OBTAIN A SYSTEM INFO MESG.    * 75440020
*        THE SYNAD ROUTINE WILL CHECK FOR AN ATTEMPT TO READ A RECORD * 75480020
*        GREATER THAN 256 BYTES.  SUCH A RECORD WOULD IMPLY THE END   * 75520020
*        OF CESD RECORDS AND WOULD NOT BE A REAL I/O ERROR            * 75560020
*                                                                     * 75600020
*********************************************************************** 75640020
         SPACE 2                                                        75680020
SYMSYNAD EQU   *                                                        75720020
         L     SYMB2,SECENTRY               ESTABLISH ADDRESSABILITY    75760020
         SYNADAF   ACSMETH=BPAM                                         75800020
         LR    WORK2,SYMWKB                 SAVE ADDR OF SYNADAF SAVE   75840020
         L     SYMWKB,N4(SYMWKB)            ADDRESS OF MY WORK AREA     75880020
         LA    WORK1,MIDBUFF                ADDR OF SECOND LEVEL BUFFER 75920020
         MVC   N21(N90,WORK1),N38(PARMREG1)  SYNADAF MESG TO BUFFER     75960020
         ST    WORK1,WAREA1+N4              ADDR OF 2ND LEVEL IN DWORD  76000020
         LR    SYMWKB,WORK2                 RESTORE SYNADAF SAVE PTR    76040020
         SYNADRLS                                                       76080020
         LA    PARMREG1,CLOSELST            ADDR OF LIST FORM OF CLOSE  76120020
         LA    WORK1,PDSDCB                 ADDR OF DCB TO CLOSE        76160020
         CLOSE ((WORK1)),MF=(E,(PARMREG1))                              76200020
         LA    WORK1,MIDBUFF                ADDR OF SECOND LEV BUFFER   76240020
         CLC   WLENRCD(N15),N53(WORK1)      IS ERR WRONG LEN RECORD     76280020
         BNE   GIVEMESG                     NO, GO GIVE I/O ERROR MESG  76320020
         LA    RETCODE,N32                  ENTRYNAME NOT IN CESD RCDS  76360020
         B     NOFIND                       ERROR, NO MORE CESD RCDS    76400020
GIVEMESG EQU   *                                                        76440020
         MVC   MIDBUFF+N4(N26),M1L2AP1      SECOND LEVEL BASIC TEXT     76480020
         LA    WORK2,N110                   LENGTH OF MESSAGE           76520020
         SLL   WORK2,N16                    LEN IN HIGH, ZEROES IN LOW  76560020
         ST    WORK2,MIDBUFF                PREFIX 2ND LEVEL I/O ERRMSG 76600020
         LA    WORK1,BUFFER                 ADDR OF FIRST LEVEL BUFFER  76640020
         MVC   N4(N17,WORK1),M1L1P1         BASIC FIRST LEVEL TEXT      76680020
         LA    WORK2,N21                    LENGTH OF 1ST LEV, SO FAR   76720020
         LR    PARMREG0,PDEB                ADDRESS OF ADDRESS PDE      76760020
         LA    PARMREG1,N0(WORK1,WORK2)     NEXT LOCATION IN BUFFER     76800020
         L     RETCODE,TSTADDR              ADDRESS OF ADDR BUILD RT    76840020
         BALR  RETURN,RETCODE               GO ADD ADDRESS TO MESG      76880020
         AR    WORK2,PARMREG0               LENGTH OF FIRST LEVEL MESG  76920020
         MVC   N0(N29,PARMREG1),M1L1P2      OTHER TEXT TO FIRST LEVEL   76960020
         LA    WORK2,N29(WORK2)             LENGTH OF FIRST LEVEL MESG  77000020
PRINTIT  SLL   WORK2,N16                    CREATE LL00 FIELD           77040020
         ST    WORK2,BUFFER                 PREFIX MESG WITH LL00 FIELD 77080020
         LA    WORK2,BUFFER                 ADDR OF FIRST LEVEL MESSAGE 77120020
         ST    WORK2,WAREA1                 ADDR OF 1ST LEVEL IN DWORD  77160020
         LA    PARMREG1,WAREA1              POINTER TO POINTERS         77200020
         BAL   RETURN,IOERROUT              GO PUT MESG TO TERMINAL     77240020
         LA    RETCODE,N12                  IO ERR, RET CODE=12, GO     77280020
         B     TOCALLER                     GO RETURN TO CALLER         77320020
         SPACE 3                                                        77360020
*********************************************************************** 77400020
*                                                                     * 77440020
*        CONSTANTS                                                    * 77480020
*                                                                     * 77520020
*********************************************************************** 77560020
         SPACE 2                                                        77600020
BPAMDCB  DCB   DSORG=PO,MACRF=(R),RECFM=U,BLKSIZE=N256,                C77640020
               SYNAD=SYMSYNAD                                           77680020
ENDBPAM  EQU   *                                                        77720020
         READ  SSDECB,SF,,,'S',,,MF=L                                   77760020
ENDSDECB EQU   *                                                        77800020
LFSTAE   DS    0F                                                       77840020
         STAE  MF=L                                                     77880020
ELFSTAE  EQU   *                                                        77920020
LFOPEN   OPEN  (,),MF=L                                                 77960020
ELFOPEN  EQU   *                                                        78000020
LFCLOSE  CLOSE (,),MF=L                                                 78040020
ELFCLOSE EQU   *                                                        78080020
LFGET    GETMAIN   MF=L                                                 78120020
ELFGET   EQU   *                                                        78160020
         SPACE 3                                                        78200020
*********************************************************************** 78240020
*                                                                       78280020
IKJEGSMG CSECT          ,    MESSAGES FOR IKJEGSYM                      78320020
*                                                                       78360020
*********************************************************************** 78400020
*        THIS SECTION OF IKJEGSYM CONTAINS THE ERROR MESSAGES.  THE   * 78440020
*        MESSAGES ARE MOVED TO BUFFER AREA IN THE MAIN SECTION WHILE  * 78480020
*        PERTINENT SYMBOLIC NAMES ARE ADDED.                          * 78520020
*                                                                     * 78560020
*********************************************************************** 78600020
         SPACE 2                                                        78640020
*                                                                       78680020
*        MESSAGE   IKJ57280I                                            78720020
*                                                                       78760020
M0L1P1   DC    C'IKJ57280I ADDRESS '                       MESG TEXT    78800020
M0L1P2   DC    C' NOT FOUND+'                              MESG TEXT    78840020
M0L2AP1  DC    C' NOT FOUND UNDER THE TEST TASK STRUC'     MESG TEXT    78880020
         DC    C'TURE, SYMBOLS UNAVAILABLE'                MESG TEXT    78920020
M0L2BP1  DC    C' LOADED BY OS LOADER, INTERNAL SYMBOL'    MESG TEXT    78960020
         DC    C'S UNAVAILABLE'                            MESG TEXT    79000020
M0L2CP1  DC    C' NOT BROUGHT INTO MAIN STORAGE UNDER '    MESG TEXT    79040020
         DC    C'TEST, SYMBOLS UNAVAILABLE'                MESG TEXT    79080020
M0L2DP1  DC    C' LOADED BY OS LOADER, NOT ENOUGH MAIN'    MESG TEXT    79120020
         DC    C' STORAGE FOR EXTERNAL SYMBOLS'            MESG TEXT    79160020
M0L2EP1  DC    C' LINK EDITED WITHOUT TEST PARAMETER, '    MESG TEXT    79200020
         DC    C'INTERNAL SYMBOLS UNAVAILABLE'             MESG TEXT    79240020
M0L2FP1  DC    C' NOT IN INTERNAL SYMBOL TABLE FOR '       MESG TEXT    79280020
M0L2GP1  DC    C' FOUND IN DSECT '                         MESG TEXT    79320020
M0L2GP2  DC    C' FOR WHICH NO BASE ADDRESS EXISTS'        MESG TEXT    79360020
M0L2HP1  DC    C' NOT FOUND IN EXTERNAL SYMBOL TABLE F'    MESG TEXT    79400020
         DC    C'OR '                                      MESG TEXT    79440020
M0L2IP1  DC    C' ASSEMBLED WITHOUT TEST PARAMETER, IN'    MESG TEXT    79480020
         DC    C'TERNAL SYMBOLS UNAVAILABLE'               MESG TEXT    79520020
M0L2JP1  DC    C' LINK EDITED IN OVERLAY, '                MESG TEXT    79560020
M0L2JP2  DC    C' NOT IN MAIN STORAGE'                     MESG TEXT    79600020
M0L2KP1  DC    C' FROM DATASET IN A LINK LIBRARY LIST,'    MESG TEXT    79640020
         DC    C' SYMBOLS UNAVAILABLE'                     MESG TEXT    79680020
*                                                                       79720020
*        MESSAGE   IKJ57281I                                            79760020
*                                                                       79800020
M1L1P1   DC    C'IKJ57281I SYMBOL '                        MESG TEXT    79840020
M1L1P2   DC    C' NOT AVAILABLE, SYSTEM ERROR+'            MESG TEXT    79880020
M1L2AP1  DC    C'IKJ57281I I/O SYNAD ERROR '               MESG TEXT    79920020
M1L2BP1  DC    C'CANNOT OPEN DATASET, DDNAME '             MESG TEXT    79960020
*                                                                       80000020
*        MESSAGE   IKJ57282I                                            80040020
*                                                                       80080020
NOCOREMG DC    A(M2L1P1)                    ADDRESS OF FIRST LEVEL MESG 80120020
         DC    A(M2L2AP1)                   ADDR OF SECOND LEVEL MESG   80160020
M2L1P1   DC    H'48'                                       BUFFER LEN   80200020
         DC    H'0'                                        ZEROES       80240020
         DC    C'IKJ57282I NOT ENOUGH STORAGE TO USE S'    MESG TEXT    80280020
         DC    C'YMBOLS+'                                  MESG TEXT    80320020
M2L2AP1  DC    H'54'                                       BUFFER LEN   80360020
         DC    H'0'                                        ZEROES       80400020
         DC    C'IKJ57282I ABSOLUTE OR RELATIVE ADDRES'    MESG TEXT    80440020
         DC    C'S MAY BE USED'                            MESG TEXT    80480020
         EJECT                                                          80520020
*                                                                       80560020
*        OTHER EQUATES                                                  80600020
*                                                                       80640020
LENDCB   EQU   ENDBPAM-BPAMDCB              LEN OF DCB                  80680020
LENDECB  EQU   ENDSDECB-SSDECB              LEN OF LIST FORM OF READ    80720020
LENSTAE  EQU   ELFSTAE-LFSTAE               LEN OF LIST FORM OF STAE    80760020
LENOPEN  EQU   ELFOPEN-LFOPEN               LEN OF LIST FORM OF OPEN    80800020
LENCLOSE EQU   ELFCLOSE-LFCLOSE             LEN OF LIST FORM OF CLOSE   80840020
LENGET   EQU   ELFGET-LFGET                 LEN OF LIST FORM OF GETMAIN 80880020
LSYMWORK EQU   ESYMWORK-SYMWORK             LEN OF SYMWORK AREA         80920020
         EJECT                                                          80960020
CVT      DSECT                                                          81000020
         CVT                                                            81040020
         EJECT                                                          81080020
         IKJTCB                                                         81120020
         EJECT                                                          81160020
         IKJRB                                                          81200020
         END                                                            81240020
