         TITLE 'IKJEHPRO-IBM S/360 TIME SHARING OPTION PROTECT COMMAND' 00080020
IKJEHPRO CSECT                                                          00160020
*A 505300                                                        A46794 00170021
*C 720000,723200,724000,727200,730400,740000                     A42336 00210021
*A 720500,724500                                                 A42336 00220021
         SPACE 2                                                        00240020
*********************************************************************** 00320020
*                                                                     * 00400020
* STATUS -- CHANGE LEVEL 01                                      A42336 00480021
*                                                                     * 00560020
* FUNCTION -- THE PROTECT COMMAND IS USED TO AFFECT THE PASSWORD AND  * 00640020
*    PROTECTION ATTRIBUTES OF BOTH NEW AND OLD DATA SETS.  IT IS ALSO * 00720020
*    TO DISPLAY THE CONTENTS OF THE SECURITY COUNTER AND THE OPTIONAL * 00800020
*    SECURITY INFORMATION WHICH APPEARS WITH EACH ENTRY IN THE        * 00880020
*    PASSWORD DATA SET.  THIS COMMAND MAY BE USED BOTH TO ASSIGN AND  * 00960020
*    TO REMOVE SECURITY PROTECTION FROM A DATA SET.                   * 01040020
*                                                                     * 01120020
* ENTRY POINTS --                                                     * 01200020
*         IKJEHPRO - MAIN ENTRY POINT OF PROGRAM, ATTACHED BY THE     * 01280020
*    TERMINAL MONITOR PROGRAM WHEN A PROTECT COMMAND IS ENTERED AT    * 01360020
*    A TERMINAL                                                       * 01440020
*                                                                     * 01520020
* INPUT -- REGISTER 1 POINTS TO THE STANDARD COMMAND PROCESSOR        * 01600020
*    PARAMETER LIST (CPPL) AS FOLLOWS-                                * 01680020
*    WORD 1 CONTAINS A POINTER TO THE COMMAND BUFFER                  * 01760020
*    WORD 2 CONTAINS A POINTER TO THE USER PROFILE TABLE              * 01840020
*    WORD 3 CONTAINS A POINTER TO THE PROTECTED STEP CONTROL BLOCK    * 01920020
*    WORD 4 CONTAINS A POINTER TO AN ENVIRONMENT CONTROL TABLE        * 02000020
*                                                                     * 02080020
* OUTPUT -- USUALLY NONE, EXCEPT APPROPRIATE ERROR MESSAGES TO        * 02160020
*    DESCRIBE ERROR CONDITIONS.  WHEN THE REQUEST IS TO LIST AN ENTRY * 02240020
*    OF THE PASSWORD DATA SET THE ACCESS COUNT, PROTECTION STATUS, AND* 02320020
*    USER INFORMATION WILL BE LISTED.                                 * 02400020
*                                                                     * 02480020
* EXTERNAL REFERENCES --                                              * 02560020
*         IKJPARS - ENTRY POINT TO PARSE ROUTINE                      * 02640020
*         IKJDAIR - ENTRY POINT TO DYNAMIC ALLOCATION INTERFACE       * 02660020
*    ROUTINE                                                          * 02680020
*         IKJPUTL - ENTRY POINT TO PUTLINE ROUTINE                    * 02720020
*         IKJDFLT - ENTRY POINT TO DEFAULT SERVICE ROUTINE            * 02800020
*         IGC0009H - ENTRY POINT TO SVC 98                            * 02880020
*                                                                     * 02960020
* EXITS, NORMAL -- RETURN TO THE TERMINAL MONITOR PROGRAM             * 03040020
*                                                                     * 03120020
* EXITS, ERROR -- RETURN TO THE TERMINAL MONITOR PROGRAM              * 03200020
*                                                                     * 03280020
* TABLES/WORKAREAS --                                                 * 03360020
*    COMMON - A DSECT TO MAP THE WORKAREA                             * 03440020
*                                                                     * 03520020
* ATTRIBUTES -- REENTRANT, READ-ONLY, REFRESHABLE                     * 03600020
*                                                                     * 03680020
* CHARACTER CODE DEPENDENCY -- CHARACTER CODE INDEPENDENT             * 03760020
*                                                                     * 03840020
* NOTES -- N/A                                                        * 03920020
*                                                                     * 04000020
*********************************************************************** 04080020
         EJECT                                                          04160020
*  REGISTER EQUATES                                                     04240020
R0       EQU   0                   GENERAL REGISTER 0                   04320020
R1       EQU   1                   GENERAL REGISTER 1                   04400020
R2       EQU   2                   GENERAL REGISTER 2                   04480020
R3       EQU   3                   GENERAL REGISTER 3                   04560020
R4       EQU   4                   GENERAL REGISTER 4                   04640020
R5       EQU   5                   GENERAL REGISTER 5                   04720020
R6       EQU   6                   GENERAL REGISTER 6                   04800020
R7       EQU   7                   GENERAL REGISTER 7                   04880020
R8       EQU   8                   GENERAL REGISTER 8                   04960020
R9       EQU   9                   GENERAL REGISTER 9                   05040020
R10      EQU   10                  GENERAL REGISTER 10                  05120020
R11      EQU   11                  GENERAL REGISTER 11                  05200020
R12      EQU   12                  GENERAL REGISTER 12                  05280020
R13      EQU   13                  GENERAL REGISTER 13                  05360020
R14      EQU   14                  GENERAL REGISTER 14                  05440020
R15      EQU   15                  GENERAL REGISTER 15                  05520020
*                                                                       05600020
*              REGISTER USUAGE                                          05680020
*                                                                       05760020
*  REGISTER 0  USED AS WORK REGISTER                                    05840020
*                                                                       05920020
*  REGISTER 1  USED AS PARAMETER REGISTER AND A WORK REGISTER           06000020
*                                                                       06080020
*  REGISTER 2  USED AS WORK REGISTER                                    06160020
*                                                                       06240020
*  REGISTER 3  USED IN 'EXECUTE MVC' AS POINTER TO 'TO AREA' AND AS     06320020
*              WORK REGISTER                                            06400020
*                                                                       06480020
*  REGISTER 4  USED IN 'EXECUTE MVC' AS POINTER TO 'FROM AREA' AND AS   06560020
*              WORK REGISTER                                            06640020
*                                                                       06720020
*  REGISTER 5  USED AS WORK REGISTER                                    06800020
*                                                                       06880020
*  REGISTER 6  USED AS WORK REGISTER                                    06960020
*                                                                       07040020
*  REGISTER 7  IS NOT USED                                              07120020
*                                                                       07200020
*  REGISTER 8  IS WORK REGISTER                                         07280020
*                                                                       07360020
*  REGISTER 9  IS BASE REGISTER FOR PARSE DSECT                         07440020
*                                                                       07520020
*  REGISTER 10 USED AS WORK REGISTER                                    07600020
*                                                                       07680020
*  REGISTER 11 USED AS WORK REGISTER                                    07760020
*                                                                       07840020
*  REGISTER 12 IS BASE REGISTER FOR THIS PROGRAM                        07920020
*                                                                       08000020
*  REGISTER 13 IS SAVEAREA AND DSECT BASE REGISTER                      08080020
*                                                                       08160020
*  REGISTER 14 IS THE LINK REGISTER                                     08240020
*                                                                       08320020
*  REGISTER 15 IS THE BRANCH AND RETURN CODE REGISTER                   08400020
*                                                                       08480020
         SPACE 2                                                        08560020
*  ABSOLUTE EQUATES (OFFSETS AND SHORT LENGTHS)                         08640020
ONE      EQU   1                   ONE                                  08720020
TWO      EQU   2                   TWO                                  08800020
F0       EQU   0                   ZERO                                 08880020
F1       EQU   1                   ONE                                  08960020
F2       EQU   2                   TWO                                  09040020
F4       EQU   4                   FOUR                                 09120020
F5       EQU   5                   FIVE                                 09200020
F6       EQU   6                   SIX                                  09280020
F7       EQU   7                   SEVEN                                09360020
F8       EQU   8                   EIGHT                                09440020
F12      EQU   12                  TWELVE                               09520020
F16      EQU   16                  SIXTEEN                              09600020
F20      EQU   20                  TWENTY                               09680020
F43      EQU   43                  FORTY-THREE                          09760020
L72      EQU   72                  LENGTH OF SAVEAREA                   09840020
F77      EQU   77                  SEVENTY-SEVEN (USER DATA LENGTH)     09920020
*  RETURN CODE EQUATES                                                  10000020
RC4      EQU   4                   RETURN CODE = 4                      10080020
RC8      EQU   8                   RETURN CODE = 8                      10160020
RC12     EQU   12                  RETURN CODE = 12                     10240020
RC16     EQU   16                  RETURN CODE = 16                     10320020
RC20     EQU   20                  RETURN CODE = 20                     10400020
RC24     EQU   24                  RETURN CODE = 24                     10480020
RC28     EQU   28                  RETURN CODE = 28                     10560020
RC32     EQU   32                  RETURN CODE = 32                     10640020
RC36     EQU   36                  RETURN CODE = 36                     10720020
*  EQUATES FOR MESSAGE NUMBERS (FIRST LEVEL MESSAGES)                   10800020
M01      EQU   1                   MESSAGE NUMBER 01                    10880020
M02      EQU   2                   MESSAGE NUMBER 02                    10960020
M03      EQU   3                   MESSAGE NUMBER 03                    11040020
M04      EQU   4                   MESSAGE NUMBER 04                    11120020
M05      EQU   5                   MESSAGE NUMBER 05                    11200020
M06      EQU   6                   MESSAGE NUMBER 06                    11280020
M07      EQU   7                   MESSAGE NUMBER 07                    11360020
M08      EQU   8                   MESSAGE NUMBER 08                    11440020
M09      EQU   9                   MESSAGE NUMBER 09                    11520020
M10      EQU   10                  MESSAGE NUMBER 10                    11600020
M11      EQU   11                  MESSAGE NUMBER 11                    11680020
M12      EQU   12                  MESSAGE NUMBER 12                    11760020
*  EQUATES FOR MESSAGE NUMBERS (SECOND LEVEL MESSAGES)                  11920020
S01      EQU   1                   SECOND LEVEL MESSAGE NUMBER 01       12000020
S02      EQU   2                   SECOND LEVEL MESSAGE NUMBER 02       12080020
S03      EQU   3                   SECOND LEVEL MESSAGE NUMBER 03       12160020
S04      EQU   4                   SECOND LEVEL MESSAGE NUMBER 04       12240020
S05      EQU   5                   SECOND LEVEL MESSAGE NUMBER 05       12320020
S06      EQU   6                   SECOND LEVEL MESSAGE NUMBER 06       12400020
S07      EQU   7                   SECOND LEVEL MESSAGE NUMBER 07       12480020
S08      EQU   8                   SECOND LEVEL MESSAGE NUMBER 08       12560020
S09      EQU   9                   SECOND LEVEL MESSAGE NUMBER 09       12640020
S10      EQU   10                  SECOND LEVEL MESSAGE NUMBER 10       12720020
S11      EQU   11                  SECOND LEVEL MESSAGE NUMBER 11       12800020
S12      EQU   12                  SECOND LEVEL MESSAGE NUMBER 12       12880020
S13      EQU   13                  SECOND LEVEL MESSAGE NUMBER 13       12960020
S14      EQU   14                  SECOND LEVEL MESSAGE NUMBER 14       13040020
S15      EQU   15                  SECOND LEVEL MESSAGE NUMBER 15       13120020
*              OTHER EQUATES                                            13200020
SPNUM    EQU   1                   SUBPOOL NUMBER                       13280020
ZERO     EQU   C'0'                CHARACTER ZERO                       13360020
PROMASK  EQU   X'01'               MASK TO CHECK PROTECTION MODE BYTE   13440020
DFLTOPT  EQU   X'04'               DEFAULT ENTRY OPTION                 13520020
DAIROPT  EQU   X'18'               DAIR ENTRY CODE - UNALLOCATE         13560020
QUOTEMSK EQU   X'40'               MASK TO CHECK IF DSNAME QUOTED       13600020
MASK1    EQU   X'40'               MASK TO CHECK FOR INTERRUPT          13680020
SWON     EQU   X'FF'               MASK TURN SWITCH ON                  13760020
SWOFF    EQU   X'00'               MASK TURN SWITCH OFF                 13840020
PRMASK   EQU   X'10'               MASK TEST FOR PROTECTION             13860020
RDWOTPAS EQU   X'04'               MASK TEST FOR READ WITHOUT PASSWORD  13880020
SVCOPT01 EQU   X'01'               SVC 98 ENTRY OPTION - ADD            13920020
SVCOPT02 EQU   X'02'               SVC 98 ENTRY OPTION - REPLACE        14000020
SVCOPT03 EQU   X'03'               SVC 98 ENTRY OPTION - DELETE         14080020
SVCOPT04 EQU   X'04'               SVC 98 ENTRY OPTION - LIST           14160020
SVCPCDE0 EQU   X'00'               SVC 98 PROTECTION - 'DEFAULT'        14240020
SVCPCDE1 EQU   X'01'               SVC 98 PROTECTION - PWREAD PWWRITE   14320020
SVCPCDE2 EQU   X'02'               SVC 98 PROTECTION - PWREAD NOWRITE   14400020
SVCPCDE3 EQU   X'03'               SVC 98 PROTECTION - NOPWREAD PWWRITE 14480020
ENDTEST  EQU   X'FF'               END OF MESSAGE CHAIN INDICATOR       14560020
BLANK    EQU   C' '                CHARACTER BLANK                      14640020
QUOTE    EQU   C''''               CHARACTER QUOTE                      14680020
PERIOD   EQU   C'.'                PERIOD                               14720020
ZONE     EQU   C'0'                CHARACTER CONSTANT FOR ZONE FIELD    14880020
*                                                                       14960020
         EJECT                                                          15040020
         SAVE  (14,12),,*          SAVE REGISTERS OF CALLING PROGRAM    15120020
         LR    R12,R15             ENTRY POINT ADDRESS TO BASE REGISTER 15200020
         USING IKJEHPRO,R12        ESTABLISH ADDRESSABILITY FOR PROGRAM 15280020
         LR    R2,R1               SAVE REG 1 - GETMAIN USES IT         15360020
         GETMAIN R,LV=CORE,SP=SPNUM get core for workarea               15440020
*  THIS IS AN UNCONDITIONAL REQUEST FOR CORE.  IF SUFFICIENT CORE IS    15520020
*  NOT AVAILABLE THE RESULT IS ABNORMAL TERMINATION OF THIS PROGRAM.    15600020
         LR    R13,R1              ADDRESS OF GETMAIN AREA TO BASE REG  15680020
         USING COMMON,R13          ESTABLISH ADDRESSABILITY GETMAIN     15760020
*  THE FIRST 18 WORDS IS THE REGISTER SAVE AREA                         15840020
         XC    F0(L72,R1),F0(R1)   INITIALIZE REGISTER SAVE AREA        15920020
         ST    R13,F4(R1)          SAVE ADDRESS OF CALLER'S REGISTERS   16000020
         ST    R1,F8(R13)          CHAIN SAVE AREAS                     16080020
*  WHEN THE TMP ATTACHES PROTECT REGISTER 1 POINTS TO A PARAMETER LIST  16240020
*  THE FORMAT OF THIS LIST IS-                                          16320020
*    1ST WORD POINTER TO THE COMMAND BUFFER                             16400020
*    2ND WORD POINTER TO THE USER PROFILE TABLE (UPT)                   16480020
*    3RD WORD POINTER TO THE PROTECTED STEP CONTROL BLOCK (PSCB)        16560020
*    4TH WORD POINTER TO THE ENVIRONMENT CONTROL TABLE (ECT)            16640020
         USING CPPL,R2             ESTABLISH ADDRESSABILITY CPPL        16720020
*  NOW INITIALIZE PARAMETERS FOR PARSE, DAIR, DEFAULT, AND PUTLINE      16800020
         LA    R5,PARSPARM         POINT TO SPACE FOR PARSE PARAMETERS  16880020
         USING PPL,R5              SET ADDRESSABILITY PARSE PARM LIST   16960020
         LA    R6,DFLTPARM         POINT TO SPACE FOR DEFAULT PARM LIST 17040020
         USING DFPL,R6             SET ADDRESSABILITY DEFAULT PARM LIST 17120020
         LA    R8,DFLTPBLK         POINT TO SPACE FOR DEFAULT PARMBLOCK 17200020
         USING DFPB,R8             SET ADDRESSABILITY DEFAULT PARMBLOCK 17280020
         LA    R9,IOPARM           POINT TO SPACE FOR I/O PARM LIST     17360020
         USING IOPL,R9             SET ADDRESSABILITY I/O PARM LIST     17440020
         LA    R10,DAIRPARM        POINT TO SPACE FOR DAPL              17460020
         USING DAPL,R10            SET ADDRESSABILITY DAPL              17480020
         L     R3,CPPLCBUF         COMMAND BUFFER ADDRESS-              17520020
         ST    R3,PPLCBUF          -TO PPL                              17600020
         L     R3,CPPLUPT          UPT ADDRESS-                         17680020
         ST    R3,PPLUPT           -TO PPL                              17760020
         ST    R3,DAPLUPT          -TO DAPL                             17800020
         ST    R3,IOPLUPT          -TO I/O PARAMETER LIST               17840020
         ST    R3,DFPLUPT          -TO DEFAULT PARAMETER LIST           17920020
         L     R3,CPPLPSCB         PSCB ADDRESS-                        18000020
         ST    R3,DAPLPSCB         -TO DAPL                             18040020
         ST    R3,DFPBPSCB         -TO DEFAULT PARAMETER BLOCK          18080020
         ST    R3,PSCBSAVE         SAVE PSCB ADDRESS                    18160020
         L     R3,CPPLECT          ECT ADDRESS-                         18240020
         ST    R3,PPLECT           -TO PPL                              18320020
         ST    R3,DAPLECT          -TO DAPL                             18360020
         ST    R3,IOPLECT          -TO I/O PARAMETER LIST               18400020
         ST    R3,DFPLECT          -TO DEFAULT PARAMETER LIST           18480020
         DROP  R2                  CPPL IS NO LONGER NEEDED             18560020
         LA    R3,PROCPECB         ADDRESS OF CP'S ECB-                 18640020
         ST    R3,PPLECB           -TO PPL                              18720020
         ST    R3,DAPLECB          -TO DAPL                             18760020
         ST    R3,IOPLECB          -TO I/O PARAMETER LIST               18800020
         ST    R3,DFPLECB          -TO DEFAULT PARAMETER LIST           18880020
         ST    R8,DFPLDFPB         POINTER TO PARM BLOCK TO PARM LIST   18960020
         LA    R3,DSL              POINT TO DSL-DSN BUFFER-             19040020
         ST    R3,DFPBDSN          -TO DEFAULT PARAMETER LIST           19120020
         MVI   DFPBCODE,DFPB04     SET DEFAULT ENTRY CODE               19200020
         MVI   DFPBCNTL,DFPBUID    INDICATE USERID ADD TO OCCUR         19280020
         LA    R3,ANSPLACE         ADDRESS OF PARSE ANSWER PLACE        19360020
         ST    R3,PPLANS           -TO PPL                              19440020
         L     R3,VPROPARM         ADDRESS OF PARSE MACROS              19520020
         ST    R3,PPLPCL           -TO PPL                              19600020
         LA    R11,DAIR18          POINT TO SPACE FOR DAPB18            19620020
         ST    R11,DAPLDAPB        PARM BLOCK TO PARM LIST              19640020
         USING DAPB18,R11          SET ADDRESSABILITY DAPB18            19660020
*  NOW INITIALIZE WORKAREAS USED IN THIS PROGRAM                        19680020
         MVC   PUT(PUTLEND-PUTL),PUTL INITIALIZE PUTLINE-               19760020
         MVC   PUTDATA(PUTDEND-PUTD),PUTD -PARMBLOCKS                   19840020
         MVI   PRMPTCNT,F0         INITIALIZE PROMPT COUNT              19920020
         MVI   PROMPTSW,SWOFF      INITIALIZE PROMPT SWITCH OFF         20000020
         MVI   STACKSW,SWOFF       TURN STACK SWITCH OFF                20050020
         XC    SVCPARMS(SVCNPRMS-SVCPARMS),SVCPARMS ZERO SVC PARMLIST   20080020
         SR    R2,R2               ZERO REGISTER                        20160020
         ST    R2,DFPBQUAL         ZERO POINTER TO DEFAULT QUALIFIER    20240020
         ST    R2,PROCPECB         INITIALIZE CP'S ECB                  20320020
         MVI   PWBLANK,BLANK       BLANK SCAN DELIMITER CHARACTER       20400020
         MVI   PWLIST,BLANK        BLANK-                               20480020
         MVC   PWLIST+F1(ENDPWLST-PWLIST-F1),PWLIST -PASSWORD BUFFERS   20560020
         MVI   DSN,BLANK           BLANK-                               20640020
         MVC   DSN+F1(F43),DSN     -DATA SET NAME BUFFER                20720020
         ST    R12,PPLUWA          PROGRAM ADDRESS FOR VALIDITY EXIT    20800020
* WHEN THE PARSE SERVICE ROUTINE IS ENTERED REGISTER 1 POINTS TO THE    20880020
* FOLLOWING PARAMETER LIST-                                             20960020
*    1ST WORD POINTER TO THE USER PROFILE TABLE                         21040020
*    2ND WORD POINTER TO THE ENVIRONMENT CONTROL TABLE                  21120020
*    3RD WORD POINTER TO THE COMMAND PROCESSOR'S EVENT CONTROL BLOCK    21200020
*    4TH WORD POINTER TO THE PARSE CONTROL LIST                         21280020
*    5TH WORD POINTER TO THE PARSE ANSWER PLACE                         21360020
*    6TH WORD POINTER TO THE COMMAND BUFFER                             21440020
*    7TH WORD POINTER TO THE USER WORK AREA (VALIDITY EXIT ROUTINE)     21520020
*                                                                       21600020
*  NOW PARSE PROTECT COMMAND                                            21680020
         DROP  R5                  PPL NO LONGER NEEDED                 21760020
         DROP  R6                  DFPL NO LONGER NEEDED                21840020
         DROP  R8                  DFPB NO LONGER NEEDED                21920020
         DROP  R9                  IOPL NO LONGER NEEDED                22000020
         DROP  R10                 DAPL NO LONGER NEEDED                22040020
         LR    R1,R5               POINT TO PARSE PARAMETER LIST        22080020
         LINK  EP=IKJPARS          LINK TO PARSE                        22160020
*  THE FORMAT OF THE LIST RETURNED FROM PARSE IS AS FOLLOWS-            22240020
*     1ST WORD POINTER TO DATA SET NAME (ZERO IF MISSING)               22320020
*     2ND WORD BYTE 0-1 LENGTH OF DATA SET NAME (EXCLUDING QUOTES)      22400020
*              BYTE 2   FLAGS (BIT 1 IS 1 IF DATA SET NAME QUOTED)      22480020
*              BYTE 3   RESERVED                                        22560020
*     3RD WORD POINTER TO MEMBER NAME (ZERO IF MISSING)                 22640020
*     4TH WORD BYTE 0-1 LENGTH OF MEMBER NAME (EXCLUDING PARENTHESES)   22720020
*              BYTE 2   FLAGS                                           22800020
*              BYTE 3   RESERVD                                         22880020
*     5TH WORD POINTER TO PASSWORD (XERO IF MISSING)                    22960020
*     6TH WORD BYTE 0-1 LENGTH OF PASSWORD                              23040020
*              BYTE 2   FLAGS                                           23120020
*              BYTE 3   RESERVED                                        23200020
*     AN ADDITIONAL HALFWORD (NAMED PROTYPE)                            23280020
*        A 1 INDICATES 'ADD' SPECIFIED OR DEFAULTED                     23360020
*        A 2 INDICATES 'REPLACE' SPECIFIED                              23440020
*        A 3 INDICATES 'DELETE' SPECIFIED                               23520020
*        A 4 INDICATES 'LIST' SPECIFIED                                 23600020
*     AN ADDITIONAL HALFWORD (NAMED RDTYPE)                             23680020
*        A 0 INDICATES NO READ KEYWORD SPECIFIED                        23760020
*        A 1 INDICATES 'PWREAD' SPECIFIED                               23840020
*        A 2 INDICATES 'NOPWREAD' SPECIFIED                             23920020
*     AN ADDITIONAL HALFWORD (NAMED WRTYPE)                             24000020
*        A 0 INDICATES NO WRITE KEYWORD SPECIFIED                       24080020
*        A 1 INDICATES 'PWWRITE' SPECIFIED                              24160020
*        A 2 INDICATES 'NOWRITE' SPECIFIED                              24240020
*     AN ADDITIONAL HALFWORD (NAMED DATATYPE)                           24320020
*        A 0 INDICATES NO DATA KEYWORD SPECIFIED                        24400020
*        A 1 INDICATES 'DATA' SPECIFIED                                 24480020
*     PLUS AN ADDITIONAL TWO WORDS FOR EACH PASSWORD OR DATA FIELD      24560020
*     SPECIFIED.  THE FORMAT OF EACH OF THESE TWO WORD FIELDS IS-       24640020
*                                                                       24720020
*     1ST WORD POINTER TO THE CHARACTER STRING                          24800020
*     2ND WORD BYTES 0-1 LENGTH OF THIS CHARACTER STRING                24880020
*              BYTES 2   FLAGS                                          24960020
*              BYTES 3   RESERVED                                       25040020
*                                                                       25120020
         LTR   R15,R15             TEST PARSE RETURN CODE               25200020
         BNZ   PARSEERR            GO ANALYZE PARSE ERROR               25280020
*  ESTABLISH ADDRESSABILITY FOR PARSE DSECT                             25360020
         L     R9,ANSPLACE         PARSE PUT DSECT ADDRESS HERE         25440020
         USING IKJPARMD,R9         ESTABLISH ADDRESSABILITY PARSE PDL   25520020
*  NOW CHECK DATA SET NAME INFORMATION FROM PARSE                       25600020
         LA    R6,PRODSN           POINT TO DSNAME PDE                  25680020
         SR    R2,R2               ZERO REGISTER                        25760020
         C     R2,F8(R6)           IS MEMBER NAME SPECIFIED             25840020
         BNE   MEMBRERR            ERROR, GO BUILD MESSAGE              25920020
         C     R2,F16(R6)          WAS CONTROL PASSWORD SPECIFIED       26000020
         BE    NOCNTLPW            NO, GO CHECK DSNAME                  26080020
         LH    R5,F20(R6)          LENGTH OF CONTROL PASSWORD           26160020
         BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    26240020
         LA    R3,CONTRLPW         POINT TO CONTROL PASSWORD            26320020
         ST    R3,SVCCONPW         SAVE THIS POINTER SVC PARAMETER LIST 26400020
         L     R4,F16(R6)          ADDRESS OF CONTROL PASSWORD (INPUT)  26480020
         EX    R5,MOVEINST         MOVE CONTROL PASSWORD TO BUFFER      26560020
*  NOW CHECK DATA SET NAME                                              26640020
NOCNTLPW LH    R5,F4(R6)           LENGTH OF DATA SET NAME              26720020
         LTR   R5,R5               IS LENGTH ZERO                       26800020
         BZ    MEMBRERR            YES, ERROR                           26880020
         STH   R5,DSL              LENGTH TO WORK AREA                  26960020
         L     R4,F0(R6)           ADDRESS OF DSNAME (INPUT)            27040020
         LA    R3,DSN              POINT TO DSNAME BUFFER               27120020
         BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    27200020
         EX    R5,MOVEINST         MOVE DSNAME TO WORK AREA             27280020
*  SAVE DATA SET NAME IN MESSAGE INSERTION BUFFER                       27360020
SAVEDSN  LH    R5,DSL              LENGTH OF DATA SET NAME              27440020
         BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    27520020
         LA    R3,DSNMESG          POINT TO DSNAME MESSAGE BUFFER       27600020
         LA    R4,DSN              ADDRESS OF DSNAME (WORKAREA)         27610020
         TM    F6(R6),QUOTEMSK     IS DATA SET NAME FULLY QUALIFIED     27612020
         BZ    SAVUNQUL            YES, SAVE UNQUALIFIED NAME           27614020
         MVI   F0(R3),QUOTE        MOVE QUOTE                           27620020
         LA    R3,F1(R3)           POINT PAST QUOTE                     27640020
         EX    R5,MOVEINST         MOVE DSNAME TO MESSAGE BUFFER        27760020
         LA    R3,F1(R5,R3)        POINT PAST DSNAME                    27780020
         MVI   F0(R3),QUOTE        MOVE QUOTE                           27800020
         LA    R5,F2(R5)           INCREASE LENGTH FOR QUOTES           27820020
         LA    R5,F5(R5)           1 FROM EXECUTE, 4 FOR HEADER         27840020
         STH   R5,DSNMESGL         DSNAME MESSAGE INSERTION LENGTH      27920020
*  NOW CHECK FOR FUNCTION REQUESTED                                     28160020
CHECKFCN LA    R5,DSN              POINT TO DSL-DSN BUFFER              28240020
         ST    R5,SVCDSL           ADDRESS OF BUFFER TO SVC PARM LIST   28320020
         LH    R5,DSL              DATA SET NAME LENGTH                 28400020
         STC   R5,SVCDSL           TO SVC PARAMETER LIST                28480020
         LH    R5,PROTYPE          LOAD PROTECTION TYPE INDICATOR       28560020
         BCTR  R5,R0               DECREMENT TO ZERO ORIGIN BRANCH      28640020
         SLL   R5,TWO              MULTIPLY TYPE NUMBER BY FOUR AND-    28720020
         B     BRTABLE(R5)         -USE AS INDEX INTO BRANCH TABLE      28800020
BRTABLE  B     ADD                 ADD WAS REQUESTED                    28880020
         B     REPLACE             REPLACE WAS REQUESTED                28960020
         B     DELETE              DELETE WAS REQUESTED                 29040020
*  NOTE LIST MUST FOLLOW SEQUENTIALLY HERE.                             29090020
*  BUILD SVC PARAMETER LIST FOR LIST REQUEST                            29120020
LIST     LA    R5,LISTBUFF         POINT TO LIST BUFFER                 29200020
         ST    R5,SVCOPT           ADDRESS TO SVC PARAMETER LIST        29280020
         MVI   SVCOPT,SVCOPT04     SVC ENTRY OPTION X'04' - LIST        29360020
         L     R4,LSTOLDPW         POINTER TO LIST PASSWORD             29440020
         LH    R5,LSTOLDPW+F4      PASSWORD LENGTH                      29520020
MOVEPW   BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    29600020
         LA    R3,CURENTPW         POINT TO CURRENT PASSWORD BUFFER     29680020
         ST    R3,SVCCURPW         ADDRESS TO SVC PARAMETER LIST        29760020
         EX    R5,MOVEINST         MOVE CURRENT PASSWORD TO BUFFER      29840020
         B     ISSUESVC            GO ISSUE SVC 98                      29920020
*  BUILD SVC PARAMETER LIST FOR DELETE REQUEST                          30000020
DELETE   MVI   SVCOPT,SVCOPT03     SVC ENTRY OPTION X'03' - DELETE      30080020
         L     R4,DELOLDPW         POINTER TO DELETE PASSWORD           30160020
         LH    R5,DELOLDPW+F4      PASSWORD LENGTH                      30240020
         B     MOVEPW              GO MOVE OLD PASSWORD TO BUFFER       30320020
*  BUILD SVC PARAMETER LIST FOR REPLACE REQUEST                         30400020
REPLACE  MVI   SVCOPT,SVCOPT02     SVC ENTRY OPTION X'02' - REPLACE     30480020
         BAL   R14,DATA            GO CHECK DATA                        30560020
         BAL   R14,SECURITY        GO CHECK PROTECTION KEYWORDS         30640020
         L     R4,REPNEWPW         POINTER TO NEW PASSWORD              30720020
         LTR   R4,R4               WAS A NEW PASSWORD SPECIFIED         30800020
         BZ    USEOLDPW            NO, GO USE OLD PASSWORD              30880020
         LH    R5,REPNEWPW+F4      PASSWORD LENGTH (NEW)                30960020
         BAL   R14,MVENEWPW        GO MOVE NEW PASSWORD TO BUFFER       31040020
OLDPW    L     R4,REPOLDPW         POINTER TO OLD PSSSWORD              31120020
         LH    R5,REPOLDPW+F4      LENGTH OF OLD PASSWORD               31200020
         B     MOVEPW              GO MOVE OLD PASSWORD TO BUFFER       31280020
USEOLDPW L     R4,REPOLDPW         POINTER TO OLD PASSWORD              31360020
         LH    R5,REPOLDPW+F4      LENGTH OF OLD PASSWORD               31440020
         BAL   R14,MVENEWPW        GO MOVE 'NEW' PASSWORD TO BUFFER     31520020
         B     OLDPW               GO PROCESS OLD PASSWORD              31600020
MVENEWPW BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    31680020
         LA    R3,NEWPW            POINT TO NEW PASSWORD BUFFER         31760020
         ST    R3,SVCPCODE         ADDRESS TO SVC PARAMETER LIST        31840020
         EX    R5,MOVEINST         MOVE NEW PASSWORD TO BUFFER          31920020
         SR    R5,R5               ZERO REGISTER                        32000020
         IC    R5,PROCODE          GET PROTECTION CODE                  32080020
         STC   R5,SVCPCODE         PROTECTION CODE TO SVC PARAMETER LST 32160020
         BR    R14                 RETURN                               32240020
*  BUILD SVC PARAMETER LIST FOR ADD REQUEST                             32320020
ADD      MVI   SVCOPT,SVCOPT01     SVC ENTRY OPTION X'01' - ADD         32400020
         BAL   R14,DATA            GO CHECK DATA                        32480020
         BAL   R14,SECURITY        GO CHECK PROTECTION KEYWORDS         32560020
         L     R4,ADDNEWPW         POINTER TO NEW PASSWORD              32640020
         LH    R5,ADDNEWPW+F4      LENGTH OF NEW PASSWORD               32720020
         BAL   R14,MVENEWPW        GO MOVE NEW PASSWORD TO BUFFER       32800020
         B     ISSUESVC            GO ISSUE SVC 98                      32880020
*  CHECK FOR DATA                                                       32960020
DATA     L     R5,STRDATA          LOAD DATA STRING POINTER             33040020
         LTR   R5,R5               IS POINTER ZERO                      33120020
         BZ    NODATA              YES, DATA NOT SPECIFIED              33200020
         ST    R5,SVCSTLTH         STRING POINTER TO SVC PARAMETER LIST 33280020
         LH    R5,STRDATA+F4       STRING LENGTH                        33360020
         STC   R5,SVCSTLTH         STRING LENGTH TO SVC PARAMETER LIST  33440020
NODATA   BR    R14                 RETURN                               33520020
*  CHECK PROTECTION KEYWORDS                                            33600020
SECURITY LH    R5,RDTYPE           LOAD READ TYPE INDICATOR             33680020
         SLL   R5,TWO              MULTIPLY TYPE NUMBER BY FOUR         33760020
         B     RDBRTAB(R5)         INDEX INTO BRANCH TABLE              33840020
RDBRTAB  B     RD0                 NO READ KEYWORD SPECIFIED            33920020
         B     RD1                 PWREAD SPECIFIED                     34000020
         B     SET3                NOPWREAD SPECIFIED, CODE IS X'03'    34080020
RD0      LH    R5,WRTYPE           LOAD WRITE TYPE INDICATOR            34160020
         SLL   R5,TWO              MULTIPLY TYPE NUMBER BY FOUR         34240020
         B     WR1BRTAB(R5)        INDEX INTO BRANCH TABLE              34320020
WR1BRTAB B     SET0                NEITHER SPECIFIED, TAKE DEFAULT      34400020
         B     SET3                PWWRITE SPECIFIED                    34480020
         B     SET2                NOWRITE SPECIFIED                    34560020
RD1      LH    R5,WRTYPE           LOAD WRITE TYPE INDICATOR            34640020
         SLL   R5,TWO              MULTIPLY TYPE NUMBER BY FOUR         34720020
         B     WR2BRTAB(R5)        INDEX INTO BRANCH TABLE              34800020
WR2BRTAB B     SET1                NO WRITE KEYWORD SPECIFIED           34880020
         B     SET1                PWWRITE SPECIFIED                    34960020
         B     SET2                NOWRITE SPECIFIED                    35040020
SET0     MVI   PROCODE,SVCPCDE0    NO KEYWORDS, INDICATE DEFAULT        35120020
         BR    R14                 RETURN                               35200020
SET1     MVI   PROCODE,SVCPCDE1    INDICATE PWREAD-PWWRITE              35280020
         BR    R14                 RETURN                               35360020
SET2     MVI   PROCODE,SVCPCDE2    INDICATE PWREAD-NOWRITE              35440020
         BR    R14                 RETURN                               35520020
SET3     MVI   PROCODE,SVCPCDE3    INDICATE NOPWREAD-NOWRITE            35600020
         BR    R14                 RETURN                               35680020
QUALDSN  LA    R1,DFLTPARM         ADDRESS OF DEFAULT PARAMETERS        35760020
         LINK  EP=IKJDFLT          LINK TO DEFAULT SERVICE ROUTINE      35840020
         B     DFLTERR(R15)        ANALYZE DEFAULT RETURN CODE          35930020
DFLTERR  B     DEFLTOK             DEFAULT RETURN CODE =  0             35940020
         B     CLEANUP             DEFAULT RETURN CODE =  4             35950020
         B     DSNBIG              DEFAULT RETURN CODE =  8             35960020
         B     CLEANUP             DEFAULT RETURN CODE = 12             35970020
         B     NOTCAT              DEFAULT RETURN CODE = 16             35980020
         B     NOTCAT              DEFAULT RETURN CODE = 20             35990020
         B     CLEANUP             DEFAULT RETURN CODE = 24             36000020
         B     DEFERR              DEFAULT RETURN CODE = 28             36010020
         B     CLEANUP             DEFAULT RETURN CODE = 32             36020020
         B     NOTCAT              DEFAULT RETURN CODE = 36             36030020
*  SAVE QUALIFIED NAME IN MESSAGE INSERTION BUFFER                      36080020
DEFLTOK  LH    R2,DSL              LENGTH OF FULLY QUALIFIED DSNAME     36160020
         LA    R3,DSNMESG          POINT TO MESSAGE INSERTION BUFFER    36240020
         LA    R4,DSN              POINT TO DATA SET NAME               36320020
         L     R5,PSCBSAVE         ADDRESS OF PSCB                      36400020
         USING PSCB,R5             SET ADDRESSABILITY TO PSCB           36480020
         SR    R1,R1               CLEAR REGISTER                       36560020
         IC    R1,PSCBUSRL         LENGTH OF USERID                     36640020
         DROP  R5                  PSCB NO LONGER NEEDED                36720020
         LA    R1,F1(R1)           PLUS ONE FOR THE PERIOD              36800020
         SR    R2,R1               SUBTRACT LENGTH OF USERID            36880020
         AR    R4,R1               POINT PAST USERID AND PERIOD         36960020
         BCTR  R2,R0               DECREMENT FOR EXECUTE INSTRUCTION    37040020
         EX    R2,MOVEINST         MOVE DSNAME TO INSERTION BUFFER      37120020
         LA    R2,F5(R2)           1 FOR EXECUTE, 4 FOR HEADER          37200020
         STH   R2,DSNMESGL         SAVE LENGTH OF INSERTION DSNAME      37280020
         B     CHECKFCN            GO CHECK REQUESTED FUNCTION          37360020
SAVUNQUL EX    R5,MOVEINST         MOVE DSNAME TO MESSAGE BUFFER        37410020
         LA    R5,F5(R5)           1 FROM EXECUTE, 4 FOR HEADER         37420020
         STH   R5,DSNMESGL         SAVE INSERTION LENGTH                37430020
         B     QUALDSN             GO QUALIFY DATA SET NAME             37432020
*  VALIDITY CHECK ROUTINE  (CHECK LENGTH OF USER DATA)                  37440020
VALDATA  SAVE  (14,12),,*          SAVE PARSE'S REGISTERS               37520020
         L     R12,F4(R1)          RESET BASE REGISTER (ADDRESSABILITY) 37600020
         L     R9,F0(R1)           ADDRESS OF PARSE DESCRIPTOR ELEMENT  37680020
         LH    R6,F4(R9)           LOAD LENGTH OF USER DATA FIELD       37760020
         CH    R6,DATALNTH         COMPARE LENGTH TO 77                 37840020
         BH    DATABAD             MORE THAN 77 IS ERROR                37920020
         SR    R15,R15             SET ZERO RETURN CODE FOR PARSE       38000020
GOBACK   RETURN (14,12),T,RC=(15)  RESTORE PARSE'S REGISTERS AND RETURN 38080020
DATABAD  LA    R15,RC4             SET RETURN CODE = 4 FOR PARSE        38160020
         B     GOBACK              RETURN TO PARSE                      38240020
*                                                                     * 38320020
*  THIS IS THE MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE MESSAGE CSECT 38400020
*  TO OBTAIN THE ADDRESS OF THE MESSAGE SEGMENT AND THE OFFSET AT WHICH 38480020
*  ANY INSERTIONS WILL BE MADE.                                         38560020
*  AT ENTRY R2 CONTAINS MESSAGE NUMBER AND R10 CONTAINS ADDRESS OF THE  38640020
*  INSERTION.  R14 IS THE RETURN REGISTER  (R10 = 0 IS NO INSERTION)    38720020
*                                                                       38800020
MSGBUILD SR    R3,R3               ZERO REGISTER                        38880020
         ST    R3,OUTAREA1         SET POINTER INDICATING ONE MESSAGE   38960020
         MVI   OUTAREA1,ENDTEST    FLAG END OF MESSAGE CHAIN            39040020
         L     R1,VCONMSG          ADDRESS OF MESSAGE BRANCH TABLE      39120020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             39200020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         39280020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              39360020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      39440020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                39520020
         ST    R3,OUTPUT11         MESSAGE ADDRESS TO OUTPUT LIST       39600020
         LTR   R10,R10             IS THERE AN INSERTION                39680020
         BZ    NOINSRT1            NO, GO SET SEGMENT COUNT TO 1        39760020
         SR    R2,R2               ZERO REGISTER                        39840020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             39920020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 40000020
         ST    R10,OUTPUT12        INSERTION ADDRESS TO OUTPUT LIST     40080020
         LA    R2,TWO              2 SEGMENTS                           40160020
SETCNT1  ST    R2,OUTCNT1          SET SEGMENT COUNT                    40240020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 40290020
         BR    R14                 RETURN                               40320020
NOINSRT1 LA    R2,ONE              ONE SEGMENT                          40400020
         B     SETCNT1             GO SET SEGMENT COUNT                 40480020
*                                                                       40560020
*  THIS IS THE SECOND LEVEL MESSAGE BUILD SUBROUTINE.  IT ACCESSES THE  40640020
*  MESSAGE CSECT TO OBTAIN THE ADDRESS OF THE SECOND LEVEL MESSAGE AND  40720020
*  THE OFFSET AT WHICH ANY INSERTIONS WILL BE MADE.                     40800020
*  AT ENTRY R2 CONTAINS SECOND LEVEL MESSAGE NUMBER AND R10 CONTAINS    40880020
*  ADDRESS OF THE INSERTION.  R14 IS THE RETURN REGISTER.  (R10 = 0 IS  40960020
*  NO INSERTION)                                                        41040020
*                                                                       41120020
SMSGBLD  SR    R3,R3               ZERO REGISTER                        41200020
         ST    R3,OUTAREA2         SET POINTER INDICATING LAST MESSAGE  41280020
         MVI   OUTAREA2,ENDTEST    FLAG END OF MESSAGE CHAIN            41360020
         LA    R3,OUTAREA2         POINT TO SECOND LEVEL MESSAGE CHAIN  41440020
         ST    R3,OUTAREA1         CHAIN SECOND LEVEL TO FIRST LEVEL    41520020
         L     R1,VCONSMSG         SECOND LEVEL MESSAGE BRANCH TABLE    41600020
         BCTR  R2,R0               DECREMENT MESSAGE NUMBER             41680020
         SLL   R2,TWO              MULTIPLY MESSAGE NUMBER BY 4         41760020
         L     R3,F0(R2,R1)        LOAD BRANCH TABLE ENTRY              41840020
         ST    R3,WORKWORD         SAVE THIS ENTRY                      41920020
         LA    R3,F0(R3)           CLEAR HIGH ORDER BYTE                42000020
         ST    R3,OUTPUT21         MESSAGE ADDRESS TO OUTPUT LIST       42080020
         LTR   R10,R10             IS THERE AN INSERTION                42160020
         BZ    NOINSRT2            NO, GO SET SEGMENT COUNT TO 1        42240020
         SR    R2,R2               ZERO REGISTER                        42320020
         IC    R2,WORKWORD         GET OFFSET FOR INSERTION             42400020
         STH   R2,F2(R10)          STORE OFFSET IN MESSAGE OFFSET FIELD 42480020
         ST    R10,OUTPUT22        INSERTION ADDRESS TO OUTPUT LIST     42560020
         LA    R2,TWO              2 SEGMENTS                           42640020
SETCNT2  ST    R2,OUTCNT2          SET SEGMENT COUNT                    42720020
         BR    R14                 RETURN                               42800020
NOINSRT2 LA    R2,ONE              ONE SEGMENT                          42880020
         B     SETCNT2             GO SET SEGMENT COUNT                 42960020
*  THIS ROUTINE CHECKS FOR ATTENTION INTERRUPT                          43040020
TESTATTN TM    PROCPECB,MASK1      IS ECB POSTED (DID INTERRUPT OCCUR)  43120020
         BO    CLEANUP             YES, CLEANUP AND RETURN              43200020
         BR    R14                 RETURN                               43280020
*  THIS ROUTINE PRINTS ERROR MESSAGES.                                  43360020
TPUT     BAL   R14,TESTATTN        GO CHECK FOR INTERRUPT               43440020
         LA    R1,IOPARM           POINT TO PUTLINE GENERAL PARAMETERS  43520020
         PUTLINE  PARM=PUT,OUTPUT=(OUTAREA1,MULTLVL),MF=(E,(1)),       X43600020
               TERMPUT=(EDIT,WAIT)                                      43680020
         LA    R3,F4               R3 = 4                               43760020
         CR    R3,R15              DID ATTENTION INTERRUPT OCCUR        43840020
         BE    CLEANUP             YES, CLEANUP AND RETURN              43920020
         CLI   PROMPTSW,SWON       IS PROMPTING REQUIRED                44000020
         BE    PWPROMPT            YES, GO PROMPT FOR CONTROL PASSWORD  44080020
         B     CLEANUP             CLEANUP AND RETURN                   44160020
*  THIS ROUTINE PRINTS DATA                                             44240020
TPUTDATA BAL   R14,TESTATTN        GO CHECK FOR INTERRUPT               44320020
         LA    R1,IOPARM           POINT TO PUTLINE GENERAL PARAMETERS  44400020
         PUTLINE  PARM=PUTDATA,OUTPUT=(OUTBUFF,SINGLE,DATA),MF=(E,(1)),X44480020
               TERMPUT=(EDIT,WAIT)                                      44560020
         LA    R3,F4               R3 = 4                               44640020
         CR    R3,R15              DID ATTENTION INTERRUPT OCCUR        44720020
         BE    CLEANUP             YES, CLEANUP AND RETURN              44800020
         BR    R2                  RETURN                               44880020
SVCOK    CLI   SVCOPT,SVCOPT04     WAS THIS A LIST REQUEST              44960020
         BE    LISTPROC            YES, GO PROCESS BUFFER               45040020
CLEANUP  EQU   *                   CLEAN UP AND RETURN                  45240020
*  ZERO ALL PASSWORD FIELDS BEFORE FREEING CORE.                        45520020
         XC    PWLIST(ENDPWLST-PWLIST),PWLIST ZERO PASSWORD LIST        45600020
         XC    LISTBUFF(ENDLSTBF-LISTBUFF),LISTBUFF ZERO LIST BUFFER    45680020
         XC    PWMSG(PWBLANK-PWMSG),PWMSG ZERO PASSWORD MESSAGE BUFFER  45760020
*  NOW CHECK IF AN ERROR HAS OCCURRED.  IF SO, THE STACK MUST BE        45810020
*  FLUSHED AND THE INPUT QUEUE CLEARED.                                 45820020
         CLI   STACKSW,SWON        IS STACK SWITCH ON                   45830020
         BNE   STACKOK             NO ERROR, END NORMALLY               45840020
         LA    R1,IOPARM           POINT TO I/O PARAMETER LIST          45850020
         LA    R2,STACKPRM         POINT TO STACK PARM BLOCK            45852020
         ST    R2,IOPLIOPB-IOPL(R1) PARM BLOCK ADDRESS TO PARM LIST     45854020
         STACK DELETE=ALL,MF=(E,(1)) FLUSH STACK                        45856020
         TCLEARQ INPUT             CLEAR ANYTHING TYPED AHEAD           45858020
STACKOK  EQU   *                   NORMAL RETURN FROM HERE              45858420
         L     R13,F4(R13)         SET REG 13 TO CALLER'S REGISTERS     45860020
         SR    R15,R15             SET SUCCESSFUL RETURN CODE           46080020
         RETURN (14,12),T,RC=(15)  RESTORE REGISTERS AND RETURN         46160020
LISTPROC LH    R2,LISTBUFF         LOAD ACCESS (USE) COUNT              46240020
         SLL   R2,F16              SHIFT OUT POSSIBLE-                  46320020
         SRL   R2,F16              -NEGATIVE SIGN                       46400020
         CVD   R2,UNPACK           CONVERT TO PACKED DECIMAL FORMAT     46480020
         UNPK  COUNT,UNPACK        CONVERT TO ZONED FORMAT              46560020
         OI    SIGNBYTE,ZONE       ZONE OVER SIGN                       46640020
         LH    R2,DSNMESGL         LENGTH OF DSNAME + HEADER            46720020
         LR    R5,R2               -TO REG 5                            46800020
         SH    R5,FIVE             LESS 4 FOR HEADER AND 1 FOR EXECUTE  46880020
         LA    R3,OUTBUFFR         POINT TO DATA BUFFER                 46960020
         LA    R4,DSNMESG          POINT TO DSNAME                      47040020
         EX    R5,MOVEINST         MOVE DSNAME TO DATA BUFFER           47120020
         LA    R3,F1(R5,R3)        POINT PAST DSNAME                    47200020
         MVC   F0(L'BLANKS,R3),BLANKS MOVE IN BLANK CHARACTERS          47280020
         LA    R3,L'BLANKS(R3)     POINT PAST BLANKS                    47360020
         LA    R2,L'BLANKS(R2)     BUMP LENGTH OF DATA BUFFER           47440020
*  SUPPRESS LEADING ZEROES IN USE COUNT                                 47520020
         LA    R4,COUNT            POINT TO COUNT BUFFER                47600020
         LA    R5,F7               R5 = 7                               47680020
SUPZERO  CLI   F0(R4),ZERO         IS THIS A LEADING ZERO               47760020
         BNE   NONZERO             NO, GO MOVE USE COUNT                47840020
         LA    R4,F1(R4)           YES, POINT TO NEXT DIGIT             47920020
         BCT   R5,SUPZERO          CHECK NEXT DIGIT                     48000020
NONZERO  LA    R5,ENDCOUNT         POINT PAST COUNT FIELD               48080020
         SR    R5,R4               NUMBER OF SIGNIFICANT DIGITS IN REG5 48160020
         AR    R2,R5               BUMP LENGTH OF DATA BUFFER           48240020
         BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    48320020
         EX    R5,MOVEINST         MOVE IN USE COUNT                    48400020
         LA    R3,F1(R5,R3)        POINT PAST USE COUNT                 48480020
         MVC   F0(L'BLANKS,R3),BLANKS MOVE IN BLANK CHARACTERS          48560020
         LA    R3,L'BLANKS(R3)     POINT PAST BLANKS                    48640020
         LA    R2,L'BLANKS(R2)     BUMP LENGTH OF DATA BUFFER           48720020
*  NOW DETERMINE PROTECTION TYPE                                        48800020
         MVC   LOCLIST(CLSTLNTH),CLISTS INITIALIZE LOCATE AND OBTAIN    48803020
         LA    R4,DSN              DSNAME ADDRESS-                      48806020
         ST    R4,LOCDSN           -TO LOCATE LIST                      48809020
         ST    R4,OBTNDSN          -TO OBTAIN LIST                      48812020
         LA    R4,VNUM             VNUM ADDRESS-                        48815020
         ST    R4,OBTNVNUM         -TO OBTAIN LIST                      48818020
         LA    R4,WORKAREA         WORKAREA ADDRESS-                    48821020
         ST    R4,LOCAREA          -TO LOCATE LIST                      48824020
         ST    R4,OBTNAREA         -TO OBTAIN LIST                      48827020
         LOCATE LOCLIST            ISSUE LOCATE                         48830020
         LTR   R15,R15             TEST LOCATE RETURN CODE              48833020
         BNZ   UNPRO               PROTECTION NOT AVAILABLE             48836020
         MVC   VNUM(F6),VOLNUM     MOVE VOLUME SERIAL NUMBER            48839020
         OBTAIN OBTNLIST           ISSUE OBTAIN                         48842020
         LTR   R15,R15             TEST OBTAIN RETURN CODE              48845020
         BNZ   UNPRO               PROTECTION NOT AVAILABLE             48848020
         USING DS1FMTID,R4         ADDRESSABILITY FORMAT 1 DSCB         48851020
         TM    DS1DSIND,PRMASK     IS DATA SET PROTECTED                48854020
         BNO   NOPRO               NOT PROTECTED                        48857020
         TM    DS1DSIND,RDWOTPAS   IS IT READ WITHOUT PASSWORD          48860020
         BO    RDWOTPRO            YES, READ WITHOUT PASSWORD           48863020
         DROP  R4                  DSCB NO LONGER NEEDED                48866020
         TM    PROMODE,PROMASK     TEST PROTECTION MODE BYTE            48880020
         BO    RDWRTPRO            ON INDICATES READ/WRITE PROTECTION   48960020
         LA    R4,READONLY         POINT TO PROTECTION TYPE             49040020
         LA    R5,L'READONLY       LENGTH OF PROTECTION TYPE            49120020
MOVEPRO  AR    R2,R5               BUMP LENGTH OF DATA BUFFER           49200020
         BCTR  R5,R0               DECREMENT FOR EXECUTE INSTRUCTION    49280020
         EX    R5,MOVEINST         MOVE PROTECTION TYPE TO DATA BUFFER  49360020
         STH   R2,OUTBUFF          LENGTH OF DATA BUFFER                49440020
         XC    OUTBUFFO(F2),OUTBUFFO ZERO INSERTION OFFSET              49520020
         BAL   R2,TPUTDATA         GO PRINT DATA                        49600020
*  CHECK IF USER DATA FIELD IS BLANK                                    49680020
         LA    R2,F77              LENGTH OF USER DATA FIELD            49760020
         LA    R3,PUSRDATA         POINT TO USER DATA                   49840020
CHCKDATA CLI   F0(R3),BLANK        IS THIS A BLANK                      49920020
         BNE   DATAOK              VALID DATA, GO PRINT IT              50000020
         LA    R3,F1(R3)           POINT TO NEXT CHARACTER              50080020
         BCT   R2,CHCKDATA         IF MORE CHARACTERS GO CHECK THEM     50160020
*  USER DATA FIELD IS BLANK ISSUE MESSAGE                               50240020
         LA    R2,M09              MESSAGE NUMBER 9                     50320020
         SR    R10,R10             NO INSERTION                         50400020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     50480020
         MVI   STACKSW,SWOFF       TURN STACK SWITCH OFF         A46794 50530021
         B     TPUT                GO PRINT MESSAGE                     50560020
RDWRTPRO LA    R4,READWRIT         POINT TO PROTECTION TYPE             50640020
         LA    R5,L'READWRIT       LENGTH OF PROTECTION TYPE            50720020
         B     MOVEPRO             GO MOVE PROTECTION TYPE TO BUFFER    50800020
UNPRO    LA    R4,NOTAVAIL         POINT TO PROTECTION TYPE             50808020
         LA    R5,L'NOTAVAIL       LENGTH OF PROTECTION TYPE            50816020
         B     MOVEPRO             GO MOVE PROTECTION TYPE TO BUFFER    50824020
NOPRO    LA    R4,NOTPROT          POINT TO PROTECTION TYPE             50832020
         LA    R5,L'NOTPROT        LENGTH OF PROTECTION TYPE            50840020
         B     MOVEPRO             GO MOVE PROTECTION TYPE TO BUFFER    50848020
RDWOTPRO LA    R4,RDWOPASS         POINT TO PROTECTION TYPE             50856020
         LA    R5,L'RDWOPASS       LENGTH OF PROTECTION TYPE            50864020
         B     MOVEPRO             GO MOVE PROTECTION TYPE TO BUFFER    50872020
*  USER DATA FIELD IS NOT BLANK PRINT IT                                50880020
DATAOK   LA    R2,F77              LENGTH OF USER DATA FIELD            50960020
         BCTR  R2,R0               DECREMENT FOR EXECUTE                51040020
         LA    R3,OUTBUFFR         POINT TO DATA BUFFER                 51120020
         LA    R4,PUSRDATA         POINT TO USER DATA                   51200020
         EX    R2,MOVEINST         MOVE USER DATA TO DATA BUFFER        51280020
         LA    R2,F5(R2)           1 FROM EXECUTE, 4 FOR HEADER         51360020
         STH   R2,OUTBUFF          LENGTH OF DATA BUFFER                51440020
         XC    OUTBUFFO(F2),OUTBUFFO ZERO INSERTION OFFSET              51520020
         BAL   R2,TPUTDATA         GO PRINT DATA                        51600020
         B     CLEANUP             GO CLEANUP AND RETURN                51680020
*  THE DATA SET BEING PROTECTED MUST BE UNALLOCATED OR SVC 98 WILL NOT  51690020
*  BE ABLE TO ENQUEUE ON THE DSCB TO UPDATE THE SECURITY FLAGS.         51700020
*  THUS NOW UNALLOCATE THE DATA SET BY DSNAME                           51710020
ISSUESVC XC    DAIR18(DAIREND),DAIR18 XERO DAIR PARAMETER BLOCK         51720020
         MVI   DA18CD+F1,DAIROPT   SET OPTION TO UNALLOCATE             51730020
         MVI   DA18DDN,BLANK       BLANK                                51740020
         MVC   DA18DDN+F1(F7),DA18DDN BLANK DDNAME FIELD                51750020
         MVC   DA18MNM(F8),DA18DDN BLANK MEMBER NAME FIELD              51760020
         MVC   DA18JBNM(F8),DA18DDN BLANK JOB NAME FIELD                51770020
         LA    R1,DSL              DSL-DSN BUFFER-                      51780020
         ST    R1,DA18PDSN         TO DAIR PARM BLOCK                   51790020
         DROP  R11                 DAPB NO LONGER NEEDED                51800020
         LA    R1,DAIRPARM         POINT TO DAIR PARAMETER LIST         51810020
         LINK  EP=IKJDAIR          LINK TO DAIR, UNALLOCATE DATA SET    51820020
SVC98    LA    R1,SVCPARMS         POINT TO SVC PARAMETER LIST          51830020
         PROTECT (1)               ISSUE PROTECT SVC                    51840020
         B     SVCRCTAB(R15)       ANALYZE SVC RETURN CODE              51920020
SVCRCTAB B     SVCOK               SVC RETURN CODE =  0                 52000020
         B     PWEXISTS            SVC RETURN CODE =  4                 52080020
         B     PWNTFND             SVC RETURN CODE =  8                 52160020
         B     PWCNTRL             SVC RETURN CODE = 12                 52240020
         B     LOGICERR            SVC RETURN CODE = 16                 52320020
         B     MPDSERR             SVC RETURN CODE = 20                 52400020
         B     MPDSFULL            SVC RETURN CODE = 24                 52480020
         B     LOGICERR            SVC RETURN CODE = 28                 52560020
         B     LOCFAIL             SVC RETURN CODE = 32                 52640020
         B     OBTNFAIL            SVC RETURN CODE = 36                 52720020
         B     NOTFLAG             SVC RETURN CODE = 40                 52800020
         B     NOMPDS              SVC RETURN CODE = 44                 52880020
         B     NOTTAPE             SVC RETURN CODE = 48                 52960020
         B     INUSE               SVC RETURN CODE = 52                 53000020
SCANPW   SR    R1,R1               CLEAR REGISTER                       53040020
         LA    R3,PWMSG            ADDRESS OF PASSWORD TO BE SCANNED    53120020
BLANKTST CLI   F0(R3),BLANK        IS THIS CHARACTER A BLANK            53200020
         BE    F0(R14)             BLANK FOUND, RETURN, LENGTH IN R1    53280020
         LA    R3,F1(R3)           POINT TO NEXT CHARACTER              53360020
         LA    R1,F1(R1)           BUMP LENGTH COUNT                    53440020
         B     BLANKTST            GO CHECK NEXT CHARACTER              53520020
BLDMSG01 LA    R2,M01              MESSAGE NUMBER 1                     53600020
         B     MSGINSRT            GO GET INSERTION                     53680020
BLDMSG03 LA    R2,M03              MESSAGE NUMBER 3                     53760020
MSGINSRT LA    R10,DSNMESGL        POINT TO DSNAME INSERTION            53840020
MESGBLD  BAL   R14,MSGBUILD        GO BUILD MESSAGE                     53920020
         BR    R8                  RETURN FOR SECOND LEVEL MESSAGE      54000020
BLDMSG04 LA    R2,M04              MESSAGE NUMBER 4                     54080020
         B     MSGINSRT            GO GET INSERTION AND BUILD MESSAGE   54160020
PWINSERT MVC   PWMSG(F8),CURENTPW  MOVE PASSWORD TO INSERTION BUFFER    54240020
*  THIS SECTION DETERMINES THE LENGTH OF PASSWORDS.  THE PASSWORD IS  * 54320020
*  IN PWMSG AND THE MAXIMUM LENGTH IS 8.  THE NINTH BYTE IS BLANK.    * 54400020
*  SCAN STARTS AT FIRST CHARACTER AND ENDS WHEN A BLANK IS FOUND.     * 54480020
*  THE LENGTH IS RETURNED IN REGISTER 1.                              * 54560020
PWLENGTH BAL   R14,SCANPW          GO DETERMINE LENGTH OF PASSWORD      54640020
         LA    R1,F4(R1)           BUMP PASSWORD LENGTH BY HEADER LNTH  54720020
         STH   R1,PWMSGL           SAVE INSERTION LENGTH                54800020
         BR    R2                  RETURN                               54880020
PWCNTRL  CLI   CONTRLPW,BLANK      WAS CONTROL PASSWORD SPECIFIED       54960020
         BE    PWPROMPT            NO, GO PROMPT FOR CONTROL PASSWORD   55040020
*  CONTROL PASSWORD SPECIFIED WAS INCORRECT.  ISSUE ERROR MESSAGE, THEN 55120020
*  PROMPT FOR NEW CONTROL PASSWORD.                                     55200020
         MVC   PWMSG(F8),CONTRLPW  PASSWORD TO MESSAGE BUFFER           55280020
         BAL   R2,PWLENGTH         GO CALCULATE LENGTH OF PASSWORD      55360020
         MVI   PROMPTSW,SWON       TURN ON PROMPT SWITCH                55440020
         LA    R2,M10              MESSAGE NUMBER 10                    55520020
         B     SETINSRT            GO BUILD AND ISSUE MESSAGE           55600020
*  THE CONTROL PASSWORD IS REQUIRED TO AUTHORIZE THE REQUESTED CHANGE * 55680020
*  TO THE PASSWORD DATA SET.  THIS ROUTINE USES PARSE SERVICE ROUTINE * 55760020
*  TO PROMPT FOR CONTROL PASSWORD.                                    * 55840020
PWPROMPT SR    R2,R2               CLEAR REGISTER                       55920020
         MVI   PROMPTSW,SWOFF      TURN OFF PROMPT SWITCH               56000020
         IC    R2,PRMPTCNT         PROMPT COUNT                         56080020
         LA    R2,F1(R2)           BUMP PROMPT COUNT                    56160020
         STC   R2,PRMPTCNT         SAVE PROMPT COUNT                    56240020
         CLI   PRMPTCNT,TWO        COMPARE PROMPT COUNT TO TWO          56320020
         BH    TWOPRMPT            MORE THAN TWO PROMPTS IS ERROR       56400020
*  NOW BUILD BUFFER (BLANK) TO PASS TO PARSE                            56560020
         LA    R2,F6               R2 = 6                               56640020
         STH   R2,PRMPTBFL         PROMPT BUFFER LENGTH                 56720020
         SR    R2,R2               ZERO REGISTER                        56800020
         STH   R2,PRMPTBFO         PROMPT BUFFER OFFSET                 56880020
         MVC   PRMPTBUF,BLANKS     BLANK PROMPT BUFFER                  56960020
*  NOW BUILD PARSE PARAMETER LIST.                                      57040020
         ST    R2,ANSPLACE         ZERO WORD, PARSE ANSWER PLACE        57120020
         LA    R1,PARSPARM         POINT TO PARSE PARAMETER AREA        57200020
         USING PPL,R1              ESTABLISH ADDRESSABILITY PPL         57280020
         LA    R2,PRMPTBFL         PROMPT BUFFER ADDRESS-               57360020
         ST    R2,PPLCBUF          -TO PARSE PARAMETER LIST             57440020
         L     R2,VPSWPARM         ADDRESS OF PARSE MACROS-             57520020
         ST    R2,PPLPCL           -TO PARSE PARAMETER LIST             57600020
         DROP  R1                  PPL NO LONGER NEEDED                 57680020
         LINK  EP=IKJPARS          USE PARSE TO PROMPT FOR PASSWORD     57760020
*  THE FORMAT OF THE LIST RETURNED FROM PARSE IS AS FOLLOWS-            57840020
*     1ST WORD POINTER TO THE CHARACTER STRING                          57920020
*     2ND WORD BYTE 0-1 LENGTH OF THIS CHARACTER STRING                 58000020
*              BYTE 2   FLAGS                                           58080020
*              BYTE 3   RESERVED                                        58160020
         LTR   R15,R15             TEST RETURN CODE                     58240020
         BNZ   PARSEERR            GO ANALYZE PARSE ERROR               58320020
         L     R9,ANSPLACE         PARSE PUT DSECT ADDRESS HERE         58400020
         USING IKJPWPRM,R9         ESTABLISH ADDRESSABILITY PARSE PDL   58480020
         L     R4,CNTRLPW          POINTER TO CONTROL PASSWORD          58560020
         LH    R2,CNTRLPW+F4       LENGTH OF CONTROL PASSWORD           58640020
         BCTR  R2,R0               DECREMENT FOR EXECUTE INSTRUCTION    58720020
         LA    R3,CONTRLPW         CONTROL PASSWORD BUFFER              58800020
         MVI   F0(R3),BLANK        BLANK FIRST CHARACTER                58880020
         MVC   F1(F7,R3),F0(R3)    BLANK CONTROL PASSWORD BUFFER        58960020
         ST    R3,SVCCONPW         SAVE POINTER TO CONTROL PASSWORD     59040020
         EX    R2,MOVEINST         MOVE CONTROL PASSWORD TO BUFFER      59120020
         B     SVC98               GO ISSUE SVC 98                      59200020
*  THE FOLLOWING ROUTINES INITIALIZE REGISTER 2 TO CONTAIN              59280020
*  MESSAGE NUMBER AND REGISTER 10 TO POINT TO MESSAGE INSERTION         59360020
PWEXISTS MVC   PWMSG(F8),NEWPW     MOVE PASSWORD TO INSERTION BUFFER    59440020
         BAL   R2,PWLENGTH         GO CALCULATE LENGTH OF PASSWORD      59520020
         LA    R2,M06              MESSAGE NUMBER 6                     59600020
SETINSRT LA    R10,PWMSGL          POINT TO PASSWORD INSERTION          59680020
BLDMESG  BAL   R14,MSGBUILD        GO BUILD MESSAGE                     59760020
         B     TPUT                GO WRITE MESSAGE                     59840020
PWNTFND  BAL   R2,PWINSERT         GO BUILD PASSWORD INSERTION          59920020
         LA    R2,M07              MESSAGE NUMBER 7                     60000020
         B     SETINSRT            GO PREPARE AND WRITE MESSAGE         60080020
MEMBRERR LA    R2,M08              MESSAGE NUMBER 8                     60160020
NOINSERT SR    R10,R10             NO INSERTION                         60240020
         B     BLDMESG             GO BUILD AND WRITE MESSAGE           60320020
NOMPDS   BAL   R8,BLDMSG01         GO BUILD MESSAGE                     60400020
         LA    R2,S01              SECOND LEVEL MESSAGE NUMBER 1        60480020
BLDSMESG SR    R10,R10             NO INSERTION                         60560020
SMESGBLD BAL   R14,SMSGBLD         GO BUILD SECOND LEVEL MESSAGE        60640020
         B     TPUT                GO WRITE MESSAGE                     60720020
MPDSFULL BAL   R8,BLDMSG01         GO BUILD MESSAGE                     60800020
         LA    R2,S02              SECOND LEVEL MESSAGE 2               60880020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           60960020
MPDSERR  BAL   R8,BLDMSG01         GO BUILD MESSAGE                     61040020
         LA    R2,S03              SECOND LEVEL MESSAGE 3               61120020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           61200020
NOTTAPE  BAL   R8,BLDMSG04         GO BUILD MESSAGE                     61280020
         LA    R2,S14              SECOND LEVEL MESSAGE 14              61360020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           61440020
NOTFLAG  BAL   R8,BLDMSG04         GO BUILD MESSAGE                     61520020
         LA    R2,S15              SECOND LEVEL MESSAGE 15              61600020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           61680020
LOCFAIL  BAL   R8,BLDMSG04         GO BUILD MESSAGE                     61760020
         LA    R2,S11              SECOND LEVEL MESSAGE 11              61840020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           61920020
OBTNFAIL STC   R1,RC               SAVE OBTAIN RETURN CODE              62000020
         BAL   R8,BLDMSG04         GO BUILD MESSAGE                     62080020
         CLI   RC,RC4              IS RETURN CODE = 4                   62160020
         BE    VOLNTMTD            YES, VOLUME NOT MOUNTED              62240020
         LA    R2,S12              SECOND LEVEL MESSAGE 12              62320020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           62400020
VOLNTMTD LA    R2,S13              SECOND LEVEL MESSAGE 13              62480020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           62560020
INUSE    BAL   R8,BLDMSG04         GO BUILD MESSAGE                     62580020
         LA    R2,S06              SECOND LEVEL MESSAGE 6               62600020
         B     BLDSMESG            GO BUILD AND WRITE MESSAGE           62620020
PARSEERR STC   R15,RC              SAVE PARSE RETURN CODE               62640020
         MVI   STACKSW,SWON        TURN STACK SWITCH ON                 62690020
         CLI   RC,RC8              DID ATTENTION INTERRUPT OCCUR        62720020
         BNH   CLEANUP             YES, CLEANUP AND RETURN              62800020
         CLI   RC,RC16             PARSE RETURN CODE = 16               62880020
         BE    NOSPACE             YES, NO CORE                         62960020
         BAL   R8,MESG12           GO BUILD MESSAGE                     63060020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         63280020
         LA    R2,S05              SECOND LEVEL MESSAGE NUMBER 5        63360020
         B     SMESGBLD            GO BUILD AND WRITE MESSAGE           63440020
NOSPACE  LA    R2,M02              MESSAGE NUMBER 2                     63520020
         B     NOINSERT            GO BUILD AND WRITE MESSAGE           63600020
MESG12   LA    R2,M12              MESSAGE NUMBER 12                    63700020
         SR    R10,R10             NO INSERTION                         63800020
         BAL   R14,MSGBUILD        GO BUILD MESSAGE                     63900020
         BR    R8                  RETURN                               64000020
NOTCAT   BAL   R8,BLDMSG03         GO BUILD MESSAGE                     64100020
         B     TPUT                GO WRITE MESSAGE                     64200020
LOGICERR BAL   R8,MESG12           GO BUILD MESSAGE                     64300020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         64800020
         LA    R2,S10              SECOND LEVEL MESSAGE NUMBER 10       64880020
         B     SMESGBLD            GO BUILD AND WRITE MESSAGE           64960020
DEFERR   BAL   R8,MESG12           GO BUILD MESSAGE                     64970020
         BAL   R2,CONVRTRC         GO SET RETURN CODE INSERTION         64980020
         LA    R2,S04              SECOND LEVEL MESSAGE 4               64990020
         B     SMESGBLD            GO BUILD AND WRITE MESSAGE           65000020
DSNBIG   L     R4,PSCBSAVE         PSCB ADDRESS                         65040020
         LA    R3,DSNMESG          DSNAME INSERTION BUFFER              65120020
         SR    R2,R2               CLEAR REGISTER                       65200020
         IC    R2,PSCBUSRL-PSCB(R4) LENGTH OF USERID                    65280020
         LA    R4,PSCBUSER-PSCB(R4) ADDRESS OF USERID                   65360020
         EX    R2,MOVEINST         USERID TO DSNAME BUFFER              65440020
*  THIS MOVED ONE EXTRA BYTE WHICH WILL NOW BE OVERLAID WITH A PERIOD   65520020
         AR    R3,R2               POINT PAST USERID                    65600020
         MVI   F0(R3),PERIOD       MOVE IN PERIOD                       65680020
         LA    R3,F1(R3)           POINT PAST PERIOD                    65760020
         LA    R4,DSN              ADDRESS OF DATA SET NAME             65840020
         LH    R5,DSL              LENGTH OF DATA SET NAME              65920020
         AR    R2,R5               PLUS LENGTH OF USERID                66000020
         LA    R2,F5(R2)           ONE FOR PERIOD, FOUR FOR HEADER      66080020
         BCTR  R5,R0               DECREMENT FOR EXECUTE                66160020
         EX    R5,MOVEINST         MOVE DATA SET NAME TO USERID         66240020
         STH   R2,DSNMESGL         SAVE TOTAL LENGTH                    66320020
         LA    R2,M11              MESSAGE NUMBER 11                    66400020
         LA    R10,DSNMESGL        POINT TO INSERTION                   66480020
         B     BLDMESG             GO BUILD AND WRITE MESSAGE           66560020
TWOPRMPT LA    R2,M05              MESSAGE NUMBER 5                     66880020
         B     NOINSERT            GO BUILD AND WRITE MESSAGE           66960020
*  CONVERT RETURN CODE, SUPPRESS LEADING ZEROS AND MOVE TO INSERTION    67040020
*  BUFFER.  INPUT - R15 CONTAINS RETURN CODE TO BE CONVERTED            67120020
*           OUTPUT - R10 POINTS TO INSERTION BUFFER                     67200020
*  R2 IS THE RETURN REGISTER                                            67280020
CONVRTRC CVD   R15,UNPACK          CONVERT TO PACKED DECIMAL FORMAT     67360020
         UNPK  COUNT,UNPACK        CONVERT TO ZONED FORMAT              67440020
         OI    SIGNBYTE,ZONE       ZONE OVER SIGN                       67520020
*  SUPPRESS LEADING ZEROS IN RETURN CODE                                67600020
         LA    R4,COUNT            POINT TO COUNT BUFFER                67680020
         LA    R5,F7               R5 = 7                               67760020
SUPPZERO CLI   F0(R4),ZERO         IS THIS LEADING ZERO                 67840020
         BNE   NOTZERO             NO, GO MOVE RETURN CODE              67920020
         LA    R4,F1(R4)           YES, POINT TO NEXT DIGIT             68000020
         BCT   R5,SUPPZERO         GO CHECK NEXT DIGIT                  68080020
NOTZERO  LA    R5,ENDCOUNT         POINT PAST COUNT BUFFER              68160020
         SR    R5,R4               NUMBER OF SIGNIFICANT DIGITS IN R5   68240020
         BCTR  R5,R0               DECREMENT FOR EXECUTE                68320020
         LA    R3,RCMESG           POINT TO RETURN CODE BUFFER          68400020
         EX    R5,MOVEINST         MOVE RETURN CODE TO INSERTION BUFFER 68480020
         LA    R5,F5(R5)           4 FOR HEADER AND 1 FOR EXECUTE       68560020
         STH   R5,RCMESGL          LENGTH OF RETURN CODE INSERTION      68640020
         LA    R10,RCMESGL         POINT TO INSERTION BUFFER            68720020
         BR    R2                  RETURN                               68800020
         EJECT                                                          68880020
*  CONSTANTS USED IN THIS PROGRAM                                       68960020
VCONMSG  DC    V(IKJEHMSG)         ENTRY MESSAGE CSECT 1ST LEVEL        69040020
VCONSMSG DC    V(IKJEHSMG)         ENTRY MESSAGE CSECT 2ND LEVEL        69120020
VPROPARM DC    V(IKJEHPCD)         PARSE PARAMETERS PROTECT COMMAND     69200020
VPSWPARM DC    V(IKJEHPWP)         PARSE PARAMETERS PASSWORD PROMPTING  69280020
PUTL     PUTLINE MF=L              LIST FORM OF PUTLINE MACRO           69360020
PUTLEND  EQU   *                   END OF PUTLINE MACRO                 69440020
PUTD     PUTLINE MF=L              LIST FORM OF PUTLINE MACRO           69520020
PUTDEND  EQU   *                   END OF PUTLINE MACRO                 69600020
*  KEEP LOCATE AND OBTAIN LISTS TOGETHER, MOVED BY ONE INSTRUCTION      69610020
CLISTS   CAMLST NAME,0,,0          LOCATE CAMLST                        69620020
         CAMLST SEARCH,0,0,0       OBTAIN CAMLST                        69630020
CLSTLNTH EQU   *-CLISTS            LENGTH OF CAMLSTS                    69640020
DATALNTH DC    H'77'               MAXIMUM LENGTH OF USER DATA          69680020
FIVE     DC    H'5'                FIVE                                 69760020
MOVEINST MVC   F0(F0,R3),F0(R4)    MOVE INSTRUCTION                     69840020
BLANKS   DC    C'  '               BLANKS FOR MESSAGE SPACING           69920020
READWRIT DC    C'READ/WRITE'       READ/WRITE PROTECTION                70000020
READONLY DC    C'READ ONLY'        READ ONLY PROTECTION                 70080020
NOTPROT  DC    C'NOT PROTECTED'    NOT PROTECTED                        70100020
RDWOPASS DC    C'READ W/O PASSWORD' READ WITHOUT PASSWORD PROTECTION    70120020
NOTAVAIL DC    C'PROTECTION NOT AVAILABLE' DSCB NOT AVAILABLE           70140020
         EJECT                                                          70160020
*                                                                     * 70240020
*              PARSE MACROS FOR PROTECT COMMAND                       * 70320020
*                                                                     * 70400020
         DS    0F                                                       70480020
IKJEHPCD IKJPARM                                                        70560020
PRODSN   IKJPOSIT   DSNAME,PROMPT='DATA SET NAME',HELP=('NAME OF DATA SX70640020
               ET TO BE PROTECTED')                                     70720020
PROTYPE  IKJKEYWD   DEFAULT='ADD'                                       70800020
         IKJNAME    'ADD',SUBFLD=ADDFIELD                               70880020
         IKJNAME    'REPLACE',SUBFLD=REPFIELD                           70960020
         IKJNAME    'DELETE',SUBFLD=DELFIELD                            71040020
         IKJNAME    'LIST',SUBFLD=LSTFIELD                              71120020
RDTYPE   IKJKEYWD                                                       71200020
         IKJNAME    'PWREAD'                                            71280020
         IKJNAME    'NOPWREAD'                                          71360020
WRTYPE   IKJKEYWD                                                       71440020
         IKJNAME    'PWWRITE'                                           71520020
         IKJNAME    'NOWRITE'                                           71600020
DATATYPE IKJKEYWD                                                       71680020
         IKJNAME    'DATA',SUBFLD=STRFIELD                              71760020
ADDFIELD IKJSUBF                                                        71840020
ADDNEWPW IKJIDENT   'PASSWORD',MAXLNTH=8,OTHER=ALPHANUM,PROMPT='NEW PASX71920020
               SWORD',HELP=('PASSWORD OF ENTRY TO BE ADDED'),FIRST=ALPHX72000021
               ANUM                                              A42336 72050021
REPFIELD IKJSUBF                                                        72080020
REPOLDPW IKJIDENT   'PASSWORD',PTBYPS,MAXLNTH=8,OTHER=ALPHANUM,PROMPT='X72160020
               CURRENT PASSWORD',HELP=('PASSWORD OF ENTRY TO BE REPLACEX72240020
               D'),FIRST=ALPHANUM                                A42336 72320021
REPNEWPW IKJIDENT   'NEW PASSWORD',MAXLNTH=8,OTHER=ALPHANUM,FIRST=ALPHAX72400021
               NUM                                               A42336 72450021
DELFIELD IKJSUBF                                                        72480020
DELOLDPW IKJIDENT   'PASSWORD',PTBYPS,MAXLNTH=8,OTHER=ALPHANUM,PROMPT='X72560020
               CURRENT PASSWORD',HELP=('PASSWORD OF ENTRY TO BE DELETEDX72640020
               '),FIRST=ALPHANUM                                 A42336 72720021
LSTFIELD IKJSUBF                                                        72800020
LSTOLDPW IKJIDENT   'PASSWORD',PTBYPS,MAXLNTH=8,OTHER=ALPHANUM,PROMPT='X72880020
               CURRENT PASSWORD',HELP=('PASSWORD OF ENTRY TO BE LISTED'X72960020
               ),FIRST=ALPHANUM                                  A42336 73040021
STRFIELD IKJSUBF                                                        73120020
STRDATA  IKJPOSIT  QSTRING,PROMPT='DATA',HELP=('UP TO 77 BYTES OF CHARAX73200020
               CTER INFORMATION IN QUOTES'),VALIDCK=VALDATA             73250020
         IKJENDP                                                        73360020
         EJECT                                                          73440020
*                                                                       73520020
*        PARSE MACROS FOR PASSWORD PROMPTING                            73600020
*                                                                       73680020
IKJEHPWP IKJPARM    DSECT=IKJPWPRM                                      73760020
CNTRLPW  IKJIDENT   'PASSWORD',PTBYPS,MAXLNTH=8,OTHER=ALPHANUM,PROMPT='X73840020
               CONTROL PASSWORD',HELP=('PASSWORD OF CONTROL (FIRST) ENTX73920020
               RY FOR THIS DATA SET'),FIRST=ALPHANUM             A42336 74000021
         IKJENDP                                                        74080020
*                                                                     * 74160020
*              END OF PARSE MACROS                                    * 74240020
*                                                                     * 74320020
         EJECT                                                          74400020
*  MAPPING MACROS                                                       74480020
         IKJCPPL                                                        74560020
         IKJPPL                                                         74640020
LPPL     EQU   *-PPL               LENGTH OF PPL                        74720020
         IKJDFPL                                                        74800020
LDFPL    EQU   *-DFPL              LENGTH OF DFPL                       74880020
         IKJDFPB                                                        74960020
LDFPB    EQU   *-DFPB              LENGTH OF DFPB                       75040020
         IKJPSCB                                                        75120020
         IKJIOPL                                                        75200020
LIOPL    EQU   *-IOPL              LENGTH OF IOPL                       75280020
         IKJSTPB                                                        75282020
LSTPB    EQU   *-STPB              LENGTH OF STPB                       75284020
         IKJDAPL                                                        75290020
LDAPL    EQU   *-DAPL              LENGTH OF DAPL                       75300020
         IKJDAP18                                                       75310020
LDAPB18  EQU   *-DAPB18                                                 75320020
         IECSDSL1 1                                                     75330020
         EJECT                                                          75360020
*              GETMAIN COMMON AREA                                      75440020
*                                                                       75520020
COMMON   DSECT                                                          75600020
SAVEAREA DS    18F                 REGISTER SAVE AREA                   75680020
UNPACK   DS    D                   WORK AREA FOR CVD                    75760020
COUNT    DS    D                   WORK AREA FOR UNPACK                 75840020
         ORG   COUNT+F7            BACK TO LAST BYTE OF COUNT FIELD     75920020
SIGNBYTE DS    CL1                 LABEL THE SIGN BYTE                  76000020
         ORG                                                            76080020
ENDCOUNT EQU   *                   END OF COUNT FIELD                   76160020
         DS    0D                  ALIGN DOUBLE WORD BOUNDARY           76170020
WORKAREA DS    350C                WORKAREA FOR LOCATE AND OBTAIN       76200020
         ORG   WORKAREA+F6         SUCCESSFUL LOCATE PUTS-              76202020
VOLNUM   DS    6C                  -VOLUME NUMBER HERE                  76204020
         ORG                                                            76206020
         DS    0F                  ALIGN SVC PARAMETER LIST             76210020
SVCPARMS EQU   *                   SVC 98 PARAMETER LIST                76240020
SVCOPT   DS    CL1                 SVC 98 ENTRY CODE                    76320020
         DS    CL3                 SVC 98 UNUSED (RESERVED)             76400020
SVCDSL   DS    CL1                 SVC 98 DATA SET LENGTH               76480020
SVCDSN   DS    CL3                 SVC 98 POINTER TO DATA SET NAME      76560020
SVCCURPW DS    F                   SVC 98 POINTER TO CURRENT PASSWORD   76640020
SVCCONPW DS    F                   SVC 98 POINTER TO CONTROL PASSWORD   76720020
SVCVOLS  DS    CL1                 SVC 98 NUMBER OF VOLUMES             76800020
SVCVLIST DS    CL3                 SVC 98 POINTER TO VOLUME LIST        76880020
SVCPCODE DS    CL1                 SVC 98 PROTECTION CODE               76960020
SVCNEWPW DS    CL3                 SVC 98 POINTER TO NEW PASSWORD       77040020
SVCSTLTH DS    CL1                 SVC 98 STRING LENGTH                 77120020
SVCSTRNG DS    CL3                 SVC 98 POINTER TO STRING             77200020
SVCNPRMS EQU   *                   SVC 98 END OF PARAMETER LIST         77280020
         DS    0F                  ALIGN PASSWORD LIST                  77360020
PWLIST   EQU   *                   PASSWORD LIST                        77440020
CURENTPW DS    2F                  CURRENT PASSWORD                     77520020
CONTRLPW DS    2F                  CONTROL PASSWORD                     77600020
NEWPW    DS    2F                  NEW PASSWORD                         77680020
ENDPWLST EQU   *                   END OF PASSWORD LIST                 77760020
LISTBUFF EQU   *                   LIST BUFFER                          77840020
PROUSECT DS    CL2                 PROTECTION USE COUNT                 77920020
PROMODE  DS    CL1                 PROTECTION MODE BYTE                 78000020
PUSRDATA DS    CL77                USER DATA                            78080020
ENDLSTBF EQU   *                   END OF LIST BUFFER                   78160020
DSL      DS    CL2                 DATA SET LENGTH                      78240020
DSN      DS    CL44                DATA SET NAME                        78320020
PROCODE  DS    CL1                 PROTECTION CODE SAVED HERE           78400020
VNUM     DS    CL6                 VOLUME NUMBER                        78440020
PROCPECB DS    F                   PROTECT'S ECB                        78480020
ANSPLACE DS    F                   PARSE RETURNS PDL ADDRESS HERE       78560020
         DS    0F                  ALIGN WORD BOUNDRY                   78640020
IOPARM   DS    (LIOPL)X            I/O PARAMETER LIST                   78720020
         DS    0F                  ALIGN WORD BOUNDRY                   78770020
STACKPRM DS    (LSTPB)X            SPACE FOR STACK PARM BLOCK           78780020
         DS    0F                  ALIGN WORD BOUNDRY                   78800020
DFLTPARM DS    (LDFPL)X            DEFAULT PARAMETER LIST               78880020
         DS    0F                  ALIGN WORD BOUNDRY                   78960020
DFLTPBLK DS    (LDFPB)X            DEFAULT PARAMETER BLOCK              79040020
         DS    0F                  ALIGN WORD BOUNDRY                   79120020
PARSPARM DS    (LPPL)X             PARSE PARAMETER LIST                 79200020
         DS    0F                  ALIGN WORD BOUNDRY                   79210020
DAIRPARM DS    (LDAPL)X            SPACE FOR DAIR PARAMETER LIST        79220020
         DS    0F                  ALIGN WORD BOUNDRY                   79230020
DAIR18   DS    (LDAPB18)X          SPACE FOR DAIR ENTRY '18'            79240020
DAIREND  EQU   *-DAIR18            LENGTH OF DAIR ENTRY '18'            79250020
WORKWORD DS    F                   WORK SPACE (TEMPORARY SAVE AREA)     79280020
PSCBSAVE DS    F                   SAVE PSCB ADDRESS HERE               79360020
PRMPTBFL DS    H                   PROMPT BUFFER LENGTH                 79440020
PRMPTBFO DS    H                   PROMPT BUFFER OFFSET                 79520020
PRMPTBUF DS    H                   PROMPT BUFFER                        79600020
*  THE FOLLOWING IS RESERVED SPACE FOR OUTPUT CHAINS                    79680020
OUTAREA1 DS    F                   MESSAGE CHAIN POINTER                79760020
OUTCNT1  DS    F                   MESSAGE SEGMENT COUNT                79840020
OUTPUT11 DS    F                   POINTER TO MESSAGE SEGMENT           79920020
OUTPUT12 DS    F                   POINTER TO MESSAGE INSERTION         80000020
OUTAREA2 DS    F                   MESSAGE CHAIN POINTER                80080020
OUTCNT2  DS    F                   MESSAGE SEGMENT COUNT                80160020
OUTPUT21 DS    F                   POINTER TO MESSAGE SEGMENT           80240020
OUTPUT22 DS    F                   POINTER TO MESSAGE INSERTION         80320020
*  BUFFER FOR PRINTING USER DATA                                        80400020
OUTBUFF  DS    H                   LENGTH OF DATA BUFFER + HEADER       80480020
OUTBUFFO DS    H                   OFFSET FOR DATA BUFFER               80560020
OUTBUFFR DS    CL84                DATA BUFFER                          80640020
*  RETURN CODE FOR MESSAGES STORED HERE                                 80720020
RCMESGL  DS    H                   LENGTH OF RETURN CODE                80800020
RCMESGO  DS    H                   OFFSET FOR INSERTION                 80880020
RCMESG   DS    CL4                 RETURN CODE                          80960020
*  DATA SET NAME FOR MESSAGES STORED HERE                               81040020
DSNMESGL DS    H                   LENGTH OF DSNAME                     81120020
DSNMESGO DS    H                   OFFSET FOR INSERTION                 81200020
DSNMESG  DS    CL54                DATA SET NAME                        81280020
*  PASSWORD FOR MESSAGES STORED HERE                                    81360020
PWMSGL   DS    H                   LENGTH OF PASSWORD                   81440020
PWMSGO   DS    H                   OFFSET FOR INSERTION                 81520020
PWMSG    DS    CL8                 PASSWORD                             81600020
PWBLANK  DS    CL1                 BLANK DELIMITER                      81680020
RC       DS    CL1                 RETURN CODE SAVED HERE               81760020
PRMPTCNT DS    CL1                 PROMPT COUNTER                       81840020
PROMPTSW DS    CL1                 SWITCH INDICATES PROMPTING REQUIRED  81920020
STACKSW  DS    CL1                 INDICATE FLUSH STACK AND CLEAR QUEUE 81970020
PUT      PUTLINE  MF=L             LIST FORM OF PUTLINE                 82000020
PUTDATA  PUTLINE  MF=L             LIST FORM OF PUTLINE                 82080020
*  KEEP LOCATE AND OBTAIN LISTS TOGETHER                                82088020
LOCLIST  CAMLST NAME,DSN,,WORKAREA LOCATE CAMLST                        82096020
LOCDSN   EQU   LOCLIST+F4          LABEL-                               82104020
LOCAREA  EQU   LOCLIST+F12         -LOCATE CAMLST FIELDS                82112020
OBTNLIST CAMLST SEARCH,DSN,VNUM,WORKAREA OBTAIN CAMLST                  82120020
OBTNDSN  EQU   OBTNLIST+F4         LABEL-                               82128020
OBTNVNUM EQU   OBTNLIST+F8         -OBTAIN-                             82136020
OBTNAREA EQU   OBTNLIST+F12        -CAMLST FIELDS                       82144020
CORE     EQU   *-SAVEAREA          SIZE OF WORKAREA                     82160020
         EJECT                                                          82240020
IKJEHMSG CSECT                                                          82320020
         ENTRY IKJEHSMG                                                 82400020
*********************************************************************** 82480020
*                                                                     * 82560020
*  THIS CONTROL SECTION CONTAINS THE MESSAGE TEXT (BOTH FIRST AND     * 82640020
*  SECOND LEVEL).  IT CONTAINS A BRANCH TABLE FOR FIRST LEVEL MESSAGES* 82720020
*  AND A BRANCH TABLE FOR SECOND LEVEL MESSAGES.  EACH BRANCH TABLE   * 82800020
*  ENTRY IS COMPOSED OF A ONE BYTE OFFSET FIELD FOR MESSAGE INSERTIONS* 82880020
*  AND A THREE BYTE ADDRESS OF THE MESSAGE.  THE MESSAGE BUILDER      * 82960020
*  ROUTINES COMBINE THE ADDRESS OF THE CONTROL SECTION AND THE ADDRESS* 83040020
*  OF THE MESSAGE TO GET THE TRUE ADDRESS OF THE MESSAGE.  THE OFFSET * 83120020
*  IS PLACED IN THE INSERTION SEGMENT.                                * 83200020
*  EACH MESSAGE IS COMPOSED OF A 4 BYTE HEADER (2 BYTE LENGTH OF      * 83280020
*  MESSAGE INCLUDING HEADER LENGTH AND A TWO BYTE OFFSET FIELD)       * 83360020
*  FOLLOWED BY THE MESSAGE TEXT.                                      * 83440020
*                                                                     * 83520020
*********************************************************************** 83600020
         SPACE                                                          83680020
*  EQUATES USED IN THIS CONTROL SECTION                                 83760020
HDR      EQU   4                   HEADER LENGTH (2 BYTES EACH, LENGTH  83840020
*                                  AND OFFSET FIELDS) EACH SEGMENT      83920020
OFST     EQU   0                   INSERTION OFFSET 1ST MESSAGE SEGMENT 84000020
*  OFFSETS FOR FIRST LEVEL MESSAGE INSERTIONS                           84080020
OFST01   EQU   37                  INSERTION OFFSET MESSAGE 01          84160020
OFST02   EQU   0                   INSERTION OFFSET MESSAGE 02          84240020
OFST03   EQU   19                  INSERTION OFFSET MESSAGE 03          84320020
OFST04   EQU   56                  INSERTION OFFSET MESSAGE 04          84400020
OFST05   EQU   0                   INSERTION OFFSET MESSAGE 05          84480020
OFST06   EQU   19                  INSERTION OFFSET MESSAGE 06          84560020
OFST07   EQU   19                  INSERTION OFFSET MESSAGE 07          84640020
OFST08   EQU   0                   INSERTION OFFSET MESSAGE 08          84720020
OFST09   EQU   0                   INSERTION OFFSET MESSAGE 09          84800020
OFST10   EQU   37                  INSERTION OFFSET MESSAGE 10          84880020
OFST11   EQU   34                  INSERTION OFFSET MESSAGE 11          84960020
OFST12   EQU   0                   INSERTION OFFSET MESSAGE 12          85040020
*  OFFSETS FOR SECOND LEVEL MESSAGE INSERTIONS                          85200020
*  NOTE-  THERE ARE CURRENTLY NO INSERTIONS IN MOST SECOND LEVEL        85280020
*  MESSAGES.  A COMMON OFFSET OF ZERO IS USED.                          85360020
OFSTSMSG EQU   0                   INSERTION OFFSET 2ND LEVEL MESSAGES  85440020
OFSTSM04 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 04 85520020
OFSTSM05 EQU   27                  INSERTION OFFSET SECOND LEVEL MSG 05 85600020
OFSTSM10 EQU   29                  INSERTION OFFSET SECOND LEVEL MSG 10 85680020
         SPACE                                                          85760020
AMSG01   DC    AL1(OFST01)         INSERTION OFFSET                     85840020
         DC    AL3(LMSG01)         MESSAGE ADDRESS                      85920020
AMSG02   DC    AL1(OFST02)         INSERTION OFFSET                     86000020
         DC    AL3(LMSG02)         MESSAGE ADDRESS                      86080020
AMSG03   DC    AL1(OFST03)         INSERTION OFFSET                     86160020
         DC    AL3(LMSG03)         MESSAGE ADDRESS                      86240020
AMSG04   DC    AL1(OFST04)         INSERTION OFFSET                     86320020
         DC    AL3(LMSG04)         MESSAGE ADDRESS                      86400020
AMSG05   DC    AL1(OFST05)         INSERTION OFFSET                     86480020
         DC    AL3(LMSG05)         MESSAGE ADDRESS                      86560020
AMSG06   DC    AL1(OFST06)         INSERTION OFFSET                     86640020
         DC    AL3(LMSG06)         MESSAGE ADDRESS                      86720020
AMSG07   DC    AL1(OFST07)         INSERTION OFFSET                     86800020
         DC    AL3(LMSG07)         MESSAGE ADDRESS                      86880020
AMSG08   DC    AL1(OFST08)         INSERTION OFFSET                     86960020
         DC    AL3(LMSG08)         MESSAGE ADDRESS                      87040020
AMSG09   DC    AL1(OFST09)         INSERTION OFFSET                     87120020
         DC    AL3(LMSG09)         MESSAGE ADDRESS                      87200020
AMSG10   DC    AL1(OFST10)         INSERTION OFFSET                     87280020
         DC    AL3(LMSG10)         MESSAGE ADDRESS                      87360020
AMSG11   DC    AL1(OFST11)         INSERTION OFFSET                     87440020
         DC    AL3(LMSG11)         MESSAGE ADDRESS                      87520020
AMSG12   DC    AL1(OFST12)         INSERTION OFFSET                     87600020
         DC    AL3(LMSG12)         MESSAGE ADDRESS                      87680020
* FIRST LEVEL MESSAGES                                                  87920020
LMSG01   DC    AL2(L'MSG01+HDR)                                         88000020
         DC    AL2(OFST)                                                88080020
MSG01    DC    C'IKJ58101I UNABLE TO PROTECT DATA SET +'                88160020
LMSG02   DC    AL2(L'MSG02+HDR)                                         88240020
         DC    AL2(OFST)                                                88320020
MSG02    DC    C'IKJ58102I NOT ENOUGH MAIN STORAGE TO EXECUTE COMMAND'  88400020
LMSG03   DC    AL2(L'MSG03+HDR)                                         88480020
         DC    AL2(OFST)                                                88560020
MSG03    DC    C'IKJ58103I DATA SET  NOT IN CATALOG'                    88660020
LMSG04   DC    AL2(L'MSG04+HDR)                                         88800020
         DC    AL2(OFST)                                                88880020
MSG04    DC    C'IKJ58104I UNABLE TO MODIFY PROTECTION FLAGS OF DATA SEX88960020
               T +'                                                     89040020
LMSG05   DC    AL2(L'MSG05+HDR)                                         89120020
         DC    AL2(OFST)                                                89200020
MSG05    DC    C'IKJ58105I INCORRECT PASSWORD ENTERED TWICE'            89280020
LMSG06   DC    AL2(L'MSG06+HDR)                                         89360020
         DC    AL2(OFST)                                                89440020
MSG06    DC    C'IKJ58106I PASSWORD  ALREADY EXISTS'                    89520020
LMSG07   DC    AL2(L'MSG07+HDR)                                         89600020
         DC    AL2(OFST)                                                89680020
MSG07    DC    C'IKJ58107I PASSWORD  DOES NOT EXIST'                    89760020
LMSG08   DC    AL2(L'MSG08+HDR)                                         89840020
         DC    AL2(OFST)                                                89920020
MSG08    DC    C'IKJ58108I PROTECTION IS FOR DATA SETS, NOT MEMBERS'    90000020
LMSG09   DC    AL2(L'MSG09+HDR)                                         90080020
         DC    AL2(OFST)                                                90160020
MSG09    DC    C'IKJ58109I USER DATA FIELD BLANK'                       90240020
LMSG10   DC    AL2(L'MSG10+HDR)                                         90320020
         DC    AL2(OFST)                                                90400020
MSG10    DC    C'IKJ58110I INCORRECT CONTROL PASSWORD '                 90480020
LMSG11   DC    AL2(L'MSG11+HDR)                                         90560020
         DC    AL2(OFST)                                                90640020
MSG11    DC    C'IKJ58111I INVALID DATA SET NAME, '''' EXCEEDS 44 CHARAX90720020
               CTERS'                                                   90800020
LMSG12   DC    AL2(L'MSG12+HDR)                                         90880020
         DC    AL2(OFST)                                                90960020
MSG12    DC    C'IKJ58112I COMMAND SYSTEM ERROR+'                       91040020
IKJEHSMG DS    0F                  SECOND LEVEL MESSAGE BRANCH TABLE    91240020
ASMSG01  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     91440020
         DC    AL3(LSMSG01)        MESSAGE ADDRESS                      91520020
ASMSG02  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     91600020
         DC    AL3(LSMSG02)        MESSAGE ADDRESS                      91680020
ASMSG03  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     91760020
         DC    AL3(LSMSG03)        MESSAGE ADDRESS                      91840020
ASMSG04  DC    AL1(OFSTSM04)       INSERTION OFFSET                     91920020
         DC    AL3(LSMSG04)        MESSAGE ADDRESS                      92000020
ASMSG05  DC    AL1(OFSTSM05)       INSERTION OFFSET                     92080020
         DC    AL3(LSMSG05)        MESSAGE ADDRESS                      92160020
ASMSG06  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     92240020
         DC    AL3(LSMSG06)        MESSAGE ADDRESS                      92320020
ASMSG07  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     92400020
         DC    AL3(LSMSG07)        MESSAGE ADDRESS                      92480020
ASMSG08  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     92560020
         DC    AL3(LSMSG08)        MESSAGE ADDRESS                      92640020
ASMSG09  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     92720020
         DC    AL3(LSMSG09)        MESSAGE ADDRESS                      92800020
ASMSG10  DC    AL1(OFSTSM10)       INSERTION OFFSET                     92880020
         DC    AL3(LSMSG10)        MESSAGE ADDRESS                      92960020
ASMSG11  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     93040020
         DC    AL3(LSMSG11)        MESSAGE ADDRESS                      93120020
ASMSG12  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     93200020
         DC    AL3(LSMSG12)        MESSAGE ADDRESS                      93280020
ASMSG13  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     93360020
         DC    AL3(LSMSG13)        MESSAGE ADDRESS                      93440020
ASMSG14  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     93520020
         DC    AL3(LSMSG14)        MESSAGE ADDRESS                      93600020
ASMSG15  DC    AL1(OFSTSMSG)       INSERTION OFFSET                     93680020
         DC    AL3(LSMSG15)        MESSAGE ADDRESS                      93760020
*  SECOND LEVEL MESSAGES                                                93840020
LSMSG01  DC    AL2(L'SMSG01+HDR)                                        93920020
         DC    AL2(OFST)                                                94000020
SMSG01   DC    C'IKJ58101I PASSWORD DATA SET NOT FOUND'                 94080020
LSMSG02  DC    AL2(L'SMSG02+HDR)                                        94160020
         DC    AL2(OFST)                                                94240020
SMSG02   DC    C'IKJ58101I PASSWORD DATA SET FULL'                      94320020
LSMSG03  DC    AL2(L'SMSG03+HDR)                                        94400020
         DC    AL2(OFST)                                                94480020
SMSG03   DC    C'IKJ58101I I/O ERROR IN PASSWORD DATA SET'              94560020
LSMSG04  DC    AL2(L'SMSG04+HDR)                                        94640020
         DC    AL2(OFST)                                                94720020
SMSG04   DC    C'IKJ58112I DEFAULT ERROR CODE '                         94800020
LSMSG05  DC    AL2(L'SMSG05+HDR)                                        94880020
         DC    AL2(OFST)                                                94960020
SMSG05   DC    C'IKJ58112I PARSE ERROR CODE '                           95040020
LSMSG06  DC    AL2(L'SMSG06+HDR)                                        95080020
         DC    AL2(OFST)                                                95120020
SMSG06   DC    C'IKJ58104I DATA SET IN USE'                             95160020
LSMSG07  EQU   *                   UNUSED SECOND LEVEL MESSAGE          95200020
LSMSG08  EQU   *                   UNUSED SECOND LEVEL MESSAGE          95280020
LSMSG09  EQU   *                   UNUSED SECOND LEVEL MESSAGE          95360020
LSMSG10  DC    AL2(L'SMSG10+HDR)                                        95440020
         DC    AL2(OFST)                                                95520020
SMSG10   DC    C'IKJ58112I SVC 98 RETURN CODE '                         95600020
LSMSG11  DC    AL2(L'SMSG11+HDR)                                        95680020
         DC    AL2(OFST)                                                95760020
SMSG11   DC    C'IKJ58104I DATA SET NOT IN CATALOG'                     95840020
LSMSG12  DC    AL2(L'SMSG12+HDR)                                        95920020
         DC    AL2(OFST)                                                96000020
SMSG12   DC    C'IKJ58104I DATA SET NOT ON VOLUME'                      96080020
LSMSG13  DC    AL2(L'SMSG13+HDR)                                        96160020
         DC    AL2(OFST)                                                96240020
SMSG13   DC    C'IKJ58104I REQUIRED VOLUME NOT MOUNTED'                 96320020
LSMSG14  DC    AL2(L'SMSG14+HDR)                                        96400020
         DC    AL2(OFST)                                                96480020
SMSG14   DC    C'IKJ58104I TAPE DATA SET CANNOT BE PROTECTED BY PROTECTX96560020
               '                                                        96640020
LSMSG15  DC    AL2(L'SMSG15+HDR)                                        96720020
         DC    AL2(OFST)                                                96800020
SMSG15   DC    C'IKJ58104I I/O ERROR WHILE UPDATING SECURITY FLAGS'     96880020
         END                                                            96960020
