 TITLE 'IKJEHCT1-IBM S/360 TIME SHARING OPTION LISTCAT COMMAND'  100000 00030021
IKJEHCT1 CSECT                                                          00040021
*C 282300                                                       SA58901 00041821
*A 189100-189260                                                SA52087 00044021
*C 185100-185400,186000-1863000,177000                          SA52087 00045821
*C 316260                                                         M2139 00047621
*A 316060,316260,317100,317900-318000,659900-659940,             A49872 00049421
*A 738400-738520,746200                                          A49872 00051221
*C 316040,316140-316160,316500-316600,317400,724800,737400,      A49872 00053021
*C 744600,745200,746100,746700-747300,747900,748500,749100,      A49872 00054821
*C 749460,749580,749730,781200                                   A49872 00056621
*D 170400-171900,733940-734400,749880                            A49872 00058421
*C 339900-340500,341400,342000,381600                            A48499 00060121
*D 341100                                                        A48499 00060221
*A 212096                                                        A48474 00060421
*D 212500                                                        A48474 00060821
*A 433300-433400,680420-680500                                    M2136 00062021
*D 678900-679200                                                  M2136 00064021
*A 701900                                         MODULE CLEANUP 100000 00070021
*C 000300,630600,657300-657600,778500             MODULE CLEANUP 100000 00080021
*D 630900,702000,711900-712200                    MODULE CLEANUP 100000 00082021
*D 212096-212097                                                 A45498 00084021
*********************************************************************** 00090020
* STATUS -- CHANGE LEVEL 01                                      A45498 00120021
*                                                                     * 00150020
* FUNCTION --                                                         * 00180020
*    THIS IS THE MAIN PROCESSING MODULE OF THE LISTCAT COMMAND.       * 00240020
*    IT GETS CONTROL FROM THE TERMINAL MONITOR PROGRAM VIA ATTACH     * 00270020
*    AND WILL SEARCH THE SYSCTLG DATA SET USING THE CATALOG           * 00300020
*    MANAGEMENT ROUTINE LOCATE AND LIST THE NAMES OF ALL DATA         * 00330020
*    SETS SETS THAT ARE FOUND TO HAVE THE USER'S USERID AS THE FIRST, * 00360020
*    (HIGHEST LEVEL), QUALIFIER. THE NODE, IN THIS CASE THE           * 00390020
*    USERID, WILL NOT BE LISTED AS PART AS PART OF THE DATA SET       * 00420020
*    NAME IN AN EFFORT TO KEEP THE LISTING AS BRIEF AS POSSIBLE.      * 00450020
*    IF THE LEVEL KEYWORD WAS SPECIFIED IN THE COMMAND WITH A         * 00480020
*    SUBPARAMETER SPECIFYING A VALID INDEX STRUCTURE NAME, THE        * 00510020
*    SPECIFIED NAME WILL BE USED INSTEAD OF THE USERID AS THE         * 00540020
*    NODE FOR SEARCHING THE CATALOG. AN ASTERISK (*) IMBEDDED IN      * 00570020
*    THE NAME SUPPLIED WITH THE LEVEL KEYWORD WILL RESULT IN THE      * 00600020
*    SEARCH BEING RESRRICTED TO FINDING FULLY QUALIFIED DSNAMES       * 00630020
*    COMPOSED OF THE SPECIFIED SIMPLE NAMES AND ANY QUALIFIER         * 00660020
*    (INDEX NAME) TO REPLACE THE IMBEDDED ASTERISK. THE OTHER         * 00690020
*    KEYWORDS, HISTORY,VOLUMES AND MEMBERS, CAUSE ADDITIONAL          * 00720020
*    INFORMATION TO BE PROVIDED ABOUT THE DATA SETS WHOSE NAMES       * 00750020
*    ARE LISTED.                                                      * 00780020
*    THE PUTLINE SERVICE ROUTINE, IKJPUTL, IS LOADED AND KEPT IN      * 00810020
*    CORE FOR THE DURATION OF THE COMMANDS OPERATION AND SERVES       * 00840020
*    AS THE I/O INTERFACE BETWEEN THIS PROGRAM AND THE TERMINAL.      * 00870020
*    THE PARSE SERVICE ROUTINE IS USED TO ANALYZE THE COMMAND         * 00900020
*    STRING AND PROMPT FOR MISSING PARAMETERS. IKJEHMEM IS            * 00930020
*    LOADED IF THE MEMBERS KEYWORD IS SPECIFIED AND WILL LIST         * 00960020
*    THE DIRECTORY OF AND PDS ENCOUNTERED IN THE CATALOG SEARCH.      * 00990020
*    THE DAIR SERVICE ROUTINE IS USED TO ALLOCATE A PDS BEFORE        * 01020020
*    CONTROL IS GIVEN TO IKJEJMEM. IKJEHCIR IS LOADED EARLY IN        * 01050020
*    THE PROGRAM AND USED AS A SUBROUTINE TO DO THE ACTUAL            * 01080020
*    LOCATES AND BUILD LISTS OF QUALIFIERS TO BE PROCESSED.           * 01110020
*                                                                     * 01170020
*    THIS MODULE CONSISTS OF SEVERAL CONTROL SECTIONS AS FOLLOWS -    * 01210020
*              IKJEHCT1- THE MAIN AND BASIC PORTION OF THE MODULE     * 01230020
*              IKJEHHST- A SUBROUTINE TO SUPPLY HISTORY INFORMATION   * 01260020
*              IKJEHVOL- A SUBROUTINE TO SUPPLY VOLUMES INFORMATION   * 01290020
*              IKJEHMBR- A SUBROUTINE TO INTERFACE WITH IKJEHMEM      * 01320020
*                        AND SUPPLY MEMBERS INFORMATION               * 01350020
*              IKJEHCTM- CONTAINS MESSAGES FOR THE COMMAND            * 01380020
*                                                                     * 01410020
* ENTRY POINTS --                                                     * 01440020
*         IKJEHCT1 - ENTRY POINT TO THE PROGRAM                       * 01450020
*                                                                     * 01460020
* INPUT --                                                            * 01590020
*    A PARAMETER LIST FROM THE TMP IS SUPPLIED AND POINTED TO BY      * 01650020
*    REG 1. IT CONTAINS POINTERS TO THE COMMAND BUFFER, UPT,          * 01680020
*    ECT, PSCB.                                                       * 01710020
*                                                                     * 01740020
* OUTPUT --                                                           * 01770020
*    A LIST OF DSNAMES FOUND CATALOGED UNDER THE NODE SPECIFIED       * 01830020
*    AND A LIST OF ATTRIBUTES IF REQUESTED BY OPTIONAL KEYWORDS.      * 01860020
*                                                                     * 01890020
* EXTERNAL REFERENCES --                                              * 01920020
*         IKJEHCIR - CATALOG INFORMATION ROUTINE                      * 01980020
*         IKJEHMEM - MEMBERS ROUTINE                                  * 02040020
*         IKJPARS - PARSE ROUTINE                                     * 02050020
*         IKJPUTL - PUTLINE ROUTINE                                   * 02060020
*         IKJDAIR - DYNAMIC ALLOCATION INTERFACE ROUTINE              * 02062020
*         IKJSTCK - STACK ROUTINE                                     * 02064020
*                                                                     * 02070020
* EXITS, NORMAL -- RETURN TO THE TERMINAL MONITOR PROGRAM             * 02080020
*                                                                     * 02090020
* EXITS, ERROR -- RETURN TO THE TERMINAL MONITOR PROGRAM              * 02100020
*                                                                     * 02110020
* TABLES/WORKAREA --                                                  * 02520020
*    OBTWAD- WORKING CORE THAT PROVIDES THE WORKAREA FOR THE          * 02580020
*    RDJFCB AND OBTAIN MACROS ALONG WITH DCBS, LIST FORMS             * 02610020
*    OF MACRSO, VARIOUS SWITCHS AND PARAMETER LISTS. THIS             * 02640020
*    AREA IS NEEDED ONLY IF THE HISTORY OR MEMBERS KEYWORD            * 02670020
*    IS SPECIFIED.                                                    * 02700020
*    WORKCORE- MAIN WORK AREA CONTAINING SWITCHS, POINTERS AND        * 02730020
*    BLOCKS OF CORE USED IN NORMAL PROCESSING.                        * 02760020
*                                                                     * 02820020
* ATTRIBUTES -- REENTRANT, READ-ONLY, REFRESHABLE                     * 02850020
*                                                                     * 02910020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 02920020
*                                                                     * 02930020
* NOTES -- N/A                                                        * 02932020
*                                                                     * 02940020
*********************************************************************** 02970020
         ENTRY IKJEHWRT                                                 03000020
         ENTRY IKJEHERR                                                 03030020
         ENTRY IKJEHCR8                                                 03060020
         ENTRY IKJEHCR4                                                 03090020
R0       EQU   0                                                        03120020
R1       EQU   1              POINTS TO CURRENT SLOT IN MAINLINE        03150020
R2       EQU   2                                                        03180020
R3       EQU   3                                                        03210020
R4       EQU   4                                                        03240020
R5       EQU   5                                                        03270020
R6       EQU   6                                                        03300020
R7       EQU   7                                                        03330020
R8       EQU   8                                                        03360020
R9       EQU   9                                                        03390020
R10      EQU   10             USED AS A BASE FOR PARSE DSECT            03420020
R11      EQU   11             MAIN BASE REG FOR THE PROGRAM             03450020
R12      EQU   12                                                       03480020
R13      EQU   13             POINTS TO WORK AREA.                      03510020
R14      EQU   14                                                       03540020
R15      EQU   15                                                       03570020
ONE      EQU   X'01'                                                    03600020
*                                                                       03630020
MSG01    EQU   1                                                        03660020
MSG02    EQU   2                                                        03690020
MSG03    EQU   3                                                        03720020
MSG04    EQU   4                                                        03750020
MSG05    EQU   5                                                        03780020
MSG06    EQU   6                                                        03810020
MSG07    EQU   7                                                        03840020
MSG08    EQU   8                                                        03870020
MSG09    EQU   9                                                        03900020
MSG10    EQU   10             COMMAND NOT EXECUTABLE                    03930020
MSG11    EQU   11                                                       03960020
MSG12    EQU   12                                                       03990020
MSG13    EQU   13                                                       04020020
MSG14    EQU   14                                                       04050020
MSG15    EQU   15                                                       04080020
MSG16    EQU   16                                                       04110020
MSG17    EQU   17                                                       04117020
MSG18    EQU   18                                                       04124020
MSG19    EQU   19                 MSG INDEX NUMBER                      04131020
*                                                                       04140020
SECMSG01 EQU   1                                                        04170020
SECMSG02 EQU   2                                                        04200020
SECMSG03 EQU   3                                                        04230020
SECMSG04 EQU   4                                                        04260020
SECMSG05 EQU   5                                                        04290020
SECMSG06 EQU   6                                                        04320020
SECMSG07 EQU   7                                                        04350020
SECMSG08 EQU   8                                                        04380020
SECMSG09 EQU   9                                                        04410020
SECMSG10 EQU   10                                                       04440020
SECMSG11 EQU   11                                                       04470020
SECMSG12 EQU   12                                                       04500020
SECMSG13 EQU   13             NOPROMPT MODE AND PROMPTING REQUIRED      04530020
SECMSG14 EQU   14             PARSE FAILED RC=XX                        04560020
SECMSG15 EQU   15                                                       04590020
SECMSG16 EQU   16                                                       04620020
SECMSG17 EQU   17                                                       04650020
SECMSG18 EQU   18                                                       04680020
SECMSG19 EQU   19                                                       04710020
SECMSG20 EQU   20                                                       04740020
SECMSG21 EQU   21                                                       04770020
SECMSG22 EQU   22                                                       04800020
SECMSG23 EQU   23                                                       04830020
SECMSG24 EQU   24                                                       04860020
SECMSG25 EQU   25                                                       04890020
SECMSG26 EQU   26                                                       04920020
*                                                                       04950020
BLKSP    EQU   1              SUBPOOL FOR LOCATE BLOCKS                 04980020
OSP      EQU   1              SUBPOOL FOR OBTWAD.                       05010020
WORKSP   EQU   1              SUBPOOL FOR WORKAREA                      05040020
DSNPDEFL EQU   6              OFFSET TO PDE FLAG BYTE.                  05070020
DSNLENOF EQU   4                   OFFSET TO LENGTH FIELD OF PDE        05100020
TTROFF   EQU   9             OFFSET TO TTR FIELD                        05130020
CIRVOLS  EQU   X'04'          VOLUMES OPTION                            05160020
CIRDSN   EQU   X'01'          DSNAME  OPTION                            05190020
CIRIND   EQU   X'02'          INDEX   OPTION                            05220020
CIRALL   EQU   X'08'          ALL OTHERS                                05250020
VCBTTROF EQU   252            OFFSET TO TTR IN VCB.                     05280020
CIROFF   EQU   8              OFFSET TO CIR ENTRY                       05310020
DSNENT   EQU   X'07'               CIR DSNAME CODE                      05340020
DSNLEN   EQU   9              LENGTH OF DSNAME ENTRY                    05370020
GDGENT   EQU   X'02'          GDG ENTRY CODE                            05400020
GDGLEN   EQU   16             LENGTH OF GDG ENTRY                       05430020
INDENT   EQU   X'00'          INDEX ENTRY                               05460020
INDLEN   EQU   12             LENGTH OF INDEX ENTRY                     05490020
VOLENT   EQU   X'08'          VOLUMES WITH DSNAME ENTRY                 05520020
VCBENT   EQU   X'01'          VOLUME CONTROL BLOCK ENTRY                05550020
VCBLEN   EQU   12             LENGTH OF VCB ENTRY                       05580020
ALIENT   EQU   X'04'          ALIAS ENTRY                               05610020
ALILEN   EQU   20             LENGTH OF ALIAS ENTRY                     05640020
CVOLENT  EQU   X'05'          CVOL POINTER ENTRY                        05670020
CVOLLEN  EQU   19             LENGTH OF CVOL ENTRY                      05700020
CIRVOLID EQU   259            OFFSET TO VOLID IN CIR LIST (LOCATE)      05730020
EOHISTOF EQU   38             LENGTH OF HISTORY DATA                    05760020
MAXLEN   EQU   44             MAXIMUM DSNAME LENGTH                     05790020
ASTSW    EQU   X'80'          OPTMASK-ASTERISK IN INDEX STRUCTURE       05820020
HISTORY  EQU   X'01'          OPTMASK BIT FOR HISTORY                   05850020
MEM      EQU   X'02'          OPTMASK BIT FOR MEM                       05880020
HISTMEM  EQU   X'03'          HISTORY + MEMBERS                         05910020
VOLUMES  EQU   X'04'          OPTMASK VOLUMES KEYWORD SWITCH            05940020
GDGSW    EQU   X'20'          OPTMASK GDG SWITCH                        05970020
MOREVOLS EQU   X'40'          INDICATOR FOR MORE THAN 5 VOLSERS.        06000020
ANYOPT   EQU   X'07'          HISTORY + DATA + MEMBERS                  06030020
WRITESW  EQU   X'20'         WRITE NEEDED SWITCH                        06060020
NWRITESW EQU   X'DF'         MASK FOR TURNING OFF WRITE SW              06090020
GDGSWOFF EQU   X'DF'         AND MASK FOR GDGSW                         06120020
VOLSWOFF EQU   X'BF'          MASK TO TURN OFF MOREVOLS INDICATOR       06150020
NHISTMEM EQU   X'FC'          AND MASK FOR HISTORY/MEMBERS.             06180020
LOCSAVOF EQU   72            OFFSET TO LOCAL SAVEAREA                   06210020
DSORGOFF EQU   2                                                        06240020
CRDATOFF EQU   9                                                        06270020
ASTERISK EQU   C'*'               USED FOR ASTERISK FEATURE OF LEVEL    06300020
HIGHBIT   EQU   X'80'           USED FOR TEST OF HIGH BIT               06330020
BLANK    EQU   C' '                BLANK                                06360020
CHARG    EQU   C'G'                G                                    06370020
CHARV    EQU   C'V'                V                                    06380020
COMPZONE EQU   X'F0'               MASK TO TEST FOR COMPLEMENT          06382020
FOXES    EQU   X'FF'                                                    06390020
ON       EQU   X'01'                                                    06397020
OFF      EQU   X'00'                                                    06404020
EIGHT    EQU   X'08'                                                    06411020
FORTY2   EQU   42            LENGTH OF TEMPNAME MINUS TWO BYTES         06420020
ENTPTR   EQU   4              OFFSET OF 4 FOR CIR RTN                   06450020
ENDTA    EQU   10            END OF DATA IN BUFF VOL RTN                06480020
ERRCOD   EQU   14             USED FOR UNPK OF ERROR CODE               06510020
RETCD12 EQU    12            RETURN CODE FOR ERROR RETURN TO TMP        06540020
EXITCD   EQU    X'87'           USED FOR EXIT CODE IN JFCB              06570020
THIRTY1  EQU   31            USED FOR COMPARE OF 31 DAYS                06600020
CHARU    EQU   C'U'          DATA SET UNMOVABLE ABBREV                  06630020
HEX00    EQU   X'00'         BYTE COMPARE FIELD                         06660020
OFF12    EQU   12            OFFSET FOR RESTORE REG AREA                06690020
SWON     EQU   X'FF'               MASK TURN SWITCH ON                  06700020
SWOFF    EQU   X'00'               MASK TURN SWITCH OFF                 06710020
*                                                                       06720020
*     THE FOLLOWING EQUATES AND CONSTANTS PUT IN 4-20-70 AND ON*        06750020
FORWARD  EQU   8             OFFSET TO FORWARD CHAIN SAVE               06780020
BACKWARD EQU   4             OFFSET TO BACKWARD CHAIN SAVE              06810020
ZONE     EQU   X'F0'         USED FOR ZONE FIELD MASK                   06840020
L0       EQU   0             USED FOR LENGTH OFFSETS WHEN NECCESSARY    06870020
L1       EQU   1             LENGTH OFFSET OF ONE                       06900020
L2       EQU   2                                                        06930020
L3       EQU   3                                                        06960020
L4       EQU   4                                                        06990020
L10      EQU   10            LENGTH OF TEN                              07020020
EIGHTY   EQU   X'F0'         USED TO TEST FOR DSNAME OPTION             07050020
* THE FOLLOWING EQUATES ARE DISPLACEMENT VALUES USED WHEN NECCESSARY*   07080020
D0       EQU   0                                                        07110020
D1       EQU   1                                                        07140020
D2       EQU   2                                                        07170020
D3       EQU   3                                                        07200020
D4       EQU   4                                                        07230020
D5       EQU   5                                                        07260020
D6       EQU   6                                                        07290020
L8       EQU   8        LENGTH OF EIGHT                                 07320020
*   END OF EQUATES AND CONSTANTS *****************                      07350020
*                                                                       07380020
D7       EQU   7        SEVEN                                           07410020
D8       EQU   8        EIGHT                                           07440020
D9       EQU   9        NINE                                            07470020
PERIOD   EQU   C'.'     USED FOR PERIOD CONSTANT                        07500020
CALLRET  EQU   52       CALLERS RETURN OFFSET                           07530020
D10      EQU   10       OFFSET OF TEN                                   07560020
D11      EQU   11       OFFSET OF ELEVEN                                07590020
D12      EQU   12       OFFSET OF TWELVE                                07620020
D13      EQU   13       OFFSET OF THIRTEEN                              07650020
D16      EQU   16       OFFSET OF SIXTEEN                               07680020
D14      EQU   14       OFFSET OF 14                                    07710020
D15      EQU   15       OFFSET OF 15                                    07740020
L6       EQU   6        LENGTH OF 6                                     07770020
L7       EQU   7        LENGTH OF 7                                     07800020
L5       EQU   5        LENGHT OF 5                                     07830020
RC28     EQU   28                                                       07837020
FOURB    EQU   4                  USED IN BITOHEX RTN                   07844020
CHARZRO  EQU   C'0'                USED TO COMPARE FOR PRINT ZERO       07845020
CHARBLK  EQU   C' '                USED TO COMPARE FOR BLANK            07846020
TCBOFF   EQU   4                   OFFSET TO CURRENT TCB                07847020
         EJECT                                                          07851020
LISTCAT  SAVE  (14,12),,*                                               07860020
         LR    R11,R15       SET UP ADDRESSABILITY                      07890020
         USING LISTCAT,R11    USE R11 FOR MAIN BASE.                    07920020
         USING OBTWAD,R12    USE R12 FOR HIST/MEM DESECT                07950020
         LR    R2,R1         COPY PARM LIST POINTER INTO WORK REG       07980020
         GETMAIN  R,LV=WORKSIZE,SP=WORKSP    GET INITIAL CORE           08010020
         ST    R13,BACKWARD(R1)      SET UP BACKWARD CHAIN              08040020
         ST    R1,FORWARD(R13)       SET UP FORWARD CHAIN               08070020
         LR    R13,R1        SETUP ADDRESSABILITY FOR WORK SPACE.       08100020
         USING WORKCORE,R13          USE R13 FOR WORKCORE BASE          08130020
         NI    OPTMASK,HEX00      CLEAR OPTION BYTE                     08160020
         MVI   FIRSTCIR,OFF        TURN OFF FIRST CVR SWITCH            08165020
         MVI   FIRSTIME,ONE       TURN ON FIRST ALLOCATE SWITCH         08170020
         MVC   GETML(LILFS),GETMLMDL  MOVE LIST FORM OF MACROS TO WORK  08190020
         MVI   USERNODE,BLANK        PROPAGATE BLANKS FOR USERID        08220020
         MVC   USERNODE+D1(L'USERNODE-D1),USERNODE CLEAR USERND AREA    08250020
         XC    RETCD,RETCD    SET RETURN CODE TO ZERO INITIALLY         08280020
         XC    GDGCNT,GDGCNT    CLEAR GDG COUNT AREA                    08310020
         MVI   STACKSW,SWOFF       TURN STACK SWITCH OFF                08320020
         LA    R3,PUTLLIST   SETUP                                      08340020
         ST    R3,PUTLCON        ADCONS                                 08370020
         LA    R3,DPUTLINE        TO                                    08400020
         ST    R3,DPUTLCON         BE USED                              08430020
         LA    R3,CPECB              BY THE                             08460020
         ST    R3,ECBPTR                PUTLINE                         08490020
         XC    CPECB,CPECB                ROUTINES                      08520020
         L     R3,CPPLUPT-CPPL(R2) GET UPT PTR                          08550020
         ST    R3,UPTPTR      SAVE UPT PTR                              08580020
         L     R3,CPPLPSCB-CPPL(R2)  GET PSCB PTR                       08610020
         ST    R3,PSCBPTR     SAVE IT                                   08640020
         L     R3,CPPLECT-CPPL(R2)  GET ECT PTR                         08670020
         ST    R3,ECTPTR      SAVE IT                                   08700020
          MVC   DPUTLINE(LTPUTL),TPUTMDL    INITIALIZE PUTLINE LIST     08730020
         XC    ERRPARM(ERRLIST),ERRPARM  CLEAR ERROR LIST               08740020
         LOAD  EP=IKJPUTL                                               08760020
         ST    R0,PUTLADDR    SAVE EP TO PUTLINE                        08790020
         LOAD  EP=IKJEHCIR                                              08820020
         ST    R0,CIRAD       SAVE EP ADDRESS OF CIR                    08850020
*                                                                       08880020
*        SETUP PARMLIST FOR PARSE, THEN PARSE COMMAND STRING            08910020
*                                                                       08940020
         LM    R3,R5,UPTPTR   SETUP FOR PARSE                           08970020
         STM   R3,R5,PUTLLIST SAVE PTRS                                 09000020
*                                                                       09030020
*                                                                       09060020
         LA    R3,PUTLLIST         SET UP USING DSECT                   09090020
         USING PPL,R3              IKJPPL MAP MACRO                     09120020
*                                                                       09150020
         L     R1,PARSCON1    PTR TO PCL                                09180020
         ST    R1,PPLPCL     PUT INTO LIST                              09210020
         XC    PARDSECT,PARDSECT CLEAR DSECT POINTER                    09240020
         LA    R1,PARDSECT    PTR TO ANSWER PLACE                       09270020
         ST    R1,PPLANS      PUT INTO LIST                             09300020
         L     R1,CPPL-CPPL(R2)  GET COMMAND BUFF PTR                   09330020
         ST    R1,PPLCBUF    PUT INTO LIST                              09360020
         DROP  R3                                                       09390020
         LA    R1,PUTLLIST    POINT AT LIST                             09420020
         LINK EP=IKJPARS,MF=(E,(R1))                TYPE 1 PARSE        09450020
*                                                                       09480020
         B     PARSCODE(R15)        BRANCH TABLE BELOW                  09510020
*                                                                       09540020
PARSCODE B     PARSCD00       RC=00 SUCCESSFUL PARSE                    09570020
         B     PARSCD04       RC=04 PARSE UNABLE TO PROMPT              09600020
         B     PARSCD08       RC=08 ATTENTION WHILE IN PARSE            09630020
         B     PARSCD12       RC=12 INVALID PARAMETER LIST              09660020
PARSCD16 EQU   *                   THIS IS PARSE RC = 16                09750020
         MVI   ERR1,MSG11         NOT ENOUGH STORAGE                    09790020
         B     PARSERR2        GO PROCESS ERROR                         09870020
PARSCD12 EQU   *                                                        10020020
         BAL   R8,CVDREG15    CONVERT RETURN CODE TO DECIMAL            10080020
PARSERR1 MVI   ERR2,SECMSG14      PARSE ERROR CODE MSG                  10110020
         MVI   ERR1,MSG10         COMMAND NOT EXECUTABLE MSG            10210020
PARSERR2 BAL   R8,ERROUT          GO TO ERROR HNDLER                    10290020
PARSCD08 LA    R1,RETCD12         RC 12 FOR TMP                         10350020
         ST    R1,RETCD       SAVE IT FOR WRAPUP RTN                    10390020
PARSCD04 MVI   STACKSW,SWON        TURN STACK SWITCH ON                 10400020
         B     WRAPUP01       GO TERMINATE                              10440020
PARSCD00 EQU   *                                                        10470020
*                                                                       10500020
         L     R10,PARDSECT  GET ADDR OF PARSE DSECT                    10530020
         USING IKJPARMD,R10                                             10560020
         TM    PHIST+D1,ONE   SEE IF HISTORY WAS REQUESTED              10590020
         BNO   NEXT00        NO, SKIP TO NEXT CHECK                     10620020
         OI    OPTMASK,HISTORY   YES, SET INDICATOR IN MAXK             10650020
NEXT00   TM    PMEM+D1,ONE    SEE IF MEMBERS WAS REQUESTED              10680020
         BNO   NEXT01        NO, SKIP TO NEXT CHECK                     10710020
*                                                                       10740020
         LOAD  EP=IKJEHMEM                                              10770020
         ST    R0,MEMMOD     SAVE ENTRY POINT ADDRESS                   10800020
         OI    OPTMASK,MEM   SET ON INDICATOR IN MASK                   10830020
NEXT01   TM    PVOLUMES+D1,ONE WAS VOLUMES REQUESTED                    10860020
         BNO   NEXT02        NO, SKIP TO NEXT CHECK                     10890020
         OI    OPTMASK,VOLUMES  TURN ON VOLUME  SWITCH                  10920020
*                                                                       10950020
*        CHECK TO SEE IF LEVEL WAS SPECIFIED. IF SO, A CHECK MUST BE    10980020
*        MADE TO SEE IF THERE IS AN EMBEDDED ASTERISK IN THE NAME. IF   11010020
*        ONE IS PRESENT, IT IS CHECKED TO SEE IF IT IS PROPERLY         11040020
*        SPECIFIED. THEN THE ASTERISK INDICATOR SWITCH IS TURNED ON.    11070020
*                                                                       11100020
NEXT02   TM    PLEVEL+D1,ONE    SEE IF LEVEL WAS SPECIFIED              11130020
         BZ    NONODE        NO, USE USERID FOR NODE.                   11160020
         L     R3,PNODE1      GET PTR TO DSNAME                         11190020
         LTR   R3,R3               TEST DSLENGTH                        11200020
         BZ    MEMONLY             MEMBER NAME ONLY WAS SPECIFIED       11210020
         LH    R4,PNODE1+DSNLENOF GET LENGTH OF NAME                    11220020
NEXT03   LA    R1,D0(R3,R4)        POINT AT END OF DSNAME               11250020
ASTSRCH  BCTR  R1,R0          BACK UP POINTER BY ONE BYTE               11280020
         CLI   D0(R1),ASTERISK CHECK IT FOR AN ASTERISK                 11310020
         BE    ASTROUT        YES, GO PROCESS                           11340020
         CR    R1,R3          SEE IF AT START OF NAME                   11370020
         BH    ASTSRCH        NO, CHECK NEXT CHARACTER                  11400020
*                                                                       11430020
*        NO ASTERISK WAS FOUND. USE SPECIFIED INDEX STRUCTURE           11460020
*        FOR NODE POINT OF CATALOG SEARCH.                              11490020
*                                                                       11520020
         STH   R4,USRNODEL   SAVE LENGTH OF NODE                        11550020
         LR    R1,R4          COPY LENGTH OF NAME                       11580020
         BCTR  R1,R0          DECREMENT FOR MOVE                        11610020
         LA    R7,USERNODE    POINT AT AREA TO HOLD USERNODE            11640020
         EX    R1,MOVE        MOVE NAME                                 11670020
         B     MAINLINE       GO TO MAINLINE PROGRAM                    11700020
*  MEMBER NAME ONLY WAS SPECIFIED, USE IT AS THE NODE                   11706020
MEMONLY  L     R3,PNODE1+D8        POINT TO MEMBER NAME                 11712020
         LH    R4,PNODE1+D12       LENGTH OF MEMBER NAME                11718020
         B     NEXT03              GO CHECK FOR ASTERISK                11724020
ASTROUT  EQU   *                                                        11730020
         BCTR  R4,R0          DECREMENT LENGTH BY ONE                   11760020
         SR    R1,R3          FIND OFFSET TO ASTERISK                   11790020
         CR    R1,R4          SEE IF * IS LAST QUALIFIER                11820020
         BNL   LEVELER1       YES, ERROR                                11850020
         LTR   R1,R1          SEE IF * IS FIRST QUALIFIER               11880020
         BZ    LEVELER1       YES, ERROR                                11910020
         LA    R2,D0(R3,R1)    POINT AT ASTERISK                        11940020
ASTSRCH2 BCTR  R2,R0          CHECK FOR ANOTHER *                       11970020
         CLI   D0(R2),ASTERISK    CHECK FOR ASTERISK                    11980020
         BE    LEVELER2       IF FOUND, ERROR                           12000020
         CR    R2,R3          START OF NAME                             12030020
         BH    ASTSRCH2       NO, TRY AGAIN                             12060020
*                                                                       12090020
*        ASTERISK WAS VALIDLY SPECIFIED. STRIP OFF PREFIX AND           12120020
*        SUFFIX PORTIONS OF NAME AND SAVE THEM. TURN ON ASTERISK        12150020
*        INDICATOR SWITCH.                                              12180020
*                                                                       12210020
         OI    OPTMASK,ASTSW  INDICATOR SWITCH FOR *.                   12240020
         BCTR  R1,R0          DECREMENT * OFFSET BY ONE TO ALLOW FOR    12270020
*                             PERIOD AND RESULT IS LENGTH OF PREFIX.    12300020
         LA    R7,PREFIXNM+D2  POINT AT SAVEAREA FOR PREFIX             12330020
         STH   R1,PREFIXNM    SAVE LENGTH                               12360020
         BCTR  R1,R0          DECREMENT FOR EX OF MVC                   12390020
         EX    R1,MOVE        MOVE PREFIX NAME                          12420020
         LA    R3,D4(R3,R1)    POINT TO SUFFIX PORTION OF NAME          12450020
         LA    R1,D4(R1)       LENGTH OF NAME PRECEDING SUFFIX          12480020
         LA    R4,D1(R4)       TOTAL LENGTH OF NAME                     12510020
         SR    R4,R1          LENGTH OF SUFFIX                          12540020
         LR    R1,R4          COPY OF LENGTH                            12570020
         LA    R7,SUFFIXNM+D2  POINT SAVEAREA FOR SUFFIX                12600020
         STH   R1,SUFFIXNM    STORE LENGTH                              12630020
         BCTR  R1,R0          DECREMENT FOR EX OF MOVE                  12660020
         EX    R1,MOVE        MOVE SUFFIX TO SAVE AREA                  12690020
         B     MAINLINE       GO TO MAINLINE PROGRAM.                   12720020
LEVELER1 MVI   ERR2,SECMSG03      IMPROPER USE OF ASTERISK              12750020
         B     LEVELERR          CONTINUE ERROR PROCESS                 12810020
LEVELER2 MVI   ERR2,SECMSG15      MULTIPLE ASTERISK MSG                 12840020
LEVELERR EQU   *                                                        12900020
         MVI   ERR1,MSG01         IMPROPER USE OF ASRERISK              12930020
         BAL   R8,ERROUT      GO PUT OUT MESSAGE                        13020020
         B     WRAPUP01             TERMINATE ROUTINE                   13080020
NONODE   EQU   *                                                        13110020
*                                                                       13140020
*        GET USERID AND USE IT FOR NODE                                 13170020
*                                                                       13200020
         L     R1,PSCBPTR     GET PSCB PTR                              13230020
         USING PSCB,R1                                                  13260020
         XR    R2,R2          CLEAR REGISTER                            13290020
         IC    R2,PSCBUSRL    GET USERID LENGTH                         13320020
         STH   R2,USRNODEL    SAVE NODE LENGTH                          13350020
         LA    R3,PSCBUSER    POINT AT USERID                           13380020
         LA    R7,USERNODE    POINT AT USERNODE AREA                    13410020
         BCTR  R2,R0          DECREMENT LENGTH FOR EX                   13440020
         EX    R2,MOVE        MOVE USERID                               13470020
         DROP  R1                                                       13500020
MAINLINE EQU   *                                                        13530020
         IKJRLSA PARDSECT                                               13560020
         DROP R10                                                       13590020
         TM    OPTMASK,HISTMEM  SEE IF HISTORY OR MEMBERS IS SPECIFIED  13620020
         BZ    SKIPGETM       NO, SKIP GETMAIN.                         13650020
       EJECT                                                            13680020
*                                                                     * 13710020
*   GETMAIN  ROUTINE FOR MEMBERS AND HISTORY KEYWORD WORK AREAS.      * 13740020
*                                                                     * 13770020
         LA    R1,GETML       ADDR OF GETMAIN PARM LIST                 13800020
         LA    R2,OBTWA       ADDR OF GOTTEN CORE GOES TO OBTWA         13830020
         GETMAIN A=(R2),SP=OSP,LV=OBTWAL,MF=(E,(1))                     13860020
         B     GMRC(R15)       ANALYZE RETURN CODE.                     13890020
GMRC     B     GMOK           CORE REQ SATISFIED                        13920020
         B     GMNOTOK        RETURN CODE=4, NO CORE AVALIABLE          13950020
*                                                                       13980020
GMOK     EQU   *                                                        14010020
         L     R12,OBTWA      ADDR OF CORE JUST GOTTEN                  14040020
         ST    R12,OBTJFCBX   ADDR OF JFCB WORK AREA                    14070020
         LA    R2,OBTDCB      ADD OF DCB IN DSECT                       14100020
         USING IHADCB,R2                                                14130020
         MVC   OBTMACS(LOLFS),OLFS  MOVE MACRO LIST FORMS TO DSECT      14160020
         LA    R15,OBTDCBXL   ADDR OF DCB EXIT LIST                     14190020
         ST    R15,DCBEXLST   SET UP EXIT LIST ADDR                     14220020
         MVI   OBTJFCBX,EXITCD SET JFCB DCB EXIT CODE.                  14250020
         DROP  R2                                                       14280020
         B     SKIPGETM       RETURN GO MAINLINE                        14310020
GMNOTOK  EQU   *                                                        14340020
*                                                                       14370020
*    PREPARE THE GETMAIN ERROR MESSAGE                                  14400020
*                                                                       14430020
*                                                                       14460020
*        GETMAIN FAILED FOR OBTAIN WORK AREA                            14490020
*                                                                       14520020
*                                                                       14550020
         MVI   ERR1,MSG07         NOT ENOUGH CORE MSG                   14580020
         LA    R1,ERRINSRT        PUT IN INSERT POINTER                 14610020
         ST    R1,ERRINST1                                              14640020
         TM    OPTMASK,HISTORY    HISTORY SPECIFIED                     14670020
         BO    CKMEM              YES CHECK MEM                         14700020
         MVC   ERRINSRT+D1(L'NMEMBERS),NMEMBERS                         14730020
         B     JUSTONE            ONE OPTION ON                         14760020
CKMEM    TM    OPTMASK,MEM        MEMBERS ON                            14790020
         BO    BOTHOPTS           USE BOTH ON MSG                       14820020
         MVC   ERRINSRT+D1(L'NHISTORY),NHISTORY                         14850020
JUSTONE  MVI   ERRINSRT,L'NHISTORY    LENGTH OF HISTORY TEXT            14880020
         B     ENDRTN             TURN OFF OPTIONS                      14910020
BOTHOPTS MVC   ERRINSRT+D1(L'NBOTH),NBOTH                               14940020
         MVI   ERRINSRT,L'NBOTH                                         14970020
ENDRTN   NI    OPTMASK,NHISTMEM                                         15000020
         BAL   R8,ERROUT          PUT OUT MSG                           15030020
         EJECT                                                          15060020
SKIPGETM EQU   *                                                        15090020
*********************************************************************** 15120020
*                                                                       15150020
*        INITIALIZE CHAIN ADDRESSES OF CIR BLOCKS AND POINT TO START    15180020
*        OF CHAIN FROM FIRSTBLK LOCATION.                               15210020
*                                                                       15240020
*      BLOCKS ARE OBTAINED DYNAMICALLY AS NEEDED AND ARE KEPT         * 15270020
*      IN THE TABLE UNTIL THE END OF THE PROGRAM WHEN THEY AR FREED.  * 15300020
*                                                                       15330020
*********************************************************************** 15360020
         LA    R1,CIRBLOCK    POINT AT FIRST BLOCK                      15390020
         ST    R1,FRSTBLK    SAVE ADDR OF FIRST CIR BLOCK               15420020
         ST    R1,CURNTBLK    INITIALIZE CURRENT CIR BLOCK PTR          15450020
         XC    ENTPTR(L4,R1),ENTPTR(R1) CLEAR CURRNT ENTRY PT           15480020
         LA    R1,CIRBLOCK+CIRBLKLN LINK FOUR BLOCKS TOGETHER           15510020
         ST    R1,CIRBLOCK    LINK ONE TO TWO                           15540020
         XC    ENTPTR(L4,R1),ENTPTR(R1) CLEAR CRRNT ENTRY PTR           15570020
         LA    R2,CIRBLKLN(R1) LINK BLOCK TWO TO THREE                  15600020
         ST    R2,D0(R1)        STORE PTR                               15630020
         XC    ENTPTR(L4,R2),ENTPTR(R2)   CLEAR CURRENT ENTPTR          15660020
         LA    R1,CIRBLKLN(R2) LINK THREE TO FOUR                       15690020
         ST    R1,D0(R2)        STORE PTR                               15720020
         XC    D0(L8,R1),D0(R1)  CLEAR CHAIN ADDR -CURRENT ENTRY PTR    15750020
*********************************************************************** 15780020
*                                                                       15810020
*        THE FOLLOWING ROUTINE WILL PUT OUT A HEADING LINE IF HISTORY   15840020
*        INFORMATION IS REQUESTED. OTHERWISE ONE LINE IS SKIPPED ON     15870020
*        THE TERMINAL AND CATALOG PROCESSING BEGINS.                    15900020
*                                                                       15930020
*********************************************************************** 15960020
         LA    R7,OUTBUF      POINT AT BUFFER                           15990020
         TM    OPTMASK,HISTORY CHECK FOR HISTORY                        16080020
         BNO   SKIPHDNG       NO, SKIP HEADING                          16110020
         MVC   D0(L'HEADING,R7),HEADING  MOVE HEADING TO BUFFER         16140020
         LA    R14,L'HEADING(R7) POINT AT END OF DATA                   16170020
         BAL   R8,WRITE       GO WRITE IT                               16200020
SKIPHDNG EQU   *                                                        16290020
         TM    OPTMASK,ASTSW  SEE IF * WAS FOUND                        16320020
         BO    GOASTRSK       GO PROCESS ASTERISK                       16350020
         LA    R1,USERNODE    POINT AT NAME TO SEARCH ON                16380020
         ST    R1,CIRINDX     STORE IN PARM LIST                        16410020
         LA    R1,CIRSAVE     CIR SAVE AREA                             16440020
         ST    R1,CIRWK2      STORE IN LIST                             16470020
         XC    CIRVOL,CIRVOL   CLEAR VOLUME PTR                         16500020
MAIN00A  XC    CIRPARM,CIRPARM      CLEAR OPTIONS                       16530020
         TM    OPTMASK,ANYOPT CHECK FOR HISTORY, VOLUMES, MEMBERS       16560020
         BZ    SKIPVOLS       SKIP VOLUMES REQUEST                      16590020
         OI    CIRPARM,CIRVOLS REQUEST VOLUMES                          16620020
SKIPVOLS EQU   *                                                        16650020
         OI    CIRPARM,CIRDSN+CIRIND REQUEST DSNAMES AND INDEX NAMES    16680020
         BAL   R8,OBTBLK      GET FIRST FREE BLK                        16710020
         MVI   FIRSTCIR,ON         TURN ON FIRST CIR SWITCH             16720020
         BAL   R8,CIRROUT     CALL CIR                                  16740020
         LTR   R15,R15        TEST R15 FOR 0                            16770020
         BZ    MAIN00         YES, GO PROCESS                           16800020
         MVI   ERR1,MSG16         NAME NOT INDEX LEVEL                  16807020
         LA    R1,USRNODEL+D1     INSERT NODE LEVEL                     16814020
         ST    R1,ERRINST1        PUT INTO FIRST MSG                    16821020
         BAL   R8,ERROUT      PUT OUT MESSAGE                           16980020
         B     WRAPUP         GO TERMINATE                              17010020
         EJECT                                                          17220020
MAIN00   EQU   *                                                        17250020
*********************************************************************** 17280020
*                                                                       17310020
*        CHECK FOR A NULL LIST AND NOTIFY THE USER IF THE INDEX         17340020
*        STRUCTURE SPECIFIED, OR USERID, HAD NO DATA SETS CATALOGED     17370020
*        UNDER IT.                                                      17400020
*                                                                       17430020
*********************************************************************** 17460020
         L     R1,CURNTBLK   GET CURRENT BLK POINTER                    17490020
         LA    R6,D8(R1)      POINT AT LIST                             17520020
         ST    R6,D4(R1)      MAKE FIRST ENTRY CURRENT                  17550020
         CLI   D0(R6),FOXES    CHECK FOR LINK ENTRY                     17580020
         BNE   MAIN01         NO, PROCESS LIST                          17610020
         CLC   D1(L3,R6),ZERO   SEE IF TTR IS ZERO                      17640020
         BE    NOENTRY        YES, PUT OUT MSG.                         17670020
MORDATA  LA    R1,D4(R6)       POINT AT VOLSER IN LINK ENTRY    SA52087 17700021
         MVC   CIRCVOL(L'CIRCVOL),D0(R1) MOVE CVOL TO SAVE AREA         17730020
         LA    R1,CIRCVOL     POINT AT CVOL                             17760020
         ST    R1,CIRVOL      STORE INTO LIST                           17790020
         LA    R1,D1(R6)       POINT AT TTR                             17820020
         MVC   CIRTTR(L'CIRTTR),D0(R1) MOVE TTR TO SAVE AREA            17850020
         LA    R1,CIRTTR      ADDRESS OF TTR FOR PARM LIST              17880020
         ST    R1,CIRINDX      STORE IN LIST                            17910020
    OI   CIRINDX,ASTSW       TURN ON TTR INDICATOR BIT                  17940020
         B     MAIN00A        TRY AGAIN                                 17970020
NOENTRY  EQU   *                                                        18000020
         MVI   ERR1,MSG03         NO ENTRY FOUND                        18030020
         BAL   R8,ERROUT      PUT OUT MESSAGE                           18120020
         B     WRAPUP         GO TERMINATE                              18150020
*                                                                       18180020
MAIN01   EQU   *                                                        18210020
*********************************************************************** 18240020
*                                                                       18270020
*        ENTRY IS MADE TO THIS ROUTINE WITH REG 6 POINTING TO A NEW     18300020
*        LIST ELEMENT. THE LIST ENTRY IS ANALYZED AND THE APPROPRIATE   18330020
*        ROUTINE IS USED TO PROCESS IT. DSNAME ENTRIES ARE USED TO      18360020
*        COMPLETE FULLY QUALIFIED DATA SET NAMES, AND ARE LISTED ON     18390020
*        THE TERMINAL.                                                  18420020
*                                                                       18450020
*********************************************************************** 18480020
         CLI   D0(R6),DSNENT   DSNAME ENTRY                     SA52087 18510021
         BE    DSNAMRT      YES, GO PROCESS--BUILD FULL DSNAME  SA52087 18540021
*                                                                       18570020
         CLI   D0(R6),VOLENT    DSNAME ENTRY WITH VOLUMES       SA52087 18600021
         BE    DSNAMRT       YES, GO PROCESS--BUILD FULL DSNAME SA52087 18630021
*                                                                       18660020
         CLI   D0(R6),VCBENT   VOLUME CONTROL BLOCK ENTRY               18690020
         BE    VCBROUT        YES, GO PROCESS--BUILD FULL DSNAME        18720020
*                                                                       18750020
         CLI   D0(R6),INDENT   INDEX ENTRY                              18780020
         BE    INDEXRT        YES, GO PROCESS-GET A NEW LIST            18810020
*                                                                       18840020
         CLI   D0(R6),GDGENT   GENERATION DATA GROUP ENTRY              18870020
         BE    GDGROUT        YES, GO PROCESS SIMPLE NAMES              18900020
         CLI   D0(R6),FOXES       CHECK FOR LINK ENTRY          SA52087 18910021
         BNE   MAIN01A            PROCESS NORMALLY              SA52087 18920021
         CLC   D1(L3,R6),ZERO     SEE IF TTR IS ZERO            SA52087 18922021
         BE    WRAPUP             GO TERMINATE                  SA52087 18924021
         B     MORDATA            MORE DATA TO BE PROCESSED     SA52087 18926021
*                                                                       18930020
MAIN01A  EQU   *                                                        18960020
         BAL   R8,POINTER     GO UPDATE CURRENT ENTRY POINTER TO NEXT.  18990020
         L     R6,CURNTBLK    GET CURRENT BLOCK POINTER                 19020020
         L     R6,D4(R6)       GET CURRENT ENTRY POINTER                19050020
         B     MAIN01         GO ANALYZE ENTRY TYPE.                    19080020
       EJECT                                                            19110020
INDEXRT  DS    0H                                                       19140020
*********************************************************************** 19170020
*                                                                       19200020
*        THIS ROUTINE GETS CONTROL WHEN AN INDEX ENTRY IS DISCOVERED    19230020
*        IN THE LIST FROM CIR. IT SETS UP A PARAMETER LIST FOR CIR      19260020
*        AND USES OBTBLK TO ALLOCATE ANOTHER BLOCK FOR A NEW LIST       19290020
*        OF LOWER QUALIFIERS. IF THE NEW LIST IS FOUND TO BE EMPTY,     19320020
*        AN INFORMATIONAL MESSAGE IS PUT OUT TO THE TERMINAL INFORMING  19350020
*        THE USER THAT THIS IS AN EMPTY INDEX STRUCTURE. OTHERWISE      19380020
*        THE NEW LIST IS MADE CURRENT.                                  19410020
*              CURNTBLK POINTS TO CURRENT CIR LIST                      19440020
*                                                                       19470020
*********************************************************************** 19500020
         XC    CIRPARM,CIRPARM  CLEAR CIR OPTIONS                       19530020
         LA    R1,TTROFF(R6)       POINT AT TTR FIELD IN INDEX ENTRY    19560020
         ST    R1,CIRINDX     STORE IN CIRPARM LIST                     19590020
         OI    CIRINDX,HIGHBIT  TURN ON HIGH BIT EQUALTTR               19620020
         L     R1,CURNTBLK    GET CURNT BLOCK ADDRESS                   19650020
         LA    R1,CIRVOLID+VOLENT(R1) POINT PAST CHAIN ADDRS TO VOLSER  19680020
*                                AT END OF CIR LIST.                    19710020
         ST    R1,CIRVOL     PUT PTR IN PARM LIST                       19740020
IND00A   TM    OPTMASK,ANYOPT CHECK FOR HISTORY, VOLUMES, MEMBERS       19770020
         BZ    IND00          NONE, SKIP VOLUMES REQUEST                19800020
         OI    CIRPARM,CIRVOLS REQUEST VOLUMES                          19830020
IND00    EQU   *                                                        19860020
         OI    CIRPARM,CIRDSN+CIRIND REQUEST DSNAMES AND INDEXNAMES     19890020
         BAL   R8,OBTBLK      GET FIRST FREE BLOCK                      19920020
         BAL   R8,CIRROUT     CALL CIR                                  19950020
         LTR   R15,R15        TEST RETURN CODE                          19980020
         BNZ   CIR08          NONZERO, LET CIRROUT HANDLE ERROR         20010020
*                                                                       20040020
*        CHECK FOR EMPTY INDEX STRUCTURE                                20070020
*                                                                       20100020
         L     R1,CURNTBLK    GET ADDR OF NEW BLOCK                     20130020
         LA    R6,D8(R1)       POINT AT FIRST ENTRY                     20160020
         ST    R6,D4(R1)       MAKE IT CURRENT ENTRY                    20190020
         CLI   D0(R6),FOXES     CHECK FOR LINK ENTRY                    20220020
         BNE   MAIN01         NO, GO PROCESS LIST                       20250020
         CLC   D1(D3,R6),ZERO   SEE IF TTR IS ZERO                      20280020
         BE    EMPTYIND       YES, IT IS AN EMPTY INDEX                 20310020
         LA    R1,D4(R6)       POINT AT VOLSER IN LINK ENTRY            20340020
         ST    R1,CIRVOL       PUT INTO CIR PARM LIST                   20370020
         LA    R1,D1(R6)       POINT AT TTR                             20400020
         ST    R1,CIRINDX      STORE INTO LIST                          20430020
         OI    CIRINDX,ASTSW INDICATE TTR ENTRY                         20460020
         XC    CIRPARM,CIRPARM  CLEAR OPTION BYTES                      20490020
         B     IND00A         TRY AGAIN                                 20520020
EMPTYIND EQU   *                                                        20550020
         XC    D4(L4,R1),D4(R1) FREE CURRENT BLK                        20580020
         MVI   ERR1,MSG05         EMPTY INDEX FOUND                     20610020
         B     OBTBLK45       USE OBTBLK ERROR ROUTINE TO BUILD NAME    20700020
       EJECT                                                            20730020
DSNAMRT  DS    0H                                                       20760020
VCBROUT  DS    0H                                                       20790020
*********************************************************************** 20820020
*                                                                       20850020
*        THIS ROUTINE IS GIVEN CONTROL WHEN A DATA SET ENTRY OR         20880020
*        VOLUME CONTROL BLOCK ENTRY IS FOUND IN THE LIST FROM CIR.      20910020
*        A CHECK IS MADE TO DETERMINE IF A GENERATION DATA GROUP IS     20940020
*        BEING PROCESSED. IF SO, THE GENERATION PORTION OF THE SIMPLE   20970020
*        NAME MUST BE COMPLEMENTED. THEN THE FULLY QUALIFIED NAME,      21000020
*        WITHOUT THE PORTION PRECEDING THE NODE, IS CONSTRUCTED AND     21030020
*        PUT TO THE TERMINAL. ANY KEYWORDS SPECIFIED ARE THEN           21060020
*        PROCESSED IN THE APPROPRIATE ROUTINES.                         21090020
*              REG 6 POINTS TO CURRENT ENTRY                            21120020
*                                                                       21150020
*********************************************************************** 21180020
*  CHECK FOR GENERATION DATA GROUP DATA SET NAME                        21182020
         CLI   D1(R6),CHARG        TEST FOR A G                         21190020
         BNE   GDGTEST             NO, CONTINUE                         21200020
         CLI   D6(R6),CHARV        TEST FOR A V                         21202020
         BNE   GDGTEST             NO, CONTINUE                         21204020
         LA    R1,FOURB            SET LOOP CONTROL                     21206020
GDGLOOP  LA    R7,D0(R1,R6)        POINT TO CHARACTER TO BE TESTED      21208020
         TM    D1(R7),COMPZONE     TEST FOR COMPLEMENTED NUMBER         21208420
         BNZ   GDGTEST             NOT COMPLEMENT, CONTINUE             21208820
         BCT   R1,GDGLOOP          YES, CHECK NEXT CHARACTER            21209220
         XC    D2(L4,R6),FOXMASK   COMPLEMENT GENERATION NUMBER  A48474 21209621
GDGTEST  TM    OPTMASK,GDGSW  SEE IF GDG SWITCH IS ON                   21210020
         BNO   DSN01          NO, SKIP COMPLEMENT                       21240020
         L     R1,GDGCNT      GET NUMBER OF DATASETS REMAINING          21420020
         BCT   R1,DSN01A      DECREMENT COUNT                           21450020
         NI    OPTMASK,GDGSWOFF   TURN OFF GDGSW                        21480020
DSN01A   ST    R1,GDGCNT      SAVE UPDATED COUNT                        21510020
DSN01    EQU   *                                                        21540020
         LA    R1,OUTBUF      POINT AT BUFFER                           21570020
         BAL   R8,BUILDNAM    USE PORTION OF OBTBLK ROUTINE TO BUILD    21600020
*                             DSNAME                                    21630020
         MVI   TEMPNAME,BLANK    BLANK OUT NAME AREA                    21660020
         MVC   TEMPNAME+D1(L'TEMPNAME-D1),TEMPNAME                      21690020
         LA    R7,TEMPNAME    POINT TO TEMPORARY AREA                   21720020
         LR    R14,R1         R1 POINTS AT END OF NAME IN BUFFER        21750020
         LH    R2,USRNODEL    GET NODE LENGTH                           21780020
         LA    R3,USERNODE    POINT AT NODE                             21810020
         BCTR  R2,R0          DECREMENT FOR MOVE                        21840020
         EX    R2,MOVE        MOVE NODE TO TEMPSAVE                     21870020
         LA    R7,D1(R2,R7)    POINT BEYOND NODE                        21900020
         MVI   D0(R7),PERIOD     PUT PERIOD SEPARATER AFTER NODE        21930020
         LA    R7,D1(R7)       BUMP POINTER                             21960020
         LA    R2,OUTBUF      POINT AT START OF BUFFER                  21990020
         LR    R3,R2          SAVE ADDRESS OF NAME                      22020020
         SR    R1,R2          CALCULATE LENGTH OF NAME IN BUFFER        22050020
         BCTR  R1,R0          DECREMENT FOR MOVE                        22080020
         EX    R1,MOVE        MOVE REMAINDER OF NAME TO TEMPSAVE        22110020
         LA    R7,D1(R1,R7)    POINT BEYOND NAME                        22140020
         LA    R1,TEMPNAME   POINT AT START OF AREA CONTAINING NAME     22170020
         SR    R7,R1          CALCULATE LENGTH OF NAME                  22200020
         STH   R7,CURNTNAM    SAVE IT                                   22230020
         LA    R7,OUTBUF      POINT AT BUFFER                           22260020
         BAL   R8,WRITE       GO WRITE THE NAME                         22290020
*                                                                       22320020
*        CHECK TO SEE WHICH KEYWORDS WERE SPECIFIED AND GIVE CONTROL    22350020
*        TO THE APPROPRIATE PROCESSING ROUTINES                         22380020
*                                                                       22410020
OPTCHK00 EQU   *                                                        22440020
         TM    OPTMASK,HISTMEM  SEE IF HISTORY OR MEMBERS REQUEST       22470020
         BZ    OPTCHK01       NO, CHECK VOLUMES                         22500020
         BAL   R8,DSOBTAIN    GET DSCB FOR CURRENT DATA SET             22530020
         TM    OPTMASK,HISTORY CHECK FOR HISTORY                        22560020
         BNO   OPTCHK01       NO, CHECK NEXT OPTION                     22590020
         L     R15,VCONHIST   GET ADDR OF HISTORY ROUTINE               22620020
         BALR  R14,R15        GO PROCESS HISTORY                        22650020
*                                                                       22680020
OPTCHK01 TM    OPTMASK,VOLUMES  WAS VOLUMES SPECIFIED                   22710020
         BNO   OPTCHK02       NO, CHECK NEXT OPTION                     22740020
         L     R15,VCONVOL    GET ADDR OF VOLUMES ROUTINE               22770020
         BALR  R14,R15        GO PROCESS VOLUMES                        22800020
*                                                                       22830020
OPTCHK02 TM    OPTMASK,MEM    WAS MEMBERS SPECIFIED                     22860020
         BNO   OPTCHK03       NO, END OF OPTIONS                        22890020
         L     R15,VCONMEM    GET ADDRESS OF MEMBERS ROUTINE            22920020
         BALR  R14,R15        GO PROCESS MEMBERS                        22950020
OPTCHK03 EQU   *                                                        23070020
         LA    R7,OUTBUF      POINT AT BUFFER                           23100020
         TM    OPTMASK,ASTSW  SEE IF ASTERISK FUNCTION IS INVOKED       23190020
         BO    ASTRSKNX       PROCESS NEXT NAME.                        23220020
         B     MAIN01A        PROCESS NORMALLY                          23250020
         EJECT                                                          23280020
GDGROUT  DS    0H                                                       23310020
*********************************************************************** 23340020
*                                                                       23370020
*        THIS ROUTINE IS ENTERED IF A GDG ENTRY IS FOUND IN THE CIR     23400020
*        LIST. IT TURNS ON THE GDGSW SWITCH SO THAT THE DSNAME ENTRY    23430020
*        ROUTINE WILL KNOW THAT THE GENERATION NUMBER IN THE SIMPLE     23460020
*        NAMES WILL REQUIRE COMPLEMENTING. A CHECK IS MADE TO SEE       23490020
*        IF ANY GENERATIONS EXIST. IF NOT, A MESSAGE IS ISSUED TO       23520020
*        INFORM THE USER THAT THE GROUP IS EMPTY. IF IT IS NOT EMPTY    23550020
*        THE COUNT IS KEPT AND DECREMENTED EACH TIME A GENERATION       23580020
*        NAME IS PROCESSED. CONTROL IS PASSED TO THE INDEX ENTRY        23610020
*        ROUTINE TO READ IN THE LIST OF NAMES THROUGH CIR.              23640020
*                                                                       23670020
*              REG 6 POINTS TO CURRENT ENTRY                            23700020
*                                                                       23730020
*********************************************************************** 23760020
         XR    R1,R1          CLEAR REG FOR IC                          23790020
         IC    R1,D14(R6)      COUNT IS LAST 2 BYTES OF ENTRY-GET FIRST 23820020
         SLL   R1,L8           SHIFT FIRST BYTE OVER                    23850020
         IC    R1,D15(R6)      GET SECOND CHARCTER                      23880020
         LTR   R1,R1          IS COUNT ZERO                             23910020
         BZ    GDG01          YES, PUT OUT MESSAGE                      23940020
         ST    R1,GDGCNT      NO, SAVE COUNT                            23970020
         OI    OPTMASK,GDGSW  TURN ON GDG SWITCH                        24000020
         B     INDEXRT        GO GET LIST FROM CIR                      24030020
GDG01    EQU   *                                                        24060020
         MVI   ERR1,MSG06         EMPTY GDG STRUCTURE                   24090020
         B     OBTBLK45           PUT OUT MSG                           24150020
         EJECT                                                          24450020
WRAPUP   DS    0H                                                       24480020
*********************************************************************** 24510020
*                                                                       24540020
*        THIS ROUTINE GETS CONTROL WHEN THE LISTING IS COMPLETE OR      24570020
*        AN ERROR RESULTING IN TERMINATION OCCURS. IT FREES ALL         24600020
*        DYNAMIC CORE OBTAINED AND DELETES ANY MODULES THAT WERE        24630020
*        LOADED.                                                        24660020
*                                                                       24690020
*********************************************************************** 24720020
         L     R1,FRSTBLK     GET PTR TO FIRST CIR BLOCK                24750020
         LA    R2,CIRBLKLN*3  OFFSET TO LAST INITIAL BLOCK              24780020
         LA    R2,D0(R1,R2)    PTR TO LAST INITIAL BLOCK                24810020
         L     R1,D0(R2)       PICK UP CHAIN PTR                        24840020
WRAPUP00 C     R1,ZERO        IS IT ZERO                                24870020
         BE    WRAPUP01       YES, ALL EXTRA BLOCKS ARE FREED           24900020
         L     R2,D0(R1)      CHAIN PTR TO NEXT                         24930020
         FREEMAIN R,LV=CIRBLKLN,A=(1),SP=BLKSP                          24960020
         LR    R1,R2            COPY CHAIN PTR                          24990020
         B     WRAPUP00       GO CHECK NEXT PTR                         25020020
WRAPUP01 EQU   *                                                        25050020
WRAPUP02 EQU   *                                                        25230020
*  NOW CHECK IF AN ERROR HAS OCCURRED.  IF SO, THE STACK MUST BE        25240020
*  FLUSHED AND THE INPUT QUEUE CLEARED.                                 25250020
         CLI   STACKSW,SWON        IS STACK SWITCH ON                   25252020
         BNE   STACKOK             NO ERROR, END NORMALLY               25254020
         LA    R1,UPTPTR           POINT TO I/O PARAMETER LIST          25256020
         LA    R2,STACKPRM         POINT TO STACK PARM BLOCK            25258020
         ST    R2,PUTLADDR         POINT TO STACK PARM BLOCK            25258420
         STACK DELETE=ALL,MF=(E,(1)) FLUSH STACK                        25258820
         TCLEARQ INPUT             CLEAR ANYTHING TYPED AHEAD           25259220
STACKOK  EQU   *                   NORMAL RETURN FROM HERE              25259620
         L    R15,RETCD                                                 25260020
         L     R13,D4(R13)     RESTORE ADDR OF CALLERS WORK AREA.       25290020
         RETURN (14,12),T,RC=(15)                                       25380020
         EJECT                                                          25410020
GOASTRSK DS    0H                                                       25440020
*********************************************************************** 25470020
*                                                                       25500020
*        THIS ROUTINE GETS CONTROL IF AN ASTERISK (*) IS FOUND          25530020
*        VALIDLY IMBEDDED IN THE STRUCTURE SPECIFIED WITH THE LEVEL     25560020
*        KEYWORD PARAMETER. IT GETS A LIST OF POSSIBLE QUALIFIERS       25590020
*        BY GOING TO CIR WITH THE SUFFIX NAME, THAT PORTION FOUND       25620020
*        PRECEDING THE *, AS A NODE FOR THE CATALOG SEARCH. EACH        25650020
*        QUALIFIER RETURNED IN THE LIST IS INSERTED INTO THE STRUCTURE  25680020
*        AND A LOCATE IS ISSUED TO SEE IF IT IS FULLY QUALIFIED         25710020
*        OR NOT. IF LOCATE IS SUCCESSFUL, IT IS A WINNER OTHERWISE      25740020
*        THE NEXT QUALIFIER IS TRIED.                                   25770020
*                                                                       25800020
*********************************************************************** 25830020
         LA    R7,TEMPNAME    POINT AT TEMPORARY NAME AREA              25860020
         LA    R3,PREFIXNM+D2  POINT AT PREFIX NAME                     25890020
         LH    R1,PREFIXNM   GET LENGTH OF NAME                         25920020
         BCTR  R1,R0          DECREMENT FOR MOVE                        25950020
         EX    R1,MOVE        MOVE PREFIX TO TEMPNAME                   25980020
         LA    R2,D1(R1,R7)    POINT BEYOND NAME                        26010020
         MVI   D0(R2),BLANK    BLANK NEXT BYTE                          26040020
         LA    R1,CIRSAVE     SAVE AREA FOR CIR                         26070020
         ST    R1,CIRWK2      PUT IN LIST                               26100020
         ST    R7,CIRINDX      PTR TO PREFIX NAME                       26130020
         L     R1,FRSTBLK     FIRST BLOCK ADDRESS                       26160020
         LA    R1,D8(R1)       BUMP ADDRESS PAST LINK FIELDS            26190020
         ST    R1,CIRWK1       PUT INTO LIST                            26220020
         XC    CIRVOL,CIRVOL  CLEAR VOL PTR                             26250020
ASTRSK00 XC    CIRPARM,CIRPARM  CLEAR OPTIONS                           26280020
         OI    CIRPARM,CIRIND      INDEX OPTION CODE                    26310020
         BAL   R8,CIRROUT     GO CALL CIR                               26340020
         LTR   R15,R15        TEST RETURN CODE                          26370020
         BZ    ASTRSK01       ZERO, CHECK NULL LIST                     26400020
         MVI   ERR1,MSG01         LEVEL NOT SPECIFIED CORRECTLY         26430020
         MVI   ERR2,SECMSG06      INVALID PREFIX                        26470020
         BAL   R8,ERROUT      PUT OUT MSG                               26580020
         B     WRAPUP         GO TERMINATE                              26610020
ASTRSK01 EQU   *                                                        26640020
*                                                                       26670020
*        CHECK FOR A NULL LIST                                          26700020
*                                                                       26730020
         L     R5,FRSTBLK     GET POINTER TO BLOCK                      26760020
         LA    R6,D8(R5)       POINT PAST CHAIN ADDRESS TO FIRST ENTRY  26790020
         ST    R6,D4(R5)       UPDATE CURRENT ENTRY POINTER             26820020
         CLI   D0(R6),FOXES    CHECK FOR LINK ENTRY                     26850020
         BNE   ASTRSK02       GO PROCESS LIST IF NOT LINK               26880020
         CLC   D1(D3,R6),ZERO   SEE IF TTR IS ZERO                      26910020
         BE    NOENTRY        YES, GO PUT OUT MSG AND TERMINATE         26940020
         LA    R1,D4(R6)       POINT AT VOLSER IN LINK ENTRY            26970020
         MVC   CIRCVOL(L'CIRCVOL),D0(R1) MOVE CVOL TO SAVE AREA         27000020
         LA    R1,CIRCVOL     ADDRESS OF CVOL                           27030020
         ST    R1,CIRVOL       PUT INTO LIST                            27060020
         LA    R1,D1(R6)       POINT AT TTR                             27090020
         MVC   CIRTTR(L'CIRTTR),D0(R1) MOVE TTR TO SAVE AREA            27120020
         LA    R1,CIRTTR      ADDRESS OF TTR                            27150020
         ST    R1,CIRINDX     PUT INTO LIST                             27180020
         OI    CIRINDX,ASTSW  TURN ON TTR INDICATOR BIT                 27210020
         B     ASTRSK00       GO TRY AGAIN                              27240020
ASTRSK02 EQU   *                                                        27270020
*                                                                       27300020
*        PROCESS THE LIST OF QUALIFIERS BY TRYING EACH ONE TO SEE IF    27330020
*        IT RESULTS IN A FULLY QUALIFIED DSNAME.                        27360020
*                                                                       27390020
         LH    R1,PREFIXNM    GET LENGTH OF PREFIX NAME                 27420020
         LA    R7,TEMPNAME    POINT AT TEMPORARY AREA                   27450020
         LA    R7,D0(R1,R7)    PREFIX IS ALREADY THERE, POINT BEYOND    27480020
         MVI   D0(R7),BLANK    CLEAR REMAINING BYTES OF BUFFER          27510020
         LA    R2,FORTY2      LENGTH OF AREA MINUS TWO BYTES            27540020
         SR    R2,R1          CALCULATE AMOUNT LEFT TO CLEAR            27570020
         EX    R2,CLEAR       CLEAR AREA                                27600020
         MVI   D0(R7),PERIOD     PUT PERIOD AFTER NAME                  27630020
         LA    R7,D1(R7)       BUMP POINTER                             27660020
         MVC   D0(L8,R7),D1(R6)  MOVE QUALIFIER TO TEMPNAME             27690020
         LA    R7,D8(R7)       POINT PAST NAME                          27720020
ASTRSK03 BCTR  R7,R0          BACK UP ONE BYTE, TRUNCATE BLANKS         27750020
         CLI   D0(R7),BLANK  IS IT A BLANK                              27780020
         BE    ASTRSK03       YES, TRY NEXT                             27810020
         MVI   D1(R7),PERIOD     PUT A PERIOD OVER FIRST BLANK          27840020
         LA    R7,D2(R7)       BUMP POINTER BEYOND PERIOD               27870020
         LH    R1,SUFFIXNM    GET LENGTH OF SUFFIX                      27900020
         LA    R3,SUFFIXNM+D2  POINT AT SUFFIX NAME                     27930020
         BCTR  R1,R0          DECREMENT COUNT FOR MOVE                  27960020
         EX    R1,MOVE        MOVE SUFFIX                               27990020
         LA    R7,D1(R1,R7)    POINT AT END OF NAME                     28020020
         LA    R1,TEMPNAME                                              28050020
         LR    R2,R7          SAVE PTR                                  28080020
         SR    R2,R1          CALCULALTE LENGTH OF NAME                 28110020
         LA    R1,MAXLEN      GET MAXIMUM DSNAME LENGTH                 28140020
         CR    R2,R1          COMPARE                                   28170020
         BH    ASTRSKNX       IF HIGH, PROCESS NEXT ENTRY               28200020
         STH   R2,CURNTNAM    SAVE LENGTH OF NAME               SA58901 28230021
*        GO TO CIR WITH THE NAME                                        28260020
*                                                                       28290020
         XC    CIRPARM,CIRPARM  CLEAR OPTIONS                           28320020
         OI    CIRPARM,CIRVOLS     SET VOLUMES OPTION                   28350020
         LA    R1,TEMPNAME     POINT AT CURRENT NAME BEING PROCESSED    28380020
         ST    R1,CIRINDX       PUT IN LIST                             28410020
         L     R1,FRSTBLK     FIRST BLOCK ADDRESS                       28440020
         L     R1,D0(R1)       GET SECOND BLOCK                         28470020
         LA    R1,D8(R1)       BUMP ADDRESS PAST LINK FIELDS            28500020
         ST    R1,CIRWK1      STORE IN LIST                             28530020
         XC    CIRVOL,CIRVOL  CLEAR VOLID SLOT                          28560020
         LA    R1,CIRPARM     PARM LIST FOR CALL MACRO                  28590020
         L     R15,CIRAD     ADDR OF CIR EP                             28620020
         CALL  (15)                                                     28650020
         LTR   R15,R15        TEST RETURN CODE                          28680020
         BNZ   ASTRSKNX       NOT ZERO, SELECT ANOTHER QUALIFIER        28710020
         LA    R7,OUTBUF      POINT TO BUFFER                           28740020
         LA    R3,TEMPNAME    POINT TO NAME                             28770020
         BCTR  R2,R0          DECREMENT FOR EX OF MVC                   28800020
         EX    R2,MOVE        MOVE NAME TO BUFFER                       28830020
         LA    R14,D1(R2,R7)   POINT AT END OF NAME                     28860020
         BAL   R8,WRITE       WRITE THE NAME                            28890020
         OI    OPTMASK,WRITESW  INDICATE A NAME WAS WRITTEN             28920020
         B     OPTCHK00       GO CHECK FOR OPTIONAL KEYWORDS            28950020
ASTRSKNX EQU   *                                                        28980020
*        CHECK TO SEE IF MORE ENTRIES ARE TO BE PROCESSED-GET NEXT      29010020
*        BLOCK OF QUALIFIERS IF NECESSARY.                              29040020
*                                                                       29070020
         L     R1,FRSTBLK     GET FIRST BLOCK                           29100020
         L     R6,D4(R1)       GET CURRENT ENTRY PTR                    29130020
         LA    R6,INDLEN(R6)  BUMP PTR TO NEXT ENTRY                    29160020
         ST    R6,D4(R1)       SAVE ENTRY PTR                           29190020
ASTRSKAG CLI   D0(R6),FOXES    CHECK FOR LINK ENTRY                     29220020
         BNE   ASTRSK02       NO, GO PROCESS LIST                       29250020
         CLC   D1(D3,R6),ZERO   SEE IF LINK TTR IS ZERO                 29280020
         BNE   ASTRSK04       NO, GO GET NEXT BLOCK                     29310020
         TM    OPTMASK,WRITESW SEE IF ANY NAMES WERE FOUND              29340020
         BNO   NOENTRY        NO, GO GIVE MESSAGE AND TERMINATE         29370020
         B     WRAPUP         OTHERWISE, JUST TERMINATE                 29400020
ASTRSK04 EQU   *                                                        29430020
         LA    R1,D4(R6)       GET VOLSER ADDR (OF CATAOG)              29460020
         MVC   CIRCVOL(L'CIRCVOL),D0(R1) MOVE CVOL TO SAVE AREA         29490020
         LA    R1,CIRCVOL     ADDRESS OF CVOL                           29520020
         ST    R1,CIRVOL       PUT INTO LIST                            29550020
         LA    R1,D1(R6)       POINT AT TTR                             29580020
         MVC   CIRTTR(L'CIRTTR),D0(R1) MOVE TTR TO SAVE AREA            29610020
         LA    R1,CIRTTR      ADDRESS OF TTR                            29640020
         ST    R1,CIRINDX      STORE INTO LIST                          29670020
         OI    CIRINDX,ASTSW  INDICATE TTR                              29700020
         L     R1,FRSTBLK     GET PTR TO FIRST BLK                      29730020
         LA    R1,D8(R1)       POINT TO CIR LIST AREA                   29760020
         ST    R1,CIRWK1       PUT IT INTO LIST                         29790020
         XC    CIRPARM,CIRPARM  CLEAR OPTIONS                           29820020
         OI    CIRPARM,CIRIND SET INDEX OPTION                          29850020
         BAL   R8,CIRROUT     GO CALL CIR                               29880020
         LTR   R15,R15        TEST RETURN CODE                          29910020
         BNZ   CIR08          NONZERO, LET CIRROUT HANDLE IT            29940020
         L     R1,FRSTBLK     GET ADDR OF FIRST BLOCK                   29970020
         LA    R6,D8(R1)       POINT AT FIRST ENTRY IN LIST             30000020
         ST    R6,D4(R1)       SAVE IT AS CURRENT                       30030020
         B     ASTRSKAG       PROCESS LIST                              30060020
         EJECT                                                          30090020
DSOBTAIN DS    0H                                                       30120020
*********************************************************************** 30150020
*                                                                       30180020
*        THIS ROUTINE IS ENTERED IF EITHER THE HISTORY OR MEMBERS       30210020
*        KEYWORDS WERE SPECIFIED. IT OBTAINS THE DSCB AND PLACES IT     30240020
*        IN THE OBTWA WORKAREA. THE FULLY QUALIFIED NAME TO BE USED     30270020
*        IS IN TEMPSAVE. IF THE ASTERISK SWITCH IS ON, A VOLUME LIST    30300020
*        IS AVAILABLE IN THE SECOND CIR BLOCK.IF NOT, REG 6 POINTS      30330020
*        TO THE CURRENT ENTRY WHICH WILL PROVIDE THE VOLSER.            30360020
*                                                                       30390020
*********************************************************************** 30420020
         LA    R1,TEMPNAME    GET PTR TO DSNAME                         30450020
         ST    R1,OBTDSN       PUT INTO OBTAIN LIST                     30480020
         LA    R1,OBTWORKA    PTR TO OBTAIN WORKAREA                    30510020
         ST    R1,OBTWKA      PUT IN LIST                               30540020
*                                                                       30570020
*        GET VOLSER POINTER FOR OBTAIN LIST                             30600020
*                                                                       30630020
         TM    OPTMASK,ASTSW  ASTERISK SWITCH ON                        30660020
         BNO   DSOBTCHK       GO CHECK ENTRY TYPE                       30690020
         L     R1,FRSTBLK     POINT AT FIRST BLOCK                      30720020
         L     R1,D0(R1)       GET SECOND BLOCK                         30750020
         LA    R1,D8(R1)       POINT AT CIR LIST AREA                   30780020
DSOBTGO  LA    R1,D6(R1)       POINT AT FIRST VOLSER IN LIST            30810020
         ST    R1,OBTVOL       PUT ADDR IN LIST                         30840020
         OBTAIN OBTCLST                                                 30870020
         B     OBTCODE(R15)   ANALYZE RETURN CODE                       30900020
*                                                                       30930020
OBTCODE  BR    R8             RC=00 OK                                  30960020
         ORG   *+2            SET COUNTER TO ALLOW FOR SHORT INST       30990020
         B     OBT04          RC=04 VOL NOT MOUNTED OR NOT DA           31020020
         B     OBT08          RC=08 DSCB NOT FOUND                      31050020
         B     OBT12          RC=12 I/O ERROR DURING OBTAIN             31080020
         B     OBT16          RC=16 ERROR IN OBTAIN WORK AREA           31110020
         B     OBT20          RC=20 DSCB OUT OF VTOC EXTENTS            31140020
*                                                                       31170020
OBT04    EQU   *                                                        31200020
         MVI   ERR2,SECMSG22       SECOND LEVEL MESSAGE 22              31240020
         B     OBTERRGO            OBTAIN ERROR RTN                     31260020
OBT08    EQU   *                                                        31290020
         MVI   ERR2,SECMSG10       SECOND LEVEL MESSAGE 10              31330020
         B     OBTERRGO            PUT OUT MESSAGE                      31350020
OBT12    EQU   *                                                        31380020
OBT16    EQU   *                                                        31410020
OBT20    EQU   *                                                        31440020
         BAL   R8,CVDREG15        CONVERT CODE                          31450020
         MVI   ERR2,SECMSG17       SECOND LEVEL MESSAGE 17              31460020
OBTERRGO EQU   *                                                        31500020
         TM    OPTMASK,HISTORY   SEE IF HISTORY WAS REQUESTED           31560020
         BNO   OBTMEMER            PUT OUT MEMBER FAILED                31590020
         TM    OPTMASK,MEM        MEMBERS OPTION ON                     31596020
         BNO   OBTHIST            ONLY HISTORY                          31602020
         MVI   ERRINSRT,L'NBOTH    LENGTH OF INSERTION           A49872 31604021
         MVC   ERRINSRT+D1(L'NBOTH),NBOTH MOVE INSERTION         A49872 31606021
         B     OBTMEMGO            PUT OUT MESSAGE               A49872 31614021
OBTHIST  MVI   ERRINSRT,L'NHISTORY LENGTH OF INSERTION           A49872 31616021
         MVC   ERRINSRT+D1(L'NHISTORY),NHISTORY MOVE INSERTION    M2139 31626021
         B     OBTMEMGO            PUT OUT MESSAGE               A49872 31650021
OBTMEMER MVI   ERRINSRT,L'NMEMBERS LENGTH OF INSERTION           A49872 31660021
         MVC   ERRINSRT+D1(L'NMEMBERS),NMEMBERS MOVE INSERTION   A49872 31710021
OBTMEMGO MVI   ERR1,MSG08          MESSAGE 8                     A49872 31740021
         LA    R15,ERRINSRT        ADDRESS OF INSERTION-         A49872 31790021
         ST    R15,ERRINST1        TO PARAMETER LIST             A49872 31800021
         BAL   R8,ERROUT      SO PUT OUT MESSAGE                        31830020
         TM    OPTMASK,VOLUMES  WAS VOLUMES REQUESTED                   31860020
         BNO   OPTCHK03       NO, PROCESS NEXT ENTRY                    31890020
         L     R15,VCONVOL    GET ADDRESS OF VOLROUT                    31920020
         BALR  R14,R15        GO OUTPUT VOLUMES                         31950020
         B     OPTCHK03       SELECT NEXT ENTRY                         31980020
DSOBTCHK EQU   *                                                        32010020
*                                                                       32040020
*        SEE IF IT IS A VOLUME DSNAME ENTRY OR A VOLUME CONTROL BLOCK   32070020
*        ENTRY                                                          32100020
*                                                                       32130020
         TM    D0(R6),VOLENT   VOLUMES DSNAME ENTRY                     32160020
         BNO   DSOBTVCB       NO, GO PROCESS VCB ENTRY                  32190020
         LA    R1,DSNLEN(R6)    POINT AT VOLSER LIST                    32220020
         B     DSOBTGO             DO OBTAIN ON VOL SER                 32250020
DSOBTVCB EQU   *                                                        32280020
         LA    R1,DSNLEN(R6)  POINT AT TTR                              32310020
         ST    R1,CIRINDX    PUT IN LIST                                32340020
         OI    CIRINDX,ASTSW  INDICATE TTR                              32370020
         XC    CIRPARM,CIRPARM  CLEAR OPTIONS                           32400020
         OI    CIRPARM,CIRVOLS  SET ON VOLUMES REQUEST                  32430020
         L     R1,CURNTBLK    GET CURRENT BLOCK                         32460020
         LA    R1,D8(R1)       POINT AT CIR LIST PORTION                32490020
         LA    R1,CIRVOLID(R1)  POINT AT VOLSER                         32520020
         ST    R1,CIRVOL        SAVE IT IN LIST FOR CIR                 32550020
         LA    R1,VOLBLK      POINT TO THE BLOCK TO HOLD VOLUMES        32580020
         ST    R1,CIRWK1       PUT IN LIST                              32610020
         LR    R7,R8          SAVE CALLERS RETURN ADDRESS               32640020
         BAL   R8,CIRROUT     GO CALL CIR                               32670020
         LTR   R15,R15        CHECK FOR RC IN REG 15                    32700020
         BNZ   CIR08          NONZERO, LET CIRROUT HAVE IT              32730020
         LR    R8,R7          GET CALLERS ADDRESS                       32760020
         LA    R1,VOLBLK      POINT AT VOLUME LIST                      32790020
         B     DSOBTGO        GO PROCESS IT                             32820020
        DROP   R13                                                      32850020
*                                                                       32880020
       EJECT                                                            32910020
IKJEHHST CSECT                                                          32970020
*********************************************************************** 33030020
*                                                                     * 33060020
*        THIS ROUTINE COLLECTS INFORMATION FOR THE HISTORY OPTION     * 33090020
*        AND FORMATS IT IN THE OUTPUT BUFFER. THE INFORMATION IS      * 33120020
*        OBTAINED FROM THE DSCB WHICH IS ALREADY AVAILABLE IN CORE    * 33150020
*        AT THIS POINT. THE INFORMATION IS REFERENCED THROUGH DSECT   * 33180020
*        OBTWAD. THE FOLLOWING INFORMATION IS COLLECTED.              * 33210020
*                                                                     * 33240020
*              1. CREATION DATE                                       * 33270020
*              2. EXPIRATION DATE                                     * 33300020
*              3. SECURITY (PASSWORD) INFORMATION                     * 33330020
*              4. DSORG                                               * 33360020
*                                                                     * 33390020
*********************************************************************** 33420020
HISTROUT SAVE  (14,12),,*                                               33450020
         LR    R10,R13        SAVE WORK AREA ADDRESS                    33480020
         USING WORKCORE,R10   R10 IS BASE FOR WORKAREA                  33510020
         USING OBTWAD,R12     R12 IS BASE FOR OBTAIN WORKAREA           33540020
         LR    R11,R15                                                  33570020
         USING HISTROUT,R11   R11 IS MAIN BASE                          33600020
         LA    R13,CIRSAVE    USE CIR SAVEAREA                          33630020
         ST    R10,D4(R13)     CHAIN AREAS TOGETHER                     33660020
         ST    R13,D8(R10)     BACKWARD CHAIN                           33690020
*                                                                       33720020
      LA R2,DS1CREDT          SET UP TO CONVERT CREATION DATE           33750020
      LA R7,OUTBUF                                                      33780020
      LA R7,CRDATOFF(R7)      POINT AT BUFFER POSITION                  33810020
         BAL   R14,HDT02      GO TO DATE CONVERSION ROUTINE             33840020
         LA    R2,DS1EXPDT    SET UP TO CONVERT EXPIRATION DATE         33870020
         LA    R7,D10(R7)      POINT AT NEXT BUFFER POSITION            33900020
         BAL   R14,HDT02      GO TO DATE CONVERSION ROUTINE             33930020
         LA    R7,D10(R7)      POINT AT NEXT BUFFER POSITION.           33960020
         TM    DS1DSIND,PWRD1      CHECK NOPWREAD PROTECTION     A48499 33990021
         BNO   HMN06               CHECK FOR PASSWORD PROTECTION A48499 34020021
         MVC   D0(L'WRITEPRO,R7),WRITEPRO PUT NAME IN BUFFER     A48499 34050021
         B     HISTDSRG      GO PROCESS DSORG                           34080020
HMN06    TM    DS1DSIND,PWRD2      CHECK FOR PASSWORD PROTECTION A48499 34140021
         BNO   NONEPROT       NO, INDICATE NONE                         34170020
         MVC   D0(L'PROTECTD,R7),PROTECTD PASSWORD PROTECTION    A48499 34200021
         B     HISTDSRG      GO PROCESS DSORG                           34230020
NONEPROT EQU   *                                                        34260020
         MVC   D0(L'NOPROTEC,R7),NOPROTEC  NO PROTECTION                34290020
         B     HISTDSRG      GO PROCESS DSORG                           34320020
       EJECT                                                            34350020
*********************************************************************** 34380020
*                                                                       34410020
*    THIS ROUTINE CONVERTS BINARY DATES OF THE FORM YYDDDD TO         * 34440020
*    CHARACTER FORMAT IN THE FORM MM/DD/YY. LEAP YEARS ARE ACCOUNTED  * 34470020
*    FOR. INPUT REQUIREMENTS ARE.                                     * 34500020
*         1.   R2 POINTS TO FIELD TO BE CONVERTED                     * 34530020
*         2.   R7 POINTS TO RECEIVING FIELD                           * 34560020
*         3.   R14 HAS RETURN ADDRESS.                                * 34590020
*                                                                     * 34620020
*********************************************************************** 34650020
HDT02 EQU      *                                                        34680020
         CLC   D0(D3,R2),HDTZ   CHECK FOR UNSPECIFIED DATE              34710020
         BNE   HDT04          BRANCH IF DATE PRESENT                    34740020
HDT03    MVC   D0(L'HDTDF,R7),HDTDF  MOVE IN DEFAULT OF 00/00/00        34770020
         BR    R14            RETURN                                    34800020
HDT04    STM   R14,R6,HDTSV   SAVE REGS                                 34830020
*                                                                       34860020
*  TEST FOR LEAP YEAR BY ANDING THE YEAR FIELD AGAINST A BYTE WITH    * 34890020
*  THE TWO LOW ORDER BITS ON. LEAP YEARS WILL HAVE ZEROS FOR THE TWO  * 34920020
*  LOW ORDER BYTES.                                                   * 34950020
*                                                                       34980020
         SR    R3,R3          CLEAR REG FOR INSERT CHARACTER.           35010020
         IC    R3,D0(R2)       GET YEAR BYTE FROM DATE FIELD            35040020
         LA    R4,HDTBIN3     SET UP TO TEST LOW ORDER BITS             35070020
         NR    R3,R4          IF YEAR IS DIVISIBLE BY 4, PROD EQ 0.     35100020
         LA    R4,HDTNY       SET UP FOR NON-LEAP YR -SAVE COND CD      35130020
         BNZ   HDT06          IF PROD NOT EQUAL TO ZERO, NOT LEAP YR.   35160020
         LA    R4,HDTLY       IF REMAINDER IS ZERO, USE LEAP YR.        35190020
HDT06    MVC   HDTWK(L2),D1(R2) MOVE 2 BYTE DAY FLD TO HWORD FOR ALIGN  35220020
         LH    R3,HDTWK                                                 35250020
         LA    R6,D12          SET UP BRANCH CONTROL AS NO. OF MONTHS   35280020
*                                                                       35310020
*   SEARCH NOW BEGINS TO FIND THE MONTH THAT THE DAY-OF-THE-YEAR OCCURS 35340020
*  IN. IF DAY-OF-THE-YEAR IS GREATER THAN 365/366, MONTH 12 IS USED.    35370020
*                                                                       35400020
HDT08     CH    R3,D0(R4)    COMPARE DAY TO TABLE ENTRY FOR MONTH       35430020
         BH    HDT10          DAY GREATER THAN TABLE IS A FIND          35460020
         LA    R4,D2(R4)       UP TBL PTR TO NEXT ELEMENT.              35490020
         BCT   R6,HDT08       DECREMENT MONTH AND RETRY.                35520020
         B     HDT03          IF DAY NEG, USE DEFAULT 00/00/00          35550020
HDT10    SH    R3,D0(R4)       SUBTRACT TABLE ELEMENT FROM DAY          35580020
         EX    R3,HDTCLI      COMPARE DAY TO 31.                        35610020
         BNL   HDT12               IF LESS THAN 31 OK                   35640020
         LA    R3,THIRTY1          DEFAULT TO 31 DAYS.                  35670020
HDT12    CVD   R6,HDTWK       CONVERT MONTH TO DEC                      35700020
         UNPK  D0(L2,R7),HD6(D2)  THEN TO CHARA                         35730020
         CVD   R3,HDTWK       CONVERT DAY TO DECIMAL                    35760020
         UNPK  D3(L2,R7),HD6(D2) THEN TO CHAR                           35790020
         IC    R6,D0(R2)       GET YEAR                                 35820020
         CVD   R6,HDTWK       CONVERT IT TO DECIMAL                     35850020
         UNPK  D6(L2,R7),HD6(D2) THEN TO CHAR                           35880020
        MVZ   D1(L7,R7),D0(R7)  PROPAGATE A NUMERIC CHAR ZONE           35910020
         MVI   D2(R7),SLASH    MOVE IN SEPARATORS BETWEEN               35940020
         MVI   D5(R7),SLASH        MONTH DAY AND YEAR                   35970020
         LM    R14,R6,HDTSV   RESTORE REGS                              36000020
HDT16    BR    R14            RETURN                                    36030020
HISTDSRG EQU   *                                                        36060020
*********************************************************************** 36090020
*                                                                       36120020
*    THE FOLLOWING ROUTINE ANALYZES THE DSORG AND MOVES THE           * 36150020
*    APPROPRIATE WORD TO THE OUTPUT BUFFER. IF THE DATA SET IS        * 36180020
*    UNMOVEABLE, A 'U' IS APPENDED TO THIS FIELD.                     * 36210020
*                                                                       36240020
*********************************************************************** 36270020
         LA    R7,OUTBUF     POINT AT OUTPUT BUFFER                     36300020
         LA    R7,DSORGOFF(R7) POINT TO DSORG FIELD IN BUFFER           36330020
         TM    DS1DSORG,PS    IS DSOR PS                                36360020
         BO    SETPS          IF YES, GO                                36390020
*                                                                       36420020
         TM    DS1DSORG,PO    IS DSORG PO                               36450020
         BO    SETPO          IF YES, GO                                36480020
*                                                                       36510020
         TM    DS1DSORG,IS    IS DSORG IS                               36540020
         BO    SETIS          IF YES, GO                                36570020
*                                                                       36600020
         TM    DS1DSORG,DA    IS DSORG DA                               36630020
         BO    SETDA          IF YES, BRANCH                            36660020
*                                                                       36690020
         TM    DS1DSORG,NOTID IS AN UIDENTIFIED BIT SET                 36720020
         BZ    SETND          IF NOT GO                                 36750020
*                                                                       36780020
         LA    R15,UNKL       DSORG NOT IDENTIFIABLE                    36810020
         LA    R14,UNK                                                  36840020
EXDSORGM BCTR  R15,R0         DECREMENT FOR MOVE                        36870020
         EX    R15,DSORGMV    MOVE DSORG TO BUFFER                      36900020
         LA    R7,D1(R15,R7)   ADD  (LENGTH-1)+1 TO CURR BUF PTR        36930020
         TM    DS1DSORG,UNMV  IS DATA SET UNMOVEABLE                    36960020
         BZ    DSOBTEXT       IF NOT, EXIT                              36990020
        MVI   D0(R7),CHARU       UNMOVABLE ATTRIBUTE                    37020020
DSOBTEXT B  HISTEXIT         GO PUT OUT BUFFER AND EXIT                 37050020
*                                                                       37080020
SETPS    LA    R15,SEQL       DSORG WAS SEQUENTIAL                      37110020
         LA    R14,SEQ                                                  37140020
         B     EXDSORGM            PUT OUT TYPE DS                      37170020
*                                                                       37200020
SETPO    LA    R15,PDSL       DSORG WAS PARTITIONED                     37230020
         LA    R14,PDS                                                  37260020
         B     EXDSORGM            PUT OUT TYPE DS                      37290020
*                                                                       37320020
SETIS    LA    R15,ISEQL      DSORG WAS INDEXED SEQ                     37350020
         LA    R14,ISEQ                                                 37380020
         B     EXDSORGM           PUT OUT TYPE DS                       37410020
*                                                                       37440020
SETDA    LA    R15,DAL        DSORG WAS DIRECT                          37470020
         LA    R14,DIRECT                                               37500020
         B     EXDSORGM           PUT OUT TYPE DS                       37530020
*                                                                       37560020
SETND    LA    R15,UNDEFL     DSORG WAS NOT DEFINED                     37590020
         LA    R14,UNDEF                                                37620020
         B     EXDSORGM           PUT OUT TYPE DS                       37650020
HISTEXIT EQU   *                                                        37680020
         LA    R7,OUTBUF      POINT AT BUFFER                           37710020
         LA    R14,EOHISTOF(R7) END OF HISTORY DATA                     37740020
         L     R15,VCONWRTE   GET ADDRESS OF WRITE ROUTINE              37770020
         BALR  R8,R15         GO WRITE THE BUFFER                       37800020
         LR    R13,R10        GET CALLERS SAVE AREA                     37830020
         LM    R14,R12,D12(R13) RESTORE REGS                            37860020
         BR    R14            RETURN TO CALLER                          37890020
*                                                                       37920020
*                                                                       37950020
DSORGMV  MVC   D0(L0,R7),D0(R14)   MOVE DSORG TO OUTPUT BUFFER          37960020
HDTCLI   CLI   HDTC31,HEX00        EXECUTE TO CHECK IF DATE IS GT 31    37970020
VCONWRTE DC    V(IKJEHWRT)         ADDRESS OF WRITE RTN                 37980020
SLASH    EQU   C'/'           DATE SEPARATORS                           38010020
PWRD1    EQU   X'14'         PASSWORD PROTECTION INDICATION             38040020
PWRD2    EQU   X'10'          WRITE PROTECTION ONLY                     38070020
PROTECTD DC    C'PROTECTED'       DS SECURITY PROTECTED                 38130020
WRITEPRO DC    C'WRITE'            WRITE PROTECTION (NOPWREAD)   A48499 38160021
NOPROTEC DC    C'NONE'            DS IS NOT PROTECTED                   38190020
HDTZ     DC    X'000000'           MASK OF NO DATA                      38250020
HDTDF    DC    C'00/00/00'         PRINTABLE NO DATE                    38280020
HDTC31   DC    FL1'31'             NUMBER 31 USED FOR COMPARE           38310020
*                                                                       38340020
*      TABLE FOR MONTHLY DATE LOOKUP IN NORMAL YEARS **                 38370020
*                                                                       38400020
HDTNY    DC    H'334'                                                   38430020
         DC    H'304'                                                   38460020
         DC    H'273'                                                   38490020
         DC    H'243'                                                   38520020
         DC    H'212'                                                   38550020
         DC    H'181'                                                   38580020
         DC    H'151'                                                   38610020
         DC    H'120'                                                   38640020
         DC    H'90'                                                    38670020
         DC    H'59'                                                    38700020
         DC    H'31'                                                    38730020
         DC    H'0'                                                     38760020
*                                                                       38790020
*       TABLE FOR MONTH LOOKUP IN LEAP YEARS         **                 38820020
*                                                                       38850020
HDTLY    DC    H'335'                                                   38880020
         DC    H'305'                                                   38910020
         DC    H'274'                                                   38940020
         DC    H'244'                                                   38970020
         DC    H'213'                                                   39000020
         DC    H'182'                                                   39030020
         DC    H'152'                                                   39060020
         DC    H'121'                                                   39090020
         DC    H'91'                                                    39120020
         DC    H'60'                                                    39150020
         DC    H'31'                                                    39180020
         DC    H'0'                                                     39210020
HDTBIN3  EQU   X'03'                                                    39240020
HDTL     EQU   10                                                       39270020
HRCL     EQU   2                                                        39300020
IS       EQU   X'80'          INDEXED SEQ                               39330020
PS       EQU   X'40'          SEQ                                       39360020
DA       EQU   X'20'          DIRECT (BDAM)                             39390020
PO       EQU   X'02'          PARTITIONED                               39420020
UNMV     EQU   X'01'          UNMOVEABLE BIT                            39450020
NOTID    EQU   X'1C'          THESE BITS CURRENTLY RESERVED.            39480020
SEQ      DC    C'PS'              PRINT OUT PHYS SEQ DS ABBREV          39510020
SEQL     EQU   L'SEQ          LENGTH OF CONSTANT SEQ                    39540020
PDS      DC    C'PO'              PARTITIONED ORG ABBREV                39570020
PDSL     EQU   L'PDS          LENGTH OF CONSTANT PDS                    39600020
ISEQ     DC    C'IS'              INDEXED SEQ ABBREV                    39630020
ISEQL    EQU   L'ISEQ         LENGTH OF CONSTANT ISEQ                   39660020
DIRECT   DC    C'DA'              DSORG IS DIRECT                       39690020
DAL      EQU   L'DIRECT       LENGTH OF CONSTANT DIRECT                 39720020
UNDEF    DC    C'**'              DSORG IS UNDEFINED                    39750020
UNDEFL   EQU   L'UNDEF        LENGTH OF CONSTANT UNDEF                  39780020
UNK      DC    C'??'              DSORG IS UNKNOWN                      39810020
UNKL     EQU   L'UNK          LENGTH OF CONSTANT UNK                    39840020
       DROP   R10                                                       39870020
*                                                                       39900020
       EJECT                                                            39930020
IKJEHVOL CSECT                                                          39990020
*********************************************************************** 40050020
*                                                                     * 40080020
*        THIS ROUTINE IS ENTERED IF THE VOLUMES KEYWORD IS SPECIFIED  * 40110020
*        ON THE COMMAND. IT PRODUCES A LIST OF VOLSERS ON WHICH THE   * 40140020
*        DSNAME CURRENTLY BEING PROCESSED RESIDES. UPON ENTRY THE     * 40170020
*        VOLUMES HEADING IS PUT OUT TO THE TERMINAL. IF THE ASTERISK  * 40200020
*        SWITCH IS ON, A LIST OF VOLUMES IS ALREADY AVAILABLE IN THE  * 40230020
*        SECOND CIRBLOCK. OTHERWISE THE CURRENT ENTRY POINTED TO BY   * 40260020
*        REG 6 IS EXAMINED TO DETERMINE THE TYPE. IF IT IS A SIMPLE   * 40290020
*        DSNAME ENTRY, THE VOLUME LIST WILL BE CONTAINED IN THE ENTRY,* 40320020
*        OTHERWISE IT IS A VCB ENTRY. IF EITHER HISTORY OR MEMBERS    * 40350020
*        WAS SPECIFIED, THE FIRST VCB BLOCK WAS READ INTO VOLBLK.     * 40380020
*        OTHERWISE IKJEHCIR MUST BE CALLED TO GET THE FIRST BLOCK.    * 40410020
*                                                                     * 40440020
*********************************************************************** 40470020
VOLROUT  DS    0H                                                       40500020
         SAVE  (14,12),,*                                               40530020
         LR    R10,R13        SAVE WORK AREA ADDRESS                    40560020
         USING WORKCORE,R10   BASE FOR GENERAL WORKAREA                 40590020
         USING VOLROUT,R11    MAIN BASE FOR THIS CSECT                  40620020
         LR    R11,R15                                                  40650020
         GETMAIN R,LV=SAVELEN,SP=WORKSP  GET A SAVE AREA                40680020
         ST    R13,D4(R1)      FORWARD                                  40710020
         ST    R1,D8(R13)         AND                                   40740020
         LR    R13,R1             BACKWARD CHAIN SAVEAREAS              40770020
         LA    R7,OUTBUF      POINT AT BUFFER                           40800020
         LR    R14,R7         INDICATE LINE SKIP                        40830020
         L     R15,VCONWRT    GET ADDR OF WRITE ROUTINE                 40860020
         BALR  R8,R15         SKIP A LINE                               40890020
         MVC   D2(L'VOLHDG,R7),VOLHDG  MOVE HEADING TO BUFFER           40920020
         LA    R14,L'VOLHDG+D2(R7)  POINT AT END OF DATA                40950020
         L     R15,VCONWRT    ADDR OF WRITE                             40980020
         BALR  R8,R15         GO WRITE THE BUFFER                       41010020
         TM    OPTMASK,ASTSW  WAS ASTERISK SWITCH ON                    41040020
         BNO   VOLRT01        NO, CHECK ENTRY TYPE                      41070020
         L     R1,FRSTBLK     GET FIRST BLOCK ADDR                      41100020
         L     R1,D0(R1)       ADDR OF SECOND CIR BLOCK                 41130020
         LA    R1,D8(R1)       POINT AT VOLUME LIST                     41160020
         B     VOLRTGO        GO PUT OUT LIST                           41190020
VOLRT01  EQU   *                                                        41220020
         CLI   D0(R6),VOLENT   SEE IF DSNAME ENTRY IS BEING PROCESSED   41250020
         BNE   VOLRT02        NO, GO GET VCB                            41280020
         LA    R1,DSNLEN(R6)  POINT AT VOLUME LIST                      41310020
         B     VOLRTGO        GO PUT OUT DATA                           41340020
VOLRT02  EQU   *                                                        41370020
         TM    OPTMASK,HISTMEM  CHECK HISTORY OR MEMBERS                41400020
         BZ    VOLRT03        NO, GO GET VCB                            41430020
         LA    R1,VOLBLK      GET ADDR OF LIST OF VOLUMES               41460020
         B     VOLRTGO        GO PROCESS LIST                           41490020
VOLRT03  EQU   *                                                        41520020
         LA    R1,DSNLEN(R6)  POINT AT TTR OF VCB                       41550020
         ST    R1,CIRINDX        PUT IN LIST                            41580020
VOLRT03A LA    R1,VOLBLK      POINT AT BLOCK TO HOLD LIST OF VOLUMES    41610020
VOLRT03B ST    R1,CIRWK1       PUT IT IN THE LIST                       41640020
         L     R1,CURNTBLK    GET ADDRESS                               41670020
         LA    R1,D8(R1)            OF CURRENT BLOCK                    41700020
         LA    R1,CIRVOLID(R1) POINT AT CATALOG VOLSER                  41730020
         ST    R1,CIRVOL        PUT IT IN THE LIST                      41760020
         OI    CIRINDX,ASTSW INDICATE TTR                               41790020
         XC    CIRPARM,CIRPARM  CLEAR OPTION WORD                       41820020
         OI    CIRPARM,CIRVOLS     SET VOLUMES OPTION                   41850020
         LA    R1,CIRPARM     PARM LIST FOR CALL MACRO                  41880020
         L     R15,CIRAD                                                41910020
         CALL  (15)                                                     41940020
         LTR   R15,R15        TEST RETURN CODE                          41970020
         BNZ   VOLRT04        NONZERO, EXIT TO PROCESS ERROR            42000020
         LA    R1,VOLBLK      POINT AT VOLUME LIST                      42030020
         B     VOLRTGO        GO PROCESS                                42060020
*                                                                       42090020
*      RETURN FROM CIR WITH ERROR CONDITIONS IS HERE ****               42120020
*                                                                       42150020
VOLRT04  EQU   *                                                        42180020
         L     R1,VCON04      GET ADDRESS OF ERROR HANDLER FOR RC=04    42210020
         C     R15,FOUR       CHECK FOR RC=04                           42240020
         BE    VOLRT05        YES, GO EXIT                              42270020
         L     R1,VCON08      GET ADDR OF ERROR HANDLER FOR RC=08,12    42300020
VOLRT05  EQU   *                                                        42330020
         LR    R2,R13         GET CALLERS SAVEAREA                      42360020
         L     R13,D4(R2)        ADDRESS IN PROPER REG                  42390020
         ST    R1,D12(R13)     CHANGE RETURN ADDRESS                    42420020
         LR    R1,R2                                                    42450020
         ST    R15,D16(R13)    SET RC                                   42480020
VOLRT05A FREEMAIN R,LV=SAVELEN,A=(1),SP=WORKSP                          42510020
         LM    R14,R12,OFF12(R13)  RESTORE REGS                         42540020
         BR    R14                RETURN TO CALLER                      42570020
VOLRTGO  EQU   *                                                        42600020
         MVC   TEMPSAVE(D2),D0(R1)   ALLIGN CVOLUME COUNT               42630020
         LH    R2,TEMPSAVE    GET VOLUME COUNT                          42660020
         C     R2,TWENTY      CHECK AGAINST 20                          42690020
         BNH   VOLRT06        NOT MORE, OK AS IS                        42720020
         L     R2,TWENTY          SET LOOP TO TWENTY                    42750020
         OI    OPTMASK,MOREVOLS  INDICATE MORE THAN 20                  42780020
VOLRT06  LA    R1,D2(R1)                                                42810020
VOLRT07  MVC   OUTBUF+D4(L6),D4(R1)   MOVE VOLSER TO BUFFER             42840020
         LA    R7,OUTBUF      POINT AT BUFFER                           42870020
         LA    R14,ENDTA(R7)      END OF DATA IN BUFFER                 42900020
         L     R15,VCONWRT    WRITE ROUTINE ADDR                        42930020
         BALR  R8,R15         GO WRITE THE BUFFER                       42960020
         LA    R1,D12(R1)      POINT AT NEXT VOLSER ENTRY               42990020
         BCT   R2,VOLRT07     IF MORE EXIST, PROCESS NEXT               43020020
         TM    OPTMASK,MOREVOLS  SEE IF MORE EXIST IN ANOTHER BLOCK     43050020
         BO    VOLRT08        YES, GO SET UP TO PROCESS THEM            43080020
         LR    R1,R13         GET CALLERS SAVEAREA                      43110020
         L     R13,D4(R1)                                               43140020
         B     VOLRT05A       GO EXIT                                   43170020
VOLRT08  EQU   *                                                        43200020
         NI    OPTMASK,VOLSWOFF   TURN OFF MOREVOLS SWITCH              43230020
         TM    OPTMASK,ASTSW  SEE IF ASTERISK SWITCH IS ON              43260020
         BO    VOLRT09        YES                                       43290020
         LA    R1,VOLBLK+VCBTTROF  POINT AT TTR OF NEXT BLOCK           43320020
         MVC   CIRTTR(L3),D0(R1)   SAVE TTR OF NEXT BLOCK         M2136 43330021
         LA    R1,CIRTTR           POINT TO TTR                   M2136 43340021
         ST    R1,CIRINDX      PUT IN LIST                              43350020
         B     VOLRT03A       TRY AGAIN                                 43380020
VOLRT09  EQU   *                                                        43410020
         L     R1,FRSTBLK     GET ADDR OF FIRST CIR BLOCK               43440020
         L     R1,D0(R1)       GET ADDR OF NEXT BLOCK                   43470020
         LA    R2,VCBTTROF+D8(R1)  POINT AT TTR                         43500020
         ST    R2,CIRINDX      PUT INTO LIST                            43530020
         LA    R1,D8(R1)       POINT AT START OF LIST BLOCK             43560020
         B     VOLRT03B       GO GET ANOTHER LIST.                      43590020
*                                                                       43620020
SAVELEN  EQU   118            GETMAIN CONSTANT                          43650020
VCONWRT  DC    V(IKJEHWRT)         ADDRESS OF WRITE RTN                 43680020
VOLHDG   DC    C'--VOLUMES--'     VOLUME HEADING                        43710020
FOUR     DC    F'4'                NUMBER FOUR RETURN CODE              43740020
TWENTY   DC    F'20'               NUMBER TWENTY VOL CNT                43770020
VCON04   DC    V(IKJEHCR4)         ADDRESS OF ERROR EXIT IN CIRROUT     43800020
VCON08   DC    V(IKJEHCR8)         ADDRESS OF ERROR EXIT IN CIRROUT     43830020
        DROP  R10                                                       43860020
*                                                                       43890020
         EJECT                                                          43920020
IKJEHMBR  CSECT                                                         43980020
*********************************************************************** 44040020
*                                                                     * 44070020
*        THIS ROUTINE GETS CONTROL IF THE MEMBERS KEYWORD WAS         * 44100020
*        SPECIFIED. IT CHECKS THE DSORG FOR PARTITIONED ORGANIZATION  * 44130020
*        AND RETURNS TO THE CALLER IF NOT. IF IT IS PARTITIONED IT    * 44160020
*        ALLOCATES THE DATA SET USING DAIR AND SETS UP A PARAMETER    * 44190020
*        LIST TO BE PASSED TO IKJEHMEM VIA THE CALL MACRO.            * 44220020
*                                                                     * 44250020
*********************************************************************** 44280020
MEMROUT  SAVE  (14,12),,*                                               44310020
         LR    R10,R13        SAVE WORKAREA ADDRESS                     44340020
         USING WORKCORE,R10   BASE FOR GENERAL WORKAREA                 44370020
         USING OBTWAD,R12     R12 IS BASE FOR OBTAIN WORKAREA           44400020
         USING MEMROUT,R11    MAIN BASE FOR THIS CSECT                  44430020
         LR    R11,R15        GET EP ADDR FOR ADDRESSABILITY            44460020
         LA    R13,CIRSAVE    USE CIR SAVEAREA                          44490020
         ST    R10,D4(R13)     CHAIN AREAS TOGETHER                     44520020
         ST    R13,D8(R10)     BACKWARD CHAIN                           44550020
         TM    DS1DSORG,PO    IS DATASET PARTITIONED                    44580020
         BNO   MEMEXIT        NO, GO EXIT THIS ROUTINE                  44610020
         LA    R7,OUTBUF      POINT AT BUFFER                           44640020
         LR    R14,R7         INDICATE LINE SKIP                        44670020
         L     R15,VCONWRIT   GET ADDRESS OF WRITE ROUTINE              44700020
         BALR  R8,R15         GO SKIP A LINE                            44730020
         MVC   D0(L'MEMHDG,R7),MEMHDG  MOVE HEADING TO BUFFER           44760020
         LA    R14,L'MEMHDG(R7)  POINT PAST DATA FOR WRITE ROUTINE      44790020
         L     R15,VCONWRIT                                             44820020
         BALR  R8,R15         GO WRITE THE BUFFER                       44850020
TRYALC   BAL   R8,ALLOCDS         ALLOCATE THE DATA SET                 44870020
         LA    R2,DAIRLIST        SET UP ADDRESSABILITY TO DAIR RC      44890020
         USING DAPB08,R2          USE MAP MACRO                         44900020
         B     DAIRCODE(R15)  ANALYZE RETURN CODES                      44910020
*                                                                       44940020
DAIRCODE B     DCODE00        RC=00 SUCCESS                             44970020
         B     DCODE04        RC=04 INVALID PARM LIST                   45000020
         B     DCODE08            CATALOG ERROR                         45030020
         B     DCODE12            DYNAM ALLOC ERROR                     45060020
         B     DCODE16            NO DYNAM AVAILABLE                    45090020
*                                                                       45150020
DCODE04  EQU   *                                                        45180020
         MVI   ERR1,MSG10         COMMAND SYSTEM ERROR                  45210020
         MVI   ERR2,SECMSG13      DAIR ERROR CODE                       45270020
        B     CVDR151        CONVERT CODE                               45330020
DCODE08  EQU   *                                                        45360020
*********RETURN CODES OF 4 8 12 16 AND 28 ARE VALID ONLY ******         45380020
         CLI   DA08CTRC+D1,D4     RC =  4 VOL NOT AVAIL                 45400020
         BE    CTRC4              PUT OUT MSG                           45420020
         CLI   DA08CTRC+D1,RC28   RC 28 CAT I/O ERROR                   45440020
         BE    CTRC28             PUT OUT MSG                           45460020
******IF NOT ABOVE  USE CATCH ALL DS NOT IN CATLG*********              45480020
         MVI   ERR1,MSG18         DSNAME NOT IN CATALOG                 45500020
         B     MCOMMON3           INSERT DSNAME IN MSG                  45520020
CTRC4    MVI   ERR2,SECMSG24      VOL OR CVOL NOT ON SYSTEM             45540020
         MVI   ERR1,MSG17         DS NOT ALLOC VOL NOT MNTED            45560020
         B     MCOMMON3           INSERT NAME AND PUT OUT MSG           45580020
CTRC28   MVI   ERR2,SECMSG11      CATALOG I/O ERROR                     45600020
         MVI   ERR1,MSG14         DS NOT ALLOC SYSTEM ERROR             45620020
         B     MCOMMON3           INSERT NAME AND PUT OUT MSG           45640020
DCODE12  EQU   *                                                        45690020
         LH    R1,DA08DARC                                              45720020
         CH    R1,C210                                                  45810020
         BE    M210                DS ALLOCATED TO ANOTHER USER         45840020
         CH    R1,C218                                                  45870020
         BE    M218                VOLUME CANNOT BE ACCESSED            45900020
         MVI   ERR2,SECMSG23      DYNAMIC ALLOC ERROR                   45962020
         MVI   ERR1,MSG14         SYSTEM ERROR                          45964020
**********  THIS RTN CONVERTS THE HEX RC FROM DAIR  ************        45966020
****** AND PUTS OUT THE FIRST AND SECOND LEVEL MSG PARMS ******         45968020
HEXRTN   EQU   *                                                        45970020
HEX      LA    R5,ERRINSRT        PUT ADDRESS OF INSERT                 45972020
         ST    R5,ERRINST2        INTO INSERT SLOT                      45974020
         LA    R5,FOURB           NO OF HALF BYTES TO CONVERT           45976020
         LA    R7,ERRINSRT+D1          OUTPUT POINTER                   45978020
         SLL   R1,D16                                                   45980020
         LR    R3,R1              PUT INTO WORK PAIR REGS               45982020
LOOP1    XR    R2,R2              CLEAR REG 2                           45984020
         SLDL  R2,FOURB           GET FOUR BITS TO CONVERT              45986020
         IC    R0,TRANSTAB(R2)    GET PRINT CHAR                        45988020
         STC   R0,D0(R7)          PUT CHARACTER IN BUFF                 45990020
         LA    R7,D1(R7)          UPDATE INDEX                          45992020
         BCT   R5,LOOP1           IF ALL DONE FALL THRU                 45994020
         CLI   ERRINSRT+D1,CHARZRO CHECK FOR LEADING ZERO               45996020
         BNE   ENDHEX             IF ANY                                45998020
         MVI   ERRINSRT+D1,CHARBLK                                      46000020
ENDHEX   MVI   ERRINSRT,FOURB     LENGTH OF TEXT                        46002020
         B     MCOMMON3           PUT OUT MSG AND INSERT                46004020
*    CONSTANTS USED BY THIS RTN BELOW                                   46020020
         DS    0H                                                       46050020
TRANSTAB DC    C'0123456789ABCDEF' TRANSLATE TABLE FOR BITOHEX ROUTINE  46080020
C210      DC   X'0210'             ERROR CODE                           46110020
C218    DC    X'0218'                                                   46140020
*                                                                       46440020
M210     MVI   ERR2,SECMSG25      DATA SET BEING USED BY OTHER          46470020
         LA    R1,MSG15                                                 46530020
MCOMMON1 EQU   *                                                        46560020
MCOMMON2 STH   R1,ERRFIRST                                              46590020
MCOMMON3 LA    R1,CURNTNAM+D1     GET CURRENT NAME                      46620020
         ST    R1,ERRINST1                                              46650020
         B     MEMEREXT            GO PROCESS MEMBER ERROR              46680020
*                                                                       46710020
M218     LA    R1,SECMSG22                                              46740020
         STH   R1,ERRSECND                                              46770020
         LA    R1,MSG17           DS NOT ALLOCATED REQ VOL NOT MNTED    46800020
         B     MCOMMON1       FILL IN REST                              46830020
        DROP  R2                                                        46980020
DCODE16  EQU   *                                                        47010020
         TM    FIRSTIME,ONE        FIRST ATTEMPT TO ALLOCATE            47020020
         BNO   UNALOCDS            NO THEN UNALLOCATE BY 20             47030020
NODYNAM  NI    OPTMASK,FOXES-MEM       TURN OFF MEM OPTION              47040020
         MVI   ERR2,SECMSG20                                            47080020
         LA    R1,MSG12                                                 47130020
         B     MCOMMON1       FILL IN REST OF MESSAGE                   47140020
UNALOCDS EQU   *                                                        47161020
         LA    R1,DAIRLIST         SET UP ADDRESSABILITY                47162020
         USING DAPB2C,R1           USE DAIR 2C MAP MACRO                47163020
         MVC   DAPB2C(DAIR2CLN),DAIR2C  INITIALIZE DAIRLIST             47164020
         L     R2,CVTPTR           ADDRESS OF CVT                       47165020
         USING CVTTCBP,R2          USE MAP MACRO                        47166020
         L     R3,CVTTCBP          POINTER TO TCB                       47167020
         L     R2,TCBOFF(R3)       ADDRESS OF CURRENT TCB               47168020
         ST    R2,DA2CTCB          STORE IN LIST                        47169020
         DROP  R1                                                       47170020
         DROP  R2                                                       47171020
         BAL   R8,MEMDAIR          LINK TO DAIR                         47172020
         LTR   R15,R15             DID UNALLOCATE WORK                  47173020
         BZ    TRYALC              YES TRY ALLOCATE AGAIN               47174020
         B     NODYNAM             NO PUT OUT MESSAGE                   47175020
*                                                                       47190020
*        CONVERT CODE IN REG 15.                                        47220020
CVDR151  EQU   *                                                        47250020
CVDR152  CVD   R15,ERRINSRT+D8   CONVERT RETURN CODE                    47280020
         UNPK  ERRINSRT+D1(L2),ERRINSRT+D8(D8)                          47310020
         OI    ERRINSRT+D2,ZONE                                         47340020
         LA    R1,D2           GET LENGTH OF DATA                       47370020
         STC   R1,ERRINSRT    PLACE IT BEFORE THE DATA                  47400020
         LA    R1,ERRINSRT    PLACE ADDRESS OF DATA INSERT IN           47430020
         ST    R1,ERRINST2          SLOT FOR SECOND LEVEL MESSAGE       47460020
MEMEREXT EQU   *                                                        47490020
         LR    R13,R10       GET CALLERS SAVEAREA                       47520020
         L     R1,VCONERRT    GET ADDRESS OF ERROUT                     47550020
         L     R2,D12(R13)     GET CALLERS RETURN ADDRESS               47580020
         ST    R1,D12(R13)     CHANGE TO POINT TO ERROUT                47610020
         ST    R2,CALLRET(R13)     SET CALLER RETURN FROM ERROUT        47640020
         LM    R14,R12,D12(R13)  RESTORE REGS                           47670020
         BR    R14            RETURN                                    47700020
DCODE00  EQU   *                                                        47730020
         NI    FIRSTIME,HEX00     TURN OFF FIRST ALLOC SWITCH           47740020
         LA    R2,OBTDCB      ADDR OF INPUT DCB                         47760020
         USING IHADCB,R2                                                47790020
         MVC   DCBDDNAM(L8),DAIRLIST+D12  DDNAME IN DCB                 47820020
         LA    R1,RDJL                                                  47850020
         LA    R3,OBTDCB                                                47880020
         RDJFCB ((R3)),MF=(E,(R1))                                      47910020
         DROP R2                                                        47940020
         L     R15,MEMMOD     ADDR OF IKJEHMEM EP                       47970020
         LA    R1,CALLIST                                               48000020
         L     R2,VCONWRIT    ADDR OF WRITE ROUTINE                     48030020
         CALL  (15),((R12),GETML,OUTBUF,(R2),FREEML),VL,MF=(E,(1))      48060020
*                                                                       48120020
         B     MEMCODE(R15)   ANALYZE IKJEHMEM RC                       48720020
*                                                                       48750020
MEMCODE  B     MEMEXIT        SUCCESS                                   48780020
         B     MEMCDE04       INSUFFICIENT CORE                         48810020
         B     MEMCDE08       I/O ERROR                                 48840020
         B     MEMCDE12       DIRECTORY ERROR                           48870020
*                                                                       48900020
MEMCDE04 EQU   *                                                        48930020
         LA    R1,SECMSG18    INSUFFICIENT CORE CODE                    48960020
         B     MEMERROR            GO TO ERROR RTN                      48990020
MEMCDE08 EQU   *                                                        49020020
         LA    R1,SECMSG19    I/O ERROR                                 49050020
         LA    R2,SYNMSG                                                49080020
         ST    R2,ERRINST2                                              49110020
         B     MEMSYN              GO TO SYNAD INSERT RTN               49140020
MEMCDE12 EQU   *                                                        49170020
         LA    R1,SECMSG07    DIRECTORY ERROR                           49200020
MEMERROR EQU   *                                                        49230020
        XC    ERRINST2,ERRINST2   CLEAR SECOND LEVEL INSERT             49260020
MEMSYN  STH   R1,ERRSECND    PUT CODE IN LIST                           49290020
         LA    R1,MSG09       MEMBERS OPTION FAILED MESSAGE             49320020
         STH   R1,ERRPARM     PUT IN LIST                               49350020
         XC    ERRINST1,ERRINST1          CLEAR FIRST INSERT PTR        49380020
         B     MEMEREXT       GO TO ERREXIT                             49410020
MEMEXIT  LR    R13,R10                                                  49440020
         LM    R14,R12,D12(R13) RESTORE                                 49470020
         BR    R14            RETURN TO CALLER                          49500020
ALLOCDS  DS    0H                                                       49530020
*********************************************************************** 49560020
*                                                                       49590020
*        THIS IS A COMMON ROUTINE THAT TAKES THE CURRENT DSNAME AND     49620020
*        ALLOCATES IT BY GOING TO DAIR AT ENTRY X'08'.                  49650020
*                                                                       49680020
*********************************************************************** 49710020
         LA    R2,DAIRLIST        SET UP USING DSECT                    49740020
         USING DAPB08,R2          USE IKJDAP08                          49770020
*                                                                       49800020
**                                                                      49830020
         MVC   DAPB08(DAIR08LN),DAIR08 INITIALIZE DAIR LIST             49860020
         LA    R1,CURNTNAM                                              49890020
         ST    R1,DA08PDSN         PUT CTR CURRENT DSNAME IN LIST       49920020
*                                                                       49950020
         DROP  R2                                                       49980020
MEMDAIR  LA   R2,PUTLLIST             SET UP USING DSECT                50010020
         USING DAPL,R2             MAP MACRO IKJDAPL                    50040020
*                                                                       50070020
         L     R1,UPTPTR            UPT PTR                             50100020
         ST    R1,DAPLUPT           STORE IN LIST                       50130020
         L     R1,ECTPTR            ECT PTR                             50160020
         ST    R1,DAPLECT           STORE IN LIST                       50190020
         L     R1,ECBPTR            CP ECB PTR                          50220020
         ST    R1,DAPLECB           STORE IN LIST                       50250020
         L     R1,PSCBPTR           PSCB PTR                            50280020
         ST    R1,DAPLPSCB          STORE IN LIST                       50310020
         LA    R1,DAIRLIST          PTR TO DAIR PARM LIST               50340020
         ST    R1,DAPLDAPB          STORE IN DAIR LIST                  50370020
         DROP  R2                                                       50400020
         LA    R1,PUTLLIST    POINT AT LIST                             50430020
         LINK  EP=IKJDAIR,MF=(E,(1))                                    50460020
         BR    R8                  RETURN TO CALLER                     50490020
*                                                                       50520020
*        MEMBERS ROUTINE CONSTANTS                                      50550020
*                                                                       50580020
VCONWRIT DC    V(IKJEHWRT)         ADDRESS OF WRITE RTN                 50610020
VCONERRT DC    V(IKJEHERR)         ADDRESS OF ERROR RTN                 50640020
MEMHDG   DC    C'--MEMBERS--'      HEADING FOR MEMBER OPTION            50670020
DAIR08   DS    0F                                                       50700020
         DC    H'8'                CODE OF 08                           50730020
         DC    H'0'                FLAGS                                50760020
         DC    F'0'                DARC CTRC                            50790020
         DC    F'0'                DSNAME PTR                           50820020
         DC    8X'40'              DDNAME FIELD                         50850020
         DC    8X'40'              UNIT NAME                            50880020
         DC    8X'40'              SERIAL NUNMBER                       50910020
         DC    4X'00'              BLOCKSIZE                            50940020
         DC    4X'00'              PRIMARY SPACE ALC                    50970020
         DC    4X'00'              SECONDARY SPACE                      51000020
         DC    4X'00'              DIRECTORY                            51030020
         DC    8X'40'              MEMBER NAME                          51060020
         DC    8X'40'              PASSWORD FIELD                       51090020
         DC    3X'08'              DISP OF SHR KP KP                    51120020
         DC    5X'00'               FIELDS NOT USED                     51150020
DAIR08LN EQU *-DAIR08                                                   51180020
******************************************************                  51210020
****CONSTANTS USED BY UNALLOC ROUTINE*****************                  51240020
**** THE UNALLOCATION IS DONE BY TCB ADDRESS  *****                     51280020
DAIR2C   DS    0F                                                       51320020
         DC    X'002C'             UNALC BY TCB ADDRESS FLAG ZEROS      51360020
         DC    H'0'               UNALLOCATE BY TCB                     51400020
         DC    F'0'                CLEAR TCB ADDRESS                    51440020
         DC    2F'0'               CLEAR REMAINDER                      51480020
DAIR2CLN EQU   *-DAIR2C                                                 51520020
****************************************************                    51600020
         DROP    R10                                                    51630020
         EJECT                                                          51660020
IKJEHCT1 CSECT                                                          51720020
         USING   LISTCAT,R11                                            51750020
         USING   WORKCORE,R13                                           51780020
POINTER  DS    0H                                                       51810020
*********************************************************************** 51840020
*                                                                       51870020
*        THIS ROUTINE IS ENTERED TO UPDATE THE CURRENT ENTRY POINTER    51900020
*        IN THE CURRENT BLOCK. THE CURRENT BLOCK IS DETERMINED BY       51930020
*        SEARCHING THE CHAIN FOR THE FIRST ONE WITH A ZERO ENTRY        51960020
*        POINTER AND THEN BACKING UP ONE. THE CURRENT ENTRY TYPE IS     51990020
*        DETERMINED AND THE POINTER IS ADVANCED ACCORDINGLY. IF THE     52020020
*        NEXT ENTRY IS A LINK ENTRY WHICH CONTAINS A NONZERO TTR,       52050020
*        THE CIR IS CALLED TO PROVIDE THE NEXT BLOCK OF ENTRIES. IF     52080020
*        THE TTR IS ZERO, THE CURRENT BLOCK IS RELEASED AND THE         52110020
*        PRECEDING BLOCK IS CONSIDERED. WHEN ALL BLOCKS ARE PROCESSED,  52140020
*        IE, THE CURRENT BLOCK EQUALS THE FIRST BLOCK AND THE ENTRY     52170020
*        POINTER IS ZERO, THE WRAPUP ROUTINE IS ENTERED.                52200020
*                                                                       52230020
*********************************************************************** 52260020
         STM   R0,R9,LOCSAVOF(R13)  SAVE REGISTERS LOCALLY              52290020
PTR00    L     R1,FRSTBLK     GET PTR TO FIRST BLOCK                    52320020
        CLC   D4(L4,R1),ZERO     SEE IF PTR IS ZERO                     52350020
         BE    WRAPUP         YES, WE ARE FINISHED                      52380020
PTR01    ST    R1,PREVBLK     SAVE THIS BLOCK PTR                       52410020
         L     R1,D0(R1)       GET PTR TO NEXT BLOCK                    52440020
        CLC   D4(L4,R1),ZERO      SEE IF PTR IS ZERO                    52470020
         BE    PTR02          YES,PROCESS LAST PTR                      52500020
         CLC   D0(L4,R1),ZERO     NO, CHECK CHAIN ADDRESS               52530020
         BNE   PTR01          IF NOT ZERO, TRY NEXT BLOCK.              52560020
         B     PTR03          GO AROUND NEXT INSTRUCTION                52590020
PTR02    L     R1,PREVBLK     GET PREVIOUS BLOCK POINTER.               52620020
PTR03    L     R2,ENTPTR(R1)       PICK UP CURRENT ENTRY POINTER        52650020
         CLI   D0(R2),DSNENT   CHECK FOR DSNAME ENTRY                   52680020
         BNE   PTR04          NO, CHECK NEXT CODE                       52710020
         LA    R2,DSNLEN(R2)  UPDATE PTR                                52740020
         B     PTRFFCHK       GO CHECK FOR LINK ENTRY                   52770020
*                                                                       52800020
PTR04    CLI   D0(R2),GDGENT   GDG ENTRY                                52830020
         BNE   PTR05          NO, CHECK NEXT                            52860020
         LA    R2,GDGLEN(R2)  BUMP PTR                                  52890020
         B     PTRFFCHK       GO CHECK FOR LINK ENTRY                   52920020
*                                                                       52950020
PTR05     CLI   D0(R2),INDENT   INDEX ENTRY                             52980020
         BNE   PTR06          NO, CHECK NEXT                            53010020
         LA    R2,INDLEN(R2)  BUMP PTR                                  53040020
         B     PTRFFCHK       GO CHECK FOR LINK ENTRY                   53070020
*                                                                       53100020
PTR06    CLI  D0(R2),VOLENT  VOLUMES WITH DSNAME                        53130020
         BNE   PTR07          NO, CHECK NEXT                            53160020
         XR    R4,R4          CLEAR FOR INSERT CHARACTER                53190020
         IC    R4,DSNLEN+D1(R2)       GET VOLUME COUNT                  53220020
         LA    R5,VCBLEN          LENGTH OF EACH ENTRY IN VOLUME LIST   53250020
         MR    R4,R4          TOTAL LENGTH OF LIST                      53280020
         LA    R2,DSNLEN+D2(R2,R5)    BUMP PTR BEYOND ENTRY             53310020
         B     PTRFFCHK       GO CHECK FOR LINK ENTRY.                  53340020
*                                                                       53370020
PTR07    CLI   D0(R2),VCBENT   VOLUME CONTROL BLOCK PTR ENTRY           53400020
         BNE   PTR08          NO, CHECK NEXT                            53430020
         LA    R2,VCBLEN(R2)  BUMP POINTER                              53460020
         B     PTRFFCHK       CHECK FOR LINK ENTRY                      53490020
*                                                                       53520020
PTR08    CLI   D0(R2),ALIENT   ALIAS ENTRY                              53550020
         BNE   PTR09          NO, CHECK NEXT                            53580020
         LA    R2,ALILEN(R2)  BUMP POINTER                              53610020
         B     PTRFFCHK       CHECK FOR LINK ENTRY                      53640020
*                                                                       53670020
PTR09    CLI   0(R2),CVOLENT  CHECK FOR CVOL PTR ENTRY                  53700020
         BNE   PTR10          NO, MUST BE LINK ENTRY                    53730020
         LA    R2,CVOLLEN(R2) BUMP POINTER                              53760020
PTRFFCHK EQU   *                                                        53790020
         ST    R2,ENTPTR(R1)       UPDATE ENTRY PTR IN BLOCK            53820020
        CLI   D0(R2),FOXES    CHECK FOR LINK ENTRY                      53850020
         BNE   PTREXIT        GO TO EXIT IF NOT LINK ENTRY              53880020
PTR10    CLC   D1(L3,R2),ZERO   IS TTR ZERO                             53910020
         BNE   PTR11          NO, GET ANOTHER BLOCK                     53940020
        XC    D4(L4,R1),D4(R1)    CLEAR ENTRY POINTER                   53970020
         B     PTR00          GO BACK TO START OF ROUTINE               54000020
PTR11    EQU   *                                                        54030020
*                                                                       54060020
*        A LINK ENTRY WAS FOUND WITH A NONZERO TTR. UNCHAIN LAST        54090020
*        BLOCK AND PASS IT BACK TO CIR TO COMPLETE LIST.                54120020
*                                                                       54150020
        XC    D4(L4,R1),D4(R1)     UNCHAIN LAST BLOCK                   54180020
         LA    R3,D8(R1)       POINT AT AREA FOR LIST FROM CIR          54210020
         ST    R3,CIRWK1      STORE IN PARM LIST                        54240020
         LA    R3,D1(R2)       POINT AT TTR                             54270020
         MVC   CIRTTR(L'CIRTTR),D0(R3)  MOVE TTR TO SAVE AREA           54300020
         LA    R1,CIRTTR      POINT AT TTR OF NEXT BLOCK                54330020
         ST    R1,CIRINDX     PUT IN LIST                               54360020
        OI    CIRINDX,ASTSW   TURN ON BIT INDICATING TTR                54390020
         LA    R3,D3(R3)       POINT AT VOLID FOR CATALOG               54420020
         MVC   CIRCVOL(L'CIRCVOL),D0(R3)  MOVE CVOL TO SAVE AREA        54450020
         LA    R1,CIRCVOL     GET ADDRESS OF CVOL                       54480020
         ST    R1,CIRVOL      PUT ADDRESS IN LIST                       54510020
         XC    CIRPARM,CIRPARM  CLEAR OPTION BYTE                       54540020
         TM    OPTMASK,ANYOPT CHECK FOR HISTORY, VOLUMES, MEMBERS       54570020
         BZ    PTR12          NONE, SKIP VOLUME REQUEST OPT             54600020
         OI    CIRPARM,CIRVOLS  REQUEST VOLUMES                         54630020
PTR12    OI    CIRPARM,CIRDSN+CIRIND REQUEST DSNAMES AND INDEX NAMES    54660020
*                                                                       54690020
         BAL   R8,CIRROUT     CALL CIR                                  54720020
         LTR   R15,R15        CHECK R15 FOR ZERO                        54750020
         BNZ   CIR08          NO, PROCESS ERROR BACK IN CIRROUT         54780020
*                                                                       54810020
         L     R2,CIRWK1      GET AREA POINTER                          54840020
         LR    R1,R2                                                    54870020
         LA    R3,D8          GET DECREMENT FACTOR                      54900020
         SR    R1,R3         POINT AT LINK FIELDS OF BLOCK              54930020
         ST    R2,D4(R1)       STORE IN BLOCK                           54960020
PTREXIT  EQU   *                                                        54990020
         ST    R1,CURNTBLK    POINT TO NEW BLOCK AS CURRENT             55020020
         LM    R0,R9,LOCSAVOF(R13)  REFRESH REGISTERS                   55050020
         BR    R8             RETURN TO CALLER                          55080020
CIRROUT  EQU   *                                                        55110020
         LA    R1,CIRPARM     PARM LIST FOR CALL MACRO                  55140020
         L     R15,CIRAD      ADDR OF CIR EP                            55170020
         CALL  (15)                                                     55200020
         B     CIRRC(R15)     ANALYZE RETURN CODE                       55230020
*                                                                       55260020
CIRRC    B     CIROK          RC=00 SUCCESSFUL OPERATION                55290020
         B     CIR04          RC=04 LOCATE FAILED                       55320020
         B     CIR08          RC=08 VOLUMES REQUEST-INCOMPATIBLE OPT    55350020
         B     CIR12          RC=12 VOLUMES FOUND-INCOMPATIBLE OPTIONS  55380020
*                                                                       55410020
IKJEHCR4 DS    0H                  RETURN CODE 4 FROM CIR               55430020
CIR04    EQU   *                                                        55450020
         L     R15,CIRPARM    GET LOCATE RETURN CODE                    55470020
         TM    FIRSTCIR,ON         IS THIS FIRST TIME                   55474020
         BNO   CIRNORM             NO USE REGULAR MESSAGE               55478020
         LA    R1,EIGHT            YES IS RC EQUAL EIGHT                55482020
         CR    R15,R1                                                   55486020
         BNE   CIRNORM             NO USE REGULAR MESSAGE               55490020
         BR    R8                  RETURN TO CALLER                     55494020
CIRNORM  MVI   ERR1,MSG02          UNABLE TO LIST CATALOG               55514020
         MVI   ERR2,SECMSG01      LOCATE ERROR CODE                     55540020
CIR04A   BAL   R8,CVDREG15    GO CONVERT R15 RETURN CODE                55620020
         BAL   R8,ERROUT      GO PUT OUT MESSAGE                        55650020
         B     WRAPUP         GO TERMINATE                              55680020
*                                                                       55710020
IKJEHCR8 DS    0H                  RETURN CODE 8 FROM CIR               55730020
CIR08    EQU   *                                                        55750020
         MVI   ERR1,MSG02         UNABLE TO LIST CATALOG                55770020
         MVI   ERR2,SECMSG02      CATALOG ERROR CODE                    55810020
         B     CIR04A         PROCESS AS RC=04                          55890020
CIROK    EQU   *                                                        55920020
CIR12    EQU   *                                                        55950020
         BR    R8             RETURN TO CALL.                           55980020
         EJECT                                                          56010020
OBTBLK   DS    0H                                                       56040020
*********************************************************************** 56070020
*                                                                       56100020
*        THIS ROUTINE IS ENTERED VIA 'BAL R8,OBTBLK' AND IS USED TO     56130020
*        OBTAIN A NEW BLOCK TO BE USED AS A WORK AREA FOR CIR AND       56160020
*        TO BECOME THE CURRENT BLOCK. IF NO FREE BLOCKS ARE AVAILABLE   56190020
*        THEN A CONDITIONAL GETMAIN IS ISSUED AND THE NEW BLOCK IS      56220020
*        ADDED ON THE CHAIN. IF THE GETMAIN FAILS, AN APPROPRIATE       56250020
*        DIAGNOSTIC IS PUT OUT AND AN ATTEMPT IS MADE TO CONTINUE       56280020
*        PROCESSING.                                                    56310020
*                                                                       56340020
*********************************************************************** 56370020
         STM   R0,R9,LOCSAVOF(R13)  SAVE REGISTERS LOCALLY.             56400020
         L     R1,FRSTBLK     GET PTR TO FIRST BLOCK.                   56430020
OBTBLK01 CLC   ENTPTR(D4,R1),ZERO     SEE IF THE ENTRY POINTER IS ZERO  56460020
         BE    OBTBLK03       YES, USE THIS BLOCK                       56490020
         CLC   D0(L4,R1),ZERO     SEE IF CHAIN ADDRESS IS ZERO          56520020
         BE    OBTBLK02       YES, ISSUE GETMAIN FOR ANOTHER BLOCK      56550020
         L     R1,0(R1)       NO, PICK UP CHAIN ADDRESS                 56580020
         B     OBTBLK01       GO CHECK NEXT BLOCK.                      56610020
OBTBLK02 LR    R3,R1          SAVE PTR TO CURRENT LAST BLK              56640020
         LA    R1,GETML       DOINT AT LIST FORM OF MACRO               56670020
         LA    R2,TEMPSAVE    ANSWER PLACE                              56700020
         GETMAIN A=(R2),LV=CIRBLKLN,SP=BLKSP,MF=(E,(1))                 56730020
         LTR   R15,R15        CHECK FOR RETURN CODE                     56760020
         BNZ   OBTBLK04       YES, PROCESS ERROR                        56790020
         L     R1,TEMPSAVE    GET NEW BLK ADDRESS                       56820020
         ST    R1,D0(R3)       CHAIN IT ONTO LAST BLK                   56850020
         XC    D0(L8,R1),D0(R1)     CLEAR ENTRY PTR AND CHAIN ADDR      56880020
OBTBLK03 EQU   *                                                        56910020
         ST    R1,CURNTBLK    SAVE IT AS CURRENT BLOCK                  56940020
         LA    R1,CIROFF(R1)       POINT AT CIR BLOCK                   56970020
         ST    R1,CIRWK1      PUT IN LIST                               57000020
         LM    R0,R9,LOCSAVOF(R13)  REFRESH REGISTERS                   57030020
         BR    R8             RETURN TO CALLER                          57060020
OBTBLK04 EQU   *                                                        57090020
*                                                                       57120020
*        THIS ROUTINE OUTPUTS AN ERROR MESSAGE WITH THE NAME OF THE     57150020
*        INDEX STRUCTURE THAT COULD NOT BE PROCESSED, THEN RETURNS      57180020
*        TO THE MAINLINE IN AN EFFORT TO PROCESS REMAINING NAMES.       57210020
*                                                                       57240020
         MVI   ERR1,MSG04         INDEX CANT BE PROCESSED               57270020
OBTBLK45 EQU   *                                                        57390020
         LA    R1,ERRINSRT+D1  POINT TO INSERT AREA                     57420020
         BAL   R8,BUILDNAM    BUILD NAME IN INSERT AREA                 57450020
         LA    R2,ERRINSRT+D1  ADDR OF START OF NAME                    57480020
         SR    R1,R2          COMPUTE LENGTH OF NAME                    57510020
         STC   R1,ERRINSRT    STORE LENGTH                              57540020
         LA    R1,ERRINSRT    PUT ADDRESS OF INSERT DATA                57570020
         ST    R1,ERRINST1   INTO PARM LIST FOR FIRST LEVEL MESSAGE     57600020
         BAL   R8,ERROUT      GO PUT OUT MESSAGE                        57660020
         LA    R7,OUTBUF      POINT AT BUFFER                           57690020
         B     MAIN01A        GO PROCESS NEXT ENTRY                     57780020
BUILDNAM EQU   *                                                        57810020
         L     R2,FRSTBLK     GET FIRST BLK PTR                         57840020
         L     R3,D4(R2)       GET CURRENT ENTRY POINTER                57870020
OBTBLK05 MVC   D0(L8,R1),D1(R3)  MOVE QUALIFIER TO INSERT AREA          57900020
         LA    R1,D8(R1)       POINT BEYOND NAME                        57930020
OBTBLK06 BCTR  R1,R0          BACKUP POINTER BY ONE AND                 57960020
        CLI   D0(R1),BLANK    TRUNCATE BLANKS.IS IT A BLANK             57990020
         BE    OBTBLK06       YES, TRY AGAIN                            58020020
         LA    R1,D1(R1)       POINT JUST BEYOND NAME                   58050020
         L     R2,D0(R2)       GET NEXT BLOCK                           58080020
         LTR   R2,R2          SEE IF ADDRESS IS ZERO                    58110020
         BZ    OBTBLK07       YES, WE ARE DONE                          58140020
         CLC   D4(L4,R2),ZERO   IS ENTRY PTR ZERO                       58170020
         BE    OBTBLK07       YES, WE ARE DONE                          58200020
         L     R3,ENTPTR(R2)       NO, PICK UP PTR                      58230020
        MVI   D0(R1),PERIOD   PLACE PERIOD AFTER LAST QUALIFIER         58260020
         LA    R1,D1(R1)       UPDATE POINTER                           58290020
         B     OBTBLK05       PROCESS NEXT QUALIFIER                    58320020
OBTBLK07 BR    R8             RETURN TO CALLER                          58350020
*                                                                       58380020
         EJECT                                                          58410020
IKJEHWRT DS    0H                  WRITE ROUTINE                        58430020
WRITE    EQU   *                                                        58450020
*********************************************************************** 58470020
*                                                                     * 58500020
*   INPUT TO THIS ROUTINE IS THE BUFFER ADDRESS IN REG7 AND END       * 58530020
*   OF BUFFER ADDRESS IN REG 14. RETURN ADDRESS IS IN REG8.           * 58560020
*                                                                       58590020
*   THE OUTPUT BUFFER IS CLEARED AND RETURNED IN REG7.                  58620020
*   TRAILING BLANKS WILL BE ELIMINATED.                                 58650020
*                                                                       58680020
*  IMPORTANT---THIS ROUTINE REQUIRES NO BASE REGISTER. KEEP IT THAT     58710020
*  WAY SO THAT IKJEHMEM CAN USE IT.(SEE CALL PARAMETERS)                58740020
*                                                                       58770020
*********************************************************************** 58800020
         STM   R0,R9,LOCSAVOF(R13)  SAVE REGISTERS LOCALLY              58830020
         LR    R2,R14         GET END OF DATA POINTER                   58860020
         SR    R2,R7          CALCULATE DATA LENGTH                     58890020
         LA    R1,D4           DECREMENT BUFFER POINTER BY 4,           58920020
         SR    R7,R1          SO R7 WILL POINT AT LL FIELD              58950020
         LA    R2,D4(R2)      BUMP LENGTH FOR LL AND OFFSET FIELDS      58980020
         STH   R2,D0(R7)       STORE LENGTH                             59010020
        XC    D2(L2,R7),D2(R7)   CLEAR OFFSET BYTE                      59040020
         LR    R6,R7          PUT OUTPUT LINE POINTER IN PROPER         59070020
         LA    R1,PARMLSTL    POINT INFRONT OF BUFFER TO PARAMETER LIST 59100020
         SR    R7,R1          CONTAING VARIOUS ADCONS. (SEE DSECT)      59130020
         LM    R1,R5,D0(R7)    SET UP REGISTERS FOR PUTLINE             59160020
         L     R15,PARMLSTL-D4(R7) GET ENTRY POINT.                     59190020
         PUTLINE PARM=(R2),UPT=(R3),ECT=(R4),ECB=(R5),OUTPUT=((R6),    X59220020
               DATA),ENTRY=(15),MF=(E,(1))                              59250020
         LA    R7,PARMLSTL+D4(R7) POINT BACK TO DATA BUFFER             59400020
*                                                                       59430020
        MVI   D0(R7),BLANK    MOVE IN BLANK                             59460020
         MVC   D1(L'OUTBUF-D1,R7),D0(R7)  CLEAR BUFFER                  59490020
         LM    R0,R9,LOCSAVOF(R13)  RESTORE CALLERS REGISTER            59520020
         BR    R8                  RETURN TO CALLER                     59550020
*                                                                       59580020
*                                                                       59610020
         EJECT                                                          59640020
IKJEHERR DS    0H                 ERROR RTN                             59660020
ERROUT   EQU   *                                                        59680020
*********************************************************************** 59700020
*                                                                       59730020
*    THIS ROUTINE IS ENTERED VIA A 'BAL R8,ERROUT' INSTRUCTION SEQUENCE 59760020
*    AND IS USED TO OUTPUT ERROR MESSAGES. INPUT IS A THREE WORD LIST   59790020
*    CALLED ERRPARM WHICH CONTAINS INFORMATION AS FOLLOWS.              59820020
*                                                                       59850020
*                    BYTE 1 AND 2 - THE RELATIVE POSITION OF THE FIRST  59880020
*                             LEVEL MESSAGE IN THE MESSAGE CSECT        59910020
*                    BYTE 3 AND 4 - THE RELATIVE POSITION OF THE        59940020
*                             SECOND LEVEL MESSAGE IN THE STRING.       59970020
*                    SECOND WORD  - POINTS TO TEXT TO BE INSERTED AFTER 60000020
*                             FIRST SEGMENT OF FIRST LEVEL MESSAGE.     60030020
*                    THIRD WORD   - POINTS TO TEXT TO BE INSERTED AFTER 60060020
*                             FIRST SEGMENT OF SECOND LEVEL MESSAGE.    60090020
*                                                                       60120020
*                                                                       60150020
*********************************************************************** 60180020
         STM   R0,R9,LOCSAVOF(R13)       SAVE LOCAL REGISTERS           60210020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 60220020
         LA    R7,OUTBUF+D4    POINT AT PROPER BUFFER OFFSET            60240020
         LH    R1,ERRPARM     RELATIVE MESSAGE NUMBER                   60270020
         BCTR  R1,R0          DECREMENT POSITION COUNT                  60300020
         SLL   R1,D3           MULTIPLY BY 8 TO GET INDEX INTO TABLE    60330020
         L     R6,MSGCSECT    PICK UP VCON FOR CSECT                    60360020
         LA    R5,D0(R6,R1)   TABLE ENTRY FOR PROPER MSG                60390020
         LH    R1,D0(R5)       LENGTH OF MESSAGE                        60420020
         LA    R2,D4(R1)       BUMP FOR LL AND OFFSET FIELDS            60450020
         STH   R2,OUTBUF     SAVE LENGTH                                60480020
         XC    OUTBUF+D2(L2),OUTBUF+D2  CLEAR OFFSET FIELD              60510020
         LH    R4,D2(R5)       OFFSET TO MESSAGE IN CSECT               60540020
         LA    R3,D0(R6,R4)    POINTER TO MESSAGE IN CSECT              60570020
         BCTR  R1,R0          DECREMENT COUNT FOR EX OF MVC             60600020
         EX    R1,MOVE        MOVE MESSAGE TO BUFFER                    60630020
         LA    R7,D1(R1,R7)    POINT BEYOND MESSAGE                     60660020
         L     R4,ERRINST1   PICKUP INSERT POINTER                      60690020
         LTR   R4,R4          TEST FOR ZERO                             60720020
         BZ    SEGCHECK       IF ZERO, CHECK FOR SEGMENTATION           60750020
         XR    R1,R1                                                    60780020
         IC    R1,D0(R4)       GET LENGTH OF INSERT DATA                60810020
         LA    R3,D1(R4)       POINT AT INSERT DATA                     60840020
         LH    R2,OUTBUF     GET LENGTH                                 60870020
         LA    R2,D0(R2,R1)    INCREMENT COUNT                          60900020
         STH   R2,OUTBUF     SAVE IT AGAIN                              60930020
         BCTR  R1,R0               DECREMENT CNTR                       60960020
         EX    R1,MOVE        MOVE INSERT DATA TO BUFFER                60990020
         LA    R7,D1(R1,R7)                                             61020020
SEGCHECK EQU   *                                                        61050020
         LH    R4,D4(R5)       PICKUP OFFSET OF SEGMENT                 61080020
         LTR   R4,R4          TEST FOR ZERO                             61110020
         BZ    SECLVTST      CHECK SECOND LEVEL                         61140020
         LA    R4,D0(R4,R6)    POINT AT SEGMENT TABLE                   61170020
SEGLOOP  EQU   *                                                        61200020
         LH    R1,D0(R4)       PICK UP LENGTH OF SEGMENT                61230020
         LTR   R1,R1         TEST CONTENTS OF REGISTERS                 61260020
         BZ    SECLVTST      CHECK FOR SECOND LEVEL                     61290020
         LH    R2,OUTBUF     GET LENGTH                                 61320020
         LA    R2,D0(R2,R1)    INCREMENT COUNT                          61350020
         STH   R2,OUTBUF     SAVE IT AGAIN                              61380020
         LH    R3,D2(R4)       PICKUP OFFSET TO SEGMENT                 61410020
        LA    R3,D0(R3,R6)   CALCULATE ADDRESS                          61440020
         BCTR  R1,R0          DECREMENT FOR MOVE                        61470020
         EX    R1,MOVE        MOVE SEGMENT TO BUFFER                    61500020
         LA    R7,D1(R7,R1)    POINT AT END OF DATA IN BUFFER           61530020
         LA    R4,D4(R4)      NEXT SEGMENT SLOT IN TABLE                61560020
         B     SEGLOOP       PROCESS ANOTHER SEGMENT                    61590020
SECLVTST EQU   *                                                        61620020
*                                                                       61650020
*    CHECK FOR SECOND LEVEL MESSAGE AND PROCESS RTN *                   61680020
*                                                                       61710020
         LA    R1,L1               SEGMENT COUNT IS ONE                 61740020
         ST    R1,MSP11       PUT IN LIST                               61770020
         LA    R1,OUTBUF                                                61800020
         ST    R1,MSP12       SAVE POINTER TO MESSAGE                   61830020
         LH    R1,ERRSECND    CHECK SECOND LEVEL                        61860020
         LTR   R1,R1                                                    61890020
         BZ    NOSECLVL            NO SECOND LEVEL MESSAGE              61920020
         BCTR  R1,R0          DECREMENT POSITION COUNT                  61950020
         LA    R0,D6          TABLE ENTRY SIZE                          61980020
         MR    R0,R0         OFFSET INTO TABLE CALCULATED               62010020
         LH    R4,D6(R5)      OFFSET TO SECOND LEVEL TABLE              62040020
         LA    R4,D0(R4,R6)    ADDRESS OF TABLE                         62070020
         LA    R5,D0(R4,R1)   ADDRESS OF ENTRY IN TABLE                 62100020
         LA    R7,SECBUFF+D4  POINT TO SECOND BUFFER OFFSET             62130020
         LH    R1,D0(R5)      GET LENGTH OF ENTRY                       62160020
         LA    R2,D4(R1)     BUMP LENGTH FOR LL AND OFFSET FIELDS       62190020
         STH   R2,SECBUFF    SAVE LENGTH OF FIRST SEGMENT               62220020
         XC    SECBUFF+D2(L2),SECBUFF+D2  CLEAR OFFSET FIELD            62250020
         LH    R4,D2(R5)      OFFSET TO MESSAGE IN CSECT                62280020
         LA    R3,D0(R6,R4)   ADDRESS OF MESSAGE IN CORE                62310020
         BCTR  R1,R0         DECREMENT LENGTH FOR EX OF MOVE            62340020
         EX    R1,MOVE        MOVE MESSAGE SEGMENT TO BUFFER            62370020
         LA    R7,D1(R1,R7)     BUMP BUFFER POINTER                     62400020
         MVC   SECBUFF+D10(L2),OUTBUF+D10   SET ID FOR SECND LEVEL      62430020
         L     R4,ERRINST2    GET INSERT POINTER                        62460020
         LTR   R4,R4         TEST FOR ZERO                              62490020
         BZ    SECSEGCK      IF ZERO, CHECK SEGMENTATION                62520020
         XR    R1,R1                                                    62550020
         IC    R1,D0(R4)      GET LENGTH OF INSERT DATA                 62580020
         LH    R2,SECBUFF                                               62610020
         LA    R2,D0(R2,R1)   UPDATE LENGTH OF BUFFER MESSAGE           62640020
         STH   R2,SECBUFF    SAVE AGAIN                                 62670020
         LA    R3,D1(R4)      POINT AT DATA                             62700020
         BCTR  R1,R0         DECREMENT COUNT FOR MOVE                   62730020
         EX    R1,MOVE       MOVE IT TO BUFFER                          62760020
         LA    R7,D1(R1,R7)    UPDATE BUFFER POINTER                    62790020
SECSEGCK EQU   *                                                        62820020
         LA    R1,D1          SET SEGMENT COUNT TO ONE                  62850020
         ST    R1,MSP22       PUT IN LIST                               62880020
         LA    R1,SECBUFF    PUT BUFFER ADDRESS INTO LIST               62910020
        ST    R1,MSP23                                                  62940020
         LA    R1,MSGPARM2   CHAIN MSG LEVEL PARM LISTS                 62970020
         ST    R1,MSGPARM1                                              63000020
         XC    MSGPARM2,MSGPARM2   CLEAR CHAIN WORD                     63030020
         MVI   MSGPARM2,FOXES      INDICATE END OF CHAIN         100000 63060021
         LH    R4,D4(R5)      OFFSET TO SEGMENT TABLE                   63120020
         LTR   R4,R4         TEST FOR ZERO                              63150020
         BZ    PUTMSG        IF ZERO, PUT OUT MESSAGE                   63180020
         LA    R4,D0(R4,R6)   ADDRESS OF SEGMENT TABLE                  63210020
         LH    R1,D0(R4)      LENGTH OF SEGMENT                         63240020
SECSEGLP EQU   *                                                        63270020
         LTR   R1,R1         SEE IF THIS IS THE LAST                    63300020
         BZ    PUTMSG        YES, GO                                    63330020
         LH    R2,SECBUFF    UPDATE THE LENGTH FIELD                    63360020
         LA    R2,D0(R2,R1)                                             63390020
         STH   R2,SECBUFF    RE-STORE IT                                63420020
         LH    R3,D2(R4)      OFFSET TO SEGMENT                         63450020
         LA    R3,D0(R3,R6)   ADDRESS OF MESSAGE                        63480020
         BCTR  R1,R0         DECREMENT COUNT FOR MOVE                   63510020
         EX    R1,MOVE        MOVE IT TO BUFFER                         63540020
         LA    R7,D1(R7,R1)   UPDATE BUFFER OFFSET                      63570020
         LA    R4,D4(R4)      GET NEXT SEGMENT                          63600020
         B     SECSEGLP            LOOP TO DO NEXT SEGMENT              63630020
NOSECLVL EQU   *                                                        63660020
         XC    MSGPARM1,MSGPARM1   CLEAR SECOND LEVEL POINTER           63690020
         MVI   MSGPARM1,FOXES      INDICATE END OF CHAIN                63720020
PUTMSG   EQU   *                                                        63750020
         LM    R3,R5,UPTPTR  LOAD UPT, ECT, ECB                         63780020
         LA    R6,MSGPARM1   POINT TO OUTPUT PARM LIST                  63810020
         LA    R2,DPUTLINE   LIST FORM OF MACRO                         63840020
         LA    R1,PUTLLIST   LIST FOR E FORM OF MACRO                   63870020
         L     R15,PUTLADDR  ADDRESS OF PUTLINE ROUTINE                 63900020
*                                                                       63930020
         PUTLINE PARM=(R2),UPT=(R3),ECT=(R4),ECB=(R5),                 X63960020
               OUTPUT=((R6),MULTLVL),ENTRY=(15),MF=(E,(1))              63990020
         XC    ERRPARM(ERRLIST),ERRPARM    CLEAR ERROR LIST             64000020
         LM    R0,R9,LOCSAVOF(R13)       RESTORE LOCAL REGISTERS        64020020
         BR    R8             RETURN                                    64050020
         EJECT                                                          64080020
*********************************************************************** 64110020
*                                                                       64140020
*        THIS ROUTINE IS USED TO CONVERT THE RETURN CODE IN REG 15      64170020
*        TO DECIMAL AND ENTER A POINTER TO THE RESULTING DATA PRECEDED  64200020
*        BY A LENGTH FIELD  INTO THE PARAMETER LIST FOR THE ERROR       64230020
*        PROCESSING ROUTINE .  IT IS ENTERED AS INSERT DATA FOR THE     64260020
*        SECOND  LEVEL MESSAGE SINCE THIS IS THE ONLY PLACE IT IS EVER  64290020
*        USED.                                                          64320020
*********************************************************************** 64350020
CVDREG15 DS    0H                                                       64380020
         CVD   R15,ERRINSRT+D8 CONVERT TO DECIMAL                       64410020
         UNPK  ERRINSRT+D1(L4),ERRINSRT+ERRCOD(L3)  UNPK TWO            64440020
         MVI   ERRINSRT,D2     MOVE IN LENGTH OF TWO                    64470020
         LA    R1,ERRINSRT    PLACE INSERT ADDRESS IN                   64500020
         ST    R1,ERRINST2     2ND LEVEL MESSAG SLOT                    64530020
         BR    R8                 RETURN TO CALLER                      64590020
************************************************************            64620020
         EJECT                                                          64650020
*  MACRO 'LIST' FORMS, INSTRUCTIONS EXECUTED BY 'EX', AND CONSTANTS.    64680020
*                                                                       64710020
*                                                                       64740020
         DS    0F                                                       64770020
*                                                                       64800020
TPUTMDL  PUTLINE MF=L                                                   64830020
ENDTPUT  EQU   *                                                        64860020
LTPUTL   EQU   ENDTPUT-TPUTMDL                                          64890020
*                                                                       64920020
OLFS     EQU   *                   BEGINNING OF LIST FORMS FOR OBTWAD   64950020
RDJMDL   RDJFCB  (,(INPUT)),MF=L                                        64980020
*                                                                       65010020
CLSTMDL  CAMLST  SEARCH,1,2,3                                           65040020
*                                                                       65070020
DCBMDL   DCB   DSORG=PS,MACRF=R,RECFM=F,BLKSIZE=256,KEYLEN=8,LRECL=256,C65100020
               DDNAME=DUMMY                                             65130020
         SPACE 3                                                        65160020
OPENMDL  OPEN  (,),MF=L            MODEL FOR THE LIST FORM OF OPEN      65190020
         SPACE                                                          65220020
READMDL  READ  RMDECB,SF,,,'S',,,MF=L   MODEL FOR THE LIST FORM OF READ 65250020
         SPACE                                                          65280020
CLOSEMDL CLOSE (,),MF=L            MODEL FOR THE LIST FORM OF CLOSE     65310020
EOLFS    EQU   *                   END OF LIST FORMS FOR OBTWAD         65340020
LOLFS    EQU   EOLFS-OLFS          LENGTH OF AREA TO MOVE               65370020
         SPACE 2                                                        65400020
         DS    0F                                                       65430020
ILFS     EQU   *                   BEGINNING OF LIST FORMS FOR INITCORE 65460020
GETMLMDL GETMAIN  EC,MF=L                                               65490020
*                                                                       65520020
FREEMMDL FREEMAIN  E,MF=L                                               65550020
*                                                                       65580020
EILFS    EQU   *                   END OF LIST FORMS FOR INITCORE       65610020
LILFS    EQU   EILFS-ILFS          LENGTH OF LIST FORMS FOR INITCORE    65640020
*                                                                       65670020
HEADING  DC    C'--DSORG--CREATED---EXPIRES---SECURITY'                 65700020
MOVE     MVC   D0(L0,R7),D0(R3)    MVC INSTRUCTION FOR MOVES     100000 65730021
CLEAR    MVC   D1(L0,R7),D0(R7)    MVC INSTRUCTION FOR MOVES     100000 65760021
VCONHIST DC    V(IKJEHHST)         ADDRESS OF HISTORY RTN               65790020
VCONVOL  DC    V(IKJEHVOL)         ADDRESS OF VOLUME RTN                65820020
VCONMEM  DC    V(IKJEHMBR)         ADDRESS OF MEMBER RTN                65850020
MSGCSECT DC    V(IKJEHCTM)                                              65880020
PARSCON1 DC    V(IKJEHPRM)                                              65910020
*                                                                       65940020
ZERO     DC    F'0'                                                     65970020
FOXMASK  DC    X'FFFFFFFF'         MASK TO COMPLEMENT GENERATION NUMBER 65980020
NHISTORY DC    C'HISTORY'          HISTORY                       A49872 65990021
NMEMBERS DC    C'MEMBERS'          MEMBERS                       A49872 65992021
NBOTH    DC    C'HISTORY AND MEMBERS' BOTH                       A49872 65994021
         EJECT                                                          66000020
IKJEHPRM IKJPARM                                                        66030020
PHIST    IKJKEYWD                                                       66060020
         IKJNAME  'HISTORY'                                             66090020
PMEM     IKJKEYWD                                                       66120020
         IKJNAME  'MEMBERS'                                             66150020
PVOLUMES IKJKEYWD                                                       66180020
        IKJNAME  'VOLUMES'                                              66210020
PLEVEL   IKJKEYWD                                                       66240020
         IKJNAME 'LEVEL',SUBFLD=PNODE                                   66270020
PNODE    IKJSUBF                                                        66300020
PNODE1   IKJPOSIT  DSTHING,PROMPT='INDEX TO BE LISTED'   REQUIRED       66330020
         IKJENDP                                                        66360020
       EJECT                                                            66390020
*                                                                       66420020
WORKCORE DSECT                                                          66450020
STRTDSCT EQU   *             START OF DSECT                             66480020
SAVE     DS    28F           SAVE AREA                                  66510020
GETML    GETMAIN EC,MF=L                                                66540020
FREEML   FREEMAIN E,MF=L                                                66570020
OBTWA    DS    A              FOR ADDR OF CORE FOR OBT WORK AREA.       66600020
USRNODEL DS    H                                                        66630020
USERNODE DS    CL44          USERID OR NODE IS KEPT HERE                66660020
OPTMASK  DS    CL1           MASK OF USER OPTIONS SPECIFIED IN COMMAND. 66690020
FIRSTIME DS    CL1                ALLOCATE FIRST TIME  SWITCH           66700020
FIRSTCIR DS    CL1                FIRST TIME SWITCH FOR CIRROUT         66710020
STACKSW  DS    CL1                 INDICATE FLUSH STACK AND CLEAR QUEUE 66712020
STACKPRM DS    2F                  STACK PARM BLOCK                     66714020
PARDSECT DS    F             FOR ADDRESS OF PARSE DSECT                 66720020
*********************************************************************** 66750020
*                                                                       66780020
*        THE FOLLOWING CONSTANTS, BUFFER AND PUTLINE MACRO MUST ALL     66810020
*        APPEAR TOGETHER IN THE SPECIFIED ORDER SO THAT THE WRITE       66840020
*        ROUTINE WILL REMAIN INDEPENDANT OF A BASE REGISTER.            66870020
*                                                                       66900020
*********************************************************************** 66930020
PARMLSTS DS    0F                                                       66960020
PUTLCON  DS    F              PTR TO LIST FOR PUTLINE MACRO             66990020
DPUTLCON DS    F              PTR TO PUTLINE LIST FORM                  67020020
UPTPTR   DS    F              UPT PTR                                   67050020
ECTPTR   DS    F              ECT PTR                                   67080020
ECBPTR   DS    F              CP ECB PTR                                67110020
PUTLADDR DS    F              ENTRY POINT OF PUTLINE                    67140020
PARMLSTL EQU   *-PARMLSTS                                               67170020
*                                                                       67200020
         DS    F              LL AND OFF FIELDS FOR OUTPUT LINES        67230020
OUTBUF   DS    CL108              COMMON OUTPUT BUFFER                  67260020
DPUTLINE PUTLINE MF=L                                                   67290020
*                                                                       67320020
*                                                                       67350020
*   AREA FOR SERVICE ROUTINE PARAMETER LIST USED BY ROUTINE             67380020
*                                                                       67410020
PUTLLIST DS    0F            ENTRY POINT OF PARMLIST                    67440020
SRPLUPT  DS    1F            UPT POINTER                                67470020
SRPLECT  DS    1F            ECT POINTER                                67500020
SRPLECB  DS    1F            ECB POINTER                                67530020
SRPLPSCB DS    0F            PSCB POINTER                               67560020
SRPLPCL  DS    1F            PCL POINTER                                67590020
SRPLDRPM DS    0F            DAIR PARM PTR                              67620020
SRPLANPL DS    1F            ANSWER PLACE PTR                           67650020
SRPLBUFF DS    1F            COMMAND BUFF PTR                           67680020
SRPLUWA  DS    1F            USER WORK AREA                             67710020
*                                                                       67740020
*   END OF SERVICE AREA ROUTINE PARMLIST                                67770020
*                                                                       67800020
CPECB    DS    F              CP ECB                                    67830020
PSCBPTR  DS    F              PSCB PTR                                  67860020
MEMMOD   DS    F    HOLDS ADDRESS OF MEMBERS MODULE                     67950020
CIRAD    DS    F              ADDR OF EP TO CIR                         67980020
PREFIXNM DS    21H            PREFIX * NAME                             68010020
SUFFIXNM DS    21H            SUFFIX * NAME                             68040020
         DS    0D                  ALIGN LOCATE WORKAREA          M2136 68042021
VOLBLK   DS    CL265               VOL CONTROL BLK CURRENT ENTRY  M2136 68050021
         EJECT                                                          68070020
*********************************************************************** 68100020
*                                                                       68130020
*   THESE THREE WORDS ARE USED TO PASS INFORMATION TO THE ERROR         68160020
*   HANDLER WHICH WILL INTERPRET THEM TO CORRESPOND TO A FIRST AND      68190020
*   SECOND LEVEL MESSAGE WITH INSERT INFORMATION.                       68220020
*                                                                       68250020
*********************************************************************** 68280020
ERRPARM  DS    0F             PARAMETER LIST FOR ERROR HANDLER          68310020
ERRFIRST DS    H              RELATIVE FIRST LEVEL MSG NUMBER           68340020
ERRSECND DS    H              RELATIVE SECOND LEVEL MSG NUMBER          68370020
ERRINST1 DS    F              INSERT DATA FOR FIRST LEVEL MSG           68400020
ERRINST2 DS    F              INSERT DATA FOR SECOND LEVEL MSG          68430020
ERREND   EQU   *                                                        68436020
ERRLIST  EQU   ERREND-ERRPARM     SIZE OF ERROR LIST                    68442020
ERR1     EQU   ERRFIRST+D1                                              68448020
ERR2     EQU   ERRSECND+D1                                              68454020
         EJECT                                                          68460020
CURNTBLK DS    F              PTR TO CURRENT BLOCK FROM CIR.            68490020
FRSTBLK  DS    F              PTR TO FIRST BLOCK IN CHAIN.              68520020
         DS    0D                                                       68550020
CIRBLOCK DS    4CL280         WORKAREAS FOR CIR--DOUBLWORD ALLIGNED     68580020
CIRBLKLN EQU   L'CIRBLOCK     LENGTH OF ONE CIRBLOCK.                   68610020
*                                                                       68640020
*                                                                       68670020
*     PARMLIST FOR CIR RTN    *********                                 68700020
CIRPARM  DS    0F            BEGIN OF PARMLIST                          68730020
CIROPTNS DS    1F            OPTIONS USED                               68760020
CIRINDX  DS    1F            ADDR OF INDEXNAMES OR TTR                  68790020
CIRVOL   DS    1F            ADDR OF VOLID OF CVOL                      68820020
CIRWK1   DS    1F            ADDR OF WORKAREA1                          68850020
CIRWK2   DS    1F            ADDR OF WORKAREA2                          68880020
*                                                                       68910020
*    END OF CIR PARMLIST                                                68940020
*                                                                       68970020
*                                                                       69000020
CIRSAVE  DS    28F            SAVEAREA FOR CIR PLUS SUBROUTINES         69030020
CIRTTR   DS    CL3            HOLDS TTR OF NEXT BLOCK FOR CIRROUT       69060020
CIRCVOL  DS    CL6            HOLDS CVOL VOLID FOR NEXT BLOCK           69090020
CALLCIR  DS    F              CALL LIST FOR CIR                         69120020
         DS    0D                                                       69150020
ERRINSRT DS    CL45           USED FOR INSERTING DATA IN A MESSAGE      69180020
SECBUFF  DS    20F            SECOND BUFFER FOR ERROR MESSAGES          69210020
PREVBLK  DS    F              USED BY POINTER ROUTINE                   69240020
CURNTNAM DS    H              CONTAINS LENGTH OF TEMPNAME FOR DAIR      69270020
TEMPNAME DS    CL52           USED TO CONTAIN FULLY QUALIFIED NAME      69300020
GDGCNT   DS    F              GDG COUNT OF GENERATIONS                  69330020
DAIRLIST DS    20F            DAIR PARAMETER LIST                       69360020
SAVEMEM  DS    F             SAVE MEM RETURN CODE                       69390020
SAVEDDN  DS    CL8                DDNAME SAVE AREA                      69420020
RETCD  DS    F                  RETURN CODE FOR TMP                     69450020
**************        *******       *********                           69480020
MSGPARM1 DS   F   PARM LIST FOR FIRST LEVEL MSG INFO                    69510020
MSP11    DS    F    PARM+4                                              69540020
MSP12    DS    F    PARM+8                                              69570020
MSGPARM2 DS   F    PARM LIST FOR SECOND LEVEL MSG INFO                  69600020
MSP22    DS    F   PARM+4                                               69630020
MSP23    DS    F   PARM+8                                               69660020
**************              ******************                          69690020
TEMPSAVE DS    F                                                        69720020
ENDDSCT  EQU   *             END OF WORKCORE DSECT                      69750020
WORKSIZE EQU   ENDDSCT-STRTDSCT   SIZE OF WORKAREA                      69780020
       EJECT                                                            69810020
    IKJEHCOM                                                            69840020
         DCBD  DSORG=PS                                                 69870020
         EJECT                                                          69900020
         IKJDAP08                                                       69930020
         EJECT                                                          69960020
         IKJDAP2C                                                       69990020
        IKJDAPL                                                         70020020
        IKJPPL                                                          70050020
         IKJCPPL                                                        70080020
         CVT                                                            70090020
          EJECT                                                         70110020
         IKJPSCB                                                        70140020
         EJECT                                                   100000 70190021
IKJEHCTM CSECT                                                        * 70230020
*********************************************************************** 70260020
*                                                                     * 70290020
*        THIS MODULE CONTAINS THE MESSAGES USED BY THE LISTCAT COMMAND* 70410020
*        THE CSECT BEGINS WITH A TABLE OF 8 BYTE ENTRIES, ONE FOR     * 70950020
*        EACH FIRST LEVEL MESSAGE. THE FIRST HWORD OF EACH ENTRY      * 70980020
*        CONTAINS THE LENGTH OF A MESSAGE. THE SECOND HWORD CONTAINS  * 71010020
*        THE OFFSET TO THE MESSAGE IN THE CSECT. THE THIRD HWORD      * 71040020
*        CONTAINS THE OFFSET TO THE SEGMENT CHAIN IF MORE THAN ONE    * 71070020
*        MESSAGE SEGMENT EXISTS FOR A PARTICULAR MESSAGE. THE FOURTH  * 71100020
*        AND LAST HALFWORD POINTS TO A TABLE DESCRIBING SECOND LEVEL  * 71130020
*        MESSAGES.                                                    * 71160020
*                                                                     * 71250020
*        THE TABLE DESCRIBING SECOND LEVEL MESSAGES IS MADE UP OF     * 71280020
*        6 BYTE ENTRIES. A 2 BYTE LENGTH, A 2 BYTE MESSAGE OFFSET,    * 71310020
*        AND A 2 BYTE SEGMENT CHAIN OFFSET.                           * 71340020
*                                                                     * 71370020
*                                                                     * 71490020
*********************************************************************** 71520020
STARTCTM DS    0F             ALLIGN ON A FULL WORD BOUNDARY            71550020
         DC    AL2(L'MSGE1)   LENGTH OF MESSAGE                         71580020
         DC    AL2(MSGE1-STARTCTM) OFFSET TO MESSAGE                    71610020
         DC    AL2(0)         OFFSET TO SEGMENT CHAIN                   71640020
         DC    AL2(SECLEVEL-STARTCTM) OFFSET TO SECOND LEVEL TABLE      71670020
         DC    AL2(L'MSGE2)                                             71700020
         DC    AL2(MSGE2-STARTCTM)                                      71730020
         DC    AL2(0)                                                   71760020
         DC    AL2(SECLEVEL-STARTCTM)                                   71790020
         DC    AL2(L'MSGE3)                                             71820020
         DC    AL2(MSGE3-STARTCTM)                                      71850020
         DC    AL2(0)                                                   71880020
         DC    AL2(SECLEVEL-STARTCTM)                                   71910020
         DC    AL2(L'MSGE4)                                             71940020
         DC    AL2(MSGE4-STARTCTM)                                      71970020
         DC    AL2(OFFSEG4-STARTCTM)                                    72000020
         DC    AL2(SECLEVEL-STARTCTM)                                   72030020
         DC    AL2(L'MSGE5)                                             72060020
         DC    AL2(MSGE5-STARTCTM)                                      72090020
         DC    AL2(OFFSEG5-STARTCTM)                                    72120020
         DC    AL2(SECLEVEL-STARTCTM)                                   72150020
         DC    AL2(L'MSGE6)                                             72180020
         DC    AL2(MSGE6-STARTCTM)                                      72210020
         DC    AL2(OFFSEG6-STARTCTM)                                    72240020
         DC    AL2(SECLEVEL-STARTCTM)                                   72270020
         DC    AL2(L'MSGE7)                                             72300020
         DC    AL2(MSGE7-STARTCTM)                                      72330020
         DC    AL2(0)                                                   72360020
         DC    AL2(SECLEVEL-STARTCTM)                                   72390020
         DC    AL2(L'MSGE8)                                             72420020
         DC    AL2(MSGE8-STARTCTM)                                      72450020
         DC    AL2(OFFSEG8-STARTCTM)                             A49872 72480021
         DC    AL2(SECLEVEL-STARTCTM)                                   72510020
         DC    AL2(L'MSGE9)                                             72540020
         DC    AL2(MSGE9-STARTCTM)                                      72570020
         DC    AL2(0)                                                   72600020
         DC    AL2(SECLEVEL-STARTCTM)                                   72630020
         DC    AL2(L'MSGE10)                                            72660020
         DC    AL2(MSGE10-STARTCTM)                                     72690020
         DC    AL2(0)                                                   72720020
         DC    AL2(SECLEVEL-STARTCTM)                                   72750020
         DC    AL2(L'MSGE11)                                            72780020
         DC    AL2(MSGE11-STARTCTM)                                     72810020
         DC    AL2(0)                                                   72840020
         DC    AL2(SECLEVEL-STARTCTM)                                   72870020
         DC    AL2(L'MSGE12)                                            72900020
         DC    AL2(MSGE12-STARTCTM)                                     72930020
         DC    AL2(OFFSEG12-STARTCTM)                                   72960020
         DC    AL2(SECLEVEL-STARTCTM)                                   72990020
         DC    AL2(L'MSGE13)                                            73020020
         DC    AL2(MSGE13-STARTCTM)                                     73050020
         DC    AL2(OFFSEG13-STARTCTM)                                   73080020
         DC    AL2(SECLEVEL-STARTCTM)                                   73110020
         DC    AL2(L'MSGE14)                                            73140020
         DC    AL2(MSGE14-STARTCTM)                                     73170020
         DC    AL2(OFFSEG14-STARTCTM)                                   73200020
         DC    AL2(SECLEVEL-STARTCTM)                                   73230020
         DC    AL2(L'MSGE15)                                            73260020
         DC    AL2(MSGE15-STARTCTM)                                     73290020
         DC    AL2(OFFSEG15-STARTCTM)                                   73320020
         DC    AL2(SECLEVEL-STARTCTM)                                   73350020
         DC    AL2(L'MSGE16)                                            73353020
         DC    AL2(MSGE16-STARTCTM)                                     73356020
         DC    AL2(OFFSEG16-STARTCTM)                                   73359020
         DC    AL2(SECLEVEL-STARTCTM)                                   73362020
         DC    AL2(L'MSGE17)                                            73365020
         DC    AL2(MSGE17-STARTCTM)                                     73368020
         DC    AL2(OFFSEG17-STARTCTM)                                   73371020
         DC    AL2(SECLEVEL-STARTCTM)                                   73374020
         DC    AL2(L'MSGE18)                                            73378020
         DC    AL2(MSGE18-STARTCTM)                                     73382020
         DC    AL2(OFFSEG18-STARTCTM)                                   73386020
         DC    AL2(SECLEVEL-STARTCTM)                                   73390020
*                                                                       73470020
*   THIS IS THE SEGMENT TABLE USED FOR MESSAGES *                       73500020
*                                                                       73530020
         DS    0F                                                       73560020
OFFSEG4  DC    AL2(L'SEG4)                                              73590020
         DC    AL2(SEG4-STARTCTM)                                       73620020
         DC    AL2(0)                                                   73650020
OFFSEG5  DC    AL2(L'SEG5)                                              73680020
         DC    AL2(SEG5-STARTCTM)                                       73710020
         DC    AL2(0)                                            A49872 73740021
OFFSEG6  DC    AL2(L'SEG6)                                              73770020
         DC    AL2(SEG6-STARTCTM)                                       73800020
         DC    AL2(0)                                                   73830020
OFFSEG8  DC    AL2(L'SEG8)                                       A49872 73840021
         DC    AL2(SEG8-STARTCTM)                                A49872 73850021
         DC    AL2(0)                                            A49872 73852021
OFFSEG12 DC    AL2(L'SEG12)                                             73860020
         DC    AL2(SEG12-STARTCTM)                                      73890020
         DC    AL2(0)                                                   73920020
OFFSEG13 DC    AL2(L'SEG13)                                             73950020
         DC    AL2(SEG13-STARTCTM)                                      73980020
         DC    AL2(0)                                                   74010020
OFFSEG14 DC    AL2(L'SEG14)                                             74040020
         DC    AL2(SEG14-STARTCTM)                                      74070020
         DC    AL2(0)                                                   74100020
OFFSEG15 DC    AL2(L'SEG15)                                             74130020
         DC    AL2(SEG15-STARTCTM)                                      74160020
         DC    AL2(0)                                                   74190020
OFFSEG16 DC    AL2(L'SEG16)                                             74194020
         DC    AL2(SEG16-STARTCTM)                                      74198020
         DC    AL2(0)                                                   74202020
OFFSEG17 DC    AL2(L'SEG17)                                             74206020
         DC    AL2(SEG17-STARTCTM)                                      74210020
         DC    AL2(0)                                                   74214020
OFFSEG18 DC    AL2(L'SEG18)                                             74221020
         DC    AL2(SEG18-STARTCTM)                                      74228020
         DC    AL2(0)                                                   74235020
******** END OF SEGMENT TABLE *********************                     74242020
         EJECT                                                          74252020
*************  BEGIN FIRST LEVEL MESSAGES ********                      74272020
MSGE1    DC    C'IKJ58405I INVALID USE OF * IN INDEX LEVEL+'            74310020
MSGE2    DC    C'IKJ58403I UNABLE TO LIST CATALOG+'                     74340020
MSGE3    DC    C'IKJ58406I NO DATA SET NAMES IN CATALOG'                74370020
MSGE4    DC    C'IKJ58404I NOT ENOUGH MAIN STORAGE TO LIST '            74400020
SEG4     DC    C' INDEX LEVEL'             SECND SEG                    74430020
MSGE5    DC    C'IKJ58407I '            FIRST SEGMENT            A49872 74460021
SEG5     DC    C' INDEX STRUCTURE EMPTY'   SECND SEG                    74490020
MSGE6    DC    C'IKJ58408I '            FIRST SEGMENT            A49872 74520021
SEG6     DC    C' GENERATION DATA GROUP STRUCTURE EMPTY'                74550020
MSGE7    DC    C'IKJ58402I NOT ENOUGH MAIN STORAGE TO LIST '            74580020
MSGE8    DC    C'IKJ58400I '                                     A49872 74610021
SEG8     DC    C' NOT AVAILABLE+'                                A49872 74620021
MSGE9    DC    C'IKJ58401I MEMBERS NOT AVAILABLE+'                      74640020
MSGE10   DC    C'IKJ58410I COMMAND SYSTEM ERROR+'                A49872 74670021
MSGE11   DC    C'IKJ58409I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  74700021
*                                                                A49872 74710021
MSGE12   DC    C'IKJ58411I DATA SET '                            A49872 74730021
SEG12    DC    C' NOT ALLOCATED, TOO MANY DATA SETS+'                   74760020
MSGE13   DC    C'IKJ58417I DATA SET '                            A49872 74790021
SEG13    DC    C' NOT ALLOCATED, DATA SET NOT ON VOLUME+'               74820020
MSGE14   DC    C'IKJ58412I DATA SET '                            A49872 74850021
SEG14    DC    C' NOT ALLOCATED, SYSTEM OR INSTALLATION ERROR+'         74880020
MSGE15   DC    C'IKJ58413I DATA SET '                            A49872 74910021
SEG15    DC    C' ALREADY IN USE, TRY LATER+'                           74940020
MSGE16   DC    C'IKJ58415I '                                     A49872 74946021
SEG16    DC    C' NAME IS NOT AN INDEX STRUCTURE'                       74952020
MSGE17   DC    C'IKJ58414I DATA SET '                            A49872 74958021
SEG17    DC    C' NOT ALLOCATED, REQUIRED VOLUME NOT MOUNTED+'          74964020
MSGE18   DC    C'IKJ58416I DATA SET '                            A49872 74973021
SEG18    DC    C' NOT IN CATALOG'                                       74982020
*                                                                       75000020
*        SECOND LEVEL MESSAGE TABLE--FORMAT AS DESCRIBED IN PROLOG      75030020
*                                                                       75060020
SECLEVEL DS    0F                                                       75090020
         DC    AL2(L'MSGSEC01)                                          75120020
         DC    AL2(MSGSEC01-STARTCTM)                                   75150020
         DC    AL2(0)                                                   75180020
         DC    AL2(L'MSGSEC02)                                          75210020
         DC    AL2(MSGSEC02-STARTCTM)                                   75240020
         DC    AL2(0)                                                   75270020
         DC    AL2(L'MSGSEC03)                                          75300020
         DC    AL2(MSGSEC03-STARTCTM)                                   75330020
         DC    AL2(0)                                                   75360020
         DC    AL2(L'MSGSEC04)                                          75390020
         DC    AL2(MSGSEC04-STARTCTM)                                   75420020
         DC    AL2(0)                                                   75450020
         DC    AL2(L'MSGSEC05)                                          75480020
         DC    AL2(MSGSEC05-STARTCTM)                                   75510020
         DC    AL2(0)                                                   75540020
         DC    AL2(L'MSGSEC06)                                          75570020
         DC    AL2(MSGSEC06-STARTCTM)                                   75600020
         DC    AL2(0)                                                   75630020
         DC    AL2(L'MSGSEC07)                                          75660020
         DC    AL2(MSGSEC07-STARTCTM)                                   75690020
         DC    AL2(0)                                                   75720020
         DC    AL2(L'MSGSEC08)                                          75750020
         DC    AL2(MSGSEC08-STARTCTM)                                   75780020
         DC    AL2(0)                                                   75810020
         DC    AL2(L'MSGSEC09)                                          75840020
         DC    AL2(MSGSEC09-STARTCTM)                                   75870020
         DC    AL2(0)                                                   75900020
         DC    AL2(L'MSGSEC10)                                          75930020
         DC    AL2(MSGSEC10-STARTCTM)                                   75960020
         DC    AL2(0)                                                   75990020
         DC    AL2(L'MSGSEC11)                                          76020020
         DC    AL2(MSGSEC11-STARTCTM)                                   76050020
         DC    AL2(0)                                                   76080020
         DC    AL2(L'MSGSEC12)                                          76110020
         DC    AL2(MSGSEC12-STARTCTM)                                   76140020
         DC    AL2(0)                                                   76170020
         DC    AL2(L'MSGSEC13)                                          76200020
         DC    AL2(MSGSEC13-STARTCTM)                                   76230020
         DC    AL2(0)                                                   76260020
         DC    AL2(L'MSGSEC14)                                          76290020
         DC    AL2(MSGSEC14-STARTCTM)                                   76320020
         DC    AL2(0)                                                   76350020
         DC    AL2(L'MSGSEC15)                                          76380020
         DC    AL2(MSGSEC15-STARTCTM)                                   76410020
         DC    AL2(0)                                                   76440020
         DC    AL2(L'MSGSEC16)                                          76470020
         DC    AL2(MSGSEC16-STARTCTM)                                   76500020
         DC    AL2(0)                                                   76530020
         DC    AL2(L'MSGSEC17)                                          76560020
         DC    AL2(MSGSEC17-STARTCTM)                                   76590020
         DC    AL2(0)                                                   76620020
         DC    AL2(L'MSGSEC18)                                          76650020
         DC    AL2(MSGSEC18-STARTCTM)                                   76680020
         DC    AL2(0)                                                   76710020
         DC    AL2(L'MSGSEC19)                                          76740020
         DC    AL2(MSGSEC19-STARTCTM)                                   76770020
         DC    AL2(0)                                                   76800020
         DC    AL2(L'MSGSEC20)                                          76830020
         DC    AL2(MSGSEC20-STARTCTM)                                   76860020
         DC    AL2(0)                                                   76890020
         DC    AL2(L'MSGSEC21)                                          76920020
         DC    AL2(MSGSEC21-STARTCTM)                                   76950020
         DC    AL2(0)                                                   76980020
         DC    AL2(L'MSGSEC22)                                          77010020
         DC    AL2(MSGSEC22-STARTCTM)                                   77040020
         DC    AL2(0)                                                   77070020
         DC    AL2(L'MSGSEC23)                                          77100020
         DC    AL2(MSGSEC23-STARTCTM)                                   77130020
         DC    AL2(0)                                                   77160020
         DC    AL2(L'MSGSEC24)                                          77190020
         DC    AL2(MSGSEC24-STARTCTM)                                   77220020
         DC    AL2(0)                                                   77250020
         DC    AL2(L'MSGSEC25)                                          77280020
         DC     AL2(MSGSEC25-STARTCTM)                                  77310020
         DC    AL2(0)                                                   77340020
*                                                                       77370020
*                                                                       77400020
*        SECOND LEVEL MESSAGES FOLLOW                                   77430020
*                                                                       77460020
MSGSEC01 DC    C'IKJ584XXI LOCATE ERROR CODE '                          77490020
MSGSEC02 DC    C'IKJ584XXI CATALOG ERROR CODE '                         77520020
MSGSEC03 DC    C'IKJ584XXI INVALID AS FIRST OR LAST INDEX LEVEL'        77550020
MSGSEC04 DC    C'IKJ584XXI NAME IS NOT INDEX STRUCTURE'                 77580020
MSGSEC05 DC    C'IKJ584XXI INSUFFICIENT CORE STORAGE'                   77610020
MSGSEC06 DC    C'IKJ584XXI QUALIFIERS PRECEDING * NOT INDEX STRUCTURE'  77640020
MSGSEC07 DC    C'IKJ584XXI DIRECTORY STRUCTURE ERROR'                   77670020
MSGSEC08 DC    C'IKJ584XXI I/O ERROR DURING LOCATE,CODE '               77700020
MSGSEC09 DC    C'IKJ584XXI CATALOG VOLUME NOT MOUNTED'                  77730020
MSGSEC12 DC    C'IKJ584XXI ALLOCATE FAILED '                            77760020
MSGSEC10 DC    C'IKJ584XXI DATA SET NOT ON VOLUME'                      77790020
MSGSEC11 DC    C'IKJ584XXI CATALOG I/O ERROR'    CTRC 28  DAIR 8        77820020
MSGSEC13 DC    C'IKJ584XXI DAIR ERROR CODE '                     100000 77850021
MSGSEC14 DC    C'IKJ584XXI PARSE ERROR CODE '                           77880020
MSGSEC15 DC    C'IKJ584XXI CANNOT USE MORE THAN ONE * IN LEVEL NAME'    77910020
MSGSEC16 DC    C'IKJ584XXI REQUIRED VOLUME NOT MOUNTED'                 77940020
MSGSEC17 DC    C'IKJ584XXI I/O ERROR DURING OBTAIN,CODE '               77970020
MSGSEC18 DC    C'IKJ584XXI NOT ENOUGH MAIN STORAGE'                     78000020
MSGSEC19 DC    C'IKJ584XXI I/O SYNAD ERROR DURING DIRECTORY SEARCH '    78030020
MSGSEC20 DC    C'IKJ584XXI USE FREE COMMAND TO FREE UNUSED DATA SETS'   78060020
MSGSEC21 DC    C'IKJ584XXI CATALOG INFORMATION INCORRECT'               78090020
MSGSEC22 DC    C'IKJ584XXI REQUIRED VOLUME NOT MOUNTED'          A49872 78120021
MSGSEC23 DC    C'IKJ584XXI DYNAMIC ALLOCATION ERROR CODE '              78150020
MSGSEC24 DC    C'IKJ584XXI VOLUME OR CVOL NOT ON SYSTEM AND CANNOT BE A-78170020
               CCESSED'           CTRC  4     DAIR  8                   78190020
MSGSEC25 DC    C'IKJ584XXI DATA SET IS ALLOCATED TO ANOTHER USER OR JOB-78200020
               '                  DARC  210    DAIR  12                 78210020
*                                                                       78240020
*                                                                       78270020
         END                                                            78300020
