         TITLE 'IKJEGWHR, ''WHERE'' SUBCOMMAND OF TEST'                 00120020
*********************************************************************** 00130020
*                                                                     * 00140020
* STATUS -- RELEASE LEVEL 21.6                                          00210000
* FUNCTION -- THIS SUBCOMMAND RESULTS IN THE QUALIFICATION (ABSOLUTE  * 00350020
*    ADDRESS) FOR THE SPECIFIED ADDRESS BEING DISPLAYED AT THE        * 00420020
*    TERMINAL. IF NO ADDRESS IS ENTERED THE INSTRUCTION COUNTER OF THE* 00490020
*    CURRENT PROBLEM PROGRAM IS DISPLAYED. IF AN ADDRESS IS AN        * 00560020
*    UNQUALIFIED SYMBOLIC OR RELATIVE, THE CURRENT INPLICIT           * 00630020
*    QUALIFICATION IS DISPLAYED. IF THE ADDRESS IS ABSOLUTE ADDRESS,  * 00700020
*    OR AN ADDRESS EXPRESSION, AN ATTEMPT IS MADE TO LOCATE THE       * 00770020
*    ADDRESS WITHIN THE SUBTASK CONTENTS STRUCTURE. IF THE ADDRESS IS * 00840020
*    FOUND TO FALL WITHIN THE STORAGE EXTENT OF ANY PROGRAM ASSIGNED  * 00910020
*    TO THE PROBLEM PROGRAM TASK OR ANY OF ITS SUBTASKS, THE LOCATION * 00980020
*    WITHIN THE PROGRAM OF THE SPECIFIED ADDRESS IS DISPLAYED AT THE  * 01050020
*    TERMINAL. IT IS IDENTIFIED BY LOAD MODULE NAME, ENTRYNAME (IF    * 01120020
*    THE CESD IS AVAILABLE) AND DISPLACEMENT FROM THE BEGINNING OF    * 01190020
*    THE LOWEST LEVEL OF QUALIFICATION AVAILABLE. IF MORE THAN ONE    * 01260020
*    TASK EXISTS ON THE SUB-TASK QUEUE, THE TCB ADDRESS IS ALSO       * 01330020
*    DISPLAYED. IF LOADNAME.ENTRYNAME IS SPECIFIED THE ABSOLUTE       * 01400020
*    ADDRESS OF THE SPECIFIED LOAD MODULE ENTRY POINT IS DISPLAYED.   * 01470020
*    ENTRYNAME MAY HAVE BEEN OMITTED, IN WHICH CASE THE BEGINNING     * 01540020
*    ADDRESS AT WHICH THE LOAD MODULE IS LOADED IS DISPLAYED. IF MORE * 01610020
*    THEN ONE TASK EXISTS ON THE SUBTASK QUEUE, THE TCB ADDRESS IS    * 01680020
*    ALSO DISPLAYED. IF AN IDENTICAL LOAD MODULE EXISTS ON ANOTHER    * 01750020
*    SUBTASK, THE SAME INFORMATION IS DISPLAYED AS ABOVE FOR THE      * 01820020
*    SECOND OCCURRENCE OF THE MODULE.                                 * 01890020
*                                                                     * 01960020
* ENTRY POINTS --                                                     * 02030020
*         IKJEGWHR -- INITIAL ENTRY POINT.                            * 02100020
*         ADDRVLCK -- VALIDITY CHECK ROUTINE.                         * 02170020
*                                                                     * 02240020
* INPUT -- IS IS EXPECTED THAT REGISTER 9 POINTS TO TCOMTAB UPON      * 02310020
*    ENTRY TO IKJEGWHR. TCOMTAB IS THE COMMUNICATIONS AREA FROM       * 02380020
*    WHICH ALL NEEDED INFORMATION MAY BE ACCESSED.                    * 02450020
*                                                                     * 02520020
* OUTPUT -- DATA MESSAGES CONTAINING PERTINENT INFORMATION, I.E.,     * 02590020
*    ABSOLUTE QUALIFICATION, OFFSET, LOADNAME, CSECTNAME AND TCB      * 02660020
*    ADDRESS, ARE PRINTED ON THE TERMINAL LISTING.                    * 02730020
*                                                                     * 02800020
* EXTERNAL REFERENCES --                                              * 02870020
*         IKJPARS IS ENTERED TO CHECK SYNTAX OF WHERE SUBCOMMANDS. IN * 02940020
*         ADDITION, MUCH OF THE ADDRESS PROCESSING IS DONE WHILE IN   * 03010020
*         IKJPARS.                                                    * 03080020
*                                                                     * 03150020
*         IKJEGCVT IS ENTERED TO CONVERT THE USER SUPPLIED ADDRESS    * 03220020
*         TO HEXIDECIMAL                                              * 03290020
*                                                                     * 03360020
*         IKJEGSYM IS ENTERED FIRST TO ACCESS A CSECT NAME IN THE     * 03430020
*         INDICATED LOADNAME, AND SECOND TO SEARCH THE SYMBOL TABLE   * 03500020
*         FOR A GIVEN LOADNAME.CSECT.                                 * 03570020
*                                                                     * 03640020
*         IKJEGIO IS CALLED TO PRINT INDICATED MESSAGES.              * 03710020
*                                                                     * 03780020
* EXITS, NORMAL -- WHEN ALL ADDRESS PROCESSING IS COMPLETED, IKJEGWHR * 03850020
*         RETURNS TO MAINLINE.                                        * 03920020
*                                                                     * 03990020
* EXITS, ERROR  --                                                    * 04060020
*         NONE                                                        * 04130020
*                                                                     * 04200020
* TABLES/WORKAREAS -- THE WORKAREA POINTER PROVIDED IN TCOMTAB IS     * 04270020
*    THE ONLY WORKAREA USED.                                          * 04340020
*                                                                     * 04410020
* ATTRIBUTES -- REFRESHABLE AND REENTRANT                             * 04480020
*                                                                     * 04550020
* CHARACTER CODE DEPENDENCY --                                        * 04620020
*                                                                     * 04690020
* NOTES -- IBM STANDARD LINKAGE CONVENTIONS WERE USED.                * 04760020
*                                                                     * 04830020
*                                                                     * 04900020
*********************************************************************** 04970020
IKJEGWHR CSECT                                                          05120020
*RELEASE 21.6 CHANGES                                                   05170021
*A386100                                                        SA49864 05172021
*C360000,C363200                                                SA49864 05174021
*A308600,A312600,A314400                                        SA49886 05180021
*C701600,C702400,C704000,C704460,C704500,C704740,C704760        SA49886 05190021
         ENTRY IKJEGVLC       ENTRY POINT FOR VALIDITY CHECK            05200020
         USING TCOMTAB,R9     OF ADDRESS. ESTABLISH TCOMTAB             05280020
         SAVE (14,12)         ADDRESSIBILITY. SAVE REGISTERS            05360020
************************************************************            05440020
**                                                        **            05520020
** AFTER REGISTERS HAVE BEEN SAVED THE ADDRESS OF A       **            05600020
** SAVE AREA IS OBTAINED FROM TCOMTAB. FORWARD AND BACK   **            05680020
** WARD CHAINING IS ACCOMPLISHED. THE ADDRESS OF THE PCL  **            05760020
** (PARAMETER CONTROL LIST) IS PLACED INTO A REGISTER TO  **            05840020
** BE PUT WITHIN THE PARAMETER LIST TO BE PASSED TO PARSE.**            05920020
** THE PARAMETER LIST WILL BE BUILT IN THE WORKAREA WHOSE **            06000020
** ADDRESS IS GOTTEN FROM TCOMTAB. PARMLIST  ADDRESS IS   **            06080020
** ALSO GOTTEN FROM TCOMTAB. PARMLIST CONTAINS UPT, ECT   **            06160020
** AND CHECK ELEMENTS OF THE PARAMETER LIST. ADDRESS OF   **            06240020
** MY SAVE AREA IS ALSO PLACED INTO THE LIST. THE COMPLETE**            06320020
** LIST IS PASSED TO THE PARSING ROUTINE VIA REG 1 AND    **            06400020
** THE LINK MACRO                                         **            06480020
************************************************************            06560020
         LR    R12,R15        RESTORE R12 TO BEGINNING ADDR             06640020
         USING IKJEGWHR,R12   USE ENTERING ADDRESS FOR ADDRESSING       06720020
         L     R2,REGSAVE2    GET ADDR OF MY SAVE AREA FROM TCOMTAB     06800020
*                             ADDRESS OBTAINED FROM TCOMTAB             06880020
         ST    R13,@4(@0,R2)  STORE CALLERS SAVE AREA ADDR              06960020
         ST    R2,@8(R13)     STORE MY SAVE IN CALLERS                  07040020
         LR    R13,R2         PLACE ADDR OF MY SAVEAREA INTO            07120020
*                             REG13                                     07200020
         MVC    TSTRETRY+@1(@3),ARETRY PUT ADDR OF RETRY RTN IN TCOMTAB 07280020
         LA     R10,STAETAB   ACCESS ADDR OF STAE EXIT TABLE            07360020
        ST      R10,ABENTAB1  STORE ADDR IN TCOMTAB                     07440020
         L      R10,WORKAREA  ACCESS WORKAREA ADDR FROM TCOMTAB         07520020
         MVC   CWORKCMD-TSTCWORK(ENDLIST,R10),LISTSTAE STAE IN WORKAREA 07600020
         LA    R1,CWORKCMD-TSTCWORK(R10)  PARAMETER TO STAE             07680020
         L     R2,TSTSTAE     ADDR OF STAE EXIT ROUTINE                 07760020
         ST    R12,@68(R13)   SAVE BASE REGISTER                        07840020
          STAE  (R2),MF=(E,(1))    STAE MACRO                           07920020
         LTR   R15,R15        TEST STAE RETURN CODE                     08000020
SMTSTAE  DS    0H             TEST CASE TWHR2700                        08050020
         BNZ   STAE4          BRANCH IF NON ZERO RETURN CODE            08080020
         TM    TSTFLGS3,NOPARMS TEST FOR PARM FIELD WITH WHERE          08160020
         BO    A0009          IF ON, SKIP PARSE AND PROCESS IC          08240020
         L     R4,PARSELST    LOAD PARSE TABLE ADDR INTO REG4           08320020
         L     R1,WORKAREA    LOAD WORKAREA ADDR FROM TCOMTAB           08400020
         LA     R1,PPLSAVE-TSTCWORK(R1) ACCESS COMMAND PORTION          08480020
         USING PPL,R1         ESTABLISH PPL ADDRESSABILITY              08560020
         MVC   PPLUPT(@4),TSTUPT PTR TO UPT FOR PARSE                   08640020
         MVC   PPLECT(@4),TSTECT PTR TO ECT FOR PARSE                   08720020
         MVC   PPLECB(@4),TSTCPECB PTR TO CP ECB FOR PARSE              08800020
         ST    R4,PPLPCL      PTR TO PCL FOR PARSE                      08880020
         ST    R13,PPLUWA     PTR TO MY SAVE AREA FOR PARSE             08960020
         LA    R4,TSTANSPL    ACCESS ADDR OF ANSWER PLACE               09040020
         ST    R4,PPLANS      PTR TO ANSWER PLACE FOR PARSE             09120020
         MVC   PPLCBUF(@4),INBUF PTR TO COMMAND BUFFER                  09200020
         DROP  R1             DROP PPL ADDRESSABILITY                   09280020
         LINK  EP=IKJPARS     LINK TO PARSING ROUTINE TO SCAN INPUT     09360020
BLOW1    EQU   *              STAE ENTRY POINT                          09440020
SMTPARS  DS    0H             TEST CASE TWHR2600                        09490020
         BAL   R14,CHKCDE     TO TEST PARSE RETURN CODE                 09520020
         L     R2,TSTANSPL    ACCESS PDE POINTER                        09600020
         USING IKJPARMD,R2    ESTABLISH PDL ADDRESSABILITY              09680020
         LA    R2,GETADDR     ACCESS ADDR OF PDE                        09760020
         DROP  R2             DROP PDL ADDRESSABILITY                   09840020
         USING IKJPARMA,R2    ESTABLISH PDE ADDRESSABILITY              09920020
         L     R3,PDEUSER     ACCESS USER WORD                          10000020
         LTR   R3,R3          TEST IF NO PARAMETERS ENTERED             10080020
*                             (ONLY APPLIES IF NULL RETURN IS USED      10160020
*                             DURING REENTER MODE)                      10240020
         BNZ   A0008          BYPASS PUTTING OUT IC                     10290020
         TM    PDEFLG4,ABSADDR+SYMADDR TEST FOR ABSOLUTE 0              10300020
         BZ    A0009          TO PUT OUT IC                             10320020
A0008    EQU    *             EQUATE LABEL TO THIS ADDRESS              10400020
         XR    R15,R15        ZERO OUT R15 FOR RETURN CODE              10480020
RET      EQU   *                                                        10560020
         L     R13,@4(R13)                                              10640020
         RETURN (14,12),RC=(15) RETURN TO MAINLINE                      10720020
STAE4    EQU   *              ENTER HERE IF STAE RETURN CODE = 4        10800020
         L     R1,MSSG7       INSUFFICIENT STORAGE MSG                  10880020
         B     COMMON         CODE TO CALL IO                           10960020
CHKCDE   EQU   *                                                        11040020
         B     *+@4(R15)      BRANCH ACCORDING TO CODE                  11120020
         BR    R14            RETURN CODE = 0                           11200020
         BR    R14            FOR ALIGNMENT PURPOSES                    11280020
         B     RETCDE4        RETURN CODE = 4                           11360020
         B     RETCDE8        RETURN CODE = 8                           11440020
         B     RETCDE12       RETURN CODE = 12                          11520020
         B     RETCDE16       RETURN CODE = 16                          11600020
         B     RETCDE20       RETURN CODE = 20                          11680020
A0009    EQU   *              EQUATE LABEL TO ADDRESS                   11760020
*************************************************************           11840020
**AT THIS POINT WE ASSUME NO SUB-COMMANDS HAVE BEEN ENTERED**           11920020
**AND WILL RETURN TO THE TERMINAL THE CURRENT INSTRUCTION  **           12000020
**COUNTER ADDRESS.                                         **           12080020
*************************************************************           12160020
         L     R4,PPTCB       GET ADDRESS OF PROBLEM PROG TCB           12240020
         USING TCB,R4         USE REG4 TO ADDRESS TCB                   12320020
         L     R4,TCBRBP      GET ADDRESS OF INITIAL REQUEST BLK        12400020
A0010    EQU   *              EQUATE LABEL TO THIS ADDRESS              12480020
         USING RBDSECT,R4     USE REG4 TO ADDRESS RB                    12560020
         TM    RBSTAB,HEXC0   TEST IF WE HAVE A SYSTEM RB               12640020
         BNZ   A0012          IF WE DONT LETS TEST SOME MORE            12720020
         L     R2,RBOPSW+@4   LOAD RESUME PSW                           13120020
         BAL   R14,CONVERT    BRANCH TO CONVERT ROUTINE                 13200020
         L     R1,OUTBUF      PLACE POINTER TO OUTPUT AREA IN R1        13280020
         LA    R3,@8(R1)      PLACE ADDRESS FROM INSIDE OUTPUT          13360020
*                             AREA INTO R3                              13440020
         ST    R3,@0(R1)      PLACE ADDRESS INTO MSG POINTER            13520020
         XR    R3,R3          ZERO OUT RE3 TO PLACE IN 2 WORD OF        13600020
*                             MSG POINTER                               13680020
         ST    R3,@4(R1)      PLACE ZEROES INTO 2 WORD OF MSG PTR       13760020
         EX    R10,ICMVC      PUT CONVERTED IC IN BUFFER                13840020
         LA    R3,@6(R10)     CREATE LENGTH COUNT                       13920020
         STH   R3,@8(R1)      PLACE LENGTH FIELD INTO FIRST WORD        14000020
         LA    R10,@13(R10,R1) UPDATE BUFFER POINTER                    14080020
         MVI   @0(R10),DOT    PERIOD TO INDICATE ABSOLUTE ADDRESS       14160020
         BAL   R14,PUTC       TO OUTPUT MSG                             14240020
         NI    TSTFLGS2,HEXFF-TADDROUT TURN OFF MSG PUT TO TERM SW      14320020
         B     A0008          BRANCH TO RETURN TO CALLER                14400020
ICMVC    MVC   @12(@1,R1),@0(R2)  MOVE EBCDIC ADDRESS INTO OUTPU T      14480020
A0012     EQU   *             EQUATE LABEL TO THIS ADDRESS              14560020
          L     R4,RBLINK     PLACE POINTER TO NEXT RB INTO R4          14640020
         DROP  R4                                                       14720020
          B     A0010         BRANCH TO PROCESS THIS RB                 14800020
RETCDE4  EQU   *                                                        14850020
         OI    TSTFLGS4,TSTFLUSH TELL MNLINE TO FLUSH STACK             14900020
         B     A0008          RETURN TO MNLINE WITH ZERO                14950020
RETCDE12  EQU   *                                                       15120020
          L     R1,MSSG9      UNABLE TO PARSE COMMAND MSG               15200020
          B     COMMON        GO TO IO PREPARATION                      15280020
RETCDE16    EQU   *                                                     15360020
          L     R1,MSSG7      INSUFFICIENT STORAGE MSG                  15440020
          B     COMMON        GO TO IO PREPARATION                      15520020
RETCDE20  EQU   *                                                       15530020
          L     R8,WORKAREA   ACCESS PTR TO WORKAREA                    15540020
          L     R15,CODESAVE-TSTCWORK(R8) ACCESS STORED RETURN CODE     15570020
          LA    R14,@16       FOR RETURN CODE COMPARISON                15580020
          CR    R15,R14       TEST RETURN CODE                          15582020
          BE    RET           IF EQUAL RETURN 16 TO MNLINE              15590020
          BH    SEND20        OHTERWISE SEND 20 TO MNLINE               15592020
          XR    R15,R15       SEND 0 IF LESS THAN 16                    15594020
          B     RET           RETURN TO MNLINE                          15596020
SEND20    EQU   *                                                       15598020
          LA    R15,@20       RETURN CODE TO MAINLINE                   15598420
          B     RET           RETURN TO MNLINE                          15598820
RETCDE8   EQU   *                                                       15600020
          LA    R15,@16       RETURN CODE TO MNLINE                     15680020
          B     RET           RETURN TO MNLINE                          15840020
COMMON    EQU   *                                                       15920020
          LCR   R1,R1         INDICATE MSG TO IO                        16000020
          L     R15,TPUTADDR  LOAD IO ADDR                              16080020
          BALR  R14,R15       BRANCH TO IO                              16160020
          L     R2,WORKAREA   ACCESS WORKAREA PTR                       16210020
          LA    R14,@16       FOR COMPARISON PURPOSES                   16230020
          CR    R14,R15       TEST RETURN CODE                          16240020
          BE    GOHOME        IF RETURN CODE EQUALS 16                  16300020
          B     A0008         RETURN TO MNLINE WITH ZERO                16310020
RETRY     EQU   *                                                       16320020
          L     R2,@16        ACCESS PTR TO CVT                         16400020
          USING CVT,R2        ESTABLISH CVT ADDRESSABILITY              16480020
          L     R3,CVTTCBP    ACCESS TCB PTR                            16560020
          L     R3,@4(R3)     ACCESS CURRENT TCB PTR                    16640020
          USING TCB,R3        ESTABLISH TCB ADDRESSABILITY              16720020
          L     R9,TCBTRN     PTR TO TCOMTAB                            16800020
          L     R13,REGSAVE2  ACCESS SAVE AREA                          16880020
          L     R12,@68(R13)  ACCESS BASE REGISTER                      16960020
          DROP  R2            DROP CVT ADDRESSABILITY                   17040020
          DROP  R3            DROP TCB ADDRESSABILITY                   17120020
          LTR   R0,R0         STAE WORKAREA INDICATOR                   17200020
         BNZ   NOFREE         IF INDICATOR N.E. TO 0, THEN NO FREEMAIN  17280020
         L     R0,SUBPOOL     SUBPOOL + BYTE LENGTH IN SUBPOOL          17360020
         FREEMAIN R,LV=(R0),A=(R1)  FREE STAE WORKAREA                  17440020
NOFREE   EQU   *              ENTER HERE IF NO FREEMAIN IS ISSUED       17520020
         NI    TSTFLGS2,HEXFF-TADDROUT-TOFFDEF  TURN OFF FLAGS          17600020
         NI    TSTFLGS1,HEXFF-TSTFIRST TURN OF FLAG                     17650020
         LA    R15,@20        RETURN CODE OF 20 TO MAINLINE             17680020
         B     RET            RETURN CONVENTIONS                        17760020
************************************************************            17840020
** PARSE WILL RETURN TO THIS ADDRESS SO THAT WE MAY       **            17920020
**VALIDITY CHECK THE ADDRESS ENTERED THRU THE TERMINAL    **            18000020
** WE WILL TRY USING IKJEGCVT AND IKJEGSYM PLUS ACTUALLY  **            18080020
** LOOKING FOR THE ADDRESS WITHIN THE CONTROL BLOCKS      **            18160020
** STRUCTRUE TO CHECK WHETHER THE ADDRESS IS VALID        **            18240020
** INVALID ADDRESSES ARE FLAGGED AS SUCH AND ASKED TO BE  **            18320020
** REENTERED.                                             **            18400020
************************************************************            18480020
IKJEGVLC EQU   *                                                        18560020
         SAVE  (14,12)        SAVE REGISTERS             ***            18640020
         DROP  R12            DROP R12 AS BASE REGISTER    *            18720020
         USING IKJEGVLC,R15   ESTABLISH E.P. ADDRESSABILITY* ESTABLISH  18800020
         L     R2,@4(R1)      ACCESS MY REGISTER SAVEAREA  *            18880020
         LM    R3,R12,@32(R2) RESTORE REGISTERS 3 THRU 12  *ADDRSABLITY 18960020
         USING IKJEGWHR,R12   ESTABLISH ADDRESSABILITY     *            19040020
         DROP  R15            DROP R15 AS BASE REGISTER  ***            19120020
*                                                        ***            19200020
         L     R2,REGSAVE3    ACCESS MY SAVE AREA ADDRESS  * STANDARD   19280020
         ST    R13,@4(R2)     SAVE CALLERS SAVEAREA        *            19360020
         ST    R2,@8(R13)     STORE MY SAVE IN CALLERS     * LINKAGE    19440020
         LR    R13,R2         MY SAVE AREA INTO R13        *            19520020
*                                                        ***CONVENTIONS 19600020
         NI    TSTFLGS2,HEXFF-TADDROUT TURN OFF MSG PUT TO TERM SW      19680020
         L     R2,WORKAREA    ACCESS PTR TO WORKAREA                    19760020
         LA    R3,@8(R1)      CREATE PTR TO PARSE 3RD WORD              19840020
         ST    R3,MSGADDR-TSTCWORK(R2) FUTURE PTR TO 2ND LEVEL MSG      19920020
*                                                                       20000020
         L     R7,@0(R1)      ACCESS PDE ADDRESS                        20080020
         USING IKJPARMA,R7    ESTABLISH PDE ADDRESSABILITY              20160020
         TM    PDEFLG4,GENR   TEST FOR REGISTER NOTATION                20240020
         BNO   FLTREG         BRANCH FOR FURTHER VALIDITY CHECK         20320020
         LH    R3,PDEINDCT    ACCESS INDIRECT COUNT                     20400020
         LTR   R3,R3          IF 0, THEN INVALID REGISTER SPECIFICATION 20480020
         BNZ   FLTREG         BRANCH FOR FURTHER VALIDITY CHECK         20560020
         L     R1,MSSG4       ACCESS DIAGNOSTIC MESSAGE                 20640020
         B     ADDRMSG        TO PROCESS DIAGNOSTIC MESSAGE             20720020
FLTREG   EQU   *                                                        20800020
         TM    PDEFLG4,LFPR+SFPR TEST FOR FLOATING POINT REGISTER       20880020
         BZ    PROCESS        IF NOT SPECIFIED, PROCESS ADDRESS STING   20960020
         L     R1,MSSG4       ACCESS REGISTER DIAGNOSTIC MESSAGE        21040020
         B     ADDRMSG        TO PROCESS DIAGNOSTIC MESSAGE             21120020
PROCESS  EQU   *                                                        21200020
         L     R3,WORKAREA              ***                             21280020
         LA    R3,PDESAVE-TSTCWORK(R3)    * SAVE PDE IN WORKAREA        21360020
         MVC   @0(@25,R3),@0(R7)        ***                             21440020
*                                                          ***          21520020
         TM    PDEFLG2,CTNAMFLG TEST IF CSECT NAME SPECIFIED *          21600020
         BO    QUALSYM        IF SPECIFIED, BRANCH           * TEST FOR 21680020
         L     R3,PDEEXPTR    ACCESS ADDRESS OF ADDR EXP     *          21730020
         LA    R3,@0(R3)      ZERO HI ORDER BYTE             *          21740020
         LTR   R3,R3          TEST FOR ADDR EXP              *          21750020
         BNZ   ADDRPROC       IF ADDR EXP, BRANCH            *          21752020
         TM    PDEFLG3,AFLG   TEST FOR ADDR STRING           *QUALIFIED 21760020
         BNO   ADDRPROC       IF NOT SPECIFIED, BRANCH       * SYMBOL   21840020
         TM    PDEFLG4,SYMADDR TEST FOR SYMBOLIC ADDR        *          21920020
         BNO   ADDRPROC       IF NOT SYMBOL, BRANCH        ***          22000020
         B     SYMBOL         BRANCH IF IT IS A SYMBOL                  22080020
SYMBOL   EQU   *                                                        22160020
         MVC   PDELDNAM(@6),PDEADRPT SYMBOL AND LEN INTO LDNAME         22240020
         L     R1,TSTTCB      ACCESS TEST'S TCB                         22320020
         L     R2,WORKAREA    ACCESS WORKAREA PTR                       22400020
         LA    R1,@0(R1)      CLEAR HI ORDER BYTE                       22480020
         ST    R1,TCBCHAI-TSTCWORK(R2) STORE MOTHER TCB                 22560020
GOCDE    EQU   *                                                        22640020
         BAL R14,TCBCHAIN     BRANCH TO GET TCB ON CHAIN                22720020
         LTR   R1,R1          TEST FOR END OF TCB CHAIN                 22800020
         BZ    ENDTCB         BRANCH IF END OF CHAIN                    22880020
         USING TCB,R1         ESTABLISH TCB ADDRESSABILITY              22930020
         TM    TCBFLGS5,TCBFC TEST IF TCB TERMINATED                    22940020
         BO    GOCDE          IF TERMINATED, GET NEXT TCB ON CHAIN      22950020
         DROP  R1             DROP ADDRESSABILITY TO TCB                22952020
         BAL   R14,CDESRCH    SEARCH CDE FOR LOADNAME MATCH             22960020
         LTR   R0,R0          TEST IF LOADNAME MATCH FOUND              23040020
         BZ    GOCDE          IF NOT GET NEXT TCB                       23120020
         ST    R0,PDEUSER     IF FOUND, STORE LOCATED AT ADDR           23200020
         OI    TSTFLGS2,TADDROUT INDICATE MATCH FOUND (MSG OUTPUT)      23280020
         BAL   R14,LDNMSG     TO BUILD AND OUTPUT MSG                   23360020
         L     R1,TCBSAVE-TSTCWORK(R8) ACCESS STORED TCB                23440020
         LTR   R11,R11        IS THERE A RETURN ADDRESS INDICATED       23520020
         BZ    GOCDE          GET NEXT TCB                              23600020
         BR    R11            TO CONTINUE PROCESSING THE PRESENT TCB    23680020
ENDTCB   EQU   *                                                        23760020
         XR    R15,R15        INDICATE ZERO RETURN CODE                 23840020
         TM    TSTFLGS2,TADDROUT WAS ANY LOADNAME MATCH FOUND           23920020
         BO    GOHOME         IF SO, RETURN TO PARSE                    24000020
         L     R2,WORKAREA    OTHERWISE, ACCESS WORKAREA PTR            24080020
         MVC   PDELDNAM(@25),PDESAVE-TSTCWORK(R2) RESTORE PDE           24160020
         B     ADDRPROC       BRANCH TO FURTHER SEARCH                  24240020
QUALSYM  EQU   *                                                        24320020
         TM    PDEFLG1,LDNAMFLG TEST IF LOADNAME IS WITH CSECT NAME     24400020
         BO    ADDRPROC       IF SO PROCESS ADDRESS                     24480020
         L     R3,WORKAREA    ACCESS WORKAREA POINTER                   24560020
         MVC   CURLD-TSTCWORK(@8,R3),TSTCURLD MOVE CURRENT LOADNAME     24640020
         LA    R4,@8          INITIALIZE REG WITH MAX LEN 8             24720020
         LA    R5,CURLD-TSTCWORK(R3) CREATE PTR TO LOADNAME             24800020
         ST    R5,PDELDNAM    STORE PTR IN PDE                          24880020
         LA    R5,@7(R5)      UPDATE PTR TO END OF LOADNAME             24960020
CHKBLNK  EQU   *                                       *****            25040020
         CLI   @0(R5),BLANK   TEST LAST CHAR FOR BLANK     * REMOVE     25120020
         BNE   STLEN          IF NOT BLANK, BRANCH         *  BLANK     25200020
         BCTR  R4,R0          DECREMENT LENGTH COUNTER     * PADDING    25280020
         BCTR  R5,R0          DECREMENT PTR TO LOADNAME    *  IF ANY    25360020
         B     CHKBLNK        TO TEST FOR BLANK        *****            25440020
STLEN    EQU   *                                                        25520020
         STH   R4,PDELEN1     STORE CALCULATED LENGTH IN PDE            25600020
         B     ADDRPROC       TO PROCESS ADDR                           25680020
ADDRPROC EQU   *                                    ***                 25760020
         LA    R0,@4          MAKE R0 POSITIVE        *                 25810020
         LR    R1,R7          ACCESS ADDR OF PDE      *                 25840020
         LCR   R1,R1          INDICATOR TO TSTCONVT   * CONVERT ADDRESS 25920020
         NI    TSTFLGS3,HEXFF-SYMMESG INDICATE PRINT  *                 26000020
         L     R15,TSTCONVT   ACCESS ADDR OF TSTCONVT *                 26080020
         BALR  R14,R15        BRANCH TO CONVERT     ***                 26160020
         BAL   R14,CODECHK    TO TEST RETURN CODE                       26240020
*                                                                       26320020
         L     R2,PDEUSER     ADDR FROM TSTCONVT         ***            26400020
         LTR   R2,R2          TEST HI ORDER BYTE           * DETERMINE  26480020
         LA    R2,@0(R2)      CLEAR HI ORDER BYTE          *    WHO     26560020
         BH    GOXLST         IF IKJEGCVT RESOLVED ADDR    * RESOLVED   26640020
         L     R2,@0(R2)      IF IKJEGSYM, GET ACTUAL ADDR *  ADDRESS   26720020
         ST    R2,PDEUSER     PUT ACTUAL ADDR IN PDEUSER   *            26800020
         B     GOXLST         TO SEARCH XTENT LIST       ***            26880020
*********************************************************************** 26960020
*                                                                     * 27040020
* THIS CODE ACCESS EACH TCB AND PASSES ITS ADDR IN REGISTER 1 TO CODE * 27120020
* WHICH SEACHES THE EXTENT LISTS FOR THE SAME ADDRESS IN PDEUSER. WHEN* 27200020
* THE ADDRESS IS FOUND, THE CORRESPONDING LOADNAME IS RETURNED IN R0  * 27280020
* IF NOT SUCCESSFUL, R0 WILL CONTAIN ZEROES.                          * 27360020
*                                                                     * 27440020
*********************************************************************** 27520020
GOXLST   EQU   *                                                        27600020
         L     R3,WORKAREA    ACCESS WORKAREA ADDR                      27680020
         ST    R2,USERSAVE-TSTCWORK(R3) SAVE ORIG CONVERTED ADDR        27760020
         L     R1,TSTTCB      ACCESS TEST TCB                           27840020
         LA    R1,@0(R1)      CLEAR HI ORDER BYTE                       27920020
         ST    R1,TCBCHAI-TSTCWORK(R3) STORE MOTHER TCB IN WORKAREA     28000020
NXTCB    EQU   *                                                        28080020
         BAL   R14,TCBCHAIN   TO GET NEXT TCB ON CHAIN                  28160020
         LTR   R1,R1          ANOTHER TCB FOUND                         28240020
         BZ    ENDCHAIN       NO, END XLST SEARCH                       28320020
         USING TCB,R1         ESTABLISH TCB ADDRESSABILITY              28370020
         TM    TCBFLGS5,TCBFC TEST IF TCB TERMINATED                    28380020
         BO    NXTCB          IF TERMINATED, GET NEXT TCB               28390020
         DROP  R1             DROP TCB ADDRESSABILITY                   28392020
         BAL   R14,XLSTSRCH   YES,SEARCH XLST                           28400020
         LTR   R0,R0          XLST SEARCH SUCCESSFUL                    28480020
         BZ    NXTCB          GET NEXT TCB                              28560020
         TM    PDEFLG1,LDNAMFLG TEST IF USER ENTERED LDNAM              28610020
         BO    GETCTN         IF SO, DO NOT ALTER PDE                   28620020
         LR    R2,R0          ACCESS PTR TO LOADNAME                    28640020
         LA    R2,@7(R2)      CREATE PTR TO END OF LOAD NAME            28720020
         LA    R8,@8          MAX LENGTH OF LOADNAME                    28800020
BLNKOFF  EQU   *                                       ****             28880020
         CLI   @0(R2),BLANK   TEST FOR BLANK              * REMOVE      28960020
         BNE   MVCPROG        NO BLANK, BRANCH            *  BLANK      29040020
         BCTR  R8,R0          DECREMENT LENGTH COUNTER    * PADDING     29120020
         BCTR  R2,R0          DECREMENT PTR TO LOADNAME   *  IF ANY     29200020
         B     BLNKOFF        TO TEST FOR BLANK        ****             29280020
PNAMVC   MVC   @0(@1,R6),@0(R2)                                         29360020
TRYALIAS EQU   *              REPLACE LDNAM WITH ALIAS                  29410020
         LA    R8,@8          MAX LENGTH OF ALIAS NAME                  29420020
         L     R6,WORKAREA    ACCESS WORKAREA PTR                       29422020
         LA    R2,ALIASAVE-TSTCWORK(R6) ACCESS PTR TO ALIAS SAVE        29430020
         TM    TSTFLGS1,TSTFIRST  HAVE WE ALREADY TRIED ALIAS           29430120
         BO    NOCTN          IF SO, BRANCH                             29430220
         OI    TSTFLGS1,TSTFIRST  SET FLAG TO INDICATE TRYING ALIAS     29430320
         LR    R0,R2          SAVE PTR TO ALIAS NAME                    29430420
         CLI   @0(R2),BLANK   TEST IF ALIAS EXISTS                      29432020
         BE    NOCTN          GO TO RECOVERY ROUTINE                    29434020
         LA    R2,@7(R2)      CREATE PTR TO END OF ALIAS NAME           29436020
         B     BLNKOFF        TO REMOVE BLANK PADDING                   29438020
NOCTN    EQU   *              RECOVERY ROUTINE IF CSECT NAME NOT FOUND  29438420
         NI    TSTFLGS1,HEXFF-TSTFIRST TURN FLAG OFF                    29439220
         STH   R8,PDELEN2       ST LENGTH OF 8                          29439620
         MVI   @0(R2),BLANK     PUT BLANK IN ALIASAVE                   29439720
         MVC   @0(@7,R2),@0(R2) SPREAD BLANKS THROUGH ALIASAVE          29439820
         ST    R2,PDECTNAM      STORE PTR TO BLANKS AS CSECT NAME PTR   29439920
         NI    TSTFLGS3,HEXFF-SYMMESG TURN OF SUPPRESS MSG FLAG         29456620
         MVC   OFFSET2-TSTCWORK(@4,R6),OFFSET-TSTCWORK(R6) MOVE OFFSET  29466620
         B     RECOVER          RESUME RECOVERY PROCESS                 29470620
MVCPROG  EQU   *                                                        29473320
         OI    PDEFLG1,LDNAMFLG  TURN ON LOADNAME FLAG                  29490020
         STH   R8,PDELEN1     STORE LOADNAME LENGTH                     29520020
         BCTR  R8,R0          DECREMENT FOR EX                          29600020
         L     R6,WORKAREA    ACCESS WORKAREA PTR                       29680020
         LA    R6,LOADNAME-TSTCWORK(R6) CREATE PTR TO LOADNAME AREA     29760020
         ST    R6,PDELDNAM    ST PTR IN PDE                             29840020
         LR    R2,R0          ACCESS LOADNAME PTR                       29920020
         EX    R8,PNAMVC      TO MOVE INTO WORKAREA                     30000020
GETCTN   EQU   *                                                        30050020
         MVI   PDEFLG2,HEX00  INDICATE CSECT NAME NOT PRESENT           30080020
*                                                                       30160020
         LA    R2,@4          LENGTH OF OFFSET (ADDR STRING)            30240020
         STH   R2,PDELEN3     STORE IN PDE LENGTH POINTER               30320020
         L     R6,WORKAREA    ACCESS WORKAREA PTR                       30400020
         LA    R2,OFFSET-TSTCWORK(R6) ACCESS GROSS OFFSET               30480020
         ST    R2,PDEADRPT    STORE OFFSET PTR IN PDE                   30560020
         OI    PDEFLG3,AFLG   TURN ON ADDRESS STRING INDICATOR          30640020
         MVI   PDEFLG4,RELADDR TURN ON RELADDR FLAG AND TURN OFF OTHERS 30720020
         OI    TSTFLGS3,SYMMESG  INDICATE TO SUPPRESS MSG               30850020
         LA    R1,IKJPARMA                                      SA49886 30860021
         BAL   R11,LINKSYM    LINK TO IKJEGSYM TO GET CSECT NAME        30880020
         BAL   R14,CODECHK2   TEST SYM RETURN CODE                      31040020
         L     R6,WORKAREA    REINITIALIZE WORKAREA PTR                 31090020
         XC    PDEADRPT(@7),PDEADRPT CLEAR ADDR PTR, LENGTH AND FLAGS   31120020
         LH    R2,PDELEN2     ACCESS LENGTH OF CSECT NAME               31170020
         BCTR  R2,R0          DECREMENT FOR EXECUTE                     31180020
         L     R1,PDECTNAM    ACCESS PTR TO CSECT NAME                  31182020
         EX    R2,CSECTMVC    MOVE CSECT NAME TO MY WORKAREA            31190020
         LA    R2,CSECTNAM-TSTCWORK(R6) CREATE PTR TO CSECT NAME        31192020
         ST    R2,PDECTNAM    STORE PTR IN PDE                          31194020
         NI    TSTFLGS3,HEXFF-SYMMESG TURN OFF SUPPRESS MSG FLAG        31250020
         LA    R1,IKJPARMA                                      SA49886 31260021
         BAL   R11,LINKSYM    LINK TO SYM FOR CSECT LOCATION            31280020
         BAL   R14,CODECHK2   TEST SYM RETURN CODE              SA49886 31440021
         L     R6,WORKAREA    REINITIALIZE WORKAREA PTR                 31490000
         L     R2,TSTWHR      ACCESS LOADED AT ADDRESS FROM IKJEGSYM    31520020
         L     R3,PDEUSER     CSECT LOCATION                            31600020
         SR    R3,R2          OFFSET OF CSECT FROM LOADED AT ADDR       31680020
         L     R4,OFFSET-TSTCWORK(R6) ACCESS SAVED GROSS OFFSET         31760020
         SR    R4,R3          CALCULATE OFFSET INTO CSECT               31840020
         ST    R4,OFFSET2-TSTCWORK(R6) STORE OFFSET IN WORKAREA         31920020
RECOVER  EQU   *              ENTER HERE IF CSECT NAME WAS NOT FOUND    31970020
         L     R1,TSTTCB      ACCESS TCB ADDRESS                        32000020
         LA    R1,@0(R1)      CLEAR HI ORDER BYTE                       32080020
         ST    R1,TCBCHAI-TSTCWORK(R6) SAVE MOTHER TCB                  32160020
GOTCB1   EQU   *                                                        32240020
         BAL   R14,TCBCHAIN   GET NEXT TCB ON CHAIN                     32320020
         XR    R15,R15        INDICATE ZERO RETURN CODE                 32400020
         LTR   R1,R1          TEST FOR END OF TCB CHAIN                 32480020
         BZ    GOHOME         BRANCH IF END OF CHAIN                    32560020
         USING TCB,R1         ESTABLISH TCB ADDRESSABILITY              32610020
         TM    TCBFLGS5,TCBFC TEST IF TCB TERMINATED                    32620020
         BO    GOTCB1         IF TERMINATED, GET NEXT TCB               32630020
         DROP  R1             DROP TCB ADDRESSABILITY                   32632020
         BAL   R14,CDESRCH    TO SEARCH CDE FOR LOADNAME MATCH          32640020
         LTR   R0,R0          TEST IF MATCH WAS FOUND                   32720020
         BZ    GOTCB1         TO GET NEXT TCB ON CHAIN                  32800020
         L     R6,OFFSET-TSTCWORK(R8)  ACCESS GROSS OFFSET              32880020
         AR    R6,R0          LOAD ADDR + GROSS OFFSET = ASOLUTE ADDR   32960020
         LA    R6,@0(R6)      CLEAR HI ORDER BYTE                       33040020
         LA    R10,PDESAVE-TSTCWORK(R8) ACCESS ADDR OF ORIGINAL PDE     33120020
         TM    @14(R10),CTNAMFLG TEST IF CSECT NAME PRESENT             33200020
         BNO   TPRINT         TO PRINT MSG                              33280020
GOPRNT   EQU   *                                                        33360020
         ST    R6,PDEUSER     STORE ABSOLUTE ADDR IN PDEUSER            33440020
         BAL   R14,OFFMSG     BRANCH TO PRINT MESSAGE                   33520020
         L     R1,TCBSAVE-TSTCWORK(R8) ACCESS CURRENT TCB               33600020
         LTR   R11,R11        TEST FOR RETURN ADDRESS FROM CDESRCH      33680020
         BZ    GOTCB1         IF NONE, GET NEXT TCB                     33760020
         BR    R11            OTHERWISE BRANCH BACK TO CDESRCH          33840020
TPRINT   EQU   *                                                        33920020
         L     R10,USERSAVE-TSTCWORK(R8) ACCESS ORIG CONVERTED ADDR     34000020
         CR    R6,R10         DOES ORIG ADDR = CALCULATED ADDR          34080020
         BE    GOPRNT         IF SO, PRINT MSG                          34160020
         LTR   R11,R11        OTHERWISE CHECK FOR CDESRCH RETURN ADDR   34240020
         BZ    GOTCB1         IF NONE, GET NEXT TCB                     34320020
         BR    R11            OTHERWISE, BRANCH INTO CDESRCH            34400020
ENDCHAIN EQU   *                                                        34480020
         BAL   R14,REGMSG     TO PUT OUT DIAGNOSTIC  MSG                34560020
         XR    R15,R15        INDICATE ZERO RETURN CODE                 34640020
         B     GOHOME         RETURN TO PARSE                           34720020
*                                                                       34800020
LINKSYM  EQU   *                                                        34850020
         LA    R1,SYM         BLDL LIST ENTRY NAME                      34860020
         L     R15,TSTEXPAN   FOR BLDL LIST EXPANSION                   34870020
         BALR  R14,R15        BRANCH TO EXPANSION ROUTINE               34872020
         LTR   R6,R1          TEST IF EXPANSION WAS SUCCESSFUL          34874020
         LR    R1,R7          PDE IN R1 FOR IKJEGSYM                    34874420
         BZ    NOBLDL         BRANCH IF NOT SUCCESSFUL                  34876020
         L     R15,WORKAREA   ACCESS WORKAREA PTR                       34878020
         LA    R15,CWORKCMD-TSTCWORK(R15) PTR TO LIST FORM OF LINK      34878420
         MVC   @0(LINKL,R15),LINKF MOVE IN LIST FORM OF LINK            34878820
         LINK  DE=(6),SF=(E,(15)) LINK TO SYM                           34879220
BLOW2    EQU   *              STAE RESUME ADDRESS                       34879620
         BR    R11            RETURN IN LINE                            34890420
NOBLDL   LINK  EP=IKJEGSYM    LINK TO SYM                               34895820
BLOW3    EQU   *              STAE RESUME ADDRESS                       34901220
SMTSYM02 DS    0H             TEST CASE TTSTC120                        34903220
         BR    R11            RETURN IN LINE                            34906620
*********************************************************************** 34933320
* THIS CODE SEARCHES THE EXTENT LISTS ON THE TCB PASSED IN REG 1      * 34960020
* FOR THE ADDRESS IN PDEUSER.  THE LOADED AT ADDRESS IS USED TO       * 35040020
* ASSOCIATE AN ADDRESS WITH A LOADNAME. A POINTER TO THE LOADNAME     * 35120020
* IS RETURNED IN REG 0, AND A GROSS OFFSET (PDEUSER-LOADED AT         * 35200020
* ADDRESS) IS STORED IN WORKAREA.                                     * 35280020
*********************************************************************** 35360020
XLSTSRCH EQU   *                                                        35440020
         XR    R0,R0          INIT R0 TO INDICATE CTN NOT FOUND         35520020
         L     R8,WORKAREA    ACCESS WORKAREA POINTER                   35570020
         LA    R8,ALIASAVE-TSTCWORK(R8) ACCESS PTR TO ALIAS SAVE AREA   35580020
         MVI   @0(R8),BLANK   TO BLANK OUT ALIAS SAVE                   35590020
         MVC   @1(@7,R8),@0(R8)  INITIALIZE ALIAS SAVE                  35592020
         USING TCB,R1         ESTABLISH TCB ADDRESSABILITY              35600020
         L     R2,TCBRBP      ACCESS RB PTR                             35680020
         USING RBDSECT,R2     ESTABLISH RB ADDRESSABILITY               35760020
RBLOOP   EQU   *                                                        35840020
         TM    RBSTAB,HEXC0   TEST IF PRB                               35920020
         BNZ   XLSTLOP        IF NOT, GET NEXT RB               SA49864 36000021
         L     R3,CDEADDR     IF SO, ACCESS CDE PTR                     36080020
         LA    R3,@0(R3)      CLEAR HI ORDER BYTE                       36160020
         LTR   R3,R3          PTR EQUAL ZERO                            36240020
         BZ    XLSTLOP        IF SO, SKIP THIS RB               SA49864 36320021
CDELOOP  EQU   *                                                        36400020
         USING CDEDSECT,R3    ESTABLISH CDE ADDRESSABILITY              36480020
         TM    NEXTCDE,HEX04  CHECK FOR ALIAS (MINOR CDE)               36560020
         BNO   CONTCDE        IF NOT ALIAS, GET XLST PTR                36640020
         L     R8,WORKAREA    ACCESS WORKAREA POINTER                   36690020
         MVC   ALIASAVE-TSTCWORK(@8,R8),PROGNAME SAVE ALIAS IN WORKAREA 36700020
         L     R3,MJCDE       ACCESS MAJOR CDE                          36720020
         LA    R3,@0(R3)      CLEAR HI ORDER BYTE                       36800020
CONTCDE  EQU   *                                                        36880020
         L     R5,XLADDR      ACCESS XLST PTR                           36960020
         USING XLDSECT,R5     ESTABLISH XLST ADDRESSABILITY             37040020
         TM    CDATTR2,HEX80  TEST FOR OBJECT                           37090020
         L     R6,LOCCSCT     ACCESS LOADED AT ADDRESS                  37100020
         BNO   GETLOC         CONTINUE PROCESSING                       37110020
         LA    R15,@2         FOR FUTURE COMPARISON                     37112020
         CL    R15,NUMCSECT   DETERMINE IF TWO ENTRIES                  37114020
         BNE   GETLOC         CONTINUE PROCESSING                       37116020
         L     R6,LOCCSCT+@4  ACCESS LOADED AT ADDRESS                  37118020
GETLOC   EQU   *                                                        37118420
         LA    R6,@0(R6)      CLEAR HI ORDER BYTE                       37200020
         L     R11,LENCSCT    ACCESS LENGTH OF CSECT                    37280020
         LA    R11,@0(R6,R11) CREATE END ADDR FOR CSECT                 37360020
         L     R8,PDEUSER     ACCESS ADDR IN PDEUSER                    37440020
         CLR   R6,R8          PDEUSER G.T. THIS LOADED AT ADDR          37520020
         BH    XLSTLOOP       IF NOT GET NEXT CDE                       37600020
         CLR   R11,R8         PDEUSER L.T. CSECT END ADDR               37680020
         BNH   XLSTLOOP       IF NOT, GET NEXT CDE                      37760020
         SLR   R8,R6          COMPUTE OFFSET                            37840020
         L     R2,WORKAREA    ACCESS WORKAREA PTR                       37920020
         ST    R8,OFFSET-TSTCWORK(R2) STORE GROSS OFFSET                38000020
         LA    R0,PROGNAME    RETURN PTR TO LOADNAME                    38080020
RETHOME  EQU   *                                                        38160020
         NI    TSTFLGS2,HEXDF TURN OFF LOAD LIST INDICATOR              38240020
         BR    R14            RETURN AND GET ANOTHER TCB                38320020
XLSTLOOP EQU   *                                                        38400020
         TM    TSTFLGS2,TOFFDEF ARE WE USING LOAD LIST CDE'S            38480020
         BO    GOLLE          IF SO, GET NEXT LLE                       38560020
XLSTLOP  EQU   *                                                SA49864 38610021
         L     R2,RBLINK      OTHERWISE ACCESS NEXT RB                  38640020
         LA    R2,@0(R2)      CLEAR HI ORDER BYTE                       38720020
         CR    R1,R2          DOES RBLINK POINT TO TCB                  38800020
         BNE   RBLOOP         IF NOT, PROCESS THIS RB                   38880020
         L     R2,TCBLLS      OTHERWISE, ACCESS LOAD LIST PTR           38960020
         OI    TSTFLGS2,TOFFDEF INDICATE USING LOAD LIST, NOT RB        39040020
         USING LLEDSECT,R2    ESTABLISH LOAD LIST ADDRESSABILITY        39120020
LLELOOP  EQU   *                                                        39200020
         LA    R2,@0(R2)      CLEAR HI ORDER BYTE                       39280020
         LTR   R2,R2          TEST FOR END OF LOAD LIST                 39360020
         BZ    RETHOME        IF END OF LOAD LIST, BRANCH               39440020
         L     R3,CDEPTR      OTHERWISE, GET CDE PTR                    39520020
         LA    R3,@0(R3)      CLEAR HI ORDER BYTE                       39600020
         LTR   R3,R3          PTR EQUAL ZERO                            39680020
         BZ    XLSTLOOP       IF SO, SKIP THIS CDE                      39760020
         B     CDELOOP        TO PROCESS NEXT CDE                       39840020
GOLLE    EQU   *                                                        39920020
         L     R2,NEXTLLE     ACCESS PTR TO NEXT LLE                    40000020
         B     LLELOOP        TO PROCESS LLE                            40080020
*********************************************************************** 40160020
* THIS CODE SEARCHES THE TCB PASSED IN REG1 FOR THE LOADNAME INDICATED* 40240020
* IN PDELDNAM. WHEN THE LOADNAME IS FOUND, THE LOADED AT ADDRESS IS   * 40320020
* PASSED BACK IN REG0. IF NOT FOUND, REG0 CONTAINS ZEROES. IF R11     * 40400020
* IS ZERO THE NEXT TCB TO BE SEARCHED SHOULD BE RETURNED IN REG1. IF  * 40480020
* REG11 HAS AN ADDR THEN THE CALLER SHOULD BRANCH ON REG11 SO THAT    * 40560020
* THE REST OF THE CDE'S ON THE PRESENT TCB CAN BE SEARCHED.           * 40640020
*********************************************************************** 40720020
CDESRCH  EQU   *              REG1 POINTS TO TCB- REG7 POINTS TO PDE    40800020
         L     R8,WORKAREA    ACCESS WORKAREA                           40880020
         ST    R14,RETURN-TSTCWORK(R8) SAVE RETURN ADDR                 40960020
         XR    R0,R0          INIT R0 TO INDICATE LO                    41040020
         XR    R11,R11        ZERO POSSIBLE RETURN ADDR                 41120020
         USING TCB,R1         ESTABLISH TCB ADDRESSABILITY              41200020
         L     R3,TCBRBP      ACCESS RB POINTER                         41280020
         USING RBDSECT,R3     ESTABLISH RB ADDRESSABILITY               41360020
RBPROC   EQU   *                                                        41440020
         LA    R3,@0(R3)      ZERO HI ORDER BYTE                        41520020
         CR    R1,R3          DOES RBLINK POINT TO TCB                  41600020
         BE    INITLLE        IF SO,USE LLE CDE                         41680020
         TM    RBSTAB,HEXC0   TEST IF PRB                               41760020
         BNZ   NEXTRB         IF NOT, GET NEXT RB IN CHAIN              41840020
         L     R5,CDEADDR     ACCESS ADDR OF CDE                        41920020
         LA    R5,0(R5)       CLEAR HI ORDER BYTE                       42000020
         LTR   R5,R5          DOES PTR EQUAL ZERO                       42080020
         BZ    NEXTRB         IF SO, SKIP THIS CDE                      42160020
USECDE   EQU   *                                                        42240020
         USING CDEDSECT,R5    ESTABLISH CDE ADDRESSABILITY              42320020
CDEPROC  EQU   *                                                        42400020
         LA    R8,PROGNAME    ACCESS ADDR OF LOADNAME                   42480020
         LA    R8,@7(R8)      UPDATE TO END OF LOADNAME                 42560020
         LA    R6,@8          INITIALIZE LENGTH COUNTER                 42640020
REMBLNK  EQU   *                                                        42720020
         CLI   @0(R8),BLANK   TEST FOR BLANK PADDING                    42800020
         BNE   COMPLEN        ALL PADDING REMOVED                       42880020
         BCTR  R8,R0          DECREMENT POINTER                         42960020
         BCTR  R6,R0          DECREMENT COUNTER                         43040020
         B     REMBLNK        TEST FOR BLANK PADDING LOOP               43120020
COMPLEN  EQU   *                                                        43200020
         LH    R15,PDELEN1    ACCESS LENGTH OF LOADNAME IN PDE          43280020
         CLR   R15,R6         ARE LOADNAME LENGTHS EQUAL                43360020
         BNE   NOCOMP         IF NOT, DO NOT COMPARE LOADNAMES          43440020
         BCTR  R6,R0          DECREMENT FOR EXECUTE                     43520020
         L     R8,PDELDNAM    ACCESS PTR TO LOADNAME                    43600020
         EX    R6,LDNCOMPR    TO COMPARE FOR LOADNAME MATCH             43680020
         BE    CHKDUP         IF = CHECK IF ITS A DUPLICATE             43760020
NOCOMP   EQU   *                                                        43840020
         TM    NEXTCDE,HEX04  CHECK FOR ALIAS (MINOR CDE)               43920020
         BNO   NEXTRB         IF NOT ALIAS, BRANCH                      44000020
         L     R5,MJCDE       ACCESS MAJOR CDE                          44080020
         LA    R5,@0(R5)      CLEAR HI ORDER BYTE                       44160020
         B     CDEPROC        PROCESS MINOR CDE                         44240020
LDNCOMPR CLC   @0(@1,R8),PROGNAME  COMPARE LOADNAMES                    44320020
NEXTRB   EQU   *                                                        44400020
         TM    TSTFLGS2,TOFFDEF TEST IF SEARCHING LOAD LIST CDE         44480020
         BO    GETLLE         IF SO, GET NEXT LLE                       44560020
         L     R3,RBLINK      OTHERWISE ACESS NEXT RB                   44640020
         B     RBPROC         PROCESS RB                                44720020
INITLLE  EQU   *              GET CDE POINTER FROM LLE                  44800020
         L     R3,TCBLLS      OTHERWISE, ACCESS ADDR OF LOADLIST        44880020
         OI    TSTFLGS2,TOFFDEF INDICATE USING LOAD LIST, NOT RB        44960020
USELLE   EQU   *                                                        45040020
         USING LLEDSECT,R3    ESTABLISH LOAD LIST ADDRESSABILITY        45120020
         LA    R3,@0(R3)      ZERO HI ORDER BYTE                        45200020
         LTR   R3,R3          END OF LOAD LIST                          45280020
         BZ    RETCALL        IF SO, RETURN TO CALLER                   45360020
         L     R5,CDEPTR      ACCESS PTR TO CDE                         45440020
         LA    R5,0(R5)       CLEAR HI ORDER BYTE                       45520020
         LTR   R5,R5          DOES PTR EQUAL ZERO                       45600020
         BZ    GETLLE         IF SO, SKIP THIS CDE                      45680020
         B     USECDE         BRANCH TO PROCESS CDE                     45760020
GETLLE   EQU   *                                                        45840020
         L     R3,NEXTLLE     ACCESS PTR TO NEXT LLE                    45920020
         B     USELLE         TO PROCESS LLE                            46000020
RETCALL  EQU   *                                                        46080020
         NI    TSTFLGS2,HEXDF TURN OFF LOAD LIST INDICATOR              46160020
         L     R8,WORKAREA    ACCESS WORKAREA                           46240020
         L     R14,RETURN-TSTCWORK(R8) ACCESS RETURN ADDRESS            46320020
         BR    R14            RETURN TO CALLER                          46400020
CHKDUP   EQU   *                                                        46480020
         L     R8,WORKAREA    ACCESS WORKAREA PTR                       46560020
         ST    R5,CDESAVE-TSTCWORK(R8)  STORE CDE ADDRESS               46640020
         ST    R1,TCBSAVE-TSTCWORK(R8)  STORE TCB ADDRESS               46720020
         LA    R3,@0(R3)                CLEAR HI ORDER BYTE             46800020
         ST    R3,RBSAVE-TSTCWORK(R8)   STORE RB ADDRESS                46880020
         TM    NEXTCDE,HEX04  TEST IF ALIAS (MINOR CDE)                 46960020
         BNO   CONTDUP        BRANCH IF NOT ALIAS                       47040020
         L     R5,MJCDE       ACCESS MAJOR CDE                          47120020
         LA    R5,@0(R5)      CLEAR HI ORDER BYTE                       47200020
CONTDUP  EQU   *                                                        47280020
         L     R4,XLADDR      ACCESS POINTER TO XTENT LIST              47360020
         USING XLDSECT,R4     ESTABLISH XTENT LIST ADDRESSABILITY       47440020
         TM    CDATTR2,HEX80  TEST FOR OBJECT                           47490020
         L     R0,LOCCSCT     ACCESS LOADED AT ADDRESS                  47500020
         BNO   GETLOC2        CONTINUE PROCESSING                       47510020
         LA    R15,@2         FOR FUTURE COMPARISON                     47512020
         CL    R15,NUMCSECT   DETERMINE IF TWO ENTRIES                  47514020
         BNE   GETLOC2        CONTINUE PROCESSING                       47516020
         L     R0,LOCCSCT+@4  ACCESS LOADED AT ADDRESS                  47518020
GETLOC2  EQU   *                                                        47518420
         ST    R0,LOADSAVE-TSTCWORK(R8) STORE LOADED AT ADDRESS         47600020
         BAL   R10,CDESRCH2   TO TEST FOR DUPLICATE LOADNAMES           47680020
         LTR   R0,R0          TEST IF DUPLICATE FOUND                   47760020
         BZ    NEXTRB         IF DUPLICATE, BRANCH TO CONTINUE CHAIN    47840020
         L     R14,RETURN-TSTCWORK(R8) RELOAD RETURN ADDRESS            47920020
         BALR  R11,R14        TO TELL CALLER TO PUT OUT MSG             48000020
         XR    R0,R0          INITIALIZE REGISTER 0                     48080020
         L     R8,WORKAREA    ACCESS WORKAREA ADDRESS                   48160020
         L     R3,RBSAVE-TSTCWORK(R8)  RESTORE RB POINTER               48240020
         L     R1,TCBSAVE-TSTCWORK(R8) RESTORE TCB POINTER              48320020
         B     NEXTRB         CONTINUE PROCESSING CHAIN                 48400020
CDESRCH2 EQU   *                                                        48480020
         L     R3,TCBRBP      ACCESS FIRST RB ON CHAIN                  48560020
         USING RBDSECT,R3     ESTABLISH RB ADDRESSABILITY               48640020
RBPROC2  EQU   *                                                        48720020
         LA    R3,@0(R3)      CLEAR HI ORDER BYTE                       48800020
         CR    R1,R3          DOES RB POINT TO TCB                      48880020
         BE    INITLLE2       ACCESS LOAD LIST                          48960020
         TM    RBSTAB,HEXC0   TEST IF PRB                               49040020
         BNZ   NEXTRB2        IF NOT, GET NEXT RB                       49120020
         L     R5,CDEADDR     ACCESS POINTER TO CDE                     49200020
         LA    R5,0(R5)       CLEAR HI ORDER BYTE                       49280020
         LTR   R5,R5          DOES PTR EQUAL ZERO                       49360020
         BZ    NEXTRB2        IF SO, SKIP THIS CDE                      49440020
USECDE2  EQU   *                                                        49520020
         L     R6,CDESAVE-TSTCWORK(R8) ACCESS STORED CDE                49600020
         CR    R5,R6          COMPARE CDE POINTERS                      49680020
         BNE   TSTMJCDE       GET NEXT RB                               49760020
         L     R6,RBSAVE-TSTCWORK(R8) ACCESS STORED RB OR LLE           49840020
         LA    R6,@0(R6)      CLEAR HI ORDER BYTE                       49920020
         CR    R6,R3          COMPARE RB OR LLE                         50000020
         BCR   @8,R10         IF EQUAL, DUPLICATE SEARCH ENDED          50080020
         XR    R0,R0          INDICATE DUPLICATE - DO NOT PRINT MSG     50160020
         LR    R3,R6          RESTORE ORIGINAL RB OR LLE                50240020
         BR    R10            CONTINUE PROCESSING                       50320020
NEXTRB2  EQU   *                                                        50400020
         CLI   RBSAVE-TSTCWORK(R8),HEX80 TEST IF SEARCHING LOAD LIST    50480020
         BE    GETLLE2        IF SO, GET NEXT LLE                       50560020
         L     R3,RBLINK      IF NOT, GET NEXT RB                       50640020
         B     RBPROC2        PROCESS RB                                50720020
TSTMJCDE EQU   *                                                        50800020
         TM    NEXTCDE,HEX04  CHECK FOR ALIAS (MINOR CDE)               50880020
         BNO   NEXTRB2        GET NEXT RB                               50960020
         L     R5,MJCDE       ACCESS MAJOR CDE                          51040020
         LA    R5,@0(R5)      CLEAR HI ORDER BYTE                       51120020
         B     USECDE2        PROCESS MAJOR CDE                         51200020
INITLLE2 EQU   *                                                        51280020
         L     R3,TCBLLS      OTHERWISE, ACCESS LOAD LIST PTR           51360020
         MVI   RBSAVE-TSTCWORK(R8),HEX80 TURN ON LLE INDICATOR          51440020
USELLE2  EQU   *                                                        51520020
         USING LLEDSECT,R3    ESTABLISH LLE ADDRESSABILITY              51600020
         LA    R3,@0(R3)      CLEAR HI ORDER BYTE                       51680020
         LTR   R3,R3          * THIS SITUATION SHOULD *                 51760020
         BCR   @8,R10         *   NEVER HAPPEN        *                 51840020
         L     R5,CDEPTR      ACCESS CDE PTR                            51920020
         LA    R5,@0(R5)      CLEAR HI ORDER BYTE                       52000020
         B     USECDE2        IF NOT, PROCESS CDE                       52080020
GETLLE2  EQU   *                                                        52160020
         L     R3,NEXTLLE     ACCESS NEXT LLE                           52240020
         B     USELLE2        PROCESS LLE                               52320020
*********************************************************************** 52400020
* THIS ROUTINE EXPECTS A TCB POINTER IN R1 AND THE ORIGINAL TCB MOTHER* 52480020
* STORED IN TCBCHAI IN WORKAREA  IT USES A MOTHER-DAUGHTER-SISTER     * 52560020
* CHAIN SEARCH AND RETURNS THE NEXT TCB IN R1. IF END OF CHAIN, R1=0  * 52640020
*********************************************************************** 52720020
TCBCHAIN EQU   *                                                        52800020
         LR    R2,R1          PUT TCB ADDRESS IN R2                     52880020
         L     R1,TCBLTC-TCB(R2) ACCESS DAUGHTER TASK PTR               52960020
         LA    R1,@0(R1)      CLEAR HI ORDER BYTE                       53040020
         LTR   R1,R1          TEST IF DAUGHTER EXISTS                   53120020
         BCR   @2,R14         IF NOT ZERO, RETURN TCB IN R1             53200020
SISTER   EQU   *                                                        53280020
         L     R1,TCBNTC-TCB(R2) IF NO DAUGHTER, GET SISTER             53360020
         LA    R1,@0(R1)      CLEAR HI ORDER BYTE                       53440020
         LTR   R1,R1          TEST IF SISTER EXISTS                     53520020
         BCR   @2,R14         IF NOT ZERO, RETURN TCB IN R1             53600020
         L     R2,TCBOTC-TCB(R2) IF NO SISTER, GET MOTHER               53680020
         LA    R2,@0(R2)      CLEAR HI ORDER BYTE                       53760020
         L     R11,WORKAREA   ACCESS WORKAREA PTR                       53840020
         L     R11,TCBCHAI-TSTCWORK(R11) ACCESS MOTHER TCB              53920020
         CR    R2,R11         DOES MOTHER = TEST TASK                   54000020
         BNE   SISTER         IF NOT GET MOTHER'S SISTER                54080020
         XR    R1,R1          INDICATE END OF TCB CHAIN                 54160020
         BR    R14            RETURN TCB ADDR TO CALLER                 54240020
*********************************************************************** 54290020
*                          MESSAGE TEXT                               * 54300020
* ......LOCATED AT +... IN ..............UNDER TCB LOCATED AT.......  * 54310020
*********************************************************************** 54312020
OFFMSG   EQU   *                                                        54320020
         LR    R3,R14         SAVE RETURN ADDRESS                       54400020
         L     R4,OUTBUF      POINTER TO OUTBUF                         54480020
         LA    R2,@8(R4)      CREATE PTR TO BEGINNING OF MSG FIELD      54560020
         ST    R2,@0(R4)      STORE MSG POINTER                         54640020
         XR    R2,R2          ZERO REGISTER TWO                         54720020
         ST    R2,@4(R4)      INDICATE NO SECOND LEVEL MSG              54800020
         STH   R2,@10(R4)     ZERO UNUSED FIELD                         54880020
         LA    R2,@81         ACCESS LENGTH OF MSG                      54960020
         STH   R2,@8(R4)      CONSTANT MSG LENGTH = 81                  55040020
         LA    R4,@12(R4)     POINTER TO ACTUAL MSG DATA                55120020
         MVI   @0(R4),BLANK   PUT BLANK IN MSG BUFFER                   55200020
         MVC   @1(@77,R4),@0(R4)  BLANK OUT MSG BUFFER                  55280020
         USING IKJPARMA,R7    ESTABLISH PDE ADDRESSABILITY              55360020
         L     R2,PDEUSER     ACCESS ABSOLUTE ADDRESS                   55440020
         BAL   R14,CONVERT    TO CONVERT ADDRESS TO PRINTABLE EBCDIC    55520020
         EX    R10,ADDRMVC    PUT CONVERTED ADDRESS IN BUFFER           55600020
         LA    R10,@2(R10,R4) UPDATE BUFFER POINTER                     55680020
         MVI   @0(R10),DOT    PUT PERIOD AFTER ABSOLUTE ADDRESS         55760020
         L     R2,MDATA1      ACCESS VCON FOR 'LOCATED AT'              55840020
         L     R2,@0(R2)      ACCESS PTR TO 'LOCATED AT'                55920020
         MVC   @8(@12,R4),@0(R2) PUT 'LOCATED AT' IN MSG BUFFER         56000020
         MVI   @20(R4),HEX4E  PUT PLUS SIGN BEFORE OFFSET               56080020
         L     R2,WORKAREA    ACCESS WORKAREA PTR                       56160020
         L     R2,OFFSET2-TSTCWORK(R2) ACCESS CALCULATED OFFSET         56240020
         BAL   R14,CONVERT    TO CONVERT OFFSET TO PRINTABLE EBCDIC     56320020
         EX    R10,OFFMVC     PUT CONVERTED OFFSET IN BUFFER            56400020
         L     R2,MDATA2      ACCESS VCON FOR 'IN'                      56480020
         L     R2,@0(R2)      ACCESS PTR TO 'IN'                        56560020
         MVC   @28(@2,R4),@9(R2) PUT 'IN' INTO MSG BUFFER               56640020
         LH    R2,PDELEN1     ACCESS LENGTH OF LOADNAME                 56720020
         BCTR  R2,R0          DECREMENT FOR EXECUTE                     56800020
         L     R5,PDELDNAM    ACCESS PTR TO LOADNAME                    56880020
         EX    R2,LDNMVC      TO MOVE LOADNAME INTO MESSAGE             56960020
         MVI   @39(R4),DOT    PUT PERIOD TO INDICATE ABSOLUTE ADDR      57040020
         LH    R2,PDELEN2     ACCESS LENGTH OF CSECTNAME                57120020
         BCTR  R2,R0          DECREMENT FOR EXECUTE                     57200020
         L     R5,PDECTNAM    ACCESS PTR TO CSECT NAME                  57280020
         EX    R2,CTNMVC      TO MOVE CSECTNAME INTO MESSAGE            57360020
         L     R2,MDATA3      ACCESS VCON FOR 'UNDER TCB'               57440020
         L     R2,@0(R2)      ACCESS PTR TO 'UNDER TCB'                 57520020
         MVC   @48(@22,R4),@0(R2) PUT 'UNDER TCB' IN MSG BUFFER         57600020
         LR    R2,R1          ACCESS TCB ADDR                           57680020
         BAL   R14,CONVERT    TO CONVERT TCB ADDRESS                    57760020
         EX    R10,TCBMVC     PUT CONVERTED TCB ADDRESS IN BUFFER       57840020
         LA    R10,@71(R10,R4) UPDATE BUFFER POINTER                    57920020
         MVI   @0(R10),DOT    PUT PERIOD AFTER TCB ADDRESS              58000020
         L     R1,OUTBUF      ACCESS PTR TO OUTPUT BUFFER               58080020
         BAL   R14,PUTMSG     TO BRANCH TO IO                           58160020
         BR    R3             RETURN TO CALLER                          58240020
ADDRMVC  MVC   @1(@1,R4),@0(R2) PUT CONVERTED ADDRESS IN MSG BUFFER     58320020
OFFMVC   MVC   @21(@1,R4),@0(R2) PUT CONVERTED OFFSET INTO MSG BUFFER   58400020
TCBMVC   MVC   @70(@1,R4),@0(R2) PUT CONVERTED ADDR INTO MSG BUFFER     58480020
*********************************************************************** 58530020
*                          MESSAGE TEXT                               * 58540020
*  .......LOCATED IN................UNDER TCB LOCATED AT.......       * 58550020
*********************************************************************** 58552020
LDNMSG   EQU   *                                                        58560020
         LR    R3,R14         SAVE RETURN ADDRESS                       58640020
         L     R4,OUTBUF      ACCESS PTR TO OUTPUT BUFFER               58720020
         LA    R2,@8(R4)      CREATE PTR TO BEGINNING OF MSG FIELD      58800020
         ST    R2,@0(R4)      STORE MSG POINTER                         58880020
         XR    R2,R2          ZERO REGISTER TWO                         58960020
         ST    R2,@4(R4)      INDICATE NO SECOND LEVEL MSG              59040020
         STH   R2,@10(R4)     ZERO UNUSED FIELD                         59120020
         LA    R2,@71         ACCESS LENGTH OF MSG                      59200020
         STH   R2,@8(R4)      CONSTANT MSG LENGTH =71                   59280020
         LA    R4,@12(R4)     POINTER TO ACTUAL MSG DATA                59360020
         MVI   @0(R4),BLANK   PUT BLANK IN MSG BUFFER                   59440020
         MVC   @1(@67,R4),@0(R4)  BLANK OUT MSG BUFFER                  59520020
         USING IKJPARMA,R7    ESTABLISH PDE ADDRESSABILITY              59600020
         LH    R2,PDELEN1     ACCESS LENGTH OF LOADNAME                 59680020
         BCTR  R2,R0          DECREMENT FOR EXECUTE                     59760020
         L     R5,PDELDNAM    ACCESS PTR TO LOADNAME                    59840020
         EX    R2,LDNMVC2     TO MOVE LOADNAME INTO MSG                 59920020
         TM    PDEFLG2,CTNAMFLG TEST IF CSECT NAME SPECIFIED            60000020
         BNO   CONTMSG        DO NOT PUT IN CSECT NAME                  60080020
         MVI   @9(R4),DOT     PUT PERIOD BETWEEN LOADNAME-CSECTNAME     60160020
         LH    R2,PDELEN2     ACCESS LENGTH OF CSECTNAME                60240020
         BCTR  R2,R0          DECREMENT FOR EXECUTE                     60320020
         L     R5,PDECTNAM    ACCESS PTR TO CSECT NAME                  60400020
         EX    R2,CTNMVC2     TO MOVE CSECT NAME INTO MSG               60480020
         LA    R4,@9(R4)      UPDATE FOR POINTER UNIFORMITY             60560020
CONTMSG  EQU   *                                                        60640020
         L     R2,MDATA1      ACCESS VCON FOR 'LOCATED AT'              60720020
         L     R2,@0(R2)      ACCESS PTR TO ' LOCATED AT'               60800020
         MVC    @9(@12,R4),@0(R2) PUT'LOCATED AT' IN MSG BUFFER         60880020
         L     R2,PDEUSER     ACCESS ABSOLUTE ADDRESS                   60960020
         BAL   R14,CONVERT    TO CONVERT ADDRESS TO PRINTABLE EBCDIC    61040020
         EX    R10,A2MVC      PUT CONVERTED ADDRESS IN BUFFER           61120020
         LA    R10,@22(R10,R4) UPDATE BUFFER POINTER                    61200020
         MVI   @0(R10),DOT    PUT PERIOD AFTER ABSOLUTE ADDRESS         61280020
         L     R2,MDATA3      ACCESS VCON FOR 'UNDER TCB'               61360020
         L     R2,@0(R2)      ACCESS PTR TO 'UNDER TCB'                 61440020
         MVC   @28(@22,R4),@0(R2) PUT'UNDER TCB' IN MSG BUFFER          61520020
         LR    R2,R1          ACCESS TCB ADDRESS                        61600020
         BAL   R14,CONVERT    TO CONVERT TCB ADDRESS                    61680020
         EX    R10,T2MVC      PUT CONVERTED TCB ADDRESS IN BUFFER       61760020
         LA    R10,@51(R10,R4) UPDATE BUFFER POINTER                    61840020
         MVI   @0(R10),DOT    PUT PERIOD AFTER TCB ADDRESS              61920020
         L     R1,OUTBUF      ACCESS ADDR OF OUTPUT BUFFER              62000020
         BAL   R14,PUTMSG     TO BRANCH TO IO                           62080020
         BR    R3             RETURN TO CALLER                          62160020
A2MVC    MVC   @21(@1,R4),@0(R2) PUT CONVERTED ADDRESS IN MSG BUFFER    62240020
T2MVC    MVC   @50(@1,R4),@0(R2) PUT CONVERTE ADDR INTO MSG BUFFER      62320020
*********************************************************************** 62370020
*                          MESSAGE TEXT                               * 62380020
*                   'NOT WITHIN ANY PROGRAM EXTENT'                   * 62390020
*********************************************************************** 62392020
REGMSG   EQU   *                                                        62400020
         LR    R3,R14         SAVE RETURN ADDRESS                       62480020
         L     R4,OUTBUF      POINTER TO OUTBUF                         62560020
         LA    R2,@8(R4)      CREATE PTR TO BEGINNING OF MSG FIELD      62640020
         ST    R2,@0(R4)      STORE MSG POINTER                         62720020
         XR    R2,R2          ZERO REGISTER TWO                         62800020
         ST    R2,@4(R4)      INDICATE NO SECOND LEVEL MSG              62880020
         STH   R2,@10(R4)     ZERO UNUSED FIELD                         62960020
         LA    R4,@12(R4)     POINTER TO ACTUAL MSG DATA                63200020
         MVI   @0(R4),BLANK   PUT BLANK IN MSG BUFFER                   63280020
         MVC   @1(@48,R4),@0(R4)  BLANK OUT MSG BUFFER                  63360020
         USING IKJPARMA,R7    ESTABLISH PDE ADDRESSABILITY              63440020
         L     R2,PDEUSER     ACCESS ABSOLUTE ADDRESS                   63520020
         BAL   R14,CONVERT    TO CONVERT ADDRESS TO PRINTABLE EBCDIC    63600020
         EX    R10,A3MVC      PUT CONVERTED ADDRESS IN BUFFER           63680020
         LA    R4,@2(R10,R4)  UPDATE BUFFER POINTER                     63760020
         LA    R5,@38         BASE LENGTH OF MESSAGE                    63810020
         LA    R5,@1(R10,R5)  ADD VARIABLE LENGTH TO BASE LENGTH        63820020
         MVI   @0(R4),DOT     PUT PERIOD AFTER ABSOLUTE ADDRESS         63840020
         LA    R1,@2(R4)      CREATE PTR TO BUFFER FOR TSTADDR          63890020
         LR    R0,R7          PTR TO PDE FOR TSTADDR                    63900020
         L     R15,TSTADDR    ACCESS ADDR OF TSTADDR                    63910020
         BALR  R14,R15        BRANCH TO TSTADDR                         63920020
         LR    R10,R0         ACCESS LENGTH OF ADDR STRING              63970020
         LA    R5,@0(R10,R5)  ADD VARIABLE LENGTH TO CURRENT MSG LENGTH 63980020
         L     R10,OUTBUF     ACCESS ADDR OF OUTBUF                     63990020
         STH   R5,@8(R10)     STORE MSG LENGTH IN OUTBUF                64000020
         LA    R4,@1(R1)      CREATE POINTER TO NEXT AVAILABLE SPACE    64050020
         L     R2,MDATA4      ACCESS VCON FOR MSG DATA                  64560020
         L     R2,@0(R2)      ACCESS PTR TO MSG DATA                    64640020
         MVC   @0(@30,R4),@0(R2) PUT DATA IN MSG BUFFER                 64720020
         L     R1,OUTBUF      ACCESS ADDRESS OF OUTBUF                  64800020
         BAL   R14,PUTMSG     TO BRANCH TO IO                           64880020
         BR    R3             RETURN TO CALLER                          64960020
A3MVC    MVC   @1(@1,R4),@0(R2) PUT CONVERTED ADDRESS IN MSG BUFFER     65040020
PUTMSG   EQU   *              TO BRANCH TO IO                           65120020
         LCR   R1,R1          INDICATE'SQUEEZE OUT BLANKS TO IO'        65200020
PUTC     EQU   *                                                        65280020
         LR    R2,R14         SAVE RETURN ADDRESS                       65360020
         L     R15,TPUTADDR   ACCESS ADDRESS OF IO                      65440020
         BALR  R14,R15        BRANCH TO IO                              65520020
         LTR   R15,R15        TEST FOR ZERO RETURN CODE                 65530020
         BCR   @8,R2          CONTINUE PROCESSING IF ZERO               65540020
         L     R14,WORKAREA   ACCESS WORKAREA PTR                       65570020
         ST    R15,CODESAVE-TSTCWORK(R14)                               65580020
         LA    R14,@16        FOR COMPARISON PURPOSES                   65590020
         CR    R14,R15        TEST RETURN CODE                          65592020
         LA    R15,@12        IN CASE RET CODE IS 16                    65594020
         BE    GOHOME         RETURN TO PARSE WITH 12                   65596020
         XR    R15,R15        ZERO RETURN CODE                          65598020
         B     GOHOME         RETURN TO PARSE WITH ZERO                 65598420
CONVERT  EQU   *              TO CONVERT TO PRINTABLE EBCDIC            65680020
         L     R5,WORKAREA    ACCESS ADDR OF WORKAREA                   65760020
         LA    R5,CWORKCMD-TSTCWORK(R5) ACCESS COMMAND PORTION          65840020
         ST    R2,@12(R5)     STORE ADDR TO BE CONVERTED                65920020
         UNPK  @0(@7,R5),@13(@4,R5) UNPACK ADDRESS                      66000020
         TR    @0(@6,R5),TRTAB-@240 CONVERT TO EBCDIC                   66080020
         LR    R2,R5          PUT ADDR OF CONVERTED STRING IN R2        66160020
         LA    R10,@5         INITIALIZE LENGTH COUNTER                 66240020
REMZ     EQU   *              THIS LOOP WILL REMOVE LEADING ZEROES      66320020
         CLI   @0(R2),ZERO    TEST FOR LEADING ZERO                     66400020
         BCR   @7,R14         IF NOT ZERO RETURN TO CALLER              66480020
         LA    R2,@1(R2)      INCREMENT ADDRESS POINTER                 66560020
         BCT   R10,REMZ       DECREMENT COUNTER AND BRANCH IF NOT ZERO  66640020
         BR    R14            RETURN TO CALLER IF COUNTER = ZERO        66720020
ADDRMSG  EQU   *              CODE TO SET UP INVALID ADDR MSG           66800020
         L     R2,OUTBUF      ACCESS PTR TO OUTBUF                      66880020
         L     R11,@4(R1)     ACCESS PTR TO 2ND LEVEL MSG               66960020
         L     R8,WORKAREA    ACCESS PTR TO WORKAREA                    67040020
         ST    R11,MSGHOLD2-TSTCWORK(R8) STORE PTR TO 2ND MSG           67120020
         L     R11,@0(R1)     ACCESS PTR TO 1ST LEVEL MSG               67200020
         LH    R10,@0(R11)    ACCESS LENGTH OF MSG                      67280020
         BCTR  R10,R0         DECREMENT COUNT FOR EXECUTE               67360020
         EX    R10,INVLD      MOVE MSG DATA TO OUTPUT BUFFER            67440020
         LA    R1,@1(R10,R2)  UPDATE PTR TO ADDR SLOT IN MSG            67520020
         MVI   @0(R1),BLANK   INSERT BLANK BEFORE ADDR                  67600020
         LA    R1,@1(R1)      UPDATE TO BEGIN OF ADDR                   67680020
         LR    R0,R7          ACCESS ADDR OF PDE                        67760020
         L     R15,TSTADDR    ACCESS ADDR OF ADDR STRING BUILDER        67840020
         BALR  R14,R15        BRANCH TO TSTADDR                         67920020
         MVI   @0(R1),HEX4E   PLUS SIGN TO INDICATE 1ST LEVEL MSG       68000020
         LR    R4,R0          RO CONTAINS LENGTH OF ADDR STRING         68080020
         LA    R10,@3(R4,R10) ADD IN LENGTH OF ADDRESS STRING           68160020
         STH   R10,@0(R2)     REFLECT NEW MSG LENGTH                    68240020
         ST    R2,MSGHOLD-TSTCWORK(R8) ST PTR TO 1ST MSG                68320020
         LA    R1,MSGHOLD-TSTCWORK(R8) CREATE PTR TO MESSAGES           68400020
         L     R11,MSGADDR-TSTCWORK(R8)  ACCESS PTR TO PARSE PARM LIST  68480020
         MVC   @0(@4,R11),@4(R1)  PUT 2ND LEVEL MSG IN PARSE PARMLIST   68560020
         BAL   R14,PUTMSG     TO OUTPUT MSG                             68640020
         LA    R15,@8         INDICATE REENTER TO PARSE                 68720020
         B     GOHOME         RETURN TO PARSE                           68800020
GOHOME   EQU   *                                                        69360020
         L     R2,WORKAREA    ACCESS WORKAREA ADDR                      69440020
         MVC   @0(@25,R7),PDESAVE-TSTCWORK(R2) RESTORE ORIGINAL PDE     69520020
         L     R13,@4(R13)    ACCESS CALLER'S SAVE AREA                 69600020
         RETURN (14,12),RC=(15) RETURN TO PARSE                         69680020
CODECHK  EQU   *              CHECK RETURN CODE                         69760020
         B     BTAB(R15)      BRANCH ACCORDING TO RETURN CODE           69840020
BTAB     BR    R14            IF RETURN CODE = 0                        69920020
         BR    R14            FOR ALIGNMENT PURPOSES                    70000020
         B     CONVMSG        IF RETURN CODE = 4                        70080020
         B     CONVMSG        IF RETURN CODE = 8                SA49886 70160021
         B     CONVMSG        IF RETURN CODE = 12               SA49886 70240021
         B     SYMSTAE        IF RETURN CODE = 16                       70320020
         B     CONVMSG        IF RETURN CODE = 20               SA49886 70400021
CODECHK2 EQU   *                                                        70410020
         B     BTAB2(R15)     BRANCH ACCORDING TO RETURN CODE           70420020
BTAB2    BR    R14            IF RETURN CODE = 0                        70430020
         BR    R14            FOR ALIGNMENT PURPOSES                    70440020
         B     TRYALIAS       IF RETURN CODE = 4                        70442020
         B     TRYALIAS       IF RETURN CODE = 8                        70444020
         B     CONVMSG        IF RETURN CODE = 12               SA49886 70446021
         B     SYMSTAE        IF RETURN CODE = 16                       70448020
         B     SYMSTAE        IF RETURN CODE = 20                       70448420
CONVMSG  EQU   *              ENTER HERE FOR RETURN CODE 8      SA49886 70450021
         L     R8,WORKAREA    ACCESS WORKAREA PTR                       70460020
         L     R11,MSGADDR-TSTCWORK(R8) ACCESS PTR TO PARSE PARMLIST    70470020
         MVC   @0(@4,R11),PDEUSER PUT 2ND LEVEL MSG IN PARSE PARMLIST   70472020
         LA    R15,@8         SET RETURN CODE TO 8              SA49886 70474021
         B     GOHOME         RETURN TO PARSE                   SA49886 70476021
SYMSTAE  EQU   *              ENTER HERE IF RETURN CODE = 20            70480020
         L     R8,WORKAREA    ACCESS PTR TO WORKAREA                    70530020
         ST    R15,CODESAVE-TSTCWORK(R8) STORE RETURN CODE              70540020
         LA    R15,@12        SET RETURN CODE TO PARSE                  70560020
         B     GOHOME         RETURN TO PARSE                           70640020
         TITLE 'IKJEGWHR, ''WHERE'' SUBCOMMAND, MACROS AND CONSTANTS'   70690020
PARSELST DC    V(IKJEGPRS)    ADDRESS OF PARAMETER PASSED TO PARSE      70720020
IKJEGPRS IKJPARM                                                        70800020
GETADDR  IKJPOSIT   ADDRESS,VALIDCK=IKJEGVLC                            70880020
*                             MACRO USED TO CHECK ADDRESS               70960020
         IKJENDP                                                        71040020
         SPACE 5                                                        71090020
LDNMVC2  MVC   @1(@1,R4),@0(R5) PUT LOADNAME IN MSG BUFFER              71200020
CTNMVC2  MVC   @10(@1,R4),@0(R5) PUT CSECT NAME IN MSG BUFFER           71280020
LDNMVC   MVC   @31(@1,R4),@0(R5) PUT LOADNAME IN MSG BUFFER             71360020
CTNMVC   MVC   @40(@1,R4),@0(R5) PUT CSECT NAME IN MSG BUFFER           71440020
MOVNAME  MVC   @0(@1,R1),@0(R3) MOVE NAME FROM PDE TO WORKAREA          71520020
MOVDISPL MVC   @30(@1,R1),@1(R10)  MOVE OFFSET TO OUTPUT                71600020
INVLD    MVC   @0(@1,R2),@0(R11) MSG DATA INTO OUTPUT BUFFER            71680020
CSECTMVC MVC   CSECTNAM-TSTCWORK(@1,R6),@0(R1) MOVE CSECT NAME          71730020
         SPACE 5                                                        71740020
MSSG4    DC    V(IKJEGMS4)   POINTER TO MESSAGE                         71760020
MSSG7    DC    V(IKJEGMS7)   POINTER TO MESSAGE                         71840020
MSSG9    DC    V(IKJEGMS9)   POINTER TO MESSAGE                         72000020
TRTAB    DC    C'0123456789ABCDEF' TRANSLATE TABLE                      72080020
MDATA1   DC    V(IKJEGDA1)   POINTER TO DATA MSG                        72160020
MDATA2   DC    V(IKJEGDA2)   POINTER TO DATA MSG                        72240020
MDATA3   DC    V(IKJEGDA3)   POINTER TO DATA MSG                        72320020
MDATA4   DC    V(IKJEGDA4)   POINTER TO DATA MSG                        72400020
ADDRSIZE DC    X'000B0000'                                              72480020
         SPACE 5                                                        72530020
************************************************************            72560020
*                                                          *            72640020
*                    EQUATES                               *            72720020
*                                                          *            72800020
************************************************************            72880020
ZERO     EQU   C'0'                                                     72960020
HEX11    EQU   X'11'                                                    73040020
HEX10    EQU   X'10'                                                    73120020
HEX04    EQU   X'04'                                                    73200020
HEX80    EQU   X'80'                                                    73280020
HEXDF    EQU   X'DF'                                                    73360020
HEXFF    EQU   X'FF'                                                    73440020
HEX4E   EQU    X'4E'                                                    73520020
HEX00    EQU    X'00'                                                   73600020
HEXC0    EQU   X'C0'                                                    73680020
BLANK    EQU   X'40'                                                    73760020
TTCBPKF  EQU   28                                                       73840020
DOT      EQU   X'4B'                                                    73920020
@0       EQU   0                                                        74000020
@1       EQU   1                                                        74080020
@2       EQU   2                                                        74160020
@3       EQU   3                                                        74240020
@4       EQU   4                                                        74320020
@5       EQU   5                                                        74400020
@6       EQU   6                                                        74480020
@7       EQU   7                                                        74560020
@8       EQU   8                                                        74640020
@9       EQU   9                                                        74720020
@10      EQU   10                                                       74800020
@12      EQU   12                                                       74880020
@13      EQU   13                                                       74960020
@14      EQU   14                                                       75040020
@16      EQU   16                                                       75120020
@18      EQU   18                                                       75200020
@20      EQU   20                                                       75280020
@21      EQU   21                                                       75360020
@22      EQU   22                                                       75440020
@24      EQU   24                                                       75520020
@25      EQU   25                                                       75600020
@27      EQU   27                                                       75680020
@28      EQU   28                                                       75760020
@30      EQU   30                                                       75840020
@31      EQU   31                                                       75920020
@32      EQU   32                                                       76000020
@36      EQU   36                                                       76080020
@38      EQU   38                                                       76160020
@39      EQU   39                                                       76240020
@40      EQU   40                                                       76320020
@41      EQU   41                                                       76400020
@44      EQU   44                                                       76480020
@48      EQU   48                                                       76560020
@49      EQU    49                                                      76640020
@50      EQU   50                                                       76720020
@51      EQU   51                                                       76800020
@52      EQU   52                                                       76880020
@53      EQU   53                                                       76960020
@56      EQU   56                                                       77040020
@57      EQU   57                                                       77120020
@58      EQU   58                                                       77200020
@60      EQU   60                                                       77280020
@64      EQU   64                                                       77360020
@67      EQU   67                                                       77440020
@68      EQU   68                                                       77520020
@70      EQU   70                                                       77600020
@71      EQU   71                                                       77680020
@76      EQU   76                                                       77760020
@77      EQU   77                                                       77840020
@81      EQU   81                                                       77920020
@92      EQU   92                                                       78000020
@96      EQU   96                                                       78050020
@240     EQU   240                                                      78080020
R0       EQU   0                                                        78160020
R1       EQU   1                                                        78240020
R2       EQU   2                                                        78320020
R3       EQU   3                                                        78400020
R4       EQU   4                                                        78480020
R5       EQU   5                                                        78560020
R6       EQU   6                                                        78640020
R7       EQU   7                                                        78720020
R8       EQU   8                                                        78800020
R9       EQU   9                                                        78880020
R10      EQU   10                                                       78960020
R11      EQU   11                                                       79040020
R12      EQU   12                                                       79120020
R13      EQU   13                                                       79200020
R14      EQU   14                                                       79280020
R15      EQU   15                                                       79360020
STAETAB  DC    X'03'                                                    79440020
         DC    AL3(BLOW1)    RESUME ADDR FOR STAE                       79520020
         DC    X'08'         STAE ABEND CODE FOR SYM LINK               79600020
         DC    AL3(BLOW2)    RESUME ADDR FOR STAE                       79680020
         DC    X'08'         STAE ABEND CODE FOR SYM LINK               79760020
         DC    AL3(BLOW3)    RESUME ADDR FOR STAE                       79840020
         DC    X'FF'         INDICATE END OF TABLE                      79920020
         DS    0F                                                       80000020
LISTSTAE STAE  MF=L          LIST FORM OF STAE                          80080020
ENDLIST  EQU   *-LISTSTAE                                               80160020
SUBPOOL  EQU   *                                                        80240020
         DC    AL1(0)         SUBPOOL NUMBER                            80320020
         DC    AL3(104)       WORKAREA LENGTH IN BYTES                  80400020
ARETRY   DC    AL3(RETRY)     ADDR OF STAE RETRY RTN                    80480020
SYM      DC    C'SYM'         FOR BLDL ENTRY TO SYM                     80530020
SMTSYM01 DS    0C             TEST CASE TTSTC120                        80532020
LINKF    LINK  SF=L           LIST FORM FOR LINK                        80540020
LINKL    EQU   *-LINKF        LENGTH OF LIST FORM OF LINK               80550020
         TITLE 'IKJEGWHR, ''WHERE'' SUBCOMMAND, MESSAGE CSECT'          80560020
************************************************************            80640020
**                                                        **            80720020
**            MESSAGE CSECT                               **            80800020
**                                                        **            80880020
************************************************************            80960020
IKJEGMSG CSECT                                                          81040020
         ENTRY IKJEGDA1                                                 81120020
         ENTRY IKJEGDA2                                                 81200020
         ENTRY IKJEGDA3                                                 81280020
         ENTRY IKJEGDA4                                                 81360020
         ENTRY IKJEGMS4                                                 81440020
         ENTRY IKJEGMS7                                                 81520020
         ENTRY IKJEGMS9                                                 81680020
IKJEGMS4 DC    A(ERRMSG1)    POINTER TO ERROR MESSAGE                   81760020
         DC    A(ERRMSG3)    POINTER TO MESSAGE                         81840020
IKJEGMS7 DC    A(ERRMSG8)    POINTER TO MESSAGE                         81920020
         DC    AL4(0)        NO SECONG LEVEL MSG                        82000020
IKJEGMS9 DC    A(ERRMSG11)   POINTER TO MESSAGE                         82240020
         DC    A(ERRMSG10)   POINTER TO MESSAGE                         82320020
IKJEGDA1 DC    A(LOCATE2)    POINTER TO MSG DATA                        82400020
IKJEGDA2 DC    A(LOCATEIN)   POINTER TO MSG DATA                        82480020
IKJEGDA3 DC    A(UNDERTCB)   POINTER TO DATA MSG                        82560020
IKJEGDA4 DC    A(EXTENT)      POINTER TO MESSAGE                        82640020
         DS    0H                                                       82720020
ERRMSG3  DC    AL2(ERR3-ERRMSG3)             MSGLEN                     82800020
         DC    AL2(0)                        UNUSED                     82880020
         DC    C'IKJ57350I '                 MSG ID                     82960020
         DC    C'REGISTER NOTATION MUST BE INDIRECT '  MSGTEXT          83040020
         DC    C'GENERAL REGISTER'           MSGTEXT                    83120020
ERR3     EQU   *                             MSG END                    83200020
         DS    0H                                                       83280020
ERRMSG1  DC    AL2(ERR1-ERRMSG1)             MSGLEN                     83360020
         DC    AL2(0)                        UNUSED                     83440020
         DC    C'IKJ57350I '                 MSG ID                     83520020
         DC    C'INVALID ADDRESS'            MSG TEXT                   83600020
ERR1     EQU   *                             MSG END                    83680020
         DS    0H                                                       84240020
ERRMSG8  DC    AL2(ERR8-ERRMSG8)             MSGLEN                     84320020
         DC    AL2(0)                        UNUSED                     84400020
         DC    C'IKJ57351I '                 MSG ID                     84480020
         DC    C'NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  MSGTEXT   84560020
ERR8     EQU   *                             MSG END                    84640020
         DS    0H                                                       85200020
ERRMSG10 DC    AL2(ERR10-ERRMSG10)           MSGLEN                     85280020
         DC    AL2(0)                        UNUSED                     85360020
         DC    C'IKJ57359I '                 MSG ID                     85440020
         DC    C'PARSE ERROR CODE 12'        MSGTEXT                    85520020
ERR10    EQU   *                             MSG END                    85600020
         DS    0H                                                       85650020
ERRMSG11 DC    AL2(ERR11-ERRMSG11)           MSGLEN                     85680020
         DC    AL2(0)                        UNUSED                     85760020
         DC    C'IKJ57359I '                 MSGID                      85840020
         DC    C'WHERE FAILED, COMMAND SYSTEM ERROR+' MSGTEXT           85920020
ERR11    EQU   *                             MSGEND                     86000020
LOCATE2  DC    C' LOCATED AT '               MSG DATA                   86080020
LOCATEIN DC    C' LOCATED IN '               MSG DATA                   86160020
UNDERTCB DC    C' UNDER TCB LOCATED AT '     MSG DATA                   86240020
EXTENT   DC    C'NOT WITHIN ANY PROGRAM EXTENT ' MSG DATA               86320020
        EJECT                                                           86400020
*                                                          *            86480020
*         TEST COMMUNICATION TABLE DSECT                   *            86560020
*                                                          *            86640020
************************************************************            86720020
TCOMTAB TCOMTAB              MACRO THAT GENERATES TCOMTAB DSECT         86800020
        EJECT                                                           86880020
************************************************************            86960020
*                                                          *            87040020
*              EXTENT BLOCK DSECT                          *            87120020
*                                                          *            87200020
************************************************************            87280020
XLDSECT  DSECT                THIS DSECT IS USED TO ADDRESS             87360020
*                             THE EXTENT BLOCK                          87440020
LENGTHXL DS    CL4            LENGTH OF EXTENT BLOCK                    87520020
NUMCSECT DS    CL4            NUMBER OF CSECTS                          87600020
LENCSCT  DS    CL4            LENGTH OF CSECT(N)                        87680020
LOCCSCT  DS    CL4            LOCATION OF CSECT(N)                      87760020
         IKJPPL                                                         87840020
         EJECT                                                          87920020
************************************************************            88000020
*                                                          *            88080020
*              TASK CONTROL BLOCK DSECT                    *            88160020
*                                                          *            88240020
************************************************************            88320020
TCBDSECT IKJTCB             TCB DSECT                                   88400020
         EJECT                                                          88480020
************************************************************            88560020
*                                                          *            88640020
*             CONTENTS DIRECTORY DSECT                     *            88720020
*                                                          *            88800020
************************************************************            88880020
CDEDSECT DSECT                DSECT OUTLINING CDE QUEUE                 88960020
NEXTCDE  DS    A             NEXT CDE POINTER                           89040020
RBADDR   DS    A             POINTER TO RB                              89120020
PROGNAME DS    CL8            EBCDIC PROGRAM NAME                       89200020
EPADDR   DS    A             POINTER TO ENTRY POINT OF LOADNAME         89280020
XLADDR   DS    A             POINTER TO EXTENT BLOCK                    89360020
MJCDE    EQU   XLADDR                                                   89440020
CDATTR2  EQU   XLADDR                                                   89490020
************************************************************            89520020
*                                                          *            89600020
*               REQUEST BLOCK DSECT                        *            89680020
*                                                          *            89760020
************************************************************            89840020
RBDSECT  DSECT               REQUEST BLOCK DSECT                        89920020
RBPPSAV  DS    A             ADDR OF PROBLEM PROG SAVE AREA             90000020
RBABOPSW DS    A             RIGHT HALF OF USER OLD PSW                 90080020
RBSIZE   DS    CL2           SIZE OF RB                                 90160020
RBSTAB   DS    CL2           STATUS BYTES                               90240020
CDEADDR  DS    CL4            CDE ADDRESS                               90320020
RBOPSW   DS    CL8           OLD PSW                                    90400020
RBPGMQ   DS    A             ADDRESS FOR SERIALLY REUSABLE              90480020
RBLINK   DS    A             POINTER TO NEXT REQUEST BLOCK              90560020
         EJECT                                                          90640020
************************************************************            90720020
*                                                          *            90800020
*             ADDRESS PDE CREATED BY PARSE                 *            90880020
*                                                          *            90960020
************************************************************            91040020
         IKJPARMA                                                       91120020
         EJECT                                                          91200020
CVT      DSECT               CVT DSECT                                  91280020
         CVT                                                            91360020
         EJECT                                                          91440020
************************************************************            91520020
**                                                        **            91600020
**               LOAD LIST DSECT                          **            91680020
**                                                        **            91760020
************************************************************            91840020
LLEDSECT DSECT               DSECT FOR LOAD LIST QUEUE                  91920020
NEXTLLE  DS    A             POINTER TO NEXT LOAD LIST QUEUE            92000020
CDEPTR   DS    A             POINTER TO NEXT CONTENTS DIRECTORY         92080020
          TSTCWORK                                                      92160020
ALIASAVE EQU   CWORKCMD+@28                                             92170020
CSECTNAM EQU   CWORKCMD+@36                                             92210020
PPLSAVE  EQU   CWORKCMD+@44                                             92240020
CODESAVE EQU   CWORKIO-@96                                              92290020
PDESAVE  EQU   CWORKIO-@92                                              92320020
CURLD    EQU   CWORKIO-@64                                              92400020
LOADNAME EQU   CWORKIO-@56                                              92480020
USERSAVE EQU   CWORKIO-@48                                              92560020
LOADSAVE EQU   CWORKIO-@44                                              92640020
TCBCHAI  EQU   CWORKIO-@40                                              92720020
TCBSAVE  EQU   CWORKIO-@36                                              92800020
RBSAVE   EQU   CWORKIO-@32                                              92880020
CDESAVE  EQU   CWORKIO-@28                                              92960020
OFFSET2  EQU   CWORKIO-@24                                              93040020
OFFSET   EQU   CWORKIO-@20                                              93120020
MSGADDR EQU    CWORKIO-@16                                              93200020
MSGHOLD  EQU   CWORKIO-@12                                              93280020
MSGHOLD2 EQU   CWORKIO-@8                                               93360020
RETURN   EQU   CWORKIO-@4                                               93440020
          END                                                           93520020
