CIR      TITLE 'IKJEHCIR--CATALOG INFORMATION ROUTINE USED IN TSO'      00200020
IKJEHCIR CSECT                                                          00400020
* A 680500-681500,818500-819000                                 SA52087 00402021
* A 866500                                                        M2136 00410021
* C 508000-512000                                                 M2136 00420021
* D 514000-522000                                                 M2136 00430021
*C 864000                                                         M0875 00450021
*              RELEASE 21.8 CHANGES                             SA66186 00500021
*C702000                                                        SA66186 00550021
*D704000-708000                                                 SA66186 00560021
*A608500                                                        SA66186 00570021
*********************************************************************** 00600020
* STATUS -- CHANGE LEVEL 02                                     SA66186 00800021
*                                                                     * 01000020
* FUNCTION --                                                         * 01200020
*                                                                     * 01400020
*    THIS MODULE IS DESIGNED TO PROVIDE AN INTERFACE BETWEEN          * 01600020
*    PROCESSING PROGRAMS AND THE SYSTEM CATALOG.  IT ABBREVIATES      * 01800020
*    INFORMATION FOUND IN THE CATALOG INDEX BLOCKS ACCORDING TO       * 02000020
*    OPTIONS SPECIFIED BY THE CALLER.  THE LIST OF INFORMATION        * 02200020
*    RETURNED TO THE CALLER AS A RESULT OF ONE CALL TO THIS           * 02400020
*    MODULE WILL INCLUDE ONLY WHAT IS FOUND IN ONE INDEX BLOCK.       * 02600020
*    MULTIPLE CALLS MAY THEREFORE BE REQUIRED IF ALL OF THE           * 02800020
*    INFORMATION AT A PARTICULAR LEVEL OF INDEX IS DESIRED.           * 03000020
*    THE INFORMATION OBTAINED BY THIS MOUDLE  IS GOTTEN BY ISSUE      * 03200020
*    OF THE LOCATE MACRO WITH EITHER THE BLOCK OR NAME OPTION.        * 03400020
*    THE SECOND WORD OF THE PARAMETER LIST INPUT TO THIS MODULE       * 03600020
*    INDICATES WHICH OPTION IS TO BE SELECTED AS DESCRIBED LATER.     * 03800020
*    THE WORK AREA PROVIDED BY THE CALLER IS USED TO HOLD THE         * 04000020
*    INDEX BLOCK READ AND ULTIMATELY THE INFORMATION LIST. EACH       * 04200020
*    ENTRY IN THE INDEX BLOCK IS EXAMINED AND REQUESTED               * 04400020
*    INFORMATION IS RIPPLED DOWN TO THE FORWARD PORTION OF THE        * 04600020
*    BLOCK.                                                           * 04800020
*                                                                     * 05000020
* ENTRY POINTS --                                                     * 05200020
*                                                                     * 05400020
*         MAIN- IKJEHCIR                                              * 05600020
*                                                                     * 05800020
* INPUT --                                                            * 06000020
*                                                                     * 06200020
*    THE FOLLOWING PARMETER LIST MUST BE SUPPLIED BY THE CALLING      * 06400020
*    PROGRAM FOR EACH ENTRY TO THIS MODULE.                           * 06600020
*                                                                     * 06800020
*                   *************************                         * 07000020
*               + 0 * OPTIONS*   UNUSED     *                         * 07200020
*                   *************************                         * 07400020
*               + 4 * A(INDEXNAME OR TTR)   *  IF TTR, HIGH ORDER BIT * 07600020
*                   *************************     SHOULD BE ON.       * 07800020
*               + 8 * A(VOLID OF CVOL)      *  DEFAULTS TO SYSRES IF  * 08000020
*                   *************************     NOT SPECIFIED.      * 08200020
*               + C * A(WORKAREA1)          *  265 BYTE AREA FOR      * 08400020
*                   *************************     LOCATE AND LIST     * 08600020
*               +10 * A(WORKAREA2)          *  72 BYTE AREA USED AS   * 08800020
*                   *************************     REG SAVEAREA        * 09000020
*                                                                     * 09200020
*    OPTIONS IS A 1 BYTE FIELD THAT COULD CONTAIN ANY COMBINATION     * 09400020
*    OF THE FOLLOWING BIT DEFINITIONS.                                * 09600020
*                                                                     * 09800020
*              X'01'-LOWEST LEVEL QUALIFIERS ARE REQUESTED            * 10000020
*              X'02'-INDEX NAMES ARE REQUESTED                        * 10200020
*              X'04'-VOLIDS ARE REQUESTED                             * 10400020
*              X'08'-ALL OTHER VALID ENTRIES ARE REQUESTED            * 10600020
*                                                                     * 10800020
* OUTPUT --                                                           * 11000020
*                                                                     * 11200020
*    LIST ENTRIES OF THE FORM SHOWN BELOW DEPENDING ON SELECTED       * 11400020
*    OPTION CODES.                                                    * 11600020
*                                                                     * 11800020
*           OPTION X'01' -   **************                           * 12000020
*                            *07* DSNAME  *                           * 12200020
*                            **************                           * 12400020
*                            / 2/   8     /                           * 12600020
*                                                                     * 12800020
*                            ************************                 * 13000020
*                            *02* GDGNAME *TTR* DATA*                 * 13200020
*                            ************************                 * 13400020
*                            / 2/   8     / 3 /  4  /                 * 13600020
*                                                                     * 13800020
*           OPTION X'02' -   *******************                      * 14000020
*                            *00* INDEXNAME*TTR*                      * 14200020
*                            *******************                      * 14400020
*                            / 2/    8     / 3 /                      * 14600020
*                                                                     * 14800020
*           OPTION X'04'     ***********************************      * 15000020
*                            *08* DSNAME *CT*CODE*VOLSER1*SEQ*        * 15200020
*                            ***********************************..... * 15400020
*                            / 2/    8   / 2/  4 /  6    / 2 /        * 15600020
*                                                                     * 15800020
*                             CT   -NUMBER OF VOLSERS DESCRIBED       * 16000020
*                             CODE -4 BYTE DEVICE CODE                * 16200020
*                             VOLSER- A VOLUME ID                     * 16400020
*                             SEQ  -SEQUENCE FIELD FOR TAPE DEVICE    * 16600020
*                                                                     * 16800020
*                            *****************                        * 17000020
*                            *01* DSNAME *TTR*                        * 17200020
*                            *****************                        * 17400020
*                            / 2/   8    / 3 /                        * 17600020
*                             TTR POINTS TO VOLUME CONTROL BLOCK      * 17800020
*                                                                     * 18000020
*           OPTION X'08'     *****************************            * 18200020
*                            *04* ALIASNAME*TTR* TRUENAME*            * 18400020
*                            *****************************            * 18600020
*                            / 2/   8      / 3 /    8    /            * 18800020
*                                                                     * 19000020
*                            **************************               * 19200020
*                            *05* DSNAME *CODE*CVOLSER*               * 19400020
*                            **************************               * 19600020
*                            / 2/   8    / 4  /   6   /               * 19800020
*                                                                     * 20000020
*    THE LAST ENTRY IN EVERY LIST WILL BE A LINK ENTRY AS SHOWN       * 20200020
*    BELOW. IT MARKS THE END OF THE LIST AND IF THE TTR IS NONZERO    * 20400020
*    IT POINTS TO THE NEXT INDEX BLOCK IN THE CURRENT STRUCTURE       * 20600020
*    AND THE VOLSER WILL INDICATE THE CVOL IT IS ON.                  * 20800020
*                                                                     * 21000020
*                            ***************                          * 21200020
*                            *FF*TTR*VOLSER*                          * 21400020
*                            ***************                          * 21600020
*                            / 2/ 3 /   6  /                          * 21800020
*                                                                     * 22000020
*                                                                     * 22200020
* EXTERNAL ROUTINES --                                                * 22400020
*                                                                     * 22600020
*        IKJEHCT1-FROM LISTCAT COMMAND                                * 22800020
*        VARIOUS SERVICE ROUTINES                                     * 23000020
*                                                                     * 23200020
* EXITS, NORMAL --                                                    * 23400020
*                                                                     * 23600020
*    BR 14 RETURN CODE IN REG 15 SET TO 00.                           * 23800020
*                                                                     * 24000020
* EXITS, ERROR                                                        * 24050020
*    BR 14 WITH A RETURN CODE IN REG 15 AS FOLLOWS                    * 24200020
*                                                                     * 24400020
*                        RC=04 LOCATE FAILED. THE LOCATE RETURN CODE  * 24600020
*                              IS STORED IN THE FIRST WORD OF THE     * 24800020
*                              USERS PARAMETER LIST                   * 25000020
*                                                                     * 25200020
*                        RC=08 ONLY VOLUMES WERE REQUESTED BUT THE    * 25400020
*                              DSNAME POINTED TO WAS NOT FULLY        * 25600020
*                              QUALIFIED OR IF A TTR WAS SPECIFIED,   * 25800020
*                              IT DID NOT POINT TO A VOLUME CONTROL   * 26000020
*                              BLOCK.                                 * 26200020
*                                                                     * 26400020
*                        RC=12 VOLUMES WERE RETURNED BY LOCATE BUT    * 26600020
*                              THIS WAS NOT COMPATIBLE WITH THE       * 26800020
*                              OPTIONS REQUESTED.                     * 27000020
*                                                                     * 27200020
* TABLES/WORKAREA --                                                  * 27400020
*                                                                     * 27600020
*    ONLY THOSE DESCRIBED IN THE INPUT PARM LIST                      * 27800020
*                                                                     * 28000020
* ATTRIBUTES --                                                       * 28200020
*        REENTRANT,READ ONLY,REFRESHABLE                              * 28400020
*                                                                     * 28600020
*********************************************************************** 28800020
*                                                                       29000020
R0       EQU   0                                                        29200020
R1       EQU   1              POINTS AT ENTRY IN WORK AREA.             29400020
R2       EQU   2              POINTS AT CURRENT ENTRY IN BLOCK          29600020
R3       EQU   3                                                        29800020
R4       EQU   4              CONTAINS PARAMETER LIST ADDRESS           30000020
R5       EQU   5                                                        30200020
R6       EQU   6                                                        30400020
R7       EQU   7                                                        30600020
R8       EQU   8                                                        30800020
R9       EQU   9                                                        31000020
R10      EQU   10                                                       31200020
R11      EQU   11             MAIN BASE REG                             31400020
R12      EQU   12                                                       31600020
R13      EQU   13             SAVEAREA                                  31800020
R14      EQU   14                                                       32000020
R15      EQU   15             WILL CONTAIN RETURN CODE                  32200020
D0       EQU   0              DISPLACEMENT OF ZERO                      32400020
L0       EQU   0              LENGTH OF ZERO                            32600020
L1       EQU   1              LENGTH OF ONE                             32800020
L4       EQU   4              LENGTH OF FOUR                            33000020
TWELVE   EQU   12             USED FOR OFFSET OF 12                     33200020
*                                                                       33400020
CIROPT   EQU   0              OFFSET TO OPTION BYTE IN PARM LIST        33600020
CIRSRCH  EQU   4              OFFSET TO WORD PTR TO TTR OR NAME         33800020
CIRCVOL  EQU   8              OFFSET TO VOLSER OF CVOL, OR ZERO         34000020
CIRWA    EQU   12             OFFSET TO WORK AREA FOR LIST              34200020
CIRSAVE  EQU   16             OFFSET TO WORK SAVE AREA PASSED           34400020
*                                                                       34600020
FORWARD  EQU   8              OFFSET TO FORWARD CHAIN SAVE AREAS        34800020
BACKWARD EQU   4              OFFSET TO BACKWARD CHAIN SAVE AREAS       35000020
HIGHBIT  EQU   X'80'          MASK FOR HIGH ORDER BIT OF A BYTE         35200020
HEXFF    EQU   X'FF'          MASK FOR ALL BITS ON                      35400020
FRSTNTRY EQU   2              OFFSET TO FIRST ENTRY IN A CATALOG BLOCK  35600020
CODEOFF  EQU   0              OFFSET TO CODE IN LIST ENTRY FOR OUTPUT   35800020
NAMEOFF  EQU   1              OFFSET TO NAME IN LIST ENTRY FOR OUTPUT   36000020
TTROFF   EQU   256            OFFSET TO TTR OF NEXT CATALOG BLOCK       36200020
VOLOFF   EQU   259            OFFSET TO VOLSER OF CVOL CATALOG IS ON    36400020
VOLSEROF EQU   4              OFFSET TO VOLSER IN LINK ENTRY IN LIST    36600020
GDGDATA  EQU   12             OFFSET TO GDGDATA FIELD IN LIST ENTRY     36800020
DEVCDEOF EQU   9              OFFSET TO DEVICE CODE FIELD IN LIST ENTRY 37000020
CVOLVOL  EQU   13             OFFSET TO VOLSER OF CVOL IN LIST ENTRY    37200020
*                                                                       37400020
NAMLEN   EQU   8              LENGTH OF SIMPLE NAME                     37600020
ONE      EQU   1              ONE MEANS 1--USED PRIMARILY IN SHIFTING   37800020
CATENTLN EQU   12             LENGTH OF BASIC CATALOG ENTRY             38000020
TTRLEN   EQU   3              LENGTH OF TTR                             38200020
VOLLEN   EQU   6              LENGTH OF VOLSER                          38400020
ALIASLEN EQU   12             LENGTH OF ALIAS ENTRY IN LIST             38600020
DSLEN    EQU   9              LENGTH OF BASIC PORTION OF LIST ENTRIES   38800020
INDLEN   EQU   12             LENGTH OF BASIC INDEX ENTRY (WITH TTR)    39000020
VCBLEN   EQU   12             LENGTH OF BASIC VCB ENTRY IN LIST         39200020
GDGLEN   EQU   16             LENGTH OF GDG ENTRY IN OUTPUT LIST        39400020
CVOLLEN  EQU   19             LENGTH OF CVOL ENTRY IN OUTPUT LIST       39600020
DATALEN  EQU   4              LENGTH OF GDG DATA IN OUTPUT LIST         39800020
DEVCDELN EQU   4              LENGTH OF DEVICE CODE IN CVOL ENTRY       40000020
*                                                                       40200020
INDXNTRY EQU   X'00'          INDEX ENTRY CODE                          40400020
DSNMNTRY EQU   X'07'          DS NAME ENTRY CODE                        40600020
MULTIVOL EQU   X'F8'          DS NAME ENTRY WITH MULTIVOLUMES           40800020
GDGENTRY EQU   X'02'          GDG ENTRY CODE                            41000020
VCBENTRY EQU   X'01'          VOLUME CONTROL BLOCK ENTRY CODE           41200020
ALIAS    EQU   X'04'          ALIAS ENTRY CODE                          41400020
OLDPTR   EQU   X'03'          OLD CVOL PTR CODE (PRIOR TO RELEASE 17)   41600020
NEWPTR   EQU   X'05'          NEW CVOL PTR CODE (AFTER RELEASE 17)      41800020
*                                                                       42000020
DSOPT    EQU   X'01'          OPTION CODE FOR SIMPLE DSNAMES IN LIST    42200020
INDOPT   EQU   X'02'          OPTION CODE FOR SIMPLE QUALIFIERS IN LIST 42400020
VOLOPT   EQU   X'04'          OPTION CODE FOR VOLUMES TO BE INCLUDED    42600020
OTHROPT  EQU   X'08'          OPTION CODE FOR ALL OTHER ENTRIES         42800020
ALLOPT   EQU   X'0F'          MASK FOR ALL OPTIONS                      43000020
*                                                                       43200020
INDXCODE EQU   X'00'          LIST CODE FOR AN INDEX ENTRY              43400020
VCBCODE  EQU   X'01'          VOLUME CONTROL BLOCK ENTRY LIST CODE      43600020
GDGCODE  EQU   X'02'          GDG ENTRY LIST CODE                       43800020
ALIASCDE EQU   X'04'          ALIAS ENTRY LIST CODE                     44000020
CVOLCODE EQU   X'05'          CVOL ENTRY LIST CODE                      44200020
DSNWOVOL EQU   X'07'          SIMPLE DSNAME ENTRY WITHOUT VOLUMES       44400020
DSNWVOLS EQU   X'08'          SIMPLE DSNAME ENTRY WITH VOLUMES          44600020
LINKCODE EQU   X'FF'          LINK ENTRY LIST CODE                      44800020
INDXCBLK EQU   X'00'          FOR TESTING FOR INDEX CONTROL ENTRIES     45000020
*                                                                       45200020
TWENTY5  EQU   25             MINIMUM COUNT FOR VALID INDEX BLOCK       45400020
VOLPLUS  EQU   X'0B'          ALL OPTIONS EXCEPT VOLOPT                 45600020
CNT      EQU   11             OFFSET TO COUNT FIELD IN CATALOG ENTRIES  45800020
ERR01    EQU   8              VOLUMES ONLY REQUEST--INDEX BLOCK FOUND   46000020
ERR02    EQU   12             VCB FOUND IN ERROR                        46200020
ERR03    EQU   4              LOCATE FAILED--LOCATE RC STORED INTO LIST 46400020
*                                                                       46600020
*                                                                       46800020
      EJECT                                                             47000020
IKJCIR   SAVE  (14,12),,*                                               47200020
         LR    R11,R15        ESTABLISH ADDRESSABILITY                  47400020
         USING IKJCIR,R11                                               47600020
         L     R2,CIRSAVE(R1) GET ADDRESS OF SAVEAREA FROM PARM LIST    47800020
         ST    R2,FORWARD(R13) ESTABLISH FORWARD CHAIN                  48000020
         ST    R13,BACKWARD(R2) ESTABLISH BACKWARD CHAIN                48200020
         LR    R13,R2         NEW SAVEAREA                              48400020
         LR    R4,R1          COPY PARAMETER LIST ADDRESS.              48600020
         L     R5,CIROPT(R4)  SAVE OPTION BITS                          48800020
         TM    CIRSRCH(R4),HIGHBIT TEST FOR TTR ADDRESS OR NAME         49000020
         BO    TTRADD         TTR WAS SPECIFIED.                        49200020
         MVC   CIROPT(L4,R4),CAM1 SET CAMLST OPTIONS TO NAME            49400020
         B     LOCATE         GO ISSUE LOCATE.                          49600020
*                                                                       49800020
TTRADD   MVC   CIROPT(L4,R4),CAM2 SET CAMLST OPTION TO BLOCK            50000020
         NI    CIRSRCH(R4),HEXFF-HIGHBIT TURN OFF TTR ADDRESS INDICATOR 50200020
LOCATE   EQU   *                                                        50400020
         LOCATE (1)                                                     50600020
         LTR   R15,R15             TEST LOCATE RETURN CODE        M2136 50800021
         BZ    CODE00              SUCCESS, CONTINUE              M2136 51000021
         C     R15,TWELVERC        TEST FOR RC = 12               M2136 51050021
         BE    CODE12              OK, INDEX BLOCK READ           M2136 51200021
ERRCODE  EQU   *                                                        52400020
         ST    R15,CIROPT(R4) SAVE LOCATE CODE IN FIRST WORD OF LIST    52600020
         LA    R15,ERR03      SET RC=4 FOR CALLER.                      52800020
ERREXIT  EQU   *                                                        53000020
         L     R13,BACKWARD(R13) GET CALLERS SAVEAREA                   53200020
         RETURN (14,12),RC=(15) RETURN  TO CALLER                       53400020
*                                                                       53600020
CODE12   ST    R5,CIROPT(R4)  REPLACE OPTION BITS IN LIST               53800020
         TM    CIROPT(R4),ALLOPT-VOLOPT WAS VOLUMES ONLY REQUESTED      54000020
         BNZ   CODE12A        NO, PROCESS BLOCK                         54200020
         LA    R15,ERR01      SET ERROR CODE                            54400020
         B     ERREXIT        GO EXIT WITH ERROR                        54600020
CODE12A  L     R1,CIRWA(R4)   POINT TO LOCATE WORKAREA                  54800020
         LR    R7,R1          SAVE BLOCK ADDRESS.                       55000020
         LH    R6,D0(R1)      GET BYTE COUNT FOR BLOCK                  55200020
         LA    R6,D0(R1,R6)   POINT AT END OF USED PORTION OF BLOCK     55400020
         LA    R2,FRSTNTRY(R1) POINT AT FIRST ENTRY                     55600020
CHKTYPE  EQU   *                                                        55800020
         CLI   CNT(R2),INDXNTRY CHECK FOR INDEX PTR ENTRY               56000020
         BE    INDEXPTR       YES, GO                                   56200020
         TM    CIROPT(R4),DSOPT CHECK FOR DSNAME OPTION SPECIFIED       56400020
         BNO   ALLCHK         NO, GO CHECK                              56600020
         TM    CNT(R2),DSNMNTRY CHECK FOR DSNAME ENTRY.                 56800020
         BO    DSENTRY        PROCESS AS A DS                           57000020
         TM    CNT(R2),MULTIVOL IS IT A DS PTR WITH SEVERAL VOLUMES     57200020
         BNZ   DSENTRY        YES, GO                                   57400020
         CLI   CNT(R2),GDGENTRY IS IT A GDG PTR                         57600020
         BE    GDGPTR         YES, GO                                   57800020
         CLI   CNT(R2),VCBENTRY IS IT A VOL CONTROL BLOCK               58000020
         BE    VOLPTR         YES, GO                                   58200020
ALLCHK   EQU   *                                                        58400020
         TM    CIROPT(R4),OTHROPT CHECK FOR OTHER OPTION                58600020
         BNO   NEXENTRY       NO, SKIP THIS ENTRY.                      58800020
         CLI   CNT(R2),ALIAS  IS IT AN ALIAS ENTRY                      59000020
         BE    ALIASENT       YES, GO                                   59200020
         CLI   CNT(R2),OLDPTR IS IT AN OLD CVOL PTR                     59400020
         BE    OLDCVOL        YES, GO                                   59600020
         CLI   CNT(R2),NEWPTR IS IT A NEW CVOL PTR                      59800020
         BE    NEWCVOL        YES, GO                                   60000020
         B     NEXENTRY       SKIP TO NEXT ENTRY                        60200020
*                                                                       60400020
DSENTRY  TM    CIROPT(R4),VOLOPT CHECK FOR VOLUME OPTION                60600020
         BO    DSENTRY1       YES, GO BUILD ENTRIES WITH VOLUMES        60800020
DSENTRY9 EQU   *                                                SA66186 60850021
         MVI   CODEOFF(R1),DSNWOVOL DSNAME WITH OUT VOLUMES CODE        61000020
         MVC   NAMEOFF(NAMLEN,R1),D0(R2) MOVE NAME TO LIST              61200020
         LA    R1,DSLEN(R1)   INCREMENT WORKAREA POINTER                61400020
NEXENTRY EQU *                                                          61600020
         XR    R3,R3          CLEAR REGISTER FOR INSERT INSTRUCTION     61800020
         IC    R3,CNT(R2)      PICK UP HW COUNT                         62000020
         SLL   R3,ONE         MULTIPLY BY 2 TO MAKE IT BYTES            62200020
         LA    R2,CATENTLN(R3,R2) ADJUST POINTER TO NEXT ENTRY          62400020
EOBCHK   EQU   *                                                        62600020
         CR    R2,R6          SEE IF END OF BLOCK IS REACHED            62800020
         BL    CHKTYPE        IF NOT, PROCESS ANOTHER ENTRY             63000020
         MVI   CODEOFF(R1),LINKCODE INDICATE LINK ENTRY                 63200020
         MVC   NAMEOFF(TTRLEN,R1),TTROFF(R7) MOVE TTR TO ENTRY          63400020
         MVC   VOLSEROF(VOLLEN,R1),VOLOFF(R7) MOVE VOLSER TO ENTRY      63600020
         B     NORMEXIT       NORMAL EXIT FROM ROUTINE                  63800020
DSENTRY1 MVI   CODEOFF(R1),DSNWVOLS INDICATE DSNAME WITH VOLUMES        64000020
         MVC   NAMEOFF(NAMLEN,R1),D0(R2) MOVE NAME TO LIST              64200020
         LA    R1,DSLEN(R1)   INCREMENT WORKAREA POINTER                64400020
         XR    R3,R3          CLEAR FOR INSERT INSTRUCTION              64600020
         IC    R3,CNT(R2)      GET HW COUNT                             64800020
         SLL   R3,ONE         MULTIPLY BY 2 TO MAKE IT BYTES            65000020
         BCTR  R3,R0          DECREMENT CNT BY ONE FOR EX               65200020
         EX    R3,MOVEVOLS    MOVE VOLUME LIST                          65400020
         LA    R3,L1(R3)      ADD BACK DECREMENT VALUE                  65600020
         LA    R2,CATENTLN(R3,R2) POINT TO NEXT ENTRY IN BLOCK          65800020
         LA    R1,L0(R3,R1)   POINT TO NEXT LIST ENTRY LOCATION.        66000020
         B     EOBCHK         CHK FOR END OF BLOCK                      66200020
INDEXPTR CLI   D0(R2),LINKCODE CHECK FOR LINK ENTRY                     66400020
         BE    LINKPTR        YES, GO EXIT.                             66600020
         TM    CIROPT(R4),INDOPT WAS INDEX INFORMATION REQUESTED        66800020
         BO    INDEXGO        YES, GO                                   67000020
         B     NEXENTRY       GET NEXT ENTRY                            67200020
INDEXGO  MVI   CODEOFF(R1),INDXCODE INDICATE INDEX NAME.                67400020
         MVC   NAMEOFF(CNT,R1),D0(R2) MOVE NAME AND TTR TO LIST ENTRY   67600020
         LA    R1,INDLEN(R1)  POINT TO NEXT LIST ENTRY                  67800020
         B     NEXENTRY       GET NEXT ENTRY                            68000020
NODATA   LR    R1,R2               POINT TO WORKAREA            SA52087 68050021
         LR    R7,R1               SAVE BLK ADDRESS             SA52087 68100021
         LA    R2,FRSTNTRY(R2)     ADJUST R2 PTR                SA52087 68150021
LINKPTR  MVI   CODEOFF(R1),LINKCODE INDICATE LINK ENTRY                 68200020
         MVC   NAMEOFF(TTRLEN,R1),NAMLEN(R2) MOVE TTR TO LIST           68400020
         MVC   VOLSEROF(VOLLEN,R1),VOLOFF(R7) MOVE VOLSER TO ENTRY      68600020
NORMEXIT EQU   *                                                        68800020
         L     R13,BACKWARD(R13) GET CALLERS SAVE AREA ADDRESS          69000020
         XR    R15,R15        SET RC=0                                  69200020
         RETURN (14,12),RC=(15) RETURN TO CALLER                        69400020
*                                                                       69600020
VOLPTR   EQU   *                                                        69800020
         TM    CIROPT(R4),VOLOPT SEE IF VOLUMES WERE REQUESTED          70000020
         BNO   DSENTRY9                 NO, GO TO DSN ROUTINE   SA66186 70200021
VOLPTR1  MVI   CODEOFF(R1),VCBCODE INDICATE DSNAME AND TTR OF VCB       71000020
         MVC   NAMEOFF(CNT,R1),D0(R2) MOVE NAME AND TTR TO LIST         71200020
VOLEXIT  LA    R1,VCBLEN(R1)  INCREMENT LIST PTR                        71400020
         B     NEXENTRY       GET NEXT ENTRY                            71600020
GDGPTR   MVI   CODEOFF(R1),GDGCODE INDICATE GDG ENTRY IN LIST           71800020
         MVC   NAMEOFF(CNT,R1),D0(R2) MOVE NAME AND TTR TO LIST ENTRY   72000020
         XR    R3,R3          CLEAR REGISTER FOR INSERT                 72200020
         IC    R3,CNT(R2)                                               72400020
         MVC   GDGDATA(DATALEN,R1),CATENTLN(R2) PUT FLAGS IN LIST       72600020
         LA    R1,GDGLEN(R1)  ADJUST LIST PTR                           72800020
         SLL   R3,ONE         MULTIPLY HW COUNT BY 2-- MAKE IT BYTES    73000020
         LA    R2,CATENTLN(R3,R2) POINT TO NEXT ENTRY IN BLOCK          73200020
         B     EOBCHK         CHECK FOR END OF BLOCK                    73400020
ALIASENT EQU   *                                                        73600020
         MVI   CODEOFF(R1),ALIASCDE INDICATE ALIAS ENTRY                73800020
         MVC   NAMEOFF(CNT,R1),D0(R2) MOVE ALIAS AND TTR TO LIST.       74000020
         XR    R3,R3          CLEAR FOR INSERT CHARA                    74200020
         IC    R3,CNT(R2)                                               74400020
         MVC   ALIASLEN(NAMLEN,R1),CATENTLN(R2) MOVE TRUE NAME TO LIST  74600020
         LA    R1,ALIASLEN+NAMLEN(R1) ADJUST LIST PTR                   74800020
         SLL   R3,ONE         CONVERT HALFWORDS TO BYTES                75000020
         LA    R2,CATENTLN(R3,R2) POINT TO NEXT ENTRY IN BLOCK          75200020
         B     EOBCHK         CHECK FOR END OF BLOCK                    75400020
OLDCVOL  CLI   D0(R2),INDXCBLK INDEX CONTROL ENTRY                      75600020
         BE    NEXENTRY       YES, GO TRY NEXT                          75800020
         MVI   CODEOFF(R1),CVOLCODE INDICATE CVOL PTR IN LIST ENTRY     76000020
         MVC   NAMEOFF(NAMLEN,R1),D0(R2) MOVE NAME TO LIST              76200020
         XC    DEVCDEOF(DEVCDELN,R1),DEVCDEOF(R1) ZERO DEVICE CODE      76400020
         MVC   CVOLVOL(VOLLEN,R1),CATENTLN(R2) MOVE VOLID TO LIST       76600020
         XR    R3,R3          CLEAR FOR INSERT CHARA                    76800020
         IC    R3,CNT(R2)                                               77000020
CVOLEXIT SLL   R3,ONE         CONVERT HALFWORD COUNT TO BYTES           77200020
         LA    R2,CATENTLN(R3,R2) POINT AT NEXT ENTRY IN BLOCK          77400020
         LA    R1,CVOLLEN(R1) POINT AT NEXT LIST ENTRY                  77600020
         B     EOBCHK         CHECK FOR END OF BLOCK                    77800020
NEWCVOL  CLI   D0(R2),INDXCBLK INDEX CONTROL ENTRY CHECK                78000020
         BE    NEXENTRY       GET NEXT ENTRY                            78200020
         MVI   CODEOFF(R1),CVOLCODE  INDICATE CVOL                      78400020
         MVC   NAMEOFF(NAMLEN,R1),D0(R2) PUT NAME INTO LIST ENTRY       78600020
         MVC   DEVCDEOF(DEVCDELN+VOLLEN,R1),CATENTLN(R2) MOVE DEVICE    78800020
*                             CODE AND VOLSER TO LIST ENTRY.            79000020
         XR    R3,R3        CLEAR FOR INSERT CHARACTER                  79200020
         IC    R3,CNT(R2)                                               79400020
         B     CVOLEXIT       EXIT FROM ROUTINE                         79600020
**********************************************************************  79800020
*                                                                       80000020
*   THIS ROUTINE GETS CONTROL IF A ROUTINE CODE OF ZERO IS PASSED BACK  80200020
*   FROM LOCATE.                                                        80400020
*                                                                       80600020
**********************************************************************  80800020
CODE00   EQU   *                                                        81000020
         L     R2,CIRWA(R4)   PICK UP BLOCK ADDRESS                     81200020
         CLC   CIROPT(L4,R4),CAM1  WAS THIS A LOCATE BY NAME            81400020
         ST    R5,D0(R4)      RESTORE OPTION BYTES                      81600020
         BE    TESTVCB        YES, BLOCK MUST BE A VCB                  81800020
         CLI   FRSTNTRY(R2),LINKCODE  TEST FOR NO ENTRY         SA52087 81850021
         BE    NODATA             YES,GO TO NODATA RTN          SA52087 81900021
         LA    R3,TWENTY5     GET MINIMUM POSSIBLE BYTE COUNT           82000020
         CH    R3,D0(R2)      CHECK AGAINST ACTUAL BYTE COUNT           82200020
         BH    TESTVCB        IF COUNT IS LESS THAN MINIMUM, VCB        82400020
         TM    CIROPT(R4),VOLPLUS WAS OTHER THAN VOLUMES REQUESTED      82600020
         BNZ   CODE12A        YES, PROCESS AS INDEX BLOCK.              82800020
*                                                                       83000020
*   SINCE NO OTHER OPTIONS WERE REQUESTED, WE MUST ASSUME IT IS A       83200020
*   VOLUME CONTROL BLOCK.  THE FOLLOWING CHECKS ARE MADE BASED          83400020
*   ON THAT ASSUMPTION. IF NO OPTIONS WERE REQUESTED, IT IS STILL       83600020
*   AN ERROR AND IS CAUGHT HERE. EVEN IF IT IS NOT A VCB, SINCE         83800020
*   OPTIONS DID NOT INDICATE HE EXPECTED OTHER THAN A VCB AND WE        84000020
*   CAN NOT DETERMINE FOR SURE WHAT IT IS, HE WILL GET WHATEVER         84200020
*   HE POINTED AT WITH THE TTR HE FURNISHED.                            84400020
*                                                                       84600020
TESTVCB  TM    CIROPT(R4),VOLOPT WAS VOLUMES REQUESTED                  84800020
         BZ    ERRVCB         NO, PROCESS ERROR                         85000020
         TM    CIROPT(R4),VOLPLUS WERE THERE OTHER REQUESTS             85200020
         BNZ   ERRVCB         YES, PROCESS AS ERROR.                    85400020
         B     NORMEXIT       NO, EXIT NORMALLY                         85600020
ERRVCB   EQU   *                                                        85800020
         LA    R15,ERR02      SET RC=12, VOLUME BLK FOUND IN ERROR      86000020
         B     ERREXIT        EXIT IN ERROR                             86200020
CAM1     CAMLST  NAME,1,,3         LOCATE CAMLST                  M0875 86400021
CAM2     CAMLST  BLOCK,1,2,3                                            86600020
TWELVERC DC    F'12'               TWELVE FOR RC TEST             M2136 86650021
MOVEVOLS MVC   D0(L0,R1),TWELVE(R2) USED FOR EXECUTE                    86800020
         END                                                            87000020
