         TITLE 'IKJEHDEF - TSO DEFAULT NAMING SERVICE ROUTINE'          00090020
IKJEHDEF CSECT                                                          00180020
         ENTRY IKJDFLT                                                  00270020
         SPACE                                                          00360020
*********************************************************************** 00450020
*                                                                     * 00540020
* STATUS -- CHANGE LEVEL 00                                           * 00630020
*                                                                     * 00720020
* FUNCTION -- THE DEFAULT NAMING SERVICE ROUTINE IS USED TO QUALIFY   * 00810020
*    DATA SET NAMES.                                                  * 00900020
*                                                                     * 00990020
* ENTRY POINTS --                                                     * 01080020
*          IKJDFLT - MAIN ENTRY POINT OF PROGRAM                      * 01170020
*                                                                     * 01260020
* INPUT -- REGISTER 1 POINTS TO THE DEFAULT SERVICE ROUTINE PARAMETER * 01350020
*    LIST AS FOLLOWS-                                                 * 01440020
*    WORD 1 POINTS TO THE USER PROFILE TABLE (UPT)                    * 01530020
*    WORD 2 POINTS TO THE ENVIORONMNT CONTROL TABLE (ECT)             * 01620020
*    WORD 3 POINTS TO THE CP'S EVENT CONTROL BLOCK (ECB)              * 01710020
*    WORD 4 POINTS TO THE DEFAULT PARAMETER BLOCK                     * 01800020
*                                                                     * 01890020
*    THE DEFAULT PARAMETER BLOCK IS AS FOLLOWS-                       * 01980020
*    WORD 1 BYTE 1   CONTAINS THE ENTRY CODE                          * 02070020
*    WORD 1 BYTE 2-4 POINTS TO THE DATA SET NAME AND LENGTH           * 02160020
*    WORD 2 BYTE 1   CONTAINS CONTROL INFORMATION                     * 02250020
*    WORD 2 BYTE 2-4 POINTS TO THE PROTECTED STEP CONTROL BLOCK (PSCB)* 02340020
*    WORD 3          POINTS TO A SPECIFIC DEFAULT QUALIFIER           * 02430020
*                                                                     * 02520020
* OUTPUT -- WHEN MORE THAN ONE QUALIFIER IS FOUND FOR A DATA SET NAME * 02610020
*    THESE QUALIFIERS ARE LISTED AT THE TERMINAL.  APPROPRIATE        * 02700020
*    PROMPTING AND DIAGNOSTIC MESSAGES MAY ALSO BE ISSUED.            * 02790020
*                                                                     * 02880020
* EXTERNAL REFERECNES --                                              * 02970020
*         IKJEHCIR - ENTRY POINT TO CATALOG INFORAMTION ORUTINE       * 03060020
*         IKJPUTL - ENTRY POINT TO PUTLINE SERVICE ROUTINE            * 03150020
*         IKJPTGT - ENTRY POINT TO PTUGET SERVICE ROUTINE             * 03240020
*         IKJSCAN - ENTRY POINT TO COMMAND SCAN SERVICE ROUTINE       * 03330020
*                                                                     * 03420020
* EXITS, NORMAL -- RETURN TO CALLER                                   * 03510020
*                                                                     * 03600020
* EXITS, ERROR -- RETURN TO CALLER                                    * 03690020
*                                                                     * 03780020
* TABLES/WORK AREAS --                                                * 03870020
*    WORKAREA - A DSECT TO MAP THE WORKAREA                           * 03960020
*                                                                     * 04050020
* ATTRIBUTES -- REENTRANT, READ-ONLY, REFRESHABLE                     * 04140020
*                                                                     * 04230020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 04320020
*                                                                     * 04410020
* NOTE -- N/A                                                         * 04500020
*                                                                     * 04590020
*********************************************************************** 04680020
         EJECT                                                          04770020
         SPACE                                                          04860020
*  REGISTER EQUATES                                                     04950020
R0       EQU   0                   GENERAL REGISTER 0                   05040020
R1       EQU   1                   GENERAL REGISTER 1                   05130020
R2       EQU   2                   GENERAL REGISTER 2                   05220020
R3       EQU   3                   GENERAL REGISTER 3                   05310020
R4       EQU   4                   GENERAL REGISTER 4                   05400020
R5       EQU   5                   GENERAL REGISTER 5                   05490020
R6       EQU   6                   GENERAL REGISTER 6                   05580020
R7       EQU   7                   GENERAL REGISTER 7                   05670020
R8       EQU   8                   GENERAL REGISTER 8                   05760020
R9       EQU   9                   GENERAL REGISTER 9                   05850020
R10      EQU   10                  GENERAL REGISTER 10                  05940020
R11      EQU   11                  GENERAL REGISTER 11                  06030020
R12      EQU   12                  GENERAL REGISTER 12                  06120020
R13      EQU   13                  GENERAL REGISTER 13                  06210020
R14      EQU   14                  GENERAL REGISTER 14                  06300020
R15      EQU   15                  GENERAL REGISTER 15                  06390020
*  OTHER EQUATES                                                        06480020
SPN      EQU   1                   SUBPOOL NUMBER FOR GETMAIN           06570020
MASK1    EQU   X'40'               MASK TO TEST FOR ATTENTION           06660020
PERIOD   EQU   C'.'                PERIOD                               06750020
BLANK    EQU   C' '                BLANK                                06840020
HALFWORD EQU   X'01'               MASK TO TEST FOR HALFWORD BOUNDRY    06930020
CIROPT   EQU   X'01'               CIR OPTION TO REQUEST DATA SET NAMES 07020020
CIRVOL   EQU   X'04'               REQUEST VOLUMES FROM CIR             07110020
GDGNAME  EQU   X'02'               CIR - GENERATION DATA GROUP NAME     07200020
NAMETEST EQU   X'07'               CIR - DATA SET NAME                  07290020
LISTEND  EQU   X'FF'               CIR - END OF LIST                    07380020
TTRSIGN  EQU   X'80'               MASK TO INDICATE TTR POINTER         07470020
LOCMSK8  EQU   X'08'               MASK TO CHECK FOR LOCATE RC=8 (CIR)  07560020
LOCMSK16 EQU   X'10'               MASK TO CHECK FOR LOCATE RC=16 (CIR) 07650020
SWON     EQU   X'FF'               MASK TO TURN SWITCHES ON             07740020
SWOFF    EQU   X'00'               MASK TO TURN SWITCHES OFF            07830020
EQ       EQU   8                   EQUAL CONDITION CODE                 07920020
ENDTEST  EQU   X'FF'               INDICATE END OF CHAIN                08010020
ZONE     EQU   C'0'                ZONE                                 08100020
FOXZERO  EQU   C'0'                CHARACTER ZERO                       08190020
ONE      EQU   1                   ONE                                  08280020
TWO      EQU   2                   TWO                                  08370020
FOUR     EQU   4                   FOUR                                 08460020
*  ABSOLUTE EQUATES (OFFSETS AND SHORT LENGTHS)                         08550020
F0       EQU   0                   ZERO                                 08640020
F1       EQU   1                   ONE                                  08730020
F2       EQU   2                   TWO                                  08820020
F4       EQU   4                   FOUR                                 08910020
F5       EQU   5                   FIVE                                 09000020
F7       EQU   7                   SEVEN                                09090020
F8       EQU   8                   EIGHT                                09180020
F12      EQU   12                  TWELVE                               09270020
F43      EQU   43                  FORTY-THREE                          09360020
*  RETURN CODE EQUATES                                                  09450020
RC4      EQU   4                   RETURN CODE = 4                      09540020
RC8      EQU   8                   RETURN CODE = 8                      09630020
RC12     EQU   12                  RETURN CODE = 12                     09720020
RC16     EQU   16                  RETURN CODE = 16                     09810020
RC20     EQU   20                  RETURN CODE = 20                     09900020
RC24     EQU   24                  RETURN CODE = 24                     09990020
RC28     EQU   28                  RETURN CODE = 28                     10080020
RC32     EQU   32                  RETURN CODE = 32                     10170020
RC36     EQU   36                  RETURN CODE = 36                     10260020
*  LENGTH EQUATES (FIXED LENGTH ITEMS)                                  10350020
L3       EQU   3                   LENGTH OF TTR                        10440020
L6       EQU   6                   LENGTH OF VOLUME ID (VOLID)          10530020
L8       EQU   8                   LENGTH OF SIMPLE DSNAME (QUALIFIER)  10620020
L9       EQU   9                   LENGTH OF CIR NAME ENTRY             10710020
L10      EQU   10                  LENGTH OF MESSAGE ID                 10800020
L13      EQU   13                  LENGTH OF (NAME + LL + OFFSET) + 1   10890020
L16      EQU   16                  LENGTH OF CIR GENERATION DATA ENTRY  10980020
L46      EQU   46                  LENGTH OF DSNAME AND DSLENGTH FIELD  11070020
L72      EQU   72                  LENGTH OF SAVEAREA                   11160020
*                                                                       11250020
*  EQUATES FOR MESSAGE NUMBERS (FIRST LEVEL MESSAGES)                   11340020
M01      EQU   1                   MESSAGE NUMBER 01                    11430020
M02      EQU   2                   MESSAGE NUMBER 02                    11520020
M03      EQU   3                   MESSAGE NUMBER 03                    11610020
M04      EQU   4                   MESSAGE NUMBER 04                    11700020
M05      EQU   5                   MESSAGE NUMBER 05                    11790020
M06      EQU   6                   MESSAGE NUMBER 06                    11880020
M07      EQU   7                   MESSAGE NUMBER 07                    11970020
M08      EQU   8                   MESSAGE NUMBER 08                    12060020
M09      EQU   9                   MESSAGE NUMBER 09                    12150020
M10      EQU   10                  MESSAGE NUMBER 10                    12240020
M11      EQU   11                  MESSAGE NUMBER 11                    12330020
M12      EQU   12                  MESSAGE NUMBER 12                    12420020
*  EQUATES FOR MESSAGE NUMBERS (SECOND LEVEL MESSAGES)                  12510020
S01      EQU   1                   SECOND LEVEL MESSAGE NUMBER 01       12600020
S02      EQU   2                   SECOND LEVEL MESSAGE NUMBER 02       12690020
S03      EQU   3                   SECOND LEVEL MESSAGE NUMBER 03       12780020
S04      EQU   4                   SECOND LEVEL MESSAGE NUMBER 04       12870020
S05      EQU   5                   SECOND LEVEL MESSAGE NUMBER 05       12960020
S06      EQU   6                   SECOND LEVEL MESSAGE NUMBER 06       13050020
S07      EQU   7                   SECOND LEVEL MESSAGE NUMBER 07       13140020
S08      EQU   8                   SECOND LEVEL MESSAGE NUMBER 08       13230020
*              REGISTER USAGE                                           13320020
*                                                                       13410020
*  REGISTER 0  USED AS WORK REGISTER                                    13500020
*                                                                       13590020
*  REGISTER 1  USED AS PARAMETER REGISTER AND AS WORK REGISTER          13680020
*                                                                       13770020
*  REGISTER 2  USED AS WORK REGISTER                                    13860020
*                                                                       13950020
*  REGISTER 3  USED AS WORK REGISTER                                    14040020
*                                                                       14130020
*  REGISTER 4  USED AS WORK REGISTER                                    14220020
*                                                                       14310020
*  REGISTER 5  USED AS WORK REGISTER                                    14400020
*                                                                       14490020
*  REGISTER 6  POINTS TO DEFAULT PARAMETER BLOCK                        14580020
*                                                                       14670020
*  REGISTER 7  NOT USED                                                 14760020
*                                                                       14850020
*  REGISTER 8  USED AS WORK REGISTER                                    14940020
*                                                                       15030020
*  REGISTER 9  USED AS WORK REGISTER                                    15120020
*                                                                       15210020
*  REGISTER 10 USED AS WORK REGISTER                                    15300020
*                                                                       15390020
*  REGISTER 11 USED AS WORK REGISTER                                    15480020
*                                                                       15570020
*  REGISTER 12 IS BASE REGISTER FOR THIS PROGRAM                        15660020
*                                                                       15750020
*  REGISTER 13 IS SAVE AREA REGISTER AND DSECT BASE REGISTER            15840020
*                                                                       15930020
*  REGISTER 14 IS THE LINK REGISTER                                     16020020
*                                                                       16110020
*  REGISTER 15 IS THE BRANCH AND RETURN CODE REGISTER                   16200020
         EJECT                                                          16290020
IKJDFLT  SAVE  (14,12),,*          SAVE CALLING PROGRAM'S REGISTERS     16380020
         LR    R12,R15             SET BASE REGISTER                    16470020
         USING IKJEHDEF,R12        ESTABLISH ADDRESSABILITY             16560020
         LR    R2,R1               SAVE REG 1 WHICH IS USED BY GETMAIN  16650020
         GETMAIN R,LV=CORE,SP=SPN  GET CORE FOR CONSTANTS AND WORKAREA  16740020
         XC    F0(L72,R1),F0(R1)   INITIALIZE REG SAVE AREA             17010020
         ST    R13,F4(R1)          CHAIN SAVE AREAS -                   17100020
         ST    R1,F8(R13)          - BACKWARDS AND FORWARDS             17190020
         LR    R13,R1              FIRST 18 WORDS IS REGISTER SAVE AREA 17220020
         USING WORKAREA,R13        ADDRESSABILITY FOR WORKAREA          17250020
         MVC   PUT(PUTLEND-PUTL),PUTL INITIALIZE PUTLINE PARM BLOCK     17280020
         MVC   PROMPT(PRMPTEND-PRMPT1),PRMPT1 AND PUTGET PARMBLOCK      17370020
         MVI   DSNAME,BLANK        BLANK DATA SET -                     17460020
         MVC   DSNAME+F1(F43),DSNAME WORK BUFFER                        17550020
         SR    R1,R1               CLEAR REGISTER                       17640020
         ST    R1,FLAGWORD         ZERO COMMAND SCAN FLAG WORD          17730020
         ST    R1,CIRADDR          ZERO CIR ADDRESS FIELD               17820020
         ST    R1,CVOLIDPT         ZERO CVOL POINTER                    17910020
         MVI   SWITCH,SWOFF        SET SWITCH OFF                       18000020
         MVI   ADDSW,SWOFF         SET SWITCH OFF                       18050020
*  INITIALIZE CIR PARAMETER LIST                                        18090020
         LA    R1,WKAREA1          ADDRESS OF FIRST WORKAREA -          18180020
         ST    R1,WKAR1PTR         TO CIR PARAMETER LIST                18270020
         LA    R1,WKAREA2          ADDRESS OF SECOND WORKAREA -         18360020
         ST    R1,WKAR2PTR         TO CIR PARAMETER LIST                18450020
*  INITIALIZE SCAN BUFFER LAST BYTE TO BLANK                            18540020
         LA    R1,SCANBUFF         POINT TO SCAN BUFFER                 18630020
         MVI   F8(R1),BLANK        MOVE IN A BLANK                      18720020
*  REGISTER 2 POINTS TO DEFAULT PARAMETER LIST                          18810020
         USING DFPL,R2             ESTABLISH ADDRESSABILITY FOR DFPL    18900020
         L     R3,DFPLUPT          UPT ADDRESS                          18990020
         L     R4,DFPLECT          ECT ADDRESS                          19080020
         L     R5,DFPLECB          ECB ADDRESS                          19170020
         L     R6,DFPLDFPB         DFPB ADDRESS                         19260020
         DROP  R2                  DFPL IS NO LONGER NEEDED             19350020
         USING DFPB,R6             ESTABLISH ADDRESSABILITY FOR DFPB    19440020
*  REGISTER 3 POINTS TO THE UPT                                         19530020
*  REGISTER 4 POINTS TO THE ECT                                         19620020
*  REGISTER 5 POINTS TO THE CP'S ECB                                    19710020
*  REGISTER 6 POINTS TO DEFAULT PARAMETER LIST                          19800020
         LA    R1,IOPARM           POINT TO SPACE FOR I/O PARM LIST     19890020
         USING IOPL,R1             SET ADDRESSABILITY IOPL              19980020
         LA    R2,CSPLPARM         POINT TO SPACE FOR CMD SCAN PARMLIST 20070020
         USING CSPL,R2             SET ADDRESSABILITY CSPL              20160020
*  INITIALIZE PARAMETERS FOR I/O AND COMMAND SCAN                       20250020
         ST    R3,IOPLUPT          UPT ADDRESS TO IOPL-                 20340020
         ST    R3,CSPLUPT          AND CSPL                             20430020
         ST    R4,IOPLECT          ECT ADDRESS TO IOPL-                 20520020
         ST    R4,CSPLECT          AND CSPL                             20610020
         ST    R5,IOPLECB          ECB ADDRESS TO IOPL-                 20700020
         ST    R5,CSPLECB          AND CSPL                             20790020
         ST    R5,ECBADDR          SAVE ECB ADDRESS                     20880020
         LA    R3,FLAGWORD         COMMAND SCAN FLAG WORD-              20970020
         ST    R3,CSPLFLG          TO CSPL                              21060020
         LA    R3,CSOAAREA         COMMAND SCAN OUTPUT AREA-            21150020
         ST    R3,CSPLOA           TO CSPL                              21240020
         DROP  R1                  IOPL NO LONGER NEEDED                21330020
         DROP  R2                  CSPL NO LONGER NEEDED                21420020
*  NOW LOAD DEFAULT PARAMETERS                                          21510020
         L     R3,DFPBDSN          POINT TO DSLENGTH AND DSNAME BUFFER  21600020
         L     R4,DFPBPSCB         POINT TO PSCB                        21690020
         L     R5,DFPBQUAL         POINT TO DEFAULT QUALIFIER           21780020
*  NOW REGISTER 3 POINTS TO DATA SET LENGTH AND NAME BUFFER             21870020
*  NOW REGISTER 4 POINTS TO THE PSCB                                    21960020
*  NOW REGISTER 5 POINTS TO THE DEFAULT QUALIFIER                       22050020
*  NOW VALIDITY CHECK PARAMETERS                                        22140020
         CLI   DFPBCODE,DFPB00     IS OPTION X'00'                      22230020
         BE    OKOPTION            YES, OK                              22320020
         CLI   DFPBCODE,DFPB04     IS OPTION X'04'                      22410020
         BE    OKOPTION            YES, OK                              22500020
         CLI   DFPBCODE,DFPB08     IS OPTION X'08'                      22590020
         BE    OKOPTION            YES, OK                              22680020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      22770020
         BE    OKOPTION            YES, OK                              22860020
         B     ERROR28             ERROR, INVALID ENTRY OPTION          22950020
OKOPTION STC   R3,TESTBYTE         STORE LAST BYTE OF ADDRESS           23040020
         TM    TESTBYTE,HALFWORD   IS DSLENGTH ON HALFWORD BOUNDRY      23130020
         BO    ERROR28             NO, ERROR, BAD PARAMETER             23220020
         LH    R8,F0(R3)           LOAD DATA SET LENGTH                 23310020
         LTR   R8,R8               IS LENGTH ZERO                       23400020
         BNZ   SIZETEST            NO , CHECK DATA SET LENGTH           23490020
         LA    R8,FOUR             HEADER LENGTH                        23580020
         STH   R8,DSNMESGL         SET INSERTION LENGTH (0)             23670020
*  DATA SET LENGTH IS ZERO, OPTION MUST BE X'00' ELSE ERROR             23760020
         CLI   DFPBCODE,DFPB00     IS OPTION X'00'                      23850020
         BNE   ERROR28             ERROR, INVALID DSLENGTH              23940020
         MVI   SWITCH,SWON         TURN SWITCH ON                       24030020
         B     CNTRLTST            GO CHECK OPTION                      24120020
SIZETEST CH    R8,DSMAXSZE         IS LENGTH GREATER THAN 44            24210020
         BH    ERROR28             ERROR, INVALID DSLENGTH              24300020
         BCTR  R8,R0               DECREMENT FOR EXECUTE                24390020
         EX    R8,DSNINSRT         MOVE DSNAME TO INSERTION BUFFER      24480020
         LA    R8,F5(R8)           4 FOR HEADER AND 1 FOR EXECUTE       24570020
         STH   R8,DSNMESGL         LENGTH OF INSERTION                  24660020
         TM    DFPBCNTL,DFPBRET    RETURN QUALIFIER                     24710020
         BNO   TEST0C              NO, GO CHECK FOR USERID ADD          24720020
         L     R8,DFPBQUAL         POINT TO QUALIFIER BUFFER            24730020
         MVC   F0(L8,R8),UPERCASE  BLANK QUALIFIER RETURN BUFFER        24740020
TEST0C   CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      24750020
         BNE   NOT0C               NO, NOT X'0C'                        24840020
CNTRLTST TM    DFPBCNTL,DFPBMSG    WAS MESSAGE REQUESTED                24930020
         BO    REUSE               YES, GO ISSUE MESSAGE                25020020
NOT0C    TM    DFPBCNTL,DFPBUID    USERID ADD REQUESTED                 25110020
         BZ    MOVENAME            NO, GO MOVE NAME                     25200020
*  NOW PREFIX THE USERID TO THE GIVEN DATA SET NAME                     25290020
ADDUSRID LA    R8,DSNAME           ADDRESS OF DATA SET NAME BUFFER      25380020
         SR    R9,R9               ZERO REGISTER                        25470020
         USING PSCB,R4             ESTABLISH ADDRESSABILITY FOR PSCB    25560020
         LA    R2,PSCBUSER         ADDRESS OF USERID                    25650020
         IC    R9,PSCBUSRL         LENGTH OF USERID                     25740020
         EX    R9,MOVEID           USERID TO DSNAME BUFFER              25830020
*  THIS ACTUALLY MOVES ONE EXTRA BYTE WHICH WILL BE OVERLAID WITH A     25920020
*  PERIOD.                                                              26010020
*  PSCB POINTER IS NO LONGER NEEDED, REGISTER 4 IS AVAILABLE            26100020
         DROP  R4                  DROP PSCB ADDRESSABILITY             26190020
         AR    R8,R9               POINT PAST USERID                    26280020
         MVI   F0(R8),PERIOD       INSERT PERIOD                        26370020
         LA    R8,F1(R8)           POINT PAST PERIOD                    26460020
         AH    R9,F0(R3)           ADD DSLENGTH TO USERID LENGTH        26550020
         LA    R9,F1(R9)           PLUS ONE FOR THE PERIOD              26640020
         TM    SWITCH,SWON         TEST SWITCH                          26730020
         BO    OPTTEST             GO SAVE DATA SET LENGTH              26820020
         CH    R9,DSMAXSZE         COMPARE TOTAL TO 44                  26910020
         BH    LENTHERR            ERROR, LENGTH GT 44                  27000020
         LA    R4,F2(R3)           POINT TO DSNAME                      27090020
         LH    R1,F0(R3)           LENGTH OF DSNAME                     27180020
         BCTR  R1,R0               DECREMENT FOR EXECUTE                27270020
         EX    R1,MOVEINST         MOVE DSNAME TO USERID                27360020
         STH   R9,DSL              SAVE TOTAL LENGTH                    27450020
         B     TESTOPTN            CHECK OPTION                         27540020
OPTTEST  STH   R9,DSL              SAVE DATA SET LENGTH                 27630020
         B     ADDNAME             GO ADD DSNAME                        27720020
MOVENAME TM    SWITCH,SWON         IS SWITCH ON                         27810020
         BO    ERROR28             ERROR, DSLENGTH 0, NO USERID ADD     27900020
         MVC   DSL(L46),F0(R3)     MOVE NAME AND LENGTH TO WORK BUFFER  27990020
TESTOPTN CLI   DFPBCODE,DFPB00     IS OPTION X'00'                      28080020
         BE    ADDNAME             PROCESS X'00' ENTRY                  28170020
*  NOW LOAD CIR ROUTINE                                                 28890020
CHECKNME LOAD  EP=IKJEHCIR         LOAD CIR                             28980020
         ST    R0,CIRADDR          SAVE ADDRESS OF CIR                  29070020
CALCIR   L     R15,CIRADDR         CIR ADDRESS TO REG 15                29120020
         MVI   CIRPARM,CIRVOL      SET CIR OPTION FOR VOLUMES           29130020
         LA    R1,DSNAME           ADDRESS OF DSNAME                    29140020
         ST    R1,NAMETTR          SET POINTER TO DSNAME                29150020
         BAL   R14,TESTATTN        CHECK FOR INTERRUPT                  29250020
         LA    R1,CIRPARM          POINT TO CIR PARAMETER LIST          29340020
         CALL  (15)                CALL CIR                             29430020
         LTR   R15,R15             TEST RETURN CODE                     29520020
         BZ    GOODEND             OK, NAME FOUND                       29610020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      29660020
         BE    CHECKADD            GO CHECK ADD QUALIFIER OPTION        29670020
CHECKRC  LA    R1,RC4              R1 = 4                               29700020
         CR    R15,R1              IS RETURN CODE 4                     29790020
         BE    CIRERROR            YES, ERROR                           29880020
         CLI   DFPBCODE,DFPB00     IS OPTION X'00'                      29970020
         BE    ERROR36             YES, ERROR                           30060020
*                                                                       30510020
*  NO QUALIFIER SPECIFED USE CIR TO GET QUALIFIERS                      30600020
*  BUILD CIR PARAMETER LIST                                             30690020
GOCIR    LA    R1,DSNAME           ADDRESS OF DATA SET NAME             30780020
         ST    R1,NAMETTR          SET POINTER TO DSNAME                30870020
         MVI   CIRPARM,CIROPT      SET CIR OPTION, REQUEST DSNAMES      30960020
         LA    R2,QUALLIST         POINT TO AREA FOR QUALIFIER LIST     31050020
         SR    R11,R11             ZERO QUALIFIER COUNTER               31140020
CALLCIR  L     R15,CIRADDR         ADDRESS OF CIR                       31230020
         BAL   R14,TESTATTN        CHECK FOR INTERRUPT                  31320020
         LA    R1,CIRPARM          POINT TO CIR PARAMETERS              31410020
         CALL  (15)                GO TO CIR                            31500020
         LTR   R15,R15             TEST RETURN CODE                     31590020
         BNZ   CIRERROR            GO CHECK NONZERO RETURN CODE         31680020
         LA    R9,WKAREA1          POINT TO CIR RETURN LIST             31770020
TESTLIST CLI   F0(R9),NAMETEST     IS IT A DATA SET NAME                31860020
         BE    BLDLIST             YES, ADD IT TO LIST OF QUALIFIERS    31950020
         CLI   F0(R9),GDGNAME      IS IT A GENERATION DATA GROUP NAME   32040020
         BE    GENNAME             GO BUMP POINTER FOR GENERATION NAME  32130020
         CLI   F0(R9),LISTEND      IS IT THE END OF THIS LIST           32220020
         BE    MORENMES            YES, ARE THERE MORE NAMES            32310020
         B     CIRERROR            NONE OF THE ABOVE IS ERROR           32400020
GENNAME  LA    R9,L16(R9)          BUMP POINTER TO NEXT ENTRY           32490020
         B     TESTLIST            GO CHECK NEXT ENTRY                  32580020
CHECKADD TM    DFPBCNTL,DFPBADD    ADD SPECIFIED QUALIFIER              32630020
         BNO   GOCIR               NO, GO GET QUALIFIERS                32640020
         CLI   ADDSW,SWON          HAS SPECIFIED QUALIFIER BEEN ADDED   32650020
         BE    GOODEND             YES, RETURN NAME                     32660020
         MVI   ADDSW,SWON          NO, TURN ON ADD SWITCH               32662020
         B     ADDNAME             GO ADD SPECIFIED QUALIFIER           32664020
MORENMES MVC   WORKWORD(F4),F0(R9) MOVE TTR                             32670020
         L     R5,WORKWORD         LOAD TTR                             32760020
         LA    R5,F0(R5)           BLANK END OF LIST INDICATOR          32850020
         LTR   R5,R5               IS TTR ZERO                          32940020
         BZ    NAMEFND             IF SO, CHECK IF ANY NAMES FOUND      33030020
         MVC   TTR(L3),F1(R9)      SAVE TTR OF NEXT CATALOG BLOCK       33120020
         LA    R5,TTR              POINT TO TTR                         33210020
         ST    R5,NAMETTR          POINTER TO CIRPARM LIST              33300020
         MVI   NAMETTR,TTRSIGN     SET TTR INDICATOR                    33390020
         MVC   CVOLID(L6),F4(R9)   SAVE CVOLID                          33480020
         LA    R5,CVOLID           ADDRESS OF CVOLID                    33570020
         ST    R5,CVOLIDPT         SET CVOLID POINTER                   33660020
         B     CALLCIR             GO BACK TO CIR                       33750020
ONEQUAL  MVC   SCANBUFF(L8),QUALLIST MOVE QUALIFIER TO SCAN BUFFER      33840020
         BAL   R14,SCANNAME        GO TO SCAN ROUTINE                   33930020
ADDQUAL  LA    R8,DSNAME           POINT TO DSNAME                      34020020
         AH    R8,DSL              POINT PAST DSNAME                    34110020
         MVI   F0(R8),PERIOD       INSERT PERIOD                        34200020
         LA    R8,F1(R8)           POINT PAST PERIOD                    34290020
         LA    R4,SCANBUFF         POINT TO THE QUALIFIER               34380020
         BCTR  R1,R0               DECREMENT FOR EXECUTE                34470020
         EX    R1,MOVEINST         QUALIFIER TO NAME                    34560020
         TM    DFPBCNTL,DFPBRET    RETURN QUALIFIER                     34650020
         BNO   SAVELNTH            NO, GO SAVE LENGTH                   34740020
         L     R8,DFPBQUAL         POINT TO QUALIFIER BUFFER            34830020
         EX    R1,MOVEINST         MOVE QUALIFIER TO BUFFER             34920020
SAVELNTH AH    R1,DSL              ADD DSNAME LENGTH TO QUALIFIER       35010020
         LA    R1,F2(R1)           LENGTH PLUS 2 (PERIOD AND EXECUTE)   35100020
         STH   R1,DSL              SAVE TOTAL LENGTH                    35190020
         B     GOODEND             SUCCESS                              35280020
BLDLIST  MVC   F0(L8,R2),F1(R9)    MOVE DSNAME TO LIST                  35370020
         LA    R11,F1(R11)         BUMP DSNAME COUNT                    35460020
         LA    R2,L8(R2)           BUMP LIST POINTER                    35550020
         CH    R11,MAXNAMES        IS LIST FULL                         35640020
         BE    LISTFULL            SPACE PROBLEM                        35730020
         LA    R9,L9(R9)           BUMP POINTER TO NEXT ENTRY           35820020
         B     TESTLIST            GO CHECK NEXT ENTRY                  35910020
NAMEFND  CLI   DFPBCODE,DFPB0C     IS CODE X'0C'                        36000020
         BNE   NMEFOUND            NO, CHECK IF NAME FOUND              36090020
         CR    R11,R5              IS QUALIFIER COUNT ZERO              36180020
         BE    GETQUAL             YES, GO GET QUAL                     36270020
         B     LISTFULL            NO, GO LIST QUALIFIERS               36360020
GETQUAL  LA    R2,M06              MESSAGE NUMBER 6                     36450020
         LA    R10,DSNMESGL        POINT TO INSERTION                   36540020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     36630020
         BAL   R9,TPUT             GO WRITE MESSAGE                     36720020
         LA    R2,M07              MESSAGE NUMBER 7                     36810020
         LA    R10,DSNMESGL        POINT TO INSERTION                   36900020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     36990020
         LA    R2,S05              SECOND LEVEL MESSAGE 5               37080020
         SR    R10,R10             NO INSERTION                         37170020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     37260020
         B     PRMPT               GO PROMT FOR QUALIFIER               37350020
QUALPRMT LA    R2,M05              MESSAGE NUMBER 5                     37440020
         SR    R10,R10             NO INSERTION                         37530020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     37620020
         LA    R2,S04              SECOND LEVEL MESSAGE 4               37710020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     37800020
         B     PRMPT               GO PROMT FOR QUALIFIER               37890020
NMEFOUND CR    R11,R5              IS QUALIFIER COUNT ZERO              37980020
         BE    ERROR36             NO DSNAMES                           38070020
         LA    R5,F1               R5 = 1                               38160020
         CR    R11,R5              CHECK IF ONLY ONE QUALIFIER          38250020
         BE    ONEQUAL             IF SO, ADD IT                        38340020
*  FINISHED WITH CIR                                                    38430020
LISTFULL DELETE EP=IKJEHCIR        DELETE CIR                           38520020
         SR    R0,R0               CLEAR REGISTER                       38610020
         ST    R0,CIRADDR          INDICATE CIR HAS BEEN DELETED        38700020
         CLI   DFPBCODE,DFPB08     IS OPTION X'08'                      38790020
         BE    ERROR32             IF YES, DO NOT PROMPT                38880020
         LA    R2,M01              MESSAGE NUMBER 1                     38970020
         LA    R10,DSNMESGL        POINT TO INSERTION                   39060020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     39150020
         BAL   R9,TPUT             GO WRITE MESSAGE                     39240020
*  NOW MOVE QUALIFIERS TO OUTBUFF.                                      39330020
         LA    R5,QUALLIST         INITIALIZE REG 5 TO FIRST QUALIFIER  39420020
         STH   R11,QUALCNT         SAVE QUALIFIER COUNT                 39510020
SETUP    LA    R8,F4               FOUR QUALIFIERS PER LINE             39600020
         LA    R4,OUTBUFF          POINT TO BUFFER                      39690020
         SR    R1,R1               ZERO REGISTER                        39780020
LOOP     MVC   F0(L8,R4),F0(R5)    MOVE QUALIFIER TO BUFFER             39870020
         MVC   L8(F2,R4),BLANKS    MOVE BLANKS TO BUFFER                39960020
         LA    R1,L10(R1)          BUMP MESSAGE LENGTH                  40050020
         LA    R4,L10(R4)          POINT PAST QUALIFIER AND BLANKS      40140020
         LA    R5,L8(R5)           POINT TO NEXT QUALIFIER              40230020
         BCT   R11,BUFCNTRL        ARE THERE MORE QUALIFIERS            40320020
         B     WRITE               WRITE LINE                           40410020
BUFCNTRL BCT   R8,LOOP             IS BUFFER FULL (4 QUALIFIERS)        40500020
WRITE    LA    R1,F4(R1)           ADD HEADER LENGTH                    40590020
         STH   R1,OUTBUFFL         MESSAGE LENGTH TO BUFFER             40680020
         LA    R2,M12              MESSAGE NUMBER 12                    40770020
         LA    R10,OUTBUFFL        POINT TO INSERTION                   40860020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     40950020
         BAL   R9,TPUT             GO PUT LINE TO TERMINAL              41040020
         LTR   R11,R11             ARE THERE MORE QUALIFIERS            41130020
         BNZ   SETUP               IF SO, GO FILL BUFFER AGAIN          41220020
*  NOW ALL QUALIFIERS HAVE BEEN LISTED, PROMPT USER FOR HIS CHOICE      41310020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      41400020
         BE    QUALPRMT            GO PROMPT FOR QUALIFIER              41490020
         LA    R2,M02              MESSAGE NUMBER 2                     41580020
         SR    R10,R10             NO INSERTION                         41670020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     41760020
         LA    R2,S01              SECOND LEVEL MESSAGE 1               41850020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     41940020
PRMPT    BAL   R9,TPUTGET          PROMPT TERMINAL USER                 42030020
*  NOW CHECK USERS RESPONSE                                             42120020
RESPONSE LA    R9,PROMPT           POINT TO PUTGET PARAMETER BLOCK      42210020
         L     R9,PGPBIBUF-PGPB(R9) LOAD POINTER TO INPUT BUFFER        42300020
         LA    R1,CSPLPARM         POINT TO CSPL                        42390020
         ST    R9,CSPLCBUF-CSPL(R1) RESPONSE TO CSPL                    42480020
         LINK  EP=IKJSCAN          LINK TO COMMAND SCAN ROUTINE         42570020
         LA    R11,CSOAAREA        POINT TO COMMAND SCAN OUTPUT AREA    42660020
         USING CSOA,R11            ADDRESSABILITY CSOA                  42750020
         MVC   COMFIELD(L8),UPERCASE BLANK COMPARE BUFFER               42840020
         CLI   CSOAFLG,CSOAVWP     IS IT VALID WITH PARAMETERS          42930020
         BE    GOODREP             YES, GOOD RESPONSE                   43020020
         CLI   CSOAFLG,CSOAVNP     IS IT VALID WITHOUT PARAMETERS       43110020
         BNE   BADREP              NO, BAD RESPONSE                     43200020
GOODREP  L     R2,CSOACNM          POINT TO RESPONSE                    43290020
         LH    R8,CSOALNM          LENGTH OF RESPONSE                   43380020
         BCTR  R8,R0               DECREMENT FOR EXECUTE                43470020
         EX    R8,MOVERPLY         USER'S RESPONSE TO COMPARE BUFFER    43560020
         LA    R8,F5(R8)           4 FOR HEADER AND 1 FOR EXECUTE       43650020
         STH   R8,COMFLDL          LENGTH FOR MESSAGE INSERTION         43740020
         DROP  R11                 CSOA NO LONGER NEEDED                43830020
         BAL   R14,FREEBUFF        GO FREE BUFFER                       43920020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      44010020
         BE    OKNME               NAME IS OK                           44100020
         LH    R11,QUALCNT         NUMBER OF QUALIFIERS                 44190020
*  INITIALIZE FOR COMPARISON OF RESPONSE TO LIST.                       44280020
         LR    R0,R11              NUMBER OF QUALIFIERS IN REG 0        44370020
         SR    R11,R11             CLEAR REGISTER                       44460020
         LA    R2,QUALLIST         POINT TO QUALLIST                    44550020
COMPARE  CLC   COMFIELD(L8),F0(R2) COMPARE QUALIFIER TO LIST            44640020
         BE    OKNAME              RESPONSE IS FROM LIST                44730020
         LA    R11,F1(R11)         NUMBER OF QUALIFIERS COMPARED        44820020
         CR    R0,R11              ARE THERE MORE QUALIFIERS IN LIST    44910020
         BE    UNLISTED            RESPONSE NOT FROM LIST               45000020
         LA    R2,L8(R2)           POINT TO NEXT QUALIFIER IN LIST      45090020
         B     COMPARE             GO COMPARE NEXT CHARACTER            45180020
OKNAME   MVC   SCANBUFF(L8),F0(R2) USER RESPONSE TO SCANBUFFER          45270020
GOSCAN   BAL   R14,SCANNAME        GO TO SCAN ROUTINE                   45360020
         B     ADDQUAL             NOW ADD QUALIFIER                    45450020
BADREP   LH    R8,F0(R9)           LENGTH OF INPUT BUFFER               45540020
         LA    R1,FOUR             R1 = 4                               45630020
         SR    R8,R1               LESS HEADER LENGTH                   45720020
         LTR   R8,R8               TEST LENGTH                          45810020
         BZ    BADREPLY            ZERO LENGTH IS BAD RESPONSE          45900020
         LA    R1,L8               R1 = 8                               45990020
         CR    R8,R1               IS LENGTH GREATER THAN 8             46080020
         BNH   OKREPLTH            LESS THAN 8 IS OK                    46170020
         LR    R8,R1               SET MAXIMUM LENGTH = 8               46260020
OKREPLTH BCTR  R8,R0               DECREMENT FOR EXECUTE                46350020
         LH    R1,F2(R9)           OFFSET TO RESPONSE                   46440020
         LA    R2,F4(R1,R9)        POINT TO RESPONSE                    46530020
         EX    R8,MOVERPLY         MOVE RESPONSE                        46620020
         BAL   R14,FREEBUFF        GO FREE BUFFER                       46660020
         LA    R8,F1(R8)           ONE FROM EXECUTE                     46670020
BADREPLY LA    R8,F4(R8)           4 FOR HEADER                         46710020
         STH   R8,COMFLDL          LENGTH FOR MESSAGE INSERTION         46800020
UNLISTED LA    R2,M03              MESSAGE NUMBER 3                     46980020
         LA    R10,COMFLDL         POINT TO INSERTION                   47070020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     47160020
         BAL   R9,TPUT             GO WRITE MESSAGE                     47250020
         BAL   R11,MESG4           GO GET MESSAGE 4                     47340020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      47430020
         BE    BADRESP             INVALID RESPONSE                     47520020
         LA    R2,S02              SECOND LEVEL MESSAGE 2               47610020
         SR    R10,R10             NO INSERTION                         47700020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     47790020
         B     PRMPT               GO PROMPT USER                       47880020
MESG4    LA    R2,M04              MESSAGE NUMBER 4                     47970020
         SR    R10,R10             NO INSERTION                         48060020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     48150020
         BR    R11                 RETURN                               48240020
MESG10   LA    R2,M10              MESSAGE NUMBER 10                    48330020
         LA    R10,DSNMESGL        POINT TO INSERTION                   48420020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     48510020
         BR    R11                 RETURN                               48600020
REUSE    LA    R2,M08              MESSAGE NUMBER 8                     48690020
         LA    R10,DSNMESGL        POINT TO INSERTION                   48780020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     48870020
         BAL   R9,TPUT             GO WRITE MESSAGE                     48960020
         LA    R2,M09              MESSAGE NUMBER 9                     49050020
         SR    R10,R10             NO INSERTION                         49140020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     49180020
         BAL   R9,TPUTGET          GO PROMPT                            49230020
         B     OKMSG               OK TO USE DATA SET                   49320020
OKNME    MVC   SCANBUFF(F8),COMFIELD MOVE NAME TO SCAN BUFFER           49410020
         B     GOSCAN              GO SCAN NAME                         49500020
BADRESP  LA    R2,S03              SECOND LEVEL MESSAGE 3               49590020
         SR    R10,R10             NO INSERTION                         49680020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     49770020
         B     PRMPT               GO PROMPT USER                       49860020
*  NOW FREE BUFFER FROM PUTGET                                          49950020
FREEBUFF LH    R11,F0(R9)          GET BUFFER LENGTH                    50040020
         ST    R11,WORKWORD        SAVE BUFFER LENGTH                   50130020
         MVI   WORKWORD,SPN        SUBPOOL NUMBER IN HIGH ORDER BYTE    50220020
         L     R0,WORKWORD         SUBPOOL NUMBER AND LENGTH            50310020
         LR    R1,R9               ADDRESS OF BUFFER                    50400020
         FREEMAIN R,LV=(0),A=(1)   FREE BUFFER                          50490020
         BR    R14                 RETURN                               50580020
*  THIS SECTION DETERMINES THE LENGTH OF NAMES. THE NAME IS IN SCANBUFF 50670020
*  AND THE MAXLENGTH IS 8. THE NINTH BYTE IS BLANK. SCAN STARTS AT      50760020
*  FIRST CHARACTER AND ENDS WHEN A BLANK IS FOUND.  THE LENGTH IS       50850020
*  RETURNED IN REGISTER 1.                                              50940020
SCANNAME SR    R1,R1               CLEAR REGISTER                       51030020
         LA    R8,SCANBUFF         ADDRESS OF SCAN BUFFER               51120020
BLANKTST CLI   F0(R8),BLANK        IS THIS CHARACTER A BLANK            51210020
         BCR   EQ,R14              BLANK ENDS SCAN, RETURN              51300020
         LA    R8,F1(R8)           POINT TO NEXT CHARACTER              51390020
         LA    R1,F1(R1)           BUMP LENGTH COUNT                    51480020
         B     BLANKTST            GO CHECK NEXT CHARACTER              51570020
ENDOFSCN BR    R14                 RETURN                               51660020
*  QUALIFIER SPECIFIED, ADD IT TO DSNAME                                51750020
ADDNAME  MVC   SCANBUFF(L8),F0(R5) MOVE QUALIFIER TO SCAN BUFFER        51840020
         BAL   R14,SCANNAME        GO TO SCAN ROUTINE                   51930020
         LTR   R1,R1               R1 CONTAINS QUALIFIER LENGTH         52020020
         BZ    ERROR28             IF ZERO LENGTH, ERROR                52110020
         LH    R9,DSL              LENGTH OF DSNAME                     52200020
         AR    R9,R1               ADD LENGTH OF QUALIFIER              52290020
         LR    R4,R5               POINT R4 TO QUALIFIER                52380020
         LA    R8,DSNAME           POINT TO DSNAME                      52470020
         AH    R8,DSL              ADD LENGTH, POINT PAST DSNAME        52560020
         TM    SWITCH,SWON         TEST SWITCH, WAS LENGTH ZERO         52650020
         BO    NOPERIOD            YES, DO NOT ADD PERIOD               52740020
         LA    R9,F1(R9)           ADD ONE FOR PERIOD                   52830020
         MVI   F0(R8),PERIOD       MOVE IN A PERIOD                     52920020
         LA    R8,F1(R8)           POINT PAST THE PERIOD                53010020
NOPERIOD CH    R9,DSMAXSZE         COMPARE TOTAL TO 44                  53100020
         BH    LENTHERR            ERROR, LENGTH GT 44                  53190020
         STH   R9,DSL              SAVE TOTAL LENGTH                    53280020
         BCTR  R1,R0               DECREMENT LENGTH FOR EXECUTE         53370020
         EX    R1,MOVEINST         MOVE QUALIFIER TO NAME               53460020
         MVC   F0(L46,R3),DSL      MOVE QUALIFIED NAME TO USER'S AREA   53550020
         CLI   ADDSW,SWON          IS ADD SWITCH ON                     53600020
         BE    CALCIR              YES, CIR ALREADY LOADED              53610020
         B     CHECKNME            GO CHECK THIS NAME                   53640020
*                                                                       53730020
*  THIS IS THE MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE MESSAGE CSECT 53820020
*  TO OBTAIN THE ADDRESS OF THE MESSAGE SEGMENT AND THE OFFSET AT WHICH 53910020
*  ANY INSERTIONS WILL BE MADE.                                         54000020
*  AT ENTRY R2 CONTAINS MESSAGE NUMBER AND R10 CONTAINS ADDRESS OF THE  54090020
*  INSERTION.  R14 IS THE RETURN REGISTER  (R10 = 0 IS NO INSERTION)    54180020
*                                                                       54270020
MSGBUILD SR    R3,R3               ZERO REGISTER                        54360020
         ST    R3,OUTAREA1         SET POINTER INDICATING ONE MESSAGE   54450020
         MVI   OUTAREA1,ENDTEST    FLAG END OF MESSAGE CHAIN            54540020
         L     R1,VCONMSG          ADDRESS OF MESSAGE BRANCH TABLE      54630020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             54720020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         54810020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              54900020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      54990020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                55080020
         ST    R3,OUTPUT11         MESSAGE ADDRESS TO OUTPUT LIST       55170020
         LTR   R10,R10             IS THERE AN INSERTION                55260020
         BZ    NOINSRT1            NO, GO SET SEGMENT COUNT TO 1        55350020
         SR    R2,R2               ZERO REGISTER                        55440020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             55530020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 55620020
         ST    R10,OUTPUT12        INSERTION ADDRESS TO OUTPUT LIST     55710020
         LA    R2,TWO              2 SEGMENTS                           55800020
SETCNT1  ST    R2,OUTCNT1          SET SEGMENT COUNT                    55890020
         BR    R14                 RETURN                               55980020
NOINSRT1 LA    R2,ONE              ONE SEGMENT                          56070020
         B     SETCNT1             GO SET SEGMENT COUNT                 56160020
*                                                                       56250020
*  THIS IS THE SECOND LEVEL MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE  56340020
*  MESSAGE CSECT TO OBTAIN THE ADDRESS OF THE SECOND LEVEL MESSAGE AND  56430020
*  THE OFFSET AT WHICH ANY INSERTIONS WILL BE MADE.                     56520020
*  AT ENTRY R2 CONTAINS SECOND LEVEL MESSAGE NUMBER AND R10 CONTAINS    56610020
*  ADDRESS OF THE INSERTION.  R14 IS THE RETURN REGISTER.  (R10 = 0 IS  56700020
*  NO INSERTION                                                         56790020
*                                                                       56880020
SMSGBLD  SR    R3,R3               ZERO REGISTER                        56970020
         ST    R3,OUTAREA2         SET POINTER INDICATING LAST MESSAGE  57060020
         MVI   OUTAREA2,ENDTEST    FLAG END OF MESSAGE CHAIN            57150020
         LA    R3,OUTAREA2         POINT TO SECOND LEVEL MESSAGE CHAIN  57240020
         ST    R3,OUTAREA1         CHAIN SECOND LEVEL TO FIRST LEVEL    57330020
         L     R1,VCONSMSG         SECOND LEVEL MESSAGE BRANCH TABLE    57420020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             57510020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         57600020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              57690020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      57780020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                57870020
         ST    R3,OUTPUT21         MESSAGE ADDRESS TO OUTPUT LIST       57960020
         LTR   R10,R10             IS THERE AN INSERTION                58050020
         BZ    NOINSRT2            NO, GO SET SEGMENT COUNT TO 1        58140020
         SR    R2,R2               ZERO REGISTER                        58230020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             58320020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 58410020
         ST    R10,OUTPUT22        INSERTION ADDRESS TO OUTPUT LIST     58500020
         LA    R2,TWO              2 SEGMENTS                           58590020
SETCNT2  ST    R2,OUTCNT2          SET SEGMENT COUNT                    58680020
         BR    R14                 RETURN                               58770020
NOINSRT2 LA    R2,ONE              ONE SEGMENT                          58860020
         B     SETCNT2             GO SET SEGMENT COUNT                 58950020
*  CONVERT RETURN CODE, SUPPRESS LEADING ZEROS AND MOVE TO INSERTION    59040020
*  BUFFER.  INPUT - R15 CONTAINS RETURN CODE TO BE CONVERTED            59130020
*           OUTPUT - R10 POINTS TO INSERTION BUFFER                     59220020
*  R2 IS THE RETURN REGISTER                                            59310020
CONVRTRC CVD   R15,UNPACK          CONVERT TO PACKED DECIMAL FORMAT     59400020
         UNPK  COUNT,UNPACK        CONVERT TO ZONED FORMAT              59490020
         OI    SIGNBYTE,ZONE       ZONE OVER SIGN                       59580020
*  SUPPRESS LEADING ZEROS IN RETURN CODE                                59670020
         LA    R4,COUNT            POINT TO COUNT BUFFER                59760020
         LA    R5,F7               R5 = 7                               59850020
SUPPZERO CLI   F0(R4),FOXZERO      IS THIS LEADING ZERO                 59940020
         BNE   NOTZERO             NO, GO MOVE RETURN CODE              60030020
         LA    R4,F1(R4)           YES, POINT TO NEXT DIGIT             60120020
         BCT   R5,SUPPZERO         GO CHECK NEXT DIGIT                  60210020
NOTZERO  LA    R5,ENDCOUNT         POINT PAST COUNT BUFFER              60300020
         SR    R5,R4               NUMBER OF SIGNIFICANT DIGITS IN R5   60390020
         BCTR  R5,R0               DECREMENT FOR EXECUTE                60480020
         LA    R8,RCMESG           POINT TO RETURN CODE BUFFER          60570020
         EX    R5,MOVEINST         MOVE RETURN CODE TO INSERTION BUFFER 60660020
         LA    R5,F5(R5)           4 FOR HEADER AND 1 FOR EXECUTE       60750020
         STH   R5,RCMESGL          LENGTH OF RETURN CODE INSERTION      60840020
         LA    R10,RCMESGL         POINT TO INSERTION BUFFER            60930020
         BR    R2                  RETURN                               61020020
*  THIS ROUTINE CHECKS FOR ATTENTION INTERRUPT                          61110020
TESTATTN LA    R4,ECBADDR          POINT TO CP'S ECB                    61200020
         TM    F0(R4),MASK1        IS ECB POSTED (DID ATTENTION OCCUR)  61290020
         BO    INTERUPT            YES, SET RC, CLEANUP AND RETURN      61380020
         BR    R14                 RETURN                               61470020
*  THIS ROUTINE WRITES A LINE TO THE TERMINAL.                          61560020
*  REG 9 IS THE RETURN REGISTER.                                        61650020
TPUT     LA    R1,IOPARM           POINT TO IO PARAMETERS               61740020
         PUTLINE PARM=PUT,OUTPUT=(OUTAREA1,MULTLVL),MF=(E,(1)),        X61830020
               TERMPUT=(EDIT,WAIT) WRITE A LINE                         61920020
         LTR   R15,R15             TEST RETURN CODE                     62010020
         BZ    OKPUT               OK, RETURN                           62100020
         LA    R4,RC4              R4 = 4                               62190020
TESTRC   CR    R15,R4              DID AN INTERUPT OCCUR                62280020
         BE    INTERUPT            HANDLE INTERUPT                      62370020
         BAL   R11,MESG10          GO GET MESSAGE 10                    62460020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         62550020
         LA    R2,S06              SECOND LEVEL MESSAGE 6               62640020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     62730020
         BAL   R9,TPUT             GO WRITE MESSAGE                     62820020
         B     ERROR4              GO SET RETURN CODE                   62910020
OKPUT    BR    R9                  RETURN                               63000020
*  THIS  ROUTINE PROMPTS THE TERMINAL USER.                             63090020
*  REG 9 IS THE RETURN REGISTER                                         63180020
TPUTGET  LA    R1,IOPARM           POINT TO IO PARAMETERS               63270020
         PUTGET PARM=PROMPT,OUTPUT=(OUTAREA1,MULTLVL),MF=(E,(1)),      X63360020
               TERMPUT=(ASIS,WAIT),TERMGET=(EDIT,WAIT) PROMPT           63450020
         LTR   R15,R15             TEST RETURN CODE                     63540020
         BZ    OKPUT               OK, RETURN                           63630020
         LA    R4,RC4              UNABLE TO PROMPT RETURN CODE         63720020
         CR    R15,R4              UNABLE TO PROMPT                     63810020
         BE    CANTPRMT            YES, CAN NOT PROMPT                  63900020
         LA    R4,RC8              R4 = 8                               63990020
         CR    R15,R4              DID ATTENTION OCCUR                  64080020
         BE    INTERUPT            YES, PROCESS INTERRUPT               64170020
         BAL   R11,MESG10          GO GET MESSAGE 10                    64260020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         64350020
         LA    R2,S07              SECOND LEVEL MESSAGE 7               64440020
         BAL   R14,SMSGBLD         GO BUILD MESSAGE                     64530020
         BAL   R9,TPUT             GO WRITE MESSAGE                     64620020
         B     ERROR4              GO SET RETURN CODE                   64710020
GOODEND  L     R3,DFPBDSN          POINT TO DSNAME BUFFER               64770020
         MVC   F0(L46,R3),DSL      MOVE QUALIFIED NAME TO USER'S AREA   64830020
OKMSG    SR    R15,R15             SET RETURN CODE TO 0                 64890020
         B     CLEANUP             GO RESTORE                           64980020
LENTHERR LA    R15,RC8             SET RETURN CODE TO 8                 65070020
         B     CLEANUP             GO RESTORE                           65160020
CANTPRMT LA    R2,M11              MESSAGE NUMBER 11                    65250020
         LA    R10,DSNMESGL        POINT TO INSERTION                   65340020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     65430020
         BAL   R9,TPUT             GO WRITE MESSAGE                     65520020
ERROR4   LA    R15,RC4             SET RETURN CODE TO 4                 65610020
         B     CLEANUP             GO RESTORE                           65700020
CIRERROR MVC   DFPBLORC(F1),CIRPARM SAVE LOCATE RETURN CODE             65790020
         TM    CIRPARM,LOCMSK8     CHECK FOR LOCATE RC = 8              65880020
         BE    ERROR20             YES, SET RETURN CODE = 20            65970020
         TM    CIRPARM,LOCMSK16    CHECK FOR LOCATE RC = 16             66060020
         BE    ERROR16             YES, SET RETURN CODE = 16            66150020
         SR    R15,R15             CLEAR REGISTER                       66240020
         IC    R15,CIRPARM         LOAD LOCATE RETURN CODE              66330020
         BAL   R11,MESG10          GO GET MESSAGE 10                    66420020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         66510020
         LA    R2,S08              SECOND LEVEL MESSAGE 8               66600020
         BAL   R9,TPUT             GO WRITE MESSAGE                     66690020
ERROR12  LA    R15,RC12            SET RETURN CODE TO 12                66780020
         B     CLEANUP             GO RESTORE                           66870020
ERROR16  LA    R15,RC16            SET RETURN CODE TO 16                66960020
         B     CLEANUP             GO RESTORE                           67050020
ERROR20  LA    R15,RC20            SET RETURN CODE TO 20                67140020
         CLI   DFPBCODE,DFPB0C     IS OPTION X'0C'                      67170020
         BE    GOODEND             YES, NAME NOT FOUND IS OKAY          67200020
         B     CLEANUP             GO RESTORE                           67230020
ERROR28  LA    R15,RC28            SET RETURN CODE TO 28                67320020
         B     CLEANUP             GO RESTORE                           67410020
ERROR32  LA    R15,RC32            SET RETURN CODE = 32                 67500020
         B     CLEANUP             GO RESTORE                           67590020
ERROR36  LA    R15,RC36            SET RETURN CODE TO 36                67680020
         B     CLEANUP             GO RESTORE                           67770020
INTERUPT LA    R15,RC24            SET RETURN CODE = 24                 67860020
         B     WRAPUP              GO FREE CORE AND LOAD MODULES        67950020
*  CLEAN UP ROUTINE                                                     68040020
CLEANUP  BAL   R14,TESTATTN        CHECK FOR INTERRUPT                  68130020
WRAPUP   L     R1,CIRADDR          LOAD ADDRESS OF CIR                  68220020
         LR    R2,R15              SAVE RETURN CODE IN REGISTER 2       68310020
         LTR   R1,R1               CHECK IF CIR WAS LOADED              68400020
         BZ    NOCIR               CIR WAS NOT LOADED                   68490020
         DELETE EP=IKJEHCIR        DELETE CIR                           68580020
NOCIR    L     R3,F4(R13)          REGISTER 3 POINTS TO CALLER'S REGS   68670020
         LR    R1,R13              REGISTER 1 = CORE TO BE FREED        68760020
         FREEMAIN R,LV=CORE,A=(1),SP=SPN  FREE CORE                     68850020
         LR    R15,R2              RC BACK TO REGISTER 15               68940020
         LR    R13,R3              REGISTER 13 POINTS TO CALLER'S REGS  69030020
         RETURN (14,12),T,RC=(15)  RESTORE REGISTERS AND RETURN         69120020
         EJECT                                                          69210020
*  CONSTANTS                                                            69300020
BLANKS   DC    C'  '               TWO BLANKS FOR MESSAGE SPACING       69390020
MAXNAMES DC    H'25'               MAXIMUM QUALIFIERS SUPPORTED         69480020
DSMAXSZE DC    H'44'               MAXIMUM DATA SET LENGTH              69570020
MOVEINST MVC   F0(F0,R8),F0(R4)    MOVE INSTRUCTION FOR EXECUTE         69660020
MOVEID   MVC   F0(F0,R8),F0(R2)    USED TO MOVE USERID                  69750020
MOVERPLY MVC   COMFIELD(F0),F0(R2) USED TO MOVE USER'S RESPONSE         69840020
DSNINSRT MVC   DSNMESG(F0),F2(R3)  MOVE DSNAME TO INSERTION BUFFER      69930020
UPERCASE DC    CL8' '              USED TO CONVERT RESPONSE             70020020
VCONMSG  DC    V(IKJEHMSG)         ENTRY MESSAGE CSECT 1ST LEVEL        70110020
VCONSMSG DC    V(IKJEHSMG)         ENTRY MESSAGE CSECT 2ND LEVEL        70200020
PUTL     PUTLINE  MF=L             LIST FORM OF PUTLINE                 70290020
PUTLEND  EQU   *                   END OF PUTGET EXPANSION              70380020
PRMPT1   PUTGET  MF=L              LIST FORM OF PUTGET                  70470020
PRMPTEND EQU   *                   END OF PUTGET EXPANSION              70560020
         EJECT                                                          70650020
*  MAPPING MACROS                                                       70740020
         SPACE                                                          70830020
         IKJDFPL                                                        70920020
         IKJDFPB                                                        71010020
         IKJPSCB                                                        71100020
         IKJCSPL                                                        71190020
LCSPL    EQU   *-CSPL              LENGTH OF CSPL                       71280020
         IKJCSOA                                                        71370020
LCSOA    EQU   *-CSOA              LENGTH OF CSOA                       71460020
         IKJIOPL                                                        71550020
LIOPL    EQU   *-IOPL              LENGTH OF IOPL                       71640020
         IKJPGPB                                                        71730020
         EJECT                                                          71820020
WORKAREA DSECT                                                          71910020
SAVEAREA DS    18F                 REGISTER SAVE AREA                   72000020
UNPACK   DS    D                   WORKAREA FOR CVD                     72090020
COUNT    DS    D                   WORKAREA FOR UNPACK                  72180020
         ORG   COUNT+F7            BACK TO LAST BYTE OF COUNT FIELD     72270020
SIGNBYTE DS    CL1                 LABEL SIGN BYTE                      72360020
         ORG                                                            72450020
ENDCOUNT EQU   *                   END OF COUNT FIELD                   72540020
CIRADDR  DS    F                   ADDRESS OF CIR                       72630020
WORKWORD DS    F                   WORD BOUNDRY WORK WORD               72720020
FLAGWORD DS    F                   FLAG WORD FOR COMMAND SCAN           72810020
ECBADDR  DS    F                   SAVE ECB ADDRESS HERE                72900020
*  CIR PARAMETER LIST                                                   72990020
CIRPARM  DS    F                   CIR OPTION                           73080020
NAMETTR  DS    F                   POINTER TO DSNAME OR TTR             73170020
CVOLIDPT DS    F                   POINTER TO CVOLID                    73260020
WKAR1PTR DS    F                   POINTER TO FIRST CIR WORKAREA        73350020
WKAR2PTR DS    F                   POINTER TO SECOND CIR WORKAREA       73440020
*  END OF CIR PARAMETER LIST                                            73530020
WKAREA2  DS    18F                 SECOND CIR WORKAREA                  73620020
QUALLIST DS    50F                 SPACE TO BUILD LIST OF QUALIFIERS    73710020
PUT      PUTLINE MF=L              LIST FORM OF PUTLINE                 73800020
PROMPT   PUTGET MF=L               LIST FORM OF PUTGET                  73890020
         DS    0F                  ALIGN WORD BOUNDRY                   73980020
IOPARM   DS    (LIOPL)X            SPACE FOR I/O PARAMETER LIST         74070020
         DS    0F                  ALIGN WORD BOUNDRY                   74160020
CSPLPARM DS    (LCSPL)X            SPACE FOR COMMAND SCAN PARM LIST     74250020
         DS    0F                  ALIGN WORD BOUNDRY                   74340020
CSOAAREA DS    (LCSOA)X            SPACE FOR COMMAND SCAN OUTPUT AREA   74430020
*  THE FOLLOWING IS RESERVED SPACE FOR OUTPUT CHAINS                    74520020
OUTAREA1 DS    F                   MESSAGE CHAIN POINTER                74610020
OUTCNT1  DS    F                   MESSAGE SEGMENT COUNT                74700020
OUTPUT11 DS    F                   POINTER TO MESSAGE SEGMENT           74790020
OUTPUT12 DS    F                   POINTER TO MESSAGE INSERTION         74880020
OUTAREA2 DS    F                   MESSAGE CHAIN POINTER                74970020
OUTCNT2  DS    F                   MESSAGE SEGMENT COUNT                75060020
OUTPUT21 DS    F                   POINTER TO MESSAGE SEGMENT           75150020
OUTPUT22 DS    F                   POINTER TO MESSAGE INSERTION         75240020
*  DATA SET NAME FOR MESSAGES STORED HERE                               75330020
DSNMESGL DS    H                   DATA SET LENGTH                      75420020
DSNMESGO DS    H                   OFFSET                               75510020
DSNMESG  DS    CL52                DATA SET NAME                        75600020
*  RETURN CODES FOR MESSAGES STORED HERE                                75690020
RCMESGL  DS    H                   RETURN CODE LENGTH                   75780020
RCMESGO  DS    H                   OFFSET                               75870020
RCMESG   DS    CL4                 RETURN CODE                          75960020
*  OUTPUT BUFFER FOR QUALIFIERS                                         76050020
OUTBUFFL DS    H                   LENGTH OF OUTBUFF                    76140020
OUTBUFFO DS    H                   OFFSET                               76230020
OUTBUFF  DS    CL40                OUTBUFF                              76320020
*  COMPARE FIELD FOR USER'S RESPONSE                                    76410020
COMFLDL  DS    H                   LENGTH OF RESPONSE                   76500020
COMFLDO  DS    H                   OFFSET OF RESPONSE                   76590020
COMFIELD DS    CL8                 COMPARE BUFFER                       76680020
         DS    0D                  ALIGN DOUBLE WORD BOUNDRY            76770020
WKAREA1  DS    CL265               FIRST CIR WORKAREA                   76860020
CVOLID   DS    CL6                 CONTROL VOLUME ID                    76950020
TTR      DS    CL3                 TTR                                  77040020
SCANBUFF DS    CL9                 SCAN BUFFER                          77130020
SWITCH   DS    CL1                 SET ON WHEN DSLENGTH IS ZERO         77220020
TESTBYTE DS    CL1                 BYTE FOR TESTING                     77310020
ADDSW    DS    CL1                 INDICATE SPECIFIED QUALIFIER ADDED   77360020
         DS    0H                  ALIGN HALF WORD BOUNDRY              77400020
DSL      DS    CL2                 DATA SET LENGTH                      77490020
DSNAME   DS    CL44                DATA SET NAME BUFFER                 77580020
QUALCNT  DS    H                   NUMBER OF QUALIFIERS FOUND           77670020
CORE     EQU   *-WORKAREA          SIZE OF GETMAIN AREA                 77760020
         EJECT                                                          77850020
IKJEHMSG CSECT                                                          77940020
         ENTRY IKJEHSMG                                                 78030020
*********************************************************************** 78120020
*                                                                     * 78210020
*  THIS CONTROL SECTION CONTAINS THE MESSAGE TEXT (BOTH FIRST AND     * 78300020
*  SECOND LEVEL).  IT CONTAINS A BRANCH TABLE FOR FIRST LEVEL MESSAGES* 78390020
*  AND A BRANCH TABLE FOR SECOND LEVEL MESSAGES.  EACH BRANCH TABLE   * 78480020
*  ENTRY IS COMPOSED OF A ONE BYTE OFFSET FIELD FOR MESSAGE INSERTIONS* 78570020
*  AND A THREE BYTE ADDRESS OF THE MESSAGE.  THE MESSAGE BUILDER      * 78660020
*  ROUTINES COMBINE THE ADDRESS OF THE CONTROL SECTION AND THE ADDRESS* 78750020
*  OF THE MESSAGE TO GET THE TRUE ADDRESS OF THE MESSAGE.  THE OFFSET * 78840020
*  IS PLACED IN THE INSERTION SEGMENT.                                * 78930020
*  EACH MESSAGE IS COMPOSED OF A 4 BYTE HEADER (2 BYTE LENGTH OF      * 79020020
*  MESSAGE INCLUDING HEADER LENGTH AND A 2 BYTE OFFSET FIELD)         * 79110020
*  FOLLOWED BY THE MESSAGE TEXT.                                      * 79200020
*                                                                     * 79290020
*********************************************************************** 79380020
         SPACE                                                          79470020
*  EQUATES USED IN THIS CONTROL SECTION                                 79560020
HDR      EQU   4                   HEADER LENGTH (2 BYTES EACH, LENGTH  79650020
*                                  AND OFFSET FIELDS) EACH SEGMENT      79740020
OFST     EQU   0                   INSERTION OFFSET 1ST MESSAGE SEGMENT 79830020
*  OFFSETS FOR FIRST LEVEL MESSAGE INSERTIONS                           79920020
OFST01   EQU   34                  INSERTION OFFSET MESSAGE 01          80010020
OFST02   EQU   0                   INSERTION OFFSET MESSAGE 02          80100020
OFST03   EQU   28                  INSERTION OFFSET MESSAGE 03          80190020
OFST04   EQU   0                   INSERTION OFFSET MESSAGE 04          80280020
OFST05   EQU   0                   INSERTION OFFSET MESSAGE 05          80370020
OFST06   EQU   24                  INSERTION OFFSET MESSAGE 06          80460020
OFST07   EQU   30                  INSERTION OFFSET MESSAGE 07          80550020
OFST08   EQU   19                  INSERTION OFFSET MESSAGE 08          80640020
OFST09   EQU   0                   INSERTION OFFSET MESSAGE 09          80730020
OFST10   EQU   24                  INSERTION OFFSET MESSAGE 10          80820020
OFST11   EQU   24                  INSERTION OFFSET MESSAGE 11          80910020
OFST12   EQU   10                  INSERTION OFFSET MESSAGE 12          81000020
*  OFFSETS FOR SECOND LEVEL MESSAGE INSERTIONS                          81090020
*  NOTE-  THERE ARE CURRENTLY NO INSERTIONS IN MOST SECOND LEVEL        81180020
*  MESSAGES.  A COMMON OFFSET OF ZERO IS USED.                          81270020
OFSTSMSG EQU   0                   INSERTION OFFSET 2ND LEVEL MESSAGES  81360020
OFSTSM06 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 06 81450020
OFSTSM07 EQU   28                  INSERTION OFFSET SECOND LEVEL MSG 07 81540020
OFSTSM08 EQU   28                  INSERTION OFFSET SECOND LEVEL MSG 08 81630020
         SPACE                                                          81720020
AMSG01   DC    AL1(OFST01)         INSERTION OFFSET                     81810020
         DC    AL3(LMSG01)         MESSAGE ADDRESS                      81900020
AMSG02   DC    AL1(OFST02)         INSERTION OFFSET                     81990020
         DC    AL3(LMSG02)         MESSAGE ADDRESS                      82080020
AMSG03   DC    AL1(OFST03)         INSERTION OFFSET                     82170020
         DC    AL3(LMSG03)         MESSAGE ADDRESS                      82260020
AMSG04   DC    AL1(OFST04)         INSERTION OFFSET                     82350020
         DC    AL3(LMSG04)         MESSAGE ADDRESS                      82440020
AMSG05   DC    AL1(OFST05)         INSERTION OFFSET                     82530020
         DC    AL3(LMSG05)         MESSAGE ADDRESS                      82620020
AMSG06   DC    AL1(OFST06)         INSERTION OFFSET                     82710020
         DC    AL3(LMSG06)         MESSAGE ADDRESS                      82800020
AMSG07   DC    AL1(OFST07)         INSERTION OFFSET                     82890020
         DC    AL3(LMSG07)         MESSAGE ADDRESS                      82980020
AMSG08   DC    AL1(OFST08)         INSERTION OFFSET                     83070020
         DC    AL3(LMSG08)         MESSAGE ADDRESS                      83160020
AMSG09   DC    AL1(OFST09)         INSERTION OFFSET                     83250020
         DC    AL3(LMSG09)         MESSAGE ADDRESS                      83340020
AMSG10   DC    AL1(OFST10)         INSERTION OFFSET                     83430020
         DC    AL3(LMSG10)         MESSAGE ADDRESS                      83520020
AMSG11   DC    AL1(OFST11)         INSERTION OFFSET                     83610020
         DC    AL3(LMSG11)         MESSAGE ADDRESS                      83700020
AMSG12   DC    AL1(OFST12)         INSERTION OFFSET                     83790020
         DC    AL3(LMSG12)         MESSAGE ADDRESS                      83880020
*  FIRST LEVEL MESSAGES                                                 83970020
LMSG01   DC    AL2(L'MSG01+HDR)                                         84060020
         DC    AL2(OFST)                                                84150020
MSG01    DC    C'IKJ58600I QUALIFIERS FOR DATA SET  ARE'                84240020
LMSG02   DC    AL2(L'MSG02+HDR)                                         84330020
         DC    AL2(OFST)                                                84420020
MSG02    DC    C'IKJ58601A ENTER QUALIFIER-'                            84510020
LMSG03   DC    AL2(L'MSG03+HDR)                                         84600020
         DC    AL2(OFST)                                                84690020
MSG03    DC    C'IKJ58602I INVALID QUALIFIER '                          84780020
LMSG04   DC    AL2(L'MSG04+HDR)                                         84870020
         DC    AL2(OFST)                                                84960020
MSG04    DC    C'IKJ58603A REENTER-'                                    85050020
LMSG05   DC    AL2(L'MSG05+HDR)                                         85140020
         DC    AL2(OFST)                                                85230020
MSG05    DC    C'IKJ58604A ENTER OLD OR NEW QUALIFIER-'                 85320020
LMSG06   DC    AL2(L'MSG06+HDR)                                         85410020
         DC    AL2(OFST)                                                85500020
MSG06    DC    C'IKJ58605I DATA SET NAME  NOT COMPLETE'                 85590020
LMSG07   DC    AL2(L'MSG07+HDR)                                         85680020
         DC    AL2(OFST)                                                85770020
MSG07    DC    C'IKJ58606A ENTER QUALIFIER FOR -'                       85860020
LMSG08   DC    AL2(L'MSG08+HDR)                                         85950020
         DC    AL2(OFST)                                                86040020
MSG08    DC    C'IKJ58607I DATA SET  IS ABOUT TO BE REUSED'             86130020
LMSG09   DC    AL2(L'MSG09+HDR)                                         86220020
         DC    AL2(OFST)                                                86310020
MSG09    DC    C'IKJ58608A ENTER CARRIER RETURN TO CONTINUE OR ATTENTIOX86400020
               N TO RESPECIFY COMMAND-'                                 86490020
LMSG10   DC    AL2(L'MSG10+HDR)                                         86580020
         DC    AL2(OFST)                                                86670020
MSG10    DC    C'IKJ58609I DATA SET NAME  CANNOT BE RESOLVED, SYSTEM ERX86760020
               ROR+'                                                    86850020
LMSG11   DC    AL2(L'MSG11+HDR)                                         86940020
         DC    AL2(OFST)                                                87030020
MSG11    DC    C'IKJ58610I DATA SET NAME  NOT FULLY QUALIFIED'          87120020
LMSG12   DC    AL2(L'MSG12+HDR)                                         87210020
         DC    AL2(OFST)                                                87300020
MSG12    DC    C'IKJ58600I '                                            87390020
*  SECOND LEVEL MESSAGE BRANCH TABLE                                    87480020
IKJEHSMG DS    0F                  SECOND LEVEL MESSAGE BRANCH TABLE    87570020
ASMSG01  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     87660020
         DC    AL3(LSMSG01)        MESSAGE ADDRESS                      87750020
ASMSG02  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     87840020
         DC    AL3(LSMSG02)        MESSAGE ADDRESS                      87930020
ASMSG03  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     88020020
         DC    AL3(LSMSG03)        MESSAGE ADDRESS                      88110020
ASMSG04  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     88200020
         DC    AL3(LSMSG04)        MESSAGE ADDRESS                      88290020
ASMSG05  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     88380020
         DC    AL3(LSMSG05)        MESSAGE ADDRESS                      88470020
ASMSG06  DC    AL1(OFSTSM06)       INSERTION OFFSET                     88560020
         DC    AL3(LSMSG06)        MESSAGE ADDRESS                      88650020
ASMSG07  DC    AL1(OFSTSM07)       INSERTION OFFSET                     88740020
         DC    AL3(LSMSG07)        MESSAGE ADDRESS                      88830020
ASMSG08  DC    AL1(OFSTSM08)       INSERTION OFFSET                     88920020
         DC    AL3(LSMSG08)        MESSAGE ADDRESS                      89010020
*  SECOND LEVEL MESSAGES                                                89100020
LSMSG01  DC    AL2(L'SMSG01+HDR)                                        89190020
         DC    AL2(OFST)                                                89280020
SMSG01   DC    C'IKJ58601A DATA SET NAME WAS NOT FULLY QUALIFIED.  ENTEX89460020
               R DESIRED QUALIFIER FROM ABOVE LIST-'                    89550020
LSMSG02  DC    AL2(L'SMSG02+HDR)                                        89640020
         DC    AL2(OFST)                                                89730020
SMSG02   DC    C'IKJ58603A ONLY QUALIFIERS LISTED ARE VALID QUALIFIERS X89820020
               FOR THIS DATA SET NAME.  REENTER DESIRED QUALIFIER FROM X89910020
               ABOVE LIST-'                                             90000020
LSMSG03  DC    AL2(L'SMSG03+HDR)                                        90090020
         DC    AL2(OFST)                                                90180020
SMSG03   DC    C'IKJ58603A QUALIFIERS CONTAIN FROM 1 TO 8 ALPHANUMERIC X90270020
               CHARACTERS.  REENTER-'                                   90360020
LSMSG04  DC    AL2(L'SMSG04+HDR)                                        90450020
         DC    AL2(OFST)                                                90540020
SMSG04   DC    C'IKJ58604A DATA SET NAME WAS NOT FULLY QUALIFIED.  ENTEX90630020
               R NEW QUALIFIER OR ONE FROM ABOVE LIST-'                 90720020
LSMSG05  DC    AL2(L'SMSG05+HDR)                                        90810020
         DC    AL2(OFST)                                                90900020
SMSG05   DC    C'IKJ58606A DATA SET NAME WAS NOT FULLY QUALIFIED.  ENTEX90990020
               R NEW QUALIFIER-'                                        91080020
LSMSG06  DC    AL2(L'SMSG06+HDR)                                        91170020
         DC    AL2(OFST)                                                91260020
SMSG06   DC    C'IKJ58609I PUTLINE ERROR CODE '                         91350020
LSMSG07  DC    AL2(L'SMSG07+HDR)                                        91440020
         DC    AL2(OFST)                                                91530020
SMSG07   DC    C'IKJ58609I PUTGET ERROR CODE '                          91620020
LSMSG08  DC    AL2(L'SMSG08+HDR)                                        91710020
         DC    AL2(OFST)                                                91800020
SMSG08   DC    C'IKJ58609I LOCATE ERROR CODE '                          91890020
         END                                                            91980020
