DEL      TITLE 'IKJEHDEL-IBM S/360 TIME SHARING OPTION DELETE COMMAND'  00110021
IKJEHDEL CSECT                                                          00120020
*C 407900,429000,434900-435000,466800,473400,480300-480400       A49872 00120421
*C 170300                                                         M2009 00122021
*A 200200-200700                                                  M0876 00130021
*D 199800-200900                                                  M0876 00140021
*A 232720                                                        A45492 00150021
*D 233300                                                        A45492 00160021
******************   RELEASE 21.8 CHANGES    ****************           00162021
*C307800                                                        SA69167 00164021
*A199800                                                        SA66200 00166021
         SPACE 2                                                        00170020
*********************************************************************** 00180020
*                                                                     * 00230020
* STATUS  -- CHANGE LEVEL 01                                      M0876 00240021
*                                                                     * 00290020
* FUNCTION -- THE DELETE COMMAND IS USED TO DELETE A DATA SET, A      * 00300020
*    MEMBER OF A PARTITIONED DATA SET, OR A LIST OF DATA SETS AND/OR  * 00350020
*    MEMBERS                                                          * 00360020
*                                                                     * 00410020
* ENTRY POINTS --                                                     * 00420020
*         IKJEHDEL - MAIN ENTRY POINT OF PROGRAM, ATTACHED BY THE     * 00470020
*    TERMINAL MONITOR PROGRAM WHEN A DELETE COMMAND IS ENTERED AT A   * 00480020
*    TERMINAL                                                         * 00530020
*                                                                     * 00540020
* INPUT --  REGISTER 1 POINTS TO THE STANDARD COMMAND PROCESSOR       * 00590020
*    PARAMETER LIST (CPPL) AS FOLLOWS-                                * 00600020
*    WORD 1 CONTAINS A POINTER TO THE COMMAND BUFFER                  * 00650020
*    WORD 2 CONTAINS A POINTER TO THE USER PROFILE TABLE              * 00660020
*    WORD 3 CONTAINS A POINTER TO THE PROTECTED STOP CONTROL BLOCK    * 00710020
*    WORD 4 CONTAINS A POINTER TO AN ENVIRONMENT CONTROL TABLE        * 00720020
*                                                                     * 00770020
* OUTPUT -- NORMALLY NONE, EXCEPT APPROPRIATE ERROR MESSAGES TO       * 00780020
*    DESCRIBE ERROR CONDITIONS                                        * 00830020
*                                                                     * 00840020
* EXTERNAL REFERENCES --                                              * 00890020
*         IKJPARS - ENTRY POINT TO PARSE ROUTINE                      * 00900020
*         IKJDAIR - ENTRY POINT TO DYNAMIC ALLOCATION INTERFACE       * 00950020
*    ROUTINE                                                          * 00960020
*         IKJPUTL - ENTRY POINT TO PUTLINE ROUTINE                    * 01010020
*         IKJEHCIR - ENTRY POINT TO CATALOG INFORMATION ROUTINE       * 01020020
*         IKJDFLT - ENTRY POINT TO DEFAULT SERVICE ROUTINE            * 01070020
*         IKJEHSIR - ENTRY POINT FOR STAE INTERFACE ROUTINE           * 01080020
*                                                                     * 01130020
* EXITS, NORMAL -- RETURN TO THE TERMINAL MONITOR PROGRAM             * 01140020
*                                                                     * 01190020
* EXITS, ERROR -- RETURN TO THE TERMINAL MONITOR PROGRAM              * 01200020
*                                                                     * 01250020
* TABLES/WORKAREA --                                                  * 01260020
*    IHADCB - A DSECT TO MAP THE WORKAREA                             * 01310020
*                                                                     * 01320020
* ATTRIBUTES -- REENTRANT, READ-ONLY, REFRESHABLE                     * 01370020
*                                                                     * 01380020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 01430020
*                                                                     * 01440020
* NOTES -- N/A                                                        * 01490020
*                                                                     * 01500020
*********************************************************************** 01550020
         EJECT                                                          01560020
*              REGISTER EQUATES                                         01610020
R0       EQU   0                   GENERAL REGISTER 0                   01620020
R1       EQU   1                   GENERAL REGISTER 1                   01670020
R2       EQU   2                   GENERAL REGISTER 2                   01680020
R3       EQU   3                   GENERAL REGISTER 3                   01730020
R4       EQU   4                   GENERAL REGISTER 4 (UNUSED)          01740020
R5       EQU   5                   GENERAL REGISTER 5                   01790020
R6       EQU   6                   GENERAL REGISTER 6                   01800020
R7       EQU   7                   GENERAL REGISTER 7                   01850020
R8       EQU   8                   GENERAL REGISTER 8                   01860020
R9       EQU   9                   GENERAL REGISTER 9                   01910020
R10      EQU   10                  GENERAL REGISTER 10                  01920020
R11      EQU   11                  GENERAL REGISTER 11                  01970020
R12      EQU   12                  GENERAL REGISTER 12                  01980020
R13      EQU   13                  GENERAL REGISTER 13                  01990020
R14      EQU   14                  GENERAL REGISTER 14                  02000020
R15      EQU   15                  GENERAL REGISTER 15                  02010020
ZEROREG  EQU   0                   REGISTER 0                           02020020
PARMREG  EQU   1                   REGISTER 1                           02030020
ONEREG   EQU   1                   REGISTER 1                           02040020
TOREG    EQU   2                   REGISTER 2                           02090020
TWOREG   EQU   2                   REGISTER 2                           02100020
WORKREG  EQU   3                   REGISTER 3                           02150020
REG4     EQU   4                   UNUSED (RESERVED) REGISTER 4         02160020
FROMREG  EQU   5                   REGISTER 5                           02210020
LENTHREG EQU   11                  REGISTER 11                          02220020
LISTREG  EQU   7                   REGISTER 7                           02270020
CIRLIST  EQU   8                   REGISTER 8                           02280020
PARSBASE EQU   9                   REGISTER 9                           02330020
COMNBASE EQU   6                   REGISTER 6                           02340020
BASEREG  EQU   12                  REGISTER 12                          02390020
SAVEREG  EQU   13                  REGISTER 13                          02400020
RETURN   EQU   14                  REGISTER 14                          02450020
BRANCH   EQU   15                  REGISTER 15                          02460020
DSPOINT  EQU   2                   REGISTER 2                           02510020
DSLENGTH EQU   3                   REGISTER 3                           02520020
LEVELCNT EQU   5                   REGISTER 5                           02570020
TESTREG  EQU   0                   REGISTER 0                           02580020
*  ABSOLUTE EQUATES (OFFSETS AND SHORT LENGTHS)                         02630020
ONE      EQU   1                   ONE                                  02640020
TWO      EQU   2                   TWO                                  02690020
F0       EQU   0                   ZERO                                 02700020
F1       EQU   1                   ONE                                  02750020
F2       EQU   2                   TWO                                  02760020
F3       EQU   3                   THREE                                02810020
F4       EQU   4                   FOUR                                 02820020
F6       EQU   6                   SIX                                  02870020
F7       EQU   7                   SEVEN                                02880020
F5       EQU   5                   FIVE                                 02930020
F8       EQU   8                   EIGHT                                02940020
F9       EQU   9                   NINE                                 02990020
F12      EQU   12                  TWELVE                               03000020
F16      EQU   16                  SIXTEEN                              03050020
F20      EQU   20                  TWENTY                               03060020
F24      EQU   24                  TWENTY-FOUR                          03110020
F43      EQU   43                  FORTY-THREE                          03120020
F44      EQU   44                  FORTY-FOUR                           03170020
F46      EQU   46                  FORTY-SIX                            03180020
F51      EQU   51                  FIFTY-ONE                            03230020
F72      EQU   72                  SEVENTY-TWO                          03240020
*  RETURN CODE EQUATES                                                  03290020
RC4      EQU   4                   RETURN CODE = 4                      03300020
RC8      EQU   8                   RETURN CODE = 8                      03350020
RC12     EQU   12                  RETURN CODE = 12                     03360020
RC16     EQU   16                  RETURN CODE = 16                     03410020
RC20     EQU   20                  RETURN CODE = 20                     03420020
RC24     EQU   24                  RETURN CODE = 24                     03470020
RC28     EQU   28                  RETURN CODE = 28                     03480020
RC32     EQU   32                  RETURN CODE = 32                     03530020
RC36     EQU   36                  RETURN CODE = 36                     03540020
*  EQUATES FOR MESSAGE NUMBERS (FIRST LEVEL MESSAGES)                   03590020
M01      EQU   1                   MESSAGE NUMBER 01                    03600020
M02      EQU   2                   MESSAGE NUMBER 02                    03650020
M03      EQU   3                   MESSAGE NUMBER 03                    03660020
M04      EQU   4                   MESSAGE NUMBER 04                    03710020
M05      EQU   5                   MESSAGE NUMBER 05                    03720020
M06      EQU   6                   MESSAGE NUMBER 06                    03770020
M07      EQU   7                   MESSAGE NUMBER 07                    03780020
M08      EQU   8                   MESSAGE NUMBER 08                    03830020
M09      EQU   9                   MESSAGE NUMBER 09                    03840020
M10      EQU   10                  MESSAGE NUMBER 10                    03890020
M11      EQU   11                  MESSAGE NUMBER 11                    03900020
M12      EQU   12                  MESSAGE NUMBER 12                    03950020
M13      EQU   13                  MESSAGE NUMBER 13                    03960020
M14      EQU   14                  MESSAGE NUMBER 14                    04010020
M15      EQU   15                  MESSAGE NUMBER 15                    04020020
M16      EQU   16                  MESSAGE NUMBER 16                    04070020
M17      EQU   17                  MESSAGE NUMBER 17                    04080020
M18      EQU   18                  MESSAGE NUMBER 18                    04130020
M19      EQU   19                  MESSAGE NUMBER 19                    04140020
M20      EQU   20                  MESSAGE NUMBER 20                    04190020
M21      EQU   21                  MESSAGE NUMBER 21                    04200020
*  EQUATES FOR MESSAGE NUMBERS (SECOND LEVEL MESSAGES)                  04310020
S01      EQU   1                   SECOND LEVEL MESSAGE NUMBER 01       04320020
S02      EQU   2                   SECOND LEVEL MESSAGE NUMBER 02       04370020
S03      EQU   3                   SECOND LEVEL MESSAGE NUMBER 03       04380020
S04      EQU   4                   SECOND LEVEL MESSAGE NUMBER 04       04430020
S05      EQU   5                   SECOND LEVEL MESSAGE NUMBER 05       04440020
S06      EQU   6                   SECOND LEVEL MESSAGE NUMBER 06       04490020
S07      EQU   7                   SECOND LEVEL MESSAGE NUMBER 07       04500020
S08      EQU   8                   SECOND LEVEL MESSAGE NUMBER 08       04550020
S09      EQU   9                   SECOND LEVEL MESSAGE NUMBER 09       04560020
S10      EQU   10                  SECOND LEVEL MESSAGE NUMBER 10       04610020
S11      EQU   11                  SECOND LEVEL MESSAGE NUMBER 11       04620020
S12      EQU   12                  SECOND LEVEL MESSAGE NUMBER 12       04670020
S13      EQU   13                  SECOND LEVEL MESSAGE NUMBER 13       04680020
S14      EQU   14                  SECOND LEVEL MESSAGE NUMBER 14       04730020
S15      EQU   15                  SECOND LEVEL MESSAGE NUMBER 15       04740020
S16      EQU   16                  SECOND LEVEL MESSAGE NUMBER 16       04790020
S17      EQU   17                  SECOND LEVEL MESSAGE NUMBER 17       04800020
S18      EQU   18                  SECOND LEVEL MESSAGE NUMBER 18       04850020
S19      EQU   19                  SECOND LEVEL MESSAGE NUMBER 19       04860020
S20      EQU   20                  SECOND LEVEL MESSAGE NUMBER 20       04910020
S21      EQU   21                  SECOND LEVEL MESSAGE NUMBER 21       04920020
S22      EQU   22                  SECOND LEVEL MESSAGE NUMBER 22       04970020
*              OTHER EQUATES                                            04980020
STAR     EQU   C'*'                ASTERISK                             05030020
PERIOD   EQU   C'.'                PERIOD                               05040020
ZERO     EQU   X'00'               ZERO                                 05090020
FOXZERO  EQU   C'0'                CHARACTER ZERO                       05100020
DSCBCHCK EQU   X'01'               IS DSCB THERE (ON VOLUME) CHECK      05150020
BADPASWD EQU   2                   MASK TO CHECK IF PASSWORD BAD        05160020
DATECHCK EQU   X'03'               EXPIRATION DATE CHECK                05210020
IOERR    EQU   X'04'               I/O ERROR CHECK                      05220020
SPNUM    EQU   1                   SUBPOOL NUMBER FOR GETMAIN           05270020
QUOTEMSK EQU   X'40'               MASK TO CHECK IF DSNAME IN QUOTES    05320020
SWON     EQU   X'FF'               MASK FOR SWITCH ON                   05330020
SWOFF    EQU   X'00'               MASK FOR SWITCH OFF                  05340020
INDEXTST EQU   X'00'               INDEX NAME (CIR)                     05390020
GDGNTST  EQU   X'02'               GENERATION DATA GROUP NAME (CIR)     05400020
NAMETST  EQU   X'07'               DATA SET NAME (CIR)                  05450020
TTRSIGN  EQU   X'80'               TTR INDICATOR (CIR)                  05460020
ENDTEST  EQU   X'FF'               LIST END (CIR)                       05510020
OVRD     EQU   X'50'               OVERRIDE OPTION FOR SCRATCH          05520020
TYPE     EQU   X'02'               MASK TO CHECK FOR PURGE/NOPURGE      05570020
NAMESOPT EQU   X'01'               OPTION BYTE FOR CIR DATA SET NAMES   05580020
INDEXOPT EQU   X'02'               OPTION BYTE FOR CIR INDEX NAMES      05630020
BLANK    EQU   C' '                BLANK CHARACTER (FOR SCAN END,ETC)   05640020
QUOTE    EQU   C''''               CHARACTER QUOTE                      05690020
ZONE     EQU   C'0'                CHARACTER CONSTANT FOR ZONE FIELD    05700020
CHARG    EQU   C'G'                CHARACTER G                          05710020
CHARV    EQU   C'V'                CHARACTER V                          05720020
COMPZONE EQU   X'F0'               MASK TO TEST FOR GENERATION NAME     05730020
PDSTEST  EQU   X'02'               MASK TO CHECK FOR PDS                05750020
DAIROPT1 EQU   X'08'               OPTION BYTE FOR DATA SET ALLOCATION  05760020
DAIROPT3 EQU   X'18'               OPTION BYTE FOR DATASET UNALLOCATION 05810020
MASK1    EQU   X'40'               MASK TO CHECK FOR INTERRUPT          05870020
VOLCOUNT EQU   1                   MAXIMUM NUMBER OF VOLUMES SUPPORTED  05880020
PERMALC  EQU   X'10'               INDICATE UNALLOC PERMANENTLY ALLOC   05930020
EQ       EQU   8                   MASK FOR EQUAL COMPARES              05932020
         EJECT                                                          05940020
         SAVE  (14,12),,*          SAVE REGISTER OF CALLING ROUTINE     05990020
         LR    BASEREG,BRANCH      ENTRY POINT ADDRESS TO BASE REGISTER 06000020
         USING IKJEHDEL,BASEREG    ESTABLISH ADDRESSABILITY FOR PROGRAM 06050020
         LR    TWOREG,PARMREG      SAVE CONTENTS OF REGISTER 1 IN       06060020
*                                  REGISTER 2 - GETMAIN USES REGISTER 1 06110020
         GETMAIN R,LV=CORE,SP=SPNUM GET CORE FOR SAVEAREA AND WORKAREA  06120020
*  THIS IS AN UNCONDITIONAL REQUEST FOR CORE.  IF SUFFICIENT CORE IS    06170020
*  NOT AVAILABLE THE RESULT IS ABNORMAL TERMINATION OF THIS PROGRAM.    06180020
*  FIRST 96 BYTES IS DCB, NEXT 18 WORDS IS REGISTER SAVE AREA           06230020
         LR    COMNBASE,ONEREG     REGISTER 6 IS BASE FOR COMMON AREA   06240020
         USING IHADCB,COMNBASE     ESTABLISH ADDRESSABILITY FOR COMMON  06290020
         LA    ONEREG,SAVEAREA     ADDRESS OF REGISTER SAVE AREA        06300020
         XC    F0(F72,ONEREG),F0(ONEREG) INITIALIZE REGISTER SAVEAREA   06350020
         ST    SAVEREG,F4(ONEREG)  ADDRESS OF CALLER'S REGISTERS SAVED  06360020
         ST    ONEREG,F8(SAVEREG)  ADDRESS OF PROGRAM'S SAVEAREA SAVED  06410020
         LR    SAVEREG,ONEREG      REGISTER 13 POINTS TO SAVEAREA       06420020
*  REGISTER 2 POINTS TO COMMAND PROCESSOR PARAMETER LIST (CPPL)         06470020
         ST    R2,TMPSR1           SAVE TMP'S REGISTER 1                06480020
*  WHEN THE TMP ATTACHES DELETE REGISTER 1 POINTS TO A PARAMETER LIST.  06530020
*  THE FORMAT OF THE TMP PARAMETER LIST IS-                             06540020
*     1ST WORD POINTER TO THE COMMAND BUFFER                            06590020
*     2ND WORD POINTER TO THE USER PROFILE TABLE                        06600020
*     3RD WORD POINTER TO THE PROTECTED STEP CONTROL BLOCK              06650020
*     4TH WORD POINTER TO THE ENVIRONMENT CONTROL TABLE                 06660020
         MVC   PUT(PUTLEND-PUTL),PUTL INITIALIZE PUTLINE PARM BLOCK     06710020
         MVI   ENDERROR,INDEXTST   TURN OFF END ERROR SWITCH            06720020
         MVI   STACKSW,SWOFF       TURN STACK SWITCH OFF                06770020
         LA    WORKREG,LEVELSCN    POINT TO SCAN BUFFER                 06780020
         MVI   F8(WORKREG),BLANK   BLANK LAST BYTE OF SCAN FIELD        06830020
         USING CPPL,R2             SET ADDRESSABILITY CPPL              06840020
         LA    R5,PARSPARM         POINT TO SPACE FOR PARSE PARAMETERS  06890020
         USING PPL,R5              SET ADDRESSABILITY PARSE PARM LIST   06900020
         LA    R7,DFLTPARM         POINT TO SPACE FOR DEFAULT PARMLIST  06950020
         USING DFPL,R7             SET ADDRESSABILITY DEFAULT PARMLIST  06960020
         LA    R11,DFLTPBLK        POINT TO SPACE FOR DEFAULT PARMBLOCK 07010020
         USING DFPB,R11            SET ADDRESSABILITY DEFAULT PARMBLOCK 07020020
         LA    R9,IOPARM           POINT TO SPACE FOR I/O PARM LIST     07070020
         USING IOPL,R9             SET ADDRESSABILITY I/O PARM LIST     07080020
         LA    R10,DAIRPARM        POINT TO SPACE FOR DAIR PARM LIST    07130020
         USING DAPL,R10            SET ADDRESSABILITY DAIR PARM LIST    07140020
*  INITIALIZE PARAMETERS FOR PARSE, DAIR, DEFAULT, AND PUTLINE          07190020
         L     WORKREG,CPPLUPT     UPT POINTER                          07200020
         ST    WORKREG,PPLUPT      - TO PARSE LIST                      07250020
         ST    WORKREG,DAPLUPT     - TO DAIR LIST                       07260020
         ST    WORKREG,IOPLUPT     - TO I/O PARAMETER LIST              07310020
         ST    R3,DFPLUPT          - TO DEFAULT PARAMETER LIST          07320020
         L     WORKREG,CPPLPSCB    PSCB POINTER                         07370020
         ST    WORKREG,DAPLPSCB    - TO DAIR LIST                       07380020
         ST    R3,DFPBPSCB         - TO DEFAULT PARAMETER BLOCK         07430020
         ST    WORKREG,PSCBSAVE    SAVE ADDRESS OF PSCB                 07440020
         L     WORKREG,CPPLECT     ECT POINTER                          07490020
         ST    WORKREG,DAPLECT     - TO DAIR LIST                       07500020
         ST    WORKREG,IOPLECT     - TO I/O PARAMETER LIST              07550020
         ST    WORKREG,PPLECT      - TO PARSE LIST                      07560020
         ST    R3,DFPLECT          - TO DEFAULT PARAMETER LIST          07610020
         LA    WORKREG,DELCPECB    CP'S ECB POINTER                     07620020
         ST    WORKREG,PPLECB      - TO PARSE LIST                      07670020
         ST    WORKREG,DAPLECB     - TO DAIR LIST                       07680020
         ST    WORKREG,IOPLECB     - TO I/O PARAMETER LIST              07730020
         ST    R3,DFPLECB          - TO DEFAULT PARAMETER LIST          07740020
         ST    R11,DFPLDFPB        PARM BLOCK POINTER TO PARM LIST      07790020
         L     WORKREG,CPPLCBUF    COMMAND BUFFER POINTER               07800020
         ST    WORKREG,PPLCBUF     - TO PARSE LIST                      07850020
         SR    CIRLIST,CIRLIST     ZERO REGISTER (NO ASTERISK)          07860020
         ST    CIRLIST,CIRADDR     ZERO ADDRESS OF CIR                  07910020
         ST    CIRLIST,DELCPECB    ZERO CP'S ECB                        07920020
         ST    R8,DFPBQUAL         ZERO POINTER TO DEFAULT QUALIFIER    07970020
         ST    R8,PPLUWA           ZERO UNUSED WORD                     07980020
         L     WORKREG,VCONPARS    ADDRESS OF PARSE MACROS              08030020
         ST    WORKREG,PPLPCL      PARSE CONTROL LIST POINTER           08040020
         LA    WORKREG,ANSPLACE    POINT TO PARSE ANSWER PLACE          08090020
         ST    WORKREG,PPLANS      ANSWER PLACE POINTER                 08100020
         DROP  R2                  CPPL NO LONGER NEEDED                08150020
         DROP  R5                  PPL NO LONGER NEEDED                 08160020
         DROP  R7                  DFPL NO LONGER NEEDED                08210020
         DROP  R9                  IOPL NO LONGER NEEDED                08220020
         DROP  R10                 DAPL NO LONGER NEEDED                08270020
         XC    STAELIST(STAELNTH),STAELIST CLEAR AREA FOR STAE BLOCKS   08280020
         LOAD  EP=IKJEHSIR         LOAD STAE INTERFACE ROUTINE          08330020
         ST    R0,STAEADDR         SAVE ADDRESS OF STAE ROUTINE         08340020
BLDSTAE  PSEUDO TMP=TMPSR1,MF=E                                         08390020
         STABUILD CODE=713,RTN=ABEND713,ADDR=STAEONE,FLAG=(ONE,NMSG),  X08400020
               NUM=4,MF=E                                               08450020
         STABUILD CODE=913,RTN=ABEND913,ADDR=STAETWO,FLAG=(ONE,NMSG),  X08460020
               MF=E                                                     08510020
         STABUILD CODE=(113,213,313,A13),RTN=ABEND13,ADDR=STAETHRE,    X08520020
               FLAG=(MUL,NMSG),LIST=STAELST,                           X08530020
               MF=E                                                     08540020
         STABUILD CODE=000,RTN=LISTTEST,ADDR=STAEFOUR,FLAG=(ALL,END),  X08550020
               MF=E                                                     08560020
         STAEPARM FLAG=(CP),PSEUDO=$PSEUDO,LIST=STAEONE,ADDR=STAEPARM, X08570020
               MF=E                                                     08580020
         BAL   R14,ISUSTAE         GO ISSUE STAE                        08630020
         LR    PARMREG,R5          POINT TO PARSE PARAMETER LIST        08640020
*  WHEN THE PARSE SERVICE ROUTINE IS CALLED REGISTER 1 POINTS TO THE    08690020
*  FOLLOWING PARAMETER LIST-                                            08700020
*     1ST WORD POINTER TO THE USER PROFILE TABLE                        08750020
*     2ND WORD POINTER TO THE ENVIRONMENT CONTROL BLOCK                 08760020
*     3RD WORD POINTER TO THE COMMAND PROCESSOR'S EVENT CONTROL BLOCK   08810020
*     4TH WORD POINTER TO THE PARSE CONTROL LIST                        08820020
*     5TH WORD POINTER TO THE ANSWER PLACE                              08870020
*     6TH WORD POINTER TO THE COMMAND BUFFER                            08880020
*     7TH WORD POINTER TO THE USER WORK AREA                            08930020
*  PARSE COMMAND                                                        08940020
         LINK  EP=IKJPARS          LINK TO PARSE                        08990020
*  THE FORMAT OF THE LIST RETURNED FROM PARSE IS AS FOLLOWS-            09000020
*     1ST WORD POINTER TO DATA SET NAME                                 09050020
*     2ND WORD BYTE 0-1 LENGTH OF DATA SET NAME (EXCLUDING QUOTES)      09060020
*              BYTE 2   FLAGS (BIT 1 IS 1 IF DATA SET NAME QUOTED)      09110020
*              BYTE 3   RESERVED                                        09120020
*     3RD WORD POINTER TO MEMBER NAME (ZERO IF MISSING)                 09170020
*     4TH WORD BYTE 0-1 LENGTH OF MEMBER NAME (EXCLUDING PARENTHESES)   09180020
*              BYTE 2   FLAGS                                           09230020
*              BYTE 3   RESERVED                                        09240020
*     5TH WORD POINTER TO PASSWORD (ZERO IF MISSING)                    09290020
*     6TH WORD BYTE 0-1 LENGTH OF PASSWORD                              09300020
*              BYTE 2   FLAGS                                           09350020
*              BYTE 3   RESERVED                                        09360020
*     7TH WORD POINTER TO NEXT DATA SET OF LIST  X'FF000000' ENDS CHAIN 09410020
*     AN ADDITIONAL TWO BYTES (NAMED DELTYPE)                           09420020
*        A 1 INDICATES 'NOPURGE' SPECIFIED OR DEFAULTED                 09470020
*        A 2 INDICATES 'PURGE' SPECIFIED                                09480020
*                                                                       09530020
         LTR   BRANCH,BRANCH       TEST PARSE RETURN CODE               09540020
         BNZ   PARSEERR            GO PROCESS NON-ZERO RETURN CODE      09590020
*  ESTABLISH ADDRESSABILITY FOR PARSE DSECT                             09600020
         L     PARSBASE,ANSPLACE   PARSE PUT DELPARM ADDRESS HERE       09650020
         USING IKJPARMD,PARSBASE   ESTABLISH ADDRESSABILITY PARSE PDL   09660020
*  NOW MOVE CAMLST MACROS TO GETMAIN AREA (COMMON)                      09670020
         MVC   SCRATLST(CLSTEND-SCRLST),SCRLST MOVE CAMLST MACROS       09680020
         MVC   IHADCB(DCBEND-DCB),DCB MOVE DCB                          09690020
         MVC   OPEN(OPENEND-OPN),OPN MOVE OPEN MACRO                    09700020
         MVC   CLOSE(CLOSEEND-CLSE),CLSE MOVE CLOSE MACRO               09710020
         LR    WORKREG,COMNBASE    ADDRESS OF DCB                       09720020
         O     WORKREG,OPEN        OR IN OPEN OPTION CODE, THEN         09770020
         ST    WORKREG,OPEN        PUT CODE AND ADDRESS IN OPEN MACRO   09780020
         LR    WORKREG,COMNBASE    ADDRESS OF DCB                       09830020
         O     WORKREG,CLOSE       OR IN CLOSE OPTION CODE, THEN        09840020
         ST    WORKREG,CLOSE       PUT CODE AND ADDRESS IN CLOSE MACRO  09890020
* INITIALIZE DAIR PARAMETER LIST TO ALLOCATE DATA SET                   09900020
         LA    R5,DAIR08           POINT TO DAIR ENTRY 08               09910020
         USING DAPB08,R5           ADDRESSABILITY FOR DAIR ENTRY 08     09920020
         LA    R7,DAIR18           POINT TO DAIR 18                     09930020
         USING DAPB18,R7           ADDRESSABILITY FOR DAIR ENTRY 18     09940020
         XC    DAIR08(DLSTEND-DAIR08),DAIR08 ZERO DAIR LISTS            09950020
         MVI   DA08CD+F1,DAIROPT1  SET OPTION FOR ALLOCATION            09960020
         MVI   DA08UNIT,BLANK      BLANK                                09970020
         MVC   DA08UNIT+F1(F7),DA08UNIT BLANK UNIT NAME                 09980020
         MVC   DA08SER(F8),DA08UNIT BLANK VOLUME SERIAL NUMBER          09990020
         MVC   DA08MNM(F8),DA08SER BLANK MEMBER FIELD                   10000020
         LA    TWOREG,DSL          ADDRESS OF DSL-DSN BUFFER            10010020
         ST    TWOREG,DA08PDSN     POINT TO BUFFER                      10020020
* INITIALIZE DAIR PARAMETER LIST TO UNALLOCATE DATA SET                 10070020
         MVI   DA18CD+F1,DAIROPT3  SET OPTION TO UNALLOCATE DATA SET    10080020
         MVC   DA18MNM(F8),DA08SER BLANK MEMBER NAME FIELD              10130020
         MVC   DA18JBNM(F8),DA08SER BLANK JOBNAME FIELD                 10140020
* INITIALIZE DEFAULT SERVICE ROUTINE PARAMETER LIST                     10190020
         ST    TWOREG,DFPBDSN      POINT TO DATA SET NAME               10200020
         MVI   DFPBCODE,DFPB04     SET DEFAULT ENTRY CODE               10250020
         MVI   DFPBCNTL,DFPBUID    INDICATE USERID ADD TO OCCUR         10260020
         DROP  R5                  DAPB08 NO LONGER NEEDED              10310020
         DROP  R7                  DAPB18 NO LONGER NEEDED              10320020
         DROP  R11                 DFPB NO LONGER NEEDED                10370020
*  INITIALIZE CATALOG INFORMATION ROUTINE PARAMETER LIST                10380020
         LA    WORKREG,WRK1AREA    POINT TO FIRST WORKAREA              10430020
         ST    WORKREG,WORK1PTR    SET POINTER TO WORKAREA1             10440020
         LA    WORKREG,WRK2AREA    POINT TO SECOND WORKAREA             10490020
         ST    WORKREG,WORK2PTR    SET POINTER TO WORKAREA2             10500020
         LA    WORKREG,NAMETTR     POINT TO INDEX STRUCTURE BUFFER      10550020
         ST    WORKREG,NAMEPTR     SET POINTER TO INDEX STRUCTURE       10560020
*  LOAD DAIR ROUTINE                                                    10610020
         LOAD  EP=IKJDAIR          LOAD DAIR                            10620020
         ST    ZEROREG,DAIRADDR    SAVE ADDRESS OF DAIR                 10670020
*  NOW CHECK IF PURGE PARAMETER WAS PRESENT IN COMMAND.  IF DELTYPE     10680020
*  CONTAINS A 1 THEN 'NOPURGE' WAS SPECIFIED OR DEFAULTED.  IF DELTYPE  10730020
*  CONTAINS A 2 THEN 'PURGE' WAS SPECIFIED.                             10740020
         TM    DELTYPE+F1,TYPE     WAS PURGE SPECIFIED                  10790020
         BO    YESPURGE            GO SET PURGE OPTION IN SCRATCH MACRO 10800020
*  NOW PROCESS DATA SET LIST                                            10850020
LISTPROC LA    LISTREG,DSNLIST     SET LISTREG AS POINTER TO FIRST PDE  10860020
*                                  (PARAMETER DESCRIPTOR ENTRY)         10910020
LISTGO   SR    WORKREG,WORKREG     ZERO REGISTER                        10920020
         ST    LISTREG,$RETRY0+LISTREG*F4 SAVE REG FOR STAE RECOVERY    10930020
         MVI   ISWITCH,INDEXTST    TURN OFF INDEX SWITCH                10940020
         MVI   UNALOCSW,SWOFF      TURN UNALLOCATE SWITCH OFF           10950020
         MVI   OPENFLAG,SWOFF      TURN OFF OPEN SWITCH                 10960020
         MVI   ERRORSW,SWOFF       TURN ERROR SWITCH OFF                10970020
         C     WORKREG,F0(LISTREG) IS DSNAME POINTER = 0                10980020
         BE    NODSN               ERROR, NO DATA SET NAME SPECIFIED    11030020
*  MOVE DATA SET NAME AND LENGTH TO DATA SET LENGTH AND NAME BUFFERS    11040020
         MVI   DSNBUFF,BLANK       FIRST BLANK BOTH DSNAME BUFFERS      11090020
         MVC   DSNBUFF+F1(F51),DSNBUFF PROPAGATE BLANKS                 11100020
         MVC   DSN(F44),DSNBUFF    BLANK DSNAME BUFFER                  11150020
         L     FROMREG,F0(LISTREG) ADDRESS OF DATA SET NAME FROM PARSE  11160020
         LH    LENTHREG,F4(LISTREG) LENGTH OF DATA SET NAME FROM PARSE  11210020
         LTR   LENTHREG,LENTHREG   TEST DATA SET LENGTH                 11220020
         BZ    NODSN               ERROR, NO DATA SET NAME SPECIFIED    11270020
         STH   LENTHREG,DSL        SAVE LENGTH                          11280020
         BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE INSTRUCTION    11330020
         LA    TOREG,DSN           ADDRESS OF BUFFER                    11340020
         EX    LENTHREG,MOVEINST   MOVE DSNAME TO BUFFER                11390020
         LA    TOREG,DSNMESG       POINT TO DSNAME BUFFER               11400020
         TM    F6(LISTREG),QUOTEMSK IS DATA SET NAME FULLY QUALIFIED    11410020
         BZ    SAVUNQUL            NO, SAVE UNQUALIFIED DSNAME          11420020
         MVI   F0(TOREG),QUOTE     MOVE QUOTE                           11450020
         LA    TOREG,F1(TOREG)     POINT PAST QUOTE                     11460020
         EX    LENTHREG,MOVEINST   MOVE DSNAME                          11510020
         LA    TOREG,F1(LENTHREG,TOREG) POINT PAST DSNAME               11520020
         LA    LENTHREG,F7(LENTHREG) 1 EXECUTE, 4 HEADER, 2 QUOTES      11570020
         MVI   F0(TOREG),QUOTE     MOVE QUOTE                           11580020
         STH   LENTHREG,DSNMESGL   SAVE LENGTH OF DSNAME                11640020
         MVC   DSBL(F46),DSL       DATA SET NAME TO SECOND BUFFER       11750020
*              ASTERISK SCAN ROUTINE                                    11760020
*        THIS ROUTINE SCANS A DATA SET NAME AND LOCATES ASTERISK        11810020
*        QUALIFIERS, IF PRESENT.  IT ALSO CHECKS THAT THE ASTERISK      11820020
*        DOES NOT OCCUR IN THE FIRST INDEX LEVEL AND THAT THERE IS NOT  11870020
*        MORE THAN ONE ASTERISK PER DATA SET NAME.                      11880020
*              NOTE-  THE SCAN BY PARSE HAS CHECKED SYNTAX OF DATA SET  11930020
*              NAME WITH ASTERISK ALLOWED IN PLACE OF ANY INDEX LEVEL.  11940020
IKJEHSCN LA    DSPOINT,DSNBUFF     POINT TO DATA SET NAME               11990020
         SR    DSLENGTH,DSLENGTH   ZERO REGISTER                        12000020
         ST    DSLENGTH,STARADDR   ZERO BUFFER -                        12050020
         STC   DSLENGTH,STARLEVL   AND LEVEL INDICATOR                  12060020
         LH    DSLENGTH,DSBL       LENGTH OF DATA SET NAME              12110020
         LA    LEVELCNT,F1         INITIALIZE TO FIRST LEVEL            12120020
         LR    TESTREG,LEVELCNT    SET TEST REGISTER TO ONE             12170020
         AR    DSLENGTH,DSPOINT    ADD DATA SET LENGTH TO ADDRESS -     12180020
*                                  THIS DETERMINES ENDING ADDRESS       12230020
STARTEST CLI   F0(DSPOINT),STAR    IS THIS CHARACTER AN ASTERISK        12240020
         BE    LEVELTST            IF *, CHECK INDEX LEVEL              12290020
NEXTCHAR LA    DSPOINT,F1(DSPOINT) POINT TO NEXT CHARACTER              12300020
         CR    DSPOINT,DSLENGTH    ARE THERE MORE CHARACTERS            12350020
         BE    GOODSCAN            IF NOT, SCAN IS FINISHED             12360020
         CLI   F0(DSPOINT),PERIOD  CHECK FOR . (NEW INDEX LEVEL)        12410020
         BNE   NEXTCHAR            IF NOT, CHECK NEXT CHARACTER         12420020
         LA    LEVELCNT,F1(LEVELCNT) INCREMENT LEVEL COUNT              12430020
         LA    DSPOINT,F1(DSPOINT) POINT TO NEXT CHARACTER              12440020
         B     STARTEST            NEW INDEX LEVEL, CHECK FOR ASTERISK  12450020
LEVELTST CR    LEVELCNT,TESTREG    IS THIS FIRST INDEX LEVEL            12460020
         BE    STARERR4            ERROR, * IN FIRST INDEX LEVEL        12470020
         CLI   STARLEVL,ZERO       IS LEVEL INDICATOR ZERO              12480020
         BNE   STARERR8            IF NOT, ERROR MORE THAN ONE ASTERISK 12530020
         ST    DSPOINT,STARADDR    SAVE ADDRESS OF ASTERISK             12540020
         STC   LEVELCNT,STARLEVL   SAVE ASTERISK LEVEL NUMBER           12590020
         B     NEXTCHAR            GO CHECK NEXT CHARACTER              12600020
*                                                                       12650020
*  WHEN THE SCAN IS FINISHED                                            12660020
*  STARLEVL WILL CONTAIN LEVEL AT WHICH ASTERISK WAS FOUND              12710020
*  STARRADDR WILL CONTAIN ADDRESS AT WHICH ASTERISK FOUND               12720020
GOODSCAN SR    WORKREG,WORKREG     ZERO REGISTER                        12770020
         C     WORKREG,STARADDR    IS STARADDR ZERO                     12780020
         BE    QUOTETST            IF YES, NO ASTERISK IN DSNAME        12830020
         C     WORKREG,F8(LISTREG) IS MEMBER SPECIFIED                  12840020
         BNE   STARMEM             ERROR, * WITH MEMBER                 12890020
*  A VALID ASTERISK HAS BEEN FOUND IN DATA SET NAME.  NOW DETERMINE IF  12900020
*  ASTERISK WAS IN INDEX LEVEL OR DATA SET NAME LEVEL (LAST POSITION)   12950020
*  OF DATA SET NAME.  SEPARATE ENTRY TO IKJEHCIR (CATALOG INFORMATION   12960020
*  ROUTINE) AND SEPARATE PROCESSING REQUIRED FOR EACH CASE.             13010020
*  FIRST BUILD PARAMETER LIST FOR CATALOG INFORMATION ROUTINE           13020020
         SR    WORKREG,WORKREG     ZERO REGISTER                        13070020
         ST    WORKREG,CIRPARM     CLEAR FIRST WORD OF PARAMETER LIST   13080020
         ST    WORKREG,VOLIDPTR    INITIALIZE TO ZERO (DEFAULT SYSRES)  13130020
         MVC   STARBUFF(F51),DSNMESGL SAVE ASTERISK NAME                13132020
         C     WORKREG,CIRADDR     IS CIR MODULE LOADED                 13140020
         BNE   NOLDCIR             YES, SKIP LOAD                       13190020
         LOAD  EP=IKJEHCIR         LOAD CATALOG INFORMATION ROUTINE     13200020
         ST    ZEROREG,CIRADDR     SAVE ADDRESS OF CIR                  13250020
NOLDCIR  MVI   NAMEPTR,ZERO        CLEAR HIGH ORDER BYTE                13260020
         MVI   CIRFLAG,SWOFF       SET SWITCH OFF                       13310020
         MVI   STARSW,SWOFF        TURN STAR SWITCH OFF                 13312020
         LA    R2,STARLIST         BEGINNING OF STARLIST                13314020
         ST    R2,STARPTR          POINT TO NEXT EMPTY SLOT             13316020
*  NOW MOVE INDEX STRUCTURE                                             13320020
         LA    TOREG,NAMETTR       TO INDEX STRUCTURE BUFFER            13370020
         LA    FROMREG,DSNBUFF     FROM SCAN BUFFER                     13380020
         L     LENTHREG,STARADDR   LOAD POINTER TO ASTERISK             13430020
         LR    WORKREG,LENTHREG    POINT TO ASTERISK                    13440020
         BCTR  WORKREG,R0          POINT TO PERIOD BEFORE ASTERISK      13490020
         MVI   F0(WORKREG),BLANK   BLANK OUT PERIOD FOR CIR             13500020
         SR    LENTHREG,FROMREG    LENGTH OF INDEX STRUCTURE AND BLANK  13550020
         EX    LENTHREG,MOVEINST   INDEX STRUCTURE TO BUFFER PLUS BLANK 13560020
         BCTR  LENTHREG,R0         DECREMENT REGISTER FOR BLANK         13610020
         STH   LENTHREG,INDEXSZE   SAVE LENGTH OF INDEX STRUCTURE       13620020
*  CATALOG INFORMATION ROUTINE PARAMETER LIST IS NOW COMPLETE EXCEPT    13670020
*  FOR OPTION BYTE.  NOW DETERMINE OPTION NEEDED.                       13680020
         LA    WORKREG,F2(LENTHREG) LENGTH OF DATA SET NAME TO ASTERISK 13730020
         CH    WORKREG,DSBL        COMPARE LENGTHS                      13740020
*  IF LENGTHS ARE EQUAL THE ASTERISK IS IN LAST POSITION OF DATA SET    13790020
*  NAME AND THE OPTION FOR THE CATALOG INFORMATION ROUTINE IS X'01'     13800020
*  REQUESTING DSNAMES.  IF LENGTHS NOT EQUAL X'02' REQUESTS INDEX NAMES 13850020
         BNE   CIRINDEX            GO GET INDEX NAMES                   13860020
         MVI   CIRPARM,NAMESOPT    SET DSNAMES OPTION FOR CIR           13910020
MORNAMES L     BRANCH,CIRADDR      ADDRESS OF CIR IN REGISTER 15        13920020
         LA    PARMREG,CIRPARM     POINT TO CIR PARAMETER LIST          13970020
         CALL  (15)                GO TO CIR                            13980020
         LTR   BRANCH,BRANCH       TEST RETURN CODE                     14030020
         BNZ   CIRERROR            NONZERO RETURN CODE IS ERROR         14040020
         LA    CIRLIST,WRK1AREA    REGISTER POINTS TO CIR LIST OF NAMES 14090020
CIRNTEST ST    CIRLIST,$RETRY0+CIRLIST*F4 SAVE REG FOR STAE RECOVERY    14100020
         CLI   F0(CIRLIST),NAMETST IS IT A DATA SET NAME ENTRY          14150020
         BE    NAMESCAN            YES, GO PROCESS DATA SET NAME ENTRY  14160020
         CLI   F0(CIRLIST),GDGNTST IS IT A GENERATION DATA GROUP ENTRY  14210020
         BE    GDGNAME             GO PROCESS GENERATION DATA GROUP     14220020
         CLI   F0(CIRLIST),ENDTEST TEST FOR END OF LIST                 14270020
         BE    ENDLIST             GO PROCESS END OF LIST               14280020
         B     CIRERROR            THIS BRANCH SHOULD NOT BE REACHED    14330020
GDGNAME  LA    CIRLIST,F16(CIRLIST) BUMP POINTER BY LENGTH OF GDG ENTRY 14340020
         B     CIRNTEST            CHECK NEXT ENTRY                     14390020
CIRINDEX MVI   CIRPARM,INDEXOPT    SET INDEX OPTION FOR CIR             14400020
MORINDXS L     BRANCH,CIRADDR      ADDRESS OF CIR IN REGISTER 15        14450020
         LA    PARMREG,CIRPARM     POINT TO CIR PARAMETER LIST          14460020
         CALL  (15)                GO TO CIR                            14510020
         LTR   BRANCH,BRANCH       TEST RETURN CODE                     14520020
         BNZ   CIRERROR            NONZERO RETURN CODE IS ERROR         14570020
         LA    CIRLIST,WRK1AREA    REGISTER POINTS TO CIR LIST OF NAMES 14580020
CIRITEST ST    CIRLIST,$RETRY0+CIRLIST*F4 SAVE REG FOR STAE RECOVERY    14630020
         CLI   F0(CIRLIST),INDEXTST IS IT AN INDEX NAME ENTRY           14640020
         BE    NAMESCAN            YES, GO PROCESS INDEX NAME ENTRY     14690020
         CLI   F0(CIRLIST),ENDTEST TEST FOR END OF LIST                 14700020
         BE    ENDLIST             GO PROCESS END OF LIST               14750020
         B     CIRERROR            ERROR, SHOULD NOT BE REACHED         14760020
STARCHCK CLI   STARSW,SWON         HAS * VALUE BEEN DELETED             14770020
         BE    DELMORE             YES, CHECK FOR MORE DSNAMES          14780020
         MVI   STARSW,SWOFF        NO, TURN OFF STAR SWITCH             14790020
         B     CIRERROR            GO PUT OUT MESSAGE                   14800020
ENDLIST  MVC   WORKWORD(F4),F0(CIRLIST) MOVE TTR TO WORD BOUNDRY        14810020
         L     WORKREG,WORKWORD    LOAD TTR AND END OF LIST INDICATOR   14820020
         LA    WORKREG,F0(WORKREG) BLANK OUT END OF LIST INDICATOR      14870020
         LTR   WORKREG,WORKREG     TEST TTR                             14880020
         BZ    STARCHCK            IF ZERO, NO MORE NAMES FOR THIS *    14930020
         CLI   CIRFLAG,SWON        HAS * NAME BEEN PROCESSED            14990020
         BE    RESETCIR            YES, GO RESET CIR PARM LIST          15000020
         MVC   NAMETTR(F3),F1(CIRLIST) TTR OF NEXT BLOCK AND VOLSER OF  15050020
         MVC   CVOLID(F6),F4(CIRLIST) CATALOG VOL TO CIR PARAMETER LST  15060020
         MVI   NAMEPTR,TTRSIGN     SET HIGH ORDER BIT OF POINTER TO     15110020
*                                  INDICATE TTR POINTER                 15120020
         LA    WORKREG,CVOLID      POINT TO CVOLID                      15170020
         ST    WORKREG,VOLIDPTR    SET CVOLID POINTER                   15180020
CIROPT   CLI   CIRPARM,INDEXOPT    CHECK OPTION                         15230020
         BE    MORINDXS            GO TO CIR AGAIN FOR MORE INDEX NAMES 15240020
         B     MORNAMES            GO TO CIR AGAIN FOR MORE DSNAMES.    15290020
*  CATALOG STRUCTURE ALTERED BY UNCATALOGGING DATA SET.  TTR NOT VALID  15300020
RESETCIR MVI   CIRFLAG,SWOFF       TURN OFF SWITCH                      15350020
         MVI   NAMEPTR,ZERO        TURN OFF TTR INDICATOR               15360020
         SR    WORKREG,WORKREG     ZERO REGISTER                        15410020
         ST    WORKREG,VOLIDPTR    RESET VOLID POINTER                  15420020
         B     CIROPT              GO DETERMINE CIR OPTION              15470020
SAVUNQUL EX    LENTHREG,MOVEINST   MOVE DSNAME TO MESSAGE BUFFER        15472020
         LA    LENTHREG,F5(LENTHREG) 1 FOR EXECUTE, 4 FOR HEADER        15474020
         STH   LENTHREG,DSNMESGL   SAVE INSERTION LENGTH                15476020
*  THIS SECTION OF CODE WILL APPEND THE USERID TO A NON-QUALIFIED       15480020
*  DATA SET NAME.                                                       15530020
ADDUSRID L     FROMREG,PSCBSAVE    ADDRESS OF PSCB                      15540020
         LA    TOREG,DSNBUFF       ADDRESS OF DSNAME BUFFER             15590020
         SR    LENTHREG,LENTHREG   ZERO REGISTER                        15600020
         IC    LENTHREG,PSCBUSRL-PSCB(FROMREG) LENGTH OF USERID         15650020
         LA    FROMREG,PSCBUSER-PSCB(FROMREG) ADDRESS OF USERID         15660020
         EX    LENTHREG,MOVEINST   USERID TO DSNAME BUFFER              15710020
*  THIS ACTUALLY MOVED ONE EXTRA BYTE WHICH WILL NOW BE OVERLAID WITH   15720020
*  A PERIOD.                                                            15770020
         AR    TOREG,LENTHREG      POINT PAST USERID                    15780020
         MVI   F0(TOREG),PERIOD    MOVE IN A PERIOD                     15830020
         LA    TOREG,F1(TOREG)     POINT PAST PERIOD                    15840020
         LA    FROMREG,DSN         ADDRESS OF DATA SET NAME             15890020
         LH    WORKREG,DSL         LENGTH OF DATA SET NAME -            15900020
         AR    LENTHREG,WORKREG    ADDED TO LENGTH OF USERID -          15902020
         LA    LENTHREG,F1(LENTHREG) PLUS ONE FOR THE PERIOD            15902420
         BCTR  WORKREG,R0          DECREMENT FOR EXECUTE INSTRUCTION    15902820
         EX    WORKREG,MOVEINST    MOVE DATA SET NAME TO USERID         15902920
         STH   LENTHREG,DSBL       SAVE TOTAL DATA SET LENGTH           15903020
         CLC   DSBL(F2),MAXLENTH   CHECK LENGTH NOT MORE THAN 44        15905020
         BH    DSNBIG              IF IT IS, ERROR                      15905420
         B     IKJEHSCN            GO TO ASTERISK SCAN ROUTINE          15905820
*  PURGE WAS SPECIFIED, SET '80' (X'50') IN THIRD BYTE OF SCRATCH MACRO 15905920
YESPURGE MVI   SCRTCH1A,OVRD       SET OVRD OPTION INDICATING NO        15906020
*                                  EXPIRATION DATE CHECK TO BE MADE.    15908020
         B     LISTPROC            GO PROCESS LIST OF DSNAMES           15908420
*  NO ASTERISK IN DATA SET NAME.  CHECK IF DATA SET NAME IS FULLY       15908820
*  QUALIFIED (IN QUOTES).  IF NOT ADD QUALIFIERS, USER ID WAS ADDED     15908920
*  PRIOR TO ASTERISK SCAN.                                              15909020
QUOTETST TM    F6(LISTREG),QUOTEMSK IS DATA SET NAME FULLY QUALIFIED    15911020
         BZ    QUALIFY             IF NOT, GO ADD QUALIFER              15911420
*  NOW ALLOCATE DATA SET                                                15911820
ALLOCDS  LA    R3,DAIR08           POINT TO DAIR ENTRY 08               15911920
         USING DAPB08,R3           ADDRESSABILITY FOR DAIR ENTRY 08     15912020
         MVC   DA08DDN(F8),DA08SER BLANK DDNAME FIELD                   15914020
         MVC   DA08PSWD(F8),DA08DDN BLANK PASSWORD FIELD                15914420
         L     FROMREG,F16(LISTREG) POINTER TO PASSWORD                 15914820
         LTR   FROMREG,FROMREG     TEST PASSWORD POINTER                15914920
         BZ    NOPASWRD            IF POINTER IS ZERO, NO PASSWORD      15915020
         LA    TOREG,DA08PSWD      POINT TO PASSWORD FIELD              15917020
         LH    LENTHREG,F20(LISTREG) LENGTH OF PASSWORD                 15917420
         BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE INSTRUCTION    15917820
         EX    LENTHREG,MOVEINST   MOVE PASSWORD TO DAIR LIST           15917920
NOPASWRD LA    PARMREG,DAIRPARM    SET REGISTER 1 TO DAIR GPL           15918020
         ST    R3,DAPLDAPB-DAPL(R1) ENTRY PARM BLOCK TO DAIR LIST       15920020
         MVI   STARSW,SWON         TURN STAR SWITCH ON                  15920120
         MVI   CIRFLAG,SWON        TURN CIR FLAG ON                     15920220
         L     BRANCH,DAIRADDR     LOAD ADDRESS OF DAIR                 15920420
         CALL  (15)                GO TO DAIR                           15920820
         LTR   BRANCH,BRANCH       TEST DAIR RETURN CODE                15920920
         BNZ   DAIRERR             ALLOCATION ERROR                     15921020
*                                                                       15923020
DSNTOVOL EQU   *                   DATA SET NOT ON VOLUME, UNCATALOG IT 15923420
*  WHEN DARC FIELD = 6708 DATA SET HAS BEEN ALLOCATED, ALTHOUGH RETURN  15923820
*  CODE INDICATES ERROR.  DDNAME IS NOT RETURNED.                       15923920
*                                                                       15924020
         MVC   DDNAME1(F8),DA08DDN SAVE DDNAME                          15926020
         MVI   UNALOCSW,SWON       TURN UNALLOCATE SWITCH ON            15926420
*  NOW TEST IF THE DELETE IS FOR A SEQUENTIAL DATA SET OR A MEMBER OF   15926820
*  A PARTITIONED DATA SET                                               15926920
TYPETEST CLI   DA08DSO,PDSTEST     IS DATA SET A PDS                    15927020
         DROP  R3                  DAPB08 NO LONGER NEEDED              15929020
         BE    MEMBRTST            IF YES, WAS A MEMBER SPECIFIED       15929420
*  THE DELETE IS NOT FOR A MEMBER OF A PDS                              15929820
DELSEQDS LH    LENTHREG,DSL        LENGTH OF DATA SET NAME              15929920
         BCTR  LENTHREG,R0         DECREMENT REGISTER FOR EXECUTE       15930020
         LA    FROMREG,DSN         POINT TO DATA SET NAME               15932020
         L     WORKREG,F8(LISTREG) LOAD MEMBER NAME POINTER             15932420
         LTR   WORKREG,WORKREG     TEST MEMBER NAME POINTER             15932820
         BNZ   BADDSN              MEMBER NAME SPECIFIED IS ERROR       15932920
*  BLANK WORK BUFFERS FOR DATA SET NAMES                                15933020
BLNKBUFF EQU   *                                                        15935020
         MVI   DSNAME1,BLANK       BLANK-                               15935420
         MVC   DSNAME1+F1(F43),DSNAME1 DSNAME BUFFER FOR SCRATCH        15935820
         MVC   DSNAME2(F44),DSNAME1 DSNAME BUFFER FOR UNCATALOG         15935920
         MVC   DSNAME3(F44),DSNAME1 DSNAME BUFFER FOR LOCATE            15936020
*  NOW MOVE DATA SET NAME TO CAMLST MACROS                              15938020
         LA    TOREG,DSNAME1       POINT TO SCRATCH DSNAME BUFFER       15938420
         EX    LENTHREG,MOVEINST   DSNAME TO SCRATCH MACRO              15938820
         LA    TOREG,DSNAME2       POINT TO UNCATALOG DSNAME BUFFER     15938920
         EX    LENTHREG,MOVEINST   DSNAME TO UNCATALOG MACRO            15939020
         AR    TOREG,LENTHREG      POINT PAST DSNAME                    15941020
         MVI   F1(TOREG),BLANK     BLANK OUT NEXT CHARACTER             15941420
         LA    TOREG,DSNAME3       POINT TO LOCATE DSNAME BUFFER        15941820
         EX    LENTHREG,MOVEINST   DSNAME TO LOCATE MACRO               15941920
*  NOW ISSUE LOCATE TO GET VOLUME INFORMATION FOR SCRATCH               15942020
         LA    WORKREG,DSNAME3     POINT TO DSNAME                      15944020
         ST    WORKREG,LOCNAME2    SET POINTER TO DSNAME                15944420
         LA    WORKREG,LOCAR1      POINT TO LOCATE WORKAREA             15944820
         ST    WORKREG,LOCNAME4    SET POINTER TO LOCATE WORKAREA       15944920
*                                                                       15945020
         LOCATE LOCNAME            ISSUE LOCATE                         15947020
         LTR   BRANCH,BRANCH       TEST LOCATE RETURN CODE              15949020
         BNZ   LOCERROR            LOCATE ERROR                         15951020
         CLI   ISWITCH,ENDTEST     WAS THIS A VALIDITY CHECK            15951420
         BE    ISWTHOFF            YES,TURN SWITCH OFF, GO PROCESS DS   15951820
*  NOW CHECK NUMBER OF VOLUMES. MORE THAN 1 VOLUME IS ERROR             15951920
         LA    WORKREG,VOLCOUNT    SET WORKREG TO 1                     15952020
         CH    WORKREG,LOCAR1      COMPARE 1 TO NUMBER OF VOLUMES       15954020
         BL    OVR20VOL            OVER 1 VOLUME                        15956020
* COMPUTE LENGTH OF VOLUME LIST AND MOVE VOLUME LIST TO SCRATCH CAMLST  15958020
         LA    LENTHREG,F12        LENGTH OF EACH VOLUME ENTRY          15960020
         MH    LENTHREG,LOCAR1     MULTIPLY BY NUMBER OF VOLUMES        16010020
         LA    LENTHREG,F1(LENTHREG) ADD 2 FOR VOLUME COUNT, DECREMENT  16020020
*                                  ONE FOR EXECUTE INSTRUCTION          16070020
         LA    TOREG,VOLIST        ADDRESS OF SCRATCH VOLUME LIST       16080020
         LA    FROMREG,LOCAR1      ADDRESS OF LOCATE WORKAREA           16130020
         EX    LENTHREG,MOVEINST   MOVE VOLUME LIST                     16140020
*  NOW SCRATCH DATA SET                                                 16190020
         ST    TOREG,SCRTCH4       POINTER TO VOLUME LIST               16200020
         LA    WORKREG,DSNAME1     POINT TO DSNAME                      16250020
         ST    WORKREG,SCRTCH2     SET POINTER TO DSNAME                16260020
*  PREVENT ATTENTION INTERRUPTIONS FROM HERE UNTIL AFTER UNALLOCATION   16270020
         STAX  DEFER=YES           DEFER ATTENTION INTERRUPTS           16280020
*  ISSUE SCRATCH MACRO                                                  16310020
         SR    ZEROREG,ZEROREG     THIS REGISTER ZEROED FOR SCRATCH     16320020
         SCRATCH SCRATLST          ISSUE SCRATCH                        16370020
         LTR   BRANCH,BRANCH       TEST SCRATCH RETURN CODE             16380020
         BNZ   SCRATERR            SCRATCH ERROR                        16430020
*  DATA SET HAS BEEN SUCCESSFULLY SCRATCHED, NOW UNCATALOG DATA SET     16440020
UNCATDS  LA    WORKREG,DSNAME2     POINT TO DSNAME                      16490020
         ST    WORKREG,UNCAT2      SET POINTER TO DSNAME                16500020
*  UNCATALOG DATA SET AND DELETE ANY EMPTY INDEX LEVELS                 16550020
         SR    ZEROREG,ZEROREG     THIS REGISTER ZEROED FOR CATALOG     16560020
         CATALOG UNCATLST          ISSUE CATALOG                        16610020
         LTR   BRANCH,BRANCH       TEST CATALOG RETURN CODE             16620020
         BNZ   UNCATERR            UNCATALOG ERROR                      16670020
*  DATA SET SUCCESSFULLY UNCATALOGED                                    16680020
*  NOW UNALLOCATE DATA SET                                              16730020
UNALOCDS LA    R5,DAIR18           POINT TO DAIR ENTRY 18               16740020
         USING DAPB18,R5           ADDRESSABILITY FOR DAIR ENTRY 18     16790020
*  IF DELETE WAS SUCCESSFUL UNALLOCATE BY DSNAME, BUT IF ERROR OR       16800020
*  DELETE WAS FOR PDS MEMBER UNALLOCATE BY DDNAME                       16850020
         SR    R3,R3               ZERO REGISTER                        16860020
         CLI   ERRORSW,SWON        DID ERROR OCCUR                      16910020
         BE    UNALOC              YES, GO UNALLOCATE DDNAME            16920020
         MVI   DA18CTL,PERMALC     UNALLOC PERMANENTLY ALLOCATED DS     16970020
         C     R3,F8(R7)           WAS MEMBER SPECIFIED                 16980020
         BNE   UNALOC              YES, GO UNALLOCATE DDNAME      M2009 17030021
         LA    R3,DSL              POINT TO DSLENGTH-DSNAME BUFFER      17040020
         ST    R3,DA18PDSN         SET DSNAME POINTER                   17090020
         MVC   DA18DDN(F8),DA18JBNM BLANK DDNAME                        17100020
         B     UNALOCGO            GO UNALLOCATE                        17150020
UNALOC   MVI   DA18CTL,ZERO        CLEAR CONTROL BYTE                   17160020
UNALOCDD ST    R3,DA18PDSN         XERO DSNAME POINTER                  17210020
         MVC   DA18DDN(F8),DDNAME1 MOVE DDNAME TO DAIR UNALLOCATE LIST  17220020
UNALOCGO L     R15,DAIRADDR        LOAD DAIR ADDRESS                    17270020
         LA    PARMREG,DAIRPARM    POINT TO DAIR PARAMETER LIST         17280020
         ST    R5,DAPLDAPB-DAPL(R1) ENTRY PARM BLOCK TO DAIR LIST       17330020
         DROP  R5                  DAPB18 NO LONGER NEEDED              17340020
         CALL  (15)                GO TO DAIR                           17390020
         MVI   UNALOCSW,SWOFF      TURN UNALLOCATE SWITCH OFF           17400020
         MVI   ERRORSW,SWOFF       TURN ERROR SWITCH OFF                17450020
*  NOW ALLOW ATTENTION INTERRUPTIONS                                    17452020
         STAX  DEFER=NO            ALLOW ATTENTION INTERRUPTS           17454020
         B     LISTTEST            GO SEE IF MORE DSNAMES               17460020
ISWTHOFF MVI   ISWITCH,INDEXTST    TURN OFF INDEX SWITCH                17510020
         B     ALLOCDS             GO ALLOCATE DATA SET                 17520020
*  DATA SET IS A PDS.  IF A MEMBER NAME WAS SPECIFIED THEN DELETE IS    17570020
*  FOR THAT MEMBER.  IF NO MEMBER NAME WAS SPECIFIED THEN DELETE IS FOR 17580020
*  THE ENTIRE PDS.                                                      17630020
MEMBRTST SR    WORKREG,WORKREG     ZERO REGISTER                        17640020
         C     WORKREG,F8(LISTREG) IS MEMBER NAME POINTER ZERO          17690020
         BE    DELSEQDS            NO MEMBER GO DELETE ENTIRE PDS       17700020
*  MEMBER NAME SPECIFIED.  PROCESS PDS MEMBER                           17750020
*  BUILD DCB BEFORE OPEN (INSERT DDNAME OBTAINED FROM DAIR)             17760020
         MVC   DCBDDNAM(F8),DDNAME1 MOVE DDNAME TO DCB                  17810020
*  NOW OPEN DATA SET                                                    17820020
         LA    ONEREG,OPEN         ADDRESS OF OPEN LIST                 17870020
         OPEN  ,MF=(E,(1))         OPEN DATA SET                        17880020
         MVI   OPENFLAG,SWON       TURN ON OPEN SWITCH                  17940020
*  NOW USE STOW TO DELETE PDS MEMBER                                    17990020
         LH    LENTHREG,F12(LISTREG) LENGTH OF MEMBER NAME              18000020
         L     FROMREG,F8(LISTREG) ADDRESS OF MEMBER NAME               18050020
         LA    TOREG,STOWMEM       ADDRESS OF STOW MEMBER FIELD         18060020
         MVI   F0(TOREG),BLANK     BLANK FIRST BYTE STOW MEMBER FIELD   18110020
         MVC   F1(F7,TOREG),F0(TOREG) BLANK STOW MEMBER FIELD           18120020
         BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE                18170020
         EX    LENTHREG,MOVEINST   MOVE MEMBER NAME TO STOW FIELD       18180020
*  MOVE MEMBER NAME IN PARENTHESES TO OUTPUT BUFFER                     18230020
         BCTR  FROMREG,R0          BACK ONE, POINT TO PARENTHESIS       18240020
         LA    TOREG,MEMMSG        POINT TO MESSAGE BUFFER              18290020
         LA    LENTHREG,F2(LENTHREG) BUMP TWO FOR PARENTHESIS           18300020
         EX    LENTHREG,MOVEINST   MOVE MEMBER NAME TO OUTPUT BUFFER    18350020
         LA    LENTHREG,F5(LENTHREG) 1 FOR EXECUTE, 4 FOR HEADER        18360020
         STH   LENTHREG,MEMMSGL    SAVE MEMBER NAME LENGTH              18410020
         STOW  IHADCB,STOWMEM,D    DELETE MEMBER                        18420020
         LTR   BRANCH,BRANCH       TEST STOW RETURN CODE                18470020
         BNZ   STWERROR            STOW ERROR                           18480020
*  STOW COMPLETE, NOW CLOSE DATA SET                                    18530020
CLOSEPDS LA    R1,CLOSE            ADDRESS OF CLOSE LIST                18540020
         CLOSE ,MF=(E,(1))         CLOSE DATA SET                       18590020
         MVI   OPENFLAG,SWOFF      TURN OFF OPEN SWITCH                 18600020
*  DATA SET CLOSED, NOW UNALLOCATE DATA SET                             18650020
         B     UNALOCDS            GO UNALLOCATE DATA SET               18660020
*  THIS SECTION DETERMINES THE LENGTH OF INDEX AND DATA SET NAMES FROM  18710020
*  THE CATALOG.  THESE NAMES HAVE A MAXIMUM LENGTH OF 8. A BLANK HAS    18720020
*  BEEN STORED IN THE NINTH BYTE.  THE SCAN STARTS WITH THE SECOND      18770020
*  BYTE AND CONTINUES UNTIL A BLANK IS FOUND.                           18780020
NAMESCAN LA    TWOREG,LEVELSCN     ADDRESS OF BUFFER                    18830020
         MVC   F0(F8,TWOREG),F1(CIRLIST) MOVE NAME TO SCAN BUFFER       18890020
         CLI   F0(CIRLIST),INDEXTST IS THIS AN INDEX NAME               18900020
         BE    INDEXBMP            YES, GO UP POINTER TO NEXT ENTRY     18950020
         LA    CIRLIST,F9(CIRLIST) UP POINTER BY LENGTH OF NAME ENTRY   18960020
*  TEST FOR GENERATION DATA GROUP DATA SET NAME                         18962020
         CLI   F0(TWOREG),CHARG    TEST FOR G                           18964020
         BNE   CHCKSTAR            NO, CONTINUE                         18966020
         CLI   F5(TWOREG),CHARV    TEST FOR V                           18968020
         BNE   CHCKSTAR            NO, CONTINUE                         18968420
         LA    R11,F4              SET LOOP CONTROL                     18968820
GDGLOOP  LA    R3,F0(R11,TWOREG)   POINT TO CHARACTER TO BE TESTED      18969220
         TM    F0(R3),COMPZONE     TEST FOR COMPLEMENTED NUMBER         18969620
         BNZ   CHCKSTAR            NOT COMPLEMENT, CONTINUE             18969720
         BCT   R11,GDGLOOP         CHECK NEXT CHARACTER                 18969820
         XC    F1(F4,TWOREG),FOXMASK COMPLEMENT GENERATION NAME         18973220
*  NOW SEE IF THIS IS AN ERROR VALUE ALREADY ATTEMPTED                  18976720
CHCKSTAR L     R11,STARPTR         POINT TO END OF CURRENT LIST         18980020
         LA    R3,STARLIST         POINT TO FIRST ENTRY                 18990020
STARLOOP CR    R11,R3              END OF LIST                          19000020
         BE    STARTSCN            YES, GO SCAN ASTERISK VALUE          19002020
         CLC   F0(F8,R3),LEVELSCN  COMPARE * VALUE TO ERROR LIST        19004020
         BE    STARPROC            ERROR VALUE OF * ALREADY TRIED       19006020
         LA    R3,F8(R3)           POINT TO NEXT * VALUE (ERROR)        19008020
         B     STARLOOP            GO CHECK THIS VALUE                  19008420
*  THE FIRST CHARACTER IS A NON-BLANK, THEREFORE START SCAN WITH        19010020
*  SECOND CHARACTER.                                                    19020020
STARTSCN LA    TWOREG,F1(TWOREG)   POINT TO SECOND BYTE OF BUFFER       19070020
         LA    LENTHREG,F1         SET BYTE COUNTER                     19080020
BLANKTST CLI   F0(TWOREG),BLANK    CHECK FOR BLANK CHARACTER            19130020
         BE    ENDOFSCN            IF A BLANK IS FOUND SCAN IS OVER     19140020
         LA    TWOREG,F1(TWOREG)   POINT TO NEXT CHARACTER (BYTE)       19190020
         LA    LENTHREG,F1(LENTHREG) BUMP CHARACTER COUNT               19200020
*  LENGTH OF DATA SET NAME OR INDEX NAME FROM CIR IS NOW IN LENTHREG    19250020
         B     BLANKTST            CHECK NEXT CHARACTER                 19260020
INDEXBMP LA    CIRLIST,F12(CIRLIST) UP POINTER BY LENGTH OF INDEX ENTRY 19310020
         B     CHCKSTAR            NOW GO CHECK ASTERISK VALUE          19320020
*  FINISHED PROCESSING THIS DATA SET.  CHECK IF PROCESSING ASTERISK     19370020
*  NAMES AND IF SO CONTINUE ASTERISK PROCESSING.  IF NOT CHECK IF MORE  19380020
*  DATA SET NAMES IN THE INPUT LIST.                                    19430020
LISTTEST CLI   ENDERROR,ENDTEST    CAN PROCESSING CONTINUE              19440020
         BE    CLEANUP             NO, GO CLEANUP AND RETURN            19490020
         BAL   R14,ISUSTAE         GO ISSUE STAE                        19500020
         LTR   CIRLIST,CIRLIST     PROCESSING ASTERISK NAME             19550020
         BNZ   STARPROC            YES, CONTINUE PROCESSING             19560020
DELMORE  SR    CIRLIST,CIRLIST     NOT ASTERISK PROCESSING              19610020
         CLI   F24(LISTREG),ENDTEST IS THERE ANOTHER DSNAME IN THE LIST 19620020
         BNE   NEXTNAME            YES, GO PROCESS NEXT DSNAME          19670020
*  NOW CHECK IF AN ERROR HAS OCCURRED.  IF SO, THE STACK MUST BE        19860020
*  FLUSHED AND THE INPUT QUEUE CLEARED.                                 19910020
CLEANUP  CLI   STACKSW,SWON        IS STACK SWITCH ON                   19920020
         BNE   STACKOK             NO ERROR, END NORMALLY               19970020
         STAX  DEFER=NO                 ALLOW ATTN INTERRUPT    SA66200 19980021
*  DESIGN CHANGE FOR RELEASE 21, STACK FLUSH REMOVED TO ALLOW     M0876 20020021
*  DELETE TO BE USED IN CLIST DATA SETS.                          M0876 20070021
         TCLEARQ INPUT             CLEAR ANYTHING TYPED AHEAD           20100020
STACKOK  EQU   *                   NORMAL RETURN FROM HERE              20150020
         L     R13,F4(R13)         POINT TO CALLER'S REGISTERS          20160020
         SR    BRANCH,BRANCH       ZERO REG 15 FOR RETURN CODE          20210020
         RETURN (14,12),T,RC=(15)  RESTORE REGISTERS AND RETURN         20220020
STARPROC CLI   CIRPARM,INDEXOPT    PROCESSING INDEX NAMES               20270020
         BE    CIRITEST            YES, GO PROCESS INDEX NAME           20280020
         B     CIRNTEST            NO, GO PROCESS DATA SET NAME         20330020
*  A DATA SET NAME OR AN INDEX LEVEL NAME HAS BEEN FOUND.  THE NAME IS  20340020
*  NOW IN LEVELSCN AND ITS LENGTH IS IN LENTHREG.  NOW BUILD THE FULLY  20390020
*  QUALIFIED DATA SET NAME AND PROCESS IT.                              20400020
ENDOFSCN LA    TOREG,DSN           POINT TO BUILD BUFFER                20450020
         LA    FROMREG,DSNBUFF     POINT TO INDEX STRUCTURE             20460020
         LH    WORKREG,INDEXSZE    LOAD LENGTH OF INDEX STRUCTURE       20510020
         EX    WORKREG,MOVEINST    MOVE INDEX STRUCTURE                 20520020
*  ACTUALLY MOVED ONE EXTRA BYTE WHICH WILL BE OVERLAID WITH A PERIOD   20570020
         AR    TOREG,WORKREG       POINT PAST INDEX STRUCTURE           20580020
         MVI   F0(TOREG),PERIOD    INSERT PERIOD                        20630020
         LA    WORKREG,F1(WORKREG) INCREASE LENGTH FOR THE PERIOD       20640020
         AR    WORKREG,LENTHREG    TOTAL LENGTH OF DATA SET NAME        20690020
         LA    TOREG,F1(TOREG)     POINT PAST PERIOD                    20700020
         LA    FROMREG,LEVELSCN    POINT TO DATA SET NAME               20750020
         BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE                20760020
         EX    LENTHREG,MOVEINST   MOVE DSNAME TO INDEX STRUCTURE       20810020
         CLI   CIRPARM,INDEXOPT    PROCESSING INDEX NAMES OR DSNAMES    20820020
         BE    BLDINDEX            GO BUILD INDEX NAME                  20870020
         STH   WORKREG,DSL         SAVE LENGTH OF DATA SET NAME         20880020
*  NOW MOVE UPDATED DSNAME TO MESSAGE AREA                              20940020
ERRORDSN LH    LENTHREG,DSL        LENGTH OF FULLY QUALIFIED NAME       20990020
         LA    TOREG,DSNMESG       POINT TO MESSAGE BUFFER              21000020
         LA    FROMREG,DSN         POINT TO DATA SET NAME               21050020
         TM    F6(LISTREG),QUOTEMSK WAS DATA SET NAME QUOTED            21060020
         BO    SAVENAME            YES, GO SAVE NAME                    21110020
         L     WORKREG,PSCBSAVE    ADDRESS OF PSCB                      21120020
         SR    ONEREG,ONEREG       CLEAR REGISTER                       21170020
         IC    ONEREG,PSCBUSRL-PSCB(WORKREG) LENGTH OF USERID           21180020
         LA    ONEREG,F1(ONEREG)   PLUS ONE FOR THE PERIOD              21230020
         SR    LENTHREG,ONEREG     SUBTRACT LENGTH OF USERID            21240020
         AR    FROMREG,ONEREG      POINT PAST USERID                    21250020
SAVENAME BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE                21260020
         EX    LENTHREG,MOVEINST   MOVE DSNAME TO ERROR BUFFER          21270020
         LA    LENTHREG,F5(LENTHREG) 1 FOR EXECUTE, 4 FOR HEADER        21280020
         STH   LENTHREG,DSNMESGL   SAVE LENGTH OF DATA SET NAME         21290020
         CLI   ISWITCH,ENDTEST     IS THIS INDEX '*' NAME               21300020
         BE    DELSEQDS            YES, GO VALIDITY CHECK NAME          21350020
         B     ALLOCDS             GO ALLOCATE DATA SET                 21360020
QUALIFY  LA    R14,DFLTPBLK        ADDRESS OF DEFAULT PARAMETERS        21370020
         LA    PARMREG,DFLTPARM    POINT TO DEFAULT PARAMETER LIST      21380020
         ST    R14,DFPLDFPB-DFPL(R1) PARM BLOCK TO PARM LIST            21390020
         LINK  EP=IKJDFLT          GO TO DEFAULT SERVICE ROUTINE        21400020
         B     DFLTERR(R15)        ANALYZE DEFAULT RETURN CODE          21410020
DFLTERR  B     ERRORDSN            DEFAULT RC =  0                      21420020
         B     LISTTEST            DEFAULT RC =  4                      21470020
         B     DSNBIG              DEFAULT RC =  8                      21480020
         B     LISTTEST            DEFAULT RC = 12                      21530020
         B     DSNOTFND            DEFAULT RC = 16                      21540020
         B     DSNOTFND            DEFAULT RC = 20                      21590020
         B     LISTTEST            DEFAULT RC = 24                      21600020
         B     DEFAULT             DEFAULT RC = 28                      21650020
         B     LISTTEST            DEFAULT RC = 32                      21660020
         B     DSNOTFND            DEFAULT RC = 36                      21710020
NEXTNAME L     LISTREG,F24(LISTREG) RESET POINTER TO NEXT PARSE LIST    21720020
         B     LISTGO              GO PROCESS THIS DATA SET             21770020
BLDINDEX AR    TOREG,LENTHREG      POINT INDEX NAME                     21780020
         LA    TOREG,F1(TOREG)     PLUS ONE FROM THE EXECUTE            21830020
         L     FROMREG,STARADDR    ADDRESS OF ASTERISK                  21840020
         LA    FROMREG,F1(FROMREG) POINT PAST ASTERISK                  21890020
         LA    ONEREG,DSNBUFF      POINT TO BUFFER                      21900020
         AH    ONEREG,DSBL         POINT ONE PAST DSNAME                21950020
         SR    ONEREG,FROMREG      LENGTH OF STRUCTURE PAST ASTERISK    21960020
         AR    WORKREG,ONEREG      TOTAL LENGTH OF NEW NAME             22010020
         CH    WORKREG,MAXLENTH    MORE THAN 44 CHARACTERS              22020020
         BH    CIRITEST            THIS INDEX INVALID GO TEST NEXT ONE  22070020
         STH   WORKREG,DSL         SAVE TOTAL LENGTH                    22080020
         BCTR  ONEREG,R0           DECREMENT FOR EXECUTE                22130020
         EX    ONEREG,MOVEINST     MOVE REST OF NAME TO INDEX STRUCTURE 22140020
         MVI   ISWITCH,ENDTEST     SET INDEX SWITCH FOR VALIDITY CHECK  22190020
         B     ERRORDSN            GO DO A LOCATE TO SEE IF NAME VALID  22200020
LOCERROR CLI   ISWITCH,ENDTEST     WAS THIS A VALIDITY CHECK            22250020
         BNE   DSNOTCAT            LOCATE ERROR                         22270020
         MVI   ISWITCH,INDEXTST    RESET INDEX SWITCH                   22280020
         B     CIRITEST            GO PROCESS NEXT INDEX NAME           22290020
TPUT     BAL   RETURN,TESTATTN     GO CHECK FOR INTERRUPT               22300020
         LA    PARMREG,IOPARM      POINT TO I/O PARAMETER LIST          22310020
         PUTLINE  PARM=PUT,OUTPUT=(OUTAREA1,MULTLVL),MF=(E,(1)),       X22320020
               TERMPUT=(EDIT,WAIT) ISSUE PUTLINE                        22330020
         LTR   BRANCH,BRANCH       TEST RETURN CODE                     22340020
         BZ    TESTSW              CONTINUE PROCESSING                  22350020
TSTATTN  LA    TWOREG,F4           R2 = 4                               22360020
         CR    BRANCH,TWOREG       DID ATTENTION INTERRUPT OCCUR        22370020
         BNE   TESTSW              NO, CONTINUE PROCESSING              22380020
         BAL   R14,TESTATTN        GO CHECK FOR INTERRUPT               22390020
TESTSW   CLI   OPENFLAG,SWON       IS DATA SET OPEN                     22400020
         BE    CLOSEPDS            YES, GO CLOSE IT                     22410020
         LTR   CIRLIST,CIRLIST     PROCESSING ASTERISKS                 22412020
         BZ    NOTSTAR             NO, CONTINUE                         22414020
         BAL   R14,SAVESTAR        YES, SAVE VALUE OF ASTERISK          22416020
NOTSTAR  CLI   UNALOCSW,SWON       IS DATA SET ALLOCATED                22420020
         BE    UNALOCDS            YES, GO UNALLOCATE DATA SET          22430020
         B     LISTTEST            NO, CONTINUE PROCESSING              22440020
PARSEERR STC   R15,RC              SAVE RETURN CODE                     22490020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 22500020
         CLI   RC,RC12             ATTENTION INTERRUPT OR NOPROMPT      22550020
         BL    CLEANUP             YES, CLEANUP AND RETURN              22560020
         MVI   ENDERROR,ENDTEST    TURN ON SWITCH, END OF PROCESSING    22610020
         BH    NOSPACE             NO CORE                              22620020
         BAL   R11,MESG01          GO GET FIRST LEVEL MESSAGE           22670020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION         22680020
         LA    R2,S02              SECOND LEVEL MESSAGE NUMBER 2        22730020
         B     BLDSMSG             GO BUILD MESSAGE                     22740020
NOMEM    LA    R2,M17              SECOND LEVEL MESSAGE NUMBER 17       22790020
         LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            22840020
         B     BLDMESG             GO BUILD MESSAGE                     22910020
CIRERROR LA    R2,M19              MESSAGE NUMBER 19                    22920020
         LA    R10,STARBUFF        POINT TO INSERTION                   22970020
         SR    R8,R8               CLEAR ASTERISK INDICATOR             22972020
         B     BLDMESG             GO BUILD MESSAGE                     22980020
STARMSG  LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            23030020
         LA    R2,M07              MESSAGE NUMBER 7                     23040020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     23090020
         BR    R11                 RETURN FOR SECOND LEVEL              23100020
UNCATERR LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            23150020
         STH   R15,CATERCDE        SAVE CATALOG ERROR CODE              23160020
         LA    R2,M03              MESSAGE NUMBER 3                     23210020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     23220020
         MVI   ERRORSW,SWOFF       TURN ERROR SWITCH OFF                23270020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION  A45492 23272021
         LA    R2,S16              SECOND LEVEL MESSAGE NUMBER 16       23280020
         B     BLDSMSG             GO BUILD SECOND LEVEL MESSAGE        23340020
DATEHIGH LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            23390020
         LA    R2,M04              MESSAGE NUMBER 4                     23400020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     23450020
         BR    R11                 RETURN FOR SECOND LEVEL              23460020
ABEND913 LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            23640020
         LA    R2,M16              MESSAGE NUMBER 16                    23690020
         B     BLDMESG             GO BUILD MESSAGE                     23700020
SAVESTAR L     R2,STARPTR          POINT TO NEXT SLOT                   23710020
         LA    R3,STAREND          POINT TO END OF LIST                 23720020
         MVC   F0(F8,R2),LEVELSCN  MOVE ERROR VALUE TO LIST             23730020
         LA    R2,F8(R2)           POINT TO NEXT SLOT                   23740020
         CR    R3,R2               END OF LIST                          23742020
         BCR   EQ,R14              YES, RETURN                          23744020
         ST    R2,STARPTR          SAVE ADDRESS OF NEXT SLOT            23746020
         BR    R14                 RETURN                               23748020
ABEND13  LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            23750020
         LR    R15,R1              MOVE ABEND CODE TO REGISTER 15       23760020
         LA    R2,M05              MESSAGE NUMBER 5                     23810020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     23820020
         BAL   R3,BITOHEX          GO SET RETURN CODE INSERTION         23870020
         LA    R2,S09              SECOND LEVEL MESSAGE 9               23880020
         B     BLDSMSG             GO BUILD MESSAGE                     23930020
DSNOTDEL LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            24120020
         LA    R2,M06              MESSAGE NUMBER 6                     24170020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     24180020
         BR    R11                 RETURN FOR SECOND LEVEL              24230020
STARMEM  BAL   R11,STARMSG         GO GET FIRST LEVEL MESSAGE           24240020
         LA    R2,S03              SECOND LEVEL MESSAGE NUMBER 3        24290020
         B     ZEROR10             GO BUILD MESSAGE                     24300020
STARERR4 BAL   R11,STARMSG         GO GET FIRST LEVEL MESSAGE           24420020
         LA    R2,S18              SECOND LEVEL MESSAGE NUMBER 18       24470020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        24480020
STARERR8 BAL   R11,STARMSG         GO GET FIRST LEVEL MESSAGE           24530020
         LA    R2,S17              SECOND LEVEL MESSAGE NUMBER 17       24540020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        24590020
STWERROR STC   R15,RC              SAVE STOW RETURN CODE                24600020
         CLI   RC,RC8              IS RETURN CODE = 8                   24650020
         BE    NOMEM               YES, MEMBER NOT FOUND                24660020
         BAL   R11,DSNOTDEL        GO GET FIRST LEVEL MESSAGE           24710020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION         24720020
         LA    R2,S12              SECOND LEVEL                         24770020
         B     BLDSMSG             GO BUILD SECOND LEVEL MESSAGE        24780020
NOSPACE  LA    R2,M02              MESSAGE NUMBER 2                     24790020
NOINSERT SR    R10,R10             NO INSERTION                         24840020
BLDMESG  BAL   R14,MSGBUILD        GO BUILD MESSAGE                     24850020
         B     TPUT                GO WRITE MESSAGE                     24860020
SYSTEMER LA    R2,M14              MESSAGE NUMBER 14                    24900020
         LA    R10,DSNMESGL        POINT TO INSERTION                   24950020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     24960020
         BR    R11                 RETURN FOR SECOND LEVEL MESSAGE      25010020
ABEND713 BAL   R11,DATEHIGH        GO GET FIRST LEVEL MESSAGE           25020020
         LA    R2,S08              SECOND LEVEL MESSAGE NUMBER 8        25070020
         B     ZEROR10             GO BUILD MESSAGE                     25080020
OVR20VOL BAL   R11,DSNOTDEL        GO GET FIRST LEVEL MESSAGE           25130020
         LA    R2,S13              SECOND LEVEL MESSAGE NUMBER 13       25140020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        25190020
DATEMSG  BAL   R11,DATEHIGH        GO GET FIRST LEVEL MESSAGE           25200020
         LA    R2,S07              SECOND LEVEL MESSAGE NUMBER 7        25250020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        25260020
*  BUILD MESSAGES-ALLOCATION ERROR                                      25310020
DAIRERR  STC   R15,RC              SAVE DAIR RETURN CODE                25320020
         CLI   RC,RC16             IS RETURN CODE = 16                  25370020
         BE    NODDS               YES, NO DD ENTRIES                   25380020
         LA    R2,DAIR08           POINT TO DAIR ENTRY 08               25430020
         CLI   RC,RC8              IS RETURN CODE = 8                   25440020
         BL    DAERROR             DAIR ERROR                           25490020
         BE    DSNCATLG            YES, DATA SET NOT CATALOGED          25500020
         LH    R15,DA08DARC-DAPB08(R2) DYNAMIC ALLOCATION RETURN CODE   25550020
         CH    R15,DARC0204        IS DARC = 0204                       25560020
         BE    NOSPACE             YES, NO CORE, GO SET RETURN CODE     25610020
         CH    R15,DARC0210        IS DARC = 0210                       25620020
         BE    INUSE               YES, DATA SET IN USE                 25670020
         CH    R15,DARC0218        IS DARC = 0218                       25680020
         BE    VOLNTMTD            YES, VOLUME NOT MOUNTED              25730020
         CH    R15,DARC6708        IS DARC = 6708                       25740020
         BE    DSNTOVOL            YES, DATA SET NOT ON VOLUME          25790020
         CH    R15,DARC021C        IS DARC = 021C                       25800020
         BE    BADUNIT             YES, BAD UNIT INFORMATION            25850020
         CH    R15,DARC0214        IS DARC = 0214                       25860020
         BE    NOUNIT              YES, NO UNIT AVAILABLE               25910020
         CH    R15,DARC041C        IS DARC = 041C                       25920020
         BE    MULTIVOL            YES, MULTI VOLUME DATA SET           25970020
         BAL   R11,SYSTEMER        GO GET FIRST LEVEL MESSAGE           25980020
         BAL   R3,BITOHEX          GO SET RETURN CODE INSERTION         26030020
         LA    R2,S06              SECOND LEVEL MESSAGE NUMBER 6        26040020
         B     BLDSMSG             GO BUILD SECOND LEVEL MESSAGE        26090020
INUSE    LA    R2,M15              MESSAGE NUMBER 15                    26100020
         LA    R10,DSNMESGL        POINT TO INSERTION                   26150020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     26160020
         LA    R2,S14              SECOND LEVEL MESSAGE NUMBER 14       26210020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        26220020
DSNCATLG LH    R15,DA08CTRC-DAPB08(R2) CATALOG RETURN CODE              26270020
         STC   R15,RC              SAVE RETURN CODE                     26280020
         CLI   RC,RC8              RETURN CODE = 8                      26330020
         BL    VOLNTMTD            VOLUME NOT MOUNTED                   26340020
         CLI   RC,RC20             RETURN CODE = 20                     26390020
         BH    CATLGIO             CATALOG I/O ERROR                    26400020
         BNE   DSNOTFND            DATA SET NOT CATALOGED               26450020
         BAL   R11,SYSTEMER        GO GET FIRST LEVEL MESSAGE           26460020
         BAL   R3,BITOHEX          GO SET RETURN CODE INSERTION         26510020
         LA    R2,S10              SECOND LEVEL MESSAGE NUMBER 10       26520020
         B     BLDSMSG             GO BUILD MESSAGE                     26570020
DSNOTFND LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            26580020
         LA    R2,M10              MESSAGE NUMBER 10                    26630020
         B     BLDMESG             GO WRITE MESSAGE                     26640020
NODDS    LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            26690020
         LA    R2,M11              MESSAGE NUMBER 11                    26700020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     26750020
         MVI   ENDERROR,SWON       INDICATE END OF PROCESSING           26760020
         LA    R2,S01              SECOND LEVEL MESSAGE NUMBER 1        26810020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        26820020
VOLNTMTD LA    R2,M13              MESSAGE NUMBER 13                    26870020
         LA    R10,DSNMESGL        POINT TO INSERTION                   26880020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     26930020
         LA    R2,S05              SECOND LEVEL MESSAGE NUMBER 5        26940020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        26990020
SCRTCHER BAL   R11,DSNOTDEL        GO GET FIRST LEVEL MESSAGE           27000020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION         27050020
         LA    R2,S11              SECOND LEVEL MESSAGE NUMBER 11       27060020
         B     BLDSMSG             GO BUILD SECOND LEVEL MESSAGE        27110020
MESG12   LA    R2,M12              MESSAGE NUMBER 12                    27120020
         LA    R10,DSNMESGL        POINT TO INSERTON                    27170020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     27180020
         BR    R11                 RETURN FOR SECOND LEVEL              27230020
BADUNIT  BAL   R11,MESG12          GO GET FIRST LEVEL MESSAGE           27240020
         LA    R2,S19              SECOND LEVEL MESSAGE 19              27290020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        27300020
NOUNIT   BAL   R11,MESG12          GO GET FIRST LEVEL MESSAGE           27350020
         LA    R2,S20              SECOND LEVEL MESSAGE 20              27360020
         B     ZEROR10             GO BUILD SECOND LEVEL MESSAGE        27410020
MULTIVOL LA    R2,M21              MESSAGE 21                           27420020
         LA    R10,DSNMESGL        POINT TO INSERTION                   27470020
         B     BLDMESG             GO BUILD MESSAGE                     27480020
DEFAULT  BAL   R11,MESG01          GO GET FIRST LEVEL MESSAGE           27530020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION         27540020
         LA    R2,S15              SECOND LEVEL MESSAGE NUMBER 15       27550020
         B     BLDSMSG             GO BUILD SECOND LEVEL MESSAGE        27560020
DAERROR  BAL   R11,MESG01          GO GET FIRST LEVEL MESSAGE           27570020
         BAL   R3,CONVRTRC         GO SET RETURN CODE INSERTION         27580020
         LA    R2,S04              SECOND LEVEL MESSAGE 4               27590020
         B     BLDSMSG             GO BUILD MESSAGE                     27600020
CATLGIO  BAL   R11,SYSTEMER        GO GET FIRST LEVEL MESSAGE           27610020
         LA    R2,S21              SECOND LEVEL MESSAGE 21              27620020
         B     ZEROR10             GO BUILD MESSAGE                     27630020
MESG01   LA    R2,M01              MESSAGE NUMBER 1                     27640020
         BAL   R14,MSGBLD          GO BUILD MESSAGE                     27660020
         BR    R11                 RETURN FOR SECOND LEVEL              27710020
BADDSN   CLI   ISWITCH,ENDTEST     WAS THIS A VALIDITY CHECK            27720020
         BE    BLNKBUFF            YES, GO CONTINUE VALIDITY CHECK      27770020
         LA    R2,M08              MESSAGE NUMBER 8                     27780020
         LA    R10,DSNMESGL        POINT TO INSERTION                   27830020
         B     BLDMESG             GO BUILD MESSAGE                     27840020
DSNBIG   L     R5,PSCBSAVE         PSCB ADDRESS                         27890020
         LA    R2,DSNMESG          DSNAME INSERTION BUFFER              27900020
         SR    R3,R3               CLEAR REGISTER                       27950020
         IC    R3,PSCBUSRL-PSCB(R5) LENGTH OF USERID                    27960020
         LA    R5,PSCBUSER-PSCB(R5) ADDRESS OF USERID                   28010020
         EX    R3,MOVEINST         USERID TO DSNAME BUFFER              28020020
*  THIS MOVED ONE EXTRA BYTE WHICH WILL NOW BE OVERLAID WITH A PERIOD   28070020
         AR    R2,R3               POINT PAST USERID                    28080020
         MVI   F0(R2),PERIOD       MOVE IN PERIOD                       28130020
         LA    R2,F1(R2)           POINT PAST PERIOD                    28140020
         LA    R5,DSN              ADDRESS OF DATA SET NAME             28190020
         LH    R11,DSL             LENGTH OF DATA SET NAME              28200020
         AR    R3,R11              PLUS LENGTH OF USERID                28250020
         LA    R3,F5(R3)           ONE FOR PERIOD, FOUR FOR HEADER      28260020
         BCTR  R11,R0              DECREMENT FOR EXECUTE                28310020
         EX    R11,MOVEINST        MOVE DATA SET NAME TO USERID         28320020
         STH   R3,DSNMESGL         SAVE TOTAL LENGTH                    28370020
         LA    R2,M18              MESSAGE NUMBER 18                    28380020
         LA    R10,DSNMESGL        POINT TO INSERTION                   28430020
         B     BLDMESG             GO BUILD AND WRITE MESSAGE           28440020
*  ISSUE STAE                                                           28490020
ISUSTAE  L     R2,STAEADDR         ADDRESS OF STAE INTERFACE ROUTINE    28500020
         STAE  (R2),CT,PARAM=STAEPARM,MF=(E,STAELIST) ISSUE STAE        28510020
         BR    R14                 RETURN                               28520020
*  CONVERT RETURN CODE, SUPPRESS LEADING ZEROS AND MOVE TO INSERTION    28530020
*  BUFFER.  INPUT - R15 CONTAINS RETURN CODE TO BE CONVERTED            28540020
*           OUTPUT - R10 POINTS TO INSERTION BUFFER                     28550020
*  R3 IS THE RETURN REGISTER                                            28560020
CONVRTRC CVD   R15,UNPACK          CONVERT TO PACKED DECIMAL FORMAT     28570020
         UNPK  COUNT,UNPACK        CONVERT TO ZONED FORMAT              28580020
         OI    SIGNBYTE,ZONE       ZONE OVER SIGN                       28590020
*  SUPPRESS LEADING ZEROS IN RETURN CODE                                28600020
         LA    R5,COUNT            POINT TO COUNT BUFFER                28610020
         LA    R11,F7              R11 = 7                              28620020
SUPPZERO CLI   F0(R5),FOXZERO      IS THIS LEADING ZERO                 28670020
         BNE   NOTZERO             NO, GO MOVE RETURN CODE              28680020
         LA    R5,F1(R5)           YES, POINT TO NEXT DIGIT             28730020
         BCT   R11,SUPPZERO        GO CHECK NEXT DIGIT                  28740020
NOTZERO  LA    R11,ENDCOUNT        POINT PAST COUNT BUFFER              28790020
         SR    R11,R5              NUMBER OF SIGNIFICANT DIGITS IN R11  28800020
         BCTR  R11,R0              DECREMENT FOR EXECUTE                28850020
         LA    R2,RCMESG           POINT TO RETURN CODE BUFFER          28860020
         EX    R11,MOVEINST        MOVE RETURN CODE TO INSERTION BUFFER 28910020
         LA    R11,F5(R11)         4 FOR HEADER AND 1 FOR EXECUTE       28920020
         STH   R11,RCMESGL         LENGTH OF RETURN CODE INSERTION      28970020
         LA    R10,RCMESGL         POINT TO INSERTION BUFFER            28980020
         BR    R3                  RETURN                               29030020
*  BINARY TO HEXIDECIMAL CONVERSION ROUTINE                             29040020
*        INPUT - R15 CONTAIN RETURN CODE TO BE CONVERTED                29090020
*        OUTPUT - R10 POINTS TO INSERTION BUFFER                        29100020
*  R3 IS THE RETURN REGISTER                                            29150020
BITOHEX  SLL   R15,F16             SHIFT RETURN CODE TO HIGH HALF REG.  29160020
         LA    R10,RCMESG          POINT TO RETURN CODE BUFFER          29210020
         LA    R5,F4               FOUR HALF BYTES TO CONVERT           29220020
HEXLOOP  XR    R14,R14             CLEAR REGISTER                       29270020
         SLDL  R14,F4              MOVE HALF BYTE TO WORK REGISTER      29280020
         IC    R14,TRANSTAB(R14)   SELECT CHARACTER                     29330020
         STC   R14,F0(R10)         PUT CHARACTER IN RETURN CODE BUFFER  29340020
         LA    R10,F1(R10)         UP POINTER FOR NEXT CHARACTER        29390020
         BCT   R5,HEXLOOP          IF MORE TO CONVERT, CONTINUE         29400020
         CLI   RCMESG,FOXZERO      TEST FOR LEADING ZERO                29450020
         BNE   HEXGO               NOT ZERO,                            29460020
         MVI   RCMESG,BLANK        SUPPRESS LEADING ZERO                29510020
HEXGO    LA    R14,F8              4 FOR LENGTH PLUS FOUR FOR HEADER    29520020
         STH   R14,RCMESGL         LENGTH TO INSERTION BUFFER           29570020
         LA    R10,RCMESGL         POINT TO INSERTION BUFFER            29580020
         BR    R3                  RETURN                               29630020
*  THIS ROUTINE TESTS FOR ATTENTION INTERRUPT                           29640020
TESTATTN TM    DELCPECB,MASK1      IS ECB POSTED (DID ATTENTION OCCUR)  29690020
         BO    CLEANUP             YES, CLEANUP AND RETURN              29700020
         BR    RETURN              RETURN                               29750020
NODSN    LA    TWOREG,MEMMSG       POINT TO MEMBER MESSAGE BUFFER       29760020
         L     FROMREG,F8(LISTREG) POINT TO MEMBER NAME                 29810020
         LH    LENTHREG,F12(LISTREG) LENGTH OF MEMBER NAME              29820020
         BCTR  LENTHREG,R0         DECREMENT FOR EXECUTE                29870020
         EX    LENTHREG,MOVEINST   MOVE MEMBER NAME TO MESSAGE BUFFER   29880020
         LA    LENTHREG,F5(LENTHREG) 1 FOR EXECUTE, 4 FOR HEADER        29930020
         STH   LENTHREG,MEMMSGL    SAVE LENGTH IN INSERTON BUFFER       29940020
         LA    R2,M09              MESSAGE NUMBER 9                     29990020
         LA    R10,MEMMSGL         POINT TO INSERTION                   30000020
         B     BLDMESG             GO BUILD MESSAGE                     30050020
*  WHEN DATA SET IS ALLOCATED BUT NOT CATALOGGED, THE DATA SET IS       30170020
*  DELETED BY USING DAIR TO UNALLOCATE THE DATA SET WITH A DISPOSITION  30180020
*  OF DELETE.                                                           30230020
DSNOTCAT LA    R5,DAIR18           POINT TO DAIR ENTRY 18               30240020
         USING DAPB18,R5           ADDRESSABILITY FOR DAIR ENTRY 18     30290020
         MVC   DA18DDN(F8),DDNAME1 MOVE DDNAME TO UNALLOCATION LIST     30300020
         MVI   DA18DPS2,DA18DEL    SET DISPOSITION FOR DELETE           30350020
         MVI   DA18CTL,PERMALC     UNALLOC PERMANENTLY ALLOCATED DS     30360020
         L     BRANCH,DAIRADDR     LOAD DAIR ADDRESS                    30410020
         LA    PARMREG,DAIRPARM    POINT TO DAIR PARAMETER LIST         30420020
         ST    R5,DAPLDAPB-DAPL(R1) ENTRY PARM BLOCK TO PARM LIST       30470020
         CALL  (15)                GO TO DAIR                           30480020
         MVI   DA18DPS2,ZERO       RESET DISPOSITION FIELD              30530020
         LTR   BRANCH,BRANCH       TEST RETURN CODE                     30540020
         BZ    LISTTEST            GO SEE IF MORE DSNAMES               30590020
         STC   R15,RC              SAVE RETURN CODE                     30600020
         CLI   RC,RC12             WAS IT A DAIR ERROR                  30650020
         BNE   DSNOTFND            IF NOT, CATALOG ERROR                30660020
         LH    R15,DA18DARC-DAPB18(R5) DYNAMIC ALLOCATION ERROR CODE    30710020
         DROP  R5                  DAPB18 NO LONGER NEEDED              30720020
         CH    R15,DARC0022        WAS IT CATALOG ERROR ONLY            30730020
         BE    LISTTEST            YES, GO SEE IF MORE DSNAMES          30740020
         CH    R15,DARC0038        HIGH DATE                            30750020
         BE    DATEBAD             EXPIRATION DATE NOT PASSED           30760020
         CH    R15,DARC0404        IS IT A DIRECT ACCESS DEVICE         30770020
         BNE   DAERROR             YES, DATA SET NOT FOUND      SA69167 30780021
         LA    R2,M20              MESSAGE NUMBER 20                    30830020
         LA    R10,DSNMESGL        POINT TO INSERTION                   30840020
         B     BLDMESG             GO BUILD MESSAGE                     30890020
SCRATERR LA    TWOREG,F8           R2 = 8                               30900020
*  ANALYZE SCRATCH RETURN CODES                                         30950020
         CR    BRANCH,TWOREG       CHECK RETURN CODE                    30960020
         BL    SCRTCHER            ERROR WHILE SCRATCHING DATA SET      31010020
         CLI   SEQNUM+F1,DATECHCK  EXPIRATION DATE ERROR                31020020
         BE    DATEMSG             EXPIRATION DATE NOT PASSED           31070020
*  NOW CHECK EACH VOLUME FOR UNUSUAL CONDITIONS                         31080020
         LA    TWOREG,SEQNUM+F1    POINT TO LAST BYTE OF VOLUME ENTRY   31130020
         LH    WORKREG,VOLIST      NUMBER OF VOLUMES                    31140020
DSCBTEST CLI   F0(TWOREG),DSCBCHCK IS DSCB ON VOLUME                    31190020
         BE    UNCATDS             NO, THEN GO UNCATALOG DATA SET       31200020
         CLI   F0(TWOREG),BADPASWD WAS INCORRECT PASSWORD SPECIFIED     31250020
         BE    ABEND913            YES, ERROR                           31260020
         CLI   F0(TWOREG),IOERR    WAS IT AN I/O ERROR                  31310020
         BE    SCRTCHER            ERROR WHILE SCRATCHING DATA SET      31320020
         LA    TWOREG,F12(TOREG)   POINT TO NEXT ENTRY                  31370020
         BCT   WORKREG,DSCBTEST    IF MORE VOLUMES, GO CHECK THEM       31380020
         B     SCRTCHER            ERROR WHILE SCRATCHING DATA SET      31430020
DATEBAD  BAL   R11,DSNOTDEL        GO GET FIRST LEVEL MESSAGE           31440020
         LA    R2,S22              SECOND LEVEL MESSAGE 22              31450020
         B     ZEROR10             GO BUILD MESSAGE                     31460020
*                                                                       31470020
*  THIS IS THE MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE MESSAGE CSECT 31490020
*  TO OBTAIN THE ADDRESS OF THE MESSAGE SEGMENT AND THE OFFSET AT WHICH 31500020
*  ANY INSERTIONS WILL BE MADE.                                         31550020
*  AT ENTRY R2 CONTAINS MESSAGE NUMBER AND R10 CONTAINS ADDRESS OF THE  31560020
*  INSERTION.  R14 IS THE RETURN REGISTER  (R10 = 0 IS NO INSERTION)    31610020
*                                                                       31620020
MSGBLD   SR    R10,R10             NO INSERTION                         31630020
MSGBUILD SR    R3,R3               ZERO REGISTER                        31670020
         ST    R3,OUTAREA1         SET POINTER INDICATING ONE MESSAGE   31680020
         MVI   OUTAREA1,ENDTEST    FLAG END OF MESSAGE CHAIN            31730020
         L     R1,VCONMSG          ADDRESS OF MESSAGE BRANCH TABLE      31740020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             31790020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         31800020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              31850020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      31860020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                31910020
         ST    R3,OUTPUT11         MESSAGE ADDRESS TO OUTPUT LIST       31920020
         LTR   R10,R10             IS THERE AN INSERTION                31970020
         BZ    NOINSRT1            NO, GO SET SEGMENT COUNT TO 1        31980020
         SR    R2,R2               ZERO REGISTER                        32030020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             32040020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 32090020
         ST    R10,OUTPUT12        INSERTION ADDRESS TO OUTPUT LIST     32100020
         LA    R2,TWO              2 SEGMENTS                           32150020
SETCNT1  ST    R2,OUTCNT1          SET SEGMENT COUNT                    32160020
         MVI   ERRORSW,SWON        TURN ERROR SWITCH ON                 32210020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 32220020
         BR    R14                 RETURN                               32270020
NOINSRT1 LA    R2,ONE              ONE SEGMENT                          32280020
         B     SETCNT1             GO SET SEGMENT COUNT                 32330020
*                                                                       32340020
*  THIS IS THE SECOND LEVEL MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE  32390020
*  MESSAGE CSECT TO OBTAIN THE ADDRESS OF THE SECOND LEVEL MESSAGE AND  32400020
*  THE OFFSET AT WHICH ANY INSERTIONS WILL BE MADE.                     32450020
*  AT ENTRY R2 CONTAINS SECOND LEVEL MESSAGE NUMBER AND R10 CONTAINS    32460020
*  ADDRESS OF THE INSERTION.  (R10 = 0 IS NO INSERTION).                32510020
*  MESSAGE IS BUILT AND CONTROL IS PASSED TO TPUT TO WRITE MESSAGE      32512020
*                                                                       32570020
ZEROR10  SR    R10,R10             NO INSERTION                         32572020
BLDSMSG  EQU   *                   ALIAS FOR SMSGBLD                    32574020
SMSGBLD  SR    R3,R3               ZERO REGISTER                        32580020
         ST    R3,OUTAREA2         SET POINTER INDICATING LAST MESSAGE  32630020
         MVI   OUTAREA2,ENDTEST    FLAG END OF MESSAGE CHAIN            32640020
         LA    R3,OUTAREA2         POINT TO SECOND LEVEL MESSAGE CHAIN  32690020
         ST    R3,OUTAREA1         CHAIN SECOND LEVEL TO FIRST LEVEL    32700020
         L     R1,VCONSMSG         SECOND LEVEL MESSAGE BRANCH TABLE    32750020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             32760020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         32810020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              32820020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      32870020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                32880020
         ST    R3,OUTPUT21         MESSAGE ADDRESS TO OUTPUT LIST       32930020
         LTR   R10,R10             IS THERE AN INSERTION                32940020
         BZ    NOINSRT2            NO, GO SET SEGMENT COUNT TO 1        32990020
         SR    R2,R2               ZERO REGISTER                        33000020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             33050020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 33060020
         ST    R10,OUTPUT22        INSERTION ADDRESS TO OUTPUT LIST     33110020
         LA    R2,TWO              2 SEGMENTS                           33120020
SETCNT2  ST    R2,OUTCNT2          SET SEGMENT COUNT                    33170020
         B     TPUT                GO WRITE MESSAGE                     33180020
NOINSRT2 LA    R2,ONE              ONE SEGMENT                          33190020
         B     SETCNT2             GO SET SEGMENT COUNT                 33200020
         EJECT                                                          33210020
*                                                                       33220020
*                                                                       33230020
*              WORKAREA - REQUIRED CONSTANTS                            33240020
*                                                                       33290020
MAXLENTH DC    H'44'               MAXIMUM LENGTH DATA SET NAME         33300020
MOVEINST MVC   F0(F0,TOREG),F0(FROMREG) MOVE INSTRUCTION FOR EXECUTE    33350020
TRANSTAB DC    C'0123456789ABCDEF' TRANSLATE TABLE FOR BITOHEX ROUTINE  33360020
FOXMASK  DC    X'FFFFFFFF'         MASK TO COMPLEMENT GENERATION NAME   33370020
         DS    0H                  ALIGN HALF WORD BOUNDRY              33410020
DARC0204 DC    X'0204'             DARC NO CORE                         33420020
DARC0210 DC    X'0210'             DARC DATA SET IN USE                 33470020
DARC0218 DC    X'0218'             DARC VOLUME NOT MOUNTED              33480020
DARC6708 DC    X'6708'             DARC DATA SET NOT ON VOLUME          33530020
DARC0022 DC    X'0022'             CATALOG ERROR ONLY                   33540020
DARC0404 DC    X'0404'             DATA SET NOT ON DIRECT ACCESS        33590020
DARC041C DC    X'041C'             MULTI VOLUME DATA SET                33600020
DARC021C DC    X'021C'             BAD UNIT INFORMATION                 33650020
DARC0214 DC    X'0214'             NO UNIT AVAILABLE                    33660020
DARC0038 DC    X'0038'             HIGH DATE                            33670020
VCONMSG  DC    V(IKJEHMSG)         ENTRY MESSAGE CSECT 1ST LEVEL        33710020
VCONSMSG DC    V(IKJEHSMG)         ENTRY MESSAGE CSECT 2ND LEVEL        33720020
VCONPARS DC    V(IKJEHPDL)         PARSE PARAMETERS DELETE COMMAND      33770020
DCB      DCB   DSORG=PO,MACRF=W    DCB                                  33780020
DCBEND   EQU   *                   END OF DCB                           33830020
OPN      OPEN  (0,OUTPUT),MF=L     LIST FORM OF OPEN                    33840020
OPENEND  EQU   *                   END OF OPEN LIST                     33890020
CLSE     CLOSE 0,MF=L              LIST FORM OF CLOSE                   33900020
CLOSEEND EQU   *                   END OF CLOSE LIST                    33950020
PUTL     PUTLINE  MF=L             LIST FORM OF PUTLINE                 33960020
PUTLEND  EQU   *                   END OF PUTLINE EXPANSION             34010020
*              SCRATCH MACRO CAMLST                                     34020020
*                                                                       34070020
SCRLST   CAMLST SCRATCH,0,,0       SCRATCH MACRO                        34080020
*                                                                       34130020
*              UNCATALOG MACRO CAMLST                                   34140020
*                                                                       34190020
UNCLST   CAMLST UCATDX,0           CATALOG MACRO                        34200020
*                                                                       34250020
*                                                                       34260020
*              LOCATE MACRO CAMLST (BY DATA SET NAME)                   34310020
LNAME    CAMLST NAME,0,,0          LOCATE MACRO                         34320020
CLSTEND  EQU   *                                                        34370020
*                                                                       34380020
*              END OF CAMLST MACROS                                     34430020
*                                                                     * 34480020
         EJECT                                                          34490020
*              PARSE MACROS FOR DELETE COMMAND                        * 34500020
*                                                                     * 34550020
         DS    0F                                                       34560020
IKJEHPDL IKJPARM                                                        34610020
DSNLIST  IKJPOSIT  DSTHING,LIST,PROMPT='DATA SET NAME',HELP=('NAME OF DX34620020
               ATA SET(S) TO BE DELETED')                               34670020
DELTYPE  IKJKEYWD   DEFAULT='NOPURGE'                                   34680020
         IKJNAME    'NOPURGE'                                           34730020
         IKJNAME    'PURGE'                                             34740020
         IKJENDP                                                        34790020
*                                                                     * 34800020
*              END OF PARSE MACROS                                    * 34850020
*                                                                       34860020
         EJECT                                                          34910020
*  MAPPING MACROS                                                       34920020
         SPACE 2                                                        34970020
         IKJCPPL                                                        34980020
         IKJPPL                                                         35030020
LPPL     EQU   *-PPL               LENGTH OF PPL                        35080020
         IKJDFPL                                                        35130020
LDFPL    EQU   *-DFPL              LENGTH OF DFPL                       35140020
         IKJDFPB                                                        35150020
LDFPB    EQU   *-DFPB              LENGTH OF DFPB                       35160020
         IKJPSCB                                                        35210020
         IKJDAPL                                                        35220020
LDAPL    EQU   *-DAPL              LENGTH OF DAPL                       35270020
         IKJDAP08                                                       35280020
LDAPB08  EQU   *-DAPB08            LENGTH OF DAPB08                     35330020
         IKJDAP18                                                       35340020
LDAPB18  EQU   *-DAPB18            LENGTH OF DAPB18                     35390020
         IKJIOPL                                                        35400020
LIOPL    EQU   *-IOPL              LENGTH OF IOPL                       35450020
         IKJSTPB                                                        35460020
LSTPB    EQU   *-STPB              LENGTH OF STPB                       35510020
         EJECT                                                          35520020
*                                                                       35570020
*              GETMAIN COMMON AREA                                      35580020
*                                                                       35630020
*                                                                       35640020
         DCBD  DSORG=PO,DEVD=DA                                         35690020
SAVEAREA DS    18F                 REGISTER SAVE AREA                   35700020
UNPACK   DS    D                   WORK AREA FOR CVD                    35750020
COUNT    DS    D                   WORKAREA FOR UNPACK                  35760020
         ORG   COUNT+F7            BACK TO LAST BYTE OF COUNT FIELD     35810020
SIGNBYTE DS    CL1                 LABEL THE SIGN BYTE                  35820020
         ORG                                                            35870020
ENDCOUNT EQU   *                   END OF COUNT FIELD                   35880020
*  CAMLST MACROS MUST BE KEPT TOGETHER - MOVED AS ONE BLOCK             35930020
*              SCRATCH MACRO CAMLST                                     35940020
*                                                                       35990020
SCRATLST CAMLST SCRATCH,DSNAME1,,VOLIST SCRATCH MACRO                   36000020
         ORG   SCRATLST            LABEL SCRATCH CAMLST FIELDS          36050020
SCRTCH1  DS    H                   SCRATCH CAMLST FIRST HALF WORD       36060020
SCRTCH1A DS    H                   SCRATCH CAMLST SECOND HALF WORD      36110020
SCRTCH2  DS    F                   SCRATCH CAMLST SECOND FULL WORD      36120020
SCRTCH3  DS    F                   SCRATCH CAMLST THIRD FULL WORD       36170020
SCRTCH4  DS    F                   SCRATCH CAMLST FOURTH FULL WORD      36180020
         ORG                                                            36230020
*                                                                       36240020
*              UNCATALOG MACRO CAMLST                                   36290020
*                                                                       36300020
UNCATLST CAMLST UCATDX,DSNAME2     CATALOG MACRO                        36350020
         ORG   UNCATLST            LABEL UNCATALOG CAMLST FIELDS        36360020
UNCAT1   DS    F                   UNCATALOG CAMLST FIRST FULL WORD     36410020
UNCAT2   DS    F                   UNCATALOG CAMLST SECOND FULL WORD    36420020
UNCAT3   DS    F                   UNCATALOG CAMLST THIRD FULL WORD     36470020
         ORG                                                            36480020
*                                                                       36530020
*              LOCATE MACRO CAMLST (BY DATA SET NAME)                   36540020
*                                                                       36590020
LOCNAME  CAMLST NAME,DSNAME3,,LOCAR1 LOCATE MACRO                       36600020
         ORG   LOCNAME             LABEL LOCATE (NAME) CAMLST FIELDS    36650020
LOCNAME1 DS    F                   LOCATE CAMLST FIRST FULL WORD        36660020
LOCNAME2 DS    F                   LOCATE CAMLST SECOND FULL WORD       36710020
LOCNAME3 DS    F                   LOCATE CAMLST THIRD FULL WORD        36720020
LOCNAME4 DS    F                   LOCATE CAMLST FOURTH FULL WORD       36770020
         ORG                                                            36780020
*                                                                       36830020
*              END OF CAMLST MACROS                                     36840020
*                                                                       36890020
DSNAME1  DS    CL44                NAME OF DATA SET                     36900020
VOLIST   DS    H                   NUMBER OF VOLUMES                    36950020
DEVCODE  DS    XL4                 UCB DEVICE CODE                      36960020
VOLSER   DS    CL6                 VOLUME SERIAL NUMBER                 37010020
SEQNUM   DS    H                   DATA SET SEQUENCE NUMBER             37020020
MANYVOLS DS    19CL12              SPACE FOR 19 MORE VOLUMES            37070020
DSNAME2  DS    CL45                NAME OF DATA SET (BLANK DELIMITER)   37080020
DSNAME3  DS    CL44                NAME OF DATA SET                     37130020
         DS    0D                  ALIGN LOCATE WORKAREA                37140020
LOCAR1   DS    265C                WORKAREA FOR LOCATE                  37190020
RC       DS    CL1                 SAVE RETURN CODES HERE               37200020
OPENFLAG DS    CL1                 OPEN SWITCH                          37250020
ERRORSW  DS    CL1                 ERROR SWITCH                         37260020
*                                                                       37310020
OPEN     OPEN  (0,OUTPUT),MF=L     LIST FORM OF OPEN                    37320020
CLOSE    CLOSE 0,MF=L              LIST FORM OF CLOSE                   37370020
DELCPECB DS    F                   CP'S ECB FOR DELETE COMMAND          37380020
WORKWORD DS    F                   WORD BOUNDRY WORD WORD               37430020
CIRADDR  DS    F                   ADDRESS OF CIR                       37440020
DAIRADDR DS    F                   ADDRESS OF DAIR                      37490020
PSCBSAVE DS    F                   SAVE PSCB ADDRESS HERE               37500020
STOWMEM  DS    2F                  MEMBER NAME FOR STOW                 37550020
STARPTR  DS    F                   ADDRESS OF NEXT EMPTY SLOT           37552020
STARLIST DS    CL256               LIST OF ERROR ASTERISK VALUES        37554020
STAREND  EQU   *                   END OF STAR LIST                     37556020
INDEXSZE DS    H                   LENGTH OF INDEX STRUCTURE            37560020
CATERCDE DS    H                   SAVE CATALOG ERROR CODE HERE         37610020
         DS    0H                  ALIGN HALF WORD BOUNDRY              37660020
DSL      DS    CL2                 DSLENGTH AND                         37710020
DSN      DS    CL44                DSNAME BUFFER                        37760020
         DS    0H                  ALIGN HALF WORD BOUNDRY              37810020
DSBL     DS    CL2                 LENGTH OF DSNAME IN DSNBUFF          37860020
DSNBUFF  DS    CL52                DATA SET NAME BUILT IN THIS BUFFER   37910020
DDNAME1  DS    CL8                 SAVE DDNAME HERE                     37960020
LEVELSCN DS    CL9                 BUFFER FOR SCANNING INDEX LEVELS     38010020
STARLEVL DS    CL1                 LEVEL AT WHICH ASTERISK FOUND        38060020
ISWITCH  DS    CL1                 SWITCH INDICATES INDEX NAMES         38110020
ENDERROR DS    CL1                 SWITCH INDICATES CONTINUE PROCESSING 38160020
UNALOCSW DS    CL1                 SWITCH INDICATES UNALLOCATE DATA SET 38210020
CIRFLAG  DS    CL1                 INDICATES * NAME PROCESSED           38260020
STACKSW  DS    CL1                 INDICATE FLUSH STACK AND CLEAR QUEUE 38310020
STARSW   DS    CL1                 INDICATES * VALUE PROCESSED          38320020
STARADDR DS    F                   ADDRESS AT WHICH ASTERISK FOUND      38360020
*  CATALOG INFORMATION ROUTINE PARAMETER LIST (KEEP INTACT)             38410020
CIRPARM  DS    F                   OPTION BYTE                          38460020
NAMEPTR  DS    F                   POINTER TO NAME OR TTR               38510020
VOLIDPTR DS    F                   POINTER TO CVOL                      38560020
WORK1PTR DS    F                   POINTER TO 265 BYTE WORKAREA         38610020
WORK2PTR DS    F                   POINTER TO 18 WORD WORKAREA          38620020
WRK2AREA DS    18F                 WORKAREA FOR CIR (SAVEAREA)          38630020
         DS    0D                  ALIGN DOUBLE WORD BOUNDRY            38640020
WRK1AREA DS    CL265               WORKAREA FOR CIR                     38690020
NAMETTR  DS    CL45                DSNAME OR TTR BUFFER                 38700020
CVOLID   DS    CL6                 VOLUME SERIAL NUMBER BUFFER          38750020
*  END OF CATALOG INFORMATION ROUTINE PARAMETER LIST                    38760020
ANSPLACE DS    F                   ANSWER PLACE FOR PARSE               38762020
         DS    0F                  ALIGN WORD BOUNDRY                   38764020
PARSPARM DS    (LPPL)X             SPACE FOR PARSE PARAMETER LIST       38766020
         DS    0F                  ALIGN WORD BOUNDRY                   38768020
IOPARM   DS    (LIOPL)X            SPACE FOR I/O PARAMETER LIST         38770020
         DS    0F                  ALIGN WORD BOUNDRY                   38772020
STACKPRM DS    (LSTPB)X            SPACE FOR STACK PARM BLOCK           38774020
         DS    0F                  ALIGN WORD BOUNDRY                   38774420
DFLTPARM DS    (LDFPL)X            SPACE FOR DEFAULT PARAMETER LIST     38774820
         DS    0F                  ALIGN WORD BOUNDRY                   38775220
DFLTPBLK DS    (LDFPB)X            SPACE FOR DEFAULT PARAMETER BLOCK    38775620
         DS    0F                  ALIGN WORD BOUNDRY                   38776020
DAIRPARM DS    (LDAPL)X            SPACE FOR DAIR PARAMETER LIST        38778020
         DS    0F                  ALIGN WORD BOUNDRY                   38780020
DAIR08   DS    (LDAPB08)X          SPACE FOR DAIR ENTRY '08'            38790020
         DS    0F                  ALIGN WORD BOUNDRY                   38792020
DAIR18   DS    (LDAPB18)X          SPACE FOR DAIR ENTRY '18'            38794020
*  KEEP DAIR LISTS TOGETHER, ZEROED BY ONE INSTRUCTION                  38796020
DLSTEND  EQU   *                   END OF DAIR ENTRY LISTS              38798020
PUT      PUTLINE  MF=L             LIST FOR OF PUTLINE                  38800020
*  THE FOLLOWING SPACE IS USED FOR STAE                                 38802020
TMPSR1   DS    F                   SAVE TMP'S REGISTER 1 HERE           38804020
STAEADDR DS    F                   ADDRESS OF STAE INTERFACE ROUTINE    38806020
         PSEUDO MF=L                                                    38808020
STAELIST STAE  STAEADDR,PARAM=STAEPARM,MF=L                             38818020
STAEONE  STABUILD CODE=713,RTN=ABEND713,ADDR=STAEONE,FLAG=(ONE,NMSG),  X38820020
               NUM=4,MF=L                                               38870020
STAETWO  STABUILD CODE=913,RTN=ABEND913,ADDR=STAETWO,FLAG=(ONE,NMSG),  X38880020
               MF=L                                                     38930020
STAETHRE STABUILD CODE=(113,213,313,A13),RTN=ABEND13,ADDR=STAETHRE,    X38940020
               FLAG=(MUL,NMSG),LIST=STAELST,                           X38990020
               MF=L                                                     39000020
STAEFOUR STABUILD CODE=000,RTN=LISTTEST,ADDR=STAEFOUR,FLAG=(ALL,END),  X39050020
               MF=L                                                     39060020
STAEPARM STAEPARM FLAG=(CP),PSEUDO=$PSEUDO,LIST=STAEONE,ADDR=STAEPARM, X39110020
               MF=L                                                     39120020
STAELNTH EQU   *-STAELIST          SIZE OF STAE LISTS                   39170020
*  THE FOLLOWING IS RESERVED SPACE FOR OUTPUT CHAINS                    39180020
OUTAREA1 DS    F                   MESSAGE CHAIN POINTER                39190020
OUTCNT1  DS    F                   MESSAGE SEGMENT COUNT                39200020
OUTPUT11 DS    F                   POINTER TO MESSAGE SEGMENT           39210020
OUTPUT12 DS    F                   POINTER TO MESSAGE INSERTION         39220020
OUTAREA2 DS    F                   MESSAGE CHAIN POINTER                39230020
OUTCNT2  DS    F                   MESSAGE SEGMENT COUNT                39240020
OUTPUT21 DS    F                   POINTER TO MESSAGE SEGMENT           39290020
OUTPUT22 DS    F                   POINTER TO MESSAGE INSERTION         39300020
*  END OF OUTPUT CHAINS                                                 39350020
*                                                                       39360020
*  DSNAME FOR MESSAGES STORED HERE                                      39410020
DSNMESGL DS    H                   LENGTH OF DSN                        39420020
DSNMESGO DS    H                   OFFSET FOR INSERTION                 39470020
DSNMESG  DS    CL52                DSNAME                               39480020
*  MEMBER NAME FOR MESSAGES STORED HERE                                 39530020
MEMMSGL  DS    H                   LENGTH OF MEMBER PLUS PARENTHESES    39540020
MEMMSGO  DS    H                   OFFSET FOR INSERTION                 39590020
MEMMSG   DS    CL10                MEMBER NAME PLUS PARENTHESES         39600020
*  RETURN CODE FOR MESSAGES STORED HERE                                 39650020
RCMESGL  DS    H                   LENGTH OF RETURN CODE                39660020
REMESGO  DS    H                   OFFSET FOR INSERTION                 39710020
RCMESG   DS    CL4                 RETURN CODE                          39720020
*  ASTERISK NAME FOR MESSAGES STORED HERE                               39772020
STARBUFF DS    CL52                LENGTH, OFFSET, ASTERISK NAME        39774020
CORE     EQU   *-IHADCB            CORE SIZE FOR GETMAIN                39780020
         EJECT                                                          39830020
IKJEHMSG CSECT                                                          39840020
         ENTRY IKJEHSMG                                                 39890020
*********************************************************************** 39900020
*                                                                     * 39950020
*  THIS CONTROL SECTION CONTAINS THE MESSAGE TEXT (BOTH FIRST AND     * 39960020
*  SECOND LEVEL).  IT CONTAINS A BRANCH TABLE FOR FIRST LEVEL MESSAGES* 40010020
*  AND A BRANCH TABLE FOR SECOND LEVEL MESSAGES.  EACH BRANCH TABLE   * 40020020
*  ENTRY IS COMPOSED OF A ONE BYTE OFFSET FIELD FOR MESSAGE INSERTIONS* 40070020
*  AND A THREE BYTE ADDRESS OF THE MESSAGE.  THE MESSAGE BUILDER      * 40080020
*  ROUTINES COMBINE THE ADDRESS OF THE CONTROL SECTION AND THE ADDRESS* 40130020
*  OF THE MESSAGE TO GET THE TRUE ADDRESS OF THE MESSAGE.  THE OFFSET * 40140020
*  IS PLACED IN THE INSERTION SEGMENT.                                * 40190020
*  EACH MESSAGE IS COMPOSED OF A 4 BYTE HEADER (2 BYTE LENGTH OF      * 40240020
*  MESSAGE INCLUDING HEADER LENGTH AND A 2 BYTE OFFSET FIELD)         * 40290020
*  FOLLOWED BY THE MESSAGE TEXT.                                      * 40300020
*                                                                     * 40310020
*********************************************************************** 40320020
         SPACE                                                          40370020
*  EQUATES USED IN THIS CONTROL SECTION                                 40380020
HDR      EQU   4                   HEADER LENGTH (2 BYTES EACH, LENGTH  40430020
*                                  AND OFFSET FIELDS) EACH SEGMENT      40440020
OFST     EQU   0                   INSERTION OFFSET 1ST MESSAGE SEGMENT 40490020
*  OFFSETS FOR FIRST LEVEL MESSAGE INSERTIONS                           40500020
OFST01   EQU   0                   INSERTION OFFSET MESSAGE 01          40550020
OFST02   EQU   0                   INSERTION OFFSET MESSAGE 02          40560020
OFST03   EQU   19                  INSERTION OFFSET MESSAGE 03          40610020
OFST04   EQU   19                  INSERTION OFFSET MESSAGE 04          40620020
OFST05   EQU   19                  INSERTION OFFSET MESSAGE 05          40670020
OFST06   EQU   36                  INSERTION OFFSET MESSAGE 06          40680020
OFST07   EQU   30                  INSERTION OFFSET MESSAGE 07          40730020
OFST08   EQU   31                  INSERTION OFFSET MESSAGE 08          40740020
OFST09   EQU   45                  INSERTION OFFSET MESSAGE 09   A49872 40790021
OFST10   EQU   19                  INSERTION OFFSET MESSAGE 10          40800020
OFST11   EQU   19                  INSERTION OFFSET MESSAGE 11          40850020
OFST12   EQU   19                  INSERTION OFFSET MESSAGE 12          40860020
OFST13   EQU   19                  INSERTION OFFSET MESSAGE 13          40910020
OFST14   EQU   19                  INSERTION OFFSET MESSAGE 14          40920020
OFST15   EQU   19                  INSERTION OFFSET MESSAGE 15          40970020
OFST16   EQU   43                  INSERTION OFFSET MESSAGE 16          40980020
OFST17   EQU   43                  INSERTION OFFSET MESSAGE 17          41030020
OFST18   EQU   34                  INSERTION OFFSET MESSAGE 18          41040020
OFST19   EQU   43                  INSERTION OFFSET MESSAGE 19          41090020
OFST20   EQU   19                  INSERTION OFFSET MESSAGE 20          41100020
OFST21   EQU   19                  INSERTION OFFSET MESSAGE 21          41150020
*  OFFSETS FOR SECOND LEVEL MESSAGE INSERTIONS                          41160020
*  NOTE-  THERE ARE CURRENTLY NO INSERTIONS IN MOST SECOND LEVEL        41210020
*  MESSAGES. A COMMON OFFSET OF ZERO IS USED.                           41220020
OFSTSMSG EQU   0                   INSERTION OFFSET 2ND LEVEL MESSAGES  41270020
OFSTSM02 EQU   27                  INSERTION OFFSET SECOND LEVEL MSG 02 41280020
OFSTSM04 EQU   26                  INSERTION OFFSET SECOND LEVEL MSG 04 41330020
OFSTSM06 EQU   40                  INSERTION OFFSET SECOND LEVEL MSG 06 41340020
OFSTSM09 EQU   26                  INSERTION OFFSET SECOND LEVEL MSG 09 41390020
OFSTSM10 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 10 41400020
OFSTSM11 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 11 41450020
OFSTSM12 EQU   26                  INSERTION OFFSET SECOND LEVEL MSG 12 41460020
OFSTSM15 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 15 41510020
OFSTSM16 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 16 41520020
         SPACE                                                          41530020
AMSG01   DC    AL1(OFST01)         INSERTION OFFSET                     41540020
         DC    AL3(LMSG01)         MESSAGE ADDRESS                      41550020
AMSG02   DC    AL1(OFST02)         INSERTION OFFSET                     41560020
         DC    AL3(LMSG02)         MESSAGE ADDRESS                      41570020
AMSG03   DC    AL1(OFST03)         INSERTION OFFSET                     41580020
         DC    AL3(LMSG03)         MESSAGE ADDRESS                      41630020
AMSG04   DC    AL1(OFST04)         INSERTION OFFSET                     41640020
         DC    AL3(LMSG04)         MESSAGE ADDRESS                      41690020
AMSG05   DC    AL1(OFST05)         INSERTION OFFSET                     41700020
         DC    AL3(LMSG05)         MESSAGE ADDRESS                      41750020
AMSG06   DC    AL1(OFST06)         INSERTION OFFSET                     41760020
         DC    AL3(LMSG06)         MESSAGE ADDRESS                      41810020
AMSG07   DC    AL1(OFST07)         INSERTION OFFSET                     41820020
         DC    AL3(LMSG07)         MESSAGE ADDRESS                      41870020
AMSG08   DC    AL1(OFST08)         INSERTION OFFSET                     41880020
         DC    AL3(LMSG08)         MESSAGE ADDRESS                      41930020
AMSG09   DC    AL1(OFST09)         INSERTION OFFSET                     41940020
         DC    AL3(LMSG09)         MESSAGE ADDRESS                      41990020
AMSG10   DC    AL1(OFST10)         INSERTION OFFSET                     42000020
         DC    AL3(LMSG10)         MESSAGE ADDRESS                      42050020
AMSG11   DC    AL1(OFST11)         INSERTION OFFSET                     42060020
         DC    AL3(LMSG11)         MESSAGE ADDRESS                      42110020
AMSG12   DC    AL1(OFST12)         INSERTION OFFSET                     42120020
         DC    AL3(LMSG12)         MESSAGE ADDRESS                      42170020
AMSG13   DC    AL1(OFST13)         INSERTION OFFSET                     42180020
         DC    AL3(LMSG13)         MESSAGE ADDRESS                      42230020
AMSG14   DC    AL1(OFST14)         INSERTION OFFSET                     42240020
         DC    AL3(LMSG14)         MESSAGE ADDRESS                      42290020
AMSG15   DC    AL1(OFST15)         INSERTION OFFSET                     42300020
         DC    AL3(LMSG15)         MESSAGE ADDRESS                      42350020
AMSG16   DC    AL1(OFST16)         INSERTION OFFSET                     42360020
         DC    AL3(LMSG16)         MESSAGE ADDRESS                      42410020
AMSG17   DC    AL1(OFST17)         INSERTION OFFSET                     42420020
         DC    AL3(LMSG17)         MESSAGE ADDRESS                      42470020
AMSG18   DC    AL1(OFST18)         INSERTION OFFSET                     42480020
         DC    AL3(LMSG18)         MESSAGE ADDRESS                      42530020
AMSG19   DC    AL1(OFST19)         INSERTION OFFSET                     42540020
         DC    AL3(LMSG19)         MESSAGE ADDRESS                      42590020
AMSG20   DC    AL1(OFST20)         INSERTION OFFSET                     42600020
         DC    AL3(LMSG20)         MESSAGE ADDRESS                      42650020
AMSG21   DC    AL1(OFST21)         INSERTION OFFSET                     42660020
         DC    AL3(LMSG21)         MESSAGE ADDRESS                      42710020
*  FIRST LEVEL MESSAGES                                                 42720020
LMSG01   DC    AL2(L'MSG01+HDR)                                         42770020
         DC    AL2(OFST)                                                42780020
MSG01    DC    C'IKJ58001I COMMAND SYSTEM ERROR+'                       42830020
LMSG02   DC    AL2(L'MSG02+HDR)                                         42840020
         DC    AL2(OFST)                                                42890020
MSG02    DC    C'IKJ58002I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  42900021
*                                                                A49872 42910021
LMSG03   DC    AL2(L'MSG03+HDR)                                         42950020
         DC    AL2(OFST)                                                42960020
MSG03    DC    C'IKJ58003I DATA SET  DELETED BUT NAME STILL CATALOGED+' 43010020
LMSG04   DC    AL2(L'MSG04+HDR)                                         43020020
         DC    AL2(OFST)                                                43070020
MSG04    DC    C'IKJ58004I DATA SET  NOT DELETED, EXPIRATION DATE HAS NX43080020
               OT PASSED+'                                              43130020
LMSG05   DC    AL2(L'MSG05+HDR)                                         43140020
         DC    AL2(OFST)                                                43190020
MSG05    DC    C'IKJ58005I DATA SET  NOT USABLE+'                       43200020
LMSG06   DC    AL2(L'MSG06+HDR)                                         43250020
         DC    AL2(OFST)                                                43260020
MSG06    DC    C'IKJ58006I UNABLE TO DELETE DATA SET +'                 43270020
LMSG07   DC    AL2(L'MSG07+HDR)                                         43280020
         DC    AL2(OFST)                                                43290020
MSG07    DC    C'IKJ58007I INVALID USE OF * IN +'                       43300020
LMSG08   DC    AL2(L'MSG08+HDR)                                         43310020
         DC    AL2(OFST)                                                43320020
MSG08    DC    C'IKJ58008I MEMBER SPECIFIED BUT  NOT A PARTITIONED DATAX43370020
                SET'                                                    43380020
LMSG09   DC    AL2(L'MSG09+HDR)                                         43430020
         DC    AL2(OFST)                                                43440020
MSG09    DC    C'IKJ58009I DATA SET NAME REQUIRED WHEN MEMBER  SPECIFIEX43490021
               D'                                                A49872 43500021
LMSG10   DC    AL2(L'MSG10+HDR)                                         43550020
         DC    AL2(OFST)                                                43560020
MSG10    DC    C'IKJ58010I DATA SET  NOT IN CATALOG'                    43610020
LMSG11   DC    AL2(L'MSG11+HDR)                                         43620020
         DC    AL2(OFST)                                                43670020
MSG11    DC    C'IKJ58011I DATA SET  NOT ALLOCATED, TOO MANY DATA SETS+X43680020
               '                                                        43730020
LMSG12   DC    AL2(L'MSG12+HDR)                                         43740020
         DC    AL2(OFST)                                                43790020
MSG12    DC    C'IKJ58012I DATA SET  NOT ALLOCATED+'                    43800020
LMSG13   DC    AL2(L'MSG13+HDR)                                         43850020
         DC    AL2(OFST)                                                43860020
MSG13    DC    C'IKJ58013I DATA SET  NOT ALLOCATED, REQUIRED VOLUME NOTX43910020
                MOUNTED+'                                               43960020
LMSG14   DC    AL2(L'MSG14+HDR)                                         44010020
         DC    AL2(OFST)                                                44020020
MSG14    DC    C'IKJ58014I DATA SET  NOT ALLOCATED, SYSTEM OR INSTALLATX44030020
               ION ERROR+'                                              44040020
LMSG15   DC    AL2(L'MSG15+HDR)                                         44050020
         DC    AL2(OFST)                                                44052020
MSG15    DC    C'IKJ58015I DATA SET  ALREADY IN USE, TRY LATER+'        44054020
LMSG16   DC    AL2(L'MSG16+HDR)                                         44056020
         DC    AL2(OFST)                                                44058020
MSG16    DC    C'IKJ58016I PROPER PASSWORD NOT SUPPLIED FOR '           44058420
LMSG17   DC    AL2(L'MSG17+HDR)                                         44058820
         DC    AL2(OFST)                                                44059220
MSG17    DC    C'IKJ58017I SPECIFIED MEMBER NOT IN DATA SET '           44059620
LMSG18   DC    AL2(L'MSG18+HDR)                                         44060020
         DC    AL2(OFST)                                                44110020
MSG18    DC    C'IKJ58018I INVALID DATA SET NAME, '''' EXCEEDS 44 CHARAX44160020
               CTERS'                                                   44210020
LMSG19   DC    AL2(L'MSG19+HDR)                                         44220020
         DC    AL2(OFST)                                                44270020
MSG19    DC    C'IKJ58019I NO DATA SETS FOUND TO MATCH * IN '           44280020
LMSG20   DC    AL2(L'MSG20+HDR)                                         44330020
         DC    AL2(OFST)                                                44340020
MSG20    DC    C'IKJ58020I DATA SET  NOT ON A DIRECT ACCESS DEVICE, NOTX44390020
                SUPPORTED'                                              44400020
LMSG21   DC    AL2(L'MSG21+HDR)                                         44450020
         DC    AL2(OFST)                                                44460020
MSG21    DC    C'IKJ58021I DATA SET  RESIDES ON MULTIPLE VOLUMES, NOT SX44750020
               UPPORTED'                                                44760020
*  SECOND LEVEL MESSAGE BRANCH TABLE                                    44810020
IKJEHSMG DS    0F                  ALIGN SECOND LEVEL BRANCH TABLE      44820020
ASMSG01  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     44870020
         DC    AL3(LSMSG01)        MESSAGE ADDRESS                      44880020
ASMSG02  DC    AL1(OFSTSM02)       INSERTION OFFSET                     44930020
         DC    AL3(LSMSG02)        MESSAGE ADDRESS                      44940020
ASMSG03  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     44990020
         DC    AL3(LSMSG03)        MESSAGE ADDRESS                      45000020
ASMSG04  DC    AL1(OFSTSM04)       INSERTION OFFSET                     45050020
         DC    AL3(LSMSG04)        MESSAGE ADDRESS                      45060020
ASMSG05  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45110020
         DC    AL3(LSMSG05)        MESSAGE ADDRESS                      45120020
ASMSG06  DC    AL1(OFSTSM06)       INSERTION OFFSET                     45170020
         DC    AL3(LSMSG06)        MESSAGE ADDRESS                      45180020
ASMSG07  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45230020
         DC    AL3(LSMSG07)        MESSAGE ADDRESS                      45240020
ASMSG08  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45290020
         DC    AL3(LSMSG08)        MESSAGE ADDRESS                      45300020
ASMSG09  DC    AL1(OFSTSM09)       INSERTION OFFSET                     45350020
         DC    AL3(LSMSG09)        MESSAGE ADDRESS                      45360020
ASMSG10  DC    AL1(OFSTSM10)       INSERTION OFFSET                     45410020
         DC    AL3(LSMSG10)        MESSAGE ADDRESS                      45420020
ASMSG11  DC    AL1(OFSTSM11)       INSERTION OFFSET                     45470020
         DC    AL3(LSMSG11)        MESSAGE ADDRESS                      45480020
ASMSG12  DC    AL1(OFSTSM12)       INSERTION OFFSET                     45530020
         DC    AL3(LSMSG12)        MESSAGE ADDRESS                      45540020
ASMSG13  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45590020
         DC    AL3(LSMSG13)        MESSAGE ADDRESS                      45600020
ASMSG14  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45650020
         DC    AL3(LSMSG14)        MESSAGE ADDRESS                      45660020
ASMSG15  DC    AL1(OFSTSM15)       INSERTION OFFSET                     45710020
         DC    AL3(LSMSG15)        MESSAGE ADDRESS                      45720020
ASMSG16  DC    AL1(OFSTSM16)       INSERTION OFFSET                     45770020
         DC    AL3(LSMSG16)        MESSAGE ADDRESS                      45780020
ASMSG17  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45830020
         DC    AL3(LSMSG17)        MESSAGE ADDRESS                      45840020
ASMSG18  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45890020
         DC    AL3(LSMSG18)        MESSAGE ADDRESS                      45900020
ASMSG19  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45910020
         DC    AL3(LSMSG19)        MESSAGE ADDRESS                      45920020
ASMSG20  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45930020
         DC    AL3(LSMSG20)        MESSAGE ADDRESS                      45940020
ASMSG21  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45942020
         DC    AL3(LSMSG21)        MESSAGE ADDRESS                      45944020
ASMSG22  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     45946020
         DC    AL3(LSMSG22)        MESSAGE ADDRESS                      45948020
*  SECOND LEVEL MESSAGES                                                45950020
LSMSG01  DC    AL2(L'SMSG01+HDR)                                        45960020
         DC    AL2(OFST)                                                46010020
SMSG01   DC    C'IKJ58011I USE FREE COMMAND TO FREE UNUSED DATA SETS'   46020020
LSMSG02  DC    AL2(L'SMSG02+HDR)                                        46070020
         DC    AL2(OFST)                                                46080020
SMSG02   DC    C'IKJ58001I PARSE ERROR CODE '                           46130020
LSMSG03  DC    AL2(L'SMSG03+HDR)                                        46140020
         DC    AL2(OFST)                                                46190020
SMSG03   DC    C'IKJ58007I * CANNOT BE USED WITH MEMBER'                46200020
LSMSG04  DC    AL2(L'SMSG04+HDR)                                        46250020
         DC    AL2(OFST)                                                46260020
SMSG04   DC    C'IKJ58001I DAIR ERROR CODE '                            46310020
LSMSG05  DC    AL2(L'SMSG05+HDR)                                        46320020
         DC    AL2(OFST)                                                46370020
SMSG05   DC    C'IKJ58013I VOLUME OR CVOL NOT ON SYSTEM AND CANNOT BE AX46380020
               CCESSED'                                                 46390020
LSMSG06  DC    AL2(L'SMSG06+HDR)                                        46430020
         DC    AL2(OFST)                                                46440020
SMSG06   DC    C'IKJ58014I DYNAMIC ALLOCATION ERROR CODE '              46490020
LSMSG07  DC    AL2(L'SMSG07+HDR)                                        46500020
         DC    AL2(OFST)                                                46550020
SMSG07   DC    C'IKJ58004I PURGE OPERAND OF THIS COMMAND MAY BE USED'   46560020
LSMSG08  DC    AL2(L'SMSG08+HDR)                                        46610020
         DC    AL2(OFST)                                                46620020
SMSG08   DC    C'IKJ58004I SYSTEM OPERATOR DID NOT AUTHORIZE ACCESS TO X46670020
               DATA SET'                                         A49872 46680021
LSMSG09  DC    AL2(L'SMSG09+HDR)                                        46730020
         DC    AL2(OFST)                                                46740020
SMSG09   DC    C'IKJ58005I OPEN ERROR CODE '                            46790020
LSMSG10  DC    AL2(L'SMSG10+HDR)                                        46800020
         DC    AL2(OFST)                                                46850020
SMSG10   DC    C'IKJ58014I CATALOG ERROR CODE '                         46860020
LSMSG11  DC    AL2(L'SMSG11+HDR)                                        46910020
         DC    AL2(OFST)                                                46920020
SMSG11   DC    C'IKJ58006I SCRATCH ERROR CODE '                         46970020
LSMSG12  DC    AL2(L'SMSG12+HDR)                                        46980020
         DC    AL2(OFST)                                                47030020
SMSG12   DC    C'IKJ58006I STOW ERROR CODE '                            47040020
LSMSG13  DC    AL2(L'SMSG13+HDR)                                        47090020
         DC    AL2(OFST)                                                47100020
SMSG13   DC    C'IKJ58006I DATA SET RESIDES ON MULTIPLE VOLUMES'        47150020
LSMSG14  DC    AL2(L'SMSG14+HDR)                                        47160020
         DC    AL2(OFST)                                                47210020
SMSG14   DC    C'IKJ58015I DATA SET IS ALLOCATED TO ANOTHER JOB OR USERX47220020
               '                                                        47270020
LSMSG15  DC    AL2(L'SMSG15+HDR)                                        47280020
         DC    AL2(OFST)                                                47330020
SMSG15   DC    C'IKJ58001I DEFAULT ERROR CODE '                  A49872 47340021
LSMSG16  DC    AL2(L'SMSG16+HDR)                                        47390020
         DC    AL2(OFST)                                                47400020
SMSG16   DC    C'IKJ58003I CATALOG ERROR CODE '                         47450020
LSMSG17  DC    AL2(L'SMSG17+HDR)                                        47460020
         DC    AL2(OFST)                                                47510020
SMSG17   DC    C'IKJ58007I MORE THAN ONE * IN DATA SET NAME'            47520020
LSMSG18  DC    AL2(L'SMSG18+HDR)                                        47570020
         DC    AL2(OFST)                                                47580020
SMSG18   DC    C'IKJ58007I * INVALID AS FIRST INDEX LEVEL'              47630020
LSMSG19  DC    AL2(L'SMSG19+HDR)                                        47640020
         DC    AL2(OFST)                                                47690020
SMSG19   DC    C'IKJ58012I INVALID UNIT IN USER ATTRIBUTE DATA SET'     47700020
LSMSG20  DC    AL2(L'SMSG20+HDR)                                        47750020
         DC    AL2(OFST)                                                47760020
SMSG20   DC    C'IKJ58012I NO UNIT AVAILABLE'                           47810020
LSMSG21  DC    AL2(L'SMSG21+HDR)                                        47820020
         DC    AL2(OFST)                                                47870020
SMSG21   DC    C'IKJ58014I CATALOG I/O ERROR'                           48000020
LSMSG22  DC    AL2(L'SMSG22+HDR)                                        48010020
         DC    AL2(OFST)                                                48020020
SMSG22   DC    C'IKJ58006I UNCATALOGED DATE PROTECTED DATA SETS NOT SUPX48030021
               PORTED'                                           A49872 48040021
         END                                                            48050020
