      TITLE 'IKJEHAL1 - IBM S/360 TIME SHARING OPTION LISTALC COMMAND'  00050020
IKJEHAL1 CSECT                                                          00100020
*A 785000                                                       SA49892 00104521
*C 800500                                                       SA49892 00109221
*D 800000                                                       SA49892 00109321
*C 391500,402000                                                 A49871 00109521
*C 638500-639500,642500,643500,688500                            A48499 00114021
*C 252500,253500,762500,765500,766200                            A42338 00118521
*A 103600,103700,252100-252499,605600,736100,736200              A42338 00123021
*D 148000-148500,247500,737500,738000,739500,741500,742000,      A42338 00127521
*D 763000                                                        A42338 00132021
*C 586600                                                         M0875 00136521
*A 873104                                                         M0883 00141021
         SPACE 2                                                        00145521
*********************************************************************** 00150020
*                                                                     * 00160020
* STATUS -- CHANGE LEVEL 01                                       M0875 00200021
*                                                                     * 00250020
* FUNCTION --                                                         * 00300020
*    THIS MODULE LISTS THE CURRENTLY ALLOCATED DATA SETS FOR A        * 00400020
*    LOGGED-ON USER OF THE SYSTEM.  DATA SET NAMES ARE EXTRACTED      * 00450020
*    FROM THE DATA SET EXTENSION (DSE) BLOCKS. ALL INFORMATION        * 00500020
*    FOR THE BASIC COMMAND AND FOR THE 'STATUS' KEYWORD IS            * 00550020
*    EXTRACTED FROM THE IN-CORE CHAIN OF DSE'S. DATA FOR THE          * 00600020
*    'HISTORY' KEYWORD IS TAKEN FROM THE DSCB WHICH IS BROUGHT        * 00650020
*    IN BY AN OBTAIN MACRO. A RDJFCB MACRO IS USED TO GET THE         * 00700020
*    VOLID NEEDED TO DO THE OBTAIN. IF THE 'MEMBERS' KEYWORD IS       * 00750020
*    SPECIFIED IN THE COMMAND AND A DATASET WITH PARTITIONED          * 00800020
*    ORGANIZATION IS FOUND TO HAVE THE USER'S USERID AS HIGHEST       * 00850020
*    LEVEL QUALIFIER, THEN IKJEHMEM IS LOADED AND CALLED AND          * 00900020
*    WILL LIST THE DIRECTORY OF THE PDS. IF THE 'SYSNAMES'            * 00950020
*    KEYWORD IS SPECIFIED, ALL SYSTEM GENERATED DSNAMES FOUND         * 01000020
*    ALLOCATED TO THIS SESSION ARE INCLUDED IN THE LISTING.           * 01050020
*    OTHERWISE SYSTEM NAMES ARE IGNORED.                              * 01100020
*                                                                     * 01150020
* ENTRY POINTS --                                                     * 01200020
*         IKJEHAL1 - MAIN ENTRY POINT OF THE PROGRAM                  * 01250020
*         IKJEHWRT - WRITE ROUTINE                                    * 01260020
*         IKJEHERR - ERROR ROUTINE                                    * 01300020
*                                                                     * 01350020
* INPUT -- REGISTER 1 POINTS TO THE COMMAND PROCESSOR PARAMETER LIST  * 01400020
*                                                                     * 01600020
* OUTPUT --                                                           * 01650020
*    DSNAME FOR EACH DSE BLOCK FOUND IN THE CHAIN, WITH THE           * 01700020
*    EXCEPTION OF ANY SYSTEM GENERATED DSNAMES FOUND. ADDITIONAL      * 01750020
*    OUTPUT OF CREATION AND EXPIRATION DATES, PASSWORD PROTECTION     * 01800020
*    STATUS, DATASET ORGANIZATION, DDNAME AND DATASET                 * 01850020
*    DISPOSITIONS, AND MEMBER NAMES IS AVAILABLE IF THE PROPER        * 01900020
*    KEYWORDS ARE SPECIFIED WITH THE COMMAND.                         * 01950020
*                                                                     * 02000020
* EXTERNAL REFERENCES --                                              * 02050020
*         IKJEHMEM - TO LIST PDS DIRECTORY                            * 02100020
*         IKJPARS - TO PARSE COMMAND STRING                           * 02150020
*         IKJPUTL - TO OUTPUT DATA TO TERMINAL                        * 02300020
*                                                                     * 02350020
* EXITS, NORMAL -- RETURN TO THE TERMINAL MONITOR PROGRAM             * 02400020
*                                                                     * 02550020
* EXITS, ERROR -- RETURN TO THE TERMINAL MONITOR PROGRAM              * 02600020
*                                                                     * 02750020
* TABLES/WORK AREAS --                                                * 02800020
*    HDTNY -THE TABLE WHICH CONTAINS THE ACCUMULATED DAYS IN THE      * 02850020
*    YEAR FOR EACH MONTH.  THIS TABLE IS USED TO FIND THE             * 02900020
*    CORRECT MONTH THAT A DAY FALLS IN.  THE NY INDICATES             * 02950020
*    THAT THIS IS FOR A NORMAL YEAR.                                  * 03000020
*    HDTLY SAME AS HDTNY BUT FOR LEAP YEAR.                           * 03050020
*    INITCORE -A WORK AREA HOLDING THE INTERNAL SWITCHES FOR THE      * 03100020
*    PROGRAM, THE LIST FORMS OF THE VARIOUS MACROS, AND               * 03150020
*    THE OUTPUT BUFFER. THIS DSECT ALSO CONTAINS THE REGISTER         * 03200020
*    SAVE AREA.  CORE IS GOTTEN BY A REGISTER GETMAIN.                * 03250020
*    OBTWAD -THE WORKING CORE GOTTEN IF THE 'HISTORY' AND/OR          * 03300020
*    'MEM' KEYWORDS WERE USED. THIS AREA PROVIDES THE WORK            * 03350020
*    AREA FOR THE RDJFCB AND OBTAIN MACROS, THE DCB NEEDED            * 03400020
*    BY RDJFCB AND BY MODULE IKJEHMEM, AND THE PARAMETER LIST         * 03450020
*    FOR THE RDJFCB AND OBTAIN MACROS.                                * 03500020
*                                                                     * 03550020
* ATTRIBUTES -- REENTRANT, READ ONLY, REFRESHABLE                     * 03700020
*                                                                     * 03800020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 03810020
*                                                                     * 03820020
* NOTES -- N/A                                                        * 03850020
*                                                                     * 04300020
*********************************************************************** 04350020
         EJECT                                                          04360020
         ENTRY IKJEHWRT                                                 04400020
         ENTRY IKJEHERR                                                 04450020
         SPACE                                                          04500020
*        REGISTER EQUATES                                               04550020
R0       EQU   0                   REGISTER 0                           04650020
R1       EQU   1                   REGISTER 1                           04700020
R2       EQU   2                   REGISTER 2                           04750020
R3       EQU   3                   REGISTER 3                           04800020
R4       EQU   4                   REGISTER 4                           04850020
R5       EQU   5                   REGISTER 5                           04900020
R6       EQU   6                   REGISTER 6                           04950020
R7       EQU   7                   REGISTER 7                           05000020
R8       EQU   8                   REGISTER 8                           05050020
R9       EQU   9                   REGISTER 9                           05100020
R10      EQU   10                  REGISTER 10                          05150020
R11      EQU   11                  REGISTER 11                          05200020
R12      EQU   12                  REGISTER 12                          05250020
R13      EQU   13                  REGISTER 13                          05300020
R14      EQU   14                  REGISTER 14                          05350020
R15      EQU   15                  REGISTER 15                          05400020
*                                                                       05450020
*        CHARACTER AND VALUE EQUATES                                    05500020
*                                                                       05550020
BLANK    EQU   C' '                BLANK                                05600020
SLASH    EQU   C'/'                SLASH                                05650020
SSP      EQU   1                   SUBPOOL NUMBER                       05750020
OSP      EQU   1                   SUBPOOL NUMBER                       05800020
*        MESSAGE NUMBERS                                                05850020
MSG01    EQU   1                   MESSAGE NUMBER 1                     05950020
MSG02    EQU   2                   MESSAGE NUMBER 2                     06000020
MSG03    EQU   3                   MESSAGE NUMBER 3                     06050020
MSG04    EQU   4                   MESSAGE NUMBER 4                     06100020
MSG05    EQU   5                   MESSAGE NUMBER 5                     06150020
MSG06    EQU   6                   MESSAGE NUMBER 6                     06200020
*        SECOND LEVEL MESSAGE NUMBERS                                   06400020
SECMSG01 EQU   1                   SECOND LEVEL MESSAGE 1               06450020
SECMSG02 EQU   2                   SECOND LEVEL MESSAGE 2               06500020
SECMSG03 EQU   3                   SECOND LEVEL MESSAGE 3               06550020
SECMSG04 EQU   4                   SECOND LEVEL MESSAGE 4               06600020
SECMSG05 EQU   5                   SECOND LEVEL MESSAGE 5               06650020
SECMSG06 EQU   6                   SECOND LEVEL MESSAGE 6               06700020
SECMSG07 EQU   7                   SECOND LEVEL MESSAGE 7               06750020
SECMSG08 EQU   8                   SECOND LEVEL MESSAGE 8               06800020
SECMSG09 EQU   9                   SECOND LEVEL MESSAGE 9               06850020
SECMSG10 EQU   10                  SECOND LEVEL MESSAGE 10              06900020
*        EQUATES                                                        06950020
DSECDYNA EQU   X'10'               TIOT ENTRY IS DYNAM                  07050020
DSECCNCT EQU   X'08'               ENTRY DYNAMICALLY CONCATENATED       07100020
ONE      EQU   1                   1                                    07150020
DYNDDOFF EQU   2                   OFFSET DDNAME LIST FOR DYNAM ENTRIES 07200020
DDNAMLEN EQU   8                   LENGTH OF DDNAME                     07250020
TERMDDOF EQU   10                  OFFSET TO DDNAME                     07300020
NULLDDOF EQU   10                  OFFSET TO DDNAME                     07350020
SAVELEN  EQU   112                 SIZE OF SAVE AREA                    07400020
RETREGOF EQU   12                  OFFSET TO RETURN REGISTER            07450020
BALREGOF EQU   52                  OFFSET TO BRANCH REGISTER            07500020
*  THE BITS OF THE CONTROL BYTE HAVE THE FOLLOWING MEANING              07600020
STATMSK  EQU   X'80'               STATUS SPECIFIED                     07700020
HISTMSK  EQU   X'40'               HISTORY SPECIFIED                    07750020
MEMMSK   EQU   X'20'               MEMBERS SPECIFIED                    07800020
SYSNMSK  EQU   X'10'               SYSNAMES SPECIFIED                   07850020
HISTSTAT EQU   X'C0'               HISTORY AND STATUS SPECIFIED         07900020
OBTSW    EQU   X'08'               OBTAIN FAILED INDICATOR              07950020
DYNAMSW  EQU   X'04'               INDICATES DYNAMIC ENTRY FOUND        08000020
CONCATSW EQU   X'02'               INDICATES DYNAMIC ALLOCATION         08050020
WRITEMSK EQU   X'01'               DATA IN THE BUFFER (TO BE WRITTEN)   08100020
NOBTSW   EQU   X'F7'               FOR TURNING OFF OBTAIN SWITCH        08150020
HISTMEM  EQU   HISTMSK+MEMMSK      HISTORY AND MEMBERS SPECIFIED        08200020
HEXFF    EQU   X'FF'               DUMMY FOR TURNING OFF SWITCHES       08250020
FIRSTKWD EQU   X'01'               TEST IF FIRST KEYWORD NAME WAS FOUND 08350020
LOCNAME  EQU   4                   OFFSET TO LOCATE NAME                08400020
LOCCVOL  EQU   8                   OFFSET TO LOCATE CVOL                08450020
LOCWA    EQU   12                  OFFSET TO LOCATE WORKAREA            08500020
D0       EQU   0                   0                                    08600020
D1       EQU   1                   1                                    08650020
D2       EQU   2                   2                                    08700020
D3       EQU   3                   3                                    08750020
D4       EQU   4                   4                                    08800020
D8       EQU   8                   8                                    08850020
L0       EQU   0                   0                                    08900020
L1       EQU   1                   1                                    08950020
L2       EQU   2                   2                                    09000020
FOUR     EQU   4                   4                                    09050020
L4       EQU   4                   4                                    09100020
L3       EQU   3                   3                                    09150020
L7       EQU   7                   7                                    09300020
L8       EQU   8                   8                                    09350020
D5       EQU   5                   5                                    09400020
D6       EQU   6                   6                                    09450020
D9       EQU   9                   9                                    09550020
D10      EQU   10                  10                                   09650020
FIRSTVOL EQU   6                   OFFSET VOLID IN LOCATE VOLUME LIST   09700020
LOCSAVOF EQU   72                  OFFSET TO LOCAL SAVEAREA             09750020
DSNAMMAX EQU   44                  MAXIMUM SIZE OF DSNAME               09800020
AMPHERND EQU   C'&&'               AMPHERSAND                           09850020
ASTERSK  EQU   C'*'                ASTERISK                             09900020
MAXBUF   EQU   72                  MAXIMUM OUTPUT LINE                  09950020
CRDTOFF  EQU   9                   OFFSET CREATION DATE FIELD IN BUFFER 10000020
STATOFF1 EQU   2                   STATUS WITHOUT HISTORY OFFSET        10050020
NXTBUF   EQU   10                  USED TO BUMP TO NEXT BUFFER SLOT     10100020
MNTHS    EQU   12                  LOOP CONTROL FOR MONTHS              10150020
STATOFF2 EQU   39                  STATUS WITH HISTORY OFFSET           10200020
RETCDOF  EQU   14                  RETURN CODE OFFSET UNPACK AREA       10250020
COMMA    EQU   C','                COMMA                                10300020
PERIOD   EQU   C'.'                PERIOD                               10350020
LPAREN   EQU   C'('                LEFT PARENTHESIS              A42338 10360021
RPAREN   EQU   C')'                RIGHT PARENTHESIS             A42338 10370021
BACKWARD EQU   4                   USED FOR BACK CHAIN DISPLACEMENT     10400020
FORWARD  EQU   8                   USED FOR FORWARD CHAIN DISPLACEMENT  10450020
RETCD12  EQU   12                  RETURN CODE OF 12                    10500020
ZONE     EQU   C'0'                USED FOR ZERO OF ZONE MASK           10550020
EXITCD   EQU   X'87'               USED FOR JFCB DCB EXIT CODE          10600020
CHARU    EQU   C'U'                CHARACTER U                          10650020
SWON     EQU   X'FF'               MASK TURN SWITCH ON                  10660020
SWOFF    EQU   X'00'               MASK TURN SWITCH OFF                 10670020
         EJECT                                                          10700020
         SAVE  (14,12),,*          SAVE REGISTERS                       10750020
         LR    R11,R15             SAVE ENTRY POINT ADDRESS             10800020
         USING OBTWAD,R12          USE R12 FOR MEMBER DSECT             10850020
         USING IKJEHAL1,R11        USE R11 FOR MAIN BASE                10900020
         LR    R2,R1               SAVE PARAMETER LIST FROM TMP         10950020
         GETMAIN R,LV=INITSIZE,SP=SSP GET CORE                          11000020
         ST    R13,BACKWARD(R1)    SET UP BACKWARD CHAIN                11050020
         ST    R1,FORWARD(R13)     SET UP FORWARD CHAIN                 11100020
         LR    R13,R1              SET UP ADDRESSABILITY FOR WORK SPACE 11150020
         USING INITCORE,R13        USE R13 FOR WORK BASE                11200020
         MVI   STACKSW,SWOFF       TURN STACK SWITCH OFF                11310020
         XC    CTLA(CTLL),CTLA     CLEAR CONTROL AREA                   11350020
         LA    R3,PUTLLIST         ADDRESS OF LIST FOR PUTLINE          11400020
         ST    R3,PUTLCON          -TO WRITE ROUTINE PARAMETER LIST     11450020
         LA    R3,DPUTLINE         ADDRESS OF PUTLINE MACRO LIST FORM   11500020
         ST    R3,DPUTLCON         -TO WRITE ROUTINE PARAMETER LIST     11550020
         LA    R3,CPECB            COMMAND PROCESSOR'S ECB              11600020
         ST    R3,ECBPTR           - TO WRITE ROUTINE PARAMETER LIST    11650020
         XC    RETCD,RETCD         CLEAR RETURN CODE SAVE AREA          11700020
         XC    CPECB,CPECB         CLEAR ECB                            11750020
*  SAVE PARMLIST FROM CPPL IN WORKAREA                                  11800020
         L     R3,CPPLUPT-CPPL(R2) UPT POINTER                          11900020
         ST    R3,UPTPTR           SAVE UPT POINTER                     11950020
         L     R3,CPPLPSCB-CPPL(R2) PSCB PTR                            12000020
         ST    R3,PSCBPTR          SAVE PSCB POINTER                    12050020
         L     R3,CPPLECT-CPPL(R2) ECT POINTER                          12100020
         ST    R3,ECTPTR           SAVE ECT POINTER                     12150020
         LOAD  EP=IKJPUTL          LOAD PUTLINE                         12200020
         ST    R0,PUTLADDR         SAVE PUTLINE ADDRESS                 12250020
         MVC   GETML(LILFS),GETMLMDL MOVE LIST FORMS OF GETMAIN ETC     12300020
         MVI   OUTBUF,BLANK        BLANK                                12350020
         MVC   OUTBUF+D1(L'OUTBUF-D1),OUTBUF -OUTPUT BUFFER             12400020
         MVC   DPUTLINE(LTPUTL),TPUTMDL INITIALIZE PUTLINE              12450020
*  SETUP PARMLIST FOR PARSE, THEN PARSE COMMAND STRING                  12550020
         LA    R3,PUTLLIST         POINT TO SPACE FOR PPL               12650020
         USING PPL,R3              ADDRESSABILITY FOR PPL               12700020
         L     R1,UPTPTR           UPT POINTER                          12850020
         ST    R1,PPLUPT           -TO LIST                             12900020
         L     R1,ECTPTR           ECT POINTER                          12950020
         ST    R1,PPLECT           -TO LIST                             13000020
         L     R1,ECBPTR           CP'S ECB POINTER                     13050020
         ST    R1,PPLECB           -TO LIST                             13100020
         L     R1,PRSEC01          POINTER TO PCL                       13150020
         ST    R1,PPLPCL           -TO LIST                             13200020
         LA    R1,PARDSECT         POINTER TO ANSWER PLACE              13250020
         ST    R1,PPLANS           -TO LIST                             13300020
         L     R1,D0(R2)           POINTER TO COMMAND BUFFER            13350020
         ST    R1,PPLCBUF          -TO LIST                             13400020
         DROP  R3                  PPL NO LONGER NEEDED                 13450020
         LA    R1,PUTLLIST         PARSE PARAMETER LIST                 13500020
         LINK  EP=IKJPARS,MF=(E,(1)) PARSE LISTALC COMMAND              13550020
*                                                                       13600020
*     TEST FOR PARSE RETURN CODES -- IF ATTENTION RETURN WITH CODE  12  13650020
*                                                                       13700020
         B     PARSCODE(R15)       ANALYZE RETURN CODE FROM PARSE       13750020
PARSCODE B     PARSCD00            RC=00 SUCCESSFUL PARSE               13850020
         B     PARSCD04            RC=04 UNABLE TO PROMPT               13900020
         B     PARSCD08            RC=08 ATTENTION - ECB POSTED         13950020
         B     PARSCD12            RC=12 INVALID PARAMETERS             14000020
         B     PARSCD16            RC=16 NO SPACE AVAILABLE             14050020
PARSCD08 LA    R1,RETCD12          RETURN CODE OF 12 FOR TMP            14200020
         ST    R1,RETCD            SAVE IT FOR THE WRAPUP ROUTINE       14250020
         B     WRAPUP00            GO TERMINATE                         14300020
PARSCD12 BAL   R8,CVDREG15         CONVERT REG15 AND SET UP INSERT      14450020
         LA    R1,SECMSG10         SECOND LEVEL MESSAGE 10              14500020
         B     PARSERR1            GO PROCESS ERROR                     14550020
PARSCD16 XC    ERRSECND,ERRSECND   CLEAR SECOND LEVEL                   14600020
         XC    ERRINST1,ERRINST1   CLEAR INSERT                         14620020
         LA    R1,MSG06            MESSAGE 6                            14650020
         B     PARSERR2            SET UP PARMLIST                      14700020
PARSERR1 STH   R1,ERRSECND         SAVE SECOND LEVEL MESSAGE NUMBER     14900020
         LA    R1,MSG05            MESSAGE 5                            14950020
PARSERR2 STH   R1,ERRFIRST         SAVE MESSAGE NUMBER                  15000020
         BAL   R8,ERROUT           GO TO ERROR ROUTINE                  15050020
PARSCD04 MVI   STACKSW,SWON        TURN STACK SWITCH ON                 15060020
         LA    R1,RETCD12          SET RETURN CODE FOR TMP              15100020
         ST    R1,RETCD            SAVE FOR WRAPUP ROUTINE              15150020
         B     WRAPUP00            GO TO TERMINATE ROUTINE              15200020
CVDREG15 CVD   R15,ERRINSRT+D8     CONVERT TO DECIMAL                   15450020
         UNPK  ERRINSRT+D1(L4),ERRINSRT+RETCDOF(D3) UNPACK              15500020
         MVI   ERRINSRT,D2         MOVE IN LENGTH                       15550020
         LA    R1,ERRINSRT         INSERT ADDRESS                       15600020
         ST    R1,ERRINST2         -TO INSERT POINTER                   15650020
         XC    ERRINST1,ERRINST1   NO INSERT FOR 1ST LEVEL MESSAGE      15700020
         BR    R8                  RETURN TO CALLER                     15750020
*     SUCCESSFUL RETURN FROM PARSE  COMES HERE                          15800020
PARSCD00 L     R9,PARDSECT         ADDRESS OF DSECT RETURNED BY PARSE   15850020
         USING IKJPARMD,R9         ADDRESSABILITY PARSE DSECT           15900020
         TM    PSTAT+D1,FIRSTKWD   WAS STATUS SPECIFIED                 15950020
         BNO   PAR04               IF NOT, BRANCH                       16000020
         OI    CNTRL,STATMSK       IF YES, SET SWITCH                   16050020
PAR04    TM    PHIST+D1,FIRSTKWD   WAS HISTORY SPECIFIED                16150020
         BNO   PAR08               IF NOT, BRANCH                       16200020
         OI    CNTRL,HISTMSK       IF YES, SET SWITCH                   16250020
PAR08    TM    PMEM+D1,FIRSTKWD    WAS MEMBERS SPECIFIED                16350020
         BNO   PAR12               IF NOT, BRANCH                       16400020
         OI    CNTRL,MEMMSK        IF YES, SET SWITCH                   16450020
PAR12    TM    PSYSN+D1,FIRSTKWD   WAS SYSNAMES SPECIFIED               16550020
         BNO   PAR16               IF NOT, BRANCH                       16600020
         OI    CNTRL,SYSNMSK       IF YES, SET SWITCH                   16650020
PAR16    LR    R1,R9               PARSE DSECT TO BE RELEASED           16750020
         IKJRLSA PARDSECT          FREE PARSE DSECT CORE                16800020
         DROP  R9                  PARSE DSECT NO LONGER NEEDED         16850020
         EJECT                                                          16900020
*********************************************************************** 16950020
*                                                                     * 17000020
*     THIS ROUTINE LOCATES THE DSE CHAIN IN THE FOLLOWING MANNER-     * 17050020
*        1. IT GOES TO THE CVT TO GET THE TCB ADDRESS.                * 17100020
*        2. IT TAKES FROM THE TCB THE PTR TO THE JSCB.                * 17150020
*        3. IT USES THE JSCB TO GET THE PTR TO THE CSCB.              * 17200020
*        4. IT TAKES THE THE TJID FIELD FROM THE CSCB AND SAVES IT.   * 17250020
*        5. THE ADDRESS OF THE TS CVT IS GOTTEN FROM THE REGULAR CVT. * 17300020
*        6. THE ADDRESS OF THE TJB TABLE IS GOTTEN FROM THE TS CVT.   * 17350020
*        7. THE TJID MULTIPLIED BY THE LENGTH OF ONE TJB ADDED TO     * 17400020
*           THE ADDRESS OF THE TJB TABLE RESULTS IN THE ADDRESS       * 17450020
*           OF THE PROPER TJB.                                        * 17500020
*        8. THE ADDRESS OF THE TJBX IS TAKEN FROM THE TJB.            * 17550020
*        9. THE ADDRESS OF THE DSE IS TAKEN FROM THE TJBX.            * 17600020
*                                                                     * 17650020
*     ONCE THE DSE POINTER IS OBTAINED, IT IS CHECKED FOR ZERO.       * 17700020
*     IF THE POINTER IS ZERO IT MEANS THE USER LOGGED ON WITH A       * 17750020
*     PROCEDURE THAT CONTAINED NO DD CARDS AND AN INFORMATIVE MESSAGE * 17800020
*     IS SENT TO THE USER FOLLOWED BY TERMINATION. IF THE POINTER     * 17850020
*     IS NONZERO, MAINLINE PROCESSING BEGINS.                         * 17900020
*                                                                     * 17950020
*********************************************************************** 18000020
         SPACE                                                          18010020
         L     R2,CVTPTR           POINTER TO CVT                       18050020
         USING CVTTCBP,R2          ADDRESSABILITY CVT                   18100020
         L     R3,CVTTCBP          POINTER TO TCB                       18150020
         L     R4,CVTTSCVT         POINTER TO TS CVT                    18200020
         L     R2,D0(R3)           POINTER TO CURRENT TCB               18250020
         USING TCB,R2              ADDRESSABILITY TCB                   18300020
         L     R2,TCBJSCB          POINTER TO JSCB FROM TCB             18350020
         USING IEZJSCB,R2          ADDRESSABILITY JSCB                  18400020
         L     R2,JSCBCSCB         POINTER TO CSCB FROM JSCB            18450020
         USING CHAIN,R2            ADDRESSABILITY CSCB                  18500020
         LH    R5,CHTJID           TJID                                 18550020
         LR    R2,R4               COPY THE TS CVT ADDRESS              18600020
         USING TSCVT,R2            ADDRESSABILITY TS CVT                18650020
         L     R4,TSCVTTJB         TOP OF TJB TABLE                     18700020
         LH    R3,TSCVTSZU         LENGTH OF ONE TJB ENTRY              18750020
         MR    R2,R5               OFFSET TO PROPER TJB                 18800020
         LA    R2,D0(R4,R3)        POINTER TO PROPER TJB                18850020
         USING TJB,R2              ADDRESSABILITY TJB                   18900020
         L     R2,TJBEXTNT         POINTER TO TJBX                      18950020
         USING TJBX,R2             ADDRESSABILITY TJBX                  19000020
         L     R9,TJBXDSE          POINTER TO DSE                       19050020
         DROP  R2                  TJBX NO LONGER NEEDED                19100020
         USING DSE,R9              ADDRESSABILITY DSE, ENTIRE PROGRAM   19150020
         LTR   R9,R9               TEST ADDRESS OF DSE FOR ZERO         19200020
         BNZ   DSEOK               NOT ZERO, GO PROCESS                 19250020
         LA    R1,MSG03            MESSAGE 3                            19300020
         STH   R1,ERRFIRST         TO PARAMETER LIST FOR ERROUT         19350020
         XC    ERRSECND,ERRSECND   NO SECOND LEVEL MESSAGE              19400020
         XC    ERRINST1,ERRINST1   NO FIRST LEVEL INSERT                19450020
         BAL   R8,ERROUT           GO TO ERROR ROUTINE                  19500020
         B     WRAPUP00            GO TO NORMAL TERMINATION             19550020
*                                                                       19600020
*     NORMAL PROCESSING BEGINS HERE                                     19650020
*                                                                       19700020
DSEOK    TM    CNTRL,HISTMEM+SYSNMSK IS CORE NEEDED                     19850020
         BZ    NOMEMREQ            NO PROCESS NORMAL                    19900020
         BAL   R8,LGM02            GO ISSUE GETMAIN                     19950020
         TM    CNTRL,MEMMSK        ARE MEMBER NAMES TO BE LISTED        20050020
         BNO   NOMEMREQ            BRANCH AROUND SET UP IF NOT          20100020
         LOAD  EP=IKJEHMEM         LOAD MEMBERS ROUTINE                 20250020
         ST    R0,MEMMOD           SAVE ADDRESS OF MEMBERS ROUTINE      20350020
*********************************************************************** 20450020
*                                                                     * 20500020
*        MAIN PROCESSING ROUTINE--REG 9 POINTS AT CURRENT DSE BLOCK   * 20550020
*                                                                     * 20600020
*********************************************************************** 20650020
NOMEMREQ LA    R7,OUTBUF           BUFFER ADDRESS                       20750020
         LR    R14,R7              INDICATE A SKIP                      20800020
         BAL   R8,WRITE            GO TO WRITE ROUTINE                  20850020
         TM    CNTRL,HISTSTAT      CHECK FOR HISTORY OR STATUS          20900020
         BZ    SKIPHDNG            NEITHER, SKIP HEADING                20950020
         TM    CNTRL,HISTMSK       WAS HISTORY SPECIFIED                21000020
         BNO   NXCHECK             NO, CHECK STATUS                     21050020
         MVC   OUTBUF(L'TITLE1),TITLE1 MOVE HEADING TO BUFFER           21100020
         LA    R7,L'TITLE1(R7)     POINT BEYOND HISTORY HEADING         21150020
NXCHECK  TM    CNTRL,STATMSK       WAS STATUS SPECIFIED                 21200020
         BZ    WRITHDNG            NO, GO WRITE HEADING                 21250020
         MVC   D0(L'TITLE2,R7),TITLE2 MOVE HEADING TO BUFFER            21300020
         LA    R7,L'TITLE2(R7)     POINT AT END OF DATA                 21350020
WRITHDNG LR    R14,R7              SETUP FOR WRITING HEADING            21450020
         LA    R7,OUTBUF           POINT AT BUFFER                      21500020
         BAL   R8,WRITE            GO WRITE BUFFER                      21550020
         LR    R14,R7              SETUP FOR LINESKIP                   21600020
         BAL   R8,WRITE            GO SKIP A LINE                       21650020
*********************************************************************** 21750020
*                                                                     * 21800020
*        THIS ROUTINE IS THE BASIC LISTALC FUNCTION. THE ROUTINE      * 21850020
*        CHECKS THE CURRENT DSE BLOCK TO SEE IF IT IS A DYNAM ENTRY.  * 21900020
*        IF IT IS, THE DYNAM HANDLING ROUTINE IS GIVEN CONTROL FOR    * 21950020
*        THE DURATION OF THE PROCESSING OF THE COMMAND. IF IT IS NOT  * 22000020
*        A DYNAM, THE DSNAME IS CHECKED TO SEE IF IT IS A SYSTEM      * 22050020
*        GENERATED NAME AND IF SO IS PROCESSED ONLY IF 'SYSNAMES' IS  * 22100020
*        SPECIFIED.                                                   * 22150020
*  NOTE- A MODIFICATION WAS MADE IN THIS ROUTINE TO SEE IF THE DSE    * 22250020
*  BLOCK HAS THE UNUSED BIT AND NOT PERMANENT BIT ON IN ADDITION TO   * 22300020
*  OR IN PLACE OF THE DYNAM BIT.  THIS WILL ENABLE A COUNT            * 22350020
*  OF ACTUAL AVAILABLE ENTRIES FOR DYNAMIC ALLOCATION                 * 22400020
*                                                                     * 22410020
*********************************************************************** 22450020
SKIPHDNG EQU   *                   ALIAS FOR BSCROUT                    22460020
BSCROUT  TM    DSECNTRL,DSEPERM    IS ENTRY PERMANENTLY ALLOCATED       22500020
         BO    BNORM               YES GO TO NORMAL PROCESSING          22550020
         TM    DSECNTRL,DSENUSED+DSEDTIOT IS IT DYNAM OR UNUSED         22600020
         BZ    BNORM               NO GO TO NORMAL PROCESSING           22650020
         B     DYNAMRT             YES GO TO DYNAM ROUTINE              22700020
BNORM    CLC   NULLFILE,DSEDSNAM   SEE IF DSNAME IS NULLFILE            22750020
         BE    NULLFRT             YES, GO TO NULLFILE HANDLING ROUTINE 22800020
         TM    DSEDSNAM,ASTERSK    SEE IF DSNAME IS * (ASTERISK)        22850020
         BO    TERMFRT             YES, PROCESS AS A TERMINAL FILE      22900020
         TM    CNTRL,SYSNMSK       WAS SYSNAMES SPECIFIED               23000020
         BO    BSCRT00A            YES, SKIP TEST FOR SYSTEM NAME       23050020
*********************************************************************** 23150020
*                                                                     * 23200020
*   THE FOLLOWING CODE WILL TEST FOR SYSTEM GENERATED NAMES.          * 23250020
*   THE TEST MAKES USE OF (AND IS DEPENDENT ON) THE FACT THAT         * 23300020
*        1.    THE ZONE FIELD OF ALL NUMERICS IS THE SAME             * 23350020
*        2.    THE NUMERIC PORTION OF A BYTE IS BINARY ZERO FOR THE   * 23400020
*              CHARACTER ZERO (0).                                    * 23450020
*   THE TEST IS PREFORMED BY ANDING A MASK OF THE CONSTANT CHARACTERS * 23500020
*   AND CHARACTER ZEROS FOR THE NUMERIC FIELDS OF DATE AND TIME,      * 23550020
*   AGAINST THE DSNAME BEING TESTED.  THE RESULT IS THEN EXCLUSIVE    * 23600020
*   OR'ED AGAINST THE ORIGINAL MASK.  RESULT SHOULD BE ZERO.          * 23650020
*                                                                     * 23700020
*********************************************************************** 23750020
         MVC   SYSNM(L'SYSNMMDL),SYSNMMDL MOVE MASK TO WORK AREA        23800020
         NC    SYSNM(L'SYSNMMDL),DSEDSNAM AND MASK AGAINST DSNAME       23850020
         XC    SYSNM(L'SYSNMMDL),SYSNMMDL EX-OR PRODUCT AGAINST MASK    23900020
         BZ    NXDSEBLK            IF SYSNAME, PROCESS NEXT BLOCK       23950020
         CLI   DSEDSNAM,AMPHERND   IS NAME SYSTEM ASSIGNED              24000020
         BE    NXDSEBLK            YES, PROCESS NEXT DSE BLOCK          24050020
         B     BSCRT00             NO, PROCESS NORMALLY                 24100020
BSCRT00A CLI   DSEDSNAM,AMPHERND   DOES DSNAME BEGINS WITH AMPHERSAND   24200020
         BNE   BSCRT00             NO, GO PROCESS NORMALLY              24250020
         LA    R2,OBTDCB           DCB ADDRESS                          24300020
         USING IHADCB,R2           ADDRESSABILITY DCB                   24350020
         MVC   DCBDDNAM(DDNAMLEN),DSEDDNAM MOVE DDNAME FROM DSE TO DCB  24400020
         LA    R1,RDJL             LIST FORM RDJFCB                     24450020
         RDJFCB ((R2)),MF=(E,(R1)) ISSUE READ JFCB                      24500020
         DROP  R2                  DCB NO LONGER NEEDED                 24550020
         MVC   OUTBUF(DSNAMMAX),OBTDSNAM MOVE DSNAME FROM JFCB          24600020
         LA    R7,OUTBUF           BUFFER ADDRESS                       24650020
         LA    R14,DSNAMMAX(R7)    END OF BUFFER ADDRESS                24700020
         B     BSCRT00B            GO CHECK FOR KEYWORDS                24800020
BSCRT00  LA    R7,OUTBUF           POINTER TO BUFFER                    24900020
         XR    R1,R1               CLEAR FOR INSERT                     24950020
         IC    R1,DSEDSLNG         GET LENGTH OF DSNAME                 25000020
         LA    R3,DSEDSNAM         POINTER TO DSNAME                    25050020
         BCTR  R1,R0               DECREMENT LENGTH FOR MOVE            25100020
         EX    R1,MOVE             MOVE DSNAME TO BUFFER                25150020
         LA    R14,D1(R7,R1)       POINT AT END OF DATA                 25200020
         TM    DSECNTRL,DSEMEM     IS MEMBER ALLOCATED           A42338 25210021
         BNO   BSCRT00B            NO, SKIP MEMBER PROCESSING    A42338 25220021
*  MEMBER NAME IMMEDIATELY FOLLOWS DATA SET NAME IN DSE.         A42338 25230021
*  IT IS NOT POINTED TO DIRECTLY.  IT IS OBTAINED BY ADDING DATA A42338 25240021
*  SET NAME LENGTH TO DATA SET NAME POINTER.                     A42338 25242021
         LA    R3,D1(R1,R3)        POINT TO MEMBER NAME          A42338 25244021
         MVI   D0(R14),LPAREN      MOVE IN LEFT PARENTHESIS      A42338 25246021
         LA    R14,D1(R14)         POINT PAST PARENTHESIS        A42338 25248021
         MVC   D0(L8,R14),D0(R3)   MOVE MEMBER NAME              A42338 25248421
         LA    R14,D8(R14)         POINT PAST MEMBER NAME        A42338 25248821
MEMLOOP  BCTR  R14,R0              POINT TO PRECEDING CHARACTER  A42338 25249221
         CLI   D0(R14),BLANK       IS IT A BLANK                 A42338 25249621
         BE    MEMLOOP             YES, CHECK PREVIOUS CHARACTER A42338 25249721
         MVI   D1(R14),RPAREN      MOVE IN CLOSING PARENTHESIS   A42338 25249821
         LA    R14,D2(R14)         POINT PAST DATA               A42338 25249921
BSCRT00B BAL   R8,WRITE            GO WRITE THE NAME             A42338 25250021
         TM    CNTRL,HISTMEM       CHECK FOR HISTORY OR MEMBERS  A42338 25350021
         BZ    BSCRT01             NEITHER, CHECK STATUS                25400020
         BAL   R8,OBTRT            OBTAIN DSCB                          25450020
         TM    CNTRL,HISTMSK       WAS HISTORY REQUESTED                25550020
         BNO   BSCRT01             NO, CHECK STATUS                     25600020
         L     R15,VCONHIST        ADDRESS OF HISTORY ROUTINE           25650020
         BALR  R14,R15             GO TO HISTORY ROUTINE                25700020
BSCRT01  TM    CNTRL,STATMSK       WAS STATUS REQUESTED                 25800020
         BNO   BSCRT02             NO, CHECK WRITE SWITCH               25850020
         L     R15,VCONSTAT        ADDRESS OF STATUS ROUTINE            25900020
         BALR  R14,R15             GO TO STATUS ROUTINE                 25950020
BSCRT02  TM    CNTRL,WRITEMSK      IS WRITE SWITCH ON                   26050020
         BNO   BSCRT02A            NO, GO CHECK NEXT OPTION             26100020
         LA    R7,OUTBUF           POINT AT BUFFER                      26150020
         LA    R14,MAXBUF(R7)      POINT AT END OF BUFFER               26200020
         BAL   R8,WRITE            GO WRITE BUFFER TO TERMINAL          26250020
         NI    CNTRL,HEXFF-WRITEMSK TURN OFF WRITE SWITCH               26300020
BSCRT02A TM    CNTRL,OBTSW         CHECK FOR OBTAIN SWITCH              26400020
*                                                                     * 26450020
*  IF THE OBTAIN SWITCH IS TURNED ON, IT MEANS THAT THE OBTAIN ISSUED * 26500020
*  FOR HISTORY INFORMATION FAILED AND NO DATA WAS SUPPLIED FOR THE    * 26550020
*  HISTORY OPTION. THE ERROR WAS NOT PROCESSED UNTIL NOW IN           * 26600020
*  ORDER TO ALLOW STATUS INFORMATION TO BE PROCESSED IF REQUESTED.    * 26650020
*                                                                     * 26750020
         BNO   BSCRT03             NO, GO CHECK FOR MEMBERS             26800020
         NI    CNTRL,NOBTSW        TURN OFF OBTAIN SWITCH               26850020
         L     R15,OBTAINRC        GET OBTAIN RETURN CODE               26900020
         LA    R15,D0(R15)         CLEAR HIGH ORDER BYTE                26950020
         TM    OBTAINRC,HEXFF      TEST FOR LOCATE FAILURE              27000020
         BNO   OBTCODE(R15)        NO, ANALYZE OBTAIN RETURN CODE       27050020
         LA    R1,MSG01            MESSAGE 1                            27100020
         STH   R1,ERRFIRST         INTO LIST FOR ERROR HANDLER          27150020
         LA    R1,SECMSG05         SECOND LEVEL MESSAGE 5               27200020
         STH   R1,ERRSECND         INTO LIST FOR ERROR HANDLER          27250020
         BAL   R8,CVDREG15         CONVERT RETURN CODE                  27300020
         BAL   R8,ERROUT           GO WRITE ERROR MESSAGE               27350020
         B     BSCRT04             CHECK FOR MORE DSE BLOCKS            27400020
OBTCODE  DS    F                   RC=00 HANDLED ELSEWHERE              27500020
         B     NOTDA               RC=04 VOLUME NOT MOUNTED OR NOT DA   27550020
         B     NODSCB              RC=08 DSCB NOT ON THIS VOLUME        27600020
         B     OBTIOERR            RC=12 I/O ERROR DURING OBTAIN        27650020
         B     OBTIOERR            RC=16 ERROR IN OBTAIN WORK AREA      27700020
         B     OBTIOERR            RC=20 DSCB OUT OF VTOC EXTENT        27750020
NOTDA    LA    R1,SECMSG01         SECOND LEVEL MESSAGE 1               27950020
         B     OBTERRRT            GO PROCESS ERROR                     28000020
NODSCB   LA    R1,SECMSG02         SECOND LEVEL MESSAGE 2               28100020
         B     OBTERRRT            GO PROCESS ERROR                     28150020
OBTIOERR BAL   R8,CVDREG15         CONVERT RETURN CODE                  28300020
         LA    R1,SECMSG04         SECOND LEVEL MESSAGE 4               28350020
         B     OBINSERT            SET UP REST OF MESSAGE               28400020
OBTERRRT XC    ERRINST1(L'ERRINST1+L'ERRINST2),ERRINST1 CLEAR BYTES     28450020
OBINSERT STH   R1,ERRSECND         INTO LIST FOR ERROR ROUTINE          28500020
*  EITHER MEMBERS OR HISTORY OR BOTH FAILED                             28510020
         TM    CNTRL,HISTMSK       HISTORY OPTION ON                    28700020
         BO    HISTFAIL            IF ONES HISTORY FAILED               28750020
         B     TESTMEM             WAS MEMBERS ON                       28800020
HISTFAIL LA    R1,MSG01            MESSAGE 1                            28850020
         STH   R1,ERRFIRST         INTO LIST FOR ERROR ROUTINE          28900020
         BAL   R8,ERROUT           WRITE MESSAGE                        28950020
         TM    LOCSW,HEXFF         WAS LOCATE ISSUED                    29000020
         BNO   TESTMEM             NO, TEST MEMBERS OPTION              29050020
         MVI   LOCSW,D0            YES, TURN OFF SWITCH                 29100020
         B     MSGDONE             CHECK FOR MORE DSE ENTRIES           29150020
TESTMEM  TM    CNTRL,MEMMSK        IS MEMBERS OPTION ON                 29200020
         BNO   MSGDONE             CHECK FOR MORE DSE ENTRIES           29250020
         LA    R1,MSG04            MESSAGE 4                            29300020
         STH   R1,ERRFIRST         INTO LIST FOR ERROR ROUTINE          29350020
         BAL   R8,ERROUT           WRITE MESSAGE                        29400020
MSGDONE  B     BSCRT04             CHECK FOR MORE DSE ENTRIES           29450020
BSCRT03  TM    CNTRL,MEMMSK        WAS MEMBERS REQUESTED                29800020
         BNO   BSCRT04             NO, PROCESS NEXT ENTRY               29850020
         L     R15,VCONMEM         ADDRESS OF MEMBERS ROUTINE           29900020
         BALR  R14,R15             GO TO MEMBERS ROUTINE                29950020
BSCRT04  CLC   DSEFORWD,ZERO       ARE THERE MORE DSE BLOCKS            30050020
         BE    WRAPUP              NO, GO FINISH                        30100020
         LA    R7,OUTBUF           SETUP TO SKIP A LINE                 30150020
         LR    R14,R7              NULL LINE                            30200020
         BAL   R8,WRITE            GO TO WRITE ROUTINE                  30250020
         L     R9,DSEFORWD         SETUP BASE TO NEXT DSE               30300020
         B     BSCROUT             GO PROCESS NEXT DSE BLOCK            30350020
NXDSEBLK CLC   DSEFORWD(L4),ZERO   CHECK CHAIN ADDRESS FOR ZERO         30550020
         BE    WRAPUP              YES, GO TO NORMAL TERMINATION        30600020
         L     R9,DSEFORWD         GET ADDRESS OF NEXT BLOCK            30650020
         B     BSCROUT             GO PROCESS IT                        30700020
         EJECT                                                          30800020
*********************************************************************** 30900020
*                                                                     * 30950020
*     THE NORMAL TERMINATION ROUTINE FIRST CHECKS TO SEE IF ANY DYNAM * 31000020
*     ENTRIES WERE FOUND. IF SO, A MESSAGE IS PUT TO THE TERMINAL     * 31050020
*     WITH THE COUNT, FOLLOWED BY THE DDNAMES IF STATUS WAS REQUESTED.* 31100020
*                                                                     * 31150020
*********************************************************************** 31200020
WRAPUP   TM    CNTRL,DYNAMSW       WERE ANY DYNAMS FOUND                31250020
         BNO   WRAPUP03            NO, PUT OUT MESSAGE                  31300020
         LH    R2,DYNAMCNT         PICK UP COUNT                        31350020
         CVD   R2,NULLCNT          CONVERT COUNT TO DECIMAL             31400020
         LA    R7,OUTBUF           POINT AT BUFFER                      31450020
         UNPK  D0(L3,R7),NULLCNT+D6(D2) UNPACK COUNT INTO BUFFER        31500020
         OI    D2(R7),ZONE         SET CORRECT ZONE                     31550020
         CLI   D0(R7),ZONE         ELIMINATE LEADING ZEROES             31600020
         BNE   DYNAMRT4            NONE, GO GET MESSAGE                 31650020
         MVC   D0(D3,R7),D1(R7)    SHIFT ZERO AWAY                      31700020
         CLI   D0(R7),ZONE         CHECK NEXT PLACE FOR ZERO            31750020
         BE    DYNAMRT5            YES, GO GET RID OF IT                31800020
         LA    R7,D3(R7)           NO, INDICATE PROPER DISPLACEMENT     31850020
DYNAMRT3 MVC   D0(L'DYNAMMSG,R7),DYNAMMSG PUT TEXT IN BUFFER            31900020
         LA    R14,L'DYNAMMSG(R7)  BUMP POINTER TO END OF DATA          31950020
         LA    R7,OUTBUF           START OF BUFFER                      32000020
         BAL   R8,WRITE            WRITE BUFFER                         32050020
         B     DYNAMRT6            GO CHECK STATUS                      32100020
DYNAMRT4 LA    R7,D4(R7)           PROPER DISPLACEMENT                  32200020
         B     DYNAMRT3            GO PUT OUT MESSAGE                   32250020
DYNAMRT5 MVC   D0(L2,R7),D1(R7)    SHIFT EXTRA ZERO OFF                 32350020
         LA    R7,D2(R7)           PROPER DISPLACEMENT                  32400020
         B     DYNAMRT3            GO COMPLETE MESSAGE                  32450020
DYNAMRT6 TM    CNTRL,STATMSK       WAS STATUS REQUESTED                 32550020
         BNO   WRAPUP00            NO, GO TERMINATE                     32600020
         L     R9,DYNAMSAV         ADDRESS OF FIRST DYNAM ENTRY         32650020
DYNAMRT7 MVC   OUTBUF+DYNDDOFF(DDNAMLEN),DSEDDNAM MOVE DDNAME TO BUFFER 32700020
         LA    R7,OUTBUF           POINT AT BUFFER                      32750020
         LA    R14,DDNAMLEN+DYNDDOFF(R7) END OF DATA POINTER            32800020
         BAL   R8,WRITE            GO WRITE BUFFER                      32850020
DYNAMRT8 CLC   DSEFORWD(L4),ZERO   IS THERE ANOTHER BLOCK               32900020
         BE    WRAPUP00            NO, GO TERMINATE                     32950020
         L     R9,DSEFORWD         POINTER TO NEXT BLOCK                33000020
         TM    DSECNTRL,DSEPERM    IS ENTRY PERMANENTLY ALLOCATED       33050020
         BO    DYNAMRT8            YES, CHECK NEXT ENTRY                33100020
         TM    DSECNTRL,DSENUSED+DSEDTIOT IS IT DYNAM OR UNUSED         33150020
         BZ    DYNAMRT8            NO, CHECK NEXT ENTRY                 33200020
         B     DYNAMRT7            YES, OUTPUT NAME                     33250020
WRAPUP00 LA    R7,OUTBUF           SETUP TO SKIP A LINE                 33350020
         LR    R14,R7              NULL LINE                            33400020
         BAL   R8,WRITE            GO TO WRITE ROUTINE                  33450020
WRAPUPT  NC    OBTWA,OBTWA         TEST FOR OBTAIN WORK AREA            33500020
         BZ    WRAPUP01            NO, SKIP FREEMAIN                    33550020
*  FREE WORK CORE GOTTEN FOR OBTAIN AND JFCB WORKAREAS                  33650020
         LA    R2,OBTWA            POINTER TO CORE TO BE FREE           33750020
         LA    R1,FREEML           FREEMAIN PARAMETER LIST              33800020
         FREEMAIN E,A=(R2),LV=OBTWAL,SP=OSP,MF=(E,(1)) FREE CORE        33850020
WRAPUP01 NC    MEMMOD,MEMMOD       WAS MEMBER MODULE LOADED             34000020
         BZ    WRAPUP02            NO, SKIP DELETE                      34050020
         DELETE EP=IKJEHMEM        DELETE MEMBERS MODULE                34100020
WRAPUP02 DELETE EP=IKJPUTL         DELETE PUTLINE                       34200020
*  NOW CHECK IF AN ERROR HAS OCCURRED.  IF SO, THE STACK MUST BE        34210020
*  FLUSHED AND THE INPUT QUEUE CLEARED.                                 34220020
         CLI   STACKSW,SWON        IS STACK SWITCH ON                   34230020
         BNE   STACKOK             NO ERROR, END NORMALLY               34240020
         LA    R1,UPTPTR           POINT TO I/O PARAMETER LIST          34242020
         LA    R2,STACKPRM         POINT TO STACK PARM BLOCK            34244020
         ST    R2,PUTLADDR         POINT TO STACK PARM BLOCK            34246020
         STACK DELETE=ALL,MF=(E,(1)) FLUSH STACK                        34248020
         TCLEARQ INPUT             CLEAR ANYTHING TYPED AHEAD           34248420
STACKOK  EQU   *                   NORMAL RETURN FROM HERE              34248820
         L     R8,RETCD            GET RETURN CODE                      34250020
         LR    R1,R13              ADDRESS OF CORE TO BE FREED          34300020
         L     R13,D4(R13)         RESTORE ADDRESS OF CALLERS SAVEAREA  34350020
         FREEMAIN R,LV=INITSIZE,A=(1),SP=SSP FREE CORE                  34400020
         LR    R15,R8              PUT RETURN CODE IN REGISTER 15       34450020
         RETURN (14,12),T,RC=(15)  RETURN                               34500020
*                                                                       34550020
*  THIS ROUTINE WRITES MESSAGE THAT NO DATA SETS ARE AVAILABLE FOR      34600020
*  DYNAMIC ALLOCATION                                                   34650020
*                                                                       34750020
WRAPUP03 LA    R7,OUTBUF           SET UP FOR MESSAGE                   34850020
         MVC   D0(L'NODSE,R7),NODSE PUT TEXT IN BUFFER                  34900020
         LA    R14,L'NODSE(R7)     BUMP POINTER TO END OF DATA          34950020
         BAL   R8,WRITE            GO WRITE MESSAGE                     35000020
         B     WRAPUP00            GO TO TERMINATE ROUTINE              35050020
*********************************************************************** 35300020
*                                                                     * 35350020
*  GETMAIN ROUTINE FOR MEMBERS, SYSNAMES AND HISTORY WORK AREA        * 35400020
*                                                                     * 35450020
*********************************************************************** 35500020
LGM02    LA    R1,GETML            GETMAIN PARAMETER LIST               35600020
         LA    R2,OBTWA            ADDRESS OF CORE GOES TO OBTWA        35650020
         GETMAIN A=(R2),SP=OSP,LV=OBTWAL,MF=(E,(1)) GET CORE            35700020
         B     GMRC(R15)           ANALYZE GETMAIN RETURN CODE          35750020
GMRC     B     GMOK                RC = 0, GETMAIN OK                   35800020
         B     GMNOTOK             RETURN CODE=4, NO CORE AVAILABLE     35850020
GMOK     L     R12,OBTWA           ADDRESS OF CORE JUST GOTTEN          36000020
         ST    R12,OBTJFCBX        ADDRESS OF JFCB WORK AREA            36050020
         LA    R2,OBTDCB           ADDRESS OF DCB IN DSECT              36100020
         USING IHADCB,R2           ADDRESSABILITY DCB                   36150020
         MVC   OBTMACS(LOLFS),OLFS MOVE MACRO LIST FORMS TO DSECT       36200020
         LA    R15,OBTDCBXL        ADDRESS OF DCB EXIT LIST             36250020
         ST    R15,DCBEXLST        SET UP EXIT LIST ADDRESS             36300020
         MVI   OBTJFCBX,EXITCD     SET JFCB DCB EXIT CODE               36350020
         DROP  R2                  DCB NO LONGER NEEDED                 36400020
         BR    R8                  RETURN TO CALLER                     36450020
GMNOTOK  LA    R1,MSG02            MESSAGE 2                            36850020
         STH   R1,ERRFIRST         INTO LIST FOR ERROR HANDLER          36900020
         XC    ERRSECND,ERRSECND   CLEAR SECOND LEVEL MESSAGE           36950020
         LA    R1,ERRINSRT         PICK UP ADDRESS OF FIRST INSERT      37000020
         ST    R1,ERRINST1         PUT IN ERROR LIST                    37050020
         MVI   ERRINSRT,L'NHISTORY LENGTH OF INSERT                     37100020
         TM    CNTRL,HISTMSK       WAS HISTORY OPTION ON                37150020
         BNO   CKMEM               NO, CHECK MEMBERS OPTION             37200020
         NI    CNTRL,HEXFF-HISTMSK YES, TURN OFF SWITCH                 37250020
         MVC   ERRINSRT+D1(L'NHISTORY),NHISTORY HISTORY INSERT          37300020
         BAL   R8,ERROUT           GO WRITE MESSAGE                     37350020
CKMEM    TM    CNTRL,MEMMSK        IS MEMBERS OPTION ON                 37400020
         BNO   CKSYSNM             NO, CHECK SYSNAMES                   37450020
         NI    CNTRL,HEXFF-MEMMSK  TURN OFF MEMBERS OPTION              37500020
         MVC   ERRINSRT+D1(L'NMEMBERS),NMEMBERS MEMBERS INSERT          37550020
         BAL   R8,ERROUT           GO WRITE MESSAGE                     37600020
CKSYSNM  TM    CNTRL,SYSNMSK       IS SYSNAMES OPTION ON                37650020
         BNO   GMEND               IF NOT, EXIT                         37700020
         NI    CNTRL,HEXFF-SYSNMSK YES, TURN OFF SYSNAMES OPTION        37750020
         MVC   ERRINSRT+D1(L'NSYSNAME),NSYSNAME SYSNAMES INSERT         37800020
         MVI   ERRINSRT,L'NSYSNAME LENGTH OF INSERT                     37850020
         BAL   R8,ERROUT           GO WRITE MESSAGE                     37900020
GMEND    B     NOMEMREQ            GO PROCESS                           37950020
*********************************************************************** 38500020
*                                                                     * 38550020
*    THIS ROUTINE GETS CONTROL WHEN A NULLFILE IS FOUND. A MESSAGE IS * 38600020
*    WRITTEN OUT INDICATING THE NULLFILE IS PRESENT.  IF STATUS       * 38650020
*    WAS REQUESTED, THE DDNAME IS INCLUDED.                           * 38700020
*                                                                     * 38750020
*********************************************************************** 38800020
NULLFRT  LA    R7,OUTBUF           POINT AT BUFFER                      38850020
         MVC   D0(L'NULLFILE,R7),NULLFILE MOVE NULLFILE TO BUFFER       38900020
         LA    R14,L'NULLFILE(R7)  POINT AT END OF DATA                 38950020
         TM    CNTRL,STATMSK       WAS STATUS REQUESTED                 39000020
         BNO   NULLFRT1            NO, GO WRITE OUT BUFFER              39050020
         MVC   NULLDDOF(DDNAMLEN,R7),DSEDDNAM MOVE DDNAME TO BUFFER     39100020
         LA    R14,D2+DDNAMLEN(R14) POINT PAST DDNAME            A49871 39150021
NULLFRT1 BAL   R8,WRITE            GO WRITE BUFFER                      39200020
         B     BSCRT04             GO CHECK FOR MORE BLOCKS             39250020
*********************************************************************** 39450020
*                                                                     * 39500020
*     THIS ROUTINE GETS CONTROL WHEN AN ASTERISK (*) IS FOUND FOR THE * 39550020
*     DSNAME IN THE DSE ENTRY. THIS IS AN INDICATION THAT IT IS A     * 39600020
*     TERMINAL FILE AND A MESSAGE IS WRITTEN TO INDICATE THIS. IF     * 39650020
*     STATUS INFORMATION WAS REQUESTED, THE DDNAME WILL BE INCLUDED.  * 39700020
*                                                                     * 39800020
*********************************************************************** 39850020
TERMFRT  LA    R7,OUTBUF           POINT AT BUFFER                      39900020
         MVC   D0(L'TERMFILE,R7),TERMFILE MOVE TERMFILE TO BUFFER       39950020
         LA    R14,L'TERMFILE(R7)  POINT AT END OF DATA                 40000020
         TM    CNTRL,STATMSK       WAS STATUS REQUESTED                 40050020
         BNO   TERMFRT1            NO, GO WRITE BUFFER                  40100020
         MVC   TERMDDOF(DDNAMLEN,R7),DSEDDNAM MOVE DDNAME TO BUFFER     40150020
         LA    R14,D2+DDNAMLEN(R14) END OF DATA POINTER          A49871 40200021
TERMFRT1 BAL   R8,WRITE            GO WRITE BUFFER                      40300020
         B     BSCRT04             GO CHECK FOR MORE BLOCKS             40350020
*********************************************************************** 40550020
*                                                                     * 40600020
*     THIS ROUTINE GETS CONTROL IF AN AVAILABLE ENTRY IS FOUND IN     * 40650020
*     THE CHAIN OF DSE ENTRIES. IF IT IS THE FIRST TIME THE ROUTINE   * 40700020
*     HAS BEEN ENTERED, A SWITCH IS TURNED ON AND A COUNTER IS SET    * 40750020
*     TO ONE. THE ADDRESS OF THE FIRST DYNAM ENTRY IS SAVED. IF THIS  * 40800020
*     IS NOT THE FIRST TIME INTO THIS ROUTINE, THE COUNTER IS BUMPED  * 40850020
*     BY ONE AND AN EXIT IS TAKEN.                                    * 40900020
*                                                                     * 40950020
*********************************************************************** 41000020
DYNAMRT  TM    CNTRL,DYNAMSW       IS THIS FIRST DYNAM ENTRY            41050020
         BO    DYNAMRT1            NO, SKIP INITIALIZATION              41100020
         ST    R9,DYNAMSAV         SAVE POINTER TO THIS DYNAM ENTRY     41150020
         XC    DYNAMCNT,DYNAMCNT   CLEAR DYNAM COUNTER                  41200020
         OI    CNTRL,DYNAMSW       TURN ON DYNAM FOUND SWITCH           41250020
DYNAMRT1 LH    R1,DYNAMCNT         PICK UP DYNAM ENTRY COUNT            41350020
         LA    R1,ONE(R1)          BUMP COUNT BY ONE                    41400020
         STH   R1,DYNAMCNT         SAVE COUNT                           41450020
         TM    DSECNTRL,DSEDTIOT   IS TIOT DYNAM ENTRY                  41550020
         BO    NXDSEBLK            YES, PROCESS NEXT DSE                41600020
         B     BNORM               NO, ADD TO COUNT AND                 41650020
*                                  -LIST DATA SET INFORMATION           41700020
*********************************************************************** 41850020
*                                                                     * 41900020
*   THIS ROUTINE IS ENTERED IF HISTORY OR MEMBERS WAS REQUESTED       * 41950020
*   ON THE COMMAND.  IT MAKES THE NECESSARY CONCATENATION TESTS AND   * 42000020
*   ISSUES A LOCATE TO GET A VOLSER FOR THE OBTAIN IF THE             * 42050020
*   HISTORY OPTION WAS REQUESTED.  IF IT IS NOT                       * 42100020
*   CONCATENATED, A RDJFCB IS ISSUED FOR THE VOLSER.  IF THE OBTAIN   * 42150020
*   FOR THE DSCB FAILS, A SWITCH IS SET (OBTSW--ALSO SET IF LOCATE    * 42200020
*   FAILS), AND CONTROL IS RETURNED TO THE MAINLINE.  THE SWITCH IS   * 42250020
*   CHECKED IN THE MAINLINE AND A MESSAGE IS PUT OUT TO THE TERMINAL  * 42300020
*   INDICATING THE REQUESTED INFORMATION CANNOT BE SUPPLIED.          * 42350020
*                                                                     * 42400020
*********************************************************************** 42450020
OBTRT    STM   R0,R9,LOCSAVOF(R13) SAVE REGISTERS LOCALLY               42550020
         CLC   DSEDDNAM(L'BLANKS),BLANKS IS DDNAME BLANKS               42600020
         BE    HISTLOC             YES, MUST BE CONCATENATED            42650020
         TM    DSECNTRL,DSECCNCT   SEE IF DYNAMICATENATION BIT IS ON    42700020
         BO    HISTDCON            YES, CHECK FURTHUR                   42750020
         NI    CNTRL,HEXFF-CONCATSW TURN OFF CONCATENATION SWITCH       42800020
HISTGO   LA    R2,OBTDCB           ADDRESS OF THE DCB IN THE DSECT      42950020
         USING IHADCB,R2           ADDRESSABILITY DCB                   43000020
         MVC   DCBDDNAM,DSEDDNAM   PUT DDNAME IN DCB                    43050020
         LA    R1,RDJL             RDJFCB LIST FORM IN DSECT            43100020
         RDJFCB  ((R2)),MF=(E,(R1)) ISSUE READ JFCB                     43150020
         DROP  R2                  DCB NO LONGER NEEDED                 43200020
         LA    R15,JFCBVOLS        ADDESS OF VOLID                      43450020
         ST    R15,OBTVOL          -TO OBTAIN LIST                      43500020
HISTOBTN LA    R15,OBTDSNAM        ADDRESS OF THE DATA SET NAME         43600020
         ST    R15,OBTDSN          -TO OBTAIN LIST                      43650020
         LA    R15,OBTWORKA        ADDRESS OF 350 BYTE WORK AREA        43700020
         ST    R15,OBTWKA          -TO OBTAIN LIST                      43750020
         OBTAIN  OBTCLST           ISSUE OBTAIN                         43850020
         LTR   R15,R15             TEST RETURN CODE                     43950020
         BZ    OBTOKGO             ZERO, GO PROCESS INFORMATION         44000020
         ST    R15,OBTAINRC        NONZERO, SAVE RETURN CODE            44100020
         OI    CNTRL,OBTSW         TURN ON OBTAIN FAILED SWITCH         44150020
         B     BSCRT01             GO CHECK NEXT ENTRY                  44200020
HISTDCON TM    CNTRL,CONCATSW      CHECK CONCATENATION SWITCH           44350020
         BO    HISTLOC             IF ON, GO ISSUE LOCATE FOR VOLUMES   44400020
         OI    CNTRL,CONCATSW      IF OFF, TURN IT ON                   44450020
         B     HISTGO              GO PROCESS THIS ENTRY NORMALLY       44500020
HISTLOC  TM    CNTRL,HISTMSK       WAS HISTORY BIT ON                   44650020
         BNO   HISTLOC1            IF NOT DO NOT DO LOCATE              44700020
         XR    R15,R15             CLEAR REGISTER FOR INSERT            44750020
         IC    R15,DSEDSLNG        GET LENGTH OF DSNAME                 44800020
         MVI   OBTDSNAM,BLANK      BLANK OUT AREA TO CONTAIN            44850020
         MVC   OBTDSNAM+D1(L'OBTDSNAM-D1),OBTDSNAM -DSNAME              44900020
         LA    R7,OBTDSNAM         POINT AT AREA TO HOLD DSNAME         44950020
         LA    R3,DSEDSNAM         POINT AT DSNAME                      45000020
         BCTR  R15,R0              DECREMENT LENGTH FOR EXECUTE         45050020
         EX    R15,MOVE            MOVE DSNAME                          45100020
         MVC   LOCLIST(L'LOCLIST),CAM1 INITIALIZE LOCATE LIST           45150020
         LA    R1,OBTDSNAM         POINT AT DSNAME                      45200020
         ST    R1,LOCLIST+LOCNAME  PUT INTO CAMLST                      45250020
         XR    R1,R1               ZERO REGISTER                        45300020
         ST    R1,LOCLIST+LOCCVOL  INDICATE NO CVOL                     45350020
         LA    R1,LOCAREA          POINT AT LOCATE WORK AREA            45400020
         ST    R1,LOCLIST+LOCWA    PUT ADDRESS INTO CAMLST              45450020
         LOCATE LOCLIST            ISSUE LOCATE                         45550020
         LTR   R15,R15             TEST RETURN CODE                     45650020
         BZ    HISLOCOK            IF ZERO, GO DO OBTAIN                45700020
         ST    R15,OBTAINRC        SAVE LOCATE RETURN CODE              45750020
         OI    OBTAINRC,HEXFF      INDICATE RETURN CODE IS FROM LOCATE  45800020
         OI    CNTRL,OBTSW         TURN ON OBTAIN SWITCH                45850020
         B     BSCRT01             GO CHECK STATUS                      45900020
HISTLOC1 XC    DS1DSORG-OBTWAD(L2,R12),ZERO CLEAR DSORG FIELD           46000020
         B     BSCRT01             GO CHECK STATUS                      46050020
HISLOCOK LA    R15,LOCAREA+FIRSTVOL POINT AT FIRST VOLSER IN LIST       46250020
         ST    R15,OBTCLST+D8      PUT IN OBTAIN LIST                   46300020
         B     HISTOBTN            GO COMPLETE LIST AND ISSUE OBTAIN    46350020
OBTOKGO  LM    R0,R9,LOCSAVOF(R13) RESTORE REGISTERS                    46500020
         BR    R8                  RETURN                               46550020
         EJECT                                                          46650020
*********************************************************************** 46750020
*                                                                     * 46800020
*   INPUT TO THIS ROUTINE IS THE BUFFER ADDRESS IN REGISTER 7         * 46850020
*   AND THE END OF BUFFER ADDRESS IN REGISTER 14.                     * 46900020
*   THE RETURN ADDRESS IS IN REGISTER 8.                              * 46950020
*   THE OUTPUT BUFFER IS CLEARED AND RETURNED IN REGISTER 7.          * 47000020
*   TRAILING BLANKS WILL BE ELIMINATED.                               * 47050020
*                                                                     * 47100020
*   IMPORTANT---THIS ROUTINE REQUIRES NO BASE REGISTER. KEEP IT THAT  * 47150020
*   WAY SO THAT IKJEHMEM CAN USE IT.                                  * 47200020
*                                                                     * 47250020
*********************************************************************** 47300020
IKJEHWRT EQU   *                   WRITE ROUTINE EXTERNAL NAME          47310020
WRITE    STM   R0,R9,LOCSAVOF(R13) SAVE REGISTERS LOCALLY               47350020
         LR    R2,R14              GET END OF DATA POINTER              47400020
         SR    R2,R7               CALCULATE DATA LENGTH                47450020
         LA    R1,FOUR             DECREMENT BUFFER POINTER BY 4        47500020
         SR    R7,R1               -SO R7 WILL POINT AT LL FIELD        47550020
         LA    R2,FOUR(R2)         BUMP LL BY FOUR FOR LL AND OFFSET    47600020
         STH   R2,D0(R7)           STORE LENGTH                         47650020
         XC    D2(L2,R7),D2(R7)    CLEAR OFFSET BYTE                    47700020
         LR    R6,R7               PUT OUTPUT LINE POINTER IN PROPER    47750020
         LA    R1,PARMLSTL         POINT IN FRONT OF BUFFER             47800020
         SR    R7,R1               CONTANING VARIOUS ADCONS             47850020
         LM    R1,R5,D0(R7)        SET UP REGISTERS FOR PUTLINE         47900020
         L     R15,PARMLSTL-FOUR(R7) GET ENTRY POINT.                   47950020
         PUTLINE PARM=(R2),UPT=(R3),ECT=(R4),ECB=(R5),OUTPUT=((R6),    X48000020
               DATA),ENTRY=(15),MF=(E,(1)) PUTLINE                      48050020
         LA    R7,PARMLSTL+FOUR(R7) POINT BACK TO DATA BUFFER           48550020
         MVI   D0(R7),BLANK        BLANK FIRST BYTE OF BUFFER           48650020
         MVC   D1(L'OUTBUF-L1,R7),D0(R7) CLEAR BUFFER                   48700020
         LM    R0,R9,LOCSAVOF(R13) RESTORE CALLERS REGISTER             48750020
         BR    R8                  RETURN TO CALLER                     48800020
         EJECT                                                          48950020
*********************************************************************** 49050020
*                                                                     * 49100020
*  THIS ROUTINE IS USED TO OUTPUT ERROR MESSAGES.  INPUT IS A THREE   * 49200020
*  WORD LIST CALLED ERRPARM WHICH CONTAINS INFORMATION AS FOLLOWS-    * 49250020
*        BYTE 1 AND 2 - THE RELATIVE POSITION OF THE FIRST            * 49350020
*                       LEVEL MESSAGE IN THE MESSAGE CSECT            * 49400020
*        BYTE 3 AND 4 - THE RELATIVE POSITION OF THE SECOND           * 49450020
*                       LEVEL MESSAGE IN THE MESSAGE CSECT            * 49500020
*        SECOND WORD  - POINTS TO TEXT TO BE INSERTED AFTER THE       * 49550020
*                       FIRST SEGMENT OF FIRST LEVEL MESSAGE          * 49600020
*        THIRD WORD   - POINTS TO TEXT TO BE INSERTED AFTER THE       * 49650020
*                       FIRST SEGMENT OF SECOND LEVEL MESSAGE         * 49700020
*  REGISTER 8 IS THE RETURN REGISTER                                  * 49750020
*                                                                     * 49800020
*********************************************************************** 49850020
IKJEHERR EQU   *                   EXTERNAL NAME FOR ERROR ROUTINE      49860020
ERROUT   STM   R0,R9,LOCSAVOF(R13) SAVE LOCAL REGISTERS                 49900020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 49910020
         LA    R7,OUTBUF+D4        POINT AT PROPER BUFFER OFFSET        49950020
         LH    R1,ERRPARM          RELATIVE MESSAGE NUMBER              50000020
         BCTR  R1,R0               DECREMENT POSITION COUNT             50050020
         SLL   R1,D3               MULTIPLY BY 8 GIVES INDEX INTO TABLE 50100020
         L     R6,MSGCSECT         ADDRESS OF MESSAGE CSECT             50150020
         LA    R5,D0(R6,R1)        TABLE ENTRY FOR PROPER MESSAGE       50200020
         LH    R1,D0(R5)           LENGTH OF MESSAGE                    50250020
         LA    R2,D4(R1)           UP LENGTH FOR LL AND OFFSET FIELDS   50300020
         STH   R2,OUTBUF           SAVE LENGTH                          50350020
         XC    OUTBUF+D2(L2),OUTBUF+D2 CLEAR OFFSET FIELD               50400020
         LH    R4,D2(R5)           OFFSET TO MESSAGE IN CSECT           50450020
         LA    R3,D0(R6,R4)        POINTER TO MESSAGE IN CSECT          50500020
         BCTR  R1,R0               DECREMENT COUNT FOR EXECUTE          50550020
         EX    R1,MOVE             MOVE MESSAGE TO BUFFER               50600020
         LA    R7,D1(R1,R7)        POINT BEYOND MESSAGE                 50650020
         L     R4,ERRINST1         INSERTION POINTER                    50700020
         LTR   R4,R4               TEST FOR ZERO                        50750020
         BZ    SEGCHECK            IF ZERO, CHECK FOR SEGMENTATION      50800020
         XR    R1,R1               ZERO REGISTER                        50850020
         IC    R1,D0(R4)           GET LENGTH OF INSERT DATA            50900020
         LA    R3,D1(R4)           POINT AT INSERT DATA                 50950020
         LH    R2,OUTBUF           GET LENGTH                           51000020
         LA    R2,D0(R2,R1)        INCREMENT COUNT                      51050020
         STH   R2,OUTBUF           SAVE LENGTH AGAIN                    51100020
         BCTR  R1,R0               DECREMENT COUNT FOR EXECUTE          51150020
         EX    R1,MOVE             MOVE INSERT DATA TO BUFFER           51200020
         LA    R7,D1(R1,R7)        POINT BEYOND MESSAGE                 51250020
SEGCHECK LH    R4,D4(R5)           PICKUP OFFSET OF SEGMENT             51350020
         LTR   R4,R4               TEST FOR ZERO                        51400020
         BZ    SECLVTST            CHECK FOR SECOND LEVEL MESSAGE       51450020
         LA    R4,D0(R4,R6)        POINT AT SEGMENT TABLE               51500020
SEGLOOP  LH    R1,D0(R4)           PICK UP LENGTH OF SEGMENT            51600020
         LTR   R1,R1               TEST LENGTH                          51650020
         BZ    SECLVTST            CHECK FOR SECOND LEVEL MESSAGE       51700020
         LH    R2,OUTBUF           GET LENGTH                           51750020
         LA    R2,D0(R2,R1)        INCREMENT COUNT                      51800020
         STH   R2,OUTBUF           SAVE LENGTH AGAIN                    51850020
         LH    R3,D2(R4)           PICKUP OFFSET TO SEGMENT             51900020
         LA    R3,D0(R3,R6)        CALCULATE THE ADDRESS                51950020
         BCTR  R1,R0               DECREMENT FOR EXECUTE                52000020
         EX    R1,MOVE             MOVE SEGMENT TO BUFFER               52050020
         LA    R7,D1(R7,R1)        POINT AT END OF DATA IN BUFFER       52100020
         LA    R4,D4(R4)           NEXT SEGMENT SLOT IN TABLE           52150020
         B     SEGLOOP             PROCESS ANOTHER SEGMENT              52200020
*  THIS ROUTINE CHECKS FOR SECOND LEVEL MESSAGES,                       52210020
*  IF NONE IT PROCESSES FIRST LEVEL                                     52220020
SECLVTST LA    R1,D1               SEGMENT COUNT IS 1                   52550020
         ST    R1,MSGPARM1+D4      PUT IN PARM LIST                     52600020
         LA    R1,OUTBUF           POINT TO OUTPUT BUFFER               52650020
         ST    R1,MSGPARM1+D8      SAVE POINTER TO FIRST LEVEL MESSAGE  52700020
         LH    R1,ERRSECND         CHECK FOR SECOND LEVEL MESSAGE       52750020
         LTR   R1,R1               TEST FOR ZERO                        52800020
         BZ    NOSECLVL            NO SECOND LEVEL PUT OUT FIRST ONLY   52850020
         BCTR  R1,R0               DECREMENT POSITION COUNT             52900020
         LA    R0,D6               TABLE ENTRY SIZE                     52950020
         MR    R0,R0               OFFSET INTO TABLE CALCULATED         53000020
         LH    R4,D6(R5)           OFFSET TO SECOND LEVEL TABLE         53050020
         LA    R4,D0(R4,R6)        ADDRESS OF TABLE                     53100020
         LA    R5,D0(R4,R1)        OFFSET TO ENTRY IN TABLE             53150020
         LA    R7,SECBUFF+D4       POINT TO SECOND BUFFER OFFSET        53200020
         LH    R1,D0(R5)           GET LENGTH OF ENTRY                  53250020
         LA    R2,D4(R1)           UP LENGTH FOR LL AND OFFSET FIELDS   53300020
         STH   R2,SECBUFF          SAVE LENGTH OF FIRST SEGMENT         53350020
         XC    SECBUFF+D2(L2),SECBUFF+D2 CLEAR OFFSET FIELD             53400020
         LH    R4,D2(R5)           OFFSET TO MESSAGE IN CSECT           53450020
         LA    R3,D0(R6,R4)        ADDRESS OF MESSAGE IN CORE           53500020
         BCTR  R1,R0               DECREMENT LENGTH FOR EXECUTE         53550020
         EX    R1,MOVE             MOVE MESSAGE SEGMENT TO BUFFER       53600020
         LA    R7,D1(R1,R7)        BUMP BUFFER POINTER                  53650020
         MVC   SECBUFF+D10(L2),OUTBUF+D10 SET ID FOR SECOND LEVEL       53700020
         L     R4,ERRINST2         INSERT POINTER FOR SECOND LEVEL      53750020
         LTR   R4,R4               TEST FOR ZERO                        53800020
         BZ    SECSEGCK            IF ZERO, CHECK SEGMENTATION          53850020
         XR    R1,R1               ZERO REGISTER                        53900020
         IC    R1,D0(R4)           GET LENGTH OF INSERT DATA            53950020
         LH    R2,SECBUFF          SEGMENT LENGTH                       54000020
         LA    R2,D0(R2,R1)        UPDATE LENGTH OF BUFFER MESSAGE      54050020
         STH   R2,SECBUFF          SAVE LENGTH AGAIN                    54100020
         LA    R3,D1(R4)           POINT AT DATA                        54150020
         BCTR  R1,R0               DECREMENT COUNT FOR EXECUTE          54200020
         EX    R1,MOVE             MOVE DATA TO BUFFER                  54250020
         LA    R7,D1(R1,R7)        UPDATE BUFFER POINTER                54300020
SECSEGCK LA    R1,D1               SET SEGMENT COUNT TO ONE             54400020
         ST    R1,MSGPARM2+D4      PUT IT INTO PARM LIST                54450020
         LA    R1,SECBUFF          BUFFER ADDRESS                       54500020
         ST    R1,MSGPARM2+D8      -INTO LIST                           54550020
         LA    R1,MSGPARM2         CHAIN MESSAGE LEVEL                  54600020
         ST    R1,MSGPARM1         -PARAMETER LISTS                     54650020
         XC    MSGPARM2,MSGPARM2   END OF CHAIN LINK ADDRESS            54700020
         MVI   MSGPARM2,HEXFF      END OF LIST FLAG IN CHAIN FIELD      54750020
         LH    R4,D4(R5)           OFFSET TO SEGMENT TABLE              54800020
         LTR   R4,R4               TEST FOR ZERO                        54850020
         BZ    PUTMSG              IF ZERO, PUT OUT MESSAGE             54900020
         LA    R4,D0(R4,R6)        ADDRESS OF SEGMENT TABLE             54950020
         LH    R1,D0(R4)           LENGTH OF SEGMENT                    55000020
SECSEGLP LTR   R1,R1               IS THIS THE LAST SEGMENT             55100020
         BZ    PUTMSG              YES, GO WRITE MESSAGE                55150020
         LH    R2,SECBUFF          SEGMENT LENGTH                       55200020
         LA    R2,D0(R2,R1)        UPDATE LENGTH OF BUFFER MESSAGE      55250020
         STH   R2,SECBUFF          RE-STORE IT                          55300020
         LH    R3,D2(R4)           OFFSET TO SEGMENT                    55350020
         LA    R3,D0(R3,R6)        ADDRESS OF MESSAGE                   55400020
         BCTR  R1,R0               DECREMENT COUNT FOR EXECUTE          55450020
         EX    R1,MOVE             MOVE INTO BUFFER                     55500020
         LA    R7,D1(R7,R1)        UPDATE BUFFER OFFSET                 55550020
         LA    R4,D4(R4)           GET NEXT SEGMENT                     55600020
         B     SECSEGLP            GO PROCESS THIS SEGMENT              55650020
NOSECLVL XC    MSGPARM1,MSGPARM1   CLEAR SECOND LEVEL POINTER           55750020
         MVI   MSGPARM1,HEXFF      PUT IN END OF CHAIN MARK             55800020
PUTMSG   LM    R3,R5,UPTPTR        LOAD UPT, ECT, ECB ADDRESSES         55900020
         LA    R6,MSGPARM1         POINT TO MESSAGE PARM LISTS          55950020
         LA    R2,DPUTLINE         LIST FORM OF MACRO                   56000020
         LA    R1,PUTLLIST         LIST FOR E FORM OF MACRO             56050020
         L     R15,PUTLADDR        ADDRESS OF PUTLINE ROUTINE           56100020
         PUTLINE PARM=(R2),UPT=(R3),ECT=(R4),ECB=(R5),                 X56200020
               OUTPUT=((R6),MULTLVL),ENTRY=(15),MF=(E,(1)) PUTLINE      56250020
         LM    R0,R9,LOCSAVOF(R13) RESTORE LOCAL REGISTERS              56300020
         BR    R8                  RETURN                               56350020
         EJECT                                                          56400020
*                                                                       56450020
*  CONSTANTS AND LIST FORMS OF MACROS                                   56500020
*                                                                       56600020
TPUTMDL  PUTLINE MF=L              LIST FORM OF PUTLINE                 56700020
ENDTPUT  EQU   *                   END OF PUTLINE EXPANSION             56750020
LTPUTL   EQU   ENDTPUT-TPUTMDL     LENGTH OF PUTLINE EXPANSION          56800020
OLFS     EQU   *                   BEGINNING OF LIST FORMS FOR OBTWAD   56850020
RDJMDL   RDJFCB  (,(INPUT)),MF=L   LIST FORM READ JFCB                  56900020
         SPACE                                                          56950020
CLSTMDL  CAMLST  SEARCH,1,2,3      OBTAIN CAMLST                        57000020
         SPACE                                                          57050020
DCBMDL   DCB   DSORG=PS,MACRF=R,RECFM=F,BLKSIZE=256,KEYLEN=8,LRECL=256,C57100020
               DDNAME=DUMMY        DCB                                  57150020
         SPACE                                                          57200020
OPENMDL  OPEN  (,),MF=L            LIST FORM OF OPEN                    57250020
         SPACE                                                          57300020
READMDL  READ  RMDECB,SF,,,'S',,,MF=L LIST FORM OF READ                 57350020
         SPACE                                                          57400020
CLOSEMDL CLOSE (,),MF=L            MODEL FOR THE LIST FORM OF CLOSE     57450020
LOLFS    EQU   *-OLFS              LENGTH OF AREA TO MOVE               57550020
         SPACE                                                          57600020
ILFS     EQU   *                   BEGINNING OF LIST FORMS FOR INITCORE 57700020
GETMLMDL GETMAIN  EC,MF=L          LIST FORM OF GETMAIN                 57750020
FREEMMDL FREEMAIN  E,MF=L          LIST FORM OF FREEMAIN                57850020
LILFS    EQU   *-ILFS              LENGTH OF LIST FORMS FOR INITCORE    58000020
         SPACE                                                          58050020
PRSEC01  DC    V(IKJEHPRM)         ADDRESS OF PARSE CONTROL CSECT       58450020
MSGCSECT DC    V(IKJEHALM)         ADDRESS OF MESSAGE CSECT             58500020
VCONHIST DC    V(IKJEHHST)         ADDRESS OF HISTORY CSECT             58550020
VCONSTAT DC    V(IKJEHSTS)         ADDRESS OF STATUS CSECT              58600020
VCONMEM  DC    V(IKJEHMMR)         ADDRESS OF MEMBER CSECT              58650020
CAM1     CAMLST NAME,1,,3          LOCATE CAMLST                  M0875 58660021
ZERO     DC    F'0'                USED FOR SETTING ZEROS               58700020
MOVE     MVC   D0(L1,R7),D0(R3)    USED FOR EXECUTE MOVES               58800020
BLANKS   DC    C'        '         BLANKS FOR COMPARISON                58850020
SYSNMMDL DC    C'SYS00000.T000000.' TEST FOR SYSNAMES MASK              58900020
NHISTORY DC    C'HISTORY'          HISTORY INSERT                       58902020
NMEMBERS DC    C'MEMBERS'          MEMBERS INSERT                       58904020
NSYSNAME DC    C'SYSNAMES'         SYSNAMES INSERT                      58906020
NULLFILE DC    C'NULLFILE'         NULLFILE                             58910020
DYNAMMSG DC    C'DATA SETS CAN BE ALLOCATED DYNAMICALLY' MESSAGE        58920020
NODSE    DC    C'NO MORE DATA SETS CAN BE ALLOCATED DYNAMICALLY -USE FR*58930020
               EE COMMAND'         MESSAGE                              58940020
TERMFILE DC    C'TERMFILE'         TERMINAL FILE                        58942020
TITLE1   DC    C'--DSORG--CREATED---EXPIRES---SECURITY'  HEADING        58944020
TITLE2   DC    C'--DDNAME---DISP--' HEADING                             58946020
         EJECT                                                          58950020
IKJEHPRM IKJPARM                                                        59000020
PSTAT    IKJKEYWD                                                       59050020
         IKJNAME  'STATUS'                                              59100020
PHIST    IKJKEYWD                                                       59150020
         IKJNAME  'HISTORY'                                             59200020
PMEM     IKJKEYWD                                                       59250020
         IKJNAME  'MEMBERS'                                             59300020
PSYSN    IKJKEYWD                                                       59350020
         IKJNAME  'SYSNAMES'                                            59400020
         IKJENDP                                                        59450020
         EJECT                                                          59550020
IKJEHHST CSECT                                                          59650020
*********************************************************************** 59700020
*                                                                     * 59750020
*    THIS ROUTINE GETS CONTROL IF HISTORY WAS REQUESTED AND           * 59800020
*    FORMATS THE REQUIRED INFORMATION INTO THE OUTPUT BUFFER.         * 59850020
*    THE INFORMATION IS OBTAINED FROM THE DSCB WHICH IS ALREADY       * 59900020
*    AVAILABLE IN CORE AT THIS POINT. THE INFORMATION IS              * 59950020
*    REFERENCED THROUGH DSECT OBTWAD. THE FOLLOWING INFORMATION       * 60000020
*    IS COLLECTED-                                                    * 60050020
*                                                                     * 60100020
*                   1. CREATION DATE                                  * 60150020
*                   2. EXPIRATION DATE                                * 60200020
*                   3. SECURITY (PASSWORD) INFORMATION                * 60250020
*                   4. DSORG                                          * 60300020
*                                                                     * 60350020
*********************************************************************** 60400020
HISTROUT SAVE  (14,12),,*          SAVE REGISTERS                       60450020
         LR    R11,R15             ENTRY POINT ADDRESS                  60500020
         LR    R10,R13             WORKAREA ADDRESS                     60550020
         DROP  R13                 CHANGE BASE FOR INITCORE      A42338 60560021
         USING INITCORE,R10        ADDRESSABILITY FOR WORK AREA         60600020
         USING OBTWAD,R12          ADDRESSABILITY FOR OBTAIN WORK AREA  60650020
         USING HISTROUT,R11        ADDRESSABILITY FOR THIS ROUTINE      60700020
         GETMAIN R,LV=SAVELEN,SP=SSP GET NEW SAVE AREA                  60750020
         ST    R13,D4(R1)          CHAIN SAVE AREAS BACKWARDS           60800020
         ST    R1,D8(R13)          -AND FORWARDS                        60850020
         LR    R13,R1              NEW SAVEAREA                         60900020
         OI    CNTRL,WRITEMSK      TURN ON WRITE SWITCH                 61000020
         TM    DS1DSORG,PS         IS DSORG PS                          61100020
         BO    SETPS               IF YES, BRANCH                       61150020
         TM    DS1DSORG,PO         IS DSORG PO                          61250020
         BO    SETPO               IF YES, BRANCH                       61300020
         TM    DS1DSORG,IS         IS DSORG IS                          61400020
         BO    SETIS               IF YES, BRANCH                       61450020
         TM    DS1DSORG,DA         IS DSORG DA                          61550020
         BO    SETDA               IF YES, BRANCH                       61600020
         TM    DS1DSORG,NOTID      IS AN UNIDENTIFIED BIT SET           61700020
         BZ    SETND               IF NO, BRANCH                        61750020
         LA    R15,UNKL            LENGTH OF DSORG FIELD                61850020
         LA    R14,UNK             DSORG WAS NOT IDENTIFIABLE           61900020
EXDSORGM LA    R5,OUTBUF+DSORGOFF  POINT AT DSORG FIELD                 62000020
         BCTR  R15,R0              DECREMENT FOR EXECUTE                62050020
         EX    R15,DSORGMV         MOVE DSORG TO BUFFER                 62100020
         LA    R5,D1(R5,R15)       POINT BEYOND DSORG IN BUFFER         62150020
         TM    DS1DSORG,UNMV       CHECK DSCB FOR UNMOVABLE ATTRIBUTE   62200020
         BZ    DSORGEXT            EXIT FROM DSORG PROCESSING           62250020
         MVI   D0(R5),CHARU        SET UNMOVABLE ATTRIBUTE              62300020
         B     DSORGEXT            GO TO DSORG OPTION PROCESSING        62350020
SETPS    LA    R15,SEQL            LENGTH OF DSORG FIELD                62450020
         LA    R14,SEQ             DSORG WAS SEQUENTIAL                 62500020
         B     EXDSORGM            PROCESS THE DSORG FIELD              62550020
SETPO    LA    R15,PDSL            LENGTH OF DSORG FIELD                62650020
         LA    R14,PDS             DSORG WAS PARTITIONED                62700020
         B     EXDSORGM            PROCESS THE DSORG FIELD              62750020
SETIS    LA    R15,ISEQL           LENGTH OF DSORG FIELD                62850020
         LA    R14,ISEQ            DSORG WAS INDEXED SEQUENTIAL         62900020
         B     EXDSORGM            PROCESS THE DSORG FIELD              62950020
SETDA    LA    R15,DAL             LENGTH OF DSORG FIELD                63050020
         LA    R14,DIRECT          DSORG WAS DIRECT (BDAM)              63100020
         B     EXDSORGM            PROCESS THE DSORG FIELD              63150020
SETND    LA    R15,UNDEFL          LENGTH OF DSORG FIELD                63250020
         LA    R14,UNDEF           DSORG WAS NOT DEFINED                63300020
         B     EXDSORGM            PROCESS THE DSORG FIELD              63350020
DSORGEXT LA    R2,DS1CREDT         SET UP TO CONVERT CREATION DATE      63450020
         LA    R7,OUTBUF           ADDRESS OF OUTPUT BUFFER             63500020
         LA    R7,CRDTOFF(R7)      POINT AT BUFFER POSITION             63550020
         BAL   R14,HDT02           GO CONVERT DATE AND PUT IN BUFFER    63600020
         LA    R2,DS1EXPDT         SET UP TO CONVERT EXPIRATION DATE    63650020
         LA    R7,NXTBUF(R7)       POINT AT NEXT BUFFER POSITION        63700020
         BAL   R14,HDT02           GO CONVERT DATE AND PUT IN BUFFER    63750020
         LA    R7,NXTBUF(R7)       POINT AT NEXT BUFFER POSITION        63800020
         TM    DS1DSIND,PWRD1      CHECK NOPWREAD PROTECTION     A48499 63850021
         BNO   WRITEPRT            CHECK FOR PASSWORD PROTECTION A48499 63900021
         MVC   D0(L'WRITEPRO,R7),WRITEPRO PUT NAME IN BUFFER     A48499 63950021
HISTEXIT LR    R1,R13              SAVE AREA ADDRESS FOR FREEMAIN       64050020
         L     R13,D4(R1)          CALLERS SAVEAREA                     64100020
         FREEMAIN R,LV=SAVELEN,A=(1),SP=SSP FREE SAVE AREA              64150020
         RETURN (14,12)            RETURN                               64200020
WRITEPRT TM    DS1DSIND,PWRD2      CHECK FOR PASSWORD PROTECTION A48499 64250021
         BNO   NONEPROT            IF NOT, INDICATE NONE                64300020
         MVC   D0(L'PROTECTD,R7),PROTECTD PUT NAME IN BUFFER     A48499 64350021
         B     HISTEXIT            GO TO HISTORY EXIT                   64400020
NONEPROT MVC   D0(L'NOPROTEC,R7),NOPROTEC PUT NAME IN BUFFER            64500020
         B     HISTEXIT            GO TO HISTORY EXIT                   64550020
*********************************************************************** 64600020
*                                                                     * 64650020
*    THIS ROUTINE CONVERTS BINARY DATES OF THE FORM YYDDDD TO         * 64700020
*    CHARACTER FORMAT IN THE FORM MM/DD/YY.  LEAP YEARS ARE HANDLED.  * 64750020
*    INPUT REQUIREMENTS ARE-                                          * 64800020
*         1.   R2 POINTS TO FIELD TO BE CONVERTED                     * 64850020
*         2.   R7 POINTS TO RECEIVING FIELD                           * 64900020
*         3.   R14 HAS RETURN ADDRESS                                 * 64950020
*                                                                     * 65000020
*********************************************************************** 65010020
HDT02    CLC   D0(L3,R2),HDTZ      CHECK FOR UNSPECIFIED DATE           65100020
         BNE   HDT04               BRANCH IF DATE PRESENT               65150020
HDT03    MVC   D0(L'HDTDF,R7),HDTDF MOVE IN DEFAULT OF 00/00/00         65200020
         BR    R14                 RETURN                               65250020
HDT04    STM   R14,R6,HDTSV        SAVE REGISTERS                       65300020
*                                                                       65350020
*  TEST FOR LEAP YEAR BY ANDING THE YEAR FIELD AGAINST A BYTE WITH      65400020
*  THE TWO LOW ORDER BITS ON. LEAP YEARS WILL HAVE ZEROS FOR THE TWO    65450020
*  LOW ORDER BYTES.                                                     65500020
*                                                                       65550020
         SR    R3,R3               CLEAR REGISTER                       65600020
         IC    R3,D0(R2)           GET YEAR BYTE FROM DATE FIELD        65650020
         LA    R4,HDTBIN3          SET UP TO TEST LOW ORDER BITS        65700020
         NR    R3,R4               ZERO, IF YEAR IS DIVISIBLE BY 4      65750020
         LA    R4,HDTNY            SET UP FOR NON-LEAP YEAR             65800020
         BNZ   HDT06               NOT ZERO, NOT LEAP YEAR              65850020
         LA    R4,HDTLY            REMAINDER IS ZERO, USE LEAP YEAR     65900020
HDT06    MVC   HDTWK(L2),D1(R2)    MOVE DAY FIELD TO HALFWORD FOR ALIGN 65950020
         LH    R3,HDTWK            DAY OF YEAR (0-365)                  66000020
         LA    R6,MNTHS            BRANCH CONTROL IS NUMBER OF MONTHS   66050020
*                                                                       66100020
*  SEARCH NOW BEGINS TO FIND THE MONTH IN WHICH THE DAY-OF-THE-YEAR     66150020
*  OCCURS. IF DAY-OF-THE-YEAR IS GREATER THAN 365/366, MONTH 12 IS USED 66200020
*                                                                       66250020
HDT08    CH    R3,D0(R4)           COMPARE DAY TO TABLE ENTRY FOR MONTH 66300020
         BH    HDT10               DAY GREATER THAN TABLE IS A FIND     66350020
         LA    R4,D2(R4)           POINT TO NEXT ELEMENT                66400020
         BCT   R6,HDT08            DECREMENT MONTH AND RETRY            66450020
         B     HDT03               USE DEFAULT 00/00/00                 66500020
HDT10    SH    R3,D0(R4)           SUBTRACT TABLE ELEMENT FROM DAY      66550020
         EX    R3,HDTCLI           COMPARE DAY TO 31                    66600020
         BNL   HDT12               OKAY, GO TO MONTHS                   66650020
         LA    R3,DYS31            DEFAULT TO 31 DAYS                   66700020
HDT12    CVD   R6,HDTWK            CONVERT MONTH TO DECIMAL             66750020
         UNPK  D0(L2,R7),HD6(D2)   -THEN TO CHARACTER                   66800020
         CVD   R3,HDTWK            CONVERT DAY TO DECIMAL               66850020
         UNPK  D3(L2,R7),HD6(D2)   -THEN TO CHARACTER                   66900020
         IC    R6,D0(R2)           GET YEAR                             66950020
         CVD   R6,HDTWK            CONVERT IT TO DECIMAL                67000020
         UNPK  D6(L2,R7),HD6(D2)   -THEN TO CHARACTER                   67050020
         MVZ   D1(L7,R7),D0(R7)    PROPAGATE NUMERIC ZONE               67100020
         MVI   D2(R7),SLASH        MOVE IN SEPARATORS BETWEEN           67150020
         MVI   D5(R7),SLASH        -MONTH, DAY, AND YEAR                67200020
         LM    R14,R6,HDTSV        RESTORE REGISTERS                    67250020
         BR    R14                 RETURN                               67300020
*                                                                       67400020
*  THE FOLLOWING EQUATES AND CONSTANTS ARE USED BY THE HISTORY ROUTINE. 67450020
*                                                                       67500020
DSORGOFF EQU   2                   OFFSET TO DSORG FIELD IN OUTPUT      67550020
PS       EQU   X'40'               SEQUENTIAL                           67600020
PO       EQU   X'02'               PARTITIONED                          67650020
IS       EQU   X'80'               INDEXED SEQUENTIAL                   67700020
DA       EQU   X'20'               DIRECT                               67750020
NOTID    EQU   X'1C'               THESE BITS RESERVED IN DSORG         67800020
UNMV     EQU   X'01'               UNMOVEABLE BIT                       67850020
DYS31    EQU   31                  USED FOR THIRTY ONE COMPARE          67860020
PWRD1    EQU   X'14'               MASK FOR PASSWORD PROTECTION (DSCB)  67870020
PWRD2    EQU   X'10'               MASK FOR WRITE PROTECTION            67880020
HDTBIN3  EQU   X'03'               BYTE WITH TWO LOW ORDER BITS ON      67890020
DSORGMV  MVC   D0(L0,R5),D0(R14)   USED WITH EXECUTE TO MOVE DSORG      67900020
HDTCLI   CLI   HDTC31,D0           CHECKS IF DATE GREATER THAN 31       67910020
SEQ      DC    C'PS'               PHYSICAL SEQUENTIAL                  67950020
SEQL     EQU   L'SEQ               LENGTH OF CONSTANT SEQ               68000020
PDS      DC    C'PO'               PARTITIONED DATA SET                 68050020
PDSL     EQU   L'PDS               LENGTH OF CONSTANT PDS               68100020
ISEQ     DC    C'IS'               INDEXED SEQUENTIAL                   68150020
ISEQL    EQU   L'ISEQ              LENGTH OF CONSTANT ISEQ              68200020
DIRECT   DC    C'DA'               DIRECT ACCESS                        68250020
DAL      EQU   L'DIRECT            LENGTH OF CONSTANT DIRECT            68300020
UNDEF    DC    C'**'               DSORG NOT SPECIFIED                  68350020
UNDEFL   EQU   L'UNDEF             LENGTH OF CONSTANT UNDEF             68400020
UNK      DC    C'??'               DSORG NOT RECOGNIZED                 68450020
UNKL     EQU   L'UNK               LENGTH OF CONSTANT UNK               68500020
PROTECTD DC    C'PROTECTED'        PROTECT SECURITY ON DATA SET         68800020
WRITEPRO DC    C'WRITE'            WRITE PROTECTION (NOPWREAD)   A48499 68850021
NOPROTEC DC    C'NONE'             NO SECURITY STATUS                   68900020
HDTZ     DC    X'000000'           DATE IS NOT SPECIFIED                69250020
HDTDF    DC    C'00/00/00'         DISPLAYED DATE OF ZERO               69300020
HDTC31   DC    FL1'31'             USED FOR 31 DAY COMPARISON           69350020
*  THIS IS THE MONTH TABLE LOOKUP INDEX FOR NON LEAP-YEARS              69450020
HDTNY    DC    H'334'              DECEMBER                             69600020
         DC    H'304'              NOVEMBER                             69650020
         DC    H'273'              OCTOBER                              69700020
         DC    H'243'              SEPTEMBER                            69750020
         DC    H'212'              AUGUST                               69800020
         DC    H'181'              JULY                                 69850020
         DC    H'151'              JUNE                                 69900020
         DC    H'120'              MAY                                  69950020
         DC    H'90'               APRIL                                70000020
         DC    H'59'               MARCH                                70050020
         DC    H'31'               FEBRUARY                             70100020
         DC    H'0'                JANUARY                              70150020
*  THIS IS THE MONTH TABLE LOOKUP INDEX FOR LEAP YEARS                  70250020
HDTLY    DC    H'335'              DECEMBER                             70350020
         DC    H'305'              NOVEMBER                             70400020
         DC    H'274'              OCTOBER                              70450020
         DC    H'244'              SEPTEMBER                            70500020
         DC    H'213'              AUGUST                               70550020
         DC    H'182'              JULY                                 70600020
         DC    H'152'              JUNE                                 70650020
         DC    H'121'              MAY                                  70700020
         DC    H'91'               APRIL                                70750020
         DC    H'60'               MARCH                                70800020
         DC    H'31'               FEBRUARY                             70850020
         DC    H'0'                JANUARY                              70900020
         EJECT                                                          71150020
IKJEHMMR CSECT                                                          71250020
*********************************************************************** 71300020
*                                                                     * 71350020
*    THIS ROUTINE GETS CONTROL IF THE MEMBERS KEYWORD IS SPECIFIED    * 71400020
*    WITH THE COMMAND AND DOES THE FOLLOWING-                         * 71450020
*         1. CHECKS WHETHER DATA SET IS PARTITIONED (DSORG IN DSCB)   * 71550020
*         2. CHECKS WHETHER DATA SET HAS THIS USERS USERID AS FIRST   * 71600020
*            QUALIFIER IN DSNAME                                      * 71650020
*         3. CHECKS FOR BLANK DDNAME (EXIT IF YES--CONCATENATED)      * 71700020
*         4. CHECKS DYNAMIC CONCATENATION BIT IN DSE--IF ON, THE      * 71750020
*            DSEDDNAM IS COMPARED TO THE DCBDDNAM. IF THEY ARE THE    * 71800020
*            SAME, THEN THIS IS AT LEAST THE SECOND MEMBER OF A       * 71850020
*            CONCATENATION CLUSTER AND AN EXIT IS TAKEN.              * 71900020
*                                                                     * 71950020
*    IF ALL CONDITIONS ARE MET, A RDJFCB IS ISSUED AND IKJEHMEM IS    * 72000020
*    CALLED TO LIST THE DIRECTORY. IF HISTORY WAS SPECIFIED AS A      * 72050020
*    KEYWORD, THE JFCB HAS ALREADY BEEN READ.                         * 72100020
*                                                                     * 72150020
*********************************************************************** 72200020
MEMROUT  SAVE  (14,12),,*          SAVE REGISTERS                       72250020
         LR    R11,R15             ENTRY POINT ADDRESS                  72300020
         LR    R10,R13             WORKAREA ADDRESS                     72350020
         USING INITCORE,R10        ADDRESSABILITY FOR WORKAREA          72400020
         USING OBTWAD,R12          ADDRESSABILITY FOR OBTAIN WORK AREA  72450020
         USING MEMROUT,R11         ADDRESSABILITY FOR ROUTINE           72500020
         GETMAIN R,LV=SAVELEN,SP=SSP GET NEW SAVE AREA                  72550020
         ST    R13,BACKWARD(R1)    CHAIN SAVE AREAS BACKWARD            72600020
         ST    R1,FORWARD(R13)     -AND FORWARD                         72650020
         LR    R13,R1              NEW SAVE AREA                        72700020
         TM    DS1DSORG,PO         IS DSORG PO                          72750020
         BNO   MEMEXIT             NO, EXIT FROM ROUTINE                72800020
*  COMPARE USERID AGAINST HIGHEST LEVEL QUALIFIER                       72900020
         L     R2,PSCBPTR          POINT TO PSCB                        73000020
         USING PSCB,R2             ADDRESSABILITY PSCB                  73050020
         XR    R1,R1               CLEAR REGISTER                       73100020
         IC    R1,PSCBUSRL         LENGTH OF USERID                     73150020
         LA    R3,DSEDSNAM         ADDRESS OF DSNAME IN DSE             73200020
         LA    R3,D0(R3,R1)        ADD USERID LENGTH TO DSNAME          73250020
         CLI   D0(R3),PERIOD       CHECK FOR A PERIOD                   73300020
         BNE   MEMEXIT             NOT EQUAL, GO EXIT THIS ROUTINE      73350020
         BCTR  R1,R0               DECREMENT LENGTH FOR EXECUTE         73400020
         EX    R1,USRIDCOM         COMPARE USERID TO FIRST QUALIFIER    73450020
         BNE   MEMEXIT             NOT EQUAL, GO EXIT THIS ROUTINE      73500020
         CLI   DSEDDNAM,BLANK      IS DDNAME BLANK                      73550020
         BE    MEMEXIT             YES, GO EXIT                         73600020
         LA    R2,OBTDCB           ADDRESS OF DCB                A42338 73610021
         USING IHADCB,R2           ADDRESSABILITY DCB            A42338 73620021
         TM    DSECNTRL,DSECCNCT   CHECK DYNAMIC CONCATENATION BIT      73650020
         BNO   MEMRT01             OFF, GO PROCESS                      73700020
         CLC   DCBDDNAM(DDNAMLEN),DSEDDNAM COMPARE DDNAMES IN DSE, DCB  73850020
         BE    MEMEXIT             EQUAL, GO EXIT--CANNOT LIST MEMBERS  73900020
MEMRT01  TM    CNTRL,HISTMSK       WAS HISTORY SPECIFIED                74050020
         BO    MEMRT02             YES, SKIP RDJFCB                     74100020
         MVC   DCBDDNAM(DDNAMLEN),DSEDDNAM MOVE DDNAME TO DCB           74250020
         LA    R1,RDJL             ADDRESS OF RDJFCB LIST FORM          74300020
         RDJFCB ((R2)),MF=(E,(R1)) ISSUE READ JFCB                      74350020
         DROP  R2                  DCB NO LONGER NEEDED                 74400020
MEMRT02  L     R15,MEMMOD          ADDRESS OF IKJEHMEM (MEMBERS MODULE) 74500020
         LA    R1,CALLIST          PARAMETER LIST FOR CALL MACRO        74550020
         L     R3,VCONWRTE         ADDRESS OF WRITE ROUTINE             74600020
*  GO TO MEMBERS ROUTINE (IKJEHMEM)                                     74650020
         CALL  (15),((R12),GETML,OUTBUF,(R3),FREEML),VL,MF=(E,(1))      74700020
         B     MEMCODE(R15)        ANALYZE IKJEHMEM RETURN CODE         74800020
MEMCODE  B     MEMEXIT             SUCCESS                              74850020
         B     MEMCDE04            INSUFFICIENT CORE                    74900020
         B     MEMCDE08            I/O ERROR                            74950020
         B     MEMCDE12            DIRECTORY ERROR                      75000020
MEMCDE04 LA    R1,SECMSG06         SECOND LEVEL MESSAGE 6               75150020
         B     MEMERROR            GO PROCESS MESSAGE                   75200020
MEMCDE08 LA    R1,SECMSG08         SECOND LEVEL MESSAGE 8               75300020
         LA    R2,SYNMSG           ADDRESS OF INSERT                    75350020
         ST    R2,ERRINST2         -TO PARM LIST                        75400020
         B     MEMSYN              GO PROCESS MESSAGE                   75450020
MEMCDE12 LA    R1,SECMSG07         SECOND LEVEL MESSAGE 7               75550020
MEMERROR XC    ERRINST2,ERRINST2   NO SECOND LEVEL INSERTION            75700020
MEMSYN   XC    ERRINST1,ERRINST1   NO FIRST LEVEL INSERTION             75750020
         STH   R1,ERRSECND         SECOND LEVEL MESSAGE CODE            75800020
         LA    R1,MSG04            MESSAGE 4                            75850020
         STH   R1,ERRFIRST         FIRST LEVEL MESSAGE CODE             75900020
         LR    R1,R13              ADDRESS OF AREA TO FREE              75950020
         LR    R13,R10             CALLERS SAVEAREA                     76000020
         L     R2,VCONERRT         ERROUT ADDRESS                       76050020
         L     R3,RETREGOF(R13)    CALLERS RETURN ADDRESS               76100020
         ST    R2,RETREGOF(R13)    MAKE RETURN TO ERROR HANDLER         76150020
         ST    R3,BALREGOF(R13)    FROM ERROR HANDLER TO CALLER         76200020
         B     MEMEXIT1            GO FREE CORE AND RETURN       A42338 76250021
MEMEXIT  LR    R1,R13              SAVE AREA ADDRESS TO BE FREED        76450020
         LR    R13,R10             CALLERS SAVEAREA                     76500020
MEMEXIT1 FREEMAIN R,LV=SAVELEN,A=(1),SP=SSP FREE SAVE AREA       A42338 76550021
         RETURN (14,12)            RETURN                               76600020
*                                                                       76610020
*  CONSTANTS USED BY THE MEMBERS ROUTINE                         A42338 76620021
*                                                                       76630020
         USING PSCB,R2             ADDRESSABILITY PSCB                  76650020
USRIDCOM CLC   PSCBUSER(L1),DSEDSNAM COMPARE TO BE EXECUTED             76700020
         DROP  R2                  PSCB NO LONGER NEEDED                76750020
VCONERRT DC    V(IKJEHERR)         ADDRESS OF ERROR ROUTINE             76800020
VCONWRTE DC    V(IKJEHWRT)         ADDRESS OF WRITE ROUTINE             76850020
         EJECT                                                          76950020
IKJEHSTS CSECT                                                          77050020
*********************************************************************** 77100020
*                                                                     * 77150020
*    THIS ROUTINE GETS CONTROL IF THE STATUS KEYWORD IS SPECIFIED ON  * 77200020
*    THE COMMAND. IT EXTRACTS THE DDNAME AND NORMAL AND ABNORMAL      * 77250020
*    DISPOSITION FROM THE DSE BLOCK CURRENTLY BEING PROCESSD. THE     * 77300020
*    DDNAME MAY BE BLANKS IF THE DATA SET WAS CONCATENATED IN THE     * 77350020
*    LOGON PROCEDURE.  SOME DDNAMES MAY BE DUPLICATED IN THE LISTING. * 77400020
*    THESE DATA SETS WILL ALL BE MEMBERS OF THE SAME CONCATENATION    * 77450020
*    CLUSTER (DYNAMIC CONCATENATION).  THE POSSIBLE DISPOSITIONS      * 77500020
*    INCLUDE ALL THOSE CURRENTLY SUPPORTED IN OS.                     * 77550020
*                                                                     * 77600020
*********************************************************************** 77650020
STATROUT SAVE  (14,12),,*          SAVE REGISTERS                       77700020
         LR    R11,R15             ENTRY POINT ADDRESS                  77750020
         LR    R10,R13             WORKAREA ADDRESS                     77800020
         USING INITCORE,R10        ADDRESSABILITY WORK AREA             77850020
         USING OBTWAD,R12          ADDRESSABILITY OBTAIN WORK AREA      77900020
         USING STATROUT,R11        ADDRESSABILITY FOR THIS ROUTINE      77950020
         GETMAIN R,LV=SAVELEN,SP=SSP GET SAVE AREA                      78000020
         ST    R13,BACKWARD(R1)    CHAIN SAVE AREAS BACKWARD            78050020
         ST    R1,FORWARD(R13)     -AND FORWARD                         78100020
         LR    R13,R1              NEW SAVE AREA                        78150020
         LA    R7,OUTBUF+STATOFF1  POINT AT OFFSET FOR STATUS ALONE     78200020
         TM    CNTRL,HISTMSK       WAS HISTORY SPECIFIED                78250020
         BNO   STATRT01            NO, USE AS IS                        78300020
         LA    R7,OUTBUF+STATOFF2  YES, POINT TO NEW OFFSET             78350020
STATRT01 MVC   D0(DDNAMLEN,R7),DSEDDNAM MOVE DDNAME TO BUFFER           78450020
         LA    R7,DDNAMLEN+D1(R7)  UPDATE BUFFER POINTER        SA49892 78500021
* TEST STATUS BITS AND MOVE IN APPROPRIATE WORD                         78550020
         TM    DSENDISP,KEEP       IS DISPOSITION KEEP                  78650020
         BO    STATKEEP            YES, BRANCH                          78700020
         TM    DSENDISP,DELETE     IS DISPOSITION DELETE                78750020
         BO    STATDELE            YES, BRANCH                          78800020
         TM    DSENDISP,CATLG      IS DISPOSITION CATALOG               78850020
         BO    STATCATL            YES, BRANCH                          78900020
         TM    DSENDISP,UNCATLG    IS DISPOSITION UNCATALOG             78950020
         BO    STATUNCT            YES, BRANCH                          79000020
         B     STATRT03            IF UNSPECIFIED, SKIP TO NEXT         79050020
STATKEEP LA    R14,SKEEP           DISPOSITION OF 'KEEP'                79100020
         LA    R15,L'SKEEP         ITS LENGTH                           79150020
         B     STATRT02            PUT IT IN BUFFER                     79200020
STATDELE LA    R14,SDELE           DISPOSITION OF 'DELETE'              79300020
         LA    R15,L'SDELE         ITS LENGTH                           79350020
         B     STATRT02            PUT IT IN BUFFER                     79400020
STATCATL LA    R14,SCATL           DISPOSITION OF 'CATLG'               79500020
         LA    R15,L'SCATL         ITS LENGTH                           79550020
         B     STATRT02            PUT IT IN BUFFER                     79600020
STATUNCT LA    R14,SUNCT           DISPOSITION OF 'UNCATLG'             79700020
         LA    R15,L'SUNCT         ITS LENGTH                           79750020
* MOVE THE CORRECT FIELD TO THE BUFFER                                  79850020
STATRT02 BCTR  R15,R0              DECREMENT COUNT FOR EXECUTE  SA49892 80050021
         EX    R15,DISPMOVE        MOVE DISPOSITION TO BUFFER           80100020
         LA    R7,D1(R15,R7)       POINT AT NEXT LOCATION               80150020
* TEST FOR ABNORMAL DISPOSITION                                         80250020
STATRT03 TM    DSEADISP,KEEP       IS DISPOSITION KEEP                  80400020
         BO    STKEEP              YES, BRANCH                          80450020
         TM    DSEADISP,DELETE     IS DISPOSITION DELETE                80500020
         BO    STDELE              YES, BRANCH                          80550020
         TM    DSEADISP,CATLG      IS DISPOSITION CATALOG               80600020
         BO    STCATL              YES, BRANCH                          80650020
         TM    DSEADISP,UNCATLG    IS DISPOSITION UNCATALOG             80700020
         BO    STUNCT              YES, BRANCH                          80750020
         B     STATRT05            IF UNSPECIFIED, SKIP IT              80800020
STKEEP   LA    R14,SKEEP           DISPOSITION OF 'KEEP'                80900020
         LA    R15,L'SKEEP         ITS LENGTH                           80950020
         B     STATRT04            PUT IT INTO THE BUFFER               81000020
STDELE   LA    R14,SDELE           DISPOSITION OF 'DELETE'              81100020
         LA    R15,L'SDELE         ITS LENGTH                           81150020
         B     STATRT04            PUT IT INTO BUFFER                   81200020
STCATL   LA    R14,SCATL           DISPOSITION OF 'CATLG'               81300020
         LA    R15,L'SCATL         ITS LENGTH                           81350020
         B     STATRT04            PUT IT INTO BUFFER                   81400020
STUNCT   LA    R14,SUNCT           DISPOSITION OF 'UNCATLG'             81500020
         LA    R15,L'SUNCT         ITS LENGTH                           81550020
* MOVE THE CORRECT FIELD TO THE BUFFER                                  81650020
STATRT04 MVI   D0(R7),COMMA         PUT A COMMA SEPARATOR IN BUFFER     81800020
         LA    R7,D1(R7)            BUMP POINTER                        81850020
         BCTR  R15,R0               DECREMENT LENGTH FOR EXECUTE        81900020
         EX    R15,DISPMOVE         MOVE DISPOSITION TO BUFFER          81950020
STATRT05 OI    CNTRL,WRITEMSK       TURN ON WRITE SWITCH                82100020
         LR    R1,R13               ADDRESS OF SAVE AREA TO BE FREED    82150020
         LR    R13,R10              USERS SAVEAREA                      82200020
         FREEMAIN R,LV=SAVELEN,A=(1),SP=SSP FREE SAVE AREA              82250020
         RETURN (14,12)             RETURN                              82300020
*                                                                       82350020
*     EQUATES AND CONSTANTS USED BY THE STATUS ROUTINE                  82400020
*                                                                       82450020
DISPMOVE MVC   D0(D0,R7),D0(R14)    EXECUTED TO MOVE DISPOSITION        82460020
KEEP     EQU   X'08'                DSE DISPOSITION KEEP                82500020
DELETE   EQU   X'04'                DSE DISPOSITION DELETE              82550020
CATLG    EQU   X'02'                DSE DISPOSITION CATALOG             82600020
UNCATLG  EQU   X'01'                DSE DISPOSITION UNCATALOG           82650020
SKEEP    DC    C'KEEP'              KEEP                                82700020
SDELE    DC    C'DELETE'            DELETE                              82750020
SCATL    DC    C'CATLG'             CATALOG                             82800020
SUNCT    DC    C'UNCATLG'           UNCATALOG                           82850020
         EJECT                                                          83000020
INITCORE DSECT                                                          83050020
SAVEAREA DS    28F                  SAVEAREA AND LOCAL SAVEAREA         83100020
NULLCNT  DS    D                    KEEPS COUNT OF DYNAMS               83110020
DYNAMSAV DS    F                    POINTS TO FIRST DYNAM ENTRY FOUND   83120020
OBTAINRC DS    F                    HOLDS OBTAIN RETURN CODE            83130020
CTLA     EQU   *                    BEGIN CONTROL WORD AND SW AREA      83150020
MEMMOD   DS    A                    ADDRESS OF MEMBERS MODULE           83200020
OBTWA    DS    A                    ADDRESS OF CORE FOR OBTAIN WORKAREA 83250020
RETCD    DS    F                    HOLDS RETURN CODE                   83300020
PARDSECT DS    F                    ADDRESS OF PARSE DSECT              83400020
CNTRL    DS    XL1                  SWITCH FOR COMMAND SCAN RESULTS     83410020
CTLL     EQU   *-CTLA               LENGTH CONTROL WORD AND SWITCH AREA 83500020
DYNAMCNT DS    H                    HOLDS COUNT OF DYNAM ENTRIES        83660020
LOCSW    DC    X'00'                SWITCH USED FOR LOCATE ISSUED       83750020
         EJECT                                                          83800020
*********************************************************************** 83850020
*                                                                     * 83900020
*    THE  FOLLOWING 3 WORDS ARE USED TO PASS PARAMETERS TO THE        * 83950020
*    ERROR HANDLING ROUTINE. THE FIRST TWO BYTES CONTAIN THE RELATIVE * 84000020
*    POSITION OF THE MESSAGE IN THE MESSAGE CSECT. THE NEXT TWO BYTES * 84050020
*    CONTAIN THE NUMBER THAT INDICATES WHICH SECOND LEVEL MESSAGE     * 84100020
*    IS TO BE SELECTED. THE SECOND WORD POINTS TO A FIELD CONTAINING  * 84150020
*    A ONE BYTE LENGTH FIELD FOLLOWED BY DATA TO BE INSERTED IN THE   * 84200020
*    FIRST MESSAGE. THE LAST WORD CONTAINS A SIMILAR POINTER FOR THE  * 84250020
*    SECOND MESSAGE.                                                  * 84300020
*                                                                     * 84350020
*********************************************************************** 84400020
ERRPARM  DS    0F                  PARAMETER LIST FOR ERROR HANDLER     84450020
ERRFIRST DS    H                   RELATIVE FIRST LEVEL MESSAGE NUMBER  84500020
ERRSECND DS    H                   RELATIVE SECOND LEVEL MESSAGE NUMBER 84550020
ERRINST1 DS    F                   INSERT DATA FOR FIRST LEVEL MESSAGE  84600020
ERRINST2 DS    F                   INSERT DATA FOR SECOND LEVEL MESSAGE 84650020
         DS    0D                  DOUBLE WORD ALIGN                    84700020
ERRINSRT DS    CL70                INSERT DATA BUFFER                   84750020
*********************************************************************** 84900020
*                                                                     * 84950020
*        THE FOLLOWING CONSTANTS, BUFFER AND PUTLINE MACRO MUST ALL   * 85000020
*        APPEAR TOGETHER IN THE SPECIFIED ORDER SO THAT THE WRITE     * 85050020
*        ROUTINE WILL REMAIN INDEPENDANT OF A BASE REGISTER.          * 85100020
*                                                                     * 85150020
*********************************************************************** 85200020
PARMLSTS DS    0F                  ALIGN PARAMETER LIST                 85250020
PUTLCON  DS    F                   LIST FOR PUTLINE MACRO               85300020
DPUTLCON DS    F                   PUTLINE LIST FORM                    85350020
UPTPTR   DS    F                   UPT POINTER                          85400020
ECTPTR   DS    F                   ECT POINTER                          85450020
ECBPTR   DS    F                   CPS ECB POINTER                      85500020
PUTLADDR DS    F                   ENTRY POINT OF PUTLINE               85550020
PARMLSTL EQU   *-PARMLSTS          LENGTH OF PARAMETER LIST             85600020
         DS    F                   LENGTH AND OFFSET FIELDS             85700020
OUTBUF   DS    CL120               OUTPUT BUFFER FOR PUTLINE            85750020
DPUTLINE PUTLINE MF=L              PUTLINE LIST FORM                    85800020
*                                                                       85900020
* SERVICE ROUTINE PARAMETER LIST AREA                                   85950020
*                                                                       86000020
PUTLLIST DS    7F                  COMMON PARAMETER AREA                86200020
* END OF SERVICE ROUTINE PARAMETER LIST AREA                            86600020
CPECB    DS    F                   CPS ECB                              86650020
PSCBPTR  DS    F                   PSCB POINTER                         86700020
GETML    GETMAIN  EC,MF=L          LIST FORM OF GETMAIN                 86850020
FREEML   FREEMAIN  E,MF=L          LIST FORM OF FREEMAIN                86900020
LOCLIST  DS    4F                  LOCATE CAMLST                        87000020
MSGPARM1 DS    3F                  FIRST LEVEL MESSAGE PARAMETERS       87100020
MSGPARM2 DS    3F                  SECOND LEVEL MESSAGE PARAMETERS      87150020
SECBUFF  DS    30F                 SECOND BUFFER FOR ERROR HANDLER      87200020
STACKPRM DS    2F                  SPACE FOR STACK PARAMETER BLOCK      87250020
SYSNM    DS    C'SYS00000.T000000.' MASK TO TEST FOR SYSNAMES           87300020
STACKSW  DS    CL1                 INDICATE FLUSH STACK AND CLEAR QUEUE 87310020
         DS    0D                  ALIGN LOCATE WORKAREA          M0883 87310421
LOCAREA  DS    CL265               WORK AREA FOR LOCATE MACRO           87312020
INITSIZE EQU   *-SAVEAREA          LENGTH OF DSECT                      87400020
         EJECT                                                          87450020
         IKJEHCOM                                                       87500020
         DCBD  DSORG=PS                                                 87550020
         EJECT                                                          87600020
         CVT                                                            87650020
         EJECT                                                          87700020
         IKJTCB                                                         87750020
         EJECT                                                          87800020
         IEZJSCB                                                        87850020
         EJECT                                                          87900020
         IEECHAIN                                                       87950020
         EJECT                                                          88000020
         IKJTSCVT                                                       88050020
         EJECT                                                          88100020
         IKJTJB                                                         88150020
         SPACE 3                                                        88200020
         IKJTJBX                                                        88250020
         EJECT                                                          88300020
         IKJDSE                                                         88350020
         EJECT                                                          88400020
         IKJPSCB                                                        88450020
         EJECT                                                          88500020
         IKJCPPL                                                        88550020
         SPACE 2                                                        88600020
         IKJPPL                                                         88700020
         SPACE 2                                                        88710020
         IKJDAPL                                                        88750020
         EJECT                                                          88800020
IKJEHALM CSECT                                                          88850020
*********************************************************************** 88900020
*                                                                     * 88950020
*    THE CSECT BEGINS WITH A TABLE OF 8 BYTE ENTRIES, ONE FOR         * 90050020
*    EACH FIRST LEVEL MESSAGE.  THE FIRST HALFWORD OF EACH ENTRY      * 90100020
*    CONTAINS THE LENGTH OF A MESSAGE.  THE SECOND HALFWORD CONTAINS  * 90150020
*    THE OFFSET TO THE MESSAGE IN THE CSECT.  THE THIRD HALFWORD      * 90200020
*    CONTAINS THE OFFSET TO THE SEGMENT CHAIN IF MORE THAN ONE        * 90250020
*    MESSAGE SEGMENT EXISTS FOR A PARTICULAR MESSAGE.  THE FOURTH     * 90300020
*    AND LAST HALFWORD POINTS TO A TABLE DESCRIBING SECOND LEVEL      * 90350020
*    MESSAGES.  THE SEGMENT CHAIN ADDRESS IS CURRENTLY ALWAYS ZERO.   * 90400020
*                                                                     * 90450020
*    THE TABLE DESCRIBING SECOND LEVEL MESSAGES IS MADE UP OF         * 90600020
*    6 BYTE ENTRIES. A 2 BYTE LENGTH, A 2 BYTE MESSAGE OFFSET,        * 90650020
*    AND A 2 BYTE SEGMENT CHAIN OFFSET.                               * 90700020
*                                                                     * 90950020
*********************************************************************** 91000020
SEGCH0   EQU   0                   SEGMENT CHAIN OFFSET                 91010020
*                                                                       91020020
*        FIRST LEVEL MESSAGE TABLE                                      91030020
*                                                                       91040020
STARTALM DS    0F                  ALIGN FIRST LEVEL MESSAGE TABLE      91050020
         DC    AL2(L'MSGE1)        LENGTH OF MESSAGE                    91100020
         DC    AL2(MSGE1-STARTALM) OFFSET TO MESSAGE                    91150020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              91200020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      91250020
         DC    AL2(L'MSGE2)        LENGTH OF MESSAGE                    91300020
         DC    AL2(MSGE2-STARTALM) OFFSET TO MESSAGE                    91350020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              91400020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      91450020
         DC    AL2(L'MSGE3)        LENGTH OF MESSAGE                    91500020
         DC    AL2(MSGE3-STARTALM) OFFSET TO MESSAGE                    91550020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              91600020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      91650020
         DC    AL2(L'MSGE4)        LENGTH OF MESSAGE                    91700020
         DC    AL2(MSGE4-STARTALM) OFFSET TO MESSAGE                    91750020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              91800020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      91820020
         DC    AL2(L'MSGE5)        LENGTH OF MESSAGE                    91850020
         DC    AL2(MSGE5-STARTALM) OFFSET TO MESSAGE                    91900020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              91950020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      91970020
         DC    AL2(L'MSGE6)        LENGTH OF MESSAGE                    92000020
         DC    AL2(MSGE6-STARTALM) OFFSET TO MESSAGE                    92050020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              92100020
         DC    AL2(SECLEVEL-STARTALM) OFFSET TO SECOND LEVEL TABLE      92150020
*                                                                       92200020
*        FIRST LEVEL MESSAGES                                           92250020
*                                                                       92300020
*                                                                       92350020
MSGE1    DC    C'IKJ58300I HISTORY NOT AVAILABLE+'                      92400020
MSGE2    DC    C'IKJ58303I NOT ENOUGH MAIN STORAGE TO LIST '            92450020
MSGE3    DC    C'IKJ58302I NO DATA SETS ALLOCATED'                      92500020
MSGE4    DC    C'IKJ58301I MEMBERS NOT AVAILABLE+'                      92550020
MSGE5    DC    C'IKJ58304I COMMAND SYSTEM ERROR+'                       92600020
MSGE6    DC    C'IKJ58305I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  92650020
*                                                                       92700020
*        SECOND LEVEL MESSAGE TABLE                                     92750020
*                                                                       92800020
SECLEVEL DS    0F                  ALIGN SECOND LEVEL MESSAGE TABLE     92900020
         DC    AL2(L'MSGSEC01)     LENGTH OF MESSAGE                    92950020
         DC    AL2(MSGSEC01-STARTALM) OFFSET TO MESSAGE                 93000020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93050020
         DC    AL2(L'MSGSEC02)     LENGTH OF MESSAGE                    93100020
         DC    AL2(MSGSEC02-STARTALM) OFFSET TO MESSAGE                 93150020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93200020
         DC    AL2(L'MSGSEC03)     LENGTH OF MESSAGE                    93250020
         DC    AL2(MSGSEC03-STARTALM) OFFSET TO MESSAGE                 93300020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93350020
         DC    AL2(L'MSGSEC04)     LENGTH OF MESSAGE                    93400020
         DC    AL2(MSGSEC04-STARTALM) OFFSET TO MESSAGE                 93450020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93500020
         DC    AL2(L'MSGSEC05)     LENGTH OF MESSAGE                    93550020
         DC    AL2(MSGSEC05-STARTALM) OFFSET TO MESSAGE                 93600020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93650020
         DC    AL2(L'MSGSEC06)     LENGTH OF MESSAGE                    93700020
         DC    AL2(MSGSEC06-STARTALM) OFFSET TO MESSAGE                 93750020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93800020
         DC    AL2(L'MSGSEC07)     LENGTH OF MESSAGE                    93850020
         DC    AL2(MSGSEC07-STARTALM) OFFSET TO MESSAGE                 93900020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              93950020
         DC    AL2(L'MSGSEC08)     LENGTH OF MESSAGE                    94000020
         DC    AL2(MSGSEC08-STARTALM) OFFSET TO MESSAGE                 94050020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              94100020
         DC    AL2(L'MSGSEC09)     LENGTH OF MESSAGE                    94150020
         DC    AL2(MSGSEC09-STARTALM) OFFSET TO MESSAGE                 94200020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              94250020
         DC    AL2(L'MSGSEC10)     LENGTH OF MESSAGE                    94300020
         DC    AL2(MSGSEC10-STARTALM) OFFSET TO MESSAGE                 94350020
         DC    AL2(SEGCH0)         OFFSET TO SEGMENT CHAIN              94400020
*                                                                       94500020
*        SECOND LEVEL MESSAGES                                          94550020
*                                                                       94600020
MSGSEC01 DC    C'IKJ583XXI REQUIRED VOLUME NOT MOUNTED'                 94650020
MSGSEC02 DC    C'IKJ583XXI DATA SET NOT ON VOLUME'                      94700020
MSGSEC03 EQU   *                                                        94750020
MSGSEC04 DC    C'IKJ583XXI I/O ERROR DURING OBTAIN, CODE '              94800020
MSGSEC05 DC    C'IKJ583XXI LOCATE ERROR CODE '                          94850020
MSGSEC06 DC    C'IKJ583XXI NOT ENOUGH MAIN STORAGE'                     94900020
MSGSEC07 DC    C'IKJ583XXI DIRECTORY STRUCTURE ERROR'                   94950020
MSGSEC08 DC    C'IKJ583XXI I/O SYNAD ERROR DURING DIRECTORY SEARCH '    95000020
MSGSEC09 EQU   *                                                        95050020
MSGSEC10 DC    C'IKJ583XXI PARSE ERROR CODE '                           95100020
         END                                                            95200020
